This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Move File::Find from lib/ to ext/
[perl5.git] / write_buildcustomize.pl
1 #!./miniperl -w
2
3 use strict;
4 if (@ARGV) {
5     my $dir = shift;
6     chdir $dir or die "Can't chdir '$dir': $!";
7     unshift @INC, 'lib';
8 }
9
10 my $file = 'lib/buildcustomize.pl';
11
12 # To clarify, this isn't the entire suite of modules considered "toolchain"
13 # It's not even all modules needed to build ext/
14 # It's just the source paths of the (minimum complete set of) modules in ext/
15 # needed to build the nonxs modules
16 # After which, all nonxs modules are in lib, which was always sufficient to
17 # allow miniperl to build everything else.
18 # Term::ReadLine is not here for building but for allowing the debugger to
19 # run under miniperl when nothing but miniperl will build :-(.
20
21 my @toolchain = qw(cpan/AutoLoader/lib
22                    dist/Carp/lib
23                    dist/Cwd dist/Cwd/lib
24                    dist/ExtUtils-Command/lib
25                    dist/ExtUtils-Install/lib
26                    cpan/ExtUtils-MakeMaker/lib
27                    dist/ExtUtils-Manifest/lib
28                    cpan/File-Path/lib
29                    ext/re
30                    dist/Term-ReadLine/lib
31                    dist/Exporter/lib
32                    ext/File-Find/lib
33                    );
34
35 # Used only in ExtUtils::Liblist::Kid::_win32_ext()
36 push @toolchain, 'cpan/Text-ParseWords/lib' if $^O eq 'MSWin32';
37 push @toolchain, 'ext/VMS-Filespec/lib' if $^O eq 'VMS';
38
39 unshift @INC, @toolchain;
40 require File::Spec::Functions;
41
42 # lib must be last, as the toolchain modules write themselves into it
43 # as they build, and it's important that @INC order ensures that the partially
44 # written files are always masked by the complete versions.
45
46 my $inc = join ",\n        ",
47     map { "q\0$_\0" }
48     (map {File::Spec::Functions::rel2abs($_)} @toolchain, 'lib'), '.';
49
50 open my $fh, '>', $file
51     or die "Can't open $file: $!";
52
53 my $error;
54
55 # If any of the system's build tools are written in Perl, then this module
56 # may well be loaded by a much older version than we are building. So keep it
57 # as backwards compatible as is easy.
58 print $fh <<"EOT" or $error = "Can't print to $file: $!";
59 #!perl
60
61 # We are miniperl, building extensions
62 # Reset \@INC completely, adding the directories we need, and removing the
63 # installed directories (which we don't need to read, and may confuse us)
64 \@INC = ($inc);
65 EOT
66
67 if ($error) {
68     close $fh
69         or warn "Can't unlink $file after error: $!";
70 } else {
71     if (close $fh) {
72         do $file and exit;
73         $error = "Can't load generated $file: $@";
74     } else {
75         $error = "Can't close $file: $!";
76     }
77 }
78
79 # It's going very wrong, so try to remove the botched file.
80
81 unlink $file
82     or warn "Can't unlink $file after error: $!";
83 die $error;
84
85 # Local variables:
86 # cperl-indent-level: 4
87 # indent-tabs-mode: nil
88 # End:
89 #
90 # ex: set ts=8 sts=4 sw=4 et: