lib/File/Copy.pm

   1 # File/Copy.pm. Written in 1994 by Aaron Sherman <ajs@ajs.com>. This
   2 # source code has been placed in the public domain by the author.
   3 # Please be kind and preserve the documentation.
   4 #
   5 # Additions copyright 1996 by Charles Bailey.  Permission is granted
   6 # to distribute the revised code under the same terms as Perl itself.
   7
   8 package File::Copy;
   9
  10 use 5.6.0;
  11 use strict;
  12 use warnings;
  13 use Carp;
  14 use File::Spec;
  15 our(@ISA, @EXPORT, @EXPORT_OK, $VERSION, $Too_Big, $Syscopy_is_copy);
  16 sub copy;
  17 sub syscopy;
  18 sub cp;
  19 sub mv;
  20
  21 # Note that this module implements only *part* of the API defined by
  22 # the File/Copy.pm module of the File-Tools-2.0 package.  However, that
  23 # package has not yet been updated to work with Perl 5.004, and so it
  24 # would be a Bad Thing for the CPAN module to grab it and replace this
  25 # module.  Therefore, we set this module's version higher than 2.0.
  26 $VERSION = '2.04';
  27
  28 require Exporter;
  29 @ISA = qw(Exporter);
  30 @EXPORT = qw(copy move);
  31 @EXPORT_OK = qw(cp mv);
  32
  33 $Too_Big = 1024 * 1024 * 2;
  34
  35 sub _catname {
  36     my($from, $to) = @_;
  37     if (not defined &basename) {
  38         require File::Basename;
  39         import  File::Basename 'basename';
  40     }
  41
  42     if ($^O eq 'MacOS') {
  43         # a partial dir name that's valid only in the cwd (e.g. 'tmp')
  44         $to = ':' . $to if $to !~ /:/;
  45     }
  46
  47     return File::Spec->catfile($to, basename($from));
  48 }
  49
  50 sub copy {
  51     croak("Usage: copy(FROM, TO [, BUFFERSIZE]) ")
  52       unless(@_ == 2 || @_ == 3);
  53
  54     my $from = shift;
  55     my $to = shift;
  56
  57     my $from_a_handle = (ref($from)
  58                          ? (ref($from) eq 'GLOB'
  59                             || UNIVERSAL::isa($from, 'GLOB')
  60                             || UNIVERSAL::isa($from, 'IO::Handle'))
  61                          : (ref(\$from) eq 'GLOB'));
  62     my $to_a_handle =   (ref($to)
  63                          ? (ref($to) eq 'GLOB'
  64                             || UNIVERSAL::isa($to, 'GLOB')
  65                             || UNIVERSAL::isa($to, 'IO::Handle'))
  66                          : (ref(\$to) eq 'GLOB'));
  67
  68     if (!$from_a_handle && !$to_a_handle && -d $to && ! -d $from) {
  69         $to = _catname($from, $to);
  70     }
  71
  72     if (defined &syscopy && !$Syscopy_is_copy
  73         && !$to_a_handle
  74         && !($from_a_handle && $^O eq 'os2' )   # OS/2 cannot handle handles
  75         && !($from_a_handle && $^O eq 'mpeix')  # and neither can MPE/iX.
  76         && !($from_a_handle && $^O eq 'MSWin32')
  77         && !($from_a_handle && $^O eq 'MacOS')
  78        )
  79     {
  80         return syscopy($from, $to);
  81     }
  82
  83     my $closefrom = 0;
  84     my $closeto = 0;
  85     my ($size, $status, $r, $buf);
  86     local(*FROM, *TO);
  87     local($\) = '';
  88
  89     if ($from_a_handle) {
  90         *FROM = *$from{FILEHANDLE};
  91     } else {
  92         $from = _protect($from) if $from =~ /^\s/s;
  93         open(FROM, "< $from\0") or goto fail_open1;
  94         binmode FROM or die "($!,$^E)";
  95         $closefrom = 1;
  96     }
  97
  98     if ($to_a_handle) {
  99         *TO = *$to{FILEHANDLE};
 100     } else {
 101         $to = _protect($to) if $to =~ /^\s/s;
 102         open(TO,"> $to\0") or goto fail_open2;
 103         binmode TO or die "($!,$^E)";
 104         $closeto = 1;
 105     }
 106
 107     if (@_) {
 108         $size = shift(@_) + 0;
 109         croak("Bad buffer size for copy: $size\n") unless ($size > 0);
 110     } else {
 111         $size = -s FROM;
 112         $size = 1024 if ($size < 512);
 113         $size = $Too_Big if ($size > $Too_Big);
 114     }
 115
 116     $! = 0;
 117     for (;;) {
 118         my ($r, $w, $t);
 119         defined($r = sysread(FROM, $buf, $size))
 120             or goto fail_inner;
 121         last unless $r;
 122         for ($w = 0; $w < $r; $w += $t) {
 123             $t = syswrite(TO, $buf, $r - $w, $w)
 124                 or goto fail_inner;
 125         }
 126     }
 127
 128     close(TO) || goto fail_open2 if $closeto;
 129     close(FROM) || goto fail_open1 if $closefrom;
 130
 131     # Use this idiom to avoid uninitialized value warning.
 132     return 1;
 133
 134     # All of these contortions try to preserve error messages...
 135   fail_inner:
 136     if ($closeto) {
 137         $status = $!;
 138         $! = 0;
 139         close TO;
 140         $! = $status unless $!;
 141     }
 142   fail_open2:
 143     if ($closefrom) {
 144         $status = $!;
 145         $! = 0;
 146         close FROM;
 147         $! = $status unless $!;
 148     }
 149   fail_open1:
 150     return 0;
 151 }
 152
 153 sub move {
 154     my($from,$to) = @_;
 155     my($copied,$fromsz,$tosz1,$tomt1,$tosz2,$tomt2,$sts,$ossts);
 156
 157     if (-d $to && ! -d $from) {
 158         $to = _catname($from, $to);
 159     }
 160
 161     ($tosz1,$tomt1) = (stat($to))[7,9];
 162     $fromsz = -s $from;
 163     if ($^O eq 'os2' and defined $tosz1 and defined $fromsz) {
 164       # will not rename with overwrite
 165       unlink $to;
 166     }
 167     return 1 if rename $from, $to;
 168
 169     ($sts,$ossts) = ($! + 0, $^E + 0);
 170     # Did rename return an error even though it succeeded, because $to
 171     # is on a remote NFS file system, and NFS lost the server's ack?
 172     return 1 if defined($fromsz) && !-e $from &&           # $from disappeared
 173                 (($tosz2,$tomt2) = (stat($to))[7,9]) &&    # $to's there
 174                 ($tosz1 != $tosz2 or $tomt1 != $tomt2) &&  #   and changed
 175                 $tosz2 == $fromsz;                         # it's all there
 176
 177     ($tosz1,$tomt1) = (stat($to))[7,9];  # just in case rename did something
 178     return 1 if ($copied = copy($from,$to)) && unlink($from);
 179
 180     ($tosz2,$tomt2) = ((stat($to))[7,9],0,0) if defined $tomt1;
 181     unlink($to) if !defined($tomt1) or $tomt1 != $tomt2 or $tosz1 != $tosz2;
 182     ($!,$^E) = ($sts,$ossts);
 183     return 0;
 184 }
 185
 186 *cp = \&copy;
 187 *mv = \&move;
 188
 189
 190 if ($^O eq 'MacOS') {
 191     *_protect = sub { MacPerl::MakeFSSpec($_[0]) };
 192 } else {
 193     *_protect = sub { "./$_[0]" };
 194 }
 195
 196 # &syscopy is an XSUB under OS/2
 197 unless (defined &syscopy) {
 198     if ($^O eq 'VMS') {
 199         *syscopy = \&rmscopy;
 200     } elsif ($^O eq 'mpeix') {
 201         *syscopy = sub {
 202             return 0 unless @_ == 2;
 203             # Use the MPE cp program in order to
 204             # preserve MPE file attributes.
 205             return system('/bin/cp', '-f', $_[0], $_[1]) == 0;
 206         };
 207     } elsif ($^O eq 'MSWin32') {
 208         *syscopy = sub {
 209             return 0 unless @_ == 2;
 210             return Win32::CopyFile(@_, 1);
 211         };
 212     } elsif ($^O eq 'MacOS') {
 213         require Mac::MoreFiles;
 214         *syscopy = sub {
 215             my($from, $to) = @_;
 216             my($dir, $toname);
 217
 218             return 0 unless -e $from;
 219
 220             if ($to =~ /(.*:)([^:]+):?$/) {
 221                 ($dir, $toname) = ($1, $2);
 222             } else {
 223                 ($dir, $toname) = (":", $to);
 224             }
 225
 226             unlink($to);
 227             Mac::MoreFiles::FSpFileCopy($from, $dir, $toname, 1);
 228         };
 229     } else {
 230         $Syscopy_is_copy = 1;
 231         *syscopy = \&copy;
 232     }
 233 }
 234
 235 1;
 236
 237 __END__
 238
 239 =head1 NAME
 240
 241 File::Copy - Copy files or filehandles
 242
 243 =head1 SYNOPSIS
 244
 245         use File::Copy;
 246
 247         copy("file1","file2");
 248         copy("Copy.pm",\*STDOUT);'
 249         move("/dev1/fileA","/dev2/fileB");
 250
 251         use POSIX;
 252         use File::Copy cp;
 253
 254         $n = FileHandle->new("/a/file","r");
 255         cp($n,"x");'
 256
 257 =head1 DESCRIPTION
 258
 259 The File::Copy module provides two basic functions, C<copy> and
 260 C<move>, which are useful for getting the contents of a file from
 261 one place to another.
 262
 263 =over 4
 264
 265 =item *
 266
 267 The C<copy> function takes two
 268 parameters: a file to copy from and a file to copy to. Either
 269 argument may be a string, a FileHandle reference or a FileHandle
 270 glob. Obviously, if the first argument is a filehandle of some
 271 sort, it will be read from, and if it is a file I<name> it will
 272 be opened for reading. Likewise, the second argument will be
 273 written to (and created if need be).
 274
 275 B<Note that passing in
 276 files as handles instead of names may lead to loss of information
 277 on some operating systems; it is recommended that you use file
 278 names whenever possible.>  Files are opened in binary mode where
 279 applicable.  To get a consistent behaviour when copying from a
 280 filehandle to a file, use C<binmode> on the filehandle.
 281
 282 An optional third parameter can be used to specify the buffer
 283 size used for copying. This is the number of bytes from the
 284 first file, that wil be held in memory at any given time, before
 285 being written to the second file. The default buffer size depends
 286 upon the file, but will generally be the whole file (up to 2Mb), or
 287 1k for filehandles that do not reference files (eg. sockets).
 288
 289 You may use the syntax C<use File::Copy "cp"> to get at the
 290 "cp" alias for this function. The syntax is I<exactly> the same.
 291
 292 =item *
 293
 294 The C<move> function also takes two parameters: the current name
 295 and the intended name of the file to be moved.  If the destination
 296 already exists and is a directory, and the source is not a
 297 directory, then the source file will be renamed into the directory
 298 specified by the destination.
 299
 300 If possible, move() will simply rename the file.  Otherwise, it copies
 301 the file to the new location and deletes the original.  If an error occurs
 302 during this copy-and-delete process, you may be left with a (possibly partial)
 303 copy of the file under the destination name.
 304
 305 You may use the "mv" alias for this function in the same way that
 306 you may use the "cp" alias for C<copy>.
 307
 308 =back
 309
 310 File::Copy also provides the C<syscopy> routine, which copies the
 311 file specified in the first parameter to the file specified in the
 312 second parameter, preserving OS-specific attributes and file
 313 structure.  For Unix systems, this is equivalent to the simple
 314 C<copy> routine.  For VMS systems, this calls the C<rmscopy>
 315 routine (see below).  For OS/2 systems, this calls the C<syscopy>
 316 XSUB directly. For Win32 systems, this calls C<Win32::CopyFile>.
 317
 318 =head2 Special behaviour if C<syscopy> is defined (OS/2, VMS and Win32)
 319
 320 If both arguments to C<copy> are not file handles,
 321 then C<copy> will perform a "system copy" of
 322 the input file to a new output file, in order to preserve file
 323 attributes, indexed file structure, I<etc.>  The buffer size
 324 parameter is ignored.  If either argument to C<copy> is a
 325 handle to an opened file, then data is copied using Perl
 326 operators, and no effort is made to preserve file attributes
 327 or record structure.
 328
 329 The system copy routine may also be called directly under VMS and OS/2
 330 as C<File::Copy::syscopy> (or under VMS as C<File::Copy::rmscopy>, which
 331 is the routine that does the actual work for syscopy).
 332
 333 =over 4
 334
 335 =item rmscopy($from,$to[,$date_flag])
 336
 337 The first and second arguments may be strings, typeglobs, typeglob
 338 references, or objects inheriting from IO::Handle;
 339 they are used in all cases to obtain the
 340 I<filespec> of the input and output files, respectively.  The
 341 name and type of the input file are used as defaults for the
 342 output file, if necessary.
 343
 344 A new version of the output file is always created, which
 345 inherits the structure and RMS attributes of the input file,
 346 except for owner and protections (and possibly timestamps;
 347 see below).  All data from the input file is copied to the
 348 output file; if either of the first two parameters to C<rmscopy>
 349 is a file handle, its position is unchanged.  (Note that this
 350 means a file handle pointing to the output file will be
 351 associated with an old version of that file after C<rmscopy>
 352 returns, not the newly created version.)
 353
 354 The third parameter is an integer flag, which tells C<rmscopy>
 355 how to handle timestamps.  If it is E<lt> 0, none of the input file's
 356 timestamps are propagated to the output file.  If it is E<gt> 0, then
 357 it is interpreted as a bitmask: if bit 0 (the LSB) is set, then
 358 timestamps other than the revision date are propagated; if bit 1
 359 is set, the revision date is propagated.  If the third parameter
 360 to C<rmscopy> is 0, then it behaves much like the DCL COPY command:
 361 if the name or type of the output file was explicitly specified,
 362 then no timestamps are propagated, but if they were taken implicitly
 363 from the input filespec, then all timestamps other than the
 364 revision date are propagated.  If this parameter is not supplied,
 365 it defaults to 0.
 366
 367 Like C<copy>, C<rmscopy> returns 1 on success.  If an error occurs,
 368 it sets C<$!>, deletes the output file, and returns 0.
 369
 370 =back
 371
 372 =head1 RETURN
 373
 374 All functions return 1 on success, 0 on failure.
 375 $! will be set if an error was encountered.
 376
 377 =head1 NOTES
 378
 379 =over 4
 380
 381 =item *
 382
 383 On Mac OS (Classic), the path separator is ':', not '/', and the
 384 current directory is denoted as ':', not '.'. You should be careful
 385 about specifying relative pathnames. While a full path always begins
 386 with a volume name, a relative pathname should always begin with a
 387 ':'.  If specifying a volume name only, a trailing ':' is required.
 388
 389 E.g.
 390
 391   copy("file1", "tmp");        # creates the file 'tmp' in the current directory
 392   copy("file1", ":tmp:");      # creates :tmp:file1
 393   copy("file1", ":tmp");       # same as above
 394   copy("file1", "tmp");        # same as above, if 'tmp' is a directory (but don't do
 395                                # that, since it may cause confusion, see example #1)
 396   copy("file1", "tmp:file1");  # error, since 'tmp:' is not a volume
 397   copy("file1", ":tmp:file1"); # ok, partial path
 398   copy("file1", "DataHD:");    # creates DataHD:file1
 399
 400   move("MacintoshHD:fileA", "DataHD:fileB"); # moves (don't copies) files from one
 401                                              # volume to another
 402
 403 =back
 404
 405 =head1 AUTHOR
 406
 407 File::Copy was written by Aaron Sherman I<E<lt>ajs@ajs.comE<gt>> in 1995,
 408 and updated by Charles Bailey I<E<lt>bailey@newman.upenn.eduE<gt>> in 1996.
 409
 410 =cut
 411