ext/re/re.pm

   1 package re;
   2
   3 # pragma for controlling the regexp engine
   4 use strict;
   5 use warnings;
   6
   7 our $VERSION     = "0.14";
   8 our @ISA         = qw(Exporter);
   9 our @EXPORT_OK   = ('regmust',
  10                     qw(is_regexp regexp_pattern
  11                        regname regnames regnames_count));
  12 our %EXPORT_OK = map { $_ => 1 } @EXPORT_OK;
  13
  14 my %bitmask = (
  15     taint   => 0x00100000, # HINT_RE_TAINT
  16     eval    => 0x00200000, # HINT_RE_EVAL
  17 );
  18
  19 my $flags_hint = 0x02000000; # HINT_RE_FLAGS
  20 my $PMMOD_SHIFT = 0;
  21 my %reflags = (
  22     m => 1 << ($PMMOD_SHIFT + 0),
  23     s => 1 << ($PMMOD_SHIFT + 1),
  24     i => 1 << ($PMMOD_SHIFT + 2),
  25     x => 1 << ($PMMOD_SHIFT + 3),
  26     p => 1 << ($PMMOD_SHIFT + 4),
  27 # special cases:
  28     l => 1 << ($PMMOD_SHIFT + 5),
  29     u => 1 << ($PMMOD_SHIFT + 6),
  30     d => 0,
  31 );
  32
  33 sub setcolor {
  34  eval {                         # Ignore errors
  35   require Term::Cap;
  36
  37   my $terminal = Tgetent Term::Cap ({OSPEED => 9600}); # Avoid warning.
  38   my $props = $ENV{PERL_RE_TC} || 'md,me,so,se,us,ue';
  39   my @props = split /,/, $props;
  40   my $colors = join "\t", map {$terminal->Tputs($_,1)} @props;
  41
  42   $colors =~ s/\0//g;
  43   $ENV{PERL_RE_COLORS} = $colors;
  44  };
  45  if ($@) {
  46     $ENV{PERL_RE_COLORS} ||= qq'\t\t> <\t> <\t\t';
  47  }
  48
  49 }
  50
  51 my %flags = (
  52     COMPILE         => 0x0000FF,
  53     PARSE           => 0x000001,
  54     OPTIMISE        => 0x000002,
  55     TRIEC           => 0x000004,
  56     DUMP            => 0x000008,
  57     FLAGS           => 0x000010,
  58
  59     EXECUTE         => 0x00FF00,
  60     INTUIT          => 0x000100,
  61     MATCH           => 0x000200,
  62     TRIEE           => 0x000400,
  63
  64     EXTRA           => 0xFF0000,
  65     TRIEM           => 0x010000,
  66     OFFSETS         => 0x020000,
  67     OFFSETSDBG      => 0x040000,
  68     STATE           => 0x080000,
  69     OPTIMISEM       => 0x100000,
  70     STACK           => 0x280000,
  71     BUFFERS         => 0x400000,
  72     GPOS            => 0x800000,
  73 );
  74 $flags{ALL} = -1 & ~($flags{OFFSETS}|$flags{OFFSETSDBG}|$flags{BUFFERS});
  75 $flags{All} = $flags{all} = $flags{DUMP} | $flags{EXECUTE};
  76 $flags{Extra} = $flags{EXECUTE} | $flags{COMPILE} | $flags{GPOS};
  77 $flags{More} = $flags{MORE} = $flags{All} | $flags{TRIEC} | $flags{TRIEM} | $flags{STATE};
  78 $flags{State} = $flags{DUMP} | $flags{EXECUTE} | $flags{STATE};
  79 $flags{TRIE} = $flags{DUMP} | $flags{EXECUTE} | $flags{TRIEC};
  80
  81 if (defined &DynaLoader::boot_DynaLoader) {
  82     require XSLoader;
  83     XSLoader::load();
  84 }
  85 # else we're miniperl
  86 # We need to work for miniperl, because the XS toolchain uses Text::Wrap, which
  87 # uses re 'taint'.
  88
  89 sub _load_unload {
  90     my ($on)= @_;
  91     if ($on) {
  92         # We call install() every time, as if we didn't, we wouldn't
  93         # "see" any changes to the color environment var since
  94         # the last time it was called.
  95
  96         # install() returns an integer, which if casted properly
  97         # in C resolves to a structure containing the regexp
  98         # hooks. Setting it to a random integer will guarantee
  99         # segfaults.
 100         $^H{regcomp} = install();
 101     } else {
 102         delete $^H{regcomp};
 103     }
 104 }
 105
 106 sub bits {
 107     my $on = shift;
 108     my $bits = 0;
 109     unless (@_) {
 110         require Carp;
 111         Carp::carp("Useless use of \"re\" pragma");
 112     }
 113    ARG:
 114     foreach my $idx (0..$#_){
 115         my $s=$_[$idx];
 116         if ($s eq 'Debug' or $s eq 'Debugcolor') {
 117             setcolor() if $s =~/color/i;
 118             ${^RE_DEBUG_FLAGS} = 0 unless defined ${^RE_DEBUG_FLAGS};
 119             for my $idx ($idx+1..$#_) {
 120                 if ($flags{$_[$idx]}) {
 121                     if ($on) {
 122                         ${^RE_DEBUG_FLAGS} |= $flags{$_[$idx]};
 123                     } else {
 124                         ${^RE_DEBUG_FLAGS} &= ~ $flags{$_[$idx]};
 125                     }
 126                 } else {
 127                     require Carp;
 128                     Carp::carp("Unknown \"re\" Debug flag '$_[$idx]', possible flags: ",
 129                                join(", ",sort keys %flags ) );
 130                 }
 131             }
 132             _load_unload($on ? 1 : ${^RE_DEBUG_FLAGS});
 133             last;
 134         } elsif ($s eq 'debug' or $s eq 'debugcolor') {
 135             setcolor() if $s =~/color/i;
 136             _load_unload($on);
 137             last;
 138         } elsif (exists $bitmask{$s}) {
 139             $bits |= $bitmask{$s};
 140         } elsif ($EXPORT_OK{$s}) {
 141             require Exporter;
 142             re->export_to_level(2, 're', $s);
 143         } elsif ($s =~ s/^\///) {
 144             my $reflags = $^H{reflags} || 0;
 145             for(split//, $s) {
 146                 if (/[dul]/) {
 147                     if ($on) {
 148                         $^H{reflags_dul} = $reflags{$_};
 149                     }
 150                     else {
 151                         delete $^H{reflags_dul}
 152                          if  defined $^H{reflags_dul}
 153                           && $^H{reflags_dul} == $reflags{$_};
 154                     }
 155                 } elsif (exists $reflags{$_}) {
 156                     $on
 157                       ? $reflags |= $reflags{$_}
 158                       : ($reflags &= ~$reflags{$_});
 159                 } else {
 160                     require Carp;
 161                     Carp::carp(
 162                      qq'Unknown regular expression flag "$_"'
 163                     );
 164                     next ARG;
 165                 }
 166             }
 167             ($^H{reflags} = $reflags or defined $^H{reflags_dul})
 168              ? $^H |= $flags_hint
 169              : ($^H &= ~$flags_hint);
 170         } else {
 171             require Carp;
 172             Carp::carp("Unknown \"re\" subpragma '$s' (known ones are: ",
 173                        join(', ', map {qq('$_')} 'debug', 'debugcolor', sort keys %bitmask),
 174                        ")");
 175         }
 176     }
 177     $bits;
 178 }
 179
 180 sub import {
 181     shift;
 182     $^H |= bits(1, @_);
 183 }
 184
 185 sub unimport {
 186     shift;
 187     $^H &= ~ bits(0, @_);
 188 }
 189
 190 1;
 191
 192 __END__
 193
 194 =head1 NAME
 195
 196 re - Perl pragma to alter regular expression behaviour
 197
 198 =head1 SYNOPSIS
 199
 200     use re 'taint';
 201     ($x) = ($^X =~ /^(.*)$/s);     # $x is tainted here
 202
 203     $pat = '(?{ $foo = 1 })';
 204     use re 'eval';
 205     /foo${pat}bar/;                # won't fail (when not under -T switch)
 206
 207     {
 208         no re 'taint';             # the default
 209         ($x) = ($^X =~ /^(.*)$/s); # $x is not tainted here
 210
 211         no re 'eval';              # the default
 212         /foo${pat}bar/;            # disallowed (with or without -T switch)
 213     }
 214
 215     use re '/ix';
 216     "FOO" =~ / foo /; # /ix implied
 217     no re '/x';
 218     "FOO" =~ /foo/; # just /i implied
 219
 220     use re 'debug';                # output debugging info during
 221     /^(.*)$/s;                     #     compile and run time
 222
 223
 224     use re 'debugcolor';           # same as 'debug', but with colored output
 225     ...
 226
 227     use re qw(Debug All);          # Finer tuned debugging options.
 228     use re qw(Debug More);
 229     no re qw(Debug ALL);           # Turn of all re debugging in this scope
 230
 231     use re qw(is_regexp regexp_pattern); # import utility functions
 232     my ($pat,$mods)=regexp_pattern(qr/foo/i);
 233     if (is_regexp($obj)) {
 234         print "Got regexp: ",
 235             scalar regexp_pattern($obj); # just as perl would stringify it
 236     }                                    # but no hassle with blessed re's.
 237
 238 (We use $^X in these examples because it's tainted by default.)
 239
 240 =head1 DESCRIPTION
 241
 242 =head2 'taint' mode
 243
 244 When C<use re 'taint'> is in effect, and a tainted string is the target
 245 of a regexp, the regexp memories (or values returned by the m// operator
 246 in list context) are tainted.  This feature is useful when regexp operations
 247 on tainted data aren't meant to extract safe substrings, but to perform
 248 other transformations.
 249
 250 =head2 'eval' mode
 251
 252 When C<use re 'eval'> is in effect, a regexp is allowed to contain
 253 C<(?{ ... })> zero-width assertions and C<(??{ ... })> postponed
 254 subexpressions, even if the regular expression contains
 255 variable interpolation.  That is normally disallowed, since it is a
 256 potential security risk.  Note that this pragma is ignored when the regular
 257 expression is obtained from tainted data, i.e.  evaluation is always
 258 disallowed with tainted regular expressions.  See L<perlre/(?{ code })>
 259 and L<perlre/(??{ code })>.
 260
 261 For the purpose of this pragma, interpolation of precompiled regular
 262 expressions (i.e., the result of C<qr//>) is I<not> considered variable
 263 interpolation.  Thus:
 264
 265     /foo${pat}bar/
 266
 267 I<is> allowed if $pat is a precompiled regular expression, even
 268 if $pat contains C<(?{ ... })> assertions or C<(??{ ... })> subexpressions.
 269
 270 =head2 '/flags' mode
 271
 272 When C<use re '/flags'> is specified, the given flags are automatically
 273 added to every regular expression till the end of the lexical scope.
 274
 275 C<no re '/flags'> will turn off the effect of C<use re '/flags'> for the
 276 given flags.
 277
 278 For example, if you want all your regular expressions to have /msx on by
 279 default, simply put
 280
 281     use re '/msx';
 282
 283 at the top of your code.
 284
 285 The /dul flags cancel each other out. So, in this example,
 286
 287     use re "/u";
 288     "ss" =~ /\xdf/;
 289     use re "/d";
 290     "ss" =~ /\xdf/;
 291
 292 The second C<use re> does an implicit C<no re '/u'>.
 293
 294 Turning on the /l and /u flags with C<use re> takes precedence over the
 295 C<locale> pragma and the 'unicode_strings' C<feature>, for regular
 296 expressions. Turning off one of these flags when it is active reverts to
 297 the behaviour specified by whatever other pragmata are in scope. For
 298 example:
 299
 300     use feature "unicode_strings";
 301     no re "/u"; # does nothing
 302     use re "/l";
 303     no re "/l"; # reverts to unicode_strings behaviour
 304
 305 =head2 'debug' mode
 306
 307 When C<use re 'debug'> is in effect, perl emits debugging messages when
 308 compiling and using regular expressions.  The output is the same as that
 309 obtained by running a C<-DDEBUGGING>-enabled perl interpreter with the
 310 B<-Dr> switch. It may be quite voluminous depending on the complexity
 311 of the match.  Using C<debugcolor> instead of C<debug> enables a
 312 form of output that can be used to get a colorful display on terminals
 313 that understand termcap color sequences.  Set C<$ENV{PERL_RE_TC}> to a
 314 comma-separated list of C<termcap> properties to use for highlighting
 315 strings on/off, pre-point part on/off.
 316 See L<perldebug/"Debugging regular expressions"> for additional info.
 317
 318 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 319 lexically scoped, as the other directives are.  However they have both
 320 compile-time and run-time effects.
 321
 322 See L<perlmodlib/Pragmatic Modules>.
 323
 324 =head2 'Debug' mode
 325
 326 Similarly C<use re 'Debug'> produces debugging output, the difference
 327 being that it allows the fine tuning of what debugging output will be
 328 emitted. Options are divided into three groups, those related to
 329 compilation, those related to execution and those related to special
 330 purposes. The options are as follows:
 331
 332 =over 4
 333
 334 =item Compile related options
 335
 336 =over 4
 337
 338 =item COMPILE
 339
 340 Turns on all compile related debug options.
 341
 342 =item PARSE
 343
 344 Turns on debug output related to the process of parsing the pattern.
 345
 346 =item OPTIMISE
 347
 348 Enables output related to the optimisation phase of compilation.
 349
 350 =item TRIEC
 351
 352 Detailed info about trie compilation.
 353
 354 =item DUMP
 355
 356 Dump the final program out after it is compiled and optimised.
 357
 358 =back
 359
 360 =item Execute related options
 361
 362 =over 4
 363
 364 =item EXECUTE
 365
 366 Turns on all execute related debug options.
 367
 368 =item MATCH
 369
 370 Turns on debugging of the main matching loop.
 371
 372 =item TRIEE
 373
 374 Extra debugging of how tries execute.
 375
 376 =item INTUIT
 377
 378 Enable debugging of start point optimisations.
 379
 380 =back
 381
 382 =item Extra debugging options
 383
 384 =over 4
 385
 386 =item EXTRA
 387
 388 Turns on all "extra" debugging options.
 389
 390 =item BUFFERS
 391
 392 Enable debugging the capture group storage during match. Warning,
 393 this can potentially produce extremely large output.
 394
 395 =item TRIEM
 396
 397 Enable enhanced TRIE debugging. Enhances both TRIEE
 398 and TRIEC.
 399
 400 =item STATE
 401
 402 Enable debugging of states in the engine.
 403
 404 =item STACK
 405
 406 Enable debugging of the recursion stack in the engine. Enabling
 407 or disabling this option automatically does the same for debugging
 408 states as well. This output from this can be quite large.
 409
 410 =item OPTIMISEM
 411
 412 Enable enhanced optimisation debugging and start point optimisations.
 413 Probably not useful except when debugging the regexp engine itself.
 414
 415 =item OFFSETS
 416
 417 Dump offset information. This can be used to see how regops correlate
 418 to the pattern. Output format is
 419
 420    NODENUM:POSITION[LENGTH]
 421
 422 Where 1 is the position of the first char in the string. Note that position
 423 can be 0, or larger than the actual length of the pattern, likewise length
 424 can be zero.
 425
 426 =item OFFSETSDBG
 427
 428 Enable debugging of offsets information. This emits copious
 429 amounts of trace information and doesn't mesh well with other
 430 debug options.
 431
 432 Almost definitely only useful to people hacking
 433 on the offsets part of the debug engine.
 434
 435 =back
 436
 437 =item Other useful flags
 438
 439 These are useful shortcuts to save on the typing.
 440
 441 =over 4
 442
 443 =item ALL
 444
 445 Enable all options at once except OFFSETS, OFFSETSDBG and BUFFERS
 446
 447 =item All
 448
 449 Enable DUMP and all execute options. Equivalent to:
 450
 451   use re 'debug';
 452
 453 =item MORE
 454
 455 =item More
 456
 457 Enable TRIEM and all execute compile and execute options.
 458
 459 =back
 460
 461 =back
 462
 463 As of 5.9.5 the directive C<use re 'debug'> and its equivalents are
 464 lexically scoped, as the other directives are.  However they have both
 465 compile-time and run-time effects.
 466
 467 =head2 Exportable Functions
 468
 469 As of perl 5.9.5 're' debug contains a number of utility functions that
 470 may be optionally exported into the caller's namespace. They are listed
 471 below.
 472
 473 =over 4
 474
 475 =item is_regexp($ref)
 476
 477 Returns true if the argument is a compiled regular expression as returned
 478 by C<qr//>, false if it is not.
 479
 480 This function will not be confused by overloading or blessing. In
 481 internals terms, this extracts the regexp pointer out of the
 482 PERL_MAGIC_qr structure so it it cannot be fooled.
 483
 484 =item regexp_pattern($ref)
 485
 486 If the argument is a compiled regular expression as returned by C<qr//>,
 487 then this function returns the pattern.
 488
 489 In list context it returns a two element list, the first element
 490 containing the pattern and the second containing the modifiers used when
 491 the pattern was compiled.
 492
 493   my ($pat, $mods) = regexp_pattern($ref);
 494
 495 In scalar context it returns the same as perl would when stringifying a raw
 496 C<qr//> with the same pattern inside.  If the argument is not a compiled
 497 reference then this routine returns false but defined in scalar context,
 498 and the empty list in list context. Thus the following
 499
 500     if (regexp_pattern($ref) eq '(?^i:foo)')
 501
 502 will be warning free regardless of what $ref actually is.
 503
 504 Like C<is_regexp> this function will not be confused by overloading
 505 or blessing of the object.
 506
 507 =item regmust($ref)
 508
 509 If the argument is a compiled regular expression as returned by C<qr//>,
 510 then this function returns what the optimiser considers to be the longest
 511 anchored fixed string and longest floating fixed string in the pattern.
 512
 513 A I<fixed string> is defined as being a substring that must appear for the
 514 pattern to match. An I<anchored fixed string> is a fixed string that must
 515 appear at a particular offset from the beginning of the match. A I<floating
 516 fixed string> is defined as a fixed string that can appear at any point in
 517 a range of positions relative to the start of the match. For example,
 518
 519     my $qr = qr/here .* there/x;
 520     my ($anchored, $floating) = regmust($qr);
 521     print "anchored:'$anchored'\nfloating:'$floating'\n";
 522
 523 results in
 524
 525     anchored:'here'
 526     floating:'there'
 527
 528 Because the C<here> is before the C<.*> in the pattern, its position
 529 can be determined exactly. That's not true, however, for the C<there>;
 530 it could appear at any point after where the anchored string appeared.
 531 Perl uses both for its optimisations, prefering the longer, or, if they are
 532 equal, the floating.
 533
 534 B<NOTE:> This may not necessarily be the definitive longest anchored and
 535 floating string. This will be what the optimiser of the Perl that you
 536 are using thinks is the longest. If you believe that the result is wrong
 537 please report it via the L<perlbug> utility.
 538
 539 =item regname($name,$all)
 540
 541 Returns the contents of a named buffer of the last successful match. If
 542 $all is true, then returns an array ref containing one entry per buffer,
 543 otherwise returns the first defined buffer.
 544
 545 =item regnames($all)
 546
 547 Returns a list of all of the named buffers defined in the last successful
 548 match. If $all is true, then it returns all names defined, if not it returns
 549 only names which were involved in the match.
 550
 551 =item regnames_count()
 552
 553 Returns the number of distinct names defined in the pattern used
 554 for the last successful match.
 555
 556 B<Note:> this result is always the actual number of distinct
 557 named buffers defined, it may not actually match that which is
 558 returned by C<regnames()> and related routines when those routines
 559 have not been called with the $all parameter set.
 560
 561 =back
 562
 563 =head1 SEE ALSO
 564
 565 L<perlmodlib/Pragmatic Modules>.
 566
 567 =cut