This is a live mirror of the Perl 5 development currently hosted at https://github.com/perl/perl5
Fixes to Pod errors found by podchecker.
[perl5.git] / pod / perlfunc.pod
1 =head1 NAME
2
3 perlfunc - Perl builtin functions
4
5 =head1 DESCRIPTION
6
7 The functions in this section can serve as terms in an expression.
8 They fall into two major categories: list operators and named unary
9 operators.  These differ in their precedence relationship with a
10 following comma.  (See the precedence table in L<perlop>.)  List
11 operators take more than one argument, while unary operators can never
12 take more than one argument.  Thus, a comma terminates the argument of
13 a unary operator, but merely separates the arguments of a list
14 operator.  A unary operator generally provides a scalar context to its
15 argument, while a list operator may provide either scalar or list
16 contexts for its arguments.  If it does both, the scalar arguments will
17 be first, and the list argument will follow.  (Note that there can ever
18 be only one such list argument.)  For instance, splice() has three scalar
19 arguments followed by a list, whereas gethostbyname() has four scalar
20 arguments.
21
22 In the syntax descriptions that follow, list operators that expect a
23 list (and provide list context for the elements of the list) are shown
24 with LIST as an argument.  Such a list may consist of any combination
25 of scalar arguments or list values; the list values will be included
26 in the list as if each individual element were interpolated at that
27 point in the list, forming a longer single-dimensional list value.
28 Commas should separate elements of the LIST.
29
30 Any function in the list below may be used either with or without
31 parentheses around its arguments.  (The syntax descriptions omit the
32 parentheses.)  If you use the parentheses, the simple (but occasionally
33 surprising) rule is this: It I<looks> like a function, therefore it I<is> a
34 function, and precedence doesn't matter.  Otherwise it's a list
35 operator or unary operator, and precedence does matter.  And whitespace
36 between the function and left parenthesis doesn't count--so you need to
37 be careful sometimes:
38
39     print 1+2+4;        # Prints 7.
40     print(1+2) + 4;     # Prints 3.
41     print (1+2)+4;      # Also prints 3!
42     print +(1+2)+4;     # Prints 7.
43     print ((1+2)+4);    # Prints 7.
44
45 If you run Perl with the B<-w> switch it can warn you about this.  For
46 example, the third line above produces:
47
48     print (...) interpreted as function at - line 1.
49     Useless use of integer addition in void context at - line 1.
50
51 A few functions take no arguments at all, and therefore work as neither
52 unary nor list operators.  These include such functions as C<time>
53 and C<endpwent>.  For example, C<time+86_400> always means
54 C<time() + 86_400>.
55
56 For functions that can be used in either a scalar or list context,
57 nonabortive failure is generally indicated in a scalar context by
58 returning the undefined value, and in a list context by returning the
59 null list.
60
61 Remember the following important rule: There is B<no rule> that relates
62 the behavior of an expression in list context to its behavior in scalar
63 context, or vice versa.  It might do two totally different things.
64 Each operator and function decides which sort of value it would be most
65 appropriate to return in scalar context.  Some operators return the
66 length of the list that would have been returned in list context.  Some
67 operators return the first value in the list.  Some operators return the
68 last value in the list.  Some operators return a count of successful
69 operations.  In general, they do what you want, unless you want
70 consistency.
71
72 A named array in scalar context is quite different from what would at
73 first glance appear to be a list in scalar context.  You can't get a list
74 like C<(1,2,3)> into being in scalar context, because the compiler knows
75 the context at compile time.  It would generate the scalar comma operator
76 there, not the list construction version of the comma.  That means it
77 was never a list to start with.
78
79 In general, functions in Perl that serve as wrappers for system calls
80 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
81 true when they succeed and C<undef> otherwise, as is usually mentioned
82 in the descriptions below.  This is different from the C interfaces,
83 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
84 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
85 variable on failure.  Other functions do not, except accidentally.
86
87 =head2 Perl Functions by Category
88
89 Here are Perl's functions (including things that look like
90 functions, like some keywords and named operators)
91 arranged by category.  Some functions appear in more
92 than one place.
93
94 =over 4
95
96 =item Functions for SCALARs or strings
97
98 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
99 C<length>, C<oct>, C<ord>, C<pack>, C<q/STRING/>, C<qq/STRING/>, C<reverse>,
100 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
101
102 =item Regular expressions and pattern matching
103
104 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
105
106 =item Numeric functions
107
108 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
109 C<sin>, C<sqrt>, C<srand>
110
111 =item Functions for real @ARRAYs
112
113 C<pop>, C<push>, C<shift>, C<splice>, C<unshift>
114
115 =item Functions for list data
116
117 C<grep>, C<join>, C<map>, C<qw/STRING/>, C<reverse>, C<sort>, C<unpack>
118
119 =item Functions for real %HASHes
120
121 C<delete>, C<each>, C<exists>, C<keys>, C<values>
122
123 =item Input and output functions
124
125 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
126 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
127 C<readdir>, C<rewinddir>, C<seek>, C<seekdir>, C<select>, C<syscall>,
128 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
129 C<warn>, C<write>
130
131 =item Functions for fixed length data or records
132
133 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
134
135 =item Functions for filehandles, files, or directories
136
137 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
138 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
139 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
140 C<umask>, C<unlink>, C<utime>
141
142 =item Keywords related to the control flow of your Perl program
143
144 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
145 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
146
147 =item Keywords related to scoping
148
149 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<use>
150
151 =item Miscellaneous functions
152
153 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>, C<reset>,
154 C<scalar>, C<undef>, C<wantarray>
155
156 =item Functions for processes and process groups
157
158 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
159 C<pipe>, C<qx/STRING/>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
160 C<times>, C<wait>, C<waitpid>
161
162 =item Keywords related to perl modules
163
164 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
165
166 =item Keywords related to classes and object-orientedness
167
168 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
169 C<untie>, C<use>
170
171 =item Low-level socket functions
172
173 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
174 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
175 C<socket>, C<socketpair>
176
177 =item System V interprocess communication functions
178
179 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
180 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
181
182 =item Fetching user and group info
183
184 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
185 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
186 C<getpwuid>, C<setgrent>, C<setpwent>
187
188 =item Fetching network info
189
190 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
191 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
192 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
193 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
194 C<setnetent>, C<setprotoent>, C<setservent>
195
196 =item Time-related functions
197
198 C<gmtime>, C<localtime>, C<time>, C<times>
199
200 =item Functions new in perl5
201
202 C<abs>, C<bless>, C<chomp>, C<chr>, C<exists>, C<formline>, C<glob>,
203 C<import>, C<lc>, C<lcfirst>, C<map>, C<my>, C<no>, C<our>, C<prototype>,
204 C<qx>, C<qw>, C<readline>, C<readpipe>, C<ref>, C<sub*>, C<sysopen>, C<tie>,
205 C<tied>, C<uc>, C<ucfirst>, C<untie>, C<use>
206
207 * - C<sub> was a keyword in perl4, but in perl5 it is an
208 operator, which can be used in expressions.
209
210 =item Functions obsoleted in perl5
211
212 C<dbmclose>, C<dbmopen>
213
214 =back
215
216 =head2 Portability
217
218 Perl was born in Unix and can therefore access all common Unix
219 system calls.  In non-Unix environments, the functionality of some
220 Unix system calls may not be available, or details of the available
221 functionality may differ slightly.  The Perl functions affected
222 by this are:
223
224 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
225 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
226 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
227 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
228 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
229 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
230 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
231 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
232 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
233 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
234 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
235 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
236 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
237 C<shmwrite>, C<socket>, C<socketpair>,
238 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
239 C<times>, C<truncate>, C<umask>, C<unlink>,
240 C<utime>, C<wait>, C<waitpid>
241
242 For more information about the portability of these functions, see
243 L<perlport> and other available platform-specific documentation.
244
245 =head2 Alphabetical Listing of Perl Functions
246
247 =over 8
248
249 =item -X FILEHANDLE
250
251 =item -X EXPR
252
253 =item -X
254
255 A file test, where X is one of the letters listed below.  This unary
256 operator takes one argument, either a filename or a filehandle, and
257 tests the associated file to see if something is true about it.  If the
258 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
259 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
260 the undefined value if the file doesn't exist.  Despite the funny
261 names, precedence is the same as any other named unary operator, and
262 the argument may be parenthesized like any other unary operator.  The
263 operator may be any of:
264 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
265 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
266
267     -r  File is readable by effective uid/gid.
268     -w  File is writable by effective uid/gid.
269     -x  File is executable by effective uid/gid.
270     -o  File is owned by effective uid.
271
272     -R  File is readable by real uid/gid.
273     -W  File is writable by real uid/gid.
274     -X  File is executable by real uid/gid.
275     -O  File is owned by real uid.
276
277     -e  File exists.
278     -z  File has zero size (is empty).
279     -s  File has nonzero size (returns size in bytes).
280
281     -f  File is a plain file.
282     -d  File is a directory.
283     -l  File is a symbolic link.
284     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
285     -S  File is a socket.
286     -b  File is a block special file.
287     -c  File is a character special file.
288     -t  Filehandle is opened to a tty.
289
290     -u  File has setuid bit set.
291     -g  File has setgid bit set.
292     -k  File has sticky bit set.
293
294     -T  File is an ASCII text file (heuristic guess).
295     -B  File is a "binary" file (opposite of -T).
296
297     -M  Script start time minus file modification time, in days.
298     -A  Same for access time.
299     -C  Same for inode change time (Unix, may differ for other platforms)
300
301 Example:
302
303     while (<>) {
304         chomp;
305         next unless -f $_;      # ignore specials
306         #...
307     }
308
309 The interpretation of the file permission operators C<-r>, C<-R>,
310 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
311 of the file and the uids and gids of the user.  There may be other
312 reasons you can't actually read, write, or execute the file.  Such
313 reasons may be for example network filesystem access controls, ACLs
314 (access control lists), read-only filesystems, and unrecognized
315 executable formats.
316
317 Also note that, for the superuser on the local filesystems, the C<-r>,
318 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
319 if any execute bit is set in the mode.  Scripts run by the superuser
320 may thus need to do a stat() to determine the actual mode of the file,
321 or temporarily set their effective uid to something else.
322
323 If you are using ACLs, there is a pragma called C<filetest> that may
324 produce more accurate results than the bare stat() mode bits.
325 When under the C<use filetest 'access'> the above-mentioned filetests
326 will test whether the permission can (not) be granted using the
327 access() family of system calls.  Also note that the C<-x> and C<-X> may
328 under this pragma return true even if there are no execute permission
329 bits set (nor any extra execute permission ACLs).  This strangeness is
330 due to the underlying system calls' definitions.  Read the
331 documentation for the C<filetest> pragma for more information.
332
333 Note that C<-s/a/b/> does not do a negated substitution.  Saying
334 C<-exp($foo)> still works as expected, however--only single letters
335 following a minus are interpreted as file tests.
336
337 The C<-T> and C<-B> switches work as follows.  The first block or so of the
338 file is examined for odd characters such as strange control codes or
339 characters with the high bit set.  If too many strange characters (>30%)
340 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
341 containing null in the first block is considered a binary file.  If C<-T>
342 or C<-B> is used on a filehandle, the current IO buffer is examined
343 rather than the first block.  Both C<-T> and C<-B> return true on a null
344 file, or a file at EOF when testing a filehandle.  Because you have to
345 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
346 against the file first, as in C<next unless -f $file && -T $file>.
347
348 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
349 the special filehandle consisting of a solitary underline, then the stat
350 structure of the previous file test (or stat operator) is used, saving
351 a system call.  (This doesn't work with C<-t>, and you need to remember
352 that lstat() and C<-l> will leave values in the stat structure for the
353 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
354 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
355 Example:
356
357     print "Can do.\n" if -r $a || -w _ || -x _;
358
359     stat($filename);
360     print "Readable\n" if -r _;
361     print "Writable\n" if -w _;
362     print "Executable\n" if -x _;
363     print "Setuid\n" if -u _;
364     print "Setgid\n" if -g _;
365     print "Sticky\n" if -k _;
366     print "Text\n" if -T _;
367     print "Binary\n" if -B _;
368
369 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
370 test operators, in a way that C<-f -w -x $file> is equivalent to
371 C<-x $file && -w _ && -f _>. (This is only syntax fancy: if you use
372 the return value of C<-f $file> as an argument to another filetest
373 operator, no special magic will happen.)
374
375 =item abs VALUE
376
377 =item abs
378
379 Returns the absolute value of its argument.
380 If VALUE is omitted, uses C<$_>.
381
382 =item accept NEWSOCKET,GENERICSOCKET
383
384 Accepts an incoming socket connect, just as the accept(2) system call
385 does.  Returns the packed address if it succeeded, false otherwise.
386 See the example in L<perlipc/"Sockets: Client/Server Communication">.
387
388 On systems that support a close-on-exec flag on files, the flag will
389 be set for the newly opened file descriptor, as determined by the
390 value of $^F.  See L<perlvar/$^F>.
391
392 =item alarm SECONDS
393
394 =item alarm
395
396 Arranges to have a SIGALRM delivered to this process after the
397 specified number of wallclock seconds has elapsed.  If SECONDS is not
398 specified, the value stored in C<$_> is used. (On some machines,
399 unfortunately, the elapsed time may be up to one second less or more
400 than you specified because of how seconds are counted, and process
401 scheduling may delay the delivery of the signal even further.)
402
403 Only one timer may be counting at once.  Each call disables the
404 previous timer, and an argument of C<0> may be supplied to cancel the
405 previous timer without starting a new one.  The returned value is the
406 amount of time remaining on the previous timer.
407
408 For delays of finer granularity than one second, you may use Perl's
409 four-argument version of select() leaving the first three arguments
410 undefined, or you might be able to use the C<syscall> interface to
411 access setitimer(2) if your system supports it.  The Time::HiRes
412 module (from CPAN, and starting from Perl 5.8 part of the standard
413 distribution) may also prove useful.
414
415 It is usually a mistake to intermix C<alarm> and C<sleep> calls.
416 (C<sleep> may be internally implemented in your system with C<alarm>)
417
418 If you want to use C<alarm> to time out a system call you need to use an
419 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
420 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
421 restart system calls on some systems.  Using C<eval>/C<die> always works,
422 modulo the caveats given in L<perlipc/"Signals">.
423
424     eval {
425         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
426         alarm $timeout;
427         $nread = sysread SOCKET, $buffer, $size;
428         alarm 0;
429     };
430     if ($@) {
431         die unless $@ eq "alarm\n";   # propagate unexpected errors
432         # timed out
433     }
434     else {
435         # didn't
436     }
437
438 For more information see L<perlipc>.
439
440 =item atan2 Y,X
441
442 Returns the arctangent of Y/X in the range -PI to PI.
443
444 For the tangent operation, you may use the C<Math::Trig::tan>
445 function, or use the familiar relation:
446
447     sub tan { sin($_[0]) / cos($_[0])  }
448
449 Note that atan2(0, 0) is not well-defined.
450
451 =item bind SOCKET,NAME
452
453 Binds a network address to a socket, just as the bind system call
454 does.  Returns true if it succeeded, false otherwise.  NAME should be a
455 packed address of the appropriate type for the socket.  See the examples in
456 L<perlipc/"Sockets: Client/Server Communication">.
457
458 =item binmode FILEHANDLE, LAYER
459
460 =item binmode FILEHANDLE
461
462 Arranges for FILEHANDLE to be read or written in "binary" or "text"
463 mode on systems where the run-time libraries distinguish between
464 binary and text files.  If FILEHANDLE is an expression, the value is
465 taken as the name of the filehandle.  Returns true on success,
466 otherwise it returns C<undef> and sets C<$!> (errno).
467
468 On some systems (in general, DOS and Windows-based systems) binmode()
469 is necessary when you're not working with a text file.  For the sake
470 of portability it is a good idea to always use it when appropriate,
471 and to never use it when it isn't appropriate.  Also, people can
472 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
473
474 In other words: regardless of platform, use binmode() on binary data,
475 like for example images.
476
477 If LAYER is present it is a single string, but may contain multiple
478 directives. The directives alter the behaviour of the file handle.
479 When LAYER is present using binmode on text file makes sense.
480
481 If LAYER is omitted or specified as C<:raw> the filehandle is made
482 suitable for passing binary data. This includes turning off possible CRLF
483 translation and marking it as bytes (as opposed to Unicode characters).
484 Note that, despite what may be implied in I<"Programming Perl"> (the
485 Camel) or elsewhere, C<:raw> is I<not> the simply inverse of C<:crlf>
486 -- other layers which would affect binary nature of the stream are
487 I<also> disabled. See L<PerlIO>, L<perlrun> and the discussion about the
488 PERLIO environment variable.
489
490 The C<:bytes>, C<:crlf>, and C<:utf8>, and any other directives of the
491 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
492 establish default I/O layers.  See L<open>.
493
494 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
495 in "Programming Perl, 3rd Edition".  However, since the publishing of this
496 book, by many known as "Camel III", the consensus of the naming of this
497 functionality has moved from "discipline" to "layer".  All documentation
498 of this version of Perl therefore refers to "layers" rather than to
499 "disciplines".  Now back to the regularly scheduled documentation...>
500
501 To mark FILEHANDLE as UTF-8, use C<:utf8>.
502
503 In general, binmode() should be called after open() but before any I/O
504 is done on the filehandle.  Calling binmode() will normally flush any
505 pending buffered output data (and perhaps pending input data) on the
506 handle.  An exception to this is the C<:encoding> layer that
507 changes the default character encoding of the handle, see L<open>.
508 The C<:encoding> layer sometimes needs to be called in
509 mid-stream, and it doesn't flush the stream.  The C<:encoding>
510 also implicitly pushes on top of itself the C<:utf8> layer because
511 internally Perl will operate on UTF-8 encoded Unicode characters.
512
513 The operating system, device drivers, C libraries, and Perl run-time
514 system all work together to let the programmer treat a single
515 character (C<\n>) as the line terminator, irrespective of the external
516 representation.  On many operating systems, the native text file
517 representation matches the internal representation, but on some
518 platforms the external representation of C<\n> is made up of more than
519 one character.
520
521 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
522 character to end each line in the external representation of text (even
523 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
524 on Unix and most VMS files). In other systems like OS/2, DOS and the
525 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
526 but what's stored in text files are the two characters C<\cM\cJ>.  That
527 means that, if you don't use binmode() on these systems, C<\cM\cJ>
528 sequences on disk will be converted to C<\n> on input, and any C<\n> in
529 your program will be converted back to C<\cM\cJ> on output.  This is what
530 you want for text files, but it can be disastrous for binary files.
531
532 Another consequence of using binmode() (on some systems) is that
533 special end-of-file markers will be seen as part of the data stream.
534 For systems from the Microsoft family this means that if your binary
535 data contains C<\cZ>, the I/O subsystem will regard it as the end of
536 the file, unless you use binmode().
537
538 binmode() is not only important for readline() and print() operations,
539 but also when using read(), seek(), sysread(), syswrite() and tell()
540 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
541 in L<perlvar> for how to manually set your input and output
542 line-termination sequences.
543
544 =item bless REF,CLASSNAME
545
546 =item bless REF
547
548 This function tells the thingy referenced by REF that it is now an object
549 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
550 is used.  Because a C<bless> is often the last thing in a constructor,
551 it returns the reference for convenience.  Always use the two-argument
552 version if a derived class might inherit the function doing the blessing.
553 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
554 of objects.
555
556 Consider always blessing objects in CLASSNAMEs that are mixed case.
557 Namespaces with all lowercase names are considered reserved for
558 Perl pragmata.  Builtin types have all uppercase names. To prevent
559 confusion, you may wish to avoid such package names as well.  Make sure
560 that CLASSNAME is a true value.
561
562 See L<perlmod/"Perl Modules">.
563
564 =item caller EXPR
565
566 =item caller
567
568 Returns the context of the current subroutine call.  In scalar context,
569 returns the caller's package name if there is a caller, that is, if
570 we're in a subroutine or C<eval> or C<require>, and the undefined value
571 otherwise.  In list context, returns
572
573     ($package, $filename, $line) = caller;
574
575 With EXPR, it returns some extra information that the debugger uses to
576 print a stack trace.  The value of EXPR indicates how many call frames
577 to go back before the current one.
578
579     ($package, $filename, $line, $subroutine, $hasargs,
580     $wantarray, $evaltext, $is_require, $hints, $bitmask) = caller($i);
581
582 Here $subroutine may be C<(eval)> if the frame is not a subroutine
583 call, but an C<eval>.  In such a case additional elements $evaltext and
584 C<$is_require> are set: C<$is_require> is true if the frame is created by a
585 C<require> or C<use> statement, $evaltext contains the text of the
586 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
587 $filename is C<(eval)>, but $evaltext is undefined.  (Note also that
588 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
589 frame.)  $subroutine may also be C<(unknown)> if this particular
590 subroutine happens to have been deleted from the symbol table.
591 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
592 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
593 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
594 between versions of Perl, and are not meant for external use.
595
596 Furthermore, when called from within the DB package, caller returns more
597 detailed information: it sets the list variable C<@DB::args> to be the
598 arguments with which the subroutine was invoked.
599
600 Be aware that the optimizer might have optimized call frames away before
601 C<caller> had a chance to get the information.  That means that C<caller(N)>
602 might not return information about the call frame you expect it do, for
603 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
604 previous time C<caller> was called.
605
606 =item chdir EXPR
607
608 =item chdir FILEHANDLE
609
610 =item chdir DIRHANDLE
611
612 =item chdir
613
614 Changes the working directory to EXPR, if possible. If EXPR is omitted,
615 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
616 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
617 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
618 neither is set, C<chdir> does nothing. It returns true upon success,
619 false otherwise. See the example under C<die>.
620
621 On systems that support fchdir, you might pass a file handle or
622 directory handle as argument.  On systems that don't support fchdir,
623 passing handles produces a fatal error at run time.
624
625 =item chmod LIST
626
627 Changes the permissions of a list of files.  The first element of the
628 list must be the numerical mode, which should probably be an octal
629 number, and which definitely should I<not> be a string of octal digits:
630 C<0644> is okay, C<'0644'> is not.  Returns the number of files
631 successfully changed.  See also L</oct>, if all you have is a string.
632
633     $cnt = chmod 0755, 'foo', 'bar';
634     chmod 0755, @executables;
635     $mode = '0644'; chmod $mode, 'foo';      # !!! sets mode to
636                                              # --w----r-T
637     $mode = '0644'; chmod oct($mode), 'foo'; # this is better
638     $mode = 0644;   chmod $mode, 'foo';      # this is best
639
640 On systems that support fchmod, you might pass file handles among the
641 files.  On systems that don't support fchmod, passing file handles
642 produces a fatal error at run time.
643
644     open(my $fh, "<", "foo");
645     my $perm = (stat $fh)[2] & 07777;
646     chmod($perm | 0600, $fh);
647
648 You can also import the symbolic C<S_I*> constants from the Fcntl
649 module:
650
651     use Fcntl ':mode';
652
653     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
654     # This is identical to the chmod 0755 of the above example.
655
656 =item chomp VARIABLE
657
658 =item chomp( LIST )
659
660 =item chomp
661
662 This safer version of L</chop> removes any trailing string
663 that corresponds to the current value of C<$/> (also known as
664 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
665 number of characters removed from all its arguments.  It's often used to
666 remove the newline from the end of an input record when you're worried
667 that the final record may be missing its newline.  When in paragraph
668 mode (C<$/ = "">), it removes all trailing newlines from the string.
669 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
670 a reference to an integer or the like, see L<perlvar>) chomp() won't
671 remove anything.
672 If VARIABLE is omitted, it chomps C<$_>.  Example:
673
674     while (<>) {
675         chomp;  # avoid \n on last field
676         @array = split(/:/);
677         # ...
678     }
679
680 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
681
682 You can actually chomp anything that's an lvalue, including an assignment:
683
684     chomp($cwd = `pwd`);
685     chomp($answer = <STDIN>);
686
687 If you chomp a list, each element is chomped, and the total number of
688 characters removed is returned.
689
690 If the C<encoding> pragma is in scope then the lengths returned are
691 calculated from the length of C<$/> in Unicode characters, which is not
692 always the same as the length of C<$/> in the native encoding.
693
694 Note that parentheses are necessary when you're chomping anything
695 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
696 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
697 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
698 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
699 as C<chomp($a, $b)>.
700
701 =item chop VARIABLE
702
703 =item chop( LIST )
704
705 =item chop
706
707 Chops off the last character of a string and returns the character
708 chopped.  It is much more efficient than C<s/.$//s> because it neither
709 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
710 If VARIABLE is a hash, it chops the hash's values, but not its keys.
711
712 You can actually chop anything that's an lvalue, including an assignment.
713
714 If you chop a list, each element is chopped.  Only the value of the
715 last C<chop> is returned.
716
717 Note that C<chop> returns the last character.  To return all but the last
718 character, use C<substr($string, 0, -1)>.
719
720 See also L</chomp>.
721
722 =item chown LIST
723
724 Changes the owner (and group) of a list of files.  The first two
725 elements of the list must be the I<numeric> uid and gid, in that
726 order.  A value of -1 in either position is interpreted by most
727 systems to leave that value unchanged.  Returns the number of files
728 successfully changed.
729
730     $cnt = chown $uid, $gid, 'foo', 'bar';
731     chown $uid, $gid, @filenames;
732
733 On systems that support fchown, you might pass file handles among the
734 files.  On systems that don't support fchown, passing file handles
735 produces a fatal error at run time.
736
737 Here's an example that looks up nonnumeric uids in the passwd file:
738
739     print "User: ";
740     chomp($user = <STDIN>);
741     print "Files: ";
742     chomp($pattern = <STDIN>);
743
744     ($login,$pass,$uid,$gid) = getpwnam($user)
745         or die "$user not in passwd file";
746
747     @ary = glob($pattern);      # expand filenames
748     chown $uid, $gid, @ary;
749
750 On most systems, you are not allowed to change the ownership of the
751 file unless you're the superuser, although you should be able to change
752 the group to any of your secondary groups.  On insecure systems, these
753 restrictions may be relaxed, but this is not a portable assumption.
754 On POSIX systems, you can detect this condition this way:
755
756     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
757     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
758
759 =item chr NUMBER
760
761 =item chr
762
763 Returns the character represented by that NUMBER in the character set.
764 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
765 chr(0x263a) is a Unicode smiley face.  Note that characters from 128
766 to 255 (inclusive) are by default not encoded in UTF-8 Unicode for
767 backward compatibility reasons (but see L<encoding>).
768
769 Negative values give the Unicode replacement character (chr(0xfffd)),
770 except under the L<bytes> pragma, where low eight bits of the value
771 (truncated to an integer) are used.
772
773 If NUMBER is omitted, uses C<$_>.
774
775 For the reverse, use L</ord>.
776
777 Note that under the C<bytes> pragma the NUMBER is masked to
778 the low eight bits.
779
780 See L<perlunicode> and L<encoding> for more about Unicode.
781
782 =item chroot FILENAME
783
784 =item chroot
785
786 This function works like the system call by the same name: it makes the
787 named directory the new root directory for all further pathnames that
788 begin with a C</> by your process and all its children.  (It doesn't
789 change your current working directory, which is unaffected.)  For security
790 reasons, this call is restricted to the superuser.  If FILENAME is
791 omitted, does a C<chroot> to C<$_>.
792
793 =item close FILEHANDLE
794
795 =item close
796
797 Closes the file or pipe associated with the file handle, returning
798 true only if IO buffers are successfully flushed and closes the system
799 file descriptor.  Closes the currently selected filehandle if the
800 argument is omitted.
801
802 You don't have to close FILEHANDLE if you are immediately going to do
803 another C<open> on it, because C<open> will close it for you.  (See
804 C<open>.)  However, an explicit C<close> on an input file resets the line
805 counter (C<$.>), while the implicit close done by C<open> does not.
806
807 If the file handle came from a piped open, C<close> will additionally
808 return false if one of the other system calls involved fails, or if the
809 program exits with non-zero status.  (If the only problem was that the
810 program exited non-zero, C<$!> will be set to C<0>.)  Closing a pipe
811 also waits for the process executing on the pipe to complete, in case you
812 want to look at the output of the pipe afterwards, and
813 implicitly puts the exit status value of that command into C<$?> and
814 C<${^CHILD_ERROR_NATIVE}>.
815
816 Prematurely closing the read end of a pipe (i.e. before the process
817 writing to it at the other end has closed it) will result in a
818 SIGPIPE being delivered to the writer.  If the other end can't
819 handle that, be sure to read all the data before closing the pipe.
820
821 Example:
822
823     open(OUTPUT, '|sort >foo')  # pipe to sort
824         or die "Can't start sort: $!";
825     #...                        # print stuff to output
826     close OUTPUT                # wait for sort to finish
827         or warn $! ? "Error closing sort pipe: $!"
828                    : "Exit status $? from sort";
829     open(INPUT, 'foo')          # get sort's results
830         or die "Can't open 'foo' for input: $!";
831
832 FILEHANDLE may be an expression whose value can be used as an indirect
833 filehandle, usually the real filehandle name.
834
835 =item closedir DIRHANDLE
836
837 Closes a directory opened by C<opendir> and returns the success of that
838 system call.
839
840 =item connect SOCKET,NAME
841
842 Attempts to connect to a remote socket, just as the connect system call
843 does.  Returns true if it succeeded, false otherwise.  NAME should be a
844 packed address of the appropriate type for the socket.  See the examples in
845 L<perlipc/"Sockets: Client/Server Communication">.
846
847 =item continue BLOCK
848
849 C<continue> is actually a flow control statement rather than a function.  If
850 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
851 C<foreach>), it is always executed just before the conditional is about to
852 be evaluated again, just like the third part of a C<for> loop in C.  Thus
853 it can be used to increment a loop variable, even when the loop has been
854 continued via the C<next> statement (which is similar to the C C<continue>
855 statement).
856
857 C<last>, C<next>, or C<redo> may appear within a C<continue>
858 block.  C<last> and C<redo> will behave as if they had been executed within
859 the main block.  So will C<next>, but since it will execute a C<continue>
860 block, it may be more entertaining.
861
862     while (EXPR) {
863         ### redo always comes here
864         do_something;
865     } continue {
866         ### next always comes here
867         do_something_else;
868         # then back the top to re-check EXPR
869     }
870     ### last always comes here
871
872 Omitting the C<continue> section is semantically equivalent to using an
873 empty one, logically enough.  In that case, C<next> goes directly back
874 to check the condition at the top of the loop.
875
876 =item cos EXPR
877
878 =item cos
879
880 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
881 takes cosine of C<$_>.
882
883 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
884 function, or use this relation:
885
886     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
887
888 =item crypt PLAINTEXT,SALT
889
890 Creates a digest string exactly like the crypt(3) function in the C
891 library (assuming that you actually have a version there that has not
892 been extirpated as a potential munitions).
893
894 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
895 into a short string, called a digest, which is returned.  The same
896 PLAINTEXT and SALT will always return the same string, but there is no
897 (known) way to get the original PLAINTEXT from the hash.  Small
898 changes in the PLAINTEXT or SALT will result in large changes in the
899 digest.
900
901 There is no decrypt function.  This function isn't all that useful for
902 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
903 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
904 primarily used to check if two pieces of text are the same without
905 having to transmit or store the text itself.  An example is checking
906 if a correct password is given.  The digest of the password is stored,
907 not the password itself.  The user types in a password that is
908 crypt()'d with the same salt as the stored digest.  If the two digests
909 match the password is correct.
910
911 When verifying an existing digest string you should use the digest as
912 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
913 to create the digest is visible as part of the digest.  This ensures
914 crypt() will hash the new string with the same salt as the digest.
915 This allows your code to work with the standard L<crypt|/crypt> and
916 with more exotic implementations.  In other words, do not assume
917 anything about the returned string itself, or how many bytes in the
918 digest matter.
919
920 Traditionally the result is a string of 13 bytes: two first bytes of
921 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
922 the first eight bytes of the digest string mattered, but alternative
923 hashing schemes (like MD5), higher level security schemes (like C2),
924 and implementations on non-UNIX platforms may produce different
925 strings.
926
927 When choosing a new salt create a random two character string whose
928 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
929 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
930 characters is just a recommendation; the characters allowed in
931 the salt depend solely on your system's crypt library, and Perl can't
932 restrict what salts C<crypt()> accepts.
933
934 Here's an example that makes sure that whoever runs this program knows
935 their password:
936
937     $pwd = (getpwuid($<))[1];
938
939     system "stty -echo";
940     print "Password: ";
941     chomp($word = <STDIN>);
942     print "\n";
943     system "stty echo";
944
945     if (crypt($word, $pwd) ne $pwd) {
946         die "Sorry...\n";
947     } else {
948         print "ok\n";
949     }
950
951 Of course, typing in your own password to whoever asks you
952 for it is unwise.
953
954 The L<crypt|/crypt> function is unsuitable for hashing large quantities
955 of data, not least of all because you can't get the information
956 back.  Look at the L<Digest> module for more robust algorithms.
957
958 If using crypt() on a Unicode string (which I<potentially> has
959 characters with codepoints above 255), Perl tries to make sense
960 of the situation by trying to downgrade (a copy of the string)
961 the string back to an eight-bit byte string before calling crypt()
962 (on that copy).  If that works, good.  If not, crypt() dies with
963 C<Wide character in crypt>.
964
965 =item dbmclose HASH
966
967 [This function has been largely superseded by the C<untie> function.]
968
969 Breaks the binding between a DBM file and a hash.
970
971 =item dbmopen HASH,DBNAME,MASK
972
973 [This function has been largely superseded by the C<tie> function.]
974
975 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
976 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
977 argument is I<not> a filehandle, even though it looks like one).  DBNAME
978 is the name of the database (without the F<.dir> or F<.pag> extension if
979 any).  If the database does not exist, it is created with protection
980 specified by MASK (as modified by the C<umask>).  If your system supports
981 only the older DBM functions, you may perform only one C<dbmopen> in your
982 program.  In older versions of Perl, if your system had neither DBM nor
983 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
984 sdbm(3).
985
986 If you don't have write access to the DBM file, you can only read hash
987 variables, not set them.  If you want to test whether you can write,
988 either use file tests or try setting a dummy hash entry inside an C<eval>,
989 which will trap the error.
990
991 Note that functions such as C<keys> and C<values> may return huge lists
992 when used on large DBM files.  You may prefer to use the C<each>
993 function to iterate over large DBM files.  Example:
994
995     # print out history file offsets
996     dbmopen(%HIST,'/usr/lib/news/history',0666);
997     while (($key,$val) = each %HIST) {
998         print $key, ' = ', unpack('L',$val), "\n";
999     }
1000     dbmclose(%HIST);
1001
1002 See also L<AnyDBM_File> for a more general description of the pros and
1003 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1004 rich implementation.
1005
1006 You can control which DBM library you use by loading that library
1007 before you call dbmopen():
1008
1009     use DB_File;
1010     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1011         or die "Can't open netscape history file: $!";
1012
1013 =item defined EXPR
1014
1015 =item defined
1016
1017 Returns a Boolean value telling whether EXPR has a value other than
1018 the undefined value C<undef>.  If EXPR is not present, C<$_> will be
1019 checked.
1020
1021 Many operations return C<undef> to indicate failure, end of file,
1022 system error, uninitialized variable, and other exceptional
1023 conditions.  This function allows you to distinguish C<undef> from
1024 other values.  (A simple Boolean test will not distinguish among
1025 C<undef>, zero, the empty string, and C<"0">, which are all equally
1026 false.)  Note that since C<undef> is a valid scalar, its presence
1027 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1028 returns C<undef> when its argument is an empty array, I<or> when the
1029 element to return happens to be C<undef>.
1030
1031 You may also use C<defined(&func)> to check whether subroutine C<&func>
1032 has ever been defined.  The return value is unaffected by any forward
1033 declarations of C<&func>.  Note that a subroutine which is not defined
1034 may still be callable: its package may have an C<AUTOLOAD> method that
1035 makes it spring into existence the first time that it is called -- see
1036 L<perlsub>.
1037
1038 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1039 used to report whether memory for that aggregate has ever been
1040 allocated.  This behavior may disappear in future versions of Perl.
1041 You should instead use a simple test for size:
1042
1043     if (@an_array) { print "has array elements\n" }
1044     if (%a_hash)   { print "has hash members\n"   }
1045
1046 When used on a hash element, it tells you whether the value is defined,
1047 not whether the key exists in the hash.  Use L</exists> for the latter
1048 purpose.
1049
1050 Examples:
1051
1052     print if defined $switch{'D'};
1053     print "$val\n" while defined($val = pop(@ary));
1054     die "Can't readlink $sym: $!"
1055         unless defined($value = readlink $sym);
1056     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1057     $debugging = 0 unless defined $debugging;
1058
1059 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1060 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1061 defined values.  For example, if you say
1062
1063     "ab" =~ /a(.*)b/;
1064
1065 The pattern match succeeds, and C<$1> is defined, despite the fact that it
1066 matched "nothing".  It didn't really fail to match anything.  Rather, it
1067 matched something that happened to be zero characters long.  This is all
1068 very above-board and honest.  When a function returns an undefined value,
1069 it's an admission that it couldn't give you an honest answer.  So you
1070 should use C<defined> only when you're questioning the integrity of what
1071 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1072 what you want.
1073
1074 See also L</undef>, L</exists>, L</ref>.
1075
1076 =item delete EXPR
1077
1078 Given an expression that specifies a hash element, array element, hash slice,
1079 or array slice, deletes the specified element(s) from the hash or array.
1080 In the case of an array, if the array elements happen to be at the end,
1081 the size of the array will shrink to the highest element that tests
1082 true for exists() (or 0 if no such element exists).
1083
1084 Returns a list with the same number of elements as the number of elements
1085 for which deletion was attempted.  Each element of that list consists of
1086 either the value of the element deleted, or the undefined value.  In scalar
1087 context, this means that you get the value of the last element deleted (or
1088 the undefined value if that element did not exist).
1089
1090     %hash = (foo => 11, bar => 22, baz => 33);
1091     $scalar = delete $hash{foo};             # $scalar is 11
1092     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1093     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1094
1095 Deleting from C<%ENV> modifies the environment.  Deleting from
1096 a hash tied to a DBM file deletes the entry from the DBM file.  Deleting
1097 from a C<tie>d hash or array may not necessarily return anything.
1098
1099 Deleting an array element effectively returns that position of the array
1100 to its initial, uninitialized state.  Subsequently testing for the same
1101 element with exists() will return false.  Also, deleting array elements
1102 in the middle of an array will not shift the index of the elements
1103 after them down.  Use splice() for that.  See L</exists>.
1104
1105 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1106
1107     foreach $key (keys %HASH) {
1108         delete $HASH{$key};
1109     }
1110
1111     foreach $index (0 .. $#ARRAY) {
1112         delete $ARRAY[$index];
1113     }
1114
1115 And so do these:
1116
1117     delete @HASH{keys %HASH};
1118
1119     delete @ARRAY[0 .. $#ARRAY];
1120
1121 But both of these are slower than just assigning the empty list
1122 or undefining %HASH or @ARRAY:
1123
1124     %HASH = ();         # completely empty %HASH
1125     undef %HASH;        # forget %HASH ever existed
1126
1127     @ARRAY = ();        # completely empty @ARRAY
1128     undef @ARRAY;       # forget @ARRAY ever existed
1129
1130 Note that the EXPR can be arbitrarily complicated as long as the final
1131 operation is a hash element, array element,  hash slice, or array slice
1132 lookup:
1133
1134     delete $ref->[$x][$y]{$key};
1135     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1136
1137     delete $ref->[$x][$y][$index];
1138     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1139
1140 =item die LIST
1141
1142 Outside an C<eval>, prints the value of LIST to C<STDERR> and
1143 exits with the current value of C<$!> (errno).  If C<$!> is C<0>,
1144 exits with the value of C<<< ($? >> 8) >>> (backtick `command`
1145 status).  If C<<< ($? >> 8) >>> is C<0>, exits with C<255>.  Inside
1146 an C<eval(),> the error message is stuffed into C<$@> and the
1147 C<eval> is terminated with the undefined value.  This makes
1148 C<die> the way to raise an exception.
1149
1150 Equivalent examples:
1151
1152     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1153     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1154
1155 If the last element of LIST does not end in a newline, the current
1156 script line number and input line number (if any) are also printed,
1157 and a newline is supplied.  Note that the "input line number" (also
1158 known as "chunk") is subject to whatever notion of "line" happens to
1159 be currently in effect, and is also available as the special variable
1160 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1161
1162 Hint: sometimes appending C<", stopped"> to your message will cause it
1163 to make better sense when the string C<"at foo line 123"> is appended.
1164 Suppose you are running script "canasta".
1165
1166     die "/etc/games is no good";
1167     die "/etc/games is no good, stopped";
1168
1169 produce, respectively
1170
1171     /etc/games is no good at canasta line 123.
1172     /etc/games is no good, stopped at canasta line 123.
1173
1174 See also exit(), warn(), and the Carp module.
1175
1176 If LIST is empty and C<$@> already contains a value (typically from a
1177 previous eval) that value is reused after appending C<"\t...propagated">.
1178 This is useful for propagating exceptions:
1179
1180     eval { ... };
1181     die unless $@ =~ /Expected exception/;
1182
1183 If LIST is empty and C<$@> contains an object reference that has a
1184 C<PROPAGATE> method, that method will be called with additional file
1185 and line number parameters.  The return value replaces the value in
1186 C<$@>.  i.e. as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1187 were called.
1188
1189 If C<$@> is empty then the string C<"Died"> is used.
1190
1191 die() can also be called with a reference argument.  If this happens to be
1192 trapped within an eval(), $@ contains the reference.  This behavior permits
1193 a more elaborate exception handling implementation using objects that
1194 maintain arbitrary state about the nature of the exception.  Such a scheme
1195 is sometimes preferable to matching particular string values of $@ using
1196 regular expressions.  Here's an example:
1197
1198     use Scalar::Util 'blessed';
1199
1200     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1201     if ($@) {
1202         if (blessed($@) && $@->isa("Some::Module::Exception")) {
1203             # handle Some::Module::Exception
1204         }
1205         else {
1206             # handle all other possible exceptions
1207         }
1208     }
1209
1210 Because perl will stringify uncaught exception messages before displaying
1211 them, you may want to overload stringification operations on such custom
1212 exception objects.  See L<overload> for details about that.
1213
1214 You can arrange for a callback to be run just before the C<die>
1215 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1216 handler will be called with the error text and can change the error
1217 message, if it sees fit, by calling C<die> again.  See
1218 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1219 L<"eval BLOCK"> for some examples.  Although this feature was 
1220 to be run only right before your program was to exit, this is not
1221 currently the case--the C<$SIG{__DIE__}> hook is currently called
1222 even inside eval()ed blocks/strings!  If one wants the hook to do
1223 nothing in such situations, put
1224
1225         die @_ if $^S;
1226
1227 as the first line of the handler (see L<perlvar/$^S>).  Because
1228 this promotes strange action at a distance, this counterintuitive
1229 behavior may be fixed in a future release.
1230
1231 =item do BLOCK
1232
1233 Not really a function.  Returns the value of the last command in the
1234 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1235 C<until> loop modifier, executes the BLOCK once before testing the loop
1236 condition. (On other statements the loop modifiers test the conditional
1237 first.)
1238
1239 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1240 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1241 See L<perlsyn> for alternative strategies.
1242
1243 =item do SUBROUTINE(LIST)
1244
1245 This form of subroutine call is deprecated.  See L<perlsub>.
1246
1247 =item do EXPR
1248
1249 Uses the value of EXPR as a filename and executes the contents of the
1250 file as a Perl script.
1251
1252     do 'stat.pl';
1253
1254 is just like
1255
1256     eval `cat stat.pl`;
1257
1258 except that it's more efficient and concise, keeps track of the current
1259 filename for error messages, searches the @INC directories, and updates
1260 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1261 variables.  It also differs in that code evaluated with C<do FILENAME>
1262 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1263 same, however, in that it does reparse the file every time you call it,
1264 so you probably don't want to do this inside a loop.
1265
1266 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1267 error.  If C<do> can read the file but cannot compile it, it
1268 returns undef and sets an error message in C<$@>.   If the file is
1269 successfully compiled, C<do> returns the value of the last expression
1270 evaluated.
1271
1272 Note that inclusion of library modules is better done with the
1273 C<use> and C<require> operators, which also do automatic error checking
1274 and raise an exception if there's a problem.
1275
1276 You might like to use C<do> to read in a program configuration
1277 file.  Manual error checking can be done this way:
1278
1279     # read in config files: system first, then user
1280     for $file ("/share/prog/defaults.rc",
1281                "$ENV{HOME}/.someprogrc")
1282    {
1283         unless ($return = do $file) {
1284             warn "couldn't parse $file: $@" if $@;
1285             warn "couldn't do $file: $!"    unless defined $return;
1286             warn "couldn't run $file"       unless $return;
1287         }
1288     }
1289
1290 =item dump LABEL
1291
1292 =item dump
1293
1294 This function causes an immediate core dump.  See also the B<-u>
1295 command-line switch in L<perlrun>, which does the same thing.
1296 Primarily this is so that you can use the B<undump> program (not
1297 supplied) to turn your core dump into an executable binary after
1298 having initialized all your variables at the beginning of the
1299 program.  When the new binary is executed it will begin by executing
1300 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1301 Think of it as a goto with an intervening core dump and reincarnation.
1302 If C<LABEL> is omitted, restarts the program from the top.
1303
1304 B<WARNING>: Any files opened at the time of the dump will I<not>
1305 be open any more when the program is reincarnated, with possible
1306 resulting confusion on the part of Perl.
1307
1308 This function is now largely obsolete, partly because it's very
1309 hard to convert a core file into an executable, and because the
1310 real compiler backends for generating portable bytecode and compilable
1311 C code have superseded it.  That's why you should now invoke it as
1312 C<CORE::dump()>, if you don't want to be warned against a possible
1313 typo.
1314
1315 If you're looking to use L<dump> to speed up your program, consider
1316 generating bytecode or native C code as described in L<perlcc>.  If
1317 you're just trying to accelerate a CGI script, consider using the
1318 C<mod_perl> extension to B<Apache>, or the CPAN module, CGI::Fast.
1319 You might also consider autoloading or selfloading, which at least
1320 make your program I<appear> to run faster.
1321
1322 =item each HASH
1323
1324 When called in list context, returns a 2-element list consisting of the
1325 key and value for the next element of a hash, so that you can iterate over
1326 it.  When called in scalar context, returns only the key for the next
1327 element in the hash.
1328
1329 Entries are returned in an apparently random order.  The actual random
1330 order is subject to change in future versions of perl, but it is
1331 guaranteed to be in the same order as either the C<keys> or C<values>
1332 function would produce on the same (unmodified) hash.  Since Perl
1333 5.8.1 the ordering is different even between different runs of Perl
1334 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1335
1336 When the hash is entirely read, a null array is returned in list context
1337 (which when assigned produces a false (C<0>) value), and C<undef> in
1338 scalar context.  The next call to C<each> after that will start iterating
1339 again.  There is a single iterator for each hash, shared by all C<each>,
1340 C<keys>, and C<values> function calls in the program; it can be reset by
1341 reading all the elements from the hash, or by evaluating C<keys HASH> or
1342 C<values HASH>.  If you add or delete elements of a hash while you're
1343 iterating over it, you may get entries skipped or duplicated, so
1344 don't.  Exception: It is always safe to delete the item most recently
1345 returned by C<each()>, which means that the following code will work:
1346
1347         while (($key, $value) = each %hash) {
1348           print $key, "\n";
1349           delete $hash{$key};   # This is safe
1350         }
1351
1352 The following prints out your environment like the printenv(1) program,
1353 only in a different order:
1354
1355     while (($key,$value) = each %ENV) {
1356         print "$key=$value\n";
1357     }
1358
1359 See also C<keys>, C<values> and C<sort>.
1360
1361 =item eof FILEHANDLE
1362
1363 =item eof ()
1364
1365 =item eof
1366
1367 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1368 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1369 gives the real filehandle.  (Note that this function actually
1370 reads a character and then C<ungetc>s it, so isn't very useful in an
1371 interactive context.)  Do not read from a terminal file (or call
1372 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1373 as terminals may lose the end-of-file condition if you do.
1374
1375 An C<eof> without an argument uses the last file read.  Using C<eof()>
1376 with empty parentheses is very different.  It refers to the pseudo file
1377 formed from the files listed on the command line and accessed via the
1378 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1379 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1380 used will cause C<@ARGV> to be examined to determine if input is
1381 available.   Similarly, an C<eof()> after C<< <> >> has returned
1382 end-of-file will assume you are processing another C<@ARGV> list,
1383 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1384 see L<perlop/"I/O Operators">.
1385
1386 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1387 detect the end of each file, C<eof()> will only detect the end of the
1388 last file.  Examples:
1389
1390     # reset line numbering on each input file
1391     while (<>) {
1392         next if /^\s*#/;        # skip comments
1393         print "$.\t$_";
1394     } continue {
1395         close ARGV  if eof;     # Not eof()!
1396     }
1397
1398     # insert dashes just before last line of last file
1399     while (<>) {
1400         if (eof()) {            # check for end of last file
1401             print "--------------\n";
1402         }
1403         print;
1404         last if eof();          # needed if we're reading from a terminal
1405     }
1406
1407 Practical hint: you almost never need to use C<eof> in Perl, because the
1408 input operators typically return C<undef> when they run out of data, or if
1409 there was an error.
1410
1411 =item eval EXPR
1412
1413 =item eval BLOCK
1414
1415 =item eval
1416
1417 In the first form, the return value of EXPR is parsed and executed as if it
1418 were a little Perl program.  The value of the expression (which is itself
1419 determined within scalar context) is first parsed, and if there weren't any
1420 errors, executed in the lexical context of the current Perl program, so
1421 that any variable settings or subroutine and format definitions remain
1422 afterwards.  Note that the value is parsed every time the C<eval> executes.
1423 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1424 delay parsing and subsequent execution of the text of EXPR until run time.
1425
1426 In the second form, the code within the BLOCK is parsed only once--at the
1427 same time the code surrounding the C<eval> itself was parsed--and executed
1428 within the context of the current Perl program.  This form is typically
1429 used to trap exceptions more efficiently than the first (see below), while
1430 also providing the benefit of checking the code within BLOCK at compile
1431 time.
1432
1433 The final semicolon, if any, may be omitted from the value of EXPR or within
1434 the BLOCK.
1435
1436 In both forms, the value returned is the value of the last expression
1437 evaluated inside the mini-program; a return statement may be also used, just
1438 as with subroutines.  The expression providing the return value is evaluated
1439 in void, scalar, or list context, depending on the context of the C<eval> 
1440 itself.  See L</wantarray> for more on how the evaluation context can be 
1441 determined.
1442
1443 If there is a syntax error or runtime error, or a C<die> statement is
1444 executed, an undefined value is returned by C<eval>, and C<$@> is set to the
1445 error message.  If there was no error, C<$@> is guaranteed to be a null
1446 string.  Beware that using C<eval> neither silences perl from printing
1447 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1448 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1449 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1450 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1451
1452 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1453 determining whether a particular feature (such as C<socket> or C<symlink>)
1454 is implemented.  It is also Perl's exception trapping mechanism, where
1455 the die operator is used to raise exceptions.
1456
1457 If the code to be executed doesn't vary, you may use the eval-BLOCK
1458 form to trap run-time errors without incurring the penalty of
1459 recompiling each time.  The error, if any, is still returned in C<$@>.
1460 Examples:
1461
1462     # make divide-by-zero nonfatal
1463     eval { $answer = $a / $b; }; warn $@ if $@;
1464
1465     # same thing, but less efficient
1466     eval '$answer = $a / $b'; warn $@ if $@;
1467
1468     # a compile-time error
1469     eval { $answer = };                 # WRONG
1470
1471     # a run-time error
1472     eval '$answer =';   # sets $@
1473
1474 Using the C<eval{}> form as an exception trap in libraries does have some
1475 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1476 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1477 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1478 as shown in this example:
1479
1480     # a very private exception trap for divide-by-zero
1481     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1482     warn $@ if $@;
1483
1484 This is especially significant, given that C<__DIE__> hooks can call
1485 C<die> again, which has the effect of changing their error messages:
1486
1487     # __DIE__ hooks may modify error messages
1488     {
1489        local $SIG{'__DIE__'} =
1490               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1491        eval { die "foo lives here" };
1492        print $@ if $@;                # prints "bar lives here"
1493     }
1494
1495 Because this promotes action at a distance, this counterintuitive behavior
1496 may be fixed in a future release.
1497
1498 With an C<eval>, you should be especially careful to remember what's
1499 being looked at when:
1500
1501     eval $x;            # CASE 1
1502     eval "$x";          # CASE 2
1503
1504     eval '$x';          # CASE 3
1505     eval { $x };        # CASE 4
1506
1507     eval "\$$x++";      # CASE 5
1508     $$x++;              # CASE 6
1509
1510 Cases 1 and 2 above behave identically: they run the code contained in
1511 the variable $x.  (Although case 2 has misleading double quotes making
1512 the reader wonder what else might be happening (nothing is).)  Cases 3
1513 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1514 does nothing but return the value of $x.  (Case 4 is preferred for
1515 purely visual reasons, but it also has the advantage of compiling at
1516 compile-time instead of at run-time.)  Case 5 is a place where
1517 normally you I<would> like to use double quotes, except that in this
1518 particular situation, you can just use symbolic references instead, as
1519 in case 6.
1520
1521 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1522 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1523
1524 Note that as a very special case, an C<eval ''> executed within the C<DB>
1525 package doesn't see the usual surrounding lexical scope, but rather the
1526 scope of the first non-DB piece of code that called it. You don't normally
1527 need to worry about this unless you are writing a Perl debugger.
1528
1529 =item exec LIST
1530
1531 =item exec PROGRAM LIST
1532
1533 The C<exec> function executes a system command I<and never returns>--
1534 use C<system> instead of C<exec> if you want it to return.  It fails and
1535 returns false only if the command does not exist I<and> it is executed
1536 directly instead of via your system's command shell (see below).
1537
1538 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1539 warns you if there is a following statement which isn't C<die>, C<warn>,
1540 or C<exit> (if C<-w> is set  -  but you always do that).   If you
1541 I<really> want to follow an C<exec> with some other statement, you
1542 can use one of these styles to avoid the warning:
1543
1544     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1545     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1546
1547 If there is more than one argument in LIST, or if LIST is an array
1548 with more than one value, calls execvp(3) with the arguments in LIST.
1549 If there is only one scalar argument or an array with one element in it,
1550 the argument is checked for shell metacharacters, and if there are any,
1551 the entire argument is passed to the system's command shell for parsing
1552 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1553 If there are no shell metacharacters in the argument, it is split into
1554 words and passed directly to C<execvp>, which is more efficient.
1555 Examples:
1556
1557     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1558     exec "sort $outfile | uniq";
1559
1560 If you don't really want to execute the first argument, but want to lie
1561 to the program you are executing about its own name, you can specify
1562 the program you actually want to run as an "indirect object" (without a
1563 comma) in front of the LIST.  (This always forces interpretation of the
1564 LIST as a multivalued list, even if there is only a single scalar in
1565 the list.)  Example:
1566
1567     $shell = '/bin/csh';
1568     exec $shell '-sh';          # pretend it's a login shell
1569
1570 or, more directly,
1571
1572     exec {'/bin/csh'} '-sh';    # pretend it's a login shell
1573
1574 When the arguments get executed via the system shell, results will
1575 be subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1576 for details.
1577
1578 Using an indirect object with C<exec> or C<system> is also more
1579 secure.  This usage (which also works fine with system()) forces
1580 interpretation of the arguments as a multivalued list, even if the
1581 list had just one argument.  That way you're safe from the shell
1582 expanding wildcards or splitting up words with whitespace in them.
1583
1584     @args = ( "echo surprise" );
1585
1586     exec @args;               # subject to shell escapes
1587                                 # if @args == 1
1588     exec { $args[0] } @args;  # safe even with one-arg list
1589
1590 The first version, the one without the indirect object, ran the I<echo>
1591 program, passing it C<"surprise"> an argument.  The second version
1592 didn't--it tried to run a program literally called I<"echo surprise">,
1593 didn't find it, and set C<$?> to a non-zero value indicating failure.
1594
1595 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1596 output before the exec, but this may not be supported on some platforms
1597 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1598 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1599 open handles in order to avoid lost output.
1600
1601 Note that C<exec> will not call your C<END> blocks, nor will it call
1602 any C<DESTROY> methods in your objects.
1603
1604 =item exists EXPR
1605
1606 Given an expression that specifies a hash element or array element,
1607 returns true if the specified element in the hash or array has ever
1608 been initialized, even if the corresponding value is undefined.  The
1609 element is not autovivified if it doesn't exist.
1610
1611     print "Exists\n"    if exists $hash{$key};
1612     print "Defined\n"   if defined $hash{$key};
1613     print "True\n"      if $hash{$key};
1614
1615     print "Exists\n"    if exists $array[$index];
1616     print "Defined\n"   if defined $array[$index];
1617     print "True\n"      if $array[$index];
1618
1619 A hash or array element can be true only if it's defined, and defined if
1620 it exists, but the reverse doesn't necessarily hold true.
1621
1622 Given an expression that specifies the name of a subroutine,
1623 returns true if the specified subroutine has ever been declared, even
1624 if it is undefined.  Mentioning a subroutine name for exists or defined
1625 does not count as declaring it.  Note that a subroutine which does not
1626 exist may still be callable: its package may have an C<AUTOLOAD>
1627 method that makes it spring into existence the first time that it is
1628 called -- see L<perlsub>.
1629
1630     print "Exists\n"    if exists &subroutine;
1631     print "Defined\n"   if defined &subroutine;
1632
1633 Note that the EXPR can be arbitrarily complicated as long as the final
1634 operation is a hash or array key lookup or subroutine name:
1635
1636     if (exists $ref->{A}->{B}->{$key})  { }
1637     if (exists $hash{A}{B}{$key})       { }
1638
1639     if (exists $ref->{A}->{B}->[$ix])   { }
1640     if (exists $hash{A}{B}[$ix])        { }
1641
1642     if (exists &{$ref->{A}{B}{$key}})   { }
1643
1644 Although the deepest nested array or hash will not spring into existence
1645 just because its existence was tested, any intervening ones will.
1646 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1647 into existence due to the existence test for the $key element above.
1648 This happens anywhere the arrow operator is used, including even:
1649
1650     undef $ref;
1651     if (exists $ref->{"Some key"})      { }
1652     print $ref;             # prints HASH(0x80d3d5c)
1653
1654 This surprising autovivification in what does not at first--or even
1655 second--glance appear to be an lvalue context may be fixed in a future
1656 release.
1657
1658 Use of a subroutine call, rather than a subroutine name, as an argument
1659 to exists() is an error.
1660
1661     exists &sub;        # OK
1662     exists &sub();      # Error
1663
1664 =item exit EXPR
1665
1666 =item exit
1667
1668 Evaluates EXPR and exits immediately with that value.    Example:
1669
1670     $ans = <STDIN>;
1671     exit 0 if $ans =~ /^[Xx]/;
1672
1673 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1674 universally recognized values for EXPR are C<0> for success and C<1>
1675 for error; other values are subject to interpretation depending on the
1676 environment in which the Perl program is running.  For example, exiting
1677 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1678 the mailer to return the item undelivered, but that's not true everywhere.
1679
1680 Don't use C<exit> to abort a subroutine if there's any chance that
1681 someone might want to trap whatever error happened.  Use C<die> instead,
1682 which can be trapped by an C<eval>.
1683
1684 The exit() function does not always exit immediately.  It calls any
1685 defined C<END> routines first, but these C<END> routines may not
1686 themselves abort the exit.  Likewise any object destructors that need to
1687 be called are called before the real exit.  If this is a problem, you
1688 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1689 See L<perlmod> for details.
1690
1691 =item exp EXPR
1692
1693 =item exp
1694
1695 Returns I<e> (the natural logarithm base) to the power of EXPR.
1696 If EXPR is omitted, gives C<exp($_)>.
1697
1698 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1699
1700 Implements the fcntl(2) function.  You'll probably have to say
1701
1702     use Fcntl;
1703
1704 first to get the correct constant definitions.  Argument processing and
1705 value return works just like C<ioctl> below.
1706 For example:
1707
1708     use Fcntl;
1709     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1710         or die "can't fcntl F_GETFL: $!";
1711
1712 You don't have to check for C<defined> on the return from C<fcntl>.
1713 Like C<ioctl>, it maps a C<0> return from the system call into
1714 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1715 in numeric context.  It is also exempt from the normal B<-w> warnings
1716 on improper numeric conversions.
1717
1718 Note that C<fcntl> will produce a fatal error if used on a machine that
1719 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1720 manpage to learn what functions are available on your system.
1721
1722 Here's an example of setting a filehandle named C<REMOTE> to be
1723 non-blocking at the system level.  You'll have to negotiate C<$|>
1724 on your own, though.
1725
1726     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1727
1728     $flags = fcntl(REMOTE, F_GETFL, 0)
1729                 or die "Can't get flags for the socket: $!\n";
1730
1731     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1732                 or die "Can't set flags for the socket: $!\n";
1733
1734 =item fileno FILEHANDLE
1735
1736 Returns the file descriptor for a filehandle, or undefined if the
1737 filehandle is not open.  This is mainly useful for constructing
1738 bitmaps for C<select> and low-level POSIX tty-handling operations.
1739 If FILEHANDLE is an expression, the value is taken as an indirect
1740 filehandle, generally its name.
1741
1742 You can use this to find out whether two handles refer to the
1743 same underlying descriptor:
1744
1745     if (fileno(THIS) == fileno(THAT)) {
1746         print "THIS and THAT are dups\n";
1747     }
1748
1749 (Filehandles connected to memory objects via new features of C<open> may
1750 return undefined even though they are open.)
1751
1752
1753 =item flock FILEHANDLE,OPERATION
1754
1755 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1756 for success, false on failure.  Produces a fatal error if used on a
1757 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1758 C<flock> is Perl's portable file locking interface, although it locks
1759 only entire files, not records.
1760
1761 Two potentially non-obvious but traditional C<flock> semantics are
1762 that it waits indefinitely until the lock is granted, and that its locks
1763 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1764 fewer guarantees.  This means that programs that do not also use C<flock>
1765 may modify files locked with C<flock>.  See L<perlport>, 
1766 your port's specific documentation, or your system-specific local manpages
1767 for details.  It's best to assume traditional behavior if you're writing
1768 portable programs.  (But if you're not, you should as always feel perfectly
1769 free to write for your own system's idiosyncrasies (sometimes called
1770 "features").  Slavish adherence to portability concerns shouldn't get
1771 in the way of your getting your job done.)
1772
1773 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1774 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1775 you can use the symbolic names if you import them from the Fcntl module,
1776 either individually, or as a group using the ':flock' tag.  LOCK_SH
1777 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1778 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1779 LOCK_SH or LOCK_EX then C<flock> will return immediately rather than blocking
1780 waiting for the lock (check the return status to see if you got it).
1781
1782 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1783 before locking or unlocking it.
1784
1785 Note that the emulation built with lockf(3) doesn't provide shared
1786 locks, and it requires that FILEHANDLE be open with write intent.  These
1787 are the semantics that lockf(3) implements.  Most if not all systems
1788 implement lockf(3) in terms of fcntl(2) locking, though, so the
1789 differing semantics shouldn't bite too many people.
1790
1791 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1792 be open with read intent to use LOCK_SH and requires that it be open
1793 with write intent to use LOCK_EX.
1794
1795 Note also that some versions of C<flock> cannot lock things over the
1796 network; you would need to use the more system-specific C<fcntl> for
1797 that.  If you like you can force Perl to ignore your system's flock(2)
1798 function, and so provide its own fcntl(2)-based emulation, by passing
1799 the switch C<-Ud_flock> to the F<Configure> program when you configure
1800 perl.
1801
1802 Here's a mailbox appender for BSD systems.
1803
1804     use Fcntl ':flock'; # import LOCK_* constants
1805
1806     sub lock {
1807         flock(MBOX,LOCK_EX);
1808         # and, in case someone appended
1809         # while we were waiting...
1810         seek(MBOX, 0, 2);
1811     }
1812
1813     sub unlock {
1814         flock(MBOX,LOCK_UN);
1815     }
1816
1817     open(MBOX, ">>/usr/spool/mail/$ENV{'USER'}")
1818             or die "Can't open mailbox: $!";
1819
1820     lock();
1821     print MBOX $msg,"\n\n";
1822     unlock();
1823
1824 On systems that support a real flock(), locks are inherited across fork()
1825 calls, whereas those that must resort to the more capricious fcntl()
1826 function lose the locks, making it harder to write servers.
1827
1828 See also L<DB_File> for other flock() examples.
1829
1830 =item fork
1831
1832 Does a fork(2) system call to create a new process running the
1833 same program at the same point.  It returns the child pid to the
1834 parent process, C<0> to the child process, or C<undef> if the fork is
1835 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
1836 are shared, while everything else is copied.  On most systems supporting
1837 fork(), great care has gone into making it extremely efficient (for
1838 example, using copy-on-write technology on data pages), making it the
1839 dominant paradigm for multitasking over the last few decades.
1840
1841 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1842 output before forking the child process, but this may not be supported
1843 on some platforms (see L<perlport>).  To be safe, you may need to set
1844 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1845 C<IO::Handle> on any open handles in order to avoid duplicate output.
1846
1847 If you C<fork> without ever waiting on your children, you will
1848 accumulate zombies.  On some systems, you can avoid this by setting
1849 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
1850 forking and reaping moribund children.
1851
1852 Note that if your forked child inherits system file descriptors like
1853 STDIN and STDOUT that are actually connected by a pipe or socket, even
1854 if you exit, then the remote server (such as, say, a CGI script or a
1855 backgrounded job launched from a remote shell) won't think you're done.
1856 You should reopen those to F</dev/null> if it's any issue.
1857
1858 =item format
1859
1860 Declare a picture format for use by the C<write> function.  For
1861 example:
1862
1863     format Something =
1864         Test: @<<<<<<<< @||||| @>>>>>
1865               $str,     $%,    '$' . int($num)
1866     .
1867
1868     $str = "widget";
1869     $num = $cost/$quantity;
1870     $~ = 'Something';
1871     write;
1872
1873 See L<perlform> for many details and examples.
1874
1875 =item formline PICTURE,LIST
1876
1877 This is an internal function used by C<format>s, though you may call it,
1878 too.  It formats (see L<perlform>) a list of values according to the
1879 contents of PICTURE, placing the output into the format output
1880 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
1881 Eventually, when a C<write> is done, the contents of
1882 C<$^A> are written to some filehandle.  You could also read C<$^A>
1883 and then set C<$^A> back to C<"">.  Note that a format typically
1884 does one C<formline> per line of form, but the C<formline> function itself
1885 doesn't care how many newlines are embedded in the PICTURE.  This means
1886 that the C<~> and C<~~> tokens will treat the entire PICTURE as a single line.
1887 You may therefore need to use multiple formlines to implement a single
1888 record format, just like the format compiler.
1889
1890 Be careful if you put double quotes around the picture, because an C<@>
1891 character may be taken to mean the beginning of an array name.
1892 C<formline> always returns true.  See L<perlform> for other examples.
1893
1894 =item getc FILEHANDLE
1895
1896 =item getc
1897
1898 Returns the next character from the input file attached to FILEHANDLE,
1899 or the undefined value at end of file, or if there was an error (in
1900 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
1901 STDIN.  This is not particularly efficient.  However, it cannot be
1902 used by itself to fetch single characters without waiting for the user
1903 to hit enter.  For that, try something more like:
1904
1905     if ($BSD_STYLE) {
1906         system "stty cbreak </dev/tty >/dev/tty 2>&1";
1907     }
1908     else {
1909         system "stty", '-icanon', 'eol', "\001";
1910     }
1911
1912     $key = getc(STDIN);
1913
1914     if ($BSD_STYLE) {
1915         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
1916     }
1917     else {
1918         system "stty", 'icanon', 'eol', '^@'; # ASCII null
1919     }
1920     print "\n";
1921
1922 Determination of whether $BSD_STYLE should be set
1923 is left as an exercise to the reader.
1924
1925 The C<POSIX::getattr> function can do this more portably on
1926 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
1927 module from your nearest CPAN site; details on CPAN can be found on
1928 L<perlmodlib/CPAN>.
1929
1930 =item getlogin
1931
1932 This implements the C library function of the same name, which on most
1933 systems returns the current login from F</etc/utmp>, if any.  If null,
1934 use C<getpwuid>.
1935
1936     $login = getlogin || getpwuid($<) || "Kilroy";
1937
1938 Do not consider C<getlogin> for authentication: it is not as
1939 secure as C<getpwuid>.
1940
1941 =item getpeername SOCKET
1942
1943 Returns the packed sockaddr address of other end of the SOCKET connection.
1944
1945     use Socket;
1946     $hersockaddr    = getpeername(SOCK);
1947     ($port, $iaddr) = sockaddr_in($hersockaddr);
1948     $herhostname    = gethostbyaddr($iaddr, AF_INET);
1949     $herstraddr     = inet_ntoa($iaddr);
1950
1951 =item getpgrp PID
1952
1953 Returns the current process group for the specified PID.  Use
1954 a PID of C<0> to get the current process group for the
1955 current process.  Will raise an exception if used on a machine that
1956 doesn't implement getpgrp(2).  If PID is omitted, returns process
1957 group of current process.  Note that the POSIX version of C<getpgrp>
1958 does not accept a PID argument, so only C<PID==0> is truly portable.
1959
1960 =item getppid
1961
1962 Returns the process id of the parent process.
1963
1964 Note for Linux users: on Linux, the C functions C<getpid()> and
1965 C<getppid()> return different values from different threads. In order to
1966 be portable, this behavior is not reflected by the perl-level function
1967 C<getppid()>, that returns a consistent value across threads. If you want
1968 to call the underlying C<getppid()>, you may use the CPAN module
1969 C<Linux::Pid>.
1970
1971 =item getpriority WHICH,WHO
1972
1973 Returns the current priority for a process, a process group, or a user.
1974 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
1975 machine that doesn't implement getpriority(2).
1976
1977 =item getpwnam NAME
1978
1979 =item getgrnam NAME
1980
1981 =item gethostbyname NAME
1982
1983 =item getnetbyname NAME
1984
1985 =item getprotobyname NAME
1986
1987 =item getpwuid UID
1988
1989 =item getgrgid GID
1990
1991 =item getservbyname NAME,PROTO
1992
1993 =item gethostbyaddr ADDR,ADDRTYPE
1994
1995 =item getnetbyaddr ADDR,ADDRTYPE
1996
1997 =item getprotobynumber NUMBER
1998
1999 =item getservbyport PORT,PROTO
2000
2001 =item getpwent
2002
2003 =item getgrent
2004
2005 =item gethostent
2006
2007 =item getnetent
2008
2009 =item getprotoent
2010
2011 =item getservent
2012
2013 =item setpwent
2014
2015 =item setgrent
2016
2017 =item sethostent STAYOPEN
2018
2019 =item setnetent STAYOPEN
2020
2021 =item setprotoent STAYOPEN
2022
2023 =item setservent STAYOPEN
2024
2025 =item endpwent
2026
2027 =item endgrent
2028
2029 =item endhostent
2030
2031 =item endnetent
2032
2033 =item endprotoent
2034
2035 =item endservent
2036
2037 These routines perform the same functions as their counterparts in the
2038 system library.  In list context, the return values from the
2039 various get routines are as follows:
2040
2041     ($name,$passwd,$uid,$gid,
2042        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2043     ($name,$passwd,$gid,$members) = getgr*
2044     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2045     ($name,$aliases,$addrtype,$net) = getnet*
2046     ($name,$aliases,$proto) = getproto*
2047     ($name,$aliases,$port,$proto) = getserv*
2048
2049 (If the entry doesn't exist you get a null list.)
2050
2051 The exact meaning of the $gcos field varies but it usually contains
2052 the real name of the user (as opposed to the login name) and other
2053 information pertaining to the user.  Beware, however, that in many
2054 system users are able to change this information and therefore it
2055 cannot be trusted and therefore the $gcos is tainted (see
2056 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2057 login shell, are also tainted, because of the same reason.
2058
2059 In scalar context, you get the name, unless the function was a
2060 lookup by name, in which case you get the other thing, whatever it is.
2061 (If the entry doesn't exist you get the undefined value.)  For example:
2062
2063     $uid   = getpwnam($name);
2064     $name  = getpwuid($num);
2065     $name  = getpwent();
2066     $gid   = getgrnam($name);
2067     $name  = getgrgid($num);
2068     $name  = getgrent();
2069     #etc.
2070
2071 In I<getpw*()> the fields $quota, $comment, and $expire are special
2072 cases in the sense that in many systems they are unsupported.  If the
2073 $quota is unsupported, it is an empty scalar.  If it is supported, it
2074 usually encodes the disk quota.  If the $comment field is unsupported,
2075 it is an empty scalar.  If it is supported it usually encodes some
2076 administrative comment about the user.  In some systems the $quota
2077 field may be $change or $age, fields that have to do with password
2078 aging.  In some systems the $comment field may be $class.  The $expire
2079 field, if present, encodes the expiration period of the account or the
2080 password.  For the availability and the exact meaning of these fields
2081 in your system, please consult your getpwnam(3) documentation and your
2082 F<pwd.h> file.  You can also find out from within Perl what your
2083 $quota and $comment fields mean and whether you have the $expire field
2084 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2085 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2086 files are only supported if your vendor has implemented them in the
2087 intuitive fashion that calling the regular C library routines gets the
2088 shadow versions if you're running under privilege or if there exists
2089 the shadow(3) functions as found in System V (this includes Solaris
2090 and Linux.)  Those systems that implement a proprietary shadow password
2091 facility are unlikely to be supported.
2092
2093 The $members value returned by I<getgr*()> is a space separated list of
2094 the login names of the members of the group.
2095
2096 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2097 C, it will be returned to you via C<$?> if the function call fails.  The
2098 C<@addrs> value returned by a successful call is a list of the raw
2099 addresses returned by the corresponding system library call.  In the
2100 Internet domain, each address is four bytes long and you can unpack it
2101 by saying something like:
2102
2103     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2104
2105 The Socket library makes this slightly easier:
2106
2107     use Socket;
2108     $iaddr = inet_aton("127.1"); # or whatever address
2109     $name  = gethostbyaddr($iaddr, AF_INET);
2110
2111     # or going the other way
2112     $straddr = inet_ntoa($iaddr);
2113
2114 If you get tired of remembering which element of the return list
2115 contains which return value, by-name interfaces are provided
2116 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2117 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2118 and C<User::grent>.  These override the normal built-ins, supplying
2119 versions that return objects with the appropriate names
2120 for each field.  For example:
2121
2122    use File::stat;
2123    use User::pwent;
2124    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2125
2126 Even though it looks like they're the same method calls (uid),
2127 they aren't, because a C<File::stat> object is different from
2128 a C<User::pwent> object.
2129
2130 =item getsockname SOCKET
2131
2132 Returns the packed sockaddr address of this end of the SOCKET connection,
2133 in case you don't know the address because you have several different
2134 IPs that the connection might have come in on.
2135
2136     use Socket;
2137     $mysockaddr = getsockname(SOCK);
2138     ($port, $myaddr) = sockaddr_in($mysockaddr);
2139     printf "Connect to %s [%s]\n",
2140        scalar gethostbyaddr($myaddr, AF_INET),
2141        inet_ntoa($myaddr);
2142
2143 =item getsockopt SOCKET,LEVEL,OPTNAME
2144
2145 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2146 Options may exist at multiple protocol levels depending on the socket
2147 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2148 C<Socket> module) will exist. To query options at another level the
2149 protocol number of the appropriate protocol controlling the option
2150 should be supplied. For example, to indicate that an option is to be
2151 interpreted by the TCP protocol, LEVEL should be set to the protocol
2152 number of TCP, which you can get using getprotobyname.
2153
2154 The call returns a packed string representing the requested socket option,
2155 or C<undef> if there is an error (the error reason will be in $!). What
2156 exactly is in the packed string depends in the LEVEL and OPTNAME, consult
2157 your system documentation for details. A very common case however is that
2158 the option is an integer, in which case the result will be a packed
2159 integer which you can decode using unpack with the C<i> (or C<I>) format.
2160
2161 An example testing if Nagle's algorithm is turned on on a socket:
2162
2163     use Socket qw(:all);
2164
2165     defined(my $tcp = getprotobyname("tcp"))
2166         or die "Could not determine the protocol number for tcp";
2167     # my $tcp = IPPROTO_TCP; # Alternative
2168     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2169         or die "Could not query TCP_NODELAY socket option: $!";
2170     my $nodelay = unpack("I", $packed);
2171     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2172
2173
2174 =item glob EXPR
2175
2176 =item glob
2177
2178 In list context, returns a (possibly empty) list of filename expansions on
2179 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2180 scalar context, glob iterates through such filename expansions, returning
2181 undef when the list is exhausted. This is the internal function
2182 implementing the C<< <*.c> >> operator, but you can use it directly. If
2183 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2184 more detail in L<perlop/"I/O Operators">.
2185
2186 Beginning with v5.6.0, this operator is implemented using the standard
2187 C<File::Glob> extension.  See L<File::Glob> for details.
2188
2189 =item gmtime EXPR
2190
2191 =item gmtime
2192
2193 Converts a time as returned by the time function to an 8-element list
2194 with the time localized for the standard Greenwich time zone.
2195 Typically used as follows:
2196
2197     #  0    1    2     3     4    5     6     7
2198     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday) =
2199                                             gmtime(time);
2200
2201 All list elements are numeric, and come straight out of the C `struct
2202 tm'.  $sec, $min, and $hour are the seconds, minutes, and hours of the
2203 specified time.  $mday is the day of the month, and $mon is the month
2204 itself, in the range C<0..11> with 0 indicating January and 11
2205 indicating December.  $year is the number of years since 1900.  That
2206 is, $year is C<123> in year 2023.  $wday is the day of the week, with
2207 0 indicating Sunday and 3 indicating Wednesday.  $yday is the day of
2208 the year, in the range C<0..364> (or C<0..365> in leap years.)
2209
2210 Note that the $year element is I<not> simply the last two digits of
2211 the year.  If you assume it is then you create non-Y2K-compliant
2212 programs--and you wouldn't want to do that, would you?
2213
2214 The proper way to get a complete 4-digit year is simply:
2215
2216         $year += 1900;
2217
2218 And to get the last two digits of the year (e.g., '01' in 2001) do:
2219
2220         $year = sprintf("%02d", $year % 100);
2221
2222 If EXPR is omitted, C<gmtime()> uses the current time (C<gmtime(time)>).
2223
2224 In scalar context, C<gmtime()> returns the ctime(3) value:
2225
2226     $now_string = gmtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2227
2228 If you need local time instead of GMT use the L</localtime> builtin. 
2229 See also the C<timegm> function provided by the C<Time::Local> module,
2230 and the strftime(3) and mktime(3) functions available via the L<POSIX> module.
2231
2232 This scalar value is B<not> locale dependent (see L<perllocale>), but is
2233 instead a Perl builtin.  To get somewhat similar but locale dependent date
2234 strings, see the example in L</localtime>.
2235
2236 See L<perlport/gmtime> for portability concerns.
2237
2238 =item goto LABEL
2239
2240 =item goto EXPR
2241
2242 =item goto &NAME
2243
2244 The C<goto-LABEL> form finds the statement labeled with LABEL and resumes
2245 execution there.  It may not be used to go into any construct that
2246 requires initialization, such as a subroutine or a C<foreach> loop.  It
2247 also can't be used to go into a construct that is optimized away,
2248 or to get out of a block or subroutine given to C<sort>.
2249 It can be used to go almost anywhere else within the dynamic scope,
2250 including out of subroutines, but it's usually better to use some other
2251 construct such as C<last> or C<die>.  The author of Perl has never felt the
2252 need to use this form of C<goto> (in Perl, that is--C is another matter).
2253 (The difference being that C does not offer named loops combined with
2254 loop control.  Perl does, and this replaces most structured uses of C<goto>
2255 in other languages.)
2256
2257 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2258 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2259 necessarily recommended if you're optimizing for maintainability:
2260
2261     goto ("FOO", "BAR", "GLARCH")[$i];
2262
2263 The C<goto-&NAME> form is quite different from the other forms of
2264 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2265 doesn't have the stigma associated with other gotos.  Instead, it
2266 exits the current subroutine (losing any changes set by local()) and
2267 immediately calls in its place the named subroutine using the current
2268 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2269 load another subroutine and then pretend that the other subroutine had
2270 been called in the first place (except that any modifications to C<@_>
2271 in the current subroutine are propagated to the other subroutine.)
2272 After the C<goto>, not even C<caller> will be able to tell that this
2273 routine was called first.
2274
2275 NAME needn't be the name of a subroutine; it can be a scalar variable
2276 containing a code reference, or a block that evaluates to a code
2277 reference.
2278
2279 =item grep BLOCK LIST
2280
2281 =item grep EXPR,LIST
2282
2283 This is similar in spirit to, but not the same as, grep(1) and its
2284 relatives.  In particular, it is not limited to using regular expressions.
2285
2286 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2287 C<$_> to each element) and returns the list value consisting of those
2288 elements for which the expression evaluated to true.  In scalar
2289 context, returns the number of times the expression was true.
2290
2291     @foo = grep(!/^#/, @bar);    # weed out comments
2292
2293 or equivalently,
2294
2295     @foo = grep {!/^#/} @bar;    # weed out comments
2296
2297 Note that C<$_> is an alias to the list value, so it can be used to
2298 modify the elements of the LIST.  While this is useful and supported,
2299 it can cause bizarre results if the elements of LIST are not variables.
2300 Similarly, grep returns aliases into the original list, much as a for
2301 loop's index variable aliases the list elements.  That is, modifying an
2302 element of a list returned by grep (for example, in a C<foreach>, C<map>
2303 or another C<grep>) actually modifies the element in the original list.
2304 This is usually something to be avoided when writing clear code.
2305
2306 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2307 been declared with C<my $_>) then, in addition to being locally aliased to
2308 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2309 can't be seen from the outside, avoiding any potential side-effects.
2310
2311 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2312
2313 =item hex EXPR
2314
2315 =item hex
2316
2317 Interprets EXPR as a hex string and returns the corresponding value.
2318 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2319 L</oct>.)  If EXPR is omitted, uses C<$_>.
2320
2321     print hex '0xAf'; # prints '175'
2322     print hex 'aF';   # same
2323
2324 Hex strings may only represent integers.  Strings that would cause
2325 integer overflow trigger a warning.  Leading whitespace is not stripped,
2326 unlike oct(). To present something as hex, look into L</printf>,
2327 L</sprintf>, or L</unpack>.
2328
2329 =item import LIST
2330
2331 There is no builtin C<import> function.  It is just an ordinary
2332 method (subroutine) defined (or inherited) by modules that wish to export
2333 names to another module.  The C<use> function calls the C<import> method
2334 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2335
2336 =item index STR,SUBSTR,POSITION
2337
2338 =item index STR,SUBSTR
2339
2340 The index function searches for one string within another, but without
2341 the wildcard-like behavior of a full regular-expression pattern match.
2342 It returns the position of the first occurrence of SUBSTR in STR at
2343 or after POSITION.  If POSITION is omitted, starts searching from the
2344 beginning of the string.  POSITION before the beginning of the string
2345 or after its end is treated as if it were the beginning or the end,
2346 respectively.  POSITION and the return value are based at C<0> (or whatever
2347 you've set the C<$[> variable to--but don't do that).  If the substring
2348 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2349
2350 =item int EXPR
2351
2352 =item int
2353
2354 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2355 You should not use this function for rounding: one because it truncates
2356 towards C<0>, and two because machine representations of floating point
2357 numbers can sometimes produce counterintuitive results.  For example,
2358 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2359 because it's really more like -268.99999999999994315658 instead.  Usually,
2360 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2361 functions will serve you better than will int().
2362
2363 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2364
2365 Implements the ioctl(2) function.  You'll probably first have to say
2366
2367     require "sys/ioctl.ph";     # probably in $Config{archlib}/ioctl.ph
2368
2369 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2370 exist or doesn't have the correct definitions you'll have to roll your
2371 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2372 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2373 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2374 written depending on the FUNCTION--a pointer to the string value of SCALAR
2375 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2376 has no string value but does have a numeric value, that value will be
2377 passed rather than a pointer to the string value.  To guarantee this to be
2378 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2379 functions may be needed to manipulate the values of structures used by
2380 C<ioctl>.
2381
2382 The return value of C<ioctl> (and C<fcntl>) is as follows:
2383
2384         if OS returns:          then Perl returns:
2385             -1                    undefined value
2386              0                  string "0 but true"
2387         anything else               that number
2388
2389 Thus Perl returns true on success and false on failure, yet you can
2390 still easily determine the actual value returned by the operating
2391 system:
2392
2393     $retval = ioctl(...) || -1;
2394     printf "System returned %d\n", $retval;
2395
2396 The special string C<"0 but true"> is exempt from B<-w> complaints
2397 about improper numeric conversions.
2398
2399 =item join EXPR,LIST
2400
2401 Joins the separate strings of LIST into a single string with fields
2402 separated by the value of EXPR, and returns that new string.  Example:
2403
2404     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2405
2406 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2407 first argument.  Compare L</split>.
2408
2409 =item keys HASH
2410
2411 Returns a list consisting of all the keys of the named hash.
2412 (In scalar context, returns the number of keys.)
2413
2414 The keys are returned in an apparently random order.  The actual
2415 random order is subject to change in future versions of perl, but it
2416 is guaranteed to be the same order as either the C<values> or C<each>
2417 function produces (given that the hash has not been modified).  Since
2418 Perl 5.8.1 the ordering is different even between different runs of
2419 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2420 Attacks">).
2421
2422 As a side effect, calling keys() resets the HASH's internal iterator
2423 (see L</each>).  In particular, calling keys() in void context resets
2424 the iterator with no other overhead.
2425
2426 Here is yet another way to print your environment:
2427
2428     @keys = keys %ENV;
2429     @values = values %ENV;
2430     while (@keys) {
2431         print pop(@keys), '=', pop(@values), "\n";
2432     }
2433
2434 or how about sorted by key:
2435
2436     foreach $key (sort(keys %ENV)) {
2437         print $key, '=', $ENV{$key}, "\n";
2438     }
2439
2440 The returned values are copies of the original keys in the hash, so
2441 modifying them will not affect the original hash.  Compare L</values>.
2442
2443 To sort a hash by value, you'll need to use a C<sort> function.
2444 Here's a descending numeric sort of a hash by its values:
2445
2446     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2447         printf "%4d %s\n", $hash{$key}, $key;
2448     }
2449
2450 As an lvalue C<keys> allows you to increase the number of hash buckets
2451 allocated for the given hash.  This can gain you a measure of efficiency if
2452 you know the hash is going to get big.  (This is similar to pre-extending
2453 an array by assigning a larger number to $#array.)  If you say
2454
2455     keys %hash = 200;
2456
2457 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2458 in fact, since it rounds up to the next power of two.  These
2459 buckets will be retained even if you do C<%hash = ()>, use C<undef
2460 %hash> if you want to free the storage while C<%hash> is still in scope.
2461 You can't shrink the number of buckets allocated for the hash using
2462 C<keys> in this way (but you needn't worry about doing this by accident,
2463 as trying has no effect).
2464
2465 See also C<each>, C<values> and C<sort>.
2466
2467 =item kill SIGNAL, LIST
2468
2469 Sends a signal to a list of processes.  Returns the number of
2470 processes successfully signaled (which is not necessarily the
2471 same as the number actually killed).
2472
2473     $cnt = kill 1, $child1, $child2;
2474     kill 9, @goners;
2475
2476 If SIGNAL is zero, no signal is sent to the process.  This is a
2477 useful way to check that a child process is alive and hasn't changed
2478 its UID.  See L<perlport> for notes on the portability of this
2479 construct.
2480
2481 Unlike in the shell, if SIGNAL is negative, it kills
2482 process groups instead of processes.  (On System V, a negative I<PROCESS>
2483 number will also kill process groups, but that's not portable.)  That
2484 means you usually want to use positive not negative signals.  You may also
2485 use a signal name in quotes.
2486
2487 See L<perlipc/"Signals"> for more details.
2488
2489 =item last LABEL
2490
2491 =item last
2492
2493 The C<last> command is like the C<break> statement in C (as used in
2494 loops); it immediately exits the loop in question.  If the LABEL is
2495 omitted, the command refers to the innermost enclosing loop.  The
2496 C<continue> block, if any, is not executed:
2497
2498     LINE: while (<STDIN>) {
2499         last LINE if /^$/;      # exit when done with header
2500         #...
2501     }
2502
2503 C<last> cannot be used to exit a block which returns a value such as
2504 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2505 a grep() or map() operation.
2506
2507 Note that a block by itself is semantically identical to a loop
2508 that executes once.  Thus C<last> can be used to effect an early
2509 exit out of such a block.
2510
2511 See also L</continue> for an illustration of how C<last>, C<next>, and
2512 C<redo> work.
2513
2514 =item lc EXPR
2515
2516 =item lc
2517
2518 Returns a lowercased version of EXPR.  This is the internal function
2519 implementing the C<\L> escape in double-quoted strings.  Respects
2520 current LC_CTYPE locale if C<use locale> in force.  See L<perllocale>
2521 and L<perlunicode> for more details about locale and Unicode support.
2522
2523 If EXPR is omitted, uses C<$_>.
2524
2525 =item lcfirst EXPR
2526
2527 =item lcfirst
2528
2529 Returns the value of EXPR with the first character lowercased.  This
2530 is the internal function implementing the C<\l> escape in
2531 double-quoted strings.  Respects current LC_CTYPE locale if C<use
2532 locale> in force.  See L<perllocale> and L<perlunicode> for more
2533 details about locale and Unicode support.
2534
2535 If EXPR is omitted, uses C<$_>.
2536
2537 =item length EXPR
2538
2539 =item length
2540
2541 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2542 omitted, returns length of C<$_>.  Note that this cannot be used on
2543 an entire array or hash to find out how many elements these have.
2544 For that, use C<scalar @array> and C<scalar keys %hash> respectively.
2545
2546 Note the I<characters>: if the EXPR is in Unicode, you will get the
2547 number of characters, not the number of bytes.  To get the length
2548 in bytes, use C<do { use bytes; length(EXPR) }>, see L<bytes>.
2549
2550 =item link OLDFILE,NEWFILE
2551
2552 Creates a new filename linked to the old filename.  Returns true for
2553 success, false otherwise.
2554
2555 =item listen SOCKET,QUEUESIZE
2556
2557 Does the same thing that the listen system call does.  Returns true if
2558 it succeeded, false otherwise.  See the example in
2559 L<perlipc/"Sockets: Client/Server Communication">.
2560
2561 =item local EXPR
2562
2563 You really probably want to be using C<my> instead, because C<local> isn't
2564 what most people think of as "local".  See
2565 L<perlsub/"Private Variables via my()"> for details.
2566
2567 A local modifies the listed variables to be local to the enclosing
2568 block, file, or eval.  If more than one value is listed, the list must
2569 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2570 for details, including issues with tied arrays and hashes.
2571
2572 =item localtime EXPR
2573
2574 =item localtime
2575
2576 Converts a time as returned by the time function to a 9-element list
2577 with the time analyzed for the local time zone.  Typically used as
2578 follows:
2579
2580     #  0    1    2     3     4    5     6     7     8
2581     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2582                                                 localtime(time);
2583
2584 All list elements are numeric, and come straight out of the C `struct
2585 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2586 of the specified time.
2587
2588 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2589 the range C<0..11> with 0 indicating January and 11 indicating December.
2590 This makes it easy to get a month name from a list:
2591
2592     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2593     print "$abbr[$mon] $mday";
2594     # $mon=9, $mday=18 gives "Oct 18"
2595
2596 C<$year> is the number of years since 1900, not just the last two digits
2597 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2598 to get a complete 4-digit year is simply:
2599
2600     $year += 1900;
2601
2602 To get the last two digits of the year (e.g., '01' in 2001) do:
2603
2604     $year = sprintf("%02d", $year % 100);
2605
2606 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2607 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2608 (or C<0..365> in leap years.)
2609
2610 C<$isdst> is true if the specified time occurs during Daylight Saving
2611 Time, false otherwise.
2612
2613 If EXPR is omitted, C<localtime()> uses the current time (C<localtime(time)>).
2614
2615 In scalar context, C<localtime()> returns the ctime(3) value:
2616
2617     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2618
2619 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2620 instead of local time use the L</gmtime> builtin. See also the
2621 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2622 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2623 and mktime(3) functions.
2624
2625 To get somewhat similar but locale dependent date strings, set up your
2626 locale environment variables appropriately (please see L<perllocale>) and
2627 try for example:
2628
2629     use POSIX qw(strftime);
2630     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2631     # or for GMT formatted appropriately for your locale:
2632     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2633
2634 Note that the C<%a> and C<%b>, the short forms of the day of the week
2635 and the month of the year, may not necessarily be three characters wide.
2636
2637 See L<perlport/localtime> for portability concerns.
2638
2639 =item lock THING
2640
2641 This function places an advisory lock on a shared variable, or referenced
2642 object contained in I<THING> until the lock goes out of scope.
2643
2644 lock() is a "weak keyword" : this means that if you've defined a function
2645 by this name (before any calls to it), that function will be called
2646 instead. (However, if you've said C<use threads>, lock() is always a
2647 keyword.) See L<threads>.
2648
2649 =item log EXPR
2650
2651 =item log
2652
2653 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2654 returns log of C<$_>.  To get the log of another base, use basic algebra:
2655 The base-N log of a number is equal to the natural log of that number
2656 divided by the natural log of N.  For example:
2657
2658     sub log10 {
2659         my $n = shift;
2660         return log($n)/log(10);
2661     }
2662
2663 See also L</exp> for the inverse operation.
2664
2665 =item lstat EXPR
2666
2667 =item lstat
2668
2669 Does the same thing as the C<stat> function (including setting the
2670 special C<_> filehandle) but stats a symbolic link instead of the file
2671 the symbolic link points to.  If symbolic links are unimplemented on
2672 your system, a normal C<stat> is done.  For much more detailed
2673 information, please see the documentation for C<stat>.
2674
2675 If EXPR is omitted, stats C<$_>.
2676
2677 =item m//
2678
2679 The match operator.  See L<perlop>.
2680
2681 =item map BLOCK LIST
2682
2683 =item map EXPR,LIST
2684
2685 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2686 C<$_> to each element) and returns the list value composed of the
2687 results of each such evaluation.  In scalar context, returns the
2688 total number of elements so generated.  Evaluates BLOCK or EXPR in
2689 list context, so each element of LIST may produce zero, one, or
2690 more elements in the returned value.
2691
2692     @chars = map(chr, @nums);
2693
2694 translates a list of numbers to the corresponding characters.  And
2695
2696     %hash = map { getkey($_) => $_ } @array;
2697
2698 is just a funny way to write
2699
2700     %hash = ();
2701     foreach $_ (@array) {
2702         $hash{getkey($_)} = $_;
2703     }
2704
2705 Note that C<$_> is an alias to the list value, so it can be used to
2706 modify the elements of the LIST.  While this is useful and supported,
2707 it can cause bizarre results if the elements of LIST are not variables.
2708 Using a regular C<foreach> loop for this purpose would be clearer in
2709 most cases.  See also L</grep> for an array composed of those items of
2710 the original list for which the BLOCK or EXPR evaluates to true.
2711
2712 If C<$_> is lexical in the scope where the C<map> appears (because it has
2713 been declared with C<my $_>) then, in addition to being locally aliased to
2714 the list elements, C<$_> keeps being lexical inside the block; i.e. it
2715 can't be seen from the outside, avoiding any potential side-effects.
2716
2717 C<{> starts both hash references and blocks, so C<map { ...> could be either
2718 the start of map BLOCK LIST or map EXPR, LIST. Because perl doesn't look
2719 ahead for the closing C<}> it has to take a guess at which its dealing with
2720 based what it finds just after the C<{>. Usually it gets it right, but if it
2721 doesn't it won't realize something is wrong until it gets to the C<}> and
2722 encounters the missing (or unexpected) comma. The syntax error will be
2723 reported close to the C<}> but you'll need to change something near the C<{>
2724 such as using a unary C<+> to give perl some help:
2725
2726     %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
2727     %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
2728     %hash = map { ("\L$_", 1) } @array  # this also works
2729     %hash = map {  lc($_), 1  } @array  # as does this.
2730     %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
2731
2732     %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)
2733
2734 or to force an anon hash constructor use C<+{>
2735
2736    @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end
2737
2738 and you get list of anonymous hashes each with only 1 entry.
2739
2740 =item mkdir FILENAME,MASK
2741
2742 =item mkdir FILENAME
2743
2744 =item mkdir
2745
2746 Creates the directory specified by FILENAME, with permissions
2747 specified by MASK (as modified by C<umask>).  If it succeeds it
2748 returns true, otherwise it returns false and sets C<$!> (errno).
2749 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
2750 to C<$_>.
2751
2752 In general, it is better to create directories with permissive MASK,
2753 and let the user modify that with their C<umask>, than it is to supply
2754 a restrictive MASK and give the user no way to be more permissive.
2755 The exceptions to this rule are when the file or directory should be
2756 kept private (mail files, for instance).  The perlfunc(1) entry on
2757 C<umask> discusses the choice of MASK in more detail.
2758
2759 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
2760 number of trailing slashes.  Some operating and filesystems do not get
2761 this right, so Perl automatically removes all trailing slashes to keep
2762 everyone happy.
2763
2764 =item msgctl ID,CMD,ARG
2765
2766 Calls the System V IPC function msgctl(2).  You'll probably have to say
2767
2768     use IPC::SysV;
2769
2770 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
2771 then ARG must be a variable that will hold the returned C<msqid_ds>
2772 structure.  Returns like C<ioctl>: the undefined value for error,
2773 C<"0 but true"> for zero, or the actual return value otherwise.  See also
2774 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
2775
2776 =item msgget KEY,FLAGS
2777
2778 Calls the System V IPC function msgget(2).  Returns the message queue
2779 id, or the undefined value if there is an error.  See also
2780 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
2781
2782 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
2783
2784 Calls the System V IPC function msgrcv to receive a message from
2785 message queue ID into variable VAR with a maximum message size of
2786 SIZE.  Note that when a message is received, the message type as a
2787 native long integer will be the first thing in VAR, followed by the
2788 actual message.  This packing may be opened with C<unpack("l! a*")>.
2789 Taints the variable.  Returns true if successful, or false if there is
2790 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
2791 C<IPC::SysV::Msg> documentation.
2792
2793 =item msgsnd ID,MSG,FLAGS
2794
2795 Calls the System V IPC function msgsnd to send the message MSG to the
2796 message queue ID.  MSG must begin with the native long integer message
2797 type, and be followed by the length of the actual message, and finally
2798 the message itself.  This kind of packing can be achieved with
2799 C<pack("l! a*", $type, $message)>.  Returns true if successful,
2800 or false if there is an error.  See also C<IPC::SysV>
2801 and C<IPC::SysV::Msg> documentation.
2802
2803 =item my EXPR
2804
2805 =item my TYPE EXPR
2806
2807 =item my EXPR : ATTRS
2808
2809 =item my TYPE EXPR : ATTRS
2810
2811 A C<my> declares the listed variables to be local (lexically) to the
2812 enclosing block, file, or C<eval>.  If more than one value is listed,
2813 the list must be placed in parentheses.
2814
2815 The exact semantics and interface of TYPE and ATTRS are still
2816 evolving.  TYPE is currently bound to the use of C<fields> pragma,
2817 and attributes are handled using the C<attributes> pragma, or starting
2818 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
2819 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
2820 L<attributes>, and L<Attribute::Handlers>.
2821
2822 =item next LABEL
2823
2824 =item next
2825
2826 The C<next> command is like the C<continue> statement in C; it starts
2827 the next iteration of the loop:
2828
2829     LINE: while (<STDIN>) {
2830         next LINE if /^#/;      # discard comments
2831         #...
2832     }
2833
2834 Note that if there were a C<continue> block on the above, it would get
2835 executed even on discarded lines.  If the LABEL is omitted, the command
2836 refers to the innermost enclosing loop.
2837
2838 C<next> cannot be used to exit a block which returns a value such as
2839 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2840 a grep() or map() operation.
2841
2842 Note that a block by itself is semantically identical to a loop
2843 that executes once.  Thus C<next> will exit such a block early.
2844
2845 See also L</continue> for an illustration of how C<last>, C<next>, and
2846 C<redo> work.
2847
2848 =item no Module VERSION LIST
2849
2850 =item no Module VERSION
2851
2852 =item no Module LIST
2853
2854 =item no Module
2855
2856 See the C<use> function, of which C<no> is the opposite.
2857
2858 =item oct EXPR
2859
2860 =item oct
2861
2862 Interprets EXPR as an octal string and returns the corresponding
2863 value.  (If EXPR happens to start off with C<0x>, interprets it as a
2864 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
2865 binary string.  Leading whitespace is ignored in all three cases.)
2866 The following will handle decimal, binary, octal, and hex in the standard
2867 Perl or C notation:
2868
2869     $val = oct($val) if $val =~ /^0/;
2870
2871 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
2872 in octal), use sprintf() or printf():
2873
2874     $perms = (stat("filename"))[2] & 07777;
2875     $oct_perms = sprintf "%lo", $perms;
2876
2877 The oct() function is commonly used when a string such as C<644> needs
2878 to be converted into a file mode, for example. (Although perl will
2879 automatically convert strings into numbers as needed, this automatic
2880 conversion assumes base 10.)
2881
2882 =item open FILEHANDLE,EXPR
2883
2884 =item open FILEHANDLE,MODE,EXPR
2885
2886 =item open FILEHANDLE,MODE,EXPR,LIST
2887
2888 =item open FILEHANDLE,MODE,REFERENCE
2889
2890 =item open FILEHANDLE
2891
2892 Opens the file whose filename is given by EXPR, and associates it with
2893 FILEHANDLE.
2894
2895 (The following is a comprehensive reference to open(): for a gentler
2896 introduction you may consider L<perlopentut>.)
2897
2898 If FILEHANDLE is an undefined scalar variable (or array or hash element)
2899 the variable is assigned a reference to a new anonymous filehandle,
2900 otherwise if FILEHANDLE is an expression, its value is used as the name of
2901 the real filehandle wanted.  (This is considered a symbolic reference, so
2902 C<use strict 'refs'> should I<not> be in effect.)
2903
2904 If EXPR is omitted, the scalar variable of the same name as the
2905 FILEHANDLE contains the filename.  (Note that lexical variables--those
2906 declared with C<my>--will not work for this purpose; so if you're
2907 using C<my>, specify EXPR in your call to open.)
2908
2909 If three or more arguments are specified then the mode of opening and
2910 the file name are separate. If MODE is C<< '<' >> or nothing, the file
2911 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
2912 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
2913 the file is opened for appending, again being created if necessary.
2914
2915 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
2916 indicate that you want both read and write access to the file; thus
2917 C<< '+<' >> is almost always preferred for read/write updates--the C<<
2918 '+>' >> mode would clobber the file first.  You can't usually use
2919 either read-write mode for updating textfiles, since they have
2920 variable length records.  See the B<-i> switch in L<perlrun> for a
2921 better approach.  The file is created with permissions of C<0666>
2922 modified by the process' C<umask> value.
2923
2924 These various prefixes correspond to the fopen(3) modes of C<'r'>,
2925 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
2926
2927 In the 2-arguments (and 1-argument) form of the call the mode and
2928 filename should be concatenated (in this order), possibly separated by
2929 spaces.  It is possible to omit the mode in these forms if the mode is
2930 C<< '<' >>.
2931
2932 If the filename begins with C<'|'>, the filename is interpreted as a
2933 command to which output is to be piped, and if the filename ends with a
2934 C<'|'>, the filename is interpreted as a command which pipes output to
2935 us.  See L<perlipc/"Using open() for IPC">
2936 for more examples of this.  (You are not allowed to C<open> to a command
2937 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
2938 and L<perlipc/"Bidirectional Communication with Another Process">
2939 for alternatives.)
2940
2941 For three or more arguments if MODE is C<'|-'>, the filename is
2942 interpreted as a command to which output is to be piped, and if MODE
2943 is C<'-|'>, the filename is interpreted as a command which pipes
2944 output to us.  In the 2-arguments (and 1-argument) form one should
2945 replace dash (C<'-'>) with the command.
2946 See L<perlipc/"Using open() for IPC"> for more examples of this.
2947 (You are not allowed to C<open> to a command that pipes both in I<and>
2948 out, but see L<IPC::Open2>, L<IPC::Open3>, and
2949 L<perlipc/"Bidirectional Communication"> for alternatives.)
2950
2951 In the three-or-more argument form of pipe opens, if LIST is specified
2952 (extra arguments after the command name) then LIST becomes arguments
2953 to the command invoked if the platform supports it.  The meaning of
2954 C<open> with more than three arguments for non-pipe modes is not yet
2955 specified. Experimental "layers" may give extra LIST arguments
2956 meaning.
2957
2958 In the 2-arguments (and 1-argument) form opening C<'-'> opens STDIN
2959 and opening C<< '>-' >> opens STDOUT.
2960
2961 You may use the three-argument form of open to specify IO "layers"
2962 (sometimes also referred to as "disciplines") to be applied to the handle
2963 that affect how the input and output are processed (see L<open> and
2964 L<PerlIO> for more details). For example
2965
2966   open(FH, "<:utf8", "file")
2967
2968 will open the UTF-8 encoded file containing Unicode characters,
2969 see L<perluniintro>. (Note that if layers are specified in the
2970 three-arg form then default layers set by the C<open> pragma are
2971 ignored.)
2972
2973 Open returns nonzero upon success, the undefined value otherwise.  If
2974 the C<open> involved a pipe, the return value happens to be the pid of
2975 the subprocess.
2976
2977 If you're running Perl on a system that distinguishes between text
2978 files and binary files, then you should check out L</binmode> for tips
2979 for dealing with this.  The key distinction between systems that need
2980 C<binmode> and those that don't is their text file formats.  Systems
2981 like Unix, Mac OS, and Plan 9, which delimit lines with a single
2982 character, and which encode that character in C as C<"\n">, do not
2983 need C<binmode>.  The rest need it.
2984
2985 When opening a file, it's usually a bad idea to continue normal execution
2986 if the request failed, so C<open> is frequently used in connection with
2987 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
2988 where you want to make a nicely formatted error message (but there are
2989 modules that can help with that problem)) you should always check
2990 the return value from opening a file.  The infrequent exception is when
2991 working with an unopened filehandle is actually what you want to do.
2992
2993 As a special case the 3-arg form with a read/write mode and the third
2994 argument being C<undef>:
2995
2996     open(TMP, "+>", undef) or die ...
2997
2998 opens a filehandle to an anonymous temporary file.  Also using "+<"
2999 works for symmetry, but you really should consider writing something
3000 to the temporary file first.  You will need to seek() to do the
3001 reading.
3002
3003 Since v5.8.0, perl has built using PerlIO by default.  Unless you've
3004 changed this (i.e. Configure -Uuseperlio), you can open file handles to
3005 "in memory" files held in Perl scalars via:
3006
3007     open($fh, '>', \$variable) || ..
3008
3009 Though if you try to re-open C<STDOUT> or C<STDERR> as an "in memory"
3010 file, you have to close it first:
3011
3012     close STDOUT;
3013     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3014
3015 Examples:
3016
3017     $ARTICLE = 100;
3018     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3019     while (<ARTICLE>) {...
3020
3021     open(LOG, '>>/usr/spool/news/twitlog');     # (log is reserved)
3022     # if the open fails, output is discarded
3023
3024     open(DBASE, '+<', 'dbase.mine')             # open for update
3025         or die "Can't open 'dbase.mine' for update: $!";
3026
3027     open(DBASE, '+<dbase.mine')                 # ditto
3028         or die "Can't open 'dbase.mine' for update: $!";
3029
3030     open(ARTICLE, '-|', "caesar <$article")     # decrypt article
3031         or die "Can't start caesar: $!";
3032
3033     open(ARTICLE, "caesar <$article |")         # ditto
3034         or die "Can't start caesar: $!";
3035
3036     open(EXTRACT, "|sort >Tmp$$")               # $$ is our process id
3037         or die "Can't start sort: $!";
3038
3039     # in memory files
3040     open(MEMORY,'>', \$var)
3041         or die "Can't open memory file: $!";
3042     print MEMORY "foo!\n";                      # output will end up in $var
3043
3044     # process argument list of files along with any includes
3045
3046     foreach $file (@ARGV) {
3047         process($file, 'fh00');
3048     }
3049
3050     sub process {
3051         my($filename, $input) = @_;
3052         $input++;               # this is a string increment
3053         unless (open($input, $filename)) {
3054             print STDERR "Can't open $filename: $!\n";
3055             return;
3056         }
3057
3058         local $_;
3059         while (<$input>) {              # note use of indirection
3060             if (/^#include "(.*)"/) {
3061                 process($1, $input);
3062                 next;
3063             }
3064             #...                # whatever
3065         }
3066     }
3067
3068 See L<perliol> for detailed info on PerlIO.
3069
3070 You may also, in the Bourne shell tradition, specify an EXPR beginning
3071 with C<< '>&' >>, in which case the rest of the string is interpreted
3072 as the name of a filehandle (or file descriptor, if numeric) to be
3073 duped (as L<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3074 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3075 The mode you specify should match the mode of the original filehandle.
3076 (Duping a filehandle does not take into account any existing contents
3077 of IO buffers.) If you use the 3-arg form then you can pass either a
3078 number, the name of a filehandle or the normal "reference to a glob".
3079
3080 Here is a script that saves, redirects, and restores C<STDOUT> and
3081 C<STDERR> using various methods:
3082
3083     #!/usr/bin/perl
3084     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3085     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3086
3087     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3088     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3089
3090     select STDERR; $| = 1;      # make unbuffered
3091     select STDOUT; $| = 1;      # make unbuffered
3092
3093     print STDOUT "stdout 1\n";  # this works for
3094     print STDERR "stderr 1\n";  # subprocesses too
3095
3096     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3097     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3098
3099     print STDOUT "stdout 2\n";
3100     print STDERR "stderr 2\n";
3101
3102 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3103 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3104 that file descriptor (and not call L<dup(2)>); this is more
3105 parsimonious of file descriptors.  For example:
3106
3107     # open for input, reusing the fileno of $fd
3108     open(FILEHANDLE, "<&=$fd")
3109
3110 or
3111
3112     open(FILEHANDLE, "<&=", $fd)
3113
3114 or
3115
3116     # open for append, using the fileno of OLDFH
3117     open(FH, ">>&=", OLDFH)
3118
3119 or
3120
3121     open(FH, ">>&=OLDFH")
3122
3123 Being parsimonious on filehandles is also useful (besides being
3124 parsimonious) for example when something is dependent on file
3125 descriptors, like for example locking using flock().  If you do just
3126 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3127 descriptor as B, and therefore flock(A) will not flock(B), and vice
3128 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3129 the same file descriptor.
3130
3131 Note that if you are using Perls older than 5.8.0, Perl will be using
3132 the standard C libraries' fdopen() to implement the "=" functionality.
3133 On many UNIX systems fdopen() fails when file descriptors exceed a
3134 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3135 most often the default.
3136
3137 You can see whether Perl has been compiled with PerlIO or not by
3138 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3139 is C<define>, you have PerlIO, otherwise you don't.
3140
3141 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3142 with 2-arguments (or 1-argument) form of open(), then
3143 there is an implicit fork done, and the return value of open is the pid
3144 of the child within the parent process, and C<0> within the child
3145 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3146 The filehandle behaves normally for the parent, but i/o to that
3147 filehandle is piped from/to the STDOUT/STDIN of the child process.
3148 In the child process the filehandle isn't opened--i/o happens from/to
3149 the new STDOUT or STDIN.  Typically this is used like the normal
3150 piped open when you want to exercise more control over just how the
3151 pipe command gets executed, such as when you are running setuid, and
3152 don't want to have to scan shell commands for metacharacters.
3153 The following triples are more or less equivalent:
3154
3155     open(FOO, "|tr '[a-z]' '[A-Z]'");
3156     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3157     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3158     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3159
3160     open(FOO, "cat -n '$file'|");
3161     open(FOO, '-|', "cat -n '$file'");
3162     open(FOO, '-|') || exec 'cat', '-n', $file;
3163     open(FOO, '-|', "cat", '-n', $file);
3164
3165 The last example in each block shows the pipe as "list form", which is
3166 not yet supported on all platforms.  A good rule of thumb is that if
3167 your platform has true C<fork()> (in other words, if your platform is
3168 UNIX) you can use the list form.
3169
3170 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3171
3172 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3173 output before any operation that may do a fork, but this may not be
3174 supported on some platforms (see L<perlport>).  To be safe, you may need
3175 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3176 of C<IO::Handle> on any open handles.
3177
3178 On systems that support a close-on-exec flag on files, the flag will
3179 be set for the newly opened file descriptor as determined by the value
3180 of $^F.  See L<perlvar/$^F>.
3181
3182 Closing any piped filehandle causes the parent process to wait for the
3183 child to finish, and returns the status value in C<$?> and
3184 C<${^CHILD_ERROR_NATIVE}>.
3185
3186 The filename passed to 2-argument (or 1-argument) form of open() will
3187 have leading and trailing whitespace deleted, and the normal
3188 redirection characters honored.  This property, known as "magic open",
3189 can often be used to good effect.  A user could specify a filename of
3190 F<"rsh cat file |">, or you could change certain filenames as needed:
3191
3192     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3193     open(FH, $filename) or die "Can't open $filename: $!";
3194
3195 Use 3-argument form to open a file with arbitrary weird characters in it,
3196
3197     open(FOO, '<', $file);
3198
3199 otherwise it's necessary to protect any leading and trailing whitespace:
3200
3201     $file =~ s#^(\s)#./$1#;
3202     open(FOO, "< $file\0");
3203
3204 (this may not work on some bizarre filesystems).  One should
3205 conscientiously choose between the I<magic> and 3-arguments form
3206 of open():
3207
3208     open IN, $ARGV[0];
3209
3210 will allow the user to specify an argument of the form C<"rsh cat file |">,
3211 but will not work on a filename which happens to have a trailing space, while
3212
3213     open IN, '<', $ARGV[0];
3214
3215 will have exactly the opposite restrictions.
3216
3217 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3218 should use the C<sysopen> function, which involves no such magic (but
3219 may use subtly different filemodes than Perl open(), which is mapped
3220 to C fopen()).  This is
3221 another way to protect your filenames from interpretation.  For example:
3222
3223     use IO::Handle;
3224     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3225         or die "sysopen $path: $!";
3226     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3227     print HANDLE "stuff $$\n";
3228     seek(HANDLE, 0, 0);
3229     print "File contains: ", <HANDLE>;
3230
3231 Using the constructor from the C<IO::Handle> package (or one of its
3232 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3233 filehandles that have the scope of whatever variables hold references to
3234 them, and automatically close whenever and however you leave that scope:
3235
3236     use IO::File;
3237     #...
3238     sub read_myfile_munged {
3239         my $ALL = shift;
3240         my $handle = new IO::File;
3241         open($handle, "myfile") or die "myfile: $!";
3242         $first = <$handle>
3243             or return ();     # Automatically closed here.
3244         mung $first or die "mung failed";       # Or here.
3245         return $first, <$handle> if $ALL;       # Or here.
3246         $first;                                 # Or here.
3247     }
3248
3249 See L</seek> for some details about mixing reading and writing.
3250
3251 =item opendir DIRHANDLE,EXPR
3252
3253 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3254 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3255 DIRHANDLE may be an expression whose value can be used as an indirect
3256 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3257 scalar variable (or array or hash element), the variable is assigned a
3258 reference to a new anonymous dirhandle.
3259 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3260
3261 =item ord EXPR
3262
3263 =item ord
3264
3265 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3266 or Unicode) value of the first character of EXPR.  If EXPR is omitted,
3267 uses C<$_>.
3268
3269 For the reverse, see L</chr>.
3270 See L<perlunicode> and L<encoding> for more about Unicode.
3271
3272 =item our EXPR
3273
3274 =item our EXPR TYPE
3275
3276 =item our EXPR : ATTRS
3277
3278 =item our TYPE EXPR : ATTRS
3279
3280 C<our> associates a simple name with a package variable in the current
3281 package for use within the current scope.  When C<use strict 'vars'> is in
3282 effect, C<our> lets you use declared global variables without qualifying
3283 them with package names, within the lexical scope of the C<our> declaration.
3284 In this way C<our> differs from C<use vars>, which is package scoped.
3285
3286 Unlike C<my>, which both allocates storage for a variable and associates
3287 a simple name with that storage for use within the current scope, C<our>
3288 associates a simple name with a package variable in the current package,
3289 for use within the current scope.  In other words, C<our> has the same
3290 scoping rules as C<my>, but does not necessarily create a
3291 variable.
3292
3293 If more than one value is listed, the list must be placed
3294 in parentheses.
3295
3296     our $foo;
3297     our($bar, $baz);
3298
3299 An C<our> declaration declares a global variable that will be visible
3300 across its entire lexical scope, even across package boundaries.  The
3301 package in which the variable is entered is determined at the point
3302 of the declaration, not at the point of use.  This means the following
3303 behavior holds:
3304
3305     package Foo;
3306     our $bar;           # declares $Foo::bar for rest of lexical scope
3307     $bar = 20;
3308
3309     package Bar;
3310     print $bar;         # prints 20, as it refers to $Foo::bar
3311
3312 Multiple C<our> declarations with the same name in the same lexical
3313 scope are allowed if they are in different packages.  If they happen
3314 to be in the same package, Perl will emit warnings if you have asked
3315 for them, just like multiple C<my> declarations.  Unlike a second
3316 C<my> declaration, which will bind the name to a fresh variable, a
3317 second C<our> declaration in the same package, in the same scope, is
3318 merely redundant.
3319
3320     use warnings;
3321     package Foo;
3322     our $bar;           # declares $Foo::bar for rest of lexical scope
3323     $bar = 20;
3324
3325     package Bar;
3326     our $bar = 30;      # declares $Bar::bar for rest of lexical scope
3327     print $bar;         # prints 30
3328
3329     our $bar;           # emits warning but has no other effect
3330     print $bar;         # still prints 30
3331
3332 An C<our> declaration may also have a list of attributes associated
3333 with it.
3334
3335 The exact semantics and interface of TYPE and ATTRS are still
3336 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3337 and attributes are handled using the C<attributes> pragma, or starting
3338 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3339 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3340 L<attributes>, and L<Attribute::Handlers>.
3341
3342 The only currently recognized C<our()> attribute is C<unique> which
3343 indicates that a single copy of the global is to be used by all
3344 interpreters should the program happen to be running in a
3345 multi-interpreter environment. (The default behaviour would be for
3346 each interpreter to have its own copy of the global.)  Examples:
3347
3348     our @EXPORT : unique = qw(foo);
3349     our %EXPORT_TAGS : unique = (bar => [qw(aa bb cc)]);
3350     our $VERSION : unique = "1.00";
3351
3352 Note that this attribute also has the effect of making the global
3353 readonly when the first new interpreter is cloned (for example,
3354 when the first new thread is created).
3355
3356 Multi-interpreter environments can come to being either through the
3357 fork() emulation on Windows platforms, or by embedding perl in a
3358 multi-threaded application.  The C<unique> attribute does nothing in
3359 all other environments.
3360
3361 Warning: the current implementation of this attribute operates on the
3362 typeglob associated with the variable; this means that C<our $x : unique>
3363 also has the effect of C<our @x : unique; our %x : unique>. This may be
3364 subject to change.
3365
3366 =item pack TEMPLATE,LIST
3367
3368 Takes a LIST of values and converts it into a string using the rules
3369 given by the TEMPLATE.  The resulting string is the concatenation of
3370 the converted values.  Typically, each converted value looks
3371 like its machine-level representation.  For example, on 32-bit machines
3372 an integer may be represented by a sequence of 4 bytes that will be 
3373 converted to a sequence of 4 characters.
3374
3375 The TEMPLATE is a sequence of characters that give the order and type
3376 of values, as follows:
3377
3378     a   A string with arbitrary binary data, will be null padded.
3379     A   A text (ASCII) string, will be space padded.
3380     Z   A null terminated (ASCIZ) string, will be null padded.
3381
3382     b   A bit string (ascending bit order inside each byte, like vec()).
3383     B   A bit string (descending bit order inside each byte).
3384     h   A hex string (low nybble first).
3385     H   A hex string (high nybble first).
3386
3387     c   A signed char (8-bit) value.
3388     C   An unsigned C char (octet) even under Unicode. Should normally not
3389         be used. See U and W instead.
3390     W   An unsigned char value (can be greater than 255).
3391
3392     s   A signed short (16-bit) value.
3393     S   An unsigned short value.
3394
3395     l   A signed long (32-bit) value.
3396     L   An unsigned long value.
3397
3398     q   A signed quad (64-bit) value.
3399     Q   An unsigned quad value.
3400           (Quads are available only if your system supports 64-bit
3401            integer values _and_ if Perl has been compiled to support those.
3402            Causes a fatal error otherwise.)
3403
3404     i   A signed integer value.
3405     I   A unsigned integer value.
3406           (This 'integer' is _at_least_ 32 bits wide.  Its exact
3407            size depends on what a local C compiler calls 'int'.)
3408  
3409     n   An unsigned short (16-bit) in "network" (big-endian) order.
3410     N   An unsigned long (32-bit) in "network" (big-endian) order.
3411     v   An unsigned short (16-bit) in "VAX" (little-endian) order.
3412     V   An unsigned long (32-bit) in "VAX" (little-endian) order.
3413
3414     j   A Perl internal signed integer value (IV).
3415     J   A Perl internal unsigned integer value (UV).
3416
3417     f   A single-precision float in the native format.
3418     d   A double-precision float in the native format.
3419
3420     F   A Perl internal floating point value (NV) in the native format
3421     D   A long double-precision float in the native format.
3422           (Long doubles are available only if your system supports long
3423            double values _and_ if Perl has been compiled to support those.
3424            Causes a fatal error otherwise.)
3425
3426     p   A pointer to a null-terminated string.
3427     P   A pointer to a structure (fixed-length string).
3428
3429     u   A uuencoded string.
3430     U   A Unicode character number.  Encodes to UTF-8 internally
3431         (or UTF-EBCDIC in EBCDIC platforms).
3432
3433     w   A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3434         details).  Its bytes represent an unsigned integer in base 128,
3435         most significant digit first, with as few digits as possible.  Bit
3436         eight (the high bit) is set on each byte except the last.
3437
3438     x   A null byte.
3439     X   Back up a byte.
3440     @   Null fill or truncate to absolute position, counted from the
3441         start of the innermost ()-group.
3442     .   Null fill or truncate to absolute position specified by value.
3443     (   Start of a ()-group.
3444
3445 One or more of the modifiers below may optionally follow some letters in the
3446 TEMPLATE (the second column lists the letters for which the modifier is
3447 valid):
3448
3449     !   sSlLiI     Forces native (short, long, int) sizes instead
3450                    of fixed (16-/32-bit) sizes.
3451
3452         xX         Make x and X act as alignment commands.
3453
3454         nNvV       Treat integers as signed instead of unsigned.
3455
3456         @.         Specify position as byte offset in the internal
3457                    representation of the packed string. Efficient but
3458                    dangerous.
3459
3460     >   sSiIlLqQ   Force big-endian byte-order on the type.
3461         jJfFdDpP   (The "big end" touches the construct.)
3462
3463     <   sSiIlLqQ   Force little-endian byte-order on the type.
3464         jJfFdDpP   (The "little end" touches the construct.)
3465
3466 The C<E<gt>> and C<E<lt>> modifiers can also be used on C<()>-groups,
3467 in which case they force a certain byte-order on all components of
3468 that group, including subgroups.
3469
3470 The following rules apply:
3471
3472 =over 8
3473
3474 =item *
3475
3476 Each letter may optionally be followed by a number giving a repeat
3477 count.  With all types except C<a>, C<A>, C<Z>, C<b>, C<B>, C<h>,
3478 C<H>, C<@>, C<.>, C<x>, C<X> and C<P> the pack function will gobble up
3479 that many values from the LIST.  A C<*> for the repeat count means to
3480 use however many items are left, except for C<@>, C<x>, C<X>, where it
3481 is equivalent to C<0>, for <.> where it means relative to string start
3482 and C<u>, where it is equivalent to 1 (or 45, which is the same).
3483 A numeric repeat count may optionally be enclosed in brackets, as in
3484 C<pack 'C[80]', @arr>.
3485
3486 One can replace the numeric repeat count by a template enclosed in brackets;
3487 then the packed length of this template in bytes is used as a count.
3488 For example, C<x[L]> skips a long (it skips the number of bytes in a long);
3489 the template C<$t X[$t] $t> unpack()s twice what $t unpacks.
3490 If the template in brackets contains alignment commands (such as C<x![d]>),
3491 its packed length is calculated as if the start of the template has the maximal
3492 possible alignment.
3493
3494 When used with C<Z>, C<*> results in the addition of a trailing null
3495 byte (so the packed result will be one longer than the byte C<length>
3496 of the item).
3497
3498 When used with C<@>, the repeat count represents an offset from the start
3499 of the innermost () group.
3500
3501 When used with C<.>, the repeat count is used to determine the starting
3502 position from where the value offset is calculated. If the repeat count
3503 is 0, it's relative to the current position. If the repeat count is C<*>,
3504 the offset is relative to the start of the packed string. And if its an
3505 integer C<n> the offset is relative to the start of the n-th innermost
3506 () group (or the start of the string if C<n> is bigger then the group
3507 level).
3508
3509 The repeat count for C<u> is interpreted as the maximal number of bytes
3510 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3511 count should not be more than 65.
3512
3513 =item *
3514
3515 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3516 string of length count, padding with nulls or spaces as necessary.  When
3517 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3518 after the first null, and C<a> returns data verbatim.
3519
3520 If the value-to-pack is too long, it is truncated.  If too long and an
3521 explicit count is provided, C<Z> packs only C<$count-1> bytes, followed
3522 by a null byte.  Thus C<Z> always packs a trailing null (except when the
3523 count is 0).
3524
3525 =item *
3526
3527 Likewise, the C<b> and C<B> fields pack a string that many bits long.
3528 Each character of the input field of pack() generates 1 bit of the result.
3529 Each result bit is based on the least-significant bit of the corresponding
3530 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3531 and C<"1"> generate bits 0 and 1, as do characters C<"\0"> and C<"\1">.
3532
3533 Starting from the beginning of the input string of pack(), each 8-tuple
3534 of characters is converted to 1 character of output.  With format C<b>
3535 the first character of the 8-tuple determines the least-significant bit of a
3536 character, and with format C<B> it determines the most-significant bit of
3537 a character.
3538
3539 If the length of the input string is not exactly divisible by 8, the
3540 remainder is packed as if the input string were padded by null characters
3541 at the end.  Similarly, during unpack()ing the "extra" bits are ignored.
3542
3543 If the input string of pack() is longer than needed, extra characters are 
3544 ignored. A C<*> for the repeat count of pack() means to use all the 
3545 characters of the input field.  On unpack()ing the bits are converted to a 
3546 string of C<"0">s and C<"1">s.
3547
3548 =item *
3549
3550 The C<h> and C<H> fields pack a string that many nybbles (4-bit groups,
3551 representable as hexadecimal digits, 0-9a-f) long.
3552
3553 Each character of the input field of pack() generates 4 bits of the result.
3554 For non-alphabetical characters the result is based on the 4 least-significant
3555 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3556 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3557 C<"\0"> and C<"\1">.  For characters C<"a".."f"> and C<"A".."F"> the result
3558 is compatible with the usual hexadecimal digits, so that C<"a"> and
3559 C<"A"> both generate the nybble C<0xa==10>.  The result for characters
3560 C<"g".."z"> and C<"G".."Z"> is not well-defined.
3561
3562 Starting from the beginning of the input string of pack(), each pair
3563 of characters is converted to 1 character of output.  With format C<h> the
3564 first character of the pair determines the least-significant nybble of the
3565 output character, and with format C<H> it determines the most-significant
3566 nybble.
3567
3568 If the length of the input string is not even, it behaves as if padded
3569 by a null character at the end.  Similarly, during unpack()ing the "extra"
3570 nybbles are ignored.
3571
3572 If the input string of pack() is longer than needed, extra characters are
3573 ignored.
3574 A C<*> for the repeat count of pack() means to use all the characters of
3575 the input field.  On unpack()ing the nybbles are converted to a string
3576 of hexadecimal digits.
3577
3578 =item *
3579
3580 The C<p> type packs a pointer to a null-terminated string.  You are
3581 responsible for ensuring the string is not a temporary value (which can
3582 potentially get deallocated before you get around to using the packed result).
3583 The C<P> type packs a pointer to a structure of the size indicated by the
3584 length.  A NULL pointer is created if the corresponding value for C<p> or
3585 C<P> is C<undef>, similarly for unpack().
3586
3587 If your system has a strange pointer size (i.e. a pointer is neither as
3588 big as an int nor as big as a long), it may not be possible to pack or
3589 unpack pointers in big- or little-endian byte order.  Attempting to do
3590 so will result in a fatal error.
3591
3592 =item *
3593
3594 The C</> template character allows packing and unpacking of a sequence of
3595 items where the packed structure contains a packed item count followed by 
3596 the packed items themselves.
3597 You write I<length-item>C</>I<sequence-item>.
3598
3599 The I<length-item> can be any C<pack> template letter, and describes
3600 how the length value is packed.  The ones likely to be of most use are
3601 integer-packing ones like C<n> (for Java strings), C<w> (for ASN.1 or
3602 SNMP) and C<N> (for Sun XDR).
3603
3604 For C<pack>, the I<sequence-item> may have a repeat count, in which case
3605 the minimum of that and the number of available items is used as argument
3606 for the I<length-item>. If it has no repeat count or uses a '*', the number
3607 of available items is used. For C<unpack> the repeat count is always obtained
3608 by decoding the packed item count, and the I<sequence-item> must not have a
3609 repeat count.
3610
3611 If the I<sequence-item> refers to a string type (C<"A">, C<"a"> or C<"Z">),
3612 the I<length-item> is a string length, not a number of strings. If there is
3613 an explicit repeat count for pack, the packed string will be adjusted to that
3614 given length.
3615
3616     unpack 'W/a', "\04Gurusamy";        gives ('Guru')
3617     unpack 'a3/A* A*', '007 Bond  J ';  gives (' Bond', 'J')
3618     pack 'n/a* w/a','hello,','world';   gives "\000\006hello,\005world"
3619     pack 'a/W2', ord('a') .. ord('z');  gives '2ab'
3620
3621 The I<length-item> is not returned explicitly from C<unpack>.
3622
3623 Adding a count to the I<length-item> letter is unlikely to do anything
3624 useful, unless that letter is C<A>, C<a> or C<Z>.  Packing with a
3625 I<length-item> of C<a> or C<Z> may introduce C<"\000"> characters,
3626 which Perl does not regard as legal in numeric strings.
3627
3628 =item *
3629
3630 The integer types C<s>, C<S>, C<l>, and C<L> may be
3631 followed by a C<!> modifier to signify native shorts or
3632 longs--as you can see from above for example a bare C<l> does mean
3633 exactly 32 bits, the native C<long> (as seen by the local C compiler)
3634 may be larger.  This is an issue mainly in 64-bit platforms.  You can
3635 see whether using C<!> makes any difference by
3636
3637         print length(pack("s")), " ", length(pack("s!")), "\n";
3638         print length(pack("l")), " ", length(pack("l!")), "\n";
3639
3640 C<i!> and C<I!> also work but only because of completeness;
3641 they are identical to C<i> and C<I>.
3642
3643 The actual sizes (in bytes) of native shorts, ints, longs, and long
3644 longs on the platform where Perl was built are also available via
3645 L<Config>:
3646
3647        use Config;
3648        print $Config{shortsize},    "\n";
3649        print $Config{intsize},      "\n";
3650        print $Config{longsize},     "\n";
3651        print $Config{longlongsize}, "\n";
3652
3653 (The C<$Config{longlongsize}> will be undefined if your system does
3654 not support long longs.)
3655
3656 =item *
3657
3658 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J>
3659 are inherently non-portable between processors and operating systems
3660 because they obey the native byteorder and endianness.  For example a
3661 4-byte integer 0x12345678 (305419896 decimal) would be ordered natively
3662 (arranged in and handled by the CPU registers) into bytes as
3663
3664         0x12 0x34 0x56 0x78     # big-endian
3665         0x78 0x56 0x34 0x12     # little-endian
3666
3667 Basically, the Intel and VAX CPUs are little-endian, while everybody
3668 else, for example Motorola m68k/88k, PPC, Sparc, HP PA, Power, and
3669 Cray are big-endian.  Alpha and MIPS can be either: Digital/Compaq
3670 used/uses them in little-endian mode; SGI/Cray uses them in big-endian
3671 mode.
3672
3673 The names `big-endian' and `little-endian' are comic references to
3674 the classic "Gulliver's Travels" (via the paper "On Holy Wars and a
3675 Plea for Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980) and
3676 the egg-eating habits of the Lilliputians.
3677
3678 Some systems may have even weirder byte orders such as
3679
3680         0x56 0x78 0x12 0x34
3681         0x34 0x12 0x78 0x56
3682
3683 You can see your system's preference with
3684
3685         print join(" ", map { sprintf "%#02x", $_ }
3686                             unpack("W*",pack("L",0x12345678))), "\n";
3687
3688 The byteorder on the platform where Perl was built is also available
3689 via L<Config>:
3690
3691         use Config;
3692         print $Config{byteorder}, "\n";
3693
3694 Byteorders C<'1234'> and C<'12345678'> are little-endian, C<'4321'>
3695 and C<'87654321'> are big-endian.
3696
3697 If you want portable packed integers you can either use the formats
3698 C<n>, C<N>, C<v>, and C<V>, or you can use the C<E<gt>> and C<E<lt>>
3699 modifiers.  These modifiers are only available as of perl 5.9.2.
3700 See also L<perlport>.
3701
3702 =item *
3703
3704 All integer and floating point formats as well as C<p> and C<P> and
3705 C<()>-groups may be followed by the C<E<gt>> or C<E<lt>> modifiers
3706 to force big- or little- endian byte-order, respectively.
3707 This is especially useful, since C<n>, C<N>, C<v> and C<V> don't cover
3708 signed integers, 64-bit integers and floating point values.  However,
3709 there are some things to keep in mind.
3710
3711 Exchanging signed integers between different platforms only works
3712 if all platforms store them in the same format.  Most platforms store
3713 signed integers in two's complement, so usually this is not an issue.
3714
3715 The C<E<gt>> or C<E<lt>> modifiers can only be used on floating point
3716 formats on big- or little-endian machines.  Otherwise, attempting to
3717 do so will result in a fatal error.
3718
3719 Forcing big- or little-endian byte-order on floating point values for
3720 data exchange can only work if all platforms are using the same
3721 binary representation (e.g. IEEE floating point format).  Even if all
3722 platforms are using IEEE, there may be subtle differences.  Being able
3723 to use C<E<gt>> or C<E<lt>> on floating point values can be very useful,
3724 but also very dangerous if you don't know exactly what you're doing.
3725 It is definitely not a general way to portably store floating point
3726 values.
3727
3728 When using C<E<gt>> or C<E<lt>> on an C<()>-group, this will affect
3729 all types inside the group that accept the byte-order modifiers,
3730 including all subgroups.  It will silently be ignored for all other
3731 types.  You are not allowed to override the byte-order within a group
3732 that already has a byte-order modifier suffix.
3733
3734 =item *
3735
3736 Real numbers (floats and doubles) are in the native machine format only;
3737 due to the multiplicity of floating formats around, and the lack of a
3738 standard "network" representation, no facility for interchange has been
3739 made.  This means that packed floating point data written on one machine
3740 may not be readable on another - even if both use IEEE floating point
3741 arithmetic (as the endian-ness of the memory representation is not part
3742 of the IEEE spec).  See also L<perlport>.
3743
3744 If you know exactly what you're doing, you can use the C<E<gt>> or C<E<lt>>
3745 modifiers to force big- or little-endian byte-order on floating point values.
3746
3747 Note that Perl uses doubles (or long doubles, if configured) internally for
3748 all numeric calculation, and converting from double into float and thence back
3749 to double again will lose precision (i.e., C<unpack("f", pack("f", $foo)>)
3750 will not in general equal $foo).
3751
3752 =item *
3753
3754 Pack and unpack can operate in two modes, character mode (C<C0> mode) where
3755 the packed string is processed per character and UTF-8 mode (C<U0> mode)
3756 where the packed string is processed in its UTF-8-encoded Unicode form on
3757 a byte by byte basis. Character mode is the default unless the format string 
3758 starts with an C<U>. You can switch mode at any moment with an explicit 
3759 C<C0> or C<U0> in the format. A mode is in effect until the next mode switch 
3760 or until the end of the ()-group in which it was entered.
3761
3762 =item *
3763
3764 You must yourself do any alignment or padding by inserting for example
3765 enough C<'x'>es while packing.  There is no way to pack() and unpack()
3766 could know where the characters are going to or coming from.  Therefore
3767 C<pack> (and C<unpack>) handle their output and input as flat
3768 sequences of characters.
3769
3770 =item *
3771
3772 A ()-group is a sub-TEMPLATE enclosed in parentheses.  A group may
3773 take a repeat count, both as postfix, and for unpack() also via the C</>
3774 template character. Within each repetition of a group, positioning with
3775 C<@> starts again at 0. Therefore, the result of
3776
3777     pack( '@1A((@2A)@3A)', 'a', 'b', 'c' )
3778
3779 is the string "\0a\0\0bc".
3780
3781 =item *
3782
3783 C<x> and C<X> accept C<!> modifier.  In this case they act as
3784 alignment commands: they jump forward/back to the closest position
3785 aligned at a multiple of C<count> characters. For example, to pack() or
3786 unpack() C's C<struct {char c; double d; char cc[2]}> one may need to
3787 use the template C<W x![d] d W[2]>; this assumes that doubles must be
3788 aligned on the double's size.
3789
3790 For alignment commands C<count> of 0 is equivalent to C<count> of 1;
3791 both result in no-ops.
3792
3793 =item *
3794
3795 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier. In this case they
3796 will represent signed 16-/32-bit integers in big-/little-endian order.
3797 This is only portable if all platforms sharing the packed data use the
3798 same binary representation for signed integers (e.g. all platforms are
3799 using two's complement representation).
3800
3801 =item *
3802
3803 A comment in a TEMPLATE starts with C<#> and goes to the end of line.
3804 White space may be used to separate pack codes from each other, but
3805 modifiers and a repeat count must follow immediately.
3806
3807 =item *
3808
3809 If TEMPLATE requires more arguments to pack() than actually given, pack()
3810 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
3811 to pack() than actually given, extra arguments are ignored.
3812
3813 =back
3814
3815 Examples:
3816
3817     $foo = pack("WWWW",65,66,67,68);
3818     # foo eq "ABCD"
3819     $foo = pack("W4",65,66,67,68);
3820     # same thing
3821     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
3822     # same thing with Unicode circled letters.
3823     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
3824     # same thing with Unicode circled letters. You don't get the UTF-8
3825     # bytes because the U at the start of the format caused a switch to
3826     # U0-mode, so the UTF-8 bytes get joined into characters
3827     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
3828     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
3829     # This is the UTF-8 encoding of the string in the previous example
3830
3831     $foo = pack("ccxxcc",65,66,67,68);
3832     # foo eq "AB\0\0CD"
3833
3834     # note: the above examples featuring "W" and "c" are true
3835     # only on ASCII and ASCII-derived systems such as ISO Latin 1
3836     # and UTF-8.  In EBCDIC the first example would be
3837     # $foo = pack("WWWW",193,194,195,196);
3838
3839     $foo = pack("s2",1,2);
3840     # "\1\0\2\0" on little-endian
3841     # "\0\1\0\2" on big-endian
3842
3843     $foo = pack("a4","abcd","x","y","z");
3844     # "abcd"
3845
3846     $foo = pack("aaaa","abcd","x","y","z");
3847     # "axyz"
3848
3849     $foo = pack("a14","abcdefg");
3850     # "abcdefg\0\0\0\0\0\0\0"
3851
3852     $foo = pack("i9pl", gmtime);
3853     # a real struct tm (on my system anyway)
3854
3855     $utmp_template = "Z8 Z8 Z16 L";
3856     $utmp = pack($utmp_template, @utmp1);
3857     # a struct utmp (BSDish)
3858
3859     @utmp2 = unpack($utmp_template, $utmp);
3860     # "@utmp1" eq "@utmp2"
3861
3862     sub bintodec {
3863         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
3864     }
3865
3866     $foo = pack('sx2l', 12, 34);
3867     # short 12, two zero bytes padding, long 34
3868     $bar = pack('s@4l', 12, 34);
3869     # short 12, zero fill to position 4, long 34
3870     # $foo eq $bar
3871     $baz = pack('s.l', 12, 4, 34);
3872     # short 12, zero fill to position 4, long 34
3873
3874     $foo = pack('nN', 42, 4711);
3875     # pack big-endian 16- and 32-bit unsigned integers
3876     $foo = pack('S>L>', 42, 4711);
3877     # exactly the same
3878     $foo = pack('s<l<', -42, 4711);
3879     # pack little-endian 16- and 32-bit signed integers
3880     $foo = pack('(sl)<', -42, 4711);
3881     # exactly the same
3882
3883 The same template may generally also be used in unpack().
3884
3885 =item package NAMESPACE
3886
3887 =item package
3888
3889 Declares the compilation unit as being in the given namespace.  The scope
3890 of the package declaration is from the declaration itself through the end
3891 of the enclosing block, file, or eval (the same as the C<my> operator).
3892 All further unqualified dynamic identifiers will be in this namespace.
3893 A package statement affects only dynamic variables--including those
3894 you've used C<local> on--but I<not> lexical variables, which are created
3895 with C<my>.  Typically it would be the first declaration in a file to
3896 be included by the C<require> or C<use> operator.  You can switch into a
3897 package in more than one place; it merely influences which symbol table
3898 is used by the compiler for the rest of that block.  You can refer to
3899 variables and filehandles in other packages by prefixing the identifier
3900 with the package name and a double colon:  C<$Package::Variable>.
3901 If the package name is null, the C<main> package as assumed.  That is,
3902 C<$::sail> is equivalent to C<$main::sail> (as well as to C<$main'sail>,
3903 still seen in older code).
3904
3905 If NAMESPACE is omitted, then there is no current package, and all
3906 identifiers must be fully qualified or lexicals.  However, you are
3907 strongly advised not to make use of this feature. Its use can cause
3908 unexpected behaviour, even crashing some versions of Perl. It is
3909 deprecated, and will be removed from a future release.
3910
3911 See L<perlmod/"Packages"> for more information about packages, modules,
3912 and classes.  See L<perlsub> for other scoping issues.
3913
3914 =item pipe READHANDLE,WRITEHANDLE
3915
3916 Opens a pair of connected pipes like the corresponding system call.
3917 Note that if you set up a loop of piped processes, deadlock can occur
3918 unless you are very careful.  In addition, note that Perl's pipes use
3919 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
3920 after each command, depending on the application.
3921
3922 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
3923 for examples of such things.
3924
3925 On systems that support a close-on-exec flag on files, the flag will be set
3926 for the newly opened file descriptors as determined by the value of $^F.
3927 See L<perlvar/$^F>.
3928
3929 =item pop ARRAY
3930
3931 =item pop
3932
3933 Pops and returns the last value of the array, shortening the array by
3934 one element.  Has an effect similar to
3935
3936     $ARRAY[$#ARRAY--]
3937
3938 If there are no elements in the array, returns the undefined value
3939 (although this may happen at other times as well).  If ARRAY is
3940 omitted, pops the C<@ARGV> array in the main program, and the C<@_>
3941 array in subroutines, just like C<shift>.
3942
3943 =item pos SCALAR
3944
3945 =item pos
3946
3947 Returns the offset of where the last C<m//g> search left off for the variable
3948 in question (C<$_> is used when the variable is not specified).  Note that
3949 0 is a valid match offset.  C<undef> indicates that the search position
3950 is reset (usually due to match failure, but can also be because no match has
3951 yet been performed on the scalar). C<pos> directly accesses the location used
3952 by the regexp engine to store the offset, so assigning to C<pos> will change
3953 that offset, and so will also influence the C<\G> zero-width assertion in
3954 regular expressions. Because a failed C<m//gc> match doesn't reset the offset,
3955 the return from C<pos> won't change either in this case.  See L<perlre> and
3956 L<perlop>.
3957
3958 =item print FILEHANDLE LIST
3959
3960 =item print LIST
3961
3962 =item print
3963
3964 Prints a string or a list of strings.  Returns true if successful.
3965 FILEHANDLE may be a scalar variable name, in which case the variable
3966 contains the name of or a reference to the filehandle, thus introducing
3967 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
3968 the next token is a term, it may be misinterpreted as an operator
3969 unless you interpose a C<+> or put parentheses around the arguments.)
3970 If FILEHANDLE is omitted, prints by default to standard output (or
3971 to the last selected output channel--see L</select>).  If LIST is
3972 also omitted, prints C<$_> to the currently selected output channel.
3973 To set the default output channel to something other than STDOUT
3974 use the select operation.  The current value of C<$,> (if any) is
3975 printed between each LIST item.  The current value of C<$\> (if
3976 any) is printed after the entire LIST has been printed.  Because
3977 print takes a LIST, anything in the LIST is evaluated in list
3978 context, and any subroutine that you call will have one or more of
3979 its expressions evaluated in list context.  Also be careful not to
3980 follow the print keyword with a left parenthesis unless you want
3981 the corresponding right parenthesis to terminate the arguments to
3982 the print--interpose a C<+> or put parentheses around all the
3983 arguments.
3984
3985 Note that if you're storing FILEHANDLEs in an array, or if you're using
3986 any other expression more complex than a scalar variable to retrieve it,
3987 you will have to use a block returning the filehandle value instead:
3988
3989     print { $files[$i] } "stuff\n";
3990     print { $OK ? STDOUT : STDERR } "stuff\n";
3991
3992 =item printf FILEHANDLE FORMAT, LIST
3993
3994 =item printf FORMAT, LIST
3995
3996 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
3997 (the output record separator) is not appended.  The first argument
3998 of the list will be interpreted as the C<printf> format. See C<sprintf>
3999 for an explanation of the format argument. If C<use locale> is in effect,
4000 the character used for the decimal point in formatted real numbers is
4001 affected by the LC_NUMERIC locale.  See L<perllocale>.
4002
4003 Don't fall into the trap of using a C<printf> when a simple
4004 C<print> would do.  The C<print> is more efficient and less
4005 error prone.
4006
4007 =item prototype FUNCTION
4008
4009 Returns the prototype of a function as a string (or C<undef> if the
4010 function has no prototype).  FUNCTION is a reference to, or the name of,
4011 the function whose prototype you want to retrieve.
4012
4013 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4014 name for Perl builtin.  If the builtin is not I<overridable> (such as
4015 C<qw//>) or its arguments cannot be expressed by a prototype (such as
4016 C<system>) returns C<undef> because the builtin does not really behave
4017 like a Perl function.  Otherwise, the string describing the equivalent
4018 prototype is returned.
4019
4020 =item push ARRAY,LIST
4021
4022 Treats ARRAY as a stack, and pushes the values of LIST
4023 onto the end of ARRAY.  The length of ARRAY increases by the length of
4024 LIST.  Has the same effect as
4025
4026     for $value (LIST) {
4027         $ARRAY[++$#ARRAY] = $value;
4028     }
4029
4030 but is more efficient.  Returns the number of elements in the array following
4031 the completed C<push>.
4032
4033 =item q/STRING/
4034
4035 =item qq/STRING/
4036
4037 =item qr/STRING/
4038
4039 =item qx/STRING/
4040
4041 =item qw/STRING/
4042
4043 Generalized quotes.  See L<perlop/"Regexp Quote-Like Operators">.
4044
4045 =item quotemeta EXPR
4046
4047 =item quotemeta
4048
4049 Returns the value of EXPR with all non-"word"
4050 characters backslashed.  (That is, all characters not matching
4051 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4052 returned string, regardless of any locale settings.)
4053 This is the internal function implementing
4054 the C<\Q> escape in double-quoted strings.
4055
4056 If EXPR is omitted, uses C<$_>.
4057
4058 =item rand EXPR
4059
4060 =item rand
4061
4062 Returns a random fractional number greater than or equal to C<0> and less
4063 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4064 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4065 also special-cased as C<1> - this has not been documented before perl 5.8.0
4066 and is subject to change in future versions of perl.  Automatically calls
4067 C<srand> unless C<srand> has already been called.  See also C<srand>.
4068
4069 Apply C<int()> to the value returned by C<rand()> if you want random
4070 integers instead of random fractional numbers.  For example,
4071
4072     int(rand(10))
4073
4074 returns a random integer between C<0> and C<9>, inclusive.
4075
4076 (Note: If your rand function consistently returns numbers that are too
4077 large or too small, then your version of Perl was probably compiled
4078 with the wrong number of RANDBITS.)
4079
4080 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4081
4082 =item read FILEHANDLE,SCALAR,LENGTH
4083
4084 Attempts to read LENGTH I<characters> of data into variable SCALAR
4085 from the specified FILEHANDLE.  Returns the number of characters
4086 actually read, C<0> at end of file, or undef if there was an error (in
4087 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4088 so that the last character actually read is the last character of the
4089 scalar after the read.
4090
4091 An OFFSET may be specified to place the read data at some place in the
4092 string other than the beginning.  A negative OFFSET specifies
4093 placement at that many characters counting backwards from the end of
4094 the string.  A positive OFFSET greater than the length of SCALAR
4095 results in the string being padded to the required size with C<"\0">
4096 bytes before the result of the read is appended.
4097
4098 The call is actually implemented in terms of either Perl's or system's
4099 fread() call.  To get a true read(2) system call, see C<sysread>.
4100
4101 Note the I<characters>: depending on the status of the filehandle,
4102 either (8-bit) bytes or characters are read.  By default all
4103 filehandles operate on bytes, but for example if the filehandle has
4104 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4105 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4106 characters, not bytes.  Similarly for the C<:encoding> pragma:
4107 in that case pretty much any characters can be read.
4108
4109 =item readdir DIRHANDLE
4110
4111 Returns the next directory entry for a directory opened by C<opendir>.
4112 If used in list context, returns all the rest of the entries in the
4113 directory.  If there are no more entries, returns an undefined value in
4114 scalar context or a null list in list context.
4115
4116 If you're planning to filetest the return values out of a C<readdir>, you'd
4117 better prepend the directory in question.  Otherwise, because we didn't
4118 C<chdir> there, it would have been testing the wrong file.
4119
4120     opendir(DIR, $some_dir) || die "can't opendir $some_dir: $!";
4121     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir(DIR);
4122     closedir DIR;
4123
4124 =item readline EXPR
4125
4126 Reads from the filehandle whose typeglob is contained in EXPR.  In scalar
4127 context, each call reads and returns the next line, until end-of-file is
4128 reached, whereupon the subsequent call returns undef.  In list context,
4129 reads until end-of-file is reached and returns a list of lines.  Note that
4130 the notion of "line" used here is however you may have defined it
4131 with C<$/> or C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4132
4133 When C<$/> is set to C<undef>, when readline() is in scalar
4134 context (i.e. file slurp mode), and when an empty file is read, it
4135 returns C<''> the first time, followed by C<undef> subsequently.
4136
4137 This is the internal function implementing the C<< <EXPR> >>
4138 operator, but you can use it directly.  The C<< <EXPR> >>
4139 operator is discussed in more detail in L<perlop/"I/O Operators">.
4140
4141     $line = <STDIN>;
4142     $line = readline(*STDIN);           # same thing
4143
4144 If readline encounters an operating system error, C<$!> will be set with the
4145 corresponding error message.  It can be helpful to check C<$!> when you are
4146 reading from filehandles you don't trust, such as a tty or a socket.  The
4147 following example uses the operator form of C<readline>, and takes the necessary
4148 steps to ensure that C<readline> was successful.
4149
4150     for (;;) {
4151         undef $!;
4152         unless (defined( $line = <> )) {
4153             die $! if $!;
4154             last; # reached EOF
4155         }
4156         # ...
4157     }
4158
4159 =item readlink EXPR
4160
4161 =item readlink
4162
4163 Returns the value of a symbolic link, if symbolic links are
4164 implemented.  If not, gives a fatal error.  If there is some system
4165 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4166 omitted, uses C<$_>.
4167
4168 =item readpipe EXPR
4169
4170 EXPR is executed as a system command.
4171 The collected standard output of the command is returned.
4172 In scalar context, it comes back as a single (potentially
4173 multi-line) string.  In list context, returns a list of lines
4174 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4175 This is the internal function implementing the C<qx/EXPR/>
4176 operator, but you can use it directly.  The C<qx/EXPR/>
4177 operator is discussed in more detail in L<perlop/"I/O Operators">.
4178
4179 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4180
4181 Receives a message on a socket.  Attempts to receive LENGTH characters
4182 of data into variable SCALAR from the specified SOCKET filehandle.
4183 SCALAR will be grown or shrunk to the length actually read.  Takes the
4184 same flags as the system call of the same name.  Returns the address
4185 of the sender if SOCKET's protocol supports this; returns an empty
4186 string otherwise.  If there's an error, returns the undefined value.
4187 This call is actually implemented in terms of recvfrom(2) system call.
4188 See L<perlipc/"UDP: Message Passing"> for examples.
4189
4190 Note the I<characters>: depending on the status of the socket, either
4191 (8-bit) bytes or characters are received.  By default all sockets
4192 operate on bytes, but for example if the socket has been changed using
4193 binmode() to operate with the C<:utf8> I/O layer (see the C<open>
4194 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4195 characters, not bytes.  Similarly for the C<:encoding> pragma:
4196 in that case pretty much any characters can be read.
4197
4198 =item redo LABEL
4199
4200 =item redo
4201
4202 The C<redo> command restarts the loop block without evaluating the
4203 conditional again.  The C<continue> block, if any, is not executed.  If
4204 the LABEL is omitted, the command refers to the innermost enclosing
4205 loop.  Programs that want to lie to themselves about what was just input 
4206 normally use this command:
4207
4208     # a simpleminded Pascal comment stripper
4209     # (warning: assumes no { or } in strings)
4210     LINE: while (<STDIN>) {
4211         while (s|({.*}.*){.*}|$1 |) {}
4212         s|{.*}| |;
4213         if (s|{.*| |) {
4214             $front = $_;
4215             while (<STDIN>) {
4216                 if (/}/) {      # end of comment?
4217                     s|^|$front\{|;
4218                     redo LINE;
4219                 }
4220             }
4221         }
4222         print;
4223     }
4224
4225 C<redo> cannot be used to retry a block which returns a value such as
4226 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
4227 a grep() or map() operation.
4228
4229 Note that a block by itself is semantically identical to a loop
4230 that executes once.  Thus C<redo> inside such a block will effectively
4231 turn it into a looping construct.
4232
4233 See also L</continue> for an illustration of how C<last>, C<next>, and
4234 C<redo> work.
4235
4236 =item ref EXPR
4237
4238 =item ref
4239
4240 Returns a non-empty string if EXPR is a reference, the empty
4241 string otherwise. If EXPR
4242 is not specified, C<$_> will be used.  The value returned depends on the
4243 type of thing the reference is a reference to.
4244 Builtin types include:
4245
4246     SCALAR
4247     ARRAY
4248     HASH
4249     CODE
4250     REF
4251     GLOB
4252     LVALUE
4253
4254 If the referenced object has been blessed into a package, then that package
4255 name is returned instead.  You can think of C<ref> as a C<typeof> operator.
4256
4257     if (ref($r) eq "HASH") {
4258         print "r is a reference to a hash.\n";
4259     }
4260     unless (ref($r)) {
4261         print "r is not a reference at all.\n";
4262     }
4263
4264 See also L<perlref>.
4265
4266 =item rename OLDNAME,NEWNAME
4267
4268 Changes the name of a file; an existing file NEWNAME will be
4269 clobbered.  Returns true for success, false otherwise.
4270
4271 Behavior of this function varies wildly depending on your system
4272 implementation.  For example, it will usually not work across file system
4273 boundaries, even though the system I<mv> command sometimes compensates
4274 for this.  Other restrictions include whether it works on directories,
4275 open files, or pre-existing files.  Check L<perlport> and either the
4276 rename(2) manpage or equivalent system documentation for details.
4277
4278 =item require VERSION
4279
4280 =item require EXPR
4281
4282 =item require
4283
4284 Demands a version of Perl specified by VERSION, or demands some semantics
4285 specified by EXPR or by C<$_> if EXPR is not supplied.
4286
4287 VERSION may be either a numeric argument such as 5.006, which will be
4288 compared to C<$]>, or a literal of the form v5.6.1, which will be compared
4289 to C<$^V> (aka $PERL_VERSION).  A fatal error is produced at run time if
4290 VERSION is greater than the version of the current Perl interpreter.
4291 Compare with L</use>, which can do a similar check at compile time.
4292
4293 Specifying VERSION as a literal of the form v5.6.1 should generally be
4294 avoided, because it leads to misleading error messages under earlier
4295 versions of Perl that do not support this syntax.  The equivalent numeric
4296 version should be used instead.
4297
4298     require v5.6.1;     # run time version check
4299     require 5.6.1;      # ditto
4300     require 5.006_001;  # ditto; preferred for backwards compatibility
4301
4302 Otherwise, C<require> demands that a library file be included if it
4303 hasn't already been included.  The file is included via the do-FILE
4304 mechanism, which is essentially just a variety of C<eval>.  Has
4305 semantics similar to the following subroutine:
4306
4307     sub require {
4308        my ($filename) = @_;
4309        if (exists $INC{$filename}) {
4310            return 1 if $INC{$filename};
4311            die "Compilation failed in require";
4312        }
4313        my ($realfilename,$result);
4314        ITER: {
4315            foreach $prefix (@INC) {
4316                $realfilename = "$prefix/$filename";
4317                if (-f $realfilename) {
4318                    $INC{$filename} = $realfilename;
4319                    $result = do $realfilename;
4320                    last ITER;
4321                }
4322            }
4323            die "Can't find $filename in \@INC";
4324        }
4325        if ($@) {
4326            $INC{$filename} = undef;
4327            die $@;
4328        } elsif (!$result) {
4329            delete $INC{$filename};
4330            die "$filename did not return true value";
4331        } else {
4332            return $result;
4333        }
4334     }
4335
4336 Note that the file will not be included twice under the same specified
4337 name.
4338
4339 The file must return true as the last statement to indicate
4340 successful execution of any initialization code, so it's customary to
4341 end such a file with C<1;> unless you're sure it'll return true
4342 otherwise.  But it's better just to put the C<1;>, in case you add more
4343 statements.
4344
4345 If EXPR is a bareword, the require assumes a "F<.pm>" extension and
4346 replaces "F<::>" with "F</>" in the filename for you,
4347 to make it easy to load standard modules.  This form of loading of
4348 modules does not risk altering your namespace.
4349
4350 In other words, if you try this:
4351
4352         require Foo::Bar;    # a splendid bareword
4353
4354 The require function will actually look for the "F<Foo/Bar.pm>" file in the
4355 directories specified in the C<@INC> array.
4356
4357 But if you try this:
4358
4359         $class = 'Foo::Bar';
4360         require $class;      # $class is not a bareword
4361     #or
4362         require "Foo::Bar";  # not a bareword because of the ""
4363
4364 The require function will look for the "F<Foo::Bar>" file in the @INC array and
4365 will complain about not finding "F<Foo::Bar>" there.  In this case you can do:
4366
4367         eval "require $class";
4368
4369 Now that you understand how C<require> looks for files in the case of
4370 a bareword argument, there is a little extra functionality going on
4371 behind the scenes.  Before C<require> looks for a "F<.pm>" extension,
4372 it will first look for a filename with a "F<.pmc>" extension.  A file
4373 with this extension is assumed to be Perl bytecode generated by
4374 L<B::Bytecode|B::Bytecode>.  If this file is found, and its modification
4375 time is newer than a coinciding "F<.pm>" non-compiled file, it will be
4376 loaded in place of that non-compiled file ending in a "F<.pm>" extension.
4377
4378 You can also insert hooks into the import facility, by putting directly
4379 Perl code into the @INC array.  There are three forms of hooks: subroutine
4380 references, array references and blessed objects.
4381
4382 Subroutine references are the simplest case.  When the inclusion system
4383 walks through @INC and encounters a subroutine, this subroutine gets
4384 called with two parameters, the first being a reference to itself, and the
4385 second the name of the file to be included (e.g. "F<Foo/Bar.pm>").  The
4386 subroutine should return C<undef> or a filehandle, from which the file to
4387 include will be read.  If C<undef> is returned, C<require> will look at
4388 the remaining elements of @INC.
4389
4390 If the hook is an array reference, its first element must be a subroutine
4391 reference.  This subroutine is called as above, but the first parameter is
4392 the array reference.  This enables to pass indirectly some arguments to
4393 the subroutine.
4394
4395 In other words, you can write:
4396
4397     push @INC, \&my_sub;
4398     sub my_sub {
4399         my ($coderef, $filename) = @_;  # $coderef is \&my_sub
4400         ...
4401     }
4402
4403 or:
4404
4405     push @INC, [ \&my_sub, $x, $y, ... ];
4406     sub my_sub {
4407         my ($arrayref, $filename) = @_;
4408         # Retrieve $x, $y, ...
4409         my @parameters = @$arrayref[1..$#$arrayref];
4410         ...
4411     }
4412
4413 If the hook is an object, it must provide an INC method that will be
4414 called as above, the first parameter being the object itself.  (Note that
4415 you must fully qualify the sub's name, as it is always forced into package
4416 C<main>.)  Here is a typical code layout:
4417
4418     # In Foo.pm
4419     package Foo;
4420     sub new { ... }
4421     sub Foo::INC {
4422         my ($self, $filename) = @_;
4423         ...
4424     }
4425
4426     # In the main program
4427     push @INC, new Foo(...);
4428
4429 Note that these hooks are also permitted to set the %INC entry
4430 corresponding to the files they have loaded. See L<perlvar/%INC>.
4431
4432 For a yet-more-powerful import facility, see L</use> and L<perlmod>.
4433
4434 =item reset EXPR
4435
4436 =item reset
4437
4438 Generally used in a C<continue> block at the end of a loop to clear
4439 variables and reset C<??> searches so that they work again.  The
4440 expression is interpreted as a list of single characters (hyphens
4441 allowed for ranges).  All variables and arrays beginning with one of
4442 those letters are reset to their pristine state.  If the expression is
4443 omitted, one-match searches (C<?pattern?>) are reset to match again.  Resets
4444 only variables or searches in the current package.  Always returns
4445 1.  Examples:
4446
4447     reset 'X';          # reset all X variables
4448     reset 'a-z';        # reset lower case variables
4449     reset;              # just reset ?one-time? searches
4450
4451 Resetting C<"A-Z"> is not recommended because you'll wipe out your
4452 C<@ARGV> and C<@INC> arrays and your C<%ENV> hash.  Resets only package
4453 variables--lexical variables are unaffected, but they clean themselves
4454 up on scope exit anyway, so you'll probably want to use them instead.
4455 See L</my>.
4456
4457 =item return EXPR
4458
4459 =item return
4460
4461 Returns from a subroutine, C<eval>, or C<do FILE> with the value
4462 given in EXPR.  Evaluation of EXPR may be in list, scalar, or void
4463 context, depending on how the return value will be used, and the context
4464 may vary from one execution to the next (see C<wantarray>).  If no EXPR
4465 is given, returns an empty list in list context, the undefined value in
4466 scalar context, and (of course) nothing at all in a void context.
4467
4468 (Note that in the absence of an explicit C<return>, a subroutine, eval,
4469 or do FILE will automatically return the value of the last expression
4470 evaluated.)
4471
4472 =item reverse LIST
4473
4474 In list context, returns a list value consisting of the elements
4475 of LIST in the opposite order.  In scalar context, concatenates the
4476 elements of LIST and returns a string value with all characters
4477 in the opposite order.
4478
4479     print reverse <>;           # line tac, last line first
4480
4481     undef $/;                   # for efficiency of <>
4482     print scalar reverse <>;    # character tac, last line tsrif
4483
4484 Used without arguments in scalar context, reverse() reverses C<$_>.
4485
4486 This operator is also handy for inverting a hash, although there are some
4487 caveats.  If a value is duplicated in the original hash, only one of those
4488 can be represented as a key in the inverted hash.  Also, this has to
4489 unwind one hash and build a whole new one, which may take some time
4490 on a large hash, such as from a DBM file.
4491
4492     %by_name = reverse %by_address;     # Invert the hash
4493
4494 =item rewinddir DIRHANDLE
4495
4496 Sets the current position to the beginning of the directory for the
4497 C<readdir> routine on DIRHANDLE.
4498
4499 =item rindex STR,SUBSTR,POSITION
4500
4501 =item rindex STR,SUBSTR
4502
4503 Works just like index() except that it returns the position of the LAST
4504 occurrence of SUBSTR in STR.  If POSITION is specified, returns the
4505 last occurrence at or before that position.
4506
4507 =item rmdir FILENAME
4508
4509 =item rmdir
4510
4511 Deletes the directory specified by FILENAME if that directory is
4512 empty.  If it succeeds it returns true, otherwise it returns false and
4513 sets C<$!> (errno).  If FILENAME is omitted, uses C<$_>.
4514
4515 =item s///
4516
4517 The substitution operator.  See L<perlop>.
4518
4519 =item scalar EXPR
4520
4521 Forces EXPR to be interpreted in scalar context and returns the value
4522 of EXPR.
4523
4524     @counts = ( scalar @a, scalar @b, scalar @c );
4525
4526 There is no equivalent operator to force an expression to
4527 be interpolated in list context because in practice, this is never
4528 needed.  If you really wanted to do so, however, you could use
4529 the construction C<@{[ (some expression) ]}>, but usually a simple
4530 C<(some expression)> suffices.
4531
4532 Because C<scalar> is unary operator, if you accidentally use for EXPR a
4533 parenthesized list, this behaves as a scalar comma expression, evaluating
4534 all but the last element in void context and returning the final element
4535 evaluated in scalar context.  This is seldom what you want.
4536
4537 The following single statement:
4538
4539         print uc(scalar(&foo,$bar)),$baz;
4540
4541 is the moral equivalent of these two:
4542
4543         &foo;
4544         print(uc($bar),$baz);
4545
4546 See L<perlop> for more details on unary operators and the comma operator.
4547
4548 =item seek FILEHANDLE,POSITION,WHENCE
4549
4550 Sets FILEHANDLE's position, just like the C<fseek> call of C<stdio>.
4551 FILEHANDLE may be an expression whose value gives the name of the
4552 filehandle.  The values for WHENCE are C<0> to set the new position
4553 I<in bytes> to POSITION, C<1> to set it to the current position plus
4554 POSITION, and C<2> to set it to EOF plus POSITION (typically
4555 negative).  For WHENCE you may use the constants C<SEEK_SET>,
4556 C<SEEK_CUR>, and C<SEEK_END> (start of the file, current position, end
4557 of the file) from the Fcntl module.  Returns C<1> upon success, C<0>
4558 otherwise.
4559
4560 Note the I<in bytes>: even if the filehandle has been set to
4561 operate on characters (for example by using the C<:utf8> open
4562 layer), tell() will return byte offsets, not character offsets
4563 (because implementing that would render seek() and tell() rather slow).
4564
4565 If you want to position file for C<sysread> or C<syswrite>, don't use
4566 C<seek>--buffering makes its effect on the file's system position
4567 unpredictable and non-portable.  Use C<sysseek> instead.
4568
4569 Due to the rules and rigors of ANSI C, on some systems you have to do a
4570 seek whenever you switch between reading and writing.  Amongst other
4571 things, this may have the effect of calling stdio's clearerr(3).
4572 A WHENCE of C<1> (C<SEEK_CUR>) is useful for not moving the file position:
4573
4574     seek(TEST,0,1);
4575
4576 This is also useful for applications emulating C<tail -f>.  Once you hit
4577 EOF on your read, and then sleep for a while, you might have to stick in a
4578 seek() to reset things.  The C<seek> doesn't change the current position,
4579 but it I<does> clear the end-of-file condition on the handle, so that the
4580 next C<< <FILE> >> makes Perl try again to read something.  We hope.
4581
4582 If that doesn't work (some IO implementations are particularly
4583 cantankerous), then you may need something more like this:
4584
4585     for (;;) {
4586         for ($curpos = tell(FILE); $_ = <FILE>;
4587              $curpos = tell(FILE)) {
4588             # search for some stuff and put it into files
4589         }
4590         sleep($for_a_while);
4591         seek(FILE, $curpos, 0);
4592     }
4593
4594 =item seekdir DIRHANDLE,POS
4595
4596 Sets the current position for the C<readdir> routine on DIRHANDLE.  POS
4597 must be a value returned by C<telldir>.  C<seekdir> also has the same caveats
4598 about possible directory compaction as the corresponding system library
4599 routine.
4600
4601 =item select FILEHANDLE
4602
4603 =item select
4604
4605 Returns the currently selected filehandle.  Sets the current default
4606 filehandle for output, if FILEHANDLE is supplied.  This has two
4607 effects: first, a C<write> or a C<print> without a filehandle will
4608 default to this FILEHANDLE.  Second, references to variables related to
4609 output will refer to this output channel.  For example, if you have to
4610 set the top of form format for more than one output channel, you might
4611 do the following:
4612
4613     select(REPORT1);
4614     $^ = 'report1_top';
4615     select(REPORT2);
4616     $^ = 'report2_top';
4617