This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
clarify significance of parens for "x" (from M.J.T. Guy
[perl5.git] / pod / perlop.pod
1 =head1 NAME
2
3 perlop - Perl operators and precedence
4
5 =head1 SYNOPSIS
6
7 Perl operators have the following associativity and precedence,
8 listed from highest precedence to lowest.  Operators borrowed from
9 C keep the same precedence relationship with each other, even where
10 C's precedence is slightly screwy.  (This makes learning Perl easier
11 for C folks.)  With very few exceptions, these all operate on scalar
12 values only, not array values.
13
14     left        terms and list operators (leftward)
15     left        ->
16     nonassoc    ++ --
17     right       **
18     right       ! ~ \ and unary + and -
19     left        =~ !~
20     left        * / % x
21     left        + - .
22     left        << >>
23     nonassoc    named unary operators
24     nonassoc    < > <= >= lt gt le ge
25     nonassoc    == != <=> eq ne cmp
26     left        &
27     left        | ^
28     left        &&
29     left        ||
30     nonassoc    ..  ...
31     right       ?:
32     right       = += -= *= etc.
33     left        , =>
34     nonassoc    list operators (rightward)
35     right       not
36     left        and
37     left        or xor
38
39 In the following sections, these operators are covered in precedence order.
40
41 Many operators can be overloaded for objects.  See L<overload>.
42
43 =head1 DESCRIPTION
44
45 =head2 Terms and List Operators (Leftward)
46
47 A TERM has the highest precedence in Perl.  They include variables,
48 quote and quote-like operators, any expression in parentheses,
49 and any function whose arguments are parenthesized.  Actually, there
50 aren't really functions in this sense, just list operators and unary
51 operators behaving as functions because you put parentheses around
52 the arguments.  These are all documented in L<perlfunc>.
53
54 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
55 is followed by a left parenthesis as the next token, the operator and
56 arguments within parentheses are taken to be of highest precedence,
57 just like a normal function call.
58
59 In the absence of parentheses, the precedence of list operators such as
60 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
61 whether you are looking at the left side or the right side of the operator.
62 For example, in
63
64     @ary = (1, 3, sort 4, 2);
65     print @ary;         # prints 1324
66
67 the commas on the right of the sort are evaluated before the sort,
68 but the commas on the left are evaluated after.  In other words,
69 list operators tend to gobble up all arguments that follow, and
70 then act like a simple TERM with regard to the preceding expression.
71 Be careful with parentheses:
72
73     # These evaluate exit before doing the print:
74     print($foo, exit);  # Obviously not what you want.
75     print $foo, exit;   # Nor is this.
76
77     # These do the print before evaluating exit:
78     (print $foo), exit; # This is what you want.
79     print($foo), exit;  # Or this.
80     print ($foo), exit; # Or even this.
81
82 Also note that
83
84     print ($foo & 255) + 1, "\n";
85
86 probably doesn't do what you expect at first glance.  See
87 L<Named Unary Operators> for more discussion of this.
88
89 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
90 well as subroutine and method calls, and the anonymous
91 constructors C<[]> and C<{}>.
92
93 See also L<Quote and Quote-like Operators> toward the end of this section,
94 as well as L<"I/O Operators">.
95
96 =head2 The Arrow Operator
97
98 "C<-E<gt>>" is an infix dereference operator, just as it is in C
99 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
100 C<(...)> subscript, then the left side must be either a hard or
101 symbolic reference to an array, a hash, or a subroutine respectively.
102 (Or technically speaking, a location capable of holding a hard
103 reference, if it's an array or hash reference being used for
104 assignment.)  See L<perlreftut> and L<perlref>.
105
106 Otherwise, the right side is a method name or a simple scalar
107 variable containing either the method name or a subroutine reference,
108 and the left side must be either an object (a blessed reference)
109 or a class name (that is, a package name).  See L<perlobj>.
110
111 =head2 Auto-increment and Auto-decrement
112
113 "++" and "--" work as in C.  That is, if placed before a variable, they
114 increment or decrement the variable before returning the value, and if
115 placed after, increment or decrement the variable after returning the value.
116
117 The auto-increment operator has a little extra builtin magic to it.  If
118 you increment a variable that is numeric, or that has ever been used in
119 a numeric context, you get a normal increment.  If, however, the
120 variable has been used in only string contexts since it was set, and
121 has a value that is not the empty string and matches the pattern
122 C</^[a-zA-Z]*[0-9]*$/>, the increment is done as a string, preserving each
123 character within its range, with carry:
124
125     print ++($foo = '99');      # prints '100'
126     print ++($foo = 'a0');      # prints 'a1'
127     print ++($foo = 'Az');      # prints 'Ba'
128     print ++($foo = 'zz');      # prints 'aaa'
129
130 The auto-decrement operator is not magical.
131
132 =head2 Exponentiation
133
134 Binary "**" is the exponentiation operator.  It binds even more
135 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
136 implemented using C's pow(3) function, which actually works on doubles
137 internally.)
138
139 =head2 Symbolic Unary Operators
140
141 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
142 precedence version of this.
143
144 Unary "-" performs arithmetic negation if the operand is numeric.  If
145 the operand is an identifier, a string consisting of a minus sign
146 concatenated with the identifier is returned.  Otherwise, if the string
147 starts with a plus or minus, a string starting with the opposite sign
148 is returned.  One effect of these rules is that C<-bareword> is equivalent
149 to C<"-bareword">.
150
151 Unary "~" performs bitwise negation, i.e., 1's complement.  For example,
152 C<0666 &~ 027> is 0640.  (See also L<Integer Arithmetic> and L<Bitwise
153 String Operators>.)
154
155 Unary "+" has no effect whatsoever, even on strings.  It is useful
156 syntactically for separating a function name from a parenthesized expression
157 that would otherwise be interpreted as the complete list of function
158 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
159
160 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
161 and L<perlref>.  Do not confuse this behavior with the behavior of
162 backslash within a string, although both forms do convey the notion
163 of protecting the next thing from interpolation.
164
165 =head2 Binding Operators
166
167 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
168 search or modify the string $_ by default.  This operator makes that kind
169 of operation work on some other string.  The right argument is a search
170 pattern, substitution, or transliteration.  The left argument is what is
171 supposed to be searched, substituted, or transliterated instead of the default
172 $_.  The return value indicates the success of the operation.  (If the
173 right argument is an expression rather than a search pattern,
174 substitution, or transliteration, it is interpreted as a search pattern at run
175 time.  This can be is less efficient than an explicit search, because the
176 pattern must be compiled every time the expression is evaluated).
177
178 Binary "!~" is just like "=~" except the return value is negated in
179 the logical sense.
180
181 =head2 Multiplicative Operators
182
183 Binary "*" multiplies two numbers.
184
185 Binary "/" divides two numbers.
186
187 Binary "%" computes the modulus of two numbers.  Given integer
188 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
189 C<$a> minus the largest multiple of C<$b> that is not greater than
190 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
191 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
192 result will be less than or equal to zero). 
193 Note than when C<use integer> is in scope, "%" give you direct access
194 to the modulus operator as implemented by your C compiler.  This
195 operator is not as well defined for negative operands, but it will
196 execute faster.
197
198 Binary "x" is the repetition operator.  In scalar context or if the left
199 operand is not enclosed in parentheses, it returns a string consisting
200 of the left operand repeated the number of times specified by the right
201 operand.  In list context, if the left operand is enclosed in
202 parentheses, it repeats the list.
203
204     print '-' x 80;             # print row of dashes
205
206     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
207
208     @ones = (1) x 80;           # a list of 80 1's
209     @ones = (5) x @ones;        # set all elements to 5
210
211
212 =head2 Additive Operators
213
214 Binary "+" returns the sum of two numbers.
215
216 Binary "-" returns the difference of two numbers.
217
218 Binary "." concatenates two strings.
219
220 =head2 Shift Operators
221
222 Binary "<<" returns the value of its left argument shifted left by the
223 number of bits specified by the right argument.  Arguments should be
224 integers.  (See also L<Integer Arithmetic>.)
225
226 Binary ">>" returns the value of its left argument shifted right by
227 the number of bits specified by the right argument.  Arguments should
228 be integers.  (See also L<Integer Arithmetic>.)
229
230 =head2 Named Unary Operators
231
232 The various named unary operators are treated as functions with one
233 argument, with optional parentheses.  These include the filetest
234 operators, like C<-f>, C<-M>, etc.  See L<perlfunc>.
235
236 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
237 is followed by a left parenthesis as the next token, the operator and
238 arguments within parentheses are taken to be of highest precedence,
239 just like a normal function call.  Examples:
240
241     chdir $foo    || die;       # (chdir $foo) || die
242     chdir($foo)   || die;       # (chdir $foo) || die
243     chdir ($foo)  || die;       # (chdir $foo) || die
244     chdir +($foo) || die;       # (chdir $foo) || die
245
246 but, because * is higher precedence than ||:
247
248     chdir $foo * 20;    # chdir ($foo * 20)
249     chdir($foo) * 20;   # (chdir $foo) * 20
250     chdir ($foo) * 20;  # (chdir $foo) * 20
251     chdir +($foo) * 20; # chdir ($foo * 20)
252
253     rand 10 * 20;       # rand (10 * 20)
254     rand(10) * 20;      # (rand 10) * 20
255     rand (10) * 20;     # (rand 10) * 20
256     rand +(10) * 20;    # rand (10 * 20)
257
258 See also L<"Terms and List Operators (Leftward)">.
259
260 =head2 Relational Operators
261
262 Binary "E<lt>" returns true if the left argument is numerically less than
263 the right argument.
264
265 Binary "E<gt>" returns true if the left argument is numerically greater
266 than the right argument.
267
268 Binary "E<lt>=" returns true if the left argument is numerically less than
269 or equal to the right argument.
270
271 Binary "E<gt>=" returns true if the left argument is numerically greater
272 than or equal to the right argument.
273
274 Binary "lt" returns true if the left argument is stringwise less than
275 the right argument.
276
277 Binary "gt" returns true if the left argument is stringwise greater
278 than the right argument.
279
280 Binary "le" returns true if the left argument is stringwise less than
281 or equal to the right argument.
282
283 Binary "ge" returns true if the left argument is stringwise greater
284 than or equal to the right argument.
285
286 =head2 Equality Operators
287
288 Binary "==" returns true if the left argument is numerically equal to
289 the right argument.
290
291 Binary "!=" returns true if the left argument is numerically not equal
292 to the right argument.
293
294 Binary "E<lt>=E<gt>" returns -1, 0, or 1 depending on whether the left
295 argument is numerically less than, equal to, or greater than the right
296 argument.
297
298 Binary "eq" returns true if the left argument is stringwise equal to
299 the right argument.
300
301 Binary "ne" returns true if the left argument is stringwise not equal
302 to the right argument.
303
304 Binary "cmp" returns -1, 0, or 1 depending on whether the left argument is stringwise
305 less than, equal to, or greater than the right argument.
306
307 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
308 by the current locale if C<use locale> is in effect.  See L<perllocale>.
309
310 =head2 Bitwise And
311
312 Binary "&" returns its operators ANDed together bit by bit.
313 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
314
315 =head2 Bitwise Or and Exclusive Or
316
317 Binary "|" returns its operators ORed together bit by bit.
318 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
319
320 Binary "^" returns its operators XORed together bit by bit.
321 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
322
323 =head2 C-style Logical And
324
325 Binary "&&" performs a short-circuit logical AND operation.  That is,
326 if the left operand is false, the right operand is not even evaluated.
327 Scalar or list context propagates down to the right operand if it
328 is evaluated.
329
330 =head2 C-style Logical Or
331
332 Binary "||" performs a short-circuit logical OR operation.  That is,
333 if the left operand is true, the right operand is not even evaluated.
334 Scalar or list context propagates down to the right operand if it
335 is evaluated.
336
337 The C<||> and C<&&> operators differ from C's in that, rather than returning
338 0 or 1, they return the last value evaluated.  Thus, a reasonably portable
339 way to find out the home directory (assuming it's not "0") might be:
340
341     $home = $ENV{'HOME'} || $ENV{'LOGDIR'} ||
342         (getpwuid($<))[7] || die "You're homeless!\n";
343
344 In particular, this means that you shouldn't use this
345 for selecting between two aggregates for assignment:
346
347     @a = @b || @c;              # this is wrong
348     @a = scalar(@b) || @c;      # really meant this
349     @a = @b ? @b : @c;          # this works fine, though
350
351 As more readable alternatives to C<&&> and C<||> when used for
352 control flow, Perl provides C<and> and C<or> operators (see below).
353 The short-circuit behavior is identical.  The precedence of "and" and
354 "or" is much lower, however, so that you can safely use them after a
355 list operator without the need for parentheses:
356
357     unlink "alpha", "beta", "gamma"
358             or gripe(), next LINE;
359
360 With the C-style operators that would have been written like this:
361
362     unlink("alpha", "beta", "gamma")
363             || (gripe(), next LINE);
364
365 Use "or" for assignment is unlikely to do what you want; see below.
366
367 =head2 Range Operators
368
369 Binary ".." is the range operator, which is really two different
370 operators depending on the context.  In list context, it returns an
371 array of values counting (up by ones) from the left value to the right
372 value.  If the left value is greater than the right value then it
373 returns the empty array.  The range operator is useful for writing
374 C<foreach (1..10)> loops and for doing slice operations on arrays.  In
375 the current implementation, no temporary array is created when the
376 range operator is used as the expression in C<foreach> loops, but older
377 versions of Perl might burn a lot of memory when you write something
378 like this:
379
380     for (1 .. 1_000_000) {
381         # code
382     }
383
384 In scalar context, ".." returns a boolean value.  The operator is
385 bistable, like a flip-flop, and emulates the line-range (comma) operator
386 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
387 own boolean state.  It is false as long as its left operand is false.
388 Once the left operand is true, the range operator stays true until the
389 right operand is true, I<AFTER> which the range operator becomes false
390 again.  It doesn't become false till the next time the range operator is
391 evaluated.  It can test the right operand and become false on the same
392 evaluation it became true (as in B<awk>), but it still returns true once.
393 If you don't want it to test the right operand till the next
394 evaluation, as in B<sed>, just use three dots ("...") instead of
395 two.  In all other regards, "..." behaves just like ".." does.
396
397 The right operand is not evaluated while the operator is in the
398 "false" state, and the left operand is not evaluated while the
399 operator is in the "true" state.  The precedence is a little lower
400 than || and &&.  The value returned is either the empty string for
401 false, or a sequence number (beginning with 1) for true.  The
402 sequence number is reset for each range encountered.  The final
403 sequence number in a range has the string "E0" appended to it, which
404 doesn't affect its numeric value, but gives you something to search
405 for if you want to exclude the endpoint.  You can exclude the
406 beginning point by waiting for the sequence number to be greater
407 than 1.  If either operand of scalar ".." is a constant expression,
408 that operand is implicitly compared to the C<$.> variable, the
409 current line number.  Examples:
410
411 As a scalar operator:
412
413     if (101 .. 200) { print; }  # print 2nd hundred lines
414     next line if (1 .. /^$/);   # skip header lines
415     s/^/> / if (/^$/ .. eof()); # quote body
416
417     # parse mail messages
418     while (<>) {
419         $in_header =   1  .. /^$/;
420         $in_body   = /^$/ .. eof();
421         # do something based on those
422     } continue {
423         close ARGV if eof;              # reset $. each file
424     }
425
426 As a list operator:
427
428     for (101 .. 200) { print; } # print $_ 100 times
429     @foo = @foo[0 .. $#foo];    # an expensive no-op
430     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
431
432 The range operator (in list context) makes use of the magical
433 auto-increment algorithm if the operands are strings.  You
434 can say
435
436     @alphabet = ('A' .. 'Z');
437
438 to get all normal letters of the alphabet, or
439
440     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
441
442 to get a hexadecimal digit, or
443
444     @z2 = ('01' .. '31');  print $z2[$mday];
445
446 to get dates with leading zeros.  If the final value specified is not
447 in the sequence that the magical increment would produce, the sequence
448 goes until the next value would be longer than the final value
449 specified.
450
451 =head2 Conditional Operator
452
453 Ternary "?:" is the conditional operator, just as in C.  It works much
454 like an if-then-else.  If the argument before the ? is true, the
455 argument before the : is returned, otherwise the argument after the :
456 is returned.  For example:
457
458     printf "I have %d dog%s.\n", $n,
459             ($n == 1) ? '' : "s";
460
461 Scalar or list context propagates downward into the 2nd
462 or 3rd argument, whichever is selected.
463
464     $a = $ok ? $b : $c;  # get a scalar
465     @a = $ok ? @b : @c;  # get an array
466     $a = $ok ? @b : @c;  # oops, that's just a count!
467
468 The operator may be assigned to if both the 2nd and 3rd arguments are
469 legal lvalues (meaning that you can assign to them):
470
471     ($a_or_b ? $a : $b) = $c;
472
473 Because this operator produces an assignable result, using assignments
474 without parentheses will get you in trouble.  For example, this:
475
476     $a % 2 ? $a += 10 : $a += 2
477
478 Really means this:
479
480     (($a % 2) ? ($a += 10) : $a) += 2
481
482 Rather than this:
483
484     ($a % 2) ? ($a += 10) : ($a += 2)
485
486 That should probably be written more simply as:
487
488     $a += ($a % 2) ? 10 : 2;
489
490 =head2 Assignment Operators
491
492 "=" is the ordinary assignment operator.
493
494 Assignment operators work as in C.  That is,
495
496     $a += 2;
497
498 is equivalent to
499
500     $a = $a + 2;
501
502 although without duplicating any side effects that dereferencing the lvalue
503 might trigger, such as from tie().  Other assignment operators work similarly.
504 The following are recognized:
505
506     **=    +=    *=    &=    <<=    &&=
507            -=    /=    |=    >>=    ||=
508            .=    %=    ^=
509                  x=
510
511 Although these are grouped by family, they all have the precedence
512 of assignment.
513
514 Unlike in C, the scalar assignment operator produces a valid lvalue.
515 Modifying an assignment is equivalent to doing the assignment and
516 then modifying the variable that was assigned to.  This is useful
517 for modifying a copy of something, like this:
518
519     ($tmp = $global) =~ tr [A-Z] [a-z];
520
521 Likewise,
522
523     ($a += 2) *= 3;
524
525 is equivalent to
526
527     $a += 2;
528     $a *= 3;
529
530 Similarly, a list assignment in list context produces the list of
531 lvalues assigned to, and a list assignment in scalar context returns
532 the number of elements produced by the expression on the right hand
533 side of the assignment.
534
535 =head2 Comma Operator
536
537 Binary "," is the comma operator.  In scalar context it evaluates
538 its left argument, throws that value away, then evaluates its right
539 argument and returns that value.  This is just like C's comma operator.
540
541 In list context, it's just the list argument separator, and inserts
542 both its arguments into the list.
543
544 The =E<gt> digraph is mostly just a synonym for the comma operator.  It's useful for
545 documenting arguments that come in pairs.  As of release 5.001, it also forces
546 any word to the left of it to be interpreted as a string.
547
548 =head2 List Operators (Rightward)
549
550 On the right side of a list operator, it has very low precedence,
551 such that it controls all comma-separated expressions found there.
552 The only operators with lower precedence are the logical operators
553 "and", "or", and "not", which may be used to evaluate calls to list
554 operators without the need for extra parentheses:
555
556     open HANDLE, "filename"
557         or die "Can't open: $!\n";
558
559 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
560
561 =head2 Logical Not
562
563 Unary "not" returns the logical negation of the expression to its right.
564 It's the equivalent of "!" except for the very low precedence.
565
566 =head2 Logical And
567
568 Binary "and" returns the logical conjunction of the two surrounding
569 expressions.  It's equivalent to && except for the very low
570 precedence.  This means that it short-circuits: i.e., the right
571 expression is evaluated only if the left expression is true.
572
573 =head2 Logical or and Exclusive Or
574
575 Binary "or" returns the logical disjunction of the two surrounding
576 expressions.  It's equivalent to || except for the very low precedence.
577 This makes it useful for control flow
578
579     print FH $data              or die "Can't write to FH: $!";
580
581 This means that it short-circuits: i.e., the right expression is evaluated
582 only if the left expression is false.  Due to its precedence, you should
583 probably avoid using this for assignment, only for control flow.
584
585     $a = $b or $c;              # bug: this is wrong
586     ($a = $b) or $c;            # really means this
587     $a = $b || $c;              # better written this way
588
589 However, when it's a list-context assignment and you're trying to use
590 "||" for control flow, you probably need "or" so that the assignment
591 takes higher precedence.
592
593     @info = stat($file) || die;     # oops, scalar sense of stat!
594     @info = stat($file) or die;     # better, now @info gets its due
595
596 Then again, you could always use parentheses. 
597
598 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
599 It cannot short circuit, of course.
600
601 =head2 C Operators Missing From Perl
602
603 Here is what C has that Perl doesn't:
604
605 =over 8
606
607 =item unary &
608
609 Address-of operator.  (But see the "\" operator for taking a reference.)
610
611 =item unary *
612
613 Dereference-address operator. (Perl's prefix dereferencing
614 operators are typed: $, @, %, and &.)
615
616 =item (TYPE)
617
618 Type-casting operator.
619
620 =back
621
622 =head2 Quote and Quote-like Operators
623
624 While we usually think of quotes as literal values, in Perl they
625 function as operators, providing various kinds of interpolating and
626 pattern matching capabilities.  Perl provides customary quote characters
627 for these behaviors, but also provides a way for you to choose your
628 quote character for any of them.  In the following table, a C<{}> represents
629 any pair of delimiters you choose.  
630
631     Customary  Generic        Meaning        Interpolates
632         ''       q{}          Literal             no
633         ""      qq{}          Literal             yes
634         ``      qx{}          Command             yes (unless '' is delimiter)
635                 qw{}         Word list            no
636         //       m{}       Pattern match          yes (unless '' is delimiter)
637                 qr{}          Pattern             yes (unless '' is delimiter)
638                  s{}{}      Substitution          yes (unless '' is delimiter)
639                 tr{}{}    Transliteration         no (but see below)
640
641 Non-bracketing delimiters use the same character fore and aft, but the four
642 sorts of brackets (round, angle, square, curly) will all nest, which means
643 that 
644
645         q{foo{bar}baz} 
646         
647 is the same as 
648
649         'foo{bar}baz'
650
651 Note, however, that this does not always work for quoting Perl code:
652
653         $s = q{ if($a eq "}") ... }; # WRONG
654
655 is a syntax error. The C<Text::Balanced> module on CPAN is able to do this
656 properly.
657
658 There can be whitespace between the operator and the quoting
659 characters, except when C<#> is being used as the quoting character.
660 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
661 operator C<q> followed by a comment.  Its argument will be taken
662 from the next line.  This allows you to write:
663
664     s {foo}  # Replace foo
665       {bar}  # with bar.
666
667 For constructs that do interpolate, variables beginning with "C<$>"
668 or "C<@>" are interpolated, as are the following escape sequences.  Within
669 a transliteration, the first eleven of these sequences may be used.
670
671     \t          tab             (HT, TAB)
672     \n          newline         (NL)
673     \r          return          (CR)
674     \f          form feed       (FF)
675     \b          backspace       (BS)
676     \a          alarm (bell)    (BEL)
677     \e          escape          (ESC)
678     \033        octal char      (ESC)
679     \x1b        hex char        (ESC)
680     \x{263a}    wide hex char   (SMILEY)
681     \c[         control char    (ESC)
682     \N{name}    named char
683
684     \l          lowercase next char
685     \u          uppercase next char
686     \L          lowercase till \E
687     \U          uppercase till \E
688     \E          end case modification
689     \Q          quote non-word characters till \E
690
691 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
692 and C<\U> is taken from the current locale.  See L<perllocale>.  For
693 documentation of C<\N{name}>, see L<charnames>.
694
695 All systems use the virtual C<"\n"> to represent a line terminator,
696 called a "newline".  There is no such thing as an unvarying, physical
697 newline character.  It is only an illusion that the operating system,
698 device drivers, C libraries, and Perl all conspire to preserve.  Not all
699 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
700 on a Mac, these are reversed, and on systems without line terminator,
701 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
702 you mean a "newline" for your system, but use the literal ASCII when you
703 need an exact character.  For example, most networking protocols expect
704 and prefer a CR+LF (C<"\012\015"> or C<"\cJ\cM">) for line terminators,
705 and although they often accept just C<"\012">, they seldom tolerate just
706 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
707 you may be burned some day.
708
709 You cannot include a literal C<$> or C<@> within a C<\Q> sequence. 
710 An unescaped C<$> or C<@> interpolates the corresponding variable, 
711 while escaping will cause the literal string C<\$> to be inserted.
712 You'll need to write something like C<m/\Quser\E\@\Qhost/>. 
713
714 Patterns are subject to an additional level of interpretation as a
715 regular expression.  This is done as a second pass, after variables are
716 interpolated, so that regular expressions may be incorporated into the
717 pattern from the variables.  If this is not what you want, use C<\Q> to
718 interpolate a variable literally.
719
720 Apart from the behavior described above, Perl does not expand
721 multiple levels of interpolation.  In particular, contrary to the
722 expectations of shell programmers, back-quotes do I<NOT> interpolate
723 within double quotes, nor do single quotes impede evaluation of
724 variables when used within double quotes.
725
726 =head2 Regexp Quote-Like Operators
727
728 Here are the quote-like operators that apply to pattern
729 matching and related activities.
730
731 =over 8
732
733 =item ?PATTERN?
734
735 This is just like the C</pattern/> search, except that it matches only
736 once between calls to the reset() operator.  This is a useful
737 optimization when you want to see only the first occurrence of
738 something in each file of a set of files, for instance.  Only C<??>
739 patterns local to the current package are reset.
740
741     while (<>) {
742         if (?^$?) {
743                             # blank line between header and body
744         }
745     } continue {
746         reset if eof;       # clear ?? status for next file
747     }
748
749 This usage is vaguely depreciated, which means it just might possibly
750 be removed in some distant future version of Perl, perhaps somewhere
751 around the year 2168.
752
753 =item m/PATTERN/cgimosx
754
755 =item /PATTERN/cgimosx
756
757 Searches a string for a pattern match, and in scalar context returns
758 true if it succeeds, false if it fails.  If no string is specified
759 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
760 string specified with C<=~> need not be an lvalue--it may be the
761 result of an expression evaluation, but remember the C<=~> binds
762 rather tightly.)  See also L<perlre>.  See L<perllocale> for
763 discussion of additional considerations that apply when C<use locale>
764 is in effect.
765
766 Options are:
767
768     c   Do not reset search position on a failed match when /g is in effect.
769     g   Match globally, i.e., find all occurrences.
770     i   Do case-insensitive pattern matching.
771     m   Treat string as multiple lines.
772     o   Compile pattern only once.
773     s   Treat string as single line.
774     x   Use extended regular expressions.
775
776 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
777 you can use any pair of non-alphanumeric, non-whitespace characters 
778 as delimiters.  This is particularly useful for matching path names
779 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
780 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
781 If "'" is the delimiter, no interpolation is performed on the PATTERN.
782
783 PATTERN may contain variables, which will be interpolated (and the
784 pattern recompiled) every time the pattern search is evaluated, except
785 for when the delimiter is a single quote.  (Note that C<$)> and C<$|>
786 might not be interpolated because they look like end-of-string tests.)
787 If you want such a pattern to be compiled only once, add a C</o> after
788 the trailing delimiter.  This avoids expensive run-time recompilations,
789 and is useful when the value you are interpolating won't change over
790 the life of the script.  However, mentioning C</o> constitutes a promise
791 that you won't change the variables in the pattern.  If you change them,
792 Perl won't even notice.  See also L<qr//>.
793
794 If the PATTERN evaluates to the empty string, the last
795 I<successfully> matched regular expression is used instead.
796
797 If the C</g> option is not used, C<m//> in list context returns a
798 list consisting of the subexpressions matched by the parentheses in the
799 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
800 also set, and that this differs from Perl 4's behavior.)  When there are
801 no parentheses in the pattern, the return value is the list C<(1)> for
802 success.  With or without parentheses, an empty list is returned upon
803 failure.
804
805 Examples:
806
807     open(TTY, '/dev/tty');
808     <TTY> =~ /^y/i && foo();    # do foo if desired
809
810     if (/Version: *([0-9.]*)/) { $version = $1; }
811
812     next if m#^/usr/spool/uucp#;
813
814     # poor man's grep
815     $arg = shift;
816     while (<>) {
817         print if /$arg/o;       # compile only once
818     }
819
820     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
821
822 This last example splits $foo into the first two words and the
823 remainder of the line, and assigns those three fields to $F1, $F2, and
824 $Etc.  The conditional is true if any variables were assigned, i.e., if
825 the pattern matched.
826
827 The C</g> modifier specifies global pattern matching--that is,
828 matching as many times as possible within the string.  How it behaves
829 depends on the context.  In list context, it returns a list of the
830 substrings matched by any capturing parentheses in the regular
831 expression.  If there are no parentheses, it returns a list of all
832 the matched strings, as if there were parentheses around the whole
833 pattern.
834
835 In scalar context, each execution of C<m//g> finds the next match,
836 returning true if it matches, and false if there is no further match.
837 The position after the last match can be read or set using the pos()
838 function; see L<perlfunc/pos>.   A failed match normally resets the
839 search position to the beginning of the string, but you can avoid that
840 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
841 string also resets the search position.
842
843 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
844 zero-width assertion that matches the exact position where the previous
845 C<m//g>, if any, left off.  The C<\G> assertion is not supported without
846 the C</g> modifier.  (Currently, without C</g>, C<\G> behaves just like
847 C<\A>, but that's accidental and may change in the future.)
848
849 Examples:
850
851     # list context
852     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
853
854     # scalar context
855     $/ = ""; $* = 1;  # $* deprecated in modern perls
856     while (defined($paragraph = <>)) {
857         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
858             $sentences++;
859         }
860     }
861     print "$sentences\n";
862
863     # using m//gc with \G
864     $_ = "ppooqppqq";
865     while ($i++ < 2) {
866         print "1: '";
867         print $1 while /(o)/gc; print "', pos=", pos, "\n";
868         print "2: '";
869         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
870         print "3: '";
871         print $1 while /(p)/gc; print "', pos=", pos, "\n";
872     }
873
874 The last example should print:
875
876     1: 'oo', pos=4
877     2: 'q', pos=5
878     3: 'pp', pos=7
879     1: '', pos=7
880     2: 'q', pos=8
881     3: '', pos=8
882
883 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
884 combine several regexps like this to process a string part-by-part,
885 doing different actions depending on which regexp matched.  Each
886 regexp tries to match where the previous one leaves off.
887
888  $_ = <<'EOL';
889       $url = new URI::URL "http://www/";   die if $url eq "xXx";
890  EOL
891  LOOP:
892     {
893       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
894       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
895       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
896       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
897       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
898       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
899       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
900       print ". That's all!\n";
901     }
902
903 Here is the output (split into several lines):
904
905  line-noise lowercase line-noise lowercase UPPERCASE line-noise
906  UPPERCASE line-noise lowercase line-noise lowercase line-noise
907  lowercase lowercase line-noise lowercase lowercase line-noise
908  MiXeD line-noise. That's all!
909
910 =item q/STRING/
911
912 =item C<'STRING'>
913
914 A single-quoted, literal string.  A backslash represents a backslash
915 unless followed by the delimiter or another backslash, in which case
916 the delimiter or backslash is interpolated.
917
918     $foo = q!I said, "You said, 'She said it.'"!;
919     $bar = q('This is it.');
920     $baz = '\n';                # a two-character string
921
922 =item qq/STRING/
923
924 =item "STRING"
925
926 A double-quoted, interpolated string.
927
928     $_ .= qq
929      (*** The previous line contains the naughty word "$1".\n)
930                 if /\b(tcl|java|python)\b/i;      # :-)
931     $baz = "\n";                # a one-character string
932
933 =item qr/STRING/imosx
934
935 This operators quotes--and compiles--its I<STRING> as a regular
936 expression.  I<STRING> is interpolated the same way as I<PATTERN>
937 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
938 is done.  Returns a Perl value which may be used instead of the
939 corresponding C</STRING/imosx> expression.
940
941 For example,
942
943     $rex = qr/my.STRING/is;
944     s/$rex/foo/;
945
946 is equivalent to
947
948     s/my.STRING/foo/is;
949
950 The result may be used as a subpattern in a match:
951
952     $re = qr/$pattern/;
953     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
954     $string =~ $re;             # or used standalone
955     $string =~ /$re/;           # or this way
956
957 Since Perl may compile the pattern at the moment of execution of qr()
958 operator, using qr() may have speed advantages in some situations,
959 notably if the result of qr() is used standalone:
960
961     sub match {
962         my $patterns = shift;
963         my @compiled = map qr/$_/i, @$patterns;
964         grep {
965             my $success = 0;
966             foreach my $pat @compiled {
967                 $success = 1, last if /$pat/;
968             }
969             $success;
970         } @_;
971     }
972
973 Precompilation of the pattern into an internal representation at
974 the moment of qr() avoids a need to recompile the pattern every
975 time a match C</$pat/> is attempted.  (Perl has many other internal
976 optimizations, but none would be triggered in the above example if
977 we did not use qr() operator.)
978
979 Options are:
980
981     i   Do case-insensitive pattern matching.
982     m   Treat string as multiple lines.
983     o   Compile pattern only once.
984     s   Treat string as single line.
985     x   Use extended regular expressions.
986
987 See L<perlre> for additional information on valid syntax for STRING, and
988 for a detailed look at the semantics of regular expressions.
989
990 =item qx/STRING/
991
992 =item `STRING`
993
994 A string which is (possibly) interpolated and then executed as a system
995 command with C</bin/sh> or its equivalent.  Shell wildcards, pipes,
996 and redirections will be honored.  The collected standard output of the
997 command is returned; standard error is unaffected.  In scalar context,
998 it comes back as a single (potentially multi-line) string.  In list
999 context, returns a list of lines (however you've defined lines with $/
1000 or $INPUT_RECORD_SEPARATOR).
1001
1002 Because backticks do not affect standard error, use shell file descriptor
1003 syntax (assuming the shell supports this) if you care to address this.
1004 To capture a command's STDERR and STDOUT together:
1005
1006     $output = `cmd 2>&1`;
1007
1008 To capture a command's STDOUT but discard its STDERR:
1009
1010     $output = `cmd 2>/dev/null`;
1011
1012 To capture a command's STDERR but discard its STDOUT (ordering is
1013 important here):
1014
1015     $output = `cmd 2>&1 1>/dev/null`;
1016
1017 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1018 but leave its STDOUT to come out the old STDERR:
1019
1020     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1021
1022 To read both a command's STDOUT and its STDERR separately, it's easiest
1023 and safest to redirect them separately to files, and then read from those
1024 files when the program is done:
1025
1026     system("program args 1>/tmp/program.stdout 2>/tmp/program.stderr");
1027
1028 Using single-quote as a delimiter protects the command from Perl's
1029 double-quote interpolation, passing it on to the shell instead:
1030
1031     $perl_info  = qx(ps $$);            # that's Perl's $$
1032     $shell_info = qx'ps $$';            # that's the new shell's $$
1033
1034 How that string gets evaluated is entirely subject to the command
1035 interpreter on your system.  On most platforms, you will have to protect
1036 shell metacharacters if you want them treated literally.  This is in
1037 practice difficult to do, as it's unclear how to escape which characters.
1038 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1039 to emulate backticks safely.
1040
1041 On some platforms (notably DOS-like ones), the shell may not be
1042 capable of dealing with multiline commands, so putting newlines in
1043 the string may not get you what you want.  You may be able to evaluate
1044 multiple commands in a single line by separating them with the command
1045 separator character, if your shell supports that (e.g. C<;> on many Unix
1046 shells; C<&> on the Windows NT C<cmd> shell).
1047
1048 Beware that some command shells may place restrictions on the length
1049 of the command line.  You must ensure your strings don't exceed this
1050 limit after any necessary interpolations.  See the platform-specific
1051 release notes for more details about your particular environment.
1052
1053 Using this operator can lead to programs that are difficult to port,
1054 because the shell commands called vary between systems, and may in
1055 fact not be present at all.  As one example, the C<type> command under
1056 the POSIX shell is very different from the C<type> command under DOS.
1057 That doesn't mean you should go out of your way to avoid backticks
1058 when they're the right way to get something done.  Perl was made to be
1059 a glue language, and one of the things it glues together is commands.
1060 Just understand what you're getting yourself into.
1061
1062 See L<"I/O Operators"> for more discussion.
1063
1064 =item qw/STRING/
1065
1066 Evaluates to a list of the words extracted out of STRING, using embedded
1067 whitespace as the word delimiters.  It can be understood as being roughly
1068 equivalent to:
1069
1070     split(' ', q/STRING/);
1071
1072 the difference being that it generates a real list at compile time.  So
1073 this expression:
1074
1075     qw(foo bar baz)
1076
1077 is exactly equivalent to the list:
1078
1079     ('foo', 'bar', 'baz')
1080
1081 Some frequently seen examples:
1082
1083     use POSIX qw( setlocale localeconv )
1084     @EXPORT = qw( foo bar baz );
1085
1086 A common mistake is to try to separate the words with comma or to
1087 put comments into a multi-line C<qw>-string.  For this reason, the
1088 B<-w> switch (that is, the C<$^W> variable) produces warnings if
1089 the STRING contains the "," or the "#" character.
1090
1091 =item s/PATTERN/REPLACEMENT/egimosx
1092
1093 Searches a string for a pattern, and if found, replaces that pattern
1094 with the replacement text and returns the number of substitutions
1095 made.  Otherwise it returns false (specifically, the empty string).
1096
1097 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1098 variable is searched and modified.  (The string specified with C<=~> must
1099 be scalar variable, an array element, a hash element, or an assignment
1100 to one of those, i.e., an lvalue.)
1101
1102 If the delimiter chosen is a single quote, no interpolation is
1103 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1104 PATTERN contains a $ that looks like a variable rather than an
1105 end-of-string test, the variable will be interpolated into the pattern
1106 at run-time.  If you want the pattern compiled only once the first time
1107 the variable is interpolated, use the C</o> option.  If the pattern
1108 evaluates to the empty string, the last successfully executed regular
1109 expression is used instead.  See L<perlre> for further explanation on these.
1110 See L<perllocale> for discussion of additional considerations that apply
1111 when C<use locale> is in effect.
1112
1113 Options are:
1114
1115     e   Evaluate the right side as an expression.
1116     g   Replace globally, i.e., all occurrences.
1117     i   Do case-insensitive pattern matching.
1118     m   Treat string as multiple lines.
1119     o   Compile pattern only once.
1120     s   Treat string as single line.
1121     x   Use extended regular expressions.
1122
1123 Any non-alphanumeric, non-whitespace delimiter may replace the
1124 slashes.  If single quotes are used, no interpretation is done on the
1125 replacement string (the C</e> modifier overrides this, however).  Unlike
1126 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1127 text is not evaluated as a command.  If the
1128 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1129 pair of quotes, which may or may not be bracketing quotes, e.g.,
1130 C<s(foo)(bar)> or C<sE<lt>fooE<gt>/bar/>.  A C</e> will cause the
1131 replacement portion to be interpreted as a full-fledged Perl expression
1132 and eval()ed right then and there.  It is, however, syntax checked at
1133 compile-time.
1134
1135 Examples:
1136
1137     s/\bgreen\b/mauve/g;                # don't change wintergreen
1138
1139     $path =~ s|/usr/bin|/usr/local/bin|;
1140
1141     s/Login: $foo/Login: $bar/; # run-time pattern
1142
1143     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1144
1145     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1146
1147     $_ = 'abc123xyz';
1148     s/\d+/$&*2/e;               # yields 'abc246xyz'
1149     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1150     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1151
1152     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1153     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1154     s/^=(\w+)/&pod($1)/ge;      # use function call
1155
1156     # expand variables in $_, but dynamics only, using
1157     # symbolic dereferencing
1158     s/\$(\w+)/${$1}/g;
1159
1160     # /e's can even nest;  this will expand
1161     # any embedded scalar variable (including lexicals) in $_
1162     s/(\$\w+)/$1/eeg;
1163
1164     # Delete (most) C comments.
1165     $program =~ s {
1166         /\*     # Match the opening delimiter.
1167         .*?     # Match a minimal number of characters.
1168         \*/     # Match the closing delimiter.
1169     } []gsx;
1170
1171     s/^\s*(.*?)\s*$/$1/;        # trim white space in $_, expensively
1172
1173     for ($variable) {           # trim white space in $variable, cheap
1174         s/^\s+//;
1175         s/\s+$//;
1176     }
1177
1178     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1179
1180 Note the use of $ instead of \ in the last example.  Unlike
1181 B<sed>, we use the \E<lt>I<digit>E<gt> form in only the left hand side.
1182 Anywhere else it's $E<lt>I<digit>E<gt>.
1183
1184 Occasionally, you can't use just a C</g> to get all the changes
1185 to occur that you might want.  Here are two common cases:
1186
1187     # put commas in the right places in an integer
1188     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;  
1189
1190     # expand tabs to 8-column spacing
1191     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1192
1193 =item tr/SEARCHLIST/REPLACEMENTLIST/cdsUC
1194
1195 =item y/SEARCHLIST/REPLACEMENTLIST/cdsUC
1196
1197 Transliterates all occurrences of the characters found in the search list
1198 with the corresponding character in the replacement list.  It returns
1199 the number of characters replaced or deleted.  If no string is
1200 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1201 string specified with =~ must be a scalar variable, an array element, a
1202 hash element, or an assignment to one of those, i.e., an lvalue.)
1203
1204 A character range may be specified with a hyphen, so C<tr/A-J/0-9/> 
1205 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1206 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1207 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1208 its own pair of quotes, which may or may not be bracketing quotes,
1209 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1210
1211 Note also that the whole range idea is rather unportable between
1212 character sets--and even within character sets they may cause results
1213 you probably didn't expect.  A sound principle is to use only ranges
1214 that begin from and end at either alphabets of equal case (a-e, A-E),
1215 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1216 character sets in full.
1217
1218 Options:
1219
1220     c   Complement the SEARCHLIST.
1221     d   Delete found but unreplaced characters.
1222     s   Squash duplicate replaced characters.
1223     U   Translate to/from UTF-8.
1224     C   Translate to/from 8-bit char (octet).
1225
1226 If the C</c> modifier is specified, the SEARCHLIST character set
1227 is complemented.  If the C</d> modifier is specified, any characters
1228 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1229 (Note that this is slightly more flexible than the behavior of some
1230 B<tr> programs, which delete anything they find in the SEARCHLIST,
1231 period.) If the C</s> modifier is specified, sequences of characters
1232 that were transliterated to the same character are squashed down
1233 to a single instance of the character.
1234
1235 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1236 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1237 than the SEARCHLIST, the final character is replicated till it is long
1238 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1239 This latter is useful for counting characters in a class or for
1240 squashing character sequences in a class.
1241
1242 The first C</U> or C</C> modifier applies to the left side of the translation.
1243 The second one applies to the right side.  If present, these modifiers override
1244 the current utf8 state.
1245
1246 Examples:
1247
1248     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1249
1250     $cnt = tr/*/*/;             # count the stars in $_
1251
1252     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1253
1254     $cnt = tr/0-9//;            # count the digits in $_
1255
1256     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1257
1258     ($HOST = $host) =~ tr/a-z/A-Z/;
1259
1260     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1261
1262     tr [\200-\377]
1263        [\000-\177];             # delete 8th bit
1264
1265     tr/\0-\xFF//CU;             # change Latin-1 to Unicode
1266     tr/\0-\x{FF}//UC;           # change Unicode to Latin-1
1267
1268 If multiple transliterations are given for a character, only the
1269 first one is used:
1270
1271     tr/AAA/XYZ/
1272
1273 will transliterate any A to X.
1274
1275 Because the transliteration table is built at compile time, neither
1276 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1277 interpolation.  That means that if you want to use variables, you
1278 must use an eval():
1279
1280     eval "tr/$oldlist/$newlist/";
1281     die $@ if $@;
1282
1283     eval "tr/$oldlist/$newlist/, 1" or die $@;
1284
1285 =back
1286
1287 =head2 Gory details of parsing quoted constructs
1288
1289 When presented with something that might have several different
1290 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1291 principle to pick the most probable interpretation.  This strategy
1292 is so successful that Perl programmers often do not suspect the
1293 ambivalence of what they write.  But from time to time, Perl's
1294 notions differ substantially from what the author honestly meant.
1295
1296 This section hopes to clarify how Perl handles quoted constructs.
1297 Although the most common reason to learn this is to unravel labyrinthine
1298 regular expressions, because the initial steps of parsing are the
1299 same for all quoting operators, they are all discussed together.
1300
1301 The most important Perl parsing rule is the first one discussed
1302 below: when processing a quoted construct, Perl first finds the end
1303 of that construct, then interprets its contents.  If you understand
1304 this rule, you may skip the rest of this section on the first
1305 reading.  The other rules are likely to contradict the user's
1306 expectations much less frequently than this first one.
1307
1308 Some passes discussed below are performed concurrently, but because
1309 their results are the same, we consider them individually.  For different
1310 quoting constructs, Perl performs different numbers of passes, from
1311 one to five, but these passes are always performed in the same order.
1312
1313 =over
1314
1315 =item Finding the end
1316
1317 The first pass is finding the end of the quoted construct, whether
1318 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1319 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1320 terminates C<qq[]> construct, or a C<E<gt>> which terminates a
1321 fileglob started with C<E<lt>>.
1322
1323 When searching for single-character non-pairing delimiters, such
1324 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1325 when searching for single-character pairing delimiter like C<[>,
1326 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1327 C<[>, C<]> are skipped as well.  When searching for multicharacter
1328 delimiters, nothing is skipped.
1329
1330 For constructs with three-part delimiters (C<s///>, C<y///>, and
1331 C<tr///>), the search is repeated once more.
1332
1333 During this search no attention is paid to the semantics of the construct.
1334 Thus:
1335
1336     "$hash{"$foo/$bar"}"
1337
1338 or:
1339
1340     m/ 
1341       bar       # NOT a comment, this slash / terminated m//!
1342      /x
1343
1344 do not form legal quoted expressions.   The quoted part ends on the
1345 first C<"> and C</>, and the rest happens to be a syntax error.
1346 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1347 the example above is not C<m//x>, but rather C<m//> with no C</x>
1348 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1349
1350 =item Removal of backslashes before delimiters
1351
1352 During the second pass, text between the starting and ending
1353 delimiters is copied to a safe location, and the C<\> is removed
1354 from combinations consisting of C<\> and delimiter--or delimiters,
1355 meaning both starting and ending delimiters will should these differ.
1356 This removal does not happen for multi-character delimiters.
1357 Note that the combination C<\\> is left intact, just as it was.
1358
1359 Starting from this step no information about the delimiters is
1360 used in parsing.
1361
1362 =item Interpolation
1363
1364 The next step is interpolation in the text obtained, which is now
1365 delimiter-independent.  There are four different cases.
1366
1367 =over
1368
1369 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1370
1371 No interpolation is performed.
1372
1373 =item C<''>, C<q//>
1374
1375 The only interpolation is removal of C<\> from pairs C<\\>.
1376
1377 =item C<"">, C<``>, C<qq//>, C<qx//>, C<<file*globE<gt>>
1378
1379 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1380 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1381 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1382 The other combinations are replaced with appropriate expansions.
1383
1384 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1385 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1386 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1387 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1388 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1389 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1390 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1391
1392   $str = '\t';
1393   return "\Q$str";
1394
1395 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1396
1397 Interpolated scalars and arrays are converted internally to the C<join> and
1398 C<.> catentation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1399
1400   $foo . " XXX '" . (join $", @arr) . "'";
1401
1402 All operations above are performed simultaneously, left to right.
1403
1404 Because the result of C<"\Q STRING \E"> has all metacharacters
1405 quoted, there is no way to insert a literal C<$> or C<@> inside a
1406 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1407 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1408 scalar.
1409
1410 Note also that the interpolation code needs to make a decision on
1411 where the interpolated scalar ends.  For instance, whether 
1412 C<"a $b -E<gt> {c}"> really means:
1413
1414   "a " . $b . " -> {c}";
1415
1416 or:
1417
1418   "a " . $b -> {c};
1419
1420 Most of the time, the longest possible text that does not include
1421 spaces between components and which contains matching braces or
1422 brackets.  because the outcome may be determined by voting based
1423 on heuristic estimators, the result is not strictly predictable.
1424 Fortunately, it's usually correct for ambiguous cases.
1425
1426 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>, 
1427
1428 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1429 happens (almost) as with C<qq//> constructs, but the substitution
1430 of C<\> followed by RE-special chars (including C<\>) is not
1431 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1432 a C<#>-comment in a C<//x>-regular expression, no processing is
1433 performed whatsoever.  This is the first step at which the presence
1434 of the C<//x> modifier is relevant.
1435
1436 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1437 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1438 different estimators) to be either an array element or C<$var>
1439 followed by an RE alternative.  This is where the notation
1440 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1441 array element C<-9>, not as a regular expression from the variable
1442 C<$arr> followed by a digit, which would be the interpretation of
1443 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1444 the result is not predictable.
1445
1446 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1447 the replacement text of C<s///> to correct the incorrigible
1448 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1449 is emitted if the B<-w> command-line flag (that is, the C<$^W> variable)
1450 was set.
1451
1452 The lack of processing of C<\\> creates specific restrictions on
1453 the post-processed text.  If the delimiter is C</>, one cannot get
1454 the combination C<\/> into the result of this step.  C</> will
1455 finish the regular expression, C<\/> will be stripped to C</> on
1456 the previous step, and C<\\/> will be left as is.  Because C</> is
1457 equivalent to C<\/> inside a regular expression, this does not
1458 matter unless the delimiter happens to be character special to the
1459 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1460 alphanumeric char, as in:
1461
1462   m m ^ a \s* b mmx;
1463
1464 In the RE above, which is intentionally obfuscated for illustration, the
1465 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1466 RE is the same as for C<m/ ^ a s* b /mx>).  There's more than one 
1467 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1468 non-whitespace choices.
1469
1470 =back
1471
1472 This step is the last one for all constructs except regular expressions,
1473 which are processed further.
1474
1475 =item Interpolation of regular expressions
1476
1477 Previous steps were performed during the compilation of Perl code,
1478 but this one happens at run time--although it may be optimized to
1479 be calculated at compile time if appropriate.  After preprocessing
1480 described above, and possibly after evaluation if catenation,
1481 joining, casing translation, or metaquoting are involved, the
1482 resulting I<string> is passed to the RE engine for compilation.
1483
1484 Whatever happens in the RE engine might be better discussed in L<perlre>,
1485 but for the sake of continuity, we shall do so here.
1486
1487 This is another step where the presence of the C<//x> modifier is
1488 relevant.  The RE engine scans the string from left to right and
1489 converts it to a finite automaton.
1490
1491 Backslashed characters are either replaced with corresponding
1492 literal strings (as with C<\{>), or else they generate special nodes
1493 in the finite automaton (as with C<\b>).  Characters special to the
1494 RE engine (such as C<|>) generate corresponding nodes or groups of
1495 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1496 converted to literal strings to match, or else is ignored (as is
1497 whitespace and C<#>-style comments if C<//x> is present).
1498
1499 Parsing of the bracketed character class construct, C<[...]>, is
1500 rather different than the rule used for the rest of the pattern.
1501 The terminator of this construct is found using the same rules as
1502 for finding the terminator of a C<{}>-delimited construct, the only
1503 exception being that C<]> immediately following C<[> is treated as
1504 though preceded by a backslash.  Similarly, the terminator of
1505 C<(?{...})> is found using the same rules as for finding the
1506 terminator of a C<{}>-delimited construct.
1507
1508 It is possible to inspect both the string given to RE engine and the
1509 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1510 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1511 switch documented in L<perlrun/Switches>.
1512
1513 =item Optimization of regular expressions
1514
1515 This step is listed for completeness only.  Since it does not change
1516 semantics, details of this step are not documented and are subject
1517 to change without notice.  This step is performed over the finite
1518 automaton that was generated during the previous pass.
1519
1520 It is at this stage that C<split()> silently optimizes C</^/> to
1521 mean C</^/m>.
1522
1523 =back
1524
1525 =head2 I/O Operators
1526
1527 There are several I/O operators you should know about.
1528
1529 A string enclosed by backticks (grave accents) first undergoes
1530 double-quote interpolation.  It is then interpreted as an external
1531 command, and the output of that command is the value of the
1532 pseudo-literal, j
1533 string consisting of all output is returned.  In list context, a
1534 list of values is returned, one per line of output.  (You can set
1535 C<$/> to use a different line terminator.)  The command is executed
1536 each time the pseudo-literal is evaluated.  The status value of the
1537 command is returned in C<$?> (see L<perlvar> for the interpretation
1538 of C<$?>).  Unlike in B<csh>, no translation is done on the return
1539 data--newlines remain newlines.  Unlike in any of the shells, single
1540 quotes do not hide variable names in the command from interpretation.
1541 To pass a literal dollar-sign through to the shell you need to hide
1542 it with a backslash.  The generalized form of backticks is C<qx//>.
1543 (Because backticks always undergo shell expansion as well, see
1544 L<perlsec> for security concerns.)
1545
1546 In scalar context, evaluating a filehandle in angle brackets yields
1547 the next line from that file (the newline, if any, included), or
1548 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
1549 (sometimes known as file-slurp mode) and the file is empty, it
1550 returns C<''> the first time, followed by C<undef> subsequently.
1551
1552 Ordinarily you must assign the returned value to a variable, but
1553 there is one situation where an automatic assignment happens.  If
1554 and only if the input symbol is the only thing inside the conditional
1555 of a C<while> statement (even if disguised as a C<for(;;)> loop),
1556 the value is automatically assigned to the global variable $_,
1557 destroying whatever was there previously.  (This may seem like an
1558 odd thing to you, but you'll use the construct in almost every Perl
1559 script you write.)  The $_ variables is not implicitly localized.
1560 You'll have to put a C<local $_;> before the loop if you want that
1561 to happen.
1562
1563 The following lines are equivalent:
1564
1565     while (defined($_ = <STDIN>)) { print; }
1566     while ($_ = <STDIN>) { print; }
1567     while (<STDIN>) { print; }
1568     for (;<STDIN>;) { print; }
1569     print while defined($_ = <STDIN>);
1570     print while ($_ = <STDIN>);
1571     print while <STDIN>;
1572
1573 This also behaves similarly, but avoids $_ :
1574
1575     while (my $line = <STDIN>) { print $line }    
1576
1577 In these loop constructs, the assigned value (whether assignment
1578 is automatic or explicit) is then tested to see whether it is
1579 defined.  The defined test avoids problems where line has a string
1580 value that would be treated as false by Perl, for example a "" or
1581 a "0" with no trailing newline.  If you really mean for such values
1582 to terminate the loop, they should be tested for explicitly:
1583
1584     while (($_ = <STDIN>) ne '0') { ... }
1585     while (<STDIN>) { last unless $_; ... }
1586
1587 In other boolean contexts, C<E<lt>I<filehandle>E<gt>> without an
1588 explicit C<defined> test or comparison elicit a warning if the B<-w>
1589 command-line switch (the C<$^W> variable) is in effect.
1590
1591 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
1592 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
1593 in packages, where they would be interpreted as local identifiers
1594 rather than global.)  Additional filehandles may be created with
1595 the open() function, amongst others.  See L<perlopentut> and
1596 L<perlfunc/open> for details on this.
1597
1598 If a E<lt>FILEHANDLEE<gt> is used in a context that is looking for
1599 a list, a list comprising all input lines is returned, one line per
1600 list element.  It's easy to grow to a rather large data space this
1601 way, so use with care.
1602
1603 E<lt>FILEHANDLEE<gt> may also be spelled C<readline(*FILEHANDLE)>.
1604 See L<perlfunc/readline>.
1605
1606 The null filehandle E<lt>E<gt> is special: it can be used to emulate the
1607 behavior of B<sed> and B<awk>.  Input from E<lt>E<gt> comes either from
1608 standard input, or from each file listed on the command line.  Here's
1609 how it works: the first time E<lt>E<gt> is evaluated, the @ARGV array is
1610 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
1611 gives you standard input.  The @ARGV array is then processed as a list
1612 of filenames.  The loop
1613
1614     while (<>) {
1615         ...                     # code for each line
1616     }
1617
1618 is equivalent to the following Perl-like pseudo code:
1619
1620     unshift(@ARGV, '-') unless @ARGV;
1621     while ($ARGV = shift) {
1622         open(ARGV, $ARGV);
1623         while (<ARGV>) {
1624             ...         # code for each line
1625         }
1626     }
1627
1628 except that it isn't so cumbersome to say, and will actually work.
1629 It really does shift the @ARGV array and put the current filename
1630 into the $ARGV variable.  It also uses filehandle I<ARGV>
1631 internally--E<lt>E<gt> is just a synonym for E<lt>ARGVE<gt>, which
1632 is magical.  (The pseudo code above doesn't work because it treats
1633 E<lt>ARGVE<gt> as non-magical.)
1634
1635 You can modify @ARGV before the first E<lt>E<gt> as long as the array ends up
1636 containing the list of filenames you really want.  Line numbers (C<$.>)
1637 continue as though the input were one big happy file.  See the example
1638 in L<perlfunc/eof> for how to reset line numbers on each file.
1639
1640 If you want to set @ARGV to your own list of files, go right ahead.  
1641 This sets @ARGV to all plain text files if no @ARGV was given:
1642
1643     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
1644
1645 You can even set them to pipe commands.  For example, this automatically
1646 filters compressed arguments through B<gzip>:
1647
1648     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
1649
1650 If you want to pass switches into your script, you can use one of the
1651 Getopts modules or put a loop on the front like this:
1652
1653     while ($_ = $ARGV[0], /^-/) {
1654         shift;
1655         last if /^--$/;
1656         if (/^-D(.*)/) { $debug = $1 }
1657         if (/^-v/)     { $verbose++  }
1658         # ...           # other switches
1659     }
1660
1661     while (<>) {
1662         # ...           # code for each line
1663     }
1664
1665 The E<lt>E<gt> symbol will return C<undef> for end-of-file only once.  
1666 If you call it again after this, it will assume you are processing another 
1667 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
1668
1669 If angle brackets contain is a simple scalar variable (e.g.,
1670 E<lt>$fooE<gt>), then that variable contains the name of the
1671 filehandle to input from, or its typeglob, or a reference to the
1672 same.  For example:
1673
1674     $fh = \*STDIN;
1675     $line = <$fh>;
1676
1677 If what's within the angle brackets is neither a filehandle nor a simple
1678 scalar variable containing a filehandle name, typeglob, or typeglob
1679 reference, it is interpreted as a filename pattern to be globbed, and
1680 either a list of filenames or the next filename in the list is returned,
1681 depending on context.  This distinction is determined on syntactic
1682 grounds alone.  That means C<E<lt>$xE<gt>> is always a readline() from
1683 an indirect handle, but C<E<lt>$hash{key}E<gt>> is always a glob().
1684 That's because $x is a simple scalar variable, but C<$hash{key}> is
1685 not--it's a hash element.
1686
1687 One level of double-quote interpretation is done first, but you can't
1688 say C<E<lt>$fooE<gt>> because that's an indirect filehandle as explained
1689 in the previous paragraph.  (In older versions of Perl, programmers
1690 would insert curly brackets to force interpretation as a filename glob:
1691 C<E<lt>${foo}E<gt>>.  These days, it's considered cleaner to call the
1692 internal function directly as C<glob($foo)>, which is probably the right
1693 way to have done it in the first place.)  For example:
1694
1695     while (<*.c>) {
1696         chmod 0644, $_;
1697     }
1698
1699 is equivalent to
1700
1701     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
1702     while (<FOO>) {
1703         chop;
1704         chmod 0644, $_;
1705     }
1706
1707 In fact, it's currently implemented that way, but this is expected
1708 to be made completely internal in the near future.  (Which means
1709 it will not work on filenames with spaces in them unless you have
1710 csh(1) on your machine.)  Of course, the shortest way to do the
1711 above is:
1712
1713     chmod 0644, <*.c>;
1714
1715 Because globbing currently invokes a shell, it's often faster to
1716 call readdir() yourself and do your own grep() on the filenames.
1717 Furthermore, due to its current implementation of using a shell,
1718 the glob() routine may get "Arg list too long" errors (unless you've
1719 installed tcsh(1L) as F</bin/csh> or hacked your F<config.sh>).
1720
1721 A (file)glob evaluates its (embedded) argument only when it is
1722 starting a new list.  All values must be read before it will start
1723 over.  In list context, this isn't important because you automatically
1724 get them all anyway.  However, in scalar context the operator returns
1725 the next value each time it's called, or C
1726 run out.  As with filehandle reads, an automatic C<defined> is
1727 generated when the glob occurs in the test part of a C<while>,
1728 because legal glob returns (e.g. a file called F<0>) would otherwise
1729 terminate the loop.  Again, C<undef> is returned only once.  So if
1730 you're expecting a single value from a glob, it is much better to
1731 say
1732
1733     ($file) = <blurch*>;
1734
1735 than
1736
1737     $file = <blurch*>;
1738
1739 because the latter will alternate between returning a filename and
1740 returning false.
1741
1742 It you're trying to do variable interpolation, it's definitely better
1743 to use the glob() function, because the older notation can cause people
1744 to become confused with the indirect filehandle notation.
1745
1746     @files = glob("$dir/*.[ch]");
1747     @files = glob($files[$i]);
1748
1749 =head2 Constant Folding
1750
1751 Like C, Perl does a certain amount of expression evaluation at
1752 compile time whenever it determines that all arguments to an
1753 operator are static and have no side effects.  In particular, string
1754 concatenation happens at compile time between literals that don't do
1755 variable substitution.  Backslash interpolation also happens at
1756 compile time.  You can say
1757
1758     'Now is the time for all' . "\n" .
1759         'good men to come to.'
1760
1761 and this all reduces to one string internally.  Likewise, if
1762 you say
1763
1764     foreach $file (@filenames) {
1765         if (-s $file > 5 + 100 * 2**16) {  }
1766     }
1767
1768 the compiler will precompute the number which that expression
1769 represents so that the interpreter won't have to.
1770
1771 =head2 Bitwise String Operators
1772
1773 Bitstrings of any size may be manipulated by the bitwise operators
1774 (C<~ | & ^>).
1775
1776 If the operands to a binary bitwise op are strings of different
1777 sizes, B<|> and B<^> ops act as though the shorter operand had
1778 additional zero bits on the right, while the B<&> op acts as though
1779 the longer operand were truncated to the length of the shorter.
1780 The granularity for such extension or truncation is one or more
1781 bytes.
1782
1783     # ASCII-based examples 
1784     print "j p \n" ^ " a h";            # prints "JAPH\n"
1785     print "JA" | "  ph\n";              # prints "japh\n"
1786     print "japh\nJunk" & '_____';       # prints "JAPH\n";
1787     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
1788
1789 If you are intending to manipulate bitstrings, be certain that
1790 you're supplying bitstrings: If an operand is a number, that will imply
1791 a B<numeric> bitwise operation.  You may explicitly show which type of
1792 operation you intend by using C<""> or C<0+>, as in the examples below.
1793
1794     $foo =  150  |  105 ;       # yields 255  (0x96 | 0x69 is 0xFF)
1795     $foo = '150' |  105 ;       # yields 255
1796     $foo =  150  | '105';       # yields 255
1797     $foo = '150' | '105';       # yields string '155' (under ASCII)
1798
1799     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
1800     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
1801
1802 See L<perlfunc/vec> for information on how to manipulate individual bits
1803 in a bit vector.
1804
1805 =head2 Integer Arithmetic
1806
1807 By default, Perl assumes that it must do most of its arithmetic in
1808 floating point.  But by saying
1809
1810     use integer;
1811
1812 you may tell the compiler that it's okay to use integer operations
1813 (if it feels like it) from here to the end of the enclosing BLOCK.
1814 An inner BLOCK may countermand this by saying
1815
1816     no integer;
1817
1818 which lasts until the end of that BLOCK.  Note that this doesn't
1819 mean everything is only an integer, merely that Perl may use integer
1820 operations if it is so inclined.  For example, even under C<use
1821 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
1822 or so.
1823
1824 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
1825 and ">>") always produce integral results.  (But see also L<Bitwise
1826 String Operators>.)  However, C<use integer> still has meaning for
1827 them.  By default, their results are interpreted as unsigned integers, but
1828 if C<use integer> is in effect, their results are interpreted
1829 as signed integers.  For example, C<~0> usually evaluates to a large
1830 integral value.  However, C<use integer; ~0> is C<-1> on twos-complement
1831 machines.
1832
1833 =head2 Floating-point Arithmetic
1834
1835 While C<use integer> provides integer-only arithmetic, there is no
1836 analogous mechanism to provide automatic rounding or truncation to a
1837 certain number of decimal places.  For rounding to a certain number
1838 of digits, sprintf() or printf() is usually the easiest route.
1839 See L<perlfaq4>.
1840
1841 Floating-point numbers are only approximations to what a mathematician
1842 would call real numbers.  There are infinitely more reals than floats,
1843 so some corners must be cut.  For example:
1844
1845     printf "%.20g\n", 123456789123456789;
1846     #        produces 123456789123456784
1847
1848 Testing for exact equality of floating-point equality or inequality is
1849 not a good idea.  Here's a (relatively expensive) work-around to compare
1850 whether two floating-point numbers are equal to a particular number of
1851 decimal places.  See Knuth, volume II, for a more robust treatment of
1852 this topic.
1853
1854     sub fp_equal {
1855         my ($X, $Y, $POINTS) = @_;
1856         my ($tX, $tY);
1857         $tX = sprintf("%.${POINTS}g", $X);
1858         $tY = sprintf("%.${POINTS}g", $Y);
1859         return $tX eq $tY;
1860     }
1861
1862 The POSIX module (part of the standard perl distribution) implements
1863 ceil(), floor(), and other mathematical and trigonometric functions.
1864 The Math::Complex module (part of the standard perl distribution)
1865 defines mathematical functions that work on both the reals and the
1866 imaginary numbers.  Math::Complex not as efficient as POSIX, but
1867 POSIX can't work with complex numbers.
1868
1869 Rounding in financial applications can have serious implications, and
1870 the rounding method used should be specified precisely.  In these
1871 cases, it probably pays not to trust whichever system rounding is
1872 being used by Perl, but to instead implement the rounding function you
1873 need yourself.
1874
1875 =head2 Bigger Numbers
1876
1877 The standard Math::BigInt and Math::BigFloat modules provide
1878 variable-precision arithmetic and overloaded operators, although
1879 they're currently pretty slow.  At the cost of some space and
1880 considerable speed, they avoid the normal pitfalls associated with
1881 limited-precision representations.
1882
1883     use Math::BigInt;
1884     $x = Math::BigInt->new('123456789123456789');
1885     print $x * $x;
1886
1887     # prints +15241578780673678515622620750190521
1888
1889 The non-standard modules SSLeay::BN and Math::Pari provide
1890 equivalent functionality (and much more) with a substantial
1891 performance savings.