This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Eliminate four unsightly magical hash refs
[perl5.git] / dist / ExtUtils-ParseXS / lib / ExtUtils / ParseXS.pm
1 package ExtUtils::ParseXS;
2 use strict;
3
4 use 5.006;  # We use /??{}/ in regexes
5 use Cwd;
6 use Config;
7 use Exporter;
8 use File::Basename;
9 use File::Spec;
10 use Symbol;
11 use ExtUtils::ParseXS::Constants ();
12 use ExtUtils::ParseXS::CountLines;
13 use ExtUtils::ParseXS::Utilities qw(
14   standard_typemap_locations
15   trim_whitespace
16   tidy_type
17   C_string
18   valid_proto_string
19   process_typemaps
20   make_targetable
21   map_type
22   standard_XS_defs
23   assign_func_args
24   analyze_preprocessor_statements
25   set_cond
26   Warn
27   blurt
28   death
29   check_conditional_preprocessor_statements
30 );
31
32 our @ISA = qw(Exporter);
33 our @EXPORT_OK = qw(
34   process_file
35   report_error_count
36 );
37 our $VERSION = '3';
38 $VERSION = eval $VERSION if $VERSION =~ /_/;
39
40 # The scalars in the line below remain as 'our' variables because pulling
41 # them into $self led to build problems.  In most cases, strings being
42 # 'eval'-ed contain the variables' names hard-coded.
43 our (
44   $FH, $Package, $func_name, $Full_func_name, $pname, $ALIAS,
45 );
46
47 our $self = bless {} => __PACKAGE__;
48
49 sub process_file {
50
51   # Allow for $package->process_file(%hash) in the future
52   my ($pkg, %options) = @_ % 2 ? @_ : (__PACKAGE__, @_);
53
54   $self->{ProtoUsed} = exists $options{prototypes};
55
56   # Set defaults.
57   my %args = (
58     argtypes        => 1,
59     csuffix         => '.c',
60     except          => 0,
61     hiertype        => 0,
62     inout           => 1,
63     linenumbers     => 1,
64     optimize        => 1,
65     output          => \*STDOUT,
66     prototypes      => 0,
67     typemap         => [],
68     versioncheck    => 1,
69     %options,
70   );
71   $args{except} = $args{except} ? ' TRY' : '';
72
73   # Global Constants
74
75   my ($Is_VMS, $SymSet);
76   if ($^O eq 'VMS') {
77     $Is_VMS = 1;
78     # Establish set of global symbols with max length 28, since xsubpp
79     # will later add the 'XS_' prefix.
80     require ExtUtils::XSSymSet;
81     $SymSet = new ExtUtils::XSSymSet 28;
82   }
83   @{ $self->{XSStack} } = ({type => 'none'});
84   $self->{InitFileCode} = [ @ExtUtils::ParseXS::Constants::InitFileCode ];
85   $FH                   = $ExtUtils::ParseXS::Constants::FH;
86   $self->{Overload}     = $ExtUtils::ParseXS::Constants::Overload;
87   $self->{errors}       = $ExtUtils::ParseXS::Constants::errors;
88   $self->{Fallback}     = $ExtUtils::ParseXS::Constants::Fallback;
89
90   # Most of the 1500 lines below uses these globals.  We'll have to
91   # clean this up sometime, probably.  For now, we just pull them out
92   # of %args.  -Ken
93
94   $self->{hiertype} = $args{hiertype};
95   $self->{WantPrototypes} = $args{prototypes};
96   $self->{WantVersionChk} = $args{versioncheck};
97   $self->{WantLineNumbers} = $args{linenumbers};
98   $self->{IncludedFiles} = {};
99
100   die "Missing required parameter 'filename'" unless $args{filename};
101   $self->{filepathname} = $args{filename};
102   ($self->{dir}, $self->{filename}) =
103     (dirname($args{filename}), basename($args{filename}));
104   $self->{filepathname} =~ s/\\/\\\\/g;
105   $self->{IncludedFiles}->{$args{filename}}++;
106
107   # Open the output file if given as a string.  If they provide some
108   # other kind of reference, trust them that we can print to it.
109   if (not ref $args{output}) {
110     open my($fh), "> $args{output}" or die "Can't create $args{output}: $!";
111     $args{outfile} = $args{output};
112     $args{output} = $fh;
113   }
114
115   # Really, we shouldn't have to chdir() or select() in the first
116   # place.  For now, just save and restore.
117   my $orig_cwd = cwd();
118   my $orig_fh = select();
119
120   chdir($self->{dir});
121   my $pwd = cwd();
122   my $csuffix = $args{csuffix};
123
124   if ($self->{WantLineNumbers}) {
125     my $cfile;
126     if ( $args{outfile} ) {
127       $cfile = $args{outfile};
128     }
129     else {
130       $cfile = $args{filename};
131       $cfile =~ s/\.xs$/$csuffix/i or $cfile .= $csuffix;
132     }
133     tie(*PSEUDO_STDOUT, 'ExtUtils::ParseXS::CountLines', $cfile, $args{output});
134     select PSEUDO_STDOUT;
135   }
136   else {
137     select $args{output};
138   }
139
140   $self->{typemap} = process_typemaps( $args{typemap}, $pwd );
141
142   my $END = "!End!\n\n";        # "impossible" keyword (multiple newline)
143
144   # Match an XS keyword
145   $self->{BLOCK_re} = '\s*(' .
146     join('|' => @ExtUtils::ParseXS::Constants::XSKeywords) .
147     "|$END)\\s*:";
148
149   our ($C_group_rex, $C_arg);
150   # Group in C (no support for comments or literals)
151   $C_group_rex = qr/ [({\[]
152                (?: (?> [^()\[\]{}]+ ) | (??{ $C_group_rex }) )*
153                [)}\]] /x;
154   # Chunk in C without comma at toplevel (no comments):
155   $C_arg = qr/ (?: (?> [^()\[\]{},"']+ )
156          |   (??{ $C_group_rex })
157          |   " (?: (?> [^\\"]+ )
158            |   \\.
159            )* "        # String literal
160                 |   ' (?: (?> [^\\']+ ) | \\. )* ' # Char literal
161          )* /xs;
162
163   # Since at this point we're ready to begin printing to the output file and
164   # reading from the input file, I want to get as much data as possible into
165   # the proto-object $self.  That means assigning to $self and elements of
166   # %args referenced below this point.
167   # HOWEVER:  This resulted in an error when I tried:
168   #   $args{'s'} ---> $self->{s}.
169   # Use of uninitialized value in quotemeta at
170   #   .../blib/lib/ExtUtils/ParseXS.pm line 733
171
172   foreach my $datum ( qw| argtypes except inout optimize | ) {
173     $self->{$datum} = $args{$datum};
174   }
175
176   # Identify the version of xsubpp used
177   print <<EOM;
178 /*
179  * This file was generated automatically by ExtUtils::ParseXS version $VERSION from the
180  * contents of $self->{filename}. Do not edit this file, edit $self->{filename} instead.
181  *
182  *    ANY CHANGES MADE HERE WILL BE LOST!
183  *
184  */
185
186 EOM
187
188
189   print("#line 1 \"$self->{filepathname}\"\n")
190     if $self->{WantLineNumbers};
191
192   # Open the input file (using $self->{filename} which
193   # is a basename'd $args{filename} due to chdir above)
194   open($FH, $self->{filename}) or die "cannot open $self->{filename}: $!\n";
195
196   firstmodule:
197   while (<$FH>) {
198     if (/^=/) {
199       my $podstartline = $.;
200       do {
201         if (/^=cut\s*$/) {
202           # We can't just write out a /* */ comment, as our embedded
203           # POD might itself be in a comment. We can't put a /**/
204           # comment inside #if 0, as the C standard says that the source
205           # file is decomposed into preprocessing characters in the stage
206           # before preprocessing commands are executed.
207           # I don't want to leave the text as barewords, because the spec
208           # isn't clear whether macros are expanded before or after
209           # preprocessing commands are executed, and someone pathological
210           # may just have defined one of the 3 words as a macro that does
211           # something strange. Multiline strings are illegal in C, so
212           # the "" we write must be a string literal. And they aren't
213           # concatenated until 2 steps later, so we are safe.
214           #     - Nicholas Clark
215           print("#if 0\n  \"Skipped embedded POD.\"\n#endif\n");
216           printf("#line %d \"$self->{filepathname}\"\n", $. + 1)
217             if $self->{WantLineNumbers};
218           next firstmodule
219         }
220
221       } while (<$FH>);
222       # At this point $. is at end of file so die won't state the start
223       # of the problem, and as we haven't yet read any lines &death won't
224       # show the correct line in the message either.
225       die ("Error: Unterminated pod in $self->{filename}, line $podstartline\n")
226         unless $self->{lastline};
227     }
228     last if ($Package, $self->{Prefix}) =
229       /^MODULE\s*=\s*[\w:]+(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/;
230
231     print $_;
232   }
233   unless (defined $_) {
234     warn "Didn't find a 'MODULE ... PACKAGE ... PREFIX' line\n";
235     exit 0; # Not a fatal error for the caller process
236   }
237
238   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
239
240   standard_XS_defs();
241
242   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
243
244   $self->{lastline}    = $_;
245   $self->{lastline_no} = $.;
246
247   my $BootCode_ref = [];
248   my $XSS_work_idx = 0;
249   my $cpp_next_tmp = 'XSubPPtmpAAAA';
250  PARAGRAPH:
251   while (fetch_para()) {
252     my $outlist_ref  = [];
253     # Print initial preprocessor statements and blank lines
254     while (@{ $self->{line} } && $self->{line}->[0] !~ /^[^\#]/) {
255       my $ln = shift(@{ $self->{line} });
256       print $ln, "\n";
257       next unless $ln =~ /^\#\s*((if)(?:n?def)?|elsif|else|endif)\b/;
258       my $statement = $+;
259       ( $self, $XSS_work_idx, $BootCode_ref ) =
260         analyze_preprocessor_statements(
261           $self, $statement, $XSS_work_idx, $BootCode_ref
262         );
263     }
264
265     next PARAGRAPH unless @{ $self->{line} };
266
267     if ($XSS_work_idx && !$self->{XSStack}->[$XSS_work_idx]{varname}) {
268       # We are inside an #if, but have not yet #defined its xsubpp variable.
269       print "#define $cpp_next_tmp 1\n\n";
270       push(@{ $self->{InitFileCode} }, "#if $cpp_next_tmp\n");
271       push(@{ $BootCode_ref },     "#if $cpp_next_tmp");
272       $self->{XSStack}->[$XSS_work_idx]{varname} = $cpp_next_tmp++;
273     }
274
275     death( $self,
276       "Code is not inside a function"
277         ." (maybe last function was ended by a blank line "
278         ." followed by a statement on column one?)")
279       if $self->{line}->[0] =~ /^\s/;
280
281     # initialize info arrays
282     undef(%{ $self->{args_match} });
283     undef(%{ $self->{var_types} });
284     undef(%{ $self->{defaults} });
285     undef(%{ $self->{arg_list} });
286     undef(@{ $self->{proto_arg} });
287     undef($self->{processing_arg_with_types});
288     undef(%{ $self->{argtype_seen} });
289     undef(%{ $self->{in_out} });
290     undef(%{ $self->{lengthof} });
291     undef($self->{proto_in_this_xsub});
292     undef($self->{scope_in_this_xsub});
293     undef($self->{interface});
294     $self->{interface_macro} = 'XSINTERFACE_FUNC';
295     $self->{interface_macro_set} = 'XSINTERFACE_FUNC_SET';
296     $self->{ProtoThisXSUB} = $self->{WantPrototypes};
297     $self->{ScopeThisXSUB} = 0;
298     my $xsreturn = 0;
299
300     $_ = shift(@{ $self->{line} });
301     while (my $kwd = check_keyword("REQUIRE|PROTOTYPES|FALLBACK|VERSIONCHECK|INCLUDE(?:_COMMAND)?|SCOPE")) {
302       no strict 'refs';
303       &{"${kwd}_handler"}();
304       use strict 'refs';
305       next PARAGRAPH unless @{ $self->{line} };
306       $_ = shift(@{ $self->{line} });
307     }
308
309     if (check_keyword("BOOT")) {
310       check_conditional_preprocessor_statements($self);
311       push (@{ $BootCode_ref }, "#line $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} }] \"$self->{filepathname}\"")
312         if $self->{WantLineNumbers} && $self->{line}->[0] !~ /^\s*#\s*line\b/;
313       push (@{ $BootCode_ref }, @{ $self->{line} }, "");
314       next PARAGRAPH;
315     }
316
317     # extract return type, function name and arguments
318     ($self->{ret_type}) = tidy_type($_);
319     my $RETVAL_no_return = 1 if $self->{ret_type} =~ s/^NO_OUTPUT\s+//;
320
321     # Allow one-line ANSI-like declaration
322     unshift @{ $self->{line} }, $2
323       if $self->{argtypes}
324         and $self->{ret_type} =~ s/^(.*?\w.*?)\s*\b(\w+\s*\(.*)/$1/s;
325
326     # a function definition needs at least 2 lines
327     blurt( $self, "Error: Function definition too short '$self->{ret_type}'"), next PARAGRAPH
328       unless @{ $self->{line} };
329
330     my $externC = 1 if $self->{ret_type} =~ s/^extern "C"\s+//;
331     my $static  = 1 if $self->{ret_type} =~ s/^static\s+//;
332
333     my $func_header = shift(@{ $self->{line} });
334     blurt( $self, "Error: Cannot parse function definition from '$func_header'"), next PARAGRAPH
335       unless $func_header =~ /^(?:([\w:]*)::)?(\w+)\s*\(\s*(.*?)\s*\)\s*(const)?\s*(;\s*)?$/s;
336
337     my ($class, $orig_args);
338     ($class, $func_name, $orig_args) =  ($1, $2, $3);
339     $class = "$4 $class" if $4;
340     ($pname = $func_name) =~ s/^($self->{Prefix})?/$self->{Packprefix}/;
341     my $clean_func_name;
342     ($clean_func_name = $func_name) =~ s/^$self->{Prefix}//;
343     $Full_func_name = "$self->{Packid}_$clean_func_name";
344     if ($Is_VMS) {
345       $Full_func_name = $SymSet->addsym($Full_func_name);
346     }
347
348     # Check for duplicate function definition
349     for my $tmp (@{ $self->{XSStack} }) {
350       next unless defined $tmp->{functions}{$Full_func_name};
351       Warn( $self, "Warning: duplicate function definition '$clean_func_name' detected");
352       last;
353     }
354     $self->{XSStack}->[$XSS_work_idx]{functions}{$Full_func_name}++;
355     %{ $self->{XsubAliases} }     = ();
356     %{ $self->{XsubAliasValues} } = ();
357     %{ $self->{Interfaces} }      = ();
358     @{ $self->{Attributes} }      = ();
359     $self->{DoSetMagic} = 1;
360
361     $orig_args =~ s/\\\s*/ /g;    # process line continuations
362     my @args;
363
364     my (@fake_INPUT_pre);    # For length(s) generated variables
365     my (@fake_INPUT);
366     my $only_C_inlist_ref = {};        # Not in the signature of Perl function
367     if ($self->{argtypes} and $orig_args =~ /\S/) {
368       my $args = "$orig_args ,";
369       if ($args =~ /^( (??{ $C_arg }) , )* $ /x) {
370         @args = ($args =~ /\G ( (??{ $C_arg }) ) , /xg);
371         for ( @args ) {
372           s/^\s+//;
373           s/\s+$//;
374           my ($arg, $default) = ($_ =~ m/ ( [^=]* ) ( (?: = .* )? ) /x);
375           my ($pre, $len_name) = ($arg =~ /(.*?) \s*
376                              \b ( \w+ | length\( \s*\w+\s* \) )
377                              \s* $ /x);
378           next unless defined($pre) && length($pre);
379           my $out_type = '';
380           my $inout_var;
381           if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//) {
382             my $type = $1;
383             $out_type = $type if $type ne 'IN';
384             $arg =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
385             $pre =~ s/^(IN|IN_OUTLIST|OUTLIST|OUT|IN_OUT)\b\s*//;
386           }
387           my $islength;
388           if ($len_name =~ /^length\( \s* (\w+) \s* \)\z/x) {
389             $len_name = "XSauto_length_of_$1";
390             $islength = 1;
391             die "Default value on length() argument: `$_'"
392               if length $default;
393           }
394           if (length $pre or $islength) { # Has a type
395             if ($islength) {
396               push @fake_INPUT_pre, $arg;
397             }
398             else {
399               push @fake_INPUT, $arg;
400             }
401             # warn "pushing '$arg'\n";
402             $self->{argtype_seen}->{$len_name}++;
403             $_ = "$len_name$default"; # Assigns to @args
404           }
405           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST" or $islength;
406           push @{ $outlist_ref }, $len_name if $out_type =~ /OUTLIST$/;
407           $self->{in_out}->{$len_name} = $out_type if $out_type;
408         }
409       }
410       else {
411         @args = split(/\s*,\s*/, $orig_args);
412         Warn( $self, "Warning: cannot parse argument list '$orig_args', fallback to split");
413       }
414     }
415     else {
416       @args = split(/\s*,\s*/, $orig_args);
417       for (@args) {
418         if ($self->{inout} and s/^(IN|IN_OUTLIST|OUTLIST|IN_OUT|OUT)\b\s*//) {
419           my $out_type = $1;
420           next if $out_type eq 'IN';
421           $only_C_inlist_ref->{$_} = 1 if $out_type eq "OUTLIST";
422           if ($out_type =~ /OUTLIST$/) {
423               push @{ $outlist_ref }, undef;
424           }
425           $self->{in_out}->{$_} = $out_type;
426         }
427       }
428     }
429     if (defined($class)) {
430       my $arg0 = ((defined($static) or $func_name eq 'new')
431           ? "CLASS" : "THIS");
432       unshift(@args, $arg0);
433     }
434     my $extra_args = 0;
435     my @args_num = ();
436     my $num_args = 0;
437     my $report_args = '';
438     my $ellipsis;
439     foreach my $i (0 .. $#args) {
440       if ($args[$i] =~ s/\.\.\.//) {
441         $ellipsis = 1;
442         if ($args[$i] eq '' && $i == $#args) {
443           $report_args .= ", ...";
444           pop(@args);
445           last;
446         }
447       }
448       if ($only_C_inlist_ref->{$args[$i]}) {
449         push @args_num, undef;
450       }
451       else {
452         push @args_num, ++$num_args;
453           $report_args .= ", $args[$i]";
454       }
455       if ($args[$i] =~ /^([^=]*[^\s=])\s*=\s*(.*)/s) {
456         $extra_args++;
457         $args[$i] = $1;
458         $self->{defaults}->{$args[$i]} = $2;
459         $self->{defaults}->{$args[$i]} =~ s/"/\\"/g;
460       }
461       $self->{proto_arg}->[$i+1] = '$';
462     }
463     my $min_args = $num_args - $extra_args;
464     $report_args =~ s/"/\\"/g;
465     $report_args =~ s/^,\s+//;
466     $self->{func_args} = assign_func_args($self, \@args, $class);
467     @{ $self->{args_match} }{@args} = @args_num;
468
469     my $PPCODE = grep(/^\s*PPCODE\s*:/, @{ $self->{line} });
470     my $CODE = grep(/^\s*CODE\s*:/, @{ $self->{line} });
471     # Detect CODE: blocks which use ST(n)= or XST_m*(n,v)
472     # to set explicit return values.
473     my $EXPLICIT_RETURN = ($CODE &&
474             ("@{ $self->{line} }" =~ /(\bST\s*\([^;]*=) | (\bXST_m\w+\s*\()/x ));
475
476     # The $ALIAS which follows is only explicitly called within the scope of
477     # process_file().  In principle, it ought to be a lexical, i.e., 'my
478     # $ALIAS' like the other nearby variables.  However, implementing that
479     # change produced a slight difference in the resulting .c output in at
480     # least two distributions:  B/BD/BDFOY/Crypt-Rijndael and
481     # G/GF/GFUJI/Hash-FieldHash.  The difference is, arguably, an improvement
482     # in the resulting C code.  Example:
483     # 388c388
484     # <                       GvNAME(CvGV(cv)),
485     # ---
486     # >                       "Crypt::Rijndael::encrypt",
487     # But at this point we're committed to generating the *same* C code that
488     # the current version of ParseXS.pm does.  So we're declaring it as 'our'.
489     $ALIAS  = grep(/^\s*ALIAS\s*:/,  @{ $self->{line} });
490
491     my $INTERFACE  = grep(/^\s*INTERFACE\s*:/,  @{ $self->{line} });
492
493     $xsreturn = 1 if $EXPLICIT_RETURN;
494
495     $externC = $externC ? qq[extern "C"] : "";
496
497     # print function header
498     print Q(<<"EOF");
499 #$externC
500 #XS(XS_${Full_func_name}); /* prototype to pass -Wmissing-prototypes */
501 #XS(XS_${Full_func_name})
502 #[[
503 ##ifdef dVAR
504 #    dVAR; dXSARGS;
505 ##else
506 #    dXSARGS;
507 ##endif
508 EOF
509     print Q(<<"EOF") if $ALIAS;
510 #    dXSI32;
511 EOF
512     print Q(<<"EOF") if $INTERFACE;
513 #    dXSFUNCTION($self->{ret_type});
514 EOF
515
516     $self->{cond} = set_cond($ellipsis, $min_args, $num_args);
517
518     print Q(<<"EOF") if $self->{except};
519 #    char errbuf[1024];
520 #    *errbuf = '\0';
521 EOF
522
523     if($self->{cond}) {
524       print Q(<<"EOF");
525 #    if ($self->{cond})
526 #       croak_xs_usage(cv,  "$report_args");
527 EOF
528     }
529     else {
530     # cv likely to be unused
531     print Q(<<"EOF");
532 #    PERL_UNUSED_VAR(cv); /* -W */
533 EOF
534     }
535
536     #gcc -Wall: if an xsub has PPCODE is used
537     #it is possible none of ST, XSRETURN or XSprePUSH macros are used
538     #hence `ax' (setup by dXSARGS) is unused
539     #XXX: could breakup the dXSARGS; into dSP;dMARK;dITEMS
540     #but such a move could break third-party extensions
541     print Q(<<"EOF") if $PPCODE;
542 #    PERL_UNUSED_VAR(ax); /* -Wall */
543 EOF
544
545     print Q(<<"EOF") if $PPCODE;
546 #    SP -= items;
547 EOF
548
549     # Now do a block of some sort.
550
551     $self->{condnum} = 0;
552     $self->{cond} = '';            # last CASE: conditional
553     push(@{ $self->{line} }, "$END:");
554     push(@{ $self->{line_no} }, $self->{line_no}->[-1]);
555     $_ = '';
556     check_conditional_preprocessor_statements($self);
557     while (@{ $self->{line} }) {
558       CASE_handler() if check_keyword("CASE");
559       print Q(<<"EOF");
560 #   $self->{except} [[
561 EOF
562
563       # do initialization of input variables
564       $self->{thisdone} = 0;
565       $self->{retvaldone} = 0;
566       $self->{deferred} = "";
567       %{ $self->{arg_list} } = ();
568       $self->{gotRETVAL} = 0;
569
570       INPUT_handler();
571       process_keyword("INPUT|PREINIT|INTERFACE_MACRO|C_ARGS|ALIAS|ATTRS|PROTOTYPE|SCOPE|OVERLOAD");
572
573       print Q(<<"EOF") if $self->{ScopeThisXSUB};
574 #   ENTER;
575 #   [[
576 EOF
577
578       if (!$self->{thisdone} && defined($class)) {
579         if (defined($static) or $func_name eq 'new') {
580           print "\tchar *";
581           $self->{var_types}->{"CLASS"} = "char *";
582           generate_init( {
583             type          => "char *",
584             num           => 1,
585             var           => "CLASS",
586             printed_name  => undef,
587           } );
588         }
589         else {
590           print "\t$class *";
591           $self->{var_types}->{"THIS"} = "$class *";
592           generate_init( {
593             type          => "$class *",
594             num           => 1,
595             var           => "THIS",
596             printed_name  => undef,
597           } );
598         }
599       }
600
601       my ($wantRETVAL);
602       # do code
603       if (/^\s*NOT_IMPLEMENTED_YET/) {
604         print "\n\tPerl_croak(aTHX_ \"$pname: not implemented yet\");\n";
605         $_ = '';
606       }
607       else {
608         if ($self->{ret_type} ne "void") {
609           print "\t" . map_type($self, $self->{ret_type}, 'RETVAL') . ";\n"
610             if !$self->{retvaldone};
611           $self->{args_match}->{"RETVAL"} = 0;
612           $self->{var_types}->{"RETVAL"} = $self->{ret_type};
613           my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
614           print "\tdXSTARG;\n"
615             if $self->{optimize} and $outputmap and $outputmap->targetable;
616         }
617
618         if (@fake_INPUT or @fake_INPUT_pre) {
619           unshift @{ $self->{line} }, @fake_INPUT_pre, @fake_INPUT, $_;
620           $_ = "";
621           $self->{processing_arg_with_types} = 1;
622           INPUT_handler();
623         }
624         print $self->{deferred};
625
626         process_keyword("INIT|ALIAS|ATTRS|PROTOTYPE|INTERFACE_MACRO|INTERFACE|C_ARGS|OVERLOAD");
627
628         if (check_keyword("PPCODE")) {
629           print_section();
630           death( $self, "PPCODE must be last thing") if @{ $self->{line} };
631           print "\tLEAVE;\n" if $self->{ScopeThisXSUB};
632           print "\tPUTBACK;\n\treturn;\n";
633         }
634         elsif (check_keyword("CODE")) {
635           print_section();
636         }
637         elsif (defined($class) and $func_name eq "DESTROY") {
638           print "\n\t";
639           print "delete THIS;\n";
640         }
641         else {
642           print "\n\t";
643           if ($self->{ret_type} ne "void") {
644             print "RETVAL = ";
645             $wantRETVAL = 1;
646           }
647           if (defined($static)) {
648             if ($func_name eq 'new') {
649               $func_name = "$class";
650             }
651             else {
652               print "${class}::";
653             }
654           }
655           elsif (defined($class)) {
656             if ($func_name eq 'new') {
657               $func_name .= " $class";
658             }
659             else {
660               print "THIS->";
661             }
662           }
663           $func_name =~ s/^\Q$args{'s'}//
664             if exists $args{'s'};
665           $func_name = 'XSFUNCTION' if $self->{interface};
666           print "$func_name($self->{func_args});\n";
667         }
668       }
669
670       # do output variables
671       $self->{gotRETVAL} = 0;        # 1 if RETVAL seen in OUTPUT section;
672       undef $self->{RETVAL_code} ;    # code to set RETVAL (from OUTPUT section);
673       # $wantRETVAL set if 'RETVAL =' autogenerated
674       ($wantRETVAL, $self->{ret_type}) = (0, 'void') if $RETVAL_no_return;
675       undef %{ $self->{outargs} };
676       process_keyword("POSTCALL|OUTPUT|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
677
678       generate_output( {
679         type        => $self->{var_types}->{$_},
680         num         => $self->{args_match}->{$_},
681         var         => $_,
682         do_setmagic => $self->{DoSetMagic},
683         do_push     => undef,
684       } ) for grep $self->{in_out}->{$_} =~ /OUT$/, keys %{ $self->{in_out} };
685
686       my $prepush_done;
687       # all OUTPUT done, so now push the return value on the stack
688       if ($self->{gotRETVAL} && $self->{RETVAL_code}) {
689         print "\t$self->{RETVAL_code}\n";
690       }
691       elsif ($self->{gotRETVAL} || $wantRETVAL) {
692         my $outputmap = $self->{typemap}->get_outputmap( ctype => $self->{ret_type} );
693         my $t = $self->{optimize} && $outputmap && $outputmap->targetable;
694         # Although the '$var' declared in the next line is never explicitly
695         # used within this 'elsif' block, commenting it out leads to
696         # disaster, starting with the first 'eval qq' inside the 'elsif' block
697         # below.
698         # It appears that this is related to the fact that at this point the
699         # value of $t is a reference to an array whose [2] element includes
700         # '$var' as a substring:
701         # <i> <> <(IV)$var>
702         my $var = 'RETVAL';
703         my $type = $self->{ret_type};
704
705         if ($t and not $t->{with_size} and $t->{type} eq 'p') {
706           # PUSHp corresponds to setpvn.  Treat setpv directly
707           my $what = eval qq("$t->{what}");
708           warn $@ if $@;
709
710           print "\tsv_setpv(TARG, $what); XSprePUSH; PUSHTARG;\n";
711           $prepush_done = 1;
712         }
713         elsif ($t) {
714           my $what = eval qq("$t->{what}");
715           warn $@ if $@;
716
717           my $tsize = $t->{what_size};
718           $tsize = '' unless defined $tsize;
719           $tsize = eval qq("$tsize");
720           warn $@ if $@;
721           print "\tXSprePUSH; PUSH$t->{type}($what$tsize);\n";
722           $prepush_done = 1;
723         }
724         else {
725           # RETVAL almost never needs SvSETMAGIC()
726           generate_output( {
727             type        => $self->{ret_type},
728             num         => 0,
729             var         => 'RETVAL',
730             do_setmagic => 0,
731             do_push     => undef,
732           } );
733         }
734       }
735
736       $xsreturn = 1 if $self->{ret_type} ne "void";
737       my $num = $xsreturn;
738       my $c = @{ $outlist_ref };
739       print "\tXSprePUSH;" if $c and not $prepush_done;
740       print "\tEXTEND(SP,$c);\n" if $c;
741       $xsreturn += $c;
742       generate_output( {
743         type        => $self->{var_types}->{$_},
744         num         => $num++,
745         var         => $_,
746         do_setmagic => 0,
747         do_push     => 1,
748       } ) for @{ $outlist_ref };
749
750       # do cleanup
751       process_keyword("CLEANUP|ALIAS|ATTRS|PROTOTYPE|OVERLOAD");
752
753       print Q(<<"EOF") if $self->{ScopeThisXSUB};
754 #   ]]
755 EOF
756       print Q(<<"EOF") if $self->{ScopeThisXSUB} and not $PPCODE;
757 #   LEAVE;
758 EOF
759
760       # print function trailer
761       print Q(<<"EOF");
762 #    ]]
763 EOF
764       print Q(<<"EOF") if $self->{except};
765 #    BEGHANDLERS
766 #    CATCHALL
767 #    sprintf(errbuf, "%s: %s\\tpropagated", Xname, Xreason);
768 #    ENDHANDLERS
769 EOF
770       if (check_keyword("CASE")) {
771         blurt( $self, "Error: No `CASE:' at top of function")
772           unless $self->{condnum};
773         $_ = "CASE: $_";    # Restore CASE: label
774         next;
775       }
776       last if $_ eq "$END:";
777       death( $self,
778         /^$self->{BLOCK_re}/o ? "Misplaced `$1:'" : "Junk at end of function ($_)");
779     }
780
781     print Q(<<"EOF") if $self->{except};
782 #    if (errbuf[0])
783 #    Perl_croak(aTHX_ errbuf);
784 EOF
785
786     if ($xsreturn) {
787       print Q(<<"EOF") unless $PPCODE;
788 #    XSRETURN($xsreturn);
789 EOF
790     }
791     else {
792       print Q(<<"EOF") unless $PPCODE;
793 #    XSRETURN_EMPTY;
794 EOF
795     }
796
797     print Q(<<"EOF");
798 #]]
799 #
800 EOF
801
802     $self->{newXS} = "newXS";
803     $self->{proto} = "";
804
805     # Build the prototype string for the xsub
806     if ($self->{ProtoThisXSUB}) {
807       $self->{newXS} = "newXSproto_portable";
808
809       if ($self->{ProtoThisXSUB} eq 2) {
810         # User has specified empty prototype
811       }
812       elsif ($self->{ProtoThisXSUB} eq 1) {
813         my $s = ';';
814         if ($min_args < $num_args)  {
815           $s = '';
816           $self->{proto_arg}->[$min_args] .= ";";
817         }
818         push @{ $self->{proto_arg} }, "$s\@"
819           if $ellipsis;
820
821         $self->{proto} = join ("", grep defined, @{ $self->{proto_arg} } );
822       }
823       else {
824         # User has specified a prototype
825         $self->{proto} = $self->{ProtoThisXSUB};
826       }
827       $self->{proto} = qq{, "$self->{proto}"};
828     }
829
830     if (%{ $self->{XsubAliases} }) {
831       $self->{XsubAliases}->{$pname} = 0
832         unless defined $self->{XsubAliases}->{$pname};
833       while ( my ($xname, $value) = each %{ $self->{XsubAliases} }) {
834         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
835 #        cv = $self->{newXS}(\"$xname\", XS_$Full_func_name, file$self->{proto});
836 #        XSANY.any_i32 = $value;
837 EOF
838       }
839     }
840     elsif (@{ $self->{Attributes} }) {
841       push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
842 #        cv = $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});
843 #        apply_attrs_string("$Package", cv, "@{ $self->{Attributes} }", 0);
844 EOF
845     }
846     elsif ($self->{interface}) {
847       while ( my ($yname, $value) = each %{ $self->{Interfaces} }) {
848         $yname = "$Package\::$yname" unless $yname =~ /::/;
849         push(@{ $self->{InitFileCode} }, Q(<<"EOF"));
850 #        cv = $self->{newXS}(\"$yname\", XS_$Full_func_name, file$self->{proto});
851 #        $self->{interface_macro_set}(cv,$value);
852 EOF
853       }
854     }
855     elsif($self->{newXS} eq 'newXS'){ # work around P5NCI's empty newXS macro
856       push(@{ $self->{InitFileCode} },
857        "        $self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
858     }
859     else {
860       push(@{ $self->{InitFileCode} },
861        "        (void)$self->{newXS}(\"$pname\", XS_$Full_func_name, file$self->{proto});\n");
862     }
863   } # END 'PARAGRAPH' 'while' loop
864
865   if ($self->{Overload}) { # make it findable with fetchmethod
866     print Q(<<"EOF");
867 #XS(XS_$self->{Packid}_nil); /* prototype to pass -Wmissing-prototypes */
868 #XS(XS_$self->{Packid}_nil)
869 #{
870 #   dXSARGS;
871 #   XSRETURN_EMPTY;
872 #}
873 #
874 EOF
875     unshift(@{ $self->{InitFileCode} }, <<"MAKE_FETCHMETHOD_WORK");
876     /* Making a sub named "${Package}::()" allows the package */
877     /* to be findable via fetchmethod(), and causes */
878     /* overload::Overloaded("${Package}") to return true. */
879     (void)$self->{newXS}("${Package}::()", XS_$self->{Packid}_nil, file$self->{proto});
880 MAKE_FETCHMETHOD_WORK
881   }
882
883   # print initialization routine
884
885   print Q(<<"EOF");
886 ##ifdef __cplusplus
887 #extern "C"
888 ##endif
889 EOF
890
891   print Q(<<"EOF");
892 #XS(boot_$self->{Module_cname}); /* prototype to pass -Wmissing-prototypes */
893 #XS(boot_$self->{Module_cname})
894 EOF
895
896   print Q(<<"EOF");
897 #[[
898 ##ifdef dVAR
899 #    dVAR; dXSARGS;
900 ##else
901 #    dXSARGS;
902 ##endif
903 EOF
904
905   #Under 5.8.x and lower, newXS is declared in proto.h as expecting a non-const
906   #file name argument. If the wrong qualifier is used, it causes breakage with
907   #C++ compilers and warnings with recent gcc.
908   #-Wall: if there is no $Full_func_name there are no xsubs in this .xs
909   #so `file' is unused
910   print Q(<<"EOF") if $Full_func_name;
911 ##if (PERL_REVISION == 5 && PERL_VERSION < 9)
912 #    char* file = __FILE__;
913 ##else
914 #    const char* file = __FILE__;
915 ##endif
916 EOF
917
918   print Q("#\n");
919
920   print Q(<<"EOF");
921 #    PERL_UNUSED_VAR(cv); /* -W */
922 #    PERL_UNUSED_VAR(items); /* -W */
923 ##ifdef XS_APIVERSION_BOOTCHECK
924 #    XS_APIVERSION_BOOTCHECK;
925 ##endif
926 EOF
927
928   print Q(<<"EOF") if $self->{WantVersionChk};
929 #    XS_VERSION_BOOTCHECK;
930 #
931 EOF
932
933   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
934 #    {
935 #        CV * cv;
936 #
937 EOF
938
939   print Q(<<"EOF") if ($self->{Overload});
940 #    /* register the overloading (type 'A') magic */
941 #    PL_amagic_generation++;
942 #    /* The magic for overload gets a GV* via gv_fetchmeth as */
943 #    /* mentioned above, and looks in the SV* slot of it for */
944 #    /* the "fallback" status. */
945 #    sv_setsv(
946 #        get_sv( "${Package}::()", TRUE ),
947 #        $self->{Fallback}
948 #    );
949 EOF
950
951   print @{ $self->{InitFileCode} };
952
953   print Q(<<"EOF") if defined $self->{xsubaliases} or defined $self->{interfaces};
954 #    }
955 EOF
956
957   if (@{ $BootCode_ref }) {
958     print "\n    /* Initialisation Section */\n\n";
959     @{ $self->{line} } = @{ $BootCode_ref };
960     print_section();
961     print "\n    /* End of Initialisation Section */\n\n";
962   }
963
964   print Q(<<'EOF');
965 ##if (PERL_REVISION == 5 && PERL_VERSION >= 9)
966 #  if (PL_unitcheckav)
967 #       call_list(PL_scopestack_ix, PL_unitcheckav);
968 ##endif
969 EOF
970
971   print Q(<<"EOF");
972 #    XSRETURN_YES;
973 #]]
974 #
975 EOF
976
977   warn("Please specify prototyping behavior for $self->{filename} (see perlxs manual)\n")
978     unless $self->{ProtoUsed};
979
980   chdir($orig_cwd);
981   select($orig_fh);
982   untie *PSEUDO_STDOUT if tied *PSEUDO_STDOUT;
983   close $FH;
984
985   return 1;
986 }
987
988 sub report_error_count { $self->{errors} }
989
990 # Input:  ($_, @{ $self->{line} }) == unparsed input.
991 # Output: ($_, @{ $self->{line} }) == (rest of line, following lines).
992 # Return: the matched keyword if found, otherwise 0
993 sub check_keyword {
994   $_ = shift(@{ $self->{line} }) while !/\S/ && @{ $self->{line} };
995   s/^(\s*)($_[0])\s*:\s*(?:#.*)?/$1/s && $2;
996 }
997
998 sub print_section {
999   # the "do" is required for right semantics
1000   do { $_ = shift(@{ $self->{line} }) } while !/\S/ && @{ $self->{line} };
1001
1002   print("#line ", $self->{line_no}->[@{ $self->{line_no} } - @{ $self->{line} } -1], " \"$self->{filepathname}\"\n")
1003     if $self->{WantLineNumbers} && !/^\s*#\s*line\b/ && !/^#if XSubPPtmp/;
1004   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1005     print "$_\n";
1006   }
1007   print 'ExtUtils::ParseXS::CountLines'->end_marker, "\n" if $self->{WantLineNumbers};
1008 }
1009
1010 sub merge_section {
1011   my $in = '';
1012
1013   while (!/\S/ && @{ $self->{line} }) {
1014     $_ = shift(@{ $self->{line} });
1015   }
1016
1017   for (;  defined($_) && !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1018     $in .= "$_\n";
1019   }
1020   chomp $in;
1021   return $in;
1022 }
1023
1024 sub process_keyword($) {
1025   my($pattern) = @_;
1026   my $kwd;
1027
1028   no strict 'refs';
1029   &{"${kwd}_handler"}()
1030     while $kwd = check_keyword($pattern);
1031   use strict 'refs';
1032 }
1033
1034 sub CASE_handler {
1035   blurt( $self, "Error: `CASE:' after unconditional `CASE:'")
1036     if $self->{condnum} && $self->{cond} eq '';
1037   $self->{cond} = $_;
1038   trim_whitespace($self->{cond});
1039   print "   ", ($self->{condnum}++ ? " else" : ""), ($self->{cond} ? " if ($self->{cond})\n" : "\n");
1040   $_ = '';
1041 }
1042
1043 sub INPUT_handler {
1044   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1045     last if /^\s*NOT_IMPLEMENTED_YET/;
1046     next unless /\S/;        # skip blank lines
1047
1048     trim_whitespace($_);
1049     my $ln = $_;
1050
1051     # remove trailing semicolon if no initialisation
1052     s/\s*;$//g unless /[=;+].*\S/;
1053
1054     # Process the length(foo) declarations
1055     if (s/^([^=]*)\blength\(\s*(\w+)\s*\)\s*$/$1 XSauto_length_of_$2=NO_INIT/x) {
1056       print "\tSTRLEN\tSTRLEN_length_of_$2;\n";
1057       $self->{lengthof}->{$2} = undef;
1058       $self->{deferred} .= "\n\tXSauto_length_of_$2 = STRLEN_length_of_$2;\n";
1059     }
1060
1061     # check for optional initialisation code
1062     my $var_init = '';
1063     $var_init = $1 if s/\s*([=;+].*)$//s;
1064     $var_init =~ s/"/\\"/g;
1065
1066     s/\s+/ /g;
1067     my ($var_type, $var_addr, $var_name) = /^(.*?[^&\s])\s*(\&?)\s*\b(\w+)$/s
1068       or blurt( $self, "Error: invalid argument declaration '$ln'"), next;
1069
1070     # Check for duplicate definitions
1071     blurt( $self, "Error: duplicate definition of argument '$var_name' ignored"), next
1072       if $self->{arg_list}->{$var_name}++
1073         or defined $self->{argtype_seen}->{$var_name} and not $self->{processing_arg_with_types};
1074
1075     $self->{thisdone} |= $var_name eq "THIS";
1076     $self->{retvaldone} |= $var_name eq "RETVAL";
1077     $self->{var_types}->{$var_name} = $var_type;
1078     # XXXX This check is a safeguard against the unfinished conversion of
1079     # generate_init().  When generate_init() is fixed,
1080     # one can use 2-args map_type() unconditionally.
1081     my $printed_name;
1082     if ($var_type =~ / \( \s* \* \s* \) /x) {
1083       # Function pointers are not yet supported with &output_init!
1084       print "\t" . map_type($self, $var_type, $var_name);
1085       $printed_name = 1;
1086     }
1087     else {
1088       print "\t" . map_type($self, $var_type, undef);
1089       $printed_name = 0;
1090     }
1091     $self->{var_num} = $self->{args_match}->{$var_name};
1092
1093     if ($self->{var_num}) {
1094       my $typemap = $self->{typemap}->get_typemap(ctype => $var_type);
1095       $self->{proto_arg}->[$self->{var_num}] = ($typemap && $typemap->proto) || "\$";
1096     }
1097     $self->{func_args} =~ s/\b($var_name)\b/&$1/ if $var_addr;
1098     if ($var_init =~ /^[=;]\s*NO_INIT\s*;?\s*$/
1099       or $self->{in_out}->{$var_name} and $self->{in_out}->{$var_name} =~ /^OUT/
1100       and $var_init !~ /\S/) {
1101       if ($printed_name) {
1102         print ";\n";
1103       }
1104       else {
1105         print "\t$var_name;\n";
1106       }
1107     }
1108     elsif ($var_init =~ /\S/) {
1109       output_init( {
1110         type          => $var_type,
1111         num           => $self->{var_num},
1112         var           => $var_name,
1113         init          => $var_init,
1114         printed_name  => $printed_name,
1115       } );
1116     }
1117     elsif ($self->{var_num}) {
1118       generate_init( {
1119         type          => $var_type,
1120         num           => $self->{var_num},
1121         var           => $var_name,
1122         printed_name  => $printed_name,
1123       } );
1124     }
1125     else {
1126       print ";\n";
1127     }
1128   }
1129 }
1130
1131 sub OUTPUT_handler {
1132   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1133     next unless /\S/;
1134     if (/^\s*SETMAGIC\s*:\s*(ENABLE|DISABLE)\s*/) {
1135       $self->{DoSetMagic} = ($1 eq "ENABLE" ? 1 : 0);
1136       next;
1137     }
1138     my ($outarg, $outcode) = /^\s*(\S+)\s*(.*?)\s*$/s;
1139     blurt( $self, "Error: duplicate OUTPUT argument '$outarg' ignored"), next
1140       if $self->{outargs}->{$outarg}++;
1141     if (!$self->{gotRETVAL} and $outarg eq 'RETVAL') {
1142       # deal with RETVAL last
1143       $self->{RETVAL_code} = $outcode;
1144       $self->{gotRETVAL} = 1;
1145       next;
1146     }
1147     blurt( $self, "Error: OUTPUT $outarg not an argument"), next
1148       unless defined($self->{args_match}->{$outarg});
1149     blurt( $self, "Error: No input definition for OUTPUT argument '$outarg' - ignored"), next
1150       unless defined $self->{var_types}->{$outarg};
1151     $self->{var_num} = $self->{args_match}->{$outarg};
1152     if ($outcode) {
1153       print "\t$outcode\n";
1154       print "\tSvSETMAGIC(ST(" , $self->{var_num} - 1 , "));\n" if $self->{DoSetMagic};
1155     }
1156     else {
1157       generate_output( {
1158         type        => $self->{var_types}->{$outarg},
1159         num         => $self->{var_num},
1160         var         => $outarg,
1161         do_setmagic => $self->{DoSetMagic},
1162         do_push     => undef,
1163       } );
1164     }
1165     delete $self->{in_out}->{$outarg}     # No need to auto-OUTPUT
1166       if exists $self->{in_out}->{$outarg} and $self->{in_out}->{$outarg} =~ /OUT$/;
1167   }
1168 }
1169
1170 sub C_ARGS_handler() {
1171   my $in = merge_section();
1172
1173   trim_whitespace($in);
1174   $self->{func_args} = $in;
1175 }
1176
1177 sub INTERFACE_MACRO_handler() {
1178   my $in = merge_section();
1179
1180   trim_whitespace($in);
1181   if ($in =~ /\s/) {        # two
1182     ($self->{interface_macro}, $self->{interface_macro_set}) = split ' ', $in;
1183   }
1184   else {
1185     $self->{interface_macro} = $in;
1186     $self->{interface_macro_set} = 'UNKNOWN_CVT'; # catch later
1187   }
1188   $self->{interface} = 1;        # local
1189   $self->{interfaces} = 1;        # global
1190 }
1191
1192 sub INTERFACE_handler() {
1193   my $in = merge_section();
1194
1195   trim_whitespace($in);
1196
1197   foreach (split /[\s,]+/, $in) {
1198     my $iface_name = $_;
1199     $iface_name =~ s/^$self->{Prefix}//;
1200     $self->{Interfaces}->{$iface_name} = $_;
1201   }
1202   print Q(<<"EOF");
1203 #    XSFUNCTION = $self->{interface_macro}($self->{ret_type},cv,XSANY.any_dptr);
1204 EOF
1205   $self->{interface} = 1;        # local
1206   $self->{interfaces} = 1;        # global
1207 }
1208
1209 sub CLEANUP_handler() { print_section() }
1210 sub PREINIT_handler() { print_section() }
1211 sub POSTCALL_handler() { print_section() }
1212 sub INIT_handler()    { print_section() }
1213
1214 sub GetAliases {
1215   my ($line) = @_;
1216   my ($orig) = $line;
1217
1218   # Parse alias definitions
1219   # format is
1220   #    alias = value alias = value ...
1221
1222   while ($line =~ s/^\s*([\w:]+)\s*=\s*(\w+)\s*//) {
1223     my ($alias, $value) = ($1, $2);
1224     my $orig_alias = $alias;
1225
1226     # check for optional package definition in the alias
1227     $alias = $self->{Packprefix} . $alias if $alias !~ /::/;
1228
1229     # check for duplicate alias name & duplicate value
1230     Warn( $self, "Warning: Ignoring duplicate alias '$orig_alias'")
1231       if defined $self->{XsubAliases}->{$alias};
1232
1233     Warn( $self, "Warning: Aliases '$orig_alias' and '$self->{XsubAliasValues}->{$value}' have identical values")
1234       if $self->{XsubAliasValues}->{$value};
1235
1236     $self->{xsubaliases} = 1;
1237     $self->{XsubAliases}->{$alias} = $value;
1238     $self->{XsubAliasValues}->{$value} = $orig_alias;
1239   }
1240
1241   blurt( $self, "Error: Cannot parse ALIAS definitions from '$orig'")
1242     if $line;
1243 }
1244
1245 sub ATTRS_handler () {
1246   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1247     next unless /\S/;
1248     trim_whitespace($_);
1249     push @{ $self->{Attributes} }, $_;
1250   }
1251 }
1252
1253 sub ALIAS_handler () {
1254   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1255     next unless /\S/;
1256     trim_whitespace($_);
1257     GetAliases($_) if $_;
1258   }
1259 }
1260
1261 sub OVERLOAD_handler() {
1262   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1263     next unless /\S/;
1264     trim_whitespace($_);
1265     while ( s/^\s*([\w:"\\)\+\-\*\/\%\<\>\.\&\|\^\!\~\{\}\=]+)\s*//) {
1266       $self->{Overload} = 1 unless $self->{Overload};
1267       my $overload = "$Package\::(".$1;
1268       push(@{ $self->{InitFileCode} },
1269        "        (void)$self->{newXS}(\"$overload\", XS_$Full_func_name, file$self->{proto});\n");
1270     }
1271   }
1272 }
1273
1274 sub FALLBACK_handler() {
1275   # the rest of the current line should contain either TRUE,
1276   # FALSE or UNDEF
1277
1278   trim_whitespace($_);
1279   my %map = (
1280     TRUE => "&PL_sv_yes", 1 => "&PL_sv_yes",
1281     FALSE => "&PL_sv_no", 0 => "&PL_sv_no",
1282     UNDEF => "&PL_sv_undef",
1283   );
1284
1285   # check for valid FALLBACK value
1286   death( $self, "Error: FALLBACK: TRUE/FALSE/UNDEF") unless exists $map{uc $_};
1287
1288   $self->{Fallback} = $map{uc $_};
1289 }
1290
1291
1292 sub REQUIRE_handler () {
1293   # the rest of the current line should contain a version number
1294   my ($Ver) = $_;
1295
1296   trim_whitespace($Ver);
1297
1298   death( $self, "Error: REQUIRE expects a version number")
1299     unless $Ver;
1300
1301   # check that the version number is of the form n.n
1302   death( $self, "Error: REQUIRE: expected a number, got '$Ver'")
1303     unless $Ver =~ /^\d+(\.\d*)?/;
1304
1305   death( $self, "Error: xsubpp $Ver (or better) required--this is only $VERSION.")
1306     unless $VERSION >= $Ver;
1307 }
1308
1309 sub VERSIONCHECK_handler () {
1310   # the rest of the current line should contain either ENABLE or
1311   # DISABLE
1312
1313   trim_whitespace($_);
1314
1315   # check for ENABLE/DISABLE
1316   death( $self, "Error: VERSIONCHECK: ENABLE/DISABLE")
1317     unless /^(ENABLE|DISABLE)/i;
1318
1319   $self->{WantVersionChk} = 1 if $1 eq 'ENABLE';
1320   $self->{WantVersionChk} = 0 if $1 eq 'DISABLE';
1321
1322 }
1323
1324 sub PROTOTYPE_handler () {
1325   my $specified;
1326
1327   death( $self, "Error: Only 1 PROTOTYPE definition allowed per xsub")
1328     if $self->{proto_in_this_xsub}++;
1329
1330   for (;  !/^$self->{BLOCK_re}/o;  $_ = shift(@{ $self->{line} })) {
1331     next unless /\S/;
1332     $specified = 1;
1333     trim_whitespace($_);
1334     if ($_ eq 'DISABLE') {
1335       $self->{ProtoThisXSUB} = 0;
1336     }
1337     elsif ($_ eq 'ENABLE') {
1338       $self->{ProtoThisXSUB} = 1;
1339     }
1340     else {
1341       # remove any whitespace
1342       s/\s+//g;
1343       death( $self, "Error: Invalid prototype '$_'")
1344         unless valid_proto_string($_);
1345       $self->{ProtoThisXSUB} = C_string($_);
1346     }
1347   }
1348
1349   # If no prototype specified, then assume empty prototype ""
1350   $self->{ProtoThisXSUB} = 2 unless $specified;
1351
1352   $self->{ProtoUsed} = 1;
1353 }
1354
1355 sub SCOPE_handler () {
1356   death( $self, "Error: Only 1 SCOPE declaration allowed per xsub")
1357     if $self->{scope_in_this_xsub}++;
1358
1359   trim_whitespace($_);
1360   death("Error: SCOPE: ENABLE/DISABLE")
1361       unless /^(ENABLE|DISABLE)\b/i;
1362   $self->{ScopeThisXSUB} = ( uc($1) eq 'ENABLE' );
1363 }
1364
1365 sub PROTOTYPES_handler () {
1366   # the rest of the current line should contain either ENABLE or
1367   # DISABLE
1368
1369   trim_whitespace($_);
1370
1371   # check for ENABLE/DISABLE
1372   death("Error: PROTOTYPES: ENABLE/DISABLE")
1373     unless /^(ENABLE|DISABLE)/i;
1374
1375   $self->{WantPrototypes} = 1 if $1 eq 'ENABLE';
1376   $self->{WantPrototypes} = 0 if $1 eq 'DISABLE';
1377   $self->{ProtoUsed} = 1;
1378
1379 }
1380
1381 sub PushXSStack {
1382   my %args = @_;
1383   # Save the current file context.
1384   push(@{ $self->{XSStack} }, {
1385           type            => 'file',
1386           LastLine        => $self->{lastline},
1387           LastLineNo      => $self->{lastline_no},
1388           Line            => $self->{line},
1389           LineNo          => $self->{line_no},
1390           Filename        => $self->{filename},
1391           Filepathname    => $self->{filepathname},
1392           Handle          => $FH,
1393           IsPipe          => scalar($self->{filename} =~ /\|\s*$/),
1394           %args,
1395          });
1396
1397 }
1398
1399 sub INCLUDE_handler () {
1400   # the rest of the current line should contain a valid filename
1401
1402   trim_whitespace($_);
1403
1404   death( $self, "INCLUDE: filename missing")
1405     unless $_;
1406
1407   death( $self, "INCLUDE: output pipe is illegal")
1408     if /^\s*\|/;
1409
1410   # simple minded recursion detector
1411   death( $self, "INCLUDE loop detected")
1412     if $self->{IncludedFiles}->{$_};
1413
1414   ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
1415
1416   if (/\|\s*$/ && /^\s*perl\s/) {
1417     Warn( $self, "The INCLUDE directive with a command is discouraged." .
1418           " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
1419           " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
1420           " up the correct perl. The INCLUDE_COMMAND directive allows" .
1421           " the use of \$^X as the currently running perl, see" .
1422           " 'perldoc perlxs' for details.");
1423   }
1424
1425   PushXSStack();
1426
1427   $FH = Symbol::gensym();
1428
1429   # open the new file
1430   open ($FH, "$_") or death( $self, "Cannot open '$_': $!");
1431
1432   print Q(<<"EOF");
1433 #
1434 #/* INCLUDE:  Including '$_' from '$self->{filename}' */
1435 #
1436 EOF
1437
1438   $self->{filename} = $_;
1439   $self->{filepathname} = File::Spec->catfile($self->{dir}, $self->{filename});
1440
1441   # Prime the pump by reading the first
1442   # non-blank line
1443
1444   # skip leading blank lines
1445   while (<$FH>) {
1446     last unless /^\s*$/;
1447   }
1448
1449   $self->{lastline} = $_;
1450   $self->{lastline_no} = $.;
1451 }
1452
1453 sub QuoteArgs {
1454   my $cmd = shift;
1455   my @args = split /\s+/, $cmd;
1456   $cmd = shift @args;
1457   for (@args) {
1458     $_ = q(").$_.q(") if !/^\"/ && length($_) > 0;
1459   }
1460   return join (' ', ($cmd, @args));
1461 }
1462
1463 sub INCLUDE_COMMAND_handler () {
1464   # the rest of the current line should contain a valid command
1465
1466   trim_whitespace($_);
1467
1468   $_ = QuoteArgs($_) if $^O eq 'VMS';
1469
1470   death( $self, "INCLUDE_COMMAND: command missing")
1471     unless $_;
1472
1473   death( $self, "INCLUDE_COMMAND: pipes are illegal")
1474     if /^\s*\|/ or /\|\s*$/;
1475
1476   PushXSStack( IsPipe => 1 );
1477
1478   $FH = Symbol::gensym();
1479
1480   # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
1481   # the same perl interpreter as we're currently running
1482   s/^\s*\$\^X/$^X/;
1483
1484   # open the new file
1485   open ($FH, "-|", "$_")
1486     or death( $self, "Cannot run command '$_' to include its output: $!");
1487
1488   print Q(<<"EOF");
1489 #
1490 #/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{filename}' */
1491 #
1492 EOF
1493
1494   $self->{filename} = $_;
1495   $self->{filepathname} = $self->{filename};
1496   $self->{filepathname} =~ s/\"/\\"/g;
1497
1498   # Prime the pump by reading the first
1499   # non-blank line
1500
1501   # skip leading blank lines
1502   while (<$FH>) {
1503     last unless /^\s*$/;
1504   }
1505
1506   $self->{lastline} = $_;
1507   $self->{lastline_no} = $.;
1508 }
1509
1510 sub PopFile() {
1511   return 0 unless $self->{XSStack}->[-1]{type} eq 'file';
1512
1513   my $data     = pop @{ $self->{XSStack} };
1514   my $ThisFile = $self->{filename};
1515   my $isPipe   = $data->{IsPipe};
1516
1517   --$self->{IncludedFiles}->{$self->{filename}}
1518     unless $isPipe;
1519
1520   close $FH;
1521
1522   $FH         = $data->{Handle};
1523   # $filename is the leafname, which for some reason isused for diagnostic
1524   # messages, whereas $filepathname is the full pathname, and is used for
1525   # #line directives.
1526   $self->{filename}   = $data->{Filename};
1527   $self->{filepathname} = $data->{Filepathname};
1528   $self->{lastline}   = $data->{LastLine};
1529   $self->{lastline_no} = $data->{LastLineNo};
1530   @{ $self->{line} }       = @{ $data->{Line} };
1531   @{ $self->{line_no} }    = @{ $data->{LineNo} };
1532
1533   if ($isPipe and $? ) {
1534     --$self->{lastline_no};
1535     print STDERR "Error reading from pipe '$ThisFile': $! in $self->{filename}, line $self->{lastline_no}\n" ;
1536     exit 1;
1537   }
1538
1539   print Q(<<"EOF");
1540 #
1541 #/* INCLUDE: Returning to '$self->{filename}' from '$ThisFile' */
1542 #
1543 EOF
1544
1545   return 1;
1546 }
1547
1548 sub Q {
1549   my($text) = @_;
1550   $text =~ s/^#//gm;
1551   $text =~ s/\[\[/{/g;
1552   $text =~ s/\]\]/}/g;
1553   $text;
1554 }
1555
1556 # Read next xsub into @{ $self->{line} } from ($lastline, <$FH>).
1557 sub fetch_para {
1558   # parse paragraph
1559   death("Error: Unterminated `#if/#ifdef/#ifndef'")
1560     if !defined $self->{lastline} && $self->{XSStack}->[-1]{type} eq 'if';
1561   @{ $self->{line} } = ();
1562   @{ $self->{line_no} } = ();
1563   return PopFile() if !defined $self->{lastline};
1564
1565   if ($self->{lastline} =~
1566       /^MODULE\s*=\s*([\w:]+)(?:\s+PACKAGE\s*=\s*([\w:]+))?(?:\s+PREFIX\s*=\s*(\S+))?\s*$/) {
1567     my $Module = $1;
1568     $Package = defined($2) ? $2 : ''; # keep -w happy
1569     $self->{Prefix}  = defined($3) ? $3 : ''; # keep -w happy
1570     $self->{Prefix} = quotemeta $self->{Prefix};
1571     ($self->{Module_cname} = $Module) =~ s/\W/_/g;
1572     ($self->{Packid} = $Package) =~ tr/:/_/;
1573     $self->{Packprefix} = $Package;
1574     $self->{Packprefix} .= "::" if $self->{Packprefix} ne "";
1575     $self->{lastline} = "";
1576   }
1577
1578   for (;;) {
1579     # Skip embedded PODs
1580     while ($self->{lastline} =~ /^=/) {
1581       while ($self->{lastline} = <$FH>) {
1582         last if ($self->{lastline} =~ /^=cut\s*$/);
1583       }
1584       death("Error: Unterminated pod") unless $self->{lastline};
1585       $self->{lastline} = <$FH>;
1586       chomp $self->{lastline};
1587       $self->{lastline} =~ s/^\s+$//;
1588     }
1589     if ($self->{lastline} !~ /^\s*#/ ||
1590     # CPP directives:
1591     #    ANSI:    if ifdef ifndef elif else endif define undef
1592     #        line error pragma
1593     #    gcc:    warning include_next
1594     #   obj-c:    import
1595     #   others:    ident (gcc notes that some cpps have this one)
1596     $self->{lastline} =~ /^#[ \t]*(?:(?:if|ifn?def|elif|else|endif|define|undef|pragma|error|warning|line\s+\d+|ident)\b|(?:include(?:_next)?|import)\s*["<].*[>"])/) {
1597       last if $self->{lastline} =~ /^\S/ && @{ $self->{line} } && $self->{line}->[-1] eq "";
1598       push(@{ $self->{line} }, $self->{lastline});
1599       push(@{ $self->{line_no} }, $self->{lastline_no});
1600     }
1601
1602     # Read next line and continuation lines
1603     last unless defined($self->{lastline} = <$FH>);
1604     $self->{lastline_no} = $.;
1605     my $tmp_line;
1606     $self->{lastline} .= $tmp_line
1607       while ($self->{lastline} =~ /\\$/ && defined($tmp_line = <$FH>));
1608
1609     chomp $self->{lastline};
1610     $self->{lastline} =~ s/^\s+$//;
1611   }
1612   pop(@{ $self->{line} }), pop(@{ $self->{line_no} }) while @{ $self->{line} } && $self->{line}->[-1] eq "";
1613   1;
1614 }
1615
1616 sub output_init {
1617   my $argsref = shift;
1618   my ($type, $num, $var, $init, $printed_name) = (
1619     $argsref->{type},
1620     $argsref->{num},
1621     $argsref->{var},
1622     $argsref->{init},
1623     $argsref->{printed_name}
1624   );
1625   my $arg = "ST(" . ($num - 1) . ")";
1626
1627   if (  $init =~ /^=/  ) {
1628     if ($printed_name) {
1629       eval qq/print " $init\\n"/;
1630     }
1631     else {
1632       eval qq/print "\\t$var $init\\n"/;
1633     }
1634     warn $@ if $@;
1635   }
1636   else {
1637     if (  $init =~ s/^\+//  &&  $num  ) {
1638       generate_init( {
1639         type          => $type,
1640         num           => $num,
1641         var           => $var,
1642         printed_name  => $printed_name,
1643       } );
1644     }
1645     elsif ($printed_name) {
1646       print ";\n";
1647       $init =~ s/^;//;
1648     }
1649     else {
1650       eval qq/print "\\t$var;\\n"/;
1651       warn $@ if $@;
1652       $init =~ s/^;//;
1653     }
1654     $self->{deferred} .= eval qq/"\\n\\t$init\\n"/;
1655     warn $@ if $@;
1656   }
1657 }
1658
1659 sub generate_init {
1660   my $argsref = shift;
1661   my ($type, $num, $var, $printed_name) = (
1662     $argsref->{type},
1663     $argsref->{num},
1664     $argsref->{var},
1665     $argsref->{printed_name},
1666   );
1667   my $arg = "ST(" . ($num - 1) . ")";
1668   my ($argoff, $ntype);
1669   $argoff = $num - 1;
1670
1671   my $typemaps = $self->{typemap};
1672
1673   $type = tidy_type($type);
1674   blurt( $self, "Error: '$type' not in typemap"), return
1675     unless $typemaps->get_typemap(ctype => $type);
1676
1677   ($ntype = $type) =~ s/\s*\*/Ptr/g;
1678   my $subtype;
1679   ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1680   my $typem = $typemaps->get_typemap(ctype => $type);
1681   my $xstype = $typem->xstype;
1682   $xstype =~ s/OBJ$/REF/ if $func_name =~ /DESTROY$/;
1683   if ($xstype eq 'T_PV' and exists $self->{lengthof}->{$var}) {
1684     print "\t$var" unless $printed_name;
1685     print " = ($type)SvPV($arg, STRLEN_length_of_$var);\n";
1686     die "default value not supported with length(NAME) supplied"
1687       if defined $self->{defaults}->{$var};
1688     return;
1689   }
1690   $type =~ tr/:/_/ unless $self->{hiertype};
1691
1692   my $inputmap = $typemaps->get_inputmap(xstype => $xstype);
1693   blurt( $self, "Error: No INPUT definition for type '$type', typekind '" . $type->xstype . "' found"), return
1694     unless defined $inputmap;
1695
1696   my $expr = $inputmap->cleaned_code;
1697   # Note: This gruesome bit either needs heavy rethinking or documentation. I vote for the former. --Steffen
1698   if ($expr =~ /DO_ARRAY_ELEM/) {
1699     my $subtypemap  = $typemaps->get_typemap(ctype => $subtype);
1700     my $subinputmap = $typemaps->get_inputmap(xstype => $subtypemap->xstype);
1701     blurt( $self, "Error: '$subtype' not in typemap"), return
1702       unless $subtypemap;
1703     blurt( $self, "Error: No INPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1704       unless $subinputmap;
1705     my $subexpr = $subinputmap->cleaned_code;
1706     $subexpr =~ s/\$type/\$subtype/g;
1707     $subexpr =~ s/ntype/subtype/g;
1708     $subexpr =~ s/\$arg/ST(ix_$var)/g;
1709     $subexpr =~ s/\n\t/\n\t\t/g;
1710     $subexpr =~ s/is not of (.*\")/[arg %d] is not of $1, ix_$var + 1/g;
1711     $subexpr =~ s/\$var/${var}[ix_$var - $argoff]/;
1712     $expr =~ s/DO_ARRAY_ELEM/$subexpr/;
1713   }
1714   if ($expr =~ m#/\*.*scope.*\*/#i) {  # "scope" in C comments
1715     $self->{ScopeThisXSUB} = 1;
1716   }
1717   if (defined($self->{defaults}->{$var})) {
1718     $expr =~ s/(\t+)/$1    /g;
1719     $expr =~ s/        /\t/g;
1720     if ($printed_name) {
1721       print ";\n";
1722     }
1723     else {
1724       eval qq/print "\\t$var;\\n"/;
1725       warn $@ if $@;
1726     }
1727     if ($self->{defaults}->{$var} eq 'NO_INIT') {
1728       $self->{deferred} .= eval qq/"\\n\\tif (items >= $num) {\\n$expr;\\n\\t}\\n"/;
1729     }
1730     else {
1731       $self->{deferred} .= eval qq/"\\n\\tif (items < $num)\\n\\t    $var = $self->{defaults}->{$var};\\n\\telse {\\n$expr;\\n\\t}\\n"/;
1732     }
1733     warn $@ if $@;
1734   }
1735   elsif ($self->{ScopeThisXSUB} or $expr !~ /^\s*\$var =/) {
1736     if ($printed_name) {
1737       print ";\n";
1738     }
1739     else {
1740       eval qq/print "\\t$var;\\n"/;
1741       warn $@ if $@;
1742     }
1743     $self->{deferred} .= eval qq/"\\n$expr;\\n"/;
1744     warn $@ if $@;
1745   }
1746   else {
1747     die "panic: do not know how to handle this branch for function pointers"
1748       if $printed_name;
1749     eval qq/print "$expr;\\n"/;
1750     warn $@ if $@;
1751   }
1752 }
1753
1754 sub generate_output {
1755   my $argsref = shift;
1756   my ($type, $num, $var, $do_setmagic, $do_push) = (
1757     $argsref->{type},
1758     $argsref->{num},
1759     $argsref->{var},
1760     $argsref->{do_setmagic},
1761     $argsref->{do_push}
1762   );
1763   my $arg = "ST(" . ($num - ($num != 0)) . ")";
1764   my $ntype;
1765
1766   my $typemaps = $self->{typemap};
1767
1768   $type = tidy_type($type);
1769   if ($type =~ /^array\(([^,]*),(.*)\)/) {
1770     print "\t$arg = sv_newmortal();\n";
1771     print "\tsv_setpvn($arg, (char *)$var, $2 * sizeof($1));\n";
1772     print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1773   }
1774   else {
1775     my $typemap   = $typemaps->get_typemap(ctype => $type);
1776     my $outputmap = $typemaps->get_outputmap(xstype => $typemap->xstype);
1777     blurt( $self, "Error: '$type' not in typemap"), return
1778       unless $typemap;
1779     blurt( $self, "Error: No OUTPUT definition for type '$type', typekind '" . $typemap->xstype . "' found"), return
1780       unless $outputmap;
1781     ($ntype = $type) =~ s/\s*\*/Ptr/g;
1782     $ntype =~ s/\(\)//g;
1783     my $subtype;
1784     ($subtype = $ntype) =~ s/(?:Array)?(?:Ptr)?$//;
1785
1786     my $expr = $outputmap->cleaned_code;
1787     if ($expr =~ /DO_ARRAY_ELEM/) {
1788       my $subtypemap   = $typemaps->get_typemap(ctype => $subtype);
1789       my $suboutputmap = $typemaps->get_outputmap(xstype => $subtypemap->xstype);
1790       blurt( $self, "Error: '$subtype' not in typemap"), return
1791         unless $subtypemap;
1792       blurt( $self, "Error: No OUTPUT definition for type '$subtype', typekind '" . $subtypemap->xstype . "' found"), return
1793         unless $suboutputmap;
1794       my $subexpr = $suboutputmap->cleaned_code;
1795       $subexpr =~ s/ntype/subtype/g;
1796       $subexpr =~ s/\$arg/ST(ix_$var)/g;
1797       $subexpr =~ s/\$var/${var}[ix_$var]/g;
1798       $subexpr =~ s/\n\t/\n\t\t/g;
1799       $expr =~ s/DO_ARRAY_ELEM\n/$subexpr/;
1800       eval "print qq\a$expr\a";
1801       warn $@ if $@;
1802       print "\t\tSvSETMAGIC(ST(ix_$var));\n" if $do_setmagic;
1803     }
1804     elsif ($var eq 'RETVAL') {
1805       if ($expr =~ /^\t\$arg = new/) {
1806         # We expect that $arg has refcnt 1, so we need to
1807         # mortalize it.
1808         eval "print qq\a$expr\a";
1809         warn $@ if $@;
1810         print "\tsv_2mortal(ST($num));\n";
1811         print "\tSvSETMAGIC(ST($num));\n" if $do_setmagic;
1812       }
1813       elsif ($expr =~ /^\s*\$arg\s*=/) {
1814         # We expect that $arg has refcnt >=1, so we need
1815         # to mortalize it!
1816         eval "print qq\a$expr\a";
1817         warn $@ if $@;
1818         print "\tsv_2mortal(ST(0));\n";
1819         print "\tSvSETMAGIC(ST(0));\n" if $do_setmagic;
1820       }
1821       else {
1822         # Just hope that the entry would safely write it
1823         # over an already mortalized value. By
1824         # coincidence, something like $arg = &sv_undef
1825         # works too.
1826         print "\tST(0) = sv_newmortal();\n";
1827         eval "print qq\a$expr\a";
1828         warn $@ if $@;
1829         # new mortals don't have set magic
1830       }
1831     }
1832     elsif ($do_push) {
1833       print "\tPUSHs(sv_newmortal());\n";
1834       $arg = "ST($num)";
1835       eval "print qq\a$expr\a";
1836       warn $@ if $@;
1837       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1838     }
1839     elsif ($arg =~ /^ST\(\d+\)$/) {
1840       eval "print qq\a$expr\a";
1841       warn $@ if $@;
1842       print "\tSvSETMAGIC($arg);\n" if $do_setmagic;
1843     }
1844   }
1845 }
1846
1847 1;
1848
1849 # vim: ts=2 sw=2 et: