This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Generate the table of core magic types in perlguts.pod using mg_vtable.pl
[perl5.git] / regen / mg_vtable.pl
1 #!/usr/bin/perl -w
2 #
3 # Regenerate (overwriting only if changed):
4 #
5 #    mg_vtable.h
6 #
7 # from information stored in this file.
8 #
9 # Accepts the standard regen_lib -q and -v args.
10 #
11 # This script is normally invoked from regen.pl.
12
13 use strict;
14 require 5.004;
15
16 BEGIN {
17     # Get function prototypes
18     require 'regen/regen_lib.pl';
19 }
20
21 # This generates the relevant section to paste into perlguts.pod to STDOUT
22 my $output_guts = grep { $_ eq '-g' } @ARGV;
23
24 my %mg =
25     (
26      sv => { char => '\0', vtable => 'sv', readonly_acceptable => 1,
27              desc => 'Special scalar variable' },
28      overload => { char => 'A', vtable => 'amagic', desc => '%OVERLOAD hash' },
29      overload_elem => { char => 'a', vtable => 'amagicelem',
30                         desc => '%OVERLOAD hash element' },
31      overload_table => { char => 'c', vtable => 'ovrld',
32                          desc => 'Holds overload table (AMT) on stash' },
33      bm => { char => 'B', vtable => 'regexp', value_magic => 1,
34              readonly_acceptable => 1,
35              desc => 'Boyer-Moore (fast string search)' },
36      regdata => { char => 'D', vtable => 'regdata',
37                   desc => "Regex match position data\n(\@+ and \@- vars)" },
38      regdatum => { char => 'd', vtable => 'regdatum',
39                    desc => 'Regex match position data element' },
40      env => { char => 'E', vtable => 'env', desc => '%ENV hash' },
41      envelem => { char => 'e', vtable => 'envelem',
42                   desc => '%ENV hash element' },
43      fm => { char => 'f', vtable => 'regdata', value_magic => 1,
44              readonly_acceptable => 1, desc => "Formline ('compiled' format)" },
45      regex_global => { char => 'g', vtable => 'mglob', value_magic => 1,
46                        readonly_acceptable => 1,
47                        desc => 'm//g target / study()ed string' },
48      hints => { char => 'H', vtable => 'hints', desc => '%^H hash' },
49      hintselem => { char => 'h', vtable => 'hintselem',
50                     desc => '%^H hash element' },
51      isa => { char => 'I', vtable => 'isa', desc => '@ISA array' },
52      isaelem => { char => 'i', vtable => 'isaelem',
53                   desc => '@ISA array element' },
54      nkeys => { char => 'k', vtable => 'nkeys', value_magic => 1,
55                 desc => 'scalar(keys()) lvalue' },
56      dbfile => { char => 'L', vtable => 'dbline',
57                  desc => 'Debugger %_<filename' },
58      dbline => { char => 'l', desc => 'Debugger %_<filename element' },
59      shared => { char => 'N', desc => 'Shared between threads',
60                  unknown_to_sv_magic => 1 },
61      shared_scalar => { char => 'n', desc => 'Shared between threads',
62                         unknown_to_sv_magic => 1 },
63      collxfrm => { char => 'o', vtable => 'collxfrm', value_magic => 1,
64                    desc => 'Locale transformation' },
65      tied => { char => 'P', vtable => 'pack',
66                value_magic => 1, # treat as value, so 'local @tied' isn't tied
67                desc => 'Tied array or hash' },
68      tiedelem => { char => 'p', vtable => 'packelem',
69                    desc => 'Tied array or hash element' },
70      tiedscalar => { char => 'q', vtable => 'packelem',
71                      desc => 'Tied scalar or handle' },
72      qr => { char => 'r', vtable => 'regexp', value_magic => 1, 
73              desc => 'precompiled qr// regex' },
74      sig => { char => 'S', desc => '%SIG hash' },
75      sigelem => { char => 's', vtable => 'sigelem',
76                   desc => '%SIG hash element' },
77      taint => { char => 't', vtable => 'taint', value_magic => 1,
78                 desc => 'Taintedness' },
79      uvar => { char => 'U', vtable => 'uvar',
80                desc => 'Available for use by extensions' },
81      uvar_elem => { char => 'u', desc => 'Reserved for use by extensions',
82                     unknown_to_sv_magic => 1 },
83      vec => { char => 'v', vtable => 'vec', value_magic => 1,
84               desc => 'vec() lvalue' },
85      vstring => { char => 'V', value_magic => 1,
86                   desc => 'SV was vstring literal' },
87      utf8 => { char => 'w', vtable => 'utf8', value_magic => 1,
88                desc => 'Cached UTF-8 information' },
89      substr => { char => 'x', vtable => 'substr',  value_magic => 1,
90                  desc => 'substr() lvalue' },
91      defelem => { char => 'y', vtable => 'defelem', value_magic => 1,
92                   desc => "Shadow \"foreach\" iterator variable /\nsmart parameter vivification" },
93      arylen => { char => '#', vtable => 'arylen', value_magic => 1,
94                  desc => 'Array length ($#ary)' },
95      pos => { char => '.', vtable => 'pos', value_magic => 1,
96               desc => 'pos() lvalue' },
97      backref => { char => '<', vtable => 'backref', value_magic => 1,
98                   readonly_acceptable => 1, desc => 'for weak ref data' },
99      symtab => { char => ':', value_magic => 1,
100                  desc => 'extra data for symbol tables' },
101      rhash => { char => '%', value_magic => 1,
102                 desc => 'extra data for restricted hashes' },
103      arylen_p => { char => '@', value_magic => 1,
104                    desc => 'to move arylen out of XPVAV' },
105      ext => { char => '~', desc => 'Available for use by extensions' },
106      checkcall => { char => ']', value_magic => 1,
107                     desc => 'inlining/mutation of call to this CV'},
108 );
109
110 # These have a subtly different "namespace" from the magic types.
111 my %sig =
112     (
113      'sv' => {get => 'get', set => 'set', len => 'len'},
114      'env' => {set => 'set_all_env', clear => 'clear_all_env'},
115      'envelem' => {set => 'setenv', clear => 'clearenv'},
116      'sigelem' => {get => 'getsig', set => 'setsig', clear => 'clearsig',
117                    cond => '#ifndef PERL_MICRO'},
118      'pack' => {len => 'sizepack', clear => 'wipepack'},
119      'packelem' => {get => 'getpack', set => 'setpack', clear => 'clearpack'},
120      'dbline' => {set => 'setdbline'},
121      'isa' => {set => 'setisa', clear => 'clearisa'},
122      'isaelem' => {set => 'setisa'},
123      'arylen' => {get => 'getarylen', set => 'setarylen', const => 1},
124      'arylen_p' => {free => 'freearylen_p'},
125      'mglob' => {set => 'setmglob'},
126      'nkeys' => {get => 'getnkeys', set => 'setnkeys'},
127      'taint' => {get => 'gettaint', set => 'settaint'},
128      'substr' => {get => 'getsubstr', set => 'setsubstr'},
129      'vec' => {get => 'getvec', set => 'setvec'},
130      'pos' => {get => 'getpos', set => 'setpos'},
131      'uvar' => {get => 'getuvar', set => 'setuvar'},
132      'defelem' => {get => 'getdefelem', set => 'setdefelem'},
133      'regexp' => {set => 'setregexp', alias => [qw(bm fm)]},
134      'regdata' => {len => 'regdata_cnt'},
135      'regdatum' => {get => 'regdatum_get', set => 'regdatum_set'},
136      'amagic' => {set => 'setamagic', free => 'setamagic'},
137      'amagicelem' => {set => 'setamagic', free => 'setamagic'},
138      'backref' => {free => 'killbackrefs'},
139      'ovrld' => {free => 'freeovrld'},
140      'utf8' => {set => 'setutf8'},
141      'collxfrm' => {set => 'setcollxfrm',
142                     cond => '#ifdef USE_LOCALE_COLLATE'},
143      'hintselem' => {set => 'sethint', clear => 'clearhint'},
144      'hints' => {clear => 'clearhints'},
145 );
146
147 my ($vt, $raw, $names) = map {
148     open_new($_, '>',
149              { by => 'regen/mg_vtable.pl', file => $_, style => '*' });
150 } 'mg_vtable.h', 'mg_raw.h', 'mg_names.c';
151
152 print $vt <<'EOH';
153 /* These constants should be used in preference to raw characters
154  * when using magic. Note that some perl guts still assume
155  * certain character properties of these constants, namely that
156  * isUPPER() and toLOWER() may do useful mappings.
157  */
158
159 EOH
160
161 # Of course, it would be *much* easier if we could output this table directly
162 # here and now. However, for our sins, we try to support EBCDIC, which wouldn't
163 # be *so* bad, except that there are (at least) 3 EBCDIC charset variants, and
164 # they don't agree on the code point for '~'. Which we use. Great.
165 # So we have to get the local build runtime to sort our table in character order
166 # (And of course, just to be helpful, in POSIX BC '~' is \xFF, so we can't even
167 # simplify the C code by assuming that the last element of the array is
168 # predictable)
169
170 {
171     my $longest = 0;
172     foreach (keys %mg) {
173         $longest = length $_ if length $_ > $longest;
174     }
175
176     my $longest_p1 = $longest + 1;
177
178     my %mg_order;
179     while (my ($name, $data) = each %mg) {
180         my $byte = eval qq{"$data->{char}"};
181         $data->{byte} = $byte;
182         $mg_order{(uc $byte) . $byte} = $name;
183     }
184     my @rows;
185     foreach (sort keys %mg_order) {
186         my $name = $mg_order{$_};
187         my $data = $mg{$name};
188         my $i = ord $data->{byte};
189         unless ($data->{unknown_to_sv_magic}) {
190             my $value = $data->{vtable}
191                 ? "want_vtbl_$data->{vtable}" : 'magic_vtable_max';
192             $value .= ' | PERL_MAGIC_READONLY_ACCEPTABLE'
193                 if $data->{readonly_acceptable};
194             $value .= ' | PERL_MAGIC_VALUE_MAGIC' if $data->{value_magic};
195             my $comment = "/* $name '$data->{char}' $data->{desc} */";
196             $comment =~ s/([\\"])/\\$1/g;
197             $comment =~ tr/\n/ /;
198             print $raw qq{    { '$data->{char}', "$value",\n      "$comment" },\n};
199         }
200
201         my $comment = $data->{desc};
202         my $leader = ' ' x ($longest + 27);
203         $comment =~ s/\n/\n$leader/s;
204         printf $vt "#define PERL_MAGIC_%-${longest}s '%s' /* %s */\n",
205             $name, $data->{char}, $comment;
206
207         my $char = $data->{char};
208         $char =~ s/([\\"])/\\$1/g;
209         printf $names qq[\t{ PERL_MAGIC_%-${longest_p1}s "%s(%s)" },\n],
210             "$name,", $name, $char;
211
212         push @rows, [(sprintf "%-2s PERL_MAGIC_%s", $data->{char}, $name),
213                      $data->{vtable} ? "vtbl_$data->{vtable}" : '(none)',
214                      $data->{desc}];
215     }
216     if ($output_guts) {
217         my @header = ('(old-style char and macro)', 'MGVTBL', 'Type of magic');
218         my @widths = (0, 0);
219         foreach my $row (@rows) {
220             for (0, 1) {
221                 $widths[$_] = length $row->[$_]
222                     if length $row->[$_] > $widths[$_];
223             }
224         }
225         my $indent = '    ';
226         my $format
227             = sprintf "$indent%%-%ds%%-%ds%%s\n", $widths[0] + 1, $widths[1] + 1;
228         my $desc_wrap = 80 - (length $indent) - $widths[0] - $widths[1] - 2;
229
230         print $indent . "mg_type\n";
231         printf $format, @header;
232         printf $format, map {'-' x length $_} @header;
233         foreach (@rows) {
234             my ($type, $vtbl, $desc) = @$_;
235             $desc =~ tr/\n/ /;
236             my @cont;
237             if (length $desc > $desc_wrap) {
238                 # If it's too long, first split on '(', if there.
239                 # [Which, if there, is always short enough, currently.
240                 # Make this more robust if that changes]
241                 ($desc, @cont) = split /(?=\()/, $desc;
242                 if (!@cont) {
243                     ($desc, @cont) = $desc =~ /(.{1,$desc_wrap})(?: |\z)/g
244                 }
245             }
246             printf $format, $type, $vtbl, $desc;
247             printf $format, '', '', $_ foreach @cont;
248         }
249     }
250 }
251
252 my @names = sort keys %sig;
253 {
254     my $want = join ",\n    ", (map {"want_vtbl_$_"} @names), 'magic_vtable_max';
255     my $names = join qq{",\n    "}, @names;
256
257     print $vt <<"EOH";
258
259 enum {          /* pass one of these to get_vtbl */
260     $want
261 };
262
263 #ifdef DOINIT
264 EXTCONST char *PL_magic_vtable_names[magic_vtable_max] = {
265     "$names"
266 };
267 #else
268 EXTCONST char *PL_magic_vtable_names[magic_vtable_max];
269 #endif
270
271 EOH
272 }
273
274 print $vt <<'EOH';
275 /* These all need to be 0, not NULL, as NULL can be (void*)0, which is a
276  * pointer to data, whereas we're assigning pointers to functions, which are
277  * not the same beast. ANSI doesn't allow the assignment from one to the other.
278  * (although most, but not all, compilers are prepared to do it)
279  */
280
281 /* order is:
282     get
283     set
284     len
285     clear
286     free
287     copy
288     dup
289     local
290 */
291
292 #ifdef DOINIT
293 EXT_MGVTBL PL_magic_vtables[magic_vtable_max] = {
294 EOH
295
296 my @vtable_names;
297 my @aliases;
298
299 while (my $name = shift @names) {
300     my $data = $sig{$name};
301     push @vtable_names, $name;
302     my @funcs = map {
303         $data->{$_} ? "Perl_magic_$data->{$_}" : 0;
304     } qw(get set len clear free copy dup local);
305
306     $funcs[0] = "(int (*)(pTHX_ SV *, MAGIC *))" . $funcs[0] if $data->{const};
307     my $funcs = join ", ", @funcs;
308
309     # Because we can't have a , after the last {...}
310     my $comma = @names ? ',' : '';
311
312     print $vt "$data->{cond}\n" if $data->{cond};
313     print $vt "  { $funcs }$comma\n";
314     print $vt <<"EOH" if $data->{cond};
315 #else
316   { 0, 0, 0, 0, 0, 0, 0, 0 }$comma
317 #endif
318 EOH
319     foreach(@{$data->{alias}}) {
320         push @aliases, "#define want_vtbl_$_ want_vtbl_$name\n";
321         push @vtable_names, $_;
322     }
323 }
324
325 print $vt <<'EOH';
326 };
327 #else
328 EXT_MGVTBL PL_magic_vtables[magic_vtable_max];
329 #endif
330
331 EOH
332
333 print $vt (sort @aliases), "\n";
334
335 print $vt "#define PL_vtbl_$_ PL_magic_vtables[want_vtbl_$_]\n"
336     foreach sort @vtable_names;
337
338 # 63, not 64, As we rely on the last possible value to mean "NULL vtable"
339 die "Too many vtable names" if @vtable_names > 63;
340
341 read_only_bottom_close_and_rename($_) foreach $vt, $raw, $names;