lib/File/Path.pm

   1 package File::Path;
   2
   3 =head1 NAME
   4
   5 File::Path - create or remove directory trees
   6
   7 =head1 SYNOPSIS
   8
   9     use File::Path;
  10
  11     mkpath(['/foo/bar/baz', 'blurfl/quux'], 1, 0711);
  12     rmtree(['foo/bar/baz', 'blurfl/quux'], 1, 1);
  13
  14 =head1 DESCRIPTION
  15
  16 The C<mkpath> function provides a convenient way to create directories, even
  17 if your C<mkdir> kernel call won't create more than one level of directory at
  18 a time.  C<mkpath> takes three arguments:
  19
  20 =over 4
  21
  22 =item *
  23
  24 the name of the path to create, or a reference
  25 to a list of paths to create,
  26
  27 =item *
  28
  29 a boolean value, which if TRUE will cause C<mkpath>
  30 to print the name of each directory as it is created
  31 (defaults to FALSE), and
  32
  33 =item *
  34
  35 the numeric mode to use when creating the directories
  36 (defaults to 0777)
  37
  38 =back
  39
  40 It returns a list of all directories (including intermediates, determined
  41 using the Unix '/' separator) created.
  42
  43 Similarly, the C<rmtree> function provides a convenient way to delete a
  44 subtree from the directory structure, much like the Unix command C<rm -r>.
  45 C<rmtree> takes three arguments:
  46
  47 =over 4
  48
  49 =item *
  50
  51 the root of the subtree to delete, or a reference to
  52 a list of roots.  All of the files and directories
  53 below each root, as well as the roots themselves,
  54 will be deleted.
  55
  56 =item *
  57
  58 a boolean value, which if TRUE will cause C<rmtree> to
  59 print a message each time it examines a file, giving the
  60 name of the file, and indicating whether it's using C<rmdir>
  61 or C<unlink> to remove it, or that it's skipping it.
  62 (defaults to FALSE)
  63
  64 =item *
  65
  66 a boolean value, which if TRUE will cause C<rmtree> to
  67 skip any files to which you do not have delete access
  68 (if running under VMS) or write access (if running
  69 under another OS).  This will change in the future when
  70 a criterion for 'delete permission' under OSs other
  71 than VMS is settled.  (defaults to FALSE)
  72
  73 =back
  74
  75 It returns the number of files successfully deleted.  Symlinks are
  76 simply deleted and not followed.
  77
  78 B<NOTE:> If the third parameter is not TRUE, C<rmtree> is B<unsecure>
  79 in the face of failure or interruption.  Files and directories which
  80 were not deleted may be left with permissions reset to allow world
  81 read and write access.  Note also that the occurrence of errors in
  82 rmtree can be determined I<only> by trapping diagnostic messages
  83 using C<$SIG{__WARN__}>; it is not apparent from the return value.
  84 Therefore, you must be extremely careful about using C<rmtree($foo,$bar,0>
  85 in situations where security is an issue.
  86
  87 =head1 AUTHORS
  88
  89 Tim Bunce <F<Tim.Bunce@ig.co.uk>> and
  90 Charles Bailey <F<bailey@newman.upenn.edu>>
  91
  92 =cut
  93
  94 use 5.006;
  95 use Carp;
  96 use File::Basename ();
  97 use Exporter ();
  98 use strict;
  99 use warnings;
 100
 101 our $VERSION = "1.05";
 102 our @ISA = qw( Exporter );
 103 our @EXPORT = qw( mkpath rmtree );
 104
 105 my $Is_VMS = $^O eq 'VMS';
 106 my $Is_MacOS = $^O eq 'MacOS';
 107
 108 # These OSes complain if you want to remove a file that you have no
 109 # write permission to:
 110 my $force_writeable = ($^O eq 'os2' || $^O eq 'dos' || $^O eq 'MSWin32' ||
 111                        $^O eq 'amigaos' || $^O eq 'MacOS' || $^O eq 'epoc');
 112
 113 sub mkpath {
 114     my($paths, $verbose, $mode) = @_;
 115     # $paths   -- either a path string or ref to list of paths
 116     # $verbose -- optional print "mkdir $path" for each directory created
 117     # $mode    -- optional permissions, defaults to 0777
 118     local($")=$Is_MacOS ? ":" : "/";
 119     $mode = 0777 unless defined($mode);
 120     $paths = [$paths] unless ref $paths;
 121     my(@created,$path);
 122     foreach $path (@$paths) {
 123         $path .= '/' if $^O eq 'os2' and $path =~ /^\w:\z/s; # feature of CRT
 124         # Logic wants Unix paths, so go with the flow.
 125         if ($Is_VMS) {
 126             next if $path eq '/';
 127             $path = VMS::Filespec::unixify($path);
 128             if ($path =~ m:^(/[^/]+)/?\z:) {
 129                 $path = $1.'/000000';
 130             }
 131         }
 132         next if -d $path;
 133         my $parent = File::Basename::dirname($path);
 134         unless (-d $parent or $path eq $parent) {
 135             push(@created,mkpath($parent, $verbose, $mode));
 136         }
 137         print "mkdir $path\n" if $verbose;
 138         unless (mkdir($path,$mode)) {
 139             my $e = $!;
 140             # allow for another process to have created it meanwhile
 141             croak "mkdir $path: $e" unless -d $path;
 142         }
 143         push(@created, $path);
 144     }
 145     @created;
 146 }
 147
 148 sub rmtree {
 149     my($roots, $verbose, $safe) = @_;
 150     my(@files);
 151     my($count) = 0;
 152     $verbose ||= 0;
 153     $safe ||= 0;
 154
 155     if ( defined($roots) && length($roots) ) {
 156       $roots = [$roots] unless ref $roots;
 157     }
 158     else {
 159       carp "No root path(s) specified\n";
 160       return 0;
 161     }
 162
 163     my($root);
 164     foreach $root (@{$roots}) {
 165         if ($Is_MacOS) {
 166             $root = ":$root" if $root !~ /:/;
 167             $root =~ s#([^:])\z#$1:#;
 168         } else {
 169             $root =~ s#/\z##;
 170         }
 171         (undef, undef, my $rp) = lstat $root or next;
 172         $rp &= 07777;   # don't forget setuid, setgid, sticky bits
 173         if ( -d _ ) {
 174             # notabene: 0777 is for making readable in the first place,
 175             # it's also intended to change it to writable in case we have
 176             # to recurse in which case we are better than rm -rf for
 177             # subtrees with strange permissions
 178             chmod(0777, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 179               or carp "Can't make directory $root read+writeable: $!"
 180                 unless $safe;
 181
 182             if (opendir my $d, $root) {
 183                 no strict 'refs';
 184                 if (!defined ${"\cTAINT"} or ${"\cTAINT"}) {
 185                     # Blindly untaint dir names
 186                     @files = map { /^(.*)$/s ; $1 } readdir $d;
 187                 } else {
 188                     @files = readdir $d;
 189                 }
 190                 closedir $d;
 191             }
 192             else {
 193                 carp "Can't read $root: $!";
 194                 @files = ();
 195             }
 196
 197             # Deleting large numbers of files from VMS Files-11 filesystems
 198             # is faster if done in reverse ASCIIbetical order
 199             @files = reverse @files if $Is_VMS;
 200             ($root = VMS::Filespec::unixify($root)) =~ s#\.dir\z## if $Is_VMS;
 201             if ($Is_MacOS) {
 202                 @files = map("$root$_", @files);
 203             } else {
 204                 @files = map("$root/$_", grep $_!~/^\.{1,2}\z/s,@files);
 205             }
 206             $count += rmtree(\@files,$verbose,$safe);
 207             if ($safe &&
 208                 ($Is_VMS ? !&VMS::Filespec::candelete($root) : !-w $root)) {
 209                 print "skipped $root\n" if $verbose;
 210                 next;
 211             }
 212             chmod 0777, $root
 213               or carp "Can't make directory $root writeable: $!"
 214                 if $force_writeable;
 215             print "rmdir $root\n" if $verbose;
 216             if (rmdir $root) {
 217                 ++$count;
 218             }
 219             else {
 220                 carp "Can't remove directory $root: $!";
 221                 chmod($rp, ($Is_VMS ? VMS::Filespec::fileify($root) : $root))
 222                     or carp("and can't restore permissions to "
 223                             . sprintf("0%o",$rp) . "\n");
 224             }
 225         }
 226         else {
 227             if ($safe &&
 228                 ($Is_VMS ? !&VMS::Filespec::candelete($root)
 229                          : !(-l $root || -w $root)))
 230             {
 231                 print "skipped $root\n" if $verbose;
 232                 next;
 233             }
 234             chmod 0666, $root
 235               or carp "Can't make file $root writeable: $!"
 236                 if $force_writeable;
 237             print "unlink $root\n" if $verbose;
 238             # delete all versions under VMS
 239             for (;;) {
 240                 unless (unlink $root) {
 241                     carp "Can't unlink file $root: $!";
 242                     if ($force_writeable) {
 243                         chmod $rp, $root
 244                             or carp("and can't restore permissions to "
 245                                     . sprintf("0%o",$rp) . "\n");
 246                     }
 247                     last;
 248                 }
 249                 ++$count;
 250                 last unless $Is_VMS && lstat $root;
 251             }
 252         }
 253     }
 254
 255     $count;
 256 }
 257
 258 1;