This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
perlfunc: Improve localtime entry
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance,
20 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST> has three scalar arguments
21 followed by a list, whereas L<C<gethostbyname>|/gethostbyname NAME> has
22 four scalar arguments.
23
24 In the syntax descriptions that follow, list operators that expect a
25 list (and provide list context for elements of the list) are shown
26 with LIST as an argument.  Such a list may consist of any combination
27 of scalar arguments or list values; the list values will be included
28 in the list as if each individual element were interpolated at that
29 point in the list, forming a longer single-dimensional list value.
30 Commas should separate literal elements of the LIST.
31
32 Any function in the list below may be used either with or without
33 parentheses around its arguments.  (The syntax descriptions omit the
34 parentheses.)  If you use parentheses, the simple but occasionally
35 surprising rule is this: It I<looks> like a function, therefore it I<is> a
36 function, and precedence doesn't matter.  Otherwise it's a list
37 operator or unary operator, and precedence does matter.  Whitespace
38 between the function and left parenthesis doesn't count, so sometimes
39 you need to be careful:
40
41     print 1+2+4;      # Prints 7.
42     print(1+2) + 4;   # Prints 3.
43     print (1+2)+4;    # Also prints 3!
44     print +(1+2)+4;   # Prints 7.
45     print ((1+2)+4);  # Prints 7.
46
47 If you run Perl with the L<C<use warnings>|warnings> pragma, it can warn
48 you about this.  For example, the third line above produces:
49
50     print (...) interpreted as function at - line 1.
51     Useless use of integer addition in void context at - line 1.
52
53 A few functions take no arguments at all, and therefore work as neither
54 unary nor list operators.  These include such functions as
55 L<C<time>|/time> and L<C<endpwent>|/endpwent>.  For example,
56 C<time+86_400> always means C<time() + 86_400>.
57
58 For functions that can be used in either a scalar or list context,
59 nonabortive failure is generally indicated in scalar context by
60 returning the undefined value, and in list context by returning the
61 empty list.
62
63 Remember the following important rule: There is B<no rule> that relates
64 the behavior of an expression in list context to its behavior in scalar
65 context, or vice versa.  It might do two totally different things.
66 Each operator and function decides which sort of value would be most
67 appropriate to return in scalar context.  Some operators return the
68 length of the list that would have been returned in list context.  Some
69 operators return the first value in the list.  Some operators return the
70 last value in the list.  Some operators return a count of successful
71 operations.  In general, they do what you want, unless you want
72 consistency.
73 X<context>
74
75 A named array in scalar context is quite different from what would at
76 first glance appear to be a list in scalar context.  You can't get a list
77 like C<(1,2,3)> into being in scalar context, because the compiler knows
78 the context at compile time.  It would generate the scalar comma operator
79 there, not the list concatenation version of the comma.  That means it
80 was never a list to start with.
81
82 In general, functions in Perl that serve as wrappers for system calls
83 ("syscalls") of the same name (like L<chown(2)>, L<fork(2)>,
84 L<closedir(2)>, etc.) return true when they succeed and
85 L<C<undef>|/undef EXPR> otherwise, as is usually mentioned in the
86 descriptions below.  This is different from the C interfaces, which
87 return C<-1> on failure.  Exceptions to this rule include
88 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>, and
89 L<C<syscall>|/syscall NUMBER, LIST>.  System calls also set the special
90 L<C<$!>|perlvar/$!> variable on failure.  Other functions do not, except
91 accidentally.
92
93 Extension modules can also hook into the Perl parser to define new
94 kinds of keyword-headed expression.  These may look like functions, but
95 may also look completely different.  The syntax following the keyword
96 is defined entirely by the extension.  If you are an implementor, see
97 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
98 a module, see the module's documentation for details of the syntax that
99 it defines.
100
101 =head2 Perl Functions by Category
102 X<function>
103
104 Here are Perl's functions (including things that look like
105 functions, like some keywords and named operators)
106 arranged by category.  Some functions appear in more
107 than one place.  Any warnings, including those produced by
108 keywords, are described in L<perldiag> and L<warnings>.
109
110 =over 4
111
112 =item Functions for SCALARs or strings
113 X<scalar> X<string> X<character>
114
115 =for Pod::Functions =String
116
117 L<C<chomp>|/chomp VARIABLE>, L<C<chop>|/chop VARIABLE>,
118 L<C<chr>|/chr NUMBER>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
119 L<C<fc>|/fc EXPR>, L<C<hex>|/hex EXPR>,
120 L<C<index>|/index STR,SUBSTR,POSITION>, L<C<lc>|/lc EXPR>,
121 L<C<lcfirst>|/lcfirst EXPR>, L<C<length>|/length EXPR>,
122 L<C<oct>|/oct EXPR>, L<C<ord>|/ord EXPR>,
123 L<C<pack>|/pack TEMPLATE,LIST>,
124 L<C<qE<sol>E<sol>>|/qE<sol>STRINGE<sol>>,
125 L<C<qqE<sol>E<sol>>|/qqE<sol>STRINGE<sol>>, L<C<reverse>|/reverse LIST>,
126 L<C<rindex>|/rindex STR,SUBSTR,POSITION>,
127 L<C<sprintf>|/sprintf FORMAT, LIST>,
128 L<C<substr>|/substr EXPR,OFFSET,LENGTH,REPLACEMENT>,
129 L<C<trE<sol>E<sol>E<sol>>|/trE<sol>E<sol>E<sol>>, L<C<uc>|/uc EXPR>,
130 L<C<ucfirst>|/ucfirst EXPR>,
131 L<C<yE<sol>E<sol>E<sol>>|/yE<sol>E<sol>E<sol>>
132
133 L<C<fc>|/fc EXPR> is available only if the
134 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
135 prefixed with C<CORE::>.  The
136 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
137 with a C<use v5.16> (or higher) declaration in the current scope.
138
139 =item Regular expressions and pattern matching
140 X<regular expression> X<regex> X<regexp>
141
142 =for Pod::Functions =Regexp
143
144 L<C<mE<sol>E<sol>>|/mE<sol>E<sol>>, L<C<pos>|/pos SCALAR>,
145 L<C<qrE<sol>E<sol>>|/qrE<sol>STRINGE<sol>>,
146 L<C<quotemeta>|/quotemeta EXPR>,
147 L<C<sE<sol>E<sol>E<sol>>|/sE<sol>E<sol>E<sol>>,
148 L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
149 L<C<study>|/study SCALAR>
150
151 =item Numeric functions
152 X<numeric> X<number> X<trigonometric> X<trigonometry>
153
154 =for Pod::Functions =Math
155
156 L<C<abs>|/abs VALUE>, L<C<atan2>|/atan2 Y,X>, L<C<cos>|/cos EXPR>,
157 L<C<exp>|/exp EXPR>, L<C<hex>|/hex EXPR>, L<C<int>|/int EXPR>,
158 L<C<log>|/log EXPR>, L<C<oct>|/oct EXPR>, L<C<rand>|/rand EXPR>,
159 L<C<sin>|/sin EXPR>, L<C<sqrt>|/sqrt EXPR>, L<C<srand>|/srand EXPR>
160
161 =item Functions for real @ARRAYs
162 X<array>
163
164 =for Pod::Functions =ARRAY
165
166 L<C<each>|/each HASH>, L<C<keys>|/keys HASH>, L<C<pop>|/pop ARRAY>,
167 L<C<push>|/push ARRAY,LIST>, L<C<shift>|/shift ARRAY>,
168 L<C<splice>|/splice ARRAY,OFFSET,LENGTH,LIST>,
169 L<C<unshift>|/unshift ARRAY,LIST>, L<C<values>|/values HASH>
170
171 =item Functions for list data
172 X<list>
173
174 =for Pod::Functions =LIST
175
176 L<C<grep>|/grep BLOCK LIST>, L<C<join>|/join EXPR,LIST>,
177 L<C<map>|/map BLOCK LIST>, L<C<qwE<sol>E<sol>>|/qwE<sol>STRINGE<sol>>,
178 L<C<reverse>|/reverse LIST>, L<C<sort>|/sort SUBNAME LIST>,
179 L<C<unpack>|/unpack TEMPLATE,EXPR>
180
181 =item Functions for real %HASHes
182 X<hash>
183
184 =for Pod::Functions =HASH
185
186 L<C<delete>|/delete EXPR>, L<C<each>|/each HASH>,
187 L<C<exists>|/exists EXPR>, L<C<keys>|/keys HASH>,
188 L<C<values>|/values HASH>
189
190 =item Input and output functions
191 X<I/O> X<input> X<output> X<dbm>
192
193 =for Pod::Functions =I/O
194
195 L<C<binmode>|/binmode FILEHANDLE, LAYER>, L<C<close>|/close FILEHANDLE>,
196 L<C<closedir>|/closedir DIRHANDLE>, L<C<dbmclose>|/dbmclose HASH>,
197 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>, L<C<die>|/die LIST>,
198 L<C<eof>|/eof FILEHANDLE>, L<C<fileno>|/fileno FILEHANDLE>,
199 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<format>|/format>,
200 L<C<getc>|/getc FILEHANDLE>, L<C<print>|/print FILEHANDLE LIST>,
201 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
202 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
203 L<C<readdir>|/readdir DIRHANDLE>, L<C<readline>|/readline EXPR>,
204 L<C<rewinddir>|/rewinddir DIRHANDLE>, L<C<say>|/say FILEHANDLE LIST>,
205 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
206 L<C<seekdir>|/seekdir DIRHANDLE,POS>,
207 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
208 L<C<syscall>|/syscall NUMBER, LIST>,
209 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
210 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
211 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
212 L<C<tell>|/tell FILEHANDLE>, L<C<telldir>|/telldir DIRHANDLE>,
213 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<warn>|/warn LIST>,
214 L<C<write>|/write FILEHANDLE>
215
216 L<C<say>|/say FILEHANDLE LIST> is available only if the
217 L<C<"say"> feature|feature/The 'say' feature> is enabled or if it is
218 prefixed with C<CORE::>.  The
219 L<C<"say"> feature|feature/The 'say' feature> is enabled automatically
220 with a C<use v5.10> (or higher) declaration in the current scope.
221
222 =item Functions for fixed-length data or records
223
224 =for Pod::Functions =Binary
225
226 L<C<pack>|/pack TEMPLATE,LIST>,
227 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
228 L<C<syscall>|/syscall NUMBER, LIST>,
229 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
230 L<C<sysseek>|/sysseek FILEHANDLE,POSITION,WHENCE>,
231 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET>,
232 L<C<unpack>|/unpack TEMPLATE,EXPR>, L<C<vec>|/vec EXPR,OFFSET,BITS>
233
234 =item Functions for filehandles, files, or directories
235 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
236
237 =for Pod::Functions =File
238
239 L<C<-I<X>>|/-X FILEHANDLE>, L<C<chdir>|/chdir EXPR>,
240 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
241 L<C<chroot>|/chroot FILENAME>,
242 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>, L<C<glob>|/glob EXPR>,
243 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
244 L<C<link>|/link OLDFILE,NEWFILE>, L<C<lstat>|/lstat FILEHANDLE>,
245 L<C<mkdir>|/mkdir FILENAME,MODE>, L<C<open>|/open FILEHANDLE,MODE,EXPR>,
246 L<C<opendir>|/opendir DIRHANDLE,EXPR>, L<C<readlink>|/readlink EXPR>,
247 L<C<rename>|/rename OLDNAME,NEWNAME>, L<C<rmdir>|/rmdir FILENAME>,
248 L<C<select>|/select FILEHANDLE>, L<C<stat>|/stat FILEHANDLE>,
249 L<C<symlink>|/symlink OLDFILE,NEWFILE>,
250 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
251 L<C<umask>|/umask EXPR>, L<C<unlink>|/unlink LIST>,
252 L<C<utime>|/utime LIST>
253
254 =item Keywords related to the control flow of your Perl program
255 X<control flow>
256
257 =for Pod::Functions =Flow
258
259 L<C<break>|/break>, L<C<caller>|/caller EXPR>,
260 L<C<continue>|/continue BLOCK>, L<C<die>|/die LIST>, L<C<do>|/do BLOCK>,
261 L<C<dump>|/dump LABEL>, L<C<eval>|/eval EXPR>,
262 L<C<evalbytes>|/evalbytes EXPR>, L<C<exit>|/exit EXPR>,
263 L<C<__FILE__>|/__FILE__>, L<C<goto>|/goto LABEL>,
264 L<C<last>|/last LABEL>, L<C<__LINE__>|/__LINE__>,
265 L<C<next>|/next LABEL>, L<C<__PACKAGE__>|/__PACKAGE__>,
266 L<C<redo>|/redo LABEL>, L<C<return>|/return EXPR>,
267 L<C<sub>|/sub NAME BLOCK>, L<C<__SUB__>|/__SUB__>,
268 L<C<wantarray>|/wantarray>
269
270 L<C<break>|/break> is available only if you enable the experimental
271 L<C<"switch"> feature|feature/The 'switch' feature> or use the C<CORE::>
272 prefix.  The L<C<"switch"> feature|feature/The 'switch' feature> also
273 enables the C<default>, C<given> and C<when> statements, which are
274 documented in L<perlsyn/"Switch Statements">.
275 The L<C<"switch"> feature|feature/The 'switch' feature> is enabled
276 automatically with a C<use v5.10> (or higher) declaration in the current
277 scope.  In Perl v5.14 and earlier, L<C<continue>|/continue BLOCK>
278 required the L<C<"switch"> feature|feature/The 'switch' feature>, like
279 the other keywords.
280
281 L<C<evalbytes>|/evalbytes EXPR> is only available with the
282 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
283 (see L<feature>) or if prefixed with C<CORE::>.  L<C<__SUB__>|/__SUB__>
284 is only available with the
285 L<C<"current_sub"> feature|feature/The 'current_sub' feature> or if
286 prefixed with C<CORE::>.  Both the
287 L<C<"evalbytes">|feature/The 'unicode_eval' and 'evalbytes' features>
288 and L<C<"current_sub">|feature/The 'current_sub' feature> features are
289 enabled automatically with a C<use v5.16> (or higher) declaration in the
290 current scope.
291
292 =item Keywords related to scoping
293
294 =for Pod::Functions =Namespace
295
296 L<C<caller>|/caller EXPR>, L<C<import>|/import LIST>,
297 L<C<local>|/local EXPR>, L<C<my>|/my VARLIST>, L<C<our>|/our VARLIST>,
298 L<C<package>|/package NAMESPACE>, L<C<state>|/state VARLIST>,
299 L<C<use>|/use Module VERSION LIST>
300
301 L<C<state>|/state VARLIST> is available only if the
302 L<C<"state"> feature|feature/The 'state' feature> is enabled or if it is
303 prefixed with C<CORE::>.  The
304 L<C<"state"> feature|feature/The 'state' feature> is enabled
305 automatically with a C<use v5.10> (or higher) declaration in the current
306 scope.
307
308 =item Miscellaneous functions
309
310 =for Pod::Functions =Misc
311
312 L<C<defined>|/defined EXPR>, L<C<formline>|/formline PICTURE,LIST>,
313 L<C<lock>|/lock THING>, L<C<prototype>|/prototype FUNCTION>,
314 L<C<reset>|/reset EXPR>, L<C<scalar>|/scalar EXPR>,
315 L<C<undef>|/undef EXPR>
316
317 =item Functions for processes and process groups
318 X<process> X<pid> X<process id>
319
320 =for Pod::Functions =Process
321
322 L<C<alarm>|/alarm SECONDS>, L<C<exec>|/exec LIST>, L<C<fork>|/fork>,
323 L<C<getpgrp>|/getpgrp PID>, L<C<getppid>|/getppid>,
324 L<C<getpriority>|/getpriority WHICH,WHO>, L<C<kill>|/kill SIGNAL, LIST>,
325 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>,
326 L<C<qxE<sol>E<sol>>|/qxE<sol>STRINGE<sol>>,
327 L<C<readpipe>|/readpipe EXPR>, L<C<setpgrp>|/setpgrp PID,PGRP>,
328 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
329 L<C<sleep>|/sleep EXPR>, L<C<system>|/system LIST>, L<C<times>|/times>,
330 L<C<wait>|/wait>, L<C<waitpid>|/waitpid PID,FLAGS>
331
332 =item Keywords related to Perl modules
333 X<module>
334
335 =for Pod::Functions =Modules
336
337 L<C<do>|/do EXPR>, L<C<import>|/import LIST>,
338 L<C<no>|/no MODULE VERSION LIST>, L<C<package>|/package NAMESPACE>,
339 L<C<require>|/require VERSION>, L<C<use>|/use Module VERSION LIST>
340
341 =item Keywords related to classes and object-orientation
342 X<object> X<class> X<package>
343
344 =for Pod::Functions =Objects
345
346 L<C<bless>|/bless REF,CLASSNAME>, L<C<dbmclose>|/dbmclose HASH>,
347 L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
348 L<C<package>|/package NAMESPACE>, L<C<ref>|/ref EXPR>,
349 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST>, L<C<tied>|/tied VARIABLE>,
350 L<C<untie>|/untie VARIABLE>, L<C<use>|/use Module VERSION LIST>
351
352 =item Low-level socket functions
353 X<socket> X<sock>
354
355 =for Pod::Functions =Socket
356
357 L<C<accept>|/accept NEWSOCKET,GENERICSOCKET>,
358 L<C<bind>|/bind SOCKET,NAME>, L<C<connect>|/connect SOCKET,NAME>,
359 L<C<getpeername>|/getpeername SOCKET>,
360 L<C<getsockname>|/getsockname SOCKET>,
361 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
362 L<C<listen>|/listen SOCKET,QUEUESIZE>,
363 L<C<recv>|/recv SOCKET,SCALAR,LENGTH,FLAGS>,
364 L<C<send>|/send SOCKET,MSG,FLAGS,TO>,
365 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
366 L<C<shutdown>|/shutdown SOCKET,HOW>,
367 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
368 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>
369
370 =item System V interprocess communication functions
371 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
372
373 =for Pod::Functions =SysV
374
375 L<C<msgctl>|/msgctl ID,CMD,ARG>, L<C<msgget>|/msgget KEY,FLAGS>,
376 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
377 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>,
378 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
379 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
380 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
381 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
382 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>
383
384 =item Fetching user and group info
385 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
386
387 =for Pod::Functions =User
388
389 L<C<endgrent>|/endgrent>, L<C<endhostent>|/endhostent>,
390 L<C<endnetent>|/endnetent>, L<C<endpwent>|/endpwent>,
391 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
392 L<C<getgrnam>|/getgrnam NAME>, L<C<getlogin>|/getlogin>,
393 L<C<getpwent>|/getpwent>, L<C<getpwnam>|/getpwnam NAME>,
394 L<C<getpwuid>|/getpwuid UID>, L<C<setgrent>|/setgrent>,
395 L<C<setpwent>|/setpwent>
396
397 =item Fetching network info
398 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
399
400 =for Pod::Functions =Network
401
402 L<C<endprotoent>|/endprotoent>, L<C<endservent>|/endservent>,
403 L<C<gethostbyaddr>|/gethostbyaddr ADDR,ADDRTYPE>,
404 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
405 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
406 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
407 L<C<getprotobyname>|/getprotobyname NAME>,
408 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
409 L<C<getprotoent>|/getprotoent>,
410 L<C<getservbyname>|/getservbyname NAME,PROTO>,
411 L<C<getservbyport>|/getservbyport PORT,PROTO>,
412 L<C<getservent>|/getservent>, L<C<sethostent>|/sethostent STAYOPEN>,
413 L<C<setnetent>|/setnetent STAYOPEN>,
414 L<C<setprotoent>|/setprotoent STAYOPEN>,
415 L<C<setservent>|/setservent STAYOPEN>
416
417 =item Time-related functions
418 X<time> X<date>
419
420 =for Pod::Functions =Time
421
422 L<C<gmtime>|/gmtime EXPR>, L<C<localtime>|/localtime EXPR>,
423 L<C<time>|/time>, L<C<times>|/times>
424
425 =item Non-function keywords
426
427 =for Pod::Functions =!Non-functions
428
429 C<and>, C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<cmp>, C<CORE>, C<__DATA__>,
430 C<default>, C<DESTROY>, C<else>, C<elseif>, C<elsif>, C<END>, C<__END__>,
431 C<eq>, C<for>, C<foreach>, C<ge>, C<given>, C<gt>, C<if>, C<INIT>, C<le>,
432 C<lt>, C<ne>, C<not>, C<or>, C<UNITCHECK>, C<unless>, C<until>, C<when>,
433 C<while>, C<x>, C<xor>
434
435 =back
436
437 =head2 Portability
438 X<portability> X<Unix> X<portable>
439
440 Perl was born in Unix and can therefore access all common Unix
441 system calls.  In non-Unix environments, the functionality of some
442 Unix system calls may not be available or details of the available
443 functionality may differ slightly.  The Perl functions affected
444 by this are:
445
446 L<C<-I<X>>|/-X FILEHANDLE>, L<C<binmode>|/binmode FILEHANDLE, LAYER>,
447 L<C<chmod>|/chmod LIST>, L<C<chown>|/chown LIST>,
448 L<C<chroot>|/chroot FILENAME>, L<C<crypt>|/crypt PLAINTEXT,SALT>,
449 L<C<dbmclose>|/dbmclose HASH>, L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>,
450 L<C<dump>|/dump LABEL>, L<C<endgrent>|/endgrent>,
451 L<C<endhostent>|/endhostent>, L<C<endnetent>|/endnetent>,
452 L<C<endprotoent>|/endprotoent>, L<C<endpwent>|/endpwent>,
453 L<C<endservent>|/endservent>, L<C<exec>|/exec LIST>,
454 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>,
455 L<C<flock>|/flock FILEHANDLE,OPERATION>, L<C<fork>|/fork>,
456 L<C<getgrent>|/getgrent>, L<C<getgrgid>|/getgrgid GID>,
457 L<C<gethostbyname>|/gethostbyname NAME>, L<C<gethostent>|/gethostent>,
458 L<C<getlogin>|/getlogin>,
459 L<C<getnetbyaddr>|/getnetbyaddr ADDR,ADDRTYPE>,
460 L<C<getnetbyname>|/getnetbyname NAME>, L<C<getnetent>|/getnetent>,
461 L<C<getppid>|/getppid>, L<C<getpgrp>|/getpgrp PID>,
462 L<C<getpriority>|/getpriority WHICH,WHO>,
463 L<C<getprotobynumber>|/getprotobynumber NUMBER>,
464 L<C<getprotoent>|/getprotoent>, L<C<getpwent>|/getpwent>,
465 L<C<getpwnam>|/getpwnam NAME>, L<C<getpwuid>|/getpwuid UID>,
466 L<C<getservbyport>|/getservbyport PORT,PROTO>,
467 L<C<getservent>|/getservent>,
468 L<C<getsockopt>|/getsockopt SOCKET,LEVEL,OPTNAME>,
469 L<C<glob>|/glob EXPR>, L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>,
470 L<C<kill>|/kill SIGNAL, LIST>, L<C<link>|/link OLDFILE,NEWFILE>,
471 L<C<lstat>|/lstat FILEHANDLE>, L<C<msgctl>|/msgctl ID,CMD,ARG>,
472 L<C<msgget>|/msgget KEY,FLAGS>,
473 L<C<msgrcv>|/msgrcv ID,VAR,SIZE,TYPE,FLAGS>,
474 L<C<msgsnd>|/msgsnd ID,MSG,FLAGS>, L<C<open>|/open FILEHANDLE,MODE,EXPR>,
475 L<C<pipe>|/pipe READHANDLE,WRITEHANDLE>, L<C<readlink>|/readlink EXPR>,
476 L<C<rename>|/rename OLDNAME,NEWNAME>,
477 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT>,
478 L<C<semctl>|/semctl ID,SEMNUM,CMD,ARG>,
479 L<C<semget>|/semget KEY,NSEMS,FLAGS>, L<C<semop>|/semop KEY,OPSTRING>,
480 L<C<setgrent>|/setgrent>, L<C<sethostent>|/sethostent STAYOPEN>,
481 L<C<setnetent>|/setnetent STAYOPEN>, L<C<setpgrp>|/setpgrp PID,PGRP>,
482 L<C<setpriority>|/setpriority WHICH,WHO,PRIORITY>,
483 L<C<setprotoent>|/setprotoent STAYOPEN>, L<C<setpwent>|/setpwent>,
484 L<C<setservent>|/setservent STAYOPEN>,
485 L<C<setsockopt>|/setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL>,
486 L<C<shmctl>|/shmctl ID,CMD,ARG>, L<C<shmget>|/shmget KEY,SIZE,FLAGS>,
487 L<C<shmread>|/shmread ID,VAR,POS,SIZE>,
488 L<C<shmwrite>|/shmwrite ID,STRING,POS,SIZE>,
489 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL>,
490 L<C<socketpair>|/socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL>,
491 L<C<stat>|/stat FILEHANDLE>, L<C<symlink>|/symlink OLDFILE,NEWFILE>,
492 L<C<syscall>|/syscall NUMBER, LIST>,
493 L<C<sysopen>|/sysopen FILEHANDLE,FILENAME,MODE>,
494 L<C<system>|/system LIST>, L<C<times>|/times>,
495 L<C<truncate>|/truncate FILEHANDLE,LENGTH>, L<C<umask>|/umask EXPR>,
496 L<C<unlink>|/unlink LIST>, L<C<utime>|/utime LIST>, L<C<wait>|/wait>,
497 L<C<waitpid>|/waitpid PID,FLAGS>
498
499 For more information about the portability of these functions, see
500 L<perlport> and other available platform-specific documentation.
501
502 =head2 Alphabetical Listing of Perl Functions
503
504 =over
505
506 =item -X FILEHANDLE
507 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
508 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
509
510 =item -X EXPR
511
512 =item -X DIRHANDLE
513
514 =item -X
515
516 =for Pod::Functions a file test (-r, -x, etc)
517
518 A file test, where X is one of the letters listed below.  This unary
519 operator takes one argument, either a filename, a filehandle, or a dirhandle,
520 and tests the associated file to see if something is true about it.  If the
521 argument is omitted, tests L<C<$_>|perlvar/$_>, except for C<-t>, which
522 tests STDIN.  Unless otherwise documented, it returns C<1> for true and
523 C<''> for false.  If the file doesn't exist or can't be examined, it
524 returns L<C<undef>|/undef EXPR> and sets L<C<$!>|perlvar/$!> (errno).
525 With the exception of the C<-l> test they all follow symbolic links
526 because they use C<stat()> and not C<lstat()> (so dangling symlinks can't
527 be examined and will therefore report failure).
528
529 Despite the funny names, precedence is the same as any other named unary
530 operator.  The operator may be any of:
531
532     -r  File is readable by effective uid/gid.
533     -w  File is writable by effective uid/gid.
534     -x  File is executable by effective uid/gid.
535     -o  File is owned by effective uid.
536
537     -R  File is readable by real uid/gid.
538     -W  File is writable by real uid/gid.
539     -X  File is executable by real uid/gid.
540     -O  File is owned by real uid.
541
542     -e  File exists.
543     -z  File has zero size (is empty).
544     -s  File has nonzero size (returns size in bytes).
545
546     -f  File is a plain file.
547     -d  File is a directory.
548     -l  File is a symbolic link (false if symlinks aren't
549         supported by the file system).
550     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
551     -S  File is a socket.
552     -b  File is a block special file.
553     -c  File is a character special file.
554     -t  Filehandle is opened to a tty.
555
556     -u  File has setuid bit set.
557     -g  File has setgid bit set.
558     -k  File has sticky bit set.
559
560     -T  File is an ASCII or UTF-8 text file (heuristic guess).
561     -B  File is a "binary" file (opposite of -T).
562
563     -M  Script start time minus file modification time, in days.
564     -A  Same for access time.
565     -C  Same for inode change time (Unix, may differ for other
566         platforms)
567
568 Example:
569
570     while (<>) {
571         chomp;
572         next unless -f $_;  # ignore specials
573         #...
574     }
575
576 Note that C<-s/a/b/> does not do a negated substitution.  Saying
577 C<-exp($foo)> still works as expected, however: only single letters
578 following a minus are interpreted as file tests.
579
580 These operators are exempt from the "looks like a function rule" described
581 above.  That is, an opening parenthesis after the operator does not affect
582 how much of the following code constitutes the argument.  Put the opening
583 parentheses before the operator to separate it from code that follows (this
584 applies only to operators with higher precedence than unary operators, of
585 course):
586
587     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
588     (-s $file) + 1024  # correct
589
590 The interpretation of the file permission operators C<-r>, C<-R>,
591 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
592 of the file and the uids and gids of the user.  There may be other
593 reasons you can't actually read, write, or execute the file: for
594 example network filesystem access controls, ACLs (access control lists),
595 read-only filesystems, and unrecognized executable formats.  Note
596 that the use of these six specific operators to verify if some operation
597 is possible is usually a mistake, because it may be open to race
598 conditions.
599
600 Also note that, for the superuser on the local filesystems, the C<-r>,
601 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
602 if any execute bit is set in the mode.  Scripts run by the superuser
603 may thus need to do a L<C<stat>|/stat FILEHANDLE> to determine the
604 actual mode of the file, or temporarily set their effective uid to
605 something else.
606
607 If you are using ACLs, there is a pragma called L<C<filetest>|filetest>
608 that may produce more accurate results than the bare
609 L<C<stat>|/stat FILEHANDLE> mode bits.
610 When under C<use filetest 'access'>, the above-mentioned filetests
611 test whether the permission can(not) be granted using the L<access(2)>
612 family of system calls.  Also note that the C<-x> and C<-X> tests may
613 under this pragma return true even if there are no execute permission
614 bits set (nor any extra execute permission ACLs).  This strangeness is
615 due to the underlying system calls' definitions.  Note also that, due to
616 the implementation of C<use filetest 'access'>, the C<_> special
617 filehandle won't cache the results of the file tests when this pragma is
618 in effect.  Read the documentation for the L<C<filetest>|filetest>
619 pragma for more information.
620
621 The C<-T> and C<-B> tests work as follows.  The first block or so of
622 the file is examined to see if it is valid UTF-8 that includes non-ASCII
623 characters.  If so, it's a C<-T> file.  Otherwise, that same portion of
624 the file is examined for odd characters such as strange control codes or
625 characters with the high bit set.  If more than a third of the
626 characters are strange, it's a C<-B> file; otherwise it's a C<-T> file.
627 Also, any file containing a zero byte in the examined portion is
628 considered a binary file.  (If executed within the scope of a L<S<use
629 locale>|perllocale> which includes C<LC_CTYPE>, odd characters are
630 anything that isn't a printable nor space in the current locale.)  If
631 C<-T> or C<-B> is used on a filehandle, the current IO buffer is
632 examined
633 rather than the first block.  Both C<-T> and C<-B> return true on an empty
634 file, or a file at EOF when testing a filehandle.  Because you have to
635 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
636 against the file first, as in C<next unless -f $file && -T $file>.
637
638 If any of the file tests (or either the L<C<stat>|/stat FILEHANDLE> or
639 L<C<lstat>|/lstat FILEHANDLE> operator) is given the special filehandle
640 consisting of a solitary underline, then the stat structure of the
641 previous file test (or L<C<stat>|/stat FILEHANDLE> operator) is used,
642 saving a system call.  (This doesn't work with C<-t>, and you need to
643 remember that L<C<lstat>|/lstat FILEHANDLE> and C<-l> leave values in
644 the stat structure for the symbolic link, not the real file.)  (Also, if
645 the stat buffer was filled by an L<C<lstat>|/lstat FILEHANDLE> call,
646 C<-T> and C<-B> will reset it with the results of C<stat _>).
647 Example:
648
649     print "Can do.\n" if -r $a || -w _ || -x _;
650
651     stat($filename);
652     print "Readable\n" if -r _;
653     print "Writable\n" if -w _;
654     print "Executable\n" if -x _;
655     print "Setuid\n" if -u _;
656     print "Setgid\n" if -g _;
657     print "Sticky\n" if -k _;
658     print "Text\n" if -T _;
659     print "Binary\n" if -B _;
660
661 As of Perl 5.10.0, as a form of purely syntactic sugar, you can stack file
662 test operators, in a way that C<-f -w -x $file> is equivalent to
663 C<-x $file && -w _ && -f _>.  (This is only fancy syntax: if you use
664 the return value of C<-f $file> as an argument to another filetest
665 operator, no special magic will happen.)
666
667 Portability issues: L<perlport/-X>.
668
669 To avoid confusing would-be users of your code with mysterious
670 syntax errors, put something like this at the top of your script:
671
672     use 5.010;  # so filetest ops can stack
673
674 =item abs VALUE
675 X<abs> X<absolute>
676
677 =item abs
678
679 =for Pod::Functions absolute value function
680
681 Returns the absolute value of its argument.
682 If VALUE is omitted, uses L<C<$_>|perlvar/$_>.
683
684 =item accept NEWSOCKET,GENERICSOCKET
685 X<accept>
686
687 =for Pod::Functions accept an incoming socket connect
688
689 Accepts an incoming socket connect, just as L<accept(2)>
690 does.  Returns the packed address if it succeeded, false otherwise.
691 See the example in L<perlipc/"Sockets: Client/Server Communication">.
692
693 On systems that support a close-on-exec flag on files, the flag will
694 be set for the newly opened file descriptor, as determined by the
695 value of L<C<$^F>|perlvar/$^F>.  See L<perlvar/$^F>.
696
697 =item alarm SECONDS
698 X<alarm>
699 X<SIGALRM>
700 X<timer>
701
702 =item alarm
703
704 =for Pod::Functions schedule a SIGALRM
705
706 Arranges to have a SIGALRM delivered to this process after the
707 specified number of wallclock seconds has elapsed.  If SECONDS is not
708 specified, the value stored in L<C<$_>|perlvar/$_> is used.  (On some
709 machines, unfortunately, the elapsed time may be up to one second less
710 or more than you specified because of how seconds are counted, and
711 process scheduling may delay the delivery of the signal even further.)
712
713 Only one timer may be counting at once.  Each call disables the
714 previous timer, and an argument of C<0> may be supplied to cancel the
715 previous timer without starting a new one.  The returned value is the
716 amount of time remaining on the previous timer.
717
718 For delays of finer granularity than one second, the L<Time::HiRes> module
719 (from CPAN, and starting from Perl 5.8 part of the standard
720 distribution) provides
721 L<C<ualarm>|Time::HiRes/ualarm ( $useconds [, $interval_useconds ] )>.
722 You may also use Perl's four-argument version of
723 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> leaving the first three
724 arguments undefined, or you might be able to use the
725 L<C<syscall>|/syscall NUMBER, LIST> interface to access L<setitimer(2)>
726 if your system supports it.  See L<perlfaq8> for details.
727
728 It is usually a mistake to intermix L<C<alarm>|/alarm SECONDS> and
729 L<C<sleep>|/sleep EXPR> calls, because L<C<sleep>|/sleep EXPR> may be
730 internally implemented on your system with L<C<alarm>|/alarm SECONDS>.
731
732 If you want to use L<C<alarm>|/alarm SECONDS> to time out a system call
733 you need to use an L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> pair.  You
734 can't rely on the alarm causing the system call to fail with
735 L<C<$!>|perlvar/$!> set to C<EINTR> because Perl sets up signal handlers
736 to restart system calls on some systems.  Using
737 L<C<eval>|/eval EXPR>/L<C<die>|/die LIST> always works, modulo the
738 caveats given in L<perlipc/"Signals">.
739
740     eval {
741         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
742         alarm $timeout;
743         my $nread = sysread $socket, $buffer, $size;
744         alarm 0;
745     };
746     if ($@) {
747         die unless $@ eq "alarm\n";   # propagate unexpected errors
748         # timed out
749     }
750     else {
751         # didn't
752     }
753
754 For more information see L<perlipc>.
755
756 Portability issues: L<perlport/alarm>.
757
758 =item atan2 Y,X
759 X<atan2> X<arctangent> X<tan> X<tangent>
760
761 =for Pod::Functions arctangent of Y/X in the range -PI to PI
762
763 Returns the arctangent of Y/X in the range -PI to PI.
764
765 For the tangent operation, you may use the
766 L<C<Math::Trig::tan>|Math::Trig/B<tan>> function, or use the familiar
767 relation:
768
769     sub tan { sin($_[0]) / cos($_[0])  }
770
771 The return value for C<atan2(0,0)> is implementation-defined; consult
772 your L<atan2(3)> manpage for more information.
773
774 Portability issues: L<perlport/atan2>.
775
776 =item bind SOCKET,NAME
777 X<bind>
778
779 =for Pod::Functions binds an address to a socket
780
781 Binds a network address to a socket, just as L<bind(2)>
782 does.  Returns true if it succeeded, false otherwise.  NAME should be a
783 packed address of the appropriate type for the socket.  See the examples in
784 L<perlipc/"Sockets: Client/Server Communication">.
785
786 =item binmode FILEHANDLE, LAYER
787 X<binmode> X<binary> X<text> X<DOS> X<Windows>
788
789 =item binmode FILEHANDLE
790
791 =for Pod::Functions prepare binary files for I/O
792
793 Arranges for FILEHANDLE to be read or written in "binary" or "text"
794 mode on systems where the run-time libraries distinguish between
795 binary and text files.  If FILEHANDLE is an expression, the value is
796 taken as the name of the filehandle.  Returns true on success,
797 otherwise it returns L<C<undef>|/undef EXPR> and sets
798 L<C<$!>|perlvar/$!> (errno).
799
800 On some systems (in general, DOS- and Windows-based systems)
801 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
802 working with a text file.  For the sake of portability it is a good idea
803 always to use it when appropriate, and never to use it when it isn't
804 appropriate.  Also, people can set their I/O to be by default
805 UTF8-encoded Unicode, not bytes.
806
807 In other words: regardless of platform, use
808 L<C<binmode>|/binmode FILEHANDLE, LAYER> on binary data, like images,
809 for example.
810
811 If LAYER is present it is a single string, but may contain multiple
812 directives.  The directives alter the behaviour of the filehandle.
813 When LAYER is present, using binmode on a text file makes sense.
814
815 If LAYER is omitted or specified as C<:raw> the filehandle is made
816 suitable for passing binary data.  This includes turning off possible CRLF
817 translation and marking it as bytes (as opposed to Unicode characters).
818 Note that, despite what may be implied in I<"Programming Perl"> (the
819 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
820 Other layers that would affect the binary nature of the stream are
821 I<also> disabled.  See L<PerlIO>, and the discussion about the PERLIO
822 environment variable in L<perlrun|perlrun/PERLIO>.
823
824 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
825 form C<:...>, are called I/O I<layers>.  The L<open> pragma can be used to
826 establish default I/O layers.
827
828 I<The LAYER parameter of the L<C<binmode>|/binmode FILEHANDLE, LAYER>
829 function is described as "DISCIPLINE" in "Programming Perl, 3rd
830 Edition".  However, since the publishing of this book, by many known as
831 "Camel III", the consensus of the naming of this functionality has moved
832 from "discipline" to "layer".  All documentation of this version of Perl
833 therefore refers to "layers" rather than to "disciplines".  Now back to
834 the regularly scheduled documentation...>
835
836 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
837 C<:utf8> just marks the data as UTF-8 without further checking,
838 while C<:encoding(UTF-8)> checks the data for actually being valid
839 UTF-8.  More details can be found in L<PerlIO::encoding>.
840
841 In general, L<C<binmode>|/binmode FILEHANDLE, LAYER> should be called
842 after L<C<open>|/open FILEHANDLE,MODE,EXPR> but before any I/O is done on the
843 filehandle.  Calling L<C<binmode>|/binmode FILEHANDLE, LAYER> normally
844 flushes any pending buffered output data (and perhaps pending input
845 data) on the handle.  An exception to this is the C<:encoding> layer
846 that changes the default character encoding of the handle.
847 The C<:encoding> layer sometimes needs to be called in
848 mid-stream, and it doesn't flush the stream.  C<:encoding>
849 also implicitly pushes on top of itself the C<:utf8> layer because
850 internally Perl operates on UTF8-encoded Unicode characters.
851
852 The operating system, device drivers, C libraries, and Perl run-time
853 system all conspire to let the programmer treat a single
854 character (C<\n>) as the line terminator, irrespective of external
855 representation.  On many operating systems, the native text file
856 representation matches the internal representation, but on some
857 platforms the external representation of C<\n> is made up of more than
858 one character.
859
860 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
861 a single character to end each line in the external representation of text
862 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
863 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
864 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
865 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
866 two characters C<\cM\cJ>.  That means that if you don't use
867 L<C<binmode>|/binmode FILEHANDLE, LAYER> on these systems, C<\cM\cJ>
868 sequences on disk will be converted to C<\n> on input, and any C<\n> in
869 your program will be converted back to C<\cM\cJ> on output.  This is
870 what you want for text files, but it can be disastrous for binary files.
871
872 Another consequence of using L<C<binmode>|/binmode FILEHANDLE, LAYER>
873 (on some systems) is that special end-of-file markers will be seen as
874 part of the data stream.  For systems from the Microsoft family this
875 means that, if your binary data contain C<\cZ>, the I/O subsystem will
876 regard it as the end of the file, unless you use
877 L<C<binmode>|/binmode FILEHANDLE, LAYER>.
878
879 L<C<binmode>|/binmode FILEHANDLE, LAYER> is important not only for
880 L<C<readline>|/readline EXPR> and L<C<print>|/print FILEHANDLE LIST>
881 operations, but also when using
882 L<C<read>|/read FILEHANDLE,SCALAR,LENGTH,OFFSET>,
883 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE>,
884 L<C<sysread>|/sysread FILEHANDLE,SCALAR,LENGTH,OFFSET>,
885 L<C<syswrite>|/syswrite FILEHANDLE,SCALAR,LENGTH,OFFSET> and
886 L<C<tell>|/tell FILEHANDLE> (see L<perlport> for more details).  See the
887 L<C<$E<sol>>|perlvar/$E<sol>> and L<C<$\>|perlvar/$\> variables in
888 L<perlvar> for how to manually set your input and output
889 line-termination sequences.
890
891 Portability issues: L<perlport/binmode>.
892
893 =item bless REF,CLASSNAME
894 X<bless>
895
896 =item bless REF
897
898 =for Pod::Functions create an object
899
900 This function tells the thingy referenced by REF that it is now an object
901 in the CLASSNAME package.  If CLASSNAME is an empty string, it is
902 interpreted as referring to the C<main> package.
903 If CLASSNAME is omitted, the current package
904 is used.  Because a L<C<bless>|/bless REF,CLASSNAME> is often the last
905 thing in a constructor, it returns the reference for convenience.
906 Always use the two-argument version if a derived class might inherit the
907 method doing the blessing.  See L<perlobj> for more about the blessing
908 (and blessings) of objects.
909
910 Consider always blessing objects in CLASSNAMEs that are mixed case.
911 Namespaces with all lowercase names are considered reserved for
912 Perl pragmas.  Builtin types have all uppercase names.  To prevent
913 confusion, you may wish to avoid such package names as well.
914 It is advised to avoid the class name C<0>, because much code erroneously
915 uses the result of L<C<ref>|/ref EXPR> as a truth value.
916
917 See L<perlmod/"Perl Modules">.
918
919 =item break
920
921 =for Pod::Functions +switch break out of a C<given> block
922
923 Break out of a C<given> block.
924
925 L<C<break>|/break> is available only if the
926 L<C<"switch"> feature|feature/The 'switch' feature> is enabled or if it
927 is prefixed with C<CORE::>. The
928 L<C<"switch"> feature|feature/The 'switch' feature> is enabled
929 automatically with a C<use v5.10> (or higher) declaration in the current
930 scope.
931
932 =item caller EXPR
933 X<caller> X<call stack> X<stack> X<stack trace>
934
935 =item caller
936
937 =for Pod::Functions get context of the current subroutine call
938
939 Returns the context of the current pure perl subroutine call.  In scalar
940 context, returns the caller's package name if there I<is> a caller (that is, if
941 we're in a subroutine or L<C<eval>|/eval EXPR> or
942 L<C<require>|/require VERSION>) and the undefined value otherwise.
943 caller never returns XS subs and they are skipped.  The next pure perl
944 sub will appear instead of the XS sub in caller's return values.  In
945 list context, caller returns
946
947        # 0         1          2
948     my ($package, $filename, $line) = caller;
949
950 Like L<C<__FILE__>|/__FILE__> and L<C<__LINE__>|/__LINE__>, the filename and
951 line number returned here may be altered by the mechanism described at
952 L<perlsyn/"Plain Old Comments (Not!)">.
953
954 With EXPR, it returns some extra information that the debugger uses to
955 print a stack trace.  The value of EXPR indicates how many call frames
956 to go back before the current one.
957
958     #  0         1          2      3            4
959  my ($package, $filename, $line, $subroutine, $hasargs,
960
961     #  5          6          7            8       9         10
962     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
963   = caller($i);
964
965 Here, $subroutine is the function that the caller called (rather than the
966 function containing the caller).  Note that $subroutine may be C<(eval)> if
967 the frame is not a subroutine call, but an L<C<eval>|/eval EXPR>.  In
968 such a case additional elements $evaltext and C<$is_require> are set:
969 C<$is_require> is true if the frame is created by a
970 L<C<require>|/require VERSION> or L<C<use>|/use Module VERSION LIST>
971 statement, $evaltext contains the text of the C<eval EXPR> statement.
972 In particular, for an C<eval BLOCK> statement, $subroutine is C<(eval)>,
973 but $evaltext is undefined.  (Note also that each
974 L<C<use>|/use Module VERSION LIST> statement creates a
975 L<C<require>|/require VERSION> frame inside an C<eval EXPR> frame.)
976 $subroutine may also be C<(unknown)> if this particular subroutine
977 happens to have been deleted from the symbol table.  C<$hasargs> is true
978 if a new instance of L<C<@_>|perlvar/@_> was set up for the frame.
979 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
980 compiled with.  C<$hints> corresponds to L<C<$^H>|perlvar/$^H>, and
981 C<$bitmask> corresponds to
982 L<C<${^WARNING_BITS}>|perlvar/${^WARNING_BITS}>.  The C<$hints> and
983 C<$bitmask> values are subject to change between versions of Perl, and
984 are not meant for external use.
985
986 C<$hinthash> is a reference to a hash containing the value of
987 L<C<%^H>|perlvar/%^H> when the caller was compiled, or
988 L<C<undef>|/undef EXPR> if L<C<%^H>|perlvar/%^H> was empty.  Do not
989 modify the values of this hash, as they are the actual values stored in
990 the optree.
991
992 Furthermore, when called from within the DB package in
993 list context, and with an argument, caller returns more
994 detailed information: it sets the list variable C<@DB::args> to be the
995 arguments with which the subroutine was invoked.
996
997 Be aware that the optimizer might have optimized call frames away before
998 L<C<caller>|/caller EXPR> had a chance to get the information.  That
999 means that C<caller(N)> might not return information about the call
1000 frame you expect it to, for C<< N > 1 >>.  In particular, C<@DB::args>
1001 might have information from the previous time L<C<caller>|/caller EXPR>
1002 was called.
1003
1004 Be aware that setting C<@DB::args> is I<best effort>, intended for
1005 debugging or generating backtraces, and should not be relied upon.  In
1006 particular, as L<C<@_>|perlvar/@_> contains aliases to the caller's
1007 arguments, Perl does not take a copy of L<C<@_>|perlvar/@_>, so
1008 C<@DB::args> will contain modifications the subroutine makes to
1009 L<C<@_>|perlvar/@_> or its contents, not the original values at call
1010 time.  C<@DB::args>, like L<C<@_>|perlvar/@_>, does not hold explicit
1011 references to its elements, so under certain cases its elements may have
1012 become freed and reallocated for other variables or temporary values.
1013 Finally, a side effect of the current implementation is that the effects
1014 of C<shift @_> can I<normally> be undone (but not C<pop @_> or other
1015 splicing, I<and> not if a reference to L<C<@_>|perlvar/@_> has been
1016 taken, I<and> subject to the caveat about reallocated elements), so
1017 C<@DB::args> is actually a hybrid of the current state and initial state
1018 of L<C<@_>|perlvar/@_>.  Buyer beware.
1019
1020 =item chdir EXPR
1021 X<chdir>
1022 X<cd>
1023 X<directory, change>
1024
1025 =item chdir FILEHANDLE
1026
1027 =item chdir DIRHANDLE
1028
1029 =item chdir
1030
1031 =for Pod::Functions change your current working directory
1032
1033 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
1034 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
1035 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
1036 variable C<$ENV{'SYS$LOGIN'}> is also checked, and used if it is set.)  If
1037 neither is set, L<C<chdir>|/chdir EXPR> does nothing and fails.  It
1038 returns true on success, false otherwise.  See the example under
1039 L<C<die>|/die LIST>.
1040
1041 On systems that support L<fchdir(2)>, you may pass a filehandle or
1042 directory handle as the argument.  On systems that don't support L<fchdir(2)>,
1043 passing handles raises an exception.
1044
1045 =item chmod LIST
1046 X<chmod> X<permission> X<mode>
1047
1048 =for Pod::Functions changes the permissions on a list of files
1049
1050 Changes the permissions of a list of files.  The first element of the
1051 list must be the numeric mode, which should probably be an octal
1052 number, and which definitely should I<not> be a string of octal digits:
1053 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
1054 successfully changed.  See also L<C<oct>|/oct EXPR> if all you have is a
1055 string.
1056
1057     my $cnt = chmod 0755, "foo", "bar";
1058     chmod 0755, @executables;
1059     my $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
1060                                                 # --w----r-T
1061     my $mode = "0644"; chmod oct($mode), "foo"; # this is better
1062     my $mode = 0644;   chmod $mode, "foo";      # this is best
1063
1064 On systems that support L<fchmod(2)>, you may pass filehandles among the
1065 files.  On systems that don't support L<fchmod(2)>, passing filehandles raises
1066 an exception.  Filehandles must be passed as globs or glob references to be
1067 recognized; barewords are considered filenames.
1068
1069     open(my $fh, "<", "foo");
1070     my $perm = (stat $fh)[2] & 07777;
1071     chmod($perm | 0600, $fh);
1072
1073 You can also import the symbolic C<S_I*> constants from the
1074 L<C<Fcntl>|Fcntl> module:
1075
1076     use Fcntl qw( :mode );
1077     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
1078     # Identical to the chmod 0755 of the example above.
1079
1080 Portability issues: L<perlport/chmod>.
1081
1082 =item chomp VARIABLE
1083 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
1084
1085 =item chomp( LIST )
1086
1087 =item chomp
1088
1089 =for Pod::Functions remove a trailing record separator from a string
1090
1091 This safer version of L<C<chop>|/chop VARIABLE> removes any trailing
1092 string that corresponds to the current value of
1093 L<C<$E<sol>>|perlvar/$E<sol>> (also known as C<$INPUT_RECORD_SEPARATOR>
1094 in the L<C<English>|English> module).  It returns the total
1095 number of characters removed from all its arguments.  It's often used to
1096 remove the newline from the end of an input record when you're worried
1097 that the final record may be missing its newline.  When in paragraph
1098 mode (C<$/ = ''>), it removes all trailing newlines from the string.
1099 When in slurp mode (C<$/ = undef>) or fixed-length record mode
1100 (L<C<$E<sol>>|perlvar/$E<sol>> is a reference to an integer or the like;
1101 see L<perlvar>), L<C<chomp>|/chomp VARIABLE> won't remove anything.
1102 If VARIABLE is omitted, it chomps L<C<$_>|perlvar/$_>.  Example:
1103
1104     while (<>) {
1105         chomp;  # avoid \n on last field
1106         my @array = split(/:/);
1107         # ...
1108     }
1109
1110 If VARIABLE is a hash, it chomps the hash's values, but not its keys,
1111 resetting the L<C<each>|/each HASH> iterator in the process.
1112
1113 You can actually chomp anything that's an lvalue, including an assignment:
1114
1115     chomp(my $cwd = `pwd`);
1116     chomp(my $answer = <STDIN>);
1117
1118 If you chomp a list, each element is chomped, and the total number of
1119 characters removed is returned.
1120
1121 Note that parentheses are necessary when you're chomping anything
1122 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
1123 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
1124 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
1125 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
1126 as C<chomp($a, $b)>.
1127
1128 =item chop VARIABLE
1129 X<chop>
1130
1131 =item chop( LIST )
1132
1133 =item chop
1134
1135 =for Pod::Functions remove the last character from a string
1136
1137 Chops off the last character of a string and returns the character
1138 chopped.  It is much more efficient than C<s/.$//s> because it neither
1139 scans nor copies the string.  If VARIABLE is omitted, chops
1140 L<C<$_>|perlvar/$_>.
1141 If VARIABLE is a hash, it chops the hash's values, but not its keys,
1142 resetting the L<C<each>|/each HASH> iterator in the process.
1143
1144 You can actually chop anything that's an lvalue, including an assignment.
1145
1146 If you chop a list, each element is chopped.  Only the value of the
1147 last L<C<chop>|/chop VARIABLE> is returned.
1148
1149 Note that L<C<chop>|/chop VARIABLE> returns the last character.  To
1150 return all but the last character, use C<substr($string, 0, -1)>.
1151
1152 See also L<C<chomp>|/chomp VARIABLE>.
1153
1154 =item chown LIST
1155 X<chown> X<owner> X<user> X<group>
1156
1157 =for Pod::Functions change the ownership on a list of files
1158
1159 Changes the owner (and group) of a list of files.  The first two
1160 elements of the list must be the I<numeric> uid and gid, in that
1161 order.  A value of -1 in either position is interpreted by most
1162 systems to leave that value unchanged.  Returns the number of files
1163 successfully changed.
1164
1165     my $cnt = chown $uid, $gid, 'foo', 'bar';
1166     chown $uid, $gid, @filenames;
1167
1168 On systems that support L<fchown(2)>, you may pass filehandles among the
1169 files.  On systems that don't support L<fchown(2)>, passing filehandles raises
1170 an exception.  Filehandles must be passed as globs or glob references to be
1171 recognized; barewords are considered filenames.
1172
1173 Here's an example that looks up nonnumeric uids in the passwd file:
1174
1175     print "User: ";
1176     chomp(my $user = <STDIN>);
1177     print "Files: ";
1178     chomp(my $pattern = <STDIN>);
1179
1180     my ($login,$pass,$uid,$gid) = getpwnam($user)
1181         or die "$user not in passwd file";
1182
1183     my @ary = glob($pattern);  # expand filenames
1184     chown $uid, $gid, @ary;
1185
1186 On most systems, you are not allowed to change the ownership of the
1187 file unless you're the superuser, although you should be able to change
1188 the group to any of your secondary groups.  On insecure systems, these
1189 restrictions may be relaxed, but this is not a portable assumption.
1190 On POSIX systems, you can detect this condition this way:
1191
1192     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
1193     my $can_chown_giveaway = ! sysconf(_PC_CHOWN_RESTRICTED);
1194
1195 Portability issues: L<perlport/chown>.
1196
1197 =item chr NUMBER
1198 X<chr> X<character> X<ASCII> X<Unicode>
1199
1200 =item chr
1201
1202 =for Pod::Functions get character this number represents
1203
1204 Returns the character represented by that NUMBER in the character set.
1205 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
1206 chr(0x263a) is a Unicode smiley face.
1207
1208 Negative values give the Unicode replacement character (chr(0xfffd)),
1209 except under the L<bytes> pragma, where the low eight bits of the value
1210 (truncated to an integer) are used.
1211
1212 If NUMBER is omitted, uses L<C<$_>|perlvar/$_>.
1213
1214 For the reverse, use L<C<ord>|/ord EXPR>.
1215
1216 Note that characters from 128 to 255 (inclusive) are by default
1217 internally not encoded as UTF-8 for backward compatibility reasons.
1218
1219 See L<perlunicode> for more about Unicode.
1220
1221 =item chroot FILENAME
1222 X<chroot> X<root>
1223
1224 =item chroot
1225
1226 =for Pod::Functions make directory new root for path lookups
1227
1228 This function works like the system call by the same name: it makes the
1229 named directory the new root directory for all further pathnames that
1230 begin with a C</> by your process and all its children.  (It doesn't
1231 change your current working directory, which is unaffected.)  For security
1232 reasons, this call is restricted to the superuser.  If FILENAME is
1233 omitted, does a L<C<chroot>|/chroot FILENAME> to L<C<$_>|perlvar/$_>.
1234
1235 B<NOTE:>  It is mandatory for security to C<chdir("/")>
1236 (L<C<chdir>|/chdir EXPR> to the root directory) immediately after a
1237 L<C<chroot>|/chroot FILENAME>, otherwise the current working directory
1238 may be outside of the new root.
1239
1240 Portability issues: L<perlport/chroot>.
1241
1242 =item close FILEHANDLE
1243 X<close>
1244
1245 =item close
1246
1247 =for Pod::Functions close file (or pipe or socket) handle
1248
1249 Closes the file or pipe associated with the filehandle, flushes the IO
1250 buffers, and closes the system file descriptor.  Returns true if those
1251 operations succeed and if no error was reported by any PerlIO
1252 layer.  Closes the currently selected filehandle if the argument is
1253 omitted.
1254
1255 You don't have to close FILEHANDLE if you are immediately going to do
1256 another L<C<open>|/open FILEHANDLE,MODE,EXPR> on it, because
1257 L<C<open>|/open FILEHANDLE,MODE,EXPR> closes it for you.  (See
1258 L<C<open>|/open FILEHANDLE,MODE,EXPR>.) However, an explicit
1259 L<C<close>|/close FILEHANDLE> on an input file resets the line counter
1260 (L<C<$.>|perlvar/$.>), while the implicit close done by
1261 L<C<open>|/open FILEHANDLE,MODE,EXPR> does not.
1262
1263 If the filehandle came from a piped open, L<C<close>|/close FILEHANDLE>
1264 returns false if one of the other syscalls involved fails or if its
1265 program exits with non-zero status.  If the only problem was that the
1266 program exited non-zero, L<C<$!>|perlvar/$!> will be set to C<0>.
1267 Closing a pipe also waits for the process executing on the pipe to
1268 exit--in case you wish to look at the output of the pipe afterwards--and
1269 implicitly puts the exit status value of that command into
1270 L<C<$?>|perlvar/$?> and
1271 L<C<${^CHILD_ERROR_NATIVE}>|perlvar/${^CHILD_ERROR_NATIVE}>.
1272
1273 If there are multiple threads running, L<C<close>|/close FILEHANDLE> on
1274 a filehandle from a piped open returns true without waiting for the
1275 child process to terminate, if the filehandle is still open in another
1276 thread.
1277
1278 Closing the read end of a pipe before the process writing to it at the
1279 other end is done writing results in the writer receiving a SIGPIPE.  If
1280 the other end can't handle that, be sure to read all the data before
1281 closing the pipe.
1282
1283 Example:
1284
1285     open(OUTPUT, '|sort >foo')  # pipe to sort
1286         or die "Can't start sort: $!";
1287     #...                        # print stuff to output
1288     close OUTPUT                # wait for sort to finish
1289         or warn $! ? "Error closing sort pipe: $!"
1290                    : "Exit status $? from sort";
1291     open(INPUT, 'foo')          # get sort's results
1292         or die "Can't open 'foo' for input: $!";
1293
1294 FILEHANDLE may be an expression whose value can be used as an indirect
1295 filehandle, usually the real filehandle name or an autovivified handle.
1296
1297 =item closedir DIRHANDLE
1298 X<closedir>
1299
1300 =for Pod::Functions close directory handle
1301
1302 Closes a directory opened by L<C<opendir>|/opendir DIRHANDLE,EXPR> and
1303 returns the success of that system call.
1304
1305 =item connect SOCKET,NAME
1306 X<connect>
1307
1308 =for Pod::Functions connect to a remote socket
1309
1310 Attempts to connect to a remote socket, just like L<connect(2)>.
1311 Returns true if it succeeded, false otherwise.  NAME should be a
1312 packed address of the appropriate type for the socket.  See the examples in
1313 L<perlipc/"Sockets: Client/Server Communication">.
1314
1315 =item continue BLOCK
1316 X<continue>
1317
1318 =item continue
1319
1320 =for Pod::Functions optional trailing block in a while or foreach
1321
1322 When followed by a BLOCK, L<C<continue>|/continue BLOCK> is actually a
1323 flow control statement rather than a function.  If there is a
1324 L<C<continue>|/continue BLOCK> BLOCK attached to a BLOCK (typically in a
1325 C<while> or C<foreach>), it is always executed just before the
1326 conditional is about to be evaluated again, just like the third part of
1327 a C<for> loop in C.  Thus it can be used to increment a loop variable,
1328 even when the loop has been continued via the L<C<next>|/next LABEL>
1329 statement (which is similar to the C L<C<continue>|/continue BLOCK>
1330 statement).
1331
1332 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, or
1333 L<C<redo>|/redo LABEL> may appear within a
1334 L<C<continue>|/continue BLOCK> block; L<C<last>|/last LABEL> and
1335 L<C<redo>|/redo LABEL> behave as if they had been executed within the
1336 main block.  So will L<C<next>|/next LABEL>, but since it will execute a
1337 L<C<continue>|/continue BLOCK> block, it may be more entertaining.
1338
1339     while (EXPR) {
1340         ### redo always comes here
1341         do_something;
1342     } continue {
1343         ### next always comes here
1344         do_something_else;
1345         # then back the top to re-check EXPR
1346     }
1347     ### last always comes here
1348
1349 Omitting the L<C<continue>|/continue BLOCK> section is equivalent to
1350 using an empty one, logically enough, so L<C<next>|/next LABEL> goes
1351 directly back to check the condition at the top of the loop.
1352
1353 When there is no BLOCK, L<C<continue>|/continue BLOCK> is a function
1354 that falls through the current C<when> or C<default> block instead of
1355 iterating a dynamically enclosing C<foreach> or exiting a lexically
1356 enclosing C<given>.  In Perl 5.14 and earlier, this form of
1357 L<C<continue>|/continue BLOCK> was only available when the
1358 L<C<"switch"> feature|feature/The 'switch' feature> was enabled.  See
1359 L<feature> and L<perlsyn/"Switch Statements"> for more information.
1360
1361 =item cos EXPR
1362 X<cos> X<cosine> X<acos> X<arccosine>
1363
1364 =item cos
1365
1366 =for Pod::Functions cosine function
1367
1368 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1369 takes the cosine of L<C<$_>|perlvar/$_>.
1370
1371 For the inverse cosine operation, you may use the
1372 L<C<Math::Trig::acos>|Math::Trig> function, or use this relation:
1373
1374     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1375
1376 =item crypt PLAINTEXT,SALT
1377 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1378 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1379
1380 =for Pod::Functions one-way passwd-style encryption
1381
1382 Creates a digest string exactly like the L<crypt(3)> function in the C
1383 library (assuming that you actually have a version there that has not
1384 been extirpated as a potential munition).
1385
1386 L<C<crypt>|/crypt PLAINTEXT,SALT> is a one-way hash function.  The
1387 PLAINTEXT and SALT are turned
1388 into a short string, called a digest, which is returned.  The same
1389 PLAINTEXT and SALT will always return the same string, but there is no
1390 (known) way to get the original PLAINTEXT from the hash.  Small
1391 changes in the PLAINTEXT or SALT will result in large changes in the
1392 digest.
1393
1394 There is no decrypt function.  This function isn't all that useful for
1395 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1396 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1397 primarily used to check if two pieces of text are the same without
1398 having to transmit or store the text itself.  An example is checking
1399 if a correct password is given.  The digest of the password is stored,
1400 not the password itself.  The user types in a password that is
1401 L<C<crypt>|/crypt PLAINTEXT,SALT>'d with the same salt as the stored
1402 digest.  If the two digests match, the password is correct.
1403
1404 When verifying an existing digest string you should use the digest as
1405 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1406 to create the digest is visible as part of the digest.  This ensures
1407 L<C<crypt>|/crypt PLAINTEXT,SALT> will hash the new string with the same
1408 salt as the digest.  This allows your code to work with the standard
1409 L<C<crypt>|/crypt PLAINTEXT,SALT> and with more exotic implementations.
1410 In other words, assume nothing about the returned string itself nor
1411 about how many bytes of SALT may matter.
1412
1413 Traditionally the result is a string of 13 bytes: two first bytes of
1414 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1415 the first eight bytes of PLAINTEXT mattered.  But alternative
1416 hashing schemes (like MD5), higher level security schemes (like C2),
1417 and implementations on non-Unix platforms may produce different
1418 strings.
1419
1420 When choosing a new salt create a random two character string whose
1421 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1422 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1423 characters is just a recommendation; the characters allowed in
1424 the salt depend solely on your system's crypt library, and Perl can't
1425 restrict what salts L<C<crypt>|/crypt PLAINTEXT,SALT> accepts.
1426
1427 Here's an example that makes sure that whoever runs this program knows
1428 their password:
1429
1430     my $pwd = (getpwuid($<))[1];
1431
1432     system "stty -echo";
1433     print "Password: ";
1434     chomp(my $word = <STDIN>);
1435     print "\n";
1436     system "stty echo";
1437
1438     if (crypt($word, $pwd) ne $pwd) {
1439         die "Sorry...\n";
1440     } else {
1441         print "ok\n";
1442     }
1443
1444 Of course, typing in your own password to whoever asks you
1445 for it is unwise.
1446
1447 The L<C<crypt>|/crypt PLAINTEXT,SALT> function is unsuitable for hashing
1448 large quantities of data, not least of all because you can't get the
1449 information back.  Look at the L<Digest> module for more robust
1450 algorithms.
1451
1452 If using L<C<crypt>|/crypt PLAINTEXT,SALT> on a Unicode string (which
1453 I<potentially> has characters with codepoints above 255), Perl tries to
1454 make sense of the situation by trying to downgrade (a copy of) the
1455 string back to an eight-bit byte string before calling
1456 L<C<crypt>|/crypt PLAINTEXT,SALT> (on that copy).  If that works, good.
1457 If not, L<C<crypt>|/crypt PLAINTEXT,SALT> dies with
1458 L<C<Wide character in crypt>|perldiag/Wide character in %s>.
1459
1460 Portability issues: L<perlport/crypt>.
1461
1462 =item dbmclose HASH
1463 X<dbmclose>
1464
1465 =for Pod::Functions breaks binding on a tied dbm file
1466
1467 [This function has been largely superseded by the
1468 L<C<untie>|/untie VARIABLE> function.]
1469
1470 Breaks the binding between a DBM file and a hash.
1471
1472 Portability issues: L<perlport/dbmclose>.
1473
1474 =item dbmopen HASH,DBNAME,MASK
1475 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1476
1477 =for Pod::Functions create binding on a tied dbm file
1478
1479 [This function has been largely superseded by the
1480 L<C<tie>|/tie VARIABLE,CLASSNAME,LIST> function.]
1481
1482 This binds a L<dbm(3)>, L<ndbm(3)>, L<sdbm(3)>, L<gdbm(3)>, or Berkeley
1483 DB file to a hash.  HASH is the name of the hash.  (Unlike normal
1484 L<C<open>|/open FILEHANDLE,MODE,EXPR>, the first argument is I<not> a
1485 filehandle, even though it looks like one).  DBNAME is the name of the
1486 database (without the F<.dir> or F<.pag> extension if any).  If the
1487 database does not exist, it is created with protection specified by MASK
1488 (as modified by the L<C<umask>|/umask EXPR>).  To prevent creation of
1489 the database if it doesn't exist, you may specify a MODE of 0, and the
1490 function will return a false value if it can't find an existing
1491 database.  If your system supports only the older DBM functions, you may
1492 make only one L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> call in your
1493 program.  In older versions of Perl, if your system had neither DBM nor
1494 ndbm, calling L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK> produced a fatal
1495 error; it now falls back to L<sdbm(3)>.
1496
1497 If you don't have write access to the DBM file, you can only read hash
1498 variables, not set them.  If you want to test whether you can write,
1499 either use file tests or try setting a dummy hash entry inside an
1500 L<C<eval>|/eval EXPR> to trap the error.
1501
1502 Note that functions such as L<C<keys>|/keys HASH> and
1503 L<C<values>|/values HASH> may return huge lists when used on large DBM
1504 files.  You may prefer to use the L<C<each>|/each HASH> function to
1505 iterate over large DBM files.  Example:
1506
1507     # print out history file offsets
1508     dbmopen(%HIST,'/usr/lib/news/history',0666);
1509     while (($key,$val) = each %HIST) {
1510         print $key, ' = ', unpack('L',$val), "\n";
1511     }
1512     dbmclose(%HIST);
1513
1514 See also L<AnyDBM_File> for a more general description of the pros and
1515 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1516 rich implementation.
1517
1518 You can control which DBM library you use by loading that library
1519 before you call L<C<dbmopen>|/dbmopen HASH,DBNAME,MASK>:
1520
1521     use DB_File;
1522     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1523         or die "Can't open netscape history file: $!";
1524
1525 Portability issues: L<perlport/dbmopen>.
1526
1527 =item defined EXPR
1528 X<defined> X<undef> X<undefined>
1529
1530 =item defined
1531
1532 =for Pod::Functions test whether a value, variable, or function is defined
1533
1534 Returns a Boolean value telling whether EXPR has a value other than the
1535 undefined value L<C<undef>|/undef EXPR>.  If EXPR is not present,
1536 L<C<$_>|perlvar/$_> is checked.
1537
1538 Many operations return L<C<undef>|/undef EXPR> to indicate failure, end
1539 of file, system error, uninitialized variable, and other exceptional
1540 conditions.  This function allows you to distinguish
1541 L<C<undef>|/undef EXPR> from other values.  (A simple Boolean test will
1542 not distinguish among L<C<undef>|/undef EXPR>, zero, the empty string,
1543 and C<"0">, which are all equally false.)  Note that since
1544 L<C<undef>|/undef EXPR> is a valid scalar, its presence doesn't
1545 I<necessarily> indicate an exceptional condition: L<C<pop>|/pop ARRAY>
1546 returns L<C<undef>|/undef EXPR> when its argument is an empty array,
1547 I<or> when the element to return happens to be L<C<undef>|/undef EXPR>.
1548
1549 You may also use C<defined(&func)> to check whether subroutine C<func>
1550 has ever been defined.  The return value is unaffected by any forward
1551 declarations of C<func>.  A subroutine that is not defined
1552 may still be callable: its package may have an C<AUTOLOAD> method that
1553 makes it spring into existence the first time that it is called; see
1554 L<perlsub>.
1555
1556 Use of L<C<defined>|/defined EXPR> on aggregates (hashes and arrays) is
1557 no longer supported. It used to report whether memory for that
1558 aggregate had ever been allocated.  You should instead use a simple
1559 test for size:
1560
1561     if (@an_array) { print "has array elements\n" }
1562     if (%a_hash)   { print "has hash members\n"   }
1563
1564 When used on a hash element, it tells you whether the value is defined,
1565 not whether the key exists in the hash.  Use L<C<exists>|/exists EXPR>
1566 for the latter purpose.
1567
1568 Examples:
1569
1570     print if defined $switch{D};
1571     print "$val\n" while defined($val = pop(@ary));
1572     die "Can't readlink $sym: $!"
1573         unless defined($value = readlink $sym);
1574     sub foo { defined &$bar ? $bar->(@_) : die "No bar"; }
1575     $debugging = 0 unless defined $debugging;
1576
1577 Note:  Many folks tend to overuse L<C<defined>|/defined EXPR> and are
1578 then surprised to discover that the number C<0> and C<""> (the
1579 zero-length string) are, in fact, defined values.  For example, if you
1580 say
1581
1582     "ab" =~ /a(.*)b/;
1583
1584 The pattern match succeeds and C<$1> is defined, although it
1585 matched "nothing".  It didn't really fail to match anything.  Rather, it
1586 matched something that happened to be zero characters long.  This is all
1587 very above-board and honest.  When a function returns an undefined value,
1588 it's an admission that it couldn't give you an honest answer.  So you
1589 should use L<C<defined>|/defined EXPR> only when questioning the
1590 integrity of what you're trying to do.  At other times, a simple
1591 comparison to C<0> or C<""> is what you want.
1592
1593 See also L<C<undef>|/undef EXPR>, L<C<exists>|/exists EXPR>,
1594 L<C<ref>|/ref EXPR>.
1595
1596 =item delete EXPR
1597 X<delete>
1598
1599 =for Pod::Functions deletes a value from a hash
1600
1601 Given an expression that specifies an element or slice of a hash,
1602 L<C<delete>|/delete EXPR> deletes the specified elements from that hash
1603 so that L<C<exists>|/exists EXPR> on that element no longer returns
1604 true.  Setting a hash element to the undefined value does not remove its
1605 key, but deleting it does; see L<C<exists>|/exists EXPR>.
1606
1607 In list context, usually returns the value or values deleted, or the last such
1608 element in scalar context.  The return list's length corresponds to that of
1609 the argument list: deleting non-existent elements returns the undefined value
1610 in their corresponding positions. When a
1611 L<keyE<sol>value hash slice|perldata/KeyE<sol>Value Hash Slices> is passed to
1612 C<delete>, the return value is a list of key/value pairs (two elements for each
1613 item deleted from the hash).
1614
1615 L<C<delete>|/delete EXPR> may also be used on arrays and array slices,
1616 but its behavior is less straightforward.  Although
1617 L<C<exists>|/exists EXPR> will return false for deleted entries,
1618 deleting array elements never changes indices of existing values; use
1619 L<C<shift>|/shift ARRAY> or L<C<splice>|/splice
1620 ARRAY,OFFSET,LENGTH,LIST> for that.  However, if any deleted elements
1621 fall at the end of an array, the array's size shrinks to the position of
1622 the highest element that still tests true for L<C<exists>|/exists EXPR>,
1623 or to 0 if none do.  In other words, an array won't have trailing
1624 nonexistent elements after a delete.
1625
1626 B<WARNING:> Calling L<C<delete>|/delete EXPR> on array values is
1627 strongly discouraged.  The
1628 notion of deleting or checking the existence of Perl array elements is not
1629 conceptually coherent, and can lead to surprising behavior.
1630
1631 Deleting from L<C<%ENV>|perlvar/%ENV> modifies the environment.
1632 Deleting from a hash tied to a DBM file deletes the entry from the DBM
1633 file.  Deleting from a L<C<tied>|/tied VARIABLE> hash or array may not
1634 necessarily return anything; it depends on the implementation of the
1635 L<C<tied>|/tied VARIABLE> package's DELETE method, which may do whatever
1636 it pleases.
1637
1638 The C<delete local EXPR> construct localizes the deletion to the current
1639 block at run time.  Until the block exits, elements locally deleted
1640 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1641 of composite types">.
1642
1643     my %hash = (foo => 11, bar => 22, baz => 33);
1644     my $scalar = delete $hash{foo};         # $scalar is 11
1645     $scalar = delete @hash{qw(foo bar)}; # $scalar is 22
1646     my @array  = delete @hash{qw(foo baz)}; # @array  is (undef,33)
1647
1648 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1649
1650     foreach my $key (keys %HASH) {
1651         delete $HASH{$key};
1652     }
1653
1654     foreach my $index (0 .. $#ARRAY) {
1655         delete $ARRAY[$index];
1656     }
1657
1658 And so do these:
1659
1660     delete @HASH{keys %HASH};
1661
1662     delete @ARRAY[0 .. $#ARRAY];
1663
1664 But both are slower than assigning the empty list
1665 or undefining %HASH or @ARRAY, which is the customary
1666 way to empty out an aggregate:
1667
1668     %HASH = ();     # completely empty %HASH
1669     undef %HASH;    # forget %HASH ever existed
1670
1671     @ARRAY = ();    # completely empty @ARRAY
1672     undef @ARRAY;   # forget @ARRAY ever existed
1673
1674 The EXPR can be arbitrarily complicated provided its
1675 final operation is an element or slice of an aggregate:
1676
1677     delete $ref->[$x][$y]{$key};
1678     delete $ref->[$x][$y]->@{$key1, $key2, @morekeys};
1679
1680     delete $ref->[$x][$y][$index];
1681     delete $ref->[$x][$y]->@[$index1, $index2, @moreindices];
1682
1683 =item die LIST
1684 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1685
1686 =for Pod::Functions raise an exception or bail out
1687
1688 L<C<die>|/die LIST> raises an exception.  Inside an L<C<eval>|/eval EXPR>
1689 the exception is stuffed into L<C<$@>|perlvar/$@> and the L<C<eval>|/eval
1690 EXPR> is terminated with the undefined value.  If the exception is
1691 outside of all enclosing L<C<eval>|/eval EXPR>s, then the uncaught
1692 exception is printed to C<STDERR> and perl exits with an exit code
1693 indicating failure.  If you need to exit the process with a specific
1694 exit code, see L<C<exit>|/exit EXPR>.
1695
1696 Equivalent examples:
1697
1698     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1699     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1700
1701 Most of the time, C<die> is called with a string to use as the exception.
1702 You may either give a single non-reference operand to serve as the
1703 exception, or a list of two or more items, which will be stringified
1704 and concatenated to make the exception.
1705
1706 If the string exception does not end in a newline, the current
1707 script line number and input line number (if any) and a newline
1708 are appended to it.  Note that the "input line number" (also
1709 known as "chunk") is subject to whatever notion of "line" happens to
1710 be currently in effect, and is also available as the special variable
1711 L<C<$.>|perlvar/$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1712
1713 Hint: sometimes appending C<", stopped"> to your message will cause it
1714 to make better sense when the string C<"at foo line 123"> is appended.
1715 Suppose you are running script "canasta".
1716
1717     die "/etc/games is no good";
1718     die "/etc/games is no good, stopped";
1719
1720 produce, respectively
1721
1722     /etc/games is no good at canasta line 123.
1723     /etc/games is no good, stopped at canasta line 123.
1724
1725 If LIST was empty or made an empty string, and L<C<$@>|perlvar/$@>
1726 already contains an exception value (typically from a previous
1727 L<C<eval>|/eval EXPR>), then that value is reused after
1728 appending C<"\t...propagated">.  This is useful for propagating exceptions:
1729
1730     eval { ... };
1731     die unless $@ =~ /Expected exception/;
1732
1733 If LIST was empty or made an empty string,
1734 and L<C<$@>|perlvar/$@> contains an object
1735 reference that has a C<PROPAGATE> method, that method will be called
1736 with additional file and line number parameters.  The return value
1737 replaces the value in L<C<$@>|perlvar/$@>;  i.e., as if
1738 C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >> were called.
1739
1740 If LIST was empty or made an empty string, and L<C<$@>|perlvar/$@>
1741 is also empty, then the string C<"Died"> is used.
1742
1743 You can also call L<C<die>|/die LIST> with a reference argument, and if
1744 this is trapped within an L<C<eval>|/eval EXPR>, L<C<$@>|perlvar/$@>
1745 contains that reference.  This permits more elaborate exception handling
1746 using objects that maintain arbitrary state about the exception.  Such a
1747 scheme is sometimes preferable to matching particular string values of
1748 L<C<$@>|perlvar/$@> with regular expressions.
1749
1750 Because Perl stringifies uncaught exception messages before display,
1751 you'll probably want to overload stringification operations on
1752 exception objects.  See L<overload> for details about that.
1753 The stringified message should be non-empty, and should end in a newline,
1754 in order to fit in with the treatment of string exceptions.
1755 Also, because an exception object reference cannot be stringified
1756 without destroying it, Perl doesn't attempt to append location or other
1757 information to a reference exception.  If you want location information
1758 with a complex exception object, you'll have to arrange to put the
1759 location information into the object yourself.
1760
1761 Because L<C<$@>|perlvar/$@> is a global variable, be careful that
1762 analyzing an exception caught by C<eval> doesn't replace the reference
1763 in the global variable.  It's
1764 easiest to make a local copy of the reference before any manipulations.
1765 Here's an example:
1766
1767     use Scalar::Util "blessed";
1768
1769     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1770     if (my $ev_err = $@) {
1771         if (blessed($ev_err)
1772             && $ev_err->isa("Some::Module::Exception")) {
1773             # handle Some::Module::Exception
1774         }
1775         else {
1776             # handle all other possible exceptions
1777         }
1778     }
1779
1780 If an uncaught exception results in interpreter exit, the exit code is
1781 determined from the values of L<C<$!>|perlvar/$!> and
1782 L<C<$?>|perlvar/$?> with this pseudocode:
1783
1784     exit $! if $!;              # errno
1785     exit $? >> 8 if $? >> 8;    # child exit status
1786     exit 255;                   # last resort
1787
1788 As with L<C<exit>|/exit EXPR>, L<C<$?>|perlvar/$?> is set prior to
1789 unwinding the call stack; any C<DESTROY> or C<END> handlers can then
1790 alter this value, and thus Perl's exit code.
1791
1792 The intent is to squeeze as much possible information about the likely cause
1793 into the limited space of the system exit code.  However, as
1794 L<C<$!>|perlvar/$!> is the value of C's C<errno>, which can be set by
1795 any system call, this means that the value of the exit code used by
1796 L<C<die>|/die LIST> can be non-predictable, so should not be relied
1797 upon, other than to be non-zero.
1798
1799 You can arrange for a callback to be run just before the
1800 L<C<die>|/die LIST> does its deed, by setting the
1801 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook.  The associated handler is called
1802 with the exception as an argument, and can change the exception,
1803 if it sees fit, by
1804 calling L<C<die>|/die LIST> again.  See L<perlvar/%SIG> for details on
1805 setting L<C<%SIG>|perlvar/%SIG> entries, and L<C<eval>|/eval EXPR> for some
1806 examples.  Although this feature was to be run only right before your
1807 program was to exit, this is not currently so: the
1808 L<C<$SIG{__DIE__}>|perlvar/%SIG> hook is currently called even inside
1809 L<C<eval>|/eval EXPR>ed blocks/strings!  If one wants the hook to do
1810 nothing in such situations, put
1811
1812     die @_ if $^S;
1813
1814 as the first line of the handler (see L<perlvar/$^S>).  Because
1815 this promotes strange action at a distance, this counterintuitive
1816 behavior may be fixed in a future release.
1817
1818 See also L<C<exit>|/exit EXPR>, L<C<warn>|/warn LIST>, and the L<Carp>
1819 module.
1820
1821 =item do BLOCK
1822 X<do> X<block>
1823
1824 =for Pod::Functions turn a BLOCK into a TERM
1825
1826 Not really a function.  Returns the value of the last command in the
1827 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1828 C<until> loop modifier, executes the BLOCK once before testing the loop
1829 condition.  (On other statements the loop modifiers test the conditional
1830 first.)
1831
1832 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1833 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
1834 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
1835 See L<perlsyn> for alternative strategies.
1836
1837 =item do EXPR
1838 X<do>
1839
1840 Uses the value of EXPR as a filename and executes the contents of the
1841 file as a Perl script:
1842
1843     # load the exact specified file (./ and ../ special-cased)
1844     do '/foo/stat.pl';
1845     do './stat.pl';
1846     do '../foo/stat.pl';
1847
1848     # search for the named file within @INC
1849     do 'stat.pl';
1850     do 'foo/stat.pl';
1851
1852 C<do './stat.pl'> is largely like
1853
1854     eval `cat stat.pl`;
1855
1856 except that it's more concise, runs no external processes, and keeps
1857 track of the current filename for error messages. It also differs in that
1858 code evaluated with C<do FILE> cannot see lexicals in the enclosing
1859 scope; C<eval STRING> does.  It's the same, however, in that it does
1860 reparse the file every time you call it, so you probably don't want
1861 to do this inside a loop.
1862
1863 Using C<do> with a relative path (except for F<./> and F<../>), like
1864
1865     do 'foo/stat.pl';
1866
1867 will search the L<C<@INC>|perlvar/@INC> directories, and update
1868 L<C<%INC>|perlvar/%INC> if the file is found.  See L<perlvar/@INC>
1869 and L<perlvar/%INC> for these variables. In particular, note that
1870 whilst historically L<C<@INC>|perlvar/@INC> contained '.' (the
1871 current directory) making these two cases equivalent, that is no
1872 longer necessarily the case, as '.' is not included in C<@INC> by default
1873 in perl versions 5.26.0 onwards. Instead, perl will now warn:
1874
1875     do "stat.pl" failed, '.' is no longer in @INC;
1876     did you mean do "./stat.pl"?
1877
1878 If L<C<do>|/do EXPR> can read the file but cannot compile it, it
1879 returns L<C<undef>|/undef EXPR> and sets an error message in
1880 L<C<$@>|perlvar/$@>.  If L<C<do>|/do EXPR> cannot read the file, it
1881 returns undef and sets L<C<$!>|perlvar/$!> to the error.  Always check
1882 L<C<$@>|perlvar/$@> first, as compilation could fail in a way that also
1883 sets L<C<$!>|perlvar/$!>.  If the file is successfully compiled,
1884 L<C<do>|/do EXPR> returns the value of the last expression evaluated.
1885
1886 Inclusion of library modules is better done with the
1887 L<C<use>|/use Module VERSION LIST> and L<C<require>|/require VERSION>
1888 operators, which also do automatic error checking and raise an exception
1889 if there's a problem.
1890
1891 You might like to use L<C<do>|/do EXPR> to read in a program
1892 configuration file.  Manual error checking can be done this way:
1893
1894     # Read in config files: system first, then user.
1895     # Beware of using relative pathnames here.
1896     for $file ("/share/prog/defaults.rc",
1897                "$ENV{HOME}/.someprogrc")
1898     {
1899         unless ($return = do $file) {
1900             warn "couldn't parse $file: $@" if $@;
1901             warn "couldn't do $file: $!"    unless defined $return;
1902             warn "couldn't run $file"       unless $return;
1903         }
1904     }
1905
1906 =item dump LABEL
1907 X<dump> X<core> X<undump>
1908
1909 =item dump EXPR
1910
1911 =item dump
1912
1913 =for Pod::Functions create an immediate core dump
1914
1915 This function causes an immediate core dump.  See also the B<-u>
1916 command-line switch in L<perlrun|perlrun/-u>, which does the same thing.
1917 Primarily this is so that you can use the B<undump> program (not
1918 supplied) to turn your core dump into an executable binary after
1919 having initialized all your variables at the beginning of the
1920 program.  When the new binary is executed it will begin by executing
1921 a C<goto LABEL> (with all the restrictions that L<C<goto>|/goto LABEL>
1922 suffers).
1923 Think of it as a goto with an intervening core dump and reincarnation.
1924 If C<LABEL> is omitted, restarts the program from the top.  The
1925 C<dump EXPR> form, available starting in Perl 5.18.0, allows a name to be
1926 computed at run time, being otherwise identical to C<dump LABEL>.
1927
1928 B<WARNING>: Any files opened at the time of the dump will I<not>
1929 be open any more when the program is reincarnated, with possible
1930 resulting confusion by Perl.
1931
1932 This function is now largely obsolete, mostly because it's very hard to
1933 convert a core file into an executable.  As of Perl 5.30, it must be invoked
1934 as C<CORE::dump()>.
1935
1936 Unlike most named operators, this has the same precedence as assignment.
1937 It is also exempt from the looks-like-a-function rule, so
1938 C<dump ("foo")."bar"> will cause "bar" to be part of the argument to
1939 L<C<dump>|/dump LABEL>.
1940
1941 Portability issues: L<perlport/dump>.
1942
1943 =item each HASH
1944 X<each> X<hash, iterator>
1945
1946 =item each ARRAY
1947 X<array, iterator>
1948
1949 =for Pod::Functions retrieve the next key/value pair from a hash
1950
1951 When called on a hash in list context, returns a 2-element list
1952 consisting of the key and value for the next element of a hash.  In Perl
1953 5.12 and later only, it will also return the index and value for the next
1954 element of an array so that you can iterate over it; older Perls consider
1955 this a syntax error.  When called in scalar context, returns only the key
1956 (not the value) in a hash, or the index in an array.
1957
1958 Hash entries are returned in an apparently random order.  The actual random
1959 order is specific to a given hash; the exact same series of operations
1960 on two hashes may result in a different order for each hash.  Any insertion
1961 into the hash may change the order, as will any deletion, with the exception
1962 that the most recent key returned by L<C<each>|/each HASH> or
1963 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
1964 long as a given hash is unmodified you may rely on
1965 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and
1966 L<C<each>|/each HASH> to repeatedly return the same order
1967 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
1968 details on why hash order is randomized.  Aside from the guarantees
1969 provided here the exact details of Perl's hash algorithm and the hash
1970 traversal order are subject to change in any release of Perl.
1971
1972 After L<C<each>|/each HASH> has returned all entries from the hash or
1973 array, the next call to L<C<each>|/each HASH> returns the empty list in
1974 list context and L<C<undef>|/undef EXPR> in scalar context; the next
1975 call following I<that> one restarts iteration.  Each hash or array has
1976 its own internal iterator, accessed by L<C<each>|/each HASH>,
1977 L<C<keys>|/keys HASH>, and L<C<values>|/values HASH>.  The iterator is
1978 implicitly reset when L<C<each>|/each HASH> has reached the end as just
1979 described; it can be explicitly reset by calling L<C<keys>|/keys HASH>
1980 or L<C<values>|/values HASH> on the hash or array, or by referencing
1981 the hash (but not array) in list context.  If you add or delete
1982 a hash's elements while iterating over it, the effect on the iterator is
1983 unspecified; for example, entries may be skipped or duplicated--so don't
1984 do that.  Exception: It is always safe to delete the item most recently
1985 returned by L<C<each>|/each HASH>, so the following code works properly:
1986
1987     while (my ($key, $value) = each %hash) {
1988         print $key, "\n";
1989         delete $hash{$key};   # This is safe
1990     }
1991
1992 Tied hashes may have a different ordering behaviour to perl's hash
1993 implementation.
1994
1995 The iterator used by C<each> is attached to the hash or array, and is
1996 shared between all iteration operations applied to the same hash or array.
1997 Thus all uses of C<each> on a single hash or array advance the same
1998 iterator location.  All uses of C<each> are also subject to having the
1999 iterator reset by any use of C<keys> or C<values> on the same hash or
2000 array, or by the hash (but not array) being referenced in list context.
2001 This makes C<each>-based loops quite fragile: it is easy to arrive at
2002 such a loop with the iterator already part way through the object, or to
2003 accidentally clobber the iterator state during execution of the loop body.
2004 It's easy enough to explicitly reset the iterator before starting a loop,
2005 but there is no way to insulate the iterator state used by a loop from
2006 the iterator state used by anything else that might execute during the
2007 loop body.  To avoid these problems, use a C<foreach> loop rather than
2008 C<while>-C<each>.
2009
2010 This prints out your environment like the L<printenv(1)> program,
2011 but in a different order:
2012
2013     while (my ($key,$value) = each %ENV) {
2014         print "$key=$value\n";
2015     }
2016
2017 Starting with Perl 5.14, an experimental feature allowed
2018 L<C<each>|/each HASH> to take a scalar expression. This experiment has
2019 been deemed unsuccessful, and was removed as of Perl 5.24.
2020
2021 As of Perl 5.18 you can use a bare L<C<each>|/each HASH> in a C<while>
2022 loop, which will set L<C<$_>|perlvar/$_> on every iteration.
2023 If either an C<each> expression or an explicit assignment of an C<each>
2024 expression to a scalar is used as a C<while>/C<for> condition, then
2025 the condition actually tests for definedness of the expression's value,
2026 not for its regular truth value.
2027
2028     while (each %ENV) {
2029         print "$_=$ENV{$_}\n";
2030     }
2031
2032 To avoid confusing would-be users of your code who are running earlier
2033 versions of Perl with mysterious syntax errors, put this sort of thing at
2034 the top of your file to signal that your code will work I<only> on Perls of
2035 a recent vintage:
2036
2037     use 5.012;  # so keys/values/each work on arrays
2038     use 5.018;  # so each assigns to $_ in a lone while test
2039
2040 See also L<C<keys>|/keys HASH>, L<C<values>|/values HASH>, and
2041 L<C<sort>|/sort SUBNAME LIST>.
2042
2043 =item eof FILEHANDLE
2044 X<eof>
2045 X<end of file>
2046 X<end-of-file>
2047
2048 =item eof ()
2049
2050 =item eof
2051
2052 =for Pod::Functions test a filehandle for its end
2053
2054 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
2055 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
2056 gives the real filehandle.  (Note that this function actually
2057 reads a character and then C<ungetc>s it, so isn't useful in an
2058 interactive context.)  Do not read from a terminal file (or call
2059 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
2060 as terminals may lose the end-of-file condition if you do.
2061
2062 An L<C<eof>|/eof FILEHANDLE> without an argument uses the last file
2063 read.  Using L<C<eof()>|/eof FILEHANDLE> with empty parentheses is
2064 different.  It refers to the pseudo file formed from the files listed on
2065 the command line and accessed via the C<< <> >> operator.  Since
2066 C<< <> >> isn't explicitly opened, as a normal filehandle is, an
2067 L<C<eof()>|/eof FILEHANDLE> before C<< <> >> has been used will cause
2068 L<C<@ARGV>|perlvar/@ARGV> to be examined to determine if input is
2069 available.   Similarly, an L<C<eof()>|/eof FILEHANDLE> after C<< <> >>
2070 has returned end-of-file will assume you are processing another
2071 L<C<@ARGV>|perlvar/@ARGV> list, and if you haven't set
2072 L<C<@ARGV>|perlvar/@ARGV>, will read input from C<STDIN>; see
2073 L<perlop/"I/O Operators">.
2074
2075 In a C<< while (<>) >> loop, L<C<eof>|/eof FILEHANDLE> or C<eof(ARGV)>
2076 can be used to detect the end of each file, whereas
2077 L<C<eof()>|/eof FILEHANDLE> will detect the end of the very last file
2078 only.  Examples:
2079
2080     # reset line numbering on each input file
2081     while (<>) {
2082         next if /^\s*#/;  # skip comments
2083         print "$.\t$_";
2084     } continue {
2085         close ARGV if eof;  # Not eof()!
2086     }
2087
2088     # insert dashes just before last line of last file
2089     while (<>) {
2090         if (eof()) {  # check for end of last file
2091             print "--------------\n";
2092         }
2093         print;
2094         last if eof();     # needed if we're reading from a terminal
2095     }
2096
2097 Practical hint: you almost never need to use L<C<eof>|/eof FILEHANDLE>
2098 in Perl, because the input operators typically return L<C<undef>|/undef
2099 EXPR> when they run out of data or encounter an error.
2100
2101 =item eval EXPR
2102 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
2103 X<error, handling> X<exception, handling>
2104
2105 =item eval BLOCK
2106
2107 =item eval
2108
2109 =for Pod::Functions catch exceptions or compile and run code
2110
2111 C<eval> in all its forms is used to execute a little Perl program,
2112 trapping any errors encountered so they don't crash the calling program.
2113
2114 Plain C<eval> with no argument is just C<eval EXPR>, where the
2115 expression is understood to be contained in L<C<$_>|perlvar/$_>.  Thus
2116 there are only two real C<eval> forms; the one with an EXPR is often
2117 called "string eval".  In a string eval, the value of the expression
2118 (which is itself determined within scalar context) is first parsed, and
2119 if there were no errors, executed as a block within the lexical context
2120 of the current Perl program.  This form is typically used to delay
2121 parsing and subsequent execution of the text of EXPR until run time.
2122 Note that the value is parsed every time the C<eval> executes.
2123
2124 The other form is called "block eval".  It is less general than string
2125 eval, but the code within the BLOCK is parsed only once (at the same
2126 time the code surrounding the C<eval> itself was parsed) and executed
2127 within the context of the current Perl program.  This form is typically
2128 used to trap exceptions more efficiently than the first, while also
2129 providing the benefit of checking the code within BLOCK at compile time.
2130 BLOCK is parsed and compiled just once.  Since errors are trapped, it
2131 often is used to check if a given feature is available.
2132
2133 In both forms, the value returned is the value of the last expression
2134 evaluated inside the mini-program; a return statement may also be used, just
2135 as with subroutines.  The expression providing the return value is evaluated
2136 in void, scalar, or list context, depending on the context of the
2137 C<eval> itself.  See L<C<wantarray>|/wantarray> for more
2138 on how the evaluation context can be determined.
2139
2140 If there is a syntax error or runtime error, or a L<C<die>|/die LIST>
2141 statement is executed, C<eval> returns
2142 L<C<undef>|/undef EXPR> in scalar context, or an empty list in list
2143 context, and L<C<$@>|perlvar/$@> is set to the error message.  (Prior to
2144 5.16, a bug caused L<C<undef>|/undef EXPR> to be returned in list
2145 context for syntax errors, but not for runtime errors.) If there was no
2146 error, L<C<$@>|perlvar/$@> is set to the empty string.  A control flow
2147 operator like L<C<last>|/last LABEL> or L<C<goto>|/goto LABEL> can
2148 bypass the setting of L<C<$@>|perlvar/$@>.  Beware that using
2149 C<eval> neither silences Perl from printing warnings to
2150 STDERR, nor does it stuff the text of warning messages into
2151 L<C<$@>|perlvar/$@>.  To do either of those, you have to use the
2152 L<C<$SIG{__WARN__}>|perlvar/%SIG> facility, or turn off warnings inside
2153 the BLOCK or EXPR using S<C<no warnings 'all'>>.  See
2154 L<C<warn>|/warn LIST>, L<perlvar>, and L<warnings>.
2155
2156 Note that, because C<eval> traps otherwise-fatal errors,
2157 it is useful for determining whether a particular feature (such as
2158 L<C<socket>|/socket SOCKET,DOMAIN,TYPE,PROTOCOL> or
2159 L<C<symlink>|/symlink OLDFILE,NEWFILE>) is implemented.  It is also
2160 Perl's exception-trapping mechanism, where the L<C<die>|/die LIST>
2161 operator is used to raise exceptions.
2162
2163 Before Perl 5.14, the assignment to L<C<$@>|perlvar/$@> occurred before
2164 restoration
2165 of localized variables, which means that for your code to run on older
2166 versions, a temporary is required if you want to mask some, but not all
2167 errors:
2168
2169  # alter $@ on nefarious repugnancy only
2170  {
2171     my $e;
2172     {
2173       local $@; # protect existing $@
2174       eval { test_repugnancy() };
2175       # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
2176       $@ =~ /nefarious/ and $e = $@;
2177     }
2178     die $e if defined $e
2179  }
2180
2181 There are some different considerations for each form:
2182
2183 =over 4
2184
2185 =item String eval
2186
2187 Since the return value of EXPR is executed as a block within the lexical
2188 context of the current Perl program, any outer lexical variables are
2189 visible to it, and any package variable settings or subroutine and
2190 format definitions remain afterwards.
2191
2192 =over 4
2193
2194 =item Under the L<C<"unicode_eval"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2195
2196 If this feature is enabled (which is the default under a C<use 5.16> or
2197 higher declaration), EXPR is considered to be
2198 in the same encoding as the surrounding program.  Thus if
2199 S<L<C<use utf8>|utf8>> is in effect, the string will be treated as being
2200 UTF-8 encoded.  Otherwise, the string is considered to be a sequence of
2201 independent bytes.  Bytes that correspond to ASCII-range code points
2202 will have their normal meanings for operators in the string.  The
2203 treatment of the other bytes depends on if the
2204 L<C<'unicode_strings"> feature|feature/The 'unicode_strings' feature> is
2205 in effect.
2206
2207 In a plain C<eval> without an EXPR argument, being in S<C<use utf8>> or
2208 not is irrelevant; the UTF-8ness of C<$_> itself determines the
2209 behavior.
2210
2211 Any S<C<use utf8>> or S<C<no utf8>> declarations within the string have
2212 no effect, and source filters are forbidden.  (C<unicode_strings>,
2213 however, can appear within the string.)  See also the
2214 L<C<evalbytes>|/evalbytes EXPR> operator, which works properly with
2215 source filters.
2216
2217 Variables defined outside the C<eval> and used inside it retain their
2218 original UTF-8ness.  Everything inside the string follows the normal
2219 rules for a Perl program with the given state of S<C<use utf8>>.
2220
2221 =item Outside the C<"unicode_eval"> feature
2222
2223 In this case, the behavior is problematic and is not so easily
2224 described.  Here are two bugs that cannot easily be fixed without
2225 breaking existing programs:
2226
2227 =over 4
2228
2229 =item *
2230
2231 It can lose track of whether something should be encoded as UTF-8 or
2232 not.
2233
2234 =item *
2235
2236 Source filters activated within C<eval> leak out into whichever file
2237 scope is currently being compiled.  To give an example with the CPAN module
2238 L<Semi::Semicolons>:
2239
2240  BEGIN { eval "use Semi::Semicolons; # not filtered" }
2241  # filtered here!
2242
2243 L<C<evalbytes>|/evalbytes EXPR> fixes that to work the way one would
2244 expect:
2245
2246  use feature "evalbytes";
2247  BEGIN { evalbytes "use Semi::Semicolons; # filtered" }
2248  # not filtered
2249
2250 =back
2251
2252 =back
2253
2254 Problems can arise if the string expands a scalar containing a floating
2255 point number.  That scalar can expand to letters, such as C<"NaN"> or
2256 C<"Infinity">; or, within the scope of a L<C<use locale>|locale>, the
2257 decimal point character may be something other than a dot (such as a
2258 comma).  None of these are likely to parse as you are likely expecting.
2259
2260 You should be especially careful to remember what's being looked at
2261 when:
2262
2263     eval $x;        # CASE 1
2264     eval "$x";      # CASE 2
2265
2266     eval '$x';      # CASE 3
2267     eval { $x };    # CASE 4
2268
2269     eval "\$$x++";  # CASE 5
2270     $$x++;          # CASE 6
2271
2272 Cases 1 and 2 above behave identically: they run the code contained in
2273 the variable $x.  (Although case 2 has misleading double quotes making
2274 the reader wonder what else might be happening (nothing is).)  Cases 3
2275 and 4 likewise behave in the same way: they run the code C<'$x'>, which
2276 does nothing but return the value of $x.  (Case 4 is preferred for
2277 purely visual reasons, but it also has the advantage of compiling at
2278 compile-time instead of at run-time.)  Case 5 is a place where
2279 normally you I<would> like to use double quotes, except that in this
2280 particular situation, you can just use symbolic references instead, as
2281 in case 6.
2282
2283 An C<eval ''> executed within a subroutine defined
2284 in the C<DB> package doesn't see the usual
2285 surrounding lexical scope, but rather the scope of the first non-DB piece
2286 of code that called it.  You don't normally need to worry about this unless
2287 you are writing a Perl debugger.
2288
2289 The final semicolon, if any, may be omitted from the value of EXPR.
2290
2291 =item Block eval
2292
2293 If the code to be executed doesn't vary, you may use the eval-BLOCK
2294 form to trap run-time errors without incurring the penalty of
2295 recompiling each time.  The error, if any, is still returned in
2296 L<C<$@>|perlvar/$@>.
2297 Examples:
2298
2299     # make divide-by-zero nonfatal
2300     eval { $answer = $a / $b; }; warn $@ if $@;
2301
2302     # same thing, but less efficient
2303     eval '$answer = $a / $b'; warn $@ if $@;
2304
2305     # a compile-time error
2306     eval { $answer = }; # WRONG
2307
2308     # a run-time error
2309     eval '$answer =';   # sets $@
2310
2311 If you want to trap errors when loading an XS module, some problems with
2312 the binary interface (such as Perl version skew) may be fatal even with
2313 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See
2314 L<perlrun|perlrun/PERL_DL_NONLAZY>.
2315
2316 Using the C<eval {}> form as an exception trap in libraries does have some
2317 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
2318 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
2319 You can use the C<local $SIG{__DIE__}> construct for this purpose,
2320 as this example shows:
2321
2322     # a private exception trap for divide-by-zero
2323     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
2324     warn $@ if $@;
2325
2326 This is especially significant, given that C<__DIE__> hooks can call
2327 L<C<die>|/die LIST> again, which has the effect of changing their error
2328 messages:
2329
2330     # __DIE__ hooks may modify error messages
2331     {
2332        local $SIG{'__DIE__'} =
2333               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
2334        eval { die "foo lives here" };
2335        print $@ if $@;                # prints "bar lives here"
2336     }
2337
2338 Because this promotes action at a distance, this counterintuitive behavior
2339 may be fixed in a future release.
2340
2341 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
2342 L<C<next>|/next LABEL>, L<C<last>|/last LABEL>, or
2343 L<C<redo>|/redo LABEL> cannot be used to leave or restart the block.
2344
2345 The final semicolon, if any, may be omitted from within the BLOCK.
2346
2347 =back
2348
2349 =item evalbytes EXPR
2350 X<evalbytes>
2351
2352 =item evalbytes
2353
2354 =for Pod::Functions +evalbytes similar to string eval, but intend to parse a bytestream
2355
2356 This function is similar to a L<string eval|/eval EXPR>, except it
2357 always parses its argument (or L<C<$_>|perlvar/$_> if EXPR is omitted)
2358 as a string of independent bytes.
2359
2360 If called when S<C<use utf8>> is in effect, the string will be assumed
2361 to be encoded in UTF-8, and C<evalbytes> will make a temporary copy to
2362 work from, downgraded to non-UTF-8.  If this is not possible
2363 (because one or more characters in it require UTF-8), the C<evalbytes>
2364 will fail with the error stored in C<$@>.
2365
2366 Bytes that correspond to ASCII-range code points will have their normal
2367 meanings for operators in the string.  The treatment of the other bytes
2368 depends on if the L<C<'unicode_strings"> feature|feature/The
2369 'unicode_strings' feature> is in effect.
2370
2371 Of course, variables that are UTF-8 and are referred to in the string
2372 retain that:
2373
2374  my $a = "\x{100}";
2375  evalbytes 'print ord $a, "\n"';
2376
2377 prints
2378
2379  256
2380
2381 and C<$@> is empty.
2382
2383 Source filters activated within the evaluated code apply to the code
2384 itself.
2385
2386 L<C<evalbytes>|/evalbytes EXPR> is available starting in Perl v5.16.  To
2387 access it, you must say C<CORE::evalbytes>, but you can omit the
2388 C<CORE::> if the
2389 L<C<"evalbytes"> feature|feature/The 'unicode_eval' and 'evalbytes' features>
2390 is enabled.  This is enabled automatically with a C<use v5.16> (or
2391 higher) declaration in the current scope.
2392
2393 =item exec LIST
2394 X<exec> X<execute>
2395
2396 =item exec PROGRAM LIST
2397
2398 =for Pod::Functions abandon this program to run another
2399
2400 The L<C<exec>|/exec LIST> function executes a system command I<and never
2401 returns>; use L<C<system>|/system LIST> instead of L<C<exec>|/exec LIST>
2402 if you want it to return.  It fails and
2403 returns false only if the command does not exist I<and> it is executed
2404 directly instead of via your system's command shell (see below).
2405
2406 Since it's a common mistake to use L<C<exec>|/exec LIST> instead of
2407 L<C<system>|/system LIST>, Perl warns you if L<C<exec>|/exec LIST> is
2408 called in void context and if there is a following statement that isn't
2409 L<C<die>|/die LIST>, L<C<warn>|/warn LIST>, or L<C<exit>|/exit EXPR> (if
2410 L<warnings> are enabled--but you always do that, right?).  If you
2411 I<really> want to follow an L<C<exec>|/exec LIST> with some other
2412 statement, you can use one of these styles to avoid the warning:
2413
2414     exec ('foo')   or print STDERR "couldn't exec foo: $!";
2415     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
2416
2417 If there is more than one argument in LIST, this calls L<execvp(3)> with the
2418 arguments in LIST.  If there is only one element in LIST, the argument is
2419 checked for shell metacharacters, and if there are any, the entire
2420 argument is passed to the system's command shell for parsing (this is
2421 C</bin/sh -c> on Unix platforms, but varies on other platforms).  If
2422 there are no shell metacharacters in the argument, it is split into words
2423 and passed directly to C<execvp>, which is more efficient.  Examples:
2424
2425     exec '/bin/echo', 'Your arguments are: ', @ARGV;
2426     exec "sort $outfile | uniq";
2427
2428 If you don't really want to execute the first argument, but want to lie
2429 to the program you are executing about its own name, you can specify
2430 the program you actually want to run as an "indirect object" (without a
2431 comma) in front of the LIST, as in C<exec PROGRAM LIST>.  (This always
2432 forces interpretation of the LIST as a multivalued list, even if there
2433 is only a single scalar in the list.)  Example:
2434
2435     my $shell = '/bin/csh';
2436     exec $shell '-sh';    # pretend it's a login shell
2437
2438 or, more directly,
2439
2440     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
2441
2442 When the arguments get executed via the system shell, results are
2443 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
2444 for details.
2445
2446 Using an indirect object with L<C<exec>|/exec LIST> or
2447 L<C<system>|/system LIST> is also more secure.  This usage (which also
2448 works fine with L<C<system>|/system LIST>) forces
2449 interpretation of the arguments as a multivalued list, even if the
2450 list had just one argument.  That way you're safe from the shell
2451 expanding wildcards or splitting up words with whitespace in them.
2452
2453     my @args = ( "echo surprise" );
2454
2455     exec @args;               # subject to shell escapes
2456                                 # if @args == 1
2457     exec { $args[0] } @args;  # safe even with one-arg list
2458
2459 The first version, the one without the indirect object, ran the I<echo>
2460 program, passing it C<"surprise"> an argument.  The second version didn't;
2461 it tried to run a program named I<"echo surprise">, didn't find it, and set
2462 L<C<$?>|perlvar/$?> to a non-zero value indicating failure.
2463
2464 On Windows, only the C<exec PROGRAM LIST> indirect object syntax will
2465 reliably avoid using the shell; C<exec LIST>, even with more than one
2466 element, will fall back to the shell if the first spawn fails.
2467
2468 Perl attempts to flush all files opened for output before the exec,
2469 but this may not be supported on some platforms (see L<perlport>).
2470 To be safe, you may need to set L<C<$E<verbar>>|perlvar/$E<verbar>>
2471 (C<$AUTOFLUSH> in L<English>) or call the C<autoflush> method of
2472 L<C<IO::Handle>|IO::Handle/METHODS> on any open handles to avoid lost
2473 output.
2474
2475 Note that L<C<exec>|/exec LIST> will not call your C<END> blocks, nor
2476 will it invoke C<DESTROY> methods on your objects.
2477
2478 Portability issues: L<perlport/exec>.
2479
2480 =item exists EXPR
2481 X<exists> X<autovivification>
2482
2483 =for Pod::Functions test whether a hash key is present
2484
2485 Given an expression that specifies an element of a hash, returns true if the
2486 specified element in the hash has ever been initialized, even if the
2487 corresponding value is undefined.
2488
2489     print "Exists\n"    if exists $hash{$key};
2490     print "Defined\n"   if defined $hash{$key};
2491     print "True\n"      if $hash{$key};
2492
2493 exists may also be called on array elements, but its behavior is much less
2494 obvious and is strongly tied to the use of L<C<delete>|/delete EXPR> on
2495 arrays.
2496
2497 B<WARNING:> Calling L<C<exists>|/exists EXPR> on array values is
2498 strongly discouraged.  The
2499 notion of deleting or checking the existence of Perl array elements is not
2500 conceptually coherent, and can lead to surprising behavior.
2501
2502     print "Exists\n"    if exists $array[$index];
2503     print "Defined\n"   if defined $array[$index];
2504     print "True\n"      if $array[$index];
2505
2506 A hash or array element can be true only if it's defined and defined only if
2507 it exists, but the reverse doesn't necessarily hold true.
2508
2509 Given an expression that specifies the name of a subroutine,
2510 returns true if the specified subroutine has ever been declared, even
2511 if it is undefined.  Mentioning a subroutine name for exists or defined
2512 does not count as declaring it.  Note that a subroutine that does not
2513 exist may still be callable: its package may have an C<AUTOLOAD>
2514 method that makes it spring into existence the first time that it is
2515 called; see L<perlsub>.
2516
2517     print "Exists\n"  if exists &subroutine;
2518     print "Defined\n" if defined &subroutine;
2519
2520 Note that the EXPR can be arbitrarily complicated as long as the final
2521 operation is a hash or array key lookup or subroutine name:
2522
2523     if (exists $ref->{A}->{B}->{$key})  { }
2524     if (exists $hash{A}{B}{$key})       { }
2525
2526     if (exists $ref->{A}->{B}->[$ix])   { }
2527     if (exists $hash{A}{B}[$ix])        { }
2528
2529     if (exists &{$ref->{A}{B}{$key}})   { }
2530
2531 Although the most deeply nested array or hash element will not spring into
2532 existence just because its existence was tested, any intervening ones will.
2533 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
2534 into existence due to the existence test for the C<$key> element above.
2535 This happens anywhere the arrow operator is used, including even here:
2536
2537     undef $ref;
2538     if (exists $ref->{"Some key"})    { }
2539     print $ref;  # prints HASH(0x80d3d5c)
2540
2541 Use of a subroutine call, rather than a subroutine name, as an argument
2542 to L<C<exists>|/exists EXPR> is an error.
2543
2544     exists &sub;    # OK
2545     exists &sub();  # Error
2546
2547 =item exit EXPR
2548 X<exit> X<terminate> X<abort>
2549
2550 =item exit
2551
2552 =for Pod::Functions terminate this program
2553
2554 Evaluates EXPR and exits immediately with that value.    Example:
2555
2556     my $ans = <STDIN>;
2557     exit 0 if $ans =~ /^[Xx]/;
2558
2559 See also L<C<die>|/die LIST>.  If EXPR is omitted, exits with C<0>
2560 status.  The only
2561 universally recognized values for EXPR are C<0> for success and C<1>
2562 for error; other values are subject to interpretation depending on the
2563 environment in which the Perl program is running.  For example, exiting
2564 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
2565 the mailer to return the item undelivered, but that's not true everywhere.
2566
2567 Don't use L<C<exit>|/exit EXPR> to abort a subroutine if there's any
2568 chance that someone might want to trap whatever error happened.  Use
2569 L<C<die>|/die LIST> instead, which can be trapped by an
2570 L<C<eval>|/eval EXPR>.
2571
2572 The L<C<exit>|/exit EXPR> function does not always exit immediately.  It
2573 calls any defined C<END> routines first, but these C<END> routines may
2574 not themselves abort the exit.  Likewise any object destructors that
2575 need to be called are called before the real exit.  C<END> routines and
2576 destructors can change the exit status by modifying L<C<$?>|perlvar/$?>.
2577 If this is a problem, you can call
2578 L<C<POSIX::_exit($status)>|POSIX/C<_exit>> to avoid C<END> and destructor
2579 processing.  See L<perlmod> for details.
2580
2581 Portability issues: L<perlport/exit>.
2582
2583 =item exp EXPR
2584 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
2585
2586 =item exp
2587
2588 =for Pod::Functions raise I<e> to a power
2589
2590 Returns I<e> (the natural logarithm base) to the power of EXPR.
2591 If EXPR is omitted, gives C<exp($_)>.
2592
2593 =item fc EXPR
2594 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2595
2596 =item fc
2597
2598 =for Pod::Functions +fc return casefolded version of a string
2599
2600 Returns the casefolded version of EXPR.  This is the internal function
2601 implementing the C<\F> escape in double-quoted strings.
2602
2603 Casefolding is the process of mapping strings to a form where case
2604 differences are erased; comparing two strings in their casefolded
2605 form is effectively a way of asking if two strings are equal,
2606 regardless of case.
2607
2608 Roughly, if you ever found yourself writing this
2609
2610     lc($this) eq lc($that)    # Wrong!
2611         # or
2612     uc($this) eq uc($that)    # Also wrong!
2613         # or
2614     $this =~ /^\Q$that\E\z/i  # Right!
2615
2616 Now you can write
2617
2618     fc($this) eq fc($that)
2619
2620 And get the correct results.
2621
2622 Perl only implements the full form of casefolding, but you can access
2623 the simple folds using L<Unicode::UCD/B<casefold()>> and
2624 L<Unicode::UCD/B<prop_invmap()>>.
2625 For further information on casefolding, refer to
2626 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2627 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2628 available at L<https://www.unicode.org/versions/latest/>, as well as the
2629 Case Charts available at L<https://www.unicode.org/charts/case/>.
2630
2631 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
2632
2633 This function behaves the same way under various pragmas, such as within
2634 L<S<C<"use feature 'unicode_strings">>|feature/The 'unicode_strings' feature>,
2635 as L<C<lc>|/lc EXPR> does, with the single exception of
2636 L<C<fc>|/fc EXPR> of I<LATIN CAPITAL LETTER SHARP S> (U+1E9E) within the
2637 scope of L<S<C<use locale>>|locale>.  The foldcase of this character
2638 would normally be C<"ss">, but as explained in the L<C<lc>|/lc EXPR>
2639 section, case
2640 changes that cross the 255/256 boundary are problematic under locales,
2641 and are hence prohibited.  Therefore, this function under locale returns
2642 instead the string C<"\x{17F}\x{17F}">, which is the I<LATIN SMALL LETTER
2643 LONG S>.  Since that character itself folds to C<"s">, the string of two
2644 of them together should be equivalent to a single U+1E9E when foldcased.
2645
2646 While the Unicode Standard defines two additional forms of casefolding,
2647 one for Turkic languages and one that never maps one character into multiple
2648 characters, these are not provided by the Perl core.  However, the CPAN module
2649 L<C<Unicode::Casing>|Unicode::Casing> may be used to provide an implementation.
2650
2651 L<C<fc>|/fc EXPR> is available only if the
2652 L<C<"fc"> feature|feature/The 'fc' feature> is enabled or if it is
2653 prefixed with C<CORE::>.  The
2654 L<C<"fc"> feature|feature/The 'fc' feature> is enabled automatically
2655 with a C<use v5.16> (or higher) declaration in the current scope.
2656
2657 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2658 X<fcntl>
2659
2660 =for Pod::Functions file control system call
2661
2662 Implements the L<fcntl(2)> function.  You'll probably have to say
2663
2664     use Fcntl;
2665
2666 first to get the correct constant definitions.  Argument processing and
2667 value returned work just like L<C<ioctl>|/ioctl
2668 FILEHANDLE,FUNCTION,SCALAR> below.  For example:
2669
2670     use Fcntl;
2671     my $flags = fcntl($filehandle, F_GETFL, 0)
2672         or die "Can't fcntl F_GETFL: $!";
2673
2674 You don't have to check for L<C<defined>|/defined EXPR> on the return
2675 from L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>.  Like
2676 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>, it maps a C<0> return
2677 from the system call into C<"0 but true"> in Perl.  This string is true
2678 in boolean context and C<0> in numeric context.  It is also exempt from
2679 the normal
2680 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
2681 L<warnings> on improper numeric conversions.
2682
2683 Note that L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> raises an
2684 exception if used on a machine that doesn't implement L<fcntl(2)>.  See
2685 the L<Fcntl> module or your L<fcntl(2)> manpage to learn what functions
2686 are available on your system.
2687
2688 Here's an example of setting a filehandle named C<$REMOTE> to be
2689 non-blocking at the system level.  You'll have to negotiate
2690 L<C<$E<verbar>>|perlvar/$E<verbar>> on your own, though.
2691
2692     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2693
2694     my $flags = fcntl($REMOTE, F_GETFL, 0)
2695         or die "Can't get flags for the socket: $!\n";
2696
2697     fcntl($REMOTE, F_SETFL, $flags | O_NONBLOCK)
2698         or die "Can't set flags for the socket: $!\n";
2699
2700 Portability issues: L<perlport/fcntl>.
2701
2702 =item __FILE__
2703 X<__FILE__>
2704
2705 =for Pod::Functions the name of the current source file
2706
2707 A special token that returns the name of the file in which it occurs.
2708 It can be altered by the mechanism described at
2709 L<perlsyn/"Plain Old Comments (Not!)">.
2710
2711 =item fileno FILEHANDLE
2712 X<fileno>
2713
2714 =item fileno DIRHANDLE
2715
2716 =for Pod::Functions return file descriptor from filehandle
2717
2718 Returns the file descriptor for a filehandle or directory handle,
2719 or undefined if the
2720 filehandle is not open.  If there is no real file descriptor at the OS
2721 level, as can happen with filehandles connected to memory objects via
2722 L<C<open>|/open FILEHANDLE,MODE,EXPR> with a reference for the third
2723 argument, -1 is returned.
2724
2725 This is mainly useful for constructing bitmaps for
2726 L<C<select>|/select RBITS,WBITS,EBITS,TIMEOUT> and low-level POSIX
2727 tty-handling operations.
2728 If FILEHANDLE is an expression, the value is taken as an indirect
2729 filehandle, generally its name.
2730
2731 You can use this to find out whether two handles refer to the
2732 same underlying descriptor:
2733
2734     if (fileno($this) != -1 && fileno($this) == fileno($that)) {
2735         print "\$this and \$that are dups\n";
2736     } elsif (fileno($this) != -1 && fileno($that) != -1) {
2737         print "\$this and \$that have different " .
2738             "underlying file descriptors\n";
2739     } else {
2740         print "At least one of \$this and \$that does " .
2741             "not have a real file descriptor\n";
2742     }
2743
2744 The behavior of L<C<fileno>|/fileno FILEHANDLE> on a directory handle
2745 depends on the operating system.  On a system with L<dirfd(3)> or
2746 similar, L<C<fileno>|/fileno FILEHANDLE> on a directory
2747 handle returns the underlying file descriptor associated with the
2748 handle; on systems with no such support, it returns the undefined value,
2749 and sets L<C<$!>|perlvar/$!> (errno).
2750
2751 =item flock FILEHANDLE,OPERATION
2752 X<flock> X<lock> X<locking>
2753
2754 =for Pod::Functions lock an entire file with an advisory lock
2755
2756 Calls L<flock(2)>, or an emulation of it, on FILEHANDLE.  Returns true
2757 for success, false on failure.  Produces a fatal error if used on a
2758 machine that doesn't implement L<flock(2)>, L<fcntl(2)> locking, or
2759 L<lockf(3)>.  L<C<flock>|/flock FILEHANDLE,OPERATION> is Perl's portable
2760 file-locking interface, although it locks entire files only, not
2761 records.
2762
2763 Two potentially non-obvious but traditional L<C<flock>|/flock
2764 FILEHANDLE,OPERATION> semantics are
2765 that it waits indefinitely until the lock is granted, and that its locks
2766 are B<merely advisory>.  Such discretionary locks are more flexible, but
2767 offer fewer guarantees.  This means that programs that do not also use
2768 L<C<flock>|/flock FILEHANDLE,OPERATION> may modify files locked with
2769 L<C<flock>|/flock FILEHANDLE,OPERATION>.  See L<perlport>,
2770 your port's specific documentation, and your system-specific local manpages
2771 for details.  It's best to assume traditional behavior if you're writing
2772 portable programs.  (But if you're not, you should as always feel perfectly
2773 free to write for your own system's idiosyncrasies (sometimes called
2774 "features").  Slavish adherence to portability concerns shouldn't get
2775 in the way of your getting your job done.)
2776
2777 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2778 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2779 you can use the symbolic names if you import them from the L<Fcntl> module,
2780 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2781 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2782 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2783 LOCK_SH or LOCK_EX, then L<C<flock>|/flock FILEHANDLE,OPERATION> returns
2784 immediately rather than blocking waiting for the lock; check the return
2785 status to see if you got it.
2786
2787 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2788 before locking or unlocking it.
2789
2790 Note that the emulation built with L<lockf(3)> doesn't provide shared
2791 locks, and it requires that FILEHANDLE be open with write intent.  These
2792 are the semantics that L<lockf(3)> implements.  Most if not all systems
2793 implement L<lockf(3)> in terms of L<fcntl(2)> locking, though, so the
2794 differing semantics shouldn't bite too many people.
2795
2796 Note that the L<fcntl(2)> emulation of L<flock(3)> requires that FILEHANDLE
2797 be open with read intent to use LOCK_SH and requires that it be open
2798 with write intent to use LOCK_EX.
2799
2800 Note also that some versions of L<C<flock>|/flock FILEHANDLE,OPERATION>
2801 cannot lock things over the network; you would need to use the more
2802 system-specific L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR> for
2803 that.  If you like you can force Perl to ignore your system's L<flock(2)>
2804 function, and so provide its own L<fcntl(2)>-based emulation, by passing
2805 the switch C<-Ud_flock> to the F<Configure> program when you configure
2806 and build a new Perl.
2807
2808 Here's a mailbox appender for BSD systems.
2809
2810     # import LOCK_* and SEEK_END constants
2811     use Fcntl qw(:flock SEEK_END);
2812
2813     sub lock {
2814         my ($fh) = @_;
2815         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2816         # and, in case we're running on a very old UNIX
2817         # variant without the modern O_APPEND semantics...
2818         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2819     }
2820
2821     sub unlock {
2822         my ($fh) = @_;
2823         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2824     }
2825
2826     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2827         or die "Can't open mailbox: $!";
2828
2829     lock($mbox);
2830     print $mbox $msg,"\n\n";
2831     unlock($mbox);
2832
2833 On systems that support a real L<flock(2)>, locks are inherited across
2834 L<C<fork>|/fork> calls, whereas those that must resort to the more
2835 capricious L<fcntl(2)> function lose their locks, making it seriously
2836 harder to write servers.
2837
2838 See also L<DB_File> for other L<C<flock>|/flock FILEHANDLE,OPERATION>
2839 examples.
2840
2841 Portability issues: L<perlport/flock>.
2842
2843 =item fork
2844 X<fork> X<child> X<parent>
2845
2846 =for Pod::Functions create a new process just like this one
2847
2848 Does a L<fork(2)> system call to create a new process running the
2849 same program at the same point.  It returns the child pid to the
2850 parent process, C<0> to the child process, or L<C<undef>|/undef EXPR> if
2851 the fork is
2852 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2853 are shared, while everything else is copied.  On most systems supporting
2854 L<fork(2)>, great care has gone into making it extremely efficient (for
2855 example, using copy-on-write technology on data pages), making it the
2856 dominant paradigm for multitasking over the last few decades.
2857
2858 Perl attempts to flush all files opened for output before forking the
2859 child process, but this may not be supported on some platforms (see
2860 L<perlport>).  To be safe, you may need to set
2861 L<C<$E<verbar>>|perlvar/$E<verbar>> (C<$AUTOFLUSH> in L<English>) or
2862 call the C<autoflush> method of L<C<IO::Handle>|IO::Handle/METHODS> on
2863 any open handles to avoid duplicate output.
2864
2865 If you L<C<fork>|/fork> without ever waiting on your children, you will
2866 accumulate zombies.  On some systems, you can avoid this by setting
2867 L<C<$SIG{CHLD}>|perlvar/%SIG> to C<"IGNORE">.  See also L<perlipc> for
2868 more examples of forking and reaping moribund children.
2869
2870 Note that if your forked child inherits system file descriptors like
2871 STDIN and STDOUT that are actually connected by a pipe or socket, even
2872 if you exit, then the remote server (such as, say, a CGI script or a
2873 backgrounded job launched from a remote shell) won't think you're done.
2874 You should reopen those to F</dev/null> if it's any issue.
2875
2876 On some platforms such as Windows, where the L<fork(2)> system call is
2877 not available, Perl can be built to emulate L<C<fork>|/fork> in the Perl
2878 interpreter.  The emulation is designed, at the level of the Perl
2879 program, to be as compatible as possible with the "Unix" L<fork(2)>.
2880 However it has limitations that have to be considered in code intended
2881 to be portable.  See L<perlfork> for more details.
2882
2883 Portability issues: L<perlport/fork>.
2884
2885 =item format
2886 X<format>
2887
2888 =for Pod::Functions declare a picture format with use by the write() function
2889
2890 Declare a picture format for use by the L<C<write>|/write FILEHANDLE>
2891 function.  For example:
2892
2893     format Something =
2894         Test: @<<<<<<<< @||||| @>>>>>
2895               $str,     $%,    '$' . int($num)
2896     .
2897
2898     $str = "widget";
2899     $num = $cost/$quantity;
2900     $~ = 'Something';
2901     write;
2902
2903 See L<perlform> for many details and examples.
2904
2905 =item formline PICTURE,LIST
2906 X<formline>
2907
2908 =for Pod::Functions internal function used for formats
2909
2910 This is an internal function used by L<C<format>|/format>s, though you
2911 may call it, too.  It formats (see L<perlform>) a list of values
2912 according to the contents of PICTURE, placing the output into the format
2913 output accumulator, L<C<$^A>|perlvar/$^A> (or C<$ACCUMULATOR> in
2914 L<English>).  Eventually, when a L<C<write>|/write FILEHANDLE> is done,
2915 the contents of L<C<$^A>|perlvar/$^A> are written to some filehandle.
2916 You could also read L<C<$^A>|perlvar/$^A> and then set
2917 L<C<$^A>|perlvar/$^A> back to C<"">.  Note that a format typically does
2918 one L<C<formline>|/formline PICTURE,LIST> per line of form, but the
2919 L<C<formline>|/formline PICTURE,LIST> function itself doesn't care how
2920 many newlines are embedded in the PICTURE.  This means that the C<~> and
2921 C<~~> tokens treat the entire PICTURE as a single line.  You may
2922 therefore need to use multiple formlines to implement a single record
2923 format, just like the L<C<format>|/format> compiler.
2924
2925 Be careful if you put double quotes around the picture, because an C<@>
2926 character may be taken to mean the beginning of an array name.
2927 L<C<formline>|/formline PICTURE,LIST> always returns true.  See
2928 L<perlform> for other examples.
2929
2930 If you are trying to use this instead of L<C<write>|/write FILEHANDLE>
2931 to capture the output, you may find it easier to open a filehandle to a
2932 scalar (C<< open my $fh, ">", \$output >>) and write to that instead.
2933
2934 =item getc FILEHANDLE
2935 X<getc> X<getchar> X<character> X<file, read>
2936
2937 =item getc
2938
2939 =for Pod::Functions get the next character from the filehandle
2940
2941 Returns the next character from the input file attached to FILEHANDLE,
2942 or the undefined value at end of file or if there was an error (in
2943 the latter case L<C<$!>|perlvar/$!> is set).  If FILEHANDLE is omitted,
2944 reads from
2945 STDIN.  This is not particularly efficient.  However, it cannot be
2946 used by itself to fetch single characters without waiting for the user
2947 to hit enter.  For that, try something more like:
2948
2949     if ($BSD_STYLE) {
2950         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2951     }
2952     else {
2953         system "stty", '-icanon', 'eol', "\001";
2954     }
2955
2956     my $key = getc(STDIN);
2957
2958     if ($BSD_STYLE) {
2959         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2960     }
2961     else {
2962         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2963     }
2964     print "\n";
2965
2966 Determination of whether C<$BSD_STYLE> should be set is left as an
2967 exercise to the reader.
2968
2969 The L<C<POSIX::getattr>|POSIX/C<getattr>> function can do this more
2970 portably on systems purporting POSIX compliance.  See also the
2971 L<C<Term::ReadKey>|Term::ReadKey> module on CPAN.
2972
2973 =item getlogin
2974 X<getlogin> X<login>
2975
2976 =for Pod::Functions return who logged in at this tty
2977
2978 This implements the C library function of the same name, which on most
2979 systems returns the current login from F</etc/utmp>, if any.  If it
2980 returns the empty string, use L<C<getpwuid>|/getpwuid UID>.
2981
2982     my $login = getlogin || getpwuid($<) || "Kilroy";
2983
2984 Do not consider L<C<getlogin>|/getlogin> for authentication: it is not
2985 as secure as L<C<getpwuid>|/getpwuid UID>.
2986
2987 Portability issues: L<perlport/getlogin>.
2988
2989 =item getpeername SOCKET
2990 X<getpeername> X<peer>
2991
2992 =for Pod::Functions find the other end of a socket connection
2993
2994 Returns the packed sockaddr address of the other end of the SOCKET
2995 connection.
2996
2997     use Socket;
2998     my $hersockaddr    = getpeername($sock);
2999     my ($port, $iaddr) = sockaddr_in($hersockaddr);
3000     my $herhostname    = gethostbyaddr($iaddr, AF_INET);
3001     my $herstraddr     = inet_ntoa($iaddr);
3002
3003 =item getpgrp PID
3004 X<getpgrp> X<group>
3005
3006 =for Pod::Functions get process group
3007
3008 Returns the current process group for the specified PID.  Use
3009 a PID of C<0> to get the current process group for the
3010 current process.  Will raise an exception if used on a machine that
3011 doesn't implement L<getpgrp(2)>.  If PID is omitted, returns the process
3012 group of the current process.  Note that the POSIX version of
3013 L<C<getpgrp>|/getpgrp PID> does not accept a PID argument, so only
3014 C<PID==0> is truly portable.
3015
3016 Portability issues: L<perlport/getpgrp>.
3017
3018 =item getppid
3019 X<getppid> X<parent> X<pid>
3020
3021 =for Pod::Functions get parent process ID
3022
3023 Returns the process id of the parent process.
3024
3025 Note for Linux users: Between v5.8.1 and v5.16.0 Perl would work
3026 around non-POSIX thread semantics the minority of Linux systems (and
3027 Debian GNU/kFreeBSD systems) that used LinuxThreads, this emulation
3028 has since been removed.  See the documentation for L<$$|perlvar/$$> for
3029 details.
3030
3031 Portability issues: L<perlport/getppid>.
3032
3033 =item getpriority WHICH,WHO
3034 X<getpriority> X<priority> X<nice>
3035
3036 =for Pod::Functions get current nice value
3037
3038 Returns the current priority for a process, a process group, or a user.
3039 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
3040 machine that doesn't implement L<getpriority(2)>.
3041
3042 C<WHICH> can be any of C<PRIO_PROCESS>, C<PRIO_PGRP> or C<PRIO_USER>
3043 imported from L<POSIX/RESOURCE CONSTANTS>.
3044
3045 Portability issues: L<perlport/getpriority>.
3046
3047 =item getpwnam NAME
3048 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
3049 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
3050 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
3051 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
3052 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
3053 X<endnetent> X<endprotoent> X<endservent>
3054
3055 =for Pod::Functions get passwd record given user login name
3056
3057 =item getgrnam NAME
3058
3059 =for Pod::Functions get group record given group name
3060
3061 =item gethostbyname NAME
3062
3063 =for Pod::Functions get host record given name
3064
3065 =item getnetbyname NAME
3066
3067 =for Pod::Functions get networks record given name
3068
3069 =item getprotobyname NAME
3070
3071 =for Pod::Functions get protocol record given name
3072
3073 =item getpwuid UID
3074
3075 =for Pod::Functions get passwd record given user ID
3076
3077 =item getgrgid GID
3078
3079 =for Pod::Functions get group record given group user ID
3080
3081 =item getservbyname NAME,PROTO
3082
3083 =for Pod::Functions get services record given its name
3084
3085 =item gethostbyaddr ADDR,ADDRTYPE
3086
3087 =for Pod::Functions get host record given its address
3088
3089 =item getnetbyaddr ADDR,ADDRTYPE
3090
3091 =for Pod::Functions get network record given its address
3092
3093 =item getprotobynumber NUMBER
3094
3095 =for Pod::Functions get protocol record numeric protocol
3096
3097 =item getservbyport PORT,PROTO
3098
3099 =for Pod::Functions get services record given numeric port
3100
3101 =item getpwent
3102
3103 =for Pod::Functions get next passwd record
3104
3105 =item getgrent
3106
3107 =for Pod::Functions get next group record
3108
3109 =item gethostent
3110
3111 =for Pod::Functions get next hosts record
3112
3113 =item getnetent
3114
3115 =for Pod::Functions get next networks record
3116
3117 =item getprotoent
3118
3119 =for Pod::Functions get next protocols record
3120
3121 =item getservent
3122
3123 =for Pod::Functions get next services record
3124
3125 =item setpwent
3126
3127 =for Pod::Functions prepare passwd file for use
3128
3129 =item setgrent
3130
3131 =for Pod::Functions prepare group file for use
3132
3133 =item sethostent STAYOPEN
3134
3135 =for Pod::Functions prepare hosts file for use
3136
3137 =item setnetent STAYOPEN
3138
3139 =for Pod::Functions prepare networks file for use
3140
3141 =item setprotoent STAYOPEN
3142
3143 =for Pod::Functions prepare protocols file for use
3144
3145 =item setservent STAYOPEN
3146
3147 =for Pod::Functions prepare services file for use
3148
3149 =item endpwent
3150
3151 =for Pod::Functions be done using passwd file
3152
3153 =item endgrent
3154
3155 =for Pod::Functions be done using group file
3156
3157 =item endhostent
3158
3159 =for Pod::Functions be done using hosts file
3160
3161 =item endnetent
3162
3163 =for Pod::Functions be done using networks file
3164
3165 =item endprotoent
3166
3167 =for Pod::Functions be done using protocols file
3168
3169 =item endservent
3170
3171 =for Pod::Functions be done using services file
3172
3173 These routines are the same as their counterparts in the
3174 system C library.  In list context, the return values from the
3175 various get routines are as follows:
3176
3177  #    0        1          2           3         4
3178  my ( $name,   $passwd,   $gid,       $members  ) = getgr*
3179  my ( $name,   $aliases,  $addrtype,  $net      ) = getnet*
3180  my ( $name,   $aliases,  $port,      $proto    ) = getserv*
3181  my ( $name,   $aliases,  $proto                ) = getproto*
3182  my ( $name,   $aliases,  $addrtype,  $length,  @addrs ) = gethost*
3183  my ( $name,   $passwd,   $uid,       $gid,     $quota,
3184     $comment,  $gcos,     $dir,       $shell,   $expire ) = getpw*
3185  #    5        6          7           8         9
3186
3187 (If the entry doesn't exist, the return value is a single meaningless true
3188 value.)
3189
3190 The exact meaning of the $gcos field varies but it usually contains
3191 the real name of the user (as opposed to the login name) and other
3192 information pertaining to the user.  Beware, however, that in many
3193 system users are able to change this information and therefore it
3194 cannot be trusted and therefore the $gcos is tainted (see
3195 L<perlsec>).  The $passwd and $shell, user's encrypted password and
3196 login shell, are also tainted, for the same reason.
3197
3198 In scalar context, you get the name, unless the function was a
3199 lookup by name, in which case you get the other thing, whatever it is.
3200 (If the entry doesn't exist you get the undefined value.)  For example:
3201
3202     my $uid   = getpwnam($name);
3203     my $name  = getpwuid($num);
3204     my $name  = getpwent();
3205     my $gid   = getgrnam($name);
3206     my $name  = getgrgid($num);
3207     my $name  = getgrent();
3208     # etc.
3209
3210 In I<getpw*()> the fields $quota, $comment, and $expire are special
3211 in that they are unsupported on many systems.  If the
3212 $quota is unsupported, it is an empty scalar.  If it is supported, it
3213 usually encodes the disk quota.  If the $comment field is unsupported,
3214 it is an empty scalar.  If it is supported it usually encodes some
3215 administrative comment about the user.  In some systems the $quota
3216 field may be $change or $age, fields that have to do with password
3217 aging.  In some systems the $comment field may be $class.  The $expire
3218 field, if present, encodes the expiration period of the account or the
3219 password.  For the availability and the exact meaning of these fields
3220 in your system, please consult L<getpwnam(3)> and your system's
3221 F<pwd.h> file.  You can also find out from within Perl what your
3222 $quota and $comment fields mean and whether you have the $expire field
3223 by using the L<C<Config>|Config> module and the values C<d_pwquota>, C<d_pwage>,
3224 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
3225 files are supported only if your vendor has implemented them in the
3226 intuitive fashion that calling the regular C library routines gets the
3227 shadow versions if you're running under privilege or if there exists
3228 the L<shadow(3)> functions as found in System V (this includes Solaris
3229 and Linux).  Those systems that implement a proprietary shadow password
3230 facility are unlikely to be supported.
3231
3232 The $members value returned by I<getgr*()> is a space-separated list of
3233 the login names of the members of the group.
3234
3235 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
3236 C, it will be returned to you via L<C<$?>|perlvar/$?> if the function
3237 call fails.  The
3238 C<@addrs> value returned by a successful call is a list of raw
3239 addresses returned by the corresponding library call.  In the
3240 Internet domain, each address is four bytes long; you can unpack it
3241 by saying something like:
3242
3243     my ($w,$x,$y,$z) = unpack('W4',$addr[0]);
3244
3245 The Socket library makes this slightly easier:
3246
3247     use Socket;
3248     my $iaddr = inet_aton("127.1"); # or whatever address
3249     my $name  = gethostbyaddr($iaddr, AF_INET);
3250
3251     # or going the other way
3252     my $straddr = inet_ntoa($iaddr);
3253
3254 In the opposite way, to resolve a hostname to the IP address
3255 you can write this:
3256
3257     use Socket;
3258     my $packed_ip = gethostbyname("www.perl.org");
3259     my $ip_address;
3260     if (defined $packed_ip) {
3261         $ip_address = inet_ntoa($packed_ip);
3262     }
3263
3264 Make sure L<C<gethostbyname>|/gethostbyname NAME> is called in SCALAR
3265 context and that its return value is checked for definedness.
3266
3267 The L<C<getprotobynumber>|/getprotobynumber NUMBER> function, even
3268 though it only takes one argument, has the precedence of a list
3269 operator, so beware:
3270
3271     getprotobynumber $number eq 'icmp'   # WRONG
3272     getprotobynumber($number eq 'icmp')  # actually means this
3273     getprotobynumber($number) eq 'icmp'  # better this way
3274
3275 If you get tired of remembering which element of the return list
3276 contains which return value, by-name interfaces are provided in standard
3277 modules: L<C<File::stat>|File::stat>, L<C<Net::hostent>|Net::hostent>,
3278 L<C<Net::netent>|Net::netent>, L<C<Net::protoent>|Net::protoent>,
3279 L<C<Net::servent>|Net::servent>, L<C<Time::gmtime>|Time::gmtime>,
3280 L<C<Time::localtime>|Time::localtime>, and
3281 L<C<User::grent>|User::grent>.  These override the normal built-ins,
3282 supplying versions that return objects with the appropriate names for
3283 each field.  For example:
3284
3285    use File::stat;
3286    use User::pwent;
3287    my $is_his = (stat($filename)->uid == pwent($whoever)->uid);
3288
3289 Even though it looks as though they're the same method calls (uid),
3290 they aren't, because a C<File::stat> object is different from
3291 a C<User::pwent> object.
3292
3293 Many of these functions are not safe in a multi-threaded environment
3294 where more than one thread can be using them.  In particular, functions
3295 like C<getpwent()> iterate per-process and not per-thread, so if two
3296 threads are simultaneously iterating, neither will get all the records.
3297
3298 Some systems have thread-safe versions of some of the functions, such as
3299 C<getpwnam_r()> instead of C<getpwnam()>.  There, Perl automatically and
3300 invisibly substitutes the thread-safe version, without notice.  This
3301 means that code that safely runs on some systems can fail on others that
3302 lack the thread-safe versions.
3303
3304 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
3305
3306 =item getsockname SOCKET
3307 X<getsockname>
3308
3309 =for Pod::Functions retrieve the sockaddr for a given socket
3310
3311 Returns the packed sockaddr address of this end of the SOCKET connection,
3312 in case you don't know the address because you have several different
3313 IPs that the connection might have come in on.
3314
3315     use Socket;
3316     my $mysockaddr = getsockname($sock);
3317     my ($port, $myaddr) = sockaddr_in($mysockaddr);
3318     printf "Connect to %s [%s]\n",
3319        scalar gethostbyaddr($myaddr, AF_INET),
3320        inet_ntoa($myaddr);
3321
3322 =item getsockopt SOCKET,LEVEL,OPTNAME
3323 X<getsockopt>
3324
3325 =for Pod::Functions get socket options on a given socket
3326
3327 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
3328 Options may exist at multiple protocol levels depending on the socket
3329 type, but at least the uppermost socket level SOL_SOCKET (defined in the
3330 L<C<Socket>|Socket> module) will exist.  To query options at another
3331 level the protocol number of the appropriate protocol controlling the
3332 option should be supplied.  For example, to indicate that an option is
3333 to be interpreted by the TCP protocol, LEVEL should be set to the
3334 protocol number of TCP, which you can get using
3335 L<C<getprotobyname>|/getprotobyname NAME>.
3336
3337 The function returns a packed string representing the requested socket
3338 option, or L<C<undef>|/undef EXPR> on error, with the reason for the
3339 error placed in L<C<$!>|perlvar/$!>.  Just what is in the packed string
3340 depends on LEVEL and OPTNAME; consult L<getsockopt(2)> for details.  A
3341 common case is that the option is an integer, in which case the result
3342 is a packed integer, which you can decode using
3343 L<C<unpack>|/unpack TEMPLATE,EXPR> with the C<i> (or C<I>) format.
3344
3345 Here's an example to test whether Nagle's algorithm is enabled on a socket:
3346
3347     use Socket qw(:all);
3348
3349     defined(my $tcp = getprotobyname("tcp"))
3350         or die "Could not determine the protocol number for tcp";
3351     # my $tcp = IPPROTO_TCP; # Alternative
3352     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
3353         or die "getsockopt TCP_NODELAY: $!";
3354     my $nodelay = unpack("I", $packed);
3355     print "Nagle's algorithm is turned ",
3356            $nodelay ? "off\n" : "on\n";
3357
3358 Portability issues: L<perlport/getsockopt>.
3359
3360 =item glob EXPR
3361 X<glob> X<wildcard> X<filename, expansion> X<expand>
3362
3363 =item glob
3364
3365 =for Pod::Functions expand filenames using wildcards
3366
3367 In list context, returns a (possibly empty) list of filename expansions on
3368 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
3369 scalar context, glob iterates through such filename expansions, returning
3370 undef when the list is exhausted.  This is the internal function
3371 implementing the C<< <*.c> >> operator, but you can use it directly.  If
3372 EXPR is omitted, L<C<$_>|perlvar/$_> is used.  The C<< <*.c> >> operator
3373 is discussed in more detail in L<perlop/"I/O Operators">.
3374
3375 Note that L<C<glob>|/glob EXPR> splits its arguments on whitespace and
3376 treats
3377 each segment as separate pattern.  As such, C<glob("*.c *.h")>
3378 matches all files with a F<.c> or F<.h> extension.  The expression
3379 C<glob(".* *")> matches all files in the current working directory.
3380 If you want to glob filenames that might contain whitespace, you'll
3381 have to use extra quotes around the spacey filename to protect it.
3382 For example, to glob filenames that have an C<e> followed by a space
3383 followed by an C<f>, use one of:
3384
3385     my @spacies = <"*e f*">;
3386     my @spacies = glob '"*e f*"';
3387     my @spacies = glob q("*e f*");
3388
3389 If you had to get a variable through, you could do this:
3390
3391     my @spacies = glob "'*${var}e f*'";
3392     my @spacies = glob qq("*${var}e f*");
3393
3394 If non-empty braces are the only wildcard characters used in the
3395 L<C<glob>|/glob EXPR>, no filenames are matched, but potentially many
3396 strings are returned.  For example, this produces nine strings, one for
3397 each pairing of fruits and colors:
3398
3399     my @many = glob "{apple,tomato,cherry}={green,yellow,red}";
3400
3401 This operator is implemented using the standard C<File::Glob> extension.
3402 See L<File::Glob> for details, including
3403 L<C<bsd_glob>|File::Glob/C<bsd_glob>>, which does not treat whitespace
3404 as a pattern separator.
3405
3406 If a C<glob> expression is used as the condition of a C<while> or C<for>
3407 loop, then it will be implicitly assigned to C<$_>.  If either a C<glob>
3408 expression or an explicit assignment of a C<glob> expression to a scalar
3409 is used as a C<while>/C<for> condition, then the condition actually
3410 tests for definedness of the expression's value, not for its regular
3411 truth value.
3412
3413 Portability issues: L<perlport/glob>.
3414
3415 =item gmtime EXPR
3416 X<gmtime> X<UTC> X<Greenwich>
3417
3418 =item gmtime
3419
3420 =for Pod::Functions convert UNIX time into record or string using Greenwich time
3421
3422 Works just like L<C<localtime>|/localtime EXPR>, but the returned values
3423 are localized for the standard Greenwich time zone.
3424
3425 Note: When called in list context, $isdst, the last value
3426 returned by gmtime, is always C<0>.  There is no
3427 Daylight Saving Time in GMT.
3428
3429 Portability issues: L<perlport/gmtime>.
3430
3431 =item goto LABEL
3432 X<goto> X<jump> X<jmp>
3433
3434 =item goto EXPR
3435
3436 =item goto &NAME
3437
3438 =for Pod::Functions create spaghetti code
3439
3440 The C<goto LABEL> form finds the statement labeled with LABEL and
3441 resumes execution there.  It can't be used to get out of a block or
3442 subroutine given to L<C<sort>|/sort SUBNAME LIST>.  It can be used to go
3443 almost anywhere else within the dynamic scope, including out of
3444 subroutines, but it's usually better to use some other construct such as
3445 L<C<last>|/last LABEL> or L<C<die>|/die LIST>.  The author of Perl has
3446 never felt the need to use this form of L<C<goto>|/goto LABEL> (in Perl,
3447 that is; C is another matter).  (The difference is that C does not offer
3448 named loops combined with loop control.  Perl does, and this replaces
3449 most structured uses of L<C<goto>|/goto LABEL> in other languages.)
3450
3451 The C<goto EXPR> form expects to evaluate C<EXPR> to a code reference or
3452 a label name.  If it evaluates to a code reference, it will be handled
3453 like C<goto &NAME>, below.  This is especially useful for implementing
3454 tail recursion via C<goto __SUB__>.
3455
3456 If the expression evaluates to a label name, its scope will be resolved
3457 dynamically.  This allows for computed L<C<goto>|/goto LABEL>s per
3458 FORTRAN, but isn't necessarily recommended if you're optimizing for
3459 maintainability:
3460
3461     goto ("FOO", "BAR", "GLARCH")[$i];
3462
3463 As shown in this example, C<goto EXPR> is exempt from the "looks like a
3464 function" rule.  A pair of parentheses following it does not (necessarily)
3465 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
3466 Also, unlike most named operators, this has the same precedence as
3467 assignment.
3468
3469 Use of C<goto LABEL> or C<goto EXPR> to jump into a construct is
3470 deprecated and will issue a warning.  Even then, it may not be used to
3471 go into any construct that requires initialization, such as a
3472 subroutine, a C<foreach> loop, or a C<given>
3473 block.  In general, it may not be used to jump into the parameter
3474 of a binary or list operator, but it may be used to jump into the
3475 I<first> parameter of a binary operator.  (The C<=>
3476 assignment operator's "first" operand is its right-hand
3477 operand.)  It also can't be used to go into a
3478 construct that is optimized away.
3479
3480 The C<goto &NAME> form is quite different from the other forms of
3481 L<C<goto>|/goto LABEL>.  In fact, it isn't a goto in the normal sense at
3482 all, and doesn't have the stigma associated with other gotos.  Instead,
3483 it exits the current subroutine (losing any changes set by
3484 L<C<local>|/local EXPR>) and immediately calls in its place the named
3485 subroutine using the current value of L<C<@_>|perlvar/@_>.  This is used
3486 by C<AUTOLOAD> subroutines that wish to load another subroutine and then
3487 pretend that the other subroutine had been called in the first place
3488 (except that any modifications to L<C<@_>|perlvar/@_> in the current
3489 subroutine are propagated to the other subroutine.) After the
3490 L<C<goto>|/goto LABEL>, not even L<C<caller>|/caller EXPR> will be able
3491 to tell that this routine was called first.
3492
3493 NAME needn't be the name of a subroutine; it can be a scalar variable
3494 containing a code reference or a block that evaluates to a code
3495 reference.
3496
3497 =item grep BLOCK LIST
3498 X<grep>
3499
3500 =item grep EXPR,LIST
3501
3502 =for Pod::Functions locate elements in a list test true against a given criterion
3503
3504 This is similar in spirit to, but not the same as, L<grep(1)> and its
3505 relatives.  In particular, it is not limited to using regular expressions.
3506
3507 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3508 L<C<$_>|perlvar/$_> to each element) and returns the list value
3509 consisting of those
3510 elements for which the expression evaluated to true.  In scalar
3511 context, returns the number of times the expression was true.
3512
3513     my @foo = grep(!/^#/, @bar);    # weed out comments
3514
3515 or equivalently,
3516
3517     my @foo = grep {!/^#/} @bar;    # weed out comments
3518
3519 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
3520 be used to
3521 modify the elements of the LIST.  While this is useful and supported,
3522 it can cause bizarre results if the elements of LIST are not variables.
3523 Similarly, grep returns aliases into the original list, much as a for
3524 loop's index variable aliases the list elements.  That is, modifying an
3525 element of a list returned by grep (for example, in a C<foreach>,
3526 L<C<map>|/map BLOCK LIST> or another L<C<grep>|/grep BLOCK LIST>)
3527 actually modifies the element in the original list.
3528 This is usually something to be avoided when writing clear code.
3529
3530 See also L<C<map>|/map BLOCK LIST> for a list composed of the results of
3531 the BLOCK or EXPR.
3532
3533 =item hex EXPR
3534 X<hex> X<hexadecimal>
3535
3536 =item hex
3537
3538 =for Pod::Functions convert a hexadecimal string to a number
3539
3540 Interprets EXPR as a hex string and returns the corresponding numeric value.
3541 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3542
3543     print hex '0xAf'; # prints '175'
3544     print hex 'aF';   # same
3545     $valid_input =~ /\A(?:0?[xX])?(?:_?[0-9a-fA-F])*\z/
3546
3547 A hex string consists of hex digits and an optional C<0x> or C<x> prefix.
3548 Each hex digit may be preceded by a single underscore, which will be ignored.
3549 Any other character triggers a warning and causes the rest of the string
3550 to be ignored (even leading whitespace, unlike L<C<oct>|/oct EXPR>).
3551 Only integers can be represented, and integer overflow triggers a warning.
3552
3553 To convert strings that might start with any of C<0>, C<0x>, or C<0b>,
3554 see L<C<oct>|/oct EXPR>.  To present something as hex, look into
3555 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>,
3556 L<C<sprintf>|/sprintf FORMAT, LIST>, and
3557 L<C<unpack>|/unpack TEMPLATE,EXPR>.
3558
3559 =item import LIST
3560 X<import>
3561
3562 =for Pod::Functions patch a module's namespace into your own
3563
3564 There is no builtin L<C<import>|/import LIST> function.  It is just an
3565 ordinary method (subroutine) defined (or inherited) by modules that wish
3566 to export names to another module.  The
3567 L<C<use>|/use Module VERSION LIST> function calls the
3568 L<C<import>|/import LIST> method for the package used.  See also
3569 L<C<use>|/use Module VERSION LIST>, L<perlmod>, and L<Exporter>.
3570
3571 =item index STR,SUBSTR,POSITION
3572 X<index> X<indexOf> X<InStr>
3573
3574 =item index STR,SUBSTR
3575
3576 =for Pod::Functions find a substring within a string
3577
3578 The index function searches for one string within another, but without
3579 the wildcard-like behavior of a full regular-expression pattern match.
3580 It returns the position of the first occurrence of SUBSTR in STR at
3581 or after POSITION.  If POSITION is omitted, starts searching from the
3582 beginning of the string.  POSITION before the beginning of the string
3583 or after its end is treated as if it were the beginning or the end,
3584 respectively.  POSITION and the return value are based at zero.
3585 If the substring is not found, L<C<index>|/index STR,SUBSTR,POSITION>
3586 returns -1.
3587
3588 Find characters or strings:
3589
3590     index("Perl is great", "P");     # Returns 0
3591     index("Perl is great", "g");     # Returns 8
3592     index("Perl is great", "great"); # Also returns 8
3593
3594 Attempting to find something not there:
3595
3596     index("Perl is great", "Z");     # Returns -1 (not found)
3597
3598 Using an offset to find the I<second> occurrence:
3599
3600     index("Perl is great", "e", 5);  # Returns 10
3601
3602 =item int EXPR
3603 X<int> X<integer> X<truncate> X<trunc> X<floor>
3604
3605 =item int
3606
3607 =for Pod::Functions get the integer portion of a number
3608
3609 Returns the integer portion of EXPR.  If EXPR is omitted, uses
3610 L<C<$_>|perlvar/$_>.
3611 You should not use this function for rounding: one because it truncates
3612 towards C<0>, and two because machine representations of floating-point
3613 numbers can sometimes produce counterintuitive results.  For example,
3614 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
3615 because it's really more like -268.99999999999994315658 instead.  Usually,
3616 the L<C<sprintf>|/sprintf FORMAT, LIST>,
3617 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>, or the
3618 L<C<POSIX::floor>|POSIX/C<floor>> and L<C<POSIX::ceil>|POSIX/C<ceil>>
3619 functions will serve you better than will L<C<int>|/int EXPR>.
3620
3621 =item ioctl FILEHANDLE,FUNCTION,SCALAR
3622 X<ioctl>
3623
3624 =for Pod::Functions system-dependent device control system call
3625
3626 Implements the L<ioctl(2)> function.  You'll probably first have to say
3627
3628     require "sys/ioctl.ph";  # probably in
3629                              # $Config{archlib}/sys/ioctl.ph
3630
3631 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
3632 exist or doesn't have the correct definitions you'll have to roll your
3633 own, based on your C header files such as F<< <sys/ioctl.h> >>.
3634 (There is a Perl script called B<h2ph> that comes with the Perl kit that
3635 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
3636 written depending on the FUNCTION; a C pointer to the string value of SCALAR
3637 will be passed as the third argument of the actual
3638 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> call.  (If SCALAR
3639 has no string value but does have a numeric value, that value will be
3640 passed rather than a pointer to the string value.  To guarantee this to be
3641 true, add a C<0> to the scalar before using it.)  The
3642 L<C<pack>|/pack TEMPLATE,LIST> and L<C<unpack>|/unpack TEMPLATE,EXPR>
3643 functions may be needed to manipulate the values of structures used by
3644 L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>.
3645
3646 The return value of L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR> (and
3647 L<C<fcntl>|/fcntl FILEHANDLE,FUNCTION,SCALAR>) is as follows:
3648
3649     if OS returns:      then Perl returns:
3650         -1               undefined value
3651          0              string "0 but true"
3652     anything else           that number
3653
3654 Thus Perl returns true on success and false on failure, yet you can
3655 still easily determine the actual value returned by the operating
3656 system:
3657
3658     my $retval = ioctl(...) || -1;
3659     printf "System returned %d\n", $retval;
3660
3661 The special string C<"0 but true"> is exempt from
3662 L<C<Argument "..." isn't numeric>|perldiag/Argument "%s" isn't numeric%s>
3663 L<warnings> on improper numeric conversions.
3664
3665 Portability issues: L<perlport/ioctl>.
3666
3667 =item join EXPR,LIST
3668 X<join>
3669
3670 =for Pod::Functions join a list into a string using a separator
3671
3672 Joins the separate strings of LIST into a single string with fields
3673 separated by the value of EXPR, and returns that new string.  Example:
3674
3675    my $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
3676
3677 Beware that unlike L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>,
3678 L<C<join>|/join EXPR,LIST> doesn't take a pattern as its first argument.
3679 Compare L<C<split>|/split E<sol>PATTERNE<sol>,EXPR,LIMIT>.
3680
3681 =item keys HASH
3682 X<keys> X<key>
3683
3684 =item keys ARRAY
3685
3686 =for Pod::Functions retrieve list of indices from a hash
3687
3688 Called in list context, returns a list consisting of all the keys of the
3689 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
3690 releases prior to 5.12 will produce a syntax error if you try to use an
3691 array argument.  In scalar context, returns the number of keys or indices.
3692
3693 Hash entries are returned in an apparently random order.  The actual random
3694 order is specific to a given hash; the exact same series of operations
3695 on two hashes may result in a different order for each hash.  Any insertion
3696 into the hash may change the order, as will any deletion, with the exception
3697 that the most recent key returned by L<C<each>|/each HASH> or
3698 L<C<keys>|/keys HASH> may be deleted without changing the order.  So
3699 long as a given hash is unmodified you may rely on
3700 L<C<keys>|/keys HASH>, L<C<values>|/values HASH> and L<C<each>|/each
3701 HASH> to repeatedly return the same order
3702 as each other.  See L<perlsec/"Algorithmic Complexity Attacks"> for
3703 details on why hash order is randomized.  Aside from the guarantees
3704 provided here the exact details of Perl's hash algorithm and the hash
3705 traversal order are subject to change in any release of Perl.  Tied hashes
3706 may behave differently to Perl's hashes with respect to changes in order on
3707 insertion and deletion of items.
3708
3709 As a side effect, calling L<C<keys>|/keys HASH> resets the internal
3710 iterator of the HASH or ARRAY (see L<C<each>|/each HASH>) before
3711 yielding the keys.  In
3712 particular, calling L<C<keys>|/keys HASH> in void context resets the
3713 iterator with no other overhead.
3714
3715 Here is yet another way to print your environment:
3716
3717     my @keys = keys %ENV;
3718     my @values = values %ENV;
3719     while (@keys) {
3720         print pop(@keys), '=', pop(@values), "\n";
3721     }
3722
3723 or how about sorted by key:
3724
3725     foreach my $key (sort(keys %ENV)) {
3726         print $key, '=', $ENV{$key}, "\n";
3727     }
3728
3729 The returned values are copies of the original keys in the hash, so
3730 modifying them will not affect the original hash.  Compare
3731 L<C<values>|/values HASH>.
3732
3733 To sort a hash by value, you'll need to use a
3734 L<C<sort>|/sort SUBNAME LIST> function.  Here's a descending numeric
3735 sort of a hash by its values:
3736
3737     foreach my $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
3738         printf "%4d %s\n", $hash{$key}, $key;
3739     }
3740
3741 Used as an lvalue, L<C<keys>|/keys HASH> allows you to increase the
3742 number of hash buckets
3743 allocated for the given hash.  This can gain you a measure of efficiency if
3744 you know the hash is going to get big.  (This is similar to pre-extending
3745 an array by assigning a larger number to $#array.)  If you say
3746
3747     keys %hash = 200;
3748
3749 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
3750 in fact, since it rounds up to the next power of two.  These
3751 buckets will be retained even if you do C<%hash = ()>, use C<undef
3752 %hash> if you want to free the storage while C<%hash> is still in scope.
3753 You can't shrink the number of buckets allocated for the hash using
3754 L<C<keys>|/keys HASH> in this way (but you needn't worry about doing
3755 this by accident, as trying has no effect).  C<keys @array> in an lvalue
3756 context is a syntax error.
3757
3758 Starting with Perl 5.14, an experimental feature allowed
3759 L<C<keys>|/keys HASH> to take a scalar expression. This experiment has
3760 been deemed unsuccessful, and was removed as of Perl 5.24.
3761
3762 To avoid confusing would-be users of your code who are running earlier
3763 versions of Perl with mysterious syntax errors, put this sort of thing at
3764 the top of your file to signal that your code will work I<only> on Perls of
3765 a recent vintage:
3766
3767     use 5.012;  # so keys/values/each work on arrays
3768
3769 See also L<C<each>|/each HASH>, L<C<values>|/values HASH>, and
3770 L<C<sort>|/sort SUBNAME LIST>.
3771
3772 =item kill SIGNAL, LIST
3773
3774 =item kill SIGNAL
3775 X<kill> X<signal>
3776
3777 =for Pod::Functions send a signal to a process or process group
3778
3779 Sends a signal to a list of processes.  Returns the number of arguments
3780 that were successfully used to signal (which is not necessarily the same
3781 as the number of processes actually killed, e.g. where a process group is
3782 killed).
3783
3784     my $cnt = kill 'HUP', $child1, $child2;
3785     kill 'KILL', @goners;
3786
3787 SIGNAL may be either a signal name (a string) or a signal number.  A signal
3788 name may start with a C<SIG> prefix, thus C<FOO> and C<SIGFOO> refer to the
3789 same signal.  The string form of SIGNAL is recommended for portability because
3790 the same signal may have different numbers in different operating systems.
3791
3792 A list of signal names supported by the current platform can be found in
3793 C<$Config{sig_name}>, which is provided by the L<C<Config>|Config>
3794 module.  See L<Config> for more details.
3795
3796 A negative signal name is the same as a negative signal number, killing process
3797 groups instead of processes.  For example, C<kill '-KILL', $pgrp> and
3798 C<kill -9, $pgrp> will send C<SIGKILL> to
3799 the entire process group specified.  That
3800 means you usually want to use positive not negative signals.
3801
3802 If SIGNAL is either the number 0 or the string C<ZERO> (or C<SIGZERO>),
3803 no signal is sent to the process, but L<C<kill>|/kill SIGNAL, LIST>
3804 checks whether it's I<possible> to send a signal to it
3805 (that means, to be brief, that the process is owned by the same user, or we are
3806 the super-user).  This is useful to check that a child process is still
3807 alive (even if only as a zombie) and hasn't changed its UID.  See
3808 L<perlport> for notes on the portability of this construct.
3809
3810 The behavior of kill when a I<PROCESS> number is zero or negative depends on
3811 the operating system.  For example, on POSIX-conforming systems, zero will
3812 signal the current process group, -1 will signal all processes, and any
3813 other negative PROCESS number will act as a negative signal number and
3814 kill the entire process group specified.
3815
3816 If both the SIGNAL and the PROCESS are negative, the results are undefined.
3817 A warning may be produced in a future version.
3818
3819 See L<perlipc/"Signals"> for more details.
3820
3821 On some platforms such as Windows where the L<fork(2)> system call is not
3822 available, Perl can be built to emulate L<C<fork>|/fork> at the
3823 interpreter level.
3824 This emulation has limitations related to kill that have to be considered,
3825 for code running on Windows and in code intended to be portable.
3826
3827 See L<perlfork> for more details.
3828
3829 If there is no I<LIST> of processes, no signal is sent, and the return
3830 value is 0.  This form is sometimes used, however, because it causes
3831 tainting checks to be run.  But see
3832 L<perlsec/Laundering and Detecting Tainted Data>.
3833
3834 Portability issues: L<perlport/kill>.
3835
3836 =item last LABEL
3837 X<last> X<break>
3838
3839 =item last EXPR
3840
3841 =item last
3842
3843 =for Pod::Functions exit a block prematurely
3844
3845 The L<C<last>|/last LABEL> command is like the C<break> statement in C
3846 (as used in
3847 loops); it immediately exits the loop in question.  If the LABEL is
3848 omitted, the command refers to the innermost enclosing
3849 loop.  The C<last EXPR> form, available starting in Perl
3850 5.18.0, allows a label name to be computed at run time,
3851 and is otherwise identical to C<last LABEL>.  The
3852 L<C<continue>|/continue BLOCK> block, if any, is not executed:
3853
3854     LINE: while (<STDIN>) {
3855         last LINE if /^$/;  # exit when done with header
3856         #...
3857     }
3858
3859 L<C<last>|/last LABEL> cannot return a value from a block that typically
3860 returns a value, such as C<eval {}>, C<sub {}>, or C<do {}>. It will perform
3861 its flow control behavior, which precludes any return value. It should not be
3862 used to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
3863 operation.
3864
3865 Note that a block by itself is semantically identical to a loop
3866 that executes once.  Thus L<C<last>|/last LABEL> can be used to effect
3867 an early exit out of such a block.
3868
3869 See also L<C<continue>|/continue BLOCK> for an illustration of how
3870 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
3871 L<C<redo>|/redo LABEL> work.
3872
3873 Unlike most named operators, this has the same precedence as assignment.
3874 It is also exempt from the looks-like-a-function rule, so
3875 C<last ("foo")."bar"> will cause "bar" to be part of the argument to
3876 L<C<last>|/last LABEL>.
3877
3878 =item lc EXPR
3879 X<lc> X<lowercase>
3880
3881 =item lc
3882
3883 =for Pod::Functions return lower-case version of a string
3884
3885 Returns a lowercased version of EXPR.  This is the internal function
3886 implementing the C<\L> escape in double-quoted strings.
3887
3888 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3889
3890 What gets returned depends on several factors:
3891
3892 =over
3893
3894 =item If C<use bytes> is in effect:
3895
3896 The results follow ASCII rules.  Only the characters C<A-Z> change,
3897 to C<a-z> respectively.
3898
3899 =item Otherwise, if C<use locale> for C<LC_CTYPE> is in effect:
3900
3901 Respects current C<LC_CTYPE> locale for code points < 256; and uses Unicode
3902 rules for the remaining code points (this last can only happen if
3903 the UTF8 flag is also set).  See L<perllocale>.
3904
3905 Starting in v5.20, Perl uses full Unicode rules if the locale is
3906 UTF-8.  Otherwise, there is a deficiency in this scheme, which is that
3907 case changes that cross the 255/256
3908 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3909 LETTER SHARP S (U+1E9E) in Unicode rules is U+00DF (on ASCII
3910 platforms).   But under C<use locale> (prior to v5.20 or not a UTF-8
3911 locale), the lower case of U+1E9E is
3912 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3913 current locale, and Perl has no way of knowing if that character even
3914 exists in the locale, much less what code point it is.  Perl returns
3915 a result that is above 255 (almost always the input character unchanged),
3916 for all instances (and there aren't many) where the 255/256 boundary
3917 would otherwise be crossed; and starting in v5.22, it raises a
3918 L<locale|perldiag/Can't do %s("%s") on non-UTF-8 locale; resolved to "%s".> warning.
3919
3920 =item Otherwise, If EXPR has the UTF8 flag set:
3921
3922 Unicode rules are used for the case change.
3923
3924 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'> is in effect:
3925
3926 Unicode rules are used for the case change.
3927
3928 =item Otherwise:
3929
3930 ASCII rules are used for the case change.  The lowercase of any character
3931 outside the ASCII range is the character itself.
3932
3933 =back
3934
3935 =item lcfirst EXPR
3936 X<lcfirst> X<lowercase>
3937
3938 =item lcfirst
3939
3940 =for Pod::Functions return a string with just the next letter in lower case
3941
3942 Returns the value of EXPR with the first character lowercased.  This
3943 is the internal function implementing the C<\l> escape in
3944 double-quoted strings.
3945
3946 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.
3947
3948 This function behaves the same way under various pragmas, such as in a locale,
3949 as L<C<lc>|/lc EXPR> does.
3950
3951 =item length EXPR
3952 X<length> X<size>
3953
3954 =item length
3955
3956 =for Pod::Functions return the number of characters in a string
3957
3958 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3959 omitted, returns the length of L<C<$_>|perlvar/$_>.  If EXPR is
3960 undefined, returns L<C<undef>|/undef EXPR>.
3961
3962 This function cannot be used on an entire array or hash to find out how
3963 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3964 %hash>, respectively.
3965
3966 Like all Perl character operations, L<C<length>|/length EXPR> normally
3967 deals in logical
3968 characters, not physical bytes.  For how many bytes a string encoded as
3969 UTF-8 would take up, use C<length(Encode::encode('UTF-8', EXPR))>
3970 (you'll have to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3971
3972 =item __LINE__
3973 X<__LINE__>
3974
3975 =for Pod::Functions the current source line number
3976
3977 A special token that compiles to the current line number.
3978 It can be altered by the mechanism described at
3979 L<perlsyn/"Plain Old Comments (Not!)">.
3980
3981 =item link OLDFILE,NEWFILE
3982 X<link>
3983
3984 =for Pod::Functions create a hard link in the filesystem
3985
3986 Creates a new filename linked to the old filename.  Returns true for
3987 success, false otherwise.
3988
3989 Portability issues: L<perlport/link>.
3990
3991 =item listen SOCKET,QUEUESIZE
3992 X<listen>
3993
3994 =for Pod::Functions register your socket as a server
3995
3996 Does the same thing that the L<listen(2)> system call does.  Returns true if
3997 it succeeded, false otherwise.  See the example in
3998 L<perlipc/"Sockets: Client/Server Communication">.
3999
4000 =item local EXPR
4001 X<local>
4002
4003 =for Pod::Functions create a temporary value for a global variable (dynamic scoping)
4004
4005 You really probably want to be using L<C<my>|/my VARLIST> instead,
4006 because L<C<local>|/local EXPR> isn't what most people think of as
4007 "local".  See L<perlsub/"Private Variables via my()"> for details.
4008
4009 A local modifies the listed variables to be local to the enclosing
4010 block, file, or eval.  If more than one value is listed, the list must
4011 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
4012 for details, including issues with tied arrays and hashes.
4013
4014 The C<delete local EXPR> construct can also be used to localize the deletion
4015 of array/hash elements to the current block.
4016 See L<perlsub/"Localized deletion of elements of composite types">.
4017
4018 =item localtime EXPR
4019 X<localtime> X<ctime>
4020
4021 =item localtime
4022
4023 =for Pod::Functions convert UNIX time into record or string using local time
4024
4025 Converts a time as returned by the time function to a 9-element list
4026 with the time analyzed for the local time zone.  Typically used as
4027 follows:
4028
4029     #     0    1    2     3     4    5     6     7     8
4030     my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
4031                                                 localtime(time);
4032
4033 All list elements are numeric and come straight out of the C `struct
4034 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
4035 of the specified time.
4036
4037 C<$mday> is the day of the month and C<$mon> the month in
4038 the range C<0..11>, with 0 indicating January and 11 indicating December.
4039 This makes it easy to get a month name from a list:
4040
4041     my @abbr = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
4042     print "$abbr[$mon] $mday";
4043     # $mon=9, $mday=18 gives "Oct 18"
4044
4045 C<$year> contains the number of years since 1900.  To get a 4-digit
4046 year write:
4047
4048     $year += 1900;
4049
4050 To get the last two digits of the year (e.g., "01" in 2001) do:
4051
4052     $year = sprintf("%02d", $year % 100);
4053
4054 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
4055 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
4056 (or C<0..365> in leap years.)
4057
4058 C<$isdst> is true if the specified time occurs when Daylight Saving
4059 Time is in effect, false otherwise.
4060
4061 If EXPR is omitted, L<C<localtime>|/localtime EXPR> uses the current
4062 time (as returned by L<C<time>|/time>).
4063
4064 In scalar context, L<C<localtime>|/localtime EXPR> returns the
4065 L<ctime(3)> value:
4066
4067  my $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
4068
4069 This scalar value is always in English, and is B<not> locale-dependent.
4070 To get similar but locale-dependent date strings, try for example:
4071
4072  use POSIX qw(strftime);
4073  my $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
4074  # or for GMT formatted appropriately for your locale:
4075  my $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
4076
4077 C$now_string> will be formatted according to the current LC_TIME locale
4078 the program or thread is running in.  See L<perllocale> for how to set
4079 up and change that locale.  Note that C<%a> and C<%b>, the short forms
4080 of the day of the week and the month of the year, may not necessarily be
4081 three characters wide.
4082
4083 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
4084 by-name access mechanism to the L<C<gmtime>|/gmtime EXPR> and
4085 L<C<localtime>|/localtime EXPR> functions, respectively.
4086
4087 For a comprehensive date and time representation look at the
4088 L<DateTime> module on CPAN.
4089
4090 For GMT instead of local time use the L<C<gmtime>|/gmtime EXPR> builtin.
4091
4092 See also the L<C<Time::Local>|Time::Local> module (for converting
4093 seconds, minutes, hours, and such back to the integer value returned by
4094 L<C<time>|/time>), and the L<POSIX> module's
4095 L<C<mktime>|POSIX/C<mktime>> function.
4096
4097 Portability issues: L<perlport/localtime>.
4098
4099 =item lock THING
4100 X<lock>
4101
4102 =for Pod::Functions +5.005 get a thread lock on a variable, subroutine, or method
4103
4104 This function places an advisory lock on a shared variable or referenced
4105 object contained in I<THING> until the lock goes out of scope.
4106
4107 The value returned is the scalar itself, if the argument is a scalar, or a
4108 reference, if the argument is a hash, array or subroutine.
4109
4110 L<C<lock>|/lock THING> is a "weak keyword"; this means that if you've
4111 defined a function
4112 by this name (before any calls to it), that function will be called
4113 instead.  If you are not under C<use threads::shared> this does nothing.
4114 See L<threads::shared>.
4115
4116 =item log EXPR
4117 X<log> X<logarithm> X<e> X<ln> X<base>
4118
4119 =item log
4120
4121 =for Pod::Functions retrieve the natural logarithm for a number
4122
4123 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
4124 returns the log of L<C<$_>|perlvar/$_>.  To get the
4125 log of another base, use basic algebra:
4126 The base-N log of a number is equal to the natural log of that number
4127 divided by the natural log of N.  For example:
4128
4129     sub log10 {
4130         my $n = shift;
4131         return log($n)/log(10);
4132     }
4133
4134 See also L<C<exp>|/exp EXPR> for the inverse operation.
4135
4136 =item lstat FILEHANDLE
4137 X<lstat>
4138
4139 =item lstat EXPR
4140
4141 =item lstat DIRHANDLE
4142
4143 =item lstat
4144
4145 =for Pod::Functions stat a symbolic link
4146
4147 Does the same thing as the L<C<stat>|/stat FILEHANDLE> function
4148 (including setting the special C<_> filehandle) but stats a symbolic
4149 link instead of the file the symbolic link points to.  If symbolic links
4150 are unimplemented on your system, a normal L<C<stat>|/stat FILEHANDLE>
4151 is done.  For much more detailed information, please see the
4152 documentation for L<C<stat>|/stat FILEHANDLE>.
4153
4154 If EXPR is omitted, stats L<C<$_>|perlvar/$_>.
4155
4156 Portability issues: L<perlport/lstat>.
4157
4158 =item m//
4159
4160 =for Pod::Functions match a string with a regular expression pattern
4161
4162 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
4163
4164 =item map BLOCK LIST
4165 X<map>
4166
4167 =item map EXPR,LIST
4168
4169 =for Pod::Functions apply a change to a list to get back a new list with the changes
4170
4171 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
4172 L<C<$_>|perlvar/$_> to each element) and composes a list of the results of
4173 each such evaluation.  Each element of LIST may produce zero, one, or more
4174 elements in the generated list, so the number of elements in the generated
4175 list may differ from that in LIST.  In scalar context, returns the total
4176 number of elements so generated.  In list context, returns the generated list.
4177
4178     my @chars = map(chr, @numbers);
4179
4180 translates a list of numbers to the corresponding characters.
4181
4182     my @squares = map { $_ * $_ } @numbers;
4183
4184 translates a list of numbers to their squared values.
4185
4186     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
4187
4188 shows that number of returned elements can differ from the number of
4189 input elements.  To omit an element, return an empty list ().
4190 This could also be achieved by writing
4191
4192     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
4193
4194 which makes the intention more clear.
4195
4196 Map always returns a list, which can be
4197 assigned to a hash such that the elements
4198 become key/value pairs.  See L<perldata> for more details.
4199
4200     my %hash = map { get_a_key_for($_) => $_ } @array;
4201
4202 is just a funny way to write
4203
4204     my %hash;
4205     foreach (@array) {
4206         $hash{get_a_key_for($_)} = $_;
4207     }
4208
4209 Note that L<C<$_>|perlvar/$_> is an alias to the list value, so it can
4210 be used to modify the elements of the LIST.  While this is useful and
4211 supported, it can cause bizarre results if the elements of LIST are not
4212 variables.  Using a regular C<foreach> loop for this purpose would be
4213 clearer in most cases.  See also L<C<grep>|/grep BLOCK LIST> for a
4214 list composed of those items of the original list for which the BLOCK
4215 or EXPR evaluates to true.
4216
4217 C<{> starts both hash references and blocks, so C<map { ...> could be either
4218 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
4219 ahead for the closing C<}> it has to take a guess at which it's dealing with
4220 based on what it finds just after the
4221 C<{>.  Usually it gets it right, but if it
4222 doesn't it won't realize something is wrong until it gets to the C<}> and
4223 encounters the missing (or unexpected) comma.  The syntax error will be
4224 reported close to the C<}>, but you'll need to change something near the C<{>
4225 such as using a unary C<+> or semicolon to give Perl some help:
4226
4227  my %hash = map {  "\L$_" => 1  } @array # perl guesses EXPR. wrong
4228  my %hash = map { +"\L$_" => 1  } @array # perl guesses BLOCK. right
4229  my %hash = map {; "\L$_" => 1  } @array # this also works
4230  my %hash = map { ("\L$_" => 1) } @array # as does this
4231  my %hash = map {  lc($_) => 1  } @array # and this.
4232  my %hash = map +( lc($_) => 1 ), @array # this is EXPR and works!
4233
4234  my %hash = map  ( lc($_), 1 ),   @array # evaluates to (1, @array)
4235
4236 or to force an anon hash constructor use C<+{>:
4237
4238     my @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs
4239                                               # comma at end
4240
4241 to get a list of anonymous hashes each with only one entry apiece.
4242
4243 =item mkdir FILENAME,MODE
4244 X<mkdir> X<md> X<directory, create>
4245
4246 =item mkdir FILENAME
4247
4248 =item mkdir
4249
4250 =for Pod::Functions create a directory
4251
4252 Creates the directory specified by FILENAME, with permissions
4253 specified by MODE (as modified by L<C<umask>|/umask EXPR>).  If it
4254 succeeds it returns true; otherwise it returns false and sets
4255 L<C<$!>|perlvar/$!> (errno).
4256 MODE defaults to 0777 if omitted, and FILENAME defaults
4257 to L<C<$_>|perlvar/$_> if omitted.
4258
4259 In general, it is better to create directories with a permissive MODE
4260 and let the user modify that with their L<C<umask>|/umask EXPR> than it
4261 is to supply
4262 a restrictive MODE and give the user no way to be more permissive.
4263 The exceptions to this rule are when the file or directory should be
4264 kept private (mail files, for instance).  The documentation for
4265 L<C<umask>|/umask EXPR> discusses the choice of MODE in more detail.
4266
4267 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
4268 number of trailing slashes.  Some operating and filesystems do not get
4269 this right, so Perl automatically removes all trailing slashes to keep
4270 everyone happy.
4271
4272 To recursively create a directory structure, look at
4273 the L<C<make_path>|File::Path/make_path( $dir1, $dir2, .... )> function
4274 of the L<File::Path> module.
4275
4276 =item msgctl ID,CMD,ARG
4277 X<msgctl>
4278
4279 =for Pod::Functions SysV IPC message control operations
4280
4281 Calls the System V IPC function L<msgctl(2)>.  You'll probably have to say
4282
4283     use IPC::SysV;
4284
4285 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4286 then ARG must be a variable that will hold the returned C<msqid_ds>
4287 structure.  Returns like L<C<ioctl>|/ioctl FILEHANDLE,FUNCTION,SCALAR>:
4288 the undefined value for error, C<"0 but true"> for zero, or the actual
4289 return value otherwise.  See also L<perlipc/"SysV IPC"> and the
4290 documentation for L<C<IPC::SysV>|IPC::SysV> and
4291 L<C<IPC::Semaphore>|IPC::Semaphore>.
4292
4293 Portability issues: L<perlport/msgctl>.
4294
4295 =item msgget KEY,FLAGS
4296 X<msgget>
4297
4298 =for Pod::Functions get SysV IPC message queue
4299
4300 Calls the System V IPC function L<msgget(2)>.  Returns the message queue
4301 id, or L<C<undef>|/undef EXPR> on error.  See also L<perlipc/"SysV IPC">
4302 and the documentation for L<C<IPC::SysV>|IPC::SysV> and
4303 L<C<IPC::Msg>|IPC::Msg>.
4304
4305 Portability issues: L<perlport/msgget>.
4306
4307 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
4308 X<msgrcv>
4309
4310 =for Pod::Functions receive a SysV IPC message from a message queue
4311
4312 Calls the System V IPC function msgrcv to receive a message from
4313 message queue ID into variable VAR with a maximum message size of
4314 SIZE.  Note that when a message is received, the message type as a
4315 native long integer will be the first thing in VAR, followed by the
4316 actual message.  This packing may be opened with C<unpack("l! a*")>.
4317 Taints the variable.  Returns true if successful, false
4318 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
4319 L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4320
4321 Portability issues: L<perlport/msgrcv>.
4322
4323 =item msgsnd ID,MSG,FLAGS
4324 X<msgsnd>
4325
4326 =for Pod::Functions send a SysV IPC message to a message queue
4327
4328 Calls the System V IPC function msgsnd to send the message MSG to the
4329 message queue ID.  MSG must begin with the native long integer message
4330 type, followed by the message itself.  This kind of packing can be achieved
4331 with C<pack("l! a*", $type, $message)>.  Returns true if successful,
4332 false on error.  See also L<perlipc/"SysV IPC"> and the documentation
4333 for L<C<IPC::SysV>|IPC::SysV> and L<C<IPC::Msg>|IPC::Msg>.
4334
4335 Portability issues: L<perlport/msgsnd>.
4336
4337 =item my VARLIST
4338 X<my>
4339
4340 =item my TYPE VARLIST
4341
4342 =item my VARLIST : ATTRS
4343
4344 =item my TYPE VARLIST : ATTRS
4345
4346 =for Pod::Functions declare and assign a local variable (lexical scoping)
4347
4348 A L<C<my>|/my VARLIST> declares the listed variables to be local
4349 (lexically) to the enclosing block, file, or L<C<eval>|/eval EXPR>.  If
4350 more than one variable is listed, the list must be placed in
4351 parentheses.
4352
4353 The exact semantics and interface of TYPE and ATTRS are still
4354 evolving.  TYPE may be a bareword, a constant declared
4355 with L<C<use constant>|constant>, or L<C<__PACKAGE__>|/__PACKAGE__>.  It
4356 is
4357 currently bound to the use of the L<fields> pragma,
4358 and attributes are handled using the L<attributes> pragma, or starting
4359 from Perl 5.8.0 also via the L<Attribute::Handlers> module.  See
4360 L<perlsub/"Private Variables via my()"> for details.
4361
4362 Note that with a parenthesised list, L<C<undef>|/undef EXPR> can be used
4363 as a dummy placeholder, for example to skip assignment of initial
4364 values:
4365
4366     my ( undef, $min, $hour ) = localtime;
4367
4368 =item next LABEL
4369 X<next> X<continue>
4370
4371 =item next EXPR
4372
4373 =item next
4374
4375 =for Pod::Functions iterate a block prematurely
4376
4377 The L<C<next>|/next LABEL> command is like the C<continue> statement in
4378 C; it starts the next iteration of the loop:
4379
4380     LINE: while (<STDIN>) {
4381         next LINE if /^#/;  # discard comments
4382         #...
4383     }
4384
4385 Note that if there were a L<C<continue>|/continue BLOCK> block on the
4386 above, it would get
4387 executed even on discarded lines.  If LABEL is omitted, the command
4388 refers to the innermost enclosing loop.  The C<next EXPR> form, available
4389 as of Perl 5.18.0, allows a label name to be computed at run time, being
4390 otherwise identical to C<next LABEL>.
4391
4392 L<C<next>|/next LABEL> cannot return a value from a block that typically
4393 returns a value, such as C<eval {}>, C<sub {}>, or C<do {}>. It will perform
4394 its flow control behavior, which precludes any return value. It should not be
4395 used to exit a L<C<grep>|/grep BLOCK LIST> or L<C<map>|/map BLOCK LIST>
4396 operation.
4397
4398 Note that a block by itself is semantically identical to a loop
4399 that executes once.  Thus L<C<next>|/next LABEL> will exit such a block
4400 early.
4401
4402 See also L<C<continue>|/continue BLOCK> for an illustration of how
4403 L<C<last>|/last LABEL>, L<C<next>|/next LABEL>, and
4404 L<C<redo>|/redo LABEL> work.
4405
4406 Unlike most named operators, this has the same precedence as assignment.
4407 It is also exempt from the looks-like-a-function rule, so
4408 C<next ("foo")."bar"> will cause "bar" to be part of the argument to
4409 L<C<next>|/next LABEL>.
4410
4411 =item no MODULE VERSION LIST
4412 X<no declarations>
4413 X<unimporting>
4414
4415 =item no MODULE VERSION
4416
4417 =item no MODULE LIST
4418
4419 =item no MODULE
4420
4421 =item no VERSION
4422
4423 =for Pod::Functions unimport some module symbols or semantics at compile time
4424
4425 See the L<C<use>|/use Module VERSION LIST> function, of which
4426 L<C<no>|/no MODULE VERSION LIST> is the opposite.
4427
4428 =item oct EXPR
4429 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
4430
4431 =item oct
4432
4433 =for Pod::Functions convert a string to an octal number
4434
4435 Interprets EXPR as an octal string and returns the corresponding
4436 value.  An octal string consists of octal digits and, as of Perl 5.33.5,
4437 an optional C<0o> or C<o> prefix.  Each octal digit may be preceded by
4438 a single underscore, which will be ignored.
4439 (If EXPR happens to start off with C<0x> or C<x>, interprets it as a
4440 hex string.  If EXPR starts off with C<0b> or C<b>, it is interpreted as a
4441 binary string.  Leading whitespace is ignored in all three cases.)
4442 The following will handle decimal, binary, octal, and hex in standard
4443 Perl notation:
4444
4445     $val = oct($val) if $val =~ /^0/;
4446
4447 If EXPR is omitted, uses L<C<$_>|perlvar/$_>.   To go the other way
4448 (produce a number in octal), use L<C<sprintf>|/sprintf FORMAT, LIST> or
4449 L<C<printf>|/printf FILEHANDLE FORMAT, LIST>:
4450
4451     my $dec_perms = (stat("filename"))[2] & 07777;
4452     my $oct_perm_str = sprintf "%o", $perms;
4453
4454 The L<C<oct>|/oct EXPR> function is commonly used when a string such as
4455 C<644> needs
4456 to be converted into a file mode, for example.  Although Perl
4457 automatically converts strings into numbers as needed, this automatic
4458 conversion assumes base 10.
4459
4460 Leading white space is ignored without warning, as too are any trailing
4461 non-digits, such as a decimal point (L<C<oct>|/oct EXPR> only handles
4462 non-negative integers, not negative integers or floating point).
4463
4464 =item open FILEHANDLE,MODE,EXPR
4465 X<open> X<pipe> X<file, open> X<fopen>
4466
4467 =item open FILEHANDLE,MODE,EXPR,LIST
4468
4469 =item open FILEHANDLE,MODE,REFERENCE
4470
4471 =item open FILEHANDLE,EXPR
4472
4473 =item open FILEHANDLE
4474
4475 =for Pod::Functions open a file, pipe, or descriptor
4476
4477 Associates an internal FILEHANDLE with the external file specified by
4478 EXPR. That filehandle will subsequently allow you to perform
4479 I/O operations on that file, such as reading from it or writing to it.
4480
4481 Instead of a filename, you may specify an external command
4482 (plus an optional argument list) or a scalar reference, in order to open
4483 filehandles on commands or in-memory scalars, respectively.
4484
4485 A thorough reference to C<open> follows. For a gentler introduction to
4486 the basics of C<open>, see also the L<perlopentut> manual page.
4487
4488 =over
4489
4490 =item Working with files
4491
4492 Most often, C<open> gets invoked with three arguments: the required
4493 FILEHANDLE (usually an empty scalar variable), followed by MODE (usually
4494 a literal describing the I/O mode the filehandle will use), and then the
4495 filename  that the new filehandle will refer to.
4496
4497 =over
4498
4499 =item Simple examples
4500
4501 Reading from a file:
4502
4503     open(my $fh, "<", "input.txt")
4504         or die "Can't open < input.txt: $!";
4505
4506     # Process every line in input.txt
4507     while (my $line = <$fh>) {
4508         #
4509         # ... do something interesting with $line here ...
4510         #
4511     }
4512
4513 or writing to one:
4514
4515     open(my $fh, ">", "output.txt")
4516         or die "Can't open > output.txt: $!";
4517
4518     print $fh "This line gets printed into output.txt.\n";
4519
4520 For a summary of common filehandle operations such as these, see
4521 L<perlintro/Files and I/O>.
4522
4523 =item About filehandles
4524
4525 The first argument to C<open>, labeled FILEHANDLE in this reference, is
4526 usually a scalar variable. (Exceptions exist, described in "Other
4527 considerations", below.) If the call to C<open> succeeds, then the
4528 expression provided as FILEHANDLE will get assigned an open
4529 I<filehandle>. That filehandle provides an internal reference to the
4530 specified external file, conveniently stored in a Perl variable, and
4531 ready for I/O operations such as reading and writing.
4532
4533 =item About modes
4534
4535 When calling C<open> with three or more arguments, the second argument
4536 -- labeled MODE here -- defines the I<open mode>. MODE is usually a
4537 literal string comprising special characters that define the intended
4538 I/O role of the filehandle being created: whether it's read-only, or
4539 read-and-write, and so on.
4540
4541 If MODE is C<< < >>, the file is opened for input (read-only).
4542 If MODE is C<< > >>, the file is opened for output, with existing files
4543 first being truncated ("clobbered") and nonexisting files newly created.
4544 If MODE is C<<< >> >>>, the file is opened for appending, again being
4545 created if necessary.
4546
4547 You can put a C<+> in front of the C<< > >> or C<< < >> to
4548 indicate that you want both read and write access to the file; thus
4549 C<< +< >> is almost always preferred for read/write updates--the
4550 C<< +> >> mode would clobber the file first.  You can't usually use
4551 either read-write mode for updating textfiles, since they have
4552 variable-length records.  See the B<-i> switch in
4553 L<perlrun|perlrun/-i[extension]> for a better approach.  The file is
4554 created with permissions of C<0666> modified by the process's
4555 L<C<umask>|/umask EXPR> value.
4556
4557 These various prefixes correspond to the L<fopen(3)> modes of C<r>,
4558 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
4559
4560 More examples of different modes in action:
4561
4562  # Open a file for concatenation
4563  open(my $log, ">>", "/usr/spool/news/twitlog")
4564      or warn "Couldn't open log file; discarding input";
4565
4566  # Open a file for reading and writing
4567  open(my $dbase, "+<", "dbase.mine")
4568      or die "Can't open 'dbase.mine' for update: $!";
4569
4570 =item Checking the return value
4571
4572 Open returns nonzero on success, the undefined value otherwise.  If the
4573 C<open> involved a pipe, the return value happens to be the pid of the
4574 subprocess.
4575
4576 When opening a file, it's seldom a good idea to continue if the request
4577 failed, so C<open> is frequently used with L<C<die>|/die LIST>. Even if
4578 you want your code to do something other than C<die> on a failed open,
4579 you should still always check the return value from opening a file.
4580
4581 =back
4582
4583 =item Specifying I/O layers in MODE
4584
4585 You can use the three-argument form of open to specify
4586 I/O layers (sometimes referred to as "disciplines") to apply to the new
4587 filehandle. These affect how the input and output are processed (see
4588 L<open> and
4589 L<PerlIO> for more details).  For example:
4590
4591     open(my $fh, "<:encoding(UTF-8)", $filename)
4592         || die "Can't open UTF-8 encoded $filename: $!";
4593
4594 This opens the UTF8-encoded file containing Unicode characters;
4595 see L<perluniintro>.  Note that if layers are specified in the
4596 three-argument form, then default layers stored in
4597 L<C<${^OPEN}>|perlvar/${^OPEN}>
4598 (usually set by the L<open> pragma or the switch C<-CioD>) are ignored.
4599 Those layers will also be ignored if you specify a colon with no name
4600 following it.  In that case the default layer for the operating system
4601 (:raw on Unix, :crlf on Windows) is used.
4602
4603 On some systems (in general, DOS- and Windows-based systems)
4604 L<C<binmode>|/binmode FILEHANDLE, LAYER> is necessary when you're not
4605 working with a text file.  For the sake of portability it is a good idea
4606 always to use it when appropriate, and never to use it when it isn't
4607 appropriate.  Also, people can set their I/O to be by default
4608 UTF8-encoded Unicode, not bytes.
4609
4610 =item Using C<undef> for temporary files
4611
4612 As a special case the three-argument form with a read/write mode and the third
4613 argument being L<C<undef>|/undef EXPR>:
4614
4615     open(my $tmp, "+>", undef) or die ...
4616
4617 opens a filehandle to a newly created empty anonymous temporary file.
4618 (This happens under any mode, which makes C<< +> >> the only useful and
4619 sensible mode to use.)  You will need to
4620 L<C<seek>|/seek FILEHANDLE,POSITION,WHENCE> to do the reading.
4621
4622
4623 =item Opening a filehandle into an in-memory scalar
4624
4625 You can open filehandles directly to Perl scalars instead of a file or
4626 other resource external to the program. To do so, provide a reference to
4627 that scalar as the third argument to C<open>, like so:
4628
4629  open(my $memory, ">", \$var)
4630      or die "Can't open memory file: $!";
4631  print $memory "foo!\n";    # output will appear in $var
4632
4633 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
4634
4635     close STDOUT;
4636     open(STDOUT, ">", \$variable)
4637         or die "Can't open STDOUT: $!";
4638
4639 The scalars for in-memory files are treated as octet strings: unless
4640 the file is being opened with truncation the scalar may not contain
4641 any code points over 0xFF.
4642
4643 Opening in-memory files I<can> fail for a variety of reasons.  As with
4644 any other C<open>, check the return value for success.
4645
4646 I<Technical note>: This feature works only when Perl is built with
4647 PerlIO -- the default, except with older (pre-5.16) Perl installations
4648 that were configured to not include it (e.g. via C<Configure
4649 -Uuseperlio>). You can see whether your Perl was built with PerlIO by
4650 running C<perl -V:useperlio>.  If it says C<'define'>, you have PerlIO;
4651 otherwise you don't.
4652
4653 See L<perliol> for detailed info on PerlIO.
4654
4655 =item Opening a filehandle into a command
4656
4657 If MODE is C<|->, then the filename is
4658 interpreted as a command to which output is to be piped, and if MODE
4659 is C<-|>, the filename is interpreted as a command that pipes
4660 output to us.  In the two-argument (and one-argument) form, one should
4661 replace dash (C<->) with the command.
4662 See L<perlipc/"Using open() for IPC"> for more examples of this.
4663 (You are not allowed to L<C<open>|/open FILEHANDLE,MODE,EXPR> to a command
4664 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>, and
4665 L<perlipc/"Bidirectional Communication with Another Process"> for
4666 alternatives.)
4667
4668
4669  open(my $article_fh, "-|", "caesar <$article")  # decrypt
4670                                                  # article
4671      or die "Can't start caesar: $!";
4672
4673  open(my $article_fh, "caesar <$article |")      # ditto
4674      or die "Can't start caesar: $!";
4675
4676  open(my $out_fh, "|-", "sort >Tmp$$")    # $$ is our process id
4677      or die "Can't start sort: $!";
4678
4679
4680 In the form of pipe opens taking three or more arguments, if LIST is specified
4681 (extra arguments after the command name) then LIST becomes arguments
4682 to the command invoked if the platform supports it.  The meaning of
4683 L<C<open>|/open FILEHANDLE,MODE,EXPR> with more than three arguments for
4684 non-pipe modes is not yet defined, but experimental "layers" may give
4685 extra LIST arguments meaning.
4686
4687 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
4688 with the one- or two-argument forms of
4689 L<C<open>|/open FILEHANDLE,MODE,EXPR>), an implicit L<C<fork>|/fork> is done,
4690 so L<C<open>|/open FILEHANDLE,MODE,EXPR> returns twice: in the parent process
4691 it returns the pid
4692 of the child process, and in the child process it returns (a defined) C<0>.
4693 Use C<defined($pid)> or C<//> to determine whether the open was successful.
4694
4695 For example, use either
4696
4697    my $child_pid = open(my $from_kid, "-|")
4698         // die "Can't fork: $!";
4699
4700 or
4701