This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
applied patch for perlfunc tweaks, removed reference to system qsort()
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar and list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one list argument.)  For instance, splice() has three scalar
19 arguments followed by a list.
20
21 In the syntax descriptions that follow, list operators that expect a
22 list (and provide list context for the elements of the list) are shown
23 with LIST as an argument.  Such a list may consist of any combination
24 of scalar arguments or list values; the list values will be included
25 in the list as if each individual element were interpolated at that
26 point in the list, forming a longer single-dimensional list value.
27 Elements of the LIST should be separated by commas.
28
29 Any function in the list below may be used either with or without
30 parentheses around its arguments.  (The syntax descriptions omit the
31 parentheses.)  If you use the parentheses, the simple (but occasionally
32 surprising) rule is this: It I<LOOKS> like a function, therefore it I<IS> a
33 function, and precedence doesn't matter.  Otherwise it's a list
34 operator or unary operator, and precedence does matter.  And whitespace
35 between the function and left parenthesis doesn't count--so you need to
36 be careful sometimes:
37
38     print 1+2+4;        # Prints 7.
39     print(1+2) + 4;     # Prints 3.
40     print (1+2)+4;      # Also prints 3!
41     print +(1+2)+4;     # Prints 7.
42     print ((1+2)+4);    # Prints 7.
43
44 If you run Perl with the B<-w> switch it can warn you about this.  For
45 example, the third line above produces:
46
47     print (...) interpreted as function at - line 1.
48     Useless use of integer addition in void context at - line 1.
49
50 For functions that can be used in either a scalar or list context,
51 nonabortive failure is generally indicated in a scalar context by
52 returning the undefined value, and in a list context by returning the
53 null list.
54
55 Remember the following important rule: There is B<no rule> that relates
56 the behavior of an expression in list context to its behavior in scalar
57 context, or vice versa.  It might do two totally different things.
58 Each operator and function decides which sort of value it would be most
59 appropriate to return in a scalar context.  Some operators return the
60 length of the list that would have been returned in list context.  Some
61 operators return the first value in the list.  Some operators return the
62 last value in the list.  Some operators return a count of successful
63 operations.  In general, they do what you want, unless you want
64 consistency.
65
66 An named array in scalar context is quite different from what would at
67 first glance appear to be a list in scalar context.  You can't get a list
68 like C<(1,2,3)> into being in scalar context, because the compiler knows
69 the context at compile time.  It would generate the scalar comma operator
70 there, not the list construction version of the comma.  That means it
71 was never a list to start with.
72
73 In general, functions in Perl that serve as wrappers for system calls
74 of the same name (like C<chown(2)>, C<fork(2)>, C<closedir(2)>, etc.) all return
75 true when they succeed and C<undef> otherwise, as is usually mentioned
76 in the descriptions below.  This is different from the C interfaces,
77 which return C<-1> on failure.  Exceptions to this rule are C<wait()>,
78 C<waitpid()>, and C<syscall()>.  System calls also set the special C<$!>
79 variable on failure.  Other functions do not, except accidentally.
80
81 =head2 Perl Functions by Category
82
83 Here are Perl's functions (including things that look like
84 functions, like some keywords and named operators)
85 arranged by category.  Some functions appear in more
86 than one place.
87
88 =over
89
90 =item Functions for SCALARs or strings
91
92 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
93 C<length>, C<oct>, C<ord>, C<pack>, C<q>/STRING/, C<qq>/STRING/, C<reverse>,
94 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y>///
95
96 =item Regular expressions and pattern matching
97
98 C<m>//, C<pos>, C<quotemeta>, C<s>///, C<split>, C<study>
99
100 =item Numeric functions
101
102 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
103 C<sin>, C<sqrt>, C<srand>
104
105 =item Functions for real @ARRAYs
106
107 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
108
109 =item Functions for list data
110
111 C<grep>, C<join>, C<map>, C<qw>/STRING/, C<reverse>, C<sort>, C<unpack>
112
113 =item Functions for real %HASHes
114
115 C<delete>, C<each>, C<exists>, C<keys>, C<values>
116
117 =item Input and output functions
118
119 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
120 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
121 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
122 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
123 C<warn>, C<write>
124
125 =item Functions for fixed length data or records
126
127 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
128
129 =item Functions for filehandles, files, or directories
130
131 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
132 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>, C<readlink>,
133 C<rename>, C<rmdir>, C<stat>, C<symlink>, C<umask>, C<unlink>, C<utime>
134
135 =item Keywords related to the control flow of your perl program
136
137 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
138 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
139
140 =item Keywords related to scoping
141
142 C<caller>, C<import>, C<local>, C<my>, C<package>, C<use>
143
144 =item Miscellaneous functions
145
146 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<reset>,
147 C<scalar>, C<undef>, C<wantarray>
148
149 =item Functions for processes and process groups
150
151 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
152 C<pipe>, C<qx>/STRING/, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
153 C<times>, C<wait>, C<waitpid>
154
155 =item Keywords related to perl modules
156
157 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
158
159 =item Keywords related to classes and object-orientedness
160
161 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
162 C<untie>, C<use>
163
164 =item Low-level socket functions
165
166 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
167 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
168 C<socket>, C<socketpair>
169
170 =item System V interprocess communication functions
171
172 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
173 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
174
175 =item Fetching user and group info
176
177 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
178 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
179 C<getpwuid>, C<setgrent>, C<setpwent>
180
181 =item Fetching network info
182
183 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
184 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
185 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
186 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
187 C<setnetent>, C<setprotoent>, C<setservent>
188
189 =item Time-related functions
190
191 C<gmtime>, C<localtime>, C<time>, C<times>
192
193 =item Functions new in perl5
194
195 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
196 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<prototype>, C<qx>,
197 C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
198 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
199
200 * - C<sub> was a keyword in perl4, but in perl5 it is an
201 operator, which can be used in expressions.
202
203 =item Functions obsoleted in perl5
204
205 C<dbmclose>, C<dbmopen>
206
207 =back
208
209 =head2 Alphabetical Listing of Perl Functions
210
211 =over 8
212
213 =item I<-X> FILEHANDLE
214
215 =item I<-X> EXPR
216
217 =item I<-X>
218
219 A file test, where X is one of the letters listed below.  This unary
220 operator takes one argument, either a filename or a filehandle, and
221 tests the associated file to see if something is true about it.  If the
222 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
223 Unless otherwise documented, it returns C<1> for TRUE and C<''> for FALSE, or
224 the undefined value if the file doesn't exist.  Despite the funny
225 names, precedence is the same as any other named unary operator, and
226 the argument may be parenthesized like any other unary operator.  The
227 operator may be any of:
228
229     -r  File is readable by effective uid/gid.
230     -w  File is writable by effective uid/gid.
231     -x  File is executable by effective uid/gid.
232     -o  File is owned by effective uid.
233
234     -R  File is readable by real uid/gid.
235     -W  File is writable by real uid/gid.
236     -X  File is executable by real uid/gid.
237     -O  File is owned by real uid.
238
239     -e  File exists.
240     -z  File has zero size.
241     -s  File has nonzero size (returns size).
242
243     -f  File is a plain file.
244     -d  File is a directory.
245     -l  File is a symbolic link.
246     -p  File is a named pipe (FIFO).
247     -S  File is a socket.
248     -b  File is a block special file.
249     -c  File is a character special file.
250     -t  Filehandle is opened to a tty.
251
252     -u  File has setuid bit set.
253     -g  File has setgid bit set.
254     -k  File has sticky bit set.
255
256     -T  File is a text file.
257     -B  File is a binary file (opposite of -T).
258
259     -M  Age of file in days when script started.
260     -A  Same for access time.
261     -C  Same for inode change time.
262
263 The interpretation of the file permission operators C<-r>, C<-R>, C<-w>,
264 C<-W>, C<-x>, and C<-X> is based solely on the mode of the file and the
265 uids and gids of the user.  There may be other reasons you can't actually
266 read, write, or execute the file, such as AFS access control lists.  Also note that, for the superuser,
267 C<-r>, C<-R>, C<-w>, and C<-W> always return C<1>, and C<-x> and C<-X> return
268 C<1> if any execute bit is set in the mode.  Scripts run by the superuser may
269 thus need to do a C<stat()> to determine the actual mode of the
270 file, or temporarily set the uid to something else.
271
272 Example:
273
274     while (<>) {
275         chop;
276         next unless -f $_;      # ignore specials
277         #...
278     }
279
280 Note that C<-s/a/b/> does not do a negated substitution.  Saying
281 C<-exp($foo)> still works as expected, however--only single letters
282 following a minus are interpreted as file tests.
283
284 The C<-T> and C<-B> switches work as follows.  The first block or so of the
285 file is examined for odd characters such as strange control codes or
286 characters with the high bit set.  If too many strange characters (E<gt>30%)
287 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
288 containing null in the first block is considered a binary file.  If C<-T>
289 or C<-B> is used on a filehandle, the current stdio buffer is examined
290 rather than the first block.  Both C<-T> and C<-B> return TRUE on a null
291 file, or a file at EOF when testing a filehandle.  Because you have to
292 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
293 against the file first, as in C<next unless -f $file && -T $file>.
294
295 If any of the file tests (or either the C<stat()> or C<lstat()> operators) are given
296 the special filehandle consisting of a solitary underline, then the stat
297 structure of the previous file test (or stat operator) is used, saving
298 a system call.  (This doesn't work with C<-t>, and you need to remember
299 that lstat() and C<-l> will leave values in the stat structure for the
300 symbolic link, not the real file.)  Example:
301
302     print "Can do.\n" if -r $a || -w _ || -x _;
303
304     stat($filename);
305     print "Readable\n" if -r _;
306     print "Writable\n" if -w _;
307     print "Executable\n" if -x _;
308     print "Setuid\n" if -u _;
309     print "Setgid\n" if -g _;
310     print "Sticky\n" if -k _;
311     print "Text\n" if -T _;
312     print "Binary\n" if -B _;
313
314 =item abs VALUE
315
316 =item abs
317
318 Returns the absolute value of its argument.
319 If VALUE is omitted, uses C<$_>.
320
321 =item accept NEWSOCKET,GENERICSOCKET
322
323 Accepts an incoming socket connect, just as the C<accept(2)> system call
324 does.  Returns the packed address if it succeeded, FALSE otherwise.
325 See example in L<perlipc/"Sockets: Client/Server Communication">.
326
327 =item alarm SECONDS
328
329 =item alarm
330
331 Arranges to have a SIGALRM delivered to this process after the
332 specified number of seconds have elapsed.  If SECONDS is not specified,
333 the value stored in C<$_> is used. (On some machines,
334 unfortunately, the elapsed time may be up to one second less than you
335 specified because of how seconds are counted.)  Only one timer may be
336 counting at once.  Each call disables the previous timer, and an
337 argument of C<0> may be supplied to cancel the previous timer without
338 starting a new one.  The returned value is the amount of time remaining
339 on the previous timer.
340
341 For delays of finer granularity than one second, you may use Perl's
342 C<syscall()> interface to access C<setitimer(2)> if your system supports it,
343 or else see L</select()>.  It is usually a mistake to intermix C<alarm()>
344 and C<sleep()> calls.
345
346 If you want to use C<alarm()> to time out a system call you need to use an
347 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
348 fail with C<$!> set to EINTR because Perl sets up signal handlers to
349 restart system calls on some systems.  Using C<eval>/C<die> always works,
350 modulo the caveats given in L<perlipc/"Signals">.
351
352     eval {
353         local $SIG{ALRM} = sub { die "alarm\n" };       # NB: \n required
354         alarm $timeout;
355         $nread = sysread SOCKET, $buffer, $size;
356         alarm 0;
357     };
358     if ($@) {
359         die unless $@ eq "alarm\n";     # propagate unexpected errors
360         # timed out
361     }
362     else {
363         # didn't
364     }
365
366 =item atan2 Y,X
367
368 Returns the arctangent of Y/X in the range -PI to PI.
369
370 For the tangent operation, you may use the C<POSIX::tan()>
371 function, or use the familiar relation:
372
373     sub tan { sin($_[0]) / cos($_[0])  }
374
375 =item bind SOCKET,NAME
376
377 Binds a network address to a socket, just as the bind system call
378 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
379 packed address of the appropriate type for the socket.  See the examples in
380 L<perlipc/"Sockets: Client/Server Communication">.
381
382 =item binmode FILEHANDLE
383
384 Arranges for the file to be read or written in "binary" mode in operating
385 systems that distinguish between binary and text files.  Files that are
386 not in binary mode have CR LF sequences translated to LF on input and LF
387 translated to CR LF on output.  Binmode has no effect under Unix; in MS-DOS
388 and similarly archaic systems, it may be imperative--otherwise your
389 MS-DOS-damaged C library may mangle your file.  The key distinction between
390 systems that need C<binmode> and those that don't is their text file
391 formats.  Systems like Unix, MacOS, and Plan9 that delimit lines with a single
392 character, and that encode that character in C as C<"\n">, do not need
393 C<binmode>.  The rest need it.  If FILEHANDLE is an expression, the value
394 is taken as the name of the filehandle.
395
396 =item bless REF,CLASSNAME
397
398 =item bless REF
399
400 This function tells the thingy referenced by REF that it is now
401 an object in the CLASSNAME package--or the current package if no CLASSNAME
402 is specified, which is often the case.  It returns the reference for
403 convenience, because a C<bless()> is often the last thing in a constructor.
404 Always use the two-argument version if the function doing the blessing
405 might be inherited by a derived class.  See L<perltoot> and L<perlobj>
406 for more about the blessing (and blessings) of objects.
407
408 =item caller EXPR
409
410 =item caller
411
412 Returns the context of the current subroutine call.  In scalar context,
413 returns the caller's package name if there is a caller, that is, if
414 we're in a subroutine or C<eval()> or C<require()>, and the undefined value
415 otherwise.  In list context, returns
416
417     ($package, $filename, $line) = caller;
418
419 With EXPR, it returns some extra information that the debugger uses to
420 print a stack trace.  The value of EXPR indicates how many call frames
421 to go back before the current one.
422
423     ($package, $filename, $line, $subroutine,
424      $hasargs, $wantarray, $evaltext, $is_require) = caller($i);
425
426 Here C<$subroutine> may be C<"(eval)"> if the frame is not a subroutine
427 call, but an C<eval>.  In such a case additional elements C<$evaltext> and
428 C<$is_require> are set: C<$is_require> is true if the frame is created by a
429 C<require> or C<use> statement, C<$evaltext> contains the text of the
430 C<eval EXPR> statement.  In particular, for a C<eval BLOCK> statement,
431 C<$filename> is C<"(eval)">, but C<$evaltext> is undefined.  (Note also that
432 each C<use> statement creates a C<require> frame inside an C<eval EXPR>)
433 frame.
434
435 Furthermore, when called from within the DB package, caller returns more
436 detailed information: it sets the list variable C<@DB::args> to be the
437 arguments with which the subroutine was invoked.
438
439 Be aware that the optimizer might have optimized call frames away before
440 C<caller> had a chance to get the information. That means that C<caller(N)>
441 might not return information about the call frame you expect it do, for
442 C<N E<gt> 1>. In particular, C<@DB::args> might have information from the 
443 previous time C<caller()> was called.
444
445 =item chdir EXPR
446
447 Changes the working directory to EXPR, if possible.  If EXPR is
448 omitted, changes to home directory.  Returns TRUE upon success, FALSE
449 otherwise.  See example under C<die()>.
450
451 =item chmod LIST
452
453 Changes the permissions of a list of files.  The first element of the
454 list must be the numerical mode, which should probably be an octal
455 number, and which definitely should I<not> a string of octal digits:
456 C<0644> is okay, C<'0644'> is not.  Returns the number of files
457 successfully changed.  See also L</oct>, if all you have is a string.
458
459     $cnt = chmod 0755, 'foo', 'bar';
460     chmod 0755, @executables;
461     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to --w----r-T
462     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
463     $mode = 0644;   chmod $mode, 'foo';      # this is best
464
465 =item chomp VARIABLE
466
467 =item chomp LIST
468
469 =item chomp
470
471 This is a slightly safer version of L</chop>.  It removes any
472 line ending that corresponds to the current value of C<$/> (also known as
473 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
474 number of characters removed from all its arguments.  It's often used to
475 remove the newline from the end of an input record when you're worried
476 that the final record may be missing its newline.  When in paragraph mode
477 (C<$/ = "">), it removes all trailing newlines from the string.  If
478 VARIABLE is omitted, it chomps C<$_>.  Example:
479
480     while (<>) {
481         chomp;  # avoid \n on last field
482         @array = split(/:/);
483         # ...
484     }
485
486 You can actually chomp anything that's an lvalue, including an assignment:
487
488     chomp($cwd = `pwd`);
489     chomp($answer = <STDIN>);
490
491 If you chomp a list, each element is chomped, and the total number of
492 characters removed is returned.
493
494 =item chop VARIABLE
495
496 =item chop LIST
497
498 =item chop
499
500 Chops off the last character of a string and returns the character
501 chopped.  It's used primarily to remove the newline from the end of an
502 input record, but is much more efficient than C<s/\n//> because it neither
503 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
504 Example:
505
506     while (<>) {
507         chop;   # avoid \n on last field
508         @array = split(/:/);
509         #...
510     }
511
512 You can actually chop anything that's an lvalue, including an assignment:
513
514     chop($cwd = `pwd`);
515     chop($answer = <STDIN>);
516
517 If you chop a list, each element is chopped.  Only the value of the
518 last C<chop> is returned.
519
520 Note that C<chop> returns the last character.  To return all but the last
521 character, use C<substr($string, 0, -1)>.
522
523 =item chown LIST
524
525 Changes the owner (and group) of a list of files.  The first two
526 elements of the list must be the I<NUMERICAL> uid and gid, in that order.
527 Returns the number of files successfully changed.
528
529     $cnt = chown $uid, $gid, 'foo', 'bar';
530     chown $uid, $gid, @filenames;
531
532 Here's an example that looks up nonnumeric uids in the passwd file:
533
534     print "User: ";
535     chop($user = <STDIN>);
536     print "Files: ";
537     chop($pattern = <STDIN>);
538
539     ($login,$pass,$uid,$gid) = getpwnam($user)
540         or die "$user not in passwd file";
541
542     @ary = glob($pattern);      # expand filenames
543     chown $uid, $gid, @ary;
544
545 On most systems, you are not allowed to change the ownership of the
546 file unless you're the superuser, although you should be able to change
547 the group to any of your secondary groups.  On insecure systems, these
548 restrictions may be relaxed, but this is not a portable assumption.
549
550 =item chr NUMBER
551
552 =item chr
553
554 Returns the character represented by that NUMBER in the character set.
555 For example, C<chr(65)> is C<"A"> in ASCII.  For the reverse, use L</ord>.
556
557 If NUMBER is omitted, uses C<$_>.
558
559 =item chroot FILENAME
560
561 =item chroot
562
563 This function works like the system call by the same name: it makes the
564 named directory the new root directory for all further pathnames that
565 begin with a C<"/"> by your process and all its children.  (It doesn't
566 change your current working directory, which is unaffected.)  For security
567 reasons, this call is restricted to the superuser.  If FILENAME is
568 omitted, does a C<chroot> to C<$_>.
569
570 =item close FILEHANDLE
571
572 =item close
573
574 Closes the file or pipe associated with the file handle, returning TRUE
575 only if stdio successfully flushes buffers and closes the system file
576 descriptor. Closes the currently selected filehandle if the argument
577 is omitted.
578
579 You don't have to close FILEHANDLE if you are immediately going to do
580 another C<open()> on it, because C<open()> will close it for you.  (See
581 C<open()>.)  However, an explicit C<close> on an input file resets the line
582 counter (C<$.>), while the implicit close done by C<open()> does not.
583
584 If the file handle came from a piped open C<close> will additionally
585 return FALSE if one of the other system calls involved fails or if the
586 program exits with non-zero status.  (If the only problem was that the
587 program exited non-zero C<$!> will be set to C<0>.)  Also, closing a pipe 
588 waits for the process executing on the pipe to complete, in case you
589 want to look at the output of the pipe afterwards.  Closing a pipe
590 explicitly also puts the exit status value of the command into C<$?>.
591
592 Example:
593
594     open(OUTPUT, '|sort >foo')  # pipe to sort
595         or die "Can't start sort: $!";
596     #...                        # print stuff to output
597     close OUTPUT                # wait for sort to finish
598         or warn $! ? "Error closing sort pipe: $!"
599                    : "Exit status $? from sort";
600     open(INPUT, 'foo')          # get sort's results
601         or die "Can't open 'foo' for input: $!";
602
603 FILEHANDLE may be an expression whose value can be used as an indirect
604 filehandle, usually the real filehandle name.
605
606 =item closedir DIRHANDLE
607
608 Closes a directory opened by C<opendir()> and returns the success of that
609 system call.
610
611 DIRHANDLE may be an expression whose value can be used as an indirect
612 dirhandle, usually the real dirhandle name.
613
614 =item connect SOCKET,NAME
615
616 Attempts to connect to a remote socket, just as the connect system call
617 does.  Returns TRUE if it succeeded, FALSE otherwise.  NAME should be a
618 packed address of the appropriate type for the socket.  See the examples in
619 L<perlipc/"Sockets: Client/Server Communication">.
620
621 =item continue BLOCK
622
623 Actually a flow control statement rather than a function.  If there is a
624 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
625 C<foreach>), it is always executed just before the conditional is about to
626 be evaluated again, just like the third part of a C<for> loop in C.  Thus
627 it can be used to increment a loop variable, even when the loop has been
628 continued via the C<next> statement (which is similar to the C C<continue>
629 statement).
630
631 C<last>, C<next>, or C<redo> may appear within a C<continue>
632 block. C<last> and C<redo> will behave as if they had been executed within
633 the main block. So will C<next>, but since it will execute a C<continue>
634 block, it may be more entertaining.
635
636     while (EXPR) {
637         ### redo always comes here
638         do_something;
639     } continue {
640         ### next always comes here
641         do_something_else;
642         # then back the top to re-check EXPR
643     }
644     ### last always comes here
645
646 Omitting the C<continue> section is semantically equivalent to using an
647 empty one, logically enough. In that case, C<next> goes directly back
648 to check the condition at the top of the loop.
649
650 =item cos EXPR
651
652 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
653 takes cosine of C<$_>.
654
655 For the inverse cosine operation, you may use the C<POSIX::acos()>
656 function, or use this relation:
657
658     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
659
660 =item crypt PLAINTEXT,SALT
661
662 Encrypts a string exactly like the C<crypt(3)> function in the C library
663 (assuming that you actually have a version there that has not been
664 extirpated as a potential munition).  This can prove useful for checking
665 the password file for lousy passwords, amongst other things.  Only the
666 guys wearing white hats should do this.
667
668 Note that C<crypt()> is intended to be a one-way function, much like breaking
669 eggs to make an omelette.  There is no (known) corresponding decrypt
670 function.  As a result, this function isn't all that useful for
671 cryptography.  (For that, see your nearby CPAN mirror.)
672
673 Here's an example that makes sure that whoever runs this program knows
674 their own password:
675
676     $pwd = (getpwuid($<))[1];
677     $salt = substr($pwd, 0, 2);
678
679     system "stty -echo";
680     print "Password: ";
681     chop($word = <STDIN>);
682     print "\n";
683     system "stty echo";
684
685     if (crypt($word, $salt) ne $pwd) {
686         die "Sorry...\n";
687     } else {
688         print "ok\n";
689     }
690
691 Of course, typing in your own password to whoever asks you
692 for it is unwise.
693
694 =item dbmclose HASH
695
696 [This function has been superseded by the C<untie()> function.]
697
698 Breaks the binding between a DBM file and a hash.
699
700 =item dbmopen HASH,DBNAME,MODE
701
702 [This function has been superseded by the C<tie()> function.]
703
704 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
705 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
706 argument is I<NOT> a filehandle, even though it looks like one).  DBNAME
707 is the name of the database (without the F<.dir> or F<.pag> extension if
708 any).  If the database does not exist, it is created with protection
709 specified by MODE (as modified by the C<umask()>).  If your system supports
710 only the older DBM functions, you may perform only one C<dbmopen()> in your
711 program.  In older versions of Perl, if your system had neither DBM nor
712 ndbm, calling C<dbmopen()> produced a fatal error; it now falls back to
713 sdbm(3).
714
715 If you don't have write access to the DBM file, you can only read hash
716 variables, not set them.  If you want to test whether you can write,
717 either use file tests or try setting a dummy hash entry inside an C<eval()>,
718 which will trap the error.
719
720 Note that functions such as C<keys()> and C<values()> may return huge lists
721 when used on large DBM files.  You may prefer to use the C<each()>
722 function to iterate over large DBM files.  Example:
723
724     # print out history file offsets
725     dbmopen(%HIST,'/usr/lib/news/history',0666);
726     while (($key,$val) = each %HIST) {
727         print $key, ' = ', unpack('L',$val), "\n";
728     }
729     dbmclose(%HIST);
730
731 See also L<AnyDBM_File> for a more general description of the pros and
732 cons of the various dbm approaches, as well as L<DB_File> for a particularly
733 rich implementation.
734
735 =item defined EXPR
736
737 =item defined
738
739 Returns a Boolean value telling whether EXPR has a value other than
740 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
741 checked.
742
743 Many operations return C<undef> to indicate failure, end of file,
744 system error, uninitialized variable, and other exceptional
745 conditions.  This function allows you to distinguish C<undef> from
746 other values.  (A simple Boolean test will not distinguish among
747 C<undef>, zero, the empty string, and C<"0">, which are all equally
748 false.)  Note that since C<undef> is a valid scalar, its presence
749 doesn't I<necessarily> indicate an exceptional condition: C<pop()>
750 returns C<undef> when its argument is an empty array, I<or> when the
751 element to return happens to be C<undef>.
752
753 You may also use C<defined()> to check whether a subroutine exists, by
754 saying C<defined &func> without parentheses.  On the other hand, use
755 of C<defined()> upon aggregates (hashes and arrays) is not guaranteed to
756 produce intuitive results, and should probably be avoided.
757
758 When used on a hash element, it tells you whether the value is defined,
759 not whether the key exists in the hash.  Use L</exists> for the latter
760 purpose.
761
762 Examples:
763
764     print if defined $switch{'D'};
765     print "$val\n" while defined($val = pop(@ary));
766     die "Can't readlink $sym: $!"
767         unless defined($value = readlink $sym);
768     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
769     $debugging = 0 unless defined $debugging;
770
771 Note:  Many folks tend to overuse C<defined()>, and then are surprised to
772 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
773 defined values.  For example, if you say
774
775     "ab" =~ /a(.*)b/;
776
777 The pattern match succeeds, and C<$1> is defined, despite the fact that it
778 matched "nothing".  But it didn't really match nothing--rather, it
779 matched something that happened to be C<0> characters long.  This is all
780 very above-board and honest.  When a function returns an undefined value,
781 it's an admission that it couldn't give you an honest answer.  So you
782 should use C<defined()> only when you're questioning the integrity of what
783 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
784 what you want.
785
786 Currently, using C<defined()> on an entire array or hash reports whether
787 memory for that aggregate has ever been allocated.  So an array you set
788 to the empty list appears undefined initially, and one that once was full
789 and that you then set to the empty list still appears defined.  You
790 should instead use a simple test for size:
791
792     if (@an_array) { print "has array elements\n" }
793     if (%a_hash)   { print "has hash members\n"   }
794
795 Using C<undef()> on these, however, does clear their memory and then report
796 them as not defined anymore, but you shouldn't do that unless you don't
797 plan to use them again, because it saves time when you load them up
798 again to have memory already ready to be filled.  The normal way to 
799 free up space used by an aggregate is to assign the empty list.
800
801 This counterintuitive behavior of C<defined()> on aggregates may be
802 changed, fixed, or broken in a future release of Perl.
803
804 See also L</undef>, L</exists>, L</ref>.
805
806 =item delete EXPR
807
808 Deletes the specified key(s) and their associated values from a hash.
809 For each key, returns the deleted value associated with that key, or
810 the undefined value if there was no such key.  Deleting from C<$ENV{}>
811 modifies the environment.  Deleting from a hash tied to a DBM file
812 deletes the entry from the DBM file.  (But deleting from a C<tie()>d hash
813 doesn't necessarily return anything.)
814
815 The following deletes all the values of a hash:
816
817     foreach $key (keys %HASH) {
818         delete $HASH{$key};
819     }
820
821 And so does this:
822
823     delete @HASH{keys %HASH}
824
825 (But both of these are slower than just assigning the empty list, or
826 using C<undef()>.)  Note that the EXPR can be arbitrarily complicated as
827 long as the final operation is a hash element lookup or hash slice:
828
829     delete $ref->[$x][$y]{$key};
830     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
831
832 =item die LIST
833
834 Outside an C<eval()>, prints the value of LIST to C<STDERR> and exits with
835 the current value of C<$!> (errno).  If C<$!> is C<0>, exits with the value of
836 C<($? E<gt>E<gt> 8)> (backtick `command` status).  If C<($? E<gt>E<gt> 8)>
837 is C<0>, exits with C<255>.  Inside an C<eval(),> the error message is stuffed into
838 C<$@> and the C<eval()> is terminated with the undefined value.  This makes
839 C<die()> the way to raise an exception.
840
841 Equivalent examples:
842
843     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
844     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
845
846 If the value of EXPR does not end in a newline, the current script line
847 number and input line number (if any) are also printed, and a newline
848 is supplied.  Hint: sometimes appending C<", stopped"> to your message
849 will cause it to make better sense when the string C<"at foo line 123"> is
850 appended.  Suppose you are running script "canasta".
851
852     die "/etc/games is no good";
853     die "/etc/games is no good, stopped";
854
855 produce, respectively
856
857     /etc/games is no good at canasta line 123.
858     /etc/games is no good, stopped at canasta line 123.
859
860 See also C<exit()> and C<warn()>.
861
862 If LIST is empty and C<$@> already contains a value (typically from a
863 previous eval) that value is reused after appending C<"\t...propagated">.
864 This is useful for propagating exceptions:
865
866     eval { ... };
867     die unless $@ =~ /Expected exception/;
868
869 If C<$@> is empty then the string C<"Died"> is used.
870
871 You can arrange for a callback to be run just before the C<die()> does
872 its deed, by setting the C<$SIG{__DIE__}> hook.  The associated handler
873 will be called with the error text and can change the error message, if
874 it sees fit, by calling C<die()> again.  See L<perlvar/$SIG{expr}> for details on
875 setting C<%SIG> entries, and L<"eval BLOCK"> for some examples.
876
877 Note that the C<$SIG{__DIE__}> hook is called even inside eval()ed
878 blocks/strings.  If one wants the hook to do nothing in such
879 situations, put
880
881         die @_ if $^S;
882
883 as the first line of the handler (see L<perlvar/$^S>).
884
885 =item do BLOCK
886
887 Not really a function.  Returns the value of the last command in the
888 sequence of commands indicated by BLOCK.  When modified by a loop
889 modifier, executes the BLOCK once before testing the loop condition.
890 (On other statements the loop modifiers test the conditional first.)
891
892 =item do SUBROUTINE(LIST)
893
894 A deprecated form of subroutine call.  See L<perlsub>.
895
896 =item do EXPR
897
898 Uses the value of EXPR as a filename and executes the contents of the
899 file as a Perl script.  Its primary use is to include subroutines
900 from a Perl subroutine library.
901
902     do 'stat.pl';
903
904 is just like
905
906     scalar eval `cat stat.pl`;
907
908 except that it's more efficient and concise, keeps track of the
909 current filename for error messages, and searches all the B<-I>
910 libraries if the file isn't in the current directory (see also the @INC
911 array in L<perlvar/Predefined Names>).  It is also different in how
912 code evaluated with C<do FILENAME> doesn't see lexicals in the enclosing
913 scope like C<eval STRING> does.  It's the same, however, in that it does
914 reparse the file every time you call it, so you probably don't want to
915 do this inside a loop.
916
917 Note that inclusion of library modules is better done with the
918 C<use()> and C<require()> operators, which also do automatic error checking
919 and raise an exception if there's a problem.
920
921 You might like to use C<do> to read in a program configuration
922 file.  Manual error checking can be done this way:
923
924     # read in config files: system first, then user 
925     for $file ('/share/prog/defaults.rc", "$ENV{HOME}/.someprogrc") {
926         unless ($return = do $file) {
927             warn "couldn't parse $file: $@"         if $@;
928             warn "couldn't do $file: $!"            unless defined $return;
929             warn "couldn't run $file"               unless $return;
930         }
931     }
932
933 =item dump LABEL
934
935 This causes an immediate core dump.  Primarily this is so that you can
936 use the B<undump> program to turn your core dump into an executable binary
937 after having initialized all your variables at the beginning of the
938 program.  When the new binary is executed it will begin by executing a
939 C<goto LABEL> (with all the restrictions that C<goto> suffers).  Think of
940 it as a goto with an intervening core dump and reincarnation.  If LABEL
941 is omitted, restarts the program from the top.  WARNING: Any files
942 opened at the time of the dump will NOT be open any more when the
943 program is reincarnated, with possible resulting confusion on the part
944 of Perl.  See also B<-u> option in L<perlrun>.
945
946 Example:
947
948     #!/usr/bin/perl
949     require 'getopt.pl';
950     require 'stat.pl';
951     %days = (
952         'Sun' => 1,
953         'Mon' => 2,
954         'Tue' => 3,
955         'Wed' => 4,
956         'Thu' => 5,
957         'Fri' => 6,
958         'Sat' => 7,
959     );
960
961     dump QUICKSTART if $ARGV[0] eq '-d';
962
963     QUICKSTART:
964     Getopt('f');
965
966 This operator is largely obsolete, partly because it's very hard to 
967 convert a core file into an executable, and because the real perl-to-C
968 compiler has superseded it.
969
970 =item each HASH
971
972 When called in list context, returns a 2-element list consisting of the
973 key and value for the next element of a hash, so that you can iterate over
974 it.  When called in scalar context, returns the key for only the "next"
975 element in the hash.  (Note: Keys may be C<"0"> or C<"">, which are logically
976 false; you may wish to avoid constructs like C<while ($k = each %foo) {}>
977 for this reason.)
978
979 Entries are returned in an apparently random order.  When the hash is
980 entirely read, a null array is returned in list context (which when
981 assigned produces a FALSE (C<0>) value), and C<undef> in
982 scalar context.  The next call to C<each()> after that will start iterating
983 again.  There is a single iterator for each hash, shared by all C<each()>,
984 C<keys()>, and C<values()> function calls in the program; it can be reset by
985 reading all the elements from the hash, or by evaluating C<keys HASH> or
986 C<values HASH>.  If you add or delete elements of a hash while you're
987 iterating over it, you may get entries skipped or duplicated, so don't.
988
989 The following prints out your environment like the C<printenv(1)> program,
990 only in a different order:
991
992     while (($key,$value) = each %ENV) {
993         print "$key=$value\n";
994     }
995
996 See also C<keys()> and C<values()>.
997
998 =item eof FILEHANDLE
999
1000 =item eof ()
1001
1002 =item eof
1003
1004 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1005 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1006 gives the real filehandle.  (Note that this function actually
1007 reads a character and then C<ungetc()>s it, so isn't very useful in an
1008 interactive context.)  Do not read from a terminal file (or call
1009 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  Filetypes such
1010 as terminals may lose the end-of-file condition if you do.
1011
1012 An C<eof> without an argument uses the last file read as argument.
1013 Using C<eof()> with empty parentheses is very different.  It indicates the pseudo file formed of
1014 the files listed on the command line, i.e., C<eof()> is reasonable to
1015 use inside a C<while (E<lt>E<gt>)> loop to detect the end of only the
1016 last file.  Use C<eof(ARGV)> or eof without the parentheses to test
1017 I<EACH> file in a while (E<lt>E<gt>) loop.  Examples:
1018
1019     # reset line numbering on each input file
1020     while (<>) {
1021         next if /^\s*#/;        # skip comments 
1022         print "$.\t$_";
1023     } continue {
1024         close ARGV  if eof;     # Not eof()!
1025     }
1026
1027     # insert dashes just before last line of last file
1028     while (<>) {
1029         if (eof()) {            # check for end of current file
1030             print "--------------\n";
1031             close(ARGV);        # close or break; is needed if we
1032                                 # are reading from the terminal
1033         }
1034         print;
1035     }
1036
1037 Practical hint: you almost never need to use C<eof> in Perl, because the
1038 input operators return false values when they run out of data, or if there
1039 was an error.
1040
1041 =item eval EXPR
1042
1043 =item eval BLOCK
1044
1045 In the first form, the return value of EXPR is parsed and executed as if it
1046 were a little Perl program.  The value of the expression (which is itself
1047 determined within scalar context) is first parsed, and if there weren't any
1048 errors, executed in the context of the current Perl program, so that any
1049 variable settings or subroutine and format definitions remain afterwards.
1050 Note that the value is parsed every time the eval executes.  If EXPR is
1051 omitted, evaluates C<$_>.  This form is typically used to delay parsing
1052 and subsequent execution of the text of EXPR until run time.
1053
1054 In the second form, the code within the BLOCK is parsed only once--at the
1055 same time the code surrounding the eval itself was parsed--and executed
1056 within the context of the current Perl program.  This form is typically
1057 used to trap exceptions more efficiently than the first (see below), while
1058 also providing the benefit of checking the code within BLOCK at compile
1059 time.
1060
1061 The final semicolon, if any, may be omitted from the value of EXPR or within
1062 the BLOCK.
1063
1064 In both forms, the value returned is the value of the last expression
1065 evaluated inside the mini-program; a return statement may be also used, just
1066 as with subroutines.  The expression providing the return value is evaluated
1067 in void, scalar, or list context, depending on the context of the eval itself.
1068 See L</wantarray> for more on how the evaluation context can be determined.
1069
1070 If there is a syntax error or runtime error, or a C<die()> statement is
1071 executed, an undefined value is returned by C<eval()>, and C<$@> is set to the
1072 error message.  If there was no error, C<$@> is guaranteed to be a null
1073 string.  Beware that using C<eval()> neither silences perl from printing
1074 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1075 To do either of those, you have to use the C<$SIG{__WARN__}> facility.  See
1076 L</warn> and L<perlvar>.
1077
1078 Note that, because C<eval()> traps otherwise-fatal errors, it is useful for
1079 determining whether a particular feature (such as C<socket()> or C<symlink()>)
1080 is implemented.  It is also Perl's exception trapping mechanism, where
1081 the die operator is used to raise exceptions.
1082
1083 If the code to be executed doesn't vary, you may use the eval-BLOCK
1084 form to trap run-time errors without incurring the penalty of
1085 recompiling each time.  The error, if any, is still returned in C<$@>.
1086 Examples:
1087
1088     # make divide-by-zero nonfatal
1089     eval { $answer = $a / $b; }; warn $@ if $@;
1090
1091     # same thing, but less efficient
1092     eval '$answer = $a / $b'; warn $@ if $@;
1093
1094     # a compile-time error
1095     eval { $answer = };                 # WRONG
1096
1097     # a run-time error
1098     eval '$answer =';   # sets $@
1099
1100 When using the C<eval{}> form as an exception trap in libraries, you may
1101 wish not to trigger any C<__DIE__> hooks that user code may have
1102 installed.  You can use the C<local $SIG{__DIE__}> construct for this
1103 purpose, as shown in this example:
1104
1105     # a very private exception trap for divide-by-zero
1106     eval { local $SIG{'__DIE__'}; $answer = $a / $b; }; warn $@ if $@;
1107
1108 This is especially significant, given that C<__DIE__> hooks can call
1109 C<die()> again, which has the effect of changing their error messages:
1110
1111     # __DIE__ hooks may modify error messages
1112     {
1113        local $SIG{'__DIE__'} = sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1114        eval { die "foo lives here" };
1115        print $@ if $@;                # prints "bar lives here"
1116     }
1117
1118 With an C<eval()>, you should be especially careful to remember what's
1119 being looked at when:
1120
1121     eval $x;            # CASE 1
1122     eval "$x";          # CASE 2
1123
1124     eval '$x';          # CASE 3
1125     eval { $x };        # CASE 4
1126
1127     eval "\$$x++";      # CASE 5
1128     $$x++;              # CASE 6
1129
1130 Cases 1 and 2 above behave identically: they run the code contained in
1131 the variable C<$x>.  (Although case 2 has misleading double quotes making
1132 the reader wonder what else might be happening (nothing is).)  Cases 3
1133 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1134 does nothing but return the value of C<$x>.  (Case 4 is preferred for
1135 purely visual reasons, but it also has the advantage of compiling at
1136 compile-time instead of at run-time.)  Case 5 is a place where
1137 normally you I<WOULD> like to use double quotes, except that in this
1138 particular situation, you can just use symbolic references instead, as
1139 in case 6.
1140
1141 =item exec LIST
1142
1143 =item exec PROGRAM LIST
1144
1145 The C<exec()> function executes a system command I<AND NEVER RETURNS> -
1146 use C<system()> instead of C<exec()> if you want it to return. It fails and
1147 returns FALSE only if the command does not exist I<and> it is executed
1148 directly instead of via your system's command shell (see below).
1149
1150 Since it's a common mistake to use C<exec()> instead of C<system()>, Perl
1151 warns you if there is a following statement which isn't C<die()>, C<warn()>,
1152 or C<exit()> (if C<-w> is set  -  but you always do that).   If you
1153 I<really> want to follow an C<exec()> with some other statement, you
1154 can use one of these styles to avoid the warning:
1155
1156     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1157     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1158
1159 If there is more than one argument in LIST, or if LIST is an array
1160 with more than one value, calls C<execvp(3)> with the arguments in LIST.
1161 If there is only one scalar argument or an array with one element in it,
1162 the argument is checked for shell metacharacters, and if there are any,
1163 the entire argument is passed to the system's command shell for parsing
1164 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1165 If there are no shell metacharacters in the argument, it is split into
1166 words and passed directly to C<execvp()>, which is more efficient.  Note:
1167 C<exec()> and C<system()> do not flush your output buffer, so you may need to
1168 set C<$|> to avoid lost output.  Examples:
1169
1170     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1171     exec "sort $outfile | uniq";
1172
1173 If you don't really want to execute the first argument, but want to lie
1174 to the program you are executing about its own name, you can specify
1175 the program you actually want to run as an "indirect object" (without a
1176 comma) in front of the LIST.  (This always forces interpretation of the
1177 LIST as a multivalued list, even if there is only a single scalar in
1178 the list.)  Example:
1179
1180     $shell = '/bin/csh';
1181     exec $shell '-sh';          # pretend it's a login shell
1182
1183 or, more directly,
1184
1185     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1186
1187 When the arguments get executed via the system shell, results will
1188 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1189 for details.
1190
1191 Using an indirect object with C<exec> or C<system> is also more secure.
1192 This usage forces interpretation of the arguments as a multivalued list,
1193 even if the list had just one argument.  That way you're safe from the
1194 shell expanding wildcards or splitting up words with whitespace in them.
1195
1196     @args = ( "echo surprise" );
1197
1198     system @args;               # subject to shell escapes if @args == 1
1199     system { $args[0] } @args;  # safe even with one-arg list
1200
1201 The first version, the one without the indirect object, ran the I<echo>
1202 program, passing it C<"surprise"> an argument.  The second version
1203 didn't--it tried to run a program literally called I<"echo surprise">,
1204 didn't find it, and set C<$?> to a non-zero value indicating failure.
1205
1206 Note that C<exec> will not call your C<END> blocks, nor will it call
1207 any C<DESTROY> methods in your objects.
1208
1209 =item exists EXPR
1210
1211 Returns TRUE if the specified hash key exists in its hash array, even
1212 if the corresponding value is undefined.
1213
1214     print "Exists\n" if exists $array{$key};
1215     print "Defined\n" if defined $array{$key};
1216     print "True\n" if $array{$key};
1217
1218 A hash element can be TRUE only if it's defined, and defined if
1219 it exists, but the reverse doesn't necessarily hold true.
1220
1221 Note that the EXPR can be arbitrarily complicated as long as the final
1222 operation is a hash key lookup:
1223
1224     if (exists $ref->{"A"}{"B"}{$key}) { ... }
1225
1226 Although the last element will not spring into existence just because its
1227 existence was tested, intervening ones will.  Thus C<$ref-E<gt>{"A"}>
1228 C<$ref-E<gt>{"B"}> will spring into existence due to the existence
1229 test for a $key element.  This autovivification may be fixed in a later
1230 release.
1231
1232 =item exit EXPR
1233
1234 Evaluates EXPR and exits immediately with that value.  (Actually, it
1235 calls any defined C<END> routines first, but the C<END> routines may not
1236 abort the exit.  Likewise any object destructors that need to be called
1237 are called before exit.)  Example:
1238
1239     $ans = <STDIN>;
1240     exit 0 if $ans =~ /^[Xx]/;
1241
1242 See also C<die()>.  If EXPR is omitted, exits with C<0> status.  The only
1243 universally portable values for EXPR are C<0> for success and C<1> for error;
1244 all other values are subject to unpredictable interpretation depending
1245 on the environment in which the Perl program is running.
1246
1247 You shouldn't use C<exit()> to abort a subroutine if there's any chance that
1248 someone might want to trap whatever error happened.  Use C<die()> instead,
1249 which can be trapped by an C<eval()>.
1250
1251 All C<END{}> blocks are run at exit time.  See L<perlsub> for details.
1252
1253 =item exp EXPR
1254
1255 =item exp
1256
1257 Returns I<e> (the natural logarithm base) to the power of EXPR.
1258 If EXPR is omitted, gives C<exp($_)>.
1259
1260 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1261
1262 Implements the C<fcntl(2)> function.  You'll probably have to say
1263
1264     use Fcntl;
1265
1266 first to get the correct constant definitions.  Argument processing and
1267 value return works just like C<ioctl()> below.  
1268 For example:
1269
1270     use Fcntl;
1271     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1272         or die "can't fcntl F_GETFL: $!";
1273
1274 You don't have to check for C<defined> on the return from 
1275 C<fnctl>.  Like C<ioctl>, it maps a C<0> return from the system
1276 call into "C<0> but true" in Perl.  This string is true in 
1277 boolean context and C<0> in numeric context.  It is also 
1278 exempt from the normal B<-w> warnings on improper numeric
1279 conversions.
1280
1281 Note that C<fcntl()> will produce a fatal error if used on a machine that
1282 doesn't implement C<fcntl(2)>.
1283
1284 =item fileno FILEHANDLE
1285
1286 Returns the file descriptor for a filehandle.  This is useful for
1287 constructing bitmaps for C<select()> and low-level POSIX tty-handling
1288 operations.  If FILEHANDLE is an expression, the value is taken as 
1289 an indirect filehandle, generally its name. 
1290
1291 You can use this to find out whether two handles refer to the 
1292 same underlying descriptor:
1293
1294     if (fileno(THIS) == fileno(THAT)) {
1295         print "THIS and THAT are dups\n";
1296     } 
1297
1298 =item flock FILEHANDLE,OPERATION
1299
1300 Calls C<flock(2)>, or an emulation of it, on FILEHANDLE.  Returns TRUE for
1301 success, FALSE on failure.  Produces a fatal error if used on a machine
1302 that doesn't implement C<flock(2)>, C<fcntl(2)> locking, or C<lockf(3)>.  C<flock()>
1303 is Perl's portable file locking interface, although it locks only entire
1304 files, not records.
1305
1306 On many platforms (including most versions or clones of Unix), locks
1307 established by C<flock()> are B<merely advisory>.  Such discretionary locks
1308 are more flexible, but offer fewer guarantees.  This means that files
1309 locked with C<flock()> may be modified by programs that do not also use
1310 C<flock()>.  Windows NT and OS/2 are among the platforms which
1311 enforce mandatory locking.  See your local documentation for details.
1312
1313 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1314 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1315 you can use the symbolic names if import them from the Fcntl module,
1316 either individually, or as a group using the ':flock' tag.  LOCK_SH
1317 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1318 releases a previously requested lock.  If LOCK_NB is added to LOCK_SH or
1319 LOCK_EX then C<flock()> will return immediately rather than blocking
1320 waiting for the lock (check the return status to see if you got it).
1321
1322 To avoid the possibility of mis-coordination, Perl flushes FILEHANDLE
1323 before (un)locking it.
1324
1325 Note that the emulation built with C<lockf(3)> doesn't provide shared
1326 locks, and it requires that FILEHANDLE be open with write intent.  These
1327 are the semantics that C<lockf(3)> implements.  Most (all?) systems
1328 implement C<lockf(3)> in terms of C<fcntl(2)> locking, though, so the
1329 differing semantics shouldn't bite too many people.
1330
1331 Note also that some versions of C<flock()> cannot lock things over the
1332 network; you would need to use the more system-specific C<fcntl()> for
1333 that.  If you like you can force Perl to ignore your system's C<flock(2)>
1334 function, and so provide its own C<fcntl(2)>-based emulation, by passing
1335 the switch C<-Ud_flock> to the F<Configure> program when you configure
1336 perl.
1337
1338 Here's a mailbox appender for BSD systems.
1339
1340     use Fcntl ':flock'; # import LOCK_* constants
1341
1342     sub lock {
1343         flock(MBOX,LOCK_EX);
1344         # and, in case someone appended
1345         # while we were waiting...
1346         seek(MBOX, 0, 2);
1347     }
1348
1349     sub unlock {
1350         flock(MBOX,LOCK_UN);
1351     }
1352
1353     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1354             or die "Can't open mailbox: $!";
1355
1356     lock();
1357     print MBOX $msg,"\n\n";
1358     unlock();
1359
1360 See also L<DB_File> for other flock() examples.
1361
1362 =item fork
1363
1364 Does a C<fork(2)> system call.  Returns the child pid to the parent process,
1365 C<0> to the child process, or C<undef> if the fork is unsuccessful.
1366
1367 Note: unflushed buffers remain unflushed in both processes, which means
1368 you may need to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()>
1369 method of C<IO::Handle> to avoid duplicate output.
1370
1371 If you C<fork()> without ever waiting on your children, you will accumulate
1372 zombies:
1373
1374     $SIG{CHLD} = sub { wait };
1375
1376 There's also the double-fork trick (error checking on
1377 C<fork()> returns omitted);
1378
1379     unless ($pid = fork) {
1380         unless (fork) {
1381             exec "what you really wanna do";
1382             die "no exec";
1383             # ... or ...
1384             ## (some_perl_code_here)
1385             exit 0;
1386         }
1387         exit 0;
1388     }
1389     waitpid($pid,0);
1390
1391 See also L<perlipc> for more examples of forking and reaping
1392 moribund children.
1393
1394 Note that if your forked child inherits system file descriptors like
1395 STDIN and STDOUT that are actually connected by a pipe or socket, even
1396 if you exit, then the remote server (such as, say, httpd or rsh) won't think
1397 you're done.  You should reopen those to F</dev/null> if it's any issue.
1398
1399 =item format
1400
1401 Declare a picture format for use by the C<write()> function.  For
1402 example:
1403
1404     format Something =
1405         Test: @<<<<<<<< @||||| @>>>>>
1406               $str,     $%,    '$' . int($num)
1407     .
1408
1409     $str = "widget";
1410     $num = $cost/$quantity;
1411     $~ = 'Something';
1412     write;
1413
1414 See L<perlform> for many details and examples.
1415
1416 =item formline PICTURE,LIST
1417
1418 This is an internal function used by C<format>s, though you may call it,
1419 too.  It formats (see L<perlform>) a list of values according to the
1420 contents of PICTURE, placing the output into the format output
1421 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1422 Eventually, when a C<write()> is done, the contents of
1423 C<$^A> are written to some filehandle, but you could also read C<$^A>
1424 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1425 does one C<formline()> per line of form, but the C<formline()> function itself
1426 doesn't care how many newlines are embedded in the PICTURE.  This means
1427 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1428 You may therefore need to use multiple formlines to implement a single
1429 record format, just like the format compiler.
1430
1431 Be careful if you put double quotes around the picture, because an "C<@>"
1432 character may be taken to mean the beginning of an array name.
1433 C<formline()> always returns TRUE.  See L<perlform> for other examples.
1434
1435 =item getc FILEHANDLE
1436
1437 =item getc
1438
1439 Returns the next character from the input file attached to FILEHANDLE,
1440 or the undefined value at end of file, or if there was an error.  If
1441 FILEHANDLE is omitted, reads from STDIN.  This is not particularly
1442 efficient.  It cannot be used to get unbuffered single-characters,
1443 however.  For that, try something more like:
1444
1445     if ($BSD_STYLE) {
1446         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1447     }
1448     else {
1449         system "stty", '-icanon', 'eol', "\001";
1450     }
1451
1452     $key = getc(STDIN);
1453
1454     if ($BSD_STYLE) {
1455         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1456     }
1457     else {
1458         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1459     }
1460     print "\n";
1461
1462 Determination of whether $BSD_STYLE should be set
1463 is left as an exercise to the reader.
1464
1465 The C<POSIX::getattr()> function can do this more portably on systems
1466 purporting POSIX compliance.
1467 See also the C<Term::ReadKey> module from your nearest CPAN site;
1468 details on CPAN can be found on L<perlmod/CPAN>.
1469
1470 =item getlogin
1471
1472 Implements the C library function of the same name, which on most
1473 systems returns the current login from F</etc/utmp>, if any.  If null,
1474 use C<getpwuid()>.
1475
1476     $login = getlogin || getpwuid($<) || "Kilroy";
1477
1478 Do not consider C<getlogin()> for authentication: it is not as
1479 secure as C<getpwuid()>.
1480
1481 =item getpeername SOCKET
1482
1483 Returns the packed sockaddr address of other end of the SOCKET connection.
1484
1485     use Socket;
1486     $hersockaddr    = getpeername(SOCK);
1487     ($port, $iaddr) = unpack_sockaddr_in($hersockaddr);
1488     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1489     $herstraddr     = inet_ntoa($iaddr);
1490
1491 =item getpgrp PID
1492
1493 Returns the current process group for the specified PID.  Use
1494 a PID of C<0> to get the current process group for the
1495 current process.  Will raise an exception if used on a machine that
1496 doesn't implement C<getpgrp(2)>.  If PID is omitted, returns process
1497 group of current process.  Note that the POSIX version of C<getpgrp()>
1498 does not accept a PID argument, so only C<PID==0> is truly portable.
1499
1500 =item getppid
1501
1502 Returns the process id of the parent process.
1503
1504 =item getpriority WHICH,WHO
1505
1506 Returns the current priority for a process, a process group, or a user.
1507 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1508 machine that doesn't implement C<getpriority(2)>.
1509
1510 =item getpwnam NAME
1511
1512 =item getgrnam NAME
1513
1514 =item gethostbyname NAME
1515
1516 =item getnetbyname NAME
1517
1518 =item getprotobyname NAME
1519
1520 =item getpwuid UID
1521
1522 =item getgrgid GID
1523
1524 =item getservbyname NAME,PROTO
1525
1526 =item gethostbyaddr ADDR,ADDRTYPE
1527
1528 =item getnetbyaddr ADDR,ADDRTYPE
1529
1530 =item getprotobynumber NUMBER
1531
1532 =item getservbyport PORT,PROTO
1533
1534 =item getpwent
1535
1536 =item getgrent
1537
1538 =item gethostent
1539
1540 =item getnetent
1541
1542 =item getprotoent
1543
1544 =item getservent
1545
1546 =item setpwent
1547
1548 =item setgrent
1549
1550 =item sethostent STAYOPEN
1551
1552 =item setnetent STAYOPEN
1553
1554 =item setprotoent STAYOPEN
1555
1556 =item setservent STAYOPEN
1557
1558 =item endpwent
1559
1560 =item endgrent
1561
1562 =item endhostent
1563
1564 =item endnetent
1565
1566 =item endprotoent
1567
1568 =item endservent
1569
1570 These routines perform the same functions as their counterparts in the
1571 system library.  In list context, the return values from the
1572 various get routines are as follows:
1573
1574     ($name,$passwd,$uid,$gid,
1575        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1576     ($name,$passwd,$gid,$members) = getgr*
1577     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1578     ($name,$aliases,$addrtype,$net) = getnet*
1579     ($name,$aliases,$proto) = getproto*
1580     ($name,$aliases,$port,$proto) = getserv*
1581
1582 (If the entry doesn't exist you get a null list.)
1583
1584 In scalar context, you get the name, unless the function was a
1585 lookup by name, in which case you get the other thing, whatever it is.
1586 (If the entry doesn't exist you get the undefined value.)  For example:
1587
1588     $uid   = getpwnam($name);
1589     $name  = getpwuid($num);
1590     $name  = getpwent();
1591     $gid   = getgrnam($name);
1592     $name  = getgrgid($num;
1593     $name  = getgrent();
1594     #etc.
1595
1596 In I<getpw*()> the fields C<$quota>, C<$comment>, and C<$expire> are special
1597 cases in the sense that in many systems they are unsupported.  If the
1598 C<$quota> is unsupported, it is an empty scalar.  If it is supported, it
1599 usually encodes the disk quota.  If the C<$comment> field is unsupported,
1600 it is an empty scalar.  If it is supported it usually encodes some
1601 administrative comment about the user.  In some systems the $quota
1602 field may be C<$change> or C<$age>, fields that have to do with password
1603 aging.  In some systems the C<$comment> field may be C<$class>.  The C<$expire>
1604 field, if present, encodes the expiration period of the account or the
1605 password.  For the availability and the exact meaning of these fields
1606 in your system, please consult your C<getpwnam(3)> documentation and your
1607 F<pwd.h> file.  You can also find out from within Perl which meaning
1608 your C<$quota> and C<$comment> fields have and whether you have the C<$expire>
1609 field by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1610 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.
1611
1612 The C<$members> value returned by I<getgr*()> is a space separated list of
1613 the login names of the members of the group.
1614
1615 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
1616 C, it will be returned to you via C<$?> if the function call fails.  The
1617 C<@addrs> value returned by a successful call is a list of the raw
1618 addresses returned by the corresponding system library call.  In the
1619 Internet domain, each address is four bytes long and you can unpack it
1620 by saying something like:
1621
1622     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
1623
1624 If you get tired of remembering which element of the return list contains
1625 which return value, by-name interfaces are also provided in modules:
1626 C<File::stat>, C<Net::hostent>, C<Net::netent>, C<Net::protoent>, C<Net::servent>,
1627 C<Time::gmtime>, C<Time::localtime>, and C<User::grent>.  These override the
1628 normal built-in, replacing them with versions that return objects with
1629 the appropriate names for each field.  For example:
1630
1631    use File::stat;
1632    use User::pwent;
1633    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
1634
1635 Even though it looks like they're the same method calls (uid), 
1636 they aren't, because a C<File::stat> object is different from a C<User::pwent> object.
1637
1638 =item getsockname SOCKET
1639
1640 Returns the packed sockaddr address of this end of the SOCKET connection.
1641
1642     use Socket;
1643     $mysockaddr = getsockname(SOCK);
1644     ($port, $myaddr) = unpack_sockaddr_in($mysockaddr);
1645
1646 =item getsockopt SOCKET,LEVEL,OPTNAME
1647
1648 Returns the socket option requested, or undef if there is an error.
1649
1650 =item glob EXPR
1651
1652 =item glob
1653
1654 Returns the value of EXPR with filename expansions such as the standard Unix shell F</bin/sh> would
1655 do.  This is the internal function implementing the C<E<lt>*.cE<gt>>
1656 operator, but you can use it directly.  If EXPR is omitted, C<$_> is used.
1657 The C<E<lt>*.cE<gt>> operator is discussed in more detail in
1658 L<perlop/"I/O Operators">.
1659
1660 =item gmtime EXPR
1661
1662 Converts a time as returned by the time function to a 9-element array
1663 with the time localized for the standard Greenwich time zone.
1664 Typically used as follows:
1665
1666     #  0    1    2     3     4    5     6     7     8
1667     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1668                                             gmtime(time);
1669
1670 All array elements are numeric, and come straight out of a struct tm.
1671 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1672 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1673 years since 1900, that is, C<$year> is C<123> in year 2023, I<not> simply the last two digits of the year.
1674
1675 If EXPR is omitted, does C<gmtime(time())>.
1676
1677 In scalar context, returns the C<ctime(3)> value:
1678
1679     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1680
1681 Also see the C<timegm()> function provided by the C<Time::Local> module,
1682 and the C<strftime(3)> function available via the POSIX module.
1683
1684 This scalar value is B<not> locale dependent, see L<perllocale>, but
1685 instead a Perl builtin.  Also see the C<Time::Local> module, and the
1686 C<strftime(3)> and C<mktime(3)> function available via the POSIX module.  To
1687 get somewhat similar but locale dependent date strings, set up your
1688 locale environment variables appropriately (please see L<perllocale>)
1689 and try for example:
1690
1691     use POSIX qw(strftime);
1692         $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
1693
1694 Note that the C<%a> and C<%b>, the short forms of the day of the week
1695 and the month of the year, may not necessarily be three characters wide.
1696
1697 =item goto LABEL
1698
1699 =item goto EXPR
1700
1701 =item goto &NAME
1702
1703 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
1704 execution there.  It may not be used to go into any construct that
1705 requires initialization, such as a subroutine or a C<foreach> loop.  It
1706 also can't be used to go into a construct that is optimized away,
1707 or to get out of a block or subroutine given to C<sort()>.
1708 It can be used to go almost anywhere else within the dynamic scope,
1709 including out of subroutines, but it's usually better to use some other
1710 construct such as C<last> or C<die>.  The author of Perl has never felt the
1711 need to use this form of C<goto> (in Perl, that is--C is another matter).
1712
1713 The C<goto-EXPR> form expects a label name, whose scope will be resolved
1714 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
1715 necessarily recommended if you're optimizing for maintainability:
1716
1717     goto ("FOO", "BAR", "GLARCH")[$i];
1718
1719 The C<goto-&NAME> form is highly magical, and substitutes a call to the
1720 named subroutine for the currently running subroutine.  This is used by
1721 C<AUTOLOAD> subroutines that wish to load another subroutine and then
1722 pretend that the other subroutine had been called in the first place
1723 (except that any modifications to C<@_> in the current subroutine are
1724 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
1725 will be able to tell that this routine was called first.
1726
1727 =item grep BLOCK LIST
1728
1729 =item grep EXPR,LIST
1730
1731 This is similar in spirit to, but not the same as, C<grep(1)>
1732 and its relatives.  In particular, it is not limited to using
1733 regular expressions.
1734
1735 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
1736 C<$_> to each element) and returns the list value consisting of those
1737 elements for which the expression evaluated to TRUE.  In a scalar
1738 context, returns the number of times the expression was TRUE.
1739
1740     @foo = grep(!/^#/, @bar);    # weed out comments
1741
1742 or equivalently,
1743
1744     @foo = grep {!/^#/} @bar;    # weed out comments
1745
1746 Note that, because C<$_> is a reference into the list value, it can be used
1747 to modify the elements of the array.  While this is useful and
1748 supported, it can cause bizarre results if the LIST is not a named
1749 array.  Similarly, grep returns aliases into the original list,
1750 much like the way that a for loops's index variable aliases the list
1751 elements.  That is, modifying an element of a list returned by grep
1752 (for example, in a C<foreach>, C<map> or another C<grep>)
1753 actually modifies the element in the original list.
1754
1755 See also L</map> for an array composed of the results of the BLOCK or EXPR.
1756
1757 =item hex EXPR
1758
1759 =item hex
1760
1761 Interprets EXPR as a hex string and returns the corresponding
1762 value.  (To convert strings that might start with either 0 or 0x
1763 see L</oct>.)  If EXPR is omitted, uses C<$_>.
1764
1765     print hex '0xAf'; # prints '175'
1766     print hex 'aF';   # same
1767
1768 =item import
1769
1770 There is no builtin C<import()> function.  It is just an ordinary
1771 method (subroutine) defined (or inherited) by modules that wish to export
1772 names to another module.  The C<use()> function calls the C<import()> method
1773 for the package used.  See also L</use()>, L<perlmod>, and L<Exporter>.
1774
1775 =item index STR,SUBSTR,POSITION
1776
1777 =item index STR,SUBSTR
1778
1779 Returns the position of the first occurrence of SUBSTR in STR at or after
1780 POSITION.  If POSITION is omitted, starts searching from the beginning of
1781 the string.  The return value is based at C<0> (or whatever you've set the C<$[>
1782 variable to--but don't do that).  If the substring is not found, returns
1783 one less than the base, ordinarily C<-1>.
1784
1785 =item int EXPR
1786
1787 =item int
1788
1789 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
1790 You should not use this for rounding, because it truncates
1791 towards C<0>, and because machine representations of floating point
1792 numbers can sometimes produce counterintuitive results.  Usually C<sprintf()> or C<printf()>,
1793 or the C<POSIX::floor> or C<POSIX::ceil> functions, would serve you better.
1794
1795 =item ioctl FILEHANDLE,FUNCTION,SCALAR
1796
1797 Implements the C<ioctl(2)> function.  You'll probably have to say
1798
1799     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
1800
1801 first to get the correct function definitions.  If F<ioctl.ph> doesn't
1802 exist or doesn't have the correct definitions you'll have to roll your
1803 own, based on your C header files such as F<E<lt>sys/ioctl.hE<gt>>.
1804 (There is a Perl script called B<h2ph> that comes with the Perl kit that
1805 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
1806 written depending on the FUNCTION--a pointer to the string value of SCALAR
1807 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
1808 has no string value but does have a numeric value, that value will be
1809 passed rather than a pointer to the string value.  To guarantee this to be
1810 TRUE, add a C<0> to the scalar before using it.)  The C<pack()> and C<unpack()>
1811 functions are useful for manipulating the values of structures used by
1812 C<ioctl()>.  The following example sets the erase character to DEL.
1813
1814     require 'ioctl.ph';
1815     $getp = &TIOCGETP;
1816     die "NO TIOCGETP" if $@ || !$getp;
1817     $sgttyb_t = "ccccs";                # 4 chars and a short
1818     if (ioctl(STDIN,$getp,$sgttyb)) {
1819         @ary = unpack($sgttyb_t,$sgttyb);
1820         $ary[2] = 127;
1821         $sgttyb = pack($sgttyb_t,@ary);
1822         ioctl(STDIN,&TIOCSETP,$sgttyb)
1823             || die "Can't ioctl: $!";
1824     }
1825
1826 The return value of C<ioctl> (and C<fcntl>) is as follows:
1827
1828         if OS returns:          then Perl returns:
1829             -1                    undefined value
1830              0                  string "0 but true"
1831         anything else               that number
1832
1833 Thus Perl returns TRUE on success and FALSE on failure, yet you can
1834 still easily determine the actual value returned by the operating
1835 system:
1836
1837     ($retval = ioctl(...)) || ($retval = -1);
1838     printf "System returned %d\n", $retval;
1839
1840 The special string "C<0> but true" is excempt from B<-w> complaints
1841 about improper numeric conversions.
1842
1843 =item join EXPR,LIST
1844
1845 Joins the separate strings of LIST into a single string with
1846 fields separated by the value of EXPR, and returns the string.
1847 Example:
1848
1849     $_ = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
1850
1851 See L</split>.
1852
1853 =item keys HASH
1854
1855 Returns a list consisting of all the keys of the named hash.  (In a
1856 scalar context, returns the number of keys.)  The keys are returned in
1857 an apparently random order, but it is the same order as either the
1858 C<values()> or C<each()> function produces (given that the hash has not been
1859 modified).  As a side effect, it resets HASH's iterator.
1860
1861 Here is yet another way to print your environment:
1862
1863     @keys = keys %ENV;
1864     @values = values %ENV;
1865     while ($#keys >= 0) {
1866         print pop(@keys), '=', pop(@values), "\n";
1867     }
1868
1869 or how about sorted by key:
1870
1871     foreach $key (sort(keys %ENV)) {
1872         print $key, '=', $ENV{$key}, "\n";
1873     }
1874
1875 To sort an array by value, you'll need to use a C<sort> function.
1876 Here's a descending numeric sort of a hash by its values:
1877
1878     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
1879         printf "%4d %s\n", $hash{$key}, $key;
1880     }
1881
1882 As an lvalue C<keys> allows you to increase the number of hash buckets
1883 allocated for the given hash.  This can gain you a measure of efficiency if
1884 you know the hash is going to get big.  (This is similar to pre-extending
1885 an array by assigning a larger number to $#array.)  If you say
1886
1887     keys %hash = 200;
1888
1889 then C<%hash> will have at least 200 buckets allocated for it--256 of them, in fact, since 
1890 it rounds up to the next power of two.  These
1891 buckets will be retained even if you do C<%hash = ()>, use C<undef
1892 %hash> if you want to free the storage while C<%hash> is still in scope.
1893 You can't shrink the number of buckets allocated for the hash using
1894 C<keys> in this way (but you needn't worry about doing this by accident,
1895 as trying has no effect).
1896
1897 =item kill LIST
1898
1899 Sends a signal to a list of processes.  The first element of
1900 the list must be the signal to send.  Returns the number of
1901 processes successfully signaled.
1902
1903     $cnt = kill 1, $child1, $child2;
1904     kill 9, @goners;
1905
1906 Unlike in the shell, in Perl if the I<SIGNAL> is negative, it kills
1907 process groups instead of processes.  (On System V, a negative I<PROCESS>
1908 number will also kill process groups, but that's not portable.)  That
1909 means you usually want to use positive not negative signals.  You may also
1910 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
1911
1912 =item last LABEL
1913
1914 =item last
1915
1916 The C<last> command is like the C<break> statement in C (as used in
1917 loops); it immediately exits the loop in question.  If the LABEL is
1918 omitted, the command refers to the innermost enclosing loop.  The
1919 C<continue> block, if any, is not executed:
1920
1921     LINE: while (<STDIN>) {
1922         last LINE if /^$/;      # exit when done with header
1923         #...
1924     }
1925
1926 See also L</continue> for an illustration of how C<last>, C<next>, and
1927 C<redo> work.
1928
1929 =item lc EXPR
1930
1931 =item lc
1932
1933 Returns an lowercased version of EXPR.  This is the internal function
1934 implementing the C<\L> escape in double-quoted strings.
1935 Respects current C<LC_CTYPE> locale if C<use locale> in force.  See L<perllocale>.
1936
1937 If EXPR is omitted, uses C<$_>.
1938
1939 =item lcfirst EXPR
1940
1941 =item lcfirst
1942
1943 Returns the value of EXPR with the first character lowercased.  This is
1944 the internal function implementing the C<\l> escape in double-quoted strings.
1945 Respects current C<LC_CTYPE> locale if C<use locale> in force.  See L<perllocale>.
1946
1947 If EXPR is omitted, uses C<$_>.
1948
1949 =item length EXPR
1950
1951 =item length
1952
1953 Returns the length in bytes of the value of EXPR.  If EXPR is
1954 omitted, returns length of C<$_>.
1955
1956 =item link OLDFILE,NEWFILE
1957
1958 Creates a new filename linked to the old filename.  Returns TRUE for
1959 success, FALSE otherwise.
1960
1961 =item listen SOCKET,QUEUESIZE
1962
1963 Does the same thing that the listen system call does.  Returns TRUE if
1964 it succeeded, FALSE otherwise.  See example in L<perlipc/"Sockets: Client/Server Communication">.
1965
1966 =item local EXPR
1967
1968 A local modifies the listed variables to be local to the enclosing
1969 block, file, or eval.  If more than one value is listed, the list must
1970 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
1971 for details, including issues with tied arrays and hashes.
1972
1973 You really probably want to be using C<my()> instead, because C<local()> isn't
1974 what most people think of as "local".  See L<perlsub/"Private Variables
1975 via my()"> for details.
1976
1977 =item localtime EXPR
1978
1979 Converts a time as returned by the time function to a 9-element array
1980 with the time analyzed for the local time zone.  Typically used as
1981 follows:
1982
1983     #  0    1    2     3     4    5     6     7     8
1984     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
1985                                                 localtime(time);
1986
1987 All array elements are numeric, and come straight out of a struct tm.
1988 In particular this means that C<$mon> has the range C<0..11> and C<$wday> has
1989 the range C<0..6> with sunday as day C<0>.  Also, C<$year> is the number of
1990 years since 1900, that is, C<$year> is C<123> in year 2023, and I<not> simply the last two digits of the year.
1991
1992 If EXPR is omitted, uses the current time (C<localtime(time)>).
1993
1994 In scalar context, returns the C<ctime(3)> value:
1995
1996     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
1997
1998 This scalar value is B<not> locale dependent, see L<perllocale>, but
1999 instead a Perl builtin.  Also see the C<Time::Local> module, and the
2000 C<strftime(3)> and C<mktime(3)> function available via the POSIX module.  To
2001 get somewhat similar but locale dependent date strings, set up your
2002 locale environment variables appropriately (please see L<perllocale>)
2003 and try for example:
2004
2005     use POSIX qw(strftime);
2006         $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2007
2008 Note that the C<%a> and C<%b>, the short forms of the day of the week
2009 and the month of the year, may not necessarily be three characters wide.
2010
2011 =item log EXPR
2012
2013 =item log
2014
2015 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted, returns log
2016 of C<$_>.
2017
2018 =item lstat FILEHANDLE
2019
2020 =item lstat EXPR
2021
2022 =item lstat
2023
2024 Does the same thing as the C<stat()> function (including setting the
2025 special C<_> filehandle) but stats a symbolic link instead of the file
2026 the symbolic link points to.  If symbolic links are unimplemented on
2027 your system, a normal C<stat()> is done.
2028
2029 If EXPR is omitted, stats C<$_>.
2030
2031 =item m//
2032
2033 The match operator.  See L<perlop>.
2034
2035 =item map BLOCK LIST
2036
2037 =item map EXPR,LIST
2038
2039 Evaluates the BLOCK or EXPR for each element of LIST (locally setting C<$_> to each
2040 element) and returns the list value composed of the results of each such
2041 evaluation.  Evaluates BLOCK or EXPR in a list context, so each element of LIST
2042 may produce zero, one, or more elements in the returned value.
2043
2044     @chars = map(chr, @nums);
2045
2046 translates a list of numbers to the corresponding characters.  And
2047
2048     %hash = map { getkey($_) => $_ } @array;
2049
2050 is just a funny way to write
2051
2052     %hash = ();
2053     foreach $_ (@array) {
2054         $hash{getkey($_)} = $_;
2055     }
2056
2057 Note that, because C<$_> is a reference into the list value, it can be used
2058 to modify the elements of the array.  While this is useful and
2059 supported, it can cause bizarre results if the LIST is not a named
2060 array.  See also L</grep> for an array composed of those items of the 
2061 original list for which the BLOCK or EXPR evaluates to true.
2062
2063 =item mkdir FILENAME,MODE
2064
2065 Creates the directory specified by FILENAME, with permissions specified
2066 by MODE (as modified by umask).  If it succeeds it returns TRUE, otherwise
2067 it returns FALSE and sets C<$!> (errno).
2068
2069 =item msgctl ID,CMD,ARG
2070
2071 Calls the System V IPC function C<msgctl(2)>.  You'll probably have to say
2072
2073     use IPC::SysV;
2074
2075 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2076 then ARG must be a variable which will hold the returned C<msqid_ds>
2077 structure.  Returns like C<ioctl>: the undefined value for error, "C<0> but
2078 true" for zero, or the actual return value otherwise.  See also
2079 C<IPC::SysV> and C<IPC::Semaphore::Msg> documentation.
2080
2081 =item msgget KEY,FLAGS
2082
2083 Calls the System V IPC function C<msgget(2)>.  Returns the message queue
2084 id, or the undefined value if there is an error.  See also C<IPC::SysV>
2085 and C<IPC::SysV::Msg> documentation.
2086
2087 =item msgsnd ID,MSG,FLAGS
2088
2089 Calls the System V IPC function msgsnd to send the message MSG to the
2090 message queue ID.  MSG must begin with the long integer message type,
2091 which may be created with C<pack("l", $type)>.  Returns TRUE if
2092 successful, or FALSE if there is an error.  See also C<IPC::SysV>
2093 and C<IPC::SysV::Msg> documentation.
2094
2095 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2096
2097 Calls the System V IPC function msgrcv to receive a message from
2098 message queue ID into variable VAR with a maximum message size of
2099 SIZE.  Note that if a message is received, the message type will be
2100 the first thing in VAR, and the maximum length of VAR is SIZE plus the
2101 size of the message type.  Returns TRUE if successful, or FALSE if
2102 there is an error.  See also C<IPC::SysV> and C<IPC::SysV::Msg> documentation.
2103
2104 =item my EXPR
2105
2106 A C<my> declares the listed variables to be local (lexically) to the
2107 enclosing block, file, or C<eval>.  If
2108 more than one value is listed, the list must be placed in parentheses.  See
2109 L<perlsub/"Private Variables via my()"> for details.
2110
2111 =item next LABEL
2112
2113 =item next
2114
2115 The C<next> command is like the C<continue> statement in C; it starts
2116 the next iteration of the loop:
2117
2118     LINE: while (<STDIN>) {
2119         next LINE if /^#/;      # discard comments
2120         #...
2121     }
2122
2123 Note that if there were a C<continue> block on the above, it would get
2124 executed even on discarded lines.  If the LABEL is omitted, the command
2125 refers to the innermost enclosing loop.
2126
2127 See also L</continue> for an illustration of how C<last>, C<next>, and
2128 C<redo> work.
2129
2130 =item no Module LIST
2131
2132 See the L</use> function, which C<no> is the opposite of.
2133
2134 =item oct EXPR
2135
2136 =item oct
2137
2138 Interprets EXPR as an octal string and returns the corresponding
2139 value.  (If EXPR happens to start off with C<0x>, interprets it as
2140 a hex string instead.)  The following will handle decimal, octal, and
2141 hex in the standard Perl or C notation:
2142
2143     $val = oct($val) if $val =~ /^0/;
2144
2145 If EXPR is omitted, uses C<$_>.  This function is commonly used when
2146 a string such as C<644> needs to be converted into a file mode, for
2147 example. (Although perl will automatically convert strings into
2148 numbers as needed, this automatic conversion assumes base 10.)
2149
2150 =item open FILEHANDLE,EXPR
2151
2152 =item open FILEHANDLE
2153
2154 Opens the file whose filename is given by EXPR, and associates it with
2155 FILEHANDLE.  If FILEHANDLE is an expression, its value is used as the
2156 name of the real filehandle wanted.  If EXPR is omitted, the scalar
2157 variable of the same name as the FILEHANDLE contains the filename.
2158 (Note that lexical variables--those declared with C<my>--will not work
2159 for this purpose; so if you're using C<my>, specify EXPR in your call
2160 to open.)
2161
2162 If the filename begins with C<'E<lt>'> or nothing, the file is opened for input.
2163 If the filename begins with C<'E<gt>'>, the file is truncated and opened for
2164 output, being created if necessary. If the filename begins with C<'E<gt>E<gt>'>,
2165 the file is opened for appending, again being created if necessary. 
2166 You can put a C<'+'> in front of the C<'E<gt>'> or C<'E<lt>'> to indicate that
2167 you want both read and write access to the file; thus C<'+E<lt>'> is almost
2168 always preferred for read/write updates--the C<'+E<gt>'> mode would clobber the
2169 file first.  You can't usually use either read-write mode for updating
2170 textfiles, since they have variable length records.  See the B<-i>
2171 switch in L<perlrun> for a better approach.
2172
2173 The prefix and the filename may be separated with spaces.
2174 These various prefixes correspond to the C<fopen(3)> modes of C<'r'>, C<'r+'>, C<'w'>,
2175 C<'w+'>, C<'a'>, and C<'a+'>.
2176
2177 If the filename begins with C<'|'>, the filename is interpreted as a
2178 command to which output is to be piped, and if the filename ends with a
2179 C<'|'>, the filename is interpreted See L<perlipc/"Using open() for IPC">
2180 for more examples of this.  (You are not allowed to C<open()> to a command
2181 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2182 and L<perlipc/"Bidirectional Communication"> for alternatives.)
2183
2184 Opening C<'-'> opens STDIN and opening C<'E<gt>-'> opens STDOUT.  Open returns
2185 nonzero upon success, the undefined value otherwise.  If the C<open>
2186 involved a pipe, the return value happens to be the pid of the
2187 subprocess.
2188
2189 If you're unfortunate enough to be running Perl on a system that
2190 distinguishes between text files and binary files (modern operating
2191 systems don't care), then you should check out L</binmode> for tips for
2192 dealing with this.  The key distinction between systems that need C<binmode>
2193 and those that don't is their text file formats.  Systems like Unix, MacOS, and
2194 Plan9, which delimit lines with a single character, and which encode that
2195 character in C as C<"\n">, do not need C<binmode>.  The rest need it.
2196
2197 When opening a file, it's usually a bad idea to continue normal execution
2198 if the request failed, so C<open> is frequently used in connection with
2199 C<die>. Even if C<die> won't do what you want (say, in a CGI script,
2200 where you want to make a nicely formatted error message (but there are
2201 modules that can help with that problem)) you should always check
2202 the return value from opening a file. The infrequent exception is when
2203 working with an unopened filehandle is actually what you want to do.
2204
2205 Examples:
2206
2207     $ARTICLE = 100;
2208     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2209     while (<ARTICLE>) {...
2210
2211     open(LOG, '>>/usr/spool/news/twitlog'); # (log is reserved)
2212     # if the open fails, output is discarded
2213
2214     open(DBASE, '+<dbase.mine')             # open for update
2215         or die "Can't open 'dbase.mine' for update: $!";
2216
2217     open(ARTICLE, "caesar <$article |")     # decrypt article
2218         or die "Can't start caesar: $!";
2219
2220     open(EXTRACT, "|sort >/tmp/Tmp$$")      # $$ is our process id
2221         or die "Can't start sort: $!";
2222
2223     # process argument list of files along with any includes
2224
2225     foreach $file (@ARGV) {
2226         process($file, 'fh00');
2227     }
2228
2229     sub process {
2230         my($filename, $input) = @_;
2231         $input++;               # this is a string increment
2232         unless (open($input, $filename)) {
2233             print STDERR "Can't open $filename: $!\n";
2234             return;
2235         }
2236
2237         local $_;
2238         while (<$input>) {              # note use of indirection
2239             if (/^#include "(.*)"/) {
2240                 process($1, $input);
2241                 next;
2242             }
2243             #...                # whatever
2244         }
2245     }
2246
2247 You may also, in the Bourne shell tradition, specify an EXPR beginning
2248 with C<'E<gt>&'>, in which case the rest of the string is interpreted as the
2249 name of a filehandle (or file descriptor, if numeric) to be
2250 duped and opened.  You may use C<&> after C<E<gt>>, C<E<gt>E<gt>>, C<E<lt>>, C<+E<gt>>,
2251 C<+E<gt>E<gt>>, and C<+E<lt>>.  The
2252 mode you specify should match the mode of the original filehandle.
2253 (Duping a filehandle does not take into account any existing contents of
2254 stdio buffers.)
2255 Here is a script that saves, redirects, and restores STDOUT and
2256 STDERR:
2257
2258     #!/usr/bin/perl
2259     open(OLDOUT, ">&STDOUT");
2260     open(OLDERR, ">&STDERR");
2261
2262     open(STDOUT, ">foo.out") || die "Can't redirect stdout";
2263     open(STDERR, ">&STDOUT") || die "Can't dup stdout";
2264
2265     select(STDERR); $| = 1;     # make unbuffered
2266     select(STDOUT); $| = 1;     # make unbuffered
2267
2268     print STDOUT "stdout 1\n";  # this works for
2269     print STDERR "stderr 1\n";  # subprocesses too
2270
2271     close(STDOUT);
2272     close(STDERR);
2273
2274     open(STDOUT, ">&OLDOUT");
2275     open(STDERR, ">&OLDERR");
2276
2277     print STDOUT "stdout 2\n";
2278     print STDERR "stderr 2\n";
2279
2280
2281 If you specify C<'E<lt>&=N'>, where C<N> is a number, then Perl will do an
2282 equivalent of C's C<fdopen()> of that file descriptor; this is more
2283 parsimonious of file descriptors.  For example:
2284
2285     open(FILEHANDLE, "<&=$fd")
2286
2287 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>, then
2288 there is an implicit fork done, and the return value of open is the pid
2289 of the child within the parent process, and C<0> within the child
2290 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2291 The filehandle behaves normally for the parent, but i/o to that
2292 filehandle is piped from/to the STDOUT/STDIN of the child process.
2293 In the child process the filehandle isn't opened--i/o happens from/to
2294 the new STDOUT or STDIN.  Typically this is used like the normal
2295 piped open when you want to exercise more control over just how the
2296 pipe command gets executed, such as when you are running setuid, and
2297 don't want to have to scan shell commands for metacharacters.
2298 The following pairs are more or less equivalent:
2299
2300     open(FOO, "|tr '[a-z]' '[A-Z]'");
2301     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
2302
2303     open(FOO, "cat -n '$file'|");
2304     open(FOO, "-|") || exec 'cat', '-n', $file;
2305
2306 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
2307
2308 NOTE: On any operation that may do a fork, any unflushed buffers remain
2309 unflushed in both processes, which means you may need to set C<$|> to
2310 avoid duplicate output.
2311
2312 Closing any piped filehandle causes the parent process to wait for the
2313 child to finish, and returns the status value in C<$?>.
2314
2315 The filename passed to open will have leading and trailing
2316 whitespace deleted, and the normal redirection chararacters
2317 honored.  This property, known as "magic open", 
2318 can often be used to good effect.  A user could specify a filename of
2319 F<"rsh cat file |">, or you could change certain filenames as needed:
2320
2321     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
2322     open(FH, $filename) or die "Can't open $filename: $!";
2323
2324 However, to open a file with arbitrary weird characters in it, it's
2325 necessary to protect any leading and trailing whitespace:
2326
2327     $file =~ s#^(\s)#./$1#;
2328     open(FOO, "< $file\0");
2329
2330 If you want a "real" C C<open()> (see L<open(2)> on your system), then you
2331 should use the C<sysopen()> function, which involves no such magic.  This is
2332 another way to protect your filenames from interpretation.  For example:
2333
2334     use IO::Handle;
2335     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
2336         or die "sysopen $path: $!";
2337     $oldfh = select(HANDLE); $| = 1; select($oldfh);
2338     print HANDLE "stuff $$\n");
2339     seek(HANDLE, 0, 0);
2340     print "File contains: ", <HANDLE>;
2341
2342 Using the constructor from the C<IO::Handle> package (or one of its
2343 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
2344 filehandles that have the scope of whatever variables hold references to
2345 them, and automatically close whenever and however you leave that scope:
2346
2347     use IO::File;
2348     #...
2349     sub read_myfile_munged {
2350         my $ALL = shift;
2351         my $handle = new IO::File;
2352         open($handle, "myfile") or die "myfile: $!";
2353         $first = <$handle>
2354             or return ();     # Automatically closed here.
2355         mung $first or die "mung failed";       # Or here.
2356         return $first, <$handle> if $ALL;       # Or here.
2357         $first;                                 # Or here.
2358     }
2359
2360 See L</seek()> for some details about mixing reading and writing.
2361
2362 =item opendir DIRHANDLE,EXPR
2363
2364 Opens a directory named EXPR for processing by C<readdir()>, C<telldir()>,
2365 C<seekdir()>, C<rewinddir()>, and C<closedir()>.  Returns TRUE if successful.
2366 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
2367
2368 =item ord EXPR
2369
2370 =item ord
2371
2372 Returns the numeric ascii value of the first character of EXPR.  If
2373 EXPR is omitted, uses C<$_>.  For the reverse, see L</chr>.
2374
2375 =item pack TEMPLATE,LIST
2376
2377 Takes an array or list of values and packs it into a binary structure,
2378 returning the string containing the structure.  The TEMPLATE is a
2379 sequence of characters that give the order and type of values, as
2380 follows:
2381
2382     A   An ascii string, will be space padded.
2383     a   An ascii string, will be null padded.
2384     b   A bit string (ascending bit order, like vec()).
2385     B   A bit string (descending bit order).
2386     h   A hex string (low nybble first).
2387     H   A hex string (high nybble first).
2388
2389     c   A signed char value.
2390     C   An unsigned char value.
2391
2392     s   A signed short value.
2393     S   An unsigned short value.
2394           (This 'short' is _exactly_ 16 bits, which may differ from
2395            what a local C compiler calls 'short'.)
2396
2397     i   A signed integer value.
2398     I   An unsigned integer value.
2399           (This 'integer' is _at_least_ 32 bits wide.  Its exact size
2400            depends on what a local C compiler calls 'int', and may
2401            even be larger than the 'long' described in the next item.)
2402
2403     l   A signed long value.
2404     L   An unsigned long value.
2405           (This 'long' is _exactly_ 32 bits, which may differ from
2406            what a local C compiler calls 'long'.)
2407
2408     n   A short in "network" (big-endian) order.
2409     N   A long in "network" (big-endian) order.
2410     v   A short in "VAX" (little-endian) order.
2411     V   A long in "VAX" (little-endian) order.
2412           (These 'shorts' and 'longs' are _exactly_ 16 bits and
2413            _exactly_ 32 bits, respectively.)
2414
2415     f   A single-precision float in the native format.
2416     d   A double-precision float in the native format.
2417
2418     p   A pointer to a null-terminated string.
2419     P   A pointer to a structure (fixed-length string).
2420
2421     u   A uuencoded string.
2422
2423     w   A BER compressed integer.  Its bytes represent an unsigned
2424         integer in base 128, most significant digit first, with as few
2425         digits as possible.  Bit eight (the high bit) is set on each
2426         byte except the last.
2427
2428     x   A null byte.
2429     X   Back up a byte.
2430     @   Null fill to absolute position.
2431
2432 Each letter may optionally be followed by a number giving a repeat
2433 count.  With all types except C<"a">, C<"A">, C<"b">, C<"B">, C<"h">, C<"H">, and C<"P"> the
2434 pack function will gobble up that many values from the LIST.  A C<*> for the
2435 repeat count means to use however many items are left.  The C<"a"> and C<"A">
2436 types gobble just one value, but pack it as a string of length count,
2437 padding with nulls or spaces as necessary.  (When unpacking, C<"A"> strips
2438 trailing spaces and nulls, but C<"a"> does not.)  Likewise, the C<"b"> and C<"B">
2439 fields pack a string that many bits long.  The C<"h"> and C<"H"> fields pack a
2440 string that many nybbles long.  The C<"p"> type packs a pointer to a null-
2441 terminated string.  You are responsible for ensuring the string is not a
2442 temporary value (which can potentially get deallocated before you get
2443 around to using the packed result).  The C<"P"> packs a pointer to a structure
2444 of the size indicated by the length. A NULL pointer is created if the 
2445 corresponding value for C<"p"> or C<"P"> is C<undef>.
2446 Real numbers (floats and doubles) are
2447 in the native machine format only; due to the multiplicity of floating
2448 formats around, and the lack of a standard "network" representation, no
2449 facility for interchange has been made.  This means that packed floating
2450 point data written on one machine may not be readable on another - even if
2451 both use IEEE floating point arithmetic (as the endian-ness of the memory
2452 representation is not part of the IEEE spec).  Note that Perl uses doubles
2453 internally for all numeric calculation, and converting from double into
2454 float and thence back to double again will lose precision (i.e.,
2455 C<unpack("f", pack("f", $foo)>) will not in general equal C<$foo>).
2456
2457 Examples:
2458
2459     $foo = pack("cccc",65,66,67,68);
2460     # foo eq "ABCD"
2461     $foo = pack("c4",65,66,67,68);
2462     # same thing
2463
2464     $foo = pack("ccxxcc",65,66,67,68);
2465     # foo eq "AB\0\0CD"
2466
2467     $foo = pack("s2",1,2);
2468     # "\1\0\2\0" on little-endian
2469     # "\0\1\0\2" on big-endian
2470
2471     $foo = pack("a4","abcd","x","y","z");
2472     # "abcd"
2473
2474     $foo = pack("aaaa","abcd","x","y","z");
2475     # "axyz"
2476
2477     $foo = pack("a14","abcdefg");
2478     # "abcdefg\0\0\0\0\0\0\0"
2479
2480     $foo = pack("i9pl", gmtime);
2481     # a real struct tm (on my system anyway)
2482
2483     sub bintodec {
2484         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
2485     }
2486
2487 The same template may generally also be used in the unpack function.
2488
2489 =item package 
2490
2491 =item package NAMESPACE
2492
2493 Declares the compilation unit as being in the given namespace.  The scope
2494 of the package declaration is from the declaration itself through the end of
2495 the enclosing block (the same scope as the C<local()> operator).  All further
2496 unqualified dynamic identifiers will be in this namespace.  A package
2497 statement affects only dynamic variables--including those you've used
2498 C<local()> on--but I<not> lexical variables created with C<my()>.  Typically it
2499 would be the first declaration in a file to be included by the C<require>
2500 or C<use> operator.  You can switch into a package in more than one place;
2501 it merely influences which symbol table is used by the compiler for the
2502 rest of that block.  You can refer to variables and filehandles in other
2503 packages by prefixing the identifier with the package name and a double
2504 colon:  C<$Package::Variable>.  If the package name is null, the C<main>
2505 package as assumed.  That is, C<$::sail> is equivalent to C<$main::sail>.
2506
2507 If NAMESPACE is omitted, then there is no current package, and all
2508 identifiers must be fully qualified or lexicals.  This is stricter
2509 than C<use strict>, since it also extends to function names.
2510
2511 See L<perlmod/"Packages"> for more information about packages, modules,
2512 and classes.  See L<perlsub> for other scoping issues.
2513
2514 =item pipe READHANDLE,WRITEHANDLE
2515
2516 Opens a pair of connected pipes like the corresponding system call.
2517 Note that if you set up a loop of piped processes, deadlock can occur
2518 unless you are very careful.  In addition, note that Perl's pipes use
2519 stdio buffering, so you may need to set C<$|> to flush your WRITEHANDLE
2520 after each command, depending on the application.
2521
2522 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
2523 for examples of such things.
2524
2525 =item pop ARRAY
2526
2527 =item pop
2528
2529 Pops and returns the last value of the array, shortening the array by
2530 1.  Has a similar effect to
2531
2532     $tmp = $ARRAY[$#ARRAY--];
2533
2534 If there are no elements in the array, returns the undefined value.
2535 If ARRAY is omitted, pops the
2536 C<@ARGV> array in the main program, and the C<@_> array in subroutines, just
2537 like C<shift()>.
2538
2539 =item pos SCALAR
2540
2541 =item pos
2542
2543 Returns the offset of where the last C<m//g> search left off for the variable
2544 is in question (C<$_> is used when the variable is not specified).  May be
2545 modified to change that offset.  Such modification will also influence
2546 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
2547 L<perlop>.
2548
2549 =item print FILEHANDLE LIST
2550
2551 =item print LIST
2552
2553 =item print
2554
2555 Prints a string or a comma-separated list of strings.  Returns TRUE
2556 if successful.  FILEHANDLE may be a scalar variable name, in which case
2557 the variable contains the name of or a reference to the filehandle, thus introducing one
2558 level of indirection.  (NOTE: If FILEHANDLE is a variable and the next
2559 token is a term, it may be misinterpreted as an operator unless you
2560 interpose a C<+> or put parentheses around the arguments.)  If FILEHANDLE is
2561 omitted, prints by default to standard output (or to the last selected
2562 output channel--see L</select>).  If LIST is also omitted, prints C<$_> to
2563 the currently selected output channel.  To set the default output channel to something other than
2564 STDOUT use the select operation.  Note that, because print takes a
2565 LIST, anything in the LIST is evaluated in list context, and any
2566 subroutine that you call will have one or more of its expressions
2567 evaluated in list context.  Also be careful not to follow the print
2568 keyword with a left parenthesis unless you want the corresponding right
2569 parenthesis to terminate the arguments to the print--interpose a C<+> or
2570 put parentheses around all the arguments.
2571
2572 Note that if you're storing FILEHANDLES in an array or other expression,
2573 you will have to use a block returning its value instead:
2574
2575     print { $files[$i] } "stuff\n";
2576     print { $OK ? STDOUT : STDERR } "stuff\n";
2577
2578 =item printf FILEHANDLE FORMAT, LIST
2579
2580 =item printf FORMAT, LIST
2581
2582 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
2583 (the output record separator) is not appended.  The first argument
2584 of the list will be interpreted as the C<printf> format.  If C<use locale> is
2585 in effect, the character used for the decimal point in formatted real numbers
2586 is affected by the LC_NUMERIC locale.  See L<perllocale>.
2587
2588 Don't fall into the trap of using a C<printf()> when a simple
2589 C<print()> would do.  The C<print()> is more efficient and less
2590 error prone.
2591
2592 =item prototype FUNCTION
2593
2594 Returns the prototype of a function as a string (or C<undef> if the
2595 function has no prototype).  FUNCTION is a reference to, or the name of,
2596 the function whose prototype you want to retrieve.
2597
2598 If FUNCTION is a string starting with C<CORE::>, the rest is taken as
2599 a name for Perl builtin.  If builtin is not I<overridable> (such as
2600 C<qw>) or its arguments cannot be expressed by a prototype (such as
2601 C<system>) - in other words, the builtin does not behave like a Perl
2602 function - returns C<undef>.  Otherwise, the string describing the
2603 equivalent prototype is returned.
2604
2605 =item push ARRAY,LIST
2606
2607 Treats ARRAY as a stack, and pushes the values of LIST
2608 onto the end of ARRAY.  The length of ARRAY increases by the length of
2609 LIST.  Has the same effect as
2610
2611     for $value (LIST) {
2612         $ARRAY[++$#ARRAY] = $value;
2613     }
2614
2615 but is more efficient.  Returns the new number of elements in the array.
2616
2617 =item q/STRING/
2618
2619 =item qq/STRING/
2620
2621 =item qx/STRING/
2622
2623 =item qw/STRING/
2624
2625 Generalized quotes.  See L<perlop>.
2626
2627 =item quotemeta EXPR
2628
2629 =item quotemeta
2630
2631 Returns the value of EXPR with all non-alphanumeric
2632 characters backslashed.  (That is, all characters not matching
2633 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
2634 returned string, regardless of any locale settings.)
2635 This is the internal function implementing
2636 the C<\Q> escape in double-quoted strings.
2637
2638 If EXPR is omitted, uses C<$_>.
2639
2640 =item rand EXPR
2641
2642 =item rand
2643
2644 Returns a random fractional number greater than or equal to C<0> and less
2645 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
2646 omitted, the value C<1> is used.  Automatically calls C<srand()> unless
2647 C<srand()> has already been called.  See also C<srand()>.
2648
2649 (Note: If your rand function consistently returns numbers that are too
2650 large or too small, then your version of Perl was probably compiled
2651 with the wrong number of RANDBITS.)
2652
2653 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
2654
2655 =item read FILEHANDLE,SCALAR,LENGTH
2656
2657 Attempts to read LENGTH bytes of data into variable SCALAR from the
2658 specified FILEHANDLE.  Returns the number of bytes actually read,
2659 C<0> at end of file, or undef if there was an error.  SCALAR will be grown
2660 or shrunk to the length actually read.  An OFFSET may be specified to
2661 place the read data at some other place than the beginning of the
2662 string.  This call is actually implemented in terms of stdio's C<fread(3)>
2663 call.  To get a true C<read(2)> system call, see C<sysread()>.
2664
2665 =item readdir DIRHANDLE
2666
2667 Returns the next directory entry for a directory opened by C<opendir()>.
2668 If used in list context, returns all the rest of the entries in the
2669 directory.  If there are no more entries, returns an undefined value in
2670 scalar context or a null list in list context.
2671
2672 If you're planning to filetest the return values out of a C<readdir()>, you'd
2673 better prepend the directory in question.  Otherwise, because we didn't
2674 C<chdir()> there, it would have been testing the wrong file.
2675
2676     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
2677     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
2678     closedir DIR;
2679
2680 =item readline EXPR
2681
2682 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar context, a single line
2683 is read and returned.  In list context, reads until end-of-file is
2684 reached and returns a list of lines (however you've defined lines
2685 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2686 This is the internal function implementing the C<E<lt>EXPRE<gt>>
2687 operator, but you can use it directly.  The C<E<lt>EXPRE<gt>>
2688 operator is discussed in more detail in L<perlop/"I/O Operators">.
2689
2690     $line = <STDIN>;
2691     $line = readline(*STDIN);           # same thing
2692
2693 =item readlink EXPR
2694
2695 =item readlink
2696
2697 Returns the value of a symbolic link, if symbolic links are
2698 implemented.  If not, gives a fatal error.  If there is some system
2699 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
2700 omitted, uses C<$_>.
2701
2702 =item readpipe EXPR
2703
2704 EXPR is executed as a system command.
2705 The collected standard output of the command is returned.
2706 In scalar context, it comes back as a single (potentially
2707 multi-line) string.  In list context, returns a list of lines
2708 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
2709 This is the internal function implementing the C<qx/EXPR/>
2710 operator, but you can use it directly.  The C<qx/EXPR/>
2711 operator is discussed in more detail in L<perlop/"I/O Operators">.
2712
2713 =item recv SOCKET,SCALAR,LEN,FLAGS
2714
2715 Receives a message on a socket.  Attempts to receive LENGTH bytes of
2716 data into variable SCALAR from the specified SOCKET filehandle.
2717 Actually does a C C<recvfrom()>, so that it can return the address of the
2718 sender.  Returns the undefined value if there's an error.  SCALAR will
2719 be grown or shrunk to the length actually read.  Takes the same flags
2720 as the system call of the same name.
2721 See L<perlipc/"UDP: Message Passing"> for examples.
2722
2723 =item redo LABEL
2724
2725 =item redo
2726
2727 The C<redo> command restarts the loop block without evaluating the
2728 conditional again.  The C<continue> block, if any, is not executed.  If
2729 the LABEL is omitted, the command refers to the innermost enclosing
2730 loop.  This command is normally used by programs that want to lie to
2731 themselves about what was just input:
2732
2733     # a simpleminded Pascal comment stripper
2734     # (warning: assumes no { or } in strings)
2735     LINE: while (<STDIN>) {
2736         while (s|({.*}.*){.*}|$1 |) {}
2737         s|{.*}| |;
2738         if (s|{.*| |) {
2739             $front = $_;
2740             while (<STDIN>) {
2741                 if (/}/) {      # end of comment?
2742                     s|^|$front\{|;
2743                     redo LINE;
2744                 }
2745             }
2746         }
2747         print;
2748     }
2749
2750 See also L</continue> for an illustration of how C<last>, C<next>, and
2751 C<redo> work.
2752
2753 =item ref EXPR
2754
2755 =item ref
2756
2757 Returns a TRUE value if EXPR is a reference, FALSE otherwise.  If EXPR
2758 is not specified, C<$_> will be used.  The value returned depends on the
2759 type of thing the reference is a reference to.
2760 Builtin types include:
2761
2762     REF
2763     SCALAR
2764     ARRAY
2765     HASH
2766     CODE
2767     GLOB
2768
2769 If the referenced object has been blessed into a package, then that package
2770 name is returned instead.  You can think of C<ref()> as a C<typeof()> operator.
2771
2772     if (ref($r) eq "HASH") {
2773         print "r is a reference to a hash.\n";
2774     }
2775     if (!ref($r)) {
2776         print "r is not a reference at all.\n";
2777     }
2778
2779 See also L<perlref>.
2780
2781 =item rename OLDNAME,NEWNAME
2782
2783 Changes the name of a file.  Returns C<1> for success, C<0> otherwise.  Will
2784 not work across file system boundaries.
2785
2786 =item require EXPR
2787
2788 =item require
2789
2790 Demands some semantics specified by EXPR, or by C<$_> if EXPR is not
2791 supplied.  If EXPR is numeric, demands that the current version of Perl
2792 (C<$]> or $PERL_VERSION) be equal or greater than EXPR.
2793
2794 Otherwise, demands that a library file be included if it hasn't already
2795 been included.  The file is included via the do-FILE mechanism, which is
2796 essentially just a variety of C<eval()>.  Has semantics similar to the following
2797 subroutine:
2798
2799     sub require {
2800         my($filename) = @_;
2801         return 1 if $INC{$filename};
2802         my($realfilename,$result);
2803         ITER: {
2804             foreach $prefix (@INC) {
2805                 $realfilename = "$prefix/$filename";
2806                 if (-f $realfilename) {
2807                     $result = do $realfilename;
2808                     last ITER;
2809                 }
2810             }
2811             die "Can't find $filename in \@INC";
2812         }
2813         die $@ if $@;
2814         die "$filename did not return true value" unless $result;
2815         $INC{$filename} = $realfilename;
2816         return $result;
2817     }
2818
2819 Note that the file will not be included twice under the same specified
2820 name.  The file must return TRUE as the last statement to indicate
2821 successful execution of any initialization code, so it's customary to
2822 end such a file with "C<1;>" unless you're sure it'll return TRUE
2823 otherwise.  But it's better just to put the "C<1;>", in case you add more
2824 statements.
2825
2826 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
2827 replaces "F<::>" with "F</>" in the filename for you,
2828 to make it easy to load standard modules.  This form of loading of
2829 modules does not risk altering your namespace.
2830
2831 In other words, if you try this:
2832
2833         require Foo::Bar;       # a splendid bareword 
2834
2835 The require function will actually look for the "F<Foo/Bar.pm>" file in the 
2836 directories specified in the C<@INC> array.
2837
2838 But if you try this:
2839
2840         $class = 'Foo::Bar';
2841         require $class;         # $class is not a bareword
2842     #or
2843         require "Foo::Bar"; # not a bareword because of the ""
2844
2845 The require function will look for the "F<Foo::Bar>" file in the @INC array and 
2846 will complain about not finding "F<Foo::Bar>" there. In this case you can do:
2847
2848         eval "require $class";
2849
2850 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
2851
2852 =item reset EXPR
2853
2854 =item reset
2855
2856 Generally used in a C<continue> block at the end of a loop to clear
2857 variables and reset C<??> searches so that they work again.  The
2858 expression is interpreted as a list of single characters (hyphens
2859 allowed for ranges).  All variables and arrays beginning with one of
2860 those letters are reset to their pristine state.  If the expression is
2861 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
2862 only variables or searches in the current package.  Always returns
2863 1.  Examples:
2864
2865     reset 'X';          # reset all X variables
2866     reset 'a-z';        # reset lower case variables
2867     reset;              # just reset ?? searches
2868
2869 Resetting C<"A-Z"> is not recommended because you'll wipe out your
2870 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package variables--lexical variables
2871 are unaffected, but they clean themselves up on scope exit anyway,
2872 so you'll probably want to use them instead.  See L</my>.
2873
2874 =item return EXPR
2875
2876 =item return
2877
2878 Returns from a subroutine, C<eval()>, or C<do FILE> with the value 
2879 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
2880 context, depending on how the return value will be used, and the context
2881 may vary from one execution to the next (see C<wantarray()>).  If no EXPR
2882 is given, returns an empty list in list context, an undefined value in
2883 scalar context, or nothing in a void context.
2884
2885 (Note that in the absence of a return, a subroutine, eval, or do FILE
2886 will automatically return the value of the last expression evaluated.)
2887
2888 =item reverse LIST
2889
2890 In list context, returns a list value consisting of the elements
2891 of LIST in the opposite order.  In scalar context, concatenates the
2892 elements of LIST, and returns a string value consisting of those bytes,
2893 but in the opposite order.
2894
2895     print reverse <>;           # line tac, last line first
2896
2897     undef $/;                   # for efficiency of <>
2898     print scalar reverse <>;    # byte tac, last line tsrif
2899
2900 This operator is also handy for inverting a hash, although there are some
2901 caveats.  If a value is duplicated in the original hash, only one of those
2902 can be represented as a key in the inverted hash.  Also, this has to
2903 unwind one hash and build a whole new one, which may take some time
2904 on a large hash.
2905
2906     %by_name = reverse %by_address;     # Invert the hash
2907
2908 =item rewinddir DIRHANDLE
2909
2910 Sets the current position to the beginning of the directory for the
2911 C<readdir()> routine on DIRHANDLE.
2912
2913 =item rindex STR,SUBSTR,POSITION
2914
2915 =item rindex STR,SUBSTR
2916
2917 Works just like index except that it returns the position of the LAST
2918 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
2919 last occurrence at or before that position.
2920
2921 =item rmdir FILENAME
2922
2923 =item rmdir
2924
2925 Deletes the directory specified by FILENAME if that directory is empty.  If it
2926 succeeds it returns TRUE, otherwise it returns FALSE and sets C<$!> (errno).  If
2927 FILENAME is omitted, uses C<$_>.
2928
2929 =item s///
2930
2931 The substitution operator.  See L<perlop>.
2932
2933 =item scalar EXPR
2934
2935 Forces EXPR to be interpreted in scalar context and returns the value
2936 of EXPR.
2937
2938     @counts = ( scalar @a, scalar @b, scalar @c );
2939
2940 There is no equivalent operator to force an expression to
2941 be interpolated in list context because it's in practice never
2942 needed.  If you really wanted to do so, however, you could use
2943 the construction C<@{[ (some expression) ]}>, but usually a simple
2944 C<(some expression)> suffices.
2945
2946 =item seek FILEHANDLE,POSITION,WHENCE
2947
2948 Sets FILEHANDLE's position, just like the C<fseek()> call of C<stdio>.
2949 FILEHANDLE may be an expression whose value gives the name of the
2950 filehandle.  The values for WHENCE are C<0> to set the new position to
2951 POSITION, C<1> to set it to the current position plus POSITION, and C<2> to
2952 set it to EOF plus POSITION (typically negative).  For WHENCE you may
2953 use the constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the
2954 C<IO::Seekable> or the POSIX module.  Returns C<1> upon success, C<0> otherwise.
2955
2956 If you want to position file for C<sysread()> or C<syswrite()>, don't use
2957 C<seek()> -- buffering makes its effect on the file's system position
2958 unpredictable and non-portable.  Use C<sysseek()> instead.
2959
2960 On some systems you have to do a seek whenever you switch between reading
2961 and writing.  Amongst other things, this may have the effect of calling
2962 stdio's C<clearerr(3)>.  A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving
2963 the file position:
2964
2965     seek(TEST,0,1);
2966
2967 This is also useful for applications emulating C<tail -f>.  Once you hit
2968 EOF on your read, and then sleep for a while, you might have to stick in a
2969 seek() to reset things.  The C<seek()> doesn't change the current position,
2970 but it I<does> clear the end-of-file condition on the handle, so that the
2971 next C<E<lt>FILEE<gt>> makes Perl try again to read something.  We hope.
2972
2973 If that doesn't work (some stdios are particularly cantankerous), then
2974 you may need something more like this:
2975
2976     for (;;) {
2977         for ($curpos = tell(FILE); $_ = <FILE>; $curpos = tell(FILE)) {
2978             # search for some stuff and put it into files
2979         }
2980         sleep($for_a_while);
2981         seek(FILE, $curpos, 0);
2982     }
2983
2984 =item seekdir DIRHANDLE,POS
2985
2986 Sets the current position for the C<readdir()> routine on DIRHANDLE.  POS
2987 must be a value returned by C<telldir()>.  Has the same caveats about
2988 possible directory compaction as the corresponding system library
2989 routine.
2990
2991 =item select FILEHANDLE
2992
2993 =item select
2994
2995 Returns the currently selected filehandle.  Sets the current default
2996 filehandle for output, if FILEHANDLE is supplied.  This has two
2997 effects: first, a C<write> or a C<print> without a filehandle will
2998 default to this FILEHANDLE.  Second, references to variables related to
2999 output will refer to this output channel.  For example, if you have to
3000 set the top of form format for more than one output channel, you might
3001 do the following:
3002
3003     select(REPORT1);
3004     $^ = 'report1_top';
3005     select(REPORT2);
3006     $^ = 'report2_top';
3007
3008 FILEHANDLE may be an expression whose value gives the name of the
3009 actual filehandle.  Thus:
3010
3011     $oldfh = select(STDERR); $| = 1; select($oldfh);
3012
3013 Some programmers may prefer to think of filehandles as objects with
3014 methods, preferring to write the last example as:
3015
3016     use IO::Handle;
3017     STDERR->autoflush(1);
3018
3019 =item select RBITS,WBITS,EBITS,TIMEOUT
3020
3021 This calls the C<select(2)> system call with the bit masks specified, which
3022 can be constructed using C<fileno()> and C<vec()>, along these lines:
3023
3024     $rin = $win = $ein = '';
3025     vec($rin,fileno(STDIN),1) = 1;
3026     vec($win,fileno(STDOUT),1) = 1;
3027     $ein = $rin | $win;
3028
3029 If you want to select on many filehandles you might wish to write a
3030 subroutine:
3031
3032     sub fhbits {
3033         my(@fhlist) = split(' ',$_[0]);
3034         my($bits);
3035         for (@fhlist) {
3036             vec($bits,fileno($_),1) = 1;
3037         }
3038         $bits;
3039     }
3040     $rin = fhbits('STDIN TTY SOCK');
3041
3042 The usual idiom is:
3043
3044     ($nfound,$timeleft) =
3045       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
3046
3047 or to block until something becomes ready just do this
3048
3049     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
3050
3051 Most systems do not bother to return anything useful in C<$timeleft>, so
3052 calling select() in scalar context just returns C<$nfound>.
3053
3054 Any of the bit masks can also be undef.  The timeout, if specified, is
3055 in seconds, which may be fractional.  Note: not all implementations are
3056 capable of returning theC<$timeleft>.  If not, they always return
3057 C<$timeleft> equal to the supplied C<$timeout>.
3058
3059 You can effect a sleep of 250 milliseconds this way:
3060
3061     select(undef, undef, undef, 0.25);
3062
3063 B<WARNING>: One should not attempt to mix buffered I/O (like C<read()>
3064 or E<lt>FHE<gt>) with C<select()>, except as permitted by POSIX, and even
3065 then only on POSIX systems.  You have to use C<sysread()> instead.
3066
3067 =item semctl ID,SEMNUM,CMD,ARG
3068
3069 Calls the System V IPC function C<semctl>.  You'll probably have to say
3070
3071     use IPC::SysV;
3072
3073 first to get the correct constant definitions.  If CMD is IPC_STAT or
3074 GETALL, then ARG must be a variable which will hold the returned
3075 semid_ds structure or semaphore value array.  Returns like C<ioctl>: the
3076 undefined value for error, "C<0> but true" for zero, or the actual return
3077 value otherwise.  See also C<IPC::SysV> and C<IPC::Semaphore> documentation.
3078
3079 =item semget KEY,NSEMS,FLAGS
3080
3081 Calls the System V IPC function semget.  Returns the semaphore id, or
3082 the undefined value if there is an error.  See also C<IPC::SysV> and
3083 C<IPC::SysV::Semaphore> documentation.
3084
3085 =item semop KEY,OPSTRING
3086
3087 Calls the System V IPC function semop to perform semaphore operations
3088 such as signaling and waiting.  OPSTRING must be a packed array of
3089 semop structures.  Each semop structure can be generated with
3090 C<pack("sss", $semnum, $semop, $semflag)>.  The number of semaphore
3091 operations is implied by the length of OPSTRING.  Returns TRUE if
3092 successful, or FALSE if there is an error.  As an example, the
3093 following code waits on semaphore C<$semnum> of semaphore id C<$semid>:
3094
3095     $semop = pack("sss", $semnum, -1, 0);
3096     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
3097
3098 To signal the semaphore, replace C<-1> with C<1>.  See also C<IPC::SysV>
3099 and C<IPC::SysV::Semaphore> documentation.
3100
3101 =item send SOCKET,MSG,FLAGS,TO
3102
3103 =item send SOCKET,MSG,FLAGS
3104
3105 Sends a message on a socket.  Takes the same flags as the system call
3106 of the same name.  On unconnected sockets you must specify a
3107 destination to send TO, in which case it does a C C<sendto()>.  Returns
3108 the number of characters sent, or the undefined value if there is an
3109 error.
3110 See L<perlipc/"UDP: Message Passing"> for examples.
3111
3112 =item setpgrp PID,PGRP
3113
3114 Sets the current process group for the specified PID, C<0> for the current
3115 process.  Will produce a fatal error if used on a machine that doesn't
3116 implement C<setpgrp(2)>.  If the arguments are omitted, it defaults to
3117 C<0,0>.  Note that the POSIX version of C<setpgrp()> does not accept any
3118 arguments, so only setpgrp C<0,0> is portable.
3119
3120 =item setpriority WHICH,WHO,PRIORITY
3121
3122 Sets the current priority for a process, a process group, or a user.
3123 (See C<setpriority(2)>.)  Will produce a fatal error if used on a machine
3124 that doesn't implement C<setpriority(2)>.
3125
3126 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
3127
3128 Sets the socket option requested.  Returns undefined if there is an
3129 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
3130 argument.
3131
3132 =item shift ARRAY
3133
3134 =item shift
3135
3136 Shifts the first value of the array off and returns it, shortening the
3137 array by 1 and moving everything down.  If there are no elements in the
3138 array, returns the undefined value.  If ARRAY is omitted, shifts the
3139 C<@_> array within the lexical scope of subroutines and formats, and the
3140 C<@ARGV> array at file scopes or within the lexical scopes established by
3141 the C<eval ''>, C<BEGIN {}>, C<END {}>, and C<INIT {}> constructs.
3142 See also C<unshift()>, C<push()>, and C<pop()>.  C<Shift()> and C<unshift()> do the
3143 same thing to the left end of an array that C<pop()> and C<push()> do to the
3144 right end.
3145
3146 =item shmctl ID,CMD,ARG
3147
3148 Calls the System V IPC function shmctl.  You'll probably have to say
3149
3150     use IPC::SysV;
3151
3152 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3153 then ARG must be a variable which will hold the returned C<shmid_ds>
3154 structure.  Returns like ioctl: the undefined value for error, "C<0> but
3155 true" for zero, or the actual return value otherwise.
3156 See also C<IPC::SysV> documentation.
3157
3158 =item shmget KEY,SIZE,FLAGS
3159
3160 Calls the System V IPC function shmget.  Returns the shared memory
3161 segment id, or the undefined value if there is an error.
3162 See also C<IPC::SysV> documentation.
3163
3164 =item shmread ID,VAR,POS,SIZE
3165
3166 =item shmwrite ID,STRING,POS,SIZE
3167
3168 Reads or writes the System V shared memory segment ID starting at
3169 position POS for size SIZE by attaching to it, copying in/out, and
3170 detaching from it.  When reading, VAR must be a variable that will
3171 hold the data read.  When writing, if STRING is too long, only SIZE
3172 bytes are used; if STRING is too short, nulls are written to fill out
3173 SIZE bytes.  Return TRUE if successful, or FALSE if there is an error.
3174 See also C<IPC::SysV> documentation.
3175
3176 =item shutdown SOCKET,HOW
3177
3178 Shuts down a socket connection in the manner indicated by HOW, which
3179 has the same interpretation as in the system call of the same name.
3180
3181     shutdown(SOCKET, 0);                # I/we have stopped reading data
3182     shutdown(SOCKET, 1);                # I/we have stopped writing data
3183     shutdown(SOCKET, 2);                # I/we have stopped using this socket
3184
3185 This is useful with sockets when you want to tell the other
3186 side you're done writing but not done reading, or vice versa.
3187 It's also a more insistent form of close because it also 
3188 disables the filedescriptor in any forked copies in other
3189 processes.
3190
3191 =item sin EXPR
3192
3193 =item sin
3194
3195 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
3196 returns sine of C<$_>.
3197
3198 For the inverse sine operation, you may use the C<POSIX::asin()>
3199 function, or use this relation:
3200
3201     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
3202
3203 =item sleep EXPR
3204
3205 =item sleep
3206
3207 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
3208 May be interrupted if the process receives a signal such as C<SIGALRM>.
3209 Returns the number of seconds actually slept.  You probably cannot
3210 mix C<alarm()> and C<sleep()> calls, because C<sleep()> is often implemented
3211 using C<alarm()>.
3212
3213 On some older systems, it may sleep up to a full second less than what
3214 you requested, depending on how it counts seconds.  Most modern systems
3215 always sleep the full amount.  They may appear to sleep longer than that,
3216 however, because your process might not be scheduled right away in a
3217 busy multitasking system.
3218
3219 For delays of finer granularity than one second, you may use Perl's
3220 C<syscall()> interface to access C<setitimer(2)> if your system supports it,
3221 or else see L</select()> above.
3222
3223 See also the POSIX module's C<sigpause()> function.
3224
3225 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
3226
3227 Opens a socket of the specified kind and attaches it to filehandle
3228 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for the
3229 system call of the same name.  You should "C<use Socket;>" first to get
3230 the proper definitions imported.  See the example in L<perlipc/"Sockets: Client/Server Communication">.
3231
3232 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
3233
3234 Creates an unnamed pair of sockets in the specified domain, of the
3235 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
3236 for the system call of the same name.  If unimplemented, yields a fatal
3237 error.  Returns TRUE if successful.
3238
3239 Some systems defined C<pipe()> in terms of C<socketpair>, in which a call
3240 to C<pipe(Rdr, Wtr)> is essentially:
3241
3242     use Socket;
3243     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
3244     shutdown(Rdr, 1);        # no more writing for reader
3245     shutdown(Wtr, 0);        # no more reading for writer
3246
3247 See L<perlipc> for an example of socketpair use.
3248
3249 =item sort SUBNAME LIST
3250
3251 =item sort BLOCK LIST
3252
3253 =item sort LIST
3254
3255 Sorts the LIST and returns the sorted list value.  If SUBNAME or BLOCK
3256 is omitted, C<sort>s in standard string comparison order.  If SUBNAME is
3257 specified, it gives the name of a subroutine that returns an integer
3258 less than, equal to, or greater than C<0>, depending on how the elements
3259 of the array are to be ordered.  (The C<E<lt>=E<gt>> and C<cmp>
3260 operators are extremely useful in such routines.)  SUBNAME may be a
3261 scalar variable name (unsubscripted), in which case the value provides
3262 the name of (or a reference to) the actual subroutine to use.  In place
3263 of a SUBNAME, you can provide a BLOCK as an anonymous, in-line sort
3264 subroutine.
3265
3266 In the interests of efficiency the normal calling code for subroutines is
3267 bypassed, with the following effects: the subroutine may not be a
3268 recursive subroutine, and the two elements to be compared are passed into
3269 the subroutine not via C<@_> but as the package global variables C<$a> and
3270 C<$b> (see example below).  They are passed by reference, so don't
3271 modify C<$a> and C<$b>.  And don't try to declare them as lexicals either.
3272
3273 You also cannot exit out of the sort block or subroutine using any of the
3274 loop control operators described in L<perlsyn> or with C<goto()>.
3275
3276 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
3277 current collation locale.  See L<perllocale>.
3278
3279 Examples:
3280
3281     # sort lexically
3282     @articles = sort @files;
3283
3284     # same thing, but with explicit sort routine
3285     @articles = sort {$a cmp $b} @files;
3286
3287     # now case-insensitively
3288     @articles = sort {uc($a) cmp uc($b)} @files;
3289
3290     # same thing in reversed order
3291     @articles = sort {$b cmp $a} @files;
3292
3293     # sort numerically ascending
3294     @articles = sort {$a <=> $b} @files;
3295
3296     # sort numerically descending
3297     @articles = sort {$b <=> $a} @files;
3298
3299     # sort using explicit subroutine name
3300     sub byage {
3301         $age{$a} <=> $age{$b};  # presuming numeric
3302     }
3303     @sortedclass = sort byage @class;
3304
3305     # this sorts the %age hash by value instead of key
3306     # using an in-line function
3307     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
3308
3309     sub backwards { $b cmp $a; }
3310     @harry = ('dog','cat','x','Cain','Abel');
3311     @george = ('gone','chased','yz','Punished','Axed');
3312     print sort @harry;
3313             # prints AbelCaincatdogx
3314     print sort backwards @harry;
3315             # prints xdogcatCainAbel
3316     print sort @george, 'to', @harry;
3317             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
3318
3319     # inefficiently sort by descending numeric compare using
3320     # the first integer after the first = sign, or the
3321     # whole record case-insensitively otherwise
3322
3323     @new = sort {
3324         ($b =~ /=(\d+)/)[0] <=> ($a =~ /=(\d+)/)[0]
3325                             ||
3326                     uc($a)  cmp  uc($b)
3327     } @old;
3328
3329     # same thing, but much more efficiently;
3330     # we'll build auxiliary indices instead
3331     # for speed
3332     @nums = @caps = ();
3333     for (@old) {
3334         push @nums, /=(\d+)/;
3335         push @caps, uc($_);
3336     }
3337
3338     @new = @old[ sort {
3339                         $nums[$b] <=> $nums[$a]
3340                                  ||
3341                         $caps[$a] cmp $caps[$b]
3342                        } 0..$#old
3343                ];
3344
3345     # same thing using a Schwartzian Transform (no temps)
3346     @new = map { $_->[0] }
3347         sort { $b->[1] <=> $a->[1]
3348                         ||
3349                $a->[2] cmp $b->[2]
3350         } map { [$_, /=(\d+)/, uc($_)] } @old;
3351
3352 If you're using strict, you I<MUST NOT> declare C<$a>
3353 and C<$b> as lexicals.  They are package globals.  That means
3354 if you're in the C<main> package, it's
3355
3356     @articles = sort {$main::b <=> $main::a} @files;
3357
3358 or just
3359
3360     @articles = sort {$::b <=> $::a} @files;
3361
3362 but if you're in the C<FooPack> package, it's
3363
3364     @articles = sort {$FooPack::b <=> $FooPack::a} @files;
3365
3366 The comparison function is required to behave.  If it returns
3367 inconsistent results (sometimes saying C<$x[1]> is less than C<$x[2]> and
3368 sometimes saying the opposite, for example) the results are not
3369 well-defined.
3370
3371 =item splice ARRAY,OFFSET,LENGTH,LIST
3372
3373 =item splice ARRAY,OFFSET,LENGTH
3374
3375 =item splice ARRAY,OFFSET
3376
3377 Removes the elements designated by OFFSET and LENGTH from an array, and
3378 replaces them with the elements of LIST, if any.  In list context,
3379 returns the elements removed from the array.  In scalar context,
3380 returns the last element removed, or C<undef> if no elements are
3381 removed.  The array grows or shrinks as necessary.
3382 If OFFSET is negative then it start that far from the end of the array.
3383 If LENGTH is omitted, removes everything from OFFSET onward.
3384 If LENGTH is negative, leave that many elements off the end of the array.
3385 The following equivalences hold (assuming C<$[ == 0>):
3386
3387     push(@a,$x,$y)      splice(@a,@a,0,$x,$y)
3388     pop(@a)             splice(@a,-1)
3389     shift(@a)           splice(@a,0,1)
3390     unshift(@a,$x,$y)   splice(@a,0,0,$x,$y)
3391     $a[$x] = $y         splice(@a,$x,1,$y)
3392
3393 Example, assuming array lengths are passed before arrays:
3394
3395     sub aeq {   # compare two list values
3396         my(@a) = splice(@_,0,shift);
3397         my(@b) = splice(@_,0,shift);
3398         return 0 unless @a == @b;       # same len?
3399         while (@a) {
3400             return 0 if pop(@a) ne pop(@b);
3401         }
3402         return 1;
3403     }
3404     if (&aeq($len,@foo[1..$len],0+@bar,@bar)) { ... }
3405
3406 =item split /PATTERN/,EXPR,LIMIT
3407
3408 =item split /PATTERN/,EXPR
3409
3410 =item split /PATTERN/
3411
3412 =item split
3413
3414 Splits a string into an array of strings, and returns it.  By default,
3415 empty leading fields are preserved, and empty trailing ones are deleted.
3416
3417 If not in list context, returns the number of fields found and splits into
3418 the C<@_> array.  (In list context, you can force the split into C<@_> by
3419 using C<??> as the pattern delimiters, but it still returns the list
3420 value.)  The use of implicit split to C<@_> is deprecated, however, because
3421 it clobbers your subroutine arguments.
3422
3423 If EXPR is omitted, splits the C<$_> string.  If PATTERN is also omitted,
3424 splits on whitespace (after skipping any leading whitespace).  Anything
3425 matching PATTERN is taken to be a delimiter separating the fields.  (Note
3426 that the delimiter may be longer than one character.)
3427
3428 If LIMIT is specified and positive, splits into no more than that
3429 many fields (though it may split into fewer).  If LIMIT is unspecified
3430 or zero, trailing null fields are stripped (which potential users
3431 of C<pop()> would do well to remember).  If LIMIT is negative, it is
3432 treated as if an arbitrarily large LIMIT had been specified.
3433
3434 A pattern matching the null string (not to be confused with
3435 a null pattern C<//>, which is just one member of the set of patterns
3436 matching a null string) will split the value of EXPR into separate
3437 characters at each point it matches that way.  For example:
3438
3439     print join(':', split(/ */, 'hi there'));
3440
3441 produces the output 'h:i:t:h:e:r:e'.
3442
3443 The LIMIT parameter can be used to split a line partially
3444
3445     ($login, $passwd, $remainder) = split(/:/, $_, 3);
3446
3447 When assigning to a list, if LIMIT is omitted, Perl supplies a LIMIT
3448 one larger than the number of variables in the list, to avoid
3449 unnecessary work.  For the list above LIMIT would have been 4 by
3450 default.  In time critical applications it behooves you not to split
3451 into more fields than you really need.
3452
3453 If the PATTERN contains parentheses, additional array elements are
3454 created from each matching substring in the delimiter.
3455
3456     split(/([,-])/, "1-10,20", 3);
3457
3458 produces the list value
3459
3460     (1, '-', 10, ',', 20)
3461
3462 If you had the entire header of a normal Unix email message in C<$header>,
3463 you could split it up into fields and their values this way:
3464
3465     $header =~ s/\n\s+/ /g;  # fix continuation lines
3466     %hdrs   =  (UNIX_FROM => split /^(\S*?):\s*/m, $header);
3467
3468 The pattern C</PATTERN/> may be replaced with an expression to specify
3469 patterns that vary at runtime.  (To do runtime compilation only once,
3470 use C</$variable/o>.)
3471
3472 As a special case, specifying a PATTERN of space (C<' '>) will split on
3473 white space just as C<split> with no arguments does.  Thus, C<split(' ')> can
3474 be used to emulate B<awk>'s default behavior, whereas C<split(/ /)>
3475 will give you as many null initial fields as there are leading spaces.
3476 A C<split> on C</\s+/> is like a C<split(' ')> except that any leading
3477 whitespace produces a null first field.  A C<split> with no arguments
3478 really does a C<split(' ', $_)> internally.
3479
3480 Example:
3481
3482     open(PASSWD, '/etc/passwd');
3483     while (<PASSWD>) {
3484         ($login, $passwd, $uid, $gid, $gcos,$home, $shell) = split(/:/);
3485         #...
3486     }
3487
3488 (Note that C<$shell> above will still have a newline on it.  See L</chop>,
3489 L</chomp>, and L</join>.)
3490
3491 =item sprintf FORMAT, LIST
3492
3493 Returns a string formatted by the usual C<printf> conventions of the
3494 C library function C<sprintf()>.  See L<sprintf(3)> or L<printf(3)>
3495 on your system for an explanation of the general principles.
3496
3497 Perl does its own C<sprintf()> formatting -- it emulates the C
3498 function C<sprintf()>, but it doesn't use it (except for floating-point
3499 numbers, and even then only the standard modifiers are allowed).  As a
3500 result, any non-standard extensions in your local C<sprintf()> are not
3501 available from Perl.
3502
3503 Perl's C<sprintf()> permits the following universally-known conversions:
3504
3505    %%   a percent sign
3506    %c   a character with the given number
3507    %s   a string
3508    %d   a signed integer, in decimal
3509    %u   an unsigned integer, in decimal
3510    %o   an unsigned integer, in octal
3511    %x   an unsigned integer, in hexadecimal
3512    %e   a floating-point number, in scientific notation
3513    %f   a floating-point number, in fixed decimal notation
3514    %g   a floating-point number, in %e or %f notation
3515
3516 In addition, Perl permits the following widely-supported conversions:
3517
3518    %X   like %x, but using upper-case letters
3519    %E   like %e, but using an upper-case "E"
3520    %G   like %g, but with an upper-case "E" (if applicable)
3521    %p   a pointer (outputs the Perl value's address in hexadecimal)
3522    %n   special: *stores* the number of characters output so far
3523         into the next variable in the parameter list 
3524
3525 Finally, for backward (and we do mean "backward") compatibility, Perl
3526 permits these unnecessary but widely-supported conversions:
3527
3528    %i   a synonym for %d
3529    %D   a synonym for %ld
3530    %U   a synonym for %lu
3531    %O   a synonym for %lo
3532    %F   a synonym for %f
3533
3534 Perl permits the following universally-known flags between the C<%>
3535 and the conversion letter:
3536
3537    space   prefix positive number with a space
3538    +       prefix positive number with a plus sign
3539    -       left-justify within the field
3540    0       use zeros, not spaces, to right-justify
3541    #       prefix non-zero octal with "0", non-zero hex with "0x"
3542    number  minimum field width
3543    .number "precision": digits after decimal point for floating-point,
3544            max length for string, minimum length for integer
3545    l       interpret integer as C type "long" or "unsigned long"
3546    h       interpret integer as C type "short" or "unsigned short"
3547
3548 There is also one Perl-specific flag:
3549
3550    V       interpret integer as Perl's standard integer type
3551
3552 Where a number would appear in the flags, an asterisk ("C<*>") may be
3553 used instead, in which case Perl uses the next item in the parameter
3554 list as the given number (that is, as the field width or precision).
3555 If a field width obtained through "C<*>" is negative, it has the same
3556 effect as the "C<->" flag: left-justification.
3557
3558 If C<use locale> is in effect, the character used for the decimal
3559 point in formatted real numbers is affected by the LC_NUMERIC locale.
3560 See L<perllocale>.
3561
3562 =item sqrt EXPR
3563
3564 =item sqrt
3565
3566 Return the square root of EXPR.  If EXPR is omitted, returns square
3567 root of C<$_>.
3568
3569 =item srand EXPR
3570
3571 =item srand
3572
3573 Sets the random number seed for the C<rand> operator.  If EXPR is
3574 omitted, uses a semi-random value based on the current time and process
3575 ID, among other things.  In versions of Perl prior to 5.004 the default
3576 seed was just the current C<time()>.  This isn't a particularly good seed,
3577 so many old programs supply their own seed value (often C<time ^ $$> or
3578 C<time ^ ($$ + ($$ E<lt>E<lt> 15))>), but that isn't necessary any more.
3579
3580 In fact, it's usually not necessary to call C<srand()> at all, because if
3581 it is not called explicitly, it is called implicitly at the first use of
3582 the C<rand> operator.  However, this was not the case in version of Perl
3583 before 5.004, so if your script will run under older Perl versions, it
3584 should call C<srand()>.
3585
3586 Note that you need something much more random than the default seed for
3587 cryptographic purposes.  Checksumming the compressed output of one or more
3588 rapidly changing operating system status programs is the usual method.  For
3589 example:
3590
3591     srand (time ^ $$ ^ unpack "%L*", `ps axww | gzip`);
3592
3593 If you're particularly concerned with this, see the C<Math::TrulyRandom>
3594 module in CPAN.
3595
3596 Do I<not> call C<srand()> multiple times in your program unless you know
3597 exactly what you're doing and why you're doing it.  The point of the
3598 function is to "seed" the C<rand()> function so that C<rand()> can produce
3599 a different sequence each time you run your program.  Just do it once at the
3600 top of your program, or you I<won't> get random numbers out of C<rand()>!
3601
3602 Frequently called programs (like CGI scripts) that simply use
3603
3604     time ^ $$
3605
3606 for a seed can fall prey to the mathematical property that
3607
3608     a^b == (a+1)^(b+1)
3609
3610 one-third of the time.  So don't do that.
3611
3612 =item stat FILEHANDLE
3613
3614 =item stat EXPR
3615
3616 =item stat
3617
3618 Returns a 13-element list giving the status info for a file, either
3619 the file opened via FILEHANDLE, or named by EXPR.  If EXPR is omitted,
3620 it stats C<$_>.  Returns a null list if the stat fails.  Typically used
3621 as follows:
3622
3623     ($dev,$ino,$mode,$nlink,$uid,$gid,$rdev,$size,
3624        $atime,$mtime,$ctime,$blksize,$blocks)
3625            = stat($filename);
3626
3627 Not all fields are supported on all filesystem types.  Here are the
3628 meaning of the fields:
3629
3630   0 dev      device number of filesystem
3631   1 ino      inode number
3632   2 mode     file mode  (type and permissions)
3633   3 nlink    number of (hard) links to the file
3634   4 uid      numeric user ID of file's owner
3635   5 gid      numeric group ID of file's owner
3636   6 rdev     the device identifier (special files only)
3637   7 size     total size of file, in bytes
3638   8 atime    last access time since the epoch
3639   9 mtime    last modify time since the epoch
3640  10 ctime    inode change time (NOT creation time!) since the epoch
3641  11 blksize  preferred block size for file system I/O
3642  12 blocks   actual number of blocks allocated
3643
3644 (The epoch was at 00:00 January 1, 1970 GMT.)
3645
3646 If stat is passed the special filehandle consisting of an underline, no
3647 stat is done, but the current contents of the stat structure from the
3648 last stat or filetest are returned.  Example:
3649
3650     if (-x $file && (($d) = stat(_)) && $d < 0) {
3651         print "$file is executable NFS file\n";
3652     }
3653
3654 (This works on machines only for which the device number is negative under NFS.)
3655
3656 In scalar context, C<stat> returns a boolean value indicating success
3657 or failure, and, if successful, sets the information associated with
3658 the special filehandle C<_>.
3659
3660 =item study SCALAR
3661
3662 =item study
3663
3664 Takes extra time to study SCALAR (C<$_> if unspecified) in anticipation of
3665 doing many pattern matches on the string before it is next modified.
3666 This may or may not save time, depending on the nature and number of
3667 patterns you are searching on, and on the distribution of character
3668 frequencies in the string to be searched -- you probably want to compare
3669 run times with and without it to see which runs faster.  Those loops
3670 which scan for many short constant strings (including the constant
3671 parts of more complex patterns) will benefit most.  You may have only
3672 one C<study> active at a time -- if you study a different scalar the first
3673 is "unstudied".  (The way C<study> works is this: a linked list of every
3674 character in the string to be searched is made, so we know, for
3675 example, where all the C<'k'> characters are.  From each search string,
3676 the rarest character is selected, based on some static frequency tables
3677 constructed from some C programs and English text.  Only those places
3678 that contain this "rarest" character are examined.)
3679
3680 For example, here is a loop that inserts index producing entries
3681 before any line containing a certain pattern:
3682
3683     while (<>) {
3684         study;
3685         print ".IX foo\n" if /\bfoo\b/;
3686         print ".IX bar\n" if /\bbar\b/;
3687         print ".IX blurfl\n" if /\bblurfl\b/;
3688         # ...
3689         print;
3690     }
3691
3692 In searching for C</\bfoo\b/>, only those locations in C<$_> that contain C<"f">
3693 will be looked at, because C<"f"> is rarer than C<"o">.  In general, this is
3694 a big win except in pathological cases.  The only question is whether
3695 it saves you more time than it took to build the linked list in the
3696 first place.
3697
3698 Note that if you have to look for strings that you don't know till
3699 runtime, you can build an entire loop as a string and C<eval> that to
3700 avoid recompiling all your patterns all the time.  Together with
3701 undefining C<$/> to input entire files as one record, this can be very
3702 fast, often faster than specialized programs like C<fgrep(1)>.  The following
3703 scans a list of files (C<@files>) for a list of words (C<@words>), and prints
3704 out the names of those files that contain a match:
3705
3706     $search = 'while (<>) { study;';
3707     foreach $word (@words) {
3708         $search .= "++\$seen{\$ARGV} if /\\b$word\\b/;\n";
3709     }
3710     $search .= "}";
3711     @ARGV = @files;
3712     undef $/;
3713     eval $search;               # this screams
3714     $/ = "\n";          # put back to normal input delimiter
3715     foreach $file (sort keys(%seen)) {
3716         print $file, "\n";
3717     }
3718
3719 =item sub BLOCK
3720
3721 =item sub NAME
3722
3723 =item sub NAME BLOCK
3724
3725 This is subroutine definition, not a real function I<per se>.  With just a
3726 NAME (and possibly prototypes), it's just a forward declaration.  Without
3727 a NAME, it's an anonymous function declaration, and does actually return a
3728 value: the CODE ref of the closure you just created.  See L<perlsub> and
3729 L<perlref> for details.
3730
3731 =item substr EXPR,OFFSET,LEN,REPLACEMENT
3732
3733 =item substr EXPR,OFFSET,LEN
3734
3735 =item substr EXPR,OFFSET
3736
3737 Extracts a substring out of EXPR and returns it.  First character is at
3738 offset C<0>, or whatever you've set C<$[> to (but don't do that).
3739 If OFFSET is negative (or more precisely, less than C<$[>), starts
3740 that far from the end of the string.  If LEN is omitted, returns
3741 everything to the end of the string.  If LEN is negative, leaves that
3742 many characters off the end of the string.
3743
3744 If you specify a substring that is partly outside the string, the part
3745 within the string is returned.    If the substring is totally outside
3746 the string a warning is produced.
3747
3748 You can use the C<substr()> function
3749 as an lvalue, in which case EXPR must be an lvalue.  If you assign
3750 something shorter than LEN, the string will shrink, and if you assign
3751 something longer than LEN, the string will grow to accommodate it.  To
3752 keep the string the same length you may need to pad or chop your value
3753 using C<sprintf()>.
3754
3755 An alternative to using C<substr()> as an lvalue is to specify the
3756 replacement string as the 4th argument.  This allows you to replace
3757 parts of the EXPR and return what was there before in one operation.
3758
3759 =item symlink OLDFILE,NEWFILE
3760
3761 Creates a new filename symbolically linked to the old filename.
3762 Returns C<1> for success, C<0> otherwise.  On systems that don't support
3763 symbolic links, produces a fatal error at run time.  To check for that,
3764 use eval:
3765
3766     $symlink_exists =  eval { symlink("",""); 1 };
3767
3768 =item syscall LIST
3769
3770 Calls the system call specified as the first element of the list,
3771 passing the remaining elements as arguments to the system call.  If
3772 unimplemented, produces a fatal error.  The arguments are interpreted
3773 as follows: if a given argument is numeric, the argument is passed as
3774 an int.  If not, the pointer to the string value is passed.  You are
3775 responsible to make sure a string is pre-extended long enough to
3776 receive any result that might be written into a string.  You can't use a
3777 string literal (or other read-only string) as an argument to C<syscall()>
3778 because Perl has to assume that any string pointer might be written
3779 through.  If your
3780 integer arguments are not literals and have never been interpreted in a
3781 numeric context, you may need to add C<0> to them to force them to look
3782 like numbers.  This emulates the C<syswrite()> function (or vice versa):
3783
3784     require 'syscall.ph';               # may need to run h2ph
3785     $s = "hi there\n";
3786     syscall(&SYS_write, fileno(STDOUT), $s, length $s);
3787
3788 Note that Perl supports passing of up to only 14 arguments to your system call,
3789 which in practice should usually suffice.
3790
3791 Syscall returns whatever value returned by the system call it calls.
3792 If the system call fails, C<syscall> returns C<-1> and sets C<$!> (errno).
3793 Note that some system calls can legitimately return C<-1>.  The proper
3794 way to handle such calls is to assign C<$!=0;> before the call and
3795 check the value of C<$!> if syscall returns C<-1>.
3796
3797 There's a problem with C<syscall(&SYS_pipe)>: it returns the file
3798 number of the read end of the pipe it creates.  There is no way
3799 to retrieve the file number of the other end.  You can avoid this 
3800 problem by using C<pipe> instead.
3801
3802 =item sysopen FILEHANDLE,FILENAME,MODE
3803
3804 =item sysopen FILEHANDLE,FILENAME,MODE,PERMS
3805
3806 Opens the file whose filename is given by FILENAME, and associates it
3807 with FILEHANDLE.  If FILEHANDLE is an expression, its value is used as
3808 the name of the real filehandle wanted.  This function calls the
3809 underlying operating system's C<open> function with the parameters
3810 FILENAME, MODE, PERMS.
3811
3812 The possible values and flag bits of the MODE parameter are
3813 system-dependent; they are available via the standard module C<Fcntl>.
3814 However, for historical reasons, some values are universal: zero means
3815 read-only, one means write-only, and two means read/write.
3816
3817 If the file named by FILENAME does not exist and the C<open> call creates
3818 it (typically because MODE includes the C<O_CREAT> flag), then the value of
3819 PERMS specifies the permissions of the newly created file.  If you omit
3820 the PERMS argument to C<sysopen>, Perl uses the octal value C<0666>.
3821 These permission values need to be in octal, and are modified by your
3822 process's current C<umask>.  The C<umask> value is a number representing
3823 disabled permissions bits--if your C<umask> were C<027> (group can't write;
3824 others can't read, write, or execute), then passing C<sysopen> C<0666> would
3825 create a file with mode C<0640> (C<0666 &~ 027> is C<0640>).
3826
3827 If you find this C<umask> talk confusing, here's some advice: supply a
3828 creation mode of C<0666> for regular files and one of C<0777> for directories
3829 (in C<mkdir>) and executable files.  This gives users the freedom of
3830 choice: if they want protected files, they might choose process umasks
3831 of C<022>, C<027>, or even the particularly antisocial mask of C<077>.  Programs
3832 should rarely if ever make policy decisions better left to the user.
3833 The exception to this is when writing files that should be kept private:
3834 mail files, web browser cookies, I<.rhosts> files, and so on.  In short,
3835 seldom if ever use C<0644> as argument to C<sysopen> because that takes
3836 away the user's option to have a more permissive umask.  Better to omit it.
3837
3838 The C<IO::File> module provides a more object-oriented approach, if you're
3839 into that kind of thing.
3840
3841 =item sysread FILEHANDLE,SCALAR,LENGTH,OFFSET
3842
3843 =item sysread FILEHANDLE,SCALAR,LENGTH
3844
3845 Attempts to read LENGTH bytes of data into variable SCALAR from the
3846 specified FILEHANDLE, using the system call C<read(2)>.  It bypasses
3847 stdio, so mixing this with other kinds of reads, C<print()>, C<write()>,
3848 C<seek()>, or C<tell()> can cause confusion because stdio usually buffers
3849 data.  Returns the number of bytes actually read, C<0> at end of file,
3850 or undef if there was an error.  SCALAR will be grown or shrunk so that
3851 the last byte actually read is the last byte of the scalar after the read.
3852
3853 An OFFSET may be specified to place the read data at some place in the
3854 string other than the beginning.  A negative OFFSET specifies
3855 placement at that many bytes counting backwards from the end of the
3856 string.  A positive OFFSET greater than the length of SCALAR results
3857 in the string being padded to the required size with C<"\0"> bytes before
3858 the result of the read is appended.
3859
3860 =item sysseek FILEHANDLE,POSITION,WHENCE
3861
3862 Sets FILEHANDLE's system position using the system call C<lseek(2)>.  It
3863 bypasses stdio, so mixing this with reads (other than C<sysread()>),
3864 C<print()>, C<write()>, C<seek()>, or C<tell()> may cause confusion.  FILEHANDLE may
3865 be an expression whose value gives the name of the filehandle.  The
3866 values for WHENCE are C<0> to set the new position to POSITION, C<1> to set
3867 the it to the current position plus POSITION, and C<2> to set it to EOF
3868 plus POSITION (typically negative).  For WHENCE, you may use the
3869 constants C<SEEK_SET>, C<SEEK_CUR>, and C<SEEK_END> from either the C<IO::Seekable>
3870 or the POSIX module.
3871
3872 Returns the new position, or the undefined value on failure.  A position
3873 of zero is returned as the string "C<0> but true"; thus C<sysseek()> returns
3874 TRUE on success and FALSE on failure, yet you can still easily determine
3875 the new position.
3876
3877 =item system LIST
3878
3879 =item system PROGRAM LIST
3880
3881 Does exactly the same thing as "C<exec LIST>" except that a fork is done
3882 first, and the parent process waits for the child process to complete.
3883 Note that argument processing varies depending on the number of
3884 arguments.  If there is more than one argument in LIST, or if LIST is
3885 an array with more than one value, starts the program given by the
3886 first element of the list with arguments given by the rest of the list.
3887 If there is only one scalar argument, the argument is
3888 checked for shell metacharacters, and if there are any, the entire
3889 argument is passed to the system's command shell for parsing (this is
3890 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
3891 there are no shell metacharacters in the argument, it is split into
3892 words and passed directly to C<execvp()>, which is more efficient.
3893
3894 The return value is the exit status of the program as
3895 returned by the C<wait()> call.  To get the actual exit value divide by
3896 256.  See also L</exec>.  This is I<NOT> what you want to use to capture
3897 the output from a command, for that you should use merely backticks or
3898 C<qx//>, as described in L<perlop/"`STRING`">.
3899
3900 Like C<exec()>, C<system()> allows you to lie to a program about its name if
3901 you use the "C<system PROGRAM LIST>" syntax.  Again, see L</exec>.
3902
3903 Because C<system()> and backticks block C<SIGINT> and C<SIGQUIT>, killing the
3904 program they're running doesn't actually interrupt your program.
3905
3906     @args = ("command", "arg1", "arg2");
3907     system(@args) == 0
3908          or die "system @args failed: $?"
3909
3910 You can check all the failure possibilities by inspecting
3911 C<$?> like this:
3912
3913     $exit_value  = $? >> 8;
3914     $signal_num  = $? & 127;
3915     $dumped_core = $? & 128;
3916
3917 When the arguments get executed via the system shell, results
3918 and return codes will be subject to its quirks and capabilities.
3919 See L<perlop/"`STRING`"> and L</exec> for details.
3920
3921 =item syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET
3922
3923 =item syswrite FILEHANDLE,SCALAR,LENGTH
3924
3925 Attempts to write LENGTH bytes of data from variable SCALAR to the
3926 specified FILEHANDLE, using the system call C<write(2)>.  It bypasses
3927 stdio, so mixing this with reads (other than C<sysread())>, C<print()>,
3928 C<write()>, C<seek()>, or C<tell()> may cause confusion because stdio usually
3929 buffers data.  Returns the number of bytes actually written, or C<undef>
3930 if there was an error.  If the LENGTH is greater than the available
3931 data in the SCALAR after the OFFSET, only as much data as is available
3932 will be written.
3933
3934 An OFFSET may be specified to write the data from some part of the
3935 string other than the beginning.  A negative OFFSET specifies writing
3936 that many bytes counting backwards from the end of the string.  In the
3937 case the SCALAR is empty you can use OFFSET but only zero offset.
3938
3939 =item tell FILEHANDLE
3940
3941 =item tell
3942
3943 Returns the current position for FILEHANDLE.  FILEHANDLE may be an
3944 expression whose value gives the name of the actual filehandle.  If
3945 FILEHANDLE is omitted, assumes the file last read.
3946
3947 =item telldir DIRHANDLE
3948
3949 Returns the current position of the C<readdir()> routines on DIRHANDLE.
3950 Value may be given to C<seekdir()> to access a particular location in a
3951 directory.  Has the same caveats about possible directory compaction as
3952 the corresponding system library routine.
3953
3954 =item tie VARIABLE,CLASSNAME,LIST
3955
3956 This function binds a variable to a package class that will provide the
3957 implementation for the variable.  VARIABLE is the name of the variable
3958 to be enchanted.  CLASSNAME is the name of a class implementing objects
3959 of correct type.  Any additional arguments are passed to the "C<new>"
3960 method of the class (meaning C<TIESCALAR>, C<TIEARRAY>, or C<TIEHASH>).
3961 Typically these are arguments such as might be passed to the C<dbm_open()>
3962 function of C.  The object returned by the "C<new>" method is also
3963 returned by the C<tie()> function, which would be useful if you want to
3964 access other methods in CLASSNAME.
3965
3966 Note that functions such as C<keys()> and C<values()> may return huge lists
3967 when used on large objects, like DBM files.  You may prefer to use the
3968 C<each()> function to iterate over such.  Example:
3969
3970     # print out history file offsets
3971     use NDBM_File;
3972     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
3973     while (($key,$val) = each %HIST) {
3974         print $key, ' = ', unpack('L',$val), "\n";
3975     }
3976     untie(%HIST);
3977
3978 A class implementing a hash should have the following methods:
3979
3980     TIEHASH classname, LIST
3981     DESTROY this
3982     FETCH this, key
3983     STORE this, key, value
3984     DELETE this, key
3985     EXISTS this, key
3986     FIRSTKEY this
3987     NEXTKEY this, lastkey
3988
3989 A class implementing an ordinary array should have the following methods:
3990
3991     TIEARRAY classname, LIST
3992     DESTROY this
3993     FETCH this, key
3994     STORE this, key, value
3995     [others TBD]
3996
3997 A class implementing a scalar should have the following methods:
3998
3999     TIESCALAR classname, LIST
4000     DESTROY this
4001     FETCH this,
4002     STORE this, value
4003
4004 Unlike C<dbmopen()>, the C<tie()> function will not use or require a module
4005 for you--you need to do that explicitly yourself.  See L<DB_File>
4006 or the F<Config> module for interesting C<tie()> implementations.
4007
4008 For further details see L<perltie>, L<tied VARIABLE>.
4009
4010 =item tied VARIABLE
4011
4012 Returns a reference to the object underlying VARIABLE (the same value
4013 that was originally returned by the C<tie()> call that bound the variable
4014 to a package.)  Returns the undefined value if VARIABLE isn't tied to a
4015 package.
4016
4017 =item time
4018
4019 Returns the number of non-leap seconds since whatever time the system
4020 considers to be the epoch (that's 00:00:00, January 1, 1904 for MacOS,
4021 and 00:00:00 UTC, January 1, 1970 for most other systems).
4022 Suitable for feeding to C<gmtime()> and C<localtime()>.
4023
4024 =item times
4025
4026 Returns a four-element list giving the user and system times, in
4027 seconds, for this process and the children of this process.
4028
4029     ($user,$system,$cuser,$csystem) = times;
4030
4031 =item tr///
4032
4033 The transliteration operator.  Same as C<y///>. See L<perlop>.
4034
4035 =item truncate FILEHANDLE,LENGTH
4036
4037 =item truncate EXPR,LENGTH
4038
4039 Truncates the file opened on FILEHANDLE, or named by EXPR, to the
4040 specified length.  Produces a fatal error if truncate isn't implemented
4041 on your system.  Returns TRUE if successful, the undefined value
4042 otherwise.
4043
4044 =item uc EXPR
4045
4046 =item uc
4047
4048 Returns an uppercased version of EXPR.  This is the internal function
4049 implementing the C<\U> escape in double-quoted strings.
4050 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4051
4052 If EXPR is omitted, uses C<$_>.
4053
4054 =item ucfirst EXPR
4055
4056 =item ucfirst
4057
4058 Returns the value of EXPR with the first character uppercased.  This is
4059 the internal function implementing the C<\u> escape in double-quoted strings.
4060 Respects current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>.
4061
4062 If EXPR is omitted, uses C<$_>.
4063
4064 =item umask EXPR
4065
4066 =item umask
4067
4068 Sets the umask for the process to EXPR and returns the previous value.
4069 If EXPR is omitted, merely returns the current umask.  If C<umask(2)> is
4070 not implemented on your system, returns C<undef>.  Remember that a
4071 umask is a number, usually given in octal; it is I<not> a string of octal
4072 digits.  See also L</oct>, if all you have is a string.
4073
4074 =item undef EXPR
4075
4076 =item undef
4077
4078 Undefines the value of EXPR, which must be an lvalue.  Use only on a
4079 scalar value, an array (using "C<@>"), a hash (using "C<%>"), a subroutine
4080 (using "C<&>"), or a typeglob (using "<*>").  (Saying C<undef $hash{$key}>
4081 will probably not do what you expect on most predefined variables or
4082 DBM list values, so don't do that; see L<delete>.)  Always returns the
4083 undefined value.  You can omit the EXPR, in which case nothing is
4084 undefined, but you still get an undefined value that you could, for
4085 instance, return from a subroutine, assign to a variable or pass as a
4086 parameter.  Examples:
4087
4088     undef $foo;
4089     undef $bar{'blurfl'};             # Compare to: delete $bar{'blurfl'};
4090     undef @ary;
4091     undef %hash;
4092     undef &mysub;
4093     undef *xyz;       # destroys $xyz, @xyz, %xyz, &xyz, etc.
4094     return (wantarray ? (undef, $errmsg) : undef) if $they_blew_it;
4095     select undef, undef, undef, 0.25;
4096     ($a, $b, undef, $c) = &foo;       # Ignore third value returned
4097
4098 Note that this is a unary operator, not a list operator.
4099
4100 =item unlink LIST
4101
4102 =item unlink
4103
4104 Deletes a list of files.  Returns the number of files successfully
4105 deleted.
4106
4107     $cnt = unlink 'a', 'b', 'c';
4108     unlink @goners;
4109     unlink <*.bak>;
4110
4111 Note: C<unlink> will not delete directories unless you are superuser and
4112 the B<-U> flag is supplied to Perl.  Even if these conditions are
4113 met, be warned that unlinking a directory can inflict damage on your
4114 filesystem.  Use C<rmdir> instead.
4115
4116 If LIST is omitted, uses C<$_>.
4117
4118 =item unpack TEMPLATE,EXPR
4119
4120 C<Unpack> does the reverse of C<pack>: it takes a string representing a
4121 structure and expands it out into a list value, returning the array
4122 value.  (In scalar context, it returns merely the first value
4123 produced.)  The TEMPLATE has the same format as in the C<pack> function.
4124 Here's a subroutine that does substring:
4125
4126     sub substr {
4127         my($what,$where,$howmuch) = @_;
4128         unpack("x$where a$howmuch", $what);
4129     }
4130
4131 and then there's
4132
4133     sub ordinal { unpack("c",$_[0]); } # same as ord()
4134
4135 In addition, you may prefix a field with a %E<lt>numberE<gt> to indicate that
4136 you want a E<lt>numberE<gt>-bit checksum of the items instead of the items
4137 themselves.  Default is a 16-bit checksum.  For example, the following
4138 computes the same number as the System V sum program:
4139
4140     while (<>) {
4141         $checksum += unpack("%16C*", $_);
4142     }
4143     $checksum %= 65536;
4144
4145 The following efficiently counts the number of set bits in a bit vector:
4146
4147     $setbits = unpack("%32b*", $selectmask);
4148
4149 =item untie VARIABLE
4150
4151 Breaks the binding between a variable and a package.  (See C<tie()>.)
4152
4153 =item unshift ARRAY,LIST
4154
4155 Does the opposite of a C<shift>.  Or the opposite of a C<push>,
4156 depending on how you look at it.  Prepends list to the front of the
4157 array, and returns the new number of elements in the array.
4158
4159     unshift(ARGV, '-e') unless $ARGV[0] =~ /^-/;
4160
4161 Note the LIST is prepended whole, not one element at a time, so the
4162 prepended elements stay in the same order.  Use C<reverse> to do the
4163 reverse.
4164
4165 =item use Module LIST
4166
4167 =item use Module
4168
4169 =item use Module VERSION LIST
4170
4171 =item use VERSION
4172
4173 Imports some semantics into the current package from the named module,
4174 generally by aliasing certain subroutine or variable names into your
4175 package.  It is exactly equivalent to
4176
4177     BEGIN { require Module; import Module LIST; }
4178
4179 except that Module I<must> be a bareword.
4180
4181 If the first argument to C<use> is a number, it is treated as a version
4182 number instead of a module name.  If the version of the Perl interpreter
4183 is less than VERSION, then an error message is printed and Perl exits
4184 immediately.  This is often useful if you need to check the current
4185 Perl version before C<use>ing library modules that have changed in
4186 incompatible ways from older versions of Perl.  (We try not to do
4187 this more than we have to.)
4188
4189 The C<BEGIN> forces the C<require> and C<import> to happen at compile time.  The
4190 C<require> makes sure the module is loaded into memory if it hasn't been
4191 yet.  The C<import> is not a builtin--it's just an ordinary static method
4192 call into the "C<Module>" package to tell the module to import the list of
4193 features back into the current package.  The module can implement its
4194 C<import> method any way it likes, though most modules just choose to
4195 derive their C<import> method via inheritance from the C<Exporter> class that
4196 is defined in the C<Exporter> module.  See L<Exporter>.  If no C<import>
4197 method can be found then the error is currently silently ignored.  This
4198 may change to a fatal error in a future version.
4199
4200 If you don't want your namespace altered, explicitly supply an empty list:
4201
4202     use Module ();
4203
4204 That is exactly equivalent to
4205
4206     BEGIN { require Module }
4207
4208 If the VERSION argument is present between Module and LIST, then the
4209 C<use> will call the VERSION method in class Module with the given
4210 version as an argument.  The default VERSION method, inherited from
4211 the Universal class, croaks if the given version is larger than the
4212 value of the variable C<$Module::VERSION>.  (Note that there is not a
4213 comma after VERSION!)
4214
4215 Because this is a wide-open interface, pragmas (compiler directives)
4216 are also implemented this way.  Currently implemented pragmas are:
4217
4218     use integer;
4219     use diagnostics;
4220     use sigtrap qw(SEGV BUS);
4221     use strict  qw(subs vars refs);
4222     use subs    qw(afunc blurfl);
4223
4224 Some of these these pseudo-modules import semantics into the current
4225 block scope (like C<strict> or C<integer>, unlike ordinary modules,
4226 which import symbols into the current package (which are effective
4227 through the end of the file).
4228
4229 There's a corresponding "C<no>" command that unimports meanings imported
4230 by C<use>, i.e., it calls C<unimport Module LIST> instead of C<import>.
4231
4232     no integer;
4233     no strict 'refs';
4234
4235 If no C<unimport> method can be found the call fails with a fatal error.
4236
4237 See L<perlmod> for a list of standard modules and pragmas.
4238
4239 =item utime LIST
4240
4241 Changes the access and modification times on each file of a list of
4242 files.  The first two elements of the list must be the NUMERICAL access
4243 and modification times, in that order.  Returns the number of files
4244 successfully changed.  The inode modification time of each file is set
4245 to the current time.  This code has the same effect as the "C<touch>"
4246 command if the files already exist:
4247
4248     #!/usr/bin/perl
4249     $now = time;
4250     utime $now, $now, @ARGV;
4251
4252 =item values HASH
4253
4254 Returns a list consisting of all the values of the named hash.  (In a
4255 scalar context, returns the number of values.)  The values are
4256 returned in an apparently random order, but it is the same order as
4257 either the C<keys()> or C<each()> function would produce on the same hash.
4258 As a side effect, it resets HASH's iterator.  See also C<keys()>, C<each()>,
4259 and C<sort()>.
4260
4261 =item vec EXPR,OFFSET,BITS
4262
4263 Treats the string in EXPR as a vector of unsigned integers, and
4264 returns the value of the bit field specified by OFFSET.  BITS specifies
4265 the number of bits that are reserved for each entry in the bit
4266 vector.  This must be a power of two from 1 to 32. C<vec()> may also be
4267 assigned to, in which case parentheses are needed to give the expression
4268 the correct precedence as in
4269
4270     vec($image, $max_x * $x + $y, 8) = 3;
4271
4272 Vectors created with C<vec()> can also be manipulated with the logical
4273 operators C<|>, C<&>, and C<^>, which will assume a bit vector operation is
4274 desired when both operands are strings.
4275
4276 The following code will build up an ASCII string saying C<'PerlPerlPerl'>.
4277 The comments show the string after each step. Note that this code works
4278 in the same way on big-endian or little-endian machines.
4279
4280     my $foo = '';
4281     vec($foo,  0, 32) = 0x5065726C;     # 'Perl'
4282     vec($foo,  2, 16) = 0x5065;         # 'PerlPe'
4283     vec($foo,  3, 16) = 0x726C;         # 'PerlPerl'
4284     vec($foo,  8,  8) = 0x50;           # 'PerlPerlP'
4285     vec($foo,  9,  8) = 0x65;           # 'PerlPerlPe'
4286     vec($foo, 20,  4) = 2;              # 'PerlPerlPe'   . "\x02"
4287     vec($foo, 21,  4) = 7;              # 'PerlPerlPer'  # 'r' is "\x72"
4288     vec($foo, 45,  2) = 3;              # 'PerlPerlPer'  . "\x0c"
4289     vec($foo, 93,  1) = 1;              # 'PerlPerlPer'  . "\x2c"
4290     vec($foo, 94,  1) = 1;              # 'PerlPerlPerl' # 'l' is "\x6c"
4291
4292 To transform a bit vector into a string or array of 0's and 1's, use these:
4293
4294     $bits = unpack("b*", $vector);
4295     @bits = split(//, unpack("b*", $vector));
4296
4297 If you know the exact length in bits, it can be used in place of the C<*>.
4298
4299 =item wait
4300
4301 Waits for a child process to terminate and returns the pid of the
4302 deceased process, or C<-1> if there are no child processes.  The status is
4303 returned in C<$?>.
4304
4305 =item waitpid PID,FLAGS
4306
4307 Waits for a particular child process to terminate and returns the pid
4308 of the deceased process, or C<-1> if there is no such child process.  The
4309 status is returned in C<$?>.  If you say
4310
4311     use POSIX ":sys_wait_h";
4312     #...
4313     waitpid(-1,&WNOHANG);
4314
4315 then you can do a non-blocking wait for any process.  Non-blocking wait
4316 is available on machines supporting either the C<waitpid(2)> or
4317 C<wait4(2)> system calls.  However, waiting for a particular pid with
4318 FLAGS of C<0> is implemented everywhere.  (Perl emulates the system call
4319 by remembering the status values of processes that have exited but have
4320 not been harvested by the Perl script yet.)
4321
4322 See L<perlipc> for other examples.
4323
4324 =item wantarray
4325
4326 Returns TRUE if the context of the currently executing subroutine is
4327 looking for a list value.  Returns FALSE if the context is looking
4328 for a scalar.  Returns the undefined value if the context is looking
4329 for no value (void context).
4330
4331     return unless defined wantarray;    # don't bother doing more
4332     my @a = complex_calculation();
4333     return wantarray ? @a : "@a";
4334
4335 =item warn LIST
4336
4337 Produces a message on STDERR just like C<die()>, but doesn't exit or throw
4338 an exception.
4339
4340 If LIST is empty and C<$@> already contains a value (typically from a
4341 previous eval) that value is used after appending C<"\t...caught">
4342 to C<$@>. This is useful for staying almost, but not entirely similar to
4343 C<die()>.
4344
4345 If C<$@> is empty then the string C<"Warning: Something's wrong"> is used.
4346
4347 No message is printed if there is a C<$SIG{__WARN__}> handler
4348 installed.  It is the handler's responsibility to deal with the message
4349 as it sees fit (like, for instance, converting it into a C<die()>).  Most
4350 handlers must therefore make arrangements to actually display the
4351 warnings that they are not prepared to deal with, by calling C<warn()>
4352 again in the handler.  Note that this is quite safe and will not
4353 produce an endless loop, since C<__WARN__> hooks are not called from
4354 inside one.
4355
4356 You will find this behavior is slightly different from that of
4357 C<$SIG{__DIE__}> handlers (which don't suppress the error text, but can
4358 instead call C<die()> again to change it).
4359
4360 Using a C<__WARN__> handler provides a powerful way to silence all
4361 warnings (even the so-called mandatory ones).  An example:
4362
4363     # wipe out *all* compile-time warnings
4364     BEGIN { $SIG{'__WARN__'} = sub { warn $_[0] if $DOWARN } }
4365     my $foo = 10;
4366     my $foo = 20;          # no warning about duplicate my $foo,
4367                            # but hey, you asked for it!
4368     # no compile-time or run-time warnings before here
4369     $DOWARN = 1;
4370
4371     # run-time warnings enabled after here
4372     warn "\$foo is alive and $foo!";     # does show up
4373
4374 See L<perlvar> for details on setting C<%SIG> entries, and for more
4375 examples.
4376
4377 =item write FILEHANDLE
4378
4379 =item write EXPR
4380
4381 =item write
4382
4383 Writes a formatted record (possibly multi-line) to the specified FILEHANDLE,
4384 using the format associated with that file.  By default the format for
4385 a file is the one having the same name as the filehandle, but the
4386 format for the current output channel (see the C<select()> function) may be set
4387 explicitly by assigning the name of the format to the C<$~> variable.
4388
4389 Top of form processing is handled automatically:  if there is
4390 insufficient room on the current page for the formatted record, the
4391 page is advanced by writing a form feed, a special top-of-page format
4392 is used to format the new page header, and then the record is written.
4393 By default the top-of-page format is the name of the filehandle with
4394 "_TOP" appended, but it may be dynamically set to the format of your
4395 choice by assigning the name to the C<$^> variable while the filehandle is
4396 selected.  The number of lines remaining on the current page is in
4397 variable C<$->, which can be set to C<0> to force a new page.
4398
4399 If FILEHANDLE is unspecified, output goes to the current default output
4400 channel, which starts out as STDOUT but may be changed by the
4401 C<select> operator.  If the FILEHANDLE is an EXPR, then the expression
4402 is evaluated and the resulting string is used to look up the name of
4403 the FILEHANDLE at run time.  For more on formats, see L<perlform>.
4404
4405 Note that write is I<NOT> the opposite of C<read>.  Unfortunately.
4406
4407 =item y///
4408
4409 The transliteration operator.  Same as C<tr///>.  See L<perlop>.
4410
4411 =back