This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
autoloaded DESTROY bugfix
[perl5.git] / ext / B / B / Deparse.pm
1 # B::Deparse.pm
2 # Copyright (c) 1998, 1999, 2000 Stephen McCamant. All rights reserved.
3 # This module is free software; you can redistribute and/or modify
4 # it under the same terms as Perl itself.
5
6 # This is based on the module of the same name by Malcolm Beattie,
7 # but essentially none of his code remains.
8
9 package B::Deparse;
10 use Carp;
11 use B qw(class main_root main_start main_cv svref_2object opnumber cstring
12          OPf_WANT OPf_WANT_VOID OPf_WANT_SCALAR OPf_WANT_LIST
13          OPf_KIDS OPf_REF OPf_STACKED OPf_SPECIAL OPf_MOD
14          OPpLVAL_INTRO OPpOUR_INTRO OPpENTERSUB_AMPER OPpSLICE OPpCONST_BARE
15          OPpTRANS_SQUASH OPpTRANS_DELETE OPpTRANS_COMPLEMENT OPpTARGET_MY
16          OPpCONST_ARYBASE OPpEXISTS_SUB OPpSORT_NUMERIC OPpSORT_INTEGER
17          OPpSORT_REVERSE
18          SVf_IOK SVf_NOK SVf_ROK SVf_POK SVpad_OUR
19          CVf_METHOD CVf_LOCKED CVf_LVALUE
20          PMf_KEEP PMf_GLOBAL PMf_CONTINUE PMf_EVAL PMf_ONCE PMf_SKIPWHITE
21          PMf_MULTILINE PMf_SINGLELINE PMf_FOLD PMf_EXTENDED);
22 $VERSION = 0.63;
23 use strict;
24 use vars qw/$AUTOLOAD/;
25 use warnings ();
26
27 # Changes between 0.50 and 0.51:
28 # - fixed nulled leave with live enter in sort { }
29 # - fixed reference constants (\"str")
30 # - handle empty programs gracefully
31 # - handle infinte loops (for (;;) {}, while (1) {})
32 # - differentiate between `for my $x ...' and `my $x; for $x ...'
33 # - various minor cleanups
34 # - moved globals into an object
35 # - added `-u', like B::C
36 # - package declarations using cop_stash
37 # - subs, formats and code sorted by cop_seq
38 # Changes between 0.51 and 0.52:
39 # - added pp_threadsv (special variables under USE_5005THREADS)
40 # - added documentation
41 # Changes between 0.52 and 0.53:
42 # - many changes adding precedence contexts and associativity
43 # - added `-p' and `-s' output style options
44 # - various other minor fixes
45 # Changes between 0.53 and 0.54:
46 # - added support for new `for (1..100)' optimization,
47 #   thanks to Gisle Aas
48 # Changes between 0.54 and 0.55:
49 # - added support for new qr// construct
50 # - added support for new pp_regcreset OP
51 # Changes between 0.55 and 0.56:
52 # - tested on base/*.t, cmd/*.t, comp/*.t, io/*.t
53 # - fixed $# on non-lexicals broken in last big rewrite
54 # - added temporary fix for change in opcode of OP_STRINGIFY
55 # - fixed problem in 0.54's for() patch in `for (@ary)'
56 # - fixed precedence in conditional of ?:
57 # - tweaked list paren elimination in `my($x) = @_'
58 # - made continue-block detection trickier wrt. null ops
59 # - fixed various prototype problems in pp_entersub
60 # - added support for sub prototypes that never get GVs
61 # - added unquoting for special filehandle first arg in truncate
62 # - print doubled rv2gv (a bug) as `*{*GV}' instead of illegal `**GV'
63 # - added semicolons at the ends of blocks
64 # - added -l `#line' declaration option -- fixes cmd/subval.t 27,28
65 # Changes between 0.56 and 0.561:
66 # - fixed multiply-declared my var in pp_truncate (thanks to Sarathy)
67 # - used new B.pm symbolic constants (done by Nick Ing-Simmons)
68 # Changes between 0.561 and 0.57:
69 # - stylistic changes to symbolic constant stuff
70 # - handled scope in s///e replacement code
71 # - added unquote option for expanding "" into concats, etc.
72 # - split method and proto parts of pp_entersub into separate functions
73 # - various minor cleanups
74 # Changes after 0.57:
75 # - added parens in \&foo (patch by Albert Dvornik)
76 # Changes between 0.57 and 0.58:
77 # - fixed `0' statements that weren't being printed
78 # - added methods for use from other programs
79 #   (based on patches from James Duncan and Hugo van der Sanden)
80 # - added -si and -sT to control indenting (also based on a patch from Hugo)
81 # - added -sv to print something else instead of '???'
82 # - preliminary version of utf8 tr/// handling
83 # Changes after 0.58:
84 # - uses of $op->ppaddr changed to new $op->name (done by Sarathy)
85 # - added support for Hugo's new OP_SETSTATE (like nextstate) 
86 # Changes between 0.58 and 0.59
87 # - added support for Chip's OP_METHOD_NAMED
88 # - added support for Ilya's OPpTARGET_MY optimization
89 # - elided arrows before `()' subscripts when possible
90 # Changes between 0.59 and 0.60
91 # - support for method attribues was added
92 # - some warnings fixed
93 # - separate recognition of constant subs
94 # - rewrote continue block handling, now recoginizing for loops
95 # - added more control of expanding control structures
96 # Changes between 0.60 and 0.61 (mostly by Robin Houston)
97 # - many bug-fixes
98 # - support for pragmas and 'use'
99 # - support for the little-used $[ variable
100 # - support for __DATA__ sections
101 # - UTF8 support
102 # - BEGIN, CHECK, INIT and END blocks
103 # - scoping of subroutine declarations fixed
104 # - compile-time output from the input program can be suppressed, so that the
105 #   output is just the deparsed code. (a change to O.pm in fact)
106 # - our() declarations
107 # - *all* the known bugs are now listed in the BUGS section
108 # - comprehensive test mechanism (TEST -deparse)
109 # Changes between 0.62 and 0.63 (mostly by Rafael Garcia-Suarez)
110 # - bug-fixes
111 # - new switch -P
112 # - support for command-line switches (-l, -0, etc.)
113
114 # Todo:
115 #  (See also BUGS section at the end of this file)
116 #
117 # - finish tr/// changes
118 # - add option for even more parens (generalize \&foo change)
119 # - left/right context
120 # - treat top-level block specially for incremental output
121 # - copy comments (look at real text with $^P?)
122 # - avoid semis in one-statement blocks
123 # - associativity of &&=, ||=, ?:
124 # - ',' => '=>' (auto-unquote?)
125 # - break long lines ("\r" as discretionary break?)
126 # - configurable syntax highlighting: ANSI color, HTML, TeX, etc.
127 # - more style options: brace style, hex vs. octal, quotes, ...
128 # - print big ints as hex/octal instead of decimal (heuristic?)
129 # - handle `my $x if 0'?
130 # - coordinate with Data::Dumper (both directions? see previous)
131 # - version using op_next instead of op_first/sibling?
132 # - avoid string copies (pass arrays, one big join?)
133 # - here-docs?
134
135 # Tests that will always fail:
136 # (see t/TEST for the short list)
137
138 # Object fields (were globals):
139 #
140 # avoid_local:
141 # (local($a), local($b)) and local($a, $b) have the same internal
142 # representation but the short form looks better. We notice we can
143 # use a large-scale local when checking the list, but need to prevent
144 # individual locals too. This hash holds the addresses of OPs that 
145 # have already had their local-ness accounted for. The same thing
146 # is done with my().
147 #
148 # curcv:
149 # CV for current sub (or main program) being deparsed
150 #
151 # curcvlex:
152 # Cached hash of lexical variables for curcv: keys are names,
153 # each value is an array of pairs, indicating the cop_seq of scopes
154 # in which a var of that name is valid.
155 #
156 # curcop:
157 # COP for statement being deparsed
158 #
159 # curstash:
160 # name of the current package for deparsed code
161 #
162 # subs_todo:
163 # array of [cop_seq, CV, is_format?] for subs and formats we still
164 # want to deparse
165 #
166 # protos_todo:
167 # as above, but [name, prototype] for subs that never got a GV
168 #
169 # subs_done, forms_done:
170 # keys are addresses of GVs for subs and formats we've already
171 # deparsed (or at least put into subs_todo)
172 #
173 # subs_declared
174 # keys are names of subs for which we've printed declarations.
175 # That means we can omit parentheses from the arguments.
176 #
177 # subs_deparsed
178 # Keeps track of fully qualified names of all deparsed subs.
179 #
180 # parens: -p
181 # linenums: -l
182 # unquote: -q
183 # cuddle: ` ' or `\n', depending on -sC
184 # indent_size: -si
185 # use_tabs: -sT
186 # ex_const: -sv
187
188 # A little explanation of how precedence contexts and associativity
189 # work:
190 #
191 # deparse() calls each per-op subroutine with an argument $cx (short
192 # for context, but not the same as the cx* in the perl core), which is
193 # a number describing the op's parents in terms of precedence, whether
194 # they're inside an expression or at statement level, etc.  (see
195 # chart below). When ops with children call deparse on them, they pass
196 # along their precedence. Fractional values are used to implement
197 # associativity (`($x + $y) + $z' => `$x + $y + $y') and related
198 # parentheses hacks. The major disadvantage of this scheme is that
199 # it doesn't know about right sides and left sides, so say if you
200 # assign a listop to a variable, it can't tell it's allowed to leave
201 # the parens off the listop.
202
203 # Precedences:
204 # 26             [TODO] inside interpolation context ("")
205 # 25 left        terms and list operators (leftward)
206 # 24 left        ->
207 # 23 nonassoc    ++ --
208 # 22 right       **
209 # 21 right       ! ~ \ and unary + and -
210 # 20 left        =~ !~
211 # 19 left        * / % x
212 # 18 left        + - .
213 # 17 left        << >>
214 # 16 nonassoc    named unary operators
215 # 15 nonassoc    < > <= >= lt gt le ge
216 # 14 nonassoc    == != <=> eq ne cmp
217 # 13 left        &
218 # 12 left        | ^
219 # 11 left        &&
220 # 10 left        ||
221 #  9 nonassoc    ..  ...
222 #  8 right       ?:
223 #  7 right       = += -= *= etc.
224 #  6 left        , =>
225 #  5 nonassoc    list operators (rightward)
226 #  4 right       not
227 #  3 left        and
228 #  2 left        or xor
229 #  1             statement modifiers
230 #  0             statement level
231
232 # Also, lineseq may pass a fourth parameter to the pp_ routines:
233 # if present, the fourth parameter is passed on by deparse.
234 #
235 # If present and true, it means that the op exists directly as
236 # part of a lineseq. Currently it's only used by scopeop to
237 # decide whether its results need to be enclosed in a do {} block.
238
239 # Nonprinting characters with special meaning:
240 # \cS - steal parens (see maybe_parens_unop)
241 # \n - newline and indent
242 # \t - increase indent
243 # \b - decrease indent (`outdent')
244 # \f - flush left (no indent)
245 # \cK - kill following semicolon, if any
246
247 sub null {
248     my $op = shift;
249     return class($op) eq "NULL";
250 }
251
252 sub todo {
253     my $self = shift;
254     my($cv, $is_form) = @_;
255     return unless ($cv->FILE eq $0 || exists $self->{files}{$cv->FILE});
256     my $seq;
257     if (!null($cv->START) and is_state($cv->START)) {
258         $seq = $cv->START->cop_seq;
259     } else {
260         $seq = 0;
261     }
262     push @{$self->{'subs_todo'}}, [$seq, $cv, $is_form];
263     unless ($is_form || class($cv->STASH) eq 'SPECIAL') {
264         $self->{'subs_deparsed'}{$cv->STASH->NAME."::".$cv->GV->NAME} = 1;
265     }
266 }
267
268 sub next_todo {
269     my $self = shift;
270     my $ent = shift @{$self->{'subs_todo'}};
271     my $cv = $ent->[1];
272     my $gv = $cv->GV;
273     my $name = $self->gv_name($gv);
274     if ($ent->[2]) {
275         return "format $name =\n"
276             . $self->deparse_format($ent->[1]). "\n";
277     } else {
278         $self->{'subs_declared'}{$name} = 1;
279         if ($name eq "BEGIN") {
280             my $use_dec = $self->begin_is_use($cv);
281             if (defined ($use_dec)) {
282                 return () if 0 == length($use_dec);
283                 return $use_dec;
284             }
285         }
286         my $l = '';
287         if ($self->{'linenums'}) {
288             my $line = $gv->LINE;
289             my $file = $gv->FILE;
290             $l = "\n\f#line $line \"$file\"\n";
291         }
292         return "${l}sub $name " . $self->deparse_sub($cv);
293     }
294 }
295
296 # Return a "use" declaration for this BEGIN block, if appropriate
297 sub begin_is_use {
298     my ($self, $cv) = @_;
299     my $root = $cv->ROOT;
300     local @$self{qw'curcv curcvlex'} = ($cv);
301 #require B::Debug;
302 #B::walkoptree($cv->ROOT, "debug");
303     my $lineseq = $root->first;
304     return if $lineseq->name ne "lineseq";
305
306     my $req_op = $lineseq->first->sibling;
307     return if $req_op->name ne "require";
308
309     my $module;
310     if ($req_op->first->private & OPpCONST_BARE) {
311         # Actually it should always be a bareword
312         $module = $self->const_sv($req_op->first)->PV;
313         $module =~ s[/][::]g;
314         $module =~ s/.pm$//;
315     }
316     else {
317         $module = const($self->const_sv($req_op->first));
318     }
319
320     my $version;
321     my $version_op = $req_op->sibling;
322     return if class($version_op) eq "NULL";
323     if ($version_op->name eq "lineseq") {
324         # We have a version parameter; skip nextstate & pushmark
325         my $constop = $version_op->first->next->next;
326
327         return unless $self->const_sv($constop)->PV eq $module;
328         $constop = $constop->sibling;
329         $version = $self->const_sv($constop)->int_value;
330         $constop = $constop->sibling;
331         return if $constop->name ne "method_named";
332         return if $self->const_sv($constop)->PV ne "VERSION";
333     }
334
335     $lineseq = $version_op->sibling;
336     return if $lineseq->name ne "lineseq";
337     my $entersub = $lineseq->first->sibling;
338     if ($entersub->name eq "stub") {
339         return "use $module $version ();\n" if defined $version;
340         return "use $module ();\n";
341     }
342     return if $entersub->name ne "entersub";
343
344     # See if there are import arguments
345     my $args = '';
346
347     my $svop = $entersub->first->sibling; # Skip over pushmark
348     return unless $self->const_sv($svop)->PV eq $module;
349
350     # Pull out the arguments
351     for ($svop=$svop->sibling; $svop->name ne "method_named";
352                 $svop = $svop->sibling) {
353         $args .= ", " if length($args);
354         $args .= $self->deparse($svop, 6);
355     }
356
357     my $use = 'use';
358     my $method_named = $svop;
359     return if $method_named->name ne "method_named";
360     my $method_name = $self->const_sv($method_named)->PV;
361
362     if ($method_name eq "unimport") {
363         $use = 'no';
364     }
365
366     # Certain pragmas are dealt with using hint bits,
367     # so we ignore them here
368     if ($module eq 'strict' || $module eq 'integer'
369         || $module eq 'bytes' || $module eq 'warnings') {
370         return "";
371     }
372
373     if (defined $version && length $args) {
374         return "$use $module $version ($args);\n";
375     } elsif (defined $version) {
376         return "$use $module $version;\n";
377     } elsif (length $args) {
378         return "$use $module ($args);\n";
379     } else {
380         return "$use $module;\n";
381     }
382 }
383
384 sub stash_subs {
385     my ($self, $pack) = @_;
386     my (@ret, $stash);
387     if (!defined $pack) {
388         $pack = '';
389         $stash = \%::;
390     }
391     else {
392         $pack =~ s/(::)?$/::/;
393         no strict 'refs';
394         $stash = \%$pack;
395     }
396     my %stash = svref_2object($stash)->ARRAY;
397     while (my ($key, $val) = each %stash) {
398         next if $key eq 'main::';       # avoid infinite recursion
399         my $class = class($val);
400         if ($class eq "PV") {
401             # Just a prototype. As an ugly but fairly effective way
402             # to find out if it belongs here is to see if the AUTOLOAD
403             # (if any) for the stash was defined in one of our files.
404             my $A = $stash{"AUTOLOAD"};
405             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
406                 && class($A->CV) eq "CV") {
407                 my $AF = $A->FILE;
408                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
409             }
410             push @{$self->{'protos_todo'}}, [$pack . $key, $val->PV];
411         } elsif ($class eq "IV") {
412             # Just a name. As above.
413             my $A = $stash{"AUTOLOAD"};
414             if (defined ($A) && class($A) eq "GV" && defined($A->CV)
415                 && class($A->CV) eq "CV") {
416                 my $AF = $A->FILE;
417                 next unless $AF eq $0 || exists $self->{'files'}{$AF};
418             }
419             push @{$self->{'protos_todo'}}, [$pack . $key, undef];          
420         } elsif ($class eq "GV") {
421             if (class(my $cv = $val->CV) ne "SPECIAL") {
422                 next if $self->{'subs_done'}{$$val}++;
423                 next if $$val != ${$cv->GV};   # Ignore imposters
424                 $self->todo($cv, 0);
425             }
426             if (class(my $cv = $val->FORM) ne "SPECIAL") {
427                 next if $self->{'forms_done'}{$$val}++;
428                 next if $$val != ${$cv->GV};   # Ignore imposters
429                 $self->todo($cv, 1);
430             }
431             if (class($val->HV) ne "SPECIAL" && $key =~ /::$/) {
432                 $self->stash_subs($pack . $key);
433             }
434         }
435     }
436 }
437
438 sub print_protos {
439     my $self = shift;
440     my $ar;
441     my @ret;
442     foreach $ar (@{$self->{'protos_todo'}}) {
443         my $proto = (defined $ar->[1] ? " (". $ar->[1] . ")" : "");
444         push @ret, "sub " . $ar->[0] .  "$proto;\n";
445     }
446     delete $self->{'protos_todo'};
447     return @ret;
448 }
449
450 sub style_opts {
451     my $self = shift;
452     my $opts = shift;
453     my $opt;
454     while (length($opt = substr($opts, 0, 1))) {
455         if ($opt eq "C") {
456             $self->{'cuddle'} = " ";
457             $opts = substr($opts, 1);
458         } elsif ($opt eq "i") {
459             $opts =~ s/^i(\d+)//;
460             $self->{'indent_size'} = $1;
461         } elsif ($opt eq "T") {
462             $self->{'use_tabs'} = 1;
463             $opts = substr($opts, 1);
464         } elsif ($opt eq "v") {
465             $opts =~ s/^v([^.]*)(.|$)//;
466             $self->{'ex_const'} = $1;
467         }
468     }
469 }
470
471 sub new {
472     my $class = shift;
473     my $self = bless {}, $class;
474     $self->{'subs_todo'} = [];
475     $self->{'files'} = {};
476     $self->{'curstash'} = "main";
477     $self->{'curcop'} = undef;
478     $self->{'cuddle'} = "\n";
479     $self->{'indent_size'} = 4;
480     $self->{'use_tabs'} = 0;
481     $self->{'expand'} = 0;
482     $self->{'unquote'} = 0;
483     $self->{'linenums'} = 0;
484     $self->{'parens'} = 0;
485     $self->{'ex_const'} = "'???'";
486
487     $self->{'ambient_arybase'} = 0;
488     $self->{'ambient_warnings'} = undef; # Assume no lexical warnings
489     $self->{'ambient_hints'} = 0;
490     $self->init();
491
492     while (my $arg = shift @_) {
493         if ($arg =~ /^-f(.*)/) {
494             $self->{'files'}{$1} = 1;
495         } elsif ($arg eq "-p") {
496             $self->{'parens'} = 1;
497         } elsif ($arg eq "-P") {
498             $self->{'noproto'} = 1;
499         } elsif ($arg eq "-l") {
500             $self->{'linenums'} = 1;
501         } elsif ($arg eq "-q") {
502             $self->{'unquote'} = 1;
503         } elsif (substr($arg, 0, 2) eq "-s") {
504             $self->style_opts(substr $arg, 2);
505         } elsif ($arg =~ /^-x(\d)$/) {
506             $self->{'expand'} = $1;
507         }
508     }
509     return $self;
510 }
511
512 {
513     # Mask out the bits that L<warnings::register> uses
514     my $WARN_MASK;
515     BEGIN {
516         $WARN_MASK = $warnings::Bits{all} | $warnings::DeadBits{all};
517     }
518     sub WARN_MASK () {
519         return $WARN_MASK;
520     }
521 }
522
523 # Initialise the contextual information, either from
524 # defaults provided with the ambient_pragmas method,
525 # or from perl's own defaults otherwise.
526 sub init {
527     my $self = shift;
528
529     $self->{'arybase'}  = $self->{'ambient_arybase'};
530     $self->{'warnings'} = defined ($self->{'ambient_warnings'})
531                                 ? $self->{'ambient_warnings'} & WARN_MASK
532                                 : undef;
533     $self->{'hints'}    = $self->{'ambient_hints'} & 0xFF;
534
535     # also a convenient place to clear out subs_declared
536     delete $self->{'subs_declared'};
537 }
538
539 sub compile {
540     my(@args) = @_;
541     return sub { 
542         my $self = B::Deparse->new(@args);
543         # First deparse command-line args
544         if (defined $^I) { # deparse -i
545             print q(BEGIN { $^I = ).cstring($^I).qq(; }\n);
546         }
547         if ($^W) { # deparse -w
548             print qq(BEGIN { \$^W = $^W; }\n);
549         }
550         if ($/ ne "\n" or defined $O::savebackslash) { # deparse -l and -0
551             my $fs = cstring($/) || 'undef';
552             my $bs = cstring($O::savebackslash) || 'undef';
553             print qq(BEGIN { \$/ = $fs; \$\\ = $bs; }\n);
554         }
555         my @BEGINs  = B::begin_av->isa("B::AV") ? B::begin_av->ARRAY : ();
556         my @INITs   = B::init_av->isa("B::AV") ? B::init_av->ARRAY : ();
557         my @ENDs    = B::end_av->isa("B::AV") ? B::end_av->ARRAY : ();
558         for my $block (@BEGINs, @INITs, @ENDs) {
559             $self->todo($block, 0);
560         }
561         $self->stash_subs();
562         $self->{'curcv'} = main_cv;
563         $self->{'curcvlex'} = undef;
564         print $self->print_protos;
565         @{$self->{'subs_todo'}} =
566           sort {$a->[0] <=> $b->[0]} @{$self->{'subs_todo'}};
567         print $self->indent($self->deparse(main_root, 0)), "\n"
568           unless null main_root;
569         my @text;
570         while (scalar(@{$self->{'subs_todo'}})) {
571             push @text, $self->next_todo;
572         }
573         print $self->indent(join("", @text)), "\n" if @text;
574
575         # Print __DATA__ section, if necessary
576         no strict 'refs';
577         my $laststash = defined $self->{'curcop'}
578             ? $self->{'curcop'}->stash->NAME : $self->{'curstash'};
579         if (defined *{$laststash."::DATA"}{IO}) {
580             print "__DATA__\n";
581             print readline(*{$laststash."::DATA"});
582         }
583     }
584 }
585
586 sub coderef2text {
587     my $self = shift;
588     my $sub = shift;
589     croak "Usage: ->coderef2text(CODEREF)" unless ref($sub) eq "CODE";
590
591     $self->init();
592     return $self->indent($self->deparse_sub(svref_2object($sub)));
593 }
594
595 sub ambient_pragmas {
596     my $self = shift;
597     my ($arybase, $hint_bits, $warning_bits) = (0, 0);
598
599     while (@_ > 1) {
600         my $name = shift();
601         my $val  = shift();
602
603         if ($name eq 'strict') {
604             require strict;
605
606             if ($val eq 'none') {
607                 $hint_bits &= ~strict::bits(qw/refs subs vars/);
608                 next();
609             }
610
611             my @names;
612             if ($val eq "all") {
613                 @names = qw/refs subs vars/;
614             }
615             elsif (ref $val) {
616                 @names = @$val;
617             }
618             else {
619                 @names = split' ', $val;
620             }
621             $hint_bits |= strict::bits(@names);
622         }
623
624         elsif ($name eq '$[') {
625             $arybase = $val;
626         }
627
628         elsif ($name eq 'integer'
629             || $name eq 'bytes'
630             || $name eq 'utf8') {
631             require "$name.pm";
632             if ($val) {
633                 $hint_bits |= ${$::{"${name}::"}{"hint_bits"}};
634             }
635             else {
636                 $hint_bits &= ~${$::{"${name}::"}{"hint_bits"}};
637             }
638         }
639
640         elsif ($name eq 're') {
641             require re;
642             if ($val eq 'none') {
643                 $hint_bits &= ~re::bits(qw/taint eval/);
644                 next();
645             }
646
647             my @names;
648             if ($val eq 'all') {
649                 @names = qw/taint eval/;
650             }
651             elsif (ref $val) {
652                 @names = @$val;
653             }
654             else {
655                 @names = split' ',$val;
656             }
657             $hint_bits |= re::bits(@names);
658         }
659
660         elsif ($name eq 'warnings') {
661             if ($val eq 'none') {
662                 $warning_bits = $warnings::NONE;
663                 next();
664             }
665
666             my @names;
667             if (ref $val) {
668                 @names = @$val;
669             }
670             else {
671                 @names = split/\s+/, $val;
672             }
673
674             $warning_bits = $warnings::NONE if !defined ($warning_bits);
675             $warning_bits |= warnings::bits(@names);
676         }
677
678         elsif ($name eq 'warning_bits') {
679             $warning_bits = $val;
680         }
681
682         elsif ($name eq 'hint_bits') {
683             $hint_bits = $val;
684         }
685
686         else {
687             croak "Unknown pragma type: $name";
688         }
689     }
690     if (@_) {
691         croak "The ambient_pragmas method expects an even number of args";
692     }
693
694     $self->{'ambient_arybase'} = $arybase;
695     $self->{'ambient_warnings'} = $warning_bits;
696     $self->{'ambient_hints'} = $hint_bits;
697 }
698
699 sub deparse {
700     my $self = shift;
701     my($op, $cx, $flags) = @_;
702
703     Carp::confess("Null op in deparse") if !defined($op)
704                                         || class($op) eq "NULL";
705     my $meth = "pp_" . $op->name;
706     if (is_scope($op)) {
707         return $self->$meth($op, $cx, $flags);
708     }
709     return $self->$meth($op, $cx);
710 }
711
712 sub indent {
713     my $self = shift;
714     my $txt = shift;
715     my @lines = split(/\n/, $txt);
716     my $leader = "";
717     my $level = 0;
718     my $line;
719     for $line (@lines) {
720         my $cmd = substr($line, 0, 1);
721         if ($cmd eq "\t" or $cmd eq "\b") {
722             $level += ($cmd eq "\t" ? 1 : -1) * $self->{'indent_size'};
723             if ($self->{'use_tabs'}) {
724                 $leader = "\t" x ($level / 8) . " " x ($level % 8);
725             } else {
726                 $leader = " " x $level;
727             }
728             $line = substr($line, 1);
729         }
730         if (substr($line, 0, 1) eq "\f") {
731             $line = substr($line, 1); # no indent
732         } else {
733             $line = $leader . $line;
734         }
735         $line =~ s/\cK;?//g;
736     }
737     return join("\n", @lines);
738 }
739
740 sub deparse_sub {
741     my $self = shift;
742     my $cv = shift;
743     my $proto = "";
744 Carp::confess("NULL in deparse_sub") if !defined($cv) || $cv->isa("B::NULL");
745 Carp::confess("SPECIAL in deparse_sub") if $cv->isa("B::SPECIAL");
746     local $self->{'curcop'} = $self->{'curcop'};
747     if ($cv->FLAGS & SVf_POK) {
748         $proto = "(". $cv->PV . ") ";
749     }
750     if ($cv->CvFLAGS & (CVf_METHOD|CVf_LOCKED|CVf_LVALUE)) {
751         $proto .= ": ";
752         $proto .= "lvalue " if $cv->CvFLAGS & CVf_LVALUE;
753         $proto .= "locked " if $cv->CvFLAGS & CVf_LOCKED;
754         $proto .= "method " if $cv->CvFLAGS & CVf_METHOD;
755     }
756
757     local($self->{'curcv'}) = $cv;
758     local($self->{'curcvlex'});
759     local(@$self{qw'curstash warnings hints'})
760                 = @$self{qw'curstash warnings hints'};
761     my $body;
762     if (not null $cv->ROOT) {
763         my $lineseq = $cv->ROOT->first;
764         if ($lineseq->name eq "lineseq") {
765             my @ops;
766             for(my$o=$lineseq->first; $$o; $o=$o->sibling) {
767                 push @ops, $o;
768             }
769             $body = $self->lineseq(undef, @ops).";";
770             my $scope_en = $self->find_scope_en($lineseq);
771             if (defined $scope_en) {
772                 my $subs = join"", $self->seq_subs($scope_en);
773                 $body .= ";\n$subs" if length($subs);
774             }
775         }
776         else {
777             $body = $self->deparse($cv->ROOT->first, 0);
778         }
779     }
780     else {
781         my $sv = $cv->const_sv;
782         if ($$sv) {
783             # uh-oh. inlinable sub... format it differently
784             return $proto . "{ " . const($sv) . " }\n";
785         } else { # XSUB? (or just a declaration)
786             return "$proto;\n";
787         }
788     }
789     return $proto ."{\n\t$body\n\b}" ."\n";
790 }
791
792 sub deparse_format {
793     my $self = shift;
794     my $form = shift;
795     my @text;
796     local($self->{'curcv'}) = $form;
797     local($self->{'curcvlex'});
798     local($self->{'in_format'}) = 1;
799     local(@$self{qw'curstash warnings hints'})
800                 = @$self{qw'curstash warnings hints'};
801     my $op = $form->ROOT;
802     my $kid;
803     return "\f." if $op->first->name eq 'stub'
804                 || $op->first->name eq 'nextstate';
805     $op = $op->first->first; # skip leavewrite, lineseq
806     while (not null $op) {
807         $op = $op->sibling; # skip nextstate
808         my @exprs;
809         $kid = $op->first->sibling; # skip pushmark
810         push @text, "\f".$self->const_sv($kid)->PV;
811         $kid = $kid->sibling;
812         for (; not null $kid; $kid = $kid->sibling) {
813             push @exprs, $self->deparse($kid, 0);
814         }
815         push @text, "\f".join(", ", @exprs)."\n" if @exprs;
816         $op = $op->sibling;
817     }
818     return join("", @text) . "\f.";
819 }
820
821 sub is_scope {
822     my $op = shift;
823     return $op->name eq "leave" || $op->name eq "scope"
824       || $op->name eq "lineseq"
825         || ($op->name eq "null" && class($op) eq "UNOP" 
826             && (is_scope($op->first) || $op->first->name eq "enter"));
827 }
828
829 sub is_state {
830     my $name = $_[0]->name;
831     return $name eq "nextstate" || $name eq "dbstate" || $name eq "setstate";
832 }
833
834 sub is_miniwhile { # check for one-line loop (`foo() while $y--')
835     my $op = shift;
836     return (!null($op) and null($op->sibling) 
837             and $op->name eq "null" and class($op) eq "UNOP"
838             and (($op->first->name =~ /^(and|or)$/
839                   and $op->first->first->sibling->name eq "lineseq")
840                  or ($op->first->name eq "lineseq"
841                      and not null $op->first->first->sibling
842                      and $op->first->first->sibling->name eq "unstack")
843                  ));
844 }
845
846 sub is_scalar {
847     my $op = shift;
848     return ($op->name eq "rv2sv" or
849             $op->name eq "padsv" or
850             $op->name eq "gv" or # only in array/hash constructs
851             $op->flags & OPf_KIDS && !null($op->first)
852               && $op->first->name eq "gvsv");
853 }
854
855 sub maybe_parens {
856     my $self = shift;
857     my($text, $cx, $prec) = @_;
858     if ($prec < $cx              # unary ops nest just fine
859         or $prec == $cx and $cx != 4 and $cx != 16 and $cx != 21
860         or $self->{'parens'})
861     {
862         $text = "($text)";
863         # In a unop, let parent reuse our parens; see maybe_parens_unop
864         $text = "\cS" . $text if $cx == 16;
865         return $text;
866     } else {
867         return $text;
868     }
869 }
870
871 # same as above, but get around the `if it looks like a function' rule
872 sub maybe_parens_unop {
873     my $self = shift;
874     my($name, $kid, $cx) = @_;
875     if ($cx > 16 or $self->{'parens'}) {
876         $kid =  $self->deparse($kid, 1);
877         if ($name eq "umask" && $kid =~ /^\d+$/) {
878             $kid = sprintf("%#o", $kid);
879         }
880         return "$name($kid)";
881     } else {
882         $kid = $self->deparse($kid, 16);
883         if ($name eq "umask" && $kid =~ /^\d+$/) {
884             $kid = sprintf("%#o", $kid);
885         }
886         if (substr($kid, 0, 1) eq "\cS") {
887             # use kid's parens
888             return $name . substr($kid, 1);
889         } elsif (substr($kid, 0, 1) eq "(") {
890             # avoid looks-like-a-function trap with extra parens
891             # (`+' can lead to ambiguities)
892             return "$name(" . $kid  . ")";
893         } else {
894             return "$name $kid";
895         }
896     }
897 }
898
899 sub maybe_parens_func {
900     my $self = shift;
901     my($func, $text, $cx, $prec) = @_;
902     if ($prec <= $cx or substr($text, 0, 1) eq "(" or $self->{'parens'}) {
903         return "$func($text)";
904     } else {
905         return "$func $text";
906     }
907 }
908
909 sub maybe_local {
910     my $self = shift;
911     my($op, $cx, $text) = @_;
912     my $our_intro = ($op->name =~ /^(gv|rv2)[ash]v$/) ? OPpOUR_INTRO : 0;
913     if ($op->private & (OPpLVAL_INTRO|$our_intro)
914         and not $self->{'avoid_local'}{$$op}) {
915         my $our_local = ($op->private & OPpLVAL_INTRO) ? "local" : "our";
916         if (want_scalar($op)) {
917             return "$our_local $text";
918         } else {
919             return $self->maybe_parens_func("$our_local", $text, $cx, 16);
920         }
921     } else {
922         return $text;
923     }
924 }
925
926 sub maybe_targmy {
927     my $self = shift;
928     my($op, $cx, $func, @args) = @_;
929     if ($op->private & OPpTARGET_MY) {
930         my $var = $self->padname($op->targ);
931         my $val = $func->($self, $op, 7, @args);
932         return $self->maybe_parens("$var = $val", $cx, 7);
933     } else {
934         return $func->($self, $op, $cx, @args);
935     }
936 }
937
938 sub padname_sv {
939     my $self = shift;
940     my $targ = shift;
941     return (($self->{'curcv'}->PADLIST->ARRAY)[0]->ARRAY)[$targ];
942 }
943
944 sub maybe_my {
945     my $self = shift;
946     my($op, $cx, $text) = @_;
947     if ($op->private & OPpLVAL_INTRO and not $self->{'avoid_local'}{$$op}) {
948         if (want_scalar($op)) {
949             return "my $text";
950         } else {
951             return $self->maybe_parens_func("my", $text, $cx, 16);
952         }
953     } else {
954         return $text;
955     }
956 }
957
958 # The following OPs don't have functions:
959
960 # pp_padany -- does not exist after parsing
961
962 sub AUTOLOAD {
963     if ($AUTOLOAD =~ s/^.*::pp_//) {
964         warn "unexpected OP_".uc $AUTOLOAD;
965         return "XXX";
966     } else {
967         die "Undefined subroutine $AUTOLOAD called";
968     }
969 }
970
971 sub DESTROY {}  #       Do not AUTOLOAD
972
973 # $root should be the op which represents the root of whatever
974 # we're sequencing here. If it's undefined, then we don't append
975 # any subroutine declarations to the deparsed ops, otherwise we
976 # append appropriate declarations.
977 sub lineseq {
978     my($self, $root, @ops) = @_;
979     my($expr, @exprs);
980
981     my $out_cop = $self->{'curcop'};
982     my $out_seq = defined($out_cop) ? $out_cop->cop_seq : undef;
983     my $limit_seq;
984     if (defined $root) {
985         $limit_seq = $out_seq;
986         my $nseq = $self->find_scope_st($root->sibling) if ${$root->sibling};
987         $limit_seq = $nseq if !defined($limit_seq)
988                            or defined($nseq) && $nseq < $limit_seq;
989     }
990     $limit_seq = $self->{'limit_seq'}
991         if defined($self->{'limit_seq'})
992         && (!defined($limit_seq) || $self->{'limit_seq'} < $limit_seq);
993     local $self->{'limit_seq'} = $limit_seq;
994     for (my $i = 0; $i < @ops; $i++) {
995         $expr = "";
996         if (is_state $ops[$i]) {
997             $expr = $self->deparse($ops[$i], 0);
998             $i++;
999             if ($i > $#ops) {
1000                 push @exprs, $expr;
1001                 last;
1002             }
1003         }
1004         if (!is_state $ops[$i] and (my $ls = $ops[$i+1]) and
1005             !null($ops[$i+1]) and $ops[$i+1]->name eq "lineseq")
1006         {
1007             if ($ls->first && !null($ls->first) && is_state($ls->first)
1008                 && (my $sib = $ls->first->sibling)) {
1009                 if (!null($sib) && $sib->name eq "leaveloop") {
1010                     push @exprs, $expr . $self->for_loop($ops[$i], 0);
1011                     $i++;
1012                     next;
1013                 }
1014             }
1015         }
1016         $expr .= $self->deparse($ops[$i], 0, (@ops != 1));
1017         $expr =~ s/;\n?\z//;
1018         push @exprs, $expr;
1019     }
1020     my $body = join(";\n", grep {length} @exprs);
1021     my $subs = "";
1022     if (defined $root && defined $limit_seq && !$self->{'in_format'}) {
1023         $subs = join "\n", $self->seq_subs($limit_seq);
1024     }
1025     return join(";\n", grep {length} $body, $subs);
1026 }
1027
1028 sub scopeop {
1029     my($real_block, $self, $op, $cx, $flags) = @_;
1030     my $kid;
1031     my @kids;
1032
1033     local(@$self{qw'curstash warnings hints'})
1034                 = @$self{qw'curstash warnings hints'} if $real_block;
1035     if ($real_block) {
1036         $kid = $op->first->sibling; # skip enter
1037         if (is_miniwhile($kid)) {
1038             my $top = $kid->first;
1039             my $name = $top->name;
1040             if ($name eq "and") {
1041                 $name = "while";
1042             } elsif ($name eq "or") {
1043                 $name = "until";
1044             } else { # no conditional -> while 1 or until 0
1045                 return $self->deparse($top->first, 1) . " while 1";
1046             }
1047             my $cond = $top->first;
1048             my $body = $cond->sibling->first; # skip lineseq
1049             $cond = $self->deparse($cond, 1);
1050             $body = $self->deparse($body, 1);
1051             return "$body $name $cond";
1052         }
1053     } else {
1054         $kid = $op->first;
1055     }
1056     for (; !null($kid); $kid = $kid->sibling) {
1057         push @kids, $kid;
1058     }
1059     if ($flags || $cx > 0) { # inside an expression, (a do {} while for lineseq)
1060         return "do {\n\t" . $self->lineseq($op, @kids) . "\n\b}";
1061     } else {
1062         my $lineseq = $self->lineseq($op, @kids);
1063         return (length ($lineseq) ? "$lineseq;" : "");
1064     }
1065 }
1066
1067 sub pp_scope { scopeop(0, @_); }
1068 sub pp_lineseq { scopeop(0, @_); }
1069 sub pp_leave { scopeop(1, @_); }
1070
1071 # The BEGIN {} is used here because otherwise this code isn't executed
1072 # when you run B::Deparse on itself.
1073 my %globalnames;
1074 BEGIN { map($globalnames{$_}++, "SIG", "STDIN", "STDOUT", "STDERR", "INC",
1075             "ENV", "ARGV", "ARGVOUT", "_"); }
1076
1077 sub gv_name {
1078     my $self = shift;
1079     my $gv = shift;
1080 Carp::confess() if $gv->isa("B::CV");
1081     my $stash = $gv->STASH->NAME;
1082     my $name = $gv->SAFENAME;
1083     if ($stash eq $self->{'curstash'} or $globalnames{$name}
1084         or $name =~ /^[^A-Za-z_]/)
1085     {
1086         $stash = "";
1087     } else {
1088         $stash = $stash . "::";
1089     }
1090     if ($name =~ /^(\^..|{)/) {
1091         $name = "{$name}";       # ${^WARNING_BITS}, etc and ${
1092     }
1093     return $stash . $name;
1094 }
1095
1096 # Return the name to use for a stash variable.
1097 # If a lexical with the same name is in scope, it may need to be
1098 # fully-qualified.
1099 sub stash_variable {
1100     my ($self, $prefix, $name) = @_;
1101
1102     return "$prefix$name" if $name =~ /::/;
1103
1104     unless ($prefix eq '$' || $prefix eq '@' ||
1105             $prefix eq '%' || $prefix eq '$#') {
1106         return "$prefix$name";
1107     }
1108
1109     my $v = ($prefix eq '$#' ? '@' : $prefix) . $name;
1110     return $prefix .$self->{'curstash'}.'::'. $name if $self->lex_in_scope($v);
1111     return "$prefix$name";
1112 }
1113
1114 sub lex_in_scope {
1115     my ($self, $name) = @_;
1116     $self->populate_curcvlex() if !defined $self->{'curcvlex'};
1117
1118     return 0 if !defined($self->{'curcop'});
1119     my $seq = $self->{'curcop'}->cop_seq;
1120     return 0 if !exists $self->{'curcvlex'}{$name};
1121     for my $a (@{$self->{'curcvlex'}{$name}}) {
1122         my ($st, $en) = @$a;
1123         return 1 if $seq > $st && $seq <= $en;
1124     }
1125     return 0;
1126 }
1127
1128 sub populate_curcvlex {
1129     my $self = shift;
1130     for (my $cv = $self->{'curcv'}; class($cv) eq "CV"; $cv = $cv->OUTSIDE) {
1131         my @padlist = $cv->PADLIST->ARRAY;
1132         my @ns = $padlist[0]->ARRAY;
1133
1134         for (my $i=0; $i<@ns; ++$i) {
1135             next if class($ns[$i]) eq "SPECIAL";
1136             next if $ns[$i]->FLAGS & SVpad_OUR;  # Skip "our" vars
1137             if (class($ns[$i]) eq "PV") {
1138                 # Probably that pesky lexical @_
1139                 next;
1140             }
1141             my $name = $ns[$i]->PVX;
1142             my $seq_st = $ns[$i]->NVX;
1143             my $seq_en = int($ns[$i]->IVX);
1144
1145             push @{$self->{'curcvlex'}{$name}}, [$seq_st, $seq_en];
1146         }
1147     }
1148 }
1149
1150 sub find_scope_st { ((find_scope(@_))[0]); }
1151 sub find_scope_en { ((find_scope(@_))[1]); }
1152
1153 # Recurses down the tree, looking for pad variable introductions and COPs
1154 sub find_scope {
1155     my ($self, $op, $scope_st, $scope_en) = @_;
1156     carp("Undefined op in find_scope") if !defined $op;
1157     return ($scope_st, $scope_en) unless $op->flags & OPf_KIDS;
1158
1159     for (my $o=$op->first; $$o; $o=$o->sibling) {
1160         if ($o->name =~ /^pad.v$/ && $o->private & OPpLVAL_INTRO) {
1161             my $s = int($self->padname_sv($o->targ)->NVX);
1162             my $e = $self->padname_sv($o->targ)->IVX;
1163             $scope_st = $s if !defined($scope_st) || $s < $scope_st;
1164             $scope_en = $e if !defined($scope_en) || $e > $scope_en;
1165         }
1166         elsif (is_state($o)) {
1167             my $c = $o->cop_seq;
1168             $scope_st = $c if !defined($scope_st) || $c < $scope_st;
1169             $scope_en = $c if !defined($scope_en) || $c > $scope_en;
1170         }
1171         elsif ($o->flags & OPf_KIDS) {
1172             ($scope_st, $scope_en) =
1173                 $self->find_scope($o, $scope_st, $scope_en)
1174         }
1175     }
1176
1177     return ($scope_st, $scope_en);
1178 }
1179
1180 # Returns a list of subs which should be inserted before the COP
1181 sub cop_subs {
1182     my ($self, $op, $out_seq) = @_;
1183     my $seq = $op->cop_seq;
1184     # If we have nephews, then our sequence number indicates
1185     # the cop_seq of the end of some sort of scope.
1186     if (class($op->sibling) ne "NULL" && $op->sibling->flags & OPf_KIDS
1187         and my $nseq = $self->find_scope_st($op->sibling) ) {
1188         $seq = $nseq;
1189     }
1190     $seq = $out_seq if defined($out_seq) && $out_seq < $seq;
1191     return $self->seq_subs($seq);
1192 }
1193
1194 sub seq_subs {
1195     my ($self, $seq) = @_;
1196     my @text;
1197 #push @text, "# ($seq)\n";
1198
1199     return "" if !defined $seq;
1200     while (scalar(@{$self->{'subs_todo'}})
1201            and $seq > $self->{'subs_todo'}[0][0]) {
1202         push @text, $self->next_todo;
1203     }
1204     return @text;
1205 }
1206
1207 # Notice how subs and formats are inserted between statements here;
1208 # also $[ assignments and pragmas.
1209 sub pp_nextstate {
1210     my $self = shift;
1211     my($op, $cx) = @_;
1212     $self->{'curcop'} = $op;
1213     my @text;
1214     push @text, $self->cop_subs($op);
1215     push @text, $op->label . ": " if $op->label;
1216     my $stash = $op->stashpv;
1217     if ($stash ne $self->{'curstash'}) {
1218         push @text, "package $stash;\n";
1219         $self->{'curstash'} = $stash;
1220     }
1221     if ($self->{'linenums'}) {
1222         push @text, "\f#line " . $op->line . 
1223           ' "' . $op->file, qq'"\n';
1224     }
1225
1226     if ($self->{'arybase'} != $op->arybase) {
1227         push @text, '$[ = '. $op->arybase .";\n";
1228         $self->{'arybase'} = $op->arybase;
1229     }
1230
1231     my $warnings = $op->warnings;
1232     my $warning_bits;
1233     if ($warnings->isa("B::SPECIAL") && $$warnings == 4) {
1234         $warning_bits = $warnings::Bits{"all"} & WARN_MASK;
1235     }
1236     elsif ($warnings->isa("B::SPECIAL") && $$warnings == 5) {
1237         $warning_bits = $warnings::NONE;
1238     }
1239     elsif ($warnings->isa("B::SPECIAL")) {
1240         $warning_bits = undef;
1241     }
1242     else {
1243         $warning_bits = $warnings->PV & WARN_MASK;
1244     }
1245
1246     if (defined ($warning_bits) and
1247        !defined($self->{warnings}) || $self->{'warnings'} ne $warning_bits) {
1248         push @text, declare_warnings($self->{'warnings'}, $warning_bits);
1249         $self->{'warnings'} = $warning_bits;
1250     }
1251
1252     if ($self->{'hints'} != $op->private) {
1253         push @text, declare_hints($self->{'hints'}, $op->private);
1254         $self->{'hints'} = $op->private;
1255     }
1256
1257     return join("", @text);
1258 }
1259
1260 sub declare_warnings {
1261     my ($from, $to) = @_;
1262     if (($to & WARN_MASK) eq warnings::bits("all")) {
1263         return "use warnings;\n";
1264     }
1265     elsif (($to & WARN_MASK) eq "\0"x length($to)) {
1266         return "no warnings;\n";
1267     }
1268     return "BEGIN {\${^WARNING_BITS} = ".cstring($to)."}\n";
1269 }
1270
1271 sub declare_hints {
1272     my ($from, $to) = @_;
1273     my $use = $to   & ~$from;
1274     my $no  = $from & ~$to;
1275     my $decls = "";
1276     for my $pragma (hint_pragmas($use)) {
1277         $decls .= "use $pragma;\n";
1278     }
1279     for my $pragma (hint_pragmas($no)) {
1280         $decls .= "no $pragma;\n";
1281     }
1282     return $decls;
1283 }
1284
1285 sub hint_pragmas {
1286     my ($bits) = @_;
1287     my @pragmas;
1288     push @pragmas, "integer" if $bits & 0x1;
1289     push @pragmas, "strict 'refs'" if $bits & 0x2;
1290     push @pragmas, "bytes" if $bits & 0x8;
1291     return @pragmas;
1292 }
1293
1294 sub pp_dbstate { pp_nextstate(@_) }
1295 sub pp_setstate { pp_nextstate(@_) }
1296
1297 sub pp_unstack { return "" } # see also leaveloop
1298
1299 sub baseop {
1300     my $self = shift;
1301     my($op, $cx, $name) = @_;
1302     return $name;
1303 }
1304
1305 sub pp_stub {
1306     my $self = shift;
1307     my($op, $cx, $name) = @_;
1308     if ($cx) {
1309         return "()";
1310     }
1311     else {
1312         return "();";
1313     }
1314 }
1315 sub pp_wantarray { baseop(@_, "wantarray") }
1316 sub pp_fork { baseop(@_, "fork") }
1317 sub pp_wait { maybe_targmy(@_, \&baseop, "wait") }
1318 sub pp_getppid { maybe_targmy(@_, \&baseop, "getppid") }
1319 sub pp_time { maybe_targmy(@_, \&baseop, "time") }
1320 sub pp_tms { baseop(@_, "times") }
1321 sub pp_ghostent { baseop(@_, "gethostent") }
1322 sub pp_gnetent { baseop(@_, "getnetent") }
1323 sub pp_gprotoent { baseop(@_, "getprotoent") }
1324 sub pp_gservent { baseop(@_, "getservent") }
1325 sub pp_ehostent { baseop(@_, "endhostent") }
1326 sub pp_enetent { baseop(@_, "endnetent") }
1327 sub pp_eprotoent { baseop(@_, "endprotoent") }
1328 sub pp_eservent { baseop(@_, "endservent") }
1329 sub pp_gpwent { baseop(@_, "getpwent") }
1330 sub pp_spwent { baseop(@_, "setpwent") }
1331 sub pp_epwent { baseop(@_, "endpwent") }
1332 sub pp_ggrent { baseop(@_, "getgrent") }
1333 sub pp_sgrent { baseop(@_, "setgrent") }
1334 sub pp_egrent { baseop(@_, "endgrent") }
1335 sub pp_getlogin { baseop(@_, "getlogin") }
1336
1337 sub POSTFIX () { 1 }
1338
1339 # I couldn't think of a good short name, but this is the category of
1340 # symbolic unary operators with interesting precedence
1341
1342 sub pfixop {
1343     my $self = shift;
1344     my($op, $cx, $name, $prec, $flags) = (@_, 0);
1345     my $kid = $op->first;
1346     $kid = $self->deparse($kid, $prec);
1347     return $self->maybe_parens(($flags & POSTFIX) ? "$kid$name" : "$name$kid",
1348                                $cx, $prec);
1349 }
1350
1351 sub pp_preinc { pfixop(@_, "++", 23) }
1352 sub pp_predec { pfixop(@_, "--", 23) }
1353 sub pp_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1354 sub pp_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1355 sub pp_i_preinc { pfixop(@_, "++", 23) }
1356 sub pp_i_predec { pfixop(@_, "--", 23) }
1357 sub pp_i_postinc { maybe_targmy(@_, \&pfixop, "++", 23, POSTFIX) }
1358 sub pp_i_postdec { maybe_targmy(@_, \&pfixop, "--", 23, POSTFIX) }
1359 sub pp_complement { maybe_targmy(@_, \&pfixop, "~", 21) }
1360
1361 sub pp_negate { maybe_targmy(@_, \&real_negate) }
1362 sub real_negate {
1363     my $self = shift;
1364     my($op, $cx) = @_;
1365     if ($op->first->name =~ /^(i_)?negate$/) {
1366         # avoid --$x
1367         $self->pfixop($op, $cx, "-", 21.5);
1368     } else {
1369         $self->pfixop($op, $cx, "-", 21);       
1370     }
1371 }
1372 sub pp_i_negate { pp_negate(@_) }
1373
1374 sub pp_not {
1375     my $self = shift;
1376     my($op, $cx) = @_;
1377     if ($cx <= 4) {
1378         $self->pfixop($op, $cx, "not ", 4);
1379     } else {
1380         $self->pfixop($op, $cx, "!", 21);       
1381     }
1382 }
1383
1384 sub unop {
1385     my $self = shift;
1386     my($op, $cx, $name) = @_;
1387     my $kid;
1388     if ($op->flags & OPf_KIDS) {
1389         $kid = $op->first;
1390         if (defined prototype("CORE::$name") 
1391            && prototype("CORE::$name") =~ /^;?\*/
1392            && $kid->name eq "rv2gv") {
1393             $kid = $kid->first;
1394         }
1395
1396         return $self->maybe_parens_unop($name, $kid, $cx);
1397     } else {
1398         return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");       
1399     }
1400 }
1401
1402 sub pp_chop { maybe_targmy(@_, \&unop, "chop") }
1403 sub pp_chomp { maybe_targmy(@_, \&unop, "chomp") }
1404 sub pp_schop { maybe_targmy(@_, \&unop, "chop") }
1405 sub pp_schomp { maybe_targmy(@_, \&unop, "chomp") }
1406 sub pp_defined { unop(@_, "defined") }
1407 sub pp_undef { unop(@_, "undef") }
1408 sub pp_study { unop(@_, "study") }
1409 sub pp_ref { unop(@_, "ref") }
1410 sub pp_pos { maybe_local(@_, unop(@_, "pos")) }
1411
1412 sub pp_sin { maybe_targmy(@_, \&unop, "sin") }
1413 sub pp_cos { maybe_targmy(@_, \&unop, "cos") }
1414 sub pp_rand { maybe_targmy(@_, \&unop, "rand") }
1415 sub pp_srand { unop(@_, "srand") }
1416 sub pp_exp { maybe_targmy(@_, \&unop, "exp") }
1417 sub pp_log { maybe_targmy(@_, \&unop, "log") }
1418 sub pp_sqrt { maybe_targmy(@_, \&unop, "sqrt") }
1419 sub pp_int { maybe_targmy(@_, \&unop, "int") }
1420 sub pp_hex { maybe_targmy(@_, \&unop, "hex") }
1421 sub pp_oct { maybe_targmy(@_, \&unop, "oct") }
1422 sub pp_abs { maybe_targmy(@_, \&unop, "abs") }
1423
1424 sub pp_length { maybe_targmy(@_, \&unop, "length") }
1425 sub pp_ord { maybe_targmy(@_, \&unop, "ord") }
1426 sub pp_chr { maybe_targmy(@_, \&unop, "chr") }
1427
1428 sub pp_each { unop(@_, "each") }
1429 sub pp_values { unop(@_, "values") }
1430 sub pp_keys { unop(@_, "keys") }
1431 sub pp_pop { unop(@_, "pop") }
1432 sub pp_shift { unop(@_, "shift") }
1433
1434 sub pp_caller { unop(@_, "caller") }
1435 sub pp_reset { unop(@_, "reset") }
1436 sub pp_exit { unop(@_, "exit") }
1437 sub pp_prototype { unop(@_, "prototype") }
1438
1439 sub pp_close { unop(@_, "close") }
1440 sub pp_fileno { unop(@_, "fileno") }
1441 sub pp_umask { unop(@_, "umask") }
1442 sub pp_untie { unop(@_, "untie") }
1443 sub pp_tied { unop(@_, "tied") }
1444 sub pp_dbmclose { unop(@_, "dbmclose") }
1445 sub pp_getc { unop(@_, "getc") }
1446 sub pp_eof { unop(@_, "eof") }
1447 sub pp_tell { unop(@_, "tell") }
1448 sub pp_getsockname { unop(@_, "getsockname") }
1449 sub pp_getpeername { unop(@_, "getpeername") }
1450
1451 sub pp_chdir { maybe_targmy(@_, \&unop, "chdir") }
1452 sub pp_chroot { maybe_targmy(@_, \&unop, "chroot") }
1453 sub pp_readlink { unop(@_, "readlink") }
1454 sub pp_rmdir { maybe_targmy(@_, \&unop, "rmdir") }
1455 sub pp_readdir { unop(@_, "readdir") }
1456 sub pp_telldir { unop(@_, "telldir") }
1457 sub pp_rewinddir { unop(@_, "rewinddir") }
1458 sub pp_closedir { unop(@_, "closedir") }
1459 sub pp_getpgrp { maybe_targmy(@_, \&unop, "getpgrp") }
1460 sub pp_localtime { unop(@_, "localtime") }
1461 sub pp_gmtime { unop(@_, "gmtime") }
1462 sub pp_alarm { unop(@_, "alarm") }
1463 sub pp_sleep { maybe_targmy(@_, \&unop, "sleep") }
1464
1465 sub pp_dofile { unop(@_, "do") }
1466 sub pp_entereval { unop(@_, "eval") }
1467
1468 sub pp_ghbyname { unop(@_, "gethostbyname") }
1469 sub pp_gnbyname { unop(@_, "getnetbyname") }
1470 sub pp_gpbyname { unop(@_, "getprotobyname") }
1471 sub pp_shostent { unop(@_, "sethostent") }
1472 sub pp_snetent { unop(@_, "setnetent") }
1473 sub pp_sprotoent { unop(@_, "setprotoent") }
1474 sub pp_sservent { unop(@_, "setservent") }
1475 sub pp_gpwnam { unop(@_, "getpwnam") }
1476 sub pp_gpwuid { unop(@_, "getpwuid") }
1477 sub pp_ggrnam { unop(@_, "getgrnam") }
1478 sub pp_ggrgid { unop(@_, "getgrgid") }
1479
1480 sub pp_lock { unop(@_, "lock") }
1481
1482 sub pp_exists {
1483     my $self = shift;
1484     my($op, $cx) = @_;
1485     my $arg;
1486     if ($op->private & OPpEXISTS_SUB) {
1487         # Checking for the existence of a subroutine
1488         return $self->maybe_parens_func("exists",
1489                                 $self->pp_rv2cv($op->first, 16), $cx, 16);
1490     }
1491     if ($op->flags & OPf_SPECIAL) {
1492         # Array element, not hash element
1493         return $self->maybe_parens_func("exists",
1494                                 $self->pp_aelem($op->first, 16), $cx, 16);
1495     }
1496     return $self->maybe_parens_func("exists", $self->pp_helem($op->first, 16),
1497                                     $cx, 16);
1498 }
1499
1500 sub pp_delete {
1501     my $self = shift;
1502     my($op, $cx) = @_;
1503     my $arg;
1504     if ($op->private & OPpSLICE) {
1505         if ($op->flags & OPf_SPECIAL) {
1506             # Deleting from an array, not a hash
1507             return $self->maybe_parens_func("delete",
1508                                         $self->pp_aslice($op->first, 16),
1509                                         $cx, 16);
1510         }
1511         return $self->maybe_parens_func("delete",
1512                                         $self->pp_hslice($op->first, 16),
1513                                         $cx, 16);
1514     } else {
1515         if ($op->flags & OPf_SPECIAL) {
1516             # Deleting from an array, not a hash
1517             return $self->maybe_parens_func("delete",
1518                                         $self->pp_aelem($op->first, 16),
1519                                         $cx, 16);
1520         }
1521         return $self->maybe_parens_func("delete",
1522                                         $self->pp_helem($op->first, 16),
1523                                         $cx, 16);
1524     }
1525 }
1526
1527 sub pp_require {
1528     my $self = shift;
1529     my($op, $cx) = @_;
1530     if (class($op) eq "UNOP" and $op->first->name eq "const"
1531         and $op->first->private & OPpCONST_BARE)
1532     {
1533         my $name = $self->const_sv($op->first)->PV;
1534         $name =~ s[/][::]g;
1535         $name =~ s/\.pm//g;
1536         return "require $name";
1537     } else {    
1538         $self->unop($op, $cx, "require");
1539     }
1540 }
1541
1542 sub pp_scalar { 
1543     my $self = shift;
1544     my($op, $cv) = @_;
1545     my $kid = $op->first;
1546     if (not null $kid->sibling) {
1547         # XXX Was a here-doc
1548         return $self->dquote($op);
1549     }
1550     $self->unop(@_, "scalar");
1551 }
1552
1553
1554 sub padval {
1555     my $self = shift;
1556     my $targ = shift;
1557     return (($self->{'curcv'}->PADLIST->ARRAY)[1]->ARRAY)[$targ];
1558 }
1559
1560 sub pp_refgen {
1561     my $self = shift;   
1562     my($op, $cx) = @_;
1563     my $kid = $op->first;
1564     if ($kid->name eq "null") {
1565         $kid = $kid->first;
1566         if ($kid->name eq "anonlist" || $kid->name eq "anonhash") {
1567             my($pre, $post) = @{{"anonlist" => ["[","]"],
1568                                  "anonhash" => ["{","}"]}->{$kid->name}};
1569             my($expr, @exprs);
1570             $kid = $kid->first->sibling; # skip pushmark
1571             for (; !null($kid); $kid = $kid->sibling) {
1572                 $expr = $self->deparse($kid, 6);
1573                 push @exprs, $expr;
1574             }
1575             return $pre . join(", ", @exprs) . $post;
1576         } elsif (!null($kid->sibling) and 
1577                  $kid->sibling->name eq "anoncode") {
1578             return "sub " .
1579                 $self->deparse_sub($self->padval($kid->sibling->targ));
1580         } elsif ($kid->name eq "pushmark") {
1581             my $sib_name = $kid->sibling->name;
1582             if ($sib_name =~ /^(pad|rv2)[ah]v$/
1583                 and not $kid->sibling->flags & OPf_REF)
1584             {
1585                 # The @a in \(@a) isn't in ref context, but only when the
1586                 # parens are there.
1587                 return "\\(" . $self->deparse($kid->sibling, 1) . ")";
1588             } elsif ($sib_name eq 'entersub') {
1589                 my $text = $self->deparse($kid->sibling, 1);
1590                 # Always show parens for \(&func()), but only with -p otherwise
1591                 $text = "($text)" if $self->{'parens'}
1592                                  or $kid->sibling->private & OPpENTERSUB_AMPER;
1593                 return "\\$text";
1594             }
1595         }
1596     }
1597     $self->pfixop($op, $cx, "\\", 20);
1598 }
1599
1600 sub pp_srefgen { pp_refgen(@_) }
1601
1602 sub pp_readline {
1603     my $self = shift;
1604     my($op, $cx) = @_;
1605     my $kid = $op->first;
1606     $kid = $kid->first if $kid->name eq "rv2gv"; # <$fh>
1607     return "<" . $self->deparse($kid, 1) . ">" if is_scalar($kid);
1608     return $self->unop($op, $cx, "readline");
1609 }
1610
1611 sub pp_rcatline {
1612     my $self = shift;
1613     my($op) = @_;
1614     return "<" . $self->gv_name($op->gv) . ">";
1615 }
1616
1617 # Unary operators that can occur as pseudo-listops inside double quotes
1618 sub dq_unop {
1619     my $self = shift;
1620     my($op, $cx, $name, $prec, $flags) = (@_, 0, 0);
1621     my $kid;
1622     if ($op->flags & OPf_KIDS) {
1623        $kid = $op->first;
1624        # If there's more than one kid, the first is an ex-pushmark.
1625        $kid = $kid->sibling if not null $kid->sibling;
1626        return $self->maybe_parens_unop($name, $kid, $cx);
1627     } else {
1628        return $name .  ($op->flags & OPf_SPECIAL ? "()" : "");       
1629     }
1630 }
1631
1632 sub pp_ucfirst { dq_unop(@_, "ucfirst") }
1633 sub pp_lcfirst { dq_unop(@_, "lcfirst") }
1634 sub pp_uc { dq_unop(@_, "uc") }
1635 sub pp_lc { dq_unop(@_, "lc") }
1636 sub pp_quotemeta { maybe_targmy(@_, \&dq_unop, "quotemeta") }
1637
1638 sub loopex {
1639     my $self = shift;
1640     my ($op, $cx, $name) = @_;
1641     if (class($op) eq "PVOP") {
1642         return "$name " . $op->pv;
1643     } elsif (class($op) eq "OP") {
1644         return $name;
1645     } elsif (class($op) eq "UNOP") {
1646         # Note -- loop exits are actually exempt from the
1647         # looks-like-a-func rule, but a few extra parens won't hurt
1648         return $self->maybe_parens_unop($name, $op->first, $cx);
1649     }
1650 }
1651
1652 sub pp_last { loopex(@_, "last") }
1653 sub pp_next { loopex(@_, "next") }
1654 sub pp_redo { loopex(@_, "redo") }
1655 sub pp_goto { loopex(@_, "goto") }
1656 sub pp_dump { loopex(@_, "dump") }
1657
1658 sub ftst {
1659     my $self = shift;
1660     my($op, $cx, $name) = @_;
1661     if (class($op) eq "UNOP") {
1662         # Genuine `-X' filetests are exempt from the LLAFR, but not
1663         # l?stat(); for the sake of clarity, give'em all parens
1664         return $self->maybe_parens_unop($name, $op->first, $cx);
1665     } elsif (class($op) eq "SVOP") {
1666         return $self->maybe_parens_func($name, $self->pp_gv($op, 1), $cx, 16);
1667     } else { # I don't think baseop filetests ever survive ck_ftst, but...
1668         return $name;
1669     }
1670 }
1671
1672 sub pp_lstat { ftst(@_, "lstat") }
1673 sub pp_stat { ftst(@_, "stat") }
1674 sub pp_ftrread { ftst(@_, "-R") }
1675 sub pp_ftrwrite { ftst(@_, "-W") }
1676 sub pp_ftrexec { ftst(@_, "-X") }
1677 sub pp_fteread { ftst(@_, "-r") }
1678 sub pp_ftewrite { ftst(@_, "-w") }
1679 sub pp_fteexec { ftst(@_, "-x") }
1680 sub pp_ftis { ftst(@_, "-e") }
1681 sub pp_fteowned { ftst(@_, "-O") }
1682 sub pp_ftrowned { ftst(@_, "-o") }
1683 sub pp_ftzero { ftst(@_, "-z") }
1684 sub pp_ftsize { ftst(@_, "-s") }
1685 sub pp_ftmtime { ftst(@_, "-M") }
1686 sub pp_ftatime { ftst(@_, "-A") }
1687 sub pp_ftctime { ftst(@_, "-C") }
1688 sub pp_ftsock { ftst(@_, "-S") }
1689 sub pp_ftchr { ftst(@_, "-c") }
1690 sub pp_ftblk { ftst(@_, "-b") }
1691 sub pp_ftfile { ftst(@_, "-f") }
1692 sub pp_ftdir { ftst(@_, "-d") }
1693 sub pp_ftpipe { ftst(@_, "-p") }
1694 sub pp_ftlink { ftst(@_, "-l") }
1695 sub pp_ftsuid { ftst(@_, "-u") }
1696 sub pp_ftsgid { ftst(@_, "-g") }
1697 sub pp_ftsvtx { ftst(@_, "-k") }
1698 sub pp_fttty { ftst(@_, "-t") }
1699 sub pp_fttext { ftst(@_, "-T") }
1700 sub pp_ftbinary { ftst(@_, "-B") }
1701
1702 sub SWAP_CHILDREN () { 1 }
1703 sub ASSIGN () { 2 } # has OP= variant
1704 sub LIST_CONTEXT () { 4 } # Assignment is in list context
1705
1706 my(%left, %right);
1707
1708 sub assoc_class {
1709     my $op = shift;
1710     my $name = $op->name;
1711     if ($name eq "concat" and $op->first->name eq "concat") {
1712         # avoid spurious `=' -- see comment in pp_concat
1713         return "concat";
1714     }
1715     if ($name eq "null" and class($op) eq "UNOP"
1716         and $op->first->name =~ /^(and|x?or)$/
1717         and null $op->first->sibling)
1718     {
1719         # Like all conditional constructs, OP_ANDs and OP_ORs are topped
1720         # with a null that's used as the common end point of the two
1721         # flows of control. For precedence purposes, ignore it.
1722         # (COND_EXPRs have these too, but we don't bother with
1723         # their associativity).
1724         return assoc_class($op->first);
1725     }
1726     return $name . ($op->flags & OPf_STACKED ? "=" : "");
1727 }
1728
1729 # Left associative operators, like `+', for which
1730 # $a + $b + $c is equivalent to ($a + $b) + $c
1731
1732 BEGIN {
1733     %left = ('multiply' => 19, 'i_multiply' => 19,
1734              'divide' => 19, 'i_divide' => 19,
1735              'modulo' => 19, 'i_modulo' => 19,
1736              'repeat' => 19,
1737              'add' => 18, 'i_add' => 18,
1738              'subtract' => 18, 'i_subtract' => 18,
1739              'concat' => 18,
1740              'left_shift' => 17, 'right_shift' => 17,
1741              'bit_and' => 13,
1742              'bit_or' => 12, 'bit_xor' => 12,
1743              'and' => 3,
1744              'or' => 2, 'xor' => 2,
1745             );
1746 }
1747
1748 sub deparse_binop_left {
1749     my $self = shift;
1750     my($op, $left, $prec) = @_;
1751     if ($left{assoc_class($op)} && $left{assoc_class($left)}
1752         and $left{assoc_class($op)} == $left{assoc_class($left)})
1753     {
1754         return $self->deparse($left, $prec - .00001);
1755     } else {
1756         return $self->deparse($left, $prec);    
1757     }
1758 }
1759
1760 # Right associative operators, like `=', for which
1761 # $a = $b = $c is equivalent to $a = ($b = $c)
1762
1763 BEGIN {
1764     %right = ('pow' => 22,
1765               'sassign=' => 7, 'aassign=' => 7,
1766               'multiply=' => 7, 'i_multiply=' => 7,
1767               'divide=' => 7, 'i_divide=' => 7,
1768               'modulo=' => 7, 'i_modulo=' => 7,
1769               'repeat=' => 7,
1770               'add=' => 7, 'i_add=' => 7,
1771               'subtract=' => 7, 'i_subtract=' => 7,
1772               'concat=' => 7,
1773               'left_shift=' => 7, 'right_shift=' => 7,
1774               'bit_and=' => 7,
1775               'bit_or=' => 7, 'bit_xor=' => 7,
1776               'andassign' => 7,
1777               'orassign' => 7,
1778              );
1779 }
1780
1781 sub deparse_binop_right {
1782     my $self = shift;
1783     my($op, $right, $prec) = @_;
1784     if ($right{assoc_class($op)} && $right{assoc_class($right)}
1785         and $right{assoc_class($op)} == $right{assoc_class($right)})
1786     {
1787         return $self->deparse($right, $prec - .00001);
1788     } else {
1789         return $self->deparse($right, $prec);   
1790     }
1791 }
1792
1793 sub binop {
1794     my $self = shift;
1795     my ($op, $cx, $opname, $prec, $flags) = (@_, 0);
1796     my $left = $op->first;
1797     my $right = $op->last;
1798     my $eq = "";
1799     if ($op->flags & OPf_STACKED && $flags & ASSIGN) {
1800         $eq = "=";
1801         $prec = 7;
1802     }
1803     if ($flags & SWAP_CHILDREN) {
1804         ($left, $right) = ($right, $left);
1805     }
1806     $left = $self->deparse_binop_left($op, $left, $prec);
1807     $left = "($left)" if $flags & LIST_CONTEXT
1808                 && $left !~ /^(my|our|local|)[\@\(]/;
1809     $right = $self->deparse_binop_right($op, $right, $prec);
1810     return $self->maybe_parens("$left $opname$eq $right", $cx, $prec);
1811 }
1812
1813 sub pp_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1814 sub pp_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1815 sub pp_subtract { maybe_targmy(@_, \&binop, "-",18,  ASSIGN) }
1816 sub pp_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1817 sub pp_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1818 sub pp_i_add { maybe_targmy(@_, \&binop, "+", 18, ASSIGN) }
1819 sub pp_i_multiply { maybe_targmy(@_, \&binop, "*", 19, ASSIGN) }
1820 sub pp_i_subtract { maybe_targmy(@_, \&binop, "-", 18, ASSIGN) }
1821 sub pp_i_divide { maybe_targmy(@_, \&binop, "/", 19, ASSIGN) }
1822 sub pp_i_modulo { maybe_targmy(@_, \&binop, "%", 19, ASSIGN) }
1823 sub pp_pow { maybe_targmy(@_, \&binop, "**", 22, ASSIGN) }
1824
1825 sub pp_left_shift { maybe_targmy(@_, \&binop, "<<", 17, ASSIGN) }
1826 sub pp_right_shift { maybe_targmy(@_, \&binop, ">>", 17, ASSIGN) }
1827 sub pp_bit_and { maybe_targmy(@_, \&binop, "&", 13, ASSIGN) }
1828 sub pp_bit_or { maybe_targmy(@_, \&binop, "|", 12, ASSIGN) }
1829 sub pp_bit_xor { maybe_targmy(@_, \&binop, "^", 12, ASSIGN) }
1830
1831 sub pp_eq { binop(@_, "==", 14) }
1832 sub pp_ne { binop(@_, "!=", 14) }
1833 sub pp_lt { binop(@_, "<", 15) }
1834 sub pp_gt { binop(@_, ">", 15) }
1835 sub pp_ge { binop(@_, ">=", 15) }
1836 sub pp_le { binop(@_, "<=", 15) }
1837 sub pp_ncmp { binop(@_, "<=>", 14) }
1838 sub pp_i_eq { binop(@_, "==", 14) }
1839 sub pp_i_ne { binop(@_, "!=", 14) }
1840 sub pp_i_lt { binop(@_, "<", 15) }
1841 sub pp_i_gt { binop(@_, ">", 15) }
1842 sub pp_i_ge { binop(@_, ">=", 15) }
1843 sub pp_i_le { binop(@_, "<=", 15) }
1844 sub pp_i_ncmp { binop(@_, "<=>", 14) }
1845
1846 sub pp_seq { binop(@_, "eq", 14) }
1847 sub pp_sne { binop(@_, "ne", 14) }
1848 sub pp_slt { binop(@_, "lt", 15) }
1849 sub pp_sgt { binop(@_, "gt", 15) }
1850 sub pp_sge { binop(@_, "ge", 15) }
1851 sub pp_sle { binop(@_, "le", 15) }
1852 sub pp_scmp { binop(@_, "cmp", 14) }
1853
1854 sub pp_sassign { binop(@_, "=", 7, SWAP_CHILDREN) }
1855 sub pp_aassign { binop(@_, "=", 7, SWAP_CHILDREN | LIST_CONTEXT) }
1856
1857 # `.' is special because concats-of-concats are optimized to save copying
1858 # by making all but the first concat stacked. The effect is as if the
1859 # programmer had written `($a . $b) .= $c', except legal.
1860 sub pp_concat { maybe_targmy(@_, \&real_concat) }
1861 sub real_concat {
1862     my $self = shift;
1863     my($op, $cx) = @_;
1864     my $left = $op->first;
1865     my $right = $op->last;
1866     my $eq = "";
1867     my $prec = 18;
1868     if ($op->flags & OPf_STACKED and $op->first->name ne "concat") {
1869         $eq = "=";
1870         $prec = 7;
1871     }
1872     $left = $self->deparse_binop_left($op, $left, $prec);
1873     $right = $self->deparse_binop_right($op, $right, $prec);
1874     return $self->maybe_parens("$left .$eq $right", $cx, $prec);
1875 }
1876
1877 # `x' is weird when the left arg is a list
1878 sub pp_repeat {
1879     my $self = shift;
1880     my($op, $cx) = @_;
1881     my $left = $op->first;
1882     my $right = $op->last;
1883     my $eq = "";
1884     my $prec = 19;
1885     if ($op->flags & OPf_STACKED) {
1886         $eq = "=";
1887         $prec = 7;
1888     }
1889     if (null($right)) { # list repeat; count is inside left-side ex-list
1890         my $kid = $left->first->sibling; # skip pushmark
1891         my @exprs;
1892         for (; !null($kid->sibling); $kid = $kid->sibling) {
1893             push @exprs, $self->deparse($kid, 6);
1894         }
1895         $right = $kid;
1896         $left = "(" . join(", ", @exprs). ")";
1897     } else {
1898         $left = $self->deparse_binop_left($op, $left, $prec);
1899     }
1900     $right = $self->deparse_binop_right($op, $right, $prec);
1901     return $self->maybe_parens("$left x$eq $right", $cx, $prec);
1902 }
1903
1904 sub range {
1905     my $self = shift;
1906     my ($op, $cx, $type) = @_;
1907     my $left = $op->first;
1908     my $right = $left->sibling;
1909     $left = $self->deparse($left, 9);
1910     $right = $self->deparse($right, 9);
1911     return $self->maybe_parens("$left $type $right", $cx, 9);
1912 }
1913
1914 sub pp_flop {
1915     my $self = shift;
1916     my($op, $cx) = @_;
1917     my $flip = $op->first;
1918     my $type = ($flip->flags & OPf_SPECIAL) ? "..." : "..";
1919     return $self->range($flip->first, $cx, $type);
1920 }
1921
1922 # one-line while/until is handled in pp_leave
1923
1924 sub logop {
1925     my $self = shift;
1926     my ($op, $cx, $lowop, $lowprec, $highop, $highprec, $blockname) = @_;
1927     my $left = $op->first;
1928     my $right = $op->first->sibling;
1929     if ($cx == 0 and is_scope($right) and $blockname
1930         and $self->{'expand'} < 7)
1931     { # if ($a) {$b}
1932         $left = $self->deparse($left, 1);
1933         $right = $self->deparse($right, 0);
1934         return "$blockname ($left) {\n\t$right\n\b}\cK";
1935     } elsif ($cx == 0 and $blockname and not $self->{'parens'}
1936              and $self->{'expand'} < 7) { # $b if $a
1937         $right = $self->deparse($right, 1);
1938         $left = $self->deparse($left, 1);
1939         return "$right $blockname $left";
1940     } elsif ($cx > $lowprec and $highop) { # $a && $b
1941         $left = $self->deparse_binop_left($op, $left, $highprec);
1942         $right = $self->deparse_binop_right($op, $right, $highprec);
1943         return $self->maybe_parens("$left $highop $right", $cx, $highprec);
1944     } else { # $a and $b
1945         $left = $self->deparse_binop_left($op, $left, $lowprec);
1946         $right = $self->deparse_binop_right($op, $right, $lowprec);
1947         return $self->maybe_parens("$left $lowop $right", $cx, $lowprec); 
1948     }
1949 }
1950
1951 sub pp_and { logop(@_, "and", 3, "&&", 11, "if") }
1952 sub pp_or  { logop(@_, "or",  2, "||", 10, "unless") }
1953
1954 # xor is syntactically a logop, but it's really a binop (contrary to
1955 # old versions of opcode.pl). Syntax is what matters here.
1956 sub pp_xor { logop(@_, "xor", 2, "",   0,  "") }
1957
1958 sub logassignop {
1959     my $self = shift;
1960     my ($op, $cx, $opname) = @_;
1961     my $left = $op->first;
1962     my $right = $op->first->sibling->first; # skip sassign
1963     $left = $self->deparse($left, 7);
1964     $right = $self->deparse($right, 7);
1965     return $self->maybe_parens("$left $opname $right", $cx, 7);
1966 }
1967
1968 sub pp_andassign { logassignop(@_, "&&=") }
1969 sub pp_orassign { logassignop(@_, "||=") }
1970
1971 sub listop {
1972     my $self = shift;
1973     my($op, $cx, $name) = @_;
1974     my(@exprs);
1975     my $parens = ($cx >= 5) || $self->{'parens'};
1976     my $kid = $op->first->sibling;
1977     return $name if null $kid;
1978     my $first;
1979     $name = "socketpair" if $name eq "sockpair";
1980     if (defined prototype("CORE::$name")
1981         && prototype("CORE::$name") =~ /^;?\*/
1982         && $kid->name eq "rv2gv") {
1983         $first = $self->deparse($kid->first, 6);
1984     }
1985     else {
1986         $first = $self->deparse($kid, 6);
1987     }
1988     if ($name eq "chmod" && $first =~ /^\d+$/) {
1989         $first = sprintf("%#o", $first);
1990     }
1991     $first = "+$first" if not $parens and substr($first, 0, 1) eq "(";
1992     push @exprs, $first;
1993     $kid = $kid->sibling;
1994     for (; !null($kid); $kid = $kid->sibling) {
1995         push @exprs, $self->deparse($kid, 6);
1996     }
1997     if ($parens) {
1998         return "$name(" . join(", ", @exprs) . ")";
1999     } else {
2000         return "$name " . join(", ", @exprs);
2001     }
2002 }
2003
2004 sub pp_bless { listop(@_, "bless") }
2005 sub pp_atan2 { maybe_targmy(@_, \&listop, "atan2") }
2006 sub pp_substr { maybe_local(@_, listop(@_, "substr")) }
2007 sub pp_vec { maybe_local(@_, listop(@_, "vec")) }
2008 sub pp_index { maybe_targmy(@_, \&listop, "index") }
2009 sub pp_rindex { maybe_targmy(@_, \&listop, "rindex") }
2010 sub pp_sprintf { maybe_targmy(@_, \&listop, "sprintf") }
2011 sub pp_formline { listop(@_, "formline") } # see also deparse_format
2012 sub pp_crypt { maybe_targmy(@_, \&listop, "crypt") }
2013 sub pp_unpack { listop(@_, "unpack") }
2014 sub pp_pack { listop(@_, "pack") }
2015 sub pp_join { maybe_targmy(@_, \&listop, "join") }
2016 sub pp_splice { listop(@_, "splice") }
2017 sub pp_push { maybe_targmy(@_, \&listop, "push") }
2018 sub pp_unshift { maybe_targmy(@_, \&listop, "unshift") }
2019 sub pp_reverse { listop(@_, "reverse") }
2020 sub pp_warn { listop(@_, "warn") }
2021 sub pp_die { listop(@_, "die") }
2022 # Actually, return is exempt from the LLAFR (see examples in this very
2023 # module!), but for consistency's sake, ignore that fact
2024 sub pp_return { listop(@_, "return") }
2025 sub pp_open { listop(@_, "open") }
2026 sub pp_pipe_op { listop(@_, "pipe") }
2027 sub pp_tie { listop(@_, "tie") }
2028 sub pp_binmode { listop(@_, "binmode") }
2029 sub pp_dbmopen { listop(@_, "dbmopen") }
2030 sub pp_sselect { listop(@_, "select") }
2031 sub pp_select { listop(@_, "select") }
2032 sub pp_read { listop(@_, "read") }
2033 sub pp_sysopen { listop(@_, "sysopen") }
2034 sub pp_sysseek { listop(@_, "sysseek") }
2035 sub pp_sysread { listop(@_, "sysread") }
2036 sub pp_syswrite { listop(@_, "syswrite") }
2037 sub pp_send { listop(@_, "send") }
2038 sub pp_recv { listop(@_, "recv") }
2039 sub pp_seek { listop(@_, "seek") }
2040 sub pp_fcntl { listop(@_, "fcntl") }
2041 sub pp_ioctl { listop(@_, "ioctl") }
2042 sub pp_flock { maybe_targmy(@_, \&listop, "flock") }
2043 sub pp_socket { listop(@_, "socket") }
2044 sub pp_sockpair { listop(@_, "sockpair") }
2045 sub pp_bind { listop(@_, "bind") }
2046 sub pp_connect { listop(@_, "connect") }
2047 sub pp_listen { listop(@_, "listen") }
2048 sub pp_accept { listop(@_, "accept") }
2049 sub pp_shutdown { listop(@_, "shutdown") }
2050 sub pp_gsockopt { listop(@_, "getsockopt") }
2051 sub pp_ssockopt { listop(@_, "setsockopt") }
2052 sub pp_chown { maybe_targmy(@_, \&listop, "chown") }
2053 sub pp_unlink { maybe_targmy(@_, \&listop, "unlink") }
2054 sub pp_chmod { maybe_targmy(@_, \&listop, "chmod") }
2055 sub pp_utime { maybe_targmy(@_, \&listop, "utime") }
2056 sub pp_rename { maybe_targmy(@_, \&listop, "rename") }
2057 sub pp_link { maybe_targmy(@_, \&listop, "link") }
2058 sub pp_symlink { maybe_targmy(@_, \&listop, "symlink") }
2059 sub pp_mkdir { maybe_targmy(@_, \&listop, "mkdir") }
2060 sub pp_open_dir { listop(@_, "opendir") }
2061 sub pp_seekdir { listop(@_, "seekdir") }
2062 sub pp_waitpid { maybe_targmy(@_, \&listop, "waitpid") }
2063 sub pp_system { maybe_targmy(@_, \&listop, "system") }
2064 sub pp_exec { maybe_targmy(@_, \&listop, "exec") }
2065 sub pp_kill { maybe_targmy(@_, \&listop, "kill") }
2066 sub pp_setpgrp { maybe_targmy(@_, \&listop, "setpgrp") }
2067 sub pp_getpriority { maybe_targmy(@_, \&listop, "getpriority") }
2068 sub pp_setpriority { maybe_targmy(@_, \&listop, "setpriority") }
2069 sub pp_shmget { listop(@_, "shmget") }
2070 sub pp_shmctl { listop(@_, "shmctl") }
2071 sub pp_shmread { listop(@_, "shmread") }
2072 sub pp_shmwrite { listop(@_, "shmwrite") }
2073 sub pp_msgget { listop(@_, "msgget") }
2074 sub pp_msgctl { listop(@_, "msgctl") }
2075 sub pp_msgsnd { listop(@_, "msgsnd") }
2076 sub pp_msgrcv { listop(@_, "msgrcv") }
2077 sub pp_semget { listop(@_, "semget") }
2078 sub pp_semctl { listop(@_, "semctl") }
2079 sub pp_semop { listop(@_, "semop") }
2080 sub pp_ghbyaddr { listop(@_, "gethostbyaddr") }
2081 sub pp_gnbyaddr { listop(@_, "getnetbyaddr") }
2082 sub pp_gpbynumber { listop(@_, "getprotobynumber") }
2083 sub pp_gsbyname { listop(@_, "getservbyname") }
2084 sub pp_gsbyport { listop(@_, "getservbyport") }
2085 sub pp_syscall { listop(@_, "syscall") }
2086
2087 sub pp_glob {
2088     my $self = shift;
2089     my($op, $cx) = @_;
2090     my $text = $self->dq($op->first->sibling);  # skip pushmark
2091     if ($text =~ /^\$?(\w|::|\`)+$/ # could look like a readline
2092         or $text =~ /[<>]/) { 
2093         return 'glob(' . single_delim('qq', '"', $text) . ')';
2094     } else {
2095         return '<' . $text . '>';
2096     }
2097 }
2098
2099 # Truncate is special because OPf_SPECIAL makes a bareword first arg
2100 # be a filehandle. This could probably be better fixed in the core
2101 # by moving the GV lookup into ck_truc.
2102
2103 sub pp_truncate {
2104     my $self = shift;
2105     my($op, $cx) = @_;
2106     my(@exprs);
2107     my $parens = ($cx >= 5) || $self->{'parens'};
2108     my $kid = $op->first->sibling;
2109     my $fh;
2110     if ($op->flags & OPf_SPECIAL) {
2111         # $kid is an OP_CONST
2112         $fh = $self->const_sv($kid)->PV;
2113     } else {
2114         $fh = $self->deparse($kid, 6);
2115         $fh = "+$fh" if not $parens and substr($fh, 0, 1) eq "(";
2116     }
2117     my $len = $self->deparse($kid->sibling, 6);
2118     if ($parens) {
2119         return "truncate($fh, $len)";
2120     } else {
2121         return "truncate $fh, $len";
2122     }
2123 }
2124
2125 sub indirop {
2126     my $self = shift;
2127     my($op, $cx, $name) = @_;
2128     my($expr, @exprs);
2129     my $kid = $op->first->sibling;
2130     my $indir = "";
2131     if ($op->flags & OPf_STACKED) {
2132         $indir = $kid;
2133         $indir = $indir->first; # skip rv2gv
2134         if (is_scope($indir)) {
2135             $indir = "{" . $self->deparse($indir, 0) . "}";
2136         } elsif ($indir->name eq "const" && $indir->private & OPpCONST_BARE) {
2137             $indir = $self->const_sv($indir)->PV;
2138         } else {
2139             $indir = $self->deparse($indir, 24);
2140         }
2141         $indir = $indir . " ";
2142         $kid = $kid->sibling;
2143     }
2144     if ($name eq "sort" && $op->private & (OPpSORT_NUMERIC | OPpSORT_INTEGER)) {
2145         $indir = ($op->private & OPpSORT_REVERSE) ? '{$b <=> $a} '
2146                                                   : '{$a <=> $b} ';
2147     }
2148     elsif ($name eq "sort" && $op->private & OPpSORT_REVERSE) {
2149         $indir = '{$b cmp $a} ';
2150     }
2151     for (; !null($kid); $kid = $kid->sibling) {
2152         $expr = $self->deparse($kid, 6);
2153         push @exprs, $expr;
2154     }
2155     return $self->maybe_parens_func($name, $indir . join(", ", @exprs),
2156                                     $cx, 5);
2157 }
2158
2159 sub pp_prtf { indirop(@_, "printf") }
2160 sub pp_print { indirop(@_, "print") }
2161 sub pp_sort { indirop(@_, "sort") }
2162
2163 sub mapop {
2164     my $self = shift;
2165     my($op, $cx, $name) = @_;
2166     my($expr, @exprs);
2167     my $kid = $op->first; # this is the (map|grep)start
2168     $kid = $kid->first->sibling; # skip a pushmark
2169     my $code = $kid->first; # skip a null
2170     if (is_scope $code) {
2171         $code = "{" . $self->deparse($code, 0) . "} ";
2172     } else {
2173         $code = $self->deparse($code, 24) . ", ";
2174     }
2175     $kid = $kid->sibling;
2176     for (; !null($kid); $kid = $kid->sibling) {
2177         $expr = $self->deparse($kid, 6);
2178         push @exprs, $expr if defined $expr;
2179     }
2180     return $self->maybe_parens_func($name, $code . join(", ", @exprs), $cx, 5);
2181 }
2182
2183 sub pp_mapwhile { mapop(@_, "map") }   
2184 sub pp_grepwhile { mapop(@_, "grep") }   
2185
2186 sub pp_list {
2187     my $self = shift;
2188     my($op, $cx) = @_;
2189     my($expr, @exprs);
2190     my $kid = $op->first->sibling; # skip pushmark
2191     my $lop;
2192     my $local = "either"; # could be local(...), my(...) or our(...)
2193     for ($lop = $kid; !null($lop); $lop = $lop->sibling) {
2194         # This assumes that no other private flags equal 128, and that
2195         # OPs that store things other than flags in their op_private,
2196         # like OP_AELEMFAST, won't be immediate children of a list.
2197         #
2198         # OP_ENTERSUB can break this logic, so check for it.
2199         # I suspect that open and exit can too.
2200
2201         if (!($lop->private & (OPpLVAL_INTRO|OPpOUR_INTRO)
2202                 or $lop->name eq "undef")
2203             or $lop->name eq "entersub"
2204             or $lop->name eq "exit"
2205             or $lop->name eq "open")
2206         {
2207             $local = ""; # or not
2208             last;
2209         }
2210         if ($lop->name =~ /^pad[ash]v$/) { # my()
2211             ($local = "", last) if $local eq "local" || $local eq "our";
2212             $local = "my";
2213         } elsif ($lop->name =~ /^(gv|rv2)[ash]v$/
2214                         && $lop->private & OPpOUR_INTRO
2215                 or $lop->name eq "null" && $lop->first->name eq "gvsv"
2216                         && $lop->first->private & OPpOUR_INTRO) { # our()
2217             ($local = "", last) if $local eq "my" || $local eq "local";
2218             $local = "our";
2219         } elsif ($lop->name ne "undef") { # local()
2220             ($local = "", last) if $local eq "my" || $local eq "our";
2221             $local = "local";
2222         }
2223     }
2224     $local = "" if $local eq "either"; # no point if it's all undefs
2225     return $self->deparse($kid, $cx) if null $kid->sibling and not $local;
2226     for (; !null($kid); $kid = $kid->sibling) {
2227         if ($local) {
2228             if (class($kid) eq "UNOP" and $kid->first->name eq "gvsv") {
2229                 $lop = $kid->first;
2230             } else {
2231                 $lop = $kid;
2232             }
2233             $self->{'avoid_local'}{$$lop}++;
2234             $expr = $self->deparse($kid, 6);
2235             delete $self->{'avoid_local'}{$$lop};
2236         } else {
2237             $expr = $self->deparse($kid, 6);
2238         }
2239         push @exprs, $expr;
2240     }
2241     if ($local) {
2242         return "$local(" . join(", ", @exprs) . ")";
2243     } else {
2244         return $self->maybe_parens( join(", ", @exprs), $cx, 6);        
2245     }
2246 }
2247
2248 sub is_ifelse_cont {
2249     my $op = shift;
2250     return ($op->name eq "null" and class($op) eq "UNOP"
2251             and $op->first->name =~ /^(and|cond_expr)$/
2252             and is_scope($op->first->first->sibling));
2253 }
2254
2255 sub pp_cond_expr {
2256     my $self = shift;
2257     my($op, $cx) = @_;
2258     my $cond = $op->first;
2259     my $true = $cond->sibling;
2260     my $false = $true->sibling;
2261     my $cuddle = $self->{'cuddle'};
2262     unless ($cx == 0 and (is_scope($true) and $true->name ne "null") and
2263             (is_scope($false) || is_ifelse_cont($false))
2264             and $self->{'expand'} < 7) {
2265         $cond = $self->deparse($cond, 8);
2266         $true = $self->deparse($true, 8);
2267         $false = $self->deparse($false, 8);
2268         return $self->maybe_parens("$cond ? $true : $false", $cx, 8);
2269     }
2270
2271     $cond = $self->deparse($cond, 1);
2272     $true = $self->deparse($true, 0);    
2273     my $head = "if ($cond) {\n\t$true\n\b}";
2274     my @elsifs;
2275     while (!null($false) and is_ifelse_cont($false)) {
2276         my $newop = $false->first;
2277         my $newcond = $newop->first;
2278         my $newtrue = $newcond->sibling;
2279         $false = $newtrue->sibling; # last in chain is OP_AND => no else
2280         $newcond = $self->deparse($newcond, 1);
2281         $newtrue = $self->deparse($newtrue, 0);
2282         push @elsifs, "elsif ($newcond) {\n\t$newtrue\n\b}";
2283     }
2284     if (!null($false)) {            
2285         $false = $cuddle . "else {\n\t" .
2286           $self->deparse($false, 0) . "\n\b}\cK";
2287     } else {
2288         $false = "\cK";
2289     }
2290     return $head . join($cuddle, "", @elsifs) . $false; 
2291 }
2292
2293 sub loop_common {
2294     my $self = shift;
2295     my($op, $cx, $init) = @_;
2296     my $enter = $op->first;
2297     my $kid = $enter->sibling;
2298     local(@$self{qw'curstash warnings hints'})
2299                 = @$self{qw'curstash warnings hints'};
2300     my $head = "";
2301     my $bare = 0;
2302     my $body;
2303     my $cond = undef;
2304     if ($kid->name eq "lineseq") { # bare or infinite loop 
2305         if (is_state $kid->last) { # infinite
2306             $head = "while (1) "; # Can't use for(;;) if there's a continue
2307             $cond = "";
2308         } else {
2309             $bare = 1;
2310         }
2311         $body = $kid;
2312     } elsif ($enter->name eq "enteriter") { # foreach
2313         my $ary = $enter->first->sibling; # first was pushmark
2314         my $var = $ary->sibling;
2315         if ($enter->flags & OPf_STACKED
2316             and not null $ary->first->sibling->sibling)
2317         {
2318             $ary = $self->deparse($ary->first->sibling, 9) . " .. " .
2319               $self->deparse($ary->first->sibling->sibling, 9);
2320         } else {
2321             $ary = $self->deparse($ary, 1);
2322         }
2323         if (null $var) {
2324             if ($enter->flags & OPf_SPECIAL) { # thread special var
2325                 $var = $self->pp_threadsv($enter, 1);
2326             } else { # regular my() variable
2327                 $var = $self->pp_padsv($enter, 1);
2328                 if ($self->padname_sv($enter->targ)->IVX ==
2329                     $kid->first->first->sibling->last->cop_seq)
2330                 {
2331                     # If the scope of this variable closes at the last
2332                     # statement of the loop, it must have been
2333                     # declared here.
2334                     $var = "my " . $var;
2335                 }
2336             }
2337         } elsif ($var->name eq "rv2gv") {
2338             $var = $self->pp_rv2sv($var, 1);
2339         } elsif ($var->name eq "gv") {
2340             $var = "\$" . $self->deparse($var, 1);
2341         }
2342         $head = "foreach $var ($ary) ";
2343         $body = $kid->first->first->sibling; # skip OP_AND and OP_ITER
2344     } elsif ($kid->name eq "null") { # while/until
2345         $kid = $kid->first;
2346         my $name = {"and" => "while", "or" => "until"}->{$kid->name};
2347         $cond = $self->deparse($kid->first, 1);
2348         $head = "$name ($cond) ";
2349         $body = $kid->first->sibling;
2350     } elsif ($kid->name eq "stub") { # bare and empty
2351         return "{;}"; # {} could be a hashref
2352     }
2353     # If there isn't a continue block, then the next pointer for the loop
2354     # will point to the unstack, which is kid's penultimate child, except
2355     # in a bare loop, when it will point to the leaveloop. When neither of
2356     # these conditions hold, then the third-to-last child in the continue
2357     # block (or the last in a bare loop).
2358     my $cont_start = $enter->nextop;
2359     my $cont;
2360     if ($$cont_start != $$op && ${$cont_start->sibling} != ${$body->last}) {
2361         if ($bare) {
2362             $cont = $body->last;
2363         } else {
2364             $cont = $body->first;
2365             while (!null($cont->sibling->sibling->sibling)) {
2366                 $cont = $cont->sibling;
2367             }
2368         }
2369         my $state = $body->first;
2370         my $cuddle = $self->{'cuddle'};
2371         my @states;
2372         for (; $$state != $$cont; $state = $state->sibling) {
2373             push @states, $state;
2374         }
2375         $body = $self->lineseq(undef, @states);
2376         if (defined $cond and not is_scope $cont and $self->{'expand'} < 3) {
2377             $head = "for ($init; $cond; " . $self->deparse($cont, 1) .") ";
2378             $cont = "\cK";
2379         } else {
2380             $cont = $cuddle . "continue {\n\t" .
2381               $self->deparse($cont, 0) . "\n\b}\cK";
2382         }
2383     } else {
2384         return "" if !defined $body;
2385         if (length $init) {
2386             $head = "for ($init; $cond;) ";
2387         }
2388         $cont = "\cK";
2389         $body = $self->deparse($body, 0);
2390     }
2391     $body =~ s/;?$/;\n/;
2392
2393     return $head . "{\n\t" . $body . "\b}" . $cont;
2394 }
2395
2396 sub pp_leaveloop { loop_common(@_, "") }
2397
2398 sub for_loop {
2399     my $self = shift;
2400     my($op, $cx) = @_;
2401     my $init = $self->deparse($op, 1);
2402     return $self->loop_common($op->sibling->first->sibling, $cx, $init);
2403 }
2404
2405 sub pp_leavetry {
2406     my $self = shift;
2407     return "eval {\n\t" . $self->pp_leave(@_) . "\n\b}";
2408 }
2409
2410 BEGIN { eval "sub OP_CONST () {" . opnumber("const") . "}" }
2411 BEGIN { eval "sub OP_STRINGIFY () {" . opnumber("stringify") . "}" }
2412 BEGIN { eval "sub OP_RV2SV () {" . opnumber("rv2sv") . "}" }
2413 BEGIN { eval "sub OP_LIST () {" . opnumber("list") . "}" }
2414
2415 sub pp_null {
2416     my $self = shift;
2417     my($op, $cx) = @_;
2418     if (class($op) eq "OP") {
2419         # old value is lost
2420         return $self->{'ex_const'} if $op->targ == OP_CONST;
2421     } elsif ($op->first->name eq "pushmark") {
2422         return $self->pp_list($op, $cx);
2423     } elsif ($op->first->name eq "enter") {
2424         return $self->pp_leave($op, $cx);
2425     } elsif ($op->targ == OP_STRINGIFY) {
2426         return $self->dquote($op, $cx);
2427     } elsif (!null($op->first->sibling) and
2428              $op->first->sibling->name eq "readline" and
2429              $op->first->sibling->flags & OPf_STACKED) {
2430         return $self->maybe_parens($self->deparse($op->first, 7) . " = "
2431                                    . $self->deparse($op->first->sibling, 7),
2432                                    $cx, 7);
2433     } elsif (!null($op->first->sibling) and
2434              $op->first->sibling->name eq "trans" and
2435              $op->first->sibling->flags & OPf_STACKED) {
2436         return $self->maybe_parens($self->deparse($op->first, 20) . " =~ "
2437                                    . $self->deparse($op->first->sibling, 20),
2438                                    $cx, 20);
2439     } elsif ($op->flags & OPf_SPECIAL && $cx == 0 && !$op->targ) {
2440         return "do {\n\t". $self->deparse($op->first, $cx) ."\n\b};";
2441     } elsif (!null($op->first->sibling) and
2442              $op->first->sibling->name eq "null" and
2443              class($op->first->sibling) eq "UNOP" and
2444              $op->first->sibling->first->flags & OPf_STACKED and
2445              $op->first->sibling->first->name eq "rcatline") {
2446         return $self->maybe_parens($self->deparse($op->first, 18) . " .= "
2447                                    . $self->deparse($op->first->sibling, 18),
2448                                    $cx, 18);
2449     } else {
2450         return $self->deparse($op->first, $cx);
2451     }
2452 }
2453
2454 sub padname {
2455     my $self = shift;
2456     my $targ = shift;
2457     return $self->padname_sv($targ)->PVX;
2458 }
2459
2460 sub padany {
2461     my $self = shift;
2462     my $op = shift;
2463     return substr($self->padname($op->targ), 1); # skip $/@/%
2464 }
2465
2466 sub pp_padsv {
2467     my $self = shift;
2468     my($op, $cx) = @_;
2469     return $self->maybe_my($op, $cx, $self->padname($op->targ));
2470 }
2471
2472 sub pp_padav { pp_padsv(@_) }
2473 sub pp_padhv { pp_padsv(@_) }
2474
2475 my @threadsv_names;
2476
2477 BEGIN {
2478     @threadsv_names = ("_", "1", "2", "3", "4", "5", "6", "7", "8", "9",
2479                        "&", "`", "'", "+", "/", ".", ",", "\\", '"', ";",
2480                        "^", "-", "%", "=", "|", "~", ":", "^A", "^E",
2481                        "!", "@");
2482 }
2483
2484 sub pp_threadsv {
2485     my $self = shift;
2486     my($op, $cx) = @_;
2487     return $self->maybe_local($op, $cx, "\$" .  $threadsv_names[$op->targ]);
2488 }    
2489
2490 sub gv_or_padgv {
2491     my $self = shift;
2492     my $op = shift;
2493     if (class($op) eq "PADOP") {
2494         return $self->padval($op->padix);
2495     } else { # class($op) eq "SVOP"
2496         return $op->gv;
2497     }
2498 }
2499
2500 sub pp_gvsv {
2501     my $self = shift;
2502     my($op, $cx) = @_;
2503     my $gv = $self->gv_or_padgv($op);
2504     return $self->maybe_local($op, $cx, $self->stash_variable("\$",
2505                                  $self->gv_name($gv)));
2506 }
2507
2508 sub pp_gv {
2509     my $self = shift;
2510     my($op, $cx) = @_;
2511     my $gv = $self->gv_or_padgv($op);
2512     return $self->gv_name($gv);
2513 }
2514
2515 sub pp_aelemfast {
2516     my $self = shift;
2517     my($op, $cx) = @_;
2518     my $gv = $self->gv_or_padgv($op);
2519     my $name = $self->gv_name($gv);
2520     $name = $self->{'curstash'}."::$name"
2521         if $name !~ /::/ && $self->lex_in_scope('@'.$name);
2522
2523     return "\$" . $name . "[" .
2524                   ($op->private + $self->{'arybase'}) . "]";
2525 }
2526
2527 sub rv2x {
2528     my $self = shift;
2529     my($op, $cx, $type) = @_;
2530
2531     if (class($op) eq 'NULL' || !$op->can("first")) {
2532         carp("Unexpected op in pp_rv2x");
2533         return 'XXX';
2534     }
2535     my $kid = $op->first;
2536     my $str = $self->deparse($kid, 0);
2537     return $self->stash_variable($type, $str) if is_scalar($kid);
2538     return $type ."{$str}";
2539 }
2540
2541 sub pp_rv2sv { maybe_local(@_, rv2x(@_, "\$")) }
2542 sub pp_rv2hv { maybe_local(@_, rv2x(@_, "%")) }
2543 sub pp_rv2gv { maybe_local(@_, rv2x(@_, "*")) }
2544
2545 # skip rv2av
2546 sub pp_av2arylen {
2547     my $self = shift;
2548     my($op, $cx) = @_;
2549     if ($op->first->name eq "padav") {
2550         return $self->maybe_local($op, $cx, '$#' . $self->padany($op->first));
2551     } else {
2552         return $self->maybe_local($op, $cx,
2553                                   $self->rv2x($op->first, $cx, '$#'));
2554     }
2555 }
2556
2557 # skip down to the old, ex-rv2cv
2558 sub pp_rv2cv {
2559     my ($self, $op, $cx) = @_;
2560     if (!null($op->first) && $op->first->name eq 'null' &&
2561         $op->first->targ eq OP_LIST)
2562     {
2563         return $self->rv2x($op->first->first->sibling, $cx, "&")
2564     }
2565     else {
2566         return $self->rv2x($op, $cx, "")
2567     }
2568 }
2569
2570 sub pp_rv2av {
2571     my $self = shift;
2572     my($op, $cx) = @_;
2573     my $kid = $op->first;
2574     if ($kid->name eq "const") { # constant list
2575         my $av = $self->const_sv($kid);
2576         return "(" . join(", ", map(const($_), $av->ARRAY)) . ")";
2577     } else {
2578         return $self->maybe_local($op, $cx, $self->rv2x($op, $cx, "\@"));
2579     }
2580  }
2581
2582 sub is_subscriptable {
2583     my $op = shift;
2584     if ($op->name =~ /^[ahg]elem/) {
2585         return 1;
2586     } elsif ($op->name eq "entersub") {
2587         my $kid = $op->first;
2588         return 0 unless null $kid->sibling;
2589         $kid = $kid->first;
2590         $kid = $kid->sibling until null $kid->sibling;
2591         return 0 if is_scope($kid);
2592         $kid = $kid->first;
2593         return 0 if $kid->name eq "gv";
2594         return 0 if is_scalar($kid);
2595         return is_subscriptable($kid);  
2596     } else {
2597         return 0;
2598     }
2599 }
2600
2601 sub elem {
2602     my $self = shift;
2603     my ($op, $cx, $left, $right, $padname) = @_;
2604     my($array, $idx) = ($op->first, $op->first->sibling);
2605     unless ($array->name eq $padname) { # Maybe this has been fixed     
2606         $array = $array->first; # skip rv2av (or ex-rv2av in _53+)
2607     }
2608     if ($array->name eq $padname) {
2609         $array = $self->padany($array);
2610     } elsif (is_scope($array)) { # ${expr}[0]
2611         $array = "{" . $self->deparse($array, 0) . "}";
2612     } elsif ($array->name eq "gv") {
2613         $array = $self->gv_name($self->gv_or_padgv($array));
2614         if ($array !~ /::/) {
2615             my $prefix = ($left eq '[' ? '@' : '%');
2616             $array = $self->{curstash}.'::'.$array
2617                 if $self->lex_in_scope($prefix . $array);
2618         }
2619     } elsif (is_scalar $array) { # $x[0], $$x[0], ...
2620         $array = $self->deparse($array, 24);
2621     } else {
2622         # $x[20][3]{hi} or expr->[20]
2623         my $arrow = is_subscriptable($array) ? "" : "->";
2624         return $self->deparse($array, 24) . $arrow .
2625             $left . $self->deparse($idx, 1) . $right;
2626     }
2627     $idx = $self->deparse($idx, 1);
2628
2629     # Outer parens in an array index will confuse perl
2630     # if we're interpolating in a regular expression, i.e.
2631     # /$x$foo[(-1)]/ is *not* the same as /$x$foo[-1]/
2632     #
2633     # If $self->{parens}, then an initial '(' will
2634     # definitely be paired with a final ')'. If
2635     # !$self->{parens}, the misleading parens won't
2636     # have been added in the first place.
2637     #
2638     # [You might think that we could get "(...)...(...)"
2639     # where the initial and final parens do not match
2640     # each other. But we can't, because the above would
2641     # only happen if there's an infix binop between the
2642     # two pairs of parens, and *that* means that the whole
2643     # expression would be parenthesized as well.]
2644     #
2645     $idx =~ s/^\((.*)\)$/$1/ if $self->{'parens'};
2646
2647     # Hash-element braces will autoquote a bareword inside themselves.
2648     # We need to make sure that C<$hash{warn()}> doesn't come out as
2649     # C<$hash{warn}>, which has a quite different meaning. Currently
2650     # B::Deparse will always quote strings, even if the string was a
2651     # bareword in the original (i.e. the OPpCONST_BARE flag is ignored
2652     # for constant strings.) So we can cheat slightly here - if we see
2653     # a bareword, we know that it is supposed to be a function call.
2654     #
2655     $idx =~ s/^([A-Za-z_]\w*)$/$1()/;
2656
2657     return "\$" . $array . $left . $idx . $right;
2658 }
2659
2660 sub pp_aelem { maybe_local(@_, elem(@_, "[", "]", "padav")) }
2661 sub pp_helem { maybe_local(@_, elem(@_, "{", "}", "padhv")) }
2662
2663 sub pp_gelem {
2664     my $self = shift;
2665     my($op, $cx) = @_;
2666     my($glob, $part) = ($op->first, $op->last);
2667     $glob = $glob->first; # skip rv2gv
2668     $glob = $glob->first if $glob->name eq "rv2gv"; # this one's a bug
2669     my $scope = is_scope($glob);
2670     $glob = $self->deparse($glob, 0);
2671     $part = $self->deparse($part, 1);
2672     return "*" . ($scope ? "{$glob}" : $glob) . "{$part}";
2673 }
2674
2675 sub slice {
2676     my $self = shift;
2677     my ($op, $cx, $left, $right, $regname, $padname) = @_;
2678     my $last;
2679     my(@elems, $kid, $array, $list);
2680     if (class($op) eq "LISTOP") {
2681         $last = $op->last;
2682     } else { # ex-hslice inside delete()
2683         for ($kid = $op->first; !null $kid->sibling; $kid = $kid->sibling) {}
2684         $last = $kid;
2685     }
2686     $array = $last;
2687     $array = $array->first
2688         if $array->name eq $regname or $array->name eq "null";
2689     if (is_scope($array)) {
2690         $array = "{" . $self->deparse($array, 0) . "}";
2691     } elsif ($array->name eq $padname) {
2692         $array = $self->padany($array);
2693     } else {
2694         $array = $self->deparse($array, 24);
2695     }
2696     $kid = $op->first->sibling; # skip pushmark
2697     if ($kid->name eq "list") {
2698         $kid = $kid->first->sibling; # skip list, pushmark
2699         for (; !null $kid; $kid = $kid->sibling) {
2700             push @elems, $self->deparse($kid, 6);
2701         }
2702         $list = join(", ", @elems);
2703     } else {
2704         $list = $self->deparse($kid, 1);
2705     }
2706     return "\@" . $array . $left . $list . $right;
2707 }
2708
2709 sub pp_aslice { maybe_local(@_, slice(@_, "[", "]", "rv2av", "padav")) }
2710 sub pp_hslice { maybe_local(@_, slice(@_, "{", "}", "rv2hv", "padhv")) }
2711
2712 sub pp_lslice {
2713     my $self = shift;
2714     my($op, $cx) = @_;
2715     my $idx = $op->first;
2716     my $list = $op->last;
2717     my(@elems, $kid);
2718     $list = $self->deparse($list, 1);
2719     $idx = $self->deparse($idx, 1);
2720     return "($list)" . "[$idx]";
2721 }
2722
2723 sub want_scalar {
2724     my $op = shift;
2725     return ($op->flags & OPf_WANT) == OPf_WANT_SCALAR;
2726 }
2727
2728 sub want_list {
2729     my $op = shift;
2730     return ($op->flags & OPf_WANT) == OPf_WANT_LIST;
2731 }
2732
2733 sub method {
2734     my $self = shift;
2735     my($op, $cx) = @_;
2736     my $kid = $op->first->sibling; # skip pushmark
2737     my($meth, $obj, @exprs);
2738     if ($kid->name eq "list" and want_list $kid) {
2739         # When an indirect object isn't a bareword but the args are in
2740         # parens, the parens aren't part of the method syntax (the LLAFR
2741         # doesn't apply), but they make a list with OPf_PARENS set that
2742         # doesn't get flattened by the append_elem that adds the method,
2743         # making a (object, arg1, arg2, ...) list where the object
2744         # usually is. This can be distinguished from 
2745         # `($obj, $arg1, $arg2)->meth()' (which is legal if $arg2 is an
2746         # object) because in the later the list is in scalar context
2747         # as the left side of -> always is, while in the former
2748         # the list is in list context as method arguments always are.
2749         # (Good thing there aren't method prototypes!)
2750         $meth = $kid->sibling;
2751         $kid = $kid->first->sibling; # skip pushmark
2752         $obj = $kid;
2753         $kid = $kid->sibling;
2754         for (; not null $kid; $kid = $kid->sibling) {
2755             push @exprs, $self->deparse($kid, 6);
2756         }
2757     } else {
2758         $obj = $kid;
2759         $kid = $kid->sibling;
2760         for (; !null ($kid->sibling) && $kid->name ne "method_named";
2761               $kid = $kid->sibling) {
2762             push @exprs, $self->deparse($kid, 6);
2763         }
2764         $meth = $kid;
2765     }
2766     $obj = $self->deparse($obj, 24);
2767     if ($meth->name eq "method_named") {
2768         $meth = $self->const_sv($meth)->PV;
2769     } else {
2770         $meth = $meth->first;
2771         if ($meth->name eq "const") {
2772             # As of 5.005_58, this case is probably obsoleted by the
2773             # method_named case above
2774             $meth = $self->const_sv($meth)->PV; # needs to be bare
2775         } else {
2776             $meth = $self->deparse($meth, 1);
2777         }
2778     }
2779     my $args = join(", ", @exprs);      
2780     $kid = $obj . "->" . $meth;
2781     if (length $args) {
2782         return $kid . "(" . $args . ")"; # parens mandatory
2783     } else {
2784         return $kid;
2785     }
2786 }
2787
2788 # returns "&" if the prototype doesn't match the args,
2789 # or ("", $args_after_prototype_demunging) if it does.
2790 sub check_proto {
2791     my $self = shift;
2792     return "&" if $self->{'noproto'};
2793     my($proto, @args) = @_;
2794     my($arg, $real);
2795     my $doneok = 0;
2796     my @reals;
2797     # An unbackslashed @ or % gobbles up the rest of the args
2798     1 while $proto =~ s/(?<!\\)([@%])[^\]]+$/$1/;
2799     while ($proto) {
2800         $proto =~ s/^(\\?[\$\@&%*]|\\\[[\$\@&%*]+\]|;)//;
2801         my $chr = $1;
2802         if ($chr eq "") {
2803             return "&" if @args;
2804         } elsif ($chr eq ";") {
2805             $doneok = 1;
2806         } elsif ($chr eq "@" or $chr eq "%") {
2807             push @reals, map($self->deparse($_, 6), @args);
2808             @args = ();
2809         } else {
2810             $arg = shift @args;
2811             last unless $arg;
2812             if ($chr eq "\$") {
2813                 if (want_scalar $arg) {
2814                     push @reals, $self->deparse($arg, 6);
2815                 } else {
2816                     return "&";
2817                 }
2818             } elsif ($chr eq "&") {
2819                 if ($arg->name =~ /^(s?refgen|undef)$/) {
2820                     push @reals, $self->deparse($arg, 6);
2821                 } else {
2822                     return "&";
2823                 }
2824             } elsif ($chr eq "*") {
2825                 if ($arg->name =~ /^s?refgen$/
2826                     and $arg->first->first->name eq "rv2gv")
2827                   {
2828                       $real = $arg->first->first; # skip refgen, null
2829                       if ($real->first->name eq "gv") {
2830                           push @reals, $self->deparse($real, 6);
2831                       } else {
2832                           push @reals, $self->deparse($real->first, 6);
2833                       }
2834                   } else {
2835                       return "&";
2836                   }
2837             } elsif (substr($chr, 0, 1) eq "\\") {
2838                 $chr =~ tr/\\[]//d;
2839                 if ($arg->name =~ /^s?refgen$/ and
2840                     !null($real = $arg->first) and
2841                     ($chr =~ /\$/ && is_scalar($real->first)
2842                      or ($chr =~ /@/
2843                          && class($real->first->sibling) ne 'NULL'
2844                          && $real->first->sibling->name
2845                          =~ /^(rv2|pad)av$/)
2846                      or ($chr =~ /%/
2847                          && class($real->first->sibling) ne 'NULL'
2848                          && $real->first->sibling->name
2849                          =~ /^(rv2|pad)hv$/)
2850                      #or ($chr =~ /&/ # This doesn't work
2851                      #   && $real->first->name eq "rv2cv")
2852                      or ($chr =~ /\*/
2853                          && $real->first->name eq "rv2gv")))
2854                   {
2855                       push @reals, $self->deparse($real, 6);
2856                   } else {
2857                       return "&";
2858                   }
2859             }
2860        }
2861     }
2862     return "&" if $proto and !$doneok; # too few args and no `;'
2863     return "&" if @args;               # too many args
2864     return ("", join ", ", @reals);
2865 }
2866
2867 sub pp_entersub {
2868     my $self = shift;
2869     my($op, $cx) = @_;
2870     return $self->method($op, $cx) unless null $op->first->sibling;
2871     my $prefix = "";
2872     my $amper = "";
2873     my($kid, @exprs);
2874     if ($op->flags & OPf_SPECIAL && !($op->flags & OPf_MOD)) {
2875         $prefix = "do ";
2876     } elsif ($op->private & OPpENTERSUB_AMPER) {
2877         $amper = "&";
2878     }
2879     $kid = $op->first;
2880     $kid = $kid->first->sibling; # skip ex-list, pushmark
2881     for (; not null $kid->sibling; $kid = $kid->sibling) {
2882         push @exprs, $kid;
2883     }
2884     my $simple = 0;
2885     my $proto = undef;
2886     if (is_scope($kid)) {
2887         $amper = "&";
2888         $kid = "{" . $self->deparse($kid, 0) . "}";
2889     } elsif ($kid->first->name eq "gv") {
2890         my $gv = $self->gv_or_padgv($kid->first);
2891         if (class($gv->CV) ne "SPECIAL") {
2892             $proto = $gv->CV->PV if $gv->CV->FLAGS & SVf_POK;
2893         }
2894         $simple = 1; # only calls of named functions can be prototyped
2895         $kid = $self->deparse($kid, 24);
2896     } elsif (is_scalar ($kid->first) && $kid->first->name ne 'rv2cv') {
2897         $amper = "&";
2898         $kid = $self->deparse($kid, 24);
2899     } else {
2900         $prefix = "";
2901         my $arrow = is_subscriptable($kid->first) ? "" : "->";
2902         $kid = $self->deparse($kid, 24) . $arrow;
2903     }
2904
2905     # Doesn't matter how many prototypes there are, if
2906     # they haven't happened yet!
2907     my $declared;
2908     {
2909         no strict 'refs';
2910         no warnings 'uninitialized';
2911         $declared = exists $self->{'subs_declared'}{$kid}
2912             || ( 
2913                  defined &{ %{$self->{'curstash'}."::"}->{$kid} }
2914                  && !exists
2915                      $self->{'subs_deparsed'}{$self->{'curstash'}."::".$kid}
2916                  && defined prototype $self->{'curstash'}."::".$kid
2917                );
2918         if (!$declared && defined($proto)) {
2919             # Avoid "too early to check prototype" warning
2920             ($amper, $proto) = ('&');
2921         }
2922     }
2923
2924     my $args;
2925     if ($declared and defined $proto and not $amper) {
2926         ($amper, $args) = $self->check_proto($proto, @exprs);
2927         if ($amper eq "&") {
2928             $args = join(", ", map($self->deparse($_, 6), @exprs));
2929         }
2930     } else {
2931         $args = join(", ", map($self->deparse($_, 6), @exprs));
2932     }
2933     if ($prefix or $amper) {
2934         if ($op->flags & OPf_STACKED) {
2935             return $prefix . $amper . $kid . "(" . $args . ")";
2936         } else {
2937             return $prefix . $amper. $kid;
2938         }
2939     } else {
2940         # glob() invocations can be translated into calls of
2941         # CORE::GLOBAL::glob with a second parameter, a number.
2942         # Reverse this.
2943         if ($kid eq "CORE::GLOBAL::glob") {
2944             $kid = "glob";
2945             $args =~ s/\s*,[^,]+$//;
2946         }
2947
2948         # It's a syntax error to call CORE::GLOBAL::foo without a prefix,
2949         # so it must have been translated from a keyword call. Translate
2950         # it back.
2951         $kid =~ s/^CORE::GLOBAL:://;
2952
2953         if (!$declared) {
2954             return "$kid(" . $args . ")";
2955         } elsif (defined $proto and $proto eq "") {
2956             return $kid;
2957         } elsif (defined $proto and $proto eq "\$" and is_scalar($exprs[0])) {
2958             return $self->maybe_parens_func($kid, $args, $cx, 16);
2959         } elsif (defined($proto) && $proto or $simple) {
2960             return $self->maybe_parens_func($kid, $args, $cx, 5);
2961         } else {
2962             return "$kid(" . $args . ")";
2963         }
2964     }
2965 }
2966
2967 sub pp_enterwrite { unop(@_, "write") }
2968
2969 # escape things that cause interpolation in double quotes,
2970 # but not character escapes
2971 sub uninterp {
2972     my($str) = @_;
2973     $str =~ s/(^|\G|[^\\])((?:\\\\)*)([\$\@]|\\[uUlLQE])/$1$2\\$3/g;
2974     return $str;
2975 }
2976
2977 {
2978 my $bal;
2979 BEGIN {
2980     use re "eval";
2981     # Matches any string which is balanced with respect to {braces}
2982     $bal = qr(
2983       (?:
2984         [^\\{}]
2985       | \\\\
2986       | \\[{}]
2987       | \{(??{$bal})\}
2988       )*
2989     )x;
2990 }
2991
2992 # the same, but treat $|, $), $( and $ at the end of the string differently
2993 sub re_uninterp {
2994     my($str) = @_;
2995
2996     $str =~ s/
2997           ( ^|\G                  # $1
2998           | [^\\]
2999           )
3000
3001           (                       # $2
3002             (?:\\\\)*
3003           )
3004
3005           (                       # $3
3006             (\(\?\??\{$bal\}\))   # $4
3007           | [\$\@]
3008             (?!\||\)|\(|$)
3009           | \\[uUlLQE]
3010           )
3011
3012         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3013
3014     return $str;
3015 }
3016
3017 # This is for regular expressions with the /x modifier
3018 # We have to leave comments unmangled.
3019 sub re_uninterp_extended {
3020     my($str) = @_;
3021
3022     $str =~ s/
3023           ( ^|\G                  # $1
3024           | [^\\]
3025           )
3026
3027           (                       # $2
3028             (?:\\\\)*
3029           )
3030
3031           (                       # $3
3032             ( \(\?\??\{$bal\}\)   # $4  (skip over (?{}) and (??{}) blocks)
3033             | \#[^\n]*            #     (skip over comments)
3034             )
3035           | [\$\@]
3036             (?!\||\)|\(|$|\s)
3037           | \\[uUlLQE]
3038           )
3039
3040         /length($4) ? "$1$2$4" : "$1$2\\$3"/xeg;
3041
3042     return $str;
3043 }
3044 }
3045
3046 # character escapes, but not delimiters that might need to be escaped
3047 sub escape_str { # ASCII, UTF8
3048     my($str) = @_;
3049     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3050     $str =~ s/\a/\\a/g;
3051 #    $str =~ s/\cH/\\b/g; # \b means something different in a regex 
3052     $str =~ s/\t/\\t/g;
3053     $str =~ s/\n/\\n/g;
3054     $str =~ s/\e/\\e/g;
3055     $str =~ s/\f/\\f/g;
3056     $str =~ s/\r/\\r/g;
3057     $str =~ s/([\cA-\cZ])/sprintf("\\c%c", ord('@') + ord($1))/ge;
3058     $str =~ s/([[:^print:]])/sprintf("\\%03o", ord($1))/ge;
3059     return $str;
3060 }
3061
3062 # For regexes with the /x modifier.
3063 # Leave whitespace unmangled.
3064 sub escape_extended_re {
3065     my($str) = @_;
3066     $str =~ s/(.)/ord($1) > 255 ? sprintf("\\x{%x}", ord($1)) : $1/eg;
3067     $str =~ s/([[:^print:]])/
3068         ($1 =~ y! \t\n!!) ? $1 : sprintf("\\%03o", ord($1))/ge;
3069     $str =~ s/\n/\n\f/g;
3070     return $str;
3071 }
3072
3073 # Don't do this for regexen
3074 sub unback {
3075     my($str) = @_;
3076     $str =~ s/\\/\\\\/g;
3077     return $str;
3078 }
3079
3080 # Remove backslashes which precede literal control characters,
3081 # to avoid creating ambiguity when we escape the latter.
3082 sub re_unback {
3083     my($str) = @_;
3084
3085     # the insane complexity here is due to the behaviour of "\c\"
3086     $str =~ s/(^|[^\\]|\\c\\)(?<!\\c)\\(\\\\)*(?=[[:^print:]])/$1$2/g;
3087     return $str;
3088 }
3089
3090 sub balanced_delim {
3091     my($str) = @_;
3092     my @str = split //, $str;
3093     my($ar, $open, $close, $fail, $c, $cnt);
3094     for $ar (['[',']'], ['(',')'], ['<','>'], ['{','}']) {
3095         ($open, $close) = @$ar;
3096         $fail = 0; $cnt = 0;
3097         for $c (@str) {
3098             if ($c eq $open) {
3099                 $cnt++;
3100             } elsif ($c eq $close) {
3101                 $cnt--;
3102                 if ($cnt < 0) {
3103                     # qq()() isn't ")("
3104                     $fail = 1;
3105                     last;
3106                 }
3107             }
3108         }
3109         $fail = 1 if $cnt != 0;
3110         return ($open, "$open$str$close") if not $fail;
3111     }
3112     return ("", $str);
3113 }
3114
3115 sub single_delim {
3116     my($q, $default, $str) = @_;
3117     return "$default$str$default" if $default and index($str, $default) == -1;
3118     if ($q ne 'qr') {
3119         (my $succeed, $str) = balanced_delim($str);
3120         return "$q$str" if $succeed;
3121     }
3122     for my $delim ('/', '"', '#') {
3123         return "$q$delim" . $str . $delim if index($str, $delim) == -1;
3124     }
3125     if ($default) {
3126         $str =~ s/$default/\\$default/g;
3127         return "$default$str$default";
3128     } else {
3129         $str =~ s[/][\\/]g;
3130         return "$q/$str/";
3131     }
3132 }
3133
3134 sub const {
3135     my $sv = shift;
3136     if (class($sv) eq "SPECIAL") {
3137         return ('undef', '1', '0')[$$sv-1]; # sv_undef, sv_yes, sv_no
3138     } elsif (class($sv) eq "NULL") {
3139        return 'undef';
3140     } elsif ($sv->FLAGS & SVf_IOK) {
3141         return $sv->int_value;
3142     } elsif ($sv->FLAGS & SVf_NOK) {
3143         # try the default stringification
3144         my $r = "".$sv->NV;
3145         if ($r =~ /e/) {
3146             # If it's in scientific notation, we might have lost information
3147             return sprintf("%.20e", $sv->NV);
3148         }
3149         return $r;
3150     } elsif ($sv->FLAGS & SVf_ROK && $sv->can("RV")) {
3151         return "\\(" . const($sv->RV) . ")"; # constant folded
3152     } elsif ($sv->FLAGS & SVf_POK) {
3153         my $str = $sv->PV;
3154         if ($str =~ /[^ -~]/) { # ASCII for non-printing
3155             return single_delim("qq", '"', uninterp escape_str unback $str);
3156         } else {
3157             return single_delim("q", "'", unback $str);
3158         }
3159     } else {
3160         return "undef";
3161     }
3162 }
3163
3164 sub const_sv {
3165     my $self = shift;
3166     my $op = shift;
3167     my $sv = $op->sv;
3168     # the constant could be in the pad (under useithreads)
3169     $sv = $self->padval($op->targ) unless $$sv;
3170     return $sv;
3171 }
3172
3173 sub pp_const {
3174     my $self = shift;
3175     my($op, $cx) = @_;
3176     if ($op->private & OPpCONST_ARYBASE) {
3177         return '$[';
3178     }
3179 #    if ($op->private & OPpCONST_BARE) { # trouble with `=>' autoquoting 
3180 #       return $self->const_sv($op)->PV;
3181 #    }
3182     my $sv = $self->const_sv($op);
3183 #    return const($sv);
3184     my $c = const $sv; 
3185     return $c =~ /^-\d/ ? $self->maybe_parens($c, $cx, 21) : $c;
3186 }
3187
3188 sub dq {
3189     my $self = shift;
3190     my $op = shift;
3191     my $type = $op->name;
3192     if ($type eq "const") {
3193         return '$[' if $op->private & OPpCONST_ARYBASE;
3194         return uninterp(escape_str(unback($self->const_sv($op)->as_string)));
3195     } elsif ($type eq "concat") {
3196         my $first = $self->dq($op->first);
3197         my $last  = $self->dq($op->last);
3198
3199         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3200         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3201             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3202             || ($last =~ /^[{\[\w_]/ &&
3203                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3204
3205         return $first . $last;
3206     } elsif ($type eq "uc") {
3207         return '\U' . $self->dq($op->first->sibling) . '\E';
3208     } elsif ($type eq "lc") {
3209         return '\L' . $self->dq($op->first->sibling) . '\E';
3210     } elsif ($type eq "ucfirst") {
3211         return '\u' . $self->dq($op->first->sibling);
3212     } elsif ($type eq "lcfirst") {
3213         return '\l' . $self->dq($op->first->sibling);
3214     } elsif ($type eq "quotemeta") {
3215         return '\Q' . $self->dq($op->first->sibling) . '\E';
3216     } elsif ($type eq "join") {
3217         return $self->deparse($op->last, 26); # was join($", @ary)
3218     } else {
3219         return $self->deparse($op, 26);
3220     }
3221 }
3222
3223 sub pp_backtick {
3224     my $self = shift;
3225     my($op, $cx) = @_;
3226     # skip pushmark
3227     return single_delim("qx", '`', $self->dq($op->first->sibling));
3228 }
3229
3230 sub dquote {
3231     my $self = shift;
3232     my($op, $cx) = @_;
3233     my $kid = $op->first->sibling; # skip ex-stringify, pushmark
3234     return $self->deparse($kid, $cx) if $self->{'unquote'};
3235     $self->maybe_targmy($kid, $cx,
3236                         sub {single_delim("qq", '"', $self->dq($_[1]))});
3237 }
3238
3239 # OP_STRINGIFY is a listop, but it only ever has one arg
3240 sub pp_stringify { maybe_targmy(@_, \&dquote) }
3241
3242 # tr/// and s/// (and tr[][], tr[]//, tr###, etc)
3243 # note that tr(from)/to/ is OK, but not tr/from/(to)
3244 sub double_delim {
3245     my($from, $to) = @_;
3246     my($succeed, $delim);
3247     if ($from !~ m[/] and $to !~ m[/]) {
3248         return "/$from/$to/";
3249     } elsif (($succeed, $from) = balanced_delim($from) and $succeed) {
3250         if (($succeed, $to) = balanced_delim($to) and $succeed) {
3251             return "$from$to";
3252         } else {
3253             for $delim ('/', '"', '#') { # note no `'' -- s''' is special
3254                 return "$from$delim$to$delim" if index($to, $delim) == -1;
3255             }
3256             $to =~ s[/][\\/]g;
3257             return "$from/$to/";
3258         }
3259     } else {
3260         for $delim ('/', '"', '#') { # note no '
3261             return "$delim$from$delim$to$delim"
3262                 if index($to . $from, $delim) == -1;
3263         }
3264         $from =~ s[/][\\/]g;
3265         $to =~ s[/][\\/]g;
3266         return "/$from/$to/";   
3267     }
3268 }
3269
3270 # Only used by tr///, so backslashes hyphens
3271 sub pchr { # ASCII
3272     my($n) = @_;
3273     if ($n == ord '\\') {
3274         return '\\\\';
3275     } elsif ($n == ord "-") {
3276         return "\\-";
3277     } elsif ($n >= ord(' ') and $n <= ord('~')) {
3278         return chr($n);
3279     } elsif ($n == ord "\a") {
3280         return '\\a';
3281     } elsif ($n == ord "\b") {
3282         return '\\b';
3283     } elsif ($n == ord "\t") {
3284         return '\\t';
3285     } elsif ($n == ord "\n") {
3286         return '\\n';
3287     } elsif ($n == ord "\e") {
3288         return '\\e';
3289     } elsif ($n == ord "\f") {
3290         return '\\f';
3291     } elsif ($n == ord "\r") {
3292         return '\\r';
3293     } elsif ($n >= ord("\cA") and $n <= ord("\cZ")) {
3294         return '\\c' . chr(ord("@") + $n);
3295     } else {
3296 #       return '\x' . sprintf("%02x", $n);
3297         return '\\' . sprintf("%03o", $n);
3298     }
3299 }
3300
3301 sub collapse {
3302     my(@chars) = @_;
3303     my($str, $c, $tr) = ("");
3304     for ($c = 0; $c < @chars; $c++) {
3305         $tr = $chars[$c];
3306         $str .= pchr($tr);
3307         if ($c <= $#chars - 2 and $chars[$c + 1] == $tr + 1 and
3308             $chars[$c + 2] == $tr + 2)
3309         {
3310             for (; $c <= $#chars-1 and $chars[$c + 1] == $chars[$c] + 1; $c++)
3311               {}
3312             $str .= "-";
3313             $str .= pchr($chars[$c]);
3314         }
3315     }
3316     return $str;
3317 }
3318
3319 sub tr_decode_byte {
3320     my($table, $flags) = @_;
3321     my(@table) = unpack("s*", $table);
3322     splice @table, 0x100, 1;   # Number of subsequent elements
3323     my($c, $tr, @from, @to, @delfrom, $delhyphen);
3324     if ($table[ord "-"] != -1 and 
3325         $table[ord("-") - 1] == -1 || $table[ord("-") + 1] == -1)
3326     {
3327         $tr = $table[ord "-"];
3328         $table[ord "-"] = -1;
3329         if ($tr >= 0) {
3330             @from = ord("-");
3331             @to = $tr;
3332         } else { # -2 ==> delete
3333             $delhyphen = 1;
3334         }
3335     }
3336     for ($c = 0; $c < @table; $c++) {
3337         $tr = $table[$c];
3338         if ($tr >= 0) {
3339             push @from, $c; push @to, $tr;
3340         } elsif ($tr == -2) {
3341             push @delfrom, $c;
3342         }
3343     }
3344     @from = (@from, @delfrom);
3345     if ($flags & OPpTRANS_COMPLEMENT) {
3346         my @newfrom = ();
3347         my %from;
3348         @from{@from} = (1) x @from;
3349         for ($c = 0; $c < 256; $c++) {
3350             push @newfrom, $c unless $from{$c};
3351         }
3352         @from = @newfrom;
3353     }
3354     unless ($flags & OPpTRANS_DELETE || !@to) {
3355         pop @to while $#to and $to[$#to] == $to[$#to -1];
3356     }
3357     my($from, $to);
3358     $from = collapse(@from);
3359     $to = collapse(@to);
3360     $from .= "-" if $delhyphen;
3361     return ($from, $to);
3362 }
3363
3364 sub tr_chr {
3365     my $x = shift;
3366     if ($x == ord "-") {
3367         return "\\-";
3368     } elsif ($x == ord "\\") {
3369         return "\\\\";
3370     } else {
3371         return chr $x;
3372     }
3373 }
3374
3375 # XXX This doesn't yet handle all cases correctly either
3376
3377 sub tr_decode_utf8 {
3378     my($swash_hv, $flags) = @_;
3379     my %swash = $swash_hv->ARRAY;
3380     my $final = undef;
3381     $final = $swash{'FINAL'}->IV if exists $swash{'FINAL'};
3382     my $none = $swash{"NONE"}->IV;
3383     my $extra = $none + 1;
3384     my(@from, @delfrom, @to);
3385     my $line;
3386     foreach $line (split /\n/, $swash{'LIST'}->PV) {
3387         my($min, $max, $result) = split(/\t/, $line);
3388         $min = hex $min;
3389         if (length $max) {
3390             $max = hex $max;
3391         } else {
3392             $max = $min;
3393         }
3394         $result = hex $result;
3395         if ($result == $extra) {
3396             push @delfrom, [$min, $max];            
3397         } else {
3398             push @from, [$min, $max];
3399             push @to, [$result, $result + $max - $min];
3400         }
3401     }
3402     for my $i (0 .. $#from) {
3403         if ($from[$i][0] == ord '-') {
3404             unshift @from, splice(@from, $i, 1);
3405             unshift @to, splice(@to, $i, 1);
3406             last;
3407         } elsif ($from[$i][1] == ord '-') {
3408             $from[$i][1]--;
3409             $to[$i][1]--;
3410             unshift @from, ord '-';
3411             unshift @to, ord '-';
3412             last;
3413         }
3414     }
3415     for my $i (0 .. $#delfrom) {
3416         if ($delfrom[$i][0] == ord '-') {
3417             push @delfrom, splice(@delfrom, $i, 1);
3418             last;
3419         } elsif ($delfrom[$i][1] == ord '-') {
3420             $delfrom[$i][1]--;
3421             push @delfrom, ord '-';
3422             last;
3423         }
3424     }
3425     if (defined $final and $to[$#to][1] != $final) {
3426         push @to, [$final, $final];
3427     }
3428     push @from, @delfrom;
3429     if ($flags & OPpTRANS_COMPLEMENT) {
3430         my @newfrom;
3431         my $next = 0;
3432         for my $i (0 .. $#from) {
3433             push @newfrom, [$next, $from[$i][0] - 1];
3434             $next = $from[$i][1] + 1;
3435         }
3436         @from = ();
3437         for my $range (@newfrom) {
3438             if ($range->[0] <= $range->[1]) {
3439                 push @from, $range;
3440             }
3441         }
3442     }
3443     my($from, $to, $diff);
3444     for my $chunk (@from) {
3445         $diff = $chunk->[1] - $chunk->[0];
3446         if ($diff > 1) {
3447             $from .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3448         } elsif ($diff == 1) {
3449             $from .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3450         } else {
3451             $from .= tr_chr($chunk->[0]);
3452         }
3453     }
3454     for my $chunk (@to) {
3455         $diff = $chunk->[1] - $chunk->[0];
3456         if ($diff > 1) {
3457             $to .= tr_chr($chunk->[0]) . "-" . tr_chr($chunk->[1]);
3458         } elsif ($diff == 1) {
3459             $to .= tr_chr($chunk->[0]) . tr_chr($chunk->[1]);
3460         } else {
3461             $to .= tr_chr($chunk->[0]);
3462         }
3463     }
3464     #$final = sprintf("%04x", $final) if defined $final;
3465     #$none = sprintf("%04x", $none) if defined $none;
3466     #$extra = sprintf("%04x", $extra) if defined $extra;    
3467     #print STDERR "final: $final\n none: $none\nextra: $extra\n";
3468     #print STDERR $swash{'LIST'}->PV;
3469     return (escape_str($from), escape_str($to));
3470 }
3471
3472 sub pp_trans {
3473     my $self = shift;
3474     my($op, $cx) = @_;
3475     my($from, $to);
3476     if (class($op) eq "PVOP") {
3477         ($from, $to) = tr_decode_byte($op->pv, $op->private);
3478     } else { # class($op) eq "SVOP"
3479         ($from, $to) = tr_decode_utf8($op->sv->RV, $op->private);
3480     }
3481     my $flags = "";
3482     $flags .= "c" if $op->private & OPpTRANS_COMPLEMENT;
3483     $flags .= "d" if $op->private & OPpTRANS_DELETE;
3484     $to = "" if $from eq $to and $flags eq "";
3485     $flags .= "s" if $op->private & OPpTRANS_SQUASH;
3486     return "tr" . double_delim($from, $to) . $flags;
3487 }
3488
3489 # Like dq(), but different
3490 sub re_dq {
3491     my $self = shift;
3492     my ($op, $extended) = @_;
3493
3494     my $type = $op->name;
3495     if ($type eq "const") {
3496         return '$[' if $op->private & OPpCONST_ARYBASE;
3497         my $unbacked = re_unback($self->const_sv($op)->as_string);
3498         return re_uninterp_extended(escape_extended_re($unbacked))
3499             if $extended;
3500         return re_uninterp(escape_str($unbacked));
3501     } elsif ($type eq "concat") {
3502         my $first = $self->re_dq($op->first, $extended);
3503         my $last  = $self->re_dq($op->last,  $extended);
3504
3505         # Disambiguate "${foo}bar", "${foo}{bar}", "${foo}[1]"
3506         ($last =~ /^[A-Z\\\^\[\]_?]/ &&
3507             $first =~ s/([\$@])\^$/${1}{^}/)  # "${^}W" etc
3508             || ($last =~ /^[{\[\w_]/ &&
3509                 $first =~ s/([\$@])([A-Za-z_]\w*)$/${1}{$2}/);
3510
3511         return $first . $last;
3512     } elsif ($type eq "uc") {
3513         return '\U' . $self->re_dq($op->first->sibling, $extended) . '\E';
3514     } elsif ($type eq "lc") {
3515         return '\L' . $self->re_dq($op->first->sibling, $extended) . '\E';
3516     } elsif ($type eq "ucfirst") {
3517         return '\u' . $self->re_dq($op->first->sibling, $extended);
3518     } elsif ($type eq "lcfirst") {
3519         return '\l' . $self->re_dq($op->first->sibling, $extended);
3520     } elsif ($type eq "quotemeta") {
3521         return '\Q' . $self->re_dq($op->first->sibling, $extended) . '\E';
3522     } elsif ($type eq "join") {
3523         return $self->deparse($op->last, 26); # was join($", @ary)
3524     } else {
3525         return $self->deparse($op, 26);
3526     }
3527 }
3528
3529 sub pure_string {
3530     my ($self, $op) = @_;
3531     my $type = $op->name;
3532
3533     if ($type eq 'const') {
3534         return 1;
3535     }
3536     elsif ($type =~ /^[ul]c(first)?$/ || $type eq 'quotemeta') {
3537         return $self->pure_string($op->first->sibling);
3538     }
3539     elsif ($type eq 'join') {
3540         my $join_op = $op->first->sibling;  # Skip pushmark
3541         return 0 unless $join_op->name eq 'null' && $join_op->targ eq OP_RV2SV;
3542
3543         my $gvop = $join_op->first;
3544         return 0 unless $gvop->name eq 'gvsv';
3545         return 0 unless '"' eq $self->gv_name($self->gv_or_padgv($gvop));
3546
3547         return 0 unless ${$join_op->sibling} eq ${$op->last};
3548         return 0 unless $op->last->name =~ /^(rv2|pad)av$/;
3549     }
3550     elsif ($type eq 'concat') {
3551         return $self->pure_string($op->first)
3552             && $self->pure_string($op->last);
3553     }
3554     elsif (is_scalar($op) || $type =~ /^[ah]elem(fast)?$/) {
3555         return 1;
3556     }
3557     else {
3558         return 0;
3559     }
3560
3561     return 1;
3562 }
3563
3564 sub regcomp {
3565     my $self = shift;
3566     my($op, $cx, $extended) = @_;
3567     my $kid = $op->first;
3568     $kid = $kid->first if $kid->name eq "regcmaybe";
3569     $kid = $kid->first if $kid->name eq "regcreset";
3570     return ($self->re_dq($kid, $extended), 1) if $self->pure_string($kid);
3571     return ($self->deparse($kid, $cx), 0);
3572 }
3573
3574 sub pp_regcomp {
3575     my ($self, $op, $cx) = @_;
3576     return (($self->regcomp($op, $cx, 0))[0]);
3577 }
3578
3579 # osmic acid -- see osmium tetroxide
3580
3581 my %matchwords;
3582 map($matchwords{join "", sort split //, $_} = $_, 'cig', 'cog', 'cos', 'cogs',
3583     'cox', 'go', 'is', 'ism', 'iso', 'mig', 'mix', 'osmic', 'ox', 'sic', 
3584     'sig', 'six', 'smog', 'so', 'soc', 'sog', 'xi'); 
3585
3586 sub matchop {
3587     my $self = shift;
3588     my($op, $cx, $name, $delim) = @_;
3589     my $kid = $op->first;
3590     my ($binop, $var, $re) = ("", "", "");
3591     if ($op->flags & OPf_STACKED) {
3592         $binop = 1;
3593         $var = $self->deparse($kid, 20);
3594         $kid = $kid->sibling;
3595     }
3596     my $quote = 1;
3597     my $extended = ($op->pmflags & PMf_EXTENDED);
3598     if (null $kid) {
3599         my $unbacked = re_unback($op->precomp);
3600         if ($extended) {
3601             $re = re_uninterp_extended(escape_extended_re($unbacked));
3602         } else {
3603             $re = re_uninterp(escape_str(re_unback($op->precomp)));
3604         }
3605     } elsif ($kid->name ne 'regcomp') {
3606         carp("found ".$kid->name." where regcomp expected");
3607     } else {
3608         ($re, $quote) = $self->regcomp($kid, 1, $extended);
3609     }
3610     my $flags = "";
3611     $flags .= "c" if $op->pmflags & PMf_CONTINUE;
3612     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3613     $flags .= "i" if $op->pmflags & PMf_FOLD;
3614     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3615     $flags .= "o" if $op->pmflags & PMf_KEEP;
3616     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3617     $flags .= "x" if $op->pmflags & PMf_EXTENDED;
3618     $flags = $matchwords{$flags} if $matchwords{$flags};
3619     if ($op->pmflags & PMf_ONCE) { # only one kind of delimiter works here
3620         $re =~ s/\?/\\?/g;
3621         $re = "?$re?";
3622     } elsif ($quote) {
3623         $re = single_delim($name, $delim, $re);
3624     }
3625     $re = $re . $flags if $quote;
3626     if ($binop) {
3627         return $self->maybe_parens("$var =~ $re", $cx, 20);
3628     } else {
3629         return $re;
3630     }
3631 }
3632
3633 sub pp_match { matchop(@_, "m", "/") }
3634 sub pp_pushre { matchop(@_, "m", "/") }
3635 sub pp_qr { matchop(@_, "qr", "") }
3636
3637 sub pp_split {
3638     my $self = shift;
3639     my($op, $cx) = @_;
3640     my($kid, @exprs, $ary, $expr);
3641     $kid = $op->first;
3642     # under ithreads pmreplroot is an integer, not an SV
3643     my $replroot = $kid->pmreplroot;
3644     if ( ( ref($replroot) && $$replroot ) ||
3645          ( !ref($replroot) && $replroot ) ) {
3646         $ary = $self->stash_variable('@', $self->gv_name($kid->pmreplroot));
3647     }
3648     for (; !null($kid); $kid = $kid->sibling) {
3649         push @exprs, $self->deparse($kid, 6);
3650     }
3651
3652     # handle special case of split(), and split(" ") that compiles to /\s+/
3653     $kid = $op->first;
3654     if ($kid->flags & OPf_SPECIAL
3655         && $exprs[0] eq '/\\s+/'
3656         && $kid->pmflags & PMf_SKIPWHITE ) {
3657             $exprs[0] = '" "';
3658     }
3659
3660     $expr = "split(" . join(", ", @exprs) . ")";
3661     if ($ary) {
3662         return $self->maybe_parens("$ary = $expr", $cx, 7);
3663     } else {
3664         return $expr;
3665     }
3666 }
3667
3668 # oxime -- any of various compounds obtained chiefly by the action of
3669 # hydroxylamine on aldehydes and ketones and characterized by the
3670 # bivalent grouping C=NOH [Webster's Tenth]
3671
3672 my %substwords;
3673 map($substwords{join "", sort split //, $_} = $_, 'ego', 'egoism', 'em',
3674     'es', 'ex', 'exes', 'gee', 'go', 'goes', 'ie', 'ism', 'iso', 'me',
3675     'meese', 'meso', 'mig', 'mix', 'os', 'ox', 'oxime', 'see', 'seem',
3676     'seg', 'sex', 'sig', 'six', 'smog', 'sog', 'some', 'xi');
3677
3678 sub pp_subst {
3679     my $self = shift;
3680     my($op, $cx) = @_;
3681     my $kid = $op->first;
3682     my($binop, $var, $re, $repl) = ("", "", "", "");
3683     if ($op->flags & OPf_STACKED) {
3684         $binop = 1;
3685         $var = $self->deparse($kid, 20);
3686         $kid = $kid->sibling;
3687     }
3688     my $flags = "";    
3689     if (null($op->pmreplroot)) {
3690         $repl = $self->dq($kid);
3691         $kid = $kid->sibling;
3692     } else {
3693         $repl = $op->pmreplroot->first; # skip substcont
3694         while ($repl->name eq "entereval") {
3695             $repl = $repl->first;
3696             $flags .= "e";
3697         }
3698         if ($op->pmflags & PMf_EVAL) {
3699             $repl = $self->deparse($repl, 0);
3700         } else {
3701             $repl = $self->dq($repl);   
3702         }
3703     }
3704     my $extended = ($op->pmflags & PMf_EXTENDED);
3705     if (null $kid) {
3706         my $unbacked = re_unback($op->precomp);
3707         if ($extended) {
3708             $re = re_uninterp_extended(escape_extended_re($unbacked));
3709         }
3710         else {
3711             $re = re_uninterp(escape_str($unbacked));
3712         }
3713     } else {
3714         ($re) = $self->regcomp($kid, 1, $extended);
3715     }
3716     $flags .= "e" if $op->pmflags & PMf_EVAL;
3717     $flags .= "g" if $op->pmflags & PMf_GLOBAL;
3718     $flags .= "i" if $op->pmflags & PMf_FOLD;
3719     $flags .= "m" if $op->pmflags & PMf_MULTILINE;
3720     $flags .= "o" if $op->pmflags & PMf_KEEP;
3721     $flags .= "s" if $op->pmflags & PMf_SINGLELINE;
3722     $flags .= "x" if $extended;
3723     $flags = $substwords{$flags} if $substwords{$flags};
3724     if ($binop) {
3725         return $self->maybe_parens("$var =~ s"
3726                                    . double_delim($re, $repl) . $flags,
3727                                    $cx, 20);
3728     } else {
3729         return "s". double_delim($re, $repl) . $flags;  
3730     }
3731 }
3732
3733 1;
3734 __END__
3735
3736 =head1 NAME
3737
3738 B::Deparse - Perl compiler backend to produce perl code
3739
3740 =head1 SYNOPSIS
3741
3742 B<perl> B<-MO=Deparse>[B<,-u>I<PACKAGE>][B<,-p>][B<,-q>][B<,-l>]
3743         [B<,-s>I<LETTERS>][B<,-x>I<LEVEL>] I<prog.pl>
3744
3745 =head1 DESCRIPTION
3746
3747 B::Deparse is a backend module for the Perl compiler that generates
3748 perl source code, based on the internal compiled structure that perl
3749 itself creates after parsing a program. The output of B::Deparse won't
3750 be exactly the same as the original source, since perl doesn't keep
3751 track of comments or whitespace, and there isn't a one-to-one
3752 correspondence between perl's syntactical constructions and their
3753 compiled form, but it will often be close. When you use the B<-p>
3754 option, the output also includes parentheses even when they are not
3755 required by precedence, which can make it easy to see if perl is
3756 parsing your expressions the way you intended.
3757
3758 Please note that this module is mainly new and untested code and is
3759 still under development, so it may change in the future.
3760
3761 =head1 OPTIONS
3762
3763 As with all compiler backend options, these must follow directly after
3764 the '-MO=Deparse', separated by a comma but not any white space.
3765
3766 =over 4
3767
3768 =item B<-l>
3769
3770 Add '#line' declarations to the output based on the line and file
3771 locations of the original code.
3772
3773 =item B<-p>
3774
3775 Print extra parentheses. Without this option, B::Deparse includes
3776 parentheses in its output only when they are needed, based on the
3777 structure of your program. With B<-p>, it uses parentheses (almost)
3778 whenever they would be legal. This can be useful if you are used to
3779 LISP, or if you want to see how perl parses your input. If you say
3780
3781     if ($var & 0x7f == 65) {print "Gimme an A!"} 
3782     print ($which ? $a : $b), "\n";
3783     $name = $ENV{USER} or "Bob";
3784
3785 C<B::Deparse,-p> will print
3786
3787     if (($var & 0)) {
3788         print('Gimme an A!')
3789     };
3790     (print(($which ? $a : $b)), '???');
3791     (($name = $ENV{'USER'}) or '???')
3792
3793 which probably isn't what you intended (the C<'???'> is a sign that
3794 perl optimized away a constant value).
3795
3796 =item B<-P>
3797
3798 Disable prototype checking. With this option, all function calls are
3799 deparsed as if no prototype was defined for them. In other words,
3800
3801     perl -MO=Deparse,-P -e 'sub foo (\@) { 1 } foo @x'
3802
3803 will print
3804
3805     sub foo (\@) {
3806         1;
3807     }
3808     &foo(\@x);
3809
3810 making clear how the parameters are actually passed to C<foo>.
3811
3812 =item B<-q>
3813
3814 Expand double-quoted strings into the corresponding combinations of
3815 concatenation, uc, ucfirst, lc, lcfirst, quotemeta, and join. For
3816 instance, print
3817
3818     print "Hello, $world, @ladies, \u$gentlemen\E, \u\L$me!";
3819
3820 as
3821
3822     print 'Hello, ' . $world . ', ' . join($", @ladies) . ', '
3823           . ucfirst($gentlemen) . ', ' . ucfirst(lc $me . '!');
3824
3825 Note that the expanded form represents the way perl handles such
3826 constructions internally -- this option actually turns off the reverse
3827 translation that B::Deparse usually does. On the other hand, note that
3828 C<$x = "$y"> is not the same as C<$x = $y>: the former makes the value
3829 of $y into a string before doing the assignment.
3830
3831 =item B<-f>I<FILE>
3832
3833 Normally, B::Deparse deparses the main code of a program, and all the subs
3834 defined in the same file. To include subs defined in other files, pass the
3835 B<-f> option with the filename. You can pass the B<-f> option several times, to
3836 include more than one secondary file.  (Most of the time you don't want to
3837 use it at all.)  You can also use this option to include subs which are
3838 defined in the scope of a B<#line> directive with two parameters.
3839
3840 =item B<-s>I<LETTERS>
3841
3842 Tweak the style of B::Deparse's output. The letters should follow
3843 directly after the 's', with no space or punctuation. The following
3844 options are available:
3845
3846 =over 4
3847
3848 =item B<C>
3849
3850 Cuddle C<elsif>, C<else>, and C<continue> blocks. For example, print
3851
3852     if (...) {
3853          ...
3854     } else {
3855          ...
3856     }
3857
3858 instead of
3859
3860     if (...) {
3861          ...
3862     }
3863     else {
3864          ...
3865     }
3866
3867 The default is not to cuddle.
3868
3869 =item B<i>I<NUMBER>
3870
3871 Indent lines by multiples of I<NUMBER> columns. The default is 4 columns.
3872
3873 =item B<T>
3874
3875 Use tabs for each 8 columns of indent. The default is to use only spaces.
3876 For instance, if the style options are B<-si4T>, a line that's indented
3877 3 times will be preceded by one tab and four spaces; if the options were
3878 B<-si8T>, the same line would be preceded by three tabs.
3879
3880 =item B<v>I<STRING>B<.>
3881
3882 Print I<STRING> for the value of a constant that can't be determined
3883 because it was optimized away (mnemonic: this happens when a constant
3884 is used in B<v>oid context). The end of the string is marked by a period.
3885 The string should be a valid perl expression, generally a constant.
3886 Note that unless it's a number, it probably needs to be quoted, and on
3887 a command line quotes need to be protected from the shell. Some
3888 conventional values include 0, 1, 42, '', 'foo', and
3889 'Useless use of constant omitted' (which may need to be
3890 B<-sv"'Useless use of constant omitted'.">
3891 or something similar depending on your shell). The default is '???'.
3892 If you're using B::Deparse on a module or other file that's require'd,
3893 you shouldn't use a value that evaluates to false, since the customary
3894 true constant at the end of a module will be in void context when the
3895 file is compiled as a main program.
3896
3897 =back
3898
3899 =item B<-x>I<LEVEL>
3900
3901 Expand conventional syntax constructions into equivalent ones that expose
3902 their internal operation. I<LEVEL> should be a digit, with higher values
3903 meaning more expansion. As with B<-q>, this actually involves turning off
3904 special cases in B::Deparse's normal operations.
3905
3906 If I<LEVEL> is at least 3, for loops will be translated into equivalent
3907 while loops with continue blocks; for instance
3908
3909     for ($i = 0; $i < 10; ++$i) {
3910         print $i;
3911     }
3912
3913 turns into
3914
3915     $i = 0;
3916     while ($i < 10) {
3917         print $i;
3918     } continue {
3919         ++$i
3920     }
3921
3922 Note that in a few cases this translation can't be perfectly carried back
3923 into the source code -- if the loop's initializer declares a my variable,
3924 for instance, it won't have the correct scope outside of the loop.
3925
3926 If I<LEVEL> is at least 7, if statements will be translated into equivalent
3927 expressions using C<&&>, C<?:> and C<do {}>; for instance
3928
3929     print 'hi' if $nice;
3930     if ($nice) {
3931         print 'hi';
3932     }
3933     if ($nice) {
3934         print 'hi';
3935     } else {
3936         print 'bye';
3937     }
3938
3939 turns into
3940
3941     $nice and print 'hi';
3942     $nice and do { print 'hi' };
3943     $nice ? do { print 'hi' } : do { print 'bye' };
3944
3945 Long sequences of elsifs will turn into nested ternary operators, which
3946 B::Deparse doesn't know how to indent nicely.
3947
3948 =back
3949
3950 =head1 USING B::Deparse AS A MODULE
3951
3952 =head2 Synopsis
3953
3954     use B::Deparse;
3955     $deparse = B::Deparse->new("-p", "-sC");
3956     $body = $deparse->coderef2text(\&func);
3957     eval "sub func $body"; # the inverse operation
3958
3959 =head2 Description
3960
3961 B::Deparse can also be used on a sub-by-sub basis from other perl
3962 programs.
3963
3964 =head2 new
3965
3966     $deparse = B::Deparse->new(OPTIONS)
3967
3968 Create an object to store the state of a deparsing operation and any
3969 options. The options are the same as those that can be given on the
3970 command line (see L</OPTIONS>); options that are separated by commas
3971 after B<-MO=Deparse> should be given as separate strings. Some
3972 options, like B<-u>, don't make sense for a single subroutine, so
3973 don't pass them.
3974
3975 =head2 ambient_pragmas
3976
3977     $deparse->ambient_pragmas(strict => 'all', '$[' => $[);
3978
3979 The compilation of a subroutine can be affected by a few compiler
3980 directives, B<pragmas>. These are:
3981
3982 =over 4
3983
3984 =item *
3985
3986 use strict;
3987
3988 =item *
3989
3990 use warnings;
3991
3992 =item *
3993
3994 Assigning to the special variable $[
3995
3996 =item *
3997
3998 use integer;
3999
4000 =item *
4001
4002 use bytes;
4003
4004 =item *
4005
4006 use utf8;
4007
4008 =item *
4009
4010 use re;
4011
4012 =back
4013
4014 Ordinarily, if you use B::Deparse on a subroutine which has
4015 been compiled in the presence of one or more of these pragmas,
4016 the output will include statements to turn on the appropriate
4017 directives. So if you then compile the code returned by coderef2text, 
4018 it will behave the same way as the subroutine which you deparsed.
4019
4020 However, you may know that you intend to use the results in a
4021 particular context, where some pragmas are already in scope. In
4022 this case, you use the B<ambient_pragmas> method to describe the
4023 assumptions you wish to make.
4024
4025 Not all of the options currently have any useful effect. See
4026 L</BUGS> for more details.
4027
4028 The parameters it accepts are:
4029
4030 =over 4
4031
4032 =item strict
4033
4034 Takes a string, possibly containing several values separated
4035 by whitespace. The special values "all" and "none" mean what you'd
4036 expect.
4037
4038     $deparse->ambient_pragmas(strict => 'subs refs');
4039
4040 =item $[
4041
4042 Takes a number, the value of the array base $[.
4043
4044 =item bytes
4045
4046 =item utf8
4047
4048 =item integer
4049
4050 If the value is true, then the appropriate pragma is assumed to
4051 be in the ambient scope, otherwise not.
4052
4053 =item re
4054
4055 Takes a string, possibly containing a whitespace-separated list of
4056 values. The values "all" and "none" are special. It's also permissible
4057 to pass an array reference here.
4058
4059     $deparser->ambient_pragmas(re => 'eval');
4060
4061
4062 =item warnings
4063
4064 Takes a string, possibly containing a whitespace-separated list of
4065 values. The values "all" and "none" are special, again. It's also
4066 permissible to pass an array reference here.
4067
4068     $deparser->ambient_pragmas(warnings => [qw[void io]]);
4069
4070 If one of the values is the string "FATAL", then all the warnings
4071 in that list will be considered fatal, just as with the B<warnings>
4072 pragma itself. Should you need to specify that some warnings are
4073 fatal, and others are merely enabled, you can pass the B<warnings>
4074 parameter twice:
4075
4076     $deparser->ambient_pragmas(
4077         warnings => 'all',
4078         warnings => [FATAL => qw/void io/],
4079     );
4080
4081 See L<perllexwarn> for more information about lexical warnings. 
4082
4083 =item hint_bits
4084
4085 =item warning_bits
4086
4087 These two parameters are used to specify the ambient pragmas in
4088 the format used by the special variables $^H and ${^WARNING_BITS}.
4089
4090 They exist principally so that you can write code like:
4091
4092     { my ($hint_bits, $warning_bits);
4093     BEGIN {($hint_bits, $warning_bits) = ($^H, ${^WARNING_BITS})}
4094     $deparser->ambient_pragmas (
4095         hint_bits    => $hint_bits,
4096         warning_bits => $warning_bits,
4097         '$['         => 0 + $[
4098     ); }
4099
4100 which specifies that the ambient pragmas are exactly those which
4101 are in scope at the point of calling.
4102
4103 =back
4104
4105 =head2 coderef2text
4106
4107     $body = $deparse->coderef2text(\&func)
4108     $body = $deparse->coderef2text(sub ($$) { ... })
4109
4110 Return source code for the body of a subroutine (a block, optionally
4111 preceded by a prototype in parens), given a reference to the
4112 sub. Because a subroutine can have no names, or more than one name,
4113 this method doesn't return a complete subroutine definition -- if you
4114 want to eval the result, you should prepend "sub subname ", or "sub "
4115 for an anonymous function constructor. Unless the sub was defined in
4116 the main:: package, the code will include a package declaration.
4117
4118 =head1 BUGS
4119
4120 =over 4
4121
4122 =item *
4123
4124 The only pragmas to be completely supported are: C<use warnings>,
4125 C<use strict 'refs'>, C<use bytes>, and C<use integer>. (C<$[>, which
4126 behaves like a pragma, is also supported.)
4127
4128 Excepting those listed above, we're currently unable to guarantee that
4129 B::Deparse will produce a pragma at the correct point in the program.
4130 Since the effects of pragmas are often lexically scoped, this can mean
4131 that the pragma holds sway over a different portion of the program
4132 than in the input file.
4133
4134 =item *
4135
4136 In fact, the above is a specific instance of a more general problem:
4137 we can't guarantee to produce BEGIN blocks or C<use> declarations in
4138 exactly the right place. So if you use a module which affects compilation
4139 (such as by over-riding keywords, overloading constants or whatever)
4140 then the output code might not work as intended.
4141
4142 This is the most serious outstanding problem, and will be very hard
4143 to fix.
4144
4145 =item *
4146
4147 If a keyword is over-ridden, and your program explicitly calls
4148 the built-in version by using CORE::keyword, the output of B::Deparse
4149 will not reflect this. If you run the resulting code, it will call
4150 the over-ridden version rather than the built-in one. (Maybe there
4151 should be an option to B<always> print keyword calls as C<CORE::name>.)
4152
4153 =item *
4154
4155 C<sort foo (1, 2, 3)> comes out as C<sort (foo 1, 2, 3)>, which
4156 causes perl to issue a warning.
4157
4158 The obvious fix doesn't work, because these are different:
4159
4160     print (FOO 1, 2, 3), 4, 5, 6;
4161     print FOO (1, 2, 3), 4, 5, 6;
4162
4163 =item *
4164
4165 Constants (other than simple strings or numbers) don't work properly.
4166 Pathological examples that fail (and probably always will) include:
4167
4168     use constant E2BIG => ($!=7);
4169     use constant x=>\$x; print x
4170
4171 The following could (and should) be made to work:
4172
4173     use constant regex => qr/blah/;
4174     print regex;
4175
4176 =item *
4177
4178 An input file that uses source filtering probably won't be deparsed into
4179 runnable code, because it will still include the B<use> declaration
4180 for the source filtering module, even though the code that is
4181 produced is already ordinary Perl which shouldn't be filtered again.
4182
4183 =item *
4184
4185 There are probably many more bugs on non-ASCII platforms (EBCDIC).
4186
4187 =back
4188
4189 =head1 AUTHOR
4190
4191 Stephen McCamant <smcc@CSUA.Berkeley.EDU>, based on an earlier
4192 version by Malcolm Beattie <mbeattie@sable.ox.ac.uk>, with
4193 contributions from Gisle Aas, James Duncan, Albert Dvornik, Robin
4194 Houston, Hugo van der Sanden, Gurusamy Sarathy, Nick Ing-Simmons,
4195 and Rafael Garcia-Suarez.
4196
4197 =cut