This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
fixes bug 20000508.004
[perl5.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8
9 Perl has three built-in data types: scalars, arrays of scalars, and
10 associative arrays of scalars, known as "hashes".  Normal arrays
11 are ordered lists of scalars indexed by number, starting with 0 and with
12 negative subscripts counting from the end.  Hashes are unordered
13 collections of scalar values indexed by their associated string key.
14
15 Values are usually referred to by name, or through a named reference.
16 The first character of the name tells you to what sort of data
17 structure it refers.  The rest of the name tells you the particular
18 value to which it refers.  Usually this name is a single I<identifier>,
19 that is, a string beginning with a letter or underscore, and
20 containing letters, underscores, and digits.  In some cases, it may
21 be a chain of identifiers, separated by C<::> (or by the slightly
22 archaic C<'>); all but the last are interpreted as names of packages,
23 to locate the namespace in which to look up the final identifier
24 (see L<perlmod/Packages> for details).  It's possible to substitute
25 for a simple identifier, an expression that produces a reference
26 to the value at runtime.   This is described in more detail below
27 and in L<perlref>.
28
29 Perl also has its own built-in variables whose names don't follow
30 these rules.  They have strange names so they don't accidentally
31 collide with one of your normal variables.  Strings that match
32 parenthesized parts of a regular expression are saved under names
33 containing only digits after the C<$> (see L<perlop> and L<perlre>).
34 In addition, several special variables that provide windows into
35 the inner working of Perl have names containing punctuation characters
36 and control characters.  These are documented in L<perlvar>.
37
38 Scalar values are always named with '$', even when referring to a
39 scalar that is part of an array or a hash.  The '$' symbol works
40 semantically like the English word "the" in that it indicates a
41 single value is expected.
42
43     $days               # the simple scalar value "days"
44     $days[28]           # the 29th element of array @days
45     $days{'Feb'}        # the 'Feb' value from hash %days
46     $#days              # the last index of array @days
47
48 Entire arrays (and slices of arrays and hashes) are denoted by '@',
49 which works much like the word "these" or "those" does in English,
50 in that it indicates multiple values are expected.
51
52     @days               # ($days[0], $days[1],... $days[n])
53     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
54     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
55
56 Entire hashes are denoted by '%':
57
58     %days               # (key1, val1, key2, val2 ...)
59
60 In addition, subroutines are named with an initial '&', though this
61 is optional when unambiguous, just as the word "do" is often redundant
62 in English.  Symbol table entries can be named with an initial '*',
63 but you don't really care about that yet (if ever :-).
64
65 Every variable type has its own namespace, as do several
66 non-variable identifiers.  This means that you can, without fear
67 of conflict, use the same name for a scalar variable, an array, or
68 a hash--or, for that matter, for a filehandle, a directory handle, a
69 subroutine name, a format name, or a label.  This means that $foo
70 and @foo are two different variables.  It also means that C<$foo[1]>
71 is a part of @foo, not a part of $foo.  This may seem a bit weird,
72 but that's okay, because it is weird.
73
74 Because variable references always start with '$', '@', or '%', the
75 "reserved" words aren't in fact reserved with respect to variable
76 names.  They I<are> reserved with respect to labels and filehandles,
77 however, which don't have an initial special character.  You can't
78 have a filehandle named "log", for instance.  Hint: you could say
79 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
80 uppercase filehandles also improves readability and protects you
81 from conflict with future reserved words.  Case I<is> significant--"FOO",
82 "Foo", and "foo" are all different names.  Names that start with a
83 letter or underscore may also contain digits and underscores.
84
85 It is possible to replace such an alphanumeric name with an expression
86 that returns a reference to the appropriate type.  For a description
87 of this, see L<perlref>.
88
89 Names that start with a digit may contain only more digits.  Names
90 that do not start with a letter, underscore, or digit are limited to
91 one character, e.g.,  C<$%> or C<$$>.  (Most of these one character names
92 have a predefined significance to Perl.  For instance, C<$$> is the
93 current process id.)
94
95 =head2 Context
96
97 The interpretation of operations and values in Perl sometimes depends
98 on the requirements of the context around the operation or value.
99 There are two major contexts: list and scalar.  Certain operations
100 return list values in contexts wanting a list, and scalar values
101 otherwise.  If this is true of an operation it will be mentioned in
102 the documentation for that operation.  In other words, Perl overloads
103 certain operations based on whether the expected return value is
104 singular or plural.  Some words in English work this way, like "fish"
105 and "sheep".
106
107 In a reciprocal fashion, an operation provides either a scalar or a
108 list context to each of its arguments.  For example, if you say
109
110     int( <STDIN> )
111
112 the integer operation provides scalar context for the <>
113 operator, which responds by reading one line from STDIN and passing it
114 back to the integer operation, which will then find the integer value
115 of that line and return that.  If, on the other hand, you say
116
117     sort( <STDIN> )
118
119 then the sort operation provides list context for <>, which
120 will proceed to read every line available up to the end of file, and
121 pass that list of lines back to the sort routine, which will then
122 sort those lines and return them as a list to whatever the context
123 of the sort was.
124
125 Assignment is a little bit special in that it uses its left argument
126 to determine the context for the right argument.  Assignment to a
127 scalar evaluates the right-hand side in scalar context, while
128 assignment to an array or hash evaluates the righthand side in list
129 context.  Assignment to a list (or slice, which is just a list
130 anyway) also evaluates the righthand side in list context.
131
132 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
133 option, you may see warnings
134 about useless uses of constants or functions in "void context".
135 Void context just means the value has been discarded, such as a
136 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
137 counts as scalar context for functions that care whether or not
138 they're being called in list context.
139
140 User-defined subroutines may choose to care whether they are being
141 called in a void, scalar, or list context.  Most subroutines do not
142 need to bother, though.  That's because both scalars and lists are
143 automatically interpolated into lists.  See L<perlfunc/wantarray>
144 for how you would dynamically discern your function's calling
145 context.
146
147 =head2 Scalar values
148
149 All data in Perl is a scalar, an array of scalars, or a hash of
150 scalars.  A scalar may contain one single value in any of three
151 different flavors: a number, a string, or a reference.  In general,
152 conversion from one form to another is transparent.  Although a
153 scalar may not directly hold multiple values, it may contain a
154 reference to an array or hash which in turn contains multiple values.
155
156 Scalars aren't necessarily one thing or another.  There's no place
157 to declare a scalar variable to be of type "string", type "number",
158 type "reference", or anything else.  Because of the automatic
159 conversion of scalars, operations that return scalars don't need
160 to care (and in fact, cannot care) whether their caller is looking
161 for a string, a number, or a reference.  Perl is a contextually
162 polymorphic language whose scalars can be strings, numbers, or
163 references (which includes objects).  Although strings and numbers
164 are considered pretty much the same thing for nearly all purposes,
165 references are strongly-typed, uncastable pointers with builtin
166 reference-counting and destructor invocation.
167
168 A scalar value is interpreted as TRUE in the Boolean sense if it is not
169 the null string or the number 0 (or its string equivalent, "0").  The
170 Boolean context is just a special kind of scalar context where no 
171 conversion to a string or a number is ever performed.
172
173 There are actually two varieties of null strings (sometimes referred
174 to as "empty" strings), a defined one and an undefined one.  The
175 defined version is just a string of length zero, such as C<"">.
176 The undefined version is the value that indicates that there is
177 no real value for something, such as when there was an error, or
178 at end of file, or when you refer to an uninitialized variable or
179 element of an array or hash.  Although in early versions of Perl,
180 an undefined scalar could become defined when first used in a
181 place expecting a defined value, this no longer happens except for
182 rare cases of autovivification as explained in L<perlref>.  You can
183 use the defined() operator to determine whether a scalar value is
184 defined (this has no meaning on arrays or hashes), and the undef()
185 operator to produce an undefined value.
186
187 To find out whether a given string is a valid non-zero number, it's
188 sometimes enough to test it against both numeric 0 and also lexical
189 "0" (although this will cause B<-w> noises).  That's because strings
190 that aren't numbers count as 0, just as they do in B<awk>:
191
192     if ($str == 0 && $str ne "0")  {
193         warn "That doesn't look like a number";
194     }
195
196 That method may be best because otherwise you won't treat IEEE
197 notations like C<NaN> or C<Infinity> properly.  At other times, you
198 might prefer to determine whether string data can be used numerically
199 by calling the POSIX::strtod() function or by inspecting your string
200 with a regular expression (as documented in L<perlre>).
201
202     warn "has nondigits"        if     /\D/;
203     warn "not a natural number" unless /^\d+$/;             # rejects -3
204     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
205     warn "not an integer"       unless /^[+-]?\d+$/;
206     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
207     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
208     warn "not a C float"
209         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
210
211 The length of an array is a scalar value.  You may find the length
212 of array @days by evaluating C<$#days>, as in B<csh>.  Technically
213 speaking, this isn't the length of the array; it's the subscript
214 of the last element, since there is ordinarily a 0th element.
215 Assigning to C<$#days> actually changes the length of the array.
216 Shortening an array this way destroys intervening values.  Lengthening
217 an array that was previously shortened does not recover values
218 that were in those elements.  (It used to do so in Perl 4, but we
219 had to break this to make sure destructors were called when expected.)
220
221 You can also gain some miniscule measure of efficiency by pre-extending
222 an array that is going to get big.  You can also extend an array
223 by assigning to an element that is off the end of the array.  You
224 can truncate an array down to nothing by assigning the null list
225 () to it.  The following are equivalent:
226
227     @whatever = ();
228     $#whatever = -1;
229
230 If you evaluate an array in scalar context, it returns the length
231 of the array.  (Note that this is not true of lists, which return
232 the last value, like the C comma operator, nor of built-in functions,
233 which return whatever they feel like returning.)  The following is
234 always true:
235
236     scalar(@whatever) == $#whatever - $[ + 1;
237
238 Version 5 of Perl changed the semantics of C<$[>: files that don't set
239 the value of C<$[> no longer need to worry about whether another
240 file changed its value.  (In other words, use of C<$[> is deprecated.)
241 So in general you can assume that
242
243     scalar(@whatever) == $#whatever + 1;
244
245 Some programmers choose to use an explicit conversion so as to 
246 leave nothing to doubt:
247
248     $element_count = scalar(@whatever);
249
250 If you evaluate a hash in scalar context, it returns false if the
251 hash is empty.  If there are any key/value pairs, it returns true;
252 more precisely, the value returned is a string consisting of the
253 number of used buckets and the number of allocated buckets, separated
254 by a slash.  This is pretty much useful only to find out whether
255 Perl's internal hashing algorithm is performing poorly on your data
256 set.  For example, you stick 10,000 things in a hash, but evaluating
257 %HASH in scalar context reveals C<"1/16">, which means only one out
258 of sixteen buckets has been touched, and presumably contains all
259 10,000 of your items.  This isn't supposed to happen.
260
261 You can preallocate space for a hash by assigning to the keys() function.
262 This rounds up the allocated buckets to the next power of two:
263
264     keys(%users) = 1000;                # allocate 1024 buckets
265
266 =head2 Scalar value constructors
267
268 Numeric literals are specified in any of the following floating point or
269 integer formats:
270
271     12345
272     12345.67
273     .23E-10             # a very small number
274     4_294_967_296       # underline for legibility
275     0xff                # hex
276     0377                # octal
277     0b011011            # binary
278
279 String literals are usually delimited by either single or double
280 quotes.  They work much like quotes in the standard Unix shells:
281 double-quoted string literals are subject to backslash and variable
282 substitution; single-quoted strings are not (except for C<\'> and
283 C<\\>).  The usual C-style backslash rules apply for making
284 characters such as newline, tab, etc., as well as some more exotic
285 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
286
287 Hexadecimal, octal, or binary, representations in string literals
288 (e.g. '0xff') are not automatically converted to their integer
289 representation.  The hex() and oct() functions make these conversions
290 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
291
292 You can also embed newlines directly in your strings, i.e., they can end
293 on a different line than they begin.  This is nice, but if you forget
294 your trailing quote, the error will not be reported until Perl finds
295 another line containing the quote character, which may be much further
296 on in the script.  Variable substitution inside strings is limited to
297 scalar variables, arrays, and array or hash slices.  (In other words,
298 names beginning with $ or @, followed by an optional bracketed
299 expression as a subscript.)  The following code segment prints out "The
300 price is $Z<>100."
301
302     $Price = '$100';    # not interpreted
303     print "The price is $Price.\n";     # interpreted
304
305 As in some shells, you can enclose the variable name in braces to
306 disambiguate it from following alphanumerics (and underscores).
307 You must also do
308 this when interpolating a variable into a string to separate the
309 variable name from a following double-colon or an apostrophe, since
310 these would be otherwise treated as a package separator:
311
312     $who = "Larry";
313     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
314     print "We use ${who}speak when ${who}'s here.\n";
315
316 Without the braces, Perl would have looked for a $whospeak, a
317 C<$who::0>, and a C<$who's> variable.  The last two would be the
318 $0 and the $s variables in the (presumably) non-existent package
319 C<who>.
320
321 In fact, an identifier within such curlies is forced to be a string,
322 as is any simple identifier within a hash subscript.  Neither need
323 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
324 C<$days{Feb}> and the quotes will be assumed automatically.  But
325 anything more complicated in the subscript will be interpreted as
326 an expression.
327
328 A literal of the form C<v1.20.300.4000> is parsed as a string composed
329 of characters with the specified ordinals.  This provides an alternative,
330 more readable way to construct strings, rather than use the somewhat less
331 readable interpolation form C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful
332 for representing Unicode strings, and for comparing version "numbers"
333 using the string comparison operators, C<cmp>, C<gt>, C<lt> etc.
334 If there are two or more dots in the literal, the leading C<v> may be
335 omitted.
336
337     print v9786;              # prints UTF-8 encoded SMILEY, "\x{263a}"
338     print v102.111.111;       # prints "foo"
339     print 102.111.111;        # same
340
341 Such literals are accepted by both C<require> and C<use> for
342 doing a version check.  The C<$^V> special variable also contains the
343 running Perl interpreter's version in this form.  See L<perlvar/$^V>.
344
345 The special literals __FILE__, __LINE__, and __PACKAGE__
346 represent the current filename, line number, and package name at that
347 point in your program.  They may be used only as separate tokens; they
348 will not be interpolated into strings.  If there is no current package
349 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
350 value.
351
352 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
353 may be used to indicate the logical end of the script before the actual
354 end of file.  Any following text is ignored.
355
356 Text after __DATA__ but may be read via the filehandle C<PACKNAME::DATA>,
357 where C<PACKNAME> is the package that was current when the __DATA__
358 token was encountered.  The filehandle is left open pointing to the
359 contents after __DATA__.  It is the program's responsibility to
360 C<close DATA> when it is done reading from it.  For compatibility with
361 older scripts written before __DATA__ was introduced, __END__ behaves
362 like __DATA__ in the toplevel script (but not in files loaded with
363 C<require> or C<do>) and leaves the remaining contents of the
364 file accessible via C<main::DATA>.
365
366 See L<SelfLoader> for more description of __DATA__, and
367 an example of its use.  Note that you cannot read from the DATA
368 filehandle in a BEGIN block: the BEGIN block is executed as soon
369 as it is seen (during compilation), at which point the corresponding
370 __DATA__ (or __END__) token has not yet been seen.
371
372 A word that has no other interpretation in the grammar will
373 be treated as if it were a quoted string.  These are known as
374 "barewords".  As with filehandles and labels, a bareword that consists
375 entirely of lowercase letters risks conflict with future reserved
376 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
377 Perl will warn you about any
378 such words.  Some people may wish to outlaw barewords entirely.  If you
379 say
380
381     use strict 'subs';
382
383 then any bareword that would NOT be interpreted as a subroutine call
384 produces a compile-time error instead.  The restriction lasts to the
385 end of the enclosing block.  An inner block may countermand this
386 by saying C<no strict 'subs'>.
387
388 Arrays and slices are interpolated into double-quoted strings
389 by joining the elements with the delimiter specified in the C<$">
390 variable (C<$LIST_SEPARATOR> in English), space by default.  The
391 following are equivalent:
392
393     $temp = join($", @ARGV);
394     system "echo $temp";
395
396     system "echo @ARGV";
397
398 Within search patterns (which also undergo double-quotish substitution)
399 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
400 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
401 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
402 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
403 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
404 and is almost always right.  If it does guess wrong, or if you're just
405 plain paranoid, you can force the correct interpretation with curly
406 braces as above.
407
408 A line-oriented form of quoting is based on the shell "here-document"
409 syntax.  Following a C<< << >> you specify a string to terminate
410 the quoted material, and all lines following the current line down to
411 the terminating string are the value of the item.  The terminating
412 string may be either an identifier (a word), or some quoted text.  If
413 quoted, the type of quotes you use determines the treatment of the
414 text, just as in regular quoting.  An unquoted identifier works like
415 double quotes.  There must be no space between the C<< << >> and
416 the identifier.  (If you put a space it will be treated as a null
417 identifier, which is valid, and matches the first empty line.)  The
418 terminating string must appear by itself (unquoted and with no
419 surrounding whitespace) on the terminating line.
420
421         print <<EOF;
422     The price is $Price.
423     EOF
424
425         print <<"EOF";  # same as above
426     The price is $Price.
427     EOF
428
429         print <<`EOC`;  # execute commands
430     echo hi there
431     echo lo there
432     EOC
433
434         print <<"foo", <<"bar"; # you can stack them
435     I said foo.
436     foo
437     I said bar.
438     bar
439
440         myfunc(<<"THIS", 23, <<'THAT');
441     Here's a line
442     or two.
443     THIS
444     and here's another.
445     THAT
446
447 Just don't forget that you have to put a semicolon on the end
448 to finish the statement, as Perl doesn't know you're not going to
449 try to do this:
450
451         print <<ABC
452     179231
453     ABC
454         + 20;
455
456 If you want your here-docs to be indented with the 
457 rest of the code, you'll need to remove leading whitespace
458 from each line manually:
459
460     ($quote = <<'FINIS') =~ s/^\s+//gm;
461         The Road goes ever on and on, 
462         down from the door where it began.
463     FINIS
464
465 =head2 List value constructors
466
467 List values are denoted by separating individual values by commas
468 (and enclosing the list in parentheses where precedence requires it):
469
470     (LIST)
471
472 In a context not requiring a list value, the value of what appears
473 to be a list literal is simply the value of the final element, as
474 with the C comma operator.  For example,
475
476     @foo = ('cc', '-E', $bar);
477
478 assigns the entire list value to array @foo, but
479
480     $foo = ('cc', '-E', $bar);
481
482 assigns the value of variable $bar to the scalar variable $foo.
483 Note that the value of an actual array in scalar context is the
484 length of the array; the following assigns the value 3 to $foo:
485
486     @foo = ('cc', '-E', $bar);
487     $foo = @foo;                # $foo gets 3
488
489 You may have an optional comma before the closing parenthesis of a
490 list literal, so that you can say:
491
492     @foo = (
493         1,
494         2,
495         3,
496     );
497
498 To use a here-document to assign an array, one line per element,
499 you might use an approach like this:
500
501     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
502         normal tomato
503         spicy tomato
504         green chile
505         pesto
506         white wine
507     End_Lines
508
509 LISTs do automatic interpolation of sublists.  That is, when a LIST is
510 evaluated, each element of the list is evaluated in list context, and
511 the resulting list value is interpolated into LIST just as if each
512 individual element were a member of LIST.  Thus arrays and hashes lose their
513 identity in a LIST--the list
514
515     (@foo,@bar,&SomeSub,%glarch)
516
517 contains all the elements of @foo followed by all the elements of @bar,
518 followed by all the elements returned by the subroutine named SomeSub 
519 called in list context, followed by the key/value pairs of %glarch.
520 To make a list reference that does I<NOT> interpolate, see L<perlref>.
521
522 The null list is represented by ().  Interpolating it in a list
523 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
524 interpolating an array with no elements is the same as if no
525 array had been interpolated at that point.
526
527 A list value may also be subscripted like a normal array.  You must
528 put the list in parentheses to avoid ambiguity.  For example:
529
530     # Stat returns list value.
531     $time = (stat($file))[8];
532
533     # SYNTAX ERROR HERE.
534     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
535
536     # Find a hex digit.
537     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
538
539     # A "reverse comma operator".
540     return (pop(@foo),pop(@foo))[0];
541
542 Lists may be assigned to only when each element of the list
543 is itself legal to assign to:
544
545     ($a, $b, $c) = (1, 2, 3);
546
547     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
548
549 An exception to this is that you may assign to C<undef> in a list.
550 This is useful for throwing away some of the return values of a
551 function:
552
553     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
554
555 List assignment in scalar context returns the number of elements
556 produced by the expression on the right side of the assignment:
557
558     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
559     $x = (($foo,$bar) = f());           # set $x to f()'s return count
560
561 This is handy when you want to do a list assignment in a Boolean
562 context, because most list functions return a null list when finished,
563 which when assigned produces a 0, which is interpreted as FALSE.
564
565 The final element may be an array or a hash:
566
567     ($a, $b, @rest) = split;
568     my($a, $b, %rest) = @_;
569
570 You can actually put an array or hash anywhere in the list, but the first one
571 in the list will soak up all the values, and anything after it will become
572 undefined.  This may be useful in a my() or local().
573
574 A hash can be initialized using a literal list holding pairs of
575 items to be interpreted as a key and a value:
576
577     # same as map assignment above
578     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
579
580 While literal lists and named arrays are often interchangeable, that's
581 not the case for hashes.  Just because you can subscript a list value like
582 a normal array does not mean that you can subscript a list value as a
583 hash.  Likewise, hashes included as parts of other lists (including
584 parameters lists and return lists from functions) always flatten out into
585 key/value pairs.  That's why it's good to use references sometimes.
586
587 It is often more readable to use the C<< => >> operator between key/value
588 pairs.  The C<< => >> operator is mostly just a more visually distinctive
589 synonym for a comma, but it also arranges for its left-hand operand to be
590 interpreted as a string--if it's a bareword that would be a legal identifier.
591 This makes it nice for initializing hashes:
592
593     %map = (
594                  red   => 0x00f,
595                  blue  => 0x0f0,
596                  green => 0xf00,
597    );
598
599 or for initializing hash references to be used as records:
600
601     $rec = {
602                 witch => 'Mable the Merciless',
603                 cat   => 'Fluffy the Ferocious',
604                 date  => '10/31/1776',
605     };
606
607 or for using call-by-named-parameter to complicated functions:
608
609    $field = $query->radio_group(
610                name      => 'group_name',
611                values    => ['eenie','meenie','minie'],
612                default   => 'meenie',
613                linebreak => 'true',
614                labels    => \%labels
615    );
616
617 Note that just because a hash is initialized in that order doesn't
618 mean that it comes out in that order.  See L<perlfunc/sort> for examples
619 of how to arrange for an output ordering.
620
621 =head2 Slices
622
623 A common way to access an array or a hash is one scalar element at a
624 time.  You can also subscript a list to get a single element from it.
625
626     $whoami = $ENV{"USER"};             # one element from the hash
627     $parent = $ISA[0];                  # one element from the array
628     $dir    = (getpwnam("daemon"))[7];  # likewise, but with list
629
630 A slice accesses several elements of a list, an array, or a hash
631 simultaneously using a list of subscripts.  It's more convenient
632 than writing out the individual elements as a list of separate
633 scalar values.
634
635     ($him, $her)   = @folks[0,-1];              # array slice
636     @them          = @folks[0 .. 3];            # array slice
637     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
638     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
639
640 Since you can assign to a list of variables, you can also assign to
641 an array or hash slice.
642
643     @days[3..5]    = qw/Wed Thu Fri/;
644     @colors{'red','blue','green'} 
645                    = (0xff0000, 0x0000ff, 0x00ff00);
646     @folks[0, -1]  = @folks[-1, 0];
647
648 The previous assignments are exactly equivalent to
649
650     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
651     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
652                    = (0xff0000, 0x0000ff, 0x00ff00);
653     ($folks[0], $folks[-1]) = ($folks[0], $folks[-1]);
654
655 Since changing a slice changes the original array or hash that it's
656 slicing, a C<foreach> construct will alter some--or even all--of the
657 values of the array or hash.
658
659     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
660
661     foreach (@hash{keys %hash}) {
662         s/^\s+//;           # trim leading whitespace
663         s/\s+$//;           # trim trailing whitespace
664         s/(\w+)/\u\L$1/g;   # "titlecase" words
665     }
666
667 A slice of an empty list is still an empty list.  Thus:
668
669     @a = ()[1,0];           # @a has no elements
670     @b = (@a)[0,1];         # @b has no elements
671     @c = (0,1)[2,3];        # @c has no elements
672
673 But:
674
675     @a = (1)[1,0];          # @a has two elements
676     @b = (1,undef)[1,0,2];  # @b has three elements
677
678 This makes it easy to write loops that terminate when a null list
679 is returned:
680
681     while ( ($home, $user) = (getpwent)[7,0]) {
682         printf "%-8s %s\n", $user, $home;
683     }
684
685 As noted earlier in this document, the scalar sense of list assignment
686 is the number of elements on the right-hand side of the assignment.
687 The null list contains no elements, so when the password file is
688 exhausted, the result is 0, not 2.
689
690 If you're confused about why you use an '@' there on a hash slice
691 instead of a '%', think of it like this.  The type of bracket (square
692 or curly) governs whether it's an array or a hash being looked at.
693 On the other hand, the leading symbol ('$' or '@') on the array or
694 hash indicates whether you are getting back a singular value (a
695 scalar) or a plural one (a list).
696
697 =head2 Typeglobs and Filehandles
698
699 Perl uses an internal type called a I<typeglob> to hold an entire
700 symbol table entry.  The type prefix of a typeglob is a C<*>, because
701 it represents all types.  This used to be the preferred way to
702 pass arrays and hashes by reference into a function, but now that
703 we have real references, this is seldom needed.  
704
705 The main use of typeglobs in modern Perl is create symbol table aliases.
706 This assignment:
707
708     *this = *that;
709
710 makes $this an alias for $that, @this an alias for @that, %this an alias
711 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
712 This:
713
714     local *Here::blue = \$There::green;
715
716 temporarily makes $Here::blue an alias for $There::green, but doesn't
717 make @Here::blue an alias for @There::green, or %Here::blue an alias for
718 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
719 of this.  Strange though this may seem, this is the basis for the whole
720 module import/export system.
721
722 Another use for typeglobs is to pass filehandles into a function or
723 to create new filehandles.  If you need to use a typeglob to save away
724 a filehandle, do it this way:
725
726     $fh = *STDOUT;
727
728 or perhaps as a real reference, like this:
729
730     $fh = \*STDOUT;
731
732 See L<perlsub> for examples of using these as indirect filehandles
733 in functions.
734
735 Typeglobs are also a way to create a local filehandle using the local()
736 operator.  These last until their block is exited, but may be passed back.
737 For example:
738
739     sub newopen {
740         my $path = shift;
741         local  *FH;  # not my!
742         open   (FH, $path)          or  return undef;
743         return *FH;
744     }
745     $fh = newopen('/etc/passwd');
746
747 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
748 for filehandle manipulations, although they're still needed to pass brand
749 new file and directory handles into or out of functions. That's because
750 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
751 In other words, C<*FH> must be used to create new symbol table entries;
752 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
753
754 All functions that are capable of creating filehandles (open(),
755 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
756 automatically create an anonymous filehandle if the handle passed to
757 them is an uninitialized scalar variable. This allows the constructs
758 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
759 create filehandles that will conveniently be closed automatically when
760 the scope ends, provided there are no other references to them. This
761 largely eliminates the need for typeglobs when opening filehandles
762 that must be passed around, as in the following example:
763
764     sub myopen {
765         open my $fh, "@_"
766              or die "Can't open '@_': $!";
767         return $fh;
768     }
769
770     {
771         my $f = myopen("</etc/motd");
772         print <$f>;
773         # $f implicitly closed here
774     }
775
776 Another way to create anonymous filehandles is with the Symbol
777 module or with the IO::Handle module and its ilk.  These modules
778 have the advantage of not hiding different types of the same name
779 during the local().  See the bottom of L<perlfunc/open()> for an
780 example.
781
782 =head1 SEE ALSO
783
784 See L<perlvar> for a description of Perl's built-in variables and
785 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
786 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
787 the C<*foo{THING}> syntax.