t/op/write.t

   1 #!./perl
   2
   3 BEGIN {
   4     chdir 't' if -d 't';
   5     @INC = '../lib';
   6     require './test.pl';
   7 }
   8
   9 use strict;     # Amazed that this hackery can be made strict ...
  10
  11 # read in a file
  12 sub cat {
  13     my $file = shift;
  14     local $/;
  15     open my $fh, $file or die "can't open '$file': $!";
  16     my $data = <$fh>;
  17     close $fh;
  18     $data;
  19 }
  20
  21 #-- testing numeric fields in all variants (WL)
  22
  23 sub swrite {
  24     my $format = shift;
  25     local $^A = ""; # don't litter, use a local bin
  26     formline( $format, @_ );
  27     return $^A;
  28 }
  29
  30 my @NumTests = (
  31     # [ format, value1, expected1, value2, expected2, .... ]
  32     [ '@###',           0,   '   0',         1, '   1',     9999.6, '####',
  33                 9999.4999,   '9999',    -999.6, '####',     1e+100, '####' ],
  34
  35     [ '@0##',           0,   '0000',         1, '0001',     9999.6, '####',
  36                 -999.4999,   '-999',    -999.6, '####',     1e+100, '####' ],
  37
  38     [ '^###',           0,   '   0',     undef, '    ' ],
  39
  40     [ '^0##',           0,   '0000',     undef, '    ' ],
  41
  42     [ '@###.',          0,  '   0.',         1, '   1.',    9999.6, '#####',
  43                 9999.4999,  '9999.',    -999.6, '#####' ],
  44
  45     [ '@##.##',         0, '  0.00',         1, '  1.00',  999.996, '######',
  46                 999.99499, '999.99',      -100, '######' ],
  47
  48     [ '@0#.##',         0, '000.00',         1, '001.00',       10, '010.00',
  49                   -0.0001, qr/^[\-0]00\.00$/ ],
  50
  51 );
  52
  53
  54 my $num_tests = 0;
  55 for my $tref ( @NumTests ){
  56     $num_tests += (@$tref - 1)/2;
  57 }
  58 #---------------------------------------------------------
  59
  60 # number of tests in section 1
  61 my $bas_tests = 20;
  62
  63 # number of tests in section 3
  64 my $bug_tests = 4 + 3 * 3 * 5 * 2 * 3 + 2 + 66 + 4 + 2 + 1 + 1;
  65
  66 # number of tests in section 4
  67 my $hmb_tests = 35;
  68
  69 my $tests = $bas_tests + $num_tests + $bug_tests + $hmb_tests;
  70
  71 plan $tests;
  72
  73 ############
  74 ## Section 1
  75 ############
  76
  77 use vars qw($fox $multiline $foo $good);
  78
  79 format OUT =
  80 the quick brown @<<
  81 $fox
  82 jumped
  83 @*
  84 $multiline
  85 ^<<<<<<<<<
  86 $foo
  87 ^<<<<<<<<<
  88 $foo
  89 ^<<<<<<...
  90 $foo
  91 now @<<the@>>>> for all@|||||men to come @<<<<
  92 {
  93     'i' . 's', "time\n", $good, 'to'
  94 }
  95 .
  96
  97 open(OUT, '>Op_write.tmp') || die "Can't create Op_write.tmp";
  98 END { unlink_all 'Op_write.tmp' }
  99
 100 $fox = 'foxiness';
 101 $good = 'good';
 102 $multiline = "forescore\nand\nseven years\n";
 103 $foo = 'when in the course of human events it becomes necessary';
 104 write(OUT);
 105 close OUT or die "Could not close: $!";
 106
 107 my $right =
 108 "the quick brown fox
 109 jumped
 110 forescore
 111 and
 112 seven years
 113 when in
 114 the course
 115 of huma...
 116 now is the time for all good men to come to\n";
 117
 118 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 119
 120 $fox = 'wolfishness';
 121 my $fox = 'foxiness';           # Test a lexical variable.
 122
 123 format OUT2 =
 124 the quick brown @<<
 125 $fox
 126 jumped
 127 @*
 128 $multiline
 129 ^<<<<<<<<< ~~
 130 $foo
 131 now @<<the@>>>> for all@|||||men to come @<<<<
 132 'i' . 's', "time\n", $good, 'to'
 133 .
 134
 135 open OUT2, '>Op_write.tmp' or die "Can't create Op_write.tmp";
 136
 137 $good = 'good';
 138 $multiline = "forescore\nand\nseven years\n";
 139 $foo = 'when in the course of human events it becomes necessary';
 140 write(OUT2);
 141 close OUT2 or die "Could not close: $!";
 142
 143 $right =
 144 "the quick brown fox
 145 jumped
 146 forescore
 147 and
 148 seven years
 149 when in
 150 the course
 151 of human
 152 events it
 153 becomes
 154 necessary
 155 now is the time for all good men to come to\n";
 156
 157 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 158
 159 eval <<'EOFORMAT';
 160 format OUT2 =
 161 the brown quick @<<
 162 $fox
 163 jumped
 164 @*
 165 $multiline
 166 and
 167 ^<<<<<<<<< ~~
 168 $foo
 169 now @<<the@>>>> for all@|||||men to come @<<<<
 170 'i' . 's', "time\n", $good, 'to'
 171 .
 172 EOFORMAT
 173
 174 open(OUT2, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 175
 176 $fox = 'foxiness';
 177 $good = 'good';
 178 $multiline = "forescore\nand\nseven years\n";
 179 $foo = 'when in the course of human events it becomes necessary';
 180 write(OUT2);
 181 close OUT2 or die "Could not close: $!";
 182
 183 $right =
 184 "the brown quick fox
 185 jumped
 186 forescore
 187 and
 188 seven years
 189 and
 190 when in
 191 the course
 192 of human
 193 events it
 194 becomes
 195 necessary
 196 now is the time for all good men to come to\n";
 197
 198 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 199
 200 # formline tests
 201
 202 $right = <<EOT;
 203 @ a
 204 @> ab
 205 @>> abc
 206 @>>>  abc
 207 @>>>>   abc
 208 @>>>>>    abc
 209 @>>>>>>     abc
 210 @>>>>>>>      abc
 211 @>>>>>>>>       abc
 212 @>>>>>>>>>        abc
 213 @>>>>>>>>>>         abc
 214 EOT
 215
 216 my $was1 = my $was2 = '';
 217 use vars '$format2';
 218 for (0..10) {
 219   # lexical picture
 220   $^A = '';
 221   my $format1 = '@' . '>' x $_;
 222   formline $format1, 'abc';
 223   $was1 .= "$format1 $^A\n";
 224   # global
 225   $^A = '';
 226   local $format2 = '@' . '>' x $_;
 227   formline $format2, 'abc';
 228   $was2 .= "$format2 $^A\n";
 229 }
 230 is $was1, $right;
 231 is $was2, $right;
 232
 233 $^A = '';
 234
 235 # more test
 236
 237 format OUT3 =
 238 ^<<<<<<...
 239 $foo
 240 .
 241
 242 open(OUT3, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 243
 244 $foo = 'fit          ';
 245 write(OUT3);
 246 close OUT3 or die "Could not close: $!";
 247
 248 $right =
 249 "fit\n";
 250
 251 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 252
 253
 254 # test lexicals and globals
 255 {
 256     my $test = curr_test();
 257     my $this = "ok";
 258     our $that = $test;
 259     format LEX =
 260 @<<@|
 261 $this,$that
 262 .
 263     open(LEX, ">&STDOUT") or die;
 264     write LEX;
 265     $that = ++$test;
 266     write LEX;
 267     close LEX or die "Could not close: $!";
 268     curr_test($test + 1);
 269 }
 270 # LEX_INTERPNORMAL test
 271 my %e = ( a => 1 );
 272 format OUT4 =
 273 @<<<<<<
 274 "$e{a}"
 275 .
 276 open   OUT4, ">Op_write.tmp" or die "Can't create Op_write.tmp";
 277 write (OUT4);
 278 close  OUT4 or die "Could not close: $!";
 279 is cat('Op_write.tmp'), "1\n" and unlink_all "Op_write.tmp";
 280
 281 eval <<'EOFORMAT';
 282 format OUT10 =
 283 @####.## @0###.##
 284 $test1, $test1
 285 .
 286 EOFORMAT
 287
 288 open(OUT10, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 289
 290 use vars '$test1';
 291 $test1 = 12.95;
 292 write(OUT10);
 293 close OUT10 or die "Could not close: $!";
 294
 295 $right = "   12.95 00012.95\n";
 296 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 297
 298 eval <<'EOFORMAT';
 299 format OUT11 =
 300 @0###.##
 301 $test1
 302 @ 0#
 303 $test1
 304 @0 #
 305 $test1
 306 .
 307 EOFORMAT
 308
 309 open(OUT11, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 310
 311 $test1 = 12.95;
 312 write(OUT11);
 313 close OUT11 or die "Could not close: $!";
 314
 315 $right =
 316 "00012.95
 317 1 0#
 318 10 #\n";
 319 is cat('Op_write.tmp'), $right and unlink_all 'Op_write.tmp';
 320
 321 {
 322     my $test = curr_test();
 323     my $el;
 324     format OUT12 =
 325 ok ^<<<<<<<<<<<<<<~~ # sv_chop() naze
 326 $el
 327 .
 328     my %hash = ($test => 3);
 329     open(OUT12, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 330
 331     for $el (keys %hash) {
 332         write(OUT12);
 333     }
 334     close OUT12 or die "Could not close: $!";
 335     print cat('Op_write.tmp');
 336     curr_test($test + 1);
 337 }
 338
 339 {
 340     my $test = curr_test();
 341     # Bug report and testcase by Alexey Tourbin
 342     use Tie::Scalar;
 343     my $v;
 344     tie $v, 'Tie::StdScalar';
 345     $v = $test;
 346     format OUT13 =
 347 ok ^<<<<<<<<< ~~
 348 $v
 349 .
 350     open(OUT13, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 351     write(OUT13);
 352     close OUT13 or die "Could not close: $!";
 353     print cat('Op_write.tmp');
 354     curr_test($test + 1);
 355 }
 356
 357 {   # test 14
 358     # Bug #24774 format without trailing \n failed assertion, but this
 359     # must fail since we have a trailing ; in the eval'ed string (WL)
 360     my @v = ('k');
 361     eval "format OUT14 = \n@\n\@v";
 362     like $@, qr/Format not terminated/;
 363 }
 364
 365 {   # test 15
 366     # text lost in ^<<< field with \r in value (WL)
 367     my $txt = "line 1\rline 2";
 368     format OUT15 =
 369 ^<<<<<<<<<<<<<<<<<<
 370 $txt
 371 ^<<<<<<<<<<<<<<<<<<
 372 $txt
 373 .
 374     open(OUT15, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 375     write(OUT15);
 376     close OUT15 or die "Could not close: $!";
 377     my $res = cat('Op_write.tmp');
 378     is $res, "line 1\nline 2\n";
 379 }
 380
 381 {   # test 16: multiple use of a variable in same line with ^<
 382     my $txt = "this_is_block_1 this_is_block_2 this_is_block_3 this_is_block_4";
 383     format OUT16 =
 384 ^<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<
 385 $txt,             $txt
 386 ^<<<<<<<<<<<<<<<< ^<<<<<<<<<<<<<<<<
 387 $txt,             $txt
 388 .
 389     open(OUT16, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 390     write(OUT16);
 391     close OUT16 or die "Could not close: $!";
 392     my $res = cat('Op_write.tmp');
 393     is $res, <<EOD;
 394 this_is_block_1   this_is_block_2
 395 this_is_block_3   this_is_block_4
 396 EOD
 397 }
 398
 399 {   # test 17: @* "should be on a line of its own", but it should work
 400     # cleanly with literals before and after. (WL)
 401
 402     my $txt = "This is line 1.\nThis is the second line.\nThird and last.\n";
 403     format OUT17 =
 404 Here we go: @* That's all, folks!
 405             $txt
 406 .
 407     open(OUT17, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 408     write(OUT17);
 409     close OUT17 or die "Could not close: $!";
 410     my $res = cat('Op_write.tmp');
 411     chomp( $txt );
 412     my $exp = <<EOD;
 413 Here we go: $txt That's all, folks!
 414 EOD
 415     is $res, $exp;
 416 }
 417
 418 {   # test 18: @# and ~~ would cause runaway format, but we now
 419     # catch this while compiling (WL)
 420
 421     format OUT18 =
 422 @######## ~~
 423 10
 424 .
 425     open(OUT18, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 426     eval { write(OUT18); };
 427     like $@,  qr/Repeated format line will never terminate/;
 428     close OUT18 or die "Could not close: $!";
 429 }
 430
 431 {   # test 19: \0 in an evel'ed format, doesn't cause empty lines (WL)
 432     my $v = 'gaga';
 433     eval "format OUT19 = \n" .
 434          '@<<<' . "\0\n" .
 435          '$v' .   "\n" .
 436          '@<<<' . "\0\n" .
 437          '$v' . "\n.\n";
 438     open(OUT19, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 439     write(OUT19);
 440     close OUT19 or die "Could not close: $!";
 441     my $res = cat('Op_write.tmp');
 442     is $res, <<EOD;
 443 gaga\0
 444 gaga\0
 445 EOD
 446 }
 447
 448 {   # test 20: hash accesses; single '}' must not terminate format '}' (WL)
 449     my %h = ( xkey => 'xval', ykey => 'yval' );
 450     format OUT20 =
 451 @>>>> @<<<< ~~
 452 each %h
 453 @>>>> @<<<<
 454 $h{xkey}, $h{ykey}
 455 @>>>> @<<<<
 456 { $h{xkey}, $h{ykey}
 457 }
 458 }
 459 .
 460     my $exp = '';
 461     while( my( $k, $v ) = each( %h ) ){
 462         $exp .= sprintf( "%5s %s\n", $k, $v );
 463     }
 464     $exp .= sprintf( "%5s %s\n", $h{xkey}, $h{ykey} );
 465     $exp .= sprintf( "%5s %s\n", $h{xkey}, $h{ykey} );
 466     $exp .= "}\n";
 467     open(OUT20, '>Op_write.tmp') || die "Can't create Op_write.tmp";
 468     write(OUT20);
 469     close OUT20 or die "Could not close: $!";
 470     my $res = cat('Op_write.tmp');
 471     is $res, $exp;
 472 }
 473
 474
 475 #####################
 476 ## Section 2
 477 ## numeric formatting
 478 #####################
 479
 480 curr_test($bas_tests + 1);
 481
 482 for my $tref ( @NumTests ){
 483     my $writefmt = shift( @$tref );
 484     while (@$tref) {
 485         my $val      = shift @$tref;
 486         my $expected = shift @$tref;
 487         my $writeres = swrite( $writefmt, $val );
 488         if (ref $expected) {
 489             like $writeres, $expected, $writefmt;
 490         } else {
 491             is $writeres, $expected, $writefmt;
 492         }
 493     }
 494 }
 495
 496
 497 #####################################
 498 ## Section 3
 499 ## Easiest to add new tests just here
 500 #####################################
 501
 502 # DAPM. Exercise a couple of error codepaths
 503
 504 {
 505     local $~ = '';
 506     eval { write };
 507     like $@, qr/Not a format reference/, 'format reference';
 508
 509     $~ = "NOSUCHFORMAT";
 510     eval { write };
 511     like $@, qr/Undefined format/, 'no such format';
 512 }
 513
 514 {
 515   package Count;
 516
 517   sub TIESCALAR {
 518     my $class = shift;
 519     bless [shift, 0, 0], $class;
 520   }
 521
 522   sub FETCH {
 523     my $self = shift;
 524     ++$self->[1];
 525     $self->[0];
 526   }
 527
 528   sub STORE {
 529     my $self = shift;
 530     ++$self->[2];
 531     $self->[0] = shift;
 532   }
 533 }
 534
 535 {
 536   my ($pound_utf8, $pm_utf8) = map { my $a = "$_\x{100}"; chop $a; $a}
 537     my ($pound, $pm) = ("\xA3", "\xB1");
 538
 539   foreach my $first ('N', $pound, $pound_utf8) {
 540     foreach my $base ('N', $pm, $pm_utf8) {
 541       foreach my $second ($base, "$base\n", "$base\nMoo!", "$base\nMoo!\n",
 542                           "$base\nMoo!\n",) {
 543         foreach (['^*', qr/(.+)/], ['@*', qr/(.*?)$/s]) {
 544           my ($format, $re) = @$_;
 545           $format = "1^*2 3${format}4";
 546           foreach my $class ('', 'Count') {
 547             my $name = qq{swrite("$format", "$first", "$second") class="$class"};
 548             $name =~ s/\n/\\n/g;
 549             $name =~ s{(.)}{
 550                         ord($1) > 126 ? sprintf("\\x{%x}",ord($1)) : $1
 551                     }ge;
 552
 553             $first =~ /(.+)/ or die $first;
 554             my $expect = "1${1}2";
 555             $second =~ $re or die $second;
 556             $expect .= " 3${1}4";
 557
 558             if ($class) {
 559               my $copy1 = $first;
 560               my $copy2;
 561               tie $copy2, $class, $second;
 562               is swrite("$format", $copy1, $copy2), $expect, $name;
 563               my $obj = tied $copy2;
 564               is $obj->[1], 1, 'value read exactly once';
 565             } else {
 566               my ($copy1, $copy2) = ($first, $second);
 567               is swrite("$format", $copy1, $copy2), $expect, $name;
 568             }
 569           }
 570         }
 571       }
 572     }
 573   }
 574 }
 575
 576 {
 577   # This will fail an assertion in 5.10.0 built with -DDEBUGGING (because
 578   # pp_formline attempts to set SvCUR() on an SVt_RV). I suspect that it will
 579   # be doing something similarly out of bounds on everything from 5.000
 580   my $ref = [];
 581   is swrite('>^*<', $ref), ">$ref<";
 582   is swrite('>@*<', $ref), ">$ref<";
 583 }
 584
 585 format EMPTY =
 586 .
 587
 588 my $test = curr_test();
 589
 590 format Comment =
 591 ok @<<<<<
 592 $test
 593 .
 594
 595
 596 # [ID 20020227.005] format bug with undefined _TOP
 597
 598 open STDOUT_DUP, ">&STDOUT";
 599 my $oldfh = select STDOUT_DUP;
 600 $= = 10;
 601 {
 602   local $~ = "Comment";
 603   write;
 604   curr_test($test + 1);
 605   {
 606     local $::TODO = '[ID 20020227.005] format bug with undefined _TOP';
 607     is $-, 9;
 608   }
 609   is $^, "STDOUT_DUP_TOP";
 610 }
 611 select $oldfh;
 612 close STDOUT_DUP;
 613
 614 *CmT =  *{$::{Comment}}{FORMAT};
 615 ok  defined *{$::{CmT}}{FORMAT}, "glob assign";
 616
 617
 618 # RT #91032: Check that "non-real" strings like tie and overload work,
 619 # especially that they re-compile the pattern on each FETCH, and that
 620 # they don't overrun the buffer
 621
 622
 623 {
 624     package RT91032;
 625
 626     sub TIESCALAR { bless [] }
 627     my $i = 0;
 628     sub FETCH { $i++; "A$i @> Z\n" }
 629
 630     use overload '""' => \&FETCH;
 631
 632     tie my $f, 'RT91032';
 633
 634     formline $f, "a";
 635     formline $f, "bc";
 636     ::is $^A, "A1  a Z\nA2 bc Z\n", "RT 91032: tied";
 637     $^A = '';
 638
 639     my $g = bless []; # has overloaded stringify
 640     formline $g, "de";
 641     formline $g, "f";
 642     ::is $^A, "A3 de Z\nA4  f Z\n", "RT 91032: overloaded";
 643     $^A = '';
 644
 645     my $h = [];
 646     formline $h, "junk1";
 647     formline $h, "junk2";
 648     ::is ref($h), 'ARRAY', "RT 91032: array ref still a ref";
 649     ::like "$h", qr/^ARRAY\(0x[0-9a-f]+\)$/, "RT 91032: array stringifies ok";
 650     ::is $^A, "$h$h","RT 91032: stringified array";
 651     $^A = '';
 652
 653     # used to overwrite the ~~ in the *original SV with spaces. Naughty!
 654
 655     my $orig = my $format = "^<<<<< ~~\n";
 656     my $abc = "abc";
 657     formline $format, $abc;
 658     $^A ='';
 659     ::is $format, $orig, "RT91032: don't overwrite orig format string";
 660
 661     # check that ~ and ~~ are displayed correctly as whitespace,
 662     # under the influence of various different types of border
 663
 664     for my $n (1,2) {
 665         for my $lhs (' ', 'Y', '^<<<', '^|||', '^>>>') {
 666             for my $rhs ('', ' ', 'Z', '^<<<', '^|||', '^>>>') {
 667                 my $fmt = "^<B$lhs" . ('~' x $n) . "$rhs\n";
 668                 my $sfmt = ($fmt =~ s/~/ /gr);
 669                 my ($a, $bc, $stop);
 670                 ($a, $bc, $stop) = ('a', 'bc', 's');
 671                 # $stop is to stop '~~' deleting the whole line
 672                 formline $sfmt, $stop, $a, $bc;
 673                 my $exp = $^A;
 674                 $^A = '';
 675                 ($a, $bc, $stop) = ('a', 'bc', 's');
 676                 formline $fmt, $stop, $a, $bc;
 677                 my $got = $^A;
 678                 $^A = '';
 679                 $fmt =~ s/\n/\\n/;
 680                 ::is($got, $exp, "chop munging: [$fmt]");
 681             }
 682         }
 683     }
 684 }
 685
 686 # check that '~  (delete current line if empty) works when
 687 # the target gets upgraded to uft8 (and re-allocated) midstream.
 688
 689 {
 690     my $format = "\x{100}@~\n"; # format is utf8
 691     # this target is not utf8, but will expand (and get reallocated)
 692     # when upgraded to utf8.
 693     my $orig = "\x80\x81\x82";
 694     local $^A = $orig;
 695     my $empty = "";
 696     formline $format, $empty;
 697     is $^A , $orig, "~ and realloc";
 698
 699     # check similarly that trailing blank removal works ok
 700
 701     $format = "@<\n\x{100}"; # format is utf8
 702     chop $format;
 703     $orig = "   ";
 704     $^A = $orig;
 705     formline $format, "  ";
 706     is $^A, "$orig\n", "end-of-line blanks and realloc";
 707
 708     # and check this doesn't overflow the buffer
 709
 710     local $^A = '';
 711     $format = "@* @####\n";
 712     $orig = "x" x 100 . "\n";
 713     formline $format, $orig, 12345;
 714     is $^A, ("x" x 100) . " 12345\n", "\@* doesn't overflow";
 715
 716     # make sure it can cope with formats > 64k
 717
 718     $format = 'x' x 65537;
 719     $^A = '';
 720     formline $format;
 721     # don't use 'is' here, as the diag output will be too long!
 722     ok $^A eq $format, ">64K";
 723 }
 724
 725
 726 SKIP: {
 727     skip_if_miniperl('miniperl does not support scalario');
 728     my $buf = "";
 729     open my $fh, ">", \$buf;
 730     my $old_fh = select $fh;
 731     local $~ = "CmT";
 732     write;
 733     select $old_fh;
 734     close $fh;
 735     is $buf, "ok $test\n", "write to duplicated format";
 736 }
 737
 738 fresh_perl_like(<<'EOP', qr/^Format STDOUT redefined at/, {stderr => 1}, '#64562 - Segmentation fault with redefined formats and warnings');
 739 #!./perl
 740
 741 use strict;
 742 use warnings; # crashes!
 743
 744 format =
 745 .
 746
 747 write;
 748
 749 format =
 750 .
 751
 752 write;
 753 EOP
 754
 755 fresh_perl_is(<<'EOP', ">ARRAY<\ncrunch_eth\n", {stderr => 1}, '#79532 - formline coerces its arguments');
 756 use strict;
 757 use warnings;
 758 my $zamm = ['crunch_eth'];
 759 formline $zamm;
 760 printf ">%s<\n", ref $zamm;
 761 print "$zamm->[0]\n";
 762 EOP
 763
 764 #############################
 765 ## Section 4
 766 ## Add new tests *above* here
 767 #############################
 768
 769 # scary format testing from H.Merijn Brand
 770
 771 # Just a complete test for format, including top-, left- and bottom marging
 772 # and format detection through glob entries
 773
 774 if ($^O eq 'VMS' || $^O eq 'MSWin32' || $^O eq 'dos' ||
 775     ($^O eq 'os2' and not eval '$OS2::can_fork')) {
 776   $test = curr_test();
 777  SKIP: {
 778       skip "'|-' and '-|' not supported", $tests - $test + 1;
 779   }
 780   exit(0);
 781 }
 782
 783
 784 $^  = "STDOUT_TOP";
 785 $=  =  7;               # Page length
 786 $-  =  0;               # Lines left
 787 my $ps = $^L; $^L = ""; # Catch the page separator
 788 my $tm =  1;            # Top margin (empty lines before first output)
 789 my $bm =  2;            # Bottom marging (empty lines between last text and footer)
 790 my $lm =  4;            # Left margin (indent in spaces)
 791
 792 # -----------------------------------------------------------------------
 793 #
 794 # execute the rest of the script in a child process. The parent reads the
 795 # output from the child and compares it with <DATA>.
 796
 797 my @data = <DATA>;
 798
 799 select ((select (STDOUT), $| = 1)[0]); # flush STDOUT
 800
 801 my $opened = open FROM_CHILD, "-|";
 802 unless (defined $opened) {
 803     fail "open gave $!";
 804     exit 0;
 805 }
 806
 807 if ($opened) {
 808     # in parent here
 809
 810     pass 'open';
 811     my $s = " " x $lm;
 812     while (<FROM_CHILD>) {
 813         unless (@data) {
 814             fail 'too much output';
 815             exit;
 816         }
 817         s/^/$s/;
 818         my $exp = shift @data;
 819         is $_, $exp;
 820     }
 821     close FROM_CHILD;
 822     is "@data", "", "correct length of output";
 823     exit;
 824 }
 825
 826 # in child here
 827 $::NO_ENDING = 1;
 828
 829     select ((select (STDOUT), $| = 1)[0]);
 830 $tm = "\n" x $tm;
 831 $= -= $bm + 1; # count one for the trailing "----"
 832 my $lastmin = 0;
 833
 834 my @E;
 835
 836 sub wryte
 837 {
 838     $lastmin = $-;
 839     write;
 840     } # wryte;
 841
 842 sub footer
 843 {
 844     $% == 1 and return "";
 845
 846     $lastmin < $= and print "\n" x $lastmin;
 847     print "\n" x $bm, "----\n", $ps;
 848     $lastmin = $-;
 849     "";
 850     } # footer
 851
 852 # Yes, this is sick ;-)
 853 format TOP =
 854 @* ~
 855 @{[footer]}
 856 @* ~
 857 $tm
 858 .
 859
 860 format ENTRY =
 861 @ @<<<<~~
 862 @{(shift @E)||["",""]}
 863 .
 864
 865 format EOR =
 866 - -----
 867 .
 868
 869 sub has_format ($)
 870 {
 871     my $fmt = shift;
 872     exists $::{$fmt} or return 0;
 873     $^O eq "MSWin32" or return defined *{$::{$fmt}}{FORMAT};
 874     open my $null, "> /dev/null" or die;
 875     my $fh = select $null;
 876     local $~ = $fmt;
 877     eval "write";
 878     select $fh;
 879     $@?0:1;
 880     } # has_format
 881
 882 $^ = has_format ("TOP") ? "TOP" : "EMPTY";
 883 has_format ("ENTRY") or die "No format defined for ENTRY";
 884 foreach my $e ( [ map { [ $_, "Test$_"   ] } 1 .. 7 ],
 885                 [ map { [ $_, "${_}tseT" ] } 1 .. 5 ]) {
 886     @E = @$e;
 887     local $~ = "ENTRY";
 888     wryte;
 889     has_format ("EOR") or next;
 890     local $~ = "EOR";
 891     wryte;
 892     }
 893 if (has_format ("EOF")) {
 894     local $~ = "EOF";
 895     wryte;
 896     }
 897
 898 close STDOUT;
 899
 900 # That was test 48.
 901
 902 __END__
 903
 904     1 Test1
 905     2 Test2
 906     3 Test3
 907
 908
 909     ----
 910     \f
 911     4 Test4
 912     5 Test5
 913     6 Test6
 914
 915
 916     ----
 917     \f
 918     7 Test7
 919     - -----
 920
 921
 922
 923     ----
 924     \f
 925     1 1tseT
 926     2 2tseT
 927     3 3tseT
 928
 929
 930     ----
 931     \f
 932     4 4tseT
 933     5 5tseT
 934     - -----