This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
765cad97f92f66eeb2a893c9a9040efb28fd49f4
[perl5.git] / cpan / ExtUtils-MakeMaker / lib / ExtUtils / Liblist / Kid.pm
1 package ExtUtils::Liblist::Kid;
2
3 # XXX Splitting this out into its own .pm is a temporary solution.
4
5 # This kid package is to be used by MakeMaker.  It will not work if
6 # $self is not a Makemaker.
7
8 use 5.006;
9
10 # Broken out of MakeMaker from version 4.11
11
12 use strict;
13 use warnings;
14 our $VERSION = '6.79_01';
15
16 use ExtUtils::MakeMaker::Config;
17 use Cwd 'cwd';
18 use File::Basename;
19 use File::Spec;
20
21 sub ext {
22     if    ( $^O eq 'VMS' )     { return &_vms_ext; }
23     elsif ( $^O eq 'MSWin32' ) { return &_win32_ext; }
24     else                       { return &_unix_os2_ext; }
25 }
26
27 sub _unix_os2_ext {
28     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
29     $verbose ||= 0;
30
31     if ( $^O =~ 'os2' and $Config{perllibs} ) {
32
33         # Dynamic libraries are not transitive, so we may need including
34         # the libraries linked against perl.dll again.
35
36         $potential_libs .= " " if $potential_libs;
37         $potential_libs .= $Config{perllibs};
38     }
39     return ( "", "", "", "", ( $give_libs ? [] : () ) ) unless $potential_libs;
40     warn "Potential libraries are '$potential_libs':\n" if $verbose;
41
42     my ( $so ) = $Config{so};
43     my ( $libs ) = defined $Config{perllibs} ? $Config{perllibs} : $Config{libs};
44     my $Config_libext = $Config{lib_ext} || ".a";
45     my $Config_dlext = $Config{dlext};
46
47     # compute $extralibs, $bsloadlibs and $ldloadlibs from
48     # $potential_libs
49     # this is a rewrite of Andy Dougherty's extliblist in perl
50
51     my ( @searchpath );    # from "-L/path" entries in $potential_libs
52     my ( @libpath ) = split " ", $Config{'libpth'};
53     my ( @ldloadlibs, @bsloadlibs, @extralibs, @ld_run_path, %ld_run_path_seen );
54     my ( @libs,       %libs_seen );
55     my ( $fullname,   @fullname );
56     my ( $pwd )   = cwd();    # from Cwd.pm
57     my ( $found ) = 0;
58
59     foreach my $thislib ( split ' ', $potential_libs ) {
60
61         # Handle possible linker path arguments.
62         if ( $thislib =~ s/^(-[LR]|-Wl,-R|-Wl,-rpath,)// ) {    # save path flag type
63             my ( $ptype ) = $1;
64             unless ( -d $thislib ) {
65                 warn "$ptype$thislib ignored, directory does not exist\n"
66                   if $verbose;
67                 next;
68             }
69             my ( $rtype ) = $ptype;
70             if ( ( $ptype eq '-R' ) or ( $ptype =~ m!^-Wl,-[Rr]! ) ) {
71                 if ( $Config{'lddlflags'} =~ /-Wl,-[Rr]/ ) {
72                     $rtype = '-Wl,-R';
73                 }
74                 elsif ( $Config{'lddlflags'} =~ /-R/ ) {
75                     $rtype = '-R';
76                 }
77             }
78             unless ( File::Spec->file_name_is_absolute( $thislib ) ) {
79                 warn "Warning: $ptype$thislib changed to $ptype$pwd/$thislib\n";
80                 $thislib = $self->catdir( $pwd, $thislib );
81             }
82             push( @searchpath, $thislib );
83             push( @extralibs,  "$ptype$thislib" );
84             push( @ldloadlibs, "$rtype$thislib" );
85             next;
86         }
87
88         if ( $thislib =~ m!^-Wl,! ) {
89             push( @extralibs,  $thislib );
90             push( @ldloadlibs, $thislib );
91             next;
92         }
93
94         # Handle possible library arguments.
95         unless ( $thislib =~ s/^-l// ) {
96             warn "Unrecognized argument in LIBS ignored: '$thislib'\n";
97             next;
98         }
99
100         my ( $found_lib ) = 0;
101         foreach my $thispth ( @searchpath, @libpath ) {
102
103             # Try to find the full name of the library.  We need this to
104             # determine whether it's a dynamically-loadable library or not.
105             # This tends to be subject to various os-specific quirks.
106             # For gcc-2.6.2 on linux (March 1995), DLD can not load
107             # .sa libraries, with the exception of libm.sa, so we
108             # deliberately skip them.
109             if ( @fullname = $self->lsdir( $thispth, "^\Qlib$thislib.$so.\E[0-9]+" ) ) {
110
111                 # Take care that libfoo.so.10 wins against libfoo.so.9.
112                 # Compare two libraries to find the most recent version
113                 # number.  E.g.  if you have libfoo.so.9.0.7 and
114                 # libfoo.so.10.1, first convert all digits into two
115                 # decimal places.  Then we'll add ".00" to the shorter
116                 # strings so that we're comparing strings of equal length
117                 # Thus we'll compare libfoo.so.09.07.00 with
118                 # libfoo.so.10.01.00.  Some libraries might have letters
119                 # in the version.  We don't know what they mean, but will
120                 # try to skip them gracefully -- we'll set any letter to
121                 # '0'.  Finally, sort in reverse so we can take the
122                 # first element.
123
124                 #TODO: iterate through the directory instead of sorting
125
126                 $fullname = "$thispth/" . (
127                     sort {
128                         my ( $ma ) = $a;
129                         my ( $mb ) = $b;
130                         $ma =~ tr/A-Za-z/0/s;
131                         $ma =~ s/\b(\d)\b/0$1/g;
132                         $mb =~ tr/A-Za-z/0/s;
133                         $mb =~ s/\b(\d)\b/0$1/g;
134                         while ( length( $ma ) < length( $mb ) ) { $ma .= ".00"; }
135                         while ( length( $mb ) < length( $ma ) ) { $mb .= ".00"; }
136
137                         # Comparison deliberately backwards
138                         $mb cmp $ma;
139                       } @fullname
140                 )[0];
141             }
142             elsif ( -f ( $fullname = "$thispth/lib$thislib.$so" )
143                 && ( ( $Config{'dlsrc'} ne "dl_dld.xs" ) || ( $thislib eq "m" ) ) )
144             {
145             }
146             elsif (-f ( $fullname = "$thispth/lib${thislib}_s$Config_libext" )
147                 && ( $Config{'archname'} !~ /RM\d\d\d-svr4/ )
148                 && ( $thislib .= "_s" ) )
149             {    # we must explicitly use _s version
150             }
151             elsif ( -f ( $fullname = "$thispth/lib$thislib$Config_libext" ) ) {
152             }
153             elsif ( defined( $Config_dlext )
154                 && -f ( $fullname = "$thispth/lib$thislib.$Config_dlext" ) )
155             {
156             }
157             elsif ( -f ( $fullname = "$thispth/$thislib$Config_libext" ) ) {
158             }
159             elsif ( -f ( $fullname = "$thispth/lib$thislib.dll$Config_libext" ) ) {
160             }
161             elsif ( $^O eq 'cygwin' && -f ( $fullname = "$thispth/$thislib.dll" ) ) {
162             }
163             elsif ( -f ( $fullname = "$thispth/Slib$thislib$Config_libext" ) ) {
164             }
165             elsif ($^O eq 'dgux'
166                 && -l ( $fullname = "$thispth/lib$thislib$Config_libext" )
167                 && readlink( $fullname ) =~ /^elink:/s )
168             {
169
170                 # Some of DG's libraries look like misconnected symbolic
171                 # links, but development tools can follow them.  (They
172                 # look like this:
173                 #
174                 #    libm.a -> elink:${SDE_PATH:-/usr}/sde/\
175                 #    ${TARGET_BINARY_INTERFACE:-m88kdgux}/usr/lib/libm.a
176                 #
177                 # , the compilation tools expand the environment variables.)
178             }
179             else {
180                 warn "$thislib not found in $thispth\n" if $verbose;
181                 next;
182             }
183             warn "'-l$thislib' found at $fullname\n" if $verbose;
184             push @libs, $fullname unless $libs_seen{$fullname}++;
185             $found++;
186             $found_lib++;
187
188             # Now update library lists
189
190             # what do we know about this library...
191             my $is_dyna = ( $fullname !~ /\Q$Config_libext\E\z/ );
192             my $in_perl = ( $libs =~ /\B-l\Q${thislib}\E\b/s );
193
194             # include the path to the lib once in the dynamic linker path
195             # but only if it is a dynamic lib and not in Perl itself
196             my ( $fullnamedir ) = dirname( $fullname );
197             push @ld_run_path, $fullnamedir
198               if $is_dyna
199                   && !$in_perl
200                   && !$ld_run_path_seen{$fullnamedir}++;
201
202             # Do not add it into the list if it is already linked in
203             # with the main perl executable.
204             # We have to special-case the NeXT, because math and ndbm
205             # are both in libsys_s
206             unless (
207                 $in_perl
208                 || ( $Config{'osname'} eq 'next'
209                     && ( $thislib eq 'm' || $thislib eq 'ndbm' ) )
210               )
211             {
212                 push( @extralibs, "-l$thislib" );
213             }
214
215             # We might be able to load this archive file dynamically
216             if (   ( $Config{'dlsrc'} =~ /dl_next/ && $Config{'osvers'} lt '4_0' )
217                 || ( $Config{'dlsrc'} =~ /dl_dld/ ) )
218             {
219
220                 # We push -l$thislib instead of $fullname because
221                 # it avoids hardwiring a fixed path into the .bs file.
222                 # Mkbootstrap will automatically add dl_findfile() to
223                 # the .bs file if it sees a name in the -l format.
224                 # USE THIS, when dl_findfile() is fixed:
225                 # push(@bsloadlibs, "-l$thislib");
226                 # OLD USE WAS while checking results against old_extliblist
227                 push( @bsloadlibs, "$fullname" );
228             }
229             else {
230                 if ( $is_dyna ) {
231
232                     # For SunOS4, do not add in this shared library if
233                     # it is already linked in the main perl executable
234                     push( @ldloadlibs, "-l$thislib" )
235                       unless ( $in_perl and $^O eq 'sunos' );
236                 }
237                 else {
238                     push( @ldloadlibs, "-l$thislib" );
239                 }
240             }
241             last;    # found one here so don't bother looking further
242         }
243         warn "Warning (mostly harmless): " . "No library found for -l$thislib\n"
244           unless $found_lib > 0;
245     }
246
247     unless ( $found ) {
248         return ( '', '', '', '', ( $give_libs ? \@libs : () ) );
249     }
250     else {
251         return ( "@extralibs", "@bsloadlibs", "@ldloadlibs", join( ":", @ld_run_path ), ( $give_libs ? \@libs : () ) );
252     }
253 }
254
255 sub _win32_ext {
256
257     require Text::ParseWords;
258
259     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
260     $verbose ||= 0;
261
262     # If user did not supply a list, we punt.
263     # (caller should probably use the list in $Config{libs})
264     return ( "", "", "", "", ( $give_libs ? [] : () ) ) unless $potential_libs;
265
266     # TODO: make this use MM_Win32.pm's compiler detection
267     my %libs_seen;
268     my @extralibs;
269     my $cc = $Config{cc} || '';
270     my $VC = $cc =~ /\bcl\b/i;
271     my $GC = $cc =~ /\bgcc\b/i;
272
273     my $libext     = _win32_lib_extensions();
274     my @searchpath = ( '' );                                    # from "-L/path" entries in $potential_libs
275     my @libpath    = _win32_default_search_paths( $VC, $GC );
276     my $pwd        = cwd();                                     # from Cwd.pm
277     my $search     = 1;
278
279     # compute @extralibs from $potential_libs
280     my @lib_search_list = _win32_make_lib_search_list( $potential_libs, $verbose );
281     for ( @lib_search_list ) {
282
283         my $thislib = $_;
284
285         # see if entry is a flag
286         if ( /^:\w+$/ ) {
287             $search = 0 if lc eq ':nosearch';
288             $search = 1 if lc eq ':search';
289             _debug( "Ignoring unknown flag '$thislib'\n", $verbose ) if !/^:(no)?(search|default)$/i;
290             next;
291         }
292
293         # if searching is disabled, do compiler-specific translations
294         unless ( $search ) {
295             s/^-l(.+)$/$1.lib/ unless $GC;
296             s/^-L/-libpath:/ if $VC;
297             push( @extralibs, $_ );
298             next;
299         }
300
301         # handle possible linker path arguments
302         if ( s/^-L// and not -d ) {
303             _debug( "$thislib ignored, directory does not exist\n", $verbose );
304             next;
305         }
306         elsif ( -d ) {
307             unless ( File::Spec->file_name_is_absolute( $_ ) ) {
308                 warn "Warning: '$thislib' changed to '-L$pwd/$_'\n";
309                 $_ = $self->catdir( $pwd, $_ );
310             }
311             push( @searchpath, $_ );
312             next;
313         }
314
315         my @paths = ( @searchpath, @libpath );
316         my ( $fullname, $path ) = _win32_search_file( $thislib, $libext, \@paths, $verbose, $GC );
317
318         if ( !$fullname ) {
319             warn "Warning (mostly harmless): No library found for $thislib\n";
320             next;
321         }
322
323         _debug( "'$thislib' found as '$fullname'\n", $verbose );
324         push( @extralibs, $fullname );
325         $libs_seen{$fullname} = 1 if $path;    # why is this a special case?
326     }
327
328     my @libs = keys %libs_seen;
329
330     return ( '', '', '', '', ( $give_libs ? \@libs : () ) ) unless @extralibs;
331
332     # make sure paths with spaces are properly quoted
333     @extralibs = map { /\s/ ? qq["$_"] : $_ } @extralibs;
334     @libs      = map { /\s/ ? qq["$_"] : $_ } @libs;
335
336     my $lib = join( ' ', @extralibs );
337
338     # normalize back to backward slashes (to help braindead tools)
339     # XXX this may break equally braindead GNU tools that don't understand
340     # backslashes, either.  Seems like one can't win here.  Cursed be CP/M.
341     $lib =~ s,/,\\,g;
342
343     _debug( "Result: $lib\n", $verbose );
344     wantarray ? ( $lib, '', $lib, '', ( $give_libs ? \@libs : () ) ) : $lib;
345 }
346
347 sub _win32_make_lib_search_list {
348     my ( $potential_libs, $verbose ) = @_;
349
350     # If Config.pm defines a set of default libs, we always
351     # tack them on to the user-supplied list, unless the user
352     # specified :nodefault
353     my $libs = $Config{'perllibs'};
354     $potential_libs = join( ' ', $potential_libs, $libs ) if $libs and $potential_libs !~ /:nodefault/i;
355     _debug( "Potential libraries are '$potential_libs':\n", $verbose );
356
357     $potential_libs =~ s,\\,/,g;    # normalize to forward slashes
358
359     my @list = Text::ParseWords::quotewords( '\s+', 0, $potential_libs );
360
361     return @list;
362 }
363
364 sub _win32_default_search_paths {
365     my ( $VC, $GC ) = @_;
366
367     my $libpth = $Config{'libpth'} || '';
368     $libpth =~ s,\\,/,g;            # normalize to forward slashes
369
370     my @libpath = Text::ParseWords::quotewords( '\s+', 0, $libpth );
371     push @libpath, "$Config{installarchlib}/CORE";    # add "$Config{installarchlib}/CORE" to default search path
372
373     push @libpath, split /;/, $ENV{LIB}          if $VC and $ENV{LIB};
374     push @libpath, split /;/, $ENV{LIBRARY_PATH} if $GC and $ENV{LIBRARY_PATH};
375
376     return @libpath;
377 }
378
379 sub _win32_search_file {
380     my ( $thislib, $libext, $paths, $verbose, $GC ) = @_;
381
382     my @file_list = _win32_build_file_list( $thislib, $GC, $libext );
383
384     for my $lib_file ( @file_list ) {
385         for my $path ( @{$paths} ) {
386             my $fullname = $lib_file;
387             $fullname = "$path\\$fullname" if $path;
388
389             return ( $fullname, $path ) if -f $fullname;
390
391             _debug( "'$thislib' not found as '$fullname'\n", $verbose );
392         }
393     }
394
395     return;
396 }
397
398 sub _win32_build_file_list {
399     my ( $lib, $GC, $extensions ) = @_;
400
401     my @pre_fixed = _win32_build_prefixed_list( $lib, $GC );
402     return map _win32_attach_extensions( $_, $extensions ), @pre_fixed;
403 }
404
405 sub _win32_build_prefixed_list {
406     my ( $lib, $GC ) = @_;
407
408     return $lib if $lib !~ s/^-l//;
409     return $lib if $lib =~ /^lib/ and !$GC;
410
411     ( my $no_prefix = $lib ) =~ s/^lib//i;
412     $lib = "lib$lib" if $no_prefix eq $lib;
413
414     return ( $lib, $no_prefix ) if $GC;
415     return ( $no_prefix, $lib );
416 }
417
418 sub _win32_attach_extensions {
419     my ( $lib, $extensions ) = @_;
420     return map _win32_try_attach_extension( $lib, $_ ), @{$extensions};
421 }
422
423 sub _win32_try_attach_extension {
424     my ( $lib, $extension ) = @_;
425
426     return $lib if $lib =~ /\Q$extension\E$/i;
427     return "$lib$extension";
428 }
429
430 sub _win32_lib_extensions {
431     my @extensions;
432     push @extensions, $Config{'lib_ext'} if $Config{'lib_ext'};
433     push @extensions, '.dll.a' if grep { m!^\.a$! } @extensions;
434     push @extensions, '.lib' unless grep { m!^\.lib$! } @extensions;
435     return \@extensions;
436 }
437
438 sub _debug {
439     my ( $message, $verbose ) = @_;
440     return if !$verbose;
441     warn $message;
442     return;
443 }
444
445 sub _vms_ext {
446     my ( $self, $potential_libs, $verbose, $give_libs ) = @_;
447     $verbose ||= 0;
448
449     my ( @crtls, $crtlstr );
450     @crtls = ( ( $Config{'ldflags'} =~ m-/Debug-i ? $Config{'dbgprefix'} : '' ) . 'PerlShr/Share' );
451     push( @crtls, grep { not /\(/ } split /\s+/, $Config{'perllibs'} );
452     push( @crtls, grep { not /\(/ } split /\s+/, $Config{'libc'} );
453
454     # In general, we pass through the basic libraries from %Config unchanged.
455     # The one exception is that if we're building in the Perl source tree, and
456     # a library spec could be resolved via a logical name, we go to some trouble
457     # to insure that the copy in the local tree is used, rather than one to
458     # which a system-wide logical may point.
459     if ( $self->{PERL_SRC} ) {
460         my ( $locspec, $type );
461         foreach my $lib ( @crtls ) {
462             if ( ( $locspec, $type ) = $lib =~ m{^([\w\$-]+)(/\w+)?} and $locspec =~ /perl/i ) {
463                 if    ( lc $type eq '/share' )   { $locspec .= $Config{'exe_ext'}; }
464                 elsif ( lc $type eq '/library' ) { $locspec .= $Config{'lib_ext'}; }
465                 else                             { $locspec .= $Config{'obj_ext'}; }
466                 $locspec = $self->catfile( $self->{PERL_SRC}, $locspec );
467                 $lib = "$locspec$type" if -e $locspec;
468             }
469         }
470     }
471     $crtlstr = @crtls ? join( ' ', @crtls ) : '';
472
473     unless ( $potential_libs ) {
474         warn "Result:\n\tEXTRALIBS: \n\tLDLOADLIBS: $crtlstr\n" if $verbose;
475         return ( '', '', $crtlstr, '', ( $give_libs ? [] : () ) );
476     }
477
478     my ( %found, @fndlibs, $ldlib );
479     my $cwd = cwd();
480     my ( $so, $lib_ext, $obj_ext ) = @Config{ 'so', 'lib_ext', 'obj_ext' };
481
482     # List of common Unix library names and their VMS equivalents
483     # (VMS equivalent of '' indicates that the library is automatically
484     # searched by the linker, and should be skipped here.)
485     my ( @flibs, %libs_seen );
486     my %libmap = (
487         'm'      => '',
488         'f77'    => '',
489         'F77'    => '',
490         'V77'    => '',
491         'c'      => '',
492         'malloc' => '',
493         'crypt'  => '',
494         'resolv' => '',
495         'c_s'    => '',
496         'socket' => '',
497         'X11'    => 'DECW$XLIBSHR',
498         'Xt'     => 'DECW$XTSHR',
499         'Xm'     => 'DECW$XMLIBSHR',
500         'Xmu'    => 'DECW$XMULIBSHR'
501     );
502     if ( $Config{'vms_cc_type'} ne 'decc' ) { $libmap{'curses'} = 'VAXCCURSE'; }
503
504     warn "Potential libraries are '$potential_libs'\n" if $verbose;
505
506     # First, sort out directories and library names in the input
507     my ( @dirs, @libs );
508     foreach my $lib ( split ' ', $potential_libs ) {
509         push( @dirs, $1 ),   next if $lib =~ /^-L(.*)/;
510         push( @dirs, $lib ), next if $lib =~ /[:>\]]$/;
511         push( @dirs, $lib ), next if -d $lib;
512         push( @libs, $1 ),   next if $lib =~ /^-l(.*)/;
513         push( @libs, $lib );
514     }
515     push( @dirs, split( ' ', $Config{'libpth'} ) );
516
517     # Now make sure we've got VMS-syntax absolute directory specs
518     # (We don't, however, check whether someone's hidden a relative
519     # path in a logical name.)
520     foreach my $dir ( @dirs ) {
521         unless ( -d $dir ) {
522             warn "Skipping nonexistent Directory $dir\n" if $verbose > 1;
523             $dir = '';
524             next;
525         }
526         warn "Resolving directory $dir\n" if $verbose;
527         if ( File::Spec->file_name_is_absolute( $dir ) ) {
528             $dir = $self->fixpath( $dir, 1 );
529         }
530         else {
531             $dir = $self->catdir( $cwd, $dir );
532         }
533     }
534     @dirs = grep { length( $_ ) } @dirs;
535     unshift( @dirs, '' );    # Check each $lib without additions first
536
537   LIB: foreach my $lib ( @libs ) {
538         if ( exists $libmap{$lib} ) {
539             next unless length $libmap{$lib};
540             $lib = $libmap{$lib};
541         }
542
543         my ( @variants, $cand );
544         my ( $ctype ) = '';
545
546         # If we don't have a file type, consider it a possibly abbreviated name and
547         # check for common variants.  We try these first to grab libraries before
548         # a like-named executable image (e.g. -lperl resolves to perlshr.exe
549         # before perl.exe).
550         if ( $lib !~ /\.[^:>\]]*$/ ) {
551             push( @variants, "${lib}shr", "${lib}rtl", "${lib}lib" );
552             push( @variants, "lib$lib" ) if $lib !~ /[:>\]]/;
553         }
554         push( @variants, $lib );
555         warn "Looking for $lib\n" if $verbose;
556         foreach my $variant ( @variants ) {
557             my ( $fullname, $name );
558
559             foreach my $dir ( @dirs ) {
560                 my ( $type );
561
562                 $name = "$dir$variant";
563                 warn "\tChecking $name\n" if $verbose > 2;
564                 $fullname = VMS::Filespec::rmsexpand( $name );
565                 if ( defined $fullname and -f $fullname ) {
566
567                     # It's got its own suffix, so we'll have to figure out the type
568                     if    ( $fullname =~ /(?:$so|exe)$/i )      { $type = 'SHR'; }
569                     elsif ( $fullname =~ /(?:$lib_ext|olb)$/i ) { $type = 'OLB'; }
570                     elsif ( $fullname =~ /(?:$obj_ext|obj)$/i ) {
571                         warn "Warning (mostly harmless): " . "Plain object file $fullname found in library list\n";
572                         $type = 'OBJ';
573                     }
574                     else {
575                         warn "Warning (mostly harmless): " . "Unknown library type for $fullname; assuming shared\n";
576                         $type = 'SHR';
577                     }
578                 }
579                 elsif (-f ( $fullname = VMS::Filespec::rmsexpand( $name, $so ) )
580                     or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.exe' ) ) )
581                 {
582                     $type = 'SHR';
583                     $name = $fullname unless $fullname =~ /exe;?\d*$/i;
584                 }
585                 elsif (
586                     not length( $ctype ) and    # If we've got a lib already,
587                                                 # don't bother
588                     ( -f ( $fullname = VMS::Filespec::rmsexpand( $name, $lib_ext ) ) or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.olb' ) ) )
589                   )
590                 {
591                     $type = 'OLB';
592                     $name = $fullname unless $fullname =~ /olb;?\d*$/i;
593                 }
594                 elsif (
595                     not length( $ctype ) and    # If we've got a lib already,
596                                                 # don't bother
597                     ( -f ( $fullname = VMS::Filespec::rmsexpand( $name, $obj_ext ) ) or -f ( $fullname = VMS::Filespec::rmsexpand( $name, '.obj' ) ) )
598                   )
599                 {
600                     warn "Warning (mostly harmless): " . "Plain object file $fullname found in library list\n";
601                     $type = 'OBJ';
602                     $name = $fullname unless $fullname =~ /obj;?\d*$/i;
603                 }
604                 if ( defined $type ) {
605                     $ctype = $type;
606                     $cand  = $name;
607                     last if $ctype eq 'SHR';
608                 }
609             }
610             if ( $ctype ) {
611
612                 # This has to precede any other CRTLs, so just make it first
613                 if ( $cand eq 'VAXCCURSE' ) { unshift @{ $found{$ctype} }, $cand; }
614                 else                        { push @{ $found{$ctype} }, $cand; }
615                 warn "\tFound as $cand (really $fullname), type $ctype\n"
616                   if $verbose > 1;
617                 push @flibs, $name unless $libs_seen{$fullname}++;
618                 next LIB;
619             }
620         }
621         warn "Warning (mostly harmless): " . "No library found for $lib\n";
622     }
623
624     push @fndlibs, @{ $found{OBJ} } if exists $found{OBJ};
625     push @fndlibs, map { "$_/Library" } @{ $found{OLB} } if exists $found{OLB};
626     push @fndlibs, map { "$_/Share" } @{ $found{SHR} }   if exists $found{SHR};
627     my $lib = join( ' ', @fndlibs );
628
629     $ldlib = $crtlstr ? "$lib $crtlstr" : $lib;
630     warn "Result:\n\tEXTRALIBS: $lib\n\tLDLOADLIBS: $ldlib\n" if $verbose;
631     wantarray ? ( $lib, '', $ldlib, '', ( $give_libs ? \@flibs : () ) ) : $lib;
632 }
633
634 1;