This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
60df0cb23ea257df2ce9c6d372d4e8dc91114ab4
[perl5.git] / pod / perltie.pod
1 =head1 NAME
2
3 perltie - how to hide an object class in a simple variable
4
5 =head1 SYNOPSIS
6
7  tie VARIABLE, CLASSNAME, LIST
8
9  $object = tied VARIABLE
10
11  untie VARIABLE
12
13 =head1 DESCRIPTION
14
15 Prior to release 5.0 of Perl, a programmer could use dbmopen()
16 to connect an on-disk database in the standard Unix dbm(3x)
17 format magically to a %HASH in their program.  However, their Perl was either
18 built with one particular dbm library or another, but not both, and
19 you couldn't extend this mechanism to other packages or types of variables.
20
21 Now you can.
22
23 The tie() function binds a variable to a class (package) that will provide
24 the implementation for access methods for that variable.  Once this magic
25 has been performed, accessing a tied variable automatically triggers
26 method calls in the proper class.  The complexity of the class is
27 hidden behind magic methods calls.  The method names are in ALL CAPS,
28 which is a convention that Perl uses to indicate that they're called
29 implicitly rather than explicitly--just like the BEGIN() and END()
30 functions.
31
32 In the tie() call, C<VARIABLE> is the name of the variable to be
33 enchanted.  C<CLASSNAME> is the name of a class implementing objects of
34 the correct type.  Any additional arguments in the C<LIST> are passed to
35 the appropriate constructor method for that class--meaning TIESCALAR(),
36 TIEARRAY(), TIEHASH(), or TIEHANDLE().  (Typically these are arguments
37 such as might be passed to the dbminit() function of C.) The object
38 returned by the "new" method is also returned by the tie() function,
39 which would be useful if you wanted to access other methods in
40 C<CLASSNAME>. (You don't actually have to return a reference to a right
41 "type" (e.g., HASH or C<CLASSNAME>) so long as it's a properly blessed
42 object.)  You can also retrieve a reference to the underlying object
43 using the tied() function.
44
45 Unlike dbmopen(), the tie() function will not C<use> or C<require> a module
46 for you--you need to do that explicitly yourself.
47
48 =head2 Tying Scalars
49
50 A class implementing a tied scalar should define the following methods:
51 TIESCALAR, FETCH, STORE, and possibly UNTIE and/or DESTROY.
52
53 Let's look at each in turn, using as an example a tie class for
54 scalars that allows the user to do something like:
55
56     tie $his_speed, 'Nice', getppid();
57     tie $my_speed,  'Nice', $$;
58
59 And now whenever either of those variables is accessed, its current
60 system priority is retrieved and returned.  If those variables are set,
61 then the process's priority is changed!
62
63 We'll use Jarkko Hietaniemi <F<jhi@iki.fi>>'s BSD::Resource class (not
64 included) to access the PRIO_PROCESS, PRIO_MIN, and PRIO_MAX constants
65 from your system, as well as the getpriority() and setpriority() system
66 calls.  Here's the preamble of the class.
67
68     package Nice;
69     use Carp;
70     use BSD::Resource;
71     use strict;
72     $Nice::DEBUG = 0 unless defined $Nice::DEBUG;
73
74 =over
75
76 =item TIESCALAR classname, LIST
77
78 This is the constructor for the class.  That means it is
79 expected to return a blessed reference to a new scalar
80 (probably anonymous) that it's creating.  For example:
81
82     sub TIESCALAR {
83         my $class = shift;
84         my $pid = shift || $$; # 0 means me
85
86         if ($pid !~ /^\d+$/) {
87             carp "Nice::Tie::Scalar got non-numeric pid $pid" if $^W;
88             return undef;
89         }
90
91         unless (kill 0, $pid) { # EPERM or ERSCH, no doubt
92             carp "Nice::Tie::Scalar got bad pid $pid: $!" if $^W;
93             return undef;
94         }
95
96         return bless \$pid, $class;
97     }
98
99 This tie class has chosen to return an error rather than raising an
100 exception if its constructor should fail.  While this is how dbmopen() works,
101 other classes may well not wish to be so forgiving.  It checks the global
102 variable C<$^W> to see whether to emit a bit of noise anyway.
103
104 =item FETCH this
105
106 This method will be triggered every time the tied variable is accessed
107 (read).  It takes no arguments beyond its self reference, which is the
108 object representing the scalar we're dealing with.  Because in this case
109 we're using just a SCALAR ref for the tied scalar object, a simple $$self
110 allows the method to get at the real value stored there.  In our example
111 below, that real value is the process ID to which we've tied our variable.
112
113     sub FETCH {
114         my $self = shift;
115         confess "wrong type" unless ref $self;
116         croak "usage error" if @_;
117         my $nicety;
118         local($!) = 0;
119         $nicety = getpriority(PRIO_PROCESS, $$self);
120         if ($!) { croak "getpriority failed: $!" }
121         return $nicety;
122     }
123
124 This time we've decided to blow up (raise an exception) if the renice
125 fails--there's no place for us to return an error otherwise, and it's
126 probably the right thing to do.
127
128 =item STORE this, value
129
130 This method will be triggered every time the tied variable is set
131 (assigned).  Beyond its self reference, it also expects one (and only one)
132 argument--the new value the user is trying to assign.
133
134     sub STORE {
135         my $self = shift;
136         confess "wrong type" unless ref $self;
137         my $new_nicety = shift;
138         croak "usage error" if @_;
139
140         if ($new_nicety < PRIO_MIN) {
141             carp sprintf
142               "WARNING: priority %d less than minimum system priority %d",
143                   $new_nicety, PRIO_MIN if $^W;
144             $new_nicety = PRIO_MIN;
145         }
146
147         if ($new_nicety > PRIO_MAX) {
148             carp sprintf
149               "WARNING: priority %d greater than maximum system priority %d",
150                   $new_nicety, PRIO_MAX if $^W;
151             $new_nicety = PRIO_MAX;
152         }
153
154         unless (defined setpriority(PRIO_PROCESS, $$self, $new_nicety)) {
155             confess "setpriority failed: $!";
156         }
157         return $new_nicety;
158     }
159
160 =item UNTIE this
161
162 This method will be triggered when the C<untie> occurs. This can be useful
163 if the class needs to know when no further calls will be made. (Except DESTROY
164 of course.) See below for more details.
165
166 =item DESTROY this
167
168 This method will be triggered when the tied variable needs to be destructed.
169 As with other object classes, such a method is seldom necessary, because Perl
170 deallocates its moribund object's memory for you automatically--this isn't
171 C++, you know.  We'll use a DESTROY method here for debugging purposes only.
172
173     sub DESTROY {
174         my $self = shift;
175         confess "wrong type" unless ref $self;
176         carp "[ Nice::DESTROY pid $$self ]" if $Nice::DEBUG;
177     }
178
179 =back
180
181 That's about all there is to it.  Actually, it's more than all there
182 is to it, because we've done a few nice things here for the sake
183 of completeness, robustness, and general aesthetics.  Simpler
184 TIESCALAR classes are certainly possible.
185
186 =head2 Tying Arrays
187
188 A class implementing a tied ordinary array should define the following
189 methods: TIEARRAY, FETCH, STORE, FETCHSIZE, STORESIZE and perhaps UNTIE and/or DESTROY.
190
191 FETCHSIZE and STORESIZE are used to provide C<$#array> and
192 equivalent C<scalar(@array)> access.
193
194 The methods POP, PUSH, SHIFT, UNSHIFT, SPLICE, DELETE, and EXISTS are
195 required if the perl operator with the corresponding (but lowercase) name
196 is to operate on the tied array. The B<Tie::Array> class can be used as a
197 base class to implement the first five of these in terms of the basic
198 methods above.  The default implementations of DELETE and EXISTS in
199 B<Tie::Array> simply C<croak>.
200
201 In addition EXTEND will be called when perl would have pre-extended
202 allocation in a real array.
203
204 This means that tied arrays are now I<complete>. The example below needs
205 upgrading to illustrate this. (The documentation in B<Tie::Array> is more
206 complete.)
207
208 For this discussion, we'll implement an array whose indices are fixed at
209 its creation.  If you try to access anything beyond those bounds, you'll
210 take an exception.  For example:
211
212     require Bounded_Array;
213     tie @ary, 'Bounded_Array', 2;
214     $| = 1;
215     for $i (0 .. 10) {
216         print "setting index $i: ";
217         $ary[$i] = 10 * $i;
218         $ary[$i] = 10 * $i;
219         print "value of elt $i now $ary[$i]\n";
220     }
221
222 The preamble code for the class is as follows:
223
224     package Bounded_Array;
225     use Carp;
226     use strict;
227
228 =over
229
230 =item TIEARRAY classname, LIST
231
232 This is the constructor for the class.  That means it is expected to
233 return a blessed reference through which the new array (probably an
234 anonymous ARRAY ref) will be accessed.
235
236 In our example, just to show you that you don't I<really> have to return an
237 ARRAY reference, we'll choose a HASH reference to represent our object.
238 A HASH works out well as a generic record type: the C<{BOUND}> field will
239 store the maximum bound allowed, and the C<{ARRAY}> field will hold the
240 true ARRAY ref.  If someone outside the class tries to dereference the
241 object returned (doubtless thinking it an ARRAY ref), they'll blow up.
242 This just goes to show you that you should respect an object's privacy.
243
244     sub TIEARRAY {
245         my $class = shift;
246         my $bound = shift;
247         confess "usage: tie(\@ary, 'Bounded_Array', max_subscript)"
248             if @_ || $bound =~ /\D/;
249         return bless {
250             BOUND => $bound,
251             ARRAY => [],
252         }, $class;
253     }
254
255 =item FETCH this, index
256
257 This method will be triggered every time an individual element the tied array
258 is accessed (read).  It takes one argument beyond its self reference: the
259 index whose value we're trying to fetch.
260
261     sub FETCH {
262       my($self,$idx) = @_;
263       if ($idx > $self->{BOUND}) {
264         confess "Array OOB: $idx > $self->{BOUND}";
265       }
266       return $self->{ARRAY}[$idx];
267     }
268
269 If a negative array index is used to read from an array, the index
270 will be translated to a positive one internally by calling FETCHSIZE
271 before being passed to FETCH.
272
273 As you may have noticed, the name of the FETCH method (et al.) is the same
274 for all accesses, even though the constructors differ in names (TIESCALAR
275 vs TIEARRAY).  While in theory you could have the same class servicing
276 several tied types, in practice this becomes cumbersome, and it's easiest
277 to keep them at simply one tie type per class.
278
279 =item STORE this, index, value
280
281 This method will be triggered every time an element in the tied array is set
282 (written).  It takes two arguments beyond its self reference: the index at
283 which we're trying to store something and the value we're trying to put
284 there.  For example:
285
286     sub STORE {
287       my($self, $idx, $value) = @_;
288       print "[STORE $value at $idx]\n" if _debug;
289       if ($idx > $self->{BOUND} ) {
290         confess "Array OOB: $idx > $self->{BOUND}";
291       }
292       return $self->{ARRAY}[$idx] = $value;
293     }
294
295 Negative indexes are treated the same as with FETCH.
296
297 =item UNTIE this
298
299 Will be called when C<untie> happens. (See below.)
300
301 =item DESTROY this
302
303 This method will be triggered when the tied variable needs to be destructed.
304 As with the scalar tie class, this is almost never needed in a
305 language that does its own garbage collection, so this time we'll
306 just leave it out.
307
308 =back
309
310 The code we presented at the top of the tied array class accesses many
311 elements of the array, far more than we've set the bounds to.  Therefore,
312 it will blow up once they try to access beyond the 2nd element of @ary, as
313 the following output demonstrates:
314
315     setting index 0: value of elt 0 now 0
316     setting index 1: value of elt 1 now 10
317     setting index 2: value of elt 2 now 20
318     setting index 3: Array OOB: 3 > 2 at Bounded_Array.pm line 39
319             Bounded_Array::FETCH called at testba line 12
320
321 =head2 Tying Hashes
322
323 Hashes were the first Perl data type to be tied (see dbmopen()).  A class
324 implementing a tied hash should define the following methods: TIEHASH is
325 the constructor.  FETCH and STORE access the key and value pairs.  EXISTS
326 reports whether a key is present in the hash, and DELETE deletes one.
327 CLEAR empties the hash by deleting all the key and value pairs.  FIRSTKEY
328 and NEXTKEY implement the keys() and each() functions to iterate over all
329 the keys.  UNTIE is called when C<untie> happens, and DESTROY is called when
330 the tied variable is garbage collected.
331
332 If this seems like a lot, then feel free to inherit from merely the
333 standard Tie::Hash module for most of your methods, redefining only the
334 interesting ones.  See L<Tie::Hash> for details.
335
336 Remember that Perl distinguishes between a key not existing in the hash,
337 and the key existing in the hash but having a corresponding value of
338 C<undef>.  The two possibilities can be tested with the C<exists()> and
339 C<defined()> functions.
340
341 Here's an example of a somewhat interesting tied hash class:  it gives you
342 a hash representing a particular user's dot files.  You index into the hash
343 with the name of the file (minus the dot) and you get back that dot file's
344 contents.  For example:
345
346     use DotFiles;
347     tie %dot, 'DotFiles';
348     if ( $dot{profile} =~ /MANPATH/ ||
349          $dot{login}   =~ /MANPATH/ ||
350          $dot{cshrc}   =~ /MANPATH/    )
351     {
352         print "you seem to set your MANPATH\n";
353     }
354
355 Or here's another sample of using our tied class:
356
357     tie %him, 'DotFiles', 'daemon';
358     foreach $f ( keys %him ) {
359         printf "daemon dot file %s is size %d\n",
360             $f, length $him{$f};
361     }
362
363 In our tied hash DotFiles example, we use a regular
364 hash for the object containing several important
365 fields, of which only the C<{LIST}> field will be what the
366 user thinks of as the real hash.
367
368 =over 5
369
370 =item USER
371
372 whose dot files this object represents
373
374 =item HOME
375
376 where those dot files live
377
378 =item CLOBBER
379
380 whether we should try to change or remove those dot files
381
382 =item LIST
383
384 the hash of dot file names and content mappings
385
386 =back
387
388 Here's the start of F<Dotfiles.pm>:
389
390     package DotFiles;
391     use Carp;
392     sub whowasi { (caller(1))[3] . '()' }
393     my $DEBUG = 0;
394     sub debug { $DEBUG = @_ ? shift : 1 }
395
396 For our example, we want to be able to emit debugging info to help in tracing
397 during development.  We keep also one convenience function around
398 internally to help print out warnings; whowasi() returns the function name
399 that calls it.
400
401 Here are the methods for the DotFiles tied hash.
402
403 =over
404
405 =item TIEHASH classname, LIST
406
407 This is the constructor for the class.  That means it is expected to
408 return a blessed reference through which the new object (probably but not
409 necessarily an anonymous hash) will be accessed.
410
411 Here's the constructor:
412
413     sub TIEHASH {
414         my $self = shift;
415         my $user = shift || $>;
416         my $dotdir = shift || '';
417         croak "usage: @{[&whowasi]} [USER [DOTDIR]]" if @_;
418         $user = getpwuid($user) if $user =~ /^\d+$/;
419         my $dir = (getpwnam($user))[7]
420                 || croak "@{[&whowasi]}: no user $user";
421         $dir .= "/$dotdir" if $dotdir;
422
423         my $node = {
424             USER    => $user,
425             HOME    => $dir,
426             LIST    => {},
427             CLOBBER => 0,
428         };
429
430         opendir(DIR, $dir)
431                 || croak "@{[&whowasi]}: can't opendir $dir: $!";
432         foreach $dot ( grep /^\./ && -f "$dir/$_", readdir(DIR)) {
433             $dot =~ s/^\.//;
434             $node->{LIST}{$dot} = undef;
435         }
436         closedir DIR;
437         return bless $node, $self;
438     }
439
440 It's probably worth mentioning that if you're going to filetest the
441 return values out of a readdir, you'd better prepend the directory
442 in question.  Otherwise, because we didn't chdir() there, it would
443 have been testing the wrong file.
444
445 =item FETCH this, key
446
447 This method will be triggered every time an element in the tied hash is
448 accessed (read).  It takes one argument beyond its self reference: the key
449 whose value we're trying to fetch.
450
451 Here's the fetch for our DotFiles example.
452
453     sub FETCH {
454         carp &whowasi if $DEBUG;
455         my $self = shift;
456         my $dot = shift;
457         my $dir = $self->{HOME};
458         my $file = "$dir/.$dot";
459
460         unless (exists $self->{LIST}->{$dot} || -f $file) {
461             carp "@{[&whowasi]}: no $dot file" if $DEBUG;
462             return undef;
463         }
464
465         if (defined $self->{LIST}->{$dot}) {
466             return $self->{LIST}->{$dot};
467         } else {
468             return $self->{LIST}->{$dot} = `cat $dir/.$dot`;
469         }
470     }
471
472 It was easy to write by having it call the Unix cat(1) command, but it
473 would probably be more portable to open the file manually (and somewhat
474 more efficient).  Of course, because dot files are a Unixy concept, we're
475 not that concerned.
476
477 =item STORE this, key, value
478
479 This method will be triggered every time an element in the tied hash is set
480 (written).  It takes two arguments beyond its self reference: the index at
481 which we're trying to store something, and the value we're trying to put
482 there.
483
484 Here in our DotFiles example, we'll be careful not to let
485 them try to overwrite the file unless they've called the clobber()
486 method on the original object reference returned by tie().
487
488     sub STORE {
489         carp &whowasi if $DEBUG;
490         my $self = shift;
491         my $dot = shift;
492         my $value = shift;
493         my $file = $self->{HOME} . "/.$dot";
494         my $user = $self->{USER};
495
496         croak "@{[&whowasi]}: $file not clobberable"
497             unless $self->{CLOBBER};
498
499         open(F, "> $file") || croak "can't open $file: $!";
500         print F $value;
501         close(F);
502     }
503
504 If they wanted to clobber something, they might say:
505
506     $ob = tie %daemon_dots, 'daemon';
507     $ob->clobber(1);
508     $daemon_dots{signature} = "A true daemon\n";
509
510 Another way to lay hands on a reference to the underlying object is to
511 use the tied() function, so they might alternately have set clobber
512 using:
513
514     tie %daemon_dots, 'daemon';
515     tied(%daemon_dots)->clobber(1);
516
517 The clobber method is simply:
518
519     sub clobber {
520         my $self = shift;
521         $self->{CLOBBER} = @_ ? shift : 1;
522     }
523
524 =item DELETE this, key
525
526 This method is triggered when we remove an element from the hash,
527 typically by using the delete() function.  Again, we'll
528 be careful to check whether they really want to clobber files.
529
530     sub DELETE   {
531         carp &whowasi if $DEBUG;
532
533         my $self = shift;
534         my $dot = shift;
535         my $file = $self->{HOME} . "/.$dot";
536         croak "@{[&whowasi]}: won't remove file $file"
537             unless $self->{CLOBBER};
538         delete $self->{LIST}->{$dot};
539         my $success = unlink($file);
540         carp "@{[&whowasi]}: can't unlink $file: $!" unless $success;
541         $success;
542     }
543
544 The value returned by DELETE becomes the return value of the call
545 to delete().  If you want to emulate the normal behavior of delete(),
546 you should return whatever FETCH would have returned for this key.
547 In this example, we have chosen instead to return a value which tells
548 the caller whether the file was successfully deleted.
549
550 =item CLEAR this
551
552 This method is triggered when the whole hash is to be cleared, usually by
553 assigning the empty list to it.
554
555 In our example, that would remove all the user's dot files!  It's such a
556 dangerous thing that they'll have to set CLOBBER to something higher than
557 1 to make it happen.
558
559     sub CLEAR    {
560         carp &whowasi if $DEBUG;
561         my $self = shift;
562         croak "@{[&whowasi]}: won't remove all dot files for $self->{USER}"
563             unless $self->{CLOBBER} > 1;
564         my $dot;
565         foreach $dot ( keys %{$self->{LIST}}) {
566             $self->DELETE($dot);
567         }
568     }
569
570 =item EXISTS this, key
571
572 This method is triggered when the user uses the exists() function
573 on a particular hash.  In our example, we'll look at the C<{LIST}>
574 hash element for this:
575
576     sub EXISTS   {
577         carp &whowasi if $DEBUG;
578         my $self = shift;
579         my $dot = shift;
580         return exists $self->{LIST}->{$dot};
581     }
582
583 =item FIRSTKEY this
584
585 This method will be triggered when the user is going
586 to iterate through the hash, such as via a keys() or each()
587 call.
588
589     sub FIRSTKEY {
590         carp &whowasi if $DEBUG;
591         my $self = shift;
592         my $a = keys %{$self->{LIST}};          # reset each() iterator
593         each %{$self->{LIST}}
594     }
595
596 =item NEXTKEY this, lastkey
597
598 This method gets triggered during a keys() or each() iteration.  It has a
599 second argument which is the last key that had been accessed.  This is
600 useful if you're carrying about ordering or calling the iterator from more
601 than one sequence, or not really storing things in a hash anywhere.
602
603 For our example, we're using a real hash so we'll do just the simple
604 thing, but we'll have to go through the LIST field indirectly.
605
606     sub NEXTKEY  {
607         carp &whowasi if $DEBUG;
608         my $self = shift;
609         return each %{ $self->{LIST} }
610     }
611
612 =item UNTIE this
613
614 This is called when C<untie> occurs.
615
616 =item DESTROY this
617
618 This method is triggered when a tied hash is about to go out of
619 scope.  You don't really need it unless you're trying to add debugging
620 or have auxiliary state to clean up.  Here's a very simple function:
621
622     sub DESTROY  {
623         carp &whowasi if $DEBUG;
624     }
625
626 =back
627
628 Note that functions such as keys() and values() may return huge lists
629 when used on large objects, like DBM files.  You may prefer to use the
630 each() function to iterate over such.  Example:
631
632     # print out history file offsets
633     use NDBM_File;
634     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
635     while (($key,$val) = each %HIST) {
636         print $key, ' = ', unpack('L',$val), "\n";
637     }
638     untie(%HIST);
639
640 =head2 Tying FileHandles
641
642 This is partially implemented now.
643
644 A class implementing a tied filehandle should define the following
645 methods: TIEHANDLE, at least one of PRINT, PRINTF, WRITE, READLINE, GETC,
646 READ, and possibly CLOSE, UNTIE and DESTROY.  The class can also provide: BINMODE,
647 OPEN, EOF, FILENO, SEEK, TELL - if the corresponding perl operators are
648 used on the handle.
649
650 It is especially useful when perl is embedded in some other program,
651 where output to STDOUT and STDERR may have to be redirected in some
652 special way. See nvi and the Apache module for examples.
653
654 In our example we're going to create a shouting handle.
655
656     package Shout;
657
658 =over
659
660 =item TIEHANDLE classname, LIST
661
662 This is the constructor for the class.  That means it is expected to
663 return a blessed reference of some sort. The reference can be used to
664 hold some internal information.
665
666     sub TIEHANDLE { print "<shout>\n"; my $i; bless \$i, shift }
667
668 =item WRITE this, LIST
669
670 This method will be called when the handle is written to via the
671 C<syswrite> function.
672
673     sub WRITE {
674         $r = shift;
675         my($buf,$len,$offset) = @_;
676         print "WRITE called, \$buf=$buf, \$len=$len, \$offset=$offset";
677     }
678
679 =item PRINT this, LIST
680
681 This method will be triggered every time the tied handle is printed to
682 with the C<print()> function.
683 Beyond its self reference it also expects the list that was passed to
684 the print function.
685
686     sub PRINT { $r = shift; $$r++; print join($,,map(uc($_),@_)),$\ }
687
688 =item PRINTF this, LIST
689
690 This method will be triggered every time the tied handle is printed to
691 with the C<printf()> function.
692 Beyond its self reference it also expects the format and list that was
693 passed to the printf function.
694
695     sub PRINTF {
696         shift;
697         my $fmt = shift;
698         print sprintf($fmt, @_)."\n";
699     }
700
701 =item READ this, LIST
702
703 This method will be called when the handle is read from via the C<read>
704 or C<sysread> functions.
705
706     sub READ {
707         my $self = shift;
708         my $$bufref = \$_[0];
709         my(undef,$len,$offset) = @_;
710         print "READ called, \$buf=$bufref, \$len=$len, \$offset=$offset";
711         # add to $$bufref, set $len to number of characters read
712         $len;
713     }
714
715 =item READLINE this
716
717 This method will be called when the handle is read from via <HANDLE>.
718 The method should return undef when there is no more data.
719
720     sub READLINE { $r = shift; "READLINE called $$r times\n"; }
721
722 =item GETC this
723
724 This method will be called when the C<getc> function is called.
725
726     sub GETC { print "Don't GETC, Get Perl"; return "a"; }
727
728 =item CLOSE this
729
730 This method will be called when the handle is closed via the C<close>
731 function.
732
733     sub CLOSE { print "CLOSE called.\n" }
734
735 =item UNTIE this
736
737 As with the other types of ties, this method will be called when C<untie> happens.
738 It may be appropriate to "auto CLOSE" when this occurs.
739
740 =item DESTROY this
741
742 As with the other types of ties, this method will be called when the
743 tied handle is about to be destroyed. This is useful for debugging and
744 possibly cleaning up.
745
746     sub DESTROY { print "</shout>\n" }
747
748 =back
749
750 Here's how to use our little example:
751
752     tie(*FOO,'Shout');
753     print FOO "hello\n";
754     $a = 4; $b = 6;
755     print FOO $a, " plus ", $b, " equals ", $a + $b, "\n";
756     print <FOO>;
757
758 =head2 UNTIE this
759
760 You can define for all tie types an UNTIE method that will be called
761 at untie().
762
763 =head2 The C<untie> Gotcha
764
765 If you intend making use of the object returned from either tie() or
766 tied(), and if the tie's target class defines a destructor, there is a
767 subtle gotcha you I<must> guard against.
768
769 As setup, consider this (admittedly rather contrived) example of a
770 tie; all it does is use a file to keep a log of the values assigned to
771 a scalar.
772
773     package Remember;
774
775     use strict;
776     use warnings;
777     use IO::File;
778
779     sub TIESCALAR {
780         my $class = shift;
781         my $filename = shift;
782         my $handle = new IO::File "> $filename"
783                          or die "Cannot open $filename: $!\n";
784
785         print $handle "The Start\n";
786         bless {FH => $handle, Value => 0}, $class;
787     }
788
789     sub FETCH {
790         my $self = shift;
791         return $self->{Value};
792     }
793
794     sub STORE {
795         my $self = shift;
796         my $value = shift;
797         my $handle = $self->{FH};
798         print $handle "$value\n";
799         $self->{Value} = $value;
800     }
801
802     sub DESTROY {
803         my $self = shift;
804         my $handle = $self->{FH};
805         print $handle "The End\n";
806         close $handle;
807     }
808
809     1;
810
811 Here is an example that makes use of this tie:
812
813     use strict;
814     use Remember;
815
816     my $fred;
817     tie $fred, 'Remember', 'myfile.txt';
818     $fred = 1;
819     $fred = 4;
820     $fred = 5;
821     untie $fred;
822     system "cat myfile.txt";
823
824 This is the output when it is executed:
825
826     The Start
827     1
828     4
829     5
830     The End
831
832 So far so good.  Those of you who have been paying attention will have
833 spotted that the tied object hasn't been used so far.  So lets add an
834 extra method to the Remember class to allow comments to be included in
835 the file -- say, something like this:
836
837     sub comment {
838         my $self = shift;
839         my $text = shift;
840         my $handle = $self->{FH};
841         print $handle $text, "\n";
842     }
843
844 And here is the previous example modified to use the C<comment> method
845 (which requires the tied object):
846
847     use strict;
848     use Remember;
849
850     my ($fred, $x);
851     $x = tie $fred, 'Remember', 'myfile.txt';
852     $fred = 1;
853     $fred = 4;
854     comment $x "changing...";
855     $fred = 5;
856     untie $fred;
857     system "cat myfile.txt";
858
859 When this code is executed there is no output.  Here's why:
860
861 When a variable is tied, it is associated with the object which is the
862 return value of the TIESCALAR, TIEARRAY, or TIEHASH function.  This
863 object normally has only one reference, namely, the implicit reference
864 from the tied variable.  When untie() is called, that reference is
865 destroyed.  Then, as in the first example above, the object's
866 destructor (DESTROY) is called, which is normal for objects that have
867 no more valid references; and thus the file is closed.
868
869 In the second example, however, we have stored another reference to
870 the tied object in $x.  That means that when untie() gets called
871 there will still be a valid reference to the object in existence, so
872 the destructor is not called at that time, and thus the file is not
873 closed.  The reason there is no output is because the file buffers
874 have not been flushed to disk.
875
876 Now that you know what the problem is, what can you do to avoid it?
877 Prior to the introduction of the optional UNTIE method the only way
878 was the good old C<-w> flag. Which will spot any instances where you call
879 untie() and there are still valid references to the tied object.  If
880 the second script above this near the top C<use warnings 'untie'>
881 or was run with the C<-w> flag, Perl prints this
882 warning message:
883
884     untie attempted while 1 inner references still exist
885
886 To get the script to work properly and silence the warning make sure
887 there are no valid references to the tied object I<before> untie() is
888 called:
889
890     undef $x;
891     untie $fred;
892
893 Now that UNTIE exists the class designer can decide which parts of the
894 class functionality are really associated with C<untie> and which with
895 the object being destroyed. What makes sense for a given class depends
896 on whether the inner references are being kept so that non-tie-related
897 methods can be called on the object. But in most cases it probably makes
898 sense to move the functionality that would have been in DESTROY to the UNTIE
899 method.
900
901 If the UNTIE method exists then the warning above does not occur. Instead the
902 UNTIE method is passed the count of "extra" references and can issue its own
903 warning if appropriate. e.g. to replicate the no UNTIE case this method can
904 be used:
905
906     sub UNTIE
907     {
908      my ($obj,$count) = @_;
909      carp "untie attempted while $count inner references still exist" if $count;
910     }
911
912 =head1 SEE ALSO
913
914 See L<DB_File> or L<Config> for some interesting tie() implementations.
915 A good starting point for many tie() implementations is with one of the
916 modules L<Tie::Scalar>, L<Tie::Array>, L<Tie::Hash>, or L<Tie::Handle>.
917
918 =head1 BUGS
919
920 You cannot easily tie a multilevel data structure (such as a hash of
921 hashes) to a dbm file.  The first problem is that all but GDBM and
922 Berkeley DB have size limitations, but beyond that, you also have problems
923 with how references are to be represented on disk.  One experimental
924 module that does attempt to address this need partially is the MLDBM
925 module.  Check your nearest CPAN site as described in L<perlmodlib> for
926 source code to MLDBM.
927
928 =head1 AUTHOR
929
930 Tom Christiansen
931
932 TIEHANDLE by Sven Verdoolaege <F<skimo@dns.ufsia.ac.be>> and Doug MacEachern <F<dougm@osf.org>>
933
934 UNTIE by Nick Ing-Simmons <F<nick@ing-simmons.net>>
935