This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
[perl5db] Remove leading ampersands in sub call.
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     @cmdfhs
631     $CommandSet
632     $CreateTTY
633     $DBGR
634     @dbline
635     $dbline
636     %dbline
637     $dieLevel
638     $filename
639     $hist
640     $histfile
641     $histsize
642     $IN
643     $inhibit_exit
644     @ini_INC
645     $ini_warn
646     $maxtrace
647     $od
648     $onetimedumpDepth
649     @options
650     $osingle
651     $otrace
652     $pager
653     $post
654     %postponed
655     $prc
656     $pre
657     $pretype
658     $psh
659     @RememberOnROptions
660     $remoteport
661     @res
662     $rl
663     @saved
664     $signalLevel
665     $sub
666     $term
667     $usercontext
668     $warnLevel
669 );
670
671 our (
672     $evalarg,
673     $frame,
674     $ImmediateStop,
675     $line,
676     $onetimeDump,
677     %option,
678     $OUT,
679     $packname,
680     $signal,
681     $single,
682     $start,
683     %sub,
684     $subname,
685     $trace,
686     $window,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 foreach my $k (keys (%INC)) {
897     share(\$main::{'_<'.$filename}) if defined $filename;
898 };
899
900 # Command-line + PERLLIB:
901 # Save the contents of @INC before they are modified elsewhere.
902 @ini_INC = @INC;
903
904 # This was an attempt to clear out the previous values of various
905 # trapped errors. Apparently it didn't help. XXX More info needed!
906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
907
908 # We set these variables to safe values. We don't want to blindly turn
909 # off warnings, because other packages may still want them.
910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
911                                    # (local $^W cannot help - other packages!).
912
913 # Default to not exiting when program finishes; print the return
914 # value when the 'r' command is used to return from a subroutine.
915 $inhibit_exit = $option{PrintRet} = 1;
916
917 use vars qw($trace_to_depth);
918
919 # Default to 1E9 so it won't be limited to a certain recursion depth.
920 $trace_to_depth = 1E9;
921
922 =head1 OPTION PROCESSING
923
924 The debugger's options are actually spread out over the debugger itself and
925 C<dumpvar.pl>; some of these are variables to be set, while others are
926 subs to be called with a value. To try to make this a little easier to
927 manage, the debugger uses a few data structures to define what options
928 are legal and how they are to be processed.
929
930 First, the C<@options> array defines the I<names> of all the options that
931 are to be accepted.
932
933 =cut
934
935 @options = qw(
936   CommandSet   HistFile      HistSize
937   hashDepth    arrayDepth    dumpDepth
938   DumpDBFiles  DumpPackages  DumpReused
939   compactDump  veryCompact   quote
940   HighBit      undefPrint    globPrint
941   PrintRet     UsageOnly     frame
942   AutoTrace    TTY           noTTY
943   ReadLine     NonStop       LineInfo
944   maxTraceLen  recallCommand ShellBang
945   pager        tkRunning     ornaments
946   signalLevel  warnLevel     dieLevel
947   inhibit_exit ImmediateStop bareStringify
948   CreateTTY    RemotePort    windowSize
949   DollarCaretP
950 );
951
952 @RememberOnROptions = qw(DollarCaretP);
953
954 =pod
955
956 Second, C<optionVars> lists the variables that each option uses to save its
957 state.
958
959 =cut
960
961 use vars qw(%optionVars);
962
963 %optionVars = (
964     hashDepth     => \$dumpvar::hashDepth,
965     arrayDepth    => \$dumpvar::arrayDepth,
966     CommandSet    => \$CommandSet,
967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
968     DumpPackages  => \$dumpvar::dumpPackages,
969     DumpReused    => \$dumpvar::dumpReused,
970     HighBit       => \$dumpvar::quoteHighBit,
971     undefPrint    => \$dumpvar::printUndef,
972     globPrint     => \$dumpvar::globPrint,
973     UsageOnly     => \$dumpvar::usageOnly,
974     CreateTTY     => \$CreateTTY,
975     bareStringify => \$dumpvar::bareStringify,
976     frame         => \$frame,
977     AutoTrace     => \$trace,
978     inhibit_exit  => \$inhibit_exit,
979     maxTraceLen   => \$maxtrace,
980     ImmediateStop => \$ImmediateStop,
981     RemotePort    => \$remoteport,
982     windowSize    => \$window,
983     HistFile      => \$histfile,
984     HistSize      => \$histsize,
985 );
986
987 =pod
988
989 Third, C<%optionAction> defines the subroutine to be called to process each
990 option.
991
992 =cut
993
994 use vars qw(%optionAction);
995
996 %optionAction = (
997     compactDump   => \&dumpvar::compactDump,
998     veryCompact   => \&dumpvar::veryCompact,
999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(@truehist %postponed_file @typeahead);
1384
1385 our (@hist);
1386
1387 sub _restore_shared_globals_after_restart
1388 {
1389     @hist          = get_list('PERLDB_HIST');
1390     %break_on_load = get_list("PERLDB_ON_LOAD");
1391     %postponed     = get_list("PERLDB_POSTPONE");
1392
1393     share(@hist);
1394     share(@truehist);
1395     share(%break_on_load);
1396     share(%postponed);
1397 }
1398
1399 sub _restore_breakpoints_and_actions {
1400
1401     my @had_breakpoints = get_list("PERLDB_VISITED");
1402
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     return;
1419 }
1420
1421 sub _restore_options_after_restart
1422 {
1423     my %options_map = get_list("PERLDB_OPT");
1424
1425     while ( my ( $opt, $val ) = each %options_map ) {
1426         $val =~ s/[\\\']/\\$1/g;
1427         parse_options("$opt'$val'");
1428     }
1429
1430     return;
1431 }
1432
1433 sub _restore_globals_after_restart
1434 {
1435     # restore original @INC
1436     @INC     = get_list("PERLDB_INC");
1437     @ini_INC = @INC;
1438
1439     # return pre/postprompt actions and typeahead buffer
1440     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1441     $pre       = [ get_list("PERLDB_PRE") ];
1442     $post      = [ get_list("PERLDB_POST") ];
1443     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1444
1445     return;
1446 }
1447
1448
1449 if ( exists $ENV{PERLDB_RESTART} ) {
1450
1451     # We're restarting, so we don't need the flag that says to restart anymore.
1452     delete $ENV{PERLDB_RESTART};
1453
1454     # $restart = 1;
1455     _restore_shared_globals_after_restart();
1456
1457     _restore_breakpoints_and_actions();
1458
1459     # restore options
1460     _restore_options_after_restart();
1461
1462     _restore_globals_after_restart();
1463 } ## end if (exists $ENV{PERLDB_RESTART...
1464
1465 =head2 SETTING UP THE TERMINAL
1466
1467 Now, we'll decide how the debugger is going to interact with the user.
1468 If there's no TTY, we set the debugger to run non-stop; there's not going
1469 to be anyone there to enter commands.
1470
1471 =cut
1472
1473 use vars qw($notty $console $tty $LINEINFO);
1474 use vars qw($lineinfo $doccmd);
1475
1476 our ($runnonstop);
1477
1478 if ($notty) {
1479     $runnonstop = 1;
1480     share($runnonstop);
1481 }
1482
1483 =pod
1484
1485 If there is a TTY, we have to determine who it belongs to before we can
1486 proceed. If this is a slave editor or graphical debugger (denoted by
1487 the first command-line switch being '-emacs'), we shift this off and
1488 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1489
1490 =cut
1491
1492 else {
1493
1494     # Is Perl being run from a slave editor or graphical debugger?
1495     # If so, don't use readline, and set $slave_editor = 1.
1496     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1497         $rl = 0;
1498         shift(@main::ARGV);
1499     }
1500
1501     #require Term::ReadLine;
1502
1503 =pod
1504
1505 We then determine what the console should be on various systems:
1506
1507 =over 4
1508
1509 =item * Cygwin - We use C<stdin> instead of a separate device.
1510
1511 =cut
1512
1513     if ( $^O eq 'cygwin' ) {
1514
1515         # /dev/tty is binary. use stdin for textmode
1516         undef $console;
1517     }
1518
1519 =item * Unix - use C</dev/tty>.
1520
1521 =cut
1522
1523     elsif ( -e "/dev/tty" ) {
1524         $console = "/dev/tty";
1525     }
1526
1527 =item * Windows or MSDOS - use C<con>.
1528
1529 =cut
1530
1531     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1532         $console = "con";
1533     }
1534
1535 =item * VMS - use C<sys$command>.
1536
1537 =cut
1538
1539     else {
1540
1541         # everything else is ...
1542         $console = "sys\$command";
1543     }
1544
1545 =pod
1546
1547 =back
1548
1549 Several other systems don't use a specific console. We C<undef $console>
1550 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1551 with a slave editor, Epoc).
1552
1553 =cut
1554
1555     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1556
1557         # /dev/tty is binary. use stdin for textmode
1558         $console = undef;
1559     }
1560
1561     if ( $^O eq 'NetWare' ) {
1562
1563         # /dev/tty is binary. use stdin for textmode
1564         $console = undef;
1565     }
1566
1567     # In OS/2, we need to use STDIN to get textmode too, even though
1568     # it pretty much looks like Unix otherwise.
1569     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1570     {    # In OS/2
1571         $console = undef;
1572     }
1573
1574     # EPOC also falls into the 'got to use STDIN' camp.
1575     if ( $^O eq 'epoc' ) {
1576         $console = undef;
1577     }
1578
1579 =pod
1580
1581 If there is a TTY hanging around from a parent, we use that as the console.
1582
1583 =cut
1584
1585     $console = $tty if defined $tty;
1586
1587 =head2 SOCKET HANDLING
1588
1589 The debugger is capable of opening a socket and carrying out a debugging
1590 session over the socket.
1591
1592 If C<RemotePort> was defined in the options, the debugger assumes that it
1593 should try to start a debugging session on that port. It builds the socket
1594 and then tries to connect the input and output filehandles to it.
1595
1596 =cut
1597
1598     # Handle socket stuff.
1599
1600     if ( defined $remoteport ) {
1601
1602         # If RemotePort was defined in the options, connect input and output
1603         # to the socket.
1604         $IN = $OUT = connect_remoteport();
1605     } ## end if (defined $remoteport)
1606
1607 =pod
1608
1609 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1610 this is probably a situation where multiple debuggers are running (for example,
1611 a backticked command that starts up another debugger). We create a new IN and
1612 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1613 and if we can.
1614
1615 =cut
1616
1617     # Non-socket.
1618     else {
1619
1620         # Two debuggers running (probably a system or a backtick that invokes
1621         # the debugger itself under the running one). create a new IN and OUT
1622         # filehandle, and do the necessary mojo to create a new tty if we
1623         # know how, and we can.
1624         create_IN_OUT(4) if $CreateTTY & 4;
1625         if ($console) {
1626
1627             # If we have a console, check to see if there are separate ins and
1628             # outs to open. (They are assumed identical if not.)
1629
1630             my ( $i, $o ) = split /,/, $console;
1631             $o = $i unless defined $o;
1632
1633             # read/write on in, or just read, or read on STDIN.
1634             open( IN,      "+<$i" )
1635               || open( IN, "<$i" )
1636               || open( IN, "<&STDIN" );
1637
1638             # read/write/create/clobber out, or write/create/clobber out,
1639             # or merge with STDERR, or merge with STDOUT.
1640                  open( OUT, "+>$o" )
1641               || open( OUT, ">$o" )
1642               || open( OUT, ">&STDERR" )
1643               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1644
1645         } ## end if ($console)
1646         elsif ( not defined $console ) {
1647
1648             # No console. Open STDIN.
1649             open( IN, "<&STDIN" );
1650
1651             # merge with STDERR, or with STDOUT.
1652             open( OUT,      ">&STDERR" )
1653               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1654             $console = 'STDIN/OUT';
1655         } ## end elsif (not defined $console)
1656
1657         # Keep copies of the filehandles so that when the pager runs, it
1658         # can close standard input without clobbering ours.
1659         if ($console or (not defined($console))) {
1660             $IN = \*IN;
1661             $OUT = \*OUT;
1662         }
1663     } ## end elsif (from if(defined $remoteport))
1664
1665     # Unbuffer DB::OUT. We need to see responses right away.
1666     $OUT->autoflush(1);
1667
1668     # Line info goes to debugger output unless pointed elsewhere.
1669     # Pointing elsewhere makes it possible for slave editors to
1670     # keep track of file and position. We have both a filehandle
1671     # and a I/O description to keep track of.
1672     $LINEINFO = $OUT     unless defined $LINEINFO;
1673     $lineinfo = $console unless defined $lineinfo;
1674     # share($LINEINFO); # <- unable to share globs
1675     share($lineinfo);   #
1676
1677 =pod
1678
1679 To finish initialization, we show the debugger greeting,
1680 and then call the C<afterinit()> subroutine if there is one.
1681
1682 =cut
1683
1684     # Show the debugger greeting.
1685     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1686     unless ($runnonstop) {
1687         local $\ = '';
1688         local $, = '';
1689         if ( $term_pid eq '-1' ) {
1690             print $OUT "\nDaughter DB session started...\n";
1691         }
1692         else {
1693             print $OUT "\nLoading DB routines from $header\n";
1694             print $OUT (
1695                 "Editor support ",
1696                 $slave_editor ? "enabled" : "available", ".\n"
1697             );
1698             print $OUT
1699 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1700         } ## end else [ if ($term_pid eq '-1')
1701     } ## end unless ($runnonstop)
1702 } ## end else [ if ($notty)
1703
1704 # XXX This looks like a bug to me.
1705 # Why copy to @ARGS and then futz with @args?
1706 @ARGS = @ARGV;
1707 # for (@args) {
1708     # Make sure backslashes before single quotes are stripped out, and
1709     # keep args unless they are numeric (XXX why?)
1710     # s/\'/\\\'/g;                      # removed while not justified understandably
1711     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1712 # }
1713
1714 # If there was an afterinit() sub defined, call it. It will get
1715 # executed in our scope, so it can fiddle with debugger globals.
1716 if ( defined &afterinit ) {    # May be defined in $rcfile
1717     afterinit();
1718 }
1719
1720 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1721 use vars qw($I_m_init);
1722
1723 $I_m_init = 1;
1724
1725 ############################################################ Subroutines
1726
1727 =head1 SUBROUTINES
1728
1729 =head2 DB
1730
1731 This gigantic subroutine is the heart of the debugger. Called before every
1732 statement, its job is to determine if a breakpoint has been reached, and
1733 stop if so; read commands from the user, parse them, and execute
1734 them, and then send execution off to the next statement.
1735
1736 Note that the order in which the commands are processed is very important;
1737 some commands earlier in the loop will actually alter the C<$cmd> variable
1738 to create other commands to be executed later. This is all highly I<optimized>
1739 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1740 see what's happening in any given command.
1741
1742 =cut
1743
1744 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1745
1746 use vars qw(
1747     $action
1748     %alias
1749     $cmd
1750     $fall_off_end
1751     $file
1752     $filename_ini
1753     $finished
1754     %had_breakpoints
1755     $level
1756     $max
1757     $package
1758     $sh
1759     $try
1760     $end
1761 );
1762
1763 our (
1764     $doret,
1765     $incr,
1766     $laststep,
1767     $rc,
1768     $stack_depth,
1769     @stack,
1770     @to_watch,
1771     @old_watch,
1772 );
1773
1774 sub _DB__determine_if_we_should_break
1775 {
1776     # if we have something here, see if we should break.
1777     # $stop is lexical and local to this block - $action on the other hand
1778     # is global.
1779     my $stop;
1780
1781     if ( $dbline{$line}
1782         && _is_breakpoint_enabled($filename, $line)
1783         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1784     {
1785
1786         # Stop if the stop criterion says to just stop.
1787         if ( $stop eq '1' ) {
1788             $signal |= 1;
1789         }
1790
1791         # It's a conditional stop; eval it in the user's context and
1792         # see if we should stop. If so, remove the one-time sigil.
1793         elsif ($stop) {
1794             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1795             DB::eval();
1796             # If the breakpoint is temporary, then delete its enabled status.
1797             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1798                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1799             }
1800         }
1801     } ## end if ($dbline{$line} && ...
1802 }
1803
1804 sub _DB__is_finished {
1805     if ($finished and $level <= 1) {
1806         end_report();
1807         return 1;
1808     }
1809     else {
1810         return;
1811     }
1812 }
1813
1814 sub _DB__read_next_cmd
1815 {
1816     my ($tid) = @_;
1817
1818     # We have a terminal, or can get one ...
1819     if (!$term) {
1820         setterm();
1821     }
1822
1823     # ... and it belogs to this PID or we get one for this PID ...
1824     if ($term_pid != $$) {
1825         resetterm(1);
1826     }
1827
1828     # ... and we got a line of command input ...
1829     $cmd = DB::readline(
1830         "$pidprompt $tid DB"
1831         . ( '<' x $level )
1832         . ( $#hist + 1 )
1833         . ( '>' x $level ) . " "
1834     );
1835
1836     return defined($cmd);
1837 }
1838
1839 sub _DB__trim_command_and_return_first_component {
1840     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1841     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1842
1843     $cmd =~ m{\A(\S*)};
1844     return $1;
1845 }
1846
1847 sub _DB__handle_f_command {
1848     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1849         $file =~ s/\s+$//;
1850
1851         # help for no arguments (old-style was return from sub).
1852         if ( !$file ) {
1853             print $OUT
1854             "The old f command is now the r command.\n";    # hint
1855             print $OUT "The new f command switches filenames.\n";
1856             next CMD;
1857         } ## end if (!$file)
1858
1859         # if not in magic file list, try a close match.
1860         if ( !defined $main::{ '_<' . $file } ) {
1861             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1862                 {
1863                     $try = substr( $try, 2 );
1864                     print $OUT "Choosing $try matching '$file':\n";
1865                     $file = $try;
1866                 }
1867             } ## end if (($try) = grep(m#^_<.*$file#...
1868         } ## end if (!defined $main::{ ...
1869
1870         # If not successfully switched now, we failed.
1871         if ( !defined $main::{ '_<' . $file } ) {
1872             print $OUT "No file matching '$file' is loaded.\n";
1873             next CMD;
1874         }
1875
1876         # We switched, so switch the debugger internals around.
1877         elsif ( $file ne $filename ) {
1878             *dbline   = $main::{ '_<' . $file };
1879             $max      = $#dbline;
1880             $filename = $file;
1881             $start    = 1;
1882             $cmd      = "l";
1883         } ## end elsif ($file ne $filename)
1884
1885         # We didn't switch; say we didn't.
1886         else {
1887             print $OUT "Already in $file.\n";
1888             next CMD;
1889         }
1890     }
1891
1892     return;
1893 }
1894
1895 sub _DB__handle_dot_command {
1896     my ($obj) = @_;
1897
1898     # . command.
1899     if ($cmd eq '.') {
1900         $incr = -1;    # stay at current line
1901
1902         # Reset everything to the old location.
1903         $start    = $line;
1904         $filename = $filename_ini;
1905         *dbline   = $main::{ '_<' . $filename };
1906         $max      = $#dbline;
1907
1908         # Now where are we?
1909         print_lineinfo($obj->position());
1910         next CMD;
1911     }
1912
1913     return;
1914 }
1915
1916 sub _DB__handle_y_command {
1917     my ($obj) = @_;
1918
1919     if (my ($match_level, $match_vars)
1920         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1921
1922         # See if we've got the necessary support.
1923         eval { require PadWalker; PadWalker->VERSION(0.08) }
1924             or &warn(
1925             $@ =~ /locate/
1926             ? "PadWalker module not found - please install\n"
1927             : $@
1928         )
1929             and next CMD;
1930
1931         # Load up dumpvar if we don't have it. If we can, that is.
1932         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1933         defined &main::dumpvar
1934             or print $OUT "dumpvar.pl not available.\n"
1935             and next CMD;
1936
1937         # Got all the modules we need. Find them and print them.
1938         my @vars = split( ' ', $match_vars || '' );
1939
1940         # Find the pad.
1941         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1942
1943         # Oops. Can't find it.
1944         $@ and $@ =~ s/ at .*//, &warn($@), next CMD;
1945
1946         # Show the desired vars with dumplex().
1947         my $savout = select($OUT);
1948
1949         # Have dumplex dump the lexicals.
1950         dumpvar::dumplex( $_, $h->{$_},
1951             defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1952             @vars )
1953         for sort keys %$h;
1954         select($savout);
1955         next CMD;
1956     }
1957 }
1958
1959 sub _DB__handle_c_command {
1960     my ($obj) = @_;
1961
1962     if (my ($new_i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
1963
1964         $obj->i_cmd($new_i);
1965
1966         # Hey, show's over. The debugged program finished
1967         # executing already.
1968         next CMD if _DB__is_finished();
1969
1970         # Capture the place to put a one-time break.
1971         $subname = $obj->i_cmd;
1972
1973         #  Probably not needed, since we finish an interactive
1974         #  sub-session anyway...
1975         # local $filename = $filename;
1976         # local *dbline = *dbline; # XXX Would this work?!
1977         #
1978         # The above question wonders if localizing the alias
1979         # to the magic array works or not. Since it's commented
1980         # out, we'll just leave that to speculation for now.
1981
1982         # If the "subname" isn't all digits, we'll assume it
1983         # is a subroutine name, and try to find it.
1984         if ( $subname =~ /\D/ ) {    # subroutine name
1985             # Qualify it to the current package unless it's
1986             # already qualified.
1987             $subname = $package . "::" . $subname
1988             unless $subname =~ /::/;
1989
1990             # find_sub will return "file:line_number" corresponding
1991             # to where the subroutine is defined; we call find_sub,
1992             # break up the return value, and assign it in one
1993             # operation.
1994             ( $file, $new_i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
1995
1996             # Force the line number to be numeric.
1997             $obj->i_cmd($new_i + 0);
1998
1999             # If we got a line number, we found the sub.
2000             if ($obj->i_cmd) {
2001
2002                 # Switch all the debugger's internals around so
2003                 # we're actually working with that file.
2004                 $filename = $file;
2005                 *dbline   = $main::{ '_<' . $filename };
2006
2007                 # Mark that there's a breakpoint in this file.
2008                 $had_breakpoints{$filename} |= 1;
2009
2010                 # Scan forward to the first executable line
2011                 # after the 'sub whatever' line.
2012                 $max = $#dbline;
2013                 my $ii = $obj->i_cmd;
2014                 ++$ii while $dbline[$ii] == 0 && $ii < $max;
2015                 $obj->i_cmd($ii);
2016             } ## end if ($i)
2017
2018             # We didn't find a sub by that name.
2019             else {
2020                 print $OUT "Subroutine $subname not found.\n";
2021                 next CMD;
2022             }
2023         } ## end if ($subname =~ /\D/)
2024
2025         # At this point, either the subname was all digits (an
2026         # absolute line-break request) or we've scanned through
2027         # the code following the definition of the sub, looking
2028         # for an executable, which we may or may not have found.
2029         #
2030         # If $i (which we set $subname from) is non-zero, we
2031         # got a request to break at some line somewhere. On
2032         # one hand, if there wasn't any real subroutine name
2033         # involved, this will be a request to break in the current
2034         # file at the specified line, so we have to check to make
2035         # sure that the line specified really is breakable.
2036         #
2037         # On the other hand, if there was a subname supplied, the
2038         # preceding block has moved us to the proper file and
2039         # location within that file, and then scanned forward
2040         # looking for the next executable line. We have to make
2041         # sure that one was found.
2042         #
2043         # On the gripping hand, we can't do anything unless the
2044         # current value of $i points to a valid breakable line.
2045         # Check that.
2046         if ($obj->i_cmd) {
2047
2048             # Breakable?
2049             if ( $dbline[$obj->i_cmd] == 0 ) {
2050                 print $OUT "Line " . $obj->i_cmd . " not breakable.\n";
2051                 next CMD;
2052             }
2053
2054             # Yes. Set up the one-time-break sigil.
2055             $dbline{$obj->i_cmd} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2056             _enable_breakpoint_temp_enabled_status($filename, $obj->i_cmd);
2057         } ## end if ($i)
2058
2059         # Turn off stack tracing from here up.
2060         for my $i (0 .. $stack_depth) {
2061             $stack[ $i ] &= ~1;
2062         }
2063         last CMD;
2064     }
2065
2066     return;
2067 }
2068
2069 sub _DB__handle_forward_slash_command {
2070     my ($obj) = @_;
2071
2072     # The pattern as a string.
2073     use vars qw($inpat);
2074
2075     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2076
2077         # Remove the final slash.
2078         $inpat =~ s:([^\\])/$:$1:;
2079
2080         # If the pattern isn't null ...
2081         if ( $inpat ne "" ) {
2082
2083             # Turn of warn and die procesing for a bit.
2084             local $SIG{__DIE__};
2085             local $SIG{__WARN__};
2086
2087             # Create the pattern.
2088             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2089             if ( $@ ne "" ) {
2090
2091                 # Oops. Bad pattern. No biscuit.
2092                 # Print the eval error and go back for more
2093                 # commands.
2094                 print $OUT "$@";
2095                 next CMD;
2096             }
2097             $obj->pat($inpat);
2098         } ## end if ($inpat ne "")
2099
2100         # Set up to stop on wrap-around.
2101         $end = $start;
2102
2103         # Don't move off the current line.
2104         $incr = -1;
2105
2106         my $pat = $obj->pat;
2107
2108         # Done in eval so nothing breaks if the pattern
2109         # does something weird.
2110         eval
2111         {
2112             no strict q/vars/;
2113             for (;;) {
2114                 # Move ahead one line.
2115                 ++$start;
2116
2117                 # Wrap if we pass the last line.
2118                 $start = 1 if ($start > $max);
2119
2120                 # Stop if we have gotten back to this line again,
2121                 last if ($start == $end);
2122
2123                 # A hit! (Note, though, that we are doing
2124                 # case-insensitive matching. Maybe a qr//
2125                 # expression would be better, so the user could
2126                 # do case-sensitive matching if desired.
2127                 if ($dbline[$start] =~ m/$pat/i) {
2128                     if ($slave_editor) {
2129                         # Handle proper escaping in the slave.
2130                         print $OUT "\032\032$filename:$start:0\n";
2131                     }
2132                     else {
2133                         # Just print the line normally.
2134                         print $OUT "$start:\t",$dbline[$start],"\n";
2135                     }
2136                     # And quit since we found something.
2137                     last;
2138                 }
2139             }
2140         };
2141
2142         if ($@) {
2143             warn $@;
2144         }
2145
2146         # If we wrapped, there never was a match.
2147         if ( $start == $end ) {
2148             print {$OUT} "/$pat/: not found\n";
2149         }
2150         next CMD;
2151     }
2152
2153     return;
2154 }
2155
2156 sub _DB__handle_question_mark_command {
2157     my ($obj) = @_;
2158
2159     # ? - backward pattern search.
2160     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2161
2162         # Get the pattern, remove trailing question mark.
2163         $inpat =~ s:([^\\])\?$:$1:;
2164
2165         # If we've got one ...
2166         if ( $inpat ne "" ) {
2167
2168             # Turn off die & warn handlers.
2169             local $SIG{__DIE__};
2170             local $SIG{__WARN__};
2171             eval '$inpat =~ m' . "\a$inpat\a";
2172
2173             if ( $@ ne "" ) {
2174
2175                 # Ouch. Not good. Print the error.
2176                 print $OUT $@;
2177                 next CMD;
2178             }
2179             $obj->pat($inpat);
2180         } ## end if ($inpat ne "")
2181
2182         # Where we are now is where to stop after wraparound.
2183         $end = $start;
2184
2185         # Don't move away from this line.
2186         $incr = -1;
2187
2188         my $pat = $obj->pat;
2189         # Search inside the eval to prevent pattern badness
2190         # from killing us.
2191         eval {
2192             no strict q/vars/;
2193             for (;;) {
2194                 # Back up a line.
2195                 --$start;
2196
2197                 # Wrap if we pass the first line.
2198
2199                 $start = $max if ($start <= 0);
2200
2201                 # Quit if we get back where we started,
2202                 last if ($start == $end);
2203
2204                 # Match?
2205                 if ($dbline[$start] =~ m/$pat/i) {
2206                     if ($slave_editor) {
2207                         # Yep, follow slave editor requirements.
2208                         print $OUT "\032\032$filename:$start:0\n";
2209                     }
2210                     else {
2211                         # Yep, just print normally.
2212                         print $OUT "$start:\t",$dbline[$start],"\n";
2213                     }
2214
2215                     # Found, so done.
2216                     last;
2217                 }
2218             }
2219         };
2220
2221         # Say we failed if the loop never found anything,
2222         if ( $start == $end ) {
2223             print {$OUT} "?$pat?: not found\n";
2224         }
2225         next CMD;
2226     }
2227
2228     return;
2229 }
2230
2231 sub DB {
2232
2233     # lock the debugger and get the thread id for the prompt
2234     lock($DBGR);
2235     my $tid;
2236     my $position;
2237     my ($prefix, $after, $infix);
2238     my $pat;
2239     my $explicit_stop;
2240
2241     if ($ENV{PERL5DB_THREADED}) {
2242         $tid = eval { "[".threads->tid."]" };
2243     }
2244
2245     my $i;
2246
2247     my $obj = DB::Obj->new(
2248         {
2249             position => \$position,
2250             prefix => \$prefix,
2251             after => \$after,
2252             explicit_stop => \$explicit_stop,
2253             infix => \$infix,
2254             i_cmd => \$i,
2255             pat => \$pat,
2256         },
2257     );
2258
2259     $obj->_DB_on_init__initialize_globals(@_);
2260
2261     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2262     # The code being debugged may have altered them.
2263     &save;
2264
2265     # Since DB::DB gets called after every line, we can use caller() to
2266     # figure out where we last were executing. Sneaky, eh? This works because
2267     # caller is returning all the extra information when called from the
2268     # debugger.
2269     local ( $package, $filename, $line ) = caller;
2270     $filename_ini = $filename;
2271
2272     # set up the context for DB::eval, so it can properly execute
2273     # code on behalf of the user. We add the package in so that the
2274     # code is eval'ed in the proper package (not in the debugger!).
2275     local $usercontext = _calc_usercontext($package);
2276
2277     # Create an alias to the active file magical array to simplify
2278     # the code here.
2279     local (*dbline) = $main::{ '_<' . $filename };
2280
2281     # Last line in the program.
2282     $max = $#dbline;
2283
2284     _DB__determine_if_we_should_break(@_);
2285
2286     # Preserve the current stop-or-not, and see if any of the W
2287     # (watch expressions) has changed.
2288     my $was_signal = $signal;
2289
2290     # If we have any watch expressions ...
2291     $obj->_DB__handle_watch_expressions(@_);
2292
2293 =head2 C<watchfunction()>
2294
2295 C<watchfunction()> is a function that can be defined by the user; it is a
2296 function which will be run on each entry to C<DB::DB>; it gets the
2297 current package, filename, and line as its parameters.
2298
2299 The watchfunction can do anything it likes; it is executing in the
2300 debugger's context, so it has access to all of the debugger's internal
2301 data structures and functions.
2302
2303 C<watchfunction()> can control the debugger's actions. Any of the following
2304 will cause the debugger to return control to the user's program after
2305 C<watchfunction()> executes:
2306
2307 =over 4
2308
2309 =item *
2310
2311 Returning a false value from the C<watchfunction()> itself.
2312
2313 =item *
2314
2315 Altering C<$single> to a false value.
2316
2317 =item *
2318
2319 Altering C<$signal> to a false value.
2320
2321 =item *
2322
2323 Turning off the C<4> bit in C<$trace> (this also disables the
2324 check for C<watchfunction()>. This can be done with
2325
2326     $trace &= ~4;
2327
2328 =back
2329
2330 =cut
2331
2332     # If there's a user-defined DB::watchfunction, call it with the
2333     # current package, filename, and line. The function executes in
2334     # the DB:: package.
2335     if ( $trace & 4 ) {    # User-installed watch
2336         return
2337           if watchfunction( $package, $filename, $line )
2338           and not $single
2339           and not $was_signal
2340           and not( $trace & ~4 );
2341     } ## end if ($trace & 4)
2342
2343     # Pick up any alteration to $signal in the watchfunction, and
2344     # turn off the signal now.
2345     $was_signal = $signal;
2346     $signal     = 0;
2347
2348 =head2 GETTING READY TO EXECUTE COMMANDS
2349
2350 The debugger decides to take control if single-step mode is on, the
2351 C<t> command was entered, or the user generated a signal. If the program
2352 has fallen off the end, we set things up so that entering further commands
2353 won't cause trouble, and we say that the program is over.
2354
2355 =cut
2356
2357     # Make sure that we always print if asked for explicitly regardless
2358     # of $trace_to_depth .
2359     $explicit_stop = ($single || $was_signal);
2360
2361     # Check to see if we should grab control ($single true,
2362     # trace set appropriately, or we got a signal).
2363     if ( $explicit_stop || ( $trace & 1 ) ) {
2364         $obj->_DB__grab_control(@_);
2365     } ## end if ($single || ($trace...
2366
2367 =pod
2368
2369 If there's an action to be executed for the line we stopped at, execute it.
2370 If there are any preprompt actions, execute those as well.
2371
2372 =cut
2373
2374     # If there's an action, do it now.
2375     if ($action) {
2376         $evalarg = $action;
2377         DB::eval();
2378     }
2379
2380     # Are we nested another level (e.g., did we evaluate a function
2381     # that had a breakpoint in it at the debugger prompt)?
2382     if ( $single || $was_signal ) {
2383
2384         # Yes, go down a level.
2385         local $level = $level + 1;
2386
2387         # Do any pre-prompt actions.
2388         foreach $evalarg (@$pre) {
2389             DB::eval();
2390         }
2391
2392         # Complain about too much recursion if we passed the limit.
2393         if ($single & 4) {
2394             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2395         }
2396
2397         # The line we're currently on. Set $incr to -1 to stay here
2398         # until we get a command that tells us to advance.
2399         $start = $line;
2400         $incr  = -1;      # for backward motion.
2401
2402         # Tack preprompt debugger actions ahead of any actual input.
2403         @typeahead = ( @$pretype, @typeahead );
2404
2405 =head2 WHERE ARE WE?
2406
2407 XXX Relocate this section?
2408
2409 The debugger normally shows the line corresponding to the current line of
2410 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2411 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2412
2413 C<$incr> controls by how many lines the I<current> line should move forward
2414 after a command is executed. If set to -1, this indicates that the I<current>
2415 line shouldn't change.
2416
2417 C<$start> is the I<current> line. It is used for things like knowing where to
2418 move forwards or backwards from when doing an C<L> or C<-> command.
2419
2420 C<$max> tells the debugger where the last line of the current file is. It's
2421 used to terminate loops most often.
2422
2423 =head2 THE COMMAND LOOP
2424
2425 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2426 in two parts:
2427
2428 =over 4
2429
2430 =item *
2431
2432 The outer part of the loop, starting at the C<CMD> label. This loop
2433 reads a command and then executes it.
2434
2435 =item *
2436
2437 The inner part of the loop, starting at the C<PIPE> label. This part
2438 is wholly contained inside the C<CMD> block and only executes a command.
2439 Used to handle commands running inside a pager.
2440
2441 =back
2442
2443 So why have two labels to restart the loop? Because sometimes, it's easier to
2444 have a command I<generate> another command and then re-execute the loop to do
2445 the new command. This is faster, but perhaps a bit more convoluted.
2446
2447 =cut
2448
2449         # The big command dispatch loop. It keeps running until the
2450         # user yields up control again.
2451         #
2452         # If we have a terminal for input, and we get something back
2453         # from readline(), keep on processing.
2454         my $piped;
2455         my $selected;
2456
2457       CMD:
2458         while (_DB__read_next_cmd($tid))
2459         {
2460
2461             share($cmd);
2462             # ... try to execute the input as debugger commands.
2463
2464             # Don't stop running.
2465             $single = 0;
2466
2467             # No signal is active.
2468             $signal = 0;
2469
2470             # Handle continued commands (ending with \):
2471             if ($cmd =~ s/\\\z/\n/) {
2472                 $cmd .= DB::readline("  cont: ");
2473                 redo CMD;
2474             }
2475
2476 =head4 The null command
2477
2478 A newline entered by itself means I<re-execute the last command>. We grab the
2479 command out of C<$laststep> (where it was recorded previously), and copy it
2480 back into C<$cmd> to be executed below. If there wasn't any previous command,
2481 we'll do nothing below (no command will match). If there was, we also save it
2482 in the command history and fall through to allow the command parsing to pick
2483 it up.
2484
2485 =cut
2486
2487             # Empty input means repeat the last command.
2488             if ($cmd eq '') {
2489                 $cmd = $laststep;
2490             }
2491             chomp($cmd);    # get rid of the annoying extra newline
2492             if (length($cmd) >= 2) {
2493                 push( @hist, $cmd );
2494             }
2495             push( @truehist, $cmd );
2496             share(@hist);
2497             share(@truehist);
2498
2499             # This is a restart point for commands that didn't arrive
2500             # via direct user input. It allows us to 'redo PIPE' to
2501             # re-execute command processing without reading a new command.
2502           PIPE: {
2503                 $i = _DB__trim_command_and_return_first_component();
2504
2505 =head3 COMMAND ALIASES
2506
2507 The debugger can create aliases for commands (these are stored in the
2508 C<%alias> hash). Before a command is executed, the command loop looks it up
2509 in the alias hash and substitutes the contents of the alias for the command,
2510 completely replacing it.
2511
2512 =cut
2513
2514                 # See if there's an alias for the command, and set it up if so.
2515                 if ( $alias{$i} ) {
2516
2517                     # Squelch signal handling; we want to keep control here
2518                     # if something goes loco during the alias eval.
2519                     local $SIG{__DIE__};
2520                     local $SIG{__WARN__};
2521
2522                     # This is a command, so we eval it in the DEBUGGER's
2523                     # scope! Otherwise, we can't see the special debugger
2524                     # variables, or get to the debugger's subs. (Well, we
2525                     # _could_, but why make it even more complicated?)
2526                     eval "\$cmd =~ $alias{$i}";
2527                     if ($@) {
2528                         local $\ = '';
2529                         print $OUT "Couldn't evaluate '$i' alias: $@";
2530                         next CMD;
2531                     }
2532                 } ## end if ($alias{$i})
2533
2534 =head3 MAIN-LINE COMMANDS
2535
2536 All of these commands work up to and after the program being debugged has
2537 terminated.
2538
2539 =head4 C<q> - quit
2540
2541 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2542 try to execute further, cleaning any restart-related stuff out of the
2543 environment, and executing with the last value of C<$?>.
2544
2545 =cut
2546
2547                 if ($cmd eq 'q') {
2548                     $fall_off_end = 1;
2549                     clean_ENV();
2550                     exit $?;
2551                 }
2552
2553 =head4 C<t> - trace [n]
2554
2555 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2556 If level is specified, set C<$trace_to_depth>.
2557
2558 =cut
2559
2560                 $obj->_handle_t_command;
2561
2562 =head4 C<S> - list subroutines matching/not matching a pattern
2563
2564 Walks through C<%sub>, checking to see whether or not to print the name.
2565
2566 =cut
2567
2568                 $obj->_handle_S_command;
2569
2570 =head4 C<X> - list variables in current package
2571
2572 Since the C<V> command actually processes this, just change this to the
2573 appropriate C<V> command and fall through.
2574
2575 =head4 C<V> - list variables
2576
2577 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2578
2579 =cut
2580
2581                 $obj->_handle_V_command_and_X_command;
2582
2583 =head4 C<x> - evaluate and print an expression
2584
2585 Hands the expression off to C<DB::eval>, setting it up to print the value
2586 via C<dumpvar.pl> instead of just printing it directly.
2587
2588 =cut
2589
2590                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2591                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2592
2593                     # handle special  "x 3 blah" syntax XXX propagate
2594                     # doc back to special variables.
2595                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2596                         $onetimedumpDepth = $1;
2597                     }
2598                 }
2599
2600 =head4 C<m> - print methods
2601
2602 Just uses C<DB::methods> to determine what methods are available.
2603
2604 =cut
2605
2606                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2607                     methods($1);
2608                     next CMD;
2609                 }
2610
2611                 # m expr - set up DB::eval to do the work
2612                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2613                     $onetimeDump = 'methods';   #  method output gets used there
2614                 }
2615
2616 =head4 C<f> - switch files
2617
2618 =cut
2619
2620                 _DB__handle_f_command();
2621
2622 =head4 C<.> - return to last-executed line.
2623
2624 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2625 and then we look up the line in the magical C<%dbline> hash.
2626
2627 =cut
2628
2629         _DB__handle_dot_command($obj);
2630
2631 =head4 C<-> - back one window
2632
2633 We change C<$start> to be one window back; if we go back past the first line,
2634 we set it to be the first line. We ser C<$incr> to put us back at the
2635 currently-executing line, and then put a C<l $start +> (list one window from
2636 C<$start>) in C<$cmd> to be executed later.
2637
2638 =cut
2639
2640                 # - - back a window.
2641                 $obj->_handle_dash_command;
2642
2643 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2644
2645 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2646 problems, most notably that the default case of several commands destroying
2647 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2648 retain the old commands for those who were used to using them or who preferred
2649 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2650 deal with them instead of processing them in-line.
2651
2652 =cut
2653
2654                 # All of these commands were remapped in perl 5.8.0;
2655                 # we send them off to the secondary dispatcher (see below).
2656                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2657                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2658                     next CMD;
2659                 }
2660
2661 =head4 C<y> - List lexicals in higher scope
2662
2663 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2664 above the current one and then displays then using C<dumpvar.pl>.
2665
2666 =cut
2667
2668                 _DB__handle_y_command($obj);
2669
2670 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2671
2672 All of the commands below this point don't work after the program being
2673 debugged has ended. All of them check to see if the program has ended; this
2674 allows the commands to be relocated without worrying about a 'line of
2675 demarcation' above which commands can be entered anytime, and below which
2676 they can't.
2677
2678 =head4 C<n> - single step, but don't trace down into subs
2679
2680 Done by setting C<$single> to 2, which forces subs to execute straight through
2681 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2682 so a null command knows what to re-execute.
2683
2684 =cut
2685
2686                 # n - next
2687                 $obj->_handle_n_command;
2688
2689 =head4 C<s> - single-step, entering subs
2690
2691 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2692 subs. Also saves C<s> as C<$lastcmd>.
2693
2694 =cut
2695
2696                 $obj->_handle_s_command;
2697
2698 =head4 C<c> - run continuously, setting an optional breakpoint
2699
2700 Most of the code for this command is taken up with locating the optional
2701 breakpoint, which is either a subroutine name or a line number. We set
2702 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2703 in this and all call levels above this one.
2704
2705 =cut
2706
2707                 # c - start continuous execution.
2708                 _DB__handle_c_command($obj);
2709
2710 =head4 C<r> - return from a subroutine
2711
2712 For C<r> to work properly, the debugger has to stop execution again
2713 immediately after the return is executed. This is done by forcing
2714 single-stepping to be on in the call level above the current one. If
2715 we are printing return values when a C<r> is executed, set C<$doret>
2716 appropriately, and force us out of the command loop.
2717
2718 =cut
2719
2720                 # r - return from the current subroutine.
2721                 $obj->_handle_r_command;
2722
2723 =head4 C<T> - stack trace
2724
2725 Just calls C<DB::print_trace>.
2726
2727 =cut
2728
2729                 $obj->_handle_T_command;
2730
2731 =head4 C<w> - List window around current line.
2732
2733 Just calls C<DB::cmd_w>.
2734
2735 =cut
2736
2737                 $obj->_handle_w_command;
2738
2739 =head4 C<W> - watch-expression processing.
2740
2741 Just calls C<DB::cmd_W>.
2742
2743 =cut
2744
2745                 $obj->_handle_W_command;
2746
2747 =head4 C</> - search forward for a string in the source
2748
2749 We take the argument and treat it as a pattern. If it turns out to be a
2750 bad one, we return the error we got from trying to C<eval> it and exit.
2751 If not, we create some code to do the search and C<eval> it so it can't
2752 mess us up.
2753
2754 =cut
2755
2756                 _DB__handle_forward_slash_command($obj);
2757
2758 =head4 C<?> - search backward for a string in the source
2759
2760 Same as for C</>, except the loop runs backwards.
2761
2762 =cut
2763
2764                 _DB__handle_question_mark_command($obj);
2765
2766 =head4 C<$rc> - Recall command
2767
2768 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2769 that the terminal supports history). It find the the command required, puts it
2770 into C<$cmd>, and redoes the loop to execute it.
2771
2772 =cut
2773
2774                 # $rc - recall command.
2775                 $obj->_handle_rc_recall_command;
2776
2777 =head4 C<$sh$sh> - C<system()> command
2778
2779 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2780 C<STDOUT> from getting messed up.
2781
2782 =cut
2783
2784                 # $sh$sh - run a shell command (if it's all ASCII).
2785                 # Can't run shell commands with Unicode in the debugger, hmm.
2786                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2787
2788                     # System it.
2789                     &system($arg);
2790                     next CMD;
2791                 }
2792
2793 =head4 C<$rc I<pattern> $rc> - Search command history
2794
2795 Another command to manipulate C<@hist>: this one searches it with a pattern.
2796 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2797
2798 =cut
2799
2800                 # $rc pattern $rc - find a command in the history.
2801                 if (my ($arg) = $cmd =~ /\A$rc([^$rc].*)\z/) {
2802
2803                     # Create the pattern to use.
2804                     $pat = "^$arg";
2805
2806                     # Toss off last entry if length is >1 (and it always is).
2807                     pop(@hist) if length($cmd) > 1;
2808
2809                     # Look backward through the history.
2810                     for ( $i = $#hist ; $i ; --$i ) {
2811                         # Stop if we find it.
2812                         last if $hist[$i] =~ /$pat/;
2813                     }
2814
2815                     if ( !$i ) {
2816
2817                         # Never found it.
2818                         print $OUT "No such command!\n\n";
2819                         next CMD;
2820                     }
2821
2822                     # Found it. Put it in the buffer, print it, and process it.
2823                     $cmd = $hist[$i];
2824                     print $OUT $cmd, "\n";
2825                     redo CMD;
2826                 }
2827
2828 =head4 C<$sh> - Invoke a shell
2829
2830 Uses C<DB::system> to invoke a shell.
2831
2832 =cut
2833
2834                 # $sh - start a shell.
2835                 if ($cmd =~ /\A$sh\z/) {
2836
2837                     # Run the user's shell. If none defined, run Bourne.
2838                     # We resume execution when the shell terminates.
2839                     &system( $ENV{SHELL} || "/bin/sh" );
2840                     next CMD;
2841                 }
2842
2843 =head4 C<$sh I<command>> - Force execution of a command in a shell
2844
2845 Like the above, but the command is passed to the shell. Again, we use
2846 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2847
2848 =cut
2849
2850                 # $sh command - start a shell and run a command in it.
2851                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2852
2853                     # XXX: using csh or tcsh destroys sigint retvals!
2854                     #&system($1);  # use this instead
2855
2856                     # use the user's shell, or Bourne if none defined.
2857                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2858                     next CMD;
2859                 }
2860
2861 =head4 C<H> - display commands in history
2862
2863 Prints the contents of C<@hist> (if any).
2864
2865 =cut
2866
2867                 if ($cmd =~ /\AH\b\s*\*/) {
2868                     @hist = @truehist = ();
2869                     print $OUT "History cleansed\n";
2870                     next CMD;
2871                 }
2872
2873                 if (my ($num)
2874                     = $cmd =~ /\AH\b\s*(?:-(\d+))?/) {
2875
2876                     # Anything other than negative numbers is ignored by
2877                     # the (incorrect) pattern, so this test does nothing.
2878                     $end = $num ? ( $#hist - $num ) : 0;
2879
2880                     # Set to the minimum if less than zero.
2881                     $hist = 0 if $hist < 0;
2882
2883                     # Start at the end of the array.
2884                     # Stay in while we're still above the ending value.
2885                     # Tick back by one each time around the loop.
2886                     for ( $i = $#hist ; $i > $end ; $i-- ) {
2887
2888                         # Print the command  unless it has no arguments.
2889                         print $OUT "$i: ", $hist[$i], "\n"
2890                           unless $hist[$i] =~ /^.?$/;
2891                     }
2892                     next CMD;
2893                 }
2894
2895 =head4 C<man, doc, perldoc> - look up documentation
2896
2897 Just calls C<runman()> to print the appropriate document.
2898
2899 =cut
2900
2901                 # man, perldoc, doc - show manual pages.
2902                 if (my ($man_page)
2903                     = $cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
2904                     runman($man_page);
2905                     next CMD;
2906                 }
2907
2908 =head4 C<p> - print
2909
2910 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2911 the bottom of the loop.
2912
2913 =cut
2914
2915                 my $print_cmd = 'print {$DB::OUT} ';
2916                 # p - print (no args): print $_.
2917                 if ($cmd eq 'p') {
2918                     $cmd = $print_cmd . '$_';
2919                 }
2920
2921                 # p - print the given expression.
2922                 $cmd =~ s/\Ap\b/$print_cmd /;
2923
2924 =head4 C<=> - define command alias
2925
2926 Manipulates C<%alias> to add or list command aliases.
2927
2928 =cut
2929
2930                 # = - set up a command alias.
2931                 if ($cmd =~ s/\A=\s*//) {
2932                     my @keys;
2933                     if ( length $cmd == 0 ) {
2934
2935                         # No args, get current aliases.
2936                         @keys = sort keys %alias;
2937                     }
2938                     elsif ( my ( $k, $v ) = ( $cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
2939
2940                         # Creating a new alias. $k is alias name, $v is
2941                         # alias value.
2942
2943                         # can't use $_ or kill //g state
2944                         for my $x ( $k, $v ) {
2945
2946                             # Escape "alarm" characters.
2947                             $x =~ s/\a/\\a/g;
2948                         }
2949
2950                         # Substitute key for value, using alarm chars
2951                         # as separators (which is why we escaped them in
2952                         # the command).
2953                         $alias{$k} = "s\a$k\a$v\a";
2954
2955                         # Turn off standard warn and die behavior.
2956                         local $SIG{__DIE__};
2957                         local $SIG{__WARN__};
2958
2959                         # Is it valid Perl?
2960                         unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
2961
2962                             # Nope. Bad alias. Say so and get out.
2963                             print $OUT "Can't alias $k to $v: $@\n";
2964                             delete $alias{$k};
2965                             next CMD;
2966                         }
2967
2968                         # We'll only list the new one.
2969                         @keys = ($k);
2970                     } ## end elsif (my ($k, $v) = ($cmd...
2971
2972                     # The argument is the alias to list.
2973                     else {
2974                         @keys = ($cmd);
2975                     }
2976
2977                     # List aliases.
2978                     for my $k (@keys) {
2979
2980                         # Messy metaquoting: Trim the substitution code off.
2981                         # We use control-G as the delimiter because it's not
2982                         # likely to appear in the alias.
2983                         if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
2984
2985                             # Print the alias.
2986                             print $OUT "$k\t= $1\n";
2987                         }
2988                         elsif ( defined $alias{$k} ) {
2989
2990                             # Couldn't trim it off; just print the alias code.
2991                             print $OUT "$k\t$alias{$k}\n";
2992                         }
2993                         else {
2994
2995                             # No such, dude.
2996                             print "No alias for $k\n";
2997                         }
2998                     } ## end for my $k (@keys)
2999                     next CMD;
3000                 }
3001
3002 =head4 C<source> - read commands from a file.
3003
3004 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3005 pick it up.
3006
3007 =cut
3008
3009                 # source - read commands from a file (or pipe!) and execute.
3010                 if (my ($sourced_fn) = $cmd =~ /\Asource\s+(.*\S)/) {
3011                     if ( open my $fh, $sourced_fn ) {
3012
3013                         # Opened OK; stick it in the list of file handles.
3014                         push @cmdfhs, $fh;
3015                     }
3016                     else {
3017
3018                         # Couldn't open it.
3019                         &warn("Can't execute '$sourced_fn': $!\n");
3020                     }
3021                     next CMD;
3022                 }
3023
3024                 if (my ($which_cmd, $position)
3025                     = $cmd =~ /^(enable|disable)\s+(\S+)\s*$/) {
3026
3027                     my ($fn, $line_num);
3028                     if ($position =~ m{\A\d+\z})
3029                     {
3030                         $fn = $filename;
3031                         $line_num = $position;
3032                     }
3033                     elsif (my ($new_fn, $new_line_num)
3034                         = $position =~ m{\A(.*):(\d+)\z}) {
3035                         ($fn, $line_num) = ($new_fn, $new_line_num);
3036                     }
3037                     else
3038                     {
3039                         &warn("Wrong spec for enable/disable argument.\n");
3040                     }
3041
3042                     if (defined($fn)) {
3043                         if (_has_breakpoint_data_ref($fn, $line_num)) {
3044                             _set_breakpoint_enabled_status($fn, $line_num,
3045                                 ($which_cmd eq 'enable' ? 1 : '')
3046                             );
3047                         }
3048                         else {
3049                             &warn("No breakpoint set at ${fn}:${line_num}\n");
3050                         }
3051                     }
3052
3053                     next CMD;
3054                 }
3055
3056 =head4 C<save> - send current history to a file
3057
3058 Takes the complete history, (not the shrunken version you see with C<H>),
3059 and saves it to the given filename, so it can be replayed using C<source>.
3060
3061 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3062
3063 =cut
3064
3065                 # save source - write commands to a file for later use
3066                 if (my ($new_fn) = $cmd =~ /\Asave\s*(.*)\z/) {
3067                     my $filename = $new_fn || '.perl5dbrc';    # default?
3068                     if ( open my $fh, '>', $filename ) {
3069
3070                        # chomp to remove extraneous newlines from source'd files
3071                         chomp( my @truelist =
3072                               map { m/^\s*(save|source)/ ? "#$_" : $_ }
3073                               @truehist );
3074                         print $fh join( "\n", @truelist );
3075                         print "commands saved in $file\n";
3076                     }
3077                     else {
3078                         &warn("Can't save debugger commands in '$new_fn': $!\n");
3079                     }
3080                     next CMD;
3081                 }
3082
3083 =head4 C<R> - restart
3084
3085 Restart the debugger session.
3086
3087 =head4 C<rerun> - rerun the current session
3088
3089 Return to any given position in the B<true>-history list
3090
3091 =cut
3092
3093                 # R - restart execution.
3094                 # rerun - controlled restart execution.
3095                 if (my ($cmd_cmd, $cmd_params) =
3096                     $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
3097                     my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
3098
3099                     # Close all non-system fds for a clean restart.  A more
3100                     # correct method would be to close all fds that were not
3101                     # open when the process started, but this seems to be
3102                     # hard.  See "debugger 'R'estart and open database
3103                     # connections" on p5p.
3104
3105                     my $max_fd = 1024; # default if POSIX can't be loaded
3106                     if (eval { require POSIX }) {
3107                         eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
3108                     }
3109
3110                     if (defined $max_fd) {
3111                         foreach ($^F+1 .. $max_fd-1) {
3112                             next unless open FD_TO_CLOSE, "<&=$_";
3113                             close(FD_TO_CLOSE);
3114                         }
3115                     }
3116
3117                     # And run Perl again.  We use exec() to keep the
3118                     # PID stable (and that way $ini_pids is still valid).
3119                     exec(@args) || print $OUT "exec failed: $!\n";
3120
3121                     last CMD;
3122                 }
3123
3124 =head4 C<|, ||> - pipe output through the pager.
3125
3126 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3127 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3128 pipe to the pager (restoring the output filehandles if this fails). If this
3129 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3130 set C<$signal>, sending us back into the debugger.
3131
3132 We then trim off the pipe symbols and C<redo> the command loop at the
3133 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3134 reading another.
3135
3136 =cut
3137
3138                 # || - run command in the pager, with output to DB::OUT.
3139                 if ($cmd =~ m#\A\|\|?\s*[^|]#) {
3140                     if ( $pager =~ /^\|/ ) {
3141
3142                         # Default pager is into a pipe. Redirect I/O.
3143                         open( SAVEOUT, ">&STDOUT" )
3144                           || &warn("Can't save STDOUT");
3145                         open( STDOUT, ">&OUT" )
3146                           || &warn("Can't redirect STDOUT");
3147                     } ## end if ($pager =~ /^\|/)
3148                     else {
3149
3150                         # Not into a pipe. STDOUT is safe.
3151                         open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
3152                     }
3153
3154                     # Fix up environment to record we have less if so.
3155                     fix_less();
3156
3157                     unless ( $piped = open( OUT, $pager ) ) {
3158
3159                         # Couldn't open pipe to pager.
3160                         &warn("Can't pipe output to '$pager'");
3161                         if ( $pager =~ /^\|/ ) {
3162
3163                             # Redirect I/O back again.
3164                             open( OUT, ">&STDOUT" )    # XXX: lost message
3165                               || &warn("Can't restore DB::OUT");
3166                             open( STDOUT, ">&SAVEOUT" )
3167                               || &warn("Can't restore STDOUT");
3168                             close(SAVEOUT);
3169                         } ## end if ($pager =~ /^\|/)
3170                         else {
3171
3172                             # Redirect I/O. STDOUT already safe.
3173                             open( OUT, ">&STDOUT" )    # XXX: lost message
3174                               || &warn("Can't restore DB::OUT");
3175                         }
3176                         next CMD;
3177                     } ## end unless ($piped = open(OUT,...
3178
3179                     # Set up broken-pipe handler if necessary.
3180                     $SIG{PIPE} = \&DB::catch
3181                       if $pager =~ /^\|/
3182                       && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
3183
3184                     OUT->autoflush(1);
3185                     # Save current filehandle, and put it back.
3186                     $selected = select(OUT);
3187                     # Don't put it back if pager was a pipe.
3188                     select($selected), $selected = "" unless $cmd =~ /^\|\|/;
3189
3190                     # Trim off the pipe symbols and run the command now.
3191                     $cmd =~ s#\A\|+\s*##;
3192                     redo PIPE;
3193                 }
3194
3195 =head3 END OF COMMAND PARSING
3196
3197 Anything left in C<$cmd> at this point is a Perl expression that we want to
3198 evaluate. We'll always evaluate in the user's context, and fully qualify
3199 any variables we might want to address in the C<DB> package.
3200
3201 =cut
3202
3203                 # t - turn trace on.
3204                 if ($cmd =~ s#\At\s+(\d+)?#\$DB::trace |= 1;\n#) {
3205                     my $trace_arg = $1;
3206                     $trace_to_depth = $trace_arg ? $stack_depth||0 + $1 : 1E9;
3207                 }
3208
3209                 # s - single-step. Remember the last command was 's'.
3210                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3211                     $laststep = 's';
3212                 }
3213
3214                 # n - single-step, but not into subs. Remember last command
3215                 # was 'n'.
3216                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3217                     $laststep = 'n';
3218                 }
3219
3220             }    # PIPE:
3221
3222             # Make sure the flag that says "the debugger's running" is
3223             # still on, to make sure we get control again.
3224             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3225
3226             # Run *our* eval that executes in the caller's context.
3227             DB::eval();
3228
3229             # Turn off the one-time-dump stuff now.
3230             if ($onetimeDump) {
3231                 $onetimeDump      = undef;
3232                 $onetimedumpDepth = undef;
3233             }
3234             elsif ( $term_pid == $$ ) {
3235                 eval { # May run under miniperl, when not available...
3236                     STDOUT->flush();
3237                     STDERR->flush();
3238                 };
3239
3240                 # XXX If this is the master pid, print a newline.
3241                 print {$OUT} "\n";
3242             }
3243         } ## end while (($term || &setterm...
3244
3245 =head3 POST-COMMAND PROCESSING
3246
3247 After each command, we check to see if the command output was piped anywhere.
3248 If so, we go through the necessary code to unhook the pipe and go back to
3249 our standard filehandles for input and output.
3250
3251 =cut
3252
3253         continue {    # CMD:
3254
3255             # At the end of every command:
3256             if ($piped) {
3257
3258                 # Unhook the pipe mechanism now.
3259                 if ( $pager =~ /^\|/ ) {
3260
3261                     # No error from the child.
3262                     $? = 0;
3263
3264                     # we cannot warn here: the handle is missing --tchrist
3265                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3266
3267                     # most of the $? crud was coping with broken cshisms
3268                     # $? is explicitly set to 0, so this never runs.
3269                     if ($?) {
3270                         print SAVEOUT "Pager '$pager' failed: ";
3271                         if ( $? == -1 ) {
3272                             print SAVEOUT "shell returned -1\n";
3273                         }
3274                         elsif ( $? >> 8 ) {
3275                             print SAVEOUT ( $? & 127 )
3276                               ? " (SIG#" . ( $? & 127 ) . ")"
3277                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3278                         }
3279                         else {
3280                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3281                         }
3282                     } ## end if ($?)
3283
3284                     # Reopen filehandle for our output (if we can) and
3285                     # restore STDOUT (if we can).
3286                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3287                     open( STDOUT, ">&SAVEOUT" )
3288                       || &warn("Can't restore STDOUT");
3289
3290                     # Turn off pipe exception handler if necessary.
3291                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3292
3293                     # Will stop ignoring SIGPIPE if done like nohup(1)
3294                     # does SIGINT but Perl doesn't give us a choice.
3295                 } ## end if ($pager =~ /^\|/)
3296                 else {
3297
3298                     # Non-piped "pager". Just restore STDOUT.
3299                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3300                 }
3301
3302                 # Close filehandle pager was using, restore the normal one
3303                 # if necessary,
3304                 close(SAVEOUT);
3305                 select($selected), $selected = "" unless $selected eq "";
3306
3307                 # No pipes now.
3308                 $piped = "";
3309             } ## end if ($piped)
3310         }    # CMD:
3311
3312 =head3 COMMAND LOOP TERMINATION
3313
3314 When commands have finished executing, we come here. If the user closed the
3315 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3316 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3317 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3318 The interpreter will then execute the next line and then return control to us
3319 again.
3320
3321 =cut
3322
3323         # No more commands? Quit.
3324         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3325
3326         # Evaluate post-prompt commands.
3327         foreach $evalarg (@$post) {
3328             DB::eval();
3329         }
3330     }    # if ($single || $signal)
3331
3332     # Put the user's globals back where you found them.
3333     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3334     ();
3335 } ## end sub DB
3336
3337 package DB::Obj;
3338
3339 sub new {
3340     my $class = shift;
3341
3342     my $self = bless {}, $class;
3343
3344     $self->_init(@_);
3345
3346     return $self;
3347 }
3348
3349 sub _init {
3350     my ($self, $args) = @_;
3351
3352     %{$self} = (%$self, %$args);
3353
3354     return;
3355 }
3356
3357 {
3358     no strict 'refs';
3359     foreach my $slot_name (qw(
3360         after explicit_stop infix pat position prefix i_cmd
3361         )) {
3362         my $slot = $slot_name;
3363         *{$slot} = sub {
3364             my $self = shift;
3365
3366             if (@_) {
3367                 ${ $self->{$slot} } = shift;
3368             }
3369
3370             return ${ $self->{$slot} };
3371         };
3372
3373         *{"append_to_$slot"} = sub {
3374             my $self = shift;
3375             my $s = shift;
3376
3377             return $self->$slot($self->$slot . $s);
3378         };
3379     }
3380 }
3381
3382 sub _DB_on_init__initialize_globals
3383 {
3384     my $self = shift;
3385
3386     # Check for whether we should be running continuously or not.
3387     # _After_ the perl program is compiled, $single is set to 1:
3388     if ( $single and not $second_time++ ) {
3389
3390         # Options say run non-stop. Run until we get an interrupt.
3391         if ($runnonstop) {    # Disable until signal
3392                 # If there's any call stack in place, turn off single
3393                 # stepping into subs throughout the stack.
3394             for my $i (0 .. $stack_depth) {
3395                 $stack[ $i ] &= ~1;
3396             }
3397
3398             # And we are now no longer in single-step mode.
3399             $single = 0;
3400
3401             # If we simply returned at this point, we wouldn't get
3402             # the trace info. Fall on through.
3403             # return;
3404         } ## end if ($runnonstop)
3405
3406         elsif ($ImmediateStop) {
3407
3408             # We are supposed to stop here; XXX probably a break.
3409             $ImmediateStop = 0;    # We've processed it; turn it off
3410             $signal        = 1;    # Simulate an interrupt to force
3411                                    # us into the command loop
3412         }
3413     } ## end if ($single and not $second_time...
3414
3415     # If we're in single-step mode, or an interrupt (real or fake)
3416     # has occurred, turn off non-stop mode.
3417     $runnonstop = 0 if $single or $signal;
3418
3419     return;
3420 }
3421
3422 sub _DB__handle_watch_expressions
3423 {
3424     my $self = shift;
3425
3426     if ( $trace & 2 ) {
3427         for my $n (0 .. $#to_watch) {
3428             $evalarg = $to_watch[$n];
3429             local $onetimeDump;    # Tell DB::eval() to not output results
3430
3431             # Fix context DB::eval() wants to return an array, but
3432             # we need a scalar here.
3433             my ($val) = join( "', '", DB::eval() );
3434             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3435
3436             # Did it change?
3437             if ( $val ne $old_watch[$n] ) {
3438
3439                 # Yep! Show the difference, and fake an interrupt.
3440                 $signal = 1;
3441                 print {$OUT} <<EOP;
3442 Watchpoint $n:\t$to_watch[$n] changed:
3443     old value:\t$old_watch[$n]
3444     new value:\t$val
3445 EOP
3446                 $old_watch[$n] = $val;
3447             } ## end if ($val ne $old_watch...
3448         } ## end for my $n (0 ..
3449     } ## end if ($trace & 2)
3450
3451     return;
3452 }
3453
3454 sub _my_print_lineinfo
3455 {
3456     my ($self, $i, $incr_pos) = @_;
3457
3458     if ($frame) {
3459         # Print it indented if tracing is on.
3460         DB::print_lineinfo( ' ' x $stack_depth,
3461             "$i:\t$DB::dbline[$i]" . $self->after );
3462     }
3463     else {
3464         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3465     }
3466 }
3467
3468 sub _curr_line {
3469     return $DB::dbline[$line];
3470 }
3471
3472 sub _DB__grab_control
3473 {
3474     my $self = shift;
3475
3476     # Yes, grab control.
3477     if ($slave_editor) {
3478
3479         # Tell the editor to update its position.
3480         $self->position("\032\032${DB::filename}:$line:0\n");
3481         DB::print_lineinfo($self->position());
3482     }
3483
3484 =pod
3485
3486 Special check: if we're in package C<DB::fake>, we've gone through the
3487 C<END> block at least once. We set up everything so that we can continue
3488 to enter commands and have a valid context to be in.
3489
3490 =cut
3491
3492     elsif ( $DB::package eq 'DB::fake' ) {
3493
3494         # Fallen off the end already.
3495         if (!$DB::term) {
3496             DB::setterm();
3497         }
3498
3499         DB::print_help(<<EOP);
3500 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3501 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3502 B<h q>, B<h R> or B<h o> to get additional info.
3503 EOP
3504
3505         # Set the DB::eval context appropriately.
3506         $DB::package     = 'main';
3507         $DB::usercontext = DB::_calc_usercontext($DB::package);
3508     } ## end elsif ($package eq 'DB::fake')
3509
3510 =pod
3511
3512 If the program hasn't finished executing, we scan forward to the
3513 next executable line, print that out, build the prompt from the file and line
3514 number information, and print that.
3515
3516 =cut
3517
3518     else {
3519
3520
3521         # Still somewhere in the midst of execution. Set up the
3522         #  debugger prompt.
3523         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3524                              # Perl 5 ones (sorry, we don't print Klingon
3525                              #module names)
3526
3527         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3528         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3529         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3530
3531         # Break up the prompt if it's really long.
3532         if ( length($self->prefix()) > 30 ) {
3533             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3534             $self->prefix("");
3535             $self->infix(":\t");
3536         }
3537         else {
3538             $self->infix("):\t");
3539             $self->position(
3540                 $self->prefix . $line. $self->infix
3541                 . $self->_curr_line . $self->after
3542             );
3543         }
3544
3545         # Print current line info, indenting if necessary.
3546         $self->_my_print_lineinfo($line, $self->position);
3547
3548         my $i;
3549         my $line_i = sub { return $DB::dbline[$i]; };
3550
3551         # Scan forward, stopping at either the end or the next
3552         # unbreakable line.
3553         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3554         {    #{ vi
3555
3556             # Drop out on null statements, block closers, and comments.
3557             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3558
3559             # Drop out if the user interrupted us.
3560             last if $signal;
3561
3562             # Append a newline if the line doesn't have one. Can happen
3563             # in eval'ed text, for instance.
3564             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3565
3566             # Next executable line.
3567             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3568                 . $self->after;
3569             $self->append_to_position($incr_pos);
3570             $self->_my_print_lineinfo($i, $incr_pos);
3571         } ## end for ($i = $line + 1 ; $i...
3572     } ## end else [ if ($slave_editor)
3573
3574     return;
3575 }
3576
3577 sub _handle_t_command {
3578     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3579         $trace ^= 1;
3580         local $\ = '';
3581         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3582         print {$OUT} "Trace = "
3583         . ( ( $trace & 1 )
3584             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3585             : "off" ) . "\n";
3586         next CMD;
3587     }
3588
3589     return;
3590 }
3591
3592
3593 sub _handle_S_command {
3594     if (my ($print_all_subs, $should_reverse, $Spatt)
3595         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3596         # $Spatt is the pattern (if any) to use.
3597         # Reverse scan?
3598         my $Srev     = defined $should_reverse;
3599         # No args - print all subs.
3600         my $Snocheck = !defined $print_all_subs;
3601
3602         # Need to make these sane here.
3603         local $\ = '';
3604         local $, = '';
3605
3606         # Search through the debugger's magical hash of subs.
3607         # If $nocheck is true, just print the sub name.
3608         # Otherwise, check it against the pattern. We then use
3609         # the XOR trick to reverse the condition as required.
3610         foreach $subname ( sort( keys %sub ) ) {
3611             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3612                 print $OUT $subname, "\n";
3613             }
3614         }
3615         next CMD;
3616     }
3617
3618     return;
3619 }
3620
3621 sub _handle_V_command_and_X_command {
3622
3623     $DB::cmd =~ s/^X\b/V $DB::package/;
3624
3625     # Bare V commands get the currently-being-debugged package
3626     # added.
3627     if ($DB::cmd eq "V") {
3628         $DB::cmd = "V $DB::package";
3629     }
3630
3631     # V - show variables in package.
3632     if (my ($new_packname, $new_vars_str) =
3633         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3634
3635         # Save the currently selected filehandle and
3636         # force output to debugger's filehandle (dumpvar
3637         # just does "print" for output).
3638         my $savout = select($OUT);
3639
3640         # Grab package name and variables to dump.
3641         $packname = $new_packname;
3642         my @vars     = split( ' ', $new_vars_str );
3643
3644         # If main::dumpvar isn't here, get it.
3645         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3646         if ( defined &main::dumpvar ) {
3647
3648             # We got it. Turn off subroutine entry/exit messages
3649             # for the moment, along with return values.
3650             local $frame = 0;
3651             local $doret = -2;
3652
3653             # must detect sigpipe failures  - not catching
3654             # then will cause the debugger to die.
3655             eval {
3656                 &main::dumpvar(
3657                     $packname,
3658                     defined $option{dumpDepth}
3659                     ? $option{dumpDepth}
3660                     : -1,    # assume -1 unless specified
3661                     @vars
3662                 );
3663             };
3664
3665             # The die doesn't need to include the $@, because
3666             # it will automatically get propagated for us.
3667             if ($@) {
3668                 die unless $@ =~ /dumpvar print failed/;
3669             }
3670         } ## end if (defined &main::dumpvar)
3671         else {
3672
3673             # Couldn't load dumpvar.
3674             print $OUT "dumpvar.pl not available.\n";
3675         }
3676
3677         # Restore the output filehandle, and go round again.
3678         select($savout);
3679         next CMD;
3680     }
3681
3682     return;
3683 }
3684
3685 sub _handle_dash_command {
3686
3687     if ($DB::cmd eq '-') {
3688
3689         # back up by a window; go to 1 if back too far.
3690         $start -= $incr + $window + 1;
3691         $start = 1 if $start <= 0;
3692         $incr  = $window - 1;
3693
3694         # Generate and execute a "l +" command (handled below).
3695         $DB::cmd = 'l ' . ($start) . '+';
3696     }
3697     return;
3698 }
3699
3700 sub _n_or_s_commands_generic {
3701     my ($self, $new_val) = @_;
3702     # n - next
3703     next CMD if DB::_DB__is_finished();
3704
3705     # Single step, but don't enter subs.
3706     $single = $new_val;
3707
3708     # Save for empty command (repeat last).
3709     $laststep = $DB::cmd;
3710     last CMD;
3711 }
3712
3713 sub _n_or_s {
3714     my ($self, $letter, $new_val) = @_;
3715
3716     if ($DB::cmd eq $letter) {
3717         $self->_n_or_s_commands_generic($new_val);
3718     }
3719
3720     return;
3721 }
3722
3723 sub _handle_n_command {
3724     my $self = shift;
3725
3726     return $self->_n_or_s('n', 2);
3727 }
3728
3729 sub _handle_s_command {
3730     my $self = shift;
3731
3732     return $self->_n_or_s('s', 1);
3733 }
3734
3735 sub _handle_r_command {
3736     my $self = shift;
3737     # r - return from the current subroutine.
3738     if ($DB::cmd eq 'r') {
3739
3740         # Can't do anything if the program's over.
3741         next CMD if DB::_DB__is_finished();
3742
3743         # Turn on stack trace.
3744         $stack[$stack_depth] |= 1;
3745
3746         # Print return value unless the stack is empty.
3747         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3748         last CMD;
3749     }
3750
3751     return;
3752 }
3753
3754 sub _handle_T_command {
3755     if ($DB::cmd eq 'T') {
3756         DB::print_trace( $OUT, 1 );    # skip DB
3757         next CMD;
3758     }
3759
3760     return;
3761 }
3762
3763 sub _handle_w_command {
3764     if (my ($arg) = $DB::cmd =~ /\Aw\b\s*(.*)/s) {
3765         DB::cmd_w( 'w', $arg );
3766         next CMD;
3767     }
3768
3769     return;
3770 }
3771
3772 sub _handle_W_command {
3773     if (my ($arg) = $DB::cmd =~ /\AW\b\s*(.*)/s) {
3774         DB::cmd_W( 'W', $arg );
3775         next CMD;
3776     }
3777
3778     return;
3779 }
3780
3781 sub _handle_rc_recall_command {
3782     my $self = shift;
3783
3784     # $rc - recall command.
3785     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3786
3787         # No arguments, take one thing off history.
3788         pop(@hist) if length($DB::cmd) > 1;
3789
3790         # Relative (- found)?
3791         #  Y - index back from most recent (by 1 if bare minus)
3792         #  N - go to that particular command slot or the last
3793         #      thing if nothing following.
3794         my $new_i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
3795
3796         $self->i_cmd($new_i);
3797
3798         # Pick out the command desired.
3799         $DB::cmd = $hist[$self->i_cmd];
3800
3801         # Print the command to be executed and restart the loop
3802         # with that command in the buffer.
3803         print {$OUT} $DB::cmd, "\n";
3804         redo CMD;
3805     }
3806
3807     return;
3808 }
3809
3810 package DB;
3811
3812 # The following code may be executed now:
3813 # BEGIN {warn 4}
3814
3815 =head2 sub
3816
3817 C<sub> is called whenever a subroutine call happens in the program being
3818 debugged. The variable C<$DB::sub> contains the name of the subroutine
3819 being called.
3820
3821 The core function of this subroutine is to actually call the sub in the proper
3822 context, capturing its output. This of course causes C<DB::DB> to get called
3823 again, repeating until the subroutine ends and returns control to C<DB::sub>
3824 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3825 return value, and returns its captured copy of the return value as its own
3826 return value. The value then feeds back into the program being debugged as if
3827 C<DB::sub> hadn't been there at all.
3828
3829 C<sub> does all the work of printing the subroutine entry and exit messages
3830 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3831 and also prints the return value if needed (for the C<r> command and if
3832 the 16 bit is set in C<$frame>).
3833
3834 It also tracks the subroutine call depth by saving the current setting of
3835 C<$single> in the C<@stack> package global; if this exceeds the value in
3836 C<$deep>, C<sub> automatically turns on printing of the current depth by
3837 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3838 of stop/don't stop on entry to subs set as it currently is set.
3839
3840 =head3 C<caller()> support
3841
3842 If C<caller()> is called from the package C<DB>, it provides some
3843 additional data, in the following order:
3844
3845 =over 4
3846
3847 =item * C<$package>
3848
3849 The package name the sub was in
3850
3851 =item * C<$filename>
3852
3853 The filename it was defined in
3854
3855 =item * C<$line>
3856
3857 The line number it was defined on
3858
3859 =item * C<$subroutine>
3860
3861 The subroutine name; C<(eval)> if an C<eval>().
3862
3863 =item * C<$hasargs>
3864
3865 1 if it has arguments, 0 if not
3866
3867 =item * C<$wantarray>
3868
3869 1 if array context, 0 if scalar context
3870
3871 =item * C<$evaltext>
3872
3873 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3874
3875 =item * C<$is_require>
3876
3877 frame was created by a C<use> or C<require> statement
3878
3879 =item * C<$hints>
3880
3881 pragma information; subject to change between versions
3882
3883 =item * C<$bitmask>
3884
3885 pragma information; subject to change between versions
3886
3887 =item * C<@DB::args>
3888
3889 arguments with which the subroutine was invoked
3890
3891 =back
3892
3893 =cut
3894
3895 use vars qw($deep);
3896
3897 # We need to fully qualify the name ("DB::sub") to make "use strict;"
3898 # happy. -- Shlomi Fish
3899 sub DB::sub {
3900     # Do not use a regex in this subroutine -> results in corrupted memory
3901     # See: [perl #66110]
3902
3903     # lock ourselves under threads
3904     lock($DBGR);
3905
3906     # Whether or not the autoloader was running, a scalar to put the
3907     # sub's return value in (if needed), and an array to put the sub's
3908     # return value in (if needed).
3909     my ( $al, $ret, @ret ) = "";
3910     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
3911         print "creating new thread\n";
3912     }
3913
3914     # If the last ten characters are '::AUTOLOAD', note we've traced
3915     # into AUTOLOAD for $sub.
3916     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
3917         no strict 'refs';
3918         $al = " for $$sub" if defined $$sub;
3919     }
3920
3921     # We stack the stack pointer and then increment it to protect us
3922     # from a situation that might unwind a whole bunch of call frames
3923     # at once. Localizing the stack pointer means that it will automatically
3924     # unwind the same amount when multiple stack frames are unwound.
3925     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
3926
3927     # Expand @stack.
3928     $#stack = $stack_depth;
3929
3930     # Save current single-step setting.
3931     $stack[-1] = $single;
3932
3933     # Turn off all flags except single-stepping.
3934     $single &= 1;
3935
3936     # If we've gotten really deeply recursed, turn on the flag that will
3937     # make us stop with the 'deep recursion' message.
3938     $single |= 4 if $stack_depth == $deep;
3939
3940     # If frame messages are on ...
3941     (
3942         $frame & 4    # Extended frame entry message
3943         ? (
3944             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
3945
3946             # Why -1? But it works! :-(
3947             # Because print_trace will call add 1 to it and then call
3948             # dump_trace; this results in our skipping -1+1 = 0 stack frames
3949             # in dump_trace.
3950             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3951           )
3952         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
3953
3954           # standard frame entry message
3955       )
3956       if $frame;
3957
3958     # Determine the sub's return type, and capture appropriately.
3959     if (wantarray) {
3960
3961         # Called in array context. call sub and capture output.
3962         # DB::DB will recursively get control again if appropriate; we'll come
3963         # back here when the sub is finished.
3964         {
3965             no strict 'refs';
3966             @ret = &$sub;
3967         }
3968
3969         # Pop the single-step value back off the stack.
3970         $single |= $stack[ $stack_depth-- ];
3971
3972         # Check for exit trace messages...
3973         (
3974             $frame & 4    # Extended exit message
3975             ? (
3976                 print_lineinfo( ' ' x $stack_depth, "out " ),
3977                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
3978               )
3979             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
3980
3981               # Standard exit message
3982           )
3983           if $frame & 2;
3984
3985         # Print the return info if we need to.
3986         if ( $doret eq $stack_depth or $frame & 16 ) {
3987
3988             # Turn off output record separator.
3989             local $\ = '';
3990             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
3991
3992             # Indent if we're printing because of $frame tracing.
3993             print $fh ' ' x $stack_depth if $frame & 16;
3994
3995             # Print the return value.
3996             print $fh "list context return from $sub:\n";
3997             dumpit( $fh, \@ret );
3998
3999             # And don't print it again.
4000             $doret = -2;
4001         } ## end if ($doret eq $stack_depth...
4002             # And we have to return the return value now.
4003         @ret;
4004     } ## end if (wantarray)
4005
4006     # Scalar context.
4007     else {
4008         if ( defined wantarray ) {
4009             no strict 'refs';
4010             # Save the value if it's wanted at all.
4011             $ret = &$sub;
4012         }
4013         else {
4014             no strict 'refs';
4015             # Void return, explicitly.
4016             &$sub;
4017             undef $ret;
4018         }
4019
4020         # Pop the single-step value off the stack.
4021         $single |= $stack[ $stack_depth-- ];
4022
4023         # If we're doing exit messages...
4024         (
4025             $frame & 4    # Extended messages
4026             ? (
4027                 print_lineinfo( ' ' x $stack_depth, "out " ),
4028                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4029               )
4030             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4031
4032               # Standard messages
4033           )
4034           if $frame & 2;
4035
4036         # If we are supposed to show the return value... same as before.
4037         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4038             local $\ = '';
4039             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4040             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4041             print $fh (
4042                 defined wantarray
4043                 ? "scalar context return from $sub: "
4044                 : "void context return from $sub\n"
4045             );
4046             dumpit( $fh, $ret ) if defined wantarray;
4047             $doret = -2;
4048         } ## end if ($doret eq $stack_depth...
4049
4050         # Return the appropriate scalar value.
4051         $ret;
4052     } ## end else [ if (wantarray)
4053 } ## end sub _sub
4054
4055 sub lsub : lvalue {
4056
4057     no strict 'refs';
4058
4059     # lock ourselves under threads
4060     lock($DBGR);
4061
4062     # Whether or not the autoloader was running, a scalar to put the
4063     # sub's return value in (if needed), and an array to put the sub's
4064     # return value in (if needed).
4065     my ( $al, $ret, @ret ) = "";
4066     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4067         print "creating new thread\n";
4068     }
4069
4070     # If the last ten characters are C'::AUTOLOAD', note we've traced
4071     # into AUTOLOAD for $sub.
4072     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4073         $al = " for $$sub";
4074     }
4075
4076     # We stack the stack pointer and then increment it to protect us
4077     # from a situation that might unwind a whole bunch of call frames
4078     # at once. Localizing the stack pointer means that it will automatically
4079     # unwind the same amount when multiple stack frames are unwound.
4080     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4081
4082     # Expand @stack.
4083     $#stack = $stack_depth;
4084
4085     # Save current single-step setting.
4086     $stack[-1] = $single;
4087
4088     # Turn off all flags except single-stepping.
4089     $single &= 1;
4090
4091     # If we've gotten really deeply recursed, turn on the flag that will
4092     # make us stop with the 'deep recursion' message.
4093     $single |= 4 if $stack_depth == $deep;
4094
4095     # If frame messages are on ...
4096     (
4097         $frame & 4    # Extended frame entry message
4098         ? (
4099             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4100
4101             # Why -1? But it works! :-(
4102             # Because print_trace will call add 1 to it and then call
4103             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4104             # in dump_trace.
4105             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4106           )
4107         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4108
4109           # standard frame entry message
4110       )
4111       if $frame;
4112
4113     # Pop the single-step value back off the stack.
4114     $single |= $stack[ $stack_depth-- ];
4115
4116     # call the original lvalue sub.
4117     &$sub;
4118 }
4119
4120 # Abstracting common code from multiple places elsewhere:
4121 sub depth_print_lineinfo {
4122     my $always_print = shift;
4123
4124     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4125 }
4126
4127 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4128
4129 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4130 Most of the changes were to systematize the command structure and to eliminate
4131 commands that threw away user input without checking.
4132
4133 The following sections describe the code added to make it easy to support
4134 multiple command sets with conflicting command names. This section is a start
4135 at unifying all command processing to make it simpler to develop commands.
4136
4137 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4138 number, and C<$dbline> (the current line) as arguments.
4139
4140 Support functions in this section which have multiple modes of failure C<die>
4141 on error; the rest simply return a false value.
4142
4143 The user-interface functions (all of the C<cmd_*> functions) just output
4144 error messages.
4145
4146 =head2 C<%set>
4147
4148 The C<%set> hash defines the mapping from command letter to subroutine
4149 name suffix.
4150
4151 C<%set> is a two-level hash, indexed by set name and then by command name.
4152 Note that trying to set the CommandSet to C<foobar> simply results in the
4153 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4154
4155 =cut
4156
4157 ### The API section
4158
4159 my %set = (    #
4160     'pre580' => {
4161         'a' => 'pre580_a',
4162         'A' => 'pre580_null',
4163         'b' => 'pre580_b',
4164         'B' => 'pre580_null',
4165         'd' => 'pre580_null',
4166         'D' => 'pre580_D',
4167         'h' => 'pre580_h',
4168         'M' => 'pre580_null',
4169         'O' => 'o',
4170         'o' => 'pre580_null',
4171         'v' => 'M',
4172         'w' => 'v',
4173         'W' => 'pre580_W',
4174     },
4175     'pre590' => {
4176         '<'  => 'pre590_prepost',
4177         '<<' => 'pre590_prepost',
4178         '>'  => 'pre590_prepost',
4179         '>>' => 'pre590_prepost',
4180         '{'  => 'pre590_prepost',
4181         '{{' => 'pre590_prepost',
4182     },
4183 );
4184
4185 my %breakpoints_data;
4186
4187 sub _has_breakpoint_data_ref {
4188     my ($filename, $line) = @_;
4189
4190     return (
4191         exists( $breakpoints_data{$filename} )
4192             and
4193         exists( $breakpoints_data{$filename}{$line} )
4194     );
4195 }
4196
4197 sub _get_breakpoint_data_ref {
4198     my ($filename, $line) = @_;
4199
4200     return ($breakpoints_data{$filename}{$line} ||= +{});
4201 }
4202
4203 sub _delete_breakpoint_data_ref {
4204     my ($filename, $line) = @_;
4205
4206     delete($breakpoints_data{$filename}{$line});
4207     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4208         delete($breakpoints_data{$filename});
4209     }
4210
4211     return;
4212 }
4213
4214 sub _set_breakpoint_enabled_status {
4215     my ($filename, $line, $status) = @_;
4216
4217     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4218         ($status ? 1 : '')
4219         ;
4220
4221     return;
4222 }
4223
4224 sub _enable_breakpoint_temp_enabled_status {
4225     my ($filename, $line) = @_;
4226
4227     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4228
4229     return;
4230 }
4231
4232 sub _cancel_breakpoint_temp_enabled_status {
4233     my ($filename, $line) = @_;
4234
4235     my $ref = _get_breakpoint_data_ref($filename, $line);
4236
4237     delete ($ref->{'temp_enabled'});
4238
4239     if (! %$ref) {
4240         _delete_breakpoint_data_ref($filename, $line);
4241     }
4242
4243     return;
4244 }
4245
4246 sub _is_breakpoint_enabled {
4247     my ($filename, $line) = @_;
4248
4249     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4250     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4251 }
4252
4253 =head2 C<cmd_wrapper()> (API)
4254
4255 C<cmd_wrapper()> allows the debugger to switch command sets
4256 depending on the value of the C<CommandSet> option.
4257
4258 It tries to look up the command in the C<%set> package-level I<lexical>
4259 (which means external entities can't fiddle with it) and create the name of
4260 the sub to call based on the value found in the hash (if it's there). I<All>
4261 of the commands to be handled in a set have to be added to C<%set>; if they
4262 aren't found, the 5.8.0 equivalent is called (if there is one).
4263
4264 This code uses symbolic references.
4265
4266 =cut
4267
4268 sub cmd_wrapper {
4269     my $cmd      = shift;
4270     my $line     = shift;
4271     my $dblineno = shift;
4272
4273     # Assemble the command subroutine's name by looking up the
4274     # command set and command name in %set. If we can't find it,
4275     # default to the older version of the command.
4276     my $call = 'cmd_'
4277       . ( $set{$CommandSet}{$cmd}
4278           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4279
4280     # Call the command subroutine, call it by name.
4281     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4282 } ## end sub cmd_wrapper
4283
4284 =head3 C<cmd_a> (command)
4285
4286 The C<a> command handles pre-execution actions. These are associated with a
4287 particular line, so they're stored in C<%dbline>. We default to the current
4288 line if none is specified.
4289
4290 =cut
4291
4292 sub cmd_a {
4293     my $cmd    = shift;
4294     my $line   = shift || '';    # [.|line] expr
4295     my $dbline = shift;
4296
4297     # If it's dot (here), or not all digits,  use the current line.
4298     $line =~ s/\A\./$dbline/;
4299
4300     # Should be a line number followed by an expression.
4301     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4302
4303         if (! length($lineno)) {
4304             $lineno = $dbline;
4305         }
4306
4307         # If we have an expression ...
4308         if ( length $expr ) {
4309
4310             # ... but the line isn't breakable, complain.
4311             if ( $dbline[$lineno] == 0 ) {
4312                 print $OUT
4313                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4314             }
4315             else {
4316
4317                 # It's executable. Record that the line has an action.
4318                 $had_breakpoints{$filename} |= 2;
4319
4320                 # Remove any action, temp breakpoint, etc.
4321                 $dbline{$lineno} =~ s/\0[^\0]*//;
4322
4323                 # Add the action to the line.
4324                 $dbline{$lineno} .= "\0" . action($expr);
4325
4326                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4327             }
4328         } ## end if (length $expr)
4329     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4330     else {
4331
4332         # Syntax wrong.
4333         print $OUT
4334           "Adding an action requires an optional lineno and an expression\n"
4335           ;    # hint
4336     }
4337 } ## end sub cmd_a
4338
4339 =head3 C<cmd_A> (command)
4340
4341 Delete actions. Similar to above, except the delete code is in a separate
4342 subroutine, C<delete_action>.
4343
4344 =cut
4345
4346 sub cmd_A {
4347     my $cmd    = shift;
4348     my $line   = shift || '';
4349     my $dbline = shift;
4350
4351     # Dot is this line.
4352     $line =~ s/^\./$dbline/;
4353
4354     # Call delete_action with a null param to delete them all.
4355     # The '1' forces the eval to be true. It'll be false only
4356     # if delete_action blows up for some reason, in which case
4357     # we print $@ and get out.
4358     if ( $line eq '*' ) {
4359         if (! eval { _delete_all_actions(); 1 }) {
4360             print {$OUT} $@;
4361             return;
4362         }
4363     }
4364
4365     # There's a real line  number. Pass it to delete_action.
4366     # Error trapping is as above.
4367     elsif ( $line =~ /^(\S.*)/ ) {
4368         if (! eval { delete_action($1); 1 }) {
4369             print {$OUT} $@;
4370             return;
4371         }
4372     }
4373
4374     # Swing and a miss. Bad syntax.
4375     else {
4376         print $OUT
4377           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4378     }
4379 } ## end sub cmd_A
4380
4381 =head3 C<delete_action> (API)
4382
4383 C<delete_action> accepts either a line number or C<undef>. If a line number
4384 is specified, we check for the line being executable (if it's not, it
4385 couldn't have had an  action). If it is, we just take the action off (this
4386 will get any kind of an action, including breakpoints).
4387
4388 =cut
4389
4390 sub _remove_action_from_dbline {
4391     my $i = shift;
4392
4393     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4394     delete $dbline{$i} if $dbline{$i} eq '';
4395
4396     return;
4397 }
4398
4399 sub _delete_all_actions {
4400     print {$OUT} "Deleting all actions...\n";
4401
4402     for my $file ( keys %had_breakpoints ) {
4403         local *dbline = $main::{ '_<' . $file };
4404         $max = $#dbline;
4405         my $was;
4406         for my $i (1 .. $max) {
4407             if ( defined $dbline{$i} ) {
4408                 _remove_action_from_dbline($i);
4409             }
4410         }
4411
4412         unless ( $had_breakpoints{$file} &= ~2 ) {
4413             delete $had_breakpoints{$file};
4414         }
4415     }
4416
4417     return;
4418 }
4419
4420 sub delete_action {
4421     my $i = shift;
4422
4423     if ( defined($i) ) {
4424         # Can there be one?
4425         die "Line $i has no action .\n" if $dbline[$i] == 0;
4426
4427         # Nuke whatever's there.
4428         _remove_action_from_dbline($i);
4429     }
4430     else {
4431         _delete_all_actions();
4432     }
4433 }
4434
4435 =head3 C<cmd_b> (command)
4436
4437 Set breakpoints. Since breakpoints can be set in so many places, in so many
4438 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4439 we try to parse the command type, and then shuttle it off to an appropriate
4440 subroutine to actually do the work of setting the breakpoint in the right
4441 place.
4442
4443 =cut
4444
4445 sub cmd_b {
4446     my $cmd    = shift;
4447     my $line   = shift;    # [.|line] [cond]
4448     my $dbline = shift;
4449
4450     my $default_cond = sub {
4451         my $cond = shift;
4452         return length($cond) ? $cond : '1';
4453     };
4454
4455     # Make . the current line number if it's there..
4456     $line =~ s/^\.(\s|\z)/$dbline$1/;
4457
4458     # No line number, no condition. Simple break on current line.
4459     if ( $line =~ /^\s*$/ ) {
4460         cmd_b_line( $dbline, 1 );
4461     }
4462
4463     # Break on load for a file.
4464     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4465         $file =~ s/\s+\z//;
4466         cmd_b_load($file);
4467     }
4468
4469     # b compile|postpone <some sub> [<condition>]
4470     # The interpreter actually traps this one for us; we just put the
4471     # necessary condition in the %postponed hash.
4472     elsif ( my ($action, $subname, $cond)
4473         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4474
4475         # De-Perl4-ify the name - ' separators to ::.
4476         $subname =~ s/'/::/g;
4477
4478         # Qualify it into the current package unless it's already qualified.
4479         $subname = "${package}::" . $subname unless $subname =~ /::/;
4480
4481         # Add main if it starts with ::.
4482         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4483
4484         # Save the break type for this sub.
4485         $postponed{$subname} = (($action eq 'postpone')
4486             ? ( "break +0 if " . $default_cond->($cond) )
4487             : "compile");
4488     } ## end elsif ($line =~ ...
4489     # b <filename>:<line> [<condition>]
4490     elsif (my ($filename, $line_num, $cond)
4491         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4492         cmd_b_filename_line(
4493             $filename,
4494             $line_num,
4495             (length($cond) ? $cond : '1'),
4496         );
4497     }
4498     # b <sub name> [<condition>]
4499     elsif ( my ($new_subname, $new_cond) =
4500         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4501
4502         #
4503         $subname = $new_subname;
4504         cmd_b_sub( $subname, $default_cond->($new_cond) );
4505     }
4506
4507     # b <line> [<condition>].
4508     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4509
4510         # Capture the line. If none, it's the current line.
4511         $line = $line_n || $dbline;
4512
4513         # Break on line.
4514         cmd_b_line( $line, $default_cond->($cond) );
4515     }
4516
4517     # Line didn't make sense.
4518     else {
4519         print "confused by line($line)?\n";
4520     }
4521
4522     return;
4523 } ## end sub cmd_b
4524
4525 =head3 C<break_on_load> (API)
4526
4527 We want to break when this file is loaded. Mark this file in the
4528 C<%break_on_load> hash, and note that it has a breakpoint in
4529 C<%had_breakpoints>.
4530
4531 =cut
4532
4533 sub break_on_load {
4534     my $file = shift;
4535     $break_on_load{$file} = 1;
4536     $had_breakpoints{$file} |= 1;
4537 }
4538
4539 =head3 C<report_break_on_load> (API)
4540
4541 Gives us an array of filenames that are set to break on load. Note that
4542 only files with break-on-load are in here, so simply showing the keys
4543 suffices.
4544
4545 =cut
4546
4547 sub report_break_on_load {
4548     sort keys %break_on_load;
4549 }
4550
4551 =head3 C<cmd_b_load> (command)
4552
4553 We take the file passed in and try to find it in C<%INC> (which maps modules
4554 to files they came from). We mark those files for break-on-load via
4555 C<break_on_load> and then report that it was done.
4556
4557 =cut
4558
4559 sub cmd_b_load {
4560     my $file = shift;
4561     my @files;
4562
4563     # This is a block because that way we can use a redo inside it
4564     # even without there being any looping structure at all outside it.
4565     {
4566
4567         # Save short name and full path if found.
4568         push @files, $file;
4569         push @files, $::INC{$file} if $::INC{$file};
4570
4571         # Tack on .pm and do it again unless there was a '.' in the name
4572         # already.
4573         $file .= '.pm', redo unless $file =~ /\./;
4574     }
4575
4576     # Do the real work here.
4577     break_on_load($_) for @files;
4578
4579     # All the files that have break-on-load breakpoints.
4580     @files = report_break_on_load;
4581
4582     # Normalize for the purposes of our printing this.
4583     local $\ = '';
4584     local $" = ' ';
4585     print $OUT "Will stop on load of '@files'.\n";
4586 } ## end sub cmd_b_load
4587
4588 =head3 C<$filename_error> (API package global)
4589
4590 Several of the functions we need to implement in the API need to work both
4591 on the current file and on other files. We don't want to duplicate code, so
4592 C<$filename_error> is used to contain the name of the file that's being
4593 worked on (if it's not the current one).
4594
4595 We can now build functions in pairs: the basic function works on the current
4596 file, and uses C<$filename_error> as part of its error message. Since this is
4597 initialized to C<"">, no filename will appear when we are working on the
4598 current file.
4599
4600 The second function is a wrapper which does the following:
4601
4602 =over 4
4603
4604 =item *
4605
4606 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4607
4608 =item *
4609
4610 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4611
4612 =item *
4613
4614 Calls the first function.
4615
4616 The first function works on the I<current> file (i.e., the one we changed to),
4617 and prints C<$filename_error> in the error message (the name of the other file)
4618 if it needs to. When the functions return, C<*dbline> is restored to point
4619 to the actual current file (the one we're executing in) and
4620 C<$filename_error> is restored to C<"">. This restores everything to
4621 the way it was before the second function was called at all.
4622
4623 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4624 details.
4625
4626 =back
4627
4628 =cut
4629
4630 use vars qw($filename_error);
4631 $filename_error = '';
4632
4633 =head3 breakable_line(from, to) (API)
4634
4635 The subroutine decides whether or not a line in the current file is breakable.
4636 It walks through C<@dbline> within the range of lines specified, looking for
4637 the first line that is breakable.
4638
4639 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4640 first line I<after> C<$to> that's breakable, if there is one.
4641
4642 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4643 first line I<before> C<$to> that's breakable, if there is one.
4644
4645 =cut
4646
4647 sub breakable_line {
4648
4649     my ( $from, $to ) = @_;
4650
4651     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4652     my $i = $from;
4653
4654     # If there are at least 2 arguments, we're trying to search a range.
4655     if ( @_ >= 2 ) {
4656
4657         # $delta is positive for a forward search, negative for a backward one.
4658         my $delta = $from < $to ? +1 : -1;
4659
4660         # Keep us from running off the ends of the file.
4661         my $limit = $delta > 0 ? $#dbline : 1;
4662
4663         # Clever test. If you're a mathematician, it's obvious why this
4664         # test works. If not:
4665         # If $delta is positive (going forward), $limit will be $#dbline.
4666         #    If $to is less than $limit, ($limit - $to) will be positive, times
4667         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4668         #    as the stopping point.
4669         #
4670         #    If $to is greater than $limit, ($limit - $to) is negative,
4671         #    times $delta of 1 (positive), so the result is < 0 and we should
4672         #    use $limit ($#dbline) as the stopping point.
4673         #
4674         # If $delta is negative (going backward), $limit will be 1.
4675         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4676         #    (negative) so the result is > 0, and we use $to as the stopping
4677         #    point.
4678         #
4679         #    If $to is less than zero, ($limit - $to) will be positive,
4680         #    times $delta of -1 (negative), so the result is not > 0, and
4681         #    we use $limit (1) as the stopping point.
4682         #
4683         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4684         #    (negative), still giving zero; the result is not > 0, and
4685         #    we use $limit (1) as the stopping point.
4686         #
4687         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4688         #    (negative), giving a positive (>0) value, so we'll set $limit to
4689         #    $to.
4690
4691         $limit = $to if ( $limit - $to ) * $delta > 0;
4692
4693         # The real search loop.
4694         # $i starts at $from (the point we want to start searching from).
4695         # We move through @dbline in the appropriate direction (determined
4696         # by $delta: either -1 (back) or +1 (ahead).
4697         # We stay in as long as we haven't hit an executable line
4698         # ($dbline[$i] == 0 means not executable) and we haven't reached
4699         # the limit yet (test similar to the above).
4700         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4701
4702     } ## end if (@_ >= 2)
4703
4704     # If $i points to a line that is executable, return that.
4705     return $i unless $dbline[$i] == 0;
4706
4707     # Format the message and print it: no breakable lines in range.
4708     my ( $pl, $upto ) = ( '', '' );
4709     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4710
4711     # If there's a filename in filename_error, we'll see it.
4712     # If not, not.
4713     die "Line$pl $from$upto$filename_error not breakable\n";
4714 } ## end sub breakable_line
4715
4716 =head3 breakable_line_in_filename(file, from, to) (API)
4717
4718 Like C<breakable_line>, but look in another file.
4719
4720 =cut
4721
4722 sub breakable_line_in_filename {
4723
4724     # Capture the file name.
4725     my ($f) = shift;
4726
4727     # Swap the magic line array over there temporarily.
4728     local *dbline = $main::{ '_<' . $f };
4729
4730     # If there's an error, it's in this other file.
4731     local $filename_error = " of '$f'";
4732
4733     # Find the breakable line.
4734     breakable_line(@_);
4735
4736     # *dbline and $filename_error get restored when this block ends.
4737
4738 } ## end sub breakable_line_in_filename
4739
4740 =head3 break_on_line(lineno, [c