pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 Predefined Names
   8
   9 The following names have special meaning to Perl.  Most of the
  10 punctuational names have reasonable mnemonics, or analogues in one of
  11 the shells.  Nevertheless, if you wish to use the long variable names,
  12 you just need to say
  13
  14     use English;
  15
  16 at the top of your program.  This will alias all the short names to the
  17 long names in the current package.  Some of them even have medium names,
  18 generally borrowed from B<awk>.
  19
  20 To go a step further, those variables that depend on the currently
  21 selected filehandle may instead be set by calling an object method on
  22 the FileHandle object.  (Summary lines below for this contain the word
  23 HANDLE.)  First you must say
  24
  25     use FileHandle;
  26
  27 after which you may use either
  28
  29     method HANDLE EXPR
  30
  31 or
  32
  33     HANDLE->method(EXPR)
  34
  35 Each of the methods returns the old value of the FileHandle attribute.
  36 The methods each take an optional EXPR, which if supplied specifies the
  37 new value for the FileHandle attribute in question.  If not supplied,
  38 most of the methods do nothing to the current value, except for
  39 autoflush(), which will assume a 1 for you, just to be different.
  40
  41 A few of these variables are considered "read-only".  This means that if
  42 you try to assign to this variable, either directly or indirectly through
  43 a reference, you'll raise a run-time exception.
  44
  45 =over 8
  46
  47 =item $ARG
  48
  49 =item $_
  50
  51 The default input and pattern-searching space.  The following pairs are
  52 equivalent:
  53
  54     while (<>) {...}    # only equivalent in while!
  55     while ($_ = <>) {...}
  56
  57     /^Subject:/
  58     $_ =~ /^Subject:/
  59
  60     tr/a-z/A-Z/
  61     $_ =~ tr/a-z/A-Z/
  62
  63     chop
  64     chop($_)
  65
  66 Here are the places where Perl will assume $_ even if you
  67 don't use it:
  68
  69 =over 3
  70
  71 =item *
  72
  73 Various unary functions, including functions like ord() and int(), as well
  74 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
  75 STDIN.
  76
  77 =item *
  78
  79 Various list functions like print() and unlink().
  80
  81 =item *
  82
  83 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
  84 without an C<=~> operator.
  85
  86 =item *
  87
  88 The default iterator variable in a C<foreach> loop if no other
  89 variable is supplied.
  90
  91 =item *
  92
  93 The implicit iterator variable in the grep() and map() functions.
  94
  95 =item *
  96
  97 The default place to put an input record when a C<E<lt>FHE<gt>>
  98 operation's result is tested by itself as the sole criterion of a C<while>
  99 test.  Note that outside of a C<while> test, this will not happen.
 100
 101 =back
 102
 103 (Mnemonic: underline is understood in certain operations.)
 104
 105 =back
 106
 107 =over 8
 108
 109 =item $E<lt>I<digit>E<gt>
 110
 111 Contains the subpattern from the corresponding set of parentheses in
 112 the last pattern matched, not counting patterns matched in nested
 113 blocks that have been exited already.  (Mnemonic: like \digit.)
 114 These variables are all read-only.
 115
 116 =item $MATCH
 117
 118 =item $&
 119
 120 The string matched by the last successful pattern match (not counting
 121 any matches hidden within a BLOCK or eval() enclosed by the current
 122 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only.
 123
 124 =item $PREMATCH
 125
 126 =item $`
 127
 128 The string preceding whatever was matched by the last successful
 129 pattern match (not counting any matches hidden within a BLOCK or eval
 130 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
 131 string.)  This variable is read-only.
 132
 133 =item $POSTMATCH
 134
 135 =item $'
 136
 137 The string following whatever was matched by the last successful
 138 pattern match (not counting any matches hidden within a BLOCK or eval()
 139 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
 140 string.)  Example:
 141
 142     $_ = 'abcdefghi';
 143     /def/;
 144     print "$`:$&:$'\n";         # prints abc:def:ghi
 145
 146 This variable is read-only.
 147
 148 =item $LAST_PAREN_MATCH
 149
 150 =item $+
 151
 152 The last bracket matched by the last search pattern.  This is useful if
 153 you don't know which of a set of alternative patterns matched.  For
 154 example:
 155
 156     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
 157
 158 (Mnemonic: be positive and forward looking.)
 159 This variable is read-only.
 160
 161 =item $MULTILINE_MATCHING
 162
 163 =item $*
 164
 165 Set to 1 to do multiline matching within a string, 0 to tell Perl
 166 that it can assume that strings contain a single line, for the purpose
 167 of optimizing pattern matches.  Pattern matches on strings containing
 168 multiple newlines can produce confusing results when "C<$*>" is 0.  Default
 169 is 0.  (Mnemonic: * matches multiple things.)  Note that this variable
 170 only influences the interpretation of "C<^>" and "C<$>".  A literal newline can
 171 be searched for even when C<$* == 0>.
 172
 173 Use of "C<$*>" is deprecated in Perl 5.
 174
 175 =item input_line_number HANDLE EXPR
 176
 177 =item $INPUT_LINE_NUMBER
 178
 179 =item $NR
 180
 181 =item $.
 182
 183 The current input line number for the last file handle from
 184 which you read (or performed a C<seek> or C<tell> on).  An
 185 explicit close on a filehandle resets the line number.  Since
 186 "C<E<lt>E<gt>>" never does an explicit close, line numbers increase
 187 across ARGV files (but see examples under eof()).  Localizing C<$.> has
 188 the effect of also localizing Perl's notion of "the last read
 189 filehandle".  (Mnemonic: many programs use "." to mean the current line
 190 number.)
 191
 192 =item input_record_separator HANDLE EXPR
 193
 194 =item $INPUT_RECORD_SEPARATOR
 195
 196 =item $RS
 197
 198 =item $/
 199
 200 The input record separator, newline by default.  Works like B<awk>'s RS
 201 variable, including treating empty lines as delimiters if set to the
 202 null string.  (Note:  An empty line cannot contain any spaces or
 203 tabs.) You may set it to a multicharacter string to match a
 204 multi-character delimiter.  Note that setting it to C<"\n\n"> means
 205 something slightly different than setting it to C<"">, if the file
 206 contains consecutive empty lines.  Setting it to C<""> will treat two
 207 or more consecutive empty lines as a single empty line.  Setting it to
 208 C<"\n\n"> will blindly assume that the next input character belongs to
 209 the next paragraph, even if it's a newline.  (Mnemonic: / is used to
 210 delimit line boundaries when quoting poetry.)
 211
 212     undef $/;
 213     $_ = <FH>;          # whole file now here
 214     s/\n[ \t]+/ /g;
 215
 216 =item autoflush HANDLE EXPR
 217
 218 =item $OUTPUT_AUTOFLUSH
 219
 220 =item $|
 221
 222 If set to nonzero, forces a flush after every write or print on the
 223 currently selected output channel.  Default is 0 (regardless of whether
 224 the channel is actually buffered by the system or not; C<$|> only tells
 225 you whether you've asked Perl to explicitly flush after each write).
 226 Note that STDOUT will typically be line buffered if output is to the
 227 terminal and block buffered otherwise.  Setting this variable is useful
 228 primarily when you are outputting to a pipe, such as when you are running
 229 a Perl script under rsh and want to see the output as it's happening.  This
 230 has no effect on input buffering.
 231 (Mnemonic: when you want your pipes to be piping hot.)
 232
 233 =item output_field_separator HANDLE EXPR
 234
 235 =item $OUTPUT_FIELD_SEPARATOR
 236
 237 =item $OFS
 238
 239 =item $,
 240
 241 The output field separator for the print operator.  Ordinarily the
 242 print operator simply prints out the comma separated fields you
 243 specify.  In order to get behavior more like B<awk>, set this variable
 244 as you would set B<awk>'s OFS variable to specify what is printed
 245 between fields.  (Mnemonic: what is printed when there is a , in your
 246 print statement.)
 247
 248 =item output_record_separator HANDLE EXPR
 249
 250 =item $OUTPUT_RECORD_SEPARATOR
 251
 252 =item $ORS
 253
 254 =item $\
 255
 256 The output record separator for the print operator.  Ordinarily the
 257 print operator simply prints out the comma separated fields you
 258 specify, with no trailing newline or record separator assumed.  In
 259 order to get behavior more like B<awk>, set this variable as you would
 260 set B<awk>'s ORS variable to specify what is printed at the end of the
 261 print.  (Mnemonic: you set "C<$\>" instead of adding \n at the end of the
 262 print.  Also, it's just like C<$/>, but it's what you get "back" from
 263 Perl.)
 264
 265 =item $LIST_SEPARATOR
 266
 267 =item $"
 268
 269 This is like "C<$,>" except that it applies to array values interpolated
 270 into a double-quoted string (or similar interpreted string).  Default
 271 is a space.  (Mnemonic: obvious, I think.)
 272
 273 =item $SUBSCRIPT_SEPARATOR
 274
 275 =item $SUBSEP
 276
 277 =item $;
 278
 279 The subscript separator for multi-dimensional array emulation.  If you
 280 refer to a hash element as
 281
 282     $foo{$a,$b,$c}
 283
 284 it really means
 285
 286     $foo{join($;, $a, $b, $c)}
 287
 288 But don't put
 289
 290     @foo{$a,$b,$c}      # a slice--note the @
 291
 292 which means
 293
 294     ($foo{$a},$foo{$b},$foo{$c})
 295
 296 Default is "\034", the same as SUBSEP in B<awk>.  Note that if your
 297 keys contain binary data there might not be any safe value for "C<$;>".
 298 (Mnemonic: comma (the syntactic subscript separator) is a
 299 semi-semicolon.  Yeah, I know, it's pretty lame, but "C<$,>" is already
 300 taken for something more important.)
 301
 302 Consider using "real" multi-dimensional arrays in Perl 5.
 303
 304 =item $OFMT
 305
 306 =item $#
 307
 308 The output format for printed numbers.  This variable is a half-hearted
 309 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
 310 when B<awk> and Perl have differing notions of what is in fact
 311 numeric.  The initial value is %.I<n>g, where I<n> is the value
 312 of the macro DBL_DIG from your system's F<float.h>.  This is different from
 313 B<awk>'s default OFMT setting of %.6g, so you need to set "C<$#>"
 314 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
 315
 316 Use of "C<$#>" is deprecated in Perl 5.
 317
 318 =item format_page_number HANDLE EXPR
 319
 320 =item $FORMAT_PAGE_NUMBER
 321
 322 =item $%
 323
 324 The current page number of the currently selected output channel.
 325 (Mnemonic: % is page number in B<nroff>.)
 326
 327 =item format_lines_per_page HANDLE EXPR
 328
 329 =item $FORMAT_LINES_PER_PAGE
 330
 331 =item $=
 332
 333 The current page length (printable lines) of the currently selected
 334 output channel.  Default is 60.  (Mnemonic: = has horizontal lines.)
 335
 336 =item format_lines_left HANDLE EXPR
 337
 338 =item $FORMAT_LINES_LEFT
 339
 340 =item $-
 341
 342 The number of lines left on the page of the currently selected output
 343 channel.  (Mnemonic: lines_on_page - lines_printed.)
 344
 345 =item format_name HANDLE EXPR
 346
 347 =item $FORMAT_NAME
 348
 349 =item $~
 350
 351 The name of the current report format for the currently selected output
 352 channel.  Default is name of the filehandle.  (Mnemonic: brother to
 353 "C<$^>".)
 354
 355 =item format_top_name HANDLE EXPR
 356
 357 =item $FORMAT_TOP_NAME
 358
 359 =item $^
 360
 361 The name of the current top-of-page format for the currently selected
 362 output channel.  Default is name of the filehandle with _TOP
 363 appended.  (Mnemonic: points to top of page.)
 364
 365 =item format_line_break_characters HANDLE EXPR
 366
 367 =item $FORMAT_LINE_BREAK_CHARACTERS
 368
 369 =item $:
 370
 371 The current set of characters after which a string may be broken to
 372 fill continuation fields (starting with ^) in a format.  Default is
 373 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
 374 poetry is a part of a line.)
 375
 376 =item format_formfeed HANDLE EXPR
 377
 378 =item $FORMAT_FORMFEED
 379
 380 =item $^L
 381
 382 What formats output to perform a formfeed.  Default is \f.
 383
 384 =item $ACCUMULATOR
 385
 386 =item $^A
 387
 388 The current value of the write() accumulator for format() lines.  A format
 389 contains formline() commands that put their result into C<$^A>.  After
 390 calling its format, write() prints out the contents of C<$^A> and empties.
 391 So you never actually see the contents of C<$^A> unless you call
 392 formline() yourself and then look at it.  See L<perlform> and
 393 L<perlfunc/formline()>.
 394
 395 =item $CHILD_ERROR
 396
 397 =item $?
 398
 399 The status returned by the last pipe close, backtick (C<``>) command,
 400 or system() operator.  Note that this is the status word returned by
 401 the wait() system call, so the exit value of the subprocess is actually
 402 (C<$? E<gt>E<gt> 8>).  Thus on many systems, C<$? & 255> gives which signal,
 403 if any, the process died from, and whether there was a core dump.
 404 (Mnemonic: similar to B<sh> and B<ksh>.)
 405
 406 Inside an C<END> subroutine C<$?> contains the value that is going to be
 407 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
 408 change the exit status of the script.
 409
 410 =item $OS_ERROR
 411
 412 =item $ERRNO
 413
 414 =item $!
 415
 416 If used in a numeric context, yields the current value of errno, with
 417 all the usual caveats.  (This means that you shouldn't depend on the
 418 value of "C<$!>" to be anything in particular unless you've gotten a
 419 specific error return indicating a system error.)  If used in a string
 420 context, yields the corresponding system error string.  You can assign
 421 to "C<$!>" in order to set I<errno> if, for instance, you want "C<$!>" to return the
 422 string for error I<n>, or you want to set the exit value for the die()
 423 operator.  (Mnemonic: What just went bang?)
 424
 425 =item $EXTENDED_OS_ERROR
 426
 427 =item $^E
 428
 429 More specific information about the last system error than that
 430 provided by C<$!>, if available.  (If not, it's just C<$!> again, except under
 431 OS/2.)
 432 At the moment, this differs from C<$!> only under VMS and OS/2, where it
 433 provides the VMS status value from the last system error, and OS/2 error
 434 code of the last call to OS/2 API which was not directed via CRT.  The
 435 caveats mentioned in the description of C<$!> apply here, too.
 436 (Mnemonic: Extra error explanation.)
 437
 438 Note that under OS/2 C<$!> and C<$^E> do not track each other, so if an
 439 OS/2-specific call is performed, you may need to check both.
 440
 441 =item $EVAL_ERROR
 442
 443 =item $@
 444
 445 The Perl syntax error message from the last eval() command.  If null, the
 446 last eval() parsed and executed correctly (although the operations you
 447 invoked may have failed in the normal fashion).  (Mnemonic: Where was
 448 the syntax error "at"?)
 449
 450 Note that warning messages are not collected in this variable.  You can,
 451 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
 452 below.
 453
 454 =item $PROCESS_ID
 455
 456 =item $PID
 457
 458 =item $$
 459
 460 The process number of the Perl running this script.  (Mnemonic: same
 461 as shells.)
 462
 463 =item $REAL_USER_ID
 464
 465 =item $UID
 466
 467 =item $<
 468
 469 The real uid of this process.  (Mnemonic: it's the uid you came I<FROM>,
 470 if you're running setuid.)
 471
 472 =item $EFFECTIVE_USER_ID
 473
 474 =item $EUID
 475
 476 =item $>
 477
 478 The effective uid of this process.  Example:
 479
 480     $< = $>;            # set real to effective uid
 481     ($<,$>) = ($>,$<);  # swap real and effective uid
 482
 483 (Mnemonic: it's the uid you went I<TO>, if you're running setuid.)  Note:
 484 "C<$E<lt>>" and "C<$E<gt>>" can only be swapped on machines supporting setreuid().
 485
 486 =item $REAL_GROUP_ID
 487
 488 =item $GID
 489
 490 =item $(
 491
 492 The real gid of this process.  If you are on a machine that supports
 493 membership in multiple groups simultaneously, gives a space separated
 494 list of groups you are in.  The first number is the one returned by
 495 getgid(), and the subsequent ones by getgroups(), one of which may be
 496 the same as the first number.  (Mnemonic: parentheses are used to I<GROUP>
 497 things.  The real gid is the group you I<LEFT>, if you're running setgid.)
 498
 499 =item $EFFECTIVE_GROUP_ID
 500
 501 =item $EGID
 502
 503 =item $)
 504
 505 The effective gid of this process.  If you are on a machine that
 506 supports membership in multiple groups simultaneously, gives a space
 507 separated list of groups you are in.  The first number is the one
 508 returned by getegid(), and the subsequent ones by getgroups(), one of
 509 which may be the same as the first number.  (Mnemonic: parentheses are
 510 used to I<GROUP> things.  The effective gid is the group that's I<RIGHT> for
 511 you, if you're running setgid.)
 512
 513 Note: "C<$E<lt>>", "C<$E<gt>>", "C<$(>" and "C<$)>" can only be set on machines
 514 that support the corresponding I<set[re][ug]id()> routine.  "C<$(>" and "C<$)>"
 515 can only be swapped on machines supporting setregid().   Because Perl doesn't
 516 currently use initgroups(), you can't set your group vector to multiple groups.
 517
 518 =item $PROGRAM_NAME
 519
 520 =item $0
 521
 522 Contains the name of the file containing the Perl script being
 523 executed.  Assigning to "C<$0>" modifies the argument area that the ps(1)
 524 program sees.  This is more useful as a way of indicating the
 525 current program state than it is for hiding the program you're running.
 526 (Mnemonic: same as B<sh> and B<ksh>.)
 527
 528 =item $[
 529
 530 The index of the first element in an array, and of the first character
 531 in a substring.  Default is 0, but you could set it to 1 to make
 532 Perl behave more like B<awk> (or Fortran) when subscripting and when
 533 evaluating the index() and substr() functions.  (Mnemonic: [ begins
 534 subscripts.)
 535
 536 As of Perl 5, assignment to "C<$[>" is treated as a compiler directive,
 537 and cannot influence the behavior of any other file.  Its use is
 538 discouraged.
 539
 540 =item $PERL_VERSION
 541
 542 =item $]
 543
 544 The string printed out when you say C<perl -v>.
 545 (This is currently I<BROKEN>).
 546 It can be used to
 547 determine at the beginning of a script whether the perl interpreter
 548 executing the script is in the right range of versions.  If used in a
 549 numeric context, returns the version + patchlevel / 1000.  Example:
 550
 551     # see if getc is available
 552     ($version,$patchlevel) =
 553              $] =~ /(\d+\.\d+).*\nPatch level: (\d+)/;
 554     print STDERR "(No filename completion available.)\n"
 555              if $version * 1000 + $patchlevel < 2016;
 556
 557 or, used numerically,
 558
 559     warn "No checksumming!\n" if $] < 3.019;
 560
 561 (Mnemonic: Is this version of perl in the right bracket?)
 562
 563 =item $DEBUGGING
 564
 565 =item $^D
 566
 567 The current value of the debugging flags.  (Mnemonic: value of B<-D>
 568 switch.)
 569
 570 =item $SYSTEM_FD_MAX
 571
 572 =item $^F
 573
 574 The maximum system file descriptor, ordinarily 2.  System file
 575 descriptors are passed to exec()ed processes, while higher file
 576 descriptors are not.  Also, during an open(), system file descriptors are
 577 preserved even if the open() fails.  (Ordinary file descriptors are
 578 closed before the open() is attempted.)  Note that the close-on-exec
 579 status of a file descriptor will be decided according to the value of
 580 C<$^F> at the time of the open, not the time of the exec.
 581
 582 =item $^H
 583
 584 The current set of syntax checks enabled by C<use strict>.  See the
 585 documentation of C<strict> for more details.
 586
 587 =item $INPLACE_EDIT
 588
 589 =item $^I
 590
 591 The current value of the inplace-edit extension.  Use C<undef> to disable
 592 inplace editing.  (Mnemonic: value of B<-i> switch.)
 593
 594 =item $OSNAME
 595
 596 =item $^O
 597
 598 The name of the operating system under which this copy of Perl was
 599 built, as determined during the configuration process.  The value
 600 is identical to C<$Config{'osname'}>.
 601
 602 =item $PERLDB
 603
 604 =item $^P
 605
 606 The internal flag that the debugger clears so that it doesn't debug
 607 itself.  You could conceivably disable debugging yourself by clearing
 608 it.
 609
 610 =item $BASETIME
 611
 612 =item $^T
 613
 614 The time at which the script began running, in seconds since the
 615 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>
 616 and B<-C> filetests are
 617 based on this value.
 618
 619 =item $WARNING
 620
 621 =item $^W
 622
 623 The current value of the warning switch, either TRUE or FALSE.
 624 (Mnemonic: related to the B<-w> switch.)
 625
 626 =item $EXECUTABLE_NAME
 627
 628 =item $^X
 629
 630 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
 631
 632 =item $ARGV
 633
 634 contains the name of the current file when reading from E<lt>E<gt>.
 635
 636 =item @ARGV
 637
 638 The array @ARGV contains the command line arguments intended for the
 639 script.  Note that C<$#ARGV> is the generally number of arguments minus
 640 one, since C<$ARGV[0]> is the first argument, I<NOT> the command name.  See
 641 "C<$0>" for the command name.
 642
 643 =item @INC
 644
 645 The array @INC contains the list of places to look for Perl scripts to
 646 be evaluated by the C<do EXPR>, C<require>, or C<use> constructs.  It
 647 initially consists of the arguments to any B<-I> command line switches,
 648 followed by the default Perl library, probably F</usr/local/lib/perl>,
 649 followed by ".", to represent the current directory.  If you need to
 650 modify this at runtime, you should use the C<use lib> pragma in order
 651 to also get the machine-dependent library properly loaded:
 652
 653     use lib '/mypath/libdir/';
 654     use SomeMod;
 655
 656 =item %INC
 657
 658 The hash %INC contains entries for each filename that has
 659 been included via C<do> or C<require>.  The key is the filename you
 660 specified, and the value is the location of the file actually found.
 661 The C<require> command uses this array to determine whether a given file
 662 has already been included.
 663
 664 =item $ENV{expr}
 665
 666 The hash %ENV contains your current environment.  Setting a
 667 value in C<ENV> changes the environment for child processes.
 668
 669 =item $SIG{expr}
 670
 671 The hash %SIG is used to set signal handlers for various
 672 signals.  Example:
 673
 674     sub handler {       # 1st argument is signal name
 675         local($sig) = @_;
 676         print "Caught a SIG$sig--shutting down\n";
 677         close(LOG);
 678         exit(0);
 679     }
 680
 681     $SIG{'INT'} = 'handler';
 682     $SIG{'QUIT'} = 'handler';
 683     ...
 684     $SIG{'INT'} = 'DEFAULT';    # restore default action
 685     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 686
 687 The %SIG array only contains values for the signals actually set within
 688 the Perl script.  Here are some other examples:
 689
 690     $SIG{PIPE} = Plumber;       # SCARY!!
 691     $SIG{"PIPE"} = "Plumber";   # just fine, assumes main::Plumber
 692     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
 693     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
 694
 695 The one marked scary is problematic because it's a bareword, which means
 696 sometimes it's a string representing the function, and sometimes it's
 697 going to call the subroutine call right then and there!  Best to be sure
 698 and quote it or take a reference to it.  *Plumber works too.  See L<perlsub>.
 699
 700 Certain internal hooks can be also set using the %SIG hash.  The
 701 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
 702 about to be printed.  The warning message is passed as the first
 703 argument.  The presence of a __WARN__ hook causes the ordinary printing
 704 of warnings to STDERR to be suppressed.  You can use this to save warnings
 705 in a variable, or turn warnings into fatal errors, like this:
 706
 707     local $SIG{__WARN__} = sub { die $_[0] };
 708     eval $proggie;
 709
 710 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
 711 is about to be thrown.  The error message is passed as the first
 712 argument.  When a __DIE__ hook routine returns, the exception
 713 processing continues as it would have in the absence of the hook,
 714 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
 715 The __DIE__ handler is explicitly disabled during the call, so that you
 716 can die from a __DIE__ handler.  Similarly for __WARN__.
 717
 718 =back