This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move B-Deparse from dist/ to lib/ since it is non-dual-lived and pure-Perl
[perl5.git] / lib / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998-2000, 2002, 2003, 2004, 2005, 2006 Stephen McCamant.
3 # All rights reserved.
4 # This module is free software; you can redistribute and/or modify
5 # it under the same terms as Perl itself.
6
7 # This is based on the module of the same name by Malcolm Beattie,
8 # but essentially none of his code remains.
9
10 package B::Deparse;
11 use Carp;
12 use B qw(class main_root main_start main_cv svref_2object opnumber perlstring
13          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
14          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
15          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
16          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
17          OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
18          OPpSORT_REVERSE
19          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR SVf_FAKE SVs_RMG SVs_SMG
20          CVf_METHOD CVf_LVALUE
21          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE
22          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
23 $VERSION = '1.23';
24 use strict;
25 use vars qw/$AUTOLOAD/;
26 use warnings ();
27 require feature;
28
29 BEGIN {
30     # List version-specific constants here.
31     # Easiest way to keep this code portable between version looks to
32     # be to fake up a dummy constant that will never actually be true.
33     foreach (qw(OPpSORT_INPLACE OPpSORT_DESCEND OPpITER_REVERSED OPpCONST_NOVER
34                 OPpPAD_STATE PMf_SKIPWHITE RXf_SKIPWHITE
35                 RXf_PMf_CHARSET RXf_PMf_KEEPCOPY
36                 CVf_LOCKED OPpREVERSE_INPLACE OPpSUBSTR_REPL_FIRST
37                 PMf_NONDESTRUCT OPpCONST_ARYBASE OPpEVAL_BYTES)) {
38         eval { import B $_ };
39         no strict 'refs';
40         *{$_} = sub () {0} unless *{$_}{CODE};
41     }
42 }
43
44 # Changes between 0.50 and 0.51:
45 # - fixed nulled leave with live enter in sort { }
46 # - fixed reference constants (\"str")
47 # - handle empty programs gracefully
48 # - handle infinite loops (for (;;) {}, while (1) {})
49 # - differentiate between 'for my $x ...' and 'my $x; for $x ...'
50 # - various minor cleanups
51 # - moved globals into an object
52 # - added '-u', like B::C
53 # - package declarations using cop_stash
54 # - subs, formats and code sorted by cop_seq
55 # Changes between 0.51 and 0.52:
56 # - added pp_threadsv (special variables under USE_5005THREADS)
57 # - added documentation
58 # Changes between 0.52 and 0.53:
59 # - many changes adding precedence contexts and associativity
60 # - added '-p' and '-s' output style options
61 # - various other minor fixes
62 # Changes between 0.53 and 0.54:
63 # - added support for new 'for (1..100)' optimization,
64 #   thanks to Gisle Aas
65 # Changes between 0.54 and 0.55:
66 # - added support for new qr// construct
67 # - added support for new pp_regcreset OP
68 # Changes between 0.55 and 0.56:
69 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
70 # - fixed $# on non-lexicals broken in last big rewrite
71 # - added temporary fix for change in opcode of OP_STRINGIFY
72 # - fixed problem in 0.54's for() patch in 'for (@ary)'
73 # - fixed precedence in conditional of ?:
74 # - tweaked list paren elimination in 'my($x) = @_'
75 # - made continue-block detection trickier wrt. null ops
76 # - fixed various prototype problems in pp_entersub
77 # - added support for sub prototypes that never get GVs
78 # - added unquoting for special filehandle first arg in truncate
79 # - print doubled rv2gv (a bug) as '*{*GV}' instead of illegal '**GV'
80 # - added semicolons at the ends of blocks
81 # - added -l '#line' declaration option -- fixes cmd/subval.t 27,28
82 # Changes between 0.56 and 0.561:
83 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
84 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
85 # Changes between 0.561 and 0.57:
86 # - stylistic changes to symbolic constant stuff
87 # - handled scope in s///e replacement code
88 # - added unquote option for expanding "" into concats, etc.
89 # - split method and proto parts of pp_entersub into separate functions
90 # - various minor cleanups
91 # Changes after 0.57:
92 # - added parens in \&foo (patch by Albert Dvornik)
93 # Changes between 0.57 and 0.58:
94 # - fixed '0' statements that weren't being printed
95 # - added methods for use from other programs
96 #   (based on patches from James Duncan and Hugo van der Sanden)
97 # - added -si and -sT to control indenting (also based on a patch from Hugo)
98 # - added -sv to print something else instead of '???'
99 # - preliminary version of utf8 tr/// handling
100 # Changes after 0.58:
101 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
102 # - added support for Hugo's new OP_SETSTATE (like nextstate)
103 # Changes between 0.58 and 0.59
104 # - added support for Chip's OP_METHOD_NAMED
105 # - added support for Ilya's OPpTARGET_MY optimization
106 # - elided arrows before '()' subscripts when possible
107 # Changes between 0.59 and 0.60
108 # - support for method attributes was added
109 # - some warnings fixed
110 # - separate recognition of constant subs
111 # - rewrote continue block handling, now recognizing for loops
112 # - added more control of expanding control structures
113 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
114 # - many bug-fixes
115 # - support for pragmas and 'use'
116 # - support for the little-used $[ variable
117 # - support for __DATA__ sections
118 # - UTF8 support
119 # - BEGIN, CHECK, INIT and END blocks
120 # - scoping of subroutine declarations fixed
121 # - compile-time output from the input program can be suppressed, so that the
122 #   output is just the deparsed code. (a change to O.pm in fact)
123 # - our() declarations
124 # - *all* the known bugs are now listed in the BUGS section
125 # - comprehensive test mechanism (TEST -deparse)
126 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
127 # - bug-fixes
128 # - new switch -P
129 # - support for command-line switches (-l, -0, etc.)
130 # Changes between 0.63 and 0.64
131 # - support for //, CHECK blocks, and assertions
132 # - improved handling of foreach loops and lexicals
133 # - option to use Data::Dumper for constants
134 # - more bug fixes
135 # - discovered lots more bugs not yet fixed
136 #
137 # ...
138 #
139 # Changes between 0.72 and 0.73
140 # - support new switch constructs
141
142 # Todo:
143 #  (See also BUGS section at the end of this file)
144 #
145 # - finish tr/// changes
146 # - add option for even more parens (generalize \&foo change)
147 # - left/right context
148 # - copy comments (look at real text with $^P?)
149 # - avoid semis in one-statement blocks
150 # - associativity of &&=, ||=, ?:
151 # - ',' => '=>' (auto-unquote?)
152 # - break long lines ("\r" as discretionary break?)
153 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
154 # - more style options: brace style, hex vs. octal, quotes, ...
155 # - print big ints as hex/octal instead of decimal (heuristic?)
156 # - handle 'my $x if 0'?
157 # - version using op_next instead of op_first/sibling?
158 # - avoid string copies (pass arrays, one big join?)
159 # - here-docs?
160
161 # Current test.deparse failures
162 # comp/hints 6 - location of BEGIN blocks wrt. block openings
163 # run/switchI 1 - missing -I switches entirely
164 #    perl -Ifoo -e 'print @INC'
165 # op/caller 2 - warning mask propagates backwards before warnings::register
166 #    'use warnings; BEGIN {${^WARNING_BITS} eq "U"x12;} use warnings::register'
167 # op/getpid 2 - can't assign to shared my() declaration (threads only)
168 #    'my $x : shared = 5'
169 # op/override 7 - parens on overridden require change v-string interpretation
170 #    'BEGIN{*CORE::GLOBAL::require=sub {}} require v5.6'
171 #    c.f. 'BEGIN { *f = sub {0} }; f 2'
172 # op/pat 774 - losing Unicode-ness of Latin1-only strings
173 #    'use charnames ":short"; $x="\N{latin:a with acute}"'
174 # op/recurse 12 - missing parens on recursive call makes it look like method
175 #    'sub f { f($x) }'
176 # op/subst 90 - inconsistent handling of utf8 under "use utf8"
177 # op/taint 29 - "use re 'taint'" deparsed in the wrong place wrt. block open
178 # op/tiehandle compile - "use strict" deparsed in the wrong place
179 # uni/tr_ several
180 # ext/B/t/xref 11 - line numbers when we add newlines to one-line subs
181 # ext/Data/Dumper/t/dumper compile
182 # ext/DB_file/several
183 # ext/Encode/several
184 # ext/Ernno/Errno warnings
185 # ext/IO/lib/IO/t/io_sel 23
186 # ext/PerlIO/t/encoding compile
187 # ext/POSIX/t/posix 6
188 # ext/Socket/Socket 8
189 # ext/Storable/t/croak compile
190 # lib/Attribute/Handlers/t/multi compile
191 # lib/bignum/ several
192 # lib/charnames 35
193 # lib/constant 32
194 # lib/English 40
195 # lib/ExtUtils/t/bytes 4
196 # lib/File/DosGlob compile
197 # lib/Filter/Simple/t/data 1
198 # lib/Math/BigInt/t/constant 1
199 # lib/Net/t/config Deparse-warning
200 # lib/overload compile
201 # lib/Switch/ several
202 # lib/Symbol 4
203 # lib/Test/Simple several
204 # lib/Term/Complete
205 # lib/Tie/File/t/29_downcopy 5
206 # lib/vars 22
207
208 # Object fields (were globals):
209 #
210 # avoid_local:
211 # (local($a), local($b)) and local($a, $b) have the same internal
212 # representation but the short form looks better. We notice we can
213 # use a large-scale local when checking the list, but need to prevent
214 # individual locals too. This hash holds the addresses of OPs that
215 # have already had their local-ness accounted for. The same thing
216 # is done with my().
217 #
218 # curcv:
219 # CV for current sub (or main program) being deparsed
220 #
221 # curcvlex:
222 # Cached hash of lexical variables for curcv: keys are
223 # names prefixed with "m" or "o" (representing my/our), and
224 # each value is an array of pairs, indicating the cop_seq of scopes
225 # in which a var of that name is valid.
226 #
227 # curcop:
228 # COP for statement being deparsed
229 #
230 # curstash:
231 # name of the current package for deparsed code
232 #
233 # subs_todo:
234 # array of [cop_seq, CV, is_format?] for subs and formats we still
235 # want to deparse
236 #
237 # protos_todo:
238 # as above, but [name, prototype] for subs that never got a GV
239 #
240 # subs_done, forms_done:
241 # keys are addresses of GVs for subs and formats we've already
242 # deparsed (or at least put into subs_todo)
243 #
244 # subs_declared
245 # keys are names of subs for which we've printed declarations.
246 # That means we can omit parentheses from the arguments. It also means we
247 # need to put CORE:: on core functions of the same name.
248 #
249 # subs_deparsed
250 # Keeps track of fully qualified names of all deparsed subs.
251 #
252 # parens: -p
253 # linenums: -l
254 # unquote: -q
255 # cuddle: ' ' or '\n', depending on -sC
256 # indent_size: -si
257 # use_tabs: -sT
258 # ex_const: -sv
259
260 # A little explanation of how precedence contexts and associativity
261 # work:
262 #
263 # deparse() calls each per-op subroutine with an argument $cx (short
264 # for context, but not the same as the cx* in the perl core), which is
265 # a number describing the op's parents in terms of precedence, whether
266 # they're inside an expression or at statement level, etc.  (see
267 # chart below). When ops with children call deparse on them, they pass
268 # along their precedence. Fractional values are used to implement
269 # associativity ('($x + $y) + $z' => '$x + $y + $y') and related
270 # parentheses hacks. The major disadvantage of this scheme is that
271 # it doesn't know about right sides and left sides, so say if you
272 # assign a listop to a variable, it can't tell it's allowed to leave
273 # the parens off the listop.
274
275 # Precedences:
276 # 26             [TODO] inside interpolation context ("")
277 # 25 left        terms and list operators (leftward)
278 # 24 left        ->
279 # 23 nonassoc    ++ --
280 # 22 right       **
281 # 21 right       ! ~ \ and unary + and -
282 # 20 left        =~ !~
283 # 19 left        * / % x
284 # 18 left        + - .
285 # 17 left        << >>
286 # 16 nonassoc    named unary operators
287 # 15 nonassoc    < > <= >= lt gt le ge
288 # 14 nonassoc    == != <=> eq ne cmp
289 # 13 left        &
290 # 12 left        | ^
291 # 11 left        &&
292 # 10 left        ||
293 #  9 nonassoc    ..  ...
294 #  8 right       ?:
295 #  7 right       = += -= *= etc.
296 #  6 left        , =>
297 #  5 nonassoc    list operators (rightward)
298 #  4 right       not
299 #  3 left        and
300 #  2 left        or xor
301 #  1             statement modifiers
302 #  0.5           statements, but still print scopes as do { ... }
303 #  0             statement level
304 # -1             format body
305
306 # Nonprinting characters with special meaning:
307 # \cS - steal parens (see maybe_parens_unop)
308 # \n - newline and indent
309 # \t - increase indent
310 # \b - decrease indent ('outdent')
311 # \f - flush left (no indent)
312 # \cK - kill following semicolon, if any
313
314
315
316
317 # _pessimise_walk(): recursively walk the optree of a sub,
318 # possibly undoing optimisations along the way.
319
320 sub _pessimise_walk {
321     my ($self, $startop) = @_;
322
323     return unless $$startop;
324     my ($op, $prevop);
325     for ($op = $startop; $$op; $prevop = $op, $op = $op->sibling) {
326         my $ppname = $op->name;
327
328         # pessimisations start here
329
330         if ($ppname eq "padrange") {
331             # remove PADRANGE:
332             # the original optimisation either (1) changed this:
333             #    pushmark -> (various pad and list and null ops) -> the_rest
334             # or (2), for the = @_ case, changed this:
335             #    pushmark -> gv[_] -> rv2av -> (pad stuff)       -> the_rest
336             # into this:
337             #    padrange ----------------------------------------> the_rest
338             # so we just need to convert the padrange back into a
339             # pushmark, and in case (1), set its op_next to op_sibling,
340             # which is the head of the original chain of optimised-away
341             # pad ops, or for (2), set it to sibling->first, which is
342             # the original gv[_].
343
344             $B::overlay->{$$op} = {
345                     name => 'pushmark',
346                     private => ($op->private & OPpLVAL_INTRO),
347                     next    => ($op->flags & OPf_SPECIAL)
348                                     ? $op->sibling->first
349                                     : $op->sibling,
350             };
351         }
352
353         # pessimisations end here
354
355         if (class($op) eq 'PMOP'
356             && ref($op->pmreplroot)
357             && ${$op->pmreplroot}
358             && $op->pmreplroot->isa( 'B::OP' ))
359         {
360             $self-> _pessimise_walk($op->pmreplroot);
361         }
362
363         if ($op->flags & OPf_KIDS) {
364             $self-> _pessimise_walk($op->first);
365         }
366
367     }
368 }
369
370
371 # _pessimise_walk_exe(): recursively walk the op_next chain of a sub,
372 # possibly undoing optimisations along the way.
373
374 sub _pessimise_walk_exe {
375     my ($self, $startop, $visited) = @_;
376
377     return unless $$startop;
378     return if $visited->{$$startop};
379     my ($op, $prevop);
380     for ($op = $startop; $$op; $prevop = $op, $op = $op->next) {
381         last if $visited->{$$op};
382         $visited->{$$op} = 1;
383         my $ppname = $op->name;
384         if ($ppname =~
385             /^((and|d?or)(assign)?|(map|grep)while|range|cond_expr|once)$/
386             # entertry is also a logop, but its op_other invariably points
387             # into the same chain as the main execution path, so we skip it
388         ) {
389             $self->_pessimise_walk_exe($op->other, $visited);
390         }
391         elsif ($ppname eq "subst") {
392             $self->_pessimise_walk_exe($op->pmreplstart, $visited);
393         }
394         elsif ($ppname =~ /^(enter(loop|iter))$/) {
395             # redoop and nextop will already be covered by the main block
396             # of the loop
397             $self->_pessimise_walk_exe($op->lastop, $visited);
398         }
399
400         # pessimisations start here
401     }
402 }
403
404 # Go through an optree and "remove" some optimisations by using an
405 # overlay to selectively modify or un-null some ops. Deparsing in the
406 # absence of those optimisations is then easier.
407 #
408 # Note that older optimisations are not removed, as Deparse was already
409 # written to recognise them before the pessimise/overlay system was added.
410
411 sub pessimise {
412     my ($self, $root, $start) = @_;
413
414     # walk tree in root-to-branch order
415     $self->_pessimise_walk($root);
416
417     my %visited;
418     # walk tree in execution order
419     $self->_pessimise_walk_exe($start, \%visited);
420 }
421
422
423 sub null {
424     my $op = shift;
425     return class($op) eq "NULL";
426 }
427
428 sub todo {
429     my $self = shift;
430     my($cv, $is_form) = @_;
431     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
432     my $seq;
433     if ($cv->OUTSIDE_SEQ) {
434         $seq = $cv->OUTSIDE_SEQ;
435     } elsif (!null($cv->START) and is_state($cv->START)) {
436         $seq = $cv->START->cop_seq;
437     } else {
438         $seq = 0;
439     }
440     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
441     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
442         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
443     }
444 }
445
446 sub next_todo {
447     my $self = shift;
448     my $ent = shift @{$self->{'subs_todo'}};
449     my $cv = $ent->[1];
450     my $gv = $cv->GV;
451     my $name = $self->gv_name($gv);
452     if ($ent->[2]) {
453         return "format $name =\n"
454             . $self->deparse_format($ent->[1]). "\n";
455     } else {
456         $self->{'subs_declared'}{$name} = 1;
457         if ($name eq "BEGIN") {
458             my $use_dec = $self->begin_is_use($cv);
459             if (defined ($use_dec) and $self->{'expand'} < 5) {
460                 return () if 0 == length($use_dec);
461                 return $use_dec;
462             }
463         }
464         my $l = '';
465         if ($self->{'linenums'}) {
466             my $line = $gv->LINE;
467             my $file = $gv->FILE;
468             $l = "\n\f#line $line \"$file\"\n";
469         }
470         my $p = '';
471         if (class($cv->STASH) ne "SPECIAL") {
472             my $stash = $cv->STASH->NAME;
473             if ($stash ne $self->{'curstash'}) {
474                 $p = "package $stash;\n";
475                 $name = "$self->{'curstash'}::$name" unless $name =~ /::/;
476                 $self->{'curstash'} = $stash;
477             }
478             $name =~ s/^\Q$stash\E::(?!\z|.*::)//;
479         }
480         return "${p}${l}sub $name " . $self->deparse_sub($cv);
481     }
482 }
483
484 # Return a "use" declaration for this BEGIN block, if appropriate
485 sub begin_is_use {
486     my ($self, $cv) = @_;
487     my $root = $cv->ROOT;
488     local @$self{qw'curcv curcvlex'} = ($cv);
489     local $B::overlay = {};
490     $self->pessimise($root, $cv->START);
491 #require B::Debug;
492 #B::walkoptree($cv->ROOT, "debug");
493     my $lineseq = $root->first;
494     return if $lineseq->name ne "lineseq";
495
496     my $req_op = $lineseq->first->sibling;
497     return if $req_op->name ne "require";
498
499     my $module;
500     if ($req_op->first->private & OPpCONST_BARE) {
501         # Actually it should always be a bareword
502         $module = $self->const_sv($req_op->first)->PV;
503         $module =~ s[/][::]g;
504         $module =~ s/.pm$//;
505     }
506     else {
507         $module = $self->const($self->const_sv($req_op->first), 6);
508     }
509
510     my $version;
511     my $version_op = $req_op->sibling;
512     return if class($version_op) eq "NULL";
513     if ($version_op->name eq "lineseq") {
514         # We have a version parameter; skip nextstate & pushmark
515         my $constop = $version_op->first->next->next;
516
517         return unless $self->const_sv($constop)->PV eq $module;
518         $constop = $constop->sibling;
519         $version = $self->const_sv($constop);
520         if (class($version) eq "IV") {
521             $version = $version->int_value;
522         } elsif (class($version) eq "NV") {
523             $version = $version->NV;
524         } elsif (class($version) ne "PVMG") {
525             # Includes PVIV and PVNV
526             $version = $version->PV;
527         } else {
528             # version specified as a v-string
529             $version = 'v'.join '.', map ord, split //, $version->PV;
530         }
531         $constop = $constop->sibling;
532         return if $constop->name ne "method_named";
533         return if $self->const_sv($constop)->PV ne "VERSION";
534     }
535
536     $lineseq = $version_op->sibling;
537     return if $lineseq->name ne "lineseq";
538     my $entersub = $lineseq->first->sibling;
539     if ($entersub->name eq "stub") {
540         return "use $module $version ();\n" if defined $version;
541         return "use $module ();\n";
542     }
543     return if $entersub->name ne "entersub";
544
545     # See if there are import arguments
546     my $args = '';
547
548     my $svop = $entersub->first->sibling; # Skip over pushmark
549     return unless $self->const_sv($svop)->PV eq $module;
550
551     # Pull out the arguments
552     for ($svop=$svop->sibling; $svop->name ne "method_named";
553                 $svop = $svop->sibling) {
554         $args .= ", " if length($args);
555         $args .= $self->deparse($svop, 6);
556     }
557
558     my $use = 'use';
559     my $method_named = $svop;
560     return if $method_named->name ne "method_named";
561     my $method_name = $self->const_sv($method_named)->PV;
562
563     if ($method_name eq "unimport") {
564         $use = 'no';
565     }
566
567     # Certain pragmas are dealt with using hint bits,
568     # so we ignore them here
569     if ($module eq 'strict' || $module eq 'integer'
570         || $module eq 'bytes' || $module eq 'warnings'
571         || $module eq 'feature') {
572         return "";
573     }
574
575     if (defined $version && length $args) {
576         return "$use $module $version ($args);\n";
577     } elsif (defined $version) {
578         return "$use $module $version;\n";
579     } elsif (length $args) {
580         return "$use $module ($args);\n";
581     } else {
582         return "$use $module;\n";
583     }
584 }
585
586 sub stash_subs {
587     my ($self, $pack, $seen) = @_;
588     my (@ret, $stash);
589     if (!defined $pack) {
590         $pack = '';
591         $stash = \%::;
592     }
593     else {
594         $pack =~ s/(::)?$/::/;
595         no strict 'refs';
596         $stash = \%{"main::$pack"};
597     }
598     return
599         if ($seen ||= {})->{
600             $INC{"overload.pm"} ? overload::StrVal($stash) : $stash
601            }++;
602     my %stash = svref_2object($stash)->ARRAY;
603     while (my ($key, $val) = each %stash) {
604         my $class = class($val);
605         if ($class eq "PV") {
606             # Just a prototype. As an ugly but fairly effective way
607             # to find out if it belongs here is to see if the AUTOLOAD
608             # (if any) for the stash was defined in one of our files.
609             my $A = $stash{"AUTOLOAD"};
610             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
611                 && class($A->CV) eq "CV") {
612                 my $AF = $A->FILE;
613                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
614             }
615             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
616         } elsif ($class eq "IV" && !($val->FLAGS & SVf_ROK)) {
617             # Just a name. As above.
618             # But skip proxy constant subroutines, as some form of perl-space
619             # visible code must have created them, be it a use statement, or
620             # some direct symbol-table manipulation code that we will Deparse
621             my $A = $stash{"AUTOLOAD"};
622             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
623                 && class($A->CV) eq "CV") {
624                 my $AF = $A->FILE;
625                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
626             }
627             push @{$self->{'protos_todo'}}, [$pack . $key, undef];
628         } elsif ($class eq "GV") {
629             if (class(my $cv = $val->CV) ne "SPECIAL") {
630                 next if $self->{'subs_done'}{$$val}++;
631                 next if $$val != ${$cv->GV};   # Ignore imposters
632                 $self->todo($cv, 0);
633             }
634             if (class(my $cv = $val->FORM) ne "SPECIAL") {
635                 next if $self->{'forms_done'}{$$val}++;
636                 next if $$val != ${$cv->GV};   # Ignore imposters
637                 $self->todo($cv, 1);
638             }
639             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
640                 $self->stash_subs($pack . $key, $seen);
641             }
642         }
643     }
644 }
645
646 sub print_protos {
647     my $self = shift;
648     my $ar;
649     my @ret;
650     foreach $ar (@{$self->{'protos_todo'}}) {
651         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
652         push @ret, "sub " . $ar->[0] .  "$proto;\n";
653     }
654     delete $self->{'protos_todo'};
655     return @ret;
656 }
657
658 sub style_opts {
659     my $self = shift;
660     my $opts = shift;
661     my $opt;
662     while (length($opt = substr($opts, 0, 1))) {
663         if ($opt eq "C") {
664             $self->{'cuddle'} = " ";
665             $opts = substr($opts, 1);
666         } elsif ($opt eq "i") {
667             $opts =~ s/^i(\d+)//;
668             $self->{'indent_size'} = $1;
669         } elsif ($opt eq "T") {
670             $self->{'use_tabs'} = 1;
671             $opts = substr($opts, 1);
672         } elsif ($opt eq "v") {
673             $opts =~ s/^v([^.]*)(.|$)//;
674             $self->{'ex_const'} = $1;
675         }
676     }
677 }
678
679 sub new {
680     my $class = shift;
681     my $self = bless {}, $class;
682     $self->{'cuddle'} = "\n";
683     $self->{'curcop'} = undef;
684     $self->{'curstash'} = "main";
685     $self->{'ex_const'} = "'???'";
686     $self->{'expand'} = 0;
687     $self->{'files'} = {};
688     $self->{'indent_size'} = 4;
689     $self->{'linenums'} = 0;
690     $self->{'parens'} = 0;
691     $self->{'subs_todo'} = [];
692     $self->{'unquote'} = 0;
693     $self->{'use_dumper'} = 0;
694     $self->{'use_tabs'} = 0;
695
696     $self->{'ambient_arybase'} = 0;
697     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
698     $self->{'ambient_hints'} = 0;
699     $self->{'ambient_hinthash'} = undef;
700     $self->init();
701
702     while (my $arg = shift @_) {
703         if ($arg eq "-d") {
704             $self->{'use_dumper'} = 1;
705             require Data::Dumper;
706         } elsif ($arg =~ /^-f(.*)/) {
707             $self->{'files'}{$1} = 1;
708         } elsif ($arg eq "-l") {
709             $self->{'linenums'} = 1;
710         } elsif ($arg eq "-p") {
711             $self->{'parens'} = 1;
712         } elsif ($arg eq "-P") {
713             $self->{'noproto'} = 1;
714         } elsif ($arg eq "-q") {
715             $self->{'unquote'} = 1;
716         } elsif (substr($arg, 0, 2) eq "-s") {
717             $self->style_opts(substr $arg, 2);
718         } elsif ($arg =~ /^-x(\d)$/) {
719             $self->{'expand'} = $1;
720         }
721     }
722     return $self;
723 }
724
725 {
726     # Mask out the bits that L<warnings::register> uses
727     my $WARN_MASK;
728     BEGIN {
729         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
730     }
731     sub WARN_MASK () {
732         return $WARN_MASK;
733     }
734 }
735
736 # Initialise the contextual information, either from
737 # defaults provided with the ambient_pragmas method,
738 # or from perl's own defaults otherwise.
739 sub init {
740     my $self = shift;
741
742     $self->{'arybase'}  = $self->{'ambient_arybase'};
743     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
744                                 ? $self->{'ambient_warnings'} & WARN_MASK
745                                 : undef;
746     $self->{'hints'}    = $self->{'ambient_hints'};
747     $self->{'hints'} &= 0xFF if $] < 5.009;
748     $self->{'hinthash'} = $self->{'ambient_hinthash'};
749
750     # also a convenient place to clear out subs_declared
751     delete $self->{'subs_declared'};
752 }
753
754 sub compile {
755     my(@args) = @_;
756     return sub {
757         my $self = B::Deparse->new(@args);
758         # First deparse command-line args
759         if (defined $^I) { # deparse -i
760             print q(BEGIN { $^I = ).perlstring($^I).qq(; }\n);
761         }
762         if ($^W) { # deparse -w
763             print qq(BEGIN { \$^W = $^W; }\n);
764         }
765         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
766             my $fs = perlstring($/) || 'undef';
767             my $bs = perlstring($O::savebackslash) || 'undef';
768             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
769         }
770         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
771         my @UNITCHECKs = B::unitcheck_av->isa("B::AV")
772             ? B::unitcheck_av->ARRAY
773             : ();
774         my @CHECKs  = B::check_av->isa("B::AV") ? B::check_av->ARRAY : ();
775         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
776         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
777         for my $block (@BEGINs, @UNITCHECKs, @CHECKs, @INITs, @ENDs) {
778             $self->todo($block, 0);
779         }
780         $self->stash_subs();
781         local($SIG{"__DIE__"}) =
782           sub {
783               if ($self->{'curcop'}) {
784                   my $cop = $self->{'curcop'};
785                   my($line, $file) = ($cop->line, $cop->file);
786                   print STDERR "While deparsing $file near line $line,\n";
787               }
788             };
789         $self->{'curcv'} = main_cv;
790         $self->{'curcvlex'} = undef;
791         print $self->print_protos;
792         @{$self->{'subs_todo'}} =
793           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
794         my $root = main_root;
795         local $B::overlay = {};
796         unless (null $root) {
797             $self->pessimise($root, main_start);
798             print $self->indent($self->deparse_root($root)), "\n";
799         }
800         my @text;
801         while (scalar(@{$self->{'subs_todo'}})) {
802             push @text, $self->next_todo;
803         }
804         print $self->indent(join("", @text)), "\n" if @text;
805
806         # Print __DATA__ section, if necessary
807         no strict 'refs';
808         my $laststash = defined $self->{'curcop'}
809             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
810         if (defined *{$laststash."::DATA"}{IO}) {
811             print "package $laststash;\n"
812                 unless $laststash eq $self->{'curstash'};
813             print "__DATA__\n";
814             print readline(*{$laststash."::DATA"});
815         }
816     }
817 }
818
819 sub coderef2text {
820     my $self = shift;
821     my $sub = shift;
822     croak "Usage: ->coderef2text(CODEREF)" unless UNIVERSAL::isa($sub, "CODE");
823
824     $self->init();
825     return $self->indent($self->deparse_sub(svref_2object($sub)));
826 }
827
828 my %strict_bits = do {
829     local $^H;
830     map +($_ => strict::bits($_)), qw/refs subs vars/
831 };
832
833 sub ambient_pragmas {
834     my $self = shift;
835     my ($arybase, $hint_bits, $warning_bits, $hinthash) = (0, 0);
836
837     while (@_ > 1) {
838         my $name = shift();
839         my $val  = shift();
840
841         if ($name eq 'strict') {
842             require strict;
843
844             if ($val eq 'none') {
845                 $hint_bits &= $strict_bits{$_} for qw/refs subs vars/;
846                 next();
847             }
848
849             my @names;
850             if ($val eq "all") {
851                 @names = qw/refs subs vars/;
852             }
853             elsif (ref $val) {
854                 @names = @$val;
855             }
856             else {
857                 @names = split' ', $val;
858             }
859             $hint_bits |= $strict_bits{$_} for @names;
860         }
861
862         elsif ($name eq '$[') {
863             if (OPpCONST_ARYBASE) {
864                 $arybase = $val;
865             } else {
866                 croak "\$[ can't be non-zero on this perl" unless $val == 0;
867             }
868         }
869
870         elsif ($name eq 'integer'
871             || $name eq 'bytes'
872             || $name eq 'utf8') {
873             require "$name.pm";
874             if ($val) {
875                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
876             }
877             else {
878                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
879             }
880         }
881
882         elsif ($name eq 're') {
883             require re;
884             if ($val eq 'none') {
885                 $hint_bits &= ~re::bits(qw/taint eval/);
886                 next();
887             }
888
889             my @names;
890             if ($val eq 'all') {
891                 @names = qw/taint eval/;
892             }
893             elsif (ref $val) {
894                 @names = @$val;
895             }
896             else {
897                 @names = split' ',$val;
898             }
899             $hint_bits |= re::bits(@names);
900         }
901
902         elsif ($name eq 'warnings') {
903             if ($val eq 'none') {
904                 $warning_bits = $warnings::NONE;
905                 next();
906             }
907
908             my @names;
909             if (ref $val) {
910                 @names = @$val;
911             }
912             else {
913                 @names = split/\s+/, $val;
914             }
915
916             $warning_bits = $warnings::NONE if !defined ($warning_bits);
917             $warning_bits |= warnings::bits(@names);
918         }
919
920         elsif ($name eq 'warning_bits') {
921             $warning_bits = $val;
922         }
923
924         elsif ($name eq 'hint_bits') {
925             $hint_bits = $val;
926         }
927
928         elsif ($name eq '%^H') {
929             $hinthash = $val;
930         }
931
932         else {
933             croak "Unknown pragma type: $name";
934         }
935     }
936     if (@_) {
937         croak "The ambient_pragmas method expects an even number of args";
938     }
939
940     $self->{'ambient_arybase'} = $arybase;
941     $self->{'ambient_warnings'} = $warning_bits;
942     $self->{'ambient_hints'} = $hint_bits;
943     $self->{'ambient_hinthash'} = $hinthash;
944 }
945
946 # This method is the inner loop, so try to keep it simple
947 sub deparse {
948     my $self = shift;
949     my($op, $cx) = @_;
950
951     Carp::confess("Null op in deparse") if !defined($op)
952                                         || class($op) eq "NULL";
953     my $meth = "pp_" . $op->name;
954     return $self->$meth($op, $cx);
955 }
956
957 sub indent {
958     my $self = shift;
959     my $txt = shift;
960     my @lines = split(/\n/, $txt);
961     my $leader = "";
962     my $level = 0;
963     my $line;
964     for $line (@lines) {
965         my $cmd = substr($line, 0, 1);
966         if ($cmd eq "\t" or $cmd eq "\b") {
967             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
968             if ($self->{'use_tabs'}) {
969                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
970             } else {
971                 $leader = " " x $level;
972             }
973             $line = substr($line, 1);
974         }
975         if (index($line, "\f") > 0) {
976                 $line =~ s/\f/\n/;
977         }
978         if (substr($line, 0, 1) eq "\f") {
979             $line = substr($line, 1); # no indent
980         } else {
981             $line = $leader . $line;
982         }
983         $line =~ s/\cK;?//g;
984     }
985     return join("\n", @lines);
986 }
987
988 sub deparse_sub {
989     my $self = shift;
990     my $cv = shift;
991     my $proto = "";
992 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
993 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
994     local $self->{'curcop'} = $self->{'curcop'};
995     if ($cv->FLAGS & SVf_POK) {
996         $proto = "(". $cv->PV . ") ";
997     }
998     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
999         $proto .= ": ";
1000         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
1001         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
1002         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
1003     }
1004
1005     local($self->{'curcv'}) = $cv;
1006     local($self->{'curcvlex'});
1007     local(@$self{qw'curstash warnings hints hinthash'})
1008                 = @$self{qw'curstash warnings hints hinthash'};
1009     my $body;
1010     my $root = $cv->ROOT;
1011     local $B::overlay = {};
1012     if (not null $root) {
1013         $self->pessimise($root, $cv->START);
1014         my $lineseq = $root->first;
1015         if ($lineseq->name eq "lineseq") {
1016             my @ops;
1017             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
1018                 push @ops, $o;
1019             }
1020             $body = $self->lineseq(undef, 0, @ops).";";
1021             my $scope_en = $self->find_scope_en($lineseq);
1022             if (defined $scope_en) {
1023                 my $subs = join"", $self->seq_subs($scope_en);
1024                 $body .= ";\n$subs" if length($subs);
1025             }
1026         }
1027         else {
1028             $body = $self->deparse($root->first, 0);
1029         }
1030     }
1031     else {
1032         my $sv = $cv->const_sv;
1033         if ($$sv) {
1034             # uh-oh. inlinable sub... format it differently
1035             return $proto . "{ " . $self->const($sv, 0) . " }\n";
1036         } else { # XSUB? (or just a declaration)
1037             return "$proto;\n";
1038         }
1039     }
1040     return $proto ."{\n\t$body\n\b}" ."\n";
1041 }
1042
1043 sub deparse_format {
1044     my $self = shift;
1045     my $form = shift;
1046     my @text;
1047     local($self->{'curcv'}) = $form;
1048     local($self->{'curcvlex'});
1049     local($self->{'in_format'}) = 1;
1050     local(@$self{qw'curstash warnings hints hinthash'})
1051                 = @$self{qw'curstash warnings hints hinthash'};
1052     my $op = $form->ROOT;
1053     local $B::overlay = {};
1054     $self->pessimise($op, $form->START);
1055     my $kid;
1056     return "\f." if $op->first->name eq 'stub'
1057                 || $op->first->name eq 'nextstate';
1058     $op = $op->first->first; # skip leavewrite, lineseq
1059     while (not null $op) {
1060         $op = $op->sibling; # skip nextstate
1061         my @exprs;
1062         $kid = $op->first->sibling; # skip pushmark
1063         push @text, "\f".$self->const_sv($kid)->PV;
1064         $kid = $kid->sibling;
1065         for (; not null $kid; $kid = $kid->sibling) {
1066             push @exprs, $self->deparse($kid, -1);
1067             $exprs[-1] =~ s/;\z//;
1068         }
1069         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
1070         $op = $op->sibling;
1071     }
1072     return join("", @text) . "\f.";
1073 }
1074
1075 sub is_scope {
1076     my $op = shift;
1077     return $op->name eq "leave" || $op->name eq "scope"
1078       || $op->name eq "lineseq"
1079         || ($op->name eq "null" && class($op) eq "UNOP"
1080             && (is_scope($op->first) || $op->first->name eq "enter"));
1081 }
1082
1083 sub is_state {
1084     my $name = $_[0]->name;
1085     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
1086 }
1087
1088 sub is_miniwhile { # check for one-line loop ('foo() while $y--')
1089     my $op = shift;
1090     return (!null($op) and null($op->sibling)
1091             and $op->name eq "null" and class($op) eq "UNOP"
1092             and (($op->first->name =~ /^(and|or)$/
1093                   and $op->first->first->sibling->name eq "lineseq")
1094                  or ($op->first->name eq "lineseq"
1095                      and not null $op->first->first->sibling
1096                      and $op->first->first->sibling->name eq "unstack")
1097                  ));
1098 }
1099
1100 # Check if the op and its sibling are the initialization and the rest of a
1101 # for (..;..;..) { ... } loop
1102 sub is_for_loop {
1103     my $op = shift;
1104     # This OP might be almost anything, though it won't be a
1105     # nextstate. (It's the initialization, so in the canonical case it
1106     # will be an sassign.) The sibling is (old style) a lineseq whose
1107     # first child is a nextstate and whose second is a leaveloop, or
1108     # (new style) an unstack whose sibling is a leaveloop.
1109     my $lseq = $op->sibling;
1110     return 0 unless !is_state($op) and !null($lseq);
1111     if ($lseq->name eq "lineseq") {
1112         if ($lseq->first && !null($lseq->first) && is_state($lseq->first)
1113             && (my $sib = $lseq->first->sibling)) {
1114             return (!null($sib) && $sib->name eq "leaveloop");
1115         }
1116     } elsif ($lseq->name eq "unstack" && ($lseq->flags & OPf_SPECIAL)) {
1117         my $sib = $lseq->sibling;
1118         return $sib && !null($sib) && $sib->name eq "leaveloop";
1119     }
1120     return 0;
1121 }
1122
1123 sub is_scalar {
1124     my $op = shift;
1125     return ($op->name eq "rv2sv" or
1126             $op->name eq "padsv" or
1127             $op->name eq "gv" or # only in array/hash constructs
1128             $op->flags & OPf_KIDS && !null($op->first)
1129               && $op->first->name eq "gvsv");
1130 }
1131
1132 sub maybe_parens {
1133     my $self = shift;
1134     my($text, $cx, $prec) = @_;
1135     if ($prec < $cx              # unary ops nest just fine
1136         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
1137         or $self->{'parens'})
1138     {
1139         $text = "($text)";
1140         # In a unop, let parent reuse our parens; see maybe_parens_unop
1141         $text = "\cS" . $text if $cx == 16;
1142         return $text;
1143     } else {
1144         return $text;
1145     }
1146 }
1147
1148 # same as above, but get around the 'if it looks like a function' rule
1149 sub maybe_parens_unop {
1150     my $self = shift;
1151     my($name, $kid, $cx) = @_;
1152     if ($cx > 16 or $self->{'parens'}) {
1153         $kid =  $self->deparse($kid, 1);
1154         if ($name eq "umask" && $kid =~ /^\d+$/) {
1155             $kid = sprintf("%#o", $kid);
1156         }
1157         return $self->keyword($name) . "($kid)";
1158     } else {
1159         $kid = $self->deparse($kid, 16);
1160         if ($name eq "umask" && $kid =~ /^\d+$/) {
1161             $kid = sprintf("%#o", $kid);
1162         }
1163         $name = $self->keyword($name);
1164         if (substr($kid, 0, 1) eq "\cS") {
1165             # use kid's parens
1166             return $name . substr($kid, 1);
1167         } elsif (substr($kid, 0, 1) eq "(") {
1168             # avoid looks-like-a-function trap with extra parens
1169             # ('+' can lead to ambiguities)
1170             return "$name(" . $kid  . ")";
1171         } else {
1172             return "$name $kid";
1173         }
1174     }
1175 }
1176
1177 sub maybe_parens_func {
1178     my $self = shift;
1179     my($func, $text, $cx, $prec) = @_;
1180     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
1181         return "$func($text)";
1182     } else {
1183         return "$func $text";
1184     }
1185 }
1186
1187 sub maybe_local {
1188     my $self = shift;
1189     my($op, $cx, $text) = @_;
1190     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
1191     if ($op->private & (OPpLVAL_INTRO|$our_intro)
1192         and not $self->{'avoid_local'}{$$op}) {
1193         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
1194         if( $our_local eq 'our' ) {
1195             if ( $text !~ /^\W(\w+::)*\w+\z/
1196              and !utf8::decode($text) || $text !~ /^\W(\w+::)*\w+\z/
1197             ) {
1198                 die "Unexpected our($text)\n";
1199             }
1200             $text =~ s/(\w+::)+//;
1201         }
1202         if (want_scalar($op)) {
1203             return "$our_local $text";
1204         } else {
1205             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
1206         }
1207     } else {
1208         return $text;
1209     }
1210 }
1211
1212 sub maybe_targmy {
1213     my $self = shift;
1214     my($op, $cx, $func, @args) = @_;
1215     if ($op->private & OPpTARGET_MY) {
1216         my $var = $self->padname($op->targ);
1217         my $val = $func->($self, $op, 7, @args);
1218         return $self->maybe_parens("$var = $val", $cx, 7);
1219     } else {
1220         return $func->($self, $op, $cx, @args);
1221     }
1222 }
1223
1224 sub padname_sv {
1225     my $self = shift;
1226     my $targ = shift;
1227     return $self->{'curcv'}->PADLIST->ARRAYelt(0)->ARRAYelt($targ);
1228 }
1229
1230 sub maybe_my {
1231     my $self = shift;
1232     my($op, $cx, $text, $forbid_parens) = @_;
1233     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
1234         my $my = $op->private & OPpPAD_STATE
1235             ? $self->keyword("state")
1236             : "my";
1237         if ($forbid_parens || want_scalar($op)) {
1238             return "$my $text";
1239         } else {
1240             return $self->maybe_parens_func($my, $text, $cx, 16);
1241         }
1242     } else {
1243         return $text;
1244     }
1245 }
1246
1247 # The following OPs don't have functions:
1248
1249 # pp_padany -- does not exist after parsing
1250
1251 sub AUTOLOAD {
1252     if ($AUTOLOAD =~ s/^.*::pp_//) {
1253         warn "unexpected OP_".uc $AUTOLOAD;
1254         return "XXX";
1255     } else {
1256         die "Undefined subroutine $AUTOLOAD called";
1257     }
1258 }
1259
1260 sub DESTROY {}  #       Do not AUTOLOAD
1261
1262 # $root should be the op which represents the root of whatever
1263 # we're sequencing here. If it's undefined, then we don't append
1264 # any subroutine declarations to the deparsed ops, otherwise we
1265 # append appropriate declarations.
1266 sub lineseq {
1267     my($self, $root, $cx, @ops) = @_;
1268     my($expr, @exprs);
1269
1270     my $out_cop = $self->{'curcop'};
1271     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
1272     my $limit_seq;
1273     if (defined $root) {
1274         $limit_seq = $out_seq;
1275         my $nseq;
1276         $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
1277         $limit_seq = $nseq if !defined($limit_seq)
1278                            or defined($nseq) && $nseq < $limit_seq;
1279     }
1280     $limit_seq = $self->{'limit_seq'}
1281         if defined($self->{'limit_seq'})
1282         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
1283     local $self->{'limit_seq'} = $limit_seq;
1284
1285     $self->walk_lineseq($root, \@ops,
1286                        sub { push @exprs, $_[0]} );
1287
1288     my $sep = $cx ? '; ' : ";\n";
1289     my $body = join($sep, grep {length} @exprs);
1290     my $subs = "";
1291     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1292         $subs = join "\n", $self->seq_subs($limit_seq);
1293     }
1294     return join($sep, grep {length} $body, $subs);
1295 }
1296
1297 sub scopeop {
1298     my($real_block, $self, $op, $cx) = @_;
1299     my $kid;
1300     my @kids;
1301
1302     local(@$self{qw'curstash warnings hints hinthash'})
1303                 = @$self{qw'curstash warnings hints hinthash'} if $real_block;
1304     if ($real_block) {
1305         $kid = $op->first->sibling; # skip enter
1306         if (is_miniwhile($kid)) {
1307             my $top = $kid->first;
1308             my $name = $top->name;
1309             if ($name eq "and") {
1310                 $name = "while";
1311             } elsif ($name eq "or") {
1312                 $name = "until";
1313             } else { # no conditional -> while 1 or until 0
1314                 return $self->deparse($top->first, 1) . " while 1";
1315             }
1316             my $cond = $top->first;
1317             my $body = $cond->sibling->first; # skip lineseq
1318             $cond = $self->deparse($cond, 1);
1319             $body = $self->deparse($body, 1);
1320             return "$body $name $cond";
1321         }
1322     } else {
1323         $kid = $op->first;
1324     }
1325     for (; !null($kid); $kid = $kid->sibling) {
1326         push @kids, $kid;
1327     }
1328     if ($cx > 0) { # inside an expression, (a do {} while for lineseq)
1329         my $body = $self->lineseq($op, 0, @kids);
1330         return is_lexical_subs(@kids) ? $body : "do {\n\t$body\n\b}";
1331     } else {
1332         my $lineseq = $self->lineseq($op, $cx, @kids);
1333         return (length ($lineseq) ? "$lineseq;" : "");
1334     }
1335 }
1336
1337 sub pp_scope { scopeop(0, @_); }
1338 sub pp_lineseq { scopeop(0, @_); }
1339 sub pp_leave { scopeop(1, @_); }
1340
1341 # This is a special case of scopeop and lineseq, for the case of the
1342 # main_root. The difference is that we print the output statements as
1343 # soon as we get them, for the sake of impatient users.
1344 sub deparse_root {
1345     my $self = shift;
1346     my($op) = @_;
1347     local(@$self{qw'curstash warnings hints hinthash'})
1348       = @$self{qw'curstash warnings hints hinthash'};
1349     my @kids;
1350     return if null $op->first; # Can happen, e.g., for Bytecode without -k
1351     for (my $kid = $op->first->sibling; !null($kid); $kid = $kid->sibling) {
1352         push @kids, $kid;
1353     }
1354     $self->walk_lineseq($op, \@kids,
1355                         sub { print $self->indent($_[0].';');
1356                               print "\n" unless $_[1] == $#kids;
1357                           });
1358 }
1359
1360 sub walk_lineseq {
1361     my ($self, $op, $kids, $callback) = @_;
1362     my @kids = @$kids;
1363     for (my $i = 0; $i < @kids; $i++) {
1364         my $expr = "";
1365         if (is_state $kids[$i]) {
1366             $expr = $self->deparse($kids[$i++], 0);
1367             if ($i > $#kids) {
1368                 $callback->($expr, $i);
1369                 last;
1370             }
1371         }
1372         if (is_for_loop($kids[$i])) {
1373             $callback->($expr . $self->for_loop($kids[$i], 0),
1374                 $i += $kids[$i]->sibling->name eq "unstack" ? 2 : 1);
1375             next;
1376         }
1377         $expr .= $self->deparse($kids[$i], (@kids != 1)/2);
1378         $expr =~ s/;\n?\z//;
1379         $callback->($expr, $i);
1380     }
1381 }
1382
1383 # The BEGIN {} is used here because otherwise this code isn't executed
1384 # when you run B::Deparse on itself.
1385 my %globalnames;
1386 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1387             "ENV", "ARGV", "ARGVOUT", "_"); }
1388
1389 sub gv_name {
1390     my $self = shift;
1391     my $gv = shift;
1392     my $raw = shift;
1393 Carp::confess() unless ref($gv) eq "B::GV";
1394     my $stash = $gv->STASH->NAME;
1395     my $name = $raw ? $gv->NAME : $gv->SAFENAME;
1396     if ($stash eq 'main' && $name =~ /^::/) {
1397         $stash = '::';
1398     }
1399     elsif (($stash eq 'main'
1400             && ($globalnames{$name} || $name =~ /^[^A-Za-z_:]/))
1401         or ($stash eq $self->{'curstash'} && !$globalnames{$name}
1402             && ($stash eq 'main' || $name !~ /::/))
1403           )
1404     {
1405         $stash = "";
1406     } else {
1407         $stash = $stash . "::";
1408     }
1409     if (!$raw and $name =~ /^(\^..|{)/) {
1410         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1411     }
1412     return $stash . $name;
1413 }
1414
1415 # Return the name to use for a stash variable.
1416 # If a lexical with the same name is in scope, or
1417 # if strictures are enabled, it may need to be
1418 # fully-qualified.
1419 sub stash_variable {
1420     my ($self, $prefix, $name, $cx) = @_;
1421
1422     return "$prefix$name" if $name =~ /::/;
1423
1424     unless ($prefix eq '$' || $prefix eq '@' || #'
1425             $prefix eq '%' || $prefix eq '$#') {
1426         return "$prefix$name";
1427     }
1428
1429     if ($name =~ /^[^\w+-]$/) {
1430       if (defined $cx && $cx == 26) {
1431         if ($prefix eq '@') {
1432             return "$prefix\{$name}";
1433         }
1434         elsif ($name eq '#') { return '${#}' } #  "${#}a" vs "$#a"
1435       }
1436       if ($prefix eq '$#') {
1437         return "\$#{$name}";
1438       }
1439     }
1440
1441     return $prefix . $self->maybe_qualify($prefix, $name);
1442 }
1443
1444 # Return just the name, without the prefix.  It may be returned as a quoted
1445 # string.  The second return value is a boolean indicating that.
1446 sub stash_variable_name {
1447     my($self, $prefix, $gv) = @_;
1448     my $name = $self->gv_name($gv, 1);
1449     $name = $self->maybe_qualify($prefix,$name);
1450     if ($name =~ /^(?:\S|(?!\d)[\ca-\cz]?(?:\w|::)*|\d+)\z/) {
1451         $name =~ s/^([\ca-\cz])/'^'.($1|'@')/e;
1452         $name =~ /^(\^..|{)/ and $name = "{$name}";
1453         return $name, 0; # not quoted
1454     }
1455     else {
1456         single_delim("q", "'", $name), 1;
1457     }
1458 }
1459
1460 sub maybe_qualify {
1461     my ($self,$prefix,$name) = @_;
1462     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1463     return $name if !$prefix || $name =~ /::/;
1464     return $self->{'curstash'}.'::'. $name
1465         if
1466             $name =~ /^(?!\d)\w/         # alphabetic
1467          && $v    !~ /^\$[ab]\z/         # not $a or $b
1468          && !$globalnames{$name}         # not a global name
1469          && $self->{hints} & $strict_bits{vars}  # strict vars
1470          && !$self->lex_in_scope($v,1)   # no "our"
1471       or $self->lex_in_scope($v);        # conflicts with "my" variable
1472     return $name;
1473 }
1474
1475 sub lex_in_scope {
1476     my ($self, $name, $our) = @_;
1477     substr $name, 0, 0, = $our ? 'o' : 'm'; # our/my
1478     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1479
1480     return 0 if !defined($self->{'curcop'});
1481     my $seq = $self->{'curcop'}->cop_seq;
1482     return 0 if !exists $self->{'curcvlex'}{$name};
1483     for my $a (@{$self->{'curcvlex'}{$name}}) {
1484         my ($st, $en) = @$a;
1485         return 1 if $seq > $st && $seq <= $en;
1486     }
1487     return 0;
1488 }
1489
1490 sub populate_curcvlex {
1491     my $self = shift;
1492     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1493         my $padlist = $cv->PADLIST;
1494         # an undef CV still in lexical chain
1495         next if class($padlist) eq "SPECIAL";
1496         my @padlist = $padlist->ARRAY;
1497         my @ns = $padlist[0]->ARRAY;
1498
1499         for (my $i=0; $i<@ns; ++$i) {
1500             next if class($ns[$i]) eq "SPECIAL";
1501             if (class($ns[$i]) eq "PV") {
1502                 # Probably that pesky lexical @_
1503                 next;
1504             }
1505             my $name = $ns[$i]->PVX;
1506             my ($seq_st, $seq_en) =
1507                 ($ns[$i]->FLAGS & SVf_FAKE)
1508                     ? (0, 999999)
1509                     : ($ns[$i]->COP_SEQ_RANGE_LOW, $ns[$i]->COP_SEQ_RANGE_HIGH);
1510
1511             push @{$self->{'curcvlex'}{
1512                         ($ns[$i]->FLAGS & SVpad_OUR ? 'o' : 'm') . $name
1513                   }}, [$seq_st, $seq_en];
1514         }
1515     }
1516 }
1517
1518 sub find_scope_st { ((find_scope(@_))[0]); }
1519 sub find_scope_en { ((find_scope(@_))[1]); }
1520
1521 # Recurses down the tree, looking for pad variable introductions and COPs
1522 sub find_scope {
1523     my ($self, $op, $scope_st, $scope_en) = @_;
1524     carp("Undefined op in find_scope") if !defined $op;
1525     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1526
1527     my @queue = ($op);
1528     while(my $op = shift @queue ) {
1529         for (my $o=$op->first; $$o; $o=$o->sibling) {
1530             if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1531                 my $s = int($self->padname_sv($o->targ)->COP_SEQ_RANGE_LOW);
1532                 my $e = $self->padname_sv($o->targ)->COP_SEQ_RANGE_HIGH;
1533                 $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1534                 $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1535                 return ($scope_st, $scope_en);
1536             }
1537             elsif (is_state($o)) {
1538                 my $c = $o->cop_seq;
1539                 $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1540                 $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1541                 return ($scope_st, $scope_en);
1542             }
1543             elsif ($o->flags & OPf_KIDS) {
1544                 unshift (@queue, $o);
1545             }
1546         }
1547     }
1548
1549     return ($scope_st, $scope_en);
1550 }
1551
1552 # Returns a list of subs which should be inserted before the COP
1553 sub cop_subs {
1554     my ($self, $op, $out_seq) = @_;
1555     my $seq = $op->cop_seq;
1556     # If we have nephews, then our sequence number indicates
1557     # the cop_seq of the end of some sort of scope.
1558     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1559         and my $nseq = $self->find_scope_st($op->sibling) ) {
1560         $seq = $nseq;
1561     }
1562     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1563     return $self->seq_subs($seq);
1564 }
1565
1566 sub seq_subs {
1567     my ($self, $seq) = @_;
1568     my @text;
1569 #push @text, "# ($seq)\n";
1570
1571     return "" if !defined $seq;
1572     while (scalar(@{$self->{'subs_todo'}})
1573            and $seq > $self->{'subs_todo'}[0][0]) {
1574         push @text, $self->next_todo;
1575     }
1576     return @text;
1577 }
1578
1579 sub _features_from_bundle {
1580     my ($hints, $hh) = @_;
1581     foreach (@{$feature::feature_bundle{@feature::hint_bundles[$hints >> $feature::hint_shift]}}) {
1582         $hh->{$feature::feature{$_}} = 1;
1583     }
1584     return $hh;
1585 }
1586
1587 # Notice how subs and formats are inserted between statements here;
1588 # also $[ assignments and pragmas.
1589 sub pp_nextstate {
1590     my $self = shift;
1591     my($op, $cx) = @_;
1592     $self->{'curcop'} = $op;
1593     my @text;
1594     push @text, $self->cop_subs($op);
1595     my $stash = $op->stashpv;
1596     if ($stash ne $self->{'curstash'}) {
1597         push @text, "package $stash;\n";
1598         $self->{'curstash'} = $stash;
1599     }
1600
1601     if (OPpCONST_ARYBASE && $self->{'arybase'} != $op->arybase) {
1602         push @text, '$[ = '. $op->arybase .";\n";
1603         $self->{'arybase'} = $op->arybase;
1604     }
1605
1606     my $warnings = $op->warnings;
1607     my $warning_bits;
1608     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1609         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1610     }
1611     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1612         $warning_bits = $warnings::NONE;
1613     }
1614     elsif ($warnings->isa("B::SPECIAL")) {
1615         $warning_bits = undef;
1616     }
1617     else {
1618         $warning_bits = $warnings->PV & WARN_MASK;
1619     }
1620
1621     if (defined ($warning_bits) and
1622        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1623         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1624         $self->{'warnings'} = $warning_bits;
1625     }
1626
1627     my $hints = $] < 5.008009 ? $op->private : $op->hints;
1628     my $old_hints = $self->{'hints'};
1629     if ($self->{'hints'} != $hints) {
1630         push @text, declare_hints($self->{'hints'}, $hints);
1631         $self->{'hints'} = $hints;
1632     }
1633
1634     my $newhh;
1635     if ($] > 5.009) {
1636         $newhh = $op->hints_hash->HASH;
1637     }
1638
1639     if ($] >= 5.015006) {
1640         # feature bundle hints
1641         my $from = $old_hints & $feature::hint_mask;
1642         my $to   = $    hints & $feature::hint_mask;
1643         if ($from != $to) {
1644             if ($to == $feature::hint_mask) {
1645                 if ($self->{'hinthash'}) {
1646                     delete $self->{'hinthash'}{$_}
1647                         for grep /^feature_/, keys %{$self->{'hinthash'}};
1648                 }
1649                 else { $self->{'hinthash'} = {} }
1650                 $self->{'hinthash'}
1651                     = _features_from_bundle($from, $self->{'hinthash'});
1652             }
1653             else {
1654                 my $bundle =
1655                     $feature::hint_bundles[$to >> $feature::hint_shift];
1656                 $bundle =~ s/(\d[13579])\z/$1+1/e; # 5.11 => 5.12
1657                 push @text, "no feature;\n",
1658                             "use feature ':$bundle';\n";
1659             }
1660         }
1661     }
1662
1663     if ($] > 5.009) {
1664         push @text, declare_hinthash(
1665             $self->{'hinthash'}, $newhh,
1666             $self->{indent_size}, $self->{hints},
1667         );
1668         $self->{'hinthash'} = $newhh;
1669     }
1670
1671     # This should go after of any branches that add statements, to
1672     # increase the chances that it refers to the same line it did in
1673     # the original program.
1674     if ($self->{'linenums'}) {
1675         push @text, "\f#line " . $op->line .
1676           ' "' . $op->file, qq'"\n';
1677     }
1678
1679     push @text, $op->label . ": " if $op->label;
1680
1681     return join("", @text);
1682 }
1683
1684 sub declare_warnings {
1685     my ($from, $to) = @_;
1686     if (($to & WARN_MASK) eq (warnings::bits("all") & WARN_MASK)) {
1687         return "use warnings;\n";
1688     }
1689     elsif (($to & WARN_MASK) eq ("\0"x length($to) & WARN_MASK)) {
1690         return "no warnings;\n";
1691     }
1692     return "BEGIN {\${^WARNING_BITS} = ".perlstring($to)."}\n";
1693 }
1694
1695 sub declare_hints {
1696     my ($from, $to) = @_;
1697     my $use = $to   & ~$from;
1698     my $no  = $from & ~$to;
1699     my $decls = "";
1700     for my $pragma (hint_pragmas($use)) {
1701         $decls .= "use $pragma;\n";
1702     }
1703     for my $pragma (hint_pragmas($no)) {
1704         $decls .= "no $pragma;\n";
1705     }
1706     return $decls;
1707 }
1708
1709 # Internal implementation hints that the core sets automatically, so don't need
1710 # (or want) to be passed back to the user
1711 my %ignored_hints = (
1712     'open<' => 1,
1713     'open>' => 1,
1714     ':'     => 1,
1715     'strict/refs' => 1,
1716     'strict/subs' => 1,
1717     'strict/vars' => 1,
1718 );
1719
1720 my %rev_feature;
1721
1722 sub declare_hinthash {
1723     my ($from, $to, $indent, $hints) = @_;
1724     my $doing_features =
1725         ($hints & $feature::hint_mask) == $feature::hint_mask;
1726     my @decls;
1727     my @features;
1728     my @unfeatures; # bugs?
1729     for my $key (sort keys %$to) {
1730         next if $ignored_hints{$key};
1731         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1732         next if $is_feature and not $doing_features;
1733         if (!exists $from->{$key} or $from->{$key} ne $to->{$key}) {
1734             push(@features, $key), next if $is_feature;
1735             push @decls,
1736                 qq(\$^H{) . single_delim("q", "'", $key) . qq(} = )
1737               . (
1738                    defined $to->{$key}
1739                         ? single_delim("q", "'", $to->{$key})
1740                         : 'undef'
1741                 )
1742               . qq(;);
1743         }
1744     }
1745     for my $key (sort keys %$from) {
1746         next if $ignored_hints{$key};
1747         my $is_feature = $key =~ /^feature_/ && $^V ge 5.15.6;
1748         next if $is_feature and not $doing_features;
1749         if (!exists $to->{$key}) {
1750             push(@unfeatures, $key), next if $is_feature;
1751             push @decls, qq(delete \$^H{'$key'};);
1752         }
1753     }
1754     my @ret;
1755     if (@features || @unfeatures) {
1756         if (!%rev_feature) { %rev_feature = reverse %feature::feature }
1757     }
1758     if (@features) {
1759         push @ret, "use feature "
1760                  . join(", ", map "'$rev_feature{$_}'", @features) . ";\n";
1761     }
1762     if (@unfeatures) {
1763         push @ret, "no feature "
1764                  . join(", ", map "'$rev_feature{$_}'", @unfeatures)
1765                  . ";\n";
1766     }
1767     @decls and
1768         push @ret,
1769              join("\n" . (" " x $indent), "BEGIN {", @decls) . "\n}\n";
1770     return @ret;
1771 }
1772
1773 sub hint_pragmas {
1774     my ($bits) = @_;
1775     my (@pragmas, @strict);
1776     push @pragmas, "integer" if $bits & 0x1;
1777     for (sort keys %strict_bits) {
1778         push @strict, "'$_'" if $bits & $strict_bits{$_};
1779     }
1780     if (@strict == keys %strict_bits) {
1781         push @pragmas, "strict";
1782     }
1783     elsif (@strict) {
1784         push @pragmas, "strict " . join ', ', @strict;
1785     }
1786     push @pragmas, "bytes" if $bits & 0x8;
1787     return @pragmas;
1788 }
1789
1790 sub pp_dbstate { pp_nextstate(@_) }
1791 sub pp_setstate { pp_nextstate(@_) }
1792
1793 sub pp_unstack { return "" } # see also leaveloop
1794
1795 my %feature_keywords = (
1796   # keyword => 'feature',
1797     state   => 'state',
1798     say     => 'say',
1799     given   => 'switch',
1800     when    => 'switch',
1801     default => 'switch',
1802     break   => 'switch',
1803     evalbytes=>'evalbytes',
1804     __SUB__ => '__SUB__',
1805    fc       => 'fc',
1806 );
1807
1808 # keywords that are strong and also have a prototype
1809 #
1810 my %strong_proto_keywords = map { $_ => 1 } qw(
1811     glob
1812     pos
1813     prototype
1814     scalar
1815     study
1816     undef
1817 );
1818
1819 sub keyword {
1820     my $self = shift;
1821     my $name = shift;
1822     return $name if $name =~ /^CORE::/; # just in case
1823     if (exists $feature_keywords{$name}) {
1824         my $hh;
1825         my $hints = $self->{hints} & $feature::hint_mask;
1826         if ($hints && $hints != $feature::hint_mask) {
1827             $hh = _features_from_bundle($hints);
1828         }
1829         elsif ($hints) { $hh = $self->{'hinthash'} }
1830         return "CORE::$name"
1831          if !$hh
1832          || !$hh->{"feature_$feature_keywords{$name}"}
1833     }
1834     if ($strong_proto_keywords{$name}
1835         || ($name !~ /^(?:chom?p|do|exec|glob|s(?:elect|ystem))\z/
1836             && !defined eval{prototype "CORE::$name"})
1837     ) { return $name }
1838     if (
1839         exists $self->{subs_declared}{$name}
1840          or
1841         exists &{"$self->{curstash}::$name"}
1842     ) {
1843         return "CORE::$name"
1844     }
1845     return $name;
1846 }
1847
1848 sub baseop {
1849     my $self = shift;
1850     my($op, $cx, $name) = @_;
1851     return $self->keyword($name);
1852 }
1853
1854 sub pp_stub {
1855     my $self = shift;
1856     my($op, $cx, $name) = @_;
1857     if ($cx >= 1) {
1858         return "()";
1859     }
1860     else {
1861         return "();";
1862     }
1863 }
1864 sub pp_wantarray { baseop(@_, "wantarray") }
1865 sub pp_fork { baseop(@_, "fork") }
1866 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1867 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1868 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1869 sub pp_tms { baseop(@_, "times") }
1870 sub pp_ghostent { baseop(@_, "gethostent") }
1871 sub pp_gnetent { baseop(@_, "getnetent") }
1872 sub pp_gprotoent { baseop(@_, "getprotoent") }
1873 sub pp_gservent { baseop(@_, "getservent") }
1874 sub pp_ehostent { baseop(@_, "endhostent") }
1875 sub pp_enetent { baseop(@_, "endnetent") }
1876 sub pp_eprotoent { baseop(@_, "endprotoent") }
1877 sub pp_eservent { baseop(@_, "endservent") }
1878 sub pp_gpwent { baseop(@_, "getpwent") }
1879 sub pp_spwent { baseop(@_, "setpwent") }
1880 sub pp_epwent { baseop(@_, "endpwent") }
1881 sub pp_ggrent { baseop(@_, "getgrent") }
1882 sub pp_sgrent { baseop(@_, "setgrent") }
1883 sub pp_egrent { baseop(@_, "endgrent") }
1884 sub pp_getlogin { baseop(@_, "getlogin") }
1885
1886 sub POSTFIX () { 1 }
1887
1888 # I couldn't think of a good short name, but this is the category of
1889 # symbolic unary operators with interesting precedence
1890
1891 sub pfixop {
1892     my $self = shift;
1893     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1894     my $kid = $op->first;
1895     $kid = $self->deparse($kid, $prec);
1896     return $self->maybe_parens(($flags & POSTFIX)
1897                                  ? "$kid$name"
1898                                    # avoid confusion with filetests
1899                                  : $name eq '-'
1900                                    && $kid =~ /^[a-zA-Z](?!\w)/
1901                                         ? "$name($kid)"
1902                                         : "$name$kid",
1903                                $cx, $prec);
1904 }
1905
1906 sub pp_preinc { pfixop(@_, "++", 23) }
1907 sub pp_predec { pfixop(@_, "--", 23) }
1908 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1909 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1910 sub pp_i_preinc { pfixop(@_, "++", 23) }
1911 sub pp_i_predec { pfixop(@_, "--", 23) }
1912 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1913 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1914 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1915
1916 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1917 sub real_negate {
1918     my $self = shift;
1919     my($op, $cx) = @_;
1920     if ($op->first->name =~ /^(i_)?negate$/) {
1921         # avoid --$x
1922         $self->pfixop($op, $cx, "-", 21.5);
1923     } else {
1924         $self->pfixop($op, $cx, "-", 21);       
1925     }
1926 }
1927 sub pp_i_negate { pp_negate(@_) }
1928
1929 sub pp_not {
1930     my $self = shift;
1931     my($op, $cx) = @_;
1932     if ($cx <= 4) {
1933         $self->listop($op, $cx, "not", $op->first);
1934     } else {
1935         $self->pfixop($op, $cx, "!", 21);       
1936     }
1937 }
1938
1939 sub unop {
1940     my $self = shift;
1941     my($op, $cx, $name, $nollafr) = @_;
1942     my $kid;
1943     if ($op->flags & OPf_KIDS) {
1944         $kid = $op->first;
1945         if (not $name) {
1946             # this deals with 'boolkeys' right now
1947             return $self->deparse($kid,$cx);
1948         }
1949         my $builtinname = $name;
1950         $builtinname =~ /^CORE::/ or $builtinname = "CORE::$name";
1951         if (defined prototype($builtinname)
1952            && prototype($builtinname) =~ /^;?\*/
1953            && $kid->name eq "rv2gv") {
1954             $kid = $kid->first;
1955         }
1956
1957         if ($nollafr) {
1958             ($kid = $self->deparse($kid, 16)) =~ s/^\cS//;
1959             return $self->maybe_parens(
1960                         $self->keyword($name) . " $kid", $cx, 16
1961                    );
1962         }   
1963         return $self->maybe_parens_unop($name, $kid, $cx);
1964     } else {
1965         return $self->maybe_parens(
1966             $self->keyword($name) . ($op->flags & OPf_SPECIAL ? "()" : ""),
1967             $cx, 16,
1968         );
1969     }
1970 }
1971
1972 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1973 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1974 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1975 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1976 sub pp_defined { unop(@_, "defined") }
1977 sub pp_undef { unop(@_, "undef") }
1978 sub pp_study { unop(@_, "study") }
1979 sub pp_ref { unop(@_, "ref") }
1980 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1981
1982 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1983 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1984 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1985 sub pp_srand { unop(@_, "srand") }
1986 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1987 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1988 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1989 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1990 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1991 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1992 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1993
1994 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1995 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1996 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1997
1998 sub pp_each { unop(@_, "each") }
1999 sub pp_values { unop(@_, "values") }
2000 sub pp_keys { unop(@_, "keys") }
2001 { no strict 'refs'; *{"pp_r$_"} = *{"pp_$_"} for qw< keys each values >; }
2002 sub pp_boolkeys { 
2003     # no name because its an optimisation op that has no keyword
2004     unop(@_,"");
2005 }
2006 sub pp_aeach { unop(@_, "each") }
2007 sub pp_avalues { unop(@_, "values") }
2008 sub pp_akeys { unop(@_, "keys") }
2009 sub pp_pop { unop(@_, "pop") }
2010 sub pp_shift { unop(@_, "shift") }
2011
2012 sub pp_caller { unop(@_, "caller") }
2013 sub pp_reset { unop(@_, "reset") }
2014 sub pp_exit { unop(@_, "exit") }
2015 sub pp_prototype { unop(@_, "prototype") }
2016
2017 sub pp_close { unop(@_, "close") }
2018 sub pp_fileno { unop(@_, "fileno") }
2019 sub pp_umask { unop(@_, "umask") }
2020 sub pp_untie { unop(@_, "untie") }
2021 sub pp_tied { unop(@_, "tied") }
2022 sub pp_dbmclose { unop(@_, "dbmclose") }
2023 sub pp_getc { unop(@_, "getc") }
2024 sub pp_eof { unop(@_, "eof") }
2025 sub pp_tell { unop(@_, "tell") }
2026 sub pp_getsockname { unop(@_, "getsockname") }
2027 sub pp_getpeername { unop(@_, "getpeername") }
2028
2029 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
2030 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
2031 sub pp_readlink { unop(@_, "readlink") }
2032 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
2033 sub pp_readdir { unop(@_, "readdir") }
2034 sub pp_telldir { unop(@_, "telldir") }
2035 sub pp_rewinddir { unop(@_, "rewinddir") }
2036 sub pp_closedir { unop(@_, "closedir") }
2037 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
2038 sub pp_localtime { unop(@_, "localtime") }
2039 sub pp_gmtime { unop(@_, "gmtime") }
2040 sub pp_alarm { unop(@_, "alarm") }
2041 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
2042
2043 sub pp_dofile {
2044     my $code = unop(@_, "do", 1); # llafr does not apply
2045     if ($code =~ s/^((?:CORE::)?do) \{/$1({/) { $code .= ')' }
2046     $code;
2047 }
2048 sub pp_entereval {
2049     unop(
2050       @_,
2051       $_[1]->private & OPpEVAL_BYTES ? $_[0]->keyword('evalbytes') : "eval"
2052     )
2053 }
2054
2055 sub pp_ghbyname { unop(@_, "gethostbyname") }
2056 sub pp_gnbyname { unop(@_, "getnetbyname") }
2057 sub pp_gpbyname { unop(@_, "getprotobyname") }
2058 sub pp_shostent { unop(@_, "sethostent") }
2059 sub pp_snetent { unop(@_, "setnetent") }
2060 sub pp_sprotoent { unop(@_, "setprotoent") }
2061 sub pp_sservent { unop(@_, "setservent") }
2062 sub pp_gpwnam { unop(@_, "getpwnam") }
2063 sub pp_gpwuid { unop(@_, "getpwuid") }
2064 sub pp_ggrnam { unop(@_, "getgrnam") }
2065 sub pp_ggrgid { unop(@_, "getgrgid") }
2066
2067 sub pp_lock { unop(@_, "lock") }
2068
2069 sub pp_continue { unop(@_, "continue"); }
2070 sub pp_break { unop(@_, "break"); }
2071
2072 sub givwhen {
2073     my $self = shift;
2074     my($op, $cx, $givwhen) = @_;
2075
2076     my $enterop = $op->first;
2077     my ($head, $block);
2078     if ($enterop->flags & OPf_SPECIAL) {
2079         $head = $self->keyword("default");
2080         $block = $self->deparse($enterop->first, 0);
2081     }
2082     else {
2083         my $cond = $enterop->first;
2084         my $cond_str = $self->deparse($cond, 1);
2085         $head = "$givwhen ($cond_str)";
2086         $block = $self->deparse($cond->sibling, 0);
2087     }
2088
2089     return "$head {\n".
2090         "\t$block\n".
2091         "\b}\cK";
2092 }
2093
2094 sub pp_leavegiven { givwhen(@_, $_[0]->keyword("given")); }
2095 sub pp_leavewhen  { givwhen(@_, $_[0]->keyword("when")); }
2096
2097 sub pp_exists {
2098     my $self = shift;
2099     my($op, $cx) = @_;
2100     my $arg;
2101     if ($op->private & OPpEXISTS_SUB) {
2102         # Checking for the existence of a subroutine
2103         return $self->maybe_parens_func("exists",
2104                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
2105     }
2106     if ($op->flags & OPf_SPECIAL) {
2107         # Array element, not hash element
2108         return $self->maybe_parens_func("exists",
2109                                 $self->pp_aelem($op->first, 16), $cx, 16);
2110     }
2111     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
2112                                     $cx, 16);
2113 }
2114
2115 sub pp_delete {
2116     my $self = shift;
2117     my($op, $cx) = @_;
2118     my $arg;
2119     if ($op->private & OPpSLICE) {
2120         if ($op->flags & OPf_SPECIAL) {
2121             # Deleting from an array, not a hash
2122             return $self->maybe_parens_func("delete",
2123                                         $self->pp_aslice($op->first, 16),
2124                                         $cx, 16);
2125         }
2126         return $self->maybe_parens_func("delete",
2127                                         $self->pp_hslice($op->first, 16),
2128                                         $cx, 16);
2129     } else {
2130         if ($op->flags & OPf_SPECIAL) {
2131             # Deleting from an array, not a hash
2132             return $self->maybe_parens_func("delete",
2133                                         $self->pp_aelem($op->first, 16),
2134                                         $cx, 16);
2135         }
2136         return $self->maybe_parens_func("delete",
2137                                         $self->pp_helem($op->first, 16),
2138                                         $cx, 16);
2139     }
2140 }
2141
2142 sub pp_require {
2143     my $self = shift;
2144     my($op, $cx) = @_;
2145     my $opname = $op->flags & OPf_SPECIAL ? 'CORE::require' : 'require';
2146     if (class($op) eq "UNOP" and $op->first->name eq "const"
2147         and $op->first->private & OPpCONST_BARE)
2148     {
2149         my $name = $self->const_sv($op->first)->PV;
2150         $name =~ s[/][::]g;
2151         $name =~ s/\.pm//g;
2152         return $self->maybe_parens("$opname $name", $cx, 16);
2153     } else {    
2154         $self->unop(
2155             $op, $cx,
2156             $op->first->name eq 'const'
2157              && $op->first->private & OPpCONST_NOVER
2158                  ? "no"
2159                  : $opname,
2160             1, # llafr does not apply
2161         );
2162     }
2163 }
2164
2165 sub pp_scalar {
2166     my $self = shift;
2167     my($op, $cx) = @_;
2168     my $kid = $op->first;
2169     if (not null $kid->sibling) {
2170         # XXX Was a here-doc
2171         return $self->dquote($op);
2172     }
2173     $self->unop(@_, "scalar");
2174 }
2175
2176
2177 sub padval {
2178     my $self = shift;
2179     my $targ = shift;
2180     return $self->{'curcv'}->PADLIST->ARRAYelt(1)->ARRAYelt($targ);
2181 }
2182
2183 sub anon_hash_or_list {
2184     my $self = shift;
2185     my($op, $cx) = @_;
2186
2187     my($pre, $post) = @{{"anonlist" => ["[","]"],
2188                          "anonhash" => ["{","}"]}->{$op->name}};
2189     my($expr, @exprs);
2190     $op = $op->first->sibling; # skip pushmark
2191     for (; !null($op); $op = $op->sibling) {
2192         $expr = $self->deparse($op, 6);
2193         push @exprs, $expr;
2194     }
2195     if ($pre eq "{" and $cx < 1) {
2196         # Disambiguate that it's not a block
2197         $pre = "+{";
2198     }
2199     return $pre . join(", ", @exprs) . $post;
2200 }
2201
2202 sub pp_anonlist {
2203     my $self = shift;
2204     my ($op, $cx) = @_;
2205     if ($op->flags & OPf_SPECIAL) {
2206         return $self->anon_hash_or_list($op, $cx);
2207     }
2208     warn "Unexpected op pp_" . $op->name() . " without OPf_SPECIAL";
2209     return 'XXX';
2210 }
2211
2212 *pp_anonhash = \&pp_anonlist;
2213
2214 sub pp_refgen {
2215     my $self = shift;   
2216     my($op, $cx) = @_;
2217     my $kid = $op->first;
2218     if ($kid->name eq "null") {
2219         $kid = $kid->first;
2220         if (!null($kid->sibling) and
2221                  $kid->sibling->name eq "anoncode") {
2222             return $self->e_anoncode({ code => $self->padval($kid->sibling->targ) });
2223         } elsif ($kid->name eq "pushmark") {
2224             my $sib_name = $kid->sibling->name;
2225             if ($sib_name =~ /^(pad|rv2)[ah]v$/
2226                 and not $kid->sibling->flags & OPf_REF)
2227             {
2228                 # The @a in \(@a) isn't in ref context, but only when the
2229                 # parens are there.
2230                 return "\\(" . $self->pp_list($op->first) . ")";
2231             } elsif ($sib_name eq 'entersub') {
2232                 my $text = $self->deparse($kid->sibling, 1);
2233                 # Always show parens for \(&func()), but only with -p otherwise
2234                 $text = "($text)" if $self->{'parens'}
2235                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
2236                 return "\\$text";
2237             }
2238         }
2239     }
2240     $self->pfixop($op, $cx, "\\", 20);
2241 }
2242
2243 sub e_anoncode {
2244     my ($self, $info) = @_;
2245     my $text = $self->deparse_sub($info->{code});
2246     return "sub " . $text;
2247 }
2248
2249 sub pp_srefgen { pp_refgen(@_) }
2250
2251 sub pp_readline {
2252     my $self = shift;
2253     my($op, $cx) = @_;
2254     my $kid = $op->first;
2255     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
2256     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
2257     return $self->unop($op, $cx, "readline");
2258 }
2259
2260 sub pp_rcatline {
2261     my $self = shift;
2262     my($op) = @_;
2263     return "<" . $self->gv_name($self->gv_or_padgv($op)) . ">";
2264 }
2265
2266 # Unary operators that can occur as pseudo-listops inside double quotes
2267 sub dq_unop {
2268     my $self = shift;
2269     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
2270     my $kid;
2271     if ($op->flags & OPf_KIDS) {
2272        $kid = $op->first;
2273        # If there's more than one kid, the first is an ex-pushmark.
2274        $kid = $kid->sibling if not null $kid->sibling;
2275        return $self->maybe_parens_unop($name, $kid, $cx);
2276     } else {
2277        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");
2278     }
2279 }
2280
2281 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
2282 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
2283 sub pp_uc { dq_unop(@_, "uc") }
2284 sub pp_lc { dq_unop(@_, "lc") }
2285 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
2286 sub pp_fc { dq_unop(@_, "fc") }
2287
2288 sub loopex {
2289     my $self = shift;
2290     my ($op, $cx, $name) = @_;
2291     if (class($op) eq "PVOP") {
2292         $name .= " " . $op->pv;
2293     } elsif (class($op) eq "OP") {
2294         # no-op
2295     } elsif (class($op) eq "UNOP") {
2296         (my $kid = $self->deparse($op->first, 7)) =~ s/^\cS//;
2297         $name .= " $kid";
2298     }
2299     return $self->maybe_parens($name, $cx, 7);
2300 }
2301
2302 sub pp_last { loopex(@_, "last") }
2303 sub pp_next { loopex(@_, "next") }
2304 sub pp_redo { loopex(@_, "redo") }
2305 sub pp_goto { loopex(@_, "goto") }
2306 sub pp_dump { loopex(@_, "CORE::dump") }
2307
2308 sub ftst {
2309     my $self = shift;
2310     my($op, $cx, $name) = @_;
2311     if (class($op) eq "UNOP") {
2312         # Genuine '-X' filetests are exempt from the LLAFR, but not
2313         # l?stat()
2314         if ($name =~ /^-/) {
2315             (my $kid = $self->deparse($op->first, 16)) =~ s/^\cS//;
2316             return $self->maybe_parens("$name $kid", $cx, 16);
2317         }
2318         return $self->maybe_parens_unop($name, $op->first, $cx);
2319     } elsif (class($op) =~ /^(SV|PAD)OP$/) {
2320         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
2321     } else { # I don't think baseop filetests ever survive ck_ftst, but...
2322         return $name;
2323     }
2324 }
2325
2326 sub pp_lstat    { ftst(@_, "lstat") }
2327 sub pp_stat     { ftst(@_, "stat") }
2328 sub pp_ftrread  { ftst(@_, "-R") }
2329 sub pp_ftrwrite { ftst(@_, "-W") }
2330 sub pp_ftrexec  { ftst(@_, "-X") }
2331 sub pp_fteread  { ftst(@_, "-r") }
2332 sub pp_ftewrite { ftst(@_, "-w") }
2333 sub pp_fteexec  { ftst(@_, "-x") }
2334 sub pp_ftis     { ftst(@_, "-e") }
2335 sub pp_fteowned { ftst(@_, "-O") }
2336 sub pp_ftrowned { ftst(@_, "-o") }
2337 sub pp_ftzero   { ftst(@_, "-z") }
2338 sub pp_ftsize   { ftst(@_, "-s") }
2339 sub pp_ftmtime  { ftst(@_, "-M") }
2340 sub pp_ftatime  { ftst(@_, "-A") }
2341 sub pp_ftctime  { ftst(@_, "-C") }
2342 sub pp_ftsock   { ftst(@_, "-S") }
2343 sub pp_ftchr    { ftst(@_, "-c") }
2344 sub pp_ftblk    { ftst(@_, "-b") }
2345 sub pp_ftfile   { ftst(@_, "-f") }
2346 sub pp_ftdir    { ftst(@_, "-d") }
2347 sub pp_ftpipe   { ftst(@_, "-p") }
2348 sub pp_ftlink   { ftst(@_, "-l") }
2349 sub pp_ftsuid   { ftst(@_, "-u") }
2350 sub pp_ftsgid   { ftst(@_, "-g") }
2351 sub pp_ftsvtx   { ftst(@_, "-k") }
2352 sub pp_fttty    { ftst(@_, "-t") }
2353 sub pp_fttext   { ftst(@_, "-T") }
2354 sub pp_ftbinary { ftst(@_, "-B") }
2355
2356 sub SWAP_CHILDREN () { 1 }
2357 sub ASSIGN () { 2 } # has OP= variant
2358 sub LIST_CONTEXT () { 4 } # Assignment is in list context
2359
2360 my(%left, %right);
2361
2362 sub assoc_class {
2363     my $op = shift;
2364     my $name = $op->name;
2365     if ($name eq "concat" and $op->first->name eq "concat") {
2366         # avoid spurious '=' -- see comment in pp_concat
2367         return "concat";
2368     }
2369     if ($name eq "null" and class($op) eq "UNOP"
2370         and $op->first->name =~ /^(and|x?or)$/
2371         and null $op->first->sibling)
2372     {
2373         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
2374         # with a null that's used as the common end point of the two
2375         # flows of control. For precedence purposes, ignore it.
2376         # (COND_EXPRs have these too, but we don't bother with
2377         # their associativity).
2378         return assoc_class($op->first);
2379     }
2380     return $name . ($op->flags & OPf_STACKED ? "=" : "");
2381 }
2382
2383 # Left associative operators, like '+', for which
2384 # $a + $b + $c is equivalent to ($a + $b) + $c
2385
2386 BEGIN {
2387     %left = ('multiply' => 19, 'i_multiply' => 19,
2388              'divide' => 19, 'i_divide' => 19,
2389              'modulo' => 19, 'i_modulo' => 19,
2390              'repeat' => 19,
2391              'add' => 18, 'i_add' => 18,
2392              'subtract' => 18, 'i_subtract' => 18,
2393              'concat' => 18,
2394              'left_shift' => 17, 'right_shift' => 17,
2395              'bit_and' => 13,
2396              'bit_or' => 12, 'bit_xor' => 12,
2397              'and' => 3,
2398              'or' => 2, 'xor' => 2,
2399             );
2400 }
2401
2402 sub deparse_binop_left {
2403     my $self = shift;
2404     my($op, $left, $prec) = @_;
2405     if ($left{assoc_class($op)} && $left{assoc_class($left)}
2406         and $left{assoc_class($op)} == $left{assoc_class($left)})
2407     {
2408         return $self->deparse($left, $prec - .00001);
2409     } else {
2410         return $self->deparse($left, $prec);    
2411     }
2412 }
2413
2414 # Right associative operators, like '=', for which
2415 # $a = $b = $c is equivalent to $a = ($b = $c)
2416
2417 BEGIN {
2418     %right = ('pow' => 22,
2419               'sassign=' => 7, 'aassign=' => 7,
2420               'multiply=' => 7, 'i_multiply=' => 7,
2421               'divide=' => 7, 'i_divide=' => 7,
2422               'modulo=' => 7, 'i_modulo=' => 7,
2423               'repeat=' => 7,
2424               'add=' => 7, 'i_add=' => 7,
2425               'subtract=' => 7, 'i_subtract=' => 7,
2426               'concat=' => 7,
2427               'left_shift=' => 7, 'right_shift=' => 7,
2428               'bit_and=' => 7,
2429               'bit_or=' => 7, 'bit_xor=' => 7,
2430               'andassign' => 7,
2431               'orassign' => 7,
2432              );
2433 }
2434
2435 sub deparse_binop_right {
2436     my $self = shift;
2437     my($op, $right, $prec) = @_;
2438     if ($right{assoc_class($op)} && $right{assoc_class($right)}
2439         and $right{assoc_class($op)} == $right{assoc_class($right)})
2440     {
2441         return $self->deparse($right, $prec - .00001);
2442     } else {
2443         return $self->deparse($right, $prec);   
2444     }
2445 }
2446
2447 sub binop {
2448     my $self = shift;
2449     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
2450     my $left = $op->first;
2451     my $right = $op->last;
2452     my $eq = "";
2453     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
2454         $eq = "=";
2455         $prec = 7;
2456     }
2457     if ($flags & SWAP_CHILDREN) {
2458         ($left, $right) = ($right, $left);
2459     }
2460     $left = $self->deparse_binop_left($op, $left, $prec);
2461     $left = "($left)" if $flags & LIST_CONTEXT
2462                 && $left !~ /^(my|our|local|)[\@\(]/;
2463     $right = $self->deparse_binop_right($op, $right, $prec);
2464     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
2465 }
2466
2467 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2468 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2469 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
2470 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2471 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2472 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
2473 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
2474 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
2475 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
2476 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
2477 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
2478
2479 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
2480 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
2481 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
2482 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
2483 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
2484
2485 sub pp_eq { binop(@_, "==", 14) }
2486 sub pp_ne { binop(@_, "!=", 14) }
2487 sub pp_lt { binop(@_, "<", 15) }
2488 sub pp_gt { binop(@_, ">", 15) }
2489 sub pp_ge { binop(@_, ">=", 15) }
2490 sub pp_le { binop(@_, "<=", 15) }
2491 sub pp_ncmp { binop(@_, "<=>", 14) }
2492 sub pp_i_eq { binop(@_, "==", 14) }
2493 sub pp_i_ne { binop(@_, "!=", 14) }
2494 sub pp_i_lt { binop(@_, "<", 15) }
2495 sub pp_i_gt { binop(@_, ">", 15) }
2496 sub pp_i_ge { binop(@_, ">=", 15) }
2497 sub pp_i_le { binop(@_, "<=", 15) }
2498 sub pp_i_ncmp { binop(@_, "<=>", 14) }
2499
2500 sub pp_seq { binop(@_, "eq", 14) }
2501 sub pp_sne { binop(@_, "ne", 14) }
2502 sub pp_slt { binop(@_, "lt", 15) }
2503 sub pp_sgt { binop(@_, "gt", 15) }
2504 sub pp_sge { binop(@_, "ge", 15) }
2505 sub pp_sle { binop(@_, "le", 15) }
2506 sub pp_scmp { binop(@_, "cmp", 14) }
2507
2508 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
2509 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
2510
2511 sub pp_smartmatch {
2512     my ($self, $op, $cx) = @_;
2513     if ($op->flags & OPf_SPECIAL) {
2514         return $self->deparse($op->last, $cx);
2515     }
2516     else {
2517         binop(@_, "~~", 14);
2518     }
2519 }
2520
2521 # '.' is special because concats-of-concats are optimized to save copying
2522 # by making all but the first concat stacked. The effect is as if the
2523 # programmer had written '($a . $b) .= $c', except legal.
2524 sub pp_concat { maybe_targmy(@_, \&real_concat) }
2525 sub real_concat {
2526     my $self = shift;
2527     my($op, $cx) = @_;
2528     my $left = $op->first;
2529     my $right = $op->last;
2530     my $eq = "";
2531     my $prec = 18;
2532     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
2533         $eq = "=";
2534         $prec = 7;
2535     }
2536     $left = $self->deparse_binop_left($op, $left, $prec);
2537     $right = $self->deparse_binop_right($op, $right, $prec);
2538     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
2539 }
2540
2541 # 'x' is weird when the left arg is a list
2542 sub pp_repeat {
2543     my $self = shift;
2544     my($op, $cx) = @_;
2545     my $left = $op->first;
2546     my $right = $op->last;
2547     my $eq = "";
2548     my $prec = 19;
2549     if ($op->flags & OPf_STACKED) {
2550         $eq = "=";
2551         $prec = 7;
2552     }
2553     if (null($right)) { # list repeat; count is inside left-side ex-list
2554         my $kid = $left->first->sibling; # skip pushmark
2555         my @exprs;
2556         for (; !null($kid->sibling); $kid = $kid->sibling) {
2557             push @exprs, $self->deparse($kid, 6);
2558         }
2559         $right = $kid;
2560         $left = "(" . join(", ", @exprs). ")";
2561     } else {
2562         $left = $self->deparse_binop_left($op, $left, $prec);
2563     }
2564     $right = $self->deparse_binop_right($op, $right, $prec);
2565     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
2566 }
2567
2568 sub range {
2569     my $self = shift;
2570     my ($op, $cx, $type) = @_;
2571     my $left = $op->first;
2572     my $right = $left->sibling;
2573     $left = $self->deparse($left, 9);
2574     $right = $self->deparse($right, 9);
2575     return $self->maybe_parens("$left $type $right", $cx, 9);
2576 }
2577
2578 sub pp_flop {
2579     my $self = shift;
2580     my($op, $cx) = @_;
2581     my $flip = $op->first;
2582     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
2583     return $self->range($flip->first, $cx, $type);
2584 }
2585
2586 # one-line while/until is handled in pp_leave
2587
2588 sub logop {
2589     my $self = shift;
2590     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
2591     my $left = $op->first;
2592     my $right = $op->first->sibling;
2593     if ($cx < 1 and is_scope($right) and $blockname
2594         and $self->{'expand'} < 7)
2595     { # if ($a) {$b}
2596         $left = $self->deparse($left, 1);
2597         $right = $self->deparse($right, 0);
2598         return "$blockname ($left) {\n\t$right\n\b}\cK";
2599     } elsif ($cx < 1 and $blockname and not $self->{'parens'}
2600              and $self->{'expand'} < 7) { # $b if $a
2601         $right = $self->deparse($right, 1);
2602         $left = $self->deparse($left, 1);
2603         return "$right $blockname $left";
2604     } elsif ($cx > $lowprec and $highop) { # $a && $b
2605         $left = $self->deparse_binop_left($op, $left, $highprec);
2606         $right = $self->deparse_binop_right($op, $right, $highprec);
2607         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
2608     } else { # $a and $b
2609         $left = $self->deparse_binop_left($op, $left, $lowprec);
2610         $right = $self->deparse_binop_right($op, $right, $lowprec);
2611         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec);
2612     }
2613 }
2614
2615 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
2616 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
2617 sub pp_dor { logop(@_, "//", 10) }
2618
2619 # xor is syntactically a logop, but it's really a binop (contrary to
2620 # old versions of opcode.pl). Syntax is what matters here.
2621 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
2622
2623 sub logassignop {
2624     my $self = shift;
2625     my ($op, $cx, $opname) = @_;
2626     my $left = $op->first;
2627     my $right = $op->first->sibling->first; # skip sassign
2628     $left = $self->deparse($left, 7);
2629     $right = $self->deparse($right, 7);
2630     return $self->maybe_parens("$left $opname $right", $cx, 7);
2631 }
2632
2633 sub pp_andassign { logassignop(@_, "&&=") }
2634 sub pp_orassign  { logassignop(@_, "||=") }
2635 sub pp_dorassign { logassignop(@_, "//=") }
2636
2637 sub rv2gv_or_string {
2638     my($self,$op) = @_;
2639     if ($op->name eq "gv") { # could be open("open") or open("###")
2640         my($name,$quoted) =
2641             $self->stash_variable_name("", $self->gv_or_padgv($op));
2642         $quoted ? $name : "*$name";
2643     }
2644     else {
2645         $self->deparse($op, 6);
2646     }
2647 }
2648
2649 sub listop {
2650     my $self = shift;
2651     my($op, $cx, $name, $kid, $nollafr) = @_;
2652     my(@exprs);
2653     my $parens = ($cx >= 5) || $self->{'parens'};
2654     $kid ||= $op->first->sibling;
2655     # If there are no arguments, add final parentheses (or parenthesize the
2656     # whole thing if the llafr does not apply) to account for cases like
2657     # (return)+1 or setpgrp()+1.  When the llafr does not apply, we use a
2658     # precedence of 6 (< comma), as "return, 1" does not need parentheses.
2659     if (null $kid) {
2660         return $nollafr
2661                 ? $self->maybe_parens($self->keyword($name), $cx, 7)
2662                 : $self->keyword($name) . '()' x (7 < $cx);
2663     }
2664     my $first;
2665     $name = "socketpair" if $name eq "sockpair";
2666     my $fullname = $self->keyword($name);
2667     my $proto = prototype("CORE::$name");
2668     if (
2669          (     (defined $proto && $proto =~ /^;?\*/)
2670             || $name eq 'select' # select(F) doesn't have a proto
2671          )
2672          && $kid->name eq "rv2gv"
2673          && !($kid->private & OPpLVAL_INTRO)
2674     ) {
2675         $first = $self->rv2gv_or_string($kid->first);
2676     }
2677     else {
2678         $first = $self->deparse($kid, 6);
2679     }
2680     if ($name eq "chmod" && $first =~ /^\d+$/) {
2681         $first = sprintf("%#o", $first);
2682     }
2683     $first = "+$first"
2684         if not $parens and not $nollafr and substr($first, 0, 1) eq "(";
2685     push @exprs, $first;
2686     $kid = $kid->sibling;
2687     if (defined $proto && $proto =~ /^\*\*/ && $kid->name eq "rv2gv"
2688          && !($kid->private & OPpLVAL_INTRO)) {
2689         push @exprs, $first = $self->rv2gv_or_string($kid->first);
2690         $kid = $kid->sibling;
2691     }
2692     for (; !null($kid); $kid = $kid->sibling) {
2693         push @exprs, $self->deparse($kid, 6);
2694     }
2695     if ($name eq "reverse" && ($op->private & OPpREVERSE_INPLACE)) {
2696         return "$exprs[0] = $fullname"
2697                  . ($parens ? "($exprs[0])" : " $exprs[0]");
2698     }
2699     if ($name =~ /^(system|exec)$/
2700         && ($op->flags & OPf_STACKED)
2701         && @exprs > 1)
2702     {
2703         # handle the "system prog a1,a2,.." form
2704         my $prog = shift @exprs;
2705         $exprs[0] = "$prog $exprs[0]";
2706     }
2707
2708     if ($parens && $nollafr) {
2709         return "($fullname " . join(", ", @exprs) . ")";
2710     } elsif ($parens) {
2711         return "$fullname(" . join(", ", @exprs) . ")";
2712     } else {
2713         return "$fullname " . join(", ", @exprs);
2714     }
2715 }
2716
2717 sub pp_bless { listop(@_, "bless") }
2718 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2719 sub pp_substr {
2720     my ($self,$op,$cx) = @_;
2721     if ($op->private & OPpSUBSTR_REPL_FIRST) {
2722         return
2723            listop($self, $op, 7, "substr", $op->first->sibling->sibling)
2724          . " = "
2725          . $self->deparse($op->first->sibling, 7);
2726     }
2727     maybe_local(@_, listop(@_, "substr"))
2728 }
2729 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2730 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2731 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2732 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2733 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2734 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2735 sub pp_unpack { listop(@_, "unpack") }
2736 sub pp_pack { listop(@_, "pack") }
2737 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2738 sub pp_splice { listop(@_, "splice") }
2739 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2740 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2741 sub pp_reverse { listop(@_, "reverse") }
2742 sub pp_warn { listop(@_, "warn") }
2743 sub pp_die { listop(@_, "die") }
2744 sub pp_return { listop(@_, "return", undef, 1) } # llafr does not apply
2745 sub pp_open { listop(@_, "open") }
2746 sub pp_pipe_op { listop(@_, "pipe") }
2747 sub pp_tie { listop(@_, "tie") }
2748 sub pp_binmode { listop(@_, "binmode") }
2749 sub pp_dbmopen { listop(@_, "dbmopen") }
2750 sub pp_sselect { listop(@_, "select") }
2751 sub pp_select { listop(@_, "select") }
2752 sub pp_read { listop(@_, "read") }
2753 sub pp_sysopen { listop(@_, "sysopen") }
2754 sub pp_sysseek { listop(@_, "sysseek") }
2755 sub pp_sysread { listop(@_, "sysread") }
2756 sub pp_syswrite { listop(@_, "syswrite") }
2757 sub pp_send { listop(@_, "send") }
2758 sub pp_recv { listop(@_, "recv") }
2759 sub pp_seek { listop(@_, "seek") }
2760 sub pp_fcntl { listop(@_, "fcntl") }
2761 sub pp_ioctl { listop(@_, "ioctl") }
2762 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2763 sub pp_socket { listop(@_, "socket") }
2764 sub pp_sockpair { listop(@_, "sockpair") }
2765 sub pp_bind { listop(@_, "bind") }
2766 sub pp_connect { listop(@_, "connect") }
2767 sub pp_listen { listop(@_, "listen") }
2768 sub pp_accept { listop(@_, "accept") }
2769 sub pp_shutdown { listop(@_, "shutdown") }
2770 sub pp_gsockopt { listop(@_, "getsockopt") }
2771 sub pp_ssockopt { listop(@_, "setsockopt") }
2772 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2773 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2774 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2775 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2776 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2777 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2778 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2779 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2780 sub pp_open_dir { listop(@_, "opendir") }
2781 sub pp_seekdir { listop(@_, "seekdir") }
2782 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2783 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2784 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2785 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2786 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2787 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2788 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2789 sub pp_shmget { listop(@_, "shmget") }
2790 sub pp_shmctl { listop(@_, "shmctl") }
2791 sub pp_shmread { listop(@_, "shmread") }
2792 sub pp_shmwrite { listop(@_, "shmwrite") }
2793 sub pp_msgget { listop(@_, "msgget") }
2794 sub pp_msgctl { listop(@_, "msgctl") }
2795 sub pp_msgsnd { listop(@_, "msgsnd") }
2796 sub pp_msgrcv { listop(@_, "msgrcv") }
2797 sub pp_semget { listop(@_, "semget") }
2798 sub pp_semctl { listop(@_, "semctl") }
2799 sub pp_semop { listop(@_, "semop") }
2800 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2801 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2802 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2803 sub pp_gsbyname { listop(@_, "getservbyname") }
2804 sub pp_gsbyport { listop(@_, "getservbyport") }
2805 sub pp_syscall { listop(@_, "syscall") }
2806
2807 sub pp_glob {
2808     my $self = shift;
2809     my($op, $cx) = @_;
2810     my $text = $self->dq($op->first->sibling);  # skip pushmark
2811     my $keyword =
2812         $op->flags & OPf_SPECIAL ? 'glob' : $self->keyword('glob');
2813     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2814         or $keyword =~ /^CORE::/
2815         or $text =~ /[<>]/) {
2816         return "$keyword(" . single_delim('qq', '"', $text) . ')';
2817     } else {
2818         return '<' . $text . '>';
2819     }
2820 }
2821
2822 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2823 # be a filehandle. This could probably be better fixed in the core
2824 # by moving the GV lookup into ck_truc.
2825
2826 sub pp_truncate {
2827     my $self = shift;
2828     my($op, $cx) = @_;
2829     my(@exprs);
2830     my $parens = ($cx >= 5) || $self->{'parens'};
2831     my $kid = $op->first->sibling;
2832     my $fh;
2833     if ($op->flags & OPf_SPECIAL) {
2834         # $kid is an OP_CONST
2835         $fh = $self->const_sv($kid)->PV;
2836     } else {
2837         $fh = $self->deparse($kid, 6);
2838         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2839     }
2840     my $len = $self->deparse($kid->sibling, 6);
2841     my $name = $self->keyword('truncate');
2842     if ($parens) {
2843         return "$name($fh, $len)";
2844     } else {
2845         return "$name $fh, $len";
2846     }
2847 }
2848
2849 sub indirop {
2850     my $self = shift;
2851     my($op, $cx, $name) = @_;
2852     my($expr, @exprs);
2853     my $firstkid = my $kid = $op->first->sibling;
2854     my $indir = "";
2855     if ($op->flags & OPf_STACKED) {
2856         $indir = $kid;
2857         $indir = $indir->first; # skip rv2gv
2858         if (is_scope($indir)) {
2859             $indir = "{" . $self->deparse($indir, 0) . "}";
2860             $indir = "{;}" if $indir eq "{}";
2861         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2862             $indir = $self->const_sv($indir)->PV;
2863         } else {
2864             $indir = $self->deparse($indir, 24);
2865         }
2866         $indir = $indir . " ";
2867         $kid = $kid->sibling;
2868     }
2869     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2870         $indir = ($op->private & OPpSORT_DESCEND) ? '{$b <=> $a} '
2871                                                   : '{$a <=> $b} ';
2872     }
2873     elsif ($name eq "sort" && $op->private & OPpSORT_DESCEND) {
2874         $indir = '{$b cmp $a} ';
2875     }
2876     for (; !null($kid); $kid = $kid->sibling) {
2877         $expr = $self->deparse($kid, !$indir && $kid == $firstkid && $name eq "sort" && $firstkid->name eq "entersub" ? 16 : 6);
2878         push @exprs, $expr;
2879     }
2880     my $name2;
2881     if ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2882         $name2 = $self->keyword('reverse') . ' ' . $self->keyword('sort');
2883     }
2884     else { $name2 = $self->keyword($name) }
2885     if ($name eq "sort" && ($op->private & OPpSORT_INPLACE)) {
2886         return "$exprs[0] = $name2 $indir $exprs[0]";
2887     }
2888
2889     my $args = $indir . join(", ", @exprs);
2890     if ($indir ne "" && $name eq "sort") {
2891         # We don't want to say "sort(f 1, 2, 3)", since perl -w will
2892         # give bareword warnings in that case. Therefore if context
2893         # requires, we'll put parens around the outside "(sort f 1, 2,
2894         # 3)". Unfortunately, we'll currently think the parens are
2895         # necessary more often that they really are, because we don't
2896         # distinguish which side of an assignment we're on.
2897         if ($cx >= 5) {
2898             return "($name2 $args)";
2899         } else {
2900             return "$name2 $args";
2901         }
2902     } elsif (
2903         !$indir && $name eq "sort"
2904       && !null($op->first->sibling)
2905       && $op->first->sibling->name eq 'entersub'
2906     ) {
2907         # We cannot say sort foo(bar), as foo will be interpreted as a
2908         # comparison routine.  We have to say sort(...) in that case.
2909         return "$name2($args)";
2910     } else {
2911         return $self->maybe_parens_func($name2, $args, $cx, 5);
2912     }
2913
2914 }
2915
2916 sub pp_prtf { indirop(@_, "printf") }
2917 sub pp_print { indirop(@_, "print") }
2918 sub pp_say  { indirop(@_, "say") }
2919 sub pp_sort { indirop(@_, "sort") }
2920
2921 sub mapop {
2922     my $self = shift;
2923     my($op, $cx, $name) = @_;
2924     my($expr, @exprs);
2925     my $kid = $op->first; # this is the (map|grep)start
2926     $kid = $kid->first->sibling; # skip a pushmark
2927     my $code = $kid->first; # skip a null
2928     if (is_scope $code) {
2929         $code = "{" . $self->deparse($code, 0) . "} ";
2930     } else {
2931         $code = $self->deparse($code, 24);
2932         $code .= ", " if !null($kid->sibling);
2933     }
2934     $kid = $kid->sibling;
2935     for (; !null($kid); $kid = $kid->sibling) {
2936         $expr = $self->deparse($kid, 6);
2937         push @exprs, $expr if defined $expr;
2938     }
2939     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2940 }
2941
2942 sub pp_mapwhile { mapop(@_, "map") }
2943 sub pp_grepwhile { mapop(@_, "grep") }
2944 sub pp_mapstart { baseop(@_, "map") }
2945 sub pp_grepstart { baseop(@_, "grep") }
2946
2947 sub pp_list {
2948     my $self = shift;
2949     my($op, $cx) = @_;
2950     my($expr, @exprs);
2951     my $kid = $op->first->sibling; # skip pushmark
2952     return '' if class($kid) eq 'NULL';
2953     my $lop;
2954     my $local = "either"; # could be local(...), my(...), state(...) or our(...)
2955     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2956         # This assumes that no other private flags equal 128, and that
2957         # OPs that store things other than flags in their op_private,
2958         # like OP_AELEMFAST, won't be immediate children of a list.
2959         #
2960         # OP_ENTERSUB and OP_SPLIT can break this logic, so check for them.
2961         # I suspect that open and exit can too.
2962         # XXX This really needs to be rewritten to accept only those ops
2963         #     known to take the OPpLVAL_INTRO flag.
2964
2965         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2966                 or $lop->name eq "undef")
2967             or $lop->name =~ /^(?:entersub|exit|open|split)\z/)
2968         {
2969             $local = ""; # or not
2970             last;
2971         }
2972         if ($lop->name =~ /^pad[ash]v$/) {
2973             if ($lop->private & OPpPAD_STATE) { # state()
2974                 ($local = "", last) if $local =~ /^(?:local|our|my)$/;
2975                 $local = "state";
2976             } else { # my()
2977                 ($local = "", last) if $local =~ /^(?:local|our|state)$/;
2978                 $local = "my";
2979             }
2980         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2981                         && $lop->private & OPpOUR_INTRO
2982                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2983                         && $lop->first->private & OPpOUR_INTRO) { # our()
2984             ($local = "", last) if $local =~ /^(?:my|local|state)$/;
2985             $local = "our";
2986         } elsif ($lop->name ne "undef"
2987                 # specifically avoid the "reverse sort" optimisation,
2988                 # where "reverse" is nullified
2989                 && !($lop->name eq 'sort' && ($lop->flags & OPpSORT_REVERSE)))
2990         {
2991             # local()
2992             ($local = "", last) if $local =~ /^(?:my|our|state)$/;
2993             $local = "local";
2994         }
2995     }
2996     $local = "" if $local eq "either"; # no point if it's all undefs
2997     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2998     for (; !null($kid); $kid = $kid->sibling) {
2999         if ($local) {
3000             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
3001                 $lop = $kid->first;
3002             } else {
3003                 $lop = $kid;
3004             }
3005             $self->{'avoid_local'}{$$lop}++;
3006             $expr = $self->deparse($kid, 6);
3007             delete $self->{'avoid_local'}{$$lop};
3008         } else {
3009             $expr = $self->deparse($kid, 6);
3010         }
3011         push @exprs, $expr;
3012     }
3013     if ($local) {
3014         return "$local(" . join(", ", @exprs) . ")";
3015     } else {
3016         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
3017     }
3018 }
3019
3020 sub is_ifelse_cont {
3021     my $op = shift;
3022     return ($op->name eq "null" and class($op) eq "UNOP"
3023             and $op->first->name =~ /^(and|cond_expr)$/
3024             and is_scope($op->first->first->sibling));
3025 }
3026
3027 sub pp_cond_expr {
3028     my $self = shift;
3029     my($op, $cx) = @_;
3030     my $cond = $op->first;
3031     my $true = $cond->sibling;
3032     my $false = $true->sibling;
3033     my $cuddle = $self->{'cuddle'};
3034     unless ($cx < 1 and (is_scope($true) and $true->name ne "null") and
3035             (is_scope($false) || is_ifelse_cont($false))
3036             and $self->{'expand'} < 7) {
3037         $cond = $self->deparse($cond, 8);
3038         $true = $self->deparse($true, 6);
3039         $false = $self->deparse($false, 8);
3040         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
3041     }
3042
3043     $cond = $self->deparse($cond, 1);
3044     $true = $self->deparse($true, 0);
3045     my $head = "if ($cond) {\n\t$true\n\b}";
3046     my @elsifs;
3047     while (!null($false) and is_ifelse_cont($false)) {
3048         my $newop = $false->first;
3049         my $newcond = $newop->first;
3050         my $newtrue = $newcond->sibling;
3051         $false = $newtrue->sibling; # last in chain is OP_AND => no else
3052         if ($newcond->name eq "lineseq")
3053         {
3054             # lineseq to ensure correct line numbers in elsif()
3055             # Bug #37302 fixed by change #33710.
3056             $newcond = $newcond->first->sibling;
3057         }
3058         $newcond = $self->deparse($newcond, 1);
3059         $newtrue = $self->deparse($newtrue, 0);
3060         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
3061     }
3062     if (!null($false)) {
3063         $false = $cuddle . "else {\n\t" .
3064           $self->deparse($false, 0) . "\n\b}\cK";
3065     } else {
3066         $false = "\cK";
3067     }
3068     return $head . join($cuddle, "", @elsifs) . $false;
3069 }
3070
3071 sub pp_once {
3072     my ($self, $op, $cx) = @_;
3073     my $cond = $op->first;
3074     my $true = $cond->sibling;
3075
3076     return $self->deparse($true, $cx);
3077 }
3078
3079 sub loop_common {
3080     my $self = shift;
3081     my($op, $cx, $init) = @_;
3082     my $enter = $op->first;
3083     my $kid = $enter->sibling;
3084     local(@$self{qw'curstash warnings hints hinthash'})
3085                 = @$self{qw'curstash warnings hints hinthash'};
3086     my $head = "";
3087     my $bare = 0;
3088     my $body;
3089     my $cond = undef;
3090     if ($kid->name eq "lineseq") { # bare or infinite loop
3091         if ($kid->last->name eq "unstack") { # infinite
3092             $head = "while (1) "; # Can't use for(;;) if there's a continue
3093             $cond = "";
3094         } else {
3095             $bare = 1;
3096         }
3097         $body = $kid;
3098     } elsif ($enter->name eq "enteriter") { # foreach
3099         my $ary = $enter->first->sibling; # first was pushmark
3100         my $var = $ary->sibling;
3101         if ($ary->name eq 'null' and $enter->private & OPpITER_REVERSED) {
3102             # "reverse" was optimised away
3103             $ary = listop($self, $ary->first->sibling, 1, 'reverse');
3104         } elsif ($enter->flags & OPf_STACKED
3105             and not null $ary->first->sibling->sibling)
3106         {
3107             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
3108               $self->deparse($ary->first->sibling->sibling, 9);
3109         } else {
3110             $ary = $self->deparse($ary, 1);
3111         }
3112         if (null $var) {
3113             if (($enter->flags & OPf_SPECIAL) && ($] < 5.009)) {
3114                 # thread special var, under 5005threads
3115                 $var = $self->pp_threadsv($enter, 1);
3116             } else { # regular my() variable
3117                 $var = $self->pp_padsv($enter, 1, 1);
3118             }
3119         } elsif ($var->name eq "rv2gv") {
3120             $var = $self->pp_rv2sv($var, 1);
3121             if ($enter->private & OPpOUR_INTRO) {
3122                 # our declarations don't have package names
3123                 $var =~ s/^(.).*::/$1/;
3124                 $var = "our $var";
3125             }
3126         } elsif ($var->name eq "gv") {
3127             $var = "\$" . $self->deparse($var, 1);
3128         }
3129         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
3130         if (!is_state $body->first and $body->first->name !~ /^(?:stub|leave|scope)$/) {
3131             confess unless $var eq '$_';
3132             $body = $body->first;
3133             return $self->deparse($body, 2) . " foreach ($ary)";
3134         }
3135         $head = "foreach $var ($ary) ";
3136     } elsif ($kid->name eq "null") { # while/until
3137         $kid = $kid->first;
3138         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
3139         $cond = $self->deparse($kid->first, 1);
3140         $head = "$name ($cond) ";
3141         $body = $kid->first->sibling;
3142     } elsif ($kid->name eq "stub") { # bare and empty
3143         return "{;}"; # {} could be a hashref
3144     }
3145     # If there isn't a continue block, then the next pointer for the loop
3146     # will point to the unstack, which is kid's last child, except
3147     # in a bare loop, when it will point to the leaveloop. When neither of
3148     # these conditions hold, then the second-to-last child is the continue
3149     # block (or the last in a bare loop).
3150     my $cont_start = $enter->nextop;
3151     my $cont;
3152     if ($$cont_start != $$op && ${$cont_start} != ${$body->last}) {
3153         if ($bare) {
3154             $cont = $body->last;
3155         } else {
3156             $cont = $body->first;
3157             while (!null($cont->sibling->sibling)) {
3158                 $cont = $cont->sibling;
3159             }
3160         }
3161         my $state = $body->first;
3162         my $cuddle = $self->{'cuddle'};
3163         my @states;
3164         for (; $$state != $$cont; $state = $state->sibling) {
3165             push @states, $state;
3166         }
3167         $body = $self->lineseq(undef, 0, @states);
3168         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
3169             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
3170             $cont = "\cK";
3171         } else {
3172             $cont = $cuddle . "continue {\n\t" .
3173               $self->deparse($cont, 0) . "\n\b}\cK";
3174         }
3175     } else {
3176         return "" if !defined $body;
3177         if (length $init) {
3178             $head = "for ($init; $cond;) ";
3179         }
3180         $cont = "\cK";
3181         $body = $self->deparse($body, 0);
3182     }
3183     $body =~ s/;?$/;\n/;
3184
3185     return $head . "{\n\t" . $body . "\b}" . $cont;
3186 }
3187
3188 sub pp_leaveloop { shift->loop_common(@_, "") }
3189
3190 sub for_loop {
3191     my $self = shift;
3192     my($op, $cx) = @_;
3193     my $init = $self->deparse($op, 1);
3194     my $s = $op->sibling;
3195     my $ll = $s->name eq "unstack" ? $s->sibling : $s->first->sibling;
3196     return $self->loop_common($ll, $cx, $init);
3197 }
3198
3199 sub pp_leavetry {
3200     my $self = shift;
3201     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
3202 }
3203
3204 BEGIN { for (qw[ const stringify rv2sv list glob ]) {
3205     eval "sub OP_\U$_ () { " . opnumber($_) . "}"
3206 }}
3207
3208 sub pp_null {
3209     my $self = shift;
3210     my($op, $cx) = @_;
3211     if (class($op) eq "OP") {
3212         # old value is lost
3213         return $self->{'ex_const'} if $op->targ == OP_CONST;
3214     } elsif ($op->first->name eq "pushmark") {
3215         return $self->pp_list($op, $cx);
3216     } elsif ($op->first->name eq "enter") {
3217         return $self->pp_leave($op, $cx);
3218     } elsif ($op->first->name eq "leave") {
3219         return $self->pp_leave($op->first, $cx);
3220     } elsif ($op->first->name eq "scope") {
3221         return $self->pp_scope($op->first, $cx);
3222     } elsif ($op->targ == OP_STRINGIFY) {
3223         return $self->dquote($op, $cx);
3224     } elsif ($op->targ == OP_GLOB) {
3225         return $self->pp_glob(
3226                  $op->first    # entersub
3227                     ->first    # ex-list
3228                     ->first    # pushmark
3229                     ->sibling, # glob
3230                  $cx
3231                );
3232     } elsif (!null($op->first->sibling) and
3233              $op->first->sibling->name eq "readline" and
3234              $op->first->sibling->flags & OPf_STACKED) {
3235         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
3236                                    . $self->deparse($op->first->sibling, 7),
3237                                    $cx, 7);
3238     } elsif (!null($op->first->sibling) and
3239              $op->first->sibling->name eq "trans" and
3240              $op->first->sibling->flags & OPf_STACKED) {
3241         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
3242                                    . $self->deparse($op->first->sibling, 20),
3243                                    $cx, 20);
3244     } elsif ($op->flags & OPf_SPECIAL && $cx < 1 && !$op->targ) {
3245         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
3246     } elsif (!null($op->first->sibling) and
3247              $op->first->sibling->name eq "null" and
3248              class($op->first->sibling) eq "UNOP" and
3249              $op->first->sibling->first->flags & OPf_STACKED and
3250              $op->first->sibling->first->name eq "rcatline") {
3251         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
3252                                    . $self->deparse($op->first->sibling, 18),
3253                                    $cx, 18);
3254     } else {
3255         return $self->deparse($op->first, $cx);
3256     }
3257 }
3258
3259 sub padname {
3260     my $self = shift;
3261     my $targ = shift;
3262     return $self->padname_sv($targ)->PVX;
3263 }
3264
3265 sub padany {
3266     my $self = shift;
3267     my $op = shift;
3268     return substr($self->padname($op->targ), 1); # skip $/@/%
3269 }
3270
3271 sub pp_padsv {
3272     my $self = shift;
3273     my($op, $cx, $forbid_parens) = @_;
3274     return $self->maybe_my($op, $cx, $self->padname($op->targ),
3275                            $forbid_parens);
3276 }
3277
3278 sub pp_padav { pp_padsv(@_) }
3279 sub pp_padhv { pp_padsv(@_) }
3280
3281 my @threadsv_names = B::threadsv_names;
3282 sub pp_threadsv {
3283     my $self = shift;
3284     my($op, $cx) = @_;
3285     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
3286 }
3287
3288 sub gv_or_padgv {
3289     my $self = shift;
3290     my $op = shift;
3291     if (class($op) eq "PADOP") {
3292         return $self->padval($op->padix);
3293     } else { # class($op) eq "SVOP"
3294         return $op->gv;
3295     }
3296 }
3297
3298 sub pp_gvsv {
3299     my $self = shift;
3300     my($op, $cx) = @_;
3301     my $gv = $self->gv_or_padgv($op);
3302     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
3303                                  $self->gv_name($gv), $cx));
3304 }
3305
3306 sub pp_gv {
3307     my $self = shift;
3308     my($op, $cx) = @_;
3309     my $gv = $self->gv_or_padgv($op);
3310     return $self->gv_name($gv);
3311 }
3312
3313 sub pp_aelemfast_lex {
3314     my $self = shift;
3315     my($op, $cx) = @_;
3316     my $name = $self->padname($op->targ);
3317     $name =~ s/^@/\$/;
3318     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3319 }
3320
3321 sub pp_aelemfast {
3322     my $self = shift;
3323     my($op, $cx) = @_;
3324     # optimised PADAV, pre 5.15
3325     return $self->pp_aelemfast_lex(@_) if ($op->flags & OPf_SPECIAL);
3326
3327     my $gv = $self->gv_or_padgv($op);
3328     my($name,$quoted) = $self->stash_variable_name('@',$gv);
3329     $name = $quoted ? "$name->" : '$' . $name;
3330     return $name . "[" .  ($op->private + $self->{'arybase'}) . "]";
3331 }
3332
3333 sub rv2x {
3334     my $self = shift;
3335     my($op, $cx, $type) = @_;
3336
3337     if (class($op) eq 'NULL' || !$op->can("first")) {
3338         carp("Unexpected op in pp_rv2x");
3339         return 'XXX';
3340     }
3341     my $kid = $op->first;
3342     if ($kid->name eq "gv") {
3343         return $self->stash_variable($type, $self->deparse($kid, 0), $cx);
3344     } elsif (is_scalar $kid) {
3345         my $str = $self->deparse($kid, 0);
3346         if ($str =~ /^\$([^\w\d])\z/) {
3347             # "$$+" isn't a legal way to write the scalar dereference
3348             # of $+, since the lexer can't tell you aren't trying to
3349             # do something like "$$ + 1" to get one more than your
3350             # PID. Either "${$+}" or "$${+}" are workable
3351             # disambiguations, but if the programmer did the former,
3352             # they'd be in the "else" clause below rather than here.
3353             # It's not clear if this should somehow be unified with
3354             # the code in dq and re_dq that also adds lexer
3355             # disambiguation braces.
3356             $str = '$' . "{$1}"; #'
3357         }
3358         return $type . $str;
3359     } else {
3360         return $type . "{" . $self->deparse($kid, 0) . "}";
3361     }
3362 }
3363
3364 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
3365 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
3366 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
3367
3368 # skip rv2av
3369 sub pp_av2arylen {
3370     my $self = shift;
3371     my($op, $cx) = @_;
3372     if ($op->first->name eq "padav") {
3373         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
3374     } else {
3375         return $self->maybe_local($op, $cx,
3376                                   $self->rv2x($op->first, $cx, '$#'));
3377     }
3378 }
3379
3380 # skip down to the old, ex-rv2cv
3381 sub pp_rv2cv {
3382     my ($self, $op, $cx) = @_;
3383     if (!null($op->first) && $op->first->name eq 'null' &&
3384         $op->first->targ eq OP_LIST)
3385     {
3386         return $self->rv2x($op->first->first->sibling, $cx, "&")
3387     }
3388     else {
3389         return $self->rv2x($op, $cx, "")
3390     }
3391 }
3392
3393 sub list_const {
3394     my $self = shift;
3395     my($cx, @list) = @_;
3396     my @a = map $self->const($_, 6), @list;
3397     if (@a == 0) {
3398         return "()";
3399     } elsif (@a == 1) {
3400         return $a[0];
3401     } elsif ( @a > 2 and !grep(!/^-?\d+$/, @a)) {
3402         # collapse (-1,0,1,2) into (-1..2)
3403         my ($s, $e) = @a[0,-1];
3404         my $i = $s;
3405         return $self->maybe_parens("$s..$e", $cx, 9)
3406           unless grep $i++ != $_, @a;
3407     }
3408     return $self->maybe_parens(join(", ", @a), $cx, 6);
3409 }
3410
3411 sub pp_rv2av {
3412     my $self = shift;
3413     my($op, $cx) = @_;
3414     my $kid = $op->first;
3415     if ($kid->name eq "const") { # constant list
3416         my $av = $self->const_sv($kid);
3417         return $self->list_const($cx, $av->ARRAY);
3418     } else {
3419         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
3420     }
3421  }
3422
3423 sub is_subscriptable {
3424     my $op = shift;
3425     if ($op->name =~ /^[ahg]elem/) {
3426         return 1;
3427     } elsif ($op->name eq "entersub") {
3428         my $kid = $op->first;
3429         return 0 unless null $kid->sibling;
3430         $kid = $kid->first;
3431         $kid = $kid->sibling until null $kid->sibling;
3432         return 0 if is_scope($kid);
3433         $kid = $kid->first;
3434         return 0 if $kid->name eq "gv" || $kid->name eq "padcv";
3435         return 0 if is_scalar($kid);
3436         return is_subscriptable($kid);  
3437     } else {
3438         return 0;
3439     }
3440 }
3441
3442 sub elem_or_slice_array_name
3443 {
3444     my $self = shift;
3445     my ($array, $left, $padname, $allow_arrow) = @_;
3446
3447     if ($array->name eq $padname) {
3448         return $self->padany($array);
3449     } elsif (is_scope($array)) { # ${expr}[0]
3450         return "{" . $self->deparse($array, 0) . "}";
3451     } elsif ($array->name eq "gv") {
3452         ($array, my $quoted) =
3453             $self->stash_variable_name(
3454                 $left eq '[' ? '@' : '%', $self->gv_or_padgv($array)
3455             );
3456         if (!$allow_arrow && $quoted) {
3457             # This cannot happen.
3458             die "Invalid variable name $array for slice";
3459         }
3460         return $quoted ? "$array->" : $array;
3461     } elsif (!$allow_arrow || is_scalar $array) { # $x[0], $$x[0], ...
3462         return $self->deparse($array, 24);
3463     } else {
3464         return undef;
3465     }
3466 }
3467
3468 sub elem_or_slice_single_index
3469 {
3470     my $self = shift;
3471     my ($idx) = @_;
3472
3473     $idx = $self->deparse($idx, 1);
3474
3475     # Outer parens in an array index will confuse perl
3476     # if we're interpolating in a regular expression, i.e.
3477     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
3478     #
3479     # If $self->{parens}, then an initial '(' will
3480     # definitely be paired with a final ')'. If
3481     # !$self->{parens}, the misleading parens won't
3482     # have been added in the first place.
3483     #
3484     # [You might think that we could get "(...)...(...)"
3485     # where the initial and final parens do not match
3486     # each other. But we can't, because the above would
3487     # only happen if there's an infix binop between the
3488     # two pairs of parens, and *that* means that the whole
3489     # expression would be parenthesized as well.]
3490     #
3491     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
3492
3493     # Hash-element braces will autoquote a bareword inside themselves.
3494     # We need to make sure that C<$hash{warn()}> doesn't come out as
3495     # C<$hash{warn}>, which has a quite different meaning. Currently
3496     # B::Deparse will always quote strings, even if the string was a
3497     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
3498     # for constant strings.) So we can cheat slightly here - if we see
3499     # a bareword, we know that it is supposed to be a function call.
3500     #
3501     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
3502
3503     return $idx;
3504 }
3505
3506 sub elem {
3507     my $self = shift;
3508     my ($op, $cx, $left, $right, $padname) = @_;
3509     my($array, $idx) = ($op->first, $op->first->sibling);
3510
3511     $idx = $self->elem_or_slice_single_index($idx);
3512
3513     unless ($array->name eq $padname) { # Maybe this has been fixed     
3514         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
3515     }
3516     if (my $array_name=$self->elem_or_slice_array_name
3517             ($array, $left, $padname, 1)) {
3518         return ($array_name =~ /->\z/
3519                     ? $array_name
3520                     : $array_name eq '#' ? '${#}' : "\$" . $array_name)
3521               . $left . $idx . $right;
3522     } else {
3523         # $x[20][3]{hi} or expr->[20]
3524         my $arrow = is_subscriptable($array) ? "" : "->";
3525         return $self->deparse($array, 24) . $arrow . $left . $idx . $right;
3526     }
3527
3528 }
3529
3530 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
3531 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
3532
3533 sub pp_gelem {
3534     my $self = shift;
3535     my($op, $cx) = @_;
3536     my($glob, $part) = ($op->first, $op->last);
3537     $glob = $glob->first; # skip rv2gv
3538     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
3539     my $scope = is_scope($glob);
3540     $glob = $self->deparse($glob, 0);
3541     $part = $self->deparse($part, 1);
3542     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
3543 }
3544
3545 sub slice {
3546     my $self = shift;
3547     my ($op, $cx, $left, $right, $regname, $padname) = @_;
3548     my $last;
3549     my(@elems, $kid, $array, $list);
3550     if (class($op) eq "LISTOP") {
3551         $last = $op->last;
3552     } else { # ex-hslice inside delete()
3553         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
3554         $last = $kid;
3555     }
3556     $array = $last;
3557     $array = $array->first
3558         if $array->name eq $regname or $array->name eq "null";
3559     $array = $self->elem_or_slice_array_name($array,$left,$padname,0);
3560     $kid = $op->first->sibling; # skip pushmark
3561     if ($kid->name eq "list") {
3562         $kid = $kid->first->sibling; # skip list, pushmark
3563         for (; !null $kid; $kid = $kid->sibling) {
3564             push @elems, $self->deparse($kid, 6);
3565         }
3566         $list = join(", ", @elems);
3567     } else {
3568         $list = $self->elem_or_slice_single_index($kid);
3569     }
3570     my $lead = '@';
3571     $lead = '%' if $op->name =~ /^kv/i;
3572     return $lead . $array . $left . $list . $right;
3573 }
3574
3575 sub pp_aslice   { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
3576 sub pp_kvaslice {                 slice(@_, "[", "]", "rv2av", "padav")  }
3577 sub pp_hslice   { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
3578 sub pp_kvhslice {                 slice(@_, "{", "}", "rv2hv", "padhv")  }
3579
3580 sub pp_lslice {
3581     my $self = shift;
3582     my($op, $cx) = @_;
3583     my $idx = $op->first;
3584     my $list = $op->last;
3585     my(@elems, $kid);
3586     $list = $self->deparse($list, 1);
3587     $idx = $self->deparse($idx, 1);
3588     return "($list)" . "[$idx]";
3589 }
3590
3591 sub want_scalar {
3592     my $op = shift;
3593     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
3594 }
3595
3596 sub want_list {
3597     my $op = shift;
3598     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
3599 }
3600
3601 sub _method {
3602     my $self = shift;
3603     my($op, $cx) = @_;
3604     my $kid = $op->first->sibling; # skip pushmark
3605     my($meth, $obj, @exprs);
3606     if ($kid->name eq "list" and want_list $kid) {
3607         # When an indirect object isn't a bareword but the args are in
3608         # parens, the parens aren't part of the method syntax (the LLAFR
3609         # doesn't apply), but they make a list with OPf_PARENS set that
3610         # doesn't get flattened by the append_elem that adds the method,
3611         # making a (object, arg1, arg2, ...) list where the object
3612         # usually is. This can be distinguished from
3613         # '($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
3614         # object) because in the later the list is in scalar context
3615         # as the left side of -> always is, while in the former
3616         # the list is in list context as method arguments always are.
3617         # (Good thing there aren't method prototypes!)
3618         $meth = $kid->sibling;
3619         $kid = $kid->first->sibling; # skip pushmark
3620         $obj = $kid;
3621         $kid = $kid->sibling;
3622         for (; not null $kid; $kid = $kid->sibling) {
3623             push @exprs, $kid;
3624         }
3625     } else {
3626         $obj = $kid;
3627         $kid = $kid->sibling;
3628         for (; !null ($kid->sibling) && $kid->name!~/^method(?:_named)?\z/;
3629               $kid = $kid->sibling) {
3630             push @exprs, $kid
3631         }
3632         $meth = $kid;
3633     }
3634
3635     if ($meth->name eq "method_named") {
3636         $meth = $self->const_sv($meth)->PV;
3637     } else {
3638         $meth = $meth->first;
3639         if ($meth->name eq "const") {
3640             # As of 5.005_58, this case is probably obsoleted by the
3641             # method_named case above
3642             $meth = $self->const_sv($meth)->PV; # needs to be bare
3643         }
3644     }
3645
3646     return { method => $meth, variable_method => ref($meth),
3647              object => $obj, args => \@exprs  },
3648            $cx;
3649 }
3650
3651 # compat function only
3652 sub method {
3653     my $self = shift;
3654     my $info = $self->_method(@_);
3655     return $self->e_method( $self->_method(@_) );
3656 }
3657
3658 sub e_method {
3659     my ($self, $info, $cx) = @_;
3660     my $obj = $self->deparse($info->{object}, 24);
3661
3662     my $meth = $info->{method};
3663     $meth = $self->deparse($meth, 1) if $info->{variable_method};
3664     my $args = join(", ", map { $self->deparse($_, 6) } @{$info->{args}} );
3665     if ($info->{object}->name eq 'scope' && want_list $info->{object}) {
3666         # method { $object }
3667         # This must be deparsed this way to preserve list context
3668         # of $object.
3669         my $need_paren = $cx >= 6;
3670         return '(' x $need_paren
3671              . $meth . substr($obj,2) # chop off the "do"
3672              . " $args"
3673              . ')' x $need_paren;
3674     }
3675     my $kid = $obj . "->" . $meth;
3676     if (length $args) {
3677         return $kid . "(" . $args . ")"; # parens mandatory
3678     } else {
3679         return $kid;
3680     }
3681 }
3682
3683 # returns "&" if the prototype doesn't match the args,
3684 # or ("", $args_after_prototype_demunging) if it does.
3685 sub check_proto {
3686     my $self = shift;
3687     return "&" if $self->{'noproto'};
3688     my($proto, @args) = @_;
3689     my($arg, $real);
3690     my $doneok = 0;
3691     my @reals;
3692     # An unbackslashed @ or % gobbles up the rest of the args
3693     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
3694     while ($proto) {
3695         $proto =~ s/^(\\?[\$\@&%*_]|\\\[[\$\@&%*]+\]|;)//;
3696         my $chr = $1;
3697         if ($chr eq "") {
3698             return "&" if @args;
3699         } elsif ($chr eq ";") {
3700             $doneok = 1;
3701         } elsif ($chr eq "@" or $chr eq "%") {
3702             push @reals, map($self->deparse($_, 6), @args);
3703             @args = ();
3704         } else {
3705             $arg = shift @args;
3706             last unless $arg;
3707             if ($chr eq "\$" || $chr eq "_") {
3708                 if (want_scalar $arg) {
3709                     push @reals, $self->deparse($arg, 6);
3710                 } else {
3711                     return "&";
3712                 }
3713             } elsif ($chr eq "&") {
3714                 if ($arg->name =~ /^(s?refgen|undef)$/) {
3715                     push @reals, $self->deparse($arg, 6);
3716                 } else {
3717                     return "&";
3718                 }
3719             } elsif ($chr eq "*") {
3720                 if ($arg->name =~ /^s?refgen$/
3721                     and $arg->first->first->name eq "rv2gv")
3722                   {
3723                       $real = $arg->first->first; # skip refgen, null
3724                       if ($real->first->name eq "gv") {
3725                           push @reals, $self->deparse($real, 6);
3726                       } else {
3727                           push @reals, $self->deparse($real->first, 6);
3728                       }
3729                   } else {
3730                       return "&";
3731                   }
3732             } elsif (substr($chr, 0, 1) eq "\\") {
3733                 $chr =~ tr/\\[]//d;
3734                 if ($arg->name =~ /^s?refgen$/ and
3735                     !null($real = $arg->first) and
3736                     ($chr =~ /\$/ && is_scalar($real->first)
3737                      or ($chr =~ /@/
3738                          && class($real->first->sibling) ne 'NULL'
3739                          && $real->first->sibling->name
3740                          =~ /^(rv2|pad)av$/)
3741                      or ($chr =~ /%/
3742                          && class($real->first->sibling) ne 'NULL'
3743                          && $real->first->sibling->name
3744                          =~ /^(rv2|pad)hv$/)
3745                      #or ($chr =~ /&/ # This doesn't work
3746                      #   && $real->first->name eq "rv2cv")
3747                      or ($chr =~ /\*/
3748                          && $real->first->name eq "rv2gv")))
3749                   {
3750                       push @reals, $self->deparse($real, 6);
3751                   } else {
3752                       return "&";
3753                   }
3754             }
3755        }
3756     }
3757     return "&" if $proto and !$doneok; # too few args and no ';'
3758     return "&" if @args;               # too many args
3759     return ("", join ", ", @reals);
3760 }
3761
3762 sub pp_entersub {
3763     my $self = shift;
3764     my($op, $cx) = @_;
3765     return $self->e_method($self->_method($op, $cx))
3766         unless null $op->first->sibling;
3767     my $prefix = "";
3768     my $amper = "";
3769     my($kid, @exprs);
3770     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
3771         $prefix = "do ";
3772     } elsif ($op->private & OPpENTERSUB_AMPER) {
3773         $amper = "&";
3774     }
3775     $kid = $op->first;
3776     $kid = $kid->first->sibling; # skip ex-list, pushmark
3777     for (; not null $kid->sibling; $kid = $kid->sibling) {
3778         push @exprs, $kid;
3779     }
3780     my $simple = 0;
3781     my $proto = undef;
3782     if (is_scope($kid)) {
3783         $amper = "&";
3784         $kid = "{" . $self->deparse($kid, 0) . "}";
3785     } elsif ($kid->first->name eq "gv") {
3786         my $gv = $self->gv_or_padgv($kid->first);
3787         if (class($gv->CV) ne "SPECIAL") {
3788             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
3789         }
3790         $simple = 1; # only calls of named functions can be prototyped
3791         $kid = $self->deparse($kid, 24);
3792         if (!$amper) {
3793             if ($kid eq 'main::') {
3794                 $kid = '::';
3795             } elsif ($kid !~ /^(?:\w|::)(?:[\w\d]|::(?!\z))*\z/) {
3796                 $kid = single_delim("q", "'", $kid) . '->';
3797             }
3798         }
3799     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
3800         $amper = "&";
3801         $kid = $self->deparse($kid, 24);
3802     } else {
3803         $prefix = "";
3804         my $arrow = is_subscriptable($kid->first) || $kid->first->name eq "padcv" ? "" : "->";
3805         $kid = $self->deparse($kid, 24) . $arrow;
3806     }
3807
3808     # Doesn't matter how many prototypes there are, if
3809     # they haven't happened yet!
3810     my $declared;
3811     {
3812         no strict 'refs';
3813         no warnings 'uninitialized';
3814         $declared = exists $self->{'subs_declared'}{$kid}
3815             || (
3816                  defined &{ ${$self->{'curstash'}."::"}{$kid} }
3817                  && !exists
3818                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
3819                  && defined prototype $self->{'curstash'}."::".$kid
3820                );
3821         if (!$declared && defined($proto)) {
3822             # Avoid "too early to check prototype" warning
3823             ($amper, $proto) = ('&');
3824         }
3825     }
3826
3827     my $args;
3828     if ($declared and defined $proto and not $amper) {
3829         ($amper, $args) = $self->check_proto($proto, @exprs);
3830         if ($amper eq "&") {
3831             $args = join(", ", map($self->deparse($_, 6), @exprs));
3832         }
3833     } else {
3834         $args = join(", ", map($self->deparse($_, 6), @exprs));
3835     }
3836     if ($prefix or $amper) {
3837         if ($kid eq '&') { $kid = "{$kid}" } # &{&} cannot be written as &&
3838         if ($op->flags & OPf_STACKED) {
3839             return $prefix . $amper . $kid . "(" . $args . ")";
3840         } else {
3841             return $prefix . $amper. $kid;
3842         }
3843     } else {
3844         # It's a syntax error to call CORE::GLOBAL::foo with a prefix,
3845         # so it must have been translated from a keyword call. Translate
3846         # it back.
3847         $kid =~ s/^CORE::GLOBAL:://;
3848
3849         my $dproto = defined($proto) ? $proto : "undefined";
3850         if (!$declared) {
3851             return "$kid(" . $args . ")";
3852         } elsif ($dproto eq "") {
3853             return $kid;
3854         } elsif ($dproto eq "\$" and is_scalar($exprs[0])) {
3855             # is_scalar is an excessively conservative test here:
3856             # really, we should be comparing to the precedence of the
3857             # top operator of $exprs[0] (ala unop()), but that would
3858             # take some major code restructuring to do right.
3859             return $self->maybe_parens_func($kid, $args, $cx, 16);
3860         } elsif ($dproto ne '$' and defined($proto) || $simple) { #'
3861             return $self->maybe_parens_func($kid, $args, $cx, 5);
3862         } else {
3863             return "$kid(" . $args . ")";
3864         }
3865     }
3866 }
3867
3868 sub pp_enterwrite { unop(@_, "write") }
3869
3870 # escape things that cause interpolation in double quotes,
3871 # but not character escapes
3872 sub uninterp {
3873     my($str) = @_;
3874     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
3875     return $str;
3876 }
3877
3878 {
3879 my $bal;
3880 BEGIN {
3881     use re "eval";
3882     # Matches any string which is balanced with respect to {braces}
3883     $bal = qr(
3884       (?:
3885         [^\\{}]
3886       | \\\\
3887       | \\[{}]
3888       | \{(??{$bal})\}
3889       )*
3890     )x;
3891 }
3892
3893 # the same, but treat $|, $), $( and $ at the end of the string differently
3894 sub re_uninterp {
3895     my($str) = @_;
3896
3897     $str =~ s/
3898           ( ^|\G                  # $1
3899           | [^\\]
3900           )
3901
3902           (                       # $2
3903             (?:\\\\)*
3904           )
3905
3906           (                       # $3
3907             (\(\?\??\{$bal\}\))   # $4
3908           | [\$\@]
3909             (?!\||\)|\(|$)
3910           | \\[uUlLQE]
3911           )
3912
3913         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3914
3915     return $str;
3916 }
3917
3918 # This is for regular expressions with the /x modifier
3919 # We have to leave comments unmangled.
3920 sub re_uninterp_extended {
3921     my($str) = @_;
3922
3923     $str =~ s/
3924           ( ^|\G                  # $1
3925           | [^\\]
3926           )
3927
3928           (                       # $2
3929             (?:\\\\)*
3930           )
3931
3932           (                       # $3
3933             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3934             | \#[^\n]*            #     (skip over comments)
3935             )
3936           | [\$\@]
3937             (?!\||\)|\(|$|\s)
3938           | \\[uUlLQE]
3939           )
3940
3941         /defined($4) && length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3942
3943     return $str;
3944 }
3945 }
3946
3947 my %unctrl = # portable to EBCDIC
3948     (
3949      "\c@" => '\c@',    # unused
3950      "\cA" => '\cA',
3951      "\cB" => '\cB',
3952      "\cC" => '\cC',
3953      "\cD" => '\cD',
3954      "\cE" => '\cE',
3955      "\cF" => '\cF',
3956      "\cG" => '\cG',
3957      "\cH" => '\cH',
3958      "\cI" => '\cI',
3959      "\cJ" => '\cJ',
3960      "\cK" => '\cK',
3961      "\cL" => '\cL',
3962      "\cM" => '\cM',
3963      "\cN" => '\cN',
3964      "\cO" => '\cO',
3965      "\cP" => '\cP',
3966      "\cQ" => '\cQ',
3967      "\cR" => '\cR',
3968      "\cS" => '\cS',
3969      "\cT" => '\cT',
3970      "\cU" => '\cU',
3971      "\cV" => '\cV',
3972      "\cW" => '\cW',
3973      "\cX" => '\cX',
3974      "\cY" => '\cY',
3975      "\cZ" => '\cZ',
3976      "\c[" => '\c[',    # unused
3977      "\c\\" => '\c\\',  # unused
3978      "\c]" => '\c]',    # unused
3979      "\c_" => '\c_',    # unused
3980     );
3981
3982 # character escapes, but not delimiters that might need to be escaped
3983 sub escape_str { # ASCII, UTF8
3984     my($str) = @_;
3985     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3986     $str =~ s/\a/\\a/g;
3987 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex
3988     $str =~ s/\t/\\t/g;
3989     $str =~ s/\n/\\n/g;
3990     $str =~ s/\e/\\e/g;
3991     $str =~ s/\f/\\f/g;
3992     $str =~ s/\r/\\r/g;
3993     $str =~ s/([\cA-\cZ])/$unctrl{$1}/ge;
3994     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3995     return $str;
3996 }
3997
3998 # For regexes with the /x modifier.
3999 # Leave whitespace unmangled.
4000 sub escape_extended_re {
4001     my($str) = @_;
4002     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
4003     $str =~ s/([[:^print:]])/
4004         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
4005     $str =~ s/\n/\n\f/g;
4006     return $str;
4007 }
4008
4009 # Don't do this for regexen
4010 sub unback {
4011     my($str) = @_;
4012     $str =~ s/\\/\\\\/g;
4013     return $str;
4014 }
4015
4016 # Remove backslashes which precede literal control characters,
4017 # to avoid creating ambiguity when we escape the latter.
4018 sub re_unback {
4019     my($str) = @_;
4020
4021     # the insane complexity here is due to the behaviour of "\c\"
4022     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
4023     return $str;
4024 }
4025
4026 sub balanced_delim {
4027     my($str) = @_;
4028     my @str = split //, $str;
4029     my($ar, $open, $close, $fail, $c, $cnt, $last_bs);
4030     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
4031         ($open, $close) = @$ar;
4032         $fail = 0; $cnt = 0; $last_bs = 0;
4033         for $c (@str) {
4034             if ($c eq $open) {
4035                 $fail = 1 if $last_bs;
4036                 $cnt++;
4037             } elsif ($c eq $close) {
4038                 $fail = 1 if $last_bs;
4039                 $cnt--;
4040                 if ($cnt < 0) {
4041                     # qq()() isn't ")("
4042                     $fail = 1;
4043                     last;
4044                 }
4045             }
4046             $last_bs = $c eq '\\';
4047         }
4048         $fail = 1 if $cnt != 0;
4049         return ($open, "$open$str$close") if not $fail;
4050     }
4051     return ("", $str);
4052 }
4053
4054 sub single_delim {
4055     my($q, $default, $str) = @_;
4056     return "$default$str$default" if $default and index($str, $default) == -1;
4057     if ($q ne 'qr') {
4058         (my $succeed, $str) = balanced_delim($str);
4059         return "$q$str" if $succeed;
4060     }
4061     for my $delim ('/', '"', '#') {
4062         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
4063     }
4064     if ($default) {
4065         $str =~ s/$default/\\$default/g;
4066         return "$default$str$default";
4067     } else {
4068         $str =~ s[/][\\/]g;
4069         return "$q/$str/";
4070     }
4071 }
4072
4073 my $max_prec;
4074 BEGIN { $max_prec = int(0.999 + 8*length(pack("F", 42))*log(2)/log(10)); }
4075
4076 # Split a floating point number into an integer mantissa and a binary
4077 # exponent. Assumes you've already made sure the number isn't zero or
4078 # some weird infinity or NaN.
4079 sub split_float {
4080     my($f) = @_;
4081     my $exponent = 0;
4082     if ($f == int($f)) {
4083         while ($f % 2 == 0) {
4084             $f /= 2;
4085             $exponent++;
4086         }
4087     } else {
4088         while ($f != int($f)) {
4089             $f *= 2;
4090             $exponent--;
4091         }
4092     }
4093     my $mantissa = sprintf("%.0f", $f);
4094     return ($mantissa, $exponent);
4095 }
4096
4097 sub const {
4098     my $self = shift;
4099     my($sv, $cx) = @_;
4100     if ($self->{'use_dumper'}) {
4101         return $self->const_dumper($sv, $cx);
4102     }
4103     if (class($sv) eq "SPECIAL") {
4104         # sv_undef, sv_yes, sv_no
4105         return ('undef', '1', $self->maybe_parens("!1", $cx, 21))[$$sv-1];
4106     }
4107     if (class($sv) eq "NULL") {
4108        return 'undef';
4109     }
4110     # convert a version object into the "v1.2.3" string in its V magic
4111     if ($sv->FLAGS & SVs_RMG) {
4112         for (my $mg = $sv->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4113             return $mg->PTR if $mg->TYPE eq 'V';
4114         }
4115     }
4116
4117     if ($sv->FLAGS & SVf_IOK) {
4118         my $str = $sv->int_value;
4119         $str = $self->maybe_parens($str, $cx, 21) if $str < 0;
4120         return $str;
4121     } elsif ($sv->FLAGS & SVf_NOK) {
4122         my $nv = $sv->NV;
4123         if ($nv == 0) {
4124             if (pack("F", $nv) eq pack("F", 0)) {
4125                 # positive zero
4126                 return "0";
4127             } else {
4128                 # negative zero
4129                 return $self->maybe_parens("-.0", $cx, 21);
4130             }
4131         } elsif (1/$nv == 0) {
4132             if ($nv > 0) {
4133                 # positive infinity
4134                 return $self->maybe_parens("9**9**9", $cx, 22);
4135             } else {
4136                 # negative infinity
4137                 return $self->maybe_parens("-9**9**9", $cx, 21);
4138             }
4139         } elsif ($nv != $nv) {
4140             # NaN
4141             if (pack("F", $nv) eq pack("F", sin(9**9**9))) {
4142                 # the normal kind
4143                 return "sin(9**9**9)";
4144             } elsif (pack("F", $nv) eq pack("F", -sin(9**9**9))) {
4145                 # the inverted kind
4146                 return $self->maybe_parens("-sin(9**9**9)", $cx, 21);
4147             } else {
4148                 # some other kind
4149                 my $hex = unpack("h*", pack("F", $nv));
4150                 return qq'unpack("F", pack("h*", "$hex"))';
4151             }
4152         }
4153         # first, try the default stringification
4154         my $str = "$nv";
4155         if ($str != $nv) {
4156             # failing that, try using more precision
4157             $str = sprintf("%.${max_prec}g", $nv);
4158 #           if (pack("F", $str) ne pack("F", $nv)) {
4159             if ($str != $nv) {
4160                 # not representable in decimal with whatever sprintf()
4161                 # and atof() Perl is using here.
4162                 my($mant, $exp) = split_float($nv);
4163                 return $self->maybe_parens("$mant * 2**$exp", $cx, 19);
4164             }
4165         }
4166         $str = $self->maybe_parens($str, $cx, 21) if $nv < 0;
4167         return $str;
4168     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
4169         my $ref = $sv->RV;
4170         if (class($ref) eq "AV") {
4171             return "[" . $self->list_const(2, $ref->ARRAY) . "]";
4172         } elsif (class($ref) eq "HV") {
4173             my %hash = $ref->ARRAY;
4174             my @elts;
4175             for my $k (sort keys %hash) {
4176                 push @elts, "$k => " . $self->const($hash{$k}, 6);
4177             }
4178             return "{" . join(", ", @elts) . "}";
4179         } elsif (class($ref) eq "CV") {
4180             BEGIN {
4181                 if ($] > 5.0150051) {
4182                     require overloading;
4183                     unimport overloading;
4184                 }
4185             }
4186             if ($] > 5.0150051 && $self->{curcv} &&
4187                  $self->{curcv}->object_2svref == $ref->object_2svref) {
4188                 return $self->keyword("__SUB__");
4189             }
4190             return "sub " . $self->deparse_sub($ref);
4191         }
4192         if ($ref->FLAGS & SVs_SMG) {
4193             for (my $mg = $ref->MAGIC; $mg; $mg = $mg->MOREMAGIC) {
4194                 if ($mg->TYPE eq 'r') {
4195                     my $re = re_uninterp(escape_str(re_unback($mg->precomp)));
4196                     return single_delim("qr", "", $re);
4197                 }
4198             }
4199         }
4200         
4201         return $self->maybe_parens("\\" . $self->const($ref, 20), $cx, 20);
4202     } elsif ($sv->FLAGS & SVf_POK) {
4203         my $str = $sv->PV;
4204         if ($str =~ /[[:^print:]]/) {
4205             return single_delim("qq", '"', uninterp escape_str unback $str);
4206         } else {
4207             return single_delim("q", "'", unback $str);
4208         }
4209     } else {
4210         return "undef";
4211     }
4212 }
4213
4214 sub const_dumper {
4215     my $self = shift;
4216     my($sv, $cx) = @_;
4217     my $ref = $sv->object_2svref();
4218     my $dumper = Data::Dumper->new([$$ref], ['$v']);
4219     $dumper->Purity(1)->Terse(1)->Deparse(1)->Indent(0)->Useqq(1)->Sortkeys(1);
4220     my $str = $dumper->Dump();
4221     if ($str =~ /^\$v/) {
4222         return '${my ' . $str . ' \$v}';
4223     } else {
4224         return $str;
4225     }
4226 }
4227
4228 sub const_sv {
4229     my $self = shift;
4230     my $op = shift;
4231     my $sv = $op->sv;
4232     # the constant could be in the pad (under useithreads)
4233     $sv = $self->padval($op->targ) unless $$sv;
4234     return $sv;
4235 }
4236
4237 sub pp_const {
4238     my $self = shift;
4239     my($op, $cx) = @_;
4240     if ($op->private & OPpCONST_ARYBASE) {
4241         return '$[';
4242     }
4243 #    if ($op->private & OPpCONST_BARE) { # trouble with '=>' autoquoting
4244 #       return $self->const_sv($op)->PV;
4245 #    }
4246     my $sv = $self->const_sv($op);
4247     return $self->const($sv, $cx);
4248 }
4249
4250 sub dq {
4251     my $self = shift;
4252     my $op = shift;
4253     my $type = $op->name;
4254     if ($type eq "const") {
4255         return '$[' if $op->private & OPpCONST_ARYBASE;
4256         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
4257     } elsif ($type eq "concat") {
4258         my $first = $self->dq($op->first);
4259         my $last  = $self->dq($op->last);
4260
4261         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]", "$foo\::bar"
4262         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
4263             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
4264             || ($last =~ /^[:'{\[\w_]/ && #'
4265                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
4266
4267         return $first . $last;
4268     } elsif ($type eq "uc") {
4269         return '\U' . $self->dq($op->first->sibling) . '\E';
4270     } elsif ($type eq "lc") {
4271         return '\L' . $self->dq($op->first->sibling) . '\E';
4272     } elsif ($type eq "ucfirst") {
4273         return '\u' . $self->dq($op->first->sibling);
4274     } elsif ($type eq "lcfirst") {
4275         return '\l' . $self->dq($op->first->sibling);
4276     } elsif ($type eq "quotemeta") {
4277         return '\Q' . $self->dq($op->first->sibling) . '\E';
4278     } elsif ($type eq "fc") {
4279         return '\F' . $self->dq($op->first->sibling) . '\E';
4280     } elsif ($type eq "join") {
4281         return $self->deparse($op->last, 26); # was join($", @ary)
4282     } else {
4283         return $self->deparse($op, 26);
4284     }
4285 }
4286
4287 sub pp_backtick {
4288     my $self = shift;
4289     my($op, $cx) = @_;
4290     # skip pushmark if it exists (readpipe() vs ``)
4291     my $child = $op->first->sibling->isa('B::NULL')
4292         ? $op->first : $op->first->sibling;
4293     if ($self->pure_string($child)) {
4294         return single_delim("qx", '`', $self->dq($child, 1));
4295     }
4296     unop($self, @_, "readpipe");
4297 }
4298
4299 sub dquote {
4300     my $self = shift;
4301     my($op, $cx) = @_;
4302     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
4303     return $self->deparse($kid, $cx) if $self->{'unquote'};
4304     $self->maybe_targmy($kid, $cx,
4305                         sub {single_delim("qq", '"', $self->dq($_[1]))});
4306 }
4307
4308 # OP_STRINGIFY is a listop, but it only ever has one arg
4309 sub pp_stringify { maybe_targmy(@_, \&dquote) }
4310
4311 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
4312 # note that tr(from)/to/ is OK, but not tr/from/(to)
4313 sub double_delim {
4314     my($from, $to) = @_;
4315     my($succeed, $delim);
4316     if ($from !~ m[/] and $to !~ m[/]) {
4317         return "/$from/$to/";
4318     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
4319         if (($succeed, $to) = balanced_delim($to) and $succeed) {
4320             return "$from$to";
4321         } else {
4322             for $delim ('/', '"', '#') { # note no "'" -- s''' is special
4323                 return "$from$delim$to$delim" if index($to, $delim) == -1;
4324             }
4325             $to =~ s[/][\\/]g;
4326             return "$from/$to/";
4327         }
4328     } else {
4329         for $delim ('/', '"', '#') { # note no '
4330             return "$delim$from$delim$to$delim"
4331                 if index($to . $from, $delim) == -1;
4332         }
4333         $from =~ s[/][\\/]g;
4334         $to =~ s[/][\\/]g;
4335         return "/$from/$to/";   
4336     }
4337 }
4338
4339 # Only used by tr///, so backslashes hyphens
4340 sub pchr { # ASCII
4341     my($n) = @_;
4342     if ($n == ord '\\') {
4343         return '\\\\';
4344     } elsif ($n == ord "-") {
4345         return "\\-";
4346     } elsif ($n >= ord(' ') and $n <= ord('~')) {
4347         return chr($n);
4348     } elsif ($n == ord "\a") {
4349         return '\\a';
4350     } elsif ($n == ord "\b") {
4351         return '\\b';
4352     } elsif ($n == ord "\t") {
4353         return '\\t';
4354     } elsif ($n == ord "\n") {
4355         return '\\n';
4356     } elsif ($n == ord "\e") {
4357         return '\\e';
4358     } elsif ($n == ord "\f") {
4359         return '\\f';
4360     } elsif ($n == ord "\r") {
4361         return '\\r';
4362     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
4363         return '\\c' . chr(ord("@") + $n);
4364     } else {
4365 #       return '\x' . sprintf("%02x", $n);
4366         return '\\' . sprintf("%03o", $n);
4367     }
4368 }
4369
4370 sub collapse {
4371     my(@chars) = @_;
4372     my($str, $c, $tr) = ("");
4373     for ($c = 0; $c < @chars; $c++) {
4374         $tr = $chars[$c];
4375         $str .= pchr($tr);
4376         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
4377             $chars[$c + 2] == $tr + 2)
4378         {
4379             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
4380               {}
4381             $str .= "-";
4382             $str .= pchr($chars[$c]);
4383         }
4384     }
4385     return $str;
4386 }
4387
4388 sub tr_decode_byte {
4389     my($table, $flags) = @_;
4390     my(@table) = unpack("s*", $table);
4391     splice @table, 0x100, 1;   # Number of subsequent elements
4392     my($c, $tr, @from, @to, @delfrom, $delhyphen);
4393     if ($table[ord "-"] != -1 and
4394         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
4395     {
4396         $tr = $table[ord "-"];
4397         $table[ord "-"] = -1;
4398         if ($tr >= 0) {
4399             @from = ord("-");
4400             @to = $tr;
4401         } else { # -2 ==> delete
4402             $delhyphen = 1;
4403         }
4404     }
4405     for ($c = 0; $c < @table; $c++) {
4406         $tr = $table[$c];
4407         if ($tr >= 0) {
4408             push @from, $c; push @to, $tr;
4409         } elsif ($tr == -2) {
4410             push @delfrom, $c;
4411         }
4412     }
4413     @from = (@from, @delfrom);
4414     if ($flags & OPpTRANS_COMPLEMENT) {
4415         my @newfrom = ();
4416         my %from;
4417         @from{@from} = (1) x @from;
4418         for ($c = 0; $c < 256; $c++) {
4419             push @newfrom, $c unless $from{$c};
4420         }
4421         @from = @newfrom;
4422     }
4423     unless ($flags & OPpTRANS_DELETE || !@to) {
4424         pop @to while $#to and $to[$#to] == $to[$#to -1];
4425     }
4426     my($from, $to);
4427     $from = collapse(@from);
4428     $to = collapse(@to);
4429     $from .= "-" if $delhyphen;
4430     return ($from, $to);
4431 }
4432
4433 sub tr_chr {
4434     my $x = shift;
4435     if ($x == ord "-") {
4436         return "\\-";
4437     } elsif ($x == ord "\\") {
4438         return "\\\\";
4439     } else {
4440         return chr $x;
4441     }
4442 }
4443
4444 # XXX This doesn't yet handle all cases correctly either
4445
4446 sub tr_decode_utf8 {
4447     my($swash_hv, $flags) = @_;
4448     my %swash = $swash_hv->ARRAY;
4449     my $final = undef;
4450     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
4451     my $none = $swash{"NONE"}->IV;
4452     my $extra = $none + 1;
4453     my(@from, @delfrom, @to);
4454     my $line;
4455     foreach $line (split /\n/, $swash{'LIST'}->PV) {
4456         my($min, $max, $result) = split(/\t/, $line);
4457         $min = hex $min;
4458         if (length $max) {
4459             $max = hex $max;
4460         } else {
4461             $max = $min;
4462         }
4463         $result = hex $result;
4464         if ($result == $extra) {
4465             push @delfrom, [$min, $max];
4466         } else {
4467             push @from, [$min, $max];
4468             push @to, [$result, $result + $max - $min];
4469         }
4470     }
4471     for my $i (0 .. $#from) {
4472         if ($from[$i][0] == ord '-') {
4473             unshift @from, splice(@from, $i, 1);
4474             unshift @to, splice(@to, $i, 1);
4475             last;
4476         } elsif ($from[$i][1] == ord '-') {
4477             $from[$i][1]--;
4478             $to[$i][1]--;
4479             unshift @from, ord '-';
4480             unshift @to, ord '-';
4481             last;
4482         }
4483     }
4484     for my $i (0 .. $#delfrom) {
4485         if ($delfrom[$i][0] == ord '-') {
4486             push @delfrom, splice(@delfrom, $i, 1);
4487             last;
4488         } elsif ($delfrom[$i][1] == ord '-') {
4489             $delfrom[$i][1]--;
4490             push @delfrom, ord '-';
4491             last;
4492         }
4493     }
4494     if (defined $final and $to[$#to][1] != $final) {
4495         push @to, [$final, $final];
4496     }
4497     push @from, @delfrom;
4498     if ($flags & OPpTRANS_COMPLEMENT) {
4499         my @newfrom;
4500         my $next = 0;
4501         for my $i (0 .. $#from) {
4502             push @newfrom, [$next, $from[$i][0] - 1];
4503             $next = $from[$i][1] + 1;
4504         }
4505         @from = ();
4506         for my $range (@newfrom) {
4507             if ($range->[0] <= $range->[1]) {
4508                 push @from, $range;
4509             }
4510         }
4511     }
4512     my($from, $to, $diff);
4513     for my $chunk (@from) {
4514         $diff = $chunk->[1] - $chunk->[0];
4515         if ($diff > 1) {
4516             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
4517         } elsif ($diff == 1) {
4518             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
4519         } else {
4520             $from .= tr_chr($chunk->[0]);
4521         }
4522     }
4523     for my $chunk (@to) {
4524         $diff = $chunk->[1] - $chunk->[0];
4525         if ($diff > 1) {