regen_perly.pl

   1 #!/usr/bin/perl
   2 #
   3 # regen_perly.pl, DAPM 12-Feb-04
   4 #
   5 # Copyright (c) 2004, 2005, 2006, 2009, 2010, 2011 Larry Wall
   6 #
   7 # Given an input file perly.y, run bison on it and produce
   8 # the following output files:
   9 #
  10 # perly.h       standard bison header file with minor doctoring of
  11 #               #line directives plus adding a #ifdef PERL_CORE
  12 #
  13 # perly.tab     the parser table C definitions extracted from the bison output
  14 #               plus an extra table generated by this script.
  15 #
  16 # perly.act     the action case statements extracted from the bison output
  17 #
  18 # Note that perly.c is *not* regenerated - this is now a static file which
  19 # is not dependent on perly.y any more.
  20 #
  21 # If a filename of the form foo.y is given on the command line, then
  22 # this is used instead as the basename for all the files mentioned
  23 # above.
  24 #
  25 # Note that temporary files of the form perlytmp.h and perlytmp.c are
  26 # created and then deleted during this process
  27 #
  28 # Note also that this script is intended to be run on a UNIX system;
  29 # it may work elsewhere but no specific attempt has been made to make it
  30 # portable.
  31
  32 use 5.006;
  33 sub usage { die "usage: $0 [ -b bison_executable ] [ file.y ]\n" }
  34
  35 use warnings;
  36 use strict;
  37
  38 BEGIN { require 'regen/regen_lib.pl'; }
  39
  40 my $bison = 'bison';
  41
  42 if (@ARGV >= 2 and $ARGV[0] eq '-b') {
  43     shift;
  44     $bison = shift;
  45 }
  46
  47 my $y_file = shift || 'perly.y';
  48
  49 usage unless @ARGV==0 && $y_file =~ /\.y$/;
  50
  51 (my $h_file    = $y_file) =~ s/\.y$/.h/;
  52 (my $act_file  = $y_file) =~ s/\.y$/.act/;
  53 (my $tab_file  = $y_file) =~ s/\.y$/.tab/;
  54 (my $tmpc_file = $y_file) =~ s/\.y$/tmp.c/;
  55 (my $tmph_file = $y_file) =~ s/\.y$/tmp.h/;
  56
  57 # the yytranslate[] table generated by bison is ASCII/EBCDIC sensitive
  58
  59 die "$0: must be run on an ASCII system\n" unless ord 'A' == 65;
  60
  61 # check for correct version number. The constraints are:
  62 #  * must be >= 1.24 to avoid licensing issues.
  63 #  * it must generate the yystos[] table. Version 1.28 doesn't generate
  64 #    this; 1.35+ does
  65 #  * Must produce output which is extractable by the regexes below
  66 #  * Must produce the right values.
  67 # These last two constraints  may well be met by earlier versions, but
  68 # I simply haven't tested them yet. If it works for you, then modify
  69 # the test below to allow that version too. DAPM Feb 04.
  70
  71 my $version = `$bison -V`;
  72 unless ($version) { die <<EOF; }
  73 Could not find a version of bison in your path. Please install bison.
  74 EOF
  75
  76 unless ($version =~ /\b(1\.875[a-z]?|2\.[0134567])\b/) { die <<EOF; }
  77
  78 You have the wrong version of bison in your path; currently 1.875
  79 2.0, 2.1, 2.3-2.7 is required.  Try installing
  80     http://ftp.gnu.org/gnu/bison/bison-2.7.tar.gz
  81 or similar.  Your bison identifies itself as:
  82
  83 $version
  84 EOF
  85
  86 # creates $tmpc_file and $tmph_file
  87 my_system("$bison -d -o $tmpc_file $y_file");
  88
  89 open my $ctmp_fh, '<', $tmpc_file or die "Can't open $tmpc_file: $!\n";
  90 my $clines;
  91 { local $/; $clines = <$ctmp_fh>; }
  92 die "failed to read $tmpc_file: length mismatch\n"
  93     unless length $clines == -s $tmpc_file;
  94 close $ctmp_fh;
  95
  96 my ($actlines, $tablines) = extract($clines);
  97
  98 our %tokens;
  99 $tablines .= make_type_tab($y_file, $tablines);
 100
 101 my ($act_fh, $tab_fh, $h_fh) = map {
 102     open_new($_, '>', { by => $0, from => $y_file });
 103 } $act_file, $tab_file, $h_file;
 104
 105 print $act_fh $actlines;
 106
 107 print $tab_fh $tablines;
 108
 109 unlink $tmpc_file;
 110
 111 # Wrap PERL_CORE round the symbol definitions. Also,  the
 112 # C<#line 30 "perly.y"> confuses the Win32 resource compiler and the
 113 # C<#line 188 "perlytmp.h"> gets picked up by make depend, so remove them.
 114
 115 open my $tmph_fh, '<', $tmph_file or die "Can't open $tmph_file: $!\n";
 116
 117 my $endcore_done = 0;
 118 # Token macros need to be generated manually from bison 2.4 on
 119 my $gather_tokens = ($version =~ /\b2\.[456]\b/ ? undef : 0);
 120 my $tokens;
 121 while (<$tmph_fh>) {
 122     # bison 2.6 adds header guards, which break things because of where we
 123     # insert #ifdef PERL_CORE, so strip them because they aren't important
 124     next if /YY_PERLYTMP_H/;
 125
 126     print $h_fh "#ifdef PERL_CORE\n" if $. == 1;
 127     if (!$endcore_done and /YYSTYPE_IS_DECLARED/) {
 128         print $h_fh <<h;
 129 #ifdef PERL_IN_TOKE_C
 130 static bool
 131 S_is_opval_token(int type) {
 132     switch (type) {
 133 h
 134         print $h_fh <<i for sort grep $tokens{$_} eq 'opval', keys %tokens;
 135     case $_:
 136 i
 137         print $h_fh <<j;
 138         return 1;
 139     }
 140     return 0;
 141 }
 142 #endif /* PERL_IN_TOKE_C */
 143 #endif /* PERL_CORE */
 144 j
 145         $endcore_done = 1;
 146     }
 147     next if /^#line \d+ ".*"/;
 148     if (not defined $gather_tokens) {
 149         $gather_tokens = 1 if /^\s* enum \s* yytokentype \s* \{/x;
 150     }
 151     elsif ($gather_tokens) {
 152         if (/^\# \s* endif/x) { # The #endif just after the end of the token enum
 153             $gather_tokens = 0;
 154             $_ .= "\n/* Tokens.  */\n$tokens";
 155         }
 156         else {
 157             my ($tok, $val) = /(\w+) \s* = \s* (\d+)/x;
 158             $tokens .= "#define $tok $val\n" if $tok;
 159         }
 160     }
 161     print $h_fh $_;
 162 }
 163 close $tmph_fh;
 164 unlink $tmph_file;
 165
 166 foreach ($act_fh, $tab_fh, $h_fh) {
 167     read_only_bottom_close_and_rename($_, ['regen_perly.pl', $y_file]);
 168 }
 169
 170 exit 0;
 171
 172
 173 sub extract {
 174     my $clines = shift;
 175     my $tablines;
 176     my $actlines;
 177
 178     $clines =~ m@
 179         (?:
 180             ^/* YYFINAL[^\n]+\n         #optional comment
 181         )?
 182         \# \s* define \s* YYFINAL       # first #define
 183         .*?                             # other defines + most tables
 184         yystos\[\]\s*=                  # start of last table
 185         .*?
 186         }\s*;                           # end of last table
 187     @xms
 188         or die "Can't extract tables from $tmpc_file\n";
 189     $tablines = $&;
 190
 191
 192     $clines =~ m@
 193         switch \s* \( \s* \w+ \s* \) \s* { \s*
 194         (
 195             case \s* \d+ \s* :
 196             \s*
 197             (?: \s* /\* .*? \*/ \s* )*  # optional C-comments
 198             \s*
 199             \#line [^\n]+"\Q$y_file\E"
 200             .*?
 201         )
 202         }
 203         \s*
 204         (?: \s* /\* .*? \*/ \s* )*      # optional C-comments
 205         \s*
 206         (
 207             \#line[^\n]+\.c"
 208         |
 209             \#line[^\n]+\.simple"
 210         |
 211             YY_SYMBOL_PRINT
 212         )
 213     @xms
 214         or die "Can't extract actions from $tmpc_file\n";
 215     $actlines = $1;
 216
 217     # Remove extraneous comments from bison 2.4
 218     $actlines =~ s!\s* /\* \s* Line \s* \d+ \s* of \s* yacc\.c \s* \*/!!gx;
 219
 220     # C<#line 188 "perlytmp.c"> gets picked up by make depend, so remove them.
 221     $actlines =~ s/^#line \d+ "\Q$tmpc_file\E".*$//gm;
 222
 223     # convert yyvsp[nnn] into ps[nnn].val
 224
 225     $actlines =~ s/yyvsp\[(.*?)\]/ps[$1].val/g
 226         or die "Can't convert value stack name\n";
 227
 228     return $actlines. "\n", $tablines. "\n";
 229 }
 230
 231 # Generate a table, yy_type_tab[], that specifies for each token, what
 232 # type of value it holds.
 233 #
 234 # Read the .y file and extract a list of all the token names and
 235 # non-terminal names; then scan the string $tablines for the table yytname,
 236 # which gives the token index of each token/non-terminal; then use this to
 237 # create yy_type_tab.
 238 #
 239 # ie given (in perly.y),
 240 #
 241 #   %token <opval> A
 242 #   %token <ival>  B
 243 #   %type  <pval>  C
 244 #   %type  <opval> D
 245 #
 246 # and (in $tablines),
 247 #
 248 #   yytname[] = { "A" "B", "C", "D", "E" };
 249 #
 250 # then return
 251 #
 252 #    typedef enum { toketype_ival, toketype_opval, toketype_pval } toketypes;
 253 #
 254 #    static const toketypes yy_type_tab[]
 255 #          = { toketype_opval, toketype_ival, toketype_pval,
 256 #                toketype_opval, toketype_ival }
 257 #
 258 # where "E" has the default type. The default type is determined
 259 # by the __DEFAULT__ comment  next to the appropriate union member in
 260 # perly.y
 261
 262 sub make_type_tab {
 263     my ($y_file, $tablines) = @_;
 264     my %just_tokens;
 265     my %tokens;
 266     my %types;
 267     my $default_token;
 268     open my $fh, '<', $y_file or die "Can't open $y_file: $!\n";
 269     while (<$fh>) {
 270         if (/(\$\d+)\s*=/) {
 271             warn "$y_file:$.: dangerous assignment to $1: $_";
 272         }
 273
 274         if (/__DEFAULT__/) {
 275             m{(\w+) \s* ; \s* /\* \s* __DEFAULT__}x
 276                 or die "$y_file: can't parse __DEFAULT__ line: $_";
 277             die "$y_file: duplicate __DEFAULT__ line: $_"
 278                     if defined $default_token;
 279             $default_token = $1;
 280             next;
 281         }
 282
 283         next unless /^%(token|type)/;
 284         s/^%((token)|type)\s+<(\w+)>\s+//
 285             or die "$y_file: unparseable token/type line: $_";
 286         for (split ' ', $_) {
 287             $tokens{$_} = $3;
 288             if ($2) {
 289                 $just_tokens{$_} = $3;
 290             }
 291         }
 292         $types{$3} = 1;
 293     }
 294     *tokens = \%just_tokens; # perly.h needs this
 295     die "$y_file: no __DEFAULT__ token defined\n" unless $default_token;
 296     $types{$default_token} = 1;
 297
 298     $tablines =~ /^\Qstatic const char *const yytname[] =\E\n
 299             \{\n
 300             (.*?)
 301             ^};
 302             /xsm
 303         or die "Can't extract yytname[] from table string\n";
 304     my $fields = $1;
 305     $fields =~ s{"([^"]+)"}
 306                 { "toketype_" .
 307                     (defined $tokens{$1} ? $tokens{$1} : $default_token)
 308                 }ge;
 309     $fields =~ s/, \s* (?:0|YY_NULL) \s* $//x
 310         or die "make_type_tab: couldn't delete trailing ',0'\n";
 311
 312     return
 313           "\ntypedef enum {\n\t"
 314         . join(", ", map "toketype_$_", sort keys %types)
 315         . "\n} toketypes;\n\n"
 316         . "/* type of each token/terminal */\n"
 317         . "static const toketypes yy_type_tab[] =\n{\n"
 318         . $fields
 319         . "\n};\n";
 320 }
 321
 322
 323 sub my_system {
 324     system(@_);
 325     if ($? == -1) {
 326         die "failed to execute command '@_': $!\n";
 327     }
 328     elsif ($? & 127) {
 329         die sprintf "command '@_' died with signal %d\n",
 330             ($? & 127);
 331     }
 332     elsif ($? >> 8) {
 333         die sprintf "command '@_' exited with value %d\n", $? >> 8;
 334     }
 335 }