This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update to Storable 1.0.13.
[perl5.git] / ext / Storable / Storable.pm
1 ;# $Id: Storable.pm,v 1.0.1.12 2001/08/28 21:51:51 ram Exp $
2 ;#
3 ;#  Copyright (c) 1995-2000, Raphael Manfredi
4 ;#  
5 ;#  You may redistribute only under the same terms as Perl 5, as specified
6 ;#  in the README file that comes with the distribution.
7 ;#
8 ;# $Log: Storable.pm,v $
9 ;# Revision 1.0.1.12  2001/08/28 21:51:51  ram
10 ;# patch13: fixed truncation race with lock_retrieve() in lock_store()
11 ;#
12 ;# Revision 1.0.1.11  2001/07/01 11:22:14  ram
13 ;# patch12: systematically use "=over 4" for POD linters
14 ;# patch12: updated version number
15 ;#
16 ;# Revision 1.0.1.10  2001/03/15 00:20:25  ram
17 ;# patch11: updated version number
18 ;#
19 ;# Revision 1.0.1.9  2001/02/17 12:37:32  ram
20 ;# patch10: forgot to increase version number at previous patch
21 ;#
22 ;# Revision 1.0.1.8  2001/02/17 12:24:37  ram
23 ;# patch8: fixed incorrect error message
24 ;#
25 ;# Revision 1.0.1.7  2001/01/03 09:39:02  ram
26 ;# patch7: added CAN_FLOCK to determine whether we can flock() or not
27 ;#
28 ;# Revision 1.0.1.6  2000/11/05 17:20:25  ram
29 ;# patch6: increased version number
30 ;#
31 ;# Revision 1.0.1.5  2000/10/26 17:10:18  ram
32 ;# patch5: documented that store() and retrieve() can return undef
33 ;# patch5: added paragraph explaining the auto require for thaw hooks
34 ;#
35 ;# Revision 1.0.1.4  2000/10/23 18:02:57  ram
36 ;# patch4: protected calls to flock() for dos platform
37 ;# patch4: added logcarp emulation if they don't have Log::Agent
38 ;#
39 ;# Revision 1.0.1.3  2000/09/29 19:49:01  ram
40 ;# patch3: updated version number
41 ;#
42 ;# Revision 1.0.1.2  2000/09/28 21:42:51  ram
43 ;# patch2: added lock_store lock_nstore lock_retrieve
44 ;#
45 ;# Revision 1.0.1.1  2000/09/17 16:46:21  ram
46 ;# patch1: documented that doubles are stringified by nstore()
47 ;# patch1: added Salvador Ortiz Garcia in CREDITS section
48 ;#
49 ;# Revision 1.0  2000/09/01 19:40:41  ram
50 ;# Baseline for first official release.
51 ;#
52
53 require DynaLoader;
54 require Exporter;
55 package Storable; @ISA = qw(Exporter DynaLoader);
56
57 @EXPORT = qw(store retrieve);
58 @EXPORT_OK = qw(
59         nstore store_fd nstore_fd fd_retrieve
60         freeze nfreeze thaw
61         dclone
62         retrieve_fd
63         lock_store lock_nstore lock_retrieve
64 );
65
66 use AutoLoader;
67 use vars qw($forgive_me $VERSION);
68
69 $VERSION = '1.013';
70 *AUTOLOAD = \&AutoLoader::AUTOLOAD;             # Grrr...
71
72 #
73 # Use of Log::Agent is optional
74 #
75
76 eval "use Log::Agent";
77
78 unless (defined @Log::Agent::EXPORT) {
79         eval q{
80                 sub logcroak {
81                         require Carp;
82                         Carp::croak(@_);
83                 }
84                 sub logcarp {
85                         require Carp;
86                         Carp::carp(@_);
87                 }
88         };
89 }
90
91 #
92 # They might miss :flock in Fcntl
93 #
94
95 BEGIN {
96         require Fcntl;
97         if (exists $Fcntl::EXPORT_TAGS{'flock'}) {
98                 Fcntl->import(':flock');
99         } else {
100                 eval q{
101                         sub LOCK_SH ()  {1}
102                         sub LOCK_EX ()  {2}
103                 };
104         }
105 }
106
107 sub logcroak;
108 sub logcarp;
109
110 sub retrieve_fd { &fd_retrieve }                # Backward compatibility
111
112 #
113 # Determine whether locking is possible, but only when needed.
114 #
115
116 my $CAN_FLOCK;
117
118 sub CAN_FLOCK {
119         return $CAN_FLOCK if defined $CAN_FLOCK;
120         require Config; import Config;
121         return $CAN_FLOCK =
122                 $Config{'d_flock'} ||
123                 $Config{'d_fcntl_can_lock'} ||
124                 $Config{'d_lockf'};
125 }
126
127 bootstrap Storable;
128 1;
129 __END__
130
131 #
132 # store
133 #
134 # Store target object hierarchy, identified by a reference to its root.
135 # The stored object tree may later be retrieved to memory via retrieve.
136 # Returns undef if an I/O error occurred, in which case the file is
137 # removed.
138 #
139 sub store {
140         return _store(\&pstore, @_, 0);
141 }
142
143 #
144 # nstore
145 #
146 # Same as store, but in network order.
147 #
148 sub nstore {
149         return _store(\&net_pstore, @_, 0);
150 }
151
152 #
153 # lock_store
154 #
155 # Same as store, but flock the file first (advisory locking).
156 #
157 sub lock_store {
158         return _store(\&pstore, @_, 1);
159 }
160
161 #
162 # lock_nstore
163 #
164 # Same as nstore, but flock the file first (advisory locking).
165 #
166 sub lock_nstore {
167         return _store(\&net_pstore, @_, 1);
168 }
169
170 # Internal store to file routine
171 sub _store {
172         my $xsptr = shift;
173         my $self = shift;
174         my ($file, $use_locking) = @_;
175         logcroak "not a reference" unless ref($self);
176         logcroak "wrong argument number" unless @_ == 2;        # No @foo in arglist
177         local *FILE;
178         if ($use_locking) {
179                 open(FILE, ">>$file") || logcroak "can't write into $file: $!";
180                 unless (&CAN_FLOCK) {
181                         logcarp "Storable::lock_store: fcntl/flock emulation broken on $^O";
182                         return undef;
183                 }
184                 flock(FILE, LOCK_EX) ||
185                         logcroak "can't get exclusive lock on $file: $!";
186                 truncate FILE, 0;
187                 # Unlocking will happen when FILE is closed
188         } else {
189                 open(FILE, ">$file") || logcroak "can't create $file: $!";
190         }
191         binmode FILE;                           # Archaic systems...
192         my $da = $@;                            # Don't mess if called from exception handler
193         my $ret;
194         # Call C routine nstore or pstore, depending on network order
195         eval { $ret = &$xsptr(*FILE, $self) };
196         close(FILE) or $ret = undef;
197         unlink($file) or warn "Can't unlink $file: $!\n" if $@ || !defined $ret;
198         logcroak $@ if $@ =~ s/\.?\n$/,/;
199         $@ = $da;
200         return $ret ? $ret : undef;
201 }
202
203 #
204 # store_fd
205 #
206 # Same as store, but perform on an already opened file descriptor instead.
207 # Returns undef if an I/O error occurred.
208 #
209 sub store_fd {
210         return _store_fd(\&pstore, @_);
211 }
212
213 #
214 # nstore_fd
215 #
216 # Same as store_fd, but in network order.
217 #
218 sub nstore_fd {
219         my ($self, $file) = @_;
220         return _store_fd(\&net_pstore, @_);
221 }
222
223 # Internal store routine on opened file descriptor
224 sub _store_fd {
225         my $xsptr = shift;
226         my $self = shift;
227         my ($file) = @_;
228         logcroak "not a reference" unless ref($self);
229         logcroak "too many arguments" unless @_ == 1;   # No @foo in arglist
230         my $fd = fileno($file);
231         logcroak "not a valid file descriptor" unless defined $fd;
232         my $da = $@;                            # Don't mess if called from exception handler
233         my $ret;
234         # Call C routine nstore or pstore, depending on network order
235         eval { $ret = &$xsptr($file, $self) };
236         logcroak $@ if $@ =~ s/\.?\n$/,/;
237         $@ = $da;
238         return $ret ? $ret : undef;
239 }
240
241 #
242 # freeze
243 #
244 # Store oject and its hierarchy in memory and return a scalar
245 # containing the result.
246 #
247 sub freeze {
248         _freeze(\&mstore, @_);
249 }
250
251 #
252 # nfreeze
253 #
254 # Same as freeze but in network order.
255 #
256 sub nfreeze {
257         _freeze(\&net_mstore, @_);
258 }
259
260 # Internal freeze routine
261 sub _freeze {
262         my $xsptr = shift;
263         my $self = shift;
264         logcroak "not a reference" unless ref($self);
265         logcroak "too many arguments" unless @_ == 0;   # No @foo in arglist
266         my $da = $@;                            # Don't mess if called from exception handler
267         my $ret;
268         # Call C routine mstore or net_mstore, depending on network order
269         eval { $ret = &$xsptr($self) };
270         logcroak $@ if $@ =~ s/\.?\n$/,/;
271         $@ = $da;
272         return $ret ? $ret : undef;
273 }
274
275 #
276 # retrieve
277 #
278 # Retrieve object hierarchy from disk, returning a reference to the root
279 # object of that tree.
280 #
281 sub retrieve {
282         _retrieve($_[0], 0);
283 }
284
285 #
286 # lock_retrieve
287 #
288 # Same as retrieve, but with advisory locking.
289 #
290 sub lock_retrieve {
291         _retrieve($_[0], 1);
292 }
293
294 # Internal retrieve routine
295 sub _retrieve {
296         my ($file, $use_locking) = @_;
297         local *FILE;
298         open(FILE, $file) || logcroak "can't open $file: $!";
299         binmode FILE;                                                   # Archaic systems...
300         my $self;
301         my $da = $@;                                                    # Could be from exception handler
302         if ($use_locking) {
303                 unless (&CAN_FLOCK) {
304                         logcarp "Storable::lock_store: fcntl/flock emulation broken on $^O";
305                         return undef;
306                 }
307                 flock(FILE, LOCK_SH) || logcroak "can't get shared lock on $file: $!";
308                 # Unlocking will happen when FILE is closed
309         }
310         eval { $self = pretrieve(*FILE) };              # Call C routine
311         close(FILE);
312         logcroak $@ if $@ =~ s/\.?\n$/,/;
313         $@ = $da;
314         return $self;
315 }
316
317 #
318 # fd_retrieve
319 #
320 # Same as retrieve, but perform from an already opened file descriptor instead.
321 #
322 sub fd_retrieve {
323         my ($file) = @_;
324         my $fd = fileno($file);
325         logcroak "not a valid file descriptor" unless defined $fd;
326         my $self;
327         my $da = $@;                                                    # Could be from exception handler
328         eval { $self = pretrieve($file) };              # Call C routine
329         logcroak $@ if $@ =~ s/\.?\n$/,/;
330         $@ = $da;
331         return $self;
332 }
333
334 #
335 # thaw
336 #
337 # Recreate objects in memory from an existing frozen image created
338 # by freeze.  If the frozen image passed is undef, return undef.
339 #
340 sub thaw {
341         my ($frozen) = @_;
342         return undef unless defined $frozen;
343         my $self;
344         my $da = $@;                                                    # Could be from exception handler
345         eval { $self = mretrieve($frozen) };    # Call C routine
346         logcroak $@ if $@ =~ s/\.?\n$/,/;
347         $@ = $da;
348         return $self;
349 }
350
351 =head1 NAME
352
353 Storable - persistency for perl data structures
354
355 =head1 SYNOPSIS
356
357  use Storable;
358  store \%table, 'file';
359  $hashref = retrieve('file');
360
361  use Storable qw(nstore store_fd nstore_fd freeze thaw dclone);
362
363  # Network order
364  nstore \%table, 'file';
365  $hashref = retrieve('file');   # There is NO nretrieve()
366
367  # Storing to and retrieving from an already opened file
368  store_fd \@array, \*STDOUT;
369  nstore_fd \%table, \*STDOUT;
370  $aryref = fd_retrieve(\*SOCKET);
371  $hashref = fd_retrieve(\*SOCKET);
372
373  # Serializing to memory
374  $serialized = freeze \%table;
375  %table_clone = %{ thaw($serialized) };
376
377  # Deep (recursive) cloning
378  $cloneref = dclone($ref);
379
380  # Advisory locking
381  use Storable qw(lock_store lock_nstore lock_retrieve)
382  lock_store \%table, 'file';
383  lock_nstore \%table, 'file';
384  $hashref = lock_retrieve('file');
385
386 =head1 DESCRIPTION
387
388 The Storable package brings persistency to your perl data structures
389 containing SCALAR, ARRAY, HASH or REF objects, i.e. anything that can be
390 convenientely stored to disk and retrieved at a later time.
391
392 It can be used in the regular procedural way by calling C<store> with
393 a reference to the object to be stored, along with the file name where
394 the image should be written.
395 The routine returns C<undef> for I/O problems or other internal error,
396 a true value otherwise. Serious errors are propagated as a C<die> exception.
397
398 To retrieve data stored to disk, use C<retrieve> with a file name,
399 and the objects stored into that file are recreated into memory for you,
400 a I<reference> to the root object being returned. In case an I/O error
401 occurs while reading, C<undef> is returned instead. Other serious
402 errors are propagated via C<die>.
403
404 Since storage is performed recursively, you might want to stuff references
405 to objects that share a lot of common data into a single array or hash
406 table, and then store that object. That way, when you retrieve back the
407 whole thing, the objects will continue to share what they originally shared.
408
409 At the cost of a slight header overhead, you may store to an already
410 opened file descriptor using the C<store_fd> routine, and retrieve
411 from a file via C<fd_retrieve>. Those names aren't imported by default,
412 so you will have to do that explicitely if you need those routines.
413 The file descriptor you supply must be already opened, for read
414 if you're going to retrieve and for write if you wish to store.
415
416         store_fd(\%table, *STDOUT) || die "can't store to stdout\n";
417         $hashref = fd_retrieve(*STDIN);
418
419 You can also store data in network order to allow easy sharing across
420 multiple platforms, or when storing on a socket known to be remotely
421 connected. The routines to call have an initial C<n> prefix for I<network>,
422 as in C<nstore> and C<nstore_fd>. At retrieval time, your data will be
423 correctly restored so you don't have to know whether you're restoring
424 from native or network ordered data.  Double values are stored stringified
425 to ensure portability as well, at the slight risk of loosing some precision
426 in the last decimals.
427
428 When using C<fd_retrieve>, objects are retrieved in sequence, one
429 object (i.e. one recursive tree) per associated C<store_fd>.
430
431 If you're more from the object-oriented camp, you can inherit from
432 Storable and directly store your objects by invoking C<store> as
433 a method. The fact that the root of the to-be-stored tree is a
434 blessed reference (i.e. an object) is special-cased so that the
435 retrieve does not provide a reference to that object but rather the
436 blessed object reference itself. (Otherwise, you'd get a reference
437 to that blessed object).
438
439 =head1 MEMORY STORE
440
441 The Storable engine can also store data into a Perl scalar instead, to
442 later retrieve them. This is mainly used to freeze a complex structure in
443 some safe compact memory place (where it can possibly be sent to another
444 process via some IPC, since freezing the structure also serializes it in
445 effect). Later on, and maybe somewhere else, you can thaw the Perl scalar
446 out and recreate the original complex structure in memory.
447
448 Surprisingly, the routines to be called are named C<freeze> and C<thaw>.
449 If you wish to send out the frozen scalar to another machine, use
450 C<nfreeze> instead to get a portable image.
451
452 Note that freezing an object structure and immediately thawing it
453 actually achieves a deep cloning of that structure:
454
455     dclone(.) = thaw(freeze(.))
456
457 Storable provides you with a C<dclone> interface which does not create
458 that intermediary scalar but instead freezes the structure in some
459 internal memory space and then immediatly thaws it out.
460
461 =head1 ADVISORY LOCKING
462
463 The C<lock_store> and C<lock_nstore> routine are equivalent to C<store>
464 and C<nstore>, only they get an exclusive lock on the file before
465 writing.  Likewise, C<lock_retrieve> performs as C<retrieve>, but also
466 gets a shared lock on the file before reading.
467
468 Like with any advisory locking scheme, the protection only works if
469 you systematically use C<lock_store> and C<lock_retrieve>.  If one
470 side of your application uses C<store> whilst the other uses C<lock_retrieve>,
471 you will get no protection at all.
472
473 The internal advisory locking is implemented using Perl's flock() routine.
474 If your system does not support any form of flock(), or if you share
475 your files across NFS, you might wish to use other forms of locking by
476 using modules like LockFile::Simple which lock a file using a filesystem
477 entry, instead of locking the file descriptor.
478
479 =head1 SPEED
480
481 The heart of Storable is written in C for decent speed. Extra low-level
482 optimization have been made when manipulating perl internals, to
483 sacrifice encapsulation for the benefit of a greater speed.
484
485 =head1 CANONICAL REPRESENTATION
486
487 Normally Storable stores elements of hashes in the order they are
488 stored internally by Perl, i.e. pseudo-randomly.  If you set
489 C<$Storable::canonical> to some C<TRUE> value, Storable will store
490 hashes with the elements sorted by their key.  This allows you to
491 compare data structures by comparing their frozen representations (or
492 even the compressed frozen representations), which can be useful for
493 creating lookup tables for complicated queries.
494
495 Canonical order does not imply network order, those are two orthogonal
496 settings.
497
498 =head1 ERROR REPORTING
499
500 Storable uses the "exception" paradigm, in that it does not try to workaround
501 failures: if something bad happens, an exception is generated from the
502 caller's perspective (see L<Carp> and C<croak()>).  Use eval {} to trap
503 those exceptions.
504
505 When Storable croaks, it tries to report the error via the C<logcroak()>
506 routine from the C<Log::Agent> package, if it is available.
507
508 Normal errors are reported by having store() or retrieve() return C<undef>.
509 Such errors are usually I/O errors (or truncated stream errors at retrieval).
510
511 =head1 WIZARDS ONLY
512
513 =head2 Hooks
514
515 Any class may define hooks that will be called during the serialization
516 and deserialization process on objects that are instances of that class.
517 Those hooks can redefine the way serialization is performed (and therefore,
518 how the symetrical deserialization should be conducted).
519
520 Since we said earlier:
521
522     dclone(.) = thaw(freeze(.))
523
524 everything we say about hooks should also hold for deep cloning. However,
525 hooks get to know whether the operation is a mere serialization, or a cloning.
526
527 Therefore, when serializing hooks are involved,
528
529     dclone(.) <> thaw(freeze(.))
530
531 Well, you could keep them in sync, but there's no guarantee it will always
532 hold on classes somebody else wrote.  Besides, there is little to gain in
533 doing so: a serializing hook could only keep one attribute of an object,
534 which is probably not what should happen during a deep cloning of that
535 same object.
536
537 Here is the hooking interface:
538
539 =over 4
540
541 =item C<STORABLE_freeze> I<obj>, I<cloning>
542
543 The serializing hook, called on the object during serialization.  It can be
544 inherited, or defined in the class itself, like any other method.
545
546 Arguments: I<obj> is the object to serialize, I<cloning> is a flag indicating
547 whether we're in a dclone() or a regular serialization via store() or freeze().
548
549 Returned value: A LIST C<($serialized, $ref1, $ref2, ...)> where $serialized
550 is the serialized form to be used, and the optional $ref1, $ref2, etc... are
551 extra references that you wish to let the Storable engine serialize.
552
553 At deserialization time, you will be given back the same LIST, but all the
554 extra references will be pointing into the deserialized structure.
555
556 The B<first time> the hook is hit in a serialization flow, you may have it
557 return an empty list.  That will signal the Storable engine to further
558 discard that hook for this class and to therefore revert to the default
559 serialization of the underlying Perl data.  The hook will again be normally
560 processed in the next serialization.
561
562 Unless you know better, serializing hook should always say:
563
564     sub STORABLE_freeze {
565         my ($self, $cloning) = @_;
566         return if $cloning;         # Regular default serialization
567         ....
568     }
569
570 in order to keep reasonable dclone() semantics.
571
572 =item C<STORABLE_thaw> I<obj>, I<cloning>, I<serialized>, ...
573
574 The deserializing hook called on the object during deserialization.
575 But wait. If we're deserializing, there's no object yet... right?
576
577 Wrong: the Storable engine creates an empty one for you.  If you know Eiffel,
578 you can view C<STORABLE_thaw> as an alternate creation routine.
579
580 This means the hook can be inherited like any other method, and that
581 I<obj> is your blessed reference for this particular instance.
582
583 The other arguments should look familiar if you know C<STORABLE_freeze>:
584 I<cloning> is true when we're part of a deep clone operation, I<serialized>
585 is the serialized string you returned to the engine in C<STORABLE_freeze>,
586 and there may be an optional list of references, in the same order you gave
587 them at serialization time, pointing to the deserialized objects (which
588 have been processed courtesy of the Storable engine).
589
590 When the Storable engine does not find any C<STORABLE_thaw> hook routine,
591 it tries to load the class by requiring the package dynamically (using
592 the blessed package name), and then re-attempts the lookup.  If at that
593 time the hook cannot be located, the engine croaks.  Note that this mechanism
594 will fail if you define several classes in the same file, but perlmod(1)
595 warned you.
596
597 It is up to you to use these information to populate I<obj> the way you want.
598
599 Returned value: none.
600
601 =back
602
603 =head2 Predicates
604
605 Predicates are not exportable.  They must be called by explicitely prefixing
606 them with the Storable package name.
607
608 =over 4
609
610 =item C<Storable::last_op_in_netorder>
611
612 The C<Storable::last_op_in_netorder()> predicate will tell you whether
613 network order was used in the last store or retrieve operation.  If you
614 don't know how to use this, just forget about it.
615
616 =item C<Storable::is_storing>
617
618 Returns true if within a store operation (via STORABLE_freeze hook).
619
620 =item C<Storable::is_retrieving>
621
622 Returns true if within a retrieve operation, (via STORABLE_thaw hook).
623
624 =back
625
626 =head2 Recursion
627
628 With hooks comes the ability to recurse back to the Storable engine.  Indeed,
629 hooks are regular Perl code, and Storable is convenient when it comes to
630 serialize and deserialize things, so why not use it to handle the
631 serialization string?
632
633 There are a few things you need to know however:
634
635 =over 4
636
637 =item *
638
639 You can create endless loops if the things you serialize via freeze()
640 (for instance) point back to the object we're trying to serialize in the hook.
641
642 =item *
643
644 Shared references among objects will not stay shared: if we're serializing
645 the list of object [A, C] where both object A and C refer to the SAME object
646 B, and if there is a serializing hook in A that says freeze(B), then when
647 deserializing, we'll get [A', C'] where A' refers to B', but C' refers to D,
648 a deep clone of B'.  The topology was not preserved.
649
650 =back
651
652 That's why C<STORABLE_freeze> lets you provide a list of references
653 to serialize.  The engine guarantees that those will be serialized in the
654 same context as the other objects, and therefore that shared objects will
655 stay shared.
656
657 In the above [A, C] example, the C<STORABLE_freeze> hook could return:
658
659         ("something", $self->{B})
660
661 and the B part would be serialized by the engine.  In C<STORABLE_thaw>, you
662 would get back the reference to the B' object, deserialized for you.
663
664 Therefore, recursion should normally be avoided, but is nonetheless supported.
665
666 =head2 Deep Cloning
667
668 There is a new Clone module available on CPAN which implements deep cloning
669 natively, i.e. without freezing to memory and thawing the result.  It is
670 aimed to replace Storable's dclone() some day.  However, it does not currently
671 support Storable hooks to redefine the way deep cloning is performed.
672
673 =head1 EXAMPLES
674
675 Here are some code samples showing a possible usage of Storable:
676
677         use Storable qw(store retrieve freeze thaw dclone);
678
679         %color = ('Blue' => 0.1, 'Red' => 0.8, 'Black' => 0, 'White' => 1);
680
681         store(\%color, '/tmp/colors') or die "Can't store %a in /tmp/colors!\n";
682
683         $colref = retrieve('/tmp/colors');
684         die "Unable to retrieve from /tmp/colors!\n" unless defined $colref;
685         printf "Blue is still %lf\n", $colref->{'Blue'};
686
687         $colref2 = dclone(\%color);
688
689         $str = freeze(\%color);
690         printf "Serialization of %%color is %d bytes long.\n", length($str);
691         $colref3 = thaw($str);
692
693 which prints (on my machine):
694
695         Blue is still 0.100000
696         Serialization of %color is 102 bytes long.
697
698 =head1 WARNING
699
700 If you're using references as keys within your hash tables, you're bound
701 to disapointment when retrieving your data. Indeed, Perl stringifies
702 references used as hash table keys. If you later wish to access the
703 items via another reference stringification (i.e. using the same
704 reference that was used for the key originally to record the value into
705 the hash table), it will work because both references stringify to the
706 same string.
707
708 It won't work across a C<store> and C<retrieve> operations however, because
709 the addresses in the retrieved objects, which are part of the stringified
710 references, will probably differ from the original addresses. The
711 topology of your structure is preserved, but not hidden semantics
712 like those.
713
714 On platforms where it matters, be sure to call C<binmode()> on the
715 descriptors that you pass to Storable functions.
716
717 Storing data canonically that contains large hashes can be
718 significantly slower than storing the same data normally, as
719 temprorary arrays to hold the keys for each hash have to be allocated,
720 populated, sorted and freed.  Some tests have shown a halving of the
721 speed of storing -- the exact penalty will depend on the complexity of
722 your data.  There is no slowdown on retrieval.
723
724 =head1 BUGS
725
726 You can't store GLOB, CODE, FORMLINE, etc... If you can define
727 semantics for those operations, feel free to enhance Storable so that
728 it can deal with them.
729
730 The store functions will C<croak> if they run into such references
731 unless you set C<$Storable::forgive_me> to some C<TRUE> value. In that
732 case, the fatal message is turned in a warning and some
733 meaningless string is stored instead.
734
735 Setting C<$Storable::canonical> may not yield frozen strings that
736 compare equal due to possible stringification of numbers. When the
737 string version of a scalar exists, it is the form stored, therefore
738 if you happen to use your numbers as strings between two freezing
739 operations on the same data structures, you will get different
740 results.
741
742 When storing doubles in network order, their value is stored as text.
743 However, you should also not expect non-numeric floating-point values
744 such as infinity and "not a number" to pass successfully through a
745 nstore()/retrieve() pair.
746
747 As Storable neither knows nor cares about character sets (although it
748 does know that characters may be more than eight bits wide), any difference
749 in the interpretation of character codes between a host and a target
750 system is your problem.  In particular, if host and target use different
751 code points to represent the characters used in the text representation
752 of floating-point numbers, you will not be able be able to exchange
753 floating-point data, even with nstore().
754
755 =head1 CREDITS
756
757 Thank you to (in chronological order):
758
759         Jarkko Hietaniemi <jhi@iki.fi>
760         Ulrich Pfeifer <pfeifer@charly.informatik.uni-dortmund.de>
761         Benjamin A. Holzman <bah@ecnvantage.com>
762         Andrew Ford <A.Ford@ford-mason.co.uk>
763         Gisle Aas <gisle@aas.no>
764         Jeff Gresham <gresham_jeffrey@jpmorgan.com>
765         Murray Nesbitt <murray@activestate.com>
766         Marc Lehmann <pcg@opengroup.org>
767         Justin Banks <justinb@wamnet.com>
768         Jarkko Hietaniemi <jhi@iki.fi> (AGAIN, as perl 5.7.0 Pumpkin!)
769         Salvador Ortiz Garcia <sog@msg.com.mx>
770         Dominic Dunlop <domo@computer.org>
771         Erik Haugan <erik@solbors.no>
772
773 for their bug reports, suggestions and contributions.
774
775 Benjamin Holzman contributed the tied variable support, Andrew Ford
776 contributed the canonical order for hashes, and Gisle Aas fixed
777 a few misunderstandings of mine regarding the Perl internals,
778 and optimized the emission of "tags" in the output streams by
779 simply counting the objects instead of tagging them (leading to
780 a binary incompatibility for the Storable image starting at version
781 0.6--older images are of course still properly understood).
782 Murray Nesbitt made Storable thread-safe.  Marc Lehmann added overloading
783 and reference to tied items support.
784
785 =head1 TRANSLATIONS
786
787 There is a Japanese translation of this man page available at
788 http://member.nifty.ne.jp/hippo2000/perltips/storable.htm ,
789 courtesy of Kawai, Takanori <kawai@nippon-rad.co.jp>.
790
791 =head1 AUTHOR
792
793 Raphael Manfredi F<E<lt>Raphael_Manfredi@pobox.comE<gt>>
794
795 =head1 SEE ALSO
796
797 Clone(3).
798
799 =cut
800