This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
integrate changes#7069..7077,7079,7081..7087,7090,7092,7093,
[perl5.git] / lib / CGI.pm
1 package CGI;
2 require 5.004;
3
4 # See the bottom of this file for the POD documentation.  Search for the
5 # string '=head'.
6
7 # You can run this file through either pod2man or pod2html to produce pretty
8 # documentation in manual or html file format (these utilities are part of the
9 # Perl 5 distribution).
10
11 # Copyright 1995-1998 Lincoln D. Stein.  All rights reserved.
12 # It may be used and modified freely, but I do request that this copyright
13 # notice remain attached to the file.  You may modify this module as you 
14 # wish, but if you redistribute a modified version, please attach a note
15 # listing the modifications you have made.
16
17 # The most recent version and complete docs are available at:
18 #   http://stein.cshl.org/WWW/software/CGI/
19
20 $CGI::revision = '$Id: CGI.pm,v 1.45 2000/09/13 02:55:41 lstein Exp $';
21 $CGI::VERSION='2.74';
22
23 # HARD-CODED LOCATION FOR FILE UPLOAD TEMPORARY FILES.
24 # UNCOMMENT THIS ONLY IF YOU KNOW WHAT YOU'RE DOING.
25 # $TempFile::TMPDIRECTORY = '/usr/tmp';
26 use CGI::Util qw(rearrange make_attributes unescape escape expires);
27
28 use constant XHTML_DTD => ['-//W3C//DTD XHTML 1.0 Transitional//EN',
29                            'DTD/xhtml1-transitional.dtd'];
30
31 # >>>>> Here are some globals that you might want to adjust <<<<<<
32 sub initialize_globals {
33     # Set this to 1 to enable copious autoloader debugging messages
34     $AUTOLOAD_DEBUG = 0;
35     
36     # Set this to 1 to generate XTML-compatible output
37     $XHTML = 1;
38
39     # Change this to the preferred DTD to print in start_html()
40     # or use default_dtd('text of DTD to use');
41     $DEFAULT_DTD = [ '-//W3C//DTD HTML 4.01 Transitional//EN',
42                      'http://www.w3.org/TR/html4/loose.dtd' ] ;
43
44     # Set this to 1 to enable NOSTICKY scripts
45     # or: 
46     #    1) use CGI qw(-nosticky)
47     #    2) $CGI::nosticky(1)
48     $NOSTICKY = 0;
49
50     # Set this to 1 to enable NPH scripts
51     # or: 
52     #    1) use CGI qw(-nph)
53     #    2) CGI::nph(1)
54     #    3) print header(-nph=>1)
55     $NPH = 0;
56
57     # Set this to 1 to enable debugging from @ARGV
58     # Set to 2 to enable debugging from STDIN
59     $DEBUG = 1;
60
61     # Set this to 1 to make the temporary files created
62     # during file uploads safe from prying eyes
63     # or do...
64     #    1) use CGI qw(:private_tempfiles)
65     #    2) CGI::private_tempfiles(1);
66     $PRIVATE_TEMPFILES = 0;
67
68     # Set this to a positive value to limit the size of a POSTing
69     # to a certain number of bytes:
70     $POST_MAX = -1;
71
72     # Change this to 1 to disable uploads entirely:
73     $DISABLE_UPLOADS = 0;
74
75     # Automatically determined -- don't change
76     $EBCDIC = 0;
77
78     # Change this to 1 to suppress redundant HTTP headers
79     $HEADERS_ONCE = 0;
80
81     # separate the name=value pairs by semicolons rather than ampersands
82     $USE_PARAM_SEMICOLONS = 1;
83
84     # Other globals that you shouldn't worry about.
85     undef $Q;
86     $BEEN_THERE = 0;
87     undef @QUERY_PARAM;
88     undef %EXPORT;
89     undef $QUERY_CHARSET;
90     undef %QUERY_FIELDNAMES;
91
92     # prevent complaints by mod_perl
93     1;
94 }
95
96 # ------------------ START OF THE LIBRARY ------------
97
98 # make mod_perlhappy
99 initialize_globals();
100
101 # FIGURE OUT THE OS WE'RE RUNNING UNDER
102 # Some systems support the $^O variable.  If not
103 # available then require() the Config library
104 unless ($OS) {
105     unless ($OS = $^O) {
106         require Config;
107         $OS = $Config::Config{'osname'};
108     }
109 }
110 if ($OS=~/Win/i) {
111   $OS = 'WINDOWS';
112 } elsif ($OS=~/vms/i) {
113   $OS = 'VMS';
114 } elsif ($OS=~/bsdos/i) {
115   $OS = 'UNIX';
116 } elsif ($OS=~/dos/i) {
117   $OS = 'DOS';
118 } elsif ($OS=~/^MacOS$/i) {
119     $OS = 'MACINTOSH';
120 } elsif ($OS=~/os2/i) {
121     $OS = 'OS2';
122 } else {
123     $OS = 'UNIX';
124 }
125
126 # Some OS logic.  Binary mode enabled on DOS, NT and VMS
127 $needs_binmode = $OS=~/^(WINDOWS|DOS|OS2|MSWin)/;
128
129 # This is the default class for the CGI object to use when all else fails.
130 $DefaultClass = 'CGI' unless defined $CGI::DefaultClass;
131
132 # This is where to look for autoloaded routines.
133 $AutoloadClass = $DefaultClass unless defined $CGI::AutoloadClass;
134
135 # The path separator is a slash, backslash or semicolon, depending
136 # on the paltform.
137 $SL = {
138     UNIX=>'/', OS2=>'\\', WINDOWS=>'\\', DOS=>'\\', MACINTOSH=>':', VMS=>'/'
139     }->{$OS};
140
141 # This no longer seems to be necessary
142 # Turn on NPH scripts by default when running under IIS server!
143 # $NPH++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
144 $IIS++ if defined($ENV{'SERVER_SOFTWARE'}) && $ENV{'SERVER_SOFTWARE'}=~/IIS/;
145
146 # Turn on special checking for Doug MacEachern's modperl
147 if (exists $ENV{'GATEWAY_INTERFACE'} 
148     && 
149     ($MOD_PERL = $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-Perl\//))
150 {
151     $| = 1;
152     require Apache;
153 }
154 # Turn on special checking for ActiveState's PerlEx
155 $PERLEX++ if defined($ENV{'GATEWAY_INTERFACE'}) && $ENV{'GATEWAY_INTERFACE'} =~ /^CGI-PerlEx/;
156
157 # Define the CRLF sequence.  I can't use a simple "\r\n" because the meaning
158 # of "\n" is different on different OS's (sometimes it generates CRLF, sometimes LF
159 # and sometimes CR).  The most popular VMS web server
160 # doesn't accept CRLF -- instead it wants a LR.  EBCDIC machines don't
161 # use ASCII, so \015\012 means something different.  I find this all 
162 # really annoying.
163 $EBCDIC = "\t" ne "\011";
164 if ($OS eq 'VMS') {
165   $CRLF = "\n";
166 } elsif ($EBCDIC) {
167   $CRLF= "\r\n";
168 } else {
169   $CRLF = "\015\012";
170 }
171
172 if ($needs_binmode) {
173     $CGI::DefaultClass->binmode(main::STDOUT);
174     $CGI::DefaultClass->binmode(main::STDIN);
175     $CGI::DefaultClass->binmode(main::STDERR);
176 }
177
178 %EXPORT_TAGS = (
179                 ':html2'=>['h1'..'h6',qw/p br hr ol ul li dl dt dd menu code var strong em
180                            tt u i b blockquote pre img a address cite samp dfn html head
181                            base body Link nextid title meta kbd start_html end_html
182                            input Select option comment charset escapeHTML/],
183                 ':html3'=>[qw/div table caption th td TR Tr sup Sub strike applet Param 
184                            embed basefont style span layer ilayer font frameset frame script small big/],
185                 ':netscape'=>[qw/blink fontsize center/],
186                 ':form'=>[qw/textfield textarea filefield password_field hidden checkbox checkbox_group 
187                           submit reset defaults radio_group popup_menu button autoEscape
188                           scrolling_list image_button start_form end_form startform endform
189                           start_multipart_form end_multipart_form isindex tmpFileName uploadInfo URL_ENCODED MULTIPART/],
190                 ':cgi'=>[qw/param upload path_info path_translated url self_url script_name cookie Dump
191                          raw_cookie request_method query_string Accept user_agent remote_host content_type
192                          remote_addr referer server_name server_software server_port server_protocol
193                          virtual_host remote_ident auth_type http
194                          save_parameters restore_parameters param_fetch
195                          remote_user user_name header redirect import_names put 
196                          Delete Delete_all url_param cgi_error/],
197                 ':ssl' => [qw/https/],
198                 ':imagemap' => [qw/Area Map/],
199                 ':cgi-lib' => [qw/ReadParse PrintHeader HtmlTop HtmlBot SplitParam Vars/],
200                 ':html' => [qw/:html2 :html3 :netscape/],
201                 ':standard' => [qw/:html2 :html3 :form :cgi/],
202                 ':push' => [qw/multipart_init multipart_start multipart_end/],
203                 ':all' => [qw/:html2 :html3 :netscape :form :cgi :internal/]
204                 );
205
206 # to import symbols into caller
207 sub import {
208     my $self = shift;
209
210 # This causes modules to clash.  
211 #    undef %EXPORT_OK;
212 #    undef %EXPORT;
213
214     $self->_setup_symbols(@_);
215     my ($callpack, $callfile, $callline) = caller;
216
217     # To allow overriding, search through the packages
218     # Till we find one in which the correct subroutine is defined.
219     my @packages = ($self,@{"$self\:\:ISA"});
220     foreach $sym (keys %EXPORT) {
221         my $pck;
222         my $def = ${"$self\:\:AutoloadClass"} || $DefaultClass;
223         foreach $pck (@packages) {
224             if (defined(&{"$pck\:\:$sym"})) {
225                 $def = $pck;
226                 last;
227             }
228         }
229         *{"${callpack}::$sym"} = \&{"$def\:\:$sym"};
230     }
231 }
232
233 sub compile {
234     my $pack = shift;
235     $pack->_setup_symbols('-compile',@_);
236 }
237
238 sub expand_tags {
239     my($tag) = @_;
240     return ("start_$1","end_$1") if $tag=~/^(?:\*|start_|end_)(.+)/;
241     my(@r);
242     return ($tag) unless $EXPORT_TAGS{$tag};
243     foreach (@{$EXPORT_TAGS{$tag}}) {
244         push(@r,&expand_tags($_));
245     }
246     return @r;
247 }
248
249 #### Method: new
250 # The new routine.  This will check the current environment
251 # for an existing query string, and initialize itself, if so.
252 ####
253 sub new {
254     my($class,$initializer) = @_;
255     my $self = {};
256     bless $self,ref $class || $class || $DefaultClass;
257     if ($MOD_PERL && defined Apache->request) {
258       Apache->request->register_cleanup(\&CGI::_reset_globals);
259       undef $NPH;
260     }
261     $self->_reset_globals if $PERLEX;
262     $self->init($initializer);
263     return $self;
264 }
265
266 # We provide a DESTROY method so that the autoloader
267 # doesn't bother trying to find it.
268 sub DESTROY { }
269
270 #### Method: param
271 # Returns the value(s)of a named parameter.
272 # If invoked in a list context, returns the
273 # entire list.  Otherwise returns the first
274 # member of the list.
275 # If name is not provided, return a list of all
276 # the known parameters names available.
277 # If more than one argument is provided, the
278 # second and subsequent arguments are used to
279 # set the value of the parameter.
280 ####
281 sub param {
282     my($self,@p) = self_or_default(@_);
283     return $self->all_parameters unless @p;
284     my($name,$value,@other);
285
286     # For compatibility between old calling style and use_named_parameters() style, 
287     # we have to special case for a single parameter present.
288     if (@p > 1) {
289         ($name,$value,@other) = rearrange([NAME,[DEFAULT,VALUE,VALUES]],@p);
290         my(@values);
291
292         if (substr($p[0],0,1) eq '-') {
293             @values = defined($value) ? (ref($value) && ref($value) eq 'ARRAY' ? @{$value} : $value) : ();
294         } else {
295             foreach ($value,@other) {
296                 push(@values,$_) if defined($_);
297             }
298         }
299         # If values is provided, then we set it.
300         if (@values) {
301             $self->add_parameter($name);
302             $self->{$name}=[@values];
303         }
304     } else {
305         $name = $p[0];
306     }
307
308     return unless defined($name) && $self->{$name};
309     return wantarray ? @{$self->{$name}} : $self->{$name}->[0];
310 }
311
312 sub self_or_default {
313     return @_ if defined($_[0]) && (!ref($_[0])) &&($_[0] eq 'CGI');
314     unless (defined($_[0]) && 
315             (ref($_[0]) eq 'CGI' || UNIVERSAL::isa($_[0],'CGI')) # slightly optimized for common case
316             ) {
317         $Q = $CGI::DefaultClass->new unless defined($Q);
318         unshift(@_,$Q);
319     }
320     return wantarray ? @_ : $Q;
321 }
322
323 sub self_or_CGI {
324     local $^W=0;                # prevent a warning
325     if (defined($_[0]) &&
326         (substr(ref($_[0]),0,3) eq 'CGI' 
327          || UNIVERSAL::isa($_[0],'CGI'))) {
328         return @_;
329     } else {
330         return ($DefaultClass,@_);
331     }
332 }
333
334 ########################################
335 # THESE METHODS ARE MORE OR LESS PRIVATE
336 # GO TO THE __DATA__ SECTION TO SEE MORE
337 # PUBLIC METHODS
338 ########################################
339
340 # Initialize the query object from the environment.
341 # If a parameter list is found, this object will be set
342 # to an associative array in which parameter names are keys
343 # and the values are stored as lists
344 # If a keyword list is found, this method creates a bogus
345 # parameter list with the single parameter 'keywords'.
346
347 sub init {
348     my($self,$initializer) = @_;
349     my($query_string,$meth,$content_length,$fh,@lines) = ('','','','');
350     local($/) = "\n";
351
352     # if we get called more than once, we want to initialize
353     # ourselves from the original query (which may be gone
354     # if it was read from STDIN originally.)
355     if (defined(@QUERY_PARAM) && !defined($initializer)) {
356         foreach (@QUERY_PARAM) {
357             $self->param('-name'=>$_,'-value'=>$QUERY_PARAM{$_});
358         }
359         $self->charset($QUERY_CHARSET);
360         $self->{'.fieldnames'} = {%QUERY_FIELDNAMES};
361         return;
362     }
363
364     $meth=$ENV{'REQUEST_METHOD'} if defined($ENV{'REQUEST_METHOD'});
365     $content_length = defined($ENV{'CONTENT_LENGTH'}) ? $ENV{'CONTENT_LENGTH'} : 0;
366
367     $fh = to_filehandle($initializer) if $initializer;
368
369     # set charset to the safe ISO-8859-1
370     $self->charset('ISO-8859-1');
371
372   METHOD: {
373
374       # avoid unreasonably large postings
375       if (($POST_MAX > 0) && ($content_length > $POST_MAX)) {
376           $self->cgi_error("413 Request entity too large");
377           last METHOD;
378       }
379
380       # Process multipart postings, but only if the initializer is
381       # not defined.
382       if ($meth eq 'POST'
383           && defined($ENV{'CONTENT_TYPE'})
384           && $ENV{'CONTENT_TYPE'}=~m|^multipart/form-data|
385           && !defined($initializer)
386           ) {
387           my($boundary) = $ENV{'CONTENT_TYPE'} =~ /boundary=\"?([^\";,]+)\"?/;
388           $self->read_multipart($boundary,$content_length);
389           last METHOD;
390       } 
391
392       # If initializer is defined, then read parameters
393       # from it.
394       if (defined($initializer)) {
395           if (UNIVERSAL::isa($initializer,'CGI')) {
396               $query_string = $initializer->query_string;
397               last METHOD;
398           }
399           if (ref($initializer) && ref($initializer) eq 'HASH') {
400               foreach (keys %$initializer) {
401                   $self->param('-name'=>$_,'-value'=>$initializer->{$_});
402               }
403               last METHOD;
404           }
405           
406           if (defined($fh) && ($fh ne '')) {
407               while (<$fh>) {
408                   chomp;
409                   last if /^=/;
410                   push(@lines,$_);
411               }
412               # massage back into standard format
413               if ("@lines" =~ /=/) {
414                   $query_string=join("&",@lines);
415               } else {
416                   $query_string=join("+",@lines);
417               }
418               last METHOD;
419           }
420
421           # last chance -- treat it as a string
422           $initializer = $$initializer if ref($initializer) eq 'SCALAR';
423           $query_string = $initializer;
424
425           last METHOD;
426       }
427
428       # If method is GET or HEAD, fetch the query from
429       # the environment.
430       if ($meth=~/^(GET|HEAD)$/) {
431           if ($MOD_PERL) {
432               $query_string = Apache->request->args;
433           } else {
434               $query_string = $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
435               $query_string ||= $ENV{'REDIRECT_QUERY_STRING'} if defined $ENV{'REDIRECT_QUERY_STRING'};
436           }
437           last METHOD;
438       }
439
440       if ($meth eq 'POST') {
441           $self->read_from_client(\*STDIN,\$query_string,$content_length,0)
442               if $content_length > 0;
443           # Some people want to have their cake and eat it too!
444           # Uncomment this line to have the contents of the query string
445           # APPENDED to the POST data.
446           # $query_string .= (length($query_string) ? '&' : '') . $ENV{'QUERY_STRING'} if defined $ENV{'QUERY_STRING'};
447           last METHOD;
448       }
449
450       # If $meth is not of GET, POST or HEAD, assume we're being debugged offline.
451       # Check the command line and then the standard input for data.
452       # We use the shellwords package in order to behave the way that
453       # UN*X programmers expect.
454       $query_string = read_from_cmdline() if $DEBUG;
455   }
456
457     # We now have the query string in hand.  We do slightly
458     # different things for keyword lists and parameter lists.
459     if (defined $query_string && $query_string) {
460         if ($query_string =~ /[&=;]/) {
461             $self->parse_params($query_string);
462         } else {
463             $self->add_parameter('keywords');
464             $self->{'keywords'} = [$self->parse_keywordlist($query_string)];
465         }
466     }
467
468     # Special case.  Erase everything if there is a field named
469     # .defaults.
470     if ($self->param('.defaults')) {
471         undef %{$self};
472     }
473
474     # Associative array containing our defined fieldnames
475     $self->{'.fieldnames'} = {};
476     foreach ($self->param('.cgifields')) {
477         $self->{'.fieldnames'}->{$_}++;
478     }
479     
480     # Clear out our default submission button flag if present
481     $self->delete('.submit');
482     $self->delete('.cgifields');
483
484     $self->save_request unless $initializer;
485 }
486
487 # FUNCTIONS TO OVERRIDE:
488 # Turn a string into a filehandle
489 sub to_filehandle {
490     my $thingy = shift;
491     return undef unless $thingy;
492     return $thingy if UNIVERSAL::isa($thingy,'GLOB');
493     return $thingy if UNIVERSAL::isa($thingy,'FileHandle');
494     if (!ref($thingy)) {
495         my $caller = 1;
496         while (my $package = caller($caller++)) {
497             my($tmp) = $thingy=~/[\':]/ ? $thingy : "$package\:\:$thingy"; 
498             return $tmp if defined(fileno($tmp));
499         }
500     }
501     return undef;
502 }
503
504 # send output to the browser
505 sub put {
506     my($self,@p) = self_or_default(@_);
507     $self->print(@p);
508 }
509
510 # print to standard output (for overriding in mod_perl)
511 sub print {
512     shift;
513     CORE::print(@_);
514 }
515
516 # get/set last cgi_error
517 sub cgi_error {
518     my ($self,$err) = self_or_default(@_);
519     $self->{'.cgi_error'} = $err if defined $err;
520     return $self->{'.cgi_error'};
521 }
522
523 sub save_request {
524     my($self) = @_;
525     # We're going to play with the package globals now so that if we get called
526     # again, we initialize ourselves in exactly the same way.  This allows
527     # us to have several of these objects.
528     @QUERY_PARAM = $self->param; # save list of parameters
529     foreach (@QUERY_PARAM) {
530       next unless defined $_;
531       $QUERY_PARAM{$_}=$self->{$_};
532     }
533     $QUERY_CHARSET = $self->charset;
534     %QUERY_FIELDNAMES = %{$self->{'.fieldnames'}};
535 }
536
537 sub parse_params {
538     my($self,$tosplit) = @_;
539     my(@pairs) = split(/[&;]/,$tosplit);
540     my($param,$value);
541     foreach (@pairs) {
542         ($param,$value) = split('=',$_,2);
543         $value = '' unless defined $value;
544         $param = unescape($param);
545         $value = unescape($value);
546         $self->add_parameter($param);
547         push (@{$self->{$param}},$value);
548     }
549 }
550
551 sub add_parameter {
552     my($self,$param)=@_;
553     return unless defined $param;
554     push (@{$self->{'.parameters'}},$param) 
555         unless defined($self->{$param});
556 }
557
558 sub all_parameters {
559     my $self = shift;
560     return () unless defined($self) && $self->{'.parameters'};
561     return () unless @{$self->{'.parameters'}};
562     return @{$self->{'.parameters'}};
563 }
564
565 # put a filehandle into binary mode (DOS)
566 sub binmode {
567     CORE::binmode($_[1]);
568 }
569
570 sub _make_tag_func {
571     my ($self,$tagname) = @_;
572     my $func = qq(
573         sub $tagname {
574             shift if \$_[0] && 
575                     (ref(\$_[0]) &&
576                      (substr(ref(\$_[0]),0,3) eq 'CGI' ||
577                     UNIVERSAL::isa(\$_[0],'CGI')));
578             my(\$attr) = '';
579             if (ref(\$_[0]) && ref(\$_[0]) eq 'HASH') {
580                 my(\@attr) = make_attributes(shift()||undef,1);
581                 \$attr = " \@attr" if \@attr;
582             }
583         );
584     if ($tagname=~/start_(\w+)/i) {
585         $func .= qq! return "<\L$1\E\$attr>";} !;
586     } elsif ($tagname=~/end_(\w+)/i) {
587         $func .= qq! return "<\L/$1\E>"; } !;
588     } else {
589         $func .= qq#
590             return \$XHTML ? "\L<$tagname\E\$attr />" : "\L<$tagname\E\$attr>" unless \@_;
591             my(\$tag,\$untag) = ("\L<$tagname\E\$attr>","\L</$tagname>\E");
592             my \@result = map { "\$tag\$_\$untag" } 
593                               (ref(\$_[0]) eq 'ARRAY') ? \@{\$_[0]} : "\@_";
594             return "\@result";
595             }#;
596     }
597 return $func;
598 }
599
600 sub AUTOLOAD {
601     print STDERR "CGI::AUTOLOAD for $AUTOLOAD\n" if $CGI::AUTOLOAD_DEBUG;
602     my $func = &_compile;
603     goto &$func;
604 }
605
606 sub _compile {
607     my($func) = $AUTOLOAD;
608     my($pack,$func_name);
609     {
610         local($1,$2); # this fixes an obscure variable suicide problem.
611         $func=~/(.+)::([^:]+)$/;
612         ($pack,$func_name) = ($1,$2);
613         $pack=~s/::SUPER$//;    # fix another obscure problem
614         $pack = ${"$pack\:\:AutoloadClass"} || $CGI::DefaultClass
615             unless defined(${"$pack\:\:AUTOLOADED_ROUTINES"});
616
617         my($sub) = \%{"$pack\:\:SUBS"};
618         unless (%$sub) {
619            my($auto) = \${"$pack\:\:AUTOLOADED_ROUTINES"};
620            eval "package $pack; $$auto";
621            die $@ if $@;
622            $$auto = '';  # Free the unneeded storage (but don't undef it!!!)
623        }
624        my($code) = $sub->{$func_name};
625
626        $code = "sub $AUTOLOAD { }" if (!$code and $func_name eq 'DESTROY');
627        if (!$code) {
628            (my $base = $func_name) =~ s/^(start_|end_)//i;
629            if ($EXPORT{':any'} || 
630                $EXPORT{'-any'} ||
631                $EXPORT{$base} || 
632                (%EXPORT_OK || grep(++$EXPORT_OK{$_},&expand_tags(':html')))
633                    && $EXPORT_OK{$base}) {
634                $code = $CGI::DefaultClass->_make_tag_func($func_name);
635            }
636        }
637        die "Undefined subroutine $AUTOLOAD\n" unless $code;
638        eval "package $pack; $code";
639        if ($@) {
640            $@ =~ s/ at .*\n//;
641            die $@;
642        }
643     }       
644     CORE::delete($sub->{$func_name});  #free storage
645     return "$pack\:\:$func_name";
646 }
647
648 sub _reset_globals { initialize_globals(); }
649
650 sub _setup_symbols {
651     my $self = shift;
652     my $compile = 0;
653     foreach (@_) {
654         $HEADERS_ONCE++,         next if /^[:-]unique_headers$/;
655         $NPH++,                  next if /^[:-]nph$/;
656         $NOSTICKY++,             next if /^[:-]nosticky$/;
657         $DEBUG=0,                next if /^[:-]no_?[Dd]ebug$/;
658         $DEBUG=2,                next if /^[:-][Dd]ebug$/;
659         $USE_PARAM_SEMICOLONS++, next if /^[:-]newstyle_urls$/;
660         $XHTML++,                next if /^[:-]xhtml$/;
661         $XHTML=0,                next if /^[:-]no_?xhtml$/;
662         $USE_PARAM_SEMICOLONS=0, next if /^[:-]oldstyle_urls$/;
663         $PRIVATE_TEMPFILES++,    next if /^[:-]private_tempfiles$/;
664         $EXPORT{$_}++,           next if /^[:-]any$/;
665         $compile++,              next if /^[:-]compile$/;
666         
667         # This is probably extremely evil code -- to be deleted some day.
668         if (/^[-]autoload$/) {
669             my($pkg) = caller(1);
670             *{"${pkg}::AUTOLOAD"} = sub { 
671                 my($routine) = $AUTOLOAD;
672                 $routine =~ s/^.*::/CGI::/;
673                 &$routine;
674             };
675             next;
676         }
677
678         foreach (&expand_tags($_)) {
679             tr/a-zA-Z0-9_//cd;  # don't allow weird function names
680             $EXPORT{$_}++;
681         }
682     }
683     _compile_all(keys %EXPORT) if $compile;
684 }
685
686 sub charset {
687   my ($self,$charset) = self_or_default(@_);
688   $self->{'.charset'} = $charset if defined $charset;
689   $self->{'.charset'};
690 }
691
692 ###############################################################################
693 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
694 ###############################################################################
695 $AUTOLOADED_ROUTINES = '';      # get rid of -w warning
696 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
697
698 %SUBS = (
699
700 'URL_ENCODED'=> <<'END_OF_FUNC',
701 sub URL_ENCODED { 'application/x-www-form-urlencoded'; }
702 END_OF_FUNC
703
704 'MULTIPART' => <<'END_OF_FUNC',
705 sub MULTIPART {  'multipart/form-data'; }
706 END_OF_FUNC
707
708 'SERVER_PUSH' => <<'END_OF_FUNC',
709 sub SERVER_PUSH { 'multipart/x-mixed-replace; boundary="' . shift() . '"'; }
710 END_OF_FUNC
711
712 'new_MultipartBuffer' => <<'END_OF_FUNC',
713 # Create a new multipart buffer
714 sub new_MultipartBuffer {
715     my($self,$boundary,$length,$filehandle) = @_;
716     return MultipartBuffer->new($self,$boundary,$length,$filehandle);
717 }
718 END_OF_FUNC
719
720 'read_from_client' => <<'END_OF_FUNC',
721 # Read data from a file handle
722 sub read_from_client {
723     my($self, $fh, $buff, $len, $offset) = @_;
724     local $^W=0;                # prevent a warning
725     return undef unless defined($fh);
726     return read($fh, $$buff, $len, $offset);
727 }
728 END_OF_FUNC
729
730 'delete' => <<'END_OF_FUNC',
731 #### Method: delete
732 # Deletes the named parameter entirely.
733 ####
734 sub delete {
735     my($self,@p) = self_or_default(@_);
736     my($name) = rearrange([NAME],@p);
737     CORE::delete $self->{$name};
738     CORE::delete $self->{'.fieldnames'}->{$name};
739     @{$self->{'.parameters'}}=grep($_ ne $name,$self->param());
740     return wantarray ? () : undef;
741 }
742 END_OF_FUNC
743
744 #### Method: import_names
745 # Import all parameters into the given namespace.
746 # Assumes namespace 'Q' if not specified
747 ####
748 'import_names' => <<'END_OF_FUNC',
749 sub import_names {
750     my($self,$namespace,$delete) = self_or_default(@_);
751     $namespace = 'Q' unless defined($namespace);
752     die "Can't import names into \"main\"\n" if \%{"${namespace}::"} == \%::;
753     if ($delete || $MOD_PERL || exists $ENV{'FCGI_ROLE'}) {
754         # can anyone find an easier way to do this?
755         foreach (keys %{"${namespace}::"}) {
756             local *symbol = "${namespace}::${_}";
757             undef $symbol;
758             undef @symbol;
759             undef %symbol;
760         }
761     }
762     my($param,@value,$var);
763     foreach $param ($self->param) {
764         # protect against silly names
765         ($var = $param)=~tr/a-zA-Z0-9_/_/c;
766         $var =~ s/^(?=\d)/_/;
767         local *symbol = "${namespace}::$var";
768         @value = $self->param($param);
769         @symbol = @value;
770         $symbol = $value[0];
771     }
772 }
773 END_OF_FUNC
774
775 #### Method: keywords
776 # Keywords acts a bit differently.  Calling it in a list context
777 # returns the list of keywords.  
778 # Calling it in a scalar context gives you the size of the list.
779 ####
780 'keywords' => <<'END_OF_FUNC',
781 sub keywords {
782     my($self,@values) = self_or_default(@_);
783     # If values is provided, then we set it.
784     $self->{'keywords'}=[@values] if @values;
785     my(@result) = defined($self->{'keywords'}) ? @{$self->{'keywords'}} : ();
786     @result;
787 }
788 END_OF_FUNC
789
790 # These are some tie() interfaces for compatibility
791 # with Steve Brenner's cgi-lib.pl routines
792 'Vars' => <<'END_OF_FUNC',
793 sub Vars {
794     my $q = shift;
795     my %in;
796     tie(%in,CGI,$q);
797     return %in if wantarray;
798     return \%in;
799 }
800 END_OF_FUNC
801
802 # These are some tie() interfaces for compatibility
803 # with Steve Brenner's cgi-lib.pl routines
804 'ReadParse' => <<'END_OF_FUNC',
805 sub ReadParse {
806     local(*in);
807     if (@_) {
808         *in = $_[0];
809     } else {
810         my $pkg = caller();
811         *in=*{"${pkg}::in"};
812     }
813     tie(%in,CGI);
814     return scalar(keys %in);
815 }
816 END_OF_FUNC
817
818 'PrintHeader' => <<'END_OF_FUNC',
819 sub PrintHeader {
820     my($self) = self_or_default(@_);
821     return $self->header();
822 }
823 END_OF_FUNC
824
825 'HtmlTop' => <<'END_OF_FUNC',
826 sub HtmlTop {
827     my($self,@p) = self_or_default(@_);
828     return $self->start_html(@p);
829 }
830 END_OF_FUNC
831
832 'HtmlBot' => <<'END_OF_FUNC',
833 sub HtmlBot {
834     my($self,@p) = self_or_default(@_);
835     return $self->end_html(@p);
836 }
837 END_OF_FUNC
838
839 'SplitParam' => <<'END_OF_FUNC',
840 sub SplitParam {
841     my ($param) = @_;
842     my (@params) = split ("\0", $param);
843     return (wantarray ? @params : $params[0]);
844 }
845 END_OF_FUNC
846
847 'MethGet' => <<'END_OF_FUNC',
848 sub MethGet {
849     return request_method() eq 'GET';
850 }
851 END_OF_FUNC
852
853 'MethPost' => <<'END_OF_FUNC',
854 sub MethPost {
855     return request_method() eq 'POST';
856 }
857 END_OF_FUNC
858
859 'TIEHASH' => <<'END_OF_FUNC',
860 sub TIEHASH { 
861     return $_[1] if defined $_[1];
862     return $Q ||= new shift;
863 }
864 END_OF_FUNC
865
866 'STORE' => <<'END_OF_FUNC',
867 sub STORE {
868     my $self = shift;
869     my $tag  = shift;
870     my $vals = shift;
871     my @vals = index($vals,"\0")!=-1 ? split("\0",$vals) : $vals;
872     $self->param(-name=>$tag,-value=>\@vals);
873 }
874 END_OF_FUNC
875
876 'FETCH' => <<'END_OF_FUNC',
877 sub FETCH {
878     return $_[0] if $_[1] eq 'CGI';
879     return undef unless defined $_[0]->param($_[1]);
880     return join("\0",$_[0]->param($_[1]));
881 }
882 END_OF_FUNC
883
884 'FIRSTKEY' => <<'END_OF_FUNC',
885 sub FIRSTKEY {
886     $_[0]->{'.iterator'}=0;
887     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
888 }
889 END_OF_FUNC
890
891 'NEXTKEY' => <<'END_OF_FUNC',
892 sub NEXTKEY {
893     $_[0]->{'.parameters'}->[$_[0]->{'.iterator'}++];
894 }
895 END_OF_FUNC
896
897 'EXISTS' => <<'END_OF_FUNC',
898 sub EXISTS {
899     exists $_[0]->{$_[1]};
900 }
901 END_OF_FUNC
902
903 'DELETE' => <<'END_OF_FUNC',
904 sub DELETE {
905     $_[0]->delete($_[1]);
906 }
907 END_OF_FUNC
908
909 'CLEAR' => <<'END_OF_FUNC',
910 sub CLEAR {
911     %{$_[0]}=();
912 }
913 ####
914 END_OF_FUNC
915
916 ####
917 # Append a new value to an existing query
918 ####
919 'append' => <<'EOF',
920 sub append {
921     my($self,@p) = @_;
922     my($name,$value) = rearrange([NAME,[VALUE,VALUES]],@p);
923     my(@values) = defined($value) ? (ref($value) ? @{$value} : $value) : ();
924     if (@values) {
925         $self->add_parameter($name);
926         push(@{$self->{$name}},@values);
927     }
928     return $self->param($name);
929 }
930 EOF
931
932 #### Method: delete_all
933 # Delete all parameters
934 ####
935 'delete_all' => <<'EOF',
936 sub delete_all {
937     my($self) = self_or_default(@_);
938     undef %{$self};
939 }
940 EOF
941
942 'Delete' => <<'EOF',
943 sub Delete {
944     my($self,@p) = self_or_default(@_);
945     $self->delete(@p);
946 }
947 EOF
948
949 'Delete_all' => <<'EOF',
950 sub Delete_all {
951     my($self,@p) = self_or_default(@_);
952     $self->delete_all(@p);
953 }
954 EOF
955
956 #### Method: autoescape
957 # If you want to turn off the autoescaping features,
958 # call this method with undef as the argument
959 'autoEscape' => <<'END_OF_FUNC',
960 sub autoEscape {
961     my($self,$escape) = self_or_default(@_);
962     $self->{'dontescape'}=!$escape;
963 }
964 END_OF_FUNC
965
966
967 #### Method: version
968 # Return the current version
969 ####
970 'version' => <<'END_OF_FUNC',
971 sub version {
972     return $VERSION;
973 }
974 END_OF_FUNC
975
976 #### Method: url_param
977 # Return a parameter in the QUERY_STRING, regardless of
978 # whether this was a POST or a GET
979 ####
980 'url_param' => <<'END_OF_FUNC',
981 sub url_param {
982     my ($self,@p) = self_or_default(@_);
983     my $name = shift(@p);
984     return undef unless exists($ENV{QUERY_STRING});
985     unless (exists($self->{'.url_param'})) {
986         $self->{'.url_param'}={}; # empty hash
987         if ($ENV{QUERY_STRING} =~ /=/) {
988             my(@pairs) = split(/[&;]/,$ENV{QUERY_STRING});
989             my($param,$value);
990             foreach (@pairs) {
991                 ($param,$value) = split('=',$_,2);
992                 $param = unescape($param);
993                 $value = unescape($value);
994                 push(@{$self->{'.url_param'}->{$param}},$value);
995             }
996         } else {
997             $self->{'.url_param'}->{'keywords'} = [$self->parse_keywordlist($ENV{QUERY_STRING})];
998         }
999     }
1000     return keys %{$self->{'.url_param'}} unless defined($name);
1001     return () unless $self->{'.url_param'}->{$name};
1002     return wantarray ? @{$self->{'.url_param'}->{$name}}
1003                      : $self->{'.url_param'}->{$name}->[0];
1004 }
1005 END_OF_FUNC
1006
1007 #### Method: Dump
1008 # Returns a string in which all the known parameter/value 
1009 # pairs are represented as nested lists, mainly for the purposes 
1010 # of debugging.
1011 ####
1012 'Dump' => <<'END_OF_FUNC',
1013 sub Dump {
1014     my($self) = self_or_default(@_);
1015     my($param,$value,@result);
1016     return '<UL></UL>' unless $self->param;
1017     push(@result,"<UL>");
1018     foreach $param ($self->param) {
1019         my($name)=$self->escapeHTML($param);
1020         push(@result,"<LI><STRONG>$param</STRONG>");
1021         push(@result,"<UL>");
1022         foreach $value ($self->param($param)) {
1023             $value = $self->escapeHTML($value);
1024             $value =~ s/\n/<BR>\n/g;
1025             push(@result,"<LI>$value");
1026         }
1027         push(@result,"</UL>");
1028     }
1029     push(@result,"</UL>\n");
1030     return join("\n",@result);
1031 }
1032 END_OF_FUNC
1033
1034 #### Method as_string
1035 #
1036 # synonym for "dump"
1037 ####
1038 'as_string' => <<'END_OF_FUNC',
1039 sub as_string {
1040     &Dump(@_);
1041 }
1042 END_OF_FUNC
1043
1044 #### Method: save
1045 # Write values out to a filehandle in such a way that they can
1046 # be reinitialized by the filehandle form of the new() method
1047 ####
1048 'save' => <<'END_OF_FUNC',
1049 sub save {
1050     my($self,$filehandle) = self_or_default(@_);
1051     $filehandle = to_filehandle($filehandle);
1052     my($param);
1053     local($,) = '';  # set print field separator back to a sane value
1054     local($\) = '';  # set output line separator to a sane value
1055     foreach $param ($self->param) {
1056         my($escaped_param) = escape($param);
1057         my($value);
1058         foreach $value ($self->param($param)) {
1059             print $filehandle "$escaped_param=",escape("$value"),"\n";
1060         }
1061     }
1062     foreach (keys %{$self->{'.fieldnames'}}) {
1063           print $filehandle ".cgifields=",escape("$_"),"\n";
1064     }
1065     print $filehandle "=\n";    # end of record
1066 }
1067 END_OF_FUNC
1068
1069
1070 #### Method: save_parameters
1071 # An alias for save() that is a better name for exportation.
1072 # Only intended to be used with the function (non-OO) interface.
1073 ####
1074 'save_parameters' => <<'END_OF_FUNC',
1075 sub save_parameters {
1076     my $fh = shift;
1077     return save(to_filehandle($fh));
1078 }
1079 END_OF_FUNC
1080
1081 #### Method: restore_parameters
1082 # A way to restore CGI parameters from an initializer.
1083 # Only intended to be used with the function (non-OO) interface.
1084 ####
1085 'restore_parameters' => <<'END_OF_FUNC',
1086 sub restore_parameters {
1087     $Q = $CGI::DefaultClass->new(@_);
1088 }
1089 END_OF_FUNC
1090
1091 #### Method: multipart_init
1092 # Return a Content-Type: style header for server-push
1093 # This has to be NPH, and it is advisable to set $| = 1
1094 #
1095 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1096 # contribution
1097 ####
1098 'multipart_init' => <<'END_OF_FUNC',
1099 sub multipart_init {
1100     my($self,@p) = self_or_default(@_);
1101     my($boundary,@other) = rearrange([BOUNDARY],@p);
1102     $boundary = $boundary || '------- =_aaaaaaaaaa0';
1103     $self->{'separator'} = "\n--$boundary\n";
1104     $type = SERVER_PUSH($boundary);
1105     return $self->header(
1106         -nph => 1,
1107         -type => $type,
1108         (map { split "=", $_, 2 } @other),
1109     ) . $self->multipart_end;
1110 }
1111 END_OF_FUNC
1112
1113
1114 #### Method: multipart_start
1115 # Return a Content-Type: style header for server-push, start of section
1116 #
1117 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1118 # contribution
1119 ####
1120 'multipart_start' => <<'END_OF_FUNC',
1121 sub multipart_start {
1122     my($self,@p) = self_or_default(@_);
1123     my($type,@other) = rearrange([TYPE],@p);
1124     $type = $type || 'text/html';
1125     return $self->header(
1126         -type => $type,
1127         (map { split "=", $_, 2 } @other),
1128     );
1129 }
1130 END_OF_FUNC
1131
1132
1133 #### Method: multipart_end
1134 # Return a Content-Type: style header for server-push, end of section
1135 #
1136 # Many thanks to Ed Jordan <ed@fidalgo.net> for this
1137 # contribution
1138 ####
1139 'multipart_end' => <<'END_OF_FUNC',
1140 sub multipart_end {
1141     my($self,@p) = self_or_default(@_);
1142     return $self->{'separator'};
1143 }
1144 END_OF_FUNC
1145
1146
1147 #### Method: header
1148 # Return a Content-Type: style header
1149 #
1150 ####
1151 'header' => <<'END_OF_FUNC',
1152 sub header {
1153     my($self,@p) = self_or_default(@_);
1154     my(@header);
1155
1156     return undef if $self->{'.header_printed'}++ and $HEADERS_ONCE;
1157
1158     my($type,$status,$cookie,$target,$expires,$nph,$charset,$attachment,@other) = 
1159         rearrange([['TYPE','CONTENT_TYPE','CONTENT-TYPE'],
1160                             'STATUS',['COOKIE','COOKIES'],'TARGET',
1161                             'EXPIRES','NPH','CHARSET',
1162                             'ATTACHMENT'],@p);
1163
1164     $nph     ||= $NPH;
1165     if (defined $charset) {
1166       $self->charset($charset);
1167     } else {
1168       $charset = $self->charset;
1169     }
1170
1171     # rearrange() was designed for the HTML portion, so we
1172     # need to fix it up a little.
1173     foreach (@other) {
1174         next unless my($header,$value) = /([^\s=]+)=\"?(.+?)\"?$/;
1175         ($_ = $header) =~ s/^(\w)(.*)/$1 . lc ($2) . ': '.$self->unescapeHTML($value)/e;
1176     }
1177
1178     $type ||= 'text/html' unless defined($type);
1179     $type .= "; charset=$charset" if $type ne '' and $type =~ m!^text/! and $type !~ /\bcharset\b/;
1180
1181     # Maybe future compatibility.  Maybe not.
1182     my $protocol = $ENV{SERVER_PROTOCOL} || 'HTTP/1.0';
1183     push(@header,$protocol . ' ' . ($status || '200 OK')) if $nph;
1184
1185     push(@header,"Status: $status") if $status;
1186     push(@header,"Window-Target: $target") if $target;
1187     # push all the cookies -- there may be several
1188     if ($cookie) {
1189         my(@cookie) = ref($cookie) && ref($cookie) eq 'ARRAY' ? @{$cookie} : $cookie;
1190         foreach (@cookie) {
1191             my $cs = UNIVERSAL::isa($_,'CGI::Cookie') ? $_->as_string : $_;
1192             push(@header,"Set-Cookie: $cs") if $cs ne '';
1193         }
1194     }
1195     # if the user indicates an expiration time, then we need
1196     # both an Expires and a Date header (so that the browser is
1197     # uses OUR clock)
1198     push(@header,"Expires: " . expires($expires,'http'))
1199         if $expires;
1200     push(@header,"Date: " . expires(0,'http')) if $expires || $cookie;
1201     push(@header,"Pragma: no-cache") if $self->cache();
1202     push(@header,"Content-Disposition: attachment; filename=\"$attachment\"") if $attachment;
1203     push(@header,@other);
1204     push(@header,"Content-Type: $type") if $type ne '';
1205
1206     my $header = join($CRLF,@header)."${CRLF}${CRLF}";
1207     if ($MOD_PERL and not $nph) {
1208         my $r = Apache->request;
1209         $r->send_cgi_header($header);
1210         return '';
1211     }
1212     return $header;
1213 }
1214 END_OF_FUNC
1215
1216
1217 #### Method: cache
1218 # Control whether header() will produce the no-cache
1219 # Pragma directive.
1220 ####
1221 'cache' => <<'END_OF_FUNC',
1222 sub cache {
1223     my($self,$new_value) = self_or_default(@_);
1224     $new_value = '' unless $new_value;
1225     if ($new_value ne '') {
1226         $self->{'cache'} = $new_value;
1227     }
1228     return $self->{'cache'};
1229 }
1230 END_OF_FUNC
1231
1232
1233 #### Method: redirect
1234 # Return a Location: style header
1235 #
1236 ####
1237 'redirect' => <<'END_OF_FUNC',
1238 sub redirect {
1239     my($self,@p) = self_or_default(@_);
1240     my($url,$target,$cookie,$nph,@other) = rearrange([[LOCATION,URI,URL],TARGET,COOKIE,NPH],@p);
1241     $url ||= $self->self_url;
1242     my(@o);
1243     foreach (@other) { tr/\"//d; push(@o,split("=",$_,2)); }
1244     unshift(@o,
1245          '-Status'=>'302 Moved',
1246          '-Location'=>$url,
1247          '-nph'=>$nph);
1248     unshift(@o,'-Target'=>$target) if $target;
1249     unshift(@o,'-Cookie'=>$cookie) if $cookie;
1250     unshift(@o,'-Type'=>'');
1251     return $self->header(@o);
1252 }
1253 END_OF_FUNC
1254
1255
1256 #### Method: start_html
1257 # Canned HTML header
1258 #
1259 # Parameters:
1260 # $title -> (optional) The title for this HTML document (-title)
1261 # $author -> (optional) e-mail address of the author (-author)
1262 # $base -> (optional) if set to true, will enter the BASE address of this document
1263 #          for resolving relative references (-base) 
1264 # $xbase -> (optional) alternative base at some remote location (-xbase)
1265 # $target -> (optional) target window to load all links into (-target)
1266 # $script -> (option) Javascript code (-script)
1267 # $no_script -> (option) Javascript <noscript> tag (-noscript)
1268 # $meta -> (optional) Meta information tags
1269 # $head -> (optional) any other elements you'd like to incorporate into the <HEAD> tag
1270 #           (a scalar or array ref)
1271 # $style -> (optional) reference to an external style sheet
1272 # @other -> (optional) any other named parameters you'd like to incorporate into
1273 #           the <BODY> tag.
1274 ####
1275 'start_html' => <<'END_OF_FUNC',
1276 sub start_html {
1277     my($self,@p) = &self_or_default(@_);
1278     my($title,$author,$base,$xbase,$script,$noscript,$target,$meta,$head,$style,$dtd,$lang,@other) = 
1279         rearrange([TITLE,AUTHOR,BASE,XBASE,SCRIPT,NOSCRIPT,TARGET,META,HEAD,STYLE,DTD,LANG],@p);
1280
1281     # strangely enough, the title needs to be escaped as HTML
1282     # while the author needs to be escaped as a URL
1283     $title = $self->escapeHTML($title || 'Untitled Document');
1284     $author = $self->escape($author);
1285     $lang ||= 'en-US';
1286     my(@result);
1287     if ($dtd) {
1288         if (defined(ref($dtd)) and (ref($dtd) eq 'ARRAY')) {
1289             $dtd = $DEFAULT_DTD unless $dtd->[0] =~ m|^-//|;
1290         } else {
1291             $dtd = $DEFAULT_DTD unless $dtd =~ m|^-//|;
1292         }
1293     } else {
1294         $dtd = $XHTML ? XHTML_DTD : $DEFAULT_DTD;
1295     }
1296     if (ref($dtd) && ref($dtd) eq 'ARRAY') {
1297         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd->[0]"\n\t"$dtd->[1]">));
1298     } else {
1299         push(@result,qq(<!DOCTYPE html\n\tPUBLIC "$dtd">));
1300     }
1301     push(@result,$XHTML ? qq(<html xmlns="http://www.w3.org/1999/xhtml" lang="$lang"><head><title>$title</title>)
1302                         : qq(<html lang="$lang"><head><title>$title</title>));
1303         if (defined $author) {
1304     push(@result,$XHTML ? "<link rev=\"made\" href=\"mailto:$author\" />"
1305                                                                 : "<link rev=\"made\" href=\"mailto:$author\">");
1306         }
1307
1308     if ($base || $xbase || $target) {
1309         my $href = $xbase || $self->url('-path'=>1);
1310         my $t = $target ? qq/ target="$target"/ : '';
1311         push(@result,$XHTML ? qq(<base href="$href"$t />) : qq(<base href="$href"$t>));
1312     }
1313
1314     if ($meta && ref($meta) && (ref($meta) eq 'HASH')) {
1315         foreach (keys %$meta) { push(@result,$XHTML ? qq(<meta name="$_" content="$meta->{$_}" />) 
1316                         : qq(<meta name="$_" content="$meta->{$_}">)); }
1317     }
1318
1319     push(@result,ref($head) ? @$head : $head) if $head;
1320
1321     # handle the infrequently-used -style and -script parameters
1322     push(@result,$self->_style($style)) if defined $style;
1323     push(@result,$self->_script($script)) if defined $script;
1324
1325     # handle -noscript parameter
1326     push(@result,<<END) if $noscript;
1327 <noscript>
1328 $noscript
1329 </noscript>
1330 END
1331     ;
1332     my($other) = @other ? " @other" : '';
1333     push(@result,"</head><body$other>");
1334     return join("\n",@result);
1335 }
1336 END_OF_FUNC
1337
1338 ### Method: _style
1339 # internal method for generating a CSS style section
1340 ####
1341 '_style' => <<'END_OF_FUNC',
1342 sub _style {
1343     my ($self,$style) = @_;
1344     my (@result);
1345     my $type = 'text/css';
1346
1347     my $cdata_start = $XHTML ? "\n<!--/* <![CDATA[ */" : "\n<!-- ";
1348     my $cdata_end   = $XHTML ? "\n/* ]]> */-->\n" : " -->\n";
1349
1350     if (ref($style)) {
1351      my($src,$code,$stype,@other) =
1352          rearrange([SRC,CODE,TYPE],
1353                     '-foo'=>'bar', # a trick to allow the '-' to be omitted
1354                     ref($style) eq 'ARRAY' ? @$style : %$style);
1355      $type = $stype if $stype;
1356      if (ref($src) eq "ARRAY") # Check to see if the $src variable is an array reference
1357      { # If it is, push a LINK tag for each one.
1358        foreach $src (@$src)
1359        {
1360          push(@result,qq/<link rel="stylesheet" type="$type" href="$src">/) if $src;
1361        }
1362      }
1363      else
1364      { # Otherwise, push the single -src, if it exists.
1365        push(@result,qq/<link rel="stylesheet" type="$type" href="$src">/) if $src;
1366       }
1367      push(@result,style({'type'=>$type},"$cdata_start\n$code\n$cdata_end")) if $code;
1368     } else {
1369      push(@result,style({'type'=>$type},"$cdata_start\n$style\n$cdata_end"));
1370     }
1371     @result;
1372 }
1373 END_OF_FUNC
1374
1375 '_script' => <<'END_OF_FUNC',
1376 sub _script {
1377     my ($self,$script) = @_;
1378     my (@result);
1379
1380     my (@scripts) = ref($script) eq 'ARRAY' ? @$script : ($script);
1381     foreach $script (@scripts) {
1382         my($src,$code,$language);
1383         if (ref($script)) { # script is a hash
1384             ($src,$code,$language, $type) =
1385                 rearrange([SRC,CODE,LANGUAGE,TYPE],
1386                                  '-foo'=>'bar', # a trick to allow the '-' to be omitted
1387                                  ref($script) eq 'ARRAY' ? @$script : %$script);
1388             # User may not have specified language
1389             $language ||= 'JavaScript';
1390             unless (defined $type) {
1391                 $type = lc $language;
1392                 # strip '1.2' from 'javascript1.2'
1393                 $type =~ s/^(\D+).*$/text\/$1/;
1394             }
1395         } else {
1396             ($src,$code,$language, $type) = ('',$script,'JavaScript', 'text/javascript');
1397         }
1398
1399     my $comment = '//';  # javascript by default
1400     $comment = '#' if $type=~/perl|tcl/i;
1401     $comment = "'" if $type=~/vbscript/i;
1402
1403     my $cdata_start  =  "\n<!-- Hide script\n";
1404     $cdata_start    .= "$comment<![CDATA[\n"  if $XHTML; 
1405     my $cdata_end    = $XHTML ? "\n$comment]]>" : $comment;
1406     $cdata_end      .= " End script hiding -->\n";
1407
1408         my(@satts);
1409         push(@satts,'src'=>$src) if $src;
1410         push(@satts,'language'=>$language);
1411         push(@satts,'type'=>$type);
1412         $code = "$cdata_start$code$cdata_end";
1413         push(@result,script({@satts},$code || ''));
1414     }
1415     @result;
1416 }
1417 END_OF_FUNC
1418
1419 #### Method: end_html
1420 # End an HTML document.
1421 # Trivial method for completeness.  Just returns "</BODY>"
1422 ####
1423 'end_html' => <<'END_OF_FUNC',
1424 sub end_html {
1425     return "</body></html>";
1426 }
1427 END_OF_FUNC
1428
1429
1430 ################################
1431 # METHODS USED IN BUILDING FORMS
1432 ################################
1433
1434 #### Method: isindex
1435 # Just prints out the isindex tag.
1436 # Parameters:
1437 #  $action -> optional URL of script to run
1438 # Returns:
1439 #   A string containing a <ISINDEX> tag
1440 'isindex' => <<'END_OF_FUNC',
1441 sub isindex {
1442     my($self,@p) = self_or_default(@_);
1443     my($action,@other) = rearrange([ACTION],@p);
1444     $action = qq/action="$action"/ if $action;
1445     my($other) = @other ? " @other" : '';
1446     return $XHTML ? "<isindex $action$other />" : "<isindex $action$other>";
1447 }
1448 END_OF_FUNC
1449
1450
1451 #### Method: startform
1452 # Start a form
1453 # Parameters:
1454 #   $method -> optional submission method to use (GET or POST)
1455 #   $action -> optional URL of script to run
1456 #   $enctype ->encoding to use (URL_ENCODED or MULTIPART)
1457 'startform' => <<'END_OF_FUNC',
1458 sub startform {
1459     my($self,@p) = self_or_default(@_);
1460
1461     my($method,$action,$enctype,@other) = 
1462         rearrange([METHOD,ACTION,ENCTYPE],@p);
1463
1464     $method = lc($method) || 'post';
1465     $enctype = $enctype || &URL_ENCODED;
1466     unless (defined $action) {
1467        $action = $self->url(-absolute=>1,-path=>1);
1468        $action .= "?$ENV{QUERY_STRING}" if $ENV{QUERY_STRING};
1469     }
1470     $action = qq(action="$action");
1471     my($other) = @other ? " @other" : '';
1472     $self->{'.parametersToAdd'}={};
1473     return qq/<form method="$method" $action enctype="$enctype"$other>\n/;
1474 }
1475 END_OF_FUNC
1476
1477
1478 #### Method: start_form
1479 # synonym for startform
1480 'start_form' => <<'END_OF_FUNC',
1481 sub start_form {
1482     &startform;
1483 }
1484 END_OF_FUNC
1485
1486 'end_multipart_form' => <<'END_OF_FUNC',
1487 sub end_multipart_form {
1488     &endform;
1489 }
1490 END_OF_FUNC
1491
1492 #### Method: start_multipart_form
1493 # synonym for startform
1494 'start_multipart_form' => <<'END_OF_FUNC',
1495 sub start_multipart_form {
1496     my($self,@p) = self_or_default(@_);
1497     if (defined($param[0]) && substr($param[0],0,1) eq '-') {
1498         my(%p) = @p;
1499         $p{'-enctype'}=&MULTIPART;
1500         return $self->startform(%p);
1501     } else {
1502         my($method,$action,@other) = 
1503             rearrange([METHOD,ACTION],@p);
1504         return $self->startform($method,$action,&MULTIPART,@other);
1505     }
1506 }
1507 END_OF_FUNC
1508
1509
1510 #### Method: endform
1511 # End a form
1512 'endform' => <<'END_OF_FUNC',
1513 sub endform {
1514     my($self,@p) = self_or_default(@_);    
1515     if ( $NOSTICKY ) {
1516     return wantarray ? ("</form>") : "\n</form>";
1517     } else {
1518     return wantarray ? ($self->get_fields,"</form>") : 
1519                         $self->get_fields ."\n</form>";
1520     }
1521 }
1522 END_OF_FUNC
1523
1524
1525 #### Method: end_form
1526 # synonym for endform
1527 'end_form' => <<'END_OF_FUNC',
1528 sub end_form {
1529     &endform;
1530 }
1531 END_OF_FUNC
1532
1533
1534 '_textfield' => <<'END_OF_FUNC',
1535 sub _textfield {
1536     my($self,$tag,@p) = self_or_default(@_);
1537     my($name,$default,$size,$maxlength,$override,@other) = 
1538         rearrange([NAME,[DEFAULT,VALUE],SIZE,MAXLENGTH,[OVERRIDE,FORCE]],@p);
1539
1540     my $current = $override ? $default : 
1541         (defined($self->param($name)) ? $self->param($name) : $default);
1542
1543     $current = defined($current) ? $self->escapeHTML($current,1) : '';
1544     $name = defined($name) ? $self->escapeHTML($name) : '';
1545     my($s) = defined($size) ? qq/ size=$size/ : '';
1546     my($m) = defined($maxlength) ? qq/ maxlength=$maxlength/ : '';
1547     my($other) = @other ? " @other" : '';
1548     # this entered at cristy's request to fix problems with file upload fields
1549     # and WebTV -- not sure it won't break stuff
1550     my($value) = $current ne '' ? qq(value="$current") : '';
1551     return $XHTML ? qq(<input type="$tag" name="$name" $value$s$m$other />) 
1552                   : qq/<input type="$tag" name="$name" $value$s$m$other>/;
1553 }
1554 END_OF_FUNC
1555
1556 #### Method: textfield
1557 # Parameters:
1558 #   $name -> Name of the text field
1559 #   $default -> Optional default value of the field if not
1560 #                already defined.
1561 #   $size ->  Optional width of field in characaters.
1562 #   $maxlength -> Optional maximum number of characters.
1563 # Returns:
1564 #   A string containing a <INPUT TYPE="text"> field
1565 #
1566 'textfield' => <<'END_OF_FUNC',
1567 sub textfield {
1568     my($self,@p) = self_or_default(@_);
1569     $self->_textfield('text',@p);
1570 }
1571 END_OF_FUNC
1572
1573
1574 #### Method: filefield
1575 # Parameters:
1576 #   $name -> Name of the file upload field
1577 #   $size ->  Optional width of field in characaters.
1578 #   $maxlength -> Optional maximum number of characters.
1579 # Returns:
1580 #   A string containing a <INPUT TYPE="text"> field
1581 #
1582 'filefield' => <<'END_OF_FUNC',
1583 sub filefield {
1584     my($self,@p) = self_or_default(@_);
1585     $self->_textfield('file',@p);
1586 }
1587 END_OF_FUNC
1588
1589
1590 #### Method: password
1591 # Create a "secret password" entry field
1592 # Parameters:
1593 #   $name -> Name of the field
1594 #   $default -> Optional default value of the field if not
1595 #                already defined.
1596 #   $size ->  Optional width of field in characters.
1597 #   $maxlength -> Optional maximum characters that can be entered.
1598 # Returns:
1599 #   A string containing a <INPUT TYPE="password"> field
1600 #
1601 'password_field' => <<'END_OF_FUNC',
1602 sub password_field {
1603     my ($self,@p) = self_or_default(@_);
1604     $self->_textfield('password',@p);
1605 }
1606 END_OF_FUNC
1607
1608 #### Method: textarea
1609 # Parameters:
1610 #   $name -> Name of the text field
1611 #   $default -> Optional default value of the field if not
1612 #                already defined.
1613 #   $rows ->  Optional number of rows in text area
1614 #   $columns -> Optional number of columns in text area
1615 # Returns:
1616 #   A string containing a <TEXTAREA></TEXTAREA> tag
1617 #
1618 'textarea' => <<'END_OF_FUNC',
1619 sub textarea {
1620     my($self,@p) = self_or_default(@_);
1621     
1622     my($name,$default,$rows,$cols,$override,@other) =
1623         rearrange([NAME,[DEFAULT,VALUE],ROWS,[COLS,COLUMNS],[OVERRIDE,FORCE]],@p);
1624
1625     my($current)= $override ? $default :
1626         (defined($self->param($name)) ? $self->param($name) : $default);
1627
1628     $name = defined($name) ? $self->escapeHTML($name) : '';
1629     $current = defined($current) ? $self->escapeHTML($current) : '';
1630     my($r) = $rows ? " rows=$rows" : '';
1631     my($c) = $cols ? " cols=$cols" : '';
1632     my($other) = @other ? " @other" : '';
1633     return qq{<textarea name="$name"$r$c$other>$current</textarea>};
1634 }
1635 END_OF_FUNC
1636
1637
1638 #### Method: button
1639 # Create a javascript button.
1640 # Parameters:
1641 #   $name ->  (optional) Name for the button. (-name)
1642 #   $value -> (optional) Value of the button when selected (and visible name) (-value)
1643 #   $onclick -> (optional) Text of the JavaScript to run when the button is
1644 #                clicked.
1645 # Returns:
1646 #   A string containing a <INPUT TYPE="button"> tag
1647 ####
1648 'button' => <<'END_OF_FUNC',
1649 sub button {
1650     my($self,@p) = self_or_default(@_);
1651
1652     my($label,$value,$script,@other) = rearrange([NAME,[VALUE,LABEL],
1653                                                          [ONCLICK,SCRIPT]],@p);
1654
1655     $label=$self->escapeHTML($label);
1656     $value=$self->escapeHTML($value,1);
1657     $script=$self->escapeHTML($script);
1658
1659     my($name) = '';
1660     $name = qq/ NAME="$label"/ if $label;
1661     $value = $value || $label;
1662     my($val) = '';
1663     $val = qq/ value="$value"/ if $value;
1664     $script = qq/ onclick="$script"/ if $script;
1665     my($other) = @other ? " @other" : '';
1666     return $XHTML ? qq(<input type="button"$name$val$script$other />)
1667                   : qq/<input type="button"$name$val$script$other>/;
1668 }
1669 END_OF_FUNC
1670
1671
1672 #### Method: submit
1673 # Create a "submit query" button.
1674 # Parameters:
1675 #   $name ->  (optional) Name for the button.
1676 #   $value -> (optional) Value of the button when selected (also doubles as label).
1677 #   $label -> (optional) Label printed on the button(also doubles as the value).
1678 # Returns:
1679 #   A string containing a <INPUT TYPE="submit"> tag
1680 ####
1681 'submit' => <<'END_OF_FUNC',
1682 sub submit {
1683     my($self,@p) = self_or_default(@_);
1684
1685     my($label,$value,@other) = rearrange([NAME,[VALUE,LABEL]],@p);
1686
1687     $label=$self->escapeHTML($label);
1688     $value=$self->escapeHTML($value,1);
1689
1690     my($name) = ' name=".submit"' unless $NOSTICKY;
1691     $name = qq/ name="$label"/ if defined($label);
1692     $value = defined($value) ? $value : $label;
1693     my($val) = '';
1694     $val = qq/ value="$value"/ if defined($value);
1695     my($other) = @other ? " @other" : '';
1696     return $XHTML ? qq(<input type="submit"$name$val$other />)
1697                   : qq/<input type="submit"$name$val$other>/;
1698 }
1699 END_OF_FUNC
1700
1701
1702 #### Method: reset
1703 # Create a "reset" button.
1704 # Parameters:
1705 #   $name -> (optional) Name for the button.
1706 # Returns:
1707 #   A string containing a <INPUT TYPE="reset"> tag
1708 ####
1709 'reset' => <<'END_OF_FUNC',
1710 sub reset {
1711     my($self,@p) = self_or_default(@_);
1712     my($label,@other) = rearrange([NAME],@p);
1713     $label=$self->escapeHTML($label);
1714     my($value) = defined($label) ? qq/ value="$label"/ : '';
1715     my($other) = @other ? " @other" : '';
1716     return $XHTML ? qq(<input type="reset"$value$other />)
1717                   : qq/<input type="reset"$value$other>/;
1718 }
1719 END_OF_FUNC
1720
1721
1722 #### Method: defaults
1723 # Create a "defaults" button.
1724 # Parameters:
1725 #   $name -> (optional) Name for the button.
1726 # Returns:
1727 #   A string containing a <INPUT TYPE="submit" NAME=".defaults"> tag
1728 #
1729 # Note: this button has a special meaning to the initialization script,
1730 # and tells it to ERASE the current query string so that your defaults
1731 # are used again!
1732 ####
1733 'defaults' => <<'END_OF_FUNC',
1734 sub defaults {
1735     my($self,@p) = self_or_default(@_);
1736
1737     my($label,@other) = rearrange([[NAME,VALUE]],@p);
1738
1739     $label=$self->escapeHTML($label,1);
1740     $label = $label || "Defaults";
1741     my($value) = qq/ value="$label"/;
1742     my($other) = @other ? " @other" : '';
1743     return $XHTML ? qq(<input type="submit" name=".defaults"$value$other />)
1744                   : qq/<input type="submit" NAME=".defaults"$value$other>/;
1745 }
1746 END_OF_FUNC
1747
1748
1749 #### Method: comment
1750 # Create an HTML <!-- comment -->
1751 # Parameters: a string
1752 'comment' => <<'END_OF_FUNC',
1753 sub comment {
1754     my($self,@p) = self_or_CGI(@_);
1755     return "<!-- @p -->";
1756 }
1757 END_OF_FUNC
1758
1759 #### Method: checkbox
1760 # Create a checkbox that is not logically linked to any others.
1761 # The field value is "on" when the button is checked.
1762 # Parameters:
1763 #   $name -> Name of the checkbox
1764 #   $checked -> (optional) turned on by default if true
1765 #   $value -> (optional) value of the checkbox, 'on' by default
1766 #   $label -> (optional) a user-readable label printed next to the box.
1767 #             Otherwise the checkbox name is used.
1768 # Returns:
1769 #   A string containing a <INPUT TYPE="checkbox"> field
1770 ####
1771 'checkbox' => <<'END_OF_FUNC',
1772 sub checkbox {
1773     my($self,@p) = self_or_default(@_);
1774
1775     my($name,$checked,$value,$label,$override,@other) = 
1776         rearrange([NAME,[CHECKED,SELECTED,ON],VALUE,LABEL,[OVERRIDE,FORCE]],@p);
1777     
1778     $value = defined $value ? $value : 'on';
1779
1780     if (!$override && ($self->{'.fieldnames'}->{$name} || 
1781                        defined $self->param($name))) {
1782         $checked = grep($_ eq $value,$self->param($name)) ? ' checked' : '';
1783     } else {
1784         $checked = $checked ? qq/ checked/ : '';
1785     }
1786     my($the_label) = defined $label ? $label : $name;
1787     $name = $self->escapeHTML($name);
1788     $value = $self->escapeHTML($value,1);
1789     $the_label = $self->escapeHTML($the_label);
1790     my($other) = @other ? " @other" : '';
1791     $self->register_parameter($name);
1792     return $XHTML ? qq{<input type="checkbox" name="$name" value="$value"$checked$other />$the_label}
1793                   : qq{<input type="checkbox" name="$name" value="$value"$checked$other>$the_label};
1794 }
1795 END_OF_FUNC
1796
1797
1798 #### Method: checkbox_group
1799 # Create a list of logically-linked checkboxes.
1800 # Parameters:
1801 #   $name -> Common name for all the check boxes
1802 #   $values -> A pointer to a regular array containing the
1803 #             values for each checkbox in the group.
1804 #   $defaults -> (optional)
1805 #             1. If a pointer to a regular array of checkbox values,
1806 #             then this will be used to decide which
1807 #             checkboxes to turn on by default.
1808 #             2. If a scalar, will be assumed to hold the
1809 #             value of a single checkbox in the group to turn on. 
1810 #   $linebreak -> (optional) Set to true to place linebreaks
1811 #             between the buttons.
1812 #   $labels -> (optional)
1813 #             A pointer to an associative array of labels to print next to each checkbox
1814 #             in the form $label{'value'}="Long explanatory label".
1815 #             Otherwise the provided values are used as the labels.
1816 # Returns:
1817 #   An ARRAY containing a series of <INPUT TYPE="checkbox"> fields
1818 ####
1819 'checkbox_group' => <<'END_OF_FUNC',
1820 sub checkbox_group {
1821     my($self,@p) = self_or_default(@_);
1822
1823     my($name,$values,$defaults,$linebreak,$labels,$rows,$columns,
1824        $rowheaders,$colheaders,$override,$nolabels,@other) =
1825         rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
1826                           LINEBREAK,LABELS,ROWS,[COLUMNS,COLS],
1827                           ROWHEADERS,COLHEADERS,
1828                           [OVERRIDE,FORCE],NOLABELS],@p);
1829
1830     my($checked,$break,$result,$label);
1831
1832     my(%checked) = $self->previous_or_default($name,$defaults,$override);
1833
1834         if ($linebreak) {
1835     $break = $XHTML ? "<br />" : "<br>";
1836         }
1837         else {
1838         $break = '';
1839         }
1840     $name=$self->escapeHTML($name);
1841
1842     # Create the elements
1843     my(@elements,@values);
1844
1845     @values = $self->_set_values_and_labels($values,\$labels,$name);
1846
1847     my($other) = @other ? " @other" : '';
1848     foreach (@values) {
1849         $checked = $checked{$_} ? qq/ checked/ : '';
1850         $label = '';
1851         unless (defined($nolabels) && $nolabels) {
1852             $label = $_;
1853             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
1854             $label = $self->escapeHTML($label);
1855         }
1856         $_ = $self->escapeHTML($_,1);
1857         push(@elements,$XHTML ? qq(<input type="checkbox" name="$name" value="$_"$checked$other />${label}${break})
1858                               : qq/<input type="checkbox" name="$name" value="$_"$checked$other>${label}${break}/);
1859     }
1860     $self->register_parameter($name);
1861     return wantarray ? @elements : join(' ',@elements)            
1862         unless defined($columns) || defined($rows);
1863     return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
1864 }
1865 END_OF_FUNC
1866
1867 # Escape HTML -- used internally
1868 'escapeHTML' => <<'END_OF_FUNC',
1869 sub escapeHTML {
1870          my ($self,$toencode,$newlinestoo) = CGI::self_or_default(@_);
1871          return undef unless defined($toencode);
1872          return $toencode if ref($self) && $self->{'dontescape'};
1873          $toencode =~ s{&}{&amp;}gso;
1874          $toencode =~ s{<}{&lt;}gso;
1875          $toencode =~ s{>}{&gt;}gso;
1876          $toencode =~ s{"}{&quot;}gso;
1877          my $latin = uc $self->{'.charset'} eq 'ISO-8859-1' ||
1878                      uc $self->{'.charset'} eq 'WINDOWS-1252';
1879          if ($latin) {  # bug in some browsers
1880                 $toencode =~ s{\x8b}{&#139;}gso;
1881                 $toencode =~ s{\x9b}{&#155;}gso;
1882                 if (defined $newlinestoo && $newlinestoo) {
1883                      $toencode =~ s{\012}{&#10;}gso;
1884                      $toencode =~ s{\015}{&#13;}gso;
1885                 }
1886          }
1887          return $toencode;
1888 }
1889 END_OF_FUNC
1890
1891 # unescape HTML -- used internally
1892 'unescapeHTML' => <<'END_OF_FUNC',
1893 sub unescapeHTML {
1894     my ($self,$string) = CGI::self_or_default(@_);
1895     return undef unless defined($string);
1896     my $latin = defined $self->{'.charset'} ? $self->{'.charset'} =~ /^(ISO-8859-1|WINDOWS-1252)$/i
1897                                             : 1;
1898     # thanks to Randal Schwartz for the correct solution to this one
1899     $string=~ s[&(.*?);]{
1900         local $_ = $1;
1901         /^amp$/i        ? "&" :
1902         /^quot$/i       ? '"' :
1903         /^gt$/i         ? ">" :
1904         /^lt$/i         ? "<" :
1905         /^#(\d+)$/ && $latin         ? chr($1) :
1906         /^#x([0-9a-f]+)$/i && $latin ? chr(hex($1)) :
1907         $_
1908         }gex;
1909     return $string;
1910 }
1911 END_OF_FUNC
1912
1913 # Internal procedure - don't use
1914 '_tableize' => <<'END_OF_FUNC',
1915 sub _tableize {
1916     my($rows,$columns,$rowheaders,$colheaders,@elements) = @_;
1917     $rowheaders = [] unless defined $rowheaders;
1918     $colheaders = [] unless defined $colheaders;
1919     my($result);
1920
1921     if (defined($columns)) {
1922         $rows = int(0.99 + @elements/$columns) unless defined($rows);
1923     }
1924     if (defined($rows)) {
1925         $columns = int(0.99 + @elements/$rows) unless defined($columns);
1926     }
1927     
1928     # rearrange into a pretty table
1929     $result = "<table>";
1930     my($row,$column);
1931     unshift(@$colheaders,'') if @$colheaders && @$rowheaders;
1932     $result .= "<tr>" if @{$colheaders};
1933     foreach (@{$colheaders}) {
1934         $result .= "<th>$_</th>";
1935     }
1936     for ($row=0;$row<$rows;$row++) {
1937         $result .= "<tr>";
1938         $result .= "<th>$rowheaders->[$row]</th>" if @$rowheaders;
1939         for ($column=0;$column<$columns;$column++) {
1940             $result .= "<td>" . $elements[$column*$rows + $row] . "</td>"
1941                 if defined($elements[$column*$rows + $row]);
1942         }
1943         $result .= "</tr>";
1944     }
1945     $result .= "</table>";
1946     return $result;
1947 }
1948 END_OF_FUNC
1949
1950
1951 #### Method: radio_group
1952 # Create a list of logically-linked radio buttons.
1953 # Parameters:
1954 #   $name -> Common name for all the buttons.
1955 #   $values -> A pointer to a regular array containing the
1956 #             values for each button in the group.
1957 #   $default -> (optional) Value of the button to turn on by default.  Pass '-'
1958 #               to turn _nothing_ on.
1959 #   $linebreak -> (optional) Set to true to place linebreaks
1960 #             between the buttons.
1961 #   $labels -> (optional)
1962 #             A pointer to an associative array of labels to print next to each checkbox
1963 #             in the form $label{'value'}="Long explanatory label".
1964 #             Otherwise the provided values are used as the labels.
1965 # Returns:
1966 #   An ARRAY containing a series of <INPUT TYPE="radio"> fields
1967 ####
1968 'radio_group' => <<'END_OF_FUNC',
1969 sub radio_group {
1970     my($self,@p) = self_or_default(@_);
1971
1972     my($name,$values,$default,$linebreak,$labels,
1973        $rows,$columns,$rowheaders,$colheaders,$override,$nolabels,@other) =
1974         rearrange([NAME,[VALUES,VALUE],DEFAULT,LINEBREAK,LABELS,
1975                           ROWS,[COLUMNS,COLS],
1976                           ROWHEADERS,COLHEADERS,
1977                           [OVERRIDE,FORCE],NOLABELS],@p);
1978     my($result,$checked);
1979
1980     if (!$override && defined($self->param($name))) {
1981         $checked = $self->param($name);
1982     } else {
1983         $checked = $default;
1984     }
1985     my(@elements,@values);
1986     @values = $self->_set_values_and_labels($values,\$labels,$name);
1987
1988     # If no check array is specified, check the first by default
1989     $checked = $values[0] unless defined($checked) && $checked ne '';
1990     $name=$self->escapeHTML($name);
1991
1992     my($other) = @other ? " @other" : '';
1993     foreach (@values) {
1994         my($checkit) = $checked eq $_ ? qq/ checked/ : '';
1995         my($break);
1996         if ($linebreak) {
1997     $break = $XHTML ? "<br />" : "<br>";
1998         }
1999         else {
2000         $break = '';
2001         }
2002         my($label)='';
2003         unless (defined($nolabels) && $nolabels) {
2004             $label = $_;
2005             $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2006             $label = $self->escapeHTML($label,1);
2007         }
2008         $_=$self->escapeHTML($_);
2009         push(@elements,$XHTML ? qq(<input type="radio" name="$name" value="$_"$checkit$other />${label}${break})
2010                               : qq/<input type="radio" name="$name" value="$_"$checkit$other>${label}${break}/);
2011     }
2012     $self->register_parameter($name);
2013     return wantarray ? @elements : join(' ',@elements) 
2014            unless defined($columns) || defined($rows);
2015     return _tableize($rows,$columns,$rowheaders,$colheaders,@elements);
2016 }
2017 END_OF_FUNC
2018
2019
2020 #### Method: popup_menu
2021 # Create a popup menu.
2022 # Parameters:
2023 #   $name -> Name for all the menu
2024 #   $values -> A pointer to a regular array containing the
2025 #             text of each menu item.
2026 #   $default -> (optional) Default item to display
2027 #   $labels -> (optional)
2028 #             A pointer to an associative array of labels to print next to each checkbox
2029 #             in the form $label{'value'}="Long explanatory label".
2030 #             Otherwise the provided values are used as the labels.
2031 # Returns:
2032 #   A string containing the definition of a popup menu.
2033 ####
2034 'popup_menu' => <<'END_OF_FUNC',
2035 sub popup_menu {
2036     my($self,@p) = self_or_default(@_);
2037
2038     my($name,$values,$default,$labels,$override,@other) =
2039         rearrange([NAME,[VALUES,VALUE],[DEFAULT,DEFAULTS],LABELS,[OVERRIDE,FORCE]],@p);
2040     my($result,$selected);
2041
2042     if (!$override && defined($self->param($name))) {
2043         $selected = $self->param($name);
2044     } else {
2045         $selected = $default;
2046     }
2047     $name=$self->escapeHTML($name);
2048     my($other) = @other ? " @other" : '';
2049
2050     my(@values);
2051     @values = $self->_set_values_and_labels($values,\$labels,$name);
2052
2053     $result = qq/<select name="$name"$other>\n/;
2054     foreach (@values) {
2055         my($selectit) = defined($selected) ? ($selected eq $_ ? qq/selected/ : '' ) : '';
2056         my($label) = $_;
2057         $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2058         my($value) = $self->escapeHTML($_);
2059         $label=$self->escapeHTML($label,1);
2060         $result .= "<option $selectit value=\"$value\">$label</option>\n";
2061     }
2062
2063     $result .= "</select>\n";
2064     return $result;
2065 }
2066 END_OF_FUNC
2067
2068
2069 #### Method: scrolling_list
2070 # Create a scrolling list.
2071 # Parameters:
2072 #   $name -> name for the list
2073 #   $values -> A pointer to a regular array containing the
2074 #             values for each option line in the list.
2075 #   $defaults -> (optional)
2076 #             1. If a pointer to a regular array of options,
2077 #             then this will be used to decide which
2078 #             lines to turn on by default.
2079 #             2. Otherwise holds the value of the single line to turn on.
2080 #   $size -> (optional) Size of the list.
2081 #   $multiple -> (optional) If set, allow multiple selections.
2082 #   $labels -> (optional)
2083 #             A pointer to an associative array of labels to print next to each checkbox
2084 #             in the form $label{'value'}="Long explanatory label".
2085 #             Otherwise the provided values are used as the labels.
2086 # Returns:
2087 #   A string containing the definition of a scrolling list.
2088 ####
2089 'scrolling_list' => <<'END_OF_FUNC',
2090 sub scrolling_list {
2091     my($self,@p) = self_or_default(@_);
2092     my($name,$values,$defaults,$size,$multiple,$labels,$override,@other)
2093         = rearrange([NAME,[VALUES,VALUE],[DEFAULTS,DEFAULT],
2094                             SIZE,MULTIPLE,LABELS,[OVERRIDE,FORCE]],@p);
2095
2096     my($result,@values);
2097     @values = $self->_set_values_and_labels($values,\$labels,$name);
2098
2099     $size = $size || scalar(@values);
2100
2101     my(%selected) = $self->previous_or_default($name,$defaults,$override);
2102     my($is_multiple) = $multiple ? qq/ multiple/ : '';
2103     my($has_size) = $size ? qq/ size="$size"/: '';
2104     my($other) = @other ? " @other" : '';
2105
2106     $name=$self->escapeHTML($name);
2107     $result = qq/<select name="$name"$has_size$is_multiple$other>\n/;
2108     foreach (@values) {
2109         my($selectit) = $selected{$_} ? qq/selected/ : '';
2110         my($label) = $_;
2111         $label = $labels->{$_} if defined($labels) && defined($labels->{$_});
2112         $label=$self->escapeHTML($label);
2113         my($value)=$self->escapeHTML($_,1);
2114         $result .= "<option $selectit value=\"$value\">$label</option>\n";
2115     }
2116     $result .= "</select>\n";
2117     $self->register_parameter($name);
2118     return $result;
2119 }
2120 END_OF_FUNC
2121
2122
2123 #### Method: hidden
2124 # Parameters:
2125 #   $name -> Name of the hidden field
2126 #   @default -> (optional) Initial values of field (may be an array)
2127 #      or
2128 #   $default->[initial values of field]
2129 # Returns:
2130 #   A string containing a <INPUT TYPE="hidden" NAME="name" VALUE="value">
2131 ####
2132 'hidden' => <<'END_OF_FUNC',
2133 sub hidden {
2134     my($self,@p) = self_or_default(@_);
2135
2136     # this is the one place where we departed from our standard
2137     # calling scheme, so we have to special-case (darn)
2138     my(@result,@value);
2139     my($name,$default,$override,@other) = 
2140         rearrange([NAME,[DEFAULT,VALUE,VALUES],[OVERRIDE,FORCE]],@p);
2141
2142     my $do_override = 0;
2143     if ( ref($p[0]) || substr($p[0],0,1) eq '-') {
2144         @value = ref($default) ? @{$default} : $default;
2145         $do_override = $override;
2146     } else {
2147         foreach ($default,$override,@other) {
2148             push(@value,$_) if defined($_);
2149         }
2150     }
2151
2152     # use previous values if override is not set
2153     my @prev = $self->param($name);
2154     @value = @prev if !$do_override && @prev;
2155
2156     $name=$self->escapeHTML($name);
2157     foreach (@value) {
2158         $_ = defined($_) ? $self->escapeHTML($_,1) : '';
2159         push @result,$XHTMl ? qq(<input type="hidden" name="$name" value="$_" />)
2160                             : qq(<input type="hidden" name="$name" value="$_">);
2161     }
2162     return wantarray ? @result : join('',@result);
2163 }
2164 END_OF_FUNC
2165
2166
2167 #### Method: image_button
2168 # Parameters:
2169 #   $name -> Name of the button
2170 #   $src ->  URL of the image source
2171 #   $align -> Alignment style (TOP, BOTTOM or MIDDLE)
2172 # Returns:
2173 #   A string containing a <INPUT TYPE="image" NAME="name" SRC="url" ALIGN="alignment">
2174 ####
2175 'image_button' => <<'END_OF_FUNC',
2176 sub image_button {
2177     my($self,@p) = self_or_default(@_);
2178
2179     my($name,$src,$alignment,@other) =
2180         rearrange([NAME,SRC,ALIGN],@p);
2181
2182     my($align) = $alignment ? " align=\U$alignment" : '';
2183     my($other) = @other ? " @other" : '';
2184     $name=$self->escapeHTML($name);
2185     return $XHTML ? qq(<input type="image" name="$name" src="$src"$align$other />)
2186                   : qq/<input type="image" name="$name" src="$src"$align$other>/;
2187 }
2188 END_OF_FUNC
2189
2190
2191 #### Method: self_url
2192 # Returns a URL containing the current script and all its
2193 # param/value pairs arranged as a query.  You can use this
2194 # to create a link that, when selected, will reinvoke the
2195 # script with all its state information preserved.
2196 ####
2197 'self_url' => <<'END_OF_FUNC',
2198 sub self_url {
2199     my($self,@p) = self_or_default(@_);
2200     return $self->url('-path_info'=>1,'-query'=>1,'-full'=>1,@p);
2201 }
2202 END_OF_FUNC
2203
2204
2205 # This is provided as a synonym to self_url() for people unfortunate
2206 # enough to have incorporated it into their programs already!
2207 'state' => <<'END_OF_FUNC',
2208 sub state {
2209     &self_url;
2210 }
2211 END_OF_FUNC
2212
2213
2214 #### Method: url
2215 # Like self_url, but doesn't return the query string part of
2216 # the URL.
2217 ####
2218 'url' => <<'END_OF_FUNC',
2219 sub url {
2220     my($self,@p) = self_or_default(@_);
2221     my ($relative,$absolute,$full,$path_info,$query,$base) = 
2222         rearrange(['RELATIVE','ABSOLUTE','FULL',['PATH','PATH_INFO'],['QUERY','QUERY_STRING'],'BASE'],@p);
2223     my $url;
2224     $full++ if $base || !($relative || $absolute);
2225
2226     my $path = $self->path_info;
2227     my $script_name = $self->script_name;
2228
2229 # If anybody knows why I ever wrote this please tell me!
2230 #    if (exists($ENV{REQUEST_URI})) {
2231 #        my $index;
2232 #       $script_name = $ENV{REQUEST_URI};
2233 #        # strip query string
2234 #        substr($script_name,$index) = '' if ($index = index($script_name,'?')) >= 0;
2235 #        # and path
2236 #        if (exists($ENV{PATH_INFO})) {
2237 #           (my $encoded_path = $ENV{PATH_INFO}) =~ s!([^a-zA-Z0-9_./-])!uc sprintf("%%%02x",ord($1))!eg;;
2238 #           substr($script_name,$index) = '' if ($index = rindex($script_name,$encoded_path)) >= 0;
2239 #         }
2240 #    } else {
2241 #       $script_name = $self->script_name;
2242 #    }
2243
2244     if ($full) {
2245         my $protocol = $self->protocol();
2246         $url = "$protocol://";
2247         my $vh = http('host');
2248         if ($vh) {
2249             $url .= $vh;
2250         } else {
2251             $url .= server_name();
2252             my $port = $self->server_port;
2253             $url .= ":" . $port
2254                 unless (lc($protocol) eq 'http' && $port == 80)
2255                     || (lc($protocol) eq 'https' && $port == 443);
2256         }
2257         return $url if $base;
2258         $url .= $script_name;
2259     } elsif ($relative) {
2260         ($url) = $script_name =~ m!([^/]+)$!;
2261     } elsif ($absolute) {
2262         $url = $script_name;
2263     }
2264
2265     $url .= $path if $path_info and defined $path;
2266     $url .= "?" . $self->query_string if $query and $self->query_string;
2267     $url = '' unless defined $url;
2268     $url =~ s/([^a-zA-Z0-9_.%;&?\/\\:+=~-])/uc sprintf("%%%02x",ord($1))/eg;
2269     return $url;
2270 }
2271
2272 END_OF_FUNC
2273
2274 #### Method: cookie
2275 # Set or read a cookie from the specified name.
2276 # Cookie can then be passed to header().
2277 # Usual rules apply to the stickiness of -value.
2278 #  Parameters:
2279 #   -name -> name for this cookie (optional)
2280 #   -value -> value of this cookie (scalar, array or hash) 
2281 #   -path -> paths for which this cookie is valid (optional)
2282 #   -domain -> internet domain in which this cookie is valid (optional)
2283 #   -secure -> if true, cookie only passed through secure channel (optional)
2284 #   -expires -> expiry date in format Wdy, DD-Mon-YYYY HH:MM:SS GMT (optional)
2285 ####
2286 'cookie' => <<'END_OF_FUNC',
2287 sub cookie {
2288     my($self,@p) = self_or_default(@_);
2289     my($name,$value,$path,$domain,$secure,$expires) =
2290         rearrange([NAME,[VALUE,VALUES],PATH,DOMAIN,SECURE,EXPIRES],@p);
2291
2292     require CGI::Cookie;
2293
2294     # if no value is supplied, then we retrieve the
2295     # value of the cookie, if any.  For efficiency, we cache the parsed
2296     # cookies in our state variables.
2297     unless ( defined($value) ) {
2298         $self->{'.cookies'} = CGI::Cookie->fetch
2299             unless $self->{'.cookies'};
2300
2301         # If no name is supplied, then retrieve the names of all our cookies.
2302         return () unless $self->{'.cookies'};
2303         return keys %{$self->{'.cookies'}} unless $name;
2304         return () unless $self->{'.cookies'}->{$name};
2305         return $self->{'.cookies'}->{$name}->value if defined($name) && $name ne '';
2306     }
2307
2308     # If we get here, we're creating a new cookie
2309     return undef unless $name;  # this is an error
2310
2311     my @param;
2312     push(@param,'-name'=>$name);
2313     push(@param,'-value'=>$value);
2314     push(@param,'-domain'=>$domain) if $domain;
2315     push(@param,'-path'=>$path) if $path;
2316     push(@param,'-expires'=>$expires) if $expires;
2317     push(@param,'-secure'=>$secure) if $secure;
2318
2319     return new CGI::Cookie(@param);
2320 }
2321 END_OF_FUNC
2322
2323 'parse_keywordlist' => <<'END_OF_FUNC',
2324 sub parse_keywordlist {
2325     my($self,$tosplit) = @_;
2326     $tosplit = unescape($tosplit); # unescape the keywords
2327     $tosplit=~tr/+/ /;          # pluses to spaces
2328     my(@keywords) = split(/\s+/,$tosplit);
2329     return @keywords;
2330 }
2331 END_OF_FUNC
2332
2333 'param_fetch' => <<'END_OF_FUNC',
2334 sub param_fetch {
2335     my($self,@p) = self_or_default(@_);
2336     my($name) = rearrange([NAME],@p);
2337     unless (exists($self->{$name})) {
2338         $self->add_parameter($name);
2339         $self->{$name} = [];
2340     }
2341     
2342     return $self->{$name};
2343 }
2344 END_OF_FUNC
2345
2346 ###############################################
2347 # OTHER INFORMATION PROVIDED BY THE ENVIRONMENT
2348 ###############################################
2349
2350 #### Method: path_info
2351 # Return the extra virtual path information provided
2352 # after the URL (if any)
2353 ####
2354 'path_info' => <<'END_OF_FUNC',
2355 sub path_info {
2356     my ($self,$info) = self_or_default(@_);
2357     if (defined($info)) {
2358         $info = "/$info" if $info ne '' &&  substr($info,0,1) ne '/';
2359         $self->{'.path_info'} = $info;
2360     } elsif (! defined($self->{'.path_info'}) ) {
2361         $self->{'.path_info'} = defined($ENV{'PATH_INFO'}) ? 
2362             $ENV{'PATH_INFO'} : '';
2363
2364         # hack to fix broken path info in IIS
2365         $self->{'.path_info'} =~ s/^\Q$ENV{'SCRIPT_NAME'}\E// if $IIS;
2366
2367     }
2368     return $self->{'.path_info'};
2369 }
2370 END_OF_FUNC
2371
2372
2373 #### Method: request_method
2374 # Returns 'POST', 'GET', 'PUT' or 'HEAD'
2375 ####
2376 'request_method' => <<'END_OF_FUNC',
2377 sub request_method {
2378     return $ENV{'REQUEST_METHOD'};
2379 }
2380 END_OF_FUNC
2381
2382 #### Method: content_type
2383 # Returns the content_type string
2384 ####
2385 'content_type' => <<'END_OF_FUNC',
2386 sub content_type {
2387     return $ENV{'CONTENT_TYPE'};
2388 }
2389 END_OF_FUNC
2390
2391 #### Method: path_translated
2392 # Return the physical path information provided
2393 # by the URL (if any)
2394 ####
2395 'path_translated' => <<'END_OF_FUNC',
2396 sub path_translated {
2397     return $ENV{'PATH_TRANSLATED'};
2398 }
2399 END_OF_FUNC
2400
2401
2402 #### Method: query_string
2403 # Synthesize a query string from our current
2404 # parameters
2405 ####
2406 'query_string' => <<'END_OF_FUNC',
2407 sub query_string {
2408     my($self) = self_or_default(@_);
2409     my($param,$value,@pairs);
2410     foreach $param ($self->param) {
2411         my($eparam) = escape($param);
2412         foreach $value ($self->param($param)) {
2413             $value = escape($value);
2414             next unless defined $value;
2415             push(@pairs,"$eparam=$value");
2416         }
2417     }
2418     foreach (keys %{$self->{'.fieldnames'}}) {
2419       push(@pairs,".cgifields=".escape("$_"));
2420     }
2421     return join($USE_PARAM_SEMICOLONS ? ';' : '&',@pairs);
2422 }
2423 END_OF_FUNC
2424
2425
2426 #### Method: accept
2427 # Without parameters, returns an array of the
2428 # MIME types the browser accepts.
2429 # With a single parameter equal to a MIME
2430 # type, will return undef if the browser won't
2431 # accept it, 1 if the browser accepts it but
2432 # doesn't give a preference, or a floating point
2433 # value between 0.0 and 1.0 if the browser
2434 # declares a quantitative score for it.
2435 # This handles MIME type globs correctly.
2436 ####
2437 'Accept' => <<'END_OF_FUNC',
2438 sub Accept {
2439     my($self,$search) = self_or_CGI(@_);
2440     my(%prefs,$type,$pref,$pat);
2441     
2442     my(@accept) = split(',',$self->http('accept'));
2443
2444     foreach (@accept) {
2445         ($pref) = /q=(\d\.\d+|\d+)/;
2446         ($type) = m#(\S+/[^;]+)#;
2447         next unless $type;
2448         $prefs{$type}=$pref || 1;
2449     }
2450
2451     return keys %prefs unless $search;
2452     
2453     # if a search type is provided, we may need to
2454     # perform a pattern matching operation.
2455     # The MIME types use a glob mechanism, which
2456     # is easily translated into a perl pattern match
2457
2458     # First return the preference for directly supported
2459     # types:
2460     return $prefs{$search} if $prefs{$search};
2461
2462     # Didn't get it, so try pattern matching.
2463     foreach (keys %prefs) {
2464         next unless /\*/;       # not a pattern match
2465         ($pat = $_) =~ s/([^\w*])/\\$1/g; # escape meta characters
2466         $pat =~ s/\*/.*/g; # turn it into a pattern
2467         return $prefs{$_} if $search=~/$pat/;
2468     }
2469 }
2470 END_OF_FUNC
2471
2472
2473 #### Method: user_agent
2474 # If called with no parameters, returns the user agent.
2475 # If called with one parameter, does a pattern match (case
2476 # insensitive) on the user agent.
2477 ####
2478 'user_agent' => <<'END_OF_FUNC',
2479 sub user_agent {
2480     my($self,$match)=self_or_CGI(@_);
2481     return $self->http('user_agent') unless $match;
2482     return $self->http('user_agent') =~ /$match/i;
2483 }
2484 END_OF_FUNC
2485
2486
2487 #### Method: raw_cookie
2488 # Returns the magic cookies for the session.
2489 # The cookies are not parsed or altered in any way, i.e.
2490 # cookies are returned exactly as given in the HTTP
2491 # headers.  If a cookie name is given, only that cookie's
2492 # value is returned, otherwise the entire raw cookie
2493 # is returned.
2494 ####
2495 'raw_cookie' => <<'END_OF_FUNC',
2496 sub raw_cookie {
2497     my($self,$key) = self_or_CGI(@_);
2498
2499     require CGI::Cookie;
2500
2501     if (defined($key)) {
2502         $self->{'.raw_cookies'} = CGI::Cookie->raw_fetch
2503             unless $self->{'.raw_cookies'};
2504
2505         return () unless $self->{'.raw_cookies'};
2506         return () unless $self->{'.raw_cookies'}->{$key};
2507         return $self->{'.raw_cookies'}->{$key};
2508     }
2509     return $self->http('cookie') || $ENV{'COOKIE'} || '';
2510 }
2511 END_OF_FUNC
2512
2513 #### Method: virtual_host
2514 # Return the name of the virtual_host, which
2515 # is not always the same as the server
2516 ######
2517 'virtual_host' => <<'END_OF_FUNC',
2518 sub virtual_host {
2519     my $vh = http('host') || server_name();
2520     $vh =~ s/:\d+$//;           # get rid of port number
2521     return $vh;
2522 }
2523 END_OF_FUNC
2524
2525 #### Method: remote_host
2526 # Return the name of the remote host, or its IP
2527 # address if unavailable.  If this variable isn't
2528 # defined, it returns "localhost" for debugging
2529 # purposes.
2530 ####
2531 'remote_host' => <<'END_OF_FUNC',
2532 sub remote_host {
2533     return $ENV{'REMOTE_HOST'} || $ENV{'REMOTE_ADDR'} 
2534     || 'localhost';
2535 }
2536 END_OF_FUNC
2537
2538
2539 #### Method: remote_addr
2540 # Return the IP addr of the remote host.
2541 ####
2542 'remote_addr' => <<'END_OF_FUNC',
2543 sub remote_addr {
2544     return $ENV{'REMOTE_ADDR'} || '127.0.0.1';
2545 }
2546 END_OF_FUNC
2547
2548
2549 #### Method: script_name
2550 # Return the partial URL to this script for
2551 # self-referencing scripts.  Also see
2552 # self_url(), which returns a URL with all state information
2553 # preserved.
2554 ####
2555 'script_name' => <<'END_OF_FUNC',
2556 sub script_name {
2557     return $ENV{'SCRIPT_NAME'} if defined($ENV{'SCRIPT_NAME'});
2558     # These are for debugging
2559     return "/$0" unless $0=~/^\//;
2560     return $0;
2561 }
2562 END_OF_FUNC
2563
2564
2565 #### Method: referer
2566 # Return the HTTP_REFERER: useful for generating
2567 # a GO BACK button.
2568 ####
2569 'referer' => <<'END_OF_FUNC',
2570 sub referer {
2571     my($self) = self_or_CGI(@_);
2572     return $self->http('referer');
2573 }
2574 END_OF_FUNC
2575
2576
2577 #### Method: server_name
2578 # Return the name of the server
2579 ####
2580 'server_name' => <<'END_OF_FUNC',
2581 sub server_name {
2582     return $ENV{'SERVER_NAME'} || 'localhost';
2583 }
2584 END_OF_FUNC
2585
2586 #### Method: server_software
2587 # Return the name of the server software
2588 ####
2589 'server_software' => <<'END_OF_FUNC',
2590 sub server_software {
2591     return $ENV{'SERVER_SOFTWARE'} || 'cmdline';
2592 }
2593 END_OF_FUNC
2594
2595 #### Method: server_port
2596 # Return the tcp/ip port the server is running on
2597 ####
2598 'server_port' => <<'END_OF_FUNC',
2599 sub server_port {
2600     return $ENV{'SERVER_PORT'} || 80; # for debugging
2601 }
2602 END_OF_FUNC
2603
2604 #### Method: server_protocol
2605 # Return the protocol (usually HTTP/1.0)
2606 ####
2607 'server_protocol' => <<'END_OF_FUNC',
2608 sub server_protocol {
2609     return $ENV{'SERVER_PROTOCOL'} || 'HTTP/1.0'; # for debugging
2610 }
2611 END_OF_FUNC
2612
2613 #### Method: http
2614 # Return the value of an HTTP variable, or
2615 # the list of variables if none provided
2616 ####
2617 'http' => <<'END_OF_FUNC',
2618 sub http {
2619     my ($self,$parameter) = self_or_CGI(@_);
2620     return $ENV{$parameter} if $parameter=~/^HTTP/;
2621     $parameter =~ tr/-/_/;
2622     return $ENV{"HTTP_\U$parameter\E"} if $parameter;
2623     my(@p);
2624     foreach (keys %ENV) {
2625         push(@p,$_) if /^HTTP/;
2626     }
2627     return @p;
2628 }
2629 END_OF_FUNC
2630
2631 #### Method: https
2632 # Return the value of HTTPS
2633 ####
2634 'https' => <<'END_OF_FUNC',
2635 sub https {
2636     local($^W)=0;
2637     my ($self,$parameter) = self_or_CGI(@_);
2638     return $ENV{HTTPS} unless $parameter;
2639     return $ENV{$parameter} if $parameter=~/^HTTPS/;
2640     $parameter =~ tr/-/_/;
2641     return $ENV{"HTTPS_\U$parameter\E"} if $parameter;
2642     my(@p);
2643     foreach (keys %ENV) {
2644         push(@p,$_) if /^HTTPS/;
2645     }
2646     return @p;
2647 }
2648 END_OF_FUNC
2649
2650 #### Method: protocol
2651 # Return the protocol (http or https currently)
2652 ####
2653 'protocol' => <<'END_OF_FUNC',
2654 sub protocol {
2655     local($^W)=0;
2656     my $self = shift;
2657     return 'https' if uc($self->https()) eq 'ON'; 
2658     return 'https' if $self->server_port == 443;
2659     my $prot = $self->server_protocol;
2660     my($protocol,$version) = split('/',$prot);
2661     return "\L$protocol\E";
2662 }
2663 END_OF_FUNC
2664
2665 #### Method: remote_ident
2666 # Return the identity of the remote user
2667 # (but only if his host is running identd)
2668 ####
2669 'remote_ident' => <<'END_OF_FUNC',
2670 sub remote_ident {
2671     return $ENV{'REMOTE_IDENT'};
2672 }
2673 END_OF_FUNC
2674
2675
2676 #### Method: auth_type
2677 # Return the type of use verification/authorization in use, if any.
2678 ####
2679 'auth_type' => <<'END_OF_FUNC',
2680 sub auth_type {
2681     return $ENV{'AUTH_TYPE'};
2682 }
2683 END_OF_FUNC
2684
2685
2686 #### Method: remote_user
2687 # Return the authorization name used for user
2688 # verification.
2689 ####
2690 'remote_user' => <<'END_OF_FUNC',
2691 sub remote_user {
2692     return $ENV{'REMOTE_USER'};
2693 }
2694 END_OF_FUNC
2695
2696
2697 #### Method: user_name
2698 # Try to return the remote user's name by hook or by
2699 # crook
2700 ####
2701 'user_name' => <<'END_OF_FUNC',
2702 sub user_name {
2703     my ($self) = self_or_CGI(@_);
2704     return $self->http('from') || $ENV{'REMOTE_IDENT'} || $ENV{'REMOTE_USER'};
2705 }
2706 END_OF_FUNC
2707
2708 #### Method: nosticky
2709 # Set or return the NOSTICKY global flag
2710 ####
2711 'nosticky' => <<'END_OF_FUNC',
2712 sub nosticky {
2713     my ($self,$param) = self_or_CGI(@_);
2714     $CGI::NOSTICKY = $param if defined($param);
2715     return $CGI::NOSTICKY;
2716 }
2717 END_OF_FUNC
2718
2719 #### Method: nph
2720 # Set or return the NPH global flag
2721 ####
2722 'nph' => <<'END_OF_FUNC',
2723 sub nph {
2724     my ($self,$param) = self_or_CGI(@_);
2725     $CGI::NPH = $param if defined($param);
2726     return $CGI::NPH;
2727 }
2728 END_OF_FUNC
2729
2730 #### Method: private_tempfiles
2731 # Set or return the private_tempfiles global flag
2732 ####
2733 'private_tempfiles' => <<'END_OF_FUNC',
2734 sub private_tempfiles {
2735     my ($self,$param) = self_or_CGI(@_);
2736     $CGI::PRIVATE_TEMPFILES = $param if defined($param);
2737     return $CGI::PRIVATE_TEMPFILES;
2738 }
2739 END_OF_FUNC
2740
2741 #### Method: default_dtd
2742 # Set or return the default_dtd global
2743 ####
2744 'default_dtd' => <<'END_OF_FUNC',
2745 sub default_dtd {
2746     my ($self,$param,$param2) = self_or_CGI(@_);
2747     if (defined $param2 && defined $param) {
2748         $CGI::DEFAULT_DTD = [ $param, $param2 ];
2749     } elsif (defined $param) {
2750         $CGI::DEFAULT_DTD = $param;
2751     }
2752     return $CGI::DEFAULT_DTD;
2753 }
2754 END_OF_FUNC
2755
2756 # -------------- really private subroutines -----------------
2757 'previous_or_default' => <<'END_OF_FUNC',
2758 sub previous_or_default {
2759     my($self,$name,$defaults,$override) = @_;
2760     my(%selected);
2761
2762     if (!$override && ($self->{'.fieldnames'}->{$name} || 
2763                        defined($self->param($name)) ) ) {
2764         grep($selected{$_}++,$self->param($name));
2765     } elsif (defined($defaults) && ref($defaults) && 
2766              (ref($defaults) eq 'ARRAY')) {
2767         grep($selected{$_}++,@{$defaults});
2768     } else {
2769         $selected{$defaults}++ if defined($defaults);
2770     }
2771
2772     return %selected;
2773 }
2774 END_OF_FUNC
2775
2776 'register_parameter' => <<'END_OF_FUNC',
2777 sub register_parameter {
2778     my($self,$param) = @_;
2779     $self->{'.parametersToAdd'}->{$param}++;
2780 }
2781 END_OF_FUNC
2782
2783 'get_fields' => <<'END_OF_FUNC',
2784 sub get_fields {
2785     my($self) = @_;
2786     return $self->CGI::hidden('-name'=>'.cgifields',
2787                               '-values'=>[keys %{$self->{'.parametersToAdd'}}],
2788                               '-override'=>1);
2789 }
2790 END_OF_FUNC
2791
2792 'read_from_cmdline' => <<'END_OF_FUNC',
2793 sub read_from_cmdline {
2794     my($input,@words);
2795     my($query_string);
2796     if ($DEBUG && @ARGV) {
2797         @words = @ARGV;
2798     } elsif ($DEBUG > 1) {
2799         require "shellwords.pl";
2800         print STDERR "(offline mode: enter name=value pairs on standard input)\n";
2801         chomp(@lines = <STDIN>); # remove newlines
2802         $input = join(" ",@lines);
2803         @words = &shellwords($input);    
2804     }
2805     foreach (@words) {
2806         s/\\=/%3D/g;
2807         s/\\&/%26/g;        
2808     }
2809
2810     if ("@words"=~/=/) {
2811         $query_string = join('&',@words);
2812     } else {
2813         $query_string = join('+',@words);
2814     }
2815     return $query_string;
2816 }
2817 END_OF_FUNC
2818
2819 #####
2820 # subroutine: read_multipart
2821 #
2822 # Read multipart data and store it into our parameters.
2823 # An interesting feature is that if any of the parts is a file, we
2824 # create a temporary file and open up a filehandle on it so that the
2825 # caller can read from it if necessary.
2826 #####
2827 'read_multipart' => <<'END_OF_FUNC',
2828 sub read_multipart {
2829     my($self,$boundary,$length,$filehandle) = @_;
2830     my($buffer) = $self->new_MultipartBuffer($boundary,$length,$filehandle);
2831     return unless $buffer;
2832     my(%header,$body);
2833     my $filenumber = 0;
2834     while (!$buffer->eof) {
2835         %header = $buffer->readHeader;
2836
2837         unless (%header) {
2838             $self->cgi_error("400 Bad request (malformed multipart POST)");
2839             return;
2840         }
2841
2842         my($param)= $header{'Content-Disposition'}=~/ name="?([^\";]*)"?/;
2843
2844         # Bug:  Netscape doesn't escape quotation marks in file names!!!
2845         my($filename) = $header{'Content-Disposition'}=~/ filename="?([^\"]*)"?/;
2846
2847         # add this parameter to our list
2848         $self->add_parameter($param);
2849
2850         # If no filename specified, then just read the data and assign it
2851         # to our parameter list.
2852         if ( !defined($filename) || $filename eq '' ) {
2853             my($value) = $buffer->readBody;
2854             push(@{$self->{$param}},$value);
2855             next;
2856         }
2857
2858         my ($tmpfile,$tmp,$filehandle);
2859       UPLOADS: {
2860           # If we get here, then we are dealing with a potentially large
2861           # uploaded form.  Save the data to a temporary file, then open
2862           # the file for reading.
2863
2864           # skip the file if uploads disabled
2865           if ($DISABLE_UPLOADS) {
2866               while (defined($data = $buffer->read)) { }
2867               last UPLOADS;
2868           }
2869
2870           # choose a relatively unpredictable tmpfile sequence number
2871           my $seqno = unpack("%16C*",join('',localtime,values %ENV));
2872           for (my $cnt=10;$cnt>0;$cnt--) {
2873             next unless $tmpfile = new TempFile($seqno);
2874             $tmp = $tmpfile->as_string;
2875             last if defined($filehandle = Fh->new($filename,$tmp,$PRIVATE_TEMPFILES));
2876             $seqno += int rand(100);
2877           }
2878           die "CGI open of tmpfile: $!\n" unless $filehandle;
2879           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode;
2880
2881           my ($data);
2882           local($\) = '';
2883           while (defined($data = $buffer->read)) {
2884               print $filehandle $data;
2885           }
2886
2887           # back up to beginning of file
2888           seek($filehandle,0,0);
2889           $CGI::DefaultClass->binmode($filehandle) if $CGI::needs_binmode;
2890
2891           # Save some information about the uploaded file where we can get
2892           # at it later.
2893           $self->{'.tmpfiles'}->{fileno($filehandle)}= {
2894               name => $tmpfile,
2895               info => {%header},
2896           };
2897           push(@{$self->{$param}},$filehandle);
2898       }
2899     }
2900 }
2901 END_OF_FUNC
2902
2903 'upload' =><<'END_OF_FUNC',
2904 sub upload {
2905     my($self,$param_name) = self_or_default(@_);
2906     my $param = $self->param($param_name);
2907     return unless $param;
2908     return unless ref($param) && fileno($param);
2909     return $param;
2910 }
2911 END_OF_FUNC
2912
2913 'tmpFileName' => <<'END_OF_FUNC',
2914 sub tmpFileName {
2915     my($self,$filename) = self_or_default(@_);
2916     return $self->{'.tmpfiles'}->{fileno($filename)}->{name} ?
2917         $self->{'.tmpfiles'}->{fileno($filename)}->{name}->as_string
2918             : '';
2919 }
2920 END_OF_FUNC
2921
2922 'uploadInfo' => <<'END_OF_FUNC',
2923 sub uploadInfo {
2924     my($self,$filename) = self_or_default(@_);
2925     return $self->{'.tmpfiles'}->{fileno($filename)}->{info};
2926 }
2927 END_OF_FUNC
2928
2929 # internal routine, don't use
2930 '_set_values_and_labels' => <<'END_OF_FUNC',
2931 sub _set_values_and_labels {
2932     my $self = shift;
2933     my ($v,$l,$n) = @_;
2934     $$l = $v if ref($v) eq 'HASH' && !ref($$l);
2935     return $self->param($n) if !defined($v);
2936     return $v if !ref($v);
2937     return ref($v) eq 'HASH' ? keys %$v : @$v;
2938 }
2939 END_OF_FUNC
2940
2941 '_compile_all' => <<'END_OF_FUNC',
2942 sub _compile_all {
2943     foreach (@_) {
2944         next if defined(&$_);
2945         $AUTOLOAD = "CGI::$_";
2946         _compile();
2947     }
2948 }
2949 END_OF_FUNC
2950
2951 );
2952 END_OF_AUTOLOAD
2953 ;
2954
2955 #########################################################
2956 # Globals and stubs for other packages that we use.
2957 #########################################################
2958
2959 ################### Fh -- lightweight filehandle ###############
2960 package Fh;
2961 use overload 
2962     '""'  => \&asString,
2963     'cmp' => \&compare,
2964     'fallback'=>1;
2965
2966 $FH='fh00000';
2967
2968 *Fh::AUTOLOAD = \&CGI::AUTOLOAD;
2969
2970 $AUTOLOADED_ROUTINES = '';      # prevent -w error
2971 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
2972 %SUBS =  (
2973 'asString' => <<'END_OF_FUNC',
2974 sub asString {
2975     my $self = shift;
2976     # get rid of package name
2977     (my $i = $$self) =~ s/^\*(\w+::fh\d{5})+//; 
2978     $i =~ s/\\(.)/$1/g;
2979     return $i;
2980 # BEGIN DEAD CODE
2981 # This was an extremely clever patch that allowed "use strict refs".
2982 # Unfortunately it relied on another bug that caused leaky file descriptors.
2983 # The underlying bug has been fixed, so this no longer works.  However
2984 # "strict refs" still works for some reason.
2985 #    my $self = shift;
2986 #    return ${*{$self}{SCALAR}};
2987 # END DEAD CODE
2988 }
2989 END_OF_FUNC
2990
2991 'compare' => <<'END_OF_FUNC',
2992 sub compare {
2993     my $self = shift;
2994     my $value = shift;
2995     return "$self" cmp $value;
2996 }
2997 END_OF_FUNC
2998
2999 'new'  => <<'END_OF_FUNC',
3000 sub new {
3001     my($pack,$name,$file,$delete) = @_;
3002     require Fcntl unless defined &Fcntl::O_RDWR;
3003     my $fv = ++$FH . quotemeta($name);
3004     my $ref = \*{"Fh::$fv"};
3005     sysopen($ref,$file,Fcntl::O_RDWR()|Fcntl::O_CREAT()|Fcntl::O_EXCL(),0600) || return;
3006     unlink($file) if $delete;
3007     CORE::delete $Fh::{$fv};
3008     return bless $ref,$pack;
3009 }
3010 END_OF_FUNC
3011
3012 'DESTROY'  => <<'END_OF_FUNC',
3013 sub DESTROY {
3014     my $self = shift;
3015     close $self;
3016 }
3017 END_OF_FUNC
3018
3019 );
3020 END_OF_AUTOLOAD
3021
3022 ######################## MultipartBuffer ####################
3023 package MultipartBuffer;
3024
3025 # how many bytes to read at a time.  We use
3026 # a 4K buffer by default.
3027 $INITIAL_FILLUNIT = 1024 * 4;
3028 $TIMEOUT = 240*60;       # 4 hour timeout for big files
3029 $SPIN_LOOP_MAX = 2000;  # bug fix for some Netscape servers
3030 $CRLF=$CGI::CRLF;
3031
3032 #reuse the autoload function
3033 *MultipartBuffer::AUTOLOAD = \&CGI::AUTOLOAD;
3034
3035 # avoid autoloader warnings
3036 sub DESTROY {}
3037
3038 ###############################################################################
3039 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3040 ###############################################################################
3041 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3042 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3043 %SUBS =  (
3044
3045 'new' => <<'END_OF_FUNC',
3046 sub new {
3047     my($package,$interface,$boundary,$length,$filehandle) = @_;
3048     $FILLUNIT = $INITIAL_FILLUNIT;
3049     my $IN;
3050     if ($filehandle) {
3051         my($package) = caller;
3052         # force into caller's package if necessary
3053         $IN = $filehandle=~/[':]/ ? $filehandle : "$package\:\:$filehandle"; 
3054     }
3055     $IN = "main::STDIN" unless $IN;
3056
3057     $CGI::DefaultClass->binmode($IN) if $CGI::needs_binmode;
3058     
3059     # If the user types garbage into the file upload field,
3060     # then Netscape passes NOTHING to the server (not good).
3061     # We may hang on this read in that case. So we implement
3062     # a read timeout.  If nothing is ready to read
3063     # by then, we return.
3064
3065     # Netscape seems to be a little bit unreliable
3066     # about providing boundary strings.
3067     my $boundary_read = 0;
3068     if ($boundary) {
3069
3070         # Under the MIME spec, the boundary consists of the 
3071         # characters "--" PLUS the Boundary string
3072
3073         # BUG: IE 3.01 on the Macintosh uses just the boundary -- not
3074         # the two extra hyphens.  We do a special case here on the user-agent!!!!
3075         $boundary = "--$boundary" unless CGI::user_agent('MSIE\s+3\.0[12];\s*Mac');
3076
3077     } else { # otherwise we find it ourselves
3078         my($old);
3079         ($old,$/) = ($/,$CRLF); # read a CRLF-delimited line
3080         $boundary = <$IN>;      # BUG: This won't work correctly under mod_perl
3081         $length -= length($boundary);
3082         chomp($boundary);               # remove the CRLF
3083         $/ = $old;                      # restore old line separator
3084         $boundary_read++;
3085     }
3086
3087     my $self = {LENGTH=>$length,
3088                 BOUNDARY=>$boundary,
3089                 IN=>$IN,
3090                 INTERFACE=>$interface,
3091                 BUFFER=>'',
3092             };
3093
3094     $FILLUNIT = length($boundary)
3095         if length($boundary) > $FILLUNIT;
3096
3097     my $retval = bless $self,ref $package || $package;
3098
3099     # Read the preamble and the topmost (boundary) line plus the CRLF.
3100     unless ($boundary_read) {
3101       while ($self->read(0)) { }
3102     }
3103     die "Malformed multipart POST\n" if $self->eof;
3104
3105     return $retval;
3106 }
3107 END_OF_FUNC
3108
3109 'readHeader' => <<'END_OF_FUNC',
3110 sub readHeader {
3111     my($self) = @_;
3112     my($end);
3113     my($ok) = 0;
3114     my($bad) = 0;
3115
3116     local($CRLF) = "\015\012" if $CGI::OS eq 'VMS';
3117
3118     do {
3119         $self->fillBuffer($FILLUNIT);
3120         $ok++ if ($end = index($self->{BUFFER},"${CRLF}${CRLF}")) >= 0;
3121         $ok++ if $self->{BUFFER} eq '';
3122         $bad++ if !$ok && $self->{LENGTH} <= 0;
3123         # this was a bad idea
3124         # $FILLUNIT *= 2 if length($self->{BUFFER}) >= $FILLUNIT; 
3125     } until $ok || $bad;
3126     return () if $bad;
3127
3128     my($header) = substr($self->{BUFFER},0,$end+2);
3129     substr($self->{BUFFER},0,$end+4) = '';
3130     my %return;
3131
3132     
3133     # See RFC 2045 Appendix A and RFC 822 sections 3.4.8
3134     #   (Folding Long Header Fields), 3.4.3 (Comments)
3135     #   and 3.4.5 (Quoted-Strings).
3136
3137     my $token = '[-\w!\#$%&\'*+.^_\`|{}~]';
3138     $header=~s/$CRLF\s+/ /og;           # merge continuation lines
3139     while ($header=~/($token+):\s+([^$CRLF]*)/mgox) {
3140         my ($field_name,$field_value) = ($1,$2); # avoid taintedness
3141         $field_name =~ s/\b(\w)/uc($1)/eg; #canonicalize
3142         $return{$field_name}=$field_value;
3143     }
3144     return %return;
3145 }
3146 END_OF_FUNC
3147
3148 # This reads and returns the body as a single scalar value.
3149 'readBody' => <<'END_OF_FUNC',
3150 sub readBody {
3151     my($self) = @_;
3152     my($data);
3153     my($returnval)='';
3154     while (defined($data = $self->read)) {
3155         $returnval .= $data;
3156     }
3157     return $returnval;
3158 }
3159 END_OF_FUNC
3160
3161 # This will read $bytes or until the boundary is hit, whichever happens
3162 # first.  After the boundary is hit, we return undef.  The next read will
3163 # skip over the boundary and begin reading again;
3164 'read' => <<'END_OF_FUNC',
3165 sub read {
3166     my($self,$bytes) = @_;
3167
3168     # default number of bytes to read
3169     $bytes = $bytes || $FILLUNIT;       
3170
3171     # Fill up our internal buffer in such a way that the boundary
3172     # is never split between reads.
3173     $self->fillBuffer($bytes);
3174
3175     # Find the boundary in the buffer (it may not be there).
3176     my $start = index($self->{BUFFER},$self->{BOUNDARY});
3177     # protect against malformed multipart POST operations
3178     die "Malformed multipart POST\n" unless ($start >= 0) || ($self->{LENGTH} > 0);
3179
3180     # If the boundary begins the data, then skip past it
3181     # and return undef.
3182     if ($start == 0) {
3183
3184         # clear us out completely if we've hit the last boundary.
3185         if (index($self->{BUFFER},"$self->{BOUNDARY}--")==0) {
3186             $self->{BUFFER}='';
3187             $self->{LENGTH}=0;
3188             return undef;
3189         }
3190
3191         # just remove the boundary.
3192         substr($self->{BUFFER},0,length($self->{BOUNDARY}))='';
3193         $self->{BUFFER} =~ s/^\012\015?//;
3194         return undef;
3195     }
3196
3197     my $bytesToReturn;    
3198     if ($start > 0) {           # read up to the boundary
3199         $bytesToReturn = $start > $bytes ? $bytes : $start;
3200     } else {    # read the requested number of bytes
3201         # leave enough bytes in the buffer to allow us to read
3202         # the boundary.  Thanks to Kevin Hendrick for finding
3203         # this one.
3204         $bytesToReturn = $bytes - (length($self->{BOUNDARY})+1);
3205     }
3206
3207     my $returnval=substr($self->{BUFFER},0,$bytesToReturn);
3208     substr($self->{BUFFER},0,$bytesToReturn)='';
3209     
3210     # If we hit the boundary, remove the CRLF from the end.
3211     return ($start > 0) ? substr($returnval,0,-2) : $returnval;
3212 }
3213 END_OF_FUNC
3214
3215
3216 # This fills up our internal buffer in such a way that the
3217 # boundary is never split between reads
3218 'fillBuffer' => <<'END_OF_FUNC',
3219 sub fillBuffer {
3220     my($self,$bytes) = @_;
3221     return unless $self->{LENGTH};
3222
3223     my($boundaryLength) = length($self->{BOUNDARY});
3224     my($bufferLength) = length($self->{BUFFER});
3225     my($bytesToRead) = $bytes - $bufferLength + $boundaryLength + 2;
3226     $bytesToRead = $self->{LENGTH} if $self->{LENGTH} < $bytesToRead;
3227
3228     # Try to read some data.  We may hang here if the browser is screwed up.  
3229     my $bytesRead = $self->{INTERFACE}->read_from_client($self->{IN},
3230                                                          \$self->{BUFFER},
3231                                                          $bytesToRead,
3232                                                          $bufferLength);
3233     $self->{BUFFER} = '' unless defined $self->{BUFFER};
3234
3235     # An apparent bug in the Apache server causes the read()
3236     # to return zero bytes repeatedly without blocking if the
3237     # remote user aborts during a file transfer.  I don't know how
3238     # they manage this, but the workaround is to abort if we get
3239     # more than SPIN_LOOP_MAX consecutive zero reads.
3240     if ($bytesRead == 0) {
3241         die  "CGI.pm: Server closed socket during multipart read (client aborted?).\n"
3242             if ($self->{ZERO_LOOP_COUNTER}++ >= $SPIN_LOOP_MAX);
3243     } else {
3244         $self->{ZERO_LOOP_COUNTER}=0;
3245     }
3246
3247     $self->{LENGTH} -= $bytesRead;
3248 }
3249 END_OF_FUNC
3250
3251
3252 # Return true when we've finished reading
3253 'eof' => <<'END_OF_FUNC'
3254 sub eof {
3255     my($self) = @_;
3256     return 1 if (length($self->{BUFFER}) == 0)
3257                  && ($self->{LENGTH} <= 0);
3258     undef;
3259 }
3260 END_OF_FUNC
3261
3262 );
3263 END_OF_AUTOLOAD
3264
3265 ####################################################################################
3266 ################################## TEMPORARY FILES #################################
3267 ####################################################################################
3268 package TempFile;
3269
3270 $SL = $CGI::SL;
3271 $MAC = $CGI::OS eq 'MACINTOSH';
3272 my ($vol) = $MAC ? MacPerl::Volumes() =~ /:(.*)/ : "";
3273 unless ($TMPDIRECTORY) {
3274     @TEMP=("${SL}usr${SL}tmp","${SL}var${SL}tmp",
3275            "C:${SL}temp","${SL}tmp","${SL}temp",
3276            "${vol}${SL}Temporary Items",
3277            "${SL}WWW_ROOT", "${SL}SYS\$SCRATCH");
3278     unshift(@TEMP,$ENV{'TMPDIR'}) if exists $ENV{'TMPDIR'};
3279
3280     # this feature was supposed to provide per-user tmpfiles, but
3281     # it is problematic.
3282     #    unshift(@TEMP,(getpwuid($<))[7].'/tmp') if $CGI::OS eq 'UNIX';
3283     # Rob: getpwuid() is unfortunately UNIX specific. On brain dead OS'es this
3284     #    : can generate a 'getpwuid() not implemented' exception, even though
3285     #    : it's never called.  Found under DOS/Win with the DJGPP perl port.
3286     #    : Refer to getpwuid() only at run-time if we're fortunate and have  UNIX.
3287     # unshift(@TEMP,(eval {(getpwuid($>))[7]}).'/tmp') if $CGI::OS eq 'UNIX' and $> != 0;
3288
3289     foreach (@TEMP) {
3290         do {$TMPDIRECTORY = $_; last} if -d $_ && -w _;
3291     }
3292 }
3293
3294 $TMPDIRECTORY  = $MAC ? "" : "." unless $TMPDIRECTORY;
3295 $MAXTRIES = 5000;
3296
3297 # cute feature, but overload implementation broke it
3298 # %OVERLOAD = ('""'=>'as_string');
3299 *TempFile::AUTOLOAD = \&CGI::AUTOLOAD;
3300
3301 ###############################################################################
3302 ################# THESE FUNCTIONS ARE AUTOLOADED ON DEMAND ####################
3303 ###############################################################################
3304 $AUTOLOADED_ROUTINES = '';      # prevent -w error
3305 $AUTOLOADED_ROUTINES=<<'END_OF_AUTOLOAD';
3306 %SUBS = (
3307
3308 'new' => <<'END_OF_FUNC',
3309 sub new {
3310     my($package,$sequence) = @_;
3311     my $filename;
3312     for (my $i = 0; $i < $MAXTRIES; $i++) {
3313         last if ! -f ($filename = sprintf("${TMPDIRECTORY}${SL}CGItemp%d",$sequence++));
3314     }
3315     # untaint the darn thing
3316     return unless $filename =~ m!^([a-zA-Z0-9_ '":/.\$\\]+)$!;
3317     $filename = $1;
3318     return bless \$filename;
3319 }
3320 END_OF_FUNC
3321
3322 'DESTROY' => <<'END_OF_FUNC',
3323 sub DESTROY {
3324     my($self) = @_;
3325     unlink $$self;              # get rid of the file
3326 }
3327 END_OF_FUNC
3328
3329 'as_string' => <<'END_OF_FUNC'
3330 sub as_string {
3331     my($self) = @_;
3332     return $$self;
3333 }
3334 END_OF_FUNC
3335
3336 );
3337 END_OF_AUTOLOAD
3338
3339 package CGI;
3340
3341 # We get a whole bunch of warnings about "possibly uninitialized variables"
3342 # when running with the -w switch.  Touch them all once to get rid of the
3343 # warnings.  This is ugly and I hate it.
3344 if ($^W) {
3345     $CGI::CGI = '';
3346     $CGI::CGI=<<EOF;
3347     $CGI::VERSION;
3348     $MultipartBuffer::SPIN_LOOP_MAX;
3349     $MultipartBuffer::CRLF;
3350     $MultipartBuffer::TIMEOUT;
3351     $MultipartBuffer::INITIAL_FILLUNIT;
3352 EOF
3353     ;
3354 }
3355
3356 1;
3357
3358 __END__
3359
3360 =head1 NAME
3361
3362 CGI - Simple Common Gateway Interface Class
3363
3364 =head1 SYNOPSIS
3365
3366   # CGI script that creates a fill-out form
3367   # and echoes back its values.
3368
3369   use CGI qw/:standard/;
3370   print header,
3371         start_html('A Simple Example'),
3372         h1('A Simple Example'),
3373         start_form,
3374         "What's your name? ",textfield('name'),p,
3375         "What's the combination?", p,
3376         checkbox_group(-name=>'words',
3377                        -values=>['eenie','meenie','minie','moe'],
3378                        -defaults=>['eenie','minie']), p,
3379         "What's your favorite color? ",
3380         popup_menu(-name=>'color',
3381                    -values=>['red','green','blue','chartreuse']),p,
3382         submit,
3383         end_form,
3384         hr;
3385
3386    if (param()) {
3387        print "Your name is",em(param('name')),p,
3388              "The keywords are: ",em(join(", ",param('words'))),p,
3389              "Your favorite color is ",em(param('color')),
3390              hr;
3391    }
3392
3393 =head1 ABSTRACT
3394
3395 This perl library uses perl5 objects to make it easy to create Web
3396 fill-out forms and parse their contents.  This package defines CGI
3397 objects, entities that contain the values of the current query string
3398 and other state variables.  Using a CGI object's methods, you can
3399 examine keywords and parameters passed to your script, and create
3400 forms whose initial values are taken from the current query (thereby
3401 preserving state information).  The module provides shortcut functions
3402 that produce boilerplate HTML, reducing typing and coding errors. It
3403 also provides functionality for some of the more advanced features of
3404 CGI scripting, including support for file uploads, cookies, cascading
3405 style sheets, server push, and frames.
3406
3407 CGI.pm also provides a simple function-oriented programming style for
3408 those who don't need its object-oriented features.
3409
3410 The current version of CGI.pm is available at
3411
3412   http://www.genome.wi.mit.edu/ftp/pub/software/WWW/cgi_docs.html
3413   ftp://ftp-genome.wi.mit.edu/pub/software/WWW/
3414
3415 =head1 DESCRIPTION
3416
3417 =head2 PROGRAMMING STYLE
3418
3419 There are two styles of programming with CGI.pm, an object-oriented
3420 style and a function-oriented style.  In the object-oriented style you
3421 create one or more CGI objects and then use object methods to create
3422 the various elements of the page.  Each CGI object starts out with the
3423 list of named parameters that were passed to your CGI script by the
3424 server.  You can modify the objects, save them to a file or database
3425 and recreate them.  Because each object corresponds to the "state" of
3426 the CGI script, and because each object's parameter list is
3427 independent of the others, this allows you to save the state of the
3428 script and restore it later.
3429
3430 For example, using the object oriented style, here is how you create
3431 a simple "Hello World" HTML page:
3432
3433    #!/usr/local/bin/perl -w
3434    use CGI;                             # load CGI routines
3435    $q = new CGI;                        # create new CGI object
3436    print $q->header,                    # create the HTTP header
3437          $q->start_html('hello world'), # start the HTML
3438          $q->h1('hello world'),         # level 1 header
3439          $q->end_html;                  # end the HTML
3440
3441 In the function-oriented style, there is one default CGI object that
3442 you rarely deal with directly.  Instead you just call functions to
3443 retrieve CGI parameters, create HTML tags, manage cookies, and so
3444 on.  This provides you with a cleaner programming interface, but
3445 limits you to using one CGI object at a time.  The following example
3446 prints the same page, but uses the function-oriented interface.
3447 The main differences are that we now need to import a set of functions
3448 into our name space (usually the "standard" functions), and we don't
3449 need to create the CGI object.
3450
3451    #!/usr/local/bin/perl
3452    use CGI qw/:standard/;           # load standard CGI routines
3453    print header,                    # create the HTTP header
3454          start_html('hello world'), # start the HTML
3455          h1('hello world'),         # level 1 header
3456          end_html;                  # end the HTML
3457
3458 The examples in this document mainly use the object-oriented style.
3459 See HOW TO IMPORT FUNCTIONS for important information on
3460 function-oriented programming in CGI.pm
3461
3462 =head2 CALLING CGI.PM ROUTINES
3463
3464 Most CGI.pm routines accept several arguments, sometimes as many as 20
3465 optional ones!  To simplify this interface, all routines use a named
3466 argument calling style that looks like this:
3467
3468    print $q->header(-type=>'image/gif',-expires=>'+3d');
3469
3470 Each argument name is preceded by a dash.  Neither case nor order
3471 matters in the argument list.  -type, -Type, and -TYPE are all
3472 acceptable.  In fact, only the first argument needs to begin with a
3473 dash.  If a dash is present in the first argument, CGI.pm assumes
3474 dashes for the subsequent ones.
3475
3476 Several routines are commonly called with just one argument.  In the
3477 case of these routines you can provide the single argument without an
3478 argument name.  header() happens to be one of these routines.  In this
3479 case, the single argument is the document type.
3480
3481    print $q->header('text/html');
3482
3483 Other such routines are documented below.
3484
3485 Sometimes named arguments expect a scalar, sometimes a reference to an
3486 array, and sometimes a reference to a hash.  Often, you can pass any
3487 type of argument and the routine will do whatever is most appropriate.
3488 For example, the param() routine is used to set a CGI parameter to a
3489 single or a multi-valued value.  The two cases are shown below:
3490
3491    $q->param(-name=>'veggie',-value=>'tomato');
3492    $q->param(-name=>'veggie',-value=>['tomato','tomahto','potato','potahto']);
3493
3494 A large number of routines in CGI.pm actually aren't specifically
3495 defined in the module, but are generated automatically as needed.
3496 These are the "HTML shortcuts," routines that generate HTML tags for
3497 use in dynamically-generated pages.  HTML tags have both attributes
3498 (the attribute="value" pairs within the tag itself) and contents (the
3499 part between the opening and closing pairs.)  To distinguish between
3500 attributes and contents, CGI.pm uses the convention of passing HTML
3501 attributes as a hash reference as the first argument, and the
3502 contents, if any, as any subsequent arguments.  It works out like
3503 this:
3504
3505    Code                           Generated HTML
3506    ----                           --------------
3507    h1()                           <H1>
3508    h1('some','contents');         <H1>some contents</H1>
3509    h1({-align=>left});            <H1 ALIGN="LEFT">
3510    h1({-align=>left},'contents'); <H1 ALIGN="LEFT">contents</H1>
3511
3512 HTML tags are described in more detail later.  
3513
3514 Many newcomers to CGI.pm are puzzled by the difference between the
3515 calling conventions for the HTML shortcuts, which require curly braces
3516 around the HTML tag attributes, and the calling conventions for other
3517 routines, which manage to generate attributes without the curly
3518 brackets.  Don't be confused.  As a convenience the curly braces are
3519 optional in all but the HTML shortcuts.  If you like, you can use
3520 curly braces when calling any routine that takes named arguments.  For
3521 example:
3522
3523    print $q->header( {-type=>'image/gif',-expires=>'+3d'} );
3524
3525 If you use the B<-w> switch, you will be warned that some CGI.pm argument
3526 names conflict with built-in Perl functions.  The most frequent of
3527 these is the -values argument, used to create multi-valued menus,
3528 radio button clusters and the like.  To get around this warning, you
3529 have several choices:
3530
3531 =over 4
3532
3533 =item 1. Use another name for the argument, if one is available.  For
3534 example, -value is an alias for -values.
3535
3536 =item 2. Change the capitalization, e.g. -Values
3537
3538 =item 3. Put quotes around the argument name, e.g. '-values'
3539
3540 =back
3541
3542 Many routines will do something useful with a named argument that it
3543 doesn't recognize.  For example, you can produce non-standard HTTP
3544 header fields by providing them as named arguments:
3545
3546   print $q->header(-type  =>  'text/html',
3547                    -cost  =>  'Three smackers',
3548                    -annoyance_level => 'high',
3549                    -complaints_to   => 'bit bucket');
3550
3551 This will produce the following nonstandard HTTP header:
3552
3553    HTTP/1.0 200 OK
3554    Cost: Three smackers
3555    Annoyance-level: high
3556    Complaints-to: bit bucket
3557    Content-type: text/html
3558
3559 Notice the way that underscores are translated automatically into
3560 hyphens.  HTML-generating routines perform a different type of
3561 translation. 
3562
3563 This feature allows you to keep up with the rapidly changing HTTP and
3564 HTML "standards".
3565
3566 =head2 CREATING A NEW QUERY OBJECT (OBJECT-ORIENTED STYLE):
3567
3568      $query = new CGI;
3569
3570 This will parse the input (from both POST and GET methods) and store
3571 it into a perl5 object called $query.  
3572
3573 =head2 CREATING A NEW QUERY OBJECT FROM AN INPUT FILE
3574
3575      $query = new CGI(INPUTFILE);
3576
3577 If you provide a file handle to the new() method, it will read
3578 parameters from the file (or STDIN, or whatever).  The file can be in
3579 any of the forms describing below under debugging (i.e. a series of
3580 newline delimited TAG=VALUE pairs will work).  Conveniently, this type
3581 of file is created by the save() method (see below).  Multiple records
3582 can be saved and restored.
3583
3584 Perl purists will be pleased to know that this syntax accepts
3585 references to file handles, or even references to filehandle globs,
3586 which is the "official" way to pass a filehandle:
3587
3588     $query = new CGI(\*STDIN);
3589
3590 You can also initialize the CGI object with a FileHandle or IO::File
3591 object.
3592
3593 If you are using the function-oriented interface and want to
3594 initialize CGI state from a file handle, the way to do this is with
3595 B<restore_parameters()>.  This will (re)initialize the
3596 default CGI object from the indicated file handle.
3597
3598     open (IN,"test.in") || die;
3599     restore_parameters(IN);
3600     close IN;
3601
3602 You can also initialize the query object from an associative array
3603 reference:
3604
3605     $query = new CGI( {'dinosaur'=>'barney',
3606                        'song'=>'I love you',
3607                        'friends'=>[qw/Jessica George Nancy/]}
3608                     );
3609
3610 or from a properly formatted, URL-escaped query string:
3611
3612     $query = new CGI('dinosaur=barney&color=purple');
3613
3614 or from a previously existing CGI object (currently this clones the
3615 parameter list, but none of the other object-specific fields, such as
3616 autoescaping):
3617
3618     $old_query = new CGI;
3619     $new_query = new CGI($old_query);
3620
3621 To create an empty query, initialize it from an empty string or hash:
3622
3623    $empty_query = new CGI("");
3624
3625        -or-
3626
3627    $empty_query = new CGI({});
3628
3629 =head2 FETCHING A LIST OF KEYWORDS FROM THE QUERY:
3630
3631      @keywords = $query->keywords
3632
3633 If the script was invoked as the result of an <ISINDEX> search, the
3634 parsed keywords can be obtained as an array using the keywords() method.
3635
3636 =head2 FETCHING THE NAMES OF ALL THE PARAMETERS PASSED TO YOUR SCRIPT:
3637
3638      @names = $query->param
3639
3640 If the script was invoked with a parameter list
3641 (e.g. "name1=value1&name2=value2&name3=value3"), the param() method
3642 will return the parameter names as a list.  If the script was invoked
3643 as an <ISINDEX> script and contains a string without ampersands
3644 (e.g. "value1+value2+value3") , there will be a single parameter named
3645 "keywords" containing the "+"-delimited keywords.
3646
3647 NOTE: As of version 1.5, the array of parameter names returned will
3648 be in the same order as they were submitted by the browser.
3649 Usually this order is the same as the order in which the 
3650 parameters are defined in the form (however, this isn't part
3651 of the spec, and so isn't guaranteed).
3652
3653 =head2 FETCHING THE VALUE OR VALUES OF A SINGLE NAMED PARAMETER:
3654
3655     @values = $query->param('foo');
3656
3657               -or-
3658
3659     $value = $query->param('foo');
3660
3661 Pass the param() method a single argument to fetch the value of the
3662 named parameter. If the parameter is multivalued (e.g. from multiple
3663 selections in a scrolling list), you can ask to receive an array.  Otherwise
3664 the method will return a single value.
3665
3666 If a value is not given in the query string, as in the queries
3667 "name1=&name2=" or "name1&name2", it will be returned as an empty
3668 string.  This feature is new in 2.63.
3669
3670 =head2 SETTING THE VALUE(S) OF A NAMED PARAMETER:
3671
3672     $query->param('foo','an','array','of','values');
3673
3674 This sets the value for the named parameter 'foo' to an array of
3675 values.  This is one way to change the value of a field AFTER
3676 the script has been invoked once before.  (Another way is with
3677 the -override parameter accepted by all methods that generate
3678 form elements.)
3679
3680 param() also recognizes a named parameter style of calling described
3681 in more detail later:
3682
3683     $query->param(-name=>'foo',-values=>['an','array','of','values']);
3684
3685                               -or-
3686
3687     $query->param(-name=>'foo',-value=>'the value');
3688
3689 =head2 APPENDING ADDITIONAL VALUES TO A NAMED PARAMETER:
3690
3691    $query->append(-name=>'foo',-values=>['yet','more','values']);
3692
3693 This adds a value or list of values to the named parameter.  The
3694 values are appended to the end of the parameter if it already exists.
3695 Otherwise the parameter is created.  Note that this method only
3696 recognizes the named argument calling syntax.
3697
3698 =head2 IMPORTING ALL PARAMETERS INTO A NAMESPACE:
3699
3700    $query->import_names('R');
3701
3702 This creates a series of variables in the 'R' namespace.  For example,
3703 $R::foo, @R:foo.  For keyword lists, a variable @R::keywords will appear.
3704 If no namespace is given, this method will assume 'Q'.
3705 WARNING:  don't import anything into 'main'; this is a major security
3706 risk!!!!
3707
3708 In older versions, this method was called B<import()>.  As of version 2.20, 
3709 this name has been removed completely to avoid conflict with the built-in
3710 Perl module B<import> operator.
3711
3712 =head2 DELETING A PARAMETER COMPLETELY:
3713
3714     $query->delete('foo');
3715
3716 This completely clears a parameter.  It sometimes useful for
3717 resetting parameters that you don't want passed down between
3718 script invocations.
3719
3720 If you are using the function call interface, use "Delete()" instead
3721 to avoid conflicts with Perl's built-in delete operator.
3722
3723 =head2 DELETING ALL PARAMETERS:
3724
3725    $query->delete_all();
3726
3727 This clears the CGI object completely.  It might be useful to ensure
3728 that all the defaults are taken when you create a fill-out form.
3729
3730 Use Delete_all() instead if you are using the function call interface.
3731
3732 =head2 DIRECT ACCESS TO THE PARAMETER LIST:
3733
3734    $q->param_fetch('address')->[1] = '1313 Mockingbird Lane';
3735    unshift @{$q->param_fetch(-name=>'address')},'George Munster';
3736
3737 If you need access to the parameter list in a way that isn't covered
3738 by the methods above, you can obtain a direct reference to it by
3739 calling the B<param_fetch()> method with the name of the .  This
3740 will return an array reference to the named parameters, which you then
3741 can manipulate in any way you like.
3742
3743 You can also use a named argument style using the B<-name> argument.
3744
3745 =head2 FETCHING THE PARAMETER LIST AS A HASH:
3746
3747     $params = $q->Vars;
3748     print $params->{'address'};
3749     @foo = split("\0",$params->{'foo'});
3750     %params = $q->Vars;
3751
3752     use CGI ':cgi-lib';
3753     $params = Vars;
3754
3755 Many people want to fetch the entire parameter list as a hash in which
3756 the keys are the names of the CGI parameters, and the values are the
3757 parameters' values.  The Vars() method does this.  Called in a scalar
3758 context, it returns the parameter list as a tied hash reference.
3759 Changing a key changes the value of the parameter in the underlying
3760 CGI parameter list.  Called in a list context, it returns the
3761 parameter list as an ordinary hash.  This allows you to read the
3762 contents of the parameter list, but not to change it.
3763
3764 When using this, the thing you must watch out for are multivalued CGI
3765 parameters.  Because a hash cannot distinguish between scalar and
3766 list context, multivalued parameters will be returned as a packed
3767 string, separated by the "\0" (null) character.  You must split this
3768 packed string in order to get at the individual values.  This is the
3769 convention introduced long ago by Steve Brenner in his cgi-lib.pl
3770 module for Perl version 4.
3771
3772 If you wish to use Vars() as a function, import the I<:cgi-lib> set of
3773 function calls (also see the section on CGI-LIB compatibility).
3774
3775 =head2 SAVING THE STATE OF THE SCRIPT TO A FILE:
3776
3777     $query->save(FILEHANDLE)
3778
3779 This will write the current state of the form to the provided
3780 filehandle.  You can read it back in by providing a filehandle
3781 to the new() method.  Note that the filehandle can be a file, a pipe,
3782 or whatever!
3783
3784 The format of the saved file is:
3785
3786         NAME1=VALUE1
3787         NAME1=VALUE1'
3788         NAME2=VALUE2
3789         NAME3=VALUE3
3790         =
3791
3792 Both name and value are URL escaped.  Multi-valued CGI parameters are
3793 represented as repeated names.  A session record is delimited by a
3794 single = symbol.  You can write out multiple records and read them
3795 back in with several calls to B<new>.  You can do this across several
3796 sessions by opening the file in append mode, allowing you to create
3797 primitive guest books, or to keep a history of users' queries.  Here's
3798 a short example of creating multiple session records:
3799
3800    use CGI;
3801
3802    open (OUT,">>test.out") || die;
3803    $records = 5;
3804    foreach (0..$records) {
3805        my $q = new CGI;
3806        $q->param(-name=>'counter',-value=>$_);
3807        $q->save(OUT);
3808    }
3809    close OUT;
3810
3811    # reopen for reading
3812    open (IN,"test.out") || die;
3813    while (!eof(IN)) {
3814        my $q = new CGI(IN);
3815        print $q->param('counter'),"\n";
3816    }
3817
3818 The file format used for save/restore is identical to that used by the
3819 Whitehead Genome Center's data exchange format "Boulderio", and can be
3820 manipulated and even databased using Boulderio utilities.  See
3821
3822   http://stein.cshl.org/boulder/
3823
3824 for further details.
3825
3826 If you wish to use this method from the function-oriented (non-OO)
3827 interface, the exported name for this method is B<save_parameters()>.
3828
3829 =head2 RETRIEVING CGI ERRORS
3830
3831 Errors can occur while processing user input, particularly when
3832 processing uploaded files.  When these errors occur, CGI will stop
3833 processing and return an empty parameter list.  You can test for
3834 the existence and nature of errors using the I<cgi_error()> function.
3835 The error messages are formatted as HTTP status codes. You can either
3836 incorporate the error text into an HTML page, or use it as the value
3837 of the HTTP status:
3838
3839     my $error = $q->cgi_error;
3840     if ($error) {
3841         print $q->header(-status=>$error),
3842               $q->start_html('Problems'),
3843               $q->h2('Request not processed'),
3844               $q->strong($error);
3845         exit 0;
3846     }
3847
3848 When using the function-oriented interface (see the next section),
3849 errors may only occur the first time you call I<param()>. Be ready
3850 for this!
3851
3852 =head2 USING THE FUNCTION-ORIENTED INTERFACE
3853
3854 To use the function-oriented interface, you must specify which CGI.pm
3855 routines or sets of routines to import into your script's namespace.
3856 There is a small overhead associated with this importation, but it
3857 isn't much.
3858
3859    use CGI <list of methods>;
3860
3861 The listed methods will be imported into the current package; you can
3862 call them directly without creating a CGI object first.  This example
3863 shows how to import the B<param()> and B<header()>
3864 methods, and then use them directly:
3865
3866    use CGI 'param','header';
3867    print header('text/plain');
3868    $zipcode = param('zipcode');
3869
3870 More frequently, you'll import common sets of functions by referring
3871 to the groups by name.  All function sets are preceded with a ":"
3872 character as in ":html3" (for tags defined in the HTML 3 standard).
3873
3874 Here is a list of the function sets you can import:
3875
3876 =over 4
3877
3878 =item B<:cgi>
3879
3880 Import all CGI-handling methods, such as B<param()>, B<path_info()>
3881 and the like.
3882
3883 =item B<:form>
3884
3885 Import all fill-out form generating methods, such as B<textfield()>.
3886
3887 =item B<:html2>
3888
3889 Import all methods that generate HTML 2.0 standard elements.
3890
3891 =item B<:html3>
3892
3893 Import all methods that generate HTML 3.0 proposed elements (such as
3894 <table>, <super> and <sub>).
3895
3896 =item B<:netscape>
3897
3898 Import all methods that generate Netscape-specific HTML extensions.
3899
3900 =item B<:html>
3901
3902 Import all HTML-generating shortcuts (i.e. 'html2' + 'html3' +
3903 'netscape')...
3904
3905 =item B<:standard>
3906
3907 Import "standard" features, 'html2', 'html3', 'form' and 'cgi'.
3908
3909 =item B<:all>
3910
3911 Import all the available methods.  For the full list, see the CGI.pm
3912 code, where the variable %EXPORT_TAGS is defined.
3913
3914 =back
3915
3916 If you import a function name that is not part of CGI.pm, the module
3917 will treat it as a new HTML tag and generate the appropriate
3918 subroutine.  You can then use it like any other HTML tag.  This is to
3919 provide for the rapidly-evolving HTML "standard."  For example, say
3920 Microsoft comes out with a new tag called <GRADIENT> (which causes the
3921 user's desktop to be flooded with a rotating gradient fill until his
3922 machine reboots).  You don't need to wait for a new version of CGI.pm
3923 to start using it immediately:
3924
3925    use CGI qw/:standard :html3 gradient/;
3926    print gradient({-start=>'red',-end=>'blue'});
3927
3928 Note that in the interests of execution speed CGI.pm does B<not> use
3929 the standard L<Exporter> syntax for specifying load symbols.  This may
3930 change in the future.
3931
3932 If you import any of the state-maintaining CGI or form-generating
3933 methods, a default CGI object will be created and initialized
3934 automatically the first time you use any of the methods that require
3935 one to be present.  This includes B<param()>, B<textfield()>,
3936 B<submit()> and the like.  (If you need direct access to the CGI
3937 object, you can find it in the global variable B<$CGI::Q>).  By
3938 importing CGI.pm methods, you can create visually elegant scripts:
3939
3940    use CGI qw/:standard/;
3941    print 
3942        header,
3943        start_html('Simple Script'),
3944        h1('Simple Script'),
3945        start_form,
3946        "What's your name? ",textfield('name'),p,
3947        "What's the combination?",
3948        checkbox_group(-name=>'words',
3949                       -values=>['eenie','meenie','minie','moe'],
3950                       -defaults=>['eenie','moe']),p,
3951        "What's your favorite color?",
3952        popup_menu(-name=>'color',
3953                   -values=>['red','green','blue','chartreuse']),p,
3954        submit,
3955        end_form,
3956        hr,"\n";
3957
3958     if (param) {
3959        print 
3960            "Your name is ",em(param('name')),p,
3961            "The keywords are: ",em(join(", ",param('words'))),p,
3962            "Your favorite color is ",em(param('color')),".\n";
3963     }
3964     print end_html;
3965
3966 =head2 PRAGMAS
3967
3968 In addition to the function sets, there are a number of pragmas that
3969 you can import.  Pragmas, which are always preceded by a hyphen,
3970 change the way that CGI.pm functions in various ways.  Pragmas,
3971 function sets, and individual functions can all be imported in the
3972 same use() line.  For example, the following use statement imports the
3973 standard set of functions and enables debugging mode (pragma
3974 -debug):
3975
3976    use CGI qw/:standard -debug/;
3977
3978 The current list of pragmas is as follows:
3979
3980 =over 4
3981
3982 =item -any
3983
3984 When you I<use CGI -any>, then any method that the query object
3985 doesn't recognize will be interpreted as a new HTML tag.  This allows
3986 you to support the next I<ad hoc> Netscape or Microsoft HTML
3987 extension.  This lets you go wild with new and unsupported tags:
3988
3989    use CGI qw(-any);
3990    $q=new CGI;
3991    print $q->gradient({speed=>'fast',start=>'red',end=>'blue'});
3992
3993 Since using <cite>any</cite> causes any mistyped method name
3994 to be interpreted as an HTML tag, use it with care or not at
3995 all.
3996
3997 =item -compile
3998
3999 This causes the indicated autoloaded methods to be compiled up front,
4000 rather than deferred to later.  This is useful for scripts that run
4001 for an extended period of time under FastCGI or mod_perl, and for
4002 those destined to be crunched by Malcom Beattie's Perl compiler.  Use
4003 it in conjunction with the methods or method families you plan to use.
4004
4005    use CGI qw(-compile :standard :html3);
4006
4007 or even
4008
4009    use CGI qw(-compile :all);
4010
4011 Note that using the -compile pragma in this way will always have
4012 the effect of importing the compiled functions into the current
4013 namespace.  If you want to compile without importing use the
4014 compile() method instead (see below).
4015
4016 =item -nosticky
4017
4018 This makes CGI.pm not generating the hidden fields .submit
4019 and .cgifields. It is very useful if you don't want to
4020 have the hidden fields appear in the querystring in a GET method.
4021 For example, a search script generated this way will have
4022 a very nice url with search parameters for bookmarking.
4023
4024 =item -no_xhtml
4025
4026 By default, CGI.pm versions 2.69 and higher emit XHTML
4027 (http://www.w3.org/TR/xhtml1/).  The -no_xhtml pragma disables this
4028 feature.  Thanks to Michalis Kabrianis <kabrianis@hellug.gr> for this
4029 feature.
4030
4031 =item -nph
4032
4033 This makes CGI.pm produce a header appropriate for an NPH (no
4034 parsed header) script.  You may need to do other things as well
4035 to tell the server that the script is NPH.  See the discussion
4036 of NPH scripts below.
4037
4038 =item -newstyle_urls
4039
4040 Separate the name=value pairs in CGI parameter query strings with
4041 semicolons rather than ampersands.  For example:
4042
4043    ?name=fred;age=24;favorite_color=3
4044
4045 Semicolon-delimited query strings are always accepted, but will not be
4046 emitted by self_url() and query_string() unless the -newstyle_urls
4047 pragma is specified.
4048
4049 This became the default in version 2.64.
4050
4051 =item -oldstyle_urls
4052
4053 Separate the name=value pairs in CGI parameter query strings with
4054 ampersands rather than semicolons.  This is no longer the default.
4055
4056 =item -autoload
4057
4058 This overrides the autoloader so that any function in your program
4059 that is not recognized is referred to CGI.pm for possible evaluation.
4060 This allows you to use all the CGI.pm functions without adding them to
4061 your symbol table, which is of concern for mod_perl users who are
4062 worried about memory consumption.  I<Warning:> when
4063 I<-autoload> is in effect, you cannot use "poetry mode"
4064 (functions without the parenthesis).  Use I<hr()> rather
4065 than I<hr>, or add something like I<use subs qw/hr p header/> 
4066 to the top of your script.
4067
4068 =item -no_debug
4069
4070 This turns off the command-line processing features.  If you want to
4071 run a CGI.pm script from the command line to produce HTML, and you
4072 don't want it to read CGI parameters from the command line or STDIN,
4073 then use this pragma:
4074
4075    use CGI qw(-no_debug :standard);
4076
4077 =item -debug
4078
4079 This turns on full debugging.  In addition to reading CGI arguments
4080 from the command-line processing, CGI.pm will pause and try to read
4081 arguments from STDIN, producing the message "(offline mode: enter
4082 name=value pairs on standard input)" features.
4083
4084 See the section on debugging for more details.
4085
4086 =item -private_tempfiles
4087
4088 CGI.pm can process uploaded file. Ordinarily it spools the uploaded
4089 file to a temporary directory, then deletes the file when done.
4090 However, this opens the risk of eavesdropping as described in the file
4091 upload section.  Another CGI script author could peek at this data
4092 during the upload, even if it is confidential information. On Unix
4093 systems, the -private_tempfiles pragma will cause the temporary file
4094 to be unlinked as soon as it is opened and before any data is written
4095 into it, reducing, but not eliminating the risk of eavesdropping
4096 (there is still a potential race condition).  To make life harder for
4097 the attacker, the program chooses tempfile names by calculating a 32
4098 bit checksum of the incoming HTTP headers.
4099
4100 To ensure that the temporary file cannot be read by other CGI scripts,
4101 use suEXEC or a CGI wrapper program to run your script.  The temporary
4102 file is created with mode 0600 (neither world nor group readable).
4103
4104 The temporary directory is selected using the following algorithm:
4105
4106     1. if the current user (e.g. "nobody") has a directory named
4107     "tmp" in its home directory, use that (Unix systems only).
4108
4109     2. if the environment variable TMPDIR exists, use the location
4110     indicated.
4111
4112     3. Otherwise try the locations /usr/tmp, /var/tmp, C:\temp,
4113     /tmp, /temp, ::Temporary Items, and \WWW_ROOT.
4114
4115 Each of these locations is checked that it is a directory and is
4116 writable.  If not, the algorithm tries the next choice.
4117
4118 =back
4119
4120 =head2 SPECIAL FORMS FOR IMPORTING HTML-TAG FUNCTIONS
4121
4122 Many of the methods generate HTML tags.  As described below, tag
4123 functions automatically generate both the opening and closing tags.
4124 For example:
4125
4126   print h1('Level 1 Header');
4127
4128 produces
4129
4130   <H1>Level 1 Header</H1>
4131
4132 There will be some times when you want to produce the start and end
4133 tags yourself.  In this case, you can use the form start_I<tag_name>
4134 and end_I<tag_name>, as in:
4135
4136   print start_h1,'Level 1 Header',end_h1;
4137
4138 With a few exceptions (described below), start_I<tag_name> and
4139 end_I<tag_name> functions are not generated automatically when you
4140 I<use CGI>.  However, you can specify the tags you want to generate
4141 I<start/end> functions for by putting an asterisk in front of their
4142 name, or, alternatively, requesting either "start_I<tag_name>" or
4143 "end_I<tag_name>" in the import list.
4144
4145 Example:
4146
4147   use CGI qw/:standard *table start_ul/;
4148
4149 In this example, the following functions are generated in addition to
4150 the standard ones:
4151
4152 =over 4
4153
4154 =item 1. start_table() (generates a <TABLE> tag)
4155
4156 =item 2. end_table() (generates a </TABLE> tag)
4157
4158 =item 3. start_ul() (generates a <UL> tag)
4159
4160 =item 4. end_ul() (generates a </UL> tag)
4161
4162 =back
4163
4164 =head1 GENERATING DYNAMIC DOCUMENTS
4165
4166 Most of CGI.pm's functions deal with creating documents on the fly.
4167 Generally you will produce the HTTP header first, followed by the
4168 document itself.  CGI.pm provides functions for generating HTTP
4169 headers of various types as well as for generating HTML.  For creating
4170 GIF images, see the GD.pm module.
4171
4172 Each of these functions produces a fragment of HTML or HTTP which you
4173 can print out directly so that it displays in the browser window,
4174 append to a string, or save to a file for later use.
4175
4176 =head2 CREATING A STANDARD HTTP HEADER:
4177
4178 Normally the first thing you will do in any CGI script is print out an
4179 HTTP header.  This tells the browser what type of document to expect,
4180 and gives other optional information, such as the language, expiration
4181 date, and whether to cache the document.  The header can also be
4182 manipulated for special purposes, such as server push and pay per view
4183 pages.
4184
4185         print $query->header;
4186
4187              -or-
4188
4189         print $query->header('image/gif');
4190
4191              -or-
4192
4193         print $query->header('text/html','204 No response');
4194
4195              -or-
4196
4197         print $query->header(-type=>'image/gif',
4198                              -nph=>1,
4199                              -status=>'402 Payment required',
4200                              -expires=>'+3d',
4201                              -cookie=>$cookie,
4202                              -charset=>'utf-7',
4203                              -attachment=>'foo.gif',
4204                              -Cost=>'$2.00');
4205
4206 header() returns the Content-type: header.  You can provide your own
4207 MIME type if you choose, otherwise it defaults to text/html.  An
4208 optional second parameter specifies the status code and a human-readable
4209 message.  For example, you can specify 204, "No response" to create a
4210 script that tells the browser to do nothing at all.
4211
4212 The last example shows the named argument style for passing arguments
4213 to the CGI methods using named parameters.  Recognized parameters are
4214 B<-type>, B<-status>, B<-expires>, and B<-cookie>.  Any other named
4215 parameters will be stripped of their initial hyphens and turned into
4216 header fields, allowing you to specify any HTTP header you desire.
4217 Internal underscores will be turned into hyphens:
4218
4219     print $query->header(-Content_length=>3002);
4220
4221 Most browsers will not cache the output from CGI scripts.  Every time
4222 the browser reloads the page, the script is invoked anew.  You can
4223 change this behavior with the B<-expires> parameter.  When you specify
4224 an absolute or relative expiration interval with this parameter, some
4225 browsers and proxy servers will cache the script's output until the
4226 indicated expiration date.  The following forms are all valid for the
4227 -expires field:
4228
4229         +30s                              30 seconds from now
4230         +10m                              ten minutes from now
4231         +1h                               one hour from now
4232         -1d                               yesterday (i.e. "ASAP!")
4233         now                               immediately
4234         +3M                               in three months
4235         +10y                              in ten years time
4236         Thursday, 25-Apr-1999 00:40:33 GMT  at the indicated time & date
4237
4238 The B<-cookie> parameter generates a header that tells the browser to provide
4239 a "magic cookie" during all subsequent transactions with your script.
4240 Netscape cookies have a special format that includes interesting attributes
4241 such as expiration time.  Use the cookie() method to create and retrieve
4242 session cookies.
4243
4244 The B<-nph> parameter, if set to a true value, will issue the correct
4245 headers to work with a NPH (no-parse-header) script.  This is important
4246 to use with certain servers that expect all their scripts to be NPH.
4247
4248 The B<-charset> parameter can be used to control the character set
4249 sent to the browser.  If not provided, defaults to ISO-8859-1.  As a
4250 side effect, this sets the charset() method as well.
4251
4252 The B<-attachment> parameter can be used to turn the page into an
4253 attachment.  Instead of displaying the page, some browsers will prompt
4254 the user to save it to disk.  The value of the argument is the
4255 suggested name for the saved file.  In order for this to work, you may
4256 have to set the B<-type> to "application/octet-stream".
4257
4258 =head2 GENERATING A REDIRECTION HEADER
4259
4260    print $query->redirect('http://somewhere.else/in/movie/land');
4261
4262 Sometimes you don't want to produce a document yourself, but simply
4263 redirect the browser elsewhere, perhaps choosing a URL based on the
4264 time of day or the identity of the user.  
4265
4266 The redirect() function redirects the browser to a different URL.  If
4267 you use redirection like this, you should B<not> print out a header as
4268 well.
4269
4270 One hint I can offer is that relative links may not work correctly
4271 when you generate a redirection to another document on your site.
4272 This is due to a well-intentioned optimization that some servers use.
4273 The solution to this is to use the full URL (including the http: part)
4274 of the document you are redirecting to.
4275
4276 You can also use named arguments:
4277
4278     print $query->redirect(-uri=>'http://somewhere.else/in/movie/land',
4279                            -nph=>1);
4280
4281 The B<-nph> parameter, if set to a true value, will issue the correct
4282 headers to work with a NPH (no-parse-header) script.  This is important
4283 to use with certain servers, such as Microsoft Internet Explorer, which
4284 expect all their scripts to be NPH.
4285
4286 =head2 CREATING THE HTML DOCUMENT HEADER
4287
4288    print $query->start_html(-title=>'Secrets of the Pyramids',
4289                             -author=>'fred@capricorn.org',
4290                             -base=>'true',
4291                             -target=>'_blank',
4292                             -meta=>{'keywords'=>'pharaoh secret mummy',
4293                                     'copyright'=>'copyright 1996 King Tut'},
4294                             -style=>{'src'=>'/styles/style1.css'},
4295                             -BGCOLOR=>'blue');
4296
4297 After creating the HTTP header, most CGI scripts will start writing
4298 out an HTML document.  The start_html() routine creates the top of the
4299 page, along with a lot of optional information that controls the
4300 page's appearance and behavior.
4301
4302 This method returns a canned HTML header and the opening <BODY> tag.
4303 All parameters are optional.  In the named parameter form, recognized
4304 parameters are -title, -author, -base, -xbase, -dtd, -lang and -target
4305 (see below for the explanation).  Any additional parameters you
4306 provide, such as the Netscape unofficial BGCOLOR attribute, are added
4307 to the <BODY> tag.  Additional parameters must be proceeded by a
4308 hyphen.
4309
4310 The argument B<-xbase> allows you to provide an HREF for the <BASE> tag
4311 different from the current location, as in
4312
4313     -xbase=>"http://home.mcom.com/"
4314
4315 All relative links will be interpreted relative to this tag.
4316
4317 The argument B<-target> allows you to provide a default target frame
4318 for all the links and fill-out forms on the page.  B<This is a
4319 non-standard HTTP feature which only works with Netscape browsers!>
4320 See the Netscape documentation on frames for details of how to
4321 manipulate this.
4322
4323     -target=>"answer_window"
4324
4325 All relative links will be interpreted relative to this tag.
4326 You add arbitrary meta information to the header with the B<-meta>
4327 argument.  This argument expects a reference to an associative array
4328 containing name/value pairs of meta information.  These will be turned
4329 into a series of header <META> tags that look something like this:
4330
4331     <META NAME="keywords" CONTENT="pharaoh secret mummy">
4332     <META NAME="description" CONTENT="copyright 1996 King Tut">
4333
4334 To create an HTTP-EQUIV type of <META> tag, use B<-head>, described
4335 below.
4336
4337 The B<-style> argument is used to incorporate cascading stylesheets
4338 into your code.  See the section on CASCADING STYLESHEETS for more
4339 information.
4340
4341 The B<-lang> argument is used to incorporate a language attribute into
4342 the <HTML> tag.  The default if not specified is "en-US" for US
4343 English.  For example:
4344
4345     print $q->header(-lang=>'fr-CA');
4346
4347 You can place other arbitrary HTML elements to the <HEAD> section with the
4348 B<-head> tag.  For example, to place the rarely-used <LINK> element in the
4349 head section, use this:
4350
4351     print start_html(-head=>Link({-rel=>'next',
4352                                   -href=>'http://www.capricorn.com/s2.html'}));
4353
4354 To incorporate multiple HTML elements into the <HEAD> section, just pass an
4355 array reference:
4356
4357     print start_html(-head=>[ 
4358                              Link({-rel=>'next',
4359                                    -href=>'http://www.capricorn.com/s2.html'}),
4360                              Link({-rel=>'previous',
4361                                    -href=>'http://www.capricorn.com/s1.html'})
4362                              ]
4363                      );
4364
4365 And here's how to create an HTTP-EQUIV <META> tag:
4366
4367       print header(-head=>meta({-http_equiv => 'Content-Type',
4368                                 -content    => 'text/html'}))
4369
4370
4371 JAVASCRIPTING: The B<-script>, B<-noScript>, B<-onLoad>,
4372 B<-onMouseOver>, B<-onMouseOut> and B<-onUnload> parameters are used
4373 to add Netscape JavaScript calls to your pages.  B<-script> should
4374 point to a block of text containing JavaScript function definitions.
4375 This block will be placed within a <SCRIPT> block inside the HTML (not
4376 HTTP) header.  The block is placed in the header in order to give your
4377 page a fighting chance of having all its JavaScript functions in place
4378 even if the user presses the stop button before the page has loaded
4379 completely.  CGI.pm attempts to format the script in such a way that
4380 JavaScript-naive browsers will not choke on the code: unfortunately
4381 there are some browsers, such as Chimera for Unix, that get confused
4382 by it nevertheless.
4383
4384 The B<-onLoad> and B<-onUnload> parameters point to fragments of JavaScript
4385 code to execute when the page is respectively opened and closed by the
4386 browser.  Usually these parameters are calls to functions defined in the
4387 B<-script> field:
4388
4389       $query = new CGI;
4390       print $query->header;
4391       $JSCRIPT=<<END;
4392       // Ask a silly question
4393       function riddle_me_this() {
4394          var r = prompt("What walks on four legs in the morning, " +
4395                        "two legs in the afternoon, " +
4396                        "and three legs in the evening?");
4397          response(r);
4398       }
4399       // Get a silly answer
4400       function response(answer) {
4401          if (answer == "man")
4402             alert("Right you are!");
4403          else
4404             alert("Wrong!  Guess again.");
4405       }
4406       END
4407       print $query->start_html(-title=>'The Riddle of the Sphinx',
4408                                -script=>$JSCRIPT);
4409
4410 Use the B<-noScript> parameter to pass some HTML text that will be displayed on 
4411 browsers that do not have JavaScript (or browsers where JavaScript is turned
4412 off).
4413
4414 Netscape 3.0 recognizes several attributes of the <SCRIPT> tag,
4415 including LANGUAGE and SRC.  The latter is particularly interesting,
4416 as it allows you to keep the JavaScript code in a file or CGI script
4417 rather than cluttering up each page with the source.  To use these
4418 attributes pass a HASH reference in the B<-script> parameter containing
4419 one or more of -language, -src, or -code:
4420
4421     print $q->start_html(-title=>'The Riddle of the Sphinx',
4422                          -script=>{-language=>'JAVASCRIPT',
4423                                    -src=>'/javascript/sphinx.js'}
4424                          );
4425
4426     print $q->(-title=>'The Riddle of the Sphinx',
4427                -script=>{-language=>'PERLSCRIPT',
4428                          -code=>'print "hello world!\n;"'}
4429                );
4430
4431
4432 A final feature allows you to incorporate multiple <SCRIPT> sections into the
4433 header.  Just pass the list of script sections as an array reference.
4434 this allows you to specify different source files for different dialects
4435 of JavaScript.  Example:     
4436
4437      print $q->start_html(-title=>'The Riddle of the Sphinx',
4438                           -script=>[
4439                                     { -language => 'JavaScript1.0',
4440                                       -src      => '/javascript/utilities10.js'
4441                                     },
4442                                     { -language => 'JavaScript1.1',
4443                                       -src      => '/javascript/utilities11.js'
4444                                     },
4445                                     { -language => 'JavaScript1.2',
4446                                       -src      => '/javascript/utilities12.js'
4447                                     },
4448                                     { -language => 'JavaScript28.2',
4449                                       -src      => '/javascript/utilities219.js'
4450                                     }
4451                                  ]
4452                              );
4453      </pre>
4454
4455 If this looks a bit extreme, take my advice and stick with straight CGI scripting.  
4456
4457 See
4458
4459    http://home.netscape.com/eng/mozilla/2.0/handbook/javascript/
4460
4461 for more information about JavaScript.
4462
4463 The old-style positional parameters are as follows:
4464
4465 =over 4
4466
4467 =item B<Parameters:>
4468
4469 =item 1.
4470
4471 The title
4472
4473 =item 2.
4474
4475 The author's e-mail address (will create a <LINK REV="MADE"> tag if present
4476
4477 =item 3.
4478
4479 A 'true' flag if you want to include a <BASE> tag in the header.  This
4480 helps resolve relative addresses to absolute ones when the document is moved, 
4481 but makes the document hierarchy non-portable.  Use with care!
4482
4483 =item 4, 5, 6...
4484
4485 Any other parameters you want to include in the <BODY> tag.  This is a good
4486 place to put Netscape extensions, such as colors and wallpaper patterns.
4487
4488 =back
4489
4490 =head2 ENDING THE HTML DOCUMENT:
4491
4492         print $query->end_html
4493
4494 This ends an HTML document by printing the </BODY></HTML> tags.
4495
4496 =head2 CREATING A SELF-REFERENCING URL THAT PRESERVES STATE INFORMATION:
4497
4498     $myself = $query->self_url;
4499     print q(<A HREF="$myself">I'm talking to myself.</A>);
4500
4501 self_url() will return a URL, that, when selected, will reinvoke
4502 this script with all its state information intact.  This is most
4503 useful when you want to jump around within the document using
4504 internal anchors but you don't want to disrupt the current contents
4505 of the form(s).  Something like this will do the trick.
4506
4507      $myself = $query->self_url;
4508      print "<A HREF=$myself#table1>See table 1</A>";
4509      print "<A HREF=$myself#table2>See table 2</A>";
4510      print "<A HREF=$myself#yourself>See for yourself</A>";
4511
4512 If you want more control over what's returned, using the B<url()>
4513 method instead.
4514
4515 You can also retrieve the unprocessed query string with query_string():
4516
4517     $the_string = $query->query_string;
4518
4519 =head2 OBTAINING THE SCRIPT'S URL
4520
4521     $full_url      = $query->url();
4522     $full_url      = $query->url(-full=>1);  #alternative syntax
4523     $relative_url  = $query->url(-relative=>1);
4524     $absolute_url  = $query->url(-absolute=>1);
4525     $url_with_path = $query->url(-path_info=>1);
4526     $url_with_path_and_query = $query->url(-path_info=>1,-query=>1);
4527     $netloc        = $query->url(-base => 1);
4528
4529 B<url()> returns the script's URL in a variety of formats.  Called
4530 without any arguments, it returns the full form of the URL, including
4531 host name and port number
4532
4533     http://your.host.com/path/to/script.cgi
4534
4535 You can modify this format with the following named arguments:
4536
4537 =over 4
4538
4539 =item B<-absolute>
4540
4541 If true, produce an absolute URL, e.g.
4542
4543     /path/to/script.cgi
4544
4545 =item B<-relative>
4546
4547 Produce a relative URL.  This is useful if you want to reinvoke your
4548 script with different parameters. For example:
4549
4550     script.cgi
4551
4552 =item B<-full>
4553
4554 Produce the full URL, exactly as if called without any arguments.
4555 This overrides the -relative and -absolute arguments.
4556
4557 =item B<-path> (B<-path_info>)
4558
4559 Append the additional path information to the URL.  This can be
4560 combined with B<-full>, B<-absolute> or B<-relative>.  B<-path_info>
4561 is provided as a synonym.
4562
4563 =item B<-query> (B<-query_string>)
4564
4565 Append the query string to the URL.  This can be combined with
4566 B<-full>, B<-absolute> or B<-relative>.  B<-query_string> is provided
4567 as a synonym.
4568
4569 =item B<-base>
4570
4571 Generate just the protocol and net location, as in http://www.foo.com:8000
4572
4573 =back
4574
4575 =head2 MIXING POST AND URL PARAMETERS
4576
4577    $color = $query-&gt;url_param('color');
4578
4579 It is possible for a script to receive CGI parameters in the URL as
4580 well as in the fill-out form by creating a form that POSTs to a URL
4581 containing a query string (a "?" mark followed by arguments).  The
4582 B<param()> method will always return the contents of the POSTed
4583 fill-out form, ignoring the URL's query string.  To retrieve URL
4584 parameters, call the B<url_param()> method.  Use it in the same way as
4585 B<param()>.  The main difference is that it allows you to read the
4586 parameters, but not set them.
4587
4588
4589 Under no circumstances will the contents of the URL query string
4590 interfere with similarly-named CGI parameters in POSTed forms.  If you
4591 try to mix a URL query string with a form submitted with the GET
4592 method, the results will not be what you expect.
4593
4594 =head1 CREATING STANDARD HTML ELEMENTS:
4595
4596 CGI.pm defines general HTML shortcut methods for most, if not all of
4597 the HTML 3 and HTML 4 tags.  HTML shortcuts are named after a single
4598 HTML element and return a fragment of HTML text that you can then
4599 print or manipulate as you like.  Each shortcut returns a fragment of
4600 HTML code that you can append to a string, save to a file, or, most
4601 commonly, print out so that it displays in the browser window.
4602
4603 This example shows how to use the HTML methods:
4604
4605    $q = new CGI;
4606    print $q->blockquote(
4607                      "Many years ago on the island of",
4608                      $q->a({href=>"http://crete.org/"},"Crete"),
4609                      "there lived a Minotaur named",
4610                      $q->strong("Fred."),
4611                     ),
4612        $q->hr;
4613
4614 This results in the following HTML code (extra newlines have been
4615 added for readability):
4616
4617    <blockquote>
4618    Many years ago on the island of
4619    <a HREF="http://crete.org/">Crete</a> there lived
4620    a minotaur named <strong>Fred.</strong> 
4621    </blockquote>
4622    <hr>
4623
4624 If you find the syntax for calling the HTML shortcuts awkward, you can
4625 import them into your namespace and dispense with the object syntax
4626 completely (see the next section for more details):
4627
4628    use CGI ':standard';
4629    print blockquote(
4630       "Many years ago on the island of",
4631       a({href=>"http://crete.org/"},"Crete"),
4632       "there lived a minotaur named",
4633       strong("Fred."),
4634       ),
4635       hr;
4636
4637 =head2 PROVIDING ARGUMENTS TO HTML SHORTCUTS
4638
4639 The HTML methods will accept zero, one or multiple arguments.  If you
4640 provide no arguments, you get a single tag:
4641
4642    print hr;    #  <HR>
4643
4644 If you provide one or more string arguments, they are concatenated
4645 together with spaces and placed between opening and closing tags:
4646
4647    print h1("Chapter","1"); # <H1>Chapter 1</H1>"
4648
4649 If the first argument is an associative array reference, then the keys
4650 and values of the associative array become the HTML tag's attributes:
4651
4652    print a({-href=>'fred.html',-target=>'_new'},
4653       "Open a new frame");
4654
4655             <A HREF="fred.html",TARGET="_new">Open a new frame</A>
4656
4657 You may dispense with the dashes in front of the attribute names if
4658 you prefer:
4659
4660    print img {src=>'fred.gif',align=>'LEFT'};
4661
4662            <IMG ALIGN="LEFT" SRC="fred.gif">
4663
4664 Sometimes an HTML tag attribute has no argument.  For example, ordered
4665 lists can be marked as COMPACT.  The syntax for this is an argument that
4666 that points to an undef string:
4667
4668    print ol({compact=>undef},li('one'),li('two'),li('three'));
4669
4670 Prior to CGI.pm version 2.41, providing an empty ('') string as an
4671 attribute argument was the same as providing undef.  However, this has
4672 changed in order to accommodate those who want to create tags of the form 
4673 <IMG ALT="">.  The difference is shown in these two pieces of code:
4674
4675    CODE                   RESULT
4676    img({alt=>undef})      <IMG ALT>
4677    img({alt=>''})         <IMT ALT="">
4678
4679 =head2 THE DISTRIBUTIVE PROPERTY OF HTML SHORTCUTS
4680
4681 One of the cool features of the HTML shortcuts is that they are
4682 distributive.  If you give them an argument consisting of a
4683 B<reference> to a list, the tag will be distributed across each
4684 element of the list.  For example, here's one way to make an ordered
4685 list:
4686
4687    print ul(
4688              li({-type=>'disc'},['Sneezy','Doc','Sleepy','Happy'])
4689            );
4690
4691 This example will result in HTML output that looks like this:
4692
4693    <UL>
4694      <LI TYPE="disc">Sneezy</LI>
4695      <LI TYPE="disc">Doc</LI>
4696      <LI TYPE="disc">Sleepy</LI>
4697      <LI TYPE="disc">Happy</LI>
4698    </UL>
4699
4700 This is extremely useful for creating tables.  For example:
4701
4702    print table({-border=>undef},
4703            caption('When Should You Eat Your Vegetables?'),
4704            Tr({-align=>CENTER,-valign=>TOP},
4705            [
4706               th(['Vegetable', 'Breakfast','Lunch','Dinner']),
4707               td(['Tomatoes' , 'no', 'yes', 'yes']),
4708               td(['Broccoli' , 'no', 'no',  'yes']),
4709               td(['Onions'   , 'yes','yes', 'yes'])
4710            ]
4711            )
4712         );
4713
4714 =head2 HTML SHORTCUTS AND LIST INTERPOLATION
4715
4716 Consider this bit of code:
4717
4718    print blockquote(em('Hi'),'mom!'));
4719
4720 It will ordinarily return the string that you probably expect, namely:
4721
4722    <BLOCKQUOTE><EM>Hi</EM> mom!</BLOCKQUOTE>
4723
4724 Note the space between the element "Hi" and the element "mom!".
4725 CGI.pm puts the extra space there using array interpolation, which is
4726 controlled by the magic $" variable.  Sometimes this extra space is
4727 not what you want, for example, when you are trying to align a series
4728 of images.  In this case, you can simply change the value of $" to an
4729 empty string.
4730
4731    {
4732       local($") = '';
4733       print blockquote(em('Hi'),'mom!'));
4734     }
4735
4736 I suggest you put the code in a block as shown here.  Otherwise the
4737 change to $" will affect all subsequent code until you explicitly
4738 reset it.
4739
4740 =head2 NON-STANDARD HTML SHORTCUTS
4741
4742 A few HTML tags don't follow the standard pattern for various
4743 reasons.  
4744
4745 B<comment()> generates an HTML comment (<!-- comment -->).  Call it
4746 like
4747
4748     print comment('here is my comment');
4749
4750 Because of conflicts with built-in Perl functions, the following functions
4751 begin with initial caps:
4752
4753     Select
4754     Tr
4755     Link
4756     Delete
4757     Accept
4758     Sub
4759
4760 In addition, start_html(), end_html(), start_form(), end_form(),
4761 start_multipart_form() and all the fill-out form tags are special.
4762 See their respective sections.
4763
4764 =head2 AUTOESCAPING HTML
4765
4766 By default, all HTML that is emitted by the form-generating functions
4767 is passed through a function called escapeHTML():
4768
4769 =over 4
4770
4771 =item $escaped_string = escapeHTML("unescaped string");
4772
4773 Escape HTML formatting characters in a string.
4774
4775 =back
4776
4777 Provided that you have specified a character set of ISO-8859-1 (the
4778 default), the standard HTML escaping rules will be used.  The "<"
4779 character becomes "&lt;", ">" becomes "&gt;", "&" becomes "&amp;", and
4780 the quote character becomes "&quot;".  In addition, the hexadecimal
4781 0x8b and 0x9b characters, which many windows-based browsers interpret
4782 as the left and right angle-bracket characters, are replaced by their
4783 numeric HTML entities ("&#139" and "&#155;").  If you manually change
4784 the charset, either by calling the charset() method explicitly or by
4785 passing a -charset argument to header(), then B<all> characters will
4786 be replaced by their numeric entities, since CGI.pm has no lookup
4787 table for all the possible encodings.
4788
4789 The automatic escaping does not apply to other shortcuts, such as
4790 h1().  You should call escapeHTML() yourself on untrusted data in
4791 order to protect your pages against nasty tricks that people may enter
4792 into guestbooks, etc..  To change the character set, use charset().
4793 To turn autoescaping off completely, use autoescape():
4794
4795 =over 4
4796
4797 =item $charset = charset([$charset]);
4798
4799 Get or set the current character set.
4800
4801 =item $flag = autoEscape([$flag]);
4802
4803 Get or set the value of the autoescape flag.
4804
4805 =back
4806
4807 =head2 PRETTY-PRINTING HTML
4808
4809 By default, all the HTML produced by these functions comes out as one
4810 long line without carriage returns or indentation. This is yuck, but
4811 it does reduce the size of the documents by 10-20%.  To get
4812 pretty-printed output, please use L<CGI::Pretty>, a subclass
4813 contributed by Brian Paulsen.
4814
4815 =head1 CREATING FILL-OUT FORMS:
4816
4817 I<General note>  The various form-creating methods all return strings
4818 to the caller, containing the tag or tags that will create the requested
4819 form element.  You are responsible for actually printing out these strings.
4820 It's set up this way so that you can place formatting tags
4821 around the form elements.
4822
4823 I<Another note> The default values that you specify for the forms are only
4824 used the B<first> time the script is invoked (when there is no query
4825 string).  On subsequent invocations of the script (when there is a query
4826 string), the former values are used even if they are blank.  
4827
4828 If you want to change the value of a field from its previous value, you have two
4829 choices:
4830
4831 (1) call the param() method to set it.
4832
4833 (2) use the -override (alias -force) parameter (a new feature in version 2.15).
4834 This forces the default value to be used, regardless of the previous value:
4835
4836    print $query->textfield(-name=>'field_name',
4837                            -default=>'starting value',
4838                            -override=>1,
4839                            -size=>50,
4840                            -maxlength=>80);
4841
4842 I<Yet another note> By default, the text and labels of form elements are
4843 escaped according to HTML rules.  This means that you can safely use
4844 "<CLICK ME>" as the label for a button.  However, it also interferes with
4845 your ability to incorporate special HTML character sequences, such as &Aacute;,
4846 into your fields.  If you wish to turn off automatic escaping, call the
4847 autoEscape() method with a false value immediately after creating the CGI object:
4848
4849    $query = new CGI;
4850    $query->autoEscape(undef);
4851
4852 =head2 CREATING AN ISINDEX TAG
4853
4854    print $query->isindex(-action=>$action);
4855
4856          -or-
4857
4858    print $query->isindex($action);
4859
4860 Prints out an <ISINDEX> tag.  Not very exciting.  The parameter
4861 -action specifies the URL of the script to process the query.  The
4862 default is to process the query with the current script.
4863
4864 =head2 STARTING AND ENDING A FORM
4865
4866     print $query->start_form(-method=>$method,
4867                             -action=>$action,
4868                             -enctype=>$encoding);
4869       <... various form stuff ...>
4870     print $query->endform;
4871
4872         -or-
4873
4874     print $query->start_form($method,$action,$encoding);
4875       <... various form stuff ...>
4876     print $query->endform;
4877
4878 start_form() will return a <FORM> tag with the optional method,
4879 action and form encoding that you specify.  The defaults are:
4880
4881     method: POST
4882     action: this script
4883     enctype: application/x-www-form-urlencoded
4884
4885 endform() returns the closing </FORM> tag.  
4886
4887 Start_form()'s enctype argument tells the browser how to package the various
4888 fields of the form before sending the form to the server.  Two
4889 values are possible:
4890
4891 B<Note:> This method was previously named startform(), and startform()
4892 is still recognized as an alias.
4893
4894 =over 4
4895
4896 =item B<application/x-www-form-urlencoded>
4897
4898 This is the older type of encoding used by all browsers prior to
4899 Netscape 2.0.  It is compatible with many CGI scripts and is
4900 suitable for short fields containing text data.  For your
4901 convenience, CGI.pm stores the name of this encoding
4902 type in B<&CGI::URL_ENCODED>.
4903
4904 =item B<multipart/form-data>
4905
4906 This is the newer type of encoding introduced by Netscape 2.0.
4907 It is suitable for forms that contain very large fields or that
4908 are intended for transferring binary data.  Most importantly,
4909 it enables the "file upload" feature of Netscape 2.0 forms.  For
4910 your convenience, CGI.pm stores the name of this encoding type
4911 in B<&CGI::MULTIPART>
4912
4913 Forms that use this type of encoding are not easily interpreted
4914 by CGI scripts unless they use CGI.pm or another library designed
4915 to handle them.
4916
4917 =back
4918
4919 For compatibility, the start_form() method uses the older form of
4920 encoding by default.  If you want to use the newer form of encoding
4921 by default, you can call B<start_multipart_form()> instead of
4922 B<start_form()>.
4923
4924 JAVASCRIPTING: The B<-name> and B<-onSubmit> parameters are provided
4925 for use with JavaScript.  The -name parameter gives the
4926 form a name so that it can be identified and manipulated by
4927 JavaScript functions.  -onSubmit should point to a JavaScript
4928 function that will be executed just before the form is submitted to your
4929 server.  You can use this opportunity to check the contents of the form 
4930 for consistency and completeness.  If you find something wrong, you
4931 can put up an alert box or maybe fix things up yourself.  You can 
4932 abort the submission by returning false from this function.  
4933
4934 Usually the bulk of JavaScript functions are defined in a <SCRIPT>
4935 block in the HTML header and -onSubmit points to one of these function
4936 call.  See start_html() for details.
4937
4938 =head2 CREATING A TEXT FIELD
4939
4940     print $query->textfield(-name=>'field_name',
4941                             -default=>'starting value',
4942                             -size=>50,
4943                             -maxlength=>80);
4944         -or-
4945
4946     print $query->textfield('field_name','starting value',50,80);
4947
4948 textfield() will return a text input field.  
4949
4950 =over 4
4951
4952 =item B<Parameters>
4953
4954 =item 1.
4955
4956 The first parameter is the required name for the field (-name).  
4957
4958 =item 2.
4959
4960 The optional second parameter is the default starting value for the field