This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
6a073bae9f6e41ba7b2be9c1ed079f25c0cab179
[perl5.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of line only at the left and right ends of the string to
35 matching them anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in an inverted bracketed
76 character class, which otherwise could be highly confusing.  See
77 L<perlrecharclass/Negation>.
78
79 Another bug involves character classes that match both a sequence of
80 multiple characters, and an initial sub-string of that sequence.  For
81 example,
82
83  /[s\xDF]/i
84
85 should match both a single and a double "s", since C<\xDF> (on ASCII
86 platforms) matches "ss".  However, this bug
87 (L<[perl #89774]|https://rt.perl.org/rt3/Ticket/Display.html?id=89774>)
88 causes it to only match a single "s", even if the final larger match
89 fails, and matching the double "ss" would have succeeded.
90
91 Also, Perl matching doesn't fully conform to the current Unicode C</i>
92 recommendations, which ask that the matching be made upon the NFD
93 (Normalization Form Decomposed) of the text.  However, Unicode is
94 in the process of reconsidering and revising their recommendations.
95
96 =item x
97 X</x>
98
99 Extend your pattern's legibility by permitting whitespace and comments.
100 Details in L</"/x">
101
102 =item p
103 X</p> X<regex, preserve> X<regexp, preserve>
104
105 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
106 ${^POSTMATCH} are available for use after matching.
107
108 =item g and c
109 X</g> X</c>
110
111 Global matching, and keep the Current position after failed matching.
112 Unlike i, m, s and x, these two flags affect the way the regex is used
113 rather than the regex itself. See
114 L<perlretut/"Using regular expressions in Perl"> for further explanation
115 of the g and c modifiers.
116
117 =item a, d, l and u
118 X</a> X</d> X</l> X</u>
119
120 These modifiers, all new in 5.14, affect which character-set semantics
121 (Unicode, etc.) are used, as described below in
122 L</Character set modifiers>.
123
124 =back
125
126 Regular expression modifiers are usually written in documentation
127 as e.g., "the C</x> modifier", even though the delimiter
128 in question might not really be a slash.  The modifiers C</imsxadlup>
129 may also be embedded within the regular expression itself using
130 the C<(?...)> construct, see L</Extended Patterns> below.
131
132 =head3 /x
133
134 C</x> tells
135 the regular expression parser to ignore most whitespace that is neither
136 backslashed nor within a character class.  You can use this to break up
137 your regular expression into (slightly) more readable parts.  The C<#>
138 character is also treated as a metacharacter introducing a comment,
139 just as in ordinary Perl code.  This also means that if you want real
140 whitespace or C<#> characters in the pattern (outside a character
141 class, where they are unaffected by C</x>), then you'll either have to
142 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
143 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
144 making Perl's regular expressions more readable.  Note that you have to
145 be careful not to include the pattern delimiter in the comment--perl has
146 no way of knowing you did not intend to close the pattern early.  See
147 the C-comment deletion code in L<perlop>.  Also note that anything inside
148 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
149 space interpretation within a single multi-character construct.  For
150 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
151 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
152 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
153 but can between the C<(> and C<?>.  Within any delimiters for such a
154 construct, allowed spaces are not affected by C</x>, and depend on the
155 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
156 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
157 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
158 L<perluniprops/Properties accessible through \p{} and \P{}>.
159 X</x>
160
161 =head3 Character set modifiers
162
163 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
164 the character set modifiers; they affect the character set semantics
165 used for the regular expression.
166
167 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
168 to you, and so you need not worry about them very much.  They exist for
169 Perl's internal use, so that complex regular expression data structures
170 can be automatically serialized and later exactly reconstituted,
171 including all their nuances.  But, since Perl can't keep a secret, and
172 there may be rare instances where they are useful, they are documented
173 here.
174
175 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
176 allow code that is to work mostly on ASCII data to not have to concern
177 itself with Unicode.
178
179 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
180 effect at the time of the execution of the pattern match.
181
182 C</u> sets the character set to B<U>nicode.
183
184 C</a> also sets the character set to Unicode, BUT adds several
185 restrictions for B<A>SCII-safe matching.
186
187 C</d> is the old, problematic, pre-5.14 B<D>efault character set
188 behavior.  Its only use is to force that old behavior.
189
190 At any given time, exactly one of these modifiers is in effect.  Their
191 existence allows Perl to keep the originally compiled behavior of a
192 regular expression, regardless of what rules are in effect when it is
193 actually executed.  And if it is interpolated into a larger regex, the
194 original's rules continue to apply to it, and only it.
195
196 The C</l> and C</u> modifiers are automatically selected for
197 regular expressions compiled within the scope of various pragmas,
198 and we recommend that in general, you use those pragmas instead of
199 specifying these modifiers explicitly.  For one thing, the modifiers
200 affect only pattern matching, and do not extend to even any replacement
201 done, whereas using the pragmas give consistent results for all
202 appropriate operations within their scopes.  For example,
203
204  s/foo/\Ubar/il
205
206 will match "foo" using the locale's rules for case-insensitive matching,
207 but the C</l> does not affect how the C<\U> operates.  Most likely you
208 want both of them to use locale rules.  To do this, instead compile the
209 regular expression within the scope of C<use locale>.  This both
210 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
211 lesson is to C<use locale> and not C</l> explicitly.
212
213 Similarly, it would be better to use C<use feature 'unicode_strings'>
214 instead of,
215
216  s/foo/\Lbar/iu
217
218 to get Unicode rules, as the C<\L> in the former (but not necessarily
219 the latter) would also use Unicode rules.
220
221 More detail on each of the modifiers follows.  Most likely you don't
222 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
223 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
224
225 =head4 /l
226
227 means to use the current locale's rules (see L<perllocale>) when pattern
228 matching.  For example, C<\w> will match the "word" characters of that
229 locale, and C<"/i"> case-insensitive matching will match according to
230 the locale's case folding rules.  The locale used will be the one in
231 effect at the time of execution of the pattern match.  This may not be
232 the same as the compilation-time locale, and can differ from one match
233 to another if there is an intervening call of the
234 L<setlocale() function|perllocale/The setlocale function>.
235
236 Perl only supports single-byte locales.  This means that code points
237 above 255 are treated as Unicode no matter what locale is in effect.
238 Under Unicode rules, there are a few case-insensitive matches that cross
239 the 255/256 boundary.  These are disallowed under C</l>.  For example,
240 0xFF (on ASCII platforms) does not caselessly match the character at
241 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
242 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
243 has no way of knowing if that character even exists in the locale, much
244 less what code point it is.
245
246 This modifier may be specified to be the default by C<use locale>, but
247 see L</Which character set modifier is in effect?>.
248 X</l>
249
250 =head4 /u
251
252 means to use Unicode rules when pattern matching.  On ASCII platforms,
253 this means that the code points between 128 and 255 take on their
254 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
255 (Otherwise Perl considers their meanings to be undefined.)  Thus,
256 under this modifier, the ASCII platform effectively becomes a Unicode
257 platform; and hence, for example, C<\w> will match any of the more than
258 100_000 word characters in Unicode.
259
260 Unlike most locales, which are specific to a language and country pair,
261 Unicode classifies all the characters that are letters I<somewhere> in
262 the world as
263 C<\w>.  For example, your locale might not think that C<LATIN SMALL
264 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
265 Unicode does.  Similarly, all the characters that are decimal digits
266 somewhere in the world will match C<\d>; this is hundreds, not 10,
267 possible matches.  And some of those digits look like some of the 10
268 ASCII digits, but mean a different number, so a human could easily think
269 a number is a different quantity than it really is.  For example,
270 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
271 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
272 that are a mixture from different writing systems, creating a security
273 issue.  L<Unicode::UCD/num()> can be used to sort
274 this out.  Or the C</a> modifier can be used to force C<\d> to match
275 just the ASCII 0 through 9.
276
277 Also, under this modifier, case-insensitive matching works on the full
278 set of Unicode
279 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
280 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
281 if you're not prepared, might make it look like a hexadecimal constant,
282 presenting another potential security issue.  See
283 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
284 security issues.
285
286 On the EBCDIC platforms that Perl handles, the native character set is
287 equivalent to Latin-1.  Thus this modifier changes behavior only when
288 the C<"/i"> modifier is also specified, and it turns out it affects only
289 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
290 will match the Greek capital and small letters C<MU>, otherwise not; and
291 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
292 C<sS>, and C<ss>, otherwise not.
293
294 This modifier may be specified to be the default by C<use feature
295 'unicode_strings>, C<use locale ':not_characters'>, or
296 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
297 but see L</Which character set modifier is in effect?>.
298 X</u>
299
300 =head4 /d
301
302 This modifier means to use the "Default" native rules of the platform
303 except when there is cause to use Unicode rules instead, as follows:
304
305 =over 4
306
307 =item 1
308
309 the target string is encoded in UTF-8; or
310
311 =item 2
312
313 the pattern is encoded in UTF-8; or
314
315 =item 3
316
317 the pattern explicitly mentions a code point that is above 255 (say by
318 C<\x{100}>); or
319
320 =item 4
321
322 the pattern uses a Unicode name (C<\N{...}>);  or
323
324 =item 5
325
326 the pattern uses a Unicode property (C<\p{...}>)
327
328 =back
329
330 Another mnemonic for this modifier is "Depends", as the rules actually
331 used depend on various things, and as a result you can get unexpected
332 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
333 become rather infamous, leading to yet another (printable) name for this
334 modifier, "Dodgy".
335
336 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
337 (at least the ones that Perl handles), they are Latin-1.
338
339 Here are some examples of how that works on an ASCII platform:
340
341  $str =  "\xDF";      # $str is not in UTF-8 format.
342  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
343  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
344  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
345  chop $str;
346  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
347
348 This modifier is automatically selected by default when none of the
349 others are, so yet another name for it is "Default".
350
351 Because of the unexpected behaviors associated with this modifier, you
352 probably should only use it to maintain weird backward compatibilities.
353
354 =head4 /a (and /aa)
355
356 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
357 unlike the others, may be doubled-up to increase its effect.
358
359 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
360 the Posix character classes to match only in the ASCII range.  They thus
361 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
362 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
363 characters C<[ \f\n\r\t]>; C<\w> means the 63 characters
364 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
365 C<[[:print:]]> match only the appropriate ASCII-range characters.
366
367 This modifier is useful for people who only incidentally use Unicode,
368 and who do not wish to be burdened with its complexities and security
369 concerns.
370
371 With C</a>, one can write C<\d> with confidence that it will only match
372 ASCII characters, and should the need arise to match beyond ASCII, you
373 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
374 similar C<\p{...}> constructs that can match beyond ASCII both white
375 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
376 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
377 doesn't mean you can't use Unicode, it means that to get Unicode
378 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
379 signals Unicode.
380
381 As you would expect, this modifier causes, for example, C<\D> to mean
382 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
383 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
384 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
385 for C<\B>).
386
387 Otherwise, C</a> behaves like the C</u> modifier, in that
388 case-insensitive matching uses Unicode semantics; for example, "k" will
389 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
390 points in the Latin1 range, above ASCII will have Unicode rules when it
391 comes to case-insensitive matching.
392
393 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
394 specify the "a" twice, for example C</aai> or C</aia>.  (The first
395 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
396 adds the C</i> restrictions.)  But, note that code points outside the
397 ASCII range will use Unicode rules for C</i> matching, so the modifier
398 doesn't really restrict things to just ASCII; it just forbids the
399 intermixing of ASCII and non-ASCII.
400
401 To summarize, this modifier provides protection for applications that
402 don't wish to be exposed to all of Unicode.  Specifying it twice
403 gives added protection.
404
405 This modifier may be specified to be the default by C<use re '/a'>
406 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
407 the C</u> modifier explictly if there are a few regular expressions
408 where you do want full Unicode rules (but even here, it's best if
409 everything were under feature C<"unicode_strings">, along with the
410 C<use re '/aa'>).  Also see L</Which character set modifier is in
411 effect?>.
412 X</a>
413 X</aa>
414
415 =head4 Which character set modifier is in effect?
416
417 Which of these modifiers is in effect at any given point in a regular
418 expression depends on a fairly complex set of interactions.  These have
419 been designed so that in general you don't have to worry about it, but
420 this section gives the gory details.  As
421 explained below in L</Extended Patterns> it is possible to explicitly
422 specify modifiers that apply only to portions of a regular expression.
423 The innermost always has priority over any outer ones, and one applying
424 to the whole expression has priority over any of the default settings that are
425 described in the remainder of this section.
426
427 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
428 default modifiers (including these) for regular expressions compiled
429 within its scope.  This pragma has precedence over the other pragmas
430 listed below that also change the defaults.
431
432 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
433 and C<L<use feature 'unicode_strings|feature>>, or
434 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
435 C</u> when not in the same scope as either C<L<use locale|perllocale>>
436 or C<L<use bytes|bytes>>.
437 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
438 sets the default to C</u>, overriding any plain C<use locale>.)
439 Unlike the mechanisms mentioned above, these
440 affect operations besides regular expressions pattern matching, and so
441 give more consistent results with other operators, including using
442 C<\U>, C<\l>, etc. in substitution replacements.
443
444 If none of the above apply, for backwards compatibility reasons, the
445 C</d> modifier is the one in effect by default.  As this can lead to
446 unexpected results, it is best to specify which other rule set should be
447 used.
448
449 =head4 Character set modifier behavior prior to Perl 5.14
450
451 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
452 for regexes compiled within the scope of C<use locale>, and C</d> was
453 implied otherwise.  However, interpolating a regex into a larger regex
454 would ignore the original compilation in favor of whatever was in effect
455 at the time of the second compilation.  There were a number of
456 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
457 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
458 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
459
460 =head2 Regular Expressions
461
462 =head3 Metacharacters
463
464 The patterns used in Perl pattern matching evolved from those supplied in
465 the Version 8 regex routines.  (The routines are derived
466 (distantly) from Henry Spencer's freely redistributable reimplementation
467 of the V8 routines.)  See L<Version 8 Regular Expressions> for
468 details.
469
470 In particular the following metacharacters have their standard I<egrep>-ish
471 meanings:
472 X<metacharacter>
473 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
474
475
476     \        Quote the next metacharacter
477     ^        Match the beginning of the line
478     .        Match any character (except newline)
479     $        Match the end of the line (or before newline at the end)
480     |        Alternation
481     ()       Grouping
482     []       Bracketed Character class
483
484 By default, the "^" character is guaranteed to match only the
485 beginning of the string, the "$" character only the end (or before the
486 newline at the end), and Perl does certain optimizations with the
487 assumption that the string contains only one line.  Embedded newlines
488 will not be matched by "^" or "$".  You may, however, wish to treat a
489 string as a multi-line buffer, such that the "^" will match after any
490 newline within the string (except if the newline is the last character in
491 the string), and "$" will match before any newline.  At the
492 cost of a little more overhead, you can do this by using the /m modifier
493 on the pattern match operator.  (Older programs did this by setting C<$*>,
494 but this option was removed in perl 5.10.)
495 X<^> X<$> X</m>
496
497 To simplify multi-line substitutions, the "." character never matches a
498 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
499 the string is a single line--even if it isn't.
500 X<.> X</s>
501
502 =head3 Quantifiers
503
504 The following standard quantifiers are recognized:
505 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
506
507     *           Match 0 or more times
508     +           Match 1 or more times
509     ?           Match 1 or 0 times
510     {n}         Match exactly n times
511     {n,}        Match at least n times
512     {n,m}       Match at least n but not more than m times
513
514 (If a curly bracket occurs in any other context and does not form part of
515 a backslashed sequence like C<\x{...}>, it is treated
516 as a regular character.  In particular, the lower quantifier bound
517 is not optional.  However, in Perl v5.18, it is planned to issue a
518 deprecation warning for all such occurrences, and in Perl v5.20 to
519 require literal uses of a curly bracket to be escaped, say by preceding
520 them with a backslash or enclosing them within square brackets, (C<"\{">
521 or C<"[{]">).  This change will allow for future syntax extensions (like
522 making the lower bound of a quantifier optional), and better error
523 checking of quantifiers.  Now, a typo in a quantifier silently causes
524 it to be treated as the literal characters.  For example,
525
526     /o{4,3}/
527
528 looks like a quantifier that matches 0 times, since 4 is greater than 3,
529 but it really means to match the sequence of six characters
530 S<C<"o { 4 , 3 }">>.)
531
532 The "*" quantifier is equivalent to C<{0,}>, the "+"
533 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
534 to non-negative integral values less than a preset limit defined when perl is built.
535 This is usually 32766 on the most common platforms.  The actual limit can
536 be seen in the error message generated by code such as this:
537
538     $_ **= $_ , / {$_} / for 2 .. 42;
539
540 By default, a quantified subpattern is "greedy", that is, it will match as
541 many times as possible (given a particular starting location) while still
542 allowing the rest of the pattern to match.  If you want it to match the
543 minimum number of times possible, follow the quantifier with a "?".  Note
544 that the meanings don't change, just the "greediness":
545 X<metacharacter> X<greedy> X<greediness>
546 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
547
548     *?        Match 0 or more times, not greedily
549     +?        Match 1 or more times, not greedily
550     ??        Match 0 or 1 time, not greedily
551     {n}?      Match exactly n times, not greedily (redundant)
552     {n,}?     Match at least n times, not greedily
553     {n,m}?    Match at least n but not more than m times, not greedily
554
555 By default, when a quantified subpattern does not allow the rest of the
556 overall pattern to match, Perl will backtrack. However, this behaviour is
557 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
558 as well.
559
560  *+     Match 0 or more times and give nothing back
561  ++     Match 1 or more times and give nothing back
562  ?+     Match 0 or 1 time and give nothing back
563  {n}+   Match exactly n times and give nothing back (redundant)
564  {n,}+  Match at least n times and give nothing back
565  {n,m}+ Match at least n but not more than m times and give nothing back
566
567 For instance,
568
569    'aaaa' =~ /a++a/
570
571 will never match, as the C<a++> will gobble up all the C<a>'s in the
572 string and won't leave any for the remaining part of the pattern. This
573 feature can be extremely useful to give perl hints about where it
574 shouldn't backtrack. For instance, the typical "match a double-quoted
575 string" problem can be most efficiently performed when written as:
576
577    /"(?:[^"\\]++|\\.)*+"/
578
579 as we know that if the final quote does not match, backtracking will not
580 help. See the independent subexpression
581 L</C<< (?>pattern) >>> for more details;
582 possessive quantifiers are just syntactic sugar for that construct. For
583 instance the above example could also be written as follows:
584
585    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
586
587 =head3 Escape sequences
588
589 Because patterns are processed as double-quoted strings, the following
590 also work:
591
592  \t          tab                   (HT, TAB)
593  \n          newline               (LF, NL)
594  \r          return                (CR)
595  \f          form feed             (FF)
596  \a          alarm (bell)          (BEL)
597  \e          escape (think troff)  (ESC)
598  \cK         control char          (example: VT)
599  \x{}, \x00  character whose ordinal is the given hexadecimal number
600  \N{name}    named Unicode character or character sequence
601  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
602  \o{}, \000  character whose ordinal is the given octal number
603  \l          lowercase next char (think vi)
604  \u          uppercase next char (think vi)
605  \L          lowercase till \E (think vi)
606  \U          uppercase till \E (think vi)
607  \Q          quote (disable) pattern metacharacters till \E
608  \E          end either case modification or quoted section, think vi
609
610 Details are in L<perlop/Quote and Quote-like Operators>.
611
612 =head3 Character Classes and other Special Escapes
613
614 In addition, Perl defines the following:
615 X<\g> X<\k> X<\K> X<backreference>
616
617  Sequence   Note    Description
618   [...]     [1]  Match a character according to the rules of the
619                    bracketed character class defined by the "...".
620                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
621   [[:...:]] [2]  Match a character according to the rules of the POSIX
622                    character class "..." within the outer bracketed
623                    character class.  Example: [[:upper:]] matches any
624                    uppercase character.
625   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
626                    other connector punctuation chars plus Unicode
627                    marks)
628   \W        [3]  Match a non-"word" character
629   \s        [3]  Match a whitespace character
630   \S        [3]  Match a non-whitespace character
631   \d        [3]  Match a decimal digit character
632   \D        [3]  Match a non-digit character
633   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
634   \PP       [3]  Match non-P
635   \X        [4]  Match Unicode "eXtended grapheme cluster"
636   \C             Match a single C-language char (octet) even if that is
637                    part of a larger UTF-8 character.  Thus it breaks up
638                    characters into their UTF-8 bytes, so you may end up
639                    with malformed pieces of UTF-8.  Unsupported in
640                    lookbehind.
641   \1        [5]  Backreference to a specific capture group or buffer.
642                    '1' may actually be any positive integer.
643   \g1       [5]  Backreference to a specific or previous group,
644   \g{-1}    [5]  The number may be negative indicating a relative
645                    previous group and may optionally be wrapped in
646                    curly brackets for safer parsing.
647   \g{name}  [5]  Named backreference
648   \k<name>  [5]  Named backreference
649   \K        [6]  Keep the stuff left of the \K, don't include it in $&
650   \N        [7]  Any character but \n (experimental).  Not affected by
651                    /s modifier
652   \v        [3]  Vertical whitespace
653   \V        [3]  Not vertical whitespace
654   \h        [3]  Horizontal whitespace
655   \H        [3]  Not horizontal whitespace
656   \R        [4]  Linebreak
657
658 =over 4
659
660 =item [1]
661
662 See L<perlrecharclass/Bracketed Character Classes> for details.
663
664 =item [2]
665
666 See L<perlrecharclass/POSIX Character Classes> for details.
667
668 =item [3]
669
670 See L<perlrecharclass/Backslash sequences> for details.
671
672 =item [4]
673
674 See L<perlrebackslash/Misc> for details.
675
676 =item [5]
677
678 See L</Capture groups> below for details.
679
680 =item [6]
681
682 See L</Extended Patterns> below for details.
683
684 =item [7]
685
686 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
687 character or character sequence whose name is C<NAME>; and similarly
688 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
689 code point is I<hex>.  Otherwise it matches any character but C<\n>.
690
691 =back
692
693 =head3 Assertions
694
695 Perl defines the following zero-width assertions:
696 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
697 X<regexp, zero-width assertion>
698 X<regular expression, zero-width assertion>
699 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
700
701     \b  Match a word boundary
702     \B  Match except at a word boundary
703     \A  Match only at beginning of string
704     \Z  Match only at end of string, or before newline at the end
705     \z  Match only at end of string
706     \G  Match only at pos() (e.g. at the end-of-match position
707         of prior m//g)
708
709 A word boundary (C<\b>) is a spot between two characters
710 that has a C<\w> on one side of it and a C<\W> on the other side
711 of it (in either order), counting the imaginary characters off the
712 beginning and end of the string as matching a C<\W>.  (Within
713 character classes C<\b> represents backspace rather than a word
714 boundary, just as it normally does in any double-quoted string.)
715 The C<\A> and C<\Z> are just like "^" and "$", except that they
716 won't match multiple times when the C</m> modifier is used, while
717 "^" and "$" will match at every internal line boundary.  To match
718 the actual end of the string and not ignore an optional trailing
719 newline, use C<\z>.
720 X<\b> X<\A> X<\Z> X<\z> X</m>
721
722 The C<\G> assertion can be used to chain global matches (using
723 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
724 It is also useful when writing C<lex>-like scanners, when you have
725 several patterns that you want to match against consequent substrings
726 of your string; see the previous reference.  The actual location
727 where C<\G> will match can also be influenced by using C<pos()> as
728 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
729 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
730 is modified somewhat, in that contents to the left of C<\G> are
731 not counted when determining the length of the match. Thus the following
732 will not match forever:
733 X<\G>
734
735      my $string = 'ABC';
736      pos($string) = 1;
737      while ($string =~ /(.\G)/g) {
738          print $1;
739      }
740
741 It will print 'A' and then terminate, as it considers the match to
742 be zero-width, and thus will not match at the same position twice in a
743 row.
744
745 It is worth noting that C<\G> improperly used can result in an infinite
746 loop. Take care when using patterns that include C<\G> in an alternation.
747
748 =head3 Capture groups
749
750 The bracketing construct C<( ... )> creates capture groups (also referred to as
751 capture buffers). To refer to the current contents of a group later on, within
752 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
753 for the second, and so on.
754 This is called a I<backreference>.
755 X<regex, capture buffer> X<regexp, capture buffer>
756 X<regex, capture group> X<regexp, capture group>
757 X<regular expression, capture buffer> X<backreference>
758 X<regular expression, capture group> X<backreference>
759 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
760 X<named capture buffer> X<regular expression, named capture buffer>
761 X<named capture group> X<regular expression, named capture group>
762 X<%+> X<$+{name}> X<< \k<name> >>
763 There is no limit to the number of captured substrings that you may use.
764 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
765 a group did not match, the associated backreference won't match either. (This
766 can happen if the group is optional, or in a different branch of an
767 alternation.)
768 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
769 this form, described below.
770
771 You can also refer to capture groups relatively, by using a negative number, so
772 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
773 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
774 example:
775
776         /
777          (Y)            # group 1
778          (              # group 2
779             (X)         # group 3
780             \g{-1}      # backref to group 3
781             \g{-3}      # backref to group 1
782          )
783         /x
784
785 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
786 interpolate regexes into larger regexes and not have to worry about the
787 capture groups being renumbered.
788
789 You can dispense with numbers altogether and create named capture groups.
790 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
791 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
792 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
793 I<name> must not begin with a number, nor contain hyphens.
794 When different groups within the same pattern have the same name, any reference
795 to that name assumes the leftmost defined group.  Named groups count in
796 absolute and relative numbering, and so can also be referred to by those
797 numbers.
798 (It's possible to do things with named capture groups that would otherwise
799 require C<(??{})>.)
800
801 Capture group contents are dynamically scoped and available to you outside the
802 pattern until the end of the enclosing block or until the next successful
803 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
804 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
805 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
806
807 Braces are required in referring to named capture groups, but are optional for
808 absolute or relative numbered ones.  Braces are safer when creating a regex by
809 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
810 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
811 is probably not what you intended.
812
813 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
814 there were no named nor relative numbered capture groups.  Absolute numbered
815 groups were referred to using C<\1>,
816 C<\2>, etc., and this notation is still
817 accepted (and likely always will be).  But it leads to some ambiguities if
818 there are more than 9 capture groups, as C<\10> could mean either the tenth
819 capture group, or the character whose ordinal in octal is 010 (a backspace in
820 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
821 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
822 a backreference only if at least 11 left parentheses have opened before it.
823 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
824 There are several examples below that illustrate these perils.  You can avoid
825 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
826 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
827 digits padded with leading zeros, since a leading zero implies an octal
828 constant.
829
830 The C<\I<digit>> notation also works in certain circumstances outside
831 the pattern.  See L</Warning on \1 Instead of $1> below for details.
832
833 Examples:
834
835     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
836
837     /(.)\g1/                        # find first doubled char
838          and print "'$1' is the first doubled character\n";
839
840     /(?<char>.)\k<char>/            # ... a different way
841          and print "'$+{char}' is the first doubled character\n";
842
843     /(?'char'.)\g1/                 # ... mix and match
844          and print "'$1' is the first doubled character\n";
845
846     if (/Time: (..):(..):(..)/) {   # parse out values
847         $hours = $1;
848         $minutes = $2;
849         $seconds = $3;
850     }
851
852     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
853     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
854     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
855     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
856
857     $a = '(.)\1';        # Creates problems when concatenated.
858     $b = '(.)\g{1}';     # Avoids the problems.
859     "aa" =~ /${a}/;      # True
860     "aa" =~ /${b}/;      # True
861     "aa0" =~ /${a}0/;    # False!
862     "aa0" =~ /${b}0/;    # True
863     "aa\x08" =~ /${a}0/;  # True!
864     "aa\x08" =~ /${b}0/;  # False
865
866 Several special variables also refer back to portions of the previous
867 match.  C<$+> returns whatever the last bracket match matched.
868 C<$&> returns the entire matched string.  (At one point C<$0> did
869 also, but now it returns the name of the program.)  C<$`> returns
870 everything before the matched string.  C<$'> returns everything
871 after the matched string. And C<$^N> contains whatever was matched by
872 the most-recently closed group (submatch). C<$^N> can be used in
873 extended patterns (see below), for example to assign a submatch to a
874 variable.
875 X<$+> X<$^N> X<$&> X<$`> X<$'>
876
877 These special variables, like the C<%+> hash and the numbered match variables
878 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
879 until the end of the enclosing block or until the next successful
880 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
881 X<$+> X<$^N> X<$&> X<$`> X<$'>
882 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
883
884 B<NOTE>: Failed matches in Perl do not reset the match variables,
885 which makes it easier to write code that tests for a series of more
886 specific cases and remembers the best match.
887
888 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
889 C<$'> anywhere in the program, it has to provide them for every
890 pattern match.  This may substantially slow your program.  Perl
891 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
892 price for each pattern that contains capturing parentheses.  (To
893 avoid this cost while retaining the grouping behaviour, use the
894 extended regular expression C<(?: ... )> instead.)  But if you never
895 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
896 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
897 if you can, but if you can't (and some algorithms really appreciate
898 them), once you've used them once, use them at will, because you've
899 already paid the price.  As of 5.005, C<$&> is not so costly as the
900 other two.
901 X<$&> X<$`> X<$'>
902
903 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
904 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
905 and C<$'>, B<except> that they are only guaranteed to be defined after a
906 successful match that was executed with the C</p> (preserve) modifier.
907 The use of these variables incurs no global performance penalty, unlike
908 their punctuation char equivalents, however at the trade-off that you
909 have to tell perl when you want to use them.
910 X</p> X<p modifier>
911
912 =head2 Quoting metacharacters
913
914 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
915 C<\w>, C<\n>.  Unlike some other regular expression languages, there
916 are no backslashed symbols that aren't alphanumeric.  So anything
917 that looks like \\, \(, \), \<, \>, \{, or \} is always
918 interpreted as a literal character, not a metacharacter.  This was
919 once used in a common idiom to disable or quote the special meanings
920 of regular expression metacharacters in a string that you want to
921 use for a pattern. Simply quote all non-"word" characters:
922
923     $pattern =~ s/(\W)/\\$1/g;
924
925 (If C<use locale> is set, then this depends on the current locale.)
926 Today it is more common to use the quotemeta() function or the C<\Q>
927 metaquoting escape sequence to disable all metacharacters' special
928 meanings like this:
929
930     /$unquoted\Q$quoted\E$unquoted/
931
932 Beware that if you put literal backslashes (those not inside
933 interpolated variables) between C<\Q> and C<\E>, double-quotish
934 backslash interpolation may lead to confusing results.  If you
935 I<need> to use literal backslashes within C<\Q...\E>,
936 consult L<perlop/"Gory details of parsing quoted constructs">.
937
938 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
939
940 =head2 Extended Patterns
941
942 Perl also defines a consistent extension syntax for features not
943 found in standard tools like B<awk> and
944 B<lex>.  The syntax for most of these is a
945 pair of parentheses with a question mark as the first thing within
946 the parentheses.  The character after the question mark indicates
947 the extension.
948
949 The stability of these extensions varies widely.  Some have been
950 part of the core language for many years.  Others are experimental
951 and may change without warning or be completely removed.  Check
952 the documentation on an individual feature to verify its current
953 status.
954
955 A question mark was chosen for this and for the minimal-matching
956 construct because 1) question marks are rare in older regular
957 expressions, and 2) whenever you see one, you should stop and
958 "question" exactly what is going on.  That's psychology....
959
960 =over 4
961
962 =item C<(?#text)>
963 X<(?#)>
964
965 A comment.  The text is ignored.  If the C</x> modifier enables
966 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
967 the comment as soon as it sees a C<)>, so there is no way to put a literal
968 C<)> in the comment.
969
970 =item C<(?adlupimsx-imsx)>
971
972 =item C<(?^alupimsx)>
973 X<(?)> X<(?^)>
974
975 One or more embedded pattern-match modifiers, to be turned on (or
976 turned off, if preceded by C<->) for the remainder of the pattern or
977 the remainder of the enclosing pattern group (if any).
978
979 This is particularly useful for dynamic patterns, such as those read in from a
980 configuration file, taken from an argument, or specified in a table
981 somewhere.  Consider the case where some patterns want to be
982 case-sensitive and some do not:  The case-insensitive ones merely need to
983 include C<(?i)> at the front of the pattern.  For example:
984
985     $pattern = "foobar";
986     if ( /$pattern/i ) { }
987
988     # more flexible:
989
990     $pattern = "(?i)foobar";
991     if ( /$pattern/ ) { }
992
993 These modifiers are restored at the end of the enclosing group. For example,
994
995     ( (?i) blah ) \s+ \g1
996
997 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
998 repetition of the previous word, assuming the C</x> modifier, and no C</i>
999 modifier outside this group.
1000
1001 These modifiers do not carry over into named subpatterns called in the
1002 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1003 change the case-sensitivity of the "NAME" pattern.
1004
1005 Any of these modifiers can be set to apply globally to all regular
1006 expressions compiled within the scope of a C<use re>.  See
1007 L<re/"'/flags' mode">.
1008
1009 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1010 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1011 C<"d">) may follow the caret to override it.
1012 But a minus sign is not legal with it.
1013
1014 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1015 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1016 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1017 others, and a maximum of one (or two C<a>'s) may appear in the
1018 construct.  Thus, for
1019 example, C<(?-p)> will warn when compiled under C<use warnings>;
1020 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1021
1022 Note also that the C<p> modifier is special in that its presence
1023 anywhere in a pattern has a global effect.
1024
1025 =item C<(?:pattern)>
1026 X<(?:)>
1027
1028 =item C<(?adluimsx-imsx:pattern)>
1029
1030 =item C<(?^aluimsx:pattern)>
1031 X<(?^:)>
1032
1033 This is for clustering, not capturing; it groups subexpressions like
1034 "()", but doesn't make backreferences as "()" does.  So
1035
1036     @fields = split(/\b(?:a|b|c)\b/)
1037
1038 is like
1039
1040     @fields = split(/\b(a|b|c)\b/)
1041
1042 but doesn't spit out extra fields.  It's also cheaper not to capture
1043 characters if you don't need to.
1044
1045 Any letters between C<?> and C<:> act as flags modifiers as with
1046 C<(?adluimsx-imsx)>.  For example,
1047
1048     /(?s-i:more.*than).*million/i
1049
1050 is equivalent to the more verbose
1051
1052     /(?:(?s-i)more.*than).*million/i
1053
1054 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1055 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1056 flags (except C<"d">) may follow the caret, so
1057
1058     (?^x:foo)
1059
1060 is equivalent to
1061
1062     (?x-ims:foo)
1063
1064 The caret tells Perl that this cluster doesn't inherit the flags of any
1065 surrounding pattern, but uses the system defaults (C<d-imsx>),
1066 modified by any flags specified.
1067
1068 The caret allows for simpler stringification of compiled regular
1069 expressions.  These look like
1070
1071     (?^:pattern)
1072
1073 with any non-default flags appearing between the caret and the colon.
1074 A test that looks at such stringification thus doesn't need to have the
1075 system default flags hard-coded in it, just the caret.  If new flags are
1076 added to Perl, the meaning of the caret's expansion will change to include
1077 the default for those flags, so the test will still work, unchanged.
1078
1079 Specifying a negative flag after the caret is an error, as the flag is
1080 redundant.
1081
1082 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1083 to match at the beginning.
1084
1085 =item C<(?|pattern)>
1086 X<(?|)> X<Branch reset>
1087
1088 This is the "branch reset" pattern, which has the special property
1089 that the capture groups are numbered from the same starting point
1090 in each alternation branch. It is available starting from perl 5.10.0.
1091
1092 Capture groups are numbered from left to right, but inside this
1093 construct the numbering is restarted for each branch.
1094
1095 The numbering within each branch will be as normal, and any groups
1096 following this construct will be numbered as though the construct
1097 contained only one branch, that being the one with the most capture
1098 groups in it.
1099
1100 This construct is useful when you want to capture one of a
1101 number of alternative matches.
1102
1103 Consider the following pattern.  The numbers underneath show in
1104 which group the captured content will be stored.
1105
1106
1107     # before  ---------------branch-reset----------- after        
1108     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1109     # 1            2         2  3        2     3     4  
1110
1111 Be careful when using the branch reset pattern in combination with 
1112 named captures. Named captures are implemented as being aliases to 
1113 numbered groups holding the captures, and that interferes with the
1114 implementation of the branch reset pattern. If you are using named
1115 captures in a branch reset pattern, it's best to use the same names,
1116 in the same order, in each of the alternations:
1117
1118    /(?|  (?<a> x ) (?<b> y )
1119       |  (?<a> z ) (?<b> w )) /x
1120
1121 Not doing so may lead to surprises:
1122
1123   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1124   say $+ {a};   # Prints '12'
1125   say $+ {b};   # *Also* prints '12'.
1126
1127 The problem here is that both the group named C<< a >> and the group
1128 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1129
1130 =item Look-Around Assertions
1131 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1132
1133 Look-around assertions are zero-width patterns which match a specific
1134 pattern without including it in C<$&>. Positive assertions match when
1135 their subpattern matches, negative assertions match when their subpattern
1136 fails. Look-behind matches text up to the current match position,
1137 look-ahead matches text following the current match position.
1138
1139 =over 4
1140
1141 =item C<(?=pattern)>
1142 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1143
1144 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1145 matches a word followed by a tab, without including the tab in C<$&>.
1146
1147 =item C<(?!pattern)>
1148 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1149
1150 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1151 matches any occurrence of "foo" that isn't followed by "bar".  Note
1152 however that look-ahead and look-behind are NOT the same thing.  You cannot
1153 use this for look-behind.
1154
1155 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1156 will not do what you want.  That's because the C<(?!foo)> is just saying that
1157 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1158 match.  Use look-behind instead (see below).
1159
1160 =item C<(?<=pattern)> C<\K>
1161 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1162
1163 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1164 matches a word that follows a tab, without including the tab in C<$&>.
1165 Works only for fixed-width look-behind.
1166
1167 There is a special form of this construct, called C<\K>, which causes the
1168 regex engine to "keep" everything it had matched prior to the C<\K> and
1169 not include it in C<$&>. This effectively provides variable-length
1170 look-behind. The use of C<\K> inside of another look-around assertion
1171 is allowed, but the behaviour is currently not well defined.
1172
1173 For various reasons C<\K> may be significantly more efficient than the
1174 equivalent C<< (?<=...) >> construct, and it is especially useful in
1175 situations where you want to efficiently remove something following
1176 something else in a string. For instance
1177
1178   s/(foo)bar/$1/g;
1179
1180 can be rewritten as the much more efficient
1181
1182   s/foo\Kbar//g;
1183
1184 =item C<(?<!pattern)>
1185 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1186
1187 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1188 matches any occurrence of "foo" that does not follow "bar".  Works
1189 only for fixed-width look-behind.
1190
1191 =back
1192
1193 =item C<(?'NAME'pattern)>
1194
1195 =item C<< (?<NAME>pattern) >>
1196 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1197
1198 A named capture group. Identical in every respect to normal capturing
1199 parentheses C<()> but for the additional fact that the group
1200 can be referred to by name in various regular expression
1201 constructs (like C<\g{NAME}>) and can be accessed by name
1202 after a successful match via C<%+> or C<%->. See L<perlvar>
1203 for more details on the C<%+> and C<%-> hashes.
1204
1205 If multiple distinct capture groups have the same name then the
1206 $+{NAME} will refer to the leftmost defined group in the match.
1207
1208 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1209
1210 B<NOTE:> While the notation of this construct is the same as the similar
1211 function in .NET regexes, the behavior is not. In Perl the groups are
1212 numbered sequentially regardless of being named or not. Thus in the
1213 pattern
1214
1215   /(x)(?<foo>y)(z)/
1216
1217 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1218 the opposite which is what a .NET regex hacker might expect.
1219
1220 Currently NAME is restricted to simple identifiers only.
1221 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1222 its Unicode extension (see L<utf8>),
1223 though it isn't extended by the locale (see L<perllocale>).
1224
1225 B<NOTE:> In order to make things easier for programmers with experience
1226 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1227 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1228 support the use of single quotes as a delimiter for the name.
1229
1230 =item C<< \k<NAME> >>
1231
1232 =item C<< \k'NAME' >>
1233
1234 Named backreference. Similar to numeric backreferences, except that
1235 the group is designated by name and not number. If multiple groups
1236 have the same name then it refers to the leftmost defined group in
1237 the current match.
1238
1239 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1240 earlier in the pattern.
1241
1242 Both forms are equivalent.
1243
1244 B<NOTE:> In order to make things easier for programmers with experience
1245 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1246 may be used instead of C<< \k<NAME> >>.
1247
1248 =item C<(?{ code })>
1249 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1250
1251 B<WARNING>: This extended regular expression feature is considered
1252 experimental, and may be changed without notice. Code executed that
1253 has side effects may not perform identically from version to version
1254 due to the effect of future optimisations in the regex engine. The
1255 implementation of this feature was radically overhauled for the 5.18.0
1256 release, and its behaviour in earlier versions of perl was much buggier,
1257 especially in relation to parsing, lexical vars, scoping, recursion and
1258 reentrancy.
1259
1260 This zero-width assertion executes any embedded Perl code.  It always
1261 succeeds, and its return value is set as C<$^R>.
1262
1263 In literal patterns, the code is parsed at the same time as the
1264 surrounding code. While within the pattern, control is passed temporarily
1265 back to the perl parser, until the logically-balancing closing brace is
1266 encountered. This is similar to the way that an array index expression in
1267 a literal string is handled, for example
1268
1269     "abc$array[ 1 + f('[') + g()]def"
1270
1271 In particular, braces do not need to be balanced:
1272
1273     /abc(?{ f('{'); })/def/
1274
1275 Even in a pattern that is interpolated and compiled at run-time, literal
1276 code blocks will be compiled once, at perl compile time; the following
1277 prints "ABCD":
1278
1279     print "D";
1280     my $qr = qr/(?{ BEGIN { print "A" } })/;
1281     my $foo = "foo";
1282     /$foo$qr(?{ BEGIN { print "B" } })/;
1283     BEGIN { print "C" }
1284
1285 In patterns where the text of the code is derived from run-time
1286 information rather than appearing literally in a source code /pattern/,
1287 the code is compiled at the same time that the pattern is compiled, and
1288 fro reasons of security, C<use re 'eval'> must be in scope. This is to
1289 stop user-supplied patterns containing code snippets from being
1290 executable.
1291
1292 In situations where you need enable this with C<use re 'eval'>, you should
1293 also have taint checking enabled.  Better yet, use the carefully
1294 constrained evaluation within a Safe compartment.  See L<perlsec> for
1295 details about both these mechanisms.
1296
1297 From the viewpoint of parsing, lexical variable scope and closures,
1298
1299     /AAA(?{ BBB })CCC/
1300
1301 behaves approximately like
1302
1303     /AAA/ && do { BBB } && /CCC/
1304
1305 Similarly,
1306
1307     qr/AAA(?{ BBB })CCC/
1308
1309 behaves approximately like
1310
1311     sub { /AAA/ && do { BBB } && /CCC/ }
1312
1313 In particular:
1314
1315     { my $i = 1; $r = qr/(?{ print $i })/ }
1316     my $i = 2;
1317     /$r/; # prints "1"
1318
1319 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1320 expression is matching against. You can also use C<pos()> to know what is
1321 the current position of matching within this string.
1322
1323 The code block introduces a new scope from the perspective of lexical
1324 variable declarations, but B<not> from the perspective of C<local> and
1325 similar localizing behaviours. So later code blocks within the same
1326 pattern will still see the values which were localized in earlier blocks.
1327 These accumulated localizations are undone either at the end of a
1328 successful match, or if the assertion is backtracked (compare
1329 L<"Backtracking">). For example,
1330
1331   $_ = 'a' x 8;
1332   m<
1333      (?{ $cnt = 0 })               # Initialize $cnt.
1334      (
1335        a
1336        (?{
1337            local $cnt = $cnt + 1;  # Update $cnt,
1338                                    # backtracking-safe.
1339        })
1340      )*
1341      aaaa
1342      (?{ $res = $cnt })            # On success copy to
1343                                    # non-localized location.
1344    >x;
1345
1346 will initially increment C<$cnt> up to 8; then during backtracking, its
1347 value will be unwound back to 4, which is the value assigned to C<$res>.
1348 At the end of the regex execution, $cnt will be wound back to its initial
1349 value of 0.
1350
1351 This assertion may be used as the condition in a
1352
1353     (?(condition)yes-pattern|no-pattern)
1354
1355 switch.  If I<not> used in this way, the result of evaluation of C<code>
1356 is put into the special variable C<$^R>.  This happens immediately, so
1357 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1358 regular expression.
1359
1360 The assignment to C<$^R> above is properly localized, so the old
1361 value of C<$^R> is restored if the assertion is backtracked; compare
1362 L<"Backtracking">.
1363
1364 Note that the special variable C<$^N>  is particularly useful with code
1365 blocks to capture the results of submatches in variables without having to
1366 keep track of the number of nested parentheses. For example:
1367
1368   $_ = "The brown fox jumps over the lazy dog";
1369   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1370   print "color = $color, animal = $animal\n";
1371
1372
1373 =item C<(??{ code })>
1374 X<(??{})>
1375 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1376
1377 B<WARNING>: This extended regular expression feature is considered
1378 experimental, and may be changed without notice. Code executed that
1379 has side effects may not perform identically from version to version
1380 due to the effect of future optimisations in the regex engine.
1381
1382 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1383 same way as a C<(?{ code })> code block as described above, except that
1384 its return value, rather than being assigned to C<$^R>, is treated as a
1385 pattern, compiled if it's a string (or used as-is if its a qr// object),
1386 then matched as if it were inserted instead of this construct.
1387
1388 During the matching of this sub-pattern, it has its own set of
1389 captures which are valid during the sub-match, but are discarded once
1390 control returns to the main pattern. For example, the following matches,
1391 with the inner pattern capturing "B" and matching "BB", while the outer
1392 pattern captures "A";
1393
1394     my $inner = '(.)\1';
1395     "ABBA" =~ /^(.)(??{ $inner })\1/;
1396     print $1; # prints "A";
1397
1398 Note that this means that  there is no way for the inner pattern to refer
1399 to a capture group defined outside.  (The code block itself can use C<$1>,
1400 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1401
1402     ('a' x 100)=~/(??{'(.)' x 100})/
1403
1404 I<will> match, it will I<not> set $1 on exit.
1405
1406 The following pattern matches a parenthesized group:
1407
1408  $re = qr{
1409             \(
1410             (?:
1411                (?> [^()]+ )  # Non-parens without backtracking
1412              |
1413                (??{ $re })   # Group with matching parens
1414             )*
1415             \)
1416          }x;
1417
1418 See also C<(?PARNO)> for a different, more efficient way to accomplish
1419 the same task.
1420
1421 Executing a postponed regular expression 50 times without consuming any
1422 input string will result in a fatal error.  The maximum depth is compiled
1423 into perl, so changing it requires a custom build.
1424
1425 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1426 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1427 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1428 X<regex, relative recursion>
1429
1430 Similar to C<(??{ code })> except that it does not involve executing any
1431 code or potentially compiling a returned pattern string; instead it treats
1432 the part of the current pattern contained within a specified capture group
1433 as an independent pattern that must match at the current position.
1434 Capture groups contained by the pattern will have the value as determined
1435 by the outermost recursion.
1436
1437 PARNO is a sequence of digits (not starting with 0) whose value reflects
1438 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1439 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1440 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1441 to be relative, with negative numbers indicating preceding capture groups
1442 and positive ones following. Thus C<(?-1)> refers to the most recently
1443 declared group, and C<(?+1)> indicates the next group to be declared.
1444 Note that the counting for relative recursion differs from that of
1445 relative backreferences, in that with recursion unclosed groups B<are>
1446 included.
1447
1448 The following pattern matches a function foo() which may contain
1449 balanced parentheses as the argument.
1450
1451   $re = qr{ (                   # paren group 1 (full function)
1452               foo
1453               (                 # paren group 2 (parens)
1454                 \(
1455                   (             # paren group 3 (contents of parens)
1456                   (?:
1457                    (?> [^()]+ ) # Non-parens without backtracking
1458                   |
1459                    (?2)         # Recurse to start of paren group 2
1460                   )*
1461                   )
1462                 \)
1463               )
1464             )
1465           }x;
1466
1467 If the pattern was used as follows
1468
1469     'foo(bar(baz)+baz(bop))'=~/$re/
1470         and print "\$1 = $1\n",
1471                   "\$2 = $2\n",
1472                   "\$3 = $3\n";
1473
1474 the output produced should be the following:
1475
1476     $1 = foo(bar(baz)+baz(bop))
1477     $2 = (bar(baz)+baz(bop))
1478     $3 = bar(baz)+baz(bop)
1479
1480 If there is no corresponding capture group defined, then it is a
1481 fatal error.  Recursing deeper than 50 times without consuming any input
1482 string will also result in a fatal error.  The maximum depth is compiled
1483 into perl, so changing it requires a custom build.
1484
1485 The following shows how using negative indexing can make it
1486 easier to embed recursive patterns inside of a C<qr//> construct
1487 for later use:
1488
1489     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1490     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1491        # do something here...
1492     }
1493
1494 B<Note> that this pattern does not behave the same way as the equivalent
1495 PCRE or Python construct of the same form. In Perl you can backtrack into
1496 a recursed group, in PCRE and Python the recursed into group is treated
1497 as atomic. Also, modifiers are resolved at compile time, so constructs
1498 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1499 be processed.
1500
1501 =item C<(?&NAME)>
1502 X<(?&NAME)>
1503
1504 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1505 parenthesis to recurse to is determined by name. If multiple parentheses have
1506 the same name, then it recurses to the leftmost.
1507
1508 It is an error to refer to a name that is not declared somewhere in the
1509 pattern.
1510
1511 B<NOTE:> In order to make things easier for programmers with experience
1512 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1513 may be used instead of C<< (?&NAME) >>.
1514
1515 =item C<(?(condition)yes-pattern|no-pattern)>
1516 X<(?()>
1517
1518 =item C<(?(condition)yes-pattern)>
1519
1520 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1521 a true value, matches C<no-pattern> otherwise. A missing pattern always
1522 matches.
1523
1524 C<(condition)> should be one of: 1) an integer in
1525 parentheses (which is valid if the corresponding pair of parentheses
1526 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1527 name in angle brackets or single quotes (which is valid if a group
1528 with the given name matched); or 4) the special symbol (R) (true when
1529 evaluated inside of recursion or eval). Additionally the R may be
1530 followed by a number, (which will be true when evaluated when recursing
1531 inside of the appropriate group), or by C<&NAME>, in which case it will
1532 be true only when evaluated during recursion in the named group.
1533
1534 Here's a summary of the possible predicates:
1535
1536 =over 4
1537
1538 =item (1) (2) ...
1539
1540 Checks if the numbered capturing group has matched something.
1541
1542 =item (<NAME>) ('NAME')
1543
1544 Checks if a group with the given name has matched something.
1545
1546 =item (?=...) (?!...) (?<=...) (?<!...)
1547
1548 Checks whether the pattern matches (or does not match, for the '!'
1549 variants).
1550
1551 =item (?{ CODE })
1552
1553 Treats the return value of the code block as the condition.
1554
1555 =item (R)
1556
1557 Checks if the expression has been evaluated inside of recursion.
1558
1559 =item (R1) (R2) ...
1560
1561 Checks if the expression has been evaluated while executing directly
1562 inside of the n-th capture group. This check is the regex equivalent of
1563
1564   if ((caller(0))[3] eq 'subname') { ... }
1565
1566 In other words, it does not check the full recursion stack.
1567
1568 =item (R&NAME)
1569
1570 Similar to C<(R1)>, this predicate checks to see if we're executing
1571 directly inside of the leftmost group with a given name (this is the same
1572 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1573 stack, but only the name of the innermost active recursion.
1574
1575 =item (DEFINE)
1576
1577 In this case, the yes-pattern is never directly executed, and no
1578 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1579 See below for details.
1580
1581 =back
1582
1583 For example:
1584
1585     m{ ( \( )?
1586        [^()]+
1587        (?(1) \) )
1588      }x
1589
1590 matches a chunk of non-parentheses, possibly included in parentheses
1591 themselves.
1592
1593 A special form is the C<(DEFINE)> predicate, which never executes its
1594 yes-pattern directly, and does not allow a no-pattern. This allows one to
1595 define subpatterns which will be executed only by the recursion mechanism.
1596 This way, you can define a set of regular expression rules that can be
1597 bundled into any pattern you choose.
1598
1599 It is recommended that for this usage you put the DEFINE block at the
1600 end of the pattern, and that you name any subpatterns defined within it.
1601
1602 Also, it's worth noting that patterns defined this way probably will
1603 not be as efficient, as the optimiser is not very clever about
1604 handling them.
1605
1606 An example of how this might be used is as follows:
1607
1608   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1609    (?(DEFINE)
1610      (?<NAME_PAT>....)
1611      (?<ADRESS_PAT>....)
1612    )/x
1613
1614 Note that capture groups matched inside of recursion are not accessible
1615 after the recursion returns, so the extra layer of capturing groups is
1616 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1617 C<$+{NAME}> would be.
1618
1619 Finally, keep in mind that subpatterns created inside a DEFINE block
1620 count towards the absolute and relative number of captures, so this:
1621
1622     my @captures = "a" =~ /(.)                  # First capture
1623                            (?(DEFINE)
1624                                (?<EXAMPLE> 1 )  # Second capture
1625                            )/x;
1626     say scalar @captures;
1627
1628 Will output 2, not 1. This is particularly important if you intend to
1629 compile the definitions with the C<qr//> operator, and later
1630 interpolate them in another pattern.
1631
1632 =item C<< (?>pattern) >>
1633 X<backtrack> X<backtracking> X<atomic> X<possessive>
1634
1635 An "independent" subexpression, one which matches the substring
1636 that a I<standalone> C<pattern> would match if anchored at the given
1637 position, and it matches I<nothing other than this substring>.  This
1638 construct is useful for optimizations of what would otherwise be
1639 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1640 It may also be useful in places where the "grab all you can, and do not
1641 give anything back" semantic is desirable.
1642
1643 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1644 (anchored at the beginning of string, as above) will match I<all>
1645 characters C<a> at the beginning of string, leaving no C<a> for
1646 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1647 since the match of the subgroup C<a*> is influenced by the following
1648 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1649 C<a*ab> will match fewer characters than a standalone C<a*>, since
1650 this makes the tail match.
1651
1652 C<< (?>pattern) >> does not disable backtracking altogether once it has
1653 matched. It is still possible to backtrack past the construct, but not
1654 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1655
1656 An effect similar to C<< (?>pattern) >> may be achieved by writing
1657 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1658 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1659 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1660 (The difference between these two constructs is that the second one
1661 uses a capturing group, thus shifting ordinals of backreferences
1662 in the rest of a regular expression.)
1663
1664 Consider this pattern:
1665
1666     m{ \(
1667           (
1668             [^()]+           # x+
1669           |
1670             \( [^()]* \)
1671           )+
1672        \)
1673      }x
1674
1675 That will efficiently match a nonempty group with matching parentheses
1676 two levels deep or less.  However, if there is no such group, it
1677 will take virtually forever on a long string.  That's because there
1678 are so many different ways to split a long string into several
1679 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1680 to a subpattern of the above pattern.  Consider how the pattern
1681 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1682 seconds, but that each extra letter doubles this time.  This
1683 exponential performance will make it appear that your program has
1684 hung.  However, a tiny change to this pattern
1685
1686     m{ \(
1687           (
1688             (?> [^()]+ )        # change x+ above to (?> x+ )
1689           |
1690             \( [^()]* \)
1691           )+
1692        \)
1693      }x
1694
1695 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1696 this yourself would be a productive exercise), but finishes in a fourth
1697 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1698 however, that, when this construct is followed by a
1699 quantifier, it currently triggers a warning message under
1700 the C<use warnings> pragma or B<-w> switch saying it
1701 C<"matches null string many times in regex">.
1702
1703 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1704 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1705 This was only 4 times slower on a string with 1000000 C<a>s.
1706
1707 The "grab all you can, and do not give anything back" semantic is desirable
1708 in many situations where on the first sight a simple C<()*> looks like
1709 the correct solution.  Suppose we parse text with comments being delimited
1710 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1711 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1712 the comment delimiter, because it may "give up" some whitespace if
1713 the remainder of the pattern can be made to match that way.  The correct
1714 answer is either one of these:
1715
1716     (?>#[ \t]*)
1717     #[ \t]*(?![ \t])
1718
1719 For example, to grab non-empty comments into $1, one should use either
1720 one of these:
1721
1722     / (?> \# [ \t]* ) (        .+ ) /x;
1723     /     \# [ \t]*   ( [^ \t] .* ) /x;
1724
1725 Which one you pick depends on which of these expressions better reflects
1726 the above specification of comments.
1727
1728 In some literature this construct is called "atomic matching" or
1729 "possessive matching".
1730
1731 Possessive quantifiers are equivalent to putting the item they are applied
1732 to inside of one of these constructs. The following equivalences apply:
1733
1734     Quantifier Form     Bracketing Form
1735     ---------------     ---------------
1736     PAT*+               (?>PAT*)
1737     PAT++               (?>PAT+)
1738     PAT?+               (?>PAT?)
1739     PAT{min,max}+       (?>PAT{min,max})
1740
1741 =back
1742
1743 =head2 Special Backtracking Control Verbs
1744
1745 B<WARNING:> These patterns are experimental and subject to change or
1746 removal in a future version of Perl. Their usage in production code should
1747 be noted to avoid problems during upgrades.
1748
1749 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1750 otherwise stated the ARG argument is optional; in some cases, it is
1751 forbidden.
1752
1753 Any pattern containing a special backtracking verb that allows an argument
1754 has the special behaviour that when executed it sets the current package's
1755 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1756 rules apply:
1757
1758 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1759 verb pattern, if the verb was involved in the failure of the match. If the
1760 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1761 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1762 none. Also, the C<$REGMARK> variable will be set to FALSE.
1763
1764 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1765 the C<$REGMARK> variable will be set to the name of the last
1766 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1767 C<(*MARK:NAME)> verb below for more details.
1768
1769 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1770 and most other regex-related variables. They are not local to a scope, nor
1771 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1772 Use C<local> to localize changes to them to a specific scope if necessary.
1773
1774 If a pattern does not contain a special backtracking verb that allows an
1775 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1776
1777 =over 3
1778
1779 =item Verbs that take an argument
1780
1781 =over 4
1782
1783 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1784 X<(*PRUNE)> X<(*PRUNE:NAME)>
1785
1786 This zero-width pattern prunes the backtracking tree at the current point
1787 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1788 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1789 A may backtrack as necessary to match. Once it is reached, matching
1790 continues in B, which may also backtrack as necessary; however, should B
1791 not match, then no further backtracking will take place, and the pattern
1792 will fail outright at the current starting position.
1793
1794 The following example counts all the possible matching strings in a
1795 pattern (without actually matching any of them).
1796
1797     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1798     print "Count=$count\n";
1799
1800 which produces:
1801
1802     aaab
1803     aaa
1804     aa
1805     a
1806     aab
1807     aa
1808     a
1809     ab
1810     a
1811     Count=9
1812
1813 If we add a C<(*PRUNE)> before the count like the following
1814
1815     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1816     print "Count=$count\n";
1817
1818 we prevent backtracking and find the count of the longest matching string
1819 at each matching starting point like so:
1820
1821     aaab
1822     aab
1823     ab
1824     Count=3
1825
1826 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1827
1828 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1829 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1830 replaced with a C<< (?>pattern) >> with no functional difference; however,
1831 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1832 C<< (?>pattern) >> alone.
1833
1834 =item C<(*SKIP)> C<(*SKIP:NAME)>
1835 X<(*SKIP)>
1836
1837 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1838 failure it also signifies that whatever text that was matched leading up
1839 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1840 of this pattern. This effectively means that the regex engine "skips" forward
1841 to this position on failure and tries to match again, (assuming that
1842 there is sufficient room to match).
1843
1844 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1845 C<(*MARK:NAME)> was encountered while matching, then it is that position
1846 which is used as the "skip point". If no C<(*MARK)> of that name was
1847 encountered, then the C<(*SKIP)> operator has no effect. When used
1848 without a name the "skip point" is where the match point was when
1849 executing the (*SKIP) pattern.
1850
1851 Compare the following to the examples in C<(*PRUNE)>; note the string
1852 is twice as long:
1853
1854  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1855  print "Count=$count\n";
1856
1857 outputs
1858
1859     aaab
1860     aaab
1861     Count=2
1862
1863 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1864 executed, the next starting point will be where the cursor was when the
1865 C<(*SKIP)> was executed.
1866
1867 =item C<(*MARK:NAME)> C<(*:NAME)>
1868 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1869
1870 This zero-width pattern can be used to mark the point reached in a string
1871 when a certain part of the pattern has been successfully matched. This
1872 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1873 forward to that point if backtracked into on failure. Any number of
1874 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1875
1876 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1877 can be used to "label" a pattern branch, so that after matching, the
1878 program can determine which branches of the pattern were involved in the
1879 match.
1880
1881 When a match is successful, the C<$REGMARK> variable will be set to the
1882 name of the most recently executed C<(*MARK:NAME)> that was involved
1883 in the match.
1884
1885 This can be used to determine which branch of a pattern was matched
1886 without using a separate capture group for each branch, which in turn
1887 can result in a performance improvement, as perl cannot optimize
1888 C</(?:(x)|(y)|(z))/> as efficiently as something like
1889 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1890
1891 When a match has failed, and unless another verb has been involved in
1892 failing the match and has provided its own name to use, the C<$REGERROR>
1893 variable will be set to the name of the most recently executed
1894 C<(*MARK:NAME)>.
1895
1896 See L</(*SKIP)> for more details.
1897
1898 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1899
1900 =item C<(*THEN)> C<(*THEN:NAME)>
1901
1902 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1903 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1904 failure, it causes the regex engine to try the next alternation in the
1905 innermost enclosing group (capturing or otherwise) that has alternations.
1906 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1907 count as an alternation, as far as C<(*THEN)> is concerned.
1908
1909 Its name comes from the observation that this operation combined with the
1910 alternation operator (C<|>) can be used to create what is essentially a
1911 pattern-based if/then/else block:
1912
1913   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1914
1915 Note that if this operator is used and NOT inside of an alternation then
1916 it acts exactly like the C<(*PRUNE)> operator.
1917
1918   / A (*PRUNE) B /
1919
1920 is the same as
1921
1922   / A (*THEN) B /
1923
1924 but
1925
1926   / ( A (*THEN) B | C ) /
1927
1928 is not the same as
1929
1930   / ( A (*PRUNE) B | C ) /
1931
1932 as after matching the A but failing on the B the C<(*THEN)> verb will
1933 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1934
1935 =back
1936
1937 =item Verbs without an argument
1938
1939 =over 4
1940
1941 =item C<(*COMMIT)>
1942 X<(*COMMIT)>
1943
1944 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1945 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1946 into on failure it causes the match to fail outright. No further attempts
1947 to find a valid match by advancing the start pointer will occur again.
1948 For example,
1949
1950  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1951  print "Count=$count\n";
1952
1953 outputs
1954
1955     aaab
1956     Count=1
1957
1958 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1959 does not match, the regex engine will not try any further matching on the
1960 rest of the string.
1961
1962 =item C<(*FAIL)> C<(*F)>
1963 X<(*FAIL)> X<(*F)>
1964
1965 This pattern matches nothing and always fails. It can be used to force the
1966 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1967 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1968
1969 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1970
1971 =item C<(*ACCEPT)>
1972 X<(*ACCEPT)>
1973
1974 B<WARNING:> This feature is highly experimental. It is not recommended
1975 for production code.
1976
1977 This pattern matches nothing and causes the end of successful matching at
1978 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1979 whether there is actually more to match in the string. When inside of a
1980 nested pattern, such as recursion, or in a subpattern dynamically generated
1981 via C<(??{})>, only the innermost pattern is ended immediately.
1982
1983 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1984 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1985 For instance:
1986
1987   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1988
1989 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1990 be set. If another branch in the inner parentheses was matched, such as in the
1991 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1992
1993 =back
1994
1995 =back
1996
1997 =head2 Backtracking
1998 X<backtrack> X<backtracking>
1999
2000 NOTE: This section presents an abstract approximation of regular
2001 expression behavior.  For a more rigorous (and complicated) view of
2002 the rules involved in selecting a match among possible alternatives,
2003 see L<Combining RE Pieces>.
2004
2005 A fundamental feature of regular expression matching involves the
2006 notion called I<backtracking>, which is currently used (when needed)
2007 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2008 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2009 internally, but the general principle outlined here is valid.
2010
2011 For a regular expression to match, the I<entire> regular expression must
2012 match, not just part of it.  So if the beginning of a pattern containing a
2013 quantifier succeeds in a way that causes later parts in the pattern to
2014 fail, the matching engine backs up and recalculates the beginning
2015 part--that's why it's called backtracking.
2016
2017 Here is an example of backtracking:  Let's say you want to find the
2018 word following "foo" in the string "Food is on the foo table.":
2019
2020     $_ = "Food is on the foo table.";
2021     if ( /\b(foo)\s+(\w+)/i ) {
2022         print "$2 follows $1.\n";
2023     }
2024
2025 When the match runs, the first part of the regular expression (C<\b(foo)>)
2026 finds a possible match right at the beginning of the string, and loads up
2027 $1 with "Foo".  However, as soon as the matching engine sees that there's
2028 no whitespace following the "Foo" that it had saved in $1, it realizes its
2029 mistake and starts over again one character after where it had the
2030 tentative match.  This time it goes all the way until the next occurrence
2031 of "foo". The complete regular expression matches this time, and you get
2032 the expected output of "table follows foo."
2033
2034 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2035 everything between "foo" and "bar".  Initially, you write something
2036 like this:
2037
2038     $_ =  "The food is under the bar in the barn.";
2039     if ( /foo(.*)bar/ ) {
2040         print "got <$1>\n";
2041     }
2042
2043 Which perhaps unexpectedly yields:
2044
2045   got <d is under the bar in the >
2046
2047 That's because C<.*> was greedy, so you get everything between the
2048 I<first> "foo" and the I<last> "bar".  Here it's more effective
2049 to use minimal matching to make sure you get the text between a "foo"
2050 and the first "bar" thereafter.
2051
2052     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2053   got <d is under the >
2054
2055 Here's another example. Let's say you'd like to match a number at the end
2056 of a string, and you also want to keep the preceding part of the match.
2057 So you write this:
2058
2059     $_ = "I have 2 numbers: 53147";
2060     if ( /(.*)(\d*)/ ) {                                # Wrong!
2061         print "Beginning is <$1>, number is <$2>.\n";
2062     }
2063
2064 That won't work at all, because C<.*> was greedy and gobbled up the
2065 whole string. As C<\d*> can match on an empty string the complete
2066 regular expression matched successfully.
2067
2068     Beginning is <I have 2 numbers: 53147>, number is <>.
2069
2070 Here are some variants, most of which don't work:
2071
2072     $_ = "I have 2 numbers: 53147";
2073     @pats = qw{
2074         (.*)(\d*)
2075         (.*)(\d+)
2076         (.*?)(\d*)
2077         (.*?)(\d+)
2078         (.*)(\d+)$
2079         (.*?)(\d+)$
2080         (.*)\b(\d+)$
2081         (.*\D)(\d+)$
2082     };
2083
2084     for $pat (@pats) {
2085         printf "%-12s ", $pat;
2086         if ( /$pat/ ) {
2087             print "<$1> <$2>\n";
2088         } else {
2089             print "FAIL\n";
2090         }
2091     }
2092
2093 That will print out:
2094
2095     (.*)(\d*)    <I have 2 numbers: 53147> <>
2096     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2097     (.*?)(\d*)   <> <>
2098     (.*?)(\d+)   <I have > <2>
2099     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2100     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2101     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2102     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2103
2104 As you see, this can be a bit tricky.  It's important to realize that a
2105 regular expression is merely a set of assertions that gives a definition
2106 of success.  There may be 0, 1, or several different ways that the
2107 definition might succeed against a particular string.  And if there are
2108 multiple ways it might succeed, you need to understand backtracking to
2109 know which variety of success you will achieve.
2110
2111 When using look-ahead assertions and negations, this can all get even
2112 trickier.  Imagine you'd like to find a sequence of non-digits not
2113 followed by "123".  You might try to write that as
2114
2115     $_ = "ABC123";
2116     if ( /^\D*(?!123)/ ) {                # Wrong!
2117         print "Yup, no 123 in $_\n";
2118     }
2119
2120 But that isn't going to match; at least, not the way you're hoping.  It
2121 claims that there is no 123 in the string.  Here's a clearer picture of
2122 why that pattern matches, contrary to popular expectations:
2123
2124     $x = 'ABC123';
2125     $y = 'ABC445';
2126
2127     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2128     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2129
2130     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2131     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2132
2133 This prints
2134
2135     2: got ABC
2136     3: got AB
2137     4: got ABC
2138
2139 You might have expected test 3 to fail because it seems to a more
2140 general purpose version of test 1.  The important difference between
2141 them is that test 3 contains a quantifier (C<\D*>) and so can use
2142 backtracking, whereas test 1 will not.  What's happening is
2143 that you've asked "Is it true that at the start of $x, following 0 or more
2144 non-digits, you have something that's not 123?"  If the pattern matcher had
2145 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2146 fail.
2147
2148 The search engine will initially match C<\D*> with "ABC".  Then it will
2149 try to match C<(?!123)> with "123", which fails.  But because
2150 a quantifier (C<\D*>) has been used in the regular expression, the
2151 search engine can backtrack and retry the match differently
2152 in the hope of matching the complete regular expression.
2153
2154 The pattern really, I<really> wants to succeed, so it uses the
2155 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2156 time.  Now there's indeed something following "AB" that is not
2157 "123".  It's "C123", which suffices.
2158
2159 We can deal with this by using both an assertion and a negation.
2160 We'll say that the first part in $1 must be followed both by a digit
2161 and by something that's not "123".  Remember that the look-aheads
2162 are zero-width expressions--they only look, but don't consume any
2163 of the string in their match.  So rewriting this way produces what
2164 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2165
2166     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2167     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2168
2169     6: got ABC
2170
2171 In other words, the two zero-width assertions next to each other work as though
2172 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2173 matches only if you're at the beginning of the line AND the end of the
2174 line simultaneously.  The deeper underlying truth is that juxtaposition in
2175 regular expressions always means AND, except when you write an explicit OR
2176 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2177 although the attempted matches are made at different positions because "a"
2178 is not a zero-width assertion, but a one-width assertion.
2179
2180 B<WARNING>: Particularly complicated regular expressions can take
2181 exponential time to solve because of the immense number of possible
2182 ways they can use backtracking to try for a match.  For example, without
2183 internal optimizations done by the regular expression engine, this will
2184 take a painfully long time to run:
2185
2186     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2187
2188 And if you used C<*>'s in the internal groups instead of limiting them
2189 to 0 through 5 matches, then it would take forever--or until you ran
2190 out of stack space.  Moreover, these internal optimizations are not
2191 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2192 on the external group, no current optimization is applicable, and the
2193 match takes a long time to finish.
2194
2195 A powerful tool for optimizing such beasts is what is known as an
2196 "independent group",
2197 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2198 zero-length look-ahead/look-behind assertions will not backtrack to make
2199 the tail match, since they are in "logical" context: only
2200 whether they match is considered relevant.  For an example
2201 where side-effects of look-ahead I<might> have influenced the
2202 following match, see L</C<< (?>pattern) >>>.
2203
2204 =head2 Version 8 Regular Expressions
2205 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2206
2207 In case you're not familiar with the "regular" Version 8 regex
2208 routines, here are the pattern-matching rules not described above.
2209
2210 Any single character matches itself, unless it is a I<metacharacter>
2211 with a special meaning described here or above.  You can cause
2212 characters that normally function as metacharacters to be interpreted
2213 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2214 character; "\\" matches a "\"). This escape mechanism is also required
2215 for the character used as the pattern delimiter.
2216
2217 A series of characters matches that series of characters in the target
2218 string, so the pattern C<blurfl> would match "blurfl" in the target
2219 string.
2220
2221 You can specify a character class, by enclosing a list of characters
2222 in C<[]>, which will match any character from the list.  If the
2223 first character after the "[" is "^", the class matches any character not
2224 in the list.  Within a list, the "-" character specifies a
2225 range, so that C<a-z> represents all characters between "a" and "z",
2226 inclusive.  If you want either "-" or "]" itself to be a member of a
2227 class, put it at the start of the list (possibly after a "^"), or
2228 escape it with a backslash.  "-" is also taken literally when it is
2229 at the end of the list, just before the closing "]".  (The
2230 following all specify the same class of three characters: C<[-az]>,
2231 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2232 specifies a class containing twenty-six characters, even on EBCDIC-based
2233 character sets.)  Also, if you try to use the character
2234 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2235 a range, the "-" is understood literally.
2236
2237 Note also that the whole range idea is rather unportable between
2238 character sets--and even within character sets they may cause results
2239 you probably didn't expect.  A sound principle is to use only ranges
2240 that begin from and end at either alphabetics of equal case ([a-e],
2241 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2242 spell out the character sets in full.
2243
2244 Characters may be specified using a metacharacter syntax much like that
2245 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2246 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2247 of three octal digits, matches the character whose coded character set value
2248 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2249 matches the character whose ordinal is I<nn>. The expression \cI<x>
2250 matches the character control-I<x>.  Finally, the "." metacharacter
2251 matches any character except "\n" (unless you use C</s>).
2252
2253 You can specify a series of alternatives for a pattern using "|" to
2254 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2255 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2256 first alternative includes everything from the last pattern delimiter
2257 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2258 the last alternative contains everything from the last "|" to the next
2259 closing pattern delimiter.  That's why it's common practice to include
2260 alternatives in parentheses: to minimize confusion about where they
2261 start and end.
2262
2263 Alternatives are tried from left to right, so the first
2264 alternative found for which the entire expression matches, is the one that
2265 is chosen. This means that alternatives are not necessarily greedy. For
2266 example: when matching C<foo|foot> against "barefoot", only the "foo"
2267 part will match, as that is the first alternative tried, and it successfully
2268 matches the target string. (This might not seem important, but it is
2269 important when you are capturing matched text using parentheses.)
2270
2271 Also remember that "|" is interpreted as a literal within square brackets,
2272 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2273
2274 Within a pattern, you may designate subpatterns for later reference
2275 by enclosing them in parentheses, and you may refer back to the
2276 I<n>th subpattern later in the pattern using the metacharacter
2277 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2278 of their opening parenthesis.  A backreference matches whatever
2279 actually matched the subpattern in the string being examined, not
2280 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2281 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2282 1 matched "0x", even though the rule C<0|0x> could potentially match
2283 the leading 0 in the second number.
2284
2285 =head2 Warning on \1 Instead of $1
2286
2287 Some people get too used to writing things like:
2288
2289     $pattern =~ s/(\W)/\\\1/g;
2290
2291 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2292 shocking the
2293 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2294 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2295 the usual double-quoted string means a control-A.  The customary Unix
2296 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2297 of doing that, you get yourself into trouble if you then add an C</e>
2298 modifier.
2299
2300     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2301
2302 Or if you try to do
2303
2304     s/(\d+)/\1000/;
2305
2306 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2307 C<${1}000>.  The operation of interpolation should not be confused
2308 with the operation of matching a backreference.  Certainly they mean two
2309 different things on the I<left> side of the C<s///>.
2310
2311 =head2 Repeated Patterns Matching a Zero-length Substring
2312
2313 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2314
2315 Regular expressions provide a terse and powerful programming language.  As
2316 with most other power tools, power comes together with the ability
2317 to wreak havoc.
2318
2319 A common abuse of this power stems from the ability to make infinite
2320 loops using regular expressions, with something as innocuous as:
2321
2322     'foo' =~ m{ ( o? )* }x;
2323
2324 The C<o?> matches at the beginning of C<'foo'>, and since the position
2325 in the string is not moved by the match, C<o?> would match again and again
2326 because of the C<*> quantifier.  Another common way to create a similar cycle
2327 is with the looping modifier C<//g>:
2328
2329     @matches = ( 'foo' =~ m{ o? }xg );
2330
2331 or
2332
2333     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2334
2335 or the loop implied by split().
2336
2337 However, long experience has shown that many programming tasks may
2338 be significantly simplified by using repeated subexpressions that
2339 may match zero-length substrings.  Here's a simple example being:
2340
2341     @chars = split //, $string;           # // is not magic in split
2342     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2343
2344 Thus Perl allows such constructs, by I<forcefully breaking
2345 the infinite loop>.  The rules for this are different for lower-level
2346 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2347 ones like the C</g> modifier or split() operator.
2348
2349 The lower-level loops are I<interrupted> (that is, the loop is
2350 broken) when Perl detects that a repeated expression matched a
2351 zero-length substring.   Thus
2352
2353    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2354
2355 is made equivalent to
2356
2357    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2358
2359 For example, this program
2360
2361    #!perl -l
2362    "aaaaab" =~ /
2363      (?:
2364         a                 # non-zero
2365         |                 # or
2366        (?{print "hello"}) # print hello whenever this
2367                           #    branch is tried
2368        (?=(b))            # zero-width assertion
2369      )*  # any number of times
2370     /x;
2371    print $&;
2372    print $1;
2373
2374 prints
2375
2376    hello
2377    aaaaa
2378    b
2379
2380 Notice that "hello" is only printed once, as when Perl sees that the sixth
2381 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2382 the C<*>.
2383
2384 The higher-level loops preserve an additional state between iterations:
2385 whether the last match was zero-length.  To break the loop, the following
2386 match after a zero-length match is prohibited to have a length of zero.
2387 This prohibition interacts with backtracking (see L<"Backtracking">),
2388 and so the I<second best> match is chosen if the I<best> match is of
2389 zero length.
2390
2391 For example:
2392
2393     $_ = 'bar';
2394     s/\w??/<$&>/g;
2395
2396 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2397 match given by non-greedy C<??> is the zero-length match, and the I<second
2398 best> match is what is matched by C<\w>.  Thus zero-length matches
2399 alternate with one-character-long matches.
2400
2401 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2402 position one notch further in the string.
2403
2404 The additional state of being I<matched with zero-length> is associated with
2405 the matched string, and is reset by each assignment to pos().
2406 Zero-length matches at the end of the previous match are ignored
2407 during C<split>.
2408
2409 =head2 Combining RE Pieces
2410
2411 Each of the elementary pieces of regular expressions which were described
2412 before (such as C<ab> or C<\Z>) could match at most one substring
2413 at the given position of the input string.  However, in a typical regular
2414 expression these elementary pieces are combined into more complicated
2415 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2416 (in these examples C<S> and C<T> are regular subexpressions).
2417
2418 Such combinations can include alternatives, leading to a problem of choice:
2419 if we match a regular expression C<a|ab> against C<"abc">, will it match
2420 substring C<"a"> or C<"ab">?  One way to describe which substring is
2421 actually matched is the concept of backtracking (see L<"Backtracking">).
2422 However, this description is too low-level and makes you think
2423 in terms of a particular implementation.
2424
2425 Another description starts with notions of "better"/"worse".  All the
2426 substrings which may be matched by the given regular expression can be
2427 sorted from the "best" match to the "worst" match, and it is the "best"
2428 match which is chosen.  This substitutes the question of "what is chosen?"
2429 by the question of "which matches are better, and which are worse?".
2430
2431 Again, for elementary pieces there is no such question, since at most
2432 one match at a given position is possible.  This section describes the
2433 notion of better/worse for combining operators.  In the description
2434 below C<S> and C<T> are regular subexpressions.
2435
2436 =over 4
2437
2438 =item C<ST>
2439
2440 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2441 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2442 which can be matched by C<T>.
2443
2444 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2445 match than C<A'B'>.
2446
2447 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2448 C<B> is a better match for C<T> than C<B'>.
2449
2450 =item C<S|T>
2451
2452 When C<S> can match, it is a better match than when only C<T> can match.
2453
2454 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2455 two matches for C<T>.
2456
2457 =item C<S{REPEAT_COUNT}>
2458
2459 Matches as C<SSS...S> (repeated as many times as necessary).
2460
2461 =item C<S{min,max}>
2462
2463 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2464
2465 =item C<S{min,max}?>
2466
2467 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2468
2469 =item C<S?>, C<S*>, C<S+>
2470
2471 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2472
2473 =item C<S??>, C<S*?>, C<S+?>
2474
2475 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2476
2477 =item C<< (?>S) >>
2478
2479 Matches the best match for C<S> and only that.
2480
2481 =item C<(?=S)>, C<(?<=S)>
2482
2483 Only the best match for C<S> is considered.  (This is important only if
2484 C<S> has capturing parentheses, and backreferences are used somewhere
2485 else in the whole regular expression.)
2486
2487 =item C<(?!S)>, C<(?<!S)>
2488
2489 For this grouping operator there is no need to describe the ordering, since
2490 only whether or not C<S> can match is important.
2491
2492 =item C<(??{ EXPR })>, C<(?PARNO)>
2493
2494 The ordering is the same as for the regular expression which is
2495 the result of EXPR, or the pattern contained by capture group PARNO.
2496
2497 =item C<(?(condition)yes-pattern|no-pattern)>
2498
2499 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2500 already determined.  The ordering of the matches is the same as for the
2501 chosen subexpression.
2502
2503 =back
2504
2505 The above recipes describe the ordering of matches I<at a given position>.
2506 One more rule is needed to understand how a match is determined for the
2507 whole regular expression: a match at an earlier position is always better
2508 than a match at a later position.
2509
2510 =head2 Creating Custom RE Engines
2511
2512 As of Perl 5.10.0, one can create custom regular expression engines.  This
2513 is not for the faint of heart, as they have to plug in at the C level.  See
2514 L<perlreapi> for more details.
2515
2516 As an alternative, overloaded constants (see L<overload>) provide a simple
2517 way to extend the functionality of the RE engine, by substituting one
2518 pattern for another.
2519
2520 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2521 matches at a boundary between whitespace characters and non-whitespace
2522 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2523 at these positions, so we want to have each C<\Y|> in the place of the
2524 more complicated version.  We can create a module C<customre> to do
2525 this:
2526
2527     package customre;
2528     use overload;
2529
2530     sub import {
2531       shift;
2532       die "No argument to customre::import allowed" if @_;
2533       overload::constant 'qr' => \&convert;
2534     }
2535
2536     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2537
2538     # We must also take care of not escaping the legitimate \\Y|
2539     # sequence, hence the presence of '\\' in the conversion rules.
2540     my %rules = ( '\\' => '\\\\',
2541                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2542     sub convert {
2543       my $re = shift;
2544       $re =~ s{
2545                 \\ ( \\ | Y . )
2546               }
2547               { $rules{$1} or invalid($re,$1) }sgex;
2548       return $re;
2549     }
2550
2551 Now C<use customre> enables the new escape in constant regular
2552 expressions, i.e., those without any runtime variable interpolations.
2553 As documented in L<overload>, this conversion will work only over
2554 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2555 part of this regular expression needs to be converted explicitly
2556 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2557
2558     use customre;
2559     $re = <>;
2560     chomp $re;
2561     $re = customre::convert $re;
2562     /\Y|$re\Y|/;
2563
2564 =head2 PCRE/Python Support
2565
2566 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2567 to the regex syntax. While Perl programmers are encouraged to use the
2568 Perl-specific syntax, the following are also accepted:
2569
2570 =over 4
2571
2572 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2573
2574 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2575
2576 =item C<< (?P=NAME) >>
2577
2578 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2579
2580 =item C<< (?P>NAME) >>
2581
2582 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2583
2584 =back
2585
2586 =head1 BUGS
2587
2588 Many regular expression constructs don't work on EBCDIC platforms.
2589
2590 There are a number of issues with regard to case-insensitive matching
2591 in Unicode rules.  See C<i> under L</Modifiers> above.
2592
2593 This document varies from difficult to understand to completely
2594 and utterly opaque.  The wandering prose riddled with jargon is
2595 hard to fathom in several places.
2596
2597 This document needs a rewrite that separates the tutorial content
2598 from the reference content.
2599
2600 =head1 SEE ALSO
2601
2602 L<perlrequick>.
2603
2604 L<perlretut>.
2605
2606 L<perlop/"Regexp Quote-Like Operators">.
2607
2608 L<perlop/"Gory details of parsing quoted constructs">.
2609
2610 L<perlfaq6>.
2611
2612 L<perlfunc/pos>.
2613
2614 L<perllocale>.
2615
2616 L<perlebcdic>.
2617
2618 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2619 by O'Reilly and Associates.