This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Update version of Safe in Maintainers.pl to match recent version change
[perl5.git] / vms / gen_shrfls.pl
1 # Create global symbol declarations, transfer vector, and
2 # linker options files for PerlShr.
3 #
4 # Input:
5 #    $cflags - command line qualifiers passed to cc when preprocesing perl.h
6 #        Note: A rather simple-minded attempt is made to restore quotes to
7 #        a /Define clause - use with care.
8 #    $objsuffix - file type (including '.') used for object files.
9 #    $libperl - Perl object library.
10 #    $extnames - package names for static extensions (used to generate
11 #        linker options file entries for boot functions)
12 #    $rtlopt - name of options file specifying RTLs to which PerlShr.Exe
13 #        must be linked
14 #
15 # Output:
16 #    PerlShr_Attr.Opt - linker options file which speficies that global vars
17 #        be placed in NOSHR,WRT psects.  Use when linking any object files
18 #        against PerlShr.Exe, since cc places global vars in SHR,WRT psects
19 #        by default.
20 #    PerlShr_Bld.Opt - declares universal symbols for PerlShr.Exe
21 #    Perlshr_Gbl*.Mar, Perlshr_Gbl*.Obj (VAX  only) - declares global symbols
22 #        for global vars (done here because gcc can't globaldef) and creates
23 #        transfer vectors for routines on a VAX.
24 #    PerlShr_Gbl.Opt (VAX only) - list of PerlShr_Gbl*.Obj, used for input
25 #        to the linker when building PerlShr.Exe.
26 #
27 # To do:
28 #   - figure out a good way to collect global vars in one psect, given that
29 #     we can't use globaldef because of gcc.
30 #   - then, check for existing files and preserve symbol and transfer vector
31 #     order for upward compatibility
32 #   - then, add GSMATCH to options file - but how do we insure that new
33 #     library has everything old one did
34 #     (i.e. /Define=DEBUGGING,EMBED,MULTIPLICITY)?
35 #
36 # Author: Charles Bailey  bailey@newman.upenn.edu
37
38 use strict;
39 require 5.000;
40
41 my $debug = $ENV{'GEN_SHRFLS_DEBUG'};
42
43 print "gen_shrfls.pl Rev. 30-Sep-2010\n" if $debug;
44
45 if ($ARGV[0] eq '-f') {
46   open(INP,$ARGV[1]) or die "Can't read input file $ARGV[1]: $!\n";
47   print "Input taken from file $ARGV[1]\n" if $debug;
48   @ARGV = ();
49   while (<INP>) {
50     chomp;
51     push(@ARGV,split(/\|/,$_));
52   }
53   close INP;
54   print "Read input data | ",join(' | ',@ARGV)," |\n" if $debug > 1;
55 }
56
57 my $cc_cmd = shift @ARGV;
58 my $cpp_file;
59
60 # Someday, we'll have $GetSyI built into perl . . .
61 my $isvax = `\$ Write Sys\$Output \(F\$GetSyI(\"HW_MODEL\") .LE. 1024 .AND. F\$GetSyI(\"HW_MODEL\") .GT. 0\)`;
62 chomp $isvax;
63 print "\$isvax: \\$isvax\\\n" if $debug;
64
65 my $isi64 = `\$ Write Sys\$Output \(F\$GetSyI(\"HW_MODEL\") .GE. 4096)`;
66 chomp $isi64;
67 print "\$isi64: \\$isi64\\\n" if $debug;
68
69 print "Input \$cc_cmd: \\$cc_cmd\\\n" if $debug;
70 my $docc = ($cc_cmd !~ /^~~/);
71 print "\$docc = $docc\n" if $debug;
72
73 my ( $use_threads, $use_mymalloc, $care_about_case, $shorten_symbols,
74      $debugging_enabled, $hide_mymalloc, $isgcc, $use_perlio, $dir )
75    = ( 0, 0, 0, 0, 0, 0, 0, 0 );
76
77 if ($docc) {
78   if (-f 'perl.h') { $dir = '[]'; }
79   elsif (-f '[-]perl.h') { $dir = '[-]'; }
80   else { die "$0: Can't find perl.h\n"; }
81
82   # Go see what is enabled in config.sh
83   my $config = $dir . "config.sh";
84   open CONFIG, '<', $config;
85   while(<CONFIG>) {
86     $use_threads++ if /usethreads='(define|yes|true|t|y|1)'/i;
87     $use_mymalloc++ if /usemymalloc='(define|yes|true|t|y|1)'/i;
88     $care_about_case++ if /d_vms_case_sensitive_symbols='(define|yes|true|t|y|1)'/i;
89     $shorten_symbols++ if /d_vms_shorten_long_symbols='(define|yes|true|t|y|1)'/i;
90     $debugging_enabled++ if /usedebugging_perl='(define|yes|true|t|y|1)'/i;
91     $hide_mymalloc++ if /embedmymalloc='(define|yes|true|t|y|1)'/i;
92     $isgcc++ if /gccversion='[^']/;
93     $use_perlio++ if /useperlio='(define|yes|true|t|y|1)'/i;
94   }
95   close CONFIG;
96   
97   # put quotes back onto defines - they were removed by DCL on the way in
98   if (my ($prefix,$defines,$suffix) =
99          ($cc_cmd =~ m#(.*)/Define=(.*?)([/\s].*)#i)) {
100     $defines =~ s/^\((.*)\)$/$1/;
101     $debugging_enabled ||= $defines =~ /\bDEBUGGING\b/;
102     my @defines = split(/,/,$defines);
103     $cc_cmd = "$prefix/Define=(" . join(',',grep($_ = "\"$_\"",@defines)) 
104               . ')' . $suffix;
105   }
106   print "Filtered \$cc_cmd: \\$cc_cmd\\\n" if $debug;
107
108   # check for gcc - if present, we'll need to use MACRO hack to
109   # define global symbols for shared variables
110
111   print "\$isgcc: $isgcc\n" if $debug;
112   print "\$debugging_enabled: $debugging_enabled\n" if $debug;
113
114 }
115 else { 
116   (undef,undef,$cpp_file,$cc_cmd) = split(/~~/,$cc_cmd,4);
117   $isgcc = $cc_cmd =~ /case_hack/i
118            or 0;  # for nice debug output
119   $debugging_enabled = $cc_cmd =~ /\bdebugging\b/i;
120   print "\$isgcc: \\$isgcc\\\n" if $debug;
121   print "\$debugging_enabled: \\$debugging_enabled\\\n" if $debug;
122   print "Not running cc, preprocesor output in \\$cpp_file\\\n" if $debug;
123 }
124
125 my $objsuffix = shift @ARGV;
126 print "\$objsuffix: \\$objsuffix\\\n" if $debug;
127 my $dbgprefix = shift @ARGV;
128 print "\$dbgprefix: \\$dbgprefix\\\n" if $debug;
129 my $olbsuffix = shift @ARGV;
130 print "\$olbsuffix: \\$olbsuffix\\\n" if $debug;
131 my $libperl = "${dbgprefix}libperl$olbsuffix";
132 my $extnames = shift @ARGV;
133 print "\$extnames: \\$extnames\\\n" if $debug;
134 my $rtlopt = shift @ARGV;
135 print "\$rtlopt: \\$rtlopt\\\n" if $debug;
136
137 my (%vars, %cvars, %fcns);
138
139 sub scan_var {
140   my($line) = @_;
141   my($const) = $line =~ /^EXTCONST/;
142
143   print "\tchecking for global variable\n" if $debug > 1;
144   $line =~ s/\s*EXT/EXT/;
145   $line =~ s/INIT\s*\(.*\)//;
146   $line =~ s/\[.*//;
147   $line =~ s/=.*//;
148   $line =~ s/\W*;?\s*$//;
149   $line =~ s/\W*\)\s*\(.*$//; # closing paren for args stripped in previous stmt
150   print "\tfiltered to \\$line\\\n" if $debug > 1;
151   if ($line =~ /(\w+)$/) {
152     print "\tvar name is \\$1\\" . ($const ? ' (const)' : '') . "\n" if $debug > 1;
153    if ($const) { $cvars{$1}++; }
154    else        { $vars{$1}++;  }
155   }
156 }
157
158 sub scan_func {
159   my @lines = split /;/, $_[0];
160
161   for my $line (@lines) {
162     print "\tchecking for global routine\n" if $debug > 1;
163     $line =~ s/\b(IV|Off_t|Size_t|SSize_t|void|int)\b//i;
164     if ( $line =~ /(\w+)\s*\(/ ) {
165       print "\troutine name is \\$1\\\n" if $debug > 1;
166       if ($1 eq 'main' || $1 eq 'perl_init_ext' || $1 eq '__attribute__format__'
167           || $1 eq 'sizeof' || (($1 eq 'Perl_stashpv_hvname_match') && ! $use_threads)
168           || $1 eq 'Perl_pp_avalues' || $1 eq 'Perl_pp_say') {
169         print "\tskipped\n" if $debug > 1;
170       }
171       else { $fcns{$1}++ }
172     }
173   }
174 }
175
176 # Go add some right up front if we need 'em
177 if ($use_mymalloc) {
178   $fcns{'Perl_malloc'}++;
179   $fcns{'Perl_calloc'}++;
180   $fcns{'Perl_realloc'}++;
181   $fcns{'Perl_mfree'}++;
182 }
183
184 my ($used_expectation_enum, $used_opcode_enum) = (0, 0); # avoid warnings
185 if ($docc) {
186   1 while unlink 'perlincludes.tmp';
187   END { 1 while unlink 'perlincludes.tmp'; }  # and clean up after
188
189   open(PERLINC, '>', 'perlincludes.tmp') or die "Couldn't open 'perlincludes.tmp' $!";
190
191   print PERLINC qq/#include "${dir}perl.h"\n/;
192   print PERLINC qq/#include "${dir}perlapi.h"\n/; 
193   print PERLINC qq/#include "${dir}perliol.h"\n/ if $use_perlio;
194   print PERLINC qq/#include "${dir}regcomp.h"\n/;
195
196   close PERLINC;
197   my $preprocess_list = 'perlincludes.tmp';
198
199   open(CPP,"${cc_cmd}/NoObj/PreProc=Sys\$Output $preprocess_list|")
200     or die "$0: Can't preprocess $preprocess_list: $!\n";
201 }
202 else {
203   open(CPP,"$cpp_file") or die "$0: Can't read preprocessed file $cpp_file: $!\n";
204 }
205 my %checkh = map { $_,1 } qw( bytecode byterun intrpvar perlapi perlio perliol 
206                            perlvars proto regcomp thrdvar thread );
207 my $ckfunc = 0;
208 LINE: while (<CPP>) {
209   while (/^#.*vmsish\.h/i .. /^#.*perl\.h/i) {
210     while (/__VMS_PROTOTYPES__/i .. /__VMS_SEPYTOTORP__/i) {
211       print "vms_proto>> $_" if $debug > 2;
212       if (/^\s*EXT(CONST|\s+)/) { &scan_var($_);  }
213       else        { &scan_func($_); }
214       last LINE unless defined($_ = <CPP>);
215     }
216     print "vmsish.h>> $_" if $debug > 2;
217     if (/^\s*EXT(CONST|\s+)/) { &scan_var($_); }
218     last LINE unless defined($_ = <CPP>);
219   }    
220   while (/^#.*opcode\.h/i .. /^#.*perl\.h/i) {
221     print "opcode.h>> $_" if $debug > 2;
222     if (/^OP \*\s/) { &scan_func($_); }
223     if (/^\s*EXT(CONST|\s+)/) { &scan_var($_); }
224     last LINE unless defined($_ = <CPP>);
225   }
226   # Check for transition to new header file
227   my $scanname;
228   if (/^# \d+ "(\S+)"/) {
229     my $spec = $1;
230     # Pull name from library module or header filespec
231     $spec =~ /^(\w+)$/ or $spec =~ /(\w+)\.h/i;
232     my $name = lc $1;
233     $ckfunc = exists $checkh{$name} ? 1 : 0;
234     $scanname = $name if $ckfunc;
235     print "Header file transition: ckfunc = $ckfunc for $name.h\n" if $debug > 1;
236   }
237   if ($ckfunc) {
238     print "$scanname>> $_" if $debug > 2;
239     if (/^\s*EXT(CONST|\s+)/) { &scan_var($_);  }
240     else           { &scan_func($_); }
241   }
242   else {
243     print $_ if $debug > 3 && ($debug > 5 || length($_));
244     if (/^\s*EXT(CONST|\s+)/) { &scan_var($_); }
245   }
246 }
247 close CPP;
248
249 while (<DATA>) {
250   next if /^#/;
251   s/\s+#.*\n//;
252   next if /^\s*$/;
253   my ($key,$array) = split('=',$_);
254   if ($array eq 'vars') { $key = "PL_$key";   }
255   else                  { $key = "Perl_$key"; }
256   print "Adding $key to \%$array list\n" if $debug > 1;
257   ${$array}{$key}++;
258 }
259 if ($debugging_enabled and $isgcc) { $vars{'colors'}++ }
260 foreach (split /\s+/, $extnames) {
261   my($pkgname) = $_;
262   $pkgname =~ s/::/__/g;
263   $fcns{"boot_$pkgname"}++;
264   print "Adding boot_$pkgname to \%fcns (for extension $_)\n" if $debug;
265 }
266
267 # For symbols over 31 characters, export the shortened name.
268 # TODO: Make this general purpose so we can predict the shortened name the
269 # compiler will generate for any symbol over 31 characters in length.  The
270 # docs to CC/NAMES=SHORTENED describe the CRC used to shorten the name, but
271 # don't describe its use fully enough to actually mimic what the compiler
272 # does.
273
274 if ($shorten_symbols) {
275   if (exists $fcns{'Perl_ck_entersub_args_proto_or_list'}) {
276     delete $fcns{'Perl_ck_entersub_args_proto_or_list'};
277     if ($care_about_case) {
278       $fcns{'Perl_ck_entersub_args_p11c2bjj$'}++;
279     }
280     else {
281       $fcns{'PERL_CK_ENTERSUB_ARGS_P3IAT616$'}++;
282     }
283   }
284 }
285
286 # Eventually, we'll check against existing copies here, so we can add new
287 # symbols to an existing options file in an upwardly-compatible manner.
288
289 my $marord = 1;
290 open(OPTBLD,'>', "${dir}${dbgprefix}perlshr_bld.opt")
291   or die "$0: Can't write to ${dir}${dbgprefix}perlshr_bld.opt: $!\n";
292 if ($isvax) {
293   open(MAR, '>', "${dir}perlshr_gbl${marord}.mar")
294     or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
295   print MAR "\t.title perlshr_gbl$marord\n";
296 }
297
298 unless ($isgcc) {
299   if ($isi64) {
300     print OPTBLD "PSECT_ATTR=\$GLOBAL_RO_VARS,NOEXE,RD,NOWRT,SHR\n";
301     print OPTBLD "PSECT_ATTR=\$GLOBAL_RW_VARS,NOEXE,RD,WRT,NOSHR\n";
302   }
303   else {
304     print OPTBLD "PSECT_ATTR=\$GLOBAL_RO_VARS,PIC,NOEXE,RD,NOWRT,SHR\n";
305     print OPTBLD "PSECT_ATTR=\$GLOBAL_RW_VARS,PIC,NOEXE,RD,WRT,NOSHR\n";
306   }
307 }
308 print OPTBLD "case_sensitive=yes\n" if $care_about_case;
309 my $count = 0;
310 foreach my $var (sort (keys %vars,keys %cvars)) {
311   if ($isvax) { print OPTBLD "UNIVERSAL=$var\n"; }
312   else { print OPTBLD "SYMBOL_VECTOR=($var=DATA)\n"; }
313   # This hack brought to you by the lack of a globaldef in gcc.
314   if ($isgcc) {
315     if ($count++ > 200) {  # max 254 psects/file
316       print MAR "\t.end\n";
317       close MAR;
318       $marord++;
319       open(MAR, '>', "${dir}perlshr_gbl${marord}.mar")
320         or die "$0: Can't write to ${dir}perlshr_gbl${marord}.mar: $!\n";
321       print MAR "\t.title perlshr_gbl$marord\n";
322       $count = 0;
323     }
324     print MAR "\t.psect ${var},long,pic,ovr,rd,wrt,noexe,noshr\n";
325     print MAR "\t${var}::       .blkl 1\n";
326   }
327 }
328
329 print MAR "\t.psect \$transfer_vec,pic,rd,nowrt,exe,shr\n" if ($isvax);
330 foreach my $func (sort keys %fcns) {
331   if ($isvax) {
332     print MAR "\t.transfer $func\n";
333     print MAR "\t.mask $func\n";
334     print MAR "\tjmp G\^${func}+2\n";
335   }
336   else { print OPTBLD "SYMBOL_VECTOR=($func=PROCEDURE)\n"; }
337 }
338 if ($isvax) {
339   print MAR "\t.end\n";
340   close MAR;
341 }
342
343 open(OPTATTR, '>', "${dir}perlshr_attr.opt")
344   or die "$0: Can't write to ${dir}perlshr_attr.opt: $!\n";
345 if ($isgcc) {
346   foreach my $var (sort keys %cvars) {
347     print OPTATTR "PSECT_ATTR=${var},PIC,OVR,RD,NOEXE,NOWRT,SHR\n";
348   }
349   foreach my $var (sort keys %vars) {
350     print OPTATTR "PSECT_ATTR=${var},PIC,OVR,RD,NOEXE,WRT,NOSHR\n";
351   }
352 }
353 else {
354   print OPTATTR "! No additional linker directives are needed when using DECC\n";
355 }
356 close OPTATTR;
357
358 my $incstr = 'PERL,GLOBALS';
359 my (@symfiles, $drvrname);
360 if ($isvax) {
361   $drvrname = "Compile_shrmars.tmp_".time;
362   open (DRVR,'>', $drvrname) or die "$0: Can't write to $drvrname: $!\n";
363   print DRVR "\$ Set NoOn\n";  
364   print DRVR "\$ Delete/NoLog/NoConfirm $drvrname;\n";
365   print DRVR "\$ old_proc_vfy = F\$Environment(\"VERIFY_PROCEDURE\")\n";
366   print DRVR "\$ old_img_vfy = F\$Environment(\"VERIFY_IMAGE\")\n";
367   print DRVR "\$ MCR $^X -e \"\$ENV{'LIBPERL_RDT'} = (stat('$libperl'))[9]\"\n";
368   print DRVR "\$ Set Verify\n";
369   print DRVR "\$ If F\$Search(\"$libperl\").eqs.\"\" Then Library/Object/Create $libperl\n";
370   do {
371     push(@symfiles,"perlshr_gbl$marord");
372     print DRVR "\$ Macro/NoDebug/Object=PerlShr_Gbl${marord}$objsuffix PerlShr_Gbl$marord.Mar\n";
373     print DRVR "\$ Library/Object/Replace/Log $libperl PerlShr_Gbl${marord}$objsuffix\n";
374   } while (--$marord); 
375   # We had to have a working miniperl to run this program; it's probably the
376   # one we just built.  It depended on LibPerl, which will be changed when
377   # the PerlShr_Gbl* modules get inserted, so miniperl will be out of date,
378   # and so, therefore, will all of its dependents . . .
379   # We touch LibPerl here so it'll be back 'in date', and we won't rebuild
380   # miniperl etc., and therefore LibPerl, the next time we invoke MM[KS].
381   print DRVR "\$ old_proc_vfy = F\$Verify(old_proc_vfy,old_img_vfy)\n";
382   print DRVR "\$ MCR $^X -e \"utime 0, \$ENV{'LIBPERL_RDT'}, '$libperl'\"\n";
383   close DRVR;
384 }
385
386 # Initial hack to permit building of compatible shareable images for a
387 # given version of Perl.
388 if ($ENV{PERLSHR_USE_GSMATCH}) {
389   if ($ENV{PERLSHR_USE_GSMATCH} eq 'INCLUDE_COMPILE_OPTIONS') {
390     # Build up a major ID. Since it can only be 8 bits, we encode the version
391     # number in the top four bits and use the bottom four for build options
392     # that'll cause incompatibilities
393     my ($ver, $sub) = $] =~ /\.(\d\d\d)(\d\d)/;
394     $ver += 0; $sub += 0;
395     my $gsmatch = ($sub >= 50) ? "equal" : "lequal"; # Force an equal match for
396                                                   # dev, but be more forgiving
397                                                   # for releases
398
399     $ver *=16;
400     $ver += 8 if $debugging_enabled;    # If DEBUGGING is set
401     $ver += 4 if $use_threads;          # if we're threaded
402     $ver += 2 if $use_mymalloc;         # if we're using perl's malloc
403     print OPTBLD "GSMATCH=$gsmatch,$ver,$sub\n";
404   }
405   else {
406     my $major = int($] * 1000)                        & 0xFF;  # range 0..255
407     my $minor = int(($] * 1000 - $major) * 100 + 0.5) & 0xFF;  # range 0..255
408     print OPTBLD "GSMATCH=LEQUAL,$major,$minor\n";
409   }
410   print OPTBLD 'CLUSTER=$$TRANSFER_VECTOR,,',
411                map(",$_$objsuffix",@symfiles), "\n";
412 }
413 elsif (@symfiles) { $incstr .= ',' . join(',',@symfiles); }
414 # Include object modules and RTLs in options file
415 # Linker wants /Include and /Library on different lines
416 print OPTBLD "$libperl/Include=($incstr)\n";
417 print OPTBLD "$libperl/Library\n";
418 open(RTLOPT,$rtlopt) or die "$0: Can't read options file $rtlopt: $!\n";
419 while (<RTLOPT>) { print OPTBLD; }
420 close RTLOPT;
421 close OPTBLD;
422
423 exec "\$ \@$drvrname" if $isvax;
424
425
426 __END__
427
428 # Oddball cases, so we can keep the perl.h scan above simple
429 #Foo=vars    # uncommented becomes PL_Foo
430 #Bar=funcs   # uncommented becomes Perl_Bar