pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19 =head2 The backslash
  20
  21 In a regular expression, the backslash can perform one of two tasks:
  22 it either takes away the special meaning of the character following it
  23 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  24 or it is the start of a backslash or escape sequence.
  25
  26 The rules determining what it is are quite simple: if the character
  27 following the backslash is an ASCII punctuation (non-word) character (that is,
  28 anything that is not a letter, digit, or underscore), then the backslash just
  29 takes away any special meaning of the character following it.
  30
  31 If the character following the backslash is an ASCII letter or an ASCII digit,
  32 then the sequence may be special; if so, it's listed below. A few letters have
  33 not been used yet, so escaping them with a backslash doesn't change them to be
  34 special.  A future version of Perl may assign a special meaning to them, so if
  35 you have warnings turned on, Perl issues a warning if you use such a
  36 sequence.  [1].
  37
  38 It is however guaranteed that backslash or escape sequences never have a
  39 punctuation character following the backslash, not now, and not in a future
  40 version of Perl 5. So it is safe to put a backslash in front of a non-word
  41 character.
  42
  43 Note that the backslash itself is special; if you want to match a backslash,
  44 you have to escape the backslash with a backslash: C</\\/> matches a single
  45 backslash.
  46
  47 =over 4
  48
  49 =item [1]
  50
  51 There is one exception. If you use an alphanumeric character as the
  52 delimiter of your pattern (which you probably shouldn't do for readability
  53 reasons), you have to escape the delimiter if you want to match
  54 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  55 quoted constructs>.
  56
  57 =back
  58
  59
  60 =head2 All the sequences and escapes
  61
  62 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
  63 as C<Not in [].>
  64
  65  \000              Octal escape sequence.  See also \o{}.
  66  \1                Absolute backreference.  Not in [].
  67  \a                Alarm or bell.
  68  \A                Beginning of string.  Not in [].
  69  \b                Word/non-word boundary. (Backspace in []).
  70  \B                Not a word/non-word boundary.  Not in [].
  71  \cX               Control-X
  72  \C                Single octet, even under UTF-8.  Not in [].
  73  \d                Character class for digits.
  74  \D                Character class for non-digits.
  75  \e                Escape character.
  76  \E                Turn off \Q, \L and \U processing.  Not in [].
  77  \f                Form feed.
  78  \F                Foldcase till \E.  Not in [].
  79  \g{}, \g1         Named, absolute or relative backreference.  Not in []
  80  \G                Pos assertion.  Not in [].
  81  \h                Character class for horizontal whitespace.
  82  \H                Character class for non horizontal whitespace.
  83  \k{}, \k<>, \k''  Named backreference.  Not in [].
  84  \K                Keep the stuff left of \K.  Not in [].
  85  \l                Lowercase next character.  Not in [].
  86  \L                Lowercase till \E.  Not in [].
  87  \n                (Logical) newline character.
  88  \N                Any character but newline.  Experimental.  Not in [].
  89  \N{}              Named or numbered (Unicode) character or sequence.
  90  \o{}              Octal escape sequence.
  91  \p{}, \pP         Character with the given Unicode property.
  92  \P{}, \PP         Character without the given Unicode property.
  93  \Q                Quotemeta till \E.  Not in [].
  94  \r                Return character.
  95  \R                Generic new line.  Not in [].
  96  \s                Character class for whitespace.
  97  \S                Character class for non whitespace.
  98  \t                Tab character.
  99  \u                Titlecase next character.  Not in [].
 100  \U                Uppercase till \E.  Not in [].
 101  \v                Character class for vertical whitespace.
 102  \V                Character class for non vertical whitespace.
 103  \w                Character class for word characters.
 104  \W                Character class for non-word characters.
 105  \x{}, \x00        Hexadecimal escape sequence.
 106  \X                Unicode "extended grapheme cluster".  Not in [].
 107  \z                End of string.  Not in [].
 108  \Z                End of string.  Not in [].
 109
 110 =head2 Character Escapes
 111
 112 =head3  Fixed characters
 113
 114 A handful of characters have a dedicated I<character escape>. The following
 115 table shows them, along with their ASCII code points (in decimal and hex),
 116 their ASCII name, the control escape on ASCII platforms and a short
 117 description.  (For EBCDIC platforms, see L<perlebcdic/OPERATOR DIFFERENCES>.)
 118
 119  Seq.  Code Point  ASCII   Cntrl   Description.
 120        Dec    Hex
 121   \a     7     07    BEL    \cG    alarm or bell
 122   \b     8     08     BS    \cH    backspace [1]
 123   \e    27     1B    ESC    \c[    escape character
 124   \f    12     0C     FF    \cL    form feed
 125   \n    10     0A     LF    \cJ    line feed [2]
 126   \r    13     0D     CR    \cM    carriage return
 127   \t     9     09    TAB    \cI    tab
 128
 129 =over 4
 130
 131 =item [1]
 132
 133 C<\b> is the backspace character only inside a character class. Outside a
 134 character class, C<\b> is a word/non-word boundary.
 135
 136 =item [2]
 137
 138 C<\n> matches a logical newline. Perl converts between C<\n> and your
 139 OS's native newline character when reading from or writing to text files.
 140
 141 =back
 142
 143 =head4 Example
 144
 145  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 146
 147 =head3 Control characters
 148
 149 C<\c> is used to denote a control character; the character following C<\c>
 150 determines the value of the construct.  For example the value of C<\cA> is
 151 C<chr(1)>, and the value of C<\cb> is C<chr(2)>, etc.
 152 The gory details are in L<perlop/"Regexp Quote-Like Operators">.  A complete
 153 list of what C<chr(1)>, etc. means for ASCII and EBCDIC platforms is in
 154 L<perlebcdic/OPERATOR DIFFERENCES>.
 155
 156 Note that C<\c\> alone at the end of a regular expression (or doubled-quoted
 157 string) is not valid.  The backslash must be followed by another character.
 158 That is, C<\c\I<X>> means C<chr(28) . 'I<X>'> for all characters I<X>.
 159
 160 To write platform-independent code, you must use C<\N{I<NAME>}> instead, like
 161 C<\N{ESCAPE}> or C<\N{U+001B}>, see L<charnames>.
 162
 163 Mnemonic: I<c>ontrol character.
 164
 165 =head4 Example
 166
 167  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 168
 169 =head3 Named or numbered characters and character sequences
 170
 171 Unicode characters have a Unicode name and numeric code point (ordinal)
 172 value.  Use the
 173 C<\N{}> construct to specify a character by either of these values.
 174 Certain sequences of characters also have names.
 175
 176 To specify by name, the name of the character or character sequence goes
 177 between the curly braces.
 178
 179 To specify a character by Unicode code point, use the form C<\N{U+I<code
 180 point>}>, where I<code point> is a number in hexadecimal that gives the
 181 code point that Unicode has assigned to the desired character.  It is
 182 customary but not required to use leading zeros to pad the number to 4
 183 digits.  Thus C<\N{U+0041}> means C<LATIN CAPITAL LETTER A>, and you will
 184 rarely see it written without the two leading zeros.  C<\N{U+0041}> means
 185 "A" even on EBCDIC machines (where the ordinal value of "A" is not 0x41).
 186
 187 It is even possible to give your own names to characters and character
 188 sequences.  For details, see L<charnames>.
 189
 190 (There is an expanded internal form that you may see in debug output:
 191 C<\N{U+I<code point>.I<code point>...}>.
 192 The C<...> means any number of these I<code point>s separated by dots.
 193 This represents the sequence formed by the characters.  This is an internal
 194 form only, subject to change, and you should not try to use it yourself.)
 195
 196 Mnemonic: I<N>amed character.
 197
 198 Note that a character or character sequence expressed as a named
 199 or numbered character is considered a character without special
 200 meaning by the regex engine, and will match "as is".
 201
 202 =head4 Example
 203
 204  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 205
 206  use charnames 'Cyrillic';            # Loads Cyrillic names.
 207  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 208
 209 =head3 Octal escapes
 210
 211 There are two forms of octal escapes.  Each is used to specify a character by
 212 its code point specified in octal notation.
 213
 214 One form, available starting in Perl 5.14 looks like C<\o{...}>, where the dots
 215 represent one or more octal digits.  It can be used for any Unicode character.
 216
 217 It was introduced to avoid the potential problems with the other form,
 218 available in all Perls.  That form consists of a backslash followed by three
 219 octal digits.  One problem with this form is that it can look exactly like an
 220 old-style backreference (see
 221 L</Disambiguation rules between old-style octal escapes and backreferences>
 222 below.)  You can avoid this by making the first of the three digits always a
 223 zero, but that makes \077 the largest code point specifiable.
 224
 225 In some contexts, a backslash followed by two or even one octal digits may be
 226 interpreted as an octal escape, sometimes with a warning, and because of some
 227 bugs, sometimes with surprising results.  Also, if you are creating a regex
 228 out of smaller snippets concatenated together, and you use fewer than three
 229 digits, the beginning of one snippet may be interpreted as adding digits to the
 230 ending of the snippet before it.  See L</Absolute referencing> for more
 231 discussion and examples of the snippet problem.
 232
 233 Note that a character expressed as an octal escape is considered
 234 a character without special meaning by the regex engine, and will match
 235 "as is".
 236
 237 To summarize, the C<\o{}> form is always safe to use, and the other form is
 238 safe to use for code points through \077 when you use exactly three digits to
 239 specify them.
 240
 241 Mnemonic: I<0>ctal or I<o>ctal.
 242
 243 =head4 Examples (assuming an ASCII platform)
 244
 245  $str = "Perl";
 246  $str =~ /\o{120}/;  # Match, "\120" is "P".
 247  $str =~ /\120/;     # Same.
 248  $str =~ /\o{120}+/; # Match, "\120" is "P", it's repeated at least once
 249  $str =~ /\120+/;    # Same.
 250  $str =~ /P\053/;    # No match, "\053" is "+" and taken literally.
 251  /\o{23073}/         # Black foreground, white background smiling face.
 252  /\o{4801234567}/    # Raises a warning, and yields chr(4)
 253
 254 =head4 Disambiguation rules between old-style octal escapes and backreferences
 255
 256 Octal escapes of the C<\000> form outside of bracketed character classes
 257 potentially clash with old-style backreferences.  (see L</Absolute referencing>
 258 below).  They both consist of a backslash followed by numbers.  So Perl has to
 259 use heuristics to determine whether it is a backreference or an octal escape.
 260 Perl uses the following rules to disambiguate:
 261
 262 =over 4
 263
 264 =item 1
 265
 266 If the backslash is followed by a single digit, it's a backreference.
 267
 268 =item 2
 269
 270 If the first digit following the backslash is a 0, it's an octal escape.
 271
 272 =item 3
 273
 274 If the number following the backslash is N (in decimal), and Perl already
 275 has seen N capture groups, Perl considers this a backreference.  Otherwise,
 276 it considers it an octal escape. If N has more than three digits, Perl
 277 takes only the first three for the octal escape; the rest are matched as is.
 278
 279  my $pat  = "(" x 999;
 280     $pat .= "a";
 281     $pat .= ")" x 999;
 282  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 283  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 284                     #    and \1000 is seen as \100 (a '@') and a '0'
 285
 286 =back
 287
 288 You can force a backreference interpretation always by using the C<\g{...}>
 289 form.  You can the force an octal interpretation always by using the C<\o{...}>
 290 form, or for numbers up through \077 (= 63 decimal), by using three digits,
 291 beginning with a "0".
 292
 293 =head3 Hexadecimal escapes
 294
 295 Like octal escapes, there are two forms of hexadecimal escapes, but both start
 296 with the same thing, C<\x>.  This is followed by either exactly two hexadecimal
 297 digits forming a number, or a hexadecimal number of arbitrary length surrounded
 298 by curly braces. The hexadecimal number is the code point of the character you
 299 want to express.
 300
 301 Note that a character expressed as one of these escapes is considered a
 302 character without special meaning by the regex engine, and will match
 303 "as is".
 304
 305 Mnemonic: heI<x>adecimal.
 306
 307 =head4 Examples (assuming an ASCII platform)
 308
 309  $str = "Perl";
 310  $str =~ /\x50/;    # Match, "\x50" is "P".
 311  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once
 312  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 313
 314  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 315                     # The Unicode character 2603 is a snowman,
 316                     # the Unicode character 2602 is an umbrella.
 317  /\x{263B}/         # Black smiling face.
 318  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 319
 320 =head2 Modifiers
 321
 322 A number of backslash sequences have to do with changing the character,
 323 or characters following them. C<\l> will lowercase the character following
 324 it, while C<\u> will uppercase (or, more accurately, titlecase) the
 325 character following it. They provide functionality similar to the
 326 functions C<lcfirst> and C<ucfirst>.
 327
 328 To uppercase or lowercase several characters, one might want to use
 329 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 330 them, until either the end of the pattern or the next occurrence of
 331 C<\E>, whichever comes first. They provide functionality similar to what
 332 the functions C<lc> and C<uc> provide.
 333
 334 C<\Q> is used to escape all characters following, up to the next C<\E>
 335 or the end of the pattern. C<\Q> adds a backslash to any character that
 336 isn't a letter, digit, or underscore. This ensures that any character
 337 between C<\Q> and C<\E> shall be matched literally, not interpreted
 338 as a metacharacter by the regex engine.
 339
 340 C<\F> can be used to casefold all characters following, up to the next C<\E>
 341 or the end of the pattern. It provides the functionality similar to
 342 the C<fc> function.
 343
 344 Mnemonic: I<L>owercase, I<U>ppercase, I<F>old-case, I<Q>uotemeta, I<E>nd.
 345
 346 =head4 Examples
 347
 348  $sid     = "sid";
 349  $greg    = "GrEg";
 350  $miranda = "(Miranda)";
 351  $str     =~ /\u$sid/;        # Matches 'Sid'
 352  $str     =~ /\L$greg/;       # Matches 'greg'
 353  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 354                               #   had been written as /\(Miranda\)/
 355
 356 =head2 Character classes
 357
 358 Perl regular expressions have a large range of character classes. Some of
 359 the character classes are written as a backslash sequence. We will briefly
 360 discuss those here; full details of character classes can be found in
 361 L<perlrecharclass>.
 362
 363 C<\w> is a character class that matches any single I<word> character
 364 (letters, digits, Unicode marks, and connector punctuation (like the
 365 underscore)).  C<\d> is a character class that matches any decimal
 366 digit, while the character class C<\s> matches any whitespace character.
 367 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
 368 and vertical whitespace characters.
 369
 370 The exact set of characters matched by C<\d>, C<\s>, and C<\w> varies
 371 depending on various pragma and regular expression modifiers.  It is
 372 possible to restrict the match to the ASCII range by using the C</a>
 373 regular expression modifier.  See L<perlrecharclass>.
 374
 375 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 376 character classes that match, respectively, any character that isn't a
 377 word character, digit, whitespace, horizontal whitespace, or vertical
 378 whitespace.
 379
 380 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 381
 382 =head3 Unicode classes
 383
 384 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 385 match a character that matches the given Unicode property; properties
 386 include things like "letter", or "thai character". Capitalizing the
 387 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 388 that doesn't match the given Unicode property. For more details, see
 389 L<perlrecharclass/Backslash sequences> and
 390 L<perlunicode/Unicode Character Properties>.
 391
 392 Mnemonic: I<p>roperty.
 393
 394 =head2 Referencing
 395
 396 If capturing parenthesis are used in a regular expression, we can refer
 397 to the part of the source string that was matched, and match exactly the
 398 same thing. There are three ways of referring to such I<backreference>:
 399 absolutely, relatively, and by name.
 400
 401 =for later add link to perlrecapture
 402
 403 =head3 Absolute referencing
 404
 405 Either C<\gI<N>> (starting in Perl 5.10.0), or C<\I<N>> (old-style) where I<N>
 406 is a positive (unsigned) decimal number of any length is an absolute reference
 407 to a capturing group.
 408
 409 I<N> refers to the Nth set of parentheses, so C<\gI<N>> refers to whatever has
 410 been matched by that set of parentheses.  Thus C<\g1> refers to the first
 411 capture group in the regex.
 412
 413 The C<\gI<N>> form can be equivalently written as C<\g{I<N>}>
 414 which avoids ambiguity when building a regex by concatenating shorter
 415 strings.  Otherwise if you had a regex C<qr/$a$b/>, and C<$a> contained
 416 C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which is
 417 probably not what you intended.
 418
 419 In the C<\I<N>> form, I<N> must not begin with a "0", and there must be at
 420 least I<N> capturing groups, or else I<N> is considered an octal escape
 421 (but something like C<\18> is the same as C<\0018>; that is, the octal escape
 422 C<"\001"> followed by a literal digit C<"8">).
 423
 424 Mnemonic: I<g>roup.
 425
 426 =head4 Examples
 427
 428  /(\w+) \g1/;    # Finds a duplicated word, (e.g. "cat cat").
 429  /(\w+) \1/;     # Same thing; written old-style
 430  /(.)(.)\g2\g1/;  # Match a four letter palindrome (e.g. "ABBA").
 431
 432
 433 =head3 Relative referencing
 434
 435 C<\g-I<N>> (starting in Perl 5.10.0) is used for relative addressing.  (It can
 436 be written as C<\g{-I<N>>.)  It refers to the I<N>th group before the
 437 C<\g{-I<N>}>.
 438
 439 The big advantage of this form is that it makes it much easier to write
 440 patterns with references that can be interpolated in larger patterns,
 441 even if the larger pattern also contains capture groups.
 442
 443 =head4 Examples
 444
 445  /(A)        # Group 1
 446   (          # Group 2
 447     (B)      # Group 3
 448     \g{-1}   # Refers to group 3 (B)
 449     \g{-3}   # Refers to group 1 (A)
 450   )
 451  /x;         # Matches "ABBA".
 452
 453  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 454  /$qr$qr/                           # Matches 'ababcdcd'.
 455
 456 =head3 Named referencing
 457
 458 C<\g{I<name>}> (starting in Perl 5.10.0) can be used to back refer to a
 459 named capture group, dispensing completely with having to think about capture
 460 buffer positions.
 461
 462 To be compatible with .Net regular expressions, C<\g{name}> may also be
 463 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 464
 465 To prevent any ambiguity, I<name> must not start with a digit nor contain a
 466 hyphen.
 467
 468 =head4 Examples
 469
 470  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 471  /(?<word>\w+) \k{word}/ # Same.
 472  /(?<word>\w+) \k<word>/ # Same.
 473  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 474                          # Match a four letter palindrome (e.g. "ABBA")
 475
 476 =head2 Assertions
 477
 478 Assertions are conditions that have to be true; they don't actually
 479 match parts of the substring. There are six assertions that are written as
 480 backslash sequences.
 481
 482 =over 4
 483
 484 =item \A
 485
 486 C<\A> only matches at the beginning of the string. If the C</m> modifier
 487 isn't used, then C</\A/> is equivalent to C</^/>. However, if the C</m>
 488 modifier is used, then C</^/> matches internal newlines, but the meaning
 489 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 490 of the string regardless whether the C</m> modifier is used.
 491
 492 =item \z, \Z
 493
 494 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 495 used, then C</\Z/> is equivalent to C</$/>; that is, it matches at the
 496 end of the string, or one before the newline at the end of the string. If the
 497 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 498 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 499 the end of the string (or just before a trailing newline) regardless whether
 500 the C</m> modifier is used.
 501
 502 C<\z> is just like C<\Z>, except that it does not match before a trailing
 503 newline. C<\z> matches at the end of the string only, regardless of the
 504 modifiers used, and not just before a newline.  It is how to anchor the
 505 match to the true end of the string under all conditions.
 506
 507 =item \G
 508
 509 C<\G> is usually used only in combination with the C</g> modifier. If the
 510 C</g> modifier is used and the match is done in scalar context, Perl
 511 remembers where in the source string the last match ended, and the next time,
 512 it will start the match from where it ended the previous time.
 513
 514 C<\G> matches the point where the previous match on that string ended,
 515 or the beginning of that string if there was no previous match.
 516
 517 =for later add link to perlremodifiers
 518
 519 Mnemonic: I<G>lobal.
 520
 521 =item \b, \B
 522
 523 C<\b> matches at any place between a word and a non-word character; C<\B>
 524 matches at any place between characters where C<\b> doesn't match. C<\b>
 525 and C<\B> assume there's a non-word character before the beginning and after
 526 the end of the source string; so C<\b> will match at the beginning (or end)
 527 of the source string if the source string begins (or ends) with a word
 528 character. Otherwise, C<\B> will match.
 529
 530 Do not use something like C<\b=head\d\b> and expect it to match the
 531 beginning of a line.  It can't, because for there to be a boundary before
 532 the non-word "=", there must be a word character immediately previous.
 533 All boundary determinations look for word characters alone, not for
 534 non-words characters nor for string ends.  It may help to understand how
 535 <\b> and <\B> work by equating them as follows:
 536
 537     \b  really means    (?:(?<=\w)(?!\w)|(?<!\w)(?=\w))
 538     \B  really means    (?:(?<=\w)(?=\w)|(?<!\w)(?!\w))
 539
 540 Mnemonic: I<b>oundary.
 541
 542 =back
 543
 544 =head4 Examples
 545
 546   "cat"   =~ /\Acat/;     # Match.
 547   "cat"   =~ /cat\Z/;     # Match.
 548   "cat\n" =~ /cat\Z/;     # Match.
 549   "cat\n" =~ /cat\z/;     # No match.
 550
 551   "cat"   =~ /\bcat\b/;   # Matches.
 552   "cats"  =~ /\bcat\b/;   # No match.
 553   "cat"   =~ /\bcat\B/;   # No match.
 554   "cats"  =~ /\bcat\B/;   # Match.
 555
 556   while ("cat dog" =~ /(\w+)/g) {
 557       print $1;           # Prints 'catdog'
 558   }
 559   while ("cat dog" =~ /\G(\w+)/g) {
 560       print $1;           # Prints 'cat'
 561   }
 562
 563 =head2 Misc
 564
 565 Here we document the backslash sequences that don't fall in one of the
 566 categories above. These are:
 567
 568 =over 4
 569
 570 =item \C
 571
 572 C<\C> always matches a single octet, even if the source string is encoded
 573 in UTF-8 format, and the character to be matched is a multi-octet character.
 574 C<\C> was introduced in perl 5.6.  This is very dangerous, because it violates
 575 the logical character abstraction and can cause UTF-8 sequences to become malformed.
 576
 577 Mnemonic: oI<C>tet.
 578
 579 =item \K
 580
 581 This appeared in perl 5.10.0. Anything matched left of C<\K> is
 582 not included in C<$&>, and will not be replaced if the pattern is
 583 used in a substitution. This lets you write C<s/PAT1 \K PAT2/REPL/x>
 584 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 585
 586 Mnemonic: I<K>eep.
 587
 588 =item \N
 589
 590 This is an experimental feature new to perl 5.12.0.  It matches any character
 591 that is B<not> a newline.  It is a short-hand for writing C<[^\n]>, and is
 592 identical to the C<.> metasymbol, except under the C</s> flag, which changes
 593 the meaning of C<.>, but not C<\N>.
 594
 595 Note that C<\N{...}> can mean a
 596 L<named or numbered character
 597 |/Named or numbered characters and character sequences>.
 598
 599 Mnemonic: Complement of I<\n>.
 600
 601 =item \R
 602 X<\R>
 603
 604 C<\R> matches a I<generic newline>; that is, anything considered a
 605 linebreak sequence by Unicode. This includes all characters matched by
 606 C<\v> (vertical whitespace), and the multi character sequence C<"\x0D\x0A">
 607 (carriage return followed by a line feed, sometimes called the network
 608 newline; it's the end of line sequence used in Microsoft text files opened
 609 in binary mode). C<\R> is equivalent to C<< (?>\x0D\x0A|\v) >>.  (The
 610 reason it doesn't backtrack is that the sequence is considered
 611 inseparable.  That means that
 612
 613  "\x0D\x0A" =~ /^\R\x0A$/   # No match
 614
 615 fails, because the C<\R> matches the entire string, and won't backtrack
 616 to match just the C<"\x0D">.)  Since
 617 C<\R> can match a sequence of more than one character, it cannot be put
 618 inside a bracketed character class; C</[\R]/> is an error; use C<\v>
 619 instead.  C<\R> was introduced in perl 5.10.0.
 620
 621 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
 622 and more importantly because Unicode recommends such a regular expression
 623 metacharacter, and suggests C<\R> as its notation.
 624
 625 =item \X
 626 X<\X>
 627
 628 This matches a Unicode I<extended grapheme cluster>.
 629
 630 C<\X> matches quite well what normal (non-Unicode-programmer) usage
 631 would consider a single character.  As an example, consider a G with some sort
 632 of diacritic mark, such as an arrow.  There is no such single character in
 633 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
 634 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
 635 were a single character.
 636
 637 Mnemonic: eI<X>tended Unicode character.
 638
 639 =back
 640
 641 =head4 Examples
 642
 643  "\x{256}" =~ /^\C\C$/;    # Match as chr (0x256) takes 2 octets in UTF-8.
 644
 645  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'
 646  $str =~ s/(.)\K\g1//g;    # Delete duplicated characters.
 647
 648  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 649  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 650  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 651
 652  "P\x{307}" =~ /^\X$/     # \X matches a P with a dot above.
 653
 654 =cut