This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
6703c6d6f6c9102182350b99c50abd2e160fcf94
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, the scalar arguments will
18 be first, and the list argument will follow.  (Note that there can ever
19 be only one such list argument.)  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for the elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use the parentheses, the simple (but occasionally
34 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  And whitespace
37 between the function and left parenthesis doesn't count--so you need to
38 be careful sometimes:
39
40     print 1+2+4;        # Prints 7.
41     print(1+2) + 4;     # Prints 3.
42     print (1+2)+4;      # Also prints 3!
43     print +(1+2)+4;     # Prints 7.
44     print ((1+2)+4);    # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 null list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value it would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 =head2 Perl Functions by Category
90 X<function>
91
92 Here are Perl's functions (including things that look like
93 functions, like some keywords and named operators)
94 arranged by category.  Some functions appear in more
95 than one place.
96
97 =over 4
98
99 =item Functions for SCALARs or strings
100 X<scalar> X<string> X<character>
101
102 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
103 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
104 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
105
106 =item Regular expressions and pattern matching
107 X<regular expression> X<regex> X<regexp>
108
109 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
110
111 =item Numeric functions
112 X<numeric> X<number> X<trigonometric> X<trigonometry>
113
114 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
115 C<sin>, C<sqrt>, C<srand>
116
117 =item Functions for real @ARRAYs
118 X<array>
119
120 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
121
122 =item Functions for list data
123 X<list>
124
125 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
126
127 =item Functions for real %HASHes
128 X<hash>
129
130 C<delete>, C<each>, C<exists>, C<keys>, C<values>
131
132 =item Input and output functions
133 X<I/O> X<input> X<output> X<dbm>
134
135 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
136 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
137 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
138 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
139 C<warn>, C<write>
140
141 =item Functions for fixed length data or records
142
143 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
144
145 =item Functions for filehandles, files, or directories
146 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
147
148 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
149 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
150 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
151 C<umask>, C<unlink>, C<utime>
152
153 =item Keywords related to the control flow of your Perl program
154 X<control flow>
155
156 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
157 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
158
159 =item Keywords related to switch
160
161 C<break>, C<continue>, C<given>, C<when>, C<default>
162
163 (These are only available if you enable the "switch" feature.
164 See L<feature> and L<perlsyn/"Switch statements">.)
165
166 =item Keywords related to scoping
167
168 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
169 C<use>
170
171 (C<state> is only available if the "state" feature is enabled. See
172 L<feature>.)
173
174 =item Miscellaneous functions
175
176 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
177 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
178
179 =item Functions for processes and process groups
180 X<process> X<pid> X<process id>
181
182 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
183 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
184 C<times>, C<wait>, C<waitpid>
185
186 =item Keywords related to perl modules
187 X<module>
188
189 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
190
191 =item Keywords related to classes and object-orientedness
192 X<object> X<class> X<package>
193
194 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
195 C<untie>, C<use>
196
197 =item Low-level socket functions
198 X<socket> X<sock>
199
200 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
201 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
202 C<socket>, C<socketpair>
203
204 =item System V interprocess communication functions
205 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
206
207 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
208 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
209
210 =item Fetching user and group info
211 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
212
213 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
214 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
215 C<getpwuid>, C<setgrent>, C<setpwent>
216
217 =item Fetching network info
218 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
219
220 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
221 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
222 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
223 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
224 C<setnetent>, C<setprotoent>, C<setservent>
225
226 =item Time-related functions
227 X<time> X<date>
228
229 C<gmtime>, C<localtime>, C<time>, C<times>
230
231 =item Functions new in perl5
232 X<perl5>
233
234 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
235 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
236 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr>, C<qw>, C<qx>,
237 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
238 C<ucfirst>, C<untie>, C<use>, C<when>
239
240 * - C<sub> was a keyword in perl4, but in perl5 it is an
241 operator, which can be used in expressions.
242
243 =item Functions obsoleted in perl5
244
245 C<dbmclose>, C<dbmopen>
246
247 =back
248
249 =head2 Portability
250 X<portability> X<Unix> X<portable>
251
252 Perl was born in Unix and can therefore access all common Unix
253 system calls.  In non-Unix environments, the functionality of some
254 Unix system calls may not be available, or details of the available
255 functionality may differ slightly.  The Perl functions affected
256 by this are:
257
258 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
259 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
260 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
261 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
262 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
263 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
264 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
265 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
266 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
267 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
268 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
269 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
270 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
271 C<shmwrite>, C<socket>, C<socketpair>,
272 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
273 C<times>, C<truncate>, C<umask>, C<unlink>,
274 C<utime>, C<wait>, C<waitpid>
275
276 For more information about the portability of these functions, see
277 L<perlport> and other available platform-specific documentation.
278
279 =head2 Alphabetical Listing of Perl Functions
280
281 =over 8
282
283 =item -X FILEHANDLE
284 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
285 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
286
287 =item -X EXPR
288
289 =item -X DIRHANDLE
290
291 =item -X
292
293 A file test, where X is one of the letters listed below.  This unary
294 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
295 and tests the associated file to see if something is true about it.  If the
296 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
297 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
298 the undefined value if the file doesn't exist.  Despite the funny
299 names, precedence is the same as any other named unary operator, and
300 the argument may be parenthesized like any other unary operator.  The
301 operator may be any of:
302
303     -r  File is readable by effective uid/gid.
304     -w  File is writable by effective uid/gid.
305     -x  File is executable by effective uid/gid.
306     -o  File is owned by effective uid.
307
308     -R  File is readable by real uid/gid.
309     -W  File is writable by real uid/gid.
310     -X  File is executable by real uid/gid.
311     -O  File is owned by real uid.
312
313     -e  File exists.
314     -z  File has zero size (is empty).
315     -s  File has nonzero size (returns size in bytes).
316
317     -f  File is a plain file.
318     -d  File is a directory.
319     -l  File is a symbolic link.
320     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
321     -S  File is a socket.
322     -b  File is a block special file.
323     -c  File is a character special file.
324     -t  Filehandle is opened to a tty.
325
326     -u  File has setuid bit set.
327     -g  File has setgid bit set.
328     -k  File has sticky bit set.
329
330     -T  File is an ASCII text file (heuristic guess).
331     -B  File is a "binary" file (opposite of -T).
332
333     -M  Script start time minus file modification time, in days.
334     -A  Same for access time.
335     -C  Same for inode change time (Unix, may differ for other platforms)
336
337 Example:
338
339     while (<>) {
340         chomp;
341         next unless -f $_;      # ignore specials
342         #...
343     }
344
345 The interpretation of the file permission operators C<-r>, C<-R>,
346 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
347 of the file and the uids and gids of the user.  There may be other
348 reasons you can't actually read, write, or execute the file.  Such
349 reasons may be for example network filesystem access controls, ACLs
350 (access control lists), read-only filesystems, and unrecognized
351 executable formats.
352
353 Also note that, for the superuser on the local filesystems, the C<-r>,
354 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
355 if any execute bit is set in the mode.  Scripts run by the superuser
356 may thus need to do a stat() to determine the actual mode of the file,
357 or temporarily set their effective uid to something else.
358
359 If you are using ACLs, there is a pragma called C<filetest> that may
360 produce more accurate results than the bare stat() mode bits.
361 When under the C<use filetest 'access'> the above-mentioned filetests
362 will test whether the permission can (not) be granted using the
363 access() family of system calls.  Also note that the C<-x> and C<-X> may
364 under this pragma return true even if there are no execute permission
365 bits set (nor any extra execute permission ACLs).  This strangeness is
366 due to the underlying system calls' definitions.  Read the
367 documentation for the C<filetest> pragma for more information.
368
369 Note that C<-s/a/b/> does not do a negated substitution.  Saying
370 C<-exp($foo)> still works as expected, however--only single letters
371 following a minus are interpreted as file tests.
372
373 The C<-T> and C<-B> switches work as follows.  The first block or so of the
374 file is examined for odd characters such as strange control codes or
375 characters with the high bit set.  If too many strange characters (>30%)
376 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
377 containing null in the first block is considered a binary file.  If C<-T>
378 or C<-B> is used on a filehandle, the current IO buffer is examined
379 rather than the first block.  Both C<-T> and C<-B> return true on a null
380 file, or a file at EOF when testing a filehandle.  Because you have to
381 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
382 against the file first, as in C<next unless -f $file && -T $file>.
383
384 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
385 the special filehandle consisting of a solitary underline, then the stat
386 structure of the previous file test (or stat operator) is used, saving
387 a system call.  (This doesn't work with C<-t>, and you need to remember
388 that lstat() and C<-l> will leave values in the stat structure for the
389 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
390 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
391 Example:
392
393     print "Can do.\n" if -r $a || -w _ || -x _;
394
395     stat($filename);
396     print "Readable\n" if -r _;
397     print "Writable\n" if -w _;
398     print "Executable\n" if -x _;
399     print "Setuid\n" if -u _;
400     print "Setgid\n" if -g _;
401     print "Sticky\n" if -k _;
402     print "Text\n" if -T _;
403     print "Binary\n" if -B _;
404
405 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
406 test operators, in a way that C<-f -w -x $file> is equivalent to
407 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
408 the return value of C<-f $file> as an argument to another filetest
409 operator, no special magic will happen.)
410
411 =item abs VALUE
412 X<abs> X<absolute>
413
414 =item abs
415
416 Returns the absolute value of its argument.
417 If VALUE is omitted, uses C<$_>.
418
419 =item accept NEWSOCKET,GENERICSOCKET
420 X<accept>
421
422 Accepts an incoming socket connect, just as the accept(2) system call
423 does.  Returns the packed address if it succeeded, false otherwise.
424 See the example in L<perlipc/"Sockets: Client/Server Communication">.
425
426 On systems that support a close-on-exec flag on files, the flag will
427 be set for the newly opened file descriptor, as determined by the
428 value of $^F.  See L<perlvar/$^F>.
429
430 =item alarm SECONDS
431 X<alarm>
432 X<SIGALRM>
433 X<timer>
434
435 =item alarm
436
437 Arranges to have a SIGALRM delivered to this process after the
438 specified number of wallclock seconds has elapsed.  If SECONDS is not
439 specified, the value stored in C<$_> is used. (On some machines,
440 unfortunately, the elapsed time may be up to one second less or more
441 than you specified because of how seconds are counted, and process
442 scheduling may delay the delivery of the signal even further.)
443
444 Only one timer may be counting at once.  Each call disables the
445 previous timer, and an argument of C<0> may be supplied to cancel the
446 previous timer without starting a new one.  The returned value is the
447 amount of time remaining on the previous timer.
448
449 For delays of finer granularity than one second, you may use Perl's
450 four-argument version of select() leaving the first three arguments
451 undefined, or you might be able to use the C<syscall> interface to
452 access setitimer(2) if your system supports it.  The Time::HiRes
453 module (from CPAN, and starting from Perl 5.8 part of the standard
454 distribution) may also prove useful.
455
456 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
457 (C<sleep> may be internally implemented in your system with C<alarm>)
458
459 If you want to use C<alarm> to time out a system call you need to use an
460 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
461 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
462 restart system calls on some systems.  Using C<eval>/C<die> always works,
463 modulo the caveats given in L<perlipc/"Signals">.
464
465     eval {
466         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
467         alarm $timeout;
468         $nread = sysread SOCKET, $buffer, $size;
469         alarm 0;
470     };
471     if ($@) {
472         die unless $@ eq "alarm\n";   # propagate unexpected errors
473         # timed out
474     }
475     else {
476         # didn't
477     }
478
479 For more information see L<perlipc>.
480
481 =item atan2 Y,X
482 X<atan2> X<arctangent> X<tan> X<tangent>
483
484 Returns the arctangent of Y/X in the range -PI to PI.
485
486 For the tangent operation, you may use the C<Math::Trig::tan>
487 function, or use the familiar relation:
488
489     sub tan { sin($_[0]) / cos($_[0])  }
490
491 Note that atan2(0, 0) is not well-defined.
492
493 =item bind SOCKET,NAME
494 X<bind>
495
496 Binds a network address to a socket, just as the bind system call
497 does.  Returns true if it succeeded, false otherwise.  NAME should be a
498 packed address of the appropriate type for the socket.  See the examples in
499 L<perlipc/"Sockets: Client/Server Communication">.
500
501 =item binmode FILEHANDLE, LAYER
502 X<binmode> X<binary> X<text> X<DOS> X<Windows>
503
504 =item binmode FILEHANDLE
505
506 Arranges for FILEHANDLE to be read or written in "binary" or "text"
507 mode on systems where the run-time libraries distinguish between
508 binary and text files.  If FILEHANDLE is an expression, the value is
509 taken as the name of the filehandle.  Returns true on success,
510 otherwise it returns C<undef> and sets C<$!> (errno).
511
512 On some systems (in general, DOS and Windows-based systems) binmode()
513 is necessary when you're not working with a text file.  For the sake
514 of portability it is a good idea to always use it when appropriate,
515 and to never use it when it isn't appropriate.  Also, people can
516 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
517
518 In other words: regardless of platform, use binmode() on binary data,
519 like for example images.
520
521 If LAYER is present it is a single string, but may contain multiple
522 directives. The directives alter the behaviour of the file handle.
523 When LAYER is present using binmode on text file makes sense.
524
525 If LAYER is omitted or specified as C<:raw> the filehandle is made
526 suitable for passing binary data. This includes turning off possible CRLF
527 translation and marking it as bytes (as opposed to Unicode characters).
528 Note that, despite what may be implied in I<"Programming Perl"> (the
529 Camel) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>
530 -- other layers which would affect the binary nature of the stream are
531 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
532 PERLIO environment variable.
533
534 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
535 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
536 establish default I/O layers.  See L<open>.
537
538 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
539 in "Programming Perl, 3rd Edition".  However, since the publishing of this
540 book, by many known as "Camel III", the consensus of the naming of this
541 functionality has moved from "discipline" to "layer".  All documentation
542 of this version of Perl therefore refers to "layers" rather than to
543 "disciplines".  Now back to the regularly scheduled documentation...>
544
545 To mark FILEHANDLE as UTF-8, use C<:utf8>.
546
547 In general, binmode() should be called after open() but before any I/O
548 is done on the filehandle.  Calling binmode() will normally flush any
549 pending buffered output data (and perhaps pending input data) on the
550 handle.  An exception to this is the C<:encoding> layer that
551 changes the default character encoding of the handle, see L<open>.
552 The C<:encoding> layer sometimes needs to be called in
553 mid-stream, and it doesn't flush the stream.  The C<:encoding>
554 also implicitly pushes on top of itself the C<:utf8> layer because
555 internally Perl will operate on UTF-8 encoded Unicode characters.
556
557 The operating system, device drivers, C libraries, and Perl run-time
558 system all work together to let the programmer treat a single
559 character (C<\n>) as the line terminator, irrespective of the external
560 representation.  On many operating systems, the native text file
561 representation matches the internal representation, but on some
562 platforms the external representation of C<\n> is made up of more than
563 one character.
564
565 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
566 character to end each line in the external representation of text (even
567 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
568 on Unix and most VMS files). In other systems like OS/2, DOS and the
569 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
570 but what's stored in text files are the two characters C<\cM\cJ>.  That
571 means that, if you don't use binmode() on these systems, C<\cM\cJ>
572 sequences on disk will be converted to C<\n> on input, and any C<\n> in
573 your program will be converted back to C<\cM\cJ> on output.  This is what
574 you want for text files, but it can be disastrous for binary files.
575
576 Another consequence of using binmode() (on some systems) is that
577 special end-of-file markers will be seen as part of the data stream.
578 For systems from the Microsoft family this means that if your binary
579 data contains C<\cZ>, the I/O subsystem will regard it as the end of
580 the file, unless you use binmode().
581
582 binmode() is not only important for readline() and print() operations,
583 but also when using read(), seek(), sysread(), syswrite() and tell()
584 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
585 in L<perlvar> for how to manually set your input and output
586 line-termination sequences.
587
588 =item bless REF,CLASSNAME
589 X<bless>
590
591 =item bless REF
592
593 This function tells the thingy referenced by REF that it is now an object
594 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
595 is used.  Because a C<bless> is often the last thing in a constructor,
596 it returns the reference for convenience.  Always use the two-argument
597 version if a derived class might inherit the function doing the blessing.
598 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
599 of objects.
600
601 Consider always blessing objects in CLASSNAMEs that are mixed case.
602 Namespaces with all lowercase names are considered reserved for
603 Perl pragmata.  Builtin types have all uppercase names. To prevent
604 confusion, you may wish to avoid such package names as well.  Make sure
605 that CLASSNAME is a true value.
606
607 See L<perlmod/"Perl Modules">.
608
609 =item break
610
611 Break out of a C<given()> block.
612
613 This keyword is enabled by the "switch" feature: see L<feature>
614 for more information.
615
616 =item caller EXPR
617 X<caller> X<call stack> X<stack> X<stack trace>
618
619 =item caller
620
621 Returns the context of the current subroutine call.  In scalar context,
622 returns the caller's package name if there is a caller, that is, if
623 we're in a subroutine or C<eval> or C<require>, and the undefined value
624 otherwise.  In list context, returns
625
626     # 0         1          2
627     ($package, $filename, $line) = caller;
628
629 With EXPR, it returns some extra information that the debugger uses to
630 print a stack trace.  The value of EXPR indicates how many call frames
631 to go back before the current one.
632
633     #  0         1          2      3            4
634     ($package, $filename, $line, $subroutine, $hasargs,
635
636     #  5          6          7            8       9         10
637     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
638      = caller($i);
639
640 Here $subroutine may be C<(eval)> if the frame is not a subroutine
641 call, but an C<eval>.  In such a case additional elements $evaltext and
642 C<$is_require> are set: C<$is_require> is true if the frame is created by a
643 C<require> or C<use> statement, $evaltext contains the text of the
644 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
645 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
646 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
647 frame.)  $subroutine may also be C<(unknown)> if this particular
648 subroutine happens to have been deleted from the symbol table.
649 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
650 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
651 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
652 between versions of Perl, and are not meant for external use.
653
654 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
655 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
656 of this hash, as they are the actual values stored in the optree.
657
658 Furthermore, when called from within the DB package, caller returns more
659 detailed information: it sets the list variable C<@DB::args> to be the
660 arguments with which the subroutine was invoked.
661
662 Be aware that the optimizer might have optimized call frames away before
663 C<caller> had a chance to get the information.  That means that C<caller(N)>
664 might not return information about the call frame you expect it do, for
665 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
666 previous time C<caller> was called.
667
668 =item chdir EXPR
669 X<chdir>
670 X<cd>
671 X<directory, change>
672
673 =item chdir FILEHANDLE
674
675 =item chdir DIRHANDLE
676
677 =item chdir
678
679 Changes the working directory to EXPR, if possible. If EXPR is omitted,
680 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
681 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
682 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
683 neither is set, C<chdir> does nothing. It returns true upon success,
684 false otherwise. See the example under C<die>.
685
686 On systems that support fchdir, you might pass a file handle or
687 directory handle as argument.  On systems that don't support fchdir,
688 passing handles produces a fatal error at run time.
689
690 =item chmod LIST
691 X<chmod> X<permission> X<mode>
692
693 Changes the permissions of a list of files.  The first element of the
694 list must be the numerical mode, which should probably be an octal
695 number, and which definitely should I<not> be a string of octal digits:
696 C<0644> is okay, C<'0644'> is not.  Returns the number of files
697 successfully changed.  See also L</oct>, if all you have is a string.
698
699     $cnt = chmod 0755, 'foo', 'bar';
700     chmod 0755, @executables;
701     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
702                                              # --w----r-T
703     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
704     $mode = 0644;   chmod $mode, 'foo';      # this is best
705
706 On systems that support fchmod, you might pass file handles among the
707 files.  On systems that don't support fchmod, passing file handles
708 produces a fatal error at run time.   The file handles must be passed
709 as globs or references to be recognized.  Barewords are considered
710 file names.
711
712     open(my $fh, "<", "foo");
713     my $perm = (stat $fh)[2] & 07777;
714     chmod($perm | 0600, $fh);
715
716 You can also import the symbolic C<S_I*> constants from the Fcntl
717 module:
718
719     use Fcntl ':mode';
720
721     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
722     # This is identical to the chmod 0755 of the above example.
723
724 =item chomp VARIABLE
725 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
726
727 =item chomp( LIST )
728
729 =item chomp
730
731 This safer version of L</chop> removes any trailing string
732 that corresponds to the current value of C<$/> (also known as
733 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
734 number of characters removed from all its arguments.  It's often used to
735 remove the newline from the end of an input record when you're worried
736 that the final record may be missing its newline.  When in paragraph
737 mode (C<$/ = "">), it removes all trailing newlines from the string.
738 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
739 a reference to an integer or the like, see L<perlvar>) chomp() won't
740 remove anything.
741 If VARIABLE is omitted, it chomps C<$_>.  Example:
742
743     while (<>) {
744         chomp;  # avoid \n on last field
745         @array = split(/:/);
746         # ...
747     }
748
749 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
750
751 You can actually chomp anything that's an lvalue, including an assignment:
752
753     chomp($cwd = `pwd`);
754     chomp($answer = <STDIN>);
755
756 If you chomp a list, each element is chomped, and the total number of
757 characters removed is returned.
758
759 If the C<encoding> pragma is in scope then the lengths returned are
760 calculated from the length of C<$/> in Unicode characters, which is not
761 always the same as the length of C<$/> in the native encoding.
762
763 Note that parentheses are necessary when you're chomping anything
764 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
765 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
766 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
767 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
768 as C<chomp($a, $b)>.
769
770 =item chop VARIABLE
771 X<chop>
772
773 =item chop( LIST )
774
775 =item chop
776
777 Chops off the last character of a string and returns the character
778 chopped.  It is much more efficient than C<s/.$//s> because it neither
779 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
780 If VARIABLE is a hash, it chops the hash's values, but not its keys.
781
782 You can actually chop anything that's an lvalue, including an assignment.
783
784 If you chop a list, each element is chopped.  Only the value of the
785 last C<chop> is returned.
786
787 Note that C<chop> returns the last character.  To return all but the last
788 character, use C<substr($string, 0, -1)>.
789
790 See also L</chomp>.
791
792 =item chown LIST
793 X<chown> X<owner> X<user> X<group>
794
795 Changes the owner (and group) of a list of files.  The first two
796 elements of the list must be the I<numeric> uid and gid, in that
797 order.  A value of -1 in either position is interpreted by most
798 systems to leave that value unchanged.  Returns the number of files
799 successfully changed.
800
801     $cnt = chown $uid, $gid, 'foo', 'bar';
802     chown $uid, $gid, @filenames;
803
804 On systems that support fchown, you might pass file handles among the
805 files.  On systems that don't support fchown, passing file handles
806 produces a fatal error at run time.  The file handles must be passed
807 as globs or references to be recognized.  Barewords are considered
808 file names.
809
810 Here's an example that looks up nonnumeric uids in the passwd file:
811
812     print "User: ";
813     chomp($user = <STDIN>);
814     print "Files: ";
815     chomp($pattern = <STDIN>);
816
817     ($login,$pass,$uid,$gid) = getpwnam($user)
818         or die "$user not in passwd file";
819
820     @ary = glob($pattern);      # expand filenames
821     chown $uid, $gid, @ary;
822
823 On most systems, you are not allowed to change the ownership of the
824 file unless you're the superuser, although you should be able to change
825 the group to any of your secondary groups.  On insecure systems, these
826 restrictions may be relaxed, but this is not a portable assumption.
827 On POSIX systems, you can detect this condition this way:
828
829     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
830     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
831
832 =item chr NUMBER
833 X<chr> X<character> X<ASCII> X<Unicode>
834
835 =item chr
836
837 Returns the character represented by that NUMBER in the character set.
838 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
839 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
840 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
841 backward compatibility reasons (but see L<encoding>).
842
843 Negative values give the Unicode replacement character (chr(0xfffd)),
844 except under the L<bytes> pragma, where low eight bits of the value
845 (truncated to an integer) are used.
846
847 If NUMBER is omitted, uses C<$_>.
848
849 For the reverse, use L</ord>.
850
851 Note that under the C<bytes> pragma the NUMBER is masked to
852 the low eight bits.
853
854 See L<perlunicode> and L<encoding> for more about Unicode.
855
856 =item chroot FILENAME
857 X<chroot> X<root>
858
859 =item chroot
860
861 This function works like the system call by the same name: it makes the
862 named directory the new root directory for all further pathnames that
863 begin with a C</> by your process and all its children.  (It doesn't
864 change your current working directory, which is unaffected.)  For security
865 reasons, this call is restricted to the superuser.  If FILENAME is
866 omitted, does a C<chroot> to C<$_>.
867
868 =item close FILEHANDLE
869 X<close>
870
871 =item close
872
873 Closes the file or pipe associated with the file handle, flushes the IO
874 buffers, and closes the system file descriptor.  Returns true if those
875 operations have succeeded and if no error was reported by any PerlIO
876 layer.  Closes the currently selected filehandle if the argument is
877 omitted.
878
879 You don't have to close FILEHANDLE if you are immediately going to do
880 another C<open> on it, because C<open> will close it for you.  (See
881 C<open>.)  However, an explicit C<close> on an input file resets the line
882 counter (C<$.>), while the implicit close done by C<open> does not.
883
884 If the file handle came from a piped open, C<close> will additionally
885 return false if one of the other system calls involved fails, or if the
886 program exits with non-zero status.  (If the only problem was that the
887 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
888 also waits for the process executing on the pipe to complete, in case you
889 want to look at the output of the pipe afterwards, and
890 implicitly puts the exit status value of that command into C<$?> and
891 C<${^CHILD_ERROR_NATIVE}>.
892
893 Prematurely closing the read end of a pipe (i.e. before the process
894 writing to it at the other end has closed it) will result in a
895 SIGPIPE being delivered to the writer.  If the other end can't
896 handle that, be sure to read all the data before closing the pipe.
897
898 Example:
899
900     open(OUTPUT, '|sort >foo')  # pipe to sort
901         or die "Can't start sort: $!";
902     #...                        # print stuff to output
903     close OUTPUT                # wait for sort to finish
904         or warn $! ? "Error closing sort pipe: $!"
905                    : "Exit status $? from sort";
906     open(INPUT, 'foo')          # get sort's results
907         or die "Can't open 'foo' for input: $!";
908
909 FILEHANDLE may be an expression whose value can be used as an indirect
910 filehandle, usually the real filehandle name.
911
912 =item closedir DIRHANDLE
913 X<closedir>
914
915 Closes a directory opened by C<opendir> and returns the success of that
916 system call.
917
918 =item connect SOCKET,NAME
919 X<connect>
920
921 Attempts to connect to a remote socket, just as the connect system call
922 does.  Returns true if it succeeded, false otherwise.  NAME should be a
923 packed address of the appropriate type for the socket.  See the examples in
924 L<perlipc/"Sockets: Client/Server Communication">.
925
926 =item continue BLOCK
927 X<continue>
928
929 =item continue
930
931 C<continue> is actually a flow control statement rather than a function.  If
932 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
933 C<foreach>), it is always executed just before the conditional is about to
934 be evaluated again, just like the third part of a C<for> loop in C.  Thus
935 it can be used to increment a loop variable, even when the loop has been
936 continued via the C<next> statement (which is similar to the C C<continue>
937 statement).
938
939 C<last>, C<next>, or C<redo> may appear within a C<continue>
940 block.  C<last> and C<redo> will behave as if they had been executed within
941 the main block.  So will C<next>, but since it will execute a C<continue>
942 block, it may be more entertaining.
943
944     while (EXPR) {
945         ### redo always comes here
946         do_something;
947     } continue {
948         ### next always comes here
949         do_something_else;
950         # then back the top to re-check EXPR
951     }
952     ### last always comes here
953
954 Omitting the C<continue> section is semantically equivalent to using an
955 empty one, logically enough.  In that case, C<next> goes directly back
956 to check the condition at the top of the loop.
957
958 If the "switch" feature is enabled, C<continue> is also a
959 function that will break out of the current C<when> or C<default>
960 block, and fall through to the next case. See L<feature> and
961 L<perlsyn/"Switch statements"> for more information.
962
963
964 =item cos EXPR
965 X<cos> X<cosine> X<acos> X<arccosine>
966
967 =item cos
968
969 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
970 takes cosine of C<$_>.
971
972 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
973 function, or use this relation:
974
975     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
976
977 =item crypt PLAINTEXT,SALT
978 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
979 X<decrypt> X<cryptography> X<passwd> X<encrypt>
980
981 Creates a digest string exactly like the crypt(3) function in the C
982 library (assuming that you actually have a version there that has not
983 been extirpated as a potential munitions).
984
985 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
986 into a short string, called a digest, which is returned.  The same
987 PLAINTEXT and SALT will always return the same string, but there is no
988 (known) way to get the original PLAINTEXT from the hash.  Small
989 changes in the PLAINTEXT or SALT will result in large changes in the
990 digest.
991
992 There is no decrypt function.  This function isn't all that useful for
993 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
994 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
995 primarily used to check if two pieces of text are the same without
996 having to transmit or store the text itself.  An example is checking
997 if a correct password is given.  The digest of the password is stored,
998 not the password itself.  The user types in a password that is
999 crypt()'d with the same salt as the stored digest.  If the two digests
1000 match the password is correct.
1001
1002 When verifying an existing digest string you should use the digest as
1003 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1004 to create the digest is visible as part of the digest.  This ensures
1005 crypt() will hash the new string with the same salt as the digest.
1006 This allows your code to work with the standard L<crypt|/crypt> and
1007 with more exotic implementations.  In other words, do not assume
1008 anything about the returned string itself, or how many bytes in the
1009 digest matter.
1010
1011 Traditionally the result is a string of 13 bytes: two first bytes of
1012 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1013 the first eight bytes of the digest string mattered, but alternative
1014 hashing schemes (like MD5), higher level security schemes (like C2),
1015 and implementations on non-UNIX platforms may produce different
1016 strings.
1017
1018 When choosing a new salt create a random two character string whose
1019 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1020 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1021 characters is just a recommendation; the characters allowed in
1022 the salt depend solely on your system's crypt library, and Perl can't
1023 restrict what salts C<crypt()> accepts.
1024
1025 Here's an example that makes sure that whoever runs this program knows
1026 their password:
1027
1028     $pwd = (getpwuid($<))[1];
1029
1030     system "stty -echo";
1031     print "Password: ";
1032     chomp($word = <STDIN>);
1033     print "\n";
1034     system "stty echo";
1035
1036     if (crypt($word, $pwd) ne $pwd) {
1037         die "Sorry...\n";
1038     } else {
1039         print "ok\n";
1040     }
1041
1042 Of course, typing in your own password to whoever asks you
1043 for it is unwise.
1044
1045 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1046 of data, not least of all because you can't get the information
1047 back.  Look at the L<Digest> module for more robust algorithms.
1048
1049 If using crypt() on a Unicode string (which I<potentially> has
1050 characters with codepoints above 255), Perl tries to make sense
1051 of the situation by trying to downgrade (a copy of the string)
1052 the string back to an eight-bit byte string before calling crypt()
1053 (on that copy).  If that works, good.  If not, crypt() dies with
1054 C<Wide character in crypt>.
1055
1056 =item dbmclose HASH
1057 X<dbmclose>
1058
1059 [This function has been largely superseded by the C<untie> function.]
1060
1061 Breaks the binding between a DBM file and a hash.
1062
1063 =item dbmopen HASH,DBNAME,MASK
1064 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1065
1066 [This function has been largely superseded by the C<tie> function.]
1067
1068 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1069 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1070 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1071 is the name of the database (without the F<.dir> or F<.pag> extension if
1072 any).  If the database does not exist, it is created with protection
1073 specified by MASK (as modified by the C<umask>).  If your system supports
1074 only the older DBM functions, you may perform only one C<dbmopen> in your
1075 program.  In older versions of Perl, if your system had neither DBM nor
1076 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1077 sdbm(3).
1078
1079 If you don't have write access to the DBM file, you can only read hash
1080 variables, not set them.  If you want to test whether you can write,
1081 either use file tests or try setting a dummy hash entry inside an C<eval>,
1082 which will trap the error.
1083
1084 Note that functions such as C<keys> and C<values> may return huge lists
1085 when used on large DBM files.  You may prefer to use the C<each>
1086 function to iterate over large DBM files.  Example:
1087
1088     # print out history file offsets
1089     dbmopen(%HIST,'/usr/lib/news/history',0666);
1090     while (($key,$val) = each %HIST) {
1091         print $key, ' = ', unpack('L',$val), "\n";
1092     }
1093     dbmclose(%HIST);
1094
1095 See also L<AnyDBM_File> for a more general description of the pros and
1096 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1097 rich implementation.
1098
1099 You can control which DBM library you use by loading that library
1100 before you call dbmopen():
1101
1102     use DB_File;
1103     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1104         or die "Can't open netscape history file: $!";
1105
1106 =item defined EXPR
1107 X<defined> X<undef> X<undefined>
1108
1109 =item defined
1110
1111 Returns a Boolean value telling whether EXPR has a value other than
1112 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1113 checked.
1114
1115 Many operations return C<undef> to indicate failure, end of file,
1116 system error, uninitialized variable, and other exceptional
1117 conditions.  This function allows you to distinguish C<undef> from
1118 other values.  (A simple Boolean test will not distinguish among
1119 C<undef>, zero, the empty string, and C<"0">, which are all equally
1120 false.)  Note that since C<undef> is a valid scalar, its presence
1121 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1122 returns C<undef> when its argument is an empty array, I<or> when the
1123 element to return happens to be C<undef>.
1124
1125 You may also use C<defined(&func)> to check whether subroutine C<&func>
1126 has ever been defined.  The return value is unaffected by any forward
1127 declarations of C<&func>.  Note that a subroutine which is not defined
1128 may still be callable: its package may have an C<AUTOLOAD> method that
1129 makes it spring into existence the first time that it is called -- see
1130 L<perlsub>.
1131
1132 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1133 used to report whether memory for that aggregate has ever been
1134 allocated.  This behavior may disappear in future versions of Perl.
1135 You should instead use a simple test for size:
1136
1137     if (@an_array) { print "has array elements\n" }
1138     if (%a_hash)   { print "has hash members\n"   }
1139
1140 When used on a hash element, it tells you whether the value is defined,
1141 not whether the key exists in the hash.  Use L</exists> for the latter
1142 purpose.
1143
1144 Examples:
1145
1146     print if defined $switch{'D'};
1147     print "$val\n" while defined($val = pop(@ary));
1148     die "Can't readlink $sym: $!"
1149         unless defined($value = readlink $sym);
1150     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1151     $debugging = 0 unless defined $debugging;
1152
1153 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1154 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1155 defined values.  For example, if you say
1156
1157     "ab" =~ /a(.*)b/;
1158
1159 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1160 matched "nothing".  It didn't really fail to match anything.  Rather, it
1161 matched something that happened to be zero characters long.  This is all
1162 very above-board and honest.  When a function returns an undefined value,
1163 it's an admission that it couldn't give you an honest answer.  So you
1164 should use C<defined> only when you're questioning the integrity of what
1165 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1166 what you want.
1167
1168 See also L</undef>, L</exists>, L</ref>.
1169
1170 =item delete EXPR
1171 X<delete>
1172
1173 Given an expression that specifies a hash element, array element, hash slice,
1174 or array slice, deletes the specified element(s) from the hash or array.
1175 In the case of an array, if the array elements happen to be at the end,
1176 the size of the array will shrink to the highest element that tests
1177 true for exists() (or 0 if no such element exists).
1178
1179 Returns a list with the same number of elements as the number of elements
1180 for which deletion was attempted.  Each element of that list consists of
1181 either the value of the element deleted, or the undefined value.  In scalar
1182 context, this means that you get the value of the last element deleted (or
1183 the undefined value if that element did not exist).
1184
1185     %hash = (foo => 11, bar => 22, baz => 33);
1186     $scalar = delete $hash{foo};             # $scalar is 11
1187     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1188     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1189
1190 Deleting from C<%ENV> modifies the environment.  Deleting from
1191 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1192 from a C<tie>d hash or array may not necessarily return anything.
1193
1194 Deleting an array element effectively returns that position of the array
1195 to its initial, uninitialized state.  Subsequently testing for the same
1196 element with exists() will return false.  Also, deleting array elements
1197 in the middle of an array will not shift the index of the elements
1198 after them down.  Use splice() for that.  See L</exists>.
1199
1200 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1201
1202     foreach $key (keys %HASH) {
1203         delete $HASH{$key};
1204     }
1205
1206     foreach $index (0 .. $#ARRAY) {
1207         delete $ARRAY[$index];
1208     }
1209
1210 And so do these:
1211
1212     delete @HASH{keys %HASH};
1213
1214     delete @ARRAY[0 .. $#ARRAY];
1215
1216 But both of these are slower than just assigning the empty list
1217 or undefining %HASH or @ARRAY:
1218
1219     %HASH = ();         # completely empty %HASH
1220     undef %HASH;        # forget %HASH ever existed
1221
1222     @ARRAY = ();        # completely empty @ARRAY
1223     undef @ARRAY;       # forget @ARRAY ever existed
1224
1225 Note that the EXPR can be arbitrarily complicated as long as the final
1226 operation is a hash element, array element,  hash slice, or array slice
1227 lookup:
1228
1229     delete $ref->[$x][$y]{$key};
1230     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1231
1232     delete $ref->[$x][$y][$index];
1233     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1234
1235 =item die LIST
1236 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1237
1238 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1239 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1240 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1241 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1242 an C<eval(),> the error message is stuffed into C<$@> and the
1243 C<eval> is terminated with the undefined value.  This makes
1244 C<die> the way to raise an exception.
1245
1246 Equivalent examples:
1247
1248     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1249     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1250
1251 If the last element of LIST does not end in a newline, the current
1252 script line number and input line number (if any) are also printed,
1253 and a newline is supplied.  Note that the "input line number" (also
1254 known as "chunk") is subject to whatever notion of "line" happens to
1255 be currently in effect, and is also available as the special variable
1256 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1257
1258 Hint: sometimes appending C<", stopped"> to your message will cause it
1259 to make better sense when the string C<"at foo line 123"> is appended.
1260 Suppose you are running script "canasta".
1261
1262     die "/etc/games is no good";
1263     die "/etc/games is no good, stopped";
1264
1265 produce, respectively
1266
1267     /etc/games is no good at canasta line 123.
1268     /etc/games is no good, stopped at canasta line 123.
1269
1270 See also exit(), warn(), and the Carp module.
1271
1272 If LIST is empty and C<$@> already contains a value (typically from a
1273 previous eval) that value is reused after appending C<"\t...propagated">.
1274 This is useful for propagating exceptions:
1275
1276     eval { ... };
1277     die unless $@ =~ /Expected exception/;
1278
1279 If LIST is empty and C<$@> contains an object reference that has a
1280 C<PROPAGATE> method, that method will be called with additional file
1281 and line number parameters.  The return value replaces the value in
1282 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1283 were called.
1284
1285 If C<$@> is empty then the string C<"Died"> is used.
1286
1287 die() can also be called with a reference argument.  If this happens to be
1288 trapped within an eval(), $@ contains the reference.  This behavior permits
1289 a more elaborate exception handling implementation using objects that
1290 maintain arbitrary state about the nature of the exception.  Such a scheme
1291 is sometimes preferable to matching particular string values of $@ using
1292 regular expressions.  Because $@ is a global variable, and eval() may be
1293 used within object implementations, care must be taken that analyzing the
1294 error object doesn't replace the reference in the global variable.  The
1295 easiest solution is to make a local copy of the reference before doing
1296 other manipulations.  Here's an example:
1297
1298     use Scalar::Util 'blessed';
1299
1300     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1301     if (my $ev_err = $@) {
1302         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1303             # handle Some::Module::Exception
1304         }
1305         else {
1306             # handle all other possible exceptions
1307         }
1308     }
1309
1310 Because perl will stringify uncaught exception messages before displaying
1311 them, you may want to overload stringification operations on such custom
1312 exception objects.  See L<overload> for details about that.
1313
1314 You can arrange for a callback to be run just before the C<die>
1315 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1316 handler will be called with the error text and can change the error
1317 message, if it sees fit, by calling C<die> again.  See
1318 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1319 L<"eval BLOCK"> for some examples.  Although this feature was 
1320 to be run only right before your program was to exit, this is not
1321 currently the case--the C<$SIG{__DIE__}> hook is currently called
1322 even inside eval()ed blocks/strings!  If one wants the hook to do
1323 nothing in such situations, put
1324
1325         die @_ if $^S;
1326
1327 as the first line of the handler (see L<perlvar/$^S>).  Because
1328 this promotes strange action at a distance, this counterintuitive
1329 behavior may be fixed in a future release.
1330
1331 =item do BLOCK
1332 X<do> X<block>
1333
1334 Not really a function.  Returns the value of the last command in the
1335 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1336 C<until> loop modifier, executes the BLOCK once before testing the loop
1337 condition. (On other statements the loop modifiers test the conditional
1338 first.)
1339
1340 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1341 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1342 See L<perlsyn> for alternative strategies.
1343
1344 =item do SUBROUTINE(LIST)
1345 X<do>
1346
1347 This form of subroutine call is deprecated.  See L<perlsub>.
1348
1349 =item do EXPR
1350 X<do>
1351
1352 Uses the value of EXPR as a filename and executes the contents of the
1353 file as a Perl script.
1354
1355     do 'stat.pl';
1356
1357 is just like
1358
1359     eval `cat stat.pl`;
1360
1361 except that it's more efficient and concise, keeps track of the current
1362 filename for error messages, searches the @INC directories, and updates
1363 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1364 variables.  It also differs in that code evaluated with C<do FILENAME>
1365 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1366 same, however, in that it does reparse the file every time you call it,
1367 so you probably don't want to do this inside a loop.
1368
1369 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1370 error.  If C<do> can read the file but cannot compile it, it
1371 returns undef and sets an error message in C<$@>.   If the file is
1372 successfully compiled, C<do> returns the value of the last expression
1373 evaluated.
1374
1375 Note that inclusion of library modules is better done with the
1376 C<use> and C<require> operators, which also do automatic error checking
1377 and raise an exception if there's a problem.
1378
1379 You might like to use C<do> to read in a program configuration
1380 file.  Manual error checking can be done this way:
1381
1382     # read in config files: system first, then user
1383     for $file ("/share/prog/defaults.rc",
1384                "$ENV{HOME}/.someprogrc")
1385    {
1386         unless ($return = do $file) {
1387             warn "couldn't parse $file: $@" if $@;
1388             warn "couldn't do $file: $!"    unless defined $return;
1389             warn "couldn't run $file"       unless $return;
1390         }
1391     }
1392
1393 =item dump LABEL
1394 X<dump> X<core> X<undump>
1395
1396 =item dump
1397
1398 This function causes an immediate core dump.  See also the B<-u>
1399 command-line switch in L<perlrun>, which does the same thing.
1400 Primarily this is so that you can use the B<undump> program (not
1401 supplied) to turn your core dump into an executable binary after
1402 having initialized all your variables at the beginning of the
1403 program.  When the new binary is executed it will begin by executing
1404 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1405 Think of it as a goto with an intervening core dump and reincarnation.
1406 If C<LABEL> is omitted, restarts the program from the top.
1407
1408 B<WARNING>: Any files opened at the time of the dump will I<not>
1409 be open any more when the program is reincarnated, with possible
1410 resulting confusion on the part of Perl.
1411
1412 This function is now largely obsolete, partly because it's very
1413 hard to convert a core file into an executable, and because the
1414 real compiler backends for generating portable bytecode and compilable
1415 C code have superseded it.  That's why you should now invoke it as
1416 C<CORE::dump()>, if you don't want to be warned against a possible
1417 typo.
1418
1419 If you're looking to use L<dump> to speed up your program, consider
1420 generating bytecode or native C code as described in L<perlcc>.  If
1421 you're just trying to accelerate a CGI script, consider using the
1422 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1423 You might also consider autoloading or selfloading, which at least
1424 make your program I<appear> to run faster.
1425
1426 =item each HASH
1427 X<each> X<hash, iterator>
1428
1429 When called in list context, returns a 2-element list consisting of the
1430 key and value for the next element of a hash, so that you can iterate over
1431 it.  When called in scalar context, returns only the key for the next
1432 element in the hash.
1433
1434 Entries are returned in an apparently random order.  The actual random
1435 order is subject to change in future versions of perl, but it is
1436 guaranteed to be in the same order as either the C<keys> or C<values>
1437 function would produce on the same (unmodified) hash.  Since Perl
1438 5.8.1 the ordering is different even between different runs of Perl
1439 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1440
1441 When the hash is entirely read, a null array is returned in list context
1442 (which when assigned produces a false (C<0>) value), and C<undef> in
1443 scalar context.  The next call to C<each> after that will start iterating
1444 again.  There is a single iterator for each hash, shared by all C<each>,
1445 C<keys>, and C<values> function calls in the program; it can be reset by
1446 reading all the elements from the hash, or by evaluating C<keys HASH> or
1447 C<values HASH>.  If you add or delete elements of a hash while you're
1448 iterating over it, you may get entries skipped or duplicated, so
1449 don't.  Exception: It is always safe to delete the item most recently
1450 returned by C<each()>, which means that the following code will work:
1451
1452         while (($key, $value) = each %hash) {
1453           print $key, "\n";
1454           delete $hash{$key};   # This is safe
1455         }
1456
1457 The following prints out your environment like the printenv(1) program,
1458 only in a different order:
1459
1460     while (($key,$value) = each %ENV) {
1461         print "$key=$value\n";
1462     }
1463
1464 See also C<keys>, C<values> and C<sort>.
1465
1466 =item eof FILEHANDLE
1467 X<eof>
1468 X<end of file>
1469 X<end-of-file>
1470
1471 =item eof ()
1472
1473 =item eof
1474
1475 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1476 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1477 gives the real filehandle.  (Note that this function actually
1478 reads a character and then C<ungetc>s it, so isn't very useful in an
1479 interactive context.)  Do not read from a terminal file (or call
1480 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1481 as terminals may lose the end-of-file condition if you do.
1482
1483 An C<eof> without an argument uses the last file read.  Using C<eof()>
1484 with empty parentheses is very different.  It refers to the pseudo file
1485 formed from the files listed on the command line and accessed via the
1486 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1487 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1488 used will cause C<@ARGV> to be examined to determine if input is
1489 available.   Similarly, an C<eof()> after C<< <> >> has returned
1490 end-of-file will assume you are processing another C<@ARGV> list,
1491 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1492 see L<perlop/"I/O Operators">.
1493
1494 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1495 detect the end of each file, C<eof()> will only detect the end of the
1496 last file.  Examples:
1497
1498     # reset line numbering on each input file
1499     while (<>) {
1500         next if /^\s*#/;        # skip comments
1501         print "$.\t$_";
1502     } continue {
1503         close ARGV  if eof;     # Not eof()!
1504     }
1505
1506     # insert dashes just before last line of last file
1507     while (<>) {
1508         if (eof()) {            # check for end of last file
1509             print "--------------\n";
1510         }
1511         print;
1512         last if eof();          # needed if we're reading from a terminal
1513     }
1514
1515 Practical hint: you almost never need to use C<eof> in Perl, because the
1516 input operators typically return C<undef> when they run out of data, or if
1517 there was an error.
1518
1519 =item eval EXPR
1520 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1521 X<error, handling> X<exception, handling>
1522
1523 =item eval BLOCK
1524
1525 =item eval
1526
1527 In the first form, the return value of EXPR is parsed and executed as if it
1528 were a little Perl program.  The value of the expression (which is itself
1529 determined within scalar context) is first parsed, and if there weren't any
1530 errors, executed in the lexical context of the current Perl program, so
1531 that any variable settings or subroutine and format definitions remain
1532 afterwards.  Note that the value is parsed every time the C<eval> executes.
1533 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1534 delay parsing and subsequent execution of the text of EXPR until run time.
1535
1536 In the second form, the code within the BLOCK is parsed only once--at the
1537 same time the code surrounding the C<eval> itself was parsed--and executed
1538 within the context of the current Perl program.  This form is typically
1539 used to trap exceptions more efficiently than the first (see below), while
1540 also providing the benefit of checking the code within BLOCK at compile
1541 time.
1542
1543 The final semicolon, if any, may be omitted from the value of EXPR or within
1544 the BLOCK.
1545
1546 In both forms, the value returned is the value of the last expression
1547 evaluated inside the mini-program; a return statement may be also used, just
1548 as with subroutines.  The expression providing the return value is evaluated
1549 in void, scalar, or list context, depending on the context of the C<eval> 
1550 itself.  See L</wantarray> for more on how the evaluation context can be 
1551 determined.
1552
1553 If there is a syntax error or runtime error, or a C<die> statement is
1554 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1555 error message.  If there was no error, C<$@> is guaranteed to be a null
1556 string.  Beware that using C<eval> neither silences perl from printing
1557 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1558 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1559 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1560 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1561
1562 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1563 determining whether a particular feature (such as C<socket> or C<symlink>)
1564 is implemented.  It is also Perl's exception trapping mechanism, where
1565 the die operator is used to raise exceptions.
1566
1567 If the code to be executed doesn't vary, you may use the eval-BLOCK
1568 form to trap run-time errors without incurring the penalty of
1569 recompiling each time.  The error, if any, is still returned in C<$@>.
1570 Examples:
1571
1572     # make divide-by-zero nonfatal
1573     eval { $answer = $a / $b; }; warn $@ if $@;
1574
1575     # same thing, but less efficient
1576     eval '$answer = $a / $b'; warn $@ if $@;
1577
1578     # a compile-time error
1579     eval { $answer = };                 # WRONG
1580
1581     # a run-time error
1582     eval '$answer =';   # sets $@
1583
1584 Using the C<eval{}> form as an exception trap in libraries does have some
1585 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1586 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1587 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1588 as shown in this example:
1589
1590     # a very private exception trap for divide-by-zero
1591     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1592     warn $@ if $@;
1593
1594 This is especially significant, given that C<__DIE__> hooks can call
1595 C<die> again, which has the effect of changing their error messages:
1596
1597     # __DIE__ hooks may modify error messages
1598     {
1599        local $SIG{'__DIE__'} =
1600               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1601        eval { die "foo lives here" };
1602        print $@ if $@;                # prints "bar lives here"
1603     }
1604
1605 Because this promotes action at a distance, this counterintuitive behavior
1606 may be fixed in a future release.
1607
1608 With an C<eval>, you should be especially careful to remember what's
1609 being looked at when:
1610
1611     eval $x;            # CASE 1
1612     eval "$x";          # CASE 2
1613
1614     eval '$x';          # CASE 3
1615     eval { $x };        # CASE 4
1616
1617     eval "\$$x++";      # CASE 5
1618     $$x++;              # CASE 6
1619
1620 Cases 1 and 2 above behave identically: they run the code contained in
1621 the variable $x.  (Although case 2 has misleading double quotes making
1622 the reader wonder what else might be happening (nothing is).)  Cases 3
1623 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1624 does nothing but return the value of $x.  (Case 4 is preferred for
1625 purely visual reasons, but it also has the advantage of compiling at
1626 compile-time instead of at run-time.)  Case 5 is a place where
1627 normally you I<would> like to use double quotes, except that in this
1628 particular situation, you can just use symbolic references instead, as
1629 in case 6.
1630
1631 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1632 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1633
1634 Note that as a very special case, an C<eval ''> executed within the C<DB>
1635 package doesn't see the usual surrounding lexical scope, but rather the
1636 scope of the first non-DB piece of code that called it. You don't normally
1637 need to worry about this unless you are writing a Perl debugger.
1638
1639 =item exec LIST
1640 X<exec> X<execute>
1641
1642 =item exec PROGRAM LIST
1643
1644 The C<exec> function executes a system command I<and never returns>--
1645 use C<system> instead of C<exec> if you want it to return.  It fails and
1646 returns false only if the command does not exist I<and> it is executed
1647 directly instead of via your system's command shell (see below).
1648
1649 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1650 warns you if there is a following statement which isn't C<die>, C<warn>,
1651 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1652 I<really> want to follow an C<exec> with some other statement, you
1653 can use one of these styles to avoid the warning:
1654
1655     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1656     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1657
1658 If there is more than one argument in LIST, or if LIST is an array
1659 with more than one value, calls execvp(3) with the arguments in LIST.
1660 If there is only one scalar argument or an array with one element in it,
1661 the argument is checked for shell metacharacters, and if there are any,
1662 the entire argument is passed to the system's command shell for parsing
1663 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1664 If there are no shell metacharacters in the argument, it is split into
1665 words and passed directly to C<execvp>, which is more efficient.
1666 Examples:
1667
1668     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1669     exec "sort $outfile | uniq";
1670
1671 If you don't really want to execute the first argument, but want to lie
1672 to the program you are executing about its own name, you can specify
1673 the program you actually want to run as an "indirect object" (without a
1674 comma) in front of the LIST.  (This always forces interpretation of the
1675 LIST as a multivalued list, even if there is only a single scalar in
1676 the list.)  Example:
1677
1678     $shell = '/bin/csh';
1679     exec $shell '-sh';          # pretend it's a login shell
1680
1681 or, more directly,
1682
1683     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1684
1685 When the arguments get executed via the system shell, results will
1686 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1687 for details.
1688
1689 Using an indirect object with C<exec> or C<system> is also more
1690 secure.  This usage (which also works fine with system()) forces
1691 interpretation of the arguments as a multivalued list, even if the
1692 list had just one argument.  That way you're safe from the shell
1693 expanding wildcards or splitting up words with whitespace in them.
1694
1695     @args = ( "echo surprise" );
1696
1697     exec @args;               # subject to shell escapes
1698                                 # if @args == 1
1699     exec { $args[0] } @args;  # safe even with one-arg list
1700
1701 The first version, the one without the indirect object, ran the I<echo>
1702 program, passing it C<"surprise"> an argument.  The second version
1703 didn't--it tried to run a program literally called I<"echo surprise">,
1704 didn't find it, and set C<$?> to a non-zero value indicating failure.
1705
1706 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1707 output before the exec, but this may not be supported on some platforms
1708 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1709 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1710 open handles in order to avoid lost output.
1711
1712 Note that C<exec> will not call your C<END> blocks, nor will it call
1713 any C<DESTROY> methods in your objects.
1714
1715 =item exists EXPR
1716 X<exists> X<autovivification>
1717
1718 Given an expression that specifies a hash element or array element,
1719 returns true if the specified element in the hash or array has ever
1720 been initialized, even if the corresponding value is undefined.  The
1721 element is not autovivified if it doesn't exist.
1722
1723     print "Exists\n"    if exists $hash{$key};
1724     print "Defined\n"   if defined $hash{$key};
1725     print "True\n"      if $hash{$key};
1726
1727     print "Exists\n"    if exists $array[$index];
1728     print "Defined\n"   if defined $array[$index];
1729     print "True\n"      if $array[$index];
1730
1731 A hash or array element can be true only if it's defined, and defined if
1732 it exists, but the reverse doesn't necessarily hold true.
1733
1734 Given an expression that specifies the name of a subroutine,
1735 returns true if the specified subroutine has ever been declared, even
1736 if it is undefined.  Mentioning a subroutine name for exists or defined
1737 does not count as declaring it.  Note that a subroutine which does not
1738 exist may still be callable: its package may have an C<AUTOLOAD>
1739 method that makes it spring into existence the first time that it is
1740 called -- see L<perlsub>.
1741
1742     print "Exists\n"    if exists &subroutine;
1743     print "Defined\n"   if defined &subroutine;
1744
1745 Note that the EXPR can be arbitrarily complicated as long as the final
1746 operation is a hash or array key lookup or subroutine name:
1747
1748     if (exists $ref->{A}->{B}->{$key})  { }
1749     if (exists $hash{A}{B}{$key})       { }
1750
1751     if (exists $ref->{A}->{B}->[$ix])   { }
1752     if (exists $hash{A}{B}[$ix])        { }
1753
1754     if (exists &{$ref->{A}{B}{$key}})   { }
1755
1756 Although the deepest nested array or hash will not spring into existence
1757 just because its existence was tested, any intervening ones will.
1758 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1759 into existence due to the existence test for the $key element above.
1760 This happens anywhere the arrow operator is used, including even:
1761
1762     undef $ref;
1763     if (exists $ref->{"Some key"})      { }
1764     print $ref;             # prints HASH(0x80d3d5c)
1765
1766 This surprising autovivification in what does not at first--or even
1767 second--glance appear to be an lvalue context may be fixed in a future
1768 release.
1769
1770 Use of a subroutine call, rather than a subroutine name, as an argument
1771 to exists() is an error.
1772
1773     exists &sub;        # OK
1774     exists &sub();      # Error
1775
1776 =item exit EXPR
1777 X<exit> X<terminate> X<abort>
1778
1779 =item exit
1780
1781 Evaluates EXPR and exits immediately with that value.    Example:
1782
1783     $ans = <STDIN>;
1784     exit 0 if $ans =~ /^[Xx]/;
1785
1786 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1787 universally recognized values for EXPR are C<0> for success and C<1>
1788 for error; other values are subject to interpretation depending on the
1789 environment in which the Perl program is running.  For example, exiting
1790 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1791 the mailer to return the item undelivered, but that's not true everywhere.
1792
1793 Don't use C<exit> to abort a subroutine if there's any chance that
1794 someone might want to trap whatever error happened.  Use C<die> instead,
1795 which can be trapped by an C<eval>.
1796
1797 The exit() function does not always exit immediately.  It calls any
1798 defined C<END> routines first, but these C<END> routines may not
1799 themselves abort the exit.  Likewise any object destructors that need to
1800 be called are called before the real exit.  If this is a problem, you
1801 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1802 See L<perlmod> for details.
1803
1804 =item exp EXPR
1805 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1806
1807 =item exp
1808
1809 Returns I<e> (the natural logarithm base) to the power of EXPR.
1810 If EXPR is omitted, gives C<exp($_)>.
1811
1812 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1813 X<fcntl>
1814
1815 Implements the fcntl(2) function.  You'll probably have to say
1816
1817     use Fcntl;
1818
1819 first to get the correct constant definitions.  Argument processing and
1820 value return works just like C<ioctl> below.
1821 For example:
1822
1823     use Fcntl;
1824     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1825         or die "can't fcntl F_GETFL: $!";
1826
1827 You don't have to check for C<defined> on the return from C<fcntl>.
1828 Like C<ioctl>, it maps a C<0> return from the system call into
1829 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1830 in numeric context.  It is also exempt from the normal B<-w> warnings
1831 on improper numeric conversions.
1832
1833 Note that C<fcntl> will produce a fatal error if used on a machine that
1834 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1835 manpage to learn what functions are available on your system.
1836
1837 Here's an example of setting a filehandle named C<REMOTE> to be
1838 non-blocking at the system level.  You'll have to negotiate C<$|>
1839 on your own, though.
1840
1841     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1842
1843     $flags = fcntl(REMOTE, F_GETFL, 0)
1844                 or die "Can't get flags for the socket: $!\n";
1845
1846     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1847                 or die "Can't set flags for the socket: $!\n";
1848
1849 =item fileno FILEHANDLE
1850 X<fileno>
1851
1852 Returns the file descriptor for a filehandle, or undefined if the
1853 filehandle is not open.  This is mainly useful for constructing
1854 bitmaps for C<select> and low-level POSIX tty-handling operations.
1855 If FILEHANDLE is an expression, the value is taken as an indirect
1856 filehandle, generally its name.
1857
1858 You can use this to find out whether two handles refer to the
1859 same underlying descriptor:
1860
1861     if (fileno(THIS) == fileno(THAT)) {
1862         print "THIS and THAT are dups\n";
1863     }
1864
1865 (Filehandles connected to memory objects via new features of C<open> may
1866 return undefined even though they are open.)
1867
1868
1869 =item flock FILEHANDLE,OPERATION
1870 X<flock> X<lock> X<locking>
1871
1872 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1873 for success, false on failure.  Produces a fatal error if used on a
1874 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1875 C<flock> is Perl's portable file locking interface, although it locks
1876 only entire files, not records.
1877
1878 Two potentially non-obvious but traditional C<flock> semantics are
1879 that it waits indefinitely until the lock is granted, and that its locks
1880 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1881 fewer guarantees.  This means that programs that do not also use C<flock>
1882 may modify files locked with C<flock>.  See L<perlport>, 
1883 your port's specific documentation, or your system-specific local manpages
1884 for details.  It's best to assume traditional behavior if you're writing
1885 portable programs.  (But if you're not, you should as always feel perfectly
1886 free to write for your own system's idiosyncrasies (sometimes called
1887 "features").  Slavish adherence to portability concerns shouldn't get
1888 in the way of your getting your job done.)
1889
1890 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1891 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1892 you can use the symbolic names if you import them from the Fcntl module,
1893 either individually, or as a group using the ':flock' tag.  LOCK_SH
1894 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1895 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1896 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1897 waiting for the lock (check the return status to see if you got it).
1898
1899 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1900 before locking or unlocking it.
1901
1902 Note that the emulation built with lockf(3) doesn't provide shared
1903 locks, and it requires that FILEHANDLE be open with write intent.  These
1904 are the semantics that lockf(3) implements.  Most if not all systems
1905 implement lockf(3) in terms of fcntl(2) locking, though, so the
1906 differing semantics shouldn't bite too many people.
1907
1908 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1909 be open with read intent to use LOCK_SH and requires that it be open
1910 with write intent to use LOCK_EX.
1911
1912 Note also that some versions of C<flock> cannot lock things over the
1913 network; you would need to use the more system-specific C<fcntl> for
1914 that.  If you like you can force Perl to ignore your system's flock(2)
1915 function, and so provide its own fcntl(2)-based emulation, by passing
1916 the switch C<-Ud_flock> to the F<Configure> program when you configure
1917 perl.
1918
1919 Here's a mailbox appender for BSD systems.
1920
1921     use Fcntl ':flock'; # import LOCK_* constants
1922
1923     sub lock {
1924         flock(MBOX,LOCK_EX);
1925         # and, in case someone appended
1926         # while we were waiting...
1927         seek(MBOX, 0, 2);
1928     }
1929
1930     sub unlock {
1931         flock(MBOX,LOCK_UN);
1932     }
1933
1934     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1935             or die "Can't open mailbox: $!";
1936
1937     lock();
1938     print MBOX $msg,"\n\n";
1939     unlock();
1940
1941 On systems that support a real flock(), locks are inherited across fork()
1942 calls, whereas those that must resort to the more capricious fcntl()
1943 function lose the locks, making it harder to write servers.
1944
1945 See also L<DB_File> for other flock() examples.
1946
1947 =item fork
1948 X<fork> X<child> X<parent>
1949
1950 Does a fork(2) system call to create a new process running the
1951 same program at the same point.  It returns the child pid to the
1952 parent process, C<0> to the child process, or C<undef> if the fork is
1953 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1954 are shared, while everything else is copied.  On most systems supporting
1955 fork(), great care has gone into making it extremely efficient (for
1956 example, using copy-on-write technology on data pages), making it the
1957 dominant paradigm for multitasking over the last few decades.
1958
1959 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1960 output before forking the child process, but this may not be supported
1961 on some platforms (see L<perlport>).  To be safe, you may need to set
1962 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1963 C<IO::Handle> on any open handles in order to avoid duplicate output.
1964
1965 If you C<fork> without ever waiting on your children, you will
1966 accumulate zombies.  On some systems, you can avoid this by setting
1967 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1968 forking and reaping moribund children.
1969
1970 Note that if your forked child inherits system file descriptors like
1971 STDIN and STDOUT that are actually connected by a pipe or socket, even
1972 if you exit, then the remote server (such as, say, a CGI script or a
1973 backgrounded job launched from a remote shell) won't think you're done.
1974 You should reopen those to F</dev/null> if it's any issue.
1975
1976 =item format
1977 X<format>
1978
1979 Declare a picture format for use by the C<write> function.  For
1980 example:
1981
1982     format Something =
1983         Test: @<<<<<<<< @||||| @>>>>>
1984               $str,     $%,    '$' . int($num)
1985     .
1986
1987     $str = "widget";
1988     $num = $cost/$quantity;
1989     $~ = 'Something';
1990     write;
1991
1992 See L<perlform> for many details and examples.
1993
1994 =item formline PICTURE,LIST
1995 X<formline>
1996
1997 This is an internal function used by C<format>s, though you may call it,
1998 too.  It formats (see L<perlform>) a list of values according to the
1999 contents of PICTURE, placing the output into the format output
2000 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2001 Eventually, when a C<write> is done, the contents of
2002 C<$^A> are written to some filehandle.  You could also read C<$^A>
2003 and then set C<$^A> back to C<"">.  Note that a format typically
2004 does one C<formline> per line of form, but the C<formline> function itself
2005 doesn't care how many newlines are embedded in the PICTURE.  This means
2006 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
2007 You may therefore need to use multiple formlines to implement a single
2008 record format, just like the format compiler.
2009
2010 Be careful if you put double quotes around the picture, because an C<@>
2011 character may be taken to mean the beginning of an array name.
2012 C<formline> always returns true.  See L<perlform> for other examples.
2013
2014 =item getc FILEHANDLE
2015 X<getc> X<getchar> X<character> X<file, read>
2016
2017 =item getc
2018
2019 Returns the next character from the input file attached to FILEHANDLE,
2020 or the undefined value at end of file, or if there was an error (in
2021 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2022 STDIN.  This is not particularly efficient.  However, it cannot be
2023 used by itself to fetch single characters without waiting for the user
2024 to hit enter.  For that, try something more like:
2025
2026     if ($BSD_STYLE) {
2027         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2028     }
2029     else {
2030         system "stty", '-icanon', 'eol', "\001";
2031     }
2032
2033     $key = getc(STDIN);
2034
2035     if ($BSD_STYLE) {
2036         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2037     }
2038     else {
2039         system "stty", 'icanon', 'eol', '^@'; # ASCII null
2040     }
2041     print "\n";
2042
2043 Determination of whether $BSD_STYLE should be set
2044 is left as an exercise to the reader.
2045
2046 The C<POSIX::getattr> function can do this more portably on
2047 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2048 module from your nearest CPAN site; details on CPAN can be found on
2049 L<perlmodlib/CPAN>.
2050
2051 =item getlogin
2052 X<getlogin> X<login>
2053
2054 This implements the C library function of the same name, which on most
2055 systems returns the current login from F</etc/utmp>, if any.  If null,
2056 use C<getpwuid>.
2057
2058     $login = getlogin || getpwuid($<) || "Kilroy";
2059
2060 Do not consider C<getlogin> for authentication: it is not as
2061 secure as C<getpwuid>.
2062
2063 =item getpeername SOCKET
2064 X<getpeername> X<peer>
2065
2066 Returns the packed sockaddr address of other end of the SOCKET connection.
2067
2068     use Socket;
2069     $hersockaddr    = getpeername(SOCK);
2070     ($port, $iaddr) = sockaddr_in($hersockaddr);
2071     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2072     $herstraddr     = inet_ntoa($iaddr);
2073
2074 =item getpgrp PID
2075 X<getpgrp> X<group>
2076
2077 Returns the current process group for the specified PID.  Use
2078 a PID of C<0> to get the current process group for the
2079 current process.  Will raise an exception if used on a machine that
2080 doesn't implement getpgrp(2).  If PID is omitted, returns process
2081 group of current process.  Note that the POSIX version of C<getpgrp>
2082 does not accept a PID argument, so only C<PID==0> is truly portable.
2083
2084 =item getppid
2085 X<getppid> X<parent> X<pid>
2086
2087 Returns the process id of the parent process.
2088
2089 Note for Linux users: on Linux, the C functions C<getpid()> and
2090 C<getppid()> return different values from different threads. In order to
2091 be portable, this behavior is not reflected by the perl-level function
2092 C<getppid()>, that returns a consistent value across threads. If you want
2093 to call the underlying C<getppid()>, you may use the CPAN module
2094 C<Linux::Pid>.
2095
2096 =item getpriority WHICH,WHO
2097 X<getpriority> X<priority> X<nice>
2098
2099 Returns the current priority for a process, a process group, or a user.
2100 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2101 machine that doesn't implement getpriority(2).
2102
2103 =item getpwnam NAME
2104 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2105 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2106 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2107 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2108 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2109 X<endnetent> X<endprotoent> X<endservent> 
2110
2111 =item getgrnam NAME
2112
2113 =item gethostbyname NAME
2114
2115 =item getnetbyname NAME
2116
2117 =item getprotobyname NAME
2118
2119 =item getpwuid UID
2120
2121 =item getgrgid GID
2122
2123 =item getservbyname NAME,PROTO
2124
2125 =item gethostbyaddr ADDR,ADDRTYPE
2126
2127 =item getnetbyaddr ADDR,ADDRTYPE
2128
2129 =item getprotobynumber NUMBER
2130
2131 =item getservbyport PORT,PROTO
2132
2133 =item getpwent
2134
2135 =item getgrent
2136
2137 =item gethostent
2138
2139 =item getnetent
2140
2141 =item getprotoent
2142
2143 =item getservent
2144
2145 =item setpwent
2146
2147 =item setgrent
2148
2149 =item sethostent STAYOPEN
2150
2151 =item setnetent STAYOPEN
2152
2153 =item setprotoent STAYOPEN
2154
2155 =item setservent STAYOPEN
2156
2157 =item endpwent
2158
2159 =item endgrent
2160
2161 =item endhostent
2162
2163 =item endnetent
2164
2165 =item endprotoent
2166
2167 =item endservent
2168
2169 These routines perform the same functions as their counterparts in the
2170 system library.  In list context, the return values from the
2171 various get routines are as follows:
2172
2173     ($name,$passwd,$uid,$gid,
2174        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2175     ($name,$passwd,$gid,$members) = getgr*
2176     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2177     ($name,$aliases,$addrtype,$net) = getnet*
2178     ($name,$aliases,$proto) = getproto*
2179     ($name,$aliases,$port,$proto) = getserv*
2180
2181 (If the entry doesn't exist you get a null list.)
2182
2183 The exact meaning of the $gcos field varies but it usually contains
2184 the real name of the user (as opposed to the login name) and other
2185 information pertaining to the user.  Beware, however, that in many
2186 system users are able to change this information and therefore it
2187 cannot be trusted and therefore the $gcos is tainted (see
2188 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2189 login shell, are also tainted, because of the same reason.
2190
2191 In scalar context, you get the name, unless the function was a
2192 lookup by name, in which case you get the other thing, whatever it is.
2193 (If the entry doesn't exist you get the undefined value.)  For example:
2194
2195     $uid   = getpwnam($name);
2196     $name  = getpwuid($num);
2197     $name  = getpwent();
2198     $gid   = getgrnam($name);
2199     $name  = getgrgid($num);
2200     $name  = getgrent();
2201     #etc.
2202
2203 In I<getpw*()> the fields $quota, $comment, and $expire are special
2204 cases in the sense that in many systems they are unsupported.  If the
2205 $quota is unsupported, it is an empty scalar.  If it is supported, it
2206 usually encodes the disk quota.  If the $comment field is unsupported,
2207 it is an empty scalar.  If it is supported it usually encodes some
2208 administrative comment about the user.  In some systems the $quota
2209 field may be $change or $age, fields that have to do with password
2210 aging.  In some systems the $comment field may be $class.  The $expire
2211 field, if present, encodes the expiration period of the account or the
2212 password.  For the availability and the exact meaning of these fields
2213 in your system, please consult your getpwnam(3) documentation and your
2214 F<pwd.h> file.  You can also find out from within Perl what your
2215 $quota and $comment fields mean and whether you have the $expire field
2216 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2217 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2218 files are only supported if your vendor has implemented them in the
2219 intuitive fashion that calling the regular C library routines gets the
2220 shadow versions if you're running under privilege or if there exists
2221 the shadow(3) functions as found in System V (this includes Solaris
2222 and Linux.)  Those systems that implement a proprietary shadow password
2223 facility are unlikely to be supported.
2224
2225 The $members value returned by I<getgr*()> is a space separated list of
2226 the login names of the members of the group.
2227
2228 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2229 C, it will be returned to you via C<$?> if the function call fails.  The
2230 C<@addrs> value returned by a successful call is a list of the raw
2231 addresses returned by the corresponding system library call.  In the
2232 Internet domain, each address is four bytes long and you can unpack it
2233 by saying something like:
2234
2235     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2236
2237 The Socket library makes this slightly easier:
2238
2239     use Socket;
2240     $iaddr = inet_aton("127.1"); # or whatever address
2241     $name  = gethostbyaddr($iaddr, AF_INET);
2242
2243     # or going the other way
2244     $straddr = inet_ntoa($iaddr);
2245
2246 If you get tired of remembering which element of the return list
2247 contains which return value, by-name interfaces are provided
2248 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2249 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2250 and C<User::grent>.  These override the normal built-ins, supplying
2251 versions that return objects with the appropriate names
2252 for each field.  For example:
2253
2254    use File::stat;
2255    use User::pwent;
2256    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2257
2258 Even though it looks like they're the same method calls (uid),
2259 they aren't, because a C<File::stat> object is different from
2260 a C<User::pwent> object.
2261
2262 =item getsockname SOCKET
2263 X<getsockname>
2264
2265 Returns the packed sockaddr address of this end of the SOCKET connection,
2266 in case you don't know the address because you have several different
2267 IPs that the connection might have come in on.
2268
2269     use Socket;
2270     $mysockaddr = getsockname(SOCK);
2271     ($port, $myaddr) = sockaddr_in($mysockaddr);
2272     printf "Connect to %s [%s]\n",
2273        scalar gethostbyaddr($myaddr, AF_INET),
2274        inet_ntoa($myaddr);
2275
2276 =item getsockopt SOCKET,LEVEL,OPTNAME
2277 X<getsockopt>
2278
2279 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2280 Options may exist at multiple protocol levels depending on the socket
2281 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2282 C<Socket> module) will exist. To query options at another level the
2283 protocol number of the appropriate protocol controlling the option
2284 should be supplied. For example, to indicate that an option is to be
2285 interpreted by the TCP protocol, LEVEL should be set to the protocol
2286 number of TCP, which you can get using getprotobyname.
2287
2288 The call returns a packed string representing the requested socket option,
2289 or C<undef> if there is an error (the error reason will be in $!). What
2290 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2291 your system documentation for details. A very common case however is that
2292 the option is an integer, in which case the result will be a packed
2293 integer which you can decode using unpack with the C<i> (or C<I>) format.
2294
2295 An example testing if Nagle's algorithm is turned on on a socket:
2296
2297     use Socket qw(:all);
2298
2299     defined(my $tcp = getprotobyname("tcp"))
2300         or die "Could not determine the protocol number for tcp";
2301     # my $tcp = IPPROTO_TCP; # Alternative
2302     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2303         or die "Could not query TCP_NODELAY socket option: $!";
2304     my $nodelay = unpack("I", $packed);
2305     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2306
2307
2308 =item glob EXPR
2309 X<glob> X<wildcard> X<filename, expansion> X<expand>
2310
2311 =item glob
2312
2313 In list context, returns a (possibly empty) list of filename expansions on
2314 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2315 scalar context, glob iterates through such filename expansions, returning
2316 undef when the list is exhausted. This is the internal function
2317 implementing the C<< <*.c> >> operator, but you can use it directly. If
2318 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2319 more detail in L<perlop/"I/O Operators">.
2320
2321 Beginning with v5.6.0, this operator is implemented using the standard
2322 C<File::Glob> extension.  See L<File::Glob> for details.
2323
2324 =item gmtime EXPR
2325 X<gmtime> X<UTC> X<Greenwich>
2326
2327 =item gmtime
2328
2329 Works just like L<localtime> but the returned values are
2330 localized for the standard Greenwich time zone.
2331
2332 Note: when called in list context, $isdst, the last value
2333 returned by gmtime is always C<0>.  There is no
2334 Daylight Saving Time in GMT.
2335
2336 See L<perlport/gmtime> for portability concerns.
2337
2338 =item goto LABEL
2339 X<goto> X<jump> X<jmp>
2340
2341 =item goto EXPR
2342
2343 =item goto &NAME
2344
2345 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2346 execution there.  It may not be used to go into any construct that
2347 requires initialization, such as a subroutine or a C<foreach> loop.  It
2348 also can't be used to go into a construct that is optimized away,
2349 or to get out of a block or subroutine given to C<sort>.
2350 It can be used to go almost anywhere else within the dynamic scope,
2351 including out of subroutines, but it's usually better to use some other
2352 construct such as C<last> or C<die>.  The author of Perl has never felt the
2353 need to use this form of C<goto> (in Perl, that is--C is another matter).
2354 (The difference being that C does not offer named loops combined with
2355 loop control.  Perl does, and this replaces most structured uses of C<goto>
2356 in other languages.)
2357
2358 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2359 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2360 necessarily recommended if you're optimizing for maintainability:
2361
2362     goto ("FOO", "BAR", "GLARCH")[$i];
2363
2364 The C<goto-&NAME> form is quite different from the other forms of
2365 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2366 doesn't have the stigma associated with other gotos.  Instead, it
2367 exits the current subroutine (losing any changes set by local()) and
2368 immediately calls in its place the named subroutine using the current
2369 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2370 load another subroutine and then pretend that the other subroutine had
2371 been called in the first place (except that any modifications to C<@_>
2372 in the current subroutine are propagated to the other subroutine.)
2373 After the C<goto>, not even C<caller> will be able to tell that this
2374 routine was called first.
2375
2376 NAME needn't be the name of a subroutine; it can be a scalar variable
2377 containing a code reference, or a block that evaluates to a code
2378 reference.
2379
2380 =item grep BLOCK LIST
2381 X<grep>
2382
2383 =item grep EXPR,LIST
2384
2385 This is similar in spirit to, but not the same as, grep(1) and its
2386 relatives.  In particular, it is not limited to using regular expressions.
2387
2388 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2389 C<$_> to each element) and returns the list value consisting of those
2390 elements for which the expression evaluated to true.  In scalar
2391 context, returns the number of times the expression was true.
2392
2393     @foo = grep(!/^#/, @bar);    # weed out comments
2394
2395 or equivalently,
2396
2397     @foo = grep {!/^#/} @bar;    # weed out comments
2398
2399 Note that C<$_> is an alias to the list value, so it can be used to
2400 modify the elements of the LIST.  While this is useful and supported,
2401 it can cause bizarre results if the elements of LIST are not variables.
2402 Similarly, grep returns aliases into the original list, much as a for
2403 loop's index variable aliases the list elements.  That is, modifying an
2404 element of a list returned by grep (for example, in a C<foreach>, C<map>
2405 or another C<grep>) actually modifies the element in the original list.
2406 This is usually something to be avoided when writing clear code.
2407
2408 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2409 been declared with C<my $_>) then, in addition to being locally aliased to
2410 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2411 can't be seen from the outside, avoiding any potential side-effects.
2412
2413 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2414
2415 =item hex EXPR
2416 X<hex> X<hexadecimal>
2417
2418 =item hex
2419
2420 Interprets EXPR as a hex string and returns the corresponding value.
2421 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2422 L</oct>.)  If EXPR is omitted, uses C<$_>.
2423
2424     print hex '0xAf'; # prints '175'
2425     print hex 'aF';   # same
2426
2427 Hex strings may only represent integers.  Strings that would cause
2428 integer overflow trigger a warning.  Leading whitespace is not stripped,
2429 unlike oct(). To present something as hex, look into L</printf>,
2430 L</sprintf>, or L</unpack>.
2431
2432 =item import LIST
2433 X<import>
2434
2435 There is no builtin C<import> function.  It is just an ordinary
2436 method (subroutine) defined (or inherited) by modules that wish to export
2437 names to another module.  The C<use> function calls the C<import> method
2438 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2439
2440 =item index STR,SUBSTR,POSITION
2441 X<index> X<indexOf> X<InStr>
2442
2443 =item index STR,SUBSTR
2444
2445 The index function searches for one string within another, but without
2446 the wildcard-like behavior of a full regular-expression pattern match.
2447 It returns the position of the first occurrence of SUBSTR in STR at
2448 or after POSITION.  If POSITION is omitted, starts searching from the
2449 beginning of the string.  POSITION before the beginning of the string
2450 or after its end is treated as if it were the beginning or the end,
2451 respectively.  POSITION and the return value are based at C<0> (or whatever
2452 you've set the C<$[> variable to--but don't do that).  If the substring
2453 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2454
2455 =item int EXPR
2456 X<int> X<integer> X<truncate> X<trunc> X<floor>
2457
2458 =item int
2459
2460 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2461 You should not use this function for rounding: one because it truncates
2462 towards C<0>, and two because machine representations of floating point
2463 numbers can sometimes produce counterintuitive results.  For example,
2464 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2465 because it's really more like -268.99999999999994315658 instead.  Usually,
2466 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2467 functions will serve you better than will int().
2468
2469 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2470 X<ioctl>
2471
2472 Implements the ioctl(2) function.  You'll probably first have to say
2473
2474     require "sys/ioctl.ph";     # probably in $Config{archlib}/sys/ioctl.ph
2475
2476 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2477 exist or doesn't have the correct definitions you'll have to roll your
2478 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2479 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2480 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2481 written depending on the FUNCTION--a pointer to the string value of SCALAR
2482 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2483 has no string value but does have a numeric value, that value will be
2484 passed rather than a pointer to the string value.  To guarantee this to be
2485 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2486 functions may be needed to manipulate the values of structures used by
2487 C<ioctl>.
2488
2489 The return value of C<ioctl> (and C<fcntl>) is as follows:
2490
2491         if OS returns:          then Perl returns:
2492             -1                    undefined value
2493              0                  string "0 but true"
2494         anything else               that number
2495
2496 Thus Perl returns true on success and false on failure, yet you can
2497 still easily determine the actual value returned by the operating
2498 system:
2499
2500     $retval = ioctl(...) || -1;
2501     printf "System returned %d\n", $retval;
2502
2503 The special string C<"0 but true"> is exempt from B<-w> complaints
2504 about improper numeric conversions.
2505
2506 =item join EXPR,LIST
2507 X<join>
2508
2509 Joins the separate strings of LIST into a single string with fields
2510 separated by the value of EXPR, and returns that new string.  Example:
2511
2512     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2513
2514 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2515 first argument.  Compare L</split>.
2516
2517 =item keys HASH
2518 X<keys> X<key>
2519
2520 Returns a list consisting of all the keys of the named hash.
2521 (In scalar context, returns the number of keys.)
2522
2523 The keys are returned in an apparently random order.  The actual
2524 random order is subject to change in future versions of perl, but it
2525 is guaranteed to be the same order as either the C<values> or C<each>
2526 function produces (given that the hash has not been modified).  Since
2527 Perl 5.8.1 the ordering is different even between different runs of
2528 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2529 Attacks">).
2530
2531 As a side effect, calling keys() resets the HASH's internal iterator
2532 (see L</each>).  In particular, calling keys() in void context resets
2533 the iterator with no other overhead.
2534
2535 Here is yet another way to print your environment:
2536
2537     @keys = keys %ENV;
2538     @values = values %ENV;
2539     while (@keys) {
2540         print pop(@keys), '=', pop(@values), "\n";
2541     }
2542
2543 or how about sorted by key:
2544
2545     foreach $key (sort(keys %ENV)) {
2546         print $key, '=', $ENV{$key}, "\n";
2547     }
2548
2549 The returned values are copies of the original keys in the hash, so
2550 modifying them will not affect the original hash.  Compare L</values>.
2551
2552 To sort a hash by value, you'll need to use a C<sort> function.
2553 Here's a descending numeric sort of a hash by its values:
2554
2555     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2556         printf "%4d %s\n", $hash{$key}, $key;
2557     }
2558
2559 As an lvalue C<keys> allows you to increase the number of hash buckets
2560 allocated for the given hash.  This can gain you a measure of efficiency if
2561 you know the hash is going to get big.  (This is similar to pre-extending
2562 an array by assigning a larger number to $#array.)  If you say
2563
2564     keys %hash = 200;
2565
2566 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2567 in fact, since it rounds up to the next power of two.  These
2568 buckets will be retained even if you do C<%hash = ()>, use C<undef
2569 %hash> if you want to free the storage while C<%hash> is still in scope.
2570 You can't shrink the number of buckets allocated for the hash using
2571 C<keys> in this way (but you needn't worry about doing this by accident,
2572 as trying has no effect).
2573
2574 See also C<each>, C<values> and C<sort>.
2575
2576 =item kill SIGNAL, LIST
2577 X<kill> X<signal>
2578
2579 Sends a signal to a list of processes.  Returns the number of
2580 processes successfully signaled (which is not necessarily the
2581 same as the number actually killed).
2582
2583     $cnt = kill 1, $child1, $child2;
2584     kill 9, @goners;
2585
2586 If SIGNAL is zero, no signal is sent to the process, but the kill(2)
2587 system call will check whether it's possible to send a signal to it (that
2588 means, to be brief, that the process is owned by the same user, or we are
2589 the super-user).  This is a useful way to check that a child process is
2590 alive (even if only as a zombie) and hasn't changed its UID.  See
2591 L<perlport> for notes on the portability of this construct.
2592
2593 Unlike in the shell, if SIGNAL is negative, it kills
2594 process groups instead of processes.  (On System V, a negative I<PROCESS>
2595 number will also kill process groups, but that's not portable.)  That
2596 means you usually want to use positive not negative signals.  You may also
2597 use a signal name in quotes.
2598
2599 See L<perlipc/"Signals"> for more details.
2600
2601 =item last LABEL
2602 X<last> X<break>
2603
2604 =item last
2605
2606 The C<last> command is like the C<break> statement in C (as used in
2607 loops); it immediately exits the loop in question.  If the LABEL is
2608 omitted, the command refers to the innermost enclosing loop.  The
2609 C<continue> block, if any, is not executed:
2610
2611     LINE: while (<STDIN>) {
2612         last LINE if /^$/;      # exit when done with header
2613         #...
2614     }
2615
2616 C<last> cannot be used to exit a block which returns a value such as
2617 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2618 a grep() or map() operation.
2619
2620 Note that a block by itself is semantically identical to a loop
2621 that executes once.  Thus C<last> can be used to effect an early
2622 exit out of such a block.
2623
2624 See also L</continue> for an illustration of how C<last>, C<next>, and
2625 C<redo> work.
2626
2627 =item lc EXPR
2628 X<lc> X<lowercase>
2629
2630 =item lc
2631
2632 Returns a lowercased version of EXPR.  This is the internal function
2633 implementing the C<\L> escape in double-quoted strings.  Respects
2634 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2635 and L<perlunicode> for more details about locale and Unicode support.
2636
2637 If EXPR is omitted, uses C<$_>.
2638
2639 =item lcfirst EXPR
2640 X<lcfirst> X<lowercase>
2641
2642 =item lcfirst
2643
2644 Returns the value of EXPR with the first character lowercased.  This
2645 is the internal function implementing the C<\l> escape in
2646 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2647 locale> in force.  See L<perllocale> and L<perlunicode> for more
2648 details about locale and Unicode support.
2649
2650 If EXPR is omitted, uses C<$_>.
2651
2652 =item length EXPR
2653 X<length> X<size>
2654
2655 =item length
2656
2657 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2658 omitted, returns length of C<$_>.  Note that this cannot be used on
2659 an entire array or hash to find out how many elements these have.
2660 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2661
2662 Note the I<characters>: if the EXPR is in Unicode, you will get the
2663 number of characters, not the number of bytes.  To get the length
2664 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2665
2666 =item link OLDFILE,NEWFILE
2667 X<link>
2668
2669 Creates a new filename linked to the old filename.  Returns true for
2670 success, false otherwise.
2671
2672 =item listen SOCKET,QUEUESIZE
2673 X<listen>
2674
2675 Does the same thing that the listen system call does.  Returns true if
2676 it succeeded, false otherwise.  See the example in
2677 L<perlipc/"Sockets: Client/Server Communication">.
2678
2679 =item local EXPR
2680 X<local>
2681
2682 You really probably want to be using C<my> instead, because C<local> isn't
2683 what most people think of as "local".  See
2684 L<perlsub/"Private Variables via my()"> for details.
2685
2686 A local modifies the listed variables to be local to the enclosing
2687 block, file, or eval.  If more than one value is listed, the list must
2688 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2689 for details, including issues with tied arrays and hashes.
2690
2691 =item localtime EXPR
2692 X<localtime> X<ctime>
2693
2694 =item localtime
2695
2696 Converts a time as returned by the time function to a 9-element list
2697 with the time analyzed for the local time zone.  Typically used as
2698 follows:
2699
2700     #  0    1    2     3     4    5     6     7     8
2701     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2702                                                 localtime(time);
2703
2704 All list elements are numeric, and come straight out of the C `struct
2705 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2706 of the specified time.
2707
2708 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2709 the range C<0..11> with 0 indicating January and 11 indicating December.
2710 This makes it easy to get a month name from a list:
2711
2712     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2713     print "$abbr[$mon] $mday";
2714     # $mon=9, $mday=18 gives "Oct 18"
2715
2716 C<$year> is the number of years since 1900, not just the last two digits
2717 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2718 to get a complete 4-digit year is simply:
2719
2720     $year += 1900;
2721
2722 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2723 to do that, would you?
2724
2725 To get the last two digits of the year (e.g., '01' in 2001) do:
2726
2727     $year = sprintf("%02d", $year % 100);
2728
2729 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2730 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2731 (or C<0..365> in leap years.)
2732
2733 C<$isdst> is true if the specified time occurs during Daylight Saving
2734 Time, false otherwise.
2735
2736 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2737
2738 In scalar context, C<localtime()> returns the ctime(3) value:
2739
2740     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2741
2742 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2743 instead of local time use the L</gmtime> builtin. See also the
2744 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2745 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2746 and mktime(3) functions.
2747
2748 To get somewhat similar but locale dependent date strings, set up your
2749 locale environment variables appropriately (please see L<perllocale>) and
2750 try for example:
2751
2752     use POSIX qw(strftime);
2753     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2754     # or for GMT formatted appropriately for your locale:
2755     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2756
2757 Note that the C<%a> and C<%b>, the short forms of the day of the week
2758 and the month of the year, may not necessarily be three characters wide.
2759
2760 See L<perlport/localtime> for portability concerns.
2761
2762 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2763 by-name access mechanism to the gmtime() and localtime() functions,
2764 respectively.
2765
2766 For a comprehensive date and time representation look at the
2767 L<DateTime> module on CPAN.
2768
2769 =item lock THING
2770 X<lock>
2771
2772 This function places an advisory lock on a shared variable, or referenced
2773 object contained in I<THING> until the lock goes out of scope.
2774
2775 lock() is a "weak keyword" : this means that if you've defined a function
2776 by this name (before any calls to it), that function will be called
2777 instead. (However, if you've said C<use threads>, lock() is always a
2778 keyword.) See L<threads>.
2779
2780 =item log EXPR
2781 X<log> X<logarithm> X<e> X<ln> X<base>
2782
2783 =item log
2784
2785 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2786 returns log of C<$_>.  To get the log of another base, use basic algebra:
2787 The base-N log of a number is equal to the natural log of that number
2788 divided by the natural log of N.  For example:
2789
2790     sub log10 {
2791         my $n = shift;
2792         return log($n)/log(10);
2793     }
2794
2795 See also L</exp> for the inverse operation.
2796
2797 =item lstat EXPR
2798 X<lstat>
2799
2800 =item lstat
2801
2802 Does the same thing as the C<stat> function (including setting the
2803 special C<_> filehandle) but stats a symbolic link instead of the file
2804 the symbolic link points to.  If symbolic links are unimplemented on
2805 your system, a normal C<stat> is done.  For much more detailed
2806 information, please see the documentation for C<stat>.
2807
2808 If EXPR is omitted, stats C<$_>.
2809
2810 =item m//
2811
2812 The match operator.  See L<perlop>.
2813
2814 =item map BLOCK LIST
2815 X<map>
2816
2817 =item map EXPR,LIST
2818
2819 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2820 C<$_> to each element) and returns the list value composed of the
2821 results of each such evaluation.  In scalar context, returns the
2822 total number of elements so generated.  Evaluates BLOCK or EXPR in
2823 list context, so each element of LIST may produce zero, one, or
2824 more elements in the returned value.
2825
2826     @chars = map(chr, @nums);
2827
2828 translates a list of numbers to the corresponding characters.  And
2829
2830     %hash = map { getkey($_) => $_ } @array;
2831
2832 is just a funny way to write
2833
2834     %hash = ();
2835     foreach $_ (@array) {
2836         $hash{getkey($_)} = $_;
2837     }
2838
2839 Note that C<$_> is an alias to the list value, so it can be used to
2840 modify the elements of the LIST.  While this is useful and supported,
2841 it can cause bizarre results if the elements of LIST are not variables.
2842 Using a regular C<foreach> loop for this purpose would be clearer in
2843 most cases.  See also L</grep> for an array composed of those items of
2844 the original list for which the BLOCK or EXPR evaluates to true.
2845
2846 If C<$_> is lexical in the scope where the C<map> appears (because it has
2847 been declared with C<my $_>) then, in addition to being locally aliased to
2848 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2849 can't be seen from the outside, avoiding any potential side-effects.
2850
2851 C<{> starts both hash references and blocks, so C<map { ...> could be either
2852 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2853 ahead for the closing C<}> it has to take a guess at which its dealing with
2854 based what it finds just after the C<{>. Usually it gets it right, but if it
2855 doesn't it won't realize something is wrong until it gets to the C<}> and
2856 encounters the missing (or unexpected) comma. The syntax error will be
2857 reported close to the C<}> but you'll need to change something near the C<{>
2858 such as using a unary C<+> to give perl some help:
2859
2860     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2861     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2862     %hash = map { ("\L$_", 1) } @array  # this also works
2863     %hash = map {  lc($_), 1  } @array  # as does this.
2864     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2865
2866     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2867
2868 or to force an anon hash constructor use C<+{>
2869
2870    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2871
2872 and you get list of anonymous hashes each with only 1 entry.
2873
2874 =item mkdir FILENAME,MASK
2875 X<mkdir> X<md> X<directory, create>
2876
2877 =item mkdir FILENAME
2878
2879 =item mkdir
2880
2881 Creates the directory specified by FILENAME, with permissions
2882 specified by MASK (as modified by C<umask>).  If it succeeds it
2883 returns true, otherwise it returns false and sets C<$!> (errno).
2884 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2885 to C<$_>.
2886
2887 In general, it is better to create directories with permissive MASK,
2888 and let the user modify that with their C<umask>, than it is to supply
2889 a restrictive MASK and give the user no way to be more permissive.
2890 The exceptions to this rule are when the file or directory should be
2891 kept private (mail files, for instance).  The perlfunc(1) entry on
2892 C<umask> discusses the choice of MASK in more detail.
2893
2894 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2895 number of trailing slashes.  Some operating and filesystems do not get
2896 this right, so Perl automatically removes all trailing slashes to keep
2897 everyone happy.
2898
2899 In order to recursively create a directory structure look at
2900 the C<mkpath> function of the L<File::Path> module.
2901
2902 =item msgctl ID,CMD,ARG
2903 X<msgctl>
2904
2905 Calls the System V IPC function msgctl(2).  You'll probably have to say
2906
2907     use IPC::SysV;
2908
2909 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2910 then ARG must be a variable that will hold the returned C<msqid_ds>
2911 structure.  Returns like C<ioctl>: the undefined value for error,
2912 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2913 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2914
2915 =item msgget KEY,FLAGS
2916 X<msgget>
2917
2918 Calls the System V IPC function msgget(2).  Returns the message queue
2919 id, or the undefined value if there is an error.  See also
2920 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2921
2922 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2923 X<msgrcv>
2924
2925 Calls the System V IPC function msgrcv to receive a message from
2926 message queue ID into variable VAR with a maximum message size of
2927 SIZE.  Note that when a message is received, the message type as a
2928 native long integer will be the first thing in VAR, followed by the
2929 actual message.  This packing may be opened with C<unpack("l! a*")>.
2930 Taints the variable.  Returns true if successful, or false if there is
2931 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2932 C<IPC::SysV::Msg> documentation.
2933
2934 =item msgsnd ID,MSG,FLAGS
2935 X<msgsnd>
2936
2937 Calls the System V IPC function msgsnd to send the message MSG to the
2938 message queue ID.  MSG must begin with the native long integer message
2939 type, and be followed by the length of the actual message, and finally
2940 the message itself.  This kind of packing can be achieved with
2941 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2942 or false if there is an error.  See also C<IPC::SysV>
2943 and C<IPC::SysV::Msg> documentation.
2944
2945 =item my EXPR
2946 X<my>
2947
2948 =item my TYPE EXPR
2949
2950 =item my EXPR : ATTRS
2951
2952 =item my TYPE EXPR : ATTRS
2953
2954 A C<my> declares the listed variables to be local (lexically) to the
2955 enclosing block, file, or C<eval>.  If more than one value is listed,
2956 the list must be placed in parentheses.
2957
2958 The exact semantics and interface of TYPE and ATTRS are still
2959 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2960 and attributes are handled using the C<attributes> pragma, or starting
2961 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2962 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2963 L<attributes>, and L<Attribute::Handlers>.
2964
2965 =item next LABEL
2966 X<next> X<continue>
2967
2968 =item next
2969
2970 The C<next> command is like the C<continue> statement in C; it starts
2971 the next iteration of the loop:
2972
2973     LINE: while (<STDIN>) {
2974         next LINE if /^#/;      # discard comments
2975         #...
2976     }
2977
2978 Note that if there were a C<continue> block on the above, it would get
2979 executed even on discarded lines.  If the LABEL is omitted, the command
2980 refers to the innermost enclosing loop.
2981
2982 C<next> cannot be used to exit a block which returns a value such as
2983 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2984 a grep() or map() operation.
2985
2986 Note that a block by itself is semantically identical to a loop
2987 that executes once.  Thus C<next> will exit such a block early.
2988
2989 See also L</continue> for an illustration of how C<last>, C<next>, and
2990 C<redo> work.
2991
2992 =item no Module VERSION LIST
2993 X<no>
2994
2995 =item no Module VERSION
2996
2997 =item no Module LIST
2998
2999 =item no Module
3000
3001 See the C<use> function, of which C<no> is the opposite.
3002
3003 =item oct EXPR
3004 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3005
3006 =item oct
3007
3008 Interprets EXPR as an octal string and returns the corresponding
3009 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3010 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3011 binary string.  Leading whitespace is ignored in all three cases.)
3012 The following will handle decimal, binary, octal, and hex in the standard
3013 Perl or C notation:
3014
3015     $val = oct($val) if $val =~ /^0/;
3016
3017 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3018 in octal), use sprintf() or printf():
3019
3020     $perms = (stat("filename"))[2] & 07777;
3021     $oct_perms = sprintf "%lo", $perms;
3022
3023 The oct() function is commonly used when a string such as C<644> needs
3024 to be converted into a file mode, for example. (Although perl will
3025 automatically convert strings into numbers as needed, this automatic
3026 conversion assumes base 10.)
3027
3028 =item open FILEHANDLE,EXPR
3029 X<open> X<pipe> X<file, open> X<fopen>
3030
3031 =item open FILEHANDLE,MODE,EXPR
3032
3033 =item open FILEHANDLE,MODE,EXPR,LIST
3034
3035 =item open FILEHANDLE,MODE,REFERENCE
3036
3037 =item open FILEHANDLE
3038
3039 Opens the file whose filename is given by EXPR, and associates it with
3040 FILEHANDLE.
3041
3042 (The following is a comprehensive reference to open(): for a gentler
3043 introduction you may consider L<perlopentut>.)
3044
3045 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3046 the variable is assigned a reference to a new anonymous filehandle,
3047 otherwise if FILEHANDLE is an expression, its value is used as the name of
3048 the real filehandle wanted.  (This is considered a symbolic reference, so
3049 C<use strict 'refs'> should I<not> be in effect.)
3050
3051 If EXPR is omitted, the scalar variable of the same name as the
3052 FILEHANDLE contains the filename.  (Note that lexical variables--those
3053 declared with C<my>--will not work for this purpose; so if you're
3054 using C<my>, specify EXPR in your call to open.)
3055
3056 If three or more arguments are specified then the mode of opening and
3057 the file name are separate. If MODE is C<< '<' >> or nothing, the file
3058 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3059 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3060 the file is opened for appending, again being created if necessary.
3061
3062 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3063 indicate that you want both read and write access to the file; thus
3064 C<< '+<' >> is almost always preferred for read/write updates--the C<<
3065 '+>' >> mode would clobber the file first.  You can't usually use
3066 either read-write mode for updating textfiles, since they have
3067 variable length records.  See the B<-i> switch in L<perlrun> for a
3068 better approach.  The file is created with permissions of C<0666>
3069 modified by the process' C<umask> value.
3070
3071 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3072 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3073
3074 In the 2-arguments (and 1-argument) form of the call the mode and
3075 filename should be concatenated (in this order), possibly separated by
3076 spaces.  It is possible to omit the mode in these forms if the mode is
3077 C<< '<' >>.
3078
3079 If the filename begins with C<'|'>, the filename is interpreted as a
3080 command to which output is to be piped, and if the filename ends with a
3081 C<'|'>, the filename is interpreted as a command which pipes output to
3082 us.  See L<perlipc/"Using open() for IPC">
3083 for more examples of this.  (You are not allowed to C<open> to a command
3084 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3085 and L<perlipc/"Bidirectional Communication with Another Process">
3086 for alternatives.)
3087
3088 For three or more arguments if MODE is C<'|-'>, the filename is
3089 interpreted as a command to which output is to be piped, and if MODE
3090 is C<'-|'>, the filename is interpreted as a command which pipes
3091 output to us.  In the 2-arguments (and 1-argument) form one should
3092 replace dash (C<'-'>) with the command.
3093 See L<perlipc/"Using open() for IPC"> for more examples of this.
3094 (You are not allowed to C<open> to a command that pipes both in I<and>
3095 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3096 L<perlipc/"Bidirectional Communication"> for alternatives.)
3097
3098 In the three-or-more argument form of pipe opens, if LIST is specified
3099 (extra arguments after the command name) then LIST becomes arguments
3100 to the command invoked if the platform supports it.  The meaning of
3101 C<open> with more than three arguments for non-pipe modes is not yet
3102 specified. Experimental "layers" may give extra LIST arguments
3103 meaning.
3104
3105 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
3106 and opening C<< '>-' >> opens STDOUT.
3107
3108 You may use the three-argument form of open to specify IO "layers"
3109 (sometimes also referred to as "disciplines") to be applied to the handle
3110 that affect how the input and output are processed (see L<open> and
3111 L<PerlIO> for more details). For example
3112
3113   open(FH, "<:utf8", "file")
3114
3115 will open the UTF-8 encoded file containing Unicode characters,
3116 see L<perluniintro>. Note that if layers are specified in the
3117 three-arg form then default layers stored in ${^OPEN} (see L<perlvar>;
3118 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3119
3120 Open returns nonzero upon success, the undefined value otherwise.  If
3121 the C<open> involved a pipe, the return value happens to be the pid of
3122 the subprocess.
3123
3124 If you're running Perl on a system that distinguishes between text
3125 files and binary files, then you should check out L</binmode> for tips
3126 for dealing with this.  The key distinction between systems that need
3127 C<binmode> and those that don't is their text file formats.  Systems
3128 like Unix, Mac OS, and Plan 9, which delimit lines with a single
3129 character, and which encode that character in C as C<"\n">, do not
3130 need C<binmode>.  The rest need it.
3131
3132 When opening a file, it's usually a bad idea to continue normal execution
3133 if the request failed, so C<open> is frequently used in connection with
3134 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3135 where you want to make a nicely formatted error message (but there are
3136 modules that can help with that problem)) you should always check
3137 the return value from opening a file.  The infrequent exception is when
3138 working with an unopened filehandle is actually what you want to do.
3139
3140 As a special case the 3-arg form with a read/write mode and the third
3141 argument being C<undef>:
3142
3143     open(TMP, "+>", undef) or die ...
3144
3145 opens a filehandle to an anonymous temporary file.  Also using "+<"
3146 works for symmetry, but you really should consider writing something
3147 to the temporary file first.  You will need to seek() to do the
3148 reading.
3149
3150 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3151 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3152 "in memory" files held in Perl scalars via:
3153
3154     open($fh, '>', \$variable) || ..
3155
3156 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3157 file, you have to close it first:
3158
3159     close STDOUT;
3160     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3161
3162 Examples:
3163
3164     $ARTICLE = 100;
3165     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3166     while (<ARTICLE>) {...
3167
3168     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3169     # if the open fails, output is discarded
3170
3171     open(DBASE, '+<', 'dbase.mine')             # open for update
3172         or die "Can't open 'dbase.mine' for update: $!";
3173
3174     open(DBASE, '+<dbase.mine')                 # ditto
3175         or die "Can't open 'dbase.mine' for update: $!";
3176
3177     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3178         or die "Can't start caesar: $!";
3179
3180     open(ARTICLE, "caesar <$article |")         # ditto
3181         or die "Can't start caesar: $!";
3182
3183     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3184         or die "Can't start sort: $!";
3185
3186     # in memory files
3187     open(MEMORY,'>', \$var)
3188         or die "Can't open memory file: $!";
3189     print MEMORY "foo!\n";                      # output will end up in $var
3190
3191     # process argument list of files along with any includes
3192
3193     foreach $file (@ARGV) {
3194         process($file, 'fh00');
3195     }
3196
3197     sub process {
3198         my($filename, $input) = @_;
3199         $input++;               # this is a string increment
3200         unless (open($input, $filename)) {
3201             print STDERR "Can't open $filename: $!\n";
3202             return;
3203         }
3204
3205         local $_;
3206         while (<$input>) {              # note use of indirection
3207             if (/^#include "(.*)"/) {
3208                 process($1, $input);
3209                 next;
3210             }
3211             #...                # whatever
3212         }
3213     }
3214
3215 See L<perliol> for detailed info on PerlIO.
3216
3217 You may also, in the Bourne shell tradition, specify an EXPR beginning
3218 with C<< '>&' >>, in which case the rest of the string is interpreted
3219 as the name of a filehandle (or file descriptor, if numeric) to be
3220 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3221 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3222 The mode you specify should match the mode of the original filehandle.
3223 (Duping a filehandle does not take into account any existing contents
3224 of IO buffers.) If you use the 3-arg form then you can pass either a
3225 number, the name of a filehandle or the normal "reference to a glob".
3226
3227 Here is a script that saves, redirects, and restores C<STDOUT> and
3228 C<STDERR> using various methods:
3229
3230     #!/usr/bin/perl
3231     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3232     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3233
3234     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3235     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3236
3237     select STDERR; $| = 1;      # make unbuffered
3238     select STDOUT; $| = 1;      # make unbuffered
3239
3240     print STDOUT "stdout 1\n";  # this works for
3241     print STDERR "stderr 1\n";  # subprocesses too
3242
3243     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3244     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3245
3246     print STDOUT "stdout 2\n";
3247     print STDERR "stderr 2\n";
3248
3249 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3250 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3251 that file descriptor (and not call L<dup(2)>); this is more
3252 parsimonious of file descriptors.  For example:
3253
3254     # open for input, reusing the fileno of $fd
3255     open(FILEHANDLE, "<&=$fd")
3256
3257 or
3258
3259     open(FILEHANDLE, "<&=", $fd)
3260
3261 or
3262
3263     # open for append, using the fileno of OLDFH
3264     open(FH, ">>&=", OLDFH)
3265
3266 or
3267
3268     open(FH, ">>&=OLDFH")
3269
3270 Being parsimonious on filehandles is also useful (besides being
3271 parsimonious) for example when something is dependent on file
3272 descriptors, like for example locking using flock().  If you do just
3273 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3274 descriptor as B, and therefore flock(A) will not flock(B), and vice
3275 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3276 the same file descriptor.
3277
3278 Note that if you are using Perls older than 5.8.0, Perl will be using
3279 the standard C libraries' fdopen() to implement the "=" functionality.
3280 On many UNIX systems fdopen() fails when file descriptors exceed a
3281 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3282 most often the default.
3283
3284 You can see whether Perl has been compiled with PerlIO or not by
3285 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3286 is C<define>, you have PerlIO, otherwise you don't.
3287
3288 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3289 with 2-arguments (or 1-argument) form of open(), then
3290 there is an implicit fork done, and the return value of open is the pid
3291 of the child within the parent process, and C<0> within the child
3292 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3293 The filehandle behaves normally for the parent, but i/o to that
3294 filehandle is piped from/to the STDOUT/STDIN of the child process.
3295 In the child process the filehandle isn't opened--i/o happens from/to
3296 the new STDOUT or STDIN.  Typically this is used like the normal
3297 piped open when you want to exercise more control over just how the
3298 pipe command gets executed, such as when you are running setuid, and
3299 don't want to have to scan shell commands for metacharacters.
3300 The following triples are more or less equivalent:
3301
3302     open(FOO, "|tr '[a-z]' '[A-Z]'");
3303     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3304     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3305     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3306
3307     open(FOO, "cat -n '$file'|");
3308     open(FOO, '-|', "cat -n '$file'");
3309     open(FOO, '-|') || exec 'cat', '-n', $file;
3310     open(FOO, '-|', "cat", '-n', $file);
3311
3312 The last example in each block shows the pipe as "list form", which is
3313 not yet supported on all platforms.  A good rule of thumb is that if
3314 your platform has true C<fork()> (in other words, if your platform is
3315 UNIX) you can use the list form.
3316
3317 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3318
3319 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3320 output before any operation that may do a fork, but this may not be
3321 supported on some platforms (see L<perlport>).  To be safe, you may need
3322 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3323 of C<IO::Handle> on any open handles.
3324
3325 On systems that support a close-on-exec flag on files, the flag will
3326 be set for the newly opened file descriptor as determined by the value
3327 of $^F.  See L<perlvar/$^F>.
3328
3329 Closing any piped filehandle causes the parent process to wait for the
3330 child to finish, and returns the status value in C<$?> and
3331 C<${^CHILD_ERROR_NATIVE}>.
3332
3333 The filename passed to 2-argument (or 1-argument) form of open() will
3334 have leading and trailing whitespace deleted, and the normal
3335 redirection characters honored.  This property, known as "magic open",
3336 can often be used to good effect.  A user could specify a filename of
3337 F<"rsh cat file |">, or you could change certain filenames as needed:
3338
3339     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3340     open(FH, $filename) or die "Can't open $filename: $!";
3341
3342 Use 3-argument form to open a file with arbitrary weird characters in it,
3343
3344     open(FOO, '<', $file);
3345
3346 otherwise it's necessary to protect any leading and trailing whitespace:
3347
3348     $file =~ s#^(\s)#./$1#;
3349     open(FOO, "< $file\0");
3350
3351 (this may not work on some bizarre filesystems).  One should
3352 conscientiously choose between the I<magic> and 3-arguments form
3353 of open():
3354
3355     open IN, $ARGV[0];
3356
3357 will allow the user to specify an argument of the form C<"rsh cat file |">,
3358 but will not work on a filename which happens to have a trailing space, while
3359
3360     open IN, '<', $ARGV[0];
3361
3362 will have exactly the opposite restrictions.
3363
3364 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3365 should use the C<sysopen> function, which involves no such magic (but
3366 may use subtly different filemodes than Perl open(), which is mapped
3367 to C fopen()).  This is
3368 another way to protect your filenames from interpretation.  For example:
3369
3370     use IO::Handle;
3371     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3372         or die "sysopen $path: $!";
3373     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3374     print HANDLE "stuff $$\n";
3375     seek(HANDLE, 0, 0);
3376     print "File contains: ", <HANDLE>;
3377
3378 Using the constructor from the C<IO::Handle> package (or one of its
3379 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3380 filehandles that have the scope of whatever variables hold references to
3381 them, and automatically close whenever and however you leave that scope:
3382
3383     use IO::File;
3384     #...
3385     sub read_myfile_munged {
3386         my $ALL = shift;
3387         my $handle = new IO::File;
3388         open($handle, "myfile") or die "myfile: $!";
3389         $first = <$handle>
3390             or return ();     # Automatically closed here.
3391         mung $first or die "mung failed";       # Or here.
3392         return $first, <$handle> if $ALL;       # Or here.
3393         $first;                                 # Or here.
3394     }
3395
3396 See L</seek> for some details about mixing reading and writing.
3397
3398 =item opendir DIRHANDLE,EXPR
3399 X<opendir>
3400
3401 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3402 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3403 DIRHANDLE may be an expression whose value can be used as an indirect
3404 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3405 scalar variable (or array or hash element), the variable is assigned a
3406 reference to a new anonymous dirhandle.
3407 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3408
3409 =item ord EXPR
3410 X<ord> X<encoding>
3411
3412 =item ord
3413
3414 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3415 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3416 uses C<$_>.
3417
3418 For the reverse, see L</chr>.
3419 See L<perlunicode> and L<encoding> for more about Unicode.
3420
3421 =item our EXPR
3422 X<our> X<global>
3423
3424 =item our TYPE EXPR
3425
3426 =item our EXPR : ATTRS
3427
3428 =item our TYPE EXPR : ATTRS
3429
3430 C<our> associates a simple name with a package variable in the current
3431 package for use within the current scope.  When C<use strict 'vars'> is in
3432 effect, C<our> lets you use declared global variables without qualifying
3433 them with package names, within the lexical scope of the C<our> declaration.
3434 In this way C<our> differs from C<use vars>, which is package scoped.
3435
3436 Unlike C<my>, which both allocates storage for a variable and associates
3437 a simple name with that storage for use within the current scope, C<our>
3438 associates a simple name with a package variable in the current package,
3439 for use within the current scope.  In other words, C<our> has the same
3440 scoping rules as C<my>, but does not necessarily create a
3441 variable.
3442
3443 If more than one value is listed, the list must be placed
3444 in parentheses.
3445
3446     our $foo;
3447     our($bar, $baz);
3448
3449 An C<our> declaration declares a global variable that will be visible
3450 across its entire lexical scope, even across package boundaries.  The
3451 package in which the variable is entered is determined at the point
3452 of the declaration, not at the point of use.  This means the following
3453 behavior holds:
3454
3455     package Foo;
3456     our $bar;           # declares $Foo::bar for rest of lexical scope
3457     $bar = 20;
3458
3459     package Bar;
3460     print $bar;         # prints 20, as it refers to $Foo::bar
3461
3462 Multiple C<our> declarations with the same name in the same lexical
3463 scope are allowed if they are in different packages.  If they happen
3464 to be in the same package, Perl will emit warnings if you have asked
3465 for them, just like multiple C<my> declarations.  Unlike a second
3466 C<my> declaration, which will bind the name to a fresh variable, a
3467 second C<our> declaration in the same package, in the same scope, is
3468 merely redundant.
3469
3470     use warnings;
3471     package Foo;
3472     our $bar;           # declares $Foo::bar for rest of lexical scope
3473     $bar = 20;
3474
3475     package Bar;
3476     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3477     print $bar;         # prints 30
3478
3479     our $bar;           # emits warning but has no other effect
3480     print $bar;         # still prints 30
3481
3482 An C<our> declaration may also have a list of attributes associated
3483 with it.
3484
3485 The exact semantics and interface of TYPE and ATTRS are still
3486 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3487 and attributes are handled using the C<attributes> pragma, or starting
3488 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3489 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3490 L<attributes>, and L<Attribute::Handlers>.
3491
3492 =item pack TEMPLATE,LIST
3493 X<pack>
3494
3495 Takes a LIST of values and converts it into a string using the rules
3496 given by the TEMPLATE.  The resulting string is the concatenation of
3497 the converted values.  Typically, each converted value looks
3498 like its machine-level representation.  For example, on 32-bit machines
3499 an integer may be represented by a sequence of 4 bytes that will be 
3500 converted to a sequence of 4 characters.
3501
3502 The TEMPLATE is a sequence of characters that give the order and type
3503 of values, as follows:
3504
3505     a   A string with arbitrary binary data, will be null padded.
3506     A   A text (ASCII) string, will be space padded.
3507     Z   A null terminated (ASCIZ) string, will be null padded.
3508
3509     b   A bit string (ascending bit order inside each byte, like vec()).
3510     B   A bit string (descending bit order inside each byte).
3511     h   A hex string (low nybble first).
3512     H   A hex string (high nybble first).
3513
3514     c   A signed char (8-bit) value.
3515     C   An unsigned C char (octet) even under Unicode. Should normally not
3516         be used. See U and W instead.
3517     W   An unsigned char value (can be greater than 255).
3518
3519     s   A signed short (16-bit) value.
3520     S   An unsigned short value.
3521
3522     l   A signed long (32-bit) value.
3523     L   An unsigned long value.
3524
3525     q   A signed quad (64-bit) value.
3526     Q   An unsigned quad value.
3527           (Quads are available only if your system supports 64-bit
3528            integer values _and_ if Perl has been compiled to support those.
3529            Causes a fatal error otherwise.)
3530
3531     i   A signed integer value.
3532     I   A unsigned integer value.
3533           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3534            size depends on what a local C compiler calls 'int'.)
3535
3536     n   An unsigned short (16-bit) in "network" (big-endian) order.
3537     N   An unsigned long (32-bit) in "network" (big-endian) order.
3538     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3539     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3540
3541     j   A Perl internal signed integer value (IV).
3542     J   A Perl internal unsigned integer value (UV).
3543
3544     f   A single-precision float in the native format.
3545     d   A double-precision float in the native format.
3546
3547     F   A Perl internal floating point value (NV) in the native format
3548     D   A long double-precision float in the native format.
3549           (Long doubles are available only if your system supports long
3550            double values _and_ if Perl has been compiled to support those.
3551            Causes a fatal error otherwise.)
3552
3553     p   A pointer to a null-terminated string.
3554     P   A pointer to a structure (fixed-length string).
3555
3556     u   A uuencoded string.
3557     U   A Unicode character number.  Encodes to UTF-8 internally
3558         (or UTF-EBCDIC in EBCDIC platforms).
3559
3560     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3561         details).  Its bytes represent an unsigned integer in base 128,
3562         most significant digit first, with as few digits as possible.  Bit
3563         eight (the high bit) is set on each byte except the last.
3564
3565     x   A null byte.
3566     X   Back up a byte.
3567     @   Null fill or truncate to absolute position, counted from the
3568         start of the innermost ()-group.
3569     .   Null fill or truncate to absolute position specified by value.
3570     (   Start of a ()-group.
3571
3572 One or more of the modifiers below may optionally follow some letters in the
3573 TEMPLATE (the second column lists the letters for which the modifier is
3574 valid):
3575
3576     !   sSlLiI     Forces native (short, long, int) sizes instead
3577                    of fixed (16-/32-bit) sizes.
3578
3579         xX         Make x and X act as alignment commands.
3580
3581         nNvV       Treat integers as signed instead of unsigned.
3582
3583         @.         Specify position as byte offset in the internal
3584                    representation of the packed string. Efficient but
3585                    dangerous.
3586
3587     >   sSiIlLqQ   Force big-endian byte-order on the type.
3588         jJfFdDpP   (The "big end" touches the construct.)
3589
3590     <   sSiIlLqQ   Force little-endian byte-order on the type.
3591         jJfFdDpP   (The "little end" touches the construct.)
3592
3593 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3594 in which case they force a certain byte-order on all components of
3595 that group, including subgroups.
3596
3597 The following rules apply:
3598
3599 =over 8
3600
3601 =item *
3602
3603 Each letter may optionally be followed by a number giving a repeat
3604 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3605 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3606 that many values from the LIST.  A C<*> for the repeat count means to
3607 use however many items are left, except for C<@>, C<x>, C<X>, where it
3608 is equivalent to C<0>, for <.> where it means relative to string start
3609 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3610 A numeric repeat count may optionally be enclosed in brackets, as in
3611 C<pack 'C[80]', @arr>.
3612
3613 One can replace the numeric repeat count by a template enclosed in brackets;
3614 then the packed length of this template in bytes is used as a count.
3615 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3616 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3617 If the template in brackets contains alignment commands (such as C<x![d]>),
3618 its packed length is calculated as if the start of the template has the maximal
3619 possible alignment.
3620
3621 When used with C<Z>, C<*> results in the addition of a trailing null
3622 byte (so the packed result will be one longer than the byte C<length>
3623 of the item).
3624
3625 When used with C<@>, the repeat count represents an offset from the start
3626 of the innermost () group.
3627
3628 When used with C<.>, the repeat count is used to determine the starting
3629 position from where the value offset is calculated. If the repeat count
3630 is 0, it's relative to the current position. If the repeat count is C<*>,
3631 the offset is relative to the start of the packed string. And if its an
3632 integer C<n> the offset is relative to the start of the n-th innermost
3633 () group (or the start of the string if C<n> is bigger then the group
3634 level).
3635
3636 The repeat count for C<u> is interpreted as the maximal number of bytes
3637 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3638 count should not be more than 65.
3639
3640 =item *
3641
3642 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3643 string of length count, padding with nulls or spaces as necessary.  When
3644 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3645 after the first null, and C<a> returns data verbatim.
3646
3647 If the value-to-pack is too long, it is truncated.  If too long and an
3648 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3649 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3650 count is 0).
3651
3652 =item *
3653
3654 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3655 Each character of the input field of pack() generates 1 bit of the result.
3656 Each result bit is based on the least-significant bit of the corresponding
3657 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3658 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3659
3660 Starting from the beginning of the input string of pack(), each 8-tuple
3661 of characters is converted to 1 character of output.  With format C<b>
3662 the first character of the 8-tuple determines the least-significant bit of a
3663 character, and with format C<B> it determines the most-significant bit of
3664 a character.
3665
3666 If the length of the input string is not exactly divisible by 8, the
3667 remainder is packed as if the input string were padded by null characters
3668 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3669
3670 If the input string of pack() is longer than needed, extra characters are 
3671 ignored. A C<*> for the repeat count of pack() means to use all the 
3672 characters of the input field.  On unpack()ing the bits are converted to a 
3673 string of C<"0">s and C<"1">s.
3674
3675 =item *
3676
3677 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3678 representable as hexadecimal digits, 0-9a-f) long.
3679
3680 Each character of the input field of pack() generates 4 bits of the result.
3681 For non-alphabetical characters the result is based on the 4 least-significant
3682 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3683 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3684 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3685 is compatible with the usual hexadecimal digits, so that C<"a"> and
3686 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3687 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3688
3689 Starting from the beginning of the input string of pack(), each pair
3690 of characters is converted to 1 character of output.  With format C<h> the
3691 first character of the pair determines the least-significant nybble of the
3692 output character, and with format C<H> it determines the most-significant
3693 nybble.
3694
3695 If the length of the input string is not even, it behaves as if padded
3696 by a null character at the end.  Similarly, during unpack()ing the "extra"
3697 nybbles are ignored.
3698
3699 If the input string of pack() is longer than needed, extra characters are
3700 ignored.
3701 A C<*> for the repeat count of pack() means to use all the characters of
3702 the input field.  On unpack()ing the nybbles are converted to a string
3703 of hexadecimal digits.
3704
3705 =item *
3706
3707 The C<p> type packs a pointer to a null-terminated string.  You are
3708 responsible for ensuring the string is not a temporary value (which can
3709 potentially get deallocated before you get around to using the packed result).
3710 The C<P> type packs a pointer to a structure of the size indicated by the
3711 length.  A NULL pointer is created if the corresponding value for C<p> or
3712 C<P> is C<undef>, similarly for unpack().
3713
3714 If your system has a strange pointer size (i.e. a pointer is neither as
3715 big as an int nor as big as a long), it may not be possible to pack or
3716 unpack pointers in big- or little-endian byte order.  Attempting to do
3717 so will result in a fatal error.
3718
3719 =item *
3720
3721 The C</> template character allows packing and unpacking of a sequence of
3722 items where the packed structure contains a packed item count followed by 
3723 the packed items themselves.
3724
3725 For C<pack> you write I<length-item>C</>I<sequence-item> and the
3726 I<length-item> describes how the length value is packed. The ones likely
3727 to be of most use are integer-packing ones like C<n> (for Java strings),
3728 C<w> (for ASN.1 or SNMP) and C<N> (for Sun XDR).
3729
3730 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3731 the minimum of that and the number of available items is used as argument
3732 for the I<length-item>. If it has no repeat count or uses a '*', the number
3733 of available items is used.
3734
3735 For C<unpack> an internal stack of integer arguments unpacked so far is
3736 used. You write C</>I<sequence-item> and the repeat count is obtained by
3737 popping off the last element from the stack. The I<sequence-item> must not
3738 have a repeat count.
3739
3740 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3741 the I<length-item> is a string length, not a number of strings. If there is
3742 an explicit repeat count for pack, the packed string will be adjusted to that
3743 given length.
3744
3745     unpack 'W/a', "\04Gurusamy";            gives ('Guru')
3746     unpack 'a3/A A*', '007 Bond  J ';       gives (' Bond', 'J')
3747     unpack 'a3 x2 /A A*', '007: Bond, J.';  gives ('Bond, J', '.')
3748     pack 'n/a* w/a','hello,','world';       gives "\000\006hello,\005world"
3749     pack 'a/W2', ord('a') .. ord('z');      gives '2ab'
3750
3751 The I<length-item> is not returned explicitly from C<unpack>.
3752
3753 Adding a count to the I<length-item> letter is unlikely to do anything
3754 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3755 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3756 which Perl does not regard as legal in numeric strings.
3757
3758 =item *
3759
3760 The integer types C<s>, C<S>, C<l>, and C<L> may be
3761 followed by a C<!> modifier to signify native shorts or
3762 longs--as you can see from above for example a bare C<l> does mean
3763 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3764 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3765 see whether using C<!> makes any difference by
3766
3767         print length(pack("s")), " ", length(pack("s!")), "\n";
3768         print length(pack("l")), " ", length(pack("l!")), "\n";
3769
3770 C<i!> and C<I!> also work but only because of completeness;
3771 they are identical to C<i> and C<I>.
3772
3773 The actual sizes (in bytes) of native shorts, ints, longs, and long
3774 longs on the platform where Perl was built are also available via
3775 L<Config>:
3776
3777        use Config;
3778        print $Config{shortsize},    "\n";
3779        print $Config{intsize},      "\n";
3780        print $Config{longsize},     "\n";
3781        print $Config{longlongsize}, "\n";
3782
3783 (The C<$Config{longlongsize}> will be undefined if your system does
3784 not support long longs.)
3785
3786 =item *
3787
3788 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3789 are inherently non-portable between processors and operating systems
3790 because they obey the native byteorder and endianness.  For example a
3791 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3792 (arranged in and handled by the CPU registers) into bytes as
3793
3794         0x12 0x34 0x56 0x78     # big-endian
3795         0x78 0x56 0x34 0x12     # little-endian
3796
3797 Basically, the Intel and VAX CPUs are little-endian, while everybody
3798 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3799 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3800 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3801 mode.
3802
3803 The names `big-endian' and `little-endian' are comic references to
3804 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3805 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3806 the egg-eating habits of the Lilliputians.
3807
3808 Some systems may have even weirder byte orders such as
3809
3810         0x56 0x78 0x12 0x34
3811         0x34 0x12 0x78 0x56
3812
3813 You can see your system's preference with
3814
3815         print join(" ", map { sprintf "%#02x", $_ }
3816                             unpack("W*",pack("L",0x12345678))), "\n";
3817
3818 The byteorder on the platform where Perl was built is also available
3819 via L<Config>:
3820
3821         use Config;
3822         print $Config{byteorder}, "\n";
3823
3824 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3825 and C<'87654321'> are big-endian.
3826
3827 If you want portable packed integers you can either use the formats
3828 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3829 modifiers.  These modifiers are only available as of perl 5.9.2.
3830 See also L<perlport>.
3831
3832 =item *
3833
3834 All integer and floating point formats as well as C<p> and C<P> and
3835 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3836 to force big- or little- endian byte-order, respectively.
3837 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3838 signed integers, 64-bit integers and floating point values.  However,
3839 there are some things to keep in mind.
3840
3841 Exchanging signed integers between different platforms only works
3842 if all platforms store them in the same format.  Most platforms store
3843 signed integers in two's complement, so usually this is not an issue.
3844
3845 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3846 formats on big- or little-endian machines.  Otherwise, attempting to
3847 do so will result in a fatal error.
3848
3849 Forcing big- or little-endian byte-order on floating point values for
3850 data exchange can only work if all platforms are using the same
3851 binary representation (e.g. IEEE floating point format).  Even if all
3852 platforms are using IEEE, there may be subtle differences.  Being able
3853 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3854 but also very dangerous if you don't know exactly what you're doing.
3855 It is definitely not a general way to portably store floating point
3856 values.
3857
3858 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3859 all types inside the group that accept the byte-order modifiers,
3860 including all subgroups.  It will silently be ignored for all other
3861 types.  You are not allowed to override the byte-order within a group
3862 that already has a byte-order modifier suffix.
3863
3864 =item *
3865
3866 Real numbers (floats and doubles) are in the native machine format only;
3867 due to the multiplicity of floating formats around, and the lack of a
3868 standard "network" representation, no facility for interchange has been
3869 made.  This means that packed floating point data written on one machine
3870 may not be readable on another - even if both use IEEE floating point
3871 arithmetic (as the endian-ness of the memory representation is not part
3872 of the IEEE spec).  See also L<perlport>.
3873
3874 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3875 modifiers to force big- or little-endian byte-order on floating point values.
3876
3877 Note that Perl uses doubles (or long doubles, if configured) internally for
3878 all numeric calculation, and converting from double into float and thence back
3879 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3880 will not in general equal $foo).
3881
3882 =item *
3883
3884 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3885 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3886 where the packed string is processed in its UTF-8-encoded Unicode form on
3887 a byte by byte basis. Character mode is the default unless the format string 
3888 starts with an C<U>. You can switch mode at any moment with an explicit 
3889 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3890 or until the end of the ()-group in which it was entered.
3891
3892 =item *
3893
3894 You must yourself do any alignment or padding by inserting for example
3895 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3896 could know where the characters are going to or coming from.  Therefore
3897 C<pack> (and C<unpack>) handle their output and input as flat
3898 sequences of characters.
3899
3900 =item *
3901
3902 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3903 take a repeat count, both as postfix, and for unpack() also via the C</>
3904 template character. Within each repetition of a group, positioning with
3905 C<@> starts again at 0. Therefore, the result of
3906
3907     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3908
3909 is the string "\0a\0\0bc".
3910
3911 =item *
3912
3913 C<x> and C<X> accept C<!> modifier.  In this case they act as
3914 alignment commands: they jump forward/back to the closest position
3915 aligned at a multiple of C<count> characters. For example, to pack() or
3916 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3917 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3918 aligned on the double's size.
3919
3920 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3921 both result in no-ops.
3922
3923 =item *
3924
3925 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3926 will represent signed 16-/32-bit integers in big-/little-endian order.
3927 This is only portable if all platforms sharing the packed data use the
3928 same binary representation for signed integers (e.g. all platforms are
3929 using two's complement representation).
3930
3931 =item *
3932
3933 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3934 White space may be used to separate pack codes from each other, but
3935 modifiers and a repeat count must follow immediately.
3936
3937 =item *
3938
3939 If TEMPLATE requires more arguments to pack() than actually given, pack()
3940 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3941 to pack() than actually given, extra arguments are ignored.
3942
3943 =back
3944
3945 Examples:
3946
3947     $foo = pack("WWWW",65,66,67,68);
3948     # foo eq "ABCD"
3949     $foo = pack("W4",65,66,67,68);
3950     # same thing
3951     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3952     # same thing with Unicode circled letters.
3953     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3954     # same thing with Unicode circled letters. You don't get the UTF-8
3955     # bytes because the U at the start of the format caused a switch to
3956     # U0-mode, so the UTF-8 bytes get joined into characters
3957     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3958     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3959     # This is the UTF-8 encoding of the string in the previous example
3960
3961     $foo = pack("ccxxcc",65,66,67,68);
3962     # foo eq "AB\0\0CD"
3963
3964     # note: the above examples featuring "W" and "c" are true
3965     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3966     # and UTF-8.  In EBCDIC the first example would be
3967     # $foo = pack("WWWW",193,194,195,196);
3968
3969     $foo = pack("s2",1,2);
3970     # "\1\0\2\0" on little-endian
3971     # "\0\1\0\2" on big-endian
3972
3973     $foo = pack("a4","abcd","x","y","z");
3974     # "abcd"
3975
3976     $foo = pack("aaaa","abcd","x","y","z");
3977     # "axyz"
3978
3979     $foo = pack("a14","abcdefg");
3980     # "abcdefg\0\0\0\0\0\0\0"
3981
3982     $foo = pack("i9pl", gmtime);
3983     # a real struct tm (on my system anyway)
3984
3985     $utmp_template = "Z8 Z8 Z16 L";
3986     $utmp = pack($utmp_template, @utmp1);
3987     # a struct utmp (BSDish)
3988
3989     @utmp2 = unpack($utmp_template, $utmp);
3990     # "@utmp1" eq "@utmp2"
3991
3992     sub bintodec {
3993         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3994     }
3995
3996     $foo = pack('sx2l', 12, 34);
3997     # short 12, two zero bytes padding, long 34
3998     $bar = pack('s@4l', 12, 34);
3999     # short 12, zero fill to position 4, long 34
4000     # $foo eq $bar
4001     $baz = pack('s.l', 12, 4, 34);
4002     # short 12, zero fill to position 4, long 34
4003
4004     $foo = pack('nN', 42, 4711);
4005     # pack big-endian 16- and 32-bit unsigned integers
4006     $foo = pack('S>L>', 42, 4711);
4007     # exactly the same
4008     $foo = pack('s<l<', -42, 4711);
4009     # pack little-endian 16- and 32-bit signed integers
4010     $foo = pack('(sl)<', -42, 4711);
4011     # exactly the same
4012
4013 The same template may generally also be used in unpack().
4014
4015 =item package NAMESPACE
4016 X<package> X<module> X<namespace>
4017
4018 =item package
4019
4020 Declares the compilation unit as being in the given namespace.  The scope
4021 of the package declaration is from the declaration itself through the end
4022 of the enclosing block, file, or eval (the same as the C<my> operator).
4023 All further unqualified dynamic identifiers will be in this namespace.
4024 A package statement affects only dynamic variables--including those
4025 you've used C<local> on--but I<not> lexical variables, which are created
4026 with C<my>.  Typically it would be the first declaration in a file to
4027 be included by the C<require> or C<use> operator.  You can switch into a
4028 package in more than one place; it merely influences which symbol table
4029 is used by the compiler for the rest of that block.  You can refer to
4030 variables and filehandles in other packages by prefixing the identifier
4031 with the package name and a double colon:  C<$Package::Variable>.
4032 If the package name is null, the C<main> package as assumed.  That is,
4033 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
4034 still seen in older code).
4035
4036 If NAMESPACE is omitted, then there is no current package, and all
4037 identifiers must be fully qualified or lexicals.  However, you are
4038 strongly advised not to make use of this feature. Its use can cause
4039 unexpected behaviour, even crashing some versions of Perl. It is
4040 deprecated, and will be removed from a future release.
4041
4042 See L<perlmod/"Packages"> for more information about packages, modules,
4043 and classes.  See L<perlsub> for other scoping issues.
4044
4045 =item pipe READHANDLE,WRITEHANDLE
4046 X<pipe>
4047
4048 Opens a pair of connected pipes like the corresponding system call.
4049 Note that if you set up a loop of piped processes, deadlock can occur
4050 unless you are very careful.  In addition, note that Perl's pipes use
4051 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4052 after each command, depending on the application.
4053
4054 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4055 for examples of such things.
4056
4057 On systems that support a close-on-exec flag on files, the flag will be set
4058 for the newly opened file descriptors as determined by the value of $^F.
4059 See L<perlvar/$^F>.
4060
4061 =item pop ARRAY
4062 X<pop> X<stack>
4063
4064 =item pop
4065
4066 Pops and returns the last value of the array, shortening the array by
4067 one element.  Has an effect similar to
4068
4069     $ARRAY[$#ARRAY--]
4070
4071 If there are no elements in the array, returns the undefined value
4072 (although this may happen at other times as well).  If ARRAY is
4073 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
4074 array in subroutines, just like C<shift>.
4075
4076 =item pos SCALAR
4077 X<pos> X<match, position>
4078
4079 =item pos
4080
4081 Returns the offset of where the last C<m//g> search left off for the variable
4082 in question (C<$_> is used when the variable is not specified).  Note that
4083 0 is a valid match offset.  C<undef> indicates that the search position
4084 is reset (usually due to match failure, but can also be because no match has
4085 yet been performed on the scalar). C<pos> directly accesses the location used
4086 by the regexp engine to store the offset, so assigning to C<pos> will change
4087 that offset, and so will also influence the C<\G> zero-width assertion in
4088 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
4089 the return from C<pos> won't change either in this case.  See L<perlre> and
4090 L<perlop>.
4091
4092 =item print FILEHANDLE LIST
4093 X<print>
4094
4095 =item print LIST
4096
4097 =item print
4098
4099 Prints a string or a list of strings.  Returns true if successful.
4100 FILEHANDLE may be a scalar variable name, in which case the variable
4101 contains the name of or a reference to the filehandle, thus introducing
4102 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4103 the next token is a term, it may be misinterpreted as an operator
4104 unless you interpose a C<+> or put parentheses around the arguments.)
4105 If FILEHANDLE is omitted, prints by default to standard output (or
4106 to the last selected output channel--see L</select>).  If LIST is
4107 also omitted, prints C<$_> to the currently selected output channel.
4108 To set the default output channel to something other than STDOUT
4109 use the select operation.  The current value of C<$,> (if any) is
4110 printed between each LIST item.  The current value of C<$\> (if
4111 any) is printed after the entire LIST has been printed.  Because
4112 print takes a LIST, anything in the LIST is evaluated in list
4113 context, and any subroutine that you call will have one or more of
4114 its expressions evaluated in list context.  Also be careful not to
4115 follow the print keyword with a left parenthesis unless you want
4116 the corresponding right parenthesis to terminate the arguments to
4117 the print--interpose a C<+> or put parentheses around all the
4118 arguments.
4119
4120 Note that if you're storing FILEHANDLEs in an array, or if you're using
4121 any other expression more complex than a scalar variable to retrieve it,
4122 you will have to use a block returning the filehandle value instead:
4123
4124     print { $files[$i] } "stuff\n";
4125     print { $OK ? STDOUT : STDERR } "stuff\n";
4126
4127 =item printf FILEHANDLE FORMAT, LIST
4128 X<printf>
4129
4130 =item printf FORMAT, LIST
4131
4132 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4133 (the output record separator) is not appended.  The first argument
4134 of the list will be interpreted as the C<printf> format. See C<sprintf>
4135 for an explanation of the format argument.  If C<use locale> is in effect,
4136 and POSIX::setlocale() has been called, the character used for the decimal
4137 separator in formatted floating point numbers is affected by the LC_NUMERIC
4138 locale.  See L<perllocale> and L<POSIX>.
4139
4140 Don't fall into the trap of using a C<printf> when a simple
4141 C<print> would do.  The C<print> is more efficient and less
4142 error prone.
4143
4144 =item prototype FUNCTION
4145 X<prototype>
4146
4147 Returns the prototype of a function as a string (or C<undef> if the
4148 function has no prototype).  FUNCTION is a reference to, or the name of,
4149 the function whose prototype you want to retrieve.
4150
4151 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4152 name for Perl builtin.  If the builtin is not I<overridable> (such as
4153 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4154 C<system>) returns C<undef> because the builtin does not really behave
4155 like a Perl function.  Otherwise, the string describing the equivalent
4156 prototype is returned.
4157
4158 =item push ARRAY,LIST
4159 X<push>, X<stack>
4160
4161 Treats ARRAY as a stack, and pushes the values of LIST
4162 onto the end of ARRAY.  The length of ARRAY increases by the length of
4163 LIST.  Has the same effect as
4164
4165     for $value (LIST) {
4166         $ARRAY[++$#ARRAY] = $value;
4167     }
4168
4169 but is more efficient.  Returns the number of elements in the array following
4170 the completed C<push>.
4171
4172 =item q/STRING/
4173
4174 =item qq/STRING/
4175
4176 =item qr/STRING/
4177
4178 =item qx/STRING/
4179
4180 =item qw/STRING/
4181
4182 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4183
4184 =item quotemeta EXPR
4185 X<quotemeta> X<metacharacter>
4186
4187 =item quotemeta
4188
4189 Returns the value of EXPR with all non-"word"
4190 characters backslashed.  (That is, all characters not matching
4191 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4192 returned string, regardless of any locale settings.)
4193 This is the internal function implementing
4194 the C<\Q> escape in double-quoted strings.
4195
4196 If EXPR is omitted, uses C<$_>.
4197
4198 =item rand EXPR
4199 X<rand> X<random>
4200
4201 =item rand
4202
4203 Returns a random fractional number greater than or equal to C<0> and less
4204 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4205 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4206 also special-cased as C<1> - this has not been documented before perl 5.8.0
4207 and is subject to change in future versions of perl.  Automatically calls
4208 C<srand> unless C<srand> has already been called.  See also C<srand>.
4209
4210 Apply C<int()> to the value returned by C<rand()> if you want random
4211 integers instead of random fractional numbers.  For example,
4212
4213     int(rand(10))
4214
4215 returns a random integer between C<0> and C<9>, inclusive.
4216
4217 (Note: If your rand function consistently returns numbers that are too
4218 large or too small, then your version of Perl was probably compiled
4219 with the wrong number of RANDBITS.)
4220
4221 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4222 X<read> X<file, read>
4223
4224 =item read FILEHANDLE,SCALAR,LENGTH
4225
4226 Attempts to read LENGTH I<characters> of data into variable SCALAR
4227 from the specified FILEHANDLE.  Returns the number of characters
4228 actually read, C<0> at end of file, or undef if there was an error (in
4229 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4230 so that the last character actually read is the last character of the
4231 scalar after the read.
4232
4233 An OFFSET may be specified to place the read data at some place in the
4234 string other than the beginning.  A negative OFFSET specifies
4235 placement at that many characters counting backwards from the end of
4236 the string.  A positive OFFSET greater than the length of SCALAR
4237 results in the string being padded to the required size with C<"\0">
4238 bytes before the result of the read is appended.
4239
4240 The call is actually implemented in terms of either Perl's or system's
4241 fread() call.  To get a true read(2) system call, see C<sysread>.
4242
4243 Note the I<characters>: depending on the status of the filehandle,
4244 either (8-bit) bytes or characters are read.  By default all
4245 filehandles operate on bytes, but for example if the filehandle has
4246 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4247 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4248 characters, not bytes.  Similarly for the C<:encoding> pragma:
4249 in that case pretty much any characters can be read.
4250
4251 =item readdir DIRHANDLE
4252 X<readdir>
4253
4254 Returns the next directory entry for a directory opened by C<opendir>.
4255 If used in list context, returns all the rest of the entries in the
4256 directory.  If there are no more entries, returns an undefined value in
4257 scalar context or a null list in list context.
4258
4259 If you're planning to filetest the return values out of a C<readdir>, you'd
4260 better prepend the directory in question.  Otherwise, because we didn't
4261 C<chdir> there, it would have been testing the wrong file.
4262
4263     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4264     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4265     closedir DIR;
4266
4267 =item readline EXPR
4268 X<readline> X<gets> X<fgets>
4269
4270 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4271 context, each call reads and returns the next line, until end-of-file is
4272 reached, whereupon the subsequent call returns undef.  In list context,
4273 reads until end-of-file is reached and returns a list of lines.  Note that
4274 the notion of "line" used here is however you may have defined it
4275 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4276
4277 When C<$/> is set to C<undef>, when readline() is in scalar
4278 context (i.e. file slurp mode), and when an empty file is read, it
4279 returns C<''> the first time, followed by C<undef> subsequently.
4280
4281 This is the internal function implementing the C<< <EXPR> >>
4282 operator, but you can use it directly.  The C<< <EXPR> >>
4283 operator is discussed in more detail in L<perlop/"I/O Operators">.
4284
4285     $line = <STDIN>;
4286     $line = readline(*STDIN);           # same thing
4287
4288 If readline encounters an operating system error, C<$!> will be set with the
4289 corresponding error message.  It can be helpful to check C<$!> when you are
4290 reading from filehandles you don't trust, such as a tty or a socket.  The
4291 following example uses the operator form of C<readline>, and takes the necessary
4292 steps to ensure that C<readline> was successful.
4293
4294     for (;;) {
4295         undef $!;
4296         unless (defined( $line = <> )) {
4297             die $! if $!;
4298             last; # reached EOF
4299         }
4300         # ...
4301     }
4302
4303 =item readlink EXPR
4304 X<readlink>
4305
4306 =item readlink
4307
4308 Returns the value of a symbolic link, if symbolic links are
4309 implemented.  If not, gives a fatal error.  If there is some system
4310 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4311 omitted, uses C<$_>.
4312
4313 =item readpipe EXPR
4314 X<readpipe>
4315
4316 EXPR is executed as a system command.
4317 The collected standard output of the command is returned.
4318 In scalar context, it comes back as a single (potentially
4319 multi-line) string.  In list context, returns a list of lines
4320 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4321 This is the internal function implementing the C<qx/EXPR/>
4322 operator, but you can use it directly.  The C<qx/EXPR/>
4323 operator is discussed in more detail in L<perlop/"I/O Operators">.
4324
4325 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4326 X<recv>
4327
4328 Receives a message on a socket.  Attempts to receive LENGTH characters
4329 of data into variable SCALAR from the specified SOCKET filehandle.
4330 SCALAR will be grown or shrunk to the length actually read.  Takes the
4331 same flags as the system call of the same name.  Returns the address
4332 of the sender if SOCKET's protocol supports this; returns an empty
4333 string otherwise.  If there's an error, returns the undefined value.
4334 This call is actually implemented in terms of recvfrom(2) system call.
4335 See L<perlipc/"UDP: Message Passing"> for examples.
4336
4337 Note the I<characters>: depending on the status of the socket, either
4338 (8-bit) bytes or characters are received.  By default all sockets
4339 operate on bytes, but for example if the socket has been changed using
4340 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4341 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4342 characters, not bytes.  Similarly for the C<:encoding> pragma:
4343 in that case pretty much any characters can be read.
4344
4345 =item redo LABEL
4346 X<redo>
4347
4348 =item redo
4349
4350 The C<redo> command restarts the loop block without evaluating the
4351 conditional again.  The C<continue> block, if any, is not executed.  If
4352 the LABEL is omitted, the command refers to the innermost enclosing
4353 loop.  Programs that want to lie to themselves about what was just input 
4354 normally use this command:
4355
4356     # a simpleminded Pascal comment stripper
4357     # (warning: assumes no { or } in strings)
4358     LINE: while (<STDIN>) {
4359         while (s|({.*}.*){.*}|$1 |) {}
4360         s|{.*}| |;
4361         if (s|{.*| |) {
4362             $front = $_;
4363             while (<STDIN>) {
4364                 if (/}/) {      # end of comment?
4365                     s|^|$front\{|;
4366                     redo LINE;
4367                 }
4368             }
4369         }
4370         print;
4371     }
4372
4373 C<redo> cannot be used to retry a block which returns a value such as
4374 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4375 a grep() or map() operation.
4376
4377 Note that a block by itself is semantically identical to a loop
4378 that executes once.  Thus C<redo> inside such a block will effectively
4379 turn it into a looping construct.
4380
4381 See also L</continue> for an illustration of how C<last>, C<next>, and
4382 C<redo> work.
4383
4384 =item ref EXPR
4385 X<ref> X<reference>
4386
4387 =item ref
4388
4389 Returns a non-empty string if EXPR is a reference, the empty
4390 string otherwise. If EXPR
4391 is not specified, C<$_> will be used.  The value returned depends on the
4392 type of thing the reference is a reference to.
4393 Builtin types include:
4394
4395     SCALAR
4396     ARRAY
4397     HASH
4398     CODE
4399     REF
4400     GLOB
4401     LVALUE
4402     FORMAT
4403     IO
4404     VSTRING
4405     Regexp
4406
4407 If the referenced object has been blessed into a package, then that package
4408 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4409
4410     if (ref($r) eq "HASH") {
4411         print "r is a reference to a hash.\n";
4412     }
4413     unless (ref($r)) {
4414         print "r is not a reference at all.\n";
4415     }
4416
4417 See also L<perlref>.
4418
4419 =item rename OLDNAME,NEWNAME
4420 X<rename> X<move> X<mv> X<ren>
4421
4422 Changes the name of a file; an existing file NEWNAME will be
4423 clobbered.  Returns true for success, false otherwise.
4424
4425 Behavior of this function varies wildly depending on your system
4426 implementation.  For example, it will usually not work across file system
4427 boundaries, even though the system I<mv> command sometimes compensates
4428 for this.  Other restrictions include whether it works on directories,
4429 open files, or pre-existing files.  Check L<perlport> and either the
4430 rename(2) manpage or equivalent system documentation for details.
4431
4432 For a platform independent C<move> function look at the L<File::Copy>
4433 module.
4434
4435 =item require VERSION
4436 X<require>
4437
4438 =item require EXPR
4439
4440 =item require
4441
4442 Demands a version of Perl specified by VERSION, or demands some semantics
4443 specified by EXPR or by C<$_> if EXPR is not supplied.
4444
4445 VERSION may be either a numeric argument such as 5.006, which will be
4446 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4447 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4448 VERSION is greater than the version of the current Perl interpreter.
4449 Compare with L</use>, which can do a similar check at compile time.
4450
4451 Specifying VERSION as a literal of the form v5.6.1 should generally be
4452 avoided, because it leads to misleading error messages under earlier
4453 versions of Perl that do not support this syntax.  The equivalent numeric
4454 version should be used instead.
4455
4456     require v5.6.1;     # run time version check
4457     require 5.6.1;      # ditto
4458     require 5.006_001;  # ditto; preferred for backwards compatibility
4459
4460 Otherwise, C<require> demands that a library file be included if it
4461 hasn't already been included.  The file is included via the do-FILE
4462 mechanism, which is essentially just a variety of C<eval>.  Has
4463 semantics similar to the following subroutine:
4464
4465     sub require {
4466        my ($filename) = @_;
4467        if (exists $INC{$filename}) {
4468            return 1 if $INC{$filename};
4469            die "Compilation failed in require";
4470        }
4471        my ($realfilename,$result);
4472        ITER: {
4473            foreach $prefix (@INC) {
4474                $realfilename = "$prefix/$filename";
4475                if (-f $realfilename) {
4476                    $INC{$filename} = $realfilename;
4477                    $result = do $realfilename;
4478                    last ITER;
4479                }
4480            }
4481            die "Can't find $filename in \@INC";
4482        }
4483        if ($@) {
4484            $INC{$filename} = undef;
4485            die $@;
4486        } elsif (!$result) {
4487            delete $INC{$filename};
4488            die "$filename did not return true value";
4489        } else {
4490            return $result;
4491        }
4492     }
4493
4494 Note that the file will not be included twice under the same specified
4495 name.
4496
4497 The file must return true as the last statement to indicate
4498 successful execution of any initialization code, so it's customary to
4499 end such a file with C<1;> unless you're sure it'll return true
4500 otherwise.  But it's better just to put the C<1;>, in case you add more
4501 statements.
4502
4503 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4504 replaces "F<::>" with "F</>" in the filename for you,
4505 to make it easy to load standard modules.  This form of loading of
4506 modules does not risk altering your namespace.
4507
4508 In other words, if you try this:
4509
4510         require Foo::Bar;    # a splendid bareword
4511
4512 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4513 directories specified in the C<@INC> array.
4514
4515 But if you try this:
4516
4517         $class = 'Foo::Bar';
4518         require $class;      # $class is not a bareword
4519     #or
4520         require "Foo::Bar";  # not a bareword because of the ""
4521
4522 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4523 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4524
4525         eval "require $class";
4526
4527 Now that you understand how C<require> looks for files in the case of a
4528 bareword argument, there is a little extra functionality going on behind
4529 the scenes.  Before C<require> looks for a "F<.pm>" extension, it will
4530 first look for a similar filename with a "F<.pmc>" extension. If this file
4531 is found, it will be loaded in place of any file ending in a "F<.pm>"
4532 extension.
4533
4534 You can also insert hooks into the import facility, by putting directly
4535 Perl code into the @INC array.  There are three forms of hooks: subroutine
4536 references, array references and blessed objects.
4537
4538 Subroutine references are the simplest case.  When the inclusion system
4539 walks through @INC and encounters a subroutine, this subroutine gets
4540 called with two parameters, the first being a reference to itself, and the
4541 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4542 subroutine should return nothing, or a list of up to three values in the
4543 following order:
4544
4545 =over
4546
4547 =item 1
4548
4549 A filehandle, from which the file will be read.  
4550
4551 =item 2
4552
4553 A reference to a subroutine. If there is no filehandle (previous item),
4554 then this subroutine is expected to generate one line of source code per
4555 call, writing the line into C<$_> and returning 1, then returning 0 at
4556 "end of file". If there is a filehandle, then the subroutine will be
4557 called to act a simple source filter, with the line as read in C<$_>.
4558 Again, return 1 for each valid line, and 0 after all lines have been
4559 returned.
4560
4561 =item 3
4562
4563 Optional state for the subroutine. The state is passed in as C<$_[1]>. A
4564 reference to the subroutine itself is passed in as C<$_[0]>.
4565
4566 =back
4567
4568 If an empty list, C<undef>, or nothing that matches the first 3 values above
4569 is returned then C<require> will look at the remaining elements of @INC.
4570 Note that this file handle must be a real file handle (strictly a typeglob,
4571 or reference to a typeglob, blessed or unblessed) - tied file handles will be
4572 ignored and return value processing will stop there.
4573
4574 If the hook is an array reference, its first element must be a subroutine
4575 reference.  This subroutine is called as above, but the first parameter is
4576 the array reference.  This enables to pass indirectly some arguments to
4577 the subroutine.
4578
4579 In other words, you can write:
4580
4581     push @INC, \&my_sub;
4582     sub my_sub {
4583         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4584         ...
4585     }
4586
4587 or:
4588
4589     push @INC, [ \&my_sub, $x, $y, ... ];
4590     sub my_sub {
4591         my ($arrayref, $filename) = @_;
4592         # Retrieve $x, $y, ...
4593         my @parameters = @$arrayref[1..$#$arrayref];
4594         ...
4595     }
4596
4597 If the hook is an object, it must provide an INC method that will be
4598 called as above, the first parameter being the object itself.  (Note that
4599 you must fully qualify the sub's name, as unqualified C<INC> is always forced
4600 into package C<main>.)  Here is a typical code layout:
4601
4602     # In Foo.pm
4603     package Foo;
4604     sub new { ... }
4605     sub Foo::INC {
4606         my ($self, $filename) = @_;
4607         ...
4608     }
4609
4610     # In the main program
4611     push @INC, new Foo(...);
4612
4613 Note that these hooks are also permitted to set the %INC entry
4614 corresponding to the files they have loaded. See L<perlvar/%INC>.
4615
4616 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4617
4618 =item reset EXPR
4619 X<reset>
4620
4621 =item reset
4622
4623 Generally used in a C<continue> block at the end of a loop to clear