installman

   1 #!./perl -w
   2 BEGIN { @INC = ('lib') }
   3 use strict;
   4 use Config;
   5 use Getopt::Long;
   6 use File::Find;
   7 use File::Copy;
   8 use File::Path qw(mkpath);
   9 use ExtUtils::Packlist;
  10 use Pod::Man;
  11 use subs qw(unlink chmod rename link);
  12 use vars qw($packlist @modpods);
  13 require Cwd;
  14
  15 if ($Config{d_umask}) {
  16     umask(022); # umasks like 077 aren't that useful for installations
  17 }
  18
  19 $ENV{SHELL} = 'sh' if $^O eq 'os2';
  20
  21 my $ver = $Config{version};     # Not used presently.
  22 my $release = substr($],0,3);   # Not used presently.
  23 my $patchlevel = substr($],3,2);
  24 die "Patchlevel of perl ($patchlevel)",
  25     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
  26         if $patchlevel != $Config{'PERL_VERSION'};
  27
  28 my $usage =
  29 "Usage:  installman --man1dir=/usr/wherever --man1ext=1
  30                    --man3dir=/usr/wherever --man3ext=3
  31                    --batchlimit=40
  32                    --notify --verbose --silent --help
  33         Defaults are:
  34         man1dir = $Config{'installman1dir'};
  35         man1ext = $Config{'man1ext'};
  36         man3dir = $Config{'installman3dir'};
  37         man3ext = $Config{'man3ext'};
  38         --notify  (or -n) just lists commands that would be executed.
  39         --verbose (or -V) report all progress.
  40         --silent  (or -S) be silent. Only report errors.\n";
  41
  42 my %opts;
  43 GetOptions( \%opts,
  44             qw( man1dir=s man1ext=s man3dir=s man3ext=s batchlimit=i
  45                 notify n help silent S verbose V))
  46         || die $usage;
  47 die $usage if $opts{help};
  48
  49 $opts{man1dir} = $Config{'installman1dir'}
  50     unless defined($opts{man1dir});
  51 $opts{man1ext} = $Config{'man1ext'}
  52     unless defined($opts{man1ext});
  53 $opts{man3dir} = $Config{'installman3dir'}
  54     unless defined($opts{man3dir});
  55 $opts{man3ext} = $Config{'man3ext'}
  56     unless defined($opts{man3ext});
  57 $opts{silent} ||= $opts{S};
  58 $opts{notify} ||= $opts{n};
  59 $opts{verbose} ||= $opts{V} || $opts{notify};
  60
  61 #Sanity checks
  62
  63 -x  "./perl$Config{exe_ext}"
  64   or warn "./perl$Config{exe_ext} not found!  Have you run make?\n";
  65 -d  $Config{'installprivlib'}
  66         || warn "Perl library directory $Config{'installprivlib'} not found.
  67                 Have you run make install?.  (Installing anyway.)\n";
  68 -x "t/perl$Config{exe_ext}"             || warn "WARNING: You've never run 'make test'!!!",
  69         "  (Installing anyway.)\n";
  70
  71 $packlist = ExtUtils::Packlist->new("$Config{installarchlib}/.packlist");
  72
  73
  74 # Install the main pod pages.
  75 pod2man('pod', $opts{man1dir}, $opts{man1ext});
  76
  77 # Install the pods for library modules.
  78 pod2man('lib', $opts{man3dir}, $opts{man3ext});
  79
  80 # Install the pods embedded in the installed scripts
  81 open UTILS, "utils.lst" or die "Can't open 'utils.lst': $!";
  82 while (<UTILS>) {
  83     next if /^#/;
  84     chomp;
  85     $_ = $1 if /#.*pod\s*=\s*(\S+)/;
  86     my ($where, $what) = m|^(.*?)/(\S+)|;
  87     pod2man($where, $opts{man1dir}, $opts{man1ext}, $what);
  88     if (($where, $what) = m|#.*link\s*=\s*(\S+)/(\S+)|) {
  89         pod2man($where, $opts{man1dir}, $opts{man1ext}, $what);
  90     }
  91 }
  92
  93 sub pod2man {
  94     # @script is scripts names if we are installing manpages embedded
  95     # in scripts, () otherwise
  96     my($poddir, $mandir, $manext, @script) = @_;
  97
  98     my($downdir); # can't just use .. when installing xsubpp manpage
  99
 100     $downdir = $poddir;
 101     $downdir =~ s:[^/]+:..:g;
 102     my($builddir) = Cwd::getcwd();
 103
 104     if ($mandir eq ' ' or $mandir eq '') {
 105         if (@script) {
 106             warn "Skipping installation of $poddir/$_ man page.\n"
 107                 foreach @script;
 108         } else {
 109             warn "Skipping installation of $poddir man pages.\n";
 110         }
 111         return;
 112     }
 113
 114     print "chdir $poddir\n" if $opts{verbose};
 115     chdir $poddir || die "Unable to cd to $poddir directory!\n$!\n";
 116
 117     mkpath($mandir, $opts{verbose}, 0777) unless $opts{notify};  # In File::Path
 118     # Make a list of all the .pm and .pod files in the directory.  We will
 119     # always run from the lib directory and use the full pathname
 120     # of the pod.
 121     if (@script) {
 122         @modpods = @script;
 123     }
 124     else {
 125         @modpods = ();
 126         File::Find::find(\&lsmodpods, '.');
 127     }
 128     my @to_process;
 129     foreach my $mod (@modpods) {
 130         my $manpage = $mod;
 131         my $tmp;
 132         # Skip .pm files that have corresponding .pod files, and Functions.pm.
 133         next if (($tmp = $mod) =~ s/\.pm$/.pod/ && -f $tmp);
 134         next if ($mod eq 'Pod/Functions.pm');   #### Used only by pod itself
 135
 136         # Convert name from  File/Basename.pm to File::Basename.3 format,
 137         # if necessary.
 138         $manpage =~ s#\.p(m|od)$##;
 139         if ($^O eq 'os2' || $^O eq 'amigaos' || $^O eq 'uwin' || $^O eq 'cygwin') {
 140           $manpage =~ s#/#.#g;
 141         }
 142         else {
 143           $manpage =~ s#/#::#g;
 144         }
 145         $tmp = "${mandir}/${manpage}.tmp";
 146         $manpage = "${mandir}/${manpage}.${manext}";
 147         push @to_process, [$mod, $tmp, $manpage];
 148     }
 149
 150     my $parser = Pod::Man->new( section => $manext,
 151                                 official=> 1,
 152                                 center  => 'Perl Programmers Reference Guide'
 153                               );
 154     foreach my $page (@to_process) {
 155         my($pod, $tmp, $manpage) = @$page;
 156
 157         print "  $manpage\n";
 158         if (!$opts{notify} && $parser->parse_from_file($pod, $tmp)) {
 159             if (-s $tmp) {
 160                 if (rename($tmp, $manpage)) {
 161                     $packlist->{$manpage} = { type => 'file' };
 162                     next;
 163                 }
 164             }
 165             unlink($tmp);
 166         }
 167     }
 168     chdir "$builddir" || die "Unable to cd back to $builddir directory!\n$!\n";
 169     print "  chdir $builddir\n" if $opts{verbose};
 170 }
 171
 172 sub lsmodpods {
 173     my $dir  = $File::Find::dir;
 174     my $name = $File::Find::name;
 175     if (-f $_) {
 176         $name =~ s#^\./##;
 177         push(@modpods, $name) if ($name =~ /\.p(m|od)$/);
 178     }
 179 }
 180
 181 $packlist->write() unless $opts{notify};
 182 print "  Installation complete\n" if $opts{verbose};
 183
 184 exit 0;
 185
 186
 187 ###############################################################################
 188 # Utility subroutines from installperl
 189
 190 sub unlink {
 191     my(@names) = @_;
 192     my $cnt = 0;
 193
 194     foreach my $name (@names) {
 195         next unless -e $name;
 196         chmod 0777, $name if $^O eq 'os2';
 197         print "  unlink $name\n" if $opts{verbose};
 198         ( CORE::unlink($name) and ++$cnt
 199             or warn "Couldn't unlink $name: $!\n" ) unless $opts{notify};
 200     }
 201     return $cnt;
 202 }
 203
 204 sub link {
 205     my($from,$to) = @_;
 206     my($success) = 0;
 207
 208     print "  ln $from $to\n" if $opts{verbose};
 209     eval {
 210         CORE::link($from, $to)
 211             ? $success++
 212             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
 213               ? die "AFS"  # okay inside eval {}
 214               : warn "Couldn't link $from to $to: $!\n"
 215           unless $opts{notify};
 216     };
 217     if ($@) {
 218         File::Copy::copy($from, $to)
 219             ? $success++
 220             : warn "Couldn't copy $from to $to: $!\n"
 221           unless $opts{notify};
 222     }
 223     $success;
 224 }
 225
 226 sub rename {
 227     my($from,$to) = @_;
 228     if (-f $to and not unlink($to)) {
 229         my($i);
 230         for ($i = 1; $i < 50; $i++) {
 231             last if CORE::rename($to, "$to.$i");
 232         }
 233         warn("Cannot rename to `$to.$i': $!"), return 0
 234             if $i >= 50;        # Give up!
 235     }
 236     link($from,$to) || return 0;
 237     unlink($from);
 238 }
 239
 240 sub chmod {
 241     my($mode,$name) = @_;
 242
 243     printf "  chmod %o %s\n", $mode, $name if $opts{verbose};
 244     CORE::chmod($mode,$name) || warn sprintf("Couldn't chmod %o %s: $!\n",$mode,$name)
 245         unless $opts{notify};
 246 }
 247
 248 sub samepath {
 249     my($p1, $p2) = @_;
 250     my($dev1, $ino1, $dev2, $ino2);
 251
 252     if ($p1 ne $p2) {
 253         ($dev1, $ino1) = stat($p1);
 254         ($dev2, $ino2) = stat($p2);
 255         ($dev1 == $dev2 && $ino1 == $ino2);
 256     }
 257     else {
 258         1;
 259     }
 260 }