This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
When running tests from lib/, set @INC and $ENV{PERL5LIB} to ../lib
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still currrent
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the the default, as it saves some fakery within TestInit
27 # which can peturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Extract' => 1,
32            '../cpan/Archive-Tar' => 1,
33            '../cpan/AutoLoader' => 1,
34            '../cpan/CPAN' => 1,
35            '../cpan/Class-ISA' => 1,
36            '../cpan/Devel-PPPort' => 1,
37            '../cpan/Encode' => 1,
38            '../cpan/ExtUtils-Constant' => 1,
39            '../cpan/ExtUtils-MakeMaker' => 1,
40            '../cpan/File-Fetch' => 1,
41            '../cpan/IPC-Cmd' => 1,
42            '../cpan/IPC-SysV' => 1,
43            '../cpan/Locale-Codes' => 1,
44            '../cpan/Log-Message' => 1,
45            '../cpan/Math-Complex' => 1,
46            '../cpan/Module-Build' => 1,
47            '../cpan/Module-Load' => 1,
48            '../cpan/Module-Load-Conditional' => 1,
49            '../cpan/Object-Accessor' => 1,
50            '../cpan/Package-Constants' => 1,
51            '../cpan/Parse-CPAN-Meta' => 1,
52            '../cpan/Pod-Simple' => 1,
53            '../cpan/Term-UI' => 1,
54            '../cpan/Test-Simple' => 1,
55            '../cpan/Tie-File' => 1,
56            '../cpan/podlators' => 1,
57            '../dist/Cwd' => 1,
58            '../dist/ExtUtils-Command' => 1,
59            '../dist/ExtUtils-Install' => 1,
60            '../dist/ExtUtils-Manifest' => 1,
61            '../dist/ExtUtils-ParseXS' => 1,
62           );
63
64 my %temp_no_core =
65     ('../cpan/B-Debug' => 1,
66      '../cpan/Compress-Raw-Bzip2' => 1,
67      '../cpan/Compress-Raw-Zlib' => 1,
68      '../cpan/Devel-PPPort' => 1,
69      '../cpan/Getopt-Long' => 1,
70      '../cpan/IO-Compress' => 1,
71      '../cpan/MIME-Base64' => 1,
72      '../cpan/parent' => 1,
73      '../cpan/Parse-CPAN-Meta' => 1,
74      '../cpan/Pod-Simple' => 1,
75      '../cpan/podlators' => 1,
76      '../cpan/Test-Simple' => 1,
77      '../cpan/Tie-RefHash' => 1,
78      '../cpan/Time-HiRes' => 1,
79      '../cpan/Unicode-Collate' => 1,
80      '../cpan/Unicode-Normalize' => 1,
81     );
82
83 # delete env vars that may influence the results
84 # but allow override via *_TEST env var if wanted
85 # (e.g. PERL5OPT_TEST=-d:NYTProf)
86 for my $envname (qw(PERL5LIB PERLLIB PERL5OPT)) {
87     my $override = $ENV{"${envname}_TEST"};
88     if (defined $override) {
89         warn "$0: $envname=$override\n";
90         $ENV{$envname} = $override;
91     }
92     else {
93         delete $ENV{$envname};
94     }
95 }
96
97 if ($::do_nothing) {
98     return 1;
99 }
100
101 # Location to put the Valgrind log.
102 our $Valgrind_Log;
103
104 $| = 1;
105
106 # for testing TEST only
107 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
108 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
109
110 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
111 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
112 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
113
114 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
115 # can't rely on require working.
116 {
117     my @argv = ();
118     foreach my $idx (0..$#ARGV) {
119         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
120         $::benchmark = 1 if $1 eq 'benchmark';
121         $::core    = 1 if $1 eq 'core';
122         $::verbose = 1 if $1 eq 'v';
123         $::torture = 1 if $1 eq 'torture';
124         $::with_utf8 = 1 if $1 eq 'utf8';
125         $::with_utf16 = 1 if $1 eq 'utf16';
126         $::taintwarn = 1 if $1 eq 'taintwarn';
127         $ENV{PERL_CORE_MINITEST} = 1 if $1 eq 'minitest';
128         if ($1 =~ /^deparse(,.+)?$/) {
129             $::deparse = 1;
130             $::deparse_opts = $1;
131         }
132     }
133     @ARGV = @argv;
134 }
135
136 chdir 't' if -f 't/TEST';
137 if (-f 'TEST' && -f 'harness' && -d '../lib') {
138     @INC = '../lib';
139 }
140
141 die "You need to run \"make test\" first to set things up.\n"
142   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
143
144 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
145     unless (-x 'perl.third') {
146         unless (-x '../perl.third') {
147             die "You need to run \"make perl.third first.\n";
148         }
149         else {
150             print "Symlinking ../perl.third as perl.third...\n";
151             die "Failed to symlink: $!\n"
152                 unless symlink("../perl.third", "perl.third");
153             die "Symlinked but no executable perl.third: $!\n"
154                 unless -x 'perl.third';
155         }
156     }
157 }
158
159 # check leakage for embedders
160 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
161
162 $ENV{EMXSHELL} = 'sh';        # For OS/2
163
164 if ($show_elapsed_time) { require Time::HiRes }
165
166 my %skip = (
167             '.' => 1,
168             '..' => 1,
169             'CVS' => 1,
170             'RCS' => 1,
171             'SCCS' => 1,
172             '.svn' => 1,
173            );
174
175 # Roll your own File::Find!
176 sub _find_tests {
177     my($dir) = @_;
178     opendir DIR, $dir or die "Trouble opening $dir: $!";
179     foreach my $f (sort { $a cmp $b } readdir DIR) {
180         next if $skip{$f};
181
182         my $fullpath = "$dir/$f";
183
184         if (-d $fullpath) {
185             _find_tests($fullpath);
186         } elsif ($f =~ /\.t$/) {
187             push @ARGV, $fullpath;
188         }
189     }
190 }
191
192
193 # Scan the text of the test program to find switches and special options
194 # we might need to apply.
195 sub _scan_test {
196     my($test, $type) = @_;
197
198     open(my $script, "<", $test) or die "Can't read $test.\n";
199     my $first_line = <$script>;
200
201     $first_line =~ tr/\0//d if $::with_utf16;
202
203     my $switch = "";
204     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
205         $switch = "-$1";
206     } else {
207         if ($::taintwarn) {
208             # not all tests are expected to pass with this option
209             $switch = '-t';
210         } else {
211             $switch = '';
212         }
213     }
214
215     my $file_opts = "";
216     if ($type eq 'deparse') {
217         # Look for #line directives which change the filename
218         while (<$script>) {
219             $file_opts = $file_opts . ",-f$3$4"
220               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
221         }
222     }
223
224     close $script;
225
226     my $perl = './perl';
227     my $lib  = '../lib';
228     my $run_dir;
229     my $return_dir;
230
231     $test =~ /^(.+)\/[^\/]+/;
232     my $dir = $1;
233     my $testswitch = $dir_to_switch{$dir};
234     if (!defined $testswitch) {
235         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
236             $run_dir = $1;
237             $return_dir = '../../t';
238             $lib = '../../lib';
239             $perl = '../../t/perl';
240             $testswitch = "-I../.. -MTestInit=U2T";
241             if ($2 eq 'cpan' || $2 eq 'dist') {
242                 if($abs{$run_dir}) {
243                     $testswitch = $testswitch . ',A';
244                 }
245                 if ($temp_no_core{$run_dir}) {
246                     $testswitch = $testswitch . ',NC';
247                 }
248             }
249         } elsif ($test =~ m!^\.\./lib!) {
250             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
251         } else {
252             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
253         }
254     }
255
256     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
257
258     my %options = (
259         perl => $perl,
260         lib => $lib,
261         test => $test,
262         run_dir => $run_dir,
263         return_dir => $return_dir,
264         testswitch => $testswitch,
265         utf8 => $utf8,
266         file => $file_opts,
267         switch => $switch,
268     );
269
270     return \%options;
271 }
272
273 sub _cmd {
274     my($options, $type) = @_;
275
276     my $test = $options->{test};
277
278     my $cmd;
279     if ($type eq 'deparse') {
280         my $perl = "$options->{perl} $options->{testswitch}";
281         my $lib = $options->{lib};
282
283         $cmd = (
284           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
285           "-l$::deparse_opts$options->{file} ".
286           "$test > $test.dp ".
287           "&& $perl $options->{switch} -I$lib $test.dp"
288         );
289     }
290     elsif ($type eq 'perl') {
291         my $perl = $options->{perl};
292         my $redir = $^O eq 'VMS' ? '2>&1' : '';
293
294         if ($ENV{PERL_VALGRIND}) {
295             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
296             my $valgrind = $ENV{VALGRIND} // 'valgrind';
297             my $vg_opts = $ENV{VG_OPTS}
298               //  "--suppressions=$perl_supp --leak-check=yes "
299                 . "--leak-resolution=high --show-reachable=yes "
300                   . "--num-callers=50 --track-origins=yes";
301             $perl = "$valgrind --log-fd=3 $vg_opts $perl";
302             $redir = "3>$Valgrind_Log";
303             if ($options->{run_dir}) {
304                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
305             }
306         }
307
308         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
309         $cmd = $perl . _quote_args($args) . " $test $redir";
310     }
311
312     return $cmd;
313 }
314
315 sub _before_fork {
316     my ($options) = @_;
317
318     if ($options->{run_dir}) {
319         my $run_dir = $options->{run_dir};
320         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
321     }
322
323     return;
324 }
325
326 sub _after_fork {
327     my ($options) = @_;
328
329     if ($options->{return_dir}) {
330         my $return_dir = $options->{return_dir};
331         chdir $return_dir
332            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
333     }
334
335     return;
336 }
337
338 sub _run_test {
339     my ($test, $type) = @_;
340
341     my $options = _scan_test($test, $type);
342     # $test might have changed if we're in ext/Foo, so don't use it anymore
343     # from now on. Use $options->{test} instead.
344
345     _before_fork($options);
346
347     my $cmd = _cmd($options, $type);
348
349     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
350
351     _after_fork($options);
352
353     # Our environment may force us to use UTF-8, but we can't be sure that
354     # anything we're reading from will be generating (well formed) UTF-8
355     # This may not be the best way - possibly we should unset ${^OPEN} up
356     # top?
357     binmode $results;
358
359     return $results;
360 }
361
362 sub _quote_args {
363     my ($args) = @_;
364     my $argstring = '';
365
366     foreach (split(/\s+/,$args)) {
367        # In VMS protect with doublequotes because otherwise
368        # DCL will lowercase -- unless already doublequoted.
369        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
370        $argstring = $argstring . ' ' . $_;
371     }
372     return $argstring;
373 }
374
375 sub _populate_hash {
376     return unless defined $_[0];
377     return map {$_, 1} split /\s+/, $_[0];
378 }
379
380 sub _tests_from_manifest {
381     my ($extensions, $known_extensions) = @_;
382     my %skip;
383     my %extensions = _populate_hash($extensions);
384     my %known_extensions = _populate_hash($known_extensions);
385
386     foreach (keys %known_extensions) {
387         $skip{$_} = 1 unless $extensions{$_};
388     }
389
390     my @results;
391     my $mani = '../MANIFEST';
392     if (open(MANI, $mani)) {
393         while (<MANI>) {
394             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
395                 my $t = $1;
396                 my $extension = $2;
397                 if (!$::core || $t =~ m!^lib/[a-z]!) {
398                     if (defined $extension) {
399                         $extension =~ s!/t(:?/\S+)*$!!;
400                         # XXX Do I want to warn that I'm skipping these?
401                         next if $skip{$extension};
402                         my $flat_extension = $extension;
403                         $flat_extension =~ s!-!/!g;
404                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
405                     }
406                     my $path = "../$t";
407                     push @results, $path;
408                     $::path_to_name{$path} = $t;
409                 }
410             }
411         }
412         close MANI;
413     } else {
414         warn "$0: cannot open $mani: $!\n";
415     }
416     return @results;
417 }
418
419 unless (@ARGV) {
420     # base first, as TEST bails out if that can't run
421     # then comp, to validate that require works
422     # then run, to validate that -M works
423     # then we know we can -MTestInit for everything else, making life simpler
424     foreach my $dir (qw(base comp run cmd io re op uni mro)) {
425         _find_tests($dir);
426     }
427     _find_tests("lib") unless $::core;
428     # Config.pm may be broken for make minitest. And this is only a refinement
429     # for skipping tests on non-default builds, so it is allowed to fail.
430     # What we want to to is make a list of extensions which we did not build.
431     my $configsh = '../config.sh';
432     my ($extensions, $known_extensions);
433     if (-f $configsh) {
434         open FH, $configsh or die "Can't open $configsh: $!";
435         while (<FH>) {
436             if (/^extensions=['"](.*)['"]$/) {
437                 $extensions = $1;
438             }
439             elsif (/^known_extensions=['"](.*)['"]$/) {
440                 $known_extensions = $1;
441             }
442         }
443         if (!defined $known_extensions) {
444             warn "No known_extensions line found in $configsh";
445         }
446         if (!defined $extensions) {
447             warn "No extensions line found in $configsh";
448         }
449     }
450     # The "complex" constructions of list return from a subroutine, and push of
451     # a list, might fail if perl is really hosed, but they aren't needed for
452     # make minitest, and the building of extensions will likely also fail if
453     # something is that badly wrong.
454     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
455     unless ($::core) {
456         _find_tests('x2p');
457         _find_tests('porting');
458         _find_tests('japh') if $::torture;
459         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
460     }
461 }
462
463 if ($::deparse) {
464     _testprogs('deparse', '',   @ARGV);
465 }
466 elsif ($::with_utf16) {
467     for my $e (0, 1) {
468         for my $b (0, 1) {
469             print STDERR "# ENDIAN $e BOM $b\n";
470             my @UARGV;
471             for my $a (@ARGV) {
472                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
473                 my $f = $e ? "v" : "n";
474                 push @UARGV, $u;
475                 unlink($u);
476                 if (open(A, $a)) {
477                     if (open(U, ">$u")) {
478                         print U pack("$f", 0xFEFF) if $b;
479                         while (<A>) {
480                             print U pack("$f*", unpack("C*", $_));
481                         }
482                         close(U);
483                     }
484                     close(A);
485                 }
486             }
487             _testprogs('perl', '', @UARGV);
488             unlink(@UARGV);
489         }
490     }
491 }
492 else {
493     _testprogs('perl',    '',   @ARGV);
494 }
495
496 sub _testprogs {
497     my ($type, $args, @tests) = @_;
498
499     print <<'EOT' if ($type eq 'deparse');
500 ------------------------------------------------------------------------------
501 TESTING DEPARSER
502 ------------------------------------------------------------------------------
503 EOT
504
505     $::bad_files = 0;
506
507     foreach my $t (@tests) {
508       unless (exists $::path_to_name{$t}) {
509         my $tname = "t/$t";
510         $::path_to_name{$t} = $tname;
511       }
512     }
513     my $maxlen = 0;
514     foreach (@::path_to_name{@tests}) {
515         s/\.\w+\z/./;
516         my $len = length ;
517         $maxlen = $len if $len > $maxlen;
518     }
519     # + 3 : we want three dots between the test name and the "ok"
520     my $dotdotdot = $maxlen + 3 ;
521     my $valgrind = 0;
522     my $total_files = @tests;
523     my $good_files = 0;
524     my $tested_files  = 0;
525     my $totmax = 0;
526     my %failed_tests;
527
528     while (my $test = shift @tests) {
529         my $test_start_time = $show_elapsed_time ? Time::HiRes::time() : 0;
530
531         if ($test =~ /^$/) {
532             next;
533         }
534         if ($type eq 'deparse') {
535             if ($test eq "comp/redef.t") {
536                 # Redefinition happens at compile time
537                 next;
538             }
539             elsif ($test =~ m{lib/Switch/t/}) {
540                 # B::Deparse doesn't support source filtering
541                 next;
542             }
543         }
544         my $te = $::path_to_name{$test} . '.'
545                     x ($dotdotdot - length($::path_to_name{$test}));
546
547         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
548             print $te;
549             $te = '';
550         }
551
552         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
553         my $results = _run_test($test, $type);
554
555         my $failure;
556         my $next = 0;
557         my $seen_leader = 0;
558         my $seen_ok = 0;
559         my $trailing_leader = 0;
560         my $max;
561         my %todo;
562         while (<$results>) {
563             next if /^\s*$/; # skip blank lines
564             if (/^1..$/ && ($^O eq 'VMS')) {
565                 # VMS pipe bug inserts blank lines.
566                 my $l2 = <RESULTS>;
567                 if ($l2 =~ /^\s*$/) {
568                     $l2 = <RESULTS>;
569                 }
570                 $_ = '1..' . $l2;
571             }
572             if ($::verbose) {
573                 print $_;
574             }
575             unless (/^\#/) {
576                 if ($trailing_leader) {
577                     # shouldn't be anything following a postfix 1..n
578                     $failure = 'FAILED--extra output after trailing 1..n';
579                     last;
580                 }
581                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
582                     if ($seen_leader) {
583                         $failure = 'FAILED--seen duplicate leader';
584                         last;
585                     }
586                     $max = $1;
587                     %todo = map { $_ => 1 } split / /, $3 if $3;
588                     $totmax = $totmax + $max;
589                     $tested_files = $tested_files + 1;
590                     if ($seen_ok) {
591                         # 1..n appears at end of file
592                         $trailing_leader = 1;
593                         if ($next != $max) {
594                             $failure = "FAILED--expected $max tests, saw $next";
595                             last;
596                         }
597                     }
598                     else {
599                         $next = 0;
600                     }
601                     $seen_leader = 1;
602                 }
603                 else {
604                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
605                         unless ($seen_leader) {
606                             unless ($seen_ok) {
607                                 $next = 0;
608                             }
609                         }
610                         $seen_ok = 1;
611                         $next = $next + 1;
612                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
613                         $num = $next unless $num;
614
615                         if ($num == $next) {
616
617                             # SKIP is essentially the same as TODO for t/TEST
618                             # this still conforms to TAP:
619                             # http://search.cpan.org/dist/TAP/TAP.pm
620                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
621                             $istodo = 1 if $todo{$num};
622
623                             if( $not && !$istodo ) {
624                                 $failure = "FAILED at test $num";
625                                 last;
626                             }
627                         }
628                         else {
629                             $failure ="FAILED--expected test $next, saw test $num";
630                             last;
631                         }
632                     }
633                     elsif (/^Bail out!\s*(.*)/i) { # magic words
634                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
635                     }
636                     else {
637                         # module tests are allowed extra output,
638                         # because Test::Harness allows it
639                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
640                         $failure = "FAILED--unexpected output at test $next";
641                         last;
642                     }
643                 }
644             }
645         }
646         close $results;
647
648         if (not defined $failure) {
649             $failure = 'FAILED--no leader found' unless $seen_leader;
650         }
651
652         if ($ENV{PERL_VALGRIND}) {
653             my @valgrind;
654             if (-e $Valgrind_Log) {
655                 if (open(V, $Valgrind_Log)) {
656                     @valgrind = <V>;
657                     close V;
658                 } else {
659                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
660                 }
661             }
662             if ($ENV{VG_OPTS} =~ /cachegrind/) {
663                 if (rename $Valgrind_Log, "$test.valgrind") {
664                     $valgrind = $valgrind + 1;
665                 } else {
666                     warn "$0: Failed to create '$test.valgrind': $!\n";
667                 }
668             }
669             elsif (@valgrind) {
670                 my $leaks = 0;
671                 my $errors = 0;
672                 for my $i (0..$#valgrind) {
673                     local $_ = $valgrind[$i];
674                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
675                         $errors = $errors + $1;   # there may be multiple error summaries
676                     } elsif (/^==\d+== LEAK SUMMARY:/) {
677                         for my $off (1 .. 4) {
678                             if ($valgrind[$i+$off] =~
679                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
680                                 $leaks = $leaks + $1;
681                             }
682                         }
683                     }
684                 }
685                 if ($errors or $leaks) {
686                     if (rename $Valgrind_Log, "$test.valgrind") {
687                         $valgrind = $valgrind + 1;
688                     } else {
689                         warn "$0: Failed to create '$test.valgrind': $!\n";
690                     }
691                 }
692             } else {
693                 warn "No valgrind output?\n";
694             }
695             if (-e $Valgrind_Log) {
696                 unlink $Valgrind_Log
697                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
698             }
699         }
700         if ($type eq 'deparse') {
701             unlink "./$test.dp";
702         }
703         if ($ENV{PERL_3LOG}) {
704             my $tpp = $test;
705             $tpp =~ s:^\.\./::;
706             $tpp =~ s:/:_:g;
707             $tpp =~ s:\.t$:.3log:;
708             rename("perl.3log", $tpp) ||
709                 die "rename: perl3.log to $tpp: $!\n";
710         }
711         if (not defined $failure and $next != $max) {
712             $failure="FAILED--expected $max tests, saw $next";
713         }
714
715         if( !defined $failure  # don't mask a test failure
716             and $? )
717         {
718             $failure = "FAILED--non-zero wait status: $?";
719         }
720
721         if (defined $failure) {
722             print "${te}$failure\n";
723             $::bad_files = $::bad_files + 1;
724             if ($test =~ /^base/) {
725                 die "Failed a basic test ($test) -- cannot continue.\n";
726             }
727             $failed_tests{$test} = 1;
728         }
729         else {
730             if ($max) {
731                 my $elapsed;
732                 if ( $show_elapsed_time ) {
733                     $elapsed = sprintf( " %8.0f ms", (Time::HiRes::time() - $test_start_time) * 1000 );
734                 }
735                 else {
736                     $elapsed = "";
737                 }
738                 print "${te}ok$elapsed\n";
739                 $good_files = $good_files + 1;
740             }
741             else {
742                 print "${te}skipped\n";
743                 $tested_files = $tested_files - 1;
744             }
745         }
746     } # while tests
747
748     if ($::bad_files == 0) {
749         if ($good_files) {
750             print "All tests successful.\n";
751             # XXX add mention of 'perlbug -ok' ?
752         }
753         else {
754             die "FAILED--no tests were run for some reason.\n";
755         }
756     }
757     else {
758         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
759         my $s = $::bad_files == 1 ? "" : "s";
760         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
761         for my $test ( sort keys %failed_tests ) {
762             print "\t$test\n";
763         }
764         warn <<'SHRDLU_1';
765 ### Since not all tests were successful, you may want to run some of
766 ### them individually and examine any diagnostic messages they produce.
767 ### See the INSTALL document's section on "make test".
768 SHRDLU_1
769         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
770 ### You have a good chance to get more information by running
771 ###   ./perl harness
772 ### in the 't' directory since most (>=80%) of the tests succeeded.
773 SHRDLU_2
774         if (eval {require Config; import Config; 1}) {
775             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
776                 warn <<SHRDLU_3;
777 ### You may have to set your dynamic library search path,
778 ### $p, to point to the build directory:
779 SHRDLU_3
780                 if (exists $ENV{$p} && $ENV{$p} ne '') {
781                     warn <<SHRDLU_4a;
782 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
783 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
784 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
785 SHRDLU_4a
786                 } else {
787                     warn <<SHRDLU_4b;
788 ###   setenv $p `pwd`; cd t; ./perl harness
789 ###   $p=`pwd`; export $p; cd t; ./perl harness
790 ###   export $p=`pwd`; cd t; ./perl harness
791 SHRDLU_4b
792                 }
793                 warn <<SHRDLU_5;
794 ### for csh-style shells, like tcsh; or for traditional/modern
795 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
796 SHRDLU_5
797             }
798         }
799     }
800     my ($user,$sys,$cuser,$csys) = times;
801     print sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d\n",
802         $user,$sys,$cuser,$csys,$tested_files,$totmax);
803     if ($ENV{PERL_VALGRIND}) {
804         my $s = $valgrind == 1 ? '' : 's';
805         print "$valgrind valgrind report$s created.\n", ;
806     }
807 }
808 exit ($::bad_files != 0);
809
810 # ex: set ts=8 sts=4 sw=4 noet: