write_buildcustomize.pl

   1 #!./miniperl -w
   2
   3 use strict;
   4
   5 my $osname = $^O;
   6 my $file = 'lib/buildcustomize.pl';
   7
   8 if ( @ARGV % 2 ) {
   9     my $dir = shift;
  10     chdir $dir or die "Can't chdir '$dir': $!";
  11     unshift @INC, 'lib';
  12 }
  13
  14 if ( @ARGV ) {
  15     # Used during cross-compilation.
  16     $osname = $ARGV[1];
  17 }
  18
  19 # To clarify, this isn't the entire suite of modules considered "toolchain"
  20 # It's not even all modules needed to build ext/
  21 # It's just the source paths of the (minimum complete set of) modules in ext/
  22 # needed to build the nonxs modules
  23 # After which, all nonxs modules are in lib, which was always sufficient to
  24 # allow miniperl to build everything else.
  25 # Term::ReadLine is not here for building but for allowing the debugger to
  26 # run under miniperl when nothing but miniperl will build :-(.
  27
  28 my @toolchain = qw(cpan/AutoLoader/lib
  29                    dist/Carp/lib
  30                    dist/PathTools dist/PathTools/lib
  31                    dist/ExtUtils-Command/lib
  32                    dist/ExtUtils-Install/lib
  33                    cpan/ExtUtils-MakeMaker/lib
  34                    dist/ExtUtils-Manifest/lib
  35                    cpan/File-Path/lib
  36                    ext/re
  37                    dist/Term-ReadLine/lib
  38                    dist/Exporter/lib
  39                    ext/File-Find/lib
  40                    cpan/Text-Tabs/lib
  41                    dist/constant/lib
  42                    );
  43
  44 # Used only in ExtUtils::Liblist::Kid::_win32_ext()
  45 push @toolchain, 'cpan/Text-ParseWords/lib' if $^O eq 'MSWin32';
  46 push @toolchain, 'ext/VMS-Filespec/lib' if $^O eq 'VMS';
  47
  48 unshift @INC, @toolchain;
  49 require File::Spec::Functions;
  50
  51 # lib must be last, as the toolchain modules write themselves into it
  52 # as they build, and it's important that @INC order ensures that the partially
  53 # written files are always masked by the complete versions.
  54
  55 my $inc = join ",\n        ",
  56     map { "q\0$_\0" }
  57     (map {File::Spec::Functions::rel2abs($_)} @toolchain, 'lib');
  58
  59 open my $fh, '>', $file
  60     or die "Can't open $file: $!";
  61
  62 my $error;
  63
  64 # If any of the system's build tools are written in Perl, then this module
  65 # may well be loaded by a much older version than we are building. So keep it
  66 # as backwards compatible as is easy.
  67 print $fh <<"EOT" or $error = "Can't print to $file: $!";
  68 #!perl
  69
  70 #   !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
  71 #   This file is generated by write_buildcustomize.pl.
  72 #   Any changes made here will be lost!
  73
  74 # We are miniperl, building extensions
  75 # Replace the first entry of \@INC ("lib") with the list of
  76 # directories we need.
  77 splice(\@INC, 0, 1, $inc);
  78 \$^O = '$osname';
  79 EOT
  80
  81 if ($error) {
  82     close $fh
  83         or warn "Can't unlink $file after error: $!";
  84 } else {
  85     if (close $fh) {
  86         do $file and exit;
  87         $error = "Can't load generated $file: $@";
  88     } else {
  89         $error = "Can't close $file: $!";
  90     }
  91 }
  92
  93 # It's going very wrong, so try to remove the botched file.
  94
  95 unlink $file
  96     or warn "Can't unlink $file after error: $!";
  97 die $error;
  98
  99 # Local variables:
 100 # cperl-indent-level: 4
 101 # indent-tabs-mode: nil
 102 # End:
 103 #
 104 # ex: set ts=8 sts=4 sw=4 et: