This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
618db5f0eb4495ca289ff6a6631d0b8b15eabced
[perl5.git] / t / TEST
1 #!./perl
2
3 # This is written in a peculiar style, since we're trying to avoid
4 # most of the constructs we'll be testing for.  (This comment is
5 # probably obsolete on the avoidance side, though still current
6 # on the peculiarity side.)
7
8 # t/TEST and t/harness need to share code. The logical way to do this would be
9 # to have the common code in a file both require or use. However, t/TEST needs
10 # to still work, to generate test results, even if require isn't working, so
11 # we cannot do that. t/harness has no such restriction, so it is quite
12 # acceptable to have it require t/TEST.
13
14 # In which case, we need to stop t/TEST actually running tests, as all
15 # t/harness needs are its subroutines.
16
17
18 # directories with special sets of test switches
19 my %dir_to_switch =
20     (base => '',
21      comp => '',
22      run => '',
23      '../ext/File-Glob/t' => '-I.. -MTestInit', # FIXME - tests assume t/
24      );
25
26 # "not absolute" is the default, as it saves some fakery within TestInit
27 # which can perturb tests, and takes CPU. Working with the upstream author of
28 # any of these, to figure out how to remove them from this list, considered
29 # "a good thing".
30 my %abs = (
31            '../cpan/Archive-Tar' => 1,
32            '../cpan/AutoLoader' => 1,
33            '../cpan/CPAN' => 1,
34            '../cpan/Class-ISA' => 1,
35            '../cpan/Devel-PPPort' => 1,
36            '../cpan/Encode' => 1,
37            '../cpan/ExtUtils-Constant' => 1,
38            '../cpan/ExtUtils-MakeMaker' => 1,
39            '../cpan/File-Fetch' => 1,
40            '../cpan/IPC-Cmd' => 1,
41            '../cpan/IPC-SysV' => 1,
42            '../cpan/Locale-Codes' => 1,
43            '../cpan/Module-Build' => 1,
44            '../cpan/Module-Load' => 1,
45            '../cpan/Module-Load-Conditional' => 1,
46            '../cpan/Package-Constants' => 1,
47            '../cpan/Parse-CPAN-Meta' => 1,
48            '../cpan/Pod-Simple' => 1,
49            '../cpan/Test-Simple' => 1,
50            '../cpan/podlators' => 1,
51            '../dist/Cwd' => 1,
52            '../dist/ExtUtils-Command' => 1,
53            '../dist/ExtUtils-Install' => 1,
54            '../dist/ExtUtils-Manifest' => 1,
55            '../dist/ExtUtils-ParseXS' => 1,
56            '../dist/Tie-File' => 1,
57           );
58
59 my %temp_no_core =
60     ('../cpan/B-Debug' => 1,
61      '../cpan/Compress-Raw-Bzip2' => 1,
62      '../cpan/Compress-Raw-Zlib' => 1,
63      '../cpan/Devel-PPPort' => 1,
64      '../cpan/Getopt-Long' => 1,
65      '../cpan/IO-Compress' => 1,
66      '../cpan/MIME-Base64' => 1,
67      '../cpan/parent' => 1,
68      '../cpan/Parse-CPAN-Meta' => 1,
69      '../cpan/Pod-Simple' => 1,
70      '../cpan/podlators' => 1,
71      '../cpan/Test-Simple' => 1,
72      '../cpan/Tie-RefHash' => 1,
73      '../cpan/Unicode-Collate' => 1,
74      '../cpan/Unicode-Normalize' => 1,
75     );
76
77 # delete env vars that may influence the results
78 # but allow override via *_TEST env var if wanted
79 # (e.g. PERL5OPT_TEST=-d:NYTProf)
80 my @bad_env_vars = qw(
81     PERL5LIB PERLLIB PERL5OPT
82     PERL_YAML_BACKEND PERL_JSON_BACKEND
83 );
84
85 for my $envname (@bad_env_vars) {
86     my $override = $ENV{"${envname}_TEST"};
87     if (defined $override) {
88         warn "$0: $envname=$override\n";
89         $ENV{$envname} = $override;
90     }
91     else {
92         delete $ENV{$envname};
93     }
94 }
95
96 if ($::do_nothing) {
97     return 1;
98 }
99
100 # Location to put the Valgrind log.
101 our $Valgrind_Log;
102
103 $| = 1;
104
105 # for testing TEST only
106 #BEGIN { require '../lib/strict.pm'; "strict"->import() };
107 #BEGIN { require '../lib/warnings.pm'; "warnings"->import() };
108
109 # remove empty elements due to insertion of empty symbols via "''p1'" syntax
110 @ARGV = grep($_,@ARGV) if $^O eq 'VMS';
111 our $show_elapsed_time = $ENV{HARNESS_TIMER} || 0;
112
113 # Cheesy version of Getopt::Std.  We can't replace it with that, because we
114 # can't rely on require working.
115 {
116     my @argv = ();
117     foreach my $idx (0..$#ARGV) {
118         push( @argv, $ARGV[$idx] ), next unless $ARGV[$idx] =~ /^-(\S+)$/;
119         $::benchmark = 1 if $1 eq 'benchmark';
120         $::core    = 1 if $1 eq 'core';
121         $::verbose = 1 if $1 eq 'v';
122         $::torture = 1 if $1 eq 'torture';
123         $::with_utf8 = 1 if $1 eq 'utf8';
124         $::with_utf16 = 1 if $1 eq 'utf16';
125         $::taintwarn = 1 if $1 eq 'taintwarn';
126         if ($1 =~ /^deparse(,.+)?$/) {
127             $::deparse = 1;
128             $::deparse_opts = $1;
129         }
130     }
131     @ARGV = @argv;
132 }
133
134 chdir 't' if -f 't/TEST';
135 if (-f 'TEST' && -f 'harness' && -d '../lib') {
136     @INC = '../lib';
137 }
138
139 die "You need to run \"make test\" first to set things up.\n"
140   unless -e 'perl' or -e 'perl.exe' or -e 'perl.pm';
141
142 if ($ENV{PERL_3LOG}) { # Tru64 third(1) tool, see perlhack
143     unless (-x 'perl.third') {
144         unless (-x '../perl.third') {
145             die "You need to run \"make perl.third first.\n";
146         }
147         else {
148             print "Symlinking ../perl.third as perl.third...\n";
149             die "Failed to symlink: $!\n"
150                 unless symlink("../perl.third", "perl.third");
151             die "Symlinked but no executable perl.third: $!\n"
152                 unless -x 'perl.third';
153         }
154     }
155 }
156
157 # check leakage for embedders
158 $ENV{PERL_DESTRUCT_LEVEL} = 2 unless exists $ENV{PERL_DESTRUCT_LEVEL};
159 # check existence of all symbols
160 $ENV{PERL_DL_NONLAZY} = 1 unless exists $ENV{PERL_DL_NONLAZY};
161
162 $ENV{EMXSHELL} = 'sh';        # For OS/2
163
164 if ($show_elapsed_time) { require Time::HiRes }
165 my %timings = (); # testname => [@et] pairs if $show_elapsed_time.
166
167 my %skip = (
168             '.' => 1,
169             '..' => 1,
170             'CVS' => 1,
171             'RCS' => 1,
172             'SCCS' => 1,
173             '.svn' => 1,
174            );
175
176 # Roll your own File::Find!
177 sub _find_tests { our @found=(); push @ARGV, _find_files('\.t$', $_[0]) }
178 sub _find_files {
179     my($patt, @dirs) = @_;
180     for my $dir (@dirs) {
181         opendir DIR, $dir or die "Trouble opening $dir: $!";
182         foreach my $f (sort { $a cmp $b } readdir DIR) {
183             next if $skip{$f};
184
185             my $fullpath = "$dir/$f";
186             
187             if (-d $fullpath) {
188                 _find_files($patt, $fullpath);
189             } elsif ($f =~ /$patt/) {
190                 push @found, $fullpath;
191             }
192         }
193     }
194     @found;
195 }
196
197
198 # Scan the text of the test program to find switches and special options
199 # we might need to apply.
200 sub _scan_test {
201     my($test, $type) = @_;
202
203     open(my $script, "<", $test) or die "Can't read $test.\n";
204     my $first_line = <$script>;
205
206     $first_line =~ tr/\0//d if $::with_utf16;
207
208     my $switch = "";
209     if ($first_line =~ /#!.*\bperl.*\s-\w*([tT])/) {
210         $switch = "-$1";
211     } else {
212         if ($::taintwarn) {
213             # not all tests are expected to pass with this option
214             $switch = '-t';
215         } else {
216             $switch = '';
217         }
218     }
219
220     my $file_opts = "";
221     if ($type eq 'deparse') {
222         # Look for #line directives which change the filename
223         while (<$script>) {
224             $file_opts = $file_opts . ",-f$3$4"
225               if /^#\s*line\s+(\d+)\s+((\w+)|"([^"]+)")/;
226         }
227     }
228
229     close $script;
230
231     my $perl = './perl';
232     my $lib  = '../lib';
233     my $run_dir;
234     my $return_dir;
235
236     $test =~ /^(.+)\/[^\/]+/;
237     my $dir = $1;
238     my $testswitch = $dir_to_switch{$dir};
239     if (!defined $testswitch) {
240         if ($test =~ s!^(\.\./(cpan|dist|ext)/[^/]+)/t!t!) {
241             $run_dir = $1;
242             $return_dir = '../../t';
243             $lib = '../../lib';
244             $perl = '../../t/perl';
245             $testswitch = "-I../.. -MTestInit=U2T";
246             if ($2 eq 'cpan' || $2 eq 'dist') {
247                 if($abs{$run_dir}) {
248                     $testswitch = $testswitch . ',A';
249                 }
250                 if ($temp_no_core{$run_dir}) {
251                     $testswitch = $testswitch . ',NC';
252                 }
253             }
254         } elsif ($test =~ m!^\.\./lib!) {
255             $testswitch = '-I.. -MTestInit=U1'; # -T will remove . from @INC
256         } else {
257             $testswitch = '-I.. -MTestInit';  # -T will remove . from @INC
258         }
259     }
260
261     my $utf8 = ($::with_utf8 || $::with_utf16) ? "-I$lib -Mutf8" : '';
262
263     my %options = (
264         perl => $perl,
265         lib => $lib,
266         test => $test,
267         run_dir => $run_dir,
268         return_dir => $return_dir,
269         testswitch => $testswitch,
270         utf8 => $utf8,
271         file => $file_opts,
272         switch => $switch,
273     );
274
275     return \%options;
276 }
277
278 sub _cmd {
279     my($options, $type) = @_;
280
281     my $test = $options->{test};
282
283     my $cmd;
284     if ($type eq 'deparse') {
285         my $perl = "$options->{perl} $options->{testswitch}";
286         my $lib = $options->{lib};
287
288         $cmd = (
289           "$perl $options->{switch} -I$lib -MO=-qq,Deparse,-sv1.,".
290           "-l$::deparse_opts$options->{file} ".
291           "$test > $test.dp ".
292           "&& $perl $options->{switch} -I$lib $test.dp"
293         );
294     }
295     elsif ($type eq 'perl') {
296         my $perl = $options->{perl};
297         my $redir = $^O eq 'VMS' ? '2>&1' : '';
298
299         if ($ENV{PERL_VALGRIND}) {
300             my $perl_supp = $options->{return_dir} ? "$options->{return_dir}/perl.supp" : "perl.supp";
301             my $valgrind_exe = $ENV{VALGRIND} // 'valgrind';
302             my $vg_opts = $ENV{VG_OPTS}
303               // '--log-fd=3 '
304                   . "--suppressions=$perl_supp --leak-check=yes "
305                   . "--leak-resolution=high --show-reachable=yes "
306                   . "--num-callers=50 --track-origins=yes";
307             $perl = "$valgrind_exe $vg_opts $perl";
308             $redir = "3>$Valgrind_Log";
309             if ($options->{run_dir}) {
310                 $Valgrind_Log = "$options->{run_dir}/$Valgrind_Log";
311             }
312         }
313
314         my $args = "$options->{testswitch} $options->{switch} $options->{utf8}";
315         $cmd = $perl . _quote_args($args) . " $test $redir";
316     }
317     return $cmd;
318 }
319
320 sub _before_fork {
321     my ($options) = @_;
322
323     if ($options->{run_dir}) {
324         my $run_dir = $options->{run_dir};
325         chdir $run_dir or die "Can't chdir to '$run_dir': $!";
326     }
327
328     return;
329 }
330
331 sub _after_fork {
332     my ($options) = @_;
333
334     if ($options->{return_dir}) {
335         my $return_dir = $options->{return_dir};
336         chdir $return_dir
337            or die "Can't chdir from '$options->{run_dir}' to '$return_dir': $!";
338     }
339
340     return;
341 }
342
343 sub _run_test {
344     my ($test, $type) = @_;
345
346     my $options = _scan_test($test, $type);
347     # $test might have changed if we're in ext/Foo, so don't use it anymore
348     # from now on. Use $options->{test} instead.
349
350     _before_fork($options);
351
352     my $cmd = _cmd($options, $type);
353
354     open(my $results, "$cmd |") or print "can't run '$cmd': $!.\n";
355
356     _after_fork($options);
357
358     # Our environment may force us to use UTF-8, but we can't be sure that
359     # anything we're reading from will be generating (well formed) UTF-8
360     # This may not be the best way - possibly we should unset ${^OPEN} up
361     # top?
362     binmode $results;
363
364     return $results;
365 }
366
367 sub _quote_args {
368     my ($args) = @_;
369     my $argstring = '';
370
371     foreach (split(/\s+/,$args)) {
372        # In VMS protect with doublequotes because otherwise
373        # DCL will lowercase -- unless already doublequoted.
374        $_ = q(").$_.q(") if ($^O eq 'VMS') && !/^\"/ && length($_) > 0;
375        $argstring = $argstring . ' ' . $_;
376     }
377     return $argstring;
378 }
379
380 sub _populate_hash {
381     return unless defined $_[0];
382     return map {$_, 1} split /\s+/, $_[0];
383 }
384
385 sub _tests_from_manifest {
386     my ($extensions, $known_extensions) = @_;
387     my %skip;
388     my %extensions = _populate_hash($extensions);
389     my %known_extensions = _populate_hash($known_extensions);
390
391     foreach (keys %known_extensions) {
392         $skip{$_} = 1 unless $extensions{$_};
393     }
394
395     my @results;
396     my $mani = '../MANIFEST';
397     if (open(MANI, $mani)) {
398         while (<MANI>) {
399             if (m!^((?:cpan|dist|ext)/(\S+)/+(?:[^/\s]+\.t|test\.pl)|lib/\S+?(?:\.t|test\.pl))\s!) {
400                 my $t = $1;
401                 my $extension = $2;
402                 if (!$::core || $t =~ m!^lib/[a-z]!) {
403                     if (defined $extension) {
404                         $extension =~ s!/t(:?/\S+)*$!!;
405                         # XXX Do I want to warn that I'm skipping these?
406                         next if $skip{$extension};
407                         my $flat_extension = $extension;
408                         $flat_extension =~ s!-!/!g;
409                         next if $skip{$flat_extension}; # Foo/Bar may live in Foo-Bar
410                     }
411                     my $path = "../$t";
412                     push @results, $path;
413                     $::path_to_name{$path} = $t;
414                 }
415             }
416         }
417         close MANI;
418     } else {
419         warn "$0: cannot open $mani: $!\n";
420     }
421     return @results;
422 }
423
424 unless (@ARGV) {
425     # base first, as TEST bails out if that can't run
426     # then comp, to validate that require works
427     # then run, to validate that -M works
428     # then we know we can -MTestInit for everything else, making life simpler
429     foreach my $dir (qw(base comp run cmd io re opbasic op uni mro)) {
430         _find_tests($dir);
431     }
432     unless ($::core) {
433         _find_tests('porting');
434         _find_tests("lib"); 
435     }
436     # Config.pm may be broken for make minitest. And this is only a refinement
437     # for skipping tests on non-default builds, so it is allowed to fail.
438     # What we want to to is make a list of extensions which we did not build.
439     my $configsh = '../config.sh';
440     my ($extensions, $known_extensions);
441     if (-f $configsh) {
442         open FH, $configsh or die "Can't open $configsh: $!";
443         while (<FH>) {
444             if (/^extensions=['"](.*)['"]$/) {
445                 $extensions = $1;
446             }
447             elsif (/^known_extensions=['"](.*)['"]$/) {
448                 $known_extensions = $1;
449             }
450         }
451         if (!defined $known_extensions) {
452             warn "No known_extensions line found in $configsh";
453         }
454         if (!defined $extensions) {
455             warn "No extensions line found in $configsh";
456         }
457     }
458     # The "complex" constructions of list return from a subroutine, and push of
459     # a list, might fail if perl is really hosed, but they aren't needed for
460     # make minitest, and the building of extensions will likely also fail if
461     # something is that badly wrong.
462     push @ARGV, _tests_from_manifest($extensions, $known_extensions);
463     unless ($::core) {
464         _find_tests('x2p');
465         _find_tests('japh') if $::torture;
466         _find_tests('t/benchmark') if $::benchmark or $ENV{PERL_BENCHMARK};
467         _find_tests('bigmem') if $ENV{PERL_TEST_MEMORY};
468     }
469 }
470
471 if ($::deparse) {
472     _testprogs('deparse', '',   @ARGV);
473 }
474 elsif ($::with_utf16) {
475     for my $e (0, 1) {
476         for my $b (0, 1) {
477             print STDERR "# ENDIAN $e BOM $b\n";
478             my @UARGV;
479             for my $a (@ARGV) {
480                 my $u = $a . "." . ($e ? "l" : "b") . "e" . ($b ? "b" : "");
481                 my $f = $e ? "v" : "n";
482                 push @UARGV, $u;
483                 unlink($u);
484                 if (open(A, $a)) {
485                     if (open(U, ">$u")) {
486                         print U pack("$f", 0xFEFF) if $b;
487                         while (<A>) {
488                             print U pack("$f*", unpack("C*", $_));
489                         }
490                         close(U);
491                     }
492                     close(A);
493                 }
494             }
495             _testprogs('perl', '', @UARGV);
496             unlink(@UARGV);
497         }
498     }
499 }
500 else {
501     _testprogs('perl',    '',   @ARGV);
502 }
503
504 sub _testprogs {
505     my ($type, $args, @tests) = @_;
506
507     print <<'EOT' if ($type eq 'deparse');
508 ------------------------------------------------------------------------------
509 TESTING DEPARSER
510 ------------------------------------------------------------------------------
511 EOT
512
513     $::bad_files = 0;
514
515     foreach my $t (@tests) {
516       unless (exists $::path_to_name{$t}) {
517         my $tname = "t/$t";
518         $::path_to_name{$t} = $tname;
519       }
520     }
521     my $maxlen = 0;
522     foreach (@::path_to_name{@tests}) {
523         s/\.\w+\z/ /; # space gives easy doubleclick to select fname
524         my $len = length ;
525         $maxlen = $len if $len > $maxlen;
526     }
527     # + 3 : we want three dots between the test name and the "ok"
528     my $dotdotdot = $maxlen + 3 ;
529     my $grind_ct = 0;           # count of non-empty valgrind reports
530     my $total_files = @tests;
531     my $good_files = 0;
532     my $tested_files  = 0;
533     my $totmax = 0;
534     my %failed_tests;
535     my $toolnm;         # valgrind, cachegrind, perf
536
537     while (my $test = shift @tests) {
538         my ($test_start_time, @starttimes) = 0;
539         if ($show_elapsed_time) {
540             $test_start_time = Time::HiRes::time();
541             # times() reports usage by TEST, but we want usage of each
542             # testprog it calls, so record accumulated times now,
543             # subtract them out afterwards.  Ideally, we'd take times
544             # in BEGIN/END blocks (giving better visibility of self vs
545             # children of each testprog), but that would require some
546             # IPC to send results back here, or a completely different
547             # collection scheme (Storable isn't tuned for incremental use)
548             @starttimes = times;
549         }
550         if ($test =~ /^$/) {
551             next;
552         }
553         if ($type eq 'deparse') {
554             if ($test eq "comp/redef.t") {
555                 # Redefinition happens at compile time
556                 next;
557             }
558             elsif ($test =~ m{lib/Switch/t/}) {
559                 # B::Deparse doesn't support source filtering
560                 next;
561             }
562         }
563         my $te = $::path_to_name{$test} . '.'
564                     x ($dotdotdot - length($::path_to_name{$test})) .' ';
565
566         if ($^O ne 'VMS') {  # defer printing on VMS due to piping bug
567             print $te;
568             $te = '';
569         }
570
571         (local $Valgrind_Log = "$test.valgrind-current") =~ s/^.*\///;
572         my $results = _run_test($test, $type);
573
574         my $failure;
575         my $next = 0;
576         my $seen_leader = 0;
577         my $seen_ok = 0;
578         my $trailing_leader = 0;
579         my $max;
580         my %todo;
581         while (<$results>) {
582             next if /^\s*$/; # skip blank lines
583             if (/^1..$/ && ($^O eq 'VMS')) {
584                 # VMS pipe bug inserts blank lines.
585                 my $l2 = <$results>;
586                 if ($l2 =~ /^\s*$/) {
587                     $l2 = <$results>;
588                 }
589                 $_ = '1..' . $l2;
590             }
591             if ($::verbose) {
592                 print $_;
593             }
594             unless (/^\#/) {
595                 if ($trailing_leader) {
596                     # shouldn't be anything following a postfix 1..n
597                     $failure = 'FAILED--extra output after trailing 1..n';
598                     last;
599                 }
600                 if (/^1\.\.([0-9]+)( todo ([\d ]+))?/) {
601                     if ($seen_leader) {
602                         $failure = 'FAILED--seen duplicate leader';
603                         last;
604                     }
605                     $max = $1;
606                     %todo = map { $_ => 1 } split / /, $3 if $3;
607                     $totmax = $totmax + $max;
608                     $tested_files = $tested_files + 1;
609                     if ($seen_ok) {
610                         # 1..n appears at end of file
611                         $trailing_leader = 1;
612                         if ($next != $max) {
613                             $failure = "FAILED--expected $max tests, saw $next";
614                             last;
615                         }
616                     }
617                     else {
618                         $next = 0;
619                     }
620                     $seen_leader = 1;
621                 }
622                 else {
623                     if (/^(not )?ok(?: (\d+))?[^\#]*(\s*\#.*)?/) {
624                         unless ($seen_leader) {
625                             unless ($seen_ok) {
626                                 $next = 0;
627                             }
628                         }
629                         $seen_ok = 1;
630                         $next = $next + 1;
631                         my($not, $num, $extra, $istodo) = ($1, $2, $3, 0);
632                         $num = $next unless $num;
633
634                         if ($num == $next) {
635
636                             # SKIP is essentially the same as TODO for t/TEST
637                             # this still conforms to TAP:
638                             # http://testanything.org/wiki/index.php/TAP_specification
639                             $extra and $istodo = $extra =~ /#\s*(?:TODO|SKIP)\b/;
640                             $istodo = 1 if $todo{$num};
641
642                             if( $not && !$istodo ) {
643                                 $failure = "FAILED at test $num";
644                                 last;
645                             }
646                         }
647                         else {
648                             $failure ="FAILED--expected test $next, saw test $num";
649                             last;
650                         }
651                     }
652                     elsif (/^Bail out!\s*(.*)/i) { # magic words
653                         die "FAILED--Further testing stopped" . ($1 ? ": $1\n" : ".\n");
654                     }
655                     else {
656                         # module tests are allowed extra output,
657                         # because Test::Harness allows it
658                         next if $test =~ /^\W*(cpan|dist|ext|lib)\b/;
659                         $failure = "FAILED--unexpected output at test $next";
660                         last;
661                     }
662                 }
663             }
664         }
665         close $results;
666
667         if (not defined $failure) {
668             $failure = 'FAILED--no leader found' unless $seen_leader;
669         }
670
671         if ($ENV{PERL_VALGRIND}) {
672             $toolnm = $ENV{VALGRIND};
673             $toolnm =~ s|.*/||;  # keep basename
674             my @valgrind;       # gets content of file
675             if (-e $Valgrind_Log) {
676                 if (open(V, $Valgrind_Log)) {
677                     @valgrind = <V>;
678                     close V;
679                 } else {
680                     warn "$0: Failed to open '$Valgrind_Log': $!\n";
681                 }
682             }
683             if ($ENV{VG_OPTS} =~ /(cachegrind)/ or $toolnm =~ /(perf)/) {
684                 $toolnm = $1;
685                 if ($toolnm eq 'perf') {
686                     # append perfs subcommand, not just stat
687                     my ($sub) = split /\s/, $ENV{VG_OPTS};
688                     $toolnm .= "-$sub";
689                 }
690                 if (rename $Valgrind_Log, "$test.$toolnm") {
691                     $grind_ct++;
692                 } else {
693                     warn "$0: Failed to create '$test.$toolnm': $!\n";
694                 }
695             }
696             elsif (@valgrind) {
697                 my $leaks = 0;
698                 my $errors = 0;
699                 for my $i (0..$#valgrind) {
700                     local $_ = $valgrind[$i];
701                     if (/^==\d+== ERROR SUMMARY: (\d+) errors? /) {
702                         $errors = $errors + $1;   # there may be multiple error summaries
703                     } elsif (/^==\d+== LEAK SUMMARY:/) {
704                         for my $off (1 .. 4) {
705                             if ($valgrind[$i+$off] =~
706                                 /(?:lost|reachable):\s+\d+ bytes in (\d+) blocks/) {
707                                 $leaks = $leaks + $1;
708                             }
709                         }
710                     }
711                 }
712                 if ($errors or $leaks) {
713                     if (rename $Valgrind_Log, "$test.valgrind") {
714                         $grind_ct = $grind_ct + 1;
715                     } else {
716                         warn "$0: Failed to create '$test.valgrind': $!\n";
717                     }
718                 }
719             } else {
720                 warn "No valgrind output?\n";
721             }
722             if (-e $Valgrind_Log) {
723                 unlink $Valgrind_Log
724                     or warn "$0: Failed to unlink '$Valgrind_Log': $!\n";
725             }
726         }
727         if ($type eq 'deparse') {
728             unlink "./$test.dp";
729         }
730         if ($ENV{PERL_3LOG}) {
731             my $tpp = $test;
732             $tpp =~ s:^\.\./::;
733             $tpp =~ s:/:_:g;
734             $tpp =~ s:\.t$:.3log:;
735             rename("perl.3log", $tpp) ||
736                 die "rename: perl3.log to $tpp: $!\n";
737         }
738         if (not defined $failure and $next != $max) {
739             $failure="FAILED--expected $max tests, saw $next";
740         }
741
742         if( !defined $failure  # don't mask a test failure
743             and $? )
744         {
745             $failure = "FAILED--non-zero wait status: $?";
746         }
747
748         if (defined $failure) {
749             print "${te}$failure\n";
750             $::bad_files = $::bad_files + 1;
751             if ($test =~ /^base/) {
752                 die "Failed a basic test ($test) -- cannot continue.\n";
753             }
754             $failed_tests{$test} = 1;
755         }
756         else {
757             if ($max) {
758                 my ($elapsed, $etms) = ("", 0);
759                 if ( $show_elapsed_time ) {
760                     $etms = (Time::HiRes::time() - $test_start_time) * 1000;
761                     $elapsed = sprintf(" %8.0f ms", $etms);
762
763                     my (@endtimes) = times;
764                     $endtimes[$_] -= $starttimes[$_] for 0..$#endtimes;
765                     splice @endtimes, 0, 2;    # drop self/harness times
766                     $_ *= 1000 for @endtimes;  # and scale to ms
767                     $timings{$test} = [$etms,@endtimes];
768                     $elapsed .= sprintf(" %5.0f ms", $_) for @endtimes;
769                 }
770                 print "${te}ok$elapsed\n";
771                 $good_files = $good_files + 1;
772             }
773             else {
774                 print "${te}skipped\n";
775                 $tested_files = $tested_files - 1;
776             }
777         }
778     } # while tests
779
780     if ($::bad_files == 0) {
781         if ($good_files) {
782             print "All tests successful.\n";
783             # XXX add mention of 'perlbug -ok' ?
784         }
785         else {
786             die "FAILED--no tests were run for some reason.\n";
787         }
788     }
789     else {
790         my $pct = $tested_files ? sprintf("%.2f", ($tested_files - $::bad_files) / $tested_files * 100) : "0.00";
791         my $s = $::bad_files == 1 ? "" : "s";
792         warn "Failed $::bad_files test$s out of $tested_files, $pct% okay.\n";
793         for my $test ( sort keys %failed_tests ) {
794             print "\t$test\n";
795         }
796         warn <<'SHRDLU_1';
797 ### Since not all tests were successful, you may want to run some of
798 ### them individually and examine any diagnostic messages they produce.
799 ### See the INSTALL document's section on "make test".
800 SHRDLU_1
801         warn <<'SHRDLU_2' if $good_files / $total_files > 0.8;
802 ### You have a good chance to get more information by running
803 ###   ./perl harness
804 ### in the 't' directory since most (>=80%) of the tests succeeded.
805 SHRDLU_2
806         if (eval {require Config; import Config; 1}) {
807             if ($::Config{usedl} && (my $p = $::Config{ldlibpthname})) {
808                 warn <<SHRDLU_3;
809 ### You may have to set your dynamic library search path,
810 ### $p, to point to the build directory:
811 SHRDLU_3
812                 if (exists $ENV{$p} && $ENV{$p} ne '') {
813                     warn <<SHRDLU_4a;
814 ###   setenv $p `pwd`:\$$p; cd t; ./perl harness
815 ###   $p=`pwd`:\$$p; export $p; cd t; ./perl harness
816 ###   export $p=`pwd`:\$$p; cd t; ./perl harness
817 SHRDLU_4a
818                 } else {
819                     warn <<SHRDLU_4b;
820 ###   setenv $p `pwd`; cd t; ./perl harness
821 ###   $p=`pwd`; export $p; cd t; ./perl harness
822 ###   export $p=`pwd`; cd t; ./perl harness
823 SHRDLU_4b
824                 }
825                 warn <<SHRDLU_5;
826 ### for csh-style shells, like tcsh; or for traditional/modern
827 ### Bourne-style shells, like bash, ksh, and zsh, respectively.
828 SHRDLU_5
829             }
830         }
831     }
832     my ($user,$sys,$cuser,$csys) = times;
833     my $tot = sprintf("u=%.2f  s=%.2f  cu=%.2f  cs=%.2f  scripts=%d  tests=%d",
834                       $user,$sys,$cuser,$csys,$tested_files,$totmax);
835     print "$tot\n";
836     if ($good_files) {
837         if (-d $show_elapsed_time) {
838             # HARNESS_TIMER = <a-directory>.  Save timings etc to
839             # storable file there.  NB: the test cds to ./t/, so
840             # relative path must account for that, ie ../../perf
841             # points to dir next to source tree.
842             require Storable;
843             my @dt = localtime;
844             $dt[5] += 1900; $dt[4] += 1; # fix year, month
845             my $fn = "$show_elapsed_time/".join('-', @dt[5,4,3,2,1]).".ttimes";
846             Storable::store({ perf => \%timings,
847                               gather_conf_platform_info(),
848                               total => $tot,
849                             }, $fn);
850             print "wrote storable file: $fn\n";
851         }
852     }
853     if ($ENV{PERL_VALGRIND}) {
854         my $s = $grind_ct == 1 ? '' : 's';
855         print "$grind_ct valgrind report$s created.\n", ;
856         if ($toolnm eq 'cachegrind') {
857             # cachegrind leaves a lot of cachegrind.out.$pid litter
858             # around the tree, find and delete them
859             unlink _find_files('cachegrind.out.\d+$',
860                              qw ( ../t ../cpan ../ext ../dist/ ));
861         }
862     }
863 }
864 exit ($::bad_files != 0);
865
866 # Collect platform, config data that should allow comparing
867 # performance data between different machines.  With enough data,
868 # and/or clever statistical analysis, it should be possible to
869 # determine the effect of config choices, more memory, etc
870
871 sub gather_conf_platform_info {
872     # currently rather quick & dirty, and subject to change
873     # for both content and format.
874     require Config;
875     my (%conf, @platform) = ();
876     $conf{$_} = $Config::Config{$_} for
877         grep /cc|git|config_arg\d+/, keys %Config::Config;
878     if (-f '/proc/cpuinfo') {
879         open my $fh, '/proc/cpuinfo' or warn "$!: /proc/cpuinfo\n";
880         @platform = grep /name|cpu/, <$fh>;
881         chomp $_ for @platform;
882     }
883     unshift @platform, $^O;
884
885     return (
886         conf => \%conf,
887         platform => {cpu => \@platform,
888                      mem => [ grep s/\s+/ /,
889                               grep chomp, `free` ],
890                      load => [ grep chomp, `uptime` ],
891         },
892         host => (grep chomp, `hostname -f`),
893         version => '0.03', # bump for conf, platform, or data collection changes
894         );
895 }
896
897 # ex: set ts=8 sts=4 sw=4 noet: