This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
7492e654d4b9aa024c3ef29eb8d4e08d3815e536
[perl5.git] / lib / _charnames.pm
1 # !!!!!!!   INTERNAL PERL USE ONLY   !!!!!!!
2 # This helper module is for internal use by core Perl only.  This module is
3 # subject to change or removal at any time without notice.  Don't use it
4 # directly.  Use the public <charnames> module instead.
5
6 package _charnames;
7 use strict;
8 use warnings;
9 use File::Spec;
10 our $VERSION = '1.37';
11 use unicore::Name;    # mktables-generated algorithmically-defined names
12
13 use bytes ();          # for $bytes::hint_bits
14 use re "/aa";          # Everything in here should be ASCII
15
16 $Carp::Internal{ (__PACKAGE__) } = 1;
17
18 # Translate between Unicode character names and their code points.  This is a
19 # submodule of package <charnames>, used to allow \N{...} to be autoloaded,
20 # but it was decided not to autoload the various functions in charnames; the
21 # splitting allows this behavior.
22 #
23 # The official names with their code points are stored in a table in
24 # lib/unicore/Name.pl which is read in as a large string (almost 3/4 Mb in
25 # Unicode 6.0).  Each code point/name combination is separated by a \n in the
26 # string.  (Some of the CJK and the Hangul syllable names are determined
27 # instead algorithmically via subroutines stored instead in
28 # lib/unicore/Name.pm).  Because of the large size of this table, it isn't
29 # converted into hashes for faster lookup.
30 #
31 # But, user defined aliases are stored in their own hashes, as are Perl
32 # extensions to the official names.  These are checked first before looking at
33 # the official table.
34 #
35 # Basically, the table is grepped for the input code point (viacode()) or
36 # name (the other functions), and the corresponding value on the same line is
37 # returned.  The grepping is done by turning the input into a regular
38 # expression.  Thus, the same table does double duty, used by both name and
39 # code point lookup.  (If we were to have hashes, we would need two, one for
40 # each lookup direction.)
41 #
42 # For loose name matching, the logical thing would be to have a table
43 # with all the ignorable characters squeezed out, and then grep it with the
44 # similiarly-squeezed input name.  (And this is in fact how the lookups are
45 # done with the small Perl extension hashes.)  But since we need to be able to
46 # go from code point to official name, the original table would still need to
47 # exist.  Due to the large size of the table, it was decided to not read
48 # another very large string into memory for a second table.  Instead, the
49 # regular expression of the input name is modified to have optional spaces and
50 # dashes between characters.  For example, in strict matching, the regular
51 # expression would be:
52 #   qr/\tDIGIT ONE$/m
53 # Under loose matching, the blank would be squeezed out, and the re would be:
54 #   qr/\tD[- ]?I[- ]?G[- ]?I[- ]?T[- ]?O[- ]?N[- ]?E$/m
55 # which matches a blank or dash between any characters in the official table.
56 #
57 # This is also how script lookup is done.  Basically the re looks like
58 #   qr/ (?:LATIN|GREEK|CYRILLIC) (?:SMALL )?LETTER $name/
59 # where $name is the loose or strict regex for the remainder of the name.
60
61 # The hashes are stored as utf8 strings.  This makes it easier to deal with
62 # sequences.  I (khw) also tried making Name.pl utf8, but it slowed things
63 # down by a factor of 7.  I then tried making Name.pl store the ut8
64 # equivalents but not calling them utf8.  That led to similar speed as leaving
65 # it alone, but since that is harder for a human to parse, I left it as-is.
66
67 my %system_aliases = (
68
69     'SINGLE-SHIFT 2'                => pack("U", 0x8E),
70     'SINGLE-SHIFT 3'                => pack("U", 0x8F),
71     'PRIVATE USE 1'                 => pack("U", 0x91),
72     'PRIVATE USE 2'                 => pack("U", 0x92),
73 );
74
75 # These are the aliases above that differ under :loose and :full matching
76 # because the :full versions have blanks or hyphens in them.
77 #my %loose_system_aliases = (
78 #);
79
80 #my %deprecated_aliases;
81 #$deprecated_aliases{'BELL'} = pack("U", 0x07) if $^V lt v5.17.0;
82
83 #my %loose_deprecated_aliases = (
84 #);
85
86 # These are special cased in :loose matching, differing only in a medial
87 # hyphen
88 my $HANGUL_JUNGSEONG_O_E_utf8 = pack("U", 0x1180);
89 my $HANGUL_JUNGSEONG_OE_utf8 = pack("U", 0x116C);
90
91
92 my $txt;  # The table of official character names
93
94 my %full_names_cache; # Holds already-looked-up names, so don't have to
95 # re-look them up again.  The previous versions of charnames had scoping
96 # bugs.  For example if we use script A in one scope and find and cache
97 # what Z resolves to, we can't use that cache in a different scope that
98 # uses script B instead of A, as Z might be an entirely different letter
99 # there; or there might be different aliases in effect in different
100 # scopes, or :short may be in effect or not effect in different scopes,
101 # or various combinations thereof.  This was solved in this version
102 # mostly by moving things to %^H.  But some things couldn't be moved
103 # there.  One of them was the cache of runtime looked-up names, in part
104 # because %^H is read-only at runtime.  I (khw) don't know why the cache
105 # was run-time only in the previous versions: perhaps oversight; perhaps
106 # that compile time looking doesn't happen in a loop so didn't think it
107 # was worthwhile; perhaps not wanting to make the cache too large.  But
108 # I decided to make it compile time as well; this could easily be
109 # changed.
110 # Anyway, this hash is not scoped, and is added to at runtime.  It
111 # doesn't have scoping problems because the data in it is restricted to
112 # official names, which are always invariant, and we only set it and
113 # look at it at during :full lookups, so is unaffected by any other
114 # scoped options.  I put this in to maintain parity with the older
115 # version.  If desired, a %short_names cache could also be made, as well
116 # as one for each script, say in %script_names_cache, with each key
117 # being a hash for a script named in a 'use charnames' statement.  I
118 # decided not to do that for now, just because it's added complication,
119 # and because I'm just trying to maintain parity, not extend it.
120
121 # Like %full_names_cache, but for use when :loose is in effect.  There needs
122 # to be two caches because :loose may not be in effect for a scope, and a
123 # loose name could inappropriately be returned when only exact matching is
124 # called for.
125 my %loose_names_cache;
126
127 # Designed so that test decimal first, and then hex.  Leading zeros
128 # imply non-decimal, as do non-[0-9]
129 my $decimal_qr = qr/^[1-9]\d*$/;
130
131 # Returns the hex number in $1.
132 my $hex_qr = qr/^(?:[Uu]\+|0[xX])?([[:xdigit:]]+)$/;
133
134 sub croak
135 {
136   require Carp; goto &Carp::croak;
137 } # croak
138
139 sub carp
140 {
141   require Carp; goto &Carp::carp;
142 } # carp
143
144 sub alias (@) # Set up a single alias
145 {
146   my @errors;
147
148   my $alias = ref $_[0] ? $_[0] : { @_ };
149   foreach my $name (sort keys %$alias) {  # Sort only because it helps having
150                                           # deterministic output for
151                                           # t/lib/charnames/alias
152     my $value = $alias->{$name};
153     next unless defined $value;          # Omit if screwed up.
154
155     # Is slightly slower to just after this statement see if it is
156     # decimal, since we already know it is after having converted from
157     # hex, but makes the code easier to maintain, and is called
158     # infrequently, only at compile-time
159     if ($value !~ $decimal_qr && $value =~ $hex_qr) {
160       $value = CORE::hex $1;
161     }
162     if ($value =~ $decimal_qr) {
163         no warnings qw(non_unicode surrogate nonchar); # Allow any of these
164         $^H{charnames_ord_aliases}{$name} = pack("U", $value);
165
166         # Use a canonical form.
167         $^H{charnames_inverse_ords}{sprintf("%05X", $value)} = $name;
168     }
169     else {
170         # This regex needs to be sync'd with the code in toke.c that checks
171         # for the same thing
172         if ($name !~ / ^
173                        \p{_Perl_Charname_Begin}
174                        \p{_Perl_Charname_Continue}*
175                        $ /x) {
176
177           push @errors, $name;
178         }
179         else {
180           $^H{charnames_name_aliases}{$name} = $value;
181
182           if (warnings::enabled('deprecated')) {
183             if ($name =~ / ( .* \s ) ( \s* ) $ /x) {
184               carp "Trailing white-space in a charnames alias definition is deprecated; marked by <-- HERE in '$1 <-- HERE " . $2 . "'";
185             }
186
187             # Use '+' instead of '*' in this regex, because any trailing
188             # blanks have already been warned about.
189             if ($name =~ / ( .*? \s{2} ) ( .+ ) /x) {
190               carp "A sequence of multiple spaces in a charnames alias definition is deprecated; marked by <-- HERE in '$1 <-- HERE " . $2 . "'";
191             }
192           }
193         }
194     }
195   }
196
197   # We find and output all errors from this :alias definition, rather than
198   # failing on the first one, so fewer runs are needed to get it to compile
199   if (@errors) {
200     foreach my $name (@errors) {
201       my $ok = "";
202       $ok = $1 if $name =~ / ^ ( \p{Alpha} [-\p{XPosixWord} ():\xa0]* ) /x;
203       my $first_bad = substr($name, length($ok), 1);
204       $name = "Invalid character in charnames alias definition; marked by <-- HERE in '$ok$first_bad<-- HERE " . substr($name, length($ok) + 1) . "'";
205     }
206     croak join "\n", @errors;
207   }
208
209   return;
210 } # alias
211
212 sub not_legal_use_bytes_msg {
213   my ($name, $utf8) = @_;
214   my $return;
215
216   if (length($utf8) == 1) {
217     $return = sprintf("Character 0x%04x with name '%s' is", ord $utf8, $name);
218   } else {
219     $return = sprintf("String with name '%s' (and ordinals %s) contains character(s)", $name, join(" ", map { sprintf "0x%04X", ord $_ } split(//, $utf8)));
220   }
221   return $return . " above 0xFF with 'use bytes' in effect";
222 }
223
224 sub alias_file ($)  # Reads a file containing alias definitions
225 {
226   my ($arg, $file) = @_;
227   if (-f $arg && File::Spec->file_name_is_absolute ($arg)) {
228     $file = $arg;
229   }
230   elsif ($arg =~ m/ ^ \p{_Perl_IDStart} \p{_Perl_IDCont}* $/x) {
231     $file = "unicore/${arg}_alias.pl";
232   }
233   else {
234     croak "Charnames alias file names can only have identifier characters";
235   }
236   if (my @alias = do $file) {
237     @alias == 1 && !defined $alias[0] and
238       croak "$file cannot be used as alias file for charnames";
239     @alias % 2 and
240       croak "$file did not return a (valid) list of alias pairs";
241     alias (@alias);
242     return (1);
243   }
244   0;
245 } # alias_file
246
247 # For use when don't import anything.  This structure must be kept in
248 # sync with the one that import() fills up.
249 my %dummy_H = (
250                 charnames_stringified_names => "",
251                 charnames_stringified_ords => "",
252                 charnames_scripts => "",
253                 charnames_full => 1,
254                 charnames_loose => 0,
255                 charnames_short => 0,
256               );
257
258
259 sub lookup_name ($$$) {
260   my ($name, $wants_ord, $runtime) = @_;
261
262   # Lookup the name or sequence $name in the tables.  If $wants_ord is false,
263   # returns the string equivalent of $name; if true, returns the ordinal value
264   # instead, but in this case $name must not be a sequence; otherwise undef is
265   # returned and a warning raised.  $runtime is 0 if compiletime, otherwise
266   # gives the number of stack frames to go back to get the application caller
267   # info.
268   # If $name is not found, returns undef in runtime with no warning; and in
269   # compiletime, the Unicode replacement character, with a warning.
270
271   # It looks first in the aliases, then in the large table of official Unicode
272   # names.
273
274   my $utf8;       # The string result
275   my $save_input;
276
277   if ($runtime) {
278
279     my $hints_ref = (caller($runtime))[10];
280
281     # If we didn't import anything (which happens with 'use charnames ()',
282     # substitute a dummy structure.
283     $hints_ref = \%dummy_H if ! defined $hints_ref
284                               || (! defined $hints_ref->{charnames_full}
285                                   && ! defined $hints_ref->{charnames_loose});
286
287     # At runtime, but currently not at compile time, $^H gets
288     # stringified, so un-stringify back to the original data structures.
289     # These get thrown away by perl before the next invocation
290     # Also fill in the hash with the non-stringified data.
291     # N.B.  New fields must be also added to %dummy_H
292
293     %{$^H{charnames_name_aliases}} = split ',',
294                                       $hints_ref->{charnames_stringified_names};
295     %{$^H{charnames_ord_aliases}} = split ',',
296                                       $hints_ref->{charnames_stringified_ords};
297     $^H{charnames_scripts} = $hints_ref->{charnames_scripts};
298     $^H{charnames_full} = $hints_ref->{charnames_full};
299     $^H{charnames_loose} = $hints_ref->{charnames_loose};
300     $^H{charnames_short} = $hints_ref->{charnames_short};
301   }
302
303   my $loose = $^H{charnames_loose};
304   my $lookup_name;  # Input name suitably modified for grepping for in the
305                     # table
306
307   # User alias should be checked first or else can't override ours, and if we
308   # were to add any, could conflict with theirs.
309   if (exists $^H{charnames_ord_aliases}{$name}) {
310     $utf8 = $^H{charnames_ord_aliases}{$name};
311   }
312   elsif (exists $^H{charnames_name_aliases}{$name}) {
313     $name = $^H{charnames_name_aliases}{$name};
314     $save_input = $lookup_name = $name;  # Cache the result for any error
315                                          # message
316     # The aliases are documented to not match loosely, so change loose match
317     # into full.
318     if ($loose) {
319       $loose = 0;
320       $^H{charnames_full} = 1;
321     }
322   }
323   else {
324
325     # Here, not a user alias.  That means that loose matching may be in
326     # effect; will have to modify the input name.
327     $lookup_name = $name;
328     if ($loose) {
329       $lookup_name = uc $lookup_name;
330
331       # Squeeze out all underscores
332       $lookup_name =~ s/_//g;
333
334       # Remove all medial hyphens
335       $lookup_name =~ s/ (?<= \S  ) - (?= \S  )//gx;
336
337       # Squeeze out all spaces
338       $lookup_name =~ s/\s//g;
339     }
340
341     # Here, $lookup_name has been modified as necessary for looking in the
342     # hashes.  Check the system alias files next.  Most of these aliases are
343     # the same for both strict and loose matching.  To save space, the ones
344     # which differ are in their own separate hash, which is checked if loose
345     # matching is selected and the regular match fails.  To save time, the
346     # loose hashes could be expanded to include all aliases, and there would
347     # only have to be one check.  But if someone specifies :loose, they are
348     # interested in convenience over speed, and the time for this second check
349     # is miniscule compared to the rest of the routine.
350     if (exists $system_aliases{$lookup_name}) {
351       $utf8 = $system_aliases{$lookup_name};
352     }
353     # There are currently no entries in this hash, so don't waste time looking
354     # for them.  But the code is retained for the unlikely possibility that
355     # some will be added in the future.
356 #    elsif ($loose && exists $loose_system_aliases{$lookup_name}) {
357 #      $utf8 = $loose_system_aliases{$lookup_name};
358 #    }
359 #    if (exists $deprecated_aliases{$lookup_name}) {
360 #      require warnings;
361 #      warnings::warnif('deprecated',
362 #                       "Unicode character name \"$name\" is deprecated, use \""
363 #                       . viacode(ord $deprecated_aliases{$lookup_name})
364 #                       . "\" instead");
365 #      $utf8 = $deprecated_aliases{$lookup_name};
366 #    }
367     # There are currently no entries in this hash, so don't waste time looking
368     # for them.  But the code is retained for the unlikely possibility that
369     # some will be added in the future.
370 #    elsif ($loose && exists $loose_deprecated_aliases{$lookup_name}) {
371 #      require warnings;
372 #      warnings::warnif('deprecated',
373 #                       "Unicode character name \"$name\" is deprecated, use \""
374 #                       . viacode(ord $loose_deprecated_aliases{$lookup_name})
375 #                       . "\" instead");
376 #      $utf8 = $loose_deprecated_aliases{$lookup_name};
377 #    }
378   }
379
380   my @off;  # Offsets into table of pattern match begin and end
381
382   # If haven't found it yet...
383   if (! defined $utf8) {
384
385     # See if has looked this input up earlier.
386     if (! $loose && $^H{charnames_full} && exists $full_names_cache{$name}) {
387       $utf8 = $full_names_cache{$name};
388     }
389     elsif ($loose && exists $loose_names_cache{$name}) {
390       $utf8 = $loose_names_cache{$name};
391     }
392     else { # Here, must do a look-up
393
394       # If full or loose matching succeeded, points to where to cache the
395       # result
396       my $cache_ref;
397
398       ## Suck in the code/name list as a big string.
399       ## Lines look like:
400       ##     "00052\tLATIN CAPITAL LETTER R\n"
401       # or
402       #      "0052 0303\tLATIN CAPITAL LETTER R WITH TILDE\n"
403       $txt = do "unicore/Name.pl" unless $txt;
404
405       ## @off will hold the index into the code/name string of the start and
406       ## end of the name as we find it.
407
408       ## If :loose, look for a loose match; if :full, look for the name
409       ## exactly
410       # First, see if the name is one which is algorithmically determinable.
411       # The subroutine is included in Name.pl.  The table contained in
412       # $txt doesn't contain these.  Experiments show that checking
413       # for these before checking for the regular names has no
414       # noticeable impact on performance for the regular names, but
415       # the other way around slows down finding these immensely.
416       # Algorithmically determinables are not placed in the cache because
417       # that uses up memory, and finding these again is fast.
418       if (($loose || $^H{charnames_full})
419           && (defined (my $ord = charnames::name_to_code_point_special($lookup_name, $loose))))
420       {
421         $utf8 = pack("U", $ord);
422       }
423       else {
424
425         # Not algorithmically determinable; look up in the table.  The name
426         # will be turned into a regex, so quote any meta characters.
427         $lookup_name = quotemeta $lookup_name;
428
429         if ($loose) {
430
431           # For loose matches, $lookup_name has already squeezed out the
432           # non-essential characters.  We have to add in code to make the
433           # squeezed version match the non-squeezed equivalent in the table.
434           # The only remaining hyphens are ones that start or end a word in
435           # the original.  They have been quoted in $lookup_name so they look
436           # like "\-".  Change all other characters except the backslash
437           # quotes for any metacharacters, and the final character, so that
438           # e.g., COLON gets transformed into: /C[- ]?O[- ]?L[- ]?O[- ]?N/
439           $lookup_name =~ s/ (?! \\ -)    # Don't do this to the \- sequence
440                              ( [^-\\] )   # Nor the "-" within that sequence,
441                                           # nor the "\" that quotes metachars,
442                                           # but otherwise put the char into $1
443                              (?=.)        # And don't do it for the final char
444                            /$1\[- \]?/gx; # And add an optional blank or
445                                           # '-' after each $1 char
446
447           # Those remaining hyphens were originally at the beginning or end of
448           # a word, so they can match either a blank before or after, but not
449           # both.  (Keep in mind that they have been quoted, so are a '\-'
450           # sequence)
451           $lookup_name =~ s/\\ -/(?:- | -)/xg;
452         }
453
454         # Do the lookup in the full table if asked for, and if succeeds
455         # save the offsets and set where to cache the result.
456         if (($loose || $^H{charnames_full}) && $txt =~ /\t$lookup_name$/m) {
457           @off = ($-[0] + 1, $+[0]);    # The 1 is for the tab
458           $cache_ref = ($loose) ? \%loose_names_cache : \%full_names_cache;
459         }
460         else {
461
462           # Here, didn't look for, or didn't find the name.
463           # If :short is allowed, see if input is like "greek:Sigma".
464           # Keep in mind that $lookup_name has had the metas quoted.
465           my $scripts_trie = "";
466           my $name_has_uppercase;
467           if (($^H{charnames_short})
468               && $lookup_name =~ /^ (?: \\ \s)*   # Quoted space
469                                     (.+?)         # $1 = the script
470                                     (?: \\ \s)*
471                                     \\ :          # Quoted colon
472                                     (?: \\ \s)*
473                                     (.+?)         # $2 = the name
474                                     (?: \\ \s)* $
475                                   /xs)
476           {
477               # Even in non-loose matching, the script traditionally has been
478               # case insensitive
479               $scripts_trie = "\U$1";
480               $lookup_name = $2;
481
482               # Use original name to find its input casing, but ignore the
483               # script part of that to make the determination.
484               $save_input = $name if ! defined $save_input;
485               $name =~ s/.*?://;
486               $name_has_uppercase = $name =~ /[[:upper:]]/;
487           }
488           else { # Otherwise look in allowed scripts
489               $scripts_trie = $^H{charnames_scripts};
490
491               # Use original name to find its input casing
492               $name_has_uppercase = $name =~ /[[:upper:]]/;
493           }
494
495           my $case = $name_has_uppercase ? "CAPITAL" : "SMALL";
496           return if (! $scripts_trie || $txt !~
497              /\t (?: $scripts_trie ) \ (?:$case\ )? LETTER \ \U$lookup_name $/xm);
498
499           # Here have found the input name in the table.
500           @off = ($-[0] + 1, $+[0]);  # The 1 is for the tab
501         }
502
503         # Here, the input name has been found; we haven't set up the output,
504         # but we know where in the string
505         # the name starts.  The string is set up so that for single characters
506         # (and not named sequences), the name is preceded immediately by a
507         # tab and 5 hex digits for its code, with a \n before those.  Named
508         # sequences won't have the 7th preceding character be a \n.
509         # (Actually, for the very first entry in the table this isn't strictly
510         # true: subtracting 7 will yield -1, and the substr below will
511         # therefore yield the very last character in the table, which should
512         # also be a \n, so the statement works anyway.)
513         if (substr($txt, $off[0] - 7, 1) eq "\n") {
514           $utf8 = pack("U", CORE::hex substr($txt, $off[0] - 6, 5));
515
516           # Handle the single loose matching special case, in which two names
517           # differ only by a single medial hyphen.  If the original had a
518           # hyphen (or more) in the right place, then it is that one.
519           $utf8 = $HANGUL_JUNGSEONG_O_E_utf8
520                   if $loose
521                      && $utf8 eq $HANGUL_JUNGSEONG_OE_utf8
522                      && $name =~ m/O \s* - [-\s]* E/ix;
523                      # Note that this wouldn't work if there were a 2nd
524                      # OE in the name
525         }
526         else {
527
528           # Here, is a named sequence.  Need to go looking for the beginning,
529           # which is just after the \n from the previous entry in the table.
530           # The +1 skips past that newline, or, if the rindex() fails, to put
531           # us to an offset of zero.
532           my $charstart = rindex($txt, "\n", $off[0] - 7) + 1;
533           $utf8 = pack("U*", map { CORE::hex }
534               split " ", substr($txt, $charstart, $off[0] - $charstart - 1));
535         }
536       }
537
538       # Cache the input so as to not have to search the large table
539       # again, but only if it came from the one search that we cache.
540       # (Haven't bothered with the pain of sorting out scoping issues for the
541       # scripts searches.)
542       $cache_ref->{$name} = $utf8 if defined $cache_ref;
543     }
544   }
545
546
547   # Here, have the utf8.  If the return is to be an ord, must be any single
548   # character.
549   if ($wants_ord) {
550     return ord($utf8) if length $utf8 == 1;
551   }
552   else {
553
554     # Here, wants string output.  If utf8 is acceptable, just return what
555     # we've got; otherwise attempt to convert it to non-utf8 and return that.
556     my $in_bytes = ($runtime)
557                    ? (caller $runtime)[8] & $bytes::hint_bits
558                    : $^H & $bytes::hint_bits;
559     return $utf8 if (! $in_bytes || utf8::downgrade($utf8, 1)) # The 1 arg
560                                                   # means don't die on failure
561   }
562
563   # Here, there is an error:  either there are too many characters, or the
564   # result string needs to be non-utf8, and at least one character requires
565   # utf8.  Prefer any official name over the input one for the error message.
566   if (@off) {
567     $name = substr($txt, $off[0], $off[1] - $off[0]) if @off;
568   }
569   else {
570     $name = (defined $save_input) ? $save_input : $_[0];
571   }
572
573   if ($wants_ord) {
574     # Only way to get here in this case is if result too long.  Message
575     # assumes that our only caller that requires single char result is
576     # vianame.
577     carp "charnames::vianame() doesn't handle named sequences ($name).  Use charnames::string_vianame() instead";
578     return;
579   }
580
581   # Only other possible failure here is from use bytes.
582   if ($runtime) {
583     carp not_legal_use_bytes_msg($name, $utf8);
584     return;
585   } else {
586     croak not_legal_use_bytes_msg($name, $utf8);
587   }
588
589 } # lookup_name
590
591 sub charnames {
592
593   # For \N{...}.  Looks up the character name and returns the string
594   # representation of it.
595
596   # The first 0 arg means wants a string returned; the second that we are in
597   # compile time
598   return lookup_name($_[0], 0, 0);
599 }
600
601 sub import
602 {
603   shift; ## ignore class name
604
605   if (not @_) {
606     carp("'use charnames' needs explicit imports list");
607   }
608   $^H{charnames} = \&charnames ;
609   $^H{charnames_ord_aliases} = {};
610   $^H{charnames_name_aliases} = {};
611   $^H{charnames_inverse_ords} = {};
612   # New fields must be added to %dummy_H, and the code in lookup_name()
613   # that copies fields from the runtime structure
614
615   ##
616   ## fill %h keys with our @_ args.
617   ##
618   my ($promote, %h, @args) = (0);
619   while (my $arg = shift) {
620     if ($arg eq ":alias") {
621       @_ or
622         croak ":alias needs an argument in charnames";
623       my $alias = shift;
624       if (ref $alias) {
625         ref $alias eq "HASH" or
626           croak "Only HASH reference supported as argument to :alias";
627         alias ($alias);
628         $promote = 1;
629         next;
630       }
631       if ($alias =~ m{:(\w+)$}) {
632         $1 eq "full" || $1 eq "loose" || $1 eq "short" and
633           croak ":alias cannot use existing pragma :$1 (reversed order?)";
634         alias_file ($1) and $promote = 1;
635         next;
636       }
637       alias_file ($alias) and $promote = 1;
638       next;
639     }
640     if (substr($arg, 0, 1) eq ':'
641       and ! ($arg eq ":full" || $arg eq ":short" || $arg eq ":loose"))
642     {
643       warn "unsupported special '$arg' in charnames";
644       next;
645     }
646     push @args, $arg;
647   }
648
649   @args == 0 && $promote and @args = (":full");
650   @h{@args} = (1) x @args;
651
652   # Don't leave these undefined as are tested for in lookup_names
653   $^H{charnames_full} = delete $h{':full'} || 0;
654   $^H{charnames_loose} = delete $h{':loose'} || 0;
655   $^H{charnames_short} = delete $h{':short'} || 0;
656   my @scripts = map { uc quotemeta } keys %h;
657
658   ##
659   ## If utf8? warnings are enabled, and some scripts were given,
660   ## see if at least we can find one letter from each script.
661   ##
662   if (warnings::enabled('utf8') && @scripts) {
663     $txt = do "unicore/Name.pl" unless $txt;
664
665     for my $script (@scripts) {
666       if (not $txt =~ m/\t$script (?:CAPITAL |SMALL )?LETTER /) {
667         warnings::warn('utf8',  "No such script: '$script'");
668         $script = quotemeta $script;  # Escape it, for use in the re.
669       }
670     }
671   }
672
673   # %^H gets stringified, so serialize it ourselves so can extract the
674   # real data back later.
675   $^H{charnames_stringified_ords} = join ",", %{$^H{charnames_ord_aliases}};
676   $^H{charnames_stringified_names} = join ",", %{$^H{charnames_name_aliases}};
677   $^H{charnames_stringified_inverse_ords} = join ",", %{$^H{charnames_inverse_ords}};
678
679   # Modify the input script names for loose name matching if that is also
680   # specified, similar to the way the base character name is prepared.  They
681   # don't (currently, and hopefully never will) have dashes.  These go into a
682   # regex, and have already been uppercased and quotemeta'd.  Squeeze out all
683   # input underscores, blanks, and dashes.  Then convert so will match a blank
684   # between any characters.
685   if ($^H{charnames_loose}) {
686     for (my $i = 0; $i < @scripts; $i++) {
687       $scripts[$i] =~ s/[_ -]//g;
688       $scripts[$i] =~ s/ ( [^\\] ) (?= . ) /$1\\ ?/gx;
689     }
690   }
691
692   $^H{charnames_scripts} = join "|", @scripts;  # Stringifiy them as a trie
693 } # import
694
695 # Cache of already looked-up values.  This is set to only contain
696 # official values, and user aliases can't override them, so scoping is
697 # not an issue.
698 my %viacode;
699
700 sub viacode {
701
702   # Returns the name of the code point argument
703
704   if (@_ != 1) {
705     carp "charnames::viacode() expects one argument";
706     return;
707   }
708
709   my $arg = shift;
710
711   # This is derived from Unicode::UCD, where it is nearly the same as the
712   # function _getcode(), but here it makes sure that even a hex argument
713   # has the proper number of leading zeros, which is critical in
714   # matching against $txt below
715   # Must check if decimal first; see comments at that definition
716   my $hex;
717   if ($arg =~ $decimal_qr) {
718     $hex = sprintf "%05X", $arg;
719   } elsif ($arg =~ $hex_qr) {
720     # Below is the line that differs from the _getcode() source
721     $hex = sprintf "%05X", hex $1;
722   } else {
723     carp("unexpected arg \"$arg\" to charnames::viacode()");
724     return;
725   }
726
727   return $viacode{$hex} if exists $viacode{$hex};
728
729   my $return;
730
731   # If the code point is above the max in the table, there's no point
732   # looking through it.  Checking the length first is slightly faster
733   if (length($hex) <= 5 || CORE::hex($hex) <= 0x10FFFF) {
734     $txt = do "unicore/Name.pl" unless $txt;
735
736     # See if the name is algorithmically determinable.
737     my $algorithmic = charnames::code_point_to_name_special(CORE::hex $hex);
738     if (defined $algorithmic) {
739       $viacode{$hex} = $algorithmic;
740       return $algorithmic;
741     }
742
743     # Return the official name, if exists.  It's unclear to me (khw) at
744     # this juncture if it is better to return a user-defined override, so
745     # leaving it as is for now.
746     if ($txt =~ m/^$hex\t/m) {
747
748         # The name starts with the next character and goes up to the
749         # next new-line.  Using capturing parentheses above instead of
750         # @+ more than doubles the execution time in Perl 5.13
751         $return = substr($txt, $+[0], index($txt, "\n", $+[0]) - $+[0]);
752
753         # If not one of these 4 code points, return what we've found.
754         if ($hex !~ / ^ 000 (?: 8[014] | 99 ) $ /x) {
755           $viacode{$hex} = $return;
756           return $return;
757         }
758
759         # For backwards compatibility, we don't return the official name of
760         # the 4 code points if there are user-defined aliases for them -- so
761         # continue looking.
762     }
763   }
764
765   # See if there is a user name for it, before giving up completely.
766   # First get the scoped aliases, give up if have none.
767   my $H_ref = (caller(1))[10];
768   return if ! defined $return
769               && (! defined $H_ref
770                   || ! exists $H_ref->{charnames_stringified_inverse_ords});
771
772   my %code_point_aliases;
773   if (defined $H_ref->{charnames_stringified_inverse_ords}) {
774     %code_point_aliases = split ',',
775                           $H_ref->{charnames_stringified_inverse_ords};
776     return $code_point_aliases{$hex} if exists $code_point_aliases{$hex};
777   }
778
779   # Here there is no user-defined alias, return any official one.
780   return $return if defined $return;
781
782   if (CORE::hex($hex) > 0x10FFFF
783       && warnings::enabled('non_unicode'))
784   {
785       carp "Unicode characters only allocated up to U+10FFFF (you asked for U+$hex)";
786   }
787   return;
788
789 } # viacode
790
791 1;
792
793 # ex: set ts=8 sts=2 sw=2 et: