This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
6dc958791c463279b49c4a3f82e048f3517a098d
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still current
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17 # Measure the elapsed wallclock time.
18 my $t0 = time();
19
20 # If we're doing deparse tests, ignore failures for these
21 my $deparse_failures;
22
23 # And skip even running these
24 my $deparse_skips;
25
26 # directories with special sets of test switches
27 my %dir_to_switch =
28     (base => '',
29      comp => '',
30      run => '',
31      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
32      );
33
34 # "not absolute" is the default, as it saves some fakery within TestInit
35 # which can perturb tests, and takes CPU. Working with the upstream author of
36 # any of these, to figure out how to remove them from this list, considered
37 # "a good thing".
38 my %abs = (
39            '../cpan/Archive-Tar' => 1,
40            '../cpan/AutoLoader' => 1,
41            '../cpan/CPAN' => 1,
42            '../cpan/Devel-PPPort' => 1,
43            '../cpan/Encode' => 1,
44            '../cpan/ExtUtils-Constant' => 1,
45            '../cpan/ExtUtils-Install' => 1,
46            '../cpan/ExtUtils-MakeMaker' => 1,
47            '../cpan/ExtUtils-Manifest' => 1,
48            '../cpan/File-Fetch' => 1,
49            '../cpan/IPC-Cmd' => 1,
50            '../cpan/IPC-SysV' => 1,
51            '../cpan/Locale-Codes' => 1,
52            '../cpan/Module-Load' => 1,
53            '../cpan/Module-Load-Conditional' => 1,
54            '../cpan/Pod-Simple' => 1,
55            '../cpan/Test-Simple' => 1,
56            '../cpan/podlators' => 1,
57            '../dist/Cwd' => 1,
58            '../dist/ExtUtils-ParseXS' => 1,
59            '../dist/Tie-File' => 1,
60           );
61
62 my %temp_no_core =
63     ('../cpan/B-Debug' => 1,
64      '../cpan/Compress-Raw-Bzip2' => 1,
65      '../cpan/Compress-Raw-Zlib' => 1,
66      '../cpan/Devel-PPPort' => 1,
67      '../cpan/Getopt-Long' => 1,
68      '../cpan/IO-Compress' => 1,
69      '../cpan/MIME-Base64' => 1,
70      '../cpan/parent' => 1,
71      '../cpan/Pod-Simple' => 1,
72      '../cpan/podlators' => 1,
73      '../cpan/Test-Simple' => 1,
74      '../cpan/Tie-RefHash' => 1,
75      '../cpan/Unicode-Collate' => 1,
76      '../dist/Unicode-Normalize' => 1,
77     );
78
79 # temporary workaround Apr 2017.  These need '.' in @INC.
80 # Ideally this # list will eventually be empty
81
82 my %temp_needs_dot  = map { $_ => 1 } qw(
83     ../cpan/ExtUtils-Install
84     ../cpan/Filter-Util-Call
85     ../cpan/libnet
86     ../cpan/Locale-Codes
87     ../cpan/Math-BigInt
88     ../cpan/Math-BigRat
89     ../cpan/Test-Harness
90     ../cpan/Test-Simple
91     ../cpan/version
92 );
93
94
95 # delete env vars that may influence the results
96 # but allow override via *_TEST env var if wanted
97 # (e.g. PERL5OPT_TEST=-d:NYTProf)
98 my @bad_env_vars = qw(
99     PERL5LIB PERLLIB PERL5OPT
100     PERL_YAML_BACKEND PERL_JSON_BACKEND
101 );
102
103 for my $envname (@bad_env_vars) {
104     my $override = $ENV{"${envname}_TEST"};
105     if (defined $override) {
106         warn "$0: $envname=$override\n";
107         $ENV{$envname} = $override;
108     }
109     else {
110         delete $ENV{$envname};
111     }
112 }
113
114 # Location to put the Valgrind log.
115 our $Valgrind_Log;
116
117 my %skip = (
118             '.' => 1,
119             '..' => 1,
120             'CVS' => 1,
121             'RCS' => 1,
122             'SCCS' => 1,
123             '.svn' => 1,
124            );
125
126
127 if ($::do_nothing) {
128     return 1;
129 }
130
131 $| = 1;
132
133 # for testing TEST only
134 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
135 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
136
137 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
138 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
139
140 # String eval to avoid loading File::Glob on non-miniperl.
141 # (Windows only uses this script for miniperl.)
142 @ARGV = eval 'map glob, @ARGV' if $^O eq 'MSWin32';
143
144 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
145
146 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
147 # can't rely on require working.
148 {
149     my @argv = ();
150     foreach my $idx (0..$#ARGV) {
151         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
152         $::benchmark = 1 if $1 eq 'benchmark';
153         $::core    = 1 if $1 eq 'core';
154         $::verbose = 1 if $1 eq 'v';
155         $::torture = 1 if $1 eq 'torture';
156         $::with_utf8 = 1 if $1 eq 'utf8';
157         $::with_utf16 = 1 if $1 eq 'utf16';
158         $::taintwarn = 1 if $1 eq 'taintwarn';
159         if ($1 =~ /^deparse(,.+)?$/) {
160             $::deparse = 1;
161             $::deparse_opts = $1;
162             _process_deparse_config();
163         }
164     }
165     @ARGV = @argv;
166 }
167
168 chdir 't' if -f 't/TEST';
169 if (-f 'TEST' && -f 'harness' && -d '../lib') {
170     @INC = '../lib';
171 }
172
173 die "You need to run \"make test_prep\" first to set things up.\n"
174   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
175
176 # check leakage for embedders
177 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
178 # check existence of all symbols
179 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
180
181 $ENV{EMXSHELL} = 'sh';        # For OS/2
182
183 if ($show_elapsed_time) { require Time::HiRes }
184 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
185
186 # Roll your own File::Find!
187 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
188 sub _find_files {
189     my($patt, @dirs) = @_;
190     for my $dir (@dirs) {
191         opendir DIR, $dir or die "Trouble opening $dir: $!";
192         foreach my $f (sort { $a cmp $b } readdir DIR) {
193             next if $skip{$f};
194
195             my $fullpath = "$dir/$f";
196             
197             if (-d $fullpath) {
198                 _find_files($patt, $fullpath);
199             } elsif ($f =~ /$patt/) {
200                 push @found, $fullpath;
201             }
202         }
203     }
204     @found;
205 }
206
207
208 # Scan the text of the test program to find switches and special options
209 # we might need to apply.
210 sub _scan_test {
211     my($test, $type) = @_;
212
213     open(my $script, "<", $test) or die "Can't read $test.\n";
214     my $first_line = <$script>;
215
216     $first_line =~ tr/\0//d if $::with_utf16;
217
218     my $switch = "";
219     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
220         $switch = "-$1";
221     } else {
222         if ($::taintwarn) {
223             # not all tests are expected to pass with this option
224             $switch = '-t';
225         } else {
226             $switch = '';
227         }
228     }
229
230     my $file_opts = "";
231     if ($type eq 'deparse') {
232         # Look for #line directives which change the filename
233         while (<$script>) {
234             $file_opts = $file_opts . ",-f$3$4"
235               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
236         }
237     }
238
239     close $script;
240
241     my $perl = $^O eq 'MSWin32' ? '.\perl' : './perl';
242     my $lib  = '../lib';
243     my $run_dir;
244     my $return_dir;
245
246     $test =~ /^(.+)\/[^\/]+/;
247     my $dir = $1;
248     my $testswitch = $dir_to_switch{$dir};
249     if (!defined $testswitch) {
250         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
251             $run_dir = $1;
252             $return_dir = '../../t';
253             $lib = '../../lib';
254             $perl = '../../t/perl';
255             $testswitch = "-I../.. -MTestInit=U2T";
256             if ($2 eq 'cpan' || $2 eq 'dist') {
257                 if($abs{$run_dir}) {
258                     $testswitch = $testswitch . ',A';
259                 }
260                 if ($temp_no_core{$run_dir}) {
261                     $testswitch = $testswitch . ',NC';
262                 }
263                 if($temp_needs_dot{$run_dir}) {
264                     $testswitch = $testswitch . ',DOT';
265                 }
266             }
267         } elsif ($test =~ m!^\.\./lib!) {
268             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
269         } else {
270             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
271         }
272     }
273
274     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
275
276     my %options = (
277         perl => $perl,
278         lib => $lib,
279         test => $test,
280         run_dir => $run_dir,
281         return_dir => $return_dir,
282         testswitch => $testswitch,
283         utf8 => $utf8,
284         file => $file_opts,
285         switch => $switch,
286     );
287
288     return \%options;
289 }
290
291 sub _cmd {
292     my($options, $type) = @_;
293
294     my $test = $options->{test};
295
296     my $cmd;
297     if ($type eq 'deparse') {
298         my $perl = "$options->{perl} $options->{testswitch}";
299         my $lib = $options->{lib};
300
301         $cmd = (
302           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
303           "-l$::deparse_opts$options->{file} ".
304           "$test > $test.dp ".
305           "&& $perl $options->{switch} -I$lib $test.dp"
306         );
307     }
308     elsif ($type eq 'perl') {
309         my $perl = $options->{perl};
310         my $redir = $^O eq 'VMS' ? '2>&1' : '';
311
312         if ($ENV{PERL_VALGRIND}) {
313             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
314             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
315             if ($options->{run_dir}) {
316                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
317             }
318             my $vg_opts = $ENV{VG_OPTS}
319                //   "--log-file=$Valgrind_Log "
320                   . "--suppressions=$perl_supp --leak-check=yes "
321                   . "--leak-resolution=high --show-reachable=yes "
322                   . "--num-callers=50 --track-origins=yes";
323             # Force logging if not asked for (so cachegrind reporting works below)
324             if ($vg_opts !~ /--log-file/) {
325                 $vg_opts = "--log-file=$Valgrind_Log $vg_opts";
326             }
327             $perl = "$valgrind_exe $vg_opts $perl";
328         }
329
330         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
331         $cmd = $perl . _quote_args($args) . " $test $redir";
332     }
333     return $cmd;
334 }
335
336 sub _before_fork {
337     my ($options) = @_;
338
339     if ($options->{run_dir}) {
340         my $run_dir = $options->{run_dir};
341         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
342     }
343
344     # Remove previous valgrind output otherwise it will interfere
345     my $test = $options->{test};
346
347     (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
348
349     if ($ENV{PERL_VALGRIND} && -e $Valgrind_Log) {
350         unlink $Valgrind_Log
351             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
352     }
353
354     return;
355 }
356
357 sub _after_fork {
358     my ($options) = @_;
359
360     if ($options->{return_dir}) {
361         my $return_dir = $options->{return_dir};
362         chdir $return_dir
363            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
364     }
365
366     return;
367 }
368
369 sub _run_test {
370     my ($test, $type) = @_;
371
372     my $options = _scan_test($test, $type);
373     # $test might have changed if we're in ext/Foo, so don't use it anymore
374     # from now on. Use $options->{test} instead.
375
376     _before_fork($options);
377
378     my $cmd = _cmd($options, $type);
379
380     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
381
382     _after_fork($options);
383
384     # Our environment may force us to use UTF-8, but we can't be sure that
385     # anything we're reading from will be generating (well formed) UTF-8
386     # This may not be the best way - possibly we should unset ${^OPEN} up
387     # top?
388     binmode $results;
389
390     return $results;
391 }
392
393 sub _quote_args {
394     my ($args) = @_;
395     my $argstring = '';
396
397     foreach (split(/\s+/,$args)) {
398        # In VMS protect with doublequotes because otherwise
399        # DCL will lowercase -- unless already doublequoted.
400        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
401        $argstring = $argstring . ' ' . $_;
402     }
403     return $argstring;
404 }
405
406 sub _populate_hash {
407     return unless defined $_[0];
408     return map {$_, 1} split /\s+/, $_[0];
409 }
410
411 sub _tests_from_manifest {
412     my ($extensions, $known_extensions) = @_;
413     my %skip;
414     my %extensions = _populate_hash($extensions);
415     my %known_extensions = _populate_hash($known_extensions);
416
417     foreach (keys %known_extensions) {
418         $skip{$_} = 1 unless $extensions{$_};
419     }
420
421     my @results;
422     my $mani = '../MANIFEST';
423     if (open(MANI, $mani)) {
424         while (<MANI>) {
425             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
426                 my $t = $1;
427                 my $extension = $2;
428
429                 # XXX Generates way too many error lines currently.  Skip for
430                 # v5.22
431                 next if $t =~ /^cpan/ && ord("A") != 65;
432
433                 if (!$::core || $t =~ m!^lib/[a-z]!) {
434                     if (defined $extension) {
435                         $extension =~ s!/t(:?/\S+)*$!!;
436                         # XXX Do I want to warn that I'm skipping these?
437                         next if $skip{$extension};
438                         my $flat_extension = $extension;
439                         $flat_extension =~ s!-!/!g;
440                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
441                     }
442                     my $path = "../$t";
443                     push @results, $path;
444                     $::path_to_name{$path} = $t;
445                 }
446             }
447         }
448         close MANI;
449     } else {
450         warn "$0: cannot open $mani: $!\n";
451     }
452     return @results;
453 }
454
455 unless (@ARGV) {
456     # base first, as TEST bails out if that can't run
457     # then comp, to validate that require works
458     # then run, to validate that -M works
459     # then we know we can -MTestInit for everything else, making life simpler
460     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro perf)) {
461         _find_tests($dir);
462     }
463     unless ($::core) {
464         _find_tests('porting');
465         _find_tests("lib"); 
466     }
467     # Config.pm may be broken for make minitest. And this is only a refinement
468     # for skipping tests on non-default builds, so it is allowed to fail.
469     # What we want to to is make a list of extensions which we did not build.
470     my $configsh = '../config.sh';
471     my ($extensions, $known_extensions);
472     if (-f $configsh) {
473         open FH, $configsh or die "Can't open $configsh: $!";
474         while (<FH>) {
475             if (/^extensions=['"](.*)['"]$/) {
476                 $extensions = $1;
477             }
478             elsif (/^known_extensions=['"](.*)['"]$/) {
479                 $known_extensions = $1;
480             }
481         }
482         if (!defined $known_extensions) {
483             warn "No known_extensions line found in $configsh";
484         }
485         if (!defined $extensions) {
486             warn "No extensions line found in $configsh";
487         }
488     }
489     # The "complex" constructions of list return from a subroutine, and push of
490     # a list, might fail if perl is really hosed, but they aren't needed for
491     # make minitest, and the building of extensions will likely also fail if
492     # something is that badly wrong.
493     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
494     unless ($::core) {
495         _find_tests('japh') if $::torture;
496         _find_tests('benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
497         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
498     }
499 }
500
501 if ($::deparse) {
502     _testprogs('deparse', '',   @ARGV);
503 }
504 elsif ($::with_utf16) {
505     for my $e (0, 1) {
506         for my $b (0, 1) {
507             print STDERR "# ENDIAN $e BOM $b\n";
508             my @UARGV;
509             for my $a (@ARGV) {
510                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
511                 my $f = $e ? "v" : "n";
512                 push @UARGV, $u;
513                 unlink($u);
514                 if (open(A, $a)) {
515                     if (open(U, ">$u")) {
516                         print U pack("$f", 0xFEFF) if $b;
517                         while (<A>) {
518                             print U pack("$f*", unpack("C*", $_));
519                         }
520                         close(U);
521                     }
522                     close(A);
523                 }
524             }
525             _testprogs('perl', '', @UARGV);
526             unlink(@UARGV);
527         }
528     }
529 }
530 else {
531     _testprogs('perl',    '',   @ARGV);
532 }
533
534 sub _testprogs {
535     my ($type, $args, @tests) = @_;
536
537     print <<'EOT' if ($type eq 'deparse');
538 ------------------------------------------------------------------------------
539 TESTING DEPARSER
540 ------------------------------------------------------------------------------
541 EOT
542
543     $::bad_files = 0;
544
545     foreach my $t (@tests) {
546       unless (exists $::path_to_name{$t}) {
547         my $tname = "t/$t";
548         $::path_to_name{$t} = $tname;
549       }
550     }
551     my $maxlen = 0;
552     foreach (@::path_to_name{@tests}) {
553         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
554         my $len = length ;
555         $maxlen = $len if $len > $maxlen;
556     }
557     # + 3 : we want three dots between the test name and the "ok"
558     my $dotdotdot = $maxlen + 3 ;
559     my $grind_ct = 0;           # count of non-empty valgrind reports
560     my $total_files = @tests;
561     my $good_files = 0;
562     my $tested_files  = 0;
563     my $totmax = 0;
564     my %failed_tests;
565     my $toolnm;         # valgrind, cachegrind, perf
566
567     while (my $test = shift @tests) {
568         my ($test_start_time, @starttimes) = 0;
569         if ($show_elapsed_time) {
570             $test_start_time = Time::HiRes::time();
571             # times() reports usage by TEST, but we want usage of each
572             # testprog it calls, so record accumulated times now,
573             # subtract them out afterwards.  Ideally, we'd take times
574             # in BEGIN/END blocks (giving better visibility of self vs
575             # children of each testprog), but that would require some
576             # IPC to send results back here, or a completely different
577             # collection scheme (Storable isn't tuned for incremental use)
578             @starttimes = times;
579         }
580         if ($test =~ /^$/) {
581             next;
582         }
583         if ($type eq 'deparse' && $test =~ $deparse_skips) {
584             next;
585         }
586         my $te = $::path_to_name{$test} . '.'
587                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
588
589         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
590             print $te;
591             $te = '';
592         }
593
594         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
595
596         my $results = _run_test($test, $type);
597
598         my $failure;
599         my $next = 0;
600         my $seen_leader = 0;
601         my $seen_ok = 0;
602         my $trailing_leader = 0;
603         my $max;
604         my %todo;
605         while (<$results>) {
606             next if /^\s*$/; # skip blank lines
607             if (/^1..$/ && ($^O eq 'VMS')) {
608                 # VMS pipe bug inserts blank lines.
609                 my $l2 = <$results>;
610                 if ($l2 =~ /^\s*$/) {
611                     $l2 = <$results>;
612                 }
613                 $_ = '1..' . $l2;
614             }
615             if ($::verbose) {
616                 print $_;
617             }
618             unless (/^\#/) {
619                 if ($trailing_leader) {
620                     # shouldn't be anything following a postfix 1..n
621                     $failure = 'FAILED--extra output after trailing 1..n';
622                     last;
623                 }
624                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
625                     if ($seen_leader) {
626                         $failure = 'FAILED--seen duplicate leader';
627                         last;
628                     }
629                     $max = $1;
630                     %todo = map { $_ => 1 } split / /, $3 if $3;
631                     $totmax = $totmax + $max;
632                     $tested_files = $tested_files + 1;
633                     if ($seen_ok) {
634                         # 1..n appears at end of file
635                         $trailing_leader = 1;
636                         if ($next != $max) {
637                             $failure = "FAILED--expected $max tests, saw $next";
638                             last;
639                         }
640                     }
641                     else {
642                         $next = 0;
643                     }
644                     $seen_leader = 1;
645                 }
646                 else {
647                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
648                         unless ($seen_leader) {
649                             unless ($seen_ok) {
650                                 $next = 0;
651                             }
652                         }
653                         $seen_ok = 1;
654                         $next = $next + 1;
655                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
656                         $num = $next unless $num;
657
658                         if ($num == $next) {
659
660                             # SKIP is essentially the same as TODO for t/TEST
661                             # this still conforms to TAP:
662                             # http://testanything.org/wiki/index.php/TAP_specification
663                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
664                             $istodo = 1 if $todo{$num};
665
666                             if( $not && !$istodo ) {
667                                 $failure = "FAILED at test $num";
668                                 last;
669                             }
670                         }
671                         else {
672                             $failure ="FAILED--expected test $next, saw test $num";
673                             last;
674                         }
675                     }
676                     elsif (/^Bail out!\s*(.*)/i) { # magic words
677                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
678                     }
679                     else {
680                         # module tests are allowed extra output,
681                         # because Test::Harness allows it
682                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
683                         $failure = "FAILED--unexpected output at test $next";
684                         last;
685                     }
686                 }
687             }
688         }
689         my  @junk = <$results>;  # dump remaining output to prevent SIGPIPE
690                                  # (so far happens only on os390)
691         close $results;
692         undef @junk;
693
694         if (not defined $failure) {
695             $failure = 'FAILED--no leader found' unless $seen_leader;
696         }
697
698         _check_valgrind(\$toolnm, \$grind_ct, \$test);
699
700         if ($type eq 'deparse' && !$ENV{KEEP_DEPARSE_FILES}) {
701             unlink "./$test.dp";
702         }
703         if (not defined $failure and $next != $max) {
704             $failure="FAILED--expected $max tests, saw $next";
705         }
706
707         if( !defined $failure  # don't mask a test failure
708             and $? )
709         {
710             $failure = "FAILED--non-zero wait status: $?";
711         }
712
713         # Deparse? Should it have passed or failed?
714         if ($type eq 'deparse' && $test =~ $deparse_failures) {
715             if (!$failure) {
716                 # Wait, it didn't fail? Great news! Tell someone!
717                 $failure = "FAILED--all tests passed but test should have failed";
718             } else {
719                 # Bah, still failing. Mask it.
720                 print "${te}skipped\n";
721                 $tested_files = $tested_files - 1;
722                 next;
723             }
724         }
725
726         if (defined $failure) {
727             print "${te}$failure\n";
728             $::bad_files = $::bad_files + 1;
729             if ($test =~ /^base/ && ! defined &DynaLoader::boot_DynaLoader) {
730                 # Die if running under minitest (no DynaLoader).  Otherwise
731                 # keep going, as  we know that Perl basically works, or we
732                 # would not have been able to actually compile it all the way.
733                 die "Failed a basic test ($test) under minitest -- cannot continue.\n";
734             }
735             $failed_tests{$test} = 1;
736         }
737         else {
738             if ($max) {
739                 my ($elapsed, $etms) = ("", 0);
740                 if ( $show_elapsed_time ) {
741                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
742                     $elapsed = sprintf(" %8.0f ms", $etms);
743
744                     my (@endtimes) = times;
745                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
746                     splice @endtimes, 0, 2;    # drop self/harness times
747                     $_ *= 1000 for @endtimes;  # and scale to ms
748                     $timings{$test} = [$etms,@endtimes];
749                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
750                 }
751                 print "${te}ok$elapsed\n";
752                 $good_files = $good_files + 1;
753             }
754             else {
755                 print "${te}skipped\n";
756                 $tested_files = $tested_files - 1;
757             }
758         }
759     } # while tests
760
761     if ($::bad_files == 0) {
762         if ($good_files) {
763             print "All tests successful.\n";
764             # XXX add mention of 'perlbug -ok' ?
765         }
766         else {
767             die "FAILED--no tests were run for some reason.\n";
768         }
769     }
770     else {
771         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
772         my $s = $::bad_files == 1 ? "" : "s";
773         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
774         for my $test ( sort keys %failed_tests ) {
775             print "\t$test\n";
776         }
777         warn <<'SHRDLU_1';
778 ### Since not all tests were successful, you may want to run some of
779 ### them individually and examine any diagnostic messages they produce.
780 ### See the INSTALL document's section on "make test".
781 SHRDLU_1
782         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
783 ### You have a good chance to get more information by running
784 ###   ./perl harness
785 ### in the 't' directory since most (>=80%) of the tests succeeded.
786 SHRDLU_2
787         if (eval {require Config; import Config; 1}) {
788             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
789                 warn <<SHRDLU_3;
790 ### You may have to set your dynamic library search path,
791 ### $p, to point to the build directory:
792 SHRDLU_3
793                 if (exists $ENV{$p} && $ENV{$p} ne '') {
794                     warn <<SHRDLU_4a;
795 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
796 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
797 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
798 SHRDLU_4a
799                 } else {
800                     warn <<SHRDLU_4b;
801 ###   setenv $p `pwd`; cd t; ./perl harness
802 ###   $p=`pwd`; export $p; cd t; ./perl harness
803 ###   export $p=`pwd`; cd t; ./perl harness
804 SHRDLU_4b
805                 }
806                 warn <<SHRDLU_5;
807 ### for csh-style shells, like tcsh; or for traditional/modern
808 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
809 SHRDLU_5
810             }
811         }
812     }
813     printf "Elapsed: %d sec\n", time() - $t0;
814     my ($user,$sys,$cuser,$csys) = times;
815     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
816                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
817     print "$tot\n";
818     if ($good_files) {
819         if (-d $show_elapsed_time) {
820             # HARNESS_TIMER = <a-directory>.  Save timings etc to
821             # storable file there.  NB: the test cds to ./t/, so
822             # relative path must account for that, ie ../../perf
823             # points to dir next to source tree.
824             require Storable;
825             my @dt = localtime;
826             $dt[5] += 1900; $dt[4] += 1; # fix year, month
827             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
828             Storable::store({ perf => \%timings,
829                               gather_conf_platform_info(),
830                               total => $tot,
831                             }, $fn);
832             print "wrote storable file: $fn\n";
833         }
834     }
835
836     _cleanup_valgrind(\$toolnm, \$grind_ct);
837 }
838 exit ($::bad_files != 0);
839
840 # Collect platform, config data that should allow comparing
841 # performance data between different machines.  With enough data,
842 # and/or clever statistical analysis, it should be possible to
843 # determine the effect of config choices, more memory, etc
844
845 sub gather_conf_platform_info {
846     # currently rather quick & dirty, and subject to change
847     # for both content and format.
848     require Config;
849     my (%conf, @platform) = ();
850     $conf{$_} = $Config::Config{$_} for
851         grep /cc|git|config_arg\d+/, keys %Config::Config;
852     if (-f '/proc/cpuinfo') {
853         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
854         @platform = grep /name|cpu/, <$fh>;
855         chomp $_ for @platform;
856     }
857     unshift @platform, $^O;
858
859     return (
860         conf => \%conf,
861         platform => {cpu => \@platform,
862                      mem => [ grep s/\s+/ /,
863                               grep chomp, `free` ],
864                      load => [ grep chomp, `uptime` ],
865         },
866         host => (grep chomp, `hostname -f`),
867         version => '0.03', # bump for conf, platform, or data collection changes
868         );
869 }
870
871 sub _check_valgrind {
872     return unless $ENV{PERL_VALGRIND};
873
874     my ($toolnm, $grind_ct, $test) = @_;
875
876     $$toolnm = $ENV{VALGRIND};
877     $$toolnm =~ s|.*/||;  # keep basename
878     my @valgrind;       # gets content of file
879     if (-e $Valgrind_Log) {
880         if (open(V, $Valgrind_Log)) {
881             @valgrind = <V>;
882             close V;
883         } else {
884             warn "$0: Failed to open '$Valgrind_Log': $!\n";
885         }
886     }
887     if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $$toolnm =~ /(perf)/) {
888         $$toolnm = $1;
889         if ($$toolnm eq 'perf') {
890             # append perfs subcommand, not just stat
891             my ($sub) = split /\s/, $ENV{VG_OPTS};
892             $$toolnm .= "-$sub";
893         }
894         if (rename $Valgrind_Log, "$$test.$$toolnm") {
895             $$grind_ct++;
896         } else {
897             warn "$0: Failed to create '$$test.$$toolnm': $!\n";
898         }
899     }
900     elsif (@valgrind) {
901         my $leaks = 0;
902         my $errors = 0;
903         for my $i (0..$#valgrind) {
904             local $_ = $valgrind[$i];
905             if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
906                 $errors = $errors + $1;   # there may be multiple error summaries
907             } elsif (/^==\d+== LEAK SUMMARY:/) {
908                 for my $off (1 .. 4) {
909                     if ($valgrind[$i+$off] =~
910                         /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
911                             $leaks = $leaks + $1;
912                     }
913                 }
914             }
915         }
916         if ($errors or $leaks) {
917             if (rename $Valgrind_Log, "$$test.valgrind") {
918                 $$grind_ct = $$grind_ct + 1;
919             } else {
920                 warn "$0: Failed to create '$$test.valgrind': $!\n";
921             }
922         }
923     } else {
924         # Quiet wasn't asked for? Something may be amiss
925         if ($ENV{VG_OPTS} && $ENV{VG_OPTS} !~ /(^|\s)(-q|--quiet)(\s|$)/) {
926             warn "No valgrind output?\n";
927         }
928     }
929     if (-e $Valgrind_Log) {
930         unlink $Valgrind_Log
931             or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
932     }
933 }
934
935 sub _cleanup_valgrind {
936     return unless $ENV{PERL_VALGRIND};
937
938     my ($toolnm, $grind_ct) = @_;
939     my $s = $$grind_ct == 1 ? '' : 's';
940     print "$$grind_ct valgrind report$s created.\n", ;
941     if ($$toolnm eq 'cachegrind') {
942         # cachegrind leaves a lot of cachegrind.out.$pid litter
943         # around the tree, find and delete them
944         unlink _find_files('cachegrind.out.\d+$',
945                      qw ( ../t ../cpan ../ext ../dist/ ));
946     }
947 }
948
949 # Generate regexps of known bad filenames / skips from Porting/deparse-skips.txt
950 my $in;
951
952 sub _process_deparse_config {
953     my @deparse_failures;
954     my @deparse_skips;
955
956     my $f = '../Porting/deparse-skips.txt';
957
958     my $skips;
959     if (!open($skips, '<', $f)) {
960         warn "Failed to find $f: $!\n";
961         return;
962     }
963
964     while(<$skips>) {
965         if (/__DEPARSE_FAILURES__/) {
966             $in = \@deparse_failures; next;
967         } elsif (/__DEPARSE_SKIPS__/) {
968             $in = \@deparse_skips; next;
969         } elsif (!$in) {
970             next;
971         }
972
973         s/#.*$//; # Kill comments
974         s/\s+$//; # And trailing whitespace
975
976         next unless $_;
977
978         push @$in, $_;
979     }
980
981     for my $f (@deparse_failures, @deparse_skips) {
982         if ($f =~ m|/$|) { # Dir? Skip everything below it
983             $f = qr/\Q$f\E.*/;
984         } else {
985             $f = qr/\Q$f\E/;
986         }
987     }
988
989     $deparse_failures = join('|', @deparse_failures);
990     $deparse_failures = qr/^(?:$deparse_failures)$/;
991
992     $deparse_skips = join('|', @deparse_skips);
993     $deparse_skips = qr/^(?:$deparse_skips)$/;
994 }
995
996 # ex: set ts=8 sts=4 sw=4 noet: