This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
B:: changes for UNITCHECK blocks
[perl5.git] / ext / B / B / Concise.pm
1 package B::Concise;
2 # Copyright (C) 2000-2003 Stephen McCamant. All rights reserved.
3 # This program is free software; you can redistribute and/or modify it
4 # under the same terms as Perl itself.
5
6 # Note: we need to keep track of how many use declarations/BEGIN
7 # blocks this module uses, so we can avoid printing them when user
8 # asks for the BEGIN blocks in her program. Update the comments and
9 # the count in concise_specials if you add or delete one. The
10 # -MO=Concise counts as use #1.
11
12 use strict; # use #2
13 use warnings; # uses #3 and #4, since warnings uses Carp
14
15 use Exporter (); # use #5
16
17 our $VERSION   = "0.70";
18 our @ISA       = qw(Exporter);
19 our @EXPORT_OK = qw( set_style set_style_standard add_callback
20                      concise_subref concise_cv concise_main
21                      add_style walk_output compile reset_sequence );
22 our %EXPORT_TAGS =
23     ( io        => [qw( walk_output compile reset_sequence )],
24       style     => [qw( add_style set_style_standard )],
25       cb        => [qw( add_callback )],
26       mech      => [qw( concise_subref concise_cv concise_main )],  );
27
28 # use #6
29 use B qw(class ppname main_start main_root main_cv cstring svref_2object
30          SVf_IOK SVf_NOK SVf_POK SVf_IVisUV SVf_FAKE OPf_KIDS OPf_SPECIAL
31          CVf_ANON);
32
33 my %style =
34   ("terse" =>
35    ["(?(#label =>\n)?)(*(    )*)#class (#addr) #name (?([#targ])?) "
36     . "#svclass~(?((#svaddr))?)~#svval~(?(label \"#coplabel\")?)\n",
37     "(*(    )*)goto #class (#addr)\n",
38     "#class pp_#name"],
39    "concise" =>
40    ["#hyphseq2 (*(   (x( ;)x))*)<#classsym> #exname#arg(?([#targarglife])?)"
41     . "~#flags(?(/#private)?)(?(:#hints)?)(x(;~->#next)x)\n"
42     , "  (*(    )*)     goto #seq\n",
43     "(?(<#seq>)?)#exname#arg(?([#targarglife])?)"],
44    "linenoise" =>
45    ["(x(;(*( )*))x)#noise#arg(?([#targarg])?)(x( ;\n)x)",
46     "gt_#seq ",
47     "(?(#seq)?)#noise#arg(?([#targarg])?)"],
48    "debug" =>
49    ["#class (#addr)\n\top_next\t\t#nextaddr\n\top_sibling\t#sibaddr\n\t"
50     . "op_ppaddr\tPL_ppaddr[OP_#NAME]\n\top_type\t\t#typenum\n" .
51     ($] > 5.009 ? '' : "\top_seq\t\t#seqnum\n")
52     . "\top_flags\t#flagval\n\top_private\t#privval\t#hintsval\n"
53     . "(?(\top_first\t#firstaddr\n)?)(?(\top_last\t\t#lastaddr\n)?)"
54     . "(?(\top_sv\t\t#svaddr\n)?)",
55     "    GOTO #addr\n",
56     "#addr"],
57    "env" => [$ENV{B_CONCISE_FORMAT}, $ENV{B_CONCISE_GOTO_FORMAT},
58              $ENV{B_CONCISE_TREE_FORMAT}],
59   );
60
61 # Renderings, ie how Concise prints, is controlled by these vars
62 # primary:
63 our $stylename;         # selects current style from %style
64 my $order = "basic";    # how optree is walked & printed: basic, exec, tree
65
66 # rendering mechanics:
67 # these 'formats' are the line-rendering templates
68 # they're updated from %style when $stylename changes
69 my ($format, $gotofmt, $treefmt);
70
71 # lesser players:
72 my $base = 36;          # how <sequence#> is displayed
73 my $big_endian = 1;     # more <sequence#> display
74 my $tree_style = 0;     # tree-order details
75 my $banner = 1;         # print banner before optree is traversed
76 my $do_main = 0;        # force printing of main routine
77
78 # another factor: can affect all styles!
79 our @callbacks;         # allow external management
80
81 set_style_standard("concise");
82
83 my $curcv;
84 my $cop_seq_base;
85
86 sub set_style {
87     ($format, $gotofmt, $treefmt) = @_;
88     #warn "set_style: deprecated, use set_style_standard instead\n"; # someday
89     die "expecting 3 style-format args\n" unless @_ == 3;
90 }
91
92 sub add_style {
93     my ($newstyle,@args) = @_;
94     die "style '$newstyle' already exists, choose a new name\n"
95         if exists $style{$newstyle};
96     die "expecting 3 style-format args\n" unless @args == 3;
97     $style{$newstyle} = [@args];
98     $stylename = $newstyle; # update rendering state
99 }
100
101 sub set_style_standard {
102     ($stylename) = @_; # update rendering state
103     die "err: style '$stylename' unknown\n" unless exists $style{$stylename};
104     set_style(@{$style{$stylename}});
105 }
106
107 sub add_callback {
108     push @callbacks, @_;
109 }
110
111 # output handle, used with all Concise-output printing
112 our $walkHandle;        # public for your convenience
113 BEGIN { $walkHandle = \*STDOUT }
114
115 sub walk_output { # updates $walkHandle
116     my $handle = shift;
117     return $walkHandle unless $handle; # allow use as accessor
118
119     if (ref $handle eq 'SCALAR') {
120         require Config;
121         die "no perlio in this build, can't call walk_output (\\\$scalar)\n"
122             unless $Config::Config{useperlio};
123         # in 5.8+, open(FILEHANDLE,MODE,REFERENCE) writes to string
124         open my $tmp, '>', $handle;     # but cant re-set existing STDOUT
125         $walkHandle = $tmp;             # so use my $tmp as intermediate var
126         return $walkHandle;
127     }
128     my $iotype = ref $handle;
129     die "expecting argument/object that can print\n"
130         unless $iotype eq 'GLOB' or $iotype and $handle->can('print');
131     $walkHandle = $handle;
132 }
133
134 sub concise_subref {
135     my($order, $coderef, $name) = @_;
136     my $codeobj = svref_2object($coderef);
137
138     return concise_stashref(@_)
139         unless ref $codeobj eq 'B::CV';
140     concise_cv_obj($order, $codeobj, $name);
141 }
142
143 sub concise_stashref {
144     my($order, $h) = @_;
145     foreach my $k (sort keys %$h) {
146         local *s = $h->{$k};
147         my $coderef = *s{CODE} or next;
148         reset_sequence();
149         print "FUNC: ", *s, "\n";
150         my $codeobj = svref_2object($coderef);
151         next unless ref $codeobj eq 'B::CV';
152         eval { concise_cv_obj($order, $codeobj) }
153         or warn "err $@ on $codeobj";
154     }
155 }
156
157 # This should have been called concise_subref, but it was exported
158 # under this name in versions before 0.56
159 *concise_cv = \&concise_subref;
160
161 sub concise_cv_obj {
162     my ($order, $cv, $name) = @_;
163     # name is either a string, or a CODE ref (copy of $cv arg??)
164
165     $curcv = $cv;
166
167     if (ref($cv->XSUBANY) =~ /B::(\w+)/) {
168         print $walkHandle "$name is a constant sub, optimized to a $1\n";
169         return;
170     }
171     if ($cv->XSUB) {
172         print $walkHandle "$name is XS code\n";
173         return;
174     }
175     if (class($cv->START) eq "NULL") {
176         no strict 'refs';
177         if (ref $name eq 'CODE') {
178             print $walkHandle "coderef $name has no START\n";
179         }
180         elsif (exists &$name) {
181             print $walkHandle "$name exists in stash, but has no START\n";
182         }
183         else {
184             print $walkHandle "$name not in symbol table\n";
185         }
186         return;
187     }
188     sequence($cv->START);
189     if ($order eq "exec") {
190         walk_exec($cv->START);
191     }
192     elsif ($order eq "basic") {
193         # walk_topdown($cv->ROOT, sub { $_[0]->concise($_[1]) }, 0);
194         my $root = $cv->ROOT;
195         unless (ref $root eq 'B::NULL') {
196             walk_topdown($root, sub { $_[0]->concise($_[1]) }, 0);
197         } else {
198             print $walkHandle "B::NULL encountered doing ROOT on $cv. avoiding disaster\n";
199         }
200     } else {
201         print $walkHandle tree($cv->ROOT, 0);
202     }
203 }
204
205 sub concise_main {
206     my($order) = @_;
207     sequence(main_start);
208     $curcv = main_cv;
209     if ($order eq "exec") {
210         return if class(main_start) eq "NULL";
211         walk_exec(main_start);
212     } elsif ($order eq "tree") {
213         return if class(main_root) eq "NULL";
214         print $walkHandle tree(main_root, 0);
215     } elsif ($order eq "basic") {
216         return if class(main_root) eq "NULL";
217         walk_topdown(main_root,
218                      sub { $_[0]->concise($_[1]) }, 0);
219     }
220 }
221
222 sub concise_specials {
223     my($name, $order, @cv_s) = @_;
224     my $i = 1;
225     if ($name eq "BEGIN") {
226         splice(@cv_s, 0, 8); # skip 7 BEGIN blocks in this file. NOW 8 ??
227     } elsif ($name eq "CHECK") {
228         pop @cv_s; # skip the CHECK block that calls us
229     }
230     for my $cv (@cv_s) {
231         print $walkHandle "$name $i:\n";
232         $i++;
233         concise_cv_obj($order, $cv, $name);
234     }
235 }
236
237 my $start_sym = "\e(0"; # "\cN" sometimes also works
238 my $end_sym   = "\e(B"; # "\cO" respectively
239
240 my @tree_decorations =
241   (["  ", "--", "+-", "|-", "| ", "`-", "-", 1],
242    [" ", "-", "+", "+", "|", "`", "", 0],
243    ["  ", map("$start_sym$_$end_sym", "qq", "wq", "tq", "x ", "mq", "q"), 1],
244    [" ", map("$start_sym$_$end_sym", "q", "w", "t", "x", "m"), "", 0],
245   );
246
247
248 sub compileOpts {
249     # set rendering state from options and args
250     my (@options,@args);
251     if (@_) {
252         @options = grep(/^-/, @_);
253         @args = grep(!/^-/, @_);
254     }
255     for my $o (@options) {
256         # mode/order
257         if ($o eq "-basic") {
258             $order = "basic";
259         } elsif ($o eq "-exec") {
260             $order = "exec";
261         } elsif ($o eq "-tree") {
262             $order = "tree";
263         }
264         # tree-specific
265         elsif ($o eq "-compact") {
266             $tree_style |= 1;
267         } elsif ($o eq "-loose") {
268             $tree_style &= ~1;
269         } elsif ($o eq "-vt") {
270             $tree_style |= 2;
271         } elsif ($o eq "-ascii") {
272             $tree_style &= ~2;
273         }
274         # sequence numbering
275         elsif ($o =~ /^-base(\d+)$/) {
276             $base = $1;
277         } elsif ($o eq "-bigendian") {
278             $big_endian = 1;
279         } elsif ($o eq "-littleendian") {
280             $big_endian = 0;
281         }
282         elsif ($o eq "-nobanner") {
283             $banner = 0;
284         } elsif ($o eq "-banner") {
285             $banner = 1;
286         }
287         elsif ($o eq "-main") {
288             $do_main = 1;
289         } elsif ($o eq "-nomain") {
290             $do_main = 0;
291         }
292         # line-style options
293         elsif (exists $style{substr($o, 1)}) {
294             $stylename = substr($o, 1);
295             set_style_standard($stylename);
296         } else {
297             warn "Option $o unrecognized";
298         }
299     }
300     return (@args);
301 }
302
303 sub compile {
304     my (@args) = compileOpts(@_);
305     return sub {
306         my @newargs = compileOpts(@_); # accept new rendering options
307         warn "disregarding non-options: @newargs\n" if @newargs;
308
309         for my $objname (@args) {
310             next unless $objname; # skip null args to avoid noisy responses
311
312             if ($objname eq "BEGIN") {
313                 concise_specials("BEGIN", $order,
314                                  B::begin_av->isa("B::AV") ?
315                                  B::begin_av->ARRAY : ());
316             } elsif ($objname eq "INIT") {
317                 concise_specials("INIT", $order,
318                                  B::init_av->isa("B::AV") ?
319                                  B::init_av->ARRAY : ());
320             } elsif ($objname eq "CHECK") {
321                 concise_specials("CHECK", $order,
322                                  B::check_av->isa("B::AV") ?
323                                  B::check_av->ARRAY : ());
324             } elsif ($objname eq "UNITCHECK") {
325                 concise_specials("UNITCHECK", $order,
326                                  B::unitcheck_av->isa("B::AV") ?
327                                  B::unitcheck_av->ARRAY : ());
328             } elsif ($objname eq "END") {
329                 concise_specials("END", $order,
330                                  B::end_av->isa("B::AV") ?
331                                  B::end_av->ARRAY : ());
332             }
333             else {
334                 # convert function names to subrefs
335                 my $objref;
336                 if (ref $objname) {
337                     print $walkHandle "B::Concise::compile($objname)\n"
338                         if $banner;
339                     $objref = $objname;
340                 } else {
341                     $objname = "main::" . $objname unless $objname =~ /::/;
342                     print $walkHandle "$objname:\n";
343                     no strict 'refs';
344                     unless (exists &$objname) {
345                         print $walkHandle "err: unknown function ($objname)\n";
346                         return;
347                     }
348                     $objref = \&$objname;
349                 }
350                 concise_subref($order, $objref, $objname);
351             }
352         }
353         if (!@args or $do_main) {
354             print $walkHandle "main program:\n" if $do_main;
355             concise_main($order);
356         }
357         return @args;   # something
358     }
359 }
360
361 my %labels;
362 my $lastnext;   # remembers op-chain, used to insert gotos
363
364 my %opclass = ('OP' => "0", 'UNOP' => "1", 'BINOP' => "2", 'LOGOP' => "|",
365                'LISTOP' => "@", 'PMOP' => "/", 'SVOP' => "\$", 'GVOP' => "*",
366                'PVOP' => '"', 'LOOP' => "{", 'COP' => ";", 'PADOP' => "#");
367
368 no warnings 'qw'; # "Possible attempt to put comments..."; use #7
369 my @linenoise =
370   qw'#  () sc (  @? 1  $* gv *{ m$ m@ m% m? p/ *$ $  $# & a& pt \\ s\\ rf bl
371      `  *? <> ?? ?/ r/ c/ // qr s/ /c y/ =  @= C  sC Cp sp df un BM po +1 +I
372      -1 -I 1+ I+ 1- I- ** *  i* /  i/ %$ i% x  +  i+ -  i- .  "  << >> <  i<
373      >  i> <= i, >= i. == i= != i! <? i? s< s> s, s. s= s! s? b& b^ b| -0 -i
374      !  ~  a2 si cs rd sr e^ lg sq in %x %o ab le ss ve ix ri sf FL od ch cy
375      uf lf uc lc qm @  [f [  @[ eh vl ky dl ex %  ${ @{ uk pk st jn )  )[ a@
376      a% sl +] -] [- [+ so rv GS GW MS MW .. f. .f && || ^^ ?: &= |= -> s{ s}
377      v} ca wa di rs ;; ;  ;d }{ {  }  {} f{ it {l l} rt }l }n }r dm }g }e ^o
378      ^c ^| ^# um bm t~ u~ ~d DB db ^s se ^g ^r {w }w pf pr ^O ^K ^R ^W ^d ^v
379      ^e ^t ^k t. fc ic fl .s .p .b .c .l .a .h g1 s1 g2 s2 ?. l? -R -W -X -r
380      -w -x -e -o -O -z -s -M -A -C -S -c -b -f -d -p -l -u -g -k -t -T -B cd
381      co cr u. cm ut r. l@ s@ r@ mD uD oD rD tD sD wD cD f$ w$ p$ sh e$ k$ g3
382      g4 s4 g5 s5 T@ C@ L@ G@ A@ S@ Hg Hc Hr Hw Mg Mc Ms Mr Sg Sc So rq do {e
383      e} {t t} g6 G6 6e g7 G7 7e g8 G8 8e g9 G9 9e 6s 7s 8s 9s 6E 7E 8E 9E Pn
384      Pu GP SP EP Gn Gg GG SG EG g0 c$ lk t$ ;s n> // /= CO';
385
386 my $chars = "0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ";
387
388 sub op_flags { # common flags (see BASOP.op_flags in op.h)
389     my($x) = @_;
390     my(@v);
391     push @v, "v" if ($x & 3) == 1;
392     push @v, "s" if ($x & 3) == 2;
393     push @v, "l" if ($x & 3) == 3;
394     push @v, "K" if $x & 4;
395     push @v, "P" if $x & 8;
396     push @v, "R" if $x & 16;
397     push @v, "M" if $x & 32;
398     push @v, "S" if $x & 64;
399     push @v, "*" if $x & 128;
400     return join("", @v);
401 }
402
403 sub base_n {
404     my $x = shift;
405     return "-" . base_n(-$x) if $x < 0;
406     my $str = "";
407     do { $str .= substr($chars, $x % $base, 1) } while $x = int($x / $base);
408     $str = reverse $str if $big_endian;
409     return $str;
410 }
411
412 my %sequence_num;
413 my $seq_max = 1;
414
415 sub reset_sequence {
416     # reset the sequence
417     %sequence_num = ();
418     $seq_max = 1;
419     $lastnext = 0;
420 }
421
422 sub seq {
423     my($op) = @_;
424     return "-" if not exists $sequence_num{$$op};
425     return base_n($sequence_num{$$op});
426 }
427
428 sub walk_topdown {
429     my($op, $sub, $level) = @_;
430     $sub->($op, $level);
431     if ($op->flags & OPf_KIDS) {
432         for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
433             walk_topdown($kid, $sub, $level + 1);
434         }
435     }
436     elsif (class($op) eq "PMOP") {
437         my $maybe_root = $op->pmreplroot;
438         if (ref($maybe_root) and $maybe_root->isa("B::OP")) {
439             # It really is the root of the replacement, not something
440             # else stored here for lack of space elsewhere
441             walk_topdown($maybe_root, $sub, $level + 1);
442         }
443     }
444 }
445
446 sub walklines {
447     my($ar, $level) = @_;
448     for my $l (@$ar) {
449         if (ref($l) eq "ARRAY") {
450             walklines($l, $level + 1);
451         } else {
452             $l->concise($level);
453         }
454     }
455 }
456
457 sub walk_exec {
458     my($top, $level) = @_;
459     my %opsseen;
460     my @lines;
461     my @todo = ([$top, \@lines]);
462     while (@todo and my($op, $targ) = @{shift @todo}) {
463         for (; $$op; $op = $op->next) {
464             last if $opsseen{$$op}++;
465             push @$targ, $op;
466             my $name = $op->name;
467             if (class($op) eq "LOGOP") {
468                 my $ar = [];
469                 push @$targ, $ar;
470                 push @todo, [$op->other, $ar];
471             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
472                 my $ar = [];
473                 push @$targ, $ar;
474                 push @todo, [$op->pmreplstart, $ar];
475             } elsif ($name =~ /^enter(loop|iter)$/) {
476                 if ($] > 5.009) {
477                     $labels{${$op->nextop}} = "NEXT";
478                     $labels{${$op->lastop}} = "LAST";
479                     $labels{${$op->redoop}} = "REDO";
480                 } else {
481                     $labels{$op->nextop->seq} = "NEXT";
482                     $labels{$op->lastop->seq} = "LAST";
483                     $labels{$op->redoop->seq} = "REDO";         
484                 }
485             }
486         }
487     }
488     walklines(\@lines, 0);
489 }
490
491 # The structure of this routine is purposely modeled after op.c's peep()
492 sub sequence {
493     my($op) = @_;
494     my $oldop = 0;
495     return if class($op) eq "NULL" or exists $sequence_num{$$op};
496     for (; $$op; $op = $op->next) {
497         last if exists $sequence_num{$$op};
498         my $name = $op->name;
499         if ($name =~ /^(null|scalar|lineseq|scope)$/) {
500             next if $oldop and $ {$op->next};
501         } else {
502             $sequence_num{$$op} = $seq_max++;
503             if (class($op) eq "LOGOP") {
504                 my $other = $op->other;
505                 $other = $other->next while $other->name eq "null";
506                 sequence($other);
507             } elsif (class($op) eq "LOOP") {
508                 my $redoop = $op->redoop;
509                 $redoop = $redoop->next while $redoop->name eq "null";
510                 sequence($redoop);
511                 my $nextop = $op->nextop;
512                 $nextop = $nextop->next while $nextop->name eq "null";
513                 sequence($nextop);
514                 my $lastop = $op->lastop;
515                 $lastop = $lastop->next while $lastop->name eq "null";
516                 sequence($lastop);
517             } elsif ($name eq "subst" and $ {$op->pmreplstart}) {
518                 my $replstart = $op->pmreplstart;
519                 $replstart = $replstart->next while $replstart->name eq "null";
520                 sequence($replstart);
521             }
522         }
523         $oldop = $op;
524     }
525 }
526
527 sub fmt_line {    # generate text-line for op.
528     my($hr, $op, $text, $level) = @_;
529
530     $_->($hr, $op, \$text, \$level, $stylename) for @callbacks;
531
532     return '' if $hr->{SKIP};   # suppress line if a callback said so
533     return '' if $hr->{goto} and $hr->{goto} eq '-';    # no goto nowhere
534
535     # spec: (?(text1#varText2)?)
536     $text =~ s/\(\?\(([^\#]*?)\#(\w+)([^\#]*?)\)\?\)/
537         $hr->{$2} ? $1.$hr->{$2}.$3 : ""/eg;
538
539     # spec: (x(exec_text;basic_text)x)
540     $text =~ s/\(x\((.*?);(.*?)\)x\)/$order eq "exec" ? $1 : $2/egs;
541
542     # spec: (*(text)*)
543     $text =~ s/\(\*\(([^;]*?)\)\*\)/$1 x $level/egs;
544
545     # spec: (*(text1;text2)*)
546     $text =~ s/\(\*\((.*?);(.*?)\)\*\)/$1 x ($level - 1) . $2 x ($level>0)/egs;
547
548     # convert #Var to tag=>val form: Var\t#var
549     $text =~ s/\#([A-Z][a-z]+)(\d+)?/\t\u$1\t\L#$1$2/gs;
550
551     # spec: #varN
552     $text =~ s/\#([a-zA-Z]+)(\d+)/sprintf("%-$2s", $hr->{$1})/eg;
553
554     $text =~ s/\#([a-zA-Z]+)/$hr->{$1}/eg;      # populate #var's
555     $text =~ s/[ \t]*~+[ \t]*/ /g;              # squeeze tildes
556     chomp $text;
557     return "$text\n" if $text ne "";
558     return $text; # suppress empty lines
559 }
560
561 our %priv; # used to display each opcode's BASEOP.op_private values
562
563 $priv{$_}{128} = "LVINTRO"
564   for ("pos", "substr", "vec", "threadsv", "gvsv", "rv2sv", "rv2hv", "rv2gv",
565        "rv2av", "rv2arylen", "aelem", "helem", "aslice", "hslice", "padsv",
566        "padav", "padhv", "enteriter");
567 $priv{$_}{64} = "REFC" for ("leave", "leavesub", "leavesublv", "leavewrite");
568 $priv{"aassign"}{64} = "COMMON";
569 $priv{"aassign"}{32} = $] < 5.009 ? "PHASH" : "STATE";
570 $priv{"sassign"}{32} = "STATE";
571 $priv{"sassign"}{64} = "BKWARD";
572 $priv{$_}{64} = "RTIME" for ("match", "subst", "substcont", "qr");
573 @{$priv{"trans"}}{1,2,4,8,16,64} = ("<UTF", ">UTF", "IDENT", "SQUASH", "DEL",
574                                     "COMPL", "GROWS");
575 $priv{"repeat"}{64} = "DOLIST";
576 $priv{"leaveloop"}{64} = "CONT";
577 @{$priv{$_}}{32,64,96} = ("DREFAV", "DREFHV", "DREFSV")
578   for (qw(rv2gv rv2sv padsv aelem helem));
579 $priv{$_}{16} = "STATE" for ("padav", "padhv", "padsv");
580 @{$priv{"entersub"}}{16,32,64} = ("DBG","TARG","NOMOD");
581 @{$priv{$_}}{4,8,128} = ("INARGS","AMPER","NO()") for ("entersub", "rv2cv");
582 $priv{"gv"}{32} = "EARLYCV";
583 $priv{"aelem"}{16} = $priv{"helem"}{16} = "LVDEFER";
584 $priv{$_}{16} = "OURINTR" for ("gvsv", "rv2sv", "rv2av", "rv2hv", "r2gv",
585         "enteriter");
586 $priv{$_}{16} = "TARGMY"
587   for (map(($_,"s$_"),"chop", "chomp"),
588        map(($_,"i_$_"), "postinc", "postdec", "multiply", "divide", "modulo",
589            "add", "subtract", "negate"), "pow", "concat", "stringify",
590        "left_shift", "right_shift", "bit_and", "bit_xor", "bit_or",
591        "complement", "atan2", "sin", "cos", "rand", "exp", "log", "sqrt",
592        "int", "hex", "oct", "abs", "length", "index", "rindex", "sprintf",
593        "ord", "chr", "crypt", "quotemeta", "join", "push", "unshift", "flock",
594        "chdir", "chown", "chroot", "unlink", "chmod", "utime", "rename",
595        "link", "symlink", "mkdir", "rmdir", "wait", "waitpid", "system",
596        "exec", "kill", "getppid", "getpgrp", "setpgrp", "getpriority",
597        "setpriority", "time", "sleep");
598 $priv{$_}{4} = "REVERSED" for ("enteriter", "iter");
599 @{$priv{"const"}}{4,8,16,32,64,128} = ("SHORT","STRICT","ENTERED",'$[',"BARE","WARN");
600 $priv{"flip"}{64} = $priv{"flop"}{64} = "LINENUM";
601 $priv{"list"}{64} = "GUESSED";
602 $priv{"delete"}{64} = "SLICE";
603 $priv{"exists"}{64} = "SUB";
604 @{$priv{"sort"}}{1,2,4,8,16,32,64} = ("NUM", "INT", "REV", "INPLACE","DESC","QSORT","STABLE");
605 $priv{"threadsv"}{64} = "SVREFd";
606 @{$priv{$_}}{16,32,64,128} = ("INBIN","INCR","OUTBIN","OUTCR")
607   for ("open", "backtick");
608 $priv{"exit"}{128} = "VMS";
609 $priv{$_}{2} = "FTACCESS"
610   for ("ftrread", "ftrwrite", "ftrexec", "fteread", "ftewrite", "fteexec");
611 $priv{"entereval"}{2} = "HAS_HH";
612 if ($] >= 5.009) {
613   # Stacked filetests are post 5.8.x
614   $priv{$_}{4} = "FTSTACKED"
615     for ("ftrread", "ftrwrite", "ftrexec", "fteread", "ftewrite", "fteexec",
616          "ftis", "fteowned", "ftrowned", "ftzero", "ftsize", "ftmtime",
617          "ftatime", "ftctime", "ftsock", "ftchr", "ftblk", "ftfile", "ftdir",
618          "ftpipe", "ftlink", "ftsuid", "ftsgid", "ftsvtx", "fttty", "fttext",
619          "ftbinary");
620   # Lexical $_ is post 5.8.x
621   $priv{$_}{2} = "GREPLEX"
622     for ("mapwhile", "mapstart", "grepwhile", "grepstart");
623 }
624
625 our %hints; # used to display each COP's op_hints values
626
627 # strict refs, subs, vars
628 @hints{2,512,1024} = ('$', '&', '*');
629 # integers, locale, bytes, arybase
630 @hints{1,4,8,16,32} = ('i', 'l', 'b', '[');
631 # block scope, localise %^H, $^OPEN
632 @hints{256,131072,262144} = ('{','%','<');
633 # overload new integer, float, binary, string, re
634 @hints{4096,8192,16384,32768,65536} = ('I', 'F', 'B', 'S', 'R');
635 # taint and eval
636 @hints{1048576,2097152} = ('T', 'E');
637 # filetest access, UTF-8, assertions, assertions seen
638 @hints{4194304,8388608,16777216,33554432} = ('X', 'U', 'A', 'a');
639
640 sub _flags {
641     my($hash, $x) = @_;
642     my @s;
643     for my $flag (sort {$b <=> $a} keys %$hash) {
644         if ($hash->{$flag} and $x & $flag and $x >= $flag) {
645             $x -= $flag;
646             push @s, $hash->{$flag};
647         }
648     }
649     push @s, $x if $x;
650     return join(",", @s);
651 }
652
653 sub private_flags {
654     my($name, $x) = @_;
655     _flags($priv{$name}, $x);
656 }
657
658 sub hints_flags {
659     my($x) = @_;
660     _flags(\%hints, $x);
661 }
662
663 sub concise_sv {
664     my($sv, $hr, $preferpv) = @_;
665     $hr->{svclass} = class($sv);
666     $hr->{svclass} = "UV"
667       if $hr->{svclass} eq "IV" and $sv->FLAGS & SVf_IVisUV;
668     Carp::cluck("bad concise_sv: $sv") unless $sv and $$sv;
669     $hr->{svaddr} = sprintf("%#x", $$sv);
670     if ($hr->{svclass} eq "GV") {
671         my $gv = $sv;
672         my $stash = $gv->STASH->NAME;
673         if ($stash eq "main") {
674             $stash = "";
675         } else {
676             $stash = $stash . "::";
677         }
678         $hr->{svval} = "*$stash" . $gv->SAFENAME;
679         return "*$stash" . $gv->SAFENAME;
680     } else {
681         while (class($sv) eq "RV") {
682             $hr->{svval} .= "\\";
683             $sv = $sv->RV;
684         }
685         if (class($sv) eq "SPECIAL") {
686             $hr->{svval} .= ["Null", "sv_undef", "sv_yes", "sv_no"]->[$$sv];
687         } elsif ($preferpv && $sv->FLAGS & SVf_POK) {
688             $hr->{svval} .= cstring($sv->PV);
689         } elsif ($sv->FLAGS & SVf_NOK) {
690             $hr->{svval} .= $sv->NV;
691         } elsif ($sv->FLAGS & SVf_IOK) {
692             $hr->{svval} .= $sv->int_value;
693         } elsif ($sv->FLAGS & SVf_POK) {
694             $hr->{svval} .= cstring($sv->PV);
695         } elsif (class($sv) eq "HV") {
696             $hr->{svval} .= 'HASH';
697         }
698
699         $hr->{svval} = 'undef' unless defined $hr->{svval};
700         my $out = $hr->{svclass};
701         return $out .= " $hr->{svval}" ; 
702     }
703 }
704
705 sub concise_op {
706     my ($op, $level, $format) = @_;
707     my %h;
708     $h{exname} = $h{name} = $op->name;
709     $h{NAME} = uc $h{name};
710     $h{class} = class($op);
711     $h{extarg} = $h{targ} = $op->targ;
712     $h{extarg} = "" unless $h{extarg};
713     if ($h{name} eq "null" and $h{targ}) {
714         # targ holds the old type
715         $h{exname} = "ex-" . substr(ppname($h{targ}), 3);
716         $h{extarg} = "";
717     } elsif ($op->name =~ /^leave(sub(lv)?|write)?$/) {
718         # targ potentially holds a reference count
719         if ($op->private & 64) {
720             my $refs = "ref" . ($h{targ} != 1 ? "s" : "");
721             $h{targarglife} = $h{targarg} = "$h{targ} $refs";
722         }
723     } elsif ($h{targ}) {
724         my $padname = (($curcv->PADLIST->ARRAY)[0]->ARRAY)[$h{targ}];
725         if (defined $padname and class($padname) ne "SPECIAL") {
726             $h{targarg}  = $padname->PVX;
727             if ($padname->FLAGS & SVf_FAKE) {
728                 if ($] < 5.009) {
729                     $h{targarglife} = "$h{targarg}:FAKE";
730                 } else {
731                     # These changes relate to the jumbo closure fix.
732                     # See changes 19939 and 20005
733                     my $fake = '';
734                     $fake .= 'a' if $padname->IVX & 1; # PAD_FAKELEX_ANON
735                     $fake .= 'm' if $padname->IVX & 2; # PAD_FAKELEX_MULTI
736                     $fake .= ':' . $padname->NVX if $curcv->CvFLAGS & CVf_ANON;
737                     $h{targarglife} = "$h{targarg}:FAKE:$fake";
738                 }
739             }
740             else {
741                 my $intro = $padname->NVX - $cop_seq_base;
742                 my $finish = int($padname->IVX) - $cop_seq_base;
743                 $finish = "end" if $finish == 999999999 - $cop_seq_base;
744                 $h{targarglife} = "$h{targarg}:$intro,$finish";
745             }
746         } else {
747             $h{targarglife} = $h{targarg} = "t" . $h{targ};
748         }
749     }
750     $h{arg} = "";
751     $h{svclass} = $h{svaddr} = $h{svval} = "";
752     if ($h{class} eq "PMOP") {
753         my $precomp = $op->precomp;
754         if (defined $precomp) {
755             $precomp = cstring($precomp); # Escape literal control sequences
756             $precomp = "/$precomp/";
757         } else {
758             $precomp = "";
759         }
760         my $pmreplroot = $op->pmreplroot;
761         my $pmreplstart;
762         if (ref($pmreplroot) eq "B::GV") {
763             # with C<@stash_array = split(/pat/, str);>,
764             #  *stash_array is stored in /pat/'s pmreplroot.
765             $h{arg} = "($precomp => \@" . $pmreplroot->NAME . ")";
766         } elsif (!ref($pmreplroot) and $pmreplroot) {
767             # same as the last case, except the value is actually a
768             # pad offset for where the GV is kept (this happens under
769             # ithreads)
770             my $gv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$pmreplroot];
771             $h{arg} = "($precomp => \@" . $gv->NAME . ")";
772         } elsif ($ {$op->pmreplstart}) {
773             undef $lastnext;
774             $pmreplstart = "replstart->" . seq($op->pmreplstart);
775             $h{arg} = "(" . join(" ", $precomp, $pmreplstart) . ")";
776         } else {
777             $h{arg} = "($precomp)";
778         }
779     } elsif ($h{class} eq "PVOP" and $h{name} ne "trans") {
780         $h{arg} = '("' . $op->pv . '")';
781         $h{svval} = '"' . $op->pv . '"';
782     } elsif ($h{class} eq "COP") {
783         my $label = $op->label;
784         $h{coplabel} = $label;
785         $label = $label ? "$label: " : "";
786         my $loc = $op->file;
787         $loc =~ s[.*/][];
788         $loc .= ":" . $op->line;
789         my($stash, $cseq) = ($op->stash->NAME, $op->cop_seq - $cop_seq_base);
790         my $arybase = $op->arybase;
791         $arybase = $arybase ? ' $[=' . $arybase : "";
792         $h{arg} = "($label$stash $cseq $loc$arybase)";
793     } elsif ($h{class} eq "LOOP") {
794         $h{arg} = "(next->" . seq($op->nextop) . " last->" . seq($op->lastop)
795           . " redo->" . seq($op->redoop) . ")";
796     } elsif ($h{class} eq "LOGOP") {
797         undef $lastnext;
798         $h{arg} = "(other->" . seq($op->other) . ")";
799     }
800     elsif ($h{class} eq "SVOP" or $h{class} eq "PADOP") {
801         unless ($h{name} eq 'aelemfast' and $op->flags & OPf_SPECIAL) {
802             my $idx = ($h{class} eq "SVOP") ? $op->targ : $op->padix;
803             my $preferpv = $h{name} eq "method_named";
804             if ($h{class} eq "PADOP" or !${$op->sv}) {
805                 my $sv = (($curcv->PADLIST->ARRAY)[1]->ARRAY)[$idx];
806                 $h{arg} = "[" . concise_sv($sv, \%h, $preferpv) . "]";
807                 $h{targarglife} = $h{targarg} = "";
808             } else {
809                 $h{arg} = "(" . concise_sv($op->sv, \%h, $preferpv) . ")";
810             }
811         }
812     }
813     $h{seq} = $h{hyphseq} = seq($op);
814     $h{seq} = "" if $h{seq} eq "-";
815     if ($] > 5.009) {
816         $h{opt} = $op->opt;
817         $h{static} = $op->static;
818         $h{label} = $labels{$$op};
819     } else {
820         $h{seqnum} = $op->seq;
821         $h{label} = $labels{$op->seq};
822     }
823     $h{next} = $op->next;
824     $h{next} = (class($h{next}) eq "NULL") ? "(end)" : seq($h{next});
825     $h{nextaddr} = sprintf("%#x", $ {$op->next});
826     $h{sibaddr} = sprintf("%#x", $ {$op->sibling});
827     $h{firstaddr} = sprintf("%#x", $ {$op->first}) if $op->can("first");
828     $h{lastaddr} = sprintf("%#x", $ {$op->last}) if $op->can("last");
829
830     $h{classsym} = $opclass{$h{class}};
831     $h{flagval} = $op->flags;
832     $h{flags} = op_flags($op->flags);
833     $h{privval} = $op->private;
834     $h{private} = private_flags($h{name}, $op->private);
835     if ($op->can("hints")) {
836       $h{hintsval} = $op->hints;
837       $h{hints} = hints_flags($h{hintsval});
838     } else {
839       $h{hintsval} = $h{hints} = '';
840     }
841     $h{addr} = sprintf("%#x", $$op);
842     $h{typenum} = $op->type;
843     $h{noise} = $linenoise[$op->type];
844
845     return fmt_line(\%h, $op, $format, $level);
846 }
847
848 sub B::OP::concise {
849     my($op, $level) = @_;
850     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
851         # insert a 'goto' line
852         my $synth = {"seq" => seq($lastnext), "class" => class($lastnext),
853                      "addr" => sprintf("%#x", $$lastnext),
854                      "goto" => seq($lastnext), # simplify goto '-' removal
855              };
856         print $walkHandle fmt_line($synth, $op, $gotofmt, $level+1);
857     }
858     $lastnext = $op->next;
859     print $walkHandle concise_op($op, $level, $format);
860 }
861
862 # B::OP::terse (see Terse.pm) now just calls this
863 sub b_terse {
864     my($op, $level) = @_;
865
866     # This isn't necessarily right, but there's no easy way to get
867     # from an OP to the right CV. This is a limitation of the
868     # ->terse() interface style, and there isn't much to do about
869     # it. In particular, we can die in concise_op if the main pad
870     # isn't long enough, or has the wrong kind of entries, compared to
871     # the pad a sub was compiled with. The fix for that would be to
872     # make a backwards compatible "terse" format that never even
873     # looked at the pad, just like the old B::Terse. I don't think
874     # that's worth the effort, though.
875     $curcv = main_cv unless $curcv;
876
877     if ($order eq "exec" and $lastnext and $$lastnext != $$op) {
878         # insert a 'goto'
879         my $h = {"seq" => seq($lastnext), "class" => class($lastnext),
880                  "addr" => sprintf("%#x", $$lastnext)};
881         print # $walkHandle
882             fmt_line($h, $op, $style{"terse"}[1], $level+1);
883     }
884     $lastnext = $op->next;
885     print # $walkHandle 
886         concise_op($op, $level, $style{"terse"}[0]);
887 }
888
889 sub tree {
890     my $op = shift;
891     my $level = shift;
892     my $style = $tree_decorations[$tree_style];
893     my($space, $single, $kids, $kid, $nokid, $last, $lead, $size) = @$style;
894     my $name = concise_op($op, $level, $treefmt);
895     if (not $op->flags & OPf_KIDS) {
896         return $name . "\n";
897     }
898     my @lines;
899     for (my $kid = $op->first; $$kid; $kid = $kid->sibling) {
900         push @lines, tree($kid, $level+1);
901     }
902     my $i;
903     for ($i = $#lines; substr($lines[$i], 0, 1) eq " "; $i--) {
904         $lines[$i] = $space . $lines[$i];
905     }
906     if ($i > 0) {
907         $lines[$i] = $last . $lines[$i];
908         while ($i-- > 1) {
909             if (substr($lines[$i], 0, 1) eq " ") {
910                 $lines[$i] = $nokid . $lines[$i];
911             } else {
912                 $lines[$i] = $kid . $lines[$i];
913             }
914         }
915         $lines[$i] = $kids . $lines[$i];
916     } else {
917         $lines[0] = $single . $lines[0];
918     }
919     return("$name$lead" . shift @lines,
920            map(" " x (length($name)+$size) . $_, @lines));
921 }
922
923 # *** Warning: fragile kludge ahead ***
924 # Because the B::* modules run in the same interpreter as the code
925 # they're compiling, their presence tends to distort the view we have of
926 # the code we're looking at. In particular, perl gives sequence numbers
927 # to COPs. If the program we're looking at were run on its own, this
928 # would start at 1. Because all of B::Concise and all the modules it
929 # uses are compiled first, though, by the time we get to the user's
930 # program the sequence number is already pretty high, which could be
931 # distracting if you're trying to tell OPs apart. Therefore we'd like to
932 # subtract an offset from all the sequence numbers we display, to
933 # restore the simpler view of the world. The trick is to know what that
934 # offset will be, when we're still compiling B::Concise!  If we
935 # hardcoded a value, it would have to change every time B::Concise or
936 # other modules we use do. To help a little, what we do here is compile
937 # a little code at the end of the module, and compute the base sequence
938 # number for the user's program as being a small offset later, so all we
939 # have to worry about are changes in the offset.
940
941 # [For 5.8.x and earlier perl is generating sequence numbers for all ops,
942 #  and using them to reference labels]
943
944
945 # When you say "perl -MO=Concise -e '$a'", the output should look like:
946
947 # 4  <@> leave[t1] vKP/REFC ->(end)
948 # 1     <0> enter ->2
949  #^ smallest OP sequence number should be 1
950 # 2     <;> nextstate(main 1 -e:1) v ->3
951  #                         ^ smallest COP sequence number should be 1
952 # -     <1> ex-rv2sv vK/1 ->4
953 # 3        <$> gvsv(*a) s ->4
954
955 # If the second of the marked numbers there isn't 1, it means you need
956 # to update the corresponding magic number in the next line.
957 # Remember, this needs to stay the last things in the module.
958
959 # Why is this different for MacOS?  Does it matter?
960 my $cop_seq_mnum = $^O eq 'MacOS' ? 12 : 11;
961 $cop_seq_base = svref_2object(eval 'sub{0;}')->START->cop_seq + $cop_seq_mnum;
962
963 1;
964
965 __END__
966
967 =head1 NAME
968
969 B::Concise - Walk Perl syntax tree, printing concise info about ops
970
971 =head1 SYNOPSIS
972
973     perl -MO=Concise[,OPTIONS] foo.pl
974
975     use B::Concise qw(set_style add_callback);
976
977 =head1 DESCRIPTION
978
979 This compiler backend prints the internal OPs of a Perl program's syntax
980 tree in one of several space-efficient text formats suitable for debugging
981 the inner workings of perl or other compiler backends. It can print OPs in
982 the order they appear in the OP tree, in the order they will execute, or
983 in a text approximation to their tree structure, and the format of the
984 information displayed is customizable. Its function is similar to that of
985 perl's B<-Dx> debugging flag or the B<B::Terse> module, but it is more
986 sophisticated and flexible.
987
988 =head1 EXAMPLE
989
990 Here's two outputs (or 'renderings'), using the -exec and -basic
991 (i.e. default) formatting conventions on the same code snippet.
992
993     % perl -MO=Concise,-exec -e '$a = $b + 42'
994     1  <0> enter
995     2  <;> nextstate(main 1 -e:1) v
996     3  <#> gvsv[*b] s
997     4  <$> const[IV 42] s
998  *  5  <2> add[t3] sK/2
999     6  <#> gvsv[*a] s
1000     7  <2> sassign vKS/2
1001     8  <@> leave[1 ref] vKP/REFC
1002
1003 In this -exec rendering, each opcode is executed in the order shown.
1004 The add opcode, marked with '*', is discussed in more detail.
1005
1006 The 1st column is the op's sequence number, starting at 1, and is
1007 displayed in base 36 by default.  Here they're purely linear; the
1008 sequences are very helpful when looking at code with loops and
1009 branches.
1010
1011 The symbol between angle brackets indicates the op's type, for
1012 example; <2> is a BINOP, <@> a LISTOP, and <#> is a PADOP, which is
1013 used in threaded perls. (see L</"OP class abbreviations">).
1014
1015 The opname, as in B<'add[t1]'>, may be followed by op-specific
1016 information in parentheses or brackets (ex B<'[t1]'>).
1017
1018 The op-flags (ex B<'sK/2'>) are described in (L</"OP flags
1019 abbreviations">).
1020
1021     % perl -MO=Concise -e '$a = $b + 42'
1022     8  <@> leave[1 ref] vKP/REFC ->(end)
1023     1     <0> enter ->2
1024     2     <;> nextstate(main 1 -e:1) v ->3
1025     7     <2> sassign vKS/2 ->8
1026  *  5        <2> add[t1] sK/2 ->6
1027     -           <1> ex-rv2sv sK/1 ->4
1028     3              <$> gvsv(*b) s ->4
1029     4           <$> const(IV 42) s ->5
1030     -        <1> ex-rv2sv sKRM*/1 ->7
1031     6           <$> gvsv(*a) s ->7
1032
1033 The default rendering is top-down, so they're not in execution order.
1034 This form reflects the way the stack is used to parse and evaluate
1035 expressions; the add operates on the two terms below it in the tree.
1036
1037 Nullops appear as C<ex-opname>, where I<opname> is an op that has been
1038 optimized away by perl.  They're displayed with a sequence-number of
1039 '-', because they are not executed (they don't appear in previous
1040 example), they're printed here because they reflect the parse.
1041
1042 The arrow points to the sequence number of the next op; they're not
1043 displayed in -exec mode, for obvious reasons.
1044
1045 Note that because this rendering was done on a non-threaded perl, the
1046 PADOPs in the previous examples are now SVOPs, and some (but not all)
1047 of the square brackets have been replaced by round ones.  This is a
1048 subtle feature to provide some visual distinction between renderings
1049 on threaded and un-threaded perls.
1050
1051
1052 =head1 OPTIONS
1053
1054 Arguments that don't start with a hyphen are taken to be the names of
1055 subroutines to print the OPs of; if no such functions are specified,
1056 the main body of the program (outside any subroutines, and not
1057 including use'd or require'd files) is rendered.  Passing C<BEGIN>,
1058 C<UNITCHECK>, C<CHECK>, C<INIT>, or C<END> will cause all of the
1059 corresponding special blocks to be printed.
1060
1061 Options affect how things are rendered (ie printed).  They're presented
1062 here by their visual effect, 1st being strongest.  They're grouped
1063 according to how they interrelate; within each group the options are
1064 mutually exclusive (unless otherwise stated).
1065
1066 =head2 Options for Opcode Ordering
1067
1068 These options control the 'vertical display' of opcodes.  The display
1069 'order' is also called 'mode' elsewhere in this document.
1070
1071 =over 4
1072
1073 =item B<-basic>
1074
1075 Print OPs in the order they appear in the OP tree (a preorder
1076 traversal, starting at the root). The indentation of each OP shows its
1077 level in the tree, and the '->' at the end of the line indicates the
1078 next opcode in execution order.  This mode is the default, so the flag
1079 is included simply for completeness.
1080
1081 =item B<-exec>
1082
1083 Print OPs in the order they would normally execute (for the majority
1084 of constructs this is a postorder traversal of the tree, ending at the
1085 root). In most cases the OP that usually follows a given OP will
1086 appear directly below it; alternate paths are shown by indentation. In
1087 cases like loops when control jumps out of a linear path, a 'goto'
1088 line is generated.
1089
1090 =item B<-tree>
1091
1092 Print OPs in a text approximation of a tree, with the root of the tree
1093 at the left and 'left-to-right' order of children transformed into
1094 'top-to-bottom'. Because this mode grows both to the right and down,
1095 it isn't suitable for large programs (unless you have a very wide
1096 terminal).
1097
1098 =back
1099
1100 =head2 Options for Line-Style
1101
1102 These options select the line-style (or just style) used to render
1103 each opcode, and dictates what info is actually printed into each line.
1104
1105 =over 4
1106
1107 =item B<-concise>
1108
1109 Use the author's favorite set of formatting conventions. This is the
1110 default, of course.
1111
1112 =item B<-terse>
1113
1114 Use formatting conventions that emulate the output of B<B::Terse>. The
1115 basic mode is almost indistinguishable from the real B<B::Terse>, and the
1116 exec mode looks very similar, but is in a more logical order and lacks
1117 curly brackets. B<B::Terse> doesn't have a tree mode, so the tree mode
1118 is only vaguely reminiscent of B<B::Terse>.
1119
1120 =item B<-linenoise>
1121
1122 Use formatting conventions in which the name of each OP, rather than being
1123 written out in full, is represented by a one- or two-character abbreviation.
1124 This is mainly a joke.
1125
1126 =item B<-debug>
1127
1128 Use formatting conventions reminiscent of B<B::Debug>; these aren't
1129 very concise at all.
1130
1131 =item B<-env>
1132
1133 Use formatting conventions read from the environment variables
1134 C<B_CONCISE_FORMAT>, C<B_CONCISE_GOTO_FORMAT>, and C<B_CONCISE_TREE_FORMAT>.
1135
1136 =back
1137
1138 =head2 Options for tree-specific formatting
1139
1140 =over 4
1141
1142 =item B<-compact>
1143
1144 Use a tree format in which the minimum amount of space is used for the
1145 lines connecting nodes (one character in most cases). This squeezes out
1146 a few precious columns of screen real estate.
1147
1148 =item B<-loose>
1149
1150 Use a tree format that uses longer edges to separate OP nodes. This format
1151 tends to look better than the compact one, especially in ASCII, and is
1152 the default.
1153
1154 =item B<-vt>
1155
1156 Use tree connecting characters drawn from the VT100 line-drawing set.
1157 This looks better if your terminal supports it.
1158
1159 =item B<-ascii>
1160
1161 Draw the tree with standard ASCII characters like C<+> and C<|>. These don't
1162 look as clean as the VT100 characters, but they'll work with almost any
1163 terminal (or the horizontal scrolling mode of less(1)) and are suitable
1164 for text documentation or email. This is the default.
1165
1166 =back
1167
1168 These are pairwise exclusive, i.e. compact or loose, vt or ascii.
1169
1170 =head2 Options controlling sequence numbering
1171
1172 =over 4
1173
1174 =item B<-base>I<n>
1175
1176 Print OP sequence numbers in base I<n>. If I<n> is greater than 10, the
1177 digit for 11 will be 'a', and so on. If I<n> is greater than 36, the digit
1178 for 37 will be 'A', and so on until 62. Values greater than 62 are not
1179 currently supported. The default is 36.
1180
1181 =item B<-bigendian>
1182
1183 Print sequence numbers with the most significant digit first. This is the
1184 usual convention for Arabic numerals, and the default.
1185
1186 =item B<-littleendian>
1187
1188 Print seqence numbers with the least significant digit first.  This is
1189 obviously mutually exclusive with bigendian.
1190
1191 =back
1192
1193 =head2 Other options
1194
1195 These are pairwise exclusive.
1196
1197 =over 4
1198
1199 =item B<-main>
1200
1201 Include the main program in the output, even if subroutines were also
1202 specified.  This rendering is normally suppressed when a subroutine
1203 name or reference is given.
1204
1205 =item B<-nomain>
1206
1207 This restores the default behavior after you've changed it with '-main'
1208 (it's not normally needed).  If no subroutine name/ref is given, main is
1209 rendered, regardless of this flag.
1210
1211 =item B<-nobanner>
1212
1213 Renderings usually include a banner line identifying the function name
1214 or stringified subref.  This suppresses the printing of the banner.
1215
1216 TBC: Remove the stringified coderef; while it provides a 'cookie' for
1217 each function rendered, the cookies used should be 1,2,3.. not a
1218 random hex-address.  It also complicates string comparison of two
1219 different trees.
1220
1221 =item B<-banner>
1222
1223 restores default banner behavior.
1224
1225 =item B<-banneris> => subref
1226
1227 TBC: a hookpoint (and an option to set it) for a user-supplied
1228 function to produce a banner appropriate for users needs.  It's not
1229 ideal, because the rendering-state variables, which are a natural
1230 candidate for use in concise.t, are unavailable to the user.
1231
1232 =back
1233
1234 =head2 Option Stickiness
1235
1236 If you invoke Concise more than once in a program, you should know that
1237 the options are 'sticky'.  This means that the options you provide in
1238 the first call will be remembered for the 2nd call, unless you
1239 re-specify or change them.
1240
1241 =head1 ABBREVIATIONS
1242
1243 The concise style uses symbols to convey maximum info with minimal
1244 clutter (like hex addresses).  With just a little practice, you can
1245 start to see the flowers, not just the branches, in the trees.
1246
1247 =head2 OP class abbreviations
1248
1249 These symbols appear before the op-name, and indicate the
1250 B:: namespace that represents the ops in your Perl code.
1251
1252     0      OP (aka BASEOP)  An OP with no children
1253     1      UNOP             An OP with one child
1254     2      BINOP            An OP with two children
1255     |      LOGOP            A control branch OP
1256     @      LISTOP           An OP that could have lots of children
1257     /      PMOP             An OP with a regular expression
1258     $      SVOP             An OP with an SV
1259     "      PVOP             An OP with a string
1260     {      LOOP             An OP that holds pointers for a loop
1261     ;      COP              An OP that marks the start of a statement
1262     #      PADOP            An OP with a GV on the pad
1263
1264 =head2 OP flags abbreviations
1265
1266 OP flags are either public or private.  The public flags alter the
1267 behavior of each opcode in consistent ways, and are represented by 0
1268 or more single characters.
1269
1270     v      OPf_WANT_VOID    Want nothing (void context)
1271     s      OPf_WANT_SCALAR  Want single value (scalar context)
1272     l      OPf_WANT_LIST    Want list of any length (list context)
1273                             Want is unknown
1274     K      OPf_KIDS         There is a firstborn child.
1275     P      OPf_PARENS       This operator was parenthesized.
1276                              (Or block needs explicit scope entry.)
1277     R      OPf_REF          Certified reference.
1278                              (Return container, not containee).
1279     M      OPf_MOD          Will modify (lvalue).
1280     S      OPf_STACKED      Some arg is arriving on the stack.
1281     *      OPf_SPECIAL      Do something weird for this op (see op.h)
1282
1283 Private flags, if any are set for an opcode, are displayed after a '/'
1284
1285     8  <@> leave[1 ref] vKP/REFC ->(end)
1286     7     <2> sassign vKS/2 ->8
1287
1288 They're opcode specific, and occur less often than the public ones, so
1289 they're represented by short mnemonics instead of single-chars; see
1290 F<op.h> for gory details, or try this quick 2-liner:
1291
1292   $> perl -MB::Concise -de 1
1293   DB<1> |x \%B::Concise::priv
1294
1295 =head1 FORMATTING SPECIFICATIONS
1296
1297 For each line-style ('concise', 'terse', 'linenoise', etc.) there are
1298 3 format-specs which control how OPs are rendered.
1299
1300 The first is the 'default' format, which is used in both basic and exec
1301 modes to print all opcodes.  The 2nd, goto-format, is used in exec
1302 mode when branches are encountered.  They're not real opcodes, and are
1303 inserted to look like a closing curly brace.  The tree-format is tree
1304 specific.
1305
1306 When a line is rendered, the correct format-spec is copied and scanned
1307 for the following items; data is substituted in, and other
1308 manipulations like basic indenting are done, for each opcode rendered.
1309
1310 There are 3 kinds of items that may be populated; special patterns,
1311 #vars, and literal text, which is copied verbatim.  (Yes, it's a set
1312 of s///g steps.)
1313
1314 =head2 Special Patterns
1315
1316 These items are the primitives used to perform indenting, and to
1317 select text from amongst alternatives.
1318
1319 =over 4
1320
1321 =item B<(x(>I<exec_text>B<;>I<basic_text>B<)x)>
1322
1323 Generates I<exec_text> in exec mode, or I<basic_text> in basic mode.
1324
1325 =item B<(*(>I<text>B<)*)>
1326
1327 Generates one copy of I<text> for each indentation level.
1328
1329 =item B<(*(>I<text1>B<;>I<text2>B<)*)>
1330
1331 Generates one fewer copies of I<text1> than the indentation level, followed
1332 by one copy of I<text2> if the indentation level is more than 0.
1333
1334 =item B<(?(>I<text1>B<#>I<var>I<Text2>B<)?)>
1335
1336 If the value of I<var> is true (not empty or zero), generates the
1337 value of I<var> surrounded by I<text1> and I<Text2>, otherwise
1338 nothing.
1339
1340 =item B<~>
1341
1342 Any number of tildes and surrounding whitespace will be collapsed to
1343 a single space.
1344
1345 =back
1346
1347 =head2 # Variables
1348
1349 These #vars represent opcode properties that you may want as part of
1350 your rendering.  The '#' is intended as a private sigil; a #var's
1351 value is interpolated into the style-line, much like "read $this".
1352
1353 These vars take 3 forms:
1354
1355 =over 4
1356
1357 =item B<#>I<var>
1358
1359 A property named 'var' is assumed to exist for the opcodes, and is
1360 interpolated into the rendering.
1361
1362 =item B<#>I<var>I<N>
1363
1364 Generates the value of I<var>, left justified to fill I<N> spaces.
1365 Note that this means while you can have properties 'foo' and 'foo2',
1366 you cannot render 'foo2', but you could with 'foo2a'.  You would be
1367 wise not to rely on this behavior going forward ;-)
1368
1369 =item B<#>I<Var>
1370
1371 This ucfirst form of #var generates a tag-value form of itself for
1372 display; it converts '#Var' into a 'Var => #var' style, which is then
1373 handled as described above.  (Imp-note: #Vars cannot be used for
1374 conditional-fills, because the => #var transform is done after the check
1375 for #Var's value).
1376
1377 =back
1378
1379 The following variables are 'defined' by B::Concise; when they are
1380 used in a style, their respective values are plugged into the
1381 rendering of each opcode.
1382
1383 Only some of these are used by the standard styles, the others are
1384 provided for you to delve into optree mechanics, should you wish to
1385 add a new style (see L</add_style> below) that uses them.  You can
1386 also add new ones using L</add_callback>.
1387
1388 =over 4
1389
1390 =item B<#addr>
1391
1392 The address of the OP, in hexadecimal.
1393
1394 =item B<#arg>
1395
1396 The OP-specific information of the OP (such as the SV for an SVOP, the
1397 non-local exit pointers for a LOOP, etc.) enclosed in parentheses.
1398
1399 =item B<#class>
1400
1401 The B-determined class of the OP, in all caps.
1402
1403 =item B<#classsym>
1404
1405 A single symbol abbreviating the class of the OP.
1406
1407 =item B<#coplabel>
1408
1409 The label of the statement or block the OP is the start of, if any.
1410
1411 =item B<#exname>
1412
1413 The name of the OP, or 'ex-foo' if the OP is a null that used to be a foo.
1414
1415 =item B<#extarg>
1416
1417 The target of the OP, or nothing for a nulled OP.
1418
1419 =item B<#firstaddr>
1420
1421 The address of the OP's first child, in hexadecimal.
1422
1423 =item B<#flags>
1424
1425 The OP's flags, abbreviated as a series of symbols.
1426
1427 =item B<#flagval>
1428
1429 The numeric value of the OP's flags.
1430
1431 =item B<#hints>
1432
1433 The COP's hint flags, rendered with abbreviated names if possible. An empty
1434 string if this is not a COP.
1435
1436 =item B<#hintsval>
1437
1438 The numeric value of the COP's hint flags, or an empty string if this is not
1439 a COP.
1440
1441 =item B<#hyphseq>
1442
1443 The sequence number of the OP, or a hyphen if it doesn't have one.
1444
1445 =item B<#label>
1446
1447 'NEXT', 'LAST', or 'REDO' if the OP is a target of one of those in exec
1448 mode, or empty otherwise.
1449
1450 =item B<#lastaddr>
1451
1452 The address of the OP's last child, in hexadecimal.
1453
1454 =item B<#name>
1455
1456 The OP's name.
1457
1458 =item B<#NAME>
1459
1460 The OP's name, in all caps.
1461
1462 =item B<#next>
1463
1464 The sequence number of the OP's next OP.
1465
1466 =item B<#nextaddr>
1467
1468 The address of the OP's next OP, in hexadecimal.
1469
1470 =item B<#noise>
1471
1472 A one- or two-character abbreviation for the OP's name.
1473
1474 =item B<#private>
1475
1476 The OP's private flags, rendered with abbreviated names if possible.
1477
1478 =item B<#privval>
1479
1480 The numeric value of the OP's private flags.
1481
1482 =item B<#seq>
1483
1484 The sequence number of the OP. Note that this is a sequence number
1485 generated by B::Concise.
1486
1487 =item B<#seqnum>
1488
1489 5.8.x and earlier only. 5.9 and later do not provide this.
1490
1491 The real sequence number of the OP, as a regular number and not adjusted
1492 to be relative to the start of the real program. (This will generally be
1493 a fairly large number because all of B<B::Concise> is compiled before
1494 your program is).
1495
1496 =item B<#opt>
1497
1498 Whether or not the op has been optimised by the peephole optimiser.
1499
1500 Only available in 5.9 and later.
1501
1502 =item B<#static>
1503
1504 Whether or not the op is statically defined.  This flag is used by the
1505 B::C compiler backend and indicates that the op should not be freed.
1506
1507 Only available in 5.9 and later.
1508
1509 =item B<#sibaddr>
1510
1511 The address of the OP's next youngest sibling, in hexadecimal.
1512
1513 =item B<#svaddr>
1514
1515 The address of the OP's SV, if it has an SV, in hexadecimal.
1516
1517 =item B<#svclass>
1518
1519 The class of the OP's SV, if it has one, in all caps (e.g., 'IV').
1520
1521 =item B<#svval>
1522
1523 The value of the OP's SV, if it has one, in a short human-readable format.
1524
1525 =item B<#targ>
1526
1527 The numeric value of the OP's targ.
1528
1529 =item B<#targarg>
1530
1531 The name of the variable the OP's targ refers to, if any, otherwise the
1532 letter t followed by the OP's targ in decimal.
1533
1534 =item B<#targarglife>
1535
1536 Same as B<#targarg>, but followed by the COP sequence numbers that delimit
1537 the variable's lifetime (or 'end' for a variable in an open scope) for a
1538 variable.
1539
1540 =item B<#typenum>
1541
1542 The numeric value of the OP's type, in decimal.
1543
1544 =back
1545
1546 =head1 One-Liner Command tips
1547
1548 =over 4
1549
1550 =item perl -MO=Concise,bar foo.pl
1551
1552 Renders only bar() from foo.pl.  To see main, drop the ',bar'.  To see
1553 both, add ',-main'
1554
1555 =item perl -MDigest::MD5=md5 -MO=Concise,md5 -e1
1556
1557 Identifies md5 as an XS function.  The export is needed so that BC can
1558 find it in main.
1559
1560 =item perl -MPOSIX -MO=Concise,_POSIX_ARG_MAX -e1
1561
1562 Identifies _POSIX_ARG_MAX as a constant sub, optimized to an IV.
1563 Although POSIX isn't entirely consistent across platforms, this is
1564 likely to be present in virtually all of them.
1565
1566 =item perl -MPOSIX -MO=Concise,a -e 'print _POSIX_SAVED_IDS'
1567
1568 This renders a print statement, which includes a call to the function.
1569 It's identical to rendering a file with a use call and that single
1570 statement, except for the filename which appears in the nextstate ops.
1571
1572 =item perl -MPOSIX -MO=Concise,a -e 'sub a{_POSIX_SAVED_IDS}'
1573
1574 This is B<very> similar to previous, only the first two ops differ.  This
1575 subroutine rendering is more representative, insofar as a single main
1576 program will have many subs.
1577
1578
1579
1580 =head1 Using B::Concise outside of the O framework
1581
1582 The common (and original) usage of B::Concise was for command-line
1583 renderings of simple code, as given in EXAMPLE.  But you can also use
1584 B<B::Concise> from your code, and call compile() directly, and
1585 repeatedly.  By doing so, you can avoid the compile-time only
1586 operation of O.pm, and even use the debugger to step through
1587 B::Concise::compile() itself.
1588
1589 Once you're doing this, you may alter Concise output by adding new
1590 rendering styles, and by optionally adding callback routines which
1591 populate new variables, if such were referenced from those (just
1592 added) styles.  
1593
1594 =head2 Example: Altering Concise Renderings
1595
1596     use B::Concise qw(set_style add_callback);
1597     add_style($yourStyleName => $defaultfmt, $gotofmt, $treefmt);
1598     add_callback
1599       ( sub {
1600             my ($h, $op, $format, $level, $stylename) = @_;
1601             $h->{variable} = some_func($op);
1602         });
1603     $walker = B::Concise::compile(@options,@subnames,@subrefs);
1604     $walker->();
1605
1606 =head2 set_style()
1607
1608 B<set_style> accepts 3 arguments, and updates the three format-specs
1609 comprising a line-style (basic-exec, goto, tree).  It has one minor
1610 drawback though; it doesn't register the style under a new name.  This
1611 can become an issue if you render more than once and switch styles.
1612 Thus you may prefer to use add_style() and/or set_style_standard()
1613 instead.
1614
1615 =head2 set_style_standard($name)
1616
1617 This restores one of the standard line-styles: C<terse>, C<concise>,
1618 C<linenoise>, C<debug>, C<env>, into effect.  It also accepts style
1619 names previously defined with add_style().
1620
1621 =head2 add_style()
1622
1623 This subroutine accepts a new style name and three style arguments as
1624 above, and creates, registers, and selects the newly named style.  It is
1625 an error to re-add a style; call set_style_standard() to switch between
1626 several styles.
1627
1628 =head2 add_callback()
1629
1630 If your newly minted styles refer to any new #variables, you'll need
1631 to define a callback subroutine that will populate (or modify) those
1632 variables.  They are then available for use in the style you've
1633 chosen.
1634
1635 The callbacks are called for each opcode visited by Concise, in the
1636 same order as they are added.  Each subroutine is passed five
1637 parameters.
1638
1639   1. A hashref, containing the variable names and values which are
1640      populated into the report-line for the op
1641   2. the op, as a B<B::OP> object
1642   3. a reference to the format string
1643   4. the formatting (indent) level
1644   5. the selected stylename
1645
1646 To define your own variables, simply add them to the hash, or change
1647 existing values if you need to.  The level and format are passed in as
1648 references to scalars, but it is unlikely that they will need to be
1649 changed or even used.
1650
1651 =head2 Running B::Concise::compile()
1652
1653 B<compile> accepts options as described above in L</OPTIONS>, and
1654 arguments, which are either coderefs, or subroutine names.
1655
1656 It constructs and returns a $treewalker coderef, which when invoked,
1657 traverses, or walks, and renders the optrees of the given arguments to
1658 STDOUT.  You can reuse this, and can change the rendering style used
1659 each time; thereafter the coderef renders in the new style.
1660
1661 B<walk_output> lets you change the print destination from STDOUT to
1662 another open filehandle, or into a string passed as a ref (unless
1663 you've built perl with -Uuseperlio).
1664
1665     my $walker = B::Concise::compile('-terse','aFuncName', \&aSubRef);  # 1
1666     walk_output(\my $buf);
1667     $walker->();                        # 1 renders -terse
1668     set_style_standard('concise');      # 2
1669     $walker->();                        # 2 renders -concise
1670     $walker->(@new);                    # 3 renders whatever
1671     print "3 different renderings: terse, concise, and @new: $buf\n";
1672
1673 When $walker is called, it traverses the subroutines supplied when it
1674 was created, and renders them using the current style.  You can change
1675 the style afterwards in several different ways:
1676
1677   1. call C<compile>, altering style or mode/order
1678   2. call C<set_style_standard>
1679   3. call $walker, passing @new options
1680
1681 Passing new options to the $walker is the easiest way to change
1682 amongst any pre-defined styles (the ones you add are automatically
1683 recognized as options), and is the only way to alter rendering order
1684 without calling compile again.  Note however that rendering state is
1685 still shared amongst multiple $walker objects, so they must still be
1686 used in a coordinated manner.
1687
1688 =head2 B::Concise::reset_sequence()
1689
1690 This function (not exported) lets you reset the sequence numbers (note
1691 that they're numbered arbitrarily, their goal being to be human
1692 readable).  Its purpose is mostly to support testing, i.e. to compare
1693 the concise output from two identical anonymous subroutines (but
1694 different instances).  Without the reset, B::Concise, seeing that
1695 they're separate optrees, generates different sequence numbers in
1696 the output.
1697
1698 =head2 Errors
1699
1700 Errors in rendering (non-existent function-name, non-existent coderef)
1701 are written to the STDOUT, or wherever you've set it via
1702 walk_output().
1703
1704 Errors using the various *style* calls, and bad args to walk_output(),
1705 result in die().  Use an eval if you wish to catch these errors and
1706 continue processing.
1707
1708 =head1 AUTHOR
1709
1710 Stephen McCamant, E<lt>smcc@CSUA.Berkeley.EDUE<gt>.
1711
1712 =cut