This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
631b391c2653dd8a15909a310677c90fe7008316
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators are evaluated before
31 others.  For example, in S<C<2 + 4 * 5>>, the multiplication has higher
32 precedence so S<C<4 * 5>> is evaluated first yielding S<C<2 + 20 ==
33 22>> and not S<C<6 * 5 == 30>>.
34
35 I<Operator associativity> defines what happens if a sequence of the
36 same operators is used one after another: whether the evaluator will
37 evaluate the left operations first, or the right first.  For example, in
38 S<C<8 - 4 - 2>>, subtraction is left associative so Perl evaluates the
39 expression left to right.  S<C<8 - 4>> is evaluated first making the
40 expression S<C<4 - 2 == 2>> and not S<C<8 - 2 == 6>>.
41
42 Perl operators have the following associativity and precedence,
43 listed from highest precedence to lowest.  Operators borrowed from
44 C keep the same precedence relationship with each other, even where
45 C's precedence is slightly screwy.  (This makes learning Perl easier
46 for C folks.)  With very few exceptions, these all operate on scalar
47 values only, not array values.
48
49     left        terms and list operators (leftward)
50     left        ->
51     nonassoc    ++ --
52     right       **
53     right       ! ~ \ and unary + and -
54     left        =~ !~
55     left        * / % x
56     left        + - .
57     left        << >>
58     nonassoc    named unary operators
59     nonassoc    < > <= >= lt gt le ge
60     nonassoc    == != <=> eq ne cmp ~~
61     left        &
62     left        | ^
63     left        &&
64     left        || //
65     nonassoc    ..  ...
66     right       ?:
67     right       = += -= *= etc. goto last next redo dump
68     left        , =>
69     nonassoc    list operators (rightward)
70     right       not
71     left        and
72     left        or xor
73
74 In the following sections, these operators are covered in precedence order.
75
76 Many operators can be overloaded for objects.  See L<overload>.
77
78 =head2 Terms and List Operators (Leftward)
79 X<list operator> X<operator, list> X<term>
80
81 A TERM has the highest precedence in Perl.  They include variables,
82 quote and quote-like operators, any expression in parentheses,
83 and any function whose arguments are parenthesized.  Actually, there
84 aren't really functions in this sense, just list operators and unary
85 operators behaving as functions because you put parentheses around
86 the arguments.  These are all documented in L<perlfunc>.
87
88 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
89 is followed by a left parenthesis as the next token, the operator and
90 arguments within parentheses are taken to be of highest precedence,
91 just like a normal function call.
92
93 In the absence of parentheses, the precedence of list operators such as
94 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
95 whether you are looking at the left side or the right side of the operator.
96 For example, in
97
98     @ary = (1, 3, sort 4, 2);
99     print @ary;         # prints 1324
100
101 the commas on the right of the C<sort> are evaluated before the C<sort>,
102 but the commas on the left are evaluated after.  In other words,
103 list operators tend to gobble up all arguments that follow, and
104 then act like a simple TERM with regard to the preceding expression.
105 Be careful with parentheses:
106
107     # These evaluate exit before doing the print:
108     print($foo, exit);  # Obviously not what you want.
109     print $foo, exit;   # Nor is this.
110
111     # These do the print before evaluating exit:
112     (print $foo), exit; # This is what you want.
113     print($foo), exit;  # Or this.
114     print ($foo), exit; # Or even this.
115
116 Also note that
117
118     print ($foo & 255) + 1, "\n";
119
120 probably doesn't do what you expect at first glance.  The parentheses
121 enclose the argument list for C<print> which is evaluated (printing
122 the result of S<C<$foo & 255>>).  Then one is added to the return value
123 of C<print> (usually 1).  The result is something like this:
124
125     1 + 1, "\n";    # Obviously not what you meant.
126
127 To do what you meant properly, you must write:
128
129     print(($foo & 255) + 1, "\n");
130
131 See L<Named Unary Operators> for more discussion of this.
132
133 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
134 well as subroutine and method calls, and the anonymous
135 constructors C<[]> and C<{}>.
136
137 See also L<Quote and Quote-like Operators> toward the end of this section,
138 as well as L</"I/O Operators">.
139
140 =head2 The Arrow Operator
141 X<arrow> X<dereference> X<< -> >>
142
143 "C<< -> >>" is an infix dereference operator, just as it is in C
144 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
145 C<(...)> subscript, then the left side must be either a hard or
146 symbolic reference to an array, a hash, or a subroutine respectively.
147 (Or technically speaking, a location capable of holding a hard
148 reference, if it's an array or hash reference being used for
149 assignment.)  See L<perlreftut> and L<perlref>.
150
151 Otherwise, the right side is a method name or a simple scalar
152 variable containing either the method name or a subroutine reference,
153 and the left side must be either an object (a blessed reference)
154 or a class name (that is, a package name).  See L<perlobj>.
155
156 The dereferencing cases (as opposed to method-calling cases) are
157 somewhat extended by the C<postderef> feature.  For the
158 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
159
160 =head2 Auto-increment and Auto-decrement
161 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
162
163 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
164 they increment or decrement the variable by one before returning the
165 value, and if placed after, increment or decrement after returning the
166 value.
167
168     $i = 0;  $j = 0;
169     print $i++;  # prints 0
170     print ++$j;  # prints 1
171
172 Note that just as in C, Perl doesn't define B<when> the variable is
173 incremented or decremented.  You just know it will be done sometime
174 before or after the value is returned.  This also means that modifying
175 a variable twice in the same statement will lead to undefined behavior.
176 Avoid statements like:
177
178     $i = $i ++;
179     print ++ $i + $i ++;
180
181 Perl will not guarantee what the result of the above statements is.
182
183 The auto-increment operator has a little extra builtin magic to it.  If
184 you increment a variable that is numeric, or that has ever been used in
185 a numeric context, you get a normal increment.  If, however, the
186 variable has been used in only string contexts since it was set, and
187 has a value that is not the empty string and matches the pattern
188 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
189 character within its range, with carry:
190
191     print ++($foo = "99");      # prints "100"
192     print ++($foo = "a0");      # prints "a1"
193     print ++($foo = "Az");      # prints "Ba"
194     print ++($foo = "zz");      # prints "aaa"
195
196 C<undef> is always treated as numeric, and in particular is changed
197 to C<0> before incrementing (so that a post-increment of an undef value
198 will return C<0> rather than C<undef>).
199
200 The auto-decrement operator is not magical.
201
202 =head2 Exponentiation
203 X<**> X<exponentiation> X<power>
204
205 Binary C<"**"> is the exponentiation operator.  It binds even more
206 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
207 (This is
208 implemented using C's C<pow(3)> function, which actually works on doubles
209 internally.)
210
211 Note that certain exponentiation expressions are ill-defined:
212 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
213 any particular results from these special cases, the results
214 are platform-dependent.
215
216 =head2 Symbolic Unary Operators
217 X<unary operator> X<operator, unary>
218
219 Unary C<"!"> performs logical negation, that is, "not".  See also C<not> for a lower
220 precedence version of this.
221 X<!>
222
223 Unary C<"-"> performs arithmetic negation if the operand is numeric,
224 including any string that looks like a number.  If the operand is
225 an identifier, a string consisting of a minus sign concatenated
226 with the identifier is returned.  Otherwise, if the string starts
227 with a plus or minus, a string starting with the opposite sign is
228 returned.  One effect of these rules is that C<-bareword> is equivalent
229 to the string C<"-bareword">.  If, however, the string begins with a
230 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
231 to convert
232 the string to a numeric, and the arithmetic negation is performed.  If the
233 string cannot be cleanly converted to a numeric, Perl will give the warning
234 B<Argument "the string" isn't numeric in negation (-) at ...>.
235 X<-> X<negation, arithmetic>
236
237 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
238 example, S<C<0666 & ~027>> is 0640.  (See also L<Integer Arithmetic> and
239 L<Bitwise String Operators>.)  Note that the width of the result is
240 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
241 bits wide on a 64-bit platform, so if you are expecting a certain bit
242 width, remember to use the C<"&"> operator to mask off the excess bits.
243 X<~> X<negation, binary>
244
245 When complementing strings, if all characters have ordinal values under
246 256, then their complements will, also.  But if they do not, all
247 characters will be in either 32- or 64-bit complements, depending on your
248 architecture.  So for example, C<~"\x{3B1}"> is C<"\x{FFFF_FC4E}"> on
249 32-bit machines and C<"\x{FFFF_FFFF_FFFF_FC4E}"> on 64-bit machines.
250
251 If the experimental "bitwise" feature is enabled via S<C<use feature
252 'bitwise'>>, then unary C<"~"> always treats its argument as a number, and an
253 alternate form of the operator, C<"~.">, always treats its argument as a
254 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
255 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  This feature
256 produces a warning unless you use S<C<no warnings 'experimental::bitwise'>>.
257
258 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
259 syntactically for separating a function name from a parenthesized expression
260 that would otherwise be interpreted as the complete list of function
261 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
262 X<+>
263
264 Unary C<"\"> creates a reference to whatever follows it.  See L<perlreftut>
265 and L<perlref>.  Do not confuse this behavior with the behavior of
266 backslash within a string, although both forms do convey the notion
267 of protecting the next thing from interpolation.
268 X<\> X<reference> X<backslash>
269
270 =head2 Binding Operators
271 X<binding> X<operator, binding> X<=~> X<!~>
272
273 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
274 search or modify the string C<$_> by default.  This operator makes that kind
275 of operation work on some other string.  The right argument is a search
276 pattern, substitution, or transliteration.  The left argument is what is
277 supposed to be searched, substituted, or transliterated instead of the default
278 C<$_>.  When used in scalar context, the return value generally indicates the
279 success of the operation.  The exceptions are substitution (C<s///>)
280 and transliteration (C<y///>) with the C</r> (non-destructive) option,
281 which cause the B<r>eturn value to be the result of the substitution.
282 Behavior in list context depends on the particular operator.
283 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
284 examples using these operators.
285
286 If the right argument is an expression rather than a search pattern,
287 substitution, or transliteration, it is interpreted as a search pattern at run
288 time.  Note that this means that its
289 contents will be interpolated twice, so
290
291     '\\' =~ q'\\';
292
293 is not ok, as the regex engine will end up trying to compile the
294 pattern C<\>, which it will consider a syntax error.
295
296 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
297 the logical sense.
298
299 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
300 (C<y///r>) is a syntax error.
301
302 =head2 Multiplicative Operators
303 X<operator, multiplicative>
304
305 Binary C<"*"> multiplies two numbers.
306 X<*>
307
308 Binary C<"/"> divides two numbers.
309 X</> X<slash>
310
311 Binary C<"%"> is the modulo operator, which computes the division
312 remainder of its first argument with respect to its second argument.
313 Given integer
314 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
315 C<$m> minus the largest multiple of C<$n> less than or equal to
316 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
317 smallest multiple of C<$n> that is not less than C<$m> (that is, the
318 result will be less than or equal to zero).  If the operands
319 C<$m> and C<$n> are floating point values and the absolute value of
320 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
321 the integer portion of C<$m> and C<$n> will be used in the operation
322 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
323 If the absolute value of the right operand (C<abs($n)>) is greater than
324 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
325 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
326 integer that makes C<$r> have the same sign as the right operand
327 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
328 and the absolute value less than that of C<$n>.
329 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
330 to the modulo operator as implemented by your C compiler.  This
331 operator is not as well defined for negative operands, but it will
332 execute faster.
333 X<%> X<remainder> X<modulo> X<mod>
334
335 Binary C<"x"> is the repetition operator.  In scalar context or if the left
336 operand is not enclosed in parentheses, it returns a string consisting
337 of the left operand repeated the number of times specified by the right
338 operand.  In list context, if the left operand is enclosed in
339 parentheses or is a list formed by C<qw/I<STRING>/>, it repeats the list.
340 If the right operand is zero or negative (raising a warning on
341 negative), it returns an empty string
342 or an empty list, depending on the context.
343 X<x>
344
345     print '-' x 80;             # print row of dashes
346
347     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
348
349     @ones = (1) x 80;           # a list of 80 1's
350     @ones = (5) x @ones;        # set all elements to 5
351
352
353 =head2 Additive Operators
354 X<operator, additive>
355
356 Binary C<"+"> returns the sum of two numbers.
357 X<+>
358
359 Binary C<"-"> returns the difference of two numbers.
360 X<->
361
362 Binary C<"."> concatenates two strings.
363 X<string, concatenation> X<concatenation>
364 X<cat> X<concat> X<concatenate> X<.>
365
366 =head2 Shift Operators
367 X<shift operator> X<operator, shift> X<<< << >>>
368 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
369 X<shl> X<shr> X<shift, right> X<shift, left>
370
371 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
372 number of bits specified by the right argument.  Arguments should be
373 integers.  (See also L<Integer Arithmetic>.)
374
375 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
376 the number of bits specified by the right argument.  Arguments should
377 be integers.  (See also L<Integer Arithmetic>.)
378
379 Note that both C<<< << >>> and C<<< >> >>> in Perl are implemented directly using
380 C<<< << >>> and C<<< >> >>>  in C.  If S<C<use integer>> (see L<Integer Arithmetic>) is
381 in force then signed C integers are used, else unsigned C integers are
382 used, even for negative shiftees.  Either way, the implementation isn't going to generate results
383 larger than the size of the integer type Perl was built with (32 bits
384 or 64 bits).
385
386 The result of overflowing the range of the integers is undefined
387 because it is undefined also in C.  In other words, using 32-bit
388 integers, S<C<< 1 << 32 >>> is undefined.  Shifting by a negative number
389 of bits is also undefined.
390
391 If you get tired of being subject to your platform's native integers,
392 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
393
394     print 20 << 20;  # 20971520
395     print 20 << 40;  # 5120 on 32-bit machines, 
396                      # 21990232555520 on 64-bit machines
397     use bigint;
398     print 20 << 100; # 25353012004564588029934064107520
399
400 =head2 Named Unary Operators
401 X<operator, named unary>
402
403 The various named unary operators are treated as functions with one
404 argument, with optional parentheses.
405
406 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
407 is followed by a left parenthesis as the next token, the operator and
408 arguments within parentheses are taken to be of highest precedence,
409 just like a normal function call.  For example,
410 because named unary operators are higher precedence than C<||>:
411
412     chdir $foo    || die;       # (chdir $foo) || die
413     chdir($foo)   || die;       # (chdir $foo) || die
414     chdir ($foo)  || die;       # (chdir $foo) || die
415     chdir +($foo) || die;       # (chdir $foo) || die
416
417 but, because C<"*"> is higher precedence than named operators:
418
419     chdir $foo * 20;    # chdir ($foo * 20)
420     chdir($foo) * 20;   # (chdir $foo) * 20
421     chdir ($foo) * 20;  # (chdir $foo) * 20
422     chdir +($foo) * 20; # chdir ($foo * 20)
423
424     rand 10 * 20;       # rand (10 * 20)
425     rand(10) * 20;      # (rand 10) * 20
426     rand (10) * 20;     # (rand 10) * 20
427     rand +(10) * 20;    # rand (10 * 20)
428
429 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
430 treated like named unary operators, but they don't follow this functional
431 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
432 equivalent to S<C<-f "$file.bak">>.
433 X<-X> X<filetest> X<operator, filetest>
434
435 See also L<"Terms and List Operators (Leftward)">.
436
437 =head2 Relational Operators
438 X<relational operator> X<operator, relational>
439
440 Perl operators that return true or false generally return values 
441 that can be safely used as numbers.  For example, the relational
442 operators in this section and the equality operators in the next
443 one return C<1> for true and a special version of the defined empty
444 string, C<"">, which counts as a zero but is exempt from warnings
445 about improper numeric conversions, just as S<C<"0 but true">> is.
446
447 Binary C<< "<" >> returns true if the left argument is numerically less than
448 the right argument.
449 X<< < >>
450
451 Binary C<< ">" >> returns true if the left argument is numerically greater
452 than the right argument.
453 X<< > >>
454
455 Binary C<< "<=" >> returns true if the left argument is numerically less than
456 or equal to the right argument.
457 X<< <= >>
458
459 Binary C<< ">=" >> returns true if the left argument is numerically greater
460 than or equal to the right argument.
461 X<< >= >>
462
463 Binary C<"lt"> returns true if the left argument is stringwise less than
464 the right argument.
465 X<< lt >>
466
467 Binary C<"gt"> returns true if the left argument is stringwise greater
468 than the right argument.
469 X<< gt >>
470
471 Binary C<"le"> returns true if the left argument is stringwise less than
472 or equal to the right argument.
473 X<< le >>
474
475 Binary C<"ge"> returns true if the left argument is stringwise greater
476 than or equal to the right argument.
477 X<< ge >>
478
479 =head2 Equality Operators
480 X<equality> X<equal> X<equals> X<operator, equality>
481
482 Binary C<< "==" >> returns true if the left argument is numerically equal to
483 the right argument.
484 X<==>
485
486 Binary C<< "!=" >> returns true if the left argument is numerically not equal
487 to the right argument.
488 X<!=>
489
490 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
491 argument is numerically less than, equal to, or greater than the right
492 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
493 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
494 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
495 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
496 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
497 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
498 X<< <=> >>
499 X<spaceship>
500
501     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
502     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
503
504 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
505 support C<"NaN">.)
506
507 Binary C<"eq"> returns true if the left argument is stringwise equal to
508 the right argument.
509 X<eq>
510
511 Binary C<"ne"> returns true if the left argument is stringwise not equal
512 to the right argument.
513 X<ne>
514
515 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
516 argument is stringwise less than, equal to, or greater than the right
517 argument.
518 X<cmp>
519
520 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
521 is described in the next section.
522 X<~~>
523
524 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
525 order specified by the current C<LC_COLLATE> locale if a S<C<use
526 locale>> form that includes collation is in effect.  See L<perllocale>.
527 Do not mix these with Unicode,
528 only use them with legacy 8-bit locale encodings.
529 The standard C<L<Unicode::Collate>> and
530 C<L<Unicode::Collate::Locale>> modules offer much more powerful
531 solutions to collation issues.
532
533 For case-insensitive comparisions, look at the L<perlfunc/fc> case-folding
534 function, available in Perl v5.16 or later:
535
536     if ( fc($x) eq fc($y) ) { ... }
537
538 =head2 Smartmatch Operator
539
540 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
541 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
542 used implicitly in the C<when> construct described in L<perlsyn>, although
543 not all C<when> clauses call the smartmatch operator.  Unique among all of
544 Perl's operators, the smartmatch operator can recurse.  The smartmatch
545 operator is L<experimental|perlpolicy/experimental> and its behavior is
546 subject to change.
547
548 It is also unique in that all other Perl operators impose a context
549 (usually string or numeric context) on their operands, autoconverting
550 those operands to those imposed contexts.  In contrast, smartmatch
551 I<infers> contexts from the actual types of its operands and uses that
552 type information to select a suitable comparison mechanism.
553
554 The C<~~> operator compares its operands "polymorphically", determining how
555 to compare them according to their actual types (numeric, string, array,
556 hash, etc.)  Like the equality operators with which it shares the same
557 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
558 read aloud as "in", "inside of", or "is contained in", because the left
559 operand is often looked for I<inside> the right operand.  That makes the
560 order of the operands to the smartmatch operand often opposite that of
561 the regular match operator.  In other words, the "smaller" thing is usually
562 placed in the left operand and the larger one in the right.
563
564 The behavior of a smartmatch depends on what type of things its arguments
565 are, as determined by the following table.  The first row of the table
566 whose types apply determines the smartmatch behavior.  Because what
567 actually happens is mostly determined by the type of the second operand,
568 the table is sorted on the right operand instead of on the left.
569
570  Left      Right      Description and pseudocode                               
571  ===============================================================
572  Any       undef      check whether Any is undefined                    
573                 like: !defined Any
574
575  Any       Object     invoke ~~ overloading on Object, or die
576
577  Right operand is an ARRAY:
578
579  Left      Right      Description and pseudocode                               
580  ===============================================================
581  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
582                 like: (ARRAY1[0] ~~ ARRAY2[0])
583                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
584  HASH      ARRAY      any ARRAY elements exist as HASH keys             
585                 like: grep { exists HASH->{$_} } ARRAY
586  Regexp    ARRAY      any ARRAY elements pattern match Regexp
587                 like: grep { /Regexp/ } ARRAY
588  undef     ARRAY      undef in ARRAY                                    
589                 like: grep { !defined } ARRAY
590  Any       ARRAY      smartmatch each ARRAY element[3]                   
591                 like: grep { Any ~~ $_ } ARRAY
592
593  Right operand is a HASH:
594
595  Left      Right      Description and pseudocode                               
596  ===============================================================
597  HASH1     HASH2      all same keys in both HASHes                      
598                 like: keys HASH1 ==
599                          grep { exists HASH2->{$_} } keys HASH1
600  ARRAY     HASH       any ARRAY elements exist as HASH keys             
601                 like: grep { exists HASH->{$_} } ARRAY
602  Regexp    HASH       any HASH keys pattern match Regexp                
603                 like: grep { /Regexp/ } keys HASH
604  undef     HASH       always false (undef can't be a key)               
605                 like: 0 == 1
606  Any       HASH       HASH key existence                                
607                 like: exists HASH->{Any}
608
609  Right operand is CODE:
610
611  Left      Right      Description and pseudocode                               
612  ===============================================================
613  ARRAY     CODE       sub returns true on all ARRAY elements[1]
614                 like: !grep { !CODE->($_) } ARRAY
615  HASH      CODE       sub returns true on all HASH keys[1]
616                 like: !grep { !CODE->($_) } keys HASH
617  Any       CODE       sub passed Any returns true              
618                 like: CODE->(Any)
619
620 Right operand is a Regexp:
621
622  Left      Right      Description and pseudocode                               
623  ===============================================================
624  ARRAY     Regexp     any ARRAY elements match Regexp                   
625                 like: grep { /Regexp/ } ARRAY
626  HASH      Regexp     any HASH keys match Regexp                        
627                 like: grep { /Regexp/ } keys HASH
628  Any       Regexp     pattern match                                     
629                 like: Any =~ /Regexp/
630
631  Other:
632
633  Left      Right      Description and pseudocode                               
634  ===============================================================
635  Object    Any        invoke ~~ overloading on Object,
636                       or fall back to...
637
638  Any       Num        numeric equality                                  
639                  like: Any == Num
640  Num       nummy[4]    numeric equality
641                  like: Num == nummy
642  undef     Any        check whether undefined
643                  like: !defined(Any)
644  Any       Any        string equality                                   
645                  like: Any eq Any
646
647
648 Notes:
649
650 =over
651
652 =item 1.
653 Empty hashes or arrays match. 
654
655 =item 2.
656 That is, each element smartmatches the element of the same index in the other array.[3]
657
658 =item 3.
659 If a circular reference is found, fall back to referential equality. 
660
661 =item 4.
662 Either an actual number, or a string that looks like one.
663
664 =back
665
666 The smartmatch implicitly dereferences any non-blessed hash or array
667 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
668 For blessed references, the C<I<Object>> entries apply.  Smartmatches
669 involving hashes only consider hash keys, never hash values.
670
671 The "like" code entry is not always an exact rendition.  For example, the
672 smartmatch operator short-circuits whenever possible, but C<grep> does
673 not.  Also, C<grep> in scalar context returns the number of matches, but
674 C<~~> returns only true or false.
675
676 Unlike most operators, the smartmatch operator knows to treat C<undef>
677 specially:
678
679     use v5.10.1;
680     @array = (1, 2, 3, undef, 4, 5);
681     say "some elements undefined" if undef ~~ @array;
682
683 Each operand is considered in a modified scalar context, the modification
684 being that array and hash variables are passed by reference to the
685 operator, which implicitly dereferences them.  Both elements
686 of each pair are the same:
687
688     use v5.10.1;
689
690     my %hash = (red    => 1, blue   => 2, green  => 3,
691                 orange => 4, yellow => 5, purple => 6,
692                 black  => 7, grey   => 8, white  => 9);
693
694     my @array = qw(red blue green);
695
696     say "some array elements in hash keys" if  @array ~~  %hash;
697     say "some array elements in hash keys" if \@array ~~ \%hash;
698
699     say "red in array" if "red" ~~  @array;
700     say "red in array" if "red" ~~ \@array;
701
702     say "some keys end in e" if /e$/ ~~  %hash;
703     say "some keys end in e" if /e$/ ~~ \%hash;
704
705 Two arrays smartmatch if each element in the first array smartmatches
706 (that is, is "in") the corresponding element in the second array,
707 recursively.
708
709     use v5.10.1;
710     my @little = qw(red blue green);
711     my @bigger = ("red", "blue", [ "orange", "green" ] );
712     if (@little ~~ @bigger) {  # true!
713         say "little is contained in bigger";
714     } 
715
716 Because the smartmatch operator recurses on nested arrays, this
717 will still report that "red" is in the array.
718
719     use v5.10.1;
720     my @array = qw(red blue green);
721     my $nested_array = [[[[[[[ @array ]]]]]]];
722     say "red in array" if "red" ~~ $nested_array;
723
724 If two arrays smartmatch each other, then they are deep
725 copies of each others' values, as this example reports:
726
727     use v5.12.0;
728     my @a = (0, 1, 2, [3, [4, 5], 6], 7); 
729     my @b = (0, 1, 2, [3, [4, 5], 6], 7); 
730
731     if (@a ~~ @b && @b ~~ @a) {
732         say "a and b are deep copies of each other";
733     } 
734     elsif (@a ~~ @b) {
735         say "a smartmatches in b";
736     } 
737     elsif (@b ~~ @a) {
738         say "b smartmatches in a";
739     } 
740     else {
741         say "a and b don't smartmatch each other at all";
742     } 
743
744
745 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
746 are deep copies of each other", it now reports that C<"b smartmatches in a">.
747 That's because the corresponding position in C<@a> contains an array that
748 (eventually) has a 4 in it.
749
750 Smartmatching one hash against another reports whether both contain the
751 same keys, no more and no less.  This could be used to see whether two
752 records have the same field names, without caring what values those fields
753 might have.  For example:
754
755     use v5.10.1;
756     sub make_dogtag {
757         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
758
759         my ($class, $init_fields) = @_;
760
761         die "Must supply (only) name, rank, and serial number"
762             unless $init_fields ~~ $REQUIRED_FIELDS;
763
764         ...
765     }
766
767 or, if other non-required fields are allowed, use ARRAY ~~ HASH:
768
769     use v5.10.1;
770     sub make_dogtag {
771         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
772
773         my ($class, $init_fields) = @_;
774
775         die "Must supply (at least) name, rank, and serial number"
776             unless [keys %{$init_fields}] ~~ $REQUIRED_FIELDS;
777
778         ...
779     }
780
781 The smartmatch operator is most often used as the implicit operator of a
782 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
783
784 =head3 Smartmatching of Objects
785
786 To avoid relying on an object's underlying representation, if the
787 smartmatch's right operand is an object that doesn't overload C<~~>,
788 it raises the exception "C<Smartmatching a non-overloaded object
789 breaks encapsulation>".  That's because one has no business digging
790 around to see whether something is "in" an object.  These are all
791 illegal on objects without a C<~~> overload:
792
793     %hash ~~ $object
794        42 ~~ $object
795    "fred" ~~ $object
796
797 However, you can change the way an object is smartmatched by overloading
798 the C<~~> operator.  This is allowed to
799 extend the usual smartmatch semantics.
800 For objects that do have an C<~~> overload, see L<overload>.
801
802 Using an object as the left operand is allowed, although not very useful.
803 Smartmatching rules take precedence over overloading, so even if the
804 object in the left operand has smartmatch overloading, this will be
805 ignored.  A left operand that is a non-overloaded object falls back on a
806 string or numeric comparison of whatever the C<ref> operator returns.  That
807 means that
808
809     $object ~~ X
810
811 does I<not> invoke the overload method with C<I<X>> as an argument.
812 Instead the above table is consulted as normal, and based on the type of
813 C<I<X>>, overloading may or may not be invoked.  For simple strings or
814 numbers, "in" becomes equivalent to this:
815
816     $object ~~ $number          ref($object) == $number
817     $object ~~ $string          ref($object) eq $string 
818
819 For example, this reports that the handle smells IOish
820 (but please don't really do this!):
821
822     use IO::Handle;
823     my $fh = IO::Handle->new();
824     if ($fh ~~ /\bIO\b/) {
825         say "handle smells IOish";
826     } 
827
828 That's because it treats C<$fh> as a string like
829 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
830
831 =head2 Bitwise And
832 X<operator, bitwise, and> X<bitwise and> X<&>
833
834 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
835 warning is currently raised, the result is not well defined when this operation
836 is performed on operands that aren't either numbers (see
837 L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String Operators>).
838
839 Note that C<"&"> has lower priority than relational operators, so for example
840 the parentheses are essential in a test like
841
842     print "Even\n" if ($x & 1) == 0;
843
844 If the experimental "bitwise" feature is enabled via S<C<use feature
845 'bitwise'>>, then this operator always treats its operand as numbers.  This
846 feature produces a warning unless you also use C<S<no warnings
847 'experimental::bitwise'>>.
848
849 =head2 Bitwise Or and Exclusive Or
850 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
851 X<bitwise xor> X<^>
852
853 Binary C<"|"> returns its operands ORed together bit by bit.
854
855 Binary C<"^"> returns its operands XORed together bit by bit.
856
857 Although no warning is currently raised, the results are not well
858 defined when these operations are performed on operands that aren't either
859 numbers (see L<Integer Arithmetic>) nor bitstrings (see L<Bitwise String
860 Operators>).
861
862 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
863 for example the parentheses are essential in a test like
864
865     print "false\n" if (8 | 2) != 10;
866
867 If the experimental "bitwise" feature is enabled via S<C<use feature
868 'bitwise'>>, then this operator always treats its operand as numbers.  This
869 feature produces a warning unless you also use S<C<no warnings
870 'experimental::bitwise'>>.
871
872 =head2 C-style Logical And
873 X<&&> X<logical and> X<operator, logical, and>
874
875 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
876 if the left operand is false, the right operand is not even evaluated.
877 Scalar or list context propagates down to the right operand if it
878 is evaluated.
879
880 =head2 C-style Logical Or
881 X<||> X<operator, logical, or>
882
883 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
884 if the left operand is true, the right operand is not even evaluated.
885 Scalar or list context propagates down to the right operand if it
886 is evaluated.
887
888 =head2 Logical Defined-Or
889 X<//> X<operator, logical, defined-or>
890
891 Although it has no direct equivalent in C, Perl's C<//> operator is related
892 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
893 tests the left hand side's definedness instead of its truth.  Thus,
894 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
895 otherwise, the value of C<< EXPR2 >> is returned.
896 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
897 in the context of C<< // >> itself).  Usually,
898 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
899 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
900 cannot).  This is very useful for
901 providing default values for variables.  If you actually want to test if
902 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
903
904 The C<||>, C<//> and C<&&> operators return the last value evaluated
905 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
906 portable way to find out the home directory might be:
907
908     $home =  $ENV{HOME}
909           // $ENV{LOGDIR}
910           // (getpwuid($<))[7]
911           // die "You're homeless!\n";
912
913 In particular, this means that you shouldn't use this
914 for selecting between two aggregates for assignment:
915
916     @a = @b || @c;              # this is wrong
917     @a = scalar(@b) || @c;      # really meant this
918     @a = @b ? @b : @c;          # this works fine, though
919
920 As alternatives to C<&&> and C<||> when used for
921 control flow, Perl provides the C<and> and C<or> operators (see below).
922 The short-circuit behavior is identical.  The precedence of C<"and">
923 and C<"or"> is much lower, however, so that you can safely use them after a
924 list operator without the need for parentheses:
925
926     unlink "alpha", "beta", "gamma"
927             or gripe(), next LINE;
928
929 With the C-style operators that would have been written like this:
930
931     unlink("alpha", "beta", "gamma")
932             || (gripe(), next LINE);
933
934 It would be even more readable to write that this way:
935
936     unless(unlink("alpha", "beta", "gamma")) {
937         gripe();
938         next LINE;
939     } 
940
941 Using C<"or"> for assignment is unlikely to do what you want; see below.
942
943 =head2 Range Operators
944 X<operator, range> X<range> X<..> X<...>
945
946 Binary C<".."> is the range operator, which is really two different
947 operators depending on the context.  In list context, it returns a
948 list of values counting (up by ones) from the left value to the right
949 value.  If the left value is greater than the right value then it
950 returns the empty list.  The range operator is useful for writing
951 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
952 the current implementation, no temporary array is created when the
953 range operator is used as the expression in C<foreach> loops, but older
954 versions of Perl might burn a lot of memory when you write something
955 like this:
956
957     for (1 .. 1_000_000) {
958         # code
959     }
960
961 The range operator also works on strings, using the magical
962 auto-increment, see below.
963
964 In scalar context, C<".."> returns a boolean value.  The operator is
965 bistable, like a flip-flop, and emulates the line-range (comma)
966 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
967 maintains its own boolean state, even across calls to a subroutine
968 that contains it.  It is false as long as its left operand is false.
969 Once the left operand is true, the range operator stays true until the
970 right operand is true, I<AFTER> which the range operator becomes false
971 again.  It doesn't become false till the next time the range operator
972 is evaluated.  It can test the right operand and become false on the
973 same evaluation it became true (as in B<awk>), but it still returns
974 true once.  If you don't want it to test the right operand until the
975 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
976 two.  In all other regards, C<"..."> behaves just like C<".."> does.
977
978 The right operand is not evaluated while the operator is in the
979 "false" state, and the left operand is not evaluated while the
980 operator is in the "true" state.  The precedence is a little lower
981 than || and &&.  The value returned is either the empty string for
982 false, or a sequence number (beginning with 1) for true.  The sequence
983 number is reset for each range encountered.  The final sequence number
984 in a range has the string C<"E0"> appended to it, which doesn't affect
985 its numeric value, but gives you something to search for if you want
986 to exclude the endpoint.  You can exclude the beginning point by
987 waiting for the sequence number to be greater than 1.
988
989 If either operand of scalar C<".."> is a constant expression,
990 that operand is considered true if it is equal (C<==>) to the current
991 input line number (the C<$.> variable).
992
993 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
994 but that is only an issue if you use a floating point expression; when
995 implicitly using C<$.> as described in the previous paragraph, the
996 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
997 is set to a floating point value and you are not reading from a file.
998 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
999 you want in scalar context because each of the operands are evaluated
1000 using their integer representation.
1001
1002 Examples:
1003
1004 As a scalar operator:
1005
1006     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1007                                #  if ($. == 101 .. $. == 200) { print; }
1008
1009     next LINE if (1 .. /^$/);  # skip header lines, short for
1010                                #   next LINE if ($. == 1 .. /^$/);
1011                                # (typically in a loop labeled LINE)
1012
1013     s/^/> / if (/^$/ .. eof());  # quote body
1014
1015     # parse mail messages
1016     while (<>) {
1017         $in_header =   1  .. /^$/;
1018         $in_body   = /^$/ .. eof;
1019         if ($in_header) {
1020             # do something
1021         } else { # in body
1022             # do something else
1023         }
1024     } continue {
1025         close ARGV if eof;             # reset $. each file
1026     }
1027
1028 Here's a simple example to illustrate the difference between
1029 the two range operators:
1030
1031     @lines = ("   - Foo",
1032               "01 - Bar",
1033               "1  - Baz",
1034               "   - Quux");
1035
1036     foreach (@lines) {
1037         if (/0/ .. /1/) {
1038             print "$_\n";
1039         }
1040     }
1041
1042 This program will print only the line containing "Bar".  If
1043 the range operator is changed to C<...>, it will also print the
1044 "Baz" line.
1045
1046 And now some examples as a list operator:
1047
1048     for (101 .. 200) { print }      # print $_ 100 times
1049     @foo = @foo[0 .. $#foo];        # an expensive no-op
1050     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1051
1052 The range operator (in list context) makes use of the magical
1053 auto-increment algorithm if the operands are strings.  You
1054 can say
1055
1056     @alphabet = ("A" .. "Z");
1057
1058 to get all normal letters of the English alphabet, or
1059
1060     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1061
1062 to get a hexadecimal digit, or
1063
1064     @z2 = ("01" .. "31");
1065     print $z2[$mday];
1066
1067 to get dates with leading zeros.
1068
1069 If the final value specified is not in the sequence that the magical
1070 increment would produce, the sequence goes until the next value would
1071 be longer than the final value specified.
1072
1073 If the initial value specified isn't part of a magical increment
1074 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1075 only the initial value will be returned.  So the following will only
1076 return an alpha:
1077
1078     use charnames "greek";
1079     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1080
1081 To get the 25 traditional lowercase Greek letters, including both sigmas,
1082 you could use this instead:
1083
1084     use charnames "greek";
1085     my @greek_small =  map { chr } ( ord("\N{alpha}") 
1086                                         ..
1087                                      ord("\N{omega}") 
1088                                    );
1089
1090 However, because there are I<many> other lowercase Greek characters than
1091 just those, to match lowercase Greek characters in a regular expression,
1092 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1093 L<experimental feature|perlrecharclass/Extended Bracketed Character
1094 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1095
1096 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1097 return two elements in list context.
1098
1099     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1100
1101 =head2 Conditional Operator
1102 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1103
1104 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1105 like an if-then-else.  If the argument before the C<?> is true, the
1106 argument before the C<:> is returned, otherwise the argument after the
1107 C<:> is returned.  For example:
1108
1109     printf "I have %d dog%s.\n", $n,
1110             ($n == 1) ? "" : "s";
1111
1112 Scalar or list context propagates downward into the 2nd
1113 or 3rd argument, whichever is selected.
1114
1115     $x = $ok ? $y : $z;  # get a scalar
1116     @x = $ok ? @y : @z;  # get an array
1117     $x = $ok ? @y : @z;  # oops, that's just a count!
1118
1119 The operator may be assigned to if both the 2nd and 3rd arguments are
1120 legal lvalues (meaning that you can assign to them):
1121
1122     ($x_or_y ? $x : $y) = $z;
1123
1124 Because this operator produces an assignable result, using assignments
1125 without parentheses will get you in trouble.  For example, this:
1126
1127     $x % 2 ? $x += 10 : $x += 2
1128
1129 Really means this:
1130
1131     (($x % 2) ? ($x += 10) : $x) += 2
1132
1133 Rather than this:
1134
1135     ($x % 2) ? ($x += 10) : ($x += 2)
1136
1137 That should probably be written more simply as:
1138
1139     $x += ($x % 2) ? 10 : 2;
1140
1141 =head2 Assignment Operators
1142 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1143 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1144 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1145
1146 C<"="> is the ordinary assignment operator.
1147
1148 Assignment operators work as in C.  That is,
1149
1150     $x += 2;
1151
1152 is equivalent to
1153
1154     $x = $x + 2;
1155
1156 although without duplicating any side effects that dereferencing the lvalue
1157 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1158 The following are recognized:
1159
1160     **=    +=    *=    &=    &.=    <<=    &&=
1161            -=    /=    |=    |.=    >>=    ||=
1162            .=    %=    ^=    ^.=           //=
1163                  x=
1164
1165 Although these are grouped by family, they all have the precedence
1166 of assignment.  These combined assignment operators can only operate on
1167 scalars, whereas the ordinary assignment operator can assign to arrays,
1168 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1169 and L<perldata/List value constructors>, and L<perlref/Assigning to
1170 References>.)
1171
1172 Unlike in C, the scalar assignment operator produces a valid lvalue.
1173 Modifying an assignment is equivalent to doing the assignment and
1174 then modifying the variable that was assigned to.  This is useful
1175 for modifying a copy of something, like this:
1176
1177     ($tmp = $global) =~ tr/13579/24680/;
1178
1179 Although as of 5.14, that can be also be accomplished this way:
1180
1181     use v5.14;
1182     $tmp = ($global =~  tr/13579/24680/r);
1183
1184 Likewise,
1185
1186     ($x += 2) *= 3;
1187
1188 is equivalent to
1189
1190     $x += 2;
1191     $x *= 3;
1192
1193 Similarly, a list assignment in list context produces the list of
1194 lvalues assigned to, and a list assignment in scalar context returns
1195 the number of elements produced by the expression on the right hand
1196 side of the assignment.
1197
1198 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1199 Perl 5.22 and experimental.  See L</Bitwise String Operators>.
1200
1201 =head2 Comma Operator
1202 X<comma> X<operator, comma> X<,>
1203
1204 Binary C<","> is the comma operator.  In scalar context it evaluates
1205 its left argument, throws that value away, then evaluates its right
1206 argument and returns that value.  This is just like C's comma operator.
1207
1208 In list context, it's just the list argument separator, and inserts
1209 both its arguments into the list.  These arguments are also evaluated
1210 from left to right.
1211
1212 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1213 for the comma except that it causes a
1214 word on its left to be interpreted as a string if it begins with a letter
1215 or underscore and is composed only of letters, digits and underscores.
1216 This includes operands that might otherwise be interpreted as operators,
1217 constants, single number v-strings or function calls.  If in doubt about
1218 this behavior, the left operand can be quoted explicitly.
1219
1220 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1221 or list argument separator, according to context.
1222
1223 For example:
1224
1225     use constant FOO => "something";
1226
1227     my %h = ( FOO => 23 );
1228
1229 is equivalent to:
1230
1231     my %h = ("FOO", 23);
1232
1233 It is I<NOT>:
1234
1235     my %h = ("something", 23);
1236
1237 The C<< => >> operator is helpful in documenting the correspondence
1238 between keys and values in hashes, and other paired elements in lists.
1239
1240     %hash = ( $key => $value );
1241     login( $username => $password );
1242
1243 The special quoting behavior ignores precedence, and hence may apply to
1244 I<part> of the left operand:
1245
1246     print time.shift => "bbb";
1247
1248 That example prints something like C<"1314363215shiftbbb">, because the
1249 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1250 the fact that C<time.shift> is the entire left operand.
1251
1252 =head2 List Operators (Rightward)
1253 X<operator, list, rightward> X<list operator>
1254
1255 On the right side of a list operator, the comma has very low precedence,
1256 such that it controls all comma-separated expressions found there.
1257 The only operators with lower precedence are the logical operators
1258 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1259 operators without the need for parentheses:
1260
1261     open HANDLE, "< :utf8", "filename" or die "Can't open: $!\n";
1262
1263 However, some people find that code harder to read than writing
1264 it with parentheses:
1265
1266     open(HANDLE, "< :utf8", "filename") or die "Can't open: $!\n";
1267
1268 in which case you might as well just use the more customary C<"||"> operator:
1269
1270     open(HANDLE, "< :utf8", "filename") || die "Can't open: $!\n";
1271
1272 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
1273
1274 =head2 Logical Not
1275 X<operator, logical, not> X<not>
1276
1277 Unary C<"not"> returns the logical negation of the expression to its right.
1278 It's the equivalent of C<"!"> except for the very low precedence.
1279
1280 =head2 Logical And
1281 X<operator, logical, and> X<and>
1282
1283 Binary C<"and"> returns the logical conjunction of the two surrounding
1284 expressions.  It's equivalent to C<&&> except for the very low
1285 precedence.  This means that it short-circuits: the right
1286 expression is evaluated only if the left expression is true.
1287
1288 =head2 Logical or and Exclusive Or
1289 X<operator, logical, or> X<operator, logical, xor>
1290 X<operator, logical, exclusive or>
1291 X<or> X<xor>
1292
1293 Binary C<"or"> returns the logical disjunction of the two surrounding
1294 expressions.  It's equivalent to C<||> except for the very low precedence.
1295 This makes it useful for control flow:
1296
1297     print FH $data              or die "Can't write to FH: $!";
1298
1299 This means that it short-circuits: the right expression is evaluated
1300 only if the left expression is false.  Due to its precedence, you must
1301 be careful to avoid using it as replacement for the C<||> operator.
1302 It usually works out better for flow control than in assignments:
1303
1304     $x = $y or $z;              # bug: this is wrong
1305     ($x = $y) or $z;            # really means this
1306     $x = $y || $z;              # better written this way
1307
1308 However, when it's a list-context assignment and you're trying to use
1309 C<||> for control flow, you probably need C<"or"> so that the assignment
1310 takes higher precedence.
1311
1312     @info = stat($file) || die;     # oops, scalar sense of stat!
1313     @info = stat($file) or die;     # better, now @info gets its due
1314
1315 Then again, you could always use parentheses.
1316
1317 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1318 It cannot short-circuit (of course).
1319
1320 There is no low precedence operator for defined-OR.
1321
1322 =head2 C Operators Missing From Perl
1323 X<operator, missing from perl> X<&> X<*>
1324 X<typecasting> X<(TYPE)>
1325
1326 Here is what C has that Perl doesn't:
1327
1328 =over 8
1329
1330 =item unary &
1331
1332 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1333
1334 =item unary *
1335
1336 Dereference-address operator.  (Perl's prefix dereferencing
1337 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1338
1339 =item (TYPE)
1340
1341 Type-casting operator.
1342
1343 =back
1344
1345 =head2 Quote and Quote-like Operators
1346 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1347 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1348 X<escape sequence> X<escape>
1349
1350 While we usually think of quotes as literal values, in Perl they
1351 function as operators, providing various kinds of interpolating and
1352 pattern matching capabilities.  Perl provides customary quote characters
1353 for these behaviors, but also provides a way for you to choose your
1354 quote character for any of them.  In the following table, a C<{}> represents
1355 any pair of delimiters you choose.
1356
1357     Customary  Generic        Meaning        Interpolates
1358         ''       q{}          Literal             no
1359         ""      qq{}          Literal             yes
1360         ``      qx{}          Command             yes*
1361                 qw{}         Word list            no
1362         //       m{}       Pattern match          yes*
1363                 qr{}          Pattern             yes*
1364                  s{}{}      Substitution          yes*
1365                 tr{}{}    Transliteration         no (but see below)
1366                  y{}{}    Transliteration         no (but see below)
1367         <<EOF                 here-doc            yes*
1368
1369         * unless the delimiter is ''.
1370
1371 Non-bracketing delimiters use the same character fore and aft, but the four
1372 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1373 that
1374
1375     q{foo{bar}baz}
1376
1377 is the same as
1378
1379     'foo{bar}baz'
1380
1381 Note, however, that this does not always work for quoting Perl code:
1382
1383     $s = q{ if($x eq "}") ... }; # WRONG
1384
1385 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1386 and from CPAN before then) is able to do this properly.
1387
1388 There can be whitespace between the operator and the quoting
1389 characters, except when C<#> is being used as the quoting character.
1390 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1391 operator C<q> followed by a comment.  Its argument will be taken
1392 from the next line.  This allows you to write:
1393
1394     s {foo}  # Replace foo
1395       {bar}  # with bar.
1396
1397 The following escape sequences are available in constructs that interpolate,
1398 and in transliterations:
1399 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1400 X<\o{}>
1401
1402     Sequence     Note  Description
1403     \t                  tab               (HT, TAB)
1404     \n                  newline           (NL)
1405     \r                  return            (CR)
1406     \f                  form feed         (FF)
1407     \b                  backspace         (BS)
1408     \a                  alarm (bell)      (BEL)
1409     \e                  escape            (ESC)
1410     \x{263A}     [1,8]  hex char          (example: SMILEY)
1411     \x1b         [2,8]  restricted range hex char (example: ESC)
1412     \N{name}     [3]    named Unicode character or character sequence
1413     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1414     \c[          [5]    control char      (example: chr(27))
1415     \o{23072}    [6,8]  octal char        (example: SMILEY)
1416     \033         [7,8]  restricted range octal char  (example: ESC)
1417
1418 =over 4
1419
1420 =item [1]
1421
1422 The result is the character specified by the hexadecimal number between
1423 the braces.  See L</[8]> below for details on which character.
1424
1425 Only hexadecimal digits are valid between the braces.  If an invalid
1426 character is encountered, a warning will be issued and the invalid
1427 character and all subsequent characters (valid or invalid) within the
1428 braces will be discarded.
1429
1430 If there are no valid digits between the braces, the generated character is
1431 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1432 will not cause a warning (currently).
1433
1434 =item [2]
1435
1436 The result is the character specified by the hexadecimal number in the range
1437 0x00 to 0xFF.  See L</[8]> below for details on which character.
1438
1439 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1440 by fewer than two valid digits, any valid digits will be zero-padded.  This
1441 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1442 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1443 two valid digits will result in a warning.  Note that although the warning
1444 says the illegal character is ignored, it is only ignored as part of the
1445 escape and will still be used as the subsequent character in the string.
1446 For example:
1447
1448   Original    Result    Warns?
1449   "\x7"       "\x07"    no
1450   "\x"        "\x00"    no
1451   "\x7q"      "\x07q"   yes
1452   "\xq"       "\x00q"   yes
1453
1454 =item [3]
1455
1456 The result is the Unicode character or character sequence given by I<name>.
1457 See L<charnames>.
1458
1459 =item [4]
1460
1461 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1462 point is I<hexadecimal number>.
1463
1464 =item [5]
1465
1466 The character following C<\c> is mapped to some other character as shown in the
1467 table:
1468
1469  Sequence   Value
1470    \c@      chr(0)
1471    \cA      chr(1)
1472    \ca      chr(1)
1473    \cB      chr(2)
1474    \cb      chr(2)
1475    ...
1476    \cZ      chr(26)
1477    \cz      chr(26)
1478    \c[      chr(27)
1479                      # See below for chr(28)
1480    \c]      chr(29)
1481    \c^      chr(30)
1482    \c_      chr(31)
1483    \c?      chr(127) # (on ASCII platforms; see below for link to
1484                      #  EBCDIC discussion)
1485
1486 In other words, it's the character whose code point has had 64 xor'd with
1487 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1488 S<C<ord("?") ^ 64>> is 127, and
1489 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1490
1491 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1492 end of a string, because the backslash would be parsed as escaping the end
1493 quote.
1494
1495 On ASCII platforms, the resulting characters from the list above are the
1496 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1497 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1498 differences between these for ASCII versus EBCDIC platforms.
1499
1500 Use of any other character following the C<"c"> besides those listed above is
1501 discouraged, and as of Perl v5.20, the only characters actually allowed
1502 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1503 for any of the allowed other characters is that the value is derived by
1504 xor'ing with the seventh bit, which is 64, and a warning raised if
1505 enabled.  Using the non-allowed characters generates a fatal error.
1506
1507 To get platform independent controls, you can use C<\N{...}>.
1508
1509 =item [6]
1510
1511 The result is the character specified by the octal number between the braces.
1512 See L</[8]> below for details on which character.
1513
1514 If a character that isn't an octal digit is encountered, a warning is raised,
1515 and the value is based on the octal digits before it, discarding it and all
1516 following characters up to the closing brace.  It is a fatal error if there are
1517 no octal digits at all.
1518
1519 =item [7]
1520
1521 The result is the character specified by the three-digit octal number in the
1522 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1523 L</[8]> below for details on which character.
1524
1525 Some contexts allow 2 or even 1 digit, but any usage without exactly
1526 three digits, the first being a zero, may give unintended results.  (For
1527 example, in a regular expression it may be confused with a backreference;
1528 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1529 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1530 use this construct only for ordinals C<\077> and below, remembering to pad to
1531 the left with zeros to make three digits.  For larger ordinals, either use
1532 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1533 (which is portable between platforms with different character sets) or
1534 C<\x{}> instead.
1535
1536 =item [8]
1537
1538 Several constructs above specify a character by a number.  That number
1539 gives the character's position in the character set encoding (indexed from 0).
1540 This is called synonymously its ordinal, code position, or code point.  Perl
1541 works on platforms that have a native encoding currently of either ASCII/Latin1
1542 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1543 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1544 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1545 it as a Unicode code point and the result is the corresponding Unicode
1546 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1547 decimal, which is less than 256, so the number is interpreted in the native
1548 character set encoding.  In ASCII the character in the 80th position (indexed
1549 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1550 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1551 as a Unicode code point no matter what the native encoding is.  The name of the
1552 character in the 256th position (indexed by 0) in Unicode is
1553 C<LATIN CAPITAL LETTER A WITH MACRON>.
1554
1555 There are a couple of exceptions to the above rule.  S<C<\N{U+I<hex number>}>> is
1556 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1557 on EBCDIC platforms.  And if C<S<L<use encoding|encoding>>> is in effect, the
1558 number is considered to be in that encoding, and is translated from that into
1559 the platform's native encoding if there is a corresponding native character;
1560 otherwise to Unicode.
1561
1562 =back
1563
1564 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1565 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1566 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1567 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1568
1569 The following escape sequences are available in constructs that interpolate,
1570 but not in transliterations.
1571 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1572
1573     \l          lowercase next character only
1574     \u          titlecase (not uppercase!) next character only
1575     \L          lowercase all characters till \E or end of string
1576     \U          uppercase all characters till \E or end of string
1577     \F          foldcase all characters till \E or end of string
1578     \Q          quote (disable) pattern metacharacters till \E or
1579                 end of string
1580     \E          end either case modification or quoted section
1581                 (whichever was last seen)
1582
1583 See L<perlfunc/quotemeta> for the exact definition of characters that
1584 are quoted by C<\Q>.
1585
1586 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1587 C<\E> for each.  For example:
1588
1589  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1590  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1591
1592 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1593 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1594 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1595 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1596 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1597 case-mapping a single character can sometimes produce a sequence of
1598 several characters.
1599 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1600 for all locales but a UTF-8 one, where it instead uses the Unicode
1601 definition.
1602
1603 All systems use the virtual C<"\n"> to represent a line terminator,
1604 called a "newline".  There is no such thing as an unvarying, physical
1605 newline character.  It is only an illusion that the operating system,
1606 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1607 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1608 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1609 and on systems without a line terminator,
1610 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1611 you mean a "newline" for your system, but use the literal ASCII when you
1612 need an exact character.  For example, most networking protocols expect
1613 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1614 and although they often accept just C<"\012">, they seldom tolerate just
1615 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1616 you may be burned some day.
1617 X<newline> X<line terminator> X<eol> X<end of line>
1618 X<\n> X<\r> X<\r\n>
1619
1620 For constructs that do interpolate, variables beginning with "C<$>"
1621 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1622 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1623 But method calls such as C<< $obj->meth >> are not.
1624
1625 Interpolating an array or slice interpolates the elements in order,
1626 separated by the value of C<$">, so is equivalent to interpolating
1627 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1628 interpolated only if the name is enclosed in braces C<@{*}>, but the
1629 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1630
1631 For double-quoted strings, the quoting from C<\Q> is applied after
1632 interpolation and escapes are processed.
1633
1634     "abc\Qfoo\tbar$s\Exyz"
1635
1636 is equivalent to
1637
1638     "abc" . quotemeta("foo\tbar$s") . "xyz"
1639
1640 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1641 the quoting from C<\Q> is applied after interpolation is processed,
1642 but before escapes are processed.  This allows the pattern to match
1643 literally (except for C<$> and C<@>).  For example, the following matches:
1644
1645     '\s\t' =~ /\Q\s\t/
1646
1647 Because C<$> or C<@> trigger interpolation, you'll need to use something
1648 like C</\Quser\E\@\Qhost/> to match them literally.
1649
1650 Patterns are subject to an additional level of interpretation as a
1651 regular expression.  This is done as a second pass, after variables are
1652 interpolated, so that regular expressions may be incorporated into the
1653 pattern from the variables.  If this is not what you want, use C<\Q> to
1654 interpolate a variable literally.
1655
1656 Apart from the behavior described above, Perl does not expand
1657 multiple levels of interpolation.  In particular, contrary to the
1658 expectations of shell programmers, back-quotes do I<NOT> interpolate
1659 within double quotes, nor do single quotes impede evaluation of
1660 variables when used within double quotes.
1661
1662 =head2 Regexp Quote-Like Operators
1663 X<operator, regexp>
1664
1665 Here are the quote-like operators that apply to pattern
1666 matching and related activities.
1667
1668 =over 8
1669
1670 =item C<qr/I<STRING>/msixpodualn>
1671 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1672
1673 This operator quotes (and possibly compiles) its I<STRING> as a regular
1674 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1675 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no interpolation
1676 is done.  Returns a Perl value which may be used instead of the
1677 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1678 normalized version of the original pattern.  It magically differs from
1679 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1680 however, dereferencing it is not well defined (you currently get the 
1681 normalized version of the original pattern, but this may change).
1682
1683
1684 For example,
1685
1686     $rex = qr/my.STRING/is;
1687     print $rex;                 # prints (?si-xm:my.STRING)
1688     s/$rex/foo/;
1689
1690 is equivalent to
1691
1692     s/my.STRING/foo/is;
1693
1694 The result may be used as a subpattern in a match:
1695
1696     $re = qr/$pattern/;
1697     $string =~ /foo${re}bar/;   # can be interpolated in other
1698                                 # patterns
1699     $string =~ $re;             # or used standalone
1700     $string =~ /$re/;           # or this way
1701
1702 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1703 operator, using C<qr()> may have speed advantages in some situations,
1704 notably if the result of C<qr()> is used standalone:
1705
1706     sub match {
1707         my $patterns = shift;
1708         my @compiled = map qr/$_/i, @$patterns;
1709         grep {
1710             my $success = 0;
1711             foreach my $pat (@compiled) {
1712                 $success = 1, last if /$pat/;
1713             }
1714             $success;
1715         } @_;
1716     }
1717
1718 Precompilation of the pattern into an internal representation at
1719 the moment of C<qr()> avoids the need to recompile the pattern every
1720 time a match C</$pat/> is attempted.  (Perl has many other internal
1721 optimizations, but none would be triggered in the above example if
1722 we did not use C<qr()> operator.)
1723
1724 Options (specified by the following modifiers) are:
1725
1726     m   Treat string as multiple lines.
1727     s   Treat string as single line. (Make . match a newline)
1728     i   Do case-insensitive pattern matching.
1729     x   Use extended regular expressions.
1730     p   When matching preserve a copy of the matched string so
1731         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1732         defined (ignored starting in v5.20) as these are always
1733         defined starting in that relese
1734     o   Compile pattern only once.
1735     a   ASCII-restrict: Use ASCII for \d, \s, \w; specifying two
1736         a's further restricts things to that that no ASCII
1737         character will match a non-ASCII one under /i.
1738     l   Use the current run-time locale's rules.
1739     u   Use Unicode rules.
1740     d   Use Unicode or native charset, as in 5.12 and earlier.
1741     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1742
1743 If a precompiled pattern is embedded in a larger pattern then the effect
1744 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1745 C</o> modifier has is not propagated, being restricted to those patterns
1746 explicitly using it.
1747
1748 The last four modifiers listed above, added in Perl 5.14,
1749 control the character set rules, but C</a> is the only one you are likely
1750 to want to specify explicitly; the other three are selected
1751 automatically by various pragmas.
1752
1753 See L<perlre> for additional information on valid syntax for I<STRING>, and
1754 for a detailed look at the semantics of regular expressions.  In
1755 particular, all modifiers except the largely obsolete C</o> are further
1756 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1757
1758 =item C<m/I<PATTERN>/msixpodualngc>
1759 X<m> X<operator, match>
1760 X<regexp, options> X<regexp> X<regex, options> X<regex>
1761 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1762
1763 =item C</I<PATTERN>/msixpodualngc>
1764
1765 Searches a string for a pattern match, and in scalar context returns
1766 true if it succeeds, false if it fails.  If no string is specified
1767 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1768 string specified with C<=~> need not be an lvalue--it may be the
1769 result of an expression evaluation, but remember the C<=~> binds
1770 rather tightly.)  See also L<perlre>.
1771
1772 Options are as described in C<qr//> above; in addition, the following match
1773 process modifiers are available:
1774
1775  g  Match globally, i.e., find all occurrences.
1776  c  Do not reset search position on a failed match when /g is
1777     in effect.
1778
1779 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1780 you can use any pair of non-whitespace (ASCII) characters
1781 as delimiters.  This is particularly useful for matching path names
1782 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1783 the delimiter, then a match-only-once rule applies,
1784 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1785 no interpolation is performed on the I<PATTERN>.
1786 When using a delimiter character valid in an identifier, whitespace is required
1787 after the C<m>.
1788
1789 I<PATTERN> may contain variables, which will be interpolated
1790 every time the pattern search is evaluated, except
1791 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1792 C<$|> are not interpolated because they look like end-of-string tests.)
1793 Perl will not recompile the pattern unless an interpolated
1794 variable that it contains changes.  You can force Perl to skip the
1795 test and never recompile by adding a C</o> (which stands for "once")
1796 after the trailing delimiter.
1797 Once upon a time, Perl would recompile regular expressions
1798 unnecessarily, and this modifier was useful to tell it not to do so, in the
1799 interests of speed.  But now, the only reasons to use C</o> are one of:
1800
1801 =over
1802
1803 =item 1
1804
1805 The variables are thousands of characters long and you know that they
1806 don't change, and you need to wring out the last little bit of speed by
1807 having Perl skip testing for that.  (There is a maintenance penalty for
1808 doing this, as mentioning C</o> constitutes a promise that you won't
1809 change the variables in the pattern.  If you do change them, Perl won't
1810 even notice.)
1811
1812 =item 2
1813
1814 you want the pattern to use the initial values of the variables
1815 regardless of whether they change or not.  (But there are saner ways
1816 of accomplishing this than using C</o>.)
1817
1818 =item 3
1819
1820 If the pattern contains embedded code, such as
1821
1822     use re 'eval';
1823     $code = 'foo(?{ $x })';
1824     /$code/
1825
1826 then perl will recompile each time, even though the pattern string hasn't
1827 changed, to ensure that the current value of C<$x> is seen each time.
1828 Use C</o> if you want to avoid this.
1829
1830 =back
1831
1832 The bottom line is that using C</o> is almost never a good idea.
1833
1834 =item The empty pattern C<//>
1835
1836 If the I<PATTERN> evaluates to the empty string, the last
1837 I<successfully> matched regular expression is used instead.  In this
1838 case, only the C<g> and C<c> flags on the empty pattern are honored;
1839 the other flags are taken from the original pattern.  If no match has
1840 previously succeeded, this will (silently) act instead as a genuine
1841 empty pattern (which will always match).
1842
1843 Note that it's possible to confuse Perl into thinking C<//> (the empty
1844 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1845 good about this, but some pathological cases might trigger this, such as
1846 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1847 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1848 will assume you meant defined-or.  If you meant the empty regex, just
1849 use parentheses or spaces to disambiguate, or even prefix the empty
1850 regex with an C<m> (so C<//> becomes C<m//>).
1851
1852 =item Matching in list context
1853
1854 If the C</g> option is not used, C<m//> in list context returns a
1855 list consisting of the subexpressions matched by the parentheses in the
1856 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1857 also set).  When there are no parentheses in the pattern, the return
1858 value is the list C<(1)> for success.  
1859 With or without parentheses, an empty list is returned upon failure.
1860
1861 Examples:
1862
1863  open(TTY, "+</dev/tty")
1864     || die "can't access /dev/tty: $!";
1865
1866  <TTY> =~ /^y/i && foo();       # do foo if desired
1867
1868  if (/Version: *([0-9.]*)/) { $version = $1; }
1869
1870  next if m#^/usr/spool/uucp#;
1871
1872  # poor man's grep
1873  $arg = shift;
1874  while (<>) {
1875     print if /$arg/o; # compile only once (no longer needed!)
1876  }
1877
1878  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1879
1880 This last example splits C<$foo> into the first two words and the
1881 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1882 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1883 if the pattern matched.
1884
1885 The C</g> modifier specifies global pattern matching--that is,
1886 matching as many times as possible within the string.  How it behaves
1887 depends on the context.  In list context, it returns a list of the
1888 substrings matched by any capturing parentheses in the regular
1889 expression.  If there are no parentheses, it returns a list of all
1890 the matched strings, as if there were parentheses around the whole
1891 pattern.
1892
1893 In scalar context, each execution of C<m//g> finds the next match,
1894 returning true if it matches, and false if there is no further match.
1895 The position after the last match can be read or set using the C<pos()>
1896 function; see L<perlfunc/pos>.  A failed match normally resets the
1897 search position to the beginning of the string, but you can avoid that
1898 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1899 string also resets the search position.
1900
1901 =item C<\G I<assertion>>
1902
1903 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1904 zero-width assertion that matches the exact position where the
1905 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1906 C<\G> assertion still anchors at C<pos()> as it was at the start of
1907 the operation (see L<perlfunc/pos>), but the match is of course only
1908 attempted once.  Using C<\G> without C</g> on a target string that has
1909 not previously had a C</g> match applied to it is the same as using
1910 the C<\A> assertion to match the beginning of the string.  Note also
1911 that, currently, C<\G> is only properly supported when anchored at the
1912 very beginning of the pattern.
1913
1914 Examples:
1915
1916     # list context
1917     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1918
1919     # scalar context
1920     local $/ = "";
1921     while ($paragraph = <>) {
1922         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1923             $sentences++;
1924         }
1925     }
1926     say $sentences;
1927
1928 Here's another way to check for sentences in a paragraph:
1929
1930  my $sentence_rx = qr{
1931     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1932                                 # whitespace
1933     \p{Lu}                      # capital letter
1934     .*?                         # a bunch of anything
1935     (?<= \S )                   # that ends in non-
1936                                 # whitespace
1937     (?<! \b [DMS]r  )           # but isn't a common abbr.
1938     (?<! \b Mrs )
1939     (?<! \b Sra )
1940     (?<! \b St  )
1941     [.?!]                       # followed by a sentence
1942                                 # ender
1943     (?= $ | \s )                # in front of end-of-string
1944                                 # or whitespace
1945  }sx;
1946  local $/ = "";
1947  while (my $paragraph = <>) {
1948     say "NEW PARAGRAPH";
1949     my $count = 0;
1950     while ($paragraph =~ /($sentence_rx)/g) {
1951         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
1952     }
1953  }
1954
1955 Here's how to use C<m//gc> with C<\G>:
1956
1957     $_ = "ppooqppqq";
1958     while ($i++ < 2) {
1959         print "1: '";
1960         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1961         print "2: '";
1962         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1963         print "3: '";
1964         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1965     }
1966     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1967
1968 The last example should print:
1969
1970     1: 'oo', pos=4
1971     2: 'q', pos=5
1972     3: 'pp', pos=7
1973     1: '', pos=7
1974     2: 'q', pos=8
1975     3: '', pos=8
1976     Final: 'q', pos=8
1977
1978 Notice that the final match matched C<q> instead of C<p>, which a match
1979 without the C<\G> anchor would have done.  Also note that the final match
1980 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
1981 final match did indeed match C<p>, it's a good bet that you're running a
1982 very old (pre-5.6.0) version of Perl.
1983
1984 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1985 combine several regexps like this to process a string part-by-part,
1986 doing different actions depending on which regexp matched.  Each
1987 regexp tries to match where the previous one leaves off.
1988
1989  $_ = <<'EOL';
1990     $url = URI::URL->new( "http://example.com/" );
1991     die if $url eq "xXx";
1992  EOL
1993
1994  LOOP: {
1995      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1996      print(" lowercase"),    redo LOOP
1997                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
1998      print(" UPPERCASE"),    redo LOOP
1999                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2000      print(" Capitalized"),  redo LOOP
2001                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2002      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2003      print(" alphanumeric"), redo LOOP
2004                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2005      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2006      print ". That's all!\n";
2007  }
2008
2009 Here is the output (split into several lines):
2010
2011  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2012  line-noise lowercase line-noise lowercase line-noise lowercase
2013  lowercase line-noise lowercase lowercase line-noise lowercase
2014  lowercase line-noise MiXeD line-noise. That's all!
2015
2016 =item C<m?I<PATTERN>?msixpodualngc>
2017 X<?> X<operator, match-once>
2018
2019 =item C<?I<PATTERN>?msixpodualngc>
2020
2021 This is just like the C<m/I<PATTERN>/> search, except that it matches
2022 only once between calls to the C<reset()> operator.  This is a useful
2023 optimization when you want to see only the first occurrence of
2024 something in each file of a set of files, for instance.  Only C<m??>
2025 patterns local to the current package are reset.
2026
2027     while (<>) {
2028         if (m?^$?) {
2029                             # blank line between header and body
2030         }
2031     } continue {
2032         reset if eof;       # clear m?? status for next file
2033     }
2034
2035 Another example switched the first "latin1" encoding it finds
2036 to "utf8" in a pod file:
2037
2038     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2039
2040 The match-once behavior is controlled by the match delimiter being
2041 C<?>; with any other delimiter this is the normal C<m//> operator.
2042
2043 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2044 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2045 syntax error.  If you encounter this construct in older code, you can just add
2046 C<m>.
2047
2048 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2049 X<substitute> X<substitution> X<replace> X<regexp, replace>
2050 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2051
2052 Searches a string for a pattern, and if found, replaces that pattern
2053 with the replacement text and returns the number of substitutions
2054 made.  Otherwise it returns false (specifically, the empty string).
2055
2056 If the C</r> (non-destructive) option is used then it runs the
2057 substitution on a copy of the string and instead of returning the
2058 number of substitutions, it returns the copy whether or not a
2059 substitution occurred.  The original string is never changed when
2060 C</r> is used.  The copy will always be a plain string, even if the
2061 input is an object or a tied variable.
2062
2063 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2064 variable is searched and modified.  Unless the C</r> option is used,
2065 the string specified must be a scalar variable, an array element, a
2066 hash element, or an assignment to one of those; that is, some sort of
2067 scalar lvalue.
2068
2069 If the delimiter chosen is a single quote, no interpolation is
2070 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2071 I<PATTERN> contains a C<$> that looks like a variable rather than an
2072 end-of-string test, the variable will be interpolated into the pattern
2073 at run-time.  If you want the pattern compiled only once the first time
2074 the variable is interpolated, use the C</o> option.  If the pattern
2075 evaluates to the empty string, the last successfully executed regular
2076 expression is used instead.  See L<perlre> for further explanation on these.
2077
2078 Options are as with C<m//> with the addition of the following replacement
2079 specific options:
2080
2081     e   Evaluate the right side as an expression.
2082     ee  Evaluate the right side as a string then eval the
2083         result.
2084     r   Return substitution and leave the original string
2085         untouched.
2086
2087 Any non-whitespace delimiter may replace the slashes.  Add space after
2088 the C<s> when using a character allowed in identifiers.  If single quotes
2089 are used, no interpretation is done on the replacement string (the C</e>
2090 modifier overrides this, however).  Note that Perl treats backticks
2091 as normal delimiters; the replacement text is not evaluated as a command.
2092 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2093 its own pair of quotes, which may or may not be bracketing quotes, for example,
2094 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2095 replacement portion to be treated as a full-fledged Perl expression
2096 and evaluated right then and there.  It is, however, syntax checked at
2097 compile-time.  A second C<e> modifier will cause the replacement portion
2098 to be C<eval>ed before being run as a Perl expression.
2099
2100 Examples:
2101
2102     s/\bgreen\b/mauve/g;              # don't change wintergreen
2103
2104     $path =~ s|/usr/bin|/usr/local/bin|;
2105
2106     s/Login: $foo/Login: $bar/; # run-time pattern
2107
2108     ($foo = $bar) =~ s/this/that/;      # copy first, then
2109                                         # change
2110     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2111                                         # copy, then change
2112     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2113     $foo = $bar =~ s/this/that/r
2114                 =~ s/that/the other/r;  # Chained substitutes
2115                                         # using /r
2116     @foo = map { s/this/that/r } @bar   # /r is very useful in
2117                                         # maps
2118
2119     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2120
2121     $_ = 'abc123xyz';
2122     s/\d+/$&*2/e;               # yields 'abc246xyz'
2123     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2124     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2125
2126     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2127     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2128     s/^=(\w+)/pod($1)/ge;       # use function call
2129
2130     $_ = 'abc123xyz';
2131     $x = s/abc/def/r;           # $x is 'def123xyz' and
2132                                 # $_ remains 'abc123xyz'.
2133
2134     # expand variables in $_, but dynamics only, using
2135     # symbolic dereferencing
2136     s/\$(\w+)/${$1}/g;
2137
2138     # Add one to the value of any numbers in the string
2139     s/(\d+)/1 + $1/eg;
2140
2141     # Titlecase words in the last 30 characters only
2142     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2143
2144     # This will expand any embedded scalar variable
2145     # (including lexicals) in $_ : First $1 is interpolated
2146     # to the variable name, and then evaluated
2147     s/(\$\w+)/$1/eeg;
2148
2149     # Delete (most) C comments.
2150     $program =~ s {
2151         /\*     # Match the opening delimiter.
2152         .*?     # Match a minimal number of characters.
2153         \*/     # Match the closing delimiter.
2154     } []gsx;
2155
2156     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2157                                 # expensively
2158
2159     for ($variable) {           # trim whitespace in $variable,
2160                                 # cheap
2161         s/^\s+//;
2162         s/\s+$//;
2163     }
2164
2165     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2166
2167 Note the use of C<$> instead of C<\> in the last example.  Unlike
2168 B<sed>, we use the \<I<digit>> form only in the left hand side.
2169 Anywhere else it's $<I<digit>>.
2170
2171 Occasionally, you can't use just a C</g> to get all the changes
2172 to occur that you might want.  Here are two common cases:
2173
2174     # put commas in the right places in an integer
2175     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2176
2177     # expand tabs to 8-column spacing
2178     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2179
2180 =back
2181
2182 =head2 Quote-Like Operators
2183 X<operator, quote-like>
2184
2185 =over 4
2186
2187 =item C<q/I<STRING>/>
2188 X<q> X<quote, single> X<'> X<''>
2189
2190 =item C<'I<STRING>'>
2191
2192 A single-quoted, literal string.  A backslash represents a backslash
2193 unless followed by the delimiter or another backslash, in which case
2194 the delimiter or backslash is interpolated.
2195
2196     $foo = q!I said, "You said, 'She said it.'"!;
2197     $bar = q('This is it.');
2198     $baz = '\n';                # a two-character string
2199
2200 =item C<qq/I<STRING>/>
2201 X<qq> X<quote, double> X<"> X<"">
2202
2203 =item "I<STRING>"
2204
2205 A double-quoted, interpolated string.
2206
2207     $_ .= qq
2208      (*** The previous line contains the naughty word "$1".\n)
2209                 if /\b(tcl|java|python)\b/i;      # :-)
2210     $baz = "\n";                # a one-character string
2211
2212 =item C<qx/I<STRING>/>
2213 X<qx> X<`> X<``> X<backtick>
2214
2215 =item C<`I<STRING>`>
2216
2217 A string which is (possibly) interpolated and then executed as a
2218 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2219 pipes, and redirections will be honored.  The collected standard
2220 output of the command is returned; standard error is unaffected.  In
2221 scalar context, it comes back as a single (potentially multi-line)
2222 string, or C<undef> if the command failed.  In list context, returns a
2223 list of lines (however you've defined lines with C<$/> or
2224 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2225
2226 Because backticks do not affect standard error, use shell file descriptor
2227 syntax (assuming the shell supports this) if you care to address this.
2228 To capture a command's STDERR and STDOUT together:
2229
2230     $output = `cmd 2>&1`;
2231
2232 To capture a command's STDOUT but discard its STDERR:
2233
2234     $output = `cmd 2>/dev/null`;
2235
2236 To capture a command's STDERR but discard its STDOUT (ordering is
2237 important here):
2238
2239     $output = `cmd 2>&1 1>/dev/null`;
2240
2241 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2242 but leave its STDOUT to come out the old STDERR:
2243
2244     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2245
2246 To read both a command's STDOUT and its STDERR separately, it's easiest
2247 to redirect them separately to files, and then read from those files
2248 when the program is done:
2249
2250     system("program args 1>program.stdout 2>program.stderr");
2251
2252 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2253 For example:
2254
2255     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2256     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2257     print STDOUT `sort`;
2258
2259 will print the sorted contents of the file named F<"stuff">.
2260
2261 Using single-quote as a delimiter protects the command from Perl's
2262 double-quote interpolation, passing it on to the shell instead:
2263
2264     $perl_info  = qx(ps $$);            # that's Perl's $$
2265     $shell_info = qx'ps $$';            # that's the new shell's $$
2266
2267 How that string gets evaluated is entirely subject to the command
2268 interpreter on your system.  On most platforms, you will have to protect
2269 shell metacharacters if you want them treated literally.  This is in
2270 practice difficult to do, as it's unclear how to escape which characters.
2271 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2272 to emulate backticks safely.
2273
2274 On some platforms (notably DOS-like ones), the shell may not be
2275 capable of dealing with multiline commands, so putting newlines in
2276 the string may not get you what you want.  You may be able to evaluate
2277 multiple commands in a single line by separating them with the command
2278 separator character, if your shell supports that (for example, C<;> on 
2279 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2280
2281 Perl will attempt to flush all files opened for
2282 output before starting the child process, but this may not be supported
2283 on some platforms (see L<perlport>).  To be safe, you may need to set
2284 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2285 C<L<IO::Handle>> on any open handles.
2286
2287 Beware that some command shells may place restrictions on the length
2288 of the command line.  You must ensure your strings don't exceed this
2289 limit after any necessary interpolations.  See the platform-specific
2290 release notes for more details about your particular environment.
2291
2292 Using this operator can lead to programs that are difficult to port,
2293 because the shell commands called vary between systems, and may in
2294 fact not be present at all.  As one example, the C<type> command under
2295 the POSIX shell is very different from the C<type> command under DOS.
2296 That doesn't mean you should go out of your way to avoid backticks
2297 when they're the right way to get something done.  Perl was made to be
2298 a glue language, and one of the things it glues together is commands.
2299 Just understand what you're getting yourself into.
2300
2301 See L</"I/O Operators"> for more discussion.
2302
2303 =item C<qw/I<STRING>/>
2304 X<qw> X<quote, list> X<quote, words>
2305
2306 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2307 whitespace as the word delimiters.  It can be understood as being roughly
2308 equivalent to:
2309
2310     split(" ", q/STRING/);
2311
2312 the differences being that it generates a real list at compile time, and
2313 in scalar context it returns the last element in the list.  So
2314 this expression:
2315
2316     qw(foo bar baz)
2317
2318 is semantically equivalent to the list:
2319
2320     "foo", "bar", "baz"
2321
2322 Some frequently seen examples:
2323
2324     use POSIX qw( setlocale localeconv )
2325     @EXPORT = qw( foo bar baz );
2326
2327 A common mistake is to try to separate the words with commas or to
2328 put comments into a multi-line C<qw>-string.  For this reason, the
2329 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2330 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2331
2332 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2333 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2334
2335 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2336
2337 Transliterates all occurrences of the characters found in the search list
2338 with the corresponding character in the replacement list.  It returns
2339 the number of characters replaced or deleted.  If no string is
2340 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2341
2342 If the C</r> (non-destructive) option is present, a new copy of the string
2343 is made and its characters transliterated, and this copy is returned no
2344 matter whether it was modified or not: the original string is always
2345 left unchanged.  The new copy is always a plain string, even if the input
2346 string is an object or a tied variable.
2347
2348 Unless the C</r> option is used, the string specified with C<=~> must be a
2349 scalar variable, an array element, a hash element, or an assignment to one
2350 of those; in other words, an lvalue.
2351
2352 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
2353 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
2354 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
2355 I<SEARCHLIST> is delimited by bracketing quotes, the I<REPLACEMENTLIST> has
2356 its own pair of quotes, which may or may not be bracketing quotes;
2357 for example, C<tr[aeiouy][yuoiea]> or C<tr(+\-*/)/ABCD/>.
2358
2359 Characters may be literals or any of the escape sequences accepted in
2360 double-quoted strings.  But there is no interpolation, so C<"$"> and
2361 C<"@"> are treated as literals.  A hyphen at the beginning or end, or
2362 preceded by a backslash is considered a literal.  Escape sequence
2363 details are in L<the table near the beginning of this section|/Quote and
2364 Quote-like Operators>.  It is a bug in Perl v5.22 that something like
2365
2366  tr/\N{U+20}-\N{U+7E}foobar//
2367
2368 does not treat that range as fully Unicode.
2369
2370 Note that C<tr> does B<not> do regular expression character classes such as
2371 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2372 utility.  If you want to map strings between lower/upper cases, see
2373 L<perlfunc/lc> and L<perlfunc/uc>, and in general consider using the C<s>
2374 operator if you need regular expressions.  The C<\U>, C<\u>, C<\L>, and
2375 C<\l> string-interpolation escapes on the right side of a substitution
2376 operator will perform correct case-mappings, but C<tr[a-z][A-Z]> will not
2377 (except sometimes on legacy 7-bit data).
2378
2379 Note also that the whole range idea is rather unportable between
2380 character sets--and even within character sets they may cause results
2381 you probably didn't expect.  A sound principle is to use only ranges
2382 that begin from and end at either alphabets of equal case (a-e, A-E),
2383 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
2384 character sets in full.
2385
2386 Options:
2387
2388     c   Complement the SEARCHLIST.
2389     d   Delete found but unreplaced characters.
2390     s   Squash duplicate replaced characters.
2391     r   Return the modified string and leave the original string
2392         untouched.
2393
2394 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2395 is complemented.  If the C</d> modifier is specified, any characters
2396 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2397 (Note that this is slightly more flexible than the behavior of some
2398 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2399 period.)  If the C</s> modifier is specified, sequences of characters
2400 that were transliterated to the same character are squashed down
2401 to a single instance of the character.
2402
2403 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2404 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2405 than the I<SEARCHLIST>, the final character is replicated till it is long
2406 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2407 This latter is useful for counting characters in a class or for
2408 squashing character sequences in a class.
2409
2410 Examples:
2411
2412     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2413
2414     $cnt = tr/*/*/;             # count the stars in $_
2415
2416     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2417
2418     $cnt = tr/0-9//;            # count the digits in $_
2419
2420     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2421
2422     ($HOST = $host) =~ tr/a-z/A-Z/;
2423      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2424
2425     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2426                   =~ s/:/ -p/r;
2427
2428     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2429
2430     @stripped = map tr/a-zA-Z/ /csr, @original;
2431                                 # /r with map
2432
2433     tr [\200-\377]
2434        [\000-\177];             # wickedly delete 8th bit
2435
2436 If multiple transliterations are given for a character, only the
2437 first one is used:
2438
2439     tr/AAA/XYZ/
2440
2441 will transliterate any A to X.
2442
2443 Because the transliteration table is built at compile time, neither
2444 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2445 interpolation.  That means that if you want to use variables, you
2446 must use an C<eval()>:
2447
2448     eval "tr/$oldlist/$newlist/";
2449     die $@ if $@;
2450
2451     eval "tr/$oldlist/$newlist/, 1" or die $@;
2452
2453 =item C<< <<I<EOF> >>
2454 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2455
2456 A line-oriented form of quoting is based on the shell "here-document"
2457 syntax.  Following a C<< << >> you specify a string to terminate
2458 the quoted material, and all lines following the current line down to
2459 the terminating string are the value of the item.
2460
2461 The terminating string may be either an identifier (a word), or some
2462 quoted text.  An unquoted identifier works like double quotes.
2463 There may not be a space between the C<< << >> and the identifier,
2464 unless the identifier is explicitly quoted.  (If you put a space it
2465 will be treated as a null identifier, which is valid, and matches the
2466 first empty line.)  The terminating string must appear by itself
2467 (unquoted and with no surrounding whitespace) on the terminating line.
2468
2469 If the terminating string is quoted, the type of quotes used determine
2470 the treatment of the text.
2471
2472 =over 4
2473
2474 =item Double Quotes
2475
2476 Double quotes indicate that the text will be interpolated using exactly
2477 the same rules as normal double quoted strings.
2478
2479        print <<EOF;
2480     The price is $Price.
2481     EOF
2482
2483        print << "EOF"; # same as above
2484     The price is $Price.
2485     EOF
2486
2487
2488 =item Single Quotes
2489
2490 Single quotes indicate the text is to be treated literally with no
2491 interpolation of its content.  This is similar to single quoted
2492 strings except that backslashes have no special meaning, with C<\\>
2493 being treated as two backslashes and not one as they would in every
2494 other quoting construct.
2495
2496 Just as in the shell, a backslashed bareword following the C<<< << >>>
2497 means the same thing as a single-quoted string does:
2498
2499         $cost = <<'VISTA';  # hasta la ...
2500     That'll be $10 please, ma'am.
2501     VISTA
2502
2503         $cost = <<\VISTA;   # Same thing!
2504     That'll be $10 please, ma'am.
2505     VISTA
2506
2507 This is the only form of quoting in perl where there is no need
2508 to worry about escaping content, something that code generators
2509 can and do make good use of.
2510
2511 =item Backticks
2512
2513 The content of the here doc is treated just as it would be if the
2514 string were embedded in backticks.  Thus the content is interpolated
2515 as though it were double quoted and then executed via the shell, with
2516 the results of the execution returned.
2517
2518        print << `EOC`; # execute command and get results
2519     echo hi there
2520     EOC
2521
2522 =back
2523
2524 It is possible to stack multiple here-docs in a row:
2525
2526        print <<"foo", <<"bar"; # you can stack them
2527     I said foo.
2528     foo
2529     I said bar.
2530     bar
2531
2532        myfunc(<< "THIS", 23, <<'THAT');
2533     Here's a line
2534     or two.
2535     THIS
2536     and here's another.
2537     THAT
2538
2539 Just don't forget that you have to put a semicolon on the end
2540 to finish the statement, as Perl doesn't know you're not going to
2541 try to do this:
2542
2543        print <<ABC
2544     179231
2545     ABC
2546        + 20;
2547
2548 If you want to remove the line terminator from your here-docs,
2549 use C<chomp()>.
2550
2551     chomp($string = <<'END');
2552     This is a string.
2553     END
2554
2555 If you want your here-docs to be indented with the rest of the code,
2556 you'll need to remove leading whitespace from each line manually:
2557
2558     ($quote = <<'FINIS') =~ s/^\s+//gm;
2559        The Road goes ever on and on,
2560        down from the door where it began.
2561     FINIS
2562
2563 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2564 the quoted material must still come on the line following the
2565 C<<< <<FOO >>> marker, which means it may be inside the delimited
2566 construct:
2567
2568     s/this/<<E . 'that'
2569     the other
2570     E
2571      . 'more '/eg;
2572
2573 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2574 you would have to write
2575
2576     s/this/<<E . 'that'
2577      . 'more '/eg;
2578     the other
2579     E
2580
2581 outside of string evals.
2582
2583 Additionally, quoting rules for the end-of-string identifier are
2584 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2585 supported in place of C<''> and C<"">, and the only interpolation is for
2586 backslashing the quoting character:
2587
2588     print << "abc\"def";
2589     testing...
2590     abc"def
2591
2592 Finally, quoted strings cannot span multiple lines.  The general rule is
2593 that the identifier must be a string literal.  Stick with that, and you
2594 should be safe.
2595
2596 =back
2597
2598 =head2 Gory details of parsing quoted constructs
2599 X<quote, gory details>
2600
2601 When presented with something that might have several different
2602 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2603 principle to pick the most probable interpretation.  This strategy
2604 is so successful that Perl programmers often do not suspect the
2605 ambivalence of what they write.  But from time to time, Perl's
2606 notions differ substantially from what the author honestly meant.
2607
2608 This section hopes to clarify how Perl handles quoted constructs.
2609 Although the most common reason to learn this is to unravel labyrinthine
2610 regular expressions, because the initial steps of parsing are the
2611 same for all quoting operators, they are all discussed together.
2612
2613 The most important Perl parsing rule is the first one discussed
2614 below: when processing a quoted construct, Perl first finds the end
2615 of that construct, then interprets its contents.  If you understand
2616 this rule, you may skip the rest of this section on the first
2617 reading.  The other rules are likely to contradict the user's
2618 expectations much less frequently than this first one.
2619
2620 Some passes discussed below are performed concurrently, but because
2621 their results are the same, we consider them individually.  For different
2622 quoting constructs, Perl performs different numbers of passes, from
2623 one to four, but these passes are always performed in the same order.
2624
2625 =over 4
2626
2627 =item Finding the end
2628
2629 The first pass is finding the end of the quoted construct.  This results
2630 in saving to a safe location a copy of the text (between the starting
2631 and ending delimiters), normalized as necessary to avoid needing to know
2632 what the original delimiters were.
2633
2634 If the construct is a here-doc, the ending delimiter is a line
2635 that has a terminating string as the content.  Therefore C<<<EOF> is
2636 terminated by C<EOF> immediately followed by C<"\n"> and starting
2637 from the first column of the terminating line.
2638 When searching for the terminating line of a here-doc, nothing
2639 is skipped.  In other words, lines after the here-doc syntax
2640 are compared with the terminating string line by line.
2641
2642 For the constructs except here-docs, single characters are used as starting
2643 and ending delimiters.  If the starting delimiter is an opening punctuation
2644 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2645 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2646 If the starting delimiter is an unpaired character like C</> or a closing
2647 punctuation, the ending delimiter is the same as the starting delimiter.
2648 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2649 both C<qq[]> and C<qq]]> constructs.
2650
2651 When searching for single-character delimiters, escaped delimiters
2652 and C<\\> are skipped.  For example, while searching for terminating C</>,
2653 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2654 bracketing, nested pairs are also skipped.  For example, while searching
2655 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2656 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2657 However, when backslashes are used as the delimiters (like C<qq\\> and
2658 C<tr\\\>), nothing is skipped.
2659 During the search for the end, backslashes that escape delimiters or
2660 other backslashes are removed (exactly speaking, they are not copied to the
2661 safe location).
2662
2663 For constructs with three-part delimiters (C<s///>, C<y///>, and
2664 C<tr///>), the search is repeated once more.
2665 If the first delimiter is not an opening punctuation, the three delimiters must
2666 be the same, such as C<s!!!> and C<tr)))>,
2667 in which case the second delimiter
2668 terminates the left part and starts the right part at once.
2669 If the left part is delimited by bracketing punctuation (that is C<()>,
2670 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2671 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2672 and comments are allowed between the two parts, although the comment must follow
2673 at least one whitespace character; otherwise a character expected as the 
2674 start of the comment may be regarded as the starting delimiter of the right part.
2675
2676 During this search no attention is paid to the semantics of the construct.
2677 Thus:
2678
2679     "$hash{"$foo/$bar"}"
2680
2681 or:
2682
2683     m/
2684       bar       # NOT a comment, this slash / terminated m//!
2685      /x
2686
2687 do not form legal quoted expressions.   The quoted part ends on the
2688 first C<"> and C</>, and the rest happens to be a syntax error.
2689 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2690 the example above is not C<m//x>, but rather C<m//> with no C</x>
2691 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2692
2693 Also no attention is paid to C<\c\> (multichar control char syntax) during
2694 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2695 of C<\/>, and the following C</> is not recognized as a delimiter.
2696 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2697
2698 =item Interpolation
2699 X<interpolation>
2700
2701 The next step is interpolation in the text obtained, which is now
2702 delimiter-independent.  There are multiple cases.
2703
2704 =over 4
2705
2706 =item C<<<'EOF'>
2707
2708 No interpolation is performed.
2709 Note that the combination C<\\> is left intact, since escaped delimiters
2710 are not available for here-docs.
2711
2712 =item  C<m''>, the pattern of C<s'''>
2713
2714 No interpolation is performed at this stage.
2715 Any backslashed sequences including C<\\> are treated at the stage
2716 to L</"parsing regular expressions">.
2717
2718 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2719
2720 The only interpolation is removal of C<\> from pairs of C<\\>.
2721 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2722 as a hyphen and no character range is available.
2723 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2724
2725 =item C<tr///>, C<y///>
2726
2727 No variable interpolation occurs.  String modifying combinations for
2728 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2729 The other escape sequences such as C<\200> and C<\t> and backslashed
2730 characters such as C<\\> and C<\-> are converted to appropriate literals.
2731 The character C<"-"> is treated specially and therefore C<\-> is treated
2732 as a literal C<"-">.
2733
2734 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2735
2736 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2737 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2738 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2739 The other escape sequences such as C<\200> and C<\t> and backslashed
2740 characters such as C<\\> and C<\-> are replaced with appropriate
2741 expansions.
2742
2743 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2744 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2745 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2746 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2747 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2748 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2749 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2750
2751   $str = '\t';
2752   return "\Q$str";
2753
2754 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2755
2756 Interpolated scalars and arrays are converted internally to the C<join> and
2757 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2758
2759   $foo . " XXX '" . (join $", @arr) . "'";
2760
2761 All operations above are performed simultaneously, left to right.
2762
2763 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2764 quoted, there is no way to insert a literal C<$> or C<@> inside a
2765 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2766 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2767 scalar.
2768
2769 Note also that the interpolation code needs to make a decision on
2770 where the interpolated scalar ends.  For instance, whether
2771 S<C<< "a $x -> {c}" >>> really means:
2772
2773   "a " . $x . " -> {c}";
2774
2775 or:
2776
2777   "a " . $x -> {c};
2778
2779 Most of the time, the longest possible text that does not include
2780 spaces between components and which contains matching braces or
2781 brackets.  because the outcome may be determined by voting based
2782 on heuristic estimators, the result is not strictly predictable.
2783 Fortunately, it's usually correct for ambiguous cases.
2784
2785 =item the replacement of C<s///>
2786
2787 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2788 happens as with C<qq//> constructs.
2789
2790 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2791 the replacement text of C<s///>, in order to correct the incorrigible
2792 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2793 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2794 (that is, the C<$^W> variable) was set.
2795
2796 =item C<RE> in C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2797
2798 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2799 and interpolation happens (almost) as with C<qq//> constructs.
2800
2801 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2802 form for the regex compiler.  (This is because, as mentioned below, the regex
2803 compilation may be done at execution time, and C<\N{...}> is a compile-time
2804 construct.)
2805
2806 However any other combinations of C<\> followed by a character
2807 are not substituted but only skipped, in order to parse them
2808 as regular expressions at the following step.
2809 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2810 treated as an array symbol (for example C<@foo>),
2811 even though the same text in C<qq//> gives interpolation of C<\c@>.
2812
2813 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2814 back to the perl parser, in a similar way that an interpolated array
2815 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2816
2817 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2818 a C<#>-comment in a C</x>-regular expression, no processing is
2819 performed whatsoever.  This is the first step at which the presence
2820 of the C</x> modifier is relevant.
2821
2822 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2823 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2824 voted (by several different estimators) to be either an array element
2825 or C<$var> followed by an RE alternative.  This is where the notation
2826 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
2827 array element C<-9>, not as a regular expression from the variable
2828 C<$arr> followed by a digit, which would be the interpretation of
2829 C</$arr[0-9]/>.  Since voting among different estimators may occur,
2830 the result is not predictable.
2831
2832 The lack of processing of C<\\> creates specific restrictions on
2833 the post-processed text.  If the delimiter is C</>, one cannot get
2834 the combination C<\/> into the result of this step.  C</> will
2835 finish the regular expression, C<\/> will be stripped to C</> on
2836 the previous step, and C<\\/> will be left as is.  Because C</> is
2837 equivalent to C<\/> inside a regular expression, this does not
2838 matter unless the delimiter happens to be character special to the
2839 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
2840 alphanumeric char, as in:
2841
2842   m m ^ a \s* b mmx;
2843
2844 In the RE above, which is intentionally obfuscated for illustration, the
2845 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
2846 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
2847 reason you're encouraged to restrict your delimiters to non-alphanumeric,
2848 non-whitespace choices.
2849
2850 =back
2851
2852 This step is the last one for all constructs except regular expressions,
2853 which are processed further.
2854
2855 =item parsing regular expressions
2856 X<regexp, parse>
2857
2858 Previous steps were performed during the compilation of Perl code,
2859 but this one happens at run time, although it may be optimized to
2860 be calculated at compile time if appropriate.  After preprocessing
2861 described above, and possibly after evaluation if concatenation,
2862 joining, casing translation, or metaquoting are involved, the
2863 resulting I<string> is passed to the RE engine for compilation.
2864
2865 Whatever happens in the RE engine might be better discussed in L<perlre>,
2866 but for the sake of continuity, we shall do so here.
2867
2868 This is another step where the presence of the C</x> modifier is
2869 relevant.  The RE engine scans the string from left to right and
2870 converts it into a finite automaton.
2871
2872 Backslashed characters are either replaced with corresponding
2873 literal strings (as with C<\{>), or else they generate special nodes
2874 in the finite automaton (as with C<\b>).  Characters special to the
2875 RE engine (such as C<|>) generate corresponding nodes or groups of
2876 nodes.  C<(?#...)> comments are ignored.  All the rest is either
2877 converted to literal strings to match, or else is ignored (as is
2878 whitespace and C<#>-style comments if C</x> is present).
2879
2880 Parsing of the bracketed character class construct, C<[...]>, is
2881 rather different than the rule used for the rest of the pattern.
2882 The terminator of this construct is found using the same rules as
2883 for finding the terminator of a C<{}>-delimited construct, the only
2884 exception being that C<]> immediately following C<[> is treated as
2885 though preceded by a backslash.
2886
2887 The terminator of runtime C<(?{...})> is found by temporarily switching
2888 control to the perl parser, which should stop at the point where the
2889 logically balancing terminating C<}> is found.
2890
2891 It is possible to inspect both the string given to RE engine and the
2892 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
2893 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
2894 switch documented in L<perlrun/"Command Switches">.
2895
2896 =item Optimization of regular expressions
2897 X<regexp, optimization>
2898
2899 This step is listed for completeness only.  Since it does not change
2900 semantics, details of this step are not documented and are subject
2901 to change without notice.  This step is performed over the finite
2902 automaton that was generated during the previous pass.
2903
2904 It is at this stage that C<split()> silently optimizes C</^/> to
2905 mean C</^/m>.
2906
2907 =back
2908
2909 =head2 I/O Operators
2910 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
2911 X<< <> >> X<< <<>> >> X<@ARGV>
2912
2913 There are several I/O operators you should know about.
2914
2915 A string enclosed by backticks (grave accents) first undergoes
2916 double-quote interpolation.  It is then interpreted as an external
2917 command, and the output of that command is the value of the
2918 backtick string, like in a shell.  In scalar context, a single string
2919 consisting of all output is returned.  In list context, a list of
2920 values is returned, one per line of output.  (You can set C<$/> to use
2921 a different line terminator.)  The command is executed each time the
2922 pseudo-literal is evaluated.  The status value of the command is
2923 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
2924 Unlike in B<csh>, no translation is done on the return data--newlines
2925 remain newlines.  Unlike in any of the shells, single quotes do not
2926 hide variable names in the command from interpretation.  To pass a
2927 literal dollar-sign through to the shell you need to hide it with a
2928 backslash.  The generalized form of backticks is C<qx//>.  (Because
2929 backticks always undergo shell expansion as well, see L<perlsec> for
2930 security concerns.)
2931 X<qx> X<`> X<``> X<backtick> X<glob>
2932
2933 In scalar context, evaluating a filehandle in angle brackets yields
2934 the next line from that file (the newline, if any, included), or
2935 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2936 (sometimes known as file-slurp mode) and the file is empty, it
2937 returns C<''> the first time, followed by C<undef> subsequently.
2938
2939 Ordinarily you must assign the returned value to a variable, but
2940 there is one situation where an automatic assignment happens.  If
2941 and only if the input symbol is the only thing inside the conditional
2942 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2943 the value is automatically assigned to the global variable C<$_>,
2944 destroying whatever was there previously.  (This may seem like an
2945 odd thing to you, but you'll use the construct in almost every Perl
2946 script you write.)  The C<$_> variable is not implicitly localized.
2947 You'll have to put a S<C<local $_;>> before the loop if you want that
2948 to happen.
2949
2950 The following lines are equivalent:
2951
2952     while (defined($_ = <STDIN>)) { print; }
2953     while ($_ = <STDIN>) { print; }
2954     while (<STDIN>) { print; }
2955     for (;<STDIN>;) { print; }
2956     print while defined($_ = <STDIN>);
2957     print while ($_ = <STDIN>);
2958     print while <STDIN>;
2959
2960 This also behaves similarly, but assigns to a lexical variable 
2961 instead of to C<$_>:
2962
2963     while (my $line = <STDIN>) { print $line }
2964
2965 In these loop constructs, the assigned value (whether assignment
2966 is automatic or explicit) is then tested to see whether it is
2967 defined.  The defined test avoids problems where the line has a string
2968 value that would be treated as false by Perl; for example a "" or
2969 a C<"0"> with no trailing newline.  If you really mean for such values
2970 to terminate the loop, they should be tested for explicitly:
2971
2972     while (($_ = <STDIN>) ne '0') { ... }
2973     while (<STDIN>) { last unless $_; ... }
2974
2975 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
2976 explicit C<defined> test or comparison elicits a warning if the
2977 S<C<use warnings>> pragma or the B<-w>
2978 command-line switch (the C<$^W> variable) is in effect.
2979
2980 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2981 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2982 in packages, where they would be interpreted as local identifiers
2983 rather than global.)  Additional filehandles may be created with
2984 the C<open()> function, amongst others.  See L<perlopentut> and
2985 L<perlfunc/open> for details on this.
2986 X<stdin> X<stdout> X<sterr>
2987
2988 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
2989 a list, a list comprising all input lines is returned, one line per
2990 list element.  It's easy to grow to a rather large data space this
2991 way, so use with care.
2992
2993 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
2994 See L<perlfunc/readline>.
2995
2996 The null filehandle C<< <> >> is special: it can be used to emulate the
2997 behavior of B<sed> and B<awk>, and any other Unix filter program
2998 that takes a list of filenames, doing the same to each line
2999 of input from all of them.  Input from C<< <> >> comes either from
3000 standard input, or from each file listed on the command line.  Here's
3001 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3002 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3003 gives you standard input.  The C<@ARGV> array is then processed as a list
3004 of filenames.  The loop
3005
3006     while (<>) {
3007         ...                     # code for each line
3008     }
3009
3010 is equivalent to the following Perl-like pseudo code:
3011
3012     unshift(@ARGV, '-') unless @ARGV;
3013     while ($ARGV = shift) {
3014         open(ARGV, $ARGV);
3015         while (<ARGV>) {
3016             ...         # code for each line
3017         }
3018     }
3019
3020 except that it isn't so cumbersome to say, and will actually work.
3021 It really does shift the C<@ARGV> array and put the current filename
3022 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3023 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3024 is magical.  (The pseudo code above doesn't work because it treats
3025 C<< <ARGV> >> as non-magical.)
3026
3027 Since the null filehandle uses the two argument form of L<perlfunc/open>
3028 it interprets special characters, so if you have a script like this:
3029
3030     while (<>) {
3031         print;
3032     }
3033
3034 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3035 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3036 If you want all items in C<@ARGV> to be interpreted as file names, you
3037 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3038
3039     while (<<>>) {
3040         print;
3041     }
3042
3043 Using double angle brackets inside of a while causes the open to use the
3044 three argument form (with the second argument being C<< < >>), so all
3045 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3046 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3047 empty, it will still read from the standard input.)
3048
3049 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3050 containing the list of filenames you really want.  Line numbers (C<$.>)
3051 continue as though the input were one big happy file.  See the example
3052 in L<perlfunc/eof> for how to reset line numbers on each file.
3053
3054 If you want to set C<@ARGV> to your own list of files, go right ahead.
3055 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3056
3057     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3058
3059 You can even set them to pipe commands.  For example, this automatically
3060 filters compressed arguments through B<gzip>:
3061
3062     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3063
3064 If you want to pass switches into your script, you can use one of the
3065 C<Getopts> modules or put a loop on the front like this:
3066
3067     while ($_ = $ARGV[0], /^-/) {
3068         shift;
3069         last if /^--$/;
3070         if (/^-D(.*)/) { $debug = $1 }
3071         if (/^-v/)     { $verbose++  }
3072         # ...           # other switches
3073     }
3074
3075     while (<>) {
3076         # ...           # code for each line
3077     }
3078
3079 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3080 If you call it again after this, it will assume you are processing another
3081 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3082
3083 If what the angle brackets contain is a simple scalar variable (for example,
3084 C<$foo>), then that variable contains the name of the
3085 filehandle to input from, or its typeglob, or a reference to the
3086 same.  For example:
3087
3088     $fh = \*STDIN;
3089     $line = <$fh>;
3090
3091 If what's within the angle brackets is neither a filehandle nor a simple
3092 scalar variable containing a filehandle name, typeglob, or typeglob
3093 reference, it is interpreted as a filename pattern to be globbed, and
3094 either a list of filenames or the next filename in the list is returned,
3095 depending on context.  This distinction is determined on syntactic
3096 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3097 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3098 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3099 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3100 is treated as C<glob("$x ")>, not C<readline($x)>.
3101
3102 One level of double-quote interpretation is done first, but you can't
3103 say C<< <$foo> >> because that's an indirect filehandle as explained
3104 in the previous paragraph.  (In older versions of Perl, programmers
3105 would insert curly brackets to force interpretation as a filename glob:
3106 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3107 internal function directly as C<glob($foo)>, which is probably the right
3108 way to have done it in the first place.)  For example:
3109
3110     while (<*.c>) {
3111         chmod 0644, $_;
3112     }
3113
3114 is roughly equivalent to:
3115
3116     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3117     while (<FOO>) {
3118         chomp;
3119         chmod 0644, $_;
3120     }
3121
3122 except that the globbing is actually done internally using the standard
3123 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3124
3125     chmod 0644, <*.c>;
3126
3127 A (file)glob evaluates its (embedded) argument only when it is
3128 starting a new list.  All values must be read before it will start
3129 over.  In list context, this isn't important because you automatically
3130 get them all anyway.  However, in scalar context the operator returns
3131 the next value each time it's called, or C<undef> when the list has
3132 run out.  As with filehandle reads, an automatic C<defined> is
3133 generated when the glob occurs in the test part of a C<while>,
3134 because legal glob returns (for example,
3135 a file called F<0>) would otherwise
3136 terminate the loop.  Again, C<undef> is returned only once.  So if
3137 you're expecting a single value from a glob, it is much better to
3138 say
3139
3140     ($file) = <blurch*>;
3141
3142 than
3143
3144     $file = <blurch*>;
3145
3146 because the latter will alternate between returning a filename and
3147 returning false.
3148
3149 If you're trying to do variable interpolation, it's definitely better
3150 to use the C<glob()> function, because the older notation can cause people
3151 to become confused with the indirect filehandle notation.
3152
3153     @files = glob("$dir/*.[ch]");
3154     @files = glob($files[$i]);
3155
3156 =head2 Constant Folding
3157 X<constant folding> X<folding>
3158
3159 Like C, Perl does a certain amount of expression evaluation at
3160 compile time whenever it determines that all arguments to an
3161 operator are static and have no side effects.  In particular, string
3162 concatenation happens at compile time between literals that don't do
3163 variable substitution.  Backslash interpolation also happens at
3164 compile time.  You can say
3165
3166       'Now is the time for all'
3167     . "\n" 
3168     .  'good men to come to.'
3169
3170 and this all reduces to one string internally.  Likewise, if
3171 you say
3172
3173     foreach $file (@filenames) {
3174         if (-s $file > 5 + 100 * 2**16) {  }
3175     }
3176
3177 the compiler precomputes the number which that expression
3178 represents so that the interpreter won't have to.
3179
3180 =head2 No-ops
3181 X<no-op> X<nop>
3182
3183 Perl doesn't officially have a no-op operator, but the bare constants
3184 C<0> and C<1> are special-cased not to produce a warning in void
3185 context, so you can for example safely do
3186
3187     1 while foo();
3188
3189 =head2 Bitwise String Operators
3190 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3191
3192 Bitstrings of any size may be manipulated by the bitwise operators
3193 (C<~ | & ^>).
3194
3195 If the operands to a binary bitwise op are strings of different
3196 sizes, B<|> and B<^> ops act as though the shorter operand had
3197 additional zero bits on the right, while the B<&> op acts as though
3198 the longer operand were truncated to the length of the shorter.
3199 The granularity for such extension or truncation is one or more
3200 bytes.
3201
3202     # ASCII-based examples
3203     print "j p \n" ^ " a h";            # prints "JAPH\n"
3204     print "JA" | "  ph\n";              # prints "japh\n"
3205     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3206     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3207
3208 If you are intending to manipulate bitstrings, be certain that
3209 you're supplying bitstrings: If an operand is a number, that will imply
3210 a B<numeric> bitwise operation.  You may explicitly show which type of
3211 operation you intend by using C<""> or C<0+>, as in the examples below.
3212
3213     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3214     $foo = '150' |  105;        # yields 255
3215     $foo =  150  | '105';       # yields 255
3216     $foo = '150' | '105';       # yields string '155' (under ASCII)
3217
3218     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3219     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3220
3221 This somewhat unpredictable behavior can be avoided with the experimental
3222 "bitwise" feature, new in Perl 5.22.  You can enable it via S<C<use feature
3223 'bitwise'>>.  By default, it will warn unless the C<"experimental::bitwise">
3224 warnings category has been disabled.  (S<C<use experimental 'bitwise'>> will
3225 enable the feature and disable the warning.)  Under this feature, the four
3226 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3227 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3228 strings:
3229
3230     use experimental "bitwise";
3231     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3232     $foo = '150' |  105;        # yields 255
3233     $foo =  150  | '105';       # yields 255
3234     $foo = '150' | '105';       # yields 255
3235     $foo =  150  |. 105;        # yields string '155'
3236     $foo = '150' |. 105;        # yields string '155'
3237     $foo =  150  |.'105';       # yields string '155'
3238     $foo = '150' |.'105';       # yields string '155'
3239
3240     $baz = $foo &  $bar;        # both operands numeric
3241     $biz = $foo ^. $bar;        # both operands stringy
3242
3243 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3244 behave likewise under the feature.
3245
3246 The behavior of these operators is problematic (and subject to change)
3247 if either or both of the strings are encoded in UTF-8 (see
3248 L<perlunicode/Byte and Character Semantics>.
3249
3250 See L<perlfunc/vec> for information on how to manipulate individual bits
3251 in a bit vector.
3252
3253 =head2 Integer Arithmetic
3254 X<integer>
3255
3256 By default, Perl assumes that it must do most of its arithmetic in
3257 floating point.  But by saying
3258
3259     use integer;
3260
3261 you may tell the compiler to use integer operations
3262 (see L<integer> for a detailed explanation) from here to the end of
3263 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3264
3265     no integer;
3266
3267 which lasts until the end of that BLOCK.  Note that this doesn't
3268 mean everything is an integer, merely that Perl will use integer
3269 operations for arithmetic, comparison, and bitwise operators.  For
3270 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3271 still get C<1.4142135623731> or so.
3272
3273 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3274 C<< >> >>) always produce integral results.  (But see also
3275 L<Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3276 them.  By default, their results are interpreted as unsigned integers, but
3277 if S<C<use integer>> is in effect, their results are interpreted
3278 as signed integers.  For example, C<~0> usually evaluates to a large
3279 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3280 machines.
3281
3282 =head2 Floating-point Arithmetic
3283
3284 X<floating-point> X<floating point> X<float> X<real>
3285
3286 While S<C<use integer>> provides integer-only arithmetic, there is no
3287 analogous mechanism to provide automatic rounding or truncation to a
3288 certain number of decimal places.  For rounding to a certain number
3289 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3290 See L<perlfaq4>.
3291
3292 Floating-point numbers are only approximations to what a mathematician
3293 would call real numbers.  There are infinitely more reals than floats,
3294 so some corners must be cut.  For example:
3295
3296     printf "%.20g\n", 123456789123456789;
3297     #        produces 123456789123456784
3298
3299 Testing for exact floating-point equality or inequality is not a
3300 good idea.  Here's a (relatively expensive) work-around to compare
3301 whether two floating-point numbers are equal to a particular number of
3302 decimal places.  See Knuth, volume II, for a more robust treatment of
3303 this topic.
3304
3305     sub fp_equal {
3306         my ($X, $Y, $POINTS) = @_;
3307         my ($tX, $tY);
3308         $tX = sprintf("%.${POINTS}g", $X);
3309         $tY = sprintf("%.${POINTS}g", $Y);
3310         return $tX eq $tY;
3311     }
3312
3313 The POSIX module (part of the standard perl distribution) implements
3314 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3315 The C<L<Math::Complex>> module (part of the standard perl distribution)
3316 defines mathematical functions that work on both the reals and the
3317 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3318 POSIX can't work with complex numbers.
3319
3320 Rounding in financial applications can have serious implications, and
3321 the rounding method used should be specified precisely.  In these
3322 cases, it probably pays not to trust whichever system rounding is
3323 being used by Perl, but to instead implement the rounding function you
3324 need yourself.
3325
3326 =head2 Bigger Numbers
3327 X<number, arbitrary precision>
3328
3329 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3330 C<L<Math::BigFloat>> modules,
3331 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3332 variable-precision arithmetic and overloaded operators, although
3333 they're currently pretty slow.  At the cost of some space and
3334 considerable speed, they avoid the normal pitfalls associated with
3335 limited-precision representations.
3336
3337         use 5.010;
3338         use bigint;  # easy interface to Math::BigInt
3339         $x = 123456789123456789;
3340         say $x * $x;
3341     +15241578780673678515622620750190521
3342
3343 Or with rationals:
3344
3345         use 5.010;
3346         use bigrat;
3347         $x = 3/22;
3348         $y = 4/6;
3349         say "x/y is ", $x/$y;
3350         say "x*y is ", $x*$y;
3351         x/y is 9/44
3352         x*y is 1/11
3353
3354 Several modules let you calculate with unlimited or fixed precision
3355 (bound only by memory and CPU time).  There
3356 are also some non-standard modules that
3357 provide faster implementations via external C libraries.
3358
3359 Here is a short, but incomplete summary:
3360
3361   Math::String           treat string sequences like numbers
3362   Math::FixedPrecision   calculate with a fixed precision
3363   Math::Currency         for currency calculations
3364   Bit::Vector            manipulate bit vectors fast (uses C)
3365   Math::BigIntFast       Bit::Vector wrapper for big numbers
3366   Math::Pari             provides access to the Pari C library
3367   Math::Cephes           uses the external Cephes C library (no
3368                          big numbers)
3369   Math::Cephes::Fraction fractions via the Cephes library
3370   Math::GMP              another one using an external C library
3371   Math::GMPz             an alternative interface to libgmp's big ints
3372   Math::GMPq             an interface to libgmp's fraction numbers
3373   Math::GMPf             an interface to libgmp's floating point numbers
3374
3375 Choose wisely.
3376
3377 =cut