dist/Devel-PPPort/parts/apicheck.pl

   1 #!/usr/bin/perl -w
   2 ################################################################################
   3 #
   4 #  apicheck.pl -- generate apicheck.c: C source for automated API check
   5 #
   6 #  WARNING:  This script will be run on very old perls.  You need to not use
   7 #            modern constructs.  See HACKERS file for examples.
   8 #
   9 ################################################################################
  10 #
  11 #  Version 3.x, Copyright (C) 2004-2013, Marcus Holland-Moritz.
  12 #  Version 2.x, Copyright (C) 2001, Paul Marquess.
  13 #  Version 1.x, Copyright (C) 1999, Kenneth Albanowski.
  14 #
  15 #  This program is free software; you can redistribute it and/or
  16 #  modify it under the same terms as Perl itself.
  17 #
  18 ################################################################################
  19
  20 use strict;
  21 require './parts/ppptools.pl';
  22
  23 if (@ARGV) {
  24   my $file = pop @ARGV;
  25   open OUT, ">$file" or die "$file: $!\n";
  26 }
  27 else {
  28   *OUT = \*STDOUT;
  29 }
  30
  31 # Get list of functions/macros to test
  32 my @f = parse_embed(qw( parts/embed.fnc parts/apidoc.fnc parts/ppport.fnc ));
  33
  34 # Read in what we've decided in previous calls should be #ifdef'd out for this
  35 # call.  The keys are the symbols to test; each value is a subhash, like so:
  36 #     'utf8_hop_forward' => {
  37 #                               'version' => '5.025007'
  38 #                           },
  39 # We don't care here about other subkeys
  40 my %todo = %{&parse_todo};
  41
  42 # We convert these types into these other types
  43 my %tmap = (
  44   void => 'int',
  45 );
  46
  47 # These are for special marker argument names, as mentioned in embed.fnc
  48 my %amap = (
  49   SP   => 'SP',
  50   type => 'int',
  51   cast => 'int',
  52   block => '{1;}',
  53 );
  54
  55 # Certain return types are instead considered void
  56 my %void = (
  57   void     => 1,
  58   Free_t   => 1,
  59   Signal_t => 1,
  60 );
  61
  62 # khw doesn't know why these exist.  These have an explicit (void) cast added.
  63 # Undef'ing this hash made no difference.  Maybe it's for older compilers?
  64 my %castvoid = (
  65   map { ($_ => 1) } qw(
  66     G_ARRAY
  67     G_DISCARD
  68     G_EVAL
  69     G_NOARGS
  70     G_SCALAR
  71     G_VOID
  72     HEf_SVKEY
  73     MARK
  74     Nullav
  75     Nullch
  76     Nullcv
  77     Nullhv
  78     Nullsv
  79     SP
  80     SVt_IV
  81     SVt_NV
  82     SVt_PV
  83     SVt_PVAV
  84     SVt_PVCV
  85     SVt_PVHV
  86     SVt_PVMG
  87     SvUOK
  88     XS_VERSION
  89   ),
  90 );
  91
  92 # Ignore the return value of these
  93 my %ignorerv = (
  94   map { ($_ => 1) } qw(
  95     newCONSTSUB
  96   ),
  97 );
  98
  99 my @simple_my_cxt_prereqs = ( 'typedef struct { int count; } my_cxt_t;', 'START_MY_CXT;' );
 100 my @my_cxt_prereqs = ( @simple_my_cxt_prereqs, 'MY_CXT_INIT;' );
 101
 102 # The value of each key is a list of things that need to be declared in order
 103 # for the key to compile.
 104 my %stack = (
 105   MULTICALL      => ['dMULTICALL;'],
 106   ORIGMARK       => ['dORIGMARK;'],
 107   POP_MULTICALL  => ['dMULTICALL;', 'U8 gimme;' ],
 108   PUSH_MULTICALL => ['dMULTICALL;', 'U8 gimme;' ],
 109   POPpbytex      => ['STRLEN n_a;'],
 110   POPpx          => ['STRLEN n_a;'],
 111   PUSHi          => ['dTARG;'],
 112   PUSHn          => ['dTARG;'],
 113   PUSHp          => ['dTARG;'],
 114   PUSHu          => ['dTARG;'],
 115   RESTORE_LC_NUMERIC => ['DECLARATION_FOR_LC_NUMERIC_MANIPULATION;'],
 116   STORE_LC_NUMERIC_FORCE_TO_UNDERLYING => ['DECLARATION_FOR_LC_NUMERIC_MANIPULATION;'],
 117   STORE_LC_NUMERIC_SET_TO_NEEDED => ['DECLARATION_FOR_LC_NUMERIC_MANIPULATION;'],
 118   STORE_LC_NUMERIC_SET_TO_NEEDED_IN => ['DECLARATION_FOR_LC_NUMERIC_MANIPULATION;'],
 119   UNDERBAR       => ['dUNDERBAR;'],
 120   XCPT_CATCH     => ['dXCPT;'],
 121   XCPT_RETHROW   => ['dXCPT;'],
 122   XCPT_TRY_END   => ['dXCPT;'],
 123   XCPT_TRY_START => ['dXCPT;'],
 124   XPUSHi         => ['dTARG;'],
 125   XPUSHn         => ['dTARG;'],
 126   XPUSHp         => ['dTARG;'],
 127   XPUSHu         => ['dTARG;'],
 128   XS_APIVERSION_BOOTCHECK => ['CV * cv;'],
 129   XS_VERSION_BOOTCHECK => ['CV * cv;'],
 130   MY_CXT_INIT  => [ @simple_my_cxt_prereqs ],
 131   MY_CXT_CLONE => [ @simple_my_cxt_prereqs ],
 132   dMY_CXT      => [ @simple_my_cxt_prereqs ],
 133   MY_CXT       => [ @my_cxt_prereqs ],
 134   _aMY_CXT     => [ @my_cxt_prereqs ],
 135    aMY_CXT     => [ @my_cxt_prereqs ],
 136    aMY_CXT_    => [ @my_cxt_prereqs ],
 137    pMY_CXT     => [ @my_cxt_prereqs ],
 138 );
 139
 140
 141 # Things to not try to check.
 142 my %ignore = map { ("$_" => 1) } keys %{&known_but_hard_to_test_for()};
 143
 144 # XXX The NEED_foo lines should be autogenerated
 145 print OUT <<HEAD;
 146 /*
 147  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
 148  * This file is built by $0.
 149  * Any changes made here will be lost!
 150  */
 151
 152 #include "EXTERN.h"
 153 #include "perl.h"
 154
 155 #define NO_XSLOCKS
 156 #include "XSUB.h"
 157
 158 #ifdef DPPP_APICHECK_NO_PPPORT_H
 159
 160 /* This is just to avoid too many baseline failures with perls < 5.6.0 */
 161
 162 #ifndef dTHX
 163 #  define dTHX extern int Perl___notused
 164 #endif
 165
 166 #else
 167
 168 #define NEED_PL_parser
 169 #define NEED_PL_signals
 170 #define NEED_caller_cx
 171 #define NEED_croak_xs_usage
 172 #define NEED_die_sv
 173 #define NEED_eval_pv
 174 #define NEED_grok_bin
 175 #define NEED_grok_hex
 176 #define NEED_grok_number
 177 #define NEED_grok_numeric_radix
 178 #define NEED_grok_oct
 179 #define NEED_load_module
 180 #define NEED_mess
 181 #define NEED_mess_nocontext
 182 #define NEED_mess_sv
 183 #define NEED_mg_findext
 184 #define NEED_my_snprintf
 185 #define NEED_my_sprintf
 186 #define NEED_my_strlcat
 187 #define NEED_my_strlcpy
 188 #define NEED_my_strnlen
 189 #define NEED_newCONSTSUB
 190 #define NEED_newSVpvn_share
 191 #define NEED_pv_display
 192 #define NEED_pv_escape
 193 #define NEED_pv_pretty
 194 #define NEED_sv_catpvf_mg
 195 #define NEED_sv_catpvf_mg_nocontext
 196 #define NEED_sv_setpvf_mg
 197 #define NEED_sv_setpvf_mg_nocontext
 198 #define NEED_sv_unmagicext
 199 #define NEED_utf8_to_uvchr_buf
 200 #define NEED_vload_module
 201 #define NEED_vmess
 202 #define NEED_warner
 203
 204 #include "ppport.h"
 205
 206 #endif
 207
 208 static int    VARarg1;
 209 static char  *VARarg2;
 210 static double VARarg3;
 211
 212 #if defined(PERL_BCDVERSION) && (PERL_BCDVERSION < 0x5009005)
 213 /* needed to make PL_parser apicheck work */
 214 typedef void yy_parser;
 215 #endif
 216
 217 HEAD
 218
 219 # Caller can restrict what functions tests are generated for
 220 if (@ARGV) {
 221   my %want = map { ($_ => 0) } @ARGV;
 222   @f = grep { exists $want{$_->{'name'}} } @f;
 223   for (@f) { $want{$_->{'name'}}++ }
 224   for (keys %want) {
 225     die "nothing found for '$_'\n" unless $want{$_};
 226   }
 227 }
 228
 229 my $f;
 230 for $f (@f) {   # Loop through all the tests to add
 231   $ignore{$f->{'name'}} and next;
 232   $f->{'flags'}{'A'} or next;  # only public API members
 233
 234   $ignore{$f->{'name'}} = 1; # ignore duplicates
 235
 236   my $Perl_ = $f->{'flags'}{'p'} ? 'Perl_' : '';
 237
 238   my $stack = '';
 239   my @arg;
 240   my $aTHX = '';
 241
 242   my $i = 1;
 243   my $ca;
 244   my $varargs = 0;
 245
 246   for $ca (@{$f->{'args'}}) {   # Loop through the function's args
 247     my $a = $ca->[0];           # 1th is the name, 0th is its type
 248     if ($a eq '...') {
 249       $varargs = 1;
 250       push @arg, qw(VARarg1 VARarg2 VARarg3);
 251       last;
 252     }
 253
 254     # Split this type into its components
 255     my($n, $p, $d) = $a =~ /^ (  (?: " [^"]* " )      # literal string type => $n
 256                                | (?: \w+ (?: \s+ \w+ )* )    # name of type => $n
 257                               )
 258                               \s*
 259                               ( \** )                 # optional pointer(s) => $p
 260                               (?: \s* \b const \b \s* )? # opt. const
 261                               ( (?: \[ [^\]]* \] )* )    # opt. dimension(s)=> $d
 262                             $/x
 263                      or die "$0 - cannot parse argument: [$a] in $f->{'name'}\n";
 264
 265     # Replace a special argument name by something that will compile.
 266     if (exists $amap{$n}) {
 267       die "$f->{'name'} had type $n, which should have been the whole type"
 268                                                                     if $p or $d;
 269       push @arg, $amap{$n};
 270       next;
 271     }
 272
 273     # Certain types, like 'void', get remapped.
 274     $n = $tmap{$n} || $n;
 275
 276     if ($n =~ / ^ " [^"]* " $/x) {  # Use the literal string, literally
 277       push @arg, $n;
 278     }
 279     else {
 280       my $v = 'arg' . $i++;     # Argument number
 281       push @arg, $v;
 282       my $no_const_n = $n;      # Get rid of any remaining 'const's
 283       $no_const_n =~ s/\bconst\b// unless $p;
 284
 285       # Declare this argument
 286       $stack .= "  static $no_const_n $p$v$d;\n";
 287     }
 288   }
 289
 290   # Declare thread context for functions and macros that might need it.
 291   # (Macros often fail to say they don't need it.)
 292   unless ($f->{'flags'}{'T'}) {
 293     $stack = "  dTHX;\n$stack";     # Harmless to declare even if not needed
 294     $aTHX = @arg ? 'aTHX_ ' : 'aTHX';
 295   }
 296
 297   # If this function is on the list of things that need declarations, add
 298   # them.
 299   if ($stack{$f->{'name'}}) {
 300     my $s = '';
 301     for (@{$stack{$f->{'name'}}}) {
 302       $s .= "  $_\n";
 303     }
 304     $stack = "$s$stack";
 305   }
 306
 307   my $args = join ', ', @arg;
 308   my $prefix = "";
 309
 310   # Failure to specify a return type in the apidoc line means void
 311   my $rvt = $f->{'ret'} || 'void';
 312
 313   my $ret;
 314   if ($void{$rvt}) {    # Certain return types are instead considered void
 315     $ret = $castvoid{$f->{'name'}} ? '(void) ' : '';
 316   }
 317   else {
 318     $stack .= "  $rvt rval;\n";
 319     $ret = $ignorerv{$f->{'name'}} ? '(void) ' : "rval = ";
 320   }
 321
 322   my $aTHX_args   = "";
 323   my $aTHX_prefix = "";
 324
 325   # Add parens to functions that take an argument list, even if empty
 326   unless ($f->{'flags'}{'n'}) {
 327     $aTHX_args = "($aTHX$args)";
 328     $args = "($args)";
 329   }
 330
 331   # Single trailing underscore in name means is a comma operator
 332   if ($f->{'name'} =~ /[^_]_$/) {
 333     $aTHX_args .= ' 1';
 334     $args .= ' 1';
 335   }
 336
 337   print OUT <<HEAD;
 338 /******************************************************************************
 339 *
 340 *  $f->{'name'}
 341 *
 342 ******************************************************************************/
 343
 344 HEAD
 345
 346   # #ifdef out if marked as todo (not known in) this version
 347   if ($todo{$f->{'name'}}) {
 348     my($five, $ver,$sub) = parse_version($todo{$f->{'name'}});
 349     print OUT "#if PERL_VERSION > $ver || (PERL_VERSION == $ver && PERL_SUBVERSION >= $sub) /* TODO */\n";
 350   }
 351
 352   my $final = $varargs
 353               ? "$aTHX_prefix$Perl_$f->{'name'}$aTHX_args"
 354               : "$prefix$f->{'name'}$args";
 355
 356   # If there is a '#if' associated with this, add that
 357   $f->{'cond'} and print OUT "#if $f->{'cond'}\n";
 358
 359   print OUT <<END;
 360 void _DPPP_test_$f->{'name'} (void)
 361 {
 362   dXSARGS;
 363 $stack
 364   {
 365 #ifdef $f->{'name'}
 366     $ret$prefix$f->{'name'}$args;
 367 #endif
 368   }
 369
 370   {
 371 #ifdef $f->{'name'}
 372     $ret$final;
 373 #else
 374     $ret$aTHX_prefix$Perl_$f->{'name'}$aTHX_args;
 375 #endif
 376   }
 377 }
 378 END
 379
 380   $f->{'cond'} and print OUT "#endif\n";
 381   $todo{$f->{'name'}} and print OUT "#endif\n";
 382
 383   print OUT "\n";
 384 }
 385
 386 @ARGV and close OUT;