This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Add skip_all_without_extension() to test.pl, for the common skip idiom.
[perl5.git] / t / test.pl
1 #
2 # t/test.pl - most of Test::More functionality without the fuss, plus
3 # has mappings native_to_latin1 and latin1_to_native so that fewer tests
4 # on non ASCII-ish platforms need to be skipped
5
6
7 # NOTE:
8 #
9 # Increment ($x++) has a certain amount of cleverness for things like
10 #
11 #   $x = 'zz';
12 #   $x++; # $x eq 'aaa';
13 #
14 # stands more chance of breaking than just a simple
15 #
16 #   $x = $x + 1
17 #
18 # In this file, we use the latter "Baby Perl" approach, and increment
19 # will be worked over by t/op/inc.t
20
21 $Level = 1;
22 my $test = 1;
23 my $planned;
24 my $noplan;
25 my $Perl;       # Safer version of $^X set by which_perl()
26
27 # This defines ASCII/UTF-8 vs EBCDIC/UTF-EBCDIC
28 $::IS_ASCII  = ord 'A' ==  65;
29 $::IS_EBCDIC = ord 'A' == 193;
30
31 $TODO = 0;
32 $NO_ENDING = 0;
33 $Tests_Are_Passing = 1;
34
35 # Use this instead of print to avoid interference while testing globals.
36 sub _print {
37     local($\, $", $,) = (undef, ' ', '');
38     print STDOUT @_;
39 }
40
41 sub _print_stderr {
42     local($\, $", $,) = (undef, ' ', '');
43     print STDERR @_;
44 }
45
46 sub plan {
47     my $n;
48     if (@_ == 1) {
49         $n = shift;
50         if ($n eq 'no_plan') {
51           undef $n;
52           $noplan = 1;
53         }
54     } else {
55         my %plan = @_;
56         $n = $plan{tests};
57     }
58     _print "1..$n\n" unless $noplan;
59     $planned = $n;
60 }
61
62
63 # Set the plan at the end.  See Test::More::done_testing.
64 sub done_testing {
65     my $n = $test - 1;
66     $n = shift if @_;
67
68     _print "1..$n\n";
69     $planned = $n;
70 }
71
72
73 END {
74     my $ran = $test - 1;
75     if (!$NO_ENDING) {
76         if (defined $planned && $planned != $ran) {
77             _print_stderr
78                 "# Looks like you planned $planned tests but ran $ran.\n";
79         } elsif ($noplan) {
80             _print "1..$ran\n";
81         }
82     }
83 }
84
85 sub _diag {
86     return unless @_;
87     my @mess = _comment(@_);
88     $TODO ? _print(@mess) : _print_stderr(@mess);
89 }
90
91 # Use this instead of "print STDERR" when outputting failure diagnostic
92 # messages
93 sub diag {
94     _diag(@_);
95 }
96
97 # Use this instead of "print" when outputting informational messages
98 sub note {
99     return unless @_;
100     _print( _comment(@_) );
101 }
102
103 sub is_miniperl {
104     return !defined &DynaLoader::boot_DynaLoader;
105 }
106
107 sub _comment {
108     return map { /^#/ ? "$_\n" : "# $_\n" }
109            map { split /\n/ } @_;
110 }
111
112 sub skip_all {
113     if (@_) {
114         _print "1..0 # Skip @_\n";
115     } else {
116         _print "1..0\n";
117     }
118     exit(0);
119 }
120
121 sub skip_all_if_miniperl {
122     skip_all(@_) if is_miniperl();
123 }
124
125 sub skip_all_without_extension {
126     my $extension = shift;
127     unless (eval 'require Config; 1') {
128         warn "test.pl had problems loading Config: $@";
129         return;
130     }
131     return if ($Config::Config{extensions} =~ /\b$extension\b/);
132     skip_all("$extension was not built");
133 }
134
135 sub _ok {
136     my ($pass, $where, $name, @mess) = @_;
137     # Do not try to microoptimize by factoring out the "not ".
138     # VMS will avenge.
139     my $out;
140     if ($name) {
141         # escape out '#' or it will interfere with '# skip' and such
142         $name =~ s/#/\\#/g;
143         $out = $pass ? "ok $test - $name" : "not ok $test - $name";
144     } else {
145         $out = $pass ? "ok $test" : "not ok $test";
146     }
147
148     if ($TODO) {
149         $out = $out . " # TODO $TODO";
150     } else {
151         $Tests_Are_Passing = 0 unless $pass;
152     }
153
154     _print "$out\n";
155
156     if ($pass) {
157         note @mess; # Ensure that the message is properly escaped.
158     }
159     else {
160         _diag "# Failed $where\n";
161         _diag @mess;
162     }
163
164     $test = $test + 1; # don't use ++
165
166     return $pass;
167 }
168
169 sub _where {
170     my @caller = caller($Level);
171     return "at $caller[1] line $caller[2]";
172 }
173
174 # DON'T use this for matches. Use like() instead.
175 sub ok ($@) {
176     my ($pass, $name, @mess) = @_;
177     _ok($pass, _where(), $name, @mess);
178 }
179
180 sub _q {
181     my $x = shift;
182     return 'undef' unless defined $x;
183     my $q = $x;
184     $q =~ s/\\/\\\\/g;
185     $q =~ s/'/\\'/g;
186     return "'$q'";
187 }
188
189 sub _qq {
190     my $x = shift;
191     return defined $x ? '"' . display ($x) . '"' : 'undef';
192 };
193
194 # keys are the codes \n etc map to, values are 2 char strings such as \n
195 my %backslash_escape;
196 foreach my $x (split //, 'nrtfa\\\'"') {
197     $backslash_escape{ord eval "\"\\$x\""} = "\\$x";
198 }
199 # A way to display scalars containing control characters and Unicode.
200 # Trying to avoid setting $_, or relying on local $_ to work.
201 sub display {
202     my @result;
203     foreach my $x (@_) {
204         if (defined $x and not ref $x) {
205             my $y = '';
206             foreach my $c (unpack("U*", $x)) {
207                 if ($c > 255) {
208                     $y = $y . sprintf "\\x{%x}", $c;
209                 } elsif ($backslash_escape{$c}) {
210                     $y = $y . $backslash_escape{$c};
211                 } else {
212                     my $z = chr $c; # Maybe we can get away with a literal...
213                     if ($z =~ /[[:^print:]]/) {
214
215                         # Use octal for characters traditionally expressed as
216                         # such: the low controls
217                         if ($c <= 037) {
218                             $z = sprintf "\\%03o", $c;
219                         } else {
220                             $z = sprintf "\\x{%x}", $c;
221                         }
222                     }
223                     $y = $y . $z;
224                 }
225             }
226             $x = $y;
227         }
228         return $x unless wantarray;
229         push @result, $x;
230     }
231     return @result;
232 }
233
234 sub is ($$@) {
235     my ($got, $expected, $name, @mess) = @_;
236
237     my $pass;
238     if( !defined $got || !defined $expected ) {
239         # undef only matches undef
240         $pass = !defined $got && !defined $expected;
241     }
242     else {
243         $pass = $got eq $expected;
244     }
245
246     unless ($pass) {
247         unshift(@mess, "#      got "._qq($got)."\n",
248                        "# expected "._qq($expected)."\n");
249     }
250     _ok($pass, _where(), $name, @mess);
251 }
252
253 sub isnt ($$@) {
254     my ($got, $isnt, $name, @mess) = @_;
255
256     my $pass;
257     if( !defined $got || !defined $isnt ) {
258         # undef only matches undef
259         $pass = defined $got || defined $isnt;
260     }
261     else {
262         $pass = $got ne $isnt;
263     }
264
265     unless( $pass ) {
266         unshift(@mess, "# it should not be "._qq($got)."\n",
267                        "# but it is.\n");
268     }
269     _ok($pass, _where(), $name, @mess);
270 }
271
272 sub cmp_ok ($$$@) {
273     my($got, $type, $expected, $name, @mess) = @_;
274
275     my $pass;
276     {
277         local $^W = 0;
278         local($@,$!);   # don't interfere with $@
279                         # eval() sometimes resets $!
280         $pass = eval "\$got $type \$expected";
281     }
282     unless ($pass) {
283         # It seems Irix long doubles can have 2147483648 and 2147483648
284         # that stringify to the same thing but are actually numerically
285         # different. Display the numbers if $type isn't a string operator,
286         # and the numbers are stringwise the same.
287         # (all string operators have alphabetic names, so tr/a-z// is true)
288         # This will also show numbers for some unneeded cases, but will
289         # definitely be helpful for things such as == and <= that fail
290         if ($got eq $expected and $type !~ tr/a-z//) {
291             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
292         }
293         unshift(@mess, "#      got "._qq($got)."\n",
294                        "# expected $type "._qq($expected)."\n");
295     }
296     _ok($pass, _where(), $name, @mess);
297 }
298
299 # Check that $got is within $range of $expected
300 # if $range is 0, then check it's exact
301 # else if $expected is 0, then $range is an absolute value
302 # otherwise $range is a fractional error.
303 # Here $range must be numeric, >= 0
304 # Non numeric ranges might be a useful future extension. (eg %)
305 sub within ($$$@) {
306     my ($got, $expected, $range, $name, @mess) = @_;
307     my $pass;
308     if (!defined $got or !defined $expected or !defined $range) {
309         # This is a fail, but doesn't need extra diagnostics
310     } elsif ($got !~ tr/0-9// or $expected !~ tr/0-9// or $range !~ tr/0-9//) {
311         # This is a fail
312         unshift @mess, "# got, expected and range must be numeric\n";
313     } elsif ($range < 0) {
314         # This is also a fail
315         unshift @mess, "# range must not be negative\n";
316     } elsif ($range == 0) {
317         # Within 0 is ==
318         $pass = $got == $expected;
319     } elsif ($expected == 0) {
320         # If expected is 0, treat range as absolute
321         $pass = ($got <= $range) && ($got >= - $range);
322     } else {
323         my $diff = $got - $expected;
324         $pass = abs ($diff / $expected) < $range;
325     }
326     unless ($pass) {
327         if ($got eq $expected) {
328             unshift @mess, "# $got - $expected = " . ($got - $expected) . "\n";
329         }
330         unshift@mess, "#      got "._qq($got)."\n",
331                       "# expected "._qq($expected)." (within "._qq($range).")\n";
332     }
333     _ok($pass, _where(), $name, @mess);
334 }
335
336 # Note: this isn't quite as fancy as Test::More::like().
337
338 sub like   ($$@) { like_yn (0,@_) }; # 0 for -
339 sub unlike ($$@) { like_yn (1,@_) }; # 1 for un-
340
341 sub like_yn ($$$@) {
342     my ($flip, undef, $expected, $name, @mess) = @_;
343     my $pass;
344     $pass = $_[1] =~ /$expected/ if !$flip;
345     $pass = $_[1] !~ /$expected/ if $flip;
346     unless ($pass) {
347         unshift(@mess, "#      got '$_[1]'\n",
348                 $flip
349                 ? "# expected !~ /$expected/\n" : "# expected /$expected/\n");
350     }
351     local $Level = $Level + 1;
352     _ok($pass, _where(), $name, @mess);
353 }
354
355 sub pass {
356     _ok(1, '', @_);
357 }
358
359 sub fail {
360     _ok(0, _where(), @_);
361 }
362
363 sub curr_test {
364     $test = shift if @_;
365     return $test;
366 }
367
368 sub next_test {
369   my $retval = $test;
370   $test = $test + 1; # don't use ++
371   $retval;
372 }
373
374 # Note: can't pass multipart messages since we try to
375 # be compatible with Test::More::skip().
376 sub skip {
377     my $why = shift;
378     my $n    = @_ ? shift : 1;
379     for (1..$n) {
380         _print "ok $test # skip $why\n";
381         $test = $test + 1;
382     }
383     local $^W = 0;
384     last SKIP;
385 }
386
387 sub skip_if_miniperl {
388     skip(@_) if is_miniperl();
389 }
390
391 sub todo_skip {
392     my $why = shift;
393     my $n   = @_ ? shift : 1;
394
395     for (1..$n) {
396         _print "not ok $test # TODO & SKIP $why\n";
397         $test = $test + 1;
398     }
399     local $^W = 0;
400     last TODO;
401 }
402
403 sub eq_array {
404     my ($ra, $rb) = @_;
405     return 0 unless $#$ra == $#$rb;
406     for my $i (0..$#$ra) {
407         next     if !defined $ra->[$i] && !defined $rb->[$i];
408         return 0 if !defined $ra->[$i];
409         return 0 if !defined $rb->[$i];
410         return 0 unless $ra->[$i] eq $rb->[$i];
411     }
412     return 1;
413 }
414
415 sub eq_hash {
416   my ($orig, $suspect) = @_;
417   my $fail;
418   while (my ($key, $value) = each %$suspect) {
419     # Force a hash recompute if this perl's internals can cache the hash key.
420     $key = "" . $key;
421     if (exists $orig->{$key}) {
422       if ($orig->{$key} ne $value) {
423         _print "# key ", _qq($key), " was ", _qq($orig->{$key}),
424                      " now ", _qq($value), "\n";
425         $fail = 1;
426       }
427     } else {
428       _print "# key ", _qq($key), " is ", _qq($value),
429                    ", not in original.\n";
430       $fail = 1;
431     }
432   }
433   foreach (keys %$orig) {
434     # Force a hash recompute if this perl's internals can cache the hash key.
435     $_ = "" . $_;
436     next if (exists $suspect->{$_});
437     _print "# key ", _qq($_), " was ", _qq($orig->{$_}), " now missing.\n";
438     $fail = 1;
439   }
440   !$fail;
441 }
442
443 # We only provide a subset of the Test::More functionality.
444 sub require_ok ($) {
445     my ($require) = @_;
446     if ($require =~ tr/[A-Za-z0-9:.]//c) {
447         fail("Invalid character in \"$require\", passed to require_ok");
448     } else {
449         eval <<REQUIRE_OK;
450 require $require;
451 REQUIRE_OK
452         is($@, '', _where(), "require $require");
453     }
454 }
455
456 sub use_ok ($) {
457     my ($use) = @_;
458     if ($use =~ tr/[A-Za-z0-9:.]//c) {
459         fail("Invalid character in \"$use\", passed to use");
460     } else {
461         eval <<USE_OK;
462 use $use;
463 USE_OK
464         is($@, '', _where(), "use $use");
465     }
466 }
467
468 # runperl - Runs a separate perl interpreter.
469 # Arguments :
470 #   switches => [ command-line switches ]
471 #   nolib    => 1 # don't use -I../lib (included by default)
472 #   non_portable => Don't warn if a one liner contains quotes
473 #   prog     => one-liner (avoid quotes)
474 #   progs    => [ multi-liner (avoid quotes) ]
475 #   progfile => perl script
476 #   stdin    => string to feed the stdin
477 #   stderr   => redirect stderr to stdout
478 #   args     => [ command-line arguments to the perl program ]
479 #   verbose  => print the command line
480
481 my $is_mswin    = $^O eq 'MSWin32';
482 my $is_netware  = $^O eq 'NetWare';
483 my $is_vms      = $^O eq 'VMS';
484 my $is_cygwin   = $^O eq 'cygwin';
485
486 sub _quote_args {
487     my ($runperl, $args) = @_;
488
489     foreach (@$args) {
490         # In VMS protect with doublequotes because otherwise
491         # DCL will lowercase -- unless already doublequoted.
492        $_ = q(").$_.q(") if $is_vms && !/^\"/ && length($_) > 0;
493        $runperl = $runperl . ' ' . $_;
494     }
495     return $runperl;
496 }
497
498 sub _create_runperl { # Create the string to qx in runperl().
499     my %args = @_;
500     my $runperl = which_perl();
501     if ($runperl =~ m/\s/) {
502         $runperl = qq{"$runperl"};
503     }
504     #- this allows, for example, to set PERL_RUNPERL_DEBUG=/usr/bin/valgrind
505     if ($ENV{PERL_RUNPERL_DEBUG}) {
506         $runperl = "$ENV{PERL_RUNPERL_DEBUG} $runperl";
507     }
508     unless ($args{nolib}) {
509         $runperl = $runperl . ' "-I../lib"'; # doublequotes because of VMS
510     }
511     if ($args{switches}) {
512         local $Level = 2;
513         die "test.pl:runperl(): 'switches' must be an ARRAYREF " . _where()
514             unless ref $args{switches} eq "ARRAY";
515         $runperl = _quote_args($runperl, $args{switches});
516     }
517     if (defined $args{prog}) {
518         die "test.pl:runperl(): both 'prog' and 'progs' cannot be used " . _where()
519             if defined $args{progs};
520         $args{progs} = [$args{prog}]
521     }
522     if (defined $args{progs}) {
523         die "test.pl:runperl(): 'progs' must be an ARRAYREF " . _where()
524             unless ref $args{progs} eq "ARRAY";
525         foreach my $prog (@{$args{progs}}) {
526             if ($prog =~ tr/'"// && !$args{non_portable}) {
527                 warn "quotes in prog >>$prog<< are not portable";
528             }
529             if ($is_mswin || $is_netware || $is_vms) {
530                 $runperl = $runperl . qq ( -e "$prog" );
531             }
532             else {
533                 $runperl = $runperl . qq ( -e '$prog' );
534             }
535         }
536     } elsif (defined $args{progfile}) {
537         $runperl = $runperl . qq( "$args{progfile}");
538     } else {
539         # You probably didn't want to be sucking in from the upstream stdin
540         die "test.pl:runperl(): none of prog, progs, progfile, args, "
541             . " switches or stdin specified"
542             unless defined $args{args} or defined $args{switches}
543                 or defined $args{stdin};
544     }
545     if (defined $args{stdin}) {
546         # so we don't try to put literal newlines and crs onto the
547         # command line.
548         $args{stdin} =~ s/\n/\\n/g;
549         $args{stdin} =~ s/\r/\\r/g;
550
551         if ($is_mswin || $is_netware || $is_vms) {
552             $runperl = qq{$Perl -e "print qq(} .
553                 $args{stdin} . q{)" | } . $runperl;
554         }
555         else {
556             $runperl = qq{$Perl -e 'print qq(} .
557                 $args{stdin} . q{)' | } . $runperl;
558         }
559     }
560     if (defined $args{args}) {
561         $runperl = _quote_args($runperl, $args{args});
562     }
563     $runperl = $runperl . ' 2>&1' if $args{stderr};
564     if ($args{verbose}) {
565         my $runperldisplay = $runperl;
566         $runperldisplay =~ s/\n/\n\#/g;
567         _print_stderr "# $runperldisplay\n";
568     }
569     return $runperl;
570 }
571
572 sub runperl {
573     die "test.pl:runperl() does not take a hashref"
574         if ref $_[0] and ref $_[0] eq 'HASH';
575     my $runperl = &_create_runperl;
576     my $result;
577
578     my $tainted = ${^TAINT};
579     my %args = @_;
580     exists $args{switches} && grep m/^-T$/, @{$args{switches}} and $tainted = $tainted + 1;
581
582     if ($tainted) {
583         # We will assume that if you're running under -T, you really mean to
584         # run a fresh perl, so we'll brute force launder everything for you
585         my $sep;
586
587         if (! eval 'require Config; 1') {
588             warn "test.pl had problems loading Config: $@";
589             $sep = ':';
590         } else {
591             $sep = $Config::Config{path_sep};
592         }
593
594         my @keys = grep {exists $ENV{$_}} qw(CDPATH IFS ENV BASH_ENV);
595         local @ENV{@keys} = ();
596         # Untaint, plus take out . and empty string:
597         local $ENV{'DCL$PATH'} = $1 if $is_vms && exists($ENV{'DCL$PATH'}) && ($ENV{'DCL$PATH'} =~ /(.*)/s);
598         $ENV{PATH} =~ /(.*)/s;
599         local $ENV{PATH} =
600             join $sep, grep { $_ ne "" and $_ ne "." and -d $_ and
601                 ($is_mswin or $is_vms or !(stat && (stat _)[2]&0022)) }
602                     split quotemeta ($sep), $1;
603         if ($is_cygwin) {   # Must have /bin under Cygwin
604             if (length $ENV{PATH}) {
605                 $ENV{PATH} = $ENV{PATH} . $sep;
606             }
607             $ENV{PATH} = $ENV{PATH} . '/bin';
608         }
609         $runperl =~ /(.*)/s;
610         $runperl = $1;
611
612         $result = `$runperl`;
613     } else {
614         $result = `$runperl`;
615     }
616     $result =~ s/\n\n/\n/ if $is_vms; # XXX pipes sometimes double these
617     return $result;
618 }
619
620 # Nice alias
621 *run_perl = *run_perl = \&runperl; # shut up "used only once" warning
622
623 sub DIE {
624     _print_stderr "# @_\n";
625     exit 1;
626 }
627
628 # A somewhat safer version of the sometimes wrong $^X.
629 sub which_perl {
630     unless (defined $Perl) {
631         $Perl = $^X;
632
633         # VMS should have 'perl' aliased properly
634         return $Perl if $is_vms;
635
636         my $exe;
637         if (! eval 'require Config; 1') {
638             warn "test.pl had problems loading Config: $@";
639             $exe = '';
640         } else {
641             $exe = $Config::Config{_exe};
642         }
643        $exe = '' unless defined $exe;
644
645         # This doesn't absolutize the path: beware of future chdirs().
646         # We could do File::Spec->abs2rel() but that does getcwd()s,
647         # which is a bit heavyweight to do here.
648
649         if ($Perl =~ /^perl\Q$exe\E$/i) {
650             my $perl = "perl$exe";
651             if (! eval 'require File::Spec; 1') {
652                 warn "test.pl had problems loading File::Spec: $@";
653                 $Perl = "./$perl";
654             } else {
655                 $Perl = File::Spec->catfile(File::Spec->curdir(), $perl);
656             }
657         }
658
659         # Build up the name of the executable file from the name of
660         # the command.
661
662         if ($Perl !~ /\Q$exe\E$/i) {
663             $Perl = $Perl . $exe;
664         }
665
666         warn "which_perl: cannot find $Perl from $^X" unless -f $Perl;
667
668         # For subcommands to use.
669         $ENV{PERLEXE} = $Perl;
670     }
671     return $Perl;
672 }
673
674 sub unlink_all {
675     my $count = 0;
676     foreach my $file (@_) {
677         1 while unlink $file;
678         if( -f $file ){
679             _print_stderr "# Couldn't unlink '$file': $!\n";
680         }else{
681             ++$count;
682         }
683     }
684     $count;
685 }
686
687 my %tmpfiles;
688 END { unlink_all keys %tmpfiles }
689
690 # A regexp that matches the tempfile names
691 $::tempfile_regexp = 'tmp\d+[A-Z][A-Z]?';
692
693 # Avoid ++, avoid ranges, avoid split //
694 my @letters = qw(A B C D E F G H I J K L M N O P Q R S T U V W X Y Z);
695 sub tempfile {
696     my $count = 0;
697     do {
698         my $temp = $count;
699         my $try = "tmp$$";
700         do {
701             $try = $try . $letters[$temp % 26];
702             $temp = int ($temp / 26);
703         } while $temp;
704         # Need to note all the file names we allocated, as a second request may
705         # come before the first is created.
706         if (!-e $try && !$tmpfiles{$try}) {
707             # We have a winner
708             $tmpfiles{$try} = 1;
709             return $try;
710         }
711         $count = $count + 1;
712     } while $count < 26 * 26;
713     die "Can't find temporary file name starting 'tmp$$'";
714 }
715
716 # This is the temporary file for _fresh_perl
717 my $tmpfile = tempfile();
718
719 sub _fresh_perl {
720     my($prog, $action, $expect, $runperl_args, $name) = @_;
721
722     # Given the choice of the mis-parsable {}
723     # (we want an anon hash, but a borked lexer might think that it's a block)
724     # or relying on taking a reference to a lexical
725     # (\ might be mis-parsed, and the reference counting on the pad may go
726     #  awry)
727     # it feels like the least-worse thing is to assume that auto-vivification
728     # works. At least, this is only going to be a run-time failure, so won't
729     # affect tests using this file but not this function.
730     $runperl_args->{progfile} = $tmpfile;
731     $runperl_args->{stderr} = 1;
732
733     open TEST, ">$tmpfile" or die "Cannot open $tmpfile: $!";
734
735     # VMS adjustments
736     if( $is_vms ) {
737         $prog =~ s#/dev/null#NL:#;
738
739         # VMS file locking
740         $prog =~ s{if \(-e _ and -f _ and -r _\)}
741                   {if (-e _ and -f _)}
742     }
743
744     print TEST $prog;
745     close TEST or die "Cannot close $tmpfile: $!";
746
747     my $results = runperl(%$runperl_args);
748     my $status = $?;
749
750     # Clean up the results into something a bit more predictable.
751     $results  =~ s/\n+$//;
752     $results =~ s/at\s+$::tempfile_regexp\s+line/at - line/g;
753     $results =~ s/of\s+$::tempfile_regexp\s+aborted/of - aborted/g;
754
755     # bison says 'parse error' instead of 'syntax error',
756     # various yaccs may or may not capitalize 'syntax'.
757     $results =~ s/^(syntax|parse) error/syntax error/mig;
758
759     if ($is_vms) {
760         # some tests will trigger VMS messages that won't be expected
761         $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
762
763         # pipes double these sometimes
764         $results =~ s/\n\n/\n/g;
765     }
766
767     # Use the first line of the program as a name if none was given
768     unless( $name ) {
769         ($first_line, $name) = $prog =~ /^((.{1,50}).*)/;
770         $name = $name . '...' if length $first_line > length $name;
771     }
772
773     # Historically this was implemented using a closure, but then that means
774     # that the tests for closures avoid using this code. Given that there
775     # are exactly two callers, doing exactly two things, the simpler approach
776     # feels like a better trade off.
777     my $pass;
778     if ($action eq 'eq') {
779         $pass = is($results, $expect, $name);
780     } elsif ($action eq '=~') {
781         $pass = like($results, $expect, $name);
782     } else {
783         die "_fresh_perl can't process action '$action'";
784     }
785         
786     unless ($pass) {
787         _diag "# PROG: \n$prog\n";
788         _diag "# STATUS: $status\n";
789     }
790
791     return $pass;
792 }
793
794 #
795 # fresh_perl_is
796 #
797 # Combination of run_perl() and is().
798 #
799
800 sub fresh_perl_is {
801     my($prog, $expected, $runperl_args, $name) = @_;
802
803     # _fresh_perl() is going to clip the trailing newlines off the result.
804     # This will make it so the test author doesn't have to know that.
805     $expected =~ s/\n+$//;
806
807     local $Level = 2;
808     _fresh_perl($prog, 'eq', $expected, $runperl_args, $name);
809 }
810
811 #
812 # fresh_perl_like
813 #
814 # Combination of run_perl() and like().
815 #
816
817 sub fresh_perl_like {
818     my($prog, $expected, $runperl_args, $name) = @_;
819     local $Level = 2;
820     _fresh_perl($prog, '=~', $expected, $runperl_args, $name);
821 }
822
823 # Many tests use the same format in __DATA__ or external files to specify a
824 # sequence of (fresh) tests to run, extra files they may temporarily need, and
825 # what the expected output is. So have excatly one copy of the code to run that
826
827 sub run_multiple_progs {
828     my $up = shift;
829     my @prgs;
830     if ($up) {
831         # The tests in lib run in a temporary subdirectory of t, and always
832         # pass in a list of "programs" to run
833         @prgs = @_;
834     } else {
835         # The tests below t run in t and pass in a file handle.
836         my $fh = shift;
837         local $/;
838         @prgs = split "\n########\n", <$fh>;
839     }
840
841     my $tmpfile = tempfile();
842
843     for (@prgs){
844         unless (/\n/) {
845             print "# From $_\n";
846             next;
847         }
848         my $switch = "";
849         my @temps ;
850         my @temp_path;
851         if (s/^(\s*-\w+)//) {
852             $switch = $1;
853         }
854         my ($prog, $expected) = split(/\nEXPECT(?:\n|$)/, $_, 2);
855
856         my %reason;
857         foreach my $what (qw(skip todo)) {
858             $prog =~ s/^#\s*\U$what\E\s*(.*)\n//m and $reason{$what} = $1;
859             # If the SKIP reason starts ? then it's taken as a code snippet to
860             # evaluate. This provides the flexibility to have conditional SKIPs
861             if ($reason{$what} && $reason{$what} =~ s/^\?//) {
862                 my $temp = eval $reason{$what};
863                 if ($@) {
864                     die "# In \U$what\E code reason:\n# $reason{$what}\n$@";
865                 }
866                 $reason{$what} = $temp;
867             }
868         }
869
870         if ($prog =~ /--FILE--/) {
871             my @files = split(/\n--FILE--\s*([^\s\n]*)\s*\n/, $prog) ;
872             shift @files ;
873             die "Internal error: test $_ didn't split into pairs, got " .
874                 scalar(@files) . "[" . join("%%%%", @files) ."]\n"
875                     if @files % 2;
876             while (@files > 2) {
877                 my $filename = shift @files;
878                 my $code = shift @files;
879                 push @temps, $filename;
880                 if ($filename =~ m#(.*)/# && $filename !~ m#^\.\./#) {
881                     require File::Path;
882                     File::Path::mkpath($1);
883                     push(@temp_path, $1);
884                 }
885                 open my $fh, '>', $filename or die "Cannot open $filename: $!\n";
886                 print $fh $code;
887                 close $fh or die "Cannot close $filename: $!\n";
888             }
889             shift @files;
890             $prog = shift @files;
891         }
892
893         open my $fh, '>', $tmpfile or die "Cannot open >$tmpfile: $!";
894         print $fh q{
895         BEGIN {
896             open STDERR, '>&', STDOUT
897               or die "Can't dup STDOUT->STDERR: $!;";
898         }
899         };
900         print $fh "\n#line 1\n";  # So the line numbers don't get messed up.
901         print $fh $prog,"\n";
902         close $fh or die "Cannot close $tmpfile: $!";
903         my $results = runperl( stderr => 1, progfile => $tmpfile, $up
904                                ? (switches => ["-I$up/lib", $switch], nolib => 1)
905                                : (switches => [$switch])
906                                 );
907         my $status = $?;
908         $results =~ s/\n+$//;
909         # allow expected output to be written as if $prog is on STDIN
910         $results =~ s/$::tempfile_regexp/-/g;
911         if ($^O eq 'VMS') {
912             # some tests will trigger VMS messages that won't be expected
913             $results =~ s/\n?%[A-Z]+-[SIWEF]-[A-Z]+,.*//;
914
915             # pipes double these sometimes
916             $results =~ s/\n\n/\n/g;
917         }
918         # bison says 'parse error' instead of 'syntax error',
919         # various yaccs may or may not capitalize 'syntax'.
920         $results =~ s/^(syntax|parse) error/syntax error/mig;
921         # allow all tests to run when there are leaks
922         $results =~ s/Scalars leaked: \d+\n//g;
923
924         $expected =~ s/\n+$//;
925         my $prefix = ($results =~ s#^PREFIX(\n|$)##) ;
926         # any special options? (OPTIONS foo bar zap)
927         my $option_regex = 0;
928         my $option_random = 0;
929         if ($expected =~ s/^OPTIONS? (.+)\n//) {
930             foreach my $option (split(' ', $1)) {
931                 if ($option eq 'regex') { # allow regular expressions
932                     $option_regex = 1;
933                 }
934                 elsif ($option eq 'random') { # all lines match, but in any order
935                     $option_random = 1;
936                 }
937                 else {
938                     die "$0: Unknown OPTION '$option'\n";
939                 }
940             }
941         }
942         die "$0: can't have OPTION regex and random\n"
943             if $option_regex + $option_random > 1;
944         my $ok = 0;
945         if ($results =~ s/^SKIPPED\n//) {
946             print "$results\n" ;
947             $ok = 1;
948         }
949         elsif ($option_random) {
950             my @got = sort split "\n", $results;
951             my @expected = sort split "\n", $expected;
952
953             $ok = "@got" eq "@expected";
954         }
955         elsif ($option_regex) {
956             $ok = $results =~ /^$expected/;
957         }
958         elsif ($prefix) {
959             $ok = $results =~ /^\Q$expected/;
960         }
961         else {
962             $ok = $results eq $expected;
963         }
964
965         local $::TODO = $reason{todo};
966
967         unless ($ok) {
968             my $err_line = "PROG: $switch\n$prog\n" .
969                            "EXPECTED:\n$expected\n" .
970                            "GOT:\n$results\n";
971             if ($::TODO) {
972                 $err_line =~ s/^/# /mg;
973                 print $err_line;  # Harness can't filter it out from STDERR.
974             }
975             else {
976                 print STDERR $err_line;
977             }
978         }
979
980         ok($ok);
981
982         foreach (@temps) {
983             unlink $_ if $_;
984         }
985         foreach (@temp_path) {
986             File::Path::rmtree $_ if -d $_;
987         }
988     }
989 }
990
991 sub can_ok ($@) {
992     my($proto, @methods) = @_;
993     my $class = ref $proto || $proto;
994
995     unless( @methods ) {
996         return _ok( 0, _where(), "$class->can(...)" );
997     }
998
999     my @nok = ();
1000     foreach my $method (@methods) {
1001         local($!, $@);  # don't interfere with caller's $@
1002                         # eval sometimes resets $!
1003         eval { $proto->can($method) } || push @nok, $method;
1004     }
1005
1006     my $name;
1007     $name = @methods == 1 ? "$class->can('$methods[0]')"
1008                           : "$class->can(...)";
1009
1010     _ok( !@nok, _where(), $name );
1011 }
1012
1013
1014 # Call $class->new( @$args ); and run the result through isa_ok.
1015 # See Test::More::new_ok
1016 sub new_ok {
1017     my($class, $args, $obj_name) = @_;
1018     $args ||= [];
1019     $object_name = "The object" unless defined $obj_name;
1020
1021     local $Level = $Level + 1;
1022
1023     my $obj;
1024     my $ok = eval { $obj = $class->new(@$args); 1 };
1025     my $error = $@;
1026
1027     if($ok) {
1028         isa_ok($obj, $class, $object_name);
1029     }
1030     else {
1031         ok( 0, "new() died" );
1032         diag("Error was:  $@");
1033     }
1034
1035     return $obj;
1036
1037 }
1038
1039
1040 sub isa_ok ($$;$) {
1041     my($object, $class, $obj_name) = @_;
1042
1043     my $diag;
1044     $obj_name = 'The object' unless defined $obj_name;
1045     my $name = "$obj_name isa $class";
1046     if( !defined $object ) {
1047         $diag = "$obj_name isn't defined";
1048     }
1049     elsif( !ref $object ) {
1050         $diag = "$obj_name isn't a reference";
1051     }
1052     else {
1053         # We can't use UNIVERSAL::isa because we want to honor isa() overrides
1054         local($@, $!);  # eval sometimes resets $!
1055         my $rslt = eval { $object->isa($class) };
1056         if( $@ ) {
1057             if( $@ =~ /^Can't call method "isa" on unblessed reference/ ) {
1058                 if( !UNIVERSAL::isa($object, $class) ) {
1059                     my $ref = ref $object;
1060                     $diag = "$obj_name isn't a '$class' it's a '$ref'";
1061                 }
1062             } else {
1063                 die <<WHOA;
1064 WHOA! I tried to call ->isa on your object and got some weird error.
1065 This should never happen.  Please contact the author immediately.
1066 Here's the error.
1067 $@
1068 WHOA
1069             }
1070         }
1071         elsif( !$rslt ) {
1072             my $ref = ref $object;
1073             $diag = "$obj_name isn't a '$class' it's a '$ref'";
1074         }
1075     }
1076
1077     _ok( !$diag, _where(), $name );
1078 }
1079
1080 # This will generate a variable number of tests if passed an array of 2 or more
1081 # tests. Use done_testing() instead of a fixed plan.
1082 sub warnings_like {
1083     my ($code, $expect, $name) = @_;
1084     my @w;
1085     local $SIG {__WARN__} = sub {push @w, join "", @_};
1086     {
1087         use warnings 'all';
1088         &$code;
1089     }
1090     local $Level = $Level + 1;
1091
1092     cmp_ok(scalar @w, '==', scalar @$expect, $name) if @$expect != 1;
1093     while (my ($i, $e) = each @$expect) {
1094         if (ref $e) {
1095             like($w[$i], $e, $name);
1096         } else {
1097             is($w[$i], $e, $name);
1098         }
1099     }
1100 }
1101
1102 sub warning_is {
1103     my ($code, $expect, $name) = @_;
1104     die sprintf "Expect must be a string or undef, not a %s reference", ref $expect
1105         if ref $expect;
1106     local $Level = $Level + 1;
1107     warnings_like($code, defined $expect? [$expect] : [], $name);
1108 }
1109
1110 sub warning_like {
1111     my ($code, $expect, $name) = @_;
1112     die sprintf "Expect must be a regexp object"
1113         unless ref $expect eq 'Regexp';
1114     local $Level = $Level + 1;
1115     warnings_like($code, [$expect], $name);
1116 }
1117
1118 # Set a watchdog to timeout the entire test file
1119 # NOTE:  If the test file uses 'threads', then call the watchdog() function
1120 #        _AFTER_ the 'threads' module is loaded.
1121 sub watchdog ($;$)
1122 {
1123     my $timeout = shift;
1124     my $method  = shift || "";
1125     my $timeout_msg = 'Test process timed out - terminating';
1126
1127     # Valgrind slows perl way down so give it more time before dying.
1128     $timeout *= 10 if $ENV{PERL_VALGRIND};
1129
1130     my $pid_to_kill = $$;   # PID for this process
1131
1132     if ($method eq "alarm") {
1133         goto WATCHDOG_VIA_ALARM;
1134     }
1135
1136     # shut up use only once warning
1137     my $threads_on = $threads::threads && $threads::threads;
1138
1139     # Don't use a watchdog process if 'threads' is loaded -
1140     #   use a watchdog thread instead
1141     if (!$threads_on) {
1142
1143         # On Windows and VMS, try launching a watchdog process
1144         #   using system(1, ...) (see perlport.pod)
1145         if ($is_mswin || $is_vms) {
1146             # On Windows, try to get the 'real' PID
1147             if ($is_mswin) {
1148                 eval { require Win32; };
1149                 if (defined(&Win32::GetCurrentProcessId)) {
1150                     $pid_to_kill = Win32::GetCurrentProcessId();
1151                 }
1152             }
1153
1154             # If we still have a fake PID, we can't use this method at all
1155             return if ($pid_to_kill <= 0);
1156
1157             # Launch watchdog process
1158             my $watchdog;
1159             eval {
1160                 local $SIG{'__WARN__'} = sub {
1161                     _diag("Watchdog warning: $_[0]");
1162                 };
1163                 my $sig = $is_vms ? 'TERM' : 'KILL';
1164                 my $cmd = _create_runperl( prog =>  "sleep($timeout);" .
1165                                                     "warn qq/# $timeout_msg" . '\n/;' .
1166                                                     "kill($sig, $pid_to_kill);");
1167                 $watchdog = system(1, $cmd);
1168             };
1169             if ($@ || ($watchdog <= 0)) {
1170                 _diag('Failed to start watchdog');
1171                 _diag($@) if $@;
1172                 undef($watchdog);
1173                 return;
1174             }
1175
1176             # Add END block to parent to terminate and
1177             #   clean up watchdog process
1178             eval "END { local \$! = 0; local \$? = 0;
1179                         wait() if kill('KILL', $watchdog); };";
1180             return;
1181         }
1182
1183         # Try using fork() to generate a watchdog process
1184         my $watchdog;
1185         eval { $watchdog = fork() };
1186         if (defined($watchdog)) {
1187             if ($watchdog) {   # Parent process
1188                 # Add END block to parent to terminate and
1189                 #   clean up watchdog process
1190                 eval "END { local \$! = 0; local \$? = 0;
1191                             wait() if kill('KILL', $watchdog); };";
1192                 return;
1193             }
1194
1195             ### Watchdog process code
1196
1197             # Load POSIX if available
1198             eval { require POSIX; };
1199
1200             # Execute the timeout
1201             sleep($timeout - 2) if ($timeout > 2);   # Workaround for perlbug #49073
1202             sleep(2);
1203
1204             # Kill test process if still running
1205             if (kill(0, $pid_to_kill)) {
1206                 _diag($timeout_msg);
1207                 kill('KILL', $pid_to_kill);
1208             }
1209
1210             # Don't execute END block (added at beginning of this file)
1211             $NO_ENDING = 1;
1212
1213             # Terminate ourself (i.e., the watchdog)
1214             POSIX::_exit(1) if (defined(&POSIX::_exit));
1215             exit(1);
1216         }
1217
1218         # fork() failed - fall through and try using a thread
1219     }
1220
1221     # Use a watchdog thread because either 'threads' is loaded,
1222     #   or fork() failed
1223     if (eval 'require threads; 1') {
1224         'threads'->create(sub {
1225                 # Load POSIX if available
1226                 eval { require POSIX; };
1227
1228                 # Execute the timeout
1229                 my $time_left = $timeout;
1230                 do {
1231                     $time_left = $time_left - sleep($time_left);
1232                 } while ($time_left > 0);
1233
1234                 # Kill the parent (and ourself)
1235                 select(STDERR); $| = 1;
1236                 _diag($timeout_msg);
1237                 POSIX::_exit(1) if (defined(&POSIX::_exit));
1238                 my $sig = $is_vms ? 'TERM' : 'KILL';
1239                 kill($sig, $pid_to_kill);
1240             })->detach();
1241         return;
1242     }
1243
1244     # If everything above fails, then just use an alarm timeout
1245 WATCHDOG_VIA_ALARM:
1246     if (eval { alarm($timeout); 1; }) {
1247         # Load POSIX if available
1248         eval { require POSIX; };
1249
1250         # Alarm handler will do the actual 'killing'
1251         $SIG{'ALRM'} = sub {
1252             select(STDERR); $| = 1;
1253             _diag($timeout_msg);
1254             POSIX::_exit(1) if (defined(&POSIX::_exit));
1255             my $sig = $is_vms ? 'TERM' : 'KILL';
1256             kill($sig, $pid_to_kill);
1257         };
1258     }
1259 }
1260
1261 my $cp_0037 =   # EBCDIC code page 0037
1262     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x25\x0B\x0C\x0D\x0E\x0F' .
1263     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1264     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1265     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1266     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1267     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBA\xE0\xBB\xB0\x6D' .
1268     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1269     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1270     '\x20\x21\x22\x23\x24\x15\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1271     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1272     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBD\xB4\x9A\x8A\x5F\xCA\xAF\xBC' .
1273     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1274     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1275     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xAD\xAE\x59' .
1276     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1277     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1278
1279 my $cp_1047 =   # EBCDIC code page 1047
1280     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1281     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1282     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1283     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1284     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1285     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xAD\xE0\xBD\x5F\x6D' .
1286     '\x79\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1287     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xC0\x4F\xD0\xA1\x07' .
1288     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1289     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\xFF' .
1290     '\x41\xAA\x4A\xB1\x9F\xB2\x6A\xB5\xBB\xB4\x9A\x8A\xB0\xCA\xAF\xBC' .
1291     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1292     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1293     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xFD\xFE\xFB\xFC\xBA\xAE\x59' .
1294     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1295     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xDD\xDE\xDB\xDC\x8D\x8E\xDF';
1296
1297 my $cp_bc = # EBCDIC code page POSiX-BC
1298     '\x00\x01\x02\x03\x37\x2D\x2E\x2F\x16\x05\x15\x0B\x0C\x0D\x0E\x0F' .
1299     '\x10\x11\x12\x13\x3C\x3D\x32\x26\x18\x19\x3F\x27\x1C\x1D\x1E\x1F' .
1300     '\x40\x5A\x7F\x7B\x5B\x6C\x50\x7D\x4D\x5D\x5C\x4E\x6B\x60\x4B\x61' .
1301     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\x7A\x5E\x4C\x7E\x6E\x6F' .
1302     '\x7C\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xD1\xD2\xD3\xD4\xD5\xD6' .
1303     '\xD7\xD8\xD9\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xBB\xBC\xBD\x6A\x6D' .
1304     '\x4A\x81\x82\x83\x84\x85\x86\x87\x88\x89\x91\x92\x93\x94\x95\x96' .
1305     '\x97\x98\x99\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xFB\x4F\xFD\xFF\x07' .
1306     '\x20\x21\x22\x23\x24\x25\x06\x17\x28\x29\x2A\x2B\x2C\x09\x0A\x1B' .
1307     '\x30\x31\x1A\x33\x34\x35\x36\x08\x38\x39\x3A\x3B\x04\x14\x3E\x5F' .
1308     '\x41\xAA\xB0\xB1\x9F\xB2\xD0\xB5\x79\xB4\x9A\x8A\xBA\xCA\xAF\xA1' .
1309     '\x90\x8F\xEA\xFA\xBE\xA0\xB6\xB3\x9D\xDA\x9B\x8B\xB7\xB8\xB9\xAB' .
1310     '\x64\x65\x62\x66\x63\x67\x9E\x68\x74\x71\x72\x73\x78\x75\x76\x77' .
1311     '\xAC\x69\xED\xEE\xEB\xEF\xEC\xBF\x80\xE0\xFE\xDD\xFC\xAD\xAE\x59' .
1312     '\x44\x45\x42\x46\x43\x47\x9C\x48\x54\x51\x52\x53\x58\x55\x56\x57' .
1313     '\x8C\x49\xCD\xCE\xCB\xCF\xCC\xE1\x70\xC0\xDE\xDB\xDC\x8D\x8E\xDF';
1314
1315 my $straight =  # Avoid ranges
1316     '\x00\x01\x02\x03\x04\x05\x06\x07\x08\x09\x0A\x0B\x0C\x0D\x0E\x0F' .
1317     '\x10\x11\x12\x13\x14\x15\x16\x17\x18\x19\x1A\x1B\x1C\x1D\x1E\x1F' .
1318     '\x20\x21\x22\x23\x24\x25\x26\x27\x28\x29\x2A\x2B\x2C\x2D\x2E\x2F' .
1319     '\x30\x31\x32\x33\x34\x35\x36\x37\x38\x39\x3A\x3B\x3C\x3D\x3E\x3F' .
1320     '\x40\x41\x42\x43\x44\x45\x46\x47\x48\x49\x4A\x4B\x4C\x4D\x4E\x4F' .
1321     '\x50\x51\x52\x53\x54\x55\x56\x57\x58\x59\x5A\x5B\x5C\x5D\x5E\x5F' .
1322     '\x60\x61\x62\x63\x64\x65\x66\x67\x68\x69\x6A\x6B\x6C\x6D\x6E\x6F' .
1323     '\x70\x71\x72\x73\x74\x75\x76\x77\x78\x79\x7A\x7B\x7C\x7D\x7E\x7F' .
1324     '\x80\x81\x82\x83\x84\x85\x86\x87\x88\x89\x8A\x8B\x8C\x8D\x8E\x8F' .
1325     '\x90\x91\x92\x93\x94\x95\x96\x97\x98\x99\x9A\x9B\x9C\x9D\x9E\x9F' .
1326     '\xA0\xA1\xA2\xA3\xA4\xA5\xA6\xA7\xA8\xA9\xAA\xAB\xAC\xAD\xAE\xAF' .
1327     '\xB0\xB1\xB2\xB3\xB4\xB5\xB6\xB7\xB8\xB9\xBA\xBB\xBC\xBD\xBE\xBF' .
1328     '\xC0\xC1\xC2\xC3\xC4\xC5\xC6\xC7\xC8\xC9\xCA\xCB\xCC\xCD\xCE\xCF' .
1329     '\xD0\xD1\xD2\xD3\xD4\xD5\xD6\xD7\xD8\xD9\xDA\xDB\xDC\xDD\xDE\xDF' .
1330     '\xE0\xE1\xE2\xE3\xE4\xE5\xE6\xE7\xE8\xE9\xEA\xEB\xEC\xED\xEE\xEF' .
1331     '\xF0\xF1\xF2\xF3\xF4\xF5\xF6\xF7\xF8\xF9\xFA\xFB\xFC\xFD\xFE\xFF';
1332
1333 # The following 2 functions allow tests to work on both EBCDIC and
1334 # ASCII-ish platforms.  They convert string scalars between the native
1335 # character set and the set of 256 characters which is usually called
1336 # Latin1.
1337 #
1338 # These routines don't work on UTF-EBCDIC and UTF-8.
1339
1340 sub native_to_latin1($) {
1341     my $string = shift;
1342
1343     return $string if ord('^') == 94;   # ASCII, Latin1
1344     my $cp;
1345     if (ord('^') == 95) {    # EBCDIC 1047
1346         $cp = \$cp_1047;
1347     }
1348     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1349         $cp = \$cp_bc;
1350     }
1351     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1352         $cp = \$cp_0037;
1353     }
1354     else {
1355         die "Unknown native character set";
1356     }
1357
1358     eval '$string =~ tr/' . $$cp . '/' . $straight . '/';
1359     return $string;
1360 }
1361
1362 sub latin1_to_native($) {
1363     my $string = shift;
1364
1365     return $string if ord('^') == 94;   # ASCII, Latin1
1366     my $cp;
1367     if (ord('^') == 95) {    # EBCDIC 1047
1368         $cp = \$cp_1047;
1369     }
1370     elsif (ord('^') == 106) {   # EBCDIC POSIX-BC
1371         $cp = \$cp_bc;
1372     }
1373     elsif (ord('^') == 176)  {   # EBCDIC 037 */
1374         $cp = \$cp_0037;
1375     }
1376     else {
1377         die "Unknown native character set";
1378     }
1379
1380     eval '$string =~ tr/' . $straight . '/' . $$cp . '/';
1381     return $string;
1382 }
1383
1384 sub ord_latin1_to_native {
1385     # given an input code point, return the platform's native
1386     # equivalent value.  Anything above latin1 is itself.
1387
1388     my $ord = shift;
1389     return $ord if $ord > 255;
1390     return ord latin1_to_native(chr $ord);
1391 }
1392
1393 sub ord_native_to_latin1 {
1394     # given an input platform code point, return the latin1 equivalent value.
1395     # Anything above latin1 is itself.
1396
1397     my $ord = shift;
1398     return $ord if $ord > 255;
1399     return ord native_to_latin1(chr $ord);
1400 }
1401
1402 1;