This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
611e34adef1e5e2efe618c61ed14b9b5594aec3a
[perl5.git] / Porting / bisect.pl
1 #!/usr/bin/perl -w
2 use strict;
3
4 my $start_time = time;
5
6 # The default, auto_abbrev will treat -e as an abbreviation of --end
7 # Which isn't what we want.
8 use Getopt::Long qw(:config pass_through no_auto_abbrev);
9
10 sub usage {
11     die "$0: [--start revlike] [--end revlike] [--target=...] [-j4] [--expect-pass=0|1] thing to test";
12 }
13
14 my ($start, $end);
15 unless(GetOptions('start=s' => \$start,
16                   'end=s' => \$end,
17                  )) {
18     usage();
19 }
20
21 # We try these in this order for the start revision if none is specified.
22 my @stable = qw(perl-5.002 perl-5.003 perl-5.004 perl-5.005 perl-5.6.0
23                 perl-5.8.0 v5.10.0 v5.12.0 v5.14.0);
24
25 if ($start) {
26     system "git rev-parse $start >/dev/null" and die;
27 }
28 $end = 'blead' unless defined $end;
29 system "git rev-parse $end >/dev/null" and die;
30
31 my $modified = () = `git ls-files --modified --deleted --others`;
32
33 die "This checkout is not clean - $modified modified or untracked file(s)"
34     if $modified;
35
36 system "git bisect reset" and die;
37
38 my $runner = $0;
39 $runner =~ s/bisect\.pl/bisect-runner.pl/;
40
41 die "Can't find bisect runner $runner" unless -f $runner;
42
43 system $^X, $runner, '--check-args', @ARGV and exit 255;
44
45 # Sanity check the first and last revisions:
46 if (defined $start) {
47     system "git checkout $start" and die;
48     my $ret = system $^X, $runner, @ARGV;
49     die "Runner returned $ret, not 0 for start revision" if $ret;
50 } else {
51     # Try to find the earliest version for which the test works
52     foreach my $try (@stable) {
53         system "git checkout $try" and die;
54         my $ret = system $^X, $runner, @ARGV;
55         if (!$ret) {
56             $start = $try;
57             last;
58         }
59     }
60     die "Can't find a suitable start revision to default to. Tried @stable"
61         unless defined $start;
62 }
63 system "git checkout $end" and die;
64 my $ret = system $^X, $runner, @ARGV;
65 die "Runner returned $ret for end revision" unless $ret;
66
67 system "git bisect start" and die;
68 system "git bisect good $start" and die;
69 system "git bisect bad $end" and die;
70
71 # And now get git bisect to do the hard work:
72 system 'git', 'bisect', 'run', $^X, $runner, @ARGV and die;
73
74 END {
75     my $end_time = time;
76
77     printf "That took %d seconds\n", $end_time - $start_time
78         if defined $start_time;
79 }
80
81 # Local variables:
82 # cperl-indent-level: 4
83 # indent-tabs-mode: nil
84 # End:
85 #
86 # ex: set ts=8 sts=4 sw=4 et: