This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
6b4898cdd18220274d8990fba5f8357e170d2e76
[perl5.git] / installperl
1 #!./perl -w
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8
9     # This needs to be at BEGIN time, before any use of Config
10     require './install_lib.pl';
11 }
12
13 use strict;
14 use vars qw($Is_VMS $Is_W32 $Is_OS2 $Is_Cygwin $Is_Darwin $Is_NetWare
15             %opts $packlist);
16 my $versiononly;
17
18 BEGIN {
19     if ($Is_VMS) { eval 'use VMS::Filespec;' }
20 }
21
22 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
23
24 use File::Find;
25 use File::Compare;
26 use File::Copy ();
27 use File::Path ();
28 use ExtUtils::Packlist;
29 use Cwd;
30
31 require './Porting/pod_lib.pl';
32
33 if ($Is_NetWare) {
34     $Is_W32 = 0;
35     $scr_ext = '.pl';
36 }
37
38 # override the ones in the rest of the script
39 sub mkpath {
40     File::Path::mkpath(@_) unless $opts{notify};
41 }
42
43 my $mainperldir = "/usr/bin";
44 my $exe_ext = $Config{exe_ext};
45
46 # Allow "make install PERLNAME=something_besides_perl":
47 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
48
49 # This is the base used for versioned names, like "perl5.6.0".
50 # It's separate because a common use of $PERLNAME is to install
51 # perl as "perl5", if that's used as base for versioned files you
52 # get "perl55.6.0".
53 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
54                     ? $ENV{PERLNAME_VERBASE}
55                     : $perl;
56 my $dbg = '';
57 my $ndbg = '';
58 if ( $Is_VMS ) {
59     if ( defined $Config{usevmsdebug} ) {
60         if ( $Config{usevmsdebug} eq 'define' ) {
61             $dbg = 'dbg';
62             $ndbg = 'ndbg';
63         }
64     }
65 }
66
67 # This little hack simplifies making the code after the comment "Fetch some
68 # frequently-used items from %Config" warning free. With $opts{destdir} always
69 # defined, it's also possible to make the s/\Q$opts{destdir}\E unconditional.
70
71 $opts{destdir} = '';
72 # Consider refactoring this to use Getopt::Long once Getopt::Long's planned
73 # feature is implemented, to distinguish + and - options.
74 while (@ARGV) {
75     $opts{notify} = 1 if $ARGV[0] eq '-n';
76     $opts{strip} = 1 if $ARGV[0] eq '-s';
77     $versiononly = 1 if $ARGV[0] eq '-v';
78     $versiononly = 0 if $ARGV[0] eq '+v';
79     $opts{silent} = 1 if $ARGV[0] eq '-S';
80     $opts{'skip-otherperls'} = 1 if $ARGV[0] eq '-o';
81     $opts{force} = 1 if $ARGV[0] eq '-f';
82     $opts{verbose} = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
83     $opts{archname} = 1 if $ARGV[0] eq '-A';
84     $opts{netware} = 1 if $ARGV[0] eq '-netware';
85     $opts{nopods} = 1 if $ARGV[0] eq '-p';
86     $opts{destdir} = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
87     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
88         print <<"EOT";
89 Usage $0: [switches]
90   -n        Don't actually run any commands; just print them.
91   -s        Run strip on installed binaries.
92   -v        Only install perl as a binary with the version number in the name.
93             (Override whatever config.sh says)
94   +v        Install perl as "perl" and as a binary with the version number in
95             the name.  (Override whatever config.sh says)
96   -S        Silent mode.
97   -f        Force installation (don't check if same version is there)
98   -o        Skip checking for other copies of perl in your PATH.
99   -V        Verbose mode.
100   -A        Also install perl with the architecture's name in the perl binary's
101             name.
102   -p        Don't install the pod files. [This will break use diagnostics;]
103   -netware  Install correctly on a Netware server.
104   -destdir  Prefix installation directories by this string.
105 EOT
106         exit;
107     }
108     shift;
109 }
110
111 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
112 my (@scripts, @tolink);
113 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
114 while (<SCRIPTS>) {
115     next if /^#/;
116     next if /a2p/; # a2p is binary, to be installed separately
117     chomp;
118     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
119         push @scripts, $1;
120         push @tolink, [$1, $2];
121     } else {
122         push @scripts, $_;
123     }
124 }
125 close SCRIPTS;
126
127 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
128
129 # Specify here any .pm files that are actually architecture-dependent.
130 # (Those included with XS extensions under ext/ are automatically
131 # added later.)
132 # Now that the default privlib has the full perl version number included,
133 # we no longer have to play the trick of sticking version-specific .pm
134 # files under the archlib directory.
135 my %archpms = (
136     Config => 1,
137     lib => 1,
138     Cwd => 1,
139 );
140
141 if ($^O eq 'dos') {
142     push(@scripts,'djgpp/fixpmain');
143     $archpms{config} = $archpms{filehand} = 1;
144 }
145
146 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
147     push(@scripts, map("$_.exe", @scripts));
148 }
149
150 # Exclude nonxs extensions that are not architecture dependent
151 my @nonxs = grep(!/^Errno$/, split(' ', $Config{'nonxs_ext'}));
152
153 my @ext_dirs = qw(cpan dist ext);
154 foreach my $ext_dir (@ext_dirs) {
155     find(sub {
156         if (($File::Find::name =~ m{^$ext_dir\b(.*)/([^/]+)\.pm$}) &&
157             ! grep { (my $dir = $_) =~ s/\//-/g;
158                      $File::Find::name =~ /^$ext_dir\/$dir\// } @nonxs)
159         {
160             my($path, $modname) = ($1,$2);
161
162             # Change hyphenated name like Filter-Util-Call to nested
163             # directory name Filter/Util/Call
164             $path =~ s{-}{/}g;
165
166             # strip to optional "/lib", or remove trailing component
167             $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
168
169             # strip any leading /
170             $path =~ s{^/}{};
171
172             # reconstitute canonical module name
173             $modname = "$path/$modname" if length $path;
174
175             # remember it
176             $archpms{$modname} = 1;
177         }
178     }, $ext_dir);
179 }
180
181 # print "[$_]\n" for sort keys %archpms;
182
183 my $ver = $Config{version};
184 my $release = substr($],0,3);   # Not used currently.
185 my $patchlevel = substr($],3,2);
186 die "Patchlevel of perl ($patchlevel)",
187     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
188         if $patchlevel != $Config{'PERL_VERSION'};
189
190 # Fetch some frequently-used items from %Config
191 my $installbin = "$opts{destdir}$Config{installbin}";
192 my $installscript = "$opts{destdir}$Config{installscript}";
193 my $installprivlib = "$opts{destdir}$Config{installprivlib}";
194 my $installarchlib = "$opts{destdir}$Config{installarchlib}";
195 my $installsitelib = "$opts{destdir}$Config{installsitelib}";
196 my $installsitearch = "$opts{destdir}$Config{installsitearch}";
197 my $installman1dir = "$opts{destdir}$Config{installman1dir}";
198 my $man1ext = $Config{man1ext};
199 my $libperl = $Config{libperl};
200 # Shared library and dynamic loading suffixes.
201 my $so = $Config{so};
202 my $dlext = $Config{dlext};
203 my $dlsrc = $Config{dlsrc};
204 if ($^O eq 'os390') {
205     my $pwd;
206     chomp($pwd=`pwd`);
207     my $archlibexp = $Config{archlibexp};
208     my $usedl = $Config{usedl};
209     if ($usedl eq 'define') {
210         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
211     }
212 }
213
214 if ($opts{netware}) {
215     # This is required only if we are installing on a NetWare server
216     $installscript = $Config{installnwscripts};
217     $installprivlib = $Config{installnwlib};
218     $installarchlib = $Config{installnwlib};
219     $installsitelib = $Config{installnwlib};
220 }
221
222 my $binexp = $Config{binexp};
223
224 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
225     foreach ( \$installbin,     \$installscript,  \$installprivlib,
226               \$installarchlib, \$installsitelib, \$installsitearch,
227               \$installman1dir ) {
228         $$_ = unixify($$_);  $$_ =~ s:/$::;
229     }
230 }
231
232 # Do some quick sanity checks.
233
234    $installbin          || die "No installbin directory in config.sh\n";
235 -d $installbin          || mkpath($installbin, $opts{verbose}, 0777);
236 -d $installbin          || $opts{notify} || die "$installbin is not a directory\n";
237 -w $installbin          || $opts{notify} || die "$installbin is not writable by you\n"
238         unless $installbin =~ m#^/afs/# || $opts{notify};
239
240 if (!$Is_NetWare) {
241 if (!$Is_VMS) {
242 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
243 }
244 else {
245 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
246     if ($dbg) {
247         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
248     }
249 }
250
251 -f 't/rantests'         || $Is_W32
252                         || warn "WARNING: You've never run 'make test' or",
253                                 " some tests failed! (Installing anyway.)\n";
254 } #if (!$Is_NetWare)
255
256 # This will be used to store the packlist
257 $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
258
259 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
260     my $perldll;
261
262     if ($Is_Cygwin) {
263         $perldll = $libperl;
264     } else {
265         $perldll = 'perl5'.$Config{patchlevel}.'.'.$dlext;
266     }
267
268     if ($dlsrc ne "dl_none.xs") {
269         -f $perldll || die "No perl DLL built\n";
270     }
271
272     # Install the DLL
273     safe_unlink("$installbin/$perldll");
274     copy("$perldll", "$installbin/$perldll");
275     chmod(0755, "$installbin/$perldll");
276     $packlist->{"$Config{installbin}/$perldll"} = { type => 'file' };
277 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
278
279 # First we install the version-numbered executables.
280
281 if ($Is_VMS) {
282     safe_unlink("$installbin/perl_setup.com");
283     copy("perl_setup.com", "$installbin/perl_setup.com");
284     chmod(0755, "$installbin/perl_setup.com");
285     safe_unlink("$installbin/$dbg$perl$exe_ext");
286     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
287     chmod(0755, "$installbin/$dbg$perl$exe_ext");
288     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
289     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
290     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
291     if ($ndbg) {
292         safe_unlink("$installbin/$ndbg$perl$exe_ext");
293         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
294         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
295         safe_unlink("$installbin/${dbg}a2p$exe_ext");
296         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
297         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
298     }
299 }
300 elsif ($^O ne 'dos') {
301     if (!$Is_NetWare) {
302         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
303         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
304         strip("$installbin/$perl_verbase$ver$exe_ext");
305         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
306     }
307     else {
308         # If installing onto a NetWare server
309         if ($opts{netware}) {
310             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
311             mkpath($Config{installnwsystem}, $opts{verbose}, 0777);
312             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
313             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
314             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
315             copy("x2p\\a2p.nlm", $Config{installnwsystem});
316             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
317             mkpath($Config{installnwlcgi}, $opts{verbose}, 0777);
318             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
319         }
320     } #if (!$Is_NetWare)
321 }
322 else {
323     safe_unlink("$installbin/$perl.exe");
324     copy("perl.exe", "$installbin/$perl.exe");
325 }
326
327 # Install library files.
328
329 my $do_installarchlib = !samepath($installarchlib, 'lib');
330 my $do_installprivlib = !samepath($installprivlib, 'lib');
331 my $vershort = ($Is_Cygwin and !$Config{usedevel}) ? substr($ver,0,-2) : $ver;
332 $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$vershort/);
333
334 mkpath($installprivlib, $opts{verbose}, 0777);
335 mkpath($installarchlib, $opts{verbose}, 0777);
336 mkpath($installsitelib, $opts{verbose}, 0777) if ($installsitelib);
337 mkpath($installsitearch, $opts{verbose}, 0777) if ($installsitearch);
338
339 if (-d 'lib') {
340     find({no_chdir => 1, wanted => \&installlib}, 'lib')
341         if $do_installarchlib || $do_installprivlib;
342 }
343 else {
344     warn "Can't install lib files - 'lib/' does not exist";
345 }
346
347 # Install header files and libraries.
348 mkpath("$installarchlib/CORE", $opts{verbose}, 0777);
349 my @corefiles;
350 if ($Is_VMS) {  # We did core file selection during build
351     my $coredir = "lib/$Config{archname}/$ver/CORE";
352     $coredir =~ tr/./_/;
353     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
354 }
355 elsif ($Is_Cygwin) { # On Cygwin symlink it to CORE to make Makefile happy
356     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
357     my $coredll = "$installarchlib/CORE/$libperl";
358     my $instcoredll = "$Config{installarchlib}/CORE/$libperl";
359     safe_unlink($coredll);
360     ( $Config{'d_link'} eq 'define' &&
361       eval {
362           CORE::link("$installbin/$libperl", $coredll);
363           $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
364                                     type => 'link' };
365       }
366     ) ||
367     eval {
368         symlink("$installbin/$libperl", $coredll);
369         $packlist->{$instcoredll} = { from => "$Config{installbin}/$libperl",
370                                   type => 'link' };
371     } ||
372     ( copy("$installbin/$libperl", $coredll) &&
373       push(@corefiles, $instcoredll)
374     )
375 } else {
376     # [als] hard-coded 'libperl' name... not good!
377     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
378
379     # AIX needs perl.exp installed as well.
380     push(@corefiles,'perl.exp') if $^O eq 'aix';
381 }
382 foreach my $file (@corefiles) {
383     # HP-UX (at least) needs to maintain execute permissions
384     # on dynamically-loadable libraries. So we do it for all.
385     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
386         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
387             strip("-S", "$installarchlib/CORE/$file") if $^O eq 'darwin';
388             chmod(0555, "$installarchlib/CORE/$file");
389         } else {
390             chmod(0444, "$installarchlib/CORE/$file");
391         }
392     }
393 }
394
395 # Install main perl executables
396 # Make links to ordinary names if installbin directory isn't current directory.
397
398 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
399     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
400     if ($^O eq 'vos') {
401         # VOS doesn't support hard links, so use a symlink.
402         symlink("$installbin/$perl_verbase$ver$exe_ext",
403                 "$installbin/$perl$exe_ext");
404     } else {
405         link("$installbin/$perl_verbase$ver$exe_ext",
406                 "$installbin/$perl$exe_ext");
407     }
408 }
409
410 # For development purposes it can be very useful to have multiple perls
411 # build for different "architectures" (eg threading or not) simultaneously.
412 if ($opts{archname} && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
413     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
414     safe_unlink("$installbin/$archperl");
415     if ($^O eq 'vos') {
416         # VOS doesn't support hard links, so use a symlink.
417         symlink("$installbin/$perl_verbase$ver$exe_ext",
418                 "$installbin/$archperl");
419     } else {
420         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
421     }
422 }
423
424 # Offer to install perl in a "standard" location
425
426 my $mainperl_is_instperl = 0;
427
428 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
429     !$versiononly && !$opts{notify} && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
430         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
431     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
432     my($instperl)       = "$installbin/$perl$exe_ext";
433     my($expinstperl)    = "$binexp/$perl$exe_ext";
434
435     # First make sure $usrbinperl is not already the same as the perl we
436     # just installed.
437     if (-x $usrbinperl) {
438         # Try to be clever about mainperl being a symbolic link
439         # to binexp/perl if binexp and installbin are different.
440         $mainperl_is_instperl =
441             samepath($usrbinperl, $instperl) ||
442             samepath($usrbinperl, $expinstperl) ||
443              (($binexp ne $installbin) &&
444               (-l $usrbinperl) &&
445               ((readlink $usrbinperl) eq $expinstperl));
446     }
447     if (! $mainperl_is_instperl) {
448         unlink($usrbinperl);
449         ( $Config{'d_link'} eq 'define' &&
450           eval { CORE::link $instperl, $usrbinperl } )  ||
451         eval { symlink $expinstperl, $usrbinperl }      ||
452         copy($instperl, $usrbinperl);
453
454         $mainperl_is_instperl = 1;
455     }
456 }
457
458 # Make links to ordinary names if installbin directory isn't current directory.
459 if (!$Is_NetWare && $dbg eq '') {
460     if (! samepath($installbin, 'x2p')) {
461         my $base = 'a2p';
462         $base .= $ver if $versiononly;
463         safe_unlink("$installbin/$base$exe_ext");
464         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
465         strip("$installbin/$base$exe_ext");
466         chmod(0755, "$installbin/$base$exe_ext");
467     }
468 }
469
470 # cppstdin is just a script, but it is architecture-dependent, so
471 # it can't safely be shared.  Place it in $installbin.
472 # Note that Configure doesn't build cppstin if it isn't needed, so
473 # we skip this if cppstdin doesn't exist.
474 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
475     safe_unlink("$installbin/cppstdin");
476     copy("cppstdin", "$installbin/cppstdin");
477     chmod(0755, "$installbin/cppstdin");
478 }
479
480 sub script_alias {
481     my ($installscript, $orig, $alias, $scr_ext) = @_;
482
483     safe_unlink("$installscript/$alias$scr_ext");
484     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
485         copy("$installscript/$orig$scr_ext",
486              "$installscript/$alias$scr_ext");
487     } elsif ($^O eq 'vos') {
488         symlink("$installscript/$orig$scr_ext",
489                 "$installscript/$alias$scr_ext");
490     } else {
491         link("$installscript/$orig$scr_ext",
492              "$installscript/$alias$scr_ext");
493     }
494 }
495
496 # Install scripts.
497 mkpath($installscript, $opts{verbose}, 0777);
498 if ($versiononly) {
499     for (@scripts) {
500         (my $base = $_) =~ s#.*/##;
501         $base .= $ver;
502         copy($_,    "$installscript/$base");
503         chmod(0755, "$installscript/$base");
504     }
505
506     for (@tolink) {
507         my ($from, $to) = map { "$_$ver" } @$_;
508         (my $frbase = $from) =~ s#.*/##;
509         (my $tobase = $to) =~ s#.*/##;
510         script_alias($installscript, $frbase, $tobase, $scr_ext);
511     }
512 } else {
513     for (@scripts) {
514         (my $base = $_) =~ s#.*/##;
515         copy($_, "$installscript/$base");
516         chmod(0755, "$installscript/$base");
517     }
518
519     for (@tolink) {
520         my ($from, $to) = @$_;
521         (my $frbase = $from) =~ s#.*/##;
522         (my $tobase = $to) =~ s#.*/##;
523         script_alias($installscript, $frbase, $tobase, $scr_ext);
524     }
525 }
526
527 # Install pod pages.  Where? I guess in $installprivlib/pod
528 # ($installprivlib/pods for cygwin).
529 if (!$opts{nopods} && (!$versiononly || ($installprivlib =~ m/\Q$vershort/))) {
530     my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
531     mkpath("${installprivlib}/$pod", $opts{verbose}, 0777);
532
533     for (map {$_->[1]} @{get_pod_metadata()->{master}}) {
534         # $_ is a name like  pod/perl.pod
535         (my $base = $_) =~ s#.*/##;
536         copy_if_diff($_, "${installprivlib}/$pod/${base}");
537         chmod(0644, "${installprivlib}/$pod/${base}");
538     }
539
540 }
541
542 # Check to make sure there aren't other perls around in installer's
543 # path.  This is probably UNIX-specific.  Check all absolute directories
544 # in the path except for where public executables are supposed to live.
545 # Also skip $mainperl if the user opted to have it be a link to the
546 # installed perl.
547
548 if (!$versiononly && !$opts{'skip-otherperls'}) {
549     my ($path, @path);
550     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
551     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
552     @path = split(/$dirsep/, $path);
553     if ($Is_VMS) {
554         my $i = 0;
555         while (exists $ENV{'DCL$PATH' . $i}) {
556             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
557             push(@path,$dir);
558         }
559     }
560     my @otherperls;
561     my %otherperls;
562     for (@path) {
563         next unless m,^/,;
564         # Use &samepath here because some systems have other dirs linked
565         # to $mainperldir (like SunOS)
566         next unless -d;
567         next if samepath($_, $binexp);
568         next if samepath($_, cwd());
569         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
570         my $otherperl = "$_/$perl$exe_ext";
571         next if $otherperls{$otherperl}++;
572         push(@otherperls, $otherperl)
573             if (-x $otherperl && ! -d $otherperl);
574     }
575     if (@otherperls) {
576         warn "\nWarning: $perl appears in your path in the following " .
577             "locations beyond where\nwe just installed it:\n";
578         for (@otherperls) {
579             warn "    ", $_, "\n";
580         }
581         warn "\n";
582     }
583
584 }
585
586 $packlist->write() unless $opts{notify};
587 print "  Installation complete\n" if $opts{verbose};
588
589 exit 0;
590
591 ###############################################################################
592
593 # If these are needed elsewhere, move them into install_lib.pl rather than
594 # copying them.
595
596 sub yn {
597     my($prompt) = @_;
598     my($answer);
599     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
600     print STDERR $prompt;
601     chop($answer = <STDIN>);
602     $answer = $default if $answer =~ m/^\s*$/;
603     ($answer =~ m/^[yY]/);
604 }
605
606 sub safe_unlink {
607     return if $opts{notify} or $Is_VMS;
608     my @names = @_;
609     foreach my $name (@names) {
610         next unless -e $name;
611         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
612         print "  unlink $name\n" if $opts{verbose};
613         next if CORE::unlink($name);
614         warn "Couldn't unlink $name: $!\n";
615         if ($! =~ /busy/i) {
616             print "  mv $name $name.old\n" if $opts{verbose};
617             safe_rename($name, "$name.old")
618                 or warn "Couldn't rename $name: $!\n";
619         }
620     }
621 }
622
623 sub safe_rename {
624     my($from,$to) = @_;
625     if (-f $to and not unlink($to)) {
626         my($i);
627         for ($i = 1; $i < 50; $i++) {
628             last if rename($to, "$to.$i");
629         }
630         warn("Cannot rename to '$to.$i': $!"), return 0
631            if $i >= 50; # Give up!
632     }
633     link($from,$to) || return 0;
634     unlink($from);
635 }
636
637 sub copy {
638     my($from,$to) = @_;
639
640     my $xto = $to;
641     $xto =~ s/^\Q$opts{destdir}\E//;
642     print $opts{verbose} ? "  cp $from $xto\n" : "  $xto\n"
643         unless $opts{silent};
644     print "  creating new version of $xto\n"
645         if $Is_VMS and -e $to and !$opts{silent};
646     unless ($opts{notify} or File::Copy::copy($from, $to)) {
647         # Might have been that F::C::c can't overwrite the target
648         warn "Couldn't copy $from to $to: $!\n"
649             unless -f $to and (chmod(0666, $to), unlink $to)
650                    and File::Copy::copy($from, $to);
651     }
652     $packlist->{$xto} = { type => 'file' };
653 }
654
655 sub installlib {
656     my $dir = $File::Find::dir;
657     $dir =~ s!\Alib/?!!;
658
659     m!([^/]+)\z!;
660     my $name = $1;
661
662     # This remains ugly, and in need of refactoring.
663
664     # $name always starts as the leafname
665     # $dir is the directory *within* lib
666     # $name later has $dir pre-pended, to give the relative path in lib/
667     # which is used to create the path in the target directory.
668
669     # $_ was always the filename to use on disk. Adding no_chdir doesn't change
670     # this, as $_ becomes a pathname, and so still works. However, it's not
671     # obvious that $_ is needed later, and hence $_ must not be modified.
672
673     # Also, many of the regex exclusion tests below are now superfluous, as the
674     # files in question are either no longer in blead, or now in ext/, dist/ or
675     # cpan/ and not copied into lib/
676
677     # Ignore version control directories.
678     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
679         $File::Find::prune = 1;
680         return;
681     }
682
683     # ignore patch backups, RCS files, emacs backup & temp files and the
684     # .exists files, .PL files, and test files.
685     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util\.pl$|^filter-util\.pl$|^uupacktool\.pl$|^\.gitignore$} ||
686               $dir  =~ m{/t(?:/|$)};
687     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
688     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
689     # the corelist script from lib/Module/CoreList/bin and ptar* in
690     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
691     # and zipdetails in cpan/IO-Compress/bin
692     # (they're installed later with other utils)
693     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|ptardiff|ptargrep|config_data|zipdetails)\z/;
694     # ignore the Makefiles
695     return if $name =~ /^makefile$/i;
696     # ignore the test extensions
697     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
698     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
699     # ignore the build support code
700     return if $name =~ /\bbuildcustomize\.pl$/;
701     # ignore the demo files
702     return if $dir =~ /\b(?:demos?|eg)\b/;
703     # ignore unneeded unicore files
704     if ( $dir =~ /^unicore/ ) {
705       if ( $name =~ /\.txt\z/ ) {
706         # We can ignore most, but not all .txt files
707         return unless $name =~ /\A(?:Blocks|SpecialCasing|NamedSequences)\.txt\z/;
708       }
709       else {
710         # TestProp only needed during testing
711         return if $name =~ /\ATestProp.pl\z/;
712         # we need version and *.pl files and can skip the rest
713         return unless $name =~ /\A(?:version|\w+\.p[lm])\z/;
714       }
715     }
716
717     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
718     # Changes.e2x and README.e2x are needed by enc2xs.
719     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
720     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
721     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
722     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
723     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
724     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
725
726     # if using a shared perl library then ignore:
727     # - static library files [of statically linked extensions];
728     # - import library files and export library files (only present on Win32
729     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
730     return if $Config{useshrplib} eq 'true' and
731              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
732
733     $name = "$dir/$name" if $dir ne '';
734
735     # ignore pods that are stand alone documentation from dual life modules.
736     return if /\.pod\z/ && is_duplicate_pod($_);
737
738     return if $name eq 'ExtUtils/XSSymSet.pm' and !$Is_VMS;
739
740     my $installlib = $installprivlib;
741     if ($dir =~ /^auto\// ||
742           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
743           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
744           $name=~/^Config_(heavy|git)\.pl\z/
745        ) {
746         $installlib = $installarchlib;
747         return unless $do_installarchlib;
748     } else {
749         return unless $do_installprivlib;
750     }
751
752     if ($Is_NetWare && !$opts{netware} && /\.(?:nlp|nlm|bs)$/) {
753         # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
754         # if copied will give problems when building new extensions.
755         # Has to be copied if we are installing on a NetWare server and
756         # hence the check !$opts{netware}
757         return;
758     }
759
760     if (-f $_) {
761         my $xname = "$installlib/$name";
762         $xname =~ s/^\Q$opts{destdir}\E//;
763         $packlist->{$xname} = { type => 'file' };
764         if ($opts{force} || compare($_, "$installlib/$name") || $opts{notify}) {
765             unlink("$installlib/$name");
766             mkpath("$installlib/$dir", $opts{verbose}, 0777);
767             # HP-UX (at least) needs to maintain execute permissions
768             # on dynamically-loaded libraries.
769             if (copy_if_diff($_, "$installlib/$name")) {
770                 strip("-S", "$installlib/$name")
771                     if $^O eq 'darwin' and /\.(?:so|$dlext|a)$/;
772                 chmod(/\.(so|$dlext)$/ ? 0555 : 0444, "$installlib/$name");
773             }
774         }
775     }
776 }
777
778 # Copy $from to $to, only if $from is different than $to.
779 # Also preserve modification times for .a libraries.
780 # On some systems, if you do
781 #   ranlib libperl.a
782 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
783 # and then try to link against the installed libperl.a, you might
784 # get an error message to the effect that the symbol table is older
785 # than the library.
786 # Return true if copying occurred.
787
788 sub copy_if_diff {
789     my($from,$to)=@_;
790     return 1 if (($^O eq 'VMS') && (-d $from));
791     my $xto = $to;
792     $xto =~ s/^\Q$opts{destdir}\E//;
793     my $perlpodbadsymlink;
794     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
795         -l $from &&
796         ! -e $from) {
797         # Some Linux implementations have problems traversing over
798         # multiple symlinks (when going over NFS?) and fail to read
799         # the symlink target.  Combine this with the fact that some
800         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
801         # and you end up with those pods not getting installed.
802         $perlpodbadsymlink = 1;
803     }
804     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
805     $packlist->{$xto} = { type => 'file' };
806     if ($opts{force} || compare($from, $to) || $opts{notify}) {
807         safe_unlink($to);   # In case we don't have write permissions.
808         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
809             $from = "README.$1";
810         }
811         copy($from, $to);
812         # Restore timestamps if it's a .a library or for OS/2.
813         if (!$opts{notify} && ($Is_OS2 || $to =~ /\.a$/)) {
814             my ($atime, $mtime) = (stat $from)[8,9];
815             utime $atime, $mtime, $to;
816         }
817         1;
818     }
819 }
820
821 sub strip
822 {
823     my(@args) = @_;
824
825     return unless $opts{strip};
826
827     my @opts;
828     while (@args && $args[0] =~ /^(-\w+)$/) {
829         push @opts, shift @args;
830     }
831
832     foreach my $file (@args) {
833         if (-f $file) {
834             if ($opts{verbose}) {
835                 print "  strip " . join(' ', @opts);
836                 print " " if (@opts);
837                 print "$file\n";
838             }
839             system("strip", @opts, $file);
840         } else {
841             print "# file '$file' skipped\n" if $opts{verbose};
842         }
843     }
844 }
845
846 # Local variables:
847 # cperl-indent-level: 4
848 # indent-tabs-mode: nil
849 # End:
850 #
851 # ex: set ts=8 sts=4 sw=4 et: