t/op/lfs.t

   1 # NOTE: this file tests how large files (>2GB) work with perlio (stdio/sfio).
   2 # sysopen(), sysseek(), syswrite(), sysread() are tested in t/lib/syslfs.t.
   3 # If you modify/add tests here, remember to update also ext/Fcntl/t/syslfs.t.
   4
   5 BEGIN {
   6         chdir 't' if -d 't';
   7         @INC = '../lib';
   8         # Don't bother if there are no quad offsets.
   9         require Config; import Config;
  10         if ($Config{lseeksize} < 8) {
  11                 print "1..0 # Skip: no 64-bit file offsets\n";
  12                 exit(0);
  13         }
  14         require './test.pl';
  15 }
  16
  17 use strict;
  18
  19 our @s;
  20 our $fail;
  21
  22 my $big0 = tempfile();
  23 my $big1 = tempfile();
  24 my $big2 = tempfile();
  25
  26 sub zap {
  27     close(BIG);
  28 }
  29
  30 sub bye {
  31     zap();
  32     exit(0);
  33 }
  34
  35 my $explained;
  36
  37 sub explain {
  38     unless ($explained++) {
  39         print <<EOM;
  40 #
  41 # If the lfs (large file support: large meaning larger than two
  42 # gigabytes) tests are skipped or fail, it may mean either that your
  43 # process (or process group) is not allowed to write large files
  44 # (resource limits) or that the file system (the network filesystem?)
  45 # you are running the tests on doesn't let your user/group have large
  46 # files (quota) or the filesystem simply doesn't support large files.
  47 # You may even need to reconfigure your kernel.  (This is all very
  48 # operating system and site-dependent.)
  49 #
  50 # Perl may still be able to support large files, once you have
  51 # such a process, enough quota, and such a (file) system.
  52 # It is just that the test failed now.
  53 #
  54 EOM
  55     }
  56     if(@_) {
  57         print "1..0 # Skip: @_\n";
  58         bye();
  59     }
  60 }
  61
  62 $| = 1;
  63
  64 print "# checking whether we have sparse files...\n";
  65
  66 # Known have-nots.
  67 if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
  68     print "1..0 # Skip: no sparse files in $^O\n";
  69     bye();
  70 }
  71
  72 # Known haves that have problems running this test
  73 # (for example because they do not support sparse files, like UNICOS)
  74 if ($^O eq 'unicos') {
  75     print "1..0 # Skip: no sparse files in $^O, unable to test large files\n";
  76     bye();
  77 }
  78
  79 # Then try heuristically to deduce whether we have sparse files.
  80
  81 # Let's not depend on Fcntl or any other extension.
  82
  83 sub SEEK_SET () {0}
  84 sub SEEK_CUR () {1}
  85 sub SEEK_END () {2}
  86
  87 # We'll start off by creating a one megabyte file which has
  88 # only three "true" bytes.  If we have sparseness, we should
  89 # consume less blocks than one megabyte (assuming nobody has
  90 # one megabyte blocks...)
  91
  92 open(BIG, ">$big1") or
  93     do { warn "open $big1 failed: $!\n"; bye };
  94 binmode(BIG) or
  95     do { warn "binmode $big1 failed: $!\n"; bye };
  96 seek(BIG, 1_000_000, SEEK_SET) or
  97     do { warn "seek $big1 failed: $!\n"; bye };
  98 print BIG "big" or
  99     do { warn "print $big1 failed: $!\n"; bye };
 100 close(BIG) or
 101     do { warn "close $big1 failed: $!\n"; bye };
 102
 103 my @s1 = stat($big1);
 104
 105 print "# s1 = @s1\n";
 106
 107 open(BIG, ">$big2") or
 108     do { warn "open $big2 failed: $!\n"; bye };
 109 binmode(BIG) or
 110     do { warn "binmode $big2 failed: $!\n"; bye };
 111 seek(BIG, 2_000_000, SEEK_SET) or
 112     do { warn "seek $big2 failed: $!\n"; bye };
 113 print BIG "big" or
 114     do { warn "print $big2 failed: $!\n"; bye };
 115 close(BIG) or
 116     do { warn "close $big2 failed: $!\n"; bye };
 117
 118 my @s2 = stat($big2);
 119
 120 print "# s2 = @s2\n";
 121
 122 zap();
 123
 124 unless ($s1[7] == 1_000_003 && $s2[7] == 2_000_003 &&
 125         $s1[11] == $s2[11] && $s1[12] == $s2[12] &&
 126         $s1[12] > 0) {
 127         print "1..0 # Skip: no sparse files?\n";
 128         bye;
 129 }
 130
 131 print "# we seem to have sparse files...\n";
 132
 133 # By now we better be sure that we do have sparse files:
 134 # if we are not, the following will hog 5 gigabytes of disk.  Ooops.
 135 # This may fail by producing some signal; run in a subprocess first for safety
 136
 137 $ENV{LC_ALL} = "C";
 138
 139 my $r = system '../perl', '-e', <<"EOF";
 140 open my \$big, '>', q{$big0} or die qq{open $big0: $!};
 141 seek \$big, 5_000_000_000, 0 or die qq{seek $big0: $!};
 142 print \$big "big" or die qq{print $big0: $!};
 143 close \$big or die qq{close $big0: $!};
 144 exit 0;
 145 EOF
 146
 147 open(BIG, ">$big0") or do { warn "open failed: $!\n"; bye };
 148 binmode BIG;
 149 if ($r or not seek(BIG, 5_000_000_000, SEEK_SET)) {
 150     my $err = $r ? 'signal '.($r & 0x7f) : $!;
 151     explain("seeking past 2GB failed: $err");
 152 }
 153
 154 # Either the print or (more likely, thanks to buffering) the close will
 155 # fail if there are are filesize limitations (process or fs).
 156 my $print = print BIG "big";
 157 print "# print failed: $!\n" unless $print;
 158 my $close = close BIG;
 159 print "# close failed: $!\n" unless $close;
 160 unless ($print && $close) {
 161     if ($! =~/too large/i) {
 162         explain("writing past 2GB failed: process limits?");
 163     } elsif ($! =~ /quota/i) {
 164         explain("filesystem quota limits?");
 165     } else {
 166         explain("error: $!");
 167     }
 168 }
 169
 170 @s = stat($big0);
 171
 172 print "# @s\n";
 173
 174 unless ($s[7] == 5_000_000_003) {
 175     explain("kernel/fs not configured to use large files?");
 176 }
 177
 178 sub fail {
 179     print "not ";
 180     $fail++;
 181 }
 182
 183 sub offset ($$) {
 184     my ($offset_will_be, $offset_want) = @_;
 185     my $offset_is = eval $offset_will_be;
 186     unless ($offset_is == $offset_want) {
 187         print "# bad offset $offset_is, want $offset_want\n";
 188         my ($offset_func) = ($offset_will_be =~ /^(\w+)/);
 189         if (unpack("L", pack("L", $offset_want)) == $offset_is) {
 190             print "# 32-bit wraparound suspected in $offset_func() since\n";
 191             print "# $offset_want cast into 32 bits equals $offset_is.\n";
 192         } elsif ($offset_want - unpack("L", pack("L", $offset_want)) - 1
 193                  == $offset_is) {
 194             print "# 32-bit wraparound suspected in $offset_func() since\n";
 195             printf "# %s - unpack('L', pack('L', %s)) - 1 equals %s.\n",
 196                 $offset_want,
 197                 $offset_want,
 198                 $offset_is;
 199         }
 200         fail;
 201     }
 202 }
 203
 204 print "1..17\n";
 205
 206 $fail = 0;
 207
 208 fail unless $s[7] == 5_000_000_003;     # exercizes pp_stat
 209 print "ok 1\n";
 210
 211 fail unless -s $big0 == 5_000_000_003;  # exercizes pp_ftsize
 212 print "ok 2\n";
 213
 214 fail unless -e $big0;
 215 print "ok 3\n";
 216
 217 fail unless -f $big0;
 218 print "ok 4\n";
 219
 220 open(BIG, $big0) or do { warn "open failed: $!\n"; bye };
 221 binmode BIG;
 222
 223 fail unless seek(BIG, 4_500_000_000, SEEK_SET);
 224 print "ok 5\n";
 225
 226 offset('tell(BIG)', 4_500_000_000);
 227 print "ok 6\n";
 228
 229 fail unless seek(BIG, 1, SEEK_CUR);
 230 print "ok 7\n";
 231
 232 # If you get 205_032_705 from here it means that
 233 # your tell() is returning 32-bit values since (I32)4_500_000_001
 234 # is exactly 205_032_705.
 235 offset('tell(BIG)', 4_500_000_001);
 236 print "ok 8\n";
 237
 238 fail unless seek(BIG, -1, SEEK_CUR);
 239 print "ok 9\n";
 240
 241 offset('tell(BIG)', 4_500_000_000);
 242 print "ok 10\n";
 243
 244 fail unless seek(BIG, -3, SEEK_END);
 245 print "ok 11\n";
 246
 247 offset('tell(BIG)', 5_000_000_000);
 248 print "ok 12\n";
 249
 250 my $big;
 251
 252 fail unless read(BIG, $big, 3) == 3;
 253 print "ok 13\n";
 254
 255 fail unless $big eq "big";
 256 print "ok 14\n";
 257
 258 # 705_032_704 = (I32)5_000_000_000
 259 # See that we don't have "big" in the 705_... spot:
 260 # that would mean that we have a wraparound.
 261 fail unless seek(BIG, 705_032_704, SEEK_SET);
 262 print "ok 15\n";
 263
 264 my $zero;
 265
 266 fail unless read(BIG, $zero, 3) == 3;
 267 print "ok 16\n";
 268
 269 fail unless $zero eq "\0\0\0";
 270 print "ok 17\n";
 271
 272 explain() if $fail;
 273
 274 bye(); # does the necessary cleanup
 275
 276 END {
 277     # unlink may fail if applied directly to a large file
 278     # be paranoid about leaving 5 gig files lying around
 279     open(BIG, ">$big0"); # truncate
 280     close(BIG);
 281 }
 282
 283 # eof