This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
mktables: Generate native code-point tables
[perl5.git] / lib / unicore / mktables
1 #!/usr/bin/perl -w
2
3 # !!!!!!!!!!!!!!       IF YOU MODIFY THIS FILE       !!!!!!!!!!!!!!!!!!!!!!!!!
4 # Any files created or read by this program should be listed in 'mktables.lst'
5 # Use -makelist to regenerate it.
6
7 # Needs 'no overloading' to run faster on miniperl.  Code commented out at the
8 # subroutine objaddr can be used instead to work as far back (untested) as
9 # 5.8: needs pack "U".  But almost all occurrences of objaddr have been
10 # removed in favor of using 'no overloading'.  You also would have to go
11 # through and replace occurrences like:
12 #       my $addr = do { no overloading; pack 'J', $self; }
13 # with
14 #       my $addr = main::objaddr $self;
15 # (or reverse commit 9b01bafde4b022706c3d6f947a0963f821b2e50b
16 # that instituted the change to main::objaddr, and subsequent commits that
17 # changed 0+$self to pack 'J', $self.)
18
19 my $start_time;
20 BEGIN { # Get the time the script started running; do it at compilation to
21         # get it as close as possible
22     $start_time= time;
23 }
24
25 require 5.010_001;
26 use strict;
27 use warnings;
28 use Carp;
29 use Config;
30 use File::Find;
31 use File::Path;
32 use File::Spec;
33 use Text::Tabs;
34 use re "/aa";
35
36 sub DEBUG () { 0 }  # Set to 0 for production; 1 for development
37 my $debugging_build = $Config{"ccflags"} =~ /-DDEBUGGING/;
38
39 sub NON_ASCII_PLATFORM { ord("A") != 65 }
40
41 ##########################################################################
42 #
43 # mktables -- create the runtime Perl Unicode files (lib/unicore/.../*.pl),
44 # from the Unicode database files (lib/unicore/.../*.txt),  It also generates
45 # a pod file and .t files, depending on option parameters.
46 #
47 # The structure of this file is:
48 #   First these introductory comments; then
49 #   code needed for everywhere, such as debugging stuff; then
50 #   code to handle input parameters; then
51 #   data structures likely to be of external interest (some of which depend on
52 #       the input parameters, so follows them; then
53 #   more data structures and subroutine and package (class) definitions; then
54 #   the small actual loop to process the input files and finish up; then
55 #   a __DATA__ section, for the .t tests
56 #
57 # This program works on all releases of Unicode so far.  The outputs have been
58 # scrutinized most intently for release 5.1.  The others have been checked for
59 # somewhat more than just sanity.  It can handle all non-provisional Unicode
60 # character properties in those releases.
61 #
62 # This program is mostly about Unicode character (or code point) properties.
63 # A property describes some attribute or quality of a code point, like if it
64 # is lowercase or not, its name, what version of Unicode it was first defined
65 # in, or what its uppercase equivalent is.  Unicode deals with these disparate
66 # possibilities by making all properties into mappings from each code point
67 # into some corresponding value.  In the case of it being lowercase or not,
68 # the mapping is either to 'Y' or 'N' (or various synonyms thereof).  Each
69 # property maps each Unicode code point to a single value, called a "property
70 # value".  (Some more recently defined properties, map a code point to a set
71 # of values.)
72 #
73 # When using a property in a regular expression, what is desired isn't the
74 # mapping of the code point to its property's value, but the reverse (or the
75 # mathematical "inverse relation"): starting with the property value, "Does a
76 # code point map to it?"  These are written in a "compound" form:
77 # \p{property=value}, e.g., \p{category=punctuation}.  This program generates
78 # files containing the lists of code points that map to each such regular
79 # expression property value, one file per list
80 #
81 # There is also a single form shortcut that Perl adds for many of the commonly
82 # used properties.  This happens for all binary properties, plus script,
83 # general_category, and block properties.
84 #
85 # Thus the outputs of this program are files.  There are map files, mostly in
86 # the 'To' directory; and there are list files for use in regular expression
87 # matching, all in subdirectories of the 'lib' directory, with each
88 # subdirectory being named for the property that the lists in it are for.
89 # Bookkeeping, test, and documentation files are also generated.
90
91 my $matches_directory = 'lib';   # Where match (\p{}) files go.
92 my $map_directory = 'To';        # Where map files go.
93
94 # DATA STRUCTURES
95 #
96 # The major data structures of this program are Property, of course, but also
97 # Table.  There are two kinds of tables, very similar to each other.
98 # "Match_Table" is the data structure giving the list of code points that have
99 # a particular property value, mentioned above.  There is also a "Map_Table"
100 # data structure which gives the property's mapping from code point to value.
101 # There are two structures because the match tables need to be combined in
102 # various ways, such as constructing unions, intersections, complements, etc.,
103 # and the map ones don't.  And there would be problems, perhaps subtle, if
104 # a map table were inadvertently operated on in some of those ways.
105 # The use of separate classes with operations defined on one but not the other
106 # prevents accidentally confusing the two.
107 #
108 # At the heart of each table's data structure is a "Range_List", which is just
109 # an ordered list of "Ranges", plus ancillary information, and methods to
110 # operate on them.  A Range is a compact way to store property information.
111 # Each range has a starting code point, an ending code point, and a value that
112 # is meant to apply to all the code points between the two end points,
113 # inclusive.  For a map table, this value is the property value for those
114 # code points.  Two such ranges could be written like this:
115 #   0x41 .. 0x5A, 'Upper',
116 #   0x61 .. 0x7A, 'Lower'
117 #
118 # Each range also has a type used as a convenience to classify the values.
119 # Most ranges in this program will be Type 0, or normal, but there are some
120 # ranges that have a non-zero type.  These are used only in map tables, and
121 # are for mappings that don't fit into the normal scheme of things.  Mappings
122 # that require a hash entry to communicate with utf8.c are one example;
123 # another example is mappings for charnames.pm to use which indicate a name
124 # that is algorithmically determinable from its code point (and the reverse).
125 # These are used to significantly compact these tables, instead of listing
126 # each one of the tens of thousands individually.
127 #
128 # In a match table, the value of a range is irrelevant (and hence the type as
129 # well, which will always be 0), and arbitrarily set to the null string.
130 # Using the example above, there would be two match tables for those two
131 # entries, one named Upper would contain the 0x41..0x5A range, and the other
132 # named Lower would contain 0x61..0x7A.
133 #
134 # Actually, there are two types of range lists, "Range_Map" is the one
135 # associated with map tables, and "Range_List" with match tables.
136 # Again, this is so that methods can be defined on one and not the others so
137 # as to prevent operating on them in incorrect ways.
138 #
139 # Eventually, most tables are written out to files to be read by utf8_heavy.pl
140 # in the perl core.  All tables could in theory be written, but some are
141 # suppressed because there is no current practical use for them.  It is easy
142 # to change which get written by changing various lists that are near the top
143 # of the actual code in this file.  The table data structures contain enough
144 # ancillary information to allow them to be treated as separate entities for
145 # writing, such as the path to each one's file.  There is a heading in each
146 # map table that gives the format of its entries, and what the map is for all
147 # the code points missing from it.  (This allows tables to be more compact.)
148 #
149 # The Property data structure contains one or more tables.  All properties
150 # contain a map table (except the $perl property which is a
151 # pseudo-property containing only match tables), and any properties that
152 # are usable in regular expression matches also contain various matching
153 # tables, one for each value the property can have.  A binary property can
154 # have two values, True and False (or Y and N, which are preferred by Unicode
155 # terminology).  Thus each of these properties will have a map table that
156 # takes every code point and maps it to Y or N (but having ranges cuts the
157 # number of entries in that table way down), and two match tables, one
158 # which has a list of all the code points that map to Y, and one for all the
159 # code points that map to N.  (For each binary property, a third table is also
160 # generated for the pseudo Perl property.  It contains the identical code
161 # points as the Y table, but can be written in regular expressions, not in the
162 # compound form, but in a "single" form like \p{IsUppercase}.)  Many
163 # properties are binary, but some properties have several possible values,
164 # some have many, and properties like Name have a different value for every
165 # named code point.  Those will not, unless the controlling lists are changed,
166 # have their match tables written out.  But all the ones which can be used in
167 # regular expression \p{} and \P{} constructs will.  Prior to 5.14, generally
168 # a property would have either its map table or its match tables written but
169 # not both.  Again, what gets written is controlled by lists which can easily
170 # be changed.  Starting in 5.14, advantage was taken of this, and all the map
171 # tables needed to reconstruct the Unicode db are now written out, while
172 # suppressing the Unicode .txt files that contain the data.  Our tables are
173 # much more compact than the .txt files, so a significant space savings was
174 # achieved.  Also, tables are not written out that are trivially derivable
175 # from tables that do get written.  So, there typically is no file containing
176 # the code points not matched by a binary property (the table for \P{} versus
177 # lowercase \p{}), since you just need to invert the True table to get the
178 # False table.
179
180 # Properties have a 'Type', like 'binary', or 'string', or 'enum' depending on
181 # how many match tables there are and the content of the maps.  This 'Type' is
182 # different than a range 'Type', so don't get confused by the two concepts
183 # having the same name.
184 #
185 # For information about the Unicode properties, see Unicode's UAX44 document:
186
187 my $unicode_reference_url = 'http://www.unicode.org/reports/tr44/';
188
189 # As stated earlier, this program will work on any release of Unicode so far.
190 # Most obvious problems in earlier data have NOT been corrected except when
191 # necessary to make Perl or this program work reasonably, and to keep out
192 # potential security issues.  For example, no folding information was given in
193 # early releases, so this program substitutes lower case instead, just so that
194 # a regular expression with the /i option will do something that actually
195 # gives the right results in many cases.  There are also a couple other
196 # corrections for version 1.1.5, commented at the point they are made.  As an
197 # example of corrections that weren't made (but could be) is this statement
198 # from DerivedAge.txt: "The supplementary private use code points and the
199 # non-character code points were assigned in version 2.0, but not specifically
200 # listed in the UCD until versions 3.0 and 3.1 respectively."  (To be precise
201 # it was 3.0.1 not 3.0.0)  More information on Unicode version glitches is
202 # further down in these introductory comments.
203 #
204 # This program works on all non-provisional properties as of the current
205 # Unicode release, though the files for some are suppressed for various
206 # reasons.  You can change which are output by changing lists in this program.
207 #
208 # The old version of mktables emphasized the term "Fuzzy" to mean Unicode's
209 # loose matchings rules (from Unicode TR18):
210 #
211 #    The recommended names for UCD properties and property values are in
212 #    PropertyAliases.txt [Prop] and PropertyValueAliases.txt
213 #    [PropValue]. There are both abbreviated names and longer, more
214 #    descriptive names. It is strongly recommended that both names be
215 #    recognized, and that loose matching of property names be used,
216 #    whereby the case distinctions, whitespace, hyphens, and underbar
217 #    are ignored.
218 #
219 # The program still allows Fuzzy to override its determination of if loose
220 # matching should be used, but it isn't currently used, as it is no longer
221 # needed; the calculations it makes are good enough.
222 #
223 # SUMMARY OF HOW IT WORKS:
224 #
225 #   Process arguments
226 #
227 #   A list is constructed containing each input file that is to be processed
228 #
229 #   Each file on the list is processed in a loop, using the associated handler
230 #   code for each:
231 #        The PropertyAliases.txt and PropValueAliases.txt files are processed
232 #            first.  These files name the properties and property values.
233 #            Objects are created of all the property and property value names
234 #            that the rest of the input should expect, including all synonyms.
235 #        The other input files give mappings from properties to property
236 #           values.  That is, they list code points and say what the mapping
237 #           is under the given property.  Some files give the mappings for
238 #           just one property; and some for many.  This program goes through
239 #           each file and populates the properties and their map tables from
240 #           them.  Some properties are listed in more than one file, and
241 #           Unicode has set up a precedence as to which has priority if there
242 #           is a conflict.  Thus the order of processing matters, and this
243 #           program handles the conflict possibility by processing the
244 #           overriding input files last, so that if necessary they replace
245 #           earlier values.
246 #        After this is all done, the program creates the property mappings not
247 #            furnished by Unicode, but derivable from what it does give.
248 #        The tables of code points that match each property value in each
249 #            property that is accessible by regular expressions are created.
250 #        The Perl-defined properties are created and populated.  Many of these
251 #            require data determined from the earlier steps
252 #        Any Perl-defined synonyms are created, and name clashes between Perl
253 #            and Unicode are reconciled and warned about.
254 #        All the properties are written to files
255 #        Any other files are written, and final warnings issued.
256 #
257 # For clarity, a number of operators have been overloaded to work on tables:
258 #   ~ means invert (take all characters not in the set).  The more
259 #       conventional '!' is not used because of the possibility of confusing
260 #       it with the actual boolean operation.
261 #   + means union
262 #   - means subtraction
263 #   & means intersection
264 # The precedence of these is the order listed.  Parentheses should be
265 # copiously used.  These are not a general scheme.  The operations aren't
266 # defined for a number of things, deliberately, to avoid getting into trouble.
267 # Operations are done on references and affect the underlying structures, so
268 # that the copy constructors for them have been overloaded to not return a new
269 # clone, but the input object itself.
270 #
271 # The bool operator is deliberately not overloaded to avoid confusion with
272 # "should it mean if the object merely exists, or also is non-empty?".
273 #
274 # WHY CERTAIN DESIGN DECISIONS WERE MADE
275 #
276 # This program needs to be able to run under miniperl.  Therefore, it uses a
277 # minimum of other modules, and hence implements some things itself that could
278 # be gotten from CPAN
279 #
280 # This program uses inputs published by the Unicode Consortium.  These can
281 # change incompatibly between releases without the Perl maintainers realizing
282 # it.  Therefore this program is now designed to try to flag these.  It looks
283 # at the directories where the inputs are, and flags any unrecognized files.
284 # It keeps track of all the properties in the files it handles, and flags any
285 # that it doesn't know how to handle.  It also flags any input lines that
286 # don't match the expected syntax, among other checks.
287 #
288 # It is also designed so if a new input file matches one of the known
289 # templates, one hopefully just needs to add it to a list to have it
290 # processed.
291 #
292 # As mentioned earlier, some properties are given in more than one file.  In
293 # particular, the files in the extracted directory are supposedly just
294 # reformattings of the others.  But they contain information not easily
295 # derivable from the other files, including results for Unihan, which this
296 # program doesn't ordinarily look at, and for unassigned code points.  They
297 # also have historically had errors or been incomplete.  In an attempt to
298 # create the best possible data, this program thus processes them first to
299 # glean information missing from the other files; then processes those other
300 # files to override any errors in the extracted ones.  Much of the design was
301 # driven by this need to store things and then possibly override them.
302 #
303 # It tries to keep fatal errors to a minimum, to generate something usable for
304 # testing purposes.  It always looks for files that could be inputs, and will
305 # warn about any that it doesn't know how to handle (the -q option suppresses
306 # the warning).
307 #
308 # Why is there more than one type of range?
309 #   This simplified things.  There are some very specialized code points that
310 #   have to be handled specially for output, such as Hangul syllable names.
311 #   By creating a range type (done late in the development process), it
312 #   allowed this to be stored with the range, and overridden by other input.
313 #   Originally these were stored in another data structure, and it became a
314 #   mess trying to decide if a second file that was for the same property was
315 #   overriding the earlier one or not.
316 #
317 # Why are there two kinds of tables, match and map?
318 #   (And there is a base class shared by the two as well.)  As stated above,
319 #   they actually are for different things.  Development proceeded much more
320 #   smoothly when I (khw) realized the distinction.  Map tables are used to
321 #   give the property value for every code point (actually every code point
322 #   that doesn't map to a default value).  Match tables are used for regular
323 #   expression matches, and are essentially the inverse mapping.  Separating
324 #   the two allows more specialized methods, and error checks so that one
325 #   can't just take the intersection of two map tables, for example, as that
326 #   is nonsensical.
327 #
328 # What about 'fate' and 'status'.  The concept of a table's fate was created
329 #   late when it became clear that something more was needed.  The difference
330 #   between this and 'status' is unclean, and could be improved if someone
331 #   wanted to spend the effort.
332 #
333 # DEBUGGING
334 #
335 # This program is written so it will run under miniperl.  Occasionally changes
336 # will cause an error where the backtrace doesn't work well under miniperl.
337 # To diagnose the problem, you can instead run it under regular perl, if you
338 # have one compiled.
339 #
340 # There is a good trace facility.  To enable it, first sub DEBUG must be set
341 # to return true.  Then a line like
342 #
343 # local $to_trace = 1 if main::DEBUG;
344 #
345 # can be added to enable tracing in its lexical scope (plus dynamic) or until
346 # you insert another line:
347 #
348 # local $to_trace = 0 if main::DEBUG;
349 #
350 # To actually trace, use a line like "trace $a, @b, %c, ...;
351 #
352 # Some of the more complex subroutines already have trace statements in them.
353 # Permanent trace statements should be like:
354 #
355 # trace ... if main::DEBUG && $to_trace;
356 #
357 # If there is just one or a few files that you're debugging, you can easily
358 # cause most everything else to be skipped.  Change the line
359 #
360 # my $debug_skip = 0;
361 #
362 # to 1, and every file whose object is in @input_file_objects and doesn't have
363 # a, 'non_skip => 1,' in its constructor will be skipped.  However, skipping
364 # Jamo.txt or UnicodeData.txt will likely cause fatal errors.
365 #
366 # To compare the output tables, it may be useful to specify the -annotate
367 # flag.  This causes the tables to expand so there is one entry for each
368 # non-algorithmically named code point giving, currently its name, and its
369 # graphic representation if printable (and you have a font that knows about
370 # it).  This makes it easier to see what the particular code points are in
371 # each output table.  The tables are usable, but because they don't have
372 # ranges (for the most part), a Perl using them will run slower.  Non-named
373 # code points are annotated with a description of their status, and contiguous
374 # ones with the same description will be output as a range rather than
375 # individually.  Algorithmically named characters are also output as ranges,
376 # except when there are just a few contiguous ones.
377 #
378 # FUTURE ISSUES
379 #
380 # The program would break if Unicode were to change its names so that
381 # interior white space, underscores, or dashes differences were significant
382 # within property and property value names.
383 #
384 # It might be easier to use the xml versions of the UCD if this program ever
385 # would need heavy revision, and the ability to handle old versions was not
386 # required.
387 #
388 # There is the potential for name collisions, in that Perl has chosen names
389 # that Unicode could decide it also likes.  There have been such collisions in
390 # the past, with mostly Perl deciding to adopt the Unicode definition of the
391 # name.  However in the 5.2 Unicode beta testing, there were a number of such
392 # collisions, which were withdrawn before the final release, because of Perl's
393 # and other's protests.  These all involved new properties which began with
394 # 'Is'.  Based on the protests, Unicode is unlikely to try that again.  Also,
395 # many of the Perl-defined synonyms, like Any, Word, etc, are listed in a
396 # Unicode document, so they are unlikely to be used by Unicode for another
397 # purpose.  However, they might try something beginning with 'In', or use any
398 # of the other Perl-defined properties.  This program will warn you of name
399 # collisions, and refuse to generate tables with them, but manual intervention
400 # will be required in this event.  One scheme that could be implemented, if
401 # necessary, would be to have this program generate another file, or add a
402 # field to mktables.lst that gives the date of first definition of a property.
403 # Each new release of Unicode would use that file as a basis for the next
404 # iteration.  And the Perl synonym addition code could sort based on the age
405 # of the property, so older properties get priority, and newer ones that clash
406 # would be refused; hence existing code would not be impacted, and some other
407 # synonym would have to be used for the new property.  This is ugly, and
408 # manual intervention would certainly be easier to do in the short run; lets
409 # hope it never comes to this.
410 #
411 # A NOTE ON UNIHAN
412 #
413 # This program can generate tables from the Unihan database.  But it doesn't
414 # by default, letting the CPAN module Unicode::Unihan handle them.  Prior to
415 # version 5.2, this database was in a single file, Unihan.txt.  In 5.2 the
416 # database was split into 8 different files, all beginning with the letters
417 # 'Unihan'.  This program will read those file(s) if present, but it needs to
418 # know which of the many properties in the file(s) should have tables created
419 # for them.  It will create tables for any properties listed in
420 # PropertyAliases.txt and PropValueAliases.txt, plus any listed in the
421 # @cjk_properties array and the @cjk_property_values array.  Thus, if a
422 # property you want is not in those files of the release you are building
423 # against, you must add it to those two arrays.  Starting in 4.0, the
424 # Unicode_Radical_Stroke was listed in those files, so if the Unihan database
425 # is present in the directory, a table will be generated for that property.
426 # In 5.2, several more properties were added.  For your convenience, the two
427 # arrays are initialized with all the 6.0 listed properties that are also in
428 # earlier releases.  But these are commented out.  You can just uncomment the
429 # ones you want, or use them as a template for adding entries for other
430 # properties.
431 #
432 # You may need to adjust the entries to suit your purposes.  setup_unihan(),
433 # and filter_unihan_line() are the functions where this is done.  This program
434 # already does some adjusting to make the lines look more like the rest of the
435 # Unicode DB;  You can see what that is in filter_unihan_line()
436 #
437 # There is a bug in the 3.2 data file in which some values for the
438 # kPrimaryNumeric property have commas and an unexpected comment.  A filter
439 # could be added for these; or for a particular installation, the Unihan.txt
440 # file could be edited to fix them.
441 #
442 # HOW TO ADD A FILE TO BE PROCESSED
443 #
444 # A new file from Unicode needs to have an object constructed for it in
445 # @input_file_objects, probably at the end or at the end of the extracted
446 # ones.  The program should warn you if its name will clash with others on
447 # restrictive file systems, like DOS.  If so, figure out a better name, and
448 # add lines to the README.perl file giving that.  If the file is a character
449 # property, it should be in the format that Unicode has implicitly
450 # standardized for such files for the more recently introduced ones.
451 # If so, the Input_file constructor for @input_file_objects can just be the
452 # file name and release it first appeared in.  If not, then it should be
453 # possible to construct an each_line_handler() to massage the line into the
454 # standardized form.
455 #
456 # For non-character properties, more code will be needed.  You can look at
457 # the existing entries for clues.
458 #
459 # UNICODE VERSIONS NOTES
460 #
461 # The Unicode UCD has had a number of errors in it over the versions.  And
462 # these remain, by policy, in the standard for that version.  Therefore it is
463 # risky to correct them, because code may be expecting the error.  So this
464 # program doesn't generally make changes, unless the error breaks the Perl
465 # core.  As an example, some versions of 2.1.x Jamo.txt have the wrong value
466 # for U+1105, which causes real problems for the algorithms for Jamo
467 # calculations, so it is changed here.
468 #
469 # But it isn't so clear cut as to what to do about concepts that are
470 # introduced in a later release; should they extend back to earlier releases
471 # where the concept just didn't exist?  It was easier to do this than to not,
472 # so that's what was done.  For example, the default value for code points not
473 # in the files for various properties was probably undefined until changed by
474 # some version.  No_Block for blocks is such an example.  This program will
475 # assign No_Block even in Unicode versions that didn't have it.  This has the
476 # benefit that code being written doesn't have to special case earlier
477 # versions; and the detriment that it doesn't match the Standard precisely for
478 # the affected versions.
479 #
480 # Here are some observations about some of the issues in early versions:
481 #
482 # Prior to version 3.0, there were 3 character decompositions.  These are not
483 # handled by Unicode::Normalize, nor will it compile when presented a version
484 # that has them.  However, you can trivially get it to compile by simply
485 # ignoring those decompositions, by changing the croak to a carp.  At the time
486 # of this writing, the line (in cpan/Unicode-Normalize/mkheader) reads
487 #
488 #   croak("Weird Canonical Decomposition of U+$h");
489 #
490 # Simply change to a carp.  It will compile, but will not know about any three
491 # character decomposition.
492
493 # The number of code points in \p{alpha=True} halved in 2.1.9.  It turns out
494 # that the reason is that the CJK block starting at 4E00 was removed from
495 # PropList, and was not put back in until 3.1.0.  The Perl extension (the
496 # single property name \p{alpha}) has the correct values.  But the compound
497 # form is simply not generated until 3.1, as it can be argued that prior to
498 # this release, this was not an official property.  The comments for
499 # filter_old_style_proplist() give more details.
500 #
501 # Unicode introduced the synonym Space for White_Space in 4.1.  Perl has
502 # always had a \p{Space}.  In release 3.2 only, they are not synonymous.  The
503 # reason is that 3.2 introduced U+205F=medium math space, which was not
504 # classed as white space, but Perl figured out that it should have been. 4.0
505 # reclassified it correctly.
506 #
507 # Another change between 3.2 and 4.0 is the CCC property value ATBL.  In 3.2
508 # this was erroneously a synonym for 202 (it should be 200).  In 4.0, ATB
509 # became 202, and ATBL was left with no code points, as all the ones that
510 # mapped to 202 stayed mapped to 202.  Thus if your program used the numeric
511 # name for the class, it would not have been affected, but if it used the
512 # mnemonic, it would have been.
513 #
514 # \p{Script=Hrkt} (Katakana_Or_Hiragana) came in 4.0.1.  Before that code
515 # points which eventually came to have this script property value, instead
516 # mapped to "Unknown".  But in the next release all these code points were
517 # moved to \p{sc=common} instead.
518 #
519 # The default for missing code points for BidiClass is complicated.  Starting
520 # in 3.1.1, the derived file DBidiClass.txt handles this, but this program
521 # tries to do the best it can for earlier releases.  It is done in
522 # process_PropertyAliases()
523 #
524 # In version 2.1.2, the entry in UnicodeData.txt:
525 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;;019F;
526 # should instead be
527 #   0275;LATIN SMALL LETTER BARRED O;Ll;0;L;;;;;N;;;019F;;019F
528 # Without this change, there are casing problems for this character.
529 #
530 ##############################################################################
531
532 my $UNDEF = ':UNDEF:';  # String to print out for undefined values in tracing
533                         # and errors
534 my $MAX_LINE_WIDTH = 78;
535
536 # Debugging aid to skip most files so as to not be distracted by them when
537 # concentrating on the ones being debugged.  Add
538 # non_skip => 1,
539 # to the constructor for those files you want processed when you set this.
540 # Files with a first version number of 0 are special: they are always
541 # processed regardless of the state of this flag.  Generally, Jamo.txt and
542 # UnicodeData.txt must not be skipped if you want this program to not die
543 # before normal completion.
544 my $debug_skip = 0;
545
546
547 # Normally these are suppressed.
548 my $write_Unicode_deprecated_tables = 0;
549
550 # Set to 1 to enable tracing.
551 our $to_trace = 0;
552
553 { # Closure for trace: debugging aid
554     my $print_caller = 1;        # ? Include calling subroutine name
555     my $main_with_colon = 'main::';
556     my $main_colon_length = length($main_with_colon);
557
558     sub trace {
559         return unless $to_trace;        # Do nothing if global flag not set
560
561         my @input = @_;
562
563         local $DB::trace = 0;
564         $DB::trace = 0;          # Quiet 'used only once' message
565
566         my $line_number;
567
568         # Loop looking up the stack to get the first non-trace caller
569         my $caller_line;
570         my $caller_name;
571         my $i = 0;
572         do {
573             $line_number = $caller_line;
574             (my $pkg, my $file, $caller_line, my $caller) = caller $i++;
575             $caller = $main_with_colon unless defined $caller;
576
577             $caller_name = $caller;
578
579             # get rid of pkg
580             $caller_name =~ s/.*:://;
581             if (substr($caller_name, 0, $main_colon_length)
582                 eq $main_with_colon)
583             {
584                 $caller_name = substr($caller_name, $main_colon_length);
585             }
586
587         } until ($caller_name ne 'trace');
588
589         # If the stack was empty, we were called from the top level
590         $caller_name = 'main' if ($caller_name eq ""
591                                     || $caller_name eq 'trace');
592
593         my $output = "";
594         foreach my $string (@input) {
595             #print STDERR __LINE__, ": ", join ", ", @input, "\n";
596             if (ref $string eq 'ARRAY' || ref $string eq 'HASH') {
597                 $output .= simple_dumper($string);
598             }
599             else {
600                 $string = "$string" if ref $string;
601                 $string = $UNDEF unless defined $string;
602                 chomp $string;
603                 $string = '""' if $string eq "";
604                 $output .= " " if $output ne ""
605                                 && $string ne ""
606                                 && substr($output, -1, 1) ne " "
607                                 && substr($string, 0, 1) ne " ";
608                 $output .= $string;
609             }
610         }
611
612         print STDERR sprintf "%4d: ", $line_number if defined $line_number;
613         print STDERR "$caller_name: " if $print_caller;
614         print STDERR $output, "\n";
615         return;
616     }
617 }
618
619 # This is for a rarely used development feature that allows you to compare two
620 # versions of the Unicode standard without having to deal with changes caused
621 # by the code points introduced in the later version.  Change the 0 to a
622 # string containing a SINGLE dotted Unicode release number (e.g. "2.1").  Only
623 # code points introduced in that release and earlier will be used; later ones
624 # are thrown away.  You use the version number of the earliest one you want to
625 # compare; then run this program on directory structures containing each
626 # release, and compare the outputs.  These outputs will therefore include only
627 # the code points common to both releases, and you can see the changes caused
628 # just by the underlying release semantic changes.  For versions earlier than
629 # 3.2, you must copy a version of DAge.txt into the directory.
630 my $string_compare_versions = DEBUG && 0; #  e.g., "2.1";
631 my $compare_versions = DEBUG
632                        && $string_compare_versions
633                        && pack "C*", split /\./, $string_compare_versions;
634
635 sub uniques {
636     # Returns non-duplicated input values.  From "Perl Best Practices:
637     # Encapsulated Cleverness".  p. 455 in first edition.
638
639     my %seen;
640     # Arguably this breaks encapsulation, if the goal is to permit multiple
641     # distinct objects to stringify to the same value, and be interchangeable.
642     # However, for this program, no two objects stringify identically, and all
643     # lists passed to this function are either objects or strings. So this
644     # doesn't affect correctness, but it does give a couple of percent speedup.
645     no overloading;
646     return grep { ! $seen{$_}++ } @_;
647 }
648
649 $0 = File::Spec->canonpath($0);
650
651 my $make_test_script = 0;      # ? Should we output a test script
652 my $make_norm_test_script = 0; # ? Should we output a normalization test script
653 my $write_unchanged_files = 0; # ? Should we update the output files even if
654                                #    we don't think they have changed
655 my $use_directory = "";        # ? Should we chdir somewhere.
656 my $pod_directory;             # input directory to store the pod file.
657 my $pod_file = 'perluniprops';
658 my $t_path;                     # Path to the .t test file
659 my $file_list = 'mktables.lst'; # File to store input and output file names.
660                                # This is used to speed up the build, by not
661                                # executing the main body of the program if
662                                # nothing on the list has changed since the
663                                # previous build
664 my $make_list = 1;             # ? Should we write $file_list.  Set to always
665                                # make a list so that when the pumpking is
666                                # preparing a release, s/he won't have to do
667                                # special things
668 my $glob_list = 0;             # ? Should we try to include unknown .txt files
669                                # in the input.
670 my $output_range_counts = $debugging_build;   # ? Should we include the number
671                                               # of code points in ranges in
672                                               # the output
673 my $annotate = 0;              # ? Should character names be in the output
674
675 # Verbosity levels; 0 is quiet
676 my $NORMAL_VERBOSITY = 1;
677 my $PROGRESS = 2;
678 my $VERBOSE = 3;
679
680 my $verbosity = $NORMAL_VERBOSITY;
681
682 # Process arguments
683 while (@ARGV) {
684     my $arg = shift @ARGV;
685     if ($arg eq '-v') {
686         $verbosity = $VERBOSE;
687     }
688     elsif ($arg eq '-p') {
689         $verbosity = $PROGRESS;
690         $| = 1;     # Flush buffers as we go.
691     }
692     elsif ($arg eq '-q') {
693         $verbosity = 0;
694     }
695     elsif ($arg eq '-w') {
696         $write_unchanged_files = 1; # update the files even if havent changed
697     }
698     elsif ($arg eq '-check') {
699         my $this = shift @ARGV;
700         my $ok = shift @ARGV;
701         if ($this ne $ok) {
702             print "Skipping as check params are not the same.\n";
703             exit(0);
704         }
705     }
706     elsif ($arg eq '-P' && defined ($pod_directory = shift)) {
707         -d $pod_directory or croak "Directory '$pod_directory' doesn't exist";
708     }
709     elsif ($arg eq '-maketest' || ($arg eq '-T' && defined ($t_path = shift)))
710     {
711         $make_test_script = 1;
712     }
713     elsif ($arg eq '-makenormtest')
714     {
715         $make_norm_test_script = 1;
716     }
717     elsif ($arg eq '-makelist') {
718         $make_list = 1;
719     }
720     elsif ($arg eq '-C' && defined ($use_directory = shift)) {
721         -d $use_directory or croak "Unknown directory '$use_directory'";
722     }
723     elsif ($arg eq '-L') {
724
725         # Existence not tested until have chdir'd
726         $file_list = shift;
727     }
728     elsif ($arg eq '-globlist') {
729         $glob_list = 1;
730     }
731     elsif ($arg eq '-c') {
732         $output_range_counts = ! $output_range_counts
733     }
734     elsif ($arg eq '-annotate') {
735         $annotate = 1;
736         $debugging_build = 1;
737         $output_range_counts = 1;
738     }
739     else {
740         my $with_c = 'with';
741         $with_c .= 'out' if $output_range_counts;   # Complements the state
742         croak <<END;
743 usage: $0 [-c|-p|-q|-v|-w] [-C dir] [-L filelist] [ -P pod_dir ]
744           [ -T test_file_path ] [-globlist] [-makelist] [-maketest]
745           [-check A B ]
746   -c          : Output comments $with_c number of code points in ranges
747   -q          : Quiet Mode: Only output serious warnings.
748   -p          : Set verbosity level to normal plus show progress.
749   -v          : Set Verbosity level high:  Show progress and non-serious
750                 warnings
751   -w          : Write files regardless
752   -C dir      : Change to this directory before proceeding. All relative paths
753                 except those specified by the -P and -T options will be done
754                 with respect to this directory.
755   -P dir      : Output $pod_file file to directory 'dir'.
756   -T path     : Create a test script as 'path'; overrides -maketest
757   -L filelist : Use alternate 'filelist' instead of standard one
758   -globlist   : Take as input all non-Test *.txt files in current and sub
759                 directories
760   -maketest   : Make test script 'TestProp.pl' in current (or -C directory),
761                 overrides -T
762   -makelist   : Rewrite the file list $file_list based on current setup
763   -annotate   : Output an annotation for each character in the table files;
764                 useful for debugging mktables, looking at diffs; but is slow,
765                 memory intensive; resulting tables are usable but are slow and
766                 very large (and currently fail the Unicode::UCD.t tests).
767   -check A B  : Executes $0 only if A and B are the same
768 END
769     }
770 }
771
772 # Stores the most-recently changed file.  If none have changed, can skip the
773 # build
774 my $most_recent = (stat $0)[9];   # Do this before the chdir!
775
776 # Change directories now, because need to read 'version' early.
777 if ($use_directory) {
778     if ($pod_directory && ! File::Spec->file_name_is_absolute($pod_directory)) {
779         $pod_directory = File::Spec->rel2abs($pod_directory);
780     }
781     if ($t_path && ! File::Spec->file_name_is_absolute($t_path)) {
782         $t_path = File::Spec->rel2abs($t_path);
783     }
784     chdir $use_directory or croak "Failed to chdir to '$use_directory':$!";
785     if ($pod_directory && File::Spec->file_name_is_absolute($pod_directory)) {
786         $pod_directory = File::Spec->abs2rel($pod_directory);
787     }
788     if ($t_path && File::Spec->file_name_is_absolute($t_path)) {
789         $t_path = File::Spec->abs2rel($t_path);
790     }
791 }
792
793 # Get Unicode version into regular and v-string.  This is done now because
794 # various tables below get populated based on it.  These tables are populated
795 # here to be near the top of the file, and so easily seeable by those needing
796 # to modify things.
797 open my $VERSION, "<", "version"
798                     or croak "$0: can't open required file 'version': $!\n";
799 my $string_version = <$VERSION>;
800 close $VERSION;
801 chomp $string_version;
802 my $v_version = pack "C*", split /\./, $string_version;        # v string
803
804 # The following are the complete names of properties with property values that
805 # are known to not match any code points in some versions of Unicode, but that
806 # may change in the future so they should be matchable, hence an empty file is
807 # generated for them.
808 my @tables_that_may_be_empty = (
809                                 'Joining_Type=Left_Joining',
810                                 );
811 push @tables_that_may_be_empty, 'Script=Common' if $v_version le v4.0.1;
812 push @tables_that_may_be_empty, 'Title' if $v_version lt v2.0.0;
813 push @tables_that_may_be_empty, 'Script=Katakana_Or_Hiragana'
814                                                     if $v_version ge v4.1.0;
815 push @tables_that_may_be_empty, 'Script_Extensions=Katakana_Or_Hiragana'
816                                                     if $v_version ge v6.0.0;
817 push @tables_that_may_be_empty, 'Grapheme_Cluster_Break=Prepend'
818                                                     if $v_version ge v6.1.0;
819 push @tables_that_may_be_empty, 'Canonical_Combining_Class=CCC133'
820                                                     if $v_version ge v6.2.0;
821
822 # The lists below are hashes, so the key is the item in the list, and the
823 # value is the reason why it is in the list.  This makes generation of
824 # documentation easier.
825
826 my %why_suppressed;  # No file generated for these.
827
828 # Files aren't generated for empty extraneous properties.  This is arguable.
829 # Extraneous properties generally come about because a property is no longer
830 # used in a newer version of Unicode.  If we generated a file without code
831 # points, programs that used to work on that property will still execute
832 # without errors.  It just won't ever match (or will always match, with \P{}).
833 # This means that the logic is now likely wrong.  I (khw) think its better to
834 # find this out by getting an error message.  Just move them to the table
835 # above to change this behavior
836 my %why_suppress_if_empty_warn_if_not = (
837
838    # It is the only property that has ever officially been removed from the
839    # Standard.  The database never contained any code points for it.
840    'Special_Case_Condition' => 'Obsolete',
841
842    # Apparently never official, but there were code points in some versions of
843    # old-style PropList.txt
844    'Non_Break' => 'Obsolete',
845 );
846
847 # These would normally go in the warn table just above, but they were changed
848 # a long time before this program was written, so warnings about them are
849 # moot.
850 if ($v_version gt v3.2.0) {
851     push @tables_that_may_be_empty,
852                                 'Canonical_Combining_Class=Attached_Below_Left'
853 }
854
855 # These are listed in the Property aliases file in 6.0, but Unihan is ignored
856 # unless explicitly added.
857 if ($v_version ge v5.2.0) {
858     my $unihan = 'Unihan; remove from list if using Unihan';
859     foreach my $table (qw (
860                            kAccountingNumeric
861                            kOtherNumeric
862                            kPrimaryNumeric
863                            kCompatibilityVariant
864                            kIICore
865                            kIRG_GSource
866                            kIRG_HSource
867                            kIRG_JSource
868                            kIRG_KPSource
869                            kIRG_MSource
870                            kIRG_KSource
871                            kIRG_TSource
872                            kIRG_USource
873                            kIRG_VSource
874                            kRSUnicode
875                         ))
876     {
877         $why_suppress_if_empty_warn_if_not{$table} = $unihan;
878     }
879 }
880
881 # Enum values for to_output_map() method in the Map_Table package.
882 my $EXTERNAL_MAP = 1;
883 my $INTERNAL_MAP = 2;
884 my $OUTPUT_ADJUSTED = 3;
885
886 # To override computed values for writing the map tables for these properties.
887 # The default for enum map tables is to write them out, so that the Unicode
888 # .txt files can be removed, but all the data to compute any property value
889 # for any code point is available in a more compact form.
890 my %global_to_output_map = (
891     # Needed by UCD.pm, but don't want to publicize that it exists, so won't
892     # get stuck supporting it if things change.  Since it is a STRING
893     # property, it normally would be listed in the pod, but INTERNAL_MAP
894     # suppresses that.
895     Unicode_1_Name => $INTERNAL_MAP,
896
897     Present_In => 0,                # Suppress, as easily computed from Age
898     Block => (NON_ASCII_PLATFORM) ? 1 : 0,  # Suppress, as Blocks.txt is
899                                             # retained, but needed for
900                                             # non-ASCII
901
902     # Suppress, as mapping can be found instead from the
903     # Perl_Decomposition_Mapping file
904     Decomposition_Type => 0,
905 );
906
907 # Properties that this program ignores.
908 my @unimplemented_properties;
909
910 # With this release, it is automatically handled if the Unihan db is
911 # downloaded
912 push @unimplemented_properties, 'Unicode_Radical_Stroke' if $v_version le v5.2.0;
913
914 # There are several types of obsolete properties defined by Unicode.  These
915 # must be hand-edited for every new Unicode release.
916 my %why_deprecated;  # Generates a deprecated warning message if used.
917 my %why_stabilized;  # Documentation only
918 my %why_obsolete;    # Documentation only
919
920 {   # Closure
921     my $simple = 'Perl uses the more complete version of this property';
922     my $unihan = 'Unihan properties are by default not enabled in the Perl core.  Instead use CPAN: Unicode::Unihan';
923
924     my $other_properties = 'other properties';
925     my $contributory = "Used by Unicode internally for generating $other_properties and not intended to be used stand-alone";
926     my $why_no_expand  = "Deprecated by Unicode.  These are characters that expand to more than one character in the specified normalization form, but whether they actually take up more bytes or not depends on the encoding being used.  For example, a UTF-8 encoded character may expand to a different number of bytes than a UTF-32 encoded character.";
927
928     %why_deprecated = (
929         'Grapheme_Link' => 'Deprecated by Unicode:  Duplicates ccc=vr (Canonical_Combining_Class=Virama)',
930         'Jamo_Short_Name' => $contributory,
931         'Line_Break=Surrogate' => 'Deprecated by Unicode because surrogates should never appear in well-formed text, and therefore shouldn\'t be the basis for line breaking',
932         'Other_Alphabetic' => $contributory,
933         'Other_Default_Ignorable_Code_Point' => $contributory,
934         'Other_Grapheme_Extend' => $contributory,
935         'Other_ID_Continue' => $contributory,
936         'Other_ID_Start' => $contributory,
937         'Other_Lowercase' => $contributory,
938         'Other_Math' => $contributory,
939         'Other_Uppercase' => $contributory,
940         'Expands_On_NFC' => $why_no_expand,
941         'Expands_On_NFD' => $why_no_expand,
942         'Expands_On_NFKC' => $why_no_expand,
943         'Expands_On_NFKD' => $why_no_expand,
944     );
945
946     %why_suppressed = (
947         # There is a lib/unicore/Decomposition.pl (used by Normalize.pm) which
948         # contains the same information, but without the algorithmically
949         # determinable Hangul syllables'.  This file is not published, so it's
950         # existence is not noted in the comment.
951         'Decomposition_Mapping' => 'Accessible via Unicode::Normalize or Unicode::UCD::prop_invmap()',
952
953         'Indic_Matra_Category' => "Provisional",
954         'Indic_Syllabic_Category' => "Provisional",
955
956         # Don't suppress ISO_Comment, as otherwise special handling is needed
957         # to differentiate between it and gc=c, which can be written as 'isc',
958         # which is the same characters as ISO_Comment's short name.
959
960         'Name' => "Accessible via \\N{...} or 'use charnames;' or Unicode::UCD::prop_invmap()",
961
962         'Simple_Case_Folding' => "$simple.  Can access this through Unicode::UCD::casefold or Unicode::UCD::prop_invmap()",
963         'Simple_Lowercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
964         'Simple_Titlecase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
965         'Simple_Uppercase_Mapping' => "$simple.  Can access this through Unicode::UCD::charinfo or Unicode::UCD::prop_invmap()",
966
967         FC_NFKC_Closure => 'Supplanted in usage by NFKC_Casefold; otherwise not useful',
968     );
969
970     foreach my $property (
971
972             # The following are suppressed because they were made contributory
973             # or deprecated by Unicode before Perl ever thought about
974             # supporting them.
975             'Jamo_Short_Name',
976             'Grapheme_Link',
977             'Expands_On_NFC',
978             'Expands_On_NFD',
979             'Expands_On_NFKC',
980             'Expands_On_NFKD',
981
982             # The following are suppressed because they have been marked
983             # as deprecated for a sufficient amount of time
984             'Other_Alphabetic',
985             'Other_Default_Ignorable_Code_Point',
986             'Other_Grapheme_Extend',
987             'Other_ID_Continue',
988             'Other_ID_Start',
989             'Other_Lowercase',
990             'Other_Math',
991             'Other_Uppercase',
992     ) {
993         $why_suppressed{$property} = $why_deprecated{$property};
994     }
995
996     # Customize the message for all the 'Other_' properties
997     foreach my $property (keys %why_deprecated) {
998         next if (my $main_property = $property) !~ s/^Other_//;
999         $why_deprecated{$property} =~ s/$other_properties/the $main_property property (which should be used instead)/;
1000     }
1001 }
1002
1003 if ($write_Unicode_deprecated_tables) {
1004     foreach my $property (keys %why_suppressed) {
1005         delete $why_suppressed{$property} if $property =~
1006                                                     / ^ Other | Grapheme /x;
1007     }
1008 }
1009
1010 if ($v_version ge 4.0.0) {
1011     $why_stabilized{'Hyphen'} = 'Use the Line_Break property instead; see www.unicode.org/reports/tr14';
1012     if ($v_version ge 6.0.0) {
1013         $why_deprecated{'Hyphen'} = 'Supplanted by Line_Break property values; see www.unicode.org/reports/tr14';
1014     }
1015 }
1016 if ($v_version ge 5.2.0 && $v_version lt 6.0.0) {
1017     $why_obsolete{'ISO_Comment'} = 'Code points for it have been removed';
1018     if ($v_version ge 6.0.0) {
1019         $why_deprecated{'ISO_Comment'} = 'No longer needed for Unicode\'s internal chart generation; otherwise not useful, and code points for it have been removed';
1020     }
1021 }
1022
1023 # Probably obsolete forever
1024 if ($v_version ge v4.1.0) {
1025     $why_suppressed{'Script=Katakana_Or_Hiragana'} = 'Obsolete.  All code points previously matched by this have been moved to "Script=Common".';
1026 }
1027 if ($v_version ge v6.0.0) {
1028     $why_suppressed{'Script=Katakana_Or_Hiragana'} .= '  Consider instead using "Script_Extensions=Katakana" or "Script_Extensions=Hiragana" (or both)';
1029     $why_suppressed{'Script_Extensions=Katakana_Or_Hiragana'} = 'All code points that would be matched by this are matched by either "Script_Extensions=Katakana" or "Script_Extensions=Hiragana"';
1030 }
1031
1032 # This program can create files for enumerated-like properties, such as
1033 # 'Numeric_Type'.  This file would be the same format as for a string
1034 # property, with a mapping from code point to its value, so you could look up,
1035 # for example, the script a code point is in.  But no one so far wants this
1036 # mapping, or they have found another way to get it since this is a new
1037 # feature.  So no file is generated except if it is in this list.
1038 my @output_mapped_properties = split "\n", <<END;
1039 END
1040
1041 # If you are using the Unihan database in a Unicode version before 5.2, you
1042 # need to add the properties that you want to extract from it to this table.
1043 # For your convenience, the properties in the 6.0 PropertyAliases.txt file are
1044 # listed, commented out
1045 my @cjk_properties = split "\n", <<'END';
1046 #cjkAccountingNumeric; kAccountingNumeric
1047 #cjkOtherNumeric; kOtherNumeric
1048 #cjkPrimaryNumeric; kPrimaryNumeric
1049 #cjkCompatibilityVariant; kCompatibilityVariant
1050 #cjkIICore ; kIICore
1051 #cjkIRG_GSource; kIRG_GSource
1052 #cjkIRG_HSource; kIRG_HSource
1053 #cjkIRG_JSource; kIRG_JSource
1054 #cjkIRG_KPSource; kIRG_KPSource
1055 #cjkIRG_KSource; kIRG_KSource
1056 #cjkIRG_TSource; kIRG_TSource
1057 #cjkIRG_USource; kIRG_USource
1058 #cjkIRG_VSource; kIRG_VSource
1059 #cjkRSUnicode; kRSUnicode                ; Unicode_Radical_Stroke; URS
1060 END
1061
1062 # Similarly for the property values.  For your convenience, the lines in the
1063 # 6.0 PropertyAliases.txt file are listed.  Just remove the first BUT NOT both
1064 # '#' marks (for Unicode versions before 5.2)
1065 my @cjk_property_values = split "\n", <<'END';
1066 ## @missing: 0000..10FFFF; cjkAccountingNumeric; NaN
1067 ## @missing: 0000..10FFFF; cjkCompatibilityVariant; <code point>
1068 ## @missing: 0000..10FFFF; cjkIICore; <none>
1069 ## @missing: 0000..10FFFF; cjkIRG_GSource; <none>
1070 ## @missing: 0000..10FFFF; cjkIRG_HSource; <none>
1071 ## @missing: 0000..10FFFF; cjkIRG_JSource; <none>
1072 ## @missing: 0000..10FFFF; cjkIRG_KPSource; <none>
1073 ## @missing: 0000..10FFFF; cjkIRG_KSource; <none>
1074 ## @missing: 0000..10FFFF; cjkIRG_TSource; <none>
1075 ## @missing: 0000..10FFFF; cjkIRG_USource; <none>
1076 ## @missing: 0000..10FFFF; cjkIRG_VSource; <none>
1077 ## @missing: 0000..10FFFF; cjkOtherNumeric; NaN
1078 ## @missing: 0000..10FFFF; cjkPrimaryNumeric; NaN
1079 ## @missing: 0000..10FFFF; cjkRSUnicode; <none>
1080 END
1081
1082 # The input files don't list every code point.  Those not listed are to be
1083 # defaulted to some value.  Below are hard-coded what those values are for
1084 # non-binary properties as of 5.1.  Starting in 5.0, there are
1085 # machine-parsable comment lines in the files that give the defaults; so this
1086 # list shouldn't have to be extended.  The claim is that all missing entries
1087 # for binary properties will default to 'N'.  Unicode tried to change that in
1088 # 5.2, but the beta period produced enough protest that they backed off.
1089 #
1090 # The defaults for the fields that appear in UnicodeData.txt in this hash must
1091 # be in the form that it expects.  The others may be synonyms.
1092 my $CODE_POINT = '<code point>';
1093 my %default_mapping = (
1094     Age => "Unassigned",
1095     # Bidi_Class => Complicated; set in code
1096     Bidi_Mirroring_Glyph => "",
1097     Block => 'No_Block',
1098     Canonical_Combining_Class => 0,
1099     Case_Folding => $CODE_POINT,
1100     Decomposition_Mapping => $CODE_POINT,
1101     Decomposition_Type => 'None',
1102     East_Asian_Width => "Neutral",
1103     FC_NFKC_Closure => $CODE_POINT,
1104     General_Category => 'Cn',
1105     Grapheme_Cluster_Break => 'Other',
1106     Hangul_Syllable_Type => 'NA',
1107     ISO_Comment => "",
1108     Jamo_Short_Name => "",
1109     Joining_Group => "No_Joining_Group",
1110     # Joining_Type => Complicated; set in code
1111     kIICore => 'N',   #                       Is converted to binary
1112     #Line_Break => Complicated; set in code
1113     Lowercase_Mapping => $CODE_POINT,
1114     Name => "",
1115     Name_Alias => "",
1116     NFC_QC => 'Yes',
1117     NFD_QC => 'Yes',
1118     NFKC_QC => 'Yes',
1119     NFKD_QC => 'Yes',
1120     Numeric_Type => 'None',
1121     Numeric_Value => 'NaN',
1122     Script => ($v_version le 4.1.0) ? 'Common' : 'Unknown',
1123     Sentence_Break => 'Other',
1124     Simple_Case_Folding => $CODE_POINT,
1125     Simple_Lowercase_Mapping => $CODE_POINT,
1126     Simple_Titlecase_Mapping => $CODE_POINT,
1127     Simple_Uppercase_Mapping => $CODE_POINT,
1128     Titlecase_Mapping => $CODE_POINT,
1129     Unicode_1_Name => "",
1130     Unicode_Radical_Stroke => "",
1131     Uppercase_Mapping => $CODE_POINT,
1132     Word_Break => 'Other',
1133 );
1134
1135 # Below are files that Unicode furnishes, but this program ignores, and why.
1136 # NormalizationCorrections.txt requires some more explanation.  It documents
1137 # the cumulative fixes to erroneous normalizations in earlier Unicode
1138 # versions.  Its main purpose is so that someone running on an earlier version
1139 # can use this file to override what got published in that earlier release.
1140 # It would be easy for mktables to read and handle this file.  But all the
1141 # corrections in it should already be in the other files for the release it
1142 # is.  To get it to actually mean something useful, someone would have to be
1143 # using an earlier Unicode release, and copy it to the files for that release
1144 # and recomplile.  So far there has been no demand to do that, so this hasn't
1145 # been implemented.
1146 my %ignored_files = (
1147     'CJKRadicals.txt' => 'Maps the kRSUnicode property values to corresponding code points',
1148     'Index.txt' => 'Alphabetical index of Unicode characters',
1149     'NamedSqProv.txt' => 'Named sequences proposed for inclusion in a later version of the Unicode Standard; if you need them now, you can append this file to F<NamedSequences.txt> and recompile perl',
1150     'NamesList.txt' => 'Annotated list of characters',
1151     'NormalizationCorrections.txt' => 'Documentation of corrections already incorporated into the Unicode data base',
1152     'Props.txt' => 'Only in very early releases; is a subset of F<PropList.txt> (which is used instead)',
1153     'ReadMe.txt' => 'Documentation',
1154     'StandardizedVariants.txt' => 'Certain glyph variations for character display are standardized.  This lists the non-Unihan ones; the Unihan ones are also not used by Perl, and are in a separate Unicode data base L<http://www.unicode.org/ivd>',
1155     'EmojiSources.txt' => 'Maps certain Unicode code points to their legacy Japanese cell-phone values',
1156     'USourceData.txt' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1157     'USourceData.pdf' => 'Documentation of status and cross reference of proposals for encoding by Unicode of Unihan characters',
1158     'auxiliary/WordBreakTest.html' => 'Documentation of validation tests',
1159     'auxiliary/SentenceBreakTest.html' => 'Documentation of validation tests',
1160     'auxiliary/GraphemeBreakTest.html' => 'Documentation of validation tests',
1161     'auxiliary/LineBreakTest.html' => 'Documentation of validation tests',
1162 );
1163
1164 my %skipped_files;  # List of files that we skip
1165
1166 ### End of externally interesting definitions, except for @input_file_objects
1167
1168 my $HEADER=<<"EOF";
1169 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
1170 # This file is machine-generated by $0 from the Unicode
1171 # database, Version $string_version.  Any changes made here will be lost!
1172 EOF
1173
1174 my $INTERNAL_ONLY_HEADER = <<"EOF";
1175
1176 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
1177 # This file is for internal use by core Perl only.  The format and even the
1178 # name or existence of this file are subject to change without notice.  Don't
1179 # use it directly.
1180 EOF
1181
1182 my $DEVELOPMENT_ONLY=<<"EOF";
1183 # !!!!!!!   DEVELOPMENT USE ONLY   !!!!!!!
1184 # This file contains information artificially constrained to code points
1185 # present in Unicode release $string_compare_versions.
1186 # IT CANNOT BE RELIED ON.  It is for use during development only and should
1187 # not be used for production.
1188
1189 EOF
1190
1191 my $MAX_UNICODE_CODEPOINT_STRING = "10FFFF";
1192 my $MAX_UNICODE_CODEPOINT = hex $MAX_UNICODE_CODEPOINT_STRING;
1193 my $MAX_UNICODE_CODEPOINTS = $MAX_UNICODE_CODEPOINT + 1;
1194
1195 # Matches legal code point.  4-6 hex numbers, If there are 6, the first
1196 # two must be 10; if there are 5, the first must not be a 0.  Written this way
1197 # to decrease backtracking.  The first regex allows the code point to be at
1198 # the end of a word, but to work properly, the word shouldn't end with a valid
1199 # hex character.  The second one won't match a code point at the end of a
1200 # word, and doesn't have the run-on issue
1201 my $run_on_code_point_re =
1202             qr/ (?: 10[0-9A-F]{4} | [1-9A-F][0-9A-F]{4} | [0-9A-F]{4} ) \b/x;
1203 my $code_point_re = qr/\b$run_on_code_point_re/;
1204
1205 # This matches the beginning of the line in the Unicode db files that give the
1206 # defaults for code points not listed (i.e., missing) in the file.  The code
1207 # depends on this ending with a semi-colon, so it can assume it is a valid
1208 # field when the line is split() by semi-colons
1209 my $missing_defaults_prefix =
1210             qr/^#\s+\@missing:\s+0000\.\.$MAX_UNICODE_CODEPOINT_STRING\s*;/;
1211
1212 # Property types.  Unicode has more types, but these are sufficient for our
1213 # purposes.
1214 my $UNKNOWN = -1;   # initialized to illegal value
1215 my $NON_STRING = 1; # Either binary or enum
1216 my $BINARY = 2;
1217 my $FORCED_BINARY = 3; # Not a binary property, but, besides its normal
1218                        # tables, additional true and false tables are
1219                        # generated so that false is anything matching the
1220                        # default value, and true is everything else.
1221 my $ENUM = 4;       # Include catalog
1222 my $STRING = 5;     # Anything else: string or misc
1223
1224 # Some input files have lines that give default values for code points not
1225 # contained in the file.  Sometimes these should be ignored.
1226 my $NO_DEFAULTS = 0;        # Must evaluate to false
1227 my $NOT_IGNORED = 1;
1228 my $IGNORED = 2;
1229
1230 # Range types.  Each range has a type.  Most ranges are type 0, for normal,
1231 # and will appear in the main body of the tables in the output files, but
1232 # there are other types of ranges as well, listed below, that are specially
1233 # handled.   There are pseudo-types as well that will never be stored as a
1234 # type, but will affect the calculation of the type.
1235
1236 # 0 is for normal, non-specials
1237 my $MULTI_CP = 1;           # Sequence of more than code point
1238 my $HANGUL_SYLLABLE = 2;
1239 my $CP_IN_NAME = 3;         # The NAME contains the code point appended to it.
1240 my $NULL = 4;               # The map is to the null string; utf8.c can't
1241                             # handle these, nor is there an accepted syntax
1242                             # for them in \p{} constructs
1243 my $COMPUTE_NO_MULTI_CP = 5; # Pseudo-type; means that ranges that would
1244                              # otherwise be $MULTI_CP type are instead type 0
1245
1246 # process_generic_property_file() can accept certain overrides in its input.
1247 # Each of these must begin AND end with $CMD_DELIM.
1248 my $CMD_DELIM = "\a";
1249 my $REPLACE_CMD = 'replace';    # Override the Replace
1250 my $MAP_TYPE_CMD = 'map_type';  # Override the Type
1251
1252 my $NO = 0;
1253 my $YES = 1;
1254
1255 # Values for the Replace argument to add_range.
1256 # $NO                      # Don't replace; add only the code points not
1257                            # already present.
1258 my $IF_NOT_EQUIVALENT = 1; # Replace only under certain conditions; details in
1259                            # the comments at the subroutine definition.
1260 my $UNCONDITIONALLY = 2;   # Replace without conditions.
1261 my $MULTIPLE_BEFORE = 4;   # Don't replace, but add a duplicate record if
1262                            # already there
1263 my $MULTIPLE_AFTER = 5;    # Don't replace, but add a duplicate record if
1264                            # already there
1265 my $CROAK = 6;             # Die with an error if is already there
1266
1267 # Flags to give property statuses.  The phrases are to remind maintainers that
1268 # if the flag is changed, the indefinite article referring to it in the
1269 # documentation may need to be as well.
1270 my $NORMAL = "";
1271 my $DEPRECATED = 'D';
1272 my $a_bold_deprecated = "a 'B<$DEPRECATED>'";
1273 my $A_bold_deprecated = "A 'B<$DEPRECATED>'";
1274 my $DISCOURAGED = 'X';
1275 my $a_bold_discouraged = "an 'B<$DISCOURAGED>'";
1276 my $A_bold_discouraged = "An 'B<$DISCOURAGED>'";
1277 my $STRICTER = 'T';
1278 my $a_bold_stricter = "a 'B<$STRICTER>'";
1279 my $A_bold_stricter = "A 'B<$STRICTER>'";
1280 my $STABILIZED = 'S';
1281 my $a_bold_stabilized = "an 'B<$STABILIZED>'";
1282 my $A_bold_stabilized = "An 'B<$STABILIZED>'";
1283 my $OBSOLETE = 'O';
1284 my $a_bold_obsolete = "an 'B<$OBSOLETE>'";
1285 my $A_bold_obsolete = "An 'B<$OBSOLETE>'";
1286
1287 my %status_past_participles = (
1288     $DISCOURAGED => 'discouraged',
1289     $STABILIZED => 'stabilized',
1290     $OBSOLETE => 'obsolete',
1291     $DEPRECATED => 'deprecated',
1292 );
1293
1294 # Table fates.  These are somewhat ordered, so that fates < $MAP_PROXIED should be
1295 # externally documented.
1296 my $ORDINARY = 0;       # The normal fate.
1297 my $MAP_PROXIED = 1;    # The map table for the property isn't written out,
1298                         # but there is a file written that can be used to
1299                         # reconstruct this table
1300 my $INTERNAL_ONLY = 2;  # The file for this table is written out, but it is
1301                         # for Perl's internal use only
1302 my $SUPPRESSED = 3;     # The file for this table is not written out, and as a
1303                         # result, we don't bother to do many computations on
1304                         # it.
1305 my $PLACEHOLDER = 4;    # Like $SUPPRESSED, but we go through all the
1306                         # computations anyway, as the values are needed for
1307                         # things to work.  This happens when we have Perl
1308                         # extensions that depend on Unicode tables that
1309                         # wouldn't normally be in a given Unicode version.
1310
1311 # The format of the values of the tables:
1312 my $EMPTY_FORMAT = "";
1313 my $BINARY_FORMAT = 'b';
1314 my $DECIMAL_FORMAT = 'd';
1315 my $FLOAT_FORMAT = 'f';
1316 my $INTEGER_FORMAT = 'i';
1317 my $HEX_FORMAT = 'x';
1318 my $RATIONAL_FORMAT = 'r';
1319 my $STRING_FORMAT = 's';
1320 my $ADJUST_FORMAT = 'a';
1321 my $DECOMP_STRING_FORMAT = 'c';
1322 my $STRING_WHITE_SPACE_LIST = 'sw';
1323
1324 my %map_table_formats = (
1325     $BINARY_FORMAT => 'binary',
1326     $DECIMAL_FORMAT => 'single decimal digit',
1327     $FLOAT_FORMAT => 'floating point number',
1328     $INTEGER_FORMAT => 'integer',
1329     $HEX_FORMAT => 'non-negative hex whole number; a code point',
1330     $RATIONAL_FORMAT => 'rational: an integer or a fraction',
1331     $STRING_FORMAT => 'string',
1332     $ADJUST_FORMAT => 'some entries need adjustment',
1333     $DECOMP_STRING_FORMAT => 'Perl\'s internal (Normalize.pm) decomposition mapping',
1334     $STRING_WHITE_SPACE_LIST => 'string, but some elements are interpreted as a list; white space occurs only as list item separators'
1335 );
1336
1337 # Unicode didn't put such derived files in a separate directory at first.
1338 my $EXTRACTED_DIR = (-d 'extracted') ? 'extracted' : "";
1339 my $EXTRACTED = ($EXTRACTED_DIR) ? "$EXTRACTED_DIR/" : "";
1340 my $AUXILIARY = 'auxiliary';
1341
1342 # Hashes that will eventually go into Heavy.pl for the use of utf8_heavy.pl
1343 # and into UCD.pl for the use of UCD.pm
1344 my %loose_to_file_of;       # loosely maps table names to their respective
1345                             # files
1346 my %stricter_to_file_of;    # same; but for stricter mapping.
1347 my %loose_property_to_file_of; # Maps a loose property name to its map file
1348 my %file_to_swash_name;     # Maps the file name to its corresponding key name
1349                             # in the hash %utf8::SwashInfo
1350 my %nv_floating_to_rational; # maps numeric values floating point numbers to
1351                              # their rational equivalent
1352 my %loose_property_name_of; # Loosely maps (non_string) property names to
1353                             # standard form
1354 my %string_property_loose_to_name; # Same, for string properties.
1355 my %loose_defaults;         # keys are of form "prop=value", where 'prop' is
1356                             # the property name in standard loose form, and
1357                             # 'value' is the default value for that property,
1358                             # also in standard loose form.
1359 my %loose_to_standard_value; # loosely maps table names to the canonical
1360                             # alias for them
1361 my %ambiguous_names;        # keys are alias names (in standard form) that
1362                             # have more than one possible meaning.
1363 my %prop_aliases;           # Keys are standard property name; values are each
1364                             # one's aliases
1365 my %prop_value_aliases;     # Keys of top level are standard property name;
1366                             # values are keys to another hash,  Each one is
1367                             # one of the property's values, in standard form.
1368                             # The values are that prop-val's aliases.
1369 my %ucd_pod;    # Holds entries that will go into the UCD section of the pod
1370
1371 # Most properties are immune to caseless matching, otherwise you would get
1372 # nonsensical results, as properties are a function of a code point, not
1373 # everything that is caselessly equivalent to that code point.  For example,
1374 # Changes_When_Case_Folded('s') should be false, whereas caselessly it would
1375 # be true because 's' and 'S' are equivalent caselessly.  However,
1376 # traditionally, [:upper:] and [:lower:] are equivalent caselessly, so we
1377 # extend that concept to those very few properties that are like this.  Each
1378 # such property will match the full range caselessly.  They are hard-coded in
1379 # the program; it's not worth trying to make it general as it's extremely
1380 # unlikely that they will ever change.
1381 my %caseless_equivalent_to;
1382
1383 # These constants names and values were taken from the Unicode standard,
1384 # version 5.1, section 3.12.  They are used in conjunction with Hangul
1385 # syllables.  The '_string' versions are so generated tables can retain the
1386 # hex format, which is the more familiar value
1387 my $SBase_string = "0xAC00";
1388 my $SBase = CORE::hex $SBase_string;
1389 my $LBase_string = "0x1100";
1390 my $LBase = CORE::hex $LBase_string;
1391 my $VBase_string = "0x1161";
1392 my $VBase = CORE::hex $VBase_string;
1393 my $TBase_string = "0x11A7";
1394 my $TBase = CORE::hex $TBase_string;
1395 my $SCount = 11172;
1396 my $LCount = 19;
1397 my $VCount = 21;
1398 my $TCount = 28;
1399 my $NCount = $VCount * $TCount;
1400
1401 # For Hangul syllables;  These store the numbers from Jamo.txt in conjunction
1402 # with the above published constants.
1403 my %Jamo;
1404 my %Jamo_L;     # Leading consonants
1405 my %Jamo_V;     # Vowels
1406 my %Jamo_T;     # Trailing consonants
1407
1408 # For code points whose name contains its ordinal as a '-ABCD' suffix.
1409 # The key is the base name of the code point, and the value is an
1410 # array giving all the ranges that use this base name.  Each range
1411 # is actually a hash giving the 'low' and 'high' values of it.
1412 my %names_ending_in_code_point;
1413 my %loose_names_ending_in_code_point;   # Same as above, but has blanks, dashes
1414                                         # removed from the names
1415 # Inverse mapping.  The list of ranges that have these kinds of
1416 # names.  Each element contains the low, high, and base names in an
1417 # anonymous hash.
1418 my @code_points_ending_in_code_point;
1419
1420 # To hold Unicode's normalization test suite
1421 my @normalization_tests;
1422
1423 # Boolean: does this Unicode version have the hangul syllables, and are we
1424 # writing out a table for them?
1425 my $has_hangul_syllables = 0;
1426
1427 # Does this Unicode version have code points whose names end in their
1428 # respective code points, and are we writing out a table for them?  0 for no;
1429 # otherwise points to first property that a table is needed for them, so that
1430 # if multiple tables are needed, we don't create duplicates
1431 my $needing_code_points_ending_in_code_point = 0;
1432
1433 my @backslash_X_tests;     # List of tests read in for testing \X
1434 my @unhandled_properties;  # Will contain a list of properties found in
1435                            # the input that we didn't process.
1436 my @match_properties;      # Properties that have match tables, to be
1437                            # listed in the pod
1438 my @map_properties;        # Properties that get map files written
1439 my @named_sequences;       # NamedSequences.txt contents.
1440 my %potential_files;       # Generated list of all .txt files in the directory
1441                            # structure so we can warn if something is being
1442                            # ignored.
1443 my @files_actually_output; # List of files we generated.
1444 my @more_Names;            # Some code point names are compound; this is used
1445                            # to store the extra components of them.
1446 my $MIN_FRACTION_LENGTH = 3; # How many digits of a floating point number at
1447                            # the minimum before we consider it equivalent to a
1448                            # candidate rational
1449 my $MAX_FLOATING_SLOP = 10 ** - $MIN_FRACTION_LENGTH; # And in floating terms
1450
1451 # These store references to certain commonly used property objects
1452 my $gc;
1453 my $perl;
1454 my $block;
1455 my $perl_charname;
1456 my $print;
1457 my $Any;
1458 my $script;
1459
1460 # Are there conflicting names because of beginning with 'In_', or 'Is_'
1461 my $has_In_conflicts = 0;
1462 my $has_Is_conflicts = 0;
1463
1464 sub internal_file_to_platform ($) {
1465     # Convert our file paths which have '/' separators to those of the
1466     # platform.
1467
1468     my $file = shift;
1469     return undef unless defined $file;
1470
1471     return File::Spec->join(split '/', $file);
1472 }
1473
1474 sub file_exists ($) {   # platform independent '-e'.  This program internally
1475                         # uses slash as a path separator.
1476     my $file = shift;
1477     return 0 if ! defined $file;
1478     return -e internal_file_to_platform($file);
1479 }
1480
1481 sub objaddr($) {
1482     # Returns the address of the blessed input object.
1483     # It doesn't check for blessedness because that would do a string eval
1484     # every call, and the program is structured so that this is never called
1485     # for a non-blessed object.
1486
1487     no overloading; # If overloaded, numifying below won't work.
1488
1489     # Numifying a ref gives its address.
1490     return pack 'J', $_[0];
1491 }
1492
1493 # These are used only if $annotate is true.
1494 # The entire range of Unicode characters is examined to populate these
1495 # after all the input has been processed.  But most can be skipped, as they
1496 # have the same descriptive phrases, such as being unassigned
1497 my @viacode;            # Contains the 1 million character names
1498 my @printable;          # boolean: And are those characters printable?
1499 my @annotate_char_type; # Contains a type of those characters, specifically
1500                         # for the purposes of annotation.
1501 my $annotate_ranges;    # A map of ranges of code points that have the same
1502                         # name for the purposes of annotation.  They map to the
1503                         # upper edge of the range, so that the end point can
1504                         # be immediately found.  This is used to skip ahead to
1505                         # the end of a range, and avoid processing each
1506                         # individual code point in it.
1507 my $unassigned_sans_noncharacters; # A Range_List of the unassigned
1508                                    # characters, but excluding those which are
1509                                    # also noncharacter code points
1510
1511 # The annotation types are an extension of the regular range types, though
1512 # some of the latter are folded into one.  Make the new types negative to
1513 # avoid conflicting with the regular types
1514 my $SURROGATE_TYPE = -1;
1515 my $UNASSIGNED_TYPE = -2;
1516 my $PRIVATE_USE_TYPE = -3;
1517 my $NONCHARACTER_TYPE = -4;
1518 my $CONTROL_TYPE = -5;
1519 my $UNKNOWN_TYPE = -6;  # Used only if there is a bug in this program
1520
1521 sub populate_char_info ($) {
1522     # Used only with the $annotate option.  Populates the arrays with the
1523     # input code point's info that are needed for outputting more detailed
1524     # comments.  If calling context wants a return, it is the end point of
1525     # any contiguous range of characters that share essentially the same info
1526
1527     my $i = shift;
1528     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1529
1530     $viacode[$i] = $perl_charname->value_of($i) || "";
1531
1532     # A character is generally printable if Unicode says it is,
1533     # but below we make sure that most Unicode general category 'C' types
1534     # aren't.
1535     $printable[$i] = $print->contains($i);
1536
1537     $annotate_char_type[$i] = $perl_charname->type_of($i) || 0;
1538
1539     # Only these two regular types are treated specially for annotations
1540     # purposes
1541     $annotate_char_type[$i] = 0 if $annotate_char_type[$i] != $CP_IN_NAME
1542                                 && $annotate_char_type[$i] != $HANGUL_SYLLABLE;
1543
1544     # Give a generic name to all code points that don't have a real name.
1545     # We output ranges, if applicable, for these.  Also calculate the end
1546     # point of the range.
1547     my $end;
1548     if (! $viacode[$i]) {
1549         my $nonchar;
1550         if ($gc-> table('Private_use')->contains($i)) {
1551             $viacode[$i] = 'Private Use';
1552             $annotate_char_type[$i] = $PRIVATE_USE_TYPE;
1553             $printable[$i] = 0;
1554             $end = $gc->table('Private_Use')->containing_range($i)->end;
1555         }
1556         elsif ((defined ($nonchar =
1557                             Property::property_ref('Noncharacter_Code_Point'))
1558                && $nonchar->table('Y')->contains($i)))
1559         {
1560             $viacode[$i] = 'Noncharacter';
1561             $annotate_char_type[$i] = $NONCHARACTER_TYPE;
1562             $printable[$i] = 0;
1563             $end = property_ref('Noncharacter_Code_Point')->table('Y')->
1564                                                     containing_range($i)->end;
1565         }
1566         elsif ($gc-> table('Control')->contains($i)) {
1567             $viacode[$i] = property_ref('Name_Alias')->value_of($i) || 'Control';
1568             $annotate_char_type[$i] = $CONTROL_TYPE;
1569             $printable[$i] = 0;
1570         }
1571         elsif ($gc-> table('Unassigned')->contains($i)) {
1572             $annotate_char_type[$i] = $UNASSIGNED_TYPE;
1573             $printable[$i] = 0;
1574             if ($v_version lt v2.0.0) { # No blocks in earliest releases
1575                 $viacode[$i] = 'Unassigned';
1576                 $end = $gc-> table('Unassigned')->containing_range($i)->end;
1577             }
1578             else {
1579                 $viacode[$i] = 'Unassigned, block=' . $block-> value_of($i);
1580
1581                 # Because we name the unassigned by the blocks they are in, it
1582                 # can't go past the end of that block, and it also can't go
1583                 # past the unassigned range it is in.  The special table makes
1584                 # sure that the non-characters, which are unassigned, are
1585                 # separated out.
1586                 $end = min($block->containing_range($i)->end,
1587                            $unassigned_sans_noncharacters->
1588                                                     containing_range($i)->end);
1589             }
1590         }
1591         elsif ($v_version lt v2.0.0) {  # No surrogates in earliest releases
1592             $viacode[$i] = $gc->value_of($i);
1593             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1594             $printable[$i] = 0;
1595         }
1596         elsif ($gc-> table('Surrogate')->contains($i)) {
1597             $viacode[$i] = 'Surrogate';
1598             $annotate_char_type[$i] = $SURROGATE_TYPE;
1599             $printable[$i] = 0;
1600             $end = $gc->table('Surrogate')->containing_range($i)->end;
1601         }
1602         else {
1603             Carp::my_carp_bug("Can't figure out how to annotate "
1604                               . sprintf("U+%04X", $i)
1605                               . ".  Proceeding anyway.");
1606             $viacode[$i] = 'UNKNOWN';
1607             $annotate_char_type[$i] = $UNKNOWN_TYPE;
1608             $printable[$i] = 0;
1609         }
1610     }
1611
1612     # Here, has a name, but if it's one in which the code point number is
1613     # appended to the name, do that.
1614     elsif ($annotate_char_type[$i] == $CP_IN_NAME) {
1615         $viacode[$i] .= sprintf("-%04X", $i);
1616         $end = $perl_charname->containing_range($i)->end;
1617     }
1618
1619     # And here, has a name, but if it's a hangul syllable one, replace it with
1620     # the correct name from the Unicode algorithm
1621     elsif ($annotate_char_type[$i] == $HANGUL_SYLLABLE) {
1622         use integer;
1623         my $SIndex = $i - $SBase;
1624         my $L = $LBase + $SIndex / $NCount;
1625         my $V = $VBase + ($SIndex % $NCount) / $TCount;
1626         my $T = $TBase + $SIndex % $TCount;
1627         $viacode[$i] = "HANGUL SYLLABLE $Jamo{$L}$Jamo{$V}";
1628         $viacode[$i] .= $Jamo{$T} if $T != $TBase;
1629         $end = $perl_charname->containing_range($i)->end;
1630     }
1631
1632     return if ! defined wantarray;
1633     return $i if ! defined $end;    # If not a range, return the input
1634
1635     # Save this whole range so can find the end point quickly
1636     $annotate_ranges->add_map($i, $end, $end);
1637
1638     return $end;
1639 }
1640
1641 # Commented code below should work on Perl 5.8.
1642 ## This 'require' doesn't necessarily work in miniperl, and even if it does,
1643 ## the native perl version of it (which is what would operate under miniperl)
1644 ## is extremely slow, as it does a string eval every call.
1645 #my $has_fast_scalar_util = $^X !~ /miniperl/
1646 #                            && defined eval "require Scalar::Util";
1647 #
1648 #sub objaddr($) {
1649 #    # Returns the address of the blessed input object.  Uses the XS version if
1650 #    # available.  It doesn't check for blessedness because that would do a
1651 #    # string eval every call, and the program is structured so that this is
1652 #    # never called for a non-blessed object.
1653 #
1654 #    return Scalar::Util::refaddr($_[0]) if $has_fast_scalar_util;
1655 #
1656 #    # Check at least that is a ref.
1657 #    my $pkg = ref($_[0]) or return undef;
1658 #
1659 #    # Change to a fake package to defeat any overloaded stringify
1660 #    bless $_[0], 'main::Fake';
1661 #
1662 #    # Numifying a ref gives its address.
1663 #    my $addr = pack 'J', $_[0];
1664 #
1665 #    # Return to original class
1666 #    bless $_[0], $pkg;
1667 #    return $addr;
1668 #}
1669
1670 sub max ($$) {
1671     my $a = shift;
1672     my $b = shift;
1673     return $a if $a >= $b;
1674     return $b;
1675 }
1676
1677 sub min ($$) {
1678     my $a = shift;
1679     my $b = shift;
1680     return $a if $a <= $b;
1681     return $b;
1682 }
1683
1684 sub clarify_number ($) {
1685     # This returns the input number with underscores inserted every 3 digits
1686     # in large (5 digits or more) numbers.  Input must be entirely digits, not
1687     # checked.
1688
1689     my $number = shift;
1690     my $pos = length($number) - 3;
1691     return $number if $pos <= 1;
1692     while ($pos > 0) {
1693         substr($number, $pos, 0) = '_';
1694         $pos -= 3;
1695     }
1696     return $number;
1697 }
1698
1699
1700 package Carp;
1701
1702 # These routines give a uniform treatment of messages in this program.  They
1703 # are placed in the Carp package to cause the stack trace to not include them,
1704 # although an alternative would be to use another package and set @CARP_NOT
1705 # for it.
1706
1707 our $Verbose = 1 if main::DEBUG;  # Useful info when debugging
1708
1709 # This is a work-around suggested by Nicholas Clark to fix a problem with Carp
1710 # and overload trying to load Scalar:Util under miniperl.  See
1711 # http://www.xray.mpe.mpg.de/mailing-lists/perl5-porters/2009-11/msg01057.html
1712 undef $overload::VERSION;
1713
1714 sub my_carp {
1715     my $message = shift || "";
1716     my $nofold = shift || 0;
1717
1718     if ($message) {
1719         $message = main::join_lines($message);
1720         $message =~ s/^$0: *//;     # Remove initial program name
1721         $message =~ s/[.;,]+$//;    # Remove certain ending punctuation
1722         $message = "\n$0: $message;";
1723
1724         # Fold the message with program name, semi-colon end punctuation
1725         # (which looks good with the message that carp appends to it), and a
1726         # hanging indent for continuation lines.
1727         $message = main::simple_fold($message, "", 4) unless $nofold;
1728         $message =~ s/\n$//;        # Remove the trailing nl so what carp
1729                                     # appends is to the same line
1730     }
1731
1732     return $message if defined wantarray;   # If a caller just wants the msg
1733
1734     carp $message;
1735     return;
1736 }
1737
1738 sub my_carp_bug {
1739     # This is called when it is clear that the problem is caused by a bug in
1740     # this program.
1741
1742     my $message = shift;
1743     $message =~ s/^$0: *//;
1744     $message = my_carp("Bug in $0.  Please report it by running perlbug or if that is unavailable, by sending email to perbug\@perl.org:\n$message");
1745     carp $message;
1746     return;
1747 }
1748
1749 sub carp_too_few_args {
1750     if (@_ != 2) {
1751         my_carp_bug("Wrong number of arguments: to 'carp_too_few_arguments'.  No action taken.");
1752         return;
1753     }
1754
1755     my $args_ref = shift;
1756     my $count = shift;
1757
1758     my_carp_bug("Need at least $count arguments to "
1759         . (caller 1)[3]
1760         . ".  Instead got: '"
1761         . join ', ', @$args_ref
1762         . "'.  No action taken.");
1763     return;
1764 }
1765
1766 sub carp_extra_args {
1767     my $args_ref = shift;
1768     my_carp_bug("Too many arguments to 'carp_extra_args': (" . join(', ', @_) . ");  Extras ignored.") if @_;
1769
1770     unless (ref $args_ref) {
1771         my_carp_bug("Argument to 'carp_extra_args' ($args_ref) must be a ref.  Not checking arguments.");
1772         return;
1773     }
1774     my ($package, $file, $line) = caller;
1775     my $subroutine = (caller 1)[3];
1776
1777     my $list;
1778     if (ref $args_ref eq 'HASH') {
1779         foreach my $key (keys %$args_ref) {
1780             $args_ref->{$key} = $UNDEF unless defined $args_ref->{$key};
1781         }
1782         $list = join ', ', each %{$args_ref};
1783     }
1784     elsif (ref $args_ref eq 'ARRAY') {
1785         foreach my $arg (@$args_ref) {
1786             $arg = $UNDEF unless defined $arg;
1787         }
1788         $list = join ', ', @$args_ref;
1789     }
1790     else {
1791         my_carp_bug("Can't cope with ref "
1792                 . ref($args_ref)
1793                 . " . argument to 'carp_extra_args'.  Not checking arguments.");
1794         return;
1795     }
1796
1797     my_carp_bug("Unrecognized parameters in options: '$list' to $subroutine.  Skipped.");
1798     return;
1799 }
1800
1801 package main;
1802
1803 { # Closure
1804
1805     # This program uses the inside-out method for objects, as recommended in
1806     # "Perl Best Practices".  This closure aids in generating those.  There
1807     # are two routines.  setup_package() is called once per package to set
1808     # things up, and then set_access() is called for each hash representing a
1809     # field in the object.  These routines arrange for the object to be
1810     # properly destroyed when no longer used, and for standard accessor
1811     # functions to be generated.  If you need more complex accessors, just
1812     # write your own and leave those accesses out of the call to set_access().
1813     # More details below.
1814
1815     my %constructor_fields; # fields that are to be used in constructors; see
1816                             # below
1817
1818     # The values of this hash will be the package names as keys to other
1819     # hashes containing the name of each field in the package as keys, and
1820     # references to their respective hashes as values.
1821     my %package_fields;
1822
1823     sub setup_package {
1824         # Sets up the package, creating standard DESTROY and dump methods
1825         # (unless already defined).  The dump method is used in debugging by
1826         # simple_dumper().
1827         # The optional parameters are:
1828         #   a)  a reference to a hash, that gets populated by later
1829         #       set_access() calls with one of the accesses being
1830         #       'constructor'.  The caller can then refer to this, but it is
1831         #       not otherwise used by these two routines.
1832         #   b)  a reference to a callback routine to call during destruction
1833         #       of the object, before any fields are actually destroyed
1834
1835         my %args = @_;
1836         my $constructor_ref = delete $args{'Constructor_Fields'};
1837         my $destroy_callback = delete $args{'Destroy_Callback'};
1838         Carp::carp_extra_args(\@_) if main::DEBUG && %args;
1839
1840         my %fields;
1841         my $package = (caller)[0];
1842
1843         $package_fields{$package} = \%fields;
1844         $constructor_fields{$package} = $constructor_ref;
1845
1846         unless ($package->can('DESTROY')) {
1847             my $destroy_name = "${package}::DESTROY";
1848             no strict "refs";
1849
1850             # Use typeglob to give the anonymous subroutine the name we want
1851             *$destroy_name = sub {
1852                 my $self = shift;
1853                 my $addr = do { no overloading; pack 'J', $self; };
1854
1855                 $self->$destroy_callback if $destroy_callback;
1856                 foreach my $field (keys %{$package_fields{$package}}) {
1857                     #print STDERR __LINE__, ": Destroying ", ref $self, " ", sprintf("%04X", $addr), ": ", $field, "\n";
1858                     delete $package_fields{$package}{$field}{$addr};
1859                 }
1860                 return;
1861             }
1862         }
1863
1864         unless ($package->can('dump')) {
1865             my $dump_name = "${package}::dump";
1866             no strict "refs";
1867             *$dump_name = sub {
1868                 my $self = shift;
1869                 return dump_inside_out($self, $package_fields{$package}, @_);
1870             }
1871         }
1872         return;
1873     }
1874
1875     sub set_access {
1876         # Arrange for the input field to be garbage collected when no longer
1877         # needed.  Also, creates standard accessor functions for the field
1878         # based on the optional parameters-- none if none of these parameters:
1879         #   'addable'    creates an 'add_NAME()' accessor function.
1880         #   'readable' or 'readable_array'   creates a 'NAME()' accessor
1881         #                function.
1882         #   'settable'   creates a 'set_NAME()' accessor function.
1883         #   'constructor' doesn't create an accessor function, but adds the
1884         #                field to the hash that was previously passed to
1885         #                setup_package();
1886         # Any of the accesses can be abbreviated down, so that 'a', 'ad',
1887         # 'add' etc. all mean 'addable'.
1888         # The read accessor function will work on both array and scalar
1889         # values.  If another accessor in the parameter list is 'a', the read
1890         # access assumes an array.  You can also force it to be array access
1891         # by specifying 'readable_array' instead of 'readable'
1892         #
1893         # A sort-of 'protected' access can be set-up by preceding the addable,
1894         # readable or settable with some initial portion of 'protected_' (but,
1895         # the underscore is required), like 'p_a', 'pro_set', etc.  The
1896         # "protection" is only by convention.  All that happens is that the
1897         # accessor functions' names begin with an underscore.  So instead of
1898         # calling set_foo, the call is _set_foo.  (Real protection could be
1899         # accomplished by having a new subroutine, end_package, called at the
1900         # end of each package, and then storing the __LINE__ ranges and
1901         # checking them on every accessor.  But that is way overkill.)
1902
1903         # We create anonymous subroutines as the accessors and then use
1904         # typeglobs to assign them to the proper package and name
1905
1906         my $name = shift;   # Name of the field
1907         my $field = shift;  # Reference to the inside-out hash containing the
1908                             # field
1909
1910         my $package = (caller)[0];
1911
1912         if (! exists $package_fields{$package}) {
1913             croak "$0: Must call 'setup_package' before 'set_access'";
1914         }
1915
1916         # Stash the field so DESTROY can get it.
1917         $package_fields{$package}{$name} = $field;
1918
1919         # Remaining arguments are the accessors.  For each...
1920         foreach my $access (@_) {
1921             my $access = lc $access;
1922
1923             my $protected = "";
1924
1925             # Match the input as far as it goes.
1926             if ($access =~ /^(p[^_]*)_/) {
1927                 $protected = $1;
1928                 if (substr('protected_', 0, length $protected)
1929                     eq $protected)
1930                 {
1931
1932                     # Add 1 for the underscore not included in $protected
1933                     $access = substr($access, length($protected) + 1);
1934                     $protected = '_';
1935                 }
1936                 else {
1937                     $protected = "";
1938                 }
1939             }
1940
1941             if (substr('addable', 0, length $access) eq $access) {
1942                 my $subname = "${package}::${protected}add_$name";
1943                 no strict "refs";
1944
1945                 # add_ accessor.  Don't add if already there, which we
1946                 # determine using 'eq' for scalars and '==' otherwise.
1947                 *$subname = sub {
1948                     use strict "refs";
1949                     return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
1950                     my $self = shift;
1951                     my $value = shift;
1952                     my $addr = do { no overloading; pack 'J', $self; };
1953                     Carp::carp_extra_args(\@_) if main::DEBUG && @_;
1954                     if (ref $value) {
1955                         return if grep { $value == $_ } @{$field->{$addr}};
1956                     }
1957                     else {
1958                         return if grep { $value eq $_ } @{$field->{$addr}};
1959                     }
1960                     push @{$field->{$addr}}, $value;
1961                     return;
1962                 }
1963             }
1964             elsif (substr('constructor', 0, length $access) eq $access) {
1965                 if ($protected) {
1966                     Carp::my_carp_bug("Can't set-up 'protected' constructors")
1967                 }
1968                 else {
1969                     $constructor_fields{$package}{$name} = $field;
1970                 }
1971             }
1972             elsif (substr('readable_array', 0, length $access) eq $access) {
1973
1974                 # Here has read access.  If one of the other parameters for
1975                 # access is array, or this one specifies array (by being more
1976                 # than just 'readable_'), then create a subroutine that
1977                 # assumes the data is an array.  Otherwise just a scalar
1978                 my $subname = "${package}::${protected}$name";
1979                 if (grep { /^a/i } @_
1980                     or length($access) > length('readable_'))
1981                 {
1982                     no strict "refs";
1983                     *$subname = sub {
1984                         use strict "refs";
1985                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
1986                         my $addr = do { no overloading; pack 'J', $_[0]; };
1987                         if (ref $field->{$addr} ne 'ARRAY') {
1988                             my $type = ref $field->{$addr};
1989                             $type = 'scalar' unless $type;
1990                             Carp::my_carp_bug("Trying to read $name as an array when it is a $type.  Big problems.");
1991                             return;
1992                         }
1993                         return scalar @{$field->{$addr}} unless wantarray;
1994
1995                         # Make a copy; had problems with caller modifying the
1996                         # original otherwise
1997                         my @return = @{$field->{$addr}};
1998                         return @return;
1999                     }
2000                 }
2001                 else {
2002
2003                     # Here not an array value, a simpler function.
2004                     no strict "refs";
2005                     *$subname = sub {
2006                         use strict "refs";
2007                         Carp::carp_extra_args(\@_) if main::DEBUG && @_ > 1;
2008                         no overloading;
2009                         return $field->{pack 'J', $_[0]};
2010                     }
2011                 }
2012             }
2013             elsif (substr('settable', 0, length $access) eq $access) {
2014                 my $subname = "${package}::${protected}set_$name";
2015                 no strict "refs";
2016                 *$subname = sub {
2017                     use strict "refs";
2018                     if (main::DEBUG) {
2019                         return Carp::carp_too_few_args(\@_, 2) if @_ < 2;
2020                         Carp::carp_extra_args(\@_) if @_ > 2;
2021                     }
2022                     # $self is $_[0]; $value is $_[1]
2023                     no overloading;
2024                     $field->{pack 'J', $_[0]} = $_[1];
2025                     return;
2026                 }
2027             }
2028             else {
2029                 Carp::my_carp_bug("Unknown accessor type $access.  No accessor set.");
2030             }
2031         }
2032         return;
2033     }
2034 }
2035
2036 package Input_file;
2037
2038 # All input files use this object, which stores various attributes about them,
2039 # and provides for convenient, uniform handling.  The run method wraps the
2040 # processing.  It handles all the bookkeeping of opening, reading, and closing
2041 # the file, returning only significant input lines.
2042 #
2043 # Each object gets a handler which processes the body of the file, and is
2044 # called by run().  All character property files must use the generic,
2045 # default handler, which has code scrubbed to handle things you might not
2046 # expect, including automatic EBCDIC handling.  For files that don't deal with
2047 # mapping code points to a property value, such as test files,
2048 # PropertyAliases, PropValueAliases, and named sequences, you can override the
2049 # handler to be a custom one.  Such a handler should basically be a
2050 # while(next_line()) {...} loop.
2051 #
2052 # You can also set up handlers to
2053 #   1) call before the first line is read, for pre processing
2054 #   2) call to adjust each line of the input before the main handler gets them
2055 #   3) call upon EOF before the main handler exits its loop
2056 #   4) call at the end, for post processing
2057 #
2058 # $_ is used to store the input line, and is to be filtered by the
2059 # each_line_handler()s.  So, if the format of the line is not in the desired
2060 # format for the main handler, these are used to do that adjusting.  They can
2061 # be stacked (by enclosing them in an [ anonymous array ] in the constructor,
2062 # so the $_ output of one is used as the input to the next.  None of the other
2063 # handlers are stackable, but could easily be changed to be so.
2064 #
2065 # Most of the handlers can call insert_lines() or insert_adjusted_lines()
2066 # which insert the parameters as lines to be processed before the next input
2067 # file line is read.  This allows the EOF handler to flush buffers, for
2068 # example.  The difference between the two routines is that the lines inserted
2069 # by insert_lines() are subjected to the each_line_handler()s.  (So if you
2070 # called it from such a handler, you would get infinite recursion.)  Lines
2071 # inserted by insert_adjusted_lines() go directly to the main handler without
2072 # any adjustments.  If the  post-processing handler calls any of these, there
2073 # will be no effect.  Some error checking for these conditions could be added,
2074 # but it hasn't been done.
2075 #
2076 # carp_bad_line() should be called to warn of bad input lines, which clears $_
2077 # to prevent further processing of the line.  This routine will output the
2078 # message as a warning once, and then keep a count of the lines that have the
2079 # same message, and output that count at the end of the file's processing.
2080 # This keeps the number of messages down to a manageable amount.
2081 #
2082 # get_missings() should be called to retrieve any @missing input lines.
2083 # Messages will be raised if this isn't done if the options aren't to ignore
2084 # missings.
2085
2086 sub trace { return main::trace(@_); }
2087
2088 { # Closure
2089     # Keep track of fields that are to be put into the constructor.
2090     my %constructor_fields;
2091
2092     main::setup_package(Constructor_Fields => \%constructor_fields);
2093
2094     my %file; # Input file name, required
2095     main::set_access('file', \%file, qw{ c r });
2096
2097     my %first_released; # Unicode version file was first released in, required
2098     main::set_access('first_released', \%first_released, qw{ c r });
2099
2100     my %handler;    # Subroutine to process the input file, defaults to
2101                     # 'process_generic_property_file'
2102     main::set_access('handler', \%handler, qw{ c });
2103
2104     my %property;
2105     # name of property this file is for.  defaults to none, meaning not
2106     # applicable, or is otherwise determinable, for example, from each line.
2107     main::set_access('property', \%property, qw{ c r });
2108
2109     my %optional;
2110     # If this is true, the file is optional.  If not present, no warning is
2111     # output.  If it is present, the string given by this parameter is
2112     # evaluated, and if false the file is not processed.
2113     main::set_access('optional', \%optional, 'c', 'r');
2114
2115     my %non_skip;
2116     # This is used for debugging, to skip processing of all but a few input
2117     # files.  Add 'non_skip => 1' to the constructor for those files you want
2118     # processed when you set the $debug_skip global.
2119     main::set_access('non_skip', \%non_skip, 'c');
2120
2121     my %skip;
2122     # This is used to skip processing of this input file semi-permanently,
2123     # when it evaluates to true.  The value should be the reason the file is
2124     # being skipped.  It is used for files that we aren't planning to process
2125     # anytime soon, but want to allow to be in the directory and not raise a
2126     # message that we are not handling.  Mostly for test files.  This is in
2127     # contrast to the non_skip element, which is supposed to be used very
2128     # temporarily for debugging.  Sets 'optional' to 1.  Also, files that we
2129     # pretty much will never look at can be placed in the global
2130     # %ignored_files instead.  Ones used here will be added to %skipped files
2131     main::set_access('skip', \%skip, 'c');
2132
2133     my %each_line_handler;
2134     # list of subroutines to look at and filter each non-comment line in the
2135     # file.  defaults to none.  The subroutines are called in order, each is
2136     # to adjust $_ for the next one, and the final one adjusts it for
2137     # 'handler'
2138     main::set_access('each_line_handler', \%each_line_handler, 'c');
2139
2140     my %has_missings_defaults;
2141     # ? Are there lines in the file giving default values for code points
2142     # missing from it?.  Defaults to NO_DEFAULTS.  Otherwise NOT_IGNORED is
2143     # the norm, but IGNORED means it has such lines, but the handler doesn't
2144     # use them.  Having these three states allows us to catch changes to the
2145     # UCD that this program should track
2146     main::set_access('has_missings_defaults',
2147                                         \%has_missings_defaults, qw{ c r });
2148
2149     my %pre_handler;
2150     # Subroutine to call before doing anything else in the file.  If undef, no
2151     # such handler is called.
2152     main::set_access('pre_handler', \%pre_handler, qw{ c });
2153
2154     my %eof_handler;
2155     # Subroutine to call upon getting an EOF on the input file, but before
2156     # that is returned to the main handler.  This is to allow buffers to be
2157     # flushed.  The handler is expected to call insert_lines() or
2158     # insert_adjusted() with the buffered material
2159     main::set_access('eof_handler', \%eof_handler, qw{ c r });
2160
2161     my %post_handler;
2162     # Subroutine to call after all the lines of the file are read in and
2163     # processed.  If undef, no such handler is called.
2164     main::set_access('post_handler', \%post_handler, qw{ c });
2165
2166     my %progress_message;
2167     # Message to print to display progress in lieu of the standard one
2168     main::set_access('progress_message', \%progress_message, qw{ c });
2169
2170     my %handle;
2171     # cache open file handle, internal.  Is undef if file hasn't been
2172     # processed at all, empty if has;
2173     main::set_access('handle', \%handle);
2174
2175     my %added_lines;
2176     # cache of lines added virtually to the file, internal
2177     main::set_access('added_lines', \%added_lines);
2178
2179     my %remapped_lines;
2180     # cache of lines added virtually to the file, internal
2181     main::set_access('remapped_lines', \%remapped_lines);
2182
2183     my %errors;
2184     # cache of errors found, internal
2185     main::set_access('errors', \%errors);
2186
2187     my %missings;
2188     # storage of '@missing' defaults lines
2189     main::set_access('missings', \%missings);
2190
2191     sub _next_line;
2192     sub _next_line_with_remapped_range;
2193
2194     sub new {
2195         my $class = shift;
2196
2197         my $self = bless \do{ my $anonymous_scalar }, $class;
2198         my $addr = do { no overloading; pack 'J', $self; };
2199
2200         # Set defaults
2201         $handler{$addr} = \&main::process_generic_property_file;
2202         $non_skip{$addr} = 0;
2203         $skip{$addr} = 0;
2204         $has_missings_defaults{$addr} = $NO_DEFAULTS;
2205         $handle{$addr} = undef;
2206         $added_lines{$addr} = [ ];
2207         $remapped_lines{$addr} = [ ];
2208         $each_line_handler{$addr} = [ ];
2209         $errors{$addr} = { };
2210         $missings{$addr} = [ ];
2211
2212         # Two positional parameters.
2213         return Carp::carp_too_few_args(\@_, 2) if main::DEBUG && @_ < 2;
2214         $file{$addr} = main::internal_file_to_platform(shift);
2215         $first_released{$addr} = shift;
2216
2217         # The rest of the arguments are key => value pairs
2218         # %constructor_fields has been set up earlier to list all possible
2219         # ones.  Either set or push, depending on how the default has been set
2220         # up just above.
2221         my %args = @_;
2222         foreach my $key (keys %args) {
2223             my $argument = $args{$key};
2224
2225             # Note that the fields are the lower case of the constructor keys
2226             my $hash = $constructor_fields{lc $key};
2227             if (! defined $hash) {
2228                 Carp::my_carp_bug("Unrecognized parameters '$key => $argument' to new() for $self.  Skipped");
2229                 next;
2230             }
2231             if (ref $hash->{$addr} eq 'ARRAY') {
2232                 if (ref $argument eq 'ARRAY') {
2233                     foreach my $argument (@{$argument}) {
2234                         next if ! defined $argument;
2235                         push @{$hash->{$addr}}, $argument;
2236                     }
2237                 }
2238                 else {
2239                     push @{$hash->{$addr}}, $argument if defined $argument;
2240                 }
2241             }
2242             else {
2243                 $hash->{$addr} = $argument;
2244             }
2245             delete $args{$key};
2246         };
2247
2248         # If the file has a property for it, it means that the property is not
2249         # listed in the file's entries.  So add a handler to the list of line
2250         # handlers to insert the property name into the lines, to provide a
2251         # uniform interface to the final processing subroutine.
2252         # the final code doesn't have to worry about that.
2253         if ($property{$addr}) {
2254             push @{$each_line_handler{$addr}}, \&_insert_property_into_line;
2255         }
2256
2257         if ($non_skip{$addr} && ! $debug_skip && $verbosity) {
2258             print "Warning: " . __PACKAGE__ . " constructor for $file{$addr} has useless 'non_skip' in it\n";
2259         }
2260
2261         # If skipping, set to optional, and add to list of ignored files,
2262         # including its reason
2263         if ($skip{$addr}) {
2264             $optional{$addr} = 1;
2265             $skipped_files{$file{$addr}} = $skip{$addr}
2266         }
2267
2268         {   # On non-ascii platforms, we use a special handler
2269             no strict;
2270             no warnings 'once';
2271             *next_line = (main::NON_ASCII_PLATFORM)
2272                          ? *_next_line_with_remapped_range
2273                          : *_next_line;
2274         }
2275
2276         return $self;
2277     }
2278
2279
2280     use overload
2281         fallback => 0,
2282         qw("") => "_operator_stringify",
2283         "." => \&main::_operator_dot,
2284         ".=" => \&main::_operator_dot_equal,
2285     ;
2286
2287     sub _operator_stringify {
2288         my $self = shift;
2289
2290         return __PACKAGE__ . " object for " . $self->file;
2291     }
2292
2293     # flag to make sure extracted files are processed early
2294     my $seen_non_extracted_non_age = 0;
2295
2296     sub run {
2297         # Process the input object $self.  This opens and closes the file and
2298         # calls all the handlers for it.  Currently,  this can only be called
2299         # once per file, as it destroy's the EOF handler
2300
2301         my $self = shift;
2302         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2303
2304         my $addr = do { no overloading; pack 'J', $self; };
2305
2306         my $file = $file{$addr};
2307
2308         # Don't process if not expecting this file (because released later
2309         # than this Unicode version), and isn't there.  This means if someone
2310         # copies it into an earlier version's directory, we will go ahead and
2311         # process it.
2312         return if $first_released{$addr} gt $v_version && ! -e $file;
2313
2314         # If in debugging mode and this file doesn't have the non-skip
2315         # flag set, and isn't one of the critical files, skip it.
2316         if ($debug_skip
2317             && $first_released{$addr} ne v0
2318             && ! $non_skip{$addr})
2319         {
2320             print "Skipping $file in debugging\n" if $verbosity;
2321             return;
2322         }
2323
2324         # File could be optional
2325         if ($optional{$addr}) {
2326             return unless -e $file;
2327             my $result = eval $optional{$addr};
2328             if (! defined $result) {
2329                 Carp::my_carp_bug("Got '$@' when tried to eval $optional{$addr}.  $file Skipped.");
2330                 return;
2331             }
2332             if (! $result) {
2333                 if ($verbosity) {
2334                     print STDERR "Skipping processing input file '$file' because '$optional{$addr}' is not true\n";
2335                 }
2336                 return;
2337             }
2338         }
2339
2340         if (! defined $file || ! -e $file) {
2341
2342             # If the file doesn't exist, see if have internal data for it
2343             # (based on first_released being 0).
2344             if ($first_released{$addr} eq v0) {
2345                 $handle{$addr} = 'pretend_is_open';
2346             }
2347             else {
2348                 if (! $optional{$addr}  # File could be optional
2349                     && $v_version ge $first_released{$addr})
2350                 {
2351                     print STDERR "Skipping processing input file '$file' because not found\n" if $v_version ge $first_released{$addr};
2352                 }
2353                 return;
2354             }
2355         }
2356         else {
2357
2358             # Here, the file exists.  Some platforms may change the case of
2359             # its name
2360             if ($seen_non_extracted_non_age) {
2361                 if ($file =~ /$EXTRACTED/i) {
2362                     Carp::my_carp_bug(main::join_lines(<<END
2363 $file should be processed just after the 'Prop...Alias' files, and before
2364 anything not in the $EXTRACTED_DIR directory.  Proceeding, but the results may
2365 have subtle problems
2366 END
2367                     ));
2368                 }
2369             }
2370             elsif ($EXTRACTED_DIR
2371                     && $first_released{$addr} ne v0
2372                     && $file !~ /$EXTRACTED/i
2373                     && lc($file) ne 'dage.txt')
2374             {
2375                 # We don't set this (by the 'if' above) if we have no
2376                 # extracted directory, so if running on an early version,
2377                 # this test won't work.  Not worth worrying about.
2378                 $seen_non_extracted_non_age = 1;
2379             }
2380
2381             # And mark the file as having being processed, and warn if it
2382             # isn't a file we are expecting.  As we process the files,
2383             # they are deleted from the hash, so any that remain at the
2384             # end of the program are files that we didn't process.
2385             my $fkey = File::Spec->rel2abs($file);
2386             my $expecting = delete $potential_files{lc($fkey)};
2387
2388             Carp::my_carp("Was not expecting '$file'.") if
2389                     ! $expecting
2390                     && ! defined $handle{$addr};
2391
2392             # Having deleted from expected files, we can quit if not to do
2393             # anything.  Don't print progress unless really want verbosity
2394             if ($skip{$addr}) {
2395                 print "Skipping $file.\n" if $verbosity >= $VERBOSE;
2396                 return;
2397             }
2398
2399             # Open the file, converting the slashes used in this program
2400             # into the proper form for the OS
2401             my $file_handle;
2402             if (not open $file_handle, "<", $file) {
2403                 Carp::my_carp("Can't open $file.  Skipping: $!");
2404                 return 0;
2405             }
2406             $handle{$addr} = $file_handle; # Cache the open file handle
2407         }
2408
2409         if ($verbosity >= $PROGRESS) {
2410             if ($progress_message{$addr}) {
2411                 print "$progress_message{$addr}\n";
2412             }
2413             else {
2414                 # If using a virtual file, say so.
2415                 print "Processing ", (-e $file)
2416                                        ? $file
2417                                        : "substitute $file",
2418                                      "\n";
2419             }
2420         }
2421
2422
2423         # Call any special handler for before the file.
2424         &{$pre_handler{$addr}}($self) if $pre_handler{$addr};
2425
2426         # Then the main handler
2427         &{$handler{$addr}}($self);
2428
2429         # Then any special post-file handler.
2430         &{$post_handler{$addr}}($self) if $post_handler{$addr};
2431
2432         # If any errors have been accumulated, output the counts (as the first
2433         # error message in each class was output when it was encountered).
2434         if ($errors{$addr}) {
2435             my $total = 0;
2436             my $types = 0;
2437             foreach my $error (keys %{$errors{$addr}}) {
2438                 $total += $errors{$addr}->{$error};
2439                 delete $errors{$addr}->{$error};
2440                 $types++;
2441             }
2442             if ($total > 1) {
2443                 my $message
2444                         = "A total of $total lines had errors in $file.  ";
2445
2446                 $message .= ($types == 1)
2447                             ? '(Only the first one was displayed.)'
2448                             : '(Only the first of each type was displayed.)';
2449                 Carp::my_carp($message);
2450             }
2451         }
2452
2453         if (@{$missings{$addr}}) {
2454             Carp::my_carp_bug("Handler for $file didn't look at all the \@missing lines.  Generated tables likely are wrong");
2455         }
2456
2457         # If a real file handle, close it.
2458         close $handle{$addr} or Carp::my_carp("Can't close $file: $!") if
2459                                                         ref $handle{$addr};
2460         $handle{$addr} = "";   # Uses empty to indicate that has already seen
2461                                # the file, as opposed to undef
2462         return;
2463     }
2464
2465     sub _next_line {
2466         # Sets $_ to be the next logical input line, if any.  Returns non-zero
2467         # if such a line exists.  'logical' means that any lines that have
2468         # been added via insert_lines() will be returned in $_ before the file
2469         # is read again.
2470
2471         my $self = shift;
2472         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2473
2474         my $addr = do { no overloading; pack 'J', $self; };
2475
2476         # Here the file is open (or if the handle is not a ref, is an open
2477         # 'virtual' file).  Get the next line; any inserted lines get priority
2478         # over the file itself.
2479         my $adjusted;
2480
2481         LINE:
2482         while (1) { # Loop until find non-comment, non-empty line
2483             #local $to_trace = 1 if main::DEBUG;
2484             my $inserted_ref = shift @{$added_lines{$addr}};
2485             if (defined $inserted_ref) {
2486                 ($adjusted, $_) = @{$inserted_ref};
2487                 trace $adjusted, $_ if main::DEBUG && $to_trace;
2488                 return 1 if $adjusted;
2489             }
2490             else {
2491                 last if ! ref $handle{$addr}; # Don't read unless is real file
2492                 last if ! defined ($_ = readline $handle{$addr});
2493             }
2494             chomp;
2495             trace $_ if main::DEBUG && $to_trace;
2496
2497             # See if this line is the comment line that defines what property
2498             # value that code points that are not listed in the file should
2499             # have.  The format or existence of these lines is not guaranteed
2500             # by Unicode since they are comments, but the documentation says
2501             # that this was added for machine-readability, so probably won't
2502             # change.  This works starting in Unicode Version 5.0.  They look
2503             # like:
2504             #
2505             # @missing: 0000..10FFFF; Not_Reordered
2506             # @missing: 0000..10FFFF; Decomposition_Mapping; <code point>
2507             # @missing: 0000..10FFFF; ; NaN
2508             #
2509             # Save the line for a later get_missings() call.
2510             if (/$missing_defaults_prefix/) {
2511                 if ($has_missings_defaults{$addr} == $NO_DEFAULTS) {
2512                     $self->carp_bad_line("Unexpected \@missing line.  Assuming no missing entries");
2513                 }
2514                 elsif ($has_missings_defaults{$addr} == $NOT_IGNORED) {
2515                     my @defaults = split /\s* ; \s*/x, $_;
2516
2517                     # The first field is the @missing, which ends in a
2518                     # semi-colon, so can safely shift.
2519                     shift @defaults;
2520
2521                     # Some of these lines may have empty field placeholders
2522                     # which get in the way.  An example is:
2523                     # @missing: 0000..10FFFF; ; NaN
2524                     # Remove them.  Process starting from the top so the
2525                     # splice doesn't affect things still to be looked at.
2526                     for (my $i = @defaults - 1; $i >= 0; $i--) {
2527                         next if $defaults[$i] ne "";
2528                         splice @defaults, $i, 1;
2529                     }
2530
2531                     # What's left should be just the property (maybe) and the
2532                     # default.  Having only one element means it doesn't have
2533                     # the property.
2534                     my $default;
2535                     my $property;
2536                     if (@defaults >= 1) {
2537                         if (@defaults == 1) {
2538                             $default = $defaults[0];
2539                         }
2540                         else {
2541                             $property = $defaults[0];
2542                             $default = $defaults[1];
2543                         }
2544                     }
2545
2546                     if (@defaults < 1
2547                         || @defaults > 2
2548                         || ($default =~ /^</
2549                             && $default !~ /^<code *point>$/i
2550                             && $default !~ /^<none>$/i
2551                             && $default !~ /^<script>$/i))
2552                     {
2553                         $self->carp_bad_line("Unrecognized \@missing line: $_.  Assuming no missing entries");
2554                     }
2555                     else {
2556
2557                         # If the property is missing from the line, it should
2558                         # be the one for the whole file
2559                         $property = $property{$addr} if ! defined $property;
2560
2561                         # Change <none> to the null string, which is what it
2562                         # really means.  If the default is the code point
2563                         # itself, set it to <code point>, which is what
2564                         # Unicode uses (but sometimes they've forgotten the
2565                         # space)
2566                         if ($default =~ /^<none>$/i) {
2567                             $default = "";
2568                         }
2569                         elsif ($default =~ /^<code *point>$/i) {
2570                             $default = $CODE_POINT;
2571                         }
2572                         elsif ($default =~ /^<script>$/i) {
2573
2574                             # Special case this one.  Currently is from
2575                             # ScriptExtensions.txt, and means for all unlisted
2576                             # code points, use their Script property values.
2577                             # For the code points not listed in that file, the
2578                             # default value is 'Unknown'.
2579                             $default = "Unknown";
2580                         }
2581
2582                         # Store them as a sub-arrays with both components.
2583                         push @{$missings{$addr}}, [ $default, $property ];
2584                     }
2585                 }
2586
2587                 # There is nothing for the caller to process on this comment
2588                 # line.
2589                 next;
2590             }
2591
2592             # Remove comments and trailing space, and skip this line if the
2593             # result is empty
2594             s/#.*//;
2595             s/\s+$//;
2596             next if /^$/;
2597
2598             # Call any handlers for this line, and skip further processing of
2599             # the line if the handler sets the line to null.
2600             foreach my $sub_ref (@{$each_line_handler{$addr}}) {
2601                 &{$sub_ref}($self);
2602                 next LINE if /^$/;
2603             }
2604
2605             # Here the line is ok.  return success.
2606             return 1;
2607         } # End of looping through lines.
2608
2609         # If there is an EOF handler, call it (only once) and if it generates
2610         # more lines to process go back in the loop to handle them.
2611         if ($eof_handler{$addr}) {
2612             &{$eof_handler{$addr}}($self);
2613             $eof_handler{$addr} = "";   # Currently only get one shot at it.
2614             goto LINE if $added_lines{$addr};
2615         }
2616
2617         # Return failure -- no more lines.
2618         return 0;
2619
2620     }
2621
2622     sub _next_line_with_remapped_range {
2623         my $self = shift;
2624         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2625
2626         # like _next_line(), but for use on non-ASCII platforms.  It sets $_
2627         # to be the next logical input line, if any.  Returns non-zero if such
2628         # a line exists.  'logical' means that any lines that have been added
2629         # via insert_lines() will be returned in $_ before the file is read
2630         # again.
2631         #
2632         # The difference from _next_line() is that this remaps the Unicode
2633         # code points in the input to those of the native platform.  Each
2634         # input line contains a single code point, or a single contiguous
2635         # range of them  This routine splits each range into its individual
2636         # code points and caches them.  It returns the cached values,
2637         # translated into their native equivalents, one at a time, for each
2638         # call, before reading the next line.  Since native values can only be
2639         # a single byte wide, no translation is needed for code points above
2640         # 0xFF, and ranges that are entirely above that number are not split.
2641         # If an input line contains the range 254-1000, it would be split into
2642         # three elements: 254, 255, and 256-1000.  (The downstream table
2643         # insertion code will sort and coalesce the individual code points
2644         # into appropriate ranges.)
2645
2646         my $addr = do { no overloading; pack 'J', $self; };
2647
2648         while (1) {
2649
2650             # Look in cache before reading the next line.  Return any cached
2651             # value, translated
2652             my $inserted = shift @{$remapped_lines{$addr}};
2653             if (defined $inserted) {
2654                 trace $inserted if main::DEBUG && $to_trace;
2655                 $_ = $inserted =~ s/^ ( \d+ ) /sprintf("%04X", utf8::unicode_to_native($1))/xer;
2656                 trace $_ if main::DEBUG && $to_trace;
2657                 return 1;
2658             }
2659
2660             # Get the next line.
2661             return 0 unless _next_line($self);
2662
2663             # If there is a special handler for it, return the line,
2664             # untranslated.  This should happen only for files that are
2665             # special, not being code-point related, such as property names.
2666             return 1 if $handler{$addr}
2667                                     != \&main::process_generic_property_file;
2668
2669             my ($range, $property_name, $map, @remainder)
2670                 = split /\s*;\s*/, $_, -1; # -1 => retain trailing null fields
2671
2672             if (@remainder
2673                 || ! defined $property_name
2674                 || $range !~ /^ ($code_point_re) (?:\.\. ($code_point_re) )? $/x)
2675             {
2676                 Carp::my_carp_bug("Unrecognized input line '$_'.  Ignored");
2677             }
2678
2679             my $low = hex $1;
2680             my $high = (defined $2) ? hex $2 : $low;
2681
2682             # If the input maps the range to another code point, remap the
2683             # target if it is between 0 and 255.
2684             my $tail;
2685             if (defined $map) {
2686                 $map =~ s/\b 00 ( [0-9A-F]{2} ) \b/sprintf("%04X", utf8::unicode_to_native(hex $1))/gxe;
2687                 $tail = "$property_name; $map";
2688                 $_ = "$range; $tail";
2689             }
2690             else {
2691                 $tail = $property_name;
2692             }
2693
2694             # If entire range is above 255, just return it, unchanged (except
2695             # any mapped-to code point, already changed above)
2696             return 1 if $low > 255;
2697
2698             # Cache an entry for every code point < 255.  For those in the
2699             # range above 255, return a dummy entry for just that portion of
2700             # the range.  Note that this will be out-of-order, but that is not
2701             # a problem.
2702             foreach my $code_point ($low .. $high) {
2703                 if ($code_point > 255) {
2704                     $_ = sprintf "%04X..%04X; $tail", $code_point, $high;
2705                     return 1;
2706                 }
2707                 push @{$remapped_lines{$addr}}, "$code_point; $tail";
2708             }
2709         } # End of looping through lines.
2710
2711         # NOTREACHED
2712     }
2713
2714 #   Not currently used, not fully tested.
2715 #    sub peek {
2716 #        # Non-destructive look-ahead one non-adjusted, non-comment, non-blank
2717 #        # record.  Not callable from an each_line_handler(), nor does it call
2718 #        # an each_line_handler() on the line.
2719 #
2720 #        my $self = shift;
2721 #        my $addr = do { no overloading; pack 'J', $self; };
2722 #
2723 #        foreach my $inserted_ref (@{$added_lines{$addr}}) {
2724 #            my ($adjusted, $line) = @{$inserted_ref};
2725 #            next if $adjusted;
2726 #
2727 #            # Remove comments and trailing space, and return a non-empty
2728 #            # resulting line
2729 #            $line =~ s/#.*//;
2730 #            $line =~ s/\s+$//;
2731 #            return $line if $line ne "";
2732 #        }
2733 #
2734 #        return if ! ref $handle{$addr}; # Don't read unless is real file
2735 #        while (1) { # Loop until find non-comment, non-empty line
2736 #            local $to_trace = 1 if main::DEBUG;
2737 #            trace $_ if main::DEBUG && $to_trace;
2738 #            return if ! defined (my $line = readline $handle{$addr});
2739 #            chomp $line;
2740 #            push @{$added_lines{$addr}}, [ 0, $line ];
2741 #
2742 #            $line =~ s/#.*//;
2743 #            $line =~ s/\s+$//;
2744 #            return $line if $line ne "";
2745 #        }
2746 #
2747 #        return;
2748 #    }
2749
2750
2751     sub insert_lines {
2752         # Lines can be inserted so that it looks like they were in the input
2753         # file at the place it was when this routine is called.  See also
2754         # insert_adjusted_lines().  Lines inserted via this routine go through
2755         # any each_line_handler()
2756
2757         my $self = shift;
2758
2759         # Each inserted line is an array, with the first element being 0 to
2760         # indicate that this line hasn't been adjusted, and needs to be
2761         # processed.
2762         no overloading;
2763         push @{$added_lines{pack 'J', $self}}, map { [ 0, $_ ] } @_;
2764         return;
2765     }
2766
2767     sub insert_adjusted_lines {
2768         # Lines can be inserted so that it looks like they were in the input
2769         # file at the place it was when this routine is called.  See also
2770         # insert_lines().  Lines inserted via this routine are already fully
2771         # adjusted, ready to be processed; each_line_handler()s handlers will
2772         # not be called.  This means this is not a completely general
2773         # facility, as only the last each_line_handler on the stack should
2774         # call this.  It could be made more general, by passing to each of the
2775         # line_handlers their position on the stack, which they would pass on
2776         # to this routine, and that would replace the boolean first element in
2777         # the anonymous array pushed here, so that the next_line routine could
2778         # use that to call only those handlers whose index is after it on the
2779         # stack.  But this is overkill for what is needed now.
2780
2781         my $self = shift;
2782         trace $_[0] if main::DEBUG && $to_trace;
2783
2784         # Each inserted line is an array, with the first element being 1 to
2785         # indicate that this line has been adjusted
2786         no overloading;
2787         push @{$added_lines{pack 'J', $self}}, map { [ 1, $_ ] } @_;
2788         return;
2789     }
2790
2791     sub get_missings {
2792         # Returns the stored up @missings lines' values, and clears the list.
2793         # The values are in an array, consisting of the default in the first
2794         # element, and the property in the 2nd.  However, since these lines
2795         # can be stacked up, the return is an array of all these arrays.
2796
2797         my $self = shift;
2798         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2799
2800         my $addr = do { no overloading; pack 'J', $self; };
2801
2802         # If not accepting a list return, just return the first one.
2803         return shift @{$missings{$addr}} unless wantarray;
2804
2805         my @return = @{$missings{$addr}};
2806         undef @{$missings{$addr}};
2807         return @return;
2808     }
2809
2810     sub _insert_property_into_line {
2811         # Add a property field to $_, if this file requires it.
2812
2813         my $self = shift;
2814         my $addr = do { no overloading; pack 'J', $self; };
2815         my $property = $property{$addr};
2816         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2817
2818         $_ =~ s/(;|$)/; $property$1/;
2819         return;
2820     }
2821
2822     sub carp_bad_line {
2823         # Output consistent error messages, using either a generic one, or the
2824         # one given by the optional parameter.  To avoid gazillions of the
2825         # same message in case the syntax of a  file is way off, this routine
2826         # only outputs the first instance of each message, incrementing a
2827         # count so the totals can be output at the end of the file.
2828
2829         my $self = shift;
2830         my $message = shift;
2831         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2832
2833         my $addr = do { no overloading; pack 'J', $self; };
2834
2835         $message = 'Unexpected line' unless $message;
2836
2837         # No trailing punctuation so as to fit with our addenda.
2838         $message =~ s/[.:;,]$//;
2839
2840         # If haven't seen this exact message before, output it now.  Otherwise
2841         # increment the count of how many times it has occurred
2842         unless ($errors{$addr}->{$message}) {
2843             Carp::my_carp("$message in '$_' in "
2844                             . $file{$addr}
2845                             . " at line $..  Skipping this line;");
2846             $errors{$addr}->{$message} = 1;
2847         }
2848         else {
2849             $errors{$addr}->{$message}++;
2850         }
2851
2852         # Clear the line to prevent any further (meaningful) processing of it.
2853         $_ = "";
2854
2855         return;
2856     }
2857 } # End closure
2858
2859 package Multi_Default;
2860
2861 # Certain properties in early versions of Unicode had more than one possible
2862 # default for code points missing from the files.  In these cases, one
2863 # default applies to everything left over after all the others are applied,
2864 # and for each of the others, there is a description of which class of code
2865 # points applies to it.  This object helps implement this by storing the
2866 # defaults, and for all but that final default, an eval string that generates
2867 # the class that it applies to.
2868
2869
2870 {   # Closure
2871
2872     main::setup_package();
2873
2874     my %class_defaults;
2875     # The defaults structure for the classes
2876     main::set_access('class_defaults', \%class_defaults);
2877
2878     my %other_default;
2879     # The default that applies to everything left over.
2880     main::set_access('other_default', \%other_default, 'r');
2881
2882
2883     sub new {
2884         # The constructor is called with default => eval pairs, terminated by
2885         # the left-over default. e.g.
2886         # Multi_Default->new(
2887         #        'T' => '$gc->table("Mn") + $gc->table("Cf") - 0x200C
2888         #               -  0x200D',
2889         #        'R' => 'some other expression that evaluates to code points',
2890         #        .
2891         #        .
2892         #        .
2893         #        'U'));
2894
2895         my $class = shift;
2896
2897         my $self = bless \do{my $anonymous_scalar}, $class;
2898         my $addr = do { no overloading; pack 'J', $self; };
2899
2900         while (@_ > 1) {
2901             my $default = shift;
2902             my $eval = shift;
2903             $class_defaults{$addr}->{$default} = $eval;
2904         }
2905
2906         $other_default{$addr} = shift;
2907
2908         return $self;
2909     }
2910
2911     sub get_next_defaults {
2912         # Iterates and returns the next class of defaults.
2913         my $self = shift;
2914         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2915
2916         my $addr = do { no overloading; pack 'J', $self; };
2917
2918         return each %{$class_defaults{$addr}};
2919     }
2920 }
2921
2922 package Alias;
2923
2924 # An alias is one of the names that a table goes by.  This class defines them
2925 # including some attributes.  Everything is currently setup in the
2926 # constructor.
2927
2928
2929 {   # Closure
2930
2931     main::setup_package();
2932
2933     my %name;
2934     main::set_access('name', \%name, 'r');
2935
2936     my %loose_match;
2937     # Should this name match loosely or not.
2938     main::set_access('loose_match', \%loose_match, 'r');
2939
2940     my %make_re_pod_entry;
2941     # Some aliases should not get their own entries in the re section of the
2942     # pod, because they are covered by a wild-card, and some we want to
2943     # discourage use of.  Binary
2944     main::set_access('make_re_pod_entry', \%make_re_pod_entry, 'r', 's');
2945
2946     my %ucd;
2947     # Is this documented to be accessible via Unicode::UCD
2948     main::set_access('ucd', \%ucd, 'r', 's');
2949
2950     my %status;
2951     # Aliases have a status, like deprecated, or even suppressed (which means
2952     # they don't appear in documentation).  Enum
2953     main::set_access('status', \%status, 'r');
2954
2955     my %ok_as_filename;
2956     # Similarly, some aliases should not be considered as usable ones for
2957     # external use, such as file names, or we don't want documentation to
2958     # recommend them.  Boolean
2959     main::set_access('ok_as_filename', \%ok_as_filename, 'r');
2960
2961     sub new {
2962         my $class = shift;
2963
2964         my $self = bless \do { my $anonymous_scalar }, $class;
2965         my $addr = do { no overloading; pack 'J', $self; };
2966
2967         $name{$addr} = shift;
2968         $loose_match{$addr} = shift;
2969         $make_re_pod_entry{$addr} = shift;
2970         $ok_as_filename{$addr} = shift;
2971         $status{$addr} = shift;
2972         $ucd{$addr} = shift;
2973
2974         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
2975
2976         # Null names are never ok externally
2977         $ok_as_filename{$addr} = 0 if $name{$addr} eq "";
2978
2979         return $self;
2980     }
2981 }
2982
2983 package Range;
2984
2985 # A range is the basic unit for storing code points, and is described in the
2986 # comments at the beginning of the program.  Each range has a starting code
2987 # point; an ending code point (not less than the starting one); a value
2988 # that applies to every code point in between the two end-points, inclusive;
2989 # and an enum type that applies to the value.  The type is for the user's
2990 # convenience, and has no meaning here, except that a non-zero type is
2991 # considered to not obey the normal Unicode rules for having standard forms.
2992 #
2993 # The same structure is used for both map and match tables, even though in the
2994 # latter, the value (and hence type) is irrelevant and could be used as a
2995 # comment.  In map tables, the value is what all the code points in the range
2996 # map to.  Type 0 values have the standardized version of the value stored as
2997 # well, so as to not have to recalculate it a lot.
2998
2999 sub trace { return main::trace(@_); }
3000
3001 {   # Closure
3002
3003     main::setup_package();
3004
3005     my %start;
3006     main::set_access('start', \%start, 'r', 's');
3007
3008     my %end;
3009     main::set_access('end', \%end, 'r', 's');
3010
3011     my %value;
3012     main::set_access('value', \%value, 'r');
3013
3014     my %type;
3015     main::set_access('type', \%type, 'r');
3016
3017     my %standard_form;
3018     # The value in internal standard form.  Defined only if the type is 0.
3019     main::set_access('standard_form', \%standard_form);
3020
3021     # Note that if these fields change, the dump() method should as well
3022
3023     sub new {
3024         return Carp::carp_too_few_args(\@_, 3) if main::DEBUG && @_ < 3;
3025         my $class = shift;
3026
3027         my $self = bless \do { my $anonymous_scalar }, $class;
3028         my $addr = do { no overloading; pack 'J', $self; };
3029
3030         $start{$addr} = shift;
3031         $end{$addr} = shift;
3032
3033         my %args = @_;
3034
3035         my $value = delete $args{'Value'};  # Can be 0
3036         $value = "" unless defined $value;
3037         $value{$addr} = $value;
3038
3039         $type{$addr} = delete $args{'Type'} || 0;
3040
3041         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3042
3043         return $self;
3044     }
3045
3046     use overload
3047         fallback => 0,
3048         qw("") => "_operator_stringify",
3049         "." => \&main::_operator_dot,
3050         ".=" => \&main::_operator_dot_equal,
3051     ;
3052
3053     sub _operator_stringify {
3054         my $self = shift;
3055         my $addr = do { no overloading; pack 'J', $self; };
3056
3057         # Output it like '0041..0065 (value)'
3058         my $return = sprintf("%04X", $start{$addr})
3059                         .  '..'
3060                         . sprintf("%04X", $end{$addr});
3061         my $value = $value{$addr};
3062         my $type = $type{$addr};
3063         $return .= ' (';
3064         $return .= "$value";
3065         $return .= ", Type=$type" if $type != 0;
3066         $return .= ')';
3067
3068         return $return;
3069     }
3070
3071     sub standard_form {
3072         # Calculate the standard form only if needed, and cache the result.
3073         # The standard form is the value itself if the type is special.
3074         # This represents a considerable CPU and memory saving - at the time
3075         # of writing there are 368676 non-special objects, but the standard
3076         # form is only requested for 22047 of them - ie about 6%.
3077
3078         my $self = shift;
3079         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3080
3081         my $addr = do { no overloading; pack 'J', $self; };
3082
3083         return $standard_form{$addr} if defined $standard_form{$addr};
3084
3085         my $value = $value{$addr};
3086         return $value if $type{$addr};
3087         return $standard_form{$addr} = main::standardize($value);
3088     }
3089
3090     sub dump {
3091         # Human, not machine readable.  For machine readable, comment out this
3092         # entire routine and let the standard one take effect.
3093         my $self = shift;
3094         my $indent = shift;
3095         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3096
3097         my $addr = do { no overloading; pack 'J', $self; };
3098
3099         my $return = $indent
3100                     . sprintf("%04X", $start{$addr})
3101                     . '..'
3102                     . sprintf("%04X", $end{$addr})
3103                     . " '$value{$addr}';";
3104         if (! defined $standard_form{$addr}) {
3105             $return .= "(type=$type{$addr})";
3106         }
3107         elsif ($standard_form{$addr} ne $value{$addr}) {
3108             $return .= "(standard '$standard_form{$addr}')";
3109         }
3110         return $return;
3111     }
3112 } # End closure
3113
3114 package _Range_List_Base;
3115
3116 # Base class for range lists.  A range list is simply an ordered list of
3117 # ranges, so that the ranges with the lowest starting numbers are first in it.
3118 #
3119 # When a new range is added that is adjacent to an existing range that has the
3120 # same value and type, it merges with it to form a larger range.
3121 #
3122 # Ranges generally do not overlap, except that there can be multiple entries
3123 # of single code point ranges.  This is because of NameAliases.txt.
3124 #
3125 # In this program, there is a standard value such that if two different
3126 # values, have the same standard value, they are considered equivalent.  This
3127 # value was chosen so that it gives correct results on Unicode data
3128
3129 # There are a number of methods to manipulate range lists, and some operators
3130 # are overloaded to handle them.
3131
3132 sub trace { return main::trace(@_); }
3133
3134 { # Closure
3135
3136     our $addr;
3137
3138     # Max is initialized to a negative value that isn't adjacent to 0, for
3139     # simpler tests
3140     my $max_init = -2;
3141
3142     main::setup_package();
3143
3144     my %ranges;
3145     # The list of ranges
3146     main::set_access('ranges', \%ranges, 'readable_array');
3147
3148     my %max;
3149     # The highest code point in the list.  This was originally a method, but
3150     # actual measurements said it was used a lot.
3151     main::set_access('max', \%max, 'r');
3152
3153     my %each_range_iterator;
3154     # Iterator position for each_range()
3155     main::set_access('each_range_iterator', \%each_range_iterator);
3156
3157     my %owner_name_of;
3158     # Name of parent this is attached to, if any.  Solely for better error
3159     # messages.
3160     main::set_access('owner_name_of', \%owner_name_of, 'p_r');
3161
3162     my %_search_ranges_cache;
3163     # A cache of the previous result from _search_ranges(), for better
3164     # performance
3165     main::set_access('_search_ranges_cache', \%_search_ranges_cache);
3166
3167     sub new {
3168         my $class = shift;
3169         my %args = @_;
3170
3171         # Optional initialization data for the range list.
3172         my $initialize = delete $args{'Initialize'};
3173
3174         my $self;
3175
3176         # Use _union() to initialize.  _union() returns an object of this
3177         # class, which means that it will call this constructor recursively.
3178         # But it won't have this $initialize parameter so that it won't
3179         # infinitely loop on this.
3180         return _union($class, $initialize, %args) if defined $initialize;
3181
3182         $self = bless \do { my $anonymous_scalar }, $class;
3183         my $addr = do { no overloading; pack 'J', $self; };
3184
3185         # Optional parent object, only for debug info.
3186         $owner_name_of{$addr} = delete $args{'Owner'};
3187         $owner_name_of{$addr} = "" if ! defined $owner_name_of{$addr};
3188
3189         # Stringify, in case it is an object.
3190         $owner_name_of{$addr} = "$owner_name_of{$addr}";
3191
3192         # This is used only for error messages, and so a colon is added
3193         $owner_name_of{$addr} .= ": " if $owner_name_of{$addr} ne "";
3194
3195         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3196
3197         $max{$addr} = $max_init;
3198
3199         $_search_ranges_cache{$addr} = 0;
3200         $ranges{$addr} = [];
3201
3202         return $self;
3203     }
3204
3205     use overload
3206         fallback => 0,
3207         qw("") => "_operator_stringify",
3208         "." => \&main::_operator_dot,
3209         ".=" => \&main::_operator_dot_equal,
3210     ;
3211
3212     sub _operator_stringify {
3213         my $self = shift;
3214         my $addr = do { no overloading; pack 'J', $self; };
3215
3216         return "Range_List attached to '$owner_name_of{$addr}'"
3217                                                 if $owner_name_of{$addr};
3218         return "anonymous Range_List " . \$self;
3219     }
3220
3221     sub _union {
3222         # Returns the union of the input code points.  It can be called as
3223         # either a constructor or a method.  If called as a method, the result
3224         # will be a new() instance of the calling object, containing the union
3225         # of that object with the other parameter's code points;  if called as
3226         # a constructor, the first parameter gives the class that the new object
3227         # should be, and the second parameter gives the code points to go into
3228         # it.
3229         # In either case, there are two parameters looked at by this routine;
3230         # any additional parameters are passed to the new() constructor.
3231         #
3232         # The code points can come in the form of some object that contains
3233         # ranges, and has a conventionally named method to access them; or
3234         # they can be an array of individual code points (as integers); or
3235         # just a single code point.
3236         #
3237         # If they are ranges, this routine doesn't make any effort to preserve
3238         # the range values and types of one input over the other.  Therefore
3239         # this base class should not allow _union to be called from other than
3240         # initialization code, so as to prevent two tables from being added
3241         # together where the range values matter.  The general form of this
3242         # routine therefore belongs in a derived class, but it was moved here
3243         # to avoid duplication of code.  The failure to overload this in this
3244         # class keeps it safe.
3245         #
3246         # It does make the effort during initialization to accept tables with
3247         # multiple values for the same code point, and to preserve the order
3248         # of these.  If there is only one input range or range set, it doesn't
3249         # sort (as it should already be sorted to the desired order), and will
3250         # accept multiple values per code point.  Otherwise it will merge
3251         # multiple values into a single one.
3252
3253         my $self;
3254         my @args;   # Arguments to pass to the constructor
3255
3256         my $class = shift;
3257
3258         # If a method call, will start the union with the object itself, and
3259         # the class of the new object will be the same as self.
3260         if (ref $class) {
3261             $self = $class;
3262             $class = ref $self;
3263             push @args, $self;
3264         }
3265
3266         # Add the other required parameter.
3267         push @args, shift;
3268         # Rest of parameters are passed on to the constructor
3269
3270         # Accumulate all records from both lists.
3271         my @records;
3272         my $input_count = 0;
3273         for my $arg (@args) {
3274             #local $to_trace = 0 if main::DEBUG;
3275             trace "argument = $arg" if main::DEBUG && $to_trace;
3276             if (! defined $arg) {
3277                 my $message = "";
3278                 if (defined $self) {
3279                     no overloading;
3280                     $message .= $owner_name_of{pack 'J', $self};
3281                 }
3282                 Carp::my_carp_bug($message . "Undefined argument to _union.  No union done.");
3283                 return;
3284             }
3285
3286             $arg = [ $arg ] if ! ref $arg;
3287             my $type = ref $arg;
3288             if ($type eq 'ARRAY') {
3289                 foreach my $element (@$arg) {
3290                     push @records, Range->new($element, $element);
3291                     $input_count++;
3292                 }
3293             }
3294             elsif ($arg->isa('Range')) {
3295                 push @records, $arg;
3296                 $input_count++;
3297             }
3298             elsif ($arg->can('ranges')) {
3299                 push @records, $arg->ranges;
3300                 $input_count++;
3301             }
3302             else {
3303                 my $message = "";
3304                 if (defined $self) {
3305                     no overloading;
3306                     $message .= $owner_name_of{pack 'J', $self};
3307                 }
3308                 Carp::my_carp_bug($message . "Cannot take the union of a $type.  No union done.");
3309                 return;
3310             }
3311         }
3312
3313         # Sort with the range containing the lowest ordinal first, but if
3314         # two ranges start at the same code point, sort with the bigger range
3315         # of the two first, because it takes fewer cycles.
3316         if ($input_count > 1) {
3317             @records = sort { ($a->start <=> $b->start)
3318                                       or
3319                                     # if b is shorter than a, b->end will be
3320                                     # less than a->end, and we want to select
3321                                     # a, so want to return -1
3322                                     ($b->end <=> $a->end)
3323                                    } @records;
3324         }
3325
3326         my $new = $class->new(@_);
3327
3328         # Fold in records so long as they add new information.
3329         for my $set (@records) {
3330             my $start = $set->start;
3331             my $end   = $set->end;
3332             my $value = $set->value;
3333             my $type  = $set->type;
3334             if ($start > $new->max) {
3335                 $new->_add_delete('+', $start, $end, $value, Type => $type);
3336             }
3337             elsif ($end > $new->max) {
3338                 $new->_add_delete('+', $new->max +1, $end, $value,
3339                                                                 Type => $type);
3340             }
3341             elsif ($input_count == 1) {
3342                 # Here, overlaps existing range, but is from a single input,
3343                 # so preserve the multiple values from that input.
3344                 $new->_add_delete('+', $start, $end, $value, Type => $type,
3345                                                 Replace => $MULTIPLE_AFTER);
3346             }
3347         }
3348
3349         return $new;
3350     }
3351
3352     sub range_count {        # Return the number of ranges in the range list
3353         my $self = shift;
3354         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3355
3356         no overloading;
3357         return scalar @{$ranges{pack 'J', $self}};
3358     }
3359
3360     sub min {
3361         # Returns the minimum code point currently in the range list, or if
3362         # the range list is empty, 2 beyond the max possible.  This is a
3363         # method because used so rarely, that not worth saving between calls,
3364         # and having to worry about changing it as ranges are added and
3365         # deleted.
3366
3367         my $self = shift;
3368         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3369
3370         my $addr = do { no overloading; pack 'J', $self; };
3371
3372         # If the range list is empty, return a large value that isn't adjacent
3373         # to any that could be in the range list, for simpler tests
3374         return $MAX_UNICODE_CODEPOINT + 2 unless scalar @{$ranges{$addr}};
3375         return $ranges{$addr}->[0]->start;
3376     }
3377
3378     sub contains {
3379         # Boolean: Is argument in the range list?  If so returns $i such that:
3380         #   range[$i]->end < $codepoint <= range[$i+1]->end
3381         # which is one beyond what you want; this is so that the 0th range
3382         # doesn't return false
3383         my $self = shift;
3384         my $codepoint = shift;
3385         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3386
3387         my $i = $self->_search_ranges($codepoint);
3388         return 0 unless defined $i;
3389
3390         # The search returns $i, such that
3391         #   range[$i-1]->end < $codepoint <= range[$i]->end
3392         # So is in the table if and only iff it is at least the start position
3393         # of range $i.
3394         no overloading;
3395         return 0 if $ranges{pack 'J', $self}->[$i]->start > $codepoint;
3396         return $i + 1;
3397     }
3398
3399     sub containing_range {
3400         # Returns the range object that contains the code point, undef if none
3401
3402         my $self = shift;
3403         my $codepoint = shift;
3404         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3405
3406         my $i = $self->contains($codepoint);
3407         return unless $i;
3408
3409         # contains() returns 1 beyond where we should look
3410         no overloading;
3411         return $ranges{pack 'J', $self}->[$i-1];
3412     }
3413
3414     sub value_of {
3415         # Returns the value associated with the code point, undef if none
3416
3417         my $self = shift;
3418         my $codepoint = shift;
3419         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3420
3421         my $range = $self->containing_range($codepoint);
3422         return unless defined $range;
3423
3424         return $range->value;
3425     }
3426
3427     sub type_of {
3428         # Returns the type of the range containing the code point, undef if
3429         # the code point is not in the table
3430
3431         my $self = shift;
3432         my $codepoint = shift;
3433         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3434
3435         my $range = $self->containing_range($codepoint);
3436         return unless defined $range;
3437
3438         return $range->type;
3439     }
3440
3441     sub _search_ranges {
3442         # Find the range in the list which contains a code point, or where it
3443         # should go if were to add it.  That is, it returns $i, such that:
3444         #   range[$i-1]->end < $codepoint <= range[$i]->end
3445         # Returns undef if no such $i is possible (e.g. at end of table), or
3446         # if there is an error.
3447
3448         my $self = shift;
3449         my $code_point = shift;
3450         Carp::carp_extra_args(\@_) if main::DEBUG && @_;
3451
3452         my $addr = do { no overloading; pack 'J', $self; };
3453
3454         return if $code_point > $max{$addr};
3455         my $r = $ranges{$addr};                # The current list of ranges
3456         my $range_list_size = scalar @$r;
3457         my $i;
3458
3459         use integer;        # want integer division
3460
3461         # Use the cached result as the starting guess for this one, because,
3462         # an experiment on 5.1 showed that 90% of the time the cache was the
3463         # same as the result on the next call (and 7% it was one less).
3464         $i = $_search_ranges_cache{$addr};
3465         $i = 0 if $i >= $range_list_size;   # Reset if no longer valid (prob.
3466                                             # from an intervening deletion
3467         #local $to_trace = 1 if main::DEBUG;
3468         trace "previous \$i is still valid: $i" if main::DEBUG && $to_trace && $code_point <= $r->[$i]->end && ($i == 0 || $r->[$i-1]->end < $code_point);
3469         return $i if $code_point <= $r->[$i]->end
3470                      && ($i == 0 || $r->[$i-1]->end < $code_point);
3471
3472         # Here the cache doesn't yield the correct $i.  Try adding 1.
3473         if ($i < $range_list_size - 1
3474             && $r->[$i]->end < $code_point &&
3475             $code_point <= $r->[$i+1]->end)
3476         {
3477             $i++;
3478             trace "next \$i is correct: $i" if main::DEBUG && $to_trace;
3479             $_search_ranges_cache{$addr} = $i;
3480             return $i;
3481         }
3482
3483         # Here, adding 1 also didn't work.  We do a binary search to
3484         # find the correct position, starting with current $i
3485         my $lower = 0;
3486         my $upper = $range_list_size - 1;
3487         while (1) {
3488             trace "top of loop i=$i:", sprintf("%04X", $r->[$lower]->start), "[$lower] .. ", sprintf("%04X", $r->[$i]->start), "[$i] .. ", sprintf("%04X", $r->[$upper]->start), "[$upper]" if main::DEBUG && $to_trace;
3489
3490             if ($code_point <= $r->[$i]->end) {
3491
3492                 # Here we have met the upper constraint.  We can quit if we
3493                 # also meet the lower one.
3494                 last if $i == 0 || $r->[$i-1]->end < $code_point;
3495
3496                 $upper = $i;        # Still too high.
3497
3498             }
3499             else {
3500
3501                 # Here, $r[$i]->end < $code_point, so look higher up.
3502                 $lower = $i;
3503             }
3504
3505             # Split search domain in half to try again.
3506             my $temp = ($upper + $lower) / 2;
3507
3508             # No point in continuing unless $i changes for next time
3509             # in the loop.
3510             if ($temp == $i) {
3511
3512                 # We can't reach the highest element because of the averaging.
3513                 # So if one below the upper edge, force it there and try one
3514                 # more time.
3515                 if ($i == $range_list_size - 2) {
3516
3517                     trace "Forcing to upper edge" if main::DEBUG && $to_trace;
3518                     $i = $range_list_size - 1;
3519
3520                     # Change $lower as well so if fails next time through,
3521                     # taking the average will yield the same $i, and we will
3522                     # quit with the error message just below.
3523                     $lower = $i;
3524                     next;
3525                 }
3526                 Carp::my_carp_bug("$owner_name_of{$addr}Can't find where the range ought to go.  No action taken.");
3527                 return;
3528             }
3529             $i = $temp;
3530         } # End of while loop
3531
3532         if (main::DEBUG && $to_trace) {
3533             trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i;
3534             trace "i=  [ $i ]", $r->[$i];
3535             trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < $range_list_size - 1;
3536         }
3537
3538         # Here we have found the offset.  Cache it as a starting point for the
3539         # next call.
3540         $_search_ranges_cache{$addr} = $i;
3541         return $i;
3542     }
3543
3544     sub _add_delete {
3545         # Add, replace or delete ranges to or from a list.  The $type
3546         # parameter gives which:
3547         #   '+' => insert or replace a range, returning a list of any changed
3548         #          ranges.
3549         #   '-' => delete a range, returning a list of any deleted ranges.
3550         #
3551         # The next three parameters give respectively the start, end, and
3552         # value associated with the range.  'value' should be null unless the
3553         # operation is '+';
3554         #
3555         # The range list is kept sorted so that the range with the lowest
3556         # starting position is first in the list, and generally, adjacent
3557         # ranges with the same values are merged into a single larger one (see
3558         # exceptions below).
3559         #
3560         # There are more parameters; all are key => value pairs:
3561         #   Type    gives the type of the value.  It is only valid for '+'.
3562         #           All ranges have types; if this parameter is omitted, 0 is
3563         #           assumed.  Ranges with type 0 are assumed to obey the
3564         #           Unicode rules for casing, etc; ranges with other types are
3565         #           not.  Otherwise, the type is arbitrary, for the caller's
3566         #           convenience, and looked at only by this routine to keep
3567         #           adjacent ranges of different types from being merged into
3568         #           a single larger range, and when Replace =>
3569         #           $IF_NOT_EQUIVALENT is specified (see just below).
3570         #   Replace  determines what to do if the range list already contains
3571         #            ranges which coincide with all or portions of the input
3572         #            range.  It is only valid for '+':
3573         #       => $NO            means that the new value is not to replace
3574         #                         any existing ones, but any empty gaps of the
3575         #                         range list coinciding with the input range
3576         #                         will be filled in with the new value.
3577         #       => $UNCONDITIONALLY  means to replace the existing values with
3578         #                         this one unconditionally.  However, if the
3579         #                         new and old values are identical, the
3580         #                         replacement is skipped to save cycles
3581         #       => $IF_NOT_EQUIVALENT means to replace the existing values
3582         #          (the default)  with this one if they are not equivalent.
3583         #                         Ranges are equivalent if their types are the
3584         #                         same, and they are the same string; or if
3585         #                         both are type 0 ranges, if their Unicode
3586         #                         standard forms are identical.  In this last
3587         #                         case, the routine chooses the more "modern"
3588         #                         one to use.  This is because some of the
3589         #                         older files are formatted with values that
3590         #                         are, for example, ALL CAPs, whereas the
3591         #                         derived files have a more modern style,
3592         #                         which looks better.  By looking for this
3593         #                         style when the pre-existing and replacement
3594         #                         standard forms are the same, we can move to
3595         #                         the modern style
3596         #       => $MULTIPLE_BEFORE means that if this range duplicates an
3597         #                         existing one, but has a different value,
3598         #                         don't replace the existing one, but insert
3599         #                         this, one so that the same range can occur
3600         #                         multiple times.  They are stored LIFO, so
3601         #                         that the final one inserted is the first one
3602         #                         returned in an ordered search of the table.
3603         #                         If this is an exact duplicate, including the
3604         #                         value, the original will be moved to be
3605         #                         first, before any other duplicate ranges
3606         #                         with different values.
3607         #       => $MULTIPLE_AFTER is like $MULTIPLE_BEFORE, but is stored
3608         #                         FIFO, so that this one is inserted after all
3609         #                         others that currently exist.  If this is an
3610         #                         exact duplicate, including value, of an
3611         #                         existing range, this one is discarded
3612         #                         (leaving the existing one in its original,
3613         #                         higher priority position
3614         #       => anything else  is the same as => $IF_NOT_EQUIVALENT
3615         #
3616         # "same value" means identical for non-type-0 ranges, and it means
3617         # having the same standard forms for type-0 ranges.
3618
3619         return Carp::carp_too_few_args(\@_, 5) if main::DEBUG && @_ < 5;
3620
3621         my $self = shift;
3622         my $operation = shift;   # '+' for add/replace; '-' for delete;
3623         my $start = shift;
3624         my $end   = shift;
3625         my $value = shift;
3626
3627         my %args = @_;
3628
3629         $value = "" if not defined $value;        # warning: $value can be "0"
3630
3631         my $replace = delete $args{'Replace'};
3632         $replace = $IF_NOT_EQUIVALENT unless defined $replace;
3633
3634         my $type = delete $args{'Type'};
3635         $type = 0 unless defined $type;
3636
3637         Carp::carp_extra_args(\%args) if main::DEBUG && %args;
3638
3639         my $addr = do { no overloading; pack 'J', $self; };
3640
3641         if ($operation ne '+' && $operation ne '-') {
3642             Carp::my_carp_bug("$owner_name_of{$addr}First parameter to _add_delete must be '+' or '-'.  No action taken.");
3643             return;
3644         }
3645         unless (defined $start && defined $end) {
3646             Carp::my_carp_bug("$owner_name_of{$addr}Undefined start and/or end to _add_delete.  No action taken.");
3647             return;
3648         }
3649         unless ($end >= $start) {
3650             Carp::my_carp_bug("$owner_name_of{$addr}End of range (" . sprintf("%04X", $end) . ") must not be before start (" . sprintf("%04X", $start) . ").  No action taken.");
3651             return;
3652         }
3653         if ($end > $MAX_UNICODE_CODEPOINT && $operation eq '+') {
3654             Carp::my_carp("$owner_name_of{$addr}Warning: Range '" . sprintf("%04X..%04X", $start, $end) . ") is above the Unicode maximum of " . sprintf("%04X", $MAX_UNICODE_CODEPOINT) . ".  Adding it anyway");
3655         }
3656         #local $to_trace = 1 if main::DEBUG;
3657
3658         if ($operation eq '-') {
3659             if ($replace != $IF_NOT_EQUIVALENT) {
3660                 Carp::my_carp_bug("$owner_name_of{$addr}Replace => \$IF_NOT_EQUIVALENT is required when deleting a range from a range list.  Assuming Replace => \$IF_NOT_EQUIVALENT.");
3661                 $replace = $IF_NOT_EQUIVALENT;
3662             }
3663             if ($type) {
3664                 Carp::my_carp_bug("$owner_name_of{$addr}Type => 0 is required when deleting a range from a range list.  Assuming Type => 0.");
3665                 $type = 0;
3666             }
3667             if ($value ne "") {
3668                 Carp::my_carp_bug("$owner_name_of{$addr}Value => \"\" is required when deleting a range from a range list.  Assuming Value => \"\".");
3669                 $value = "";
3670             }
3671         }
3672
3673         my $r = $ranges{$addr};               # The current list of ranges
3674         my $range_list_size = scalar @$r;     # And its size
3675         my $max = $max{$addr};                # The current high code point in
3676                                               # the list of ranges
3677
3678         # Do a special case requiring fewer machine cycles when the new range
3679         # starts after the current highest point.  The Unicode input data is
3680         # structured so this is common.
3681         if ($start > $max) {
3682
3683             trace "$owner_name_of{$addr} $operation", sprintf("%04X..%04X (%s) type=%d; prev max=%04X", $start, $end, $value, $type, $max) if main::DEBUG && $to_trace;
3684             return if $operation eq '-'; # Deleting a non-existing range is a
3685                                          # no-op
3686
3687             # If the new range doesn't logically extend the current final one
3688             # in the range list, create a new range at the end of the range
3689             # list.  (max cleverly is initialized to a negative number not
3690             # adjacent to 0 if the range list is empty, so even adding a range
3691             # to an empty range list starting at 0 will have this 'if'
3692             # succeed.)
3693             if ($start > $max + 1        # non-adjacent means can't extend.
3694                 || @{$r}[-1]->value ne $value # values differ, can't extend.
3695                 || @{$r}[-1]->type != $type # types differ, can't extend.
3696             ) {
3697                 push @$r, Range->new($start, $end,
3698                                      Value => $value,
3699                                      Type => $type);
3700             }
3701             else {
3702
3703                 # Here, the new range starts just after the current highest in
3704                 # the range list, and they have the same type and value.
3705                 # Extend the current range to incorporate the new one.
3706                 @{$r}[-1]->set_end($end);
3707             }
3708
3709             # This becomes the new maximum.
3710             $max{$addr} = $end;
3711
3712             return;
3713         }
3714         #local $to_trace = 0 if main::DEBUG;
3715
3716         trace "$owner_name_of{$addr} $operation", sprintf("%04X", $start) . '..' . sprintf("%04X", $end) . " ($value) replace=$replace" if main::DEBUG && $to_trace;
3717
3718         # Here, the input range isn't after the whole rest of the range list.
3719         # Most likely 'splice' will be needed.  The rest of the routine finds
3720         # the needed splice parameters, and if necessary, does the splice.
3721         # First, find the offset parameter needed by the splice function for
3722         # the input range.  Note that the input range may span multiple
3723         # existing ones, but we'll worry about that later.  For now, just find
3724         # the beginning.  If the input range is to be inserted starting in a
3725         # position not currently in the range list, it must (obviously) come
3726         # just after the range below it, and just before the range above it.
3727         # Slightly less obviously, it will occupy the position currently
3728         # occupied by the range that is to come after it.  More formally, we
3729         # are looking for the position, $i, in the array of ranges, such that:
3730         #
3731         # r[$i-1]->start <= r[$i-1]->end < $start < r[$i]->start <= r[$i]->end
3732         #
3733         # (The ordered relationships within existing ranges are also shown in
3734         # the equation above).  However, if the start of the input range is
3735         # within an existing range, the splice offset should point to that
3736         # existing range's position in the list; that is $i satisfies a
3737         # somewhat different equation, namely:
3738         #
3739         #r[$i-1]->start <= r[$i-1]->end < r[$i]->start <= $start <= r[$i]->end
3740         #
3741         # More briefly, $start can come before or after r[$i]->start, and at
3742         # this point, we don't know which it will be.  However, these
3743         # two equations share these constraints:
3744         #
3745         #   r[$i-1]->end < $start <= r[$i]->end
3746         #
3747         # And that is good enough to find $i.
3748
3749         my $i = $self->_search_ranges($start);
3750         if (! defined $i) {
3751             Carp::my_carp_bug("Searching $self for range beginning with $start unexpectedly returned undefined.  Operation '$operation' not performed");
3752             return;
3753         }
3754
3755         # The search function returns $i such that:
3756         #
3757         # r[$i-1]->end < $start <= r[$i]->end
3758         #
3759         # That means that $i points to the first range in the range list
3760         # that could possibly be affected by this operation.  We still don't
3761         # know if the start of the input range is within r[$i], or if it
3762         # points to empty space between r[$i-1] and r[$i].
3763         trace "[$i] is the beginning splice point.  Existing range there is ", $r->[$i] if main::DEBUG && $to_trace;
3764
3765         # Special case the insertion of data that is not to replace any
3766         # existing data.
3767         if ($replace == $NO) {  # If $NO, has to be operation '+'
3768             #local $to_trace = 1 if main::DEBUG;
3769             trace "Doesn't replace" if main::DEBUG && $to_trace;
3770
3771             # Here, the new range is to take effect only on those code points
3772             # that aren't already in an existing range.  This can be done by
3773             # looking through the existing range list and finding the gaps in
3774             # the ranges that this new range affects, and then calling this
3775             # function recursively on each of those gaps, leaving untouched
3776             # anything already in the list.  Gather up a list of the changed
3777             # gaps first so that changes to the internal state as new ranges
3778             # are added won't be a problem.
3779             my @gap_list;
3780
3781             # First, if the starting point of the input range is outside an
3782             # existing one, there is a gap from there to the beginning of the
3783             # existing range -- add a span to fill the part that this new
3784             # range occupies
3785             if ($start < $r->[$i]->start) {
3786                 push @gap_list, Range->new($start,
3787                                            main::min($end,
3788                                                      $r->[$i]->start - 1),
3789                                            Type => $type);
3790                 trace "gap before $r->[$i] [$i], will add", $gap_list[-1] if main::DEBUG && $to_trace;
3791             }
3792
3793             # Then look through the range list for other gaps until we reach
3794             # the highest range affected by the input one.
3795             my $j;
3796             for ($j = $i+1; $j < $range_list_size; $j++) {
3797                 trace "j=[$j]", $r->[$j] if main::DEBUG && $to_trace;
3798                 last if $end < $r->[$j]->start;
3799
3800                 # If there is a gap between when this range starts and the
3801                 # previous one ends, add a span to fill it.  Note that just
3802                 # because there are two ranges doesn't mean there is a
3803                 # non-zero gap between them.  It could be that they have
3804                 # different values or types
3805                 if ($r->[$j-1]->end + 1 != $r->[$j]->start) {
3806                     push @gap_list,
3807                         Range->new($r->[$j-1]->end + 1,
3808                                    $r->[$j]->start - 1,
3809                                    Type => $type);
3810                     trace "gap between $r->[$j-1] and $r->[$j] [$j], will add: $gap_list[-1]" if main::DEBUG && $to_trace;
3811                 }
3812             }
3813
3814             # Here, we have either found an existing range in the range list,
3815             # beyond the area affected by the input one, or we fell off the
3816             # end of the loop because the input range affects the whole rest
3817             # of the range list.  In either case, $j is 1 higher than the
3818             # highest affected range.  If $j == $i, it means that there are no
3819             # affected ranges, that the entire insertion is in the gap between
3820             # r[$i-1], and r[$i], which we already have taken care of before
3821             # the loop.
3822             # On the other hand, if there are affected ranges, it might be
3823             # that there is a gap that needs filling after the final such
3824             # range to the end of the input range
3825             if ($r->[$j-1]->end < $end) {
3826                     push @gap_list, Range->new(main::max($start,
3827                                                          $r->[$j-1]->end + 1),
3828                                                $end,
3829                                                Type => $type);
3830                     trace "gap after $r->[$j-1], will add $gap_list[-1]" if main::DEBUG && $to_trace;
3831             }
3832
3833             # Call recursively to fill in all the gaps.
3834             foreach my $gap (@gap_list) {
3835                 $self->_add_delete($operation,
3836                                    $gap->start,
3837                                    $gap->end,
3838                                    $value,
3839                                    Type => $type);
3840             }
3841
3842             return;
3843         }
3844
3845         # Here, we have taken care of the case where $replace is $NO.
3846         # Remember that here, r[$i-1]->end < $start <= r[$i]->end
3847         # If inserting a multiple record, this is where it goes, before the
3848         # first (if any) existing one if inserting LIFO.  (If this is to go
3849         # afterwards, FIFO, we below move the pointer to there.)  These imply
3850         # an insertion, and no change to any existing ranges.  Note that $i
3851         # can be -1 if this new range doesn't actually duplicate any existing,
3852         # and comes at the beginning of the list.
3853         if ($replace == $MULTIPLE_BEFORE || $replace == $MULTIPLE_AFTER) {
3854
3855             if ($start != $end) {
3856                 Carp::my_carp_bug("$owner_name_of{$addr}Can't cope with adding a multiple record when the range ($start..$end) contains more than one code point.  No action taken.");
3857                 return;
3858             }
3859
3860             # If the new code point is within a current range ...
3861             if ($end >= $r->[$i]->start) {
3862
3863                 # Don't add an exact duplicate, as it isn't really a multiple
3864                 my $existing_value = $r->[$i]->value;
3865                 my $existing_type = $r->[$i]->type;
3866                 return if $value eq $existing_value && $type eq $existing_type;
3867
3868                 # If the multiple value is part of an existing range, we want
3869                 # to split up that range, so that only the single code point
3870                 # is affected.  To do this, we first call ourselves
3871                 # recursively to delete that code point from the table, having
3872                 # preserved its current data above.  Then we call ourselves
3873                 # recursively again to add the new multiple, which we know by
3874                 # the test just above is different than the current code
3875                 # point's value, so it will become a range containing a single
3876                 # code point: just itself.  Finally, we add back in the
3877                 # pre-existing code point, which will again be a single code
3878                 # point range.  Because 'i' likely will have changed as a
3879                 # result of these operations, we can't just continue on, but
3880                 # do this operation recursively as well.  If we are inserting
3881                 # LIFO, the pre-existing code point needs to go after the new
3882                 # one, so use MULTIPLE_AFTER; and vice versa.
3883                 if ($r->[$i]->start != $r->[$i]->end) {
3884                     $self->_add_delete('-', $start, $end, "");
3885                     $self->_add_delete('+', $start, $end, $value, Type => $type);
3886                     return $self->_add_delete('+',
3887                             $start, $end,
3888                             $existing_value,
3889                             Type => $existing_type,
3890                             Replace => ($replace == $MULTIPLE_BEFORE)
3891                                        ? $MULTIPLE_AFTER
3892                                        : $MULTIPLE_BEFORE);
3893                 }
3894             }
3895
3896             # If to place this new record after, move to beyond all existing
3897             # ones; but don't add this one if identical to any of them, as it
3898             # isn't really a multiple.  This leaves the original order, so
3899             # that the current request is ignored.  The reasoning is that the
3900             # previous request that wanted this record to have high priority
3901             # should have precedence.
3902             if ($replace == $MULTIPLE_AFTER) {
3903                 while ($i < @$r && $r->[$i]->start == $start) {
3904                     return if $value eq $r->[$i]->value
3905                               && $type eq $r->[$i]->type;
3906                     $i++;
3907                 }
3908             }
3909             else {
3910                 # If instead we are to place this new record before any
3911                 # existing ones, remove any identical ones that come after it.
3912                 # This changes the existing order so that the new one is
3913                 # first, as is being requested.
3914                 for (my $j = $i + 1;
3915                      $j < @$r && $r->[$j]->start == $start;
3916                      $j++)
3917                 {
3918                     if ($value eq $r->[$j]->value && $type eq $r->[$j]->type) {
3919                         splice @$r, $j, 1;
3920                         last;   # There should only be one instance, so no
3921                                 # need to keep looking
3922                     }
3923                 }
3924             }
3925
3926             trace "Adding multiple record at $i with $start..$end, $value" if main::DEBUG && $to_trace;
3927             my @return = splice @$r,
3928                                 $i,
3929                                 0,
3930                                 Range->new($start,
3931                                            $end,
3932                                            Value => $value,
3933                                            Type => $type);
3934             if (main::DEBUG && $to_trace) {
3935                 trace "After splice:";
3936                 trace 'i-2=[', $i-2, ']', $r->[$i-2] if $i >= 2;
3937                 trace 'i-1=[', $i-1, ']', $r->[$i-1] if $i >= 1;
3938                 trace "i  =[", $i, "]", $r->[$i] if $i >= 0;
3939                 trace 'i+1=[', $i+1, ']', $r->[$i+1] if $i < @$r - 1;
3940                 trace 'i+2=[', $i+2, ']', $r->[$i+2] if $i < @$r - 2;
3941                 trace 'i+3=[', $i+3, ']', $r->[$i+3] if $i < @$r - 3;
3942             }
3943             return @return;
3944         }
3945
3946         # Here, we have taken care of $NO and $MULTIPLE_foo replaces.  This
3947         # leaves delete, insert, and replace either unconditionally or if not
3948         # equivalent.  $i still points to the first potential affected range.
3949         # Now find the highest range affected, which will determine the length
3950         # parameter to splice.  (The input range can span multiple existing
3951         # ones.)  If this isn't a deletion, while we are looking through the
3952         # range list, see also if this is a replacement rather than a clean
3953         # insertion; that is if it will change the values of at least one
3954         # existing range.  Start off assuming it is an insert, until find it
3955         # isn't.
3956         my $clean_insert = $operation eq '+';
3957         my $j;        # This will point to the highest affected range
3958
3959         # For non-zero types, the standard form is the value itself;
3960         my $standard_form = ($type) ? $value : main::standardize($value);
3961
3962         for ($j = $i; $j < $range_list_size; $j++) {
3963             trace "Looking for highest affected range; the one at $j is ", $r->[$j] if main::DEBUG && $to_trace;
3964
3965             # If find a range that it doesn't overlap into, we can stop
3966             # searching
3967             last if $end < $r->[$j]->start;
3968
3969             # Here, overlaps the range at $j.  If the values don't match,
3970             # and so far we think this is a clean insertion, it becomes a
3971             # non-clean insertion, i.e., a 'change' or 'replace' instead.
3972             if ($clean_insert) {
3973                 if ($r->[$j]->standard_form ne $standard_form) {
3974                     $clean_insert = 0;
3975                     if ($replace == $CROAK) {
3976                         main::croak("The range to add "
3977                         . sprintf("%04X", $start)
3978                         . '-'
3979                         . sprintf("%04X", $end)
3980                         . " with value '$value' overlaps an existing range $r->[$j]");
3981                     }
3982                 }
3983                 else {
3984
3985                     # Here, the two values are essentially the same.  If the
3986                     # two are actually identical, replacing wouldn't change
3987                     # anything so skip it.
3988                     my $pre_existing = $r->[$j]->value;
3989                     if ($pre_existing ne $value) {
3990
3991                         # Here the new and old standardized values are the
3992                         # same, but the non-standardized values aren't.  If
3993                         # replacing unconditionally, then replace
3994                         if( $replace == $UNCONDITIONALLY) {