This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
73a6dc2021926772946102faefe1891af69938cd
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still current
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the default, as it saves some fakery within TestInit
27 # which can perturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Tar' => 1,
32            '../cpan/AutoLoader' => 1,
33            '../cpan/CPAN' => 1,
34            '../cpan/Class-ISA' => 1,
35            '../cpan/Devel-PPPort' => 1,
36            '../cpan/Encode' => 1,
37            '../cpan/ExtUtils-Constant' => 1,
38            '../cpan/ExtUtils-MakeMaker' => 1,
39            '../cpan/File-Fetch' => 1,
40            '../cpan/IPC-Cmd' => 1,
41            '../cpan/IPC-SysV' => 1,
42            '../cpan/Locale-Codes' => 1,
43            '../cpan/Module-Build' => 1,
44            '../cpan/Module-Load' => 1,
45            '../cpan/Module-Load-Conditional' => 1,
46            '../cpan/Package-Constants' => 1,
47            '../cpan/Parse-CPAN-Meta' => 1,
48            '../cpan/Pod-Simple' => 1,
49            '../cpan/Test-Simple' => 1,
50            '../cpan/podlators' => 1,
51            '../dist/Cwd' => 1,
52            '../dist/ExtUtils-Command' => 1,
53            '../dist/ExtUtils-Install' => 1,
54            '../dist/ExtUtils-Manifest' => 1,
55            '../dist/ExtUtils-ParseXS' => 1,
56            '../dist/Tie-File' => 1,
57           );
58
59 my %temp_no_core =
60     ('../cpan/B-Debug' => 1,
61      '../cpan/Compress-Raw-Bzip2' => 1,
62      '../cpan/Compress-Raw-Zlib' => 1,
63      '../cpan/Devel-PPPort' => 1,
64      '../cpan/Getopt-Long' => 1,
65      '../cpan/IO-Compress' => 1,
66      '../cpan/MIME-Base64' => 1,
67      '../cpan/parent' => 1,
68      '../cpan/Parse-CPAN-Meta' => 1,
69      '../cpan/Pod-Simple' => 1,
70      '../cpan/podlators' => 1,
71      '../cpan/Test-Simple' => 1,
72      '../cpan/Tie-RefHash' => 1,
73      '../cpan/Unicode-Collate' => 1,
74      '../cpan/Unicode-Normalize' => 1,
75     );
76
77 # delete env vars that may influence the results
78 # but allow override via *_TEST env var if wanted
79 # (e.g. PERL5OPT_TEST=-d:NYTProf)
80 my @bad_env_vars = qw(
81     PERL5LIB PERLLIB PERL5OPT
82     PERL_YAML_BACKEND PERL_JSON_BACKEND
83 );
84
85 for my $envname (@bad_env_vars) {
86     my $override = $ENV{"${envname}_TEST"};
87     if (defined $override) {
88         warn "$0: $envname=$override\n";
89         $ENV{$envname} = $override;
90     }
91     else {
92         delete $ENV{$envname};
93     }
94 }
95
96 # Location to put the Valgrind log.
97 our $Valgrind_Log;
98
99 my %skip = (
100             '.' => 1,
101             '..' => 1,
102             'CVS' => 1,
103             'RCS' => 1,
104             'SCCS' => 1,
105             '.svn' => 1,
106            );
107
108
109 if ($::do_nothing) {
110     return 1;
111 }
112
113 $| = 1;
114
115 # for testing TEST only
116 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
117 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
118
119 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
120 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
121 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
122
123 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
124 # can't rely on require working.
125 {
126     my @argv = ();
127     foreach my $idx (0..$#ARGV) {
128         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
129         $::benchmark = 1 if $1 eq 'benchmark';
130         $::core    = 1 if $1 eq 'core';
131         $::verbose = 1 if $1 eq 'v';
132         $::torture = 1 if $1 eq 'torture';
133         $::with_utf8 = 1 if $1 eq 'utf8';
134         $::with_utf16 = 1 if $1 eq 'utf16';
135         $::taintwarn = 1 if $1 eq 'taintwarn';
136         if ($1 =~ /^deparse(,.+)?$/) {
137             $::deparse = 1;
138             $::deparse_opts = $1;
139         }
140     }
141     @ARGV = @argv;
142 }
143
144 chdir 't' if -f 't/TEST';
145 if (-f 'TEST' && -f 'harness' && -d '../lib') {
146     @INC = '../lib';
147 }
148
149 die "You need to run \"make test\" first to set things up.\n"
150   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
151
152 # check leakage for embedders
153 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
154 # check existence of all symbols
155 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
156
157 $ENV{EMXSHELL} = 'sh';        # For OS/2
158
159 if ($show_elapsed_time) { require Time::HiRes }
160 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
161
162 # Roll your own File::Find!
163 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
164 sub _find_files {
165     my($patt, @dirs) = @_;
166     for my $dir (@dirs) {
167         opendir DIR, $dir or die "Trouble opening $dir: $!";
168         foreach my $f (sort { $a cmp $b } readdir DIR) {
169             next if $skip{$f};
170
171             my $fullpath = "$dir/$f";
172             
173             if (-d $fullpath) {
174                 _find_files($patt, $fullpath);
175             } elsif ($f =~ /$patt/) {
176                 push @found, $fullpath;
177             }
178         }
179     }
180     @found;
181 }
182
183
184 # Scan the text of the test program to find switches and special options
185 # we might need to apply.
186 sub _scan_test {
187     my($test, $type) = @_;
188
189     open(my $script, "<", $test) or die "Can't read $test.\n";
190     my $first_line = <$script>;
191
192     $first_line =~ tr/\0//d if $::with_utf16;
193
194     my $switch = "";
195     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
196         $switch = "-$1";
197     } else {
198         if ($::taintwarn) {
199             # not all tests are expected to pass with this option
200             $switch = '-t';
201         } else {
202             $switch = '';
203         }
204     }
205
206     my $file_opts = "";
207     if ($type eq 'deparse') {
208         # Look for #line directives which change the filename
209         while (<$script>) {
210             $file_opts = $file_opts . ",-f$3$4"
211               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
212         }
213     }
214
215     close $script;
216
217     my $perl = './perl';
218     my $lib  = '../lib';
219     my $run_dir;
220     my $return_dir;
221
222     $test =~ /^(.+)\/[^\/]+/;
223     my $dir = $1;
224     my $testswitch = $dir_to_switch{$dir};
225     if (!defined $testswitch) {
226         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
227             $run_dir = $1;
228             $return_dir = '../../t';
229             $lib = '../../lib';
230             $perl = '../../t/perl';
231             $testswitch = "-I../.. -MTestInit=U2T";
232             if ($2 eq 'cpan' || $2 eq 'dist') {
233                 if($abs{$run_dir}) {
234                     $testswitch = $testswitch . ',A';
235                 }
236                 if ($temp_no_core{$run_dir}) {
237                     $testswitch = $testswitch . ',NC';
238                 }
239             }
240         } elsif ($test =~ m!^\.\./lib!) {
241             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
242         } else {
243             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
244         }
245     }
246
247     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
248
249     my %options = (
250         perl => $perl,
251         lib => $lib,
252         test => $test,
253         run_dir => $run_dir,
254         return_dir => $return_dir,
255         testswitch => $testswitch,
256         utf8 => $utf8,
257         file => $file_opts,
258         switch => $switch,
259     );
260
261     return \%options;
262 }
263
264 sub _cmd {
265     my($options, $type) = @_;
266
267     my $test = $options->{test};
268
269     my $cmd;
270     if ($type eq 'deparse') {
271         my $perl = "$options->{perl} $options->{testswitch}";
272         my $lib = $options->{lib};
273
274         $cmd = (
275           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
276           "-l$::deparse_opts$options->{file} ".
277           "$test > $test.dp ".
278           "&& $perl $options->{switch} -I$lib $test.dp"
279         );
280     }
281     elsif ($type eq 'perl') {
282         my $perl = $options->{perl};
283         my $redir = $^O eq 'VMS' ? '2>&1' : '';
284
285         if ($ENV{PERL_VALGRIND}) {
286             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
287             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
288             if ($options->{run_dir}) {
289                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
290             }
291             my $vg_opts = $ENV{VG_OPTS}
292                //   "--log-file=$Valgrind_Log "
293                   . "--suppressions=$perl_supp --leak-check=yes "
294                   . "--leak-resolution=high --show-reachable=yes "
295                   . "--num-callers=50 --track-origins=yes";
296             # Force logging if not asked for (so cachegrind reporting works below)
297             if ($vg_opts !~ /--log-file/) {
298                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
299             }
300             $perl = "$valgrind_exe $vg_opts $perl";
301         }
302
303         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
304         $cmd = $perl . _quote_args($args) . " $test $redir";
305     }
306     return $cmd;
307 }
308
309 sub _before_fork {
310     my ($options) = @_;
311
312     if ($options->{run_dir}) {
313         my $run_dir = $options->{run_dir};
314         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
315     }
316
317     # Remove previous valgrind output otherwise it will interfere
318     my $test = $options->{test};
319
320     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
321
322     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
323         unlink $Valgrind_Log
324             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
325     }
326
327     return;
328 }
329
330 sub _after_fork {
331     my ($options) = @_;
332
333     if ($options->{return_dir}) {
334         my $return_dir = $options->{return_dir};
335         chdir $return_dir
336            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
337     }
338
339     return;
340 }
341
342 sub _run_test {
343     my ($test, $type) = @_;
344
345     my $options = _scan_test($test, $type);
346     # $test might have changed if we're in ext/Foo, so don't use it anymore
347     # from now on. Use $options->{test} instead.
348
349     _before_fork($options);
350
351     my $cmd = _cmd($options, $type);
352
353     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
354
355     _after_fork($options);
356
357     # Our environment may force us to use UTF-8, but we can't be sure that
358     # anything we're reading from will be generating (well formed) UTF-8
359     # This may not be the best way - possibly we should unset ${^OPEN} up
360     # top?
361     binmode $results;
362
363     return $results;
364 }
365
366 sub _quote_args {
367     my ($args) = @_;
368     my $argstring = '';
369
370     foreach (split(/\s+/,$args)) {
371        # In VMS protect with doublequotes because otherwise
372        # DCL will lowercase -- unless already doublequoted.
373        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
374        $argstring = $argstring . ' ' . $_;
375     }
376     return $argstring;
377 }
378
379 sub _populate_hash {
380     return unless defined $_[0];
381     return map {$_, 1} split /\s+/, $_[0];
382 }
383
384 sub _tests_from_manifest {
385     my ($extensions, $known_extensions) = @_;
386     my %skip;
387     my %extensions = _populate_hash($extensions);
388     my %known_extensions = _populate_hash($known_extensions);
389
390     foreach (keys %known_extensions) {
391         $skip{$_} = 1 unless $extensions{$_};
392     }
393
394     my @results;
395     my $mani = '../MANIFEST';
396     if (open(MANI, $mani)) {
397         while (<MANI>) {
398             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
399                 my $t = $1;
400                 my $extension = $2;
401                 if (!$::core || $t =~ m!^lib/[a-z]!) {
402                     if (defined $extension) {
403                         $extension =~ s!/t(:?/\S+)*$!!;
404                         # XXX Do I want to warn that I'm skipping these?
405                         next if $skip{$extension};
406                         my $flat_extension = $extension;
407                         $flat_extension =~ s!-!/!g;
408                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
409                     }
410                     my $path = "../$t";
411                     push @results, $path;
412                     $::path_to_name{$path} = $t;
413                 }
414             }
415         }
416         close MANI;
417     } else {
418         warn "$0: cannot open $mani: $!\n";
419     }
420     return @results;
421 }
422
423 unless (@ARGV) {
424     # base first, as TEST bails out if that can't run
425     # then comp, to validate that require works
426     # then run, to validate that -M works
427     # then we know we can -MTestInit for everything else, making life simpler
428     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
429         _find_tests($dir);
430     }
431     unless ($::core) {
432         _find_tests('porting');
433         _find_tests("lib"); 
434     }
435     # Config.pm may be broken for make minitest. And this is only a refinement
436     # for skipping tests on non-default builds, so it is allowed to fail.
437     # What we want to to is make a list of extensions which we did not build.
438     my $configsh = '../config.sh';
439     my ($extensions, $known_extensions);
440     if (-f $configsh) {
441         open FH, $configsh or die "Can't open $configsh: $!";
442         while (<FH>) {
443             if (/^extensions=['"](.*)['"]$/) {
444                 $extensions = $1;
445             }
446             elsif (/^known_extensions=['"](.*)['"]$/) {
447                 $known_extensions = $1;
448             }
449         }
450         if (!defined $known_extensions) {
451             warn "No known_extensions line found in $configsh";
452         }
453         if (!defined $extensions) {
454             warn "No extensions line found in $configsh";
455         }
456     }
457     # The "complex" constructions of list return from a subroutine, and push of
458     # a list, might fail if perl is really hosed, but they aren't needed for
459     # make minitest, and the building of extensions will likely also fail if
460     # something is that badly wrong.
461     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
462     unless ($::core) {
463         _find_tests('japh') if $::torture;
464         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
465         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
466     }
467 }
468
469 if ($::deparse) {
470     _testprogs('deparse', '',   @ARGV);
471 }
472 elsif ($::with_utf16) {
473     for my $e (0, 1) {
474         for my $b (0, 1) {
475             print STDERR "# ENDIAN $e BOM $b\n";
476             my @UARGV;
477             for my $a (@ARGV) {
478                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
479                 my $f = $e ? "v" : "n";
480                 push @UARGV, $u;
481                 unlink($u);
482                 if (open(A, $a)) {
483                     if (open(U, ">$u")) {
484                         print U pack("$f", 0xFEFF) if $b;
485                         while (<A>) {
486                             print U pack("$f*", unpack("C*", $_));
487                         }
488                         close(U);
489                     }
490                     close(A);
491                 }
492             }
493             _testprogs('perl', '', @UARGV);
494             unlink(@UARGV);
495         }
496     }
497 }
498 else {
499     _testprogs('perl',    '',   @ARGV);
500 }
501
502 sub _testprogs {
503     my ($type, $args, @tests) = @_;
504
505     print <<'EOT' if ($type eq 'deparse');
506 ------------------------------------------------------------------------------
507 TESTING DEPARSER
508 ------------------------------------------------------------------------------
509 EOT
510
511     $::bad_files = 0;
512
513     foreach my $t (@tests) {
514       unless (exists $::path_to_name{$t}) {
515         my $tname = "t/$t";
516         $::path_to_name{$t} = $tname;
517       }
518     }
519     my $maxlen = 0;
520     foreach (@::path_to_name{@tests}) {
521         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
522         my $len = length ;
523         $maxlen = $len if $len > $maxlen;
524     }
525     # + 3 : we want three dots between the test name and the "ok"
526     my $dotdotdot = $maxlen + 3 ;
527     my $grind_ct = 0;           # count of non-empty valgrind reports
528     my $total_files = @tests;
529     my $good_files = 0;
530     my $tested_files  = 0;
531     my $totmax = 0;
532     my %failed_tests;
533     my $toolnm;         # valgrind, cachegrind, perf
534
535     while (my $test = shift @tests) {
536         my ($test_start_time, @starttimes) = 0;
537         if ($show_elapsed_time) {
538             $test_start_time = Time::HiRes::time();
539             # times() reports usage by TEST, but we want usage of each
540             # testprog it calls, so record accumulated times now,
541             # subtract them out afterwards.  Ideally, we'd take times
542             # in BEGIN/END blocks (giving better visibility of self vs
543             # children of each testprog), but that would require some
544             # IPC to send results back here, or a completely different
545             # collection scheme (Storable isn't tuned for incremental use)
546             @starttimes = times;
547         }
548         if ($test =~ /^$/) {
549             next;
550         }
551         if ($type eq 'deparse') {
552             if ($test eq "comp/redef.t") {
553                 # Redefinition happens at compile time
554                 next;
555             }
556             elsif ($test =~ m{lib/Switch/t/}) {
557                 # B::Deparse doesn't support source filtering
558                 next;
559             }
560         }
561         my $te = $::path_to_name{$test} . '.'
562                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
563
564         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
565             print $te;
566             $te = '';
567         }
568
569         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
570
571         my $results = _run_test($test, $type);
572
573         my $failure;
574         my $next = 0;
575         my $seen_leader = 0;
576         my $seen_ok = 0;
577         my $trailing_leader = 0;
578         my $max;
579         my %todo;
580         while (<$results>) {
581             next if /^\s*$/; # skip blank lines
582             if (/^1..$/ && ($^O eq 'VMS')) {
583                 # VMS pipe bug inserts blank lines.
584                 my $l2 = <$results>;
585                 if ($l2 =~ /^\s*$/) {
586                     $l2 = <$results>;
587                 }
588                 $_ = '1..' . $l2;
589             }
590             if ($::verbose) {
591                 print $_;
592             }
593             unless (/^\#/) {
594                 if ($trailing_leader) {
595                     # shouldn't be anything following a postfix 1..n
596                     $failure = 'FAILED--extra output after trailing 1..n';
597                     last;
598                 }
599                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
600                     if ($seen_leader) {
601                         $failure = 'FAILED--seen duplicate leader';
602                         last;
603                     }
604                     $max = $1;
605                     %todo = map { $_ => 1 } split / /, $3 if $3;
606                     $totmax = $totmax + $max;
607                     $tested_files = $tested_files + 1;
608                     if ($seen_ok) {
609                         # 1..n appears at end of file
610                         $trailing_leader = 1;
611                         if ($next != $max) {
612                             $failure = "FAILED--expected $max tests, saw $next";
613                             last;
614                         }
615                     }
616                     else {
617                         $next = 0;
618                     }
619                     $seen_leader = 1;
620                 }
621                 else {
622                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
623                         unless ($seen_leader) {
624                             unless ($seen_ok) {
625                                 $next = 0;
626                             }
627                         }
628                         $seen_ok = 1;
629                         $next = $next + 1;
630                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
631                         $num = $next unless $num;
632
633                         if ($num == $next) {
634
635                             # SKIP is essentially the same as TODO for t/TEST
636                             # this still conforms to TAP:
637                             # http://testanything.org/wiki/index.php/TAP_specification
638                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
639                             $istodo = 1 if $todo{$num};
640
641                             if( $not && !$istodo ) {
642                                 $failure = "FAILED at test $num";
643                                 last;
644                             }
645                         }
646                         else {
647                             $failure ="FAILED--expected test $next, saw test $num";
648                             last;
649                         }
650                     }
651                     elsif (/^Bail out!\s*(.*)/i) { # magic words
652                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
653                     }
654                     else {
655                         # module tests are allowed extra output,
656                         # because Test::Harness allows it
657                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
658                         $failure = "FAILED--unexpected output at test $next";
659                         last;
660                     }
661                 }
662             }
663         }
664         close $results;
665
666         if (not defined $failure) {
667             $failure = 'FAILED--no leader found' unless $seen_leader;
668         }
669
670         _check_valgrind(\$toolnm, \$grind_ct, \$test);
671
672         if ($type eq 'deparse') {
673             unlink "./$test.dp";
674         }
675         if (not defined $failure and $next != $max) {
676             $failure="FAILED--expected $max tests, saw $next";
677         }
678
679         if( !defined $failure  # don't mask a test failure
680             and $? )
681         {
682             $failure = "FAILED--non-zero wait status: $?";
683         }
684
685         if (defined $failure) {
686             print "${te}$failure\n";
687             $::bad_files = $::bad_files + 1;
688             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
689                 # Die if running under minitest (no DynaLoader).  Otherwise
690                 # keep going, as  we know that Perl basically works, or we
691                 # would not have been able to actually compile it all the way.
692                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
693             }
694             $failed_tests{$test} = 1;
695         }
696         else {
697             if ($max) {
698                 my ($elapsed, $etms) = ("", 0);
699                 if ( $show_elapsed_time ) {
700                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
701                     $elapsed = sprintf(" %8.0f ms", $etms);
702
703                     my (@endtimes) = times;
704                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
705                     splice @endtimes, 0, 2;    # drop self/harness times
706                     $_ *= 1000 for @endtimes;  # and scale to ms
707                     $timings{$test} = [$etms,@endtimes];
708                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
709                 }
710                 print "${te}ok$elapsed\n";
711                 $good_files = $good_files + 1;
712             }
713             else {
714                 print "${te}skipped\n";
715                 $tested_files = $tested_files - 1;
716             }
717         }
718     } # while tests
719
720     if ($::bad_files == 0) {
721         if ($good_files) {
722             print "All tests successful.\n";
723             # XXX add mention of 'perlbug -ok' ?
724         }
725         else {
726             die "FAILED--no tests were run for some reason.\n";
727         }
728     }
729     else {
730         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
731         my $s = $::bad_files == 1 ? "" : "s";
732         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
733         for my $test ( sort keys %failed_tests ) {
734             print "\t$test\n";
735         }
736         warn <<'SHRDLU_1';
737 ### Since not all tests were successful, you may want to run some of
738 ### them individually and examine any diagnostic messages they produce.
739 ### See the INSTALL document's section on "make test".
740 SHRDLU_1
741         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
742 ### You have a good chance to get more information by running
743 ###   ./perl harness
744 ### in the 't' directory since most (>=80%) of the tests succeeded.
745 SHRDLU_2
746         if (eval {require Config; import Config; 1}) {
747             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
748                 warn <<SHRDLU_3;
749 ### You may have to set your dynamic library search path,
750 ### $p, to point to the build directory:
751 SHRDLU_3
752                 if (exists $ENV{$p} && $ENV{$p} ne '') {
753                     warn <<SHRDLU_4a;
754 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
755 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
756 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
757 SHRDLU_4a
758                 } else {
759                     warn <<SHRDLU_4b;
760 ###   setenv $p `pwd`; cd t; ./perl harness
761 ###   $p=`pwd`; export $p; cd t; ./perl harness
762 ###   export $p=`pwd`; cd t; ./perl harness
763 SHRDLU_4b
764                 }
765                 warn <<SHRDLU_5;
766 ### for csh-style shells, like tcsh; or for traditional/modern
767 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
768 SHRDLU_5
769             }
770         }
771     }
772     my ($user,$sys,$cuser,$csys) = times;
773     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
774                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
775     print "$tot\n";
776     if ($good_files) {
777         if (-d $show_elapsed_time) {
778             # HARNESS_TIMER = <a-directory>.  Save timings etc to
779             # storable file there.  NB: the test cds to ./t/, so
780             # relative path must account for that, ie ../../perf
781             # points to dir next to source tree.
782             require Storable;
783             my @dt = localtime;
784             $dt[5] += 1900; $dt[4] += 1; # fix year, month
785             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
786             Storable::store({ perf => \%timings,
787                               gather_conf_platform_info(),
788                               total => $tot,
789                             }, $fn);
790             print "wrote storable file: $fn\n";
791         }
792     }
793
794     _cleanup_valgrind(\$toolnm, \$grind_ct);
795 }
796 exit ($::bad_files != 0);
797
798 # Collect platform, config data that should allow comparing
799 # performance data between different machines.  With enough data,
800 # and/or clever statistical analysis, it should be possible to
801 # determine the effect of config choices, more memory, etc
802
803 sub gather_conf_platform_info {
804     # currently rather quick & dirty, and subject to change
805     # for both content and format.
806     require Config;
807     my (%conf, @platform) = ();
808     $conf{$_} = $Config::Config{$_} for
809         grep /cc|git|config_arg\d+/, keys %Config::Config;
810     if (-f '/proc/cpuinfo') {
811         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
812         @platform = grep /name|cpu/, <$fh>;
813         chomp $_ for @platform;
814     }
815     unshift @platform, $^O;
816
817     return (
818         conf => \%conf,
819         platform => {cpu => \@platform,
820                      mem => [ grep s/\s+/ /,
821                               grep chomp, `free` ],
822                      load => [ grep chomp, `uptime` ],
823         },
824         host => (grep chomp, `hostname -f`),
825         version => '0.03', # bump for conf, platform, or data collection changes
826         );
827 }
828
829 sub _check_valgrind {
830     return unless $ENV{PERL_VALGRIND};
831
832     my ($toolnm, $grind_ct, $test) = @_;
833
834     $$toolnm = $ENV{VALGRIND};
835     $$toolnm =~ s|.*/||;  # keep basename
836     my @valgrind;       # gets content of file
837     if (-e $Valgrind_Log) {
838         if (open(V, $Valgrind_Log)) {
839             @valgrind = <V>;
840             close V;
841         } else {
842             warn "$0: Failed to open '$Valgrind_Log': $!\n";
843         }
844     }
845     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
846         $$toolnm = $1;
847         if ($$toolnm eq 'perf') {
848             # append perfs subcommand, not just stat
849             my ($sub) = split /\s/, $ENV{VG_OPTS};
850             $$toolnm .= "-$sub";
851         }
852         if (rename $Valgrind_Log, "$$test.$$toolnm") {
853             $$grind_ct++;
854         } else {
855             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
856         }
857     }
858     elsif (@valgrind) {
859         my $leaks = 0;
860         my $errors = 0;
861         for my $i (0..$#valgrind) {
862             local $_ = $valgrind[$i];
863             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
864                 $errors = $errors + $1;   # there may be multiple error summaries
865             } elsif (/^==\d+== LEAK SUMMARY:/) {
866                 for my $off (1 .. 4) {
867                     if ($valgrind[$i+$off] =~
868                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
869                             $leaks = $leaks + $1;
870                     }
871                 }
872             }
873         }
874         if ($errors or $leaks) {
875             if (rename $Valgrind_Log, "$$test.valgrind") {
876                 $$grind_ct = $$grind_ct + 1;
877             } else {
878                 warn "$0: Failed to create '$$test.valgrind': $!\n";
879             }
880         }
881     } else {
882         # Quiet wasn't asked for? Something may be amiss
883         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
884             warn "No valgrind output?\n";
885         }
886     }
887     if (-e $Valgrind_Log) {
888         unlink $Valgrind_Log
889             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
890     }
891 }
892
893 sub _cleanup_valgrind {
894     return unless $ENV{PERL_VALGRIND};
895
896     my ($toolnm, $grind_ct) = @_;
897     my $s = $$grind_ct == 1 ? '' : 's';
898     print "$$grind_ct valgrind report$s created.\n", ;
899     if ($$toolnm eq 'cachegrind') {
900         # cachegrind leaves a lot of cachegrind.out.$pid litter
901         # around the tree, find and delete them
902         unlink _find_files('cachegrind.out.\d+$',
903                      qw ( ../t ../cpan ../ext ../dist/ ));
904     }
905 }
906
907 # ex: set ts=8 sts=4 sw=4 noet: