This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Upgrade Module-Metadata from version 1.000026 to 1.000027
[perl5.git] / cpan / Module-Metadata / t / metadata.t
1 # -*- mode: cperl; tab-width: 8; indent-tabs-mode: nil; basic-offset: 2 -*-
2 # vim:ts=8:sw=2:et:sta:sts=2
3
4 use strict;
5 use warnings;
6 use Test::More 0.82;
7 use IO::File;
8 use File::Spec;
9 use File::Temp;
10 use File::Basename;
11 use Cwd ();
12 use File::Path;
13 use Data::Dumper;
14
15 my $undef;
16
17 # parse various module $VERSION lines
18 # format: expected version => code snippet
19 my @modules = (
20   $undef => <<'---', # no $VERSION line
21 package Simple;
22 ---
23   $undef => <<'---', # undefined $VERSION
24 package Simple;
25 our $VERSION;
26 ---
27   '1.23' => <<'---', # declared & defined on same line with 'our'
28 package Simple;
29 our $VERSION = '1.23';
30 ---
31   '1.23' => <<'---', # declared & defined on separate lines with 'our'
32 package Simple;
33 our $VERSION;
34 $VERSION = '1.23';
35 ---
36   '1.23' => <<'---', # commented & defined on same line
37 package Simple;
38 our $VERSION = '1.23'; # our $VERSION = '4.56';
39 ---
40   '1.23' => <<'---', # commented & defined on separate lines
41 package Simple;
42 # our $VERSION = '4.56';
43 our $VERSION = '1.23';
44 ---
45   '1.23' => <<'---', # use vars
46 package Simple;
47 use vars qw( $VERSION );
48 $VERSION = '1.23';
49 ---
50   '1.23' => <<'---', # choose the right default package based on package/file name
51 package Simple::_private;
52 $VERSION = '0';
53 package Simple;
54 $VERSION = '1.23'; # this should be chosen for version
55 ---
56   '1.23' => <<'---', # just read the first $VERSION line
57 package Simple;
58 $VERSION = '1.23'; # we should see this line
59 $VERSION = eval $VERSION; # and ignore this one
60 ---
61   '1.23' => <<'---', # just read the first $VERSION line in reopened package (1)
62 package Simple;
63 $VERSION = '1.23';
64 package Error::Simple;
65 $VERSION = '2.34';
66 package Simple;
67 ---
68   '1.23' => <<'---', # just read the first $VERSION line in reopened package (2)
69 package Simple;
70 package Error::Simple;
71 $VERSION = '2.34';
72 package Simple;
73 $VERSION = '1.23';
74 ---
75   '1.23' => <<'---', # mentions another module's $VERSION
76 package Simple;
77 $VERSION = '1.23';
78 if ( $Other::VERSION ) {
79     # whatever
80 }
81 ---
82   '1.23' => <<'---', # mentions another module's $VERSION in a different package
83 package Simple;
84 $VERSION = '1.23';
85 package Simple2;
86 if ( $Simple::VERSION ) {
87     # whatever
88 }
89 ---
90   '1.23' => <<'---', # $VERSION checked only in assignments, not regexp ops
91 package Simple;
92 $VERSION = '1.23';
93 if ( $VERSION =~ /1\.23/ ) {
94     # whatever
95 }
96 ---
97   '1.23' => <<'---', # $VERSION checked only in assignments, not relational ops
98 package Simple;
99 $VERSION = '1.23';
100 if ( $VERSION == 3.45 ) {
101     # whatever
102 }
103 ---
104   '1.23' => <<'---', # $VERSION checked only in assignments, not relational ops
105 package Simple;
106 $VERSION = '1.23';
107 package Simple2;
108 if ( $Simple::VERSION == 3.45 ) {
109     # whatever
110 }
111 ---
112   '1.23' => <<'---', # Fully qualified $VERSION declared in package
113 package Simple;
114 $Simple::VERSION = 1.23;
115 ---
116   '1.23' => <<'---', # Differentiate fully qualified $VERSION in a package
117 package Simple;
118 $Simple2::VERSION = '999';
119 $Simple::VERSION = 1.23;
120 ---
121   '1.23' => <<'---', # Differentiate fully qualified $VERSION and unqualified
122 package Simple;
123 $Simple2::VERSION = '999';
124 $VERSION = 1.23;
125 ---
126   '1.23' => <<'---', # $VERSION declared as package variable from within 'main' package
127 $Simple::VERSION = '1.23';
128 {
129   package Simple;
130   $x = $y, $cats = $dogs;
131 }
132 ---
133   '1.23' => <<'---', # $VERSION wrapped in parens - space inside
134 package Simple;
135 ( $VERSION ) = '1.23';
136 ---
137   '1.23' => <<'---', # $VERSION wrapped in parens - no space inside
138 package Simple;
139 ($VERSION) = '1.23';
140 ---
141   '1.23' => <<'---', # $VERSION follows a spurious 'package' in a quoted construct
142 package Simple;
143 __PACKAGE__->mk_accessors(qw(
144     program socket proc
145     package filename line codeline subroutine finished));
146
147 our $VERSION = "1.23";
148 ---
149   '1.23' => <<'---', # $VERSION using version.pm
150   package Simple;
151   use version; our $VERSION = version->new('1.23');
152 ---
153   'v1.230' => <<'---', # $VERSION using version.pm and qv()
154   package Simple;
155   use version; our $VERSION = qv('1.230');
156 ---
157   '1.230' => <<'---', # Two version assignments, should ignore second one
158   $Simple::VERSION = '1.230';
159   $Simple::VERSION = eval $Simple::VERSION;
160 ---
161   '1.230000' => <<'---', # declared & defined on same line with 'our'
162 package Simple;
163 our $VERSION = '1.23_00_00';
164 ---
165   '1.23' => <<'---', # package NAME VERSION
166   package Simple 1.23;
167 ---
168   '1.23_01' => <<'---', # package NAME VERSION
169   package Simple 1.23_01;
170 ---
171   'v1.2.3' => <<'---', # package NAME VERSION
172   package Simple v1.2.3;
173 ---
174   'v1.2_3' => <<'---', # package NAME VERSION
175   package Simple v1.2_3;
176 ---
177   '1.23' => <<'---', # trailing crud
178   package Simple;
179   our $VERSION;
180   $VERSION = '1.23-alpha';
181 ---
182   '1.23' => <<'---', # trailing crud
183   package Simple;
184   our $VERSION;
185   $VERSION = '1.23b';
186 ---
187   '1.234' => <<'---', # multi_underscore
188   package Simple;
189   our $VERSION;
190   $VERSION = '1.2_3_4';
191 ---
192   '0' => <<'---', # non-numeric
193   package Simple;
194   our $VERSION;
195   $VERSION = 'onetwothree';
196 ---
197   $undef => <<'---', # package NAME BLOCK, undef $VERSION
198 package Simple {
199   our $VERSION;
200 }
201 ---
202   '1.23' => <<'---', # package NAME BLOCK, with $VERSION
203 package Simple {
204   our $VERSION = '1.23';
205 }
206 ---
207   '1.23' => <<'---', # package NAME VERSION BLOCK
208 package Simple 1.23 {
209   1;
210 }
211 ---
212   'v1.2.3_4' => <<'---', # package NAME VERSION BLOCK
213 package Simple v1.2.3_4 {
214   1;
215 }
216 ---
217   '0' => <<'---', # set from separately-initialised variable
218 package Simple;
219   our $CVSVERSION   = '$Revision: 1.7 $';
220   our ($VERSION)    = ($CVSVERSION =~ /(\d+\.\d+)/);
221 }
222 ---
223   'v2.2.102.2' => <<'---', # our + bare v-string
224 package Simple;
225 our $VERSION     = v2.2.102.2;
226 ---
227   '0.0.9_1' => <<'---', # our + dev release
228 package Simple;
229 our $VERSION = "0.0.9_1";
230 ---
231   '1.12' => <<'---', # our + crazy string and substitution code
232 package Simple;
233 our $VERSION     = '1.12.B55J2qn'; our $WTF = $VERSION; $WTF =~ s/^\d+\.\d+\.//; # attempts to rationalize $WTF go here.
234 ---
235   '1.12' => <<'---', # our in braces, as in Dist::Zilla::Plugin::PkgVersion with use_our = 1
236 package Simple;
237 { our $VERSION = '1.12'; }
238 ---
239   sub { defined $_[0] and $_[0] =~ /^3\.14159/ } => <<'---', # calculated version - from Acme-Pi-3.14
240 package Simple;
241 my $version = atan2(1,1) * 4; $Simple::VERSION = "$version";
242 1;
243 ---
244 );
245
246 # format: expected package name => code snippet
247 my @pkg_names = (
248   [ 'Simple' ] => <<'---', # package NAME
249 package Simple;
250 ---
251   [ 'Simple::Edward' ] => <<'---', # package NAME::SUBNAME
252 package Simple::Edward;
253 ---
254   [ 'Simple::Edward::' ] => <<'---', # package NAME::SUBNAME::
255 package Simple::Edward::;
256 ---
257   [ "Simple'Edward" ] => <<'---', # package NAME'SUBNAME
258 package Simple'Edward;
259 ---
260   [ "Simple'Edward::" ] => <<'---', # package NAME'SUBNAME::
261 package Simple'Edward::;
262 ---
263   [ 'Simple::::Edward' ] => <<'---', # package NAME::::SUBNAME
264 package Simple::::Edward;
265 ---
266   [ '::Simple::Edward' ] => <<'---', # package ::NAME::SUBNAME
267 package ::Simple::Edward;
268 ---
269   [ 'main' ] => <<'---', # package NAME:SUBNAME (fail)
270 package Simple:Edward;
271 ---
272   [ 'main' ] => <<'---', # package NAME' (fail)
273 package Simple';
274 ---
275   [ 'main' ] => <<'---', # package NAME::SUBNAME' (fail)
276 package Simple::Edward';
277 ---
278   [ 'main' ] => <<'---', # package NAME''SUBNAME (fail)
279 package Simple''Edward;
280 ---
281   [ 'main' ] => <<'---', # package NAME-SUBNAME (fail)
282 package Simple-Edward;
283 ---
284 );
285
286 # 2 tests per each pair of @modules (plus 1 for defined keys), 2 per pair of @pkg_names
287 plan tests => 63
288   + ( @modules + grep { defined $modules[2*$_] } 0..$#modules/2 )
289   + ( @pkg_names );
290
291 require_ok('Module::Metadata');
292
293 {
294     # class method C<find_module_by_name>
295     my $module = Module::Metadata->find_module_by_name(
296                    'Module::Metadata' );
297     ok( -e $module, 'find_module_by_name() succeeds' );
298 }
299
300 #########################
301
302 BEGIN {
303   my $cwd = File::Spec->rel2abs(Cwd::cwd);
304   sub original_cwd { return $cwd }
305 }
306
307 # Set up a temp directory
308 sub tmpdir {
309   my (@args) = @_;
310   my $dir = $ENV{PERL_CORE} ? original_cwd : File::Spec->tmpdir;
311   return File::Temp::tempdir('MMD-XXXXXXXX', CLEANUP => 0, DIR => $dir, @args);
312 }
313
314 my $tmp;
315 BEGIN { $tmp = tmpdir; note "using temp dir $tmp"; }
316
317 END {
318   die "tests failed; leaving temp dir $tmp behind"
319     if $ENV{AUTHOR_TESTING} and not Test::Builder->new->is_passing;
320   note "removing temp dir $tmp";
321   chdir original_cwd;
322   File::Path::rmtree($tmp);
323 }
324
325 # generates a new distribution:
326 # files => { relative filename => $content ... }
327 # returns the name of the distribution (not including version),
328 # and the absolute path name to the dist.
329 {
330   my $test_num = 0;
331   sub new_dist {
332     my %opts = @_;
333
334     my $distname = 'Simple' . $test_num++;
335     my $distdir = File::Spec->catdir($tmp, $distname);
336     note "using dist $distname in $distdir";
337
338     File::Path::mkpath($distdir) or die "failed to create '$distdir'";
339
340     foreach my $rel_filename (keys %{$opts{files}})
341     {
342       my $abs_filename = File::Spec->catfile($distdir, $rel_filename);
343       my $dirname = File::Basename::dirname($abs_filename);
344       unless (-d $dirname) {
345         File::Path::mkpath($dirname) or die "Can't create '$dirname'";
346       }
347
348       note "creating $abs_filename";
349       my $fh = IO::File->new(">$abs_filename") or die "Can't write '$abs_filename'\n";
350       print $fh $opts{files}{$rel_filename};
351       close $fh;
352     }
353
354     chdir $distdir;
355     return ($distname, $distdir);
356   }
357 }
358
359 {
360   # fail on invalid module name
361   my $pm_info = Module::Metadata->new_from_module(
362                   'Foo::Bar', inc => [] );
363   ok( !defined( $pm_info ), 'fail if can\'t find module by module name' );
364 }
365
366 {
367   # fail on invalid filename
368   my $file = File::Spec->catfile( 'Foo', 'Bar.pm' );
369   my $pm_info = Module::Metadata->new_from_file( $file, inc => [] );
370   ok( !defined( $pm_info ), 'fail if can\'t find module by file name' );
371 }
372
373 {
374   my $file = File::Spec->catfile('lib', 'Simple.pm');
375   my ($dist_name, $dist_dir) = new_dist(files => { $file => "package Simple;\n" });
376
377   # construct from module filename
378   my $pm_info = Module::Metadata->new_from_file( $file );
379   ok( defined( $pm_info ), 'new_from_file() succeeds' );
380
381   # construct from filehandle
382   my $handle = IO::File->new($file);
383   $pm_info = Module::Metadata->new_from_handle( $handle, $file );
384   ok( defined( $pm_info ), 'new_from_handle() succeeds' );
385   $pm_info = Module::Metadata->new_from_handle( $handle );
386   is( $pm_info, undef, "new_from_handle() without filename returns undef" );
387   close($handle);
388 }
389
390 {
391   # construct from module name, using custom include path
392   my $pm_info = Module::Metadata->new_from_module(
393                'Simple', inc => [ 'lib', @INC ] );
394   ok( defined( $pm_info ), 'new_from_module() succeeds' );
395 }
396
397
398 # iterate through @modules pairwise
399 my $test_case = 0;
400 while (++$test_case and my ($expected_version, $code) = splice @modules, 0, 2 ) {
401  SKIP: {
402     skip( "No our() support until perl 5.6", (defined $expected_version ? 3 : 2) )
403         if $] < 5.006 && $code =~ /\bour\b/;
404     skip( "No package NAME VERSION support until perl 5.11.1", (defined $expected_version ? 3 : 2) )
405         if $] < 5.011001 && $code =~ /package\s+[\w\:\']+\s+v?[0-9._]+/;
406
407     my $file = File::Spec->catfile('lib', 'Simple.pm');
408     my ($dist_name, $dist_dir) = new_dist(files => { $file => $code });
409
410     my $warnings = '';
411     local $SIG{__WARN__} = sub { $warnings .= $_ for @_ };
412     my $pm_info = Module::Metadata->new_from_file( $file );
413
414     my $errs;
415     my $got = $pm_info->version;
416
417     # note that in Test::More 0.94 and earlier, is() stringifies first before comparing;
418     # from 0.95_01 and later, it just lets the objects figure out how to handle 'eq'
419     # We want to ensure we preserve the original, as long as it's legal, so we
420     # explicitly check the stringified form.
421     isa_ok($got, 'version') if defined $expected_version;
422
423     if (ref($expected_version) eq 'CODE') {
424       ok(
425         $expected_version->($got),
426         "case $test_case: module version passes match sub"
427       )
428       or $errs++;
429     }
430     else {
431       is(
432         (defined $got ? "$got" : $got),
433         $expected_version,
434         "case $test_case: correct module version ("
435           . (defined $expected_version? "'$expected_version'" : 'undef')
436           . ')'
437       )
438       or $errs++;
439     }
440
441     is( $warnings, '', "case $test_case: no warnings from parsing" ) or $errs++;
442     diag Dumper({ got => $pm_info->version, module_contents => $code }) if $errs;
443   }
444 }
445
446 $test_case = 0;
447 while (++$test_case and my ($expected_name, $code) = splice @pkg_names, 0, 2) {
448     my $file = File::Spec->catfile('lib', 'Simple.pm');
449     my ($dist_name, $dist_dir) = new_dist(files => { $file => $code });
450
451     my $warnings = '';
452     local $SIG{__WARN__} = sub { $warnings .= $_ for @_ };
453     my $pm_info = Module::Metadata->new_from_file( $file );
454
455     # Test::Builder will prematurely numify objects, so use this form
456     my $errs;
457     my @got = $pm_info->packages_inside();
458     is_deeply( \@got, $expected_name,
459                "case $test_case: correct package names (expected '" . join(', ', @$expected_name) . "')" )
460             or $errs++;
461     is( $warnings, '', "case $test_case: no warnings from parsing" ) or $errs++;
462     diag "Got: '" . join(', ', @got) . "'\nModule contents:\n$code" if $errs;
463 }
464
465 {
466   # Find each package only once
467   my $file = File::Spec->catfile('lib', 'Simple.pm');
468   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
469 package Simple;
470 $VERSION = '1.23';
471 package Error::Simple;
472 $VERSION = '2.34';
473 package Simple;
474 ---
475
476   my $pm_info = Module::Metadata->new_from_file( $file );
477
478   my @packages = $pm_info->packages_inside;
479   is( @packages, 2, 'record only one occurence of each package' );
480 }
481
482 {
483   # Module 'Simple.pm' does not contain package 'Simple';
484   # constructor should not complain, no default module name or version
485   my $file = File::Spec->catfile('lib', 'Simple.pm');
486   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
487 package Simple::Not;
488 $VERSION = '1.23';
489 ---
490
491   my $pm_info = Module::Metadata->new_from_file( $file );
492
493   is( $pm_info->name, undef, 'no default package' );
494   is( $pm_info->version, undef, 'no version w/o default package' );
495 }
496
497 {
498   # Module 'Simple.pm' contains an alpha version
499   # constructor should report first $VERSION found
500   my $file = File::Spec->catfile('lib', 'Simple.pm');
501   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
502 package Simple;
503 $VERSION = '1.23_01';
504 $VERSION = eval $VERSION;
505 ---
506
507   my $pm_info = Module::Metadata->new_from_file( $file );
508
509   is( $pm_info->version, '1.23_01', 'alpha version reported');
510
511   # NOTE the following test has be done this way because Test::Builder is
512   # too smart for our own good and tries to see if the version object is a
513   # dual-var, which breaks with alpha versions:
514   #    Argument "1.23_0100" isn't numeric in addition (+) at
515   #    /usr/lib/perl5/5.8.7/Test/Builder.pm line 505.
516
517   ok( $pm_info->version > 1.23, 'alpha version greater than non');
518 }
519
520 # parse $VERSION lines scripts for package main
521 my @scripts = (
522   <<'---', # package main declared
523 #!perl -w
524 package main;
525 $VERSION = '0.01';
526 ---
527   <<'---', # on first non-comment line, non declared package main
528 #!perl -w
529 $VERSION = '0.01';
530 ---
531   <<'---', # after non-comment line
532 #!perl -w
533 use strict;
534 $VERSION = '0.01';
535 ---
536   <<'---', # 1st declared package
537 #!perl -w
538 package main;
539 $VERSION = '0.01';
540 package _private;
541 $VERSION = '999';
542 ---
543   <<'---', # 2nd declared package
544 #!perl -w
545 package _private;
546 $VERSION = '999';
547 package main;
548 $VERSION = '0.01';
549 ---
550   <<'---', # split package
551 #!perl -w
552 package main;
553 package _private;
554 $VERSION = '999';
555 package main;
556 $VERSION = '0.01';
557 ---
558   <<'---', # define 'main' version from other package
559 package _private;
560 $::VERSION = 0.01;
561 $VERSION = '999';
562 ---
563   <<'---', # define 'main' version from other package
564 package _private;
565 $VERSION = '999';
566 $::VERSION = 0.01;
567 ---
568 );
569
570 my ( $i, $n ) = ( 1, scalar( @scripts ) );
571 foreach my $script ( @scripts ) {
572   my $file = File::Spec->catfile('bin', 'simple.plx');
573   my ($dist_name, $dist_dir) = new_dist(files => { $file => $script } );
574   my $pm_info = Module::Metadata->new_from_file( $file );
575
576   is( $pm_info->version, '0.01', "correct script version ($i of $n)" );
577   $i++;
578 }
579
580 {
581   # examine properties of a module: name, pod, etc
582   my $file = File::Spec->catfile('lib', 'Simple.pm');
583   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
584 package Simple;
585 $VERSION = '0.01';
586 package Simple::Ex;
587 $VERSION = '0.02';
588
589 =head1 NAME
590
591 Simple - It's easy.
592
593 =head1 AUTHOR
594
595 Simple Simon
596
597 You can find me on the IRC channel
598 #simon on irc.perl.org.
599
600 =cut
601 ---
602
603   my $pm_info = Module::Metadata->new_from_module(
604              'Simple', inc => [ 'lib', @INC ] );
605
606   is( $pm_info->name, 'Simple', 'found default package' );
607   is( $pm_info->version, '0.01', 'version for default package' );
608
609   # got correct version for secondary package
610   is( $pm_info->version( 'Simple::Ex' ), '0.02',
611       'version for secondary package' );
612
613   my $filename = $pm_info->filename;
614   ok( defined( $filename ) && -e $filename,
615       'filename() returns valid path to module file' );
616
617   my @packages = $pm_info->packages_inside;
618   is( @packages, 2, 'found correct number of packages' );
619   is( $packages[0], 'Simple', 'packages stored in order found' );
620
621   # we can detect presence of pod regardless of whether we are collecting it
622   ok( $pm_info->contains_pod, 'contains_pod() succeeds' );
623
624   my @pod = $pm_info->pod_inside;
625   is_deeply( \@pod, [qw(NAME AUTHOR)], 'found all pod sections' );
626
627   is( $pm_info->pod('NONE') , undef,
628       'return undef() if pod section not present' );
629
630   is( $pm_info->pod('NAME'), undef,
631       'return undef() if pod section not collected' );
632
633
634   # collect_pod
635   $pm_info = Module::Metadata->new_from_module(
636                'Simple', inc => [ 'lib', @INC ], collect_pod => 1 );
637
638   my %pod;
639   for my $section (qw(NAME AUTHOR)) {
640     my $content = $pm_info->pod( $section );
641     if ( $content ) {
642       $content =~ s/^\s+//;
643       $content =~ s/\s+$//;
644     }
645     $pod{$section} = $content;
646   }
647   my %expected = (
648     NAME   => q|Simple - It's easy.|,
649     AUTHOR => <<'EXPECTED'
650 Simple Simon
651
652 You can find me on the IRC channel
653 #simon on irc.perl.org.
654 EXPECTED
655   );
656   for my $text (values %expected) {
657     $text =~ s/^\s+//;
658     $text =~ s/\s+$//;
659   }
660   is( $pod{NAME},   $expected{NAME},   'collected NAME pod section' );
661   is( $pod{AUTHOR}, $expected{AUTHOR}, 'collected AUTHOR pod section' );
662 }
663
664 {
665   # test things that look like POD, but aren't
666   my $file = File::Spec->catfile('lib', 'Simple.pm');
667   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
668 package Simple;
669
670 =YES THIS STARTS POD
671
672 our $VERSION = '999';
673
674 =cute
675
676 our $VERSION = '666';
677
678 =cut
679
680 *foo
681 =*no_this_does_not_start_pod;
682
683 our $VERSION = '1.23';
684
685 ---
686   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
687   is( $pm_info->name, 'Simple', 'found default package' );
688   is( $pm_info->version, '1.23', 'version for default package' );
689 }
690
691 {
692   # Make sure processing stops after __DATA__
693   my $file = File::Spec->catfile('lib', 'Simple.pm');
694   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
695 package Simple;
696 $VERSION = '0.01';
697 __DATA__
698 *UNIVERSAL::VERSION = sub {
699   foo();
700 };
701 ---
702
703   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
704   is( $pm_info->name, 'Simple', 'found default package' );
705   is( $pm_info->version, '0.01', 'version for default package' );
706   my @packages = $pm_info->packages_inside;
707   is_deeply(\@packages, ['Simple'], 'packages inside');
708 }
709
710 {
711   # Make sure we handle version.pm $VERSIONs well
712   my $file = File::Spec->catfile('lib', 'Simple.pm');
713   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
714 package Simple;
715 $VERSION = version->new('0.60.' . (qw$Revision: 128 $)[1]);
716 package Simple::Simon;
717 $VERSION = version->new('0.61.' . (qw$Revision: 129 $)[1]);
718 ---
719
720   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
721   is( $pm_info->name, 'Simple', 'found default package' );
722   is( $pm_info->version, '0.60.128', 'version for default package' );
723   my @packages = $pm_info->packages_inside;
724   is_deeply([sort @packages], ['Simple', 'Simple::Simon'], 'packages inside');
725   is( $pm_info->version('Simple::Simon'), '0.61.129', 'version for embedded package' );
726 }
727
728 # check that package_versions_from_directory works
729
730 {
731   my $file = File::Spec->catfile('lib', 'Simple.pm');
732   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
733 package Simple;
734 $VERSION = '0.01';
735 package Simple::Ex;
736 $VERSION = '0.02';
737 {
738   package main; # should ignore this
739 }
740 {
741   package DB; # should ignore this
742 }
743 {
744   package Simple::_private; # should ignore this
745 }
746
747 =head1 NAME
748
749 Simple - It's easy.
750
751 =head1 AUTHOR
752
753 Simple Simon
754
755 =cut
756 ---
757
758   my $exp_pvfd = {
759     'Simple' => {
760       'file' => 'Simple.pm',
761       'version' => '0.01'
762     },
763     'Simple::Ex' => {
764       'file' => 'Simple.pm',
765       'version' => '0.02'
766     }
767   };
768
769   my $got_pvfd = Module::Metadata->package_versions_from_directory('lib');
770
771   is_deeply( $got_pvfd, $exp_pvfd, "package_version_from_directory()" )
772     or diag explain $got_pvfd;
773
774 {
775   my $got_provides = Module::Metadata->provides(dir => 'lib', version => 2);
776   my $exp_provides = {
777     'Simple' => {
778       'file' => 'lib/Simple.pm',
779       'version' => '0.01'
780     },
781     'Simple::Ex' => {
782       'file' => 'lib/Simple.pm',
783       'version' => '0.02'
784     }
785   };
786
787   is_deeply( $got_provides, $exp_provides, "provides()" )
788     or diag explain $got_provides;
789 }
790
791 {
792   my $got_provides = Module::Metadata->provides(dir => 'lib', prefix => 'other', version => 1.4);
793   my $exp_provides = {
794     'Simple' => {
795       'file' => 'other/Simple.pm',
796       'version' => '0.01'
797     },
798     'Simple::Ex' => {
799       'file' => 'other/Simple.pm',
800       'version' => '0.02'
801     }
802   };
803
804   is_deeply( $got_provides, $exp_provides, "provides()" )
805     or diag explain $got_provides;
806 }
807 }
808
809 # Check package_versions_from_directory with regard to case-sensitivity
810 {
811   my $file = File::Spec->catfile('lib', 'Simple.pm');
812   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
813 package simple;
814 $VERSION = '0.01';
815 ---
816
817   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
818   is( $pm_info->name, undef, 'no default package' );
819   is( $pm_info->version, undef, 'version for default package' );
820   is( $pm_info->version('simple'), '0.01', 'version for lower-case package' );
821   is( $pm_info->version('Simple'), undef, 'version for capitalized package' );
822   ok( $pm_info->is_indexable(), 'an indexable package is found' );
823   ok( $pm_info->is_indexable('simple'), 'the simple package is indexable' );
824   ok( !$pm_info->is_indexable('Simple'), 'the Simple package would not be indexed' );
825 }
826
827 {
828   my $file = File::Spec->catfile('lib', 'Simple.pm');
829   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
830 package simple;
831 $VERSION = '0.01';
832 package Simple;
833 $VERSION = '0.02';
834 package SiMpLe;
835 $VERSION = '0.03';
836 ---
837
838   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
839   is( $pm_info->name, 'Simple', 'found default package' );
840   is( $pm_info->version, '0.02', 'version for default package' );
841   is( $pm_info->version('simple'), '0.01', 'version for lower-case package' );
842   is( $pm_info->version('Simple'), '0.02', 'version for capitalized package' );
843   is( $pm_info->version('SiMpLe'), '0.03', 'version for mixed-case package' );
844   ok( $pm_info->is_indexable('simple'), 'the simple package is indexable' );
845   ok( $pm_info->is_indexable('Simple'), 'the Simple package is indexable' );
846 }
847
848 {
849   my $file = File::Spec->catfile('lib', 'Simple.pm');
850   my ($dist_name, $dist_dir) = new_dist(files => { $file => <<'---' } );
851 package ## hide from PAUSE
852    simple;
853 $VERSION = '0.01';
854 ---
855
856   my $pm_info = Module::Metadata->new_from_file('lib/Simple.pm');
857   is( $pm_info->name, undef, 'no package names found' );
858   ok( !$pm_info->is_indexable('simple'), 'the simple package would not be indexed' );
859   ok( !$pm_info->is_indexable('Simple'), 'the Simple package would not be indexed' );
860   ok( !$pm_info->is_indexable(), 'no indexable package is found' );
861 }