This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
67ad3d1d0eff513fa118d63e888e4937083000be
[perl5.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<$filename>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 use Cwd ();
516
517 my $_initial_cwd;
518
519 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
520
521 BEGIN {
522     require feature;
523     $^V =~ /^v(\d+\.\d+)/;
524     feature->import(":$1");
525     $_initial_cwd = Cwd::getcwd();
526 }
527
528 # Debugger for Perl 5.00x; perl5db.pl patch level:
529 use vars qw($VERSION $header);
530
531 $VERSION = '1.49_02';
532
533 $header = "perl5db.pl version $VERSION";
534
535 =head1 DEBUGGER ROUTINES
536
537 =head2 C<DB::eval()>
538
539 This function replaces straight C<eval()> inside the debugger; it simplifies
540 the process of evaluating code in the user's context.
541
542 The code to be evaluated is passed via the package global variable
543 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
544
545 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
546 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
547 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
548 user's current package, grabbed when C<DB::DB> got control.  This causes the
549 proper context to be used when the eval is actually done.  Afterward, we
550 restore C<$trace>, C<$single>, and C<$^D>.
551
552 Next we need to handle C<$@> without getting confused. We save C<$@> in a
553 local lexical, localize C<$saved[0]> (which is where C<save()> will put
554 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
555 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
556 considered sane by the debugger. If there was an C<eval()> error, we print
557 it on the debugger's output. If C<$onetimedump> is defined, we call
558 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
559 'methods'. Setting it to something else causes the debugger to do the eval
560 but not print the result - handy if you want to do something else with it
561 (the "watch expressions" code does this to get the value of the watch
562 expression but not show it unless it matters).
563
564 In any case, we then return the list of output from C<eval> to the caller,
565 and unwinding restores the former version of C<$@> in C<@saved> as well
566 (the localization of C<$saved[0]> goes away at the end of this scope).
567
568 =head3 Parameters and variables influencing execution of DB::eval()
569
570 C<DB::eval> isn't parameterized in the standard way; this is to keep the
571 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
572 The variables listed below influence C<DB::eval()>'s execution directly.
573
574 =over 4
575
576 =item C<$evalarg> - the thing to actually be eval'ed
577
578 =item C<$trace> - Current state of execution tracing
579
580 =item C<$single> - Current state of single-stepping
581
582 =item C<$onetimeDump> - what is to be displayed after the evaluation
583
584 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
585
586 =back
587
588 The following variables are altered by C<DB::eval()> during its execution. They
589 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
590
591 =over 4
592
593 =item C<@res> - used to capture output from actual C<eval>.
594
595 =item C<$otrace> - saved value of C<$trace>.
596
597 =item C<$osingle> - saved value of C<$single>.
598
599 =item C<$od> - saved value of C<$^D>.
600
601 =item C<$saved[0]> - saved value of C<$@>.
602
603 =item $\ - for output of C<$@> if there is an evaluation error.
604
605 =back
606
607 =head3 The problem of lexicals
608
609 The context of C<DB::eval()> presents us with some problems. Obviously,
610 we want to be 'sandboxed' away from the debugger's internals when we do
611 the eval, but we need some way to control how punctuation variables and
612 debugger globals are used.
613
614 We can't use local, because the code inside C<DB::eval> can see localized
615 variables; and we can't use C<my> either for the same reason. The code
616 in this routine compromises and uses C<my>.
617
618 After this routine is over, we don't have user code executing in the debugger's
619 context, so we can use C<my> freely.
620
621 =cut
622
623 ############################################## Begin lexical danger zone
624
625 # 'my' variables used here could leak into (that is, be visible in)
626 # the context that the code being evaluated is executing in. This means that
627 # the code could modify the debugger's variables.
628 #
629 # Fiddling with the debugger's context could be Bad. We insulate things as
630 # much as we can.
631
632 use vars qw(
633     @args
634     %break_on_load
635     $CommandSet
636     $CreateTTY
637     $DBGR
638     @dbline
639     $dbline
640     %dbline
641     $dieLevel
642     $filename
643     $histfile
644     $histsize
645     $IN
646     $inhibit_exit
647     @ini_INC
648     $ini_warn
649     $maxtrace
650     $od
651     @options
652     $osingle
653     $otrace
654     $pager
655     $post
656     %postponed
657     $prc
658     $pre
659     $pretype
660     $psh
661     @RememberOnROptions
662     $remoteport
663     @res
664     $rl
665     @saved
666     $signalLevel
667     $sub
668     $term
669     $usercontext
670     $warnLevel
671 );
672
673 our (
674     @cmdfhs,
675     $evalarg,
676     $frame,
677     $hist,
678     $ImmediateStop,
679     $line,
680     $onetimeDump,
681     $onetimedumpDepth,
682     %option,
683     $OUT,
684     $packname,
685     $signal,
686     $single,
687     $start,
688     %sub,
689     $subname,
690     $trace,
691     $window,
692 );
693
694 # Used to save @ARGV and extract any debugger-related flags.
695 use vars qw(@ARGS);
696
697 # Used to prevent multiple entries to diesignal()
698 # (if for instance diesignal() itself dies)
699 use vars qw($panic);
700
701 # Used to prevent the debugger from running nonstop
702 # after a restart
703 our ($second_time);
704
705 sub _calc_usercontext {
706     my ($package) = @_;
707
708     # Cancel strict completely for the evaluated code, so the code
709     # the user evaluates won't be affected by it. (Shlomi Fish)
710     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
711     . "package $package;";    # this won't let them modify, alas
712 }
713
714 sub eval {
715
716     # 'my' would make it visible from user code
717     #    but so does local! --tchrist
718     # Remember: this localizes @DB::res, not @main::res.
719     local @res;
720     {
721
722         # Try to keep the user code from messing  with us. Save these so that
723         # even if the eval'ed code changes them, we can put them back again.
724         # Needed because the user could refer directly to the debugger's
725         # package globals (and any 'my' variables in this containing scope)
726         # inside the eval(), and we want to try to stay safe.
727         local $otrace  = $trace;
728         local $osingle = $single;
729         local $od      = $^D;
730
731         # Untaint the incoming eval() argument.
732         { ($evalarg) = $evalarg =~ /(.*)/s; }
733
734         # $usercontext built in DB::DB near the comment
735         # "set up the context for DB::eval ..."
736         # Evaluate and save any results.
737         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
738
739         # Restore those old values.
740         $trace  = $otrace;
741         $single = $osingle;
742         $^D     = $od;
743     }
744
745     # Save the current value of $@, and preserve it in the debugger's copy
746     # of the saved precious globals.
747     my $at = $@;
748
749     # Since we're only saving $@, we only have to localize the array element
750     # that it will be stored in.
751     local $saved[0];    # Preserve the old value of $@
752     eval { &DB::save };
753
754     # Now see whether we need to report an error back to the user.
755     if ($at) {
756         local $\ = '';
757         print $OUT $at;
758     }
759
760     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
761     # are package globals.
762     elsif ($onetimeDump) {
763         if ( $onetimeDump eq 'dump' ) {
764             local $option{dumpDepth} = $onetimedumpDepth
765               if defined $onetimedumpDepth;
766             dumpit( $OUT, \@res );
767         }
768         elsif ( $onetimeDump eq 'methods' ) {
769             methods( $res[0] );
770         }
771     } ## end elsif ($onetimeDump)
772     @res;
773 } ## end sub eval
774
775 ############################################## End lexical danger zone
776
777 # After this point it is safe to introduce lexicals.
778 # The code being debugged will be executing in its own context, and
779 # can't see the inside of the debugger.
780 #
781 # However, one should not overdo it: leave as much control from outside as
782 # possible. If you make something a lexical, it's not going to be addressable
783 # from outside the debugger even if you know its name.
784
785 # This file is automatically included if you do perl -d.
786 # It's probably not useful to include this yourself.
787 #
788 # Before venturing further into these twisty passages, it is
789 # wise to read the perldebguts man page or risk the ire of dragons.
790 #
791 # (It should be noted that perldebguts will tell you a lot about
792 # the underlying mechanics of how the debugger interfaces into the
793 # Perl interpreter, but not a lot about the debugger itself. The new
794 # comments in this code try to address this problem.)
795
796 # Note that no subroutine call is possible until &DB::sub is defined
797 # (for subroutines defined outside of the package DB). In fact the same is
798 # true if $deep is not defined.
799
800 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
801
802 # modified Perl debugger, to be run from Emacs in perldb-mode
803 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
804 # Johan Vromans -- upgrade to 4.0 pl 10
805 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
806 ########################################################################
807
808 =head1 DEBUGGER INITIALIZATION
809
810 The debugger starts up in phases.
811
812 =head2 BASIC SETUP
813
814 First, it initializes the environment it wants to run in: turning off
815 warnings during its own compilation, defining variables which it will need
816 to avoid warnings later, setting itself up to not exit when the program
817 terminates, and defaulting to printing return values for the C<r> command.
818
819 =cut
820
821 # Needed for the statement after exec():
822 #
823 # This BEGIN block is simply used to switch off warnings during debugger
824 # compilation. Probably it would be better practice to fix the warnings,
825 # but this is how it's done at the moment.
826
827 BEGIN {
828     $ini_warn = $^W;
829     $^W       = 0;
830 }    # Switch compilation warnings off until another BEGIN.
831
832 local ($^W) = 0;    # Switch run-time warnings off during init.
833
834 =head2 THREADS SUPPORT
835
836 If we are running under a threaded Perl, we require threads and threads::shared
837 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
838 threaded debugger control.  C<-dt> can also be used to set this.
839
840 Each new thread will be announced and the debugger prompt will always inform
841 you of each new thread created.  It will also indicate the thread id in which
842 we are currently running within the prompt like this:
843
844     [tid] DB<$i>
845
846 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
847 command prompt.  The prompt will show: C<[0]> when running under threads, but
848 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
849
850 While running under threads, when you set or delete a breakpoint (etc.), this
851 will apply to all threads, not just the currently running one.  When you are
852 in a currently executing thread, you will stay there until it completes.  With
853 the current implementation it is not currently possible to hop from one thread
854 to another.
855
856 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
857
858 Note that threading support was built into the debugger as of Perl version
859 C<5.8.6> and debugger version C<1.2.8>.
860
861 =cut
862
863 BEGIN {
864     # ensure we can share our non-threaded variables or no-op
865     if ($ENV{PERL5DB_THREADED}) {
866         require threads;
867         require threads::shared;
868         import threads::shared qw(share);
869         $DBGR;
870         share(\$DBGR);
871         lock($DBGR);
872         print "Threads support enabled\n";
873     } else {
874         *lock = sub(*) {};
875         *share = sub(\[$@%]) {};
876     }
877 }
878
879 # These variables control the execution of 'dumpvar.pl'.
880 {
881     package dumpvar;
882     use vars qw(
883     $hashDepth
884     $arrayDepth
885     $dumpDBFiles
886     $dumpPackages
887     $quoteHighBit
888     $printUndef
889     $globPrint
890     $usageOnly
891     );
892 }
893
894 # used to control die() reporting in diesignal()
895 {
896     package Carp;
897     use vars qw($CarpLevel);
898 }
899
900 # without threads, $filename is not defined until DB::DB is called
901 share($main::{'_<'.$filename}) if defined $filename;
902
903 # Command-line + PERLLIB:
904 # Save the contents of @INC before they are modified elsewhere.
905 @ini_INC = @INC;
906
907 # This was an attempt to clear out the previous values of various
908 # trapped errors. Apparently it didn't help. XXX More info needed!
909 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
910
911 # We set these variables to safe values. We don't want to blindly turn
912 # off warnings, because other packages may still want them.
913 $trace = $signal = $single = 0;    # Uninitialized warning suppression
914                                    # (local $^W cannot help - other packages!).
915
916 # Default to not exiting when program finishes; print the return
917 # value when the 'r' command is used to return from a subroutine.
918 $inhibit_exit = $option{PrintRet} = 1;
919
920 use vars qw($trace_to_depth);
921
922 # Default to 1E9 so it won't be limited to a certain recursion depth.
923 $trace_to_depth = 1E9;
924
925 =head1 OPTION PROCESSING
926
927 The debugger's options are actually spread out over the debugger itself and
928 C<dumpvar.pl>; some of these are variables to be set, while others are
929 subs to be called with a value. To try to make this a little easier to
930 manage, the debugger uses a few data structures to define what options
931 are legal and how they are to be processed.
932
933 First, the C<@options> array defines the I<names> of all the options that
934 are to be accepted.
935
936 =cut
937
938 @options = qw(
939   CommandSet   HistFile      HistSize
940   hashDepth    arrayDepth    dumpDepth
941   DumpDBFiles  DumpPackages  DumpReused
942   compactDump  veryCompact   quote
943   HighBit      undefPrint    globPrint
944   PrintRet     UsageOnly     frame
945   AutoTrace    TTY           noTTY
946   ReadLine     NonStop       LineInfo
947   maxTraceLen  recallCommand ShellBang
948   pager        tkRunning     ornaments
949   signalLevel  warnLevel     dieLevel
950   inhibit_exit ImmediateStop bareStringify
951   CreateTTY    RemotePort    windowSize
952   DollarCaretP
953 );
954
955 @RememberOnROptions = qw(DollarCaretP);
956
957 =pod
958
959 Second, C<optionVars> lists the variables that each option uses to save its
960 state.
961
962 =cut
963
964 use vars qw(%optionVars);
965
966 %optionVars = (
967     hashDepth     => \$dumpvar::hashDepth,
968     arrayDepth    => \$dumpvar::arrayDepth,
969     CommandSet    => \$CommandSet,
970     DumpDBFiles   => \$dumpvar::dumpDBFiles,
971     DumpPackages  => \$dumpvar::dumpPackages,
972     DumpReused    => \$dumpvar::dumpReused,
973     HighBit       => \$dumpvar::quoteHighBit,
974     undefPrint    => \$dumpvar::printUndef,
975     globPrint     => \$dumpvar::globPrint,
976     UsageOnly     => \$dumpvar::usageOnly,
977     CreateTTY     => \$CreateTTY,
978     bareStringify => \$dumpvar::bareStringify,
979     frame         => \$frame,
980     AutoTrace     => \$trace,
981     inhibit_exit  => \$inhibit_exit,
982     maxTraceLen   => \$maxtrace,
983     ImmediateStop => \$ImmediateStop,
984     RemotePort    => \$remoteport,
985     windowSize    => \$window,
986     HistFile      => \$histfile,
987     HistSize      => \$histsize,
988 );
989
990 =pod
991
992 Third, C<%optionAction> defines the subroutine to be called to process each
993 option.
994
995 =cut
996
997 use vars qw(%optionAction);
998
999 %optionAction = (
1000     compactDump   => \&dumpvar::compactDump,
1001     veryCompact   => \&dumpvar::veryCompact,
1002     quote         => \&dumpvar::quote,
1003     TTY           => \&TTY,
1004     noTTY         => \&noTTY,
1005     ReadLine      => \&ReadLine,
1006     NonStop       => \&NonStop,
1007     LineInfo      => \&LineInfo,
1008     recallCommand => \&recallCommand,
1009     ShellBang     => \&shellBang,
1010     pager         => \&pager,
1011     signalLevel   => \&signalLevel,
1012     warnLevel     => \&warnLevel,
1013     dieLevel      => \&dieLevel,
1014     tkRunning     => \&tkRunning,
1015     ornaments     => \&ornaments,
1016     RemotePort    => \&RemotePort,
1017     DollarCaretP  => \&DollarCaretP,
1018 );
1019
1020 =pod
1021
1022 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1023 option is used.
1024
1025 =cut
1026
1027 # Note that this list is not complete: several options not listed here
1028 # actually require that dumpvar.pl be loaded for them to work, but are
1029 # not in the table. A subsequent patch will correct this problem; for
1030 # the moment, we're just recommenting, and we are NOT going to change
1031 # function.
1032 use vars qw(%optionRequire);
1033
1034 %optionRequire = (
1035     compactDump => 'dumpvar.pl',
1036     veryCompact => 'dumpvar.pl',
1037     quote       => 'dumpvar.pl',
1038 );
1039
1040 =pod
1041
1042 There are a number of initialization-related variables which can be set
1043 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1044 variable. These are:
1045
1046 =over 4
1047
1048 =item C<$rl> - readline control XXX needs more explanation
1049
1050 =item C<$warnLevel> - whether or not debugger takes over warning handling
1051
1052 =item C<$dieLevel> - whether or not debugger takes over die handling
1053
1054 =item C<$signalLevel> - whether or not debugger takes over signal handling
1055
1056 =item C<$pre> - preprompt actions (array reference)
1057
1058 =item C<$post> - postprompt actions (array reference)
1059
1060 =item C<$pretype>
1061
1062 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1063
1064 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1065
1066 =back
1067
1068 =cut
1069
1070 # These guys may be defined in $ENV{PERL5DB} :
1071 $rl          = 1     unless defined $rl;
1072 $warnLevel   = 1     unless defined $warnLevel;
1073 $dieLevel    = 1     unless defined $dieLevel;
1074 $signalLevel = 1     unless defined $signalLevel;
1075 $pre         = []    unless defined $pre;
1076 $post        = []    unless defined $post;
1077 $pretype     = []    unless defined $pretype;
1078 $CreateTTY   = 3     unless defined $CreateTTY;
1079 $CommandSet  = '580' unless defined $CommandSet;
1080
1081 share($rl);
1082 share($warnLevel);
1083 share($dieLevel);
1084 share($signalLevel);
1085 share($pre);
1086 share($post);
1087 share($pretype);
1088 share($rl);
1089 share($CreateTTY);
1090 share($CommandSet);
1091
1092 =pod
1093
1094 The default C<die>, C<warn>, and C<signal> handlers are set up.
1095
1096 =cut
1097
1098 warnLevel($warnLevel);
1099 dieLevel($dieLevel);
1100 signalLevel($signalLevel);
1101
1102 =pod
1103
1104 The pager to be used is needed next. We try to get it from the
1105 environment first.  If it's not defined there, we try to find it in
1106 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1107 then call the C<pager()> function to save the pager name.
1108
1109 =cut
1110
1111 # This routine makes sure $pager is set up so that '|' can use it.
1112 pager(
1113
1114     # If PAGER is defined in the environment, use it.
1115     defined $ENV{PAGER}
1116     ? $ENV{PAGER}
1117
1118       # If not, see if Config.pm defines it.
1119     : eval { require Config }
1120       && defined $Config::Config{pager}
1121     ? $Config::Config{pager}
1122
1123       # If not, fall back to 'more'.
1124     : 'more'
1125   )
1126   unless defined $pager;
1127
1128 =pod
1129
1130 We set up the command to be used to access the man pages, the command
1131 recall character (C<!> unless otherwise defined) and the shell escape
1132 character (C<!> unless otherwise defined). Yes, these do conflict, and
1133 neither works in the debugger at the moment.
1134
1135 =cut
1136
1137 setman();
1138
1139 # Set up defaults for command recall and shell escape (note:
1140 # these currently don't work in linemode debugging).
1141 recallCommand("!") unless defined $prc;
1142 shellBang("!")     unless defined $psh;
1143
1144 =pod
1145
1146 We then set up the gigantic string containing the debugger help.
1147 We also set the limit on the number of arguments we'll display during a
1148 trace.
1149
1150 =cut
1151
1152 sethelp();
1153
1154 # If we didn't get a default for the length of eval/stack trace args,
1155 # set it here.
1156 $maxtrace = 400 unless defined $maxtrace;
1157
1158 =head2 SETTING UP THE DEBUGGER GREETING
1159
1160 The debugger I<greeting> helps to inform the user how many debuggers are
1161 running, and whether the current debugger is the primary or a child.
1162
1163 If we are the primary, we just hang onto our pid so we'll have it when
1164 or if we start a child debugger. If we are a child, we'll set things up
1165 so we'll have a unique greeting and so the parent will give us our own
1166 TTY later.
1167
1168 We save the current contents of the C<PERLDB_PIDS> environment variable
1169 because we mess around with it. We'll also need to hang onto it because
1170 we'll need it if we restart.
1171
1172 Child debuggers make a label out of the current PID structure recorded in
1173 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1174 yet so the parent will give them one later via C<resetterm()>.
1175
1176 =cut
1177
1178 # Save the current contents of the environment; we're about to
1179 # much with it. We'll need this if we have to restart.
1180 use vars qw($ini_pids);
1181 $ini_pids = $ENV{PERLDB_PIDS};
1182
1183 use vars qw ($pids $term_pid);
1184
1185 if ( defined $ENV{PERLDB_PIDS} ) {
1186
1187     # We're a child. Make us a label out of the current PID structure
1188     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1189     # a term yet so the parent will give us one later via resetterm().
1190
1191     my $env_pids = $ENV{PERLDB_PIDS};
1192     $pids = "[$env_pids]";
1193
1194     # Unless we are on OpenVMS, all programs under the DCL shell run under
1195     # the same PID.
1196
1197     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1198         $term_pid         = $$;
1199     }
1200     else {
1201         $ENV{PERLDB_PIDS} .= "->$$";
1202         $term_pid = -1;
1203     }
1204
1205 } ## end if (defined $ENV{PERLDB_PIDS...
1206 else {
1207
1208     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1209     # child debugger, and mark us as the parent, so we'll know to set up
1210     # more TTY's is we have to.
1211     $ENV{PERLDB_PIDS} = "$$";
1212     $pids             = "[pid=$$]";
1213     $term_pid         = $$;
1214 }
1215
1216 use vars qw($pidprompt);
1217 $pidprompt = '';
1218
1219 # Sets up $emacs as a synonym for $slave_editor.
1220 our ($slave_editor);
1221 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1222
1223 =head2 READING THE RC FILE
1224
1225 The debugger will read a file of initialization options if supplied. If
1226 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1227
1228 =cut
1229
1230 # As noted, this test really doesn't check accurately that the debugger
1231 # is running at a terminal or not.
1232
1233 use vars qw($rcfile);
1234 {
1235     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1236     # this is the wrong metric!
1237     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1238 }
1239
1240 =pod
1241
1242 The debugger does a safety test of the file to be read. It must be owned
1243 either by the current user or root, and must only be writable by the owner.
1244
1245 =cut
1246
1247 # This wraps a safety test around "do" to read and evaluate the init file.
1248 #
1249 # This isn't really safe, because there's a race
1250 # between checking and opening.  The solution is to
1251 # open and fstat the handle, but then you have to read and
1252 # eval the contents.  But then the silly thing gets
1253 # your lexical scope, which is unfortunate at best.
1254 sub safe_do {
1255     my $file = shift;
1256
1257     # Just exactly what part of the word "CORE::" don't you understand?
1258     local $SIG{__WARN__};
1259     local $SIG{__DIE__};
1260
1261     unless ( is_safe_file($file) ) {
1262         CORE::warn <<EO_GRIPE;
1263 perldb: Must not source insecure rcfile $file.
1264         You or the superuser must be the owner, and it must not
1265         be writable by anyone but its owner.
1266 EO_GRIPE
1267         return;
1268     } ## end unless (is_safe_file($file...
1269
1270     do $file;
1271     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1272 } ## end sub safe_do
1273
1274 # This is the safety test itself.
1275 #
1276 # Verifies that owner is either real user or superuser and that no
1277 # one but owner may write to it.  This function is of limited use
1278 # when called on a path instead of upon a handle, because there are
1279 # no guarantees that filename (by dirent) whose file (by ino) is
1280 # eventually accessed is the same as the one tested.
1281 # Assumes that the file's existence is not in doubt.
1282 sub is_safe_file {
1283     my $path = shift;
1284     stat($path) || return;    # mysteriously vaporized
1285     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1286
1287     return 0 if $uid != 0 && $uid != $<;
1288     return 0 if $mode & 022;
1289     return 1;
1290 } ## end sub is_safe_file
1291
1292 # If the rcfile (whichever one we decided was the right one to read)
1293 # exists, we safely do it.
1294 if ( -f $rcfile ) {
1295     safe_do("./$rcfile");
1296 }
1297
1298 # If there isn't one here, try the user's home directory.
1299 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1300     safe_do("$ENV{HOME}/$rcfile");
1301 }
1302
1303 # Else try the login directory.
1304 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1305     safe_do("$ENV{LOGDIR}/$rcfile");
1306 }
1307
1308 # If the PERLDB_OPTS variable has options in it, parse those out next.
1309 if ( defined $ENV{PERLDB_OPTS} ) {
1310     parse_options( $ENV{PERLDB_OPTS} );
1311 }
1312
1313 =pod
1314
1315 The last thing we do during initialization is determine which subroutine is
1316 to be used to obtain a new terminal when a new debugger is started. Right now,
1317 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1318 (darwin).
1319
1320 =cut
1321
1322 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1323 # Works if you're running an xterm or xterm-like window, or you're on
1324 # OS/2, or on Mac OS X. This may need some expansion.
1325
1326 if (not defined &get_fork_TTY)       # only if no routine exists
1327 {
1328     if ( defined $remoteport ) {
1329                                                  # Expect an inetd-like server
1330         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1331     }
1332     elsif (defined $ENV{TERM}                    # If we know what kind
1333                                                  # of terminal this is,
1334         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1335         and defined $ENV{DISPLAY}                # and what display it's on,
1336       )
1337     {
1338         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1339     }
1340     elsif ( $ENV{TMUX} ) {
1341         *get_fork_TTY = \&tmux_get_fork_TTY;
1342     }
1343     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1344         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1345     }
1346     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1347             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1348             and $ENV{TERM_PROGRAM}
1349                 eq 'Apple_Terminal'              # Terminal.app
1350             )
1351     {
1352         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1353     }
1354 } ## end if (not defined &get_fork_TTY...
1355
1356 # untaint $^O, which may have been tainted by the last statement.
1357 # see bug [perl #24674]
1358 $^O =~ m/^(.*)\z/;
1359 $^O = $1;
1360
1361 # Here begin the unreadable code.  It needs fixing.
1362
1363 =head2 RESTART PROCESSING
1364
1365 This section handles the restart command. When the C<R> command is invoked, it
1366 tries to capture all of the state it can into environment variables, and
1367 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1368 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1369 the R command stuffed into the environment variables.
1370
1371   PERLDB_RESTART   - flag only, contains no restart data itself.
1372   PERLDB_HIST      - command history, if it's available
1373   PERLDB_ON_LOAD   - breakpoints set by the rc file
1374   PERLDB_POSTPONE  - subs that have been loaded/not executed,
1375                      and have actions
1376   PERLDB_VISITED   - files that had breakpoints
1377   PERLDB_FILE_...  - breakpoints for a file
1378   PERLDB_OPT       - active options
1379   PERLDB_INC       - the original @INC
1380   PERLDB_PRETYPE   - preprompt debugger actions
1381   PERLDB_PRE       - preprompt Perl code
1382   PERLDB_POST      - post-prompt Perl code
1383   PERLDB_TYPEAHEAD - typeahead captured by readline()
1384
1385 We chug through all these variables and plug the values saved in them
1386 back into the appropriate spots in the debugger.
1387
1388 =cut
1389
1390 use vars qw(%postponed_file @typeahead);
1391
1392 our (@hist, @truehist);
1393
1394 sub _restore_shared_globals_after_restart
1395 {
1396     @hist          = get_list('PERLDB_HIST');
1397     %break_on_load = get_list("PERLDB_ON_LOAD");
1398     %postponed     = get_list("PERLDB_POSTPONE");
1399
1400     share(@hist);
1401     share(@truehist);
1402     share(%break_on_load);
1403     share(%postponed);
1404 }
1405
1406 sub _restore_breakpoints_and_actions {
1407
1408     my @had_breakpoints = get_list("PERLDB_VISITED");
1409
1410     for my $file_idx ( 0 .. $#had_breakpoints ) {
1411         my $filename = $had_breakpoints[$file_idx];
1412         my %pf = get_list("PERLDB_FILE_$file_idx");
1413         $postponed_file{ $filename } = \%pf if %pf;
1414         my @lines = sort {$a <=> $b} keys(%pf);
1415         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1416         for my $line_idx (0 .. $#lines) {
1417             _set_breakpoint_enabled_status(
1418                 $filename,
1419                 $lines[$line_idx],
1420                 ($enabled_statuses[$line_idx] ? 1 : ''),
1421             );
1422         }
1423     }
1424
1425     return;
1426 }
1427
1428 sub _restore_options_after_restart
1429 {
1430     my %options_map = get_list("PERLDB_OPT");
1431
1432     while ( my ( $opt, $val ) = each %options_map ) {
1433         $val =~ s/[\\\']/\\$1/g;
1434         parse_options("$opt'$val'");
1435     }
1436
1437     return;
1438 }
1439
1440 sub _restore_globals_after_restart
1441 {
1442     # restore original @INC
1443     @INC     = get_list("PERLDB_INC");
1444     @ini_INC = @INC;
1445
1446     # return pre/postprompt actions and typeahead buffer
1447     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1448     $pre       = [ get_list("PERLDB_PRE") ];
1449     $post      = [ get_list("PERLDB_POST") ];
1450     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1451
1452     return;
1453 }
1454
1455
1456 if ( exists $ENV{PERLDB_RESTART} ) {
1457
1458     # We're restarting, so we don't need the flag that says to restart anymore.
1459     delete $ENV{PERLDB_RESTART};
1460
1461     # $restart = 1;
1462     _restore_shared_globals_after_restart();
1463
1464     _restore_breakpoints_and_actions();
1465
1466     # restore options
1467     _restore_options_after_restart();
1468
1469     _restore_globals_after_restart();
1470 } ## end if (exists $ENV{PERLDB_RESTART...
1471
1472 =head2 SETTING UP THE TERMINAL
1473
1474 Now, we'll decide how the debugger is going to interact with the user.
1475 If there's no TTY, we set the debugger to run non-stop; there's not going
1476 to be anyone there to enter commands.
1477
1478 =cut
1479
1480 use vars qw($notty $console $tty $LINEINFO);
1481 use vars qw($lineinfo $doccmd);
1482
1483 our ($runnonstop);
1484
1485 # Local autoflush to avoid rt#116769,
1486 # as calling IO::File methods causes an unresolvable loop
1487 # that results in debugger failure.
1488 sub _autoflush {
1489     my $o = select($_[0]);
1490     $|++;
1491     select($o);
1492 }
1493
1494 if ($notty) {
1495     $runnonstop = 1;
1496     share($runnonstop);
1497 }
1498
1499 =pod
1500
1501 If there is a TTY, we have to determine who it belongs to before we can
1502 proceed. If this is a slave editor or graphical debugger (denoted by
1503 the first command-line switch being '-emacs'), we shift this off and
1504 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1505
1506 =cut
1507
1508 else {
1509
1510     # Is Perl being run from a slave editor or graphical debugger?
1511     # If so, don't use readline, and set $slave_editor = 1.
1512     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1513         $rl = 0;
1514         shift(@main::ARGV);
1515     }
1516
1517     #require Term::ReadLine;
1518
1519 =pod
1520
1521 We then determine what the console should be on various systems:
1522
1523 =over 4
1524
1525 =item * Cygwin - We use C<stdin> instead of a separate device.
1526
1527 =cut
1528
1529     if ( $^O eq 'cygwin' ) {
1530
1531         # /dev/tty is binary. use stdin for textmode
1532         undef $console;
1533     }
1534
1535 =item * Unix - use F</dev/tty>.
1536
1537 =cut
1538
1539     elsif ( -e "/dev/tty" ) {
1540         $console = "/dev/tty";
1541     }
1542
1543 =item * Windows or MSDOS - use C<con>.
1544
1545 =cut
1546
1547     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1548         $console = "con";
1549     }
1550
1551 =item * AmigaOS - use C<CONSOLE:>.
1552
1553 =cut
1554
1555     elsif ( $^O eq 'amigaos' ) {
1556         $console = "CONSOLE:";
1557     }
1558
1559 =item * VMS - use C<sys$command>.
1560
1561 =cut
1562
1563     else {
1564
1565         # everything else is ...
1566         $console = "sys\$command";
1567     }
1568
1569 =pod
1570
1571 =back
1572
1573 Several other systems don't use a specific console. We C<undef $console>
1574 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1575 with a slave editor).
1576
1577 =cut
1578
1579     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1580
1581         # /dev/tty is binary. use stdin for textmode
1582         $console = undef;
1583     }
1584
1585     if ( $^O eq 'NetWare' ) {
1586
1587         # /dev/tty is binary. use stdin for textmode
1588         $console = undef;
1589     }
1590
1591     # In OS/2, we need to use STDIN to get textmode too, even though
1592     # it pretty much looks like Unix otherwise.
1593     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1594     {    # In OS/2
1595         $console = undef;
1596     }
1597
1598 =pod
1599
1600 If there is a TTY hanging around from a parent, we use that as the console.
1601
1602 =cut
1603
1604     $console = $tty if defined $tty;
1605
1606 =head2 SOCKET HANDLING
1607
1608 The debugger is capable of opening a socket and carrying out a debugging
1609 session over the socket.
1610
1611 If C<RemotePort> was defined in the options, the debugger assumes that it
1612 should try to start a debugging session on that port. It builds the socket
1613 and then tries to connect the input and output filehandles to it.
1614
1615 =cut
1616
1617     # Handle socket stuff.
1618
1619     if ( defined $remoteport ) {
1620
1621         # If RemotePort was defined in the options, connect input and output
1622         # to the socket.
1623         $IN = $OUT = connect_remoteport();
1624     } ## end if (defined $remoteport)
1625
1626 =pod
1627
1628 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1629 this is probably a situation where multiple debuggers are running (for example,
1630 a backticked command that starts up another debugger). We create a new IN and
1631 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1632 and if we can.
1633
1634 =cut
1635
1636     # Non-socket.
1637     else {
1638
1639         # Two debuggers running (probably a system or a backtick that invokes
1640         # the debugger itself under the running one). create a new IN and OUT
1641         # filehandle, and do the necessary mojo to create a new tty if we
1642         # know how, and we can.
1643         create_IN_OUT(4) if $CreateTTY & 4;
1644         if ($console) {
1645
1646             # If we have a console, check to see if there are separate ins and
1647             # outs to open. (They are assumed identical if not.)
1648
1649             my ( $i, $o ) = split /,/, $console;
1650             $o = $i unless defined $o;
1651
1652             # read/write on in, or just read, or read on STDIN.
1653             open( IN,      "+<$i" )
1654               || open( IN, "<$i" )
1655               || open( IN, "<&STDIN" );
1656
1657             # read/write/create/clobber out, or write/create/clobber out,
1658             # or merge with STDERR, or merge with STDOUT.
1659                  open( OUT, "+>$o" )
1660               || open( OUT, ">$o" )
1661               || open( OUT, ">&STDERR" )
1662               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1663
1664         } ## end if ($console)
1665         elsif ( not defined $console ) {
1666
1667             # No console. Open STDIN.
1668             open( IN, "<&STDIN" );
1669
1670             # merge with STDERR, or with STDOUT.
1671             open( OUT,      ">&STDERR" )
1672               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1673             $console = 'STDIN/OUT';
1674         } ## end elsif (not defined $console)
1675
1676         # Keep copies of the filehandles so that when the pager runs, it
1677         # can close standard input without clobbering ours.
1678         if ($console or (not defined($console))) {
1679             $IN = \*IN;
1680             $OUT = \*OUT;
1681         }
1682     } ## end elsif (from if(defined $remoteport))
1683
1684     # Unbuffer DB::OUT. We need to see responses right away.
1685     _autoflush($OUT);
1686
1687     # Line info goes to debugger output unless pointed elsewhere.
1688     # Pointing elsewhere makes it possible for slave editors to
1689     # keep track of file and position. We have both a filehandle
1690     # and a I/O description to keep track of.
1691     $LINEINFO = $OUT     unless defined $LINEINFO;
1692     $lineinfo = $console unless defined $lineinfo;
1693     # share($LINEINFO); # <- unable to share globs
1694     share($lineinfo);   #
1695
1696 =pod
1697
1698 To finish initialization, we show the debugger greeting,
1699 and then call the C<afterinit()> subroutine if there is one.
1700
1701 =cut
1702
1703     # Show the debugger greeting.
1704     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1705     unless ($runnonstop) {
1706         local $\ = '';
1707         local $, = '';
1708         if ( $term_pid eq '-1' ) {
1709             print $OUT "\nDaughter DB session started...\n";
1710         }
1711         else {
1712             print $OUT "\nLoading DB routines from $header\n";
1713             print $OUT (
1714                 "Editor support ",
1715                 $slave_editor ? "enabled" : "available", ".\n"
1716             );
1717             print $OUT
1718 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1719         } ## end else [ if ($term_pid eq '-1')
1720     } ## end unless ($runnonstop)
1721 } ## end else [ if ($notty)
1722
1723 # XXX This looks like a bug to me.
1724 # Why copy to @ARGS and then futz with @args?
1725 @ARGS = @ARGV;
1726 # for (@args) {
1727     # Make sure backslashes before single quotes are stripped out, and
1728     # keep args unless they are numeric (XXX why?)
1729     # s/\'/\\\'/g;                      # removed while not justified understandably
1730     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1731 # }
1732
1733 # If there was an afterinit() sub defined, call it. It will get
1734 # executed in our scope, so it can fiddle with debugger globals.
1735 if ( defined &afterinit ) {    # May be defined in $rcfile
1736     afterinit();
1737 }
1738
1739 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1740 use vars qw($I_m_init);
1741
1742 $I_m_init = 1;
1743
1744 ############################################################ Subroutines
1745
1746 =head1 SUBROUTINES
1747
1748 =head2 DB
1749
1750 This gigantic subroutine is the heart of the debugger. Called before every
1751 statement, its job is to determine if a breakpoint has been reached, and
1752 stop if so; read commands from the user, parse them, and execute
1753 them, and then send execution off to the next statement.
1754
1755 Note that the order in which the commands are processed is very important;
1756 some commands earlier in the loop will actually alter the C<$cmd> variable
1757 to create other commands to be executed later. This is all highly I<optimized>
1758 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1759 see what's happening in any given command.
1760
1761 =cut
1762
1763 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1764
1765 use vars qw(
1766     $action
1767     $cmd
1768     $file
1769     $filename_ini
1770     $finished
1771     %had_breakpoints
1772     $level
1773     $max
1774     $package
1775     $try
1776 );
1777
1778 our (
1779     %alias,
1780     $doret,
1781     $end,
1782     $fall_off_end,
1783     $incr,
1784     $laststep,
1785     $rc,
1786     $sh,
1787     $stack_depth,
1788     @stack,
1789     @to_watch,
1790     @old_watch,
1791 );
1792
1793 sub _DB__determine_if_we_should_break
1794 {
1795     # if we have something here, see if we should break.
1796     # $stop is lexical and local to this block - $action on the other hand
1797     # is global.
1798     my $stop;
1799
1800     if ( $dbline{$line}
1801         && _is_breakpoint_enabled($filename, $line)
1802         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1803     {
1804
1805         # Stop if the stop criterion says to just stop.
1806         if ( $stop eq '1' ) {
1807             $signal |= 1;
1808         }
1809
1810         # It's a conditional stop; eval it in the user's context and
1811         # see if we should stop. If so, remove the one-time sigil.
1812         elsif ($stop) {
1813             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1814             # The &-call is here to ascertain the mutability of @_.
1815             &DB::eval;
1816             # If the breakpoint is temporary, then delete its enabled status.
1817             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1818                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1819             }
1820         }
1821     } ## end if ($dbline{$line} && ...
1822 }
1823
1824 sub _DB__is_finished {
1825     if ($finished and $level <= 1) {
1826         end_report();
1827         return 1;
1828     }
1829     else {
1830         return;
1831     }
1832 }
1833
1834 sub _DB__read_next_cmd
1835 {
1836     my ($tid) = @_;
1837
1838     # We have a terminal, or can get one ...
1839     if (!$term) {
1840         setterm();
1841     }
1842
1843     # ... and it belongs to this PID or we get one for this PID ...
1844     if ($term_pid != $$) {
1845         resetterm(1);
1846     }
1847
1848     # ... and we got a line of command input ...
1849     $cmd = DB::readline(
1850         "$pidprompt $tid DB"
1851         . ( '<' x $level )
1852         . ( $#hist + 1 )
1853         . ( '>' x $level ) . " "
1854     );
1855
1856     return defined($cmd);
1857 }
1858
1859 sub _DB__trim_command_and_return_first_component {
1860     my ($obj) = @_;
1861
1862     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1863     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1864
1865     my ($verb, $args) = $cmd =~ m{\A(\S*)\s*(.*)}s;
1866
1867     $obj->cmd_verb($verb);
1868     $obj->cmd_args($args);
1869
1870     return;
1871 }
1872
1873 sub _DB__handle_f_command {
1874     my ($obj) = @_;
1875
1876     if ($file = $obj->cmd_args) {
1877         # help for no arguments (old-style was return from sub).
1878         if ( !$file ) {
1879             print $OUT
1880             "The old f command is now the r command.\n";    # hint
1881             print $OUT "The new f command switches filenames.\n";
1882             next CMD;
1883         } ## end if (!$file)
1884
1885         # if not in magic file list, try a close match.
1886         if ( !defined $main::{ '_<' . $file } ) {
1887             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1888                 {
1889                     $try = substr( $try, 2 );
1890                     print $OUT "Choosing $try matching '$file':\n";
1891                     $file = $try;
1892                 }
1893             } ## end if (($try) = grep(m#^_<.*$file#...
1894         } ## end if (!defined $main::{ ...
1895
1896         # If not successfully switched now, we failed.
1897         if ( !defined $main::{ '_<' . $file } ) {
1898             print $OUT "No file matching '$file' is loaded.\n";
1899             next CMD;
1900         }
1901
1902         # We switched, so switch the debugger internals around.
1903         elsif ( $file ne $filename ) {
1904             *dbline   = $main::{ '_<' . $file };
1905             $max      = $#dbline;
1906             $filename = $file;
1907             $start    = 1;
1908             $cmd      = "l";
1909         } ## end elsif ($file ne $filename)
1910
1911         # We didn't switch; say we didn't.
1912         else {
1913             print $OUT "Already in $file.\n";
1914             next CMD;
1915         }
1916     }
1917
1918     return;
1919 }
1920
1921 sub _DB__handle_dot_command {
1922     my ($obj) = @_;
1923
1924     # . command.
1925     if ($obj->_is_full('.')) {
1926         $incr = -1;    # stay at current line
1927
1928         # Reset everything to the old location.
1929         $start    = $line;
1930         $filename = $filename_ini;
1931         *dbline   = $main::{ '_<' . $filename };
1932         $max      = $#dbline;
1933
1934         # Now where are we?
1935         print_lineinfo($obj->position());
1936         next CMD;
1937     }
1938
1939     return;
1940 }
1941
1942 sub _DB__handle_y_command {
1943     my ($obj) = @_;
1944
1945     if (my ($match_level, $match_vars)
1946         = $obj->cmd_args =~ /\A(?:(\d*)\s*(.*))?\z/) {
1947
1948         # See if we've got the necessary support.
1949         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1950             my $Err = $@;
1951             _db_warn(
1952                 $Err =~ /locate/
1953                 ? "PadWalker module not found - please install\n"
1954                 : $Err
1955             );
1956             next CMD;
1957         }
1958
1959         # Load up dumpvar if we don't have it. If we can, that is.
1960         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1961         defined &main::dumpvar
1962             or print $OUT "dumpvar.pl not available.\n"
1963             and next CMD;
1964
1965         # Got all the modules we need. Find them and print them.
1966         my @vars = split( ' ', $match_vars || '' );
1967
1968         # Find the pad.
1969         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 2 ) };
1970
1971         # Oops. Can't find it.
1972         if (my $Err = $@) {
1973             $Err =~ s/ at .*//;
1974             _db_warn($Err);
1975             next CMD;
1976         }
1977
1978         # Show the desired vars with dumplex().
1979         my $savout = select($OUT);
1980
1981         # Have dumplex dump the lexicals.
1982         foreach my $key (sort keys %$h) {
1983             dumpvar::dumplex( $key, $h->{$key},
1984                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1985                 @vars );
1986         }
1987         select($savout);
1988         next CMD;
1989     }
1990 }
1991
1992 sub _DB__handle_c_command {
1993     my ($obj) = @_;
1994
1995     my $i = $obj->cmd_args;
1996
1997     if ($i =~ m#\A[\w:]*\z#) {
1998
1999         # Hey, show's over. The debugged program finished
2000         # executing already.
2001         next CMD if _DB__is_finished();
2002
2003         # Capture the place to put a one-time break.
2004         $subname = $i;
2005
2006         #  Probably not needed, since we finish an interactive
2007         #  sub-session anyway...
2008         # local $filename = $filename;
2009         # local *dbline = *dbline; # XXX Would this work?!
2010         #
2011         # The above question wonders if localizing the alias
2012         # to the magic array works or not. Since it's commented
2013         # out, we'll just leave that to speculation for now.
2014
2015         # If the "subname" isn't all digits, we'll assume it
2016         # is a subroutine name, and try to find it.
2017         if ( $subname =~ /\D/ ) {    # subroutine name
2018             # Qualify it to the current package unless it's
2019             # already qualified.
2020             $subname = $package . "::" . $subname
2021             unless $subname =~ /::/;
2022
2023             # find_sub will return "file:line_number" corresponding
2024             # to where the subroutine is defined; we call find_sub,
2025             # break up the return value, and assign it in one
2026             # operation.
2027             ( $file, $i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2028
2029             # Force the line number to be numeric.
2030             $i = $i + 0;
2031
2032             # If we got a line number, we found the sub.
2033             if ($i) {
2034
2035                 # Switch all the debugger's internals around so
2036                 # we're actually working with that file.
2037                 $filename = $file;
2038                 *dbline   = $main::{ '_<' . $filename };
2039
2040                 # Mark that there's a breakpoint in this file.
2041                 $had_breakpoints{$filename} |= 1;
2042
2043                 # Scan forward to the first executable line
2044                 # after the 'sub whatever' line.
2045                 $max = $#dbline;
2046                 my $_line_num = $i;
2047                 while ($dbline[$_line_num] == 0 && $_line_num< $max)
2048                 {
2049                     $_line_num++;
2050                 }
2051                 $i = $_line_num;
2052             } ## end if ($i)
2053
2054             # We didn't find a sub by that name.
2055             else {
2056                 print $OUT "Subroutine $subname not found.\n";
2057                 next CMD;
2058             }
2059         } ## end if ($subname =~ /\D/)
2060
2061         # At this point, either the subname was all digits (an
2062         # absolute line-break request) or we've scanned through
2063         # the code following the definition of the sub, looking
2064         # for an executable, which we may or may not have found.
2065         #
2066         # If $i (which we set $subname from) is non-zero, we
2067         # got a request to break at some line somewhere. On
2068         # one hand, if there wasn't any real subroutine name
2069         # involved, this will be a request to break in the current
2070         # file at the specified line, so we have to check to make
2071         # sure that the line specified really is breakable.
2072         #
2073         # On the other hand, if there was a subname supplied, the
2074         # preceding block has moved us to the proper file and
2075         # location within that file, and then scanned forward
2076         # looking for the next executable line. We have to make
2077         # sure that one was found.
2078         #
2079         # On the gripping hand, we can't do anything unless the
2080         # current value of $i points to a valid breakable line.
2081         # Check that.
2082         if ($i) {
2083
2084             # Breakable?
2085             if ( $dbline[$i] == 0 ) {
2086                 print $OUT "Line $i not breakable.\n";
2087                 next CMD;
2088             }
2089
2090             # Yes. Set up the one-time-break sigil.
2091             $dbline{$i} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2092             _enable_breakpoint_temp_enabled_status($filename, $i);
2093         } ## end if ($i)
2094
2095         # Turn off stack tracing from here up.
2096         for my $j (0 .. $stack_depth) {
2097             $stack[ $j ] &= ~1;
2098         }
2099         last CMD;
2100     }
2101
2102     return;
2103 }
2104
2105 sub _DB__handle_forward_slash_command {
2106     my ($obj) = @_;
2107
2108     # The pattern as a string.
2109     use vars qw($inpat);
2110
2111     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2112
2113         # Remove the final slash.
2114         $inpat =~ s:([^\\])/$:$1:;
2115
2116         # If the pattern isn't null ...
2117         if ( $inpat ne "" ) {
2118
2119             # Turn off warn and die processing for a bit.
2120             local $SIG{__DIE__};
2121             local $SIG{__WARN__};
2122
2123             # Create the pattern.
2124             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2125             if ( $@ ne "" ) {
2126
2127                 # Oops. Bad pattern. No biscuit.
2128                 # Print the eval error and go back for more
2129                 # commands.
2130                 print {$OUT} "$@";
2131                 next CMD;
2132             }
2133             $obj->pat($inpat);
2134         } ## end if ($inpat ne "")
2135
2136         # Set up to stop on wrap-around.
2137         $end = $start;
2138
2139         # Don't move off the current line.
2140         $incr = -1;
2141
2142         my $pat = $obj->pat;
2143
2144         # Done in eval so nothing breaks if the pattern
2145         # does something weird.
2146         eval
2147         {
2148             no strict q/vars/;
2149             for (;;) {
2150                 # Move ahead one line.
2151                 ++$start;
2152
2153                 # Wrap if we pass the last line.
2154                 if ($start > $max) {
2155                     $start = 1;
2156                 }
2157
2158                 # Stop if we have gotten back to this line again,
2159                 last if ($start == $end);
2160
2161                 # A hit! (Note, though, that we are doing
2162                 # case-insensitive matching. Maybe a qr//
2163                 # expression would be better, so the user could
2164                 # do case-sensitive matching if desired.
2165                 if ($dbline[$start] =~ m/$pat/i) {
2166                     if ($slave_editor) {
2167                         # Handle proper escaping in the slave.
2168                         print {$OUT} "\032\032$filename:$start:0\n";
2169                     }
2170                     else {
2171                         # Just print the line normally.
2172                         print {$OUT} "$start:\t",$dbline[$start],"\n";
2173                     }
2174                     # And quit since we found something.
2175                     last;
2176                 }
2177             }
2178         };
2179
2180         if ($@) {
2181             warn $@;
2182         }
2183
2184         # If we wrapped, there never was a match.
2185         if ( $start == $end ) {
2186             print {$OUT} "/$pat/: not found\n";
2187         }
2188         next CMD;
2189     }
2190
2191     return;
2192 }
2193
2194 sub _DB__handle_question_mark_command {
2195     my ($obj) = @_;
2196
2197     # ? - backward pattern search.
2198     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2199
2200         # Get the pattern, remove trailing question mark.
2201         $inpat =~ s:([^\\])\?$:$1:;
2202
2203         # If we've got one ...
2204         if ( $inpat ne "" ) {
2205
2206             # Turn off die & warn handlers.
2207             local $SIG{__DIE__};
2208             local $SIG{__WARN__};
2209             eval '$inpat =~ m' . "\a$inpat\a";
2210
2211             if ( $@ ne "" ) {
2212
2213                 # Ouch. Not good. Print the error.
2214                 print $OUT $@;
2215                 next CMD;
2216             }
2217             $obj->pat($inpat);
2218         } ## end if ($inpat ne "")
2219
2220         # Where we are now is where to stop after wraparound.
2221         $end = $start;
2222
2223         # Don't move away from this line.
2224         $incr = -1;
2225
2226         my $pat = $obj->pat;
2227         # Search inside the eval to prevent pattern badness
2228         # from killing us.
2229         eval {
2230             no strict q/vars/;
2231             for (;;) {
2232                 # Back up a line.
2233                 --$start;
2234
2235                 # Wrap if we pass the first line.
2236
2237                 $start = $max if ($start <= 0);
2238
2239                 # Quit if we get back where we started,
2240                 last if ($start == $end);
2241
2242                 # Match?
2243                 if ($dbline[$start] =~ m/$pat/i) {
2244                     if ($slave_editor) {
2245                         # Yep, follow slave editor requirements.
2246                         print $OUT "\032\032$filename:$start:0\n";
2247                     }
2248                     else {
2249                         # Yep, just print normally.
2250                         print $OUT "$start:\t",$dbline[$start],"\n";
2251                     }
2252
2253                     # Found, so done.
2254                     last;
2255                 }
2256             }
2257         };
2258
2259         # Say we failed if the loop never found anything,
2260         if ( $start == $end ) {
2261             print {$OUT} "?$pat?: not found\n";
2262         }
2263         next CMD;
2264     }
2265
2266     return;
2267 }
2268
2269 sub _DB__handle_restart_and_rerun_commands {
2270     my ($obj) = @_;
2271
2272     my $cmd_cmd = $obj->cmd_verb;
2273     my $cmd_params = $obj->cmd_args;
2274     # R - restart execution.
2275     # rerun - controlled restart execution.
2276     if ($cmd_cmd eq 'rerun' or $cmd_params eq '') {
2277
2278         # Change directory to the initial current working directory on
2279         # the script startup, so if the debugged program changed the
2280         # directory, then we will still be able to find the path to the
2281         # the program. (perl 5 RT #121509 ).
2282         chdir ($_initial_cwd);
2283
2284         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2285
2286         # Close all non-system fds for a clean restart.  A more
2287         # correct method would be to close all fds that were not
2288         # open when the process started, but this seems to be
2289         # hard.  See "debugger 'R'estart and open database
2290         # connections" on p5p.
2291
2292         my $max_fd = 1024; # default if POSIX can't be loaded
2293         if (eval { require POSIX }) {
2294             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2295         }
2296
2297         if (defined $max_fd) {
2298             foreach ($^F+1 .. $max_fd-1) {
2299                 next unless open FD_TO_CLOSE, "<&=$_";
2300                 close(FD_TO_CLOSE);
2301             }
2302         }
2303
2304         # And run Perl again.  We use exec() to keep the
2305         # PID stable (and that way $ini_pids is still valid).
2306         exec(@args) or print {$OUT} "exec failed: $!\n";
2307
2308         last CMD;
2309     }
2310
2311     return;
2312 }
2313
2314 sub _DB__handle_run_command_in_pager_command {
2315     my ($obj) = @_;
2316
2317     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2318         if ( $pager =~ /^\|/ ) {
2319
2320             # Default pager is into a pipe. Redirect I/O.
2321             open( SAVEOUT, ">&STDOUT" )
2322             || _db_warn("Can't save STDOUT");
2323             open( STDOUT, ">&OUT" )
2324             || _db_warn("Can't redirect STDOUT");
2325         } ## end if ($pager =~ /^\|/)
2326         else {
2327
2328             # Not into a pipe. STDOUT is safe.
2329             open( SAVEOUT, ">&OUT" ) || _db_warn("Can't save DB::OUT");
2330         }
2331
2332         # Fix up environment to record we have less if so.
2333         fix_less();
2334
2335         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2336
2337             # Couldn't open pipe to pager.
2338             _db_warn("Can't pipe output to '$pager'");
2339             if ( $pager =~ /^\|/ ) {
2340
2341                 # Redirect I/O back again.
2342                 open( OUT, ">&STDOUT" )    # XXX: lost message
2343                 || _db_warn("Can't restore DB::OUT");
2344                 open( STDOUT, ">&SAVEOUT" )
2345                 || _db_warn("Can't restore STDOUT");
2346                 close(SAVEOUT);
2347             } ## end if ($pager =~ /^\|/)
2348             else {
2349
2350                 # Redirect I/O. STDOUT already safe.
2351                 open( OUT, ">&STDOUT" )    # XXX: lost message
2352                 || _db_warn("Can't restore DB::OUT");
2353             }
2354             next CMD;
2355         } ## end unless ($piped = open(OUT,...
2356
2357         # Set up broken-pipe handler if necessary.
2358         $SIG{PIPE} = \&DB::catch
2359         if $pager =~ /^\|/
2360         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2361
2362         _autoflush(\*OUT);
2363         # Save current filehandle, and put it back.
2364         $obj->selected(scalar( select(OUT) ));
2365         # Don't put it back if pager was a pipe.
2366         if ($cmd !~ /\A\|\|/)
2367         {
2368             select($obj->selected());
2369             $obj->selected("");
2370         }
2371
2372         # Trim off the pipe symbols and run the command now.
2373         $cmd =~ s#\A\|+\s*##;
2374         redo PIPE;
2375     }
2376
2377     return;
2378 }
2379
2380 sub _DB__handle_m_command {
2381     my ($obj) = @_;
2382
2383     if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2384         methods($1);
2385         next CMD;
2386     }
2387
2388     # m expr - set up DB::eval to do the work
2389     if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2390         $onetimeDump = 'methods';   #  method output gets used there
2391     }
2392
2393     return;
2394 }
2395
2396 sub _DB__at_end_of_every_command {
2397     my ($obj) = @_;
2398
2399     # At the end of every command:
2400     if ($obj->piped) {
2401
2402         # Unhook the pipe mechanism now.
2403         if ( $pager =~ /^\|/ ) {
2404
2405             # No error from the child.
2406             $? = 0;
2407
2408             # we cannot warn here: the handle is missing --tchrist
2409             close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
2410
2411             # most of the $? crud was coping with broken cshisms
2412             # $? is explicitly set to 0, so this never runs.
2413             if ($?) {
2414                 print SAVEOUT "Pager '$pager' failed: ";
2415                 if ( $? == -1 ) {
2416                     print SAVEOUT "shell returned -1\n";
2417                 }
2418                 elsif ( $? >> 8 ) {
2419                     print SAVEOUT ( $? & 127 )
2420                     ? " (SIG#" . ( $? & 127 ) . ")"
2421                     : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
2422                 }
2423                 else {
2424                     print SAVEOUT "status ", ( $? >> 8 ), "\n";
2425                 }
2426             } ## end if ($?)
2427
2428             # Reopen filehandle for our output (if we can) and
2429             # restore STDOUT (if we can).
2430             open( OUT, ">&STDOUT" ) || _db_warn("Can't restore DB::OUT");
2431             open( STDOUT, ">&SAVEOUT" )
2432             || _db_warn("Can't restore STDOUT");
2433
2434             # Turn off pipe exception handler if necessary.
2435             $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
2436
2437             # Will stop ignoring SIGPIPE if done like nohup(1)
2438             # does SIGINT but Perl doesn't give us a choice.
2439         } ## end if ($pager =~ /^\|/)
2440         else {
2441
2442             # Non-piped "pager". Just restore STDOUT.
2443             open( OUT, ">&SAVEOUT" ) || _db_warn("Can't restore DB::OUT");
2444         }
2445
2446         # Let Readline know about the new filehandles.
2447         reset_IN_OUT( \*IN, \*OUT );
2448
2449         # Close filehandle pager was using, restore the normal one
2450         # if necessary,
2451         close(SAVEOUT);
2452
2453         if ($obj->selected() ne "") {
2454             select($obj->selected);
2455             $obj->selected("");
2456         }
2457
2458         # No pipes now.
2459         $obj->piped("");
2460     } ## end if ($piped)
2461
2462     return;
2463 }
2464
2465 sub _DB__handle_watch_expressions
2466 {
2467     my $self = shift;
2468
2469     if ( $DB::trace & 2 ) {
2470         for my $n (0 .. $#DB::to_watch) {
2471             $DB::evalarg = $DB::to_watch[$n];
2472             local $DB::onetimeDump;    # Tell DB::eval() to not output results
2473
2474             # Fix context DB::eval() wants to return an array, but
2475             # we need a scalar here.
2476             my ($val) = join( "', '", DB::eval(@_) );
2477             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
2478
2479             # Did it change?
2480             if ( $val ne $DB::old_watch[$n] ) {
2481
2482                 # Yep! Show the difference, and fake an interrupt.
2483                 $DB::signal = 1;
2484                 print {$DB::OUT} <<EOP;
2485 Watchpoint $n:\t$DB::to_watch[$n] changed:
2486     old value:\t$DB::old_watch[$n]
2487     new value:\t$val
2488 EOP
2489                 $DB::old_watch[$n] = $val;
2490             } ## end if ($val ne $old_watch...
2491         } ## end for my $n (0 ..
2492     } ## end if ($trace & 2)
2493
2494     return;
2495 }
2496
2497 # 't' is type.
2498 # 'm' is method.
2499 # 'v' is the value (i.e: method name or subroutine ref).
2500 # 's' is subroutine.
2501 my %cmd_lookup;
2502
2503 BEGIN
2504 {
2505     %cmd_lookup =
2506 (
2507     '-' => { t => 'm', v => '_handle_dash_command', },
2508     '.' => { t => 's', v => \&_DB__handle_dot_command, },
2509     '=' => { t => 'm', v => '_handle_equal_sign_command', },
2510     'H' => { t => 'm', v => '_handle_H_command', },
2511     'S' => { t => 'm', v => '_handle_S_command', },
2512     'T' => { t => 'm', v => '_handle_T_command', },
2513     'W' => { t => 'm', v => '_handle_W_command', },
2514     'c' => { t => 's', v => \&_DB__handle_c_command, },
2515     'f' => { t => 's', v => \&_DB__handle_f_command, },
2516     'm' => { t => 's', v => \&_DB__handle_m_command, },
2517     'n' => { t => 'm', v => '_handle_n_command', },
2518     'p' => { t => 'm', v => '_handle_p_command', },
2519     'q' => { t => 'm', v => '_handle_q_command', },
2520     'r' => { t => 'm', v => '_handle_r_command', },
2521     's' => { t => 'm', v => '_handle_s_command', },
2522     'save' => { t => 'm', v => '_handle_save_command', },
2523     'source' => { t => 'm', v => '_handle_source_command', },
2524     't' => { t => 'm', v => '_handle_t_command', },
2525     'w' => { t => 'm', v => '_handle_w_command', },
2526     'x' => { t => 'm', v => '_handle_x_command', },
2527     'y' => { t => 's', v => \&_DB__handle_y_command, },
2528     (map { $_ => { t => 'm', v => '_handle_V_command_and_X_command', }, }
2529         ('X', 'V')),
2530     (map { $_ => { t => 'm', v => '_handle_enable_disable_commands', }, }
2531         qw(enable disable)),
2532     (map { $_ =>
2533         { t => 's', v => \&_DB__handle_restart_and_rerun_commands, },
2534         } qw(R rerun)),
2535     (map { $_ => {t => 'm', v => '_handle_cmd_wrapper_commands' }, }
2536         qw(a A b B e E h i l L M o O v w W)),
2537 );
2538 };
2539
2540 sub DB {
2541
2542     # lock the debugger and get the thread id for the prompt
2543     lock($DBGR);
2544     my $tid;
2545     my $position;
2546     my ($prefix, $after, $infix);
2547     my $pat;
2548     my $explicit_stop;
2549     my $piped;
2550     my $selected;
2551
2552     if ($ENV{PERL5DB_THREADED}) {
2553         $tid = eval { "[".threads->tid."]" };
2554     }
2555
2556     my $cmd_verb;
2557     my $cmd_args;
2558
2559     my $obj = DB::Obj->new(
2560         {
2561             position => \$position,
2562             prefix => \$prefix,
2563             after => \$after,
2564             explicit_stop => \$explicit_stop,
2565             infix => \$infix,
2566             cmd_args => \$cmd_args,
2567             cmd_verb => \$cmd_verb,
2568             pat => \$pat,
2569             piped => \$piped,
2570             selected => \$selected,
2571         },
2572     );
2573
2574     $obj->_DB_on_init__initialize_globals(@_);
2575
2576     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2577     # The code being debugged may have altered them.
2578     DB::save();
2579
2580     # Since DB::DB gets called after every line, we can use caller() to
2581     # figure out where we last were executing. Sneaky, eh? This works because
2582     # caller is returning all the extra information when called from the
2583     # debugger.
2584     local ( $package, $filename, $line ) = caller;
2585     $filename_ini = $filename;
2586
2587     # set up the context for DB::eval, so it can properly execute
2588     # code on behalf of the user. We add the package in so that the
2589     # code is eval'ed in the proper package (not in the debugger!).
2590     local $usercontext = _calc_usercontext($package);
2591
2592     # Create an alias to the active file magical array to simplify
2593     # the code here.
2594     local (*dbline) = $main::{ '_<' . $filename };
2595
2596     # Last line in the program.
2597     $max = $#dbline;
2598
2599     # The &-call is here to ascertain the mutability of @_.
2600     &_DB__determine_if_we_should_break;
2601
2602     # Preserve the current stop-or-not, and see if any of the W
2603     # (watch expressions) has changed.
2604     my $was_signal = $signal;
2605
2606     # If we have any watch expressions ...
2607     _DB__handle_watch_expressions($obj);
2608
2609 =head2 C<watchfunction()>
2610
2611 C<watchfunction()> is a function that can be defined by the user; it is a
2612 function which will be run on each entry to C<DB::DB>; it gets the
2613 current package, filename, and line as its parameters.
2614
2615 The watchfunction can do anything it likes; it is executing in the
2616 debugger's context, so it has access to all of the debugger's internal
2617 data structures and functions.
2618
2619 C<watchfunction()> can control the debugger's actions. Any of the following
2620 will cause the debugger to return control to the user's program after
2621 C<watchfunction()> executes:
2622
2623 =over 4
2624
2625 =item *
2626
2627 Returning a false value from the C<watchfunction()> itself.
2628
2629 =item *
2630
2631 Altering C<$single> to a false value.
2632
2633 =item *
2634
2635 Altering C<$signal> to a false value.
2636
2637 =item *
2638
2639 Turning off the C<4> bit in C<$trace> (this also disables the
2640 check for C<watchfunction()>. This can be done with
2641
2642     $trace &= ~4;
2643
2644 =back
2645
2646 =cut
2647
2648     # If there's a user-defined DB::watchfunction, call it with the
2649     # current package, filename, and line. The function executes in
2650     # the DB:: package.
2651     if ( $trace & 4 ) {    # User-installed watch
2652         return
2653           if watchfunction( $package, $filename, $line )
2654           and not $single
2655           and not $was_signal
2656           and not( $trace & ~4 );
2657     } ## end if ($trace & 4)
2658
2659     # Pick up any alteration to $signal in the watchfunction, and
2660     # turn off the signal now.
2661     $was_signal = $signal;
2662     $signal     = 0;
2663
2664 =head2 GETTING READY TO EXECUTE COMMANDS
2665
2666 The debugger decides to take control if single-step mode is on, the
2667 C<t> command was entered, or the user generated a signal. If the program
2668 has fallen off the end, we set things up so that entering further commands
2669 won't cause trouble, and we say that the program is over.
2670
2671 =cut
2672
2673     # Make sure that we always print if asked for explicitly regardless
2674     # of $trace_to_depth .
2675     $explicit_stop = ($single || $was_signal);
2676
2677     # Check to see if we should grab control ($single true,
2678     # trace set appropriately, or we got a signal).
2679     if ( $explicit_stop || ( $trace & 1 ) ) {
2680         $obj->_DB__grab_control(@_);
2681     } ## end if ($single || ($trace...
2682
2683 =pod
2684
2685 If there's an action to be executed for the line we stopped at, execute it.
2686 If there are any preprompt actions, execute those as well.
2687
2688 =cut
2689
2690     # If there's an action, do it now.
2691     if ($action) {
2692         $evalarg = $action;
2693         # The &-call is here to ascertain the mutability of @_.
2694         &DB::eval;
2695     }
2696
2697     # Are we nested another level (e.g., did we evaluate a function
2698     # that had a breakpoint in it at the debugger prompt)?
2699     if ( $single || $was_signal ) {
2700
2701         # Yes, go down a level.
2702         local $level = $level + 1;
2703
2704         # Do any pre-prompt actions.
2705         foreach $evalarg (@$pre) {
2706             # The &-call is here to ascertain the mutability of @_.
2707             &DB::eval;
2708         }
2709
2710         # Complain about too much recursion if we passed the limit.
2711         if ($single & 4) {
2712             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2713         }
2714
2715         # The line we're currently on. Set $incr to -1 to stay here
2716         # until we get a command that tells us to advance.
2717         $start = $line;
2718         $incr  = -1;      # for backward motion.
2719
2720         # Tack preprompt debugger actions ahead of any actual input.
2721         @typeahead = ( @$pretype, @typeahead );
2722
2723 =head2 WHERE ARE WE?
2724
2725 XXX Relocate this section?
2726
2727 The debugger normally shows the line corresponding to the current line of
2728 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2729 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2730
2731 C<$incr> controls by how many lines the I<current> line should move forward
2732 after a command is executed. If set to -1, this indicates that the I<current>
2733 line shouldn't change.
2734
2735 C<$start> is the I<current> line. It is used for things like knowing where to
2736 move forwards or backwards from when doing an C<L> or C<-> command.
2737
2738 C<$max> tells the debugger where the last line of the current file is. It's
2739 used to terminate loops most often.
2740
2741 =head2 THE COMMAND LOOP
2742
2743 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2744 in two parts:
2745
2746 =over 4
2747
2748 =item *
2749
2750 The outer part of the loop, starting at the C<CMD> label. This loop
2751 reads a command and then executes it.
2752
2753 =item *
2754
2755 The inner part of the loop, starting at the C<PIPE> label. This part
2756 is wholly contained inside the C<CMD> block and only executes a command.
2757 Used to handle commands running inside a pager.
2758
2759 =back
2760
2761 So why have two labels to restart the loop? Because sometimes, it's easier to
2762 have a command I<generate> another command and then re-execute the loop to do
2763 the new command. This is faster, but perhaps a bit more convoluted.
2764
2765 =cut
2766
2767         # The big command dispatch loop. It keeps running until the
2768         # user yields up control again.
2769         #
2770         # If we have a terminal for input, and we get something back
2771         # from readline(), keep on processing.
2772
2773       CMD:
2774         while (_DB__read_next_cmd($tid))
2775         {
2776
2777             share($cmd);
2778             # ... try to execute the input as debugger commands.
2779
2780             # Don't stop running.
2781             $single = 0;
2782
2783             # No signal is active.
2784             $signal = 0;
2785
2786             # Handle continued commands (ending with \):
2787             if ($cmd =~ s/\\\z/\n/) {
2788                 $cmd .= DB::readline("  cont: ");
2789                 redo CMD;
2790             }
2791
2792 =head4 The null command
2793
2794 A newline entered by itself means I<re-execute the last command>. We grab the
2795 command out of C<$laststep> (where it was recorded previously), and copy it
2796 back into C<$cmd> to be executed below. If there wasn't any previous command,
2797 we'll do nothing below (no command will match). If there was, we also save it
2798 in the command history and fall through to allow the command parsing to pick
2799 it up.
2800
2801 =cut
2802
2803             # Empty input means repeat the last command.
2804             if ($cmd eq '') {
2805                 $cmd = $laststep;
2806             }
2807             chomp($cmd);    # get rid of the annoying extra newline
2808             if (length($cmd) >= 2) {
2809                 push( @hist, $cmd );
2810             }
2811             push( @truehist, $cmd );
2812             share(@hist);
2813             share(@truehist);
2814
2815             # This is a restart point for commands that didn't arrive
2816             # via direct user input. It allows us to 'redo PIPE' to
2817             # re-execute command processing without reading a new command.
2818           PIPE: {
2819                 _DB__trim_command_and_return_first_component($obj);
2820
2821 =head3 COMMAND ALIASES
2822
2823 The debugger can create aliases for commands (these are stored in the
2824 C<%alias> hash). Before a command is executed, the command loop looks it up
2825 in the alias hash and substitutes the contents of the alias for the command,
2826 completely replacing it.
2827
2828 =cut
2829
2830                 # See if there's an alias for the command, and set it up if so.
2831                 if ( $alias{$cmd_verb} ) {
2832
2833                     # Squelch signal handling; we want to keep control here
2834                     # if something goes loco during the alias eval.
2835                     local $SIG{__DIE__};
2836                     local $SIG{__WARN__};
2837
2838                     # This is a command, so we eval it in the DEBUGGER's
2839                     # scope! Otherwise, we can't see the special debugger
2840                     # variables, or get to the debugger's subs. (Well, we
2841                     # _could_, but why make it even more complicated?)
2842                     eval "\$cmd =~ $alias{$cmd_verb}";
2843                     if ($@) {
2844                         local $\ = '';
2845                         print $OUT "Couldn't evaluate '$cmd_verb' alias: $@";
2846                         next CMD;
2847                     }
2848                     _DB__trim_command_and_return_first_component($obj);
2849                 } ## end if ($alias{$cmd_verb})
2850
2851 =head3 MAIN-LINE COMMANDS
2852
2853 All of these commands work up to and after the program being debugged has
2854 terminated.
2855
2856 =head4 C<q> - quit
2857
2858 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2859 try to execute further, cleaning any restart-related stuff out of the
2860 environment, and executing with the last value of C<$?>.
2861
2862 =cut
2863
2864                 # All of these commands were remapped in perl 5.8.0;
2865                 # we send them off to the secondary dispatcher (see below).
2866                 $obj->_handle_special_char_cmd_wrapper_commands;
2867                 _DB__trim_command_and_return_first_component($obj);
2868
2869                 if (my $cmd_rec = $cmd_lookup{$cmd_verb}) {
2870                     my $type = $cmd_rec->{t};
2871                     my $val = $cmd_rec->{v};
2872                     if ($type eq 'm') {
2873                         $obj->$val();
2874                     }
2875                     elsif ($type eq 's') {
2876                         $val->($obj);
2877                     }
2878                 }
2879
2880 =head4 C<t> - trace [n]
2881
2882 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2883 If level is specified, set C<$trace_to_depth>.
2884
2885 =head4 C<S> - list subroutines matching/not matching a pattern
2886
2887 Walks through C<%sub>, checking to see whether or not to print the name.
2888
2889 =head4 C<X> - list variables in current package
2890
2891 Since the C<V> command actually processes this, just change this to the
2892 appropriate C<V> command and fall through.
2893
2894 =head4 C<V> - list variables
2895
2896 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2897
2898 =head4 C<x> - evaluate and print an expression
2899
2900 Hands the expression off to C<DB::eval>, setting it up to print the value
2901 via C<dumpvar.pl> instead of just printing it directly.
2902
2903 =head4 C<m> - print methods
2904
2905 Just uses C<DB::methods> to determine what methods are available.
2906
2907 =head4 C<f> - switch files
2908
2909 Switch to a different filename.
2910
2911 =head4 C<.> - return to last-executed line.
2912
2913 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2914 and then we look up the line in the magical C<%dbline> hash.
2915
2916 =head4 C<-> - back one window
2917
2918 We change C<$start> to be one window back; if we go back past the first line,
2919 we set it to be the first line. We ser C<$incr> to put us back at the
2920 currently-executing line, and then put a C<l $start +> (list one window from
2921 C<$start>) in C<$cmd> to be executed later.
2922
2923 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2924
2925 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2926 problems, most notably that the default case of several commands destroying
2927 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2928 retain the old commands for those who were used to using them or who preferred
2929 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2930 deal with them instead of processing them in-line.
2931
2932 =head4 C<y> - List lexicals in higher scope
2933
2934 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2935 above the current one and then displays then using C<dumpvar.pl>.
2936
2937 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2938
2939 All of the commands below this point don't work after the program being
2940 debugged has ended. All of them check to see if the program has ended; this
2941 allows the commands to be relocated without worrying about a 'line of
2942 demarcation' above which commands can be entered anytime, and below which
2943 they can't.
2944
2945 =head4 C<n> - single step, but don't trace down into subs
2946
2947 Done by setting C<$single> to 2, which forces subs to execute straight through
2948 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2949 so a null command knows what to re-execute.
2950
2951 =head4 C<s> - single-step, entering subs
2952
2953 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2954 subs. Also saves C<s> as C<$lastcmd>.
2955
2956 =head4 C<c> - run continuously, setting an optional breakpoint
2957
2958 Most of the code for this command is taken up with locating the optional
2959 breakpoint, which is either a subroutine name or a line number. We set
2960 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2961 in this and all call levels above this one.
2962
2963 =head4 C<r> - return from a subroutine
2964
2965 For C<r> to work properly, the debugger has to stop execution again
2966 immediately after the return is executed. This is done by forcing
2967 single-stepping to be on in the call level above the current one. If
2968 we are printing return values when a C<r> is executed, set C<$doret>
2969 appropriately, and force us out of the command loop.
2970
2971 =head4 C<T> - stack trace
2972
2973 Just calls C<DB::print_trace>.
2974
2975 =head4 C<w> - List window around current line.
2976
2977 Just calls C<DB::cmd_w>.
2978
2979 =head4 C<W> - watch-expression processing.
2980
2981 Just calls C<DB::cmd_W>.
2982
2983 =head4 C</> - search forward for a string in the source
2984
2985 We take the argument and treat it as a pattern. If it turns out to be a
2986 bad one, we return the error we got from trying to C<eval> it and exit.
2987 If not, we create some code to do the search and C<eval> it so it can't
2988 mess us up.
2989
2990 =cut
2991
2992                 _DB__handle_forward_slash_command($obj);
2993
2994 =head4 C<?> - search backward for a string in the source
2995
2996 Same as for C</>, except the loop runs backwards.
2997
2998 =cut
2999
3000                 _DB__handle_question_mark_command($obj);
3001
3002 =head4 C<$rc> - Recall command
3003
3004 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
3005 that the terminal supports history). It finds the command required, puts it
3006 into C<$cmd>, and redoes the loop to execute it.
3007
3008 =cut
3009
3010                 # $rc - recall command.
3011                 $obj->_handle_rc_recall_command;
3012
3013 =head4 C<$sh$sh> - C<system()> command
3014
3015 Calls the C<_db_system()> to handle the command. This keeps the C<STDIN> and
3016 C<STDOUT> from getting messed up.
3017
3018 =cut
3019
3020                 $obj->_handle_sh_command;
3021
3022 =head4 C<$rc I<pattern> $rc> - Search command history
3023
3024 Another command to manipulate C<@hist>: this one searches it with a pattern.
3025 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
3026
3027 =cut
3028
3029                 $obj->_handle_rc_search_history_command;
3030
3031 =head4 C<$sh> - Invoke a shell
3032
3033 Uses C<_db_system()> to invoke a shell.
3034
3035 =cut
3036
3037 =head4 C<$sh I<command>> - Force execution of a command in a shell
3038
3039 Like the above, but the command is passed to the shell. Again, we use
3040 C<_db_system()> to avoid problems with C<STDIN> and C<STDOUT>.
3041
3042 =head4 C<H> - display commands in history
3043
3044 Prints the contents of C<@hist> (if any).
3045
3046 =head4 C<man, doc, perldoc> - look up documentation
3047
3048 Just calls C<runman()> to print the appropriate document.
3049
3050 =cut
3051
3052                 $obj->_handle_doc_command;
3053
3054 =head4 C<p> - print
3055
3056 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
3057 the bottom of the loop.
3058
3059 =head4 C<=> - define command alias
3060
3061 Manipulates C<%alias> to add or list command aliases.
3062
3063 =head4 C<source> - read commands from a file.
3064
3065 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
3066 pick it up.
3067
3068 =head4 C<enable> C<disable> - enable or disable breakpoints
3069
3070 This enables or disables breakpoints.
3071
3072 =head4 C<save> - send current history to a file
3073
3074 Takes the complete history, (not the shrunken version you see with C<H>),
3075 and saves it to the given filename, so it can be replayed using C<source>.
3076
3077 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3078
3079 =head4 C<R> - restart
3080
3081 Restart the debugger session.
3082
3083 =head4 C<rerun> - rerun the current session
3084
3085 Return to any given position in the B<true>-history list
3086
3087 =head4 C<|, ||> - pipe output through the pager.
3088
3089 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3090 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3091 pipe to the pager (restoring the output filehandles if this fails). If this
3092 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3093 set C<$signal>, sending us back into the debugger.
3094
3095 We then trim off the pipe symbols and C<redo> the command loop at the
3096 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3097 reading another.
3098
3099 =cut
3100
3101                 # || - run command in the pager, with output to DB::OUT.
3102                 _DB__handle_run_command_in_pager_command($obj);
3103
3104 =head3 END OF COMMAND PARSING
3105
3106 Anything left in C<$cmd> at this point is a Perl expression that we want to
3107 evaluate. We'll always evaluate in the user's context, and fully qualify
3108 any variables we might want to address in the C<DB> package.
3109
3110 =cut
3111
3112             }    # PIPE:
3113
3114             # trace an expression
3115             $cmd =~ s/^t\s/\$DB::trace |= 1;\n/;
3116
3117             # Make sure the flag that says "the debugger's running" is
3118             # still on, to make sure we get control again.
3119             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3120
3121             # Run *our* eval that executes in the caller's context.
3122             # The &-call is here to ascertain the mutability of @_.
3123             &DB::eval;
3124
3125             # Turn off the one-time-dump stuff now.
3126             if ($onetimeDump) {
3127                 $onetimeDump      = undef;
3128                 $onetimedumpDepth = undef;
3129             }
3130             elsif ( $term_pid == $$ ) {
3131                 eval { # May run under miniperl, when not available...
3132                     STDOUT->flush();
3133                     STDERR->flush();
3134                 };
3135
3136                 # XXX If this is the master pid, print a newline.
3137                 print {$OUT} "\n";
3138             }
3139         } ## end while (($term || &setterm...
3140
3141 =head3 POST-COMMAND PROCESSING
3142
3143 After each command, we check to see if the command output was piped anywhere.
3144 If so, we go through the necessary code to unhook the pipe and go back to
3145 our standard filehandles for input and output.
3146
3147 =cut
3148
3149         continue {    # CMD:
3150             _DB__at_end_of_every_command($obj);
3151         }    # CMD:
3152
3153 =head3 COMMAND LOOP TERMINATION
3154
3155 When commands have finished executing, we come here. If the user closed the
3156 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3157 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3158 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3159 The interpreter will then execute the next line and then return control to us
3160 again.
3161
3162 =cut
3163
3164         # No more commands? Quit.
3165         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3166
3167         # Evaluate post-prompt commands.
3168         foreach $evalarg (@$post) {
3169             # The &-call is here to ascertain the mutability of @_.
3170             &DB::eval;
3171         }
3172     }    # if ($single || $signal)
3173
3174     # Put the user's globals back where you found them.
3175     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3176     ();
3177 } ## end sub DB
3178
3179 # Because DB::Obj is used above,
3180 #
3181 #   my $obj = DB::Obj->new(
3182 #
3183 # The following package declaration must come before that,
3184 # or else runtime errors will occur with
3185 #
3186 #   PERLDB_OPTS="autotrace nonstop"
3187 #
3188 # ( rt#116771 )
3189 BEGIN {
3190
3191 package DB::Obj;
3192
3193 sub new {
3194     my $class = shift;
3195
3196     my $self = bless {}, $class;
3197
3198     $self->_init(@_);
3199
3200     return $self;
3201 }
3202
3203 sub _init {
3204     my ($self, $args) = @_;
3205
3206     %{$self} = (%$self, %$args);
3207
3208     return;
3209 }
3210
3211 {
3212     no strict 'refs';
3213     foreach my $slot_name (qw(
3214         after explicit_stop infix pat piped position prefix selected cmd_verb
3215         cmd_args
3216         )) {
3217         my $slot = $slot_name;
3218         *{$slot} = sub {
3219             my $self = shift;
3220
3221             if (@_) {
3222                 ${ $self->{$slot} } = shift;
3223             }
3224
3225             return ${ $self->{$slot} };
3226         };
3227
3228         *{"append_to_$slot"} = sub {
3229             my $self = shift;
3230             my $s = shift;
3231
3232             return $self->$slot($self->$slot . $s);
3233         };
3234     }
3235 }
3236
3237 sub _DB_on_init__initialize_globals
3238 {
3239     my $self = shift;
3240
3241     # Check for whether we should be running continuously or not.
3242     # _After_ the perl program is compiled, $single is set to 1:
3243     if ( $single and not $second_time++ ) {
3244
3245         # Options say run non-stop. Run until we get an interrupt.
3246         if ($runnonstop) {    # Disable until signal
3247                 # If there's any call stack in place, turn off single
3248                 # stepping into subs throughout the stack.
3249             for my $i (0 .. $stack_depth) {
3250                 $stack[ $i ] &= ~1;
3251             }
3252
3253             # And we are now no longer in single-step mode.
3254             $single = 0;
3255
3256             # If we simply returned at this point, we wouldn't get
3257             # the trace info. Fall on through.
3258             # return;
3259         } ## end if ($runnonstop)
3260
3261         elsif ($ImmediateStop) {
3262
3263             # We are supposed to stop here; XXX probably a break.
3264             $ImmediateStop = 0;    # We've processed it; turn it off
3265             $signal        = 1;    # Simulate an interrupt to force
3266                                    # us into the command loop
3267         }
3268     } ## end if ($single and not $second_time...
3269
3270     # If we're in single-step mode, or an interrupt (real or fake)
3271     # has occurred, turn off non-stop mode.
3272     $runnonstop = 0 if $single or $signal;
3273
3274     return;
3275 }
3276
3277 sub _my_print_lineinfo
3278 {
3279     my ($self, $i, $incr_pos) = @_;
3280
3281     if ($frame) {
3282         # Print it indented if tracing is on.
3283         DB::print_lineinfo( ' ' x $stack_depth,
3284             "$i:\t$DB::dbline[$i]" . $self->after );
3285     }
3286     else {
3287         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3288     }
3289 }
3290
3291 sub _curr_line {
3292     return $DB::dbline[$line];
3293 }
3294
3295 sub _is_full {
3296     my ($self, $letter) = @_;
3297
3298     return ($DB::cmd eq $letter);
3299 }
3300
3301 sub _DB__grab_control
3302 {
3303     my $self = shift;
3304
3305     # Yes, grab control.
3306     if ($slave_editor) {
3307
3308         # Tell the editor to update its position.
3309         $self->position("\032\032${DB::filename}:$line:0\n");
3310         DB::print_lineinfo($self->position());
3311     }
3312
3313 =pod
3314
3315 Special check: if we're in package C<DB::fake>, we've gone through the
3316 C<END> block at least once. We set up everything so that we can continue
3317 to enter commands and have a valid context to be in.
3318
3319 =cut
3320
3321     elsif ( $DB::package eq 'DB::fake' ) {
3322
3323         # Fallen off the end already.
3324         if (!$DB::term) {
3325             DB::setterm();
3326         }
3327
3328         DB::print_help(<<EOP);
3329 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3330 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3331 B<h q>, B<h R> or B<h o> to get additional info.
3332 EOP
3333
3334         # Set the DB::eval context appropriately.
3335         # At program termination disable any user actions.
3336         $DB::action = undef;
3337
3338         $DB::package     = 'main';
3339         $DB::usercontext = DB::_calc_usercontext($DB::package);
3340     } ## end elsif ($package eq 'DB::fake')
3341
3342 =pod
3343
3344 If the program hasn't finished executing, we scan forward to the
3345 next executable line, print that out, build the prompt from the file and line
3346 number information, and print that.
3347
3348 =cut
3349
3350     else {
3351
3352
3353         # Still somewhere in the midst of execution. Set up the
3354         #  debugger prompt.
3355         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3356                              # Perl 5 ones (sorry, we don't print Klingon
3357                              #module names)
3358
3359         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3360         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3361         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3362
3363         # Break up the prompt if it's really long.
3364         if ( length($self->prefix()) > 30 ) {
3365             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3366             $self->prefix("");
3367             $self->infix(":\t");
3368         }
3369         else {
3370             $self->infix("):\t");
3371             $self->position(
3372                 $self->prefix . $line. $self->infix
3373                 . $self->_curr_line . $self->after
3374             );
3375         }
3376
3377         # Print current line info, indenting if necessary.
3378         $self->_my_print_lineinfo($line, $self->position);
3379
3380         my $i;
3381         my $line_i = sub { return $DB::dbline[$i]; };
3382
3383         # Scan forward, stopping at either the end or the next
3384         # unbreakable line.
3385         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3386         {    #{ vi
3387
3388             # Drop out on null statements, block closers, and comments.
3389             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3390
3391             # Drop out if the user interrupted us.
3392             last if $signal;
3393
3394             # Append a newline if the line doesn't have one. Can happen
3395             # in eval'ed text, for instance.
3396             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3397
3398             # Next executable line.
3399             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3400                 . $self->after;
3401             $self->append_to_position($incr_pos);
3402             $self->_my_print_lineinfo($i, $incr_pos);
3403         } ## end for ($i = $line + 1 ; $i...
3404     } ## end else [ if ($slave_editor)
3405
3406     return;
3407 }
3408
3409 sub _handle_t_command {
3410     my $self = shift;
3411
3412     my $levels = $self->cmd_args();
3413
3414     if ((!length($levels)) or ($levels !~ /\D/)) {
3415         $trace ^= 1;
3416         local $\ = '';
3417         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3418         print {$OUT} "Trace = "
3419         . ( ( $trace & 1 )
3420             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3421             : "off" ) . "\n";
3422         next CMD;
3423     }
3424
3425     return;
3426 }
3427
3428
3429 sub _handle_S_command {
3430     my $self = shift;
3431
3432     if (my ($print_all_subs, $should_reverse, $Spatt)
3433         = $self->cmd_args =~ /\A((!)?(.+))?\z/) {
3434         # $Spatt is the pattern (if any) to use.
3435         # Reverse scan?
3436         my $Srev     = defined $should_reverse;
3437         # No args - print all subs.
3438         my $Snocheck = !defined $print_all_subs;
3439
3440         # Need to make these sane here.
3441         local $\ = '';
3442         local $, = '';
3443
3444         # Search through the debugger's magical hash of subs.
3445         # If $nocheck is true, just print the sub name.
3446         # Otherwise, check it against the pattern. We then use
3447         # the XOR trick to reverse the condition as required.
3448         foreach $subname ( sort( keys %sub ) ) {
3449             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3450                 print $OUT $subname, "\n";
3451             }
3452         }
3453         next CMD;
3454     }
3455
3456     return;
3457 }
3458
3459 sub _handle_V_command_and_X_command {
3460     my $self = shift;
3461
3462     $DB::cmd =~ s/^X\b/V $DB::package/;
3463
3464     # Bare V commands get the currently-being-debugged package
3465     # added.
3466     if ($self->_is_full('V')) {
3467         $DB::cmd = "V $DB::package";
3468     }
3469
3470     # V - show variables in package.
3471     if (my ($new_packname, $new_vars_str) =
3472         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3473
3474         # Save the currently selected filehandle and
3475         # force output to debugger's filehandle (dumpvar
3476         # just does "print" for output).
3477         my $savout = select($OUT);
3478
3479         # Grab package name and variables to dump.
3480         $packname = $new_packname;
3481         my @vars     = split( ' ', $new_vars_str );
3482
3483         # If main::dumpvar isn't here, get it.
3484         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3485         if ( defined &main::dumpvar ) {
3486
3487             # We got it. Turn off subroutine entry/exit messages
3488             # for the moment, along with return values.
3489             local $frame = 0;
3490             local $doret = -2;
3491
3492             # must detect sigpipe failures  - not catching
3493             # then will cause the debugger to die.
3494             eval {
3495                 main::dumpvar(
3496                     $packname,
3497                     defined $option{dumpDepth}
3498                     ? $option{dumpDepth}
3499                     : -1,    # assume -1 unless specified
3500                     @vars
3501                 );
3502             };
3503
3504             # The die doesn't need to include the $@, because
3505             # it will automatically get propagated for us.
3506             if ($@) {
3507                 die unless $@ =~ /dumpvar print failed/;
3508             }
3509         } ## end if (defined &main::dumpvar)
3510         else {
3511
3512             # Couldn't load dumpvar.
3513             print $OUT "dumpvar.pl not available.\n";
3514         }
3515
3516         # Restore the output filehandle, and go round again.
3517         select($savout);
3518         next CMD;
3519     }
3520
3521     return;
3522 }
3523
3524 sub _handle_dash_command {
3525     my $self = shift;
3526
3527     if ($self->_is_full('-')) {
3528
3529         # back up by a window; go to 1 if back too far.
3530         $start -= $incr + $window + 1;
3531         $start = 1 if $start <= 0;
3532         $incr  = $window - 1;
3533
3534         # Generate and execute a "l +" command (handled below).
3535         $DB::cmd = 'l ' . ($start) . '+';
3536         redo CMD;
3537     }
3538     return;
3539 }
3540
3541 sub _n_or_s_commands_generic {
3542     my ($self, $new_val) = @_;
3543     # n - next
3544     next CMD if DB::_DB__is_finished();
3545
3546     # Single step, but don't enter subs.
3547     $single = $new_val;
3548
3549     # Save for empty command (repeat last).
3550     $laststep = $DB::cmd;
3551     last CMD;
3552 }
3553
3554 sub _n_or_s {
3555     my ($self, $letter, $new_val) = @_;
3556
3557     if ($self->_is_full($letter)) {
3558         $self->_n_or_s_commands_generic($new_val);
3559     }
3560     else {
3561         $self->_n_or_s_and_arg_commands_generic($letter, $new_val);
3562     }
3563
3564     return;
3565 }
3566
3567 sub _handle_n_command {
3568     my $self = shift;
3569
3570     return $self->_n_or_s('n', 2);
3571 }
3572
3573 sub _handle_s_command {
3574     my $self = shift;
3575
3576     return $self->_n_or_s('s', 1);
3577 }
3578
3579 sub _handle_r_command {
3580     my $self = shift;
3581
3582     # r - return from the current subroutine.
3583     if ($self->_is_full('r')) {
3584
3585         # Can't do anything if the program's over.
3586         next CMD if DB::_DB__is_finished();
3587
3588         # Turn on stack trace.
3589         $stack[$stack_depth] |= 1;
3590
3591         # Print return value unless the stack is empty.
3592         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3593         last CMD;
3594     }
3595
3596     return;
3597 }
3598
3599 sub _handle_T_command {
3600     my $self = shift;
3601
3602     if ($self->_is_full('T')) {
3603         DB::print_trace( $OUT, 1 );    # skip DB
3604         next CMD;
3605     }
3606
3607     return;
3608 }
3609
3610 sub _handle_w_command {
3611     my $self = shift;
3612
3613     DB::cmd_w( 'w', $self->cmd_args() );
3614     next CMD;
3615
3616     return;
3617 }
3618
3619 sub _handle_W_command {
3620     my $self = shift;
3621
3622     if (my $arg = $self->cmd_args) {
3623         DB::cmd_W( 'W', $arg );
3624         next CMD;
3625     }
3626
3627     return;
3628 }
3629
3630 sub _handle_rc_recall_command {
3631     my $self = shift;
3632
3633     # $rc - recall command.
3634     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3635
3636         # No arguments, take one thing off history.
3637         pop(@hist) if length($DB::cmd) > 1;
3638
3639         # Relative (- found)?
3640         #  Y - index back from most recent (by 1 if bare minus)
3641         #  N - go to that particular command slot or the last
3642         #      thing if nothing following.
3643
3644         $self->cmd_verb(
3645             scalar($minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist ))
3646         );
3647
3648         # Pick out the command desired.
3649         $DB::cmd = $hist[$self->cmd_verb];
3650
3651         # Print the command to be executed and restart the loop
3652         # with that command in the buffer.
3653         print {$OUT} $DB::cmd, "\n";
3654         redo CMD;
3655     }
3656
3657     return;
3658 }
3659
3660 sub _handle_rc_search_history_command {
3661     my $self = shift;
3662
3663     # $rc pattern $rc - find a command in the history.
3664     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3665
3666         # Create the pattern to use.
3667         my $pat = "^$arg";
3668         $self->pat($pat);
3669
3670         # Toss off last entry if length is >1 (and it always is).
3671         pop(@hist) if length($DB::cmd) > 1;
3672
3673         my $i;
3674
3675         # Look backward through the history.
3676         SEARCH_HIST:
3677         for ( $i = $#hist ; $i ; --$i ) {
3678             # Stop if we find it.
3679             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3680         }
3681
3682         if ( !$i ) {
3683
3684             # Never found it.
3685             print $OUT "No such command!\n\n";
3686             next CMD;
3687         }
3688
3689         # Found it. Put it in the buffer, print it, and process it.
3690         $DB::cmd = $hist[$i];
3691         print $OUT $DB::cmd, "\n";
3692         redo CMD;
3693     }
3694
3695     return;
3696 }
3697
3698 sub _handle_H_command {
3699     my $self = shift;
3700
3701     if ($self->cmd_args =~ m#\A\*#) {
3702         @hist = @truehist = ();
3703         print $OUT "History cleansed\n";
3704         next CMD;
3705     }
3706
3707     if (my ($num) = $self->cmd_args =~ /\A(?:-(\d+))?/) {
3708
3709         # Anything other than negative numbers is ignored by
3710         # the (incorrect) pattern, so this test does nothing.
3711         $end = $num ? ( $#hist - $num ) : 0;
3712
3713         # Set to the minimum if less than zero.
3714         $hist = 0 if $hist < 0;
3715
3716         # Start at the end of the array.
3717         # Stay in while we're still above the ending value.
3718         # Tick back by one each time around the loop.
3719         my $i;
3720
3721         for ( $i = $#hist ; $i > $end ; $i-- ) {
3722
3723             # Print the command  unless it has no arguments.
3724             print $OUT "$i: ", $hist[$i], "\n"
3725             unless $hist[$i] =~ /^.?$/;
3726         }
3727
3728         next CMD;
3729     }
3730
3731     return;
3732 }
3733
3734 sub _handle_doc_command {
3735     my $self = shift;
3736
3737     # man, perldoc, doc - show manual pages.
3738     if (my ($man_page)
3739         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3740         DB::runman($man_page);
3741         next CMD;
3742     }
3743
3744     return;
3745 }
3746
3747 sub _handle_p_command {
3748     my $self = shift;
3749
3750     my $print_cmd = 'print {$DB::OUT} ';
3751     # p - print (no args): print $_.
3752     if ($self->_is_full('p')) {
3753         $DB::cmd = $print_cmd . '$_';
3754     }
3755     else {
3756         # p - print the given expression.
3757         $DB::cmd =~ s/\Ap\b/$print_cmd /;
3758     }
3759
3760     return;
3761 }
3762
3763 sub _handle_equal_sign_command {
3764     my $self = shift;
3765
3766     if ($DB::cmd =~ s/\A=\s*//) {
3767         my @keys;
3768         if ( length $DB::cmd == 0 ) {
3769
3770             # No args, get current aliases.
3771             @keys = sort keys %alias;
3772         }
3773         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3774
3775             # Creating a new alias. $k is alias name, $v is
3776             # alias value.
3777
3778             # can't use $_ or kill //g state
3779             for my $x ( $k, $v ) {
3780
3781                 # Escape "alarm" characters.
3782                 $x =~ s/\a/\\a/g;
3783             }
3784
3785             # Substitute key for value, using alarm chars
3786             # as separators (which is why we escaped them in
3787             # the command).
3788             $alias{$k} = "s\a$k\a$v\a";
3789
3790             # Turn off standard warn and die behavior.
3791             local $SIG{__DIE__};
3792             local $SIG{__WARN__};
3793
3794             # Is it valid Perl?
3795             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3796
3797                 # Nope. Bad alias. Say so and get out.
3798                 print $OUT "Can't alias $k to $v: $@\n";
3799                 delete $alias{$k};
3800                 next CMD;
3801             }
3802
3803             # We'll only list the new one.
3804             @keys = ($k);
3805         } ## end elsif (my ($k, $v) = ($DB::cmd...
3806
3807         # The argument is the alias to list.
3808         else {
3809             @keys = ($DB::cmd);
3810         }
3811
3812         # List aliases.
3813         for my $k (@keys) {
3814
3815             # Messy metaquoting: Trim the substitution code off.
3816             # We use control-G as the delimiter because it's not
3817             # likely to appear in the alias.
3818             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3819
3820                 # Print the alias.
3821                 print $OUT "$k\t= $1\n";
3822             }
3823             elsif ( defined $alias{$k} ) {
3824
3825                 # Couldn't trim it off; just print the alias code.
3826                 print $OUT "$k\t$alias{$k}\n";
3827             }
3828             else {
3829
3830                 # No such, dude.
3831                 print "No alias for $k\n";
3832             }
3833         } ## end for my $k (@keys)
3834         next CMD;
3835     }
3836
3837     return;
3838 }
3839
3840 sub _handle_source_command {
3841     my $self = shift;
3842
3843     # source - read commands from a file (or pipe!) and execute.
3844     if (my $sourced_fn = $self->cmd_args) {
3845         if ( open my $fh, $sourced_fn ) {
3846
3847             # Opened OK; stick it in the list of file handles.
3848             push @cmdfhs, $fh;
3849         }
3850         else {
3851
3852             # Couldn't open it.
3853             DB::_db_warn("Can't execute '$sourced_fn': $!\n");
3854         }
3855         next CMD;
3856     }
3857
3858     return;
3859 }
3860
3861 sub _handle_enable_disable_commands {
3862     my $self = shift;
3863
3864     my $which_cmd = $self->cmd_verb;
3865     my $position = $self->cmd_args;
3866
3867     if ($position !~ /\s/) {
3868         my ($fn, $line_num);
3869         if ($position =~ m{\A\d+\z})
3870         {
3871             $fn = $DB::filename;
3872             $line_num = $position;
3873         }
3874         elsif (my ($new_fn, $new_line_num)
3875             = $position =~ m{\A(.*):(\d+)\z}) {
3876             ($fn, $line_num) = ($new_fn, $new_line_num);
3877         }
3878         else
3879         {
3880             DB::_db_warn("Wrong spec for enable/disable argument.\n");
3881         }
3882
3883         if (defined($fn)) {
3884             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3885                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3886                     ($which_cmd eq 'enable' ? 1 : '')
3887                 );
3888             }
3889             else {
3890                 DB::_db_warn("No breakpoint set at ${fn}:${line_num}\n");
3891             }
3892         }
3893
3894         next CMD;
3895     }
3896
3897     return;
3898 }
3899
3900 sub _handle_save_command {
3901     my $self = shift;
3902
3903     if (my $new_fn = $self->cmd_args) {
3904         my $filename = $new_fn || '.perl5dbrc';    # default?
3905         if ( open my $fh, '>', $filename ) {
3906
3907             # chomp to remove extraneous newlines from source'd files
3908             chomp( my @truelist =
3909                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3910                 @truehist );
3911             print {$fh} join( "\n", @truelist );
3912             print "commands saved in $filename\n";
3913         }
3914         else {
3915             DB::_db_warn("Can't save debugger commands in '$new_fn': $!\n");
3916         }
3917         next CMD;
3918     }
3919
3920     return;
3921 }
3922
3923 sub _n_or_s_and_arg_commands_generic {
3924     my ($self, $letter, $new_val) = @_;
3925
3926     # s - single-step. Remember the last command was 's'.
3927     if ($DB::cmd =~ s#\A\Q$letter\E\s#\$DB::single = $new_val;\n#) {
3928         $laststep = $letter;
3929     }
3930
3931     return;
3932 }
3933
3934 sub _handle_sh_command {
3935     my $self = shift;
3936
3937     # $sh$sh - run a shell command (if it's all ASCII).
3938     # Can't run shell commands with Unicode in the debugger, hmm.
3939     my $my_cmd = $DB::cmd;
3940     if ($my_cmd =~ m#\A$sh#gms) {
3941
3942         if ($my_cmd =~ m#\G\z#cgms) {
3943             # Run the user's shell. If none defined, run Bourne.
3944             # We resume execution when the shell terminates.
3945             DB::_db_system( $ENV{SHELL} || "/bin/sh" );
3946             next CMD;
3947         }
3948         elsif ($my_cmd =~ m#\G$sh\s*(.*)#cgms) {
3949             # System it.
3950             DB::_db_system($1);
3951             next CMD;
3952         }
3953         elsif ($my_cmd =~ m#\G\s*(.*)#cgms) {
3954             DB::_db_system( $ENV{SHELL} || "/bin/sh", "-c", $1 );
3955             next CMD;
3956         }
3957     }
3958 }
3959
3960 sub _handle_x_command {
3961     my $self = shift;
3962
3963     if ($DB::cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
3964         $onetimeDump = 'dump';    # main::dumpvar shows the output
3965
3966         # handle special  "x 3 blah" syntax XXX propagate
3967         # doc back to special variables.
3968         if ( $DB::cmd =~ s#\A\s*(\d+)(?=\s)# #) {
3969             $onetimedumpDepth = $1;
3970         }
3971     }
3972
3973     return;
3974 }
3975
3976 sub _handle_q_command {
3977     my $self = shift;
3978
3979     if ($self->_is_full('q')) {
3980         $fall_off_end = 1;
3981         DB::clean_ENV();
3982         exit $?;
3983     }
3984
3985     return;
3986 }
3987
3988 sub _handle_cmd_wrapper_commands {
3989     my $self = shift;
3990
3991     DB::cmd_wrapper( $self->cmd_verb, $self->cmd_args, $line );
3992     next CMD;
3993 }
3994
3995 sub _handle_special_char_cmd_wrapper_commands {
3996     my $self = shift;
3997
3998     # All of these commands were remapped in perl 5.8.0;
3999     # we send them off to the secondary dispatcher (see below).
4000     if (my ($cmd_letter, $my_arg) = $DB::cmd =~ /\A([<>\{]{1,2})\s*(.*)/so) {
4001         DB::cmd_wrapper( $cmd_letter, $my_arg, $line );
4002         next CMD;
4003     }
4004
4005     return;
4006 }
4007
4008 } ## end DB::Obj
4009
4010 package DB;
4011
4012 # The following code may be executed now:
4013 # BEGIN {warn 4}
4014
4015 =head2 sub
4016
4017 C<sub> is called whenever a subroutine call happens in the program being
4018 debugged. The variable C<$DB::sub> contains the name of the subroutine
4019 being called.
4020
4021 The core function of this subroutine is to actually call the sub in the proper
4022 context, capturing its output. This of course causes C<DB::DB> to get called
4023 again, repeating until the subroutine ends and returns control to C<DB::sub>
4024 again. Once control returns, C<DB::sub> figures out whether or not to dump the
4025 return value, and returns its captured copy of the return value as its own
4026 return value. The value then feeds back into the program being debugged as if
4027 C<DB::sub> hadn't been there at all.
4028
4029 C<sub> does all the work of printing the subroutine entry and exit messages
4030 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
4031 and also prints the return value if needed (for the C<r> command and if
4032 the 16 bit is set in C<$frame>).
4033
4034 It also tracks the subroutine call depth by saving the current setting of
4035 C<$single> in the C<@stack> package global; if this exceeds the value in
4036 C<$deep>, C<sub> automatically turns on printing of the current depth by
4037 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
4038 of stop/don't stop on entry to subs set as it currently is set.
4039
4040 =head3 C<caller()> support
4041
4042 If C<caller()> is called from the package C<DB>, it provides some
4043 additional data, in the following order:
4044
4045 =over 4
4046
4047 =item * C<$package>
4048
4049 The package name the sub was in
4050
4051 =item * C<$filename>
4052
4053 The filename it was defined in
4054
4055 =item * C<$line>
4056
4057 The line number it was defined on
4058
4059 =item * C<$subroutine>
4060
4061 The subroutine name; C<(eval)> if an C<eval>().
4062
4063 =item * C<$hasargs>
4064
4065 1 if it has arguments, 0 if not
4066
4067 =item * C<$wantarray>
4068
4069 1 if array context, 0 if scalar context
4070
4071 =item * C<$evaltext>
4072
4073 The C<eval>() text, if any (undefined for C<eval BLOCK>)
4074
4075 =item * C<$is_require>
4076
4077 frame was created by a C<use> or C<require> statement
4078
4079 =item * C<$hints>
4080
4081 pragma information; subject to change between versions
4082
4083 =item * C<$bitmask>
4084
4085 pragma information; subject to change between versions
4086
4087 =item * C<@DB::args>
4088
4089 arguments with which the subroutine was invoked
4090
4091 =back
4092
4093 =cut
4094
4095 use vars qw($deep);
4096
4097 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4098 # happy. -- Shlomi Fish
4099
4100 sub _indent_print_line_info {
4101     my ($offset, $str) = @_;
4102
4103     print_lineinfo( ' ' x ($stack_depth - $offset), $str);
4104
4105     return;
4106 }
4107
4108 sub _print_frame_message {
4109     my ($al) = @_;
4110
4111     if ($frame) {
4112         if ($frame & 4) {   # Extended frame entry message
4113             _indent_print_line_info(-1, "in  ");
4114
4115             # Why -1? But it works! :-(
4116             # Because print_trace will call add 1 to it and then call
4117             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4118             # in dump_trace.
4119             #
4120             # Now it's 0 because we extracted a function.
4121             print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4122         }
4123         else {
4124             _indent_print_line_info(-1, "entering $sub$al\n" );
4125         }
4126     }
4127
4128     return;
4129 }
4130
4131 sub DB::sub {
4132     # lock ourselves under threads
4133     lock($DBGR);
4134
4135     # Whether or not the autoloader was running, a scalar to put the
4136     # sub's return value in (if needed), and an array to put the sub's
4137     # return value in (if needed).
4138     my ( $al, $ret, @ret ) = "";
4139     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4140         print "creating new thread\n";
4141     }
4142
4143     # If the last ten characters are '::AUTOLOAD', note we've traced
4144     # into AUTOLOAD for $sub.
4145     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4146         no strict 'refs';
4147         $al = " for $$sub" if defined $$sub;
4148     }
4149
4150     # We stack the stack pointer and then increment it to protect us
4151     # from a situation that might unwind a whole bunch of call frames
4152     # at once. Localizing the stack pointer means that it will automatically
4153     # unwind the same amount when multiple stack frames are unwound.
4154     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4155
4156     # Expand @stack.
4157     $#stack = $stack_depth;
4158
4159     # Save current single-step setting.
4160     $stack[-1] = $single;
4161
4162     # Turn off all flags except single-stepping.
4163     $single &= 1;
4164
4165     # If we've gotten really deeply recursed, turn on the flag that will
4166     # make us stop with the 'deep recursion' message.
4167     $single |= 4 if $stack_depth == $deep;
4168
4169     # If frame messages are on ...
4170
4171     _print_frame_message($al);
4172     # standard frame entry message
4173
4174     my $print_exit_msg = sub {
4175         # Check for exit trace messages...
4176         if ($frame & 2)
4177         {
4178             if ($frame & 4)    # Extended exit message
4179             {
4180                 _indent_print_line_info(0, "out ");
4181                 print_trace( $LINEINFO, 0, 1, 1, "$sub$al" );
4182             }
4183             else
4184             {
4185                 _indent_print_line_info(0, "exited $sub$al\n" );
4186             }
4187         }
4188         return;
4189     };
4190
4191     # Determine the sub's return type, and capture appropriately.
4192     if (wantarray) {
4193
4194         # Called in array context. call sub and capture output.
4195         # DB::DB will recursively get control again if appropriate; we'll come
4196         # back here when the sub is finished.
4197         {
4198             no strict 'refs';
4199             @ret = &$sub;
4200         }
4201
4202         # Pop the single-step value back off the stack.
4203         $single |= $stack[ $stack_depth-- ];
4204
4205         $print_exit_msg->();
4206
4207         # Print the return info if we need to.
4208         if ( $doret eq $stack_depth or $frame & 16 ) {
4209
4210             # Turn off output record separator.
4211             local $\ = '';
4212             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4213
4214             # Indent if we're printing because of $frame tracing.
4215             if ($frame & 16)
4216             {
4217                 print {$fh} ' ' x $stack_depth;
4218             }
4219
4220             # Print the return value.
4221             print {$fh} "list context return from $sub:\n";
4222             dumpit( $fh, \@ret );
4223
4224             # And don't print it again.
4225             $doret = -2;
4226         } ## end if ($doret eq $stack_depth...
4227             # And we have to return the return value now.
4228         @ret;
4229     } ## end if (wantarray)
4230
4231     # Scalar context.
4232     else {
4233         if ( defined wantarray ) {
4234             no strict 'refs';
4235             # Save the value if it's wanted at all.
4236             $ret = &$sub;
4237         }
4238         else {
4239             no strict 'refs';
4240             # Void return, explicitly.
4241             &$sub;
4242             undef $ret;
4243         }
4244
4245         # Pop the single-step value off the stack.
4246         $single |= $stack[ $stack_depth-- ];
4247
4248         # If we're doing exit messages...
4249         $print_exit_msg->();
4250
4251         # If we are supposed to show the return value... same as before.
4252         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4253             local $\ = '';
4254             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4255             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4256             print $fh (
4257                 defined wantarray
4258                 ? "scalar context return from $sub: "
4259                 : "void context return from $sub\n"
4260             );
4261             dumpit( $fh, $ret ) if defined wantarray;
4262             $doret = -2;
4263         } ## end if ($doret eq $stack_depth...
4264
4265         # Return the appropriate scalar value.
4266         $ret;
4267     } ## end else [ if (wantarray)
4268 } ## end sub _sub
4269
4270 sub lsub : lvalue {
4271
4272     no strict 'refs';
4273
4274     # lock ourselves under threads
4275     lock($DBGR);
4276
4277     # Whether or not the autoloader was running, a scalar to put the
4278     # sub's return value in (if needed), and an array to put the sub's
4279     # return value in (if needed).
4280     my ( $al, $ret, @ret ) = "";
4281     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4282         print "creating new thread\n";
4283     }
4284
4285     # If the last ten characters are C'::AUTOLOAD', note we've traced
4286     # into AUTOLOAD for $sub.
4287     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4288         $al = " for $$sub";
4289     }
4290
4291     # We stack the stack pointer and then increment it to protect us
4292     # from a situation that might unwind a whole bunch of call frames
4293     # at once. Localizing the stack pointer means that it will automatically
4294     # unwind the same amount when multiple stack frames are unwound.
4295     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4296
4297     # Expand @stack.
4298     $#stack = $stack_depth;
4299
4300     # Save current single-step setting.
4301     $stack[-1] = $single;
4302
4303     # Turn off all flags except single-stepping.
4304     # Use local so the single-step value is popped back off the
4305     # stack for us.
4306     local $single = $single & 1;
4307
4308     # If we've gotten really deeply recursed, turn on the flag that will
4309     # make us stop with the 'deep recursion' message.
4310     $single |= 4 if $stack_depth == $deep;
4311
4312     # If frame messages are on ...
4313     _print_frame_message($al);
4314
4315     # call the original lvalue sub.
4316     &$sub;
4317 }
4318
4319 # Abstracting common code from multiple places elsewhere:
4320 sub depth_print_lineinfo {
4321     my $always_print = shift;
4322
4323     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4324 }
4325
4326 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4327
4328 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4329 Most of the changes were to systematize the command structure and to eliminate
4330 commands that threw away user input without checking.
4331
4332 The following sections describe the code added to make it easy to support
4333 multiple command sets with conflicting command names. This section is a start
4334 at unifying all command processing to make it simpler to develop commands.
4335
4336 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4337 number, and C<$dbline> (the current line) as arguments.
4338
4339 Support functions in this section which have multiple modes of failure C<die>
4340 on error; the rest simply return a false value.
4341
4342 The user-interface functions (all of the C<cmd_*> functions) just output
4343 error messages.
4344
4345 =head2 C<%set>
4346
4347 The C<%set> hash defines the mapping from command letter to subroutine
4348 name suffix.
4349
4350 C<%set> is a two-level hash, indexed by set name and then by command name.
4351 Note that trying to set the CommandSet to C<foobar> simply results in the
4352 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4353
4354 =cut
4355
4356 ### The API section
4357
4358 my %set = (    #
4359     'pre580' => {
4360         'a' => 'pre580_a',
4361         'A' => 'pre580_null',
4362         'b' => 'pre580_b',
4363         'B' => 'pre580_null',
4364         'd' => 'pre580_null',
4365         'D' => 'pre580_D',
4366         'h' => 'pre580_h',
4367         'M' => 'pre580_null',
4368         'O' => 'o',
4369         'o' => 'pre580_null',
4370         'v' => 'M',
4371         'w' => 'v',
4372         'W' => 'pre580_W',
4373     },
4374     'pre590' => {
4375         '<'  => 'pre590_prepost',
4376         '<<' => 'pre590_prepost',
4377         '>'  => 'pre590_prepost',
4378         '>>' => 'pre590_prepost',
4379         '{'  => 'pre590_prepost',
4380         '{{' => 'pre590_prepost',
4381     },
4382 );
4383
4384 my %breakpoints_data;
4385
4386 sub _has_breakpoint_data_ref {
4387     my ($filename, $line) = @_;
4388
4389     return (
4390         exists( $breakpoints_data{$filename} )
4391             and
4392         exists( $breakpoints_data{$filename}{$line} )
4393     );
4394 }
4395
4396 sub _get_breakpoint_data_ref {
4397     my ($filename, $line) = @_;
4398
4399     return ($breakpoints_data{$filename}{$line} ||= +{});
4400 }
4401
4402 sub _delete_breakpoint_data_ref {
4403     my ($filename, $line) = @_;
4404
4405     delete($breakpoints_data{$filename}{$line});
4406     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4407         delete($breakpoints_data{$filename});
4408     }
4409
4410     return;
4411 }
4412
4413 sub _set_breakpoint_enabled_status {
4414     my ($filename, $line, $status) = @_;
4415
4416     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4417         ($status ? 1 : '')
4418         ;
4419
4420     return;
4421 }
4422
4423 sub _enable_breakpoint_temp_enabled_status {
4424     my ($filename, $line) = @_;
4425
4426     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4427
4428     return;
4429 }
4430
4431 sub _cancel_breakpoint_temp_enabled_status {
4432     my ($filename, $line) = @_;
4433
4434     my $ref = _get_breakpoint_data_ref($filename, $line);
4435
4436     delete ($ref->{'temp_enabled'});
4437
4438     if (! %$ref) {
4439         _delete_breakpoint_data_ref($filename, $line);
4440     }
4441
4442     return;
4443 }
4444
4445 sub _is_breakpoint_enabled {
4446     my ($filename, $line) = @_;
4447
4448     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4449     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4450 }
4451
4452 =head2 C<cmd_wrapper()> (API)
4453
4454 C<cmd_wrapper()> allows the debugger to switch command sets
4455 depending on the value of the C<CommandSet> option.
4456
4457 It tries to look up the command in the C<%set> package-level I<lexical>
4458 (which means external entities can't fiddle with it) and create the name of
4459 the sub to call based on the value found in the hash (if it's there). I<All>
4460 of the commands to be handled in a set have to be added to C<%set>; if they
4461 aren't found, the 5.8.0 equivalent is called (if there is one).
4462
4463 This code uses symbolic references.
4464
4465 =cut
4466
4467 sub cmd_wrapper {
4468     my $cmd      = shift;
4469     my $line     = shift;
4470     my $dblineno = shift;
4471
4472     # Assemble the command subroutine's name by looking up the
4473     # command set and command name in %set. If we can't find it,
4474     # default to the older version of the command.
4475     my $call = 'cmd_'
4476       . ( $set{$CommandSet}{$cmd}
4477           || ( $cmd =~ /\A[<>{]+/o ? 'prepost' : $cmd ) );
4478
4479     # Call the command subroutine, call it by name.
4480     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4481 } ## end sub cmd_wrapper
4482
4483 =head3 C<cmd_a> (command)
4484
4485 The C<a> command handles pre-execution actions. These are associated with a
4486 particular line, so they're stored in C<%dbline>. We default to the current
4487 line if none is specified.
4488
4489 =cut
4490
4491 sub cmd_a {
4492     my $cmd    = shift;
4493     my $line   = shift || '';    # [.|line] expr
4494     my $dbline = shift;
4495
4496     # If it's dot (here), or not all digits,  use the current line.
4497     $line =~ s/\A\./$dbline/;
4498
4499     # Should be a line number followed by an expression.
4500     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4501
4502         if (! length($lineno)) {
4503             $lineno = $dbline;
4504         }
4505
4506         # If we have an expression ...
4507         if ( length $expr ) {
4508
4509             # ... but the line isn't breakable, complain.
4510             if ( $dbline[$lineno] == 0 ) {
4511                 print $OUT
4512                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4513             }
4514             else {
4515
4516                 # It's executable. Record that the line has an action.
4517                 $had_breakpoints{$filename} |= 2;
4518
4519                 # Remove any action, temp breakpoint, etc.
4520                 $dbline{$lineno} =~ s/\0[^\0]*//;
4521
4522                 # Add the action to the line.
4523                 $dbline{$lineno} .= "\0" . action($expr);
4524
4525                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4526             }
4527         } ## end if (length $expr)
4528     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4529     else {
4530
4531         # Syntax wrong.
4532         print $OUT
4533           "Adding an action requires an optional lineno and an expression\n"
4534           ;    # hint
4535     }
4536 } ## end sub cmd_a
4537
4538 =head3 C<cmd_A> (command)
4539
4540 Delete actions. Similar to above, except the delete code is in a separate
4541 subroutine, C<delete_action>.
4542
4543 =cut
4544
4545 sub cmd_A {
4546     my $cmd    = shift;
4547     my $line   = shift || '';
4548     my $dbline = shift;
4549
4550     # Dot is this line.
4551     $line =~ s/^\./$dbline/;
4552
4553     # Call delete_action with a null param to delete them all.
4554     # The '1' forces the eval to be true. It'll be false only
4555     # if delete_action blows up for some reason, in which case
4556     # we print $@ and get out.
4557     if ( $line eq '*' ) {
4558         if (! eval { _delete_all_actions(); 1 }) {
4559             print {$OUT} $@;
4560             return;
4561         }
4562     }
4563
4564     # There's a real line  number. Pass it to delete_action.
4565     # Error trapping is as above.
4566     elsif ( $line =~ /^(\S.*)/ ) {
4567         if (! eval { delete_action($1); 1 }) {
4568             print {$OUT} $@;
4569             return;
4570         }
4571     }
4572
4573     # Swing and a miss. Bad syntax.
4574     else {
4575         print $OUT
4576           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4577     }
4578 } ## end sub cmd_A
4579
4580 =head3 C<delete_action> (API)
4581
4582 C<delete_action> accepts either a line number or C<undef>. If a line number
4583 is specified, we check for the line being executable (if it's not, it
4584 couldn't have had an  action). If it is, we just take the action off (this
4585 will get any kind of an action, including breakpoints).
4586
4587 =cut
4588
4589 sub _remove_action_from_dbline {
4590     my $i = shift;
4591
4592     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4593     delete $dbline{$i} if $dbline{$i} eq '';
4594
4595     return;
4596 }
4597
4598 sub _delete_all_actions {
4599     print {$OUT} "Deleting all actions...\n";
4600
4601     for my $file ( keys %had_breakpoints ) {
4602         local *dbline = $main::{ '_<' . $file };
4603         $max = $#dbline;
4604         my $was;
4605         for my $i (1 .. $max) {
4606             if ( defined $dbline{$i} ) {
4607                 _remove_action_from_dbline($i);
4608             }
4609         }
4610
4611         unless ( $had_breakpoints{$file} &= ~2 ) {
4612             delete $had_breakpoints{$file};
4613         }
4614     }
4615
4616     return;
4617 }
4618
4619 sub delete_action {
4620     my $i = shift;
4621
4622     if ( defined($i) ) {
4623         # Can there be one?
4624         die "Line $i has no action .\n" if $dbline[$i] == 0;
4625
4626         # Nuke whatever's there.
4627         _remove_action_from_dbline($i);
4628     }
4629     else {
4630         _delete_all_actions();
4631     }
4632 }
4633
4634 =head3 C<cmd_b> (command)
4635
4636 Set breakpoints. Since breakpoints can be set in so many places, in so many
4637 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4638 we try to parse the command type, and then shuttle it off to an appropriate
4639 subroutine to actually do the work of setting the breakpoint in the right
4640 place.
4641
4642 =cut
4643
4644 sub cmd_b {
4645     my $cmd    = shift;
4646     my $line   = shift;    # [.|line] [cond]
4647     my $dbline = shift;
4648
4649     my $default_cond = sub {
4650         my $cond = shift;
4651         return length($cond) ? $cond : '1';
4652     };
4653
4654     # Make . the current line number if it's there..
4655     $line =~ s/^\.(\s|\z)/$dbline$1/;
4656
4657     # No line number, no condition. Simple break on current line.
4658     if ( $line =~ /^\s*$/ ) {
4659         cmd_b_line( $dbline, 1 );
4660     }
4661
4662     # Break on load for a file.
4663     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4664         $file =~ s/\s+\z//;
4665         cmd_b_load($file);
4666     }
4667
4668     # b compile|postpone <some sub> [<condition>]
4669     # The interpreter actually traps this one for us; we just put the
4670     # necessary condition in the %postponed hash.
4671     elsif ( my ($action, $subname, $cond)
4672         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4673
4674         # De-Perl4-ify the name - ' separators to ::.
4675         $subname =~ s/'/::/g;
4676
4677         # Qualify it into the current package unless it's already qualified.
4678         $subname = "${package}::" . $subname unless $subname =~ /::/;
4679
4680         # Add main if it starts with ::.
4681         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4682
4683         # Save the break type for this sub.
4684         $postponed{$subname} = (($action eq 'postpone')
4685             ? ( "break +0 if " . $default_cond->($cond) )
4686             : "compile");
4687     } ## end elsif ($line =~ ...
4688     # b <filename>:<line> [<condition>]
4689     elsif (my ($filename, $line_num, $cond)
4690         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4691         cmd_b_filename_line(
4692             $filename,
4693             $line_num,
4694             (length($cond) ? $cond : '1'),
4695         );
4696     }
4697     # b <sub name> [<condition>]
4698     elsif ( my ($new_subname, $new_cond) =
4699         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4700
4701         #
4702         $subname = $new_subname;
4703         cmd_b_sub( $subname, $default_cond->($new_cond) );
4704     }
4705
4706     # b <line> [<condition>].
4707     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4708
4709         # Capture the line. If none, it's the current line.
4710         $line = $line_n || $dbline;
4711
4712         # Break on line.
4713         cmd_b_line( $line, $default_cond->($cond) );
4714     }
4715
4716     # Line didn't make sense.
4717     else {
4718         print "confused by line($line)?\n";
4719     }
4720
4721     return;
4722 } ## end sub cmd_b
4723
4724 =head3 C<break_on_load> (API)
4725
4726 We want to break when this file is loaded. Mark this file in the
4727 C<%break_on_load> hash, and note that it has a breakpoint in
4728 C<%had_breakpoints>.
4729
4730 =cut
4731
4732 sub break_on_load {
4733     my $file = shift;
4734     $break_on_load{$file} = 1;
4735     $had_breakpoints{$file} |= 1;
4736 }
4737
4738 =head3 C<report_break_on_load> (API)
4739
4740 Gives us an array of filenames that are set to break on load. Note that
4741 only files with break-on-load are in here, so simply showing the keys
4742 suffices.
4743
4744 =cut
4745
4746 sub report_break_on_load {
4747     sort keys %break_on_load;
4748 }
4749
4750 =head3 C<cmd_b_load> (command)
4751
4752 We take the file passed in and try to find it in C<%INC> (which maps modules
4753 to files they came from). We mark those files for break-on-load via
4754 C<break_on_load> and then report that it was done.
4755
4756 =cut
4757
4758 sub cmd_b_load {
4759     my $file = shift;
4760     my @files;
4761
4762     # This is a block because that way we can use a redo inside it
4763     # even without there being any looping structure at all outside it.
4764     {
4765
4766         # Save short name and full path if found.
4767         push @files, $file;
4768         push @files, $::INC{$file} if $::INC{$file};
4769
4770         # Tack on .pm and do it again unless there was a '.' in the name
4771         # already.
4772         $file .= '.pm', redo unless $file =~ /\./;
4773     }
4774
4775     # Do the real work here.
4776     break_on_load($_) for @files;
4777
4778     # All the files that have break-on-load breakpoints.
4779     @files = report_break_on_load;
4780
4781     # Normalize for the purposes of our printing this.
4782     local $\ = '';
4783     local $" = ' ';
4784     print $OUT "Will stop on load of '@files'.\n";
4785 } ## end sub cmd_b_load
4786
4787 =head3 C<$filename_error> (API package global)
4788
4789 Several of the functions we need to implement in the API need to work both
4790 on the current file and on other files. We don't want to duplicate code, so
4791 C<$filename_error> is used to contain the name of the file that's being
4792 worked on (if it's not the current one).
4793
4794 We can now build functions in pairs: the basic function works on the current
4795 file, and uses C<$filename_error> as part of its error message. Since this is
4796 initialized to C<"">, no filename will appear when we are working on the
4797 current file.
4798
4799 The second function is a wrapper which does the following:
4800
4801 =over 4
4802
4803 =item *
4804
4805 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4806
4807 =item *
4808
4809 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4810
4811 =item *
4812
4813 Calls the first function.
4814
4815 The first function works on the I<current> file (i.e., the one we changed to),
4816 and prints C<$filename_error> in the error message (the name of the other file)
4817 if it needs to. When the functions return, C<*dbline> is restored to point
4818 to the actual current file (the one we're executing in) and
4819 C<$filename_error> is restored to C<"">. This restores everything to
4820 the way it was before the second function was called at all.
4821
4822 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4823 details.
4824
4825 =back
4826
4827 =cut
4828
4829 use vars qw($filename_error);
4830 $filename_error = '';
4831
4832 =head3 breakable_line(from, to) (API)
4833
4834 The subroutine decides whether or not a line in the current file is breakable.
4835 It walks through C<@dbline> within the range of lines specified, looking for
4836 the first line that is breakable.
4837
4838 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4839 first line I<after> C<$to> that's breakable, if there is one.
4840
4841 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4842 first line I<before> C<$to> that's breakable, if there is one.
4843
4844 =cut
4845
4846 sub breakable_line {
4847
4848     my ( $from, $to ) = @_;
4849
4850     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4851     my $i = $from;
4852
4853     # If there are at least 2 arguments, we're trying to search a range.
4854     if (