This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
760e496fab70e85c6be1a1e61c12e83a525d2323
[perl5.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME : ATTRS BLOCK        #  with attributes
19     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
20
21 To define an anonymous subroutine at runtime:
22 X<subroutine, anonymous>
23
24     $subref = sub BLOCK;                 # no proto
25     $subref = sub (PROTO) BLOCK;         # with proto
26     $subref = sub : ATTRS BLOCK;         # with attributes
27     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
28
29 To import subroutines:
30 X<import>
31
32     use MODULE qw(NAME1 NAME2 NAME3);
33
34 To call subroutines:
35 X<subroutine, call> X<call>
36
37     NAME(LIST);    # & is optional with parentheses.
38     NAME LIST;     # Parentheses optional if predeclared/imported.
39     &NAME(LIST);   # Circumvent prototypes.
40     &NAME;         # Makes current @_ visible to called subroutine.
41
42 =head1 DESCRIPTION
43
44 Like many languages, Perl provides for user-defined subroutines.
45 These may be located anywhere in the main program, loaded in from
46 other files via the C<do>, C<require>, or C<use> keywords, or
47 generated on the fly using C<eval> or anonymous subroutines.
48 You can even call a function indirectly using a variable containing
49 its name or a CODE reference.
50
51 The Perl model for function call and return values is simple: all
52 functions are passed as parameters one single flat list of scalars, and
53 all functions likewise return to their caller one single flat list of
54 scalars.  Any arrays or hashes in these call and return lists will
55 collapse, losing their identities--but you may always use
56 pass-by-reference instead to avoid this.  Both call and return lists may
57 contain as many or as few scalar elements as you'd like.  (Often a
58 function without an explicit return statement is called a subroutine, but
59 there's really no difference from Perl's perspective.)
60 X<subroutine, parameter> X<parameter>
61
62 Any arguments passed in show up in the array C<@_>.  Therefore, if
63 you called a function with two arguments, those would be stored in
64 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
65 elements are aliases for the actual scalar parameters.  In particular,
66 if an element C<$_[0]> is updated, the corresponding argument is
67 updated (or an error occurs if it is not updatable).  If an argument
68 is an array or hash element which did not exist when the function
69 was called, that element is created only when (and if) it is modified
70 or a reference to it is taken.  (Some earlier versions of Perl
71 created the element whether or not the element was assigned to.)
72 Assigning to the whole array C<@_> removes that aliasing, and does
73 not update any arguments.
74 X<subroutine, argument> X<argument> X<@_>
75
76 A C<return> statement may be used to exit a subroutine, optionally
77 specifying the returned value, which will be evaluated in the
78 appropriate context (list, scalar, or void) depending on the context of
79 the subroutine call.  If you specify no return value, the subroutine
80 returns an empty list in list context, the undefined value in scalar
81 context, or nothing in void context.  If you return one or more
82 aggregates (arrays and hashes), these will be flattened together into
83 one large indistinguishable list.
84
85 If no C<return> is found and if the last statement is an expression, its
86 value is returned. If the last statement is a loop control structure
87 like a C<foreach> or a C<while>, the returned value is unspecified. The
88 empty sub returns the empty list.
89 X<subroutine, return value> X<return value> X<return>
90
91 Perl does not have named formal parameters.  In practice all you
92 do is assign to a C<my()> list of these.  Variables that aren't
93 declared to be private are global variables.  For gory details
94 on creating private variables, see L<"Private Variables via my()">
95 and L<"Temporary Values via local()">.  To create protected
96 environments for a set of functions in a separate package (and
97 probably a separate file), see L<perlmod/"Packages">.
98 X<formal parameter> X<parameter, formal>
99
100 Example:
101
102     sub max {
103         my $max = shift(@_);
104         foreach $foo (@_) {
105             $max = $foo if $max < $foo;
106         }
107         return $max;
108     }
109     $bestday = max($mon,$tue,$wed,$thu,$fri);
110
111 Example:
112
113     # get a line, combining continuation lines
114     #  that start with whitespace
115
116     sub get_line {
117         $thisline = $lookahead;  # global variables!
118         LINE: while (defined($lookahead = <STDIN>)) {
119             if ($lookahead =~ /^[ \t]/) {
120                 $thisline .= $lookahead;
121             }
122             else {
123                 last LINE;
124             }
125         }
126         return $thisline;
127     }
128
129     $lookahead = <STDIN>;       # get first line
130     while (defined($line = get_line())) {
131         ...
132     }
133
134 Assigning to a list of private variables to name your arguments:
135
136     sub maybeset {
137         my($key, $value) = @_;
138         $Foo{$key} = $value unless $Foo{$key};
139     }
140
141 Because the assignment copies the values, this also has the effect
142 of turning call-by-reference into call-by-value.  Otherwise a
143 function is free to do in-place modifications of C<@_> and change
144 its caller's values.
145 X<call-by-reference> X<call-by-value>
146
147     upcase_in($v1, $v2);  # this changes $v1 and $v2
148     sub upcase_in {
149         for (@_) { tr/a-z/A-Z/ }
150     }
151
152 You aren't allowed to modify constants in this way, of course.  If an
153 argument were actually literal and you tried to change it, you'd take a
154 (presumably fatal) exception.   For example, this won't work:
155 X<call-by-reference> X<call-by-value>
156
157     upcase_in("frederick");
158
159 It would be much safer if the C<upcase_in()> function
160 were written to return a copy of its parameters instead
161 of changing them in place:
162
163     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
164     sub upcase {
165         return unless defined wantarray;  # void context, do nothing
166         my @parms = @_;
167         for (@parms) { tr/a-z/A-Z/ }
168         return wantarray ? @parms : $parms[0];
169     }
170
171 Notice how this (unprototyped) function doesn't care whether it was
172 passed real scalars or arrays.  Perl sees all arguments as one big,
173 long, flat parameter list in C<@_>.  This is one area where
174 Perl's simple argument-passing style shines.  The C<upcase()>
175 function would work perfectly well without changing the C<upcase()>
176 definition even if we fed it things like this:
177
178     @newlist   = upcase(@list1, @list2);
179     @newlist   = upcase( split /:/, $var );
180
181 Do not, however, be tempted to do this:
182
183     (@a, @b)   = upcase(@list1, @list2);
184
185 Like the flattened incoming parameter list, the return list is also
186 flattened on return.  So all you have managed to do here is stored
187 everything in C<@a> and made C<@b> empty.  See 
188 L<Pass by Reference> for alternatives.
189
190 A subroutine may be called using an explicit C<&> prefix.  The
191 C<&> is optional in modern Perl, as are parentheses if the
192 subroutine has been predeclared.  The C<&> is I<not> optional
193 when just naming the subroutine, such as when it's used as
194 an argument to defined() or undef().  Nor is it optional when you
195 want to do an indirect subroutine call with a subroutine name or
196 reference using the C<&$subref()> or C<&{$subref}()> constructs,
197 although the C<< $subref->() >> notation solves that problem.
198 See L<perlref> for more about all that.
199 X<&>
200
201 Subroutines may be called recursively.  If a subroutine is called
202 using the C<&> form, the argument list is optional, and if omitted,
203 no C<@_> array is set up for the subroutine: the C<@_> array at the
204 time of the call is visible to subroutine instead.  This is an
205 efficiency mechanism that new users may wish to avoid.
206 X<recursion>
207
208     &foo(1,2,3);        # pass three arguments
209     foo(1,2,3);         # the same
210
211     foo();              # pass a null list
212     &foo();             # the same
213
214     &foo;               # foo() get current args, like foo(@_) !!
215     foo;                # like foo() IFF sub foo predeclared, else "foo"
216
217 Not only does the C<&> form make the argument list optional, it also
218 disables any prototype checking on arguments you do provide.  This
219 is partly for historical reasons, and partly for having a convenient way
220 to cheat if you know what you're doing.  See L</Prototypes> below.
221 X<&>
222
223 Since Perl 5.16.0, the C<__SUB__> token is available under C<use feature
224 'current_sub'> and C<use 5.16.0>.  It will evaluate to a reference to the
225 currently-running sub, which allows for recursive calls without knowing
226 your subroutine's name.
227
228     use 5.16.0;
229     my $factorial = sub {
230       my ($x) = @_;
231       return 1 if $x == 1;
232       return($x * __SUB__->( $x - 1 ) );
233     };
234
235 Subroutines whose names are in all upper case are reserved to the Perl
236 core, as are modules whose names are in all lower case.  A subroutine in
237 all capitals is a loosely-held convention meaning it will be called
238 indirectly by the run-time system itself, usually due to a triggered event.
239 Subroutines that do special, pre-defined things include C<AUTOLOAD>, C<CLONE>,
240 C<DESTROY> plus all functions mentioned in L<perltie> and L<PerlIO::via>.
241
242 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
243 are not so much subroutines as named special code blocks, of which you
244 can have more than one in a package, and which you can B<not> call
245 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
246
247 =head2 Private Variables via my()
248 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
249 X<lexical scope> X<attributes, my>
250
251 Synopsis:
252
253     my $foo;            # declare $foo lexically local
254     my (@wid, %get);    # declare list of variables local
255     my $foo = "flurp";  # declare $foo lexical, and init it
256     my @oof = @bar;     # declare @oof lexical, and init it
257     my $x : Foo = $y;   # similar, with an attribute applied
258
259 B<WARNING>: The use of attribute lists on C<my> declarations is still
260 evolving.  The current semantics and interface are subject to change.
261 See L<attributes> and L<Attribute::Handlers>.
262
263 The C<my> operator declares the listed variables to be lexically
264 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
265 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
266 or C<do/require/use>'d file.  If more than one value is listed, the
267 list must be placed in parentheses.  All listed elements must be
268 legal lvalues.  Only alphanumeric identifiers may be lexically
269 scoped--magical built-ins like C<$/> must currently be C<local>ized
270 with C<local> instead.
271
272 Unlike dynamic variables created by the C<local> operator, lexical
273 variables declared with C<my> are totally hidden from the outside
274 world, including any called subroutines.  This is true if it's the
275 same subroutine called from itself or elsewhere--every call gets
276 its own copy.
277 X<local>
278
279 This doesn't mean that a C<my> variable declared in a statically
280 enclosing lexical scope would be invisible.  Only dynamic scopes
281 are cut off.   For example, the C<bumpx()> function below has access
282 to the lexical $x variable because both the C<my> and the C<sub>
283 occurred at the same scope, presumably file scope.
284
285     my $x = 10;
286     sub bumpx { $x++ } 
287
288 An C<eval()>, however, can see lexical variables of the scope it is
289 being evaluated in, so long as the names aren't hidden by declarations within
290 the C<eval()> itself.  See L<perlref>.
291 X<eval, scope of>
292
293 The parameter list to my() may be assigned to if desired, which allows you
294 to initialize your variables.  (If no initializer is given for a
295 particular variable, it is created with the undefined value.)  Commonly
296 this is used to name input parameters to a subroutine.  Examples:
297
298     $arg = "fred";        # "global" variable
299     $n = cube_root(27);
300     print "$arg thinks the root is $n\n";
301  fred thinks the root is 3
302
303     sub cube_root {
304         my $arg = shift;  # name doesn't matter
305         $arg **= 1/3;
306         return $arg;
307     }
308
309 The C<my> is simply a modifier on something you might assign to.  So when
310 you do assign to variables in its argument list, C<my> doesn't
311 change whether those variables are viewed as a scalar or an array.  So
312
313     my ($foo) = <STDIN>;                # WRONG?
314     my @FOO = <STDIN>;
315
316 both supply a list context to the right-hand side, while
317
318     my $foo = <STDIN>;
319
320 supplies a scalar context.  But the following declares only one variable:
321
322     my $foo, $bar = 1;                  # WRONG
323
324 That has the same effect as
325
326     my $foo;
327     $bar = 1;
328
329 The declared variable is not introduced (is not visible) until after
330 the current statement.  Thus,
331
332     my $x = $x;
333
334 can be used to initialize a new $x with the value of the old $x, and
335 the expression
336
337     my $x = 123 and $x == 123
338
339 is false unless the old $x happened to have the value C<123>.
340
341 Lexical scopes of control structures are not bounded precisely by the
342 braces that delimit their controlled blocks; control expressions are
343 part of that scope, too.  Thus in the loop
344
345     while (my $line = <>) {
346         $line = lc $line;
347     } continue {
348         print $line;
349     }
350
351 the scope of $line extends from its declaration throughout the rest of
352 the loop construct (including the C<continue> clause), but not beyond
353 it.  Similarly, in the conditional
354
355     if ((my $answer = <STDIN>) =~ /^yes$/i) {
356         user_agrees();
357     } elsif ($answer =~ /^no$/i) {
358         user_disagrees();
359     } else {
360         chomp $answer;
361         die "'$answer' is neither 'yes' nor 'no'";
362     }
363
364 the scope of $answer extends from its declaration through the rest
365 of that conditional, including any C<elsif> and C<else> clauses, 
366 but not beyond it.  See L<perlsyn/"Simple Statements"> for information
367 on the scope of variables in statements with modifiers.
368
369 The C<foreach> loop defaults to scoping its index variable dynamically
370 in the manner of C<local>.  However, if the index variable is
371 prefixed with the keyword C<my>, or if there is already a lexical
372 by that name in scope, then a new lexical is created instead.  Thus
373 in the loop
374 X<foreach> X<for>
375
376     for my $i (1, 2, 3) {
377         some_function();
378     }
379
380 the scope of $i extends to the end of the loop, but not beyond it,
381 rendering the value of $i inaccessible within C<some_function()>.
382 X<foreach> X<for>
383
384 Some users may wish to encourage the use of lexically scoped variables.
385 As an aid to catching implicit uses to package variables,
386 which are always global, if you say
387
388     use strict 'vars';
389
390 then any variable mentioned from there to the end of the enclosing
391 block must either refer to a lexical variable, be predeclared via
392 C<our> or C<use vars>, or else must be fully qualified with the package name.
393 A compilation error results otherwise.  An inner block may countermand
394 this with C<no strict 'vars'>.
395
396 A C<my> has both a compile-time and a run-time effect.  At compile
397 time, the compiler takes notice of it.  The principal usefulness
398 of this is to quiet C<use strict 'vars'>, but it is also essential
399 for generation of closures as detailed in L<perlref>.  Actual
400 initialization is delayed until run time, though, so it gets executed
401 at the appropriate time, such as each time through a loop, for
402 example.
403
404 Variables declared with C<my> are not part of any package and are therefore
405 never fully qualified with the package name.  In particular, you're not
406 allowed to try to make a package variable (or other global) lexical:
407
408     my $pack::var;      # ERROR!  Illegal syntax
409
410 In fact, a dynamic variable (also known as package or global variables)
411 are still accessible using the fully qualified C<::> notation even while a
412 lexical of the same name is also visible:
413
414     package main;
415     local $x = 10;
416     my    $x = 20;
417     print "$x and $::x\n";
418
419 That will print out C<20> and C<10>.
420
421 You may declare C<my> variables at the outermost scope of a file
422 to hide any such identifiers from the world outside that file.  This
423 is similar in spirit to C's static variables when they are used at
424 the file level.  To do this with a subroutine requires the use of
425 a closure (an anonymous function that accesses enclosing lexicals).
426 If you want to create a private subroutine that cannot be called
427 from outside that block, it can declare a lexical variable containing
428 an anonymous sub reference:
429
430     my $secret_version = '1.001-beta';
431     my $secret_sub = sub { print $secret_version };
432     &$secret_sub();
433
434 As long as the reference is never returned by any function within the
435 module, no outside module can see the subroutine, because its name is not in
436 any package's symbol table.  Remember that it's not I<REALLY> called
437 C<$some_pack::secret_version> or anything; it's just $secret_version,
438 unqualified and unqualifiable.
439
440 This does not work with object methods, however; all object methods
441 have to be in the symbol table of some package to be found.  See
442 L<perlref/"Function Templates"> for something of a work-around to
443 this.
444
445 =head2 Persistent Private Variables
446 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
447
448 There are two ways to build persistent private variables in Perl 5.10.
449 First, you can simply use the C<state> feature. Or, you can use closures,
450 if you want to stay compatible with releases older than 5.10.
451
452 =head3 Persistent variables via state()
453
454 Beginning with Perl 5.9.4, you can declare variables with the C<state>
455 keyword in place of C<my>.  For that to work, though, you must have
456 enabled that feature beforehand, either by using the C<feature> pragma, or
457 by using C<-E> on one-liners (see L<feature>).  Beginning with Perl 5.16,
458 the C<CORE::state> form does not require the
459 C<feature> pragma.
460
461 For example, the following code maintains a private counter, incremented
462 each time the gimme_another() function is called:
463
464     use feature 'state';
465     sub gimme_another { state $x; return ++$x }
466
467 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
468 code outside.
469
470 When combined with variable declaration, simple scalar assignment to C<state>
471 variables (as in C<state $x = 42>) is executed only the first time.  When such
472 statements are evaluated subsequent times, the assignment is ignored.  The
473 behavior of this sort of assignment to non-scalar variables is undefined.
474
475 =head3 Persistent variables with closures
476
477 Just because a lexical variable is lexically (also called statically)
478 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
479 within a function it works like a C static.  It normally works more
480 like a C auto, but with implicit garbage collection.  
481
482 Unlike local variables in C or C++, Perl's lexical variables don't
483 necessarily get recycled just because their scope has exited.
484 If something more permanent is still aware of the lexical, it will
485 stick around.  So long as something else references a lexical, that
486 lexical won't be freed--which is as it should be.  You wouldn't want
487 memory being free until you were done using it, or kept around once you
488 were done.  Automatic garbage collection takes care of this for you.
489
490 This means that you can pass back or save away references to lexical
491 variables, whereas to return a pointer to a C auto is a grave error.
492 It also gives us a way to simulate C's function statics.  Here's a
493 mechanism for giving a function private variables with both lexical
494 scoping and a static lifetime.  If you do want to create something like
495 C's static variables, just enclose the whole function in an extra block,
496 and put the static variable outside the function but in the block.
497
498     {
499         my $secret_val = 0;
500         sub gimme_another {
501             return ++$secret_val;
502         }
503     }
504     # $secret_val now becomes unreachable by the outside
505     # world, but retains its value between calls to gimme_another
506
507 If this function is being sourced in from a separate file
508 via C<require> or C<use>, then this is probably just fine.  If it's
509 all in the main program, you'll need to arrange for the C<my>
510 to be executed early, either by putting the whole block above
511 your main program, or more likely, placing merely a C<BEGIN>
512 code block around it to make sure it gets executed before your program
513 starts to run:
514
515     BEGIN {
516         my $secret_val = 0;
517         sub gimme_another {
518             return ++$secret_val;
519         }
520     }
521
522 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
523 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
524 C<INIT> and C<END>.
525
526 If declared at the outermost scope (the file scope), then lexicals
527 work somewhat like C's file statics.  They are available to all
528 functions in that same file declared below them, but are inaccessible
529 from outside that file.  This strategy is sometimes used in modules
530 to create private variables that the whole module can see.
531
532 =head2 Temporary Values via local()
533 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
534 X<variable, temporary>
535
536 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
537 it's faster and safer.  Exceptions to this include the global punctuation
538 variables, global filehandles and formats, and direct manipulation of the
539 Perl symbol table itself.  C<local> is mostly used when the current value
540 of a variable must be visible to called subroutines.
541
542 Synopsis:
543
544     # localization of values
545
546     local $foo;                 # make $foo dynamically local
547     local (@wid, %get);         # make list of variables local
548     local $foo = "flurp";       # make $foo dynamic, and init it
549     local @oof = @bar;          # make @oof dynamic, and init it
550
551     local $hash{key} = "val";   # sets a local value for this hash entry
552     delete local $hash{key};    # delete this entry for the current block
553     local ($cond ? $v1 : $v2);  # several types of lvalues support
554                                 # localization
555
556     # localization of symbols
557
558     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
559     local *merlyn = *randal;    # now $merlyn is really $randal, plus
560                                 #     @merlyn is really @randal, etc
561     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
562     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
563
564 A C<local> modifies its listed variables to be "local" to the
565 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
566 called from within that block>.  A C<local> just gives temporary
567 values to global (meaning package) variables.  It does I<not> create
568 a local variable.  This is known as dynamic scoping.  Lexical scoping
569 is done with C<my>, which works more like C's auto declarations.
570
571 Some types of lvalues can be localized as well: hash and array elements
572 and slices, conditionals (provided that their result is always
573 localizable), and symbolic references.  As for simple variables, this
574 creates new, dynamically scoped values.
575
576 If more than one variable or expression is given to C<local>, they must be
577 placed in parentheses.  This operator works
578 by saving the current values of those variables in its argument list on a
579 hidden stack and restoring them upon exiting the block, subroutine, or
580 eval.  This means that called subroutines can also reference the local
581 variable, but not the global one.  The argument list may be assigned to if
582 desired, which allows you to initialize your local variables.  (If no
583 initializer is given for a particular variable, it is created with an
584 undefined value.)
585
586 Because C<local> is a run-time operator, it gets executed each time
587 through a loop.  Consequently, it's more efficient to localize your
588 variables outside the loop.
589
590 =head3 Grammatical note on local()
591 X<local, context>
592
593 A C<local> is simply a modifier on an lvalue expression.  When you assign to
594 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
595 as a scalar or an array.  So
596
597     local($foo) = <STDIN>;
598     local @FOO = <STDIN>;
599
600 both supply a list context to the right-hand side, while
601
602     local $foo = <STDIN>;
603
604 supplies a scalar context.
605
606 =head3 Localization of special variables
607 X<local, special variable>
608
609 If you localize a special variable, you'll be giving a new value to it,
610 but its magic won't go away.  That means that all side-effects related
611 to this magic still work with the localized value.
612
613 This feature allows code like this to work :
614
615     # Read the whole contents of FILE in $slurp
616     { local $/ = undef; $slurp = <FILE>; }
617
618 Note, however, that this restricts localization of some values ; for
619 example, the following statement dies, as of perl 5.9.0, with an error
620 I<Modification of a read-only value attempted>, because the $1 variable is
621 magical and read-only :
622
623     local $1 = 2;
624
625 One exception is the default scalar variable: starting with perl 5.14
626 C<local($_)> will always strip all magic from $_, to make it possible
627 to safely reuse $_ in a subroutine.
628
629 B<WARNING>: Localization of tied arrays and hashes does not currently
630 work as described.
631 This will be fixed in a future release of Perl; in the meantime, avoid
632 code that relies on any particular behaviour of localising tied arrays
633 or hashes (localising individual elements is still okay).
634 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
635 details.
636 X<local, tie>
637
638 =head3 Localization of globs
639 X<local, glob> X<glob>
640
641 The construct
642
643     local *name;
644
645 creates a whole new symbol table entry for the glob C<name> in the
646 current package.  That means that all variables in its glob slot ($name,
647 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
648
649 This implies, among other things, that any magic eventually carried by
650 those variables is locally lost.  In other words, saying C<local */>
651 will not have any effect on the internal value of the input record
652 separator.
653
654 =head3 Localization of elements of composite types
655 X<local, composite type element> X<local, array element> X<local, hash element>
656
657 It's also worth taking a moment to explain what happens when you
658 C<local>ize a member of a composite type (i.e. an array or hash element).
659 In this case, the element is C<local>ized I<by name>. This means that
660 when the scope of the C<local()> ends, the saved value will be
661 restored to the hash element whose key was named in the C<local()>, or
662 the array element whose index was named in the C<local()>.  If that
663 element was deleted while the C<local()> was in effect (e.g. by a
664 C<delete()> from a hash or a C<shift()> of an array), it will spring
665 back into existence, possibly extending an array and filling in the
666 skipped elements with C<undef>.  For instance, if you say
667
668     %hash = ( 'This' => 'is', 'a' => 'test' );
669     @ary  = ( 0..5 );
670     {
671          local($ary[5]) = 6;
672          local($hash{'a'}) = 'drill';
673          while (my $e = pop(@ary)) {
674              print "$e . . .\n";
675              last unless $e > 3;
676          }
677          if (@ary) {
678              $hash{'only a'} = 'test';
679              delete $hash{'a'};
680          }
681     }
682     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
683     print "The array has ",scalar(@ary)," elements: ",
684           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
685
686 Perl will print
687
688     6 . . .
689     4 . . .
690     3 . . .
691     This is a test only a test.
692     The array has 6 elements: 0, 1, 2, undef, undef, 5
693
694 The behavior of local() on non-existent members of composite
695 types is subject to change in future.
696
697 =head3 Localized deletion of elements of composite types
698 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
699
700 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
701 constructs to delete a composite type entry for the current block and restore
702 it when it ends. They return the array/hash value before the localization,
703 which means that they are respectively equivalent to
704
705     do {
706         my $val = $array[$idx];
707         local  $array[$idx];
708         delete $array[$idx];
709         $val
710     }
711
712 and
713
714     do {
715         my $val = $hash{key};
716         local  $hash{key};
717         delete $hash{key};
718         $val
719     }
720
721 except that for those the C<local> is scoped to the C<do> block. Slices are
722 also accepted.
723
724     my %hash = (
725      a => [ 7, 8, 9 ],
726      b => 1,
727     )
728
729     {
730      my $a = delete local $hash{a};
731      # $a is [ 7, 8, 9 ]
732      # %hash is (b => 1)
733
734      {
735       my @nums = delete local @$a[0, 2]
736       # @nums is (7, 9)
737       # $a is [ undef, 8 ]
738
739       $a[0] = 999; # will be erased when the scope ends
740      }
741      # $a is back to [ 7, 8, 9 ]
742
743     }
744     # %hash is back to its original state
745
746 =head2 Lvalue subroutines
747 X<lvalue> X<subroutine, lvalue>
748
749 B<WARNING>: Lvalue subroutines are still experimental and the
750 implementation may change in future versions of Perl.
751
752 It is possible to return a modifiable value from a subroutine.
753 To do this, you have to declare the subroutine to return an lvalue.
754
755     my $val;
756     sub canmod : lvalue {
757         $val;  # or:  return $val;
758     }
759     sub nomod {
760         $val;
761     }
762
763     canmod() = 5;   # assigns to $val
764     nomod()  = 5;   # ERROR
765
766 The scalar/list context for the subroutine and for the right-hand
767 side of assignment is determined as if the subroutine call is replaced
768 by a scalar. For example, consider:
769
770     data(2,3) = get_data(3,4);
771
772 Both subroutines here are called in a scalar context, while in:
773
774     (data(2,3)) = get_data(3,4);
775
776 and in:
777
778     (data(2),data(3)) = get_data(3,4);
779
780 all the subroutines are called in a list context.
781
782 =over 4
783
784 =item Lvalue subroutines are EXPERIMENTAL
785
786 They appear to be convenient, but there is at least one reason to be
787 circumspect.
788
789 They violate encapsulation.  A normal mutator can check the supplied
790 argument before setting the attribute it is protecting, an lvalue
791 subroutine never gets that chance.  Consider;
792
793     my $some_array_ref = [];    # protected by mutators ??
794
795     sub set_arr {               # normal mutator
796         my $val = shift;
797         die("expected array, you supplied ", ref $val)
798            unless ref $val eq 'ARRAY';
799         $some_array_ref = $val;
800     }
801     sub set_arr_lv : lvalue {   # lvalue mutator
802         $some_array_ref;
803     }
804
805     # set_arr_lv cannot stop this !
806     set_arr_lv() = { a => 1 };
807
808 =back
809
810 =head2 Passing Symbol Table Entries (typeglobs)
811 X<typeglob> X<*>
812
813 B<WARNING>: The mechanism described in this section was originally
814 the only way to simulate pass-by-reference in older versions of
815 Perl.  While it still works fine in modern versions, the new reference
816 mechanism is generally easier to work with.  See below.
817
818 Sometimes you don't want to pass the value of an array to a subroutine
819 but rather the name of it, so that the subroutine can modify the global
820 copy of it rather than working with a local copy.  In perl you can
821 refer to all objects of a particular name by prefixing the name
822 with a star: C<*foo>.  This is often known as a "typeglob", because the
823 star on the front can be thought of as a wildcard match for all the
824 funny prefix characters on variables and subroutines and such.
825
826 When evaluated, the typeglob produces a scalar value that represents
827 all the objects of that name, including any filehandle, format, or
828 subroutine.  When assigned to, it causes the name mentioned to refer to
829 whatever C<*> value was assigned to it.  Example:
830
831     sub doubleary {
832         local(*someary) = @_;
833         foreach $elem (@someary) {
834             $elem *= 2;
835         }
836     }
837     doubleary(*foo);
838     doubleary(*bar);
839
840 Scalars are already passed by reference, so you can modify
841 scalar arguments without using this mechanism by referring explicitly
842 to C<$_[0]> etc.  You can modify all the elements of an array by passing
843 all the elements as scalars, but you have to use the C<*> mechanism (or
844 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
845 an array.  It will certainly be faster to pass the typeglob (or reference).
846
847 Even if you don't want to modify an array, this mechanism is useful for
848 passing multiple arrays in a single LIST, because normally the LIST
849 mechanism will merge all the array values so that you can't extract out
850 the individual arrays.  For more on typeglobs, see
851 L<perldata/"Typeglobs and Filehandles">.
852
853 =head2 When to Still Use local()
854 X<local> X<variable, local>
855
856 Despite the existence of C<my>, there are still three places where the
857 C<local> operator still shines.  In fact, in these three places, you
858 I<must> use C<local> instead of C<my>.
859
860 =over 4
861
862 =item 1.
863
864 You need to give a global variable a temporary value, especially $_.
865
866 The global variables, like C<@ARGV> or the punctuation variables, must be 
867 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
868 it up into chunks separated by lines of equal signs, which are placed
869 in C<@Fields>.
870
871     {
872         local @ARGV = ("/etc/motd");
873         local $/ = undef;
874         local $_ = <>;  
875         @Fields = split /^\s*=+\s*$/;
876     } 
877
878 It particular, it's important to C<local>ize $_ in any routine that assigns
879 to it.  Look out for implicit assignments in C<while> conditionals.
880
881 =item 2.
882
883 You need to create a local file or directory handle or a local function.
884
885 A function that needs a filehandle of its own must use
886 C<local()> on a complete typeglob.   This can be used to create new symbol
887 table entries:
888
889     sub ioqueue {
890         local  (*READER, *WRITER);    # not my!
891         pipe    (READER,  WRITER)     or die "pipe: $!";
892         return (*READER, *WRITER);
893     }
894     ($head, $tail) = ioqueue();
895
896 See the Symbol module for a way to create anonymous symbol table
897 entries.
898
899 Because assignment of a reference to a typeglob creates an alias, this
900 can be used to create what is effectively a local function, or at least,
901 a local alias.
902
903     {
904         local *grow = \&shrink; # only until this block exits
905         grow();                 # really calls shrink()
906         move();                 # if move() grow()s, it shrink()s too
907     }
908     grow();                     # get the real grow() again
909
910 See L<perlref/"Function Templates"> for more about manipulating
911 functions by name in this way.
912
913 =item 3.
914
915 You want to temporarily change just one element of an array or hash.
916
917 You can C<local>ize just one element of an aggregate.  Usually this
918 is done on dynamics:
919
920     {
921         local $SIG{INT} = 'IGNORE';
922         funct();                            # uninterruptible
923     } 
924     # interruptibility automatically restored here
925
926 But it also works on lexically declared aggregates.  Prior to 5.005,
927 this operation could on occasion misbehave.
928
929 =back
930
931 =head2 Pass by Reference
932 X<pass by reference> X<pass-by-reference> X<reference>
933
934 If you want to pass more than one array or hash into a function--or
935 return them from it--and have them maintain their integrity, then
936 you're going to have to use an explicit pass-by-reference.  Before you
937 do that, you need to understand references as detailed in L<perlref>.
938 This section may not make much sense to you otherwise.
939
940 Here are a few simple examples.  First, let's pass in several arrays
941 to a function and have it C<pop> all of then, returning a new list
942 of all their former last elements:
943
944     @tailings = popmany ( \@a, \@b, \@c, \@d );
945
946     sub popmany {
947         my $aref;
948         my @retlist = ();
949         foreach $aref ( @_ ) {
950             push @retlist, pop @$aref;
951         }
952         return @retlist;
953     }
954
955 Here's how you might write a function that returns a
956 list of keys occurring in all the hashes passed to it:
957
958     @common = inter( \%foo, \%bar, \%joe );
959     sub inter {
960         my ($k, $href, %seen); # locals
961         foreach $href (@_) {
962             while ( $k = each %$href ) {
963                 $seen{$k}++;
964             }
965         }
966         return grep { $seen{$_} == @_ } keys %seen;
967     }
968
969 So far, we're using just the normal list return mechanism.
970 What happens if you want to pass or return a hash?  Well,
971 if you're using only one of them, or you don't mind them
972 concatenating, then the normal calling convention is ok, although
973 a little expensive.
974
975 Where people get into trouble is here:
976
977     (@a, @b) = func(@c, @d);
978 or
979     (%a, %b) = func(%c, %d);
980
981 That syntax simply won't work.  It sets just C<@a> or C<%a> and
982 clears the C<@b> or C<%b>.  Plus the function didn't get passed
983 into two separate arrays or hashes: it got one long list in C<@_>,
984 as always.
985
986 If you can arrange for everyone to deal with this through references, it's
987 cleaner code, although not so nice to look at.  Here's a function that
988 takes two array references as arguments, returning the two array elements
989 in order of how many elements they have in them:
990
991     ($aref, $bref) = func(\@c, \@d);
992     print "@$aref has more than @$bref\n";
993     sub func {
994         my ($cref, $dref) = @_;
995         if (@$cref > @$dref) {
996             return ($cref, $dref);
997         } else {
998             return ($dref, $cref);
999         }
1000     }
1001
1002 It turns out that you can actually do this also:
1003
1004     (*a, *b) = func(\@c, \@d);
1005     print "@a has more than @b\n";
1006     sub func {
1007         local (*c, *d) = @_;
1008         if (@c > @d) {
1009             return (\@c, \@d);
1010         } else {
1011             return (\@d, \@c);
1012         }
1013     }
1014
1015 Here we're using the typeglobs to do symbol table aliasing.  It's
1016 a tad subtle, though, and also won't work if you're using C<my>
1017 variables, because only globals (even in disguise as C<local>s)
1018 are in the symbol table.
1019
1020 If you're passing around filehandles, you could usually just use the bare
1021 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1022 For example:
1023
1024     splutter(\*STDOUT);
1025     sub splutter {
1026         my $fh = shift;
1027         print $fh "her um well a hmmm\n";
1028     }
1029
1030     $rec = get_rec(\*STDIN);
1031     sub get_rec {
1032         my $fh = shift;
1033         return scalar <$fh>;
1034     }
1035
1036 If you're planning on generating new filehandles, you could do this.
1037 Notice to pass back just the bare *FH, not its reference.
1038
1039     sub openit {
1040         my $path = shift;
1041         local *FH;
1042         return open (FH, $path) ? *FH : undef;
1043     }
1044
1045 =head2 Prototypes
1046 X<prototype> X<subroutine, prototype>
1047
1048 Perl supports a very limited kind of compile-time argument checking
1049 using function prototyping.  If you declare
1050
1051     sub mypush (+@)
1052
1053 then C<mypush()> takes arguments exactly like C<push()> does.  The
1054 function declaration must be visible at compile time.  The prototype
1055 affects only interpretation of new-style calls to the function,
1056 where new-style is defined as not using the C<&> character.  In
1057 other words, if you call it like a built-in function, then it behaves
1058 like a built-in function.  If you call it like an old-fashioned
1059 subroutine, then it behaves like an old-fashioned subroutine.  It
1060 naturally falls out from this rule that prototypes have no influence
1061 on subroutine references like C<\&foo> or on indirect subroutine
1062 calls like C<&{$subref}> or C<< $subref->() >>.
1063
1064 Method calls are not influenced by prototypes either, because the
1065 function to be called is indeterminate at compile time, since
1066 the exact code called depends on inheritance.
1067
1068 Because the intent of this feature is primarily to let you define
1069 subroutines that work like built-in functions, here are prototypes
1070 for some other functions that parse almost exactly like the
1071 corresponding built-in.
1072
1073     Declared as                 Called as
1074
1075     sub mylink ($$)          mylink $old, $new
1076     sub myvec ($$$)          myvec $var, $offset, 1
1077     sub myindex ($$;$)       myindex &getstring, "substr"
1078     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
1079     sub myreverse (@)        myreverse $a, $b, $c
1080     sub myjoin ($@)          myjoin ":", $a, $b, $c
1081     sub mypop (+)            mypop @array
1082     sub mysplice (+$$@)      mysplice @array, 0, 2, @pushme
1083     sub mykeys (+)           mykeys %{$hashref}
1084     sub myopen (*;$)         myopen HANDLE, $name
1085     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
1086     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
1087     sub myrand (;$)          myrand 42
1088     sub mytime ()            mytime
1089
1090 Any backslashed prototype character represents an actual argument
1091 that must start with that character (optionally preceded by C<my>,
1092 C<our> or C<local>), with the exception of C<$>, which will
1093 accept any scalar lvalue expression, such as C<$foo = 7> or
1094 C<< my_function()->[0] >>. The value passed as part of C<@_> will be a
1095 reference to the actual argument given in the subroutine call,
1096 obtained by applying C<\> to that argument.
1097
1098 You can use the C<\[]> backslash group notation to specify more than one
1099 allowed argument type. For example:
1100
1101     sub myref (\[$@%&*])
1102
1103 will allow calling myref() as
1104
1105     myref $var
1106     myref @array
1107     myref %hash
1108     myref &sub
1109     myref *glob
1110
1111 and the first argument of myref() will be a reference to
1112 a scalar, an array, a hash, a code, or a glob.
1113
1114 Unbackslashed prototype characters have special meanings.  Any
1115 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1116 list context.  An argument represented by C<$> forces scalar context.  An
1117 C<&> requires an anonymous subroutine, which, if passed as the first
1118 argument, does not require the C<sub> keyword or a subsequent comma.
1119
1120 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1121 typeglob, or a reference to a typeglob in that slot.  The value will be
1122 available to the subroutine either as a simple scalar, or (in the latter
1123 two cases) as a reference to the typeglob.  If you wish to always convert
1124 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1125 follows:
1126
1127     use Symbol 'qualify_to_ref';
1128
1129     sub foo (*) {
1130         my $fh = qualify_to_ref(shift, caller);
1131         ...
1132     }
1133
1134 The C<+> prototype is a special alternative to C<$> that will act like
1135 C<\[@%]> when given a literal array or hash variable, but will otherwise
1136 force scalar context on the argument.  This is useful for functions which
1137 should accept either a literal array or an array reference as the argument:
1138
1139     sub mypush (+@) {
1140         my $aref = shift;
1141         die "Not an array or arrayref" unless ref $aref eq 'ARRAY';
1142         push @$aref, @_;
1143     }
1144
1145 When using the C<+> prototype, your function must check that the argument
1146 is of an acceptable type.
1147
1148 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1149 It is redundant before C<@> or C<%>, which gobble up everything else.
1150
1151 As the last character of a prototype, or just before a semicolon, a C<@>
1152 or a C<%>, you can use C<_> in place of C<$>: if this argument is not
1153 provided, C<$_> will be used instead.
1154
1155 Note how the last three examples in the table above are treated
1156 specially by the parser.  C<mygrep()> is parsed as a true list
1157 operator, C<myrand()> is parsed as a true unary operator with unary
1158 precedence the same as C<rand()>, and C<mytime()> is truly without
1159 arguments, just like C<time()>.  That is, if you say
1160
1161     mytime +2;
1162
1163 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1164 without a prototype.  If you want to force a unary function to have the
1165 same precedence as a list operator, add C<;> to the end of the prototype:
1166
1167     sub mygetprotobynumber($;);
1168     mygetprotobynumber $a > $b; # parsed as mygetprotobynumber($a > $b)
1169
1170 The interesting thing about C<&> is that you can generate new syntax with it,
1171 provided it's in the initial position:
1172 X<&>
1173
1174     sub try (&@) {
1175         my($try,$catch) = @_;
1176         eval { &$try };
1177         if ($@) {
1178             local $_ = $@;
1179             &$catch;
1180         }
1181     }
1182     sub catch (&) { $_[0] }
1183
1184     try {
1185         die "phooey";
1186     } catch {
1187         /phooey/ and print "unphooey\n";
1188     };
1189
1190 That prints C<"unphooey">.  (Yes, there are still unresolved
1191 issues having to do with visibility of C<@_>.  I'm ignoring that
1192 question for the moment.  (But note that if we make C<@_> lexically
1193 scoped, those anonymous subroutines can act like closures... (Gee,
1194 is this sounding a little Lispish?  (Never mind.))))
1195
1196 And here's a reimplementation of the Perl C<grep> operator:
1197 X<grep>
1198
1199     sub mygrep (&@) {
1200         my $code = shift;
1201         my @result;
1202         foreach $_ (@_) {
1203             push(@result, $_) if &$code;
1204         }
1205         @result;
1206     }
1207
1208 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1209 been intentionally left out of prototypes for the express purpose of
1210 someday in the future adding named, formal parameters.  The current
1211 mechanism's main goal is to let module writers provide better diagnostics
1212 for module users.  Larry feels the notation quite understandable to Perl
1213 programmers, and that it will not intrude greatly upon the meat of the
1214 module, nor make it harder to read.  The line noise is visually
1215 encapsulated into a small pill that's easy to swallow.
1216
1217 If you try to use an alphanumeric sequence in a prototype you will
1218 generate an optional warning - "Illegal character in prototype...".
1219 Unfortunately earlier versions of Perl allowed the prototype to be
1220 used as long as its prefix was a valid prototype.  The warning may be
1221 upgraded to a fatal error in a future version of Perl once the
1222 majority of offending code is fixed.
1223
1224 It's probably best to prototype new functions, not retrofit prototyping
1225 into older ones.  That's because you must be especially careful about
1226 silent impositions of differing list versus scalar contexts.  For example,
1227 if you decide that a function should take just one parameter, like this:
1228
1229     sub func ($) {
1230         my $n = shift;
1231         print "you gave me $n\n";
1232     }
1233
1234 and someone has been calling it with an array or expression
1235 returning a list:
1236
1237     func(@foo);
1238     func( split /:/ );
1239
1240 Then you've just supplied an automatic C<scalar> in front of their
1241 argument, which can be more than a bit surprising.  The old C<@foo>
1242 which used to hold one thing doesn't get passed in.  Instead,
1243 C<func()> now gets passed in a C<1>; that is, the number of elements
1244 in C<@foo>.  And the C<split> gets called in scalar context so it
1245 starts scribbling on your C<@_> parameter list.  Ouch!
1246
1247 This is all very powerful, of course, and should be used only in moderation
1248 to make the world a better place.
1249
1250 =head2 Constant Functions
1251 X<constant>
1252
1253 Functions with a prototype of C<()> are potential candidates for
1254 inlining.  If the result after optimization and constant folding
1255 is either a constant or a lexically-scoped scalar which has no other
1256 references, then it will be used in place of function calls made
1257 without C<&>.  Calls made using C<&> are never inlined.  (See
1258 F<constant.pm> for an easy way to declare most constants.)
1259
1260 The following functions would all be inlined:
1261
1262     sub pi ()           { 3.14159 }             # Not exact, but close.
1263     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1264                                                 # and it's inlined, too!
1265     sub ST_DEV ()       { 0 }
1266     sub ST_INO ()       { 1 }
1267
1268     sub FLAG_FOO ()     { 1 << 8 }
1269     sub FLAG_BAR ()     { 1 << 9 }
1270     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1271
1272     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1273
1274     sub N () { int(OPT_BAZ) / 3 }
1275
1276     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1277
1278 Be aware that these will not be inlined; as they contain inner scopes,
1279 the constant folding doesn't reduce them to a single constant:
1280
1281     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1282
1283     sub baz_val () {
1284         if (OPT_BAZ) {
1285             return 23;
1286         }
1287         else {
1288             return 42;
1289         }
1290     }
1291
1292 If you redefine a subroutine that was eligible for inlining, you'll get
1293 a warning by default.  (You can use this warning to tell whether or not a
1294 particular subroutine is considered constant.)  The warning is
1295 considered severe enough not to be affected by the B<-w>
1296 switch (or its absence) because previously compiled
1297 invocations of the function will still be using the old value of the
1298 function.  If you need to be able to redefine the subroutine, you need to
1299 ensure that it isn't inlined, either by dropping the C<()> prototype
1300 (which changes calling semantics, so beware) or by thwarting the
1301 inlining mechanism in some other way, such as
1302
1303     sub not_inlined () {
1304         23 if $];
1305     }
1306
1307 =head2 Overriding Built-in Functions
1308 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1309
1310 Many built-in functions may be overridden, though this should be tried
1311 only occasionally and for good reason.  Typically this might be
1312 done by a package attempting to emulate missing built-in functionality
1313 on a non-Unix system.
1314
1315 Overriding may be done only by importing the name from a module at
1316 compile time--ordinary predeclaration isn't good enough.  However, the
1317 C<use subs> pragma lets you, in effect, predeclare subs
1318 via the import syntax, and these names may then override built-in ones:
1319
1320     use subs 'chdir', 'chroot', 'chmod', 'chown';
1321     chdir $somewhere;
1322     sub chdir { ... }
1323
1324 To unambiguously refer to the built-in form, precede the
1325 built-in name with the special package qualifier C<CORE::>.  For example,
1326 saying C<CORE::open()> always refers to the built-in C<open()>, even
1327 if the current package has imported some other subroutine called
1328 C<&open()> from elsewhere.  Even though it looks like a regular
1329 function call, it isn't: the CORE:: prefix in that case is part of Perl's
1330 syntax, and works for any keyword, regardless of what is in the CORE
1331 package.  Taking a reference to it, that is, C<\&CORE::open>, only works
1332 for some keywords.  See L<CORE>.
1333
1334 Library modules should not in general export built-in names like C<open>
1335 or C<chdir> as part of their default C<@EXPORT> list, because these may
1336 sneak into someone else's namespace and change the semantics unexpectedly.
1337 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1338 possible for a user to import the name explicitly, but not implicitly.
1339 That is, they could say
1340
1341     use Module 'open';
1342
1343 and it would import the C<open> override.  But if they said
1344
1345     use Module;
1346
1347 they would get the default imports without overrides.
1348
1349 The foregoing mechanism for overriding built-in is restricted, quite
1350 deliberately, to the package that requests the import.  There is a second
1351 method that is sometimes applicable when you wish to override a built-in
1352 everywhere, without regard to namespace boundaries.  This is achieved by
1353 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1354 example that quite brazenly replaces the C<glob> operator with something
1355 that understands regular expressions.
1356
1357     package REGlob;
1358     require Exporter;
1359     @ISA = 'Exporter';
1360     @EXPORT_OK = 'glob';
1361
1362     sub import {
1363         my $pkg = shift;
1364         return unless @_;
1365         my $sym = shift;
1366         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1367         $pkg->export($where, $sym, @_);
1368     }
1369
1370     sub glob {
1371         my $pat = shift;
1372         my @got;
1373         if (opendir my $d, '.') { 
1374             @got = grep /$pat/, readdir $d; 
1375             closedir $d;   
1376         }
1377         return @got;
1378     }
1379     1;
1380
1381 And here's how it could be (ab)used:
1382
1383     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1384     package Foo;
1385     use REGlob 'glob';              # override glob() in Foo:: only
1386     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1387
1388 The initial comment shows a contrived, even dangerous example.
1389 By overriding C<glob> globally, you would be forcing the new (and
1390 subversive) behavior for the C<glob> operator for I<every> namespace,
1391 without the complete cognizance or cooperation of the modules that own
1392 those namespaces.  Naturally, this should be done with extreme caution--if
1393 it must be done at all.
1394
1395 The C<REGlob> example above does not implement all the support needed to
1396 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1397 different behaviors depending on whether it appears in a scalar or list
1398 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1399 context sensitive behaviors, and these must be adequately supported by
1400 a properly written override.  For a fully functional example of overriding
1401 C<glob>, study the implementation of C<File::DosGlob> in the standard
1402 library.
1403
1404 When you override a built-in, your replacement should be consistent (if
1405 possible) with the built-in native syntax.  You can achieve this by using
1406 a suitable prototype.  To get the prototype of an overridable built-in,
1407 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1408 (see L<perlfunc/prototype>).
1409
1410 Note however that some built-ins can't have their syntax expressed by a
1411 prototype (such as C<system> or C<chomp>).  If you override them you won't
1412 be able to fully mimic their original syntax.
1413
1414 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1415 to special magic, their original syntax is preserved, and you don't have
1416 to define a prototype for their replacements.  (You can't override the
1417 C<do BLOCK> syntax, though).
1418
1419 C<require> has special additional dark magic: if you invoke your
1420 C<require> replacement as C<require Foo::Bar>, it will actually receive
1421 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1422
1423 And, as you'll have noticed from the previous example, if you override
1424 C<glob>, the C<< <*> >> glob operator is overridden as well.
1425
1426 In a similar fashion, overriding the C<readline> function also overrides
1427 the equivalent I/O operator C<< <FILEHANDLE> >>. Also, overriding
1428 C<readpipe> also overrides the operators C<``> and C<qx//>.
1429
1430 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1431
1432 =head2 Autoloading
1433 X<autoloading> X<AUTOLOAD>
1434
1435 If you call a subroutine that is undefined, you would ordinarily
1436 get an immediate, fatal error complaining that the subroutine doesn't
1437 exist.  (Likewise for subroutines being used as methods, when the
1438 method doesn't exist in any base class of the class's package.)
1439 However, if an C<AUTOLOAD> subroutine is defined in the package or
1440 packages used to locate the original subroutine, then that
1441 C<AUTOLOAD> subroutine is called with the arguments that would have
1442 been passed to the original subroutine.  The fully qualified name
1443 of the original subroutine magically appears in the global $AUTOLOAD
1444 variable of the same package as the C<AUTOLOAD> routine.  The name
1445 is not passed as an ordinary argument because, er, well, just
1446 because, that's why.  (As an exception, a method call to a nonexistent
1447 C<import> or C<unimport> method is just skipped instead.  Also, if
1448 the AUTOLOAD subroutine is an XSUB, there are other ways to retrieve the
1449 subroutine name.  See L<perlguts/Autoloading with XSUBs> for details.)
1450
1451
1452 Many C<AUTOLOAD> routines load in a definition for the requested
1453 subroutine using eval(), then execute that subroutine using a special
1454 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1455 without a trace.  (See the source to the standard module documented
1456 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1457 also just emulate the routine and never define it.   For example,
1458 let's pretend that a function that wasn't defined should just invoke
1459 C<system> with those arguments.  All you'd do is:
1460
1461     sub AUTOLOAD {
1462         my $program = $AUTOLOAD;
1463         $program =~ s/.*:://;
1464         system($program, @_);
1465     }
1466     date();
1467     who('am', 'i');
1468     ls('-l');
1469
1470 In fact, if you predeclare functions you want to call that way, you don't
1471 even need parentheses:
1472
1473     use subs qw(date who ls);
1474     date;
1475     who "am", "i";
1476     ls '-l';
1477
1478 A more complete example of this is the Shell module on CPAN, which
1479 can treat undefined subroutine calls as calls to external programs.
1480
1481 Mechanisms are available to help modules writers split their modules
1482 into autoloadable files.  See the standard AutoLoader module
1483 described in L<AutoLoader> and in L<AutoSplit>, the standard
1484 SelfLoader modules in L<SelfLoader>, and the document on adding C
1485 functions to Perl code in L<perlxs>.
1486
1487 =head2 Subroutine Attributes
1488 X<attribute> X<subroutine, attribute> X<attrs>
1489
1490 A subroutine declaration or definition may have a list of attributes
1491 associated with it.  If such an attribute list is present, it is
1492 broken up at space or colon boundaries and treated as though a
1493 C<use attributes> had been seen.  See L<attributes> for details
1494 about what attributes are currently supported.
1495 Unlike the limitation with the obsolescent C<use attrs>, the
1496 C<sub : ATTRLIST> syntax works to associate the attributes with
1497 a pre-declaration, and not just with a subroutine definition.
1498
1499 The attributes must be valid as simple identifier names (without any
1500 punctuation other than the '_' character).  They may have a parameter
1501 list appended, which is only checked for whether its parentheses ('(',')')
1502 nest properly.
1503
1504 Examples of valid syntax (even though the attributes are unknown):
1505
1506     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1507     sub plugh () : Ugly('\(") :Bad;
1508     sub xyzzy : _5x5 { ... }
1509
1510 Examples of invalid syntax:
1511
1512     sub fnord : switch(10,foo(); # ()-string not balanced
1513     sub snoid : Ugly('(');        # ()-string not balanced
1514     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1515     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1516     sub snurt : foo + bar;        # "+" not a colon or space
1517
1518 The attribute list is passed as a list of constant strings to the code
1519 which associates them with the subroutine.  In particular, the second example
1520 of valid syntax above currently looks like this in terms of how it's
1521 parsed and invoked:
1522
1523     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1524
1525 For further details on attribute lists and their manipulation,
1526 see L<attributes> and L<Attribute::Handlers>.
1527
1528 =head1 SEE ALSO
1529
1530 See L<perlref/"Function Templates"> for more about references and closures.
1531 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1532 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1533 See L<perlmod> to learn about bundling up your functions in separate files.
1534 See L<perlmodlib> to learn what library modules come standard on your system.
1535 See L<perlootut> to learn how to make object method calls.