This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Re: [perl #24071] Typo in description of binmode
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 For more information see L<perlipc>.
433
434 =item atan2 Y,X
435
436 Returns the arctangent of Y/X in the range -PI to PI.
437
438 For the tangent operation, you may use the C<Math::Trig::tan>
439 function, or use the familiar relation:
440
441     sub tan { sin($_[0]) / cos($_[0])  }
442
443 =item bind SOCKET,NAME
444
445 Binds a network address to a socket, just as the bind system call
446 does.  Returns true if it succeeded, false otherwise.  NAME should be a
447 packed address of the appropriate type for the socket.  See the examples in
448 L<perlipc/"Sockets: Client/Server Communication">.
449
450 =item binmode FILEHANDLE, LAYER
451
452 =item binmode FILEHANDLE
453
454 Arranges for FILEHANDLE to be read or written in "binary" or "text"
455 mode on systems where the run-time libraries distinguish between
456 binary and text files.  If FILEHANDLE is an expression, the value is
457 taken as the name of the filehandle.  Returns true on success,
458 otherwise it returns C<undef> and sets C<$!> (errno).
459
460 On some systems (in general, DOS and Windows-based systems) binmode()
461 is necessary when you're not working with a text file.  For the sake
462 of portability it is a good idea to always use it when appropriate,
463 and to never use it when it isn't appropriate.  Also, people can
464 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
465
466 In other words: regardless of platform, use binmode() on binary data,
467 like for example images.
468
469 If LAYER is present it is a single string, but may contain multiple
470 directives. The directives alter the behaviour of the file handle.
471 When LAYER is present using binmode on text file makes sense.
472
473 If LAYER is omitted or specified as C<:raw> the filehandle is made
474 suitable for passing binary data. This includes turning off possible CRLF
475 translation and marking it as bytes (as opposed to Unicode characters).
476 Note that, despite what may be implied in I<"Programming Perl"> (the
477 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
478 -- other layers which would affect binary nature of the stream are
479 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
480 PERLIO environment variable.
481
482 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
483 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
484 establish default I/O layers.  See L<open>.
485
486 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
487 in "Programming Perl, 3rd Edition".  However, since the publishing of this
488 book, by many known as "Camel III", the consensus of the naming of this
489 functionality has moved from "discipline" to "layer".  All documentation
490 of this version of Perl therefore refers to "layers" rather than to
491 "disciplines".  Now back to the regularly scheduled documentation...>
492
493 To mark FILEHANDLE as UTF-8, use C<:utf8>.
494
495 In general, binmode() should be called after open() but before any I/O
496 is done on the filehandle.  Calling binmode() will normally flush any
497 pending buffered output data (and perhaps pending input data) on the
498 handle.  An exception to this is the C<:encoding> layer that
499 changes the default character encoding of the handle, see L<open>.
500 The C<:encoding> layer sometimes needs to be called in
501 mid-stream, and it doesn't flush the stream.  The C<:encoding>
502 also implicitly pushes on top of itself the C<:utf8> layer because
503 internally Perl will operate on UTF-8 encoded Unicode characters.
504
505 The operating system, device drivers, C libraries, and Perl run-time
506 system all work together to let the programmer treat a single
507 character (C<\n>) as the line terminator, irrespective of the external
508 representation.  On many operating systems, the native text file
509 representation matches the internal representation, but on some
510 platforms the external representation of C<\n> is made up of more than
511 one character.
512
513 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
514 character to end each line in the external representation of text (even
515 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
516 on Unix and most VMS files). In other systems like OS/2, DOS and the
517 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
518 but what's stored in text files are the two characters C<\cM\cJ>.  That
519 means that, if you don't use binmode() on these systems, C<\cM\cJ>
520 sequences on disk will be converted to C<\n> on input, and any C<\n> in
521 your program will be converted back to C<\cM\cJ> on output.  This is what
522 you want for text files, but it can be disastrous for binary files.
523
524 Another consequence of using binmode() (on some systems) is that
525 special end-of-file markers will be seen as part of the data stream.
526 For systems from the Microsoft family this means that if your binary
527 data contains C<\cZ>, the I/O subsystem will regard it as the end of
528 the file, unless you use binmode().
529
530 binmode() is not only important for readline() and print() operations,
531 but also when using read(), seek(), sysread(), syswrite() and tell()
532 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
533 in L<perlvar> for how to manually set your input and output
534 line-termination sequences.
535
536 =item bless REF,CLASSNAME
537
538 =item bless REF
539
540 This function tells the thingy referenced by REF that it is now an object
541 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
542 is used.  Because a C<bless> is often the last thing in a constructor,
543 it returns the reference for convenience.  Always use the two-argument
544 version if the function doing the blessing might be inherited by a
545 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
546 (and blessings) of objects.
547
548 Consider always blessing objects in CLASSNAMEs that are mixed case.
549 Namespaces with all lowercase names are considered reserved for
550 Perl pragmata.  Builtin types have all uppercase names, so to prevent
551 confusion, you may wish to avoid such package names as well.  Make sure
552 that CLASSNAME is a true value.
553
554 See L<perlmod/"Perl Modules">.
555
556 =item caller EXPR
557
558 =item caller
559
560 Returns the context of the current subroutine call.  In scalar context,
561 returns the caller's package name if there is a caller, that is, if
562 we're in a subroutine or C<eval> or C<require>, and the undefined value
563 otherwise.  In list context, returns
564
565     ($package, $filename, $line) = caller;
566
567 With EXPR, it returns some extra information that the debugger uses to
568 print a stack trace.  The value of EXPR indicates how many call frames
569 to go back before the current one.
570
571     ($package, $filename, $line, $subroutine, $hasargs,
572     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
573
574 Here $subroutine may be C<(eval)> if the frame is not a subroutine
575 call, but an C<eval>.  In such a case additional elements $evaltext and
576 C<$is_require> are set: C<$is_require> is true if the frame is created by a
577 C<require> or C<use> statement, $evaltext contains the text of the
578 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
579 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
580 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
581 frame.)  $subroutine may also be C<(unknown)> if this particular
582 subroutine happens to have been deleted from the symbol table.
583 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
584 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
585 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
586 between versions of Perl, and are not meant for external use.
587
588 Furthermore, when called from within the DB package, caller returns more
589 detailed information: it sets the list variable C<@DB::args> to be the
590 arguments with which the subroutine was invoked.
591
592 Be aware that the optimizer might have optimized call frames away before
593 C<caller> had a chance to get the information.  That means that C<caller(N)>
594 might not return information about the call frame you expect it do, for
595 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
596 previous time C<caller> was called.
597
598 =item chdir EXPR
599
600 Changes the working directory to EXPR, if possible. If EXPR is omitted,
601 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
602 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
603 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
604 neither is set, C<chdir> does nothing. It returns true upon success,
605 false otherwise. See the example under C<die>.
606
607 =item chmod LIST
608
609 Changes the permissions of a list of files.  The first element of the
610 list must be the numerical mode, which should probably be an octal
611 number, and which definitely should I<not> a string of octal digits:
612 C<0644> is okay, C<'0644'> is not.  Returns the number of files
613 successfully changed.  See also L</oct>, if all you have is a string.
614
615     $cnt = chmod 0755, 'foo', 'bar';
616     chmod 0755, @executables;
617     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
618                                              # --w----r-T
619     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
620     $mode = 0644;   chmod $mode, 'foo';      # this is best
621
622 You can also import the symbolic C<S_I*> constants from the Fcntl
623 module:
624
625     use Fcntl ':mode';
626
627     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
628     # This is identical to the chmod 0755 of the above example.
629
630 =item chomp VARIABLE
631
632 =item chomp( LIST )
633
634 =item chomp
635
636 This safer version of L</chop> removes any trailing string
637 that corresponds to the current value of C<$/> (also known as
638 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
639 number of characters removed from all its arguments.  It's often used to
640 remove the newline from the end of an input record when you're worried
641 that the final record may be missing its newline.  When in paragraph
642 mode (C<$/ = "">), it removes all trailing newlines from the string.
643 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
644 a reference to an integer or the like, see L<perlvar>) chomp() won't
645 remove anything.
646 If VARIABLE is omitted, it chomps C<$_>.  Example:
647
648     while (<>) {
649         chomp;  # avoid \n on last field
650         @array = split(/:/);
651         # ...
652     }
653
654 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
655
656 You can actually chomp anything that's an lvalue, including an assignment:
657
658     chomp($cwd = `pwd`);
659     chomp($answer = <STDIN>);
660
661 If you chomp a list, each element is chomped, and the total number of
662 characters removed is returned.
663
664 Note that parentheses are necessary when you're chomping anything
665 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
666 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
667 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
668 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
669 as C<chomp($a, $b)>.
670
671 =item chop VARIABLE
672
673 =item chop( LIST )
674
675 =item chop
676
677 Chops off the last character of a string and returns the character
678 chopped.  It is much more efficient than C<s/.$//s> because it neither
679 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
680 If VARIABLE is a hash, it chops the hash's values, but not its keys.
681
682 You can actually chop anything that's an lvalue, including an assignment.
683
684 If you chop a list, each element is chopped.  Only the value of the
685 last C<chop> is returned.
686
687 Note that C<chop> returns the last character.  To return all but the last
688 character, use C<substr($string, 0, -1)>.
689
690 See also L</chomp>.
691
692 =item chown LIST
693
694 Changes the owner (and group) of a list of files.  The first two
695 elements of the list must be the I<numeric> uid and gid, in that
696 order.  A value of -1 in either position is interpreted by most
697 systems to leave that value unchanged.  Returns the number of files
698 successfully changed.
699
700     $cnt = chown $uid, $gid, 'foo', 'bar';
701     chown $uid, $gid, @filenames;
702
703 Here's an example that looks up nonnumeric uids in the passwd file:
704
705     print "User: ";
706     chomp($user = <STDIN>);
707     print "Files: ";
708     chomp($pattern = <STDIN>);
709
710     ($login,$pass,$uid,$gid) = getpwnam($user)
711         or die "$user not in passwd file";
712
713     @ary = glob($pattern);      # expand filenames
714     chown $uid, $gid, @ary;
715
716 On most systems, you are not allowed to change the ownership of the
717 file unless you're the superuser, although you should be able to change
718 the group to any of your secondary groups.  On insecure systems, these
719 restrictions may be relaxed, but this is not a portable assumption.
720 On POSIX systems, you can detect this condition this way:
721
722     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
723     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
724
725 =item chr NUMBER
726
727 =item chr
728
729 Returns the character represented by that NUMBER in the character set.
730 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
731 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
732 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
733 backward compatibility reasons (but see L<encoding>).
734
735 If NUMBER is omitted, uses C<$_>.
736
737 For the reverse, use L</ord>.
738
739 Note that under the C<bytes> pragma the NUMBER is masked to
740 the low eight bits.
741
742 See L<perlunicode> and L<encoding> for more about Unicode.
743
744 =item chroot FILENAME
745
746 =item chroot
747
748 This function works like the system call by the same name: it makes the
749 named directory the new root directory for all further pathnames that
750 begin with a C</> by your process and all its children.  (It doesn't
751 change your current working directory, which is unaffected.)  For security
752 reasons, this call is restricted to the superuser.  If FILENAME is
753 omitted, does a C<chroot> to C<$_>.
754
755 =item close FILEHANDLE
756
757 =item close
758
759 Closes the file or pipe associated with the file handle, returning
760 true only if IO buffers are successfully flushed and closes the system
761 file descriptor.  Closes the currently selected filehandle if the
762 argument is omitted.
763
764 You don't have to close FILEHANDLE if you are immediately going to do
765 another C<open> on it, because C<open> will close it for you.  (See
766 C<open>.)  However, an explicit C<close> on an input file resets the line
767 counter (C<$.>), while the implicit close done by C<open> does not.
768
769 If the file handle came from a piped open C<close> will additionally
770 return false if one of the other system calls involved fails or if the
771 program exits with non-zero status.  (If the only problem was that the
772 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
773 also waits for the process executing on the pipe to complete, in case you
774 want to look at the output of the pipe afterwards, and
775 implicitly puts the exit status value of that command into C<$?>.
776
777 Prematurely closing the read end of a pipe (i.e. before the process
778 writing to it at the other end has closed it) will result in a
779 SIGPIPE being delivered to the writer.  If the other end can't
780 handle that, be sure to read all the data before closing the pipe.
781
782 Example:
783
784     open(OUTPUT, '|sort >foo')  # pipe to sort
785         or die "Can't start sort: $!";
786     #...                        # print stuff to output
787     close OUTPUT                # wait for sort to finish
788         or warn $! ? "Error closing sort pipe: $!"
789                    : "Exit status $? from sort";
790     open(INPUT, 'foo')          # get sort's results
791         or die "Can't open 'foo' for input: $!";
792
793 FILEHANDLE may be an expression whose value can be used as an indirect
794 filehandle, usually the real filehandle name.
795
796 =item closedir DIRHANDLE
797
798 Closes a directory opened by C<opendir> and returns the success of that
799 system call.
800
801 =item connect SOCKET,NAME
802
803 Attempts to connect to a remote socket, just as the connect system call
804 does.  Returns true if it succeeded, false otherwise.  NAME should be a
805 packed address of the appropriate type for the socket.  See the examples in
806 L<perlipc/"Sockets: Client/Server Communication">.
807
808 =item continue BLOCK
809
810 Actually a flow control statement rather than a function.  If there is a
811 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
812 C<foreach>), it is always executed just before the conditional is about to
813 be evaluated again, just like the third part of a C<for> loop in C.  Thus
814 it can be used to increment a loop variable, even when the loop has been
815 continued via the C<next> statement (which is similar to the C C<continue>
816 statement).
817
818 C<last>, C<next>, or C<redo> may appear within a C<continue>
819 block.  C<last> and C<redo> will behave as if they had been executed within
820 the main block.  So will C<next>, but since it will execute a C<continue>
821 block, it may be more entertaining.
822
823     while (EXPR) {
824         ### redo always comes here
825         do_something;
826     } continue {
827         ### next always comes here
828         do_something_else;
829         # then back the top to re-check EXPR
830     }
831     ### last always comes here
832
833 Omitting the C<continue> section is semantically equivalent to using an
834 empty one, logically enough.  In that case, C<next> goes directly back
835 to check the condition at the top of the loop.
836
837 =item cos EXPR
838
839 =item cos
840
841 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
842 takes cosine of C<$_>.
843
844 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
845 function, or use this relation:
846
847     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
848
849 =item crypt PLAINTEXT,SALT
850
851 Encrypts a string exactly like the crypt(3) function in the C library
852 (assuming that you actually have a version there that has not been
853 extirpated as a potential munition).  This can prove useful for checking
854 the password file for lousy passwords, amongst other things.  Only the
855 guys wearing white hats should do this.
856
857 Note that L<crypt|/crypt> is intended to be a one-way function, much like
858 breaking eggs to make an omelette.  There is no (known) corresponding
859 decrypt function (in other words, the crypt() is a one-way hash
860 function).  As a result, this function isn't all that useful for
861 cryptography.  (For that, see your nearby CPAN mirror.)
862
863 When verifying an existing encrypted string you should use the
864 encrypted text as the salt (like C<crypt($plain, $crypted) eq
865 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
866 and with more exotic implementations.  In other words, do not assume
867 anything about the returned string itself, or how many bytes in
868 the encrypted string matter.
869
870 Traditionally the result is a string of 13 bytes: two first bytes of
871 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
872 the first eight bytes of the encrypted string mattered, but
873 alternative hashing schemes (like MD5), higher level security schemes
874 (like C2), and implementations on non-UNIX platforms may produce
875 different strings.
876
877 When choosing a new salt create a random two character string whose
878 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
879 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
880 characters is just a recommendation; the characters allowed in
881 the salt depend solely on your system's crypt library, and Perl can't
882 restrict what salts C<crypt()> accepts.
883
884 Here's an example that makes sure that whoever runs this program knows
885 their own password:
886
887     $pwd = (getpwuid($<))[1];
888
889     system "stty -echo";
890     print "Password: ";
891     chomp($word = <STDIN>);
892     print "\n";
893     system "stty echo";
894
895     if (crypt($word, $pwd) ne $pwd) {
896         die "Sorry...\n";
897     } else {
898         print "ok\n";
899     }
900
901 Of course, typing in your own password to whoever asks you
902 for it is unwise.
903
904 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
905 of data, not least of all because you can't get the information
906 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
907 on your favorite CPAN mirror for a slew of potentially useful
908 modules.
909
910 If using crypt() on a Unicode string (which I<potentially> has
911 characters with codepoints above 255), Perl tries to make sense
912 of the situation by trying to downgrade (a copy of the string)
913 the string back to an eight-bit byte string before calling crypt()
914 (on that copy).  If that works, good.  If not, crypt() dies with
915 C<Wide character in crypt>.
916
917 =item dbmclose HASH
918
919 [This function has been largely superseded by the C<untie> function.]
920
921 Breaks the binding between a DBM file and a hash.
922
923 =item dbmopen HASH,DBNAME,MASK
924
925 [This function has been largely superseded by the C<tie> function.]
926
927 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
928 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
929 argument is I<not> a filehandle, even though it looks like one).  DBNAME
930 is the name of the database (without the F<.dir> or F<.pag> extension if
931 any).  If the database does not exist, it is created with protection
932 specified by MASK (as modified by the C<umask>).  If your system supports
933 only the older DBM functions, you may perform only one C<dbmopen> in your
934 program.  In older versions of Perl, if your system had neither DBM nor
935 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
936 sdbm(3).
937
938 If you don't have write access to the DBM file, you can only read hash
939 variables, not set them.  If you want to test whether you can write,
940 either use file tests or try setting a dummy hash entry inside an C<eval>,
941 which will trap the error.
942
943 Note that functions such as C<keys> and C<values> may return huge lists
944 when used on large DBM files.  You may prefer to use the C<each>
945 function to iterate over large DBM files.  Example:
946
947     # print out history file offsets
948     dbmopen(%HIST,'/usr/lib/news/history',0666);
949     while (($key,$val) = each %HIST) {
950         print $key, ' = ', unpack('L',$val), "\n";
951     }
952     dbmclose(%HIST);
953
954 See also L<AnyDBM_File> for a more general description of the pros and
955 cons of the various dbm approaches, as well as L<DB_File> for a particularly
956 rich implementation.
957
958 You can control which DBM library you use by loading that library
959 before you call dbmopen():
960
961     use DB_File;
962     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
963         or die "Can't open netscape history file: $!";
964
965 =item defined EXPR
966
967 =item defined
968
969 Returns a Boolean value telling whether EXPR has a value other than
970 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
971 checked.
972
973 Many operations return C<undef> to indicate failure, end of file,
974 system error, uninitialized variable, and other exceptional
975 conditions.  This function allows you to distinguish C<undef> from
976 other values.  (A simple Boolean test will not distinguish among
977 C<undef>, zero, the empty string, and C<"0">, which are all equally
978 false.)  Note that since C<undef> is a valid scalar, its presence
979 doesn't I<necessarily> indicate an exceptional condition: C<pop>
980 returns C<undef> when its argument is an empty array, I<or> when the
981 element to return happens to be C<undef>.
982
983 You may also use C<defined(&func)> to check whether subroutine C<&func>
984 has ever been defined.  The return value is unaffected by any forward
985 declarations of C<&func>.  Note that a subroutine which is not defined
986 may still be callable: its package may have an C<AUTOLOAD> method that
987 makes it spring into existence the first time that it is called -- see
988 L<perlsub>.
989
990 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
991 used to report whether memory for that aggregate has ever been
992 allocated.  This behavior may disappear in future versions of Perl.
993 You should instead use a simple test for size:
994
995     if (@an_array) { print "has array elements\n" }
996     if (%a_hash)   { print "has hash members\n"   }
997
998 When used on a hash element, it tells you whether the value is defined,
999 not whether the key exists in the hash.  Use L</exists> for the latter
1000 purpose.
1001
1002 Examples:
1003
1004     print if defined $switch{'D'};
1005     print "$val\n" while defined($val = pop(@ary));
1006     die "Can't readlink $sym: $!"
1007         unless defined($value = readlink $sym);
1008     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1009     $debugging = 0 unless defined $debugging;
1010
1011 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1012 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1013 defined values.  For example, if you say
1014
1015     "ab" =~ /a(.*)b/;
1016
1017 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1018 matched "nothing".  But it didn't really match nothing--rather, it
1019 matched something that happened to be zero characters long.  This is all
1020 very above-board and honest.  When a function returns an undefined value,
1021 it's an admission that it couldn't give you an honest answer.  So you
1022 should use C<defined> only when you're questioning the integrity of what
1023 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1024 what you want.
1025
1026 See also L</undef>, L</exists>, L</ref>.
1027
1028 =item delete EXPR
1029
1030 Given an expression that specifies a hash element, array element, hash slice,
1031 or array slice, deletes the specified element(s) from the hash or array.
1032 In the case of an array, if the array elements happen to be at the end,
1033 the size of the array will shrink to the highest element that tests
1034 true for exists() (or 0 if no such element exists).
1035
1036 Returns each element so deleted or the undefined value if there was no such
1037 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
1038 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1039 from a C<tie>d hash or array may not necessarily return anything.
1040
1041 Deleting an array element effectively returns that position of the array
1042 to its initial, uninitialized state.  Subsequently testing for the same
1043 element with exists() will return false.  Note that deleting array
1044 elements in the middle of an array will not shift the index of the ones
1045 after them down--use splice() for that.  See L</exists>.
1046
1047 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1048
1049     foreach $key (keys %HASH) {
1050         delete $HASH{$key};
1051     }
1052
1053     foreach $index (0 .. $#ARRAY) {
1054         delete $ARRAY[$index];
1055     }
1056
1057 And so do these:
1058
1059     delete @HASH{keys %HASH};
1060
1061     delete @ARRAY[0 .. $#ARRAY];
1062
1063 But both of these are slower than just assigning the empty list
1064 or undefining %HASH or @ARRAY:
1065
1066     %HASH = ();         # completely empty %HASH
1067     undef %HASH;        # forget %HASH ever existed
1068
1069     @ARRAY = ();        # completely empty @ARRAY
1070     undef @ARRAY;       # forget @ARRAY ever existed
1071
1072 Note that the EXPR can be arbitrarily complicated as long as the final
1073 operation is a hash element, array element,  hash slice, or array slice
1074 lookup:
1075
1076     delete $ref->[$x][$y]{$key};
1077     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1078
1079     delete $ref->[$x][$y][$index];
1080     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1081
1082 =item die LIST
1083
1084 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1085 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1086 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1087 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1088 an C<eval(),> the error message is stuffed into C<$@> and the
1089 C<eval> is terminated with the undefined value.  This makes
1090 C<die> the way to raise an exception.
1091
1092 Equivalent examples:
1093
1094     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1095     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1096
1097 If the last element of LIST does not end in a newline, the current
1098 script line number and input line number (if any) are also printed,
1099 and a newline is supplied.  Note that the "input line number" (also
1100 known as "chunk") is subject to whatever notion of "line" happens to
1101 be currently in effect, and is also available as the special variable
1102 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1103
1104 Hint: sometimes appending C<", stopped"> to your message will cause it
1105 to make better sense when the string C<"at foo line 123"> is appended.
1106 Suppose you are running script "canasta".
1107
1108     die "/etc/games is no good";
1109     die "/etc/games is no good, stopped";
1110
1111 produce, respectively
1112
1113     /etc/games is no good at canasta line 123.
1114     /etc/games is no good, stopped at canasta line 123.
1115
1116 See also exit(), warn(), and the Carp module.
1117
1118 If LIST is empty and C<$@> already contains a value (typically from a
1119 previous eval) that value is reused after appending C<"\t...propagated">.
1120 This is useful for propagating exceptions:
1121
1122     eval { ... };
1123     die unless $@ =~ /Expected exception/;
1124
1125 If LIST is empty and C<$@> contains an object reference that has a
1126 C<PROPAGATE> method, that method will be called with additional file
1127 and line number parameters.  The return value replaces the value in
1128 C<$@>.  ie. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1129 were called.
1130
1131 If C<$@> is empty then the string C<"Died"> is used.
1132
1133 die() can also be called with a reference argument.  If this happens to be
1134 trapped within an eval(), $@ contains the reference.  This behavior permits
1135 a more elaborate exception handling implementation using objects that
1136 maintain arbitrary state about the nature of the exception.  Such a scheme
1137 is sometimes preferable to matching particular string values of $@ using
1138 regular expressions.  Here's an example:
1139
1140     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1141     if ($@) {
1142         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1143             # handle Some::Module::Exception
1144         }
1145         else {
1146             # handle all other possible exceptions
1147         }
1148     }
1149
1150 Because perl will stringify uncaught exception messages before displaying
1151 them, you may want to overload stringification operations on such custom
1152 exception objects.  See L<overload> for details about that.
1153
1154 You can arrange for a callback to be run just before the C<die>
1155 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1156 handler will be called with the error text and can change the error
1157 message, if it sees fit, by calling C<die> again.  See
1158 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1159 L<"eval BLOCK"> for some examples.  Although this feature was meant
1160 to be run only right before your program was to exit, this is not
1161 currently the case--the C<$SIG{__DIE__}> hook is currently called
1162 even inside eval()ed blocks/strings!  If one wants the hook to do
1163 nothing in such situations, put
1164
1165         die @_ if $^S;
1166
1167 as the first line of the handler (see L<perlvar/$^S>).  Because
1168 this promotes strange action at a distance, this counterintuitive
1169 behavior may be fixed in a future release.
1170
1171 =item do BLOCK
1172
1173 Not really a function.  Returns the value of the last command in the
1174 sequence of commands indicated by BLOCK.  When modified by a loop
1175 modifier, executes the BLOCK once before testing the loop condition.
1176 (On other statements the loop modifiers test the conditional first.)
1177
1178 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1179 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1180 See L<perlsyn> for alternative strategies.
1181
1182 =item do SUBROUTINE(LIST)
1183
1184 A deprecated form of subroutine call.  See L<perlsub>.
1185
1186 =item do EXPR
1187
1188 Uses the value of EXPR as a filename and executes the contents of the
1189 file as a Perl script.  Its primary use is to include subroutines
1190 from a Perl subroutine library.
1191
1192     do 'stat.pl';
1193
1194 is just like
1195
1196     eval `cat stat.pl`;
1197
1198 except that it's more efficient and concise, keeps track of the current
1199 filename for error messages, searches the @INC libraries, and updates
1200 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1201 variables.  It also differs in that code evaluated with C<do FILENAME>
1202 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1203 same, however, in that it does reparse the file every time you call it,
1204 so you probably don't want to do this inside a loop.
1205
1206 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1207 error.  If C<do> can read the file but cannot compile it, it
1208 returns undef and sets an error message in C<$@>.   If the file is
1209 successfully compiled, C<do> returns the value of the last expression
1210 evaluated.
1211
1212 Note that inclusion of library modules is better done with the
1213 C<use> and C<require> operators, which also do automatic error checking
1214 and raise an exception if there's a problem.
1215
1216 You might like to use C<do> to read in a program configuration
1217 file.  Manual error checking can be done this way:
1218
1219     # read in config files: system first, then user
1220     for $file ("/share/prog/defaults.rc",
1221                "$ENV{HOME}/.someprogrc")
1222    {
1223         unless ($return = do $file) {
1224             warn "couldn't parse $file: $@" if $@;
1225             warn "couldn't do $file: $!"    unless defined $return;
1226             warn "couldn't run $file"       unless $return;
1227         }
1228     }
1229
1230 =item dump LABEL
1231
1232 =item dump
1233
1234 This function causes an immediate core dump.  See also the B<-u>
1235 command-line switch in L<perlrun>, which does the same thing.
1236 Primarily this is so that you can use the B<undump> program (not
1237 supplied) to turn your core dump into an executable binary after
1238 having initialized all your variables at the beginning of the
1239 program.  When the new binary is executed it will begin by executing
1240 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1241 Think of it as a goto with an intervening core dump and reincarnation.
1242 If C<LABEL> is omitted, restarts the program from the top.
1243
1244 B<WARNING>: Any files opened at the time of the dump will I<not>
1245 be open any more when the program is reincarnated, with possible
1246 resulting confusion on the part of Perl.
1247
1248 This function is now largely obsolete, partly because it's very
1249 hard to convert a core file into an executable, and because the
1250 real compiler backends for generating portable bytecode and compilable
1251 C code have superseded it.  That's why you should now invoke it as
1252 C<CORE::dump()>, if you don't want to be warned against a possible
1253 typo.
1254
1255 If you're looking to use L<dump> to speed up your program, consider
1256 generating bytecode or native C code as described in L<perlcc>.  If
1257 you're just trying to accelerate a CGI script, consider using the
1258 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1259 You might also consider autoloading or selfloading, which at least
1260 make your program I<appear> to run faster.
1261
1262 =item each HASH
1263
1264 When called in list context, returns a 2-element list consisting of the
1265 key and value for the next element of a hash, so that you can iterate over
1266 it.  When called in scalar context, returns only the key for the next
1267 element in the hash.
1268
1269 Entries are returned in an apparently random order.  The actual random
1270 order is subject to change in future versions of perl, but it is
1271 guaranteed to be in the same order as either the C<keys> or C<values>
1272 function would produce on the same (unmodified) hash.  Since Perl
1273 5.8.1 the ordering is different even between different runs of Perl
1274 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1275
1276 When the hash is entirely read, a null array is returned in list context
1277 (which when assigned produces a false (C<0>) value), and C<undef> in
1278 scalar context.  The next call to C<each> after that will start iterating
1279 again.  There is a single iterator for each hash, shared by all C<each>,
1280 C<keys>, and C<values> function calls in the program; it can be reset by
1281 reading all the elements from the hash, or by evaluating C<keys HASH> or
1282 C<values HASH>.  If you add or delete elements of a hash while you're
1283 iterating over it, you may get entries skipped or duplicated, so
1284 don't.  Exception: It is always safe to delete the item most recently
1285 returned by C<each()>, which means that the following code will work:
1286
1287         while (($key, $value) = each %hash) {
1288           print $key, "\n";
1289           delete $hash{$key};   # This is safe
1290         }
1291
1292 The following prints out your environment like the printenv(1) program,
1293 only in a different order:
1294
1295     while (($key,$value) = each %ENV) {
1296         print "$key=$value\n";
1297     }
1298
1299 See also C<keys>, C<values> and C<sort>.
1300
1301 =item eof FILEHANDLE
1302
1303 =item eof ()
1304
1305 =item eof
1306
1307 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1308 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1309 gives the real filehandle.  (Note that this function actually
1310 reads a character and then C<ungetc>s it, so isn't very useful in an
1311 interactive context.)  Do not read from a terminal file (or call
1312 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1313 as terminals may lose the end-of-file condition if you do.
1314
1315 An C<eof> without an argument uses the last file read.  Using C<eof()>
1316 with empty parentheses is very different.  It refers to the pseudo file
1317 formed from the files listed on the command line and accessed via the
1318 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1319 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1320 used will cause C<@ARGV> to be examined to determine if input is
1321 available.   Similarly, an C<eof()> after C<< <> >> has returned
1322 end-of-file will assume you are processing another C<@ARGV> list,
1323 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1324 see L<perlop/"I/O Operators">.
1325
1326 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1327 detect the end of each file, C<eof()> will only detect the end of the
1328 last file.  Examples:
1329
1330     # reset line numbering on each input file
1331     while (<>) {
1332         next if /^\s*#/;        # skip comments
1333         print "$.\t$_";
1334     } continue {
1335         close ARGV  if eof;     # Not eof()!
1336     }
1337
1338     # insert dashes just before last line of last file
1339     while (<>) {
1340         if (eof()) {            # check for end of last file
1341             print "--------------\n";
1342         }
1343         print;
1344         last if eof();          # needed if we're reading from a terminal
1345     }
1346
1347 Practical hint: you almost never need to use C<eof> in Perl, because the
1348 input operators typically return C<undef> when they run out of data, or if
1349 there was an error.
1350
1351 =item eval EXPR
1352
1353 =item eval BLOCK
1354
1355 In the first form, the return value of EXPR is parsed and executed as if it
1356 were a little Perl program.  The value of the expression (which is itself
1357 determined within scalar context) is first parsed, and if there weren't any
1358 errors, executed in the lexical context of the current Perl program, so
1359 that any variable settings or subroutine and format definitions remain
1360 afterwards.  Note that the value is parsed every time the eval executes.
1361 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1362 delay parsing and subsequent execution of the text of EXPR until run time.
1363
1364 In the second form, the code within the BLOCK is parsed only once--at the
1365 same time the code surrounding the eval itself was parsed--and executed
1366 within the context of the current Perl program.  This form is typically
1367 used to trap exceptions more efficiently than the first (see below), while
1368 also providing the benefit of checking the code within BLOCK at compile
1369 time.
1370
1371 The final semicolon, if any, may be omitted from the value of EXPR or within
1372 the BLOCK.
1373
1374 In both forms, the value returned is the value of the last expression
1375 evaluated inside the mini-program; a return statement may be also used, just
1376 as with subroutines.  The expression providing the return value is evaluated
1377 in void, scalar, or list context, depending on the context of the eval itself.
1378 See L</wantarray> for more on how the evaluation context can be determined.
1379
1380 If there is a syntax error or runtime error, or a C<die> statement is
1381 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1382 error message.  If there was no error, C<$@> is guaranteed to be a null
1383 string.  Beware that using C<eval> neither silences perl from printing
1384 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1385 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1386 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1387 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1388
1389 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1390 determining whether a particular feature (such as C<socket> or C<symlink>)
1391 is implemented.  It is also Perl's exception trapping mechanism, where
1392 the die operator is used to raise exceptions.
1393
1394 If the code to be executed doesn't vary, you may use the eval-BLOCK
1395 form to trap run-time errors without incurring the penalty of
1396 recompiling each time.  The error, if any, is still returned in C<$@>.
1397 Examples:
1398
1399     # make divide-by-zero nonfatal
1400     eval { $answer = $a / $b; }; warn $@ if $@;
1401
1402     # same thing, but less efficient
1403     eval '$answer = $a / $b'; warn $@ if $@;
1404
1405     # a compile-time error
1406     eval { $answer = };                 # WRONG
1407
1408     # a run-time error
1409     eval '$answer =';   # sets $@
1410
1411 Due to the current arguably broken state of C<__DIE__> hooks, when using
1412 the C<eval{}> form as an exception trap in libraries, you may wish not
1413 to trigger any C<__DIE__> hooks that user code may have installed.
1414 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1415 as shown in this example:
1416
1417     # a very private exception trap for divide-by-zero
1418     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1419     warn $@ if $@;
1420
1421 This is especially significant, given that C<__DIE__> hooks can call
1422 C<die> again, which has the effect of changing their error messages:
1423
1424     # __DIE__ hooks may modify error messages
1425     {
1426        local $SIG{'__DIE__'} =
1427               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1428        eval { die "foo lives here" };
1429        print $@ if $@;                # prints "bar lives here"
1430     }
1431
1432 Because this promotes action at a distance, this counterintuitive behavior
1433 may be fixed in a future release.
1434
1435 With an C<eval>, you should be especially careful to remember what's
1436 being looked at when:
1437
1438     eval $x;            # CASE 1
1439     eval "$x";          # CASE 2
1440
1441     eval '$x';          # CASE 3
1442     eval { $x };        # CASE 4
1443
1444     eval "\$$x++";      # CASE 5
1445     $$x++;              # CASE 6
1446
1447 Cases 1 and 2 above behave identically: they run the code contained in
1448 the variable $x.  (Although case 2 has misleading double quotes making
1449 the reader wonder what else might be happening (nothing is).)  Cases 3
1450 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1451 does nothing but return the value of $x.  (Case 4 is preferred for
1452 purely visual reasons, but it also has the advantage of compiling at
1453 compile-time instead of at run-time.)  Case 5 is a place where
1454 normally you I<would> like to use double quotes, except that in this
1455 particular situation, you can just use symbolic references instead, as
1456 in case 6.
1457
1458 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1459 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1460
1461 Note that as a very special case, an C<eval ''> executed within the C<DB>
1462 package doesn't see the usual surrounding lexical scope, but rather the
1463 scope of the first non-DB piece of code that called it. You don't normally
1464 need to worry about this unless you are writing a Perl debugger.
1465
1466 =item exec LIST
1467
1468 =item exec PROGRAM LIST
1469
1470 The C<exec> function executes a system command I<and never returns>--
1471 use C<system> instead of C<exec> if you want it to return.  It fails and
1472 returns false only if the command does not exist I<and> it is executed
1473 directly instead of via your system's command shell (see below).
1474
1475 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1476 warns you if there is a following statement which isn't C<die>, C<warn>,
1477 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1478 I<really> want to follow an C<exec> with some other statement, you
1479 can use one of these styles to avoid the warning:
1480
1481     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1482     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1483
1484 If there is more than one argument in LIST, or if LIST is an array
1485 with more than one value, calls execvp(3) with the arguments in LIST.
1486 If there is only one scalar argument or an array with one element in it,
1487 the argument is checked for shell metacharacters, and if there are any,
1488 the entire argument is passed to the system's command shell for parsing
1489 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1490 If there are no shell metacharacters in the argument, it is split into
1491 words and passed directly to C<execvp>, which is more efficient.
1492 Examples:
1493
1494     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1495     exec "sort $outfile | uniq";
1496
1497 If you don't really want to execute the first argument, but want to lie
1498 to the program you are executing about its own name, you can specify
1499 the program you actually want to run as an "indirect object" (without a
1500 comma) in front of the LIST.  (This always forces interpretation of the
1501 LIST as a multivalued list, even if there is only a single scalar in
1502 the list.)  Example:
1503
1504     $shell = '/bin/csh';
1505     exec $shell '-sh';          # pretend it's a login shell
1506
1507 or, more directly,
1508
1509     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1510
1511 When the arguments get executed via the system shell, results will
1512 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1513 for details.
1514
1515 Using an indirect object with C<exec> or C<system> is also more
1516 secure.  This usage (which also works fine with system()) forces
1517 interpretation of the arguments as a multivalued list, even if the
1518 list had just one argument.  That way you're safe from the shell
1519 expanding wildcards or splitting up words with whitespace in them.
1520
1521     @args = ( "echo surprise" );
1522
1523     exec @args;               # subject to shell escapes
1524                                 # if @args == 1
1525     exec { $args[0] } @args;  # safe even with one-arg list
1526
1527 The first version, the one without the indirect object, ran the I<echo>
1528 program, passing it C<"surprise"> an argument.  The second version
1529 didn't--it tried to run a program literally called I<"echo surprise">,
1530 didn't find it, and set C<$?> to a non-zero value indicating failure.
1531
1532 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1533 output before the exec, but this may not be supported on some platforms
1534 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1535 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1536 open handles in order to avoid lost output.
1537
1538 Note that C<exec> will not call your C<END> blocks, nor will it call
1539 any C<DESTROY> methods in your objects.
1540
1541 =item exists EXPR
1542
1543 Given an expression that specifies a hash element or array element,
1544 returns true if the specified element in the hash or array has ever
1545 been initialized, even if the corresponding value is undefined.  The
1546 element is not autovivified if it doesn't exist.
1547
1548     print "Exists\n"    if exists $hash{$key};
1549     print "Defined\n"   if defined $hash{$key};
1550     print "True\n"      if $hash{$key};
1551
1552     print "Exists\n"    if exists $array[$index];
1553     print "Defined\n"   if defined $array[$index];
1554     print "True\n"      if $array[$index];
1555
1556 A hash or array element can be true only if it's defined, and defined if
1557 it exists, but the reverse doesn't necessarily hold true.
1558
1559 Given an expression that specifies the name of a subroutine,
1560 returns true if the specified subroutine has ever been declared, even
1561 if it is undefined.  Mentioning a subroutine name for exists or defined
1562 does not count as declaring it.  Note that a subroutine which does not
1563 exist may still be callable: its package may have an C<AUTOLOAD>
1564 method that makes it spring into existence the first time that it is
1565 called -- see L<perlsub>.
1566
1567     print "Exists\n"    if exists &subroutine;
1568     print "Defined\n"   if defined &subroutine;
1569
1570 Note that the EXPR can be arbitrarily complicated as long as the final
1571 operation is a hash or array key lookup or subroutine name:
1572
1573     if (exists $ref->{A}->{B}->{$key})  { }
1574     if (exists $hash{A}{B}{$key})       { }
1575
1576     if (exists $ref->{A}->{B}->[$ix])   { }
1577     if (exists $hash{A}{B}[$ix])        { }
1578
1579     if (exists &{$ref->{A}{B}{$key}})   { }
1580
1581 Although the deepest nested array or hash will not spring into existence
1582 just because its existence was tested, any intervening ones will.
1583 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1584 into existence due to the existence test for the $key element above.
1585 This happens anywhere the arrow operator is used, including even:
1586
1587     undef $ref;
1588     if (exists $ref->{"Some key"})      { }
1589     print $ref;             # prints HASH(0x80d3d5c)
1590
1591 This surprising autovivification in what does not at first--or even
1592 second--glance appear to be an lvalue context may be fixed in a future
1593 release.
1594
1595 Use of a subroutine call, rather than a subroutine name, as an argument
1596 to exists() is an error.
1597
1598     exists &sub;        # OK
1599     exists &sub();      # Error
1600
1601 =item exit EXPR
1602
1603 Evaluates EXPR and exits immediately with that value.    Example:
1604
1605     $ans = <STDIN>;
1606     exit 0 if $ans =~ /^[Xx]/;
1607
1608 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1609 universally recognized values for EXPR are C<0> for success and C<1>
1610 for error; other values are subject to interpretation depending on the
1611 environment in which the Perl program is running.  For example, exiting
1612 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1613 the mailer to return the item undelivered, but that's not true everywhere.
1614
1615 Don't use C<exit> to abort a subroutine if there's any chance that
1616 someone might want to trap whatever error happened.  Use C<die> instead,
1617 which can be trapped by an C<eval>.
1618
1619 The exit() function does not always exit immediately.  It calls any
1620 defined C<END> routines first, but these C<END> routines may not
1621 themselves abort the exit.  Likewise any object destructors that need to
1622 be called are called before the real exit.  If this is a problem, you
1623 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1624 See L<perlmod> for details.
1625
1626 =item exp EXPR
1627
1628 =item exp
1629
1630 Returns I<e> (the natural logarithm base) to the power of EXPR.
1631 If EXPR is omitted, gives C<exp($_)>.
1632
1633 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1634
1635 Implements the fcntl(2) function.  You'll probably have to say
1636
1637     use Fcntl;
1638
1639 first to get the correct constant definitions.  Argument processing and
1640 value return works just like C<ioctl> below.
1641 For example:
1642
1643     use Fcntl;
1644     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1645         or die "can't fcntl F_GETFL: $!";
1646
1647 You don't have to check for C<defined> on the return from C<fcntl>.
1648 Like C<ioctl>, it maps a C<0> return from the system call into
1649 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1650 in numeric context.  It is also exempt from the normal B<-w> warnings
1651 on improper numeric conversions.
1652
1653 Note that C<fcntl> will produce a fatal error if used on a machine that
1654 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1655 manpage to learn what functions are available on your system.
1656
1657 =item fileno FILEHANDLE
1658
1659 Returns the file descriptor for a filehandle, or undefined if the
1660 filehandle is not open.  This is mainly useful for constructing
1661 bitmaps for C<select> and low-level POSIX tty-handling operations.
1662 If FILEHANDLE is an expression, the value is taken as an indirect
1663 filehandle, generally its name.
1664
1665 You can use this to find out whether two handles refer to the
1666 same underlying descriptor:
1667
1668     if (fileno(THIS) == fileno(THAT)) {
1669         print "THIS and THAT are dups\n";
1670     }
1671
1672 (Filehandles connected to memory objects via new features of C<open> may
1673 return undefined even though they are open.)
1674
1675
1676 =item flock FILEHANDLE,OPERATION
1677
1678 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1679 for success, false on failure.  Produces a fatal error if used on a
1680 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1681 C<flock> is Perl's portable file locking interface, although it locks
1682 only entire files, not records.
1683
1684 Two potentially non-obvious but traditional C<flock> semantics are
1685 that it waits indefinitely until the lock is granted, and that its locks
1686 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1687 fewer guarantees.  This means that files locked with C<flock> may be
1688 modified by programs that do not also use C<flock>.  See L<perlport>,
1689 your port's specific documentation, or your system-specific local manpages
1690 for details.  It's best to assume traditional behavior if you're writing
1691 portable programs.  (But if you're not, you should as always feel perfectly
1692 free to write for your own system's idiosyncrasies (sometimes called
1693 "features").  Slavish adherence to portability concerns shouldn't get
1694 in the way of your getting your job done.)
1695
1696 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1697 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1698 you can use the symbolic names if you import them from the Fcntl module,
1699 either individually, or as a group using the ':flock' tag.  LOCK_SH
1700 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1701 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1702 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1703 waiting for the lock (check the return status to see if you got it).
1704
1705 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1706 before locking or unlocking it.
1707
1708 Note that the emulation built with lockf(3) doesn't provide shared
1709 locks, and it requires that FILEHANDLE be open with write intent.  These
1710 are the semantics that lockf(3) implements.  Most if not all systems
1711 implement lockf(3) in terms of fcntl(2) locking, though, so the
1712 differing semantics shouldn't bite too many people.
1713
1714 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1715 be open with read intent to use LOCK_SH and requires that it be open
1716 with write intent to use LOCK_EX.
1717
1718 Note also that some versions of C<flock> cannot lock things over the
1719 network; you would need to use the more system-specific C<fcntl> for
1720 that.  If you like you can force Perl to ignore your system's flock(2)
1721 function, and so provide its own fcntl(2)-based emulation, by passing
1722 the switch C<-Ud_flock> to the F<Configure> program when you configure
1723 perl.
1724
1725 Here's a mailbox appender for BSD systems.
1726
1727     use Fcntl ':flock'; # import LOCK_* constants
1728
1729     sub lock {
1730         flock(MBOX,LOCK_EX);
1731         # and, in case someone appended
1732         # while we were waiting...
1733         seek(MBOX, 0, 2);
1734     }
1735
1736     sub unlock {
1737         flock(MBOX,LOCK_UN);
1738     }
1739
1740     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1741             or die "Can't open mailbox: $!";
1742
1743     lock();
1744     print MBOX $msg,"\n\n";
1745     unlock();
1746
1747 On systems that support a real flock(), locks are inherited across fork()
1748 calls, whereas those that must resort to the more capricious fcntl()
1749 function lose the locks, making it harder to write servers.
1750
1751 See also L<DB_File> for other flock() examples.
1752
1753 =item fork
1754
1755 Does a fork(2) system call to create a new process running the
1756 same program at the same point.  It returns the child pid to the
1757 parent process, C<0> to the child process, or C<undef> if the fork is
1758 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1759 are shared, while everything else is copied.  On most systems supporting
1760 fork(), great care has gone into making it extremely efficient (for
1761 example, using copy-on-write technology on data pages), making it the
1762 dominant paradigm for multitasking over the last few decades.
1763
1764 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1765 output before forking the child process, but this may not be supported
1766 on some platforms (see L<perlport>).  To be safe, you may need to set
1767 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1768 C<IO::Handle> on any open handles in order to avoid duplicate output.
1769
1770 If you C<fork> without ever waiting on your children, you will
1771 accumulate zombies.  On some systems, you can avoid this by setting
1772 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1773 forking and reaping moribund children.
1774
1775 Note that if your forked child inherits system file descriptors like
1776 STDIN and STDOUT that are actually connected by a pipe or socket, even
1777 if you exit, then the remote server (such as, say, a CGI script or a
1778 backgrounded job launched from a remote shell) won't think you're done.
1779 You should reopen those to F</dev/null> if it's any issue.
1780
1781 =item format
1782
1783 Declare a picture format for use by the C<write> function.  For
1784 example:
1785
1786     format Something =
1787         Test: @<<<<<<<< @||||| @>>>>>
1788               $str,     $%,    '$' . int($num)
1789     .
1790
1791     $str = "widget";
1792     $num = $cost/$quantity;
1793     $~ = 'Something';
1794     write;
1795
1796 See L<perlform> for many details and examples.
1797
1798 =item formline PICTURE,LIST
1799
1800 This is an internal function used by C<format>s, though you may call it,
1801 too.  It formats (see L<perlform>) a list of values according to the
1802 contents of PICTURE, placing the output into the format output
1803 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1804 Eventually, when a C<write> is done, the contents of
1805 C<$^A> are written to some filehandle, but you could also read C<$^A>
1806 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1807 does one C<formline> per line of form, but the C<formline> function itself
1808 doesn't care how many newlines are embedded in the PICTURE.  This means
1809 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1810 You may therefore need to use multiple formlines to implement a single
1811 record format, just like the format compiler.
1812
1813 Be careful if you put double quotes around the picture, because an C<@>
1814 character may be taken to mean the beginning of an array name.
1815 C<formline> always returns true.  See L<perlform> for other examples.
1816
1817 =item getc FILEHANDLE
1818
1819 =item getc
1820
1821 Returns the next character from the input file attached to FILEHANDLE,
1822 or the undefined value at end of file, or if there was an error (in
1823 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1824 STDIN.  This is not particularly efficient.  However, it cannot be
1825 used by itself to fetch single characters without waiting for the user
1826 to hit enter.  For that, try something more like:
1827
1828     if ($BSD_STYLE) {
1829         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1830     }
1831     else {
1832         system "stty", '-icanon', 'eol', "\001";
1833     }
1834
1835     $key = getc(STDIN);
1836
1837     if ($BSD_STYLE) {
1838         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1839     }
1840     else {
1841         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1842     }
1843     print "\n";
1844
1845 Determination of whether $BSD_STYLE should be set
1846 is left as an exercise to the reader.
1847
1848 The C<POSIX::getattr> function can do this more portably on
1849 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1850 module from your nearest CPAN site; details on CPAN can be found on
1851 L<perlmodlib/CPAN>.
1852
1853 =item getlogin
1854
1855 Implements the C library function of the same name, which on most
1856 systems returns the current login from F</etc/utmp>, if any.  If null,
1857 use C<getpwuid>.
1858
1859     $login = getlogin || getpwuid($<) || "Kilroy";
1860
1861 Do not consider C<getlogin> for authentication: it is not as
1862 secure as C<getpwuid>.
1863
1864 =item getpeername SOCKET
1865
1866 Returns the packed sockaddr address of other end of the SOCKET connection.
1867
1868     use Socket;
1869     $hersockaddr    = getpeername(SOCK);
1870     ($port, $iaddr) = sockaddr_in($hersockaddr);
1871     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1872     $herstraddr     = inet_ntoa($iaddr);
1873
1874 =item getpgrp PID
1875
1876 Returns the current process group for the specified PID.  Use
1877 a PID of C<0> to get the current process group for the
1878 current process.  Will raise an exception if used on a machine that
1879 doesn't implement getpgrp(2).  If PID is omitted, returns process
1880 group of current process.  Note that the POSIX version of C<getpgrp>
1881 does not accept a PID argument, so only C<PID==0> is truly portable.
1882
1883 =item getppid
1884
1885 Returns the process id of the parent process.
1886
1887 Note for Linux users: on Linux, the C functions C<getpid()> and
1888 C<getppid()> return different values from different threads. In order to
1889 be portable, this behavior is not reflected by the perl-level function
1890 C<getppid()>, that returns a consistent value across threads. If you want
1891 to call the underlying C<getppid()>, you may use the CPAN module
1892 C<Linux::Pid>.
1893
1894 =item getpriority WHICH,WHO
1895
1896 Returns the current priority for a process, a process group, or a user.
1897 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1898 machine that doesn't implement getpriority(2).
1899
1900 =item getpwnam NAME
1901
1902 =item getgrnam NAME
1903
1904 =item gethostbyname NAME
1905
1906 =item getnetbyname NAME
1907
1908 =item getprotobyname NAME
1909
1910 =item getpwuid UID
1911
1912 =item getgrgid GID
1913
1914 =item getservbyname NAME,PROTO
1915
1916 =item gethostbyaddr ADDR,ADDRTYPE
1917
1918 =item getnetbyaddr ADDR,ADDRTYPE
1919
1920 =item getprotobynumber NUMBER
1921
1922 =item getservbyport PORT,PROTO
1923
1924 =item getpwent
1925
1926 =item getgrent
1927
1928 =item gethostent
1929
1930 =item getnetent
1931
1932 =item getprotoent
1933
1934 =item getservent
1935
1936 =item setpwent
1937
1938 =item setgrent
1939
1940 =item sethostent STAYOPEN
1941
1942 =item setnetent STAYOPEN
1943
1944 =item setprotoent STAYOPEN
1945
1946 =item setservent STAYOPEN
1947
1948 =item endpwent
1949
1950 =item endgrent
1951
1952 =item endhostent
1953
1954 =item endnetent
1955
1956 =item endprotoent
1957
1958 =item endservent
1959
1960 These routines perform the same functions as their counterparts in the
1961 system library.  In list context, the return values from the
1962 various get routines are as follows:
1963
1964     ($name,$passwd,$uid,$gid,
1965        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1966     ($name,$passwd,$gid,$members) = getgr*
1967     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1968     ($name,$aliases,$addrtype,$net) = getnet*
1969     ($name,$aliases,$proto) = getproto*
1970     ($name,$aliases,$port,$proto) = getserv*
1971
1972 (If the entry doesn't exist you get a null list.)
1973
1974 The exact meaning of the $gcos field varies but it usually contains
1975 the real name of the user (as opposed to the login name) and other
1976 information pertaining to the user.  Beware, however, that in many
1977 system users are able to change this information and therefore it
1978 cannot be trusted and therefore the $gcos is tainted (see
1979 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1980 login shell, are also tainted, because of the same reason.
1981
1982 In scalar context, you get the name, unless the function was a
1983 lookup by name, in which case you get the other thing, whatever it is.
1984 (If the entry doesn't exist you get the undefined value.)  For example:
1985
1986     $uid   = getpwnam($name);
1987     $name  = getpwuid($num);
1988     $name  = getpwent();
1989     $gid   = getgrnam($name);
1990     $name  = getgrgid($num);
1991     $name  = getgrent();
1992     #etc.
1993
1994 In I<getpw*()> the fields $quota, $comment, and $expire are special
1995 cases in the sense that in many systems they are unsupported.  If the
1996 $quota is unsupported, it is an empty scalar.  If it is supported, it
1997 usually encodes the disk quota.  If the $comment field is unsupported,
1998 it is an empty scalar.  If it is supported it usually encodes some
1999 administrative comment about the user.  In some systems the $quota
2000 field may be $change or $age, fields that have to do with password
2001 aging.  In some systems the $comment field may be $class.  The $expire
2002 field, if present, encodes the expiration period of the account or the
2003 password.  For the availability and the exact meaning of these fields
2004 in your system, please consult your getpwnam(3) documentation and your
2005 F<pwd.h> file.  You can also find out from within Perl what your
2006 $quota and $comment fields mean and whether you have the $expire field
2007 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2008 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2009 files are only supported if your vendor has implemented them in the
2010 intuitive fashion that calling the regular C library routines gets the
2011 shadow versions if you're running under privilege or if there exists
2012 the shadow(3) functions as found in System V ( this includes Solaris
2013 and Linux.)  Those systems which implement a proprietary shadow password
2014 facility are unlikely to be supported.
2015
2016 The $members value returned by I<getgr*()> is a space separated list of
2017 the login names of the members of the group.
2018
2019 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2020 C, it will be returned to you via C<$?> if the function call fails.  The
2021 C<@addrs> value returned by a successful call is a list of the raw
2022 addresses returned by the corresponding system library call.  In the
2023 Internet domain, each address is four bytes long and you can unpack it
2024 by saying something like:
2025
2026     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2027
2028 The Socket library makes this slightly easier:
2029
2030     use Socket;
2031     $iaddr = inet_aton("127.1"); # or whatever address
2032     $name  = gethostbyaddr($iaddr, AF_INET);
2033
2034     # or going the other way
2035     $straddr = inet_ntoa($iaddr);
2036
2037 If you get tired of remembering which element of the return list
2038 contains which return value, by-name interfaces are provided
2039 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2040 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2041 and C<User::grent>.  These override the normal built-ins, supplying
2042 versions that return objects with the appropriate names
2043 for each field.  For example:
2044
2045    use File::stat;
2046    use User::pwent;
2047    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2048
2049 Even though it looks like they're the same method calls (uid),
2050 they aren't, because a C<File::stat> object is different from
2051 a C<User::pwent> object.
2052
2053 =item getsockname SOCKET
2054
2055 Returns the packed sockaddr address of this end of the SOCKET connection,
2056 in case you don't know the address because you have several different
2057 IPs that the connection might have come in on.
2058
2059     use Socket;
2060     $mysockaddr = getsockname(SOCK);
2061     ($port, $myaddr) = sockaddr_in($mysockaddr);
2062     printf "Connect to %s [%s]\n",
2063        scalar gethostbyaddr($myaddr, AF_INET),
2064        inet_ntoa($myaddr);
2065
2066 =item getsockopt SOCKET,LEVEL,OPTNAME
2067
2068 Returns the socket option requested, or undef if there is an error.
2069
2070 =item glob EXPR
2071
2072 =item glob
2073
2074 In list context, returns a (possibly empty) list of filename expansions on
2075 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2076 scalar context, glob iterates through such filename expansions, returning
2077 undef when the list is exhausted. This is the internal function
2078 implementing the C<< <*.c> >> operator, but you can use it directly. If
2079 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2080 more detail in L<perlop/"I/O Operators">.
2081
2082 Beginning with v5.6.0, this operator is implemented using the standard
2083 C<File::Glob> extension.  See L<File::Glob> for details.
2084
2085 =item gmtime EXPR
2086
2087 Converts a time as returned by the time function to an 8-element list
2088 with the time localized for the standard Greenwich time zone.
2089 Typically used as follows:
2090
2091     #  0    1    2     3     4    5     6     7
2092     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2093                                             gmtime(time);
2094
2095 All list elements are numeric, and come straight out of the C `struct
2096 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2097 specified time.  $mday is the day of the month, and $mon is the month
2098 itself, in the range C<0..11> with 0 indicating January and 11
2099 indicating December.  $year is the number of years since 1900.  That
2100 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2101 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2102 the year, in the range C<0..364> (or C<0..365> in leap years.)
2103
2104 Note that the $year element is I<not> simply the last two digits of
2105 the year.  If you assume it is, then you create non-Y2K-compliant
2106 programs--and you wouldn't want to do that, would you?
2107
2108 The proper way to get a complete 4-digit year is simply:
2109
2110         $year += 1900;
2111
2112 And to get the last two digits of the year (e.g., '01' in 2001) do:
2113
2114         $year = sprintf("%02d", $year % 100);
2115
2116 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2117
2118 In scalar context, C<gmtime()> returns the ctime(3) value:
2119
2120     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2121
2122 Also see the C<timegm> function provided by the C<Time::Local> module,
2123 and the strftime(3) function available via the POSIX module.
2124
2125 This scalar value is B<not> locale dependent (see L<perllocale>), but
2126 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2127 strftime(3) and mktime(3) functions available via the POSIX module.  To
2128 get somewhat similar but locale dependent date strings, set up your
2129 locale environment variables appropriately (please see L<perllocale>)
2130 and try for example:
2131
2132     use POSIX qw(strftime);
2133     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2134
2135 Note that the C<%a> and C<%b> escapes, which represent the short forms
2136 of the day of the week and the month of the year, may not necessarily
2137 be three characters wide in all locales.
2138
2139 =item goto LABEL
2140
2141 =item goto EXPR
2142
2143 =item goto &NAME
2144
2145 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2146 execution there.  It may not be used to go into any construct that
2147 requires initialization, such as a subroutine or a C<foreach> loop.  It
2148 also can't be used to go into a construct that is optimized away,
2149 or to get out of a block or subroutine given to C<sort>.
2150 It can be used to go almost anywhere else within the dynamic scope,
2151 including out of subroutines, but it's usually better to use some other
2152 construct such as C<last> or C<die>.  The author of Perl has never felt the
2153 need to use this form of C<goto> (in Perl, that is--C is another matter).
2154 (The difference being that C does not offer named loops combined with
2155 loop control.  Perl does, and this replaces most structured uses of C<goto>
2156 in other languages.)
2157
2158 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2159 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2160 necessarily recommended if you're optimizing for maintainability:
2161
2162     goto ("FOO", "BAR", "GLARCH")[$i];
2163
2164 The C<goto-&NAME> form is quite different from the other forms of
2165 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2166 doesn't have the stigma associated with other gotos.  Instead, it
2167 exits the current subroutine (losing any changes set by local()) and
2168 immediately calls in its place the named subroutine using the current
2169 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2170 load another subroutine and then pretend that the other subroutine had
2171 been called in the first place (except that any modifications to C<@_>
2172 in the current subroutine are propagated to the other subroutine.)
2173 After the C<goto>, not even C<caller> will be able to tell that this
2174 routine was called first.
2175
2176 NAME needn't be the name of a subroutine; it can be a scalar variable
2177 containing a code reference, or a block which evaluates to a code
2178 reference.
2179
2180 =item grep BLOCK LIST
2181
2182 =item grep EXPR,LIST
2183
2184 This is similar in spirit to, but not the same as, grep(1) and its
2185 relatives.  In particular, it is not limited to using regular expressions.
2186
2187 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2188 C<$_> to each element) and returns the list value consisting of those
2189 elements for which the expression evaluated to true.  In scalar
2190 context, returns the number of times the expression was true.
2191
2192     @foo = grep(!/^#/, @bar);    # weed out comments
2193
2194 or equivalently,
2195
2196     @foo = grep {!/^#/} @bar;    # weed out comments
2197
2198 Note that C<$_> is an alias to the list value, so it can be used to
2199 modify the elements of the LIST.  While this is useful and supported,
2200 it can cause bizarre results if the elements of LIST are not variables.
2201 Similarly, grep returns aliases into the original list, much as a for
2202 loop's index variable aliases the list elements.  That is, modifying an
2203 element of a list returned by grep (for example, in a C<foreach>, C<map>
2204 or another C<grep>) actually modifies the element in the original list.
2205 This is usually something to be avoided when writing clear code.
2206
2207 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2208
2209 =item hex EXPR
2210
2211 =item hex
2212
2213 Interprets EXPR as a hex string and returns the corresponding value.
2214 (To convert strings that might start with either 0, 0x, or 0b, see
2215 L</oct>.)  If EXPR is omitted, uses C<$_>.
2216
2217     print hex '0xAf'; # prints '175'
2218     print hex 'aF';   # same
2219
2220 Hex strings may only represent integers.  Strings that would cause
2221 integer overflow trigger a warning.  Leading whitespace is not stripped,
2222 unlike oct().
2223
2224 =item import
2225
2226 There is no builtin C<import> function.  It is just an ordinary
2227 method (subroutine) defined (or inherited) by modules that wish to export
2228 names to another module.  The C<use> function calls the C<import> method
2229 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2230
2231 =item index STR,SUBSTR,POSITION
2232
2233 =item index STR,SUBSTR
2234
2235 The index function searches for one string within another, but without
2236 the wildcard-like behavior of a full regular-expression pattern match.
2237 It returns the position of the first occurrence of SUBSTR in STR at
2238 or after POSITION.  If POSITION is omitted, starts searching from the
2239 beginning of the string.  The return value is based at C<0> (or whatever
2240 you've set the C<$[> variable to--but don't do that).  If the substring
2241 is not found, returns one less than the base, ordinarily C<-1>.
2242
2243 =item int EXPR
2244
2245 =item int
2246
2247 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2248 You should not use this function for rounding: one because it truncates
2249 towards C<0>, and two because machine representations of floating point
2250 numbers can sometimes produce counterintuitive results.  For example,
2251 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2252 because it's really more like -268.99999999999994315658 instead.  Usually,
2253 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2254 functions will serve you better than will int().
2255
2256 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2257
2258 Implements the ioctl(2) function.  You'll probably first have to say
2259
2260     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2261
2262 to get the correct function definitions.  If F<ioctl.ph> doesn't
2263 exist or doesn't have the correct definitions you'll have to roll your
2264 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2265 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2266 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2267 written depending on the FUNCTION--a pointer to the string value of SCALAR
2268 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2269 has no string value but does have a numeric value, that value will be
2270 passed rather than a pointer to the string value.  To guarantee this to be
2271 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2272 functions may be needed to manipulate the values of structures used by
2273 C<ioctl>.
2274
2275 The return value of C<ioctl> (and C<fcntl>) is as follows:
2276
2277         if OS returns:          then Perl returns:
2278             -1                    undefined value
2279              0                  string "0 but true"
2280         anything else               that number
2281
2282 Thus Perl returns true on success and false on failure, yet you can
2283 still easily determine the actual value returned by the operating
2284 system:
2285
2286     $retval = ioctl(...) || -1;
2287     printf "System returned %d\n", $retval;
2288
2289 The special string "C<0> but true" is exempt from B<-w> complaints
2290 about improper numeric conversions.
2291
2292 Here's an example of setting a filehandle named C<REMOTE> to be
2293 non-blocking at the system level.  You'll have to negotiate C<$|>
2294 on your own, though.
2295
2296     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2297
2298     $flags = fcntl(REMOTE, F_GETFL, 0)
2299                 or die "Can't get flags for the socket: $!\n";
2300
2301     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2302                 or die "Can't set flags for the socket: $!\n";
2303
2304 =item join EXPR,LIST
2305
2306 Joins the separate strings of LIST into a single string with fields
2307 separated by the value of EXPR, and returns that new string.  Example:
2308
2309     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2310
2311 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2312 first argument.  Compare L</split>.
2313
2314 =item keys HASH
2315
2316 Returns a list consisting of all the keys of the named hash.
2317 (In scalar context, returns the number of keys.)
2318
2319 The keys are returned in an apparently random order.  The actual
2320 random order is subject to change in future versions of perl, but it
2321 is guaranteed to be the same order as either the C<values> or C<each>
2322 function produces (given that the hash has not been modified).  Since
2323 Perl 5.8.1 the ordering is different even between different runs of
2324 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2325 Attacks">).
2326
2327 As a side effect, calling keys() resets the HASH's internal iterator,
2328 see L</each>.
2329
2330 Here is yet another way to print your environment:
2331
2332     @keys = keys %ENV;
2333     @values = values %ENV;
2334     while (@keys) {
2335         print pop(@keys), '=', pop(@values), "\n";
2336     }
2337
2338 or how about sorted by key:
2339
2340     foreach $key (sort(keys %ENV)) {
2341         print $key, '=', $ENV{$key}, "\n";
2342     }
2343
2344 The returned values are copies of the original keys in the hash, so
2345 modifying them will not affect the original hash.  Compare L</values>.
2346
2347 To sort a hash by value, you'll need to use a C<sort> function.
2348 Here's a descending numeric sort of a hash by its values:
2349
2350     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2351         printf "%4d %s\n", $hash{$key}, $key;
2352     }
2353
2354 As an lvalue C<keys> allows you to increase the number of hash buckets
2355 allocated for the given hash.  This can gain you a measure of efficiency if
2356 you know the hash is going to get big.  (This is similar to pre-extending
2357 an array by assigning a larger number to $#array.)  If you say
2358
2359     keys %hash = 200;
2360
2361 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2362 in fact, since it rounds up to the next power of two.  These
2363 buckets will be retained even if you do C<%hash = ()>, use C<undef
2364 %hash> if you want to free the storage while C<%hash> is still in scope.
2365 You can't shrink the number of buckets allocated for the hash using
2366 C<keys> in this way (but you needn't worry about doing this by accident,
2367 as trying has no effect).
2368
2369 See also C<each>, C<values> and C<sort>.
2370
2371 =item kill SIGNAL, LIST
2372
2373 Sends a signal to a list of processes.  Returns the number of
2374 processes successfully signaled (which is not necessarily the
2375 same as the number actually killed).
2376
2377     $cnt = kill 1, $child1, $child2;
2378     kill 9, @goners;
2379
2380 If SIGNAL is zero, no signal is sent to the process.  This is a
2381 useful way to check that a child process is alive and hasn't changed
2382 its UID.  See L<perlport> for notes on the portability of this
2383 construct.
2384
2385 Unlike in the shell, if SIGNAL is negative, it kills
2386 process groups instead of processes.  (On System V, a negative I<PROCESS>
2387 number will also kill process groups, but that's not portable.)  That
2388 means you usually want to use positive not negative signals.  You may also
2389 use a signal name in quotes.
2390
2391 See L<perlipc/"Signals"> for more details.
2392
2393 =item last LABEL
2394
2395 =item last
2396
2397 The C<last> command is like the C<break> statement in C (as used in
2398 loops); it immediately exits the loop in question.  If the LABEL is
2399 omitted, the command refers to the innermost enclosing loop.  The
2400 C<continue> block, if any, is not executed:
2401
2402     LINE: while (<STDIN>) {
2403         last LINE if /^$/;      # exit when done with header
2404         #...
2405     }
2406
2407 C<last> cannot be used to exit a block which returns a value such as
2408 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2409 a grep() or map() operation.
2410
2411 Note that a block by itself is semantically identical to a loop
2412 that executes once.  Thus C<last> can be used to effect an early
2413 exit out of such a block.
2414
2415 See also L</continue> for an illustration of how C<last>, C<next>, and
2416 C<redo> work.
2417
2418 =item lc EXPR
2419
2420 =item lc
2421
2422 Returns a lowercased version of EXPR.  This is the internal function
2423 implementing the C<\L> escape in double-quoted strings.  Respects
2424 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2425 and L<perlunicode> for more details about locale and Unicode support.
2426
2427 If EXPR is omitted, uses C<$_>.
2428
2429 =item lcfirst EXPR
2430
2431 =item lcfirst
2432
2433 Returns the value of EXPR with the first character lowercased.  This
2434 is the internal function implementing the C<\l> escape in
2435 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2436 locale> in force.  See L<perllocale> and L<perlunicode> for more
2437 details about locale and Unicode support.
2438
2439 If EXPR is omitted, uses C<$_>.
2440
2441 =item length EXPR
2442
2443 =item length
2444
2445 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2446 omitted, returns length of C<$_>.  Note that this cannot be used on
2447 an entire array or hash to find out how many elements these have.
2448 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2449
2450 Note the I<characters>: if the EXPR is in Unicode, you will get the
2451 number of characters, not the number of bytes.  To get the length
2452 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2453
2454 =item link OLDFILE,NEWFILE
2455
2456 Creates a new filename linked to the old filename.  Returns true for
2457 success, false otherwise.
2458
2459 =item listen SOCKET,QUEUESIZE
2460
2461 Does the same thing that the listen system call does.  Returns true if
2462 it succeeded, false otherwise.  See the example in
2463 L<perlipc/"Sockets: Client/Server Communication">.
2464
2465 =item local EXPR
2466
2467 You really probably want to be using C<my> instead, because C<local> isn't
2468 what most people think of as "local".  See
2469 L<perlsub/"Private Variables via my()"> for details.
2470
2471 A local modifies the listed variables to be local to the enclosing
2472 block, file, or eval.  If more than one value is listed, the list must
2473 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2474 for details, including issues with tied arrays and hashes.
2475
2476 =item localtime EXPR
2477
2478 Converts a time as returned by the time function to a 9-element list
2479 with the time analyzed for the local time zone.  Typically used as
2480 follows:
2481
2482     #  0    1    2     3     4    5     6     7     8
2483     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2484                                                 localtime(time);
2485
2486 All list elements are numeric, and come straight out of the C `struct
2487 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2488 specified time.  $mday is the day of the month, and $mon is the month
2489 itself, in the range C<0..11> with 0 indicating January and 11
2490 indicating December.  $year is the number of years since 1900.  That
2491 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2492 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2493 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2494 is true if the specified time occurs during daylight savings time,
2495 false otherwise.
2496
2497 Note that the $year element is I<not> simply the last two digits of
2498 the year.  If you assume it is, then you create non-Y2K-compliant
2499 programs--and you wouldn't want to do that, would you?
2500
2501 The proper way to get a complete 4-digit year is simply:
2502
2503         $year += 1900;
2504
2505 And to get the last two digits of the year (e.g., '01' in 2001) do:
2506
2507         $year = sprintf("%02d", $year % 100);
2508
2509 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2510
2511 In scalar context, C<localtime()> returns the ctime(3) value:
2512
2513     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2514
2515 This scalar value is B<not> locale dependent, see L<perllocale>, but
2516 instead a Perl builtin.  Also see the C<Time::Local> module
2517 (to convert the second, minutes, hours, ... back to seconds since the
2518 stroke of midnight the 1st of January 1970, the value returned by
2519 time()), and the strftime(3) and mktime(3) functions available via the
2520 POSIX module.  To get somewhat similar but locale dependent date
2521 strings, set up your locale environment variables appropriately
2522 (please see L<perllocale>) and try for example:
2523
2524     use POSIX qw(strftime);
2525     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2526
2527 Note that the C<%a> and C<%b>, the short forms of the day of the week
2528 and the month of the year, may not necessarily be three characters wide.
2529
2530 =item lock THING
2531
2532 This function places an advisory lock on a shared variable, or referenced
2533 object contained in I<THING> until the lock goes out of scope.
2534
2535 lock() is a "weak keyword" : this means that if you've defined a function
2536 by this name (before any calls to it), that function will be called
2537 instead. (However, if you've said C<use threads>, lock() is always a
2538 keyword.) See L<threads>.
2539
2540 =item log EXPR
2541
2542 =item log
2543
2544 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2545 returns log of C<$_>.  To get the log of another base, use basic algebra:
2546 The base-N log of a number is equal to the natural log of that number
2547 divided by the natural log of N.  For example:
2548
2549     sub log10 {
2550         my $n = shift;
2551         return log($n)/log(10);
2552     }
2553
2554 See also L</exp> for the inverse operation.
2555
2556 =item lstat EXPR
2557
2558 =item lstat
2559
2560 Does the same thing as the C<stat> function (including setting the
2561 special C<_> filehandle) but stats a symbolic link instead of the file
2562 the symbolic link points to.  If symbolic links are unimplemented on
2563 your system, a normal C<stat> is done.  For much more detailed
2564 information, please see the documentation for C<stat>.
2565
2566 If EXPR is omitted, stats C<$_>.
2567
2568 =item m//
2569
2570 The match operator.  See L<perlop>.
2571
2572 =item map BLOCK LIST
2573
2574 =item map EXPR,LIST
2575
2576 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2577 C<$_> to each element) and returns the list value composed of the
2578 results of each such evaluation.  In scalar context, returns the
2579 total number of elements so generated.  Evaluates BLOCK or EXPR in
2580 list context, so each element of LIST may produce zero, one, or
2581 more elements in the returned value.
2582
2583     @chars = map(chr, @nums);
2584
2585 translates a list of numbers to the corresponding characters.  And
2586
2587     %hash = map { getkey($_) => $_ } @array;
2588
2589 is just a funny way to write
2590
2591     %hash = ();
2592     foreach $_ (@array) {
2593         $hash{getkey($_)} = $_;
2594     }
2595
2596 Note that C<$_> is an alias to the list value, so it can be used to
2597 modify the elements of the LIST.  While this is useful and supported,
2598 it can cause bizarre results if the elements of LIST are not variables.
2599 Using a regular C<foreach> loop for this purpose would be clearer in
2600 most cases.  See also L</grep> for an array composed of those items of
2601 the original list for which the BLOCK or EXPR evaluates to true.
2602
2603 C<{> starts both hash references and blocks, so C<map { ...> could be either
2604 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2605 ahead for the closing C<}> it has to take a guess at which its dealing with
2606 based what it finds just after the C<{>. Usually it gets it right, but if it
2607 doesn't it won't realize something is wrong until it gets to the C<}> and
2608 encounters the missing (or unexpected) comma. The syntax error will be
2609 reported close to the C<}> but you'll need to change something near the C<{>
2610 such as using a unary C<+> to give perl some help:
2611
2612     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2613     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2614     %hash = map { ("\L$_", 1) } @array  # this also works
2615     %hash = map {  lc($_), 1  } @array  # as does this.
2616     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2617
2618     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2619
2620 or to force an anon hash constructor use C<+{>
2621
2622    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2623
2624 and you get list of anonymous hashes each with only 1 entry.
2625
2626 =item mkdir FILENAME,MASK
2627
2628 =item mkdir FILENAME
2629
2630 Creates the directory specified by FILENAME, with permissions
2631 specified by MASK (as modified by C<umask>).  If it succeeds it
2632 returns true, otherwise it returns false and sets C<$!> (errno).
2633 If omitted, MASK defaults to 0777.
2634
2635 In general, it is better to create directories with permissive MASK,
2636 and let the user modify that with their C<umask>, than it is to supply
2637 a restrictive MASK and give the user no way to be more permissive.
2638 The exceptions to this rule are when the file or directory should be
2639 kept private (mail files, for instance).  The perlfunc(1) entry on
2640 C<umask> discusses the choice of MASK in more detail.
2641
2642 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2643 number of trailing slashes.  Some operating and filesystems do not get
2644 this right, so Perl automatically removes all trailing slashes to keep
2645 everyone happy.
2646
2647 =item msgctl ID,CMD,ARG
2648
2649 Calls the System V IPC function msgctl(2).  You'll probably have to say
2650
2651     use IPC::SysV;
2652
2653 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2654 then ARG must be a variable which will hold the returned C<msqid_ds>
2655 structure.  Returns like C<ioctl>: the undefined value for error,
2656 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2657 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2658
2659 =item msgget KEY,FLAGS
2660
2661 Calls the System V IPC function msgget(2).  Returns the message queue
2662 id, or the undefined value if there is an error.  See also
2663 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2664
2665 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2666
2667 Calls the System V IPC function msgrcv to receive a message from
2668 message queue ID into variable VAR with a maximum message size of
2669 SIZE.  Note that when a message is received, the message type as a
2670 native long integer will be the first thing in VAR, followed by the
2671 actual message.  This packing may be opened with C<unpack("l! a*")>.
2672 Taints the variable.  Returns true if successful, or false if there is
2673 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2674 C<IPC::SysV::Msg> documentation.
2675
2676 =item msgsnd ID,MSG,FLAGS
2677
2678 Calls the System V IPC function msgsnd to send the message MSG to the
2679 message queue ID.  MSG must begin with the native long integer message
2680 type, and be followed by the length of the actual message, and finally
2681 the message itself.  This kind of packing can be achieved with
2682 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2683 or false if there is an error.  See also C<IPC::SysV>
2684 and C<IPC::SysV::Msg> documentation.
2685
2686 =item my EXPR
2687
2688 =item my TYPE EXPR
2689
2690 =item my EXPR : ATTRS
2691
2692 =item my TYPE EXPR : ATTRS
2693
2694 A C<my> declares the listed variables to be local (lexically) to the
2695 enclosing block, file, or C<eval>.  If more than one value is listed,
2696 the list must be placed in parentheses.
2697
2698 The exact semantics and interface of TYPE and ATTRS are still
2699 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2700 and attributes are handled using the C<attributes> pragma, or starting
2701 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2702 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2703 L<attributes>, and L<Attribute::Handlers>.
2704
2705 =item next LABEL
2706
2707 =item next
2708
2709 The C<next> command is like the C<continue> statement in C; it starts
2710 the next iteration of the loop:
2711
2712     LINE: while (<STDIN>) {
2713         next LINE if /^#/;      # discard comments
2714         #...
2715     }
2716
2717 Note that if there were a C<continue> block on the above, it would get
2718 executed even on discarded lines.  If the LABEL is omitted, the command
2719 refers to the innermost enclosing loop.
2720
2721 C<next> cannot be used to exit a block which returns a value such as
2722 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2723 a grep() or map() operation.
2724
2725 Note that a block by itself is semantically identical to a loop
2726 that executes once.  Thus C<next> will exit such a block early.
2727
2728 See also L</continue> for an illustration of how C<last>, C<next>, and
2729 C<redo> work.
2730
2731 =item no Module VERSION LIST
2732
2733 =item no Module VERSION
2734
2735 =item no Module LIST
2736
2737 =item no Module
2738
2739 See the C<use> function, of which C<no> is the opposite.
2740
2741 =item oct EXPR
2742
2743 =item oct
2744
2745 Interprets EXPR as an octal string and returns the corresponding
2746 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2747 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2748 binary string.  Leading whitespace is ignored in all three cases.)
2749 The following will handle decimal, binary, octal, and hex in the standard
2750 Perl or C notation:
2751
2752     $val = oct($val) if $val =~ /^0/;
2753
2754 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2755 in octal), use sprintf() or printf():
2756
2757     $perms = (stat("filename"))[2] & 07777;
2758     $oct_perms = sprintf "%lo", $perms;
2759
2760 The oct() function is commonly used when a string such as C<644> needs
2761 to be converted into a file mode, for example. (Although perl will
2762 automatically convert strings into numbers as needed, this automatic
2763 conversion assumes base 10.)
2764
2765 =item open FILEHANDLE,EXPR
2766
2767 =item open FILEHANDLE,MODE,EXPR
2768
2769 =item open FILEHANDLE,MODE,EXPR,LIST
2770
2771 =item open FILEHANDLE,MODE,REFERENCE
2772
2773 =item open FILEHANDLE
2774
2775 Opens the file whose filename is given by EXPR, and associates it with
2776 FILEHANDLE.
2777
2778 (The following is a comprehensive reference to open(): for a gentler
2779 introduction you may consider L<perlopentut>.)
2780
2781 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2782 the variable is assigned a reference to a new anonymous filehandle,
2783 otherwise if FILEHANDLE is an expression, its value is used as the name of
2784 the real filehandle wanted.  (This is considered a symbolic reference, so
2785 C<use strict 'refs'> should I<not> be in effect.)
2786
2787 If EXPR is omitted, the scalar variable of the same name as the
2788 FILEHANDLE contains the filename.  (Note that lexical variables--those
2789 declared with C<my>--will not work for this purpose; so if you're
2790 using C<my>, specify EXPR in your call to open.)
2791
2792 If three or more arguments are specified then the mode of opening and
2793 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2794 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2795 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2796 the file is opened for appending, again being created if necessary.
2797
2798 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2799 indicate that you want both read and write access to the file; thus
2800 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2801 '+>' >> mode would clobber the file first.  You can't usually use
2802 either read-write mode for updating textfiles, since they have
2803 variable length records.  See the B<-i> switch in L<perlrun> for a
2804 better approach.  The file is created with permissions of C<0666>
2805 modified by the process' C<umask> value.
2806
2807 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2808 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2809
2810 In the 2-arguments (and 1-argument) form of the call the mode and
2811 filename should be concatenated (in this order), possibly separated by
2812 spaces.  It is possible to omit the mode in these forms if the mode is
2813 C<< '<' >>.
2814
2815 If the filename begins with C<'|'>, the filename is interpreted as a
2816 command to which output is to be piped, and if the filename ends with a
2817 C<'|'>, the filename is interpreted as a command which pipes output to
2818 us.  See L<perlipc/"Using open() for IPC">
2819 for more examples of this.  (You are not allowed to C<open> to a command
2820 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2821 and L<perlipc/"Bidirectional Communication with Another Process">
2822 for alternatives.)
2823
2824 For three or more arguments if MODE is C<'|-'>, the filename is
2825 interpreted as a command to which output is to be piped, and if MODE
2826 is C<'-|'>, the filename is interpreted as a command which pipes
2827 output to us.  In the 2-arguments (and 1-argument) form one should
2828 replace dash (C<'-'>) with the command.
2829 See L<perlipc/"Using open() for IPC"> for more examples of this.
2830 (You are not allowed to C<open> to a command that pipes both in I<and>
2831 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2832 L<perlipc/"Bidirectional Communication"> for alternatives.)
2833
2834 In the three-or-more argument form of pipe opens, if LIST is specified
2835 (extra arguments after the command name) then LIST becomes arguments
2836 to the command invoked if the platform supports it.  The meaning of
2837 C<open> with more than three arguments for non-pipe modes is not yet
2838 specified. Experimental "layers" may give extra LIST arguments
2839 meaning.
2840
2841 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2842 and opening C<< '>-' >> opens STDOUT.
2843
2844 You may use the three-argument form of open to specify IO "layers"
2845 (sometimes also referred to as "disciplines") to be applied to the handle
2846 that affect how the input and output are processed (see L<open> and
2847 L<PerlIO> for more details). For example
2848
2849   open(FH, "<:utf8", "file")
2850
2851 will open the UTF-8 encoded file containing Unicode characters,
2852 see L<perluniintro>. (Note that if layers are specified in the
2853 three-arg form then default layers set by the C<open> pragma are
2854 ignored.)
2855
2856 Open returns nonzero upon success, the undefined value otherwise.  If
2857 the C<open> involved a pipe, the return value happens to be the pid of
2858 the subprocess.
2859
2860 If you're running Perl on a system that distinguishes between text
2861 files and binary files, then you should check out L</binmode> for tips
2862 for dealing with this.  The key distinction between systems that need
2863 C<binmode> and those that don't is their text file formats.  Systems
2864 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2865 character, and which encode that character in C as C<"\n">, do not
2866 need C<binmode>.  The rest need it.
2867
2868 When opening a file, it's usually a bad idea to continue normal execution
2869 if the request failed, so C<open> is frequently used in connection with
2870 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2871 where you want to make a nicely formatted error message (but there are
2872 modules that can help with that problem)) you should always check
2873 the return value from opening a file.  The infrequent exception is when
2874 working with an unopened filehandle is actually what you want to do.
2875
2876 As a special case the 3 arg form with a read/write mode and the third
2877 argument being C<undef>:
2878
2879     open(TMP, "+>", undef) or die ...
2880
2881 opens a filehandle to an anonymous temporary file.  Also using "+<"
2882 works for symmetry, but you really should consider writing something
2883 to the temporary file first.  You will need to seek() to do the
2884 reading.
2885
2886 File handles can be opened to "in memory" files held in Perl scalars via:
2887
2888     open($fh, '>', \$variable) || ..
2889
2890 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2891 file, you have to close it first:
2892
2893     close STDOUT;
2894     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2895
2896 Examples:
2897
2898     $ARTICLE = 100;
2899     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2900     while (<ARTICLE>) {...
2901
2902     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2903     # if the open fails, output is discarded
2904
2905     open(DBASE, '+<', 'dbase.mine')             # open for update
2906         or die "Can't open 'dbase.mine' for update: $!";
2907
2908     open(DBASE, '+<dbase.mine')                 # ditto
2909         or die "Can't open 'dbase.mine' for update: $!";
2910
2911     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2912         or die "Can't start caesar: $!";
2913
2914     open(ARTICLE, "caesar <$article |")         # ditto
2915         or die "Can't start caesar: $!";
2916
2917     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2918         or die "Can't start sort: $!";
2919
2920     # in memory files
2921     open(MEMORY,'>', \$var)
2922         or die "Can't open memory file: $!";
2923     print MEMORY "foo!\n";                      # output will end up in $var
2924
2925     # process argument list of files along with any includes
2926
2927     foreach $file (@ARGV) {
2928         process($file, 'fh00');
2929     }
2930
2931     sub process {
2932         my($filename, $input) = @_;
2933         $input++;               # this is a string increment
2934         unless (open($input, $filename)) {
2935             print STDERR "Can't open $filename: $!\n";
2936             return;
2937         }
2938
2939         local $_;
2940         while (<$input>) {              # note use of indirection
2941             if (/^#include "(.*)"/) {
2942                 process($1, $input);
2943                 next;
2944             }
2945             #...                # whatever
2946         }
2947     }
2948
2949 You may also, in the Bourne shell tradition, specify an EXPR beginning
2950 with C<< '>&' >>, in which case the rest of the string is interpreted
2951 as the name of a filehandle (or file descriptor, if numeric) to be
2952 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
2953 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
2954 The mode you specify should match the mode of the original filehandle.
2955 (Duping a filehandle does not take into account any existing contents
2956 of IO buffers.) If you use the 3 arg form then you can pass either a
2957 number, the name of a filehandle or the normal "reference to a glob".
2958
2959 Here is a script that saves, redirects, and restores C<STDOUT> and
2960 C<STDERR> using various methods:
2961
2962     #!/usr/bin/perl
2963     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2964     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2965
2966     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2967     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2968
2969     select STDERR; $| = 1;      # make unbuffered
2970     select STDOUT; $| = 1;      # make unbuffered
2971
2972     print STDOUT "stdout 1\n";  # this works for
2973     print STDERR "stderr 1\n";  # subprocesses too
2974
2975     close STDOUT;
2976     close STDERR;
2977
2978     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2979     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2980
2981     print STDOUT "stdout 2\n";
2982     print STDERR "stderr 2\n";
2983
2984 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
2985 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
2986 that file descriptor (and not call L<dup(2)>); this is more
2987 parsimonious of file descriptors.  For example:
2988
2989     # open for input, reusing the fileno of $fd
2990     open(FILEHANDLE, "<&=$fd")
2991
2992 or
2993
2994     open(FILEHANDLE, "<&=", $fd)
2995
2996 or
2997
2998     # open for append, using the fileno of OLDFH
2999     open(FH, ">>&=", OLDFH)
3000
3001 or
3002
3003     open(FH, ">>&=OLDFH")
3004
3005 Being parsimonious on filehandles is also useful (besides being
3006 parsimonious) for example when something is dependent on file
3007 descriptors, like for example locking using flock().  If you do just
3008 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3009 descriptor as B, and therefore flock(A) will not flock(B), and vice
3010 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3011 the same file descriptor.
3012
3013 Note that if you are using Perls older than 5.8.0, Perl will be using
3014 the standard C libraries' fdopen() to implement the "=" functionality.
3015 On many UNIX systems fdopen() fails when file descriptors exceed a
3016 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3017 most often the default.
3018
3019 You can see whether Perl has been compiled with PerlIO or not by
3020 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3021 is C<define>, you have PerlIO, otherwise you don't.
3022
3023 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3024 with 2-arguments (or 1-argument) form of open(), then
3025 there is an implicit fork done, and the return value of open is the pid
3026 of the child within the parent process, and C<0> within the child
3027 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3028 The filehandle behaves normally for the parent, but i/o to that
3029 filehandle is piped from/to the STDOUT/STDIN of the child process.
3030 In the child process the filehandle isn't opened--i/o happens from/to
3031 the new STDOUT or STDIN.  Typically this is used like the normal
3032 piped open when you want to exercise more control over just how the
3033 pipe command gets executed, such as when you are running setuid, and
3034 don't want to have to scan shell commands for metacharacters.
3035 The following triples are more or less equivalent:
3036
3037     open(FOO, "|tr '[a-z]' '[A-Z]'");
3038     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3039     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3040     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3041
3042     open(FOO, "cat -n '$file'|");
3043     open(FOO, '-|', "cat -n '$file'");
3044     open(FOO, '-|') || exec 'cat', '-n', $file;
3045     open(FOO, '-|', "cat", '-n', $file);
3046
3047 The last example in each block shows the pipe as "list form", which is
3048 not yet supported on all platforms.  A good rule of thumb is that if
3049 your platform has true C<fork()> (in other words, if your platform is
3050 UNIX) you can use the list form.
3051
3052 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3053
3054 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3055 output before any operation that may do a fork, but this may not be
3056 supported on some platforms (see L<perlport>).  To be safe, you may need
3057 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3058 of C<IO::Handle> on any open handles.
3059
3060 On systems that support a close-on-exec flag on files, the flag will
3061 be set for the newly opened file descriptor as determined by the value
3062 of $^F.  See L<perlvar/$^F>.
3063
3064 Closing any piped filehandle causes the parent process to wait for the
3065 child to finish, and returns the status value in C<$?>.
3066
3067 The filename passed to 2-argument (or 1-argument) form of open() will
3068 have leading and trailing whitespace deleted, and the normal
3069 redirection characters honored.  This property, known as "magic open",
3070 can often be used to good effect.  A user could specify a filename of
3071 F<"rsh cat file |">, or you could change certain filenames as needed:
3072
3073     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3074     open(FH, $filename) or die "Can't open $filename: $!";
3075
3076 Use 3-argument form to open a file with arbitrary weird characters in it,
3077
3078     open(FOO, '<', $file);
3079
3080 otherwise it's necessary to protect any leading and trailing whitespace:
3081
3082     $file =~ s#^(\s)#./$1#;
3083     open(FOO, "< $file\0");
3084
3085 (this may not work on some bizarre filesystems).  One should
3086 conscientiously choose between the I<magic> and 3-arguments form
3087 of open():
3088
3089     open IN, $ARGV[0];
3090
3091 will allow the user to specify an argument of the form C<"rsh cat file |">,
3092 but will not work on a filename which happens to have a trailing space, while
3093
3094     open IN, '<', $ARGV[0];
3095
3096 will have exactly the opposite restrictions.
3097
3098 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3099 should use the C<sysopen> function, which involves no such magic (but
3100 may use subtly different filemodes than Perl open(), which is mapped
3101 to C fopen()).  This is
3102 another way to protect your filenames from interpretation.  For example:
3103
3104     use IO::Handle;
3105     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3106         or die "sysopen $path: $!";
3107     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3108     print HANDLE "stuff $$\n";
3109     seek(HANDLE, 0, 0);
3110     print "File contains: ", <HANDLE>;
3111
3112 Using the constructor from the C<IO::Handle> package (or one of its
3113 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3114 filehandles that have the scope of whatever variables hold references to
3115 them, and automatically close whenever and however you leave that scope:
3116
3117     use IO::File;
3118     #...
3119     sub read_myfile_munged {
3120         my $ALL = shift;
3121         my $handle = new IO::File;
3122         open($handle, "myfile") or die "myfile: $!";
3123         $first = <$handle>
3124             or return ();     # Automatically closed here.
3125         mung $first or die "mung failed";       # Or here.
3126         return $first, <$handle> if $ALL;       # Or here.
3127         $first;                                 # Or here.
3128     }
3129
3130 See L</seek> for some details about mixing reading and writing.
3131
3132 =item opendir DIRHANDLE,EXPR
3133
3134 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3135 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3136 DIRHANDLE may be an expression whose value can be used as an indirect
3137 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3138 scalar variable (or array or hash element), the variable is assigned a
3139 reference to a new anonymous dirhandle.
3140 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3141
3142 =item ord EXPR
3143
3144 =item ord
3145
3146 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3147 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3148 uses C<$_>.
3149
3150 For the reverse, see L</chr>.
3151 See L<perlunicode> and L<encoding> for more about Unicode.
3152
3153 =item our EXPR
3154
3155 =item our EXPR TYPE
3156
3157 =item our EXPR : ATTRS
3158
3159 =item our TYPE EXPR : ATTRS
3160
3161 An C<our> declares the listed variables to be valid globals within
3162 the enclosing block, file, or C<eval>.  That is, it has the same
3163 scoping rules as a "my" declaration, but does not create a local
3164 variable.  If more than one value is listed, the list must be placed
3165 in parentheses.  The C<our> declaration has no semantic effect unless
3166 "use strict vars" is in effect, in which case it lets you use the
3167 declared global variable without qualifying it with a package name.
3168 (But only within the lexical scope of the C<our> declaration.  In this
3169 it differs from "use vars", which is package scoped.)
3170
3171 An C<our> declaration declares a global variable that will be visible
3172 across its entire lexical scope, even across package boundaries.  The
3173 package in which the variable is entered is determined at the point
3174 of the declaration, not at the point of use.  This means the following
3175 behavior holds:
3176
3177     package Foo;
3178     our $bar;           # declares $Foo::bar for rest of lexical scope
3179     $bar = 20;
3180
3181     package Bar;
3182     print $bar;         # prints 20
3183
3184 Multiple C<our> declarations in the same lexical scope are allowed
3185 if they are in different packages.  If they happened to be in the same
3186 package, Perl will emit warnings if you have asked for them.
3187
3188     use warnings;
3189     package Foo;
3190     our $bar;           # declares $Foo::bar for rest of lexical scope
3191     $bar = 20;
3192
3193     package Bar;
3194     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3195     print $bar;         # prints 30
3196
3197     our $bar;           # emits warning
3198
3199 An C<our> declaration may also have a list of attributes associated
3200 with it.
3201
3202 The exact semantics and interface of TYPE and ATTRS are still
3203 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3204 and attributes are handled using the C<attributes> pragma, or starting
3205 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3206 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3207 L<attributes>, and L<Attribute::Handlers>.
3208
3209 The only currently recognized C<our()> attribute is C<unique> which
3210 indicates that a single copy of the global is to be used by all
3211 interpreters should the program happen to be running in a
3212 multi-interpreter environment. (The default behaviour would be for
3213 each interpreter to have its own copy of the global.)  Examples:
3214
3215     our @EXPORT : unique = qw(foo);
3216     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3217     our $VERSION : unique = "1.00";
3218
3219 Note that this attribute also has the effect of making the global
3220 readonly when the first new interpreter is cloned (for example,
3221 when the first new thread is created).
3222
3223 Multi-interpreter environments can come to being either through the
3224 fork() emulation on Windows platforms, or by embedding perl in a
3225 multi-threaded application.  The C<unique> attribute does nothing in
3226 all other environments.
3227
3228 =item pack TEMPLATE,LIST
3229
3230 Takes a LIST of values and converts it into a string using the rules
3231 given by the TEMPLATE.  The resulting string is the concatenation of
3232 the converted values.  Typically, each converted value looks
3233 like its machine-level representation.  For example, on 32-bit machines
3234 a converted integer may be represented by a sequence of 4 bytes.
3235
3236 The TEMPLATE is a sequence of characters that give the order and type
3237 of values, as follows:
3238
3239     a   A string with arbitrary binary data, will be null padded.
3240     A   A text (ASCII) string, will be space padded.
3241     Z   A null terminated (ASCIZ) string, will be null padded.
3242
3243     b   A bit string (ascending bit order inside each byte, like vec()).
3244     B   A bit string (descending bit order inside each byte).
3245     h   A hex string (low nybble first).
3246     H   A hex string (high nybble first).
3247
3248     c   A signed char value.
3249     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3250
3251     s   A signed short value.
3252     S   An unsigned short value.
3253           (This 'short' is _exactly_ 16 bits, which may differ from
3254            what a local C compiler calls 'short'.  If you want
3255            native-length shorts, use the '!' suffix.)
3256
3257     i   A signed integer value.
3258     I   An unsigned integer value.
3259           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3260            size depends on what a local C compiler calls 'int',
3261            and may even be larger than the 'long' described in
3262            the next item.)
3263
3264     l   A signed long value.
3265     L   An unsigned long value.
3266           (This 'long' is _exactly_ 32 bits, which may differ from
3267            what a local C compiler calls 'long'.  If you want
3268            native-length longs, use the '!' suffix.)
3269
3270     n   An unsigned short in "network" (big-endian) order.
3271     N   An unsigned long in "network" (big-endian) order.
3272     v   An unsigned short in "VAX" (little-endian) order.
3273     V   An unsigned long in "VAX" (little-endian) order.
3274           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3275            _exactly_ 32 bits, respectively.)
3276
3277     q   A signed quad (64-bit) value.
3278     Q   An unsigned quad value.
3279           (Quads are available only if your system supports 64-bit
3280            integer values _and_ if Perl has been compiled to support those.
3281            Causes a fatal error otherwise.)
3282
3283     j   A signed integer value (a Perl internal integer, IV).
3284     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3285
3286     f   A single-precision float in the native format.
3287     d   A double-precision float in the native format.
3288
3289     F   A floating point value in the native native format
3290            (a Perl internal floating point value, NV).
3291     D   A long double-precision float in the native format.
3292           (Long doubles are available only if your system supports long
3293            double values _and_ if Perl has been compiled to support those.
3294            Causes a fatal error otherwise.)
3295
3296     p   A pointer to a null-terminated string.
3297     P   A pointer to a structure (fixed-length string).
3298
3299     u   A uuencoded string.
3300     U   A Unicode character number.  Encodes to UTF-8 internally
3301         (or UTF-EBCDIC in EBCDIC platforms).
3302
3303     w   A BER compressed integer.  Its bytes represent an unsigned
3304         integer in base 128, most significant digit first, with as
3305         few digits as possible.  Bit eight (the high bit) is set
3306         on each byte except the last.
3307
3308     x   A null byte.
3309     X   Back up a byte.
3310     @   Null fill to absolute position, counted from the start of
3311         the innermost ()-group.
3312     (   Start of a ()-group.
3313
3314 The following rules apply:
3315
3316 =over 8
3317
3318 =item *
3319
3320 Each letter may optionally be followed by a number giving a repeat
3321 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3322 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3323 many values from the LIST.  A C<*> for the repeat count means to use
3324 however many items are left, except for C<@>, C<x>, C<X>, where it is
3325 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3326 is the same).  A numeric repeat count may optionally be enclosed in
3327 brackets, as in C<pack 'C[80]', @arr>.
3328
3329 One can replace the numeric repeat count by a template enclosed in brackets;
3330 then the packed length of this template in bytes is used as a count.
3331 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3332 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3333 If the template in brackets contains alignment commands (such as C<x![d]>),
3334 its packed length is calculated as if the start of the template has the maximal
3335 possible alignment.
3336
3337 When used with C<Z>, C<*> results in the addition of a trailing null
3338 byte (so the packed result will be one longer than the byte C<length>
3339 of the item).
3340
3341 The repeat count for C<u> is interpreted as the maximal number of bytes
3342 to encode per line of output, with 0 and 1 replaced by 45.
3343
3344 =item *
3345
3346 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3347 string of length count, padding with nulls or spaces as necessary.  When
3348 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3349 after the first null, and C<a> returns data verbatim.  When packing,
3350 C<a>, and C<Z> are equivalent.
3351
3352 If the value-to-pack is too long, it is truncated.  If too long and an
3353 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3354 by a null byte.  Thus C<Z> always packs a trailing null byte under
3355 all circumstances.
3356
3357 =item *
3358
3359 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3360 Each byte of the input field of pack() generates 1 bit of the result.
3361 Each result bit is based on the least-significant bit of the corresponding
3362 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3363 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3364
3365 Starting from the beginning of the input string of pack(), each 8-tuple
3366 of bytes is converted to 1 byte of output.  With format C<b>
3367 the first byte of the 8-tuple determines the least-significant bit of a
3368 byte, and with format C<B> it determines the most-significant bit of
3369 a byte.
3370
3371 If the length of the input string is not exactly divisible by 8, the
3372 remainder is packed as if the input string were padded by null bytes
3373 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3374
3375 If the input string of pack() is longer than needed, extra bytes are ignored.
3376 A C<*> for the repeat count of pack() means to use all the bytes of
3377 the input field.  On unpack()ing the bits are converted to a string
3378 of C<"0">s and C<"1">s.
3379
3380 =item *
3381
3382 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3383 representable as hexadecimal digits, 0-9a-f) long.
3384
3385 Each byte of the input field of pack() generates 4 bits of the result.
3386 For non-alphabetical bytes the result is based on the 4 least-significant
3387 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3388 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3389 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3390 is compatible with the usual hexadecimal digits, so that C<"a"> and
3391 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3392 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3393
3394 Starting from the beginning of the input string of pack(), each pair
3395 of bytes is converted to 1 byte of output.  With format C<h> the
3396 first byte of the pair determines the least-significant nybble of the
3397 output byte, and with format C<H> it determines the most-significant
3398 nybble.
3399
3400 If the length of the input string is not even, it behaves as if padded
3401 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3402 nybbles are ignored.
3403
3404 If the input string of pack() is longer than needed, extra bytes are ignored.
3405 A C<*> for the repeat count of pack() means to use all the bytes of
3406 the input field.  On unpack()ing the bits are converted to a string
3407 of hexadecimal digits.
3408
3409 =item *
3410
3411 The C<p> type packs a pointer to a null-terminated string.  You are
3412 responsible for ensuring the string is not a temporary value (which can
3413 potentially get deallocated before you get around to using the packed result).
3414 The C<P> type packs a pointer to a structure of the size indicated by the
3415 length.  A NULL pointer is created if the corresponding value for C<p> or
3416 C<P> is C<undef>, similarly for unpack().
3417
3418 =item *
3419
3420 The C</> template character allows packing and unpacking of strings where
3421 the packed structure contains a byte count followed by the string itself.
3422 You write I<length-item>C</>I<string-item>.
3423
3424 The I<length-item> can be any C<pack> template letter, and describes
3425 how the length value is packed.  The ones likely to be of most use are
3426 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3427 SNMP) and C<N> (for Sun XDR).
3428
3429 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3430 C<"Z*">. For C<unpack> the length of the string is obtained from the
3431 I<length-item>, but if you put in the '*' it will be ignored. For all other
3432 codes, C<unpack> applies the length value to the next item, which must not
3433 have a repeat count.
3434
3435     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3436     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3437     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3438
3439 The I<length-item> is not returned explicitly from C<unpack>.
3440
3441 Adding a count to the I<length-item> letter is unlikely to do anything
3442 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3443 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3444 which Perl does not regard as legal in numeric strings.
3445
3446 =item *
3447
3448 The integer types C<s>, C<S>, C<l>, and C<L> may be
3449 immediately followed by a C<!> suffix to signify native shorts or
3450 longs--as you can see from above for example a bare C<l> does mean
3451 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3452 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3453 see whether using C<!> makes any difference by
3454
3455         print length(pack("s")), " ", length(pack("s!")), "\n";
3456         print length(pack("l")), " ", length(pack("l!")), "\n";
3457
3458 C<i!> and C<I!> also work but only because of completeness;
3459 they are identical to C<i> and C<I>.
3460
3461 The actual sizes (in bytes) of native shorts, ints, longs, and long
3462 longs on the platform where Perl was built are also available via
3463 L<Config>:
3464
3465        use Config;
3466        print $Config{shortsize},    "\n";
3467        print $Config{intsize},      "\n";
3468        print $Config{longsize},     "\n";
3469        print $Config{longlongsize}, "\n";
3470
3471 (The C<$Config{longlongsize}> will be undefined if your system does
3472 not support long longs.)
3473
3474 =item *
3475
3476 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3477 are inherently non-portable between processors and operating systems
3478 because they obey the native byteorder and endianness.  For example a
3479 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3480 (arranged in and handled by the CPU registers) into bytes as
3481
3482         0x12 0x34 0x56 0x78     # big-endian
3483         0x78 0x56 0x34 0x12     # little-endian
3484
3485 Basically, the Intel and VAX CPUs are little-endian, while everybody
3486 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3487 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3488 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3489 mode.
3490
3491 The names `big-endian' and `little-endian' are comic references to
3492 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3493 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3494 the egg-eating habits of the Lilliputians.
3495
3496 Some systems may have even weirder byte orders such as
3497
3498         0x56 0x78 0x12 0x34
3499         0x34 0x12 0x78 0x56
3500
3501 You can see your system's preference with
3502
3503         print join(" ", map { sprintf "%#02x", $_ }
3504                             unpack("C*",pack("L",0x12345678))), "\n";
3505
3506 The byteorder on the platform where Perl was built is also available
3507 via L<Config>:
3508
3509         use Config;
3510         print $Config{byteorder}, "\n";
3511
3512 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3513 and C<'87654321'> are big-endian.
3514
3515 If you want portable packed integers use the formats C<n>, C<N>,
3516 C<v>, and C<V>, their byte endianness and size are known.
3517 See also L<perlport>.
3518
3519 =item *
3520
3521 Real numbers (floats and doubles) are in the native machine format only;
3522 due to the multiplicity of floating formats around, and the lack of a
3523 standard "network" representation, no facility for interchange has been
3524 made.  This means that packed floating point data written on one machine
3525 may not be readable on another - even if both use IEEE floating point
3526 arithmetic (as the endian-ness of the memory representation is not part
3527 of the IEEE spec).  See also L<perlport>.
3528
3529 Note that Perl uses doubles internally for all numeric calculation, and
3530 converting from double into float and thence back to double again will
3531 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3532 equal $foo).
3533
3534 =item *
3535
3536 If the pattern begins with a C<U>, the resulting string will be
3537 treated as UTF-8-encoded Unicode. You can force UTF-8 encoding on in a
3538 string with an initial C<U0>, and the bytes that follow will be
3539 interpreted as Unicode characters. If you don't want this to happen,
3540 you can begin your pattern with C<C0> (or anything else) to force Perl
3541 not to UTF-8 encode your string, and then follow this with a C<U*>
3542 somewhere in your pattern.
3543
3544 =item *
3545
3546 You must yourself do any alignment or padding by inserting for example
3547 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3548 could know where the bytes are going to or coming from.  Therefore
3549 C<pack> (and C<unpack>) handle their output and input as flat
3550 sequences of bytes.
3551
3552 =item *
3553
3554 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3555 take a repeat count, both as postfix, and for unpack() also via the C</>
3556 template character. Within each repetition of a group, positioning with
3557 C<@> starts again at 0. Therefore, the result of
3558
3559     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3560
3561 is the string "\0a\0\0bc".
3562
3563
3564 =item *
3565
3566 C<x> and C<X> accept C<!> modifier.  In this case they act as
3567 alignment commands: they jump forward/back to the closest position
3568 aligned at a multiple of C<count> bytes.  For example, to pack() or
3569 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3570 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3571 aligned on the double's size.
3572
3573 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3574 both result in no-ops.
3575
3576 =item *
3577
3578 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3579 White space may be used to separate pack codes from each other, but
3580 a C<!> modifier and a repeat count must follow immediately.
3581
3582 =item *
3583
3584 If TEMPLATE requires more arguments to pack() than actually given, pack()
3585 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3586 to pack() than actually given, extra arguments are ignored.
3587
3588 =back
3589
3590 Examples:
3591
3592     $foo = pack("CCCC",65,66,67,68);
3593     # foo eq "ABCD"
3594     $foo = pack("C4",65,66,67,68);
3595     # same thing
3596     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3597     # same thing with Unicode circled letters
3598
3599     $foo = pack("ccxxcc",65,66,67,68);
3600     # foo eq "AB\0\0CD"
3601
3602     # note: the above examples featuring "C" and "c" are true
3603     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3604     # and UTF-8.  In EBCDIC the first example would be
3605     # $foo = pack("CCCC",193,194,195,196);
3606
3607     $foo = pack("s2",1,2);
3608     # "\1\0\2\0" on little-endian
3609     # "\0\1\0\2" on big-endian
3610
3611     $foo = pack("a4","abcd","x","y","z");
3612     # "abcd"
3613
3614     $foo = pack("aaaa","abcd","x","y","z");
3615     # "axyz"
3616
3617     $foo = pack("a14","abcdefg");
3618     # "abcdefg\0\0\0\0\0\0\0"
3619
3620     $foo = pack("i9pl", gmtime);
3621     # a real struct tm (on my system anyway)
3622
3623     $utmp_template = "Z8 Z8 Z16 L";
3624     $utmp = pack($utmp_template, @utmp1);
3625     # a struct utmp (BSDish)
3626
3627     @utmp2 = unpack($utmp_template, $utmp);
3628     # "@utmp1" eq "@utmp2"
3629
3630     sub bintodec {
3631         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3632     }
3633
3634     $foo = pack('sx2l', 12, 34);
3635     # short 12, two zero bytes padding, long 34
3636     $bar = pack('s@4l', 12, 34);
3637     # short 12, zero fill to position 4, long 34
3638     # $foo eq $bar
3639
3640 The same template may generally also be used in unpack().
3641
3642 =item package NAMESPACE
3643
3644 =item package
3645
3646 Declares the compilation unit as being in the given namespace.  The scope
3647 of the package declaration is from the declaration itself through the end
3648 of the enclosing block, file, or eval (the same as the C<my> operator).
3649 All further unqualified dynamic identifiers will be in this namespace.
3650 A package statement affects only dynamic variables--including those
3651 you've used C<local> on--but I<not> lexical variables, which are created
3652 with C<my>.  Typically it would be the first declaration in a file to
3653 be included by the C<require> or C<use> operator.  You can switch into a
3654 package in more than one place; it merely influences which symbol table
3655 is used by the compiler for the rest of that block.  You can refer to
3656 variables and filehandles in other packages by prefixing the identifier
3657 with the package name and a double colon:  C<$Package::Variable>.
3658 If the package name is null, the C<main> package as assumed.  That is,
3659 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3660 still seen in older code).
3661
3662 If NAMESPACE is omitted, then there is no current package, and all
3663 identifiers must be fully qualified or lexicals.  However, you are
3664 strongly advised not to make use of this feature. Its use can cause
3665 unexpected behaviour, even crashing some versions of Perl. It is
3666 deprecated, and will be removed from a future release.
3667
3668 See L<perlmod/"Packages"> for more information about packages, modules,
3669 and classes.  See L<perlsub> for other scoping issues.
3670
3671 =item pipe READHANDLE,WRITEHANDLE
3672
3673 Opens a pair of connected pipes like the corresponding system call.
3674 Note that if you set up a loop of piped processes, deadlock can occur
3675 unless you are very careful.  In addition, note that Perl's pipes use
3676 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3677 after each command, depending on the application.
3678
3679 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3680 for examples of such things.
3681
3682 On systems that support a close-on-exec flag on files, the flag will be set
3683 for the newly opened file descriptors as determined by the value of $^F.
3684 See L<perlvar/$^F>.
3685
3686 =item pop ARRAY
3687
3688 =item pop
3689
3690 Pops and returns the last value of the array, shortening the array by
3691 one element.  Has an effect similar to
3692
3693     $ARRAY[$#ARRAY--]
3694
3695 If there are no elements in the array, returns the undefined value
3696 (although this may happen at other times as well).  If ARRAY is
3697 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3698 array in subroutines, just like C<shift>.
3699
3700 =item pos SCALAR
3701
3702 =item pos
3703
3704 Returns the offset of where the last C<m//g> search left off for the variable
3705 in question (C<$_> is used when the variable is not specified).  May be
3706 modified to change that offset.  Such modification will also influence
3707 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3708 L<perlop>.
3709
3710 =item print FILEHANDLE LIST
3711
3712 =item print LIST
3713
3714 =item print
3715
3716 Prints a string or a list of strings.  Returns true if successful.
3717 FILEHANDLE may be a scalar variable name, in which case the variable
3718 contains the name of or a reference to the filehandle, thus introducing
3719 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3720 the next token is a term, it may be misinterpreted as an operator
3721 unless you interpose a C<+> or put parentheses around the arguments.)
3722 If FILEHANDLE is omitted, prints by default to standard output (or
3723 to the last selected output channel--see L</select>).  If LIST is
3724 also omitted, prints C<$_> to the currently selected output channel.
3725 To set the default output channel to something other than STDOUT
3726 use the select operation.  The current value of C<$,> (if any) is
3727 printed between each LIST item.  The current value of C<$\> (if
3728 any) is printed after the entire LIST has been printed.  Because
3729 print takes a LIST, anything in the LIST is evaluated in list
3730 context, and any subroutine that you call will have one or more of
3731 its expressions evaluated in list context.  Also be careful not to
3732 follow the print keyword with a left parenthesis unless you want
3733 the corresponding right parenthesis to terminate the arguments to
3734 the print--interpose a C<+> or put parentheses around all the
3735 arguments.
3736
3737 Note that if you're storing FILEHANDLES in an array or other expression,
3738 you will have to use a block returning its value instead:
3739
3740     print { $files[$i] } "stuff\n";
3741     print { $OK ? STDOUT : STDERR } "stuff\n";
3742
3743 =item printf FILEHANDLE FORMAT, LIST
3744
3745 =item printf FORMAT, LIST
3746
3747 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3748 (the output record separator) is not appended.  The first argument
3749 of the list will be interpreted as the C<printf> format. See C<sprintf>
3750 for an explanation of the format argument. If C<use locale> is in effect,
3751 the character used for the decimal point in formatted real numbers is
3752 affected by the LC_NUMERIC locale.  See L<perllocale>.
3753
3754 Don't fall into the trap of using a C<printf> when a simple
3755 C<print> would do.  The C<print> is more efficient and less
3756 error prone.
3757
3758 =item prototype FUNCTION
3759
3760 Returns the prototype of a function as a string (or C<undef> if the
3761 function has no prototype).  FUNCTION is a reference to, or the name of,
3762 the function whose prototype you want to retrieve.
3763
3764 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3765 name for Perl builtin.  If the builtin is not I<overridable> (such as
3766 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3767 C<system>) returns C<undef> because the builtin does not really behave
3768 like a Perl function.  Otherwise, the string describing the equivalent
3769 prototype is returned.
3770
3771 =item push ARRAY,LIST
3772
3773 Treats ARRAY as a stack, and pushes the values of LIST
3774 onto the end of ARRAY.  The length of ARRAY increases by the length of
3775 LIST.  Has the same effect as
3776
3777     for $value (LIST) {
3778         $ARRAY[++$#ARRAY] = $value;
3779     }
3780
3781 but is more efficient.  Returns the new number of elements in the array.
3782
3783 =item q/STRING/
3784
3785 =item qq/STRING/
3786
3787 =item qr/STRING/
3788
3789 =item qx/STRING/
3790
3791 =item qw/STRING/
3792
3793 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3794
3795 =item quotemeta EXPR
3796
3797 =item quotemeta
3798
3799 Returns the value of EXPR with all non-"word"
3800 characters backslashed.  (That is, all characters not matching
3801 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3802 returned string, regardless of any locale settings.)
3803 This is the internal function implementing
3804 the C<\Q> escape in double-quoted strings.
3805
3806 If EXPR is omitted, uses C<$_>.
3807
3808 =item rand EXPR
3809
3810 =item rand
3811
3812 Returns a random fractional number greater than or equal to C<0> and less
3813 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3814 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3815 also special-cased as C<1> - this has not been documented before perl 5.8.0
3816 and is subject to change in future versions of perl.  Automatically calls
3817 C<srand> unless C<srand> has already been called.  See also C<srand>.
3818
3819 Apply C<int()> to the value returned by C<rand()> if you want random
3820 integers instead of random fractional numbers.  For example,
3821
3822     int(rand(10))
3823
3824 returns a random integer between C<0> and C<9>, inclusive.
3825
3826 (Note: If your rand function consistently returns numbers that are too
3827 large or too small, then your version of Perl was probably compiled
3828 with the wrong number of RANDBITS.)
3829
3830 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3831
3832 =item read FILEHANDLE,SCALAR,LENGTH
3833
3834 Attempts to read LENGTH I<characters> of data into variable SCALAR
3835 from the specified FILEHANDLE.  Returns the number of characters
3836 actually read, C<0> at end of file, or undef if there was an error (in
3837 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
3838 so that the last character actually read is the last character of the
3839 scalar after the read.
3840
3841 An OFFSET may be specified to place the read data at some place in the
3842 string other than the beginning.  A negative OFFSET specifies
3843 placement at that many characters counting backwards from the end of
3844 the string.  A positive OFFSET greater than the length of SCALAR
3845 results in the string being padded to the required size with C<"\0">
3846 bytes before the result of the read is appended.
3847
3848 The call is actually implemented in terms of either Perl's or system's
3849 fread() call.  To get a true read(2) system call, see C<sysread>.
3850
3851 Note the I<characters>: depending on the status of the filehandle,
3852 either (8-bit) bytes or characters are read.  By default all
3853 filehandles operate on bytes, but for example if the filehandle has
3854 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3855 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3856 characters, not bytes.  Similarly for the C<:encoding> pragma:
3857 in that case pretty much any characters can be read.
3858
3859 =item readdir DIRHANDLE
3860
3861 Returns the next directory entry for a directory opened by C<opendir>.
3862 If used in list context, returns all the rest of the entries in the
3863 directory.  If there are no more entries, returns an undefined value in
3864 scalar context or a null list in list context.
3865
3866 If you're planning to filetest the return values out of a C<readdir>, you'd
3867 better prepend the directory in question.  Otherwise, because we didn't
3868 C<chdir> there, it would have been testing the wrong file.
3869
3870     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3871     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3872     closedir DIR;
3873
3874 =item readline EXPR
3875
3876 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3877 context, each call reads and returns the next line, until end-of-file is
3878 reached, whereupon the subsequent call returns undef.  In list context,
3879 reads until end-of-file is reached and returns a list of lines.  Note that
3880 the notion of "line" used here is however you may have defined it
3881 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3882
3883 When C<$/> is set to C<undef>, when readline() is in scalar
3884 context (i.e. file slurp mode), and when an empty file is read, it
3885 returns C<''> the first time, followed by C<undef> subsequently.
3886
3887 This is the internal function implementing the C<< <EXPR> >>
3888 operator, but you can use it directly.  The C<< <EXPR> >>
3889 operator is discussed in more detail in L<perlop/"I/O Operators">.
3890
3891     $line = <STDIN>;
3892     $line = readline(*STDIN);           # same thing
3893
3894 If readline encounters an operating system error, C<$!> will be set with the
3895 corresponding error message.  It can be helpful to check C<$!> when you are
3896 reading from filehandles you don't trust, such as a tty or a socket.  The
3897 following example uses the operator form of C<readline>, and takes the necessary
3898 steps to ensure that C<readline> was successful.
3899
3900     for (;;) {
3901         undef $!;
3902         unless (defined( $line = <> )) {
3903             die $! if $!;
3904             last; # reached EOF
3905         }
3906         # ...
3907     }
3908
3909 =item readlink EXPR
3910
3911 =item readlink
3912
3913 Returns the value of a symbolic link, if symbolic links are
3914 implemented.  If not, gives a fatal error.  If there is some system
3915 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3916 omitted, uses C<$_>.
3917
3918 =item readpipe EXPR
3919
3920 EXPR is executed as a system command.
3921 The collected standard output of the command is returned.
3922 In scalar context, it comes back as a single (potentially
3923 multi-line) string.  In list context, returns a list of lines
3924 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3925 This is the internal function implementing the C<qx/EXPR/>
3926 operator, but you can use it directly.  The C<qx/EXPR/>
3927 operator is discussed in more detail in L<perlop/"I/O Operators">.
3928
3929 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3930
3931 Receives a message on a socket.  Attempts to receive LENGTH characters
3932 of data into variable SCALAR from the specified SOCKET filehandle.
3933 SCALAR will be grown or shrunk to the length actually read.  Takes the
3934 same flags as the system call of the same name.  Returns the address
3935 of the sender if SOCKET's protocol supports this; returns an empty
3936 string otherwise.  If there's an error, returns the undefined value.
3937 This call is actually implemented in terms of recvfrom(2) system call.
3938 See L<perlipc/"UDP: Message Passing"> for examples.
3939
3940 Note the I<characters>: depending on the status of the socket, either
3941 (8-bit) bytes or characters are received.  By default all sockets
3942 operate on bytes, but for example if the socket has been changed using
3943 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
3944 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
3945 characters, not bytes.  Similarly for the C<:encoding> pragma:
3946 in that case pretty much any characters can be read.
3947
3948 =item redo LABEL
3949
3950 =item redo
3951
3952 The C<redo> command restarts the loop block without evaluating the
3953 conditional again.  The C<continue> block, if any, is not executed.  If
3954 the LABEL is omitted, the command refers to the innermost enclosing
3955 loop.  This command is normally used by programs that want to lie to
3956 themselves about what was just input:
3957
3958     # a simpleminded Pascal comment stripper
3959     # (warning: assumes no { or } in strings)
3960     LINE: while (<STDIN>) {
3961         while (s|({.*}.*){.*}|$1 |) {}
3962         s|{.*}| |;
3963         if (s|{.*| |) {
3964             $front = $_;
3965             while (<STDIN>) {
3966                 if (/}/) {      # end of comment?
3967                     s|^|$front\{|;
3968                     redo LINE;
3969                 }
3970             }
3971         }
3972         print;
3973     }
3974
3975 C<redo> cannot be used to retry a block which returns a value such as
3976 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3977 a grep() or map() operation.
3978
3979 Note that a block by itself is semantically identical to a loop
3980 that executes once.  Thus C<redo> inside such a block will effectively
3981 turn it into a looping construct.
3982
3983 See also L</continue> for an illustration of how C<last>, C<next>, and
3984 C<redo> work.
3985
3986 =item ref EXPR
3987
3988 =item ref
3989
3990 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3991 is not specified, C<$_> will be used.  The value returned depends on the
3992 type of thing the reference is a reference to.
3993 Builtin types include:
3994
3995     SCALAR
3996     ARRAY
3997     HASH
3998     CODE
3999     REF
4000     GLOB
4001     LVALUE
4002
4003 If the referenced object has been blessed into a package, then that package
4004 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4005
4006     if (ref($r) eq "HASH") {
4007         print "r is a reference to a hash.\n";
4008     }
4009     unless (ref($r)) {
4010         print "r is not a reference at all.\n";
4011     }
4012     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
4013         print "r is a reference to something that isa hash.\n";
4014     }
4015
4016 See also L<perlref>.
4017
4018 =item rename OLDNAME,NEWNAME
4019
4020 Changes the name of a file; an existing file NEWNAME will be
4021 clobbered.  Returns true for success, false otherwise.
4022
4023 Behavior of this function varies wildly depending on your system
4024 implementation.  For example, it will usually not work across file system
4025 boundaries, even though the system I<mv> command sometimes compensates
4026 for this.  Other restrictions include whether it works on directories,
4027 open files, or pre-existing files.  Check L<perlport> and either the
4028 rename(2) manpage or equivalent system documentation for details.
4029
4030 =item require VERSION
4031
4032 =item require EXPR
4033
4034 =item require
4035
4036 Demands a version of Perl specified by VERSION, or demands some semantics
4037 specified by EXPR or by C<$_> if EXPR is not supplied.
4038
4039 VERSION may be either a numeric argument such as 5.006, which will be
4040 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4041 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4042 VERSION is greater than the version of the current Perl interpreter.
4043 Compare with L</use>, which can do a similar check at compile time.
4044
4045 Specifying VERSION as a literal of the form v5.6.1 should generally be
4046 avoided, because it leads to misleading error messages under earlier
4047 versions of Perl which do not support this syntax.  The equivalent numeric
4048 version should be used instead.
4049
4050     require v5.6.1;     # run time version check
4051     require 5.6.1;      # ditto
4052     require 5.006_001;  # ditto; preferred for backwards compatibility
4053
4054 Otherwise, demands that a library file be included if it hasn't already
4055 been included.  The file is included via the do-FILE mechanism, which is
4056 essentially just a variety of C<eval>.  Has semantics similar to the following
4057 subroutine:
4058
4059     sub require {
4060         my($filename) = @_;
4061         return 1 if $INC{$filename};
4062         my($realfilename,$result);
4063         ITER: {
4064             foreach $prefix (@INC) {
4065                 $realfilename = "$prefix/$filename";
4066                 if (-f $realfilename) {
4067                     $INC{$filename} = $realfilename;
4068                     $result = do $realfilename;
4069                     last ITER;
4070                 }
4071             }
4072             die "Can't find $filename in \@INC";
4073         }
4074         delete $INC{$filename} if $@ || !$result;
4075         die $@ if $@;
4076         die "$filename did not return true value" unless $result;
4077         return $result;
4078     }
4079
4080 Note that the file will not be included twice under the same specified
4081 name.  The file must return true as the last statement to indicate
4082 successful execution of any initialization code, so it's customary to
4083 end such a file with C<1;> unless you're sure it'll return true
4084 otherwise.  But it's better just to put the C<1;>, in case you add more
4085 statements.
4086
4087 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4088 replaces "F<::>" with "F</>" in the filename for you,
4089 to make it easy to load standard modules.  This form of loading of
4090 modules does not risk altering your namespace.
4091
4092 In other words, if you try this:
4093
4094         require Foo::Bar;    # a splendid bareword
4095
4096 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4097 directories specified in the C<@INC> array.
4098
4099 But if you try this:
4100
4101         $class = 'Foo::Bar';
4102         require $class;      # $class is not a bareword
4103     #or
4104         require "Foo::Bar";  # not a bareword because of the ""
4105
4106 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4107 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4108
4109         eval "require $class";
4110
4111 Now that you understand how C<require> looks for files in the case of
4112 a bareword argument, there is a little extra functionality going on
4113 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4114 it will first look for a filename with a "F<.pmc>" extension.  A file
4115 with this extension is assumed to be Perl bytecode generated by
4116 L<B::Bytecode|B::Bytecode>.  If this file is found, and it's modification
4117 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4118 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4119
4120 You can also insert hooks into the import facility, by putting directly
4121 Perl code into the @INC array.  There are three forms of hooks: subroutine
4122 references, array references and blessed objects.
4123
4124 Subroutine references are the simplest case.  When the inclusion system
4125 walks through @INC and encounters a subroutine, this subroutine gets
4126 called with two parameters, the first being a reference to itself, and the
4127 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4128 subroutine should return C<undef> or a filehandle, from which the file to
4129 include will be read.  If C<undef> is returned, C<require> will look at
4130 the remaining elements of @INC.
4131
4132 If the hook is an array reference, its first element must be a subroutine
4133 reference.  This subroutine is called as above, but the first parameter is
4134 the array reference.  This enables to pass indirectly some arguments to
4135 the subroutine.
4136
4137 In other words, you can write:
4138
4139     push @INC, \&my_sub;
4140     sub my_sub {
4141         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4142         ...
4143     }
4144
4145 or:
4146
4147     push @INC, [ \&my_sub, $x, $y, ... ];
4148     sub my_sub {
4149         my ($arrayref, $filename) = @_;
4150         # Retrieve $x, $y, ...
4151         my @parameters = @$arrayref[1..$#$arrayref];
4152         ...
4153     }
4154
4155 If the hook is an object, it must provide an INC method, that will be
4156 called as above, the first parameter being the object itself.  (Note that
4157 you must fully qualify the sub's name, as it is always forced into package
4158 C<main>.)  Here is a typical code layout:
4159
4160     # In Foo.pm
4161     package Foo;
4162     sub new { ... }
4163     sub Foo::INC {
4164         my ($self, $filename) = @_;
4165         ...
4166     }
4167
4168     # In the main program
4169     push @INC, new Foo(...);
4170
4171 Note that these hooks are also permitted to set the %INC entry
4172 corresponding to the files they have loaded. See L<perlvar/%INC>.
4173
4174 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4175
4176 =item reset EXPR
4177
4178 =item reset
4179
4180 Generally used in a C<continue> block at the end of a loop to clear
4181 variables and reset C<??> searches so that they work again.  The
4182 expression is interpreted as a list of single characters (hyphens
4183 allowed for ranges).  All variables and arrays beginning with one of
4184 those letters are reset to their pristine state.  If the expression is
4185 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4186 only variables or searches in the current package.  Always returns
4187 1.  Examples:
4188
4189     reset 'X';          # reset all X variables
4190     reset 'a-z';        # reset lower case variables
4191     reset;              # just reset ?one-time? searches
4192
4193 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4194 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4195 variables--lexical variables are unaffected, but they clean themselves
4196 up on scope exit anyway, so you'll probably want to use them instead.
4197 See L</my>.
4198
4199 =item return EXPR
4200
4201 =item return
4202
4203 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4204 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4205 context, depending on how the return value will be used, and the context
4206 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4207 is given, returns an empty list in list context, the undefined value in
4208 scalar context, and (of course) nothing at all in a void context.
4209
4210 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4211 or do FILE will automatically return the value of the last expression
4212 evaluated.)
4213
4214 =item reverse LIST
4215
4216 In list context, returns a list value consisting of the elements
4217 of LIST in the opposite order.  In scalar context, concatenates the
4218 elements of LIST and returns a string value with all characters
4219 in the opposite order.
4220
4221     print reverse <>;           # line tac, last line first
4222
4223     undef $/;                   # for efficiency of <>
4224     print scalar reverse <>;    # character tac, last line tsrif
4225
4226 This operator is also handy for inverting a hash, although there are some
4227 caveats.  If a value is duplicated in the original hash, only one of those
4228 can be represented as a key in the inverted hash.  Also, this has to
4229 unwind one hash and build a whole new one, which may take some time
4230 on a large hash, such as from a DBM file.
4231
4232     %by_name = reverse %by_address;     # Invert the hash
4233
4234 =item rewinddir DIRHANDLE
4235
4236 Sets the current position to the beginning of the directory for the
4237 C<readdir> routine on DIRHANDLE.
4238
4239 =item rindex STR,SUBSTR,POSITION
4240
4241 =item rindex STR,SUBSTR
4242
4243 Works just like index() except that it returns the position of the LAST
4244 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4245 last occurrence at or before that position.
4246
4247 =item rmdir FILENAME
4248
4249 =item rmdir
4250
4251 Deletes the directory specified by FILENAME if that directory is
4252 empty.  If it succeeds it returns true, otherwise it returns false and
4253 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4254
4255 =item s///
4256
4257 The substitution operator.  See L<perlop>.
4258
4259 =item scalar EXPR
4260
4261 Forces EXPR to be interpreted in scalar context and returns the value
4262 of EXPR.
4263
4264     @counts = ( scalar @a, scalar @b, scalar @c );
4265
4266 There is no equivalent operator to force an expression to
4267 be interpolated in list context because in practice, this is never
4268 needed.  If you really wanted to do so, however, you could use
4269 the construction C<@{[ (some expression) ]}>, but usually a simple
4270 C<(some expression)> suffices.
4271
4272 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4273 parenthesized list, this behaves as a scalar comma expression, evaluating
4274 all but the last element in void context and returning the final element
4275 evaluated in scalar context.  This is seldom what you want.
4276
4277 The following single statement:
4278
4279         print uc(scalar(&foo,$bar)),$baz;
4280
4281 is the moral equivalent of these two:
4282
4283         &foo;
4284         print(uc($bar),$baz);
4285
4286 See L<perlop> for more details on unary operators and the comma operator.
4287
4288 =item seek FILEHANDLE,POSITION,WHENCE
4289
4290 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4291 FILEHANDLE may be an expression whose value gives the name of the
4292 filehandle.  The values for WHENCE are C<0> to set the new position
4293 I<in bytes> to POSITION, C<1> to set it to the current position plus
4294 POSITION, and C<2> to set it to EOF plus POSITION (typically
4295 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4296 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4297 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4298 otherwise.
4299
4300 Note the I<in bytes>: even if the filehandle has been set to
4301 operate on characters (for example by using the C<:utf8> open
4302 layer), tell() will return byte offsets, not character offsets
4303 (because implementing that would render seek() and tell() rather slow).
4304
4305 If you want to position file for C<sysread> or C<syswrite>, don't use
4306 C<seek>--buffering makes its effect on the file's system position
4307 unpredictable and non-portable.  Use C<sysseek> instead.
4308
4309 Due to the rules and rigors of ANSI C, on some systems you have to do a
4310 seek whenever you switch between reading and writing.  Amongst other
4311 things, this may have the effect of calling stdio's clearerr(3).
4312 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4313
4314     seek(TEST,0,1);
4315
4316 This is also useful for applications emulating C<tail -f>.  Once you hit
4317 EOF on your read, and then sleep for a while, you might have to stick in a
4318 seek() to reset things.  The C<seek> doesn't change the current position,
4319 but it I<does> clear the end-of-file condition on the handle, so that the
4320 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4321
4322 If that doesn't work (some IO implementations are particularly
4323 cantankerous), then you may need something more like this:
4324
4325     for (;;) {
4326         for ($curpos = tell(FILE); $_ = <FILE>;
4327              $curpos = tell(FILE)) {
4328             # search for some stuff and put it into files
4329         }
4330         sleep($for_a_while);
4331         seek(FILE, $curpos, 0);
4332     }
4333
4334 =item seekdir DIRHANDLE,POS
4335
4336 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4337 must be a value returned by C<telldir>.  Has the same caveats about
4338 possible directory compaction as the corresponding system library
4339 routine.
4340
4341 =item select FILEHANDLE
4342
4343 =item select
4344
4345 Returns the currently selected filehandle.  Sets the current default
4346 filehandle for output, if FILEHANDLE is supplied.  This has two
4347 effects: first, a C<write> or a C<print> without a filehandle will
4348 default to this FILEHANDLE.  Second, references to variables related to
4349 output will refer to this output channel.  For example, if you have to
4350 set the top of form format for more than one output channel, you might
4351 do the following:
4352
4353     select(REPORT1);
4354     $^ = 'report1_top';
4355     select(REPORT2);
4356     $^ = 'report2_top';
4357
4358 FILEHANDLE may be an expression whose value gives the name of the
4359 actual filehandle.  Thus:
4360
4361     $oldfh = select(STDERR); $| = 1; select($oldfh);
4362
4363 Some programmers may prefer to think of filehandles as objects with
4364 methods, preferring to write the last example as:
4365
4366     use IO::Handle;
4367     STDERR->autoflush(1);
4368
4369 =item select RBITS,WBITS,EBITS,TIMEOUT
4370
4371 This calls the select(2) system call with the bit masks specified, which
4372 can be constructed using C<fileno> and C<vec>, along these lines:
4373
4374     $rin = $win = $ein = '';
4375     vec($rin,fileno(STDIN),1) = 1;
4376     vec($win,fileno(STDOUT),1) = 1;
4377     $ein = $rin | $win;
4378
4379 If you want to select on many filehandles you might wish to write a
4380 subroutine:
4381
4382     sub fhbits {
4383         my(@fhlist) = split(' ',$_[0]);
4384         my($bits);
4385         for (@fhlist) {
4386             vec($bits,fileno($_),1) = 1;
4387         }
4388         $bits;
4389     }
4390     $rin = fhbits('STDIN TTY SOCK');
4391
4392 The usual idiom is:
4393
4394     ($nfound,$timeleft) =
4395       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4396
4397 or to block until something becomes ready just do this
4398
4399     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4400
4401 Most systems do not bother to return anything useful in $timeleft, so
4402 calling select() in scalar context just returns $nfound.
4403
4404 Any of the bit masks can also be undef.  The timeout, if specified, is
4405 in seconds, which may be fractional.  Note: not all implementations are
4406 capable of returning the $timeleft.  If not, they always return
4407 $timeleft equal to the supplied $timeout.
4408
4409 You can effect a sleep of 250 milliseconds this way:
4410
4411     select(undef, undef, undef, 0.25);
4412
4413 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4414 is implementation-dependent.
4415
4416 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4417 or <FH>) with C<select>, except as permitted by POSIX, and even
4418 then only on POSIX systems.  You have to use C<sysread> instead.
4419
4420 =item semctl ID,SEMNUM,CMD,ARG
4421
4422 Calls the System V IPC function C<semctl>.  You'll probably have to say
4423
4424     use IPC::SysV;
4425
4426 first to get the correct constant definitions.  If CMD is IPC_STAT or
4427 GETALL, then ARG must be a variable which will hold the returned
4428 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4429 the undefined value for error, "C<0 but true>" for zero, or the actual
4430 return value otherwise.  The ARG must consist of a vector of native
4431 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4432 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4433 documentation.
4434
4435 =item semget KEY,NSEMS,FLAGS
4436
4437 Calls the System V IPC function semget.  Returns the semaphore id, or
4438 the undefined value if there is an error.  See also
4439 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4440 documentation.
4441
4442 =item semop KEY,OPSTRING
4443
4444 Calls the System V IPC function semop to perform semaphore operations
4445 such as signalling and waiting.  OPSTRING must be a packed array of
4446 semop structures.  Each semop structure can be generated with
4447 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4448 operations is implied by the length of OPSTRING.  Returns true if
4449 successful, or false if there is an error.  As an example, the
4450 following code waits on semaphore $semnum of semaphore id $semid:
4451
4452     $semop = pack("s!3", $semnum, -1, 0);
4453     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4454
4455 To signal the semaphore, replace C<-1> with C<1>.  See also
4456 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4457 documentation.
4458
4459 =item send SOCKET,MSG,FLAGS,TO
4460
4461 =item send SOCKET,MSG,FLAGS
4462
4463 Sends a message on a socket.  Attempts to send the scalar MSG to the
4464 SOCKET filehandle.  Takes the same flags as the system call of the
4465 same name.  On unconnected sockets you must specify a destination to
4466 send TO, in which case it does a C C<sendto>.  Returns the number of
4467 characters sent, or the undefined value if there is an error.  The C
4468 system call sendmsg(2) is currently unimplemented.  See
4469 L<perlipc/"UDP: Message Passing"> for examples.
4470
4471 Note the I<characters>: depending on the status of the socket, either
4472 (8-bit) bytes or characters are sent.  By default all sockets operate
4473 on bytes, but for example if the socket has been changed using
4474 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or the
4475 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded
4476 Unicode characters, not bytes.  Similarly for the C<:encoding> pragma:
4477 in that case pretty much any characters can be sent.
4478
4479 =item setpgrp PID,PGRP
4480
4481 Sets the current process group for the specified PID, C<0> for the current
4482 process.  Will produce a fatal error if used on a machine that doesn't
4483 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4484 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4485 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4486 C<POSIX::setsid()>.
4487
4488 =item setpriority WHICH,WHO,PRIORITY
4489
4490 Sets the current priority for a process, a process group, or a user.
4491 (See setpriority(2).)  Will produce a fatal error if used on a machine
4492 that doesn't implement setpriority(2).
4493
4494 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4495
4496 Sets the socket option requested.  Returns undefined if there is an
4497 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4498 argument.
4499
4500 =item shift ARRAY
4501
4502 =item shift
4503
4504 Shifts the first value of the array off and returns it, shortening the
4505 array by 1 and moving everything down.  If there are no elements in the
4506 array, returns the undefined value.  If ARRAY is omitted, shifts the
4507 C<@_> array within the lexical scope of subroutines and formats, and the
4508 C<@ARGV> array at file scopes or within the lexical scopes established by
4509 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4510 constructs.
4511
4512 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4513 same thing to the left end of an array that C<pop> and C<push> do to the
4514 right end.
4515
4516 =item shmctl ID,CMD,ARG
4517
4518 Calls the System V IPC function shmctl.  You'll probably have to say
4519
4520     use IPC::SysV;
4521
4522 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4523 then ARG must be a variable which will hold the returned C<shmid_ds>
4524 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4525 true" for zero, or the actual return value otherwise.
4526 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4527
4528 =item shmget KEY,SIZE,FLAGS
4529
4530 Calls the System V IPC function shmget.  Returns the shared memory
4531 segment id, or the undefined value if there is an error.
4532 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4533
4534 =item shmread ID,VAR,POS,SIZE
4535
4536 =item shmwrite ID,STRING,POS,SIZE
4537
4538 Reads or writes the System V shared memory segment ID starting at
4539 position POS for size SIZE by attaching to it, copying in/out, and
4540 detaching from it.  When reading, VAR must be a variable that will
4541 hold the data read.  When writing, if STRING is too long, only SIZE
4542 bytes are used; if STRING is too short, nulls are written to fill out
4543 SIZE bytes.  Return true if successful, or false if there is an error.
4544 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4545 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4546
4547 =item shutdown SOCKET,HOW
4548
4549 Shuts down a socket connection in the manner indicated by HOW, which
4550 has the same interpretation as in the system call of the same name.
4551
4552     shutdown(SOCKET, 0);    # I/we have stopped reading data
4553     shutdown(SOCKET, 1);    # I/we have stopped writing data
4554     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4555
4556 This is useful with sockets when you want to tell the other
4557 side you're done writing but not done reading, or vice versa.
4558 It's also a more insistent form of close because it also
4559 disables the file descriptor in any forked copies in other
4560 processes.
4561
4562 =item sin EXPR
4563
4564 =item sin
4565
4566 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4567 returns sine of C<$_>.
4568
4569 For the inverse sine operation, you may use the C<Math::Trig::asin>
4570 function, or use this relation:
4571
4572     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4573
4574 =item sleep EXPR
4575
4576 =item sleep
4577
4578 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4579 May be interrupted if the process receives a signal such as C<SIGALRM>.
4580 Returns the number of seconds actually slept.  You probably cannot
4581 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4582 using C<alarm>.
4583
4584 On some older systems, it may sleep up to a full second less than what
4585 you requested, depending on how it counts seconds.  Most modern systems
4586 always sleep the full amount.  They may appear to sleep longer than that,
4587 however, because your process might not be scheduled right away in a
4588 busy multitasking system.
4589
4590 For delays of finer granularity than one second, you may use Perl's
4591 C<syscall> interface to access setitimer(2) if your system supports
4592 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4593 and starting from Perl 5.8 part of the standard distribution) may also
4594 help.
4595
4596 See also the POSIX module's C<pause> function.
4597
4598 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4599
4600 Opens a socket of the specified kind and attaches it to filehandle
4601 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4602 the system call of the same name.  You should C<use Socket> first
4603 to get the proper definitions imported.  See the examples in
4604 L<perlipc/"Sockets: Client/Server Communication">.
4605
4606 On systems that support a close-on-exec flag on files, the flag will
4607 be set for the newly opened file descriptor, as determined by the
4608 value of $^F.  See L<perlvar/$^F>.
4609
4610 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4611
4612 Creates an unnamed pair of sockets in the specified domain, of the
4613 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4614 for the system call of the same name.  If unimplemented, yields a fatal
4615 error.  Returns true if successful.
4616
4617 On systems that support a close-on-exec flag on files, the flag will
4618 be set for the newly opened file descriptors, as determined by the value
4619 of $^F.  See L<perlvar/$^F>.
4620
4621 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4622 to C<pipe(Rdr, Wtr)> is essentially:
4623
4624     use Socket;
4625     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4626     shutdown(Rdr, 1);        # no more writing for reader
4627     shutdown(Wtr, 0);        # no more reading for writer
4628
4629 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4630 emulate socketpair using IP sockets to localhost if your system implements
4631 sockets but not socketpair.
4632
4633 =item sort SUBNAME LIST
4634
4635 =item sort BLOCK LIST
4636