This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
making the BSD in bsdish stand out for Sys::Hostname
[perl5.git] / ext / Sys-Hostname / Hostname.pm
1 package Sys::Hostname;
2
3 use strict;
4
5 use Carp;
6
7 require Exporter;
8
9 our @ISA     = qw/ Exporter /;
10 our @EXPORT  = qw/ hostname /;
11
12 our $VERSION;
13
14 our $host;
15
16 BEGIN {
17     $VERSION = '1.18';
18     {
19         local $SIG{__DIE__};
20         eval {
21             require XSLoader;
22             XSLoader::load();
23         };
24         warn $@ if $@;
25     }
26 }
27
28
29 sub hostname {
30
31   # method 1 - we already know it
32   return $host if defined $host;
33
34   # method 1' - try to ask the system
35   $host = ghname() if defined &ghname;
36   return $host if defined $host;
37
38   if ($^O eq 'VMS') {
39
40     # method 2 - no sockets ==> return DECnet node name
41     eval { local $SIG{__DIE__}; $host = (gethostbyname('me'))[0] };
42     if ($@) { return $host = $ENV{'SYS$NODE'}; }
43
44     # method 3 - has someone else done the job already?  It's common for the
45     #    TCP/IP stack to advertise the hostname via a logical name.  (Are
46     #    there any other logicals which TCP/IP stacks use for the host name?)
47     $host = $ENV{'ARPANET_HOST_NAME'}  || $ENV{'INTERNET_HOST_NAME'} ||
48             $ENV{'MULTINET_HOST_NAME'} || $ENV{'UCX$INET_HOST'}      ||
49             $ENV{'TCPWARE_DOMAINNAME'} || $ENV{'NEWS_ADDRESS'};
50     return $host if $host;
51
52     # method 4 - does hostname happen to work?
53     my($rslt) = `hostname`;
54     if ($rslt !~ /IVVERB/) { ($host) = $rslt =~ /^(\S+)/; }
55     return $host if $host;
56
57     # rats!
58     $host = '';
59     croak "Cannot get host name of local machine";  
60
61   }
62   elsif ($^O eq 'MSWin32') {
63     ($host) = gethostbyname('localhost');
64     chomp($host = `hostname 2> NUL`) unless defined $host;
65     return $host;
66   }
67   else {  # Unix
68     # is anyone going to make it here?
69
70     local $ENV{PATH} = '/usr/bin:/bin:/usr/sbin:/sbin'; # Paranoia.
71
72     # method 2 - syscall is preferred since it avoids tainting problems
73     # XXX: is it such a good idea to return hostname untainted?
74     eval {
75         local $SIG{__DIE__};
76         require "syscall.ph";
77         $host = "\0" x 65; ## preload scalar
78         syscall(&SYS_gethostname, $host, 65) == 0;
79     }
80
81     # method 2a - syscall using systeminfo instead of gethostname
82     #           -- needed on systems like Solaris
83     || eval {
84         local $SIG{__DIE__};
85         require "sys/syscall.ph";
86         require "sys/systeminfo.ph";
87         $host = "\0" x 65; ## preload scalar
88         syscall(&SYS_systeminfo, &SI_HOSTNAME, $host, 65) != -1;
89     }
90
91     # method 3 - trusty old hostname command
92     || eval {
93         local $SIG{__DIE__};
94         local $SIG{CHLD};
95         $host = `(hostname) 2>/dev/null`; # BSDish
96     }
97
98     # method 4 - use POSIX::uname(), which strictly can't be expected to be
99     # correct
100     || eval {
101         local $SIG{__DIE__};
102         require POSIX;
103         $host = (POSIX::uname())[1];
104     }
105
106     # method 5 - sysV uname command (may truncate)
107     || eval {
108         local $SIG{__DIE__};
109         $host = `uname -n 2>/dev/null`; ## sysVish
110     }
111
112     # bummer
113     || croak "Cannot get host name of local machine";  
114
115     # remove garbage 
116     $host =~ tr/\0\r\n//d;
117     $host;
118   }
119 }
120
121 1;
122
123 __END__
124
125 =head1 NAME
126
127 Sys::Hostname - Try every conceivable way to get hostname
128
129 =head1 SYNOPSIS
130
131     use Sys::Hostname;
132     $host = hostname;
133
134 =head1 DESCRIPTION
135
136 Attempts several methods of getting the system hostname and
137 then caches the result.  It tries the first available of the C
138 library's gethostname(), C<`$Config{aphostname}`>, uname(2),
139 C<syscall(SYS_gethostname)>, C<`hostname`>, C<`uname -n`>,
140 and the file F</com/host>.  If all that fails it C<croak>s.
141
142 All NULs, returns, and newlines are removed from the result.
143
144 =head1 AUTHOR
145
146 David Sundstrom E<lt>F<sunds@asictest.sc.ti.com>E<gt>
147
148 Texas Instruments
149
150 XS code added by Greg Bacon E<lt>F<gbacon@cs.uah.edu>E<gt>
151
152 =cut
153