lib/perl5db.pl

   1
   2 =head1 NAME
   3
   4 perl5db.pl - the perl debugger
   5
   6 =head1 SYNOPSIS
   7
   8     perl -d  your_Perl_script
   9
  10 =head1 DESCRIPTION
  11
  12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
  13 you invoke a script with C<perl -d>. This documentation tries to outline the
  14 structure and services provided by C<perl5db.pl>, and to describe how you
  15 can use them.
  16
  17 =head1 GENERAL NOTES
  18
  19 The debugger can look pretty forbidding to many Perl programmers. There are
  20 a number of reasons for this, many stemming out of the debugger's history.
  21
  22 When the debugger was first written, Perl didn't have a lot of its nicer
  23 features - no references, no lexical variables, no closures, no object-oriented
  24 programming. So a lot of the things one would normally have done using such
  25 features was done using global variables, globs and the C<local()> operator
  26 in creative ways.
  27
  28 Some of these have survived into the current debugger; a few of the more
  29 interesting and still-useful idioms are noted in this section, along with notes
  30 on the comments themselves.
  31
  32 =head2 Why not use more lexicals?
  33
  34 Experienced Perl programmers will note that the debugger code tends to use
  35 mostly package globals rather than lexically-scoped variables. This is done
  36 to allow a significant amount of control of the debugger from outside the
  37 debugger itself.
  38
  39 Unfortunately, though the variables are accessible, they're not well
  40 documented, so it's generally been a decision that hasn't made a lot of
  41 difference to most users. Where appropriate, comments have been added to
  42 make variables more accessible and usable, with the understanding that these
  43 I<are> debugger internals, and are therefore subject to change. Future
  44 development should probably attempt to replace the globals with a well-defined
  45 API, but for now, the variables are what we've got.
  46
  47 =head2 Automated variable stacking via C<local()>
  48
  49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
  50 temporary copy of a variable in the current scope. When the scope ends, the
  51 old copy is restored. This is often used in the debugger to handle the
  52 automatic stacking of variables during recursive calls:
  53
  54      sub foo {
  55         local $some_global++;
  56
  57         # Do some stuff, then ...
  58         return;
  59      }
  60
  61 What happens is that on entry to the subroutine, C<$some_global> is localized,
  62 then altered. When the subroutine returns, Perl automatically undoes the
  63 localization, restoring the previous value. Voila, automatic stack management.
  64
  65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
  66 which lets the debugger get control inside of C<eval>'ed code. The debugger
  67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
  68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
  69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
  70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
  71
  72 In any case, watch for this pattern. It occurs fairly often.
  73
  74 =head2 The C<^> trick
  75
  76 This is used to cleverly reverse the sense of a logical test depending on
  77 the value of an auxiliary variable. For instance, the debugger's C<S>
  78 (search for subroutines by pattern) allows you to negate the pattern
  79 like this:
  80
  81    # Find all non-'foo' subs:
  82    S !/foo/
  83
  84 Boolean algebra states that the truth table for XOR looks like this:
  85
  86 =over 4
  87
  88 =item * 0 ^ 0 = 0
  89
  90 (! not present and no match) --> false, don't print
  91
  92 =item * 0 ^ 1 = 1
  93
  94 (! not present and matches) --> true, print
  95
  96 =item * 1 ^ 0 = 1
  97
  98 (! present and no match) --> true, print
  99
 100 =item * 1 ^ 1 = 0
 101
 102 (! present and matches) --> false, don't print
 103
 104 =back
 105
 106 As you can see, the first pair applies when C<!> isn't supplied, and
 107 the second pair applies when it is. The XOR simply allows us to
 108 compact a more complicated if-then-elseif-else into a more elegant
 109 (but perhaps overly clever) single test. After all, it needed this
 110 explanation...
 111
 112 =head2 FLAGS, FLAGS, FLAGS
 113
 114 There is a certain C programming legacy in the debugger. Some variables,
 115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
 116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
 117 of state to be stored independently in a single scalar.
 118
 119 A test like
 120
 121     if ($scalar & 4) ...
 122
 123 is checking to see if the appropriate bit is on. Since each bit can be
 124 "addressed" independently in this way, C<$scalar> is acting sort of like
 125 an array of bits. Obviously, since the contents of C<$scalar> are just a
 126 bit-pattern, we can save and restore it easily (it will just look like
 127 a number).
 128
 129 The problem, is of course, that this tends to leave magic numbers scattered
 130 all over your program whenever a bit is set, cleared, or checked. So why do
 131 it?
 132
 133 =over 4
 134
 135 =item *
 136
 137 First, doing an arithmetical or bitwise operation on a scalar is
 138 just about the fastest thing you can do in Perl: C<use constant> actually
 139 creates a subroutine call, and array and hash lookups are much slower. Is
 140 this over-optimization at the expense of readability? Possibly, but the
 141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
 142 probably have to benchmark alternate implementations and see which is the
 143 best balance of readability and speed, and then document how it actually
 144 works.
 145
 146 =item *
 147
 148 Second, it's very easy to serialize a scalar number. This is done in
 149 the restart code; the debugger state variables are saved in C<%ENV> and then
 150 restored when the debugger is restarted. Having them be just numbers makes
 151 this trivial.
 152
 153 =item *
 154
 155 Third, some of these variables are being shared with the Perl core
 156 smack in the middle of the interpreter's execution loop. It's much faster for
 157 a C program (like the interpreter) to check a bit in a scalar than to access
 158 several different variables (or a Perl array).
 159
 160 =back
 161
 162 =head2 What are those C<XXX> comments for?
 163
 164 Any comment containing C<XXX> means that the comment is either somewhat
 165 speculative - it's not exactly clear what a given variable or chunk of
 166 code is doing, or that it is incomplete - the basics may be clear, but the
 167 subtleties are not completely documented.
 168
 169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
 170
 171 =head1 DATA STRUCTURES MAINTAINED BY CORE
 172
 173 There are a number of special data structures provided to the debugger by
 174 the Perl interpreter.
 175
 176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
 177 via glob assignment) contains the text from C<$filename>, with each
 178 element corresponding to a single line of C<$filename>. Additionally,
 179 breakable lines will be dualvars with the numeric component being the
 180 memory address of a COP node. Non-breakable lines are dualvar to 0.
 181
 182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
 183 assignment) contains breakpoints and actions.  The keys are line numbers;
 184 you can set individual values, but not the whole hash. The Perl interpreter
 185 uses this hash to determine where breakpoints have been set. Any true value is
 186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
 187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
 188
 189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
 190 This is also the case for evaluated strings that contain subroutines, or
 191 which are currently being executed.  The $filename for C<eval>ed strings looks
 192 like C<(eval 34).
 193
 194 =head1 DEBUGGER STARTUP
 195
 196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
 197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
 198 of options. In addition, this file may define a subroutine C<&afterinit>
 199 that will be executed (in the debugger's context) after the debugger has
 200 initialized itself.
 201
 202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
 203 contents as the argument of a C<o> command in the debugger.
 204
 205 =head2 STARTUP-ONLY OPTIONS
 206
 207 The following options can only be specified at startup.
 208 To set them in your rcfile, add a call to
 209 C<&parse_options("optionName=new_value")>.
 210
 211 =over 4
 212
 213 =item * TTY
 214
 215 the TTY to use for debugging i/o.
 216
 217 =item * noTTY
 218
 219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
 220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
 221 Term::Rendezvous.  Current variant is to have the name of TTY in this
 222 file.
 223
 224 =item * ReadLine
 225
 226 if false, a dummy ReadLine is used, so you can debug
 227 ReadLine applications.
 228
 229 =item * NonStop
 230
 231 if true, no i/o is performed until interrupt.
 232
 233 =item * LineInfo
 234
 235 file or pipe to print line number info to.  If it is a
 236 pipe, a short "emacs like" message is used.
 237
 238 =item * RemotePort
 239
 240 host:port to connect to on remote host for remote debugging.
 241
 242 =item * HistFile
 243
 244 file to store session history to. There is no default and so no
 245 history file is written unless this variable is explicitly set.
 246
 247 =item * HistSize
 248
 249 number of commands to store to the file specified in C<HistFile>.
 250 Default is 100.
 251
 252 =back
 253
 254 =head3 SAMPLE RCFILE
 255
 256  &parse_options("NonStop=1 LineInfo=db.out");
 257   sub afterinit { $trace = 1; }
 258
 259 The script will run without human intervention, putting trace
 260 information into C<db.out>.  (If you interrupt it, you had better
 261 reset C<LineInfo> to something I<interactive>!)
 262
 263 =head1 INTERNALS DESCRIPTION
 264
 265 =head2 DEBUGGER INTERFACE VARIABLES
 266
 267 Perl supplies the values for C<%sub>.  It effectively inserts
 268 a C<&DB::DB();> in front of each place that can have a
 269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
 270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
 271 {require 'perl5db.pl'}> before the first line.
 272
 273 After each C<require>d file is compiled, but before it is executed, a
 274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
 275 is the expanded name of the C<require>d file (as found via C<%INC>).
 276
 277 =head3 IMPORTANT INTERNAL VARIABLES
 278
 279 =head4 C<$CreateTTY>
 280
 281 Used to control when the debugger will attempt to acquire another TTY to be
 282 used for input.
 283
 284 =over
 285
 286 =item * 1 -  on C<fork()>
 287
 288 =item * 2 - debugger is started inside debugger
 289
 290 =item * 4 -  on startup
 291
 292 =back
 293
 294 =head4 C<$doret>
 295
 296 The value -2 indicates that no return value should be printed.
 297 Any other positive value causes C<DB::sub> to print return values.
 298
 299 =head4 C<$evalarg>
 300
 301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
 302 contents of C<@_> when C<DB::eval> is called.
 303
 304 =head4 C<$frame>
 305
 306 Determines what messages (if any) will get printed when a subroutine (or eval)
 307 is entered or exited.
 308
 309 =over 4
 310
 311 =item * 0 -  No enter/exit messages
 312
 313 =item * 1 - Print I<entering> messages on subroutine entry
 314
 315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
 316
 317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
 318
 319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
 320
 321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
 322
 323 =back
 324
 325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
 326 The debugger internally juggles the value of C<$frame> during execution to
 327 protect external modules that the debugger uses from getting traced.
 328
 329 =head4 C<$level>
 330
 331 Tracks current debugger nesting level. Used to figure out how many
 332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
 333 outputs a prompt. Also used to help determine if the program has finished
 334 during command parsing.
 335
 336 =head4 C<$onetimeDump>
 337
 338 Controls what (if anything) C<DB::eval()> will print after evaluating an
 339 expression.
 340
 341 =over 4
 342
 343 =item * C<undef> - don't print anything
 344
 345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
 346
 347 =item * C<methods> - print the methods callable on the first item returned
 348
 349 =back
 350
 351 =head4 C<$onetimeDumpDepth>
 352
 353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
 354 dumping a structure. Numeric. If C<undef>, print all levels.
 355
 356 =head4 C<$signal>
 357
 358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
 359 which is called before every statement, checks this and puts the user into
 360 command mode if it finds C<$signal> set to a true value.
 361
 362 =head4 C<$single>
 363
 364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
 365 each subroutine; popped again at the end of each subroutine.
 366
 367 =over 4
 368
 369 =item * 0 - run continuously.
 370
 371 =item * 1 - single-step, go into subs. The C<s> command.
 372
 373 =item * 2 - single-step, don't go into subs. The C<n> command.
 374
 375 =item * 4 - print current sub depth (turned on to force this when C<too much
 376 recursion> occurs.
 377
 378 =back
 379
 380 =head4 C<$trace>
 381
 382 Controls the output of trace information.
 383
 384 =over 4
 385
 386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
 387
 388 =item * 2 - watch expressions are active
 389
 390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
 391
 392 =back
 393
 394 =head4 C<$slave_editor>
 395
 396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
 397
 398 =head4 C<@cmdfhs>
 399
 400 Stack of filehandles that C<DB::readline()> will read commands from.
 401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
 402
 403 =head4 C<@dbline>
 404
 405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
 406 supplied by the Perl interpreter to the debugger. Contains the source.
 407
 408 =head4 C<@old_watch>
 409
 410 Previous values of watch expressions. First set when the expression is
 411 entered; reset whenever the watch expression changes.
 412
 413 =head4 C<@saved>
 414
 415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
 416 so that the debugger can substitute safe values while it's running, and
 417 restore them when it returns control.
 418
 419 =head4 C<@stack>
 420
 421 Saves the current value of C<$single> on entry to a subroutine.
 422 Manipulated by the C<c> command to turn off tracing in all subs above the
 423 current one.
 424
 425 =head4 C<@to_watch>
 426
 427 The 'watch' expressions: to be evaluated before each line is executed.
 428
 429 =head4 C<@typeahead>
 430
 431 The typeahead buffer, used by C<DB::readline>.
 432
 433 =head4 C<%alias>
 434
 435 Command aliases. Stored as character strings to be substituted for a command
 436 entered.
 437
 438 =head4 C<%break_on_load>
 439
 440 Keys are file names, values are 1 (break when this file is loaded) or undef
 441 (don't break when it is loaded).
 442
 443 =head4 C<%dbline>
 444
 445 Keys are line numbers, values are C<condition\0action>. If used in numeric
 446 context, values are 0 if not breakable, 1 if breakable, no matter what is
 447 in the actual hash entry.
 448
 449 =head4 C<%had_breakpoints>
 450
 451 Keys are file names; values are bitfields:
 452
 453 =over 4
 454
 455 =item * 1 - file has a breakpoint in it.
 456
 457 =item * 2 - file has an action in it.
 458
 459 =back
 460
 461 A zero or undefined value means this file has neither.
 462
 463 =head4 C<%option>
 464
 465 Stores the debugger options. These are character string values.
 466
 467 =head4 C<%postponed>
 468
 469 Saves breakpoints for code that hasn't been compiled yet.
 470 Keys are subroutine names, values are:
 471
 472 =over 4
 473
 474 =item * C<compile> - break when this sub is compiled
 475
 476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
 477
 478 =back
 479
 480 =head4 C<%postponed_file>
 481
 482 This hash keeps track of breakpoints that need to be set for files that have
 483 not yet been compiled. Keys are filenames; values are references to hashes.
 484 Each of these hashes is keyed by line number, and its values are breakpoint
 485 definitions (C<condition\0action>).
 486
 487 =head1 DEBUGGER INITIALIZATION
 488
 489 The debugger's initialization actually jumps all over the place inside this
 490 package. This is because there are several BEGIN blocks (which of course
 491 execute immediately) spread through the code. Why is that?
 492
 493 The debugger needs to be able to change some things and set some things up
 494 before the debugger code is compiled; most notably, the C<$deep> variable that
 495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
 496 debugger has to turn off warnings while the debugger code is compiled, but then
 497 restore them to their original setting before the program being debugged begins
 498 executing.
 499
 500 The first C<BEGIN> block simply turns off warnings by saving the current
 501 setting of C<$^W> and then setting it to zero. The second one initializes
 502 the debugger variables that are needed before the debugger begins executing.
 503 The third one puts C<$^X> back to its former value.
 504
 505 We'll detail the second C<BEGIN> block later; just remember that if you need
 506 to initialize something before the debugger starts really executing, that's
 507 where it has to go.
 508
 509 =cut
 510
 511 package DB;
 512
 513 use strict;
 514
 515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
 516
 517 BEGIN {
 518     require feature;
 519     $^V =~ /^v(\d+\.\d+)/;
 520     feature->import(":$1");
 521 }
 522
 523 # Debugger for Perl 5.00x; perl5db.pl patch level:
 524 use vars qw($VERSION $header);
 525
 526 $VERSION = '1.39_05';
 527
 528 $header = "perl5db.pl version $VERSION";
 529
 530 =head1 DEBUGGER ROUTINES
 531
 532 =head2 C<DB::eval()>
 533
 534 This function replaces straight C<eval()> inside the debugger; it simplifies
 535 the process of evaluating code in the user's context.
 536
 537 The code to be evaluated is passed via the package global variable
 538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
 539
 540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
 541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
 542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
 543 user's current package, grabbed when C<DB::DB> got control.  This causes the
 544 proper context to be used when the eval is actually done.  Afterward, we
 545 restore C<$trace>, C<$single>, and C<$^D>.
 546
 547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
 548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
 549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
 550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
 551 considered sane by the debugger. If there was an C<eval()> error, we print
 552 it on the debugger's output. If C<$onetimedump> is defined, we call
 553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
 554 'methods'. Setting it to something else causes the debugger to do the eval
 555 but not print the result - handy if you want to do something else with it
 556 (the "watch expressions" code does this to get the value of the watch
 557 expression but not show it unless it matters).
 558
 559 In any case, we then return the list of output from C<eval> to the caller,
 560 and unwinding restores the former version of C<$@> in C<@saved> as well
 561 (the localization of C<$saved[0]> goes away at the end of this scope).
 562
 563 =head3 Parameters and variables influencing execution of DB::eval()
 564
 565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
 566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
 567 The variables listed below influence C<DB::eval()>'s execution directly.
 568
 569 =over 4
 570
 571 =item C<$evalarg> - the thing to actually be eval'ed
 572
 573 =item C<$trace> - Current state of execution tracing
 574
 575 =item C<$single> - Current state of single-stepping
 576
 577 =item C<$onetimeDump> - what is to be displayed after the evaluation
 578
 579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
 580
 581 =back
 582
 583 The following variables are altered by C<DB::eval()> during its execution. They
 584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
 585
 586 =over 4
 587
 588 =item C<@res> - used to capture output from actual C<eval>.
 589
 590 =item C<$otrace> - saved value of C<$trace>.
 591
 592 =item C<$osingle> - saved value of C<$single>.
 593
 594 =item C<$od> - saved value of C<$^D>.
 595
 596 =item C<$saved[0]> - saved value of C<$@>.
 597
 598 =item $\ - for output of C<$@> if there is an evaluation error.
 599
 600 =back
 601
 602 =head3 The problem of lexicals
 603
 604 The context of C<DB::eval()> presents us with some problems. Obviously,
 605 we want to be 'sandboxed' away from the debugger's internals when we do
 606 the eval, but we need some way to control how punctuation variables and
 607 debugger globals are used.
 608
 609 We can't use local, because the code inside C<DB::eval> can see localized
 610 variables; and we can't use C<my> either for the same reason. The code
 611 in this routine compromises and uses C<my>.
 612
 613 After this routine is over, we don't have user code executing in the debugger's
 614 context, so we can use C<my> freely.
 615
 616 =cut
 617
 618 ############################################## Begin lexical danger zone
 619
 620 # 'my' variables used here could leak into (that is, be visible in)
 621 # the context that the code being evaluated is executing in. This means that
 622 # the code could modify the debugger's variables.
 623 #
 624 # Fiddling with the debugger's context could be Bad. We insulate things as
 625 # much as we can.
 626
 627 use vars qw(
 628     @args
 629     %break_on_load
 630     $CommandSet
 631     $CreateTTY
 632     $DBGR
 633     @dbline
 634     $dbline
 635     %dbline
 636     $dieLevel
 637     $filename
 638     $histfile
 639     $histsize
 640     $IN
 641     $inhibit_exit
 642     @ini_INC
 643     $ini_warn
 644     $maxtrace
 645     $od
 646     @options
 647     $osingle
 648     $otrace
 649     $pager
 650     $post
 651     %postponed
 652     $prc
 653     $pre
 654     $pretype
 655     $psh
 656     @RememberOnROptions
 657     $remoteport
 658     @res
 659     $rl
 660     @saved
 661     $signalLevel
 662     $sub
 663     $term
 664     $usercontext
 665     $warnLevel
 666 );
 667
 668 our (
 669     @cmdfhs,
 670     $evalarg,
 671     $frame,
 672     $hist,
 673     $ImmediateStop,
 674     $line,
 675     $onetimeDump,
 676     $onetimedumpDepth,
 677     %option,
 678     $OUT,
 679     $packname,
 680     $signal,
 681     $single,
 682     $start,
 683     %sub,
 684     $subname,
 685     $trace,
 686     $window,
 687 );
 688
 689 # Used to save @ARGV and extract any debugger-related flags.
 690 use vars qw(@ARGS);
 691
 692 # Used to prevent multiple entries to diesignal()
 693 # (if for instance diesignal() itself dies)
 694 use vars qw($panic);
 695
 696 # Used to prevent the debugger from running nonstop
 697 # after a restart
 698 our ($second_time);
 699
 700 sub _calc_usercontext {
 701     my ($package) = @_;
 702
 703     # Cancel strict completely for the evaluated code, so the code
 704     # the user evaluates won't be affected by it. (Shlomi Fish)
 705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
 706     . "package $package;";    # this won't let them modify, alas
 707 }
 708
 709 sub eval {
 710
 711     # 'my' would make it visible from user code
 712     #    but so does local! --tchrist
 713     # Remember: this localizes @DB::res, not @main::res.
 714     local @res;
 715     {
 716
 717         # Try to keep the user code from messing  with us. Save these so that
 718         # even if the eval'ed code changes them, we can put them back again.
 719         # Needed because the user could refer directly to the debugger's
 720         # package globals (and any 'my' variables in this containing scope)
 721         # inside the eval(), and we want to try to stay safe.
 722         local $otrace  = $trace;
 723         local $osingle = $single;
 724         local $od      = $^D;
 725
 726         # Untaint the incoming eval() argument.
 727         { ($evalarg) = $evalarg =~ /(.*)/s; }
 728
 729         # $usercontext built in DB::DB near the comment
 730         # "set up the context for DB::eval ..."
 731         # Evaluate and save any results.
 732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
 733
 734         # Restore those old values.
 735         $trace  = $otrace;
 736         $single = $osingle;
 737         $^D     = $od;
 738     }
 739
 740     # Save the current value of $@, and preserve it in the debugger's copy
 741     # of the saved precious globals.
 742     my $at = $@;
 743
 744     # Since we're only saving $@, we only have to localize the array element
 745     # that it will be stored in.
 746     local $saved[0];    # Preserve the old value of $@
 747     eval { DB::save() };
 748
 749     # Now see whether we need to report an error back to the user.
 750     if ($at) {
 751         local $\ = '';
 752         print $OUT $at;
 753     }
 754
 755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
 756     # are package globals.
 757     elsif ($onetimeDump) {
 758         if ( $onetimeDump eq 'dump' ) {
 759             local $option{dumpDepth} = $onetimedumpDepth
 760               if defined $onetimedumpDepth;
 761             dumpit( $OUT, \@res );
 762         }
 763         elsif ( $onetimeDump eq 'methods' ) {
 764             methods( $res[0] );
 765         }
 766     } ## end elsif ($onetimeDump)
 767     @res;
 768 } ## end sub eval
 769
 770 ############################################## End lexical danger zone
 771
 772 # After this point it is safe to introduce lexicals.
 773 # The code being debugged will be executing in its own context, and
 774 # can't see the inside of the debugger.
 775 #
 776 # However, one should not overdo it: leave as much control from outside as
 777 # possible. If you make something a lexical, it's not going to be addressable
 778 # from outside the debugger even if you know its name.
 779
 780 # This file is automatically included if you do perl -d.
 781 # It's probably not useful to include this yourself.
 782 #
 783 # Before venturing further into these twisty passages, it is
 784 # wise to read the perldebguts man page or risk the ire of dragons.
 785 #
 786 # (It should be noted that perldebguts will tell you a lot about
 787 # the underlying mechanics of how the debugger interfaces into the
 788 # Perl interpreter, but not a lot about the debugger itself. The new
 789 # comments in this code try to address this problem.)
 790
 791 # Note that no subroutine call is possible until &DB::sub is defined
 792 # (for subroutines defined outside of the package DB). In fact the same is
 793 # true if $deep is not defined.
 794
 795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
 796
 797 # modified Perl debugger, to be run from Emacs in perldb-mode
 798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
 799 # Johan Vromans -- upgrade to 4.0 pl 10
 800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
 801 ########################################################################
 802
 803 =head1 DEBUGGER INITIALIZATION
 804
 805 The debugger starts up in phases.
 806
 807 =head2 BASIC SETUP
 808
 809 First, it initializes the environment it wants to run in: turning off
 810 warnings during its own compilation, defining variables which it will need
 811 to avoid warnings later, setting itself up to not exit when the program
 812 terminates, and defaulting to printing return values for the C<r> command.
 813
 814 =cut
 815
 816 # Needed for the statement after exec():
 817 #
 818 # This BEGIN block is simply used to switch off warnings during debugger
 819 # compilation. Probably it would be better practice to fix the warnings,
 820 # but this is how it's done at the moment.
 821
 822 BEGIN {
 823     $ini_warn = $^W;
 824     $^W       = 0;
 825 }    # Switch compilation warnings off until another BEGIN.
 826
 827 local ($^W) = 0;    # Switch run-time warnings off during init.
 828
 829 =head2 THREADS SUPPORT
 830
 831 If we are running under a threaded Perl, we require threads and threads::shared
 832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
 833 threaded debugger control.  C<-dt> can also be used to set this.
 834
 835 Each new thread will be announced and the debugger prompt will always inform
 836 you of each new thread created.  It will also indicate the thread id in which
 837 we are currently running within the prompt like this:
 838
 839     [tid] DB<$i>
 840
 841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
 842 command prompt.  The prompt will show: C<[0]> when running under threads, but
 843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
 844
 845 While running under threads, when you set or delete a breakpoint (etc.), this
 846 will apply to all threads, not just the currently running one.  When you are
 847 in a currently executing thread, you will stay there until it completes.  With
 848 the current implementation it is not currently possible to hop from one thread
 849 to another.
 850
 851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
 852
 853 Note that threading support was built into the debugger as of Perl version
 854 C<5.8.6> and debugger version C<1.2.8>.
 855
 856 =cut
 857
 858 BEGIN {
 859     # ensure we can share our non-threaded variables or no-op
 860     if ($ENV{PERL5DB_THREADED}) {
 861         require threads;
 862         require threads::shared;
 863         import threads::shared qw(share);
 864         $DBGR;
 865         share(\$DBGR);
 866         lock($DBGR);
 867         print "Threads support enabled\n";
 868     } else {
 869         *share = sub(\[$@%]) {};
 870     }
 871 }
 872
 873 # These variables control the execution of 'dumpvar.pl'.
 874 {
 875     package dumpvar;
 876     use vars qw(
 877     $hashDepth
 878     $arrayDepth
 879     $dumpDBFiles
 880     $dumpPackages
 881     $quoteHighBit
 882     $printUndef
 883     $globPrint
 884     $usageOnly
 885     );
 886 }
 887
 888 # used to control die() reporting in diesignal()
 889 {
 890     package Carp;
 891     use vars qw($CarpLevel);
 892 }
 893
 894 # without threads, $filename is not defined until DB::DB is called
 895 share($main::{'_<'.$filename}) if defined $filename;
 896
 897 # Command-line + PERLLIB:
 898 # Save the contents of @INC before they are modified elsewhere.
 899 @ini_INC = @INC;
 900
 901 # This was an attempt to clear out the previous values of various
 902 # trapped errors. Apparently it didn't help. XXX More info needed!
 903 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
 904
 905 # We set these variables to safe values. We don't want to blindly turn
 906 # off warnings, because other packages may still want them.
 907 $trace = $signal = $single = 0;    # Uninitialized warning suppression
 908                                    # (local $^W cannot help - other packages!).
 909
 910 # Default to not exiting when program finishes; print the return
 911 # value when the 'r' command is used to return from a subroutine.
 912 $inhibit_exit = $option{PrintRet} = 1;
 913
 914 use vars qw($trace_to_depth);
 915
 916 # Default to 1E9 so it won't be limited to a certain recursion depth.
 917 $trace_to_depth = 1E9;
 918
 919 =head1 OPTION PROCESSING
 920
 921 The debugger's options are actually spread out over the debugger itself and
 922 C<dumpvar.pl>; some of these are variables to be set, while others are
 923 subs to be called with a value. To try to make this a little easier to
 924 manage, the debugger uses a few data structures to define what options
 925 are legal and how they are to be processed.
 926
 927 First, the C<@options> array defines the I<names> of all the options that
 928 are to be accepted.
 929
 930 =cut
 931
 932 @options = qw(
 933   CommandSet   HistFile      HistSize
 934   hashDepth    arrayDepth    dumpDepth
 935   DumpDBFiles  DumpPackages  DumpReused
 936   compactDump  veryCompact   quote
 937   HighBit      undefPrint    globPrint
 938   PrintRet     UsageOnly     frame
 939   AutoTrace    TTY           noTTY
 940   ReadLine     NonStop       LineInfo
 941   maxTraceLen  recallCommand ShellBang
 942   pager        tkRunning     ornaments
 943   signalLevel  warnLevel     dieLevel
 944   inhibit_exit ImmediateStop bareStringify
 945   CreateTTY    RemotePort    windowSize
 946   DollarCaretP
 947 );
 948
 949 @RememberOnROptions = qw(DollarCaretP);
 950
 951 =pod
 952
 953 Second, C<optionVars> lists the variables that each option uses to save its
 954 state.
 955
 956 =cut
 957
 958 use vars qw(%optionVars);
 959
 960 %optionVars = (
 961     hashDepth     => \$dumpvar::hashDepth,
 962     arrayDepth    => \$dumpvar::arrayDepth,
 963     CommandSet    => \$CommandSet,
 964     DumpDBFiles   => \$dumpvar::dumpDBFiles,
 965     DumpPackages  => \$dumpvar::dumpPackages,
 966     DumpReused    => \$dumpvar::dumpReused,
 967     HighBit       => \$dumpvar::quoteHighBit,
 968     undefPrint    => \$dumpvar::printUndef,
 969     globPrint     => \$dumpvar::globPrint,
 970     UsageOnly     => \$dumpvar::usageOnly,
 971     CreateTTY     => \$CreateTTY,
 972     bareStringify => \$dumpvar::bareStringify,
 973     frame         => \$frame,
 974     AutoTrace     => \$trace,
 975     inhibit_exit  => \$inhibit_exit,
 976     maxTraceLen   => \$maxtrace,
 977     ImmediateStop => \$ImmediateStop,
 978     RemotePort    => \$remoteport,
 979     windowSize    => \$window,
 980     HistFile      => \$histfile,
 981     HistSize      => \$histsize,
 982 );
 983
 984 =pod
 985
 986 Third, C<%optionAction> defines the subroutine to be called to process each
 987 option.
 988
 989 =cut
 990
 991 use vars qw(%optionAction);
 992
 993 %optionAction = (
 994     compactDump   => \&dumpvar::compactDump,
 995     veryCompact   => \&dumpvar::veryCompact,
 996     quote         => \&dumpvar::quote,
 997     TTY           => \&TTY,
 998     noTTY         => \&noTTY,
 999     ReadLine      => \&ReadLine,
1000     NonStop       => \&NonStop,
1001     LineInfo      => \&LineInfo,
1002     recallCommand => \&recallCommand,
1003     ShellBang     => \&shellBang,
1004     pager         => \&pager,
1005     signalLevel   => \&signalLevel,
1006     warnLevel     => \&warnLevel,
1007     dieLevel      => \&dieLevel,
1008     tkRunning     => \&tkRunning,
1009     ornaments     => \&ornaments,
1010     RemotePort    => \&RemotePort,
1011     DollarCaretP  => \&DollarCaretP,
1012 );
1013
1014 =pod
1015
1016 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1017 option is used.
1018
1019 =cut
1020
1021 # Note that this list is not complete: several options not listed here
1022 # actually require that dumpvar.pl be loaded for them to work, but are
1023 # not in the table. A subsequent patch will correct this problem; for
1024 # the moment, we're just recommenting, and we are NOT going to change
1025 # function.
1026 use vars qw(%optionRequire);
1027
1028 %optionRequire = (
1029     compactDump => 'dumpvar.pl',
1030     veryCompact => 'dumpvar.pl',
1031     quote       => 'dumpvar.pl',
1032 );
1033
1034 =pod
1035
1036 There are a number of initialization-related variables which can be set
1037 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1038 variable. These are:
1039
1040 =over 4
1041
1042 =item C<$rl> - readline control XXX needs more explanation
1043
1044 =item C<$warnLevel> - whether or not debugger takes over warning handling
1045
1046 =item C<$dieLevel> - whether or not debugger takes over die handling
1047
1048 =item C<$signalLevel> - whether or not debugger takes over signal handling
1049
1050 =item C<$pre> - preprompt actions (array reference)
1051
1052 =item C<$post> - postprompt actions (array reference)
1053
1054 =item C<$pretype>
1055
1056 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1057
1058 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1059
1060 =back
1061
1062 =cut
1063
1064 # These guys may be defined in $ENV{PERL5DB} :
1065 $rl          = 1     unless defined $rl;
1066 $warnLevel   = 1     unless defined $warnLevel;
1067 $dieLevel    = 1     unless defined $dieLevel;
1068 $signalLevel = 1     unless defined $signalLevel;
1069 $pre         = []    unless defined $pre;
1070 $post        = []    unless defined $post;
1071 $pretype     = []    unless defined $pretype;
1072 $CreateTTY   = 3     unless defined $CreateTTY;
1073 $CommandSet  = '580' unless defined $CommandSet;
1074
1075 share($rl);
1076 share($warnLevel);
1077 share($dieLevel);
1078 share($signalLevel);
1079 share($pre);
1080 share($post);
1081 share($pretype);
1082 share($rl);
1083 share($CreateTTY);
1084 share($CommandSet);
1085
1086 =pod
1087
1088 The default C<die>, C<warn>, and C<signal> handlers are set up.
1089
1090 =cut
1091
1092 warnLevel($warnLevel);
1093 dieLevel($dieLevel);
1094 signalLevel($signalLevel);
1095
1096 =pod
1097
1098 The pager to be used is needed next. We try to get it from the
1099 environment first.  If it's not defined there, we try to find it in
1100 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1101 then call the C<pager()> function to save the pager name.
1102
1103 =cut
1104
1105 # This routine makes sure $pager is set up so that '|' can use it.
1106 pager(
1107
1108     # If PAGER is defined in the environment, use it.
1109     defined $ENV{PAGER}
1110     ? $ENV{PAGER}
1111
1112       # If not, see if Config.pm defines it.
1113     : eval { require Config }
1114       && defined $Config::Config{pager}
1115     ? $Config::Config{pager}
1116
1117       # If not, fall back to 'more'.
1118     : 'more'
1119   )
1120   unless defined $pager;
1121
1122 =pod
1123
1124 We set up the command to be used to access the man pages, the command
1125 recall character (C<!> unless otherwise defined) and the shell escape
1126 character (C<!> unless otherwise defined). Yes, these do conflict, and
1127 neither works in the debugger at the moment.
1128
1129 =cut
1130
1131 setman();
1132
1133 # Set up defaults for command recall and shell escape (note:
1134 # these currently don't work in linemode debugging).
1135 recallCommand("!") unless defined $prc;
1136 shellBang("!")     unless defined $psh;
1137
1138 =pod
1139
1140 We then set up the gigantic string containing the debugger help.
1141 We also set the limit on the number of arguments we'll display during a
1142 trace.
1143
1144 =cut
1145
1146 sethelp();
1147
1148 # If we didn't get a default for the length of eval/stack trace args,
1149 # set it here.
1150 $maxtrace = 400 unless defined $maxtrace;
1151
1152 =head2 SETTING UP THE DEBUGGER GREETING
1153
1154 The debugger I<greeting> helps to inform the user how many debuggers are
1155 running, and whether the current debugger is the primary or a child.
1156
1157 If we are the primary, we just hang onto our pid so we'll have it when
1158 or if we start a child debugger. If we are a child, we'll set things up
1159 so we'll have a unique greeting and so the parent will give us our own
1160 TTY later.
1161
1162 We save the current contents of the C<PERLDB_PIDS> environment variable
1163 because we mess around with it. We'll also need to hang onto it because
1164 we'll need it if we restart.
1165
1166 Child debuggers make a label out of the current PID structure recorded in
1167 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1168 yet so the parent will give them one later via C<resetterm()>.
1169
1170 =cut
1171
1172 # Save the current contents of the environment; we're about to
1173 # much with it. We'll need this if we have to restart.
1174 use vars qw($ini_pids);
1175 $ini_pids = $ENV{PERLDB_PIDS};
1176
1177 use vars qw ($pids $term_pid);
1178
1179 if ( defined $ENV{PERLDB_PIDS} ) {
1180
1181     # We're a child. Make us a label out of the current PID structure
1182     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1183     # a term yet so the parent will give us one later via resetterm().
1184
1185     my $env_pids = $ENV{PERLDB_PIDS};
1186     $pids = "[$env_pids]";
1187
1188     # Unless we are on OpenVMS, all programs under the DCL shell run under
1189     # the same PID.
1190
1191     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1192         $term_pid         = $$;
1193     }
1194     else {
1195         $ENV{PERLDB_PIDS} .= "->$$";
1196         $term_pid = -1;
1197     }
1198
1199 } ## end if (defined $ENV{PERLDB_PIDS...
1200 else {
1201
1202     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1203     # child debugger, and mark us as the parent, so we'll know to set up
1204     # more TTY's is we have to.
1205     $ENV{PERLDB_PIDS} = "$$";
1206     $pids             = "[pid=$$]";
1207     $term_pid         = $$;
1208 }
1209
1210 use vars qw($pidprompt);
1211 $pidprompt = '';
1212
1213 # Sets up $emacs as a synonym for $slave_editor.
1214 our ($slave_editor);
1215 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1216
1217 =head2 READING THE RC FILE
1218
1219 The debugger will read a file of initialization options if supplied. If
1220 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1221
1222 =cut
1223
1224 # As noted, this test really doesn't check accurately that the debugger
1225 # is running at a terminal or not.
1226
1227 use vars qw($rcfile);
1228 {
1229     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1230     # this is the wrong metric!
1231     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1232 }
1233
1234 =pod
1235
1236 The debugger does a safety test of the file to be read. It must be owned
1237 either by the current user or root, and must only be writable by the owner.
1238
1239 =cut
1240
1241 # This wraps a safety test around "do" to read and evaluate the init file.
1242 #
1243 # This isn't really safe, because there's a race
1244 # between checking and opening.  The solution is to
1245 # open and fstat the handle, but then you have to read and
1246 # eval the contents.  But then the silly thing gets
1247 # your lexical scope, which is unfortunate at best.
1248 sub safe_do {
1249     my $file = shift;
1250
1251     # Just exactly what part of the word "CORE::" don't you understand?
1252     local $SIG{__WARN__};
1253     local $SIG{__DIE__};
1254
1255     unless ( is_safe_file($file) ) {
1256         CORE::warn <<EO_GRIPE;
1257 perldb: Must not source insecure rcfile $file.
1258         You or the superuser must be the owner, and it must not
1259         be writable by anyone but its owner.
1260 EO_GRIPE
1261         return;
1262     } ## end unless (is_safe_file($file...
1263
1264     do $file;
1265     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1266 } ## end sub safe_do
1267
1268 # This is the safety test itself.
1269 #
1270 # Verifies that owner is either real user or superuser and that no
1271 # one but owner may write to it.  This function is of limited use
1272 # when called on a path instead of upon a handle, because there are
1273 # no guarantees that filename (by dirent) whose file (by ino) is
1274 # eventually accessed is the same as the one tested.
1275 # Assumes that the file's existence is not in doubt.
1276 sub is_safe_file {
1277     my $path = shift;
1278     stat($path) || return;    # mysteriously vaporized
1279     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1280
1281     return 0 if $uid != 0 && $uid != $<;
1282     return 0 if $mode & 022;
1283     return 1;
1284 } ## end sub is_safe_file
1285
1286 # If the rcfile (whichever one we decided was the right one to read)
1287 # exists, we safely do it.
1288 if ( -f $rcfile ) {
1289     safe_do("./$rcfile");
1290 }
1291
1292 # If there isn't one here, try the user's home directory.
1293 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1294     safe_do("$ENV{HOME}/$rcfile");
1295 }
1296
1297 # Else try the login directory.
1298 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1299     safe_do("$ENV{LOGDIR}/$rcfile");
1300 }
1301
1302 # If the PERLDB_OPTS variable has options in it, parse those out next.
1303 if ( defined $ENV{PERLDB_OPTS} ) {
1304     parse_options( $ENV{PERLDB_OPTS} );
1305 }
1306
1307 =pod
1308
1309 The last thing we do during initialization is determine which subroutine is
1310 to be used to obtain a new terminal when a new debugger is started. Right now,
1311 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1312 (darwin).
1313
1314 =cut
1315
1316 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1317 # Works if you're running an xterm or xterm-like window, or you're on
1318 # OS/2, or on Mac OS X. This may need some expansion.
1319
1320 if (not defined &get_fork_TTY)       # only if no routine exists
1321 {
1322     if ( defined $remoteport ) {
1323                                                  # Expect an inetd-like server
1324         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1325     }
1326     elsif (defined $ENV{TERM}                    # If we know what kind
1327                                                  # of terminal this is,
1328         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1329         and defined $ENV{DISPLAY}                # and what display it's on,
1330       )
1331     {
1332         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1333     }
1334     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1335         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1336     }
1337     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1338             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1339             and $ENV{TERM_PROGRAM}
1340                 eq 'Apple_Terminal'              # Terminal.app
1341             )
1342     {
1343         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1344     }
1345 } ## end if (not defined &get_fork_TTY...
1346
1347 # untaint $^O, which may have been tainted by the last statement.
1348 # see bug [perl #24674]
1349 $^O =~ m/^(.*)\z/;
1350 $^O = $1;
1351
1352 # Here begin the unreadable code.  It needs fixing.
1353
1354 =head2 RESTART PROCESSING
1355
1356 This section handles the restart command. When the C<R> command is invoked, it
1357 tries to capture all of the state it can into environment variables, and
1358 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1359 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1360 the R command stuffed into the environment variables.
1361
1362   PERLDB_RESTART   - flag only, contains no restart data itself.
1363   PERLDB_HIST      - command history, if it's available
1364   PERLDB_ON_LOAD   - breakpoints set by the rc file
1365   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1366   PERLDB_VISITED   - files that had breakpoints
1367   PERLDB_FILE_...  - breakpoints for a file
1368   PERLDB_OPT       - active options
1369   PERLDB_INC       - the original @INC
1370   PERLDB_PRETYPE   - preprompt debugger actions
1371   PERLDB_PRE       - preprompt Perl code
1372   PERLDB_POST      - post-prompt Perl code
1373   PERLDB_TYPEAHEAD - typeahead captured by readline()
1374
1375 We chug through all these variables and plug the values saved in them
1376 back into the appropriate spots in the debugger.
1377
1378 =cut
1379
1380 use vars qw(%postponed_file @typeahead);
1381
1382 our (@hist, @truehist);
1383
1384 sub _restore_shared_globals_after_restart
1385 {
1386     @hist          = get_list('PERLDB_HIST');
1387     %break_on_load = get_list("PERLDB_ON_LOAD");
1388     %postponed     = get_list("PERLDB_POSTPONE");
1389
1390     share(@hist);
1391     share(@truehist);
1392     share(%break_on_load);
1393     share(%postponed);
1394 }
1395
1396 sub _restore_breakpoints_and_actions {
1397
1398     my @had_breakpoints = get_list("PERLDB_VISITED");
1399
1400     for my $file_idx ( 0 .. $#had_breakpoints ) {
1401         my $filename = $had_breakpoints[$file_idx];
1402         my %pf = get_list("PERLDB_FILE_$file_idx");
1403         $postponed_file{ $filename } = \%pf if %pf;
1404         my @lines = sort {$a <=> $b} keys(%pf);
1405         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1406         for my $line_idx (0 .. $#lines) {
1407             _set_breakpoint_enabled_status(
1408                 $filename,
1409                 $lines[$line_idx],
1410                 ($enabled_statuses[$line_idx] ? 1 : ''),
1411             );
1412         }
1413     }
1414
1415     return;
1416 }
1417
1418 sub _restore_options_after_restart
1419 {
1420     my %options_map = get_list("PERLDB_OPT");
1421
1422     while ( my ( $opt, $val ) = each %options_map ) {
1423         $val =~ s/[\\\']/\\$1/g;
1424         parse_options("$opt'$val'");
1425     }
1426
1427     return;
1428 }
1429
1430 sub _restore_globals_after_restart
1431 {
1432     # restore original @INC
1433     @INC     = get_list("PERLDB_INC");
1434     @ini_INC = @INC;
1435
1436     # return pre/postprompt actions and typeahead buffer
1437     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1438     $pre       = [ get_list("PERLDB_PRE") ];
1439     $post      = [ get_list("PERLDB_POST") ];
1440     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1441
1442     return;
1443 }
1444
1445
1446 if ( exists $ENV{PERLDB_RESTART} ) {
1447
1448     # We're restarting, so we don't need the flag that says to restart anymore.
1449     delete $ENV{PERLDB_RESTART};
1450
1451     # $restart = 1;
1452     _restore_shared_globals_after_restart();
1453
1454     _restore_breakpoints_and_actions();
1455
1456     # restore options
1457     _restore_options_after_restart();
1458
1459     _restore_globals_after_restart();
1460 } ## end if (exists $ENV{PERLDB_RESTART...
1461
1462 =head2 SETTING UP THE TERMINAL
1463
1464 Now, we'll decide how the debugger is going to interact with the user.
1465 If there's no TTY, we set the debugger to run non-stop; there's not going
1466 to be anyone there to enter commands.
1467
1468 =cut
1469
1470 use vars qw($notty $console $tty $LINEINFO);
1471 use vars qw($lineinfo $doccmd);
1472
1473 our ($runnonstop);
1474
1475 if ($notty) {
1476     $runnonstop = 1;
1477     share($runnonstop);
1478 }
1479
1480 =pod
1481
1482 If there is a TTY, we have to determine who it belongs to before we can
1483 proceed. If this is a slave editor or graphical debugger (denoted by
1484 the first command-line switch being '-emacs'), we shift this off and
1485 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1486
1487 =cut
1488
1489 else {
1490
1491     # Is Perl being run from a slave editor or graphical debugger?
1492     # If so, don't use readline, and set $slave_editor = 1.
1493     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1494         $rl = 0;
1495         shift(@main::ARGV);
1496     }
1497
1498     #require Term::ReadLine;
1499
1500 =pod
1501
1502 We then determine what the console should be on various systems:
1503
1504 =over 4
1505
1506 =item * Cygwin - We use C<stdin> instead of a separate device.
1507
1508 =cut
1509
1510     if ( $^O eq 'cygwin' ) {
1511
1512         # /dev/tty is binary. use stdin for textmode
1513         undef $console;
1514     }
1515
1516 =item * Unix - use C</dev/tty>.
1517
1518 =cut
1519
1520     elsif ( -e "/dev/tty" ) {
1521         $console = "/dev/tty";
1522     }
1523
1524 =item * Windows or MSDOS - use C<con>.
1525
1526 =cut
1527
1528     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1529         $console = "con";
1530     }
1531
1532 =item * VMS - use C<sys$command>.
1533
1534 =cut
1535
1536     else {
1537
1538         # everything else is ...
1539         $console = "sys\$command";
1540     }
1541
1542 =pod
1543
1544 =back
1545
1546 Several other systems don't use a specific console. We C<undef $console>
1547 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1548 with a slave editor, Epoc).
1549
1550 =cut
1551
1552     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1553
1554         # /dev/tty is binary. use stdin for textmode
1555         $console = undef;
1556     }
1557
1558     if ( $^O eq 'NetWare' ) {
1559
1560         # /dev/tty is binary. use stdin for textmode
1561         $console = undef;
1562     }
1563
1564     # In OS/2, we need to use STDIN to get textmode too, even though
1565     # it pretty much looks like Unix otherwise.
1566     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1567     {    # In OS/2
1568         $console = undef;
1569     }
1570
1571     # EPOC also falls into the 'got to use STDIN' camp.
1572     if ( $^O eq 'epoc' ) {
1573         $console = undef;
1574     }
1575
1576 =pod
1577
1578 If there is a TTY hanging around from a parent, we use that as the console.
1579
1580 =cut
1581
1582     $console = $tty if defined $tty;
1583
1584 =head2 SOCKET HANDLING
1585
1586 The debugger is capable of opening a socket and carrying out a debugging
1587 session over the socket.
1588
1589 If C<RemotePort> was defined in the options, the debugger assumes that it
1590 should try to start a debugging session on that port. It builds the socket
1591 and then tries to connect the input and output filehandles to it.
1592
1593 =cut
1594
1595     # Handle socket stuff.
1596
1597     if ( defined $remoteport ) {
1598
1599         # If RemotePort was defined in the options, connect input and output
1600         # to the socket.
1601         $IN = $OUT = connect_remoteport();
1602     } ## end if (defined $remoteport)
1603
1604 =pod
1605
1606 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1607 this is probably a situation where multiple debuggers are running (for example,
1608 a backticked command that starts up another debugger). We create a new IN and
1609 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1610 and if we can.
1611
1612 =cut
1613
1614     # Non-socket.
1615     else {
1616
1617         # Two debuggers running (probably a system or a backtick that invokes
1618         # the debugger itself under the running one). create a new IN and OUT
1619         # filehandle, and do the necessary mojo to create a new tty if we
1620         # know how, and we can.
1621         create_IN_OUT(4) if $CreateTTY & 4;
1622         if ($console) {
1623
1624             # If we have a console, check to see if there are separate ins and
1625             # outs to open. (They are assumed identical if not.)
1626
1627             my ( $i, $o ) = split /,/, $console;
1628             $o = $i unless defined $o;
1629
1630             # read/write on in, or just read, or read on STDIN.
1631             open( IN,      "+<$i" )
1632               || open( IN, "<$i" )
1633               || open( IN, "<&STDIN" );
1634
1635             # read/write/create/clobber out, or write/create/clobber out,
1636             # or merge with STDERR, or merge with STDOUT.
1637                  open( OUT, "+>$o" )
1638               || open( OUT, ">$o" )
1639               || open( OUT, ">&STDERR" )
1640               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1641
1642         } ## end if ($console)
1643         elsif ( not defined $console ) {
1644
1645             # No console. Open STDIN.
1646             open( IN, "<&STDIN" );
1647
1648             # merge with STDERR, or with STDOUT.
1649             open( OUT,      ">&STDERR" )
1650               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1651             $console = 'STDIN/OUT';
1652         } ## end elsif (not defined $console)
1653
1654         # Keep copies of the filehandles so that when the pager runs, it
1655         # can close standard input without clobbering ours.
1656         if ($console or (not defined($console))) {
1657             $IN = \*IN;
1658             $OUT = \*OUT;
1659         }
1660     } ## end elsif (from if(defined $remoteport))
1661
1662     # Unbuffer DB::OUT. We need to see responses right away.
1663     $OUT->autoflush(1);
1664
1665     # Line info goes to debugger output unless pointed elsewhere.
1666     # Pointing elsewhere makes it possible for slave editors to
1667     # keep track of file and position. We have both a filehandle
1668     # and a I/O description to keep track of.
1669     $LINEINFO = $OUT     unless defined $LINEINFO;
1670     $lineinfo = $console unless defined $lineinfo;
1671     # share($LINEINFO); # <- unable to share globs
1672     share($lineinfo);   #
1673
1674 =pod
1675
1676 To finish initialization, we show the debugger greeting,
1677 and then call the C<afterinit()> subroutine if there is one.
1678
1679 =cut
1680
1681     # Show the debugger greeting.
1682     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1683     unless ($runnonstop) {
1684         local $\ = '';
1685         local $, = '';
1686         if ( $term_pid eq '-1' ) {
1687             print $OUT "\nDaughter DB session started...\n";
1688         }
1689         else {
1690             print $OUT "\nLoading DB routines from $header\n";
1691             print $OUT (
1692                 "Editor support ",
1693                 $slave_editor ? "enabled" : "available", ".\n"
1694             );
1695             print $OUT
1696 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1697         } ## end else [ if ($term_pid eq '-1')
1698     } ## end unless ($runnonstop)
1699 } ## end else [ if ($notty)
1700
1701 # XXX This looks like a bug to me.
1702 # Why copy to @ARGS and then futz with @args?
1703 @ARGS = @ARGV;
1704 # for (@args) {
1705     # Make sure backslashes before single quotes are stripped out, and
1706     # keep args unless they are numeric (XXX why?)
1707     # s/\'/\\\'/g;                      # removed while not justified understandably
1708     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1709 # }
1710
1711 # If there was an afterinit() sub defined, call it. It will get
1712 # executed in our scope, so it can fiddle with debugger globals.
1713 if ( defined &afterinit ) {    # May be defined in $rcfile
1714     afterinit();
1715 }
1716
1717 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1718 use vars qw($I_m_init);
1719
1720 $I_m_init = 1;
1721
1722 ############################################################ Subroutines
1723
1724 =head1 SUBROUTINES
1725
1726 =head2 DB
1727
1728 This gigantic subroutine is the heart of the debugger. Called before every
1729 statement, its job is to determine if a breakpoint has been reached, and
1730 stop if so; read commands from the user, parse them, and execute
1731 them, and then send execution off to the next statement.
1732
1733 Note that the order in which the commands are processed is very important;
1734 some commands earlier in the loop will actually alter the C<$cmd> variable
1735 to create other commands to be executed later. This is all highly I<optimized>
1736 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1737 see what's happening in any given command.
1738
1739 =cut
1740
1741 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1742
1743 use vars qw(
1744     $action
1745     $cmd
1746     $file
1747     $filename_ini
1748     $finished
1749     %had_breakpoints
1750     $level
1751     $max
1752     $package
1753     $try
1754 );
1755
1756 our (
1757     %alias,
1758     $doret,
1759     $end,
1760     $fall_off_end,
1761     $incr,
1762     $laststep,
1763     $rc,
1764     $sh,
1765     $stack_depth,
1766     @stack,
1767     @to_watch,
1768     @old_watch,
1769 );
1770
1771 sub _DB__determine_if_we_should_break
1772 {
1773     # if we have something here, see if we should break.
1774     # $stop is lexical and local to this block - $action on the other hand
1775     # is global.
1776     my $stop;
1777
1778     if ( $dbline{$line}
1779         && _is_breakpoint_enabled($filename, $line)
1780         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1781     {
1782
1783         # Stop if the stop criterion says to just stop.
1784         if ( $stop eq '1' ) {
1785             $signal |= 1;
1786         }
1787
1788         # It's a conditional stop; eval it in the user's context and
1789         # see if we should stop. If so, remove the one-time sigil.
1790         elsif ($stop) {
1791             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1792             DB::eval();
1793             # If the breakpoint is temporary, then delete its enabled status.
1794             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1795                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1796             }
1797         }
1798     } ## end if ($dbline{$line} && ...
1799 }
1800
1801 sub _DB__is_finished {
1802     if ($finished and $level <= 1) {
1803         end_report();
1804         return 1;
1805     }
1806     else {
1807         return;
1808     }
1809 }
1810
1811 sub _DB__read_next_cmd
1812 {
1813     my ($tid) = @_;
1814
1815     # We have a terminal, or can get one ...
1816     if (!$term) {
1817         setterm();
1818     }
1819
1820     # ... and it belogs to this PID or we get one for this PID ...
1821     if ($term_pid != $$) {
1822         resetterm(1);
1823     }
1824
1825     # ... and we got a line of command input ...
1826     $cmd = DB::readline(
1827         "$pidprompt $tid DB"
1828         . ( '<' x $level )
1829         . ( $#hist + 1 )
1830         . ( '>' x $level ) . " "
1831     );
1832
1833     return defined($cmd);
1834 }
1835
1836 sub _DB__trim_command_and_return_first_component {
1837     my ($obj) = @_;
1838
1839     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1840     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1841
1842     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1843
1844     $obj->cmd_verb($verb);
1845     $obj->cmd_args($args);
1846
1847     return;
1848 }
1849
1850 sub _DB__handle_f_command {
1851     my ($obj) = @_;
1852
1853     if ($file = $obj->cmd_args) {
1854         # help for no arguments (old-style was return from sub).
1855         if ( !$file ) {
1856             print $OUT
1857             "The old f command is now the r command.\n";    # hint
1858             print $OUT "The new f command switches filenames.\n";
1859             next CMD;
1860         } ## end if (!$file)
1861
1862         # if not in magic file list, try a close match.
1863         if ( !defined $main::{ '_<' . $file } ) {
1864             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1865                 {
1866                     $try = substr( $try, 2 );
1867                     print $OUT "Choosing $try matching '$file':\n";
1868                     $file = $try;
1869                 }
1870             } ## end if (($try) = grep(m#^_<.*$file#...
1871         } ## end if (!defined $main::{ ...
1872
1873         # If not successfully switched now, we failed.
1874         if ( !defined $main::{ '_<' . $file } ) {
1875             print $OUT "No file matching '$file' is loaded.\n";
1876             next CMD;
1877         }
1878
1879         # We switched, so switch the debugger internals around.
1880         elsif ( $file ne $filename ) {
1881             *dbline   = $main::{ '_<' . $file };
1882             $max      = $#dbline;
1883             $filename = $file;
1884             $start    = 1;
1885             $cmd      = "l";
1886         } ## end elsif ($file ne $filename)
1887
1888         # We didn't switch; say we didn't.
1889         else {
1890             print $OUT "Already in $file.\n";
1891             next CMD;
1892         }
1893     }
1894
1895     return;
1896 }
1897
1898 sub _DB__handle_dot_command {
1899     my ($obj) = @_;
1900
1901     # . command.
1902     if ($obj->_is_full('.')) {
1903         $incr = -1;    # stay at current line
1904
1905         # Reset everything to the old location.
1906         $start    = $line;
1907         $filename = $filename_ini;
1908         *dbline   = $main::{ '_<' . $filename };
1909         $max      = $#dbline;
1910
1911         # Now where are we?
1912         print_lineinfo($obj->position());
1913         next CMD;
1914     }
1915
1916     return;
1917 }
1918
1919 sub _DB__handle_y_command {
1920     my ($obj) = @_;
1921
1922     if (my ($match_level, $match_vars)
1923         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1924
1925         # See if we've got the necessary support.
1926         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1927             my $Err = $@;
1928             _db_warn(
1929                 $Err =~ /locate/
1930                 ? "PadWalker module not found - please install\n"
1931                 : $Err
1932             );
1933             next CMD;
1934         }
1935
1936         # Load up dumpvar if we don't have it. If we can, that is.
1937         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1938         defined &main::dumpvar
1939             or print $OUT "dumpvar.pl not available.\n"
1940             and next CMD;
1941
1942         # Got all the modules we need. Find them and print them.
1943         my @vars = split( ' ', $match_vars || '' );
1944
1945         # Find the pad.
1946         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1947
1948         # Oops. Can't find it.
1949         if (my $Err = $@) {
1950             $Err =~ s/ at .*//;
1951             _db_warn($Err);
1952             next CMD;
1953         }
1954
1955         # Show the desired vars with dumplex().
1956         my $savout = select($OUT);
1957
1958         # Have dumplex dump the lexicals.
1959         foreach my $key (sort keys %$h) {
1960             dumpvar::dumplex( $key, $h->{$key},
1961                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1962                 @vars );
1963         }
1964         select($savout);
1965         next CMD;
1966     }
1967 }
1968
1969 sub _DB__handle_c_command {
1970     my ($obj) = @_;
1971
1972     my $i = $obj->cmd_args;
1973
1974     if ($i =~ m#\A[\w:]*\z#) {
1975
1976         # Hey, show's over. The debugged program finished
1977         # executing already.
1978         next CMD if _DB__is_finished();
1979
1980         # Capture the place to put a one-time break.
1981         $subname = $i;
1982
1983         #  Probably not needed, since we finish an interactive
1984         #  sub-session anyway...
1985         # local $filename = $filename;
1986         # local *dbline = *dbline; # XXX Would this work?!
1987         #
1988         # The above question wonders if localizing the alias
1989         # to the magic array works or not. Since it's commented
1990         # out, we'll just leave that to speculation for now.
1991
1992         # If the "subname" isn't all digits, we'll assume it
1993         # is a subroutine name, and try to find it.
1994         if ( $subname =~ /\D/ ) {    # subroutine name
1995             # Qualify it to the current package unless it's
1996             # already qualified.
1997             $subname = $package . "::" . $subname
1998             unless $subname =~ /::/;
1999
2000             # find_sub will return "file:line_number" corresponding
2001             # to where the subroutine is defined; we call find_sub,
2002             # break up the return value, and assign it in one
2003             # operation.
2004             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2005
2006             # Force the line number to be numeric.
2007             $i = $i + 0;
2008
2009             # If we got a line number, we found the sub.
2010             if ($i) {
2011
2012                 # Switch all the debugger's internals around so
2013                 # we're actually working with that file.
2014                 $filename = $file;
2015                 *dbline   = $main::{ '_<' . $filename };
2016
2017                 # Mark that there's a breakpoint in this file.
2018                 $had_breakpoints{$filename} |= 1;
2019
2020                 # Scan forward to the first executable line
2021                 # after the 'sub whatever' line.
2022                 $max = $#dbline;
2023                 my $_line_num = $i;
2024                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2025                 {
2026                     $_line_num++;
2027                 }
2028                 $i = $_line_num;
2029             } ## end if ($i)
2030
2031             # We didn't find a sub by that name.
2032             else {
2033                 print $OUT "Subroutine $subname not found.\n";
2034                 next CMD;
2035             }
2036         } ## end if ($subname =~ /\D/)
2037
2038         # At this point, either the subname was all digits (an
2039         # absolute line-break request) or we've scanned through
2040         # the code following the definition of the sub, looking
2041         # for an executable, which we may or may not have found.
2042         #
2043         # If $i (which we set $subname from) is non-zero, we
2044         # got a request to break at some line somewhere. On
2045         # one hand, if there wasn't any real subroutine name
2046         # involved, this will be a request to break in the current
2047         # file at the specified line, so we have to check to make
2048         # sure that the line specified really is breakable.
2049         #
2050         # On the other hand, if there was a subname supplied, the
2051         # preceding block has moved us to the proper file and
2052         # location within that file, and then scanned forward
2053         # looking for the next executable line. We have to make
2054         # sure that one was found.
2055         #
2056         # On the gripping hand, we can't do anything unless the
2057         # current value of $i points to a valid breakable line.
2058         # Check that.
2059         if ($i) {
2060
2061             # Breakable?
2062             if ( $dbline[$i] == 0 ) {
2063                 print $OUT "Line $i not breakable.\n";
2064                 next CMD;
2065             }
2066
2067             # Yes. Set up the one-time-break sigil.
2068             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2069             _enable_breakpoint_temp_enabled_status($filename, $i);
2070         } ## end if ($i)
2071
2072         # Turn off stack tracing from here up.
2073         for my $j (0 .. $stack_depth) {
2074             $stack[ $j ] &= ~1;
2075         }
2076         last CMD;
2077     }
2078
2079     return;
2080 }
2081
2082 sub _DB__handle_forward_slash_command {
2083     my ($obj) = @_;
2084
2085     # The pattern as a string.
2086     use vars qw($inpat);
2087
2088     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2089
2090         # Remove the final slash.
2091         $inpat =~ s:([^\\])/$:$1:;
2092
2093         # If the pattern isn't null ...
2094         if ( $inpat ne "" ) {
2095
2096             # Turn of warn and die procesing for a bit.
2097             local $SIG{__DIE__};
2098             local $SIG{__WARN__};
2099
2100             # Create the pattern.
2101             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2102             if ( $@ ne "" ) {
2103
2104                 # Oops. Bad pattern. No biscuit.
2105                 # Print the eval error and go back for more
2106                 # commands.
2107                 print $OUT "$@";
2108                 next CMD;
2109             }
2110             $obj->pat($inpat);
2111         } ## end if ($inpat ne "")
2112
2113         # Set up to stop on wrap-around.
2114         $end = $start;
2115
2116         # Don't move off the current line.
2117         $incr = -1;
2118
2119         my $pat = $obj->pat;
2120
2121         # Done in eval so nothing breaks if the pattern
2122         # does something weird.
2123         eval
2124         {
2125             no strict q/vars/;
2126             for (;;) {
2127                 # Move ahead one line.
2128                 ++$start;
2129
2130                 # Wrap if we pass the last line.
2131                 $start = 1 if ($start > $max);
2132
2133                 # Stop if we have gotten back to this line again,
2134                 last if ($start == $end);
2135
2136                 # A hit! (Note, though, that we are doing
2137                 # case-insensitive matching. Maybe a qr//
2138                 # expression would be better, so the user could
2139                 # do case-sensitive matching if desired.
2140                 if ($dbline[$start] =~ m/$pat/i) {
2141                     if ($slave_editor) {
2142                         # Handle proper escaping in the slave.
2143                         print $OUT "\032\032$filename:$start:0\n";
2144                     }
2145                     else {
2146                         # Just print the line normally.
2147                         print $OUT "$start:\t",$dbline[$start],"\n";
2148                     }
2149                     # And quit since we found something.
2150                     last;
2151                 }
2152             }
2153         };
2154
2155         if ($@) {
2156             warn $@;
2157         }
2158
2159         # If we wrapped, there never was a match.
2160         if ( $start == $end ) {
2161             print {$OUT} "/$pat/: not found\n";
2162         }
2163         next CMD;
2164     }
2165
2166     return;
2167 }
2168
2169 sub _DB__handle_question_mark_command {
2170     my ($obj) = @_;
2171
2172     # ? - backward pattern search.
2173     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2174
2175         # Get the pattern, remove trailing question mark.
2176         $inpat =~ s:([^\\])\?$:$1:;
2177
2178         # If we've got one ...
2179         if ( $inpat ne "" ) {
2180
2181             # Turn off die & warn handlers.
2182             local $SIG{__DIE__};
2183             local $SIG{__WARN__};
2184             eval '$inpat =~ m' . "\a$inpat\a";
2185
2186             if ( $@ ne "" ) {
2187
2188                 # Ouch. Not good. Print the error.
2189                 print $OUT $@;
2190                 next CMD;
2191             }
2192             $obj->pat($inpat);
2193         } ## end if ($inpat ne "")
2194
2195         # Where we are now is where to stop after wraparound.
2196         $end = $start;
2197
2198         # Don't move away from this line.
2199         $incr = -1;
2200
2201         my $pat = $obj->pat;
2202         # Search inside the eval to prevent pattern badness
2203         # from killing us.
2204         eval {
2205             no strict q/vars/;
2206             for (;;) {
2207                 # Back up a line.
2208                 --$start;
2209
2210                 # Wrap if we pass the first line.
2211
2212                 $start = $max if ($start <= 0);
2213
2214                 # Quit if we get back where we started,
2215                 last if ($start == $end);
2216
2217                 # Match?
2218                 if ($dbline[$start] =~ m/$pat/i) {
2219                     if ($slave_editor) {
2220                         # Yep, follow slave editor requirements.
2221                         print $OUT "\032\032$filename:$start:0\n";
2222                     }
2223                     else {
2224                         # Yep, just print normally.
2225                         print $OUT "$start:\t",$dbline[$start],"\n";
2226                     }
2227
2228                     # Found, so done.
2229                     last;
2230                 }
2231             }
2232         };
2233
2234         # Say we failed if the loop never found anything,
2235         if ( $start == $end ) {
2236             print {$OUT} "?$pat?: not found\n";
2237         }
2238         next CMD;
2239     }
2240
2241     return;
2242 }
2243
2244 sub _DB__handle_restart_and_rerun_commands {
2245     my ($obj) = @_;
2246
2247     my $cmd_cmd = $obj->cmd_verb;
2248     my $cmd_params = $obj->cmd_args;
2249     # R - restart execution.
2250     # rerun - controlled restart execution.
2251     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2252         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2253
2254         # Close all non-system fds for a clean restart.  A more
2255         # correct method would be to close all fds that were not
2256         # open when the process started, but this seems to be
2257         # hard.  See "debugger 'R'estart and open database
2258         # connections" on p5p.
2259
2260         my $max_fd = 1024; # default if POSIX can't be loaded
2261         if (eval { require POSIX }) {
2262             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2263         }
2264
2265         if (defined $max_fd) {
2266             foreach ($^F+1 .. $max_fd-1) {
2267                 next unless open FD_TO_CLOSE, "<&=$_";
2268                 close(FD_TO_CLOSE);
2269             }
2270         }
2271
2272         # And run Perl again.  We use exec() to keep the
2273         # PID stable (and that way $ini_pids is still valid).
2274         exec(@args) or print {$OUT} "exec failed: $!\n";
2275
2276         last CMD;
2277     }
2278
2279     return;
2280 }
2281
2282 sub _DB__handle_run_command_in_pager_command {
2283     my ($obj) = @_;
2284
2285     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2286         if ( $pager =~ /^\|/ ) {
2287
2288             # Default pager is into a pipe. Redirect I/O.
2289             open( SAVEOUT, ">&STDOUT" )
2290             || _db_warn("Can't save STDOUT");
2291             open( STDOUT, ">&OUT" )
2292             || _db_warn("Can't redirect STDOUT");
2293         } ## end if ($pager =~ /^\|/)
2294         else {
2295
2296             # Not into a pipe. STDOUT is safe.
2297             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2298         }
2299
2300         # Fix up environment to record we have less if so.
2301         fix_less();
2302
2303         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2304
2305             # Couldn't open pipe to pager.
2306             _db_warn("Can't pipe output to '$pager'");
2307             if ( $pager =~ /^\|/ ) {
2308
2309                 # Redirect I/O back again.
2310                 open( OUT, ">&STDOUT" )    # XXX: lost message
2311                 || _db_warn("Can't restore DB::OUT");
2312                 open( STDOUT, ">&SAVEOUT" )
2313                 || _db_warn("Can't restore STDOUT");
2314                 close(SAVEOUT);
2315             } ## end if ($pager =~ /^\|/)
2316             else {
2317
2318                 # Redirect I/O. STDOUT already safe.
2319                 open( OUT, ">&STDOUT" )    # XXX: lost message
2320                 || _db_warn("Can't restore DB::OUT");
2321             }
2322             next CMD;
2323         } ## end unless ($piped = open(OUT,...
2324
2325         # Set up broken-pipe handler if necessary.
2326         $SIG{PIPE} = \&DB::catch
2327         if $pager =~ /^\|/
2328         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2329
2330         OUT->autoflush(1);
2331         # Save current filehandle, and put it back.
2332         $obj->selected(scalar( select(OUT) ));
2333         # Don't put it back if pager was a pipe.
2334         if ($cmd !~ /\A\|\|/)
2335         {
2336             select($obj->selected());
2337             $obj->selected("");
2338         }
2339
2340         # Trim off the pipe symbols and run the command now.
2341         $cmd =~ s#\A\|+\s*##;
2342         redo PIPE;
2343     }
2344
2345     return;
2346 }
2347
2348 sub _DB__handle_m_command {
2349     my ($obj) = @_;
2350
2351     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2352         methods($1);
2353         next CMD;
2354     }
2355
2356     # m expr - set up DB::eval to do the work
2357     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2358         $onetimeDump = 'methods';   #  method output gets used there
2359     }
2360
2361     return;
2362 }
2363
2364 sub _DB__at_end_of_every_command {
2365     my ($obj) = @_;
2366
2367     # At the end of every command:
2368     if ($obj->piped) {
2369
2370         # Unhook the pipe mechanism now.
2371         if ( $pager =~ /^\|/ ) {
2372
2373             # No error from the child.
2374             $? = 0;
2375
2376             # we cannot warn here: the handle is missing --tchrist
2377             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2378
2379             # most of the $? crud was coping with broken cshisms
2380             # $? is explicitly set to 0, so this never runs.
2381             if ($?) {
2382                 print SAVEOUT "Pager '$pager' failed: ";
2383                 if ( $? == -1 ) {
2384                     print SAVEOUT "shell returned -1\n";
2385                 }
2386                 elsif ( $? >> 8 ) {
2387                     print SAVEOUT ( $? & 127 )
2388                     ? " (SIG#" . ( $? & 127 ) . ")"
2389                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2390                 }
2391                 else {
2392                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2393                 }
2394             } ## end if ($?)
2395
2396             # Reopen filehandle for our output (if we can) and
2397             # restore STDOUT (if we can).
2398             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2399             open( STDOUT, ">&SAVEOUT" )
2400             || _db_warn("Can't restore STDOUT");
2401
2402             # Turn off pipe exception handler if necessary.
2403             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2404
2405             # Will stop ignoring SIGPIPE if done like nohup(1)
2406             # does SIGINT but Perl doesn't give us a choice.
2407         } ## end if ($pager =~ /^\|/)
2408         else {
2409
2410             # Non-piped "pager". Just restore STDOUT.
2411             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2412         }
2413
2414         # Close filehandle pager was using, restore the normal one
2415         # if necessary,
2416         close(SAVEOUT);
2417
2418         if ($obj->selected() ne "") {
2419             select($obj->selected);
2420             $obj->selected("");
2421         }
2422
2423         # No pipes now.
2424         $obj->piped("");
2425     } ## end if ($piped)
2426
2427     return;
2428 }
2429
2430 # 't' is type.
2431 # 'm' is method.
2432 # 'v' is the value (i.e: method name or subroutine ref).
2433 # 's' is subroutine.
2434 my %cmd_lookup =
2435 (
2436     '-' => { t => 'm', v => '_handle_dash_command', },
2437     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2438     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2439     'H' => { t => 'm', v => '_handle_H_command', },
2440     'S' => { t => 'm', v => '_handle_S_command', },
2441     'T' => { t => 'm', v => '_handle_T_command', },
2442     'W' => { t => 'm', v => '_handle_W_command', },
2443     'c' => { t => 's', v => \&_DB__handle_c_command, },
2444     'f' => { t => 's', v => \&_DB__handle_f_command, },
2445     'm' => { t => 's', v => \&_DB__handle_m_command, },
2446     'n' => { t => 'm', v => '_handle_n_command', },
2447     'p' => { t => 'm', v => '_handle_p_command', },
2448     'q' => { t => 'm', v => '_handle_q_command', },
2449     'r' => { t => 'm', v => '_handle_r_command', },
2450     's' => { t => 'm', v => '_handle_s_command', },
2451     'save' => { t => 'm', v => '_handle_save_command', },
2452     'source' => { t => 'm', v => '_handle_source_command', },
2453     't' => { t => 'm', v => '_handle_t_command', },
2454     'w' => { t => 'm', v => '_handle_w_command', },
2455     'x' => { t => 'm', v => '_handle_x_command', },
2456     'y' => { t => 's', v => \&_DB__handle_y_command, },
2457     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2458         ('X', 'V')),
2459     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2460         qw(enable disable)),
2461     (map { $_ =>
2462         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2463         } qw(R rerun)),
2464     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2465     qw(a A b B e E h i l L M o O P v w W)),
2466 );
2467
2468 sub DB {
2469
2470     # lock the debugger and get the thread id for the prompt
2471     lock($DBGR);
2472     my $tid;
2473     my $position;
2474     my ($prefix, $after, $infix);
2475     my $pat;
2476     my $explicit_stop;
2477     my $piped;
2478     my $selected;
2479
2480     if ($ENV{PERL5DB_THREADED}) {
2481         $tid = eval { "[".threads->tid."]" };
2482     }
2483
2484     my $cmd_verb;
2485     my $cmd_args;
2486
2487     my $obj = DB::Obj->new(
2488         {
2489             position => \$position,
2490             prefix => \$prefix,
2491             after => \$after,
2492             explicit_stop => \$explicit_stop,
2493             infix => \$infix,
2494             cmd_args => \$cmd_args,
2495             cmd_verb => \$cmd_verb,
2496             pat => \$pat,
2497             piped => \$piped,
2498             selected => \$selected,
2499         },
2500     );
2501
2502     $obj->_DB_on_init__initialize_globals(@_);
2503
2504     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2505     # The code being debugged may have altered them.
2506     DB::save();
2507
2508     # Since DB::DB gets called after every line, we can use caller() to
2509     # figure out where we last were executing. Sneaky, eh? This works because
2510     # caller is returning all the extra information when called from the
2511     # debugger.
2512     local ( $package, $filename, $line ) = caller;
2513     $filename_ini = $filename;
2514
2515     # set up the context for DB::eval, so it can properly execute
2516     # code on behalf of the user. We add the package in so that the
2517     # code is eval'ed in the proper package (not in the debugger!).
2518     local $usercontext = _calc_usercontext($package);
2519
2520     # Create an alias to the active file magical array to simplify
2521     # the code here.
2522     local (*dbline) = $main::{ '_<' . $filename };
2523
2524     # Last line in the program.
2525     $max = $#dbline;
2526
2527     _DB__determine_if_we_should_break(@_);
2528
2529     # Preserve the current stop-or-not, and see if any of the W
2530     # (watch expressions) has changed.
2531     my $was_signal = $signal;
2532
2533     # If we have any watch expressions ...
2534     $obj->_DB__handle_watch_expressions(@_);
2535
2536 =head2 C<watchfunction()>
2537
2538 C<watchfunction()> is a function that can be defined by the user; it is a
2539 function which will be run on each entry to C<DB::DB>; it gets the
2540 current package, filename, and line as its parameters.
2541
2542 The watchfunction can do anything it likes; it is executing in the
2543 debugger's context, so it has access to all of the debugger's internal
2544 data structures and functions.
2545
2546 C<watchfunction()> can control the debugger's actions. Any of the following
2547 will cause the debugger to return control to the user's program after
2548 C<watchfunction()> executes:
2549
2550 =over 4
2551
2552 =item *
2553
2554 Returning a false value from the C<watchfunction()> itself.
2555
2556 =item *
2557
2558 Altering C<$single> to a false value.
2559
2560 =item *
2561
2562 Altering C<$signal> to a false value.
2563
2564 =item *
2565
2566 Turning off the C<4> bit in C<$trace> (this also disables the
2567 check for C<watchfunction()>. This can be done with
2568
2569     $trace &= ~4;
2570
2571 =back
2572
2573 =cut
2574
2575     # If there's a user-defined DB::watchfunction, call it with the
2576     # current package, filename, and line. The function executes in
2577     # the DB:: package.
2578     if ( $trace & 4 ) {    # User-installed watch
2579         return
2580           if watchfunction( $package, $filename, $line )
2581           and not $single
2582           and not $was_signal
2583           and not( $trace & ~4 );
2584     } ## end if ($trace & 4)
2585
2586     # Pick up any alteration to $signal in the watchfunction, and
2587     # turn off the signal now.
2588     $was_signal = $signal;
2589     $signal     = 0;
2590
2591 =head2 GETTING READY TO EXECUTE COMMANDS
2592
2593 The debugger decides to take control if single-step mode is on, the
2594 C<t> command was entered, or the user generated a signal. If the program
2595 has fallen off the end, we set things up so that entering further commands
2596 won't cause trouble, and we say that the program is over.
2597
2598 =cut
2599
2600     # Make sure that we always print if asked for explicitly regardless
2601     # of $trace_to_depth .
2602     $explicit_stop = ($single || $was_signal);
2603
2604     # Check to see if we should grab control ($single true,
2605     # trace set appropriately, or we got a signal).
2606     if ( $explicit_stop || ( $trace & 1 ) ) {
2607         $obj->_DB__grab_control(@_);
2608     } ## end if ($single || ($trace...
2609
2610 =pod
2611
2612 If there's an action to be executed for the line we stopped at, execute it.
2613 If there are any preprompt actions, execute those as well.
2614
2615 =cut
2616
2617     # If there's an action, do it now.
2618     if ($action) {
2619         $evalarg = $action;
2620         DB::eval();
2621     }
2622
2623     # Are we nested another level (e.g., did we evaluate a function
2624     # that had a breakpoint in it at the debugger prompt)?
2625     if ( $single || $was_signal ) {
2626
2627         # Yes, go down a level.
2628         local $level = $level + 1;
2629
2630         # Do any pre-prompt actions.
2631         foreach $evalarg (@$pre) {
2632             DB::eval();
2633         }
2634
2635         # Complain about too much recursion if we passed the limit.
2636         if ($single & 4) {
2637             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2638         }
2639
2640         # The line we're currently on. Set $incr to -1 to stay here
2641         # until we get a command that tells us to advance.
2642         $start = $line;
2643         $incr  = -1;      # for backward motion.
2644
2645         # Tack preprompt debugger actions ahead of any actual input.
2646         @typeahead = ( @$pretype, @typeahead );
2647
2648 =head2 WHERE ARE WE?
2649
2650 XXX Relocate this section?
2651
2652 The debugger normally shows the line corresponding to the current line of
2653 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2654 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2655
2656 C<$incr> controls by how many lines the I<current> line should move forward
2657 after a command is executed. If set to -1, this indicates that the I<current>
2658 line shouldn't change.
2659
2660 C<$start> is the I<current> line. It is used for things like knowing where to
2661 move forwards or backwards from when doing an C<L> or C<-> command.
2662
2663 C<$max> tells the debugger where the last line of the current file is. It's
2664 used to terminate loops most often.
2665
2666 =head2 THE COMMAND LOOP
2667
2668 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2669 in two parts:
2670
2671 =over 4
2672
2673 =item *
2674
2675 The outer part of the loop, starting at the C<CMD> label. This loop
2676 reads a command and then executes it.
2677
2678 =item *
2679
2680 The inner part of the loop, starting at the C<PIPE> label. This part
2681 is wholly contained inside the C<CMD> block and only executes a command.
2682 Used to handle commands running inside a pager.
2683
2684 =back
2685
2686 So why have two labels to restart the loop? Because sometimes, it's easier to
2687 have a command I<generate> another command and then re-execute the loop to do
2688 the new command. This is faster, but perhaps a bit more convoluted.
2689
2690 =cut
2691
2692         # The big command dispatch loop. It keeps running until the
2693         # user yields up control again.
2694         #
2695         # If we have a terminal for input, and we get something back
2696         # from readline(), keep on processing.
2697
2698       CMD:
2699         while (_DB__read_next_cmd($tid))
2700         {
2701
2702             share($cmd);
2703             # ... try to execute the input as debugger commands.
2704
2705             # Don't stop running.
2706             $single = 0;
2707
2708             # No signal is active.
2709             $signal = 0;
2710
2711             # Handle continued commands (ending with \):
2712             if ($cmd =~ s/\\\z/\n/) {
2713                 $cmd .= DB::readline("  cont: ");
2714                 redo CMD;
2715             }
2716
2717 =head4 The null command
2718
2719 A newline entered by itself means I<re-execute the last command>. We grab the
2720 command out of C<$laststep> (where it was recorded previously), and copy it
2721 back into C<$cmd> to be executed below. If there wasn't any previous command,
2722 we'll do nothing below (no command will match). If there was, we also save it
2723 in the command history and fall through to allow the command parsing to pick
2724 it up.
2725
2726 =cut
2727
2728             # Empty input means repeat the last command.
2729             if ($cmd eq '') {
2730                 $cmd = $laststep;
2731             }
2732             chomp($cmd);    # get rid of the annoying extra newline
2733             if (length($cmd) >= 2) {
2734                 push( @hist, $cmd );
2735             }
2736             push( @truehist, $cmd );
2737             share(@hist);
2738             share(@truehist);
2739
2740             # This is a restart point for commands that didn't arrive
2741             # via direct user input. It allows us to 'redo PIPE' to
2742             # re-execute command processing without reading a new command.
2743           PIPE: {
2744                 _DB__trim_command_and_return_first_component($obj);
2745
2746 =head3 COMMAND ALIASES
2747
2748 The debugger can create aliases for commands (these are stored in the
2749 C<%alias> hash). Before a command is executed, the command loop looks it up
2750 in the alias hash and substitutes the contents of the alias for the command,
2751 completely replacing it.
2752
2753 =cut
2754
2755                 # See if there's an alias for the command, and set it up if so.
2756                 if ( $alias{$cmd_verb} ) {
2757
2758                     # Squelch signal handling; we want to keep control here
2759                     # if something goes loco during the alias eval.
2760                     local $SIG{__DIE__};
2761                     local $SIG{__WARN__};
2762
2763                     # This is a command, so we eval it in the DEBUGGER's
2764                     # scope! Otherwise, we can't see the special debugger
2765                     # variables, or get to the debugger's subs. (Well, we
2766                     # _could_, but why make it even more complicated?)
2767                     eval "\$cmd =~ $alias{$cmd_verb}";
2768                     if ($@) {
2769                         local $\ = '';
2770                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2771                         next CMD;
2772                     }
2773                     _DB__trim_command_and_return_first_component($obj);
2774                 } ## end if ($alias{$cmd_verb})
2775
2776 =head3 MAIN-LINE COMMANDS
2777
2778 All of these commands work up to and after the program being debugged has
2779 terminated.
2780
2781 =head4 C<q> - quit
2782
2783 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2784 try to execute further, cleaning any restart-related stuff out of the
2785 environment, and executing with the last value of C<$?>.
2786
2787 =cut
2788
2789                 # All of these commands were remapped in perl 5.8.0;
2790                 # we send them off to the secondary dispatcher (see below).
2791                 $obj->_handle_special_char_cmd_wrapper_commands;
2792                 _DB__trim_command_and_return_first_component($obj);
2793
2794                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2795                     my $type = $cmd_rec->{t};
2796                     my $val = $cmd_rec->{v};
2797                     if ($type eq 'm') {
2798                         $obj->$val();
2799                     }
2800                     elsif ($type eq 's') {
2801                         $val->($obj);
2802                     }
2803                 }
2804
2805 =head4 C<t> - trace [n]
2806
2807 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2808 If level is specified, set C<$trace_to_depth>.
2809
2810 =head4 C<S> - list subroutines matching/not matching a pattern
2811
2812 Walks through C<%sub>, checking to see whether or not to print the name.
2813
2814 =head4 C<X> - list variables in current package
2815
2816 Since the C<V> command actually processes this, just change this to the
2817 appropriate C<V> command and fall through.
2818
2819 =head4 C<V> - list variables
2820
2821 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2822
2823 =head4 C<x> - evaluate and print an expression
2824
2825 Hands the expression off to C<DB::eval>, setting it up to print the value
2826 via C<dumpvar.pl> instead of just printing it directly.
2827
2828 =head4 C<m> - print methods
2829
2830 Just uses C<DB::methods> to determine what methods are available.
2831
2832 =head4 C<f> - switch files
2833
2834 Switch to a different filename.
2835
2836 =head4 C<.> - return to last-executed line.
2837
2838 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2839 and then we look up the line in the magical C<%dbline> hash.
2840
2841 =head4 C<-> - back one window
2842
2843 We change C<$start> to be one window back; if we go back past the first line,
2844 we set it to be the first line. We ser C<$incr> to put us back at the
2845 currently-executing line, and then put a C<l $start +> (list one window from
2846 C<$start>) in C<$cmd> to be executed later.
2847
2848 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2849
2850 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2851 problems, most notably that the default case of several commands destroying
2852 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2853 retain the old commands for those who were used to using them or who preferred
2854 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2855 deal with them instead of processing them in-line.
2856
2857 =head4 C<y> - List lexicals in higher scope
2858
2859 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2860 above the current one and then displays then using C<dumpvar.pl>.
2861
2862 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2863
2864 All of the commands below this point don't work after the program being
2865 debugged has ended. All of them check to see if the program has ended; this
2866 allows the commands to be relocated without worrying about a 'line of
2867 demarcation' above which commands can be entered anytime, and below which
2868 they can't.
2869
2870 =head4 C<n> - single step, but don't trace down into subs
2871
2872 Done by setting C<$single> to 2, which forces subs to execute straight through
2873 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2874 so a null command knows what to re-execute.
2875
2876 =head4 C<s> - single-step, entering subs
2877
2878 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2879 subs. Also saves C<s> as C<$lastcmd>.
2880
2881 =head4 C<c> - run continuously, setting an optional breakpoint
2882
2883 Most of the code for this command is taken up with locating the optional
2884 breakpoint, which is either a subroutine name or a line number. We set
2885 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2886 in this and all call levels above this one.
2887
2888 =head4 C<r> - return from a subroutine
2889
2890 For C<r> to work properly, the debugger has to stop execution again
2891 immediately after the return is executed. This is done by forcing
2892 single-stepping to be on in the call level above the current one. If
2893 we are printing return values when a C<r> is executed, set C<$doret>
2894 appropriately, and force us out of the command loop.
2895
2896 =head4 C<T> - stack trace
2897
2898 Just calls C<DB::print_trace>.
2899
2900 =head4 C<w> - List window around current line.
2901
2902 Just calls C<DB::cmd_w>.
2903
2904 =head4 C<W> - watch-expression processing.
2905
2906 Just calls C<DB::cmd_W>.
2907
2908 =head4 C</> - search forward for a string in the source
2909
2910 We take the argument and treat it as a pattern. If it turns out to be a
2911 bad one, we return the error we got from trying to C<eval> it and exit.
2912 If not, we create some code to do the search and C<eval> it so it can't
2913 mess us up.
2914
2915 =cut
2916
2917                 _DB__handle_forward_slash_command($obj);
2918
2919 =head4 C<?> - search backward for a string in the source
2920
2921 Same as for C</>, except the loop runs backwards.
2922
2923 =cut
2924
2925                 _DB__handle_question_mark_command($obj);
2926
2927 =head4 C<$rc> - Recall command
2928
2929 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2930 that the terminal supports history). It find the the command required, puts it
2931 into C<$cmd>, and redoes the loop to execute it.
2932
2933 =cut
2934
2935                 # $rc - recall command.
2936                 $obj->_handle_rc_recall_command;
2937
2938 =head4 C<$sh$sh> - C<system()> command
2939
2940 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
2941 C<STDOUT> from getting messed up.
2942
2943 =cut
2944
2945                 $obj->_handle_sh_command;
2946
2947 =head4 C<$rc I<pattern> $rc> - Search command history
2948
2949 Another command to manipulate C<@hist>: this one searches it with a pattern.
2950 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2951
2952 =cut
2953
2954                 $obj->_handle_rc_search_history_command;
2955
2956 =head4 C<$sh> - Invoke a shell
2957
2958 Uses C<_db_system()> to invoke a shell.
2959
2960 =cut
2961
2962 =head4 C<$sh I<command>> - Force execution of a command in a shell
2963
2964 Like the above, but the command is passed to the shell. Again, we use
2965 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
2966
2967 =head4 C<H> - display commands in history
2968
2969 Prints the contents of C<@hist> (if any).
2970
2971 =head4 C<man, doc, perldoc> - look up documentation
2972
2973 Just calls C<runman()> to print the appropriate document.
2974
2975 =cut
2976
2977                 $obj->_handle_doc_command;
2978
2979 =head4 C<p> - print
2980
2981 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2982 the bottom of the loop.
2983
2984 =head4 C<=> - define command alias
2985
2986 Manipulates C<%alias> to add or list command aliases.
2987
2988 =head4 C<source> - read commands from a file.
2989
2990 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2991 pick it up.
2992
2993 =head4 C<enable> C<disable> - enable or disable breakpoints
2994
2995 This enables or disables breakpoints.
2996
2997 =head4 C<save> - send current history to a file
2998
2999 Takes the complete history, (not the shrunken version you see with C<H>),
3000 and saves it to the given filename, so it can be replayed using C<source>.
3001
3002 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3003
3004 =head4 C<R> - restart
3005
3006 Restart the debugger session.
3007
3008 =head4 C<rerun> - rerun the current session
3009
3010 Return to any given position in the B<true>-history list
3011
3012 =head4 C<|, ||> - pipe output through the pager.
3013
3014 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3015 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3016 pipe to the pager (restoring the output filehandles if this fails). If this
3017 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3018 set C<$signal>, sending us back into the debugger.
3019
3020 We then trim off the pipe symbols and C<redo> the command loop at the
3021 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3022 reading another.
3023
3024 =cut
3025
3026                 # || - run command in the pager, with output to DB::OUT.
3027                 _DB__handle_run_command_in_pager_command($obj);
3028
3029 =head3 END OF COMMAND PARSING
3030
3031 Anything left in C<$cmd> at this point is a Perl expression that we want to
3032 evaluate. We'll always evaluate in the user's context, and fully qualify
3033 any variables we might want to address in the C<DB> package.
3034
3035 =cut
3036
3037             }    # PIPE:
3038
3039             # Make sure the flag that says "the debugger's running" is
3040             # still on, to make sure we get control again.
3041             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3042
3043             # Run *our* eval that executes in the caller's context.
3044             DB::eval();
3045
3046             # Turn off the one-time-dump stuff now.
3047             if ($onetimeDump) {
3048                 $onetimeDump      = undef;
3049                 $onetimedumpDepth = undef;
3050             }
3051             elsif ( $term_pid == $$ ) {
3052                 eval { # May run under miniperl, when not available...
3053                     STDOUT->flush();
3054                     STDERR->flush();
3055                 };
3056
3057                 # XXX If this is the master pid, print a newline.
3058                 print {$OUT} "\n";
3059             }
3060         } ## end while (($term || &setterm...
3061
3062 =head3 POST-COMMAND PROCESSING
3063
3064 After each command, we check to see if the command output was piped anywhere.
3065 If so, we go through the necessary code to unhook the pipe and go back to
3066 our standard filehandles for input and output.
3067
3068 =cut
3069
3070         continue {    # CMD:
3071             _DB__at_end_of_every_command($obj);
3072         }    # CMD:
3073
3074 =head3 COMMAND LOOP TERMINATION
3075
3076 When commands have finished executing, we come here. If the user closed the
3077 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3078 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3079 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3080 The interpreter will then execute the next line and then return control to us
3081 again.
3082
3083 =cut
3084
3085         # No more commands? Quit.
3086         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3087
3088         # Evaluate post-prompt commands.
3089         foreach $evalarg (@$post) {
3090             DB::eval();
3091         }
3092     }    # if ($single || $signal)
3093
3094     # Put the user's globals back where you found them.
3095     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3096     ();
3097 } ## end sub DB
3098
3099 package DB::Obj;
3100
3101 sub new {
3102     my $class = shift;
3103
3104     my $self = bless {}, $class;
3105
3106     $self->_init(@_);
3107
3108     return $self;
3109 }
3110
3111 sub _init {
3112     my ($self, $args) = @_;
3113
3114     %{$self} = (%$self, %$args);
3115
3116     return;
3117 }
3118
3119 {
3120     no strict 'refs';
3121     foreach my $slot_name (qw(
3122         after explicit_stop infix pat piped position prefix selected cmd_verb
3123         cmd_args
3124         )) {
3125         my $slot = $slot_name;
3126         *{$slot} = sub {
3127             my $self = shift;
3128
3129             if (@_) {
3130                 ${ $self->{$slot} } = shift;
3131             }
3132
3133             return ${ $self->{$slot} };
3134         };
3135
3136         *{"append_to_$slot"} = sub {
3137             my $self = shift;
3138             my $s = shift;
3139
3140             return $self->$slot($self->$slot . $s);
3141         };
3142     }
3143 }
3144
3145 sub _DB_on_init__initialize_globals
3146 {
3147     my $self = shift;
3148
3149     # Check for whether we should be running continuously or not.
3150     # _After_ the perl program is compiled, $single is set to 1:
3151     if ( $single and not $second_time++ ) {
3152
3153         # Options say run non-stop. Run until we get an interrupt.
3154         if ($runnonstop) {    # Disable until signal
3155                 # If there's any call stack in place, turn off single
3156                 # stepping into subs throughout the stack.
3157             for my $i (0 .. $stack_depth) {
3158                 $stack[ $i ] &= ~1;
3159             }
3160
3161             # And we are now no longer in single-step mode.
3162             $single = 0;
3163
3164             # If we simply returned at this point, we wouldn't get
3165             # the trace info. Fall on through.
3166             # return;
3167         } ## end if ($runnonstop)
3168
3169         elsif ($ImmediateStop) {
3170
3171             # We are supposed to stop here; XXX probably a break.
3172             $ImmediateStop = 0;    # We've processed it; turn it off
3173             $signal        = 1;    # Simulate an interrupt to force
3174                                    # us into the command loop
3175         }
3176     } ## end if ($single and not $second_time...
3177
3178     # If we're in single-step mode, or an interrupt (real or fake)
3179     # has occurred, turn off non-stop mode.
3180     $runnonstop = 0 if $single or $signal;
3181
3182     return;
3183 }
3184
3185 sub _DB__handle_watch_expressions
3186 {
3187     my $self = shift;
3188
3189     if ( $trace & 2 ) {
3190         for my $n (0 .. $#to_watch) {
3191             $evalarg = $to_watch[$n];
3192             local $onetimeDump;    # Tell DB::eval() to not output results
3193
3194             # Fix context DB::eval() wants to return an array, but
3195             # we need a scalar here.
3196             my ($val) = join( "', '", DB::eval() );
3197             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3198
3199             # Did it change?
3200             if ( $val ne $old_watch[$n] ) {
3201
3202                 # Yep! Show the difference, and fake an interrupt.
3203                 $signal = 1;
3204                 print {$OUT} <<EOP;
3205 Watchpoint $n:\t$to_watch[$n] changed:
3206     old value:\t$old_watch[$n]
3207     new value:\t$val
3208 EOP
3209                 $old_watch[$n] = $val;
3210             } ## end if ($val ne $old_watch...
3211         } ## end for my $n (0 ..
3212     } ## end if ($trace & 2)
3213
3214     return;
3215 }
3216
3217 sub _my_print_lineinfo
3218 {
3219     my ($self, $i, $incr_pos) = @_;
3220
3221     if ($frame) {
3222         # Print it indented if tracing is on.
3223         DB::print_lineinfo( ' ' x $stack_depth,
3224             "$i:\t$DB::dbline[$i]" . $self->after );
3225     }
3226     else {
3227         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3228     }
3229 }
3230
3231 sub _curr_line {
3232     return $DB::dbline[$line];
3233 }
3234
3235 sub _is_full {
3236     my ($self, $letter) = @_;
3237
3238     return ($DB::cmd eq $letter);
3239 }
3240
3241 sub _DB__grab_control
3242 {
3243     my $self = shift;
3244
3245     # Yes, grab control.
3246     if ($slave_editor) {
3247
3248         # Tell the editor to update its position.
3249         $self->position("\032\032${DB::filename}:$line:0\n");
3250         DB::print_lineinfo($self->position());
3251     }
3252
3253 =pod
3254
3255 Special check: if we're in package C<DB::fake>, we've gone through the
3256 C<END> block at least once. We set up everything so that we can continue
3257 to enter commands and have a valid context to be in.
3258
3259 =cut
3260
3261     elsif ( $DB::package eq 'DB::fake' ) {
3262
3263         # Fallen off the end already.
3264         if (!$DB::term) {
3265             DB::setterm();
3266         }
3267
3268         DB::print_help(<<EOP);
3269 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3270 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3271 B<h q>, B<h R> or B<h o> to get additional info.
3272 EOP
3273
3274         # Set the DB::eval context appropriately.
3275         $DB::package     = 'main';
3276         $DB::usercontext = DB::_calc_usercontext($DB::package);
3277     } ## end elsif ($package eq 'DB::fake')
3278
3279 =pod
3280
3281 If the program hasn't finished executing, we scan forward to the
3282 next executable line, print that out, build the prompt from the file and line
3283 number information, and print that.
3284
3285 =cut
3286
3287     else {
3288
3289
3290         # Still somewhere in the midst of execution. Set up the
3291         #  debugger prompt.
3292         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3293                              # Perl 5 ones (sorry, we don't print Klingon
3294                              #module names)
3295
3296         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3297         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3298         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3299
3300         # Break up the prompt if it's really long.
3301         if ( length($self->prefix()) > 30 ) {
3302             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3303             $self->prefix("");
3304             $self->infix(":\t");
3305         }
3306         else {
3307             $self->infix("):\t");
3308             $self->position(
3309                 $self->prefix . $line. $self->infix
3310                 . $self->_curr_line . $self->after
3311             );
3312         }
3313
3314         # Print current line info, indenting if necessary.
3315         $self->_my_print_lineinfo($line, $self->position);
3316
3317         my $i;
3318         my $line_i = sub { return $DB::dbline[$i]; };
3319
3320         # Scan forward, stopping at either the end or the next
3321         # unbreakable line.
3322         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3323         {    #{ vi
3324
3325             # Drop out on null statements, block closers, and comments.
3326             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3327
3328             # Drop out if the user interrupted us.
3329             last if $signal;
3330
3331             # Append a newline if the line doesn't have one. Can happen
3332             # in eval'ed text, for instance.
3333             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3334
3335             # Next executable line.
3336             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3337                 . $self->after;
3338             $self->append_to_position($incr_pos);
3339             $self->_my_print_lineinfo($i, $incr_pos);
3340         } ## end for ($i = $line + 1 ; $i...
3341     } ## end else [ if ($slave_editor)
3342
3343     return;
3344 }
3345
3346 sub _handle_t_command {
3347     my $self = shift;
3348
3349     my $levels = $self->cmd_args();
3350
3351     if ((!length($levels)) or ($levels !~ /\D/)) {
3352         $trace ^= 1;
3353         local $\ = '';
3354         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3355         print {$OUT} "Trace = "
3356         . ( ( $trace & 1 )
3357             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3358             : "off" ) . "\n";
3359         next CMD;
3360     }
3361
3362     return;
3363 }
3364
3365
3366 sub _handle_S_command {
3367     my $self = shift;
3368
3369     if (my ($print_all_subs, $should_reverse, $Spatt)
3370         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3371         # $Spatt is the pattern (if any) to use.
3372         # Reverse scan?
3373         my $Srev     = defined $should_reverse;
3374         # No args - print all subs.
3375         my $Snocheck = !defined $print_all_subs;
3376
3377         # Need to make these sane here.
3378         local $\ = '';
3379         local $, = '';
3380
3381         # Search through the debugger's magical hash of subs.
3382         # If $nocheck is true, just print the sub name.
3383         # Otherwise, check it against the pattern. We then use
3384         # the XOR trick to reverse the condition as required.
3385         foreach $subname ( sort( keys %sub ) ) {
3386             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3387                 print $OUT $subname, "\n";
3388             }
3389         }
3390         next CMD;
3391     }
3392
3393     return;
3394 }
3395
3396 sub _handle_V_command_and_X_command {
3397     my $self = shift;
3398
3399     $DB::cmd =~ s/^X\b/V $DB::package/;
3400
3401     # Bare V commands get the currently-being-debugged package
3402     # added.
3403     if ($self->_is_full('V')) {
3404         $DB::cmd = "V $DB::package";
3405     }
3406
3407     # V - show variables in package.
3408     if (my ($new_packname, $new_vars_str) =
3409         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3410
3411         # Save the currently selected filehandle and
3412         # force output to debugger's filehandle (dumpvar
3413         # just does "print" for output).
3414         my $savout = select($OUT);
3415
3416         # Grab package name and variables to dump.
3417         $packname = $new_packname;
3418         my @vars     = split( ' ', $new_vars_str );
3419
3420         # If main::dumpvar isn't here, get it.
3421         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3422         if ( defined &main::dumpvar ) {
3423
3424             # We got it. Turn off subroutine entry/exit messages
3425             # for the moment, along with return values.
3426             local $frame = 0;
3427             local $doret = -2;
3428
3429             # must detect sigpipe failures  - not catching
3430             # then will cause the debugger to die.
3431             eval {
3432                 main::dumpvar(
3433                     $packname,
3434                     defined $option{dumpDepth}
3435                     ? $option{dumpDepth}
3436                     : -1,    # assume -1 unless specified
3437                     @vars
3438                 );
3439             };
3440
3441             # The die doesn't need to include the $@, because
3442             # it will automatically get propagated for us.
3443             if ($@) {
3444                 die unless $@ =~ /dumpvar print failed/;
3445             }
3446         } ## end if (defined &main::dumpvar)
3447         else {
3448
3449             # Couldn't load dumpvar.
3450             print $OUT "dumpvar.pl not available.\n";
3451         }
3452
3453         # Restore the output filehandle, and go round again.
3454         select($savout);
3455         next CMD;
3456     }
3457
3458     return;
3459 }
3460
3461 sub _handle_dash_command {
3462     my $self = shift;
3463
3464     if ($self->_is_full('-')) {
3465
3466         # back up by a window; go to 1 if back too far.
3467         $start -= $incr + $window + 1;
3468         $start = 1 if $start <= 0;
3469         $incr  = $window - 1;
3470
3471         # Generate and execute a "l +" command (handled below).
3472         $DB::cmd = 'l ' . ($start) . '+';
3473         redo CMD;
3474     }
3475     return;
3476 }
3477
3478 sub _n_or_s_commands_generic {
3479     my ($self, $new_val) = @_;
3480     # n - next
3481     next CMD if DB::_DB__is_finished();
3482
3483     # Single step, but don't enter subs.
3484     $single = $new_val;
3485
3486     # Save for empty command (repeat last).
3487     $laststep = $DB::cmd;
3488     last CMD;
3489 }
3490
3491 sub _n_or_s {
3492     my ($self, $letter, $new_val) = @_;
3493
3494     if ($self->_is_full($letter)) {
3495         $self->_n_or_s_commands_generic($new_val);
3496     }
3497     else {
3498         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3499     }
3500
3501     return;
3502 }
3503
3504 sub _handle_n_command {
3505     my $self = shift;
3506
3507     return $self->_n_or_s('n', 2);
3508 }
3509
3510 sub _handle_s_command {
3511     my $self = shift;
3512
3513     return $self->_n_or_s('s', 1);
3514 }
3515
3516 sub _handle_r_command {
3517     my $self = shift;
3518
3519     # r - return from the current subroutine.
3520     if ($self->_is_full('r')) {
3521
3522         # Can't do anything if the program's over.
3523         next CMD if DB::_DB__is_finished();
3524
3525         # Turn on stack trace.
3526         $stack[$stack_depth] |= 1;
3527
3528         # Print return value unless the stack is empty.
3529         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3530         last CMD;
3531     }
3532
3533     return;
3534 }
3535
3536 sub _handle_T_command {
3537     my $self = shift;
3538
3539     if ($self->_is_full('T')) {
3540         DB::print_trace( $OUT, 1 );    # skip DB
3541         next CMD;
3542     }
3543
3544     return;
3545 }
3546
3547 sub _handle_w_command {
3548     my $self = shift;
3549
3550     DB::cmd_w( 'w', $self->cmd_args() );
3551     next CMD;
3552
3553     return;
3554 }
3555
3556 sub _handle_W_command {
3557     my $self = shift;
3558
3559     if (my $arg = $self->cmd_args) {
3560         DB::cmd_W( 'W', $arg );
3561         next CMD;
3562     }
3563
3564     return;
3565 }
3566
3567 sub _handle_rc_recall_command {
3568     my $self = shift;
3569
3570     # $rc - recall command.
3571     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3572
3573         # No arguments, take one thing off history.
3574         pop(@hist) if length($DB::cmd) > 1;
3575
3576         # Relative (- found)?
3577         #  Y - index back from most recent (by 1 if bare minus)
3578         #  N - go to that particular command slot or the last
3579         #      thing if nothing following.
3580
3581         $self->cmd_verb(
3582             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3583         );
3584
3585         # Pick out the command desired.
3586         $DB::cmd = $hist[$self->cmd_verb];
3587
3588         # Print the command to be executed and restart the loop
3589         # with that command in the buffer.
3590         print {$OUT} $DB::cmd, "\n";
3591         redo CMD;
3592     }
3593
3594     return;
3595 }
3596
3597 sub _handle_rc_search_history_command {
3598     my $self = shift;
3599
3600     # $rc pattern $rc - find a command in the history.
3601     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3602
3603         # Create the pattern to use.
3604         my $pat = "^$arg";
3605         $self->pat($pat);
3606
3607         # Toss off last entry if length is >1 (and it always is).
3608         pop(@hist) if length($DB::cmd) > 1;
3609
3610         my $i;
3611
3612         # Look backward through the history.
3613         SEARCH_HIST:
3614         for ( $i = $#hist ; $i ; --$i ) {
3615             # Stop if we find it.
3616             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3617         }
3618
3619         if ( !$i ) {
3620
3621             # Never found it.
3622             print $OUT "No such command!\n\n";
3623             next CMD;
3624         }
3625
3626         # Found it. Put it in the buffer, print it, and process it.
3627         $DB::cmd = $hist[$i];
3628         print $OUT $DB::cmd, "\n";
3629         redo CMD;
3630     }
3631
3632     return;
3633 }
3634
3635 sub _handle_H_command {
3636     my $self = shift;
3637
3638     if ($self->cmd_args =~ m#\A\*#) {
3639         @hist = @truehist = ();
3640         print $OUT "History cleansed\n";
3641         next CMD;
3642     }
3643
3644     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3645
3646         # Anything other than negative numbers is ignored by
3647         # the (incorrect) pattern, so this test does nothing.
3648         $end = $num ? ( $#hist - $num ) : 0;
3649
3650         # Set to the minimum if less than zero.
3651         $hist = 0 if $hist < 0;
3652
3653         # Start at the end of the array.
3654         # Stay in while we're still above the ending value.
3655         # Tick back by one each time around the loop.
3656         my $i;
3657
3658         for ( $i = $#hist ; $i > $end ; $i-- ) {
3659
3660             # Print the command  unless it has no arguments.
3661             print $OUT "$i: ", $hist[$i], "\n"
3662             unless $hist[$i] =~ /^.?$/;
3663         }
3664
3665         next CMD;
3666     }
3667
3668     return;
3669 }
3670
3671 sub _handle_doc_command {
3672     my $self = shift;
3673
3674     # man, perldoc, doc - show manual pages.
3675     if (my ($man_page)
3676         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3677         runman($man_page);
3678         next CMD;
3679     }
3680
3681     return;
3682 }
3683
3684 sub _handle_p_command {
3685     my $self = shift;
3686
3687     my $print_cmd = 'print {$DB::OUT} ';
3688     # p - print (no args): print $_.
3689     if ($self->_is_full('p')) {
3690         $DB::cmd = $print_cmd . '$_';
3691     }
3692     else {
3693         # p - print the given expression.
3694         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3695     }
3696
3697     return;
3698 }
3699
3700 sub _handle_equal_sign_command {
3701     my $self = shift;
3702
3703     if ($DB::cmd =~ s/\A=\s*//) {
3704         my @keys;
3705         if ( length $DB::cmd == 0 ) {
3706
3707             # No args, get current aliases.
3708             @keys = sort keys %alias;
3709         }
3710         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3711
3712             # Creating a new alias. $k is alias name, $v is
3713             # alias value.
3714
3715             # can't use $_ or kill //g state
3716             for my $x ( $k, $v ) {
3717
3718                 # Escape "alarm" characters.
3719                 $x =~ s/\a/\\a/g;
3720             }
3721
3722             # Substitute key for value, using alarm chars
3723             # as separators (which is why we escaped them in
3724             # the command).
3725             $alias{$k} = "s\a$k\a$v\a";
3726
3727             # Turn off standard warn and die behavior.
3728             local $SIG{__DIE__};
3729             local $SIG{__WARN__};
3730
3731             # Is it valid Perl?
3732             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3733
3734                 # Nope. Bad alias. Say so and get out.
3735                 print $OUT "Can't alias $k to $v: $@\n";
3736                 delete $alias{$k};
3737                 next CMD;
3738             }
3739
3740             # We'll only list the new one.
3741             @keys = ($k);
3742         } ## end elsif (my ($k, $v) = ($DB::cmd...
3743
3744         # The argument is the alias to list.
3745         else {
3746             @keys = ($DB::cmd);
3747         }
3748
3749         # List aliases.
3750         for my $k (@keys) {
3751
3752             # Messy metaquoting: Trim the substitution code off.
3753             # We use control-G as the delimiter because it's not
3754             # likely to appear in the alias.
3755             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3756
3757                 # Print the alias.
3758                 print $OUT "$k\t= $1\n";
3759             }
3760             elsif ( defined $alias{$k} ) {
3761
3762                 # Couldn't trim it off; just print the alias code.
3763                 print $OUT "$k\t$alias{$k}\n";
3764             }
3765             else {
3766
3767                 # No such, dude.
3768                 print "No alias for $k\n";
3769             }
3770         } ## end for my $k (@keys)
3771         next CMD;
3772     }
3773
3774     return;
3775 }
3776
3777 sub _handle_source_command {
3778     my $self = shift;
3779
3780     # source - read commands from a file (or pipe!) and execute.
3781     if (my $sourced_fn = $self->cmd_args) {
3782         if ( open my $fh, $sourced_fn ) {
3783
3784             # Opened OK; stick it in the list of file handles.
3785             push @cmdfhs, $fh;
3786         }
3787         else {
3788
3789             # Couldn't open it.
3790             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3791         }
3792         next CMD;
3793     }
3794
3795     return;
3796 }
3797
3798 sub _handle_enable_disable_commands {
3799     my $self = shift;
3800
3801     my $which_cmd = $self->cmd_verb;
3802     my $position = $self->cmd_args;
3803
3804     if ($position !~ /\s/) {
3805         my ($fn, $line_num);
3806         if ($position =~ m{\A\d+\z})
3807         {
3808             $fn = $DB::filename;
3809             $line_num = $position;
3810         }
3811         elsif (my ($new_fn, $new_line_num)
3812             = $position =~ m{\A(.*):(\d+)\z}) {
3813             ($fn, $line_num) = ($new_fn, $new_line_num);
3814         }
3815         else
3816         {
3817             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3818         }
3819
3820         if (defined($fn)) {
3821             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3822                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3823                     ($which_cmd eq 'enable' ? 1 : '')
3824                 );
3825             }
3826             else {
3827                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3828             }
3829         }
3830
3831         next CMD;
3832     }
3833
3834     return;
3835 }
3836
3837 sub _handle_save_command {
3838     my $self = shift;
3839
3840     if (my $new_fn = $self->cmd_args) {
3841         my $filename = $new_fn || '.perl5dbrc';    # default?
3842         if ( open my $fh, '>', $filename ) {
3843
3844             # chomp to remove extraneous newlines from source'd files
3845             chomp( my @truelist =
3846                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3847                 @truehist );
3848             print {$fh} join( "\n", @truelist );
3849             print "commands saved in $filename\n";
3850         }
3851         else {
3852             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3853         }
3854         next CMD;
3855     }
3856
3857     return;
3858 }
3859
3860 sub _n_or_s_and_arg_commands_generic {
3861     my ($self, $letter, $new_val) = @_;
3862
3863     # s - single-step. Remember the last command was 's'.
3864     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3865         $laststep = $letter;
3866     }
3867
3868     return;
3869 }
3870
3871 sub _handle_sh_command {
3872     my $self = shift;
3873
3874     # $sh$sh - run a shell command (if it's all ASCII).
3875     # Can't run shell commands with Unicode in the debugger, hmm.
3876     my $my_cmd = $DB::cmd;
3877     if ($my_cmd =~ m#\A$sh#gms) {
3878
3879         if ($my_cmd =~ m#\G\z#cgms) {
3880             # Run the user's shell. If none defined, run Bourne.
3881             # We resume execution when the shell terminates.
3882             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3883             next CMD;
3884         }
3885         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3886             # System it.
3887             DB::_db_system($1);
3888             next CMD;
3889         }
3890         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3891             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3892             next CMD;
3893         }
3894     }
3895 }
3896
3897 sub _handle_x_command {
3898     my $self = shift;
3899
3900     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3901         $onetimeDump = 'dump';    # main::dumpvar shows the output
3902
3903         # handle special  "x 3 blah" syntax XXX propagate
3904         # doc back to special variables.
3905         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3906             $onetimedumpDepth = $1;
3907         }
3908     }
3909
3910     return;
3911 }
3912
3913 sub _handle_q_command {
3914     my $self = shift;
3915
3916     if ($self->_is_full('q')) {
3917         $fall_off_end = 1;
3918         DB::clean_ENV();
3919         exit $?;
3920     }
3921
3922     return;
3923 }
3924
3925 sub _handle_cmd_wrapper_commands {
3926     my $self = shift;
3927
3928     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3929     next CMD;
3930 }
3931
3932 sub _handle_special_char_cmd_wrapper_commands {
3933     my $self = shift;
3934
3935     # All of these commands were remapped in perl 5.8.0;
3936     # we send them off to the secondary dispatcher (see below).
3937     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
3938         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
3939         next CMD;
3940     }
3941
3942     return;
3943 }
3944
3945 package DB;
3946
3947 # The following code may be executed now:
3948 # BEGIN {warn 4}
3949
3950 =head2 sub
3951
3952 C<sub> is called whenever a subroutine call happens in the program being
3953 debugged. The variable C<$DB::sub> contains the name of the subroutine
3954 being called.
3955
3956 The core function of this subroutine is to actually call the sub in the proper
3957 context, capturing its output. This of course causes C<DB::DB> to get called
3958 again, repeating until the subroutine ends and returns control to C<DB::sub>
3959 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3960 return value, and returns its captured copy of the return value as its own
3961 return value. The value then feeds back into the program being debugged as if
3962 C<DB::sub> hadn't been there at all.
3963
3964 C<sub> does all the work of printing the subroutine entry and exit messages
3965 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3966 and also prints the return value if needed (for the C<r> command and if
3967 the 16 bit is set in C<$frame>).
3968
3969 It also tracks the subroutine call depth by saving the current setting of
3970 C<$single> in the C<@stack> package global; if this exceeds the value in
3971 C<$deep>, C<sub> automatically turns on printing of the current depth by
3972 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3973 of stop/don't stop on entry to subs set as it currently is set.
3974
3975 =head3 C<caller()> support
3976
3977 If C<caller()> is called from the package C<DB>, it provides some
3978 additional data, in the following order:
3979
3980 =over 4
3981
3982 =item * C<$package>
3983
3984 The package name the sub was in
3985
3986 =item * C<$filename>
3987
3988 The filename it was defined in
3989
3990 =item * C<$line>
3991
3992 The line number it was defined on
3993
3994 =item * C<$subroutine>
3995
3996 The subroutine name; C<(eval)> if an C<eval>().
3997
3998 =item * C<$hasargs>
3999
4000 1 if it has arguments, 0 if not
4001
4002 =item * C<$wantarray>
4003
4004 1 if array context, 0 if scalar context
4005
4006 =item * C<$evaltext>
4007
4008 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4009
4010 =item * C<$is_require>
4011
4012 frame was created by a C<use> or C<require> statement
4013
4014 =item * C<$hints>
4015
4016 pragma information; subject to change between versions
4017
4018 =item * C<$bitmask>
4019
4020 pragma information; subject to change between versions
4021
4022 =item * C<@DB::args>
4023
4024 arguments with which the subroutine was invoked
4025
4026 =back
4027
4028 =cut
4029
4030 use vars qw($deep);
4031
4032 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4033 # happy. -- Shlomi Fish
4034
4035 sub _indent_print_line_info {
4036     my ($offset, $str) = @_;
4037
4038     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4039
4040     return;
4041 }
4042
4043 sub _print_frame_message {
4044     my ($al) = @_;
4045
4046     if ($frame) {
4047         if ($frame & 4) {   # Extended frame entry message
4048             _indent_print_line_info(-1, "in  ");
4049
4050             # Why -1? But it works! :-(
4051             # Because print_trace will call add 1 to it and then call
4052             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4053             # in dump_trace.
4054             #
4055             # Now it's 0 because we extracted a function.
4056             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4057         }
4058         else {
4059             _indent_print_line_info(-1, "entering $sub$al\n" );
4060         }
4061     }
4062
4063     return;
4064 }
4065
4066 sub DB::sub {
4067     # Do not use a regex in this subroutine -> results in corrupted memory
4068     # See: [perl #66110]
4069
4070     # lock ourselves under threads
4071     lock($DBGR);
4072
4073     # Whether or not the autoloader was running, a scalar to put the
4074     # sub's return value in (if needed), and an array to put the sub's
4075     # return value in (if needed).
4076     my ( $al, $ret, @ret ) = "";
4077     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4078         print "creating new thread\n";
4079     }
4080
4081     # If the last ten characters are '::AUTOLOAD', note we've traced
4082     # into AUTOLOAD for $sub.
4083     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4084         no strict 'refs';
4085         $al = " for $$sub" if defined $$sub;
4086     }
4087
4088     # We stack the stack pointer and then increment it to protect us
4089     # from a situation that might unwind a whole bunch of call frames
4090     # at once. Localizing the stack pointer means that it will automatically
4091     # unwind the same amount when multiple stack frames are unwound.
4092     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4093
4094     # Expand @stack.
4095     $#stack = $stack_depth;
4096
4097     # Save current single-step setting.
4098     $stack[-1] = $single;
4099
4100     # Turn off all flags except single-stepping.
4101     $single &= 1;
4102
4103     # If we've gotten really deeply recursed, turn on the flag that will
4104     # make us stop with the 'deep recursion' message.
4105     $single |= 4 if $stack_depth == $deep;
4106
4107     # If frame messages are on ...
4108
4109     _print_frame_message($al);
4110     # standard frame entry message
4111
4112     my $print_exit_msg = sub {
4113         # Check for exit trace messages...
4114         if ($frame & 2)
4115         {
4116             if ($frame & 4)    # Extended exit message
4117             {
4118                 _indent_print_line_info(0, "out ");
4119                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4120             }
4121             else
4122             {
4123                 _indent_print_line_info(0, "exited $sub$al\n" );
4124             }
4125         }
4126         return;
4127     };
4128
4129     # Determine the sub's return type, and capture appropriately.
4130     if (wantarray) {
4131
4132         # Called in array context. call sub and capture output.
4133         # DB::DB will recursively get control again if appropriate; we'll come
4134         # back here when the sub is finished.
4135         {
4136             no strict 'refs';
4137             @ret = &$sub;
4138         }
4139
4140         # Pop the single-step value back off the stack.
4141         $single |= $stack[ $stack_depth-- ];
4142
4143         $print_exit_msg->();
4144
4145         # Print the return info if we need to.
4146         if ( $doret eq $stack_depth or $frame & 16 ) {
4147
4148             # Turn off output record separator.
4149             local $\ = '';
4150             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4151
4152             # Indent if we're printing because of $frame tracing.
4153             if ($frame & 16)
4154             {
4155                 print {$fh} ' ' x $stack_depth;
4156             }
4157
4158             # Print the return value.
4159             print {$fh} "list context return from $sub:\n";
4160             dumpit( $fh, \@ret );
4161
4162             # And don't print it again.
4163             $doret = -2;
4164         } ## end if ($doret eq $stack_depth...
4165             # And we have to return the return value now.
4166         @ret;
4167     } ## end if (wantarray)
4168
4169     # Scalar context.
4170     else {
4171         if ( defined wantarray ) {
4172             no strict 'refs';
4173             # Save the value if it's wanted at all.
4174             $ret = &$sub;
4175         }
4176         else {
4177             no strict 'refs';
4178             # Void return, explicitly.
4179             &$sub;
4180             undef $ret;
4181         }
4182
4183         # Pop the single-step value off the stack.
4184         $single |= $stack[ $stack_depth-- ];
4185
4186         # If we're doing exit messages...
4187         $print_exit_msg->();
4188
4189         # If we are supposed to show the return value... same as before.
4190         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4191             local $\ = '';
4192             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4193             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4194             print $fh (
4195                 defined wantarray
4196                 ? "scalar context return from $sub: "
4197                 : "void context return from $sub\n"
4198             );
4199             dumpit( $fh, $ret ) if defined wantarray;
4200             $doret = -2;
4201         } ## end if ($doret eq $stack_depth...
4202
4203         # Return the appropriate scalar value.
4204         $ret;
4205     } ## end else [ if (wantarray)
4206 } ## end sub _sub
4207
4208 sub lsub : lvalue {
4209
4210     no strict 'refs';
4211
4212     # lock ourselves under threads
4213     lock($DBGR);
4214
4215     # Whether or not the autoloader was running, a scalar to put the
4216     # sub's return value in (if needed), and an array to put the sub's
4217     # return value in (if needed).
4218     my ( $al, $ret, @ret ) = "";
4219     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4220         print "creating new thread\n";
4221     }
4222
4223     # If the last ten characters are C'::AUTOLOAD', note we've traced
4224     # into AUTOLOAD for $sub.
4225     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4226         $al = " for $$sub";
4227     }
4228
4229     # We stack the stack pointer and then increment it to protect us
4230     # from a situation that might unwind a whole bunch of call frames
4231     # at once. Localizing the stack pointer means that it will automatically
4232     # unwind the same amount when multiple stack frames are unwound.
4233     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4234
4235     # Expand @stack.
4236     $#stack = $stack_depth;
4237
4238     # Save current single-step setting.
4239     $stack[-1] = $single;
4240
4241     # Turn off all flags except single-stepping.
4242     $single &= 1;
4243
4244     # If we've gotten really deeply recursed, turn on the flag that will
4245     # make us stop with the 'deep recursion' message.
4246     $single |= 4 if $stack_depth == $deep;
4247
4248     # If frame messages are on ...
4249     _print_frame_message($al);
4250
4251     # Pop the single-step value back off the stack.
4252     $single |= $stack[ $stack_depth-- ];
4253
4254     # call the original lvalue sub.
4255     &$sub;
4256 }
4257
4258 # Abstracting common code from multiple places elsewhere:
4259 sub depth_print_lineinfo {
4260     my $always_print = shift;
4261
4262     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4263 }
4264
4265 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4266
4267 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4268 Most of the changes were to systematize the command structure and to eliminate
4269 commands that threw away user input without checking.
4270
4271 The following sections describe the code added to make it easy to support
4272 multiple command sets with conflicting command names. This section is a start
4273 at unifying all command processing to make it simpler to develop commands.
4274
4275 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4276 number, and C<$dbline> (the current line) as arguments.
4277
4278 Support functions in this section which have multiple modes of failure C<die>
4279 on error; the rest simply return a false value.
4280
4281 The user-interface functions (all of the C<cmd_*> functions) just output
4282 error messages.
4283
4284 =head2 C<%set>
4285
4286 The C<%set> hash defines the mapping from command letter to subroutine
4287 name suffix.
4288
4289 C<%set> is a two-level hash, indexed by set name and then by command name.
4290 Note that trying to set the CommandSet to C<foobar> simply results in the
4291 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4292
4293 =cut
4294
4295 ### The API section
4296
4297 my %set = (    #
4298     'pre580' => {
4299         'a' => 'pre580_a',
4300         'A' => 'pre580_null',
4301         'b' => 'pre580_b',
4302         'B' => 'pre580_null',
4303         'd' => 'pre580_null',
4304         'D' => 'pre580_D',
4305         'h' => 'pre580_h',
4306         'M' => 'pre580_null',
4307         'O' => 'o',
4308         'o' => 'pre580_null',
4309         'v' => 'M',
4310         'w' => 'v',
4311         'W' => 'pre580_W',
4312     },
4313     'pre590' => {
4314         '<'  => 'pre590_prepost',
4315         '<<' => 'pre590_prepost',
4316         '>'  => 'pre590_prepost',
4317         '>>' => 'pre590_prepost',
4318         '{'  => 'pre590_prepost',
4319         '{{' => 'pre590_prepost',
4320     },
4321 );
4322
4323 my %breakpoints_data;
4324
4325 sub _has_breakpoint_data_ref {
4326     my ($filename, $line) = @_;
4327
4328     return (
4329         exists( $breakpoints_data{$filename} )
4330             and
4331         exists( $breakpoints_data{$filename}{$line} )
4332     );
4333 }
4334
4335 sub _get_breakpoint_data_ref {
4336     my ($filename, $line) = @_;
4337
4338     return ($breakpoints_data{$filename}{$line} ||= +{});
4339 }
4340
4341 sub _delete_breakpoint_data_ref {
4342     my ($filename, $line) = @_;
4343
4344     delete($breakpoints_data{$filename}{$line});
4345     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4346         delete($breakpoints_data{$filename});
4347     }
4348
4349     return;
4350 }
4351
4352 sub _set_breakpoint_enabled_status {
4353     my ($filename, $line, $status) = @_;
4354
4355     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4356         ($status ? 1 : '')
4357         ;
4358
4359     return;
4360 }
4361
4362 sub _enable_breakpoint_temp_enabled_status {
4363     my ($filename, $line) = @_;
4364
4365     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4366
4367     return;
4368 }
4369
4370 sub _cancel_breakpoint_temp_enabled_status {
4371     my ($filename, $line) = @_;
4372
4373     my $ref = _get_breakpoint_data_ref($filename, $line);
4374
4375     delete ($ref->{'temp_enabled'});
4376
4377     if (! %$ref) {
4378         _delete_breakpoint_data_ref($filename, $line);
4379     }
4380
4381     return;
4382 }
4383
4384 sub _is_breakpoint_enabled {
4385     my ($filename, $line) = @_;
4386
4387     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4388     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4389 }
4390
4391 =head2 C<cmd_wrapper()> (API)
4392
4393 C<cmd_wrapper()> allows the debugger to switch command sets
4394 depending on the value of the C<CommandSet> option.
4395
4396 It tries to look up the command in the C<%set> package-level I<lexical>
4397 (which means external entities can't fiddle with it) and create the name of
4398 the sub to call based on the value found in the hash (if it's there). I<All>
4399 of the commands to be handled in a set have to be added to C<%set>; if they
4400 aren't found, the 5.8.0 equivalent is called (if there is one).
4401
4402 This code uses symbolic references.
4403
4404 =cut
4405
4406 sub cmd_wrapper {
4407     my $cmd      = shift;
4408     my $line     = shift;
4409     my $dblineno = shift;
4410
4411     # Assemble the command subroutine's name by looking up the
4412     # command set and command name in %set. If we can't find it,
4413     # default to the older version of the command.
4414     my $call = 'cmd_'
4415       . ( $set{$CommandSet}{$cmd}
4416           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4417
4418     # Call the command subroutine, call it by name.
4419     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4420 } ## end sub cmd_wrapper
4421
4422 =head3 C<cmd_a> (command)
4423
4424 The C<a> command handles pre-execution actions. These are associated with a
4425 particular line, so they're stored in C<%dbline>. We default to the current
4426 line if none is specified.
4427
4428 =cut
4429
4430 sub cmd_a {
4431     my $cmd    = shift;
4432     my $line   = shift || '';    # [.|line] expr
4433     my $dbline = shift;
4434
4435     # If it's dot (here), or not all digits,  use the current line.
4436     $line =~ s/\A\./$dbline/;
4437
4438     # Should be a line number followed by an expression.
4439     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4440
4441         if (! length($lineno)) {
4442             $lineno = $dbline;
4443         }
4444
4445         # If we have an expression ...
4446         if ( length $expr ) {
4447
4448             # ... but the line isn't breakable, complain.
4449             if ( $dbline[$lineno] == 0 ) {
4450                 print $OUT
4451                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4452             }
4453             else {
4454
4455                 # It's executable. Record that the line has an action.
4456                 $had_breakpoints{$filename} |= 2;
4457
4458                 # Remove any action, temp breakpoint, etc.
4459                 $dbline{$lineno} =~ s/\0[^\0]*//;
4460
4461                 # Add the action to the line.
4462                 $dbline{$lineno} .= "\0" . action($expr);
4463
4464                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4465             }
4466         } ## end if (length $expr)
4467     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4468     else {
4469
4470         # Syntax wrong.
4471         print $OUT
4472           "Adding an action requires an optional lineno and an expression\n"
4473           ;    # hint
4474     }
4475 } ## end sub cmd_a
4476
4477 =head3 C<cmd_A> (command)
4478
4479 Delete actions. Similar to above, except the delete code is in a separate
4480 subroutine, C<delete_action>.
4481
4482 =cut
4483
4484 sub cmd_A {
4485     my $cmd    = shift;
4486     my $line   = shift || '';
4487     my $dbline = shift;
4488
4489     # Dot is this line.
4490     $line =~ s/^\./$dbline/;
4491
4492     # Call delete_action with a null param to delete them all.
4493     # The '1' forces the eval to be true. It'll be false only
4494     # if delete_action blows up for some reason, in which case
4495     # we print $@ and get out.
4496     if ( $line eq '*' ) {
4497         if (! eval { _delete_all_actions(); 1 }) {
4498             print {$OUT} $@;
4499             return;
4500         }
4501     }
4502
4503     # There's a real line  number. Pass it to delete_action.
4504     # Error trapping is as above.
4505     elsif ( $line =~ /^(\S.*)/ ) {
4506         if (! eval { delete_action($1); 1 }) {
4507             print {$OUT} $@;
4508             return;
4509         }
4510     }
4511
4512     # Swing and a miss. Bad syntax.
4513     else {
4514         print $OUT
4515           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4516     }
4517 } ## end sub cmd_A
4518
4519 =head3 C<delete_action> (API)
4520
4521 C<delete_action> accepts either a line number or C<undef>. If a line number
4522 is specified, we check for the line being executable (if it's not, it
4523 couldn't have had an  action). If it is, we just take the action off (this
4524 will get any kind of an action, including breakpoints).
4525
4526 =cut
4527
4528 sub _remove_action_from_dbline {
4529     my $i = shift;
4530
4531     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4532     delete $dbline{$i} if $dbline{$i} eq '';
4533
4534     return;
4535 }
4536
4537 sub _delete_all_actions {
4538     print {$OUT} "Deleting all actions...\n";
4539
4540     for my $file ( keys %had_breakpoints ) {
4541         local *dbline = $main::{ '_<' . $file };
4542         $max = $#dbline;
4543         my $was;
4544         for my $i (1 .. $max) {
4545             if ( defined $dbline{$i} ) {
4546                 _remove_action_from_dbline($i);
4547             }
4548         }
4549
4550         unless ( $had_breakpoints{$file} &= ~2 ) {
4551             delete $had_breakpoints{$file};
4552         }
4553     }
4554
4555     return;
4556 }
4557
4558 sub delete_action {
4559     my $i = shift;
4560
4561     if ( defined($i) ) {
4562         # Can there be one?
4563         die "Line $i has no action .\n" if $dbline[$i] == 0;
4564
4565         # Nuke whatever's there.
4566         _remove_action_from_dbline($i);
4567     }
4568     else {
4569         _delete_all_actions();
4570     }
4571 }
4572
4573 =head3 C<cmd_b> (command)
4574
4575 Set breakpoints. Since breakpoints can be set in so many places, in so many
4576 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4577 we try to parse the command type, and then shuttle it off to an appropriate
4578 subroutine to actually do the work of setting the breakpoint in the right
4579 place.
4580
4581 =cut
4582
4583 sub cmd_b {
4584     my $cmd    = shift;
4585     my $line   = shift;    # [.|line] [cond]
4586     my $dbline = shift;
4587
4588     my $default_cond = sub {
4589         my $cond = shift;
4590         return length($cond) ? $cond : '1';
4591     };
4592
4593     # Make . the current line number if it's there..
4594     $line =~ s/^\.(\s|\z)/$dbline$1/;
4595
4596     # No line number, no condition. Simple break on current line.
4597     if ( $line =~ /^\s*$/ ) {
4598         cmd_b_line( $dbline, 1 );
4599     }
4600
4601     # Break on load for a file.
4602     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4603         $file =~ s/\s+\z//;
4604         cmd_b_load($file);
4605     }
4606
4607     # b compile|postpone <some sub> [<condition>]
4608     # The interpreter actually traps this one for us; we just put the
4609     # necessary condition in the %postponed hash.
4610     elsif ( my ($action, $subname, $cond)
4611         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4612
4613         # De-Perl4-ify the name - ' separators to ::.
4614         $subname =~ s/'/::/g;
4615
4616         # Qualify it into the current package unless it's already qualified.
4617         $subname = "${package}::" . $subname unless $subname =~ /::/;
4618
4619         # Add main if it starts with ::.
4620         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4621
4622         # Save the break type for this sub.
4623         $postponed{$subname} = (($action eq 'postpone')
4624             ? ( "break +0 if " . $default_cond->($cond) )
4625             : "compile");
4626     } ## end elsif ($line =~ ...
4627     # b <filename>:<line> [<condition>]
4628     elsif (my ($filename, $line_num, $cond)
4629         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4630         cmd_b_filename_line(
4631             $filename,
4632             $line_num,
4633             (length($cond) ? $cond : '1'),
4634         );
4635     }
4636     # b <sub name> [<condition>]
4637     elsif ( my ($new_subname, $new_cond) =
4638         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4639
4640         #
4641         $subname = $new_subname;
4642         cmd_b_sub( $subname, $default_cond->($new_cond) );
4643     }
4644
4645     # b <line> [<condition>].
4646     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4647
4648         # Capture the line. If none, it's the current line.
4649         $line = $line_n || $dbline;
4650
4651         # Break on line.
4652         cmd_b_line( $line, $default_cond->($cond) );
4653     }
4654
4655     # Line didn't make sense.
4656     else {
4657         print "confused by line($line)?\n";
4658     }
4659
4660     return;
4661 } ## end sub cmd_b
4662
4663 =head3 C<break_on_load> (API)
4664
4665 We want to break when this file is loaded. Mark this file in the
4666 C<%break_on_load> hash, and note that it has a breakpoint in
4667 C<%had_breakpoints>.
4668
4669 =cut
4670
4671 sub break_on_load {
4672     my $file = shift;
4673     $break_on_load{$file} = 1;
4674     $had_breakpoints{$file} |= 1;
4675 }
4676
4677 =head3 C<report_break_on_load> (API)
4678
4679 Gives us an array of filenames that are set to break on load. Note that
4680 only files with break-on-load are in here, so simply showing the keys
4681 suffices.
4682
4683 =cut
4684
4685 sub report_break_on_load {
4686     sort keys %break_on_load;
4687 }
4688
4689 =head3 C<cmd_b_load> (command)
4690
4691 We take the file passed in and try to find it in C<%INC> (which maps modules
4692 to files they came from). We mark those files for break-on-load via
4693 C<break_on_load> and then report that it was done.
4694
4695 =cut
4696
4697 sub cmd_b_load {
4698     my $file = shift;
4699     my @files;
4700
4701     # This is a block because that way we can use a redo inside it
4702     # even without there being any looping structure at all outside it.
4703     {
4704
4705         # Save short name and full path if found.
4706         push @files, $file;
4707         push @files, $::INC{$file} if $::INC{$file};
4708
4709         # Tack on .pm and do it again unless there was a '.' in the name
4710         # already.
4711         $file .= '.pm', redo unless $file =~ /\./;
4712     }
4713
4714     # Do the real work here.
4715     break_on_load($_) for @files;
4716
4717     # All the files that have break-on-load breakpoints.
4718     @files = report_break_on_load;
4719
4720     # Normalize for the purposes of our printing this.
4721     local $\ = '';
4722     local $" = ' ';
4723     print $OUT "Will stop on load of '@files'.\n";
4724 } ## end sub cmd_b_load
4725
4726 =head3 C<$filename_error> (API package global)
4727
4728 Several of the functions we need to implement in the API need to work both
4729 on the current file and on other files. We don't want to duplicate code, so
4730 C<$filename_error> is used to contain the name of the file that's being
4731 worked on (if it's not the current one).
4732
4733 We can now build functions in pairs: the basic function works on the current
4734 file, and uses C<$filename_error> as part of its error message. Since this is
4735 initialized to C<"">, no filename will appear when we are working on the
4736 current file.
4737
4738 The second function is a wrapper which does the following:
4739
4740 =over 4
4741
4742 =item *
4743
4744 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4745
4746 =item *
4747
4748 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4749
4750 =item *
4751
4752 Calls the first function.
4753
4754 The first function works on the I<current> file (i.e., the one we changed to),
4755 and prints C<$filename_error> in the error message (the name of the other file)
4756 if it needs to. When the functions return, C<*dbline> is restored to point
4757 to the actual current file (the one we're executing in) and
4758 C<$filename_error> is restored to C<"">. This restores everything to
4759 the way it was before the second function was called at all.
4760
4761 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4762 details.
4763
4764 =back
4765
4766 =cut
4767
4768 use vars qw($filename_error);
4769 $filename_error = '';
4770
4771 =head3 breakable_line(from, to) (API)
4772
4773 The subroutine decides whether or not a line in the current file is breakable.
4774 It walks through C<@dbline> within the range of lines specified, looking for
4775 the first line that is breakable.
4776
4777 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4778 first line I<after> C<$to> that's breakable, if there is one.
4779
4780 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4781 first line I<before> C<$to> that's breakable, if there is one.
4782
4783 =cut
4784
4785 sub breakable_line {
4786
4787     my ( $from, $to ) = @_;
4788
4789     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4790     my $i = $from;
4791
4792     # If there are at least 2 arguments, we're trying to search a range.
4793     if ( @_ >= 2 ) {
4794
4795         # $delta is positive for a forward search, negative for a backward one.
4796         my $delta = $from < $to ? +1 : -1;
4797
4798         # Keep us from running off the ends of the file.
4799         my $limit = $delta > 0 ? $#dbline : 1;
4800
4801         # Clever test. If you're a mathematician, it's obvious why this
4802         # test works. If not:
4803         # If $delta is positive (going forward), $limit will be $#dbline.
4804         #    If $to is less than $limit, ($limit - $to) will be positive, times
4805         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4806         #    as the stopping point.
4807         #
4808         #    If $to is greater than $limit, ($limit - $to) is negative,
4809         #    times $delta of 1 (positive), so the result is < 0 and we should
4810         #    use $limit ($#dbline) as the stopping point.
4811         #
4812         # If $delta is negative (going backward), $limit will be 1.
4813         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4814         #    (negative) so the result is > 0, and we use $to as the stopping
4815         #    point.
4816         #
4817         #    If $to is less than zero, ($limit - $to) will be positive,
4818         #    times $delta of -1 (negative), so the result is not > 0, and
4819         #    we use $limit (1) as the stopping point.
4820         #
4821         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4822         #    (negative), still giving zero; the result is not > 0, and
4823         #    we use $limit (1) as the stopping point.
4824         #
4825         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4826         #    (negative), giving a positive (>0) value, so we'll set $limit to
4827         #    $to.
4828
4829         $limit = $to if ( $limit - $to ) * $delta > 0;
4830
4831         # The real search loop.
4832         # $i starts at $from (the point we want to start searching from).
4833         # We move through @dbline in the appropriate direction (determined
4834         # by $delta: either -1 (back) or +1 (ahead).
4835         # We stay in as long as we haven't hit an executable line
4836         # ($dbline[$i] == 0 means not executable) and we haven't reached
4837         # the limit yet (test similar to the above).
4838         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4839
4840     } ## end if (@_ >= 2)
4841
4842     # If $i points to a line that is executable, return that.
4843     return $i unless $dbline[$i] == 0;
4844
4845     # Format the message and print it: no breakable lines in range.
4846     my ( $pl, $upto ) = ( '', '' );
4847     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4848
4849     # If there's a filename in filename_error, we'll see it.
4850     # If not, not.
4851     die "Line$pl $from$upto$filename_error not breakable\n";
4852 } ## end sub breakable_line
4853
4854 =head3 breakable_line_in_filename(file, from, to) (API)
4855
4856 Like C<breakable_line>, but look in another file.
4857
4858 =cut
4859
4860 sub breakable_line_in_filename {
4861
4862     # Capture the file name.
4863     my ($f) = shift;
4864
4865     # Swap the magic line array over there temporarily.
4866     local *dbline = $main::{ '_<' . $f };
4867
4868     # If there's an error, it's in this other file.
4869     local $filename_error = " of '$f'";
4870
4871     # Find the breakable line.
4872     breakable_line(@_);
4873
4874     # *dbline and $filename_error get restored when this block ends.
4875
4876 } ## end sub breakable_line_in_filename
4877
4878 =head3 break_on_line(lineno, [condition]) (API)
4879
4880 Adds a breakpoint with the specified condition (or 1 if no condition was
4881 specified) to the specified line. Dies if it can't.
4882
4883 =cut
4884
4885 sub break_on_line {
4886     my $i = shift;
4887     my $cond = @_ ? shift(@_) : 1;
4888
4889     my $inii  = $i;
4890     my $after = '';
4891     my $pl    = '';
4892
4893     # Woops, not a breakable line. $filename_error allows us to say
4894     # if it was in a different file.
4895     die "Line $i$filename_error not breakable.\n" if $dbline[$i] == 0;
4896
4897     # Mark this file as having breakpoints in it.
4898     $had_breakpoints{$filename} |= 1;
4899
4900     # If there is an action or condition here already ...
4901     if ( $dbline{$i} ) {
4902
4903         # ... swap this condition for the existing one.
4904         $dbline{$i} =~ s/^[^\0]*/$cond/;
4905     }
4906     else {
4907
4908         # Nothing here - just add the condition.
4909         $dbline{$i} = $cond;
4910
4911         _set_breakpoint_enabled_status($filename, $i, 1);
4912     }
4913
4914     return;
4915 } ## end sub break_on_line
4916
4917 =head3 cmd_b_line(line, [condition]) (command)
4918
4919 Wrapper for C<break_on_line>. Prints the failure message if it
4920 doesn't work.
4921
4922 =cut
4923
4924 sub cmd_b_line {
4925     if (not eval { break_on_line(@_); 1 }) {
4926         local $\ = '';
4927         print $OUT $@ and return;
4928     }
4929
4930     return;
4931 } ## end sub cmd_b_line
4932
4933 =head3 cmd_b_filename_line(line, [condition]) (command)
4934
4935 Wrapper for C<break_on_filename_line>. Prints the failure message if it
4936 doesn't work.
4937
4938 =cut
4939
4940 sub cmd_b_filename_line {
4941     if (not eval { break_on_filename_line(@_); 1 }) {
4942         local $\ = '';
4943         print $OUT $@ and return;
4944     }
4945
4946     return;
4947 }
4948
4949 =head3 break_on_filename_line(file, line, [condition]) (API)
4950
4951 Switches to the file specified and then calls C<break_on_line> to set
4952 the breakpoint.
4953
4954 =cut
4955
4956 sub break_on_filename_line {
4957     my $f = shift;
4958     my $i = shift;
4959     my $cond = @_ ? shift(@_) : 1;
4960
4961     # Switch the magical hash temporarily.
4962     local *dbline = $main::{ '_<' . $f };
4963
4964     # Localize the variables that break_on_line uses to make its message.
4965     local $filename_error = " of '$f'";
4966     local $filename       = $f;
4967
4968     # Add the breakpoint.
4969     break_on_line( $i, $cond );
4970
4971     return;
4972 } ## end sub break_on_filename_line
4973
4974 =head3 break_on_filename_line_range(file, from, to, [condition]) (API)
4975
4976 Switch to another file, search the range of lines specified for an
4977 executable one, and put a breakpoint on the first one you find.
4978
4979 =cut
4980
4981 sub break_on_filename_line_range {
4982     my $f = shift;
4983     my $from = shift;
4984     my $to = shift;
4985     my $cond = @_ ? shift(@_) : 1;
4986
4987     # Find a breakable line if there is one.
4988     my $i = breakable_line_in_filename( $f, $from, $to );
4989
4990     # Add the breakpoint.
4991     break_on_filename_line( $f, $i, $cond );
4992
4993     return;
4994 } ## end sub break_on_filename_line_range
4995
4996 =head3 subroutine_filename_lines(subname, [condition]) (API)
4997
4998 Search for a subroutine within a given file. The condition is ignored.
4999 Uses C<find_sub> to locate the desired subroutine.
5000
5001 =cut
5002
5003 sub subroutine_filename_lines {
5004     my ( $subname ) = @_;
5005
5006     # Returned value from find_sub() is fullpathname:startline-endline.
5007     # The match creates the list (fullpathname, start, end).
5008     return (find_sub($subname) =~ /^(.*):(\d+)-(\d+)$/);
5009 } ## end sub subroutine_filename_lines
5010
5011 =head3 break_subroutine(subname) (API)
5012
5013 Places a break on the first line possible in the specified subroutine. Uses
5014 C<subroutine_filename_lines> to find the subroutine, and
5015 C<break_on_filename_line_range> to place the break.
5016
5017 =cut
5018
5019 sub break_subroutine {
5020     my $subname = shift;
5021
5022     # Get filename, start, and end.
5023     my ( $file, $s, $e ) = subroutine_filename_lines($subname)
5024       or die "Subroutine $subname not found.\n";
5025
5026
5027     # Null condition changes to '1' (always true).
5028     my $cond = @_ ? shift(@_) : 1;
5029
5030     # Put a break the first place possible in the range of lines
5031     # that make up this subroutine.
5032     break_on_filename_line_range( $file, $s, $e, $cond );
5033
5034     return;
5035 } ## end sub break_subroutine
5036
5037 =head3 cmd_b_sub(subname, [condition]) (command)
5038
5039 We take the incoming subroutine name and fully-qualify it as best we can.
5040
5041 =over 4
5042
5043 =item 1. If it's already fully-qualified, leave it alone.
5044
5045 =item 2. Try putting it in the current package.
5046
5047 =item 3. If it's not there, try putting it in CORE::GLOBAL if it exists there.
5048
5049 =item 4. If it starts with '::', put it in 'main::'.
5050
5051 =back
5052
5053 After all this cleanup, we call C<break_subroutine> to try to set the
5054 breakpoint.
5055
5056 =cut
5057
5058 sub cmd_b_sub {
5059     my ( $subname, $cond ) = @_;
5060
5061     # Add always-true condition if we have none.
5062     $cond = 1 unless @_ >= 2;
5063
5064     # If the subname isn't a code reference, qualify it so that
5065     # break_subroutine() will work right.
5066     unless ( ref $subname eq 'CODE' ) {
5067
5068         # Not Perl4.
5069         $subname =~ s/\'/::/g;
5070         my $s = $subname;
5071
5072         # Put it in this package unless it's already qualified.
5073         $subname = "${package}::" . $subname
5074           unless $subname =~ /::/;
5075
5076         # Requalify it into CORE::GLOBAL if qualifying it into this
5077         # package resulted in its not being defined, but only do so
5078         # if it really is in CORE::GLOBAL.
5079         $subname = "CORE::GLOBAL::$s"
5080           if not defined &$subname
5081           and $s !~ /::/
5082           and defined &{"CORE::GLOBAL::$s"};
5083
5084         # Put it in package 'main' if it has a leading ::.
5085         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5086
5087     } ## end unless (ref $subname eq 'CODE')
5088
5089     # Try to set the breakpoint.
5090     if (not eval { break_subroutine( $subname, $cond ); 1 }) {
5091         local $\ = '';
5092         print $OUT $@ and return;
5093     }
5094
5095     return;
5096 } ## end sub cmd_b_sub
5097
5098 =head3 C<cmd_B> - delete breakpoint(s) (command)
5099
5100 The command mostly parses the command line and tries to turn the argument
5101 into a line spec. If it can't, it uses the current line. It then calls
5102 C<delete_breakpoint> to actually do the work.
5103
5104 If C<*> is  specified, C<cmd_B> calls C<delete_breakpoint> with no arguments,
5105 thereby deleting all the breakpoints.
5106
5107 =cut
5108
5109 sub cmd_B {
5110     my $cmd = shift;
5111
5112     # No line spec? Use dbline.
5113     # If there is one, use it if it's non-zero, or wipe it out if it is.
5114     my $line   = ( $_[0] =~ /\A\./ ) ? $dbline : (shift || '');
5115     my $dbline = shift;
5116
5117     # If the line was dot, make the line the current one.
5118     $line =~ s/^\./$dbline/;
5119
5120     # If it's * we're deleting all the breakpoints.
5121     if ( $line eq '*' ) {
5122         if (not eval { delete_breakpoint(); 1 }) {
5123             print {$OUT} $@;
5124         }
5125     }
5126
5127     # If there is a line spec, delete the breakpoint on that line.
5128     elsif ( $line =~ /\A(\S.*)/ ) {
5129         if (not eval { delete_breakpoint( $line || $dbline ); 1 }) {
5130             local $\ = '';
5131             print {$OUT} $@;
5132         }
5133     } ## end elsif ($line =~ /^(\S.*)/)
5134
5135     # No line spec.
5136     else {
5137         print {$OUT}
5138           "Deleting a breakpoint requires a line number, or '*' for all\n"
5139           ;    # hint
5140     }
5141
5142     return;
5143 } ## end sub cmd_B
5144
5145 =head3 delete_breakpoint([line]) (API)
5146
5147 This actually does the work of deleting either a single breakpoint, or all
5148 of them.
5149
5150 For a single line, we look for it in C<@dbline>. If it's nonbreakable, we
5151 just drop out with a message saying so. If it is, we remove the condition
5152 part of the 'condition\0action' that says there's a breakpoint here. If,
5153 after we've done that, there's nothing left, we delete the corresponding
5154 line in C<%dbline> to signal that no action needs to be taken for this line.
5155
5156 For all breakpoints, we iterate through the keys of C<%had_breakpoints>,
5157 which lists all currently-loaded files which have breakpoints. We then look
5158 at each line in each of these files, temporarily switching the C<%dbline>
5159 and C<@dbline> structures to point to the files in question, and do what
5160 we did in the single line case: delete the condition in C<@dbline>, and
5161 delete the key in C<%dbline> if nothing's left.
5162
5163 We then wholesale delete C<%postponed>, C<%postponed_file>, and
5164 C<%break_on_load>, because these structures contain breakpoints for files
5165 and code that haven't been loaded yet. We can just kill these off because there
5166 are no magical debugger structures associated with them.
5167
5168 =cut
5169
5170 sub _remove_breakpoint_entry {
5171     my ($fn, $i) = @_;
5172
5173     delete $dbline{$i};
5174     _delete_breakpoint_data_ref($fn, $i);
5175
5176     return;
5177 }
5178
5179 sub _delete_all_breakpoints {
5180     print {$OUT} "Deleting all breakpoints...\n";
5181
5182     # %had_breakpoints lists every file that had at least one
5183     # breakpoint in it.
5184     for my $fn ( keys %had_breakpoints ) {
5185
5186         # Switch to the desired file temporarily.
5187         local *dbline = $main::{ '_<' . $fn };
5188
5189         $max = $#dbline;
5190
5191         # For all lines in this file ...
5192         for my $i (1 .. $max) {
5193
5194             # If there's a breakpoint or action on this line ...
5195             if ( defined $dbline{$i} ) {
5196
5197                 # ... remove the breakpoint.
5198                 $dbline{$i} =~ s/\A[^\0]+//;
5199                 if ( $dbline{$i} =~ s/\A\0?\z// ) {
5200                     # Remove the entry altogether if no action is there.
5201                     _remove_breakpoint_entry($fn, $i);
5202                 }
5203             } ## end if (defined $dbline{$i...
5204         } ## end for $i (1 .. $max)
5205
5206         # If, after we turn off the "there were breakpoints in this file"
5207         # bit, the entry in %had_breakpoints for this file is zero,
5208         # we should remove this file from the hash.
5209         if ( not $had_breakpoints{$fn} &= (~1) ) {
5210             delete $had_breakpoints{$fn};
5211         }
5212     } ## end for my $fn (keys %had_breakpoints)
5213
5214     # Kill off all the other breakpoints that are waiting for files that
5215     # haven't been loaded yet.
5216     undef %postponed;
5217     undef %postponed_file;
5218     undef %break_on_load;
5219
5220     return;
5221 }
5222
5223 sub _delete_breakpoint_from_line {
5224     my ($i) = @_;
5225
5226     # Woops. This line wasn't breakable at all.
5227     die "Line $i not breakable.\n" if $dbline[$i] == 0;
5228
5229     # Kill the condition, but leave any action.
5230     $dbline{$i} =~ s/\A[^\0]*//;
5231
5232     # Remove the entry entirely if there's no action left.
5233     if ($dbline{$i} eq '') {
5234         _remove_breakpoint_entry($filename, $i);
5235     }
5236
5237     return;
5238 }
5239
5240 sub delete_breakpoint {
5241     my $i = shift;
5242
5243     # If we got a line, delete just that one.
5244     if ( defined($i) ) {
5245         _delete_breakpoint_from_line($i);
5246     }
5247     # No line; delete them all.
5248     else {
5249         _delete_all_breakpoints();
5250     }
5251
5252     return;
5253 }
5254
5255 =head3 cmd_stop (command)
5256
5257 This is meant to be part of the new command API, but it isn't called or used
5258 anywhere else in the debugger. XXX It is probably meant for use in development
5259 of new commands.
5260
5261 =cut
5262
5263 sub cmd_stop {    # As on ^C, but not signal-safy.
5264     $signal = 1;
5265 }
5266
5267 =head3 C<cmd_e> - threads
5268
5269 Display the current thread id:
5270
5271     e
5272
5273 This could be how (when implemented) to send commands to this thread id (e cmd)
5274 or that thread id (e tid cmd).
5275
5276 =cut
5277
5278 sub cmd_e {
5279     my $cmd  = shift;
5280     my $line = shift;
5281     unless (exists($INC{'threads.pm'})) {
5282         print "threads not loaded($ENV{PERL5DB_THREADED})
5283         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5284     } else {
5285         my $tid = threads->tid;
5286         print "thread id: $tid\n";
5287     }
5288 } ## end sub cmd_e
5289
5290 =head3 C<cmd_E> - list of thread ids
5291
5292 Display the list of available thread ids:
5293
5294     E
5295
5296 This could be used (when implemented) to send commands to all threads (E cmd).
5297
5298 =cut
5299
5300 sub cmd_E {
5301     my $cmd  = shift;
5302     my $line = shift;
5303     unless (exists($INC{'threads.pm'})) {
5304         print "threads not loaded($ENV{PERL5DB_THREADED})
5305         please run the debugger with PERL5DB_THREADED=1 set in the environment\n";
5306     } else {
5307         my $tid = threads->tid;
5308         print "thread ids: ".join(', ',
5309             map { ($tid == $_->tid ? '<'.$_->tid.'>' : $_->tid) } threads->list
5310         )."\n";
5311     }
5312 } ## end sub cmd_E
5313
5314 =head3 C<cmd_h> - help command (command)
5315
5316 Does the work of either
5317
5318 =over 4
5319
5320 =item *
5321
5322 Showing all the debugger help
5323
5324 =item *
5325
5326 Showing help for a specific command
5327
5328 =back
5329
5330 =cut
5331
5332 use vars qw($help);
5333 use vars qw($summary);
5334
5335 sub cmd_h {
5336     my $cmd = shift;
5337
5338     # If we have no operand, assume null.
5339     my $line = shift || '';
5340
5341     # 'h h'. Print the long-format help.
5342     if ( $line =~ /\Ah\s*\z/ ) {
5343         print_help($help);
5344     }
5345
5346     # 'h <something>'. Search for the command and print only its help.
5347     elsif ( my ($asked) = $line =~ /\A(\S.*)\z/ ) {
5348
5349         # support long commands; otherwise bogus errors
5350         # happen when you ask for h on <CR> for example
5351         my $qasked = quotemeta($asked);    # for searching; we don't
5352                                            # want to use it as a pattern.
5353                                            # XXX: finds CR but not <CR>
5354
5355         # Search the help string for the command.
5356         if (
5357             $help =~ /^                    # Start of a line
5358                       <?                   # Optional '<'
5359                       (?:[IB]<)            # Optional markup
5360                       $qasked              # The requested command
5361                      /mx
5362           )
5363         {
5364
5365             # It's there; pull it out and print it.
5366             while (
5367                 $help =~ /^
5368                               (<?            # Optional '<'
5369                                  (?:[IB]<)   # Optional markup
5370                                  $qasked     # The command
5371                                  ([\s\S]*?)  # Description line(s)
5372                               \n)            # End of last description line
5373                               (?!\s)         # Next line not starting with
5374                                              # whitespace
5375                              /mgx
5376               )
5377             {
5378                 print_help($1);
5379             }
5380         }
5381
5382         # Not found; not a debugger command.
5383         else {
5384             print_help("B<$asked> is not a debugger command.\n");
5385         }
5386     } ## end elsif ($line =~ /^(\S.*)$/)
5387
5388     # 'h' - print the summary help.
5389     else {
5390         print_help($summary);
5391     }
5392 } ## end sub cmd_h
5393
5394 =head3 C<cmd_i> - inheritance display
5395
5396 Display the (nested) parentage of the module or object given.
5397
5398 =cut
5399
5400 sub cmd_i {
5401     my $cmd  = shift;
5402     my $line = shift;
5403     foreach my $isa ( split( /\s+/, $line ) ) {
5404         $evalarg = $isa;
5405         ($isa) = DB::eval();
5406         no strict 'refs';
5407         print join(
5408             ', ',
5409             map {
5410                 "$_"
5411                   . (
5412                     defined( ${"$_\::VERSION"} )
5413                     ? ' ' . ${"$_\::VERSION"}
5414                     : undef )
5415               } @{mro::get_linear_isa(ref($isa) || $isa)}
5416         );
5417         print "\n";
5418     }
5419 } ## end sub cmd_i
5420
5421 =head3 C<cmd_l> - list lines (command)
5422
5423 Most of the command is taken up with transforming all the different line
5424 specification syntaxes into 'start-stop'. After that is done, the command
5425 runs a loop over C<@dbline> for the specified range of lines. It handles
5426 the printing of each line and any markers (C<==E<gt>> for current line,
5427 C<b> for break on this line, C<a> for action on this line, C<:> for this
5428 line breakable).
5429
5430 We save the last line listed in the C<$start> global for further listing
5431 later.
5432
5433 =cut
5434
5435 sub cmd_l {
5436     my $current_line = $line;
5437     my $cmd  = shift;
5438     my $line = shift;
5439
5440     # If this is '-something', delete any spaces after the dash.
5441     $line =~ s/^-\s*$/-/;
5442
5443     # If the line is '$something', assume this is a scalar containing a
5444     # line number.
5445     if ( $line =~ /^(\$.*)/s ) {
5446
5447         # Set up for DB::eval() - evaluate in *user* context.
5448         $evalarg = $1;
5449         # $evalarg = $2;
5450         my ($s) = DB::eval();
5451
5452         # Ooops. Bad scalar.
5453         if ($@) {
5454             print {$OUT} "Error: $@\n";
5455             next CMD;
5456         }
5457
5458         # Good scalar. If it's a reference, find what it points to.
5459         $s = CvGV_name($s);
5460         print {$OUT} "Interpreted as: $1 $s\n";
5461         $line = "$1 $s";
5462
5463         # Call self recursively to really do the command.
5464         cmd_l( 'l', $s );
5465     } ## end if ($line =~ /^(\$.*)/s)
5466
5467     # l name. Try to find a sub by that name.
5468     elsif ( ($subname) = $line =~ /\A([\':A-Za-z_][\':\w]*(?:\[.*\])?)/s ) {
5469         my $s = $subname;
5470
5471         # De-Perl4.
5472         $subname =~ s/\'/::/;
5473
5474         # Put it in this package unless it starts with ::.
5475         $subname = $package . "::" . $subname unless $subname =~ /::/;
5476
5477         # Put it in CORE::GLOBAL if t doesn't start with :: and
5478         # it doesn't live in this package and it lives in CORE::GLOBAL.
5479         $subname = "CORE::GLOBAL::$s"
5480           if not defined &$subname
5481           and $s !~ /::/
5482           and defined &{"CORE::GLOBAL::$s"};
5483
5484         # Put leading '::' names into 'main::'.
5485         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
5486
5487         # Get name:start-stop from find_sub, and break this up at
5488         # colons.
5489         my @pieces = split( /:/, find_sub($subname) || $sub{$subname} );
5490
5491         # Pull off start-stop.
5492         my $subrange = pop @pieces;
5493
5494         # If the name contained colons, the split broke it up.
5495         # Put it back together.
5496         $file = join( ':', @pieces );
5497
5498         # If we're not in that file, switch over to it.
5499         if ( $file ne $filename ) {
5500             print $OUT "Switching to file '$file'.\n"
5501               unless $slave_editor;
5502
5503             # Switch debugger's magic structures.
5504             *dbline   = $main::{ '_<' . $file };
5505             $max      = $#dbline;
5506             $filename = $file;
5507         } ## end if ($file ne $filename)
5508
5509         # Subrange is 'start-stop'. If this is less than a window full,
5510         # swap it to 'start+', which will list a window from the start point.
5511         if ($subrange) {
5512             if ( eval($subrange) < -$window ) {
5513                 $subrange =~ s/-.*/+/;
5514             }
5515
5516             # Call self recursively to list the range.
5517             $line = $subrange;
5518             cmd_l( 'l', $subrange );
5519         } ## end if ($subrange)
5520
5521         # Couldn't find it.
5522         else {
5523             print $OUT "Subroutine $subname not found.\n";
5524         }
5525     } ## end elsif ($line =~ /^([\':A-Za-z_][\':\w]*(\[.*\])?)/s)
5526
5527     # Bare 'l' command.
5528     elsif ( $line !~ /\S/ ) {
5529
5530         # Compute new range to list.
5531         $incr = $window - 1;
5532         $line = $start . '-' . ( $start + $incr );
5533
5534         # Recurse to do it.
5535         cmd_l( 'l', $line );
5536     }
5537
5538     # l [start]+number_of_lines
5539     elsif ( my ($new_start, $new_incr) = $line =~ /\A(\d*)\+(\d*)\z/ ) {
5540
5541         # Don't reset start for 'l +nnn'.
5542         $start = $new_start if $new_start;
5543
5544         # Increment for list. Use window size if not specified.
5545         # (Allows 'l +' to work.)
5546         $incr = $new_incr;
5547         $incr = $window - 1 unless $incr;
5548
5549         # Create a line range we'll understand, and recurse to do it.
5550         $line = $start . '-' . ( $start + $incr );
5551         cmd_l( 'l', $line );
5552     } ## end elsif ($line =~ /^(\d*)\+(\d*)$/)
5553
5554     # l start-stop or l start,stop
5555     elsif ( $line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/ ) {
5556
5557         # Determine end point; use end of file if not specified.
5558         my $end = ( !defined $2 ) ? $max : ( $4 ? $4 : $2 );
5559
5560         # Go on to the end, and then stop.
5561         $end = $max if $end > $max;
5562
5563         # Determine start line.
5564         my $i    = $2;
5565         $i    = $line if $i eq '.';
5566         $i    = 1 if $i < 1;
5567         $incr = $end - $i;
5568
5569         # If we're running under a slave editor, force it to show the lines.
5570         if ($slave_editor) {
5571             print $OUT "\032\032$filename:$i:0\n";
5572             $i = $end;
5573         }
5574
5575         # We're doing it ourselves. We want to show the line and special
5576         # markers for:
5577         # - the current line in execution
5578         # - whether a line is breakable or not
5579         # - whether a line has a break or not
5580         # - whether a line has an action or not
5581         else {
5582             for ( ; $i <= $end ; $i++ ) {
5583
5584                 # Check for breakpoints and actions.
5585                 my ( $stop, $action );
5586                 ( $stop, $action ) = split( /\0/, $dbline{$i} )
5587                   if $dbline{$i};
5588
5589                 # ==> if this is the current line in execution,
5590                 # : if it's breakable.
5591                 my $arrow =
5592                   ( $i == $current_line and $filename eq $filename_ini )
5593                   ? '==>'
5594                   : ( $dbline[$i] + 0 ? ':' : ' ' );
5595
5596                 # Add break and action indicators.
5597                 $arrow .= 'b' if $stop;
5598                 $arrow .= 'a' if $action;
5599
5600                 # Print the line.
5601                 print $OUT "$i$arrow\t", $dbline[$i];
5602
5603                 # Move on to the next line. Drop out on an interrupt.
5604                 $i++, last if $signal;
5605             } ## end for (; $i <= $end ; $i++)
5606
5607             # Line the prompt up; print a newline if the last line listed
5608             # didn't have a newline.
5609             print $OUT "\n" unless $dbline[ $i - 1 ] =~ /\n$/;
5610         } ## end else [ if ($slave_editor)
5611
5612         # Save the point we last listed to in case another relative 'l'
5613         # command is desired. Don't let it run off the end.
5614         $start = $i;
5615         $start = $max if $start > $max;
5616     } ## end elsif ($line =~ /^((-?[\d\$\.]+)([-,]([\d\$\.]+))?)?/)
5617 } ## end sub cmd_l
5618
5619 =head3 C<cmd_L> - list breakpoints, actions, and watch expressions (command)
5620
5621 To list breakpoints, the command has to look determine where all of them are
5622 first. It starts a C<%had_breakpoints>, which tells us what all files have
5623 breakpoints and/or actions. For each file, we switch the C<*dbline> glob (the
5624 magic source and breakpoint data structures) to the file, and then look
5625 through C<%dbline> for lines with breakpoints and/or actions, listing them
5626 out. We look through C<%postponed> not-yet-compiled subroutines that have
5627 breakpoints, and through C<%postponed_file> for not-yet-C<require>'d files
5628 that have breakpoints.
5629
5630 Watchpoints are simpler: we just list the entries in C<@to_watch>.
5631
5632 =cut
5633
5634 sub cmd_L {
5635     my $cmd = shift;
5636
5637     # If no argument, list everything. Pre-5.8.0 version always lists
5638     # everything
5639     my $arg = shift || 'abw';
5640     $arg = 'abw' unless $CommandSet eq '580';    # sigh...
5641
5642     # See what is wanted.
5643     my $action_wanted = ( $arg =~ /a/ ) ? 1 : 0;
5644     my $break_wanted  = ( $arg =~ /b/ ) ? 1 : 0;
5645     my $watch_wanted  = ( $arg =~ /w/ ) ? 1 : 0;
5646
5647     # Breaks and actions are found together, so we look in the same place
5648     # for both.
5649     if ( $break_wanted or $action_wanted ) {
5650
5651         # Look in all the files with breakpoints...
5652         for my $file ( keys %had_breakpoints ) {
5653
5654             # Temporary switch to this file.
5655             local *dbline = $main::{ '_<' . $file };
5656
5657             # Set up to look through the whole file.
5658             $max = $#dbline;
5659             my $was;    # Flag: did we print something
5660                         # in this file?
5661
5662             # For each line in the file ...
5663             for my $i (1 .. $max) {
5664
5665                 # We've got something on this line.
5666                 if ( defined $dbline{$i} ) {
5667
5668                     # Print the header if we haven't.
5669                     print $OUT "$file:\n" unless $was++;
5670
5671                     # Print the line.
5672                     print $OUT " $i:\t", $dbline[$i];
5673
5674                     # Pull out the condition and the action.
5675                     my ( $stop, $action ) = split( /\0/, $dbline{$i} );
5676
5677                     # Print the break if there is one and it's wanted.
5678                     print $OUT "   break if (", $stop, ")\n"
5679                       if $stop
5680                       and $break_wanted;
5681
5682                     # Print the action if there is one and it's wanted.
5683                     print $OUT "   action:  ", $action, "\n"
5684                       if $action
5685                       and $action_wanted;
5686
5687                     # Quit if the user hit interrupt.
5688                     last if $signal;
5689                 } ## end if (defined $dbline{$i...
5690             } ## end for my $i (1 .. $max)
5691         } ## end for my $file (keys %had_breakpoints)
5692     } ## end if ($break_wanted or $action_wanted)
5693
5694     # Look for breaks in not-yet-compiled subs:
5695     if ( %postponed and $break_wanted ) {
5696         print $OUT "Postponed breakpoints in subroutines:\n";
5697         my $subname;
5698         for $subname ( keys %postponed ) {
5699             print $OUT " $subname\t$postponed{$subname}\n";
5700             last if $signal;
5701         }
5702     } ## end if (%postponed and $break_wanted)
5703
5704     # Find files that have not-yet-loaded breaks:
5705     my @have = map {    # Combined keys
5706         keys %{ $postponed_file{$_} }
5707     } keys %postponed_file;
5708
5709     # If there are any, list them.
5710     if ( @have and ( $break_wanted or $action_wanted ) ) {
5711         print $OUT "Postponed breakpoints in files:\n";
5712         for my $file ( keys %postponed_file ) {
5713             my $db = $postponed_file{$file};
5714             print $OUT " $file:\n";
5715             for my $line ( sort { $a <=> $b } keys %$db ) {
5716                 print $OUT "  $line:\n";
5717                 my ( $stop, $action ) = split( /\0/, $$db{$line} );
5718                 print $OUT "    break if (", $stop, ")\n"
5719                   if $stop
5720                   and $break_wanted;
5721                 print $OUT "    action:  ", $action, "\n"
5722                   if $action
5723                   and $action_wanted;
5724                 last if $signal;
5725             } ## end for $line (sort { $a <=>...
5726             last if $signal;
5727         } ## end for $file (keys %postponed_file)
5728     } ## end if (@have and ($break_wanted...
5729     if ( %break_on_load and $break_wanted ) {
5730         print {$OUT} "Breakpoints on load:\n";
5731         BREAK_ON_LOAD: for my $filename ( keys %break_on_load ) {
5732             print {$OUT} " $filename\n";
5733             last BREAK_ON_LOAD if $signal;
5734         }
5735     } ## end if (%break_on_load and...
5736     if ($watch_wanted and ( $trace & 2 )) {
5737         print {$OUT} "Watch-expressions:\n" if @to_watch;
5738         TO_WATCH: for my $expr (@to_watch) {
5739             print {$OUT} " $expr\n";
5740             last TO_WATCH if $signal;
5741         }
5742     }
5743 } ## end sub cmd_L
5744
5745 =head3 C<cmd_M> - list modules (command)
5746
5747 Just call C<list_modules>.
5748
5749 =cut
5750
5751 sub cmd_M {
5752     list_modules();
5753
5754     return;
5755 }
5756
5757 =head3 C<cmd_o> - options (command)
5758
5759 If this is just C<o> by itself, we list the current settings via
5760 C<dump_option>. If there's a nonblank value following it, we pass that on to
5761 C<parse_options> for processing.
5762
5763 =cut
5764
5765 sub cmd_o {
5766     my $cmd = shift;
5767     my $opt = shift || '';    # opt[=val]
5768
5769     # Nonblank. Try to parse and process.
5770     if ( $opt =~ /^(\S.*)/ ) {
5771         parse_options($1);
5772     }
5773
5774     # Blank. List the current option settings.
5775     else {
5776         for (@options) {
5777             dump_option($_);
5778         }
5779     }
5780 } ## end sub cmd_o
5781
5782 =head3 C<cmd_O> - nonexistent in 5.8.x (command)
5783
5784 Advises the user that the O command has been renamed.
5785
5786 =cut
5787
5788 sub cmd_O {
5789     print $OUT "The old O command is now the o command.\n";             # hint
5790     print $OUT "Use 'h' to get current command help synopsis or\n";     #
5791     print $OUT "use 'o CommandSet=pre580' to revert to old usage\n";    #
5792 }
5793
5794 =head3 C<cmd_v> - view window (command)
5795
5796 Uses the C<$preview> variable set in the second C<BEGIN> block (q.v.) to
5797 move back a few lines to list the selected line in context. Uses C<cmd_l>
5798 to do the actual listing after figuring out the range of line to request.
5799
5800 =cut
5801
5802 use vars qw($preview);
5803
5804 sub cmd_v {
5805     my $cmd  = shift;
5806     my $line = shift;
5807
5808     # Extract the line to list around. (Astute readers will have noted that
5809     # this pattern will match whether or not a numeric line is specified,
5810     # which means that we'll always enter this loop (though a non-numeric
5811     # argument results in no action at all)).
5812     if ( $line =~ /^(\d*)$/ ) {
5813
5814         # Total number of lines to list (a windowful).
5815         $incr = $window - 1;
5816
5817         # Set the start to the argument given (if there was one).
5818         $start = $1 if $1;
5819
5820         # Back up by the context amount.
5821         $start -= $preview;
5822
5823         # Put together a linespec that cmd_l will like.
5824         $line = $start . '-' . ( $start + $incr );
5825
5826         # List the lines.
5827         cmd_l( 'l', $line );
5828     } ## end if ($line =~ /^(\d*)$/)
5829 } ## end sub cmd_v
5830
5831 =head3 C<cmd_w> - add a watch expression (command)
5832
5833 The 5.8 version of this command adds a watch expression if one is specified;
5834 it does nothing if entered with no operands.
5835
5836 We extract the expression, save it, evaluate it in the user's context, and
5837 save the value. We'll re-evaluate it each time the debugger passes a line,
5838 and will stop (see the code at the top of the command loop) if the value
5839 of any of the expressions changes.
5840
5841 =cut
5842
5843 sub _add_watch_expr {
5844     my $expr = shift;
5845
5846     # ... save it.
5847     push @to_watch, $expr;
5848
5849     # Parameterize DB::eval and call it to get the expression's value
5850     # in the user's context. This version can handle expressions which
5851     # return a list value.
5852     $evalarg = $expr;
5853     my ($val) = join( ' ', DB::eval() );
5854     $val = ( defined $val ) ? "'$val'" : 'undef';
5855
5856     # Save the current value of the expression.
5857     push @old_watch, $val;
5858
5859     # We are now watching expressions.
5860     $trace |= 2;
5861
5862     return;
5863 }
5864
5865 sub cmd_w {
5866     my $cmd = shift;
5867
5868     # Null expression if no arguments.
5869     my $expr = shift || '';
5870
5871     # If expression is not null ...
5872     if ( $expr =~ /\A\S/ ) {
5873         _add_watch_expr($expr);
5874     } ## end if ($expr =~ /^(\S.*)/)
5875
5876     # You have to give one to get one.
5877     else {
5878         print $OUT "Adding a watch-expression requires an expression\n";  # hint
5879     }
5880
5881     return;
5882 }
5883
5884 =head3 C<cmd_W> - delete watch expressions (command)
5885
5886 This command accepts either a watch expression to be removed from the list
5887 of watch expressions, or C<*> to delete them all.
5888
5889 If C<*> is specified, we simply empty the watch expression list and the
5890 watch expression value list. We also turn off the bit that says we've got
5891 watch expressions.
5892
5893 If an expression (or partial expression) is specified, we pattern-match
5894 through the expressions and remove the ones that match. We also discard
5895 the corresponding values. If no watch expressions are left, we turn off
5896 the I<watching expressions> bit.
5897
5898 =cut
5899
5900 sub cmd_W {
5901     my $cmd  = shift;
5902     my $expr = shift || '';
5903
5904     # Delete them all.
5905     if ( $expr eq '*' ) {
5906
5907         # Not watching now.
5908         $trace &= ~2;
5909
5910         print $OUT "Deleting all watch expressions ...\n";
5911
5912         # And all gone.
5913         @to_watch = @old_watch = ();
5914     }
5915
5916     # Delete one of them.
5917     elsif ( $expr =~ /^(\S.*)/ ) {
5918
5919         # Where we are in the list.
5920         my $i_cnt = 0;
5921
5922         # For each expression ...
5923         foreach (@to_watch) {
5924             my $val = $to_watch[$i_cnt];
5925
5926             # Does this one match the command argument?
5927             if ( $val eq $expr ) {    # =~ m/^\Q$i$/) {
5928                                       # Yes. Turn it off, and its value too.
5929                 splice( @to_watch,  $i_cnt, 1 );
5930                 splice( @old_watch, $i_cnt, 1 );
5931             }
5932             $i_cnt++;
5933         } ## end foreach (@to_watch)
5934
5935         # We don't bother to turn watching off because
5936         #  a) we don't want to stop calling watchfunction() it it exists
5937         #  b) foreach over a null list doesn't do anything anyway
5938
5939     } ## end elsif ($expr =~ /^(\S.*)/)
5940
5941     # No command arguments entered.
5942     else {
5943         print $OUT
5944           "Deleting a watch-expression requires an expression, or '*' for all\n"
5945           ;    # hint
5946     }
5947 } ## end sub cmd_W
5948
5949 ### END of the API section
5950
5951 =head1 SUPPORT ROUTINES
5952
5953 These are general support routines that are used in a number of places
5954 throughout the debugger.
5955
5956 =head2 save
5957
5958 save() saves the user's versions of globals that would mess us up in C<@saved>,
5959 and installs the versions we like better.
5960
5961 =cut
5962
5963 sub save {
5964
5965     # Save eval failure, command failure, extended OS error, output field
5966     # separator, input record separator, output record separator and
5967     # the warning setting.
5968     @saved = ( $@, $!, $^E, $,, $/, $\, $^W );
5969
5970     $,  = "";      # output field separator is null string
5971     $/  = "\n";    # input record separator is newline
5972     $\  = "";      # output record separator is null string
5973     $^W = 0;       # warnings are off
5974 } ## end sub save
5975
5976 =head2 C<print_lineinfo> - show where we are now
5977
5978 print_lineinfo prints whatever it is that it is handed; it prints it to the
5979 C<$LINEINFO> filehandle instead of just printing it to STDOUT. This allows
5980 us to feed line information to a slave editor without messing up the
5981 debugger output.
5982
5983 =cut
5984
5985 sub print_lineinfo {
5986
5987     # Make the terminal sensible if we're not the primary debugger.
5988     resetterm(1) if $LINEINFO eq $OUT and $term_pid != $$;
5989     local $\ = '';
5990     local $, = '';
5991     print $LINEINFO @_;
5992 } ## end sub print_lineinfo
5993
5994 =head2 C<postponed_sub>
5995
5996 Handles setting postponed breakpoints in subroutines once they're compiled.
5997 For breakpoints, we use C<DB::find_sub> to locate the source file and line
5998 range for the subroutine, then mark the file as having a breakpoint,
5999 temporarily switch the C<*dbline> glob over to the source file, and then
6000 search the given range of lines to find a breakable line. If we find one,
6001 we set the breakpoint on it, deleting the breakpoint from C<%postponed>.
6002
6003 =cut
6004
6005 # The following takes its argument via $evalarg to preserve current @_
6006
6007 sub postponed_sub {
6008
6009     # Get the subroutine name.
6010     my $subname = shift;
6011
6012     # If this is a 'break +<n> if <condition>' ...
6013     if ( $postponed{$subname} =~ s/^break\s([+-]?\d+)\s+if\s// ) {
6014
6015         # If there's no offset, use '+0'.
6016         my $offset = $1 || 0;
6017
6018         # find_sub's value is 'fullpath-filename:start-stop'. It's
6019         # possible that the filename might have colons in it too.
6020         my ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(\d+)-.*$/ );
6021         if ($i) {
6022
6023             # We got the start line. Add the offset '+<n>' from
6024             # $postponed{subname}.
6025             $i += $offset;
6026
6027             # Switch to the file this sub is in, temporarily.
6028             local *dbline = $main::{ '_<' . $file };
6029
6030             # No warnings, please.
6031             local $^W = 0;    # != 0 is magical below
6032
6033             # This file's got a breakpoint in it.
6034             $had_breakpoints{$file} |= 1;
6035
6036             # Last line in file.
6037             $max = $#dbline;
6038
6039             # Search forward until we hit a breakable line or get to
6040             # the end of the file.
6041             ++$i until $dbline[$i] != 0 or $i >= $max;
6042
6043             # Copy the breakpoint in and delete it from %postponed.
6044             $dbline{$i} = delete $postponed{$subname};
6045         } ## end if ($i)
6046
6047         # find_sub didn't find the sub.
6048         else {
6049             local $\ = '';
6050             print $OUT "Subroutine $subname not found.\n";
6051         }
6052         return;
6053     } ## end if ($postponed{$subname...
6054     elsif ( $postponed{$subname} eq 'compile' ) { $signal = 1 }
6055
6056     #print $OUT "In postponed_sub for '$subname'.\n";
6057 } ## end sub postponed_sub
6058
6059 =head2 C<postponed>
6060
6061 Called after each required file is compiled, but before it is executed;
6062 also called if the name of a just-compiled subroutine is a key of
6063 C<%postponed>. Propagates saved breakpoints (from C<b compile>, C<b load>,
6064 etc.) into the just-compiled code.
6065
6066 If this is a C<require>'d file, the incoming parameter is the glob
6067 C<*{"_<$filename"}>, with C<$filename> the name of the C<require>'d file.
6068
6069 If it's a subroutine, the incoming parameter is the subroutine name.
6070
6071 =cut
6072
6073 sub postponed {
6074
6075     # If there's a break, process it.
6076     if ($ImmediateStop) {
6077
6078         # Right, we've stopped. Turn it off.
6079         $ImmediateStop = 0;
6080
6081         # Enter the command loop when DB::DB gets called.
6082         $signal = 1;
6083     }
6084
6085     # If this is a subroutine, let postponed_sub() deal with it.
6086     return postponed_sub(@_) unless ref \$_[0] eq 'GLOB';
6087
6088     # Not a subroutine. Deal with the file.
6089     local *dbline = shift;
6090     my $filename = $dbline;
6091     $filename =~ s/^_<//;
6092     local $\ = '';
6093     $signal = 1, print $OUT "'$filename' loaded...\n"
6094       if $break_on_load{$filename};
6095     print_lineinfo( ' ' x $stack_depth, "Package $filename.\n" ) if $frame;
6096
6097     # Do we have any breakpoints to put in this file?
6098     return unless $postponed_file{$filename};
6099
6100     # Yes. Mark this file as having breakpoints.
6101     $had_breakpoints{$filename} |= 1;
6102
6103     # "Cannot be done: insufficient magic" - we can't just put the
6104     # breakpoints saved in %postponed_file into %dbline by assigning
6105     # the whole hash; we have to do it one item at a time for the
6106     # breakpoints to be set properly.
6107     #%dbline = %{$postponed_file{$filename}};
6108
6109     # Set the breakpoints, one at a time.
6110     my $key;
6111
6112     for $key ( keys %{ $postponed_file{$filename} } ) {
6113
6114         # Stash the saved breakpoint into the current file's magic line array.
6115         $dbline{$key} = ${ $postponed_file{$filename} }{$key};
6116     }
6117
6118     # This file's been compiled; discard the stored breakpoints.
6119     delete $postponed_file{$filename};
6120
6121 } ## end sub postponed
6122
6123 =head2 C<dumpit>
6124
6125 C<dumpit> is the debugger's wrapper around dumpvar.pl.
6126
6127 It gets a filehandle (to which C<dumpvar.pl>'s output will be directed) and
6128 a reference to a variable (the thing to be dumped) as its input.
6129
6130 The incoming filehandle is selected for output (C<dumpvar.pl> is printing to
6131 the currently-selected filehandle, thank you very much). The current
6132 values of the package globals C<$single> and C<$trace> are backed up in
6133 lexicals, and they are turned off (this keeps the debugger from trying
6134 to single-step through C<dumpvar.pl> (I think.)). C<$frame> is localized to
6135 preserve its current value and it is set to zero to prevent entry/exit
6136 messages from printing, and C<$doret> is localized as well and set to -2 to
6137 prevent return values from being shown.
6138
6139 C<dumpit()> then checks to see if it needs to load C<dumpvar.pl> and
6140 tries to load it (note: if you have a C<dumpvar.pl>  ahead of the
6141 installed version in C<@INC>, yours will be used instead. Possible security
6142 problem?).
6143
6144 It then checks to see if the subroutine C<main::dumpValue> is now defined
6145 it should have been defined by C<dumpvar.pl>). If it has, C<dumpit()>
6146 localizes the globals necessary for things to be sane when C<main::dumpValue()>
6147 is called, and picks up the variable to be dumped from the parameter list.
6148
6149 It checks the package global C<%options> to see if there's a C<dumpDepth>
6150 specified. If not, -1 is assumed; if so, the supplied value gets passed on to
6151 C<dumpvar.pl>. This tells C<dumpvar.pl> where to leave off when dumping a
6152 structure: -1 means dump everything.
6153
6154 C<dumpValue()> is then called if possible; if not, C<dumpit()>just prints a
6155 warning.
6156
6157 In either case, C<$single>, C<$trace>, C<$frame>, and C<$doret> are restored
6158 and we then return to the caller.
6159
6160 =cut
6161
6162 sub dumpit {
6163
6164     # Save the current output filehandle and switch to the one
6165     # passed in as the first parameter.
6166     my $savout = select(shift);
6167
6168     # Save current settings of $single and $trace, and then turn them off.
6169     my $osingle = $single;
6170     my $otrace  = $trace;
6171     $single = $trace = 0;
6172
6173     # XXX Okay, what do $frame and $doret do, again?
6174     local $frame = 0;
6175     local $doret = -2;
6176
6177     # Load dumpvar.pl unless we've already got the sub we need from it.
6178     unless ( defined &main::dumpValue ) {
6179         do 'dumpvar.pl' or die $@;
6180     }
6181
6182     # If the load succeeded (or we already had dumpvalue()), go ahead
6183     # and dump things.
6184     if ( defined &main::dumpValue ) {
6185         local $\ = '';
6186         local $, = '';
6187         local $" = ' ';
6188         my $v = shift;
6189         my $maxdepth = shift || $option{dumpDepth};
6190         $maxdepth = -1 unless defined $maxdepth;    # -1 means infinite depth
6191         main::dumpValue( $v, $maxdepth );
6192     } ## end if (defined &main::dumpValue)
6193
6194     # Oops, couldn't load dumpvar.pl.
6195     else {
6196         local $\ = '';
6197         print $OUT "dumpvar.pl not available.\n";
6198     }
6199
6200     # Reset $single and $trace to their old values.
6201     $single = $osingle;
6202     $trace  = $otrace;
6203
6204     # Restore the old filehandle.
6205     select($savout);
6206 } ## end sub dumpit
6207
6208 =head2 C<print_trace>
6209
6210 C<print_trace>'s job is to print a stack trace. It does this via the
6211 C<dump_trace> routine, which actually does all the ferreting-out of the
6212 stack trace data. C<print_trace> takes care of formatting it nicely and
6213 printing it to the proper filehandle.
6214
6215 Parameters:
6216
6217 =over 4
6218
6219 =item *
6220
6221 The filehandle to print to.
6222
6223 =item *
6224
6225 How many frames to skip before starting trace.
6226
6227 =item *
6228
6229 How many frames to print.
6230
6231 =item *
6232
6233 A flag: if true, print a I<short> trace without filenames, line numbers, or arguments
6234
6235 =back
6236
6237 The original comment below seems to be noting that the traceback may not be
6238 correct if this routine is called in a tied method.
6239
6240 =cut
6241
6242 # Tied method do not create a context, so may get wrong message:
6243
6244 sub print_trace {
6245     local $\ = '';
6246     my $fh = shift;
6247
6248     # If this is going to a slave editor, but we're not the primary
6249     # debugger, reset it first.
6250     resetterm(1)
6251       if $fh        eq $LINEINFO    # slave editor
6252       and $LINEINFO eq $OUT         # normal output
6253       and $term_pid != $$;          # not the primary
6254
6255     # Collect the actual trace information to be formatted.
6256     # This is an array of hashes of subroutine call info.
6257     my @sub = dump_trace( $_[0] + 1, $_[1] );
6258
6259     # Grab the "short report" flag from @_.
6260     my $short = $_[2];              # Print short report, next one for sub name
6261
6262     # Run through the traceback info, format it, and print it.
6263     my $s;
6264     for my $i (0 .. $#sub) {
6265
6266         # Drop out if the user has lost interest and hit control-C.
6267         last if $signal;
6268
6269         # Set the separator so arrys print nice.
6270         local $" = ', ';
6271
6272         # Grab and stringify the arguments if they are there.
6273         my $args =
6274           defined $sub[$i]{args}
6275           ? "(@{ $sub[$i]{args} })"
6276           : '';
6277
6278         # Shorten them up if $maxtrace says they're too long.
6279         $args = ( substr $args, 0, $maxtrace - 3 ) . '...'
6280           if length $args > $maxtrace;
6281
6282         # Get the file name.
6283         my $file = $sub[$i]{file};
6284
6285         # Put in a filename header if short is off.
6286         $file = $file eq '-e' ? $file : "file '$file'" unless $short;
6287
6288         # Get the actual sub's name, and shorten to $maxtrace's requirement.
6289         $s = $sub[$i]{'sub'};
6290         $s = ( substr $s, 0, $maxtrace - 3 ) . '...' if length $s > $maxtrace;
6291
6292         # Short report uses trimmed file and sub names.
6293         if ($short) {
6294             my $sub = @_ >= 4 ? $_[3] : $s;
6295             print $fh "$sub[$i]{context}=$sub$args from $file:$sub[$i]{line}\n";
6296         } ## end if ($short)
6297
6298         # Non-short report includes full names.
6299         else {
6300             print $fh "$sub[$i]{context} = $s$args"
6301               . " called from $file"
6302               . " line $sub[$i]{line}\n";
6303         }
6304     } ## end for my $i (0 .. $#sub)
6305 } ## end sub print_trace
6306
6307 =head2 dump_trace(skip[,count])
6308
6309 Actually collect the traceback information available via C<caller()>. It does
6310 some filtering and cleanup of the data, but mostly it just collects it to
6311 make C<print_trace()>'s job easier.
6312
6313 C<skip> defines the number of stack frames to be skipped, working backwards
6314 from the most current. C<count> determines the total number of frames to
6315 be returned; all of them (well, the first 10^9) are returned if C<count>
6316 is omitted.
6317
6318 This routine returns a list of hashes, from most-recent to least-recent
6319 stack frame. Each has the following keys and values:
6320
6321 =over 4
6322
6323 =item * C<context> - C<.> (null), C<$> (scalar), or C<@> (array)
6324
6325 =item * C<sub> - subroutine name, or C<eval> information
6326
6327 =item * C<args> - undef, or a reference to an array of arguments
6328
6329 =item * C<file> - the file in which this item was defined (if any)
6330
6331 =item * C<line> - the line on which it was defined
6332
6333 =back
6334
6335 =cut
6336
6337 sub dump_trace {
6338
6339     # How many levels to skip.
6340     my $skip = shift;
6341
6342     # How many levels to show. (1e9 is a cheap way of saying "all of them";
6343     # it's unlikely that we'll have more than a billion stack frames. If you
6344     # do, you've got an awfully big machine...)
6345     my $count = shift || 1e9;
6346
6347     # We increment skip because caller(1) is the first level *back* from
6348     # the current one.  Add $skip to the count of frames so we have a
6349     # simple stop criterion, counting from $skip to $count+$skip.
6350     $skip++;
6351     $count += $skip;
6352
6353     # These variables are used to capture output from caller();
6354     my ( $p, $file, $line, $sub, $h, $context );
6355
6356     my ( $e, $r, @a, @sub, $args );
6357
6358     # XXX Okay... why'd we do that?
6359     my $nothard = not $frame & 8;
6360     local $frame = 0;
6361
6362     # Do not want to trace this.
6363     my $otrace = $trace;
6364     $trace = 0;
6365
6366     # Start out at the skip count.
6367     # If we haven't reached the number of frames requested, and caller() is
6368     # still returning something, stay in the loop. (If we pass the requested
6369     # number of stack frames, or we run out - caller() returns nothing - we
6370     # quit.
6371     # Up the stack frame index to go back one more level each time.
6372     for (
6373         my $i = $skip ;
6374         $i < $count
6375         and ( $p, $file, $line, $sub, $h, $context, $e, $r ) = caller($i) ;
6376         $i++
6377     )
6378     {
6379
6380         # Go through the arguments and save them for later.
6381         @a = ();
6382         for my $arg (@args) {
6383             my $type;
6384             if ( not defined $arg ) {    # undefined parameter
6385                 push @a, "undef";
6386             }
6387
6388             elsif ( $nothard and tied $arg ) {    # tied parameter
6389                 push @a, "tied";
6390             }
6391             elsif ( $nothard and $type = ref $arg ) {    # reference
6392                 push @a, "ref($type)";
6393             }
6394             else {                                       # can be stringified
6395                 local $_ =
6396                   "$arg";    # Safe to stringify now - should not call f().
6397
6398                 # Backslash any single-quotes or backslashes.
6399                 s/([\'\\])/\\$1/g;
6400
6401                 # Single-quote it unless it's a number or a colon-separated
6402                 # name.
6403                 s/(.*)/'$1'/s
6404                   unless /^(?: -?[\d.]+ | \*[\w:]* )$/x;
6405
6406                 # Turn high-bit characters into meta-whatever.
6407                 s/([\200-\377])/sprintf("M-%c",ord($1)&0177)/eg;
6408
6409                 # Turn control characters into ^-whatever.
6410                 s/([\0-\37\177])/sprintf("^%c",ord($1)^64)/eg;
6411
6412                 push( @a, $_ );
6413             } ## end else [ if (not defined $arg)
6414         } ## end for $arg (@args)
6415
6416         # If context is true, this is array (@)context.
6417         # If context is false, this is scalar ($) context.
6418         # If neither, context isn't defined. (This is apparently a 'can't
6419         # happen' trap.)
6420         $context = $context ? '@' : ( defined $context ? "\$" : '.' );
6421
6422         # if the sub has args ($h true), make an anonymous array of the
6423         # dumped args.
6424         $args = $h ? [@a] : undef;
6425
6426         # remove trailing newline-whitespace-semicolon-end of line sequence
6427         # from the eval text, if any.
6428         $e =~ s/\n\s*\;\s*\Z// if $e;
6429
6430         # Escape backslashed single-quotes again if necessary.
6431         $e =~ s/([\\\'])/\\$1/g if $e;
6432
6433         # if the require flag is true, the eval text is from a require.
6434         if ($r) {
6435             $sub = "require '$e'";
6436         }
6437
6438         # if it's false, the eval text is really from an eval.
6439         elsif ( defined $r ) {
6440             $sub = "eval '$e'";
6441         }
6442
6443         # If the sub is '(eval)', this is a block eval, meaning we don't
6444         # know what the eval'ed text actually was.
6445         elsif ( $sub eq '(eval)' ) {
6446             $sub = "eval {...}";
6447         }
6448
6449         # Stick the collected information into @sub as an anonymous hash.
6450         push(
6451             @sub,
6452             {
6453                 context => $context,
6454                 sub     => $sub,
6455                 args    => $args,
6456                 file    => $file,
6457                 line    => $line
6458             }
6459         );
6460
6461         # Stop processing frames if the user hit control-C.
6462         last if $signal;
6463     } ## end for ($i = $skip ; $i < ...
6464
6465     # Restore the trace value again.
6466     $trace = $otrace;
6467     @sub;
6468 } ## end sub dump_trace
6469
6470 =head2 C<action()>
6471
6472 C<action()> takes input provided as the argument to an add-action command,
6473 either pre- or post-, and makes sure it's a complete command. It doesn't do
6474 any fancy parsing; it just keeps reading input until it gets a string
6475 without a trailing backslash.
6476
6477 =cut
6478
6479 sub action {
6480     my $action = shift;
6481
6482     while ( $action =~ s/\\$// ) {
6483
6484         # We have a backslash on the end. Read more.
6485         $action .= gets();
6486     } ## end while ($action =~ s/\\$//)
6487
6488     # Return the assembled action.
6489     $action;
6490 } ## end sub action
6491
6492 =head2 unbalanced
6493
6494 This routine mostly just packages up a regular expression to be used
6495 to check that the thing it's being matched against has properly-matched
6496 curly braces.
6497
6498 Of note is the definition of the C<$balanced_brace_re> global via C<||=>, which
6499 speeds things up by only creating the qr//'ed expression once; if it's
6500 already defined, we don't try to define it again. A speed hack.
6501
6502 =cut
6503
6504 use vars qw($balanced_brace_re);
6505
6506 sub unbalanced {
6507
6508     # I hate using globals!
6509     $balanced_brace_re ||= qr{
6510         ^ \{
6511              (?:
6512                  (?> [^{}] + )              # Non-parens without backtracking
6513                 |
6514                  (??{ $balanced_brace_re }) # Group with matching parens
6515               ) *
6516           \} $
6517    }x;
6518     return $_[0] !~ m/$balanced_brace_re/;
6519 } ## end sub unbalanced
6520
6521 =head2 C<gets()>
6522
6523 C<gets()> is a primitive (very primitive) routine to read continuations.
6524 It was devised for reading continuations for actions.
6525 it just reads more input with C<readline()> and returns it.
6526
6527 =cut
6528
6529 sub gets {
6530     return DB::readline("cont: ");
6531 }
6532
6533 =head2 C<_db_system()> - handle calls to<system()> without messing up the debugger
6534
6535 The C<system()> function assumes that it can just go ahead and use STDIN and
6536 STDOUT, but under the debugger, we want it to use the debugger's input and
6537 outout filehandles.
6538
6539 C<_db_system()> socks away the program's STDIN and STDOUT, and then substitutes
6540 the debugger's IN and OUT filehandles for them. It does the C<system()> call,
6541 and then puts everything back again.
6542
6543 =cut
6544
6545 sub _db_system {
6546
6547     # We save, change, then restore STDIN and STDOUT to avoid fork() since
6548     # some non-Unix systems can do system() but have problems with fork().
6549     open( SAVEIN,  "<&STDIN" )  || db_warn("Can't save STDIN");
6550     open( SAVEOUT, ">&STDOUT" ) || db_warn("Can't save STDOUT");
6551     open( STDIN,   "<&IN" )     || db_warn("Can't redirect STDIN");
6552     open( STDOUT,  ">&OUT" )    || db_warn("Can't redirect STDOUT");
6553
6554     # XXX: using csh or tcsh destroys sigint retvals!
6555     system(@_);
6556     open( STDIN,  "<&SAVEIN" )  || db_warn("Can't restore STDIN");
6557     open( STDOUT, ">&SAVEOUT" ) || db_warn("Can't restore STDOUT");
6558     close(SAVEIN);
6559     close(SAVEOUT);
6560
6561     # most of the $? crud was coping with broken cshisms
6562     if ( $? >> 8 ) {
6563         db_warn( "(Command exited ", ( $? >> 8 ), ")\n" );
6564     }
6565     elsif ($?) {
6566         db_warn(
6567             "(Command died of SIG#",
6568             ( $? & 127 ),
6569             ( ( $? & 128 ) ? " -- core dumped" : "" ),
6570             ")", "\n"
6571         );
6572     } ## end elsif ($?)
6573
6574     return $?;
6575
6576 } ## end sub system
6577
6578 *system = \&_db_system;
6579
6580 =head1 TTY MANAGEMENT
6581
6582 The subs here do some of the terminal management for multiple debuggers.
6583
6584 =head2 setterm
6585
6586 Top-level function called when we want to set up a new terminal for use
6587 by the debugger.
6588
6589 If the C<noTTY> debugger option was set, we'll either use the terminal
6590 supplied (the value of the C<noTTY> option), or we'll use C<Term::Rendezvous>
6591 to find one. If we're a forked debugger, we call C<resetterm> to try to
6592 get a whole new terminal if we can.
6593
6594 In either case, we set up the terminal next. If the C<ReadLine> option was
6595 true, we'll get a C<Term::ReadLine> object for the current terminal and save
6596 the appropriate attributes. We then
6597
6598 =cut
6599
6600 use vars qw($ornaments);
6601 use vars qw($rl_attribs);
6602
6603 sub setterm {
6604
6605     # Load Term::Readline, but quietly; don't debug it and don't trace it.
6606     local $frame = 0;
6607     local $doret = -2;
6608     require Term::ReadLine;
6609
6610     # If noTTY is set, but we have a TTY name, go ahead and hook up to it.
6611     if ($notty) {
6612         if ($tty) {
6613             my ( $i, $o ) = split $tty, /,/;
6614             $o = $i unless defined $o;
6615             open( IN,  "<$i" ) or die "Cannot open TTY '$i' for read: $!";
6616             open( OUT, ">$o" ) or die "Cannot open TTY '$o' for write: $!";
6617             $IN  = \*IN;
6618             $OUT = \*OUT;
6619             $OUT->autoflush(1);
6620         } ## end if ($tty)
6621
6622         # We don't have a TTY - try to find one via Term::Rendezvous.
6623         else {
6624             require Term::Rendezvous;
6625
6626             # See if we have anything to pass to Term::Rendezvous.
6627             # Use $HOME/.perldbtty$$ if not.
6628             my $rv = $ENV{PERLDB_NOTTY} || "$ENV{HOME}/.perldbtty$$";
6629
6630             # Rendezvous and get the filehandles.
6631             my $term_rv = Term::Rendezvous->new( $rv );
6632             $IN  = $term_rv->IN;
6633             $OUT = $term_rv->OUT;
6634         } ## end else [ if ($tty)
6635     } ## end if ($notty)
6636
6637     # We're a daughter debugger. Try to fork off another TTY.
6638     if ( $term_pid eq '-1' ) {    # In a TTY with another debugger
6639         resetterm(2);
6640     }
6641
6642     # If we shouldn't use Term::ReadLine, don't.
6643     if ( !$rl ) {
6644         $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6645     }
6646
6647     # We're using Term::ReadLine. Get all the attributes for this terminal.
6648     else {
6649         $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6650
6651         $rl_attribs = $term->Attribs;
6652         $rl_attribs->{basic_word_break_characters} .= '-:+/*,[])}'
6653           if defined $rl_attribs->{basic_word_break_characters}
6654           and index( $rl_attribs->{basic_word_break_characters}, ":" ) == -1;
6655         $rl_attribs->{special_prefixes} = '$@&%';
6656         $rl_attribs->{completer_word_break_characters} .= '$@&%';
6657         $rl_attribs->{completion_function} = \&db_complete;
6658     } ## end else [ if (!$rl)
6659
6660     # Set up the LINEINFO filehandle.
6661     $LINEINFO = $OUT     unless defined $LINEINFO;
6662     $lineinfo = $console unless defined $lineinfo;
6663
6664     $term->MinLine(2);
6665
6666     load_hist();
6667
6668     if ( $term->Features->{setHistory} and "@hist" ne "?" ) {
6669         $term->SetHistory(@hist);
6670     }
6671
6672     # XXX Ornaments are turned on unconditionally, which is not
6673     # always a good thing.
6674     ornaments($ornaments) if defined $ornaments;
6675     $term_pid = $$;
6676 } ## end sub setterm
6677
6678 sub load_hist {
6679     $histfile //= option_val("HistFile", undef);
6680     return unless defined $histfile;
6681     open my $fh, "<", $histfile or return;
6682     local $/ = "\n";
6683     @hist = ();
6684     while (<$fh>) {
6685         chomp;
6686         push @hist, $_;
6687     }
6688     close $fh;
6689 }
6690
6691 sub save_hist {
6692     return unless defined $histfile;
6693     eval { require File::Path } or return;
6694     eval { require File::Basename } or return;
6695     File::Path::mkpath(File::Basename::dirname($histfile));
6696     open my $fh, ">", $histfile or die "Could not open '$histfile': $!";
6697     $histsize //= option_val("HistSize",100);
6698     my @copy = grep { $_ ne '?' } @hist;
6699     my $start = scalar(@copy) > $histsize ? scalar(@copy)-$histsize : 0;
6700     for ($start .. $#copy) {
6701         print $fh "$copy[$_]\n";
6702     }
6703     close $fh or die "Could not write '$histfile': $!";
6704 }
6705
6706 =head1 GET_FORK_TTY EXAMPLE FUNCTIONS
6707
6708 When the process being debugged forks, or the process invokes a command
6709 via C<system()> which starts a new debugger, we need to be able to get a new
6710 C<IN> and C<OUT> filehandle for the new debugger. Otherwise, the two processes
6711 fight over the terminal, and you can never quite be sure who's going to get the
6712 input you're typing.
6713
6714 C<get_fork_TTY> is a glob-aliased function which calls the real function that
6715 is tasked with doing all the necessary operating system mojo to get a new
6716 TTY (and probably another window) and to direct the new debugger to read and
6717 write there.
6718
6719 The debugger provides C<get_fork_TTY> functions which work for TCP
6720 socket servers, X11, OS/2, and Mac OS X. Other systems are not
6721 supported. You are encouraged to write C<get_fork_TTY> functions which
6722 work for I<your> platform and contribute them.
6723
6724 =head3 C<socket_get_fork_TTY>
6725
6726 =cut
6727
6728 sub connect_remoteport {
6729     require IO::Socket;
6730
6731     my $socket = IO::Socket::INET->new(
6732         Timeout  => '10',
6733         PeerAddr => $remoteport,
6734         Proto    => 'tcp',
6735     );
6736     if ( ! $socket ) {
6737         die "Unable to connect to remote host: $remoteport\n";
6738     }
6739     return $socket;
6740 }
6741
6742 sub socket_get_fork_TTY {
6743     $tty = $LINEINFO = $IN = $OUT = connect_remoteport();
6744
6745     # Do I need to worry about setting $term?
6746
6747     reset_IN_OUT( $IN, $OUT );
6748     return '';
6749 }
6750
6751 =head3 C<xterm_get_fork_TTY>
6752
6753 This function provides the C<get_fork_TTY> function for X11. If a
6754 program running under the debugger forks, a new <xterm> window is opened and
6755 the subsidiary debugger is directed there.
6756
6757 The C<open()> call is of particular note here. We have the new C<xterm>
6758 we're spawning route file number 3 to STDOUT, and then execute the C<tty>
6759 command (which prints the device name of the TTY we'll want to use for input
6760 and output to STDOUT, then C<sleep> for a very long time, routing this output
6761 to file number 3. This way we can simply read from the <XT> filehandle (which
6762 is STDOUT from the I<commands> we ran) to get the TTY we want to use.
6763
6764 Only works if C<xterm> is in your path and C<$ENV{DISPLAY}>, etc. are
6765 properly set up.
6766
6767 =cut
6768
6769 sub xterm_get_fork_TTY {
6770     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6771     open XT,
6772 qq[3>&1 xterm -title "Daughter Perl debugger $pids $name" -e sh -c 'tty 1>&3;\
6773  sleep 10000000' |];
6774
6775     # Get the output from 'tty' and clean it up a little.
6776     my $tty = <XT>;
6777     chomp $tty;
6778
6779     $pidprompt = '';    # Shown anyway in titlebar
6780
6781     # We need $term defined or we can not switch to the newly created xterm
6782     if ($tty ne '' && !defined $term) {
6783         require Term::ReadLine;
6784         if ( !$rl ) {
6785             $term = Term::ReadLine::Stub->new( 'perldb', $IN, $OUT );
6786         }
6787         else {
6788             $term = Term::ReadLine->new( 'perldb', $IN, $OUT );
6789         }
6790     }
6791     # There's our new TTY.
6792     return $tty;
6793 } ## end sub xterm_get_fork_TTY
6794
6795 =head3 C<os2_get_fork_TTY>
6796
6797 XXX It behooves an OS/2 expert to write the necessary documentation for this!
6798
6799 =cut
6800
6801 # This example function resets $IN, $OUT itself
6802 my $c_pipe = 0;
6803 sub os2_get_fork_TTY { # A simplification of the following (and works without):
6804     local $\  = '';
6805     ( my $name = $0 ) =~ s,^.*[/\\],,s;
6806     my %opt = ( title => "Daughter Perl debugger $pids $name",
6807         ($rl ? (read_by_key => 1) : ()) );
6808     require OS2::Process;
6809     my ($in, $out, $pid) = eval { OS2::Process::io_term(related => 0, %opt) }
6810       or return;
6811     $pidprompt = '';    # Shown anyway in titlebar
6812     reset_IN_OUT($in, $out);
6813     $tty = '*reset*';
6814     return '';          # Indicate that reset_IN_OUT is called
6815 } ## end sub os2_get_fork_TTY
6816
6817 =head3 C<macosx_get_fork_TTY>
6818
6819 The Mac OS X version uses AppleScript to tell Terminal.app to create
6820 a new window.
6821
6822 =cut
6823
6824 # Notes about Terminal.app's AppleScript support,
6825 # (aka things that might break in future OS versions).
6826 #
6827 # The "do script" command doesn't return a reference to the new window
6828 # it creates, but since it appears frontmost and windows are enumerated
6829 # front to back, we can use "first window" === "window 1".
6830 #
6831 # Since "do script" is implemented by supplying the argument (plus a
6832 # return character) as terminal input, there's a potential race condition
6833 # where the debugger could beat the shell to reading the command.
6834 # To prevent this, we wait for the screen to clear before proceeding.
6835 #
6836 # 10.3 and 10.4:
6837 # There's no direct accessor for the tty device name, so we fiddle
6838 # with the window title options until it says what we want.
6839 #
6840 # 10.5:
6841 # There _is_ a direct accessor for the tty device name, _and_ there's
6842 # a new possible component of the window title (the name of the settings
6843 # set).  A separate version is needed.
6844
6845 my @script_versions=
6846
6847     ([237, <<'__LEOPARD__'],
6848 tell application "Terminal"
6849     do script "clear;exec sleep 100000"
6850     tell first tab of first window
6851         copy tty to thetty
6852         set custom title to "forked perl debugger"
6853         set title displays custom title to true
6854         repeat while (length of first paragraph of (get contents)) > 0
6855             delay 0.1
6856         end repeat
6857     end tell
6858 end tell
6859 thetty
6860 __LEOPARD__
6861
6862      [100, <<'__JAGUAR_TIGER__'],
6863 tell application "Terminal"
6864     do script "clear;exec sleep 100000"
6865     tell first window
6866         set title displays shell path to false
6867         set title displays window size to false
6868         set title displays file name to false
6869         set title displays device name to true
6870         set title displays custom title to true
6871         set custom title to ""
6872         copy "/dev/" & name to thetty
6873         set custom title to "forked perl debugger"
6874         repeat while (length of first paragraph of (get contents)) > 0
6875             delay 0.1
6876         end repeat
6877     end tell
6878 end tell
6879 thetty
6880 __JAGUAR_TIGER__
6881
6882 );
6883
6884 sub macosx_get_fork_TTY
6885 {
6886     my($version,$script,$pipe,$tty);
6887
6888     return unless $version=$ENV{TERM_PROGRAM_VERSION};
6889     foreach my $entry (@script_versions) {
6890         if ($version>=$entry->[0]) {
6891             $script=$entry->[1];
6892             last;
6893         }
6894     }
6895     return unless defined($script);
6896     return unless open($pipe,'-|','/usr/bin/osascript','-e',$script);
6897     $tty=readline($pipe);
6898     close($pipe);
6899     return unless defined($tty) && $tty =~ m(^/dev/);
6900     chomp $tty;
6901     return $tty;
6902 }
6903
6904 =head2 C<create_IN_OUT($flags)>
6905
6906 Create a new pair of filehandles, pointing to a new TTY. If impossible,
6907 try to diagnose why.
6908
6909 Flags are:
6910
6911 =over 4
6912
6913 =item * 1 - Don't know how to create a new TTY.
6914
6915 =item * 2 - Debugger has forked, but we can't get a new TTY.
6916
6917 =item * 4 - standard debugger startup is happening.
6918
6919 =back
6920
6921 =cut
6922
6923 use vars qw($fork_TTY);
6924
6925 sub create_IN_OUT {    # Create a window with IN/OUT handles redirected there
6926
6927     # If we know how to get a new TTY, do it! $in will have
6928     # the TTY name if get_fork_TTY works.
6929     my $in = get_fork_TTY(@_) if defined &get_fork_TTY;
6930
6931     # It used to be that
6932     $in = $fork_TTY if defined $fork_TTY;    # Backward compatibility
6933
6934     if ( not defined $in ) {
6935         my $why = shift;
6936
6937         # We don't know how.
6938         print_help(<<EOP) if $why == 1;
6939 I<#########> Forked, but do not know how to create a new B<TTY>. I<#########>
6940 EOP
6941
6942         # Forked debugger.
6943         print_help(<<EOP) if $why == 2;
6944 I<#########> Daughter session, do not know how to change a B<TTY>. I<#########>
6945   This may be an asynchronous session, so the parent debugger may be active.
6946 EOP
6947
6948         # Note that both debuggers are fighting over the same input.
6949         print_help(<<EOP) if $why != 4;
6950   Since two debuggers fight for the same TTY, input is severely entangled.
6951
6952 EOP
6953         print_help(<<EOP);
6954   I know how to switch the output to a different window in xterms, OS/2
6955   consoles, and Mac OS X Terminal.app only.  For a manual switch, put the name
6956   of the created I<TTY> in B<\$DB::fork_TTY>, or define a function
6957   B<DB::get_fork_TTY()> returning this.
6958
6959   On I<UNIX>-like systems one can get the name of a I<TTY> for the given window
6960   by typing B<tty>, and disconnect the I<shell> from I<TTY> by B<sleep 1000000>.
6961
6962 EOP
6963     } ## end if (not defined $in)
6964     elsif ( $in ne '' ) {
6965         TTY($in);
6966     }
6967     else {
6968         $console = '';    # Indicate no need to open-from-the-console
6969     }
6970     undef $fork_TTY;
6971 } ## end sub create_IN_OUT
6972
6973 =head2 C<resetterm>
6974
6975 Handles rejiggering the prompt when we've forked off a new debugger.
6976
6977 If the new debugger happened because of a C<system()> that invoked a
6978 program under the debugger, the arrow between the old pid and the new
6979 in the prompt has I<two> dashes instead of one.
6980
6981 We take the current list of pids and add this one to the end. If there
6982 isn't any list yet, we make one up out of the initial pid associated with
6983 the terminal and our new pid, sticking an arrow (either one-dashed or
6984 two dashed) in between them.
6985
6986 If C<CreateTTY> is off, or C<resetterm> was called with no arguments,
6987 we don't try to create a new IN and OUT filehandle. Otherwise, we go ahead
6988 and try to do that.
6989
6990 =cut
6991
6992 sub resetterm {    # We forked, so we need a different TTY
6993
6994     # Needs to be passed to create_IN_OUT() as well.
6995     my $in = shift;
6996
6997     # resetterm(2): got in here because of a system() starting a debugger.
6998     # resetterm(1): just forked.
6999     my $systemed = $in > 1 ? '-' : '';
7000
7001     # If there's already a list of pids, add this to the end.
7002     if ($pids) {
7003         $pids =~ s/\]/$systemed->$$]/;
7004     }
7005
7006     # No pid list. Time to make one.
7007     else {
7008         $pids = "[$term_pid->$$]";
7009     }
7010
7011     # The prompt we're going to be using for this debugger.
7012     $pidprompt = $pids;
7013
7014     # We now 0wnz this terminal.
7015     $term_pid = $$;
7016
7017     # Just return if we're not supposed to try to create a new TTY.
7018     return unless $CreateTTY & $in;
7019
7020     # Try to create a new IN/OUT pair.
7021     create_IN_OUT($in);
7022 } ## end sub resetterm
7023
7024 =head2 C<readline>
7025
7026 First, we handle stuff in the typeahead buffer. If there is any, we shift off
7027 the next line, print a message saying we got it, add it to the terminal
7028 history (if possible), and return it.
7029
7030 If there's nothing in the typeahead buffer, check the command filehandle stack.
7031 If there are any filehandles there, read from the last one, and return the line
7032 if we got one. If not, we pop the filehandle off and close it, and try the
7033 next one up the stack.
7034
7035 If we've emptied the filehandle stack, we check to see if we've got a socket
7036 open, and we read that and return it if we do. If we don't, we just call the
7037 core C<readline()> and return its value.
7038
7039 =cut
7040
7041 sub readline {
7042
7043     # Localize to prevent it from being smashed in the program being debugged.
7044     local $.;
7045
7046     # If there are stacked filehandles to read from ...
7047     # (Handle it before the typeahead, because we may call source/etc. from
7048     # the typeahead.)
7049     while (@cmdfhs) {
7050
7051         # Read from the last one in the stack.
7052         my $line = CORE::readline( $cmdfhs[-1] );
7053
7054         # If we got a line ...
7055         defined $line
7056           ? ( print $OUT ">> $line" and return $line )    # Echo and return
7057           : close pop @cmdfhs;                            # Pop and close
7058     } ## end while (@cmdfhs)
7059
7060     # Pull a line out of the typeahead if there's stuff there.
7061     if (@typeahead) {
7062
7063         # How many lines left.
7064         my $left = @typeahead;
7065
7066         # Get the next line.
7067         my $got = shift @typeahead;
7068
7069         # Print a message saying we got input from the typeahead.
7070         local $\ = '';
7071         print $OUT "auto(-$left)", shift, $got, "\n";
7072
7073         # Add it to the terminal history (if possible).
7074         $term->AddHistory($got)
7075           if length($got) > 1
7076           and defined $term->Features->{addHistory};
7077         return $got;
7078     } ## end if (@typeahead)
7079
7080     # We really need to read some input. Turn off entry/exit trace and
7081     # return value printing.
7082     local $frame = 0;
7083     local $doret = -2;
7084
7085     # Nothing on the filehandle stack. Socket?
7086     if ( ref $OUT and UNIVERSAL::isa( $OUT, 'IO::Socket::INET' ) ) {
7087
7088         # Send anything we have to send.
7089         $OUT->write( join( '', @_ ) );
7090
7091         # Receive anything there is to receive.
7092         my $stuff = '';
7093         my $buf;
7094         my $first_time = 1;
7095
7096         while ($first_time or (length($buf) && ($stuff .= $buf) !~ /\n/))
7097         {
7098             $first_time = 0;
7099             $IN->recv( $buf = '', 2048 );   # XXX "what's wrong with sysread?"
7100                                             # XXX Don't know. You tell me.
7101         }
7102
7103         # What we got.
7104         return $stuff;
7105     } ## end if (ref $OUT and UNIVERSAL::isa...
7106
7107     # No socket. Just read from the terminal.
7108     else {
7109         return $term->readline(@_);
7110     }
7111 } ## end sub readline
7112
7113 =head1 OPTIONS SUPPORT ROUTINES
7114
7115 These routines handle listing and setting option values.
7116
7117 =head2 C<dump_option> - list the current value of an option setting
7118
7119 This routine uses C<option_val> to look up the value for an option.
7120 It cleans up escaped single-quotes and then displays the option and
7121 its value.
7122
7123 =cut
7124
7125 sub dump_option {
7126     my ( $opt, $val ) = @_;
7127     $val = option_val( $opt, 'N/A' );
7128     $val =~ s/([\\\'])/\\$1/g;
7129     printf $OUT "%20s = '%s'\n", $opt, $val;
7130 } ## end sub dump_option
7131
7132 sub options2remember {
7133     foreach my $k (@RememberOnROptions) {
7134         $option{$k} = option_val( $k, 'N/A' );
7135     }
7136     return %option;
7137 }
7138
7139 =head2 C<option_val> - find the current value of an option
7140
7141 This can't just be a simple hash lookup because of the indirect way that
7142 the option values are stored. Some are retrieved by calling a subroutine,
7143 some are just variables.
7144
7145 You must supply a default value to be used in case the option isn't set.
7146
7147 =cut
7148
7149 sub option_val {
7150     my ( $opt, $default ) = @_;
7151     my $val;
7152
7153     # Does this option exist, and is it a variable?
7154     # If so, retrieve the value via the value in %optionVars.
7155     if (    defined $optionVars{$opt}
7156         and defined ${ $optionVars{$opt} } )
7157     {
7158         $val = ${ $optionVars{$opt} };
7159     }
7160
7161     # Does this option exist, and it's a subroutine?
7162     # If so, call the subroutine via the ref in %optionAction
7163     # and capture the value.
7164     elsif ( defined $optionAction{$opt}
7165         and defined &{ $optionAction{$opt} } )
7166     {
7167         $val = &{ $optionAction{$opt} }();
7168     }
7169
7170     # If there's an action or variable for the supplied option,
7171     # but no value was set, use the default.
7172     elsif (defined $optionAction{$opt} and not defined $option{$opt}
7173         or defined $optionVars{$opt} and not defined ${ $optionVars{$opt} } )
7174     {
7175         $val = $default;
7176     }
7177
7178     # Otherwise, do the simple hash lookup.
7179     else {
7180         $val = $option{$opt};
7181     }
7182
7183     # If the value isn't defined, use the default.
7184     # Then return whatever the value is.
7185     $val = $default unless defined $val;
7186     $val;
7187 } ## end sub option_val
7188
7189 =head2 C<parse_options>
7190
7191 Handles the parsing and execution of option setting/displaying commands.
7192
7193 An option entered by itself is assumed to be I<set me to 1> (the default value)
7194 if the option is a boolean one. If not, the user is prompted to enter a valid
7195 value or to query the current value (via C<option? >).
7196
7197 If C<option=value> is entered, we try to extract a quoted string from the
7198 value (if it is quoted). If it's not, we just use the whole value as-is.
7199
7200 We load any modules required to service this option, and then we set it: if
7201 it just gets stuck in a variable, we do that; if there's a subroutine to
7202 handle setting the option, we call that.
7203
7204 Finally, if we're running in interactive mode, we display the effect of the
7205 user's command back to the terminal, skipping this if we're setting things
7206 during initialization.
7207
7208 =cut
7209
7210 sub parse_options {
7211     my ($s) = @_;
7212     local $\ = '';
7213
7214     my $option;
7215
7216     # These options need a value. Don't allow them to be clobbered by accident.
7217     my %opt_needs_val = map { ( $_ => 1 ) } qw{
7218       dumpDepth arrayDepth hashDepth LineInfo maxTraceLen ornaments windowSize
7219       pager quote ReadLine recallCommand RemotePort ShellBang TTY CommandSet
7220     };
7221
7222     while (length($s)) {
7223         my $val_defaulted;
7224
7225         # Clean off excess leading whitespace.
7226         $s =~ s/^\s+// && next;
7227
7228         # Options are always all word characters, followed by a non-word
7229         # separator.
7230         if ($s !~ s/^(\w+)(\W?)//) {
7231             print {$OUT} "Invalid option '$s'\n";
7232             last;
7233         }
7234         my ( $opt, $sep ) = ( $1, $2 );
7235
7236         # Make sure that such an option exists.
7237         my $matches = ( grep { /^\Q$opt/ && ( $option = $_ ) } @options )
7238           || ( grep { /^\Q$opt/i && ( $option = $_ ) } @options );
7239
7240         unless ($matches) {
7241             print {$OUT} "Unknown option '$opt'\n";
7242             next;
7243         }
7244         if ($matches > 1) {
7245             print {$OUT} "Ambiguous option '$opt'\n";
7246             next;
7247         }
7248         my $val;
7249
7250         # '?' as separator means query, but must have whitespace after it.
7251         if ( "?" eq $sep ) {
7252             if ($s =~ /\A\S/) {
7253                 print {$OUT} "Option query '$opt?' followed by non-space '$s'\n" ;
7254
7255                 last;
7256             }
7257
7258             #&dump_option($opt);
7259         } ## end if ("?" eq $sep)
7260
7261         # Separator is whitespace (or just a carriage return).
7262         # They're going for a default, which we assume is 1.
7263         elsif ( $sep !~ /\S/ ) {
7264             $val_defaulted = 1;
7265             $val           = "1";   #  this is an evil default; make 'em set it!
7266         }
7267
7268         # Separator is =. Trying to set a value.
7269         elsif ( $sep eq "=" ) {
7270
7271             # If quoted, extract a quoted string.
7272             if ($s =~ s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x) {
7273                 my $quote = $1;
7274                 ( $val = $2 ) =~ s/\\([$quote\\])/$1/g;
7275             }
7276
7277             # Not quoted. Use the whole thing. Warn about 'option='.
7278             else {
7279                 $s =~ s/^(\S*)//;
7280                 $val = $1;
7281                 print OUT qq(Option better cleared using $opt=""\n)
7282                   unless length $val;
7283             } ## end else [ if (s/ (["']) ( (?: \\. | (?! \1 ) [^\\] )* ) \1 //x)
7284
7285         } ## end elsif ($sep eq "=")
7286
7287         # "Quoted" with [], <>, or {}.
7288         else {    #{ to "let some poor schmuck bounce on the % key in B<vi>."
7289             my ($end) =
7290               "\\" . substr( ")]>}$sep", index( "([<{", $sep ), 1 );    #}
7291             $s =~ s/^(([^\\$end]|\\[\\$end])*)$end($|\s+)//
7292               or print( $OUT "Unclosed option value '$opt$sep$_'\n" ), last;
7293             ( $val = $1 ) =~ s/\\([\\$end])/$1/g;
7294         } ## end else [ if ("?" eq $sep)
7295
7296         # Exclude non-booleans from getting set to 1 by default.
7297         if ( $opt_needs_val{$option} && $val_defaulted ) {
7298             my $cmd = ( $CommandSet eq '580' ) ? 'o' : 'O';
7299             print {$OUT}
7300 "Option '$opt' is non-boolean.  Use '$cmd $option=VAL' to set, '$cmd $option?' to query\n";
7301             next;
7302         } ## end if ($opt_needs_val{$option...
7303
7304         # Save the option value.
7305         $option{$option} = $val if defined $val;
7306
7307         # Load any module that this option requires.
7308         if ( defined($optionRequire{$option}) && defined($val) ) {
7309             eval qq{
7310             local \$frame = 0;
7311             local \$doret = -2;
7312             require '$optionRequire{$option}';
7313             1;
7314             } || die $@   # XXX: shouldn't happen
7315         }
7316
7317         # Set it.
7318         # Stick it in the proper variable if it goes in a variable.
7319         if (defined($optionVars{$option}) && defined($val)) {
7320             ${ $optionVars{$option} } = $val;
7321         }
7322
7323         # Call the appropriate sub if it gets set via sub.
7324         if (defined($optionAction{$option})
7325           && defined (&{ $optionAction{$option} })
7326           && defined ($val))
7327         {
7328           &{ $optionAction{$option} }($val);
7329         }
7330
7331         # Not initialization - echo the value we set it to.
7332         dump_option($option) if ($OUT ne \*STDERR);
7333     } ## end while (length)
7334 } ## end sub parse_options
7335
7336 =head1 RESTART SUPPORT
7337
7338 These routines are used to store (and restore) lists of items in environment
7339 variables during a restart.
7340
7341 =head2 set_list
7342
7343 Set_list packages up items to be stored in a set of environment variables
7344 (VAR_n, containing the number of items, and VAR_0, VAR_1, etc., containing
7345 the values). Values outside the standard ASCII charset are stored by encoding
7346 then as hexadecimal values.
7347
7348 =cut
7349
7350 sub set_list {
7351     my ( $stem, @list ) = @_;
7352     my $val;
7353
7354     # VAR_n: how many we have. Scalar assignment gets the number of items.
7355     $ENV{"${stem}_n"} = @list;
7356
7357     # Grab each item in the list, escape the backslashes, encode the non-ASCII
7358     # as hex, and then save in the appropriate VAR_0, VAR_1, etc.
7359     for my $i ( 0 .. $#list ) {
7360         $val = $list[$i];
7361         $val =~ s/\\/\\\\/g;
7362         $val =~ s/([\0-\37\177\200-\377])/"\\0x" . unpack('H2',$1)/eg;
7363         $ENV{"${stem}_$i"} = $val;
7364     } ## end for $i (0 .. $#list)
7365 } ## end sub set_list
7366
7367 =head2 get_list
7368
7369 Reverse the set_list operation: grab VAR_n to see how many we should be getting
7370 back, and then pull VAR_0, VAR_1. etc. back out.
7371
7372 =cut
7373
7374 sub get_list {
7375     my $stem = shift;
7376     my @list;
7377     my $n = delete $ENV{"${stem}_n"};
7378     my $val;
7379     for my $i ( 0 .. $n - 1 ) {
7380         $val = delete $ENV{"${stem}_$i"};
7381         $val =~ s/\\((\\)|0x(..))/ $2 ? $2 : pack('H2', $3) /ge;
7382         push @list, $val;
7383     }
7384     @list;
7385 } ## end sub get_list
7386
7387 =head1 MISCELLANEOUS SIGNAL AND I/O MANAGEMENT
7388
7389 =head2 catch()
7390
7391 The C<catch()> subroutine is the essence of fast and low-impact. We simply
7392 set an already-existing global scalar variable to a constant value. This
7393 avoids allocating any memory possibly in the middle of something that will
7394 get all confused if we do, particularly under I<unsafe signals>.
7395
7396 =cut
7397
7398 sub catch {
7399     $signal = 1;
7400     return;    # Put nothing on the stack - malloc/free land!
7401 }
7402
7403 =head2 C<warn()>
7404
7405 C<warn> emits a warning, by joining together its arguments and printing
7406 them, with couple of fillips.
7407
7408 If the composited message I<doesn't> end with a newline, we automatically
7409 add C<$!> and a newline to the end of the message. The subroutine expects $OUT
7410 to be set to the filehandle to be used to output warnings; it makes no
7411 assumptions about what filehandles are available.
7412
7413 =cut
7414
7415 sub _db_warn {
7416     my ($msg) = join( "", @_ );
7417     $msg .= ": $!\n" unless $msg =~ /\n$/;
7418     local $\ = '';
7419     print $OUT $msg;
7420 } ## end sub warn
7421
7422 *warn = \&_db_warn;
7423
7424 =head1 INITIALIZATION TTY SUPPORT
7425
7426 =head2 C<reset_IN_OUT>
7427
7428 This routine handles restoring the debugger's input and output filehandles
7429 after we've tried and failed to move them elsewhere.  In addition, it assigns
7430 the debugger's output filehandle to $LINEINFO if it was already open there.
7431
7432 =cut
7433
7434 sub reset_IN_OUT {
7435     my $switch_li = $LINEINFO eq $OUT;
7436
7437     # If there's a term and it's able to get a new tty, try to get one.
7438     if ( $term and $term->Features->{newTTY} ) {
7439         ( $IN, $OUT ) = ( shift, shift );
7440         $term->newTTY( $IN, $OUT );
7441     }
7442
7443     # This term can't get a new tty now. Better luck later.
7444     elsif ($term) {
7445         _db_warn("Too late to set IN/OUT filehandles, enabled on next 'R'!\n");
7446     }
7447
7448     # Set the filehndles up as they were.
7449     else {
7450         ( $IN, $OUT ) = ( shift, shift );
7451     }
7452
7453     # Unbuffer the output filehandle.
7454     $OUT->autoflush(1);
7455
7456     # Point LINEINFO to the same output filehandle if it was there before.
7457     $LINEINFO = $OUT if $switch_li;
7458 } ## end sub reset_IN_OUT
7459
7460 =head1 OPTION SUPPORT ROUTINES
7461
7462 The following routines are used to process some of the more complicated
7463 debugger options.
7464
7465 =head2 C<TTY>
7466
7467 Sets the input and output filehandles to the specified files or pipes.
7468 If the terminal supports switching, we go ahead and do it. If not, and
7469 there's already a terminal in place, we save the information to take effect
7470 on restart.
7471
7472 If there's no terminal yet (for instance, during debugger initialization),
7473 we go ahead and set C<$console> and C<$tty> to the file indicated.
7474
7475 =cut
7476
7477 sub TTY {
7478
7479     if ( @_ and $term and $term->Features->{newTTY} ) {
7480
7481         # This terminal supports switching to a new TTY.
7482         # Can be a list of two files, or on string containing both names,
7483         # comma-separated.
7484         # XXX Should this perhaps be an assignment from @_?
7485         my ( $in, $out ) = shift;
7486         if ( $in =~ /,/ ) {
7487
7488             # Split list apart if supplied.
7489             ( $in, $out ) = split /,/, $in, 2;
7490         }
7491         else {
7492
7493             # Use the same file for both input and output.
7494             $out = $in;
7495         }
7496
7497         # Open file onto the debugger's filehandles, if you can.
7498         open IN,  $in     or die "cannot open '$in' for read: $!";
7499         open OUT, ">$out" or die "cannot open '$out' for write: $!";
7500
7501         # Swap to the new filehandles.
7502         reset_IN_OUT( \*IN, \*OUT );
7503
7504         # Save the setting for later.
7505         return $tty = $in;
7506     } ## end if (@_ and $term and $term...
7507
7508     # Terminal doesn't support new TTY, or doesn't support readline.
7509     # Can't do it now, try restarting.
7510     if ($term and @_) {
7511         _db_warn("Too late to set TTY, enabled on next 'R'!\n");
7512     }
7513
7514     # Useful if done through PERLDB_OPTS:
7515     $console = $tty = shift if @_;
7516
7517     # Return whatever the TTY is.
7518     $tty or $console;
7519 } ## end sub TTY
7520
7521 =head2 C<noTTY>
7522
7523 Sets the C<$notty> global, controlling whether or not the debugger tries to
7524 get a terminal to read from. If called after a terminal is already in place,
7525 we save the value to use it if we're restarted.
7526
7527 =cut
7528
7529 sub noTTY {
7530     if ($term) {
7531         _db_warn("Too late to set noTTY, enabled on next 'R'!\n") if @_;
7532     }
7533     $notty = shift if @_;
7534     $notty;
7535 } ## end sub noTTY
7536
7537 =head2 C<ReadLine>
7538
7539 Sets the C<$rl> option variable. If 0, we use C<Term::ReadLine::Stub>
7540 (essentially, no C<readline> processing on this I<terminal>). Otherwise, we
7541 use C<Term::ReadLine>. Can't be changed after a terminal's in place; we save
7542 the value in case a restart is done so we can change it then.
7543
7544 =cut
7545
7546 sub ReadLine {
7547     if ($term) {
7548         _db_warn("Too late to set ReadLine, enabled on next 'R'!\n") if @_;
7549     }
7550     $rl = shift if @_;
7551     $rl;
7552 } ## end sub ReadLine
7553
7554 =head2 C<RemotePort>
7555
7556 Sets the port that the debugger will try to connect to when starting up.
7557 If the terminal's already been set up, we can't do it, but we remember the
7558 setting in case the user does a restart.
7559
7560 =cut
7561
7562 sub RemotePort {
7563     if ($term) {
7564         _db_warn("Too late to set RemotePort, enabled on next 'R'!\n") if @_;
7565     }
7566     $remoteport = shift if @_;
7567     $remoteport;
7568 } ## end sub RemotePort
7569
7570 =head2 C<tkRunning>
7571
7572 Checks with the terminal to see if C<Tk> is running, and returns true or
7573 false. Returns false if the current terminal doesn't support C<readline>.
7574
7575 =cut
7576
7577 sub tkRunning {
7578     if ( ${ $term->Features }{tkRunning} ) {
7579         return $term->tkRunning(@_);
7580     }
7581     else {
7582         local $\ = '';
7583         print $OUT "tkRunning not supported by current ReadLine package.\n";
7584         0;
7585     }
7586 } ## end sub tkRunning
7587
7588 =head2 C<NonStop>
7589
7590 Sets nonstop mode. If a terminal's already been set up, it's too late; the
7591 debugger remembers the setting in case you restart, though.
7592
7593 =cut
7594
7595 sub NonStop {
7596     if ($term) {
7597         _db_warn("Too late to set up NonStop mode, enabled on next 'R'!\n")
7598           if @_;
7599     }
7600     $runnonstop = shift if @_;
7601     $runnonstop;
7602 } ## end sub NonStop
7603
7604 sub DollarCaretP {
7605     if ($term) {
7606         _db_warn("Some flag changes could not take effect until next 'R'!\n")
7607           if @_;
7608     }
7609     $^P = parse_DollarCaretP_flags(shift) if @_;
7610     expand_DollarCaretP_flags($^P);
7611 }
7612
7613 =head2 C<pager>
7614
7615 Set up the C<$pager> variable. Adds a pipe to the front unless there's one
7616 there already.
7617
7618 =cut
7619
7620 sub pager {
7621     if (@_) {
7622         $pager = shift;
7623         $pager = "|" . $pager unless $pager =~ /^(\+?\>|\|)/;
7624     }
7625     $pager;
7626 } ## end sub pager
7627
7628 =head2 C<shellBang>
7629
7630 Sets the shell escape command, and generates a printable copy to be used
7631 in the help.
7632
7633 =cut
7634
7635 sub shellBang {
7636
7637     # If we got an argument, meta-quote it, and add '\b' if it
7638     # ends in a word character.
7639     if (@_) {
7640         $sh = quotemeta shift;
7641         $sh .= "\\b" if $sh =~ /\w$/;
7642     }
7643
7644     # Generate the printable version for the help:
7645     $psh = $sh;    # copy it
7646     $psh =~ s/\\b$//;        # Take off trailing \b if any
7647     $psh =~ s/\\(.)/$1/g;    # De-escape
7648     $psh;                    # return the printable version
7649 } ## end sub shellBang
7650
7651 =head2 C<ornaments>
7652
7653 If the terminal has its own ornaments, fetch them. Otherwise accept whatever
7654 was passed as the argument. (This means you can't override the terminal's
7655 ornaments.)
7656
7657 =cut
7658
7659 sub ornaments {
7660     if ( defined $term ) {
7661
7662         # We don't want to show warning backtraces, but we do want die() ones.
7663         local ( $warnLevel, $dieLevel ) = ( 0, 1 );
7664
7665         # No ornaments if the terminal doesn't support them.
7666         return '' unless $term->Features->{ornaments};
7667         eval { $term->ornaments(@_) } || '';
7668     }
7669
7670     # Use what was passed in if we can't determine it ourselves.
7671     else {
7672         $ornaments = shift;
7673     }
7674 } ## end sub ornaments
7675
7676 =head2 C<recallCommand>
7677
7678 Sets the recall command, and builds a printable version which will appear in
7679 the help text.
7680
7681 =cut
7682
7683 sub recallCommand {
7684
7685     # If there is input, metaquote it. Add '\b' if it ends with a word
7686     # character.
7687     if (@_) {
7688         $rc = quotemeta shift;
7689         $rc .= "\\b" if $rc =~ /\w$/;
7690     }
7691
7692     # Build it into a printable version.
7693     $prc = $rc;    # Copy it
7694     $prc =~ s/\\b$//;        # Remove trailing \b
7695     $prc =~ s/\\(.)/$1/g;    # Remove escapes
7696     $prc;                    # Return the printable version
7697 } ## end sub recallCommand
7698
7699 =head2 C<LineInfo> - where the line number information goes
7700
7701 Called with no arguments, returns the file or pipe that line info should go to.
7702
7703 Called with an argument (a file or a pipe), it opens that onto the
7704 C<LINEINFO> filehandle, unbuffers the filehandle, and then returns the
7705 file or pipe again to the caller.
7706
7707 =cut
7708
7709 sub LineInfo {
7710     if (@_) {
7711         $lineinfo = shift;
7712
7713         #  If this is a valid "thing to be opened for output", tack a
7714         # '>' onto the front.
7715         my $stream = ( $lineinfo =~ /^(\+?\>|\|)/ ) ? $lineinfo : ">$lineinfo";
7716
7717         # If this is a pipe, the stream points to a slave editor.
7718         $slave_editor = ( $stream =~ /^\|/ );
7719
7720         # Open it up and unbuffer it.
7721         open( LINEINFO, $stream ) || _db_warn("Cannot open '$stream' for write");
7722         $LINEINFO = \*LINEINFO;
7723         $LINEINFO->autoflush(1);
7724     }
7725
7726     return $lineinfo;
7727 } ## end sub LineInfo
7728
7729 =head1 COMMAND SUPPORT ROUTINES
7730
7731 These subroutines provide functionality for various commands.
7732
7733 =head2 C<list_modules>
7734
7735 For the C<M> command: list modules loaded and their versions.
7736 Essentially just runs through the keys in %INC, picks each package's
7737 C<$VERSION> variable, gets the file name, and formats the information
7738 for output.
7739
7740 =cut
7741
7742 sub list_modules {    # versions
7743     my %version;
7744     my $file;
7745
7746     # keys are the "as-loaded" name, values are the fully-qualified path
7747     # to the file itself.
7748     for ( keys %INC ) {
7749         $file = $_;                                # get the module name
7750         s,\.p[lm]$,,i;                             # remove '.pl' or '.pm'
7751         s,/,::,g;                                  # change '/' to '::'
7752         s/^perl5db$/DB/;                           # Special case: debugger
7753                                                    # moves to package DB
7754         s/^Term::ReadLine::readline$/readline/;    # simplify readline
7755
7756         # If the package has a $VERSION package global (as all good packages
7757         # should!) decode it and save as partial message.
7758         my $pkg_version = do { no strict 'refs'; ${ $_ . '::VERSION' } };
7759         if ( defined $pkg_version ) {
7760             $version{$file} = "$pkg_version from ";
7761         }
7762
7763         # Finish up the message with the file the package came from.
7764         $version{$file} .= $INC{$file};
7765     } ## end for (keys %INC)
7766
7767     # Hey, dumpit() formats a hash nicely, so why not use it?
7768     dumpit( $OUT, \%version );
7769 } ## end sub list_modules
7770
7771 =head2 C<sethelp()>
7772
7773 Sets up the monster string used to format and print the help.
7774
7775 =head3 HELP MESSAGE FORMAT
7776
7777 The help message is a peculiar format unto itself; it mixes C<pod> I<ornaments>
7778 (C<< B<> >> C<< I<> >>) with tabs to come up with a format that's fairly
7779 easy to parse and portable, but which still allows the help to be a little
7780 nicer than just plain text.
7781
7782 Essentially, you define the command name (usually marked up with C<< B<> >>
7783 and C<< I<> >>), followed by a tab, and then the descriptive text, ending in a
7784 newline. The descriptive text can also be marked up in the same way. If you
7785 need to continue the descriptive text to another line, start that line with
7786 just tabs and then enter the marked-up text.
7787
7788 If you are modifying the help text, I<be careful>. The help-string parser is
7789 not very sophisticated, and if you don't follow these rules it will mangle the
7790 help beyond hope until you fix the string.
7791
7792 =cut
7793
7794 use vars qw($pre580_help);
7795 use vars qw($pre580_summary);
7796
7797 sub sethelp {
7798
7799     # XXX: make sure there are tabs between the command and explanation,
7800     #      or print_help will screw up your formatting if you have
7801     #      eeevil ornaments enabled.  This is an insane mess.
7802
7803     $help = "
7804 Help is currently only available for the new 5.8 command set.
7805 No help is available for the old command set.
7806 We assume you know what you're doing if you switch to it.
7807
7808 B<T>        Stack trace.
7809 B<s> [I<expr>]    Single step [in I<expr>].
7810 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
7811 <B<CR>>        Repeat last B<n> or B<s> command.
7812 B<r>        Return from current subroutine.
7813 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
7814         at the specified position.
7815 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
7816 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
7817 B<l> I<line>        List single I<line>.
7818 B<l> I<subname>    List first window of lines from subroutine.
7819 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
7820 B<l>        List next window of lines.
7821 B<->        List previous window of lines.
7822 B<v> [I<line>]    View window around I<line>.
7823 B<.>        Return to the executed line.
7824 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
7825         I<filename> may be either the full name of the file, or a regular
7826         expression matching the full file name:
7827         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
7828         Evals (with saved bodies) are considered to be filenames:
7829         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
7830         (in the order of execution).
7831 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
7832 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
7833 B<L> [I<a|b|w>]        List actions and or breakpoints and or watch-expressions.
7834 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
7835 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth).
7836 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
7837 B<b>        Sets breakpoint on current line)
7838 B<b> [I<line>] [I<condition>]
7839         Set breakpoint; I<line> defaults to the current execution line;
7840         I<condition> breaks if it evaluates to true, defaults to '1'.
7841 B<b> I<subname> [I<condition>]
7842         Set breakpoint at first line of subroutine.
7843 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
7844 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
7845 B<b> B<postpone> I<subname> [I<condition>]
7846         Set breakpoint at first line of subroutine after
7847         it is compiled.
7848 B<b> B<compile> I<subname>
7849         Stop after the subroutine is compiled.
7850 B<B> [I<line>]    Delete the breakpoint for I<line>.
7851 B<B> I<*>             Delete all breakpoints.
7852 B<a> [I<line>] I<command>
7853         Set an action to be done before the I<line> is executed;
7854         I<line> defaults to the current execution line.
7855         Sequence is: check for breakpoint/watchpoint, print line
7856         if necessary, do action, prompt user if necessary,
7857         execute line.
7858 B<a>        Does nothing
7859 B<A> [I<line>]    Delete the action for I<line>.
7860 B<A> I<*>             Delete all actions.
7861 B<w> I<expr>        Add a global watch-expression.
7862 B<w>             Does nothing
7863 B<W> I<expr>        Delete a global watch-expression.
7864 B<W> I<*>             Delete all watch-expressions.
7865 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
7866         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
7867 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
7868 B<x> I<expr>        Evals expression in list context, dumps the result.
7869 B<m> I<expr>        Evals expression in list context, prints methods callable
7870         on the first element of the result.
7871 B<m> I<class>        Prints methods callable via the given class.
7872 B<M>        Show versions of loaded modules.
7873 B<i> I<class>       Prints nested parents of given class.
7874 B<e>         Display current thread id.
7875 B<E>         Display all thread ids the current one will be identified: <n>.
7876 B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7877
7878 B<<> ?            List Perl commands to run before each prompt.
7879 B<<> I<expr>        Define Perl command to run before each prompt.
7880 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
7881 B<< *>                Delete the list of perl commands to run before each prompt.
7882 B<>> ?            List Perl commands to run after each prompt.
7883 B<>> I<expr>        Define Perl command to run after each prompt.
7884 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
7885 B<>>B< *>        Delete the list of Perl commands to run after each prompt.
7886 B<{> I<db_command>    Define debugger command to run before each prompt.
7887 B<{> ?            List debugger commands to run before each prompt.
7888 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
7889 B<{ *>             Delete the list of debugger commands to run before each prompt.
7890 B<$prc> I<number>    Redo a previous command (default previous command).
7891 B<$prc> I<-number>    Redo number'th-to-last command.
7892 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
7893         See 'B<O> I<recallCommand>' too.
7894 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
7895       . (
7896         $rc eq $sh
7897         ? ""
7898         : "
7899 B<$psh> [I<cmd>] Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
7900       ) . "
7901         See 'B<O> I<shellBang>' too.
7902 B<source> I<file>     Execute I<file> containing debugger commands (may nest).
7903 B<save> I<file>       Save current debugger session (actual history) to I<file>.
7904 B<rerun>           Rerun session to current position.
7905 B<rerun> I<n>         Rerun session to numbered command.
7906 B<rerun> I<-n>        Rerun session to number'th-to-last command.
7907 B<H> I<-number>    Display last number commands (default all).
7908 B<H> I<*>          Delete complete history.
7909 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
7910 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
7911 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarily select()ed as well.
7912 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
7913 I<command>        Execute as a perl statement in current package.
7914 B<R>        Pure-man-restart of debugger, some of debugger state
7915         and command-line options may be lost.
7916         Currently the following settings are preserved:
7917         history, breakpoints and actions, debugger B<O>ptions
7918         and the following command-line options: I<-w>, I<-I>, I<-e>.
7919
7920 B<o> [I<opt>] ...    Set boolean option to true
7921 B<o> [I<opt>B<?>]    Query options
7922 B<o> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
7923         Set options.  Use quotes if spaces in value.
7924     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
7925     I<pager>            program for output of \"|cmd\";
7926     I<tkRunning>            run Tk while prompting (with ReadLine);
7927     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
7928     I<inhibit_exit>        Allows stepping off the end of the script.
7929     I<ImmediateStop>        Debugger should stop as early as possible.
7930     I<RemotePort>            Remote hostname:port for remote debugging
7931   The following options affect what happens with B<V>, B<X>, and B<x> commands:
7932     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
7933     I<compactDump>, I<veryCompact>     change style of array and hash dump;
7934     I<globPrint>             whether to print contents of globs;
7935     I<DumpDBFiles>         dump arrays holding debugged files;
7936     I<DumpPackages>         dump symbol tables of packages;
7937     I<DumpReused>             dump contents of \"reused\" addresses;
7938     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
7939     I<bareStringify>         Do not print the overload-stringified value;
7940   Other options include:
7941     I<PrintRet>        affects printing of return value after B<r> command,
7942     I<frame>        affects printing messages on subroutine entry/exit.
7943     I<AutoTrace>    affects printing messages on possible breaking points.
7944     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
7945     I<ornaments>     affects screen appearance of the command line.
7946     I<CreateTTY>     bits control attempts to create a new TTY on events:
7947             1: on fork()    2: debugger is started inside debugger
7948             4: on startup
7949     During startup options are initialized from \$ENV{PERLDB_OPTS}.
7950     You can put additional initialization options I<TTY>, I<noTTY>,
7951     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
7952     B<R> after you set them).
7953
7954 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
7955 B<h>        Summary of debugger commands.
7956 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
7957 B<h h>        Long help for debugger commands
7958 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
7959         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
7960         Set B<\$DB::doccmd> to change viewer.
7961
7962 Type '|h h' for a paged display if this was too hard to read.
7963
7964 ";    # Fix balance of vi % matching: }}}}
7965
7966     #  note: tabs in the following section are not-so-helpful
7967     $summary = <<"END_SUM";
7968 I<List/search source lines:>               I<Control script execution:>
7969   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
7970   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
7971   B<v> [I<line>]    View around line            B<n> [I<expr>]    Next, steps over subs
7972   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
7973   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
7974   B<M>           Show module versions        B<c> [I<ln>|I<sub>]  Continue until position
7975 I<Debugger controls:>                        B<L>           List break/watch/actions
7976   B<o> [...]     Set debugger options        B<t> [I<n>] [I<expr>] Toggle trace [max depth] ][trace expr]
7977   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
7978   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<B> I<ln|*>      Delete a/all breakpoints
7979   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
7980   B<=> [I<a> I<val>]   Define/list an alias        B<A> I<ln|*>      Delete a/all actions
7981   B<h> [I<db_cmd>]  Get help on command         B<w> I<expr>      Add a watch expression
7982   B<h h>         Complete help page          B<W> I<expr|*>    Delete a/all watch exprs
7983   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
7984   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
7985 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
7986   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
7987   B<p> I<expr>         Print expression (uses script's current package).
7988   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
7989   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
7990   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".  B<i> I<class> inheritance tree.
7991   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
7992   B<e>     Display thread id     B<E> Display all thread ids.
7993 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
7994 END_SUM
7995
7996     # ')}}; # Fix balance of vi % matching
7997
7998     # and this is really numb...
7999     $pre580_help = "
8000 B<T>        Stack trace.
8001 B<s> [I<expr>]    Single step [in I<expr>].
8002 B<n> [I<expr>]    Next, steps over subroutine calls [in I<expr>].
8003 B<CR>>        Repeat last B<n> or B<s> command.
8004 B<r>        Return from current subroutine.
8005 B<c> [I<line>|I<sub>]    Continue; optionally inserts a one-time-only breakpoint
8006         at the specified position.
8007 B<l> I<min>B<+>I<incr>    List I<incr>+1 lines starting at I<min>.
8008 B<l> I<min>B<->I<max>    List lines I<min> through I<max>.
8009 B<l> I<line>        List single I<line>.
8010 B<l> I<subname>    List first window of lines from subroutine.
8011 B<l> I<\$var>        List first window of lines from subroutine referenced by I<\$var>.
8012 B<l>        List next window of lines.
8013 B<->        List previous window of lines.
8014 B<w> [I<line>]    List window around I<line>.
8015 B<.>        Return to the executed line.
8016 B<f> I<filename>    Switch to viewing I<filename>. File must be already loaded.
8017         I<filename> may be either the full name of the file, or a regular
8018         expression matching the full file name:
8019         B<f> I</home/me/foo.pl> and B<f> I<oo\\.> may access the same file.
8020         Evals (with saved bodies) are considered to be filenames:
8021         B<f> I<(eval 7)> and B<f> I<eval 7\\b> access the body of the 7th eval
8022         (in the order of execution).
8023 B</>I<pattern>B</>    Search forwards for I<pattern>; final B</> is optional.
8024 B<?>I<pattern>B<?>    Search backwards for I<pattern>; final B<?> is optional.
8025 B<L>        List all breakpoints and actions.
8026 B<S> [[B<!>]I<pattern>]    List subroutine names [not] matching I<pattern>.
8027 B<t> [I<n>]       Toggle trace mode (to max I<n> levels below current stack depth) .
8028 B<t> [I<n>] I<expr>        Trace through execution of I<expr>.
8029 B<b> [I<line>] [I<condition>]
8030         Set breakpoint; I<line> defaults to the current execution line;
8031         I<condition> breaks if it evaluates to true, defaults to '1'.
8032 B<b> I<subname> [I<condition>]
8033         Set breakpoint at first line of subroutine.
8034 B<b> I<\$var>        Set breakpoint at first line of subroutine referenced by I<\$var>.
8035 B<b> B<load> I<filename> Set breakpoint on 'require'ing the given file.
8036 B<b> B<postpone> I<subname> [I<condition>]
8037         Set breakpoint at first line of subroutine after
8038         it is compiled.
8039 B<b> B<compile> I<subname>
8040         Stop after the subroutine is compiled.
8041 B<d> [I<line>]    Delete the breakpoint for I<line>.
8042 B<D>        Delete all breakpoints.
8043 B<a> [I<line>] I<command>
8044         Set an action to be done before the I<line> is executed;
8045         I<line> defaults to the current execution line.
8046         Sequence is: check for breakpoint/watchpoint, print line
8047         if necessary, do action, prompt user if necessary,
8048         execute line.
8049 B<a> [I<line>]    Delete the action for I<line>.
8050 B<A>        Delete all actions.
8051 B<W> I<expr>        Add a global watch-expression.
8052 B<W>        Delete all watch-expressions.
8053 B<V> [I<pkg> [I<vars>]]    List some (default all) variables in package (default current).
8054         Use B<~>I<pattern> and B<!>I<pattern> for positive and negative regexps.
8055 B<X> [I<vars>]    Same as \"B<V> I<currentpackage> [I<vars>]\".
8056 B<x> I<expr>        Evals expression in list context, dumps the result.
8057 B<m> I<expr>        Evals expression in list context, prints methods callable
8058         on the first element of the result.
8059 B<m> I<class>        Prints methods callable via the given class.
8060
8061 B<<> ?            List Perl commands to run before each prompt.
8062 B<<> I<expr>        Define Perl command to run before each prompt.
8063 B<<<> I<expr>        Add to the list of Perl commands to run before each prompt.
8064 B<>> ?            List Perl commands to run after each prompt.
8065 B<>> I<expr>        Define Perl command to run after each prompt.
8066 B<>>B<>> I<expr>        Add to the list of Perl commands to run after each prompt.
8067 B<{> I<db_command>    Define debugger command to run before each prompt.
8068 B<{> ?            List debugger commands to run before each prompt.
8069 B<{{> I<db_command>    Add to the list of debugger commands to run before each prompt.
8070 B<$prc> I<number>    Redo a previous command (default previous command).
8071 B<$prc> I<-number>    Redo number'th-to-last command.
8072 B<$prc> I<pattern>    Redo last command that started with I<pattern>.
8073         See 'B<O> I<recallCommand>' too.
8074 B<$psh$psh> I<cmd>      Run cmd in a subprocess (reads from DB::IN, writes to DB::OUT)"
8075       . (
8076         $rc eq $sh
8077         ? ""
8078         : "
8079 B<$psh> [I<cmd>]     Run I<cmd> in subshell (forces \"\$SHELL -c 'cmd'\")."
8080       ) . "
8081         See 'B<O> I<shellBang>' too.
8082 B<source> I<file>        Execute I<file> containing debugger commands (may nest).
8083 B<H> I<-number>    Display last number commands (default all).
8084 B<p> I<expr>        Same as \"I<print {DB::OUT} expr>\" in current package.
8085 B<|>I<dbcmd>        Run debugger command, piping DB::OUT to current pager.
8086 B<||>I<dbcmd>        Same as B<|>I<dbcmd> but DB::OUT is temporarilly select()ed as well.
8087 B<\=> [I<alias> I<value>]    Define a command alias, or list current aliases.
8088 I<command>        Execute as a perl statement in current package.
8089 B<v>        Show versions of loaded modules.
8090 B<R>        Pure-man-restart of debugger, some of debugger state
8091         and command-line options may be lost.
8092         Currently the following settings are preserved:
8093         history, breakpoints and actions, debugger B<O>ptions
8094         and the following command-line options: I<-w>, I<-I>, I<-e>.
8095
8096 B<O> [I<opt>] ...    Set boolean option to true
8097 B<O> [I<opt>B<?>]    Query options
8098 B<O> [I<opt>B<=>I<val>] [I<opt>=B<\">I<val>B<\">] ...
8099         Set options.  Use quotes if spaces in value.
8100     I<recallCommand>, I<ShellBang>    chars used to recall command or spawn shell;
8101     I<pager>            program for output of \"|cmd\";
8102     I<tkRunning>            run Tk while prompting (with ReadLine);
8103     I<signalLevel> I<warnLevel> I<dieLevel>    level of verbosity;
8104     I<inhibit_exit>        Allows stepping off the end of the script.
8105     I<ImmediateStop>        Debugger should stop as early as possible.
8106     I<RemotePort>            Remote hostname:port for remote debugging
8107   The following options affect what happens with B<V>, B<X>, and B<x> commands:
8108     I<arrayDepth>, I<hashDepth>     print only first N elements ('' for all);
8109     I<compactDump>, I<veryCompact>     change style of array and hash dump;
8110     I<globPrint>             whether to print contents of globs;
8111     I<DumpDBFiles>         dump arrays holding debugged files;
8112     I<DumpPackages>         dump symbol tables of packages;
8113     I<DumpReused>             dump contents of \"reused\" addresses;
8114     I<quote>, I<HighBit>, I<undefPrint>     change style of string dump;
8115     I<bareStringify>         Do not print the overload-stringified value;
8116   Other options include:
8117     I<PrintRet>        affects printing of return value after B<r> command,
8118     I<frame>        affects printing messages on subroutine entry/exit.
8119     I<AutoTrace>    affects printing messages on possible breaking points.
8120     I<maxTraceLen>    gives max length of evals/args listed in stack trace.
8121     I<ornaments>     affects screen appearance of the command line.
8122     I<CreateTTY>     bits control attempts to create a new TTY on events:
8123             1: on fork()    2: debugger is started inside debugger
8124             4: on startup
8125     During startup options are initialized from \$ENV{PERLDB_OPTS}.
8126     You can put additional initialization options I<TTY>, I<noTTY>,
8127     I<ReadLine>, I<NonStop>, and I<RemotePort> there (or use
8128     B<R> after you set them).
8129
8130 B<q> or B<^D>        Quit. Set B<\$DB::finished = 0> to debug global destruction.
8131 B<h> [I<db_command>]    Get help [on a specific debugger command], enter B<|h> to page.
8132 B<h h>        Summary of debugger commands.
8133 B<$doccmd> I<manpage>    Runs the external doc viewer B<$doccmd> command on the
8134         named Perl I<manpage>, or on B<$doccmd> itself if omitted.
8135         Set B<\$DB::doccmd> to change viewer.
8136
8137 Type '|h' for a paged display if this was too hard to read.
8138
8139 ";    # Fix balance of vi % matching: }}}}
8140
8141     #  note: tabs in the following section are not-so-helpful
8142     $pre580_summary = <<"END_SUM";
8143 I<List/search source lines:>               I<Control script execution:>
8144   B<l> [I<ln>|I<sub>]  List source code            B<T>           Stack trace
8145   B<-> or B<.>      List previous/current line  B<s> [I<expr>]    Single step [in expr]
8146   B<w> [I<line>]    List around line            B<n> [I<expr>]    Next, steps over subs
8147   B<f> I<filename>  View source in file         <B<CR>/B<Enter>>  Repeat last B<n> or B<s>
8148   B</>I<pattern>B</> B<?>I<patt>B<?>   Search forw/backw    B<r>           Return from subroutine
8149   B<v>           Show versions of modules    B<c> [I<ln>|I<sub>]  Continue until position
8150 I<Debugger controls:>                        B<L>           List break/watch/actions
8151   B<O> [...]     Set debugger options        B<t> [I<expr>]    Toggle trace [trace expr]
8152   B<<>[B<<>]|B<{>[B<{>]|B<>>[B<>>] [I<cmd>] Do pre/post-prompt B<b> [I<ln>|I<event>|I<sub>] [I<cnd>] Set breakpoint
8153   B<$prc> [I<N>|I<pat>]   Redo a previous command     B<d> [I<ln>] or B<D> Delete a/all breakpoints
8154   B<H> [I<-num>]    Display last num commands   B<a> [I<ln>] I<cmd>  Do cmd before line
8155   B<=> [I<a> I<val>]   Define/list an alias        B<W> I<expr>      Add a watch expression
8156   B<h> [I<db_cmd>]  Get help on command         B<A> or B<W>      Delete all actions/watch
8157   B<|>[B<|>]I<db_cmd>  Send output to pager        B<$psh>\[B<$psh>\] I<syscmd> Run cmd in a subprocess
8158   B<q> or B<^D>     Quit                        B<R>           Attempt a restart
8159 I<Data Examination:>     B<expr>     Execute perl code, also see: B<s>,B<n>,B<t> I<expr>
8160   B<x>|B<m> I<expr>       Evals expr in list context, dumps the result or lists methods.
8161   B<p> I<expr>         Print expression (uses script's current package).
8162   B<S> [[B<!>]I<pat>]     List subroutine names [not] matching pattern
8163   B<V> [I<Pk> [I<Vars>]]  List Variables in Package.  Vars can be ~pattern or !pattern.
8164   B<X> [I<Vars>]       Same as \"B<V> I<current_package> [I<Vars>]\".
8165   B<y> [I<n> [I<Vars>]]   List lexicals in higher scope <n>.  Vars same as B<V>.
8166 For more help, type B<h> I<cmd_letter>, or run B<$doccmd perldebug> for all docs.
8167 END_SUM
8168
8169     # ')}}; # Fix balance of vi % matching
8170
8171 } ## end sub sethelp
8172
8173 =head2 C<print_help()>
8174
8175 Most of what C<print_help> does is just text formatting. It finds the
8176 C<B> and C<I> ornaments, cleans them off, and substitutes the proper
8177 terminal control characters to simulate them (courtesy of
8178 C<Term::ReadLine::TermCap>).
8179
8180 =cut
8181
8182 sub print_help {
8183     my $help_str = shift;
8184
8185     # Restore proper alignment destroyed by eeevil I<> and B<>
8186     # ornaments: A pox on both their houses!
8187     #
8188     # A help command will have everything up to and including
8189     # the first tab sequence padded into a field 16 (or if indented 20)
8190     # wide.  If it's wider than that, an extra space will be added.
8191     $help_str =~ s{
8192         ^                       # only matters at start of line
8193           ( \040{4} | \t )*     # some subcommands are indented
8194           ( < ?                 # so <CR> works
8195             [BI] < [^\t\n] + )  # find an eeevil ornament
8196           ( \t+ )               # original separation, discarded
8197           ( .* )                # this will now start (no earlier) than
8198                                 # column 16
8199     } {
8200         my($leadwhite, $command, $midwhite, $text) = ($1, $2, $3, $4);
8201         my $clean = $command;
8202         $clean =~ s/[BI]<([^>]*)>/$1/g;
8203
8204         # replace with this whole string:
8205         ($leadwhite ? " " x 4 : "")
8206       . $command
8207       . ((" " x (16 + ($leadwhite ? 4 : 0) - length($clean))) || " ")
8208       . $text;
8209
8210     }mgex;
8211
8212     $help_str =~ s{                          # handle bold ornaments
8213        B < ( [^>] + | > ) >
8214     } {
8215           $Term::ReadLine::TermCap::rl_term_set[2]
8216         . $1
8217         . $Term::ReadLine::TermCap::rl_term_set[3]
8218     }gex;
8219
8220     $help_str =~ s{                         # handle italic ornaments
8221        I < ( [^>] + | > ) >
8222     } {
8223           $Term::ReadLine::TermCap::rl_term_set[0]
8224         . $1
8225         . $Term::ReadLine::TermCap::rl_term_set[1]
8226     }gex;
8227
8228     local $\ = '';
8229     print {$OUT} $help_str;
8230
8231     return;
8232 } ## end sub print_help
8233
8234 =head2 C<fix_less>
8235
8236 This routine does a lot of gyrations to be sure that the pager is C<less>.
8237 It checks for C<less> masquerading as C<more> and records the result in
8238 C<$fixed_less> so we don't have to go through doing the stats again.
8239
8240 =cut
8241
8242 use vars qw($fixed_less);
8243
8244 sub _calc_is_less {
8245     if ($pager =~ /\bless\b/)
8246     {
8247         return 1;
8248     }
8249     elsif ($pager =~ /\bmore\b/)
8250     {
8251         # Nope, set to more. See what's out there.
8252         my @st_more = stat('/usr/bin/more');
8253         my @st_less = stat('/usr/bin/less');
8254
8255         # is it really less, pretending to be more?
8256         return (
8257             @st_more
8258             && @st_less
8259             && $st_more[0] == $st_less[0]
8260             && $st_more[1] == $st_less[1]
8261         );
8262     }
8263     else {
8264         return;
8265     }
8266 }
8267
8268 sub fix_less {
8269
8270     # We already know if this is set.
8271     return if $fixed_less;
8272
8273     # changes environment!
8274     # 'r' added so we don't do (slow) stats again.
8275     $fixed_less = 1 if _calc_is_less();
8276
8277     return;
8278 } ## end sub fix_less
8279
8280 =head1 DIE AND WARN MANAGEMENT
8281
8282 =head2 C<diesignal>
8283
8284 C<diesignal> is a just-drop-dead C<die> handler. It's most useful when trying
8285 to debug a debugger problem.
8286
8287 It does its best to report the error that occurred, and then forces the
8288 program, debugger, and everything to die.
8289
8290 =cut
8291
8292 sub diesignal {
8293
8294     # No entry/exit messages.
8295     local $frame = 0;
8296
8297     # No return value prints.
8298     local $doret = -2;
8299
8300     # set the abort signal handling to the default (just terminate).
8301     $SIG{'ABRT'} = 'DEFAULT';
8302
8303     # If we enter the signal handler recursively, kill myself with an
8304     # abort signal (so we just terminate).
8305     kill 'ABRT', $$ if $panic++;
8306
8307     # If we can show detailed info, do so.
8308     if ( defined &Carp::longmess ) {
8309
8310         # Don't recursively enter the warn handler, since we're carping.
8311         local $SIG{__WARN__} = '';
8312
8313         # Skip two levels before reporting traceback: we're skipping
8314         # mydie and confess.
8315         local $Carp::CarpLevel = 2;    # mydie + confess
8316
8317         # Tell us all about it.
8318         _db_warn( Carp::longmess("Signal @_") );
8319     }
8320
8321     # No Carp. Tell us about the signal as best we can.
8322     else {
8323         local $\ = '';
8324         print $DB::OUT "Got signal @_\n";
8325     }
8326
8327     # Drop dead.
8328     kill 'ABRT', $$;
8329 } ## end sub diesignal
8330
8331 =head2 C<dbwarn>
8332
8333 The debugger's own default C<$SIG{__WARN__}> handler. We load C<Carp> to
8334 be able to get a stack trace, and output the warning message vi C<DB::dbwarn()>.
8335
8336 =cut
8337
8338 sub dbwarn {
8339
8340     # No entry/exit trace.
8341     local $frame = 0;
8342
8343     # No return value printing.
8344     local $doret = -2;
8345
8346     # Turn off warn and die handling to prevent recursive entries to this
8347     # routine.
8348     local $SIG{__WARN__} = '';
8349     local $SIG{__DIE__}  = '';
8350
8351     # Load Carp if we can. If $^S is false (current thing being compiled isn't
8352     # done yet), we may not be able to do a require.
8353     eval { require Carp }
8354       if defined $^S;    # If error/warning during compilation,
8355                          # require may be broken.
8356
8357     # Use the core warn() unless Carp loaded OK.
8358     CORE::warn( @_,
8359         "\nCannot print stack trace, load with -MCarp option to see stack" ),
8360       return
8361       unless defined &Carp::longmess;
8362
8363     # Save the current values of $single and $trace, and then turn them off.
8364     my ( $mysingle, $mytrace ) = ( $single, $trace );
8365     $single = 0;
8366     $trace  = 0;
8367
8368     # We can call Carp::longmess without its being "debugged" (which we
8369     # don't want - we just want to use it!). Capture this for later.
8370     my $mess = Carp::longmess(@_);
8371
8372     # Restore $single and $trace to their original values.
8373     ( $single, $trace ) = ( $mysingle, $mytrace );
8374
8375     # Use the debugger's own special way of printing warnings to print
8376     # the stack trace message.
8377     _db_warn($mess);
8378 } ## end sub dbwarn
8379
8380 =head2 C<dbdie>
8381
8382 The debugger's own C<$SIG{__DIE__}> handler. Handles providing a stack trace
8383 by loading C<Carp> and calling C<Carp::longmess()> to get it. We turn off
8384 single stepping and tracing during the call to C<Carp::longmess> to avoid
8385 debugging it - we just want to use it.
8386
8387 If C<dieLevel> is zero, we let the program being debugged handle the
8388 exceptions. If it's 1, you get backtraces for any exception. If it's 2,
8389 the debugger takes over all exception handling, printing a backtrace and
8390 displaying the exception via its C<dbwarn()> routine.
8391
8392 =cut
8393
8394 sub dbdie {
8395     local $frame         = 0;
8396     local $doret         = -2;
8397     local $SIG{__DIE__}  = '';
8398     local $SIG{__WARN__} = '';
8399     if ( $dieLevel > 2 ) {
8400         local $SIG{__WARN__} = \&dbwarn;
8401         _db_warn(@_);    # Yell no matter what
8402         return;
8403     }
8404     if ( $dieLevel < 2 ) {
8405         die @_ if $^S;    # in eval propagate
8406     }
8407
8408     # The code used to check $^S to see if compilation of the current thing
8409     # hadn't finished. We don't do it anymore, figuring eval is pretty stable.
8410     eval { require Carp };
8411
8412     die( @_,
8413         "\nCannot print stack trace, load with -MCarp option to see stack" )
8414       unless defined &Carp::longmess;
8415
8416     # We do not want to debug this chunk (automatic disabling works
8417     # inside DB::DB, but not in Carp). Save $single and $trace, turn them off,
8418     # get the stack trace from Carp::longmess (if possible), restore $signal
8419     # and $trace, and then die with the stack trace.
8420     my ( $mysingle, $mytrace ) = ( $single, $trace );
8421     $single = 0;
8422     $trace  = 0;
8423     my $mess = "@_";
8424     {
8425
8426         package Carp;    # Do not include us in the list
8427         eval { $mess = Carp::longmess(@_); };
8428     }
8429     ( $single, $trace ) = ( $mysingle, $mytrace );
8430     die $mess;
8431 } ## end sub dbdie
8432
8433 =head2 C<warnlevel()>
8434
8435 Set the C<$DB::warnLevel> variable that stores the value of the
8436 C<warnLevel> option. Calling C<warnLevel()> with a positive value
8437 results in the debugger taking over all warning handlers. Setting
8438 C<warnLevel> to zero leaves any warning handlers set up by the program
8439 being debugged in place.
8440
8441 =cut
8442
8443 sub warnLevel {
8444     if (@_) {
8445         my $prevwarn = $SIG{__WARN__} unless $warnLevel;
8446         $warnLevel = shift;
8447         if ($warnLevel) {
8448             $SIG{__WARN__} = \&DB::dbwarn;
8449         }
8450         elsif ($prevwarn) {
8451             $SIG{__WARN__} = $prevwarn;
8452         } else {
8453             undef $SIG{__WARN__};
8454         }
8455     } ## end if (@_)
8456     $warnLevel;
8457 } ## end sub warnLevel
8458
8459 =head2 C<dielevel>
8460
8461 Similar to C<warnLevel>. Non-zero values for C<dieLevel> result in the
8462 C<DB::dbdie()> function overriding any other C<die()> handler. Setting it to
8463 zero lets you use your own C<die()> handler.
8464
8465 =cut
8466
8467 sub dieLevel {
8468     local $\ = '';
8469     if (@_) {
8470         my $prevdie = $SIG{__DIE__} unless $dieLevel;
8471         $dieLevel = shift;
8472         if ($dieLevel) {
8473
8474             # Always set it to dbdie() for non-zero values.
8475             $SIG{__DIE__} = \&DB::dbdie;    # if $dieLevel < 2;
8476
8477             # No longer exists, so don't try  to use it.
8478             #$SIG{__DIE__} = \&DB::diehard if $dieLevel >= 2;
8479
8480             # If we've finished initialization, mention that stack dumps
8481             # are enabled, If dieLevel is 1, we won't stack dump if we die
8482             # in an eval().
8483             print $OUT "Stack dump during die enabled",
8484               ( $dieLevel == 1 ? " outside of evals" : "" ), ".\n"
8485               if $I_m_init;
8486
8487             # XXX This is probably obsolete, given that diehard() is gone.
8488             print $OUT "Dump printed too.\n" if $dieLevel > 2;
8489         } ## end if ($dieLevel)
8490
8491         # Put the old one back if there was one.
8492         elsif ($prevdie) {
8493             $SIG{__DIE__} = $prevdie;
8494             print $OUT "Default die handler restored.\n";
8495         } else {
8496             undef $SIG{__DIE__};
8497             print $OUT "Die handler removed.\n";
8498         }
8499     } ## end if (@_)
8500     $dieLevel;
8501 } ## end sub dieLevel
8502
8503 =head2 C<signalLevel>
8504
8505 Number three in a series: set C<signalLevel> to zero to keep your own
8506 signal handler for C<SIGSEGV> and/or C<SIGBUS>. Otherwise, the debugger
8507 takes over and handles them with C<DB::diesignal()>.
8508
8509 =cut
8510
8511 sub signalLevel {
8512     if (@_) {
8513         my $prevsegv = $SIG{SEGV} unless $signalLevel;
8514         my $prevbus  = $SIG{BUS}  unless $signalLevel;
8515         $signalLevel = shift;
8516         if ($signalLevel) {
8517             $SIG{SEGV} = \&DB::diesignal;
8518             $SIG{BUS}  = \&DB::diesignal;
8519         }
8520         else {
8521             $SIG{SEGV} = $prevsegv;
8522             $SIG{BUS}  = $prevbus;
8523         }
8524     } ## end if (@_)
8525     $signalLevel;
8526 } ## end sub signalLevel
8527
8528 =head1 SUBROUTINE DECODING SUPPORT
8529
8530 These subroutines are used during the C<x> and C<X> commands to try to
8531 produce as much information as possible about a code reference. They use
8532 L<Devel::Peek> to try to find the glob in which this code reference lives
8533 (if it does) - this allows us to actually code references which correspond
8534 to named subroutines (including those aliased via glob assignment).
8535
8536 =head2 C<CvGV_name()>
8537
8538 Wrapper for C<CvGV_name_or_bust>; tries to get the name of a reference
8539 via that routine. If this fails, return the reference again (when the
8540 reference is stringified, it'll come out as C<SOMETHING(0x...)>).
8541
8542 =cut
8543
8544 sub CvGV_name {
8545     my $in   = shift;
8546     my $name = CvGV_name_or_bust($in);
8547     defined $name ? $name : $in;
8548 }
8549
8550 =head2 C<CvGV_name_or_bust> I<coderef>
8551
8552 Calls L<Devel::Peek> to try to find the glob the ref lives in; returns
8553 C<undef> if L<Devel::Peek> can't be loaded, or if C<Devel::Peek::CvGV> can't
8554 find a glob for this ref.
8555
8556 Returns C<< I<package>::I<glob name> >> if the code ref is found in a glob.
8557
8558 =cut
8559
8560 use vars qw($skipCvGV);
8561
8562 sub CvGV_name_or_bust {
8563     my $in = shift;
8564     return if $skipCvGV;    # Backdoor to avoid problems if XS broken...
8565     return unless ref $in;
8566     $in = \&$in;            # Hard reference...
8567     eval { require Devel::Peek; 1 } or return;
8568     my $gv = Devel::Peek::CvGV($in) or return;
8569     *$gv{PACKAGE} . '::' . *$gv{NAME};
8570 } ## end sub CvGV_name_or_bust
8571
8572 =head2 C<find_sub>
8573
8574 A utility routine used in various places; finds the file where a subroutine
8575 was defined, and returns that filename and a line-number range.
8576
8577 Tries to use C<@sub> first; if it can't find it there, it tries building a
8578 reference to the subroutine and uses C<CvGV_name_or_bust> to locate it,
8579 loading it into C<@sub> as a side effect (XXX I think). If it can't find it
8580 this way, it brute-force searches C<%sub>, checking for identical references.
8581
8582 =cut
8583
8584 sub _find_sub_helper {
8585     my $subr = shift;
8586
8587     return unless defined &$subr;
8588     my $name = CvGV_name_or_bust($subr);
8589     my $data;
8590     $data = $sub{$name} if defined $name;
8591     return $data if defined $data;
8592
8593     # Old stupid way...
8594     $subr = \&$subr;    # Hard reference
8595     my $s;
8596     for ( keys %sub ) {
8597         $s = $_, last if $subr eq \&$_;
8598     }
8599     if ($s)
8600     {
8601         return $sub{$s};
8602     }
8603     else
8604     {
8605         return;
8606     }
8607
8608 }
8609
8610 sub find_sub {
8611     my $subr = shift;
8612     return ( $sub{$subr} || _find_sub_helper($subr) );
8613 } ## end sub find_sub
8614
8615 =head2 C<methods>
8616
8617 A subroutine that uses the utility function C<methods_via> to find all the
8618 methods in the class corresponding to the current reference and in
8619 C<UNIVERSAL>.
8620
8621 =cut
8622
8623 use vars qw(%seen);
8624
8625 sub methods {
8626
8627     # Figure out the class - either this is the class or it's a reference
8628     # to something blessed into that class.
8629     my $class = shift;
8630     $class = ref $class if ref $class;
8631
8632     local %seen;
8633
8634     # Show the methods that this class has.
8635     methods_via( $class, '', 1 );
8636
8637     # Show the methods that UNIVERSAL has.
8638     methods_via( 'UNIVERSAL', 'UNIVERSAL', 0 );
8639 } ## end sub methods
8640
8641 =head2 C<methods_via($class, $prefix, $crawl_upward)>
8642
8643 C<methods_via> does the work of crawling up the C<@ISA> tree and reporting
8644 all the parent class methods. C<$class> is the name of the next class to
8645 try; C<$prefix> is the message prefix, which gets built up as we go up the
8646 C<@ISA> tree to show parentage; C<$crawl_upward> is 1 if we should try to go
8647 higher in the C<@ISA> tree, 0 if we should stop.
8648
8649 =cut
8650
8651 sub methods_via {
8652
8653     # If we've processed this class already, just quit.
8654     my $class = shift;
8655     return if $seen{$class}++;
8656
8657     # This is a package that is contributing the methods we're about to print.
8658     my $prefix  = shift;
8659     my $prepend = $prefix ? "via $prefix: " : '';
8660     my @to_print;
8661
8662     # Extract from all the symbols in this class.
8663     my $class_ref = do { no strict "refs"; \%{$class . '::'} };
8664     while (my ($name, $glob) = each %$class_ref) {
8665         # references directly in the symbol table are Proxy Constant
8666         # Subroutines, and are by their very nature defined
8667         # Otherwise, check if the thing is a typeglob, and if it is, it decays
8668         # to a subroutine reference, which can be tested by defined.
8669         # $glob might also be the value -1  (from sub foo;)
8670         # or (say) '$$' (from sub foo ($$);)
8671         # \$glob will be SCALAR in both cases.
8672         if ((ref $glob || ($glob && ref \$glob eq 'GLOB' && defined &$glob))
8673             && !$seen{$name}++) {
8674             push @to_print, "$prepend$name\n";
8675         }
8676     }
8677
8678     {
8679         local $\ = '';
8680         local $, = '';
8681         print $DB::OUT $_ foreach sort @to_print;
8682     }
8683
8684     # If the $crawl_upward argument is false, just quit here.
8685     return unless shift;
8686
8687     # $crawl_upward true: keep going up the tree.
8688     # Find all the classes this one is a subclass of.
8689     my $class_ISA_ref = do { no strict "refs"; \@{"${class}::ISA"} };
8690     for my $name ( @$class_ISA_ref ) {
8691
8692         # Set up the new prefix.
8693         $prepend = $prefix ? $prefix . " -> $name" : $name;
8694
8695         # Crawl up the tree and keep trying to crawl up.
8696         methods_via( $name, $prepend, 1 );
8697     }
8698 } ## end sub methods_via
8699
8700 =head2 C<setman> - figure out which command to use to show documentation
8701
8702 Just checks the contents of C<$^O> and sets the C<$doccmd> global accordingly.
8703
8704 =cut
8705
8706 sub setman {
8707     $doccmd = $^O !~ /^(?:MSWin32|VMS|os2|dos|amigaos|riscos|NetWare)\z/s
8708       ? "man"         # O Happy Day!
8709       : "perldoc";    # Alas, poor unfortunates
8710 } ## end sub setman
8711
8712 =head2 C<runman> - run the appropriate command to show documentation
8713
8714 Accepts a man page name; runs the appropriate command to display it (set up
8715 during debugger initialization). Uses C<_db_system()> to avoid mucking up the
8716 program's STDIN and STDOUT.
8717
8718 =cut
8719
8720 my %_is_in_pods = (map { $_ => 1 }
8721     qw(
8722     5004delta
8723     5005delta
8724     561delta
8725     56delta
8726     570delta
8727     571delta
8728     572delta
8729     573delta
8730     58delta
8731     581delta
8732     582delta
8733     583delta
8734     584delta
8735     590delta
8736     591delta
8737     592delta
8738     aix
8739     amiga
8740     apio
8741     api
8742     artistic
8743     beos
8744     book
8745     boot
8746     bot
8747     bs2000
8748     call
8749     ce
8750     cheat
8751     clib
8752     cn
8753     compile
8754     cygwin
8755     data
8756     dbmfilter
8757     debguts
8758     debtut
8759     debug
8760     delta
8761     dgux
8762     diag
8763     doc
8764     dos
8765     dsc
8766     ebcdic
8767     embed
8768     epoc
8769     faq1
8770     faq2
8771     faq3
8772     faq4
8773     faq5
8774     faq6
8775     faq7
8776     faq8
8777     faq9
8778     faq
8779     filter
8780     fork
8781     form
8782     freebsd
8783     func
8784     gpl
8785     guts
8786     hack
8787     hist
8788     hpux
8789     hurd
8790     intern
8791     intro
8792     iol
8793     ipc
8794     irix
8795     jp
8796     ko
8797     lexwarn
8798     locale
8799     lol
8800     macos
8801     macosx
8802     modinstall
8803     modlib
8804     mod
8805     modstyle
8806     netware
8807     newmod
8808     number
8809     obj
8810     opentut
8811     op
8812     os2
8813     os390
8814     os400
8815     packtut
8816     plan9
8817     pod
8818     podspec
8819     port
8820     qnx
8821     ref
8822     reftut
8823     re
8824     requick
8825     reref
8826     retut
8827     run
8828     sec
8829     solaris
8830     style
8831     sub
8832     syn
8833     thrtut
8834     tie
8835     toc
8836     todo
8837     tooc
8838     toot
8839     trap
8840     tru64
8841     tw
8842     unicode
8843     uniintro
8844     util
8845     uts
8846     var
8847     vms
8848     vos
8849     win32
8850     xs
8851     xstut
8852     )
8853 );
8854
8855 sub runman {
8856     my $page = shift;
8857     unless ($page) {
8858         _db_system("$doccmd $doccmd");
8859         return;
8860     }
8861
8862     # this way user can override, like with $doccmd="man -Mwhatever"
8863     # or even just "man " to disable the path check.
8864     unless ( $doccmd eq 'man' ) {
8865         _db_system("$doccmd $page");
8866         return;
8867     }
8868
8869     $page = 'perl' if lc($page) eq 'help';
8870
8871     require Config;
8872     my $man1dir = $Config::Config{'man1dir'};
8873     my $man3dir = $Config::Config{'man3dir'};
8874     for ( $man1dir, $man3dir ) { s#/[^/]*\z## if /\S/ }
8875     my $manpath = '';
8876     $manpath .= "$man1dir:" if $man1dir =~ /\S/;
8877     $manpath .= "$man3dir:" if $man3dir =~ /\S/ && $man1dir ne $man3dir;
8878     chop $manpath if $manpath;
8879
8880     # harmless if missing, I figure
8881     my $oldpath = $ENV{MANPATH};
8882     $ENV{MANPATH} = $manpath if $manpath;
8883     my $nopathopt = $^O =~ /dunno what goes here/;
8884     if (
8885         CORE::system(
8886             $doccmd,
8887
8888             # I just *know* there are men without -M
8889             ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8890             split ' ', $page
8891         )
8892       )
8893     {
8894         unless ( $page =~ /^perl\w/ ) {
8895 # do it this way because its easier to slurp in to keep up to date - clunky though.
8896             if (exists($_is_in_pods{$page})) {
8897                 CORE::system( $doccmd,
8898                     ( ( $manpath && !$nopathopt ) ? ( "-M", $manpath ) : () ),
8899                     "perl$page" );
8900             }
8901         }
8902     } ## end if (CORE::system($doccmd...
8903     if ( defined $oldpath ) {
8904         $ENV{MANPATH} = $manpath;
8905     }
8906     else {
8907         delete $ENV{MANPATH};
8908     }
8909 } ## end sub runman
8910
8911 #use Carp;                          # This did break, left for debugging
8912
8913 =head1 DEBUGGER INITIALIZATION - THE SECOND BEGIN BLOCK
8914
8915 Because of the way the debugger interface to the Perl core is designed, any
8916 debugger package globals that C<DB::sub()> requires have to be defined before
8917 any subroutines can be called. These are defined in the second C<BEGIN> block.
8918
8919 This block sets things up so that (basically) the world is sane
8920 before the debugger starts executing. We set up various variables that the
8921 debugger has to have set up before the Perl core starts running:
8922
8923 =over 4
8924
8925 =item *
8926
8927 The debugger's own filehandles (copies of STD and STDOUT for now).
8928
8929 =item *
8930
8931 Characters for shell escapes, the recall command, and the history command.
8932
8933 =item *
8934
8935 The maximum recursion depth.
8936
8937 =item *
8938
8939 The size of a C<w> command's window.
8940
8941 =item *
8942
8943 The before-this-line context to be printed in a C<v> (view a window around this line) command.
8944
8945 =item *
8946
8947 The fact that we're not in a sub at all right now.
8948
8949 =item *
8950
8951 The default SIGINT handler for the debugger.
8952
8953 =item *
8954
8955 The appropriate value of the flag in C<$^D> that says the debugger is running
8956
8957 =item *
8958
8959 The current debugger recursion level
8960
8961 =item *
8962
8963 The list of postponed items and the C<$single> stack (XXX define this)
8964
8965 =item *
8966
8967 That we want no return values and no subroutine entry/exit trace.
8968
8969 =back
8970
8971 =cut
8972
8973 # The following BEGIN is very handy if debugger goes havoc, debugging debugger?
8974
8975 use vars qw($db_stop);
8976
8977 BEGIN {    # This does not compile, alas. (XXX eh?)
8978     $IN  = \*STDIN;     # For bugs before DB::OUT has been opened
8979     $OUT = \*STDERR;    # For errors before DB::OUT has been opened
8980
8981     # Define characters used by command parsing.
8982     $sh       = '!';      # Shell escape (does not work)
8983     $rc       = ',';      # Recall command (does not work)
8984     @hist     = ('?');    # Show history (does not work)
8985     @truehist = ();       # Can be saved for replay (per session)
8986
8987     # This defines the point at which you get the 'deep recursion'
8988     # warning. It MUST be defined or the debugger will not load.
8989     $deep = 100;
8990
8991     # Number of lines around the current one that are shown in the
8992     # 'w' command.
8993     $window = 10;
8994
8995     # How much before-the-current-line context the 'v' command should
8996     # use in calculating the start of the window it will display.
8997     $preview = 3;
8998
8999     # We're not in any sub yet, but we need this to be a defined value.
9000     $sub = '';
9001
9002     # Set up the debugger's interrupt handler. It simply sets a flag
9003     # ($signal) that DB::DB() will check before each command is executed.
9004     $SIG{INT} = \&DB::catch;
9005
9006     # The following lines supposedly, if uncommented, allow the debugger to
9007     # debug itself. Perhaps we can try that someday.
9008     # This may be enabled to debug debugger:
9009     #$warnLevel = 1 unless defined $warnLevel;
9010     #$dieLevel = 1 unless defined $dieLevel;
9011     #$signalLevel = 1 unless defined $signalLevel;
9012
9013     # This is the flag that says "a debugger is running, please call
9014     # DB::DB and DB::sub". We will turn it on forcibly before we try to
9015     # execute anything in the user's context, because we always want to
9016     # get control back.
9017     $db_stop = 0;          # Compiler warning ...
9018     $db_stop = 1 << 30;    # ... because this is only used in an eval() later.
9019
9020     # This variable records how many levels we're nested in debugging. Used
9021     # Used in the debugger prompt, and in determining whether it's all over or
9022     # not.
9023     $level = 0;            # Level of recursive debugging
9024
9025     # "Triggers bug (?) in perl if we postpone this until runtime."
9026     # XXX No details on this yet, or whether we should fix the bug instead
9027     # of work around it. Stay tuned.
9028     @stack = (0);
9029
9030     # Used to track the current stack depth using the auto-stacked-variable
9031     # trick.
9032     $stack_depth = 0;      # Localized repeatedly; simple way to track $#stack
9033
9034     # Don't print return values on exiting a subroutine.
9035     $doret = -2;
9036
9037     # No extry/exit tracing.
9038     $frame = 0;
9039
9040 } ## end BEGIN
9041
9042 BEGIN { $^W = $ini_warn; }    # Switch warnings back
9043
9044 =head1 READLINE SUPPORT - COMPLETION FUNCTION
9045
9046 =head2 db_complete
9047
9048 C<readline> support - adds command completion to basic C<readline>.
9049
9050 Returns a list of possible completions to C<readline> when invoked. C<readline>
9051 will print the longest common substring following the text already entered.
9052
9053 If there is only a single possible completion, C<readline> will use it in full.
9054
9055 This code uses C<map> and C<grep> heavily to create lists of possible
9056 completion. Think LISP in this section.
9057
9058 =cut
9059
9060 sub db_complete {
9061
9062     # Specific code for b c l V m f O, &blah, $blah, @blah, %blah
9063     # $text is the text to be completed.
9064     # $line is the incoming line typed by the user.
9065     # $start is the start of the text to be completed in the incoming line.
9066     my ( $text, $line, $start ) = @_;
9067
9068     # Save the initial text.
9069     # The search pattern is current package, ::, extract the next qualifier
9070     # Prefix and pack are set to undef.
9071     my ( $itext, $search, $prefix, $pack ) =
9072       ( $text, "^\Q${package}::\E([^:]+)\$" );
9073
9074 =head3 C<b postpone|compile>
9075
9076 =over 4
9077
9078 =item *
9079
9080 Find all the subroutines that might match in this package
9081
9082 =item *
9083
9084 Add C<postpone>, C<load>, and C<compile> as possibles (we may be completing the keyword itself)
9085
9086 =item *
9087
9088 Include all the rest of the subs that are known
9089
9090 =item *
9091
9092 C<grep> out the ones that match the text we have so far
9093
9094 =item *
9095
9096 Return this as the list of possible completions
9097
9098 =back
9099
9100 =cut
9101
9102     return sort grep /^\Q$text/, ( keys %sub ),
9103       qw(postpone load compile),    # subroutines
9104       ( map { /$search/ ? ($1) : () } keys %sub )
9105       if ( substr $line, 0, $start ) =~ /^\|*[blc]\s+((postpone|compile)\s+)?$/;
9106
9107 =head3 C<b load>
9108
9109 Get all the possible files from C<@INC> as it currently stands and
9110 select the ones that match the text so far.
9111
9112 =cut
9113
9114     return sort grep /^\Q$text/, values %INC    # files
9115       if ( substr $line, 0, $start ) =~ /^\|*b\s+load\s+$/;
9116
9117 =head3  C<V> (list variable) and C<m> (list modules)
9118
9119 There are two entry points for these commands:
9120
9121 =head4 Unqualified package names
9122
9123 Get the top-level packages and grab everything that matches the text
9124 so far. For each match, recursively complete the partial packages to
9125 get all possible matching packages. Return this sorted list.
9126
9127 =cut
9128
9129     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9130       grep /^\Q$text/, map { /^(.*)::$/ ? ($1) : () } keys %::    # top-packages
9131       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/ and $text =~ /^\w*$/;
9132
9133 =head4 Qualified package names
9134
9135 Take a partially-qualified package and find all subpackages for it
9136 by getting all the subpackages for the package so far, matching all
9137 the subpackages against the text, and discarding all of them which
9138 start with 'main::'. Return this list.
9139
9140 =cut
9141
9142     return sort map { ( $_, db_complete( $_ . "::", "V ", 2 ) ) }
9143       grep !/^main::/, grep /^\Q$text/,
9144       map { /^(.*)::$/ ? ( $prefix . "::$1" ) : () }
9145       do { no strict 'refs'; keys %{ $prefix . '::' } }
9146       if ( substr $line, 0, $start ) =~ /^\|*[Vm]\s+$/
9147       and $text =~ /^(.*[^:])::?(\w*)$/
9148       and $prefix = $1;
9149
9150 =head3 C<f> - switch files
9151
9152 Here, we want to get a fully-qualified filename for the C<f> command.
9153 Possibilities are:
9154
9155 =over 4
9156
9157 =item 1. The original source file itself
9158
9159 =item 2. A file from C<@INC>
9160
9161 =item 3. An C<eval> (the debugger gets a C<(eval N)> fake file for each C<eval>).
9162
9163 =back
9164
9165 =cut
9166
9167     if ( $line =~ /^\|*f\s+(.*)/ ) {    # Loaded files
9168            # We might possibly want to switch to an eval (which has a "filename"
9169            # like '(eval 9)'), so we may need to clean up the completion text
9170            # before proceeding.
9171         $prefix = length($1) - length($text);
9172         $text   = $1;
9173
9174 =pod
9175
9176 Under the debugger, source files are represented as C<_E<lt>/fullpath/to/file>
9177 (C<eval>s are C<_E<lt>(eval NNN)>) keys in C<%main::>. We pull all of these
9178 out of C<%main::>, add the initial source file, and extract the ones that
9179 match the completion text so far.
9180
9181 =cut
9182
9183         return sort
9184           map { substr $_, 2 + $prefix } grep /^_<\Q$text/, ( keys %main:: ),
9185           $0;
9186     } ## end if ($line =~ /^\|*f\s+(.*)/)
9187
9188 =head3 Subroutine name completion
9189
9190 We look through all of the defined subs (the keys of C<%sub>) and
9191 return both all the possible matches to the subroutine name plus
9192 all the matches qualified to the current package.
9193
9194 =cut
9195
9196     if ( ( substr $text, 0, 1 ) eq '&' ) {    # subroutines
9197         $text = substr $text, 1;
9198         $prefix = "&";
9199         return sort map "$prefix$_", grep /^\Q$text/, ( keys %sub ),
9200           (
9201             map { /$search/ ? ($1) : () }
9202               keys %sub
9203           );
9204     } ## end if ((substr $text, 0, ...
9205
9206 =head3  Scalar, array, and hash completion: partially qualified package
9207
9208 Much like the above, except we have to do a little more cleanup:
9209
9210 =cut
9211
9212     if ( $text =~ /^[\$@%](.*)::(.*)/ ) {    # symbols in a package
9213
9214 =pod
9215
9216 =over 4
9217
9218 =item *
9219
9220 Determine the package that the symbol is in. Put it in C<::> (effectively C<main::>) if no package is specified.
9221
9222 =cut
9223
9224         $pack = ( $1 eq 'main' ? '' : $1 ) . '::';
9225
9226 =pod
9227
9228 =item *
9229
9230 Figure out the prefix vs. what needs completing.
9231
9232 =cut
9233
9234         $prefix = ( substr $text, 0, 1 ) . $1 . '::';
9235         $text   = $2;
9236
9237 =pod
9238
9239 =item *
9240
9241 Look through all the symbols in the package. C<grep> out all the possible hashes/arrays/scalars, and then C<grep> the possible matches out of those. C<map> the prefix onto all the possibilities.
9242
9243 =cut
9244
9245         my @out = do {
9246             no strict 'refs';
9247             map "$prefix$_", grep /^\Q$text/, grep /^_?[a-zA-Z]/,
9248             keys %$pack;
9249         };
9250
9251 =pod
9252
9253 =item *
9254
9255 If there's only one hit, and it's a package qualifier, and it's not equal to the initial text, re-complete it using the symbol we actually found.
9256
9257 =cut
9258
9259         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9260             return db_complete( $out[0], $line, $start );
9261         }
9262
9263         # Return the list of possibles.
9264         return sort @out;
9265
9266     } ## end if ($text =~ /^[\$@%](.*)::(.*)/)
9267
9268 =pod
9269
9270 =back
9271
9272 =head3 Symbol completion: current package or package C<main>.
9273
9274 =cut
9275
9276     if ( $text =~ /^[\$@%]/ ) {    # symbols (in $package + packages in main)
9277 =pod
9278
9279 =over 4
9280
9281 =item *
9282
9283 If it's C<main>, delete main to just get C<::> leading.
9284
9285 =cut
9286
9287         $pack = ( $package eq 'main' ? '' : $package ) . '::';
9288
9289 =pod
9290
9291 =item *
9292
9293 We set the prefix to the item's sigil, and trim off the sigil to get the text to be completed.
9294
9295 =cut
9296
9297         $prefix = substr $text, 0, 1;
9298         $text   = substr $text, 1;
9299
9300         my @out;
9301
9302 =pod
9303
9304 =item *
9305
9306 We look for the lexical scope above DB::DB and auto-complete lexical variables
9307 if PadWalker could be loaded.
9308
9309 =cut
9310
9311         if (not $text =~ /::/ and eval { require PadWalker } ) {
9312             my $level = 1;
9313             while (1) {
9314                 my @info = caller($level);
9315                 $level++;
9316                 $level = -1, last
9317                   if not @info;
9318                 last if $info[3] eq 'DB::DB';
9319             }
9320             if ($level > 0) {
9321                 my $lexicals = PadWalker::peek_my($level);
9322                 push @out, grep /^\Q$prefix$text/, keys %$lexicals;
9323             }
9324         }
9325
9326 =pod
9327
9328 =item *
9329
9330 If the package is C<::> (C<main>), create an empty list; if it's something else, create a list of all the packages known.  Append whichever list to a list of all the possible symbols in the current package. C<grep> out the matches to the text entered so far, then C<map> the prefix back onto the symbols.
9331
9332 =cut
9333
9334         push @out, map "$prefix$_", grep /^\Q$text/,
9335           ( grep /^_?[a-zA-Z]/, keys %$pack ),
9336           ( $pack eq '::' ? () : ( grep /::$/, keys %:: ) );
9337
9338 =item *
9339
9340 If there's only one hit, it's a package qualifier, and it's not equal to the initial text, recomplete using this symbol.
9341
9342 =back
9343
9344 =cut
9345
9346         if ( @out == 1 and $out[0] =~ /::$/ and $out[0] ne $itext ) {
9347             return db_complete( $out[0], $line, $start );
9348         }
9349
9350         # Return the list of possibles.
9351         return sort @out;
9352     } ## end if ($text =~ /^[\$@%]/)
9353
9354 =head3 Options
9355
9356 We use C<option_val()> to look up the current value of the option. If there's
9357 only a single value, we complete the command in such a way that it is a
9358 complete command for setting the option in question. If there are multiple
9359 possible values, we generate a command consisting of the option plus a trailing
9360 question mark, which, if executed, will list the current value of the option.
9361
9362 =cut
9363
9364     if ( ( substr $line, 0, $start ) =~ /^\|*[oO]\b.*\s$/ )
9365     {    # Options after space
9366            # We look for the text to be matched in the list of possible options,
9367            # and fetch the current value.
9368         my @out = grep /^\Q$text/, @options;
9369         my $val = option_val( $out[0], undef );
9370
9371         # Set up a 'query option's value' command.
9372         my $out = '? ';
9373         if ( not defined $val or $val =~ /[\n\r]/ ) {
9374
9375             # There's really nothing else we can do.
9376         }
9377
9378         # We have a value. Create a proper option-setting command.
9379         elsif ( $val =~ /\s/ ) {
9380
9381             # XXX This may be an extraneous variable.
9382             my $found;
9383
9384             # We'll want to quote the string (because of the embedded
9385             # whtespace), but we want to make sure we don't end up with
9386             # mismatched quote characters. We try several possibilities.
9387             foreach my $l ( split //, qq/\"\'\#\|/ ) {
9388
9389                 # If we didn't find this quote character in the value,
9390                 # quote it using this quote character.
9391                 $out = "$l$val$l ", last if ( index $val, $l ) == -1;
9392             }
9393         } ## end elsif ($val =~ /\s/)
9394
9395         # Don't need any quotes.
9396         else {
9397             $out = "=$val ";
9398         }
9399
9400         # If there were multiple possible values, return '? ', which
9401         # makes the command into a query command. If there was just one,
9402         # have readline append that.
9403         $rl_attribs->{completer_terminator_character} =
9404           ( @out == 1 ? $out : '? ' );
9405
9406         # Return list of possibilities.
9407         return sort @out;
9408     } ## end if ((substr $line, 0, ...
9409
9410 =head3 Filename completion
9411
9412 For entering filenames. We simply call C<readline>'s C<filename_list()>
9413 method with the completion text to get the possible completions.
9414
9415 =cut
9416
9417     return $term->filename_list($text);    # filenames
9418
9419 } ## end sub db_complete
9420
9421 =head1 MISCELLANEOUS SUPPORT FUNCTIONS
9422
9423 Functions that possibly ought to be somewhere else.
9424
9425 =head2 end_report
9426
9427 Say we're done.
9428
9429 =cut
9430
9431 sub end_report {
9432     local $\ = '';
9433     print $OUT "Use 'q' to quit or 'R' to restart.  'h q' for details.\n";
9434 }
9435
9436 =head2 clean_ENV
9437
9438 If we have $ini_pids, save it in the environment; else remove it from the
9439 environment. Used by the C<R> (restart) command.
9440
9441 =cut
9442
9443 sub clean_ENV {
9444     if ( defined($ini_pids) ) {
9445         $ENV{PERLDB_PIDS} = $ini_pids;
9446     }
9447     else {
9448         delete( $ENV{PERLDB_PIDS} );
9449     }
9450 } ## end sub clean_ENV
9451
9452 # PERLDBf_... flag names from perl.h
9453 our ( %DollarCaretP_flags, %DollarCaretP_flags_r );
9454
9455 BEGIN {
9456     %DollarCaretP_flags = (
9457         PERLDBf_SUB       => 0x01,     # Debug sub enter/exit
9458         PERLDBf_LINE      => 0x02,     # Keep line #
9459         PERLDBf_NOOPT     => 0x04,     # Switch off optimizations
9460         PERLDBf_INTER     => 0x08,     # Preserve more data
9461         PERLDBf_SUBLINE   => 0x10,     # Keep subr source lines
9462         PERLDBf_SINGLE    => 0x20,     # Start with single-step on
9463         PERLDBf_NONAME    => 0x40,     # For _SUB: no name of the subr
9464         PERLDBf_GOTO      => 0x80,     # Report goto: call DB::goto
9465         PERLDBf_NAMEEVAL  => 0x100,    # Informative names for evals
9466         PERLDBf_NAMEANON  => 0x200,    # Informative names for anon subs
9467         PERLDBf_SAVESRC   => 0x400,    # Save source lines into @{"_<$filename"}
9468         PERLDB_ALL        => 0x33f,    # No _NONAME, _GOTO
9469     );
9470     # PERLDBf_LINE also enables the actions of PERLDBf_SAVESRC, so the debugger
9471     # doesn't need to set it. It's provided for the benefit of profilers and
9472     # other code analysers.
9473
9474     %DollarCaretP_flags_r = reverse %DollarCaretP_flags;
9475 }
9476
9477 sub parse_DollarCaretP_flags {
9478     my $flags = shift;
9479     $flags =~ s/^\s+//;
9480     $flags =~ s/\s+$//;
9481     my $acu = 0;
9482     foreach my $f ( split /\s*\|\s*/, $flags ) {
9483         my $value;
9484         if ( $f =~ /^0x([[:xdigit:]]+)$/ ) {
9485             $value = hex $1;
9486         }
9487         elsif ( $f =~ /^(\d+)$/ ) {
9488             $value = int $1;
9489         }
9490         elsif ( $f =~ /^DEFAULT$/i ) {
9491             $value = $DollarCaretP_flags{PERLDB_ALL};
9492         }
9493         else {
9494             $f =~ /^(?:PERLDBf_)?(.*)$/i;
9495             $value = $DollarCaretP_flags{ 'PERLDBf_' . uc($1) };
9496             unless ( defined $value ) {
9497                 print $OUT (
9498                     "Unrecognized \$^P flag '$f'!\n",
9499                     "Acceptable flags are: "
9500                       . join( ', ', sort keys %DollarCaretP_flags ),
9501                     ", and hexadecimal and decimal numbers.\n"
9502                 );
9503                 return undef;
9504             }
9505         }
9506         $acu |= $value;
9507     }
9508     $acu;
9509 }
9510
9511 sub expand_DollarCaretP_flags {
9512     my $DollarCaretP = shift;
9513     my @bits         = (
9514         map {
9515             my $n = ( 1 << $_ );
9516             ( $DollarCaretP & $n )
9517               ? ( $DollarCaretP_flags_r{$n}
9518                   || sprintf( '0x%x', $n ) )
9519               : ()
9520           } 0 .. 31
9521     );
9522     return @bits ? join( '|', @bits ) : 0;
9523 }
9524
9525 =over 4
9526
9527 =item rerun
9528
9529 Rerun the current session to:
9530
9531     rerun        current position
9532
9533     rerun 4      command number 4
9534
9535     rerun -4     current command minus 4 (go back 4 steps)
9536
9537 Whether this always makes sense, in the current context is unknowable, and is
9538 in part left as a useful exercise for the reader.  This sub returns the
9539 appropriate arguments to rerun the current session.
9540
9541 =cut
9542
9543 sub rerun {
9544     my $i = shift;
9545     my @args;
9546     pop(@truehist);                      # strim
9547     unless (defined $truehist[$i]) {
9548         print "Unable to return to non-existent command: $i\n";
9549     } else {
9550         $#truehist = ($i < 0 ? $#truehist + $i : $i > 0 ? $i : $#truehist);
9551         my @temp = @truehist;            # store
9552         push(@DB::typeahead, @truehist); # saved
9553         @truehist = @hist = ();          # flush
9554         @args = restart();              # setup
9555         get_list("PERLDB_HIST");        # clean
9556         set_list("PERLDB_HIST", @temp); # reset
9557     }
9558     return @args;
9559 }
9560
9561 =item restart
9562
9563 Restarting the debugger is a complex operation that occurs in several phases.
9564 First, we try to reconstruct the command line that was used to invoke Perl
9565 and the debugger.
9566
9567 =cut
9568
9569 sub restart {
9570     # I may not be able to resurrect you, but here goes ...
9571     print $OUT
9572 "Warning: some settings and command-line options may be lost!\n";
9573     my ( @script, @flags, $cl );
9574
9575     # If warn was on before, turn it on again.
9576     push @flags, '-w' if $ini_warn;
9577
9578     # Rebuild the -I flags that were on the initial
9579     # command line.
9580     for (@ini_INC) {
9581         push @flags, '-I', $_;
9582     }
9583
9584     # Turn on taint if it was on before.
9585     push @flags, '-T' if ${^TAINT};
9586
9587     # Arrange for setting the old INC:
9588     # Save the current @init_INC in the environment.
9589     set_list( "PERLDB_INC", @ini_INC );
9590
9591     # If this was a perl one-liner, go to the "file"
9592     # corresponding to the one-liner read all the lines
9593     # out of it (except for the first one, which is going
9594     # to be added back on again when 'perl -d' runs: that's
9595     # the 'require perl5db.pl;' line), and add them back on
9596     # to the command line to be executed.
9597     if ( $0 eq '-e' ) {
9598         my $lines = *{$main::{'_<-e'}}{ARRAY};
9599         for ( 1 .. $#$lines ) {  # The first line is PERL5DB
9600             chomp( $cl = $lines->[$_] );
9601             push @script, '-e', $cl;
9602         }
9603     } ## end if ($0 eq '-e')
9604
9605     # Otherwise we just reuse the original name we had
9606     # before.
9607     else {
9608         @script = $0;
9609     }
9610
9611 =pod
9612
9613 After the command line  has been reconstructed, the next step is to save
9614 the debugger's status in environment variables. The C<DB::set_list> routine
9615 is used to save aggregate variables (both hashes and arrays); scalars are
9616 just popped into environment variables directly.
9617
9618 =cut
9619
9620     # If the terminal supported history, grab it and
9621     # save that in the environment.
9622     set_list( "PERLDB_HIST",
9623           $term->Features->{getHistory}
9624         ? $term->GetHistory
9625         : @hist );
9626
9627     # Find all the files that were visited during this
9628     # session (i.e., the debugger had magic hashes
9629     # corresponding to them) and stick them in the environment.
9630     my @had_breakpoints = keys %had_breakpoints;
9631     set_list( "PERLDB_VISITED", @had_breakpoints );
9632
9633     # Save the debugger options we chose.
9634     set_list( "PERLDB_OPT", %option );
9635     # set_list( "PERLDB_OPT", options2remember() );
9636
9637     # Save the break-on-loads.
9638     set_list( "PERLDB_ON_LOAD", %break_on_load );
9639
9640 =pod
9641
9642 The most complex part of this is the saving of all of the breakpoints. They
9643 can live in an awful lot of places, and we have to go through all of them,
9644 find the breakpoints, and then save them in the appropriate environment
9645 variable via C<DB::set_list>.
9646
9647 =cut
9648
9649     # Go through all the breakpoints and make sure they're
9650     # still valid.
9651     my @hard;
9652     for ( 0 .. $#had_breakpoints ) {
9653
9654         # We were in this file.
9655         my $file = $had_breakpoints[$_];
9656
9657         # Grab that file's magic line hash.
9658         *dbline = $main::{ '_<' . $file };
9659
9660         # Skip out if it doesn't exist, or if the breakpoint
9661         # is in a postponed file (we'll do postponed ones
9662         # later).
9663         next unless %dbline or $postponed_file{$file};
9664
9665         # In an eval. This is a little harder, so we'll
9666         # do more processing on that below.
9667         ( push @hard, $file ), next
9668           if $file =~ /^\(\w*eval/;
9669
9670         # XXX I have no idea what this is doing. Yet.
9671         my @add;
9672         @add = %{ $postponed_file{$file} }
9673           if $postponed_file{$file};
9674
9675         # Save the list of all the breakpoints for this file.
9676         set_list( "PERLDB_FILE_$_", %dbline, @add );
9677
9678         # Serialize the extra data %breakpoints_data hash.
9679         # That's a bug fix.
9680         set_list( "PERLDB_FILE_ENABLED_$_",
9681             map { _is_breakpoint_enabled($file, $_) ? 1 : 0 }
9682             sort { $a <=> $b } keys(%dbline)
9683         )
9684     } ## end for (0 .. $#had_breakpoints)
9685
9686     # The breakpoint was inside an eval. This is a little
9687     # more difficult. XXX and I don't understand it.
9688     for (@hard) {
9689         # Get over to the eval in question.
9690         *dbline = $main::{ '_<' . $_ };
9691         my ( $quoted, $sub, %subs, $line ) = quotemeta $_;
9692         for $sub ( keys %sub ) {
9693             next unless $sub{$sub} =~ /^$quoted:(\d+)-(\d+)$/;
9694             $subs{$sub} = [ $1, $2 ];
9695         }
9696         unless (%subs) {
9697             print $OUT
9698               "No subroutines in $_, ignoring breakpoints.\n";
9699             next;
9700         }
9701       LINES: for $line ( keys %dbline ) {
9702
9703             # One breakpoint per sub only:
9704             my ( $offset, $sub, $found );
9705           SUBS: for $sub ( keys %subs ) {
9706                 if (
9707                     $subs{$sub}->[1] >=
9708                     $line    # Not after the subroutine
9709                     and (
9710                         not defined $offset    # Not caught
9711                         or $offset < 0
9712                     )
9713                   )
9714                 {                              # or badly caught
9715                     $found  = $sub;
9716                     $offset = $line - $subs{$sub}->[0];
9717                     $offset = "+$offset", last SUBS
9718                       if $offset >= 0;
9719                 } ## end if ($subs{$sub}->[1] >=...
9720             } ## end for $sub (keys %subs)
9721             if ( defined $offset ) {
9722                 $postponed{$found} =
9723                   "break $offset if $dbline{$line}";
9724             }
9725             else {
9726                 print $OUT
9727 "Breakpoint in $_:$line ignored: after all the subroutines.\n";
9728             }
9729         } ## end for $line (keys %dbline)
9730     } ## end for (@hard)
9731
9732     # Save the other things that don't need to be
9733     # processed.
9734     set_list( "PERLDB_POSTPONE",  %postponed );
9735     set_list( "PERLDB_PRETYPE",   @$pretype );
9736     set_list( "PERLDB_PRE",       @$pre );
9737     set_list( "PERLDB_POST",      @$post );
9738     set_list( "PERLDB_TYPEAHEAD", @typeahead );
9739
9740     # We are officially restarting.
9741     $ENV{PERLDB_RESTART} = 1;
9742
9743     # We are junking all child debuggers.
9744     delete $ENV{PERLDB_PIDS};    # Restore ini state
9745
9746     # Set this back to the initial pid.
9747     $ENV{PERLDB_PIDS} = $ini_pids if defined $ini_pids;
9748
9749 =pod
9750
9751 After all the debugger status has been saved, we take the command we built up
9752 and then return it, so we can C<exec()> it. The debugger will spot the
9753 C<PERLDB_RESTART> environment variable and realize it needs to reload its state
9754 from the environment.
9755
9756 =cut
9757
9758     # And run Perl again. Add the "-d" flag, all the
9759     # flags we built up, the script (whether a one-liner
9760     # or a file), add on the -emacs flag for a slave editor,
9761     # and then the old arguments.
9762
9763     return ($^X, '-d', @flags, @script, ($slave_editor ? '-emacs' : ()), @ARGS);
9764
9765 };  # end restart
9766
9767 =back
9768
9769 =head1 END PROCESSING - THE C<END> BLOCK
9770
9771 Come here at the very end of processing. We want to go into a
9772 loop where we allow the user to enter commands and interact with the
9773 debugger, but we don't want anything else to execute.
9774
9775 First we set the C<$finished> variable, so that some commands that
9776 shouldn't be run after the end of program quit working.
9777
9778 We then figure out whether we're truly done (as in the user entered a C<q>
9779 command, or we finished execution while running nonstop). If we aren't,
9780 we set C<$single> to 1 (causing the debugger to get control again).
9781
9782 We then call C<DB::fake::at_exit()>, which returns the C<Use 'q' to quit ...>
9783 message and returns control to the debugger. Repeat.
9784
9785 When the user finally enters a C<q> command, C<$fall_off_end> is set to
9786 1 and the C<END> block simply exits with C<$single> set to 0 (don't
9787 break, run to completion.).
9788
9789 =cut
9790
9791 END {
9792     $finished = 1 if $inhibit_exit;    # So that some commands may be disabled.
9793     $fall_off_end = 1 unless $inhibit_exit;
9794
9795     # Do not stop in at_exit() and destructors on exit:
9796     if ($fall_off_end or $runnonstop) {
9797         save_hist();
9798     } else {
9799         $DB::single = 1;
9800         DB::fake::at_exit();
9801     }
9802 } ## end END
9803
9804 =head1 PRE-5.8 COMMANDS
9805
9806 Some of the commands changed function quite a bit in the 5.8 command
9807 realignment, so much so that the old code had to be replaced completely.
9808 Because we wanted to retain the option of being able to go back to the
9809 former command set, we moved the old code off to this section.
9810
9811 There's an awful lot of duplicated code here. We've duplicated the
9812 comments to keep things clear.
9813
9814 =head2 Null command
9815
9816 Does nothing. Used to I<turn off> commands.
9817
9818 =cut
9819
9820 sub cmd_pre580_null {
9821
9822     # do nothing...
9823 }
9824
9825 =head2 Old C<a> command.
9826
9827 This version added actions if you supplied them, and deleted them
9828 if you didn't.
9829
9830 =cut
9831
9832 sub cmd_pre580_a {
9833     my $xcmd = shift;
9834     my $cmd  = shift;
9835
9836     # Argument supplied. Add the action.
9837     if ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9838
9839         # If the line isn't there, use the current line.
9840         my $i = $1 || $line;
9841         my $j = $2;
9842
9843         # If there is an action ...
9844         if ( length $j ) {
9845
9846             # ... but the line isn't breakable, skip it.
9847             if ( $dbline[$i] == 0 ) {
9848                 print $OUT "Line $i may not have an action.\n";
9849             }
9850             else {
9851
9852                 # ... and the line is breakable:
9853                 # Mark that there's an action in this file.
9854                 $had_breakpoints{$filename} |= 2;
9855
9856                 # Delete any current action.
9857                 $dbline{$i} =~ s/\0[^\0]*//;
9858
9859                 # Add the new action, continuing the line as needed.
9860                 $dbline{$i} .= "\0" . action($j);
9861             }
9862         } ## end if (length $j)
9863
9864         # No action supplied.
9865         else {
9866
9867             # Delete the action.
9868             $dbline{$i} =~ s/\0[^\0]*//;
9869
9870             # Mark as having no break or action if nothing's left.
9871             delete $dbline{$i} if $dbline{$i} eq '';
9872         }
9873     } ## end if ($cmd =~ /^(\d*)\s*(.*)/)
9874 } ## end sub cmd_pre580_a
9875
9876 =head2 Old C<b> command
9877
9878 Add breakpoints.
9879
9880 =cut
9881
9882 sub cmd_pre580_b {
9883     my $xcmd   = shift;
9884     my $cmd    = shift;
9885     my $dbline = shift;
9886
9887     # Break on load.
9888     if ( $cmd =~ /^load\b\s*(.*)/ ) {
9889         my $file = $1;
9890         $file =~ s/\s+$//;
9891         cmd_b_load($file);
9892     }
9893
9894     # b compile|postpone <some sub> [<condition>]
9895     # The interpreter actually traps this one for us; we just put the
9896     # necessary condition in the %postponed hash.
9897     elsif ( $cmd =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
9898
9899         # Capture the condition if there is one. Make it true if none.
9900         my $cond = length $3 ? $3 : '1';
9901
9902         # Save the sub name and set $break to 1 if $1 was 'postpone', 0
9903         # if it was 'compile'.
9904         my ( $subname, $break ) = ( $2, $1 eq 'postpone' );
9905
9906         # De-Perl4-ify the name - ' separators to ::.
9907         $subname =~ s/\'/::/g;
9908
9909         # Qualify it into the current package unless it's already qualified.
9910         $subname = "${package}::" . $subname
9911           unless $subname =~ /::/;
9912
9913         # Add main if it starts with ::.
9914         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
9915
9916         # Save the break type for this sub.
9917         $postponed{$subname} = $break ? "break +0 if $cond" : "compile";
9918     } ## end elsif ($cmd =~ ...
9919
9920     # b <sub name> [<condition>]
9921     elsif ( $cmd =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
9922         my $subname = $1;
9923         my $cond = length $2 ? $2 : '1';
9924         cmd_b_sub( $subname, $cond );
9925     }
9926     # b <line> [<condition>].
9927     elsif ( $cmd =~ /^(\d*)\s*(.*)/ ) {
9928         my $i = $1 || $dbline;
9929         my $cond = length $2 ? $2 : '1';
9930         cmd_b_line( $i, $cond );
9931     }
9932 } ## end sub cmd_pre580_b
9933
9934 =head2 Old C<D> command.
9935
9936 Delete all breakpoints unconditionally.
9937
9938 =cut
9939
9940 sub cmd_pre580_D {
9941     my $xcmd = shift;
9942     my $cmd  = shift;
9943     if ( $cmd =~ /^\s*$/ ) {
9944         print $OUT "Deleting all breakpoints...\n";
9945
9946         # %had_breakpoints lists every file that had at least one
9947         # breakpoint in it.
9948         my $file;
9949         for $file ( keys %had_breakpoints ) {
9950
9951             # Switch to the desired file temporarily.
9952             local *dbline = $main::{ '_<' . $file };
9953
9954             $max = $#dbline;
9955             my $was;
9956
9957             # For all lines in this file ...
9958             for my $i (1 .. $max) {
9959
9960                 # If there's a breakpoint or action on this line ...
9961                 if ( defined $dbline{$i} ) {
9962
9963                     # ... remove the breakpoint.
9964                     $dbline{$i} =~ s/^[^\0]+//;
9965                     if ( $dbline{$i} =~ s/^\0?$// ) {
9966
9967                         # Remove the entry altogether if no action is there.
9968                         delete $dbline{$i};
9969                     }
9970                 } ## end if (defined $dbline{$i...
9971             } ## end for my $i (1 .. $max)
9972
9973             # If, after we turn off the "there were breakpoints in this file"
9974             # bit, the entry in %had_breakpoints for this file is zero,
9975             # we should remove this file from the hash.
9976             if ( not $had_breakpoints{$file} &= ~1 ) {
9977                 delete $had_breakpoints{$file};
9978             }
9979         } ## end for $file (keys %had_breakpoints)
9980
9981         # Kill off all the other breakpoints that are waiting for files that
9982         # haven't been loaded yet.
9983         undef %postponed;
9984         undef %postponed_file;
9985         undef %break_on_load;
9986     } ## end if ($cmd =~ /^\s*$/)
9987 } ## end sub cmd_pre580_D
9988
9989 =head2 Old C<h> command
9990
9991 Print help. Defaults to printing the long-form help; the 5.8 version
9992 prints the summary by default.
9993
9994 =cut
9995
9996 sub cmd_pre580_h {
9997     my $xcmd = shift;
9998     my $cmd  = shift;
9999
10000     # Print the *right* help, long format.
10001     if ( $cmd =~ /^\s*$/ ) {
10002         print_help($pre580_help);
10003     }
10004
10005     # 'h h' - explicitly-requested summary.
10006     elsif ( $cmd =~ /^h\s*/ ) {
10007         print_help($pre580_summary);
10008     }
10009
10010     # Find and print a command's help.
10011     elsif ( $cmd =~ /^h\s+(\S.*)$/ ) {
10012         my $asked  = $1;                   # for proper errmsg
10013         my $qasked = quotemeta($asked);    # for searching
10014                                            # XXX: finds CR but not <CR>
10015         if (
10016             $pre580_help =~ /^
10017                               <?           # Optional '<'
10018                               (?:[IB]<)    # Optional markup
10019                               $qasked      # The command name
10020                             /mx
10021           )
10022         {
10023
10024             while (
10025                 $pre580_help =~ /^
10026                                   (             # The command help:
10027                                    <?           # Optional '<'
10028                                    (?:[IB]<)    # Optional markup
10029                                    $qasked      # The command name
10030                                    ([\s\S]*?)   # Lines starting with tabs
10031                                    \n           # Final newline
10032                                   )
10033                                   (?!\s)/mgx
10034               )    # Line not starting with space
10035                    # (Next command's help)
10036             {
10037                 print_help($1);
10038             }
10039         } ## end if ($pre580_help =~ /^<?(?:[IB]<)$qasked/m)
10040
10041         # Help not found.
10042         else {
10043             print_help("B<$asked> is not a debugger command.\n");
10044         }
10045     } ## end elsif ($cmd =~ /^h\s+(\S.*)$/)
10046 } ## end sub cmd_pre580_h
10047
10048 =head2 Old C<W> command
10049
10050 C<W E<lt>exprE<gt>> adds a watch expression, C<W> deletes them all.
10051
10052 =cut
10053
10054 sub cmd_pre580_W {
10055     my $xcmd = shift;
10056     my $cmd  = shift;
10057
10058     # Delete all watch expressions.
10059     if ( $cmd =~ /^$/ ) {
10060
10061         # No watching is going on.
10062         $trace &= ~2;
10063
10064         # Kill all the watch expressions and values.
10065         @to_watch = @old_watch = ();
10066     }
10067
10068     # Add a watch expression.
10069     elsif ( $cmd =~ /^(.*)/s ) {
10070
10071         # add it to the list to be watched.
10072         push @to_watch, $1;
10073
10074         # Get the current value of the expression.
10075         # Doesn't handle expressions returning list values!
10076         $evalarg = $1;
10077         my ($val) = DB::eval();
10078         $val = ( defined $val ) ? "'$val'" : 'undef';
10079
10080         # Save it.
10081         push @old_watch, $val;
10082
10083         # We're watching stuff.
10084         $trace |= 2;
10085
10086     } ## end elsif ($cmd =~ /^(.*)/s)
10087 } ## end sub cmd_pre580_W
10088
10089 =head1 PRE-AND-POST-PROMPT COMMANDS AND ACTIONS
10090
10091 The debugger used to have a bunch of nearly-identical code to handle
10092 the pre-and-post-prompt action commands. C<cmd_pre590_prepost> and
10093 C<cmd_prepost> unify all this into one set of code to handle the
10094 appropriate actions.
10095
10096 =head2 C<cmd_pre590_prepost>
10097
10098 A small wrapper around C<cmd_prepost>; it makes sure that the default doesn't
10099 do something destructive. In pre 5.8 debuggers, the default action was to
10100 delete all the actions.
10101
10102 =cut
10103
10104 sub cmd_pre590_prepost {
10105     my $cmd    = shift;
10106     my $line   = shift || '*';
10107     my $dbline = shift;
10108
10109     return cmd_prepost( $cmd, $line, $dbline );
10110 } ## end sub cmd_pre590_prepost
10111
10112 =head2 C<cmd_prepost>
10113
10114 Actually does all the handling for C<E<lt>>, C<E<gt>>, C<{{>, C<{>, etc.
10115 Since the lists of actions are all held in arrays that are pointed to by
10116 references anyway, all we have to do is pick the right array reference and
10117 then use generic code to all, delete, or list actions.
10118
10119 =cut
10120
10121 sub cmd_prepost {
10122     my $cmd = shift;
10123
10124     # No action supplied defaults to 'list'.
10125     my $line = shift || '?';
10126
10127     # Figure out what to put in the prompt.
10128     my $which = '';
10129
10130     # Make sure we have some array or another to address later.
10131     # This means that if ssome reason the tests fail, we won't be
10132     # trying to stash actions or delete them from the wrong place.
10133     my $aref = [];
10134
10135     # < - Perl code to run before prompt.
10136     if ( $cmd =~ /^\</o ) {
10137         $which = 'pre-perl';
10138         $aref  = $pre;
10139     }
10140
10141     # > - Perl code to run after prompt.
10142     elsif ( $cmd =~ /^\>/o ) {
10143         $which = 'post-perl';
10144         $aref  = $post;
10145     }
10146
10147     # { - first check for properly-balanced braces.
10148     elsif ( $cmd =~ /^\{/o ) {
10149         if ( $cmd =~ /^\{.*\}$/o && unbalanced( substr( $cmd, 1 ) ) ) {
10150             print $OUT
10151 "$cmd is now a debugger command\nuse ';$cmd' if you mean Perl code\n";
10152         }
10153
10154         # Properly balanced. Pre-prompt debugger actions.
10155         else {
10156             $which = 'pre-debugger';
10157             $aref  = $pretype;
10158         }
10159     } ## end elsif ( $cmd =~ /^\{/o )
10160
10161     # Did we find something that makes sense?
10162     unless ($which) {
10163         print $OUT "Confused by command: $cmd\n";
10164     }
10165
10166     # Yes.
10167     else {
10168
10169         # List actions.
10170         if ( $line =~ /^\s*\?\s*$/o ) {
10171             unless (@$aref) {
10172
10173                 # Nothing there. Complain.
10174                 print $OUT "No $which actions.\n";
10175             }
10176             else {
10177
10178                 # List the actions in the selected list.
10179                 print $OUT "$which commands:\n";
10180                 foreach my $action (@$aref) {
10181                     print $OUT "\t$cmd -- $action\n";
10182                 }
10183             } ## end else
10184         } ## end if ( $line =~ /^\s*\?\s*$/o)
10185
10186         # Might be a delete.
10187         else {
10188             if ( length($cmd) == 1 ) {
10189                 if ( $line =~ /^\s*\*\s*$/o ) {
10190
10191                     # It's a delete. Get rid of the old actions in the
10192                     # selected list..
10193                     @$aref = ();
10194                     print $OUT "All $cmd actions cleared.\n";
10195                 }
10196                 else {
10197
10198                     # Replace all the actions. (This is a <, >, or {).
10199                     @$aref = action($line);
10200                 }
10201             } ## end if ( length($cmd) == 1)
10202             elsif ( length($cmd) == 2 ) {
10203
10204                 # Add the action to the line. (This is a <<, >>, or {{).
10205                 push @$aref, action($line);
10206             }
10207             else {
10208
10209                 # <<<, >>>>, {{{{{{ ... something not a command.
10210                 print $OUT
10211                   "Confused by strange length of $which command($cmd)...\n";
10212             }
10213         } ## end else [ if ( $line =~ /^\s*\?\s*$/o)
10214     } ## end else
10215 } ## end sub cmd_prepost
10216
10217 =head1 C<DB::fake>
10218
10219 Contains the C<at_exit> routine that the debugger uses to issue the
10220 C<Debugged program terminated ...> message after the program completes. See
10221 the C<END> block documentation for more details.
10222
10223 =cut
10224
10225 package DB::fake;
10226
10227 sub at_exit {
10228     "Debugged program terminated.  Use 'q' to quit or 'R' to restart.";
10229 }
10230
10231 package DB;    # Do not trace this 1; below!
10232
10233 1;
10234
10235