This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Make perldiag agree with #19138.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Elements of the LIST should be separated by commas.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getprgp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item I<-X> FILEHANDLE
250
251 =item I<-X> EXPR
252
253 =item I<-X>
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file, otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 a C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 =item abs VALUE
370
371 =item abs
372
373 Returns the absolute value of its argument.
374 If VALUE is omitted, uses C<$_>.
375
376 =item accept NEWSOCKET,GENERICSOCKET
377
378 Accepts an incoming socket connect, just as the accept(2) system call
379 does.  Returns the packed address if it succeeded, false otherwise.
380 See the example in L<perlipc/"Sockets: Client/Server Communication">.
381
382 On systems that support a close-on-exec flag on files, the flag will
383 be set for the newly opened file descriptor, as determined by the
384 value of $^F.  See L<perlvar/$^F>.
385
386 =item alarm SECONDS
387
388 =item alarm
389
390 Arranges to have a SIGALRM delivered to this process after the
391 specified number of wallclock seconds have elapsed.  If SECONDS is not
392 specified, the value stored in C<$_> is used. (On some machines,
393 unfortunately, the elapsed time may be up to one second less or more
394 than you specified because of how seconds are counted, and process
395 scheduling may delay the delivery of the signal even further.)
396
397 Only one timer may be counting at once.  Each call disables the
398 previous timer, and an argument of C<0> may be supplied to cancel the
399 previous timer without starting a new one.  The returned value is the
400 amount of time remaining on the previous timer.
401
402 For delays of finer granularity than one second, you may use Perl's
403 four-argument version of select() leaving the first three arguments
404 undefined, or you might be able to use the C<syscall> interface to
405 access setitimer(2) if your system supports it.  The Time::HiRes
406 module (from CPAN, and starting from Perl 5.8 part of the standard
407 distribution) may also prove useful.
408
409 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
410 (C<sleep> may be internally implemented in your system with C<alarm>)
411
412 If you want to use C<alarm> to time out a system call you need to use an
413 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
414 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
415 restart system calls on some systems.  Using C<eval>/C<die> always works,
416 modulo the caveats given in L<perlipc/"Signals">.
417
418     eval {
419         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
420         alarm $timeout;
421         $nread = sysread SOCKET, $buffer, $size;
422         alarm 0;
423     };
424     if ($@) {
425         die unless $@ eq "alarm\n";   # propagate unexpected errors
426         # timed out
427     }
428     else {
429         # didn't
430     }
431
432 =item atan2 Y,X
433
434 Returns the arctangent of Y/X in the range -PI to PI.
435
436 For the tangent operation, you may use the C<Math::Trig::tan>
437 function, or use the familiar relation:
438
439     sub tan { sin($_[0]) / cos($_[0])  }
440
441 =item bind SOCKET,NAME
442
443 Binds a network address to a socket, just as the bind system call
444 does.  Returns true if it succeeded, false otherwise.  NAME should be a
445 packed address of the appropriate type for the socket.  See the examples in
446 L<perlipc/"Sockets: Client/Server Communication">.
447
448 =item binmode FILEHANDLE, LAYER
449
450 =item binmode FILEHANDLE
451
452 Arranges for FILEHANDLE to be read or written in "binary" or "text"
453 mode on systems where the run-time libraries distinguish between
454 binary and text files.  If FILEHANDLE is an expression, the value is
455 taken as the name of the filehandle.  Returns true on success,
456 otherwise it returns C<undef> and sets C<$!> (errno).
457
458 If LAYER is omitted or specified as C<:raw> the filehandle is made
459 suitable for passing binary data. This includes turning off possible CRLF
460 translation and marking it as bytes (as opposed to Unicode characters).
461 Note that as desipite what may be implied in I<"Programming Perl">
462 (the Camel) or elsewhere C<:raw> is I<not> the simply inverse of C<:crlf>
463 -- other layers which would affect binary nature of the stream are
464 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
465 PERLIO environment variable.
466
467 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
468 in "Programming Perl, 3rd Edition".  However, since the publishing of this
469 book, by many known as "Camel III", the consensus of the naming of this
470 functionality has moved from "discipline" to "layer".  All documentation
471 of this version of Perl therefore refers to "layers" rather than to
472 "disciplines".  Now back to the regularly scheduled documentation...>
473
474 On some systems (in general, DOS and Windows-based systems) binmode()
475 is necessary when you're not working with a text file.  For the sake
476 of portability it is a good idea to always use it when appropriate,
477 and to never use it when it isn't appropriate.
478
479 In other words: regardless of platform, use binmode() on binary files
480 (like for example images).
481
482 If LAYER is present it is a single string, but may contain
483 multiple directives. The directives alter the behaviour of the
484 file handle. When LAYER is present using binmode on text
485 file makes sense.
486
487 To mark FILEHANDLE as UTF-8, use C<:utf8>.
488
489 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
490 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
491 establish default I/O layers.  See L<open>.
492
493 In general, binmode() should be called after open() but before any I/O
494 is done on the filehandle.  Calling binmode() will normally flush any
495 pending buffered output data (and perhaps pending input data) on the
496 handle.  An exception to this is the C<:encoding> layer that
497 changes the default character encoding of the handle, see L<open>.
498 The C<:encoding> layer sometimes needs to be called in
499 mid-stream, and it doesn't flush the stream.
500
501 The operating system, device drivers, C libraries, and Perl run-time
502 system all work together to let the programmer treat a single
503 character (C<\n>) as the line terminator, irrespective of the external
504 representation.  On many operating systems, the native text file
505 representation matches the internal representation, but on some
506 platforms the external representation of C<\n> is made up of more than
507 one character.
508
509 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
510 character to end each line in the external representation of text (even
511 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
512 on Unix and most VMS files). In other systems like OS/2, DOS and the
513 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
514 but what's stored in text files are the two characters C<\cM\cJ>.  That
515 means that, if you don't use binmode() on these systems, C<\cM\cJ>
516 sequences on disk will be converted to C<\n> on input, and any C<\n> in
517 your program will be converted back to C<\cM\cJ> on output.  This is what
518 you want for text files, but it can be disastrous for binary files.
519
520 Another consequence of using binmode() (on some systems) is that
521 special end-of-file markers will be seen as part of the data stream.
522 For systems from the Microsoft family this means that if your binary
523 data contains C<\cZ>, the I/O subsystem will regard it as the end of
524 the file, unless you use binmode().
525
526 binmode() is not only important for readline() and print() operations,
527 but also when using read(), seek(), sysread(), syswrite() and tell()
528 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
529 in L<perlvar> for how to manually set your input and output
530 line-termination sequences.
531
532 =item bless REF,CLASSNAME
533
534 =item bless REF
535
536 This function tells the thingy referenced by REF that it is now an object
537 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
538 is used.  Because a C<bless> is often the last thing in a constructor,
539 it returns the reference for convenience.  Always use the two-argument
540 version if the function doing the blessing might be inherited by a
541 derived class.  See L<perltoot> and L<perlobj> for more about the blessing
542 (and blessings) of objects.
543
544 Consider always blessing objects in CLASSNAMEs that are mixed case.
545 Namespaces with all lowercase names are considered reserved for
546 Perl pragmata.  Builtin types have all uppercase names, so to prevent
547 confusion, you may wish to avoid such package names as well.  Make sure
548 that CLASSNAME is a true value.
549
550 See L<perlmod/"Perl Modules">.
551
552 =item caller EXPR
553
554 =item caller
555
556 Returns the context of the current subroutine call.  In scalar context,
557 returns the caller's package name if there is a caller, that is, if
558 we're in a subroutine or C<eval> or C<require>, and the undefined value
559 otherwise.  In list context, returns
560
561     ($package, $filename, $line) = caller;
562
563 With EXPR, it returns some extra information that the debugger uses to
564 print a stack trace.  The value of EXPR indicates how many call frames
565 to go back before the current one.
566
567     ($package, $filename, $line, $subroutine, $hasargs,
568     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
569
570 Here $subroutine may be C<(eval)> if the frame is not a subroutine
571 call, but an C<eval>.  In such a case additional elements $evaltext and
572 C<$is_require> are set: C<$is_require> is true if the frame is created by a
573 C<require> or C<use> statement, $evaltext contains the text of the
574 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
575 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
576 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
577 frame.)  $subroutine may also be C<(unknown)> if this particular
578 subroutine happens to have been deleted from the symbol table.
579 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
580 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
581 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
582 between versions of Perl, and are not meant for external use.
583
584 Furthermore, when called from within the DB package, caller returns more
585 detailed information: it sets the list variable C<@DB::args> to be the
586 arguments with which the subroutine was invoked.
587
588 Be aware that the optimizer might have optimized call frames away before
589 C<caller> had a chance to get the information.  That means that C<caller(N)>
590 might not return information about the call frame you expect it do, for
591 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
592 previous time C<caller> was called.
593
594 =item chdir EXPR
595
596 Changes the working directory to EXPR, if possible. If EXPR is omitted,
597 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
598 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
599 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
600 neither is set, C<chdir> does nothing. It returns true upon success,
601 false otherwise. See the example under C<die>.
602
603 =item chmod LIST
604
605 Changes the permissions of a list of files.  The first element of the
606 list must be the numerical mode, which should probably be an octal
607 number, and which definitely should I<not> a string of octal digits:
608 C<0644> is okay, C<'0644'> is not.  Returns the number of files
609 successfully changed.  See also L</oct>, if all you have is a string.
610
611     $cnt = chmod 0755, 'foo', 'bar';
612     chmod 0755, @executables;
613     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
614                                              # --w----r-T
615     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
616     $mode = 0644;   chmod $mode, 'foo';      # this is best
617
618 You can also import the symbolic C<S_I*> constants from the Fcntl
619 module:
620
621     use Fcntl ':mode';
622
623     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
624     # This is identical to the chmod 0755 of the above example.
625
626 =item chomp VARIABLE
627
628 =item chomp( LIST )
629
630 =item chomp
631
632 This safer version of L</chop> removes any trailing string
633 that corresponds to the current value of C<$/> (also known as
634 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
635 number of characters removed from all its arguments.  It's often used to
636 remove the newline from the end of an input record when you're worried
637 that the final record may be missing its newline.  When in paragraph
638 mode (C<$/ = "">), it removes all trailing newlines from the string.
639 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
640 a reference to an integer or the like, see L<perlvar>) chomp() won't
641 remove anything.
642 If VARIABLE is omitted, it chomps C<$_>.  Example:
643
644     while (<>) {
645         chomp;  # avoid \n on last field
646         @array = split(/:/);
647         # ...
648     }
649
650 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
651
652 You can actually chomp anything that's an lvalue, including an assignment:
653
654     chomp($cwd = `pwd`);
655     chomp($answer = <STDIN>);
656
657 If you chomp a list, each element is chomped, and the total number of
658 characters removed is returned.
659
660 Note that parentheses are necessary when you're chomping anything
661 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
662 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
663 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
664 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
665 as C<chomp($a, $b)>.
666
667 =item chop VARIABLE
668
669 =item chop( LIST )
670
671 =item chop
672
673 Chops off the last character of a string and returns the character
674 chopped.  It is much more efficient than C<s/.$//s> because it neither
675 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
676 If VARIABLE is a hash, it chops the hash's values, but not its keys.
677
678 You can actually chop anything that's an lvalue, including an assignment.
679
680 If you chop a list, each element is chopped.  Only the value of the
681 last C<chop> is returned.
682
683 Note that C<chop> returns the last character.  To return all but the last
684 character, use C<substr($string, 0, -1)>.
685
686 See also L</chomp>.
687
688 =item chown LIST
689
690 Changes the owner (and group) of a list of files.  The first two
691 elements of the list must be the I<numeric> uid and gid, in that
692 order.  A value of -1 in either position is interpreted by most
693 systems to leave that value unchanged.  Returns the number of files
694 successfully changed.
695
696     $cnt = chown $uid, $gid, 'foo', 'bar';
697     chown $uid, $gid, @filenames;
698
699 Here's an example that looks up nonnumeric uids in the passwd file:
700
701     print "User: ";
702     chomp($user = <STDIN>);
703     print "Files: ";
704     chomp($pattern = <STDIN>);
705
706     ($login,$pass,$uid,$gid) = getpwnam($user)
707         or die "$user not in passwd file";
708
709     @ary = glob($pattern);      # expand filenames
710     chown $uid, $gid, @ary;
711
712 On most systems, you are not allowed to change the ownership of the
713 file unless you're the superuser, although you should be able to change
714 the group to any of your secondary groups.  On insecure systems, these
715 restrictions may be relaxed, but this is not a portable assumption.
716 On POSIX systems, you can detect this condition this way:
717
718     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
719     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
720
721 =item chr NUMBER
722
723 =item chr
724
725 Returns the character represented by that NUMBER in the character set.
726 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
727 chr(0x263a) is a Unicode smiley face.  Note that characters from 127
728 to 255 (inclusive) are by default not encoded in Unicode for backward
729 compatibility reasons (but see L<encoding>).
730
731 For the reverse, use L</ord>.
732 See L<perlunicode> and L<encoding> for more about Unicode.
733
734 If NUMBER is omitted, uses C<$_>.
735
736 =item chroot FILENAME
737
738 =item chroot
739
740 This function works like the system call by the same name: it makes the
741 named directory the new root directory for all further pathnames that
742 begin with a C</> by your process and all its children.  (It doesn't
743 change your current working directory, which is unaffected.)  For security
744 reasons, this call is restricted to the superuser.  If FILENAME is
745 omitted, does a C<chroot> to C<$_>.
746
747 =item close FILEHANDLE
748
749 =item close
750
751 Closes the file or pipe associated with the file handle, returning
752 true only if IO buffers are successfully flushed and closes the system
753 file descriptor.  Closes the currently selected filehandle if the
754 argument is omitted.
755
756 You don't have to close FILEHANDLE if you are immediately going to do
757 another C<open> on it, because C<open> will close it for you.  (See
758 C<open>.)  However, an explicit C<close> on an input file resets the line
759 counter (C<$.>), while the implicit close done by C<open> does not.
760
761 If the file handle came from a piped open C<close> will additionally
762 return false if one of the other system calls involved fails or if the
763 program exits with non-zero status.  (If the only problem was that the
764 program exited non-zero C<$!> will be set to C<0>.)  Closing a pipe
765 also waits for the process executing on the pipe to complete, in case you
766 want to look at the output of the pipe afterwards, and
767 implicitly puts the exit status value of that command into C<$?>.
768
769 Prematurely closing the read end of a pipe (i.e. before the process
770 writing to it at the other end has closed it) will result in a
771 SIGPIPE being delivered to the writer.  If the other end can't
772 handle that, be sure to read all the data before closing the pipe.
773
774 Example:
775
776     open(OUTPUT, '|sort >foo')  # pipe to sort
777         or die "Can't start sort: $!";
778     #...                        # print stuff to output
779     close OUTPUT                # wait for sort to finish
780         or warn $! ? "Error closing sort pipe: $!"
781                    : "Exit status $? from sort";
782     open(INPUT, 'foo')          # get sort's results
783         or die "Can't open 'foo' for input: $!";
784
785 FILEHANDLE may be an expression whose value can be used as an indirect
786 filehandle, usually the real filehandle name.
787
788 =item closedir DIRHANDLE
789
790 Closes a directory opened by C<opendir> and returns the success of that
791 system call.
792
793 DIRHANDLE may be an expression whose value can be used as an indirect
794 dirhandle, usually the real dirhandle name.
795
796 =item connect SOCKET,NAME
797
798 Attempts to connect to a remote socket, just as the connect system call
799 does.  Returns true if it succeeded, false otherwise.  NAME should be a
800 packed address of the appropriate type for the socket.  See the examples in
801 L<perlipc/"Sockets: Client/Server Communication">.
802
803 =item continue BLOCK
804
805 Actually a flow control statement rather than a function.  If there is a
806 C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
807 C<foreach>), it is always executed just before the conditional is about to
808 be evaluated again, just like the third part of a C<for> loop in C.  Thus
809 it can be used to increment a loop variable, even when the loop has been
810 continued via the C<next> statement (which is similar to the C C<continue>
811 statement).
812
813 C<last>, C<next>, or C<redo> may appear within a C<continue>
814 block.  C<last> and C<redo> will behave as if they had been executed within
815 the main block.  So will C<next>, but since it will execute a C<continue>
816 block, it may be more entertaining.
817
818     while (EXPR) {
819         ### redo always comes here
820         do_something;
821     } continue {
822         ### next always comes here
823         do_something_else;
824         # then back the top to re-check EXPR
825     }
826     ### last always comes here
827
828 Omitting the C<continue> section is semantically equivalent to using an
829 empty one, logically enough.  In that case, C<next> goes directly back
830 to check the condition at the top of the loop.
831
832 =item cos EXPR
833
834 =item cos
835
836 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
837 takes cosine of C<$_>.
838
839 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
840 function, or use this relation:
841
842     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
843
844 =item crypt PLAINTEXT,SALT
845
846 Encrypts a string exactly like the crypt(3) function in the C library
847 (assuming that you actually have a version there that has not been
848 extirpated as a potential munition).  This can prove useful for checking
849 the password file for lousy passwords, amongst other things.  Only the
850 guys wearing white hats should do this.
851
852 Note that L<crypt|/crypt> is intended to be a one-way function, much like
853 breaking eggs to make an omelette.  There is no (known) corresponding
854 decrypt function (in other words, the crypt() is a one-way hash
855 function).  As a result, this function isn't all that useful for
856 cryptography.  (For that, see your nearby CPAN mirror.)
857
858 When verifying an existing encrypted string you should use the
859 encrypted text as the salt (like C<crypt($plain, $crypted) eq
860 $crypted>).  This allows your code to work with the standard L<crypt|/crypt>
861 and with more exotic implementations.  In other words, do not assume
862 anything about the returned string itself, or how many bytes in
863 the encrypted string matter.
864
865 Traditionally the result is a string of 13 bytes: two first bytes of
866 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
867 the first eight bytes of the encrypted string mattered, but
868 alternative hashing schemes (like MD5), higher level security schemes
869 (like C2), and implementations on non-UNIX platforms may produce
870 different strings.
871
872 When choosing a new salt create a random two character string whose
873 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
874 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).
875
876 Here's an example that makes sure that whoever runs this program knows
877 their own password:
878
879     $pwd = (getpwuid($<))[1];
880
881     system "stty -echo";
882     print "Password: ";
883     chomp($word = <STDIN>);
884     print "\n";
885     system "stty echo";
886
887     if (crypt($word, $pwd) ne $pwd) {
888         die "Sorry...\n";
889     } else {
890         print "ok\n";
891     }
892
893 Of course, typing in your own password to whoever asks you
894 for it is unwise.
895
896 The L<crypt|/crypt> function is unsuitable for encrypting large quantities
897 of data, not least of all because you can't get the information
898 back.  Look at the F<by-module/Crypt> and F<by-module/PGP> directories
899 on your favorite CPAN mirror for a slew of potentially useful
900 modules.
901
902 If using crypt() on a Unicode string (which I<potentially> has
903 characters with codepoints above 255), Perl tries to make sense
904 of the situation by trying to downgrade (a copy of the string)
905 the string back to an eight-bit byte string before calling crypt()
906 (on that copy).  If that works, good.  If not, crypt() dies with
907 C<Wide character in crypt>.
908
909 =item dbmclose HASH
910
911 [This function has been largely superseded by the C<untie> function.]
912
913 Breaks the binding between a DBM file and a hash.
914
915 =item dbmopen HASH,DBNAME,MASK
916
917 [This function has been largely superseded by the C<tie> function.]
918
919 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
920 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
921 argument is I<not> a filehandle, even though it looks like one).  DBNAME
922 is the name of the database (without the F<.dir> or F<.pag> extension if
923 any).  If the database does not exist, it is created with protection
924 specified by MASK (as modified by the C<umask>).  If your system supports
925 only the older DBM functions, you may perform only one C<dbmopen> in your
926 program.  In older versions of Perl, if your system had neither DBM nor
927 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
928 sdbm(3).
929
930 If you don't have write access to the DBM file, you can only read hash
931 variables, not set them.  If you want to test whether you can write,
932 either use file tests or try setting a dummy hash entry inside an C<eval>,
933 which will trap the error.
934
935 Note that functions such as C<keys> and C<values> may return huge lists
936 when used on large DBM files.  You may prefer to use the C<each>
937 function to iterate over large DBM files.  Example:
938
939     # print out history file offsets
940     dbmopen(%HIST,'/usr/lib/news/history',0666);
941     while (($key,$val) = each %HIST) {
942         print $key, ' = ', unpack('L',$val), "\n";
943     }
944     dbmclose(%HIST);
945
946 See also L<AnyDBM_File> for a more general description of the pros and
947 cons of the various dbm approaches, as well as L<DB_File> for a particularly
948 rich implementation.
949
950 You can control which DBM library you use by loading that library
951 before you call dbmopen():
952
953     use DB_File;
954     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
955         or die "Can't open netscape history file: $!";
956
957 =item defined EXPR
958
959 =item defined
960
961 Returns a Boolean value telling whether EXPR has a value other than
962 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
963 checked.
964
965 Many operations return C<undef> to indicate failure, end of file,
966 system error, uninitialized variable, and other exceptional
967 conditions.  This function allows you to distinguish C<undef> from
968 other values.  (A simple Boolean test will not distinguish among
969 C<undef>, zero, the empty string, and C<"0">, which are all equally
970 false.)  Note that since C<undef> is a valid scalar, its presence
971 doesn't I<necessarily> indicate an exceptional condition: C<pop>
972 returns C<undef> when its argument is an empty array, I<or> when the
973 element to return happens to be C<undef>.
974
975 You may also use C<defined(&func)> to check whether subroutine C<&func>
976 has ever been defined.  The return value is unaffected by any forward
977 declarations of C<&foo>.  Note that a subroutine which is not defined
978 may still be callable: its package may have an C<AUTOLOAD> method that
979 makes it spring into existence the first time that it is called -- see
980 L<perlsub>.
981
982 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
983 used to report whether memory for that aggregate has ever been
984 allocated.  This behavior may disappear in future versions of Perl.
985 You should instead use a simple test for size:
986
987     if (@an_array) { print "has array elements\n" }
988     if (%a_hash)   { print "has hash members\n"   }
989
990 When used on a hash element, it tells you whether the value is defined,
991 not whether the key exists in the hash.  Use L</exists> for the latter
992 purpose.
993
994 Examples:
995
996     print if defined $switch{'D'};
997     print "$val\n" while defined($val = pop(@ary));
998     die "Can't readlink $sym: $!"
999         unless defined($value = readlink $sym);
1000     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1001     $debugging = 0 unless defined $debugging;
1002
1003 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1004 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1005 defined values.  For example, if you say
1006
1007     "ab" =~ /a(.*)b/;
1008
1009 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1010 matched "nothing".  But it didn't really match nothing--rather, it
1011 matched something that happened to be zero characters long.  This is all
1012 very above-board and honest.  When a function returns an undefined value,
1013 it's an admission that it couldn't give you an honest answer.  So you
1014 should use C<defined> only when you're questioning the integrity of what
1015 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1016 what you want.
1017
1018 See also L</undef>, L</exists>, L</ref>.
1019
1020 =item delete EXPR
1021
1022 Given an expression that specifies a hash element, array element, hash slice,
1023 or array slice, deletes the specified element(s) from the hash or array.
1024 In the case of an array, if the array elements happen to be at the end,
1025 the size of the array will shrink to the highest element that tests
1026 true for exists() (or 0 if no such element exists).
1027
1028 Returns each element so deleted or the undefined value if there was no such
1029 element.  Deleting from C<$ENV{}> modifies the environment.  Deleting from
1030 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1031 from a C<tie>d hash or array may not necessarily return anything.
1032
1033 Deleting an array element effectively returns that position of the array
1034 to its initial, uninitialized state.  Subsequently testing for the same
1035 element with exists() will return false.  Note that deleting array
1036 elements in the middle of an array will not shift the index of the ones
1037 after them down--use splice() for that.  See L</exists>.
1038
1039 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1040
1041     foreach $key (keys %HASH) {
1042         delete $HASH{$key};
1043     }
1044
1045     foreach $index (0 .. $#ARRAY) {
1046         delete $ARRAY[$index];
1047     }
1048
1049 And so do these:
1050
1051     delete @HASH{keys %HASH};
1052
1053     delete @ARRAY[0 .. $#ARRAY];
1054
1055 But both of these are slower than just assigning the empty list
1056 or undefining %HASH or @ARRAY:
1057
1058     %HASH = ();         # completely empty %HASH
1059     undef %HASH;        # forget %HASH ever existed
1060
1061     @ARRAY = ();        # completely empty @ARRAY
1062     undef @ARRAY;       # forget @ARRAY ever existed
1063
1064 Note that the EXPR can be arbitrarily complicated as long as the final
1065 operation is a hash element, array element,  hash slice, or array slice
1066 lookup:
1067
1068     delete $ref->[$x][$y]{$key};
1069     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1070
1071     delete $ref->[$x][$y][$index];
1072     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1073
1074 =item die LIST
1075
1076 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1077 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1078 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1079 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1080 an C<eval(),> the error message is stuffed into C<$@> and the
1081 C<eval> is terminated with the undefined value.  This makes
1082 C<die> the way to raise an exception.
1083
1084 Equivalent examples:
1085
1086     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1087     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1088
1089 If the last element of LIST does not end in a newline, the current
1090 script line number and input line number (if any) are also printed,
1091 and a newline is supplied.  Note that the "input line number" (also
1092 known as "chunk") is subject to whatever notion of "line" happens to
1093 be currently in effect, and is also available as the special variable
1094 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1095
1096 Hint: sometimes appending C<", stopped"> to your message will cause it
1097 to make better sense when the string C<"at foo line 123"> is appended.
1098 Suppose you are running script "canasta".
1099
1100     die "/etc/games is no good";
1101     die "/etc/games is no good, stopped";
1102
1103 produce, respectively
1104
1105     /etc/games is no good at canasta line 123.
1106     /etc/games is no good, stopped at canasta line 123.
1107
1108 See also exit(), warn(), and the Carp module.
1109
1110 If LIST is empty and C<$@> already contains a value (typically from a
1111 previous eval) that value is reused after appending C<"\t...propagated">.
1112 This is useful for propagating exceptions:
1113
1114     eval { ... };
1115     die unless $@ =~ /Expected exception/;
1116
1117 If LIST is empty and C<$@> contains an object reference that has a
1118 C<PROPAGATE> method, that method will be called with additional file
1119 and line number parameters.  The return value replaces the value in
1120 C<$@>.  ie. as if C<<$@ = eval { $@->PROPAGATE(__FILE__, __LINE__) };>>
1121 were called.
1122
1123 If C<$@> is empty then the string C<"Died"> is used.
1124
1125 die() can also be called with a reference argument.  If this happens to be
1126 trapped within an eval(), $@ contains the reference.  This behavior permits
1127 a more elaborate exception handling implementation using objects that
1128 maintain arbitrary state about the nature of the exception.  Such a scheme
1129 is sometimes preferable to matching particular string values of $@ using
1130 regular expressions.  Here's an example:
1131
1132     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1133     if ($@) {
1134         if (ref($@) && UNIVERSAL::isa($@,"Some::Module::Exception")) {
1135             # handle Some::Module::Exception
1136         }
1137         else {
1138             # handle all other possible exceptions
1139         }
1140     }
1141
1142 Because perl will stringify uncaught exception messages before displaying
1143 them, you may want to overload stringification operations on such custom
1144 exception objects.  See L<overload> for details about that.
1145
1146 You can arrange for a callback to be run just before the C<die>
1147 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1148 handler will be called with the error text and can change the error
1149 message, if it sees fit, by calling C<die> again.  See
1150 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1151 L<"eval BLOCK"> for some examples.  Although this feature was meant
1152 to be run only right before your program was to exit, this is not
1153 currently the case--the C<$SIG{__DIE__}> hook is currently called
1154 even inside eval()ed blocks/strings!  If one wants the hook to do
1155 nothing in such situations, put
1156
1157         die @_ if $^S;
1158
1159 as the first line of the handler (see L<perlvar/$^S>).  Because
1160 this promotes strange action at a distance, this counterintuitive
1161 behavior may be fixed in a future release.
1162
1163 =item do BLOCK
1164
1165 Not really a function.  Returns the value of the last command in the
1166 sequence of commands indicated by BLOCK.  When modified by a loop
1167 modifier, executes the BLOCK once before testing the loop condition.
1168 (On other statements the loop modifiers test the conditional first.)
1169
1170 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1171 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1172 See L<perlsyn> for alternative strategies.
1173
1174 =item do SUBROUTINE(LIST)
1175
1176 A deprecated form of subroutine call.  See L<perlsub>.
1177
1178 =item do EXPR
1179
1180 Uses the value of EXPR as a filename and executes the contents of the
1181 file as a Perl script.  Its primary use is to include subroutines
1182 from a Perl subroutine library.
1183
1184     do 'stat.pl';
1185
1186 is just like
1187
1188     eval `cat stat.pl`;
1189
1190 except that it's more efficient and concise, keeps track of the current
1191 filename for error messages, searches the @INC libraries, and updates
1192 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1193 variables.  It also differs in that code evaluated with C<do FILENAME>
1194 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1195 same, however, in that it does reparse the file every time you call it,
1196 so you probably don't want to do this inside a loop.
1197
1198 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1199 error.  If C<do> can read the file but cannot compile it, it
1200 returns undef and sets an error message in C<$@>.   If the file is
1201 successfully compiled, C<do> returns the value of the last expression
1202 evaluated.
1203
1204 Note that inclusion of library modules is better done with the
1205 C<use> and C<require> operators, which also do automatic error checking
1206 and raise an exception if there's a problem.
1207
1208 You might like to use C<do> to read in a program configuration
1209 file.  Manual error checking can be done this way:
1210
1211     # read in config files: system first, then user
1212     for $file ("/share/prog/defaults.rc",
1213                "$ENV{HOME}/.someprogrc")
1214    {
1215         unless ($return = do $file) {
1216             warn "couldn't parse $file: $@" if $@;
1217             warn "couldn't do $file: $!"    unless defined $return;
1218             warn "couldn't run $file"       unless $return;
1219         }
1220     }
1221
1222 =item dump LABEL
1223
1224 =item dump
1225
1226 This function causes an immediate core dump.  See also the B<-u>
1227 command-line switch in L<perlrun>, which does the same thing.
1228 Primarily this is so that you can use the B<undump> program (not
1229 supplied) to turn your core dump into an executable binary after
1230 having initialized all your variables at the beginning of the
1231 program.  When the new binary is executed it will begin by executing
1232 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1233 Think of it as a goto with an intervening core dump and reincarnation.
1234 If C<LABEL> is omitted, restarts the program from the top.
1235
1236 B<WARNING>: Any files opened at the time of the dump will I<not>
1237 be open any more when the program is reincarnated, with possible
1238 resulting confusion on the part of Perl.
1239
1240 This function is now largely obsolete, partly because it's very
1241 hard to convert a core file into an executable, and because the
1242 real compiler backends for generating portable bytecode and compilable
1243 C code have superseded it.  That's why you should now invoke it as
1244 C<CORE::dump()>, if you don't want to be warned against a possible
1245 typo.
1246
1247 If you're looking to use L<dump> to speed up your program, consider
1248 generating bytecode or native C code as described in L<perlcc>.  If
1249 you're just trying to accelerate a CGI script, consider using the
1250 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1251 You might also consider autoloading or selfloading, which at least
1252 make your program I<appear> to run faster.
1253
1254 =item each HASH
1255
1256 When called in list context, returns a 2-element list consisting of the
1257 key and value for the next element of a hash, so that you can iterate over
1258 it.  When called in scalar context, returns only the key for the next
1259 element in the hash.
1260
1261 Entries are returned in an apparently random order.  The actual random
1262 order is subject to change in future versions of perl, but it is guaranteed
1263 to be in the same order as either the C<keys> or C<values> function
1264 would produce on the same (unmodified) hash.
1265
1266 When the hash is entirely read, a null array is returned in list context
1267 (which when assigned produces a false (C<0>) value), and C<undef> in
1268 scalar context.  The next call to C<each> after that will start iterating
1269 again.  There is a single iterator for each hash, shared by all C<each>,
1270 C<keys>, and C<values> function calls in the program; it can be reset by
1271 reading all the elements from the hash, or by evaluating C<keys HASH> or
1272 C<values HASH>.  If you add or delete elements of a hash while you're
1273 iterating over it, you may get entries skipped or duplicated, so
1274 don't.  Exception: It is always safe to delete the item most recently
1275 returned by C<each()>, which means that the following code will work:
1276
1277         while (($key, $value) = each %hash) {
1278           print $key, "\n";
1279           delete $hash{$key};   # This is safe
1280         }
1281
1282 The following prints out your environment like the printenv(1) program,
1283 only in a different order:
1284
1285     while (($key,$value) = each %ENV) {
1286         print "$key=$value\n";
1287     }
1288
1289 See also C<keys>, C<values> and C<sort>.
1290
1291 =item eof FILEHANDLE
1292
1293 =item eof ()
1294
1295 =item eof
1296
1297 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1298 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1299 gives the real filehandle.  (Note that this function actually
1300 reads a character and then C<ungetc>s it, so isn't very useful in an
1301 interactive context.)  Do not read from a terminal file (or call
1302 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1303 as terminals may lose the end-of-file condition if you do.
1304
1305 An C<eof> without an argument uses the last file read.  Using C<eof()>
1306 with empty parentheses is very different.  It refers to the pseudo file
1307 formed from the files listed on the command line and accessed via the
1308 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1309 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1310 used will cause C<@ARGV> to be examined to determine if input is
1311 available.   Similarly, an C<eof()> after C<< <> >> has returned
1312 end-of-file will assume you are processing another C<@ARGV> list,
1313 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1314 see L<perlop/"I/O Operators">.
1315
1316 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1317 detect the end of each file, C<eof()> will only detect the end of the
1318 last file.  Examples:
1319
1320     # reset line numbering on each input file
1321     while (<>) {
1322         next if /^\s*#/;        # skip comments
1323         print "$.\t$_";
1324     } continue {
1325         close ARGV  if eof;     # Not eof()!
1326     }
1327
1328     # insert dashes just before last line of last file
1329     while (<>) {
1330         if (eof()) {            # check for end of current file
1331             print "--------------\n";
1332             close(ARGV);        # close or last; is needed if we
1333                                 # are reading from the terminal
1334         }
1335         print;
1336     }
1337
1338 Practical hint: you almost never need to use C<eof> in Perl, because the
1339 input operators typically return C<undef> when they run out of data, or if
1340 there was an error.
1341
1342 =item eval EXPR
1343
1344 =item eval BLOCK
1345
1346 In the first form, the return value of EXPR is parsed and executed as if it
1347 were a little Perl program.  The value of the expression (which is itself
1348 determined within scalar context) is first parsed, and if there weren't any
1349 errors, executed in the lexical context of the current Perl program, so
1350 that any variable settings or subroutine and format definitions remain
1351 afterwards.  Note that the value is parsed every time the eval executes.
1352 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1353 delay parsing and subsequent execution of the text of EXPR until run time.
1354
1355 In the second form, the code within the BLOCK is parsed only once--at the
1356 same time the code surrounding the eval itself was parsed--and executed
1357 within the context of the current Perl program.  This form is typically
1358 used to trap exceptions more efficiently than the first (see below), while
1359 also providing the benefit of checking the code within BLOCK at compile
1360 time.
1361
1362 The final semicolon, if any, may be omitted from the value of EXPR or within
1363 the BLOCK.
1364
1365 In both forms, the value returned is the value of the last expression
1366 evaluated inside the mini-program; a return statement may be also used, just
1367 as with subroutines.  The expression providing the return value is evaluated
1368 in void, scalar, or list context, depending on the context of the eval itself.
1369 See L</wantarray> for more on how the evaluation context can be determined.
1370
1371 If there is a syntax error or runtime error, or a C<die> statement is
1372 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1373 error message.  If there was no error, C<$@> is guaranteed to be a null
1374 string.  Beware that using C<eval> neither silences perl from printing
1375 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1376 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1377 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1378 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1379
1380 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1381 determining whether a particular feature (such as C<socket> or C<symlink>)
1382 is implemented.  It is also Perl's exception trapping mechanism, where
1383 the die operator is used to raise exceptions.
1384
1385 If the code to be executed doesn't vary, you may use the eval-BLOCK
1386 form to trap run-time errors without incurring the penalty of
1387 recompiling each time.  The error, if any, is still returned in C<$@>.
1388 Examples:
1389
1390     # make divide-by-zero nonfatal
1391     eval { $answer = $a / $b; }; warn $@ if $@;
1392
1393     # same thing, but less efficient
1394     eval '$answer = $a / $b'; warn $@ if $@;
1395
1396     # a compile-time error
1397     eval { $answer = };                 # WRONG
1398
1399     # a run-time error
1400     eval '$answer =';   # sets $@
1401
1402 Due to the current arguably broken state of C<__DIE__> hooks, when using
1403 the C<eval{}> form as an exception trap in libraries, you may wish not
1404 to trigger any C<__DIE__> hooks that user code may have installed.
1405 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1406 as shown in this example:
1407
1408     # a very private exception trap for divide-by-zero
1409     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1410     warn $@ if $@;
1411
1412 This is especially significant, given that C<__DIE__> hooks can call
1413 C<die> again, which has the effect of changing their error messages:
1414
1415     # __DIE__ hooks may modify error messages
1416     {
1417        local $SIG{'__DIE__'} =
1418               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1419        eval { die "foo lives here" };
1420        print $@ if $@;                # prints "bar lives here"
1421     }
1422
1423 Because this promotes action at a distance, this counterintuitive behavior
1424 may be fixed in a future release.
1425
1426 With an C<eval>, you should be especially careful to remember what's
1427 being looked at when:
1428
1429     eval $x;            # CASE 1
1430     eval "$x";          # CASE 2
1431
1432     eval '$x';          # CASE 3
1433     eval { $x };        # CASE 4
1434
1435     eval "\$$x++";      # CASE 5
1436     $$x++;              # CASE 6
1437
1438 Cases 1 and 2 above behave identically: they run the code contained in
1439 the variable $x.  (Although case 2 has misleading double quotes making
1440 the reader wonder what else might be happening (nothing is).)  Cases 3
1441 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1442 does nothing but return the value of $x.  (Case 4 is preferred for
1443 purely visual reasons, but it also has the advantage of compiling at
1444 compile-time instead of at run-time.)  Case 5 is a place where
1445 normally you I<would> like to use double quotes, except that in this
1446 particular situation, you can just use symbolic references instead, as
1447 in case 6.
1448
1449 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1450 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1451
1452 Note that as a very special case, an C<eval ''> executed within the C<DB>
1453 package doesn't see the usual surrounding lexical scope, but rather the
1454 scope of the first non-DB piece of code that called it. You don't normally
1455 need to worry about this unless you are writing a Perl debugger.
1456
1457 =item exec LIST
1458
1459 =item exec PROGRAM LIST
1460
1461 The C<exec> function executes a system command I<and never returns>--
1462 use C<system> instead of C<exec> if you want it to return.  It fails and
1463 returns false only if the command does not exist I<and> it is executed
1464 directly instead of via your system's command shell (see below).
1465
1466 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1467 warns you if there is a following statement which isn't C<die>, C<warn>,
1468 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1469 I<really> want to follow an C<exec> with some other statement, you
1470 can use one of these styles to avoid the warning:
1471
1472     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1473     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1474
1475 If there is more than one argument in LIST, or if LIST is an array
1476 with more than one value, calls execvp(3) with the arguments in LIST.
1477 If there is only one scalar argument or an array with one element in it,
1478 the argument is checked for shell metacharacters, and if there are any,
1479 the entire argument is passed to the system's command shell for parsing
1480 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1481 If there are no shell metacharacters in the argument, it is split into
1482 words and passed directly to C<execvp>, which is more efficient.
1483 Examples:
1484
1485     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1486     exec "sort $outfile | uniq";
1487
1488 If you don't really want to execute the first argument, but want to lie
1489 to the program you are executing about its own name, you can specify
1490 the program you actually want to run as an "indirect object" (without a
1491 comma) in front of the LIST.  (This always forces interpretation of the
1492 LIST as a multivalued list, even if there is only a single scalar in
1493 the list.)  Example:
1494
1495     $shell = '/bin/csh';
1496     exec $shell '-sh';          # pretend it's a login shell
1497
1498 or, more directly,
1499
1500     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1501
1502 When the arguments get executed via the system shell, results will
1503 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1504 for details.
1505
1506 Using an indirect object with C<exec> or C<system> is also more
1507 secure.  This usage (which also works fine with system()) forces
1508 interpretation of the arguments as a multivalued list, even if the
1509 list had just one argument.  That way you're safe from the shell
1510 expanding wildcards or splitting up words with whitespace in them.
1511
1512     @args = ( "echo surprise" );
1513
1514     exec @args;               # subject to shell escapes
1515                                 # if @args == 1
1516     exec { $args[0] } @args;  # safe even with one-arg list
1517
1518 The first version, the one without the indirect object, ran the I<echo>
1519 program, passing it C<"surprise"> an argument.  The second version
1520 didn't--it tried to run a program literally called I<"echo surprise">,
1521 didn't find it, and set C<$?> to a non-zero value indicating failure.
1522
1523 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1524 output before the exec, but this may not be supported on some platforms
1525 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1526 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1527 open handles in order to avoid lost output.
1528
1529 Note that C<exec> will not call your C<END> blocks, nor will it call
1530 any C<DESTROY> methods in your objects.
1531
1532 =item exists EXPR
1533
1534 Given an expression that specifies a hash element or array element,
1535 returns true if the specified element in the hash or array has ever
1536 been initialized, even if the corresponding value is undefined.  The
1537 element is not autovivified if it doesn't exist.
1538
1539     print "Exists\n"    if exists $hash{$key};
1540     print "Defined\n"   if defined $hash{$key};
1541     print "True\n"      if $hash{$key};
1542
1543     print "Exists\n"    if exists $array[$index];
1544     print "Defined\n"   if defined $array[$index];
1545     print "True\n"      if $array[$index];
1546
1547 A hash or array element can be true only if it's defined, and defined if
1548 it exists, but the reverse doesn't necessarily hold true.
1549
1550 Given an expression that specifies the name of a subroutine,
1551 returns true if the specified subroutine has ever been declared, even
1552 if it is undefined.  Mentioning a subroutine name for exists or defined
1553 does not count as declaring it.  Note that a subroutine which does not
1554 exist may still be callable: its package may have an C<AUTOLOAD>
1555 method that makes it spring into existence the first time that it is
1556 called -- see L<perlsub>.
1557
1558     print "Exists\n"    if exists &subroutine;
1559     print "Defined\n"   if defined &subroutine;
1560
1561 Note that the EXPR can be arbitrarily complicated as long as the final
1562 operation is a hash or array key lookup or subroutine name:
1563
1564     if (exists $ref->{A}->{B}->{$key})  { }
1565     if (exists $hash{A}{B}{$key})       { }
1566
1567     if (exists $ref->{A}->{B}->[$ix])   { }
1568     if (exists $hash{A}{B}[$ix])        { }
1569
1570     if (exists &{$ref->{A}{B}{$key}})   { }
1571
1572 Although the deepest nested array or hash will not spring into existence
1573 just because its existence was tested, any intervening ones will.
1574 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1575 into existence due to the existence test for the $key element above.
1576 This happens anywhere the arrow operator is used, including even:
1577
1578     undef $ref;
1579     if (exists $ref->{"Some key"})      { }
1580     print $ref;             # prints HASH(0x80d3d5c)
1581
1582 This surprising autovivification in what does not at first--or even
1583 second--glance appear to be an lvalue context may be fixed in a future
1584 release.
1585
1586 Use of a subroutine call, rather than a subroutine name, as an argument
1587 to exists() is an error.
1588
1589     exists &sub;        # OK
1590     exists &sub();      # Error
1591
1592 =item exit EXPR
1593
1594 Evaluates EXPR and exits immediately with that value.    Example:
1595
1596     $ans = <STDIN>;
1597     exit 0 if $ans =~ /^[Xx]/;
1598
1599 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1600 universally recognized values for EXPR are C<0> for success and C<1>
1601 for error; other values are subject to interpretation depending on the
1602 environment in which the Perl program is running.  For example, exiting
1603 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1604 the mailer to return the item undelivered, but that's not true everywhere.
1605
1606 Don't use C<exit> to abort a subroutine if there's any chance that
1607 someone might want to trap whatever error happened.  Use C<die> instead,
1608 which can be trapped by an C<eval>.
1609
1610 The exit() function does not always exit immediately.  It calls any
1611 defined C<END> routines first, but these C<END> routines may not
1612 themselves abort the exit.  Likewise any object destructors that need to
1613 be called are called before the real exit.  If this is a problem, you
1614 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1615 See L<perlmod> for details.
1616
1617 =item exp EXPR
1618
1619 =item exp
1620
1621 Returns I<e> (the natural logarithm base) to the power of EXPR.
1622 If EXPR is omitted, gives C<exp($_)>.
1623
1624 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1625
1626 Implements the fcntl(2) function.  You'll probably have to say
1627
1628     use Fcntl;
1629
1630 first to get the correct constant definitions.  Argument processing and
1631 value return works just like C<ioctl> below.
1632 For example:
1633
1634     use Fcntl;
1635     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1636         or die "can't fcntl F_GETFL: $!";
1637
1638 You don't have to check for C<defined> on the return from C<fnctl>.
1639 Like C<ioctl>, it maps a C<0> return from the system call into
1640 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1641 in numeric context.  It is also exempt from the normal B<-w> warnings
1642 on improper numeric conversions.
1643
1644 Note that C<fcntl> will produce a fatal error if used on a machine that
1645 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1646 manpage to learn what functions are available on your system.
1647
1648 =item fileno FILEHANDLE
1649
1650 Returns the file descriptor for a filehandle, or undefined if the
1651 filehandle is not open.  This is mainly useful for constructing
1652 bitmaps for C<select> and low-level POSIX tty-handling operations.
1653 If FILEHANDLE is an expression, the value is taken as an indirect
1654 filehandle, generally its name.
1655
1656 You can use this to find out whether two handles refer to the
1657 same underlying descriptor:
1658
1659     if (fileno(THIS) == fileno(THAT)) {
1660         print "THIS and THAT are dups\n";
1661     }
1662
1663 (Filehandles connected to memory objects via new features of C<open> may
1664 return undefined even though they are open.)
1665
1666
1667 =item flock FILEHANDLE,OPERATION
1668
1669 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1670 for success, false on failure.  Produces a fatal error if used on a
1671 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1672 C<flock> is Perl's portable file locking interface, although it locks
1673 only entire files, not records.
1674
1675 Two potentially non-obvious but traditional C<flock> semantics are
1676 that it waits indefinitely until the lock is granted, and that its locks
1677 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1678 fewer guarantees.  This means that files locked with C<flock> may be
1679 modified by programs that do not also use C<flock>.  See L<perlport>,
1680 your port's specific documentation, or your system-specific local manpages
1681 for details.  It's best to assume traditional behavior if you're writing
1682 portable programs.  (But if you're not, you should as always feel perfectly
1683 free to write for your own system's idiosyncrasies (sometimes called
1684 "features").  Slavish adherence to portability concerns shouldn't get
1685 in the way of your getting your job done.)
1686
1687 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1688 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1689 you can use the symbolic names if you import them from the Fcntl module,
1690 either individually, or as a group using the ':flock' tag.  LOCK_SH
1691 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1692 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1693 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1694 waiting for the lock (check the return status to see if you got it).
1695
1696 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1697 before locking or unlocking it.
1698
1699 Note that the emulation built with lockf(3) doesn't provide shared
1700 locks, and it requires that FILEHANDLE be open with write intent.  These
1701 are the semantics that lockf(3) implements.  Most if not all systems
1702 implement lockf(3) in terms of fcntl(2) locking, though, so the
1703 differing semantics shouldn't bite too many people.
1704
1705 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1706 be open with read intent to use LOCK_SH and requires that it be open
1707 with write intent to use LOCK_EX.
1708
1709 Note also that some versions of C<flock> cannot lock things over the
1710 network; you would need to use the more system-specific C<fcntl> for
1711 that.  If you like you can force Perl to ignore your system's flock(2)
1712 function, and so provide its own fcntl(2)-based emulation, by passing
1713 the switch C<-Ud_flock> to the F<Configure> program when you configure
1714 perl.
1715
1716 Here's a mailbox appender for BSD systems.
1717
1718     use Fcntl ':flock'; # import LOCK_* constants
1719
1720     sub lock {
1721         flock(MBOX,LOCK_EX);
1722         # and, in case someone appended
1723         # while we were waiting...
1724         seek(MBOX, 0, 2);
1725     }
1726
1727     sub unlock {
1728         flock(MBOX,LOCK_UN);
1729     }
1730
1731     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1732             or die "Can't open mailbox: $!";
1733
1734     lock();
1735     print MBOX $msg,"\n\n";
1736     unlock();
1737
1738 On systems that support a real flock(), locks are inherited across fork()
1739 calls, whereas those that must resort to the more capricious fcntl()
1740 function lose the locks, making it harder to write servers.
1741
1742 See also L<DB_File> for other flock() examples.
1743
1744 =item fork
1745
1746 Does a fork(2) system call to create a new process running the
1747 same program at the same point.  It returns the child pid to the
1748 parent process, C<0> to the child process, or C<undef> if the fork is
1749 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1750 are shared, while everything else is copied.  On most systems supporting
1751 fork(), great care has gone into making it extremely efficient (for
1752 example, using copy-on-write technology on data pages), making it the
1753 dominant paradigm for multitasking over the last few decades.
1754
1755 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1756 output before forking the child process, but this may not be supported
1757 on some platforms (see L<perlport>).  To be safe, you may need to set
1758 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1759 C<IO::Handle> on any open handles in order to avoid duplicate output.
1760
1761 If you C<fork> without ever waiting on your children, you will
1762 accumulate zombies.  On some systems, you can avoid this by setting
1763 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1764 forking and reaping moribund children.
1765
1766 Note that if your forked child inherits system file descriptors like
1767 STDIN and STDOUT that are actually connected by a pipe or socket, even
1768 if you exit, then the remote server (such as, say, a CGI script or a
1769 backgrounded job launched from a remote shell) won't think you're done.
1770 You should reopen those to F</dev/null> if it's any issue.
1771
1772 =item format
1773
1774 Declare a picture format for use by the C<write> function.  For
1775 example:
1776
1777     format Something =
1778         Test: @<<<<<<<< @||||| @>>>>>
1779               $str,     $%,    '$' . int($num)
1780     .
1781
1782     $str = "widget";
1783     $num = $cost/$quantity;
1784     $~ = 'Something';
1785     write;
1786
1787 See L<perlform> for many details and examples.
1788
1789 =item formline PICTURE,LIST
1790
1791 This is an internal function used by C<format>s, though you may call it,
1792 too.  It formats (see L<perlform>) a list of values according to the
1793 contents of PICTURE, placing the output into the format output
1794 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1795 Eventually, when a C<write> is done, the contents of
1796 C<$^A> are written to some filehandle, but you could also read C<$^A>
1797 yourself and then set C<$^A> back to C<"">.  Note that a format typically
1798 does one C<formline> per line of form, but the C<formline> function itself
1799 doesn't care how many newlines are embedded in the PICTURE.  This means
1800 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1801 You may therefore need to use multiple formlines to implement a single
1802 record format, just like the format compiler.
1803
1804 Be careful if you put double quotes around the picture, because an C<@>
1805 character may be taken to mean the beginning of an array name.
1806 C<formline> always returns true.  See L<perlform> for other examples.
1807
1808 =item getc FILEHANDLE
1809
1810 =item getc
1811
1812 Returns the next character from the input file attached to FILEHANDLE,
1813 or the undefined value at end of file, or if there was an error (in
1814 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1815 STDIN.  This is not particularly efficient.  However, it cannot be
1816 used by itself to fetch single characters without waiting for the user
1817 to hit enter.  For that, try something more like:
1818
1819     if ($BSD_STYLE) {
1820         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1821     }
1822     else {
1823         system "stty", '-icanon', 'eol', "\001";
1824     }
1825
1826     $key = getc(STDIN);
1827
1828     if ($BSD_STYLE) {
1829         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1830     }
1831     else {
1832         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1833     }
1834     print "\n";
1835
1836 Determination of whether $BSD_STYLE should be set
1837 is left as an exercise to the reader.
1838
1839 The C<POSIX::getattr> function can do this more portably on
1840 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1841 module from your nearest CPAN site; details on CPAN can be found on
1842 L<perlmodlib/CPAN>.
1843
1844 =item getlogin
1845
1846 Implements the C library function of the same name, which on most
1847 systems returns the current login from F</etc/utmp>, if any.  If null,
1848 use C<getpwuid>.
1849
1850     $login = getlogin || getpwuid($<) || "Kilroy";
1851
1852 Do not consider C<getlogin> for authentication: it is not as
1853 secure as C<getpwuid>.
1854
1855 =item getpeername SOCKET
1856
1857 Returns the packed sockaddr address of other end of the SOCKET connection.
1858
1859     use Socket;
1860     $hersockaddr    = getpeername(SOCK);
1861     ($port, $iaddr) = sockaddr_in($hersockaddr);
1862     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1863     $herstraddr     = inet_ntoa($iaddr);
1864
1865 =item getpgrp PID
1866
1867 Returns the current process group for the specified PID.  Use
1868 a PID of C<0> to get the current process group for the
1869 current process.  Will raise an exception if used on a machine that
1870 doesn't implement getpgrp(2).  If PID is omitted, returns process
1871 group of current process.  Note that the POSIX version of C<getpgrp>
1872 does not accept a PID argument, so only C<PID==0> is truly portable.
1873
1874 =item getppid
1875
1876 Returns the process id of the parent process.
1877
1878 Note for Linux users: on Linux, the C functions C<getpid()> and
1879 C<getppid()> return different values from different threads. In order to
1880 be portable, this behavior is not reflected by the perl-level function
1881 C<getppid()>, that returns a consistent value across threads. If you want
1882 to call the underlying C<getppid()>, you may use the CPAN module
1883 C<Linux::Pid>.
1884
1885 =item getpriority WHICH,WHO
1886
1887 Returns the current priority for a process, a process group, or a user.
1888 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1889 machine that doesn't implement getpriority(2).
1890
1891 =item getpwnam NAME
1892
1893 =item getgrnam NAME
1894
1895 =item gethostbyname NAME
1896
1897 =item getnetbyname NAME
1898
1899 =item getprotobyname NAME
1900
1901 =item getpwuid UID
1902
1903 =item getgrgid GID
1904
1905 =item getservbyname NAME,PROTO
1906
1907 =item gethostbyaddr ADDR,ADDRTYPE
1908
1909 =item getnetbyaddr ADDR,ADDRTYPE
1910
1911 =item getprotobynumber NUMBER
1912
1913 =item getservbyport PORT,PROTO
1914
1915 =item getpwent
1916
1917 =item getgrent
1918
1919 =item gethostent
1920
1921 =item getnetent
1922
1923 =item getprotoent
1924
1925 =item getservent
1926
1927 =item setpwent
1928
1929 =item setgrent
1930
1931 =item sethostent STAYOPEN
1932
1933 =item setnetent STAYOPEN
1934
1935 =item setprotoent STAYOPEN
1936
1937 =item setservent STAYOPEN
1938
1939 =item endpwent
1940
1941 =item endgrent
1942
1943 =item endhostent
1944
1945 =item endnetent
1946
1947 =item endprotoent
1948
1949 =item endservent
1950
1951 These routines perform the same functions as their counterparts in the
1952 system library.  In list context, the return values from the
1953 various get routines are as follows:
1954
1955     ($name,$passwd,$uid,$gid,
1956        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
1957     ($name,$passwd,$gid,$members) = getgr*
1958     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
1959     ($name,$aliases,$addrtype,$net) = getnet*
1960     ($name,$aliases,$proto) = getproto*
1961     ($name,$aliases,$port,$proto) = getserv*
1962
1963 (If the entry doesn't exist you get a null list.)
1964
1965 The exact meaning of the $gcos field varies but it usually contains
1966 the real name of the user (as opposed to the login name) and other
1967 information pertaining to the user.  Beware, however, that in many
1968 system users are able to change this information and therefore it
1969 cannot be trusted and therefore the $gcos is tainted (see
1970 L<perlsec>).  The $passwd and $shell, user's encrypted password and
1971 login shell, are also tainted, because of the same reason.
1972
1973 In scalar context, you get the name, unless the function was a
1974 lookup by name, in which case you get the other thing, whatever it is.
1975 (If the entry doesn't exist you get the undefined value.)  For example:
1976
1977     $uid   = getpwnam($name);
1978     $name  = getpwuid($num);
1979     $name  = getpwent();
1980     $gid   = getgrnam($name);
1981     $name  = getgrgid($num);
1982     $name  = getgrent();
1983     #etc.
1984
1985 In I<getpw*()> the fields $quota, $comment, and $expire are special
1986 cases in the sense that in many systems they are unsupported.  If the
1987 $quota is unsupported, it is an empty scalar.  If it is supported, it
1988 usually encodes the disk quota.  If the $comment field is unsupported,
1989 it is an empty scalar.  If it is supported it usually encodes some
1990 administrative comment about the user.  In some systems the $quota
1991 field may be $change or $age, fields that have to do with password
1992 aging.  In some systems the $comment field may be $class.  The $expire
1993 field, if present, encodes the expiration period of the account or the
1994 password.  For the availability and the exact meaning of these fields
1995 in your system, please consult your getpwnam(3) documentation and your
1996 F<pwd.h> file.  You can also find out from within Perl what your
1997 $quota and $comment fields mean and whether you have the $expire field
1998 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
1999 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2000 files are only supported if your vendor has implemented them in the
2001 intuitive fashion that calling the regular C library routines gets the
2002 shadow versions if you're running under privilege or if there exists
2003 the shadow(3) functions as found in System V ( this includes Solaris
2004 and Linux.)  Those systems which implement a proprietary shadow password
2005 facility are unlikely to be supported.
2006
2007 The $members value returned by I<getgr*()> is a space separated list of
2008 the login names of the members of the group.
2009
2010 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2011 C, it will be returned to you via C<$?> if the function call fails.  The
2012 C<@addrs> value returned by a successful call is a list of the raw
2013 addresses returned by the corresponding system library call.  In the
2014 Internet domain, each address is four bytes long and you can unpack it
2015 by saying something like:
2016
2017     ($a,$b,$c,$d) = unpack('C4',$addr[0]);
2018
2019 The Socket library makes this slightly easier:
2020
2021     use Socket;
2022     $iaddr = inet_aton("127.1"); # or whatever address
2023     $name  = gethostbyaddr($iaddr, AF_INET);
2024
2025     # or going the other way
2026     $straddr = inet_ntoa($iaddr);
2027
2028 If you get tired of remembering which element of the return list
2029 contains which return value, by-name interfaces are provided
2030 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2031 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2032 and C<User::grent>.  These override the normal built-ins, supplying
2033 versions that return objects with the appropriate names
2034 for each field.  For example:
2035
2036    use File::stat;
2037    use User::pwent;
2038    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2039
2040 Even though it looks like they're the same method calls (uid),
2041 they aren't, because a C<File::stat> object is different from
2042 a C<User::pwent> object.
2043
2044 =item getsockname SOCKET
2045
2046 Returns the packed sockaddr address of this end of the SOCKET connection,
2047 in case you don't know the address because you have several different
2048 IPs that the connection might have come in on.
2049
2050     use Socket;
2051     $mysockaddr = getsockname(SOCK);
2052     ($port, $myaddr) = sockaddr_in($mysockaddr);
2053     printf "Connect to %s [%s]\n",
2054        scalar gethostbyaddr($myaddr, AF_INET),
2055        inet_ntoa($myaddr);
2056
2057 =item getsockopt SOCKET,LEVEL,OPTNAME
2058
2059 Returns the socket option requested, or undef if there is an error.
2060
2061 =item glob EXPR
2062
2063 =item glob
2064
2065 In list context, returns a (possibly empty) list of filename expansions on
2066 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2067 scalar context, glob iterates through such filename expansions, returning
2068 undef when the list is exhausted. This is the internal function
2069 implementing the C<< <*.c> >> operator, but you can use it directly. If
2070 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2071 more detail in L<perlop/"I/O Operators">.
2072
2073 Beginning with v5.6.0, this operator is implemented using the standard
2074 C<File::Glob> extension.  See L<File::Glob> for details.
2075
2076 =item gmtime EXPR
2077
2078 Converts a time as returned by the time function to an 8-element list
2079 with the time localized for the standard Greenwich time zone.
2080 Typically used as follows:
2081
2082     #  0    1    2     3     4    5     6     7
2083     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2084                                             gmtime(time);
2085
2086 All list elements are numeric, and come straight out of the C `struct
2087 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2088 specified time.  $mday is the day of the month, and $mon is the month
2089 itself, in the range C<0..11> with 0 indicating January and 11
2090 indicating December.  $year is the number of years since 1900.  That
2091 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2092 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2093 the year, in the range C<0..364> (or C<0..365> in leap years.)
2094
2095 Note that the $year element is I<not> simply the last two digits of
2096 the year.  If you assume it is, then you create non-Y2K-compliant
2097 programs--and you wouldn't want to do that, would you?
2098
2099 The proper way to get a complete 4-digit year is simply:
2100
2101         $year += 1900;
2102
2103 And to get the last two digits of the year (e.g., '01' in 2001) do:
2104
2105         $year = sprintf("%02d", $year % 100);
2106
2107 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2108
2109 In scalar context, C<gmtime()> returns the ctime(3) value:
2110
2111     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2112
2113 Also see the C<timegm> function provided by the C<Time::Local> module,
2114 and the strftime(3) function available via the POSIX module.
2115
2116 This scalar value is B<not> locale dependent (see L<perllocale>), but
2117 is instead a Perl builtin.  Also see the C<Time::Local> module, and the
2118 strftime(3) and mktime(3) functions available via the POSIX module.  To
2119 get somewhat similar but locale dependent date strings, set up your
2120 locale environment variables appropriately (please see L<perllocale>)
2121 and try for example:
2122
2123     use POSIX qw(strftime);
2124     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2125
2126 Note that the C<%a> and C<%b> escapes, which represent the short forms
2127 of the day of the week and the month of the year, may not necessarily
2128 be three characters wide in all locales.
2129
2130 =item goto LABEL
2131
2132 =item goto EXPR
2133
2134 =item goto &NAME
2135
2136 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2137 execution there.  It may not be used to go into any construct that
2138 requires initialization, such as a subroutine or a C<foreach> loop.  It
2139 also can't be used to go into a construct that is optimized away,
2140 or to get out of a block or subroutine given to C<sort>.
2141 It can be used to go almost anywhere else within the dynamic scope,
2142 including out of subroutines, but it's usually better to use some other
2143 construct such as C<last> or C<die>.  The author of Perl has never felt the
2144 need to use this form of C<goto> (in Perl, that is--C is another matter).
2145 (The difference being that C does not offer named loops combined with
2146 loop control.  Perl does, and this replaces most structured uses of C<goto>
2147 in other languages.)
2148
2149 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2150 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2151 necessarily recommended if you're optimizing for maintainability:
2152
2153     goto ("FOO", "BAR", "GLARCH")[$i];
2154
2155 The C<goto-&NAME> form is quite different from the other forms of
2156 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2157 doesn't have the stigma associated with other gotos.  Instead, it
2158 exits the current subroutine (losing any changes set by local()) and
2159 immediately calls in its place the named subroutine using the current
2160 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2161 load another subroutine and then pretend that the other subroutine had
2162 been called in the first place (except that any modifications to C<@_>
2163 in the current subroutine are propagated to the other subroutine.)
2164 After the C<goto>, not even C<caller> will be able to tell that this
2165 routine was called first.
2166
2167 NAME needn't be the name of a subroutine; it can be a scalar variable
2168 containing a code reference, or a block which evaluates to a code
2169 reference.
2170
2171 =item grep BLOCK LIST
2172
2173 =item grep EXPR,LIST
2174
2175 This is similar in spirit to, but not the same as, grep(1) and its
2176 relatives.  In particular, it is not limited to using regular expressions.
2177
2178 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2179 C<$_> to each element) and returns the list value consisting of those
2180 elements for which the expression evaluated to true.  In scalar
2181 context, returns the number of times the expression was true.
2182
2183     @foo = grep(!/^#/, @bar);    # weed out comments
2184
2185 or equivalently,
2186
2187     @foo = grep {!/^#/} @bar;    # weed out comments
2188
2189 Note that C<$_> is an alias to the list value, so it can be used to
2190 modify the elements of the LIST.  While this is useful and supported,
2191 it can cause bizarre results if the elements of LIST are not variables.
2192 Similarly, grep returns aliases into the original list, much as a for
2193 loop's index variable aliases the list elements.  That is, modifying an
2194 element of a list returned by grep (for example, in a C<foreach>, C<map>
2195 or another C<grep>) actually modifies the element in the original list.
2196 This is usually something to be avoided when writing clear code.
2197
2198 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2199
2200 =item hex EXPR
2201
2202 =item hex
2203
2204 Interprets EXPR as a hex string and returns the corresponding value.
2205 (To convert strings that might start with either 0, 0x, or 0b, see
2206 L</oct>.)  If EXPR is omitted, uses C<$_>.
2207
2208     print hex '0xAf'; # prints '175'
2209     print hex 'aF';   # same
2210
2211 Hex strings may only represent integers.  Strings that would cause
2212 integer overflow trigger a warning.  Leading whitespace is not stripped,
2213 unlike oct().
2214
2215 =item import
2216
2217 There is no builtin C<import> function.  It is just an ordinary
2218 method (subroutine) defined (or inherited) by modules that wish to export
2219 names to another module.  The C<use> function calls the C<import> method
2220 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2221
2222 =item index STR,SUBSTR,POSITION
2223
2224 =item index STR,SUBSTR
2225
2226 The index function searches for one string within another, but without
2227 the wildcard-like behavior of a full regular-expression pattern match.
2228 It returns the position of the first occurrence of SUBSTR in STR at
2229 or after POSITION.  If POSITION is omitted, starts searching from the
2230 beginning of the string.  The return value is based at C<0> (or whatever
2231 you've set the C<$[> variable to--but don't do that).  If the substring
2232 is not found, returns one less than the base, ordinarily C<-1>.
2233
2234 =item int EXPR
2235
2236 =item int
2237
2238 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2239 You should not use this function for rounding: one because it truncates
2240 towards C<0>, and two because machine representations of floating point
2241 numbers can sometimes produce counterintuitive results.  For example,
2242 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2243 because it's really more like -268.99999999999994315658 instead.  Usually,
2244 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2245 functions will serve you better than will int().
2246
2247 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2248
2249 Implements the ioctl(2) function.  You'll probably first have to say
2250
2251     require "ioctl.ph"; # probably in /usr/local/lib/perl/ioctl.ph
2252
2253 to get the correct function definitions.  If F<ioctl.ph> doesn't
2254 exist or doesn't have the correct definitions you'll have to roll your
2255 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2256 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2257 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2258 written depending on the FUNCTION--a pointer to the string value of SCALAR
2259 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2260 has no string value but does have a numeric value, that value will be
2261 passed rather than a pointer to the string value.  To guarantee this to be
2262 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2263 functions may be needed to manipulate the values of structures used by
2264 C<ioctl>.
2265
2266 The return value of C<ioctl> (and C<fcntl>) is as follows:
2267
2268         if OS returns:          then Perl returns:
2269             -1                    undefined value
2270              0                  string "0 but true"
2271         anything else               that number
2272
2273 Thus Perl returns true on success and false on failure, yet you can
2274 still easily determine the actual value returned by the operating
2275 system:
2276
2277     $retval = ioctl(...) || -1;
2278     printf "System returned %d\n", $retval;
2279
2280 The special string "C<0> but true" is exempt from B<-w> complaints
2281 about improper numeric conversions.
2282
2283 Here's an example of setting a filehandle named C<REMOTE> to be
2284 non-blocking at the system level.  You'll have to negotiate C<$|>
2285 on your own, though.
2286
2287     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2288
2289     $flags = fcntl(REMOTE, F_GETFL, 0)
2290                 or die "Can't get flags for the socket: $!\n";
2291
2292     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2293                 or die "Can't set flags for the socket: $!\n";
2294
2295 =item join EXPR,LIST
2296
2297 Joins the separate strings of LIST into a single string with fields
2298 separated by the value of EXPR, and returns that new string.  Example:
2299
2300     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2301
2302 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2303 first argument.  Compare L</split>.
2304
2305 =item keys HASH
2306
2307 Returns a list consisting of all the keys of the named hash.  (In
2308 scalar context, returns the number of keys.)  The keys are returned in
2309 an apparently random order.  The actual random order is subject to
2310 change in future versions of perl, but it is guaranteed to be the same
2311 order as either the C<values> or C<each> function produces (given
2312 that the hash has not been modified).  As a side effect, it resets
2313 HASH's iterator.
2314
2315 Here is yet another way to print your environment:
2316
2317     @keys = keys %ENV;
2318     @values = values %ENV;
2319     while (@keys) {
2320         print pop(@keys), '=', pop(@values), "\n";
2321     }
2322
2323 or how about sorted by key:
2324
2325     foreach $key (sort(keys %ENV)) {
2326         print $key, '=', $ENV{$key}, "\n";
2327     }
2328
2329 The returned values are copies of the original keys in the hash, so
2330 modifying them will not affect the original hash.  Compare L</values>.
2331
2332 To sort a hash by value, you'll need to use a C<sort> function.
2333 Here's a descending numeric sort of a hash by its values:
2334
2335     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2336         printf "%4d %s\n", $hash{$key}, $key;
2337     }
2338
2339 As an lvalue C<keys> allows you to increase the number of hash buckets
2340 allocated for the given hash.  This can gain you a measure of efficiency if
2341 you know the hash is going to get big.  (This is similar to pre-extending
2342 an array by assigning a larger number to $#array.)  If you say
2343
2344     keys %hash = 200;
2345
2346 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2347 in fact, since it rounds up to the next power of two.  These
2348 buckets will be retained even if you do C<%hash = ()>, use C<undef
2349 %hash> if you want to free the storage while C<%hash> is still in scope.
2350 You can't shrink the number of buckets allocated for the hash using
2351 C<keys> in this way (but you needn't worry about doing this by accident,
2352 as trying has no effect).
2353
2354 See also C<each>, C<values> and C<sort>.
2355
2356 =item kill SIGNAL, LIST
2357
2358 Sends a signal to a list of processes.  Returns the number of
2359 processes successfully signaled (which is not necessarily the
2360 same as the number actually killed).
2361
2362     $cnt = kill 1, $child1, $child2;
2363     kill 9, @goners;
2364
2365 If SIGNAL is zero, no signal is sent to the process.  This is a
2366 useful way to check that the process is alive and hasn't changed
2367 its UID.  See L<perlport> for notes on the portability of this
2368 construct.
2369
2370 Unlike in the shell, if SIGNAL is negative, it kills
2371 process groups instead of processes.  (On System V, a negative I<PROCESS>
2372 number will also kill process groups, but that's not portable.)  That
2373 means you usually want to use positive not negative signals.  You may also
2374 use a signal name in quotes.  See L<perlipc/"Signals"> for details.
2375
2376 =item last LABEL
2377
2378 =item last
2379
2380 The C<last> command is like the C<break> statement in C (as used in
2381 loops); it immediately exits the loop in question.  If the LABEL is
2382 omitted, the command refers to the innermost enclosing loop.  The
2383 C<continue> block, if any, is not executed:
2384
2385     LINE: while (<STDIN>) {
2386         last LINE if /^$/;      # exit when done with header
2387         #...
2388     }
2389
2390 C<last> cannot be used to exit a block which returns a value such as
2391 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2392 a grep() or map() operation.
2393
2394 Note that a block by itself is semantically identical to a loop
2395 that executes once.  Thus C<last> can be used to effect an early
2396 exit out of such a block.
2397
2398 See also L</continue> for an illustration of how C<last>, C<next>, and
2399 C<redo> work.
2400
2401 =item lc EXPR
2402
2403 =item lc
2404
2405 Returns a lowercased version of EXPR.  This is the internal function
2406 implementing the C<\L> escape in double-quoted strings.  Respects
2407 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2408 and L<perlunicode> for more details about locale and Unicode support.
2409
2410 If EXPR is omitted, uses C<$_>.
2411
2412 =item lcfirst EXPR
2413
2414 =item lcfirst
2415
2416 Returns the value of EXPR with the first character lowercased.  This
2417 is the internal function implementing the C<\l> escape in
2418 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2419 locale> in force.  See L<perllocale> and L<perlunicode> for more
2420 details about locale and Unicode support.
2421
2422 If EXPR is omitted, uses C<$_>.
2423
2424 =item length EXPR
2425
2426 =item length
2427
2428 Returns the length in characters of the value of EXPR.  If EXPR is
2429 omitted, returns length of C<$_>.  Note that this cannot be used on
2430 an entire array or hash to find out how many elements these have.
2431 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2432
2433 =item link OLDFILE,NEWFILE
2434
2435 Creates a new filename linked to the old filename.  Returns true for
2436 success, false otherwise.
2437
2438 =item listen SOCKET,QUEUESIZE
2439
2440 Does the same thing that the listen system call does.  Returns true if
2441 it succeeded, false otherwise.  See the example in
2442 L<perlipc/"Sockets: Client/Server Communication">.
2443
2444 =item local EXPR
2445
2446 You really probably want to be using C<my> instead, because C<local> isn't
2447 what most people think of as "local".  See
2448 L<perlsub/"Private Variables via my()"> for details.
2449
2450 A local modifies the listed variables to be local to the enclosing
2451 block, file, or eval.  If more than one value is listed, the list must
2452 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2453 for details, including issues with tied arrays and hashes.
2454
2455 =item localtime EXPR
2456
2457 Converts a time as returned by the time function to a 9-element list
2458 with the time analyzed for the local time zone.  Typically used as
2459 follows:
2460
2461     #  0    1    2     3     4    5     6     7     8
2462     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2463                                                 localtime(time);
2464
2465 All list elements are numeric, and come straight out of the C `struct
2466 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2467 specified time.  $mday is the day of the month, and $mon is the month
2468 itself, in the range C<0..11> with 0 indicating January and 11
2469 indicating December.  $year is the number of years since 1900.  That
2470 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2471 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2472 the year, in the range C<0..364> (or C<0..365> in leap years.)  $isdst
2473 is true if the specified time occurs during daylight savings time,
2474 false otherwise.
2475
2476 Note that the $year element is I<not> simply the last two digits of
2477 the year.  If you assume it is, then you create non-Y2K-compliant
2478 programs--and you wouldn't want to do that, would you?
2479
2480 The proper way to get a complete 4-digit year is simply:
2481
2482         $year += 1900;
2483
2484 And to get the last two digits of the year (e.g., '01' in 2001) do:
2485
2486         $year = sprintf("%02d", $year % 100);
2487
2488 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2489
2490 In scalar context, C<localtime()> returns the ctime(3) value:
2491
2492     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2493
2494 This scalar value is B<not> locale dependent, see L<perllocale>, but
2495 instead a Perl builtin.  Also see the C<Time::Local> module
2496 (to convert the second, minutes, hours, ... back to seconds since the
2497 stroke of midnight the 1st of January 1970, the value returned by
2498 time()), and the strftime(3) and mktime(3) functions available via the
2499 POSIX module.  To get somewhat similar but locale dependent date
2500 strings, set up your locale environment variables appropriately
2501 (please see L<perllocale>) and try for example:
2502
2503     use POSIX qw(strftime);
2504     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2505
2506 Note that the C<%a> and C<%b>, the short forms of the day of the week
2507 and the month of the year, may not necessarily be three characters wide.
2508
2509 =item lock THING
2510
2511 This function places an advisory lock on a shared variable, or referenced
2512 object contained in I<THING> until the lock goes out of scope.
2513
2514 lock() is a "weak keyword" : this means that if you've defined a function
2515 by this name (before any calls to it), that function will be called
2516 instead. (However, if you've said C<use threads>, lock() is always a
2517 keyword.) See L<threads>.
2518
2519 =item log EXPR
2520
2521 =item log
2522
2523 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2524 returns log of C<$_>.  To get the log of another base, use basic algebra:
2525 The base-N log of a number is equal to the natural log of that number
2526 divided by the natural log of N.  For example:
2527
2528     sub log10 {
2529         my $n = shift;
2530         return log($n)/log(10);
2531     }
2532
2533 See also L</exp> for the inverse operation.
2534
2535 =item lstat EXPR
2536
2537 =item lstat
2538
2539 Does the same thing as the C<stat> function (including setting the
2540 special C<_> filehandle) but stats a symbolic link instead of the file
2541 the symbolic link points to.  If symbolic links are unimplemented on
2542 your system, a normal C<stat> is done.  For much more detailed
2543 information, please see the documentation for C<stat>.
2544
2545 If EXPR is omitted, stats C<$_>.
2546
2547 =item m//
2548
2549 The match operator.  See L<perlop>.
2550
2551 =item map BLOCK LIST
2552
2553 =item map EXPR,LIST
2554
2555 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2556 C<$_> to each element) and returns the list value composed of the
2557 results of each such evaluation.  In scalar context, returns the
2558 total number of elements so generated.  Evaluates BLOCK or EXPR in
2559 list context, so each element of LIST may produce zero, one, or
2560 more elements in the returned value.
2561
2562     @chars = map(chr, @nums);
2563
2564 translates a list of numbers to the corresponding characters.  And
2565
2566     %hash = map { getkey($_) => $_ } @array;
2567
2568 is just a funny way to write
2569
2570     %hash = ();
2571     foreach $_ (@array) {
2572         $hash{getkey($_)} = $_;
2573     }
2574
2575 Note that C<$_> is an alias to the list value, so it can be used to
2576 modify the elements of the LIST.  While this is useful and supported,
2577 it can cause bizarre results if the elements of LIST are not variables.
2578 Using a regular C<foreach> loop for this purpose would be clearer in
2579 most cases.  See also L</grep> for an array composed of those items of
2580 the original list for which the BLOCK or EXPR evaluates to true.
2581
2582 C<{> starts both hash references and blocks, so C<map { ...> could be either
2583 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2584 ahead for the closing C<}> it has to take a guess at which its dealing with
2585 based what it finds just after the C<{>. Usually it gets it right, but if it
2586 doesn't it won't realize something is wrong until it gets to the C<}> and
2587 encounters the missing (or unexpected) comma. The syntax error will be
2588 reported close to the C<}> but you'll need to change something near the C<{>
2589 such as using a unary C<+> to give perl some help:
2590
2591     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2592     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2593     %hash = map { ("\L$_", 1) } @array  # this also works
2594     %hash = map {  lc($_), 1  } @array  # as does this.
2595     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2596
2597     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2598
2599 or to force an anon hash constructor use C<+{>
2600
2601    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2602
2603 and you get list of anonymous hashes each with only 1 entry.
2604
2605 =item mkdir FILENAME,MASK
2606
2607 =item mkdir FILENAME
2608
2609 Creates the directory specified by FILENAME, with permissions
2610 specified by MASK (as modified by C<umask>).  If it succeeds it
2611 returns true, otherwise it returns false and sets C<$!> (errno).
2612 If omitted, MASK defaults to 0777.
2613
2614 In general, it is better to create directories with permissive MASK,
2615 and let the user modify that with their C<umask>, than it is to supply
2616 a restrictive MASK and give the user no way to be more permissive.
2617 The exceptions to this rule are when the file or directory should be
2618 kept private (mail files, for instance).  The perlfunc(1) entry on
2619 C<umask> discusses the choice of MASK in more detail.
2620
2621 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2622 number of trailing slashes.  Some operating and filesystems do not get
2623 this right, so Perl automatically removes all trailing slashes to keep
2624 everyone happy.
2625
2626 =item msgctl ID,CMD,ARG
2627
2628 Calls the System V IPC function msgctl(2).  You'll probably have to say
2629
2630     use IPC::SysV;
2631
2632 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2633 then ARG must be a variable which will hold the returned C<msqid_ds>
2634 structure.  Returns like C<ioctl>: the undefined value for error,
2635 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2636 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2637
2638 =item msgget KEY,FLAGS
2639
2640 Calls the System V IPC function msgget(2).  Returns the message queue
2641 id, or the undefined value if there is an error.  See also
2642 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2643
2644 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2645
2646 Calls the System V IPC function msgrcv to receive a message from
2647 message queue ID into variable VAR with a maximum message size of
2648 SIZE.  Note that when a message is received, the message type as a
2649 native long integer will be the first thing in VAR, followed by the
2650 actual message.  This packing may be opened with C<unpack("l! a*")>.
2651 Taints the variable.  Returns true if successful, or false if there is
2652 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2653 C<IPC::SysV::Msg> documentation.
2654
2655 =item msgsnd ID,MSG,FLAGS
2656
2657 Calls the System V IPC function msgsnd to send the message MSG to the
2658 message queue ID.  MSG must begin with the native long integer message
2659 type, and be followed by the length of the actual message, and finally
2660 the message itself.  This kind of packing can be achieved with
2661 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2662 or false if there is an error.  See also C<IPC::SysV>
2663 and C<IPC::SysV::Msg> documentation.
2664
2665 =item my EXPR
2666
2667 =item my TYPE EXPR
2668
2669 =item my EXPR : ATTRS
2670
2671 =item my TYPE EXPR : ATTRS
2672
2673 A C<my> declares the listed variables to be local (lexically) to the
2674 enclosing block, file, or C<eval>.  If more than one value is listed,
2675 the list must be placed in parentheses.
2676
2677 The exact semantics and interface of TYPE and ATTRS are still
2678 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2679 and attributes are handled using the C<attributes> pragma, or starting
2680 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2681 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2682 L<attributes>, and L<Attribute::Handlers>.
2683
2684 =item next LABEL
2685
2686 =item next
2687
2688 The C<next> command is like the C<continue> statement in C; it starts
2689 the next iteration of the loop:
2690
2691     LINE: while (<STDIN>) {
2692         next LINE if /^#/;      # discard comments
2693         #...
2694     }
2695
2696 Note that if there were a C<continue> block on the above, it would get
2697 executed even on discarded lines.  If the LABEL is omitted, the command
2698 refers to the innermost enclosing loop.
2699
2700 C<next> cannot be used to exit a block which returns a value such as
2701 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2702 a grep() or map() operation.
2703
2704 Note that a block by itself is semantically identical to a loop
2705 that executes once.  Thus C<next> will exit such a block early.
2706
2707 See also L</continue> for an illustration of how C<last>, C<next>, and
2708 C<redo> work.
2709
2710 =item no Module VERSION LIST
2711
2712 =item no Module VERSION
2713
2714 =item no Module LIST
2715
2716 =item no Module
2717
2718 See the C<use> function, which C<no> is the opposite of.
2719
2720 =item oct EXPR
2721
2722 =item oct
2723
2724 Interprets EXPR as an octal string and returns the corresponding
2725 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2726 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2727 binary string.  Leading whitespace is ignored in all three cases.)
2728 The following will handle decimal, binary, octal, and hex in the standard
2729 Perl or C notation:
2730
2731     $val = oct($val) if $val =~ /^0/;
2732
2733 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2734 in octal), use sprintf() or printf():
2735
2736     $perms = (stat("filename"))[2] & 07777;
2737     $oct_perms = sprintf "%lo", $perms;
2738
2739 The oct() function is commonly used when a string such as C<644> needs
2740 to be converted into a file mode, for example. (Although perl will
2741 automatically convert strings into numbers as needed, this automatic
2742 conversion assumes base 10.)
2743
2744 =item open FILEHANDLE,EXPR
2745
2746 =item open FILEHANDLE,MODE,EXPR
2747
2748 =item open FILEHANDLE,MODE,EXPR,LIST
2749
2750 =item open FILEHANDLE,MODE,REFERENCE
2751
2752 =item open FILEHANDLE
2753
2754 Opens the file whose filename is given by EXPR, and associates it with
2755 FILEHANDLE.
2756
2757 (The following is a comprehensive reference to open(): for a gentler
2758 introduction you may consider L<perlopentut>.)
2759
2760 If FILEHANDLE is an undefined lexical (C<my>) variable the variable is
2761 assigned a reference to a new anonymous filehandle, otherwise if
2762 FILEHANDLE is an expression, its value is used as the name of the real
2763 filehandle wanted.  (This is considered a symbolic reference, so C<use
2764 strict 'refs'> should I<not> be in effect.)
2765
2766 If EXPR is omitted, the scalar variable of the same name as the
2767 FILEHANDLE contains the filename.  (Note that lexical variables--those
2768 declared with C<my>--will not work for this purpose; so if you're
2769 using C<my>, specify EXPR in your call to open.)
2770
2771 If three or more arguments are specified then the mode of opening and
2772 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2773 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2774 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2775 the file is opened for appending, again being created if necessary.
2776
2777 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2778 indicate that you want both read and write access to the file; thus
2779 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2780 '+>' >> mode would clobber the file first.  You can't usually use
2781 either read-write mode for updating textfiles, since they have
2782 variable length records.  See the B<-i> switch in L<perlrun> for a
2783 better approach.  The file is created with permissions of C<0666>
2784 modified by the process' C<umask> value.
2785
2786 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2787 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2788
2789 In the 2-arguments (and 1-argument) form of the call the mode and
2790 filename should be concatenated (in this order), possibly separated by
2791 spaces.  It is possible to omit the mode in these forms if the mode is
2792 C<< '<' >>.
2793
2794 If the filename begins with C<'|'>, the filename is interpreted as a
2795 command to which output is to be piped, and if the filename ends with a
2796 C<'|'>, the filename is interpreted as a command which pipes output to
2797 us.  See L<perlipc/"Using open() for IPC">
2798 for more examples of this.  (You are not allowed to C<open> to a command
2799 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2800 and L<perlipc/"Bidirectional Communication with Another Process">
2801 for alternatives.)
2802
2803 For three or more arguments if MODE is C<'|-'>, the filename is
2804 interpreted as a command to which output is to be piped, and if MODE
2805 is C<'-|'>, the filename is interpreted as a command which pipes
2806 output to us.  In the 2-arguments (and 1-argument) form one should
2807 replace dash (C<'-'>) with the command.
2808 See L<perlipc/"Using open() for IPC"> for more examples of this.
2809 (You are not allowed to C<open> to a command that pipes both in I<and>
2810 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2811 L<perlipc/"Bidirectional Communication"> for alternatives.)
2812
2813 In the three-or-more argument form of pipe opens, if LIST is specified
2814 (extra arguments after the command name) then LIST becomes arguments
2815 to the command invoked if the platform supports it.  The meaning of
2816 C<open> with more than three arguments for non-pipe modes is not yet
2817 specified. Experimental "layers" may give extra LIST arguments
2818 meaning.
2819
2820 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2821 and opening C<< '>-' >> opens STDOUT.
2822
2823 You may use the three-argument form of open to specify IO "layers"
2824 (sometimes also referred to as "disciplines") to be applied to the handle
2825 that affect how the input and output are processed (see L<open> and
2826 L<PerlIO> for more details). For example
2827
2828   open(FH, "<:utf8", "file")
2829
2830 will open the UTF-8 encoded file containing Unicode characters,
2831 see L<perluniintro>. (Note that if layers are specified in the
2832 three-arg form then default layers set by the C<open> pragma are
2833 ignored.)
2834
2835 Open returns nonzero upon success, the undefined value otherwise.  If
2836 the C<open> involved a pipe, the return value happens to be the pid of
2837 the subprocess.
2838
2839 If you're running Perl on a system that distinguishes between text
2840 files and binary files, then you should check out L</binmode> for tips
2841 for dealing with this.  The key distinction between systems that need
2842 C<binmode> and those that don't is their text file formats.  Systems
2843 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2844 character, and which encode that character in C as C<"\n">, do not
2845 need C<binmode>.  The rest need it.
2846
2847 When opening a file, it's usually a bad idea to continue normal execution
2848 if the request failed, so C<open> is frequently used in connection with
2849 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2850 where you want to make a nicely formatted error message (but there are
2851 modules that can help with that problem)) you should always check
2852 the return value from opening a file.  The infrequent exception is when
2853 working with an unopened filehandle is actually what you want to do.
2854
2855 As a special case the 3 arg form with a read/write mode and the third
2856 argument being C<undef>:
2857
2858     open(TMP, "+>", undef) or die ...
2859
2860 opens a filehandle to an anonymous temporary file.
2861
2862 File handles can be opened to "in memory" files held in Perl scalars via:
2863
2864     open($fh, '>', \$variable) || ..
2865
2866 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
2867 file, you have to close it first:
2868
2869     close STDOUT;
2870     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
2871
2872 Examples:
2873
2874     $ARTICLE = 100;
2875     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
2876     while (<ARTICLE>) {...
2877
2878     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
2879     # if the open fails, output is discarded
2880
2881     open(DBASE, '+<', 'dbase.mine')             # open for update
2882         or die "Can't open 'dbase.mine' for update: $!";
2883
2884     open(DBASE, '+<dbase.mine')                 # ditto
2885         or die "Can't open 'dbase.mine' for update: $!";
2886
2887     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
2888         or die "Can't start caesar: $!";
2889
2890     open(ARTICLE, "caesar <$article |")         # ditto
2891         or die "Can't start caesar: $!";
2892
2893     open(EXTRACT, "|sort >/tmp/Tmp$$")          # $$ is our process id
2894         or die "Can't start sort: $!";
2895
2896     # in memory files
2897     open(MEMORY,'>', \$var)
2898         or die "Can't open memory file: $!";
2899     print MEMORY "foo!\n";                      # output will end up in $var
2900
2901     # process argument list of files along with any includes
2902
2903     foreach $file (@ARGV) {
2904         process($file, 'fh00');
2905     }
2906
2907     sub process {
2908         my($filename, $input) = @_;
2909         $input++;               # this is a string increment
2910         unless (open($input, $filename)) {
2911             print STDERR "Can't open $filename: $!\n";
2912             return;
2913         }
2914
2915         local $_;
2916         while (<$input>) {              # note use of indirection
2917             if (/^#include "(.*)"/) {
2918                 process($1, $input);
2919                 next;
2920             }
2921             #...                # whatever
2922         }
2923     }
2924
2925 You may also, in the Bourne shell tradition, specify an EXPR beginning
2926 with C<< '>&' >>, in which case the rest of the string is interpreted as the
2927 name of a filehandle (or file descriptor, if numeric) to be
2928 duped and opened.  You may use C<&> after C<< > >>, C<<< >> >>>,
2929 C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.  The
2930 mode you specify should match the mode of the original filehandle.
2931 (Duping a filehandle does not take into account any existing contents of
2932 IO buffers.) If you use the 3 arg form then you can pass either a number,
2933 the name of a filehandle or the normal "reference to a glob".
2934
2935 Here is a script that saves, redirects, and restores C<STDOUT> and
2936 C<STDERR> using various methods:
2937
2938     #!/usr/bin/perl
2939     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2940     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
2941
2942     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
2943     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
2944
2945     select STDERR; $| = 1;      # make unbuffered
2946     select STDOUT; $| = 1;      # make unbuffered
2947
2948     print STDOUT "stdout 1\n";  # this works for
2949     print STDERR "stderr 1\n";  # subprocesses too
2950
2951     close STDOUT;
2952     close STDERR;
2953
2954     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
2955     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
2956
2957     print STDOUT "stdout 2\n";
2958     print STDERR "stderr 2\n";
2959
2960 If you specify C<< '<&=N' >>, where C<N> is a number, then Perl will
2961 do an equivalent of C's C<fdopen> of that file descriptor; this is
2962 more parsimonious of file descriptors.  For example:
2963
2964     open(FILEHANDLE, "<&=$fd")
2965
2966 or
2967
2968     open(FILEHANDLE, "<&=", $fd)
2969
2970 Note that if Perl is using the standard C libraries' fdopen() then on
2971 many UNIX systems, fdopen() is known to fail when file descriptors
2972 exceed a certain value, typically 255. If you need more file
2973 descriptors than that, consider rebuilding Perl to use the C<PerlIO>.
2974
2975 You can see whether Perl has been compiled with PerlIO or not by
2976 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
2977 is C<define>, you have PerlIO, otherwise you don't.
2978
2979 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
2980 with 2-arguments (or 1-argument) form of open(), then
2981 there is an implicit fork done, and the return value of open is the pid
2982 of the child within the parent process, and C<0> within the child
2983 process.  (Use C<defined($pid)> to determine whether the open was successful.)
2984 The filehandle behaves normally for the parent, but i/o to that
2985 filehandle is piped from/to the STDOUT/STDIN of the child process.
2986 In the child process the filehandle isn't opened--i/o happens from/to
2987 the new STDOUT or STDIN.  Typically this is used like the normal
2988 piped open when you want to exercise more control over just how the
2989 pipe command gets executed, such as when you are running setuid, and
2990 don't want to have to scan shell commands for metacharacters.
2991 The following triples are more or less equivalent:
2992
2993     open(FOO, "|tr '[a-z]' '[A-Z]'");
2994     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
2995     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
2996     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
2997
2998     open(FOO, "cat -n '$file'|");
2999     open(FOO, '-|', "cat -n '$file'");
3000     open(FOO, '-|') || exec 'cat', '-n', $file;
3001     open(FOO, '-|', "cat", '-n', $file);
3002
3003 The last example in each block shows the pipe as "list form", which is
3004 not yet supported on all platforms.  A good rule of thumb is that if
3005 your platform has true C<fork()> (in other words, if your platform is
3006 UNIX) you can use the list form.
3007
3008 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3009
3010 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3011 output before any operation that may do a fork, but this may not be
3012 supported on some platforms (see L<perlport>).  To be safe, you may need
3013 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3014 of C<IO::Handle> on any open handles.
3015
3016 On systems that support a close-on-exec flag on files, the flag will
3017 be set for the newly opened file descriptor as determined by the value
3018 of $^F.  See L<perlvar/$^F>.
3019
3020 Closing any piped filehandle causes the parent process to wait for the
3021 child to finish, and returns the status value in C<$?>.
3022
3023 The filename passed to 2-argument (or 1-argument) form of open() will
3024 have leading and trailing whitespace deleted, and the normal
3025 redirection characters honored.  This property, known as "magic open",
3026 can often be used to good effect.  A user could specify a filename of
3027 F<"rsh cat file |">, or you could change certain filenames as needed:
3028
3029     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3030     open(FH, $filename) or die "Can't open $filename: $!";
3031
3032 Use 3-argument form to open a file with arbitrary weird characters in it,
3033
3034     open(FOO, '<', $file);
3035
3036 otherwise it's necessary to protect any leading and trailing whitespace:
3037
3038     $file =~ s#^(\s)#./$1#;
3039     open(FOO, "< $file\0");
3040
3041 (this may not work on some bizarre filesystems).  One should
3042 conscientiously choose between the I<magic> and 3-arguments form
3043 of open():
3044
3045     open IN, $ARGV[0];
3046
3047 will allow the user to specify an argument of the form C<"rsh cat file |">,
3048 but will not work on a filename which happens to have a trailing space, while
3049
3050     open IN, '<', $ARGV[0];
3051
3052 will have exactly the opposite restrictions.
3053
3054 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3055 should use the C<sysopen> function, which involves no such magic (but
3056 may use subtly different filemodes than Perl open(), which is mapped
3057 to C fopen()).  This is
3058 another way to protect your filenames from interpretation.  For example:
3059
3060     use IO::Handle;
3061     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3062         or die "sysopen $path: $!";
3063     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3064     print HANDLE "stuff $$\n";
3065     seek(HANDLE, 0, 0);
3066     print "File contains: ", <HANDLE>;
3067
3068 Using the constructor from the C<IO::Handle> package (or one of its
3069 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3070 filehandles that have the scope of whatever variables hold references to
3071 them, and automatically close whenever and however you leave that scope:
3072
3073     use IO::File;
3074     #...
3075     sub read_myfile_munged {
3076         my $ALL = shift;
3077         my $handle = new IO::File;
3078         open($handle, "myfile") or die "myfile: $!";
3079         $first = <$handle>
3080             or return ();     # Automatically closed here.
3081         mung $first or die "mung failed";       # Or here.
3082         return $first, <$handle> if $ALL;       # Or here.
3083         $first;                                 # Or here.
3084     }
3085
3086 See L</seek> for some details about mixing reading and writing.
3087
3088 =item opendir DIRHANDLE,EXPR
3089
3090 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3091 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3092 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3093
3094 =item ord EXPR
3095
3096 =item ord
3097
3098 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3099 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3100 uses C<$_>.
3101
3102 For the reverse, see L</chr>.
3103 See L<perlunicode> and L<encoding> for more about Unicode.
3104
3105 =item our EXPR
3106
3107 =item our EXPR TYPE
3108
3109 =item our EXPR : ATTRS
3110
3111 =item our TYPE EXPR : ATTRS
3112
3113 An C<our> declares the listed variables to be valid globals within
3114 the enclosing block, file, or C<eval>.  That is, it has the same
3115 scoping rules as a "my" declaration, but does not create a local
3116 variable.  If more than one value is listed, the list must be placed
3117 in parentheses.  The C<our> declaration has no semantic effect unless
3118 "use strict vars" is in effect, in which case it lets you use the
3119 declared global variable without qualifying it with a package name.
3120 (But only within the lexical scope of the C<our> declaration.  In this
3121 it differs from "use vars", which is package scoped.)
3122
3123 An C<our> declaration declares a global variable that will be visible
3124 across its entire lexical scope, even across package boundaries.  The
3125 package in which the variable is entered is determined at the point
3126 of the declaration, not at the point of use.  This means the following
3127 behavior holds:
3128
3129     package Foo;
3130     our $bar;           # declares $Foo::bar for rest of lexical scope
3131     $bar = 20;
3132
3133     package Bar;
3134     print $bar;         # prints 20
3135
3136 Multiple C<our> declarations in the same lexical scope are allowed
3137 if they are in different packages.  If they happened to be in the same
3138 package, Perl will emit warnings if you have asked for them.
3139
3140     use warnings;
3141     package Foo;
3142     our $bar;           # declares $Foo::bar for rest of lexical scope
3143     $bar = 20;
3144
3145     package Bar;
3146     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3147     print $bar;         # prints 30
3148
3149     our $bar;           # emits warning
3150
3151 An C<our> declaration may also have a list of attributes associated
3152 with it.
3153
3154 The exact semantics and interface of TYPE and ATTRS are still
3155 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3156 and attributes are handled using the C<attributes> pragma, or starting
3157 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3158 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3159 L<attributes>, and L<Attribute::Handlers>.
3160
3161 The only currently recognized C<our()> attribute is C<unique> which
3162 indicates that a single copy of the global is to be used by all
3163 interpreters should the program happen to be running in a
3164 multi-interpreter environment. (The default behaviour would be for
3165 each interpreter to have its own copy of the global.)  Examples:
3166
3167     our @EXPORT : unique = qw(foo);
3168     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3169     our $VERSION : unique = "1.00";
3170
3171 Note that this attribute also has the effect of making the global
3172 readonly when the first new interpreter is cloned (for example,
3173 when the first new thread is created).
3174
3175 Multi-interpreter environments can come to being either through the
3176 fork() emulation on Windows platforms, or by embedding perl in a
3177 multi-threaded application.  The C<unique> attribute does nothing in
3178 all other environments.
3179
3180 =item pack TEMPLATE,LIST
3181
3182 Takes a LIST of values and converts it into a string using the rules
3183 given by the TEMPLATE.  The resulting string is the concatenation of
3184 the converted values.  Typically, each converted value looks
3185 like its machine-level representation.  For example, on 32-bit machines
3186 a converted integer may be represented by a sequence of 4 bytes.
3187
3188 The TEMPLATE is a sequence of characters that give the order and type
3189 of values, as follows:
3190
3191     a   A string with arbitrary binary data, will be null padded.
3192     A   A text (ASCII) string, will be space padded.
3193     Z   A null terminated (ASCIZ) string, will be null padded.
3194
3195     b   A bit string (ascending bit order inside each byte, like vec()).
3196     B   A bit string (descending bit order inside each byte).
3197     h   A hex string (low nybble first).
3198     H   A hex string (high nybble first).
3199
3200     c   A signed char value.
3201     C   An unsigned char value.  Only does bytes.  See U for Unicode.
3202
3203     s   A signed short value.
3204     S   An unsigned short value.
3205           (This 'short' is _exactly_ 16 bits, which may differ from
3206            what a local C compiler calls 'short'.  If you want
3207            native-length shorts, use the '!' suffix.)
3208
3209     i   A signed integer value.
3210     I   An unsigned integer value.
3211           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3212            size depends on what a local C compiler calls 'int',
3213            and may even be larger than the 'long' described in
3214            the next item.)
3215
3216     l   A signed long value.
3217     L   An unsigned long value.
3218           (This 'long' is _exactly_ 32 bits, which may differ from
3219            what a local C compiler calls 'long'.  If you want
3220            native-length longs, use the '!' suffix.)
3221
3222     n   An unsigned short in "network" (big-endian) order.
3223     N   An unsigned long in "network" (big-endian) order.
3224     v   An unsigned short in "VAX" (little-endian) order.
3225     V   An unsigned long in "VAX" (little-endian) order.
3226           (These 'shorts' and 'longs' are _exactly_ 16 bits and
3227            _exactly_ 32 bits, respectively.)
3228
3229     q   A signed quad (64-bit) value.
3230     Q   An unsigned quad value.
3231           (Quads are available only if your system supports 64-bit
3232            integer values _and_ if Perl has been compiled to support those.
3233            Causes a fatal error otherwise.)
3234
3235     j   A signed integer value (a Perl internal integer, IV).
3236     J   An unsigned integer value (a Perl internal unsigned integer, UV).
3237
3238     f   A single-precision float in the native format.
3239     d   A double-precision float in the native format.
3240
3241     F   A floating point value in the native native format
3242            (a Perl internal floating point value, NV).
3243     D   A long double-precision float in the native format.
3244           (Long doubles are available only if your system supports long
3245            double values _and_ if Perl has been compiled to support those.
3246            Causes a fatal error otherwise.)
3247
3248     p   A pointer to a null-terminated string.
3249     P   A pointer to a structure (fixed-length string).
3250
3251     u   A uuencoded string.
3252     U   A Unicode character number.  Encodes to UTF-8 internally
3253         (or UTF-EBCDIC in EBCDIC platforms).
3254
3255     w   A BER compressed integer.  Its bytes represent an unsigned
3256         integer in base 128, most significant digit first, with as
3257         few digits as possible.  Bit eight (the high bit) is set
3258         on each byte except the last.
3259
3260     x   A null byte.
3261     X   Back up a byte.
3262     @   Null fill to absolute position, counted from the start of
3263         the innermost ()-group.
3264     (   Start of a ()-group.
3265
3266 The following rules apply:
3267
3268 =over 8
3269
3270 =item *
3271
3272 Each letter may optionally be followed by a number giving a repeat
3273 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3274 C<H>, C<@>, C<x>, C<X> and C<P> the pack function will gobble up that
3275 many values from the LIST.  A C<*> for the repeat count means to use
3276 however many items are left, except for C<@>, C<x>, C<X>, where it is
3277 equivalent to C<0>, and C<u>, where it is equivalent to 1 (or 45, what
3278 is the same).  A numeric repeat count may optionally be enclosed in
3279 brackets, as in C<pack 'C[80]', @arr>.
3280
3281 One can replace the numeric repeat count by a template enclosed in brackets;
3282 then the packed length of this template in bytes is used as a count.
3283 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3284 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3285 If the template in brackets contains alignment commands (such as C<x![d]>),
3286 its packed length is calculated as if the start of the template has the maximal
3287 possible alignment.
3288
3289 When used with C<Z>, C<*> results in the addition of a trailing null
3290 byte (so the packed result will be one longer than the byte C<length>
3291 of the item).
3292
3293 The repeat count for C<u> is interpreted as the maximal number of bytes
3294 to encode per line of output, with 0 and 1 replaced by 45.
3295
3296 =item *
3297
3298 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3299 string of length count, padding with nulls or spaces as necessary.  When
3300 unpacking, C<A> strips trailing spaces and nulls, C<Z> strips everything
3301 after the first null, and C<a> returns data verbatim.  When packing,
3302 C<a>, and C<Z> are equivalent.
3303
3304 If the value-to-pack is too long, it is truncated.  If too long and an
3305 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3306 by a null byte.  Thus C<Z> always packs a trailing null byte under
3307 all circumstances.
3308
3309 =item *
3310
3311 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3312 Each byte of the input field of pack() generates 1 bit of the result.
3313 Each result bit is based on the least-significant bit of the corresponding
3314 input byte, i.e., on C<ord($byte)%2>.  In particular, bytes C<"0"> and
3315 C<"1"> generate bits 0 and 1, as do bytes C<"\0"> and C<"\1">.
3316
3317 Starting from the beginning of the input string of pack(), each 8-tuple
3318 of bytes is converted to 1 byte of output.  With format C<b>
3319 the first byte of the 8-tuple determines the least-significant bit of a
3320 byte, and with format C<B> it determines the most-significant bit of
3321 a byte.
3322
3323 If the length of the input string is not exactly divisible by 8, the
3324 remainder is packed as if the input string were padded by null bytes
3325 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3326
3327 If the input string of pack() is longer than needed, extra bytes are ignored.
3328 A C<*> for the repeat count of pack() means to use all the bytes of
3329 the input field.  On unpack()ing the bits are converted to a string
3330 of C<"0">s and C<"1">s.
3331
3332 =item *
3333
3334 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3335 representable as hexadecimal digits, 0-9a-f) long.
3336
3337 Each byte of the input field of pack() generates 4 bits of the result.
3338 For non-alphabetical bytes the result is based on the 4 least-significant
3339 bits of the input byte, i.e., on C<ord($byte)%16>.  In particular,
3340 bytes C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3341 C<"\0"> and C<"\1">.  For bytes C<"a".."f"> and C<"A".."F"> the result
3342 is compatible with the usual hexadecimal digits, so that C<"a"> and
3343 C<"A"> both generate the nybble C<0xa==10>.  The result for bytes
3344 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3345
3346 Starting from the beginning of the input string of pack(), each pair
3347 of bytes is converted to 1 byte of output.  With format C<h> the
3348 first byte of the pair determines the least-significant nybble of the
3349 output byte, and with format C<H> it determines the most-significant
3350 nybble.
3351
3352 If the length of the input string is not even, it behaves as if padded
3353 by a null byte at the end.  Similarly, during unpack()ing the "extra"
3354 nybbles are ignored.
3355
3356 If the input string of pack() is longer than needed, extra bytes are ignored.
3357 A C<*> for the repeat count of pack() means to use all the bytes of
3358 the input field.  On unpack()ing the bits are converted to a string
3359 of hexadecimal digits.
3360
3361 =item *
3362
3363 The C<p> type packs a pointer to a null-terminated string.  You are
3364 responsible for ensuring the string is not a temporary value (which can
3365 potentially get deallocated before you get around to using the packed result).
3366 The C<P> type packs a pointer to a structure of the size indicated by the
3367 length.  A NULL pointer is created if the corresponding value for C<p> or
3368 C<P> is C<undef>, similarly for unpack().
3369
3370 =item *
3371
3372 The C</> template character allows packing and unpacking of strings where
3373 the packed structure contains a byte count followed by the string itself.
3374 You write I<length-item>C</>I<string-item>.
3375
3376 The I<length-item> can be any C<pack> template letter, and describes
3377 how the length value is packed.  The ones likely to be of most use are
3378 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3379 SNMP) and C<N> (for Sun XDR).
3380
3381 For C<pack>, the I<string-item> must, at present, be C<"A*">, C<"a*"> or
3382 C<"Z*">. For C<unpack> the length of the string is obtained from the
3383 I<length-item>, but if you put in the '*' it will be ignored. For all other
3384 codes, C<unpack> applies the length value to the next item, which must not
3385 have a repeat count.
3386
3387     unpack 'C/a', "\04Gurusamy";        gives 'Guru'
3388     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond','J')
3389     pack 'n/a* w/a*','hello,','world';  gives "\000\006hello,\005world"
3390
3391 The I<length-item> is not returned explicitly from C<unpack>.
3392
3393 Adding a count to the I<length-item> letter is unlikely to do anything
3394 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3395 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3396 which Perl does not regard as legal in numeric strings.
3397
3398 =item *
3399
3400 The integer types C<s>, C<S>, C<l>, and C<L> may be
3401 immediately followed by a C<!> suffix to signify native shorts or
3402 longs--as you can see from above for example a bare C<l> does mean
3403 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3404 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3405 see whether using C<!> makes any difference by
3406
3407         print length(pack("s")), " ", length(pack("s!")), "\n";
3408         print length(pack("l")), " ", length(pack("l!")), "\n";
3409
3410 C<i!> and C<I!> also work but only because of completeness;
3411 they are identical to C<i> and C<I>.
3412
3413 The actual sizes (in bytes) of native shorts, ints, longs, and long
3414 longs on the platform where Perl was built are also available via
3415 L<Config>:
3416
3417        use Config;
3418        print $Config{shortsize},    "\n";
3419        print $Config{intsize},      "\n";
3420        print $Config{longsize},     "\n";
3421        print $Config{longlongsize}, "\n";
3422
3423 (The C<$Config{longlongsize}> will be undefined if your system does
3424 not support long longs.)
3425
3426 =item *
3427
3428 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3429 are inherently non-portable between processors and operating systems
3430 because they obey the native byteorder and endianness.  For example a
3431 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3432 (arranged in and handled by the CPU registers) into bytes as
3433
3434         0x12 0x34 0x56 0x78     # big-endian
3435         0x78 0x56 0x34 0x12     # little-endian
3436
3437 Basically, the Intel and VAX CPUs are little-endian, while everybody
3438 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3439 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3440 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3441 mode.
3442
3443 The names `big-endian' and `little-endian' are comic references to
3444 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3445 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3446 the egg-eating habits of the Lilliputians.
3447
3448 Some systems may have even weirder byte orders such as
3449
3450         0x56 0x78 0x12 0x34
3451         0x34 0x12 0x78 0x56
3452
3453 You can see your system's preference with
3454
3455         print join(" ", map { sprintf "%#02x", $_ }
3456                             unpack("C*",pack("L",0x12345678))), "\n";
3457
3458 The byteorder on the platform where Perl was built is also available
3459 via L<Config>:
3460
3461         use Config;
3462         print $Config{byteorder}, "\n";
3463
3464 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3465 and C<'87654321'> are big-endian.
3466
3467 If you want portable packed integers use the formats C<n>, C<N>,
3468 C<v>, and C<V>, their byte endianness and size are known.
3469 See also L<perlport>.
3470
3471 =item *
3472
3473 Real numbers (floats and doubles) are in the native machine format only;
3474 due to the multiplicity of floating formats around, and the lack of a
3475 standard "network" representation, no facility for interchange has been
3476 made.  This means that packed floating point data written on one machine
3477 may not be readable on another - even if both use IEEE floating point
3478 arithmetic (as the endian-ness of the memory representation is not part
3479 of the IEEE spec).  See also L<perlport>.
3480
3481 Note that Perl uses doubles internally for all numeric calculation, and
3482 converting from double into float and thence back to double again will
3483 lose precision (i.e., C<unpack("f", pack("f", $foo)>) will not in general
3484 equal $foo).
3485
3486 =item *
3487
3488 If the pattern begins with a C<U>, the resulting string will be treated
3489 as Unicode-encoded. You can force UTF8 encoding on in a string with an
3490 initial C<U0>, and the bytes that follow will be interpreted as Unicode
3491 characters. If you don't want this to happen, you can begin your pattern
3492 with C<C0> (or anything else) to force Perl not to UTF8 encode your
3493 string, and then follow this with a C<U*> somewhere in your pattern.
3494
3495 =item *
3496
3497 You must yourself do any alignment or padding by inserting for example
3498 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3499 could know where the bytes are going to or coming from.  Therefore
3500 C<pack> (and C<unpack>) handle their output and input as flat
3501 sequences of bytes.
3502
3503 =item *
3504
3505 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3506 take a repeat count, both as postfix, and for unpack() also via the C</>
3507 template character. Within each repetition of a group, positioning with
3508 C<@> starts again at 0. Therefore, the result of
3509
3510     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3511
3512 is the string "\0a\0\0bc".
3513
3514
3515 =item *
3516
3517 C<x> and C<X> accept C<!> modifier.  In this case they act as
3518 alignment commands: they jump forward/back to the closest position
3519 aligned at a multiple of C<count> bytes.  For example, to pack() or
3520 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3521 use the template C<C x![d] d C[2]>; this assumes that doubles must be
3522 aligned on the double's size.
3523
3524 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3525 both result in no-ops.
3526
3527 =item *
3528
3529 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3530 White space may be used to separate pack codes from each other, but
3531 a C<!> modifier and a repeat count must follow immediately.
3532
3533 =item *
3534
3535 If TEMPLATE requires more arguments to pack() than actually given, pack()
3536 assumes additional C<""> arguments.  If TEMPLATE requires less arguments
3537 to pack() than actually given, extra arguments are ignored.
3538
3539 =back
3540
3541 Examples:
3542
3543     $foo = pack("CCCC",65,66,67,68);
3544     # foo eq "ABCD"
3545     $foo = pack("C4",65,66,67,68);
3546     # same thing
3547     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3548     # same thing with Unicode circled letters
3549
3550     $foo = pack("ccxxcc",65,66,67,68);
3551     # foo eq "AB\0\0CD"
3552
3553     # note: the above examples featuring "C" and "c" are true
3554     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3555     # and UTF-8.  In EBCDIC the first example would be
3556     # $foo = pack("CCCC",193,194,195,196);
3557
3558     $foo = pack("s2",1,2);
3559     # "\1\0\2\0" on little-endian
3560     # "\0\1\0\2" on big-endian
3561
3562     $foo = pack("a4","abcd","x","y","z");
3563     # "abcd"
3564
3565     $foo = pack("aaaa","abcd","x","y","z");
3566     # "axyz"
3567
3568     $foo = pack("a14","abcdefg");
3569     # "abcdefg\0\0\0\0\0\0\0"
3570
3571     $foo = pack("i9pl", gmtime);
3572     # a real struct tm (on my system anyway)
3573
3574     $utmp_template = "Z8 Z8 Z16 L";
3575     $utmp = pack($utmp_template, @utmp1);
3576     # a struct utmp (BSDish)
3577
3578     @utmp2 = unpack($utmp_template, $utmp);
3579     # "@utmp1" eq "@utmp2"
3580
3581     sub bintodec {
3582         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3583     }
3584
3585     $foo = pack('sx2l', 12, 34);
3586     # short 12, two zero bytes padding, long 34
3587     $bar = pack('s@4l', 12, 34);
3588     # short 12, zero fill to position 4, long 34
3589     # $foo eq $bar
3590
3591 The same template may generally also be used in unpack().
3592
3593 =item package NAMESPACE
3594
3595 =item package
3596
3597 Declares the compilation unit as being in the given namespace.  The scope
3598 of the package declaration is from the declaration itself through the end
3599 of the enclosing block, file, or eval (the same as the C<my> operator).
3600 All further unqualified dynamic identifiers will be in this namespace.
3601 A package statement affects only dynamic variables--including those
3602 you've used C<local> on--but I<not> lexical variables, which are created
3603 with C<my>.  Typically it would be the first declaration in a file to
3604 be included by the C<require> or C<use> operator.  You can switch into a
3605 package in more than one place; it merely influences which symbol table
3606 is used by the compiler for the rest of that block.  You can refer to
3607 variables and filehandles in other packages by prefixing the identifier
3608 with the package name and a double colon:  C<$Package::Variable>.
3609 If the package name is null, the C<main> package as assumed.  That is,
3610 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3611 still seen in older code).
3612
3613 If NAMESPACE is omitted, then there is no current package, and all
3614 identifiers must be fully qualified or lexicals.  However, you are
3615 strongly advised not to make use of this feature. Its use can cause
3616 unexpected behaviour, even crashing some versions of Perl. It is
3617 deprecated, and will be removed from a future release.
3618
3619 See L<perlmod/"Packages"> for more information about packages, modules,
3620 and classes.  See L<perlsub> for other scoping issues.
3621
3622 =item pipe READHANDLE,WRITEHANDLE
3623
3624 Opens a pair of connected pipes like the corresponding system call.
3625 Note that if you set up a loop of piped processes, deadlock can occur
3626 unless you are very careful.  In addition, note that Perl's pipes use
3627 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3628 after each command, depending on the application.
3629
3630 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3631 for examples of such things.
3632
3633 On systems that support a close-on-exec flag on files, the flag will be set
3634 for the newly opened file descriptors as determined by the value of $^F.
3635 See L<perlvar/$^F>.
3636
3637 =item pop ARRAY
3638
3639 =item pop
3640
3641 Pops and returns the last value of the array, shortening the array by
3642 one element.  Has an effect similar to
3643
3644     $ARRAY[$#ARRAY--]
3645
3646 If there are no elements in the array, returns the undefined value
3647 (although this may happen at other times as well).  If ARRAY is
3648 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3649 array in subroutines, just like C<shift>.
3650
3651 =item pos SCALAR
3652
3653 =item pos
3654
3655 Returns the offset of where the last C<m//g> search left off for the variable
3656 in question (C<$_> is used when the variable is not specified).  May be
3657 modified to change that offset.  Such modification will also influence
3658 the C<\G> zero-width assertion in regular expressions.  See L<perlre> and
3659 L<perlop>.
3660
3661 =item print FILEHANDLE LIST
3662
3663 =item print LIST
3664
3665 =item print
3666
3667 Prints a string or a list of strings.  Returns true if successful.
3668 FILEHANDLE may be a scalar variable name, in which case the variable
3669 contains the name of or a reference to the filehandle, thus introducing
3670 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3671 the next token is a term, it may be misinterpreted as an operator
3672 unless you interpose a C<+> or put parentheses around the arguments.)
3673 If FILEHANDLE is omitted, prints by default to standard output (or
3674 to the last selected output channel--see L</select>).  If LIST is
3675 also omitted, prints C<$_> to the currently selected output channel.
3676 To set the default output channel to something other than STDOUT
3677 use the select operation.  The current value of C<$,> (if any) is
3678 printed between each LIST item.  The current value of C<$\> (if
3679 any) is printed after the entire LIST has been printed.  Because
3680 print takes a LIST, anything in the LIST is evaluated in list
3681 context, and any subroutine that you call will have one or more of
3682 its expressions evaluated in list context.  Also be careful not to
3683 follow the print keyword with a left parenthesis unless you want
3684 the corresponding right parenthesis to terminate the arguments to
3685 the print--interpose a C<+> or put parentheses around all the
3686 arguments.
3687
3688 Note that if you're storing FILEHANDLES in an array or other expression,
3689 you will have to use a block returning its value instead:
3690
3691     print { $files[$i] } "stuff\n";
3692     print { $OK ? STDOUT : STDERR } "stuff\n";
3693
3694 =item printf FILEHANDLE FORMAT, LIST
3695
3696 =item printf FORMAT, LIST
3697
3698 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3699 (the output record separator) is not appended.  The first argument
3700 of the list will be interpreted as the C<printf> format. See C<sprintf>
3701 for an explanation of the format argument. If C<use locale> is in effect,
3702 the character used for the decimal point in formatted real numbers is
3703 affected by the LC_NUMERIC locale.  See L<perllocale>.
3704
3705 Don't fall into the trap of using a C<printf> when a simple
3706 C<print> would do.  The C<print> is more efficient and less
3707 error prone.
3708
3709 =item prototype FUNCTION
3710
3711 Returns the prototype of a function as a string (or C<undef> if the
3712 function has no prototype).  FUNCTION is a reference to, or the name of,
3713 the function whose prototype you want to retrieve.
3714
3715 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
3716 name for Perl builtin.  If the builtin is not I<overridable> (such as
3717 C<qw//>) or its arguments cannot be expressed by a prototype (such as
3718 C<system>) returns C<undef> because the builtin does not really behave
3719 like a Perl function.  Otherwise, the string describing the equivalent
3720 prototype is returned.
3721
3722 =item push ARRAY,LIST
3723
3724 Treats ARRAY as a stack, and pushes the values of LIST
3725 onto the end of ARRAY.  The length of ARRAY increases by the length of
3726 LIST.  Has the same effect as
3727
3728     for $value (LIST) {
3729         $ARRAY[++$#ARRAY] = $value;
3730     }
3731
3732 but is more efficient.  Returns the new number of elements in the array.
3733
3734 =item q/STRING/
3735
3736 =item qq/STRING/
3737
3738 =item qr/STRING/
3739
3740 =item qx/STRING/
3741
3742 =item qw/STRING/
3743
3744 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
3745
3746 =item quotemeta EXPR
3747
3748 =item quotemeta
3749
3750 Returns the value of EXPR with all non-"word"
3751 characters backslashed.  (That is, all characters not matching
3752 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
3753 returned string, regardless of any locale settings.)
3754 This is the internal function implementing
3755 the C<\Q> escape in double-quoted strings.
3756
3757 If EXPR is omitted, uses C<$_>.
3758
3759 =item rand EXPR
3760
3761 =item rand
3762
3763 Returns a random fractional number greater than or equal to C<0> and less
3764 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
3765 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
3766 also special-cased as C<1> - this has not been documented before perl 5.8.0
3767 and is subject to change in future versions of perl.  Automatically calls
3768 C<srand> unless C<srand> has already been called.  See also C<srand>.
3769
3770 Apply C<int()> to the value returned by C<rand()> if you want random
3771 integers instead of random fractional numbers.  For example,
3772
3773     int(rand(10))
3774
3775 returns a random integer between C<0> and C<9>, inclusive.
3776
3777 (Note: If your rand function consistently returns numbers that are too
3778 large or too small, then your version of Perl was probably compiled
3779 with the wrong number of RANDBITS.)
3780
3781 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
3782
3783 =item read FILEHANDLE,SCALAR,LENGTH
3784
3785 Attempts to read LENGTH I<characters> of data into variable SCALAR
3786 from the specified FILEHANDLE.  Returns the number of characters
3787 actually read, C<0> at end of file, or undef if there was an error (in
3788 the latter case C<$!> is also set).  SCALAR will be grown or shrunk to
3789 the length actually read.  If SCALAR needs growing, the new bytes will
3790 be zero bytes.  An OFFSET may be specified to place the read data into
3791 some other place in SCALAR than the beginning.  The call is actually
3792 implemented in terms of either Perl's or system's fread() call.  To
3793 get a true read(2) system call, see C<sysread>.
3794
3795 Note the I<characters>: depending on the status of the filehandle,
3796 either (8-bit) bytes or characters are read.  By default all
3797 filehandles operate on bytes, but for example if the filehandle has
3798 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
3799 pragma, L<open>), the I/O will operate on characters, not bytes.
3800
3801 =item readdir DIRHANDLE
3802
3803 Returns the next directory entry for a directory opened by C<opendir>.
3804 If used in list context, returns all the rest of the entries in the
3805 directory.  If there are no more entries, returns an undefined value in
3806 scalar context or a null list in list context.
3807
3808 If you're planning to filetest the return values out of a C<readdir>, you'd
3809 better prepend the directory in question.  Otherwise, because we didn't
3810 C<chdir> there, it would have been testing the wrong file.
3811
3812     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
3813     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
3814     closedir DIR;
3815
3816 =item readline EXPR
3817
3818 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
3819 context, each call reads and returns the next line, until end-of-file is
3820 reached, whereupon the subsequent call returns undef.  In list context,
3821 reads until end-of-file is reached and returns a list of lines.  Note that
3822 the notion of "line" used here is however you may have defined it
3823 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
3824
3825 When C<$/> is set to C<undef>, when readline() is in scalar
3826 context (i.e. file slurp mode), and when an empty file is read, it
3827 returns C<''> the first time, followed by C<undef> subsequently.
3828
3829 This is the internal function implementing the C<< <EXPR> >>
3830 operator, but you can use it directly.  The C<< <EXPR> >>
3831 operator is discussed in more detail in L<perlop/"I/O Operators">.
3832
3833     $line = <STDIN>;
3834     $line = readline(*STDIN);           # same thing
3835
3836 =item readlink EXPR
3837
3838 =item readlink
3839
3840 Returns the value of a symbolic link, if symbolic links are
3841 implemented.  If not, gives a fatal error.  If there is some system
3842 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
3843 omitted, uses C<$_>.
3844
3845 =item readpipe EXPR
3846
3847 EXPR is executed as a system command.
3848 The collected standard output of the command is returned.
3849 In scalar context, it comes back as a single (potentially
3850 multi-line) string.  In list context, returns a list of lines
3851 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
3852 This is the internal function implementing the C<qx/EXPR/>
3853 operator, but you can use it directly.  The C<qx/EXPR/>
3854 operator is discussed in more detail in L<perlop/"I/O Operators">.
3855
3856 =item recv SOCKET,SCALAR,LENGTH,FLAGS
3857
3858 Receives a message on a socket.  Attempts to receive LENGTH characters
3859 of data into variable SCALAR from the specified SOCKET filehandle.
3860 SCALAR will be grown or shrunk to the length actually read.  Takes the
3861 same flags as the system call of the same name.  Returns the address
3862 of the sender if SOCKET's protocol supports this; returns an empty
3863 string otherwise.  If there's an error, returns the undefined value.
3864 This call is actually implemented in terms of recvfrom(2) system call.
3865 See L<perlipc/"UDP: Message Passing"> for examples.
3866
3867 Note the I<characters>: depending on the status of the socket, either
3868 (8-bit) bytes or characters are received.  By default all sockets
3869 operate on bytes, but for example if the socket has been changed using
3870 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
3871 pragma, L<open>), the I/O will operate on characters, not bytes.
3872
3873 =item redo LABEL
3874
3875 =item redo
3876
3877 The C<redo> command restarts the loop block without evaluating the
3878 conditional again.  The C<continue> block, if any, is not executed.  If
3879 the LABEL is omitted, the command refers to the innermost enclosing
3880 loop.  This command is normally used by programs that want to lie to
3881 themselves about what was just input:
3882
3883     # a simpleminded Pascal comment stripper
3884     # (warning: assumes no { or } in strings)
3885     LINE: while (<STDIN>) {
3886         while (s|({.*}.*){.*}|$1 |) {}
3887         s|{.*}| |;
3888         if (s|{.*| |) {
3889             $front = $_;
3890             while (<STDIN>) {
3891                 if (/}/) {      # end of comment?
3892                     s|^|$front\{|;
3893                     redo LINE;
3894                 }
3895             }
3896         }
3897         print;
3898     }
3899
3900 C<redo> cannot be used to retry a block which returns a value such as
3901 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3902 a grep() or map() operation.
3903
3904 Note that a block by itself is semantically identical to a loop
3905 that executes once.  Thus C<redo> inside such a block will effectively
3906 turn it into a looping construct.
3907
3908 See also L</continue> for an illustration of how C<last>, C<next>, and
3909 C<redo> work.
3910
3911 =item ref EXPR
3912
3913 =item ref
3914
3915 Returns a true value if EXPR is a reference, false otherwise.  If EXPR
3916 is not specified, C<$_> will be used.  The value returned depends on the
3917 type of thing the reference is a reference to.
3918 Builtin types include:
3919
3920     SCALAR
3921     ARRAY
3922     HASH
3923     CODE
3924     REF
3925     GLOB
3926     LVALUE
3927
3928 If the referenced object has been blessed into a package, then that package
3929 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
3930
3931     if (ref($r) eq "HASH") {
3932         print "r is a reference to a hash.\n";
3933     }
3934     unless (ref($r)) {
3935         print "r is not a reference at all.\n";
3936     }
3937     if (UNIVERSAL::isa($r, "HASH")) {  # for subclassing
3938         print "r is a reference to something that isa hash.\n";
3939     }
3940
3941 See also L<perlref>.
3942
3943 =item rename OLDNAME,NEWNAME
3944
3945 Changes the name of a file; an existing file NEWNAME will be
3946 clobbered.  Returns true for success, false otherwise.
3947
3948 Behavior of this function varies wildly depending on your system
3949 implementation.  For example, it will usually not work across file system
3950 boundaries, even though the system I<mv> command sometimes compensates
3951 for this.  Other restrictions include whether it works on directories,
3952 open files, or pre-existing files.  Check L<perlport> and either the
3953 rename(2) manpage or equivalent system documentation for details.
3954
3955 =item require VERSION
3956
3957 =item require EXPR
3958
3959 =item require
3960
3961 Demands a version of Perl specified by VERSION, or demands some semantics
3962 specified by EXPR or by C<$_> if EXPR is not supplied.
3963
3964 VERSION may be either a numeric argument such as 5.006, which will be
3965 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
3966 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
3967 VERSION is greater than the version of the current Perl interpreter.
3968 Compare with L</use>, which can do a similar check at compile time.
3969
3970 Specifying VERSION as a literal of the form v5.6.1 should generally be
3971 avoided, because it leads to misleading error messages under earlier
3972 versions of Perl which do not support this syntax.  The equivalent numeric
3973 version should be used instead.
3974
3975     require v5.6.1;     # run time version check
3976     require 5.6.1;      # ditto
3977     require 5.006_001;  # ditto; preferred for backwards compatibility
3978
3979 Otherwise, demands that a library file be included if it hasn't already
3980 been included.  The file is included via the do-FILE mechanism, which is
3981 essentially just a variety of C<eval>.  Has semantics similar to the following
3982 subroutine:
3983
3984     sub require {
3985         my($filename) = @_;
3986         return 1 if $INC{$filename};
3987         my($realfilename,$result);
3988         ITER: {
3989             foreach $prefix (@INC) {
3990                 $realfilename = "$prefix/$filename";
3991                 if (-f $realfilename) {
3992                     $INC{$filename} = $realfilename;
3993                     $result = do $realfilename;
3994                     last ITER;
3995                 }
3996             }
3997             die "Can't find $filename in \@INC";
3998         }
3999         delete $INC{$filename} if $@ || !$result;
4000         die $@ if $@;
4001         die "$filename did not return true value" unless $result;
4002         return $result;
4003     }
4004
4005 Note that the file will not be included twice under the same specified
4006 name.  The file must return true as the last statement to indicate
4007 successful execution of any initialization code, so it's customary to
4008 end such a file with C<1;> unless you're sure it'll return true
4009 otherwise.  But it's better just to put the C<1;>, in case you add more
4010 statements.
4011
4012 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4013 replaces "F<::>" with "F</>" in the filename for you,
4014 to make it easy to load standard modules.  This form of loading of
4015 modules does not risk altering your namespace.
4016
4017 In other words, if you try this:
4018
4019         require Foo::Bar;    # a splendid bareword
4020
4021 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4022 directories specified in the C<@INC> array.
4023
4024 But if you try this:
4025
4026         $class = 'Foo::Bar';
4027         require $class;      # $class is not a bareword
4028     #or
4029         require "Foo::Bar";  # not a bareword because of the ""
4030
4031 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4032 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4033
4034         eval "require $class";
4035
4036 You can also insert hooks into the import facility, by putting directly
4037 Perl code into the @INC array.  There are three forms of hooks: subroutine
4038 references, array references and blessed objects.
4039
4040 Subroutine references are the simplest case.  When the inclusion system
4041 walks through @INC and encounters a subroutine, this subroutine gets
4042 called with two parameters, the first being a reference to itself, and the
4043 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4044 subroutine should return C<undef> or a filehandle, from which the file to
4045 include will be read.  If C<undef> is returned, C<require> will look at
4046 the remaining elements of @INC.
4047
4048 If the hook is an array reference, its first element must be a subroutine
4049 reference.  This subroutine is called as above, but the first parameter is
4050 the array reference.  This enables to pass indirectly some arguments to
4051 the subroutine.
4052
4053 In other words, you can write:
4054
4055     push @INC, \&my_sub;
4056     sub my_sub {
4057         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4058         ...
4059     }
4060
4061 or:
4062
4063     push @INC, [ \&my_sub, $x, $y, ... ];
4064     sub my_sub {
4065         my ($arrayref, $filename) = @_;
4066         # Retrieve $x, $y, ...
4067         my @parameters = @$arrayref[1..$#$arrayref];
4068         ...
4069     }
4070
4071 If the hook is an object, it must provide an INC method, that will be
4072 called as above, the first parameter being the object itself.  (Note that
4073 you must fully qualify the sub's name, as it is always forced into package
4074 C<main>.)  Here is a typical code layout:
4075
4076     # In Foo.pm
4077     package Foo;
4078     sub new { ... }
4079     sub Foo::INC {
4080         my ($self, $filename) = @_;
4081         ...
4082     }
4083
4084     # In the main program
4085     push @INC, new Foo(...);
4086
4087 Note that these hooks are also permitted to set the %INC entry
4088 corresponding to the files they have loaded. See L<perlvar/%INC>.
4089
4090 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4091
4092 =item reset EXPR
4093
4094 =item reset
4095
4096 Generally used in a C<continue> block at the end of a loop to clear
4097 variables and reset C<??> searches so that they work again.  The
4098 expression is interpreted as a list of single characters (hyphens
4099 allowed for ranges).  All variables and arrays beginning with one of
4100 those letters are reset to their pristine state.  If the expression is
4101 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4102 only variables or searches in the current package.  Always returns
4103 1.  Examples:
4104
4105     reset 'X';          # reset all X variables
4106     reset 'a-z';        # reset lower case variables
4107     reset;              # just reset ?one-time? searches
4108
4109 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4110 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4111 variables--lexical variables are unaffected, but they clean themselves
4112 up on scope exit anyway, so you'll probably want to use them instead.
4113 See L</my>.
4114
4115 =item return EXPR
4116
4117 =item return
4118
4119 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4120 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4121 context, depending on how the return value will be used, and the context
4122 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4123 is given, returns an empty list in list context, the undefined value in
4124 scalar context, and (of course) nothing at all in a void context.
4125
4126 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4127 or do FILE will automatically return the value of the last expression
4128 evaluated.)
4129
4130 =item reverse LIST
4131
4132 In list context, returns a list value consisting of the elements
4133 of LIST in the opposite order.  In scalar context, concatenates the
4134 elements of LIST and returns a string value with all characters
4135 in the opposite order.
4136
4137     print reverse <>;           # line tac, last line first
4138
4139     undef $/;                   # for efficiency of <>
4140     print scalar reverse <>;    # character tac, last line tsrif
4141
4142 This operator is also handy for inverting a hash, although there are some
4143 caveats.  If a value is duplicated in the original hash, only one of those
4144 can be represented as a key in the inverted hash.  Also, this has to
4145 unwind one hash and build a whole new one, which may take some time
4146 on a large hash, such as from a DBM file.
4147
4148     %by_name = reverse %by_address;     # Invert the hash
4149
4150 =item rewinddir DIRHANDLE
4151
4152 Sets the current position to the beginning of the directory for the
4153 C<readdir> routine on DIRHANDLE.
4154
4155 =item rindex STR,SUBSTR,POSITION
4156
4157 =item rindex STR,SUBSTR
4158
4159 Works just like index() except that it returns the position of the LAST
4160 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4161 last occurrence at or before that position.
4162
4163 =item rmdir FILENAME
4164
4165 =item rmdir
4166
4167 Deletes the directory specified by FILENAME if that directory is empty.  If it
4168 succeeds it returns true, otherwise it returns false and sets C<$!> (errno).  If
4169 FILENAME is omitted, uses C<$_>.
4170
4171 =item s///
4172
4173 The substitution operator.  See L<perlop>.
4174
4175 =item scalar EXPR
4176
4177 Forces EXPR to be interpreted in scalar context and returns the value
4178 of EXPR.
4179
4180     @counts = ( scalar @a, scalar @b, scalar @c );
4181
4182 There is no equivalent operator to force an expression to
4183 be interpolated in list context because in practice, this is never
4184 needed.  If you really wanted to do so, however, you could use
4185 the construction C<@{[ (some expression) ]}>, but usually a simple
4186 C<(some expression)> suffices.
4187
4188 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4189 parenthesized list, this behaves as a scalar comma expression, evaluating
4190 all but the last element in void context and returning the final element
4191 evaluated in scalar context.  This is seldom what you want.
4192
4193 The following single statement:
4194
4195         print uc(scalar(&foo,$bar)),$baz;
4196
4197 is the moral equivalent of these two:
4198
4199         &foo;
4200         print(uc($bar),$baz);
4201
4202 See L<perlop> for more details on unary operators and the comma operator.
4203
4204 =item seek FILEHANDLE,POSITION,WHENCE
4205
4206 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4207 FILEHANDLE may be an expression whose value gives the name of the
4208 filehandle.  The values for WHENCE are C<0> to set the new position
4209 I<in bytes> to POSITION, C<1> to set it to the current position plus
4210 POSITION, and C<2> to set it to EOF plus POSITION (typically
4211 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4212 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4213 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4214 otherwise.
4215
4216 Note the I<in bytes>: even if the filehandle has been set to
4217 operate on characters (for example by using the C<:utf8> open
4218 layer), tell() will return byte offsets, not character offsets
4219 (because implementing that would render seek() and tell() rather slow).
4220
4221 If you want to position file for C<sysread> or C<syswrite>, don't use
4222 C<seek>--buffering makes its effect on the file's system position
4223 unpredictable and non-portable.  Use C<sysseek> instead.
4224
4225 Due to the rules and rigors of ANSI C, on some systems you have to do a
4226 seek whenever you switch between reading and writing.  Amongst other
4227 things, this may have the effect of calling stdio's clearerr(3).
4228 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4229
4230     seek(TEST,0,1);
4231
4232 This is also useful for applications emulating C<tail -f>.  Once you hit
4233 EOF on your read, and then sleep for a while, you might have to stick in a
4234 seek() to reset things.  The C<seek> doesn't change the current position,
4235 but it I<does> clear the end-of-file condition on the handle, so that the
4236 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4237
4238 If that doesn't work (some IO implementations are particularly
4239 cantankerous), then you may need something more like this:
4240
4241     for (;;) {
4242         for ($curpos = tell(FILE); $_ = <FILE>;
4243              $curpos = tell(FILE)) {
4244             # search for some stuff and put it into files
4245         }
4246         sleep($for_a_while);
4247         seek(FILE, $curpos, 0);
4248     }
4249
4250 =item seekdir DIRHANDLE,POS
4251
4252 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4253 must be a value returned by C<telldir>.  Has the same caveats about
4254 possible directory compaction as the corresponding system library
4255 routine.
4256
4257 =item select FILEHANDLE
4258
4259 =item select
4260
4261 Returns the currently selected filehandle.  Sets the current default
4262 filehandle for output, if FILEHANDLE is supplied.  This has two
4263 effects: first, a C<write> or a C<print> without a filehandle will
4264 default to this FILEHANDLE.  Second, references to variables related to
4265 output will refer to this output channel.  For example, if you have to
4266 set the top of form format for more than one output channel, you might
4267 do the following:
4268
4269     select(REPORT1);
4270     $^ = 'report1_top';
4271     select(REPORT2);
4272     $^ = 'report2_top';
4273
4274 FILEHANDLE may be an expression whose value gives the name of the
4275 actual filehandle.  Thus:
4276
4277     $oldfh = select(STDERR); $| = 1; select($oldfh);
4278
4279 Some programmers may prefer to think of filehandles as objects with
4280 methods, preferring to write the last example as:
4281
4282     use IO::Handle;
4283     STDERR->autoflush(1);
4284
4285 =item select RBITS,WBITS,EBITS,TIMEOUT
4286
4287 This calls the select(2) system call with the bit masks specified, which
4288 can be constructed using C<fileno> and C<vec>, along these lines:
4289
4290     $rin = $win = $ein = '';
4291     vec($rin,fileno(STDIN),1) = 1;
4292     vec($win,fileno(STDOUT),1) = 1;
4293     $ein = $rin | $win;
4294
4295 If you want to select on many filehandles you might wish to write a
4296 subroutine:
4297
4298     sub fhbits {
4299         my(@fhlist) = split(' ',$_[0]);
4300         my($bits);
4301         for (@fhlist) {
4302             vec($bits,fileno($_),1) = 1;
4303         }
4304         $bits;
4305     }
4306     $rin = fhbits('STDIN TTY SOCK');
4307
4308 The usual idiom is:
4309
4310     ($nfound,$timeleft) =
4311       select($rout=$rin, $wout=$win, $eout=$ein, $timeout);
4312
4313 or to block until something becomes ready just do this
4314
4315     $nfound = select($rout=$rin, $wout=$win, $eout=$ein, undef);
4316
4317 Most systems do not bother to return anything useful in $timeleft, so
4318 calling select() in scalar context just returns $nfound.
4319
4320 Any of the bit masks can also be undef.  The timeout, if specified, is
4321 in seconds, which may be fractional.  Note: not all implementations are
4322 capable of returning the $timeleft.  If not, they always return
4323 $timeleft equal to the supplied $timeout.
4324
4325 You can effect a sleep of 250 milliseconds this way:
4326
4327     select(undef, undef, undef, 0.25);
4328
4329 Note that whether C<select> gets restarted after signals (say, SIGALRM)
4330 is implementation-dependent.
4331
4332 B<WARNING>: One should not attempt to mix buffered I/O (like C<read>
4333 or <FH>) with C<select>, except as permitted by POSIX, and even
4334 then only on POSIX systems.  You have to use C<sysread> instead.
4335
4336 =item semctl ID,SEMNUM,CMD,ARG
4337
4338 Calls the System V IPC function C<semctl>.  You'll probably have to say
4339
4340     use IPC::SysV;
4341
4342 first to get the correct constant definitions.  If CMD is IPC_STAT or
4343 GETALL, then ARG must be a variable which will hold the returned
4344 semid_ds structure or semaphore value array.  Returns like C<ioctl>:
4345 the undefined value for error, "C<0 but true>" for zero, or the actual
4346 return value otherwise.  The ARG must consist of a vector of native
4347 short integers, which may be created with C<pack("s!",(0)x$nsem)>.
4348 See also L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::Semaphore>
4349 documentation.
4350
4351 =item semget KEY,NSEMS,FLAGS
4352
4353 Calls the System V IPC function semget.  Returns the semaphore id, or
4354 the undefined value if there is an error.  See also
4355 L<perlipc/"SysV IPC">, C<IPC::SysV>, C<IPC::SysV::Semaphore>
4356 documentation.
4357
4358 =item semop KEY,OPSTRING
4359
4360 Calls the System V IPC function semop to perform semaphore operations
4361 such as signalling and waiting.  OPSTRING must be a packed array of
4362 semop structures.  Each semop structure can be generated with
4363 C<pack("s!3", $semnum, $semop, $semflag)>.  The number of semaphore
4364 operations is implied by the length of OPSTRING.  Returns true if
4365 successful, or false if there is an error.  As an example, the
4366 following code waits on semaphore $semnum of semaphore id $semid:
4367
4368     $semop = pack("s!3", $semnum, -1, 0);
4369     die "Semaphore trouble: $!\n" unless semop($semid, $semop);
4370
4371 To signal the semaphore, replace C<-1> with C<1>.  See also
4372 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::SysV::Semaphore>
4373 documentation.
4374
4375 =item send SOCKET,MSG,FLAGS,TO
4376
4377 =item send SOCKET,MSG,FLAGS
4378
4379 Sends a message on a socket.  Attempts to send the scalar MSG to the
4380 SOCKET filehandle.  Takes the same flags as the system call of the
4381 same name.  On unconnected sockets you must specify a destination to
4382 send TO, in which case it does a C C<sendto>.  Returns the number of
4383 characters sent, or the undefined value if there is an error.  The C
4384 system call sendmsg(2) is currently unimplemented.  See
4385 L<perlipc/"UDP: Message Passing"> for examples.
4386
4387 Note the I<characters>: depending on the status of the socket, either
4388 (8-bit) bytes or characters are sent.  By default all sockets operate
4389 on bytes, but for example if the socket has been changed using
4390 binmode() to operate with the C<:utf8> I/O layer (see L</open>, or
4391 the C<open> pragma, L<open>), the I/O will operate on characters, not
4392 bytes.
4393
4394 =item setpgrp PID,PGRP
4395
4396 Sets the current process group for the specified PID, C<0> for the current
4397 process.  Will produce a fatal error if used on a machine that doesn't
4398 implement POSIX setpgid(2) or BSD setpgrp(2).  If the arguments are omitted,
4399 it defaults to C<0,0>.  Note that the BSD 4.2 version of C<setpgrp> does not
4400 accept any arguments, so only C<setpgrp(0,0)> is portable.  See also
4401 C<POSIX::setsid()>.
4402
4403 =item setpriority WHICH,WHO,PRIORITY
4404
4405 Sets the current priority for a process, a process group, or a user.
4406 (See setpriority(2).)  Will produce a fatal error if used on a machine
4407 that doesn't implement setpriority(2).
4408
4409 =item setsockopt SOCKET,LEVEL,OPTNAME,OPTVAL
4410
4411 Sets the socket option requested.  Returns undefined if there is an
4412 error.  OPTVAL may be specified as C<undef> if you don't want to pass an
4413 argument.
4414
4415 =item shift ARRAY
4416
4417 =item shift
4418
4419 Shifts the first value of the array off and returns it, shortening the
4420 array by 1 and moving everything down.  If there are no elements in the
4421 array, returns the undefined value.  If ARRAY is omitted, shifts the
4422 C<@_> array within the lexical scope of subroutines and formats, and the
4423 C<@ARGV> array at file scopes or within the lexical scopes established by
4424 the C<eval ''>, C<BEGIN {}>, C<INIT {}>, C<CHECK {}>, and C<END {}>
4425 constructs.
4426
4427 See also C<unshift>, C<push>, and C<pop>.  C<shift> and C<unshift> do the
4428 same thing to the left end of an array that C<pop> and C<push> do to the
4429 right end.
4430
4431 =item shmctl ID,CMD,ARG
4432
4433 Calls the System V IPC function shmctl.  You'll probably have to say
4434
4435     use IPC::SysV;
4436
4437 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
4438 then ARG must be a variable which will hold the returned C<shmid_ds>
4439 structure.  Returns like ioctl: the undefined value for error, "C<0> but
4440 true" for zero, or the actual return value otherwise.
4441 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4442
4443 =item shmget KEY,SIZE,FLAGS
4444
4445 Calls the System V IPC function shmget.  Returns the shared memory
4446 segment id, or the undefined value if there is an error.
4447 See also L<perlipc/"SysV IPC"> and C<IPC::SysV> documentation.
4448
4449 =item shmread ID,VAR,POS,SIZE
4450
4451 =item shmwrite ID,STRING,POS,SIZE
4452
4453 Reads or writes the System V shared memory segment ID starting at
4454 position POS for size SIZE by attaching to it, copying in/out, and
4455 detaching from it.  When reading, VAR must be a variable that will
4456 hold the data read.  When writing, if STRING is too long, only SIZE
4457 bytes are used; if STRING is too short, nulls are written to fill out
4458 SIZE bytes.  Return true if successful, or false if there is an error.
4459 shmread() taints the variable. See also L<perlipc/"SysV IPC">,
4460 C<IPC::SysV> documentation, and the C<IPC::Shareable> module from CPAN.
4461
4462 =item shutdown SOCKET,HOW
4463
4464 Shuts down a socket connection in the manner indicated by HOW, which
4465 has the same interpretation as in the system call of the same name.
4466
4467     shutdown(SOCKET, 0);    # I/we have stopped reading data
4468     shutdown(SOCKET, 1);    # I/we have stopped writing data
4469     shutdown(SOCKET, 2);    # I/we have stopped using this socket
4470
4471 This is useful with sockets when you want to tell the other
4472 side you're done writing but not done reading, or vice versa.
4473 It's also a more insistent form of close because it also
4474 disables the file descriptor in any forked copies in other
4475 processes.
4476
4477 =item sin EXPR
4478
4479 =item sin
4480
4481 Returns the sine of EXPR (expressed in radians).  If EXPR is omitted,
4482 returns sine of C<$_>.
4483
4484 For the inverse sine operation, you may use the C<Math::Trig::asin>
4485 function, or use this relation:
4486
4487     sub asin { atan2($_[0], sqrt(1 - $_[0] * $_[0])) }
4488
4489 =item sleep EXPR
4490
4491 =item sleep
4492
4493 Causes the script to sleep for EXPR seconds, or forever if no EXPR.
4494 May be interrupted if the process receives a signal such as C<SIGALRM>.
4495 Returns the number of seconds actually slept.  You probably cannot
4496 mix C<alarm> and C<sleep> calls, because C<sleep> is often implemented
4497 using C<alarm>.
4498
4499 On some older systems, it may sleep up to a full second less than what
4500 you requested, depending on how it counts seconds.  Most modern systems
4501 always sleep the full amount.  They may appear to sleep longer than that,
4502 however, because your process might not be scheduled right away in a
4503 busy multitasking system.
4504
4505 For delays of finer granularity than one second, you may use Perl's
4506 C<syscall> interface to access setitimer(2) if your system supports
4507 it, or else see L</select> above.  The Time::HiRes module (from CPAN,
4508 and starting from Perl 5.8 part of the standard distribution) may also
4509 help.
4510
4511 See also the POSIX module's C<pause> function.
4512
4513 =item socket SOCKET,DOMAIN,TYPE,PROTOCOL
4514
4515 Opens a socket of the specified kind and attaches it to filehandle
4516 SOCKET.  DOMAIN, TYPE, and PROTOCOL are specified the same as for
4517 the system call of the same name.  You should C<use Socket> first
4518 to get the proper definitions imported.  See the examples in
4519 L<perlipc/"Sockets: Client/Server Communication">.
4520
4521 On systems that support a close-on-exec flag on files, the flag will
4522 be set for the newly opened file descriptor, as determined by the
4523 value of $^F.  See L<perlvar/$^F>.
4524
4525 =item socketpair SOCKET1,SOCKET2,DOMAIN,TYPE,PROTOCOL
4526
4527 Creates an unnamed pair of sockets in the specified domain, of the
4528 specified type.  DOMAIN, TYPE, and PROTOCOL are specified the same as
4529 for the system call of the same name.  If unimplemented, yields a fatal
4530 error.  Returns true if successful.
4531
4532 On systems that support a close-on-exec flag on files, the flag will
4533 be set for the newly opened file descriptors, as determined by the value
4534 of $^F.  See L<perlvar/$^F>.
4535
4536 Some systems defined C<pipe> in terms of C<socketpair>, in which a call
4537 to C<pipe(Rdr, Wtr)> is essentially:
4538
4539     use Socket;
4540     socketpair(Rdr, Wtr, AF_UNIX, SOCK_STREAM, PF_UNSPEC);
4541     shutdown(Rdr, 1);        # no more writing for reader
4542     shutdown(Wtr, 0);        # no more reading for writer
4543
4544 See L<perlipc> for an example of socketpair use.  Perl 5.8 and later will
4545 emulate socketpair using IP sockets to localhost if your system implements
4546 sockets but not socketpair.
4547
4548 =item sort SUBNAME LIST
4549
4550 =item sort BLOCK LIST
4551
4552 =item sort LIST
4553
4554 In list context, this sorts the LIST and returns the sorted list value.
4555 In scalar context, the behaviour of C<sort()> is undefined.
4556
4557 If SUBNAME or BLOCK is omitted, C<sort>s in standard string comparison
4558 order.  If SUBNAME is specified, it gives the name of a subroutine
4559 that returns an integer less than, equal to, or greater than C<0>,
4560 depending on how the elements of the list are to be ordered.  (The C<<
4561 <=> >> and C<cmp> operators are extremely useful in such routines.)
4562 SUBNAME may be a scalar variable name (unsubscripted), in which case
4563 the value provides the name of (or a reference to) the actual
4564 subroutine to use.  In place of a SUBNAME, you can provide a BLOCK as
4565 an anonymous, in-line sort subroutine.
4566
4567 If the subroutine's prototype is C<($$)>, the elements to be compared
4568 are passed by reference in C<@_>, as for a normal subroutine.  This is
4569 slower than unprototyped subroutines, where the elements to be
4570 compared are passed into the subroutine
4571 as the package global variables $a and $b (see example below).  Note that
4572 in the latter case, it is usually counter-productive to declare $a and
4573 $b as lexicals.
4574
4575 In either case, the subroutine may not be recursive.  The values to be
4576 compared are always passed by reference, so don't modify them.
4577
4578 You also cannot exit out of the sort block or subroutine using any of the
4579 loop control operators described in L<perlsyn> or with C<goto>.
4580
4581 When C<use locale> is in effect, C<sort LIST> sorts LIST according to the
4582 current collation locale.  See L<perllocale>.
4583
4584 Perl 5.6 and earlier used a quicksort algorithm to implement sort.
4585 That algorithm was not stable, and I<could> go quadratic.  (A I<stable> sort
4586 preserves the input order of elements that compare equal.  Although
4587 quicksort's run time is O(NlogN) when averaged over all arrays of
4588 length N, the time can be O(N**2), I<quadratic> behavior, for some
4589 inputs.)  In 5.7, the quicksort implementation was replaced with
4590 a stable mergesort algorithm whose worst case behavior is O(NlogN).
4591 But benchmarks indicated that for some inputs, on some platforms,
4592 the original quicksort was faster.  5.8 has a sort pragma for
4593 limited control of the sort.  Its rather blunt control of the
4594 underlying algorithm may not persist into future perls, but the
4595 ability to characterize the input or output in implementation
4596 independent ways quite probably will.  See L<sort>.
4597
4598 Examples:
4599
4600     # sort lexically
4601     @articles = sort @files;
4602
4603     # same thing, but with explicit sort routine
4604     @articles = sort {$a cmp $b} @files;
4605
4606     # now case-insensitively
4607     @articles = sort {uc($a) cmp uc($b)} @files;
4608
4609     # same thing in reversed order
4610     @articles = sort {$b cmp $a} @files;
4611
4612     # sort numerically ascending
4613     @articles = sort {$a <=> $b} @files;
4614
4615     # sort numerically descending
4616     @articles = sort {$b <=> $a} @files;
4617
4618     # this sorts the %age hash by value instead of key
4619     # using an in-line function
4620     @eldest = sort { $age{$b} <=> $age{$a} } keys %age;
4621
4622     # sort using explicit subroutine name
4623     sub byage {
4624         $age{$a} <=> $age{$b};  # presuming numeric
4625     }
4626     @sortedclass = sort byage @class;
4627
4628     sub backwards { $b cmp $a }
4629     @harry  = qw(dog cat x Cain Abel);
4630     @george = qw(gone chased yz Punished Axed);
4631     print sort @harry;
4632             # prints AbelCaincatdogx
4633     print sort backwards @harry;
4634             # prints xdogcatCainAbel
4635     print sort @george, 'to', @harry;
4636             # prints AbelAxedCainPunishedcatchaseddoggonetoxyz
4637
4638     # inefficiently&nbs