This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlretut.pod, 2nd version
[perl5.git] / pod / perlretut.pod
1 =head1 NAME
2
3 perlretut - Perl regular expressions tutorial
4
5 =head1 DESCRIPTION
6
7 This page provides a basic tutorial on understanding, creating and
8 using regular expressions in Perl.  It serves as a complement to the
9 reference page on regular expressions L<perlre>.  Regular expressions
10 are an integral part of the C<m//>, C<s///>, C<qr//> and C<split>
11 operators and so this tutorial also overlaps with
12 L<perlop/"Regexp Quote-Like Operators"> and L<perlfunc/split>.
13
14 Perl is widely renowned for excellence in text processing, and regular
15 expressions are one of the big factors behind this fame.  Perl regular
16 expressions display an efficiency and flexibility unknown in most
17 other computer languages.  Mastering even the basics of regular
18 expressions will allow you to manipulate text with surprising ease.
19
20 What is a regular expression?  A regular expression is simply a string
21 that describes a pattern.  Patterns are in common use these days;
22 examples are the patterns typed into a search engine to find web pages
23 and the patterns used to list files in a directory, e.g., C<ls *.txt>
24 or C<dir *.*>.  In Perl, the patterns described by regular expressions
25 are used to search strings, extract desired parts of strings, and to
26 do search and replace operations.
27
28 Regular expressions have the undeserved reputation of being abstract
29 and difficult to understand.  Regular expressions are constructed using
30 simple concepts like conditionals and loops and are no more difficult
31 to understand than the corresponding C<if> conditionals and C<while>
32 loops in the Perl language itself.  In fact, the main challenge in
33 learning regular expressions is just getting used to the terse
34 notation used to express these concepts.
35
36 This tutorial flattens the learning curve by discussing regular
37 expression concepts, along with their notation, one at a time and with
38 many examples.  The first part of the tutorial will progress from the
39 simplest word searches to the basic regular expression concepts.  If
40 you master the first part, you will have all the tools needed to solve
41 about 98% of your needs.  The second part of the tutorial is for those
42 comfortable with the basics and hungry for more power tools.  It
43 discusses the more advanced regular expression operators and
44 introduces the latest cutting edge innovations in 5.6.0.
45
46 A note: to save time, 'regular expression' is often abbreviated as
47 regexp or regex.  Regexp is a more natural abbreviation than regex, but
48 is harder to pronounce.  The Perl pod documentation is evenly split on
49 regexp vs regex; in Perl, there is more than one way to abbreviate it.
50 We'll use regexp in this tutorial.
51
52 =head1 Part 1: The basics
53
54 =head2 Simple word matching
55
56 The simplest regexp is simply a word, or more generally, a string of
57 characters.  A regexp consisting of a word matches any string that
58 contains that word:
59
60     "Hello World" =~ /World/;  # matches
61
62 What is this Perl statement all about? C<"Hello World"> is a simple
63 double quoted string.  C<World> is the regular expression and the
64 C<//> enclosing C</World/> tells Perl to search a string for a match.
65 The operator C<=~> associates the string with the regexp match and
66 produces a true value if the regexp matched, or false if the regexp
67 did not match.  In our case, C<World> matches the second word in
68 C<"Hello World">, so the expression is true.  Expressions like this
69 are useful in conditionals:
70
71     if ("Hello World" =~ /World/) {
72         print "It matches\n";
73     }
74     else {
75         print "It doesn't match\n";
76     }
77
78 There are useful variations on this theme.  The sense of the match can
79 be reversed by using the C<!~> operator:
80
81     if ("Hello World" !~ /World/) {
82         print "It doesn't match\n";
83     }
84     else {
85         print "It matches\n";
86     }
87
88 The literal string in the regexp can be replaced by a variable:
89
90     $greeting = "World";
91     if ("Hello World" =~ /$greeting/) {
92         print "It matches\n";
93     }
94     else {
95         print "It doesn't match\n";
96     }
97
98 If you're matching against the special default variable C<$_>, the
99 C<$_ =~> part can be omitted:
100
101     $_ = "Hello World";
102     if (/World/) {
103         print "It matches\n";
104     }
105     else {
106         print "It doesn't match\n";
107     }
108
109 And finally, the C<//> default delimiters for a match can be changed
110 to arbitrary delimiters by putting an C<'m'> out front:
111
112     "Hello World" =~ m!World!;   # matches, delimited by '!'
113     "Hello World" =~ m{World};   # matches, note the matching '{}'
114     "/usr/bin/perl" =~ m"/perl"; # matches after '/usr/bin',
115                                  # '/' becomes an ordinary char
116
117 C</World/>, C<m!World!>, and C<m{World}> all represent the
118 same thing.  When, e.g., the quote (C<">) is used as a delimiter, the forward
119 slash C<'/'> becomes an ordinary character and can be used in this regexp
120 without trouble.
121
122 Let's consider how different regexps would match C<"Hello World">:
123
124     "Hello World" =~ /world/;  # doesn't match
125     "Hello World" =~ /o W/;    # matches
126     "Hello World" =~ /oW/;     # doesn't match
127     "Hello World" =~ /World /; # doesn't match
128
129 The first regexp C<world> doesn't match because regexps are
130 case-sensitive.  The second regexp matches because the substring
131 S<C<'o W'>> occurs in the string S<C<"Hello World">>.  The space
132 character ' ' is treated like any other character in a regexp and is
133 needed to match in this case.  The lack of a space character is the
134 reason the third regexp C<'oW'> doesn't match.  The fourth regexp
135 C<'World '> doesn't match because there is a space at the end of the
136 regexp, but not at the end of the string.  The lesson here is that
137 regexps must match a part of the string I<exactly> in order for the
138 statement to be true.
139
140 If a regexp matches in more than one place in the string, Perl will
141 always match at the earliest possible point in the string:
142
143     "Hello World" =~ /o/;       # matches 'o' in 'Hello'
144     "That hat is red" =~ /hat/; # matches 'hat' in 'That'
145
146 With respect to character matching, there are a few more points you
147 need to know about.   First of all, not all characters can be used 'as
148 is' in a match.  Some characters, called I<metacharacters>, are reserved
149 for use in regexp notation.  The metacharacters are
150
151     {}[]()^$.|*+?\
152
153 The significance of each of these will be explained
154 in the rest of the tutorial, but for now, it is important only to know
155 that a metacharacter can be matched by putting a backslash before it:
156
157     "2+2=4" =~ /2+2/;    # doesn't match, + is a metacharacter
158     "2+2=4" =~ /2\+2/;   # matches, \+ is treated like an ordinary +
159     "The interval is [0,1)." =~ /[0,1)./     # is a syntax error!
160     "The interval is [0,1)." =~ /\[0,1\)\./  # matches
161     "#!/usr/bin/perl" =~ /#!\/usr\/bin\/perl/;  # matches
162
163 In the last regexp, the forward slash C<'/'> is also backslashed,
164 because it is used to delimit the regexp.  This can lead to LTS
165 (leaning toothpick syndrome), however, and it is often more readable
166 to change delimiters.
167
168     "#!/usr/bin/perl" =~ m!#\!/usr/bin/perl!;  # easier to read
169
170 The backslash character C<'\'> is a metacharacter itself and needs to
171 be backslashed:
172
173     'C:\WIN32' =~ /C:\\WIN/;   # matches
174
175 In addition to the metacharacters, there are some ASCII characters
176 which don't have printable character equivalents and are instead
177 represented by I<escape sequences>.  Common examples are C<\t> for a
178 tab, C<\n> for a newline, C<\r> for a carriage return and C<\a> for a
179 bell.  If your string is better thought of as a sequence of arbitrary
180 bytes, the octal escape sequence, e.g., C<\033>, or hexadecimal escape
181 sequence, e.g., C<\x1B> may be a more natural representation for your
182 bytes.  Here are some examples of escapes:
183
184     "1000\t2000" =~ m(0\t2)   # matches
185     "1000\n2000" =~ /0\n20/   # matches
186     "1000\t2000" =~ /\000\t2/ # doesn't match, "0" ne "\000"
187     "cat"        =~ /\143\x61\x74/ # matches, but a weird way to spell cat
188
189 If you've been around Perl a while, all this talk of escape sequences
190 may seem familiar.  Similar escape sequences are used in double-quoted
191 strings and in fact the regexps in Perl are mostly treated as
192 double-quoted strings.  This means that variables can be used in
193 regexps as well.  Just like double-quoted strings, the values of the
194 variables in the regexp will be substituted in before the regexp is
195 evaluated for matching purposes.  So we have:
196
197     $foo = 'house';
198     'housecat' =~ /$foo/;      # matches
199     'cathouse' =~ /cat$foo/;   # matches
200     'housecat' =~ /${foo}cat/; # matches
201
202 So far, so good.  With the knowledge above you can already perform
203 searches with just about any literal string regexp you can dream up.
204 Here is a I<very simple> emulation of the Unix grep program:
205
206     % cat > simple_grep
207     #!/usr/bin/perl
208     $regexp = shift;
209     while (<>) {
210         print if /$regexp/;
211     }
212     ^D
213
214     % chmod +x simple_grep
215
216     % simple_grep abba /usr/dict/words
217     Babbage
218     cabbage
219     cabbages
220     sabbath
221     Sabbathize
222     Sabbathizes
223     sabbatical
224     scabbard
225     scabbards
226
227 This program is easy to understand.  C<#!/usr/bin/perl> is the standard
228 way to invoke a perl program from the shell.
229 S<C<$regexp = shift;>> saves the first command line argument as the
230 regexp to be used, leaving the rest of the command line arguments to
231 be treated as files.  S<C<< while (<>) >>> loops over all the lines in
232 all the files.  For each line, S<C<print if /$regexp/;>> prints the
233 line if the regexp matches the line.  In this line, both C<print> and
234 C</$regexp/> use the default variable C<$_> implicitly.
235
236 With all of the regexps above, if the regexp matched anywhere in the
237 string, it was considered a match.  Sometimes, however, we'd like to
238 specify I<where> in the string the regexp should try to match.  To do
239 this, we would use the I<anchor> metacharacters C<^> and C<$>.  The
240 anchor C<^> means match at the beginning of the string and the anchor
241 C<$> means match at the end of the string, or before a newline at the
242 end of the string.  Here is how they are used:
243
244     "housekeeper" =~ /keeper/;    # matches
245     "housekeeper" =~ /^keeper/;   # doesn't match
246     "housekeeper" =~ /keeper$/;   # matches
247     "housekeeper\n" =~ /keeper$/; # matches
248
249 The second regexp doesn't match because C<^> constrains C<keeper> to
250 match only at the beginning of the string, but C<"housekeeper"> has
251 keeper starting in the middle.  The third regexp does match, since the
252 C<$> constrains C<keeper> to match only at the end of the string.
253
254 When both C<^> and C<$> are used at the same time, the regexp has to
255 match both the beginning and the end of the string, i.e., the regexp
256 matches the whole string.  Consider
257
258     "keeper" =~ /^keep$/;      # doesn't match
259     "keeper" =~ /^keeper$/;    # matches
260     ""       =~ /^$/;          # ^$ matches an empty string
261
262 The first regexp doesn't match because the string has more to it than
263 C<keep>.  Since the second regexp is exactly the string, it
264 matches.  Using both C<^> and C<$> in a regexp forces the complete
265 string to match, so it gives you complete control over which strings
266 match and which don't.  Suppose you are looking for a fellow named
267 bert, off in a string by himself:
268
269     "dogbert" =~ /bert/;   # matches, but not what you want
270
271     "dilbert" =~ /^bert/;  # doesn't match, but ..
272     "bertram" =~ /^bert/;  # matches, so still not good enough
273
274     "bertram" =~ /^bert$/; # doesn't match, good
275     "dilbert" =~ /^bert$/; # doesn't match, good
276     "bert"    =~ /^bert$/; # matches, perfect
277
278 Of course, in the case of a literal string, one could just as easily
279 use the string comparison S<C<$string eq 'bert'>> and it would be
280 more efficient.   The  C<^...$> regexp really becomes useful when we
281 add in the more powerful regexp tools below.
282
283 =head2 Using character classes
284
285 Although one can already do quite a lot with the literal string
286 regexps above, we've only scratched the surface of regular expression
287 technology.  In this and subsequent sections we will introduce regexp
288 concepts (and associated metacharacter notations) that will allow a
289 regexp to not just represent a single character sequence, but a I<whole
290 class> of them.
291
292 One such concept is that of a I<character class>.  A character class
293 allows a set of possible characters, rather than just a single
294 character, to match at a particular point in a regexp.  Character
295 classes are denoted by brackets C<[...]>, with the set of characters
296 to be possibly matched inside.  Here are some examples:
297
298     /cat/;       # matches 'cat'
299     /[bcr]at/;   # matches 'bat, 'cat', or 'rat'
300     /item[0123456789]/;  # matches 'item0' or ... or 'item9'
301     "abc" =~ /[cab]/;    # matches 'a'
302
303 In the last statement, even though C<'c'> is the first character in
304 the class, C<'a'> matches because the first character position in the
305 string is the earliest point at which the regexp can match.
306
307     /[yY][eE][sS]/;      # match 'yes' in a case-insensitive way
308                          # 'yes', 'Yes', 'YES', etc.
309
310 This regexp displays a common task: perform a case-insensitive
311 match.  Perl provides a way of avoiding all those brackets by simply
312 appending an C<'i'> to the end of the match.  Then C</[yY][eE][sS]/;>
313 can be rewritten as C</yes/i;>.  The C<'i'> stands for
314 case-insensitive and is an example of a I<modifier> of the matching
315 operation.  We will meet other modifiers later in the tutorial.
316
317 We saw in the section above that there were ordinary characters, which
318 represented themselves, and special characters, which needed a
319 backslash C<\> to represent themselves.  The same is true in a
320 character class, but the sets of ordinary and special characters
321 inside a character class are different than those outside a character
322 class.  The special characters for a character class are C<-]\^$> (and
323 the pattern delimiter, whatever it is). 
324 C<]> is special because it denotes the end of a character class.  C<$> is
325 special because it denotes a scalar variable.  C<\> is special because
326 it is used in escape sequences, just like above.  Here is how the
327 special characters C<]$\> are handled:
328
329    /[\]c]def/; # matches ']def' or 'cdef'
330    $x = 'bcr';
331    /[$x]at/;   # matches 'bat', 'cat', or 'rat'
332    /[\$x]at/;  # matches '$at' or 'xat'
333    /[\\$x]at/; # matches '\at', 'bat, 'cat', or 'rat'
334
335 The last two are a little tricky.  in C<[\$x]>, the backslash protects
336 the dollar sign, so the character class has two members C<$> and C<x>.
337 In C<[\\$x]>, the backslash is protected, so C<$x> is treated as a
338 variable and substituted in double quote fashion.
339
340 The special character C<'-'> acts as a range operator within character
341 classes, so that a contiguous set of characters can be written as a
342 range.  With ranges, the unwieldy C<[0123456789]> and C<[abc...xyz]>
343 become the svelte C<[0-9]> and C<[a-z]>.  Some examples are
344
345     /item[0-9]/;  # matches 'item0' or ... or 'item9'
346     /[0-9bx-z]aa/;  # matches '0aa', ..., '9aa',
347                     # 'baa', 'xaa', 'yaa', or 'zaa'
348     /[0-9a-fA-F]/;  # matches a hexadecimal digit
349     /[0-9a-zA-Z_]/; # matches a "word" character,
350                     # like those in a Perl variable name
351
352 If C<'-'> is the first or last character in a character class, it is
353 treated as an ordinary character; C<[-ab]>, C<[ab-]> and C<[a\-b]> are
354 all equivalent.
355
356 The special character C<^> in the first position of a character class
357 denotes a I<negated character class>, which matches any character but
358 those in the brackets.  Both C<[...]> and C<[^...]> must match a
359 character, or the match fails.  Then
360
361     /[^a]at/;  # doesn't match 'aat' or 'at', but matches
362                # all other 'bat', 'cat, '0at', '%at', etc.
363     /[^0-9]/;  # matches a non-numeric character
364     /[a^]at/;  # matches 'aat' or '^at'; here '^' is ordinary
365
366 Now, even C<[0-9]> can be a bother to write multiple times, so in the
367 interest of saving keystrokes and making regexps more readable, Perl
368 has several abbreviations for common character classes, as shown below.
369 Since the introduction of Unicode, these character classes match more
370 than just a few characters in the ISO 8859-1 range.
371
372 =over 4
373
374 =item *
375
376 \d matches a digit, not just [0-9] but also digits from non-roman scripts
377
378 =item *
379
380 \s matches a whitespace character, the set [\ \t\r\n\f] and others
381
382 =item *
383
384 \w matches a word character (alphanumeric or _), not just [0-9a-zA-Z_]
385 but also digits and characters from non-roman scripts
386
387 =item *
388
389 \D is a negated \d; it represents any other character than a digit, or [^\d]
390
391 =item *
392
393 \S is a negated \s; it represents any non-whitespace character [^\s]
394
395 =item *
396
397 \W is a negated \w; it represents any non-word character [^\w]
398
399 =item *
400
401 The period '.' matches any character but "\n" (unless the modifier C<//s> is
402 in effect, as explained below).
403
404 =back
405
406 The C<\d\s\w\D\S\W> abbreviations can be used both inside and outside
407 of character classes.  Here are some in use:
408
409     /\d\d:\d\d:\d\d/; # matches a hh:mm:ss time format
410     /[\d\s]/;         # matches any digit or whitespace character
411     /\w\W\w/;         # matches a word char, followed by a
412                       # non-word char, followed by a word char
413     /..rt/;           # matches any two chars, followed by 'rt'
414     /end\./;          # matches 'end.'
415     /end[.]/;         # same thing, matches 'end.'
416
417 Because a period is a metacharacter, it needs to be escaped to match
418 as an ordinary period. Because, for example, C<\d> and C<\w> are sets
419 of characters, it is incorrect to think of C<[^\d\w]> as C<[\D\W]>; in
420 fact C<[^\d\w]> is the same as C<[^\w]>, which is the same as
421 C<[\W]>. Think DeMorgan's laws.
422
423 An anchor useful in basic regexps is the I<word anchor>
424 C<\b>.  This matches a boundary between a word character and a non-word
425 character C<\w\W> or C<\W\w>:
426
427     $x = "Housecat catenates house and cat";
428     $x =~ /cat/;    # matches cat in 'housecat'
429     $x =~ /\bcat/;  # matches cat in 'catenates'
430     $x =~ /cat\b/;  # matches cat in 'housecat'
431     $x =~ /\bcat\b/;  # matches 'cat' at end of string
432
433 Note in the last example, the end of the string is considered a word
434 boundary.
435
436 You might wonder why C<'.'> matches everything but C<"\n"> - why not
437 every character? The reason is that often one is matching against
438 lines and would like to ignore the newline characters.  For instance,
439 while the string C<"\n"> represents one line, we would like to think
440 of it as empty.  Then
441
442     ""   =~ /^$/;    # matches
443     "\n" =~ /^$/;    # matches, $ anchors before "\n"
444
445     ""   =~ /./;      # doesn't match; it needs a char
446     ""   =~ /^.$/;    # doesn't match; it needs a char
447     "\n" =~ /^.$/;    # doesn't match; it needs a char other than "\n"
448     "a"  =~ /^.$/;    # matches
449     "a\n"  =~ /^.$/;  # matches, $ anchors before "\n"
450
451 This behavior is convenient, because we usually want to ignore
452 newlines when we count and match characters in a line.  Sometimes,
453 however, we want to keep track of newlines.  We might even want C<^>
454 and C<$> to anchor at the beginning and end of lines within the
455 string, rather than just the beginning and end of the string.  Perl
456 allows us to choose between ignoring and paying attention to newlines
457 by using the C<//s> and C<//m> modifiers.  C<//s> and C<//m> stand for
458 single line and multi-line and they determine whether a string is to
459 be treated as one continuous string, or as a set of lines.  The two
460 modifiers affect two aspects of how the regexp is interpreted: 1) how
461 the C<'.'> character class is defined, and 2) where the anchors C<^>
462 and C<$> are able to match.  Here are the four possible combinations:
463
464 =over 4
465
466 =item *
467
468 no modifiers (//): Default behavior.  C<'.'> matches any character
469 except C<"\n">.  C<^> matches only at the beginning of the string and
470 C<$> matches only at the end or before a newline at the end.
471
472 =item *
473
474 s modifier (//s): Treat string as a single long line.  C<'.'> matches
475 any character, even C<"\n">.  C<^> matches only at the beginning of
476 the string and C<$> matches only at the end or before a newline at the
477 end.
478
479 =item *
480
481 m modifier (//m): Treat string as a set of multiple lines.  C<'.'>
482 matches any character except C<"\n">.  C<^> and C<$> are able to match
483 at the start or end of I<any> line within the string.
484
485 =item *
486
487 both s and m modifiers (//sm): Treat string as a single long line, but
488 detect multiple lines.  C<'.'> matches any character, even
489 C<"\n">.  C<^> and C<$>, however, are able to match at the start or end
490 of I<any> line within the string.
491
492 =back
493
494 Here are examples of C<//s> and C<//m> in action:
495
496     $x = "There once was a girl\nWho programmed in Perl\n";
497
498     $x =~ /^Who/;   # doesn't match, "Who" not at start of string
499     $x =~ /^Who/s;  # doesn't match, "Who" not at start of string
500     $x =~ /^Who/m;  # matches, "Who" at start of second line
501     $x =~ /^Who/sm; # matches, "Who" at start of second line
502
503     $x =~ /girl.Who/;   # doesn't match, "." doesn't match "\n"
504     $x =~ /girl.Who/s;  # matches, "." matches "\n"
505     $x =~ /girl.Who/m;  # doesn't match, "." doesn't match "\n"
506     $x =~ /girl.Who/sm; # matches, "." matches "\n"
507
508 Most of the time, the default behavior is what is wanted, but C<//s> and
509 C<//m> are occasionally very useful.  If C<//m> is being used, the start
510 of the string can still be matched with C<\A> and the end of the string
511 can still be matched with the anchors C<\Z> (matches both the end and
512 the newline before, like C<$>), and C<\z> (matches only the end):
513
514     $x =~ /^Who/m;   # matches, "Who" at start of second line
515     $x =~ /\AWho/m;  # doesn't match, "Who" is not at start of string
516
517     $x =~ /girl$/m;  # matches, "girl" at end of first line
518     $x =~ /girl\Z/m; # doesn't match, "girl" is not at end of string
519
520     $x =~ /Perl\Z/m; # matches, "Perl" is at newline before end
521     $x =~ /Perl\z/m; # doesn't match, "Perl" is not at end of string
522
523 We now know how to create choices among classes of characters in a
524 regexp.  What about choices among words or character strings? Such
525 choices are described in the next section.
526
527 =head2 Matching this or that
528
529 Sometimes we would like our regexp to be able to match different
530 possible words or character strings.  This is accomplished by using
531 the I<alternation> metacharacter C<|>.  To match C<dog> or C<cat>, we
532 form the regexp C<dog|cat>.  As before, Perl will try to match the
533 regexp at the earliest possible point in the string.  At each
534 character position, Perl will first try to match the first
535 alternative, C<dog>.  If C<dog> doesn't match, Perl will then try the
536 next alternative, C<cat>.  If C<cat> doesn't match either, then the
537 match fails and Perl moves to the next position in the string.  Some
538 examples:
539
540     "cats and dogs" =~ /cat|dog|bird/;  # matches "cat"
541     "cats and dogs" =~ /dog|cat|bird/;  # matches "cat"
542
543 Even though C<dog> is the first alternative in the second regexp,
544 C<cat> is able to match earlier in the string.
545
546     "cats"          =~ /c|ca|cat|cats/; # matches "c"
547     "cats"          =~ /cats|cat|ca|c/; # matches "cats"
548
549 Here, all the alternatives match at the first string position, so the
550 first alternative is the one that matches.  If some of the
551 alternatives are truncations of the others, put the longest ones first
552 to give them a chance to match.
553
554     "cab" =~ /a|b|c/ # matches "c"
555                      # /a|b|c/ == /[abc]/
556
557 The last example points out that character classes are like
558 alternations of characters.  At a given character position, the first
559 alternative that allows the regexp match to succeed will be the one
560 that matches.
561
562 =head2 Grouping things and hierarchical matching
563
564 Alternation allows a regexp to choose among alternatives, but by
565 itself it is unsatisfying.  The reason is that each alternative is a whole
566 regexp, but sometime we want alternatives for just part of a
567 regexp.  For instance, suppose we want to search for housecats or
568 housekeepers.  The regexp C<housecat|housekeeper> fits the bill, but is
569 inefficient because we had to type C<house> twice.  It would be nice to
570 have parts of the regexp be constant, like C<house>, and some
571 parts have alternatives, like C<cat|keeper>.
572
573 The I<grouping> metacharacters C<()> solve this problem.  Grouping
574 allows parts of a regexp to be treated as a single unit.  Parts of a
575 regexp are grouped by enclosing them in parentheses.  Thus we could solve
576 the C<housecat|housekeeper> by forming the regexp as
577 C<house(cat|keeper)>.  The regexp C<house(cat|keeper)> means match
578 C<house> followed by either C<cat> or C<keeper>.  Some more examples
579 are
580
581     /(a|b)b/;    # matches 'ab' or 'bb'
582     /(ac|b)b/;   # matches 'acb' or 'bb'
583     /(^a|b)c/;   # matches 'ac' at start of string or 'bc' anywhere
584     /(a|[bc])d/; # matches 'ad', 'bd', or 'cd'
585
586     /house(cat|)/;  # matches either 'housecat' or 'house'
587     /house(cat(s|)|)/;  # matches either 'housecats' or 'housecat' or
588                         # 'house'.  Note groups can be nested.
589
590     /(19|20|)\d\d/;  # match years 19xx, 20xx, or the Y2K problem, xx
591     "20" =~ /(19|20|)\d\d/;  # matches the null alternative '()\d\d',
592                              # because '20\d\d' can't match
593
594 Alternations behave the same way in groups as out of them: at a given
595 string position, the leftmost alternative that allows the regexp to
596 match is taken.  So in the last example at the first string position,
597 C<"20"> matches the second alternative, but there is nothing left over
598 to match the next two digits C<\d\d>.  So Perl moves on to the next
599 alternative, which is the null alternative and that works, since
600 C<"20"> is two digits.
601
602 The process of trying one alternative, seeing if it matches, and
603 moving on to the next alternative, while going back in the string
604 from where the previous alternative was tried, if it doesn't, is called
605 I<backtracking>.  The term 'backtracking' comes from the idea that
606 matching a regexp is like a walk in the woods.  Successfully matching
607 a regexp is like arriving at a destination.  There are many possible
608 trailheads, one for each string position, and each one is tried in
609 order, left to right.  From each trailhead there may be many paths,
610 some of which get you there, and some which are dead ends.  When you
611 walk along a trail and hit a dead end, you have to backtrack along the
612 trail to an earlier point to try another trail.  If you hit your
613 destination, you stop immediately and forget about trying all the
614 other trails.  You are persistent, and only if you have tried all the
615 trails from all the trailheads and not arrived at your destination, do
616 you declare failure.  To be concrete, here is a step-by-step analysis
617 of what Perl does when it tries to match the regexp
618
619     "abcde" =~ /(abd|abc)(df|d|de)/;
620
621 =over 4
622
623 =item 0
624
625 Start with the first letter in the string 'a'.
626
627 =item 1
628
629 Try the first alternative in the first group 'abd'.
630
631 =item 2
632
633 Match 'a' followed by 'b'. So far so good.
634
635 =item 3
636
637 'd' in the regexp doesn't match 'c' in the string - a dead
638 end.  So backtrack two characters and pick the second alternative in
639 the first group 'abc'.
640
641 =item 4
642
643 Match 'a' followed by 'b' followed by 'c'.  We are on a roll
644 and have satisfied the first group. Set $1 to 'abc'.
645
646 =item 5
647
648 Move on to the second group and pick the first alternative
649 'df'.
650
651 =item 6
652
653 Match the 'd'.
654
655 =item 7
656
657 'f' in the regexp doesn't match 'e' in the string, so a dead
658 end.  Backtrack one character and pick the second alternative in the
659 second group 'd'.
660
661 =item 8
662
663 'd' matches. The second grouping is satisfied, so set $2 to
664 'd'.
665
666 =item 9
667
668 We are at the end of the regexp, so we are done! We have
669 matched 'abcd' out of the string "abcde".
670
671 =back
672
673 There are a couple of things to note about this analysis.  First, the
674 third alternative in the second group 'de' also allows a match, but we
675 stopped before we got to it - at a given character position, leftmost
676 wins.  Second, we were able to get a match at the first character
677 position of the string 'a'.  If there were no matches at the first
678 position, Perl would move to the second character position 'b' and
679 attempt the match all over again.  Only when all possible paths at all
680 possible character positions have been exhausted does Perl give
681 up and declare S<C<$string =~ /(abd|abc)(df|d|de)/;>> to be false.
682
683 Even with all this work, regexp matching happens remarkably fast.  To
684 speed things up, Perl compiles the regexp into a compact sequence of 
685 opcodes that can often fit inside a processor cache.  When the code is 
686 executed, these opcodes can then run at full throttle and search very
687 quickly.
688
689 =head2 Extracting matches
690
691 The grouping metacharacters C<()> also serve another completely
692 different function: they allow the extraction of the parts of a string
693 that matched.  This is very useful to find out what matched and for
694 text processing in general.  For each grouping, the part that matched
695 inside goes into the special variables C<$1>, C<$2>, etc.  They can be
696 used just as ordinary variables:
697
698     # extract hours, minutes, seconds
699     if ($time =~ /(\d\d):(\d\d):(\d\d)/) {    # match hh:mm:ss format
700         $hours = $1;
701         $minutes = $2;
702         $seconds = $3;
703     }
704
705 Now, we know that in scalar context,
706 S<C<$time =~ /(\d\d):(\d\d):(\d\d)/>> returns a true or false
707 value.  In list context, however, it returns the list of matched values
708 C<($1,$2,$3)>.  So we could write the code more compactly as
709
710     # extract hours, minutes, seconds
711     ($hours, $minutes, $second) = ($time =~ /(\d\d):(\d\d):(\d\d)/);
712
713 If the groupings in a regexp are nested, C<$1> gets the group with the
714 leftmost opening parenthesis, C<$2> the next opening parenthesis,
715 etc.  Here is a regexp with nested groups:
716
717     /(ab(cd|ef)((gi)|j))/;
718      1  2      34
719
720 If this regexp matches, C<$1> contains a string starting with
721 C<'ab'>, C<$2> is either set to C<'cd'> or C<'ef'>, C<$3> equals either
722 C<'gi'> or C<'j'>, and C<$4> is either set to C<'gi'>, just like C<$3>,
723 or it remains undefined.
724
725 For convenience, Perl sets C<$+> to the string held by the highest numbered
726 C<$1>, C<$2>,... that got assigned (and, somewhat related, C<$^N> to the
727 value of the C<$1>, C<$2>,... most-recently assigned; i.e. the C<$1>,
728 C<$2>,... associated with the rightmost closing parenthesis used in the
729 match).
730
731
732 =head2 Backreferences
733
734 Closely associated with the matching variables C<$1>, C<$2>, ... are
735 the I<backreferences> C<\1>, C<\2>,...  Backreferences are simply
736 matching variables that can be used I<inside> a regexp.  This is a
737 really nice feature -- what matches later in a regexp is made to depend on
738 what matched earlier in the regexp.  Suppose we wanted to look
739 for doubled words in a text, like 'the the'.  The following regexp finds
740 all 3-letter doubles with a space in between:
741
742     /\b(\w\w\w)\s\1\b/;
743
744 The grouping assigns a value to \1, so that the same 3 letter sequence
745 is used for both parts.
746
747 A similar task is to find words consisting of two identical parts:
748
749     % simple_grep '^(\w\w\w\w|\w\w\w|\w\w|\w)\1$' /usr/dict/words
750     beriberi
751     booboo
752     coco
753     mama
754     murmur
755     papa
756
757 The regexp has a single grouping which considers 4-letter
758 combinations, then 3-letter combinations, etc., and uses C<\1> to look for
759 a repeat.  Although C<$1> and C<\1> represent the same thing, care should be
760 taken to use matched variables C<$1>, C<$2>,... only I<outside> a regexp
761 and backreferences C<\1>, C<\2>,... only I<inside> a regexp; not doing
762 so may lead to surprising and unsatisfactory results.
763
764
765 =head2 Relative backreferences
766
767 Counting the opening parentheses to get the correct number for a
768 backreference is errorprone as soon as there is more than one 
769 capturing group.  A more convenient technique became available
770 with Perl 5.10: relative backreferences. To refer to the immediately
771 preceding capture group one now may write C<\g{-1}>, the next but
772 last is available via C<\g{-2}>, and so on.
773
774 Another good reason in addition to readability and maintainability
775 for using relative backreferences  is illustrated by the following example,
776 where a simple pattern for matching peculiar strings is used:
777
778     $a99a = '([a-z])(\d)\2\1';   # matches a11a, g22g, x33x, etc. 
779
780 Now that we have this pattern stored as a handy string, we might feel
781 tempted to use it as a part of some other pattern:
782
783     $line = "code=e99e";
784     if ($line =~ /^(\w+)=$a99a$/){   # unexpected behavior!
785         print "$1 is valid\n";
786     } else {
787         print "bad line: '$line'\n";
788     }
789
790 But this doesn't match -- at least not the way one might expect. Only
791 after inserting the interpolated C<$a99a> and looking at the resulting
792 full text of the regexp is it obvious that the backreferences have
793 backfired -- the subexpression C<(\w+)> has snatched number 1 and
794 demoted the groups in C<$a99a> by one rank. This can be avoided by
795 using relative backreferences:
796
797     $a99a = '([a-z])(\d)\g{-1}\g{-2}';  # safe for being interpolated
798
799
800 =head2 Named backreferences
801
802 Perl 5.10 also introduced named capture buffers and named backreferences.
803 To attach a name to a capturing group, you write either
804 C<< (?<name>...) >> or C<< (?'name'...) >>.  The backreference may
805 then be written as C<\g{name}>.  It is permissible to attach the
806 same name to more than one group, but then only the leftmost one of the
807 eponymous set can be referenced.  Outside of the pattern a named
808 capture buffer is accessible through the C<%+> hash.
809
810 Assuming that we have to match calendar dates which may be given in one 
811 of the three formats yyyy-mm-dd, mm/dd/yyyy or dd.mm.yyyy, we can write
812 three suitable patterns where we use 'd', 'm' and 'y' respectively as the 
813 names of the buffers capturing the pertaining components of a date. The
814 matching operation combines the three patterns as alternatives:
815
816     $fmt1 = '(?<y>\d\d\d\d)-(?<m>\d\d)-(?<d>\d\d)';
817     $fmt2 = '(?<m>\d\d)/(?<d>\d\d)/(?<y>\d\d\d\d)';
818     $fmt3 = '(?<d>\d\d)\.(?<m>\d\d)\.(?<y>\d\d\d\d)';
819     for my $d qw( 2006-10-21 15.01.2007 10/31/2005 ){
820         if ( $d =~ m{$fmt1|$fmt2|$fmt3} ){
821             print "day=$+{d} month=$+{m} year=$+{y}\n";
822         }
823     }
824
825 If any of the alternatives matches, the hash C<%+> is bound to contain the
826 three key-value pairs.
827
828
829 =head2 Alternative capture group numbering
830
831 Yet another capturing group numbering technique (also as from Perl 5.10)
832 deals with the problem of referring to groups within a set of alternatives.
833 Consider a pattern for matching a time of the day, civil or military style:
834
835     if ( $time =~ /(\d\d|\d):(\d\d)|(\d\d)(\d\d)/ ){
836         # process hour and minute
837     }
838
839 Processing the results requires an additional if statement to determine
840 whether C<$1> and C<$2> or C<$3> and C<$4> contain the goodies. It would 
841 be easier if we could use buffer numbers 1 and 2 in second alternative as
842 well, and this is exactly what the parenthesized construct C<(?|...)>, 
843 set around an alternative achieves. Here is an extended version of the
844 previous pattern:
845
846     if ( $time =~ /(?|(\d\d|\d):(\d\d)|(\d\d)(\d\d))\s+([A-Z][A-Z][A-Z])/ ){
847         print "hour=$1 minute=$2 zone=$3\n";
848     }
849
850 Within the alternative numbering group, buffer numbers start at the same
851 position for each alternative. After the group, numbering continues
852 with one higher than the maximum reached across all the alteratives.
853
854
855 =head2 Position information
856
857 In addition to what was matched, Perl (since 5.6.0) also provides the
858 positions of what was matched as contents of the C<@-> and C<@+>
859 arrays. C<$-[0]> is the position of the start of the entire match and
860 C<$+[0]> is the position of the end. Similarly, C<$-[n]> is the
861 position of the start of the C<$n> match and C<$+[n]> is the position
862 of the end. If C<$n> is undefined, so are C<$-[n]> and C<$+[n]>. Then
863 this code
864
865     $x = "Mmm...donut, thought Homer";
866     $x =~ /^(Mmm|Yech)\.\.\.(donut|peas)/; # matches
867     foreach $expr (1..$#-) {
868         print "Match $expr: '${$expr}' at position ($-[$expr],$+[$expr])\n";
869     }
870
871 prints
872
873     Match 1: 'Mmm' at position (0,3)
874     Match 2: 'donut' at position (6,11)
875
876 Even if there are no groupings in a regexp, it is still possible to
877 find out what exactly matched in a string.  If you use them, Perl
878 will set C<$`> to the part of the string before the match, will set C<$&>
879 to the part of the string that matched, and will set C<$'> to the part
880 of the string after the match.  An example:
881
882     $x = "the cat caught the mouse";
883     $x =~ /cat/;  # $` = 'the ', $& = 'cat', $' = ' caught the mouse'
884     $x =~ /the/;  # $` = '', $& = 'the', $' = ' cat caught the mouse'
885
886 In the second match, C<$`> equals C<''> because the regexp matched at the
887 first character position in the string and stopped; it never saw the
888 second 'the'.  It is important to note that using C<$`> and C<$'>
889 slows down regexp matching quite a bit, while C<$&> slows it down to a
890 lesser extent, because if they are used in one regexp in a program,
891 they are generated for I<all> regexps in the program.  So if raw
892 performance is a goal of your application, they should be avoided.
893 If you need to extract the corresponding substrings, use C<@-> and
894 C<@+> instead:
895
896     $` is the same as substr( $x, 0, $-[0] )
897     $& is the same as substr( $x, $-[0], $+[0]-$-[0] )
898     $' is the same as substr( $x, $+[0] )
899
900
901 =head2 Non-capturing groupings
902
903 A group that is required to bundle a set of alternatives may or may not be 
904 useful as a capturing group.  If it isn't, it just creates a superfluous
905 addition to the set of available capture buffer values, inside as well as
906 outside the regexp.  Non-capturing groupings, denoted by C<(?:regexp)>,
907 still allow the regexp to be treated as a single unit, but don't establish 
908 a capturing buffer at the same time.  Both capturing and non-capturing
909 groupings are allowed to co-exist in the same regexp.  Because there is
910 no extraction, non-capturing groupings are faster than capturing
911 groupings.  Non-capturing groupings are also handy for choosing exactly
912 which parts of a regexp are to be extracted to matching variables:
913
914     # match a number, $1-$4 are set, but we only want $1
915     /([+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?)/;
916
917     # match a number faster , only $1 is set
918     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE][+-]?\d+)?)/;
919
920     # match a number, get $1 = whole number, $2 = exponent
921     /([+-]?\ *(?:\d+(?:\.\d*)?|\.\d+)(?:[eE]([+-]?\d+))?)/;
922
923 Non-capturing groupings are also useful for removing nuisance
924 elements gathered from a split operation where parentheses are
925 required for some reason:
926
927     $x = '12aba34ba5';
928     @num = split /(a|b)+/, $x;    # @num = ('12','a','34','b','5')
929     @num = split /(?:a|b)+/, $x;  # @num = ('12','34','5')
930
931
932 =head2 Matching repetitions
933
934 The examples in the previous section display an annoying weakness.  We
935 were only matching 3-letter words, or chunks of words of 4 letters or
936 less.  We'd like to be able to match words or, more generally, strings
937 of any length, without writing out tedious alternatives like
938 C<\w\w\w\w|\w\w\w|\w\w|\w>.
939
940 This is exactly the problem the I<quantifier> metacharacters C<?>,
941 C<*>, C<+>, and C<{}> were created for.  They allow us to delimit the
942 number of repeats for a portion of a regexp we consider to be a
943 match.  Quantifiers are put immediately after the character, character
944 class, or grouping that we want to specify.  They have the following
945 meanings:
946
947 =over 4
948
949 =item *
950
951 C<a?> means: match 'a' 1 or 0 times
952
953 =item *
954
955 C<a*> means: match 'a' 0 or more times, i.e., any number of times
956
957 =item *
958
959 C<a+> means: match 'a' 1 or more times, i.e., at least once
960
961 =item *
962
963 C<a{n,m}> means: match at least C<n> times, but not more than C<m>
964 times.
965
966 =item *
967
968 C<a{n,}> means: match at least C<n> or more times
969
970 =item *
971
972 C<a{n}> means: match exactly C<n> times
973
974 =back
975
976 Here are some examples:
977
978     /[a-z]+\s+\d*/;  # match a lowercase word, at least one space, and
979                      # any number of digits
980     /(\w+)\s+\1/;    # match doubled words of arbitrary length
981     /y(es)?/i;       # matches 'y', 'Y', or a case-insensitive 'yes'
982     $year =~ /\d{2,4}/;  # make sure year is at least 2 but not more
983                          # than 4 digits
984     $year =~ /\d{4}|\d{2}/;    # better match; throw out 3 digit dates
985     $year =~ /\d{2}(\d{2})?/;  # same thing written differently. However,
986                                # this produces $1 and the other does not.
987
988     % simple_grep '^(\w+)\1$' /usr/dict/words   # isn't this easier?
989     beriberi
990     booboo
991     coco
992     mama
993     murmur
994     papa
995
996 For all of these quantifiers, Perl will try to match as much of the
997 string as possible, while still allowing the regexp to succeed.  Thus
998 with C</a?.../>, Perl will first try to match the regexp with the C<a>
999 present; if that fails, Perl will try to match the regexp without the
1000 C<a> present.  For the quantifier C<*>, we get the following:
1001
1002     $x = "the cat in the hat";
1003     $x =~ /^(.*)(cat)(.*)$/; # matches,
1004                              # $1 = 'the '
1005                              # $2 = 'cat'
1006                              # $3 = ' in the hat'
1007
1008 Which is what we might expect, the match finds the only C<cat> in the
1009 string and locks onto it.  Consider, however, this regexp:
1010
1011     $x =~ /^(.*)(at)(.*)$/; # matches,
1012                             # $1 = 'the cat in the h'
1013                             # $2 = 'at'
1014                             # $3 = ''   (0 characters match)
1015
1016 One might initially guess that Perl would find the C<at> in C<cat> and
1017 stop there, but that wouldn't give the longest possible string to the
1018 first quantifier C<.*>.  Instead, the first quantifier C<.*> grabs as
1019 much of the string as possible while still having the regexp match.  In
1020 this example, that means having the C<at> sequence with the final C<at>
1021 in the string.  The other important principle illustrated here is that
1022 when there are two or more elements in a regexp, the I<leftmost>
1023 quantifier, if there is one, gets to grab as much the string as
1024 possible, leaving the rest of the regexp to fight over scraps.  Thus in
1025 our example, the first quantifier C<.*> grabs most of the string, while
1026 the second quantifier C<.*> gets the empty string.   Quantifiers that
1027 grab as much of the string as possible are called I<maximal match> or
1028 I<greedy> quantifiers.
1029
1030 When a regexp can match a string in several different ways, we can use
1031 the principles above to predict which way the regexp will match:
1032
1033 =over 4
1034
1035 =item *
1036
1037 Principle 0: Taken as a whole, any regexp will be matched at the
1038 earliest possible position in the string.
1039
1040 =item *
1041
1042 Principle 1: In an alternation C<a|b|c...>, the leftmost alternative
1043 that allows a match for the whole regexp will be the one used.
1044
1045 =item *
1046
1047 Principle 2: The maximal matching quantifiers C<?>, C<*>, C<+> and
1048 C<{n,m}> will in general match as much of the string as possible while
1049 still allowing the whole regexp to match.
1050
1051 =item *
1052
1053 Principle 3: If there are two or more elements in a regexp, the
1054 leftmost greedy quantifier, if any, will match as much of the string
1055 as possible while still allowing the whole regexp to match.  The next
1056 leftmost greedy quantifier, if any, will try to match as much of the
1057 string remaining available to it as possible, while still allowing the
1058 whole regexp to match.  And so on, until all the regexp elements are
1059 satisfied.
1060
1061 =back
1062
1063 As we have seen above, Principle 0 overrides the others -- the regexp
1064 will be matched as early as possible, with the other principles
1065 determining how the regexp matches at that earliest character
1066 position.
1067
1068 Here is an example of these principles in action:
1069
1070     $x = "The programming republic of Perl";
1071     $x =~ /^(.+)(e|r)(.*)$/;  # matches,
1072                               # $1 = 'The programming republic of Pe'
1073                               # $2 = 'r'
1074                               # $3 = 'l'
1075
1076 This regexp matches at the earliest string position, C<'T'>.  One
1077 might think that C<e>, being leftmost in the alternation, would be
1078 matched, but C<r> produces the longest string in the first quantifier.
1079
1080     $x =~ /(m{1,2})(.*)$/;  # matches,
1081                             # $1 = 'mm'
1082                             # $2 = 'ing republic of Perl'
1083
1084 Here, The earliest possible match is at the first C<'m'> in
1085 C<programming>. C<m{1,2}> is the first quantifier, so it gets to match
1086 a maximal C<mm>.
1087
1088     $x =~ /.*(m{1,2})(.*)$/;  # matches,
1089                               # $1 = 'm'
1090                               # $2 = 'ing republic of Perl'
1091
1092 Here, the regexp matches at the start of the string. The first
1093 quantifier C<.*> grabs as much as possible, leaving just a single
1094 C<'m'> for the second quantifier C<m{1,2}>.
1095
1096     $x =~ /(.?)(m{1,2})(.*)$/;  # matches,
1097                                 # $1 = 'a'
1098                                 # $2 = 'mm'
1099                                 # $3 = 'ing republic of Perl'
1100
1101 Here, C<.?> eats its maximal one character at the earliest possible
1102 position in the string, C<'a'> in C<programming>, leaving C<m{1,2}>
1103 the opportunity to match both C<m>'s. Finally,
1104
1105     "aXXXb" =~ /(X*)/; # matches with $1 = ''
1106
1107 because it can match zero copies of C<'X'> at the beginning of the
1108 string.  If you definitely want to match at least one C<'X'>, use
1109 C<X+>, not C<X*>.
1110
1111 Sometimes greed is not good.  At times, we would like quantifiers to
1112 match a I<minimal> piece of string, rather than a maximal piece.  For
1113 this purpose, Larry Wall created the I<minimal match> or
1114 I<non-greedy> quantifiers C<??>, C<*?>, C<+?>, and C<{}?>.  These are
1115 the usual quantifiers with a C<?> appended to them.  They have the
1116 following meanings:
1117
1118 =over 4
1119
1120 =item *
1121
1122 C<a??> means: match 'a' 0 or 1 times. Try 0 first, then 1.
1123
1124 =item *
1125
1126 C<a*?> means: match 'a' 0 or more times, i.e., any number of times,
1127 but as few times as possible
1128
1129 =item *
1130
1131 C<a+?> means: match 'a' 1 or more times, i.e., at least once, but
1132 as few times as possible
1133
1134 =item *
1135
1136 C<a{n,m}?> means: match at least C<n> times, not more than C<m>
1137 times, as few times as possible
1138
1139 =item *
1140
1141 C<a{n,}?> means: match at least C<n> times, but as few times as
1142 possible
1143
1144 =item *
1145
1146 C<a{n}?> means: match exactly C<n> times.  Because we match exactly
1147 C<n> times, C<a{n}?> is equivalent to C<a{n}> and is just there for
1148 notational consistency.
1149
1150 =back
1151
1152 Let's look at the example above, but with minimal quantifiers:
1153
1154     $x = "The programming republic of Perl";
1155     $x =~ /^(.+?)(e|r)(.*)$/; # matches,
1156                               # $1 = 'Th'
1157                               # $2 = 'e'
1158                               # $3 = ' programming republic of Perl'
1159
1160 The minimal string that will allow both the start of the string C<^>
1161 and the alternation to match is C<Th>, with the alternation C<e|r>
1162 matching C<e>.  The second quantifier C<.*> is free to gobble up the
1163 rest of the string.
1164
1165     $x =~ /(m{1,2}?)(.*?)$/;  # matches,
1166                               # $1 = 'm'
1167                               # $2 = 'ming republic of Perl'
1168
1169 The first string position that this regexp can match is at the first
1170 C<'m'> in C<programming>. At this position, the minimal C<m{1,2}?>
1171 matches just one C<'m'>.  Although the second quantifier C<.*?> would
1172 prefer to match no characters, it is constrained by the end-of-string
1173 anchor C<$> to match the rest of the string.
1174
1175     $x =~ /(.*?)(m{1,2}?)(.*)$/;  # matches,
1176                                   # $1 = 'The progra'
1177                                   # $2 = 'm'
1178                                   # $3 = 'ming republic of Perl'
1179
1180 In this regexp, you might expect the first minimal quantifier C<.*?>
1181 to match the empty string, because it is not constrained by a C<^>
1182 anchor to match the beginning of the word.  Principle 0 applies here,
1183 however.  Because it is possible for the whole regexp to match at the
1184 start of the string, it I<will> match at the start of the string.  Thus
1185 the first quantifier has to match everything up to the first C<m>.  The
1186 second minimal quantifier matches just one C<m> and the third
1187 quantifier matches the rest of the string.
1188
1189     $x =~ /(.??)(m{1,2})(.*)$/;  # matches,
1190                                  # $1 = 'a'
1191                                  # $2 = 'mm'
1192                                  # $3 = 'ing republic of Perl'
1193
1194 Just as in the previous regexp, the first quantifier C<.??> can match
1195 earliest at position C<'a'>, so it does.  The second quantifier is
1196 greedy, so it matches C<mm>, and the third matches the rest of the
1197 string.
1198
1199 We can modify principle 3 above to take into account non-greedy
1200 quantifiers:
1201
1202 =over 4
1203
1204 =item *
1205
1206 Principle 3: If there are two or more elements in a regexp, the
1207 leftmost greedy (non-greedy) quantifier, if any, will match as much
1208 (little) of the string as possible while still allowing the whole
1209 regexp to match.  The next leftmost greedy (non-greedy) quantifier, if
1210 any, will try to match as much (little) of the string remaining
1211 available to it as possible, while still allowing the whole regexp to
1212 match.  And so on, until all the regexp elements are satisfied.
1213
1214 =back
1215
1216 Just like alternation, quantifiers are also susceptible to
1217 backtracking.  Here is a step-by-step analysis of the example
1218
1219     $x = "the cat in the hat";
1220     $x =~ /^(.*)(at)(.*)$/; # matches,
1221                             # $1 = 'the cat in the h'
1222                             # $2 = 'at'
1223                             # $3 = ''   (0 matches)
1224
1225 =over 4
1226
1227 =item 0
1228
1229 Start with the first letter in the string 't'.
1230
1231 =item 1
1232
1233 The first quantifier '.*' starts out by matching the whole
1234 string 'the cat in the hat'.
1235
1236 =item 2
1237
1238 'a' in the regexp element 'at' doesn't match the end of the
1239 string.  Backtrack one character.
1240
1241 =item 3
1242
1243 'a' in the regexp element 'at' still doesn't match the last
1244 letter of the string 't', so backtrack one more character.
1245
1246 =item 4
1247
1248 Now we can match the 'a' and the 't'.
1249
1250 =item 5
1251
1252 Move on to the third element '.*'.  Since we are at the end of
1253 the string and '.*' can match 0 times, assign it the empty string.
1254
1255 =item 6
1256
1257 We are done!
1258
1259 =back
1260
1261 Most of the time, all this moving forward and backtracking happens
1262 quickly and searching is fast. There are some pathological regexps,
1263 however, whose execution time exponentially grows with the size of the
1264 string.  A typical structure that blows up in your face is of the form
1265
1266     /(a|b+)*/;
1267
1268 The problem is the nested indeterminate quantifiers.  There are many
1269 different ways of partitioning a string of length n between the C<+>
1270 and C<*>: one repetition with C<b+> of length n, two repetitions with
1271 the first C<b+> length k and the second with length n-k, m repetitions
1272 whose bits add up to length n, etc.  In fact there are an exponential
1273 number of ways to partition a string as a function of its length.  A
1274 regexp may get lucky and match early in the process, but if there is
1275 no match, Perl will try I<every> possibility before giving up.  So be
1276 careful with nested C<*>'s, C<{n,m}>'s, and C<+>'s.  The book
1277 I<Mastering Regular Expressions> by Jeffrey Friedl gives a wonderful
1278 discussion of this and other efficiency issues.
1279
1280
1281 =head2 Possessive quantifiers
1282
1283 Backtracking during the relentless search for a match may be a waste
1284 of time, particularly when the match is bound to fail.  Consider
1285 the simple pattern
1286
1287     /^\w+\s+\w+$/; # a word, spaces, a word
1288
1289 Whenever this is applied to a string which doesn't quite meet the
1290 pattern's expectations such as S<C<"abc  ">> or S<C<"abc  def ">>,
1291 the regex engine will backtrack, approximately once for each character 
1292 in the string.  But we know that there is no way around taking I<all> 
1293 of the inital word characters to match the first repetition, that I<all> 
1294 spaces must be eaten by the middle part, and the same goes for the second
1295 word.  With the introduction of the I<possessive quantifiers> in 
1296 Perl 5.10 we have a way of instructing the regexp engine not to backtrack, 
1297 with the usual quantifiers with a C<+> appended to them.  This makes them 
1298 greedy as well as stingy; once they succeed they won't give anything back
1299 to permit another solution. They have the following meanings:
1300
1301 =over 4
1302
1303 =item *
1304
1305 C<a{n,m}+> means: match at least C<n> times, not more than C<m> times, 
1306 as many times as possible, and don't give anything up. C<a?+> is short 
1307 for C<a{0,1}+>
1308
1309 =item *
1310
1311 C<a{n,}+> means: match at least C<n> times, but as many times as possible,
1312 and don't give anything up. C<a*+> is short for C<a{0,}+> and C<a++> is 
1313 short for C<a{1,}+>.
1314
1315 =item *
1316
1317 C<a{n}+> means: match exactly C<n> times.  It is just there for
1318 notational consistency.
1319
1320 =back
1321
1322 These possessive quantifiers represent a special case of a more general 
1323 concept, the I<independent subexpression>, see below. 
1324
1325 As an example where a possessive quantifier is suitable we consider
1326 matching a quoted string, as it appears in several programming languages.
1327 The backslash is used as an escape character that indicates that the
1328 next character is to be taken literally, as another character for the
1329 string.  Therefore, after the opening quote, we expect a (possibly
1330 empty) sequence of alternatives: either some character except an 
1331 unescaped quote or backslash or an escaped character.
1332
1333     /"(?:[^"\\]++|\\.)*+"/;
1334
1335
1336 =head2 Building a regexp
1337
1338 At this point, we have all the basic regexp concepts covered, so let's
1339 give a more involved example of a regular expression.  We will build a
1340 regexp that matches numbers.
1341
1342 The first task in building a regexp is to decide what we want to match
1343 and what we want to exclude.  In our case, we want to match both
1344 integers and floating point numbers and we want to reject any string
1345 that isn't a number.
1346
1347 The next task is to break the problem down into smaller problems that
1348 are easily converted into a regexp.
1349
1350 The simplest case is integers.  These consist of a sequence of digits,
1351 with an optional sign in front.  The digits we can represent with
1352 C<\d+> and the sign can be matched with C<[+-]>.  Thus the integer
1353 regexp is
1354
1355     /[+-]?\d+/;  # matches integers
1356
1357 A floating point number potentially has a sign, an integral part, a
1358 decimal point, a fractional part, and an exponent.  One or more of these
1359 parts is optional, so we need to check out the different
1360 possibilities.  Floating point numbers which are in proper form include
1361 123., 0.345, .34, -1e6, and 25.4E-72.  As with integers, the sign out
1362 front is completely optional and can be matched by C<[+-]?>.  We can
1363 see that if there is no exponent, floating point numbers must have a
1364 decimal point, otherwise they are integers.  We might be tempted to
1365 model these with C<\d*\.\d*>, but this would also match just a single
1366 decimal point, which is not a number.  So the three cases of floating
1367 point number without exponent are
1368
1369    /[+-]?\d+\./;  # 1., 321., etc.
1370    /[+-]?\.\d+/;  # .1, .234, etc.
1371    /[+-]?\d+\.\d+/;  # 1.0, 30.56, etc.
1372
1373 These can be combined into a single regexp with a three-way alternation:
1374
1375    /[+-]?(\d+\.\d+|\d+\.|\.\d+)/;  # floating point, no exponent
1376
1377 In this alternation, it is important to put C<'\d+\.\d+'> before
1378 C<'\d+\.'>.  If C<'\d+\.'> were first, the regexp would happily match that
1379 and ignore the fractional part of the number.
1380
1381 Now consider floating point numbers with exponents.  The key
1382 observation here is that I<both> integers and numbers with decimal
1383 points are allowed in front of an exponent.  Then exponents, like the
1384 overall sign, are independent of whether we are matching numbers with
1385 or without decimal points, and can be 'decoupled' from the
1386 mantissa.  The overall form of the regexp now becomes clear:
1387
1388     /^(optional sign)(integer | f.p. mantissa)(optional exponent)$/;
1389
1390 The exponent is an C<e> or C<E>, followed by an integer.  So the
1391 exponent regexp is
1392
1393    /[eE][+-]?\d+/;  # exponent
1394
1395 Putting all the parts together, we get a regexp that matches numbers:
1396
1397    /^[+-]?(\d+\.\d+|\d+\.|\.\d+|\d+)([eE][+-]?\d+)?$/;  # Ta da!
1398
1399 Long regexps like this may impress your friends, but can be hard to
1400 decipher.  In complex situations like this, the C<//x> modifier for a
1401 match is invaluable.  It allows one to put nearly arbitrary whitespace
1402 and comments into a regexp without affecting their meaning.  Using it,
1403 we can rewrite our 'extended' regexp in the more pleasing form
1404
1405    /^
1406       [+-]?         # first, match an optional sign
1407       (             # then match integers or f.p. mantissas:
1408           \d+\.\d+  # mantissa of the form a.b
1409          |\d+\.     # mantissa of the form a.
1410          |\.\d+     # mantissa of the form .b
1411          |\d+       # integer of the form a
1412       )
1413       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1414    $/x;
1415
1416 If whitespace is mostly irrelevant, how does one include space
1417 characters in an extended regexp? The answer is to backslash it
1418 S<C<'\ '>> or put it in a character class S<C<[ ]>>.  The same thing
1419 goes for pound signs, use C<\#> or C<[#]>.  For instance, Perl allows
1420 a space between the sign and the mantissa or integer, and we could add
1421 this to our regexp as follows:
1422
1423    /^
1424       [+-]?\ *      # first, match an optional sign *and space*
1425       (             # then match integers or f.p. mantissas:
1426           \d+\.\d+  # mantissa of the form a.b
1427          |\d+\.     # mantissa of the form a.
1428          |\.\d+     # mantissa of the form .b
1429          |\d+       # integer of the form a
1430       )
1431       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1432    $/x;
1433
1434 In this form, it is easier to see a way to simplify the
1435 alternation.  Alternatives 1, 2, and 4 all start with C<\d+>, so it
1436 could be factored out:
1437
1438    /^
1439       [+-]?\ *      # first, match an optional sign
1440       (             # then match integers or f.p. mantissas:
1441           \d+       # start out with a ...
1442           (
1443               \.\d* # mantissa of the form a.b or a.
1444           )?        # ? takes care of integers of the form a
1445          |\.\d+     # mantissa of the form .b
1446       )
1447       ([eE][+-]?\d+)?  # finally, optionally match an exponent
1448    $/x;
1449
1450 or written in the compact form,
1451
1452     /^[+-]?\ *(\d+(\.\d*)?|\.\d+)([eE][+-]?\d+)?$/;
1453
1454 This is our final regexp.  To recap, we built a regexp by
1455
1456 =over 4
1457
1458 =item *
1459
1460 specifying the task in detail,
1461
1462 =item *
1463
1464 breaking down the problem into smaller parts,
1465
1466 =item *
1467
1468 translating the small parts into regexps,
1469
1470 =item *
1471
1472 combining the regexps,
1473
1474 =item *
1475
1476 and optimizing the final combined regexp.
1477
1478 =back
1479
1480 These are also the typical steps involved in writing a computer
1481 program.  This makes perfect sense, because regular expressions are
1482 essentially programs written in a little computer language that specifies
1483 patterns.
1484
1485 =head2 Using regular expressions in Perl
1486
1487 The last topic of Part 1 briefly covers how regexps are used in Perl
1488 programs.  Where do they fit into Perl syntax?
1489
1490 We have already introduced the matching operator in its default
1491 C</regexp/> and arbitrary delimiter C<m!regexp!> forms.  We have used
1492 the binding operator C<=~> and its negation C<!~> to test for string
1493 matches.  Associated with the matching operator, we have discussed the
1494 single line C<//s>, multi-line C<//m>, case-insensitive C<//i> and
1495 extended C<//x> modifiers.  There are a few more things you might 
1496 want to know about matching operators. 
1497
1498 =head3 Optimizing pattern evaluation
1499
1500 We pointed out earlier that variables in regexps are substituted 
1501 before the regexp is evaluated:
1502
1503     $pattern = 'Seuss';
1504     while (<>) {
1505         print if /$pattern/;
1506     }
1507
1508 This will print any lines containing the word C<Seuss>.  It is not as
1509 efficient as it could be, however, because Perl has to re-evaluate
1510 (or compile) C<$pattern> each time through the loop.  If C<$pattern> won't be
1511 changing over the lifetime of the script, we can add the C<//o>
1512 modifier, which directs Perl to only perform variable substitutions
1513 once:
1514
1515     #!/usr/bin/perl
1516     #    Improved simple_grep
1517     $regexp = shift;
1518     while (<>) {
1519         print if /$regexp/o;  # a good deal faster
1520     }
1521
1522
1523 =head3 Prohibiting substitution
1524
1525 If you change C<$pattern> after the first substitution happens, Perl
1526 will ignore it.  If you don't want any substitutions at all, use the
1527 special delimiter C<m''>:
1528
1529     @pattern = ('Seuss');
1530     while (<>) {
1531         print if m'@pattern';  # matches literal '@pattern', not 'Seuss'
1532     }
1533
1534 Similar to strings, C<m''> acts like apostrophes on a regexp; all other 
1535 C<m> delimiters act like quotes.  If the regexp evaluates to the empty string,
1536 the regexp in the I<last successful match> is used instead.  So we have
1537
1538     "dog" =~ /d/;  # 'd' matches
1539     "dogbert =~ //;  # this matches the 'd' regexp used before
1540
1541
1542 =head3 Global matching
1543
1544 The final two modifiers C<//g> and C<//c> concern multiple matches.
1545 The modifier C<//g> stands for global matching and allows the
1546 matching operator to match within a string as many times as possible.
1547 In scalar context, successive invocations against a string will have
1548 `C<//g> jump from match to match, keeping track of position in the
1549 string as it goes along.  You can get or set the position with the
1550 C<pos()> function.
1551
1552 The use of C<//g> is shown in the following example.  Suppose we have
1553 a string that consists of words separated by spaces.  If we know how
1554 many words there are in advance, we could extract the words using
1555 groupings:
1556
1557     $x = "cat dog house"; # 3 words
1558     $x =~ /^\s*(\w+)\s+(\w+)\s+(\w+)\s*$/; # matches,
1559                                            # $1 = 'cat'
1560                                            # $2 = 'dog'
1561                                            # $3 = 'house'
1562
1563 But what if we had an indeterminate number of words? This is the sort
1564 of task C<//g> was made for.  To extract all words, form the simple
1565 regexp C<(\w+)> and loop over all matches with C</(\w+)/g>:
1566
1567     while ($x =~ /(\w+)/g) {
1568         print "Word is $1, ends at position ", pos $x, "\n";
1569     }
1570
1571 prints
1572
1573     Word is cat, ends at position 3
1574     Word is dog, ends at position 7
1575     Word is house, ends at position 13
1576
1577 A failed match or changing the target string resets the position.  If
1578 you don't want the position reset after failure to match, add the
1579 C<//c>, as in C</regexp/gc>.  The current position in the string is
1580 associated with the string, not the regexp.  This means that different
1581 strings have different positions and their respective positions can be
1582 set or read independently.
1583
1584 In list context, C<//g> returns a list of matched groupings, or if
1585 there are no groupings, a list of matches to the whole regexp.  So if
1586 we wanted just the words, we could use
1587
1588     @words = ($x =~ /(\w+)/g);  # matches,
1589                                 # $word[0] = 'cat'
1590                                 # $word[1] = 'dog'
1591                                 # $word[2] = 'house'
1592
1593 Closely associated with the C<//g> modifier is the C<\G> anchor.  The
1594 C<\G> anchor matches at the point where the previous C<//g> match left
1595 off.  C<\G> allows us to easily do context-sensitive matching:
1596
1597     $metric = 1;  # use metric units
1598     ...
1599     $x = <FILE>;  # read in measurement
1600     $x =~ /^([+-]?\d+)\s*/g;  # get magnitude
1601     $weight = $1;
1602     if ($metric) { # error checking
1603         print "Units error!" unless $x =~ /\Gkg\./g;
1604     }
1605     else {
1606         print "Units error!" unless $x =~ /\Glbs\./g;
1607     }
1608     $x =~ /\G\s+(widget|sprocket)/g;  # continue processing
1609
1610 The combination of C<//g> and C<\G> allows us to process the string a
1611 bit at a time and use arbitrary Perl logic to decide what to do next.
1612 Currently, the C<\G> anchor is only fully supported when used to anchor
1613 to the start of the pattern.
1614
1615 C<\G> is also invaluable in processing fixed length records with
1616 regexps.  Suppose we have a snippet of coding region DNA, encoded as
1617 base pair letters C<ATCGTTGAAT...> and we want to find all the stop
1618 codons C<TGA>.  In a coding region, codons are 3-letter sequences, so
1619 we can think of the DNA snippet as a sequence of 3-letter records.  The
1620 naive regexp
1621
1622     # expanded, this is "ATC GTT GAA TGC AAA TGA CAT GAC"
1623     $dna = "ATCGTTGAATGCAAATGACATGAC";
1624     $dna =~ /TGA/;
1625
1626 doesn't work; it may match a C<TGA>, but there is no guarantee that
1627 the match is aligned with codon boundaries, e.g., the substring
1628 S<C<GTT GAA>> gives a match.  A better solution is
1629
1630     while ($dna =~ /(\w\w\w)*?TGA/g) {  # note the minimal *?
1631         print "Got a TGA stop codon at position ", pos $dna, "\n";
1632     }
1633
1634 which prints
1635
1636     Got a TGA stop codon at position 18
1637     Got a TGA stop codon at position 23
1638
1639 Position 18 is good, but position 23 is bogus.  What happened?
1640
1641 The answer is that our regexp works well until we get past the last
1642 real match.  Then the regexp will fail to match a synchronized C<TGA>
1643 and start stepping ahead one character position at a time, not what we
1644 want.  The solution is to use C<\G> to anchor the match to the codon
1645 alignment:
1646
1647     while ($dna =~ /\G(\w\w\w)*?TGA/g) {
1648         print "Got a TGA stop codon at position ", pos $dna, "\n";
1649     }
1650
1651 This prints
1652
1653     Got a TGA stop codon at position 18
1654
1655 which is the correct answer.  This example illustrates that it is
1656 important not only to match what is desired, but to reject what is not
1657 desired.
1658
1659 =head3 Search and replace
1660
1661 Regular expressions also play a big role in I<search and replace>
1662 operations in Perl.  Search and replace is accomplished with the
1663 C<s///> operator.  The general form is
1664 C<s/regexp/replacement/modifiers>, with everything we know about
1665 regexps and modifiers applying in this case as well.  The
1666 C<replacement> is a Perl double quoted string that replaces in the
1667 string whatever is matched with the C<regexp>.  The operator C<=~> is
1668 also used here to associate a string with C<s///>.  If matching
1669 against C<$_>, the S<C<$_ =~>> can be dropped.  If there is a match,
1670 C<s///> returns the number of substitutions made, otherwise it returns
1671 false.  Here are a few examples:
1672
1673     $x = "Time to feed the cat!";
1674     $x =~ s/cat/hacker/;   # $x contains "Time to feed the hacker!"
1675     if ($x =~ s/^(Time.*hacker)!$/$1 now!/) {
1676         $more_insistent = 1;
1677     }
1678     $y = "'quoted words'";
1679     $y =~ s/^'(.*)'$/$1/;  # strip single quotes,
1680                            # $y contains "quoted words"
1681
1682 In the last example, the whole string was matched, but only the part
1683 inside the single quotes was grouped.  With the C<s///> operator, the
1684 matched variables C<$1>, C<$2>, etc.  are immediately available for use
1685 in the replacement expression, so we use C<$1> to replace the quoted
1686 string with just what was quoted.  With the global modifier, C<s///g>
1687 will search and replace all occurrences of the regexp in the string:
1688
1689     $x = "I batted 4 for 4";
1690     $x =~ s/4/four/;   # doesn't do it all:
1691                        # $x contains "I batted four for 4"
1692     $x = "I batted 4 for 4";
1693     $x =~ s/4/four/g;  # does it all:
1694                        # $x contains "I batted four for four"
1695
1696 If you prefer 'regex' over 'regexp' in this tutorial, you could use
1697 the following program to replace it:
1698
1699     % cat > simple_replace
1700     #!/usr/bin/perl
1701     $regexp = shift;
1702     $replacement = shift;
1703     while (<>) {
1704         s/$regexp/$replacement/go;
1705         print;
1706     }
1707     ^D
1708
1709     % simple_replace regexp regex perlretut.pod
1710
1711 In C<simple_replace> we used the C<s///g> modifier to replace all
1712 occurrences of the regexp on each line and the C<s///o> modifier to
1713 compile the regexp only once.  As with C<simple_grep>, both the
1714 C<print> and the C<s/$regexp/$replacement/go> use C<$_> implicitly.
1715
1716 A modifier available specifically to search and replace is the
1717 C<s///e> evaluation modifier.  C<s///e> wraps an C<eval{...}> around
1718 the replacement string and the evaluated result is substituted for the
1719 matched substring.  C<s///e> is useful if you need to do a bit of
1720 computation in the process of replacing text.  This example counts
1721 character frequencies in a line:
1722
1723     $x = "Bill the cat";
1724     $x =~ s/(.)/$chars{$1}++;$1/eg;  # final $1 replaces char with itself
1725     print "frequency of '$_' is $chars{$_}\n"
1726         foreach (sort {$chars{$b} <=> $chars{$a}} keys %chars);
1727
1728 This prints
1729
1730     frequency of ' ' is 2
1731     frequency of 't' is 2
1732     frequency of 'l' is 2
1733     frequency of 'B' is 1
1734     frequency of 'c' is 1
1735     frequency of 'e' is 1
1736     frequency of 'h' is 1
1737     frequency of 'i' is 1
1738     frequency of 'a' is 1
1739
1740 As with the match C<m//> operator, C<s///> can use other delimiters,
1741 such as C<s!!!> and C<s{}{}>, and even C<s{}//>.  If single quotes are
1742 used C<s'''>, then the regexp and replacement are treated as single
1743 quoted strings and there are no substitutions.  C<s///> in list context
1744 returns the same thing as in scalar context, i.e., the number of
1745 matches.
1746
1747 =head3 The split function
1748
1749 The C<split()> function is another place where a regexp is used.
1750 C<split /regexp/, string, limit> separates the C<string> operand into 
1751 a list of substrings and returns that list.  The regexp must be designed 
1752 to match whatever constitutes the separators for the desired substrings.
1753 The C<limit>, if present, constrains splitting into no more than C<limit> 
1754 number of strings.  For example, to split a string into words, use
1755
1756     $x = "Calvin and Hobbes";
1757     @words = split /\s+/, $x;  # $word[0] = 'Calvin'
1758                                # $word[1] = 'and'
1759                                # $word[2] = 'Hobbes'
1760
1761 If the empty regexp C<//> is used, the regexp always matches and
1762 the string is split into individual characters.  If the regexp has
1763 groupings, then the resulting list contains the matched substrings from the
1764 groupings as well.  For instance,
1765
1766     $x = "/usr/bin/perl";
1767     @dirs = split m!/!, $x;  # $dirs[0] = ''
1768                              # $dirs[1] = 'usr'
1769                              # $dirs[2] = 'bin'
1770                              # $dirs[3] = 'perl'
1771     @parts = split m!(/)!, $x;  # $parts[0] = ''
1772                                 # $parts[1] = '/'
1773                                 # $parts[2] = 'usr'
1774                                 # $parts[3] = '/'
1775                                 # $parts[4] = 'bin'
1776                                 # $parts[5] = '/'
1777                                 # $parts[6] = 'perl'
1778
1779 Since the first character of $x matched the regexp, C<split> prepended
1780 an empty initial element to the list.
1781
1782 If you have read this far, congratulations! You now have all the basic
1783 tools needed to use regular expressions to solve a wide range of text
1784 processing problems.  If this is your first time through the tutorial,
1785 why not stop here and play around with regexps a while...  S<Part 2>
1786 concerns the more esoteric aspects of regular expressions and those
1787 concepts certainly aren't needed right at the start.
1788
1789 =head1 Part 2: Power tools
1790
1791 OK, you know the basics of regexps and you want to know more.  If
1792 matching regular expressions is analogous to a walk in the woods, then
1793 the tools discussed in Part 1 are analogous to topo maps and a
1794 compass, basic tools we use all the time.  Most of the tools in part 2
1795 are analogous to flare guns and satellite phones.  They aren't used
1796 too often on a hike, but when we are stuck, they can be invaluable.
1797
1798 What follows are the more advanced, less used, or sometimes esoteric
1799 capabilities of Perl regexps.  In Part 2, we will assume you are
1800 comfortable with the basics and concentrate on the new features.
1801
1802 =head2 More on characters, strings, and character classes
1803
1804 There are a number of escape sequences and character classes that we
1805 haven't covered yet.
1806
1807 There are several escape sequences that convert characters or strings
1808 between upper and lower case, and they are also available within
1809 patterns.  C<\l> and C<\u> convert the next character to lower or 
1810 upper case, respectively:
1811
1812     $x = "perl";
1813     $string =~ /\u$x/;  # matches 'Perl' in $string
1814     $x = "M(rs?|s)\\."; # note the double backslash
1815     $string =~ /\l$x/;  # matches 'mr.', 'mrs.', and 'ms.',
1816
1817 A C<\L> or C<\U> indicates a lasting conversion of case, until
1818 terminated by C<\E> or thrown over by another C<\U> or C<\L>:
1819
1820     $x = "This word is in lower case:\L SHOUT\E";
1821     $x =~ /shout/;       # matches
1822     $x = "I STILL KEYPUNCH CARDS FOR MY 360"
1823     $x =~ /\Ukeypunch/;  # matches punch card string
1824
1825 If there is no C<\E>, case is converted until the end of the
1826 string. The regexps C<\L\u$word> or C<\u\L$word> convert the first
1827 character of C<$word> to uppercase and the rest of the characters to
1828 lowercase.
1829
1830 Control characters can be escaped with C<\c>, so that a control-Z
1831 character would be matched with C<\cZ>.  The escape sequence
1832 C<\Q>...C<\E> quotes, or protects most non-alphabetic characters.   For
1833 instance,
1834
1835     $x = "\QThat !^*&%~& cat!";
1836     $x =~ /\Q!^*&%~&\E/;  # check for rough language
1837
1838 It does not protect C<$> or C<@>, so that variables can still be
1839 substituted.
1840
1841 With the advent of 5.6.0, Perl regexps can handle more than just the
1842 standard ASCII character set.  Perl now supports I<Unicode>, a standard
1843 for representing the alphabets from virtually all of the world's written
1844 languages, and a host of symbols.  Perl uses the UTF-8 encoding, in which 
1845 ASCII characters are still encoded as one byte, but characters greater 
1846 than C<chr(127)> may be stored as two or more bytes.
1847
1848 What does this mean for regexps? Well, regexp users don't need to know
1849 much about Perl's internal representation of strings.  But they do need
1850 to know 1) how to represent Unicode characters in a regexp and 2) when
1851 a matching operation will treat the string to be searched as a
1852 sequence of bytes (the old way) or as a sequence of Unicode characters
1853 (the new way).  The answer to 1) is that Unicode characters greater
1854 than C<chr(127)> may be represented using the C<\x{hex}> notation,
1855 with C<hex> a hexadecimal integer:
1856
1857     /\x{263a}/;  # match a Unicode smiley face :)
1858
1859 Unicode characters in the range of 128-255 use two hexadecimal digits
1860 with braces: C<\x{ab}>.  Note that this is in general different than
1861 C<\xab>, which is just a hexadecimal byte with no Unicode significance,
1862 except when your script is encoded in UTF-8 where C<\xab> has the
1863 same byte representation as C<\x{ab}>.
1864
1865 B<NOTE>: In Perl 5.6.0 it used to be that one needed to say C<use
1866 utf8> to use any Unicode features.  This is no more the case: for
1867 almost all Unicode processing, the explicit C<utf8> pragma is not
1868 needed.  (The only case where it matters is if your Perl script is in
1869 Unicode and encoded in UTF-8, then an explicit C<use utf8> is needed.)
1870
1871 Figuring out the hexadecimal sequence of a Unicode character you want
1872 or deciphering someone else's hexadecimal Unicode regexp is about as
1873 much fun as programming in machine code.  So another way to specify
1874 Unicode characters is to use the I<named character>> escape
1875 sequence C<\N{name}>.  C<name> is a name for the Unicode character, as
1876 specified in the Unicode standard.  For instance, if we wanted to
1877 represent or match the astrological sign for the planet Mercury, we
1878 could use
1879
1880     use charnames ":full"; # use named chars with Unicode full names
1881     $x = "abc\N{MERCURY}def";
1882     $x =~ /\N{MERCURY}/;   # matches
1883
1884 One can also use short names or restrict names to a certain alphabet:
1885
1886     use charnames ':full';
1887     print "\N{GREEK SMALL LETTER SIGMA} is called sigma.\n";
1888
1889     use charnames ":short";
1890     print "\N{greek:Sigma} is an upper-case sigma.\n";
1891
1892     use charnames qw(greek);
1893     print "\N{sigma} is Greek sigma\n";
1894
1895 A list of full names is found in the file NamesList.txt in the
1896 lib/perl5/X.X.X/unicore directory (where X.X.X is the perl
1897 version number as it is installed on your system).
1898
1899 The answer to requirement 2), as of 5.6.0, is that if a regexp
1900 contains Unicode characters, the string is searched as a sequence of
1901 Unicode characters.  Otherwise, the string is searched as a sequence of
1902 bytes.  If the string is being searched as a sequence of Unicode
1903 characters, but matching a single byte is required, we can use the C<\C>
1904 escape sequence.  C<\C> is a character class akin to C<.> except that
1905 it matches I<any> byte 0-255.  So
1906
1907     use charnames ":full"; # use named chars with Unicode full names
1908     $x = "a";
1909     $x =~ /\C/;  # matches 'a', eats one byte
1910     $x = "";
1911     $x =~ /\C/;  # doesn't match, no bytes to match
1912     $x = "\N{MERCURY}";  # two-byte Unicode character
1913     $x =~ /\C/;  # matches, but dangerous!
1914
1915 The last regexp matches, but is dangerous because the string
1916 I<character> position is no longer synchronized to the string I<byte>
1917 position.  This generates the warning 'Malformed UTF-8
1918 character'.  The C<\C> is best used for matching the binary data in strings
1919 with binary data intermixed with Unicode characters.
1920
1921 Let us now discuss the rest of the character classes.  Just as with
1922 Unicode characters, there are named Unicode character classes
1923 represented by the C<\p{name}> escape sequence.  Closely associated is
1924 the C<\P{name}> character class, which is the negation of the
1925 C<\p{name}> class.  For example, to match lower and uppercase
1926 characters,
1927
1928     use charnames ":full"; # use named chars with Unicode full names
1929     $x = "BOB";
1930     $x =~ /^\p{IsUpper}/;   # matches, uppercase char class
1931     $x =~ /^\P{IsUpper}/;   # doesn't match, char class sans uppercase
1932     $x =~ /^\p{IsLower}/;   # doesn't match, lowercase char class
1933     $x =~ /^\P{IsLower}/;   # matches, char class sans lowercase
1934
1935 Here is the association between some Perl named classes and the
1936 traditional Unicode classes:
1937
1938     Perl class name  Unicode class name or regular expression
1939
1940     IsAlpha          /^[LM]/
1941     IsAlnum          /^[LMN]/
1942     IsASCII          $code <= 127
1943     IsCntrl          /^C/
1944     IsBlank          $code =~ /^(0020|0009)$/ || /^Z[^lp]/
1945     IsDigit          Nd
1946     IsGraph          /^([LMNPS]|Co)/
1947     IsLower          Ll
1948     IsPrint          /^([LMNPS]|Co|Zs)/
1949     IsPunct          /^P/
1950     IsSpace          /^Z/ || ($code =~ /^(0009|000A|000B|000C|000D)$/
1951     IsSpacePerl      /^Z/ || ($code =~ /^(0009|000A|000C|000D|0085|2028|2029)$/
1952     IsUpper          /^L[ut]/
1953     IsWord           /^[LMN]/ || $code eq "005F"
1954     IsXDigit         $code =~ /^00(3[0-9]|[46][1-6])$/
1955
1956 You can also use the official Unicode class names with the C<\p> and
1957 C<\P>, like C<\p{L}> for Unicode 'letters', or C<\p{Lu}> for uppercase
1958 letters, or C<\P{Nd}> for non-digits.  If a C<name> is just one
1959 letter, the braces can be dropped.  For instance, C<\pM> is the
1960 character class of Unicode 'marks', for example accent marks.
1961 For the full list see L<perlunicode>.
1962
1963 The Unicode has also been separated into various sets of characters
1964 which you can test with C<\p{...}> (in) and C<\P{...}> (not in).
1965 To test whether a character is (or is not) an element of a script
1966 you would use the script name, for example C<\p{Latin}>, C<\p{Greek}>, 
1967 or C<\P{Katakana}>. Other sets are the Unicode blocks, the names
1968 of which begin with "In". One such block is dedicated to mathematical
1969 operators, and its pattern formula is <C\p{InMathematicalOperators>}>.
1970 For the full list see L<perlunicode>.
1971
1972 C<\X> is an abbreviation for a character class that comprises
1973 the Unicode I<combining character sequences>.  A combining character
1974 sequence is a base character followed by any number of diacritics, i.e.,
1975 signs like accents used to indicate different sounds of a letter. Using
1976 the Unicode full names, e.g., S<C<A + COMBINING RING>> is a combining
1977 character sequence with base character C<A> and combining character
1978 S<C<COMBINING RING>>, which translates in Danish to A with the circle
1979 atop it, as in the word Angstrom.  C<\X> is equivalent to C<\PM\pM*}>,
1980 i.e., a non-mark followed by one or more marks.
1981
1982 For the full and latest information about Unicode see the latest
1983 Unicode standard, or the Unicode Consortium's website http://www.unicode.org/
1984
1985 As if all those classes weren't enough, Perl also defines POSIX style
1986 character classes.  These have the form C<[:name:]>, with C<name> the
1987 name of the POSIX class.  The POSIX classes are C<alpha>, C<alnum>,
1988 C<ascii>, C<cntrl>, C<digit>, C<graph>, C<lower>, C<print>, C<punct>,
1989 C<space>, C<upper>, and C<xdigit>, and two extensions, C<word> (a Perl
1990 extension to match C<\w>), and C<blank> (a GNU extension).  If C<utf8>
1991 is being used, then these classes are defined the same as their
1992 corresponding Perl Unicode classes: C<[:upper:]> is the same as
1993 C<\p{IsUpper}>, etc.  The POSIX character classes, however, don't
1994 require using C<utf8>.  The C<[:digit:]>, C<[:word:]>, and
1995 C<[:space:]> correspond to the familiar C<\d>, C<\w>, and C<\s>
1996 character classes.  To negate a POSIX class, put a C<^> in front of
1997 the name, so that, e.g., C<[:^digit:]> corresponds to C<\D> and under
1998 C<utf8>, C<\P{IsDigit}>.  The Unicode and POSIX character classes can
1999 be used just like C<\d>, with the exception that POSIX character
2000 classes can only be used inside of a character class:
2001
2002     /\s+[abc[:digit:]xyz]\s*/;  # match a,b,c,x,y,z, or a digit
2003     /^=item\s[[:digit:]]/;      # match '=item',
2004                                 # followed by a space and a digit
2005     use charnames ":full";
2006     /\s+[abc\p{IsDigit}xyz]\s+/;  # match a,b,c,x,y,z, or a digit
2007     /^=item\s\p{IsDigit}/;        # match '=item',
2008                                   # followed by a space and a digit
2009
2010 Whew! That is all the rest of the characters and character classes.
2011
2012 =head2 Compiling and saving regular expressions
2013
2014 In Part 1 we discussed the C<//o> modifier, which compiles a regexp
2015 just once.  This suggests that a compiled regexp is some data structure
2016 that can be stored once and used again and again.  The regexp quote
2017 C<qr//> does exactly that: C<qr/string/> compiles the C<string> as a
2018 regexp and transforms the result into a form that can be assigned to a
2019 variable:
2020
2021     $reg = qr/foo+bar?/;  # reg contains a compiled regexp
2022
2023 Then C<$reg> can be used as a regexp:
2024
2025     $x = "fooooba";
2026     $x =~ $reg;     # matches, just like /foo+bar?/
2027     $x =~ /$reg/;   # same thing, alternate form
2028
2029 C<$reg> can also be interpolated into a larger regexp:
2030
2031     $x =~ /(abc)?$reg/;  # still matches
2032
2033 As with the matching operator, the regexp quote can use different
2034 delimiters, e.g., C<qr!!>, C<qr{}> or C<qr~~>.  Apostrophes
2035 as delimiters (C<qr''>) inhibit any interpolation.
2036
2037 Pre-compiled regexps are useful for creating dynamic matches that
2038 don't need to be recompiled each time they are encountered.  Using
2039 pre-compiled regexps, we write a C<grep_step> program which greps
2040 for a sequence of patterns, advancing to the next pattern as soon
2041 as one has been satisfied.
2042
2043     % cat > grep_step
2044     #!/usr/bin/perl
2045     # grep_step - match <number> regexps, one after the other
2046     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2047
2048     $number = shift;
2049     $regexp[$_] = shift foreach (0..$number-1);
2050     @compiled = map qr/$_/, @regexp;
2051     while ($line = <>) {
2052         if ($line =~ /$compiled[0]/) {
2053             print $line;
2054             shift @compiled;
2055             last unless @compiled;
2056         }
2057     }
2058     ^D
2059
2060     % grep_step 3 shift print last grep_step
2061     $number = shift;
2062             print $line;
2063             last unless @compiled;
2064
2065 Storing pre-compiled regexps in an array C<@compiled> allows us to
2066 simply loop through the regexps without any recompilation, thus gaining
2067 flexibility without sacrificing speed.
2068
2069
2070 =head2 Composing regular expressions at runtime
2071
2072 Backtracking is more efficient than repeated tries with different regular
2073 expressions.  If there are several regular expressions and a match with
2074 any of them is acceptable, then it is possible to combine them into a set 
2075 of alternatives.  If the individual expressions are input data, this
2076 can be done by programming a join operation.  We'll exploit this idea in 
2077 an improved version of the C<simple_grep> program: a program that matches 
2078 multiple patterns:
2079
2080     % cat > multi_grep
2081     #!/usr/bin/perl
2082     # multi_grep - match any of <number> regexps
2083     # usage: multi_grep <number> regexp1 regexp2 ... file1 file2 ...
2084
2085     $number = shift;
2086     $regexp[$_] = shift foreach (0..$number-1);
2087     $pattern = join '|', @regexp;
2088
2089     while ($line = <>) {
2090         print $line if $line =~ /$pattern/o;
2091     }
2092     ^D
2093
2094     % multi_grep 2 shift for multi_grep
2095     $number = shift;
2096     $regexp[$_] = shift foreach (0..$number-1);
2097
2098 Sometimes it is advantageous to construct a pattern from the I<input>
2099 that is to be analyzed and use the permissible values on the left
2100 hand side of the matching operations.  As an example for this somewhat
2101 paradoxical situation, let's assume that our input contains a command 
2102 verb which should match one out of a set of available command verbs,
2103 with the additional twist that commands may be abbreviated as long as 
2104 the given string is unique. The program below demonstrates the basic
2105 algorithm.
2106
2107     % cat > keymatch
2108     #!/usr/bin/perl
2109     $kwds = 'copy compare list print';
2110     while( $command = <> ){
2111         $command =~ s/^\s+|\s+$//g;  # trim leading and trailing spaces
2112         if( ( @matches = $kwds =~ /\b$command\w*/g ) == 1 ){
2113             print "command: '$matches'\n";
2114         } elsif( @matches == 0 ){
2115             print "no such command: '$command'\n";
2116         } else {
2117             print "not unique: '$command' (could be one of: @matches)\n";
2118         }
2119     }
2120     ^D
2121
2122     % keymatch
2123     li
2124     command: 'list'
2125     co
2126     not unique: 'co' (could be one of: copy compare)
2127     printer
2128     no such command: 'printer'
2129
2130 Rather than trying to match the input against the keywords, we match the
2131 combined set of keywords against the input.  The pattern matching
2132 operation S<C<$kwds =~ /\b($command\w*)/g>> does several things at the 
2133 same time. It makes sure that the given command begins where a keyword 
2134 begins (C<\b>). It tolerates abbreviations due to the added C<\w*>. It 
2135 tells us the number of matches (C<scalar @matches>) and all the keywords 
2136 that were actually matched.  You could hardly ask for more.
2137  
2138
2139 =head2 Embedding comments and modifiers in a regular expression
2140
2141 Starting with this section, we will be discussing Perl's set of
2142 I<extended patterns>.  These are extensions to the traditional regular
2143 expression syntax that provide powerful new tools for pattern
2144 matching.  We have already seen extensions in the form of the minimal
2145 matching constructs C<??>, C<*?>, C<+?>, C<{n,m}?>, and C<{n,}?>.  The
2146 rest of the extensions below have the form C<(?char...)>, where the
2147 C<char> is a character that determines the type of extension.
2148
2149 The first extension is an embedded comment C<(?#text)>.  This embeds a
2150 comment into the regular expression without affecting its meaning.  The
2151 comment should not have any closing parentheses in the text.  An
2152 example is
2153
2154     /(?# Match an integer:)[+-]?\d+/;
2155
2156 This style of commenting has been largely superseded by the raw,
2157 freeform commenting that is allowed with the C<//x> modifier.
2158
2159 The modifiers C<//i>, C<//m>, C<//s>, C<//x> and C<//k> (or any 
2160 combination thereof) can also embedded in
2161 a regexp using C<(?i)>, C<(?m)>, C<(?s)>, and C<(?x)>.  For instance,
2162
2163     /(?i)yes/;  # match 'yes' case insensitively
2164     /yes/i;     # same thing
2165     /(?x)(          # freeform version of an integer regexp
2166              [+-]?  # match an optional sign
2167              \d+    # match a sequence of digits
2168          )
2169     /x;
2170
2171 Embedded modifiers can have two important advantages over the usual
2172 modifiers.  Embedded modifiers allow a custom set of modifiers to
2173 I<each> regexp pattern.  This is great for matching an array of regexps
2174 that must have different modifiers:
2175
2176     $pattern[0] = '(?i)doctor';
2177     $pattern[1] = 'Johnson';
2178     ...
2179     while (<>) {
2180         foreach $patt (@pattern) {
2181             print if /$patt/;
2182         }
2183     }
2184
2185 The second advantage is that embedded modifiers (except C<//k>, which
2186 modifies the entire regexp) only affect the regexp
2187 inside the group the embedded modifier is contained in.  So grouping
2188 can be used to localize the modifier's effects:
2189
2190     /Answer: ((?i)yes)/;  # matches 'Answer: yes', 'Answer: YES', etc.
2191
2192 Embedded modifiers can also turn off any modifiers already present
2193 by using, e.g., C<(?-i)>.  Modifiers can also be combined into
2194 a single expression, e.g., C<(?s-i)> turns on single line mode and
2195 turns off case insensitivity.
2196
2197 Embedded modifiers may also be added to a non-capturing grouping.
2198 C<(?i-m:regexp)> is a non-capturing grouping that matches C<regexp>
2199 case insensitively and turns off multi-line mode.
2200
2201
2202 =head2 Looking ahead and looking behind
2203
2204 This section concerns the lookahead and lookbehind assertions.  First,
2205 a little background.
2206
2207 In Perl regular expressions, most regexp elements 'eat up' a certain
2208 amount of string when they match.  For instance, the regexp element
2209 C<[abc}]> eats up one character of the string when it matches, in the
2210 sense that Perl moves to the next character position in the string
2211 after the match.  There are some elements, however, that don't eat up
2212 characters (advance the character position) if they match.  The examples
2213 we have seen so far are the anchors.  The anchor C<^> matches the
2214 beginning of the line, but doesn't eat any characters.  Similarly, the
2215 word boundary anchor C<\b> matches wherever a character matching C<\w>
2216 is next to a character that doesn't, but it doesn't eat up any 
2217 characters itself.  Anchors are examples of I<zero-width assertions>.
2218 Zero-width, because they consume
2219 no characters, and assertions, because they test some property of the
2220 string.  In the context of our walk in the woods analogy to regexp
2221 matching, most regexp elements move us along a trail, but anchors have
2222 us stop a moment and check our surroundings.  If the local environment
2223 checks out, we can proceed forward.  But if the local environment
2224 doesn't satisfy us, we must backtrack.
2225
2226 Checking the environment entails either looking ahead on the trail,
2227 looking behind, or both.  C<^> looks behind, to see that there are no
2228 characters before.  C<$> looks ahead, to see that there are no
2229 characters after.  C<\b> looks both ahead and behind, to see if the
2230 characters on either side differ in their "word-ness".
2231
2232 The lookahead and lookbehind assertions are generalizations of the
2233 anchor concept.  Lookahead and lookbehind are zero-width assertions
2234 that let us specify which characters we want to test for.  The
2235 lookahead assertion is denoted by C<(?=regexp)> and the lookbehind
2236 assertion is denoted by C<< (?<=fixed-regexp) >>.  Some examples are
2237
2238     $x = "I catch the housecat 'Tom-cat' with catnip";
2239     $x =~ /cat(?=\s)/;   # matches 'cat' in 'housecat'
2240     @catwords = ($x =~ /(?<=\s)cat\w+/g);  # matches,
2241                                            # $catwords[0] = 'catch'
2242                                            # $catwords[1] = 'catnip'
2243     $x =~ /\bcat\b/;  # matches 'cat' in 'Tom-cat'
2244     $x =~ /(?<=\s)cat(?=\s)/; # doesn't match; no isolated 'cat' in
2245                               # middle of $x
2246
2247 Note that the parentheses in C<(?=regexp)> and C<< (?<=regexp) >> are
2248 non-capturing, since these are zero-width assertions.  Thus in the
2249 second regexp, the substrings captured are those of the whole regexp
2250 itself.  Lookahead C<(?=regexp)> can match arbitrary regexps, but
2251 lookbehind C<< (?<=fixed-regexp) >> only works for regexps of fixed
2252 width, i.e., a fixed number of characters long.  Thus
2253 C<< (?<=(ab|bc)) >> is fine, but C<< (?<=(ab)*) >> is not.  The
2254 negated versions of the lookahead and lookbehind assertions are
2255 denoted by C<(?!regexp)> and C<< (?<!fixed-regexp) >> respectively.
2256 They evaluate true if the regexps do I<not> match:
2257
2258     $x = "foobar";
2259     $x =~ /foo(?!bar)/;  # doesn't match, 'bar' follows 'foo'
2260     $x =~ /foo(?!baz)/;  # matches, 'baz' doesn't follow 'foo'
2261     $x =~ /(?<!\s)foo/;  # matches, there is no \s before 'foo'
2262
2263 The C<\C> is unsupported in lookbehind, because the already
2264 treacherous definition of C<\C> would become even more so
2265 when going backwards.
2266
2267 Here is an example where a string containing blank-separated words,
2268 numbers and single dashes is to be split into its components.
2269 Using C</\s+/> alone won't work, because spaces are not required between
2270 dashes, or a word or a dash. Additional places for a split are established
2271 by looking ahead and behind:
2272
2273     $str = "one two - --6-8";
2274     @toks = split / \s+              # a run of spaces
2275                   | (?<=\S) (?=-)    # any non-space followed by '-'
2276                   | (?<=-)  (?=\S)   # a '-' followed by any non-space
2277                   /x, $str;          # @toks = qw(one two - - - 6 - 8)
2278
2279
2280 =head2 Using independent subexpressions to prevent backtracking
2281
2282 I<Independent subexpressions> are regular expressions, in the
2283 context of a larger regular expression, that function independently of
2284 the larger regular expression.  That is, they consume as much or as
2285 little of the string as they wish without regard for the ability of
2286 the larger regexp to match.  Independent subexpressions are represented
2287 by C<< (?>regexp) >>.  We can illustrate their behavior by first
2288 considering an ordinary regexp:
2289
2290     $x = "ab";
2291     $x =~ /a*ab/;  # matches
2292
2293 This obviously matches, but in the process of matching, the
2294 subexpression C<a*> first grabbed the C<a>.  Doing so, however,
2295 wouldn't allow the whole regexp to match, so after backtracking, C<a*>
2296 eventually gave back the C<a> and matched the empty string.  Here, what
2297 C<a*> matched was I<dependent> on what the rest of the regexp matched.
2298
2299 Contrast that with an independent subexpression:
2300
2301     $x =~ /(?>a*)ab/;  # doesn't match!
2302
2303 The independent subexpression C<< (?>a*) >> doesn't care about the rest
2304 of the regexp, so it sees an C<a> and grabs it.  Then the rest of the
2305 regexp C<ab> cannot match.  Because C<< (?>a*) >> is independent, there
2306 is no backtracking and the independent subexpression does not give
2307 up its C<a>.  Thus the match of the regexp as a whole fails.  A similar
2308 behavior occurs with completely independent regexps:
2309
2310     $x = "ab";
2311     $x =~ /a*/g;   # matches, eats an 'a'
2312     $x =~ /\Gab/g; # doesn't match, no 'a' available
2313
2314 Here C<//g> and C<\G> create a 'tag team' handoff of the string from
2315 one regexp to the other.  Regexps with an independent subexpression are
2316 much like this, with a handoff of the string to the independent
2317 subexpression, and a handoff of the string back to the enclosing
2318 regexp.
2319
2320 The ability of an independent subexpression to prevent backtracking
2321 can be quite useful.  Suppose we want to match a non-empty string
2322 enclosed in parentheses up to two levels deep.  Then the following
2323 regexp matches:
2324
2325     $x = "abc(de(fg)h";  # unbalanced parentheses
2326     $x =~ /\( ( [^()]+ | \([^()]*\) )+ \)/x;
2327
2328 The regexp matches an open parenthesis, one or more copies of an
2329 alternation, and a close parenthesis.  The alternation is two-way, with
2330 the first alternative C<[^()]+> matching a substring with no
2331 parentheses and the second alternative C<\([^()]*\)>  matching a
2332 substring delimited by parentheses.  The problem with this regexp is
2333 that it is pathological: it has nested indeterminate quantifiers
2334 of the form C<(a+|b)+>.  We discussed in Part 1 how nested quantifiers
2335 like this could take an exponentially long time to execute if there
2336 was no match possible.  To prevent the exponential blowup, we need to
2337 prevent useless backtracking at some point.  This can be done by
2338 enclosing the inner quantifier as an independent subexpression:
2339
2340     $x =~ /\( ( (?>[^()]+) | \([^()]*\) )+ \)/x;
2341
2342 Here, C<< (?>[^()]+) >> breaks the degeneracy of string partitioning
2343 by gobbling up as much of the string as possible and keeping it.   Then
2344 match failures fail much more quickly.
2345
2346
2347 =head2 Conditional expressions
2348
2349 A I<conditional expression> is a form of if-then-else statement
2350 that allows one to choose which patterns are to be matched, based on
2351 some condition.  There are two types of conditional expression:
2352 C<(?(condition)yes-regexp)> and
2353 C<(?(condition)yes-regexp|no-regexp)>.  C<(?(condition)yes-regexp)> is
2354 like an S<C<'if () {}'>> statement in Perl.  If the C<condition> is true,
2355 the C<yes-regexp> will be matched.  If the C<condition> is false, the
2356 C<yes-regexp> will be skipped and Perl will move onto the next regexp
2357 element.  The second form is like an S<C<'if () {} else {}'>> statement
2358 in Perl.  If the C<condition> is true, the C<yes-regexp> will be
2359 matched, otherwise the C<no-regexp> will be matched.
2360
2361 The C<condition> can have several forms.  The first form is simply an
2362 integer in parentheses C<(integer)>.  It is true if the corresponding
2363 backreference C<\integer> matched earlier in the regexp.  The same
2364 thing can be done with a name associated with a capture buffer, written
2365 as C<< (<name>) >> or C<< ('name') >>.  The second form is a bare
2366 zero width assertion C<(?...)>, either a lookahead, a lookbehind, or a 
2367 code assertion (discussed in the next section).  The third set of forms
2368 provides tests that return true if the expression is executed within
2369 a recursion (C<(R)>) or is being called from some capturing group,
2370 referenced either by number (C<(R1)>, C<(R2)>,...) or by name
2371 (C<(R&name)>).
2372
2373 The integer or name form of the C<condition> allows us to choose,
2374 with more flexibility, what to match based on what matched earlier in the
2375 regexp. This searches for words of the form C<"$x$x"> or C<"$x$y$y$x">:
2376
2377     % simple_grep '^(\w+)(\w+)?(?(2)\2\1|\1)$' /usr/dict/words
2378     beriberi
2379     coco
2380     couscous
2381     deed
2382     ...
2383     toot
2384     toto
2385     tutu
2386
2387 The lookbehind C<condition> allows, along with backreferences,
2388 an earlier part of the match to influence a later part of the
2389 match.  For instance,
2390
2391     /[ATGC]+(?(?<=AA)G|C)$/;
2392
2393 matches a DNA sequence such that it either ends in C<AAG>, or some
2394 other base pair combination and C<C>.  Note that the form is
2395 C<< (?(?<=AA)G|C) >> and not C<< (?((?<=AA))G|C) >>; for the
2396 lookahead, lookbehind or code assertions, the parentheses around the
2397 conditional are not needed.
2398
2399
2400 =head2 Defining named patterns
2401
2402 Some regular expressions use identical subpatterns in several places.
2403 Starting with Perl 5.10, it is possible to define named subpatterns in
2404 a section of the pattern so that they can be called up by name
2405 anywhere in the pattern.  This syntactic pattern for this definition
2406 group is C<< (?(DEFINE)(?<name>pattern)...) >>.  An insertion
2407 of a named pattern is written as C<(?&name)>.
2408
2409 The example below illustrates this feature using the pattern for
2410 floating point numbers that was presented earlier on.  The three
2411 subpatterns that are used more than once are the optional sign, the
2412 digit sequence for an integer and the decimal fraction.  The DEFINE
2413 group at the end of the pattern contains their definition.  Notice
2414 that the decimal fraction pattern is the first place where we can
2415 reuse the integer pattern.
2416
2417    /^ (?&osg)\ * ( (?&int)(?&dec)? | (?&dec) ) 
2418       (?: [eE](?&osg)(?&int) )?
2419     $
2420     (?(DEFINE)
2421       (?<osg>[-+]?)         # optional sign
2422       (?<int>\d++)          # integer
2423       (?<dec>\.(?&int))     # decimal fraction
2424     )/x
2425
2426
2427 =head2 Recursive patterns
2428
2429 This feature (introduced in Perl 5.10) significantly extends the
2430 power of Perl's pattern matching.  By referring to some other
2431 capture group anywhere in the pattern with the construct
2432 C<(?group-ref)>, the I<pattern> within the referenced group is used 
2433 as an independent subpattern in place of the group reference itself.
2434 Because the group reference may be contained I<within> the group it
2435 refers to, it is now possible to apply pattern matching to tasks that
2436 hitherto required a recursive parser.
2437
2438 To illustrate this feature, we'll design a pattern that matches if
2439 a string contains a palindrome. (This is a word or a sentence that,
2440 while ignoring spaces, interpunctuation and case, reads the same backwards
2441 as forwards. We begin by observing that the empty string or a string
2442 containing just one word character is a palindrome. Otherwise it must
2443 have a word character up front and the same at its end, with another
2444 palindrome in between.
2445
2446     /(?: (\w) (?...Here be a palindrome...) \{-1} | \w? )/x
2447
2448 Adding C<\W*> at either end to eliminate was is to be ignored, we already
2449 have the full pattern:
2450
2451     my $pp = qr/^(\W* (?: (\w) (?1) \g{-1} | \w? ) \W*)$/ix;
2452     for $s ( "saippuakauppias", "A man, a plan, a canal: Panama!" ){
2453         print "'$s' is a palindrome\n" if $s =~ /$pp/;
2454     }
2455
2456 In C<(?...)> both absolute and relative backreferences may be used.
2457 The entire pattern can be reinserted with C<(?R)> or C<(?0)>.
2458 If you prefer to name your buffers, you can use C<(?&name)> to
2459 recurse into that buffer.
2460
2461
2462 =head2 A bit of magic: executing Perl code in a regular expression
2463
2464 Normally, regexps are a part of Perl expressions.
2465 I<Code evaluation> expressions turn that around by allowing
2466 arbitrary Perl code to be a part of a regexp.  A code evaluation
2467 expression is denoted C<(?{code})>, with I<code> a string of Perl
2468 statements.
2469
2470 Be warned that this feature is considered experimental, and may be 
2471 changed without notice.
2472
2473 Code expressions are zero-width assertions, and the value they return
2474 depends on their environment.  There are two possibilities: either the
2475 code expression is used as a conditional in a conditional expression
2476 C<(?(condition)...)>, or it is not.  If the code expression is a
2477 conditional, the code is evaluated and the result (i.e., the result of
2478 the last statement) is used to determine truth or falsehood.  If the
2479 code expression is not used as a conditional, the assertion always
2480 evaluates true and the result is put into the special variable
2481 C<$^R>.  The variable C<$^R> can then be used in code expressions later
2482 in the regexp.  Here are some silly examples:
2483
2484     $x = "abcdef";
2485     $x =~ /abc(?{print "Hi Mom!";})def/; # matches,
2486                                          # prints 'Hi Mom!'
2487     $x =~ /aaa(?{print "Hi Mom!";})def/; # doesn't match,
2488                                          # no 'Hi Mom!'
2489
2490 Pay careful attention to the next example:
2491
2492     $x =~ /abc(?{print "Hi Mom!";})ddd/; # doesn't match,
2493                                          # no 'Hi Mom!'
2494                                          # but why not?
2495
2496 At first glance, you'd think that it shouldn't print, because obviously
2497 the C<ddd> isn't going to match the target string. But look at this
2498 example:
2499
2500     $x =~ /abc(?{print "Hi Mom!";})[d]dd/; # doesn't match,
2501                                            # but _does_ print
2502
2503 Hmm. What happened here? If you've been following along, you know that
2504 the above pattern should be effectively the same as the last one --
2505 enclosing the d in a character class isn't going to change what it
2506 matches. So why does the first not print while the second one does?
2507
2508 The answer lies in the optimizations the regex engine makes. In the first
2509 case, all the engine sees are plain old characters (aside from the
2510 C<?{}> construct). It's smart enough to realize that the string 'ddd'
2511 doesn't occur in our target string before actually running the pattern
2512 through. But in the second case, we've tricked it into thinking that our
2513 pattern is more complicated than it is. It takes a look, sees our
2514 character class, and decides that it will have to actually run the
2515 pattern to determine whether or not it matches, and in the process of
2516 running it hits the print statement before it discovers that we don't
2517 have a match.
2518
2519 To take a closer look at how the engine does optimizations, see the
2520 section L<"Pragmas and debugging"> below.
2521
2522 More fun with C<?{}>:
2523
2524     $x =~ /(?{print "Hi Mom!";})/;       # matches,
2525                                          # prints 'Hi Mom!'
2526     $x =~ /(?{$c = 1;})(?{print "$c";})/;  # matches,
2527                                            # prints '1'
2528     $x =~ /(?{$c = 1;})(?{print "$^R";})/; # matches,
2529                                            # prints '1'
2530
2531 The bit of magic mentioned in the section title occurs when the regexp
2532 backtracks in the process of searching for a match.  If the regexp
2533 backtracks over a code expression and if the variables used within are
2534 localized using C<local>, the changes in the variables produced by the
2535 code expression are undone! Thus, if we wanted to count how many times
2536 a character got matched inside a group, we could use, e.g.,
2537
2538     $x = "aaaa";
2539     $count = 0;  # initialize 'a' count
2540     $c = "bob";  # test if $c gets clobbered
2541     $x =~ /(?{local $c = 0;})         # initialize count
2542            ( a                        # match 'a'
2543              (?{local $c = $c + 1;})  # increment count
2544            )*                         # do this any number of times,
2545            aa                         # but match 'aa' at the end
2546            (?{$count = $c;})          # copy local $c var into $count
2547           /x;
2548     print "'a' count is $count, \$c variable is '$c'\n";
2549
2550 This prints
2551
2552     'a' count is 2, $c variable is 'bob'
2553
2554 If we replace the S<C< (?{local $c = $c + 1;})>> with
2555 S<C< (?{$c = $c + 1;})>>, the variable changes are I<not> undone
2556 during backtracking, and we get
2557
2558     'a' count is 4, $c variable is 'bob'
2559
2560 Note that only localized variable changes are undone.  Other side
2561 effects of code expression execution are permanent.  Thus
2562
2563     $x = "aaaa";
2564     $x =~ /(a(?{print "Yow\n";}))*aa/;
2565
2566 produces
2567
2568    Yow
2569    Yow
2570    Yow
2571    Yow
2572
2573 The result C<$^R> is automatically localized, so that it will behave
2574 properly in the presence of backtracking.
2575
2576 This example uses a code expression in a conditional to match a
2577 definite article, either 'the' in English or 'der|die|das' in German:
2578
2579     $lang = 'DE';  # use German
2580     ...
2581     $text = "das";
2582     print "matched\n"
2583         if $text =~ /(?(?{
2584                           $lang eq 'EN'; # is the language English?
2585                          })
2586                        the |             # if so, then match 'the'
2587                        (der|die|das)     # else, match 'der|die|das'
2588                      )
2589                     /xi;
2590
2591 Note that the syntax here is C<(?(?{...})yes-regexp|no-regexp)>, not
2592 C<(?((?{...}))yes-regexp|no-regexp)>.  In other words, in the case of a
2593 code expression, we don't need the extra parentheses around the
2594 conditional.
2595
2596 If you try to use code expressions with interpolating variables, Perl
2597 may surprise you:
2598
2599     $bar = 5;
2600     $pat = '(?{ 1 })';
2601     /foo(?{ $bar })bar/; # compiles ok, $bar not interpolated
2602     /foo(?{ 1 })$bar/;   # compile error!
2603     /foo${pat}bar/;      # compile error!
2604
2605     $pat = qr/(?{ $foo = 1 })/;  # precompile code regexp
2606     /foo${pat}bar/;      # compiles ok
2607
2608 If a regexp has (1) code expressions and interpolating variables, or
2609 (2) a variable that interpolates a code expression, Perl treats the
2610 regexp as an error. If the code expression is precompiled into a
2611 variable, however, interpolating is ok. The question is, why is this
2612 an error?
2613
2614 The reason is that variable interpolation and code expressions
2615 together pose a security risk.  The combination is dangerous because
2616 many programmers who write search engines often take user input and
2617 plug it directly into a regexp:
2618
2619     $regexp = <>;       # read user-supplied regexp
2620     $chomp $regexp;     # get rid of possible newline
2621     $text =~ /$regexp/; # search $text for the $regexp
2622
2623 If the C<$regexp> variable contains a code expression, the user could
2624 then execute arbitrary Perl code.  For instance, some joker could
2625 search for S<C<system('rm -rf *');>> to erase your files.  In this
2626 sense, the combination of interpolation and code expressions I<taints>
2627 your regexp.  So by default, using both interpolation and code
2628 expressions in the same regexp is not allowed.  If you're not
2629 concerned about malicious users, it is possible to bypass this
2630 security check by invoking S<C<use re 'eval'>>:
2631
2632     use re 'eval';       # throw caution out the door
2633     $bar = 5;
2634     $pat = '(?{ 1 })';
2635     /foo(?{ 1 })$bar/;   # compiles ok
2636     /foo${pat}bar/;      # compiles ok
2637
2638 Another form of code expression is the I<pattern code expression>.
2639 The pattern code expression is like a regular code expression, except
2640 that the result of the code evaluation is treated as a regular
2641 expression and matched immediately.  A simple example is
2642
2643     $length = 5;
2644     $char = 'a';
2645     $x = 'aaaaabb';
2646     $x =~ /(??{$char x $length})/x; # matches, there are 5 of 'a'
2647
2648
2649 This final example contains both ordinary and pattern code
2650 expressions.  It detects whether a binary string C<1101010010001...> has a
2651 Fibonacci spacing 0,1,1,2,3,5,...  of the C<1>'s:
2652
2653     $x = "1101010010001000001";
2654     $z0 = ''; $z1 = '0';   # initial conditions
2655     print "It is a Fibonacci sequence\n"
2656         if $x =~ /^1         # match an initial '1'
2657                     (?:
2658                        ((??{ $z0 })) # match some '0'
2659                        1             # and then a '1'
2660                        (?{ $z0 = $z1; $z1 .= $^N; })
2661                     )+   # repeat as needed
2662                   $      # that is all there is
2663                  /x;
2664     printf "Largest sequence matched was %d\n", length($z1)-length($z0);
2665
2666 Remember that C<$^N> is set to whatever was matched by the last
2667 completed capture group. This prints
2668
2669     It is a Fibonacci sequence
2670     Largest sequence matched was 5
2671
2672 Ha! Try that with your garden variety regexp package...
2673
2674 Note that the variables C<$z0> and C<$z1> are not substituted when the
2675 regexp is compiled, as happens for ordinary variables outside a code
2676 expression.  Rather, the code expressions are evaluated when Perl
2677 encounters them during the search for a match.
2678
2679 The regexp without the C<//x> modifier is
2680
2681     /^1(?:((??{ $z0 }))1(?{ $z0 = $z1; $z1 .= $^N; }))+$/
2682
2683 which shows that spaces are still possible in the code parts. Nevertheless,
2684 when working with code and conditional expressions, the extended form of 
2685 regexps is almost necessary in creating and debugging regexps.
2686
2687
2688 =head2 Backtracking control verbs
2689
2690 Perl 5.10 introduced a number of control verbs intended to provide
2691 detailed control over the backtracking process, by directly influencing
2692 the regexp engine and by providing monitoring techniques.  As all
2693 the features in this group are experimental and subject to change or
2694 removal in a future version of Perl, the interested reader is
2695 referred to L<perlre/"Special Backtracking Control Verbs"> for a
2696 detailed description.
2697
2698 Below is just one example, illustrating the control verb C<(*FAIL)>,
2699 which may be abbreviated as C<(*F)>. If this is inserted in a regexp
2700 it will cause to fail, just like at some mismatch between the pattern
2701 and the string. Processing of the regexp continues like after any "normal"
2702 failure, so that, for instance, the next position in the string or another 
2703 alternative will be tried. As failing to match doesn't preserve capture 
2704 buffers or produce results, it may be necessary to use this in 
2705 combination with embedded code.
2706
2707    %count = ();
2708    "supercalifragilisticexpialidoceous" =~
2709        /([aeiou])(?{ $count{$1}++; })(*FAIL)/oi;
2710    printf "%3d '%s'\n", $count{$_}, $_ for (sort keys %count);
2711
2712 The pattern begins with a class matching a subset of letters.  Whenever 
2713 this matches, a statement like C<$count{'a'}++;> is executed, incrementing 
2714 the letter's counter. Then C<(*FAIL)> does what it says, and 
2715 the regexp  engine proceeds according to the book: as long as the end of 
2716 the string  hasn't been reached, the position is advanced before looking 
2717 for another vowel. Thus, match or no match makes no difference, and the
2718 regexp engine proceeds until the the entire string has been inspected.
2719 (It's remarkable that an alternative solution using something like
2720
2721    $count{lc($_)}++ for split('', "supercalifragilisticexpialidoceous");
2722    printf "%3d '%s'\n", $count2{$_}, $_ for ( qw{ a e i o u } );
2723
2724 is considerably slower.)
2725
2726
2727 =head2 Pragmas and debugging
2728
2729 Speaking of debugging, there are several pragmas available to control
2730 and debug regexps in Perl.  We have already encountered one pragma in
2731 the previous section, S<C<use re 'eval';>>, that allows variable
2732 interpolation and code expressions to coexist in a regexp.  The other
2733 pragmas are
2734
2735     use re 'taint';
2736     $tainted = <>;
2737     @parts = ($tainted =~ /(\w+)\s+(\w+)/; # @parts is now tainted
2738
2739 The C<taint> pragma causes any substrings from a match with a tainted
2740 variable to be tainted as well.  This is not normally the case, as
2741 regexps are often used to extract the safe bits from a tainted
2742 variable.  Use C<taint> when you are not extracting safe bits, but are
2743 performing some other processing.  Both C<taint> and C<eval> pragmas
2744 are lexically scoped, which means they are in effect only until
2745 the end of the block enclosing the pragmas.
2746
2747     use re 'debug';
2748     /^(.*)$/s;       # output debugging info
2749
2750     use re 'debugcolor';
2751     /^(.*)$/s;       # output debugging info in living color
2752
2753 The global C<debug> and C<debugcolor> pragmas allow one to get
2754 detailed debugging info about regexp compilation and
2755 execution.  C<debugcolor> is the same as debug, except the debugging
2756 information is displayed in color on terminals that can display
2757 termcap color sequences.  Here is example output:
2758
2759     % perl -e 'use re "debug"; "abc" =~ /a*b+c/;'
2760     Compiling REx `a*b+c'
2761     size 9 first at 1
2762        1: STAR(4)
2763        2:   EXACT <a>(0)
2764        4: PLUS(7)
2765        5:   EXACT <b>(0)
2766        7: EXACT <c>(9)
2767        9: END(0)
2768     floating `bc' at 0..2147483647 (checking floating) minlen 2
2769     Guessing start of match, REx `a*b+c' against `abc'...
2770     Found floating substr `bc' at offset 1...
2771     Guessed: match at offset 0
2772     Matching REx `a*b+c' against `abc'
2773       Setting an EVAL scope, savestack=3
2774        0 <> <abc>             |  1:  STAR
2775                                EXACT <a> can match 1 times out of 32767...
2776       Setting an EVAL scope, savestack=3
2777        1 <a> <bc>             |  4:    PLUS
2778                                EXACT <b> can match 1 times out of 32767...
2779       Setting an EVAL scope, savestack=3
2780        2 <ab> <c>             |  7:      EXACT <c>
2781        3 <abc> <>             |  9:      END
2782     Match successful!
2783     Freeing REx: `a*b+c'
2784
2785 If you have gotten this far into the tutorial, you can probably guess
2786 what the different parts of the debugging output tell you.  The first
2787 part
2788
2789     Compiling REx `a*b+c'
2790     size 9 first at 1
2791        1: STAR(4)
2792        2:   EXACT <a>(0)
2793        4: PLUS(7)
2794        5:   EXACT <b>(0)
2795        7: EXACT <c>(9)
2796        9: END(0)
2797
2798 describes the compilation stage.  C<STAR(4)> means that there is a
2799 starred object, in this case C<'a'>, and if it matches, goto line 4,
2800 i.e., C<PLUS(7)>.  The middle lines describe some heuristics and
2801 optimizations performed before a match:
2802
2803     floating `bc' at 0..2147483647 (checking floating) minlen 2
2804     Guessing start of match, REx `a*b+c' against `abc'...
2805     Found floating substr `bc' at offset 1...
2806     Guessed: match at offset 0
2807
2808 Then the match is executed and the remaining lines describe the
2809 process:
2810
2811     Matching REx `a*b+c' against `abc'
2812       Setting an EVAL scope, savestack=3
2813        0 <> <abc>             |  1:  STAR
2814                                EXACT <a> can match 1 times out of 32767...
2815       Setting an EVAL scope, savestack=3
2816        1 <a> <bc>             |  4:    PLUS
2817                                EXACT <b> can match 1 times out of 32767...
2818       Setting an EVAL scope, savestack=3
2819        2 <ab> <c>             |  7:      EXACT <c>
2820        3 <abc> <>             |  9:      END
2821     Match successful!
2822     Freeing REx: `a*b+c'
2823
2824 Each step is of the form S<C<< n <x> <y> >>>, with C<< <x> >> the
2825 part of the string matched and C<< <y> >> the part not yet
2826 matched.  The S<C<< |  1:  STAR >>> says that Perl is at line number 1
2827 n the compilation list above.  See
2828 L<perldebguts/"Debugging regular expressions"> for much more detail.
2829
2830 An alternative method of debugging regexps is to embed C<print>
2831 statements within the regexp.  This provides a blow-by-blow account of
2832 the backtracking in an alternation:
2833
2834     "that this" =~ m@(?{print "Start at position ", pos, "\n";})
2835                      t(?{print "t1\n";})
2836                      h(?{print "h1\n";})
2837                      i(?{print "i1\n";})
2838                      s(?{print "s1\n";})
2839                          |
2840                      t(?{print "t2\n";})
2841                      h(?{print "h2\n";})
2842                      a(?{print "a2\n";})
2843                      t(?{print "t2\n";})
2844                      (?{print "Done at position ", pos, "\n";})
2845                     @x;
2846
2847 prints
2848
2849     Start at position 0
2850     t1
2851     h1
2852     t2
2853     h2
2854     a2
2855     t2
2856     Done at position 4
2857
2858 =head1 BUGS
2859
2860 Code expressions, conditional expressions, and independent expressions
2861 are I<experimental>.  Don't use them in production code.  Yet.
2862
2863 =head1 SEE ALSO
2864
2865 This is just a tutorial.  For the full story on Perl regular
2866 expressions, see the L<perlre> regular expressions reference page.
2867
2868 For more information on the matching C<m//> and substitution C<s///>
2869 operators, see L<perlop/"Regexp Quote-Like Operators">.  For
2870 information on the C<split> operation, see L<perlfunc/split>.
2871
2872 For an excellent all-around resource on the care and feeding of
2873 regular expressions, see the book I<Mastering Regular Expressions> by
2874 Jeffrey Friedl (published by O'Reilly, ISBN 1556592-257-3).
2875
2876 =head1 AUTHOR AND COPYRIGHT
2877
2878 Copyright (c) 2000 Mark Kvale
2879 All rights reserved.
2880
2881 This document may be distributed under the same terms as Perl itself.
2882
2883 =head2 Acknowledgments
2884
2885 The inspiration for the stop codon DNA example came from the ZIP
2886 code example in chapter 7 of I<Mastering Regular Expressions>.
2887
2888 The author would like to thank Jeff Pinyan, Andrew Johnson, Peter
2889 Haworth, Ronald J Kimball, and Joe Smith for all their helpful
2890 comments.
2891
2892 =cut
2893