utils/h2xs.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 my $origdir = cwd;
  17 chdir dirname($0);
  18 my $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 use warnings;
  39
  40 =head1 NAME
  41
  42 h2xs - convert .h C header files to Perl extensions
  43
  44 =head1 SYNOPSIS
  45
  46 B<h2xs> [B<OPTIONS> ...] [headerfile ... [extra_libraries]]
  47
  48 B<h2xs> B<-h>|B<-?>|B<--help>
  49
  50 =head1 DESCRIPTION
  51
  52 I<h2xs> builds a Perl extension from C header files.  The extension
  53 will include functions which can be used to retrieve the value of any
  54 #define statement which was in the C header files.
  55
  56 The I<module_name> will be used for the name of the extension.  If
  57 module_name is not supplied then the name of the first header file
  58 will be used, with the first character capitalized.
  59
  60 If the extension might need extra libraries, they should be included
  61 here.  The extension Makefile.PL will take care of checking whether
  62 the libraries actually exist and how they should be loaded.  The extra
  63 libraries should be specified in the form -lm -lposix, etc, just as on
  64 the cc command line.  By default, the Makefile.PL will search through
  65 the library path determined by Configure.  That path can be augmented
  66 by including arguments of the form B<-L/another/library/path> in the
  67 extra-libraries argument.
  68
  69 =head1 OPTIONS
  70
  71 =over 5
  72
  73 =item B<-A>, B<--omit-autoload>
  74
  75 Omit all autoload facilities.  This is the same as B<-c> but also
  76 removes the S<C<use AutoLoader>> statement from the .pm file.
  77
  78 =item B<-B>, B<--beta-version>
  79
  80 Use an alpha/beta style version number.  Causes version number to
  81 be "0.00_01" unless B<-v> is specified.
  82
  83 =item B<-C>, B<--omit-changes>
  84
  85 Omits creation of the F<Changes> file, and adds a HISTORY section to
  86 the POD template.
  87
  88 =item B<-F>, B<--cpp-flags>=I<addflags>
  89
  90 Additional flags to specify to C preprocessor when scanning header for
  91 function declarations.  Writes these options in the generated F<Makefile.PL>
  92 too.
  93
  94 =item B<-M>, B<--func-mask>=I<regular expression>
  95
  96 selects functions/macros to process.
  97
  98 =item B<-O>, B<--overwrite-ok>
  99
 100 Allows a pre-existing extension directory to be overwritten.
 101
 102 =item B<-P>, B<--omit-pod>
 103
 104 Omit the autogenerated stub POD section.
 105
 106 =item B<-X>, B<--omit-XS>
 107
 108 Omit the XS portion.  Used to generate templates for a module which is not
 109 XS-based.  C<-c> and C<-f> are implicitly enabled.
 110
 111 =item B<-a>, B<--gen-accessors>
 112
 113 Generate an accessor method for each element of structs and unions. The
 114 generated methods are named after the element name; will return the current
 115 value of the element if called without additional arguments; and will set
 116 the element to the supplied value (and return the new value) if called with
 117 an additional argument. Embedded structures and unions are returned as a
 118 pointer rather than the complete structure, to facilitate chained calls.
 119
 120 These methods all apply to the Ptr type for the structure; additionally
 121 two methods are constructed for the structure type itself, C<_to_ptr>
 122 which returns a Ptr type pointing to the same structure, and a C<new>
 123 method to construct and return a new structure, initialised to zeroes.
 124
 125 =item B<-b>, B<--compat-version>=I<version>
 126
 127 Generates a .pm file which is backwards compatible with the specified
 128 perl version.
 129
 130 For versions < 5.6.0, the changes are.
 131     - no use of 'our' (uses 'use vars' instead)
 132     - no 'use warnings'
 133
 134 Specifying a compatibility version higher than the version of perl you
 135 are using to run h2xs will have no effect.  If unspecified h2xs will default
 136 to compatibility with the version of perl you are using to run h2xs.
 137
 138 =item B<-c>, B<--omit-constant>
 139
 140 Omit C<constant()> from the .xs file and corresponding specialised
 141 C<AUTOLOAD> from the .pm file.
 142
 143 =item B<-d>, B<--debugging>
 144
 145 Turn on debugging messages.
 146
 147 =item B<-e>, B<--omit-enums>=[I<regular expression>]
 148
 149 If I<regular expression> is not given, skip all constants that are defined in
 150 a C enumeration. Otherwise skip only those constants that are defined in an
 151 enum whose name matches I<regular expression>.
 152
 153 Since I<regular expression> is optional, make sure that this switch is followed
 154 by at least one other switch if you omit I<regular expression> and have some
 155 pending arguments such as header-file names. This is ok:
 156
 157     h2xs -e -n Module::Foo foo.h
 158
 159 This is not ok:
 160
 161     h2xs -n Module::Foo -e foo.h
 162
 163 In the latter, foo.h is taken as I<regular expression>.
 164
 165 =item B<-f>, B<--force>
 166
 167 Allows an extension to be created for a header even if that header is
 168 not found in standard include directories.
 169
 170 =item B<-g>, B<--global>
 171
 172 Include code for safely storing static data in the .xs file.
 173 Extensions that do no make use of static data can ignore this option.
 174
 175 =item B<-h>, B<-?>, B<--help>
 176
 177 Print the usage, help and version for this h2xs and exit.
 178
 179 =item B<-k>, B<--omit-const-func>
 180
 181 For function arguments declared as C<const>, omit the const attribute in the
 182 generated XS code.
 183
 184 =item B<-m>, B<--gen-tied-var>
 185
 186 B<Experimental>: for each variable declared in the header file(s), declare
 187 a perl variable of the same name magically tied to the C variable.
 188
 189 =item B<-n>, B<--name>=I<module_name>
 190
 191 Specifies a name to be used for the extension, e.g., S<-n RPC::DCE>
 192
 193 =item B<-o>, B<--opaque-re>=I<regular expression>
 194
 195 Use "opaque" data type for the C types matched by the regular
 196 expression, even if these types are C<typedef>-equivalent to types
 197 from typemaps.  Should not be used without B<-x>.
 198
 199 This may be useful since, say, types which are C<typedef>-equivalent
 200 to integers may represent OS-related handles, and one may want to work
 201 with these handles in OO-way, as in C<$handle-E<gt>do_something()>.
 202 Use C<-o .> if you want to handle all the C<typedef>ed types as opaque
 203 types.
 204
 205 The type-to-match is whitewashed (except for commas, which have no
 206 whitespace before them, and multiple C<*> which have no whitespace
 207 between them).
 208
 209 =item B<-p>, B<--remove-prefix>=I<prefix>
 210
 211 Specify a prefix which should be removed from the Perl function names,
 212 e.g., S<-p sec_rgy_> This sets up the XS B<PREFIX> keyword and removes
 213 the prefix from functions that are autoloaded via the C<constant()>
 214 mechanism.
 215
 216 =item B<-s>, B<--const-subs>=I<sub1,sub2>
 217
 218 Create a perl subroutine for the specified macros rather than autoload
 219 with the constant() subroutine.  These macros are assumed to have a
 220 return type of B<char *>, e.g.,
 221 S<-s sec_rgy_wildcard_name,sec_rgy_wildcard_sid>.
 222
 223 =item B<-t>, B<--default-type>=I<type>
 224
 225 Specify the internal type that the constant() mechanism uses for macros.
 226 The default is IV (signed integer).  Currently all macros found during the
 227 header scanning process will be assumed to have this type.  Future versions
 228 of C<h2xs> may gain the ability to make educated guesses.
 229
 230 =item B<--use-new-tests>
 231
 232 When B<--compat-version> (B<-b>) is present the generated tests will use
 233 C<Test::More> rather than C<Test> which is the default for versions before
 234 5.7.2 .   C<Test::More> will be added to PREREQ_PM in the generated
 235 C<Makefile.PL>.
 236
 237 =item B<--use-old-tests>
 238
 239 Will force the generation of test code that uses the older C<Test> module.
 240
 241 =item B<--skip-exporter>
 242
 243 Do not use C<Exporter> and/or export any symbol.
 244
 245 =item B<--skip-ppport>
 246
 247 Do not use C<Devel::PPPort>: no portability to older version.
 248
 249 =item B<--skip-autoloader>
 250
 251 Do not use the module C<AutoLoader>; but keep the constant() function
 252 and C<sub AUTOLOAD> for constants.
 253
 254 =item B<--skip-strict>
 255
 256 Do not use the pragma C<strict>.
 257
 258 =item B<--skip-warnings>
 259
 260 Do not use the pragma C<warnings>.
 261
 262 =item B<-v>, B<--version>=I<version>
 263
 264 Specify a version number for this extension.  This version number is added
 265 to the templates.  The default is 0.01, or 0.00_01 if C<-B> is specified.
 266 The version specified should be numeric.
 267
 268 =item B<-x>, B<--autogen-xsubs>
 269
 270 Automatically generate XSUBs basing on function declarations in the
 271 header file.  The package C<C::Scan> should be installed. If this
 272 option is specified, the name of the header file may look like
 273 C<NAME1,NAME2>. In this case NAME1 is used instead of the specified
 274 string, but XSUBs are emitted only for the declarations included from
 275 file NAME2.
 276
 277 Note that some types of arguments/return-values for functions may
 278 result in XSUB-declarations/typemap-entries which need
 279 hand-editing. Such may be objects which cannot be converted from/to a
 280 pointer (like C<long long>), pointers to functions, or arrays.  See
 281 also the section on L<LIMITATIONS of B<-x>>.
 282
 283 =back
 284
 285 =head1 EXAMPLES
 286
 287
 288     # Default behavior, extension is Rusers
 289     h2xs rpcsvc/rusers
 290
 291     # Same, but extension is RUSERS
 292     h2xs -n RUSERS rpcsvc/rusers
 293
 294     # Extension is rpcsvc::rusers. Still finds <rpcsvc/rusers.h>
 295     h2xs rpcsvc::rusers
 296
 297     # Extension is ONC::RPC.  Still finds <rpcsvc/rusers.h>
 298     h2xs -n ONC::RPC rpcsvc/rusers
 299
 300     # Without constant() or AUTOLOAD
 301     h2xs -c rpcsvc/rusers
 302
 303     # Creates templates for an extension named RPC
 304     h2xs -cfn RPC
 305
 306     # Extension is ONC::RPC.
 307     h2xs -cfn ONC::RPC
 308
 309     # Extension is Lib::Foo which works at least with Perl5.005_03.
 310     # Constants are created for all #defines and enums h2xs can find
 311     # in foo.h.
 312     h2xs -b 5.5.3 -n Lib::Foo foo.h
 313
 314     # Extension is Lib::Foo which works at least with Perl5.005_03.
 315     # Constants are created for all #defines but only for enums
 316     # whose names do not start with 'bar_'.
 317     h2xs -b 5.5.3 -e '^bar_' -n Lib::Foo foo.h
 318
 319     # Makefile.PL will look for library -lrpc in
 320     # additional directory /opt/net/lib
 321     h2xs rpcsvc/rusers -L/opt/net/lib -lrpc
 322
 323     # Extension is DCE::rgynbase
 324     # prefix "sec_rgy_" is dropped from perl function names
 325     h2xs -n DCE::rgynbase -p sec_rgy_ dce/rgynbase
 326
 327     # Extension is DCE::rgynbase
 328     # prefix "sec_rgy_" is dropped from perl function names
 329     # subroutines are created for sec_rgy_wildcard_name and
 330     # sec_rgy_wildcard_sid
 331     h2xs -n DCE::rgynbase -p sec_rgy_ \
 332     -s sec_rgy_wildcard_name,sec_rgy_wildcard_sid dce/rgynbase
 333
 334     # Make XS without defines in perl.h, but with function declarations
 335     # visible from perl.h. Name of the extension is perl1.
 336     # When scanning perl.h, define -DEXT=extern -DdEXT= -DINIT(x)=
 337     # Extra backslashes below because the string is passed to shell.
 338     # Note that a directory with perl header files would
 339     #  be added automatically to include path.
 340     h2xs -xAn perl1 -F "-DEXT=extern -DdEXT= -DINIT\(x\)=" perl.h
 341
 342     # Same with function declaration in proto.h as visible from perl.h.
 343     h2xs -xAn perl2 perl.h,proto.h
 344
 345     # Same but select only functions which match /^av_/
 346     h2xs -M '^av_' -xAn perl2 perl.h,proto.h
 347
 348     # Same but treat SV* etc as "opaque" types
 349     h2xs -o '^[S]V \*$' -M '^av_' -xAn perl2 perl.h,proto.h
 350
 351 =head2 Extension based on F<.h> and F<.c> files
 352
 353 Suppose that you have some C files implementing some functionality,
 354 and the corresponding header files.  How to create an extension which
 355 makes this functionality accessable in Perl?  The example below
 356 assumes that the header files are F<interface_simple.h> and
 357 I<interface_hairy.h>, and you want the perl module be named as
 358 C<Ext::Ension>.  If you need some preprocessor directives and/or
 359 linking with external libraries, see the flags C<-F>, C<-L> and C<-l>
 360 in L<"OPTIONS">.
 361
 362 =over
 363
 364 =item Find the directory name
 365
 366 Start with a dummy run of h2xs:
 367
 368   h2xs -Afn Ext::Ension
 369
 370 The only purpose of this step is to create the needed directories, and
 371 let you know the names of these directories.  From the output you can
 372 see that the directory for the extension is F<Ext/Ension>.
 373
 374 =item Copy C files
 375
 376 Copy your header files and C files to this directory F<Ext/Ension>.
 377
 378 =item Create the extension
 379
 380 Run h2xs, overwriting older autogenerated files:
 381
 382   h2xs -Oxan Ext::Ension interface_simple.h interface_hairy.h
 383
 384 h2xs looks for header files I<after> changing to the extension
 385 directory, so it will find your header files OK.
 386
 387 =item Archive and test
 388
 389 As usual, run
 390
 391   cd Ext/Ension
 392   perl Makefile.PL
 393   make dist
 394   make
 395   make test
 396
 397 =item Hints
 398
 399 It is important to do C<make dist> as early as possible.  This way you
 400 can easily merge(1) your changes to autogenerated files if you decide
 401 to edit your C<.h> files and rerun h2xs.
 402
 403 Do not forget to edit the documentation in the generated F<.pm> file.
 404
 405 Consider the autogenerated files as skeletons only, you may invent
 406 better interfaces than what h2xs could guess.
 407
 408 Consider this section as a guideline only, some other options of h2xs
 409 may better suit your needs.
 410
 411 =back
 412
 413 =head1 ENVIRONMENT
 414
 415 No environment variables are used.
 416
 417 =head1 AUTHOR
 418
 419 Larry Wall and others
 420
 421 =head1 SEE ALSO
 422
 423 L<perl>, L<perlxstut>, L<ExtUtils::MakeMaker>, and L<AutoLoader>.
 424
 425 =head1 DIAGNOSTICS
 426
 427 The usual warnings if it cannot read or write the files involved.
 428
 429 =head1 LIMITATIONS of B<-x>
 430
 431 F<h2xs> would not distinguish whether an argument to a C function
 432 which is of the form, say, C<int *>, is an input, output, or
 433 input/output parameter.  In particular, argument declarations of the
 434 form
 435
 436     int
 437     foo(n)
 438         int *n
 439
 440 should be better rewritten as
 441
 442     int
 443     foo(n)
 444         int &n
 445
 446 if C<n> is an input parameter.
 447
 448 Additionally, F<h2xs> has no facilities to intuit that a function
 449
 450    int
 451    foo(addr,l)
 452         char *addr
 453         int   l
 454
 455 takes a pair of address and length of data at this address, so it is better
 456 to rewrite this function as
 457
 458     int
 459     foo(sv)
 460             SV *addr
 461         PREINIT:
 462             STRLEN len;
 463             char *s;
 464         CODE:
 465             s = SvPV(sv,len);
 466             RETVAL = foo(s, len);
 467         OUTPUT:
 468             RETVAL
 469
 470 or alternately
 471
 472     static int
 473     my_foo(SV *sv)
 474     {
 475         STRLEN len;
 476         char *s = SvPV(sv,len);
 477
 478         return foo(s, len);
 479     }
 480
 481     MODULE = foo        PACKAGE = foo   PREFIX = my_
 482
 483     int
 484     foo(sv)
 485         SV *sv
 486
 487 See L<perlxs> and L<perlxstut> for additional details.
 488
 489 =cut
 490
 491 # ' # Grr
 492 use strict;
 493
 494
 495 my( $H2XS_VERSION ) = ' $Revision: 1.22 $ ' =~ /\$Revision:\s+([^\s]+)/;
 496 my $TEMPLATE_VERSION = '0.01';
 497 my @ARGS = @ARGV;
 498 my $compat_version = $];
 499
 500 use Getopt::Long;
 501 use Config;
 502 use Text::Wrap;
 503 $Text::Wrap::huge = 'overflow';
 504 $Text::Wrap::columns = 80;
 505 use ExtUtils::Constant qw (WriteConstants WriteMakefileSnippet autoload);
 506 use File::Compare;
 507
 508 sub usage {
 509     warn "@_\n" if @_;
 510     die <<EOFUSAGE;
 511 h2xs [OPTIONS ... ] [headerfile [extra_libraries]]
 512 version: $H2XS_VERSION
 513 OPTIONS:
 514     -A, --omit-autoload   Omit all autoloading facilities (implies -c).
 515     -B, --beta-version    Use beta \$VERSION of 0.00_01 (ignored if -v).
 516     -C, --omit-changes    Omit creating the Changes file, add HISTORY heading
 517                           to stub POD.
 518     -F, --cpp-flags       Additional flags for C preprocessor/compile.
 519     -M, --func-mask       Mask to select C functions/macros
 520                           (default is select all).
 521     -O, --overwrite-ok    Allow overwriting of a pre-existing extension directory.
 522     -P, --omit-pod        Omit the stub POD section.
 523     -X, --omit-XS         Omit the XS portion (implies both -c and -f).
 524     -a, --gen-accessors   Generate get/set accessors for struct and union members                           (used with -x).
 525     -b, --compat-version  Specify a perl version to be backwards compatibile with
 526     -c, --omit-constant   Omit the constant() function and specialised AUTOLOAD
 527                           from the XS file.
 528     -d, --debugging       Turn on debugging messages.
 529     -e, --omit-enums      Omit constants from enums in the constant() function.
 530                           If a pattern is given, only the matching enums are
 531                           ignored.
 532     -f, --force           Force creation of the extension even if the C header
 533                           does not exist.
 534     -g, --global          Include code for safely storing static data in the .xs file.
 535     -h, -?, --help        Display this help message
 536     -k, --omit-const-func Omit 'const' attribute on function arguments
 537                           (used with -x).
 538     -m, --gen-tied-var    Generate tied variables for access to declared
 539                           variables.
 540     -n, --name            Specify a name to use for the extension (recommended).
 541     -o, --opaque-re       Regular expression for \"opaque\" types.
 542     -p, --remove-prefix   Specify a prefix which should be removed from the
 543                           Perl function names.
 544     -s, --const-subs      Create subroutines for specified macros.
 545     -t, --default-type    Default type for autoloaded constants (default is IV)
 546         --use-new-tests   Use Test::More in backward compatible modules
 547         --use-old-tests   Use the module Test rather than Test::More
 548         --skip-exporter   Do not export symbols
 549         --skip-ppport     Do not use portability layer
 550         --skip-autoloader Do not use the module C<AutoLoader>
 551         --skip-strict     Do not use the pragma C<strict>
 552         --skip-warnings   Do not use the pragma C<warnings>
 553     -v, --version         Specify a version number for this extension.
 554     -x, --autogen-xsubs   Autogenerate XSUBs using C::Scan.
 555
 556 extra_libraries
 557          are any libraries that might be needed for loading the
 558          extension, e.g. -lm would try to link in the math library.
 559 EOFUSAGE
 560 }
 561
 562 my ($opt_A,
 563     $opt_B,
 564     $opt_C,
 565     $opt_F,
 566     $opt_M,
 567     $opt_O,
 568     $opt_P,
 569     $opt_X,
 570     $opt_a,
 571     $opt_c,
 572     $opt_d,
 573     $opt_e,
 574     $opt_f,
 575     $opt_g,
 576     $opt_h,
 577     $opt_k,
 578     $opt_m,
 579     $opt_n,
 580     $opt_o,
 581     $opt_p,
 582     $opt_s,
 583     $opt_v,
 584     $opt_x,
 585     $opt_b,
 586     $opt_t,
 587     $new_test,
 588     $old_test,
 589     $skip_exporter,
 590     $skip_ppport,
 591     $skip_autoloader,
 592     $skip_strict,
 593     $skip_warnings,
 594    );
 595
 596 Getopt::Long::Configure('bundling');
 597
 598 my %options = (
 599                 'omit-autoload|A'    => \$opt_A,
 600                 'beta-version|B'     => \$opt_B,
 601                 'omit-changes|C'     => \$opt_C,
 602                 'cpp-flags|F=s'      => \$opt_F,
 603                 'func-mask|M=s'      => \$opt_M,
 604                 'overwrite_ok|O'     => \$opt_O,
 605                 'omit-pod|P'         => \$opt_P,
 606                 'omit-XS|X'          => \$opt_X,
 607                 'gen-accessors|a'    => \$opt_a,
 608                 'compat-version|b=s' => \$opt_b,
 609                 'omit-constant|c'    => \$opt_c,
 610                 'debugging|d'        => \$opt_d,
 611                 'omit-enums|e:s'     => \$opt_e,
 612                 'force|f'            => \$opt_f,
 613                 'global|g'           => \$opt_g,
 614                 'help|h|?'           => \$opt_h,
 615                 'omit-const-func|k'  => \$opt_k,
 616                 'gen-tied-var|m'     => \$opt_m,
 617                 'name|n=s'           => \$opt_n,
 618                 'opaque-re|o=s'      => \$opt_o,
 619                 'remove-prefix|p=s'  => \$opt_p,
 620                 'const-subs|s=s'     => \$opt_s,
 621                 'default-type|t=s'   => \$opt_t,
 622                 'version|v=s'        => \$opt_v,
 623                 'autogen-xsubs|x'    => \$opt_x,
 624                 'use-new-tests'      => \$new_test,
 625                 'use-old-tests'      => \$old_test,
 626                 'skip-exporter'      => \$skip_exporter,
 627                 'skip-ppport'        => \$skip_ppport,
 628                 'skip-autoloader'    => \$skip_autoloader,
 629                 'skip-warnings'      => \$skip_warnings,
 630                 'skip-strict'        => \$skip_strict,
 631               );
 632
 633 GetOptions(%options) || usage;
 634
 635 usage if $opt_h;
 636
 637 if( $opt_b ){
 638     usage "You cannot use -b and -m at the same time.\n" if ($opt_b && $opt_m);
 639     $opt_b =~ /^\d+\.\d+\.\d+/ ||
 640     usage "You must provide the backwards compatibility version in X.Y.Z form. "
 641           .  "(i.e. 5.5.0)\n";
 642     my ($maj,$min,$sub) = split(/\./,$opt_b,3);
 643     if ($maj < 5 || ($maj == 5 && $min < 6)) {
 644         $compat_version =
 645             $sub ? sprintf("%d.%03d%02d",$maj,$min,$sub) :
 646                    sprintf("%d.%03d",    $maj,$min);
 647     } else {
 648         $compat_version =
 649             $sub ? sprintf("%d.%03d%03d",$maj,$min,$sub) :
 650                    sprintf("%d.%03d",    $maj,$min);
 651     }
 652 } else {
 653     my ($maj,$min,$sub) = $compat_version =~ /(\d+)\.(\d\d\d)(\d*)/;
 654     $sub ||= 0;
 655     warn sprintf <<'EOF', $maj,$min,$sub;
 656 Defaulting to backwards compatibility with perl %d.%d.%d
 657 If you intend this module to be compatible with earlier perl versions, please
 658 specify a minimum perl version with the -b option.
 659
 660 EOF
 661 }
 662
 663 if( $opt_B ){
 664     $TEMPLATE_VERSION = '0.00_01';
 665 }
 666
 667 if( $opt_v ){
 668         $TEMPLATE_VERSION = $opt_v;
 669
 670     # check if it is numeric
 671     my $temp_version = $TEMPLATE_VERSION;
 672     my $beta_version = $temp_version =~ s/(\d)_(\d\d)/$1$2/;
 673     my $notnum;
 674     {
 675         local $SIG{__WARN__} = sub { $notnum = 1 };
 676         use warnings 'numeric';
 677         $temp_version = 0+$temp_version;
 678     }
 679
 680     if ($notnum) {
 681         my $module = $opt_n || 'Your::Module';
 682         warn <<"EOF";
 683 You have specified a non-numeric version.  Unless you supply an
 684 appropriate VERSION class method, users may not be able to specify a
 685 minimum required version with C<use $module versionnum>.
 686
 687 EOF
 688     }
 689     else {
 690         $opt_B = $beta_version;
 691     }
 692 }
 693
 694 # -A implies -c.
 695 $skip_autoloader = $opt_c = 1 if $opt_A;
 696
 697 # -X implies -c and -f
 698 $opt_c = $opt_f = 1 if $opt_X;
 699
 700 $opt_t ||= 'IV';
 701
 702 my %const_xsub = map { $_,1 } split(/,+/, $opt_s) if $opt_s;
 703
 704 my $extralibs = '';
 705
 706 my @path_h;
 707
 708 while (my $arg = shift) {
 709     if ($arg =~ /^-l/i) {
 710         $extralibs = "$arg @ARGV";
 711         last;
 712     }
 713     push(@path_h, $arg);
 714 }
 715
 716 usage "Must supply header file or module name\n"
 717         unless (@path_h or $opt_n);
 718
 719 my $fmask;
 720 my $tmask;
 721
 722 $fmask = qr{$opt_M} if defined $opt_M;
 723 $tmask = qr{$opt_o} if defined $opt_o;
 724 my $tmask_all = $tmask && $opt_o eq '.';
 725
 726 if ($opt_x) {
 727   eval {require C::Scan; 1}
 728     or die <<EOD;
 729 C::Scan required if you use -x option.
 730 To install C::Scan, execute
 731    perl -MCPAN -e "install C::Scan"
 732 EOD
 733   unless ($tmask_all) {
 734     $C::Scan::VERSION >= 0.70
 735       or die <<EOD;
 736 C::Scan v. 0.70 or later required unless you use -o . option.
 737 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 738 To install C::Scan, execute
 739    perl -MCPAN -e "install C::Scan"
 740 EOD
 741   }
 742   if (($opt_m || $opt_a) && $C::Scan::VERSION < 0.73) {
 743     die <<EOD;
 744 C::Scan v. 0.73 or later required to use -m or -a options.
 745 You have version $C::Scan::VERSION installed as $INC{'C/Scan.pm'}.
 746 To install C::Scan, execute
 747    perl -MCPAN -e "install C::Scan"
 748 EOD
 749   }
 750 }
 751 elsif ($opt_o or $opt_F) {
 752   warn <<EOD if $opt_o;
 753 Option -o does not make sense without -x.
 754 EOD
 755   warn <<EOD if $opt_F and $opt_X ;
 756 Option -F does not make sense with -X.
 757 EOD
 758 }
 759
 760 my @path_h_ini = @path_h;
 761 my ($name, %fullpath, %prefix, %seen_define, %prefixless, %const_names);
 762
 763 my $module = $opt_n;
 764
 765 if( @path_h ){
 766     use File::Spec;
 767     my @paths;
 768     my $pre_sub_tri_graphs = 1;
 769     if ($^O eq 'VMS') {  # Consider overrides of default location
 770       # XXXX This is not equivalent to what the older version did:
 771       #         it was looking at $hadsys header-file per header-file...
 772       my($hadsys) = grep s!^sys/!!i , @path_h;
 773       @paths = qw( Sys$Library VAXC$Include );
 774       push @paths, ($hadsys ? 'GNU_CC_Include[vms]' : 'GNU_CC_Include[000000]');
 775       push @paths, qw( DECC$Library_Include DECC$System_Include );
 776     }
 777     else {
 778       @paths = (File::Spec->curdir(), $Config{usrinc},
 779                 (split ' ', $Config{locincpth}), '/usr/include');
 780     }
 781     foreach my $path_h (@path_h) {
 782         $name ||= $path_h;
 783     $module ||= do {
 784       $name =~ s/\.h$//;
 785       if ( $name !~ /::/ ) {
 786         $name =~ s#^.*/##;
 787         $name = "\u$name";
 788       }
 789       $name;
 790     };
 791
 792     if( $path_h =~ s#::#/#g && $opt_n ){
 793         warn "Nesting of headerfile ignored with -n\n";
 794     }
 795     $path_h .= ".h" unless $path_h =~ /\.h$/;
 796     my $fullpath = $path_h;
 797     $path_h =~ s/,.*$// if $opt_x;
 798     $fullpath{$path_h} = $fullpath;
 799
 800     # Minor trickery: we can't chdir() before we processed the headers
 801     # (so know the name of the extension), but the header may be in the
 802     # extension directory...
 803     my $tmp_path_h = $path_h;
 804     my $rel_path_h = $path_h;
 805     my @dirs = @paths;
 806     if (not -f $path_h) {
 807       my $found;
 808       for my $dir (@paths) {
 809         $found++, last
 810           if -f ($path_h = File::Spec->catfile($dir, $tmp_path_h));
 811       }
 812       if ($found) {
 813         $rel_path_h = $path_h;
 814         $fullpath{$path_h} = $fullpath;
 815       } else {
 816         (my $epath = $module) =~ s,::,/,g;
 817         $epath = File::Spec->catdir('ext', $epath) if -d 'ext';
 818         $rel_path_h = File::Spec->catfile($epath, $tmp_path_h);
 819         $path_h = $tmp_path_h;  # Used during -x
 820         push @dirs, $epath;
 821       }
 822     }
 823
 824     if (!$opt_c) {
 825       die "Can't find $tmp_path_h in @dirs\n"
 826         if ( ! $opt_f && ! -f "$rel_path_h" );
 827       # Scan the header file (we should deal with nested header files)
 828       # Record the names of simple #define constants into const_names
 829             # Function prototypes are processed below.
 830       open(CH, "<$rel_path_h") || die "Can't open $rel_path_h: $!\n";
 831     defines:
 832       while (<CH>) {
 833         if ($pre_sub_tri_graphs) {
 834             # Preprocess all tri-graphs
 835             # including things stuck in quoted string constants.
 836             s/\?\?=/#/g;                         # | ??=|  #|
 837             s/\?\?\!/|/g;                        # | ??!|  ||
 838             s/\?\?'/^/g;                         # | ??'|  ^|
 839             s/\?\?\(/[/g;                        # | ??(|  [|
 840             s/\?\?\)/]/g;                        # | ??)|  ]|
 841             s/\?\?\-/~/g;                        # | ??-|  ~|
 842             s/\?\?\//\\/g;                       # | ??/|  \|
 843             s/\?\?</{/g;                         # | ??<|  {|
 844             s/\?\?>/}/g;                         # | ??>|  }|
 845         }
 846         if (/^[ \t]*#[ \t]*define\s+([\$\w]+)\b(?!\()\s*(?=[^"\s])(.*)/) {
 847             my $def = $1;
 848             my $rest = $2;
 849             $rest =~ s!/\*.*?(\*/|\n)|//.*!!g; # Remove comments
 850             $rest =~ s/^\s+//;
 851             $rest =~ s/\s+$//;
 852             # Cannot do: (-1) and ((LHANDLE)3) are OK:
 853             #print("Skip non-wordy $def => $rest\n"),
 854             #  next defines if $rest =~ /[^\w\$]/;
 855             if ($rest =~ /"/) {
 856               print("Skip stringy $def => $rest\n") if $opt_d;
 857               next defines;
 858             }
 859             print "Matched $_ ($def)\n" if $opt_d;
 860             $seen_define{$def} = $rest;
 861             $_ = $def;
 862             next if /^_.*_h_*$/i; # special case, but for what?
 863             if (defined $opt_p) {
 864               if (!/^$opt_p(\d)/) {
 865                 ++$prefix{$_} if s/^$opt_p//;
 866               }
 867               else {
 868                 warn "can't remove $opt_p prefix from '$_'!\n";
 869               }
 870             }
 871             $prefixless{$def} = $_;
 872             if (!$fmask or /$fmask/) {
 873                 print "... Passes mask of -M.\n" if $opt_d and $fmask;
 874                 $const_names{$_}++;
 875             }
 876           }
 877       }
 878       if (defined $opt_e and !$opt_e) {
 879         close(CH);
 880       }
 881       else {
 882         # Work from miniperl too - on "normal" systems
 883         my $SEEK_SET = eval 'use Fcntl qw/SEEK_SET/; SEEK_SET' or 0;
 884         seek CH, 0, $SEEK_SET;
 885         my $src = do { local $/; <CH> };
 886         close CH;
 887         no warnings 'uninitialized';
 888
 889         # Remove C and C++ comments
 890         $src =~ s#/\*[^*]*\*+([^/*][^*]*\*+)*/|("(\\.|[^"\\])*"|'(\\.|[^'\\])*'|.[^/"'\\]*)#$2#gs;
 891
 892         while ($src =~ /(\benum\s*([\w_]*)\s*\{\s([\s\w=,]+)\})/gsc) {
 893             my ($enum_name, $enum_body) =
 894                 $1 =~ /enum\s*([\w_]*)\s*\{\s([\s\w=,]+)\}/gs;
 895             # skip enums matching $opt_e
 896             next if $opt_e && $enum_name =~ /$opt_e/;
 897             my $val = 0;
 898             for my $item (split /,/, $enum_body) {
 899                 my ($key, $declared_val) = $item =~ /(\w*)\s*=\s*(.*)/;
 900                 $val = length($declared_val) ? $declared_val : 1 + $val;
 901                 $seen_define{$key} = $declared_val;
 902                 $const_names{$key}++;
 903             }
 904         } # while (...)
 905       } # if (!defined $opt_e or $opt_e)
 906     }
 907     }
 908 }
 909
 910 # Save current directory so that C::Scan can use it
 911 my $cwd = File::Spec->rel2abs( File::Spec->curdir );
 912
 913 my ($ext, $nested, @modparts, $modfname, $modpname);
 914 # As Ilya suggested, use a name that contains - and then it can't clash with
 915 # the names of any packages. A directory 'fallback' will clash with any
 916 # new pragmata down the fallback:: tree, but that seems unlikely.
 917 my $constscfname = 'const-c.inc';
 918 my $constsxsfname = 'const-xs.inc';
 919 my $fallbackdirname = 'fallback';
 920
 921 $ext = chdir 'ext' ? 'ext/' : '';
 922
 923 if( $module =~ /::/ ){
 924         $nested = 1;
 925         @modparts = split(/::/,$module);
 926         $modfname = $modparts[-1];
 927         $modpname = join('/',@modparts);
 928 }
 929 else {
 930         $nested = 0;
 931         @modparts = ();
 932         $modfname = $modpname = $module;
 933 }
 934
 935
 936 if ($opt_O) {
 937         warn "Overwriting existing $ext$modpname!!!\n" if -e $modpname;
 938 }
 939 else {
 940         die "Won't overwrite existing $ext$modpname\n" if -e $modpname;
 941 }
 942 if( $nested ){
 943         my $modpath = "";
 944         foreach (@modparts){
 945                 -d "$modpath$_" || mkdir("$modpath$_", 0777);
 946                 $modpath .= "$_/";
 947         }
 948 }
 949 -d "$modpname"   || mkdir($modpname, 0777);
 950 chdir($modpname) || die "Can't chdir $ext$modpname: $!\n";
 951
 952 my %types_seen;
 953 my %std_types;
 954 my $fdecls = [];
 955 my $fdecls_parsed = [];
 956 my $typedef_rex;
 957 my %typedefs_pre;
 958 my %known_fnames;
 959 my %structs;
 960
 961 my @fnames;
 962 my @fnames_no_prefix;
 963 my %vdecl_hash;
 964 my @vdecls;
 965
 966 if( ! $opt_X ){  # use XS, unless it was disabled
 967   unless ($skip_ppport) {
 968     require Devel::PPPort;
 969     warn "Writing $ext$modpname/ppport.h\n";
 970     Devel::PPPort::WriteFile('ppport.h')
 971         || die "Can't create $ext$modpname/ppport.h: $!\n";
 972   }
 973   open(XS, ">$modfname.xs") || die "Can't create $ext$modpname/$modfname.xs: $!\n";
 974   if ($opt_x) {
 975     warn "Scanning typemaps...\n";
 976     get_typemap();
 977     my @td;
 978     my @good_td;
 979     my $addflags = $opt_F || '';
 980
 981     foreach my $filename (@path_h) {
 982       my $c;
 983       my $filter;
 984
 985       if ($fullpath{$filename} =~ /,/) {
 986         $filename = $`;
 987         $filter = $';
 988       }
 989       warn "Scanning $filename for functions...\n";
 990       my @styles = $Config{gccversion} ? qw(C++ C9X GNU) : qw(C++ C9X);
 991       $c = new C::Scan 'filename' => $filename, 'filename_filter' => $filter,
 992         'add_cppflags' => $addflags, 'c_styles' => \@styles;
 993       $c->set('includeDirs' => ["$Config::Config{archlib}/CORE", $cwd]);
 994
 995       push @$fdecls_parsed, @{ $c->get('parsed_fdecls') };
 996       push(@$fdecls, @{$c->get('fdecls')});
 997
 998       push @td, @{$c->get('typedefs_maybe')};
 999       if ($opt_a) {
1000         my $structs = $c->get('typedef_structs');
1001         @structs{keys %$structs} = values %$structs;
1002       }
1003
1004       if ($opt_m) {
1005         %vdecl_hash = %{ $c->get('vdecl_hash') };
1006         @vdecls = sort keys %vdecl_hash;
1007         for (local $_ = 0; $_ < @vdecls; ++$_) {
1008           my $var = $vdecls[$_];
1009           my($type, $post) = @{ $vdecl_hash{$var} };
1010           if (defined $post) {
1011             warn "Can't handle variable '$type $var $post', skipping.\n";
1012             splice @vdecls, $_, 1;
1013             redo;
1014           }
1015           $type = normalize_type($type);
1016           $vdecl_hash{$var} = $type;
1017         }
1018       }
1019
1020       unless ($tmask_all) {
1021         warn "Scanning $filename for typedefs...\n";
1022         my $td = $c->get('typedef_hash');
1023         # eval {require 'dumpvar.pl'; ::dumpValue($td)} or warn $@ if $opt_d;
1024         my @f_good_td = grep $td->{$_}[1] eq '', keys %$td;
1025         push @good_td, @f_good_td;
1026         @typedefs_pre{@f_good_td}  = map $_->[0], @$td{@f_good_td};
1027       }
1028     }
1029     { local $" = '|';
1030       $typedef_rex = qr(\b(?<!struct )(?:@good_td)\b) if @good_td;
1031     }
1032     %known_fnames = map @$_[1,3], @$fdecls_parsed; # [1,3] is NAME, FULLTEXT
1033     if ($fmask) {
1034       my @good;
1035       for my $i (0..$#$fdecls_parsed) {
1036         next unless $fdecls_parsed->[$i][1] =~ /$fmask/; # [1] is NAME
1037         push @good, $i;
1038         print "... Function $fdecls_parsed->[$i][1] passes -M mask.\n"
1039           if $opt_d;
1040       }
1041       $fdecls = [@$fdecls[@good]];
1042       $fdecls_parsed = [@$fdecls_parsed[@good]];
1043     }
1044     @fnames = sort map $_->[1], @$fdecls_parsed; # 1 is NAME
1045     # Sort declarations:
1046     {
1047       my %h = map( ($_->[1], $_), @$fdecls_parsed);
1048       $fdecls_parsed = [ @h{@fnames} ];
1049     }
1050     @fnames_no_prefix = @fnames;
1051     @fnames_no_prefix
1052       = sort map { ++$prefix{$_} if s/^$opt_p(?!\d)//; $_ } @fnames_no_prefix
1053          if defined $opt_p;
1054     # Remove macros which expand to typedefs
1055     print "Typedefs are @td.\n" if $opt_d;
1056     my %td = map {($_, $_)} @td;
1057     # Add some other possible but meaningless values for macros
1058     for my $k (qw(char double float int long short unsigned signed void)) {
1059       $td{"$_$k"} = "$_$k" for ('', 'signed ', 'unsigned ');
1060     }
1061     # eval {require 'dumpvar.pl'; ::dumpValue( [\@td, \%td] ); 1} or warn $@;
1062     my $n = 0;
1063     my %bad_macs;
1064     while (keys %td > $n) {
1065       $n = keys %td;
1066       my ($k, $v);
1067       while (($k, $v) = each %seen_define) {
1068         # print("found '$k'=>'$v'\n"),
1069         $bad_macs{$k} = $td{$k} = $td{$v} if exists $td{$v};
1070       }
1071     }
1072     # Now %bad_macs contains names of bad macros
1073     for my $k (keys %bad_macs) {
1074       delete $const_names{$prefixless{$k}};
1075       print "Ignoring macro $k which expands to a typedef name '$bad_macs{$k}'\n" if $opt_d;
1076     }
1077   }
1078 }
1079 my @const_names = sort keys %const_names;
1080
1081 open(PM, ">$modfname.pm") || die "Can't create $ext$modpname/$modfname.pm: $!\n";
1082
1083 $" = "\n\t";
1084 warn "Writing $ext$modpname/$modfname.pm\n";
1085
1086 print PM <<"END";
1087 package $module;
1088
1089 use $compat_version;
1090 END
1091
1092 print PM <<"END" unless $skip_strict;
1093 use strict;
1094 END
1095
1096 print PM "use warnings;\n" unless $skip_warnings or $compat_version < 5.006;
1097
1098 unless( $opt_X || $opt_c || $opt_A ){
1099         # we'll have an AUTOLOAD(), and it will have $AUTOLOAD and
1100         # will want Carp.
1101         print PM <<'END';
1102 use Carp;
1103 END
1104 }
1105
1106 print PM <<'END' unless $skip_exporter;
1107
1108 require Exporter;
1109 END
1110
1111 my $use_Dyna = (not $opt_X and $compat_version < 5.006);
1112 print PM <<"END" if $use_Dyna;  # use DynaLoader, unless XS was disabled
1113 require DynaLoader;
1114 END
1115
1116
1117 # Are we using AutoLoader or not?
1118 unless ($skip_autoloader) { # no autoloader whatsoever.
1119         unless ($opt_c) { # we're doing the AUTOLOAD
1120                 print PM "use AutoLoader;\n";
1121         }
1122         else {
1123                 print PM "use AutoLoader qw(AUTOLOAD);\n"
1124         }
1125 }
1126
1127 if ( $compat_version < 5.006 ) {
1128     my $vars = '$VERSION @ISA';
1129     $vars .= ' @EXPORT @EXPORT_OK %EXPORT_TAGS' unless $skip_exporter;
1130     $vars .= ' $AUTOLOAD' unless $opt_X || $opt_c || $opt_A;
1131     $vars .= ' $XS_VERSION' if $opt_B && !$opt_X;
1132     print PM "use vars qw($vars);";
1133 }
1134
1135 # Determine @ISA.
1136 my @modISA;
1137 push @modISA, 'Exporter'        unless $skip_exporter;
1138 push @modISA, 'DynaLoader'      if $use_Dyna;  # no XS
1139 my $myISA = "our \@ISA = qw(@modISA);";
1140 $myISA =~ s/^our // if $compat_version < 5.006;
1141
1142 print PM "\n$myISA\n\n";
1143
1144 my @exported_names = (@const_names, @fnames_no_prefix, map '$'.$_, @vdecls);
1145
1146 my $tmp='';
1147 $tmp .= <<"END" unless $skip_exporter;
1148 # Items to export into callers namespace by default. Note: do not export
1149 # names by default without a very good reason. Use EXPORT_OK instead.
1150 # Do not simply export all your public functions/methods/constants.
1151
1152 # This allows declaration       use $module ':all';
1153 # If you do not need this, moving things directly into \@EXPORT or \@EXPORT_OK
1154 # will save memory.
1155 our %EXPORT_TAGS = ( 'all' => [ qw(
1156         @exported_names
1157 ) ] );
1158
1159 our \@EXPORT_OK = ( \@{ \$EXPORT_TAGS{'all'} } );
1160
1161 our \@EXPORT = qw(
1162         @const_names
1163 );
1164
1165 END
1166
1167 $tmp .= "our \$VERSION = '$TEMPLATE_VERSION';\n";
1168 if ($opt_B) {
1169     $tmp .= "our \$XS_VERSION = \$VERSION;\n" unless $opt_X;
1170     $tmp .= "\$VERSION = eval \$VERSION;  # see L<perlmodstyle>\n";
1171 }
1172 $tmp .= "\n";
1173
1174 $tmp =~ s/^our //mg if $compat_version < 5.006;
1175 print PM $tmp;
1176
1177 if (@vdecls) {
1178     printf PM "our(@{[ join ', ', map '$'.$_, @vdecls ]});\n\n";
1179 }
1180
1181
1182 print PM autoload ($module, $compat_version) unless $opt_c or $opt_X;
1183
1184 if( ! $opt_X ){ # print bootstrap, unless XS is disabled
1185   if ($use_Dyna) {
1186         $tmp = <<"END";
1187 bootstrap $module \$VERSION;
1188 END
1189   } else {
1190         $tmp = <<"END";
1191 require XSLoader;
1192 XSLoader::load('$module', \$VERSION);
1193 END
1194   }
1195   $tmp =~ s:\$VERSION:\$XS_VERSION:g if $opt_B;
1196   print PM $tmp;
1197 }
1198
1199 # tying the variables can happen only after bootstrap
1200 if (@vdecls) {
1201     printf PM <<END;
1202 {
1203 @{[ join "\n", map "    _tievar_$_(\$$_);", @vdecls ]}
1204 }
1205
1206 END
1207 }
1208
1209 my $after;
1210 if( $opt_P ){ # if POD is disabled
1211         $after = '__END__';
1212 }
1213 else {
1214         $after = '=cut';
1215 }
1216
1217 print PM <<"END";
1218
1219 # Preloaded methods go here.
1220 END
1221
1222 print PM <<"END" unless $opt_A;
1223
1224 # Autoload methods go after $after, and are processed by the autosplit program.
1225 END
1226
1227 print PM <<"END";
1228
1229 1;
1230 __END__
1231 END
1232
1233 my ($email,$author);
1234
1235 eval {
1236        my $username;
1237        ($username,$author) = (getpwuid($>))[0,6];
1238        if (defined $username && defined $author) {
1239            $author =~ s/,.*$//; # in case of sub fields
1240            my $domain = $Config{'mydomain'};
1241            $domain =~ s/^\.//;
1242            $email = "$username\@$domain";
1243        }
1244      };
1245
1246 $author ||= "A. U. Thor";
1247 $email  ||= 'a.u.thor@a.galaxy.far.far.away';
1248
1249 my $revhist = '';
1250 $revhist = <<EOT if $opt_C;
1251 #
1252 #=head1 HISTORY
1253 #
1254 #=over 8
1255 #
1256 #=item $TEMPLATE_VERSION
1257 #
1258 #Original version; created by h2xs $H2XS_VERSION with options
1259 #
1260 #  @ARGS
1261 #
1262 #=back
1263 #
1264 EOT
1265
1266 my $exp_doc = $skip_exporter ? '' : <<EOD;
1267 #
1268 #=head2 EXPORT
1269 #
1270 #None by default.
1271 #
1272 EOD
1273
1274 if (@const_names and not $opt_P) {
1275   $exp_doc .= <<EOD unless $skip_exporter;
1276 #=head2 Exportable constants
1277 #
1278 #  @{[join "\n  ", @const_names]}
1279 #
1280 EOD
1281 }
1282
1283 if (defined $fdecls and @$fdecls and not $opt_P) {
1284   $exp_doc .= <<EOD unless $skip_exporter;
1285 #=head2 Exportable functions
1286 #
1287 EOD
1288
1289 #  $exp_doc .= <<EOD if $opt_p;
1290 #When accessing these functions from Perl, prefix C<$opt_p> should be removed.
1291 #
1292 #EOD
1293   $exp_doc .= <<EOD unless $skip_exporter;
1294 #  @{[join "\n  ", @known_fnames{@fnames}]}
1295 #
1296 EOD
1297 }
1298
1299 my $meth_doc = '';
1300
1301 if ($opt_x && $opt_a) {
1302   my($name, $struct);
1303   $meth_doc .= accessor_docs($name, $struct)
1304     while ($name, $struct) = each %structs;
1305 }
1306
1307 my $pod = <<"END" unless $opt_P;
1308 ## Below is stub documentation for your module. You'd better edit it!
1309 #
1310 #=head1 NAME
1311 #
1312 #$module - Perl extension for blah blah blah
1313 #
1314 #=head1 SYNOPSIS
1315 #
1316 #  use $module;
1317 #  blah blah blah
1318 #
1319 #=head1 DESCRIPTION
1320 #
1321 #Stub documentation for $module, created by h2xs. It looks like the
1322 #author of the extension was negligent enough to leave the stub
1323 #unedited.
1324 #
1325 #Blah blah blah.
1326 $exp_doc$meth_doc$revhist
1327 #
1328 #=head1 SEE ALSO
1329 #
1330 #Mention other useful documentation such as the documentation of
1331 #related modules or operating system documentation (such as man pages
1332 #in UNIX), or any relevant external documentation such as RFCs or
1333 #standards.
1334 #
1335 #If you have a mailing list set up for your module, mention it here.
1336 #
1337 #If you have a web site set up for your module, mention it here.
1338 #
1339 #=head1 AUTHOR
1340 #
1341 #$author, E<lt>${email}E<gt>
1342 #
1343 #=head1 COPYRIGHT AND LICENSE
1344 #
1345 #Copyright ${\(1900 + (localtime) [5])} by $author
1346 #
1347 #This library is free software; you can redistribute it and/or modify
1348 #it under the same terms as Perl itself.
1349 #
1350 #=cut
1351 END
1352
1353 $pod =~ s/^\#//gm unless $opt_P;
1354 print PM $pod unless $opt_P;
1355
1356 close PM;
1357
1358
1359 if( ! $opt_X ){ # print XS, unless it is disabled
1360 warn "Writing $ext$modpname/$modfname.xs\n";
1361
1362 print XS <<"END";
1363 #include "EXTERN.h"
1364 #include "perl.h"
1365 #include "XSUB.h"
1366
1367 END
1368
1369 print XS <<"END" unless $skip_ppport;
1370 #include "ppport.h"
1371
1372 END
1373
1374 if( @path_h ){
1375     foreach my $path_h (@path_h_ini) {
1376         my($h) = $path_h;
1377         $h =~ s#^/usr/include/##;
1378         if ($^O eq 'VMS') { $h =~ s#.*vms\]#sys/# or $h =~ s#.*[:>\]]##; }
1379         print XS qq{#include <$h>\n};
1380     }
1381     print XS "\n";
1382 }
1383
1384 print XS <<"END" if $opt_g;
1385
1386 /* Global Data */
1387
1388 #define MY_CXT_KEY "${module}::_guts" XS_VERSION
1389
1390 typedef struct {
1391     /* Put Global Data in here */
1392     int dummy;          /* you can access this elsewhere as MY_CXT.dummy */
1393 } my_cxt_t;
1394
1395 START_MY_CXT
1396
1397 END
1398
1399 my %pointer_typedefs;
1400 my %struct_typedefs;
1401
1402 sub td_is_pointer {
1403   my $type = shift;
1404   my $out = $pointer_typedefs{$type};
1405   return $out if defined $out;
1406   my $otype = $type;
1407   $out = ($type =~ /\*$/);
1408   # This converts only the guys which do not have trailing part in the typedef
1409   if (not $out
1410       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1411     $type = normalize_type($type);
1412     print "Is-Pointer: Type mutation via typedefs: $otype ==> $type\n"
1413       if $opt_d;
1414     $out = td_is_pointer($type);
1415   }
1416   return ($pointer_typedefs{$otype} = $out);
1417 }
1418
1419 sub td_is_struct {
1420   my $type = shift;
1421   my $out = $struct_typedefs{$type};
1422   return $out if defined $out;
1423   my $otype = $type;
1424   $out = ($type =~ /^(struct|union)\b/) && !td_is_pointer($type);
1425   # This converts only the guys which do not have trailing part in the typedef
1426   if (not $out
1427       and $typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1428     $type = normalize_type($type);
1429     print "Is-Struct: Type mutation via typedefs: $otype ==> $type\n"
1430       if $opt_d;
1431     $out = td_is_struct($type);
1432   }
1433   return ($struct_typedefs{$otype} = $out);
1434 }
1435
1436 print_tievar_subs(\*XS, $_, $vdecl_hash{$_}) for @vdecls;
1437
1438 if( ! $opt_c ) {
1439   # We write the "sample" files used when this module is built by perl without
1440   # ExtUtils::Constant.
1441   # h2xs will later check that these are the same as those generated by the
1442   # code embedded into Makefile.PL
1443   unless (-d $fallbackdirname) {
1444     mkdir "$fallbackdirname" or die "Cannot mkdir $fallbackdirname: $!\n";
1445   }
1446   warn "Writing $ext$modpname/$fallbackdirname/$constscfname\n";
1447   warn "Writing $ext$modpname/$fallbackdirname/$constsxsfname\n";
1448   my $cfallback = File::Spec->catfile($fallbackdirname, $constscfname);
1449   my $xsfallback = File::Spec->catfile($fallbackdirname, $constsxsfname);
1450   WriteConstants ( C_FILE =>       $cfallback,
1451                    XS_FILE =>      $xsfallback,
1452                    DEFAULT_TYPE => $opt_t,
1453                    NAME =>         $module,
1454                    NAMES =>        \@const_names,
1455                  );
1456   print XS "#include \"$constscfname\"\n";
1457 }
1458
1459
1460 my $prefix = defined $opt_p ? "PREFIX = $opt_p" : '';
1461
1462 # Now switch from C to XS by issuing the first MODULE declaration:
1463 print XS <<"END";
1464
1465 MODULE = $module                PACKAGE = $module               $prefix
1466
1467 END
1468
1469 # If a constant() function was #included then output a corresponding
1470 # XS declaration:
1471 print XS "INCLUDE: $constsxsfname\n" unless $opt_c;
1472
1473 print XS <<"END" if $opt_g;
1474
1475 BOOT:
1476 {
1477     MY_CXT_INIT;
1478     /* If any of the fields in the my_cxt_t struct need
1479        to be initialised, do it here.
1480      */
1481 }
1482
1483 END
1484
1485 foreach (sort keys %const_xsub) {
1486     print XS <<"END";
1487 char *
1488 $_()
1489
1490     CODE:
1491 #ifdef $_
1492         RETVAL = $_;
1493 #else
1494         croak("Your vendor has not defined the $module macro $_");
1495 #endif
1496
1497     OUTPUT:
1498         RETVAL
1499
1500 END
1501 }
1502
1503 my %seen_decl;
1504 my %typemap;
1505
1506 sub print_decl {
1507   my $fh = shift;
1508   my $decl = shift;
1509   my ($type, $name, $args) = @$decl;
1510   return if $seen_decl{$name}++; # Need to do the same for docs as well?
1511
1512   my @argnames = map {$_->[1]} @$args;
1513   my @argtypes = map { normalize_type( $_->[0], 1 ) } @$args;
1514   if ($opt_k) {
1515     s/^\s*const\b\s*// for @argtypes;
1516   }
1517   my @argarrays = map { $_->[4] || '' } @$args;
1518   my $numargs = @$args;
1519   if ($numargs and $argtypes[-1] eq '...') {
1520     $numargs--;
1521     $argnames[-1] = '...';
1522   }
1523   local $" = ', ';
1524   $type = normalize_type($type, 1);
1525
1526   print $fh <<"EOP";
1527
1528 $type
1529 $name(@argnames)
1530 EOP
1531
1532   for my $arg (0 .. $numargs - 1) {
1533     print $fh <<"EOP";
1534         $argtypes[$arg] $argnames[$arg]$argarrays[$arg]
1535 EOP
1536   }
1537 }
1538
1539 sub print_tievar_subs {
1540   my($fh, $name, $type) = @_;
1541   print $fh <<END;
1542 I32
1543 _get_$name(IV index, SV *sv) {
1544     dSP;
1545     PUSHMARK(SP);
1546     XPUSHs(sv);
1547     PUTBACK;
1548     (void)call_pv("$module\::_get_$name", G_DISCARD);
1549     return (I32)0;
1550 }
1551
1552 I32
1553 _set_$name(IV index, SV *sv) {
1554     dSP;
1555     PUSHMARK(SP);
1556     XPUSHs(sv);
1557     PUTBACK;
1558     (void)call_pv("$module\::_set_$name", G_DISCARD);
1559     return (I32)0;
1560 }
1561
1562 END
1563 }
1564
1565 sub print_tievar_xsubs {
1566   my($fh, $name, $type) = @_;
1567   print $fh <<END;
1568 void
1569 _tievar_$name(sv)
1570         SV* sv
1571     PREINIT:
1572         struct ufuncs uf;
1573     CODE:
1574         uf.uf_val = &_get_$name;
1575         uf.uf_set = &_set_$name;
1576         uf.uf_index = (IV)&_get_$name;
1577         sv_magic(sv, 0, 'U', (char*)&uf, sizeof(uf));
1578
1579 void
1580 _get_$name(THIS)
1581         $type THIS = NO_INIT
1582     CODE:
1583         THIS = $name;
1584     OUTPUT:
1585         SETMAGIC: DISABLE
1586         THIS
1587
1588 void
1589 _set_$name(THIS)
1590         $type THIS
1591     CODE:
1592         $name = THIS;
1593
1594 END
1595 }
1596
1597 sub print_accessors {
1598   my($fh, $name, $struct) = @_;
1599   return unless defined $struct && $name !~ /\s|_ANON/;
1600   $name = normalize_type($name);
1601   my $ptrname = normalize_type("$name *");
1602   print $fh <<"EOF";
1603
1604 MODULE = $module                PACKAGE = ${name}               $prefix
1605
1606 $name *
1607 _to_ptr(THIS)
1608         $name THIS = NO_INIT
1609     PROTOTYPE: \$
1610     CODE:
1611         if (sv_derived_from(ST(0), "$name")) {
1612             STRLEN len;
1613             char *s = SvPV((SV*)SvRV(ST(0)), len);
1614             if (len != sizeof(THIS))
1615                 croak("Size \%d of packed data != expected \%d",
1616                         len, sizeof(THIS));
1617             RETVAL = ($name *)s;
1618         }
1619         else
1620             croak("THIS is not of type $name");
1621     OUTPUT:
1622         RETVAL
1623
1624 $name
1625 new(CLASS)
1626         char *CLASS = NO_INIT
1627     PROTOTYPE: \$
1628     CODE:
1629         Zero((void*)&RETVAL, sizeof(RETVAL), char);
1630     OUTPUT:
1631         RETVAL
1632
1633 MODULE = $module                PACKAGE = ${name}Ptr            $prefix
1634
1635 EOF
1636   my @items = @$struct;
1637   while (@items) {
1638     my $item = shift @items;
1639     if ($item->[0] =~ /_ANON/) {
1640       if (defined $item->[2]) {
1641         push @items, map [
1642           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1643         ], @{ $structs{$item->[0]} };
1644       } else {
1645         push @items, @{ $structs{$item->[0]} };
1646       }
1647     } else {
1648       my $type = normalize_type($item->[0]);
1649       my $ttype = $structs{$type} ? normalize_type("$type *") : $type;
1650       print $fh <<"EOF";
1651 $ttype
1652 $item->[2](THIS, __value = NO_INIT)
1653         $ptrname THIS
1654         $type __value
1655     PROTOTYPE: \$;\$
1656     CODE:
1657         if (items > 1)
1658             THIS->$item->[-1] = __value;
1659         RETVAL = @{[
1660             $type eq $ttype ? "THIS->$item->[-1]" : "&(THIS->$item->[-1])"
1661         ]};
1662     OUTPUT:
1663         RETVAL
1664
1665 EOF
1666     }
1667   }
1668 }
1669
1670 sub accessor_docs {
1671   my($name, $struct) = @_;
1672   return unless defined $struct && $name !~ /\s|_ANON/;
1673   $name = normalize_type($name);
1674   my $ptrname = $name . 'Ptr';
1675   my @items = @$struct;
1676   my @list;
1677   while (@items) {
1678     my $item = shift @items;
1679     if ($item->[0] =~ /_ANON/) {
1680       if (defined $item->[2]) {
1681         push @items, map [
1682           @$_[0, 1], "$item->[2]_$_->[2]", "$item->[2].$_->[2]",
1683         ], @{ $structs{$item->[0]} };
1684       } else {
1685         push @items, @{ $structs{$item->[0]} };
1686       }
1687     } else {
1688       push @list, $item->[2];
1689     }
1690   }
1691   my $methods = (join '(...)>, C<', @list) . '(...)';
1692
1693   my $pod = <<"EOF";
1694 #
1695 #=head2 Object and class methods for C<$name>/C<$ptrname>
1696 #
1697 #The principal Perl representation of a C object of type C<$name> is an
1698 #object of class C<$ptrname> which is a reference to an integer
1699 #representation of a C pointer.  To create such an object, one may use
1700 #a combination
1701 #
1702 #  my \$buffer = $name->new();
1703 #  my \$obj = \$buffer->_to_ptr();
1704 #
1705 #This exersizes the following two methods, and an additional class
1706 #C<$name>, the internal representation of which is a reference to a
1707 #packed string with the C structure.  Keep in mind that \$buffer should
1708 #better survive longer than \$obj.
1709 #
1710 #=over
1711 #
1712 #=item C<\$object_of_type_$name-E<gt>_to_ptr()>
1713 #
1714 #Converts an object of type C<$name> to an object of type C<$ptrname>.
1715 #
1716 #=item C<$name-E<gt>new()>
1717 #
1718 #Creates an empty object of type C<$name>.  The corresponding packed
1719 #string is zeroed out.
1720 #
1721 #=item C<$methods>
1722 #
1723 #return the current value of the corresponding element if called
1724 #without additional arguments.  Set the element to the supplied value
1725 #(and return the new value) if called with an additional argument.
1726 #
1727 #Applicable to objects of type C<$ptrname>.
1728 #
1729 #=back
1730 #
1731 EOF
1732   $pod =~ s/^\#//gm;
1733   return $pod;
1734 }
1735
1736 # Should be called before any actual call to normalize_type().
1737 sub get_typemap {
1738   # We do not want to read ./typemap by obvios reasons.
1739   my @tm =  qw(../../../typemap ../../typemap ../typemap);
1740   my $stdtypemap =  "$Config::Config{privlib}/ExtUtils/typemap";
1741   unshift @tm, $stdtypemap;
1742   my $proto_re = "[" . quotemeta('\$%&*@;') . "]" ;
1743
1744   # Start with useful default values
1745   $typemap{float} = 'T_NV';
1746
1747   foreach my $typemap (@tm) {
1748     next unless -e $typemap ;
1749     # skip directories, binary files etc.
1750     warn " Scanning $typemap\n";
1751     warn("Warning: ignoring non-text typemap file '$typemap'\n"), next
1752       unless -T $typemap ;
1753     open(TYPEMAP, $typemap)
1754       or warn ("Warning: could not open typemap file '$typemap': $!\n"), next;
1755     my $mode = 'Typemap';
1756     while (<TYPEMAP>) {
1757       next if /^\s*\#/;
1758       if (/^INPUT\s*$/)   { $mode = 'Input'; next; }
1759       elsif (/^OUTPUT\s*$/)  { $mode = 'Output'; next; }
1760       elsif (/^TYPEMAP\s*$/) { $mode = 'Typemap'; next; }
1761       elsif ($mode eq 'Typemap') {
1762         next if /^\s*($|\#)/ ;
1763         my ($type, $image);
1764         if ( ($type, $image) =
1765              /^\s*(.*?\S)\s+(\S+)\s*($proto_re*)\s*$/o
1766              # This may reference undefined functions:
1767              and not ($image eq 'T_PACKED' and $typemap eq $stdtypemap)) {
1768           $typemap{normalize_type($type)} = $image;
1769         }
1770       }
1771     }
1772     close(TYPEMAP) or die "Cannot close $typemap: $!";
1773   }
1774   %std_types = %types_seen;
1775   %types_seen = ();
1776 }
1777
1778
1779 sub normalize_type {            # Second arg: do not strip const's before \*
1780   my $type = shift;
1781   my $do_keep_deep_const = shift;
1782   # If $do_keep_deep_const this is heuristical only
1783   my $keep_deep_const = ($do_keep_deep_const ? '\b(?![^(,)]*\*)' : '');
1784   my $ignore_mods
1785     = "(?:\\b(?:(?:__const__|const)$keep_deep_const|static|inline|__inline__)\\b\\s*)*";
1786   if ($do_keep_deep_const) {    # Keep different compiled /RExen/o separately!
1787     $type =~ s/$ignore_mods//go;
1788   }
1789   else {
1790     $type =~ s/$ignore_mods//go;
1791   }
1792   $type =~ s/([^\s\w])/ $1 /g;
1793   $type =~ s/\s+$//;
1794   $type =~ s/^\s+//;
1795   $type =~ s/\s+/ /g;
1796   $type =~ s/\* (?=\*)/*/g;
1797   $type =~ s/\. \. \./.../g;
1798   $type =~ s/ ,/,/g;
1799   $types_seen{$type}++
1800     unless $type eq '...' or $type eq 'void' or $std_types{$type};
1801   $type;
1802 }
1803
1804 my $need_opaque;
1805
1806 sub assign_typemap_entry {
1807   my $type = shift;
1808   my $otype = $type;
1809   my $entry;
1810   if ($tmask and $type =~ /$tmask/) {
1811     print "Type $type matches -o mask\n" if $opt_d;
1812     $entry = (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1813   }
1814   elsif ($typedef_rex and $type =~ s/($typedef_rex)/$typedefs_pre{$1}/go) {
1815     $type = normalize_type $type;
1816     print "Type mutation via typedefs: $otype ==> $type\n" if $opt_d;
1817     $entry = assign_typemap_entry($type);
1818   }
1819   # XXX good do better if our UV happens to be long long
1820   return "T_NV" if $type =~ /^(unsigned\s+)?long\s+(long|double)\z/;
1821   $entry ||= $typemap{$otype}
1822     || (td_is_struct($type) ? "T_OPAQUE_STRUCT" : "T_PTROBJ");
1823   $typemap{$otype} = $entry;
1824   $need_opaque = 1 if $entry eq "T_OPAQUE_STRUCT";
1825   return $entry;
1826 }
1827
1828 for (@vdecls) {
1829   print_tievar_xsubs(\*XS, $_, $vdecl_hash{$_});
1830 }
1831
1832 if ($opt_x) {
1833   for my $decl (@$fdecls_parsed) { print_decl(\*XS, $decl) }
1834   if ($opt_a) {
1835     while (my($name, $struct) = each %structs) {
1836       print_accessors(\*XS, $name, $struct);
1837     }
1838   }
1839 }
1840
1841 close XS;
1842
1843 if (%types_seen) {
1844   my $type;
1845   warn "Writing $ext$modpname/typemap\n";
1846   open TM, ">typemap" or die "Cannot open typemap file for write: $!";
1847
1848   for $type (sort keys %types_seen) {
1849     my $entry = assign_typemap_entry $type;
1850     print TM $type, "\t" x (5 - int((length $type)/8)), "\t$entry\n"
1851   }
1852
1853   print TM <<'EOP' if $need_opaque; # Older Perls do not have correct entry
1854 #############################################################################
1855 INPUT
1856 T_OPAQUE_STRUCT
1857         if (sv_derived_from($arg, \"${ntype}\")) {
1858             STRLEN len;
1859             char  *s = SvPV((SV*)SvRV($arg), len);
1860
1861             if (len != sizeof($var))
1862                 croak(\"Size %d of packed data != expected %d\",
1863                         len, sizeof($var));
1864             $var = *($type *)s;
1865         }
1866         else
1867             croak(\"$var is not of type ${ntype}\")
1868 #############################################################################
1869 OUTPUT
1870 T_OPAQUE_STRUCT
1871         sv_setref_pvn($arg, \"${ntype}\", (char *)&$var, sizeof($var));
1872 EOP
1873
1874   close TM or die "Cannot close typemap file for write: $!";
1875 }
1876
1877 } # if( ! $opt_X )
1878
1879 warn "Writing $ext$modpname/Makefile.PL\n";
1880 open(PL, ">Makefile.PL") || die "Can't create $ext$modpname/Makefile.PL: $!\n";
1881
1882 my $prereq_pm;
1883
1884 if ( $compat_version < 5.00702 and $new_test )
1885 {
1886   $prereq_pm = q%'Test::More'  =>  0%;
1887 }
1888 else
1889 {
1890   $prereq_pm = '';
1891 }
1892
1893 print PL <<"END";
1894 use $compat_version;
1895 use ExtUtils::MakeMaker;
1896 # See lib/ExtUtils/MakeMaker.pm for details of how to influence
1897 # the contents of the Makefile that is written.
1898 WriteMakefile(
1899     NAME              => '$module',
1900     VERSION_FROM      => '$modfname.pm', # finds \$VERSION
1901     PREREQ_PM         => {$prereq_pm}, # e.g., Module::Name => 1.1
1902     (\$] >= 5.005 ?     ## Add these new keywords supported since 5.005
1903       (ABSTRACT_FROM  => '$modfname.pm', # retrieve abstract from module
1904        AUTHOR         => '$author <$email>') : ()),
1905 END
1906 if (!$opt_X) { # print C stuff, unless XS is disabled
1907   $opt_F = '' unless defined $opt_F;
1908   my $I = (((glob '*.h') || (glob '*.hh')) ? '-I.' : '');
1909   my $Ihelp = ($I ? '-I. ' : '');
1910   my $Icomment = ($I ? '' : <<EOC);
1911         # Insert -I. if you add *.h files later:
1912 EOC
1913
1914   print PL <<END;
1915     LIBS              => ['$extralibs'], # e.g., '-lm'
1916     DEFINE            => '$opt_F', # e.g., '-DHAVE_SOMETHING'
1917 $Icomment    INC               => '$I', # e.g., '${Ihelp}-I/usr/include/other'
1918 END
1919
1920   my $C = grep {$_ ne "$modfname.c"}
1921     (glob '*.c'), (glob '*.cc'), (glob '*.C');
1922   my $Cpre = ($C ? '' : '# ');
1923   my $Ccomment = ($C ? '' : <<EOC);
1924         # Un-comment this if you add C files to link with later:
1925 EOC
1926
1927   print PL <<END;
1928 $Ccomment    ${Cpre}OBJECT            => '\$(O_FILES)', # link all the C files too
1929 END
1930 } # ' # Grr
1931 print PL ");\n";
1932 if (!$opt_c) {
1933   my $generate_code =
1934     WriteMakefileSnippet ( C_FILE =>       $constscfname,
1935                            XS_FILE =>      $constsxsfname,
1936                            DEFAULT_TYPE => $opt_t,
1937                            NAME =>         $module,
1938                            NAMES =>        \@const_names,
1939                  );
1940   print PL <<"END";
1941 if  (eval {require ExtUtils::Constant; 1}) {
1942   # If you edit these definitions to change the constants used by this module,
1943   # you will need to use the generated $constscfname and $constsxsfname
1944   # files to replace their "fallback" counterparts before distributing your
1945   # changes.
1946 $generate_code
1947 }
1948 else {
1949   use File::Copy;
1950   use File::Spec;
1951   foreach my \$file ('$constscfname', '$constsxsfname') {
1952     my \$fallback = File::Spec->catfile('$fallbackdirname', \$file);
1953     copy (\$fallback, \$file) or die "Can't copy \$fallback to \$file: \$!";
1954   }
1955 }
1956 END
1957
1958   eval $generate_code;
1959   if ($@) {
1960     warn <<"EOM";
1961 Attempting to test constant code in $ext$modpname/Makefile.PL:
1962 $generate_code
1963 __END__
1964 gave unexpected error $@
1965 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1966 using the perlbug script.
1967 EOM
1968   } else {
1969     my $fail;
1970
1971     foreach my $file ($constscfname, $constsxsfname) {
1972       my $fallback = File::Spec->catfile($fallbackdirname, $file);
1973       if (compare($file, $fallback)) {
1974         warn << "EOM";
1975 Files "$ext$modpname/$fallbackdirname/$file" and "$ext$modpname/$file" differ.
1976 EOM
1977         $fail++;
1978       }
1979     }
1980     if ($fail) {
1981       warn fill ('','', <<"EOM") . "\n";
1982 It appears that the code in $ext$modpname/Makefile.PL does not autogenerate
1983 the files $ext$modpname/$constscfname and $ext$modpname/$constsxsfname
1984 correctly.
1985
1986 Please report the circumstances of this bug in h2xs version $H2XS_VERSION
1987 using the perlbug script.
1988 EOM
1989     } else {
1990       unlink $constscfname, $constsxsfname;
1991     }
1992   }
1993 }
1994 close(PL) || die "Can't close $ext$modpname/Makefile.PL: $!\n";
1995
1996 # Create a simple README since this is a CPAN requirement
1997 # and it doesnt hurt to have one
1998 warn "Writing $ext$modpname/README\n";
1999 open(RM, ">README") || die "Can't create $ext$modpname/README:$!\n";
2000 my $thisyear = (gmtime)[5] + 1900;
2001 my $rmhead = "$modpname version $TEMPLATE_VERSION";
2002 my $rmheadeq = "=" x length($rmhead);
2003
2004 my $rm_prereq;
2005
2006 if ( $compat_version < 5.00702 and $new_test )
2007 {
2008    $rm_prereq = 'Test::More';
2009 }
2010 else
2011 {
2012    $rm_prereq = 'blah blah blah';
2013 }
2014
2015 print RM <<_RMEND_;
2016 $rmhead
2017 $rmheadeq
2018
2019 The README is used to introduce the module and provide instructions on
2020 how to install the module, any machine dependencies it may have (for
2021 example C compilers and installed libraries) and any other information
2022 that should be provided before the module is installed.
2023
2024 A README file is required for CPAN modules since CPAN extracts the
2025 README file from a module distribution so that people browsing the
2026 archive can use it get an idea of the modules uses. It is usually a
2027 good idea to provide version information here so that people can
2028 decide whether fixes for the module are worth downloading.
2029
2030 INSTALLATION
2031
2032 To install this module type the following:
2033
2034    perl Makefile.PL
2035    make
2036    make test
2037    make install
2038
2039 DEPENDENCIES
2040
2041 This module requires these other modules and libraries:
2042
2043   $rm_prereq
2044
2045 COPYRIGHT AND LICENCE
2046
2047 Put the correct copyright and licence information here.
2048
2049 Copyright (C) $thisyear $author
2050
2051 This library is free software; you can redistribute it and/or modify
2052 it under the same terms as Perl itself.
2053
2054 _RMEND_
2055 close(RM) || die "Can't close $ext$modpname/README: $!\n";
2056
2057 my $testdir  = "t";
2058 my $testfile = "$testdir/1.t";
2059 unless (-d "$testdir") {
2060   mkdir "$testdir" or die "Cannot mkdir $testdir: $!\n";
2061 }
2062 warn "Writing $ext$modpname/$testfile\n";
2063 my $tests = @const_names ? 2 : 1;
2064
2065 open EX, ">$testfile" or die "Can't create $ext$modpname/$testfile: $!\n";
2066
2067 print EX <<_END_;
2068 # Before `make install' is performed this script should be runnable with
2069 # `make test'. After `make install' it should work as `perl 1.t'
2070
2071 #########################
2072
2073 # change 'tests => $tests' to 'tests => last_test_to_print';
2074
2075 _END_
2076
2077 my $test_mod = 'Test::More';
2078
2079 if ( $old_test or ($compat_version < 5.007 and not $new_test ))
2080 {
2081   my $test_mod = 'Test';
2082
2083   print EX <<_END_;
2084 use Test;
2085 BEGIN { plan tests => $tests };
2086 use $module;
2087 ok(1); # If we made it this far, we're ok.
2088
2089 _END_
2090
2091    if (@const_names) {
2092      my $const_names = join " ", @const_names;
2093      print EX <<'_END_';
2094
2095 my $fail;
2096 foreach my $constname (qw(
2097 _END_
2098
2099      print EX wrap ("\t", "\t", $const_names);
2100      print EX (")) {\n");
2101
2102      print EX <<_END_;
2103   next if (eval "my \\\$a = \$constname; 1");
2104   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2105     print "# pass: \$\@";
2106   } else {
2107     print "# fail: \$\@";
2108     \$fail = 1;
2109   }
2110 }
2111 if (\$fail) {
2112   print "not ok 2\\n";
2113 } else {
2114   print "ok 2\\n";
2115 }
2116
2117 _END_
2118   }
2119 }
2120 else
2121 {
2122   print EX <<_END_;
2123 use Test::More tests => $tests;
2124 BEGIN { use_ok('$module') };
2125
2126 _END_
2127
2128    if (@const_names) {
2129      my $const_names = join " ", @const_names;
2130      print EX <<'_END_';
2131
2132 my $fail = 0;
2133 foreach my $constname (qw(
2134 _END_
2135
2136      print EX wrap ("\t", "\t", $const_names);
2137      print EX (")) {\n");
2138
2139      print EX <<_END_;
2140   next if (eval "my \\\$a = \$constname; 1");
2141   if (\$\@ =~ /^Your vendor has not defined $module macro \$constname/) {
2142     print "# pass: \$\@";
2143   } else {
2144     print "# fail: \$\@";
2145     \$fail = 1;
2146   }
2147
2148 }
2149
2150 ok( \$fail == 0 , 'Constants' );
2151 _END_
2152   }
2153 }
2154
2155 print EX <<_END_;
2156 #########################
2157
2158 # Insert your test code below, the $test_mod module is use()ed here so read
2159 # its man page ( perldoc $test_mod ) for help writing this test script.
2160
2161 _END_
2162
2163 close(EX) || die "Can't close $ext$modpname/$testfile: $!\n";
2164
2165 unless ($opt_C) {
2166   warn "Writing $ext$modpname/Changes\n";
2167   $" = ' ';
2168   open(EX, ">Changes") || die "Can't create $ext$modpname/Changes: $!\n";
2169   @ARGS = map {/[\s\"\'\`\$*?^|&<>\[\]\{\}\(\)]/ ? "'$_'" : $_} @ARGS;
2170   print EX <<EOP;
2171 Revision history for Perl extension $module.
2172
2173 $TEMPLATE_VERSION  @{[scalar localtime]}
2174 \t- original version; created by h2xs $H2XS_VERSION with options
2175 \t\t@ARGS
2176
2177 EOP
2178   close(EX) || die "Can't close $ext$modpname/Changes: $!\n";
2179 }
2180
2181 warn "Writing $ext$modpname/MANIFEST\n";
2182 open(MANI,'>MANIFEST') or die "Can't create MANIFEST: $!";
2183 my @files = grep { -f } (<*>, <t/*>, <$fallbackdirname/*>);
2184 if (!@files) {
2185   eval {opendir(D,'.');};
2186   unless ($@) { @files = readdir(D); closedir(D); }
2187 }
2188 if (!@files) { @files = map {chomp && $_} `ls`; }
2189 if ($^O eq 'VMS') {
2190   foreach (@files) {
2191     # Clip trailing '.' for portability -- non-VMS OSs don't expect it
2192     s%\.$%%;
2193     # Fix up for case-sensitive file systems
2194     s/$modfname/$modfname/i && next;
2195     $_ = "\U$_" if $_ eq 'manifest' or $_ eq 'changes';
2196     $_ = 'Makefile.PL' if $_ eq 'makefile.pl';
2197   }
2198 }
2199 print MANI join("\n",@files), "\n";
2200 close MANI;
2201 !NO!SUBS!
2202
2203 close OUT or die "Can't close $file: $!";
2204 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
2205 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
2206 chdir $origdir;