This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Look up state subs in the pad
[perl5.git] / perly.y
1 /*    perly.y
2  *
3  *    Copyright (c) 1991-2002, 2003, 2004, 2005, 2006 Larry Wall
4  *    Copyright (c) 2007, 2008, 2009, 2010, 2011 by Larry Wall and others
5  *
6  *    You may distribute under the terms of either the GNU General Public
7  *    License or the Artistic License, as specified in the README file.
8  *
9  */
10
11 /*
12  * 'I see,' laughed Strider.  'I look foul and feel fair.  Is that it?
13  *  All that is gold does not glitter, not all those who wander are lost.'
14  *
15  *     [p.171 of _The Lord of the Rings_, I/x: "Strider"]
16  */
17
18 /*
19  * This file holds the grammar for the Perl language. If edited, you need
20  * to run regen_perly.pl, which re-creates the files perly.h, perly.tab
21  * and perly.act which are derived from this.
22  *
23  * Note that these derived files are included and compiled twice; once
24  * from perly.c, and once from madly.c. The second time, a number of MAD
25  * macros are defined, which compile in extra code that allows the parse
26  * tree to be accurately dumped. In particular:
27  *
28  * MAD            defined if compiling madly.c
29  * DO_MAD(A)      expands to A  under madly.c, to null otherwise
30  * IF_MAD(a,b)    expands to A under madly.c, to B otherwise
31  * TOKEN_GETMAD() expands to token_getmad() under madly.c, to null otherwise
32  * TOKEN_FREE()   similarly
33  * OP_GETMAD()    similarly
34  * IVAL(i)        expands to (i)->tk_lval.ival or (i)
35  * PVAL(p)        expands to (p)->tk_lval.pval or (p)
36  *
37  * The main job of of this grammar is to call the various newFOO()
38  * functions in op.c to build a syntax tree of OP structs.
39  * It relies on the lexer in toke.c to do the tokenizing.
40  *
41  * Note: due to the way that the cleanup code works WRT to freeing ops on
42  * the parse stack, it is dangerous to assign to the $n variables within
43  * an action.
44  */
45
46 /*  Make the parser re-entrant. */
47
48 %pure_parser
49
50 /* FIXME for MAD - is the new mintro on while and until important?  */
51
52 %start grammar
53
54 %union {
55     I32 ival; /* __DEFAULT__ (marker for regen_perly.pl;
56                                 must always be 1st union member) */
57     char *pval;
58     OP *opval;
59     GV *gvval;
60 #ifdef PERL_IN_MADLY_C
61     TOKEN* p_tkval;
62     TOKEN* i_tkval;
63 #else
64     char *p_tkval;
65     I32 i_tkval;
66 #endif
67 #ifdef PERL_MAD
68     TOKEN* tkval;
69 #endif
70 }
71
72 %token <ival> GRAMPROG GRAMEXPR GRAMBLOCK GRAMBARESTMT GRAMFULLSTMT GRAMSTMTSEQ
73
74 %token <i_tkval> '{' '}' '[' ']' '-' '+' '$' '@' '%' '*' '&' ';' '=' '.'
75
76 %token <opval> WORD METHOD FUNCMETH THING PMFUNC PRIVATEREF QWLIST
77 %token <opval> FUNC0OP FUNC0SUB UNIOPSUB LSTOPSUB
78 %token <opval> PLUGEXPR PLUGSTMT
79 %token <p_tkval> LABEL
80 %token <i_tkval> FORMAT SUB ANONSUB PACKAGE USE
81 %token <i_tkval> WHILE UNTIL IF UNLESS ELSE ELSIF CONTINUE FOR
82 %token <i_tkval> GIVEN WHEN DEFAULT
83 %token <i_tkval> LOOPEX DOTDOT YADAYADA
84 %token <i_tkval> FUNC0 FUNC1 FUNC UNIOP LSTOP
85 %token <i_tkval> RELOP EQOP MULOP ADDOP
86 %token <i_tkval> DOLSHARP DO HASHBRACK NOAMP
87 %token <i_tkval> LOCAL MY MYSUB REQUIRE
88 %token <i_tkval> COLONATTR FORMLBRACK FORMRBRACK
89
90 %type <ival> grammar remember mremember
91 %type <ival>  startsub startanonsub startformsub
92 /* FIXME for MAD - are these two ival? */
93 %type <ival> mintro
94
95 %type <opval> stmtseq fullstmt labfullstmt barestmt block mblock else
96 %type <opval> expr term subscripted scalar ary hsh arylen star amper sideff
97 %type <opval> listexpr nexpr texpr iexpr mexpr mnexpr miexpr
98 %type <opval> optlistexpr optexpr indirob listop method
99 %type <opval> formname subname proto subbody cont my_scalar formblock
100 %type <opval> subattrlist myattrlist myattrterm myterm
101 %type <opval> termbinop termunop anonymous termdo
102 %type <opval> formstmtseq formline formarg
103
104 %nonassoc <i_tkval> PREC_LOW
105 %nonassoc LOOPEX
106
107 %left <i_tkval> OROP DOROP
108 %left <i_tkval> ANDOP
109 %right <i_tkval> NOTOP
110 %nonassoc LSTOP LSTOPSUB
111 %left <i_tkval> ','
112 %right <i_tkval> ASSIGNOP
113 %right <i_tkval> '?' ':'
114 %nonassoc DOTDOT YADAYADA
115 %left <i_tkval> OROR DORDOR
116 %left <i_tkval> ANDAND
117 %left <i_tkval> BITOROP
118 %left <i_tkval> BITANDOP
119 %nonassoc EQOP
120 %nonassoc RELOP
121 %nonassoc UNIOP UNIOPSUB
122 %nonassoc REQUIRE
123 %left <i_tkval> SHIFTOP
124 %left ADDOP
125 %left MULOP
126 %left <i_tkval> MATCHOP
127 %right <i_tkval> '!' '~' UMINUS REFGEN
128 %right <i_tkval> POWOP
129 %nonassoc <i_tkval> PREINC PREDEC POSTINC POSTDEC
130 %left <i_tkval> ARROW
131 %nonassoc <i_tkval> ')'
132 %left <i_tkval> '('
133 %left '[' '{'
134
135 %token <i_tkval> PEG
136
137 %% /* RULES */
138
139 /* Top-level choice of what kind of thing yyparse was called to parse */
140 grammar :       GRAMPROG
141                         {
142                           PL_parser->expect = XSTATE;
143                         }
144                 remember stmtseq
145                         {
146                           newPROG(block_end($3,$4));
147                           $$ = 0;
148                         }
149         |       GRAMEXPR
150                         {
151                           parser->expect = XTERM;
152                         }
153                 optexpr
154                         {
155                           PL_eval_root = $3;
156                           $$ = 0;
157                         }
158         |       GRAMBLOCK
159                         {
160                           parser->expect = XBLOCK;
161                         }
162                 block
163                         {
164                           PL_pad_reset_pending = TRUE;
165                           PL_eval_root = $3;
166                           $$ = 0;
167                           yyunlex();
168                           parser->yychar = YYEOF;
169                         }
170         |       GRAMBARESTMT
171                         {
172                           parser->expect = XSTATE;
173                         }
174                 barestmt
175                         {
176                           PL_pad_reset_pending = TRUE;
177                           PL_eval_root = $3;
178                           $$ = 0;
179                           yyunlex();
180                           parser->yychar = YYEOF;
181                         }
182         |       GRAMFULLSTMT
183                         {
184                           parser->expect = XSTATE;
185                         }
186                 fullstmt
187                         {
188                           PL_pad_reset_pending = TRUE;
189                           PL_eval_root = $3;
190                           $$ = 0;
191                           yyunlex();
192                           parser->yychar = YYEOF;
193                         }
194         |       GRAMSTMTSEQ
195                         {
196                           parser->expect = XSTATE;
197                         }
198                 stmtseq
199                         {
200                           PL_eval_root = $3;
201                           $$ = 0;
202                         }
203         ;
204
205 /* An ordinary block */
206 block   :       '{' remember stmtseq '}'
207                         { if (PL_parser->copline > (line_t)IVAL($1))
208                               PL_parser->copline = (line_t)IVAL($1);
209                           $$ = block_end($2, $3);
210                           TOKEN_GETMAD($1,$$,'{');
211                           TOKEN_GETMAD($4,$$,'}');
212                         }
213         ;
214
215 /* format body */
216 formblock:      '=' remember ';' FORMRBRACK formstmtseq ';' '.'
217                         { if (PL_parser->copline > (line_t)IVAL($1))
218                               PL_parser->copline = (line_t)IVAL($1);
219                           $$ = block_end($2, $5);
220                           TOKEN_GETMAD($1,$$,'{');
221                           TOKEN_GETMAD($7,$$,'}');
222                         }
223         ;
224
225 remember:       /* NULL */      /* start a full lexical scope */
226                         { $$ = block_start(TRUE); }
227         ;
228
229 mblock  :       '{' mremember stmtseq '}'
230                         { if (PL_parser->copline > (line_t)IVAL($1))
231                               PL_parser->copline = (line_t)IVAL($1);
232                           $$ = block_end($2, $3);
233                           TOKEN_GETMAD($1,$$,'{');
234                           TOKEN_GETMAD($4,$$,'}');
235                         }
236         ;
237
238 mremember:      /* NULL */      /* start a partial lexical scope */
239                         { $$ = block_start(FALSE); }
240         ;
241
242 /* A sequence of statements in the program */
243 stmtseq :       /* NULL */
244                         { $$ = (OP*)NULL; }
245         |       stmtseq fullstmt
246                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
247                             PL_pad_reset_pending = TRUE;
248                             if ($1 && $2)
249                                 PL_hints |= HINT_BLOCK_SCOPE;
250                         }
251         ;
252
253 /* A sequence of format lines */
254 formstmtseq:    /* NULL */
255                         { $$ = (OP*)NULL; }
256         |       formstmtseq formline
257                         {   $$ = op_append_list(OP_LINESEQ, $1, $2);
258                             PL_pad_reset_pending = TRUE;
259                             if ($1 && $2)
260                                 PL_hints |= HINT_BLOCK_SCOPE;
261                         }
262         ;
263
264 /* A statement in the program, including optional labels */
265 fullstmt:       barestmt
266                         {
267                           if($1) {
268                               $$ = newSTATEOP(0, NULL, $1);
269                           } else {
270                               $$ = IF_MAD(newOP(OP_NULL, 0), NULL);
271                           }
272                         }
273         |       labfullstmt
274                         { $$ = $1; }
275         ;
276
277 labfullstmt:    LABEL barestmt
278                         {
279                           $$ = newSTATEOP(SvUTF8(((SVOP*)$1)->op_sv),
280                                         savepv(SvPVX(((SVOP*)$1)->op_sv)), $2);
281                           TOKEN_GETMAD($1,
282                               $2 ? cLISTOPx($$)->op_first : $$, 'L');
283                         }
284         |       LABEL labfullstmt
285                         {
286                           $$ = newSTATEOP(SvUTF8(((SVOP*)$1)->op_sv),
287                                         savepv(SvPVX(((SVOP*)$1)->op_sv)), $2);
288                           TOKEN_GETMAD($1, cLISTOPx($$)->op_first, 'L');
289                         }
290         ;
291
292 /* A bare statement, lacking label and other aspects of state op */
293 barestmt:       PLUGSTMT
294                         { $$ = $1; }
295         |       PEG
296                         {
297                           $$ = newOP(OP_NULL,0);
298                           TOKEN_GETMAD($1,$$,'p');
299                         }
300         |       FORMAT startformsub formname formblock
301                         {
302                           CV *fmtcv = PL_compcv;
303 #ifdef MAD
304                           $$ = newFORM($2, $3, $4);
305                           prepend_madprops($1->tk_mad, $$, 'F');
306                           $1->tk_mad = 0;
307                           token_free($1);
308 #else
309                           newFORM($2, $3, $4);
310                           $$ = (OP*)NULL;
311 #endif
312                           if (CvOUTSIDE(fmtcv) && !CvEVAL(CvOUTSIDE(fmtcv))) {
313                               SvREFCNT_inc_simple_void(fmtcv);
314                               pad_add_anon(fmtcv, OP_NULL);
315                           }
316                         }
317         |       SUB subname startsub
318                         {
319                           if ($2->op_type == OP_CONST) {
320                             const char *const name =
321                                 SvPV_nolen_const(((SVOP*)$2)->op_sv);
322                             if (strEQ(name, "BEGIN") || strEQ(name, "END")
323                               || strEQ(name, "INIT") || strEQ(name, "CHECK")
324                               || strEQ(name, "UNITCHECK"))
325                               CvSPECIAL_on(PL_compcv);
326                           }
327                           PL_parser->in_my = 0;
328                           PL_parser->in_my_stash = NULL;
329                         }
330                 proto subattrlist subbody
331                         {
332                           SvREFCNT_inc_simple_void(PL_compcv);
333 #ifdef MAD
334                           {
335                               OP* o = newSVOP(OP_ANONCODE, 0,
336                                 (SV*)(
337 #endif
338                           $2->op_type == OP_CONST
339                               ? newATTRSUB($3, $2, $5, $6, $7)
340                               : newMYSUB($3, $2, $5, $6, $7)
341 #ifdef MAD
342                                 ));
343                               $$ = newOP(OP_NULL,0);
344                               op_getmad(o,$$,'&');
345                               op_getmad($2,$$,'n');
346                               op_getmad($5,$$,'s');
347                               op_getmad($6,$$,'a');
348                               token_getmad($1,$$,'d');
349                               append_madprops($7->op_madprop, $$, 0);
350                               $7->op_madprop = 0;
351                           }
352 #else
353                           ;
354                           $$ = (OP*)NULL;
355 #endif
356                           intro_my();
357                         }
358         |       MYSUB startsub subname proto subattrlist subbody
359                         {
360                           /* Unimplemented "my sub foo { }" */
361                           SvREFCNT_inc_simple_void(PL_compcv);
362 #ifdef MAD
363                           $$ = newMYSUB($2, $3, $4, $5, $6);
364                           token_getmad($1,$$,'d');
365 #else
366                           newMYSUB($2, $3, $4, $5, $6);
367                           $$ = (OP*)NULL;
368 #endif
369                         }
370         |       PACKAGE WORD WORD ';'
371                         {
372 #ifdef MAD
373                           $$ = package($3);
374                           token_getmad($1,$$,'o');
375                           if ($2)
376                               package_version($2);
377                           token_getmad($4,$$,';');
378 #else
379                           package($3);
380                           if ($2)
381                               package_version($2);
382                           $$ = (OP*)NULL;
383 #endif
384                         }
385         |       USE startsub
386                         { CvSPECIAL_on(PL_compcv); /* It's a BEGIN {} */ }
387                 WORD WORD optlistexpr ';'
388                         {
389                           SvREFCNT_inc_simple_void(PL_compcv);
390 #ifdef MAD
391                           $$ = utilize(IVAL($1), $2, $4, $5, $6);
392                           token_getmad($1,$$,'o');
393                           token_getmad($7,$$,';');
394                           if (PL_parser->rsfp_filters &&
395                                       AvFILLp(PL_parser->rsfp_filters) >= 0)
396                               append_madprops(newMADPROP('!', MAD_NULL, NULL, 0), $$, 0);
397 #else
398                           utilize(IVAL($1), $2, $4, $5, $6);
399                           $$ = (OP*)NULL;
400 #endif
401                         }
402         |       IF '(' remember mexpr ')' mblock else
403                         {
404                           $$ = block_end($3,
405                               newCONDOP(0, $4, op_scope($6), $7));
406                           TOKEN_GETMAD($1,$$,'I');
407                           TOKEN_GETMAD($2,$$,'(');
408                           TOKEN_GETMAD($5,$$,')');
409                           PL_parser->copline = (line_t)IVAL($1);
410                         }
411         |       UNLESS '(' remember miexpr ')' mblock else
412                         {
413                           $$ = block_end($3,
414                               newCONDOP(0, $4, op_scope($6), $7));
415                           TOKEN_GETMAD($1,$$,'I');
416                           TOKEN_GETMAD($2,$$,'(');
417                           TOKEN_GETMAD($5,$$,')');
418                           PL_parser->copline = (line_t)IVAL($1);
419                         }
420         |       GIVEN '(' remember mexpr ')' mblock
421                         {
422                           const PADOFFSET offset = pad_findmy_pvs("$_", 0);
423                           $$ = block_end($3,
424                                   newGIVENOP($4, op_scope($6),
425                                     offset == NOT_IN_PAD
426                                     || PAD_COMPNAME_FLAGS_isOUR(offset)
427                                       ? 0
428                                       : offset));
429                           PL_parser->copline = (line_t)IVAL($1);
430                         }
431         |       WHEN '(' remember mexpr ')' mblock
432                         { $$ = block_end($3, newWHENOP($4, op_scope($6))); }
433         |       DEFAULT block
434                         { $$ = newWHENOP(0, op_scope($2)); }
435         |       WHILE '(' remember texpr ')' mintro mblock cont
436                         {
437                           $$ = block_end($3,
438                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
439                                       $4, $7, $8, $6));
440                           TOKEN_GETMAD($1,$$,'W');
441                           TOKEN_GETMAD($2,$$,'(');
442                           TOKEN_GETMAD($5,$$,')');
443                           PL_parser->copline = (line_t)IVAL($1);
444                         }
445         |       UNTIL '(' remember iexpr ')' mintro mblock cont
446                         {
447                           $$ = block_end($3,
448                                   newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
449                                       $4, $7, $8, $6));
450                           TOKEN_GETMAD($1,$$,'W');
451                           TOKEN_GETMAD($2,$$,'(');
452                           TOKEN_GETMAD($5,$$,')');
453                           PL_parser->copline = (line_t)IVAL($1);
454                         }
455         |       FOR '(' remember mnexpr ';' texpr ';' mintro mnexpr ')'
456                 mblock
457                         {
458                           OP *initop = IF_MAD($4 ? $4 : newOP(OP_NULL, 0), $4);
459                           OP *forop = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
460                                       scalar($6), $11, $9, $8);
461                           if (initop) {
462                               forop = op_prepend_elem(OP_LINESEQ, initop,
463                                   op_append_elem(OP_LINESEQ,
464                                       newOP(OP_UNSTACK, OPf_SPECIAL),
465                                       forop));
466                           }
467                           DO_MAD({ forop = newUNOP(OP_NULL, 0, forop); })
468                           $$ = block_end($3, forop);
469                           TOKEN_GETMAD($1,$$,'3');
470                           TOKEN_GETMAD($2,$$,'(');
471                           TOKEN_GETMAD($5,$$,'1');
472                           TOKEN_GETMAD($7,$$,'2');
473                           TOKEN_GETMAD($10,$$,')');
474                           PL_parser->copline = (line_t)IVAL($1);
475                         }
476         |       FOR MY remember my_scalar '(' mexpr ')' mblock cont
477                         {
478                           $$ = block_end($3, newFOROP(0, $4, $6, $8, $9));
479                           TOKEN_GETMAD($1,$$,'W');
480                           TOKEN_GETMAD($2,$$,'d');
481                           TOKEN_GETMAD($5,$$,'(');
482                           TOKEN_GETMAD($7,$$,')');
483                           PL_parser->copline = (line_t)IVAL($1);
484                         }
485         |       FOR scalar '(' remember mexpr ')' mblock cont
486                         {
487                           $$ = block_end($4, newFOROP(0,
488                                       op_lvalue($2, OP_ENTERLOOP), $5, $7, $8));
489                           TOKEN_GETMAD($1,$$,'W');
490                           TOKEN_GETMAD($3,$$,'(');
491                           TOKEN_GETMAD($6,$$,')');
492                           PL_parser->copline = (line_t)IVAL($1);
493                         }
494         |       FOR '(' remember mexpr ')' mblock cont
495                         {
496                           $$ = block_end($3,
497                                   newFOROP(0, (OP*)NULL, $4, $6, $7));
498                           TOKEN_GETMAD($1,$$,'W');
499                           TOKEN_GETMAD($2,$$,'(');
500                           TOKEN_GETMAD($5,$$,')');
501                           PL_parser->copline = (line_t)IVAL($1);
502                         }
503         |       block cont
504                         {
505                           /* a block is a loop that happens once */
506                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
507                                   (OP*)NULL, $1, $2, 0);
508                         }
509         |       PACKAGE WORD WORD '{' remember
510                         {
511                           package($3);
512                           if ($2) {
513                               package_version($2);
514                           }
515                         }
516                 stmtseq '}'
517                         {
518                           /* a block is a loop that happens once */
519                           $$ = newWHILEOP(0, 1, (LOOP*)(OP*)NULL,
520                                   (OP*)NULL, block_end($5, $7), (OP*)NULL, 0);
521                           TOKEN_GETMAD($4,$$,'{');
522                           TOKEN_GETMAD($8,$$,'}');
523                           if (PL_parser->copline > (line_t)IVAL($4))
524                               PL_parser->copline = (line_t)IVAL($4);
525                         }
526         |       sideff ';'
527                         {
528                           PL_parser->expect = XSTATE;
529                           $$ = $1;
530                           TOKEN_GETMAD($2,$$,';');
531                         }
532         |       ';'
533                         {
534                           PL_parser->expect = XSTATE;
535                           $$ = IF_MAD(newOP(OP_NULL, 0), (OP*)NULL);
536                           TOKEN_GETMAD($1,$$,';');
537                           PL_parser->copline = NOLINE;
538                         }
539         ;
540
541 /* Format line */
542 formline:       THING formarg
543                         { OP *list;
544                           if ($2) {
545                               OP *term = $2;
546                               DO_MAD(term = newUNOP(OP_NULL, 0, term));
547                               list = op_append_elem(OP_LIST, $1, term);
548                           }
549                           else {
550 #ifdef MAD
551                               OP *op = newNULLLIST();
552                               list = op_append_elem(OP_LIST, $1, op);
553 #else
554                               list = $1;
555 #endif
556                           }
557                           if (PL_parser->copline == NOLINE)
558                                PL_parser->copline = CopLINE(PL_curcop)-1;
559                           else PL_parser->copline--;
560                           $$ = newSTATEOP(0, NULL,
561                                           convert(OP_FORMLINE, 0, list));
562                         }
563         ;
564
565 formarg :       /* NULL */
566                         { $$ = NULL; }
567         |       FORMLBRACK stmtseq FORMRBRACK
568                         { $$ = op_unscope($2); }
569         ;
570
571 /* An expression which may have a side-effect */
572 sideff  :       error
573                         { $$ = (OP*)NULL; }
574         |       expr
575                         { $$ = $1; }
576         |       expr IF expr
577                         { $$ = newLOGOP(OP_AND, 0, $3, $1);
578                           TOKEN_GETMAD($2,$$,'i');
579                         }
580         |       expr UNLESS expr
581                         { $$ = newLOGOP(OP_OR, 0, $3, $1);
582                           TOKEN_GETMAD($2,$$,'i');
583                         }
584         |       expr WHILE expr
585                         { $$ = newLOOPOP(OPf_PARENS, 1, scalar($3), $1);
586                           TOKEN_GETMAD($2,$$,'w');
587                         }
588         |       expr UNTIL iexpr
589                         { $$ = newLOOPOP(OPf_PARENS, 1, $3, $1);
590                           TOKEN_GETMAD($2,$$,'w');
591                         }
592         |       expr FOR expr
593                         { $$ = newFOROP(0, (OP*)NULL, $3, $1, (OP*)NULL);
594                           TOKEN_GETMAD($2,$$,'w');
595                           PL_parser->copline = (line_t)IVAL($2);
596                         }
597         |       expr WHEN expr
598                         { $$ = newWHENOP($3, op_scope($1)); }
599         ;
600
601 /* else and elsif blocks */
602 else    :       /* NULL */
603                         { $$ = (OP*)NULL; }
604         |       ELSE mblock
605                         {
606                           ($2)->op_flags |= OPf_PARENS;
607                           $$ = op_scope($2);
608                           TOKEN_GETMAD($1,$$,'o');
609                         }
610         |       ELSIF '(' mexpr ')' mblock else
611                         { PL_parser->copline = (line_t)IVAL($1);
612                             $$ = newCONDOP(0,
613                                 newSTATEOP(OPf_SPECIAL,NULL,$3),
614                                 op_scope($5), $6);
615                           PL_hints |= HINT_BLOCK_SCOPE;
616                           TOKEN_GETMAD($1,$$,'I');
617                           TOKEN_GETMAD($2,$$,'(');
618                           TOKEN_GETMAD($4,$$,')');
619                         }
620         ;
621
622 /* Continue blocks */
623 cont    :       /* NULL */
624                         { $$ = (OP*)NULL; }
625         |       CONTINUE block
626                         {
627                           $$ = op_scope($2);
628                           TOKEN_GETMAD($1,$$,'o');
629                         }
630         ;
631
632 /* determine whether there are any new my declarations */
633 mintro  :       /* NULL */
634                         { $$ = (PL_min_intro_pending &&
635                             PL_max_intro_pending >=  PL_min_intro_pending);
636                           intro_my(); }
637
638 /* Normal expression */
639 nexpr   :       /* NULL */
640                         { $$ = (OP*)NULL; }
641         |       sideff
642         ;
643
644 /* Boolean expression */
645 texpr   :       /* NULL means true */
646                         { YYSTYPE tmplval;
647                           (void)scan_num("1", &tmplval);
648                           $$ = tmplval.opval; }
649         |       expr
650         ;
651
652 /* Inverted boolean expression */
653 iexpr   :       expr
654                         { $$ = invert(scalar($1)); }
655         ;
656
657 /* Expression with its own lexical scope */
658 mexpr   :       expr
659                         { $$ = $1; intro_my(); }
660         ;
661
662 mnexpr  :       nexpr
663                         { $$ = $1; intro_my(); }
664         ;
665
666 miexpr  :       iexpr
667                         { $$ = $1; intro_my(); }
668         ;
669
670 formname:       WORD            { $$ = $1; }
671         |       /* NULL */      { $$ = (OP*)NULL; }
672         ;
673
674 startsub:       /* NULL */      /* start a regular subroutine scope */
675                         { $$ = start_subparse(FALSE, 0);
676                             SAVEFREESV(PL_compcv); }
677
678         ;
679
680 startanonsub:   /* NULL */      /* start an anonymous subroutine scope */
681                         { $$ = start_subparse(FALSE, CVf_ANON);
682                             SAVEFREESV(PL_compcv); }
683         ;
684
685 startformsub:   /* NULL */      /* start a format subroutine scope */
686                         { $$ = start_subparse(TRUE, 0);
687                             SAVEFREESV(PL_compcv); }
688         ;
689
690 /* Name of a subroutine - must be a bareword, could be special */
691 subname :       WORD
692         |       PRIVATEREF
693         ;
694
695 /* Subroutine prototype */
696 proto   :       /* NULL */
697                         { $$ = (OP*)NULL; }
698         |       THING
699         ;
700
701 /* Optional list of subroutine attributes */
702 subattrlist:    /* NULL */
703                         { $$ = (OP*)NULL; }
704         |       COLONATTR THING
705                         { $$ = $2;
706                           TOKEN_GETMAD($1,$$,':');
707                         }
708         |       COLONATTR
709                         { $$ = IF_MAD(
710                                     newOP(OP_NULL, 0),
711                                     (OP*)NULL
712                                 );
713                           TOKEN_GETMAD($1,$$,':');
714                         }
715         ;
716
717 /* List of attributes for a "my" variable declaration */
718 myattrlist:     COLONATTR THING
719                         { $$ = $2;
720                           TOKEN_GETMAD($1,$$,':');
721                         }
722         |       COLONATTR
723                         { $$ = IF_MAD(
724                                     newOP(OP_NULL, 0),
725                                     (OP*)NULL
726                                 );
727                           TOKEN_GETMAD($1,$$,':');
728                         }
729         ;
730
731 /* Subroutine body - either null or a block */
732 subbody :       block   { $$ = $1; }
733         |       ';'     { $$ = IF_MAD(
734                                     newOP(OP_NULL,0),
735                                     (OP*)NULL
736                                 );
737                           PL_parser->expect = XSTATE;
738                           TOKEN_GETMAD($1,$$,';');
739                         }
740         ;
741
742 /* Ordinary expressions; logical combinations */
743 expr    :       expr ANDOP expr
744                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
745                           TOKEN_GETMAD($2,$$,'o');
746                         }
747         |       expr OROP expr
748                         { $$ = newLOGOP(IVAL($2), 0, $1, $3);
749                           TOKEN_GETMAD($2,$$,'o');
750                         }
751         |       expr DOROP expr
752                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
753                           TOKEN_GETMAD($2,$$,'o');
754                         }
755         |       listexpr %prec PREC_LOW
756         ;
757
758 /* Expressions are a list of terms joined by commas */
759 listexpr:       listexpr ','
760                         {
761 #ifdef MAD
762                           OP* op = newNULLLIST();
763                           token_getmad($2,op,',');
764                           $$ = op_append_elem(OP_LIST, $1, op);
765 #else
766                           $$ = $1;
767 #endif
768                         }
769         |       listexpr ',' term
770                         { 
771                           OP* term = $3;
772                           DO_MAD(
773                               term = newUNOP(OP_NULL, 0, term);
774                               token_getmad($2,term,',');
775                           )
776                           $$ = op_append_elem(OP_LIST, $1, term);
777                         }
778         |       term %prec PREC_LOW
779         ;
780
781 /* List operators */
782 listop  :       LSTOP indirob listexpr /* map {...} @args or print $fh @args */
783                         { $$ = convert(IVAL($1), OPf_STACKED,
784                                 op_prepend_elem(OP_LIST, newGVREF(IVAL($1),$2), $3) );
785                           TOKEN_GETMAD($1,$$,'o');
786                         }
787         |       FUNC '(' indirob expr ')'      /* print ($fh @args */
788                         { $$ = convert(IVAL($1), OPf_STACKED,
789                                 op_prepend_elem(OP_LIST, newGVREF(IVAL($1),$3), $4) );
790                           TOKEN_GETMAD($1,$$,'o');
791                           TOKEN_GETMAD($2,$$,'(');
792                           TOKEN_GETMAD($5,$$,')');
793                         }
794         |       term ARROW method '(' optexpr ')' /* $foo->bar(list) */
795                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
796                                 op_append_elem(OP_LIST,
797                                     op_prepend_elem(OP_LIST, scalar($1), $5),
798                                     newUNOP(OP_METHOD, 0, $3)));
799                           TOKEN_GETMAD($2,$$,'A');
800                           TOKEN_GETMAD($4,$$,'(');
801                           TOKEN_GETMAD($6,$$,')');
802                         }
803         |       term ARROW method                     /* $foo->bar */
804                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
805                                 op_append_elem(OP_LIST, scalar($1),
806                                     newUNOP(OP_METHOD, 0, $3)));
807                           TOKEN_GETMAD($2,$$,'A');
808                         }
809         |       METHOD indirob optlistexpr           /* new Class @args */
810                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
811                                 op_append_elem(OP_LIST,
812                                     op_prepend_elem(OP_LIST, $2, $3),
813                                     newUNOP(OP_METHOD, 0, $1)));
814                         }
815         |       FUNCMETH indirob '(' optexpr ')'    /* method $object (@args) */
816                         { $$ = convert(OP_ENTERSUB, OPf_STACKED,
817                                 op_append_elem(OP_LIST,
818                                     op_prepend_elem(OP_LIST, $2, $4),
819                                     newUNOP(OP_METHOD, 0, $1)));
820                           TOKEN_GETMAD($3,$$,'(');
821                           TOKEN_GETMAD($5,$$,')');
822                         }
823         |       LSTOP optlistexpr                    /* print @args */
824                         { $$ = convert(IVAL($1), 0, $2);
825                           TOKEN_GETMAD($1,$$,'o');
826                         }
827         |       FUNC '(' optexpr ')'                 /* print (@args) */
828                         { $$ = convert(IVAL($1), 0, $3);
829                           TOKEN_GETMAD($1,$$,'o');
830                           TOKEN_GETMAD($2,$$,'(');
831                           TOKEN_GETMAD($4,$$,')');
832                         }
833         |       LSTOPSUB startanonsub block /* sub f(&@);   f { foo } ... */
834                         { SvREFCNT_inc_simple_void(PL_compcv);
835                           $<opval>$ = newANONATTRSUB($2, 0, (OP*)NULL, $3); }
836                     optlistexpr         %prec LSTOP  /* ... @bar */
837                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
838                                  op_append_elem(OP_LIST,
839                                    op_prepend_elem(OP_LIST, $<opval>4, $5), $1));
840                         }
841         ;
842
843 /* Names of methods. May use $object->$methodname */
844 method  :       METHOD
845         |       scalar
846         ;
847
848 /* Some kind of subscripted expression */
849 subscripted:    star '{' expr ';' '}'        /* *main::{something} */
850                         /* In this and all the hash accessors, ';' is
851                          * provided by the tokeniser */
852                         { $$ = newBINOP(OP_GELEM, 0, $1, scalar($3));
853                             PL_parser->expect = XOPERATOR;
854                           TOKEN_GETMAD($2,$$,'{');
855                           TOKEN_GETMAD($4,$$,';');
856                           TOKEN_GETMAD($5,$$,'}');
857                         }
858         |       scalar '[' expr ']'          /* $array[$element] */
859                         { $$ = newBINOP(OP_AELEM, 0, oopsAV($1), scalar($3));
860                           TOKEN_GETMAD($2,$$,'[');
861                           TOKEN_GETMAD($4,$$,']');
862                         }
863         |       term ARROW '[' expr ']'      /* somearef->[$element] */
864                         { $$ = newBINOP(OP_AELEM, 0,
865                                         ref(newAVREF($1),OP_RV2AV),
866                                         scalar($4));
867                           TOKEN_GETMAD($2,$$,'a');
868                           TOKEN_GETMAD($3,$$,'[');
869                           TOKEN_GETMAD($5,$$,']');
870                         }
871         |       subscripted '[' expr ']'    /* $foo->[$bar]->[$baz] */
872                         { $$ = newBINOP(OP_AELEM, 0,
873                                         ref(newAVREF($1),OP_RV2AV),
874                                         scalar($3));
875                           TOKEN_GETMAD($2,$$,'[');
876                           TOKEN_GETMAD($4,$$,']');
877                         }
878         |       scalar '{' expr ';' '}'    /* $foo{bar();} */
879                         { $$ = newBINOP(OP_HELEM, 0, oopsHV($1), jmaybe($3));
880                             PL_parser->expect = XOPERATOR;
881                           TOKEN_GETMAD($2,$$,'{');
882                           TOKEN_GETMAD($4,$$,';');
883                           TOKEN_GETMAD($5,$$,'}');
884                         }
885         |       term ARROW '{' expr ';' '}' /* somehref->{bar();} */
886                         { $$ = newBINOP(OP_HELEM, 0,
887                                         ref(newHVREF($1),OP_RV2HV),
888                                         jmaybe($4));
889                             PL_parser->expect = XOPERATOR;
890                           TOKEN_GETMAD($2,$$,'a');
891                           TOKEN_GETMAD($3,$$,'{');
892                           TOKEN_GETMAD($5,$$,';');
893                           TOKEN_GETMAD($6,$$,'}');
894                         }
895         |       subscripted '{' expr ';' '}' /* $foo->[bar]->{baz;} */
896                         { $$ = newBINOP(OP_HELEM, 0,
897                                         ref(newHVREF($1),OP_RV2HV),
898                                         jmaybe($3));
899                             PL_parser->expect = XOPERATOR;
900                           TOKEN_GETMAD($2,$$,'{');
901                           TOKEN_GETMAD($4,$$,';');
902                           TOKEN_GETMAD($5,$$,'}');
903                         }
904         |       term ARROW '(' ')'          /* $subref->() */
905                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
906                                    newCVREF(0, scalar($1)));
907                           TOKEN_GETMAD($2,$$,'a');
908                           TOKEN_GETMAD($3,$$,'(');
909                           TOKEN_GETMAD($4,$$,')');
910                         }
911         |       term ARROW '(' expr ')'     /* $subref->(@args) */
912                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
913                                    op_append_elem(OP_LIST, $4,
914                                        newCVREF(0, scalar($1))));
915                           TOKEN_GETMAD($2,$$,'a');
916                           TOKEN_GETMAD($3,$$,'(');
917                           TOKEN_GETMAD($5,$$,')');
918                         }
919
920         |       subscripted '(' expr ')'   /* $foo->{bar}->(@args) */
921                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
922                                    op_append_elem(OP_LIST, $3,
923                                                newCVREF(0, scalar($1))));
924                           TOKEN_GETMAD($2,$$,'(');
925                           TOKEN_GETMAD($4,$$,')');
926                         }
927         |       subscripted '(' ')'        /* $foo->{bar}->() */
928                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
929                                    newCVREF(0, scalar($1)));
930                           TOKEN_GETMAD($2,$$,'(');
931                           TOKEN_GETMAD($3,$$,')');
932                         }
933         |       '(' expr ')' '[' expr ']'            /* list slice */
934                         { $$ = newSLICEOP(0, $5, $2);
935                           TOKEN_GETMAD($1,$$,'(');
936                           TOKEN_GETMAD($3,$$,')');
937                           TOKEN_GETMAD($4,$$,'[');
938                           TOKEN_GETMAD($6,$$,']');
939                         }
940         |       QWLIST '[' expr ']'            /* list literal slice */
941                         { $$ = newSLICEOP(0, $3, $1);
942                           TOKEN_GETMAD($2,$$,'[');
943                           TOKEN_GETMAD($4,$$,']');
944                         }
945         |       '(' ')' '[' expr ']'                 /* empty list slice! */
946                         { $$ = newSLICEOP(0, $4, (OP*)NULL);
947                           TOKEN_GETMAD($1,$$,'(');
948                           TOKEN_GETMAD($2,$$,')');
949                           TOKEN_GETMAD($3,$$,'[');
950                           TOKEN_GETMAD($5,$$,']');
951                         }
952     ;
953
954 /* Binary operators between terms */
955 termbinop:      term ASSIGNOP term                     /* $x = $y */
956                         { $$ = newASSIGNOP(OPf_STACKED, $1, IVAL($2), $3);
957                           TOKEN_GETMAD($2,$$,'o');
958                         }
959         |       term POWOP term                        /* $x ** $y */
960                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
961                           TOKEN_GETMAD($2,$$,'o');
962                         }
963         |       term MULOP term                        /* $x * $y, $x x $y */
964                         {   if (IVAL($2) != OP_REPEAT)
965                                 scalar($1);
966                             $$ = newBINOP(IVAL($2), 0, $1, scalar($3));
967                           TOKEN_GETMAD($2,$$,'o');
968                         }
969         |       term ADDOP term                        /* $x + $y */
970                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
971                           TOKEN_GETMAD($2,$$,'o');
972                         }
973         |       term SHIFTOP term                      /* $x >> $y, $x << $y */
974                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
975                           TOKEN_GETMAD($2,$$,'o');
976                         }
977         |       term RELOP term                        /* $x > $y, etc. */
978                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
979                           TOKEN_GETMAD($2,$$,'o');
980                         }
981         |       term EQOP term                         /* $x == $y, $x eq $y */
982                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
983                           TOKEN_GETMAD($2,$$,'o');
984                         }
985         |       term BITANDOP term                     /* $x & $y */
986                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
987                           TOKEN_GETMAD($2,$$,'o');
988                         }
989         |       term BITOROP term                      /* $x | $y */
990                         { $$ = newBINOP(IVAL($2), 0, scalar($1), scalar($3));
991                           TOKEN_GETMAD($2,$$,'o');
992                         }
993         |       term DOTDOT term                       /* $x..$y, $x...$y */
994                         {
995                           $$ = newRANGE(IVAL($2), scalar($1), scalar($3));
996                           DO_MAD({
997                               UNOP *op;
998                               op = (UNOP*)$$;
999                               op = (UNOP*)op->op_first; /* get to flop */
1000                               op = (UNOP*)op->op_first; /* get to flip */
1001                               op = (UNOP*)op->op_first; /* get to range */
1002                               token_getmad($2,(OP*)op,'o');
1003                             })
1004                         }
1005         |       term ANDAND term                       /* $x && $y */
1006                         { $$ = newLOGOP(OP_AND, 0, $1, $3);
1007                           TOKEN_GETMAD($2,$$,'o');
1008                         }
1009         |       term OROR term                         /* $x || $y */
1010                         { $$ = newLOGOP(OP_OR, 0, $1, $3);
1011                           TOKEN_GETMAD($2,$$,'o');
1012                         }
1013         |       term DORDOR term                       /* $x // $y */
1014                         { $$ = newLOGOP(OP_DOR, 0, $1, $3);
1015                           TOKEN_GETMAD($2,$$,'o');
1016                         }
1017         |       term MATCHOP term                      /* $x =~ /$y/ */
1018                         { $$ = bind_match(IVAL($2), $1, $3);
1019                           TOKEN_GETMAD($2,
1020                                 ($$->op_type == OP_NOT
1021                                     ? ((UNOP*)$$)->op_first : $$),
1022                                 '~');
1023                         }
1024     ;
1025
1026 /* Unary operators and terms */
1027 termunop : '-' term %prec UMINUS                       /* -$x */
1028                         { $$ = newUNOP(OP_NEGATE, 0, scalar($2));
1029                           TOKEN_GETMAD($1,$$,'o');
1030                         }
1031         |       '+' term %prec UMINUS                  /* +$x */
1032                         { $$ = IF_MAD(
1033                                     newUNOP(OP_NULL, 0, $2),
1034                                     $2
1035                                 );
1036                           TOKEN_GETMAD($1,$$,'+');
1037                         }
1038         |       '!' term                               /* !$x */
1039                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1040                           TOKEN_GETMAD($1,$$,'o');
1041                         }
1042         |       '~' term                               /* ~$x */
1043                         { $$ = newUNOP(OP_COMPLEMENT, 0, scalar($2));
1044                           TOKEN_GETMAD($1,$$,'o');
1045                         }
1046         |       term POSTINC                           /* $x++ */
1047                         { $$ = newUNOP(OP_POSTINC, 0,
1048                                         op_lvalue(scalar($1), OP_POSTINC));
1049                           TOKEN_GETMAD($2,$$,'o');
1050                         }
1051         |       term POSTDEC                           /* $x-- */
1052                         { $$ = newUNOP(OP_POSTDEC, 0,
1053                                         op_lvalue(scalar($1), OP_POSTDEC));
1054                           TOKEN_GETMAD($2,$$,'o');
1055                         }
1056         |       PREINC term                            /* ++$x */
1057                         { $$ = newUNOP(OP_PREINC, 0,
1058                                         op_lvalue(scalar($2), OP_PREINC));
1059                           TOKEN_GETMAD($1,$$,'o');
1060                         }
1061         |       PREDEC term                            /* --$x */
1062                         { $$ = newUNOP(OP_PREDEC, 0,
1063                                         op_lvalue(scalar($2), OP_PREDEC));
1064                           TOKEN_GETMAD($1,$$,'o');
1065                         }
1066
1067     ;
1068
1069 /* Constructors for anonymous data */
1070 anonymous:      '[' expr ']'
1071                         { $$ = newANONLIST($2);
1072                           TOKEN_GETMAD($1,$$,'[');
1073                           TOKEN_GETMAD($3,$$,']');
1074                         }
1075         |       '[' ']'
1076                         { $$ = newANONLIST((OP*)NULL);
1077                           TOKEN_GETMAD($1,$$,'[');
1078                           TOKEN_GETMAD($2,$$,']');
1079                         }
1080         |       HASHBRACK expr ';' '}'  %prec '(' /* { foo => "Bar" } */
1081                         { $$ = newANONHASH($2);
1082                           TOKEN_GETMAD($1,$$,'{');
1083                           TOKEN_GETMAD($3,$$,';');
1084                           TOKEN_GETMAD($4,$$,'}');
1085                         }
1086         |       HASHBRACK ';' '}'       %prec '(' /* { } (';' by tokener) */
1087                         { $$ = newANONHASH((OP*)NULL);
1088                           TOKEN_GETMAD($1,$$,'{');
1089                           TOKEN_GETMAD($2,$$,';');
1090                           TOKEN_GETMAD($3,$$,'}');
1091                         }
1092         |       ANONSUB startanonsub proto subattrlist block    %prec '('
1093                         { SvREFCNT_inc_simple_void(PL_compcv);
1094                           $$ = newANONATTRSUB($2, $3, $4, $5);
1095                           TOKEN_GETMAD($1,$$,'o');
1096                           OP_GETMAD($3,$$,'s');
1097                           OP_GETMAD($4,$$,'a');
1098                         }
1099
1100     ;
1101
1102 /* Things called with "do" */
1103 termdo  :       DO term %prec UNIOP                     /* do $filename */
1104                         { $$ = dofile($2, IVAL($1));
1105                           TOKEN_GETMAD($1,$$,'o');
1106                         }
1107         |       DO block        %prec '('               /* do { code */
1108                         { $$ = newUNOP(OP_NULL, OPf_SPECIAL, op_scope($2));
1109                           TOKEN_GETMAD($1,$$,'D');
1110                         }
1111         |       DO subname '(' ')'                  /* do somesub() */
1112                         { $$ = newUNOP(OP_ENTERSUB,
1113                             OPf_SPECIAL|OPf_STACKED,
1114                             op_prepend_elem(OP_LIST,
1115                                 scalar(newCVREF(
1116                                     (OPpENTERSUB_AMPER<<8),
1117                                     scalar($2)
1118                                 )),(OP*)NULL)); dep();
1119                           TOKEN_GETMAD($1,$$,'o');
1120                           TOKEN_GETMAD($3,$$,'(');
1121                           TOKEN_GETMAD($4,$$,')');
1122                         }
1123         |       DO subname '(' expr ')'             /* do somesub(@args) */
1124                         { $$ = newUNOP(OP_ENTERSUB,
1125                             OPf_SPECIAL|OPf_STACKED,
1126                             op_append_elem(OP_LIST,
1127                                 $4,
1128                                 scalar(newCVREF(
1129                                     (OPpENTERSUB_AMPER<<8),
1130                                     scalar($2)
1131                                 )))); dep();
1132                           TOKEN_GETMAD($1,$$,'o');
1133                           TOKEN_GETMAD($3,$$,'(');
1134                           TOKEN_GETMAD($5,$$,')');
1135                         }
1136         |       DO scalar '(' ')'                /* do $subref () */
1137                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1138                             op_prepend_elem(OP_LIST,
1139                                 scalar(newCVREF(0,scalar($2))), (OP*)NULL)); dep();
1140                           TOKEN_GETMAD($1,$$,'o');
1141                           TOKEN_GETMAD($3,$$,'(');
1142                           TOKEN_GETMAD($4,$$,')');
1143                         }
1144         |       DO scalar '(' expr ')'           /* do $subref (@args) */
1145                         { $$ = newUNOP(OP_ENTERSUB, OPf_SPECIAL|OPf_STACKED,
1146                             op_prepend_elem(OP_LIST,
1147                                 $4,
1148                                 scalar(newCVREF(0,scalar($2))))); dep();
1149                           TOKEN_GETMAD($1,$$,'o');
1150                           TOKEN_GETMAD($3,$$,'(');
1151                           TOKEN_GETMAD($5,$$,')');
1152                         }
1153
1154         ;
1155
1156 term    :       termbinop
1157         |       termunop
1158         |       anonymous
1159         |       termdo
1160         |       term '?' term ':' term
1161                         { $$ = newCONDOP(0, $1, $3, $5);
1162                           TOKEN_GETMAD($2,$$,'?');
1163                           TOKEN_GETMAD($4,$$,':');
1164                         }
1165         |       REFGEN term                          /* \$x, \@y, \%z */
1166                         { $$ = newUNOP(OP_REFGEN, 0, op_lvalue($2,OP_REFGEN));
1167                           TOKEN_GETMAD($1,$$,'o');
1168                         }
1169         |       myattrterm      %prec UNIOP
1170                         { $$ = $1; }
1171         |       LOCAL term      %prec UNIOP
1172                         { $$ = localize($2,IVAL($1));
1173                           TOKEN_GETMAD($1,$$,'k');
1174                         }
1175         |       '(' expr ')'
1176                         { $$ = sawparens(IF_MAD(newUNOP(OP_NULL,0,$2), $2));
1177                           TOKEN_GETMAD($1,$$,'(');
1178                           TOKEN_GETMAD($3,$$,')');
1179                         }
1180         |       QWLIST
1181                         { $$ = IF_MAD(newUNOP(OP_NULL,0,$1), $1); }
1182         |       '(' ')'
1183                         { $$ = sawparens(newNULLLIST());
1184                           TOKEN_GETMAD($1,$$,'(');
1185                           TOKEN_GETMAD($2,$$,')');
1186                         }
1187         |       scalar  %prec '('
1188                         { $$ = $1; }
1189         |       star    %prec '('
1190                         { $$ = $1; }
1191         |       hsh     %prec '('
1192                         { $$ = $1; }
1193         |       ary     %prec '('
1194                         { $$ = $1; }
1195         |       arylen  %prec '('                    /* $#x, $#{ something } */
1196                         { $$ = newUNOP(OP_AV2ARYLEN, 0, ref($1, OP_AV2ARYLEN));}
1197         |       subscripted
1198                         { $$ = $1; }
1199         |       ary '[' expr ']'                     /* array slice */
1200                         { $$ = op_prepend_elem(OP_ASLICE,
1201                                 newOP(OP_PUSHMARK, 0),
1202                                     newLISTOP(OP_ASLICE, 0,
1203                                         list($3),
1204                                         ref($1, OP_ASLICE)));
1205                           TOKEN_GETMAD($2,$$,'[');
1206                           TOKEN_GETMAD($4,$$,']');
1207                         }
1208         |       ary '{' expr ';' '}'                 /* @hash{@keys} */
1209                         { $$ = op_prepend_elem(OP_HSLICE,
1210                                 newOP(OP_PUSHMARK, 0),
1211                                     newLISTOP(OP_HSLICE, 0,
1212                                         list($3),
1213                                         ref(oopsHV($1), OP_HSLICE)));
1214                             PL_parser->expect = XOPERATOR;
1215                           TOKEN_GETMAD($2,$$,'{');
1216                           TOKEN_GETMAD($4,$$,';');
1217                           TOKEN_GETMAD($5,$$,'}');
1218                         }
1219         |       THING   %prec '('
1220                         { $$ = $1; }
1221         |       amper                                /* &foo; */
1222                         { $$ = newUNOP(OP_ENTERSUB, 0, scalar($1)); }
1223         |       amper '(' ')'                 /* &foo() */
1224                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1));
1225                           TOKEN_GETMAD($2,$$,'(');
1226                           TOKEN_GETMAD($3,$$,')');
1227                         }
1228         |       amper '(' expr ')'            /* &foo(@args) */
1229                         {
1230                           $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1231                                 op_append_elem(OP_LIST, $3, scalar($1)));
1232                           DO_MAD({
1233                               OP* op = $$;
1234                               if (op->op_type == OP_CONST) { /* defeat const fold */
1235                                 op = (OP*)op->op_madprop->mad_val;
1236                               }
1237                               token_getmad($2,op,'(');
1238                               token_getmad($4,op,')');
1239                           })
1240                         }
1241         |       NOAMP subname optlistexpr               /* foo(@args) */
1242                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1243                             op_append_elem(OP_LIST, $3, scalar($2)));
1244                           TOKEN_GETMAD($1,$$,'o');
1245                         }
1246         |       LOOPEX  /* loop exiting command (goto, last, dump, etc) */
1247                         { $$ = newOP(IVAL($1), OPf_SPECIAL);
1248                             PL_hints |= HINT_BLOCK_SCOPE;
1249                           TOKEN_GETMAD($1,$$,'o');
1250                         }
1251         |       LOOPEX term
1252                         { $$ = newLOOPEX(IVAL($1),$2);
1253                           TOKEN_GETMAD($1,$$,'o');
1254                         }
1255         |       NOTOP listexpr                       /* not $foo */
1256                         { $$ = newUNOP(OP_NOT, 0, scalar($2));
1257                           TOKEN_GETMAD($1,$$,'o');
1258                         }
1259         |       UNIOP                                /* Unary op, $_ implied */
1260                         { $$ = newOP(IVAL($1), 0);
1261                           TOKEN_GETMAD($1,$$,'o');
1262                         }
1263         |       UNIOP block                          /* eval { foo }* */
1264                         { $$ = newUNOP(IVAL($1), 0, $2);
1265                           TOKEN_GETMAD($1,$$,'o');
1266                         }
1267         |       UNIOP term                           /* Unary op */
1268                         { $$ = newUNOP(IVAL($1), 0, $2);
1269                           TOKEN_GETMAD($1,$$,'o');
1270                         }
1271         |       REQUIRE                              /* require, $_ implied */
1272                         { $$ = newOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0);
1273                           TOKEN_GETMAD($1,$$,'o');
1274                         }
1275         |       REQUIRE term                         /* require Foo */
1276                         { $$ = newUNOP(OP_REQUIRE, $1 ? OPf_SPECIAL : 0, $2);
1277                           TOKEN_GETMAD($1,$$,'o');
1278                         }
1279         |       UNIOPSUB
1280                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED, scalar($1)); }
1281         |       UNIOPSUB term                        /* Sub treated as unop */
1282                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1283                             op_append_elem(OP_LIST, $2, scalar($1))); }
1284         |       FUNC0                                /* Nullary operator */
1285                         { $$ = newOP(IVAL($1), 0);
1286                           TOKEN_GETMAD($1,$$,'o');
1287                         }
1288         |       FUNC0 '(' ')'
1289                         { $$ = newOP(IVAL($1), 0);
1290                           TOKEN_GETMAD($1,$$,'o');
1291                           TOKEN_GETMAD($2,$$,'(');
1292                           TOKEN_GETMAD($3,$$,')');
1293                         }
1294         |       FUNC0OP       /* Same as above, but op created in toke.c */
1295                         { $$ = $1; }
1296         |       FUNC0OP '(' ')'
1297                         { $$ = $1;
1298                           TOKEN_GETMAD($2,$$,'(');
1299                           TOKEN_GETMAD($3,$$,')');
1300                         }
1301         |       FUNC0SUB                             /* Sub treated as nullop */
1302                         { $$ = newUNOP(OP_ENTERSUB, OPf_STACKED,
1303                                 scalar($1)); }
1304         |       FUNC1 '(' ')'                        /* not () */
1305                         { $$ = (IVAL($1) == OP_NOT)
1306                             ? newUNOP(IVAL($1), 0, newSVOP(OP_CONST, 0, newSViv(0)))
1307                             : newOP(IVAL($1), OPf_SPECIAL);
1308
1309                           TOKEN_GETMAD($1,$$,'o');
1310                           TOKEN_GETMAD($2,$$,'(');
1311                           TOKEN_GETMAD($3,$$,')');
1312                         }
1313         |       FUNC1 '(' expr ')'                   /* not($foo) */
1314                         { $$ = newUNOP(IVAL($1), 0, $3);
1315                           TOKEN_GETMAD($1,$$,'o');
1316                           TOKEN_GETMAD($2,$$,'(');
1317                           TOKEN_GETMAD($4,$$,')');
1318                         }
1319         |       PMFUNC /* m//, s///, qr//, tr/// */
1320                         {
1321                             if (   $1->op_type != OP_TRANS
1322                                 && $1->op_type != OP_TRANSR
1323                                 && (((PMOP*)$1)->op_pmflags & PMf_HAS_CV))
1324                             {
1325                                 $<ival>$ = start_subparse(FALSE, CVf_ANON);
1326                                 SAVEFREESV(PL_compcv);
1327                             } else
1328                                 $<ival>$ = 0;
1329                         }
1330                     '(' listexpr ')'
1331                         { $$ = pmruntime($1, $4, 1, $<ival>2);
1332                           TOKEN_GETMAD($3,$$,'(');
1333                           TOKEN_GETMAD($5,$$,')');
1334                         }
1335         |       WORD
1336         |       listop
1337         |       YADAYADA
1338                         {
1339                           $$ = newLISTOP(OP_DIE, 0, newOP(OP_PUSHMARK, 0),
1340                                 newSVOP(OP_CONST, 0, newSVpvs("Unimplemented")));
1341                           TOKEN_GETMAD($1,$$,'X');
1342                         }
1343         |       PLUGEXPR
1344         ;
1345
1346 /* "my" declarations, with optional attributes */
1347 myattrterm:     MY myterm myattrlist
1348                         { $$ = my_attrs($2,$3);
1349                           DO_MAD(
1350                               token_getmad($1,$$,'d');
1351                               append_madprops($3->op_madprop, $$, 'a');
1352                               $3->op_madprop = 0;
1353                           )
1354                         }
1355         |       MY myterm
1356                         { $$ = localize($2,IVAL($1));
1357                           TOKEN_GETMAD($1,$$,'d');
1358                         }
1359         ;
1360
1361 /* Things that can be "my"'d */
1362 myterm  :       '(' expr ')'
1363                         { $$ = sawparens($2);
1364                           TOKEN_GETMAD($1,$$,'(');
1365                           TOKEN_GETMAD($3,$$,')');
1366                         }
1367         |       '(' ')'
1368                         { $$ = sawparens(newNULLLIST());
1369                           TOKEN_GETMAD($1,$$,'(');
1370                           TOKEN_GETMAD($2,$$,')');
1371                         }
1372         |       scalar  %prec '('
1373                         { $$ = $1; }
1374         |       hsh     %prec '('
1375                         { $$ = $1; }
1376         |       ary     %prec '('
1377                         { $$ = $1; }
1378         ;
1379
1380 /* Basic list expressions */
1381 optlistexpr:    /* NULL */ %prec PREC_LOW
1382                         { $$ = (OP*)NULL; }
1383         |       listexpr    %prec PREC_LOW
1384                         { $$ = $1; }
1385         ;
1386
1387 optexpr:        /* NULL */
1388                         { $$ = (OP*)NULL; }
1389         |       expr
1390                         { $$ = $1; }
1391         ;
1392
1393 /* A little bit of trickery to make "for my $foo (@bar)" actually be
1394    lexical */
1395 my_scalar:      scalar
1396                         { PL_parser->in_my = 0; $$ = my($1); }
1397         ;
1398
1399 amper   :       '&' indirob
1400                         { $$ = newCVREF(IVAL($1),$2);
1401                           TOKEN_GETMAD($1,$$,'&');
1402                         }
1403         ;
1404
1405 scalar  :       '$' indirob
1406                         { $$ = newSVREF($2);
1407                           TOKEN_GETMAD($1,$$,'$');
1408                         }
1409         ;
1410
1411 ary     :       '@' indirob
1412                         { $$ = newAVREF($2);
1413                           TOKEN_GETMAD($1,$$,'@');
1414                         }
1415         ;
1416
1417 hsh     :       '%' indirob
1418                         { $$ = newHVREF($2);
1419                           TOKEN_GETMAD($1,$$,'%');
1420                         }
1421         ;
1422
1423 arylen  :       DOLSHARP indirob
1424                         { $$ = newAVREF($2);
1425                           TOKEN_GETMAD($1,$$,'l');
1426                         }
1427         ;
1428
1429 star    :       '*' indirob
1430                         { $$ = newGVREF(0,$2);
1431                           TOKEN_GETMAD($1,$$,'*');
1432                         }
1433         ;
1434
1435 /* Indirect objects */
1436 indirob :       WORD
1437                         { $$ = scalar($1); }
1438         |       scalar %prec PREC_LOW
1439                         { $$ = scalar($1); }
1440         |       block
1441                         { $$ = op_scope($1); }
1442
1443         |       PRIVATEREF
1444                         { $$ = $1; }
1445         ;